git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea (;$) {
 132     my ($subdir) = @_;
 133     $subdir //= 'work';
 134     $workarea = fresh_playground "$playprefix/$subdir";
 135     in_workarea sub { playtree_setup };
 136 }
 137
 138 sub run_ref_updates_now ($$) {
 139     my ($mrest, $updates) = @_;
 140     # @$updates is a list of lines for git-update-ref, without \ns
 141
 142     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 143     debugcmd '>|', @upd_cmd;
 144     open U, "|-", @upd_cmd or die $!;
 145     foreach (@$updates) {
 146         printdebug ">= ", $_, "\n";
 147         print U $_, "\n" or die $!;
 148     }
 149     printdebug ">\$\n";
 150     close U or failedcmd @upd_cmd;
 151 }
 152
 153 our $snags_forced = 0;
 154 our $snags_tripped = 0;
 155 our $snags_summarised = 0;
 156 our @deferred_updates;
 157 our @deferred_update_messages;
 158
 159 sub merge_wreckage_cleaning ($) {
 160     my ($updates) = @_;
 161     git_for_each_ref("$wrecknoteprefix/*", sub {
 162         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 163         push @$updates, "delete $fullrefname";
 164     });
 165 }
 166
 167 sub all_snags_summarised () {
 168     $snags_forced + $snags_tripped == $snags_summarised;
 169 }
 170 sub run_deferred_updates ($) {
 171     my ($mrest) = @_;
 172
 173     confess 'dangerous internal error' unless all_snags_summarised();
 174
 175     merge_wreckage_cleaning \@deferred_updates;
 176     run_ref_updates_now $mrest, \@deferred_updates;
 177     print $_, "\n" foreach @deferred_update_messages;
 178
 179     @deferred_updates = ();
 180     @deferred_update_messages = ();
 181 }
 182
 183 sub get_differs ($$) {
 184     my ($x,$y) = @_;
 185     # This resembles quiltify_trees_differ, in dgit, a bit.
 186     # But we don't care about modes, or dpkg-source-unrepresentable
 187     # changes, and we don't need the plethora of different modes.
 188     # Conversely we need to distinguish different kinds of changes to
 189     # debian/ and debian/patches/.
 190
 191     my $differs = 0;
 192
 193     my $rundiff = sub {
 194         my ($opts, $limits, $fn) = @_;
 195         my @cmd = (@git, qw(diff-tree -z --no-renames));
 196         push @cmd, @$opts;
 197         push @cmd, "$_:" foreach $x, $y;
 198         push @cmd, '--', @$limits;
 199         my $diffs = cmdoutput @cmd;
 200         foreach (split /\0/, $diffs) { $fn->(); }
 201     };
 202
 203     $rundiff->([qw(--name-only)], [], sub {
 204         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 205     });
 206
 207     if ($differs & DS_DEB) {
 208         $differs &= ~DS_DEB;
 209         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 210             $differs |=
 211                 m{^debian/patches/}      ? D_PAT_OTH  :
 212                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 213                                            D_DEB_OTH;
 214         });
 215         die "mysterious debian changes $x..$y"
 216             unless $differs & (D_PAT_OTH|DS_DEB);
 217     }
 218
 219     if ($differs & D_PAT_OTH) {
 220         my $mode;
 221         $differs &= ~D_PAT_OTH;
 222         my $pat_oth = sub {
 223             $differs |= D_PAT_OTH;
 224             no warnings qw(exiting);  last;
 225         };
 226         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 227             no warnings qw(exiting);
 228             if (!defined $mode) {
 229                 $mode = $_;  next;
 230             }
 231             die unless s{^debian/patches/}{};
 232             my $ok;
 233             if ($mode eq 'A' && !m/\.series$/s) {
 234                 $ok = 1;
 235             } elsif ($mode eq 'M' && $_ eq 'series') {
 236                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 237                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 238                 chomp $x_s;  $x_s .= "\n";
 239                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 240             } else {
 241                 # nope
 242             }
 243             $mode = undef;
 244             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 245         });
 246         die "mysterious debian/patches changes $x..$y"
 247             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 248     }
 249
 250     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 251
 252     return $differs;
 253 }
 254
 255 sub commit_pr_info ($) {
 256     my ($r) = @_;
 257     return Data::Dumper->dump([$r], [qw(commit)]);
 258 }
 259
 260 sub calculate_committer_authline () {
 261     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 262         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 263     my ($h,$m) = get_commit $c;
 264     $h =~ m/^committer .*$/m or confess "($h) ?";
 265     return $&;
 266 }
 267
 268 sub rm_subdir_cached ($) {
 269     my ($subdir) = @_;
 270     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 271 }
 272
 273 sub read_tree_subdir ($$) {
 274     my ($subdir, $new_tree_object) = @_;
 275     rm_subdir_cached $subdir;
 276     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 277 }
 278
 279 sub read_tree_debian ($) {
 280     my ($treeish) = @_;
 281     read_tree_subdir 'debian', "$treeish:debian";
 282     rm_subdir_cached 'debian/patches';
 283 }
 284
 285 sub read_tree_upstream ($;$$) {
 286     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 287     # if $tree_with_debian is supplied, will use that for debian/
 288     # otherwise will save and restore it.
 289     my $debian =
 290         $tree_with_debian ? "$tree_with_debian:debian"
 291         : cmdoutput @git, qw(write-tree --prefix=debian/);
 292     runcmd @git, qw(read-tree), $treeish;
 293     read_tree_subdir 'debian', $debian;
 294     rm_subdir_cached 'debian/patches' unless $keep_patches;
 295 };
 296
 297 sub make_commit ($$) {
 298     my ($parents, $message_paras) = @_;
 299     my $tree = cmdoutput @git, qw(write-tree);
 300     my @cmd = (@git, qw(commit-tree), $tree);
 301     push @cmd, qw(-p), $_ foreach @$parents;
 302     push @cmd, qw(-m), $_ foreach @$message_paras;
 303     return cmdoutput @cmd;
 304 }
 305
 306 our @snag_force_opts;
 307 sub snag ($$;@) {
 308     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 309     if (grep { $_ eq $tag } @snag_force_opts) {
 310         $snags_forced++;
 311         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 312     } else {
 313         $snags_tripped++;
 314         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 315     }
 316 }
 317
 318 # Important: all mainline code must call snags_maybe_bail after
 319 # any point where snag might be called, but before making changes
 320 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 321 # may be called more than once if necessary (but this is not ideal
 322 # because then the messages about number of snags may be confusing).
 323 sub snags_maybe_bail () {
 324     return if all_snags_summarised();
 325     if ($snags_forced) {
 326         printf STDERR
 327             "%s: snags: %d overriden by individual -f options\n",
 328             $us, $snags_forced;
 329     }
 330     if ($snags_tripped) {
 331         if ($opt_force) {
 332             printf STDERR
 333                 "%s: snags: %d overriden by global --force\n",
 334                 $us, $snags_tripped;
 335         } else {
 336             fail sprintf
 337   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 338                 $us, $snags_tripped;
 339         }
 340     }
 341     $snags_summarised = $snags_forced + $snags_tripped;
 342 }
 343 sub snags_maybe_bail_early () {
 344     # useful to bail out early without doing a lot of work;
 345     # not a substitute for snags_maybe_bail.
 346     snags_maybe_bail() if $snags_tripped && !$opt_force;
 347 }
 348 sub any_snags () {
 349     return $snags_forced || $snags_tripped;
 350 }
 351
 352 sub gbp_pq_export ($$$) {
 353     my ($bname, $base, $tip) = @_;
 354     # must be run in a workarea.  $bname and patch-queue/$bname
 355     # ought not to exist.  Leaves you on patch-queue/$bname with
 356     # the patches staged but not committed.
 357     printdebug "gbp_pq_export $bname $base $tip\n";
 358     runcmd @git, qw(checkout -q -b), $bname, $base;
 359     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 360     my @gbp_cmd = (qw(gbp pq export));
 361     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 362     if ($r) {
 363         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 364         failedcmd @gbp_cmd;
 365     }
 366     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 367 }
 368
 369
 370 # xxx allow merge resolution separately from laundering, before git merge
 371 #
 372 # xxx general gdr docs highlight forbidden things
 373 # xxx general gdr docs list allowable things ?
 374 # xxx general gdr docs explicitly forbid some rebase
 375 #
 376 # xxx provide a way for the user to help
 377 # xxx (eg, provide wreckage provide way to continue)
 378
 379 # later/rework?
 380 #  use git-format-patch?
 381 #  our own patch identification algorithm?
 382 #  this is an alternative strategy
 383
 384 sub merge_failed ($$;@) {
 385     my ($wrecknotes, $emsg, @xmsgs) = @_;
 386     my @m;
 387     push @m, "Merge resolution failed: $emsg";
 388     push @m, @xmsgs;
 389
 390     changedir $maindir;
 391
 392     my @updates;
 393     merge_wreckage_cleaning \@updates;
 394     run_ref_updates_now "merge failed", \@updates;
 395
 396     @updates = ();
 397     keys %$wrecknotes;
 398     while (my ($k,$v) = each %$wrecknotes) {
 399         push @updates, "create $wrecknoteprefix/$k $v";
 400     }
 401     run_ref_updates_now "merge failed", \@updates;
 402     push @m, "Wreckage left in $wrecknoteprefix/*.";
 403
 404     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 405
 406     # use finish rather than fail, in case we are within an eval
 407     # (that can happen inside walk!)
 408     print STDERR "\n";
 409     print STDERR "$us: $_\n" foreach @m;
 410     finish 15;
 411 }
 412
 413 sub mwrecknote ($$$) {
 414     my ($wrecknotes, $reftail, $commitish) = @_;
 415     confess unless defined $commitish;
 416     printdebug "mwrecknote $reftail $commitish\n";
 417     $wrecknotes->{$reftail} = $commitish;
 418 }
 419
 420 sub merge_attempt_cmd {
 421     my $wrecknotes = shift @_;
 422     debugcmd '+', @_;
 423     $!=0; $?=-1;
 424     if (system @_) {
 425         merge_failed $wrecknotes,
 426             failedcmd_waitstatus(),
 427             "failed command: @_";
 428     }
 429 }
 430
 431 sub merge_series ($$$;@) {
 432     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 433     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 434     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 435     # ^ specifies several patch series (currently we only support exactly 2)
 436     # return value is a commit which is the result of
 437     # merging the two versions of the same topic branch
 438     #   $input_q[0] and $input_q[1]
 439     # with respect to the old version
 440     #   $base_q
 441     # all onto $newbase.
 442
 443     # Creates, in *_q, a key MR for its private use
 444
 445     printdebug "merge_series newbase=$newbase\n";
 446
 447     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 448     $base_q->{MR}{S} = 'base';
 449
 450     my %prereq;
 451     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 452     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 453     # $prereq{<patch filename>}               exists or not (even later)
 454
 455     my $result;
 456     my $merged_pq;
 457
 458     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 459
 460     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 461
 462     local $workarea;
 463     fresh_workarea "merge";
 464     my $seriesfile = "debian/patches/series";
 465     in_workarea sub {
 466         playtree_setup();
 467         foreach my $q ($base_q, reverse @input_qs) {
 468             my $s = $q->{MR}{S};
 469             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 470             my @earlier;
 471             if (open S, $seriesfile) {
 472                 while (my $patch = <S>) {
 473                     chomp $patch or die $!;
 474                     $prereq{$patch} //= {};
 475                     foreach my $earlier (@earlier) {
 476                         $prereq{$patch}{$earlier}{$s}++ and die;
 477                     }
 478                     push @earlier, $patch;
 479                     stat "debian/patches/$patch" or die "$patch ?";
 480                 }
 481                 S->error and die "$seriesfile $!";
 482                 close S;
 483             } else {
 484                 die "$seriesfile $!" unless $!==ENOENT;
 485             }
 486             read_tree_upstream $newbase, 1;
 487             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 488                 "Convert $s to patch queue for merging",
 489                 "[git-debrebase merge-innards patch-queue import:".
 490                 " $q->{SeriesTip}]"
 491             ];
 492             printdebug "merge_series  pec $pec ";
 493             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 494             $pec = make_commit [ $pec ], [
 495                 "Drop series file from $s to avoid merge trouble",
 496                 "[git-debrebase merge-innards patch-queue prep:".
 497                 " $q->{SeriesTip}]"
 498             ];
 499
 500             read_tree_debian $newbase;
 501             if (@earlier) {
 502                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 503             } else {
 504                 rm_subdir_cached 'debian/patches';
 505             }
 506             $pec = make_commit [ $pec ], [
 507  "Update debian/ (excluding patches) to final to avoid re-merging",
 508  "debian/ was already merged and we need to just take that.",
 509                 "[git-debrebase merge-innards patch-queue packaging:".
 510                 " $q->{SeriesTip}]"
 511             ];
 512
 513             printdebug "pec' $pec\n";
 514             runcmd @git, qw(reset -q --hard), $pec;
 515             $q->{MR}{PEC} = $pec;
 516             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 517         }
 518         # now, because of reverse, we are on $input_q->{MR}{OQC}
 519         runcmd @git, qw(checkout -q -b merge);
 520         printdebug "merge_series merging...\n";
 521         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 522
 523         $attempt_cmd->(@mergecmd);
 524
 525         printdebug "merge_series merge ok, series...\n";
 526         # We need to construct a new series file
 527         # Firstly, resolve prereq
 528         foreach my $f (sort keys %prereq) {
 529             printdebug "merge_series  patch\t$f\t";
 530             if (!stat_exists "debian/patches/$f") {
 531                 print DEBUG " drop\n" if $debuglevel;
 532                 # git merge deleted it; that's how we tell it's not wanted
 533                 delete $prereq{$f};
 534                 next;
 535             }
 536             print DEBUG " keep\n" if $debuglevel;
 537             foreach my $g (sort keys %{ $prereq{$f} }) {
 538                 my $gfp = $prereq{$f}{$g};
 539                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 540                 if (!!$gfp->{0} == !!$gfp->{1}
 541                     ? $gfp->{0}
 542                     : !$gfp->{base}) {
 543                     print DEBUG "\tkeep\n" if $debuglevel;
 544                 } else {
 545                     print DEBUG "\tdrop\n" if $debuglevel;
 546                     delete $prereq{$f}{$g};
 547                 }
 548             }
 549         }
 550
 551         my $unsat = sub {
 552             my ($f) = @_;
 553             return scalar keys %{ $prereq{$f} };
 554         };
 555
 556         my $nodate = time + 1;
 557         my %authordate;
 558         # $authordate{<patch filename>};
 559         my $authordate = sub {
 560             my ($f) = @_;
 561             $authordate{$f} //= do {
 562                 open PF, "<", "debian/patches/$f" or die "$f $!";
 563                 while (<PF>) {
 564                     return $nodate if m/^$/;
 565                     last if s{^Date: }{};
 566                 }
 567                 chomp;
 568                 return cmdoutput qw(date +%s -d), $_;
 569             };
 570         };
 571
 572         open NS, '>', $seriesfile or die $!;
 573
 574         while (keys %prereq) {
 575             my $best;
 576             foreach my $try (sort keys %prereq) {
 577                 if ($best) {
 578                     next if (
 579                              $unsat->($try) <=> $unsat->($best) or
 580                              $authordate->($try) <=> $authordate->($best) or
 581                              $try cmp $best
 582                             ) >= 0;
 583                 }
 584                 $best = $try;
 585             }
 586             printdebug "merge_series series next $best\n";
 587             print NS "$best\n" or die $!;
 588             delete $prereq{$best};
 589             foreach my $gp (values %prereq) {
 590                 delete $gp->{$best};
 591             }
 592         }
 593
 594         runcmd @git, qw(add), $seriesfile;
 595         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 596         $merged_pq = git_rev_parse 'HEAD';
 597         $mwrecknote->('merged-patchqueue', $merged_pq);
 598
 599         printdebug "merge_series series gbp pq import\n";
 600         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 601
 602         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 603
 604         # OK now we are on patch-queue/merge, and we need to rebase
 605         # onto the intended parent and drop the patches from each one
 606
 607         printdebug "merge_series series ok, building...\n";
 608         my $build = $newbase;
 609         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 610         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 611             my $commit = git_cat_file $c, 'commit';
 612             printdebug "merge_series series ok, building $c\n";
 613             read_tree_upstream $c, 0, $newbase;
 614             my $tree = cmdoutput @git, qw(write-tree);
 615             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 616             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 617             open C, ">", "../mcommit" or die $!;
 618             print C $commit or die $!;
 619             close C or die $!;
 620             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 621         }
 622         $result = $build;
 623         mwrecknote($wrecknotes, 'merged-result', $result);
 624
 625         runcmd @git, qw(update-ref refs/heads/result), $result;
 626
 627         runcmd @git, qw(checkout -q -b debug);
 628         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 629         runcmd @git, qw(add .);
 630         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 631         my $mdebug = git_rev_parse 'HEAD';
 632         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 633         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 634     };
 635     printdebug "merge_series returns $result\n";
 636     return $result;
 637 }
 638
 639 # classify returns an info hash like this
 640 #   CommitId => $objid
 641 #   Hdr => # commit headers, including 1 final newline
 642 #   Msg => # commit message (so one newline is dropped)
 643 #   Tree => $treeobjid
 644 #   Type => (see below)
 645 #   Parents = [ {
 646 #       Ix => $index # ie 0, 1, 2, ...
 647 #       CommitId
 648 #       Differs => return value from get_differs
 649 #       IsOrigin
 650 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 651 #     } ...]
 652 #   NewMsg => # commit message, but with any [dgit import ...] edited
 653 #             # to say "[was: ...]"
 654 #
 655 # Types:
 656 #   Packaging
 657 #   Changelog
 658 #   Upstream
 659 #   AddPatches
 660 #   Mixed
 661 #
 662 #   Pseudomerge
 663 #     has additional entres in classification result
 664 #       Overwritten = [ subset of Parents ]
 665 #       Contributor = $the_remaining_Parent
 666 #
 667 #   DgitImportUnpatched
 668 #     has additional entry in classification result
 669 #       OrigParents = [ subset of Parents ]
 670 #
 671 #   Anchor
 672 #     has additional entry in classification result
 673 #       OrigParents = [ subset of Parents ]  # singleton list
 674 #
 675 #   TreatAsAnchor
 676 #
 677 #   BreakwaterStart
 678 #
 679 #   Unknown
 680 #     has additional entry in classification result
 681 #       Why => "prose"
 682
 683 sub parsecommit ($;$) {
 684     my ($objid, $p_ref) = @_;
 685     # => hash with                   CommitId Hdr Msg Tree Parents
 686     #    Parents entries have only   Ix CommitId
 687     #    $p_ref, if provided, must be [] and is used as a base for Parents
 688
 689     $p_ref //= [];
 690     die if @$p_ref;
 691
 692     my ($h,$m) = get_commit $objid;
 693
 694     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 695     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 696
 697     my $r = {
 698         CommitId => $objid,
 699         Hdr => $h,
 700         Msg => $m,
 701         Tree => $t,
 702         Parents => $p_ref,
 703     };
 704
 705     foreach my $ph (@ph) {
 706         push @$p_ref, {
 707             Ix => scalar @$p_ref,
 708             CommitId => $ph,
 709         };
 710     }
 711
 712     return $r;
 713 }
 714
 715 sub classify ($) {
 716     my ($objid) = @_;
 717
 718     my @p;
 719     my $r = parsecommit($objid, \@p);
 720     my $t = $r->{Tree};
 721
 722     foreach my $p (@p) {
 723         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 724     }
 725
 726     printdebug "classify $objid \$t=$t \@p",
 727         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 728         "\n";
 729
 730     my $classify = sub {
 731         my ($type, @rest) = @_;
 732         $r = { %$r, Type => $type, @rest };
 733         if ($debuglevel) {
 734             printdebug " = $type ".(dd $r)."\n";
 735         }
 736         return $r;
 737     };
 738     my $unknown = sub {
 739         my ($why) = @_;
 740         $r = { %$r, Type => qw(Unknown), Why => $why };
 741         printdebug " ** Unknown\n";
 742         return $r;
 743     };
 744
 745     if (grep { $_ eq $objid } @opt_anchors) {
 746         return $classify->('TreatAsAnchor');
 747     }
 748
 749     my @identical = grep { !$_->{Differs} } @p;
 750     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 751     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 752
 753     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 754         # multi-orig upstreams are represented with an anchor merge
 755         # from a single upstream commit which combines the orig tarballs
 756
 757         # Every anchor tagged this way must be a merge.
 758         # We are relying on the
 759         #     [git-debrebase anchor: ...]
 760         # commit message annotation in "declare" anchor merges (which
 761         # do not have any upstream changes), to distinguish those
 762         # anchor merges from ordinary pseudomerges (which we might
 763         # just try to strip).
 764         #
 765         # However, the user is going to be doing git-rebase a lot.  We
 766         # really don't want them to rewrite an anchor commit.
 767         # git-rebase trips up on merges, so that is a useful safety
 768         # catch.
 769         #
 770         # BreakwaterStart commits are also anchors in the terminology
 771         # of git-debrebase(5), but they are untagged (and always
 772         # manually generated).
 773         #
 774         # We cannot not tolerate any tagged linear commit (ie,
 775         # BreakwaterStart commits tagged `[anchor:') because such a
 776         # thing could result from an erroneous linearising raw git
 777         # rebase of a merge anchor.  That would represent a corruption
 778         # of the branch. and we want to detect and reject the results
 779         # of such corruption before it makes it out anywhere.  If we
 780         # reject it here then we avoid making the pseudomerge which
 781         # would be needed to push it.
 782
 783         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 784         @p == 2 or return $badanchor->("has other than two parents");
 785         $haspatches and return $badanchor->("contains debian/patches");
 786
 787         # How to decide about l/r ordering of anchors ?  git
 788         # --topo-order prefers to expand 2nd parent first.  There's
 789         # already an easy rune to look for debian/ history anyway (git log
 790         # debian/) so debian breakwater branch should be 1st parent; that
 791         # way also there's also an easy rune to look for the upstream
 792         # patches (--topo-order).
 793
 794         # Also this makes --first-parent be slightly more likely to
 795         # be useful - it makes it provide a linearised breakwater history.
 796
 797         # Of course one can say somthing like
 798         #  gitk -- ':/' ':!/debian'
 799         # to get _just_ the commits touching upstream files, and by
 800         # the TREESAME logic in git-rev-list this will leave the
 801         # breakwater into upstream at the first anchor.  But that
 802         # doesn't report debian/ changes at all.
 803
 804         # Other observations about gitk: by default, gitk seems to
 805         # produce output in a different order to git-rev-list.  I
 806         # can't seem to find this documented anywhere.  gitk
 807         # --date-order DTRT.  But, gitk always seems to put the
 808         # parents from left to right, in order, so it's easy to see
 809         # which way round a pseudomerge is.
 810
 811         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 812         $p[1]{Differs} & ~DS_DEB and
 813             $badanchor->("upstream files differ from left parent");
 814         $p[0]{Differs} & ~D_UPS and
 815             $badanchor->("debian/ differs from right parent");
 816
 817         return $classify->(qw(Anchor),
 818                            OrigParents => [ $p[1] ]);
 819     }
 820
 821     if (@p == 1) {
 822         my $d = $r->{Parents}[0]{Differs};
 823         if ($d == D_PAT_ADD) {
 824             return $classify->(qw(AddPatches));
 825         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 826             return $unknown->("edits debian/patches");
 827         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 828             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 829             if ($ty eq 'tree') {
 830                 if ($d == D_DEB_CLOG) {
 831                     return $classify->(qw(Changelog));
 832                 } else {
 833                     return $classify->(qw(Packaging));
 834                 }
 835             } elsif ($ty eq 'missing') {
 836                 return $classify->(qw(BreakwaterStart));
 837             } else {
 838                 return $unknown->("parent's debian is not a directory");
 839             }
 840         } elsif ($d == D_UPS) {
 841             return $classify->(qw(Upstream));
 842         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 843             return $classify->(qw(Mixed));
 844         } elsif ($d == 0) {
 845             return $unknown->("no changes");
 846         } else {
 847             confess "internal error $objid ?";
 848         }
 849     }
 850     if (!@p) {
 851         return $unknown->("origin commit");
 852     }
 853
 854     if (@p == 2 && @identical == 1) {
 855         my @overwritten = grep { $_->{Differs} } @p;
 856         confess "internal error $objid ?" unless @overwritten==1;
 857         return $classify->(qw(Pseudomerge),
 858                            Overwritten => [ $overwritten[0] ],
 859                            Contributor => $identical[0]);
 860     }
 861     if (@p == 2 && @identical == 2) {
 862         my $get_t = sub {
 863             my ($ph,$pm) = get_commit $_[0]{CommitId};
 864             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 865             $1;
 866         };
 867         my @bytime = @p;
 868         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 869         if ($order > 0) { # newer first
 870         } elsif ($order < 0) {
 871             @bytime = reverse @bytime;
 872         } else {
 873             # same age, default to order made by -s ours
 874             # that is, commit was made by someone who preferred L
 875         }
 876         return $classify->(qw(Pseudomerge),
 877                            SubType => qw(Ambiguous),
 878                            Contributor => $bytime[0],
 879                            Overwritten => [ $bytime[1] ]);
 880     }
 881     foreach my $p (@p) {
 882         my ($p_h, $p_m) = get_commit $p->{CommitId};
 883         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 884         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 885     }
 886     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 887     my $m2 = $r->{Msg};
 888     if (!(grep { !$_->{IsOrigin} } @p) and
 889         (@orig_ps >= @p - 1) and
 890         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 891         $r->{NewMsg} = $m2;
 892         return $classify->(qw(DgitImportUnpatched),
 893                            OrigParents => \@orig_ps);
 894     }
 895
 896     if (@p == 2 and
 897         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 898         # xxx ^ metadata tag needs adding to (5)
 899         return $classify->("MergedBreakwaters");
 900     }
 901     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 902         return $unknown->("unknown kind of merge from $1");
 903     }
 904     if (@p > 2) {
 905         return $unknown->("octopus merge");
 906     }
 907
 908     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 909         return $unknown->("general two-parent merge");
 910     }
 911
 912     return $classify->("VanillaMerge");
 913 }
 914
 915 sub keycommits ($;$$$$$);
 916
 917 sub mergedbreakwaters_anchor ($) {
 918     my ($cl) = @_;
 919     my $best_anchor;
 920     foreach my $p (@{ $cl->{Parents} }) {
 921         my ($panchor, $pbw) = keycommits $p->{CommitId},
 922             undef,undef,undef,undef, 1;
 923         $best_anchor = $panchor
 924             if !defined $best_anchor
 925             or is_fast_fwd $best_anchor, $panchor;
 926         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 927             unless is_fast_fwd $panchor, $best_anchor;
 928     }
 929     return $best_anchor;
 930 }
 931
 932 sub keycommits ($;$$$$$) {
 933     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 934     # => ($anchor, $breakwater)
 935
 936     # $unclean->("unclean-$tagsfx", $msg, $cl)
 937     # $furniture->("unclean-$tagsfx", $msg, $cl)
 938     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 939     #   is callled for each situation or commit that
 940     #   wouldn't be found in a laundered branch
 941     # $furniture is for furniture commits such as might be found on an
 942     #   interchange branch (pseudomerge, d/patches, changelog)
 943     # $trouble is for things whnich prevent the return of
 944     #   anchor and breakwater information; if that is ignored,
 945     #   then keycommits returns (undef, undef) instead.
 946     # $fatal is for unprocessable commits, and should normally cause
 947     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 948     #
 949     # If $claimed_bw, this is supposed to be a breakwater commit.
 950     #
 951     # If a callback is undef, fail is called instead.
 952     # If a callback is defined but false, the situation is ignored.
 953     # Callbacks may say:
 954     #   no warnings qw(exiting); last;
 955     # if the answer is no longer wanted.
 956
 957     my ($anchor, $breakwater);
 958     $breakwater = $head if $claimed_bw;
 959     my $clogonly;
 960     my $cl;
 961     my $found_pm;
 962     $fatal //= sub { fail $_[1]; };
 963     my $x = sub {
 964         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 965         my $why = $mainwhy.$xwhy;
 966         my $m = "branch needs laundering (run git-debrebase): $why";
 967         fail $m unless defined $cb;
 968         return unless $cb;
 969         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 970     };
 971     my $found_anchor = sub {
 972         ($anchor) = @_;
 973         $breakwater //= $clogonly;
 974         $breakwater //= $head;
 975         no warnings qw(exiting);
 976         last;
 977     };
 978     for (;;) {
 979         $cl = classify $head;
 980         my $ty = $cl->{Type};
 981         if ($ty eq 'Packaging') {
 982             $breakwater //= $clogonly;
 983             $breakwater //= $head;
 984         } elsif ($ty eq 'Changelog') {
 985             # this is going to count as the tip of the breakwater
 986             # only if it has no upstream stuff before it
 987             $clogonly //= $head;
 988         } elsif ($ty eq 'Anchor' or
 989                  $ty eq 'TreatAsAnchor' or
 990                  $ty eq 'BreakwaterStart') {
 991             $found_anchor->($head);
 992         } elsif ($ty eq 'Upstream') {
 993             $x->($unclean, 'ordering',
 994  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 995                 if defined $breakwater;
 996             $clogonly = undef;
 997             $breakwater = undef;
 998         } elsif ($ty eq 'Mixed') {
 999             $x->($unclean, 'mixed',
1000                  "found mixed upstream/packaging commit"," ($head)");
1001             $clogonly = undef;
1002             $breakwater = undef;
1003         } elsif ($ty eq 'Pseudomerge' or
1004                  $ty eq 'AddPatches') {
1005             my $found_pm = 1;
1006             $x->($furniture, (lc $ty),
1007                  "found interchange bureaucracy commit ($ty)"," ($head)");
1008         } elsif ($ty eq 'DgitImportUnpatched') {
1009             if ($found_pm) {
1010                 $x->($trouble, 'dgitimport',
1011                      "found dgit dsc import"," ($head)");
1012                 return (undef,undef);
1013             } else {
1014                 $x->($fatal, 'unprocessable',
1015                      "found bare dgit dsc import with no prior history",
1016                      " ($head)");
1017                 return (undef,undef);
1018             }
1019         } elsif ($ty eq 'VanillaMerge') {
1020             $x->($trouble, 'vanillamerge',
1021                  "found vanilla merge"," ($head)");
1022             return (undef,undef);
1023         } elsif ($ty eq 'MergedBreakwaters') {
1024             $found_anchor->(mergedbreakwaters_anchor $cl);
1025         } else {
1026             $x->($fatal, 'unprocessable',
1027                  "found unprocessable commit, cannot cope: $cl->{Why}",
1028                  " ($head)");
1029             return (undef,undef);
1030         }
1031         $head = $cl->{Parents}[0]{CommitId};
1032     }
1033     return ($anchor, $breakwater);
1034 }
1035
1036 sub walk ($;$$$);
1037 sub walk ($;$$$) {
1038     my ($input,
1039         $nogenerate,$report, $report_lprefix) = @_;
1040     # => ($tip, $breakwater_tip, $last_anchor)
1041     # (or nothing, if $nogenerate)
1042
1043     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1044     $report_lprefix //= '';
1045
1046     # go through commits backwards
1047     # we generate two lists of commits to apply:
1048     # breakwater branch and upstream patches
1049     my (@brw_cl, @upp_cl, @processed);
1050     my %found;
1051     my $upp_limit;
1052     my @pseudomerges;
1053
1054     my $cl;
1055     my $xmsg = sub {
1056         my ($prose, $info) = @_;
1057         my $ms = $cl->{Msg};
1058         chomp $ms;
1059         $info //= '';
1060         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1061         return (Msg => $ms);
1062     };
1063     my $rewrite_from_here = sub {
1064         my ($cl) = @_;
1065         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1066         push @$cl, $sp_cl;
1067         push @processed, $sp_cl;
1068     };
1069     my $cur = $input;
1070
1071     my $prdelim = "";
1072     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1073
1074     my $prline = sub {
1075         return unless $report;
1076         print $report $prdelim, $report_lprefix, @_;
1077         $prdelim = "\n";
1078     };
1079
1080     my $bomb = sub { # usage: return $bomb->();
1081         print $report " Unprocessable" if $report;
1082         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1083         $prprdelim->();
1084         if ($nogenerate) {
1085             return (undef,undef);
1086         }
1087         fail "found unprocessable commit, cannot cope".
1088             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1089             " (commit $cur) (d.".
1090             (join ' ', map { sprintf "%#x", $_->{Differs} }
1091              @{ $cl->{Parents} }).
1092                  ")";
1093     };
1094
1095     my $build;
1096     my $breakwater;
1097
1098     my $build_start = sub {
1099         my ($msg, $parent) = @_;
1100         $prline->(" $msg");
1101         $build = $parent;
1102         no warnings qw(exiting); last;
1103     };
1104
1105     my $nomerge = sub {
1106         my ($emsg) = @_;
1107         merge_failed $cl->{MergeWreckNotes}, $emsg;
1108     };
1109
1110     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1111
1112     my $last_anchor;
1113
1114     for (;;) {
1115         $cl = classify $cur;
1116         $cl->{MergeWreckNotes} //= {};
1117         my $ty = $cl->{Type};
1118         my $st = $cl->{SubType};
1119         $prline->("$cl->{CommitId} $cl->{Type}");
1120         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1121         push @processed, $cl;
1122         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1123         if ($ty eq 'AddPatches') {
1124             $cur = $p0;
1125             $rewrite_from_here->(\@upp_cl);
1126             next;
1127         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1128             push @brw_cl, $cl;
1129             $cur = $p0;
1130             next;
1131         } elsif ($ty eq 'BreakwaterStart') {
1132             $last_anchor = $cur;
1133             $build_start->('FirstPackaging', $cur);
1134         } elsif ($ty eq 'Upstream') {
1135             push @upp_cl, $cl;
1136             $cur = $p0;
1137             next;
1138         } elsif ($ty eq 'Mixed') {
1139             my $queue = sub {
1140                 my ($q, $wh) = @_;
1141                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1142                 push @$q, $cls;
1143             };
1144             $queue->(\@brw_cl, "debian");
1145             $queue->(\@upp_cl, "upstream");
1146             $rewrite_from_here->(\@brw_cl);
1147             $cur = $p0;
1148             next;
1149         } elsif ($ty eq 'Pseudomerge') {
1150             my $contrib = $cl->{Contributor}{CommitId};
1151             print $report " Contributor=$contrib" if $report;
1152             push @pseudomerges, $cl;
1153             $rewrite_from_here->(\@upp_cl);
1154             $cur = $contrib;
1155             next;
1156         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1157             $last_anchor = $cur;
1158             $build_start->("Anchor", $cur);
1159         } elsif ($ty eq 'DgitImportUnpatched') {
1160             my $pm = $pseudomerges[-1];
1161             if (defined $pm) {
1162                 # To an extent, this is heuristic.  Imports don't have
1163                 # a useful history of the debian/ branch.  We assume
1164                 # that the first pseudomerge after an import has a
1165                 # useful history of debian/, and ignore the histories
1166                 # from later pseudomerges.  Often the first pseudomerge
1167                 # will be the dgit import of the upload to the actual
1168                 # suite intended by the non-dgit NMUer, and later
1169                 # pseudomerges may represent in-archive copies.
1170                 my $ovwrs = $pm->{Overwritten};
1171                 printf $report " PM=%s \@Overwr:%d",
1172                     $pm->{CommitId}, (scalar @$ovwrs)
1173                     if $report;
1174                 if (@$ovwrs != 1) {
1175                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1176                     return $bomb->();
1177                 }
1178                 my $ovwr = $ovwrs->[0]{CommitId};
1179                 printf $report " Overwr=%s", $ovwr if $report;
1180                 # This import has a tree which is just like a
1181                 # breakwater tree, but it has the wrong history.  It
1182                 # ought to have the previous breakwater (which the
1183                 # pseudomerge overwrote) as an ancestor.  That will
1184                 # make the history of the debian/ files correct.  As
1185                 # for the upstream version: either it's the same as
1186                 # was ovewritten (ie, same as the previous
1187                 # breakwater), in which case that history is precisely
1188                 # right; or, otherwise, it was a non-gitish upload of a
1189                 # new upstream version.  We can tell these apart by
1190                 # looking at the tree of the supposed upstream.
1191                 push @brw_cl, {
1192                     %$cl,
1193                     SpecialMethod => 'DgitImportDebianUpdate',
1194                     $xmsg->("convert dgit import: debian changes")
1195                 }, {
1196                     %$cl,
1197                     SpecialMethod => 'DgitImportUpstreamUpdate',
1198                     $xmsg->("convert dgit import: upstream update",
1199                             " anchor")
1200                 };
1201                 $prline->(" Import");
1202                 $rewrite_from_here->(\@brw_cl);
1203                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1204                 $cur = $ovwr;
1205                 next;
1206             } else {
1207                 # Everything is from this import.  This kind of import
1208                 # is already nearly in valid breakwater format, with the
1209                 # patches as commits.  Unfortunately it contains
1210                 # debian/patches/.
1211                 printdebug "*** WALK BOMB bare dgit import\n";
1212                 $cl->{Why} = "bare dgit dsc import";
1213                 return $bomb->();
1214             }
1215             die "$ty ?";
1216         } elsif ($ty eq 'MergedBreakwaters') {
1217             $last_anchor = mergedbreakwaters_anchor $cl;
1218             $build_start->(' MergedBreakwaters', $cur);
1219             last;
1220         } elsif ($ty eq 'VanillaMerge') {
1221             # User may have merged unstitched branch(es).  We will
1222             # have now lost what ffq-prev was then (since the later
1223             # pseudomerge may introduce further changes).  The effect
1224             # of resolving such a merge is that we may have to go back
1225             # further in history to find a merge base, since the one
1226             # which was reachable via ffq-prev is no longer findable.
1227             # This is suboptimal, but if it all works we'll have done
1228             # the right thing.
1229             # xxx we should warn the user in the docs about this
1230
1231             my $ok=1;
1232             my $best_anchor;
1233             # We expect to find a dominating anchor amongst the
1234             # inputs' anchors.  That will be the new anchor.
1235             #
1236             # More complicated is finding a merge base for the
1237             # breakwaters.  We need a merge base that is a breakwater
1238             # commit.  The ancestors of breakwater commits are more
1239             # breakwater commits and possibly upstream commits and the
1240             # ancestors of those upstream.  Upstreams might have
1241             # arbitrary ancestors.  But any upstream commit U is
1242             # either included in both anchors, in which case the
1243             # earlier anchor is a better merge base than any of U's
1244             # ancestors; or U is not included in the older anchor, in
1245             # which case U is not an ancestor of the vanilla merge at
1246             # all.  So no upstream commit, nor any ancestor thereof,
1247             # is a best merge base.  As for non-breakwater Debian
1248             # commits: these are never ancestors of any breakwater.
1249             #
1250             # So any best merge base as found by git-merge-base
1251             # is a suitable breakwater anchor.  Usually there will
1252             # be only one.
1253
1254             printdebug "*** MERGE\n";
1255
1256             my @bwbcmd = (@git, qw(merge-base));
1257             my @ibcmd = (@git, qw(merge-base --all));
1258             my $might_be_in_bw = 1;
1259
1260             my $ps = $cl->{Parents};
1261
1262             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1263
1264             foreach my $p (@$ps) {
1265                 $prline->(" VanillaMerge ".$p->{Ix});
1266                 $prprdelim->();
1267                 my ($ptip, $pbw, $panchor) =
1268                     walk $p->{CommitId}, 0, $report,
1269                          $report_lprefix.'  ';
1270                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1271                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1272                 $p->{Anchor} = $panchor;
1273
1274                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1275                 $mwrecknote->("$lr-input", $p->{CommitId});
1276
1277                 my $mwrecknote_parent = sub {
1278                     my ($which) = @_;
1279                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1280                 };
1281                 $mwrecknote_parent->('Laundered');
1282                 $mwrecknote_parent->('Breakwater');
1283                 $mwrecknote_parent->('Anchor');
1284
1285                 $best_anchor = $panchor if
1286                     !defined $best_anchor or
1287                     is_fast_fwd $best_anchor, $panchor;
1288
1289                 printdebug " MERGE BA best=".($best_anchor//'-').
1290                     " p=$panchor\n";
1291             }
1292
1293             $mwrecknote->('result-anchor', $best_anchor);
1294
1295             foreach my $p (@$ps) {
1296                 $prline->(" VanillaMerge ".$p->{Ix});
1297                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1298                     $nomerge->('divergent anchors');
1299                 } elsif ($p->{Anchor} eq $best_anchor) {
1300                     print $report " SameAnchor" if $report;
1301                 } else {
1302                     print $report " SupersededAnchor" if $report;
1303                 }
1304                 if ($p->{Breakwater} eq $p->{CommitId}) {
1305                     # this parent commit was its own breakwater,
1306                     # ie it is part of the breakwater
1307                     print $report " Breakwater" if $report;
1308                 } else {
1309                     $might_be_in_bw = 0;
1310                 }
1311                 push @bwbcmd, $p->{Breakwater};
1312                 push @ibcmd, $p->{CommitId};
1313             }
1314
1315             if ($ok && $might_be_in_bw) {
1316                 # We could rewrite this to contaion the metadata
1317                 # declaring it to be MergedBreakwaters, but
1318                 # unnecessarily rewriting a merge seems unhelpful.
1319                 $prline->(" VanillaMerge MergedBreakwaters");
1320                 $last_anchor = $best_anchor;
1321                 $build_start->('MergedBreakwaters', $cur);
1322             }
1323
1324             my $bwb = cmdoutput @bwbcmd;
1325
1326             # OK, now we have a breakwater base, but we need the merge
1327             # base for the interchange branch because we need the delta
1328             # queue.
1329             #
1330             # This a the best merge base of our inputs which has the
1331             # breakwater merge base as an ancestor.
1332
1333             my @ibs =
1334                 grep /./,
1335                 split /\n/,
1336                 cmdoutput @ibcmd;
1337
1338             @ibs or confess 'internal error, expected anchor at least ?';
1339
1340             my $ib;
1341             my $ibleaf;
1342             foreach my $tibix (0..$#ibs) {
1343                 my $tib = $ibs[$tibix];
1344                 my $ff = is_fast_fwd $bwb, $tib;
1345                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1346                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1347                 $mwrecknote->($tibleaf, $tib);
1348                 next unless $ff;
1349                 next if $ib;
1350                 $ib = $tib;
1351                 $ibleaf = $tibleaf;
1352             }
1353
1354             $ib or $nomerge->("no suitable interchange merge base");
1355
1356             $prline->("  VanillaMerge Base");
1357             $prprdelim->();
1358             my ($btip, $bbw, $banchor) = eval {
1359                 walk $ib, 0, $report, $report_lprefix.'  ';
1360             };
1361             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1362                        $@)
1363                 if length $@;
1364
1365             $mwrecknote->("mergebase-laundered", $btip);
1366             $mwrecknote->("mergebase-breakwater", $bbw);
1367             $mwrecknote->("mergebase-anchor", $banchor);
1368
1369             my $ibinfo = { SeriesTip => $btip,
1370                            SeriesBase => $bbw,
1371                            Anchor => $banchor,
1372                            LeftRight => 'mergebase' };
1373
1374             $bbw eq $bwb
1375                 or $nomerge->("interchange merge-base ($ib)'s".
1376                               " breakwater ($bbw)".
1377                               " != breakwaters' merge-base ($bwb)");
1378
1379             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1380                  or $nomerge->("interchange merge-base ($ib)'s".
1381                                " anchor ($ibinfo->{SeriesBase})".
1382                                " != any merge input's anchor (".
1383                                (join ' ', map { $_->{Anchor} } @$ps).
1384                                ")");
1385
1386             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1387             $cl->{MergeBestAnchor} = $best_anchor;
1388             push @brw_cl, {
1389                 %$cl,
1390                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1391                 $xmsg->('constructed from vanilla merge',
1392                         ' merged-breakwater'),
1393             };
1394             push @upp_cl, {
1395                 %$cl,
1396                 SpecialMethod => 'MergeMergeSeries',
1397             };
1398             $build_start->('MergeBreakwaters', $cur);
1399         } else {
1400             printdebug "*** WALK BOMB unrecognised\n";
1401             return $bomb->();
1402         }
1403     }
1404     $prprdelim->();
1405
1406     printdebug "*** WALK prep done cur=$cur".
1407         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1408
1409     return if $nogenerate;
1410
1411     # Now we build it back up again
1412
1413     fresh_workarea();
1414
1415     my $rewriting = 0;
1416
1417     my $read_tree_upstream = sub {
1418         my ($treeish) = @_;
1419         read_tree_upstream $treeish, 0, $build;
1420     };
1421
1422     $#upp_cl = $upp_limit if defined $upp_limit;
1423
1424     my $committer_authline = calculate_committer_authline();
1425
1426     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1427
1428     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1429
1430     in_workarea sub {
1431         mkdir $rd or $!==EEXIST or die $!;
1432         my $current_method;
1433         runcmd @git, qw(read-tree), $build;
1434         foreach my $cl (qw(Debian), (reverse @brw_cl),
1435                         { SpecialMethod => 'RecordBreakwaterTip' },
1436                         qw(Upstream), (reverse @upp_cl)) {
1437             if (!ref $cl) {
1438                 $current_method = $cl;
1439                 next;
1440             }
1441             my $method = $cl->{SpecialMethod} // $current_method;
1442             my @parents = ($build);
1443             my $cltree = $cl->{CommitId};
1444             printdebug "WALK BUILD ".($cltree//'undef').
1445                 " $method (rewriting=$rewriting)\n";
1446             if ($method eq 'Debian') {
1447                 read_tree_debian($cltree);
1448             } elsif ($method eq 'Upstream') {
1449                 $read_tree_upstream->($cltree);
1450             } elsif ($method eq 'StartRewrite') {
1451                 $rewriting = 1;
1452                 next;
1453             } elsif ($method eq 'RecordBreakwaterTip') {
1454                 $breakwater = $build;
1455                 next;
1456             } elsif ($method eq 'DgitImportDebianUpdate') {
1457                 read_tree_debian($cltree);
1458             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1459                 confess unless $rewriting;
1460                 my $differs = (get_differs $build, $cltree);
1461                 next unless $differs & D_UPS;
1462                 $read_tree_upstream->($cltree);
1463                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1464             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1465                 print "Found a general merge, will try to tidy it up.\n";
1466                 $rewriting = 1;
1467                 $read_tree_upstream->($cl->{MergeBestAnchor});
1468                 $read_tree_upstream->($cl->{MergeBestAnchor});
1469                 read_tree_debian($cltree);
1470                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1471             } elsif ($method eq 'MergeMergeSeries') {
1472                 print "Running merge resolution for $cl->{CommitId}...\n";
1473                 $build = merge_series
1474                     $build, $cl->{MergeWreckNotes},
1475                     $cl->{MergeInterchangeBaseInfo},
1476                     @{ $cl->{Parents} };
1477                 $last_anchor = $cl->{MergeBestAnchor};
1478
1479                 # Check for mismerges:
1480                 my $check = sub {
1481                     my ($against, $allow, $what) = @_;
1482                     my $differs = get_differs $build, $against;
1483                     $nomerge->(sprintf
1484        "merge misresolved: %s are not the same (%s %s d.%#x)",
1485                                $what, $against, $build, $differs)
1486                         if $differs & ~($allow | D_PAT_ADD);
1487                 };
1488
1489                 # Breakwater changes which were in each side of the
1490                 # merge will have been incorporated into the
1491                 # MergeCreateMergedBreakwaters output.  Because the
1492                 # upstream series was rebased onto the new breakwater,
1493                 # so should all of the packaging changes which were in
1494                 # the input.
1495                 $check->($input, D_UPS, 'debian files');
1496
1497                 # Upstream files are merge_series, which ought to
1498                 # have been identical to the original merge.
1499                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1500
1501                 print "Merge resolution successful.\n";
1502                 next;
1503             } else {
1504                 confess "$method ?";
1505             }
1506             if (!$rewriting) {
1507                 my $procd = (pop @processed) // 'UNDEF';
1508                 if ($cl ne $procd) {
1509                     $rewriting = 1;
1510                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1511                 }
1512             }
1513             my $newtree = cmdoutput @git, qw(write-tree);
1514             my $ch = $cl->{Hdr};
1515             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1516             $ch =~ s{^parent .*\n}{}mg;
1517             $ch =~ s{(?=^author)}{
1518                 join '', map { "parent $_\n" } @parents
1519             }me or confess "$ch ?";
1520             if ($rewriting) {
1521                 $ch =~ s{^committer .*$}{$committer_authline}m
1522                     or confess "$ch ?";
1523             }
1524             my $cf = "$rd/m$rewriting";
1525             open CD, ">", $cf or die $!;
1526             print CD $ch, "\n", $cl->{Msg} or die $!;
1527             close CD or die $!;
1528             my @cmd = (@git, qw(hash-object));
1529             push @cmd, qw(-w) if $rewriting;
1530             push @cmd, qw(-t commit), $cf;
1531             my $newcommit = cmdoutput @cmd;
1532             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1533             $build = $newcommit;
1534             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1535                 $last_anchor = $cur;
1536             }
1537         }
1538     };
1539
1540     my $final_check = get_differs $build, $input;
1541     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1542         if $final_check & ~D_PAT_ADD;
1543
1544     my @r = ($build, $breakwater, $last_anchor);
1545     printdebug "*** WALK RETURN @r\n";
1546     return @r
1547 }
1548
1549 sub get_head () {
1550     git_check_unmodified();
1551     return git_rev_parse qw(HEAD);
1552 }
1553
1554 sub update_head ($$$) {
1555     my ($old, $new, $mrest) = @_;
1556     push @deferred_updates, "update HEAD $new $old";
1557     run_deferred_updates $mrest;
1558 }
1559
1560 sub update_head_checkout ($$$) {
1561     my ($old, $new, $mrest) = @_;
1562     update_head $old, $new, $mrest;
1563     runcmd @git, qw(reset --hard);
1564 }
1565
1566 sub update_head_postlaunder ($$$) {
1567     my ($old, $tip, $reflogmsg) = @_;
1568     return if $tip eq $old;
1569     print "git-debrebase: laundered (head was $old)\n";
1570     update_head $old, $tip, $reflogmsg;
1571     # no tree changes except debian/patches
1572     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1573 }
1574
1575 sub currently_rebasing() {
1576     foreach (qw(rebase-merge rebase-apply)) {
1577         return 1 if stat_exists "$maindir_gitdir/$_";
1578     }
1579     return 0;
1580 }
1581
1582 sub bail_if_rebasing() {
1583     fail "you are in the middle of a git-rebase already"
1584         if currently_rebasing();
1585 }
1586
1587 sub do_launder_head ($) {
1588     my ($reflogmsg) = @_;
1589     my $old = get_head();
1590     record_ffq_auto();
1591     my ($tip,$breakwater) = walk $old;
1592     snags_maybe_bail();
1593     update_head_postlaunder $old, $tip, $reflogmsg;
1594     return ($tip,$breakwater);
1595 }
1596
1597 sub cmd_launder_v0 () {
1598     badusage "no arguments to launder-v0 allowed" if @ARGV;
1599     my $old = get_head();
1600     my ($tip,$breakwater,$last_anchor) = walk $old;
1601     update_head_postlaunder $old, $tip, 'launder';
1602     printf "# breakwater tip\n%s\n", $breakwater;
1603     printf "# working tip\n%s\n", $tip;
1604     printf "# last anchor\n%s\n", $last_anchor;
1605 }
1606
1607 sub defaultcmd_rebase () {
1608     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1609     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1610     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1611 }
1612
1613 sub cmd_analyse () {
1614     badusage "analyse does not support any options"
1615         if @ARGV and $ARGV[0] =~ m/^-/;
1616     badusage "too many arguments to analyse" if @ARGV>1;
1617     my ($old) = @ARGV;
1618     if (defined $old) {
1619         $old = git_rev_parse $old;
1620     } else {
1621         $old = git_rev_parse 'HEAD';
1622     }
1623     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1624     STDOUT->error and die $!;
1625 }
1626
1627 sub ffq_prev_branchinfo () {
1628     my $current = git_get_symref();
1629     return gdr_ffq_prev_branchinfo($current);
1630 }
1631
1632 sub ffq_check ($;$$) {
1633     # calls $ff and/or $notff zero or more times
1634     # then returns either (status,message) where status is
1635     #    exists
1636     #    detached
1637     #    weird-symref
1638     #    notbranch
1639     # or (undef,undef, $ffq_prev,$gdrlast)
1640     # $ff and $notff are called like this:
1641     #   $ff->("message for stdout\n");
1642     #   $notff->('snag-name', $message);
1643     # normally $currentval should be HEAD
1644     my ($currentval, $ff, $notff) =@_;
1645
1646     $ff //= sub { print $_[0] or die $!; };
1647     $notff //= \&snag;
1648
1649     my ($status, $message, $current, $ffq_prev, $gdrlast)
1650         = ffq_prev_branchinfo();
1651     return ($status, $message) unless $status eq 'branch';
1652
1653     my $exists = git_get_ref $ffq_prev;
1654     return ('exists',"$ffq_prev already exists") if $exists;
1655
1656     return ('not-branch', 'HEAD symref is not to refs/heads/')
1657         unless $current =~ m{^refs/heads/};
1658     my $branch = $';
1659
1660     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1661     my %checked;
1662
1663     printdebug "ffq check_specs @check_specs\n";
1664
1665     my $check = sub {
1666         my ($lrref, $desc) = @_;
1667         printdebug "ffq might check $lrref ($desc)\n";
1668         my $invert;
1669         for my $chk (@check_specs) {
1670             my $glob = $chk;
1671             $invert = $glob =~ s{^[!^]}{};
1672             last if fnmatch $glob, $lrref;
1673         }
1674         return if $invert;
1675         my $lrval = git_get_ref $lrref;
1676         return unless length $lrval;
1677
1678         if (is_fast_fwd $lrval, $currentval) {
1679             $ff->("OK, you are ahead of $lrref\n");
1680             $checked{$lrref} = 1;
1681         } elsif (is_fast_fwd $currentval, $lrval) {
1682             $checked{$lrref} = -1;
1683             $notff->('behind', "you are behind $lrref, divergence risk");
1684         } else {
1685             $checked{$lrref} = -1;
1686             $notff->('diverged', "you have diverged from $lrref");
1687         }
1688     };
1689
1690     my $merge = cfg "branch.$branch.merge",1;
1691     if (defined $merge and $merge =~ m{^refs/heads/}) {
1692         my $rhs = $';
1693         printdebug "ffq merge $rhs\n";
1694         my $check_remote = sub {
1695             my ($remote, $desc) = @_;
1696             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1697             return unless defined $remote;
1698             $check->("refs/remotes/$remote/$rhs", $desc);
1699         };
1700         $check_remote->((scalar cfg "branch.$branch.remote",1),
1701                         'remote fetch/merge branch');
1702         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1703                         (scalar cfg "branch.$branch.pushDefault",1),
1704                         'remote push branch');
1705     }
1706     if ($branch =~ m{^dgit/}) {
1707         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1708     } elsif ($branch =~ m{^master$}) {
1709         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1710     }
1711     return (undef, undef, $ffq_prev, $gdrlast);
1712 }
1713
1714 sub record_ffq_prev_deferred () {
1715     # => ('status', "message")
1716     # 'status' may be
1717     #    deferred          message is undef
1718     #    exists
1719     #    detached
1720     #    weird-symref
1721     #    notbranch
1722     # if not ff from some branch we should be ff from, is an snag
1723     # if "deferred", will have added something about that to
1724     #   @deferred_update_messages, and also maybe printed (already)
1725     #   some messages about ff checks
1726     bail_if_rebasing();
1727     my $currentval = get_head();
1728
1729     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1730     return ($status,$message) if defined $status;
1731
1732     snags_maybe_bail();
1733
1734     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1735     push @deferred_updates, "delete $gdrlast";
1736     push @deferred_update_messages, "Recorded previous head for preservation";
1737     return ('deferred', undef);
1738 }
1739
1740 sub record_ffq_auto () {
1741     my ($status, $message) = record_ffq_prev_deferred();
1742     if ($status eq 'deferred' || $status eq 'exists') {
1743     } else {
1744         snag $status, "could not record ffq-prev: $message";
1745         snags_maybe_bail();
1746     }
1747 }
1748
1749 sub ffq_prev_info () {
1750     bail_if_rebasing();
1751     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1752     my ($status, $message, $current, $ffq_prev, $gdrlast)
1753         = ffq_prev_branchinfo();
1754     if ($status ne 'branch') {
1755         snag $status, "could not check ffq-prev: $message";
1756         snags_maybe_bail();
1757     }
1758     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1759     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1760 }
1761
1762 sub stitch ($$$$$) {
1763     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1764
1765     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1766
1767     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1768         my $differs = get_differs $old_head, $ffq_prev_commitish;
1769         unless ($differs & ~D_PAT_ADD) {
1770             # ffq-prev is ahead of us, and the only tree changes it has
1771             # are possibly addition of things in debian/patches/.
1772             # Just wind forwards rather than making a pointless pseudomerge.
1773             push @deferred_updates,
1774                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1775             update_head_checkout $old_head, $ffq_prev_commitish,
1776                 "stitch (fast forward)";
1777             return;
1778         }
1779     }
1780     fresh_workarea();
1781     # We make pseudomerges with L as the contributing parent.
1782     # This makes git rev-list --first-parent work properly.
1783     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1784         'Declare fast forward / record previous work',
1785         "[git-debrebase pseudomerge: $prose]",
1786     ];
1787     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1788     update_head $old_head, $new_head, "stitch: $prose";
1789 }
1790
1791 sub do_stitch ($;$) {
1792     my ($prose, $unclean) = @_;
1793
1794     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1795     if (!$ffq_prev_commitish) {
1796         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1797         return;
1798     }
1799     my $dangling_head = get_head();
1800
1801     keycommits $dangling_head, $unclean,$unclean,$unclean;
1802     snags_maybe_bail();
1803
1804     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1805 }
1806
1807 sub upstream_commitish_search ($$) {
1808     my ($upstream_version, $tried) = @_;
1809     # todo: at some point maybe use git-deborig to do this
1810     foreach my $tagpfx ('', 'v', 'upstream/') {
1811         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1812         my $new_upstream = git_get_ref "refs/tags/$tag";
1813         push @$tried, $tag;
1814         return $new_upstream if length $new_upstream;
1815     }
1816 }
1817
1818 sub resolve_upstream_version ($$) {
1819     my ($new_upstream, $upstream_version) = @_;
1820
1821     if (!defined $new_upstream) {
1822         my @tried;
1823         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1824         if (!length $new_upstream) {
1825             fail "Could not determine appropriate upstream commitish.\n".
1826                 " (Tried these tags: @tried)\n".
1827                 " Check version, and specify upstream commitish explicitly.";
1828         }
1829     }
1830     $new_upstream = git_rev_parse $new_upstream;
1831
1832     return $new_upstream;
1833 }
1834
1835 sub cmd_new_upstream () {
1836     # automatically and unconditionally launders before rebasing
1837     # if rebase --abort is used, laundering has still been done
1838
1839     my %pieces;
1840
1841     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1842
1843     # parse args - low commitment
1844     my $spec_version = shift @ARGV;
1845     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1846     fail "bad version number \`$spec_version'" unless defined $new_version;
1847     if ($new_version->is_native()) {
1848         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1849     }
1850
1851     my $new_upstream = shift @ARGV;
1852     my $new_upstream_version = upstreamversion  $new_version;
1853     $new_upstream =
1854         resolve_upstream_version $new_upstream, $new_upstream_version;
1855
1856     record_ffq_auto();
1857
1858     my $piece = sub {
1859         my ($n, @x) = @_; # may be ''
1860         my $pc = $pieces{$n} //= {
1861             Name => $n,
1862             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1863         };
1864         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1865         $pc;
1866     };
1867
1868     my @newpieces;
1869     my $newpiece = sub {
1870         my ($n, @x) = @_; # may be ''
1871         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1872         push @newpieces, $pc;
1873     };
1874
1875     $newpiece->('',
1876         OldIx => 0,
1877         New => $new_upstream,
1878     );
1879     while (@ARGV && $ARGV[0] !~ m{^-}) {
1880         my $n = shift @ARGV;
1881
1882         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1883             unless @ARGV && $ARGV[0] !~ m{^-};
1884
1885         my $c = git_rev_parse shift @ARGV;
1886         die unless $n =~ m/^$extra_orig_namepart_re$/;
1887         $newpiece->($n, New => $c);
1888     }
1889
1890     # now we need to investigate the branch this generates the
1891     # laundered version but we don't switch to it yet
1892     my $old_head = get_head();
1893     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1894
1895     my $old_bw_cl = classify $old_bw;
1896     my $old_anchor_cl = classify $old_anchor;
1897     my $old_upstream;
1898     if (!$old_anchor_cl->{OrigParents}) {
1899         snag 'anchor-treated',
1900             'old anchor is recognised due to --anchor, cannot check upstream';
1901     } else {
1902         $old_upstream = parsecommit
1903             $old_anchor_cl->{OrigParents}[0]{CommitId};
1904         $piece->('', Old => $old_upstream->{CommitId});
1905     }
1906
1907     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1908         if ($old_upstream->{Msg} =~
1909  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1910            ) {
1911             my @oldpieces = (split / /, $1);
1912             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1913             if ($old_n_parents != @oldpieces &&
1914                 $old_n_parents != @oldpieces + 1) {
1915                 snag 'upstream-confusing', sprintf
1916                     "previous upstream combine %s".
1917                     " mentions %d pieces (each implying one parent)".
1918                     " but has %d parents".
1919                     " (one per piece plus maybe a previous combine)",
1920                     $old_upstream->{CommitId},
1921                     (scalar @oldpieces),
1922                     $old_n_parents;
1923             } elsif ($oldpieces[0] ne '.') {
1924                 snag 'upstream-confusing', sprintf
1925                     "previous upstream combine %s".
1926                     " first piece is not \`.'",
1927                     $oldpieces[0];
1928             } else {
1929                 $oldpieces[0] = '';
1930                 foreach my $i (0..$#oldpieces) {
1931                     my $n = $oldpieces[$i];
1932                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1933                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1934                 }
1935             }
1936         } else {
1937             snag 'upstream-confusing',
1938                 "previous upstream $old_upstream->{CommitId} is from".
1939                " git-debrebase but not an \`upstream-combine' commit";
1940         }
1941     }
1942
1943     foreach my $pc (values %pieces) {
1944         if (!$old_upstream) {
1945             # we have complained already
1946         } elsif (!$pc->{Old}) {
1947             snag 'upstream-new-piece',
1948                 "introducing upstream piece \`$pc->{Name}'";
1949         } elsif (!$pc->{New}) {
1950             snag 'upstream-rm-piece',
1951                 "dropping upstream piece \`$pc->{Name}'";
1952         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1953             snag 'upstream-not-ff',
1954                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1955         }
1956     }
1957
1958     printdebug "%pieces = ", (dd \%pieces), "\n";
1959     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1960
1961     snags_maybe_bail();
1962
1963     my $new_bw;
1964
1965     fresh_workarea();
1966     in_workarea sub {
1967         my @upstream_merge_parents;
1968
1969         if (!any_snags()) {
1970             push @upstream_merge_parents, $old_upstream->{CommitId};
1971         }
1972
1973         foreach my $pc (@newpieces) { # always has '' first
1974             if ($pc->{Name}) {
1975                 read_tree_subdir $pc->{Name}, $pc->{New};
1976             } else {
1977                 runcmd @git, qw(read-tree), $pc->{New};
1978             }
1979             push @upstream_merge_parents, $pc->{New};
1980         }
1981
1982         # index now contains the new upstream
1983
1984         if (@newpieces > 1) {
1985             # need to make the upstream subtree merge commit
1986             $new_upstream = make_commit \@upstream_merge_parents,
1987                 [ "Combine upstreams for $new_upstream_version",
1988  ("[git-debrebase upstream-combine . ".
1989  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1990  ": new upstream]"),
1991                 ];
1992         }
1993
1994         # $new_upstream is either the single upstream commit, or the
1995         # combined commit we just made.  Either way it will be the
1996         # "upstream" parent of the anchor merge.
1997
1998         read_tree_subdir 'debian', "$old_bw:debian";
1999
2000         # index now contains the anchor merge contents
2001         $new_bw = make_commit [ $old_bw, $new_upstream ],
2002             [ "Update to upstream $new_upstream_version",
2003  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2004             ];
2005
2006         my $clogsignoff = cmdoutput qw(git show),
2007             '--pretty=format:%an <%ae>  %aD',
2008             $new_bw;
2009
2010         # Now we have to add a changelog stanza so the Debian version
2011         # is right.
2012         die if unlink "debian";
2013         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2014         unlink "debian/changelog" or $!==ENOENT or die $!;
2015         mkdir "debian" or die $!;
2016         open CN, ">", "debian/changelog" or die $!;
2017         my $oldclog = git_cat_file ":debian/changelog";
2018         $oldclog =~ m/^($package_re) \(\S+\) / or
2019             fail "cannot parse old changelog to get package name";
2020         my $p = $1;
2021         print CN <<END, $oldclog or die $!;
2022 $p ($new_version) UNRELEASED; urgency=medium
2023
2024   * Update to new upstream version $new_upstream_version.
2025
2026  -- $clogsignoff
2027
2028 END
2029         close CN or die $!;
2030         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2031
2032         # Now we have the final new breakwater branch in the index
2033         $new_bw = make_commit [ $new_bw ],
2034             [ "Update changelog for new upstream $new_upstream_version",
2035               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2036             ];
2037     };
2038
2039     # we have constructed the new breakwater. we now need to commit to
2040     # the laundering output, because git-rebase can't easily be made
2041     # to make a replay list which is based on some other branch
2042
2043     update_head_postlaunder $old_head, $old_laundered_tip,
2044         'launder for new upstream';
2045
2046     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2047     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2048         "debrebase new-upstream $new_version: rebase";
2049     runcmd @cmd;
2050     # now it's for the user to sort out
2051 }
2052
2053 sub cmd_record_ffq_prev () {
2054     badusage "no arguments allowed" if @ARGV;
2055     my ($status, $msg) = record_ffq_prev_deferred();
2056     if ($status eq 'exists' && $opt_noop_ok) {
2057         print "Previous head already recorded\n" or die $!;
2058     } elsif ($status eq 'deferred') {
2059         run_deferred_updates 'record-ffq-prev';
2060     } else {
2061         fail "Could not preserve: $msg";
2062     }
2063 }
2064
2065 sub cmd_anchor () {
2066     badusage "no arguments allowed" if @ARGV;
2067     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2068     print "$bw\n" or die $!;
2069 }
2070
2071 sub cmd_breakwater () {
2072     badusage "no arguments allowed" if @ARGV;
2073     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2074     print "$bw\n" or die $!;
2075 }
2076
2077 sub cmd_status () {
2078     badusage "no arguments allowed" if @ARGV;
2079
2080     # todo: gdr status should print divergence info
2081     # todo: gdr status should print upstream component(s) info
2082     # todo: gdr should leave/maintain some refs with this kind of info ?
2083
2084     my $oldest = { Badness => 0 };
2085     my $newest;
2086     my $note = sub {
2087         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2088         if ($oldest->{Badness} < $badness) {
2089             $oldest = $newest = undef;
2090         }
2091         $oldest = {
2092                    Badness => $badness,
2093                    CommitId => $cl->{CommitId},
2094                    OurMsg => $ourmsg,
2095                    KcMsg => $kcmsg,
2096                   };
2097         $newest //= $oldest;
2098     };
2099     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2100         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2101         sub { $note->(2, 'branch is unlaundered', @_); },
2102         sub { $note->(3, 'branch needs laundering', @_); },
2103         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2104
2105     my $prcommitinfo = sub {
2106         my ($cid) = @_;
2107         flush STDOUT or die $!;
2108         runcmd @git, qw(--no-pager log -n1),
2109             '--pretty=format:    %h %s%n',
2110             $cid;
2111     };
2112
2113     print "current branch contents, in git-debrebase terms:\n";
2114     if (!$oldest->{Badness}) {
2115         print "  branch is laundered\n";
2116     } else {
2117         print "  $oldest->{OurMsg}\n";
2118         my $printed = '';
2119         foreach my $info ($oldest, $newest) {
2120             my $cid = $info->{CommitId};
2121             next if $cid eq $printed;
2122             $printed = $cid;
2123             print "  $info->{KcMsg}\n";
2124             $prcommitinfo->($cid);
2125         }
2126     }
2127
2128     my $prab = sub {
2129         my ($cid, $what) = @_;
2130         if (!defined $cid) {
2131             print "  $what is not well-defined\n";
2132         } else {
2133             print "  $what\n";
2134             $prcommitinfo->($cid);
2135         }
2136     };
2137     print "key git-debrebase commits:\n";
2138     $prab->($anchor, 'anchor');
2139     $prab->($bw, 'breakwater');
2140
2141     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2142         ffq_prev_branchinfo();
2143
2144     print "branch and ref status, in git-debrebase terms:\n";
2145     if ($ffq_msg) {
2146         print "  $ffq_msg\n";
2147     } else {
2148         $ffq_prev = git_get_ref $ffq_prev;
2149         $gdrlast = git_get_ref $gdrlast;
2150         if ($ffq_prev) {
2151             print "  unstitched; previous tip was:\n";
2152             $prcommitinfo->($ffq_prev);
2153         } elsif (!$gdrlast) {
2154             print "  stitched? (no record of git-debrebase work)\n";
2155         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2156             print "  stitched\n";
2157         } else {
2158             print "  not git-debrebase (diverged since last stitch)\n"
2159         }
2160     }
2161     print "you are currently rebasing\n" if currently_rebasing();
2162 }
2163
2164 sub cmd_stitch () {
2165     my $prose = 'stitch';
2166     getoptions("stitch",
2167                'prose=s', \$prose);
2168     badusage "no arguments allowed" if @ARGV;
2169     do_stitch $prose, 0;
2170 }
2171 sub cmd_prepush () { cmd_stitch(); }
2172
2173 sub cmd_quick () {
2174     badusage "no arguments allowed" if @ARGV;
2175     do_launder_head 'launder for git-debrebase quick';
2176     do_stitch 'quick';
2177 }
2178
2179 sub cmd_conclude () {
2180     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2181     if (!$ffq_prev_commitish) {
2182         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2183         return;
2184     }
2185     my $dangling_head = get_head();
2186
2187     badusage "no arguments allowed" if @ARGV;
2188     do_launder_head 'launder for git-debrebase quick';
2189     do_stitch 'quick';
2190 }
2191
2192 sub cmd_scrap () {
2193     if (currently_rebasing()) {
2194         runcmd @git, qw(rebase --abort);
2195     }
2196     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2197     if (!$ffq_prev_commitish) {
2198         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2199         finish 0;
2200     }
2201     my $scrapping_head = get_head();
2202     badusage "no arguments allowed" if @ARGV;
2203     push @deferred_updates,
2204         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2205         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2206     snags_maybe_bail();
2207     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2208 }
2209
2210 sub make_patches_staged ($) {
2211     my ($head) = @_;
2212     # Produces the patches that would result from $head if it were
2213     # laundered.
2214     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2215     fresh_workarea();
2216     in_workarea sub {
2217         gbp_pq_export 'bw', $secret_bw, $secret_head;
2218     };
2219 }
2220
2221 sub make_patches ($) {
2222     my ($head) = @_;
2223     keycommits $head, 0, \&snag;
2224     make_patches_staged $head;
2225     my $out;
2226     in_workarea sub {
2227         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2228         runcmd @git, qw(read-tree), $head;
2229         read_tree_subdir 'debian/patches', $ptree;
2230         $out = make_commit [$head], [
2231             'Commit patch queue (exported by git-debrebase)',
2232             '[git-debrebase: export and commit patches]',
2233         ];
2234     };
2235     return $out;
2236 }
2237
2238 sub cmd_make_patches () {
2239     my $opt_quiet_would_amend;
2240     getoptions("make-patches",
2241                'quiet-would-amend!', \$opt_quiet_would_amend);
2242     badusage "no arguments allowed" if @ARGV;
2243     bail_if_rebasing();
2244     my $old_head = get_head();
2245     my $new = make_patches $old_head;
2246     my $d = get_differs $old_head, $new;
2247     if ($d == 0) {
2248         fail "No (more) patches to export." unless $opt_noop_ok;
2249         return;
2250     } elsif ($d == D_PAT_ADD) {
2251         snags_maybe_bail();
2252         update_head_checkout $old_head, $new, 'make-patches';
2253     } else {
2254         print STDERR failmsg
2255             "Patch export produced patch amendments".
2256             " (abandoned output commit $new).".
2257             "  Try laundering first."
2258             unless $opt_quiet_would_amend;
2259         finish 7;
2260     }
2261 }
2262
2263 sub cmd_convert_from_gbp () {
2264     badusage "want only 1 optional argument, the upstream git commitish"
2265         unless @ARGV<=1;
2266
2267     my $clogp = parsechangelog();
2268     my $version = $clogp->{'Version'}
2269         // die "missing Version from changelog";
2270
2271     my ($upstream_spec) = @ARGV;
2272
2273     my $upstream_version = upstreamversion $version;
2274     my $upstream =
2275         resolve_upstream_version($upstream_spec, $upstream_version);
2276
2277     my $old_head = get_head();
2278
2279     my $upsdiff = get_differs $upstream, $old_head;
2280     if ($upsdiff & D_UPS) {
2281         runcmd @git, qw(--no-pager diff --stat),
2282             $upstream, $old_head,
2283             qw( -- :!/debian :/);
2284         fail <<END;
2285 upstream ($upstream_spec) and HEAD are not
2286 identical in upstream files.  See diffstat above, or run
2287   git diff $upstream_spec HEAD -- :!/debian :/
2288 END
2289     }
2290
2291     if (!is_fast_fwd $upstream, $old_head) {
2292         snag 'upstream-not-ancestor',
2293             "upstream ($upstream) is not an ancestor of HEAD";
2294     } else {
2295         my $wrong = cmdoutput
2296             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2297              qw(-- :/ :!/debian));
2298         if (length $wrong) {
2299             snag 'unexpected-upstream-changes',
2300                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2301             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2302         }
2303     }
2304
2305     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2306         snag 'upstream-has-debian',
2307             "upstream ($upstream) contains debian/ directory";
2308     }
2309
2310     my $previous_dgit_view = eval {
2311         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2312         my ($lvsn, $suite);
2313         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2314             my ($stz, $desc) = @_;
2315             no warnings qw(exiting);
2316             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2317             next unless $stz->{Date};
2318             next unless $stz->{Distribution} ne 'UNRELEASED';
2319             $lvsn = $stz->{Version};
2320             $suite = $stz->{Distribution};
2321             last;
2322         };
2323         die "neither of the first two changelog entries are released\n"
2324             unless defined $lvsn;
2325         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2326         my $mtag_pat = debiantag_maintview $lvsn, '*';
2327         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2328             $mtag_pat;
2329         die "could not find suitable maintainer view tag $mtag_pat\n"
2330             unless $mtag_pat =~ m{/};
2331         is_fast_fwd $mtag, 'HEAD' or
2332             die "HEAD is not FF from maintainer tag $mtag!";
2333         my $dtag = "archive/$mtag";
2334         is_fast_fwd $mtag, $dtag or
2335             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2336         print "will stitch in dgit view, $dtag\n";
2337         git_rev_parse $dtag;
2338     };
2339     if (!$previous_dgit_view) {
2340         $@ =~ s/^\n+//;
2341         chomp $@;
2342         print STDERR "cannot stitch in dgit view: $@\n";
2343     }
2344
2345     snags_maybe_bail_early();
2346
2347     my $work;
2348
2349     fresh_workarea();
2350     in_workarea sub {
2351         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2352         # make a branch out of the patch queue - we'll want this in a mo
2353         runcmd qw(gbp pq import);
2354         # strip the patches out
2355         runcmd @git, qw(checkout -q gdr-internal~0);
2356         rm_subdir_cached 'debian/patches';
2357         $work = make_commit ['HEAD'], [
2358  'git-debrebase convert-from-gbp: drop patches from tree',
2359  'Delete debian/patches, as part of converting to git-debrebase format.',
2360  '[git-debrebase convert-from-gbp: drop patches from tree]'
2361                               ];
2362         # make the anchor merge
2363         # the tree is already exactly right
2364         $work = make_commit [$work, $upstream], [
2365  'git-debrebase import: declare upstream',
2366  'First breakwater merge.',
2367  '[git-debrebase anchor: declare upstream]'
2368                               ];
2369
2370         # rebase the patch queue onto the new breakwater
2371         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2372         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2373         $work = git_rev_parse 'HEAD';
2374
2375         if ($previous_dgit_view) {
2376             $work = make_commit [$work, $previous_dgit_view], [
2377  'git-debrebase import: declare ff from dgit archive view',
2378  '[git-debrebase pseudomerge: import-from-gbp]',
2379             ];
2380         }
2381     };
2382
2383     ffq_check $work;
2384     snags_maybe_bail();
2385     update_head_checkout $old_head, $work, 'convert-from-gbp';
2386 }
2387
2388 sub cmd_convert_to_gbp () {
2389     badusage "no arguments allowed" if @ARGV;
2390     my $head = get_head();
2391     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2392     keycommits $head, 0;
2393     my $out;
2394     make_patches_staged $head;
2395     in_workarea sub {
2396         $out = make_commit ['HEAD'], [
2397             'Commit patch queue (converted from git-debrebase format)',
2398             '[git-debrebase convert-to-gbp: commit patches]',
2399         ];
2400     };
2401     if (defined $ffq) {
2402         push @deferred_updates, "delete $ffq";
2403         push @deferred_updates, "delete $gdrlast";
2404     }
2405     snags_maybe_bail();
2406     update_head_checkout $head, $out, "convert to gbp (v0)";
2407     print <<END or die $!;
2408 git-debrebase: converted to git-buildpackage branch format
2409 git-debrebase: WARNING: do not now run "git-debrebase" any more
2410 git-debrebase: WARNING: doing so would drop all upstream patches!
2411 END
2412 }
2413
2414 sub cmd_convert_from_dgit_view () {
2415     my $clogp = parsechangelog();
2416
2417     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2418     my $do_origs = 1;
2419     my $do_tags = 1;
2420     my $always = 0;
2421     my $diagnose = 0;
2422
2423     getoptions("convert-from-dgit-view",
2424                'diagnose!', \$diagnose,
2425                'build-products-dir:s', \$bpd,
2426                'origs!', \$do_origs,
2427                'tags!', \$do_tags,
2428                'always-convert-anyway!', \$always);
2429     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2430
2431     my @upstreams;
2432
2433     if (@ARGV) {
2434         my $spec = shift @ARGV;
2435         my $commit = git_rev_parse "$spec^{commit}";
2436         push @upstreams, { Commit => $commit,
2437                            Source => "$ARGV[0], from command line",
2438                            Only => 1,
2439                          };
2440     }
2441
2442     my $head = get_head();
2443
2444     if (!$always) {
2445         my $troubles = 0;
2446         my $trouble = sub { $troubles++; };
2447         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2448         printdebug "troubles=$troubles\n";
2449         if (!$troubles) {
2450             print STDERR <<END;
2451 $us: Branch already seems to be in git-debrebase format!
2452 $us: --always-convert-anyway would do the conversion operation anyway
2453 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2454 END
2455             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2456             finish 0;
2457         }
2458     }
2459
2460     snags_maybe_bail_early();
2461
2462     my $version = upstreamversion $clogp->{Version};
2463     print STDERR "Considering possible commits corresponding to upstream:\n";
2464
2465     if (!@upstreams) {
2466         if ($do_tags) {
2467             my @tried;
2468             my $ups_tag = upstream_commitish_search $version, \@tried;
2469             if ($ups_tag) {
2470                 my $this = "git tag $tried[-1]";
2471                 push @upstreams, { Commit => $ups_tag,
2472                                    Source => $this,
2473                                  };
2474             } else {
2475                 printf STDERR
2476                     " git tag: no suitable tag found (tried %s)\n",
2477                     "@tried";
2478             }
2479         }
2480         if ($do_origs) {
2481             my $p = $clogp->{'Source'};
2482             # we do a quick check to see if there are plausible origs
2483             my $something=0;
2484             if (!opendir BPD, $bpd) {
2485                 die "$bpd: opendir: $!" unless $!==ENOENT;
2486             } else {
2487                 while ($!=0, my $f = readdir BPD) {
2488                     next unless is_orig_file_of_p_v $f, $p, $version;
2489                     printf STDERR
2490                         " orig: found what looks like a .orig, %s\n",
2491                         "$bpd/$f";
2492                     $something=1;
2493                     last;
2494                 }
2495                 die "read $bpd: $!" if $!;
2496                 closedir BPD;
2497             }
2498             if ($something) {
2499                 my $tree = cmdoutput
2500                     @dgit, qw(--build-products-dir), $bpd,
2501                     qw(print-unapplied-treeish);
2502                 fresh_workarea();
2503                 in_workarea sub {
2504                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2505                     rm_subdir_cached 'debian';
2506                     $tree = cmdoutput @git, qw(write-tree);
2507                     my $ups_synth = make_commit [], [ <<END, <<END,
2508 Import effective orig tree for upstream version $version
2509 END
2510 This includes the contents of the .orig(s), minus any debian/ directory.
2511
2512 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2513 END
2514                                                     ];
2515                     push @upstreams, { Commit => $ups_synth,
2516                                        Source => "orig(s) imported via dgit",
2517                                      };
2518                 }
2519             } else {
2520                 printf STDERR
2521                     " orig: no suitable origs found (looked for %s in %s)\n",
2522                     "${p}_".(stripeoch $version)."...", $bpd;
2523             }
2524         }
2525     }
2526
2527     my $some_patches = stat_exists 'debian/patches/series';
2528
2529     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2530
2531     my $result;
2532     foreach my $u (@upstreams) {
2533         my $work = $head;
2534         fresh_workarea();
2535         in_workarea sub {
2536             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2537             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2538             runcmd @git, qw(clean -xdff);
2539             runcmd @git, qw(checkout), $head, qw(-- debian);
2540             if ($some_patches) {
2541                 rm_subdir_cached 'debian/patches';
2542                 $work = make_commit [ $work ], [
2543  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2544  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2545  "to git-debrebase format.  Upstream changes will appear as commits.",
2546  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2547                                            ];
2548             }
2549             $work = make_commit [ $work, $u->{Commit} ], [
2550  'git-debrebase convert-from-dgit-view: declare upstream',
2551  '(Re)constructed breakwater merge.',
2552  '[git-debrebase anchor: declare upstream]'
2553                                                          ];
2554             runcmd @git, qw(checkout --quiet -b mk), $work;
2555             if ($some_patches) {
2556                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2557                 runcmd @git, qw(reset --quiet);
2558                 my @gbp_cmd = (qw(gbp pq import));
2559                 if (!$diagnose) {
2560                     my $gbp_err = "../gbp-pq-err";
2561                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2562                 }
2563                 my $r = system @gbp_cmd;
2564                 if ($r) {
2565                     printf STDERR
2566                         " %s: couldn't apply patches: gbp pq %s",
2567                         $u->{Source}, waitstatusmsg();
2568                     return;
2569                 }
2570             }
2571             my $work = git_rev_parse qw(HEAD);
2572             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2573             if (length $diffout) {
2574                 print STDERR
2575                     " $u->{Source}: applying patches gives different tree\n";
2576                 print STDERR $diffout if $diagnose;
2577                 return;
2578             }
2579             # OMG!
2580             $u->{Result} = $work;
2581             $result = $u;
2582         };
2583         last if $result;
2584     }
2585
2586     if (!$result) {
2587         fail <<END;
2588 Could not find or construct a suitable upstream commit.
2589 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2590 upstream commmit explicitly or provide suitable origs.
2591 END
2592     }
2593
2594     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2595
2596     ffq_check $result->{Result};
2597     snags_maybe_bail();
2598     update_head_checkout $head, $result->{Result},
2599         'convert-from-dgit-view';
2600 }
2601
2602 sub cmd_downstream_rebase_launder_v0 () {
2603     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2604     my ($base) = @ARGV;
2605     $base = git_rev_parse $base;
2606     my $old_head = get_head();
2607     my $current = $old_head;
2608     my $topmost_keep;
2609     for (;;) {
2610         if ($current eq $base) {
2611             $topmost_keep //= $current;
2612             print " $current BASE stop\n";
2613             last;
2614         }
2615         my $cl = classify $current;
2616         print " $current $cl->{Type}";
2617         my $keep = 0;
2618         my $p0 = $cl->{Parents}[0]{CommitId};
2619         my $next;
2620         if ($cl->{Type} eq 'Pseudomerge') {
2621             print " ^".($cl->{Contributor}{Ix}+1);
2622             $next = $cl->{Contributor}{CommitId};
2623         } elsif ($cl->{Type} eq 'AddPatches' or
2624                  $cl->{Type} eq 'Changelog') {
2625             print " strip";
2626             $next = $p0;
2627         } else {
2628             print " keep";
2629             $next = $p0;
2630             $keep = 1;
2631         }
2632         print "\n";
2633         if ($keep) {
2634             $topmost_keep //= $current;
2635         } else {
2636             die "to-be stripped changes not on top of the branch\n"
2637                 if $topmost_keep;
2638         }
2639         $current = $next;
2640     }
2641     if ($topmost_keep eq $old_head) {
2642         print "unchanged\n";
2643     } else {
2644         print "updating to $topmost_keep\n";
2645         update_head_checkout
2646             $old_head, $topmost_keep,
2647             'downstream-rebase-launder-v0';
2648     }
2649 }
2650
2651 getoptions_main
2652           ("bad options\n",
2653            "D+" => \$debuglevel,
2654            'noop-ok', => \$opt_noop_ok,
2655            'f=s' => \@snag_force_opts,
2656            'anchor=s' => \@opt_anchors,
2657            '--dgit=s' => \($dgit[0]),
2658            'force!',
2659            '-i:s' => sub {
2660                my ($opt,$val) = @_;
2661                badusage "git-debrebase: no cuddling to -i for git-rebase"
2662                    if length $val;
2663                die if $opt_defaultcmd_interactive; # should not happen
2664                $opt_defaultcmd_interactive = [ qw(-i) ];
2665                # This access to @ARGV is excessive familiarity with
2666                # Getopt::Long, but there isn't another sensible
2667                # approach.  '-i=s{0,}' does not work with bundling.
2668                push @$opt_defaultcmd_interactive, @ARGV;
2669                @ARGV=();
2670            },
2671            'help' => sub { print $usage_message or die $!; finish 0; },
2672            );
2673
2674 initdebug('git-debrebase ');
2675 enabledebug if $debuglevel;
2676
2677 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2678 chdir $toplevel or die "chdir $toplevel: $!";
2679
2680 $rd = fresh_playground "$playprefix/misc";
2681
2682 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2683
2684 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2685     defaultcmd_rebase();
2686 } else {
2687     my $cmd = shift @ARGV;
2688     my $cmdfn = $cmd;
2689     $cmdfn =~ y/-/_/;
2690     $cmdfn = ${*::}{"cmd_$cmdfn"};
2691
2692     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2693     $cmdfn->();
2694 }
2695
2696 finish 0;