git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_careful, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 $opt_careful = 0;
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR "$us: bad usage: $m\n";
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail "missing required git config $k" unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or die $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or die $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     confess 'dangerous internal error' unless all_snags_summarised();
 177
 178     merge_wreckage_cleaning \@deferred_updates;
 179     run_ref_updates_now $mrest, \@deferred_updates;
 180     print $_, "\n" foreach @deferred_update_messages;
 181
 182     @deferred_updates = ();
 183     @deferred_update_messages = ();
 184 }
 185
 186 sub get_tree ($) {
 187     # tree object name => ([ $name, $info ], ...)
 188     # where $name is the sort key, ie has / at end for subtrees
 189     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 190     # will crash if $x does not exist, so don't do that
 191     my ($x) = @_;
 192     our (@get_tree_memo, %get_tree_memo);
 193     my $memo = $get_tree_memo{$x};
 194     return @$memo if $memo;
 195
 196     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 197     my @l;
 198     my @cmd = (qw(git ls-tree -z --full-tree --), $x);
 199     my $o = cmdoutput @cmd;
 200     $o =~ s/\0$//s;
 201     my $last = '';
 202     foreach my $l (split /\0/, $o) {
 203         my ($i, $n) = split /\t/, $l, 2;
 204         $n .= '/' if $i =~ m/^\d+ tree /;
 205         push @l, [ $n, $i ];
 206         confess "$x need $last < $n ?" unless $last lt $n;
 207     }
 208     $get_tree_memo{$x} = \@l;
 209     push @get_tree_memo, $x;
 210     if (@get_tree_memo > 10) {
 211         delete $get_tree_memo{ shift @get_tree_memo };
 212     }
 213     return @l;
 214 }
 215
 216 sub trees_diff_walk ($$$;$) {
 217     # trees_diff_walk [$all,] $x, $y, sub {... }
 218     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 219     # $x and $y are as for get_tree
 220     # where $name, $ix, $iy are $name and $info from get_tree
 221     my $all = shift @_ if @_>=4;
 222     my ($x,$y,$call) = @_;
 223     return if !$all and $x eq $y;
 224     my @x = get_tree $x;
 225     my @y = get_tree $y;
 226     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 227         if $debuglevel >= 3;
 228     while (@x || @y) {
 229         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 230              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 231         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 232         $ix=$iy='';
 233         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 234             if $debuglevel >= 3;
 235         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 236         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 237         next if !$all and $ix eq $iy;
 238         printdebug sprintf
 239             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 240             !!$all,$x,$y, $n,$ix,$iy
 241             if $debuglevel >= 2;
 242         $call->($n, $ix, $iy);
 243     }
 244 }
 245
 246 sub get_differs ($$) {
 247     my ($x,$y) = @_;
 248     # This resembles quiltify_trees_differ, in dgit, a bit.
 249     # But we don't care about modes, or dpkg-source-unrepresentable
 250     # changes, and we don't need the plethora of different modes.
 251     # Conversely we need to distinguish different kinds of changes to
 252     # debian/ and debian/patches/.
 253
 254     my $differs = 0;
 255
 256     my $rundiff = sub {
 257         my ($opts, $limits, $fn) = @_;
 258         my @cmd = (@git, qw(diff-tree -z --no-renames));
 259         push @cmd, @$opts;
 260         push @cmd, "$_:" foreach $x, $y;
 261         push @cmd, '--', @$limits;
 262         my $diffs = cmdoutput @cmd;
 263         foreach (split /\0/, $diffs) { $fn->(); }
 264     };
 265
 266     $rundiff->([qw(--name-only)], [], sub {
 267         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 268     });
 269
 270     if ($differs & DS_DEB) {
 271         $differs &= ~DS_DEB;
 272         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 273             $differs |=
 274                 m{^debian/patches/}      ? D_PAT_OTH  :
 275                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 276                                            D_DEB_OTH;
 277         });
 278         die "mysterious debian changes $x..$y"
 279             unless $differs & (D_PAT_OTH|DS_DEB);
 280     }
 281
 282     if ($differs & D_PAT_OTH) {
 283         my $mode;
 284         $differs &= ~D_PAT_OTH;
 285         my $pat_oth = sub {
 286             $differs |= D_PAT_OTH;
 287             no warnings qw(exiting);  last;
 288         };
 289         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 290             no warnings qw(exiting);
 291             if (!defined $mode) {
 292                 $mode = $_;  next;
 293             }
 294             die unless s{^debian/patches/}{};
 295             my $ok;
 296             if ($mode eq 'A' && !m/\.series$/s) {
 297                 $ok = 1;
 298             } elsif ($mode eq 'M' && $_ eq 'series') {
 299                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 300                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 301                 chomp $x_s;  $x_s .= "\n";
 302                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 303             } else {
 304                 # nope
 305             }
 306             $mode = undef;
 307             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 308         });
 309         die "mysterious debian/patches changes $x..$y"
 310             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 311     }
 312
 313     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 314
 315     return $differs;
 316 }
 317
 318 sub commit_pr_info ($) {
 319     my ($r) = @_;
 320     return Data::Dumper->dump([$r], [qw(commit)]);
 321 }
 322
 323 sub calculate_committer_authline () {
 324     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 325         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 326     my ($h,$m) = get_commit $c;
 327     $h =~ m/^committer .*$/m or confess "($h) ?";
 328     return $&;
 329 }
 330
 331 sub rm_subdir_cached ($) {
 332     my ($subdir) = @_;
 333     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 334 }
 335
 336 sub read_tree_subdir ($$) {
 337     my ($subdir, $new_tree_object) = @_;
 338     rm_subdir_cached $subdir;
 339     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 340 }
 341
 342 sub read_tree_debian ($) {
 343     my ($treeish) = @_;
 344     read_tree_subdir 'debian', "$treeish:debian";
 345     rm_subdir_cached 'debian/patches';
 346 }
 347
 348 sub read_tree_upstream ($;$$) {
 349     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 350     # if $tree_with_debian is supplied, will use that for debian/
 351     # otherwise will save and restore it.
 352     my $debian =
 353         $tree_with_debian ? "$tree_with_debian:debian"
 354         : cmdoutput @git, qw(write-tree --prefix=debian/);
 355     runcmd @git, qw(read-tree), $treeish;
 356     read_tree_subdir 'debian', $debian;
 357     rm_subdir_cached 'debian/patches' unless $keep_patches;
 358 };
 359
 360 sub make_commit ($$) {
 361     my ($parents, $message_paras) = @_;
 362     my $tree = cmdoutput @git, qw(write-tree);
 363     my @cmd = (@git, qw(commit-tree), $tree);
 364     push @cmd, qw(-p), $_ foreach @$parents;
 365     push @cmd, qw(-m), $_ foreach @$message_paras;
 366     return cmdoutput @cmd;
 367 }
 368
 369 our @snag_force_opts;
 370 sub snag ($$;@) {
 371     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 372     if (grep { $_ eq $tag } @snag_force_opts) {
 373         $snags_forced++;
 374         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 375     } else {
 376         $snags_tripped++;
 377         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 378     }
 379 }
 380
 381 # Important: all mainline code must call snags_maybe_bail after
 382 # any point where snag might be called, but before making changes
 383 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 384 # may be called more than once if necessary (but this is not ideal
 385 # because then the messages about number of snags may be confusing).
 386 sub snags_maybe_bail () {
 387     return if all_snags_summarised();
 388     if ($snags_forced) {
 389         printf STDERR
 390             "%s: snags: %d overriden by individual -f options\n",
 391             $us, $snags_forced;
 392     }
 393     if ($snags_tripped) {
 394         if ($opt_force) {
 395             printf STDERR
 396                 "%s: snags: %d overriden by global --force\n",
 397                 $us, $snags_tripped;
 398         } else {
 399             fail sprintf
 400   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 401                 $us, $snags_tripped;
 402         }
 403     }
 404     $snags_summarised = $snags_forced + $snags_tripped;
 405 }
 406 sub snags_maybe_bail_early () {
 407     # useful to bail out early without doing a lot of work;
 408     # not a substitute for snags_maybe_bail.
 409     snags_maybe_bail() if $snags_tripped && !$opt_force;
 410 }
 411 sub any_snags () {
 412     return $snags_forced || $snags_tripped;
 413 }
 414
 415 sub gbp_pq_export ($$$) {
 416     my ($bname, $base, $tip) = @_;
 417     # must be run in a workarea.  $bname and patch-queue/$bname
 418     # ought not to exist.  Leaves you on patch-queue/$bname with
 419     # the patches staged but not committed.
 420     printdebug "gbp_pq_export $bname $base $tip\n";
 421     runcmd @git, qw(checkout -q -b), $bname, $base;
 422     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 423     my @gbp_cmd = (qw(gbp pq export));
 424     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 425     if ($r) {
 426         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 427         failedcmd @gbp_cmd;
 428     }
 429     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 430 }
 431
 432
 433 # xxx allow merge resolution separately from laundering, before git merge
 434 #
 435 # xxx general gdr docs highlight forbidden things
 436 # xxx general gdr docs list allowable things ?
 437 # xxx general gdr docs explicitly forbid some rebase
 438
 439 # later/rework?
 440 #  use git-format-patch?
 441 #  our own patch identification algorithm?
 442 #  this is an alternative strategy
 443
 444 sub merge_failed ($$;@) {
 445     my ($wrecknotes, $emsg, @xmsgs) = @_;
 446     my @m;
 447     push @m, "Merge resolution failed: $emsg";
 448     push @m, @xmsgs;
 449
 450     changedir $maindir;
 451
 452     my @updates;
 453     merge_wreckage_cleaning \@updates;
 454     run_ref_updates_now "merge failed", \@updates;
 455
 456     @updates = ();
 457     keys %$wrecknotes;
 458     while (my ($k,$v) = each %$wrecknotes) {
 459         push @updates, "create $wrecknoteprefix/$k $v";
 460     }
 461     run_ref_updates_now "merge failed", \@updates;
 462     push @m, "Wreckage left in $wrecknoteprefix/*.";
 463
 464     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 465
 466     # use finish rather than fail, in case we are within an eval
 467     # (that can happen inside walk!)
 468     print STDERR "\n";
 469     print STDERR "$us: $_\n" foreach @m;
 470     finish 15;
 471 }
 472
 473 sub mwrecknote ($$$) {
 474     my ($wrecknotes, $reftail, $commitish) = @_;
 475     confess unless defined $commitish;
 476     printdebug "mwrecknote $reftail $commitish\n";
 477     $wrecknotes->{$reftail} = $commitish;
 478 }
 479
 480 sub merge_attempt_cmd {
 481     my $wrecknotes = shift @_;
 482     debugcmd '+', @_;
 483     $!=0; $?=-1;
 484     if (system @_) {
 485         merge_failed $wrecknotes,
 486             failedcmd_waitstatus(),
 487             "failed command: @_";
 488     }
 489 }
 490
 491 sub merge_series_patchqueue_convert ($$$);
 492
 493 sub merge_series ($$$;@) {
 494     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 495     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 496     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 497     # ^ specifies several patch series (currently we only support exactly 2)
 498     # return value is a commit which is the result of
 499     # merging the two versions of the same topic branch
 500     #   $input_q[0] and $input_q[1]
 501     # with respect to the old version
 502     #   $base_q
 503     # all onto $newbase.
 504
 505     # Creates, in *_q, a key MR for its private use
 506
 507     printdebug "merge_series newbase=$newbase\n";
 508
 509     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 510     $base_q->{MR}{S} = 'base';
 511
 512     my %prereq;
 513     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 514     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 515     # $prereq{<patch filename>}               exists or not (even later)
 516
 517     my $merged_pq;
 518
 519     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 520
 521     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 522
 523     local $workarea;
 524     fresh_workarea "merge";
 525     my $seriesfile = "debian/patches/series";
 526     in_workarea sub {
 527         playtree_setup();
 528         foreach my $q ($base_q, reverse @input_qs) {
 529             my $s = $q->{MR}{S};
 530             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 531             my @earlier;
 532             if (open S, $seriesfile) {
 533                 while (my $patch = <S>) {
 534                     chomp $patch or die $!;
 535                     $prereq{$patch} //= {};
 536                     foreach my $earlier (@earlier) {
 537                         $prereq{$patch}{$earlier}{$s}++ and die;
 538                     }
 539                     push @earlier, $patch;
 540                     stat "debian/patches/$patch" or die "$patch ?";
 541                 }
 542                 S->error and die "$seriesfile $!";
 543                 close S;
 544             } else {
 545                 die "$seriesfile $!" unless $!==ENOENT;
 546             }
 547             read_tree_upstream $newbase, 1;
 548             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 549                 "Convert $s to patch queue for merging",
 550                 "[git-debrebase merge-innards patch-queue import:".
 551                 " $q->{SeriesTip}]"
 552             ];
 553             printdebug "merge_series  pec $pec ";
 554             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 555             $pec = make_commit [ $pec ], [
 556                 "Drop series file from $s to avoid merge trouble",
 557                 "[git-debrebase merge-innards patch-queue prep:".
 558                 " $q->{SeriesTip}]"
 559             ];
 560
 561             read_tree_debian $newbase;
 562             if (@earlier) {
 563                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 564             } else {
 565                 rm_subdir_cached 'debian/patches';
 566             }
 567             $pec = make_commit [ $pec ], [
 568  "Update debian/ (excluding patches) to final to avoid re-merging",
 569  "debian/ was already merged and we need to just take that.",
 570                 "[git-debrebase merge-innards patch-queue packaging:".
 571                 " $q->{SeriesTip}]"
 572             ];
 573
 574             printdebug "pec' $pec\n";
 575             runcmd @git, qw(reset -q --hard), $pec;
 576             $q->{MR}{PEC} = $pec;
 577             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 578         }
 579         # now, because of reverse, we are on $input_q->{MR}{OQC}
 580         runcmd @git, qw(checkout -q -b merge);
 581         printdebug "merge_series merging...\n";
 582         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 583
 584         $attempt_cmd->(@mergecmd);
 585
 586         printdebug "merge_series merge ok, series...\n";
 587         # We need to construct a new series file
 588         # Firstly, resolve prereq
 589         foreach my $f (sort keys %prereq) {
 590             printdebug "merge_series  patch\t$f\t";
 591             if (!stat_exists "debian/patches/$f") {
 592                 print DEBUG " drop\n" if $debuglevel;
 593                 # git merge deleted it; that's how we tell it's not wanted
 594                 delete $prereq{$f};
 595                 next;
 596             }
 597             print DEBUG " keep\n" if $debuglevel;
 598             foreach my $g (sort keys %{ $prereq{$f} }) {
 599                 my $gfp = $prereq{$f}{$g};
 600                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 601                 if (!!$gfp->{0} == !!$gfp->{1}
 602                     ? $gfp->{0}
 603                     : !$gfp->{base}) {
 604                     print DEBUG "\tkeep\n" if $debuglevel;
 605                 } else {
 606                     print DEBUG "\tdrop\n" if $debuglevel;
 607                     delete $prereq{$f}{$g};
 608                 }
 609             }
 610         }
 611
 612         my $unsat = sub {
 613             my ($f) = @_;
 614             return scalar keys %{ $prereq{$f} };
 615         };
 616
 617         my $nodate = time + 1;
 618         my %authordate;
 619         # $authordate{<patch filename>};
 620         my $authordate = sub {
 621             my ($f) = @_;
 622             $authordate{$f} //= do {
 623                 open PF, "<", "debian/patches/$f" or die "$f $!";
 624                 while (<PF>) {
 625                     return $nodate if m/^$/;
 626                     last if s{^Date: }{};
 627                 }
 628                 chomp;
 629                 return cmdoutput qw(date +%s -d), $_;
 630             };
 631         };
 632
 633         open NS, '>', $seriesfile or die $!;
 634
 635         while (keys %prereq) {
 636             my $best;
 637             foreach my $try (sort keys %prereq) {
 638                 if ($best) {
 639                     next if (
 640                              $unsat->($try) <=> $unsat->($best) or
 641                              $authordate->($try) <=> $authordate->($best) or
 642                              $try cmp $best
 643                             ) >= 0;
 644                 }
 645                 $best = $try;
 646             }
 647             printdebug "merge_series series next $best\n";
 648             print NS "$best\n" or die $!;
 649             delete $prereq{$best};
 650             foreach my $gp (values %prereq) {
 651                 delete $gp->{$best};
 652             }
 653         }
 654
 655         runcmd @git, qw(add), $seriesfile;
 656         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 657         $merged_pq = git_rev_parse 'HEAD';
 658         $mwrecknote->('merged-patchqueue', $merged_pq);
 659     };
 660     return merge_series_patchqueue_convert
 661             $wrecknotes, $newbase, $merged_pq;
 662 }
 663
 664 sub merge_series_patchqueue_convert ($$$) {
 665     my ($wrecknotes, $newbase, $merged_pq) = @_;
 666
 667     my $result;
 668     in_workarea sub {
 669         playtree_setup();
 670         printdebug "merge_series series gbp pq import\n";
 671         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 672
 673         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 674
 675         # OK now we are on patch-queue/merge, and we need to rebase
 676         # onto the intended parent and drop the patches from each one
 677
 678         printdebug "merge_series series ok, building...\n";
 679         my $build = $newbase;
 680         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 681         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 682             my $commit = git_cat_file $c, 'commit';
 683             printdebug "merge_series series ok, building $c\n";
 684             read_tree_upstream $c, 0, $newbase;
 685             my $tree = cmdoutput @git, qw(write-tree);
 686             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 687             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 688             open C, ">", "../mcommit" or die $!;
 689             print C $commit or die $!;
 690             close C or die $!;
 691             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 692         }
 693         $result = $build;
 694         mwrecknote($wrecknotes, 'merged-result', $result);
 695
 696         runcmd @git, qw(update-ref refs/heads/result), $result;
 697
 698         runcmd @git, qw(checkout -q -b debug);
 699         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 700         runcmd @git, qw(add .);
 701         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 702         my $mdebug = git_rev_parse 'HEAD';
 703         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 704         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 705     };
 706     printdebug "merge_series returns $result\n";
 707     return $result;
 708 }
 709
 710 # classify returns an info hash like this
 711 #   CommitId => $objid
 712 #   Hdr => # commit headers, including 1 final newline
 713 #   Msg => # commit message (so one newline is dropped)
 714 #   Tree => $treeobjid
 715 #   Type => (see below)
 716 #   Parents = [ {
 717 #       Ix => $index # ie 0, 1, 2, ...
 718 #       CommitId
 719 #       Differs => return value from get_differs
 720 #       IsOrigin
 721 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 722 #     } ...]
 723 #   NewMsg => # commit message, but with any [dgit import ...] edited
 724 #             # to say "[was: ...]"
 725 #
 726 # Types:
 727 #   Packaging
 728 #   Changelog
 729 #   Upstream
 730 #   AddPatches
 731 #   Mixed
 732 #
 733 #   Pseudomerge
 734 #     has additional entres in classification result
 735 #       Overwritten = [ subset of Parents ]
 736 #       Contributor = $the_remaining_Parent
 737 #
 738 #   DgitImportUnpatched
 739 #     has additional entry in classification result
 740 #       OrigParents = [ subset of Parents ]
 741 #
 742 #   Anchor
 743 #     has additional entry in classification result
 744 #       OrigParents = [ subset of Parents ]  # singleton list
 745 #
 746 #   TreatAsAnchor
 747 #
 748 #   BreakwaterStart
 749 #
 750 #   Unknown
 751 #     has additional entry in classification result
 752 #       Why => "prose"
 753
 754 sub parsecommit ($;$) {
 755     my ($objid, $p_ref) = @_;
 756     # => hash with                   CommitId Hdr Msg Tree Parents
 757     #    Parents entries have only   Ix CommitId
 758     #    $p_ref, if provided, must be [] and is used as a base for Parents
 759
 760     $p_ref //= [];
 761     die if @$p_ref;
 762
 763     my ($h,$m) = get_commit $objid;
 764
 765     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 766     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 767
 768     my $r = {
 769         CommitId => $objid,
 770         Hdr => $h,
 771         Msg => $m,
 772         Tree => $t,
 773         Parents => $p_ref,
 774     };
 775
 776     foreach my $ph (@ph) {
 777         push @$p_ref, {
 778             Ix => scalar @$p_ref,
 779             CommitId => $ph,
 780         };
 781     }
 782
 783     return $r;
 784 }
 785
 786 sub classify ($) {
 787     my ($objid) = @_;
 788
 789     my @p;
 790     my $r = parsecommit($objid, \@p);
 791     my $t = $r->{Tree};
 792
 793     foreach my $p (@p) {
 794         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 795     }
 796
 797     printdebug "classify $objid \$t=$t \@p",
 798         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 799         "\n";
 800
 801     my $classify = sub {
 802         my ($type, @rest) = @_;
 803         $r = { %$r, Type => $type, @rest };
 804         if ($debuglevel) {
 805             printdebug " = $type ".(dd $r)."\n";
 806         }
 807         return $r;
 808     };
 809     my $unknown = sub {
 810         my ($why) = @_;
 811         $r = { %$r, Type => qw(Unknown), Why => $why };
 812         printdebug " ** Unknown\n";
 813         return $r;
 814     };
 815
 816     if (grep { $_ eq $objid } @opt_anchors) {
 817         return $classify->('TreatAsAnchor');
 818     }
 819
 820     my @identical = grep { !$_->{Differs} } @p;
 821     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 822     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 823
 824     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 825         # multi-orig upstreams are represented with an anchor merge
 826         # from a single upstream commit which combines the orig tarballs
 827
 828         # Every anchor tagged this way must be a merge.
 829         # We are relying on the
 830         #     [git-debrebase anchor: ...]
 831         # commit message annotation in "declare" anchor merges (which
 832         # do not have any upstream changes), to distinguish those
 833         # anchor merges from ordinary pseudomerges (which we might
 834         # just try to strip).
 835         #
 836         # However, the user is going to be doing git-rebase a lot.  We
 837         # really don't want them to rewrite an anchor commit.
 838         # git-rebase trips up on merges, so that is a useful safety
 839         # catch.
 840         #
 841         # BreakwaterStart commits are also anchors in the terminology
 842         # of git-debrebase(5), but they are untagged (and always
 843         # manually generated).
 844         #
 845         # We cannot not tolerate any tagged linear commit (ie,
 846         # BreakwaterStart commits tagged `[anchor:') because such a
 847         # thing could result from an erroneous linearising raw git
 848         # rebase of a merge anchor.  That would represent a corruption
 849         # of the branch. and we want to detect and reject the results
 850         # of such corruption before it makes it out anywhere.  If we
 851         # reject it here then we avoid making the pseudomerge which
 852         # would be needed to push it.
 853
 854         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 855         @p == 2 or return $badanchor->("has other than two parents");
 856         $haspatches and return $badanchor->("contains debian/patches");
 857
 858         # How to decide about l/r ordering of anchors ?  git
 859         # --topo-order prefers to expand 2nd parent first.  There's
 860         # already an easy rune to look for debian/ history anyway (git log
 861         # debian/) so debian breakwater branch should be 1st parent; that
 862         # way also there's also an easy rune to look for the upstream
 863         # patches (--topo-order).
 864
 865         # Also this makes --first-parent be slightly more likely to
 866         # be useful - it makes it provide a linearised breakwater history.
 867
 868         # Of course one can say somthing like
 869         #  gitk -- ':/' ':!/debian'
 870         # to get _just_ the commits touching upstream files, and by
 871         # the TREESAME logic in git-rev-list this will leave the
 872         # breakwater into upstream at the first anchor.  But that
 873         # doesn't report debian/ changes at all.
 874
 875         # Other observations about gitk: by default, gitk seems to
 876         # produce output in a different order to git-rev-list.  I
 877         # can't seem to find this documented anywhere.  gitk
 878         # --date-order DTRT.  But, gitk always seems to put the
 879         # parents from left to right, in order, so it's easy to see
 880         # which way round a pseudomerge is.
 881
 882         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 883         $p[1]{Differs} & ~DS_DEB and
 884             $badanchor->("upstream files differ from left parent");
 885         $p[0]{Differs} & ~D_UPS and
 886             $badanchor->("debian/ differs from right parent");
 887
 888         return $classify->(qw(Anchor),
 889                            OrigParents => [ $p[1] ]);
 890     }
 891
 892     if (@p == 1) {
 893         my $d = $r->{Parents}[0]{Differs};
 894         if ($d == D_PAT_ADD) {
 895             return $classify->(qw(AddPatches));
 896         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 897             return $unknown->("edits debian/patches");
 898         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 899             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 900             if ($ty eq 'tree') {
 901                 if ($d == D_DEB_CLOG) {
 902                     return $classify->(qw(Changelog));
 903                 } else {
 904                     return $classify->(qw(Packaging));
 905                 }
 906             } elsif ($ty eq 'missing') {
 907                 return $classify->(qw(BreakwaterStart));
 908             } else {
 909                 return $unknown->("parent's debian is not a directory");
 910             }
 911         } elsif ($d == D_UPS) {
 912             return $classify->(qw(Upstream));
 913         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 914             return $classify->(qw(Mixed));
 915         } elsif ($d == 0) {
 916             return $unknown->("no changes");
 917         } else {
 918             confess "internal error $objid ?";
 919         }
 920     }
 921     if (!@p) {
 922         return $unknown->("origin commit");
 923     }
 924
 925     if (@p == 2 && @identical == 1) {
 926         my @overwritten = grep { $_->{Differs} } @p;
 927         confess "internal error $objid ?" unless @overwritten==1;
 928         return $classify->(qw(Pseudomerge),
 929                            Overwritten => [ $overwritten[0] ],
 930                            Contributor => $identical[0]);
 931     }
 932     if (@p == 2 && @identical == 2) {
 933         my $get_t = sub {
 934             my ($ph,$pm) = get_commit $_[0]{CommitId};
 935             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 936             $1;
 937         };
 938         my @bytime = @p;
 939         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 940         if ($order > 0) { # newer first
 941         } elsif ($order < 0) {
 942             @bytime = reverse @bytime;
 943         } else {
 944             # same age, default to order made by -s ours
 945             # that is, commit was made by someone who preferred L
 946         }
 947         return $classify->(qw(Pseudomerge),
 948                            SubType => qw(Ambiguous),
 949                            Contributor => $bytime[0],
 950                            Overwritten => [ $bytime[1] ]);
 951     }
 952     foreach my $p (@p) {
 953         my ($p_h, $p_m) = get_commit $p->{CommitId};
 954         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 955         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 956     }
 957     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 958     my $m2 = $r->{Msg};
 959     if (!(grep { !$_->{IsOrigin} } @p) and
 960         (@orig_ps >= @p - 1) and
 961         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 962         $r->{NewMsg} = $m2;
 963         return $classify->(qw(DgitImportUnpatched),
 964                            OrigParents => \@orig_ps);
 965     }
 966
 967     if (@p == 2 and
 968         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 969         # xxx ^ metadata tag needs adding to (5)
 970         return $classify->("MergedBreakwaters");
 971     }
 972     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 973         return $unknown->("unknown kind of merge from $1");
 974     }
 975     if (@p > 2) {
 976         return $unknown->("octopus merge");
 977     }
 978
 979     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 980         return $unknown->("general two-parent merge");
 981     }
 982
 983     return $classify->("VanillaMerge");
 984 }
 985
 986 sub keycommits ($;$$$$$);
 987
 988 sub mergedbreakwaters_anchor ($) {
 989     my ($cl) = @_;
 990     my $best_anchor;
 991     foreach my $p (@{ $cl->{Parents} }) {
 992         my ($panchor, $pbw) = keycommits $p->{CommitId},
 993             undef,undef,undef,undef, 1;
 994         $best_anchor = $panchor
 995             if !defined $best_anchor
 996             or is_fast_fwd $best_anchor, $panchor;
 997         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 998             unless is_fast_fwd $panchor, $best_anchor;
 999     }
1000     return $best_anchor;
1001 }
1002
1003 sub keycommits ($;$$$$$) {
1004     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1005     # => ($anchor, $breakwater)
1006
1007     # $unclean->("unclean-$tagsfx", $msg, $cl)
1008     # $furniture->("unclean-$tagsfx", $msg, $cl)
1009     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1010     #   is callled for each situation or commit that
1011     #   wouldn't be found in a laundered branch
1012     # $furniture is for furniture commits such as might be found on an
1013     #   interchange branch (pseudomerge, d/patches, changelog)
1014     # $trouble is for things whnich prevent the return of
1015     #   anchor and breakwater information; if that is ignored,
1016     #   then keycommits returns (undef, undef) instead.
1017     # $fatal is for unprocessable commits, and should normally cause
1018     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1019     #
1020     # If $claimed_bw, this is supposed to be a breakwater commit.
1021     #
1022     # If a callback is undef, fail is called instead.
1023     # If a callback is defined but false, the situation is ignored.
1024     # Callbacks may say:
1025     #   no warnings qw(exiting); last;
1026     # if the answer is no longer wanted.
1027
1028     my ($anchor, $breakwater);
1029     $breakwater = $head if $claimed_bw;
1030     my $clogonly;
1031     my $cl;
1032     my $found_pm;
1033     $fatal //= sub { fail $_[1]; };
1034     my $x = sub {
1035         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1036         my $why = $mainwhy.$xwhy;
1037         my $m = "branch needs laundering (run git-debrebase): $why";
1038         fail $m unless defined $cb;
1039         return unless $cb;
1040         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1041     };
1042     my $found_anchor = sub {
1043         ($anchor) = @_;
1044         $breakwater //= $clogonly;
1045         $breakwater //= $head;
1046         no warnings qw(exiting);
1047         last;
1048     };
1049     for (;;) {
1050         $cl = classify $head;
1051         my $ty = $cl->{Type};
1052         if ($ty eq 'Packaging') {
1053             $breakwater //= $clogonly;
1054             $breakwater //= $head;
1055         } elsif ($ty eq 'Changelog') {
1056             # this is going to count as the tip of the breakwater
1057             # only if it has no upstream stuff before it
1058             $clogonly //= $head;
1059         } elsif ($ty eq 'Anchor' or
1060                  $ty eq 'TreatAsAnchor' or
1061                  $ty eq 'BreakwaterStart') {
1062             $found_anchor->($head);
1063         } elsif ($ty eq 'Upstream') {
1064             $x->($unclean, 'ordering',
1065  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1066                 if defined $breakwater;
1067             $clogonly = undef;
1068             $breakwater = undef;
1069         } elsif ($ty eq 'Mixed') {
1070             $x->($unclean, 'mixed',
1071                  "found mixed upstream/packaging commit"," ($head)");
1072             $clogonly = undef;
1073             $breakwater = undef;
1074         } elsif ($ty eq 'Pseudomerge' or
1075                  $ty eq 'AddPatches') {
1076             my $found_pm = 1;
1077             $x->($furniture, (lc $ty),
1078                  "found interchange bureaucracy commit ($ty)"," ($head)");
1079         } elsif ($ty eq 'DgitImportUnpatched') {
1080             if ($found_pm) {
1081                 $x->($trouble, 'dgitimport',
1082                      "found dgit dsc import"," ($head)");
1083                 return (undef,undef);
1084             } else {
1085                 $x->($fatal, 'unprocessable',
1086                      "found bare dgit dsc import with no prior history",
1087                      " ($head)");
1088                 return (undef,undef);
1089             }
1090         } elsif ($ty eq 'VanillaMerge') {
1091             $x->($trouble, 'vanillamerge',
1092                  "found vanilla merge"," ($head)");
1093             return (undef,undef);
1094         } elsif ($ty eq 'MergedBreakwaters') {
1095             $found_anchor->(mergedbreakwaters_anchor $cl);
1096         } else {
1097             $x->($fatal, 'unprocessable',
1098                  "found unprocessable commit, cannot cope: $cl->{Why}",
1099                  " ($head)");
1100             return (undef,undef);
1101         }
1102         $head = $cl->{Parents}[0]{CommitId};
1103     }
1104     return ($anchor, $breakwater);
1105 }
1106
1107 sub walk ($;$$$);
1108 sub walk ($;$$$) {
1109     my ($input,
1110         $nogenerate,$report, $report_lprefix) = @_;
1111     # => ($tip, $breakwater_tip, $last_anchor)
1112     # (or nothing, if $nogenerate)
1113
1114     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1115     $report_lprefix //= '';
1116
1117     # go through commits backwards
1118     # we generate two lists of commits to apply:
1119     # breakwater branch and upstream patches
1120     my (@brw_cl, @upp_cl, @processed);
1121     my %found;
1122     my $upp_limit;
1123     my @pseudomerges;
1124
1125     my $cl;
1126     my $xmsg = sub {
1127         my ($prose, $info) = @_;
1128         my $ms = $cl->{Msg};
1129         chomp $ms;
1130         $info //= '';
1131         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1132         return (Msg => $ms);
1133     };
1134     my $rewrite_from_here = sub {
1135         my ($cl) = @_;
1136         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1137         push @$cl, $sp_cl;
1138         push @processed, $sp_cl;
1139     };
1140     my $cur = $input;
1141
1142     my $prdelim = "";
1143     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1144
1145     my $prline = sub {
1146         return unless $report;
1147         print $report $prdelim, $report_lprefix, @_;
1148         $prdelim = "\n";
1149     };
1150
1151     my $bomb = sub { # usage: return $bomb->();
1152         print $report " Unprocessable" if $report;
1153         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1154         $prprdelim->();
1155         if ($nogenerate) {
1156             return (undef,undef);
1157         }
1158         fail "found unprocessable commit, cannot cope".
1159             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1160             " (commit $cur) (d.".
1161             (join ' ', map { sprintf "%#x", $_->{Differs} }
1162              @{ $cl->{Parents} }).
1163                  ")";
1164     };
1165
1166     my $build;
1167     my $breakwater;
1168
1169     my $build_start = sub {
1170         my ($msg, $parent) = @_;
1171         $prline->(" $msg");
1172         $build = $parent;
1173         no warnings qw(exiting); last;
1174     };
1175
1176     my $nomerge = sub {
1177         my ($emsg) = @_;
1178         merge_failed $cl->{MergeWreckNotes}, $emsg;
1179     };
1180
1181     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1182
1183     my $last_anchor;
1184
1185     for (;;) {
1186         $cl = classify $cur;
1187         $cl->{MergeWreckNotes} //= {};
1188         my $ty = $cl->{Type};
1189         my $st = $cl->{SubType};
1190         $prline->("$cl->{CommitId} $cl->{Type}");
1191         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1192         push @processed, $cl;
1193         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1194         if ($ty eq 'AddPatches') {
1195             $cur = $p0;
1196             $rewrite_from_here->(\@upp_cl);
1197             next;
1198         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1199             push @brw_cl, $cl;
1200             $cur = $p0;
1201             next;
1202         } elsif ($ty eq 'BreakwaterStart') {
1203             $last_anchor = $cur;
1204             $build_start->('FirstPackaging', $cur);
1205         } elsif ($ty eq 'Upstream') {
1206             push @upp_cl, $cl;
1207             $cur = $p0;
1208             next;
1209         } elsif ($ty eq 'Mixed') {
1210             my $queue = sub {
1211                 my ($q, $wh) = @_;
1212                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1213                 push @$q, $cls;
1214             };
1215             $queue->(\@brw_cl, "debian");
1216             $queue->(\@upp_cl, "upstream");
1217             $rewrite_from_here->(\@brw_cl);
1218             $cur = $p0;
1219             next;
1220         } elsif ($ty eq 'Pseudomerge') {
1221             my $contrib = $cl->{Contributor}{CommitId};
1222             print $report " Contributor=$contrib" if $report;
1223             push @pseudomerges, $cl;
1224             $rewrite_from_here->(\@upp_cl);
1225             $cur = $contrib;
1226             next;
1227         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1228             $last_anchor = $cur;
1229             $build_start->("Anchor", $cur);
1230         } elsif ($ty eq 'DgitImportUnpatched') {
1231             my $pm = $pseudomerges[-1];
1232             if (defined $pm) {
1233                 # To an extent, this is heuristic.  Imports don't have
1234                 # a useful history of the debian/ branch.  We assume
1235                 # that the first pseudomerge after an import has a
1236                 # useful history of debian/, and ignore the histories
1237                 # from later pseudomerges.  Often the first pseudomerge
1238                 # will be the dgit import of the upload to the actual
1239                 # suite intended by the non-dgit NMUer, and later
1240                 # pseudomerges may represent in-archive copies.
1241                 my $ovwrs = $pm->{Overwritten};
1242                 printf $report " PM=%s \@Overwr:%d",
1243                     $pm->{CommitId}, (scalar @$ovwrs)
1244                     if $report;
1245                 if (@$ovwrs != 1) {
1246                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1247                     return $bomb->();
1248                 }
1249                 my $ovwr = $ovwrs->[0]{CommitId};
1250                 printf $report " Overwr=%s", $ovwr if $report;
1251                 # This import has a tree which is just like a
1252                 # breakwater tree, but it has the wrong history.  It
1253                 # ought to have the previous breakwater (which the
1254                 # pseudomerge overwrote) as an ancestor.  That will
1255                 # make the history of the debian/ files correct.  As
1256                 # for the upstream version: either it's the same as
1257                 # was ovewritten (ie, same as the previous
1258                 # breakwater), in which case that history is precisely
1259                 # right; or, otherwise, it was a non-gitish upload of a
1260                 # new upstream version.  We can tell these apart by
1261                 # looking at the tree of the supposed upstream.
1262                 push @brw_cl, {
1263                     %$cl,
1264                     SpecialMethod => 'DgitImportDebianUpdate',
1265                     $xmsg->("convert dgit import: debian changes")
1266                 }, {
1267                     %$cl,
1268                     SpecialMethod => 'DgitImportUpstreamUpdate',
1269                     $xmsg->("convert dgit import: upstream update",
1270                             " anchor")
1271                 };
1272                 $prline->(" Import");
1273                 $rewrite_from_here->(\@brw_cl);
1274                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1275                 $cur = $ovwr;
1276                 next;
1277             } else {
1278                 # Everything is from this import.  This kind of import
1279                 # is already nearly in valid breakwater format, with the
1280                 # patches as commits.  Unfortunately it contains
1281                 # debian/patches/.
1282                 printdebug "*** WALK BOMB bare dgit import\n";
1283                 $cl->{Why} = "bare dgit dsc import";
1284                 return $bomb->();
1285             }
1286             die "$ty ?";
1287         } elsif ($ty eq 'MergedBreakwaters') {
1288             $last_anchor = mergedbreakwaters_anchor $cl;
1289             $build_start->(' MergedBreakwaters', $cur);
1290             last;
1291         } elsif ($ty eq 'VanillaMerge') {
1292             # User may have merged unstitched branch(es).  We will
1293             # have now lost what ffq-prev was then (since the later
1294             # pseudomerge may introduce further changes).  The effect
1295             # of resolving such a merge is that we may have to go back
1296             # further in history to find a merge base, since the one
1297             # which was reachable via ffq-prev is no longer findable.
1298             # This is suboptimal, but if it all works we'll have done
1299             # the right thing.
1300             # xxx we should warn the user in the docs about this
1301
1302             my $ok=1;
1303             my $best_anchor;
1304             # We expect to find a dominating anchor amongst the
1305             # inputs' anchors.  That will be the new anchor.
1306             #
1307             # More complicated is finding a merge base for the
1308             # breakwaters.  We need a merge base that is a breakwater
1309             # commit.  The ancestors of breakwater commits are more
1310             # breakwater commits and possibly upstream commits and the
1311             # ancestors of those upstream.  Upstreams might have
1312             # arbitrary ancestors.  But any upstream commit U is
1313             # either included in both anchors, in which case the
1314             # earlier anchor is a better merge base than any of U's
1315             # ancestors; or U is not included in the older anchor, in
1316             # which case U is not an ancestor of the vanilla merge at
1317             # all.  So no upstream commit, nor any ancestor thereof,
1318             # is a best merge base.  As for non-breakwater Debian
1319             # commits: these are never ancestors of any breakwater.
1320             #
1321             # So any best merge base as found by git-merge-base
1322             # is a suitable breakwater anchor.  Usually there will
1323             # be only one.
1324
1325             printdebug "*** MERGE\n";
1326
1327             my @bwbcmd = (@git, qw(merge-base));
1328             my @ibcmd = (@git, qw(merge-base --all));
1329             my $might_be_in_bw = 1;
1330
1331             my $ps = $cl->{Parents};
1332
1333             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1334
1335             foreach my $p (@$ps) {
1336                 $prline->(" VanillaMerge ".$p->{Ix});
1337                 $prprdelim->();
1338                 my ($ptip, $pbw, $panchor) =
1339                     walk $p->{CommitId}, 0, $report,
1340                          $report_lprefix.'  ';
1341                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1342                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1343                 $p->{Anchor} = $panchor;
1344
1345                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1346                 $mwrecknote->("$lr-input", $p->{CommitId});
1347
1348                 my $mwrecknote_parent = sub {
1349                     my ($which) = @_;
1350                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1351                 };
1352                 $mwrecknote_parent->('Laundered');
1353                 $mwrecknote_parent->('Breakwater');
1354                 $mwrecknote_parent->('Anchor');
1355
1356                 $best_anchor = $panchor if
1357                     !defined $best_anchor or
1358                     is_fast_fwd $best_anchor, $panchor;
1359
1360                 printdebug " MERGE BA best=".($best_anchor//'-').
1361                     " p=$panchor\n";
1362             }
1363
1364             $mwrecknote->('result-anchor', $best_anchor);
1365
1366             foreach my $p (@$ps) {
1367                 $prline->(" VanillaMerge ".$p->{Ix});
1368                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1369                     $nomerge->('divergent anchors');
1370                 } elsif ($p->{Anchor} eq $best_anchor) {
1371                     print $report " SameAnchor" if $report;
1372                 } else {
1373                     print $report " SupersededAnchor" if $report;
1374                 }
1375                 if ($p->{Breakwater} eq $p->{CommitId}) {
1376                     # this parent commit was its own breakwater,
1377                     # ie it is part of the breakwater
1378                     print $report " Breakwater" if $report;
1379                 } else {
1380                     $might_be_in_bw = 0;
1381                 }
1382                 push @bwbcmd, $p->{Breakwater};
1383                 push @ibcmd, $p->{CommitId};
1384             }
1385
1386             if ($ok && $might_be_in_bw) {
1387                 # We could rewrite this to contaion the metadata
1388                 # declaring it to be MergedBreakwaters, but
1389                 # unnecessarily rewriting a merge seems unhelpful.
1390                 $prline->(" VanillaMerge MergedBreakwaters");
1391                 $last_anchor = $best_anchor;
1392                 $build_start->('MergedBreakwaters', $cur);
1393             }
1394
1395             my $bwb = cmdoutput @bwbcmd;
1396
1397             # OK, now we have a breakwater base, but we need the merge
1398             # base for the interchange branch because we need the delta
1399             # queue.
1400             #
1401             # This a the best merge base of our inputs which has the
1402             # breakwater merge base as an ancestor.
1403
1404             my @ibs =
1405                 grep /./,
1406                 split /\n/,
1407                 cmdoutput @ibcmd;
1408
1409             @ibs or confess 'internal error, expected anchor at least ?';
1410
1411             my $ib;
1412             my $ibleaf;
1413             foreach my $tibix (0..$#ibs) {
1414                 my $tib = $ibs[$tibix];
1415                 my $ff = is_fast_fwd $bwb, $tib;
1416                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1417                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1418                 $mwrecknote->($tibleaf, $tib);
1419                 next unless $ff;
1420                 next if $ib;
1421                 $ib = $tib;
1422                 $ibleaf = $tibleaf;
1423             }
1424
1425             $ib or $nomerge->("no suitable interchange merge base");
1426
1427             $prline->("  VanillaMerge Base");
1428             $prprdelim->();
1429             my ($btip, $bbw, $banchor) = eval {
1430                 walk $ib, 0, $report, $report_lprefix.'  ';
1431             };
1432             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1433                        $@)
1434                 if length $@;
1435
1436             $mwrecknote->("mergebase-laundered", $btip);
1437             $mwrecknote->("mergebase-breakwater", $bbw);
1438             $mwrecknote->("mergebase-anchor", $banchor);
1439
1440             my $ibinfo = { SeriesTip => $btip,
1441                            SeriesBase => $bbw,
1442                            Anchor => $banchor,
1443                            LeftRight => 'mergebase' };
1444
1445             $bbw eq $bwb
1446                 or $nomerge->("interchange merge-base ($ib)'s".
1447                               " breakwater ($bbw)".
1448                               " != breakwaters' merge-base ($bwb)");
1449
1450             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1451                  or $nomerge->("interchange merge-base ($ib)'s".
1452                                " anchor ($ibinfo->{SeriesBase})".
1453                                " != any merge input's anchor (".
1454                                (join ' ', map { $_->{Anchor} } @$ps).
1455                                ")");
1456
1457             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1458             $cl->{MergeBestAnchor} = $best_anchor;
1459             push @brw_cl, {
1460                 %$cl,
1461                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1462                 $xmsg->('constructed from vanilla merge',
1463                         ' merged-breakwater'),
1464             };
1465             push @upp_cl, {
1466                 %$cl,
1467                 SpecialMethod => 'MergeMergeSeries',
1468             };
1469             $build_start->('MergeBreakwaters', $cur);
1470         } else {
1471             printdebug "*** WALK BOMB unrecognised\n";
1472             return $bomb->();
1473         }
1474     }
1475     $prprdelim->();
1476
1477     printdebug "*** WALK prep done cur=$cur".
1478         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1479
1480     return if $nogenerate;
1481
1482     # Now we build it back up again
1483
1484     fresh_workarea();
1485
1486     my $rewriting = 0;
1487
1488     $#upp_cl = $upp_limit if defined $upp_limit;
1489
1490     my $committer_authline = calculate_committer_authline();
1491
1492     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1493
1494     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1495
1496     in_workarea sub {
1497         mkdir $rd or $!==EEXIST or die $!;
1498         my $current_method;
1499         my $want_debian = $build;
1500         my $want_upstream = $build;
1501
1502         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1503         my $read_tree_debian = sub { ($want_debian) = @_; };
1504
1505         foreach my $cl (qw(Debian), (reverse @brw_cl),
1506                         { SpecialMethod => 'RecordBreakwaterTip' },
1507                         qw(Upstream), (reverse @upp_cl)) {
1508             if (!ref $cl) {
1509                 $current_method = $cl;
1510                 next;
1511             }
1512             my $method = $cl->{SpecialMethod} // $current_method;
1513             my @parents = ($build);
1514             my $cltree = $cl->{CommitId};
1515             printdebug "WALK BUILD ".($cltree//'undef').
1516                 " $method (rewriting=$rewriting)\n";
1517             if ($method eq 'Debian') {
1518                 $read_tree_debian->($cltree);
1519             } elsif ($method eq 'Upstream') {
1520                 $read_tree_upstream->($cltree);
1521             } elsif ($method eq 'StartRewrite') {
1522                 $rewriting = 1;
1523                 next;
1524             } elsif ($method eq 'RecordBreakwaterTip') {
1525                 $breakwater = $build;
1526                 next;
1527             } elsif ($method eq 'DgitImportDebianUpdate') {
1528                 $read_tree_debian->($cltree);
1529             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1530                 confess unless $rewriting;
1531                 my $differs = (get_differs $build, $cltree);
1532                 next unless $differs & D_UPS;
1533                 $read_tree_upstream->($cltree);
1534                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1535             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1536                 print "Found a general merge, will try to tidy it up.\n";
1537                 $rewriting = 1;
1538                 $read_tree_upstream->($cl->{MergeBestAnchor});
1539                 $read_tree_debian->($cltree);
1540                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1541             } elsif ($method eq 'MergeMergeSeries') {
1542                 my $cachehit = reflog_cache_lookup
1543                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1544                 if ($cachehit) {
1545                     print "Using supplied resolution for $cl->{CommitId}...\n";
1546                     $build = $cachehit;
1547                     $mwrecknote->('cached-resolution', $build);
1548                 } else {
1549                     print "Running merge resolution for $cl->{CommitId}...\n";
1550                     $mwrecknote->('new-base', $build);
1551                     $build = merge_series
1552                         $build, $cl->{MergeWreckNotes},
1553                         $cl->{MergeInterchangeBaseInfo},
1554                         @{ $cl->{Parents} };
1555                 }
1556                 $last_anchor = $cl->{MergeBestAnchor};
1557
1558                 # Check for mismerges:
1559                 my $check = sub {
1560                     my ($against, $allow, $what) = @_;
1561                     my $differs = get_differs $build, $against;
1562                     $nomerge->(sprintf
1563        "merge misresolved: %s are not the same (%s %s d.%#x)",
1564                                $what, $against, $build, $differs)
1565                         if $differs & ~($allow | D_PAT_ADD);
1566                 };
1567
1568                 # Breakwater changes which were in each side of the
1569                 # merge will have been incorporated into the
1570                 # MergeCreateMergedBreakwaters output.  Because the
1571                 # upstream series was rebased onto the new breakwater,
1572                 # so should all of the packaging changes which were in
1573                 # the input.
1574                 $check->($input, D_UPS, 'debian files');
1575
1576                 # Upstream files are merge_series, which ought to
1577                 # have been identical to the original merge.
1578                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1579
1580                 print "Merge resolution successful.\n";
1581                 next;
1582             } else {
1583                 confess "$method ?";
1584             }
1585             if (!$rewriting) {
1586                 my $procd = (pop @processed) // 'UNDEF';
1587                 if ($cl ne $procd) {
1588                     $rewriting = 1;
1589                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1590                 }
1591             }
1592             if ($rewriting || $opt_careful) {
1593                 read_tree_upstream $want_upstream, 0, $want_debian;
1594
1595                 my $newtree = cmdoutput @git, qw(write-tree);
1596                 my $ch = $cl->{Hdr};
1597                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1598                 $ch =~ s{^parent .*\n}{}mg;
1599                 $ch =~ s{(?=^author)}{
1600                     join '', map { "parent $_\n" } @parents
1601                 }me or confess "$ch ?";
1602                 if ($rewriting) {
1603                     $ch =~ s{^committer .*$}{$committer_authline}m
1604                         or confess "$ch ?";
1605                 }
1606                 my $cf = "$rd/m$rewriting";
1607                 open CD, ">", $cf or die $!;
1608                 print CD $ch, "\n", $cl->{Msg} or die $!;
1609                 close CD or die $!;
1610                 my @cmd = (@git, qw(hash-object));
1611                 push @cmd, qw(-w) if $rewriting;
1612                 push @cmd, qw(-t commit), $cf;
1613                 my $newcommit = cmdoutput @cmd;
1614                 confess "$ch ?" unless $rewriting
1615                     or $newcommit eq $cl->{CommitId};
1616                 $build = $newcommit;
1617             } else {
1618                 $build = $cl->{CommitId};
1619                 trees_diff_walk "$want_upstream:", "$build:", sub {
1620                     my ($n) = @_;
1621                     no warnings qw(exiting);
1622                     next if $n eq 'debian/';
1623                     confess "mismatch @_ ?";
1624                 };
1625                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1626                     confess "mismatch @_ ?";
1627                 };
1628                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1629                 confess "mismatch @parents != @old_parents ?"
1630                     unless "@parents" eq "@old_parents";
1631             }
1632             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1633                 $last_anchor = $cur;
1634             }
1635         }
1636     };
1637
1638     my $final_check = get_differs $build, $input;
1639     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1640         if $final_check & ~D_PAT_ADD;
1641
1642     my @r = ($build, $breakwater, $last_anchor);
1643     printdebug "*** WALK RETURN @r\n";
1644     return @r
1645 }
1646
1647 sub get_head () {
1648     git_check_unmodified();
1649     return git_rev_parse qw(HEAD);
1650 }
1651
1652 sub update_head ($$$) {
1653     my ($old, $new, $mrest) = @_;
1654     push @deferred_updates, "update HEAD $new $old";
1655     run_deferred_updates $mrest;
1656 }
1657
1658 sub update_head_checkout ($$$) {
1659     my ($old, $new, $mrest) = @_;
1660     update_head $old, $new, $mrest;
1661     runcmd @git, qw(reset --hard);
1662 }
1663
1664 sub update_head_postlaunder ($$$) {
1665     my ($old, $tip, $reflogmsg) = @_;
1666     return if $tip eq $old;
1667     print "git-debrebase: laundered (head was $old)\n";
1668     update_head $old, $tip, $reflogmsg;
1669     # no tree changes except debian/patches
1670     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1671 }
1672
1673 sub currently_rebasing() {
1674     foreach (qw(rebase-merge rebase-apply)) {
1675         return 1 if stat_exists "$maindir_gitdir/$_";
1676     }
1677     return 0;
1678 }
1679
1680 sub bail_if_rebasing() {
1681     fail "you are in the middle of a git-rebase already"
1682         if currently_rebasing();
1683 }
1684
1685 sub do_launder_head ($) {
1686     my ($reflogmsg) = @_;
1687     my $old = get_head();
1688     record_ffq_auto();
1689     my ($tip,$breakwater) = walk $old;
1690     snags_maybe_bail();
1691     update_head_postlaunder $old, $tip, $reflogmsg;
1692     return ($tip,$breakwater);
1693 }
1694
1695 sub cmd_launder_v0 () {
1696     badusage "no arguments to launder-v0 allowed" if @ARGV;
1697     my $old = get_head();
1698     my ($tip,$breakwater,$last_anchor) = walk $old;
1699     update_head_postlaunder $old, $tip, 'launder';
1700     printf "# breakwater tip\n%s\n", $breakwater;
1701     printf "# working tip\n%s\n", $tip;
1702     printf "# last anchor\n%s\n", $last_anchor;
1703 }
1704
1705 sub defaultcmd_rebase () {
1706     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1707     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1708     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1709 }
1710
1711 sub cmd_analyse () {
1712     badusage "analyse does not support any options"
1713         if @ARGV and $ARGV[0] =~ m/^-/;
1714     badusage "too many arguments to analyse" if @ARGV>1;
1715     my ($old) = @ARGV;
1716     if (defined $old) {
1717         $old = git_rev_parse $old;
1718     } else {
1719         $old = git_rev_parse 'HEAD';
1720     }
1721     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1722     STDOUT->error and die $!;
1723 }
1724
1725 sub ffq_prev_branchinfo () {
1726     my $current = git_get_symref();
1727     return gdr_ffq_prev_branchinfo($current);
1728 }
1729
1730 sub ffq_check ($;$$) {
1731     # calls $ff and/or $notff zero or more times
1732     # then returns either (status,message) where status is
1733     #    exists
1734     #    detached
1735     #    weird-symref
1736     #    notbranch
1737     # or (undef,undef, $ffq_prev,$gdrlast)
1738     # $ff and $notff are called like this:
1739     #   $ff->("message for stdout\n");
1740     #   $notff->('snag-name', $message);
1741     # normally $currentval should be HEAD
1742     my ($currentval, $ff, $notff) =@_;
1743
1744     $ff //= sub { print $_[0] or die $!; };
1745     $notff //= \&snag;
1746
1747     my ($status, $message, $current, $ffq_prev, $gdrlast)
1748         = ffq_prev_branchinfo();
1749     return ($status, $message) unless $status eq 'branch';
1750
1751     my $exists = git_get_ref $ffq_prev;
1752     return ('exists',"$ffq_prev already exists") if $exists;
1753
1754     return ('not-branch', 'HEAD symref is not to refs/heads/')
1755         unless $current =~ m{^refs/heads/};
1756     my $branch = $';
1757
1758     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1759     my %checked;
1760
1761     printdebug "ffq check_specs @check_specs\n";
1762
1763     my $check = sub {
1764         my ($lrref, $desc) = @_;
1765         printdebug "ffq might check $lrref ($desc)\n";
1766         my $invert;
1767         for my $chk (@check_specs) {
1768             my $glob = $chk;
1769             $invert = $glob =~ s{^[!^]}{};
1770             last if fnmatch $glob, $lrref;
1771         }
1772         return if $invert;
1773         my $lrval = git_get_ref $lrref;
1774         return unless length $lrval;
1775
1776         if (is_fast_fwd $lrval, $currentval) {
1777             $ff->("OK, you are ahead of $lrref\n");
1778             $checked{$lrref} = 1;
1779         } elsif (is_fast_fwd $currentval, $lrval) {
1780             $checked{$lrref} = -1;
1781             $notff->('behind', "you are behind $lrref, divergence risk");
1782         } else {
1783             $checked{$lrref} = -1;
1784             $notff->('diverged', "you have diverged from $lrref");
1785         }
1786     };
1787
1788     my $merge = cfg "branch.$branch.merge",1;
1789     if (defined $merge and $merge =~ m{^refs/heads/}) {
1790         my $rhs = $';
1791         printdebug "ffq merge $rhs\n";
1792         my $check_remote = sub {
1793             my ($remote, $desc) = @_;
1794             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1795             return unless defined $remote;
1796             $check->("refs/remotes/$remote/$rhs", $desc);
1797         };
1798         $check_remote->((scalar cfg "branch.$branch.remote",1),
1799                         'remote fetch/merge branch');
1800         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1801                         (scalar cfg "branch.$branch.pushDefault",1),
1802                         'remote push branch');
1803     }
1804     if ($branch =~ m{^dgit/}) {
1805         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1806     } elsif ($branch =~ m{^master$}) {
1807         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1808     }
1809     return (undef, undef, $ffq_prev, $gdrlast);
1810 }
1811
1812 sub record_ffq_prev_deferred () {
1813     # => ('status', "message")
1814     # 'status' may be
1815     #    deferred          message is undef
1816     #    exists
1817     #    detached
1818     #    weird-symref
1819     #    notbranch
1820     # if not ff from some branch we should be ff from, is an snag
1821     # if "deferred", will have added something about that to
1822     #   @deferred_update_messages, and also maybe printed (already)
1823     #   some messages about ff checks
1824     bail_if_rebasing();
1825     my $currentval = get_head();
1826
1827     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1828     return ($status,$message) if defined $status;
1829
1830     snags_maybe_bail();
1831
1832     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1833     push @deferred_updates, "delete $gdrlast";
1834     push @deferred_update_messages, "Recorded previous head for preservation";
1835     return ('deferred', undef);
1836 }
1837
1838 sub record_ffq_auto () {
1839     my ($status, $message) = record_ffq_prev_deferred();
1840     if ($status eq 'deferred' || $status eq 'exists') {
1841     } else {
1842         snag $status, "could not record ffq-prev: $message";
1843         snags_maybe_bail();
1844     }
1845 }
1846
1847 sub ffq_prev_info () {
1848     bail_if_rebasing();
1849     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1850     my ($status, $message, $current, $ffq_prev, $gdrlast)
1851         = ffq_prev_branchinfo();
1852     if ($status ne 'branch') {
1853         snag $status, "could not check ffq-prev: $message";
1854         snags_maybe_bail();
1855     }
1856     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1857     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1858 }
1859
1860 sub stitch ($$$$$) {
1861     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1862
1863     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1864
1865     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1866         my $differs = get_differs $old_head, $ffq_prev_commitish;
1867         unless ($differs & ~D_PAT_ADD) {
1868             # ffq-prev is ahead of us, and the only tree changes it has
1869             # are possibly addition of things in debian/patches/.
1870             # Just wind forwards rather than making a pointless pseudomerge.
1871             push @deferred_updates,
1872                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1873             update_head_checkout $old_head, $ffq_prev_commitish,
1874                 "stitch (fast forward)";
1875             return;
1876         }
1877     }
1878     fresh_workarea();
1879     # We make pseudomerges with L as the contributing parent.
1880     # This makes git rev-list --first-parent work properly.
1881     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1882         'Declare fast forward / record previous work',
1883         "[git-debrebase pseudomerge: $prose]",
1884     ];
1885     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1886     update_head $old_head, $new_head, "stitch: $prose";
1887 }
1888
1889 sub do_stitch ($;$) {
1890     my ($prose, $unclean) = @_;
1891
1892     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1893     if (!$ffq_prev_commitish) {
1894         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1895         return;
1896     }
1897     my $dangling_head = get_head();
1898
1899     keycommits $dangling_head, $unclean,$unclean,$unclean;
1900     snags_maybe_bail();
1901
1902     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1903 }
1904
1905 sub upstream_commitish_search ($$) {
1906     my ($upstream_version, $tried) = @_;
1907     # todo: at some point maybe use git-deborig to do this
1908     foreach my $tagpfx ('', 'v', 'upstream/') {
1909         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1910         my $new_upstream = git_get_ref "refs/tags/$tag";
1911         push @$tried, $tag;
1912         return $new_upstream if length $new_upstream;
1913     }
1914 }
1915
1916 sub resolve_upstream_version ($$) {
1917     my ($new_upstream, $upstream_version) = @_;
1918
1919     if (!defined $new_upstream) {
1920         my @tried;
1921         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1922         if (!length $new_upstream) {
1923             fail "Could not determine appropriate upstream commitish.\n".
1924                 " (Tried these tags: @tried)\n".
1925                 " Check version, and specify upstream commitish explicitly.";
1926         }
1927     }
1928     $new_upstream = git_rev_parse $new_upstream;
1929
1930     return $new_upstream;
1931 }
1932
1933 sub cmd_new_upstream () {
1934     # automatically and unconditionally launders before rebasing
1935     # if rebase --abort is used, laundering has still been done
1936
1937     my %pieces;
1938
1939     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1940
1941     # parse args - low commitment
1942     my $spec_version = shift @ARGV;
1943     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1944     fail "bad version number \`$spec_version'" unless defined $new_version;
1945     if ($new_version->is_native()) {
1946         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1947     }
1948
1949     my $new_upstream = shift @ARGV;
1950     my $new_upstream_version = upstreamversion  $new_version;
1951     $new_upstream =
1952         resolve_upstream_version $new_upstream, $new_upstream_version;
1953
1954     record_ffq_auto();
1955
1956     my $piece = sub {
1957         my ($n, @x) = @_; # may be ''
1958         my $pc = $pieces{$n} //= {
1959             Name => $n,
1960             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1961         };
1962         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1963         $pc;
1964     };
1965
1966     my @newpieces;
1967     my $newpiece = sub {
1968         my ($n, @x) = @_; # may be ''
1969         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1970         push @newpieces, $pc;
1971     };
1972
1973     $newpiece->('',
1974         OldIx => 0,
1975         New => $new_upstream,
1976     );
1977     while (@ARGV && $ARGV[0] !~ m{^-}) {
1978         my $n = shift @ARGV;
1979
1980         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1981             unless @ARGV && $ARGV[0] !~ m{^-};
1982
1983         my $c = git_rev_parse shift @ARGV;
1984         die unless $n =~ m/^$extra_orig_namepart_re$/;
1985         $newpiece->($n, New => $c);
1986     }
1987
1988     # now we need to investigate the branch this generates the
1989     # laundered version but we don't switch to it yet
1990     my $old_head = get_head();
1991     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1992
1993     my $old_bw_cl = classify $old_bw;
1994     my $old_anchor_cl = classify $old_anchor;
1995     my $old_upstream;
1996     if (!$old_anchor_cl->{OrigParents}) {
1997         snag 'anchor-treated',
1998             'old anchor is recognised due to --anchor, cannot check upstream';
1999     } else {
2000         $old_upstream = parsecommit
2001             $old_anchor_cl->{OrigParents}[0]{CommitId};
2002         $piece->('', Old => $old_upstream->{CommitId});
2003     }
2004
2005     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2006         if ($old_upstream->{Msg} =~
2007  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2008            ) {
2009             my @oldpieces = (split / /, $1);
2010             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2011             if ($old_n_parents != @oldpieces &&
2012                 $old_n_parents != @oldpieces + 1) {
2013                 snag 'upstream-confusing', sprintf
2014                     "previous upstream combine %s".
2015                     " mentions %d pieces (each implying one parent)".
2016                     " but has %d parents".
2017                     " (one per piece plus maybe a previous combine)",
2018                     $old_upstream->{CommitId},
2019                     (scalar @oldpieces),
2020                     $old_n_parents;
2021             } elsif ($oldpieces[0] ne '.') {
2022                 snag 'upstream-confusing', sprintf
2023                     "previous upstream combine %s".
2024                     " first piece is not \`.'",
2025                     $oldpieces[0];
2026             } else {
2027                 $oldpieces[0] = '';
2028                 foreach my $i (0..$#oldpieces) {
2029                     my $n = $oldpieces[$i];
2030                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2031                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2032                 }
2033             }
2034         } else {
2035             snag 'upstream-confusing',
2036                 "previous upstream $old_upstream->{CommitId} is from".
2037                " git-debrebase but not an \`upstream-combine' commit";
2038         }
2039     }
2040
2041     foreach my $pc (values %pieces) {
2042         if (!$old_upstream) {
2043             # we have complained already
2044         } elsif (!$pc->{Old}) {
2045             snag 'upstream-new-piece',
2046                 "introducing upstream piece \`$pc->{Name}'";
2047         } elsif (!$pc->{New}) {
2048             snag 'upstream-rm-piece',
2049                 "dropping upstream piece \`$pc->{Name}'";
2050         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2051             snag 'upstream-not-ff',
2052                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2053         }
2054     }
2055
2056     printdebug "%pieces = ", (dd \%pieces), "\n";
2057     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2058
2059     snags_maybe_bail();
2060
2061     my $new_bw;
2062
2063     fresh_workarea();
2064     in_workarea sub {
2065         my @upstream_merge_parents;
2066
2067         if (!any_snags()) {
2068             push @upstream_merge_parents, $old_upstream->{CommitId};
2069         }
2070
2071         foreach my $pc (@newpieces) { # always has '' first
2072             if ($pc->{Name}) {
2073                 read_tree_subdir $pc->{Name}, $pc->{New};
2074             } else {
2075                 runcmd @git, qw(read-tree), $pc->{New};
2076             }
2077             push @upstream_merge_parents, $pc->{New};
2078         }
2079
2080         # index now contains the new upstream
2081
2082         if (@newpieces > 1) {
2083             # need to make the upstream subtree merge commit
2084             $new_upstream = make_commit \@upstream_merge_parents,
2085                 [ "Combine upstreams for $new_upstream_version",
2086  ("[git-debrebase upstream-combine . ".
2087  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2088  ": new upstream]"),
2089                 ];
2090         }
2091
2092         # $new_upstream is either the single upstream commit, or the
2093         # combined commit we just made.  Either way it will be the
2094         # "upstream" parent of the anchor merge.
2095
2096         read_tree_subdir 'debian', "$old_bw:debian";
2097
2098         # index now contains the anchor merge contents
2099         $new_bw = make_commit [ $old_bw, $new_upstream ],
2100             [ "Update to upstream $new_upstream_version",
2101  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2102             ];
2103
2104         my $clogsignoff = cmdoutput qw(git show),
2105             '--pretty=format:%an <%ae>  %aD',
2106             $new_bw;
2107
2108         # Now we have to add a changelog stanza so the Debian version
2109         # is right.
2110         die if unlink "debian";
2111         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2112         unlink "debian/changelog" or $!==ENOENT or die $!;
2113         mkdir "debian" or die $!;
2114         open CN, ">", "debian/changelog" or die $!;
2115         my $oldclog = git_cat_file ":debian/changelog";
2116         $oldclog =~ m/^($package_re) \(\S+\) / or
2117             fail "cannot parse old changelog to get package name";
2118         my $p = $1;
2119         print CN <<END, $oldclog or die $!;
2120 $p ($new_version) UNRELEASED; urgency=medium
2121
2122   * Update to new upstream version $new_upstream_version.
2123
2124  -- $clogsignoff
2125
2126 END
2127         close CN or die $!;
2128         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2129
2130         # Now we have the final new breakwater branch in the index
2131         $new_bw = make_commit [ $new_bw ],
2132             [ "Update changelog for new upstream $new_upstream_version",
2133               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2134             ];
2135     };
2136
2137     # we have constructed the new breakwater. we now need to commit to
2138     # the laundering output, because git-rebase can't easily be made
2139     # to make a replay list which is based on some other branch
2140
2141     update_head_postlaunder $old_head, $old_laundered_tip,
2142         'launder for new upstream';
2143
2144     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2145     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2146         "debrebase new-upstream $new_version: rebase";
2147     runcmd @cmd;
2148     # now it's for the user to sort out
2149 }
2150
2151 sub cmd_record_ffq_prev () {
2152     badusage "no arguments allowed" if @ARGV;
2153     my ($status, $msg) = record_ffq_prev_deferred();
2154     if ($status eq 'exists' && $opt_noop_ok) {
2155         print "Previous head already recorded\n" or die $!;
2156     } elsif ($status eq 'deferred') {
2157         run_deferred_updates 'record-ffq-prev';
2158     } else {
2159         fail "Could not preserve: $msg";
2160     }
2161 }
2162
2163 sub cmd_anchor () {
2164     badusage "no arguments allowed" if @ARGV;
2165     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2166     print "$bw\n" or die $!;
2167 }
2168
2169 sub cmd_breakwater () {
2170     badusage "no arguments allowed" if @ARGV;
2171     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2172     print "$bw\n" or die $!;
2173 }
2174
2175 sub cmd_status () {
2176     badusage "no arguments allowed" if @ARGV;
2177
2178     # todo: gdr status should print divergence info
2179     # todo: gdr status should print upstream component(s) info
2180     # todo: gdr should leave/maintain some refs with this kind of info ?
2181
2182     my $oldest = { Badness => 0 };
2183     my $newest;
2184     my $note = sub {
2185         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2186         if ($oldest->{Badness} < $badness) {
2187             $oldest = $newest = undef;
2188         }
2189         $oldest = {
2190                    Badness => $badness,
2191                    CommitId => $cl->{CommitId},
2192                    OurMsg => $ourmsg,
2193                    KcMsg => $kcmsg,
2194                   };
2195         $newest //= $oldest;
2196     };
2197     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2198         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2199         sub { $note->(2, 'branch is unlaundered', @_); },
2200         sub { $note->(3, 'branch needs laundering', @_); },
2201         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2202
2203     my $prcommitinfo = sub {
2204         my ($cid) = @_;
2205         flush STDOUT or die $!;
2206         runcmd @git, qw(--no-pager log -n1),
2207             '--pretty=format:    %h %s%n',
2208             $cid;
2209     };
2210
2211     print "current branch contents, in git-debrebase terms:\n";
2212     if (!$oldest->{Badness}) {
2213         print "  branch is laundered\n";
2214     } else {
2215         print "  $oldest->{OurMsg}\n";
2216         my $printed = '';
2217         foreach my $info ($oldest, $newest) {
2218             my $cid = $info->{CommitId};
2219             next if $cid eq $printed;
2220             $printed = $cid;
2221             print "  $info->{KcMsg}\n";
2222             $prcommitinfo->($cid);
2223         }
2224     }
2225
2226     my $prab = sub {
2227         my ($cid, $what) = @_;
2228         if (!defined $cid) {
2229             print "  $what is not well-defined\n";
2230         } else {
2231             print "  $what\n";
2232             $prcommitinfo->($cid);
2233         }
2234     };
2235     print "key git-debrebase commits:\n";
2236     $prab->($anchor, 'anchor');
2237     $prab->($bw, 'breakwater');
2238
2239     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2240         ffq_prev_branchinfo();
2241
2242     print "branch and ref status, in git-debrebase terms:\n";
2243     if ($ffq_msg) {
2244         print "  $ffq_msg\n";
2245     } else {
2246         $ffq_prev = git_get_ref $ffq_prev;
2247         $gdrlast = git_get_ref $gdrlast;
2248         if ($ffq_prev) {
2249             print "  unstitched; previous tip was:\n";
2250             $prcommitinfo->($ffq_prev);
2251         } elsif (!$gdrlast) {
2252             print "  stitched? (no record of git-debrebase work)\n";
2253         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2254             print "  stitched\n";
2255         } else {
2256             print "  not git-debrebase (diverged since last stitch)\n"
2257         }
2258     }
2259     print "you are currently rebasing\n" if currently_rebasing();
2260 }
2261
2262 sub cmd_stitch () {
2263     my $prose = 'stitch';
2264     getoptions("stitch",
2265                'prose=s', \$prose);
2266     badusage "no arguments allowed" if @ARGV;
2267     do_stitch $prose, 0;
2268 }
2269 sub cmd_prepush () { cmd_stitch(); }
2270
2271 sub cmd_quick () {
2272     badusage "no arguments allowed" if @ARGV;
2273     do_launder_head 'launder for git-debrebase quick';
2274     do_stitch 'quick';
2275 }
2276
2277 sub cmd_conclude () {
2278     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2279     if (!$ffq_prev_commitish) {
2280         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2281         return;
2282     }
2283     my $dangling_head = get_head();
2284
2285     badusage "no arguments allowed" if @ARGV;
2286     do_launder_head 'launder for git-debrebase quick';
2287     do_stitch 'quick';
2288 }
2289
2290 sub cmd_scrap () {
2291     if (currently_rebasing()) {
2292         runcmd @git, qw(rebase --abort);
2293         push @deferred_updates, 'verify HEAD HEAD';
2294         # noop, but stops us complaining that scrap was a noop
2295     }
2296     badusage "no arguments allowed" if @ARGV;
2297     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2298     my $scrapping_head;
2299     if ($ffq_prev_commitish) {
2300         $scrapping_head = get_head();
2301         push @deferred_updates,
2302             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2303             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2304     }
2305     if (git_get_ref $merge_cache_ref) {
2306         push @deferred_updates,
2307             "delete $merge_cache_ref";
2308     }
2309     if (!@deferred_updates) {
2310         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2311         finish 0;
2312     }
2313     snags_maybe_bail();
2314     if ($scrapping_head) {
2315         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2316     } else {
2317         run_deferred_updates "scrap";
2318     }
2319 }
2320
2321 sub make_patches_staged ($) {
2322     my ($head) = @_;
2323     # Produces the patches that would result from $head if it were
2324     # laundered.
2325     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2326     fresh_workarea();
2327     in_workarea sub {
2328         gbp_pq_export 'bw', $secret_bw, $secret_head;
2329     };
2330 }
2331
2332 sub make_patches ($) {
2333     my ($head) = @_;
2334     keycommits $head, 0, \&snag;
2335     make_patches_staged $head;
2336     my $out;
2337     in_workarea sub {
2338         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2339         runcmd @git, qw(read-tree), $head;
2340         read_tree_subdir 'debian/patches', $ptree;
2341         $out = make_commit [$head], [
2342             'Commit patch queue (exported by git-debrebase)',
2343             '[git-debrebase: export and commit patches]',
2344         ];
2345     };
2346     return $out;
2347 }
2348
2349 sub cmd_make_patches () {
2350     my $opt_quiet_would_amend;
2351     getoptions("make-patches",
2352                'quiet-would-amend!', \$opt_quiet_would_amend);
2353     badusage "no arguments allowed" if @ARGV;
2354     bail_if_rebasing();
2355     my $old_head = get_head();
2356     my $new = make_patches $old_head;
2357     my $d = get_differs $old_head, $new;
2358     if ($d == 0) {
2359         fail "No (more) patches to export." unless $opt_noop_ok;
2360         return;
2361     } elsif ($d == D_PAT_ADD) {
2362         snags_maybe_bail();
2363         update_head_checkout $old_head, $new, 'make-patches';
2364     } else {
2365         print STDERR failmsg
2366             "Patch export produced patch amendments".
2367             " (abandoned output commit $new).".
2368             "  Try laundering first."
2369             unless $opt_quiet_would_amend;
2370         finish 7;
2371     }
2372 }
2373
2374 sub cmd_convert_from_gbp () {
2375     badusage "want only 1 optional argument, the upstream git commitish"
2376         unless @ARGV<=1;
2377
2378     my $clogp = parsechangelog();
2379     my $version = $clogp->{'Version'}
2380         // die "missing Version from changelog";
2381
2382     my ($upstream_spec) = @ARGV;
2383
2384     my $upstream_version = upstreamversion $version;
2385     my $upstream =
2386         resolve_upstream_version($upstream_spec, $upstream_version);
2387
2388     my $old_head = get_head();
2389
2390     my $upsdiff = get_differs $upstream, $old_head;
2391     if ($upsdiff & D_UPS) {
2392         runcmd @git, qw(--no-pager diff --stat),
2393             $upstream, $old_head,
2394             qw( -- :!/debian :/);
2395         fail <<END;
2396 upstream ($upstream_spec) and HEAD are not
2397 identical in upstream files.  See diffstat above, or run
2398   git diff $upstream_spec HEAD -- :!/debian :/
2399 END
2400     }
2401
2402     if (!is_fast_fwd $upstream, $old_head) {
2403         snag 'upstream-not-ancestor',
2404             "upstream ($upstream) is not an ancestor of HEAD";
2405     } else {
2406         my $wrong = cmdoutput
2407             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2408              qw(-- :/ :!/debian));
2409         if (length $wrong) {
2410             snag 'unexpected-upstream-changes',
2411                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2412             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2413         }
2414     }
2415
2416     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2417         snag 'upstream-has-debian',
2418             "upstream ($upstream) contains debian/ directory";
2419     }
2420
2421     my $previous_dgit_view = eval {
2422         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2423         my ($lvsn, $suite);
2424         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2425             my ($stz, $desc) = @_;
2426             no warnings qw(exiting);
2427             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2428             next unless $stz->{Date};
2429             next unless $stz->{Distribution} ne 'UNRELEASED';
2430             $lvsn = $stz->{Version};
2431             $suite = $stz->{Distribution};
2432             last;
2433         };
2434         die "neither of the first two changelog entries are released\n"
2435             unless defined $lvsn;
2436         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2437         my $mtag_pat = debiantag_maintview $lvsn, '*';
2438         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2439             $mtag_pat;
2440         die "could not find suitable maintainer view tag $mtag_pat\n"
2441             unless $mtag_pat =~ m{/};
2442         is_fast_fwd $mtag, 'HEAD' or
2443             die "HEAD is not FF from maintainer tag $mtag!";
2444         my $dtag = "archive/$mtag";
2445         is_fast_fwd $mtag, $dtag or
2446             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2447         print "will stitch in dgit view, $dtag\n";
2448         git_rev_parse $dtag;
2449     };
2450     if (!$previous_dgit_view) {
2451         $@ =~ s/^\n+//;
2452         chomp $@;
2453         print STDERR "cannot stitch in dgit view: $@\n";
2454     }
2455
2456     snags_maybe_bail_early();
2457
2458     my $work;
2459
2460     fresh_workarea();
2461     in_workarea sub {
2462         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2463         # make a branch out of the patch queue - we'll want this in a mo
2464         runcmd qw(gbp pq import);
2465         # strip the patches out
2466         runcmd @git, qw(checkout -q gdr-internal~0);
2467         rm_subdir_cached 'debian/patches';
2468         $work = make_commit ['HEAD'], [
2469  'git-debrebase convert-from-gbp: drop patches from tree',
2470  'Delete debian/patches, as part of converting to git-debrebase format.',
2471  '[git-debrebase convert-from-gbp: drop patches from tree]'
2472                               ];
2473         # make the anchor merge
2474         # the tree is already exactly right
2475         $work = make_commit [$work, $upstream], [
2476  'git-debrebase import: declare upstream',
2477  'First breakwater merge.',
2478  '[git-debrebase anchor: declare upstream]'
2479                               ];
2480
2481         # rebase the patch queue onto the new breakwater
2482         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2483         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2484         $work = git_rev_parse 'HEAD';
2485
2486         if ($previous_dgit_view) {
2487             $work = make_commit [$work, $previous_dgit_view], [
2488  'git-debrebase import: declare ff from dgit archive view',
2489  '[git-debrebase pseudomerge: import-from-gbp]',
2490             ];
2491         }
2492     };
2493
2494     ffq_check $work;
2495     snags_maybe_bail();
2496     update_head_checkout $old_head, $work, 'convert-from-gbp';
2497 }
2498
2499 sub cmd_convert_to_gbp () {
2500     badusage "no arguments allowed" if @ARGV;
2501     my $head = get_head();
2502     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2503     keycommits $head, 0;
2504     my $out;
2505     make_patches_staged $head;
2506     in_workarea sub {
2507         $out = make_commit ['HEAD'], [
2508             'Commit patch queue (converted from git-debrebase format)',
2509             '[git-debrebase convert-to-gbp: commit patches]',
2510         ];
2511     };
2512     if (defined $ffq) {
2513         push @deferred_updates, "delete $ffq";
2514         push @deferred_updates, "delete $gdrlast";
2515     }
2516     snags_maybe_bail();
2517     update_head_checkout $head, $out, "convert to gbp (v0)";
2518     print <<END or die $!;
2519 git-debrebase: converted to git-buildpackage branch format
2520 git-debrebase: WARNING: do not now run "git-debrebase" any more
2521 git-debrebase: WARNING: doing so would drop all upstream patches!
2522 END
2523 }
2524
2525 sub cmd_convert_from_dgit_view () {
2526     my $clogp = parsechangelog();
2527
2528     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2529     my $do_origs = 1;
2530     my $do_tags = 1;
2531     my $always = 0;
2532     my $diagnose = 0;
2533
2534     getoptions("convert-from-dgit-view",
2535                'diagnose!', \$diagnose,
2536                'build-products-dir:s', \$bpd,
2537                'origs!', \$do_origs,
2538                'tags!', \$do_tags,
2539                'always-convert-anyway!', \$always);
2540     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2541
2542     my @upstreams;
2543
2544     if (@ARGV) {
2545         my $spec = shift @ARGV;
2546         my $commit = git_rev_parse "$spec^{commit}";
2547         push @upstreams, { Commit => $commit,
2548                            Source => "$ARGV[0], from command line",
2549                            Only => 1,
2550                          };
2551     }
2552
2553     my $head = get_head();
2554
2555     if (!$always) {
2556         my $troubles = 0;
2557         my $trouble = sub { $troubles++; };
2558         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2559         printdebug "troubles=$troubles\n";
2560         if (!$troubles) {
2561             print STDERR <<END;
2562 $us: Branch already seems to be in git-debrebase format!
2563 $us: --always-convert-anyway would do the conversion operation anyway
2564 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2565 END
2566             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2567             finish 0;
2568         }
2569     }
2570
2571     snags_maybe_bail_early();
2572
2573     my $version = upstreamversion $clogp->{Version};
2574     print STDERR "Considering possible commits corresponding to upstream:\n";
2575
2576     if (!@upstreams) {
2577         if ($do_tags) {
2578             my @tried;
2579             my $ups_tag = upstream_commitish_search $version, \@tried;
2580             if ($ups_tag) {
2581                 my $this = "git tag $tried[-1]";
2582                 push @upstreams, { Commit => $ups_tag,
2583                                    Source => $this,
2584                                  };
2585             } else {
2586                 printf STDERR
2587                     " git tag: no suitable tag found (tried %s)\n",
2588                     "@tried";
2589             }
2590         }
2591         if ($do_origs) {
2592             my $p = $clogp->{'Source'};
2593             # we do a quick check to see if there are plausible origs
2594             my $something=0;
2595             if (!opendir BPD, $bpd) {
2596                 die "$bpd: opendir: $!" unless $!==ENOENT;
2597             } else {
2598                 while ($!=0, my $f = readdir BPD) {
2599                     next unless is_orig_file_of_p_v $f, $p, $version;
2600                     printf STDERR
2601                         " orig: found what looks like a .orig, %s\n",
2602                         "$bpd/$f";
2603                     $something=1;
2604                     last;
2605                 }
2606                 die "read $bpd: $!" if $!;
2607                 closedir BPD;
2608             }
2609             if ($something) {
2610                 my $tree = cmdoutput
2611                     @dgit, qw(--build-products-dir), $bpd,
2612                     qw(print-unapplied-treeish);
2613                 fresh_workarea();
2614                 in_workarea sub {
2615                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2616                     rm_subdir_cached 'debian';
2617                     $tree = cmdoutput @git, qw(write-tree);
2618                     my $ups_synth = make_commit [], [ <<END, <<END,
2619 Import effective orig tree for upstream version $version
2620 END
2621 This includes the contents of the .orig(s), minus any debian/ directory.
2622
2623 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2624 END
2625                                                     ];
2626                     push @upstreams, { Commit => $ups_synth,
2627                                        Source => "orig(s) imported via dgit",
2628                                      };
2629                 }
2630             } else {
2631                 printf STDERR
2632                     " orig: no suitable origs found (looked for %s in %s)\n",
2633                     "${p}_".(stripeoch $version)."...", $bpd;
2634             }
2635         }
2636     }
2637
2638     my $some_patches = stat_exists 'debian/patches/series';
2639
2640     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2641
2642     my $result;
2643     foreach my $u (@upstreams) {
2644         my $work = $head;
2645         fresh_workarea();
2646         in_workarea sub {
2647             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2648             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2649             runcmd @git, qw(clean -xdff);
2650             runcmd @git, qw(checkout), $head, qw(-- debian);
2651             if ($some_patches) {
2652                 rm_subdir_cached 'debian/patches';
2653                 $work = make_commit [ $work ], [
2654  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2655  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2656  "to git-debrebase format.  Upstream changes will appear as commits.",
2657  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2658                                            ];
2659             }
2660             $work = make_commit [ $work, $u->{Commit} ], [
2661  'git-debrebase convert-from-dgit-view: declare upstream',
2662  '(Re)constructed breakwater merge.',
2663  '[git-debrebase anchor: declare upstream]'
2664                                                          ];
2665             runcmd @git, qw(checkout --quiet -b mk), $work;
2666             if ($some_patches) {
2667                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2668                 runcmd @git, qw(reset --quiet);
2669                 my @gbp_cmd = (qw(gbp pq import));
2670                 if (!$diagnose) {
2671                     my $gbp_err = "../gbp-pq-err";
2672                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2673                 }
2674                 my $r = system @gbp_cmd;
2675                 if ($r) {
2676                     printf STDERR
2677                         " %s: couldn't apply patches: gbp pq %s",
2678                         $u->{Source}, waitstatusmsg();
2679                     return;
2680                 }
2681             }
2682             my $work = git_rev_parse qw(HEAD);
2683             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2684             if (length $diffout) {
2685                 print STDERR
2686                     " $u->{Source}: applying patches gives different tree\n";
2687                 print STDERR $diffout if $diagnose;
2688                 return;
2689             }
2690             # OMG!
2691             $u->{Result} = $work;
2692             $result = $u;
2693         };
2694         last if $result;
2695     }
2696
2697     if (!$result) {
2698         fail <<END;
2699 Could not find or construct a suitable upstream commit.
2700 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2701 upstream commmit explicitly or provide suitable origs.
2702 END
2703     }
2704
2705     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2706
2707     ffq_check $result->{Result};
2708     snags_maybe_bail();
2709     update_head_checkout $head, $result->{Result},
2710         'convert-from-dgit-view';
2711 }
2712
2713 sub cmd_record_resolved_merge () {
2714     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2715     # xxx needs documentation
2716     my $new = get_head();
2717     my $method;
2718
2719     print "Checking how you have resolved the merge problem\n";
2720     my $nope = sub { print "Not $method: @_"; 0; };
2721
2722     my $maybe = sub { print "Seems to be $method.\n"; };
2723     my $yes = sub {
2724         my ($key, $ref) = @_;
2725         reflog_cache_insert $merge_cache_ref, $key, $ref;
2726         print "OK.  You can switch branches and try git-debrebase again.\n";
2727         1;
2728     };
2729
2730     fresh_workarea 'merge';
2731     sub {
2732         $method = 'vanilla-merge patchqueue';
2733         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2734         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2735         foreach my $lr (qw(left right)) {
2736             my $n = "$wrecknoteprefix/$lr-patchqueue";
2737             my $lrpq = git_get_ref $n;
2738             $lrpq or return $nope->("wreckage did not contain patchqueues");
2739             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2740         }
2741         $maybe->();
2742         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2743             or die "wreckage element $wrecknoteprefix/new-base missing";
2744         my $result = merge_series_patchqueue_convert
2745             {}, $newbase, $new;
2746         $yes->("vanilla-merge $vanilla", $result);
2747         1;
2748     }->() or sub {
2749         fail "No resolved merge method seems applicable.\n";
2750     }->();
2751 }
2752
2753 sub cmd_downstream_rebase_launder_v0 () {
2754     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2755     my ($base) = @ARGV;
2756     $base = git_rev_parse $base;
2757     my $old_head = get_head();
2758     my $current = $old_head;
2759     my $topmost_keep;
2760     for (;;) {
2761         if ($current eq $base) {
2762             $topmost_keep //= $current;
2763             print " $current BASE stop\n";
2764             last;
2765         }
2766         my $cl = classify $current;
2767         print " $current $cl->{Type}";
2768         my $keep = 0;
2769         my $p0 = $cl->{Parents}[0]{CommitId};
2770         my $next;
2771         if ($cl->{Type} eq 'Pseudomerge') {
2772             print " ^".($cl->{Contributor}{Ix}+1);
2773             $next = $cl->{Contributor}{CommitId};
2774         } elsif ($cl->{Type} eq 'AddPatches' or
2775                  $cl->{Type} eq 'Changelog') {
2776             print " strip";
2777             $next = $p0;
2778         } else {
2779             print " keep";
2780             $next = $p0;
2781             $keep = 1;
2782         }
2783         print "\n";
2784         if ($keep) {
2785             $topmost_keep //= $current;
2786         } else {
2787             die "to-be stripped changes not on top of the branch\n"
2788                 if $topmost_keep;
2789         }
2790         $current = $next;
2791     }
2792     if ($topmost_keep eq $old_head) {
2793         print "unchanged\n";
2794     } else {
2795         print "updating to $topmost_keep\n";
2796         update_head_checkout
2797             $old_head, $topmost_keep,
2798             'downstream-rebase-launder-v0';
2799     }
2800 }
2801
2802 getoptions_main
2803           ("bad options\n",
2804            "D+" => \$debuglevel,
2805            'noop-ok', => \$opt_noop_ok,
2806            'f=s' => \@snag_force_opts,
2807            'anchor=s' => \@opt_anchors,
2808            '--dgit=s' => \($dgit[0]),
2809            'force!',
2810            '-i:s' => sub {
2811                my ($opt,$val) = @_;
2812                badusage "git-debrebase: no cuddling to -i for git-rebase"
2813                    if length $val;
2814                die if $opt_defaultcmd_interactive; # should not happen
2815                $opt_defaultcmd_interactive = [ qw(-i) ];
2816                # This access to @ARGV is excessive familiarity with
2817                # Getopt::Long, but there isn't another sensible
2818                # approach.  '-i=s{0,}' does not work with bundling.
2819                push @$opt_defaultcmd_interactive, @ARGV;
2820                @ARGV=();
2821            },
2822            'help' => sub { print $usage_message or die $!; finish 0; },
2823            );
2824
2825 initdebug('git-debrebase ');
2826 enabledebug if $debuglevel;
2827
2828 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2829 chdir $toplevel or die "chdir $toplevel: $!";
2830
2831 $rd = fresh_playground "$playprefix/misc";
2832
2833 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2834
2835 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2836     defaultcmd_rebase();
2837 } else {
2838     my $cmd = shift @ARGV;
2839     my $cmdfn = $cmd;
2840     $cmdfn =~ y/-/_/;
2841     $cmdfn = ${*::}{"cmd_$cmdfn"};
2842
2843     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2844     $cmdfn->();
2845 }
2846
2847 finish 0;