configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [208],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
  80
  81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  82 m4_ifdef([GTK_DOC_CHECK], [
  83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  85           enable_gtk_doc=no])
  86
  87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  89 ])
  90
  91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  93 ], [
  94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  95    enable_introspection=no])
  96
  97 AC_CHECK_TOOL(OBJCOPY, objcopy)
  98 AC_CHECK_TOOL(STRINGS, strings)
  99 AC_CHECK_TOOL(GPERF, gperf)
 100 if test -z "$GPERF" ; then
 101         AC_MSG_ERROR([*** gperf not found])
 102 fi
 103
 104 # ------------------------------------------------------------------------------
 105 address_sanitizer_cflags=
 106 address_sanitizer_cppflags=
 107 address_sanitizer_ldflags=
 108 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 109 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 110             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 111             AS_IF([test -z "$with_as_cflags"],
 112                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 113             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 114             address_sanitizer_cppflags="-DVALGRIND=1"
 115             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 116       ])
 117
 118 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 119         -pipe \
 120         -Wall \
 121         -Wextra \
 122         -Wno-inline \
 123         -Wundef \
 124         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 125         -Wlogical-op \
 126         -Wsign-compare \
 127         -Wmissing-include-dirs \
 128         -Wold-style-definition \
 129         -Wpointer-arith \
 130         -Winit-self \
 131         -Wdeclaration-after-statement \
 132         -Wfloat-equal \
 133         -Wmissing-prototypes \
 134         -Wstrict-prototypes \
 135         -Wredundant-decls \
 136         -Wmissing-declarations \
 137         -Wmissing-noreturn \
 138         -Wshadow \
 139         -Wendif-labels \
 140         -Wcast-align \
 141         -Wstrict-aliasing=2 \
 142         -Wwrite-strings \
 143         -Wno-long-long \
 144         -Wno-overlength-strings \
 145         -Wno-unused-parameter \
 146         -Wno-missing-field-initializers \
 147         -Wno-unused-result \
 148         -Werror=overflow \
 149         -ffast-math \
 150         -fno-common \
 151         -fdiagnostics-show-option \
 152         -fdiagnostics-color \
 153         -fno-strict-aliasing \
 154         -fvisibility=hidden \
 155         -ffunction-sections \
 156         -fdata-sections \
 157         -fstack-protector \
 158         --param=ssp-buffer-size=4])
 159 AC_SUBST([OUR_CFLAGS], "$with_cflags $address_sanitizer_cflags")
 160
 161 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
 162         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 163                -Wp,-D_FORTIFY_SOURCE=2])],
 164         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 165 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $address_sanitizer_cppflags")
 166
 167 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 168         -Wl,--as-needed \
 169         -Wl,--no-undefined \
 170         -Wl,--gc-sections \
 171         -Wl,-z,relro \
 172         -Wl,-z,now])
 173 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $address_sanitizer_ldflags")
 174
 175 # ------------------------------------------------------------------------------
 176 # we use python to build the man page index, and for systemd-python
 177 have_python=no
 178 AC_ARG_WITH([python],
 179         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 180
 181 AS_IF([test "x$with_python" != "xno"], [
 182         AM_PATH_PYTHON(,, [:])
 183         AS_IF([test "$PYTHON" != :], [have_python=yes])
 184 ])
 185 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 186 AS_IF([test "x$PYTHON_BINARY" = "x"],
 187       [AS_IF([test "x$have_python" = "xyes"],
 188              [PYTHON_BINARY="$(which "$PYTHON")"],
 189              [PYTHON_BINARY=/usr/bin/python])])
 190 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 191
 192 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
 193       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
 194
 195 have_python_devel=no
 196 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
 197 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
 198       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
 199             [have_python_devel=yes],
 200             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
 201                   [have_python_devel=yes],
 202                   [have_python_devel=no])])
 203       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
 204             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
 205       AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 206 ])
 207 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 208
 209 # ------------------------------------------------------------------------------
 210
 211 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 212 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 213 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 214
 215 # unconditionally pull-in librt with old glibc versions
 216 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 217
 218 save_LIBS="$LIBS"
 219 LIBS=
 220 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 221 CAP_LIBS="$LIBS"
 222 AC_SUBST(CAP_LIBS)
 223
 224 LIBS=
 225 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 226 RT_LIBS="$LIBS"
 227 AC_SUBST(RT_LIBS)
 228 LIBS="$save_LIBS"
 229
 230 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 231 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 232 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 233 #include <unistd.h>
 234 #include <sys/mount.h>
 235 #include <fcntl.h>]])
 236
 237 # This makes sure pkg.m4 is available.
 238 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 239
 240 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 241
 242
 243 # ------------------------------------------------------------------------------
 244 have_coverage=no
 245 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 246 if test "x$enable_coverage" = "xyes" ; then
 247         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 248         if test "x$lcov_found" = xno ; then
 249                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 250         else
 251                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 252                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 253                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 254                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 255                 else
 256                         have_coverage=yes
 257                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 258                         -fprofile-arcs \
 259                         -ftest-coverage])
 260                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 261                 fi
 262         fi
 263 fi
 264 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 265
 266 # ------------------------------------------------------------------------------
 267 have_kmod=no
 268 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 269 if test "x$enable_kmod" != "xno"; then
 270         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 271         if test "x$have_kmod" = "xyes"; then
 272                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 273                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 274                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 275         fi
 276         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 277                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 278         fi
 279 fi
 280 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 281
 282 # ------------------------------------------------------------------------------
 283 have_blkid=no
 284 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 285 if test "x$enable_blkid" != "xno"; then
 286         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 287                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 288         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 289                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 290         fi
 291 fi
 292 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 293
 294 # ------------------------------------------------------------------------------
 295 have_ima=yes
 296 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 297                 [case "${enableval}" in
 298                         yes) have_ima=yes ;;
 299                         no) have_ima=no ;;
 300                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 301                 esac],
 302                 [have_ima=yes])
 303
 304 if test "x${have_ima}" != xno ; then
 305         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 306 fi
 307
 308 # ------------------------------------------------------------------------------
 309 have_chkconfig=yes
 310 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 311                 [case "${enableval}" in
 312                         yes) have_chkconfig=yes ;;
 313                         no) have_chkconfig=no ;;
 314                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 315                 esac],
 316                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 317                 if test -z "$CHKCONFIG"; then
 318                         have_chkconfig=no
 319                 else
 320                         have_chkconfig=yes
 321                 fi])
 322
 323 if test "x${have_chkconfig}" != xno ; then
 324         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 325 fi
 326
 327 # ------------------------------------------------------------------------------
 328 have_selinux=no
 329 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 330 if test "x$enable_selinux" != "xno"; then
 331         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 332                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 333         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 334                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 335         fi
 336 fi
 337 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 338
 339 AC_ARG_WITH(debug-shell,
 340         AS_HELP_STRING([--with-debug-shell=PATH],
 341                 [Path to debug shell binary]),
 342         [SUSHELL="$withval"],[
 343         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 344
 345 AC_SUBST(SUSHELL)
 346
 347 AC_ARG_WITH([debug-tty],
 348         AS_HELP_STRING([--with-debug-tty=PATH],
 349                 [Specify the tty device for debug shell]),
 350         [DEBUGTTY="$withval"],
 351         [DEBUGTTY=/dev/tty9])
 352
 353 AC_SUBST(DEBUGTTY)
 354
 355 # ------------------------------------------------------------------------------
 356 have_xz=no
 357 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 358 if test "x$enable_xz" != "xno"; then
 359         PKG_CHECK_MODULES(XZ, [ liblzma ],
 360                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 361         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 362                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 363         fi
 364 fi
 365 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 366
 367 # ------------------------------------------------------------------------------
 368 AC_ARG_ENABLE([tcpwrap],
 369         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 370                 [case "${enableval}" in
 371                         yes) have_tcpwrap=yes ;;
 372                         no) have_tcpwrap=no ;;
 373                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 374                 esac],
 375                 [have_tcpwrap=auto])
 376
 377 if test "x${have_tcpwrap}" != xno ; then
 378         ACX_LIBWRAP
 379         if test "x${LIBWRAP_LIBS}" = x ; then
 380                 if test "x$have_tcpwrap" = xyes ; then
 381                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 382                 fi
 383                 have_tcpwrap=no
 384         else
 385                 have_tcpwrap=yes
 386         fi
 387 else
 388         LIBWRAP_LIBS=
 389 fi
 390 AC_SUBST(LIBWRAP_LIBS)
 391
 392 # ------------------------------------------------------------------------------
 393 AC_ARG_ENABLE([pam],
 394         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 395                 [case "${enableval}" in
 396                         yes) have_pam=yes ;;
 397                         no) have_pam=no ;;
 398                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 399                 esac],
 400                 [have_pam=auto])
 401
 402 if test "x${have_pam}" != xno ; then
 403         AC_CHECK_HEADERS(
 404                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 405                 [have_pam=yes],
 406                 [if test "x$have_pam" = xyes ; then
 407                         AC_MSG_ERROR([*** PAM headers not found.])
 408                 fi])
 409
 410         AC_CHECK_LIB(
 411                 [pam],
 412                 [pam_syslog],
 413                 [have_pam=yes],
 414                 [if test "x$have_pam" = xyes ; then
 415                         AC_MSG_ERROR([*** libpam not found.])
 416                 fi])
 417
 418         if test "x$have_pam" = xyes ; then
 419                 PAM_LIBS="-lpam -lpam_misc"
 420                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 421         else
 422                 have_pam=no
 423         fi
 424 else
 425         PAM_LIBS=
 426 fi
 427 AC_SUBST(PAM_LIBS)
 428 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 429
 430 # ------------------------------------------------------------------------------
 431 AC_ARG_ENABLE([acl],
 432         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 433                 [case "${enableval}" in
 434                         yes) have_acl=yes ;;
 435                         no) have_acl=no ;;
 436                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 437                 esac],
 438                 [have_acl=auto])
 439
 440 if test "x${have_acl}" != xno ; then
 441         AC_CHECK_HEADERS(
 442                 [sys/acl.h acl/libacl.h],
 443                 [have_acl=yes],
 444                 [if test "x$have_acl" = xyes ; then
 445                         AC_MSG_ERROR([*** ACL headers not found.])
 446                 fi])
 447
 448         AC_CHECK_LIB(
 449                 [acl],
 450                 [acl_get_file],
 451                 [have_acl=yes],
 452                 [if test "x$have_acl" = xyes ; then
 453                         AC_MSG_ERROR([*** libacl not found.])
 454                 fi])
 455
 456         if test "x$have_acl" = xyes ; then
 457                 ACL_LIBS="-lacl"
 458                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 459         else
 460                 have_acl=no
 461         fi
 462 else
 463         ACL_LIBS=
 464 fi
 465 AC_SUBST(ACL_LIBS)
 466 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 467
 468 # ------------------------------------------------------------------------------
 469 AC_ARG_ENABLE([xattr],
 470         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 471                 [case "${enableval}" in
 472                         yes) have_xattr=yes ;;
 473                         no) have_xattr=no ;;
 474                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 475                 esac],
 476                 [have_xattr=auto])
 477
 478 if test "x${have_xattr}" != xno ; then
 479         AC_CHECK_HEADERS(
 480                 [attr/xattr.h],
 481                 [have_xattr=yes],
 482                 [if test "x$have_xattr" = xyes ; then
 483                         AC_MSG_ERROR([*** XATTR headers not found.])
 484                 fi])
 485
 486         AC_CHECK_LIB(
 487                 [attr],
 488                 [fsetxattr],
 489                 [have_xattr=yes],
 490                 [if test "x$have_xattr" = xyes ; then
 491                         AC_MSG_ERROR([*** libattr not found.])
 492                 fi])
 493
 494         if test "x$have_xattr" = xyes ; then
 495                 XATTR_LIBS="-lattr"
 496                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 497         else
 498                 have_xattr=no
 499         fi
 500 else
 501         XATTR_LIBS=
 502 fi
 503 AC_SUBST(XATTR_LIBS)
 504 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 505
 506 # ------------------------------------------------------------------------------
 507 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 508                 [case "${enableval}" in
 509                         yes) have_smack=yes ;;
 510                         no) have_smack=no ;;
 511                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 512                 esac],
 513                 [have_smack=auto])
 514
 515 if test "x${have_xattr}" = xno; then
 516         if test "x${have_smack}" = xyes; then
 517                 AC_MSG_ERROR(SMACK requires xattr support)
 518         else
 519                 have_smack=no
 520         fi
 521 else
 522         if test "x${have_smack}" = xauto; then
 523                 have_smack=yes
 524         fi
 525 fi
 526
 527 AC_ARG_WITH(smack-run-label,
 528 AS_HELP_STRING([--with-smack-run-label=STRING],
 529         [run systemd --system with a specific SMACK label]),
 530         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 531         [])
 532
 533 if test "x${have_smack}" = xyes ; then
 534         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 535 fi
 536
 537 # ------------------------------------------------------------------------------
 538 AC_ARG_ENABLE([gcrypt],
 539         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 540                 [case "${enableval}" in
 541                         yes) have_gcrypt=yes ;;
 542                         no) have_gcrypt=no ;;
 543                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 544                 esac],
 545                 [have_gcrypt=auto])
 546
 547 if test "x${have_gcrypt}" != xno ; then
 548         AM_PATH_LIBGCRYPT(
 549                 [1.4.5],
 550                 [have_gcrypt=yes],
 551                 [if test "x$have_gcrypt" = xyes ; then
 552                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 553                 fi])
 554
 555         if test "x$have_gcrypt" = xyes ; then
 556                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 557                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 558                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 559         else
 560                 have_gcrypt=no
 561         fi
 562 else
 563         GCRYPT_LIBS=
 564         GCRYPT_CFLAGS=
 565 fi
 566 AC_SUBST(GCRYPT_LIBS)
 567 AC_SUBST(GCRYPT_CFLAGS)
 568 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 569
 570 # ------------------------------------------------------------------------------
 571 AC_ARG_ENABLE([audit],
 572         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 573                 [case "${enableval}" in
 574                         yes) have_audit=yes ;;
 575                         no) have_audit=no ;;
 576                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 577                 esac],
 578                 [have_audit=auto])
 579
 580 if test "x${have_audit}" != xno ; then
 581         AC_CHECK_HEADERS(
 582                 [libaudit.h],
 583                 [have_audit=yes],
 584                 [if test "x$have_audit" = xyes ; then
 585                         AC_MSG_ERROR([*** AUDIT headers not found.])
 586                 fi])
 587
 588         AC_CHECK_LIB(
 589                 [audit],
 590                 [audit_open],
 591                 [have_audit=yes],
 592                 [if test "x$have_audit" = xyes ; then
 593                         AC_MSG_ERROR([*** libaudit not found.])
 594                 fi])
 595
 596         if test "x$have_audit" = xyes ; then
 597                 AUDIT_LIBS="-laudit"
 598                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 599         else
 600                 have_audit=no
 601         fi
 602 else
 603         AUDIT_LIBS=
 604 fi
 605 AC_SUBST(AUDIT_LIBS)
 606
 607 # ------------------------------------------------------------------------------
 608 have_libcryptsetup=no
 609 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 610 if test "x$enable_libcryptsetup" != "xno"; then
 611         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 612                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 613         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 614                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 615         fi
 616 fi
 617 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 618
 619 # ------------------------------------------------------------------------------
 620 have_qrencode=no
 621 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 622 if test "x$enable_qrencode" != "xno"; then
 623         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 624                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 625         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 626                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 627         fi
 628 fi
 629 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 630
 631 # ------------------------------------------------------------------------------
 632 have_microhttpd=no
 633 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 634 if test "x$enable_microhttpd" != "xno"; then
 635         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 636                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 637         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 638                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 639         fi
 640 fi
 641 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 642
 643 # ------------------------------------------------------------------------------
 644 have_binfmt=no
 645 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 646 if test "x$enable_binfmt" != "xno"; then
 647         have_binfmt=yes
 648 fi
 649 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 650
 651 # ------------------------------------------------------------------------------
 652 have_vconsole=no
 653 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 654 if test "x$enable_vconsole" != "xno"; then
 655         have_vconsole=yes
 656 fi
 657 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 658
 659 # ------------------------------------------------------------------------------
 660 have_readahead=no
 661 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 662 if test "x$enable_readahead" != "xno"; then
 663         have_readahead=yes
 664 fi
 665 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 666
 667 # ------------------------------------------------------------------------------
 668 have_bootchart=no
 669 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 670 if test "x$enable_bootchart" != "xno"; then
 671         have_bootchart=yes
 672 fi
 673 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 674
 675 # ------------------------------------------------------------------------------
 676 have_quotacheck=no
 677 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 678 if test "x$enable_quotacheck" != "xno"; then
 679         have_quotacheck=yes
 680 fi
 681 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 682
 683 # ------------------------------------------------------------------------------
 684 have_tmpfiles=no
 685 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 686 if test "x$enable_tmpfiles" != "xno"; then
 687         have_tmpfiles=yes
 688 fi
 689 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 690
 691 # ------------------------------------------------------------------------------
 692 have_randomseed=no
 693 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 694 if test "x$enable_randomseed" != "xno"; then
 695         have_randomseed=yes
 696 fi
 697 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 698
 699 # ------------------------------------------------------------------------------
 700 have_backlight=no
 701 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
 702 if test "x$enable_backlight" != "xno"; then
 703         have_backlight=yes
 704 fi
 705 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
 706
 707 # ------------------------------------------------------------------------------
 708 have_logind=no
 709 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 710 if test "x$enable_logind" != "xno"; then
 711         have_logind=yes
 712 fi
 713 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 714 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 715
 716 # ------------------------------------------------------------------------------
 717 have_machined=no
 718 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 719 if test "x$enable_machined" != "xno"; then
 720         have_machined=yes
 721 fi
 722 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 723 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 724
 725 # ------------------------------------------------------------------------------
 726 have_hostnamed=no
 727 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 728 if test "x$enable_hostnamed" != "xno"; then
 729         have_hostnamed=yes
 730 fi
 731 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 732
 733 # ------------------------------------------------------------------------------
 734 have_timedated=no
 735 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 736 if test "x$enable_timedated" != "xno"; then
 737         have_timedated=yes
 738 fi
 739 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 740
 741 # ------------------------------------------------------------------------------
 742 have_localed=no
 743 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 744 if test "x$enable_localed" != "xno"; then
 745         have_localed=yes
 746 fi
 747 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 748
 749 # ------------------------------------------------------------------------------
 750 have_coredump=no
 751 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 752 if test "x$enable_coredump" != "xno"; then
 753         have_coredump=yes
 754 fi
 755 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 756
 757 # ------------------------------------------------------------------------------
 758 have_polkit=no
 759 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 760 if test "x$enable_polkit" != "xno"; then
 761         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 762         have_polkit=yes
 763 fi
 764 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 765
 766 # ------------------------------------------------------------------------------
 767 have_efi=no
 768 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 769 if test "x$enable_efi" != "xno"; then
 770         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 771         have_efi=yes
 772 fi
 773 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 774
 775 # ------------------------------------------------------------------------------
 776 AC_ARG_WITH(rc-local-script-path-start,
 777         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 778                 [Path to /etc/rc.local]),
 779         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 780         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 781
 782 AC_ARG_WITH(rc-local-script-path-stop,
 783         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 784                 [Path to /usr/sbin/halt.local]),
 785         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 786         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 787
 788 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 789 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 790
 791 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 792 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 793
 794 # ------------------------------------------------------------------------------
 795 AC_ARG_WITH(kbd-loadkeys,
 796         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 797                 [Path to loadkeys]),
 798         [KBD_LOADKEYS="$withval"],
 799         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 800
 801 AC_ARG_WITH(kbd-setfont,
 802         AS_HELP_STRING([--with-kbd-setfont=PATH],
 803                 [Path to setfont]),
 804         [KBD_SETFONT="$withval"],
 805         [KBD_SETFONT="/usr/bin/setfont"])
 806
 807 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 808 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 809
 810 AC_SUBST(KBD_LOADKEYS)
 811 AC_SUBST(KBD_SETFONT)
 812
 813 AC_ARG_WITH(telinit,
 814         AS_HELP_STRING([--with-telinit=PATH],
 815                 [Path to telinit]),
 816         [TELINIT="$withval"],
 817         [TELINIT="/lib/sysvinit/telinit"])
 818
 819 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 820
 821 AC_SUBST(TELINIT)
 822
 823 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 824
 825 # ------------------------------------------------------------------------------
 826 have_myhostname=no
 827 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 828 if test "x$enable_myhostname" != "xno"; then
 829         AC_HEADER_STDC
 830         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
 831
 832         AC_C_CONST
 833         AC_TYPE_SIZE_T
 834         AC_HEADER_TIME
 835
 836         AC_FUNC_MALLOC
 837         AC_FUNC_SELECT_ARGTYPES
 838         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 839
 840         have_myhostname=yes
 841 fi
 842 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 843
 844 # ------------------------------------------------------------------------------
 845 AC_ARG_WITH(firmware-path,
 846        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 847           [Firmware search path (default="")]),
 848        [], [with_firmware_path=""])
 849 OLD_IFS=$IFS
 850 IFS=:
 851 for i in $with_firmware_path; do
 852        if test "x${FIRMWARE_PATH}" = "x"; then
 853               FIRMWARE_PATH="\\\"${i}/\\\""
 854        else
 855               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 856        fi
 857 done
 858 IFS=$OLD_IFS
 859 AC_SUBST(FIRMWARE_PATH)
 860 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 861 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 862
 863 # ------------------------------------------------------------------------------
 864 AC_ARG_ENABLE([gudev],
 865        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 866        [], [enable_gudev=yes])
 867 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 868 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 869 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 870
 871 # ------------------------------------------------------------------------------
 872 have_manpages=no
 873 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 874 AS_IF([test "x$enable_manpages" != xno], [
 875         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 876                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 877         ])
 878         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 879 ])
 880 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 881
 882 # ------------------------------------------------------------------------------
 883
 884 # Location of the init scripts as mandated by LSB
 885 SYSTEM_SYSVINIT_PATH=/etc/init.d
 886 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 887 M4_DEFINES=
 888
 889 AC_ARG_WITH([sysvinit-path],
 890         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 891                 [Specify the path to where the SysV init scripts are located])],
 892         [SYSTEM_SYSVINIT_PATH="$withval"],
 893         [])
 894
 895 AC_ARG_WITH([sysvrcnd-path],
 896         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 897                 [Specify the path to the base directory for the SysV rcN.d directories])],
 898         [SYSTEM_SYSVRCND_PATH="$withval"],
 899         [])
 900
 901 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 902         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 903         SYSTEM_SYSV_COMPAT="yes"
 904         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 905 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 906         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 907 else
 908         SYSTEM_SYSV_COMPAT="no"
 909 fi
 910
 911 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 912 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 913 AC_SUBST(M4_DEFINES)
 914
 915 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 916
 917 AC_ARG_WITH([tty-gid],
 918         [AS_HELP_STRING([--with-tty-gid=GID],
 919                 [Specify the numeric GID of the 'tty' group])],
 920         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 921         [])
 922
 923 AC_ARG_WITH([dbuspolicydir],
 924         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 925         [],
 926         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 927
 928 AC_ARG_WITH([dbussessionservicedir],
 929         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 930         [],
 931         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 932
 933 AC_ARG_WITH([dbussystemservicedir],
 934         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 935         [],
 936         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 937
 938 AC_ARG_WITH([dbusinterfacedir],
 939         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 940         [],
 941         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 942
 943 AC_ARG_WITH([bashcompletiondir],
 944         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 945         [],
 946         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 947                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 948         ] , [
 949                 with_bashcompletiondir=${datadir}/bash-completion/completions
 950         ])])
 951
 952 AC_ARG_WITH([zshcompletiondir],
 953         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 954         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 955
 956 AC_ARG_WITH([rootprefix],
 957         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 958         [], [with_rootprefix=${ac_default_prefix}])
 959
 960 AC_ARG_WITH([rootlibdir],
 961         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 962         [],
 963         [with_rootlibdir=${libdir}])
 964
 965 AC_ARG_WITH([pamlibdir],
 966         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 967         [],
 968         [with_pamlibdir=${with_rootlibdir}/security])
 969
 970 AC_ARG_WITH([pamconfdir],
 971         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 972         [],
 973         [with_pamconfdir=${sysconfdir}/pam.d])
 974
 975 AC_ARG_ENABLE([split-usr],
 976         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 977         [],
 978         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 979                 enable_split_usr=yes
 980         ], [
 981                 enable_split_usr=no
 982         ])])
 983
 984 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 985         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 986 ])
 987
 988 # Work around intltoolize and gtk-doc problems in VPATH builds
 989 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 990                                        [Define to do gtk-doc tests])
 991 AS_IF([test "x$0" != "x./configure"], [
 992         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 993 ])
 994
 995 AC_ARG_ENABLE(tests,
 996        [AC_HELP_STRING([--disable-tests], [disable tests])],
 997        enable_tests=$enableval, enable_tests=yes)
 998 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 999
1000 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1001 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1002 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1003 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
1004 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1005 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1006 AC_SUBST([pamlibdir], [$with_pamlibdir])
1007 AC_SUBST([pamconfdir], [$with_pamconfdir])
1008 AC_SUBST([rootprefix], [$with_rootprefix])
1009 AC_SUBST([rootlibdir], [$with_rootlibdir])
1010
1011 AC_CONFIG_FILES([
1012         Makefile po/Makefile.in
1013         docs/libudev/Makefile
1014         docs/libudev/version.xml
1015         docs/gudev/Makefile
1016         docs/gudev/version.xml
1017 ])
1018
1019 AC_OUTPUT
1020 AC_MSG_RESULT([
1021         $PACKAGE_NAME $VERSION
1022
1023         libcryptsetup:           ${have_libcryptsetup}
1024         tcpwrap:                 ${have_tcpwrap}
1025         PAM:                     ${have_pam}
1026         AUDIT:                   ${have_audit}
1027         IMA:                     ${have_ima}
1028         SELinux:                 ${have_selinux}
1029         SMACK:                   ${have_smack}
1030         XZ:                      ${have_xz}
1031         ACL:                     ${have_acl}
1032         XATTR:                   ${have_xattr}
1033         GCRYPT:                  ${have_gcrypt}
1034         QRENCODE:                ${have_qrencode}
1035         MICROHTTPD:              ${have_microhttpd}
1036         CHKCONFIG:               ${have_chkconfig}
1037         binfmt:                  ${have_binfmt}
1038         vconsole:                ${have_vconsole}
1039         readahead:               ${have_readahead}
1040         bootchart:               ${have_bootchart}
1041         quotacheck:              ${have_quotacheck}
1042         tmpfiles:                ${have_tmpfiles}
1043         randomseed:              ${have_randomseed}
1044         backlight:               ${have_backlight}
1045         logind:                  ${have_logind}
1046         machined:                ${have_machined}
1047         hostnamed:               ${have_hostnamed}
1048         timedated:               ${have_timedated}
1049         localed:                 ${have_localed}
1050         coredump:                ${have_coredump}
1051         polkit:                  ${have_polkit}
1052         efi:                     ${have_efi}
1053         kmod:                    ${have_kmod}
1054         blkid:                   ${have_blkid}
1055         nss-myhostname:          ${have_myhostname}
1056         gudev:                   ${enable_gudev}
1057         gintrospection:          ${enable_introspection}
1058         Python:                  ${have_python}
1059         Python Headers:          ${have_python_devel}
1060         man pages:               ${have_manpages}
1061         gtk-doc:                 ${enable_gtk_doc}
1062         test coverage:           ${have_coverage}
1063         Split /usr:              ${enable_split_usr}
1064         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1065
1066         prefix:                  ${prefix}
1067         rootprefix:              ${with_rootprefix}
1068         sysconf dir:             ${sysconfdir}
1069         datarootdir:             ${datarootdir}
1070         includedir:              ${includedir}
1071         include_prefix:          ${INCLUDE_PREFIX}
1072         lib dir:                 ${libdir}
1073         rootlib dir:             ${with_rootlibdir}
1074         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1075         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1076         Build Python:            ${PYTHON}
1077         Installation Python:     ${PYTHON_BINARY}
1078         sphinx binary:           ${SPHINX_BUILD}
1079         firmware path:           ${FIRMWARE_PATH}
1080         PAM modules dir:         ${with_pamlibdir}
1081         PAM configuration dir:   ${with_pamconfdir}
1082         D-Bus policy dir:        ${with_dbuspolicydir}
1083         D-Bus session dir:       ${with_dbussessionservicedir}
1084         D-Bus system dir:        ${with_dbussystemservicedir}
1085         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1086         Bash completions dir:    ${with_bashcompletiondir}
1087         Zsh completions dir:     ${with_zshcompletiondir}
1088         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1089         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1090         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1091
1092         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1093         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1094         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1095         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1096         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1097 ])