git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             my @earlier;
 399             if (open S, $seriesfile) {
 400                 while (my $patch = <S>) {
 401                     chomp $patch or die $!;
 402                     $prereq{$patch} //= {};
 403                     foreach my $earlier (@earlier) {
 404                         $prereq{$patch}{$earlier}{$s}++ and die;
 405                     }
 406                     push @earlier, $patch;
 407                     stat "debian/patches/$patch" or die "$patch ?";
 408                 }
 409                 S->error and die "$seriesfile $!";
 410                 close S;
 411             } else {
 412                 die "$seriesfile $!" unless $!==ENOENT;
 413             }
 414             read_tree_upstream $newbase, 1;
 415             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 416                 "Convert $s to patch queue for merging",
 417                 "[git-debrebase merge-innards patch-queue import:".
 418                 " $q->{SeriesTip}]"
 419             ];
 420             printdebug "merge_series  pec $pec ";
 421             runcmd @git, qw(rm -q --cached), $seriesfile;
 422             $pec = make_commit [ $pec ], [
 423                 "Drop series file from $s to avoid merge trouble",
 424                 "[git-debrebase merge-innards patch-queue prep:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427
 428             read_tree_debian $newbase;
 429             if (@earlier) {
 430                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 431             } else {
 432                 rm_subdir_cached 'debian/patches';
 433             }
 434             $pec = make_commit [ $pec ], [
 435  "Update debian/ (excluding patches) to final to avoid re-merging",
 436  "debian/ was already merged and we need to just take that.",
 437                 "[git-debrebase merge-innards patch-queue packaging:".
 438                 " $q->{SeriesTip}]"
 439             ];
 440
 441             printdebug "pec' $pec\n";
 442             runcmd @git, qw(reset -q --hard), $pec;
 443             $q->{MR}{PEC} = $pec;
 444         }
 445         # now, because of reverse, we are on $input_q->{MR}{OQC}
 446         runcmd @git, qw(checkout -q -b merge);
 447         printdebug "merge_series merging...\n";
 448         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 449         debugcmd '+', @mergecmd;
 450         $!=0; $?=-1;
 451         if (system @mergecmd) {
 452             failedcmd @mergecmd;
 453         }
 454
 455         printdebug "merge_series merge ok, series...\n";
 456         # We need to construct a new series file
 457         # Firstly, resolve prereq
 458         foreach my $f (sort keys %prereq) {
 459             printdebug "merge_series  patch\t$f\t";
 460             if (!stat_exists "debian/patches/$f") {
 461                 print DEBUG " drop\n" if $debuglevel;
 462                 # git merge deleted it; that's how we tell it's not wanted
 463                 delete $prereq{$f};
 464                 next;
 465             }
 466             print DEBUG " keep\n" if $debuglevel;
 467             foreach my $g (sort keys %{ $prereq{$f} }) {
 468                 my $gfp = $prereq{$f}{$g};
 469                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 470                 if (!!$gfp->{0} == !!$gfp->{1}
 471                     ? $gfp->{0}
 472                     : !$gfp->{base}) {
 473                     print DEBUG "\tkeep\n" if $debuglevel;
 474                 } else {
 475                     print DEBUG "\tdrop\n" if $debuglevel;
 476                     delete $prereq{$f}{$g};
 477                 }
 478             }
 479         }
 480
 481         my $unsat = sub {
 482             my ($f) = @_;
 483             return scalar keys %{ $prereq{$f} };
 484         };
 485
 486         my $nodate = time + 1;
 487         my %authordate;
 488         # $authordate{<patch filename>};
 489         my $authordate = sub {
 490             my ($f) = @_;
 491             $authordate{$f} //= do {
 492                 open PF, "<", "debian/patches/$f" or die "$f $!";
 493                 while (<PF>) {
 494                     return $nodate if m/^$/;
 495                     last if s{^Date: }{};
 496                 }
 497                 chomp;
 498                 return cmdoutput qw(date +%s -d), $_;
 499             };
 500         };
 501
 502         open NS, '>', $seriesfile or die $!;
 503
 504         while (keys %prereq) {
 505             my $best;
 506             foreach my $try (sort keys %prereq) {
 507                 if ($best) {
 508                     next if (
 509                              $unsat->($try) <=> $unsat->($best) or
 510                              $authordate->($try) <=> $authordate->($best) or
 511                              $try cmp $best
 512                             ) >= 0;
 513                 }
 514                 $best = $try;
 515             }
 516             printdebug "merge_series series next $best\n";
 517             print NS "$best\n" or die $!;
 518             delete $prereq{$best};
 519             foreach my $gp (values %prereq) {
 520                 delete $gp->{$best};
 521             }
 522         }
 523
 524         runcmd @git, qw(add), $seriesfile;
 525         runcmd @git, qw(commit --quiet -m), 'Merged series';
 526
 527         printdebug "merge_series series gbp pq import\n";
 528         runcmd qw(gbp pq import);
 529
 530         # OK now we are on patch-queue/merge, and we need to rebase
 531         # onto the intended parent and drop the patches from each one
 532
 533         printdebug "merge_series series ok, building...\n";
 534         my $build = $newbase;
 535         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 536         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 537             my $commit = git_cat_file $c, 'commit';
 538             printdebug "merge_series series ok, building $c\n";
 539             read_tree_upstream $c, 0, $newbase;
 540             my $tree = cmdoutput @git, qw(write-tree);
 541             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 542             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 543             open C, ">", "../mcommit" or die $!;
 544             print C $commit or die $!;
 545             close C or die $!;
 546             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 547         }
 548         $result = $build;
 549         runcmd @git, qw(update-ref refs/heads/result), $result;
 550
 551         runcmd @git, qw(checkout -q -b debug);
 552         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 553         runcmd @git, qw(add .);
 554         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 555         printdebug sprintf "merge_series done debug=%s\n",
 556             git_rev_parse 'HEAD';
 557     };
 558     printdebug "merge_series returns $result\n";
 559     return $result;
 560 }
 561
 562 # classify returns an info hash like this
 563 #   CommitId => $objid
 564 #   Hdr => # commit headers, including 1 final newline
 565 #   Msg => # commit message (so one newline is dropped)
 566 #   Tree => $treeobjid
 567 #   Type => (see below)
 568 #   Parents = [ {
 569 #       Ix => $index # ie 0, 1, 2, ...
 570 #       CommitId
 571 #       Differs => return value from get_differs
 572 #       IsOrigin
 573 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 574 #     } ...]
 575 #   NewMsg => # commit message, but with any [dgit import ...] edited
 576 #             # to say "[was: ...]"
 577 #
 578 # Types:
 579 #   Packaging
 580 #   Changelog
 581 #   Upstream
 582 #   AddPatches
 583 #   Mixed
 584 #
 585 #   Pseudomerge
 586 #     has additional entres in classification result
 587 #       Overwritten = [ subset of Parents ]
 588 #       Contributor = $the_remaining_Parent
 589 #
 590 #   DgitImportUnpatched
 591 #     has additional entry in classification result
 592 #       OrigParents = [ subset of Parents ]
 593 #
 594 #   Anchor
 595 #     has additional entry in classification result
 596 #       OrigParents = [ subset of Parents ]  # singleton list
 597 #
 598 #   TreatAsAnchor
 599 #
 600 #   BreakwaterStart
 601 #
 602 #   Unknown
 603 #     has additional entry in classification result
 604 #       Why => "prose"
 605
 606 sub parsecommit ($;$) {
 607     my ($objid, $p_ref) = @_;
 608     # => hash with                   CommitId Hdr Msg Tree Parents
 609     #    Parents entries have only   Ix CommitId
 610     #    $p_ref, if provided, must be [] and is used as a base for Parents
 611
 612     $p_ref //= [];
 613     die if @$p_ref;
 614
 615     my ($h,$m) = get_commit $objid;
 616
 617     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 618     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 619
 620     my $r = {
 621         CommitId => $objid,
 622         Hdr => $h,
 623         Msg => $m,
 624         Tree => $t,
 625         Parents => $p_ref,
 626     };
 627
 628     foreach my $ph (@ph) {
 629         push @$p_ref, {
 630             Ix => scalar @$p_ref,
 631             CommitId => $ph,
 632         };
 633     }
 634
 635     return $r;
 636 }
 637
 638 sub classify ($) {
 639     my ($objid) = @_;
 640
 641     my @p;
 642     my $r = parsecommit($objid, \@p);
 643     my $t = $r->{Tree};
 644
 645     foreach my $p (@p) {
 646         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 647     }
 648
 649     printdebug "classify $objid \$t=$t \@p",
 650         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 651         "\n";
 652
 653     my $classify = sub {
 654         my ($type, @rest) = @_;
 655         $r = { %$r, Type => $type, @rest };
 656         if ($debuglevel) {
 657             printdebug " = $type ".(dd $r)."\n";
 658         }
 659         return $r;
 660     };
 661     my $unknown = sub {
 662         my ($why) = @_;
 663         $r = { %$r, Type => qw(Unknown), Why => $why };
 664         printdebug " ** Unknown\n";
 665         return $r;
 666     };
 667
 668     if (grep { $_ eq $objid } @opt_anchors) {
 669         return $classify->('TreatAsAnchor');
 670     }
 671
 672     my @identical = grep { !$_->{Differs} } @p;
 673     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 674     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 675
 676     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 677         # multi-orig upstreams are represented with an anchor merge
 678         # from a single upstream commit which combines the orig tarballs
 679
 680         # Every anchor tagged this way must be a merge.
 681         # We are relying on the
 682         #     [git-debrebase anchor: ...]
 683         # commit message annotation in "declare" anchor merges (which
 684         # do not have any upstream changes), to distinguish those
 685         # anchor merges from ordinary pseudomerges (which we might
 686         # just try to strip).
 687         #
 688         # However, the user is going to be doing git-rebase a lot.  We
 689         # really don't want them to rewrite an anchor commit.
 690         # git-rebase trips up on merges, so that is a useful safety
 691         # catch.
 692         #
 693         # BreakwaterStart commits are also anchors in the terminology
 694         # of git-debrebase(5), but they are untagged (and always
 695         # manually generated).
 696         #
 697         # We cannot not tolerate any tagged linear commit (ie,
 698         # BreakwaterStart commits tagged `[anchor:') because such a
 699         # thing could result from an erroneous linearising raw git
 700         # rebase of a merge anchor.  That would represent a corruption
 701         # of the branch. and we want to detect and reject the results
 702         # of such corruption before it makes it out anywhere.  If we
 703         # reject it here then we avoid making the pseudomerge which
 704         # would be needed to push it.
 705
 706         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 707         @p == 2 or return $badanchor->("has other than two parents");
 708         $haspatches and return $badanchor->("contains debian/patches");
 709
 710         # How to decide about l/r ordering of anchors ?  git
 711         # --topo-order prefers to expand 2nd parent first.  There's
 712         # already an easy rune to look for debian/ history anyway (git log
 713         # debian/) so debian breakwater branch should be 1st parent; that
 714         # way also there's also an easy rune to look for the upstream
 715         # patches (--topo-order).
 716
 717         # Also this makes --first-parent be slightly more likely to
 718         # be useful - it makes it provide a linearised breakwater history.
 719
 720         # Of course one can say somthing like
 721         #  gitk -- ':/' ':!/debian'
 722         # to get _just_ the commits touching upstream files, and by
 723         # the TREESAME logic in git-rev-list this will leave the
 724         # breakwater into upstream at the first anchor.  But that
 725         # doesn't report debian/ changes at all.
 726
 727         # Other observations about gitk: by default, gitk seems to
 728         # produce output in a different order to git-rev-list.  I
 729         # can't seem to find this documented anywhere.  gitk
 730         # --date-order DTRT.  But, gitk always seems to put the
 731         # parents from left to right, in order, so it's easy to see
 732         # which way round a pseudomerge is.
 733
 734         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 735         $p[1]{Differs} & ~DS_DEB and
 736             $badanchor->("upstream files differ from left parent");
 737         $p[0]{Differs} & ~D_UPS and
 738             $badanchor->("debian/ differs from right parent");
 739
 740         return $classify->(qw(Anchor),
 741                            OrigParents => [ $p[1] ]);
 742     }
 743
 744     if (@p == 1) {
 745         my $d = $r->{Parents}[0]{Differs};
 746         if ($d == D_PAT_ADD) {
 747             return $classify->(qw(AddPatches));
 748         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 749             return $unknown->("edits debian/patches");
 750         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 751             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 752             if ($ty eq 'tree') {
 753                 if ($d == D_DEB_CLOG) {
 754                     return $classify->(qw(Changelog));
 755                 } else {
 756                     return $classify->(qw(Packaging));
 757                 }
 758             } elsif ($ty eq 'missing') {
 759                 return $classify->(qw(BreakwaterStart));
 760             } else {
 761                 return $unknown->("parent's debian is not a directory");
 762             }
 763         } elsif ($d == D_UPS) {
 764             return $classify->(qw(Upstream));
 765         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 766             return $classify->(qw(Mixed));
 767         } elsif ($d == 0) {
 768             return $unknown->("no changes");
 769         } else {
 770             confess "internal error $objid ?";
 771         }
 772     }
 773     if (!@p) {
 774         return $unknown->("origin commit");
 775     }
 776
 777     if (@p == 2 && @identical == 1) {
 778         my @overwritten = grep { $_->{Differs} } @p;
 779         confess "internal error $objid ?" unless @overwritten==1;
 780         return $classify->(qw(Pseudomerge),
 781                            Overwritten => [ $overwritten[0] ],
 782                            Contributor => $identical[0]);
 783     }
 784     if (@p == 2 && @identical == 2) {
 785         my $get_t = sub {
 786             my ($ph,$pm) = get_commit $_[0]{CommitId};
 787             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 788             $1;
 789         };
 790         my @bytime = @p;
 791         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 792         if ($order > 0) { # newer first
 793         } elsif ($order < 0) {
 794             @bytime = reverse @bytime;
 795         } else {
 796             # same age, default to order made by -s ours
 797             # that is, commit was made by someone who preferred L
 798         }
 799         return $classify->(qw(Pseudomerge),
 800                            SubType => qw(Ambiguous),
 801                            Contributor => $bytime[0],
 802                            Overwritten => [ $bytime[1] ]);
 803     }
 804     foreach my $p (@p) {
 805         my ($p_h, $p_m) = get_commit $p->{CommitId};
 806         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 807         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 808     }
 809     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 810     my $m2 = $r->{Msg};
 811     if (!(grep { !$_->{IsOrigin} } @p) and
 812         (@orig_ps >= @p - 1) and
 813         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 814         $r->{NewMsg} = $m2;
 815         return $classify->(qw(DgitImportUnpatched),
 816                            OrigParents => \@orig_ps);
 817     }
 818
 819     if (@p == 2 and
 820         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 821         # xxx ^ metadata tag needs adding to (5)
 822         return $classify->("MergedBreakwaters");
 823     }
 824     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 825         return $unknown->("unknown kind of merge from $1");
 826     }
 827     if (@p > 2) {
 828         return $unknown->("octopus merge");
 829     }
 830
 831     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 832         return $unknown->("general two-parent merge");
 833     }
 834
 835     return $classify->("VanillaMerge");
 836 }
 837
 838 sub keycommits ($;$$$$$);
 839
 840 sub mergedbreakwaters_anchor ($) {
 841     my ($cl) = @_;
 842     my $best_anchor;
 843     foreach my $p (@{ $cl->{Parents} }) {
 844         my ($panchor, $pbw) = keycommits $p->{CommitId},
 845             undef,undef,undef,undef, 1;
 846         $best_anchor = $panchor
 847             if !defined $best_anchor
 848             or is_fast_fwd $best_anchor, $panchor;
 849         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 850             unless is_fast_fwd $panchor, $best_anchor;
 851     }
 852     return $best_anchor;
 853 }
 854
 855 sub keycommits ($;$$$$$) {
 856     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 857     # => ($anchor, $breakwater)
 858
 859     # $unclean->("unclean-$tagsfx", $msg, $cl)
 860     # $furniture->("unclean-$tagsfx", $msg, $cl)
 861     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 862     #   is callled for each situation or commit that
 863     #   wouldn't be found in a laundered branch
 864     # $furniture is for furniture commits such as might be found on an
 865     #   interchange branch (pseudomerge, d/patches, changelog)
 866     # $trouble is for things whnich prevent the return of
 867     #   anchor and breakwater information; if that is ignored,
 868     #   then keycommits returns (undef, undef) instead.
 869     # $fatal is for unprocessable commits, and should normally cause
 870     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 871     #
 872     # If $claimed_bw, this is supposed to be a breakwater commit.
 873     #
 874     # If a callback is undef, fail is called instead.
 875     # If a callback is defined but false, the situation is ignored.
 876     # Callbacks may say:
 877     #   no warnings qw(exiting); last;
 878     # if the answer is no longer wanted.
 879
 880     my ($anchor, $breakwater);
 881     $breakwater = $head if $claimed_bw;
 882     my $clogonly;
 883     my $cl;
 884     my $found_pm;
 885     $fatal //= sub { fail $_[1]; };
 886     my $x = sub {
 887         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 888         my $why = $mainwhy.$xwhy;
 889         my $m = "branch needs laundering (run git-debrebase): $why";
 890         fail $m unless defined $cb;
 891         return unless $cb;
 892         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 893     };
 894     my $found_anchor = sub {
 895         ($anchor) = @_;
 896         $breakwater //= $clogonly;
 897         $breakwater //= $head;
 898         no warnings qw(exiting);
 899         last;
 900     };
 901     for (;;) {
 902         $cl = classify $head;
 903         my $ty = $cl->{Type};
 904         if ($ty eq 'Packaging') {
 905             $breakwater //= $clogonly;
 906             $breakwater //= $head;
 907         } elsif ($ty eq 'Changelog') {
 908             # this is going to count as the tip of the breakwater
 909             # only if it has no upstream stuff before it
 910             $clogonly //= $head;
 911         } elsif ($ty eq 'Anchor' or
 912                  $ty eq 'TreatAsAnchor' or
 913                  $ty eq 'BreakwaterStart') {
 914             $found_anchor->($head);
 915         } elsif ($ty eq 'Upstream') {
 916             $x->($unclean, 'ordering',
 917  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 918                 if defined $breakwater;
 919             $clogonly = undef;
 920             $breakwater = undef;
 921         } elsif ($ty eq 'Mixed') {
 922             $x->($unclean, 'mixed',
 923                  "found mixed upstream/packaging commit"," ($head)");
 924             $clogonly = undef;
 925             $breakwater = undef;
 926         } elsif ($ty eq 'Pseudomerge' or
 927                  $ty eq 'AddPatches') {
 928             my $found_pm = 1;
 929             $x->($furniture, (lc $ty),
 930                  "found interchange bureaucracy commit ($ty)"," ($head)");
 931         } elsif ($ty eq 'DgitImportUnpatched') {
 932             if ($found_pm) {
 933                 $x->($trouble, 'dgitimport',
 934                      "found dgit dsc import"," ($head)");
 935                 return (undef,undef);
 936             } else {
 937                 $x->($fatal, 'unprocessable',
 938                      "found bare dgit dsc import with no prior history",
 939                      " ($head)");
 940                 return (undef,undef);
 941             }
 942         } elsif ($ty eq 'VanillaMerge') {
 943             $x->($trouble, 'vanillamerge',
 944                  "found vanilla merge"," ($head)");
 945             return (undef,undef);
 946         } elsif ($ty eq 'MergedBreakwaters') {
 947             $found_anchor->(mergedbreakwaters_anchor $cl);
 948         } else {
 949             $x->($fatal, 'unprocessable',
 950                  "found unprocessable commit, cannot cope: $cl->{Why}",
 951                  " ($head)");
 952             return (undef,undef);
 953         }
 954         $head = $cl->{Parents}[0]{CommitId};
 955     }
 956     return ($anchor, $breakwater);
 957 }
 958
 959 sub walk ($;$$$);
 960 sub walk ($;$$$) {
 961     my ($input,
 962         $nogenerate,$report, $report_lprefix) = @_;
 963     # => ($tip, $breakwater_tip, $last_anchor)
 964     # (or nothing, if $nogenerate)
 965
 966     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 967     $report_lprefix //= '';
 968
 969     # go through commits backwards
 970     # we generate two lists of commits to apply:
 971     # breakwater branch and upstream patches
 972     my (@brw_cl, @upp_cl, @processed);
 973     my %found;
 974     my $upp_limit;
 975     my @pseudomerges;
 976
 977     my $cl;
 978     my $xmsg = sub {
 979         my ($prose, $info) = @_;
 980         my $ms = $cl->{Msg};
 981         chomp $ms;
 982         $info //= '';
 983         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 984         return (Msg => $ms);
 985     };
 986     my $rewrite_from_here = sub {
 987         my ($cl) = @_;
 988         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 989         push @$cl, $sp_cl;
 990         push @processed, $sp_cl;
 991     };
 992     my $cur = $input;
 993
 994     my $prdelim = "";
 995     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 996
 997     my $prline = sub {
 998         return unless $report;
 999         print $report $prdelim, $report_lprefix, @_;
1000         $prdelim = "\n";
1001     };
1002
1003     my $bomb = sub { # usage: return $bomb->();
1004         print $report " Unprocessable" if $report;
1005         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1006         $prprdelim->();
1007         if ($nogenerate) {
1008             return (undef,undef);
1009         }
1010         fail "found unprocessable commit, cannot cope".
1011             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1012             " (commit $cur) (d.".
1013             (join ' ', map { sprintf "%#x", $_->{Differs} }
1014              @{ $cl->{Parents} }).
1015                  ")";
1016     };
1017
1018     my $build;
1019     my $breakwater;
1020
1021     my $build_start = sub {
1022         my ($msg, $parent) = @_;
1023         $prline->(" $msg");
1024         $build = $parent;
1025         no warnings qw(exiting); last;
1026     };
1027
1028     my $nomerge = sub {
1029         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1030     };
1031
1032     my $mwrecknote = sub {
1033         my ($reftail, $commitish) = @_;
1034         $cl->{MergeWreckNotes}{$reftail} = $commitish;
1035     };
1036
1037     my $last_anchor;
1038
1039     for (;;) {
1040         $cl = classify $cur;
1041         my $ty = $cl->{Type};
1042         my $st = $cl->{SubType};
1043         $prline->("$cl->{CommitId} $cl->{Type}");
1044         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1045         push @processed, $cl;
1046         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1047         if ($ty eq 'AddPatches') {
1048             $cur = $p0;
1049             $rewrite_from_here->(\@upp_cl);
1050             next;
1051         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1052             push @brw_cl, $cl;
1053             $cur = $p0;
1054             next;
1055         } elsif ($ty eq 'BreakwaterStart') {
1056             $last_anchor = $cur;
1057             $build_start->('FirstPackaging', $cur);
1058         } elsif ($ty eq 'Upstream') {
1059             push @upp_cl, $cl;
1060             $cur = $p0;
1061             next;
1062         } elsif ($ty eq 'Mixed') {
1063             my $queue = sub {
1064                 my ($q, $wh) = @_;
1065                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1066                 push @$q, $cls;
1067             };
1068             $queue->(\@brw_cl, "debian");
1069             $queue->(\@upp_cl, "upstream");
1070             $rewrite_from_here->(\@brw_cl);
1071             $cur = $p0;
1072             next;
1073         } elsif ($ty eq 'Pseudomerge') {
1074             my $contrib = $cl->{Contributor}{CommitId};
1075             print $report " Contributor=$contrib" if $report;
1076             push @pseudomerges, $cl;
1077             $rewrite_from_here->(\@upp_cl);
1078             $cur = $contrib;
1079             next;
1080         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1081             $last_anchor = $cur;
1082             $build_start->("Anchor", $cur);
1083         } elsif ($ty eq 'DgitImportUnpatched') {
1084             my $pm = $pseudomerges[-1];
1085             if (defined $pm) {
1086                 # To an extent, this is heuristic.  Imports don't have
1087                 # a useful history of the debian/ branch.  We assume
1088                 # that the first pseudomerge after an import has a
1089                 # useful history of debian/, and ignore the histories
1090                 # from later pseudomerges.  Often the first pseudomerge
1091                 # will be the dgit import of the upload to the actual
1092                 # suite intended by the non-dgit NMUer, and later
1093                 # pseudomerges may represent in-archive copies.
1094                 my $ovwrs = $pm->{Overwritten};
1095                 printf $report " PM=%s \@Overwr:%d",
1096                     $pm->{CommitId}, (scalar @$ovwrs)
1097                     if $report;
1098                 if (@$ovwrs != 1) {
1099                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1100                     return $bomb->();
1101                 }
1102                 my $ovwr = $ovwrs->[0]{CommitId};
1103                 printf $report " Overwr=%s", $ovwr if $report;
1104                 # This import has a tree which is just like a
1105                 # breakwater tree, but it has the wrong history.  It
1106                 # ought to have the previous breakwater (which the
1107                 # pseudomerge overwrote) as an ancestor.  That will
1108                 # make the history of the debian/ files correct.  As
1109                 # for the upstream version: either it's the same as
1110                 # was ovewritten (ie, same as the previous
1111                 # breakwater), in which case that history is precisely
1112                 # right; or, otherwise, it was a non-gitish upload of a
1113                 # new upstream version.  We can tell these apart by
1114                 # looking at the tree of the supposed upstream.
1115                 push @brw_cl, {
1116                     %$cl,
1117                     SpecialMethod => 'DgitImportDebianUpdate',
1118                     $xmsg->("convert dgit import: debian changes")
1119                 }, {
1120                     %$cl,
1121                     SpecialMethod => 'DgitImportUpstreamUpdate',
1122                     $xmsg->("convert dgit import: upstream update",
1123                             " anchor")
1124                 };
1125                 $prline->(" Import");
1126                 $rewrite_from_here->(\@brw_cl);
1127                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1128                 $cur = $ovwr;
1129                 next;
1130             } else {
1131                 # Everything is from this import.  This kind of import
1132                 # is already nearly in valid breakwater format, with the
1133                 # patches as commits.  Unfortunately it contains
1134                 # debian/patches/.
1135                 printdebug "*** WALK BOMB bare dgit import\n";
1136                 $cl->{Why} = "bare dgit dsc import";
1137                 return $bomb->();
1138             }
1139             die "$ty ?";
1140         } elsif ($ty eq 'MergedBreakwaters') {
1141             $last_anchor = mergedbreakwaters_anchor $cl;
1142             $build_start->(' MergedBreakwaters', $cur);
1143             last;
1144         } elsif ($ty eq 'VanillaMerge') {
1145             # User may have merged unstitched branch(es).  We will
1146             # have now lost what ffq-prev was then (since the later
1147             # pseudomerge may introduce further changes).  The effect
1148             # of resolving such a merge is that we may have to go back
1149             # further in history to find a merge base, since the one
1150             # which was reachable via ffq-prev is no longer findable.
1151             # This is suboptimal, but if it all works we'll have done
1152             # the right thing.
1153             # xxx we should warn the user in the docs about this
1154
1155             my $ok=1;
1156             my $best_anchor;
1157             # We expect to find a dominating anchor amongst the
1158             # inputs' anchors.  That will be the new anchor.
1159             #
1160             # More complicated is finding a merge base for the
1161             # breakwaters.  We need a merge base that is a breakwater
1162             # commit.  The ancestors of breakwater commits are more
1163             # breakwater commits and possibly upstream commits and the
1164             # ancestors of those upstream.  Upstreams might have
1165             # arbitrary ancestors.  But any upstream commit U is
1166             # either included in both anchors, in which case the
1167             # earlier anchor is a better merge base than any of U's
1168             # ancestors; or U is not included in the older anchor, in
1169             # which case U is not an ancestor of the vanilla merge at
1170             # all.  So no upstream commit, nor any ancestor thereof,
1171             # is a best merge base.  As for non-breakwater Debian
1172             # commits: these are never ancestors of any breakwater.
1173             #
1174             # So any best merge base as found by git-merge-base
1175             # is a suitable breakwater anchor.  Usually there will
1176             # be only one.
1177
1178             printdebug "*** MERGE\n";
1179
1180             my @bwbcmd = (@git, qw(merge-base));
1181             my @ibcmd = (@git, qw(merge-base --all));
1182             my $might_be_in_bw = 1;
1183
1184             my $ps = $cl->{Parents};
1185
1186             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1187
1188             foreach my $p (@$ps) {
1189                 $prline->(" VanillaMerge ".$p->{Ix});
1190                 $prprdelim->();
1191                 my ($ptip, $pbw, $panchor) =
1192                     walk $p->{CommitId}, 0, $report,
1193                          $report_lprefix.'  ';
1194                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1195                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1196                 $p->{Anchor} = $panchor;
1197
1198                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1199                 $mwrecknote->("$lr-input", $p->{CommitId});
1200
1201                 my $mwrecknote_parent = sub {
1202                     my ($which) = @_;
1203                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1204                 };
1205                 $mwrecknote_parent->('Laundered');
1206                 $mwrecknote_parent->('Breakwater');
1207                 $mwrecknote_parent->('Anchor');
1208
1209                 $best_anchor = $panchor if
1210                     !defined $best_anchor or
1211                     is_fast_fwd $best_anchor, $panchor;
1212
1213                 printdebug " MERGE BA best=".($best_anchor//'-').
1214                     " p=$panchor\n";
1215             }
1216
1217             $mwrecknote->('result-anchor', $best_anchor);
1218
1219             foreach my $p (@$ps) {
1220                 $prline->(" VanillaMerge ".$p->{Ix});
1221                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1222                     $nomerge->('divergent anchors');
1223                 } elsif ($p->{Anchor} eq $best_anchor) {
1224                     print $report " SameAnchor" if $report;
1225                 } else {
1226                     print $report " SupersededAnchor" if $report;
1227                 }
1228                 if ($p->{Breakwater} eq $p->{CommitId}) {
1229                     # this parent commit was its own breakwater,
1230                     # ie it is part of the breakwater
1231                     print $report " Breakwater" if $report;
1232                 } else {
1233                     $might_be_in_bw = 0;
1234                 }
1235                 push @bwbcmd, $p->{Breakwater};
1236                 push @ibcmd, $p->{CommitId};
1237             }
1238
1239             if ($ok && $might_be_in_bw) {
1240                 # We could rewrite this to contaion the metadata
1241                 # declaring it to be MergedBreakwaters, but
1242                 # unnecessarily rewriting a merge seems unhelpful.
1243                 $prline->(" VanillaMerge MergedBreakwaters");
1244                 $last_anchor = $best_anchor;
1245                 $build_start->('MergedBreakwaters', $cur);
1246             }
1247
1248             my $bwb = cmdoutput @bwbcmd;
1249
1250             # OK, now we have a breakwater base, but we need the merge
1251             # base for the interchange branch because we need the delta
1252             # queue.
1253             #
1254             # This a the best merge base of our inputs which has the
1255             # breakwater merge base as an ancestor.
1256
1257             my @ibs =
1258                 grep /./,
1259                 split /\n/,
1260                 cmdoutput @ibcmd;
1261
1262             @ibs or confess 'internal error, expected anchor at least ?';
1263
1264             my $ib;
1265             my $ibleaf;
1266             foreach my $tibix (0..$#ibs) {
1267                 my $tib = $ibs[$tibix];
1268                 my $ff = is_fast_fwd $bwb, $tib;
1269                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1270                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1271                 $mwrecknote->($tibleaf, $tib);
1272                 next unless $ff;
1273                 next if $ib;
1274                 $ib = $tib;
1275                 $ibleaf = $tibleaf;
1276             }
1277
1278             $ib or $nomerge->("no suitable interchange merge base");
1279
1280             $prline->("  VanillaMerge Base");
1281             $prprdelim->();
1282             my ($btip, $bbw, $banchor) = eval {
1283                 walk $ib, 0, $report, $report_lprefix.'  ';
1284             };
1285             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1286                        $@) if length $@;
1287
1288             $mwrecknote->("mergebase-laundered", $btip);
1289             $mwrecknote->("mergebase-breakwater", $bbw);
1290             $mwrecknote->("mergebase-anchor", $banchor);
1291
1292             my $ibinfo = { SeriesTip => $btip,
1293                            SeriesBase => $bbw,
1294                            Anchor => $banchor };
1295             $bbw eq $bwb
1296                 or $nomerge->("interchange merge-base ($ib)'s".
1297                               " breakwater ($bbw)".
1298                               " != breakwaters' merge-base ($bwb)");
1299
1300             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1301                  or $nomerge->("interchange merge-base ($ib)'s".
1302                                " anchor ($ibinfo->{SeriesBase})".
1303                                " != any merge input's anchor (".
1304                                (join ' ', map { $_->{Anchor} } @$ps).
1305                                ")");
1306
1307             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1308             $cl->{MergeBestAnchor} = $best_anchor;
1309             push @brw_cl, {
1310                 %$cl,
1311                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1312                 $xmsg->('constructed from vanilla merge',
1313                         ' merged-breakwater'),
1314             };
1315             push @upp_cl, {
1316                 %$cl,
1317                 SpecialMethod => 'MergeMergeSeries',
1318             };
1319             $build_start->('MergeBreakwaters', $cur);
1320         } else {
1321             printdebug "*** WALK BOMB unrecognised\n";
1322             return $bomb->();
1323         }
1324     }
1325     $prprdelim->();
1326
1327     printdebug "*** WALK prep done cur=$cur".
1328         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1329
1330     return if $nogenerate;
1331
1332     # Now we build it back up again
1333
1334     fresh_workarea();
1335
1336     my $rewriting = 0;
1337
1338     my $read_tree_upstream = sub {
1339         my ($treeish) = @_;
1340         read_tree_upstream $treeish, 0, $build;
1341     };
1342
1343     $#upp_cl = $upp_limit if defined $upp_limit;
1344
1345     my $committer_authline = calculate_committer_authline();
1346
1347     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1348
1349     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1350
1351     in_workarea sub {
1352         mkdir $rd or $!==EEXIST or die $!;
1353         my $current_method;
1354         runcmd @git, qw(read-tree), $build;
1355         foreach my $cl (qw(Debian), (reverse @brw_cl),
1356                         { SpecialMethod => 'RecordBreakwaterTip' },
1357                         qw(Upstream), (reverse @upp_cl)) {
1358             if (!ref $cl) {
1359                 $current_method = $cl;
1360                 next;
1361             }
1362             my $method = $cl->{SpecialMethod} // $current_method;
1363             my @parents = ($build);
1364             my $cltree = $cl->{CommitId};
1365             printdebug "WALK BUILD ".($cltree//'undef').
1366                 " $method (rewriting=$rewriting)\n";
1367             if ($method eq 'Debian') {
1368                 read_tree_debian($cltree);
1369             } elsif ($method eq 'Upstream') {
1370                 $read_tree_upstream->($cltree);
1371             } elsif ($method eq 'StartRewrite') {
1372                 $rewriting = 1;
1373                 next;
1374             } elsif ($method eq 'RecordBreakwaterTip') {
1375                 $breakwater = $build;
1376                 next;
1377             } elsif ($method eq 'DgitImportDebianUpdate') {
1378                 read_tree_debian($cltree);
1379             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1380                 confess unless $rewriting;
1381                 my $differs = (get_differs $build, $cltree);
1382                 next unless $differs & D_UPS;
1383                 $read_tree_upstream->($cltree);
1384                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1385             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1386                 print "Found a general merge, will try to tidy it up.\n";
1387                 $rewriting = 1;
1388                 $read_tree_upstream->($cl->{MergeBestAnchor});
1389                 $read_tree_upstream->($cl->{MergeBestAnchor});
1390                 read_tree_debian($cltree);
1391                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1392             } elsif ($method eq 'MergeMergeSeries') {
1393                 print "Running merge resolution for $cl->{CommitId}...\n";
1394                 $build = merge_series
1395                     $build,
1396                     $cl->{MergeInterchangeBaseInfo},
1397                     @{ $cl->{Parents} };
1398                 $last_anchor = $cl->{MergeBestAnchor};
1399
1400                 # Check for mismerges:
1401                 my $check = sub {
1402                     my ($against, $allow, $what) = @_;
1403                     my $differs = get_differs $build, $against;
1404                     $nomerge->(sprintf
1405        "merge misresolved: %s are not the same (%s %s d.%#x)",
1406                                $what, $against, $build, $differs)
1407                         if $differs & ~($allow | D_PAT_ADD);
1408                 };
1409
1410                 # Breakwater changes which were in each side of the
1411                 # merge will have been incorporated into the
1412                 # MergeCreateMergedBreakwaters output.  Because the
1413                 # upstream series was rebased onto the new breakwater,
1414                 # so should all of the packaging changes which were in
1415                 # the input.
1416                 $check->($input, D_UPS, 'debian files');
1417
1418                 # Upstream files are merge_series, which ought to
1419                 # have been identical to the original merge.
1420                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1421
1422                 print "Merge resolution successful.\n";
1423                 next;
1424             } else {
1425                 confess "$method ?";
1426             }
1427             if (!$rewriting) {
1428                 my $procd = (pop @processed) // 'UNDEF';
1429                 if ($cl ne $procd) {
1430                     $rewriting = 1;
1431                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1432                 }
1433             }
1434             my $newtree = cmdoutput @git, qw(write-tree);
1435             my $ch = $cl->{Hdr};
1436             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1437             $ch =~ s{^parent .*\n}{}mg;
1438             $ch =~ s{(?=^author)}{
1439                 join '', map { "parent $_\n" } @parents
1440             }me or confess "$ch ?";
1441             if ($rewriting) {
1442                 $ch =~ s{^committer .*$}{$committer_authline}m
1443                     or confess "$ch ?";
1444             }
1445             my $cf = "$rd/m$rewriting";
1446             open CD, ">", $cf or die $!;
1447             print CD $ch, "\n", $cl->{Msg} or die $!;
1448             close CD or die $!;
1449             my @cmd = (@git, qw(hash-object));
1450             push @cmd, qw(-w) if $rewriting;
1451             push @cmd, qw(-t commit), $cf;
1452             my $newcommit = cmdoutput @cmd;
1453             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1454             $build = $newcommit;
1455             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1456                 $last_anchor = $cur;
1457             }
1458         }
1459     };
1460
1461     my $final_check = get_differs $build, $input;
1462     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1463         if $final_check & ~D_PAT_ADD;
1464
1465     my @r = ($build, $breakwater, $last_anchor);
1466     printdebug "*** WALK RETURN @r\n";
1467     return @r
1468 }
1469
1470 sub get_head () {
1471     git_check_unmodified();
1472     return git_rev_parse qw(HEAD);
1473 }
1474
1475 sub update_head ($$$) {
1476     my ($old, $new, $mrest) = @_;
1477     push @deferred_updates, "update HEAD $new $old";
1478     run_deferred_updates $mrest;
1479 }
1480
1481 sub update_head_checkout ($$$) {
1482     my ($old, $new, $mrest) = @_;
1483     update_head $old, $new, $mrest;
1484     runcmd @git, qw(reset --hard);
1485 }
1486
1487 sub update_head_postlaunder ($$$) {
1488     my ($old, $tip, $reflogmsg) = @_;
1489     return if $tip eq $old;
1490     print "git-debrebase: laundered (head was $old)\n";
1491     update_head $old, $tip, $reflogmsg;
1492     # no tree changes except debian/patches
1493     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1494 }
1495
1496 sub currently_rebasing() {
1497     foreach (qw(rebase-merge rebase-apply)) {
1498         return 1 if stat_exists "$maindir_gitdir/$_";
1499     }
1500     return 0;
1501 }
1502
1503 sub bail_if_rebasing() {
1504     fail "you are in the middle of a git-rebase already"
1505         if currently_rebasing();
1506 }
1507
1508 sub do_launder_head ($) {
1509     my ($reflogmsg) = @_;
1510     my $old = get_head();
1511     record_ffq_auto();
1512     my ($tip,$breakwater) = walk $old;
1513     snags_maybe_bail();
1514     update_head_postlaunder $old, $tip, $reflogmsg;
1515     return ($tip,$breakwater);
1516 }
1517
1518 sub cmd_launder_v0 () {
1519     badusage "no arguments to launder-v0 allowed" if @ARGV;
1520     my $old = get_head();
1521     my ($tip,$breakwater,$last_anchor) = walk $old;
1522     update_head_postlaunder $old, $tip, 'launder';
1523     printf "# breakwater tip\n%s\n", $breakwater;
1524     printf "# working tip\n%s\n", $tip;
1525     printf "# last anchor\n%s\n", $last_anchor;
1526 }
1527
1528 sub defaultcmd_rebase () {
1529     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1530     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1531     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1532 }
1533
1534 sub cmd_analyse () {
1535     badusage "analyse does not support any options"
1536         if @ARGV and $ARGV[0] =~ m/^-/;
1537     badusage "too many arguments to analyse" if @ARGV>1;
1538     my ($old) = @ARGV;
1539     if (defined $old) {
1540         $old = git_rev_parse $old;
1541     } else {
1542         $old = git_rev_parse 'HEAD';
1543     }
1544     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1545     STDOUT->error and die $!;
1546 }
1547
1548 sub ffq_prev_branchinfo () {
1549     my $current = git_get_symref();
1550     return gdr_ffq_prev_branchinfo($current);
1551 }
1552
1553 sub ffq_check ($;$$) {
1554     # calls $ff and/or $notff zero or more times
1555     # then returns either (status,message) where status is
1556     #    exists
1557     #    detached
1558     #    weird-symref
1559     #    notbranch
1560     # or (undef,undef, $ffq_prev,$gdrlast)
1561     # $ff and $notff are called like this:
1562     #   $ff->("message for stdout\n");
1563     #   $notff->('snag-name', $message);
1564     # normally $currentval should be HEAD
1565     my ($currentval, $ff, $notff) =@_;
1566
1567     $ff //= sub { print $_[0] or die $!; };
1568     $notff //= \&snag;
1569
1570     my ($status, $message, $current, $ffq_prev, $gdrlast)
1571         = ffq_prev_branchinfo();
1572     return ($status, $message) unless $status eq 'branch';
1573
1574     my $exists = git_get_ref $ffq_prev;
1575     return ('exists',"$ffq_prev already exists") if $exists;
1576
1577     return ('not-branch', 'HEAD symref is not to refs/heads/')
1578         unless $current =~ m{^refs/heads/};
1579     my $branch = $';
1580
1581     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1582     my %checked;
1583
1584     printdebug "ffq check_specs @check_specs\n";
1585
1586     my $check = sub {
1587         my ($lrref, $desc) = @_;
1588         printdebug "ffq might check $lrref ($desc)\n";
1589         my $invert;
1590         for my $chk (@check_specs) {
1591             my $glob = $chk;
1592             $invert = $glob =~ s{^[!^]}{};
1593             last if fnmatch $glob, $lrref;
1594         }
1595         return if $invert;
1596         my $lrval = git_get_ref $lrref;
1597         return unless length $lrval;
1598
1599         if (is_fast_fwd $lrval, $currentval) {
1600             $ff->("OK, you are ahead of $lrref\n");
1601             $checked{$lrref} = 1;
1602         } elsif (is_fast_fwd $currentval, $lrval) {
1603             $checked{$lrref} = -1;
1604             $notff->('behind', "you are behind $lrref, divergence risk");
1605         } else {
1606             $checked{$lrref} = -1;
1607             $notff->('diverged', "you have diverged from $lrref");
1608         }
1609     };
1610
1611     my $merge = cfg "branch.$branch.merge",1;
1612     if (defined $merge and $merge =~ m{^refs/heads/}) {
1613         my $rhs = $';
1614         printdebug "ffq merge $rhs\n";
1615         my $check_remote = sub {
1616             my ($remote, $desc) = @_;
1617             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1618             return unless defined $remote;
1619             $check->("refs/remotes/$remote/$rhs", $desc);
1620         };
1621         $check_remote->((scalar cfg "branch.$branch.remote",1),
1622                         'remote fetch/merge branch');
1623         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1624                         (scalar cfg "branch.$branch.pushDefault",1),
1625                         'remote push branch');
1626     }
1627     if ($branch =~ m{^dgit/}) {
1628         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1629     } elsif ($branch =~ m{^master$}) {
1630         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1631     }
1632     return (undef, undef, $ffq_prev, $gdrlast);
1633 }
1634
1635 sub record_ffq_prev_deferred () {
1636     # => ('status', "message")
1637     # 'status' may be
1638     #    deferred          message is undef
1639     #    exists
1640     #    detached
1641     #    weird-symref
1642     #    notbranch
1643     # if not ff from some branch we should be ff from, is an snag
1644     # if "deferred", will have added something about that to
1645     #   @deferred_update_messages, and also maybe printed (already)
1646     #   some messages about ff checks
1647     bail_if_rebasing();
1648     my $currentval = get_head();
1649
1650     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1651     return ($status,$message) if defined $status;
1652
1653     snags_maybe_bail();
1654
1655     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1656     push @deferred_updates, "delete $gdrlast";
1657     push @deferred_update_messages, "Recorded previous head for preservation";
1658     return ('deferred', undef);
1659 }
1660
1661 sub record_ffq_auto () {
1662     my ($status, $message) = record_ffq_prev_deferred();
1663     if ($status eq 'deferred' || $status eq 'exists') {
1664     } else {
1665         snag $status, "could not record ffq-prev: $message";
1666         snags_maybe_bail();
1667     }
1668 }
1669
1670 sub ffq_prev_info () {
1671     bail_if_rebasing();
1672     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1673     my ($status, $message, $current, $ffq_prev, $gdrlast)
1674         = ffq_prev_branchinfo();
1675     if ($status ne 'branch') {
1676         snag $status, "could not check ffq-prev: $message";
1677         snags_maybe_bail();
1678     }
1679     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1680     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1681 }
1682
1683 sub stitch ($$$$$) {
1684     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1685
1686     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1687
1688     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1689         my $differs = get_differs $old_head, $ffq_prev_commitish;
1690         unless ($differs & ~D_PAT_ADD) {
1691             # ffq-prev is ahead of us, and the only tree changes it has
1692             # are possibly addition of things in debian/patches/.
1693             # Just wind forwards rather than making a pointless pseudomerge.
1694             push @deferred_updates,
1695                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1696             update_head_checkout $old_head, $ffq_prev_commitish,
1697                 "stitch (fast forward)";
1698             return;
1699         }
1700     }
1701     fresh_workarea();
1702     # We make pseudomerges with L as the contributing parent.
1703     # This makes git rev-list --first-parent work properly.
1704     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1705         'Declare fast forward / record previous work',
1706         "[git-debrebase pseudomerge: $prose]",
1707     ];
1708     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1709     update_head $old_head, $new_head, "stitch: $prose";
1710 }
1711
1712 sub do_stitch ($;$) {
1713     my ($prose, $unclean) = @_;
1714
1715     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1716     if (!$ffq_prev_commitish) {
1717         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1718         return;
1719     }
1720     my $dangling_head = get_head();
1721
1722     keycommits $dangling_head, $unclean,$unclean,$unclean;
1723     snags_maybe_bail();
1724
1725     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1726 }
1727
1728 sub upstream_commitish_search ($$) {
1729     my ($upstream_version, $tried) = @_;
1730     # todo: at some point maybe use git-deborig to do this
1731     foreach my $tagpfx ('', 'v', 'upstream/') {
1732         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1733         my $new_upstream = git_get_ref "refs/tags/$tag";
1734         push @$tried, $tag;
1735         return $new_upstream if length $new_upstream;
1736     }
1737 }
1738
1739 sub resolve_upstream_version ($$) {
1740     my ($new_upstream, $upstream_version) = @_;
1741
1742     if (!defined $new_upstream) {
1743         my @tried;
1744         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1745         if (!length $new_upstream) {
1746             fail "Could not determine appropriate upstream commitish.\n".
1747                 " (Tried these tags: @tried)\n".
1748                 " Check version, and specify upstream commitish explicitly.";
1749         }
1750     }
1751     $new_upstream = git_rev_parse $new_upstream;
1752
1753     return $new_upstream;
1754 }
1755
1756 sub cmd_new_upstream () {
1757     # automatically and unconditionally launders before rebasing
1758     # if rebase --abort is used, laundering has still been done
1759
1760     my %pieces;
1761
1762     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1763
1764     # parse args - low commitment
1765     my $spec_version = shift @ARGV;
1766     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1767     fail "bad version number \`$spec_version'" unless defined $new_version;
1768     if ($new_version->is_native()) {
1769         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1770     }
1771
1772     my $new_upstream = shift @ARGV;
1773     my $new_upstream_version = upstreamversion  $new_version;
1774     $new_upstream =
1775         resolve_upstream_version $new_upstream, $new_upstream_version;
1776
1777     record_ffq_auto();
1778
1779     my $piece = sub {
1780         my ($n, @x) = @_; # may be ''
1781         my $pc = $pieces{$n} //= {
1782             Name => $n,
1783             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1784         };
1785         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1786         $pc;
1787     };
1788
1789     my @newpieces;
1790     my $newpiece = sub {
1791         my ($n, @x) = @_; # may be ''
1792         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1793         push @newpieces, $pc;
1794     };
1795
1796     $newpiece->('',
1797         OldIx => 0,
1798         New => $new_upstream,
1799     );
1800     while (@ARGV && $ARGV[0] !~ m{^-}) {
1801         my $n = shift @ARGV;
1802
1803         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1804             unless @ARGV && $ARGV[0] !~ m{^-};
1805
1806         my $c = git_rev_parse shift @ARGV;
1807         die unless $n =~ m/^$extra_orig_namepart_re$/;
1808         $newpiece->($n, New => $c);
1809     }
1810
1811     # now we need to investigate the branch this generates the
1812     # laundered version but we don't switch to it yet
1813     my $old_head = get_head();
1814     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1815
1816     my $old_bw_cl = classify $old_bw;
1817     my $old_anchor_cl = classify $old_anchor;
1818     my $old_upstream;
1819     if (!$old_anchor_cl->{OrigParents}) {
1820         snag 'anchor-treated',
1821             'old anchor is recognised due to --anchor, cannot check upstream';
1822     } else {
1823         $old_upstream = parsecommit
1824             $old_anchor_cl->{OrigParents}[0]{CommitId};
1825         $piece->('', Old => $old_upstream->{CommitId});
1826     }
1827
1828     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1829         if ($old_upstream->{Msg} =~
1830  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1831            ) {
1832             my @oldpieces = (split / /, $1);
1833             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1834             if ($old_n_parents != @oldpieces &&
1835                 $old_n_parents != @oldpieces + 1) {
1836                 snag 'upstream-confusing', sprintf
1837                     "previous upstream combine %s".
1838                     " mentions %d pieces (each implying one parent)".
1839                     " but has %d parents".
1840                     " (one per piece plus maybe a previous combine)",
1841                     $old_upstream->{CommitId},
1842                     (scalar @oldpieces),
1843                     $old_n_parents;
1844             } elsif ($oldpieces[0] ne '.') {
1845                 snag 'upstream-confusing', sprintf
1846                     "previous upstream combine %s".
1847                     " first piece is not \`.'",
1848                     $oldpieces[0];
1849             } else {
1850                 $oldpieces[0] = '';
1851                 foreach my $i (0..$#oldpieces) {
1852                     my $n = $oldpieces[$i];
1853                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1854                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1855                 }
1856             }
1857         } else {
1858             snag 'upstream-confusing',
1859                 "previous upstream $old_upstream->{CommitId} is from".
1860                " git-debrebase but not an \`upstream-combine' commit";
1861         }
1862     }
1863
1864     foreach my $pc (values %pieces) {
1865         if (!$old_upstream) {
1866             # we have complained already
1867         } elsif (!$pc->{Old}) {
1868             snag 'upstream-new-piece',
1869                 "introducing upstream piece \`$pc->{Name}'";
1870         } elsif (!$pc->{New}) {
1871             snag 'upstream-rm-piece',
1872                 "dropping upstream piece \`$pc->{Name}'";
1873         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1874             snag 'upstream-not-ff',
1875                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1876         }
1877     }
1878
1879     printdebug "%pieces = ", (dd \%pieces), "\n";
1880     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1881
1882     snags_maybe_bail();
1883
1884     my $new_bw;
1885
1886     fresh_workarea();
1887     in_workarea sub {
1888         my @upstream_merge_parents;
1889
1890         if (!any_snags()) {
1891             push @upstream_merge_parents, $old_upstream->{CommitId};
1892         }
1893
1894         foreach my $pc (@newpieces) { # always has '' first
1895             if ($pc->{Name}) {
1896                 read_tree_subdir $pc->{Name}, $pc->{New};
1897             } else {
1898                 runcmd @git, qw(read-tree), $pc->{New};
1899             }
1900             push @upstream_merge_parents, $pc->{New};
1901         }
1902
1903         # index now contains the new upstream
1904
1905         if (@newpieces > 1) {
1906             # need to make the upstream subtree merge commit
1907             $new_upstream = make_commit \@upstream_merge_parents,
1908                 [ "Combine upstreams for $new_upstream_version",
1909  ("[git-debrebase upstream-combine . ".
1910  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1911  ": new upstream]"),
1912                 ];
1913         }
1914
1915         # $new_upstream is either the single upstream commit, or the
1916         # combined commit we just made.  Either way it will be the
1917         # "upstream" parent of the anchor merge.
1918
1919         read_tree_subdir 'debian', "$old_bw:debian";
1920
1921         # index now contains the anchor merge contents
1922         $new_bw = make_commit [ $old_bw, $new_upstream ],
1923             [ "Update to upstream $new_upstream_version",
1924  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1925             ];
1926
1927         my $clogsignoff = cmdoutput qw(git show),
1928             '--pretty=format:%an <%ae>  %aD',
1929             $new_bw;
1930
1931         # Now we have to add a changelog stanza so the Debian version
1932         # is right.
1933         die if unlink "debian";
1934         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1935         unlink "debian/changelog" or $!==ENOENT or die $!;
1936         mkdir "debian" or die $!;
1937         open CN, ">", "debian/changelog" or die $!;
1938         my $oldclog = git_cat_file ":debian/changelog";
1939         $oldclog =~ m/^($package_re) \(\S+\) / or
1940             fail "cannot parse old changelog to get package name";
1941         my $p = $1;
1942         print CN <<END, $oldclog or die $!;
1943 $p ($new_version) UNRELEASED; urgency=medium
1944
1945   * Update to new upstream version $new_upstream_version.
1946
1947  -- $clogsignoff
1948
1949 END
1950         close CN or die $!;
1951         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1952
1953         # Now we have the final new breakwater branch in the index
1954         $new_bw = make_commit [ $new_bw ],
1955             [ "Update changelog for new upstream $new_upstream_version",
1956               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1957             ];
1958     };
1959
1960     # we have constructed the new breakwater. we now need to commit to
1961     # the laundering output, because git-rebase can't easily be made
1962     # to make a replay list which is based on some other branch
1963
1964     update_head_postlaunder $old_head, $old_laundered_tip,
1965         'launder for new upstream';
1966
1967     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1968     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1969         "debrebase new-upstream $new_version: rebase";
1970     runcmd @cmd;
1971     # now it's for the user to sort out
1972 }
1973
1974 sub cmd_record_ffq_prev () {
1975     badusage "no arguments allowed" if @ARGV;
1976     my ($status, $msg) = record_ffq_prev_deferred();
1977     if ($status eq 'exists' && $opt_noop_ok) {
1978         print "Previous head already recorded\n" or die $!;
1979     } elsif ($status eq 'deferred') {
1980         run_deferred_updates 'record-ffq-prev';
1981     } else {
1982         fail "Could not preserve: $msg";
1983     }
1984 }
1985
1986 sub cmd_anchor () {
1987     badusage "no arguments allowed" if @ARGV;
1988     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1989     print "$bw\n" or die $!;
1990 }
1991
1992 sub cmd_breakwater () {
1993     badusage "no arguments allowed" if @ARGV;
1994     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1995     print "$bw\n" or die $!;
1996 }
1997
1998 sub cmd_status () {
1999     badusage "no arguments allowed" if @ARGV;
2000
2001     # todo: gdr status should print divergence info
2002     # todo: gdr status should print upstream component(s) info
2003     # todo: gdr should leave/maintain some refs with this kind of info ?
2004
2005     my $oldest = { Badness => 0 };
2006     my $newest;
2007     my $note = sub {
2008         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2009         if ($oldest->{Badness} < $badness) {
2010             $oldest = $newest = undef;
2011         }
2012         $oldest = {
2013                    Badness => $badness,
2014                    CommitId => $cl->{CommitId},
2015                    OurMsg => $ourmsg,
2016                    KcMsg => $kcmsg,
2017                   };
2018         $newest //= $oldest;
2019     };
2020     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2021         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2022         sub { $note->(2, 'branch is unlaundered', @_); },
2023         sub { $note->(3, 'branch needs laundering', @_); },
2024         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2025
2026     my $prcommitinfo = sub {
2027         my ($cid) = @_;
2028         flush STDOUT or die $!;
2029         runcmd @git, qw(--no-pager log -n1),
2030             '--pretty=format:    %h %s%n',
2031             $cid;
2032     };
2033
2034     print "current branch contents, in git-debrebase terms:\n";
2035     if (!$oldest->{Badness}) {
2036         print "  branch is laundered\n";
2037     } else {
2038         print "  $oldest->{OurMsg}\n";
2039         my $printed = '';
2040         foreach my $info ($oldest, $newest) {
2041             my $cid = $info->{CommitId};
2042             next if $cid eq $printed;
2043             $printed = $cid;
2044             print "  $info->{KcMsg}\n";
2045             $prcommitinfo->($cid);
2046         }
2047     }
2048
2049     my $prab = sub {
2050         my ($cid, $what) = @_;
2051         if (!defined $cid) {
2052             print "  $what is not well-defined\n";
2053         } else {
2054             print "  $what\n";
2055             $prcommitinfo->($cid);
2056         }
2057     };
2058     print "key git-debrebase commits:\n";
2059     $prab->($anchor, 'anchor');
2060     $prab->($bw, 'breakwater');
2061
2062     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2063         ffq_prev_branchinfo();
2064
2065     print "branch and ref status, in git-debrebase terms:\n";
2066     if ($ffq_msg) {
2067         print "  $ffq_msg\n";
2068     } else {
2069         $ffq_prev = git_get_ref $ffq_prev;
2070         $gdrlast = git_get_ref $gdrlast;
2071         if ($ffq_prev) {
2072             print "  unstitched; previous tip was:\n";
2073             $prcommitinfo->($ffq_prev);
2074         } elsif (!$gdrlast) {
2075             print "  stitched? (no record of git-debrebase work)\n";
2076         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2077             print "  stitched\n";
2078         } else {
2079             print "  not git-debrebase (diverged since last stitch)\n"
2080         }
2081     }
2082     print "you are currently rebasing\n" if currently_rebasing();
2083 }
2084
2085 sub cmd_stitch () {
2086     my $prose = 'stitch';
2087     getoptions("stitch",
2088                'prose=s', \$prose);
2089     badusage "no arguments allowed" if @ARGV;
2090     do_stitch $prose, 0;
2091 }
2092 sub cmd_prepush () { cmd_stitch(); }
2093
2094 sub cmd_quick () {
2095     badusage "no arguments allowed" if @ARGV;
2096     do_launder_head 'launder for git-debrebase quick';
2097     do_stitch 'quick';
2098 }
2099
2100 sub cmd_conclude () {
2101     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2102     if (!$ffq_prev_commitish) {
2103         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2104         return;
2105     }
2106     my $dangling_head = get_head();
2107
2108     badusage "no arguments allowed" if @ARGV;
2109     do_launder_head 'launder for git-debrebase quick';
2110     do_stitch 'quick';
2111 }
2112
2113 sub cmd_scrap () {
2114     if (currently_rebasing()) {
2115         runcmd @git, qw(rebase --abort);
2116     }
2117     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2118     if (!$ffq_prev_commitish) {
2119         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2120         finish 0;
2121     }
2122     my $scrapping_head = get_head();
2123     badusage "no arguments allowed" if @ARGV;
2124     push @deferred_updates,
2125         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2126         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2127     snags_maybe_bail();
2128     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2129 }
2130
2131 sub make_patches_staged ($) {
2132     my ($head) = @_;
2133     # Produces the patches that would result from $head if it were
2134     # laundered.
2135     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2136     fresh_workarea();
2137     in_workarea sub {
2138         gbp_pq_export 'bw', $secret_bw, $secret_head;
2139     };
2140 }
2141
2142 sub make_patches ($) {
2143     my ($head) = @_;
2144     keycommits $head, 0, \&snag;
2145     make_patches_staged $head;
2146     my $out;
2147     in_workarea sub {
2148         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2149         runcmd @git, qw(read-tree), $head;
2150         read_tree_subdir 'debian/patches', $ptree;
2151         $out = make_commit [$head], [
2152             'Commit patch queue (exported by git-debrebase)',
2153             '[git-debrebase: export and commit patches]',
2154         ];
2155     };
2156     return $out;
2157 }
2158
2159 sub cmd_make_patches () {
2160     my $opt_quiet_would_amend;
2161     getoptions("make-patches",
2162                'quiet-would-amend!', \$opt_quiet_would_amend);
2163     badusage "no arguments allowed" if @ARGV;
2164     bail_if_rebasing();
2165     my $old_head = get_head();
2166     my $new = make_patches $old_head;
2167     my $d = get_differs $old_head, $new;
2168     if ($d == 0) {
2169         fail "No (more) patches to export." unless $opt_noop_ok;
2170         return;
2171     } elsif ($d == D_PAT_ADD) {
2172         snags_maybe_bail();
2173         update_head_checkout $old_head, $new, 'make-patches';
2174     } else {
2175         print STDERR failmsg
2176             "Patch export produced patch amendments".
2177             " (abandoned output commit $new).".
2178             "  Try laundering first."
2179             unless $opt_quiet_would_amend;
2180         finish 7;
2181     }
2182 }
2183
2184 sub cmd_convert_from_gbp () {
2185     badusage "want only 1 optional argument, the upstream git commitish"
2186         unless @ARGV<=1;
2187
2188     my $clogp = parsechangelog();
2189     my $version = $clogp->{'Version'}
2190         // die "missing Version from changelog";
2191
2192     my ($upstream_spec) = @ARGV;
2193
2194     my $upstream_version = upstreamversion $version;
2195     my $upstream =
2196         resolve_upstream_version($upstream_spec, $upstream_version);
2197
2198     my $old_head = get_head();
2199
2200     my $upsdiff = get_differs $upstream, $old_head;
2201     if ($upsdiff & D_UPS) {
2202         runcmd @git, qw(--no-pager diff --stat),
2203             $upstream, $old_head,
2204             qw( -- :!/debian :/);
2205         fail <<END;
2206 upstream ($upstream_spec) and HEAD are not
2207 identical in upstream files.  See diffstat above, or run
2208   git diff $upstream_spec HEAD -- :!/debian :/
2209 END
2210     }
2211
2212     if (!is_fast_fwd $upstream, $old_head) {
2213         snag 'upstream-not-ancestor',
2214             "upstream ($upstream) is not an ancestor of HEAD";
2215     } else {
2216         my $wrong = cmdoutput
2217             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2218              qw(-- :/ :!/debian));
2219         if (length $wrong) {
2220             snag 'unexpected-upstream-changes',
2221                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2222             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2223         }
2224     }
2225
2226     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2227         snag 'upstream-has-debian',
2228             "upstream ($upstream) contains debian/ directory";
2229     }
2230
2231     my $previous_dgit_view = eval {
2232         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2233         my ($lvsn, $suite);
2234         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2235             my ($stz, $desc) = @_;
2236             no warnings qw(exiting);
2237             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2238             next unless $stz->{Date};
2239             next unless $stz->{Distribution} ne 'UNRELEASED';
2240             $lvsn = $stz->{Version};
2241             $suite = $stz->{Distribution};
2242             last;
2243         };
2244         die "neither of the first two changelog entries are released\n"
2245             unless defined $lvsn;
2246         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2247         my $mtag_pat = debiantag_maintview $lvsn, '*';
2248         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2249             $mtag_pat;
2250         die "could not find suitable maintainer view tag $mtag_pat\n"
2251             unless $mtag_pat =~ m{/};
2252         is_fast_fwd $mtag, 'HEAD' or
2253             die "HEAD is not FF from maintainer tag $mtag!";
2254         my $dtag = "archive/$mtag";
2255         is_fast_fwd $mtag, $dtag or
2256             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2257         print "will stitch in dgit view, $dtag\n";
2258         git_rev_parse $dtag;
2259     };
2260     if (!$previous_dgit_view) {
2261         $@ =~ s/^\n+//;
2262         chomp $@;
2263         print STDERR "cannot stitch in dgit view: $@\n";
2264     }
2265
2266     snags_maybe_bail_early();
2267
2268     my $work;
2269
2270     fresh_workarea();
2271     in_workarea sub {
2272         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2273         # make a branch out of the patch queue - we'll want this in a mo
2274         runcmd qw(gbp pq import);
2275         # strip the patches out
2276         runcmd @git, qw(checkout -q gdr-internal~0);
2277         rm_subdir_cached 'debian/patches';
2278         $work = make_commit ['HEAD'], [
2279  'git-debrebase convert-from-gbp: drop patches from tree',
2280  'Delete debian/patches, as part of converting to git-debrebase format.',
2281  '[git-debrebase convert-from-gbp: drop patches from tree]'
2282                               ];
2283         # make the anchor merge
2284         # the tree is already exactly right
2285         $work = make_commit [$work, $upstream], [
2286  'git-debrebase import: declare upstream',
2287  'First breakwater merge.',
2288  '[git-debrebase anchor: declare upstream]'
2289                               ];
2290
2291         # rebase the patch queue onto the new breakwater
2292         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2293         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2294         $work = git_rev_parse 'HEAD';
2295
2296         if ($previous_dgit_view) {
2297             $work = make_commit [$work, $previous_dgit_view], [
2298  'git-debrebase import: declare ff from dgit archive view',
2299  '[git-debrebase pseudomerge: import-from-gbp]',
2300             ];
2301         }
2302     };
2303
2304     ffq_check $work;
2305     snags_maybe_bail();
2306     update_head_checkout $old_head, $work, 'convert-from-gbp';
2307 }
2308
2309 sub cmd_convert_to_gbp () {
2310     badusage "no arguments allowed" if @ARGV;
2311     my $head = get_head();
2312     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2313     keycommits $head, 0;
2314     my $out;
2315     make_patches_staged $head;
2316     in_workarea sub {
2317         $out = make_commit ['HEAD'], [
2318             'Commit patch queue (converted from git-debrebase format)',
2319             '[git-debrebase convert-to-gbp: commit patches]',
2320         ];
2321     };
2322     if (defined $ffq) {
2323         push @deferred_updates, "delete $ffq";
2324         push @deferred_updates, "delete $gdrlast";
2325     }
2326     snags_maybe_bail();
2327     update_head_checkout $head, $out, "convert to gbp (v0)";
2328     print <<END or die $!;
2329 git-debrebase: converted to git-buildpackage branch format
2330 git-debrebase: WARNING: do not now run "git-debrebase" any more
2331 git-debrebase: WARNING: doing so would drop all upstream patches!
2332 END
2333 }
2334
2335 sub cmd_convert_from_dgit_view () {
2336     my $clogp = parsechangelog();
2337
2338     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2339     my $do_origs = 1;
2340     my $do_tags = 1;
2341     my $always = 0;
2342     my $diagnose = 0;
2343
2344     getoptions("convert-from-dgit-view",
2345                'diagnose!', \$diagnose,
2346                'build-products-dir:s', \$bpd,
2347                'origs!', \$do_origs,
2348                'tags!', \$do_tags,
2349                'always-convert-anyway!', \$always);
2350     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2351
2352     my @upstreams;
2353
2354     if (@ARGV) {
2355         my $spec = shift @ARGV;
2356         my $commit = git_rev_parse "$spec^{commit}";
2357         push @upstreams, { Commit => $commit,
2358                            Source => "$ARGV[0], from command line",
2359                            Only => 1,
2360                          };
2361     }
2362
2363     my $head = get_head();
2364
2365     if (!$always) {
2366         my $troubles = 0;
2367         my $trouble = sub { $troubles++; };
2368         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2369         printdebug "troubles=$troubles\n";
2370         if (!$troubles) {
2371             print STDERR <<END;
2372 $us: Branch already seems to be in git-debrebase format!
2373 $us: --always-convert-anyway would do the conversion operation anyway
2374 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2375 END
2376             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2377             finish 0;
2378         }
2379     }
2380
2381     snags_maybe_bail_early();
2382
2383     my $version = upstreamversion $clogp->{Version};
2384     print STDERR "Considering possible commits corresponding to upstream:\n";
2385
2386     if (!@upstreams) {
2387         if ($do_tags) {
2388             my @tried;
2389             my $ups_tag = upstream_commitish_search $version, \@tried;
2390             if ($ups_tag) {
2391                 my $this = "git tag $tried[-1]";
2392                 push @upstreams, { Commit => $ups_tag,
2393                                    Source => $this,
2394                                  };
2395             } else {
2396                 printf STDERR
2397                     " git tag: no suitable tag found (tried %s)\n",
2398                     "@tried";
2399             }
2400         }
2401         if ($do_origs) {
2402             my $p = $clogp->{'Source'};
2403             # we do a quick check to see if there are plausible origs
2404             my $something=0;
2405             if (!opendir BPD, $bpd) {
2406                 die "$bpd: opendir: $!" unless $!==ENOENT;
2407             } else {
2408                 while ($!=0, my $f = readdir BPD) {
2409                     next unless is_orig_file_of_p_v $f, $p, $version;
2410                     printf STDERR
2411                         " orig: found what looks like a .orig, %s\n",
2412                         "$bpd/$f";
2413                     $something=1;
2414                     last;
2415                 }
2416                 die "read $bpd: $!" if $!;
2417                 closedir BPD;
2418             }
2419             if ($something) {
2420                 my $tree = cmdoutput
2421                     @dgit, qw(--build-products-dir), $bpd,
2422                     qw(print-unapplied-treeish);
2423                 fresh_workarea();
2424                 in_workarea sub {
2425                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2426                     rm_subdir_cached 'debian';
2427                     $tree = cmdoutput @git, qw(write-tree);
2428                     my $ups_synth = make_commit [], [ <<END, <<END,
2429 Import effective orig tree for upstream version $version
2430 END
2431 This includes the contents of the .orig(s), minus any debian/ directory.
2432
2433 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2434 END
2435                                                     ];
2436                     push @upstreams, { Commit => $ups_synth,
2437                                        Source => "orig(s) imported via dgit",
2438                                      };
2439                 }
2440             } else {
2441                 printf STDERR
2442                     " orig: no suitable origs found (looked for %s in %s)\n",
2443                     "${p}_".(stripeoch $version)."...", $bpd;
2444             }
2445         }
2446     }
2447
2448     my $some_patches = stat_exists 'debian/patches/series';
2449
2450     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2451
2452     my $result;
2453     foreach my $u (@upstreams) {
2454         my $work = $head;
2455         fresh_workarea();
2456         in_workarea sub {
2457             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2458             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2459             runcmd @git, qw(clean -xdff);
2460             runcmd @git, qw(checkout), $head, qw(-- debian);
2461             if ($some_patches) {
2462                 rm_subdir_cached 'debian/patches';
2463                 $work = make_commit [ $work ], [
2464  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2465  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2466  "to git-debrebase format.  Upstream changes will appear as commits.",
2467  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2468                                            ];
2469             }
2470             $work = make_commit [ $work, $u->{Commit} ], [
2471  'git-debrebase convert-from-dgit-view: declare upstream',
2472  '(Re)constructed breakwater merge.',
2473  '[git-debrebase anchor: declare upstream]'
2474                                                          ];
2475             runcmd @git, qw(checkout --quiet -b mk), $work;
2476             if ($some_patches) {
2477                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2478                 runcmd @git, qw(reset --quiet);
2479                 my @gbp_cmd = (qw(gbp pq import));
2480                 if (!$diagnose) {
2481                     my $gbp_err = "../gbp-pq-err";
2482                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2483                 }
2484                 my $r = system @gbp_cmd;
2485                 if ($r) {
2486                     printf STDERR
2487                         " %s: couldn't apply patches: gbp pq %s",
2488                         $u->{Source}, waitstatusmsg();
2489                     return;
2490                 }
2491             }
2492             my $work = git_rev_parse qw(HEAD);
2493             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2494             if (length $diffout) {
2495                 print STDERR
2496                     " $u->{Source}: applying patches gives different tree\n";
2497                 print STDERR $diffout if $diagnose;
2498                 return;
2499             }
2500             # OMG!
2501             $u->{Result} = $work;
2502             $result = $u;
2503         };
2504         last if $result;
2505     }
2506
2507     if (!$result) {
2508         fail <<END;
2509 Could not find or construct a suitable upstream commit.
2510 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2511 upstream commmit explicitly or provide suitable origs.
2512 END
2513     }
2514
2515     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2516
2517     ffq_check $result->{Result};
2518     snags_maybe_bail();
2519     update_head_checkout $head, $result->{Result},
2520         'convert-from-dgit-view';
2521 }
2522
2523 sub cmd_downstream_rebase_launder_v0 () {
2524     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2525     my ($base) = @ARGV;
2526     $base = git_rev_parse $base;
2527     my $old_head = get_head();
2528     my $current = $old_head;
2529     my $topmost_keep;
2530     for (;;) {
2531         if ($current eq $base) {
2532             $topmost_keep //= $current;
2533             print " $current BASE stop\n";
2534             last;
2535         }
2536         my $cl = classify $current;
2537         print " $current $cl->{Type}";
2538         my $keep = 0;
2539         my $p0 = $cl->{Parents}[0]{CommitId};
2540         my $next;
2541         if ($cl->{Type} eq 'Pseudomerge') {
2542             print " ^".($cl->{Contributor}{Ix}+1);
2543             $next = $cl->{Contributor}{CommitId};
2544         } elsif ($cl->{Type} eq 'AddPatches' or
2545                  $cl->{Type} eq 'Changelog') {
2546             print " strip";
2547             $next = $p0;
2548         } else {
2549             print " keep";
2550             $next = $p0;
2551             $keep = 1;
2552         }
2553         print "\n";
2554         if ($keep) {
2555             $topmost_keep //= $current;
2556         } else {
2557             die "to-be stripped changes not on top of the branch\n"
2558                 if $topmost_keep;
2559         }
2560         $current = $next;
2561     }
2562     if ($topmost_keep eq $old_head) {
2563         print "unchanged\n";
2564     } else {
2565         print "updating to $topmost_keep\n";
2566         update_head_checkout
2567             $old_head, $topmost_keep,
2568             'downstream-rebase-launder-v0';
2569     }
2570 }
2571
2572 getoptions_main
2573           ("bad options\n",
2574            "D+" => \$debuglevel,
2575            'noop-ok', => \$opt_noop_ok,
2576            'f=s' => \@snag_force_opts,
2577            'anchor=s' => \@opt_anchors,
2578            '--dgit=s' => \($dgit[0]),
2579            'force!',
2580            '-i:s' => sub {
2581                my ($opt,$val) = @_;
2582                badusage "git-debrebase: no cuddling to -i for git-rebase"
2583                    if length $val;
2584                die if $opt_defaultcmd_interactive; # should not happen
2585                $opt_defaultcmd_interactive = [ qw(-i) ];
2586                # This access to @ARGV is excessive familiarity with
2587                # Getopt::Long, but there isn't another sensible
2588                # approach.  '-i=s{0,}' does not work with bundling.
2589                push @$opt_defaultcmd_interactive, @ARGV;
2590                @ARGV=();
2591            },
2592            'help' => sub { print $usage_message or die $!; finish 0; },
2593            );
2594
2595 initdebug('git-debrebase ');
2596 enabledebug if $debuglevel;
2597
2598 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2599 chdir $toplevel or die "chdir $toplevel: $!";
2600
2601 $rd = fresh_playground "$playprefix/misc";
2602
2603 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2604
2605 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2606     defaultcmd_rebase();
2607 } else {
2608     my $cmd = shift @ARGV;
2609     my $cmdfn = $cmd;
2610     $cmdfn =~ y/-/_/;
2611     $cmdfn = ${*::}{"cmd_$cmdfn"};
2612
2613     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2614     $cmdfn->();
2615 }
2616
2617 finish 0;