git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$) {
 267     my ($treeish, $keep_patches) = @_;
 268     my $save = cmdoutput @git, qw(write-tree --prefix=debian/);
 269     runcmd @git, qw(read-tree), $treeish;
 270     read_tree_subdir 'debian', $save;
 271     rm_subdir_cached 'debian/patches' unless $keep_patches;
 272 };
 273
 274 sub make_commit ($$) {
 275     my ($parents, $message_paras) = @_;
 276     my $tree = cmdoutput @git, qw(write-tree);
 277     my @cmd = (@git, qw(commit-tree), $tree);
 278     push @cmd, qw(-p), $_ foreach @$parents;
 279     push @cmd, qw(-m), $_ foreach @$message_paras;
 280     return cmdoutput @cmd;
 281 }
 282
 283 our @snag_force_opts;
 284 sub snag ($$;@) {
 285     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 286     if (grep { $_ eq $tag } @snag_force_opts) {
 287         $snags_forced++;
 288         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 289     } else {
 290         $snags_tripped++;
 291         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 292     }
 293 }
 294
 295 # Important: all mainline code must call snags_maybe_bail after
 296 # any point where snag might be called, but before making changes
 297 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 298 # may be called more than once if necessary (but this is not ideal
 299 # because then the messages about number of snags may be confusing).
 300 sub snags_maybe_bail () {
 301     return if all_snags_summarised();
 302     if ($snags_forced) {
 303         printf STDERR
 304             "%s: snags: %d overriden by individual -f options\n",
 305             $us, $snags_forced;
 306     }
 307     if ($snags_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: snags: %d overriden by global --force\n",
 311                 $us, $snags_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 315                 $us, $snags_tripped;
 316         }
 317     }
 318     $snags_summarised = $snags_forced + $snags_tripped;
 319 }
 320 sub snags_maybe_bail_early () {
 321     # useful to bail out early without doing a lot of work;
 322     # not a substitute for snags_maybe_bail.
 323     snags_maybe_bail() if $snags_tripped && !$opt_force;
 324 }
 325 sub any_snags () {
 326     return $snags_forced || $snags_tripped;
 327 }
 328
 329 sub gbp_pq_export ($$$) {
 330     my ($bname, $base, $tip) = @_;
 331     # must be run in a workarea.  $bname and patch-queue/$bname
 332     # ought not to exist.  Leaves you on patch-queue/$bname with
 333     # the patches staged but not committed.
 334     printdebug "gbp_pq_export $bname $base $tip\n";
 335     runcmd @git, qw(checkout -q -b), $bname, $base;
 336     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 337     my @gbp_cmd = (qw(gbp pq export));
 338     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 339     if ($r) {
 340         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 341         failedcmd @gbp_cmd;
 342     }
 343     runcmd @git, qw(add -f debian/patches);
 344 }
 345
 346
 347 # xxx allow merge resolution separately from laundering, before git merge
 348 #
 349 # xxx general gdr docs highlight forbidden things
 350 # xxx general gdr docs list allowable things ?
 351 # xxx general gdr docs explicitly forbid some rebase
 352 #
 353 # xxx provide a way for the user to help
 354 # xxx (eg, provide wreckage provide way to continue)
 355
 356 # later/rework?
 357 #  use git-format-patch?
 358 #  our own patch identification algorithm?
 359 #  this is an alternative strategy
 360
 361 sub merge_series ($$;@) {
 362     my ($newbase, $base_q, @input_qs) = @_;
 363     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 364     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 365     # ^ specifies several patch series (currently we only support exactly 2)
 366     # return value is a commit which is the result of
 367     # merging the two versions of the same topic branch
 368     #   $input_q[0] and $input_q[1]
 369     # with respect to the old version
 370     #   $base_q
 371     # all onto $newbase.
 372
 373     # Creates, in *_q, a key MR for its private use
 374
 375     printdebug "merge_series newbase=$newbase\n";
 376
 377     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 378     $base_q->{MR}{S} = 'base';
 379
 380     my %prereq;
 381     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 382     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 383     # $prereq{<patch filename>}               exists or not (even later)
 384
 385     my $result;
 386
 387     local $workarea = fresh_playground "$playprefix/merge";
 388     my $seriesfile = "debian/patches/series";
 389     in_workarea sub {
 390         playtree_setup();
 391         foreach my $q ($base_q, reverse @input_qs) {
 392             my $s = $q->{MR}{S};
 393             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 394             if (open S, $seriesfile) {
 395                 my @earlier;
 396                 while (my $patch = <S>) {
 397                     chomp $patch or die $!;
 398                     $prereq{$patch} //= {};
 399                     foreach my $earlier (@earlier) {
 400                         $prereq{$patch}{$earlier}{$s}++ and die;
 401                     }
 402                     push @earlier, $patch;
 403                     stat "debian/patches/$patch" or die "$patch ?";
 404                 }
 405                 S->error and die "$seriesfile $!";
 406                 close S;
 407             } else {
 408                 die "$seriesfile $!" unless $!==ENOENT;
 409             }
 410             read_tree_upstream $newbase, 1;
 411             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 412                 "Convert $s to patch queue for merging",
 413                 "[git-debrebase merge-innards patch-queue import:".
 414                 " $q->{SeriesTip}]"
 415             ];
 416             printdebug "merge_series  pec $pec ";
 417             runcmd @git, qw(rm -q --cached), $seriesfile;
 418             $pec = make_commit [ $pec ], [
 419                 "Drop series file from $s to avoid merge trouble",
 420                 "[git-debrebase merge-innards patch-queue prep:".
 421                 " $q->{SeriesTip}]"
 422             ];
 423             printdebug "pec' $pec\n";
 424             runcmd @git, qw(reset -q --hard), $pec;
 425             $q->{MR}{PEC} = $pec;
 426         }
 427         # now, because of reverse, we are on $input_q->{MR}{OQC}
 428         runcmd @git, qw(checkout -q -b merge);
 429         printdebug "merge_series merging...\n";
 430         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 431         debugcmd '+', @mergecmd;
 432         $!=0; $?=-1;
 433         if (system @mergecmd) {
 434             failedcmd @mergecmd;
 435         }
 436
 437         printdebug "merge_series merge ok, series...\n";
 438         # We need to construct a new series file
 439         # Firstly, resolve prereq
 440         foreach my $f (sort keys %prereq) {
 441             printdebug "merge_series  patch\t$f\t";
 442             if (!stat_exists "debian/patches/$f") {
 443                 print DEBUG " drop\n" if $debuglevel;
 444                 # git merge deleted it; that's how we tell it's not wanted
 445                 delete $prereq{$f};
 446                 next;
 447             }
 448             print DEBUG " keep\n" if $debuglevel;
 449             foreach my $g (sort keys %{ $prereq{$f} }) {
 450                 my $gfp = $prereq{$f}{$g};
 451                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 452                 if (!!$gfp->{0} == !!$gfp->{1}
 453                     ? $gfp->{0}
 454                     : !$gfp->{base}) {
 455                     print DEBUG "\tkeep\n" if $debuglevel;
 456                 } else {
 457                     print DEBUG "\tdrop\n" if $debuglevel;
 458                     delete $prereq{$f}{$g};
 459                 }
 460             }
 461         }
 462
 463         my $unsat = sub {
 464             my ($f) = @_;
 465             return scalar keys %{ $prereq{$f} };
 466         };
 467
 468         my $nodate = time + 1;
 469         my %authordate;
 470         # $authordate{<patch filename>};
 471         my $authordate = sub {
 472             my ($f) = @_;
 473             $authordate{$f} //= do {
 474                 open PF, "<", "debian/patches/$f" or die "$f $!";
 475                 while (<PF>) {
 476                     return $nodate if m/^$/;
 477                     last if s{^Date: }{};
 478                 }
 479                 chomp;
 480                 return cmdoutput qw(date +%s -d), $_;
 481             };
 482         };
 483
 484         open NS, '>', $seriesfile or die $!;
 485
 486         while (keys %prereq) {
 487             my $best;
 488             foreach my $try (sort keys %prereq) {
 489                 if ($best) {
 490                     next if (
 491                              $unsat->($try) <=> $unsat->($best) or
 492                              $authordate->($try) <=> $authordate->($best) or
 493                              $try cmp $best
 494                             ) >= 0;
 495                 }
 496                 $best = $try;
 497             }
 498             printdebug "merge_series series next $best\n";
 499             print NS "$best\n" or die $!;
 500             delete $prereq{$best};
 501             foreach my $gp (values %prereq) {
 502                 delete $gp->{$best};
 503             }
 504         }
 505
 506         runcmd @git, qw(add), $seriesfile;
 507         runcmd @git, qw(commit --quiet -m), 'Merged series';
 508
 509         printdebug "merge_series series gbp pq import\n";
 510         runcmd qw(gbp pq import);
 511
 512         # OK now we are on patch-queue/merge, and we need to rebase
 513         # onto the intended parent and drop the patches from each one
 514
 515         printdebug "merge_series series ok, building...\n";
 516         my $build = $newbase;
 517         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 518         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 519             my $commit = git_cat_file $c, 'commit';
 520             printdebug "merge_series series ok, building $c\n";
 521             read_tree_upstream $c;
 522             my $tree = cmdoutput @git, qw(write-tree);
 523             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 524             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 525             open C, ">", "../mcommit" or die $!;
 526             print C $commit or die $!;
 527             close C or die $!;
 528             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 529         }
 530         $result = $build;
 531         runcmd @git, qw(update-ref refs/heads/result), $result;
 532     };
 533     printdebug "merge_series returns $result\n";
 534     return $result;
 535 }
 536
 537 # classify returns an info hash like this
 538 #   CommitId => $objid
 539 #   Hdr => # commit headers, including 1 final newline
 540 #   Msg => # commit message (so one newline is dropped)
 541 #   Tree => $treeobjid
 542 #   Type => (see below)
 543 #   Parents = [ {
 544 #       Ix => $index # ie 0, 1, 2, ...
 545 #       CommitId
 546 #       Differs => return value from get_differs
 547 #       IsOrigin
 548 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 549 #     } ...]
 550 #   NewMsg => # commit message, but with any [dgit import ...] edited
 551 #             # to say "[was: ...]"
 552 #
 553 # Types:
 554 #   Packaging
 555 #   Changelog
 556 #   Upstream
 557 #   AddPatches
 558 #   Mixed
 559 #
 560 #   Pseudomerge
 561 #     has additional entres in classification result
 562 #       Overwritten = [ subset of Parents ]
 563 #       Contributor = $the_remaining_Parent
 564 #
 565 #   DgitImportUnpatched
 566 #     has additional entry in classification result
 567 #       OrigParents = [ subset of Parents ]
 568 #
 569 #   Anchor
 570 #     has additional entry in classification result
 571 #       OrigParents = [ subset of Parents ]  # singleton list
 572 #
 573 #   TreatAsAnchor
 574 #
 575 #   BreakwaterStart
 576 #
 577 #   Unknown
 578 #     has additional entry in classification result
 579 #       Why => "prose"
 580
 581 sub parsecommit ($;$) {
 582     my ($objid, $p_ref) = @_;
 583     # => hash with                   CommitId Hdr Msg Tree Parents
 584     #    Parents entries have only   Ix CommitId
 585     #    $p_ref, if provided, must be [] and is used as a base for Parents
 586
 587     $p_ref //= [];
 588     die if @$p_ref;
 589
 590     my ($h,$m) = get_commit $objid;
 591
 592     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 593     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 594
 595     my $r = {
 596         CommitId => $objid,
 597         Hdr => $h,
 598         Msg => $m,
 599         Tree => $t,
 600         Parents => $p_ref,
 601     };
 602
 603     foreach my $ph (@ph) {
 604         push @$p_ref, {
 605             Ix => scalar @$p_ref,
 606             CommitId => $ph,
 607         };
 608     }
 609
 610     return $r;
 611 }
 612
 613 sub classify ($) {
 614     my ($objid) = @_;
 615
 616     my @p;
 617     my $r = parsecommit($objid, \@p);
 618     my $t = $r->{Tree};
 619
 620     foreach my $p (@p) {
 621         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 622     }
 623
 624     printdebug "classify $objid \$t=$t \@p",
 625         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 626         "\n";
 627
 628     my $classify = sub {
 629         my ($type, @rest) = @_;
 630         $r = { %$r, Type => $type, @rest };
 631         if ($debuglevel) {
 632             printdebug " = $type ".(dd $r)."\n";
 633         }
 634         return $r;
 635     };
 636     my $unknown = sub {
 637         my ($why) = @_;
 638         $r = { %$r, Type => qw(Unknown), Why => $why };
 639         printdebug " ** Unknown\n";
 640         return $r;
 641     };
 642
 643     if (grep { $_ eq $objid } @opt_anchors) {
 644         return $classify->('TreatAsAnchor');
 645     }
 646
 647     my @identical = grep { !$_->{Differs} } @p;
 648     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 649     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 650
 651     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 652         # multi-orig upstreams are represented with an anchor merge
 653         # from a single upstream commit which combines the orig tarballs
 654
 655         # Every anchor tagged this way must be a merge.
 656         # We are relying on the
 657         #     [git-debrebase anchor: ...]
 658         # commit message annotation in "declare" anchor merges (which
 659         # do not have any upstream changes), to distinguish those
 660         # anchor merges from ordinary pseudomerges (which we might
 661         # just try to strip).
 662         #
 663         # However, the user is going to be doing git-rebase a lot.  We
 664         # really don't want them to rewrite an anchor commit.
 665         # git-rebase trips up on merges, so that is a useful safety
 666         # catch.
 667         #
 668         # BreakwaterStart commits are also anchors in the terminology
 669         # of git-debrebase(5), but they are untagged (and always
 670         # manually generated).
 671         #
 672         # We cannot not tolerate any tagged linear commit (ie,
 673         # BreakwaterStart commits tagged `[anchor:') because such a
 674         # thing could result from an erroneous linearising raw git
 675         # rebase of a merge anchor.  That would represent a corruption
 676         # of the branch. and we want to detect and reject the results
 677         # of such corruption before it makes it out anywhere.  If we
 678         # reject it here then we avoid making the pseudomerge which
 679         # would be needed to push it.
 680
 681         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 682         @p == 2 or return $badanchor->("has other than two parents");
 683         $haspatches and return $badanchor->("contains debian/patches");
 684
 685         # How to decide about l/r ordering of anchors ?  git
 686         # --topo-order prefers to expand 2nd parent first.  There's
 687         # already an easy rune to look for debian/ history anyway (git log
 688         # debian/) so debian breakwater branch should be 1st parent; that
 689         # way also there's also an easy rune to look for the upstream
 690         # patches (--topo-order).
 691
 692         # Also this makes --first-parent be slightly more likely to
 693         # be useful - it makes it provide a linearised breakwater history.
 694
 695         # Of course one can say somthing like
 696         #  gitk -- ':/' ':!/debian'
 697         # to get _just_ the commits touching upstream files, and by
 698         # the TREESAME logic in git-rev-list this will leave the
 699         # breakwater into upstream at the first anchor.  But that
 700         # doesn't report debian/ changes at all.
 701
 702         # Other observations about gitk: by default, gitk seems to
 703         # produce output in a different order to git-rev-list.  I
 704         # can't seem to find this documented anywhere.  gitk
 705         # --date-order DTRT.  But, gitk always seems to put the
 706         # parents from left to right, in order, so it's easy to see
 707         # which way round a pseudomerge is.
 708
 709         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 710         $p[1]{Differs} & ~DS_DEB and
 711             $badanchor->("upstream files differ from left parent");
 712         $p[0]{Differs} & ~D_UPS and
 713             $badanchor->("debian/ differs from right parent");
 714
 715         return $classify->(qw(Anchor),
 716                            OrigParents => [ $p[1] ]);
 717     }
 718
 719     if (@p == 1) {
 720         my $d = $r->{Parents}[0]{Differs};
 721         if ($d == D_PAT_ADD) {
 722             return $classify->(qw(AddPatches));
 723         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 724             return $unknown->("edits debian/patches");
 725         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 726             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 727             if ($ty eq 'tree') {
 728                 if ($d == D_DEB_CLOG) {
 729                     return $classify->(qw(Changelog));
 730                 } else {
 731                     return $classify->(qw(Packaging));
 732                 }
 733             } elsif ($ty eq 'missing') {
 734                 return $classify->(qw(BreakwaterStart));
 735             } else {
 736                 return $unknown->("parent's debian is not a directory");
 737             }
 738         } elsif ($d == D_UPS) {
 739             return $classify->(qw(Upstream));
 740         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 741             return $classify->(qw(Mixed));
 742         } elsif ($d == 0) {
 743             return $unknown->("no changes");
 744         } else {
 745             confess "internal error $objid ?";
 746         }
 747     }
 748     if (!@p) {
 749         return $unknown->("origin commit");
 750     }
 751
 752     if (@p == 2 && @identical == 1) {
 753         my @overwritten = grep { $_->{Differs} } @p;
 754         confess "internal error $objid ?" unless @overwritten==1;
 755         return $classify->(qw(Pseudomerge),
 756                            Overwritten => [ $overwritten[0] ],
 757                            Contributor => $identical[0]);
 758     }
 759     if (@p == 2 && @identical == 2) {
 760         my $get_t = sub {
 761             my ($ph,$pm) = get_commit $_[0]{CommitId};
 762             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 763             $1;
 764         };
 765         my @bytime = @p;
 766         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 767         if ($order > 0) { # newer first
 768         } elsif ($order < 0) {
 769             @bytime = reverse @bytime;
 770         } else {
 771             # same age, default to order made by -s ours
 772             # that is, commit was made by someone who preferred L
 773         }
 774         return $classify->(qw(Pseudomerge),
 775                            SubType => qw(Ambiguous),
 776                            Contributor => $bytime[0],
 777                            Overwritten => [ $bytime[1] ]);
 778     }
 779     foreach my $p (@p) {
 780         my ($p_h, $p_m) = get_commit $p->{CommitId};
 781         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 782         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 783     }
 784     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 785     my $m2 = $r->{Msg};
 786     if (!(grep { !$_->{IsOrigin} } @p) and
 787         (@orig_ps >= @p - 1) and
 788         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 789         $r->{NewMsg} = $m2;
 790         return $classify->(qw(DgitImportUnpatched),
 791                            OrigParents => \@orig_ps);
 792     }
 793
 794     if (@p == 2 and
 795         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 796         # xxx ^ metadata tag needs adding to (5)
 797         return $classify->("MergedBreakwaters");
 798     }
 799     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 800         return $unknown->("unknown kind of merge from $1");
 801     }
 802     if (@p > 2) {
 803         return $unknown->("octopus merge");
 804     }
 805
 806     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 807         return $unknown->("general two-parent merge");
 808     }
 809
 810     return $classify->("VanillaMerge");
 811 }
 812
 813 sub keycommits ($;$$$$) {
 814     my ($head, $furniture, $unclean, $trouble, $fatal) = @_;
 815     # => ($anchor, $breakwater)
 816
 817     # $unclean->("unclean-$tagsfx", $msg, $cl)
 818     # $furniture->("unclean-$tagsfx", $msg, $cl)
 819     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 820     #   is callled for each situation or commit that
 821     #   wouldn't be found in a laundered branch
 822     # $furniture is for furniture commits such as might be found on an
 823     #   interchange branch (pseudomerge, d/patches, changelog)
 824     # $trouble is for things whnich prevent the return of
 825     #   anchor and breakwater information; if that is ignored,
 826     #   then keycommits returns (undef, undef) instead.
 827     # $fatal is for unprocessable commits, and should normally cause
 828     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 829     #
 830     # If a callback is undef, fail is called instead.
 831     # If a callback is defined but false, the situation is ignored.
 832     # Callbacks may say:
 833     #   no warnings qw(exiting); last;
 834     # if the answer is no longer wanted.
 835
 836     my ($anchor, $breakwater);
 837     my $clogonly;
 838     my $cl;
 839     my $found_pm;
 840     $fatal //= sub { fail $_[1]; };
 841     my $x = sub {
 842         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 843         my $why = $mainwhy.$xwhy;
 844         my $m = "branch needs laundering (run git-debrebase): $why";
 845         fail $m unless defined $cb;
 846         return unless $cb;
 847         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 848     };
 849     my $found_anchor = sub {
 850         ($anchor) = @_;
 851         $breakwater //= $clogonly;
 852         $breakwater //= $head;
 853         no warnings qw(exiting);
 854         last;
 855     };
 856     for (;;) {
 857         $cl = classify $head;
 858         my $ty = $cl->{Type};
 859         if ($ty eq 'Packaging') {
 860             $breakwater //= $clogonly;
 861             $breakwater //= $head;
 862         } elsif ($ty eq 'Changelog') {
 863             # this is going to count as the tip of the breakwater
 864             # only if it has no upstream stuff before it
 865             $clogonly //= $head;
 866         } elsif ($ty eq 'Anchor' or
 867                  $ty eq 'TreatAsAnchor' or
 868                  $ty eq 'BreakwaterStart') {
 869             $found_anchor->($head);
 870         } elsif ($ty eq 'Upstream') {
 871             $x->($unclean, 'ordering',
 872  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 873                 if defined $breakwater;
 874             $clogonly = undef;
 875             $breakwater = undef;
 876         } elsif ($ty eq 'Mixed') {
 877             $x->($unclean, 'mixed',
 878                  "found mixed upstream/packaging commit"," ($head)");
 879             $clogonly = undef;
 880             $breakwater = undef;
 881         } elsif ($ty eq 'Pseudomerge' or
 882                  $ty eq 'AddPatches') {
 883             my $found_pm = 1;
 884             $x->($furniture, (lc $ty),
 885                  "found interchange bureaucracy commit ($ty)"," ($head)");
 886         } elsif ($ty eq 'DgitImportUnpatched') {
 887             if ($found_pm) {
 888                 $x->($trouble, 'dgitimport',
 889                      "found dgit dsc import"," ($head)");
 890                 return (undef,undef);
 891             } else {
 892                 $x->($fatal, 'unprocessable',
 893                      "found bare dgit dsc import with no prior history",
 894                      " ($head)");
 895                 return (undef,undef);
 896             }
 897         } elsif ($ty eq 'VanillaMerge') {
 898             $x->($trouble, 'vanillamerge',
 899                  "found vanilla merge"," ($head)");
 900             return (undef,undef);
 901         } else {
 902             $x->($fatal, 'unprocessable',
 903                  "found unprocessable commit, cannot cope: $cl->{Why}",
 904                  " ($head)");
 905             return (undef,undef);
 906         }
 907         $head = $cl->{Parents}[0]{CommitId};
 908     }
 909     return ($anchor, $breakwater);
 910 }
 911
 912 sub walk ($;$$$);
 913 sub walk ($;$$$) {
 914     my ($input,
 915         $nogenerate,$report, $report_lprefix) = @_;
 916     # => ($tip, $breakwater_tip, $last_anchor)
 917     # (or nothing, if $nogenerate)
 918
 919     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 920     $report_lprefix //= '';
 921
 922     # go through commits backwards
 923     # we generate two lists of commits to apply:
 924     # breakwater branch and upstream patches
 925     my (@brw_cl, @upp_cl, @processed);
 926     my %found;
 927     my $upp_limit;
 928     my @pseudomerges;
 929
 930     my $cl;
 931     my $xmsg = sub {
 932         my ($prose, $info) = @_;
 933         my $ms = $cl->{Msg};
 934         chomp $ms;
 935         $info //= '';
 936         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 937         return (Msg => $ms);
 938     };
 939     my $rewrite_from_here = sub {
 940         my ($cl) = @_;
 941         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 942         push @$cl, $sp_cl;
 943         push @processed, $sp_cl;
 944     };
 945     my $cur = $input;
 946
 947     my $prdelim = "";
 948     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 949
 950     my $prline = sub {
 951         return unless $report;
 952         print $report $prdelim, $report_lprefix, @_;
 953         $prdelim = "\n";
 954     };
 955
 956     my $bomb = sub { # usage: return $bomb->();
 957         print $report " Unprocessable" if $report;
 958         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 959         $prprdelim->();
 960         if ($nogenerate) {
 961             return (undef,undef);
 962         }
 963         fail "found unprocessable commit, cannot cope".
 964             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 965             " (commit $cur) (d.".
 966             (join ' ', map { sprintf "%#x", $_->{Differs} }
 967              @{ $cl->{Parents} }).
 968                  ")";
 969     };
 970
 971     my $build;
 972     my $breakwater;
 973
 974     my $build_start = sub {
 975         my ($msg, $parent) = @_;
 976         $prline->(" $msg");
 977         $build = $parent;
 978         no warnings qw(exiting); last;
 979     };
 980
 981     my $nomerge = sub {
 982         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
 983     };
 984
 985     my $last_anchor;
 986
 987     for (;;) {
 988         $cl = classify $cur;
 989         my $ty = $cl->{Type};
 990         my $st = $cl->{SubType};
 991         $prline->("$cl->{CommitId} $cl->{Type}");
 992         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 993         push @processed, $cl;
 994         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 995         if ($ty eq 'AddPatches') {
 996             $cur = $p0;
 997             $rewrite_from_here->(\@upp_cl);
 998             next;
 999         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1000             push @brw_cl, $cl;
1001             $cur = $p0;
1002             next;
1003         } elsif ($ty eq 'BreakwaterStart') {
1004             $last_anchor = $cur;
1005             $build_start->('FirstPackaging', $cur);
1006         } elsif ($ty eq 'Upstream') {
1007             push @upp_cl, $cl;
1008             $cur = $p0;
1009             next;
1010         } elsif ($ty eq 'Mixed') {
1011             my $queue = sub {
1012                 my ($q, $wh) = @_;
1013                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1014                 push @$q, $cls;
1015             };
1016             $queue->(\@brw_cl, "debian");
1017             $queue->(\@upp_cl, "upstream");
1018             $rewrite_from_here->(\@brw_cl);
1019             $cur = $p0;
1020             next;
1021         } elsif ($ty eq 'Pseudomerge') {
1022             my $contrib = $cl->{Contributor}{CommitId};
1023             print $report " Contributor=$contrib" if $report;
1024             push @pseudomerges, $cl;
1025             $rewrite_from_here->(\@upp_cl);
1026             $cur = $contrib;
1027             next;
1028         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1029             $last_anchor = $cur;
1030             $build_start->("Anchor", $cur);
1031         } elsif ($ty eq 'DgitImportUnpatched') {
1032             my $pm = $pseudomerges[-1];
1033             if (defined $pm) {
1034                 # To an extent, this is heuristic.  Imports don't have
1035                 # a useful history of the debian/ branch.  We assume
1036                 # that the first pseudomerge after an import has a
1037                 # useful history of debian/, and ignore the histories
1038                 # from later pseudomerges.  Often the first pseudomerge
1039                 # will be the dgit import of the upload to the actual
1040                 # suite intended by the non-dgit NMUer, and later
1041                 # pseudomerges may represent in-archive copies.
1042                 my $ovwrs = $pm->{Overwritten};
1043                 printf $report " PM=%s \@Overwr:%d",
1044                     $pm->{CommitId}, (scalar @$ovwrs)
1045                     if $report;
1046                 if (@$ovwrs != 1) {
1047                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1048                     return $bomb->();
1049                 }
1050                 my $ovwr = $ovwrs->[0]{CommitId};
1051                 printf $report " Overwr=%s", $ovwr if $report;
1052                 # This import has a tree which is just like a
1053                 # breakwater tree, but it has the wrong history.  It
1054                 # ought to have the previous breakwater (which the
1055                 # pseudomerge overwrote) as an ancestor.  That will
1056                 # make the history of the debian/ files correct.  As
1057                 # for the upstream version: either it's the same as
1058                 # was ovewritten (ie, same as the previous
1059                 # breakwater), in which case that history is precisely
1060                 # right; or, otherwise, it was a non-gitish upload of a
1061                 # new upstream version.  We can tell these apart by
1062                 # looking at the tree of the supposed upstream.
1063                 push @brw_cl, {
1064                     %$cl,
1065                     SpecialMethod => 'DgitImportDebianUpdate',
1066                     $xmsg->("convert dgit import: debian changes")
1067                 }, {
1068                     %$cl,
1069                     SpecialMethod => 'DgitImportUpstreamUpdate',
1070                     $xmsg->("convert dgit import: upstream update",
1071                             " anchor")
1072                 };
1073                 $prline->(" Import");
1074                 $rewrite_from_here->(\@brw_cl);
1075                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1076                 $cur = $ovwr;
1077                 next;
1078             } else {
1079                 # Everything is from this import.  This kind of import
1080                 # is already nearly in valid breakwater format, with the
1081                 # patches as commits.  Unfortunately it contains
1082                 # debian/patches/.
1083                 printdebug "*** WALK BOMB bare dgit import\n";
1084                 $cl->{Why} = "bare dgit dsc import";
1085                 return $bomb->();
1086             }
1087             die "$ty ?";
1088         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1089             # User may have merged unstitched branch(es).  We will
1090             # have now lost what ffq-prev was then (since the later
1091             # pseudomerge may introduce further changes).  The effect
1092             # of resolving such a merge is that we may have to go back
1093             # further in history to find a merge base, since the one
1094             # which was reachable via ffq-prev is no longer findable.
1095             # This is suboptimal, but if it all works we'll have done
1096             # the right thing.
1097             # xxx we should warn the user in the docs about this
1098
1099             my $ok=1;
1100             my $best_anchor;
1101             # We expect to find a dominating anchor amongst the
1102             # inputs' anchors.  That will be the new anchor.
1103             #
1104             # More complicated is finding a merge base for the
1105             # breakwaters.  We need a merge base that is a breakwater
1106             # commit.  The ancestors of breakwater commits are more
1107             # breakwater commits and possibly upstream commits and the
1108             # ancestors of those upstream.  Upstreams might have
1109             # arbitrary ancestors.  But any upstream commit U is
1110             # either included in both anchors, in which case the
1111             # earlier anchor is a better merge base than any of U's
1112             # ancestors; or U is not included in the older anchor, in
1113             # which case U is not an ancestor of the vanilla merge at
1114             # all.  So no upstream commit, nor any ancestor thereof,
1115             # is a best merge base.  As for non-breakwater Debian
1116             # commits: these are never ancestors of any breakwater.
1117             #
1118             # So any best merge base as found by git-merge-base
1119             # is a suitable breakwater anchor.  Usually there will
1120             # be only one.
1121
1122             printdebug "*** MERGE\n";
1123
1124             # xxx avoid calling walk without nogenerate when
1125             # we have a MergedBreakwater; instead call keycommits ?
1126
1127             my @bwbcmd = (@git, qw(merge-base));
1128             my @ibcmd = (@git, qw(merge-base --all));
1129             my $might_be_in_bw = 1;
1130
1131             my $ps = $cl->{Parents};
1132
1133             foreach my $p (@$ps) {
1134                 $prline->(" VanillaMerge ".$p->{Ix});
1135                 $prprdelim->();
1136                 my ($ptip, $pbw, $panchor) =
1137                     walk $p->{CommitId}, 0, $report,
1138                          $report_lprefix.'  ';
1139                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1140                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1141                 $p->{Anchor} = $panchor;
1142
1143                 $best_anchor = $panchor if
1144                     !defined $best_anchor or
1145                     is_fast_fwd $best_anchor, $panchor;
1146
1147                 printdebug " MERGE BA best=".($best_anchor//'-').
1148                     " p=$panchor\n";
1149             }
1150
1151             foreach my $p (@$ps) {
1152                 $prline->(" VanillaMerge ".$p->{Ix});
1153                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1154                     $nomerge->('DivergentAnchor');
1155                 } elsif ($p->{Anchor} eq $best_anchor) {
1156                     print $report " SameAnchor" if $report;
1157                 } else {
1158                     print $report " SupersededAnchor" if $report;
1159                 }
1160                 if ($p->{Breakwater} eq $p->{CommitId}) {
1161                     # this parent commit was its own breakwater,
1162                     # ie it is part of the breakwater
1163                     print $report " Breakwater" if $report;
1164                 } else {
1165                     $might_be_in_bw = 0;
1166                 }
1167                 push @bwbcmd, $p->{Breakwater};
1168                 push @ibcmd, $p->{CommitId};
1169             }
1170
1171             if ($ok && $might_be_in_bw) {
1172                 $prline->(" VanillaMerge MergedBreakwaters");
1173                 $last_anchor = $best_anchor;
1174                 $build_start->('MergedBreakwaters', $cur);
1175             }
1176
1177             $nomerge->("alleged merged-breakwater is not a breakwater")
1178                 unless $ty eq 'VanillaMerge';
1179
1180             my $bwb = cmdoutput @bwbcmd;
1181
1182             # OK, now we have a breakwater base, but we need the merge
1183             # base for the interchange branch because we need the delta
1184             # queue.
1185             #
1186             # This a the best merge base of our inputs which has the
1187             # breakwater merge base as an ancestor.
1188
1189             my @ibs =
1190                 grep { is_fast_fwd $bwb, $_ }
1191                 grep /./,
1192                 split /\n/,
1193                 cmdoutput @ibcmd;
1194             my ($ib) = @ibs
1195                 or $nomerge->("no suitable interchange merge base");
1196
1197             $prline->("  VanillaMerge Base");
1198             $prprdelim->();
1199             my ($btip, $bbw, $banchor) =
1200                 walk $ib, 0, $report, $report_lprefix.'  ';
1201
1202             my $ibinfo = { SeriesTip => $btip,
1203                            SeriesBase => $bbw,
1204                            Anchor => $banchor };
1205             $bbw eq $bwb
1206                 or $nomerge->("interchange merge-base ($ib)'s".
1207                               " breakwater ($bbw)".
1208                               " != breakwaters' merge-base ($bwb)");
1209             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1210                  or $nomerge->("interchange merge-base ($ib)'s".
1211                                " anchor ($ibinfo->{SeriesBase})".
1212                                " != any merge input's anchor (".
1213                                (join ' ', map { $_->{Anchor} } @$ps).
1214                                ")");
1215
1216
1217             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1218             $cl->{MergeBestAnchor} = $best_anchor;
1219             push @brw_cl, {
1220                 %$cl,
1221                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1222                 $xmsg->('constructed from vanilla merge',
1223                         ' merged-breakwater'),
1224             };
1225             push @upp_cl, {
1226                 %$cl,
1227                 SpecialMethod => 'MergeMergeSeries',
1228             };
1229             $build_start->('MergeBreakwaters', $cur);
1230         } else {
1231             printdebug "*** WALK BOMB unrecognised\n";
1232             return $bomb->();
1233         }
1234     }
1235     $prprdelim->();
1236
1237     printdebug "*** WALK prep done cur=$cur".
1238         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1239
1240     return if $nogenerate;
1241
1242     # Now we build it back up again
1243
1244     fresh_workarea();
1245
1246     my $rewriting = 0;
1247
1248     $#upp_cl = $upp_limit if defined $upp_limit;
1249
1250     my $committer_authline = calculate_committer_authline();
1251
1252     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1253
1254     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1255
1256     in_workarea sub {
1257         mkdir $rd or $!==EEXIST or die $!;
1258         my $current_method;
1259         runcmd @git, qw(read-tree), $build;
1260         foreach my $cl (qw(Debian), (reverse @brw_cl),
1261                         { SpecialMethod => 'RecordBreakwaterTip' },
1262                         qw(Upstream), (reverse @upp_cl)) {
1263             if (!ref $cl) {
1264                 $current_method = $cl;
1265                 next;
1266             }
1267             my $method = $cl->{SpecialMethod} // $current_method;
1268             my @parents = ($build);
1269             my $cltree = $cl->{CommitId};
1270             printdebug "WALK BUILD ".($cltree//'undef').
1271                 " $method (rewriting=$rewriting)\n";
1272             if ($method eq 'Debian') {
1273                 read_tree_debian($cltree);
1274             } elsif ($method eq 'Upstream') {
1275                 read_tree_upstream($cltree);
1276             } elsif ($method eq 'StartRewrite') {
1277                 $rewriting = 1;
1278                 next;
1279             } elsif ($method eq 'RecordBreakwaterTip') {
1280                 $breakwater = $build;
1281                 next;
1282             } elsif ($method eq 'DgitImportDebianUpdate') {
1283                 read_tree_debian($cltree);
1284             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1285                 confess unless $rewriting;
1286                 my $differs = (get_differs $build, $cltree);
1287                 next unless $differs & D_UPS;
1288                 read_tree_upstream($cltree);
1289                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1290             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1291                 print "Found a general merge, will try to tidy it up.\n";
1292                 $rewriting = 1;
1293                 read_tree_upstream($cl->{MergeBestAnchor});
1294                 read_tree_upstream($cl->{MergeBestAnchor});
1295                 read_tree_debian($cltree);
1296                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1297             } elsif ($method eq 'MergeMergeSeries') {
1298                 print "Running merge resolution for $cl->{CommitId}...\n";
1299                 $build = merge_series
1300                     $build,
1301                     $cl->{MergeInterchangeBaseInfo},
1302                     @{ $cl->{Parents} };
1303                 $last_anchor = $cl->{MergeBestAnchor};
1304                 my $check_differs = get_differs $build, $cl->{CommitId};
1305                 # Breakwater changes which were in each side of the
1306                 # merge should be in MergeCreateMergedBreakwaters
1307                 # output.  Upstream changes are exactly the result
1308                 # of merge_series.  So the only difference should
1309                 # be potential laundry results.
1310                 $nomerge->(sprintf
1311                     "merge misresolved: tree is not the same (%s %s d.%#x)",
1312                            $cl->{CommitId}, $build, $check_differs)
1313                     if $check_differs & ~D_PAT_ADD;
1314                 print "Merge resolution successful.\n";
1315                 next;
1316             } else {
1317                 confess "$method ?";
1318             }
1319             if (!$rewriting) {
1320                 my $procd = (pop @processed) // 'UNDEF';
1321                 if ($cl ne $procd) {
1322                     $rewriting = 1;
1323                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1324                 }
1325             }
1326             my $newtree = cmdoutput @git, qw(write-tree);
1327             my $ch = $cl->{Hdr};
1328             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1329             $ch =~ s{^parent .*\n}{}mg;
1330             $ch =~ s{(?=^author)}{
1331                 join '', map { "parent $_\n" } @parents
1332             }me or confess "$ch ?";
1333             if ($rewriting) {
1334                 $ch =~ s{^committer .*$}{$committer_authline}m
1335                     or confess "$ch ?";
1336             }
1337             my $cf = "$rd/m$rewriting";
1338             open CD, ">", $cf or die $!;
1339             print CD $ch, "\n", $cl->{Msg} or die $!;
1340             close CD or die $!;
1341             my @cmd = (@git, qw(hash-object));
1342             push @cmd, qw(-w) if $rewriting;
1343             push @cmd, qw(-t commit), $cf;
1344             my $newcommit = cmdoutput @cmd;
1345             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1346             $build = $newcommit;
1347             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1348                 $last_anchor = $cur;
1349             }
1350         }
1351     };
1352
1353     my $final_check = get_differs $build, $input;
1354     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1355         if $final_check & ~D_PAT_ADD;
1356
1357     my @r = ($build, $breakwater, $last_anchor);
1358     printdebug "*** WALK RETURN @r\n";
1359     return @r
1360 }
1361
1362 sub get_head () {
1363     git_check_unmodified();
1364     return git_rev_parse qw(HEAD);
1365 }
1366
1367 sub update_head ($$$) {
1368     my ($old, $new, $mrest) = @_;
1369     push @deferred_updates, "update HEAD $new $old";
1370     run_deferred_updates $mrest;
1371 }
1372
1373 sub update_head_checkout ($$$) {
1374     my ($old, $new, $mrest) = @_;
1375     update_head $old, $new, $mrest;
1376     runcmd @git, qw(reset --hard);
1377 }
1378
1379 sub update_head_postlaunder ($$$) {
1380     my ($old, $tip, $reflogmsg) = @_;
1381     return if $tip eq $old;
1382     print "git-debrebase: laundered (head was $old)\n";
1383     update_head $old, $tip, $reflogmsg;
1384     # no tree changes except debian/patches
1385     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1386 }
1387
1388 sub currently_rebasing() {
1389     foreach (qw(rebase-merge rebase-apply)) {
1390         return 1 if stat_exists "$maindir_gitdir/$_";
1391     }
1392     return 0;
1393 }
1394
1395 sub bail_if_rebasing() {
1396     fail "you are in the middle of a git-rebase already"
1397         if currently_rebasing();
1398 }
1399
1400 sub do_launder_head ($) {
1401     my ($reflogmsg) = @_;
1402     my $old = get_head();
1403     record_ffq_auto();
1404     my ($tip,$breakwater) = walk $old;
1405     snags_maybe_bail();
1406     update_head_postlaunder $old, $tip, $reflogmsg;
1407     return ($tip,$breakwater);
1408 }
1409
1410 sub cmd_launder_v0 () {
1411     badusage "no arguments to launder-v0 allowed" if @ARGV;
1412     my $old = get_head();
1413     my ($tip,$breakwater,$last_anchor) = walk $old;
1414     update_head_postlaunder $old, $tip, 'launder';
1415     printf "# breakwater tip\n%s\n", $breakwater;
1416     printf "# working tip\n%s\n", $tip;
1417     printf "# last anchor\n%s\n", $last_anchor;
1418 }
1419
1420 sub defaultcmd_rebase () {
1421     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1422     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1423     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1424 }
1425
1426 sub cmd_analyse () {
1427     badusage "analyse does not support any options"
1428         if @ARGV and $ARGV[0] =~ m/^-/;
1429     badusage "too many arguments to analyse" if @ARGV>1;
1430     my ($old) = @ARGV;
1431     if (defined $old) {
1432         $old = git_rev_parse $old;
1433     } else {
1434         $old = git_rev_parse 'HEAD';
1435     }
1436     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1437     STDOUT->error and die $!;
1438 }
1439
1440 sub ffq_prev_branchinfo () {
1441     my $current = git_get_symref();
1442     return gdr_ffq_prev_branchinfo($current);
1443 }
1444
1445 sub ffq_check ($;$$) {
1446     # calls $ff and/or $notff zero or more times
1447     # then returns either (status,message) where status is
1448     #    exists
1449     #    detached
1450     #    weird-symref
1451     #    notbranch
1452     # or (undef,undef, $ffq_prev,$gdrlast)
1453     # $ff and $notff are called like this:
1454     #   $ff->("message for stdout\n");
1455     #   $notff->('snag-name', $message);
1456     # normally $currentval should be HEAD
1457     my ($currentval, $ff, $notff) =@_;
1458
1459     $ff //= sub { print $_[0] or die $!; };
1460     $notff //= \&snag;
1461
1462     my ($status, $message, $current, $ffq_prev, $gdrlast)
1463         = ffq_prev_branchinfo();
1464     return ($status, $message) unless $status eq 'branch';
1465
1466     my $exists = git_get_ref $ffq_prev;
1467     return ('exists',"$ffq_prev already exists") if $exists;
1468
1469     return ('not-branch', 'HEAD symref is not to refs/heads/')
1470         unless $current =~ m{^refs/heads/};
1471     my $branch = $';
1472
1473     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1474     my %checked;
1475
1476     printdebug "ffq check_specs @check_specs\n";
1477
1478     my $check = sub {
1479         my ($lrref, $desc) = @_;
1480         printdebug "ffq might check $lrref ($desc)\n";
1481         my $invert;
1482         for my $chk (@check_specs) {
1483             my $glob = $chk;
1484             $invert = $glob =~ s{^[!^]}{};
1485             last if fnmatch $glob, $lrref;
1486         }
1487         return if $invert;
1488         my $lrval = git_get_ref $lrref;
1489         return unless length $lrval;
1490
1491         if (is_fast_fwd $lrval, $currentval) {
1492             $ff->("OK, you are ahead of $lrref\n");
1493             $checked{$lrref} = 1;
1494         } elsif (is_fast_fwd $currentval, $lrval) {
1495             $checked{$lrref} = -1;
1496             $notff->('behind', "you are behind $lrref, divergence risk");
1497         } else {
1498             $checked{$lrref} = -1;
1499             $notff->('diverged', "you have diverged from $lrref");
1500         }
1501     };
1502
1503     my $merge = cfg "branch.$branch.merge",1;
1504     if (defined $merge and $merge =~ m{^refs/heads/}) {
1505         my $rhs = $';
1506         printdebug "ffq merge $rhs\n";
1507         my $check_remote = sub {
1508             my ($remote, $desc) = @_;
1509             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1510             return unless defined $remote;
1511             $check->("refs/remotes/$remote/$rhs", $desc);
1512         };
1513         $check_remote->((scalar cfg "branch.$branch.remote",1),
1514                         'remote fetch/merge branch');
1515         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1516                         (scalar cfg "branch.$branch.pushDefault",1),
1517                         'remote push branch');
1518     }
1519     if ($branch =~ m{^dgit/}) {
1520         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1521     } elsif ($branch =~ m{^master$}) {
1522         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1523     }
1524     return (undef, undef, $ffq_prev, $gdrlast);
1525 }
1526
1527 sub record_ffq_prev_deferred () {
1528     # => ('status', "message")
1529     # 'status' may be
1530     #    deferred          message is undef
1531     #    exists
1532     #    detached
1533     #    weird-symref
1534     #    notbranch
1535     # if not ff from some branch we should be ff from, is an snag
1536     # if "deferred", will have added something about that to
1537     #   @deferred_update_messages, and also maybe printed (already)
1538     #   some messages about ff checks
1539     bail_if_rebasing();
1540     my $currentval = get_head();
1541
1542     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1543     return ($status,$message) if defined $status;
1544
1545     snags_maybe_bail();
1546
1547     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1548     push @deferred_updates, "delete $gdrlast";
1549     push @deferred_update_messages, "Recorded previous head for preservation";
1550     return ('deferred', undef);
1551 }
1552
1553 sub record_ffq_auto () {
1554     my ($status, $message) = record_ffq_prev_deferred();
1555     if ($status eq 'deferred' || $status eq 'exists') {
1556     } else {
1557         snag $status, "could not record ffq-prev: $message";
1558         snags_maybe_bail();
1559     }
1560 }
1561
1562 sub ffq_prev_info () {
1563     bail_if_rebasing();
1564     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1565     my ($status, $message, $current, $ffq_prev, $gdrlast)
1566         = ffq_prev_branchinfo();
1567     if ($status ne 'branch') {
1568         snag $status, "could not check ffq-prev: $message";
1569         snags_maybe_bail();
1570     }
1571     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1572     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1573 }
1574
1575 sub stitch ($$$$$) {
1576     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1577
1578     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1579
1580     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1581         my $differs = get_differs $old_head, $ffq_prev_commitish;
1582         unless ($differs & ~D_PAT_ADD) {
1583             # ffq-prev is ahead of us, and the only tree changes it has
1584             # are possibly addition of things in debian/patches/.
1585             # Just wind forwards rather than making a pointless pseudomerge.
1586             push @deferred_updates,
1587                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1588             update_head_checkout $old_head, $ffq_prev_commitish,
1589                 "stitch (fast forward)";
1590             return;
1591         }
1592     }
1593     fresh_workarea();
1594     # We make pseudomerges with L as the contributing parent.
1595     # This makes git rev-list --first-parent work properly.
1596     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1597         'Declare fast forward / record previous work',
1598         "[git-debrebase pseudomerge: $prose]",
1599     ];
1600     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1601     update_head $old_head, $new_head, "stitch: $prose";
1602 }
1603
1604 sub do_stitch ($;$) {
1605     my ($prose, $unclean) = @_;
1606
1607     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1608     if (!$ffq_prev_commitish) {
1609         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1610         return;
1611     }
1612     my $dangling_head = get_head();
1613
1614     keycommits $dangling_head, $unclean,$unclean,$unclean;
1615     snags_maybe_bail();
1616
1617     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1618 }
1619
1620 sub upstream_commitish_search ($$) {
1621     my ($upstream_version, $tried) = @_;
1622     # todo: at some point maybe use git-deborig to do this
1623     foreach my $tagpfx ('', 'v', 'upstream/') {
1624         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1625         my $new_upstream = git_get_ref "refs/tags/$tag";
1626         push @$tried, $tag;
1627         return $new_upstream if length $new_upstream;
1628     }
1629 }
1630
1631 sub resolve_upstream_version ($$) {
1632     my ($new_upstream, $upstream_version) = @_;
1633
1634     if (!defined $new_upstream) {
1635         my @tried;
1636         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1637         if (!length $new_upstream) {
1638             fail "Could not determine appropriate upstream commitish.\n".
1639                 " (Tried these tags: @tried)\n".
1640                 " Check version, and specify upstream commitish explicitly.";
1641         }
1642     }
1643     $new_upstream = git_rev_parse $new_upstream;
1644
1645     return $new_upstream;
1646 }
1647
1648 sub cmd_new_upstream () {
1649     # automatically and unconditionally launders before rebasing
1650     # if rebase --abort is used, laundering has still been done
1651
1652     my %pieces;
1653
1654     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1655
1656     # parse args - low commitment
1657     my $spec_version = shift @ARGV;
1658     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1659     fail "bad version number \`$spec_version'" unless defined $new_version;
1660     if ($new_version->is_native()) {
1661         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1662     }
1663
1664     my $new_upstream = shift @ARGV;
1665     my $new_upstream_version = upstreamversion  $new_version;
1666     $new_upstream =
1667         resolve_upstream_version $new_upstream, $new_upstream_version;
1668
1669     record_ffq_auto();
1670
1671     my $piece = sub {
1672         my ($n, @x) = @_; # may be ''
1673         my $pc = $pieces{$n} //= {
1674             Name => $n,
1675             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1676         };
1677         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1678         $pc;
1679     };
1680
1681     my @newpieces;
1682     my $newpiece = sub {
1683         my ($n, @x) = @_; # may be ''
1684         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1685         push @newpieces, $pc;
1686     };
1687
1688     $newpiece->('',
1689         OldIx => 0,
1690         New => $new_upstream,
1691     );
1692     while (@ARGV && $ARGV[0] !~ m{^-}) {
1693         my $n = shift @ARGV;
1694
1695         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1696             unless @ARGV && $ARGV[0] !~ m{^-};
1697
1698         my $c = git_rev_parse shift @ARGV;
1699         die unless $n =~ m/^$extra_orig_namepart_re$/;
1700         $newpiece->($n, New => $c);
1701     }
1702
1703     # now we need to investigate the branch this generates the
1704     # laundered version but we don't switch to it yet
1705     my $old_head = get_head();
1706     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1707
1708     my $old_bw_cl = classify $old_bw;
1709     my $old_anchor_cl = classify $old_anchor;
1710     my $old_upstream;
1711     if (!$old_anchor_cl->{OrigParents}) {
1712         snag 'anchor-treated',
1713             'old anchor is recognised due to --anchor, cannot check upstream';
1714     } else {
1715         $old_upstream = parsecommit
1716             $old_anchor_cl->{OrigParents}[0]{CommitId};
1717         $piece->('', Old => $old_upstream->{CommitId});
1718     }
1719
1720     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1721         if ($old_upstream->{Msg} =~
1722  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1723            ) {
1724             my @oldpieces = (split / /, $1);
1725             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1726             if ($old_n_parents != @oldpieces &&
1727                 $old_n_parents != @oldpieces + 1) {
1728                 snag 'upstream-confusing', sprintf
1729                     "previous upstream combine %s".
1730                     " mentions %d pieces (each implying one parent)".
1731                     " but has %d parents".
1732                     " (one per piece plus maybe a previous combine)",
1733                     $old_upstream->{CommitId},
1734                     (scalar @oldpieces),
1735                     $old_n_parents;
1736             } elsif ($oldpieces[0] ne '.') {
1737                 snag 'upstream-confusing', sprintf
1738                     "previous upstream combine %s".
1739                     " first piece is not \`.'",
1740                     $oldpieces[0];
1741             } else {
1742                 $oldpieces[0] = '';
1743                 foreach my $i (0..$#oldpieces) {
1744                     my $n = $oldpieces[$i];
1745                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1746                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1747                 }
1748             }
1749         } else {
1750             snag 'upstream-confusing',
1751                 "previous upstream $old_upstream->{CommitId} is from".
1752                " git-debrebase but not an \`upstream-combine' commit";
1753         }
1754     }
1755
1756     foreach my $pc (values %pieces) {
1757         if (!$old_upstream) {
1758             # we have complained already
1759         } elsif (!$pc->{Old}) {
1760             snag 'upstream-new-piece',
1761                 "introducing upstream piece \`$pc->{Name}'";
1762         } elsif (!$pc->{New}) {
1763             snag 'upstream-rm-piece',
1764                 "dropping upstream piece \`$pc->{Name}'";
1765         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1766             snag 'upstream-not-ff',
1767                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1768         }
1769     }
1770
1771     printdebug "%pieces = ", (dd \%pieces), "\n";
1772     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1773
1774     snags_maybe_bail();
1775
1776     my $new_bw;
1777
1778     fresh_workarea();
1779     in_workarea sub {
1780         my @upstream_merge_parents;
1781
1782         if (!any_snags()) {
1783             push @upstream_merge_parents, $old_upstream->{CommitId};
1784         }
1785
1786         foreach my $pc (@newpieces) { # always has '' first
1787             if ($pc->{Name}) {
1788                 read_tree_subdir $pc->{Name}, $pc->{New};
1789             } else {
1790                 runcmd @git, qw(read-tree), $pc->{New};
1791             }
1792             push @upstream_merge_parents, $pc->{New};
1793         }
1794
1795         # index now contains the new upstream
1796
1797         if (@newpieces > 1) {
1798             # need to make the upstream subtree merge commit
1799             $new_upstream = make_commit \@upstream_merge_parents,
1800                 [ "Combine upstreams for $new_upstream_version",
1801  ("[git-debrebase upstream-combine . ".
1802  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1803  ": new upstream]"),
1804                 ];
1805         }
1806
1807         # $new_upstream is either the single upstream commit, or the
1808         # combined commit we just made.  Either way it will be the
1809         # "upstream" parent of the anchor merge.
1810
1811         read_tree_subdir 'debian', "$old_bw:debian";
1812
1813         # index now contains the anchor merge contents
1814         $new_bw = make_commit [ $old_bw, $new_upstream ],
1815             [ "Update to upstream $new_upstream_version",
1816  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1817             ];
1818
1819         my $clogsignoff = cmdoutput qw(git show),
1820             '--pretty=format:%an <%ae>  %aD',
1821             $new_bw;
1822
1823         # Now we have to add a changelog stanza so the Debian version
1824         # is right.
1825         die if unlink "debian";
1826         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1827         unlink "debian/changelog" or $!==ENOENT or die $!;
1828         mkdir "debian" or die $!;
1829         open CN, ">", "debian/changelog" or die $!;
1830         my $oldclog = git_cat_file ":debian/changelog";
1831         $oldclog =~ m/^($package_re) \(\S+\) / or
1832             fail "cannot parse old changelog to get package name";
1833         my $p = $1;
1834         print CN <<END, $oldclog or die $!;
1835 $p ($new_version) UNRELEASED; urgency=medium
1836
1837   * Update to new upstream version $new_upstream_version.
1838
1839  -- $clogsignoff
1840
1841 END
1842         close CN or die $!;
1843         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1844
1845         # Now we have the final new breakwater branch in the index
1846         $new_bw = make_commit [ $new_bw ],
1847             [ "Update changelog for new upstream $new_upstream_version",
1848               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1849             ];
1850     };
1851
1852     # we have constructed the new breakwater. we now need to commit to
1853     # the laundering output, because git-rebase can't easily be made
1854     # to make a replay list which is based on some other branch
1855
1856     update_head_postlaunder $old_head, $old_laundered_tip,
1857         'launder for new upstream';
1858
1859     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1860     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1861         "debrebase new-upstream $new_version: rebase";
1862     runcmd @cmd;
1863     # now it's for the user to sort out
1864 }
1865
1866 sub cmd_record_ffq_prev () {
1867     badusage "no arguments allowed" if @ARGV;
1868     my ($status, $msg) = record_ffq_prev_deferred();
1869     if ($status eq 'exists' && $opt_noop_ok) {
1870         print "Previous head already recorded\n" or die $!;
1871     } elsif ($status eq 'deferred') {
1872         run_deferred_updates 'record-ffq-prev';
1873     } else {
1874         fail "Could not preserve: $msg";
1875     }
1876 }
1877
1878 sub cmd_anchor () {
1879     badusage "no arguments allowed" if @ARGV;
1880     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1881     print "$bw\n" or die $!;
1882 }
1883
1884 sub cmd_breakwater () {
1885     badusage "no arguments allowed" if @ARGV;
1886     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1887     print "$bw\n" or die $!;
1888 }
1889
1890 sub cmd_status () {
1891     badusage "no arguments allowed" if @ARGV;
1892
1893     # todo: gdr status should print divergence info
1894     # todo: gdr status should print upstream component(s) info
1895     # todo: gdr should leave/maintain some refs with this kind of info ?
1896
1897     my $oldest = { Badness => 0 };
1898     my $newest;
1899     my $note = sub {
1900         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1901         if ($oldest->{Badness} < $badness) {
1902             $oldest = $newest = undef;
1903         }
1904         $oldest = {
1905                    Badness => $badness,
1906                    CommitId => $cl->{CommitId},
1907                    OurMsg => $ourmsg,
1908                    KcMsg => $kcmsg,
1909                   };
1910         $newest //= $oldest;
1911     };
1912     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1913         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1914         sub { $note->(2, 'branch is unlaundered', @_); },
1915         sub { $note->(3, 'branch needs laundering', @_); },
1916         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1917
1918     my $prcommitinfo = sub {
1919         my ($cid) = @_;
1920         flush STDOUT or die $!;
1921         runcmd @git, qw(--no-pager log -n1),
1922             '--pretty=format:    %h %s%n',
1923             $cid;
1924     };
1925
1926     print "current branch contents, in git-debrebase terms:\n";
1927     if (!$oldest->{Badness}) {
1928         print "  branch is laundered\n";
1929     } else {
1930         print "  $oldest->{OurMsg}\n";
1931         my $printed = '';
1932         foreach my $info ($oldest, $newest) {
1933             my $cid = $info->{CommitId};
1934             next if $cid eq $printed;
1935             $printed = $cid;
1936             print "  $info->{KcMsg}\n";
1937             $prcommitinfo->($cid);
1938         }
1939     }
1940
1941     my $prab = sub {
1942         my ($cid, $what) = @_;
1943         if (!defined $cid) {
1944             print "  $what is not well-defined\n";
1945         } else {
1946             print "  $what\n";
1947             $prcommitinfo->($cid);
1948         }
1949     };
1950     print "key git-debrebase commits:\n";
1951     $prab->($anchor, 'anchor');
1952     $prab->($bw, 'breakwater');
1953
1954     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1955         ffq_prev_branchinfo();
1956
1957     print "branch and ref status, in git-debrebase terms:\n";
1958     if ($ffq_msg) {
1959         print "  $ffq_msg\n";
1960     } else {
1961         $ffq_prev = git_get_ref $ffq_prev;
1962         $gdrlast = git_get_ref $gdrlast;
1963         if ($ffq_prev) {
1964             print "  unstitched; previous tip was:\n";
1965             $prcommitinfo->($ffq_prev);
1966         } elsif (!$gdrlast) {
1967             print "  stitched? (no record of git-debrebase work)\n";
1968         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1969             print "  stitched\n";
1970         } else {
1971             print "  not git-debrebase (diverged since last stitch)\n"
1972         }
1973     }
1974     print "you are currently rebasing\n" if currently_rebasing();
1975 }
1976
1977 sub cmd_stitch () {
1978     my $prose = 'stitch';
1979     getoptions("stitch",
1980                'prose=s', \$prose);
1981     badusage "no arguments allowed" if @ARGV;
1982     do_stitch $prose, 0;
1983 }
1984 sub cmd_prepush () { cmd_stitch(); }
1985
1986 sub cmd_quick () {
1987     badusage "no arguments allowed" if @ARGV;
1988     do_launder_head 'launder for git-debrebase quick';
1989     do_stitch 'quick';
1990 }
1991
1992 sub cmd_conclude () {
1993     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1994     if (!$ffq_prev_commitish) {
1995         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1996         return;
1997     }
1998     my $dangling_head = get_head();
1999
2000     badusage "no arguments allowed" if @ARGV;
2001     do_launder_head 'launder for git-debrebase quick';
2002     do_stitch 'quick';
2003 }
2004
2005 sub cmd_scrap () {
2006     if (currently_rebasing()) {
2007         runcmd @git, qw(rebase --abort);
2008     }
2009     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2010     if (!$ffq_prev_commitish) {
2011         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2012         finish 0;
2013     }
2014     my $scrapping_head = get_head();
2015     badusage "no arguments allowed" if @ARGV;
2016     push @deferred_updates,
2017         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2018         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2019     snags_maybe_bail();
2020     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2021 }
2022
2023 sub make_patches_staged ($) {
2024     my ($head) = @_;
2025     # Produces the patches that would result from $head if it were
2026     # laundered.
2027     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2028     fresh_workarea();
2029     in_workarea sub {
2030         gbp_pq_export 'bw', $secret_bw, $secret_head;
2031     };
2032 }
2033
2034 sub make_patches ($) {
2035     my ($head) = @_;
2036     keycommits $head, 0, \&snag;
2037     make_patches_staged $head;
2038     my $out;
2039     in_workarea sub {
2040         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2041         runcmd @git, qw(read-tree), $head;
2042         read_tree_subdir 'debian/patches', $ptree;
2043         $out = make_commit [$head], [
2044             'Commit patch queue (exported by git-debrebase)',
2045             '[git-debrebase: export and commit patches]',
2046         ];
2047     };
2048     return $out;
2049 }
2050
2051 sub cmd_make_patches () {
2052     my $opt_quiet_would_amend;
2053     getoptions("make-patches",
2054                'quiet-would-amend!', \$opt_quiet_would_amend);
2055     badusage "no arguments allowed" if @ARGV;
2056     bail_if_rebasing();
2057     my $old_head = get_head();
2058     my $new = make_patches $old_head;
2059     my $d = get_differs $old_head, $new;
2060     if ($d == 0) {
2061         fail "No (more) patches to export." unless $opt_noop_ok;
2062         return;
2063     } elsif ($d == D_PAT_ADD) {
2064         snags_maybe_bail();
2065         update_head_checkout $old_head, $new, 'make-patches';
2066     } else {
2067         print STDERR failmsg
2068             "Patch export produced patch amendments".
2069             " (abandoned output commit $new).".
2070             "  Try laundering first."
2071             unless $opt_quiet_would_amend;
2072         finish 7;
2073     }
2074 }
2075
2076 sub cmd_convert_from_gbp () {
2077     badusage "want only 1 optional argument, the upstream git commitish"
2078         unless @ARGV<=1;
2079
2080     my $clogp = parsechangelog();
2081     my $version = $clogp->{'Version'}
2082         // die "missing Version from changelog";
2083
2084     my ($upstream_spec) = @ARGV;
2085
2086     my $upstream_version = upstreamversion $version;
2087     my $upstream =
2088         resolve_upstream_version($upstream_spec, $upstream_version);
2089
2090     my $old_head = get_head();
2091
2092     my $upsdiff = get_differs $upstream, $old_head;
2093     if ($upsdiff & D_UPS) {
2094         runcmd @git, qw(--no-pager diff --stat),
2095             $upstream, $old_head,
2096             qw( -- :!/debian :/);
2097         fail <<END;
2098 upstream ($upstream_spec) and HEAD are not
2099 identical in upstream files.  See diffstat above, or run
2100   git diff $upstream_spec HEAD -- :!/debian :/
2101 END
2102     }
2103
2104     if (!is_fast_fwd $upstream, $old_head) {
2105         snag 'upstream-not-ancestor',
2106             "upstream ($upstream) is not an ancestor of HEAD";
2107     } else {
2108         my $wrong = cmdoutput
2109             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2110              qw(-- :/ :!/debian));
2111         if (length $wrong) {
2112             snag 'unexpected-upstream-changes',
2113                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2114             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2115         }
2116     }
2117
2118     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2119         snag 'upstream-has-debian',
2120             "upstream ($upstream) contains debian/ directory";
2121     }
2122
2123     my $previous_dgit_view = eval {
2124         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2125         my ($lvsn, $suite);
2126         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2127             my ($stz, $desc) = @_;
2128             no warnings qw(exiting);
2129             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2130             next unless $stz->{Date};
2131             next unless $stz->{Distribution} ne 'UNRELEASED';
2132             $lvsn = $stz->{Version};
2133             $suite = $stz->{Distribution};
2134             last;
2135         };
2136         die "neither of the first two changelog entries are released\n"
2137             unless defined $lvsn;
2138         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2139         my $mtag_pat = debiantag_maintview $lvsn, '*';
2140         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2141             $mtag_pat;
2142         die "could not find suitable maintainer view tag $mtag_pat\n"
2143             unless $mtag_pat =~ m{/};
2144         is_fast_fwd $mtag, 'HEAD' or
2145             die "HEAD is not FF from maintainer tag $mtag!";
2146         my $dtag = "archive/$mtag";
2147         is_fast_fwd $mtag, $dtag or
2148             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2149         print "will stitch in dgit view, $dtag\n";
2150         git_rev_parse $dtag;
2151     };
2152     if (!$previous_dgit_view) {
2153         $@ =~ s/^\n+//;
2154         chomp $@;
2155         print STDERR "cannot stitch in dgit view: $@\n";
2156     }
2157
2158     snags_maybe_bail_early();
2159
2160     my $work;
2161
2162     fresh_workarea();
2163     in_workarea sub {
2164         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2165         # make a branch out of the patch queue - we'll want this in a mo
2166         runcmd qw(gbp pq import);
2167         # strip the patches out
2168         runcmd @git, qw(checkout -q gdr-internal~0);
2169         rm_subdir_cached 'debian/patches';
2170         $work = make_commit ['HEAD'], [
2171  'git-debrebase convert-from-gbp: drop patches from tree',
2172  'Delete debian/patches, as part of converting to git-debrebase format.',
2173  '[git-debrebase convert-from-gbp: drop patches from tree]'
2174                               ];
2175         # make the anchor merge
2176         # the tree is already exactly right
2177         $work = make_commit [$work, $upstream], [
2178  'git-debrebase import: declare upstream',
2179  'First breakwater merge.',
2180  '[git-debrebase anchor: declare upstream]'
2181                               ];
2182
2183         # rebase the patch queue onto the new breakwater
2184         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2185         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2186         $work = git_rev_parse 'HEAD';
2187
2188         if ($previous_dgit_view) {
2189             $work = make_commit [$work, $previous_dgit_view], [
2190  'git-debrebase import: declare ff from dgit archive view',
2191  '[git-debrebase pseudomerge: import-from-gbp]',
2192             ];
2193         }
2194     };
2195
2196     ffq_check $work;
2197     snags_maybe_bail();
2198     update_head_checkout $old_head, $work, 'convert-from-gbp';
2199 }
2200
2201 sub cmd_convert_to_gbp () {
2202     badusage "no arguments allowed" if @ARGV;
2203     my $head = get_head();
2204     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2205     keycommits $head, 0;
2206     my $out;
2207     make_patches_staged $head;
2208     in_workarea sub {
2209         $out = make_commit ['HEAD'], [
2210             'Commit patch queue (converted from git-debrebase format)',
2211             '[git-debrebase convert-to-gbp: commit patches]',
2212         ];
2213     };
2214     if (defined $ffq) {
2215         push @deferred_updates, "delete $ffq";
2216         push @deferred_updates, "delete $gdrlast";
2217     }
2218     snags_maybe_bail();
2219     update_head_checkout $head, $out, "convert to gbp (v0)";
2220     print <<END or die $!;
2221 git-debrebase: converted to git-buildpackage branch format
2222 git-debrebase: WARNING: do not now run "git-debrebase" any more
2223 git-debrebase: WARNING: doing so would drop all upstream patches!
2224 END
2225 }
2226
2227 sub cmd_convert_from_dgit_view () {
2228     my $clogp = parsechangelog();
2229
2230     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2231     my $do_origs = 1;
2232     my $do_tags = 1;
2233     my $always = 0;
2234     my $diagnose = 0;
2235
2236     getoptions("convert-from-dgit-view",
2237                'diagnose!', \$diagnose,
2238                'build-products-dir:s', \$bpd,
2239                'origs!', \$do_origs,
2240                'tags!', \$do_tags,
2241                'always-convert-anyway!', \$always);
2242     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2243
2244     my @upstreams;
2245
2246     if (@ARGV) {
2247         my $spec = shift @ARGV;
2248         my $commit = git_rev_parse "$spec^{commit}";
2249         push @upstreams, { Commit => $commit,
2250                            Source => "$ARGV[0], from command line",
2251                            Only => 1,
2252                          };
2253     }
2254
2255     my $head = get_head();
2256
2257     if (!$always) {
2258         my $troubles = 0;
2259         my $trouble = sub { $troubles++; };
2260         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2261         printdebug "troubles=$troubles\n";
2262         if (!$troubles) {
2263             print STDERR <<END;
2264 $us: Branch already seems to be in git-debrebase format!
2265 $us: --always-convert-anyway would do the conversion operation anyway
2266 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2267 END
2268             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2269             finish 0;
2270         }
2271     }
2272
2273     snags_maybe_bail_early();
2274
2275     my $version = upstreamversion $clogp->{Version};
2276     print STDERR "Considering possible commits corresponding to upstream:\n";
2277
2278     if (!@upstreams) {
2279         if ($do_tags) {
2280             my @tried;
2281             my $ups_tag = upstream_commitish_search $version, \@tried;
2282             if ($ups_tag) {
2283                 my $this = "git tag $tried[-1]";
2284                 push @upstreams, { Commit => $ups_tag,
2285                                    Source => $this,
2286                                  };
2287             } else {
2288                 printf STDERR
2289                     " git tag: no suitable tag found (tried %s)\n",
2290                     "@tried";
2291             }
2292         }
2293         if ($do_origs) {
2294             my $p = $clogp->{'Source'};
2295             # we do a quick check to see if there are plausible origs
2296             my $something=0;
2297             if (!opendir BPD, $bpd) {
2298                 die "$bpd: opendir: $!" unless $!==ENOENT;
2299             } else {
2300                 while ($!=0, my $f = readdir BPD) {
2301                     next unless is_orig_file_of_p_v $f, $p, $version;
2302                     printf STDERR
2303                         " orig: found what looks like a .orig, %s\n",
2304                         "$bpd/$f";
2305                     $something=1;
2306                     last;
2307                 }
2308                 die "read $bpd: $!" if $!;
2309                 closedir BPD;
2310             }
2311             if ($something) {
2312                 my $tree = cmdoutput
2313                     @dgit, qw(--build-products-dir), $bpd,
2314                     qw(print-unapplied-treeish);
2315                 fresh_workarea();
2316                 in_workarea sub {
2317                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2318                     rm_subdir_cached 'debian';
2319                     $tree = cmdoutput @git, qw(write-tree);
2320                     my $ups_synth = make_commit [], [ <<END, <<END,
2321 Import effective orig tree for upstream version $version
2322 END
2323 This includes the contents of the .orig(s), minus any debian/ directory.
2324
2325 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2326 END
2327                                                     ];
2328                     push @upstreams, { Commit => $ups_synth,
2329                                        Source => "orig(s) imported via dgit",
2330                                      };
2331                 }
2332             } else {
2333                 printf STDERR
2334                     " orig: no suitable origs found (looked for %s in %s)\n",
2335                     "${p}_".(stripeoch $version)."...", $bpd;
2336             }
2337         }
2338     }
2339
2340     my $some_patches = stat_exists 'debian/patches/series';
2341
2342     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2343
2344     my $result;
2345     foreach my $u (@upstreams) {
2346         my $work = $head;
2347         fresh_workarea();
2348         in_workarea sub {
2349             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2350             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2351             runcmd @git, qw(clean -xdff);
2352             runcmd @git, qw(checkout), $head, qw(-- debian);
2353             if ($some_patches) {
2354                 rm_subdir_cached 'debian/patches';
2355                 $work = make_commit [ $work ], [
2356  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2357  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2358  "to git-debrebase format.  Upstream changes will appear as commits.",
2359  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2360                                            ];
2361             }
2362             $work = make_commit [ $work, $u->{Commit} ], [
2363  'git-debrebase convert-from-dgit-view: declare upstream',
2364  '(Re)constructed breakwater merge.',
2365  '[git-debrebase anchor: declare upstream]'
2366                                                          ];
2367             runcmd @git, qw(checkout --quiet -b mk), $work;
2368             if ($some_patches) {
2369                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2370                 runcmd @git, qw(reset --quiet);
2371                 my @gbp_cmd = (qw(gbp pq import));
2372                 if (!$diagnose) {
2373                     my $gbp_err = "../gbp-pq-err";
2374                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2375                 }
2376                 my $r = system @gbp_cmd;
2377                 if ($r) {
2378                     printf STDERR
2379                         " %s: couldn't apply patches: gbp pq %s",
2380                         $u->{Source}, waitstatusmsg();
2381                     return;
2382                 }
2383             }
2384             my $work = git_rev_parse qw(HEAD);
2385             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2386             if (length $diffout) {
2387                 print STDERR
2388                     " $u->{Source}: applying patches gives different tree\n";
2389                 print STDERR $diffout if $diagnose;
2390                 return;
2391             }
2392             # OMG!
2393             $u->{Result} = $work;
2394             $result = $u;
2395         };
2396         last if $result;
2397     }
2398
2399     if (!$result) {
2400         fail <<END;
2401 Could not find or construct a suitable upstream commit.
2402 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2403 upstream commmit explicitly or provide suitable origs.
2404 END
2405     }
2406
2407     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2408
2409     ffq_check $result->{Result};
2410     snags_maybe_bail();
2411     update_head_checkout $head, $result->{Result},
2412         'convert-from-dgit-view';
2413 }
2414
2415 sub cmd_downstream_rebase_launder_v0 () {
2416     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2417     my ($base) = @ARGV;
2418     $base = git_rev_parse $base;
2419     my $old_head = get_head();
2420     my $current = $old_head;
2421     my $topmost_keep;
2422     for (;;) {
2423         if ($current eq $base) {
2424             $topmost_keep //= $current;
2425             print " $current BASE stop\n";
2426             last;
2427         }
2428         my $cl = classify $current;
2429         print " $current $cl->{Type}";
2430         my $keep = 0;
2431         my $p0 = $cl->{Parents}[0]{CommitId};
2432         my $next;
2433         if ($cl->{Type} eq 'Pseudomerge') {
2434             print " ^".($cl->{Contributor}{Ix}+1);
2435             $next = $cl->{Contributor}{CommitId};
2436         } elsif ($cl->{Type} eq 'AddPatches' or
2437                  $cl->{Type} eq 'Changelog') {
2438             print " strip";
2439             $next = $p0;
2440         } else {
2441             print " keep";
2442             $next = $p0;
2443             $keep = 1;
2444         }
2445         print "\n";
2446         if ($keep) {
2447             $topmost_keep //= $current;
2448         } else {
2449             die "to-be stripped changes not on top of the branch\n"
2450                 if $topmost_keep;
2451         }
2452         $current = $next;
2453     }
2454     if ($topmost_keep eq $old_head) {
2455         print "unchanged\n";
2456     } else {
2457         print "updating to $topmost_keep\n";
2458         update_head_checkout
2459             $old_head, $topmost_keep,
2460             'downstream-rebase-launder-v0';
2461     }
2462 }
2463
2464 getoptions_main
2465           ("bad options\n",
2466            "D+" => \$debuglevel,
2467            'noop-ok', => \$opt_noop_ok,
2468            'f=s' => \@snag_force_opts,
2469            'anchor=s' => \@opt_anchors,
2470            '--dgit=s' => \($dgit[0]),
2471            'force!',
2472            '-i:s' => sub {
2473                my ($opt,$val) = @_;
2474                badusage "git-debrebase: no cuddling to -i for git-rebase"
2475                    if length $val;
2476                die if $opt_defaultcmd_interactive; # should not happen
2477                $opt_defaultcmd_interactive = [ qw(-i) ];
2478                # This access to @ARGV is excessive familiarity with
2479                # Getopt::Long, but there isn't another sensible
2480                # approach.  '-i=s{0,}' does not work with bundling.
2481                push @$opt_defaultcmd_interactive, @ARGV;
2482                @ARGV=();
2483            },
2484            'help' => sub { print $usage_message or die $!; finish 0; },
2485            );
2486
2487 initdebug('git-debrebase ');
2488 enabledebug if $debuglevel;
2489
2490 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2491 chdir $toplevel or die "chdir $toplevel: $!";
2492
2493 $rd = fresh_playground "$playprefix/misc";
2494
2495 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2496
2497 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2498     defaultcmd_rebase();
2499 } else {
2500     my $cmd = shift @ARGV;
2501     my $cmdfn = $cmd;
2502     $cmdfn =~ y/-/_/;
2503     $cmdfn = ${*::}{"cmd_$cmdfn"};
2504
2505     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2506     $cmdfn->();
2507 }
2508
2509 finish 0;