infra/dgit-repos-server

   1 #!/usr/bin/perl -w
   2 # dgit-repos-server
   3 #
   4 # usages:
   5 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --ssh
   6 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --cron
   7 # settings
   8 #   --repos=GIT-REPOS-DIR      default DISTRO-DIR/repos/
   9 #   --suites=SUITES-FILE       default DISTRO-DIR/suites
  10 #   --policy-hook=POLICY-HOOK  default DISTRO-DIR/policy-hook
  11 #   --dgit-live=DGIT-LIVE-DIR  default DISTRO-DIR/dgit-live
  12 # (DISTRO-DIR is not used other than as default)
  13 # internal usage:
  14 #  .../dgit-repos-server --pre-receive-hook PACKAGE
  15 #
  16 # Invoked as the ssh restricted command
  17 #
  18 # Works like git-receive-pack
  19 #
  20 # SUITES is the name of a file which lists the permissible suites
  21 # one per line (#-comments and blank lines ignored)
  22 #
  23 # AUTH-SPEC is a :-separated list of
  24 #   KEYRING.GPG,AUTH-SPEC
  25 # where AUTH-SPEC is one of
  26 #   a
  27 #   mDM.TXT
  28 # (With --cron AUTH-SPEC is not used and may be the empty string.)
  29
  30 use strict;
  31 $SIG{__WARN__} = sub { die $_[0]; };
  32
  33 # DGIT-REPOS-DIR contains:
  34 # git tree (or other object)      lock (in acquisition order, outer first)
  35 #
  36 #  _tmp/PACKAGE_prospective       ! } SAME.lock, held during receive-pack
  37 #
  38 #  _tmp/PACKAGE_incoming$$        ! } SAME.lock, held during receive-pack
  39 #  _tmp/PACKAGE_incoming$$_fresh  ! }
  40 #
  41 #  PACKAGE.git                      } PACKAGE.git.lock
  42 #  PACKAGE_garbage                  }   (also covers executions of
  43 #  PACKAGE_garbage-old              }    policy hook script for PACKAGE)
  44 #  PACKAGE_garbage-tmp              }
  45 #  policy*                          } (for policy hook script, covered by
  46 #                                   }  lock only when invoked for a package)
  47 #
  48 # leaf locks, held during brief operaton only:
  49 #
  50 #  _empty                           } SAME.lock
  51 #  _empty.new                       }
  52 #
  53 #  _template                        } SAME.lock
  54 #
  55 # locks marked ! may be held during client data transfer
  56
  57 # What we do on push is this:
  58 #  - extract the destination repo name
  59 #  - make a hardlink clone of the destination repo
  60 #  - provide the destination with a stunt pre-receive hook
  61 #  - run actual git-receive-pack with that new destination
  62 #   as a result of this the stunt pre-receive hook runs; it does this:
  63 #    + understand what refs we are allegedly updating and
  64 #      check some correspondences:
  65 #        * we are updating only refs/tags/debian/* and refs/dgit/*
  66 #        * and only one of each
  67 #        * and the tag does not already exist
  68 #      and
  69 #        * recover the suite name from the destination refs/dgit/ ref
  70 #    + disassemble the signed tag into its various fields and signature
  71 #      including:
  72 #        * parsing the first line of the tag message to recover
  73 #          the package name, version and suite
  74 #        * checking that the package name corresponds to the dest repo name
  75 #        * checking that the suite name is as recovered above
  76 #    + verify the signature on the signed tag
  77 #      and if necessary check that the keyid and package are listed in dm.txt
  78 #    + check various correspondences:
  79 #        * the signed tag must refer to a commit
  80 #        * the signed tag commit must be the refs/dgit value
  81 #        * the name in the signed tag must correspond to its ref name
  82 #        * the tag name must be debian/<version> (massaged as needed)
  83 #        * the suite is one of those permitted
  84 #        * the signed tag has a suitable name
  85 #        * run the "push" policy hook
  86 #        * replay prevention for --deliberately-not-fast-forward
  87 #        * check the commit is a fast forward
  88 #        * handle a request from the policy hook for a fresh repo
  89 #    + push the signed tag and new dgit branch to the actual repo
  90 #
  91 # If the destination repo does not already exist, we need to make
  92 # sure that we create it reasonably atomically, and also that
  93 # we don't every have a destination repo containing no refs at all
  94 # (because such a thing causes git-fetch-pack to barf).  So then we
  95 # do as above, except:
  96 #  - before starting, we take out our own lock for the destination repo
  97 #  - we create a prospective new destination repo by making a copy
  98 #    of _template
  99 #  - we use the prospective new destination repo instead of the
 100 #    actual new destination repo (since the latter doesn't exist)
 101 #  - after git-receive-pack exits, we
 102 #    + check that the prospective repo contains a tag and head
 103 #    + rename the prospective destination repo into place
 104 #
 105 # Cleanup strategy:
 106 #  - We are crash-only
 107 #  - Temporary working trees and their locks are cleaned up
 108 #    opportunistically by a program which tries to take each lock and
 109 #    if successful deletes both the tree and the lockfile
 110 #  - Prospective working trees and their locks are cleaned up by
 111 #    a program which tries to take each lock and if successful
 112 #    deletes any prospective working tree and the lock (but not
 113 #    of course any actual tree)
 114 #  - It is forbidden to _remove_ the lockfile without removing
 115 #    the corresponding temporary tree, as the lockfile is also
 116 #    a stampfile whose presence indicates that there may be
 117 #    cleanup to do
 118 #
 119 # Policy hook script is invoked like this:
 120 #   POLICY-HOOK-SCRIPT DISTRO DGIT-REPOS-DIR DGIT-LIVE-DIR ACTION...
 121 # ie.
 122 #   POLICY-HOOK-SCRIPT ... check-list [...]
 123 #   POLICY-HOOK-SCRIPT ... check-package PACKAGE [...]
 124 #   POLICY-HOOK-SCRIPT ... push PACKAGE \
 125 #         VERSION SUITE TAGNAME DELIBERATELIES [...]
 126 #   POLICY-HOOK-SCRIPT ... push-confirm PACKAGE \
 127 #         VERSION SUITE TAGNAME DELIBERATELIES FRESH-REPO|'' [...]
 128 #
 129 # Exit status is a bitmask.  Bit weight constants are defined in Dgit.pm.
 130 #    NOFFCHECK   (2)
 131 #         suppress dgit-repos-server's fast-forward check ("push" only)
 132 #    FRESHREPO   (4)
 133 #         blow away repo right away (ie, as if before push or fetch)
 134 #         ("check-package" and "push" only)
 135 # any unexpected bits mean failure, and then known set bits are ignored
 136 # if no unexpected bits set, operation continues (subject to meaning
 137 # of any expected bits set).  So, eg, exit 0 means "continue normally"
 138 # and would be appropriate for an unknown action.
 139 #
 140 # cwd for push and push-confirm is a temporary repo where the
 141 # to-be-pushed objects have been received; TAGNAME is the
 142 # version-based tag
 143 #
 144 # FRESH-REPO is '' iff the repo for this package already existed, or
 145 # the pathname of the newly-created repo which will be renamed into
 146 # place if everything goes well.  (NB that this is generally not the
 147 # same repo as the cwd, because the objects are first received into a
 148 # temporary repo so they can be examined.)
 149 #
 150 # if push requested FRESHREPO, push-confirm happens in said fresh repo
 151 # and FRESH-REPO is guaranteed not to be ''.
 152 #
 153 # policy hook for a particular package will be invoked only once at
 154 # a time - (see comments about DGIT-REPOS-DIR, above)
 155 #
 156 # check-list and check-package are invoked via the --cron option.
 157 # First, without any locking, check-list is called.  It should produce
 158 # a list of package names (one per line).  Then check-package will be
 159 # invoked for each named package, in each case after taking an
 160 # appropriate lock.
 161 #
 162 # If policy hook wants to run dgit (or something else in the dgit
 163 # package), it should use DGIT-LIVE-DIR/dgit (etc.)
 164
 165
 166 use POSIX;
 167 use Fcntl qw(:flock);
 168 use File::Path qw(rmtree);
 169 use File::Temp qw(tempfile);
 170
 171 use Debian::Dgit qw(:DEFAULT :policyflags);
 172
 173 initdebug('');
 174
 175 our $func;
 176 our $dgitrepos;
 177 our $package;
 178 our $distro;
 179 our $suitesfile;
 180 our $policyhook;
 181 our $dgitlive;
 182 our $destrepo;
 183 our $workrepo;
 184 our $keyrings;
 185 our @lockfhs;
 186
 187 our @deliberatelies;
 188 our %supersedes;
 189 our $policy;
 190
 191 #----- utilities -----
 192
 193 sub realdestrepo () { "$dgitrepos/$package.git"; }
 194
 195 sub acquirelock ($$) {
 196     my ($lock, $must) = @_;
 197     my $fh;
 198     printdebug sprintf "locking %s %d\n", $lock, $must;
 199     for (;;) {
 200         close $fh if $fh;
 201         $fh = new IO::File $lock, ">" or die "open $lock: $!";
 202         my $ok = flock $fh, $must ? LOCK_EX : (LOCK_EX|LOCK_NB);
 203         if (!$ok) {
 204             die "flock $lock: $!" if $must;
 205             printdebug " locking $lock failed\n";
 206             return undef;
 207         }
 208         next unless stat_exists $lock;
 209         my $want = (stat _)[1];
 210         stat $fh or die $!;
 211         my $got = (stat _)[1];
 212         last if $got == $want;
 213     }
 214     return $fh;
 215 }
 216
 217 sub acquirermtree ($$) {
 218     my ($tree, $must) = @_;
 219     my $fh = acquirelock("$tree.lock", $must);
 220     if ($fh) {
 221         push @lockfhs, $fh;
 222         rmtree $tree;
 223     }
 224     return $fh;
 225 }
 226
 227 sub locksometree ($) {
 228     my ($tree) = @_;
 229     acquirelock("$tree.lock", 1);
 230 }
 231
 232 sub lockrealtree () {
 233     locksometree(realdestrepo);
 234 }
 235
 236 sub mkrepotmp () {
 237     my $tmpdir = "$dgitrepos/_tmp";
 238     return if mkdir $tmpdir;
 239     return if $! == EEXIST;
 240     die $!;
 241 }
 242
 243 sub recorderror ($) {
 244     my ($why) = @_;
 245     my $w = $ENV{'DGIT_DRS_WORK'}; # we are in stunthook
 246     if (defined $w) {
 247         chomp $why;
 248         open ERR, ">", "$w/drs-error" or die $!;
 249         print ERR $why, "\n" or die $!;
 250         close ERR or die $!;
 251         return 1;
 252     }
 253     return 0;
 254 }
 255
 256 sub reject ($) {
 257     my ($why) = @_;
 258     recorderror "reject: $why";
 259     die "dgit-repos-server: reject: $why\n";
 260 }
 261
 262 sub runcmd {
 263     debugcmd '+',@_;
 264     $!=0; $?=0;
 265     my $r = system @_;
 266     die "@_ $? $!" if $r;
 267 }
 268
 269 sub policyhook {
 270     my ($policyallowbits, @polargs) = @_;
 271     # => ($exitstatuspolicybitmap);
 272     die if $policyallowbits & ~0x3e;
 273     my @cmd = ($policyhook,$distro,$dgitrepos,$dgitlive,@polargs);
 274     debugcmd '+',@cmd;
 275     my $r = system @cmd;
 276     die "system: $!" if $r < 0;
 277     die "hook (@cmd) failed ($?)" if $r & ~($policyallowbits << 8);
 278     printdebug sprintf "hook (%s) => %#x\n", "@polargs", $r;
 279     return $r >> 8;
 280 }
 281
 282 sub mkemptyrepo ($$) {
 283     my ($dir,$sharedperm) = @_;
 284     runcmd qw(git init --bare --quiet), "--shared=$sharedperm", $dir;
 285 }
 286
 287 sub mkrepo_fromtemplate ($) {
 288     my ($dir) = @_;
 289     my $template = "$dgitrepos/_template";
 290     locksometree($template);
 291     printdebug "copy template $template -> $dir\n";
 292     my $r = system qw(cp -a --), $template, $dir;
 293     !$r or die "create new repo $dir failed: $r $!";
 294 }
 295
 296 sub movetogarbage () {
 297     # realdestrepo must have been locked
 298     my $garbagerepo = "$dgitrepos/${package}_garbage";
 299     # We arrange to always keep at least one old tree, for anti-rewind
 300     # purposes (and, I guess, recovery from mistakes).  This is either
 301     # $garbage or $garbage-old.
 302     if (stat_exists "$garbagerepo") {
 303         rmtree "$garbagerepo-tmp";
 304         if (rename "$garbagerepo-old", "$garbagerepo-tmp") {
 305             rmtree "$garbagerepo-tmp";
 306         } else {
 307             die "$garbagerepo $!" unless $!==ENOENT;
 308         }
 309         rename "$garbagerepo", "$garbagerepo-old" or die "$garbagerepo $!";
 310     }
 311     rename realdestrepo, $garbagerepo
 312         or $! == ENOENT
 313         or die "$garbagerepo $!";
 314 }
 315
 316 sub policy_checkpackage () {
 317     my $lfh = lockrealtree();
 318
 319     $policy = policyhook(FRESHREPO,'check-package',$package);
 320     if ($policy & FRESHREPO) {
 321         movetogarbage();
 322     }
 323
 324     close $lfh;
 325 }
 326
 327 #----- git-receive-pack -----
 328
 329 sub fixmissing__git_receive_pack () {
 330     mkrepotmp();
 331     $destrepo = "$dgitrepos/_tmp/${package}_prospective";
 332     acquirermtree($destrepo, 1);
 333     mkrepo_fromtemplate($destrepo);
 334 }
 335
 336 sub makeworkingclone () {
 337     mkrepotmp();
 338     $workrepo = "$dgitrepos/_tmp/${package}_incoming$$";
 339     acquirermtree($workrepo, 1);
 340     my $lfh = lockrealtree();
 341     runcmd qw(git clone -l -q --mirror), $destrepo, $workrepo;
 342     close $lfh;
 343     rmtree "${workrepo}_fresh";
 344 }
 345
 346 sub setupstunthook () {
 347     my $prerecv = "$workrepo/hooks/pre-receive";
 348     my $fh = new IO::File $prerecv, O_WRONLY|O_CREAT|O_TRUNC, 0777
 349         or die "$prerecv: $!";
 350     print $fh <<END or die "$prerecv: $!";
 351 #!/bin/sh
 352 set -e
 353 exec $0 --pre-receive-hook $package
 354 END
 355     close $fh or die "$prerecv: $!";
 356     $ENV{'DGIT_DRS_WORK'}= $workrepo;
 357     $ENV{'DGIT_DRS_DEST'}= $destrepo;
 358     printdebug " stunt hook set up $prerecv\n";
 359 }
 360
 361 sub dealwithfreshrepo () {
 362     my $freshrepo = "${workrepo}_fresh";
 363     return unless stat_exists $freshrepo;
 364     $destrepo = $freshrepo;
 365 }
 366
 367 sub maybeinstallprospective () {
 368     return if $destrepo eq realdestrepo;
 369
 370     if (open REJ, "<", "$workrepo/drs-error") {
 371         local $/ = undef;
 372         my $msg = <REJ>;
 373         REJ->error and die $!;
 374         print STDERR $msg;
 375         exit 1;
 376     } else {
 377         $!==&ENOENT or die $!;
 378     }
 379
 380     printdebug " show-ref ($destrepo) ...\n";
 381
 382     my $child = open SR, "-|";
 383     defined $child or die $!;
 384     if (!$child) {
 385         chdir $destrepo or die $!;
 386         exec qw(git show-ref);
 387         die $!;
 388     }
 389     my %got = qw(tag 0 head 0);
 390     while (<SR>) {
 391         chomp or die;
 392         printdebug " show-refs| $_\n";
 393         s/^\S*[1-9a-f]\S* (\S+)$/$1/ or die;
 394         my $wh =
 395             m{^refs/tags/} ? 'tag' :
 396             m{^refs/dgit/} ? 'head' :
 397             die;
 398         die if $got{$wh}++;
 399     }
 400     $!=0; $?=0; close SR or $?==256 or die "$? $!";
 401
 402     printdebug "installprospective ?\n";
 403     die Dumper(\%got)." -- missing refs in new repo"
 404         if grep { !$_ } values %got;
 405
 406     lockrealtree();
 407
 408     if ($destrepo eq "${workrepo}_fresh") {
 409         movetogarbage;
 410     }
 411
 412     printdebug "install $destrepo => ".realdestrepo."\n";
 413     rename $destrepo, realdestrepo or die $!;
 414     remove "$destrepo.lock" or die $!;
 415 }
 416
 417 sub main__git_receive_pack () {
 418     makeworkingclone();
 419     setupstunthook();
 420     runcmd qw(git receive-pack), $workrepo;
 421     dealwithfreshrepo();
 422     maybeinstallprospective();
 423 }
 424
 425 #----- stunt post-receive hook -----
 426
 427 our ($tagname, $tagval, $suite, $oldcommit, $commit);
 428 our ($version, %tagh);
 429
 430 sub readupdates () {
 431     printdebug " updates ...\n";
 432     while (<STDIN>) {
 433         chomp or die;
 434         printdebug " upd.| $_\n";
 435         m/^(\S+) (\S+) (\S+)$/ or die "$_ ?";
 436         my ($old, $sha1, $refname) = ($1, $2, $3);
 437         if ($refname =~ m{^refs/tags/(?=debian/)}) {
 438             reject "pushing multiple tags!" if defined $tagname;
 439             $tagname = $'; #';
 440             $tagval = $sha1;
 441             reject "tag $tagname already exists -".
 442                 " not replacing previously-pushed version"
 443                 if $old =~ m/[^0]/;
 444         } elsif ($refname =~ m{^refs/dgit/}) {
 445             reject "pushing multiple heads!" if defined $suite;
 446             $suite = $'; #';
 447             $oldcommit = $old;
 448             $commit = $sha1;
 449         } else {
 450             reject "pushing unexpected ref!";
 451         }
 452     }
 453     STDIN->error and die $!;
 454
 455     reject "push is missing tag ref update" unless defined $tagname;
 456     reject "push is missing head ref update" unless defined $suite;
 457     printdebug " updates ok.\n";
 458 }
 459
 460 sub parsetag () {
 461     printdebug " parsetag...\n";
 462     open PT, ">dgit-tmp/plaintext" or die $!;
 463     open DS, ">dgit-tmp/plaintext.asc" or die $!;
 464     open T, "-|", qw(git cat-file tag), $tagval or die $!;
 465     for (;;) {
 466         $!=0; $_=<T>; defined or die $!;
 467         print PT or die $!;
 468         if (m/^(\S+) (.*)/) {
 469             push @{ $tagh{$1} }, $2;
 470         } elsif (!m/\S/) {
 471             last;
 472         } else {
 473             die;
 474         }
 475     }
 476     $!=0; $_=<T>; defined or die $!;
 477     m/^($package_re) release (\S+) for \S+ \((\S+)\) \[dgit\]$/ or
 478         reject "tag message not in expected format";
 479
 480     die unless $1 eq $package;
 481     $version = $2;
 482     die "$3 != $suite " unless $3 eq $suite;
 483
 484     my $copyl = $_;
 485     for (;;) {
 486         print PT $copyl or die $!;
 487         $!=0; $_=<T>; defined or die "missing signature? $!";
 488         $copyl = $_;
 489         if (m/^\[dgit ([^"].*)\]$/) { # [dgit "something"] is for future
 490             $_ = $1." ";
 491             while (length) {
 492                 if (s/^distro\=(\S+) //) {
 493                     die "$1 != $distro" unless $1 eq $distro;
 494                 } elsif (s/^(--deliberately-$package_re) //) {
 495                     push @deliberatelies, $1;
 496                 } elsif (s/^supersede:(\S+)=(\w+) //) {
 497                     die "supersede $1 twice" if defined $supersedes{$1};
 498                     $supersedes{$1} = $2;
 499                 } elsif (s/^[-+.=0-9a-z]\S* //) {
 500                 } else {
 501                     die "unknown dgit info in tag ($_)";
 502                 }
 503             }
 504             next;
 505         }
 506         last if m/^-----BEGIN PGP/;
 507     }
 508     $_ = $copyl;
 509     for (;;) {
 510         print DS or die $!;
 511         $!=0; $_=<T>;
 512         last if !defined;
 513     }
 514     T->error and die $!;
 515     close PT or die $!;
 516     close DS or die $!;
 517     printdebug " parsetag ok.\n";
 518 }
 519
 520 sub checksig_keyring ($) {
 521     my ($keyringfile) = @_;
 522     # returns primary-keyid if signed by a key in this keyring
 523     # or undef if not
 524     # or dies on other errors
 525
 526     my $ok = undef;
 527
 528     printdebug " checksig keyring $keyringfile...\n";
 529
 530     our @cmd = (qw(gpgv --status-fd=1 --keyring),
 531                    $keyringfile,
 532                    qw(dgit-tmp/plaintext.asc dgit-tmp/plaintext));
 533     debugcmd '|',@cmd;
 534
 535     open P, "-|", @cmd
 536         or die $!;
 537
 538     while (<P>) {
 539         next unless s/^\[GNUPG:\] //;
 540         chomp or die;
 541         printdebug " checksig| $_\n";
 542         my @l = split / /, $_;
 543         if ($l[0] eq 'NO_PUBKEY') {
 544             last;
 545         } elsif ($l[0] eq 'VALIDSIG') {
 546             my $sigtype = $l[9];
 547             $sigtype eq '00' or reject "signature is not of type 00!";
 548             $ok = $l[10];
 549             die unless defined $ok;
 550             last;
 551         }
 552     }
 553     close P;
 554
 555     printdebug sprintf " checksig ok=%d\n", !!$ok;
 556
 557     return $ok;
 558 }
 559
 560 sub dm_txt_check ($$) {
 561     my ($keyid, $dmtxtfn) = @_;
 562     printdebug " dm_txt_check $keyid $dmtxtfn\n";
 563     open DT, '<', $dmtxtfn or die "$dmtxtfn $!";
 564     while (<DT>) {
 565         m/^fingerprint:\s+$keyid$/oi
 566             ..0 or next;
 567         if (s/^allow:/ /i..0) {
 568         } else {
 569             m/^./
 570                 or reject "key $keyid missing Allow section in permissions!";
 571             next;
 572         }
 573         # in right stanza...
 574         s/^[ \t]+//
 575             or reject "package $package not allowed for key $keyid";
 576         # in allow field...
 577         s/\([^()]+\)//;
 578         s/\,//;
 579         chomp or die;
 580         printdebug " dm_txt_check allow| $_\n";
 581         foreach my $p (split /\s+/) {
 582             if ($p eq $package) {
 583                 # yay!
 584                 printdebug " dm_txt_check ok\n";
 585                 return;
 586             }
 587         }
 588     }
 589     DT->error and die $!;
 590     close DT or die $!;
 591     reject "key $keyid not in permissions list although in keyring!";
 592 }
 593
 594 sub verifytag () {
 595     foreach my $kas (split /:/, $keyrings) {
 596         printdebug "verifytag $kas...\n";
 597         $kas =~ s/^([^,]+),// or die;
 598         my $keyid = checksig_keyring $1;
 599         if (defined $keyid) {
 600             if ($kas =~ m/^a$/) {
 601                 printdebug "verifytag a ok\n";
 602                 return; # yay
 603             } elsif ($kas =~ m/^m([^,]+)$/) {
 604                 dm_txt_check($keyid, $1);
 605                 printdebug "verifytag m ok\n";
 606                 return;
 607             } else {
 608                 die;
 609             }
 610         }
 611     }
 612     reject "key not found in keyrings";
 613 }
 614
 615 sub checksuite () {
 616     printdebug "checksuite ($suitesfile)\n";
 617     open SUITES, "<", $suitesfile or die $!;
 618     while (<SUITES>) {
 619         chomp;
 620         next unless m/\S/;
 621         next if m/^\#/;
 622         s/\s+$//;
 623         return if $_ eq $suite;
 624     }
 625     die $! if SUITES->error;
 626     reject "unknown suite";
 627 }
 628
 629 sub checktagnoreplay () {
 630     # We check that the signed tag mentions the name and value of
 631     # (a) in the case of FRESHREPO all tags in the repo;
 632     # (b) in the case of just NOFFCHECK all tags referring to
 633     # the current head for the suite (there must be at least one).
 634     # This prevents a replay attack using an earlier signed tag.
 635     return unless $policy & (FRESHREPO|NOFFCHECK);
 636
 637     my $garbagerepo = "$dgitrepos/${package}_garbage";
 638     lockrealtree();
 639
 640     local $ENV{GIT_DIR};
 641     foreach my $garb ("$garbagerepo", "$garbagerepo-old") {
 642         if (stat_exists $garb) {
 643             $ENV{GIT_DIR} = $garb;
 644             last;
 645         }
 646     }
 647     if (!defined $ENV{GIT_DIR}) {
 648         # Nothing to overwrite so the FRESHREPO and NOFFCHECK were
 649         # pointless.  Oh well.
 650         printdebug "checktagnoreplay - no garbage, ok\n";
 651         return;
 652     }
 653
 654     my $onlyreferring;
 655     if (!($policy & FRESHREPO)) {
 656         my $branch = server_branch($suite);
 657         $!=0; $?=0; $_ =
 658             `git for-each-ref --format='%(objectname)' '[r]efs/$branch'`;
 659         defined or die "$branch $? $!";
 660         $? and die "$branch $?";
 661         if (!length) {
 662             # No such branch - NOFFCHECK was unnecessary.  Oh well.
 663             printdebug "checktagnoreplay - not FRESHREPO, new branch, ok\n";
 664             return;
 665         }
 666         m/^(\w+)\n$/ or die "$branch $_ ?";
 667         $onlyreferring = $1;
 668         printdebug "checktagnoreplay - not FRESHREPO,".
 669             " checking for overwriting refs/$branch=$onlyreferring\n";
 670     }
 671
 672     my @problems;
 673
 674     git_for_each_tag_referring($onlyreferring, sub {
 675         my ($objid,$fullrefname,$tagname) = @_;
 676         printdebug "checktagnoreplay - overwriting $fullrefname=$objid\n";
 677         my $supers = $supersedes{$fullrefname};
 678         if (!defined $supers) {
 679             push @problems, "does not supersede $fullrefname";
 680         } elsif ($supers ne $objid) {
 681             push @problems,
 682  "supersedes $fullrefname=$supers but previously $fullrefname=$objid";
 683         } else {
 684             # ok;
 685         }
 686     });
 687
 688     if (@problems) {
 689         reject "replay attack prevention check failed:".
 690             " signed tag for $version: ".
 691             join("; ", @problems).
 692             "\n";
 693     }
 694     printdebug "checktagnoreply - all ok\n"
 695 }
 696
 697 sub tagh1 ($) {
 698     my ($tag) = @_;
 699     my $vals = $tagh{$tag};
 700     reject "missing header $tag in signed tag object" unless $vals;
 701     reject "multiple headers $tag in signed tag object" unless @$vals == 1;
 702     return $vals->[0];
 703 }
 704
 705 sub checks () {
 706     printdebug "checks\n";
 707
 708     tagh1('type') eq 'commit' or reject "tag refers to wrong kind of object";
 709     tagh1('object') eq $commit or reject "tag refers to wrong commit";
 710     tagh1('tag') eq $tagname or reject "tag name in tag is wrong";
 711
 712     my $v = $version;
 713     $v =~ y/~:/_%/;
 714
 715     printdebug "translated version $v\n";
 716     $tagname eq "debian/$v" or die;
 717
 718     lockrealtree();
 719
 720     my @policy_args = ($package,$version,$suite,$tagname,
 721                        join(",",@deliberatelies));
 722     $policy = policyhook(NOFFCHECK|FRESHREPO, 'push', @policy_args);
 723
 724     checktagnoreplay();
 725     checksuite();
 726
 727     # check that our ref is being fast-forwarded
 728     printdebug "oldcommit $oldcommit\n";
 729     if (!($policy & NOFFCHECK) && $oldcommit =~ m/[^0]/) {
 730         $?=0; $!=0; my $mb = `git merge-base $commit $oldcommit`;
 731         chomp $mb;
 732         $mb eq $oldcommit or reject "not fast forward on dgit branch";
 733     }
 734
 735     if ($policy & FRESHREPO) {
 736         # This is troublesome.  We have been asked by the policy hook
 737         # to receive the push into a fresh repo.  But of course we
 738         # have actually already mostly received the push into the working
 739         # repo.  (This is unavoidable because the instruction to use a new
 740         # repo comes ultimately from the signed tag for the dgit push,
 741         # which has to have been received into some repo.)
 742         #
 743         # So what we do is generate a fresh working repo right now and
 744         # push the head and tag into it.  The presence of this fresh
 745         # working repo is detected by the parent, which responds by
 746         # making a fresh master repo from the template.
 747
 748         $destrepo = "${workrepo}_fresh"; # workrepo lock covers
 749         mkrepo_fromtemplate $destrepo;
 750     }
 751
 752     my $willinstall = ($destrepo eq realdestrepo ? '' : $destrepo);
 753     policyhook(0, 'push-confirm', @policy_args, $willinstall);
 754 }
 755
 756 sub onwardpush () {
 757     my @cmd = (qw(git send-pack), $destrepo);
 758     push @cmd, qw(--force) if $policy & NOFFCHECK;
 759     push @cmd, "$commit:refs/dgit/$suite",
 760                "$tagval:refs/tags/$tagname";
 761     debugcmd '+',@cmd;
 762     $!=0;
 763     my $r = system @cmd;
 764     !$r or die "onward push to $destrepo failed: $r $!";
 765 }
 766
 767 sub stunthook () {
 768     printdebug "stunthook in $workrepo\n";
 769     chdir $workrepo or die "chdir $workrepo: $!";
 770     mkdir "dgit-tmp" or $!==EEXIST or die $!;
 771     readupdates();
 772     parsetag();
 773     verifytag();
 774     checks();
 775     onwardpush();
 776     printdebug "stunthook done.\n";
 777 }
 778
 779 #----- git-upload-pack -----
 780
 781 sub fixmissing__git_upload_pack () {
 782     $destrepo = "$dgitrepos/_empty";
 783     my $lfh = locksometree($destrepo);
 784     return if stat_exists $destrepo;
 785     rmtree "$destrepo.new";
 786     mkemptyrepo "$destrepo.new", "0644";
 787     rename "$destrepo.new", $destrepo or die $!;
 788     unlink "$destrepo.lock" or die $!;
 789     close $lfh;
 790 }
 791
 792 sub main__git_upload_pack () {
 793     my $lfh = locksometree($destrepo);
 794     printdebug "git-upload-pack in $destrepo\n";
 795     chdir $destrepo or die "$destrepo: $!";
 796     close $lfh;
 797     runcmd qw(git upload-pack), ".";
 798 }
 799
 800 #----- arg parsing and main program -----
 801
 802 sub argval () {
 803     die unless @ARGV;
 804     my $v = shift @ARGV;
 805     die if $v =~ m/^-/;
 806     return $v;
 807 }
 808
 809 our %indistrodir = (
 810     # keys are used for DGIT_DRS_XXX too
 811     'repos' => \$dgitrepos,
 812     'suites' => \$suitesfile,
 813     'policy-hook' => \$policyhook,
 814     'dgit-live' => \$dgitlive,
 815     );
 816
 817 our @hookenvs = qw(distro suitesfile policyhook dgitlive keyrings dgitrepos);
 818
 819 # workrepo and destrepo handled ad-hoc
 820
 821 sub mode_ssh () {
 822     die if @ARGV;
 823
 824     my $cmd = $ENV{'SSH_ORIGINAL_COMMAND'};
 825     $cmd =~ m{
 826         ^
 827         (?: \S* / )?
 828         ( [-0-9a-z]+ )
 829         \s+
 830         '? (?: \S* / )?
 831         ($package_re) \.git
 832         '?$
 833     }ox
 834     or reject "command string not understood";
 835     my $method = $1;
 836     $package = $2;
 837
 838     my $funcn = $method;
 839     $funcn =~ y/-/_/;
 840     my $mainfunc = $main::{"main__$funcn"};
 841
 842     reject "unknown method" unless $mainfunc;
 843
 844     policy_checkpackage();
 845
 846     if (stat_exists realdestrepo) {
 847         $destrepo = realdestrepo;
 848     } else {
 849         printdebug " fixmissing $funcn\n";
 850         my $fixfunc = $main::{"fixmissing__$funcn"};
 851         &$fixfunc;
 852     }
 853
 854     printdebug " running main $funcn\n";
 855     &$mainfunc;
 856 }
 857
 858 sub mode_cron () {
 859     die if @ARGV;
 860
 861     my $listfh = tempfile();
 862     open STDOUT, ">&", $listfh or die $!;
 863     policyhook(0,'check-list');
 864     open STDOUT, ">&STDERR" or die $!;
 865
 866     seek $listfh, 0, 0 or die $!;
 867     while (<$listfh>) {
 868         chomp or die;
 869         next if m/^\s*\#/;
 870         next unless m/\S/;
 871         die unless m/^($package_re)$/;
 872
 873         $package = $1;
 874         policy_checkpackage();
 875     }
 876     die $! if $listfh->error;
 877 }
 878
 879 sub parseargsdispatch () {
 880     die unless @ARGV;
 881
 882     delete $ENV{'GIT_DIR'}; # if not run via ssh, our parent git process
 883     delete $ENV{'GIT_PREFIX'}; # sets these and they mess things up
 884
 885     if ($ENV{'DGIT_DRS_DEBUG'}) {
 886         enabledebug();
 887     }
 888
 889     if ($ARGV[0] eq '--pre-receive-hook') {
 890         if ($debuglevel) {
 891             $debugprefix.="=";
 892             printdebug "in stunthook @ARGV\n";
 893             foreach my $k (sort keys %ENV) {
 894                 printdebug "$k=$ENV{$k}\n" if $k =~  m/^DGIT/;
 895             }
 896         }
 897         shift @ARGV;
 898         @ARGV == 1 or die;
 899         $package = shift @ARGV;
 900         ${ $main::{$_} } = $ENV{"DGIT_DRS_\U$_"} foreach @hookenvs;
 901         defined($workrepo = $ENV{'DGIT_DRS_WORK'}) or die;
 902         defined($destrepo = $ENV{'DGIT_DRS_DEST'}) or die;
 903         open STDOUT, ">&STDERR" or die $!;
 904         eval {
 905             stunthook();
 906         };
 907         if ($@) {
 908             recorderror "$@" or die;
 909             die $@;
 910         }
 911         exit 0;
 912     }
 913
 914     $distro = $ENV{'DGIT_DRS_DISTRO'}     = argval();
 915     my $distrodir                         = argval();
 916     $keyrings = $ENV{'DGIT_DRS_KEYRINGS'} = argval();
 917
 918     foreach my $dk (keys %indistrodir) {
 919         ${ $indistrodir{$dk} } = "$distrodir/$dk";
 920     }
 921
 922     while (@ARGV && $ARGV[0] =~ m/^--([-0-9a-z]+)=/ && $indistrodir{$1}) {
 923         ${ $indistrodir{$1} } = $'; #';
 924         shift @ARGV;
 925     }
 926
 927     $ENV{"DGIT_DRS_\U$_"} = ${ $main::{$_} } foreach @hookenvs;
 928
 929     die unless @ARGV==1;
 930
 931     my $mode = shift @ARGV;
 932     die unless $mode =~ m/^--(\w+)$/;
 933     my $fn = ${*::}{"mode_$1"};
 934     die unless $fn;
 935     $fn->();
 936 }
 937
 938 sub unlockall () {
 939     while (my $fh = pop @lockfhs) { close $fh; }
 940 }
 941
 942 sub cleanup () {
 943     unlockall();
 944     if (!chdir "$dgitrepos/_tmp") {
 945         $!==ENOENT or die $!;
 946         return;
 947     }
 948     foreach my $lf (<*.lock>) {
 949         my $tree = $lf;
 950         $tree =~ s/\.lock$//;
 951         next unless acquirermtree($tree, 0);
 952         remove $lf or warn $!;
 953         unlockall();
 954     }
 955 }
 956
 957 parseargsdispatch();
 958 cleanup();