git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$) {
 267     my ($treeish, $keep_patches) = @_;
 268     my $save = cmdoutput @git, qw(write-tree --prefix=debian/);
 269     runcmd @git, qw(read-tree), $treeish;
 270     read_tree_subdir 'debian', $save;
 271     rm_subdir_cached 'debian/patches' unless $keep_patches;
 272 };
 273
 274 sub make_commit ($$) {
 275     my ($parents, $message_paras) = @_;
 276     my $tree = cmdoutput @git, qw(write-tree);
 277     my @cmd = (@git, qw(commit-tree), $tree);
 278     push @cmd, qw(-p), $_ foreach @$parents;
 279     push @cmd, qw(-m), $_ foreach @$message_paras;
 280     return cmdoutput @cmd;
 281 }
 282
 283 our @snag_force_opts;
 284 sub snag ($$;@) {
 285     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 286     if (grep { $_ eq $tag } @snag_force_opts) {
 287         $snags_forced++;
 288         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 289     } else {
 290         $snags_tripped++;
 291         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 292     }
 293 }
 294
 295 # Important: all mainline code must call snags_maybe_bail after
 296 # any point where snag might be called, but before making changes
 297 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 298 # may be called more than once if necessary (but this is not ideal
 299 # because then the messages about number of snags may be confusing).
 300 sub snags_maybe_bail () {
 301     return if all_snags_summarised();
 302     if ($snags_forced) {
 303         printf STDERR
 304             "%s: snags: %d overriden by individual -f options\n",
 305             $us, $snags_forced;
 306     }
 307     if ($snags_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: snags: %d overriden by global --force\n",
 311                 $us, $snags_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 315                 $us, $snags_tripped;
 316         }
 317     }
 318     $snags_summarised = $snags_forced + $snags_tripped;
 319 }
 320 sub snags_maybe_bail_early () {
 321     # useful to bail out early without doing a lot of work;
 322     # not a substitute for snags_maybe_bail.
 323     snags_maybe_bail() if $snags_tripped && !$opt_force;
 324 }
 325 sub any_snags () {
 326     return $snags_forced || $snags_tripped;
 327 }
 328
 329 sub gbp_pq_export ($$$) {
 330     my ($bname, $base, $tip) = @_;
 331     # must be run in a workarea.  $bname and patch-queue/$bname
 332     # ought not to exist.  Leaves you on patch-queue/$bname with
 333     # the patches staged but not committed.
 334     printdebug "gbp_pq_export $bname $base $tip\n";
 335     runcmd @git, qw(checkout -q -b), $bname, $base;
 336     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 337     my @gbp_cmd = (qw(gbp pq export));
 338     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 339     if ($r) {
 340         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 341         failedcmd @gbp_cmd;
 342     }
 343     runcmd @git, qw(add -f debian/patches);
 344 }
 345
 346
 347 # xxx allow merge resolution separately from laundering, before git merge
 348 #
 349 # xxx general gdr docs highlight forbidden things
 350 # xxx general gdr docs list allowable things ?
 351 # xxx general gdr docs explicitly forbid some rebase
 352 #
 353 # xxx provide a way for the user to help
 354 # xxx (eg, provide wreckage provide way to continue)
 355
 356 # later/rework?
 357 #  use git-format-patch?
 358 #  our own patch identification algorithm?
 359 #  this is an alternative strategy
 360
 361 sub merge_series ($$;@) {
 362     my ($newbase, $base_q, @input_qs) = @_;
 363     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 364     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 365     # ^ specifies several patch series (currently we only support exactly 2)
 366     # return value is a commit which is the result of
 367     # merging the two versions of the same topic branch
 368     #   $input_q[0] and $input_q[1]
 369     # with respect to the old version
 370     #   $base_q
 371     # all onto $newbase.
 372
 373     # Creates, in *_q, a key MR for its private use
 374
 375     printdebug "merge_series newbase=$newbase\n";
 376
 377     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 378     $base_q->{MR}{S} = 'base';
 379
 380     my %prereq;
 381     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 382     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 383     # $prereq{<patch filename>}               exists or not (even later)
 384
 385     my $result;
 386
 387     local $workarea = fresh_playground "$playprefix/merge";
 388     my $seriesfile = "debian/patches/series";
 389     in_workarea sub {
 390         playtree_setup();
 391         foreach my $q ($base_q, reverse @input_qs) {
 392             my $s = $q->{MR}{S};
 393             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 394             if (open S, $seriesfile) {
 395                 my @earlier;
 396                 while (my $patch = <S>) {
 397                     chomp $patch or die $!;
 398                     $prereq{$patch} //= {};
 399                     foreach my $earlier (@earlier) {
 400                         $prereq{$patch}{$earlier}{$s}++ and die;
 401                     }
 402                     push @earlier, $patch;
 403                     stat "debian/patches/$patch" or die "$patch ?";
 404                 }
 405                 S->error and die "$seriesfile $!";
 406                 close S;
 407             } else {
 408                 die "$seriesfile $!" unless $!==ENOENT;
 409             }
 410             read_tree_upstream $newbase, 1;
 411             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 412                 "Convert $s to patch queue for merging",
 413                 "[git-debrebase merge-innards patch-queue import:".
 414                 " $q->{SeriesTip}]"
 415             ];
 416             printdebug "merge_series  pec $pec ";
 417             runcmd @git, qw(rm -q --cached), $seriesfile;
 418             $pec = make_commit [ $pec ], [
 419                 "Drop series file from $s to avoid merge trouble",
 420                 "[git-debrebase merge-innards patch-queue prep:".
 421                 " $q->{SeriesTip}]"
 422             ];
 423             printdebug "pec' $pec\n";
 424             runcmd @git, qw(reset -q --hard), $pec;
 425             $q->{MR}{PEC} = $pec;
 426         }
 427         # now, because of reverse, we are on $input_q->{MR}{OQC}
 428         runcmd @git, qw(checkout -q -b merge);
 429         printdebug "merge_series merging...\n";
 430         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 431         debugcmd '+', @mergecmd;
 432         $!=0; $?=-1;
 433         if (system @mergecmd) {
 434             failedcmd @mergecmd;
 435         }
 436
 437         printdebug "merge_series merge ok, series...\n";
 438         # We need to construct a new series file
 439         # Firstly, resolve prereq
 440         foreach my $f (sort keys %prereq) {
 441             printdebug "merge_series  patch\t$f\t";
 442             if (!stat_exists "debian/patches/$f") {
 443                 print DEBUG " drop\n" if $debuglevel;
 444                 # git merge deleted it; that's how we tell it's not wanted
 445                 delete $prereq{$f};
 446                 next;
 447             }
 448             print DEBUG " keep\n" if $debuglevel;
 449             foreach my $g (sort keys %{ $prereq{$f} }) {
 450                 my $gfp = $prereq{$f}{$g};
 451                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 452                 if (!!$gfp->{0} == !!$gfp->{1}
 453                     ? $gfp->{0}
 454                     : !$gfp->{base}) {
 455                     print DEBUG "\tkeep\n" if $debuglevel;
 456                 } else {
 457                     print DEBUG "\tdrop\n" if $debuglevel;
 458                     delete $prereq{$f}{$g};
 459                 }
 460             }
 461         }
 462
 463         my $unsat = sub {
 464             my ($f) = @_;
 465             return scalar keys %{ $prereq{$f} };
 466         };
 467
 468         my $nodate = time + 1;
 469         my %authordate;
 470         # $authordate{<patch filename>};
 471         my $authordate = sub {
 472             my ($f) = @_;
 473             $authordate{$f} //= do {
 474                 open PF, "<", "debian/patches/$f" or die "$f $!";
 475                 while (<PF>) {
 476                     return $nodate if m/^$/;
 477                     last if s{^Date: }{};
 478                 }
 479                 chomp;
 480                 return cmdoutput qw(date +%s -d), $_;
 481             };
 482         };
 483
 484         open NS, '>', $seriesfile or die $!;
 485
 486         while (keys %prereq) {
 487             my $best;
 488             foreach my $try (sort keys %prereq) {
 489                 if ($best) {
 490                     next if (
 491                              $unsat->($try) <=> $unsat->($best) or
 492                              $authordate->($try) <=> $authordate->($best) or
 493                              $try cmp $best
 494                             ) >= 0;
 495                 }
 496                 $best = $try;
 497             }
 498             printdebug "merge_series series next $best\n";
 499             print NS "$best\n" or die $!;
 500             delete $prereq{$best};
 501             foreach my $gp (values %prereq) {
 502                 delete $gp->{$best};
 503             }
 504         }
 505
 506         runcmd @git, qw(add), $seriesfile;
 507         runcmd @git, qw(commit --quiet -m), 'Merged series';
 508
 509         printdebug "merge_series series gbp pq import\n";
 510         runcmd qw(gbp pq import);
 511
 512         # OK now we are on patch-queue/merge, and we need to rebase
 513         # onto the intended parent and drop the patches from each one
 514
 515         printdebug "merge_series series ok, building...\n";
 516         my $build = $newbase;
 517         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 518         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 519             my $commit = git_cat_file $c, 'commit';
 520             printdebug "merge_series series ok, building $c\n";
 521             read_tree_upstream $c;
 522             my $tree = cmdoutput @git, qw(write-tree);
 523             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 524             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 525             open C, ">", "../mcommit" or die $!;
 526             print C $commit or die $!;
 527             close C or die $!;
 528             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 529         }
 530         $result = $build;
 531         runcmd @git, qw(update-ref refs/heads/result), $result;
 532     };
 533     printdebug "merge_series returns $result\n";
 534     return $result;
 535 }
 536
 537 # classify returns an info hash like this
 538 #   CommitId => $objid
 539 #   Hdr => # commit headers, including 1 final newline
 540 #   Msg => # commit message (so one newline is dropped)
 541 #   Tree => $treeobjid
 542 #   Type => (see below)
 543 #   Parents = [ {
 544 #       Ix => $index # ie 0, 1, 2, ...
 545 #       CommitId
 546 #       Differs => return value from get_differs
 547 #       IsOrigin
 548 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 549 #     } ...]
 550 #   NewMsg => # commit message, but with any [dgit import ...] edited
 551 #             # to say "[was: ...]"
 552 #
 553 # Types:
 554 #   Packaging
 555 #   Changelog
 556 #   Upstream
 557 #   AddPatches
 558 #   Mixed
 559 #
 560 #   Pseudomerge
 561 #     has additional entres in classification result
 562 #       Overwritten = [ subset of Parents ]
 563 #       Contributor = $the_remaining_Parent
 564 #
 565 #   DgitImportUnpatched
 566 #     has additional entry in classification result
 567 #       OrigParents = [ subset of Parents ]
 568 #
 569 #   Anchor
 570 #     has additional entry in classification result
 571 #       OrigParents = [ subset of Parents ]  # singleton list
 572 #
 573 #   TreatAsAnchor
 574 #
 575 #   BreakwaterStart
 576 #
 577 #   Unknown
 578 #     has additional entry in classification result
 579 #       Why => "prose"
 580
 581 sub parsecommit ($;$) {
 582     my ($objid, $p_ref) = @_;
 583     # => hash with                   CommitId Hdr Msg Tree Parents
 584     #    Parents entries have only   Ix CommitId
 585     #    $p_ref, if provided, must be [] and is used as a base for Parents
 586
 587     $p_ref //= [];
 588     die if @$p_ref;
 589
 590     my ($h,$m) = get_commit $objid;
 591
 592     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 593     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 594
 595     my $r = {
 596         CommitId => $objid,
 597         Hdr => $h,
 598         Msg => $m,
 599         Tree => $t,
 600         Parents => $p_ref,
 601     };
 602
 603     foreach my $ph (@ph) {
 604         push @$p_ref, {
 605             Ix => scalar @$p_ref,
 606             CommitId => $ph,
 607         };
 608     }
 609
 610     return $r;
 611 }
 612
 613 sub classify ($) {
 614     my ($objid) = @_;
 615
 616     my @p;
 617     my $r = parsecommit($objid, \@p);
 618     my $t = $r->{Tree};
 619
 620     foreach my $p (@p) {
 621         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 622     }
 623
 624     printdebug "classify $objid \$t=$t \@p",
 625         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 626         "\n";
 627
 628     my $classify = sub {
 629         my ($type, @rest) = @_;
 630         $r = { %$r, Type => $type, @rest };
 631         if ($debuglevel) {
 632             printdebug " = $type ".(dd $r)."\n";
 633         }
 634         return $r;
 635     };
 636     my $unknown = sub {
 637         my ($why) = @_;
 638         $r = { %$r, Type => qw(Unknown), Why => $why };
 639         printdebug " ** Unknown\n";
 640         return $r;
 641     };
 642
 643     if (grep { $_ eq $objid } @opt_anchors) {
 644         return $classify->('TreatAsAnchor');
 645     }
 646
 647     my @identical = grep { !$_->{Differs} } @p;
 648     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 649     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 650
 651     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 652         # multi-orig upstreams are represented with an anchor merge
 653         # from a single upstream commit which combines the orig tarballs
 654
 655         # Every anchor tagged this way must be a merge.
 656         # We are relying on the
 657         #     [git-debrebase anchor: ...]
 658         # commit message annotation in "declare" anchor merges (which
 659         # do not have any upstream changes), to distinguish those
 660         # anchor merges from ordinary pseudomerges (which we might
 661         # just try to strip).
 662         #
 663         # However, the user is going to be doing git-rebase a lot.  We
 664         # really don't want them to rewrite an anchor commit.
 665         # git-rebase trips up on merges, so that is a useful safety
 666         # catch.
 667         #
 668         # BreakwaterStart commits are also anchors in the terminology
 669         # of git-debrebase(5), but they are untagged (and always
 670         # manually generated).
 671         #
 672         # We cannot not tolerate any tagged linear commit (ie,
 673         # BreakwaterStart commits tagged `[anchor:') because such a
 674         # thing could result from an erroneous linearising raw git
 675         # rebase of a merge anchor.  That would represent a corruption
 676         # of the branch. and we want to detect and reject the results
 677         # of such corruption before it makes it out anywhere.  If we
 678         # reject it here then we avoid making the pseudomerge which
 679         # would be needed to push it.
 680
 681         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 682         @p == 2 or return $badanchor->("has other than two parents");
 683         $haspatches and return $badanchor->("contains debian/patches");
 684
 685         # How to decide about l/r ordering of anchors ?  git
 686         # --topo-order prefers to expand 2nd parent first.  There's
 687         # already an easy rune to look for debian/ history anyway (git log
 688         # debian/) so debian breakwater branch should be 1st parent; that
 689         # way also there's also an easy rune to look for the upstream
 690         # patches (--topo-order).
 691
 692         # Also this makes --first-parent be slightly more likely to
 693         # be useful - it makes it provide a linearised breakwater history.
 694
 695         # Of course one can say somthing like
 696         #  gitk -- ':/' ':!/debian'
 697         # to get _just_ the commits touching upstream files, and by
 698         # the TREESAME logic in git-rev-list this will leave the
 699         # breakwater into upstream at the first anchor.  But that
 700         # doesn't report debian/ changes at all.
 701
 702         # Other observations about gitk: by default, gitk seems to
 703         # produce output in a different order to git-rev-list.  I
 704         # can't seem to find this documented anywhere.  gitk
 705         # --date-order DTRT.  But, gitk always seems to put the
 706         # parents from left to right, in order, so it's easy to see
 707         # which way round a pseudomerge is.
 708
 709         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 710         $p[1]{Differs} & ~DS_DEB and
 711             $badanchor->("upstream files differ from left parent");
 712         $p[0]{Differs} & ~D_UPS and
 713             $badanchor->("debian/ differs from right parent");
 714
 715         return $classify->(qw(Anchor),
 716                            OrigParents => [ $p[1] ]);
 717     }
 718
 719     if (@p == 1) {
 720         my $d = $r->{Parents}[0]{Differs};
 721         if ($d == D_PAT_ADD) {
 722             return $classify->(qw(AddPatches));
 723         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 724             return $unknown->("edits debian/patches");
 725         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 726             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 727             if ($ty eq 'tree') {
 728                 if ($d == D_DEB_CLOG) {
 729                     return $classify->(qw(Changelog));
 730                 } else {
 731                     return $classify->(qw(Packaging));
 732                 }
 733             } elsif ($ty eq 'missing') {
 734                 return $classify->(qw(BreakwaterStart));
 735             } else {
 736                 return $unknown->("parent's debian is not a directory");
 737             }
 738         } elsif ($d == D_UPS) {
 739             return $classify->(qw(Upstream));
 740         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 741             return $classify->(qw(Mixed));
 742         } elsif ($d == 0) {
 743             return $unknown->("no changes");
 744         } else {
 745             confess "internal error $objid ?";
 746         }
 747     }
 748     if (!@p) {
 749         return $unknown->("origin commit");
 750     }
 751
 752     if (@p == 2 && @identical == 1) {
 753         my @overwritten = grep { $_->{Differs} } @p;
 754         confess "internal error $objid ?" unless @overwritten==1;
 755         return $classify->(qw(Pseudomerge),
 756                            Overwritten => [ $overwritten[0] ],
 757                            Contributor => $identical[0]);
 758     }
 759     if (@p == 2 && @identical == 2) {
 760         my $get_t = sub {
 761             my ($ph,$pm) = get_commit $_[0]{CommitId};
 762             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 763             $1;
 764         };
 765         my @bytime = @p;
 766         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 767         if ($order > 0) { # newer first
 768         } elsif ($order < 0) {
 769             @bytime = reverse @bytime;
 770         } else {
 771             # same age, default to order made by -s ours
 772             # that is, commit was made by someone who preferred L
 773         }
 774         return $classify->(qw(Pseudomerge),
 775                            SubType => qw(Ambiguous),
 776                            Contributor => $bytime[0],
 777                            Overwritten => [ $bytime[1] ]);
 778     }
 779     foreach my $p (@p) {
 780         my ($p_h, $p_m) = get_commit $p->{CommitId};
 781         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 782         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 783     }
 784     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 785     my $m2 = $r->{Msg};
 786     if (!(grep { !$_->{IsOrigin} } @p) and
 787         (@orig_ps >= @p - 1) and
 788         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 789         $r->{NewMsg} = $m2;
 790         return $classify->(qw(DgitImportUnpatched),
 791                            OrigParents => \@orig_ps);
 792     }
 793
 794     if (@p == 2 and
 795         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 796         # xxx ^ metadata tag needs adding to (5)
 797         return $classify->("MergedBreakwaters");
 798     }
 799     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 800         return $unknown->("unknown kind of merge from $1");
 801     }
 802     if (@p > 2) {
 803         return $unknown->("octopus merge");
 804     }
 805
 806     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 807         return $unknown->("general two-parent merge");
 808     }
 809
 810     return $classify->("VanillaMerge");
 811 }
 812
 813 sub keycommits ($;$$$$) {
 814     my ($head, $furniture, $unclean, $trouble, $fatal) = @_;
 815     # => ($anchor, $breakwater)
 816
 817     # $unclean->("unclean-$tagsfx", $msg, $cl)
 818     # $furniture->("unclean-$tagsfx", $msg, $cl)
 819     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 820     #   is callled for each situation or commit that
 821     #   wouldn't be found in a laundered branch
 822     # $furniture is for furniture commits such as might be found on an
 823     #   interchange branch (pseudomerge, d/patches, changelog)
 824     # $trouble is for things whnich prevent the return of
 825     #   anchor and breakwater information; if that is ignored,
 826     #   then keycommits returns (undef, undef) instead.
 827     # $fatal is for unprocessable commits, and should normally cause
 828     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 829     #
 830     # If a callback is undef, fail is called instead.
 831     # If a callback is defined but false, the situation is ignored.
 832     # Callbacks may say:
 833     #   no warnings qw(exiting); last;
 834     # if the answer is no longer wanted.
 835
 836     my ($anchor, $breakwater);
 837     my $clogonly;
 838     my $cl;
 839     my $found_pm;
 840     $fatal //= sub { fail $_[1]; };
 841     my $x = sub {
 842         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 843         my $why = $mainwhy.$xwhy;
 844         my $m = "branch needs laundering (run git-debrebase): $why";
 845         fail $m unless defined $cb;
 846         return unless $cb;
 847         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 848     };
 849     for (;;) {
 850         $cl = classify $head;
 851         my $ty = $cl->{Type};
 852         if ($ty eq 'Packaging') {
 853             $breakwater //= $clogonly;
 854             $breakwater //= $head;
 855         } elsif ($ty eq 'Changelog') {
 856             # this is going to count as the tip of the breakwater
 857             # only if it has no upstream stuff before it
 858             $clogonly //= $head;
 859         } elsif ($ty eq 'Anchor' or
 860                  $ty eq 'TreatAsAnchor' or
 861                  $ty eq 'BreakwaterStart') {
 862             $anchor = $head;
 863             $breakwater //= $clogonly;
 864             $breakwater //= $head;
 865             last;
 866         } elsif ($ty eq 'Upstream') {
 867             $x->($unclean, 'ordering',
 868  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 869                 if defined $breakwater;
 870             $clogonly = undef;
 871             $breakwater = undef;
 872         } elsif ($ty eq 'Mixed') {
 873             $x->($unclean, 'mixed',
 874                  "found mixed upstream/packaging commit"," ($head)");
 875             $clogonly = undef;
 876             $breakwater = undef;
 877         } elsif ($ty eq 'Pseudomerge' or
 878                  $ty eq 'AddPatches') {
 879             my $found_pm = 1;
 880             $x->($furniture, (lc $ty),
 881                  "found interchange bureaucracy commit ($ty)"," ($head)");
 882         } elsif ($ty eq 'DgitImportUnpatched') {
 883             if ($found_pm) {
 884                 $x->($trouble, 'dgitimport',
 885                      "found dgit dsc import"," ($head)");
 886                 return (undef,undef);
 887             } else {
 888                 $x->($fatal, 'unprocessable',
 889                      "found bare dgit dsc import with no prior history",
 890                      " ($head)");
 891                 return (undef,undef);
 892             }
 893         } elsif ($ty eq 'VanillaMerge') {
 894             $x->($trouble, 'vanillamerge',
 895                  "found vanilla merge"," ($head)");
 896             return (undef,undef);
 897         } else {
 898             $x->($fatal, 'unprocessable',
 899                  "found unprocessable commit, cannot cope: $cl->{Why}",
 900                  " ($head)");
 901             return (undef,undef);
 902         }
 903         $head = $cl->{Parents}[0]{CommitId};
 904     }
 905     return ($anchor, $breakwater);
 906 }
 907
 908 sub walk ($;$$$);
 909 sub walk ($;$$$) {
 910     my ($input,
 911         $nogenerate,$report, $report_lprefix) = @_;
 912     # => ($tip, $breakwater_tip, $last_anchor)
 913     # (or nothing, if $nogenerate)
 914
 915     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 916     $report_lprefix //= '';
 917
 918     # go through commits backwards
 919     # we generate two lists of commits to apply:
 920     # breakwater branch and upstream patches
 921     my (@brw_cl, @upp_cl, @processed);
 922     my %found;
 923     my $upp_limit;
 924     my @pseudomerges;
 925
 926     my $cl;
 927     my $xmsg = sub {
 928         my ($prose, $info) = @_;
 929         my $ms = $cl->{Msg};
 930         chomp $ms;
 931         $info //= '';
 932         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 933         return (Msg => $ms);
 934     };
 935     my $rewrite_from_here = sub {
 936         my ($cl) = @_;
 937         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 938         push @$cl, $sp_cl;
 939         push @processed, $sp_cl;
 940     };
 941     my $cur = $input;
 942
 943     my $prdelim = "";
 944     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 945
 946     my $prline = sub {
 947         return unless $report;
 948         print $report $prdelim, $report_lprefix, @_;
 949         $prdelim = "\n";
 950     };
 951
 952     my $bomb = sub { # usage: return $bomb->();
 953         print $report " Unprocessable" if $report;
 954         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 955         $prprdelim->();
 956         if ($nogenerate) {
 957             return (undef,undef);
 958         }
 959         fail "found unprocessable commit, cannot cope".
 960             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 961             " (commit $cur) (d.".
 962             (join ' ', map { sprintf "%#x", $_->{Differs} }
 963              @{ $cl->{Parents} }).
 964                  ")";
 965     };
 966
 967     my $build;
 968     my $breakwater;
 969
 970     my $build_start = sub {
 971         my ($msg, $parent) = @_;
 972         $prline->(" $msg");
 973         $build = $parent;
 974         no warnings qw(exiting); last;
 975     };
 976
 977     my $nomerge = sub {
 978         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
 979     };
 980
 981     my $last_anchor;
 982
 983     for (;;) {
 984         $cl = classify $cur;
 985         my $ty = $cl->{Type};
 986         my $st = $cl->{SubType};
 987         $prline->("$cl->{CommitId} $cl->{Type}");
 988         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 989         push @processed, $cl;
 990         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 991         if ($ty eq 'AddPatches') {
 992             $cur = $p0;
 993             $rewrite_from_here->(\@upp_cl);
 994             next;
 995         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 996             push @brw_cl, $cl;
 997             $cur = $p0;
 998             next;
 999         } elsif ($ty eq 'BreakwaterStart') {
1000             $last_anchor = $cur;
1001             $build_start->('FirstPackaging', $cur);
1002         } elsif ($ty eq 'Upstream') {
1003             push @upp_cl, $cl;
1004             $cur = $p0;
1005             next;
1006         } elsif ($ty eq 'Mixed') {
1007             my $queue = sub {
1008                 my ($q, $wh) = @_;
1009                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1010                 push @$q, $cls;
1011             };
1012             $queue->(\@brw_cl, "debian");
1013             $queue->(\@upp_cl, "upstream");
1014             $rewrite_from_here->(\@brw_cl);
1015             $cur = $p0;
1016             next;
1017         } elsif ($ty eq 'Pseudomerge') {
1018             my $contrib = $cl->{Contributor}{CommitId};
1019             print $report " Contributor=$contrib" if $report;
1020             push @pseudomerges, $cl;
1021             $rewrite_from_here->(\@upp_cl);
1022             $cur = $contrib;
1023             next;
1024         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1025             $last_anchor = $cur;
1026             $build_start->("Anchor", $cur);
1027         } elsif ($ty eq 'DgitImportUnpatched') {
1028             my $pm = $pseudomerges[-1];
1029             if (defined $pm) {
1030                 # To an extent, this is heuristic.  Imports don't have
1031                 # a useful history of the debian/ branch.  We assume
1032                 # that the first pseudomerge after an import has a
1033                 # useful history of debian/, and ignore the histories
1034                 # from later pseudomerges.  Often the first pseudomerge
1035                 # will be the dgit import of the upload to the actual
1036                 # suite intended by the non-dgit NMUer, and later
1037                 # pseudomerges may represent in-archive copies.
1038                 my $ovwrs = $pm->{Overwritten};
1039                 printf $report " PM=%s \@Overwr:%d",
1040                     $pm->{CommitId}, (scalar @$ovwrs)
1041                     if $report;
1042                 if (@$ovwrs != 1) {
1043                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1044                     return $bomb->();
1045                 }
1046                 my $ovwr = $ovwrs->[0]{CommitId};
1047                 printf $report " Overwr=%s", $ovwr if $report;
1048                 # This import has a tree which is just like a
1049                 # breakwater tree, but it has the wrong history.  It
1050                 # ought to have the previous breakwater (which the
1051                 # pseudomerge overwrote) as an ancestor.  That will
1052                 # make the history of the debian/ files correct.  As
1053                 # for the upstream version: either it's the same as
1054                 # was ovewritten (ie, same as the previous
1055                 # breakwater), in which case that history is precisely
1056                 # right; or, otherwise, it was a non-gitish upload of a
1057                 # new upstream version.  We can tell these apart by
1058                 # looking at the tree of the supposed upstream.
1059                 push @brw_cl, {
1060                     %$cl,
1061                     SpecialMethod => 'DgitImportDebianUpdate',
1062                     $xmsg->("convert dgit import: debian changes")
1063                 }, {
1064                     %$cl,
1065                     SpecialMethod => 'DgitImportUpstreamUpdate',
1066                     $xmsg->("convert dgit import: upstream update",
1067                             " anchor")
1068                 };
1069                 $prline->(" Import");
1070                 $rewrite_from_here->(\@brw_cl);
1071                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1072                 $cur = $ovwr;
1073                 next;
1074             } else {
1075                 # Everything is from this import.  This kind of import
1076                 # is already nearly in valid breakwater format, with the
1077                 # patches as commits.  Unfortunately it contains
1078                 # debian/patches/.
1079                 printdebug "*** WALK BOMB bare dgit import\n";
1080                 $cl->{Why} = "bare dgit dsc import";
1081                 return $bomb->();
1082             }
1083             die "$ty ?";
1084         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1085             # xxx need to handle ffq if one side was unstitched
1086             # wait both of them may be!
1087             my $ok=1;
1088             my $best_anchor;
1089             # We expect to find a dominating anchor amongst the
1090             # inputs' anchors.  That will be the new anchor.
1091             #
1092             # More complicated is finding a merge base for the
1093             # breakwaters.  We need a merge base that is a breakwater
1094             # commit.  The ancestors of breakwater commits are more
1095             # breakwater commits and possibly upstream commits and the
1096             # ancestors of those upstream.  Upstreams might have
1097             # arbitrary ancestors.  But any upstream commit U is
1098             # either included in both anchors, in which case the
1099             # earlier anchor is a better merge base than any of U's
1100             # ancestors; or U is not included in the older anchor, in
1101             # which case U is not an ancestor of the vanilla merge at
1102             # all.  So no upstream commit, nor any ancestor thereof,
1103             # is a best merge base.  As for non-breakwater Debian
1104             # commits: these are never ancestors of any breakwater.
1105             #
1106             # So any best merge base as found by git-merge-base
1107             # is a suitable breakwater anchor.  Usually there will
1108             # be only one.
1109
1110             printdebug "*** MERGE\n";
1111
1112             # xxx avoid calling walk without nogenerate when
1113             # we have a MergedBreakwater; instead call keycommits ?
1114
1115             my @bwbcmd = (@git, qw(merge-base));
1116             my @ibcmd = (@git, qw(merge-base --all));
1117             my $might_be_in_bw = 1;
1118
1119             my $ps = $cl->{Parents};
1120
1121             foreach my $p (@$ps) {
1122                 $prline->(" VanillaMerge ".$p->{Ix});
1123                 $prprdelim->();
1124                 my ($ptip, $pbw, $panchor) =
1125                     walk $p->{CommitId}, 0, $report,
1126                          $report_lprefix.'  ';
1127                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1128                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1129                 $p->{Anchor} = $panchor;
1130
1131                 $best_anchor = $panchor if
1132                     !defined $best_anchor or
1133                     is_fast_fwd $best_anchor, $panchor;
1134
1135                 printdebug " MERGE BA best=".($best_anchor//'-').
1136                     " p=$panchor\n";
1137             }
1138
1139             foreach my $p (@$ps) {
1140                 $prline->(" VanillaMerge ".$p->{Ix});
1141                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1142                     $nomerge->('DivergentAnchor');
1143                 } elsif ($p->{Anchor} eq $best_anchor) {
1144                     print $report " SameAnchor" if $report;
1145                 } else {
1146                     print $report " SupersededAnchor" if $report;
1147                 }
1148                 if ($p->{Breakwater} eq $p->{CommitId}) {
1149                     # this parent commit was its own breakwater,
1150                     # ie it is part of the breakwater
1151                     print $report " Breakwater" if $report;
1152                 } else {
1153                     $might_be_in_bw = 0;
1154                 }
1155                 push @bwbcmd, $p->{Breakwater};
1156                 push @ibcmd, $p->{CommitId};
1157             }
1158
1159             if ($ok && $might_be_in_bw) {
1160                 $prline->(" VanillaMerge MergedBreakwaters");
1161                 $last_anchor = $best_anchor;
1162                 $build_start->('MergedBreakwaters', $cur);
1163             }
1164
1165             $nomerge->("alleged merged-breakwater is not a breakwater")
1166                 unless $ty eq 'VanillaMerge';
1167
1168             my $bwb = cmdoutput @bwbcmd;
1169
1170             # OK, now we have a breakwater base, but we need the merge
1171             # base for the interchange branch because we need the delta
1172             # queue.
1173             #
1174             # This a the best merge base of our inputs which has the
1175             # breakwater merge base as an ancestor.
1176
1177             my @ibs =
1178                 grep { is_fast_fwd $bwb, $_ }
1179                 grep /./,
1180                 split /\n/,
1181                 cmdoutput @ibcmd;
1182             my ($ib) = @ibs
1183                 or $nomerge->("no suitable interchange merge base");
1184
1185             $prline->("  VanillaMerge Base");
1186             $prprdelim->();
1187             my ($btip, $bbw, $banchor) =
1188                 walk $ib, 0, $report, $report_lprefix.'  ';
1189
1190             my $ibinfo = { SeriesTip => $btip,
1191                            SeriesBase => $bbw,
1192                            Anchor => $banchor };
1193             $bbw eq $bwb
1194                 or $nomerge->("interchange merge-base ($ib)'s".
1195                               " breakwater ($bbw)".
1196                               " != breakwaters' merge-base ($bwb)");
1197             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1198                  or $nomerge->("interchange merge-base ($ib)'s".
1199                                " anchor ($ibinfo->{SeriesBase})".
1200                                " != any merge input's anchor (".
1201                                (join ' ', map { $_->{Anchor} } @$ps).
1202                                ")");
1203
1204
1205             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1206             $cl->{MergeBestAnchor} = $best_anchor;
1207             push @brw_cl, {
1208                 %$cl,
1209                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1210                 $xmsg->('construct merged breakwater from vanilla merge'),
1211             };
1212             push @upp_cl, {
1213                 %$cl,
1214                 SpecialMethod => 'MergeMergeSeries',
1215             };
1216             $build_start->('MergeBreakwaters', $cur);
1217         } else {
1218             printdebug "*** WALK BOMB unrecognised\n";
1219             return $bomb->();
1220         }
1221     }
1222     $prprdelim->();
1223
1224     printdebug "*** WALK prep done cur=$cur".
1225         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1226
1227     return if $nogenerate;
1228
1229     # Now we build it back up again
1230
1231     fresh_workarea();
1232
1233     my $rewriting = 0;
1234
1235     $#upp_cl = $upp_limit if defined $upp_limit;
1236
1237     my $committer_authline = calculate_committer_authline();
1238
1239     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1240
1241     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1242
1243     in_workarea sub {
1244         mkdir $rd or $!==EEXIST or die $!;
1245         my $current_method;
1246         runcmd @git, qw(read-tree), $build;
1247         foreach my $cl (qw(Debian), (reverse @brw_cl),
1248                         { SpecialMethod => 'RecordBreakwaterTip' },
1249                         qw(Upstream), (reverse @upp_cl)) {
1250             if (!ref $cl) {
1251                 $current_method = $cl;
1252                 next;
1253             }
1254             my $method = $cl->{SpecialMethod} // $current_method;
1255             my @parents = ($build);
1256             my $cltree = $cl->{CommitId};
1257             printdebug "WALK BUILD ".($cltree//'undef').
1258                 " $method (rewriting=$rewriting)\n";
1259             if ($method eq 'Debian') {
1260                 read_tree_debian($cltree);
1261             } elsif ($method eq 'Upstream') {
1262                 read_tree_upstream($cltree);
1263             } elsif ($method eq 'StartRewrite') {
1264                 $rewriting = 1;
1265                 next;
1266             } elsif ($method eq 'RecordBreakwaterTip') {
1267                 $breakwater = $build;
1268                 next;
1269             } elsif ($method eq 'DgitImportDebianUpdate') {
1270                 read_tree_debian($cltree);
1271             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1272                 confess unless $rewriting;
1273                 my $differs = (get_differs $build, $cltree);
1274                 next unless $differs & D_UPS;
1275                 read_tree_upstream($cltree);
1276                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1277             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1278                 print "Found a general merge, will try to tidy it up.\n";
1279                 $rewriting = 1;
1280                 read_tree_upstream($cl->{MergeBestAnchor});
1281                 read_tree_upstream($cl->{MergeBestAnchor});
1282                 read_tree_debian($cltree);
1283                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1284             } elsif ($method eq 'MergeMergeSeries') {
1285                 print "Running merge resolution for $cl->{CommitId}...\n";
1286                 $build = merge_series
1287                     $build,
1288                     $cl->{MergeInterchangeBaseInfo},
1289                     @{ $cl->{Parents} };
1290                 $last_anchor = $cl->{MergeBestAnchor};
1291                 # xxx need to check the tree somehow
1292                 print "Merge resolution successful.\n";
1293                 next;
1294             } else {
1295                 confess "$method ?";
1296             }
1297             if (!$rewriting) {
1298                 my $procd = (pop @processed) // 'UNDEF';
1299                 if ($cl ne $procd) {
1300                     $rewriting = 1;
1301                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1302                 }
1303             }
1304             my $newtree = cmdoutput @git, qw(write-tree);
1305             my $ch = $cl->{Hdr};
1306             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1307             $ch =~ s{^parent .*\n}{}mg;
1308             $ch =~ s{(?=^author)}{
1309                 join '', map { "parent $_\n" } @parents
1310             }me or confess "$ch ?";
1311             if ($rewriting) {
1312                 $ch =~ s{^committer .*$}{$committer_authline}m
1313                     or confess "$ch ?";
1314             }
1315             my $cf = "$rd/m$rewriting";
1316             open CD, ">", $cf or die $!;
1317             print CD $ch, "\n", $cl->{Msg} or die $!;
1318             close CD or die $!;
1319             my @cmd = (@git, qw(hash-object));
1320             push @cmd, qw(-w) if $rewriting;
1321             push @cmd, qw(-t commit), $cf;
1322             my $newcommit = cmdoutput @cmd;
1323             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1324             $build = $newcommit;
1325             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1326                 $last_anchor = $cur;
1327             }
1328         }
1329     };
1330
1331     my $final_check = get_differs $build, $input;
1332     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1333         if $final_check & ~D_PAT_ADD;
1334
1335     my @r = ($build, $breakwater, $last_anchor);
1336     printdebug "*** WALK RETURN @r\n";
1337     return @r
1338 }
1339
1340 sub get_head () {
1341     git_check_unmodified();
1342     return git_rev_parse qw(HEAD);
1343 }
1344
1345 sub update_head ($$$) {
1346     my ($old, $new, $mrest) = @_;
1347     push @deferred_updates, "update HEAD $new $old";
1348     run_deferred_updates $mrest;
1349 }
1350
1351 sub update_head_checkout ($$$) {
1352     my ($old, $new, $mrest) = @_;
1353     update_head $old, $new, $mrest;
1354     runcmd @git, qw(reset --hard);
1355 }
1356
1357 sub update_head_postlaunder ($$$) {
1358     my ($old, $tip, $reflogmsg) = @_;
1359     return if $tip eq $old;
1360     print "git-debrebase: laundered (head was $old)\n";
1361     update_head $old, $tip, $reflogmsg;
1362     # no tree changes except debian/patches
1363     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1364 }
1365
1366 sub currently_rebasing() {
1367     foreach (qw(rebase-merge rebase-apply)) {
1368         return 1 if stat_exists "$maindir_gitdir/$_";
1369     }
1370     return 0;
1371 }
1372
1373 sub bail_if_rebasing() {
1374     fail "you are in the middle of a git-rebase already"
1375         if currently_rebasing();
1376 }
1377
1378 sub do_launder_head ($) {
1379     my ($reflogmsg) = @_;
1380     my $old = get_head();
1381     record_ffq_auto();
1382     my ($tip,$breakwater) = walk $old;
1383     snags_maybe_bail();
1384     update_head_postlaunder $old, $tip, $reflogmsg;
1385     return ($tip,$breakwater);
1386 }
1387
1388 sub cmd_launder_v0 () {
1389     badusage "no arguments to launder-v0 allowed" if @ARGV;
1390     my $old = get_head();
1391     my ($tip,$breakwater,$last_anchor) = walk $old;
1392     update_head_postlaunder $old, $tip, 'launder';
1393     printf "# breakwater tip\n%s\n", $breakwater;
1394     printf "# working tip\n%s\n", $tip;
1395     printf "# last anchor\n%s\n", $last_anchor;
1396 }
1397
1398 sub defaultcmd_rebase () {
1399     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1400     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1401     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1402 }
1403
1404 sub cmd_analyse () {
1405     badusage "analyse does not support any options"
1406         if @ARGV and $ARGV[0] =~ m/^-/;
1407     badusage "too many arguments to analyse" if @ARGV>1;
1408     my ($old) = @ARGV;
1409     if (defined $old) {
1410         $old = git_rev_parse $old;
1411     } else {
1412         $old = git_rev_parse 'HEAD';
1413     }
1414     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1415     STDOUT->error and die $!;
1416 }
1417
1418 sub ffq_prev_branchinfo () {
1419     my $current = git_get_symref();
1420     return gdr_ffq_prev_branchinfo($current);
1421 }
1422
1423 sub ffq_check ($;$$) {
1424     # calls $ff and/or $notff zero or more times
1425     # then returns either (status,message) where status is
1426     #    exists
1427     #    detached
1428     #    weird-symref
1429     #    notbranch
1430     # or (undef,undef, $ffq_prev,$gdrlast)
1431     # $ff and $notff are called like this:
1432     #   $ff->("message for stdout\n");
1433     #   $notff->('snag-name', $message);
1434     # normally $currentval should be HEAD
1435     my ($currentval, $ff, $notff) =@_;
1436
1437     $ff //= sub { print $_[0] or die $!; };
1438     $notff //= \&snag;
1439
1440     my ($status, $message, $current, $ffq_prev, $gdrlast)
1441         = ffq_prev_branchinfo();
1442     return ($status, $message) unless $status eq 'branch';
1443
1444     my $exists = git_get_ref $ffq_prev;
1445     return ('exists',"$ffq_prev already exists") if $exists;
1446
1447     return ('not-branch', 'HEAD symref is not to refs/heads/')
1448         unless $current =~ m{^refs/heads/};
1449     my $branch = $';
1450
1451     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1452     my %checked;
1453
1454     printdebug "ffq check_specs @check_specs\n";
1455
1456     my $check = sub {
1457         my ($lrref, $desc) = @_;
1458         printdebug "ffq might check $lrref ($desc)\n";
1459         my $invert;
1460         for my $chk (@check_specs) {
1461             my $glob = $chk;
1462             $invert = $glob =~ s{^[!^]}{};
1463             last if fnmatch $glob, $lrref;
1464         }
1465         return if $invert;
1466         my $lrval = git_get_ref $lrref;
1467         return unless length $lrval;
1468
1469         if (is_fast_fwd $lrval, $currentval) {
1470             $ff->("OK, you are ahead of $lrref\n");
1471             $checked{$lrref} = 1;
1472         } elsif (is_fast_fwd $currentval, $lrval) {
1473             $checked{$lrref} = -1;
1474             $notff->('behind', "you are behind $lrref, divergence risk");
1475         } else {
1476             $checked{$lrref} = -1;
1477             $notff->('diverged', "you have diverged from $lrref");
1478         }
1479     };
1480
1481     my $merge = cfg "branch.$branch.merge",1;
1482     if (defined $merge and $merge =~ m{^refs/heads/}) {
1483         my $rhs = $';
1484         printdebug "ffq merge $rhs\n";
1485         my $check_remote = sub {
1486             my ($remote, $desc) = @_;
1487             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1488             return unless defined $remote;
1489             $check->("refs/remotes/$remote/$rhs", $desc);
1490         };
1491         $check_remote->((scalar cfg "branch.$branch.remote",1),
1492                         'remote fetch/merge branch');
1493         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1494                         (scalar cfg "branch.$branch.pushDefault",1),
1495                         'remote push branch');
1496     }
1497     if ($branch =~ m{^dgit/}) {
1498         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1499     } elsif ($branch =~ m{^master$}) {
1500         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1501     }
1502     return (undef, undef, $ffq_prev, $gdrlast);
1503 }
1504
1505 sub record_ffq_prev_deferred () {
1506     # => ('status', "message")
1507     # 'status' may be
1508     #    deferred          message is undef
1509     #    exists
1510     #    detached
1511     #    weird-symref
1512     #    notbranch
1513     # if not ff from some branch we should be ff from, is an snag
1514     # if "deferred", will have added something about that to
1515     #   @deferred_update_messages, and also maybe printed (already)
1516     #   some messages about ff checks
1517     bail_if_rebasing();
1518     my $currentval = get_head();
1519
1520     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1521     return ($status,$message) if defined $status;
1522
1523     snags_maybe_bail();
1524
1525     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1526     push @deferred_updates, "delete $gdrlast";
1527     push @deferred_update_messages, "Recorded previous head for preservation";
1528     return ('deferred', undef);
1529 }
1530
1531 sub record_ffq_auto () {
1532     my ($status, $message) = record_ffq_prev_deferred();
1533     if ($status eq 'deferred' || $status eq 'exists') {
1534     } else {
1535         snag $status, "could not record ffq-prev: $message";
1536         snags_maybe_bail();
1537     }
1538 }
1539
1540 sub ffq_prev_info () {
1541     bail_if_rebasing();
1542     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1543     my ($status, $message, $current, $ffq_prev, $gdrlast)
1544         = ffq_prev_branchinfo();
1545     if ($status ne 'branch') {
1546         snag $status, "could not check ffq-prev: $message";
1547         snags_maybe_bail();
1548     }
1549     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1550     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1551 }
1552
1553 sub stitch ($$$$$) {
1554     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1555
1556     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1557
1558     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1559         my $differs = get_differs $old_head, $ffq_prev_commitish;
1560         unless ($differs & ~D_PAT_ADD) {
1561             # ffq-prev is ahead of us, and the only tree changes it has
1562             # are possibly addition of things in debian/patches/.
1563             # Just wind forwards rather than making a pointless pseudomerge.
1564             push @deferred_updates,
1565                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1566             update_head_checkout $old_head, $ffq_prev_commitish,
1567                 "stitch (fast forward)";
1568             return;
1569         }
1570     }
1571     fresh_workarea();
1572     # We make pseudomerges with L as the contributing parent.
1573     # This makes git rev-list --first-parent work properly.
1574     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1575         'Declare fast forward / record previous work',
1576         "[git-debrebase pseudomerge: $prose]",
1577     ];
1578     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1579     update_head $old_head, $new_head, "stitch: $prose";
1580 }
1581
1582 sub do_stitch ($;$) {
1583     my ($prose, $unclean) = @_;
1584
1585     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1586     if (!$ffq_prev_commitish) {
1587         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1588         return;
1589     }
1590     my $dangling_head = get_head();
1591
1592     keycommits $dangling_head, $unclean,$unclean,$unclean;
1593     snags_maybe_bail();
1594
1595     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1596 }
1597
1598 sub upstream_commitish_search ($$) {
1599     my ($upstream_version, $tried) = @_;
1600     # todo: at some point maybe use git-deborig to do this
1601     foreach my $tagpfx ('', 'v', 'upstream/') {
1602         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1603         my $new_upstream = git_get_ref "refs/tags/$tag";
1604         push @$tried, $tag;
1605         return $new_upstream if length $new_upstream;
1606     }
1607 }
1608
1609 sub resolve_upstream_version ($$) {
1610     my ($new_upstream, $upstream_version) = @_;
1611
1612     if (!defined $new_upstream) {
1613         my @tried;
1614         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1615         if (!length $new_upstream) {
1616             fail "Could not determine appropriate upstream commitish.\n".
1617                 " (Tried these tags: @tried)\n".
1618                 " Check version, and specify upstream commitish explicitly.";
1619         }
1620     }
1621     $new_upstream = git_rev_parse $new_upstream;
1622
1623     return $new_upstream;
1624 }
1625
1626 sub cmd_new_upstream () {
1627     # automatically and unconditionally launders before rebasing
1628     # if rebase --abort is used, laundering has still been done
1629
1630     my %pieces;
1631
1632     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1633
1634     # parse args - low commitment
1635     my $spec_version = shift @ARGV;
1636     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1637     fail "bad version number \`$spec_version'" unless defined $new_version;
1638     if ($new_version->is_native()) {
1639         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1640     }
1641
1642     my $new_upstream = shift @ARGV;
1643     my $new_upstream_version = upstreamversion  $new_version;
1644     $new_upstream =
1645         resolve_upstream_version $new_upstream, $new_upstream_version;
1646
1647     record_ffq_auto();
1648
1649     my $piece = sub {
1650         my ($n, @x) = @_; # may be ''
1651         my $pc = $pieces{$n} //= {
1652             Name => $n,
1653             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1654         };
1655         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1656         $pc;
1657     };
1658
1659     my @newpieces;
1660     my $newpiece = sub {
1661         my ($n, @x) = @_; # may be ''
1662         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1663         push @newpieces, $pc;
1664     };
1665
1666     $newpiece->('',
1667         OldIx => 0,
1668         New => $new_upstream,
1669     );
1670     while (@ARGV && $ARGV[0] !~ m{^-}) {
1671         my $n = shift @ARGV;
1672
1673         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1674             unless @ARGV && $ARGV[0] !~ m{^-};
1675
1676         my $c = git_rev_parse shift @ARGV;
1677         die unless $n =~ m/^$extra_orig_namepart_re$/;
1678         $newpiece->($n, New => $c);
1679     }
1680
1681     # now we need to investigate the branch this generates the
1682     # laundered version but we don't switch to it yet
1683     my $old_head = get_head();
1684     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1685
1686     my $old_bw_cl = classify $old_bw;
1687     my $old_anchor_cl = classify $old_anchor;
1688     my $old_upstream;
1689     if (!$old_anchor_cl->{OrigParents}) {
1690         snag 'anchor-treated',
1691             'old anchor is recognised due to --anchor, cannot check upstream';
1692     } else {
1693         $old_upstream = parsecommit
1694             $old_anchor_cl->{OrigParents}[0]{CommitId};
1695         $piece->('', Old => $old_upstream->{CommitId});
1696     }
1697
1698     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1699         if ($old_upstream->{Msg} =~
1700  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1701            ) {
1702             my @oldpieces = (split / /, $1);
1703             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1704             if ($old_n_parents != @oldpieces &&
1705                 $old_n_parents != @oldpieces + 1) {
1706                 snag 'upstream-confusing', sprintf
1707                     "previous upstream combine %s".
1708                     " mentions %d pieces (each implying one parent)".
1709                     " but has %d parents".
1710                     " (one per piece plus maybe a previous combine)",
1711                     $old_upstream->{CommitId},
1712                     (scalar @oldpieces),
1713                     $old_n_parents;
1714             } elsif ($oldpieces[0] ne '.') {
1715                 snag 'upstream-confusing', sprintf
1716                     "previous upstream combine %s".
1717                     " first piece is not \`.'",
1718                     $oldpieces[0];
1719             } else {
1720                 $oldpieces[0] = '';
1721                 foreach my $i (0..$#oldpieces) {
1722                     my $n = $oldpieces[$i];
1723                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1724                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1725                 }
1726             }
1727         } else {
1728             snag 'upstream-confusing',
1729                 "previous upstream $old_upstream->{CommitId} is from".
1730                " git-debrebase but not an \`upstream-combine' commit";
1731         }
1732     }
1733
1734     foreach my $pc (values %pieces) {
1735         if (!$old_upstream) {
1736             # we have complained already
1737         } elsif (!$pc->{Old}) {
1738             snag 'upstream-new-piece',
1739                 "introducing upstream piece \`$pc->{Name}'";
1740         } elsif (!$pc->{New}) {
1741             snag 'upstream-rm-piece',
1742                 "dropping upstream piece \`$pc->{Name}'";
1743         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1744             snag 'upstream-not-ff',
1745                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1746         }
1747     }
1748
1749     printdebug "%pieces = ", (dd \%pieces), "\n";
1750     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1751
1752     snags_maybe_bail();
1753
1754     my $new_bw;
1755
1756     fresh_workarea();
1757     in_workarea sub {
1758         my @upstream_merge_parents;
1759
1760         if (!any_snags()) {
1761             push @upstream_merge_parents, $old_upstream->{CommitId};
1762         }
1763
1764         foreach my $pc (@newpieces) { # always has '' first
1765             if ($pc->{Name}) {
1766                 read_tree_subdir $pc->{Name}, $pc->{New};
1767             } else {
1768                 runcmd @git, qw(read-tree), $pc->{New};
1769             }
1770             push @upstream_merge_parents, $pc->{New};
1771         }
1772
1773         # index now contains the new upstream
1774
1775         if (@newpieces > 1) {
1776             # need to make the upstream subtree merge commit
1777             $new_upstream = make_commit \@upstream_merge_parents,
1778                 [ "Combine upstreams for $new_upstream_version",
1779  ("[git-debrebase upstream-combine . ".
1780  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1781  ": new upstream]"),
1782                 ];
1783         }
1784
1785         # $new_upstream is either the single upstream commit, or the
1786         # combined commit we just made.  Either way it will be the
1787         # "upstream" parent of the anchor merge.
1788
1789         read_tree_subdir 'debian', "$old_bw:debian";
1790
1791         # index now contains the anchor merge contents
1792         $new_bw = make_commit [ $old_bw, $new_upstream ],
1793             [ "Update to upstream $new_upstream_version",
1794  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1795             ];
1796
1797         my $clogsignoff = cmdoutput qw(git show),
1798             '--pretty=format:%an <%ae>  %aD',
1799             $new_bw;
1800
1801         # Now we have to add a changelog stanza so the Debian version
1802         # is right.
1803         die if unlink "debian";
1804         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1805         unlink "debian/changelog" or $!==ENOENT or die $!;
1806         mkdir "debian" or die $!;
1807         open CN, ">", "debian/changelog" or die $!;
1808         my $oldclog = git_cat_file ":debian/changelog";
1809         $oldclog =~ m/^($package_re) \(\S+\) / or
1810             fail "cannot parse old changelog to get package name";
1811         my $p = $1;
1812         print CN <<END, $oldclog or die $!;
1813 $p ($new_version) UNRELEASED; urgency=medium
1814
1815   * Update to new upstream version $new_upstream_version.
1816
1817  -- $clogsignoff
1818
1819 END
1820         close CN or die $!;
1821         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1822
1823         # Now we have the final new breakwater branch in the index
1824         $new_bw = make_commit [ $new_bw ],
1825             [ "Update changelog for new upstream $new_upstream_version",
1826               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1827             ];
1828     };
1829
1830     # we have constructed the new breakwater. we now need to commit to
1831     # the laundering output, because git-rebase can't easily be made
1832     # to make a replay list which is based on some other branch
1833
1834     update_head_postlaunder $old_head, $old_laundered_tip,
1835         'launder for new upstream';
1836
1837     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1838     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1839         "debrebase new-upstream $new_version: rebase";
1840     runcmd @cmd;
1841     # now it's for the user to sort out
1842 }
1843
1844 sub cmd_record_ffq_prev () {
1845     badusage "no arguments allowed" if @ARGV;
1846     my ($status, $msg) = record_ffq_prev_deferred();
1847     if ($status eq 'exists' && $opt_noop_ok) {
1848         print "Previous head already recorded\n" or die $!;
1849     } elsif ($status eq 'deferred') {
1850         run_deferred_updates 'record-ffq-prev';
1851     } else {
1852         fail "Could not preserve: $msg";
1853     }
1854 }
1855
1856 sub cmd_anchor () {
1857     badusage "no arguments allowed" if @ARGV;
1858     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1859     print "$bw\n" or die $!;
1860 }
1861
1862 sub cmd_breakwater () {
1863     badusage "no arguments allowed" if @ARGV;
1864     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1865     print "$bw\n" or die $!;
1866 }
1867
1868 sub cmd_status () {
1869     badusage "no arguments allowed" if @ARGV;
1870
1871     # todo: gdr status should print divergence info
1872     # todo: gdr status should print upstream component(s) info
1873     # todo: gdr should leave/maintain some refs with this kind of info ?
1874
1875     my $oldest = { Badness => 0 };
1876     my $newest;
1877     my $note = sub {
1878         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1879         if ($oldest->{Badness} < $badness) {
1880             $oldest = $newest = undef;
1881         }
1882         $oldest = {
1883                    Badness => $badness,
1884                    CommitId => $cl->{CommitId},
1885                    OurMsg => $ourmsg,
1886                    KcMsg => $kcmsg,
1887                   };
1888         $newest //= $oldest;
1889     };
1890     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1891         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1892         sub { $note->(2, 'branch is unlaundered', @_); },
1893         sub { $note->(3, 'branch needs laundering', @_); },
1894         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1895
1896     my $prcommitinfo = sub {
1897         my ($cid) = @_;
1898         flush STDOUT or die $!;
1899         runcmd @git, qw(--no-pager log -n1),
1900             '--pretty=format:    %h %s%n',
1901             $cid;
1902     };
1903
1904     print "current branch contents, in git-debrebase terms:\n";
1905     if (!$oldest->{Badness}) {
1906         print "  branch is laundered\n";
1907     } else {
1908         print "  $oldest->{OurMsg}\n";
1909         my $printed = '';
1910         foreach my $info ($oldest, $newest) {
1911             my $cid = $info->{CommitId};
1912             next if $cid eq $printed;
1913             $printed = $cid;
1914             print "  $info->{KcMsg}\n";
1915             $prcommitinfo->($cid);
1916         }
1917     }
1918
1919     my $prab = sub {
1920         my ($cid, $what) = @_;
1921         if (!defined $cid) {
1922             print "  $what is not well-defined\n";
1923         } else {
1924             print "  $what\n";
1925             $prcommitinfo->($cid);
1926         }
1927     };
1928     print "key git-debrebase commits:\n";
1929     $prab->($anchor, 'anchor');
1930     $prab->($bw, 'breakwater');
1931
1932     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1933         ffq_prev_branchinfo();
1934
1935     print "branch and ref status, in git-debrebase terms:\n";
1936     if ($ffq_msg) {
1937         print "  $ffq_msg\n";
1938     } else {
1939         $ffq_prev = git_get_ref $ffq_prev;
1940         $gdrlast = git_get_ref $gdrlast;
1941         if ($ffq_prev) {
1942             print "  unstitched; previous tip was:\n";
1943             $prcommitinfo->($ffq_prev);
1944         } elsif (!$gdrlast) {
1945             print "  stitched? (no record of git-debrebase work)\n";
1946         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1947             print "  stitched\n";
1948         } else {
1949             print "  not git-debrebase (diverged since last stitch)\n"
1950         }
1951     }
1952     print "you are currently rebasing\n" if currently_rebasing();
1953 }
1954
1955 sub cmd_stitch () {
1956     my $prose = 'stitch';
1957     getoptions("stitch",
1958                'prose=s', \$prose);
1959     badusage "no arguments allowed" if @ARGV;
1960     do_stitch $prose, 0;
1961 }
1962 sub cmd_prepush () { cmd_stitch(); }
1963
1964 sub cmd_quick () {
1965     badusage "no arguments allowed" if @ARGV;
1966     do_launder_head 'launder for git-debrebase quick';
1967     do_stitch 'quick';
1968 }
1969
1970 sub cmd_conclude () {
1971     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1972     if (!$ffq_prev_commitish) {
1973         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1974         return;
1975     }
1976     my $dangling_head = get_head();
1977
1978     badusage "no arguments allowed" if @ARGV;
1979     do_launder_head 'launder for git-debrebase quick';
1980     do_stitch 'quick';
1981 }
1982
1983 sub cmd_scrap () {
1984     if (currently_rebasing()) {
1985         runcmd @git, qw(rebase --abort);
1986     }
1987     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1988     if (!$ffq_prev_commitish) {
1989         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1990         finish 0;
1991     }
1992     my $scrapping_head = get_head();
1993     badusage "no arguments allowed" if @ARGV;
1994     push @deferred_updates,
1995         "update $gdrlast $ffq_prev_commitish $git_null_obj",
1996         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
1997     snags_maybe_bail();
1998     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
1999 }
2000
2001 sub make_patches_staged ($) {
2002     my ($head) = @_;
2003     # Produces the patches that would result from $head if it were
2004     # laundered.
2005     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2006     fresh_workarea();
2007     in_workarea sub {
2008         gbp_pq_export 'bw', $secret_bw, $secret_head;
2009     };
2010 }
2011
2012 sub make_patches ($) {
2013     my ($head) = @_;
2014     keycommits $head, 0, \&snag;
2015     make_patches_staged $head;
2016     my $out;
2017     in_workarea sub {
2018         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2019         runcmd @git, qw(read-tree), $head;
2020         read_tree_subdir 'debian/patches', $ptree;
2021         $out = make_commit [$head], [
2022             'Commit patch queue (exported by git-debrebase)',
2023             '[git-debrebase: export and commit patches]',
2024         ];
2025     };
2026     return $out;
2027 }
2028
2029 sub cmd_make_patches () {
2030     my $opt_quiet_would_amend;
2031     getoptions("make-patches",
2032                'quiet-would-amend!', \$opt_quiet_would_amend);
2033     badusage "no arguments allowed" if @ARGV;
2034     bail_if_rebasing();
2035     my $old_head = get_head();
2036     my $new = make_patches $old_head;
2037     my $d = get_differs $old_head, $new;
2038     if ($d == 0) {
2039         fail "No (more) patches to export." unless $opt_noop_ok;
2040         return;
2041     } elsif ($d == D_PAT_ADD) {
2042         snags_maybe_bail();
2043         update_head_checkout $old_head, $new, 'make-patches';
2044     } else {
2045         print STDERR failmsg
2046             "Patch export produced patch amendments".
2047             " (abandoned output commit $new).".
2048             "  Try laundering first."
2049             unless $opt_quiet_would_amend;
2050         finish 7;
2051     }
2052 }
2053
2054 sub cmd_convert_from_gbp () {
2055     badusage "want only 1 optional argument, the upstream git commitish"
2056         unless @ARGV<=1;
2057
2058     my $clogp = parsechangelog();
2059     my $version = $clogp->{'Version'}
2060         // die "missing Version from changelog";
2061
2062     my ($upstream_spec) = @ARGV;
2063
2064     my $upstream_version = upstreamversion $version;
2065     my $upstream =
2066         resolve_upstream_version($upstream_spec, $upstream_version);
2067
2068     my $old_head = get_head();
2069
2070     my $upsdiff = get_differs $upstream, $old_head;
2071     if ($upsdiff & D_UPS) {
2072         runcmd @git, qw(--no-pager diff --stat),
2073             $upstream, $old_head,
2074             qw( -- :!/debian :/);
2075         fail <<END;
2076 upstream ($upstream_spec) and HEAD are not
2077 identical in upstream files.  See diffstat above, or run
2078   git diff $upstream_spec HEAD -- :!/debian :/
2079 END
2080     }
2081
2082     if (!is_fast_fwd $upstream, $old_head) {
2083         snag 'upstream-not-ancestor',
2084             "upstream ($upstream) is not an ancestor of HEAD";
2085     } else {
2086         my $wrong = cmdoutput
2087             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2088              qw(-- :/ :!/debian));
2089         if (length $wrong) {
2090             snag 'unexpected-upstream-changes',
2091                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2092             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2093         }
2094     }
2095
2096     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2097         snag 'upstream-has-debian',
2098             "upstream ($upstream) contains debian/ directory";
2099     }
2100
2101     my $previous_dgit_view = eval {
2102         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2103         my ($lvsn, $suite);
2104         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2105             my ($stz, $desc) = @_;
2106             no warnings qw(exiting);
2107             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2108             next unless $stz->{Date};
2109             next unless $stz->{Distribution} ne 'UNRELEASED';
2110             $lvsn = $stz->{Version};
2111             $suite = $stz->{Distribution};
2112             last;
2113         };
2114         die "neither of the first two changelog entries are released\n"
2115             unless defined $lvsn;
2116         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2117         my $mtag_pat = debiantag_maintview $lvsn, '*';
2118         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2119             $mtag_pat;
2120         die "could not find suitable maintainer view tag $mtag_pat\n"
2121             unless $mtag_pat =~ m{/};
2122         is_fast_fwd $mtag, 'HEAD' or
2123             die "HEAD is not FF from maintainer tag $mtag!";
2124         my $dtag = "archive/$mtag";
2125         is_fast_fwd $mtag, $dtag or
2126             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2127         print "will stitch in dgit view, $dtag\n";
2128         git_rev_parse $dtag;
2129     };
2130     if (!$previous_dgit_view) {
2131         $@ =~ s/^\n+//;
2132         chomp $@;
2133         print STDERR "cannot stitch in dgit view: $@\n";
2134     }
2135
2136     snags_maybe_bail_early();
2137
2138     my $work;
2139
2140     fresh_workarea();
2141     in_workarea sub {
2142         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2143         # make a branch out of the patch queue - we'll want this in a mo
2144         runcmd qw(gbp pq import);
2145         # strip the patches out
2146         runcmd @git, qw(checkout -q gdr-internal~0);
2147         rm_subdir_cached 'debian/patches';
2148         $work = make_commit ['HEAD'], [
2149  'git-debrebase convert-from-gbp: drop patches from tree',
2150  'Delete debian/patches, as part of converting to git-debrebase format.',
2151  '[git-debrebase convert-from-gbp: drop patches from tree]'
2152                               ];
2153         # make the anchor merge
2154         # the tree is already exactly right
2155         $work = make_commit [$work, $upstream], [
2156  'git-debrebase import: declare upstream',
2157  'First breakwater merge.',
2158  '[git-debrebase anchor: declare upstream]'
2159                               ];
2160
2161         # rebase the patch queue onto the new breakwater
2162         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2163         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2164         $work = git_rev_parse 'HEAD';
2165
2166         if ($previous_dgit_view) {
2167             $work = make_commit [$work, $previous_dgit_view], [
2168  'git-debrebase import: declare ff from dgit archive view',
2169  '[git-debrebase pseudomerge: import-from-gbp]',
2170             ];
2171         }
2172     };
2173
2174     ffq_check $work;
2175     snags_maybe_bail();
2176     update_head_checkout $old_head, $work, 'convert-from-gbp';
2177 }
2178
2179 sub cmd_convert_to_gbp () {
2180     badusage "no arguments allowed" if @ARGV;
2181     my $head = get_head();
2182     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2183     keycommits $head, 0;
2184     my $out;
2185     make_patches_staged $head;
2186     in_workarea sub {
2187         $out = make_commit ['HEAD'], [
2188             'Commit patch queue (converted from git-debrebase format)',
2189             '[git-debrebase convert-to-gbp: commit patches]',
2190         ];
2191     };
2192     if (defined $ffq) {
2193         push @deferred_updates, "delete $ffq";
2194         push @deferred_updates, "delete $gdrlast";
2195     }
2196     snags_maybe_bail();
2197     update_head_checkout $head, $out, "convert to gbp (v0)";
2198     print <<END or die $!;
2199 git-debrebase: converted to git-buildpackage branch format
2200 git-debrebase: WARNING: do not now run "git-debrebase" any more
2201 git-debrebase: WARNING: doing so would drop all upstream patches!
2202 END
2203 }
2204
2205 sub cmd_convert_from_dgit_view () {
2206     my $clogp = parsechangelog();
2207
2208     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2209     my $do_origs = 1;
2210     my $do_tags = 1;
2211     my $always = 0;
2212     my $diagnose = 0;
2213
2214     getoptions("convert-from-dgit-view",
2215                'diagnose!', \$diagnose,
2216                'build-products-dir:s', \$bpd,
2217                'origs!', \$do_origs,
2218                'tags!', \$do_tags,
2219                'always-convert-anyway!', \$always);
2220     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2221
2222     my @upstreams;
2223
2224     if (@ARGV) {
2225         my $spec = shift @ARGV;
2226         my $commit = git_rev_parse "$spec^{commit}";
2227         push @upstreams, { Commit => $commit,
2228                            Source => "$ARGV[0], from command line",
2229                            Only => 1,
2230                          };
2231     }
2232
2233     my $head = get_head();
2234
2235     if (!$always) {
2236         my $troubles = 0;
2237         my $trouble = sub { $troubles++; };
2238         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2239         printdebug "troubles=$troubles\n";
2240         if (!$troubles) {
2241             print STDERR <<END;
2242 $us: Branch already seems to be in git-debrebase format!
2243 $us: --always-convert-anyway would do the conversion operation anyway
2244 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2245 END
2246             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2247             finish 0;
2248         }
2249     }
2250
2251     snags_maybe_bail_early();
2252
2253     my $version = upstreamversion $clogp->{Version};
2254     print STDERR "Considering possible commits corresponding to upstream:\n";
2255
2256     if (!@upstreams) {
2257         if ($do_tags) {
2258             my @tried;
2259             my $ups_tag = upstream_commitish_search $version, \@tried;
2260             if ($ups_tag) {
2261                 my $this = "git tag $tried[-1]";
2262                 push @upstreams, { Commit => $ups_tag,
2263                                    Source => $this,
2264                                  };
2265             } else {
2266                 printf STDERR
2267                     " git tag: no suitable tag found (tried %s)\n",
2268                     "@tried";
2269             }
2270         }
2271         if ($do_origs) {
2272             my $p = $clogp->{'Source'};
2273             # we do a quick check to see if there are plausible origs
2274             my $something=0;
2275             if (!opendir BPD, $bpd) {
2276                 die "$bpd: opendir: $!" unless $!==ENOENT;
2277             } else {
2278                 while ($!=0, my $f = readdir BPD) {
2279                     next unless is_orig_file_of_p_v $f, $p, $version;
2280                     printf STDERR
2281                         " orig: found what looks like a .orig, %s\n",
2282                         "$bpd/$f";
2283                     $something=1;
2284                     last;
2285                 }
2286                 die "read $bpd: $!" if $!;
2287                 closedir BPD;
2288             }
2289             if ($something) {
2290                 my $tree = cmdoutput
2291                     @dgit, qw(--build-products-dir), $bpd,
2292                     qw(print-unapplied-treeish);
2293                 fresh_workarea();
2294                 in_workarea sub {
2295                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2296                     rm_subdir_cached 'debian';
2297                     $tree = cmdoutput @git, qw(write-tree);
2298                     my $ups_synth = make_commit [], [ <<END, <<END,
2299 Import effective orig tree for upstream version $version
2300 END
2301 This includes the contents of the .orig(s), minus any debian/ directory.
2302
2303 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2304 END
2305                                                     ];
2306                     push @upstreams, { Commit => $ups_synth,
2307                                        Source => "orig(s) imported via dgit",
2308                                      };
2309                 }
2310             } else {
2311                 printf STDERR
2312                     " orig: no suitable origs found (looked for %s in %s)\n",
2313                     "${p}_".(stripeoch $version)."...", $bpd;
2314             }
2315         }
2316     }
2317
2318     my $some_patches = stat_exists 'debian/patches/series';
2319
2320     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2321
2322     my $result;
2323     foreach my $u (@upstreams) {
2324         my $work = $head;
2325         fresh_workarea();
2326         in_workarea sub {
2327             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2328             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2329             runcmd @git, qw(clean -xdff);
2330             runcmd @git, qw(checkout), $head, qw(-- debian);
2331             if ($some_patches) {
2332                 rm_subdir_cached 'debian/patches';
2333                 $work = make_commit [ $work ], [
2334  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2335  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2336  "to git-debrebase format.  Upstream changes will appear as commits.",
2337  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2338                                            ];
2339             }
2340             $work = make_commit [ $work, $u->{Commit} ], [
2341  'git-debrebase convert-from-dgit-view: declare upstream',
2342  '(Re)constructed breakwater merge.',
2343  '[git-debrebase anchor: declare upstream]'
2344                                                          ];
2345             runcmd @git, qw(checkout --quiet -b mk), $work;
2346             if ($some_patches) {
2347                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2348                 runcmd @git, qw(reset --quiet);
2349                 my @gbp_cmd = (qw(gbp pq import));
2350                 if (!$diagnose) {
2351                     my $gbp_err = "../gbp-pq-err";
2352                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2353                 }
2354                 my $r = system @gbp_cmd;
2355                 if ($r) {
2356                     printf STDERR
2357                         " %s: couldn't apply patches: gbp pq %s",
2358                         $u->{Source}, waitstatusmsg();
2359                     return;
2360                 }
2361             }
2362             my $work = git_rev_parse qw(HEAD);
2363             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2364             if (length $diffout) {
2365                 print STDERR
2366                     " $u->{Source}: applying patches gives different tree\n";
2367                 print STDERR $diffout if $diagnose;
2368                 return;
2369             }
2370             # OMG!
2371             $u->{Result} = $work;
2372             $result = $u;
2373         };
2374         last if $result;
2375     }
2376
2377     if (!$result) {
2378         fail <<END;
2379 Could not find or construct a suitable upstream commit.
2380 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2381 upstream commmit explicitly or provide suitable origs.
2382 END
2383     }
2384
2385     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2386
2387     ffq_check $result->{Result};
2388     snags_maybe_bail();
2389     update_head_checkout $head, $result->{Result},
2390         'convert-from-dgit-view';
2391 }
2392
2393 sub cmd_downstream_rebase_launder_v0 () {
2394     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2395     my ($base) = @ARGV;
2396     $base = git_rev_parse $base;
2397     my $old_head = get_head();
2398     my $current = $old_head;
2399     my $topmost_keep;
2400     for (;;) {
2401         if ($current eq $base) {
2402             $topmost_keep //= $current;
2403             print " $current BASE stop\n";
2404             last;
2405         }
2406         my $cl = classify $current;
2407         print " $current $cl->{Type}";
2408         my $keep = 0;
2409         my $p0 = $cl->{Parents}[0]{CommitId};
2410         my $next;
2411         if ($cl->{Type} eq 'Pseudomerge') {
2412             print " ^".($cl->{Contributor}{Ix}+1);
2413             $next = $cl->{Contributor}{CommitId};
2414         } elsif ($cl->{Type} eq 'AddPatches' or
2415                  $cl->{Type} eq 'Changelog') {
2416             print " strip";
2417             $next = $p0;
2418         } else {
2419             print " keep";
2420             $next = $p0;
2421             $keep = 1;
2422         }
2423         print "\n";
2424         if ($keep) {
2425             $topmost_keep //= $current;
2426         } else {
2427             die "to-be stripped changes not on top of the branch\n"
2428                 if $topmost_keep;
2429         }
2430         $current = $next;
2431     }
2432     if ($topmost_keep eq $old_head) {
2433         print "unchanged\n";
2434     } else {
2435         print "updating to $topmost_keep\n";
2436         update_head_checkout
2437             $old_head, $topmost_keep,
2438             'downstream-rebase-launder-v0';
2439     }
2440 }
2441
2442 getoptions_main
2443           ("bad options\n",
2444            "D+" => \$debuglevel,
2445            'noop-ok', => \$opt_noop_ok,
2446            'f=s' => \@snag_force_opts,
2447            'anchor=s' => \@opt_anchors,
2448            '--dgit=s' => \($dgit[0]),
2449            'force!',
2450            '-i:s' => sub {
2451                my ($opt,$val) = @_;
2452                badusage "git-debrebase: no cuddling to -i for git-rebase"
2453                    if length $val;
2454                die if $opt_defaultcmd_interactive; # should not happen
2455                $opt_defaultcmd_interactive = [ qw(-i) ];
2456                # This access to @ARGV is excessive familiarity with
2457                # Getopt::Long, but there isn't another sensible
2458                # approach.  '-i=s{0,}' does not work with bundling.
2459                push @$opt_defaultcmd_interactive, @ARGV;
2460                @ARGV=();
2461            },
2462            'help' => sub { print $usage_message or die $!; finish 0; },
2463            );
2464
2465 initdebug('git-debrebase ');
2466 enabledebug if $debuglevel;
2467
2468 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2469 chdir $toplevel or die "chdir $toplevel: $!";
2470
2471 $rd = fresh_playground "$playprefix/misc";
2472
2473 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2474
2475 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2476     defaultcmd_rebase();
2477 } else {
2478     my $cmd = shift @ARGV;
2479     my $cmdfn = $cmd;
2480     $cmdfn =~ y/-/_/;
2481     $cmdfn = ${*::}{"cmd_$cmdfn"};
2482
2483     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2484     $cmdfn->();
2485 }
2486
2487 finish 0;