git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, $opt_merges, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  59 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  60
  61 $|=1;
  62
  63 sub badusage ($) {
  64     my ($m) = @_;
  65     print STDERR "$us: bad usage: $m\n";
  66     finish 8;
  67 }
  68
  69 sub getoptions_main {
  70     my $m = shift;
  71     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  72     GetOptions @_ or badusage $m;
  73 }
  74 sub getoptions {
  75     my $sc = shift;
  76     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  77 }
  78
  79 sub cfg ($;$) {
  80     my ($k, $optional) = @_;
  81     local $/ = "\0";
  82     my @cmd = qw(git config -z);
  83     push @cmd, qw(--get-all) if wantarray;
  84     push @cmd, $k;
  85     my $out = cmdoutput_errok @cmd;
  86     if (!defined $out) {
  87         fail "missing required git config $k" unless $optional;
  88         return ();
  89     }
  90     my @l = split /\0/, $out;
  91     return wantarray ? @l : $l[0];
  92 }
  93
  94 memoize('cfg');
  95
  96 sub dd ($) {
  97     my ($v) = @_;
  98     my $dd = new Data::Dumper [ $v ];
  99     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 100     return Dump $dd;
 101 }
 102
 103 sub get_commit ($) {
 104     my ($objid) = @_;
 105     my $data = (git_cat_file $objid, 'commit');
 106     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 107     return ($`,$');
 108 }
 109
 110 sub D_UPS ()      { 0x02; } # upstream files
 111 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 112 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 113 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 114 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 115 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 116
 117 our $playprefix = 'debrebase';
 118 our $rd;
 119 our $workarea;
 120
 121 our @git = qw(git);
 122 our @dgit = qw(dgit);
 123
 124 sub in_workarea ($) {
 125     my ($sub) = @_;
 126     changedir $workarea;
 127     my $r = eval { $sub->(); };
 128     { local $@; changedir $maindir; }
 129     die $@ if $@;
 130 }
 131
 132 sub fresh_workarea (;$) {
 133     my ($subdir) = @_;
 134     $subdir //= 'work';
 135     $workarea = fresh_playground "$playprefix/$subdir";
 136     in_workarea sub { playtree_setup };
 137 }
 138
 139 sub run_ref_updates_now ($$) {
 140     my ($mrest, $updates) = @_;
 141     # @$updates is a list of lines for git-update-ref, without \ns
 142
 143     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 144     debugcmd '>|', @upd_cmd;
 145     open U, "|-", @upd_cmd or die $!;
 146     foreach (@$updates) {
 147         printdebug ">= ", $_, "\n";
 148         print U $_, "\n" or die $!;
 149     }
 150     printdebug ">\$\n";
 151     close U or failedcmd @upd_cmd;
 152 }
 153
 154 our $snags_forced = 0;
 155 our $snags_tripped = 0;
 156 our $snags_summarised = 0;
 157 our @deferred_updates;
 158 our @deferred_update_messages;
 159
 160 sub merge_wreckage_cleaning ($) {
 161     my ($updates) = @_;
 162     git_for_each_ref("$wrecknoteprefix/*", sub {
 163         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 164         push @$updates, "delete $fullrefname";
 165     });
 166 }
 167
 168 sub all_snags_summarised () {
 169     $snags_forced + $snags_tripped == $snags_summarised;
 170 }
 171 sub run_deferred_updates ($) {
 172     my ($mrest) = @_;
 173
 174     confess 'dangerous internal error' unless all_snags_summarised();
 175
 176     merge_wreckage_cleaning \@deferred_updates;
 177     run_ref_updates_now $mrest, \@deferred_updates;
 178     print $_, "\n" foreach @deferred_update_messages;
 179
 180     @deferred_updates = ();
 181     @deferred_update_messages = ();
 182 }
 183
 184 sub get_tree ($;$$) {
 185     # tree object name => ([ $name, $info ], ...)
 186     # where $name is the sort key, ie has / at end for subtrees
 187     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 188     # without $precheck, will crash if $x does not exist, so don't do that;
 189     # instead pass '' to get ().
 190     my ($x, $precheck, $recurse) = @_;
 191
 192     return () if !length $x;
 193
 194     if ($precheck) {
 195         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 196         return () if $type eq 'missing';
 197     }
 198
 199     confess "get_tree needs object not $x ?" unless $x =~ m{^[0-9a-f]+\:};
 200
 201     our (@get_tree_memo, %get_tree_memo);
 202     my $memo = $get_tree_memo{$x};
 203     return @$memo if $memo;
 204
 205     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 206     my @l;
 207     my @cmd = (qw(git ls-tree -z --full-tree));
 208     push @cmd, qw(-r) if $recurse;
 209     push @cmd, qw(--), $x;
 210     my $o = cmdoutput @cmd;
 211     $o =~ s/\0$//s;
 212     my $last = '';
 213     foreach my $l (split /\0/, $o) {
 214         my ($i, $n) = split /\t/, $l, 2;
 215         $n .= '/' if $i =~ m/^\d+ tree /;
 216         push @l, [ $n, $i ];
 217         confess "$x need $last < $n ?" unless $last lt $n;
 218     }
 219     $get_tree_memo{$x} = \@l;
 220     push @get_tree_memo, $x;
 221     if (@get_tree_memo > 10) {
 222         delete $get_tree_memo{ shift @get_tree_memo };
 223     }
 224     return @l;
 225 }
 226
 227 sub trees_diff_walk ($$$;$) {
 228     # trees_diff_walk [$all,] $x, $y, sub {... }
 229     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 230     # $x and $y are as for get_tree
 231     # where $name, $ix, $iy are $name and $info from get_tree
 232     my $all = shift @_ if @_>=4;
 233     my ($x,$y,$call) = @_;
 234     return if !$all and $x eq $y;
 235     my @x = get_tree $x;
 236     my @y = get_tree $y;
 237     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 238         if $debuglevel >= 3;
 239     while (@x || @y) {
 240         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 241              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 242         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 243         $ix=$iy='';
 244         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 245             if $debuglevel >= 3;
 246         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 247         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 248         next if !$all and $ix eq $iy;
 249         printdebug sprintf
 250             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 251             !!$all,$x,$y, $n,$ix,$iy
 252             if $debuglevel >= 2;
 253         $call->($n, $ix, $iy);
 254     }
 255 }
 256
 257 sub get_differs ($$) {
 258     my ($x,$y) = @_;
 259     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 260     # But we don't care about modes, or dpkg-source-unrepresentable
 261     # changes, and we don't need the plethora of different modes.
 262     # Conversely we need to distinguish different kinds of changes to
 263     # debian/ and debian/patches/.
 264     # Also, here we have, and want to use, trees_diff_walk, because
 265     # we may be calling this an awful lot and we want it to be fast.
 266
 267     my $differs = 0;
 268     my @debian_info;
 269
 270     no warnings qw(exiting);
 271
 272     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 273
 274     trees_diff_walk "$x:", "$y:", sub {
 275         my ($n,$ix,$iy) = @_;
 276
 277         # analyse difference at the toplevel
 278
 279         if ($n ne 'debian/') {
 280             $differs |= D_UPS;
 281             next;
 282         }
 283         if ($n eq 'debian') {
 284             # one side has a non-tree for ./debian !
 285             $differs |= D_DEB_OTH;
 286             next;
 287         }
 288
 289         my $xd = $ix && "$x:debian";
 290         my $yd = $iy && "$y:debian";
 291         trees_diff_walk $xd, $yd, sub {
 292             my ($n,$ix,$iy) = @_;
 293
 294             # analyse difference in debian/
 295
 296             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 297                                   &&          $plain->($iy) ) {
 298                 $differs |= D_DEB_CLOG;
 299                 next;
 300             }
 301             if ($n ne 'patches/') {
 302                 $differs |= D_DEB_OTH;
 303                 next;
 304             }
 305
 306             my $xp = $ix && "$xd/patches";
 307             my $yp = $iy && "$yd/patches";
 308             trees_diff_walk $xp, $yp, sub {
 309                 my ($n,$ix,$iy) = @_;
 310
 311                 # analyse difference in debian/patches
 312
 313                 my $ok;
 314                 if ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 315                     $ok = 1;
 316                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 317                     my $x_s = (git_cat_file "$xp/series", 'blob');
 318                     my $y_s = (git_cat_file "$yp/series", 'blob');
 319                     chomp $x_s;  $x_s .= "\n";
 320                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 321                 } else {
 322                     # nope
 323                 }
 324                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 325             };
 326         };
 327     };
 328
 329     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 330
 331     return $differs;
 332 }
 333
 334 sub commit_pr_info ($) {
 335     my ($r) = @_;
 336     return Data::Dumper->dump([$r], [qw(commit)]);
 337 }
 338
 339 sub calculate_committer_authline () {
 340     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 341         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 342     my ($h,$m) = get_commit $c;
 343     $h =~ m/^committer .*$/m or confess "($h) ?";
 344     return $&;
 345 }
 346
 347 sub rm_subdir_cached ($) {
 348     my ($subdir) = @_;
 349     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 350 }
 351
 352 sub read_tree_subdir ($$) {
 353     my ($subdir, $new_tree_object) = @_;
 354     rm_subdir_cached $subdir;
 355     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 356 }
 357
 358 sub read_tree_debian ($) {
 359     my ($treeish) = @_;
 360     read_tree_subdir 'debian', "$treeish:debian";
 361     rm_subdir_cached 'debian/patches';
 362 }
 363
 364 sub read_tree_upstream ($;$$) {
 365     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 366     # if $tree_with_debian is supplied, will use that for debian/
 367     # otherwise will save and restore it.
 368     my $debian =
 369         $tree_with_debian ? "$tree_with_debian:debian"
 370         : cmdoutput @git, qw(write-tree --prefix=debian/);
 371     runcmd @git, qw(read-tree), $treeish;
 372     read_tree_subdir 'debian', $debian;
 373     rm_subdir_cached 'debian/patches' unless $keep_patches;
 374 };
 375
 376 sub make_commit ($$) {
 377     my ($parents, $message_paras) = @_;
 378     my $tree = cmdoutput @git, qw(write-tree);
 379     my @cmd = (@git, qw(commit-tree), $tree);
 380     push @cmd, qw(-p), $_ foreach @$parents;
 381     push @cmd, qw(-m), $_ foreach @$message_paras;
 382     return cmdoutput @cmd;
 383 }
 384
 385 our @snag_force_opts;
 386 sub snag ($$;@) {
 387     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 388     if (grep { $_ eq $tag } @snag_force_opts) {
 389         $snags_forced++;
 390         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 391     } else {
 392         $snags_tripped++;
 393         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 394     }
 395 }
 396
 397 # Important: all mainline code must call snags_maybe_bail after
 398 # any point where snag might be called, but before making changes
 399 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 400 # may be called more than once if necessary (but this is not ideal
 401 # because then the messages about number of snags may be confusing).
 402 sub snags_maybe_bail () {
 403     return if all_snags_summarised();
 404     if ($snags_forced) {
 405         printf STDERR
 406             "%s: snags: %d overriden by individual -f options\n",
 407             $us, $snags_forced;
 408     }
 409     if ($snags_tripped) {
 410         if ($opt_force) {
 411             printf STDERR
 412                 "%s: snags: %d overriden by global --force\n",
 413                 $us, $snags_tripped;
 414         } else {
 415             fail sprintf
 416   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 417                 $us, $snags_tripped;
 418         }
 419     }
 420     $snags_summarised = $snags_forced + $snags_tripped;
 421 }
 422 sub snags_maybe_bail_early () {
 423     # useful to bail out early without doing a lot of work;
 424     # not a substitute for snags_maybe_bail.
 425     snags_maybe_bail() if $snags_tripped && !$opt_force;
 426 }
 427 sub any_snags () {
 428     return $snags_forced || $snags_tripped;
 429 }
 430
 431 sub ffq_prev_branchinfo () {
 432     my $current = git_get_symref();
 433     return gdr_ffq_prev_branchinfo($current);
 434 }
 435
 436 sub record_gdrlast ($$;$) {
 437     my ($gdrlast, $newvalue, $oldvalue) = @_;
 438     $oldvalue ||= $git_null_obj;
 439     push @deferred_updates, "update $gdrlast $newvalue $oldvalue";
 440 }
 441
 442 sub fail_unprocessable ($) {
 443     my ($msg) = @_;
 444     fail $msg;
 445 };
 446
 447 sub gbp_pq_export ($$$) {
 448     my ($bname, $base, $tip) = @_;
 449     # must be run in a workarea.  $bname and patch-queue/$bname
 450     # ought not to exist.  Leaves you on patch-queue/$bname with
 451     # the patches staged but not committed.
 452     printdebug "gbp_pq_export $bname $base $tip\n";
 453     runcmd @git, qw(checkout -q -b), $bname, $base;
 454     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 455     my @gbp_cmd = (qw(gbp pq export));
 456     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 457     if ($r) {
 458         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 459         failedcmd @gbp_cmd;
 460     }
 461     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 462 }
 463
 464
 465 # MERGE-TODO allow merge resolution separately from laundering, before git merge
 466
 467 # later/rework?
 468 #  use git-format-patch?
 469 #  our own patch identification algorithm?
 470 #  this is an alternative strategy
 471
 472 sub merge_failed ($$;@) {
 473     my ($wrecknotes, $emsg, @xmsgs) = @_;
 474     my @m;
 475     push @m, "Merge resolution failed: $emsg";
 476     push @m, @xmsgs;
 477
 478     changedir $maindir;
 479
 480     my @updates;
 481     merge_wreckage_cleaning \@updates;
 482     run_ref_updates_now "merge failed", \@updates;
 483
 484     @updates = ();
 485     keys %$wrecknotes;
 486     while (my ($k,$v) = each %$wrecknotes) {
 487         push @updates, "create $wrecknoteprefix/$k $v";
 488     }
 489     run_ref_updates_now "merge failed", \@updates;
 490     push @m, "Wreckage left in $wrecknoteprefix/*.";
 491
 492     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 493
 494     # use finish rather than fail, in case we are within an eval
 495     # (that can happen inside walk!)
 496     print STDERR "\n";
 497     print STDERR "$us: $_\n" foreach @m;
 498     finish 15;
 499 }
 500
 501 sub mwrecknote ($$$) {
 502     my ($wrecknotes, $reftail, $commitish) = @_;
 503     confess unless defined $commitish;
 504     printdebug "mwrecknote $reftail $commitish\n";
 505     $wrecknotes->{$reftail} = $commitish;
 506 }
 507
 508 sub merge_attempt_cmd {
 509     my $wrecknotes = shift @_;
 510     debugcmd '+', @_;
 511     $!=0; $?=-1;
 512     if (system @_) {
 513         merge_failed $wrecknotes,
 514             failedcmd_waitstatus(),
 515             "failed command: @_";
 516     }
 517 }
 518
 519 sub merge_series_patchqueue_convert ($$$);
 520
 521 sub merge_series ($$$;@) {
 522     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 523     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 524     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 525     # ^ specifies several patch series (currently we only support exactly 2)
 526     # return value is a commit which is the result of
 527     # merging the two versions of the same topic branch
 528     #   $input_q[0] and $input_q[1]
 529     # with respect to the old version
 530     #   $base_q
 531     # all onto $newbase.
 532
 533     # Creates, in *_q, a key MR for its private use
 534
 535     printdebug "merge_series newbase=$newbase\n";
 536
 537     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 538     $base_q->{MR}{S} = 'base';
 539
 540     my %prereq;
 541     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 542     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 543     # $prereq{<patch filename>}               exists or not (even later)
 544
 545     my $merged_pq;
 546
 547     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 548
 549     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 550
 551     local $workarea;
 552     fresh_workarea "merge";
 553     my $seriesfile = "debian/patches/series";
 554     in_workarea sub {
 555         playtree_setup();
 556         foreach my $q ($base_q, reverse @input_qs) {
 557             my $s = $q->{MR}{S};
 558             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 559             my @earlier;
 560             if (open S, $seriesfile) {
 561                 while (my $patch = <S>) {
 562                     chomp $patch or die $!;
 563                     $prereq{$patch} //= {};
 564                     foreach my $earlier (@earlier) {
 565                         $prereq{$patch}{$earlier}{$s}++ and die;
 566                     }
 567                     push @earlier, $patch;
 568                     stat "debian/patches/$patch" or die "$patch ?";
 569                 }
 570                 S->error and die "$seriesfile $!";
 571                 close S;
 572             } else {
 573                 die "$seriesfile $!" unless $!==ENOENT;
 574             }
 575             read_tree_upstream $newbase, 1;
 576             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 577                 "Convert $s to patch queue for merging",
 578                 "[git-debrebase merge-innards patch-queue import:".
 579                 " $q->{SeriesTip}]"
 580             ];
 581             printdebug "merge_series  pec $pec ";
 582             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 583             $pec = make_commit [ $pec ], [
 584                 "Drop series file from $s to avoid merge trouble",
 585                 "[git-debrebase merge-innards patch-queue prep:".
 586                 " $q->{SeriesTip}]"
 587             ];
 588
 589             read_tree_debian $newbase;
 590             if (@earlier) {
 591                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 592             } else {
 593                 rm_subdir_cached 'debian/patches';
 594             }
 595             $pec = make_commit [ $pec ], [
 596  "Update debian/ (excluding patches) to final to avoid re-merging",
 597  "debian/ was already merged and we need to just take that.",
 598                 "[git-debrebase merge-innards patch-queue packaging:".
 599                 " $q->{SeriesTip}]"
 600             ];
 601
 602             printdebug "pec' $pec\n";
 603             runcmd @git, qw(reset -q --hard), $pec;
 604             $q->{MR}{PEC} = $pec;
 605             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 606         }
 607         # now, because of reverse, we are on $input_q->{MR}{OQC}
 608         runcmd @git, qw(checkout -q -b merge);
 609         printdebug "merge_series merging...\n";
 610         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 611
 612         $attempt_cmd->(@mergecmd);
 613
 614         printdebug "merge_series merge ok, series...\n";
 615         # We need to construct a new series file
 616         # Firstly, resolve prereq
 617         foreach my $f (sort keys %prereq) {
 618             printdebug "merge_series  patch\t$f\t";
 619             if (!stat_exists "debian/patches/$f") {
 620                 print DEBUG " drop\n" if $debuglevel;
 621                 # git merge deleted it; that's how we tell it's not wanted
 622                 delete $prereq{$f};
 623                 next;
 624             }
 625             print DEBUG " keep\n" if $debuglevel;
 626             foreach my $g (sort keys %{ $prereq{$f} }) {
 627                 my $gfp = $prereq{$f}{$g};
 628                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 629                 if (!!$gfp->{0} == !!$gfp->{1}
 630                     ? $gfp->{0}
 631                     : !$gfp->{base}) {
 632                     print DEBUG "\tkeep\n" if $debuglevel;
 633                 } else {
 634                     print DEBUG "\tdrop\n" if $debuglevel;
 635                     delete $prereq{$f}{$g};
 636                 }
 637             }
 638         }
 639
 640         my $unsat = sub {
 641             my ($f) = @_;
 642             return scalar keys %{ $prereq{$f} };
 643         };
 644
 645         my $nodate = time + 1;
 646         my %authordate;
 647         # $authordate{<patch filename>};
 648         my $authordate = sub {
 649             my ($f) = @_;
 650             $authordate{$f} //= do {
 651                 open PF, "<", "debian/patches/$f" or die "$f $!";
 652                 while (<PF>) {
 653                     return $nodate if m/^$/;
 654                     last if s{^Date: }{};
 655                 }
 656                 chomp;
 657                 return cmdoutput qw(date +%s -d), $_;
 658             };
 659         };
 660
 661         open NS, '>', $seriesfile or die $!;
 662
 663         while (keys %prereq) {
 664             my $best;
 665             foreach my $try (sort keys %prereq) {
 666                 if ($best) {
 667                     next if (
 668                              $unsat->($try) <=> $unsat->($best) or
 669                              $authordate->($try) <=> $authordate->($best) or
 670                              $try cmp $best
 671                             ) >= 0;
 672                 }
 673                 $best = $try;
 674             }
 675             printdebug "merge_series series next $best\n";
 676             print NS "$best\n" or die $!;
 677             delete $prereq{$best};
 678             foreach my $gp (values %prereq) {
 679                 delete $gp->{$best};
 680             }
 681         }
 682
 683         runcmd @git, qw(add), $seriesfile;
 684         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 685         $merged_pq = git_rev_parse 'HEAD';
 686         $mwrecknote->('merged-patchqueue', $merged_pq);
 687     };
 688     return merge_series_patchqueue_convert
 689             $wrecknotes, $newbase, $merged_pq;
 690 }
 691
 692 sub merge_series_patchqueue_convert ($$$) {
 693     my ($wrecknotes, $newbase, $merged_pq) = @_;
 694
 695     my $result;
 696     in_workarea sub {
 697         playtree_setup();
 698         printdebug "merge_series series gbp pq import\n";
 699         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 700
 701         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 702         # MERGE-TODO consider git-format-patch etc. instead,
 703         # since gbp pq doesn't always round-trip :-/
 704
 705         # OK now we are on patch-queue/merge, and we need to rebase
 706         # onto the intended parent and drop the patches from each one
 707
 708         printdebug "merge_series series ok, building...\n";
 709         my $build = $newbase;
 710         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 711         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 712             my $commit = git_cat_file $c, 'commit';
 713             printdebug "merge_series series ok, building $c\n";
 714             read_tree_upstream $c, 0, $newbase;
 715             my $tree = cmdoutput @git, qw(write-tree);
 716             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 717             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 718             open C, ">", "../mcommit" or die $!;
 719             print C $commit or die $!;
 720             close C or die $!;
 721             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 722         }
 723         $result = $build;
 724         mwrecknote($wrecknotes, 'merged-result', $result);
 725
 726         runcmd @git, qw(update-ref refs/heads/result), $result;
 727
 728         runcmd @git, qw(checkout -q -b debug);
 729         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 730         runcmd @git, qw(add .);
 731         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 732         my $mdebug = git_rev_parse 'HEAD';
 733         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 734         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 735     };
 736     printdebug "merge_series returns $result\n";
 737     return $result;
 738 }
 739
 740 # classify returns an info hash like this
 741 #   CommitId => $objid
 742 #   Hdr => # commit headers, including 1 final newline
 743 #   Msg => # commit message (so one newline is dropped)
 744 #   Tree => $treeobjid
 745 #   Type => (see below)
 746 #   Parents = [ {
 747 #       Ix => $index # ie 0, 1, 2, ...
 748 #       CommitId
 749 #       Differs => return value from get_differs
 750 #       IsOrigin
 751 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 752 #     } ...]
 753 #   NewMsg => # commit message, but with any [dgit import ...] edited
 754 #             # to say "[was: ...]"
 755 #
 756 # Types:
 757 #   Packaging
 758 #   Changelog
 759 #   Upstream
 760 #   AddPatches
 761 #   Mixed
 762 #
 763 #   Pseudomerge
 764 #     has additional entres in classification result
 765 #       Overwritten = [ subset of Parents ]
 766 #       Contributor = $the_remaining_Parent
 767 #
 768 #   DgitImportUnpatched
 769 #     has additional entry in classification result
 770 #       OrigParents = [ subset of Parents ]
 771 #
 772 #   Anchor
 773 #     has additional entry in classification result
 774 #       OrigParents = [ subset of Parents ]  # singleton list
 775 #
 776 #   TreatAsAnchor
 777 #
 778 #   BreakwaterStart
 779 #
 780 #   Unknown
 781 #     has additional entry in classification result
 782 #       Why => "prose"
 783
 784 sub parsecommit ($;$) {
 785     my ($objid, $p_ref) = @_;
 786     # => hash with                   CommitId Hdr Msg Tree Parents
 787     #    Parents entries have only   Ix CommitId
 788     #    $p_ref, if provided, must be [] and is used as a base for Parents
 789
 790     $p_ref //= [];
 791     die if @$p_ref;
 792
 793     my ($h,$m) = get_commit $objid;
 794
 795     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 796     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 797
 798     my $r = {
 799         CommitId => $objid,
 800         Hdr => $h,
 801         Msg => $m,
 802         Tree => $t,
 803         Parents => $p_ref,
 804     };
 805
 806     foreach my $ph (@ph) {
 807         push @$p_ref, {
 808             Ix => scalar @$p_ref,
 809             CommitId => $ph,
 810         };
 811     }
 812
 813     return $r;
 814 }
 815
 816 sub classify ($) {
 817     my ($objid) = @_;
 818
 819     my @p;
 820     my $r = parsecommit($objid, \@p);
 821     my $t = $r->{Tree};
 822
 823     foreach my $p (@p) {
 824         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 825     }
 826
 827     printdebug "classify $objid \$t=$t \@p",
 828         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 829         "\n";
 830
 831     my $classify = sub {
 832         my ($type, @rest) = @_;
 833         $r = { %$r, Type => $type, @rest };
 834         if ($debuglevel) {
 835             printdebug " = $type ".(dd $r)."\n";
 836         }
 837         return $r;
 838     };
 839     my $unknown = sub {
 840         my ($why) = @_;
 841         $r = { %$r, Type => qw(Unknown), Why => $why };
 842         printdebug " ** Unknown\n";
 843         return $r;
 844     };
 845
 846     if (grep { $_ eq $objid } @opt_anchors) {
 847         return $classify->('TreatAsAnchor');
 848     }
 849
 850     my @identical = grep { !$_->{Differs} } @p;
 851     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 852     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 853
 854     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 855         # multi-orig upstreams are represented with an anchor merge
 856         # from a single upstream commit which combines the orig tarballs
 857
 858         # Every anchor tagged this way must be a merge.
 859         # We are relying on the
 860         #     [git-debrebase anchor: ...]
 861         # commit message annotation in "declare" anchor merges (which
 862         # do not have any upstream changes), to distinguish those
 863         # anchor merges from ordinary pseudomerges (which we might
 864         # just try to strip).
 865         #
 866         # However, the user is going to be doing git-rebase a lot.  We
 867         # really don't want them to rewrite an anchor commit.
 868         # git-rebase trips up on merges, so that is a useful safety
 869         # catch.
 870         #
 871         # BreakwaterStart commits are also anchors in the terminology
 872         # of git-debrebase(5), but they are untagged (and always
 873         # manually generated).
 874         #
 875         # We cannot not tolerate any tagged linear commit (ie,
 876         # BreakwaterStart commits tagged `[anchor:') because such a
 877         # thing could result from an erroneous linearising raw git
 878         # rebase of a merge anchor.  That would represent a corruption
 879         # of the branch. and we want to detect and reject the results
 880         # of such corruption before it makes it out anywhere.  If we
 881         # reject it here then we avoid making the pseudomerge which
 882         # would be needed to push it.
 883
 884         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 885         @p == 2 or return $badanchor->("has other than two parents");
 886         $haspatches and return $badanchor->("contains debian/patches");
 887
 888         # How to decide about l/r ordering of anchors ?  git
 889         # --topo-order prefers to expand 2nd parent first.  There's
 890         # already an easy rune to look for debian/ history anyway (git log
 891         # debian/) so debian breakwater branch should be 1st parent; that
 892         # way also there's also an easy rune to look for the upstream
 893         # patches (--topo-order).
 894
 895         # Also this makes --first-parent be slightly more likely to
 896         # be useful - it makes it provide a linearised breakwater history.
 897
 898         # Of course one can say somthing like
 899         #  gitk -- ':/' ':!/debian'
 900         # to get _just_ the commits touching upstream files, and by
 901         # the TREESAME logic in git-rev-list this will leave the
 902         # breakwater into upstream at the first anchor.  But that
 903         # doesn't report debian/ changes at all.
 904
 905         # Other observations about gitk: by default, gitk seems to
 906         # produce output in a different order to git-rev-list.  I
 907         # can't seem to find this documented anywhere.  gitk
 908         # --date-order DTRT.  But, gitk always seems to put the
 909         # parents from left to right, in order, so it's easy to see
 910         # which way round a pseudomerge is.
 911
 912         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 913         $p[1]{Differs} & ~DS_DEB and
 914             $badanchor->("upstream files differ from left parent");
 915         $p[0]{Differs} & ~D_UPS and
 916             $badanchor->("debian/ differs from right parent");
 917
 918         return $classify->(qw(Anchor),
 919                            OrigParents => [ $p[1] ]);
 920     }
 921
 922     if (@p == 1) {
 923         my $d = $r->{Parents}[0]{Differs};
 924         if ($d == D_PAT_ADD) {
 925             return $classify->(qw(AddPatches));
 926         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 927             return $unknown->("edits debian/patches");
 928         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 929             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 930             if ($ty eq 'tree') {
 931                 if ($d == D_DEB_CLOG) {
 932                     return $classify->(qw(Changelog));
 933                 } else {
 934                     return $classify->(qw(Packaging));
 935                 }
 936             } elsif ($ty eq 'missing') {
 937                 return $classify->(qw(BreakwaterStart));
 938             } else {
 939                 return $unknown->("parent's debian is not a directory");
 940             }
 941         } elsif ($d == D_UPS) {
 942             return $classify->(qw(Upstream));
 943         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 944             return $classify->(qw(Mixed));
 945         } elsif ($d == 0) {
 946             return $unknown->("no changes");
 947         } else {
 948             confess "internal error $objid ?";
 949         }
 950     }
 951     if (!@p) {
 952         return $unknown->("origin commit");
 953     }
 954
 955     if (@p == 2 && @identical == 1) {
 956         my @overwritten = grep { $_->{Differs} } @p;
 957         confess "internal error $objid ?" unless @overwritten==1;
 958         return $classify->(qw(Pseudomerge),
 959                            Overwritten => [ $overwritten[0] ],
 960                            Contributor => $identical[0]);
 961     }
 962     if (@p == 2 && @identical == 2) {
 963         my $get_t = sub {
 964             my ($ph,$pm) = get_commit $_[0]{CommitId};
 965             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 966             $1;
 967         };
 968         my @bytime = @p;
 969         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 970         if ($order > 0) { # newer first
 971         } elsif ($order < 0) {
 972             @bytime = reverse @bytime;
 973         } else {
 974             # same age, default to order made by -s ours
 975             # that is, commit was made by someone who preferred L
 976         }
 977         return $classify->(qw(Pseudomerge),
 978                            SubType => qw(Ambiguous),
 979                            Contributor => $bytime[0],
 980                            Overwritten => [ $bytime[1] ]);
 981     }
 982     foreach my $p (@p) {
 983         my ($p_h, $p_m) = get_commit $p->{CommitId};
 984         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 985         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 986     }
 987     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 988     my $m2 = $r->{Msg};
 989     if (!(grep { !$_->{IsOrigin} } @p) and
 990         (@orig_ps >= @p - 1) and
 991         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 992         $r->{NewMsg} = $m2;
 993         return $classify->(qw(DgitImportUnpatched),
 994                            OrigParents => \@orig_ps);
 995     }
 996
 997     if (@p == 2 and
 998         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 999         return $classify->("MergedBreakwaters");
1000     }
1001     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
1002         return $unknown->("unknown kind of merge from $1");
1003     }
1004     if (@p > 2) {
1005         return $unknown->("octopus merge");
1006     }
1007
1008     if (!$opt_merges) {
1009         return $unknown->("general two-parent merge");
1010     }
1011
1012     return $classify->("VanillaMerge");
1013 }
1014
1015 sub keycommits ($;$$$$$);
1016
1017 sub mergedbreakwaters_anchor ($) {
1018     my ($cl) = @_;
1019     my $best_anchor;
1020     foreach my $p (@{ $cl->{Parents} }) {
1021         my ($panchor, $pbw) = keycommits $p->{CommitId},
1022             undef,undef,undef,undef, 1;
1023         $best_anchor = $panchor
1024             if !defined $best_anchor
1025             or is_fast_fwd $best_anchor, $panchor;
1026         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
1027             unless is_fast_fwd $panchor, $best_anchor;
1028     }
1029     return $best_anchor;
1030 }
1031
1032 sub keycommits ($;$$$$$) {
1033     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1034     # => ($anchor, $breakwater)
1035
1036     # $unclean->("unclean-$tagsfx", $msg, $cl)
1037     # $furniture->("unclean-$tagsfx", $msg, $cl)
1038     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1039     #   is callled for each situation or commit that
1040     #   wouldn't be found in a laundered branch
1041     # $furniture is for furniture commits such as might be found on an
1042     #   interchange branch (pseudomerge, d/patches, changelog)
1043     # $trouble is for things whnich prevent the return of
1044     #   anchor and breakwater information; if that is ignored,
1045     #   then keycommits returns (undef, undef) instead.
1046     # $fatal is for unprocessable commits, and should normally cause
1047     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1048     #
1049     # If $claimed_bw, this is supposed to be a breakwater commit.
1050     #
1051     # If a callback is undef, fail is called instead.
1052     # If a callback is defined but false, the situation is ignored.
1053     # Callbacks may say:
1054     #   no warnings qw(exiting); last;
1055     # if the answer is no longer wanted.
1056
1057     my ($anchor, $breakwater);
1058     $breakwater = $head if $claimed_bw;
1059     my $clogonly;
1060     my $cl;
1061     my $found_pm;
1062     $fatal //= sub { fail_unprocessable $_[1]; };
1063     my $x = sub {
1064         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1065         my $why = $mainwhy.$xwhy;
1066         my $m = "branch needs laundering (run git-debrebase): $why";
1067         fail $m unless defined $cb;
1068         return unless $cb;
1069         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1070     };
1071     my $found_anchor = sub {
1072         ($anchor) = @_;
1073         $breakwater //= $clogonly;
1074         $breakwater //= $head;
1075         no warnings qw(exiting);
1076         last;
1077     };
1078     for (;;) {
1079         $cl = classify $head;
1080         my $ty = $cl->{Type};
1081         if ($ty eq 'Packaging') {
1082             $breakwater //= $clogonly;
1083             $breakwater //= $head;
1084         } elsif ($ty eq 'Changelog') {
1085             # this is going to count as the tip of the breakwater
1086             # only if it has no upstream stuff before it
1087             $clogonly //= $head;
1088         } elsif ($ty eq 'Anchor' or
1089                  $ty eq 'TreatAsAnchor' or
1090                  $ty eq 'BreakwaterStart') {
1091             $found_anchor->($head);
1092         } elsif ($ty eq 'Upstream') {
1093             $x->($unclean, 'ordering',
1094  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1095                 if defined $breakwater;
1096             $clogonly = undef;
1097             $breakwater = undef;
1098         } elsif ($ty eq 'Mixed') {
1099             $x->($unclean, 'mixed',
1100                  "found mixed upstream/packaging commit"," ($head)");
1101             $clogonly = undef;
1102             $breakwater = undef;
1103         } elsif ($ty eq 'Pseudomerge' or
1104                  $ty eq 'AddPatches') {
1105             my $found_pm = 1;
1106             $x->($furniture, (lc $ty),
1107                  "found interchange bureaucracy commit ($ty)"," ($head)");
1108         } elsif ($ty eq 'DgitImportUnpatched') {
1109             if ($found_pm) {
1110                 $x->($trouble, 'dgitimport',
1111                      "found dgit dsc import"," ($head)");
1112                 return (undef,undef);
1113             } else {
1114                 $x->($fatal, 'unprocessable',
1115                      "found bare dgit dsc import with no prior history",
1116                      " ($head)");
1117                 return (undef,undef);
1118             }
1119         } elsif ($ty eq 'VanillaMerge') {
1120             $x->($trouble, 'vanillamerge',
1121                  "found vanilla merge"," ($head)");
1122             return (undef,undef);
1123         } elsif ($ty eq 'MergedBreakwaters') {
1124             $found_anchor->(mergedbreakwaters_anchor $cl);
1125         } else {
1126             $x->($fatal, 'unprocessable',
1127                  "found unprocessable commit, cannot cope: $cl->{Why}",
1128                  " ($head)");
1129             return (undef,undef);
1130         }
1131         $head = $cl->{Parents}[0]{CommitId};
1132     }
1133     return ($anchor, $breakwater);
1134 }
1135
1136 sub walk ($;$$$);
1137 sub walk ($;$$$) {
1138     my ($input,
1139         $nogenerate,$report, $report_lprefix) = @_;
1140     # => ($tip, $breakwater_tip, $last_anchor)
1141     # (or nothing, if $nogenerate)
1142
1143     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1144     $report_lprefix //= '';
1145
1146     # go through commits backwards
1147     # we generate two lists of commits to apply:
1148     # breakwater branch and upstream patches
1149     my (@brw_cl, @upp_cl, @processed);
1150     my %found;
1151     my $upp_limit;
1152     my @pseudomerges;
1153
1154     my $cl;
1155     my $xmsg = sub {
1156         my ($prose, $info) = @_;
1157         my $ms = $cl->{Msg};
1158         chomp $ms;
1159         $info //= '';
1160         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1161         return (Msg => $ms);
1162     };
1163     my $rewrite_from_here = sub {
1164         my ($cl) = @_;
1165         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1166         push @$cl, $sp_cl;
1167         push @processed, $sp_cl;
1168     };
1169     my $cur = $input;
1170
1171     my $prdelim = "";
1172     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1173
1174     my $prline = sub {
1175         return unless $report;
1176         print $report $prdelim, $report_lprefix, @_;
1177         $prdelim = "\n";
1178     };
1179
1180     my $bomb = sub { # usage: return $bomb->();
1181         print $report " Unprocessable" if $report;
1182         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1183         $prprdelim->();
1184         if ($nogenerate) {
1185             return (undef,undef);
1186         }
1187         fail_unprocessable "found unprocessable commit, cannot cope".
1188             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1189             " (commit $cur) (d.".
1190             (join ' ', map { sprintf "%#x", $_->{Differs} }
1191              @{ $cl->{Parents} }).
1192                  ")";
1193     };
1194
1195     my $build;
1196     my $breakwater;
1197
1198     my $build_start = sub {
1199         my ($msg, $parent) = @_;
1200         $prline->(" $msg");
1201         $build = $parent;
1202         no warnings qw(exiting); last;
1203     };
1204
1205     my $nomerge = sub {
1206         my ($emsg) = @_;
1207         merge_failed $cl->{MergeWreckNotes}, $emsg;
1208     };
1209
1210     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1211
1212     my $last_anchor;
1213
1214     for (;;) {
1215         $cl = classify $cur;
1216         $cl->{MergeWreckNotes} //= {};
1217         my $ty = $cl->{Type};
1218         my $st = $cl->{SubType};
1219         $prline->("$cl->{CommitId} $cl->{Type}");
1220         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1221         push @processed, $cl;
1222         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1223         if ($ty eq 'AddPatches') {
1224             $cur = $p0;
1225             $rewrite_from_here->(\@upp_cl);
1226             next;
1227         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1228             push @brw_cl, $cl;
1229             $cur = $p0;
1230             next;
1231         } elsif ($ty eq 'BreakwaterStart') {
1232             $last_anchor = $cur;
1233             $build_start->('FirstPackaging', $cur);
1234         } elsif ($ty eq 'Upstream') {
1235             push @upp_cl, $cl;
1236             $cur = $p0;
1237             next;
1238         } elsif ($ty eq 'Mixed') {
1239             my $queue = sub {
1240                 my ($q, $wh) = @_;
1241                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1242                 push @$q, $cls;
1243             };
1244             $queue->(\@brw_cl, "debian");
1245             $queue->(\@upp_cl, "upstream");
1246             $rewrite_from_here->(\@brw_cl);
1247             $cur = $p0;
1248             next;
1249         } elsif ($ty eq 'Pseudomerge') {
1250             my $contrib = $cl->{Contributor}{CommitId};
1251             print $report " Contributor=$contrib" if $report;
1252             push @pseudomerges, $cl;
1253             $rewrite_from_here->(\@upp_cl);
1254             $cur = $contrib;
1255             next;
1256         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1257             $last_anchor = $cur;
1258             $build_start->("Anchor", $cur);
1259         } elsif ($ty eq 'DgitImportUnpatched') {
1260             my $pm = $pseudomerges[-1];
1261             if (defined $pm) {
1262                 # To an extent, this is heuristic.  Imports don't have
1263                 # a useful history of the debian/ branch.  We assume
1264                 # that the first pseudomerge after an import has a
1265                 # useful history of debian/, and ignore the histories
1266                 # from later pseudomerges.  Often the first pseudomerge
1267                 # will be the dgit import of the upload to the actual
1268                 # suite intended by the non-dgit NMUer, and later
1269                 # pseudomerges may represent in-archive copies.
1270                 my $ovwrs = $pm->{Overwritten};
1271                 printf $report " PM=%s \@Overwr:%d",
1272                     $pm->{CommitId}, (scalar @$ovwrs)
1273                     if $report;
1274                 if (@$ovwrs != 1) {
1275                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1276                     return $bomb->();
1277                 }
1278                 my $ovwr = $ovwrs->[0]{CommitId};
1279                 printf $report " Overwr=%s", $ovwr if $report;
1280                 # This import has a tree which is just like a
1281                 # breakwater tree, but it has the wrong history.  It
1282                 # ought to have the previous breakwater (which the
1283                 # pseudomerge overwrote) as an ancestor.  That will
1284                 # make the history of the debian/ files correct.  As
1285                 # for the upstream version: either it's the same as
1286                 # was ovewritten (ie, same as the previous
1287                 # breakwater), in which case that history is precisely
1288                 # right; or, otherwise, it was a non-gitish upload of a
1289                 # new upstream version.  We can tell these apart by
1290                 # looking at the tree of the supposed upstream.
1291                 push @brw_cl, {
1292                     %$cl,
1293                     SpecialMethod => 'DgitImportDebianUpdate',
1294                     $xmsg->("convert dgit import: debian changes")
1295                 }, {
1296                     %$cl,
1297                     SpecialMethod => 'DgitImportUpstreamUpdate',
1298                     $xmsg->("convert dgit import: upstream update",
1299                             " anchor")
1300                 };
1301                 $prline->(" Import");
1302                 $rewrite_from_here->(\@brw_cl);
1303                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1304                 $cur = $ovwr;
1305                 next;
1306             } else {
1307                 # Everything is from this import.  This kind of import
1308                 # is already nearly in valid breakwater format, with the
1309                 # patches as commits.  Unfortunately it contains
1310                 # debian/patches/.
1311                 printdebug "*** WALK BOMB bare dgit import\n";
1312                 $cl->{Why} = "bare dgit dsc import";
1313                 return $bomb->();
1314             }
1315             die "$ty ?";
1316         } elsif ($ty eq 'MergedBreakwaters') {
1317             $last_anchor = mergedbreakwaters_anchor $cl;
1318             $build_start->(' MergedBreakwaters', $cur);
1319             last;
1320         } elsif ($ty eq 'VanillaMerge') {
1321             # User may have merged unstitched branch(es).  We will
1322             # have now lost what ffq-prev was then (since the later
1323             # pseudomerge may introduce further changes).  The effect
1324             # of resolving such a merge is that we may have to go back
1325             # further in history to find a merge base, since the one
1326             # which was reachable via ffq-prev is no longer findable.
1327             # This is suboptimal, but if it all works we'll have done
1328             # the right thing.
1329             # MERGE-TODO we should warn the user in the docs about this
1330
1331             my $ok=1;
1332             my $best_anchor;
1333             # We expect to find a dominating anchor amongst the
1334             # inputs' anchors.  That will be the new anchor.
1335             #
1336             # More complicated is finding a merge base for the
1337             # breakwaters.  We need a merge base that is a breakwater
1338             # commit.  The ancestors of breakwater commits are more
1339             # breakwater commits and possibly upstream commits and the
1340             # ancestors of those upstream.  Upstreams might have
1341             # arbitrary ancestors.  But any upstream commit U is
1342             # either included in both anchors, in which case the
1343             # earlier anchor is a better merge base than any of U's
1344             # ancestors; or U is not included in the older anchor, in
1345             # which case U is not an ancestor of the vanilla merge at
1346             # all.  So no upstream commit, nor any ancestor thereof,
1347             # is a best merge base.  As for non-breakwater Debian
1348             # commits: these are never ancestors of any breakwater.
1349             #
1350             # So any best merge base as found by git-merge-base
1351             # is a suitable breakwater anchor.  Usually there will
1352             # be only one.
1353
1354             printdebug "*** MERGE\n";
1355
1356             my @bwbcmd = (@git, qw(merge-base));
1357             my @ibcmd = (@git, qw(merge-base --all));
1358             my $might_be_in_bw = 1;
1359
1360             my $ps = $cl->{Parents};
1361
1362             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1363
1364             foreach my $p (@$ps) {
1365                 $prline->(" VanillaMerge ".$p->{Ix});
1366                 $prprdelim->();
1367                 my ($ptip, $pbw, $panchor) =
1368                     walk $p->{CommitId}, 0, $report,
1369                          $report_lprefix.'  ';
1370                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1371                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1372                 $p->{Anchor} = $panchor;
1373
1374                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1375                 $mwrecknote->("$lr-input", $p->{CommitId});
1376
1377                 my $mwrecknote_parent = sub {
1378                     my ($which) = @_;
1379                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1380                 };
1381                 $mwrecknote_parent->('Laundered');
1382                 $mwrecknote_parent->('Breakwater');
1383                 $mwrecknote_parent->('Anchor');
1384
1385                 $best_anchor = $panchor if
1386                     !defined $best_anchor or
1387                     is_fast_fwd $best_anchor, $panchor;
1388
1389                 printdebug " MERGE BA best=".($best_anchor//'-').
1390                     " p=$panchor\n";
1391             }
1392
1393             $mwrecknote->('result-anchor', $best_anchor);
1394
1395             foreach my $p (@$ps) {
1396                 $prline->(" VanillaMerge ".$p->{Ix});
1397                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1398                     $nomerge->('divergent anchors');
1399                 } elsif ($p->{Anchor} eq $best_anchor) {
1400                     print $report " SameAnchor" if $report;
1401                 } else {
1402                     print $report " SupersededAnchor" if $report;
1403                 }
1404                 if ($p->{Breakwater} eq $p->{CommitId}) {
1405                     # this parent commit was its own breakwater,
1406                     # ie it is part of the breakwater
1407                     print $report " Breakwater" if $report;
1408                 } else {
1409                     $might_be_in_bw = 0;
1410                 }
1411                 push @bwbcmd, $p->{Breakwater};
1412                 push @ibcmd, $p->{CommitId};
1413             }
1414
1415             if ($ok && $might_be_in_bw) {
1416                 # We could rewrite this to contaion the metadata
1417                 # declaring it to be MergedBreakwaters, but
1418                 # unnecessarily rewriting a merge seems unhelpful.
1419                 $prline->(" VanillaMerge MergedBreakwaters");
1420                 $last_anchor = $best_anchor;
1421                 $build_start->('MergedBreakwaters', $cur);
1422             }
1423
1424             my $bwb = cmdoutput @bwbcmd;
1425
1426             # OK, now we have a breakwater base, but we need the merge
1427             # base for the interchange branch because we need the delta
1428             # queue.
1429             #
1430             # This a the best merge base of our inputs which has the
1431             # breakwater merge base as an ancestor.
1432
1433             my @ibs =
1434                 grep /./,
1435                 split /\n/,
1436                 cmdoutput @ibcmd;
1437
1438             @ibs or confess 'internal error, expected anchor at least ?';
1439
1440             my $ib;
1441             my $ibleaf;
1442             foreach my $tibix (0..$#ibs) {
1443                 my $tib = $ibs[$tibix];
1444                 my $ff = is_fast_fwd $bwb, $tib;
1445                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1446                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1447                 $mwrecknote->($tibleaf, $tib);
1448                 next unless $ff;
1449                 next if $ib;
1450                 $ib = $tib;
1451                 $ibleaf = $tibleaf;
1452             }
1453
1454             $ib or $nomerge->("no suitable interchange merge base");
1455
1456             $prline->("  VanillaMerge Base");
1457             $prprdelim->();
1458             my ($btip, $bbw, $banchor) = eval {
1459                 walk $ib, 0, $report, $report_lprefix.'  ';
1460             };
1461             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1462                        $@)
1463                 if length $@;
1464
1465             $mwrecknote->("mergebase-laundered", $btip);
1466             $mwrecknote->("mergebase-breakwater", $bbw);
1467             $mwrecknote->("mergebase-anchor", $banchor);
1468
1469             my $ibinfo = { SeriesTip => $btip,
1470                            SeriesBase => $bbw,
1471                            Anchor => $banchor,
1472                            LeftRight => 'mergebase' };
1473
1474             $bbw eq $bwb
1475                 or $nomerge->("interchange merge-base ($ib)'s".
1476                               " breakwater ($bbw)".
1477                               " != breakwaters' merge-base ($bwb)");
1478
1479             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1480                  or $nomerge->("interchange merge-base ($ib)'s".
1481                                " anchor ($ibinfo->{SeriesBase})".
1482                                " != any merge input's anchor (".
1483                                (join ' ', map { $_->{Anchor} } @$ps).
1484                                ")");
1485
1486             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1487             $cl->{MergeBestAnchor} = $best_anchor;
1488             push @brw_cl, {
1489                 %$cl,
1490                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1491                 $xmsg->('constructed from vanilla merge',
1492                         ' merged-breakwater'),
1493             };
1494             push @upp_cl, {
1495                 %$cl,
1496                 SpecialMethod => 'MergeMergeSeries',
1497             };
1498             $build_start->('MergeBreakwaters', $cur);
1499         } else {
1500             printdebug "*** WALK BOMB unrecognised\n";
1501             return $bomb->();
1502         }
1503     }
1504     $prprdelim->();
1505
1506     printdebug "*** WALK prep done cur=$cur".
1507         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1508
1509     return if $nogenerate;
1510
1511     # Now we build it back up again
1512
1513     fresh_workarea();
1514
1515     my $rewriting = 0;
1516
1517     $#upp_cl = $upp_limit if defined $upp_limit;
1518
1519     my $committer_authline = calculate_committer_authline();
1520
1521     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1522
1523     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1524
1525     in_workarea sub {
1526         mkdir $rd or $!==EEXIST or die $!;
1527         my $current_method;
1528         my $want_debian = $build;
1529         my $want_upstream = $build;
1530
1531         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1532         my $read_tree_debian = sub { ($want_debian) = @_; };
1533
1534         foreach my $cl (qw(Debian), (reverse @brw_cl),
1535                         { SpecialMethod => 'RecordBreakwaterTip' },
1536                         qw(Upstream), (reverse @upp_cl)) {
1537             if (!ref $cl) {
1538                 $current_method = $cl;
1539                 next;
1540             }
1541             my $method = $cl->{SpecialMethod} // $current_method;
1542             my @parents = ($build);
1543             my $cltree = $cl->{CommitId};
1544             printdebug "WALK BUILD ".($cltree//'undef').
1545                 " $method (rewriting=$rewriting)\n";
1546             if ($method eq 'Debian') {
1547                 $read_tree_debian->($cltree);
1548             } elsif ($method eq 'Upstream') {
1549                 $read_tree_upstream->($cltree);
1550             } elsif ($method eq 'StartRewrite') {
1551                 $rewriting = 1;
1552                 next;
1553             } elsif ($method eq 'RecordBreakwaterTip') {
1554                 $breakwater = $build;
1555                 next;
1556             } elsif ($method eq 'DgitImportDebianUpdate') {
1557                 $read_tree_debian->($cltree);
1558             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1559                 confess unless $rewriting;
1560                 my $differs = (get_differs $build, $cltree);
1561                 next unless $differs & D_UPS;
1562                 $read_tree_upstream->($cltree);
1563                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1564             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1565                 print "Found a general merge, will try to tidy it up.\n";
1566                 $rewriting = 1;
1567                 $read_tree_upstream->($cl->{MergeBestAnchor});
1568                 $read_tree_debian->($cltree);
1569                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1570             } elsif ($method eq 'MergeMergeSeries') {
1571                 my $cachehit = reflog_cache_lookup
1572                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1573                 if ($cachehit) {
1574                     print "Using supplied resolution for $cl->{CommitId}...\n";
1575                     $build = $cachehit;
1576                     $mwrecknote->('cached-resolution', $build);
1577                 } else {
1578                     print "Running merge resolution for $cl->{CommitId}...\n";
1579                     $mwrecknote->('new-base', $build);
1580                     $build = merge_series
1581                         $build, $cl->{MergeWreckNotes},
1582                         $cl->{MergeInterchangeBaseInfo},
1583                         @{ $cl->{Parents} };
1584                 }
1585                 $last_anchor = $cl->{MergeBestAnchor};
1586
1587                 # Check for mismerges:
1588                 my $check = sub {
1589                     my ($against, $allow, $what) = @_;
1590                     my $differs = get_differs $build, $against;
1591                     $nomerge->(sprintf
1592        "merge misresolved: %s are not the same (%s %s d.%#x)",
1593                                $what, $against, $build, $differs)
1594                         if $differs & ~($allow | D_PAT_ADD);
1595                 };
1596
1597                 # Breakwater changes which were in each side of the
1598                 # merge will have been incorporated into the
1599                 # MergeCreateMergedBreakwaters output.  Because the
1600                 # upstream series was rebased onto the new breakwater,
1601                 # so should all of the packaging changes which were in
1602                 # the input.
1603                 $check->($input, D_UPS, 'debian files');
1604
1605                 # Upstream files are merge_series, which ought to
1606                 # have been identical to the original merge.
1607                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1608
1609                 print "Merge resolution successful.\n";
1610                 next;
1611             } else {
1612                 confess "$method ?";
1613             }
1614             if (!$rewriting) {
1615                 my $procd = (pop @processed) // 'UNDEF';
1616                 if ($cl ne $procd) {
1617                     $rewriting = 1;
1618                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1619                 }
1620             }
1621             if ($rewriting) {
1622                 read_tree_upstream $want_upstream, 0, $want_debian;
1623
1624                 my $newtree = cmdoutput @git, qw(write-tree);
1625                 my $ch = $cl->{Hdr};
1626                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1627                 $ch =~ s{^parent .*\n}{}mg;
1628                 $ch =~ s{(?=^author)}{
1629                     join '', map { "parent $_\n" } @parents
1630                 }me or confess "$ch ?";
1631                 if ($rewriting) {
1632                     $ch =~ s{^committer .*$}{$committer_authline}m
1633                         or confess "$ch ?";
1634                 }
1635                 my $cf = "$rd/m$rewriting";
1636                 open CD, ">", $cf or die $!;
1637                 print CD $ch, "\n", $cl->{Msg} or die $!;
1638                 close CD or die $!;
1639                 my @cmd = (@git, qw(hash-object));
1640                 push @cmd, qw(-w) if $rewriting;
1641                 push @cmd, qw(-t commit), $cf;
1642                 my $newcommit = cmdoutput @cmd;
1643                 confess "$ch ?" unless $rewriting
1644                     or $newcommit eq $cl->{CommitId};
1645                 $build = $newcommit;
1646             } else {
1647                 $build = $cl->{CommitId};
1648                 trees_diff_walk "$want_upstream:", "$build:", sub {
1649                     my ($n) = @_;
1650                     no warnings qw(exiting);
1651                     next if $n eq 'debian/';
1652                     confess "mismatch @_ ?";
1653                 };
1654                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1655                     confess "mismatch @_ ?";
1656                 };
1657                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1658                 confess "mismatch @parents != @old_parents ?"
1659                     unless "@parents" eq "@old_parents";
1660             }
1661             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1662                 $last_anchor = $cur;
1663             }
1664         }
1665     };
1666
1667     my $final_check = get_differs $build, $input;
1668     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1669         if $final_check & ~D_PAT_ADD;
1670
1671     my @r = ($build, $breakwater, $last_anchor);
1672     printdebug "*** WALK RETURN @r\n";
1673     return @r
1674 }
1675
1676 sub get_head () {
1677     git_check_unmodified();
1678     return git_rev_parse qw(HEAD);
1679 }
1680
1681 sub update_head ($$$) {
1682     my ($old, $new, $mrest) = @_;
1683     push @deferred_updates, "update HEAD $new $old";
1684     run_deferred_updates $mrest;
1685 }
1686
1687 sub update_head_checkout ($$$) {
1688     my ($old, $new, $mrest) = @_;
1689     update_head $old, $new, $mrest;
1690     runcmd @git, qw(reset --hard);
1691 }
1692
1693 sub update_head_postlaunder ($$$) {
1694     my ($old, $tip, $reflogmsg) = @_;
1695     return if $tip eq $old && !@deferred_updates;
1696     print "git-debrebase: laundered (head was $old)\n";
1697     update_head $old, $tip, $reflogmsg;
1698     # no tree changes except debian/patches
1699     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1700 }
1701
1702 sub currently_rebasing() {
1703     foreach (qw(rebase-merge rebase-apply)) {
1704         return 1 if stat_exists "$maindir_gitdir/$_";
1705     }
1706     return 0;
1707 }
1708
1709 sub bail_if_rebasing() {
1710     fail "you are in the middle of a git-rebase already"
1711         if currently_rebasing();
1712 }
1713
1714 sub do_launder_head ($) {
1715     my ($reflogmsg) = @_;
1716     my $old = get_head();
1717     record_ffq_auto();
1718     my ($tip,$breakwater) = walk $old;
1719     snags_maybe_bail();
1720     update_head_postlaunder $old, $tip, $reflogmsg;
1721     return ($tip,$breakwater);
1722 }
1723
1724 sub cmd_launder_v0 () {
1725     badusage "no arguments to launder-v0 allowed" if @ARGV;
1726     my $old = get_head();
1727     my ($tip,$breakwater,$last_anchor) = walk $old;
1728     update_head_postlaunder $old, $tip, 'launder';
1729     printf "# breakwater tip\n%s\n", $breakwater;
1730     printf "# working tip\n%s\n", $tip;
1731     printf "# last anchor\n%s\n", $last_anchor;
1732 }
1733
1734 sub defaultcmd_rebase () {
1735     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1736     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1737     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1738 }
1739
1740 sub cmd_analyse () {
1741     badusage "analyse does not support any options"
1742         if @ARGV and $ARGV[0] =~ m/^-/;
1743     badusage "too many arguments to analyse" if @ARGV>1;
1744     my ($old) = @ARGV;
1745     if (defined $old) {
1746         $old = git_rev_parse $old;
1747     } else {
1748         $old = git_rev_parse 'HEAD';
1749     }
1750     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1751     STDOUT->error and die $!;
1752 }
1753
1754 sub ffq_check ($;$$) {
1755     # calls $ff and/or $notff zero or more times
1756     # then returns either (status,message) where status is
1757     #    exists
1758     #    detached
1759     #    weird-symref
1760     #    notbranch
1761     # or (undef,undef, $ffq_prev,$gdrlast)
1762     # $ff and $notff are called like this:
1763     #   $ff->("message for stdout\n");
1764     #   $notff->('snag-name', $message);
1765     # normally $currentval should be HEAD
1766     my ($currentval, $ff, $notff) =@_;
1767
1768     $ff //= sub { print $_[0] or die $!; };
1769     $notff //= \&snag;
1770
1771     my ($status, $message, $current, $ffq_prev, $gdrlast)
1772         = ffq_prev_branchinfo();
1773     return ($status, $message) unless $status eq 'branch';
1774
1775     my $exists = git_get_ref $ffq_prev;
1776     return ('exists',"$ffq_prev already exists") if $exists;
1777
1778     return ('not-branch', 'HEAD symref is not to refs/heads/')
1779         unless $current =~ m{^refs/heads/};
1780     my $branch = $';
1781
1782     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1783     my %checked;
1784
1785     printdebug "ffq check_specs @check_specs\n";
1786
1787     my $check = sub {
1788         my ($lrref, $desc) = @_;
1789         printdebug "ffq might check $lrref ($desc)\n";
1790         my $invert;
1791         for my $chk (@check_specs) {
1792             my $glob = $chk;
1793             $invert = $glob =~ s{^[!^]}{};
1794             last if fnmatch $glob, $lrref;
1795         }
1796         return if $invert;
1797         my $lrval = git_get_ref $lrref;
1798         return unless length $lrval;
1799
1800         if (is_fast_fwd $lrval, $currentval) {
1801             $ff->("OK, you are ahead of $lrref\n");
1802             $checked{$lrref} = 1;
1803         } elsif (is_fast_fwd $currentval, $lrval) {
1804             $checked{$lrref} = -1;
1805             $notff->('behind', "you are behind $lrref, divergence risk");
1806         } else {
1807             $checked{$lrref} = -1;
1808             $notff->('diverged', "you have diverged from $lrref");
1809         }
1810     };
1811
1812     my $merge = cfg "branch.$branch.merge",1;
1813     if (defined $merge and $merge =~ m{^refs/heads/}) {
1814         my $rhs = $';
1815         printdebug "ffq merge $rhs\n";
1816         my $check_remote = sub {
1817             my ($remote, $desc) = @_;
1818             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1819             return unless defined $remote;
1820             $check->("refs/remotes/$remote/$rhs", $desc);
1821         };
1822         $check_remote->((scalar cfg "branch.$branch.remote",1),
1823                         'remote fetch/merge branch');
1824         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1825                         (scalar cfg "branch.$branch.pushDefault",1),
1826                         'remote push branch');
1827     }
1828     if ($branch =~ m{^dgit/}) {
1829         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1830     } elsif ($branch =~ m{^master$}) {
1831         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1832     }
1833     return (undef, undef, $ffq_prev, $gdrlast);
1834 }
1835
1836 sub record_ffq_prev_deferred () {
1837     # => ('status', "message")
1838     # 'status' may be
1839     #    deferred          message is undef
1840     #    exists
1841     #    detached
1842     #    weird-symref
1843     #    notbranch
1844     # if not ff from some branch we should be ff from, is an snag
1845     # if "deferred", will have added something about that to
1846     #   @deferred_update_messages, and also maybe printed (already)
1847     #   some messages about ff checks
1848     bail_if_rebasing();
1849     my $currentval = get_head();
1850
1851     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1852     return ($status,$message) if defined $status;
1853
1854     snags_maybe_bail();
1855
1856     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1857     push @deferred_updates, "delete $gdrlast";
1858     push @deferred_update_messages, "Recorded previous head for preservation";
1859     return ('deferred', undef);
1860 }
1861
1862 sub record_ffq_auto () {
1863     my ($status, $message) = record_ffq_prev_deferred();
1864     if ($status eq 'deferred' || $status eq 'exists') {
1865     } else {
1866         snag $status, "could not record ffq-prev: $message";
1867         snags_maybe_bail();
1868     }
1869 }
1870
1871 sub ffq_prev_info () {
1872     bail_if_rebasing();
1873     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1874     my ($status, $message, $current, $ffq_prev, $gdrlast)
1875         = ffq_prev_branchinfo();
1876     if ($status ne 'branch') {
1877         snag $status, "could not check ffq-prev: $message";
1878         snags_maybe_bail();
1879     }
1880     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1881     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1882 }
1883
1884 sub stitch ($$$$$) {
1885     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1886
1887     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1888
1889     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1890         my $differs = get_differs $old_head, $ffq_prev_commitish;
1891         unless ($differs & ~D_PAT_ADD) {
1892             # ffq-prev is ahead of us, and the only tree changes it has
1893             # are possibly addition of things in debian/patches/.
1894             # Just wind forwards rather than making a pointless pseudomerge.
1895             record_gdrlast $gdrlast, $ffq_prev_commitish;
1896             update_head_checkout $old_head, $ffq_prev_commitish,
1897                 "stitch (fast forward)";
1898             return;
1899         }
1900     }
1901     fresh_workarea();
1902     # We make pseudomerges with L as the contributing parent.
1903     # This makes git rev-list --first-parent work properly.
1904     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1905         'Declare fast forward / record previous work',
1906         "[git-debrebase pseudomerge: $prose]",
1907     ];
1908     record_gdrlast $gdrlast, $new_head;
1909     update_head $old_head, $new_head, "stitch: $prose";
1910 }
1911
1912 sub do_stitch ($;$) {
1913     my ($prose, $unclean) = @_;
1914
1915     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1916     if (!$ffq_prev_commitish) {
1917         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1918         return;
1919     }
1920     my $dangling_head = get_head();
1921
1922     keycommits $dangling_head, $unclean,$unclean,$unclean;
1923     snags_maybe_bail();
1924
1925     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1926 }
1927
1928 sub upstream_commitish_search ($$) {
1929     my ($upstream_version, $tried) = @_;
1930     # todo: at some point maybe use git-deborig to do this
1931     foreach my $tagpfx ('', 'v', 'upstream/') {
1932         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1933         my $new_upstream = git_get_ref "refs/tags/$tag";
1934         push @$tried, $tag;
1935         return $new_upstream if length $new_upstream;
1936     }
1937 }
1938
1939 sub resolve_upstream_version ($$) {
1940     my ($new_upstream, $upstream_version) = @_;
1941
1942     if (!defined $new_upstream) {
1943         my @tried;
1944         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1945         if (!length $new_upstream) {
1946             fail "Could not determine appropriate upstream commitish.\n".
1947                 " (Tried these tags: @tried)\n".
1948                 " Check version, and specify upstream commitish explicitly.";
1949         }
1950     }
1951     $new_upstream = git_rev_parse $new_upstream;
1952
1953     return $new_upstream;
1954 }
1955
1956 sub cmd_new_upstream () {
1957     # automatically and unconditionally launders before rebasing
1958     # if rebase --abort is used, laundering has still been done
1959
1960     my %pieces;
1961
1962     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1963
1964     # parse args - low commitment
1965     my $spec_version = shift @ARGV;
1966     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1967     fail "bad version number \`$spec_version'" unless defined $new_version;
1968     if ($new_version->is_native()) {
1969         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1970     }
1971
1972     my $new_upstream = shift @ARGV;
1973     my $new_upstream_version = upstreamversion  $new_version;
1974     $new_upstream =
1975         resolve_upstream_version $new_upstream, $new_upstream_version;
1976
1977     record_ffq_auto();
1978
1979     my $piece = sub {
1980         my ($n, @x) = @_; # may be ''
1981         my $pc = $pieces{$n} //= {
1982             Name => $n,
1983             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1984         };
1985         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1986         $pc;
1987     };
1988
1989     my @newpieces;
1990     my $newpiece = sub {
1991         my ($n, @x) = @_; # may be ''
1992         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1993         push @newpieces, $pc;
1994     };
1995
1996     $newpiece->('',
1997         OldIx => 0,
1998         New => $new_upstream,
1999     );
2000     while (@ARGV && $ARGV[0] !~ m{^-}) {
2001         my $n = shift @ARGV;
2002
2003         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
2004             unless @ARGV && $ARGV[0] !~ m{^-};
2005
2006         my $c = git_rev_parse shift @ARGV;
2007         die unless $n =~ m/^$extra_orig_namepart_re$/;
2008         $newpiece->($n, New => $c);
2009     }
2010
2011     # now we need to investigate the branch this generates the
2012     # laundered version but we don't switch to it yet
2013     my $old_head = get_head();
2014     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2015
2016     my $old_bw_cl = classify $old_bw;
2017     my $old_anchor_cl = classify $old_anchor;
2018     my $old_upstream;
2019     if (!$old_anchor_cl->{OrigParents}) {
2020         snag 'anchor-treated',
2021             'old anchor is recognised due to --anchor, cannot check upstream';
2022     } else {
2023         $old_upstream = parsecommit
2024             $old_anchor_cl->{OrigParents}[0]{CommitId};
2025         $piece->('', Old => $old_upstream->{CommitId});
2026     }
2027
2028     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2029         if ($old_upstream->{Msg} =~
2030  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2031            ) {
2032             my @oldpieces = (split / /, $1);
2033             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2034             if ($old_n_parents != @oldpieces &&
2035                 $old_n_parents != @oldpieces + 1) {
2036                 snag 'upstream-confusing', sprintf
2037                     "previous upstream combine %s".
2038                     " mentions %d pieces (each implying one parent)".
2039                     " but has %d parents".
2040                     " (one per piece plus maybe a previous combine)",
2041                     $old_upstream->{CommitId},
2042                     (scalar @oldpieces),
2043                     $old_n_parents;
2044             } elsif ($oldpieces[0] ne '.') {
2045                 snag 'upstream-confusing', sprintf
2046                     "previous upstream combine %s".
2047                     " first piece is not \`.'",
2048                     $oldpieces[0];
2049             } else {
2050                 $oldpieces[0] = '';
2051                 foreach my $i (0..$#oldpieces) {
2052                     my $n = $oldpieces[$i];
2053                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2054                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2055                 }
2056             }
2057         } else {
2058             snag 'upstream-confusing',
2059                 "previous upstream $old_upstream->{CommitId} is from".
2060                " git-debrebase but not an \`upstream-combine' commit";
2061         }
2062     }
2063
2064     foreach my $pc (values %pieces) {
2065         if (!$old_upstream) {
2066             # we have complained already
2067         } elsif (!$pc->{Old}) {
2068             snag 'upstream-new-piece',
2069                 "introducing upstream piece \`$pc->{Name}'";
2070         } elsif (!$pc->{New}) {
2071             snag 'upstream-rm-piece',
2072                 "dropping upstream piece \`$pc->{Name}'";
2073         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2074             snag 'upstream-not-ff',
2075                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2076         }
2077     }
2078
2079     printdebug "%pieces = ", (dd \%pieces), "\n";
2080     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2081
2082     snags_maybe_bail();
2083
2084     my $new_bw;
2085
2086     fresh_workarea();
2087     in_workarea sub {
2088         my @upstream_merge_parents;
2089
2090         if (!any_snags()) {
2091             push @upstream_merge_parents, $old_upstream->{CommitId};
2092         }
2093
2094         foreach my $pc (@newpieces) { # always has '' first
2095             if ($pc->{Name}) {
2096                 read_tree_subdir $pc->{Name}, $pc->{New};
2097             } else {
2098                 runcmd @git, qw(read-tree), $pc->{New};
2099             }
2100             push @upstream_merge_parents, $pc->{New};
2101         }
2102
2103         # index now contains the new upstream
2104
2105         if (@newpieces > 1) {
2106             # need to make the upstream subtree merge commit
2107             $new_upstream = make_commit \@upstream_merge_parents,
2108                 [ "Combine upstreams for $new_upstream_version",
2109  ("[git-debrebase upstream-combine . ".
2110  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2111  ": new upstream]"),
2112                 ];
2113         }
2114
2115         # $new_upstream is either the single upstream commit, or the
2116         # combined commit we just made.  Either way it will be the
2117         # "upstream" parent of the anchor merge.
2118
2119         read_tree_subdir 'debian', "$old_bw:debian";
2120
2121         # index now contains the anchor merge contents
2122         $new_bw = make_commit [ $old_bw, $new_upstream ],
2123             [ "Update to upstream $new_upstream_version",
2124  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2125             ];
2126
2127         my $clogsignoff = cmdoutput qw(git show),
2128             '--pretty=format:%an <%ae>  %aD',
2129             $new_bw;
2130
2131         # Now we have to add a changelog stanza so the Debian version
2132         # is right.
2133         die if unlink "debian";
2134         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2135         unlink "debian/changelog" or $!==ENOENT or die $!;
2136         mkdir "debian" or die $!;
2137         open CN, ">", "debian/changelog" or die $!;
2138         my $oldclog = git_cat_file ":debian/changelog";
2139         $oldclog =~ m/^($package_re) \(\S+\) / or
2140             fail "cannot parse old changelog to get package name";
2141         my $p = $1;
2142         print CN <<END, $oldclog or die $!;
2143 $p ($new_version) UNRELEASED; urgency=medium
2144
2145   * Update to new upstream version $new_upstream_version.
2146
2147  -- $clogsignoff
2148
2149 END
2150         close CN or die $!;
2151         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2152
2153         # Now we have the final new breakwater branch in the index
2154         $new_bw = make_commit [ $new_bw ],
2155             [ "Update changelog for new upstream $new_upstream_version",
2156               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2157             ];
2158     };
2159
2160     # we have constructed the new breakwater. we now need to commit to
2161     # the laundering output, because git-rebase can't easily be made
2162     # to make a replay list which is based on some other branch
2163
2164     update_head_postlaunder $old_head, $old_laundered_tip,
2165         'launder for new upstream';
2166
2167     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2168     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2169         "debrebase new-upstream $new_version: rebase";
2170     runcmd @cmd;
2171     # now it's for the user to sort out
2172 }
2173
2174 sub cmd_record_ffq_prev () {
2175     badusage "no arguments allowed" if @ARGV;
2176     my ($status, $msg) = record_ffq_prev_deferred();
2177     if ($status eq 'exists' && $opt_noop_ok) {
2178         print "Previous head already recorded\n" or die $!;
2179     } elsif ($status eq 'deferred') {
2180         run_deferred_updates 'record-ffq-prev';
2181     } else {
2182         fail "Could not preserve: $msg";
2183     }
2184 }
2185
2186 sub cmd_anchor () {
2187     badusage "no arguments allowed" if @ARGV;
2188     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2189     print "$bw\n" or die $!;
2190 }
2191
2192 sub cmd_breakwater () {
2193     badusage "no arguments allowed" if @ARGV;
2194     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2195     print "$bw\n" or die $!;
2196 }
2197
2198 sub cmd_status () {
2199     badusage "no arguments allowed" if @ARGV;
2200
2201     # todo: gdr status should print divergence info
2202     # todo: gdr status should print upstream component(s) info
2203     # todo: gdr should leave/maintain some refs with this kind of info ?
2204
2205     my $oldest = { Badness => 0 };
2206     my $newest;
2207     my $note = sub {
2208         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2209         if ($oldest->{Badness} < $badness) {
2210             $oldest = $newest = undef;
2211         }
2212         $oldest = {
2213                    Badness => $badness,
2214                    CommitId => $cl->{CommitId},
2215                    OurMsg => $ourmsg,
2216                    KcMsg => $kcmsg,
2217                   };
2218         $newest //= $oldest;
2219     };
2220     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2221         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2222         sub { $note->(2, 'branch is unlaundered', @_); },
2223         sub { $note->(3, 'branch needs laundering', @_); },
2224         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2225
2226     my $prcommitinfo = sub {
2227         my ($cid) = @_;
2228         flush STDOUT or die $!;
2229         runcmd @git, qw(--no-pager log -n1),
2230             '--pretty=format:    %h %s%n',
2231             $cid;
2232     };
2233
2234     print "current branch contents, in git-debrebase terms:\n";
2235     if (!$oldest->{Badness}) {
2236         print "  branch is laundered\n";
2237     } else {
2238         print "  $oldest->{OurMsg}\n";
2239         my $printed = '';
2240         foreach my $info ($oldest, $newest) {
2241             my $cid = $info->{CommitId};
2242             next if $cid eq $printed;
2243             $printed = $cid;
2244             print "  $info->{KcMsg}\n";
2245             $prcommitinfo->($cid);
2246         }
2247     }
2248
2249     my $prab = sub {
2250         my ($cid, $what) = @_;
2251         if (!defined $cid) {
2252             print "  $what is not well-defined\n";
2253         } else {
2254             print "  $what\n";
2255             $prcommitinfo->($cid);
2256         }
2257     };
2258     print "key git-debrebase commits:\n";
2259     $prab->($anchor, 'anchor');
2260     $prab->($bw, 'breakwater');
2261
2262     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2263         ffq_prev_branchinfo();
2264
2265     print "branch and ref status, in git-debrebase terms:\n";
2266     if ($ffq_msg) {
2267         print "  $ffq_msg\n";
2268     } else {
2269         $ffq_prev = git_get_ref $ffq_prev;
2270         $gdrlast = git_get_ref $gdrlast;
2271         if ($ffq_prev) {
2272             print "  unstitched; previous tip was:\n";
2273             $prcommitinfo->($ffq_prev);
2274         } elsif (!$gdrlast) {
2275             print "  stitched? (no record of git-debrebase work)\n";
2276         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2277             print "  stitched\n";
2278         } else {
2279             print "  not git-debrebase (diverged since last stitch)\n"
2280         }
2281     }
2282     print "you are currently rebasing\n" if currently_rebasing();
2283 }
2284
2285 sub cmd_stitch () {
2286     my $prose = 'stitch';
2287     getoptions("stitch",
2288                'prose=s', \$prose);
2289     badusage "no arguments allowed" if @ARGV;
2290     do_stitch $prose, 0;
2291 }
2292 sub cmd_prepush () {
2293     $opt_noop_ok = 1;
2294     cmd_stitch();
2295 }
2296
2297 sub cmd_quick () {
2298     badusage "no arguments allowed" if @ARGV;
2299     do_launder_head 'launder for git-debrebase quick';
2300     do_stitch 'quick';
2301 }
2302
2303 sub cmd_conclude () {
2304     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2305     if (!$ffq_prev_commitish) {
2306         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2307         return;
2308     }
2309     my $dangling_head = get_head();
2310
2311     badusage "no arguments allowed" if @ARGV;
2312     do_launder_head 'launder for git-debrebase quick';
2313     do_stitch 'quick';
2314 }
2315
2316 sub cmd_scrap () {
2317     if (currently_rebasing()) {
2318         runcmd @git, qw(rebase --abort);
2319         push @deferred_updates, 'verify HEAD HEAD';
2320         # noop, but stops us complaining that scrap was a noop
2321     }
2322     badusage "no arguments allowed" if @ARGV;
2323     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2324     my $scrapping_head;
2325     if ($ffq_prev_commitish) {
2326         $scrapping_head = get_head();
2327         push @deferred_updates,
2328             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2329             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2330     }
2331     if (git_get_ref $merge_cache_ref) {
2332         push @deferred_updates,
2333             "delete $merge_cache_ref";
2334     }
2335     if (!@deferred_updates) {
2336         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2337         finish 0;
2338     }
2339     snags_maybe_bail();
2340     if ($scrapping_head) {
2341         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2342     } else {
2343         run_deferred_updates "scrap";
2344     }
2345 }
2346
2347 sub make_patches_staged ($) {
2348     my ($head) = @_;
2349     # Produces the patches that would result from $head if it were
2350     # laundered.
2351     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2352     fresh_workarea();
2353     in_workarea sub {
2354         gbp_pq_export 'bw', $secret_bw, $secret_head;
2355     };
2356 }
2357
2358 sub make_patches ($) {
2359     my ($head) = @_;
2360     keycommits $head, 0, \&snag;
2361     make_patches_staged $head;
2362     my $out;
2363     in_workarea sub {
2364         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2365         runcmd @git, qw(read-tree), $head;
2366         read_tree_subdir 'debian/patches', $ptree;
2367         $out = make_commit [$head], [
2368             'Commit patch queue (exported by git-debrebase)',
2369             '[git-debrebase: export and commit patches]',
2370         ];
2371     };
2372     return $out;
2373 }
2374
2375 sub cmd_make_patches () {
2376     my $opt_quiet_would_amend;
2377     getoptions("make-patches",
2378                'quiet-would-amend!', \$opt_quiet_would_amend);
2379     badusage "no arguments allowed" if @ARGV;
2380     bail_if_rebasing();
2381     my $old_head = get_head();
2382     my $new = make_patches $old_head;
2383     my $d = get_differs $old_head, $new;
2384     if ($d == 0) {
2385         fail "No (more) patches to export." unless $opt_noop_ok;
2386         return;
2387     } elsif ($d == D_PAT_ADD) {
2388         snags_maybe_bail();
2389         update_head_checkout $old_head, $new, 'make-patches';
2390     } else {
2391         print STDERR failmsg
2392             "Patch export produced patch amendments".
2393             " (abandoned output commit $new).".
2394             "  Try laundering first."
2395             unless $opt_quiet_would_amend;
2396         finish 7;
2397     }
2398 }
2399
2400 sub check_series_has_all_patches ($) {
2401     my ($head) = @_;
2402     my $seriesfn = 'debian/patches/series';
2403     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2404         [qw(blob missing)];
2405     $series //= '';
2406     my %series;
2407     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2408         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2409     }
2410     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2411         my ($f,$i) = @$patchfile;
2412         next if $series{$f};
2413         next if $f eq 'series';
2414         snag 'unused-patches', "Unused patch file $f will be discarded";
2415     }
2416 }
2417
2418 sub begin_convert_from () {
2419     my $head = get_head();
2420     my ($ffqs, $ffqm, $symref, $ffq_prev, $gdrlast) = ffq_prev_branchinfo();
2421
2422     fail "ffq-prev exists, this is already managed by git-debrebase!"
2423         if $ffq_prev && git_get_ref $ffq_prev;
2424
2425     my $gdrlast_obj = $gdrlast && git_get_ref $gdrlast;
2426     snag 'already-converted',
2427         "ahead of debrebase-last, this is already managed by git-debrebase!"
2428         if $gdrlast_obj && is_fast_fwd $gdrlast_obj, $head;
2429     return ($head, { LastRef => $gdrlast, LastObj => $gdrlast_obj });
2430 }
2431
2432 sub complete_convert_from ($$$$) {
2433     my ($old_head, $new_head, $gi, $mrest) = @_;
2434     ffq_check $new_head;
2435     record_gdrlast $gi->{LastRef}, $new_head, $gi->{LastObj}
2436         if $gi->{LastRef};
2437     snags_maybe_bail();
2438     update_head_checkout $old_head, $new_head, $mrest;
2439 }
2440
2441 sub cmd_convert_from_gbp () {
2442     badusage "want only 1 optional argument, the upstream git commitish"
2443         unless @ARGV<=1;
2444
2445     my $clogp = parsechangelog();
2446     my $version = $clogp->{'Version'}
2447         // die "missing Version from changelog";
2448
2449     my ($upstream_spec) = @ARGV;
2450
2451     my $upstream_version = upstreamversion $version;
2452     my $upstream =
2453         resolve_upstream_version($upstream_spec, $upstream_version);
2454
2455     my ($old_head, $gdrlastinfo) = begin_convert_from();
2456
2457     my $upsdiff = get_differs $upstream, $old_head;
2458     if ($upsdiff & D_UPS) {
2459         runcmd @git, qw(--no-pager diff --stat),
2460             $upstream, $old_head,
2461             qw( -- :!/debian :/);
2462         fail <<END;
2463 upstream ($upstream_spec) and HEAD are not
2464 identical in upstream files.  See diffstat above, or run
2465   git diff $upstream_spec HEAD -- :!/debian :/
2466 END
2467     }
2468
2469     if (!is_fast_fwd $upstream, $old_head) {
2470         snag 'upstream-not-ancestor',
2471             "upstream ($upstream) is not an ancestor of HEAD";
2472     } else {
2473         my $wrong = cmdoutput
2474             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2475              qw(-- :/ :!/debian));
2476         if (length $wrong) {
2477             snag 'unexpected-upstream-changes',
2478                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2479             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2480         }
2481     }
2482
2483     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2484         snag 'upstream-has-debian',
2485             "upstream ($upstream) contains debian/ directory";
2486     }
2487
2488     check_series_has_all_patches $old_head;
2489
2490     my $previous_dgit_view = eval {
2491         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2492         my ($lvsn, $suite);
2493         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2494             my ($stz, $desc) = @_;
2495             no warnings qw(exiting);
2496             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2497             next unless $stz->{Date};
2498             next unless $stz->{Distribution} ne 'UNRELEASED';
2499             $lvsn = $stz->{Version};
2500             $suite = $stz->{Distribution};
2501             last;
2502         };
2503         die "neither of the first two changelog entries are released\n"
2504             unless defined $lvsn;
2505         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2506         my $mtag_pat = debiantag_maintview $lvsn, '*';
2507         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2508             $mtag_pat;
2509         die "could not find suitable maintainer view tag $mtag_pat\n"
2510             unless $mtag =~ m{/};
2511         is_fast_fwd $mtag, 'HEAD' or
2512             die "HEAD is not FF from maintainer tag $mtag!";
2513         my $dtag = "archive/$mtag";
2514         git_get_ref "refs/tags/$dtag" or
2515             die "dgit view tag $dtag not found\n";
2516         is_fast_fwd $mtag, $dtag or
2517             die "dgit view tag $dtag is not FF from maintainer tag $mtag\n";
2518         print "will stitch in dgit view, $dtag\n";
2519         git_rev_parse $dtag;
2520     };
2521     if (!$previous_dgit_view) {
2522         $@ =~ s/^\n+//;
2523         chomp $@;
2524         print STDERR <<END;
2525 Cannot confirm dgit view: $@
2526 Failed to stitch in dgit view (see messages above).
2527 dgit --overwrite will be needed on the first dgit push after conversion.
2528 END
2529     }
2530
2531     snags_maybe_bail_early();
2532
2533     my $work;
2534
2535     fresh_workarea();
2536     in_workarea sub {
2537         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2538         # make a branch out of the patch queue - we'll want this in a mo
2539         runcmd qw(gbp pq import);
2540         # strip the patches out
2541         runcmd @git, qw(checkout -q gdr-internal~0);
2542         rm_subdir_cached 'debian/patches';
2543         $work = make_commit ['HEAD'], [
2544  'git-debrebase convert-from-gbp: drop patches from tree',
2545  'Delete debian/patches, as part of converting to git-debrebase format.',
2546  '[git-debrebase convert-from-gbp: drop patches from tree]'
2547                               ];
2548         # make the anchor merge
2549         # the tree is already exactly right
2550         $work = make_commit [$work, $upstream], [
2551  'git-debrebase import: declare upstream',
2552  'First breakwater merge.',
2553  '[git-debrebase anchor: declare upstream]'
2554                               ];
2555
2556         # rebase the patch queue onto the new breakwater
2557         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2558         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2559         $work = git_rev_parse 'HEAD';
2560
2561         if ($previous_dgit_view) {
2562             $work = make_commit [$work, $previous_dgit_view], [
2563  'git-debrebase import: declare ff from dgit archive view',
2564  '[git-debrebase pseudomerge: import-from-gbp]',
2565             ];
2566         }
2567     };
2568
2569     complete_convert_from $old_head, $work, $gdrlastinfo, 'convert-from-gbp';
2570     print <<END or die $!;
2571 git-debrebase: converted from patched-unapplied (gbp) branch format, OK
2572 END
2573 }
2574
2575 sub cmd_convert_to_gbp () {
2576     badusage "no arguments allowed" if @ARGV;
2577     my $head = get_head();
2578     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2579     keycommits $head, 0;
2580     my $out;
2581     make_patches_staged $head;
2582     in_workarea sub {
2583         $out = make_commit ['HEAD'], [
2584             'Commit patch queue (converted from git-debrebase format)',
2585             '[git-debrebase convert-to-gbp: commit patches]',
2586         ];
2587     };
2588     if (defined $ffq) {
2589         push @deferred_updates, "delete $ffq";
2590         push @deferred_updates, "delete $gdrlast";
2591     }
2592     snags_maybe_bail();
2593     update_head_checkout $head, $out, "convert to gbp (v0)";
2594     print <<END or die $!;
2595 git-debrebase: converted to git-buildpackage branch format
2596 git-debrebase: WARNING: do not now run "git-debrebase" any more
2597 git-debrebase: WARNING: doing so would drop all upstream patches!
2598 END
2599 }
2600
2601 sub cmd_convert_from_dgit_view () {
2602     my $clogp = parsechangelog();
2603
2604     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2605     my $do_origs = 1;
2606     my $do_tags = 1;
2607     my $always = 0;
2608     my $diagnose = 0;
2609
2610     getoptions("convert-from-dgit-view",
2611                'diagnose!', \$diagnose,
2612                'build-products-dir:s', \$bpd,
2613                'origs!', \$do_origs,
2614                'tags!', \$do_tags,
2615                'always-convert-anyway!', \$always);
2616     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2617
2618     my @upstreams;
2619
2620     if (@ARGV) {
2621         my $spec = shift @ARGV;
2622         my $commit = git_rev_parse "$spec^{commit}";
2623         push @upstreams, { Commit => $commit,
2624                            Source => "$ARGV[0], from command line",
2625                            Only => 1,
2626                          };
2627     }
2628
2629     my ($head, $gdrlastinfo) = begin_convert_from();
2630
2631     if (!$always) {
2632         my $troubles = 0;
2633         my $trouble = sub { $troubles++; };
2634         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2635         printdebug "troubles=$troubles\n";
2636         if (!$troubles) {
2637             print STDERR <<END;
2638 $us: Branch already seems to be in git-debrebase format!
2639 $us: --always-convert-anyway would do the conversion operation anyway
2640 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2641 END
2642             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2643             finish 0;
2644         }
2645     }
2646
2647     check_series_has_all_patches $head;
2648
2649     snags_maybe_bail_early();
2650
2651     my $version = upstreamversion $clogp->{Version};
2652     print STDERR "Considering possible commits corresponding to upstream:\n";
2653
2654     if (!@upstreams) {
2655         if ($do_tags) {
2656             my @tried;
2657             my $ups_tag = upstream_commitish_search $version, \@tried;
2658             if ($ups_tag) {
2659                 my $this = "git tag $tried[-1]";
2660                 push @upstreams, { Commit => $ups_tag,
2661                                    Source => $this,
2662                                  };
2663             } else {
2664                 printf STDERR
2665                     " git tag: no suitable tag found (tried %s)\n",
2666                     "@tried";
2667             }
2668         }
2669         if ($do_origs) {
2670             my $p = $clogp->{'Source'};
2671             # we do a quick check to see if there are plausible origs
2672             my $something=0;
2673             if (!opendir BPD, $bpd) {
2674                 die "$bpd: opendir: $!" unless $!==ENOENT;
2675             } else {
2676                 while ($!=0, my $f = readdir BPD) {
2677                     next unless is_orig_file_of_p_v $f, $p, $version;
2678                     printf STDERR
2679                         " orig: found what looks like a .orig, %s\n",
2680                         "$bpd/$f";
2681                     $something=1;
2682                     last;
2683                 }
2684                 die "read $bpd: $!" if $!;
2685                 closedir BPD;
2686             }
2687             if ($something) {
2688                 my $tree = cmdoutput
2689                     @dgit, qw(--build-products-dir), $bpd,
2690                     qw(print-unapplied-treeish);
2691                 fresh_workarea();
2692                 in_workarea sub {
2693                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2694                     rm_subdir_cached 'debian';
2695                     $tree = cmdoutput @git, qw(write-tree);
2696                     my $ups_synth = make_commit [], [ <<END, <<END,
2697 Import effective orig tree for upstream version $version
2698 END
2699 This includes the contents of the .orig(s), minus any debian/ directory.
2700
2701 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2702 END
2703                                                     ];
2704                     push @upstreams, { Commit => $ups_synth,
2705                                        Source => "orig(s) imported via dgit",
2706                                      };
2707                 }
2708             } else {
2709                 printf STDERR
2710                     " orig: no suitable origs found (looked for %s in %s)\n",
2711                     "${p}_".(stripeoch $version)."...", $bpd;
2712             }
2713         }
2714     }
2715
2716     my $some_patches = stat_exists 'debian/patches/series';
2717
2718     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2719
2720     my $result;
2721     foreach my $u (@upstreams) {
2722         my $work = $head;
2723         fresh_workarea();
2724         in_workarea sub {
2725             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2726             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2727             runcmd @git, qw(clean -xdff);
2728             runcmd @git, qw(checkout), $head, qw(-- debian);
2729             if ($some_patches) {
2730                 rm_subdir_cached 'debian/patches';
2731                 $work = make_commit [ $work ], [
2732  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2733  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2734  "to git-debrebase format.  Upstream changes will appear as commits.",
2735  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2736                                            ];
2737             }
2738             $work = make_commit [ $work, $u->{Commit} ], [
2739  'git-debrebase convert-from-dgit-view: declare upstream',
2740  '(Re)constructed breakwater merge.',
2741  '[git-debrebase anchor: declare upstream]'
2742                                                          ];
2743             runcmd @git, qw(checkout --quiet -b mk), $work;
2744             if ($some_patches) {
2745                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2746                 runcmd @git, qw(reset --quiet);
2747                 my @gbp_cmd = (qw(gbp pq import));
2748                 if (!$diagnose) {
2749                     my $gbp_err = "../gbp-pq-err";
2750                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2751                 }
2752                 my $r = system @gbp_cmd;
2753                 if ($r) {
2754                     printf STDERR
2755                         " %s: couldn't apply patches: gbp pq %s",
2756                         $u->{Source}, waitstatusmsg();
2757                     return;
2758                 }
2759             }
2760             my $work = git_rev_parse qw(HEAD);
2761             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2762             if (length $diffout) {
2763                 print STDERR
2764                     " $u->{Source}: applying patches gives different tree\n";
2765                 print STDERR $diffout if $diagnose;
2766                 return;
2767             }
2768             # OMG!
2769             $u->{Result} = $work;
2770             $result = $u;
2771         };
2772         last if $result;
2773     }
2774
2775     if (!$result) {
2776         fail <<END;
2777 Could not find or construct a suitable upstream commit.
2778 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2779 upstream commmit explicitly or provide suitable origs.
2780 END
2781     }
2782
2783     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2784
2785     complete_convert_from $head, $result->{Result}, $gdrlastinfo,
2786         'convert-from-dgit-view';
2787 }
2788
2789 sub cmd_record_resolved_merge () {
2790     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2791     # MERGE-TODO needs documentation
2792     my $new = get_head();
2793     my $method;
2794
2795     print "Checking how you have resolved the merge problem\n";
2796     my $nope = sub { print "Not $method: @_"; 0; };
2797
2798     my $maybe = sub { print "Seems to be $method.\n"; };
2799     my $yes = sub {
2800         my ($key, $ref) = @_;
2801         reflog_cache_insert $merge_cache_ref, $key, $ref;
2802         print "OK.  You can switch branches and try git-debrebase again.\n";
2803         1;
2804     };
2805
2806     fresh_workarea 'merge';
2807     sub {
2808         $method = 'vanilla-merge patchqueue';
2809         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2810         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2811         foreach my $lr (qw(left right)) {
2812             my $n = "$wrecknoteprefix/$lr-patchqueue";
2813             my $lrpq = git_get_ref $n;
2814             $lrpq or return $nope->("wreckage did not contain patchqueues");
2815             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2816         }
2817         $maybe->();
2818         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2819             or die "wreckage element $wrecknoteprefix/new-base missing";
2820         my $result = merge_series_patchqueue_convert
2821             {}, $newbase, $new;
2822         $yes->("vanilla-merge $vanilla", $result);
2823         1;
2824     }->() or sub {
2825         fail "No resolved merge method seems applicable.\n";
2826     }->();
2827 }
2828
2829 sub cmd_downstream_rebase_launder_v0 () {
2830     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2831     my ($base) = @ARGV;
2832     $base = git_rev_parse $base;
2833     my $old_head = get_head();
2834     my $current = $old_head;
2835     my $topmost_keep;
2836     for (;;) {
2837         if ($current eq $base) {
2838             $topmost_keep //= $current;
2839             print " $current BASE stop\n";
2840             last;
2841         }
2842         my $cl = classify $current;
2843         print " $current $cl->{Type}";
2844         my $keep = 0;
2845         my $p0 = $cl->{Parents}[0]{CommitId};
2846         my $next;
2847         if ($cl->{Type} eq 'Pseudomerge') {
2848             print " ^".($cl->{Contributor}{Ix}+1);
2849             $next = $cl->{Contributor}{CommitId};
2850         } elsif ($cl->{Type} eq 'AddPatches' or
2851                  $cl->{Type} eq 'Changelog') {
2852             print " strip";
2853             $next = $p0;
2854         } else {
2855             print " keep";
2856             $next = $p0;
2857             $keep = 1;
2858         }
2859         print "\n";
2860         if ($keep) {
2861             $topmost_keep //= $current;
2862         } else {
2863             die "to-be stripped changes not on top of the branch\n"
2864                 if $topmost_keep;
2865         }
2866         $current = $next;
2867     }
2868     if ($topmost_keep eq $old_head) {
2869         print "unchanged\n";
2870     } else {
2871         print "updating to $topmost_keep\n";
2872         update_head_checkout
2873             $old_head, $topmost_keep,
2874             'downstream-rebase-launder-v0';
2875     }
2876 }
2877
2878 getoptions_main
2879           ("bad options\n",
2880            "D+" => \$debuglevel,
2881            'noop-ok', => \$opt_noop_ok,
2882            'f=s' => \@snag_force_opts,
2883            'anchor=s' => \@opt_anchors,
2884            '--dgit=s' => \($dgit[0]),
2885            'force!',
2886            'experimental-merge-resolution!', \$opt_merges,
2887            '-i:s' => sub {
2888                my ($opt,$val) = @_;
2889                badusage "git-debrebase: no cuddling to -i for git-rebase"
2890                    if length $val;
2891                die if $opt_defaultcmd_interactive; # should not happen
2892                $opt_defaultcmd_interactive = [ qw(-i) ];
2893                # This access to @ARGV is excessive familiarity with
2894                # Getopt::Long, but there isn't another sensible
2895                # approach.  '-i=s{0,}' does not work with bundling.
2896                push @$opt_defaultcmd_interactive, @ARGV;
2897                @ARGV=();
2898            },
2899            'help' => sub { print $usage_message or die $!; finish 0; },
2900            );
2901
2902 initdebug('git-debrebase ');
2903 enabledebug if $debuglevel;
2904
2905 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2906 chdir $toplevel or die "chdir $toplevel: $!";
2907
2908 $rd = fresh_playground "$playprefix/misc";
2909
2910 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2911
2912 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2913     defaultcmd_rebase();
2914 } else {
2915     my $cmd = shift @ARGV;
2916     my $cmdfn = $cmd;
2917     $cmdfn =~ y/-/_/;
2918     $cmdfn = ${*::}{"cmd_$cmdfn"};
2919
2920     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2921     $cmdfn->();
2922 }
2923
2924 finish 0;