git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 use strict;
  22
  23 use Debian::Dgit qw(:DEFAULT :playground);
  24 setup_sigwarn();
  25
  26 use Memoize;
  27 use Carp;
  28 use POSIX;
  29 use Data::Dumper;
  30 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  31 use Dpkg::Version;
  32 use File::FnMatch qw(:fnmatch);
  33
  34 our ($opt_force, $opt_noop_ok, @opt_anchors);
  35
  36 our $us = qw(git-debrebase);
  37
  38 sub badusage ($) {
  39     my ($m) = @_;
  40     die "bad usage: $m\n";
  41 }
  42
  43 sub cfg ($;$) {
  44     my ($k, $optional) = @_;
  45     local $/ = "\0";
  46     my @cmd = qw(git config -z);
  47     push @cmd, qw(--get-all) if wantarray;
  48     push @cmd, $k;
  49     my $out = cmdoutput_errok @cmd;
  50     if (!defined $out) {
  51         fail "missing required git config $k" unless $optional;
  52         return ();
  53     }
  54     my @l = split /\0/, $out;
  55     return wantarray ? @l : $l[0];
  56 }
  57
  58 memoize('cfg');
  59
  60 sub dd ($) {
  61     my ($v) = @_;
  62     my $dd = new Data::Dumper [ $v ];
  63     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  64     return Dump $dd;
  65 }
  66
  67 sub get_commit ($) {
  68     my ($objid) = @_;
  69     my $data = (git_cat_file $objid, 'commit');
  70     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
  71     return ($`,$');
  72 }
  73
  74 sub D_UPS ()      { 0x02; } # upstream files
  75 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
  76 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
  77 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
  78 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
  79 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
  80
  81 our $playprefix = 'debrebase';
  82 our $rd;
  83 our $workarea;
  84
  85 our @git = qw(git);
  86
  87 sub in_workarea ($) {
  88     my ($sub) = @_;
  89     changedir $workarea;
  90     my $r = eval { $sub->(); };
  91     { local $@; changedir $maindir; }
  92     die $@ if $@;
  93 }
  94
  95 sub fresh_workarea () {
  96     $workarea = fresh_playground "$playprefix/work";
  97     in_workarea sub { playtree_setup };
  98 }
  99
 100 our @deferred_updates;
 101 our @deferred_update_messages;
 102
 103 sub run_deferred_updates ($) {
 104     my ($mrest) = @_;
 105
 106     my @upd_cmd = (@git, qw(update-ref --stdin -m), "debrebase: $mrest");
 107     debugcmd '>|', @upd_cmd;
 108     open U, "|-", @upd_cmd or die $!;
 109     foreach (@deferred_updates) {
 110         printdebug ">= ", $_, "\n";
 111         print U $_, "\n" or die $!;
 112     }
 113     printdebug ">\$\n";
 114     close U or failedcmd @upd_cmd;
 115
 116     print $_, "\n" foreach @deferred_update_messages;
 117
 118     @deferred_updates = ();
 119     @deferred_update_messages = ();
 120 }
 121
 122 sub get_differs ($$) {
 123     my ($x,$y) = @_;
 124     # This resembles quiltify_trees_differ, in dgit, a bit.
 125     # But we don't care about modes, or dpkg-source-unrepresentable
 126     # changes, and we don't need the plethora of different modes.
 127     # Conversely we need to distinguish different kinds of changes to
 128     # debian/ and debian/patches/.
 129
 130     my $differs = 0;
 131
 132     my $rundiff = sub {
 133         my ($opts, $limits, $fn) = @_;
 134         my @cmd = (@git, qw(diff-tree -z --no-renames));
 135         push @cmd, @$opts;
 136         push @cmd, "$_:" foreach $x, $y;
 137         push @cmd, '--', @$limits;
 138         my $diffs = cmdoutput @cmd;
 139         foreach (split /\0/, $diffs) { $fn->(); }
 140     };
 141
 142     $rundiff->([qw(--name-only)], [], sub {
 143         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 144     });
 145
 146     if ($differs & DS_DEB) {
 147         $differs &= ~DS_DEB;
 148         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 149             $differs |=
 150                 m{^debian/patches/}      ? D_PAT_OTH  :
 151                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 152                                            D_DEB_OTH;
 153         });
 154         die "mysterious debian changes $x..$y"
 155             unless $differs & (D_PAT_OTH|DS_DEB);
 156     }
 157
 158     if ($differs & D_PAT_OTH) {
 159         my $mode;
 160         $differs &= ~D_PAT_OTH;
 161         my $pat_oth = sub {
 162             $differs |= D_PAT_OTH;
 163             no warnings qw(exiting);  last;
 164         };
 165         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 166             no warnings qw(exiting);
 167             if (!defined $mode) {
 168                 $mode = $_;  next;
 169             }
 170             die unless s{^debian/patches/}{};
 171             my $ok;
 172             if ($mode eq 'A' && !m/\.series$/s) {
 173                 $ok = 1;
 174             } elsif ($mode eq 'M' && $_ eq 'series') {
 175                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 176                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 177                 chomp $x_s;  $x_s .= "\n";
 178                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 179             } else {
 180                 # nope
 181             }
 182             $mode = undef;
 183             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 184         });
 185         die "mysterious debian/patches changes $x..$y"
 186             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 187     }
 188
 189     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 190
 191     return $differs;
 192 }
 193
 194 sub commit_pr_info ($) {
 195     my ($r) = @_;
 196     return Data::Dumper->dump([$r], [qw(commit)]);
 197 }
 198
 199 sub calculate_committer_authline () {
 200     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 201         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 202     my ($h,$m) = get_commit $c;
 203     $h =~ m/^committer .*$/m or confess "($h) ?";
 204     return $&;
 205 }
 206
 207 sub rm_subdir_cached ($) {
 208     my ($subdir) = @_;
 209     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 210 }
 211
 212 sub read_tree_subdir ($$) {
 213     my ($subdir, $new_tree_object) = @_;
 214     rm_subdir_cached $subdir;
 215     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 216 }
 217
 218 sub make_commit ($$) {
 219     my ($parents, $message_paras) = @_;
 220     my $tree = cmdoutput @git, qw(write-tree);
 221     my @cmd = (@git, qw(commit-tree), $tree);
 222     push @cmd, qw(-p), $_ foreach @$parents;
 223     push @cmd, qw(-m), $_ foreach @$message_paras;
 224     return cmdoutput @cmd;
 225 }
 226
 227 our @fproblem_force_opts;
 228 our $fproblems_forced;
 229 our $fproblems_tripped;
 230 sub fproblem ($$) {
 231     my ($tag,$msg) = @_;
 232     if (grep { $_ eq $tag } @fproblem_force_opts) {
 233         $fproblems_forced++;
 234         print STDERR "git-debrebase: safety catch overridden (-f$tag): $msg\n";
 235     } else {
 236         $fproblems_tripped++;
 237         print STDERR "git-debrebase: safety catch tripped (-f$tag): $msg\n";
 238     }
 239 }
 240
 241 sub fproblems_maybe_bail () {
 242     if ($fproblems_forced) {
 243         printf STDERR
 244             "%s: safety catch trips: %d overriden by individual -f options\n",
 245             $us, $fproblems_forced;
 246     }
 247     if ($fproblems_tripped) {
 248         if ($opt_force) {
 249             printf STDERR
 250                 "%s: safety catch trips: %d overriden by global --force\n",
 251                 $us, $fproblems_tripped;
 252         } else {
 253             fail sprintf
 254   "%s: safety catch trips: %d blockers (you could -f<tag>, or --force)",
 255                 $us, $fproblems_tripped;
 256         }
 257     }
 258 }
 259 sub any_fproblems () {
 260     return $fproblems_forced || $fproblems_tripped;
 261 }
 262
 263 # classify returns an info hash like this
 264 #   CommitId => $objid
 265 #   Hdr => # commit headers, including 1 final newline
 266 #   Msg => # commit message (so one newline is dropped)
 267 #   Tree => $treeobjid
 268 #   Type => (see below)
 269 #   Parents = [ {
 270 #       Ix => $index # ie 0, 1, 2, ...
 271 #       CommitId
 272 #       Differs => return value from get_differs
 273 #       IsOrigin
 274 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 275 #     } ...]
 276 #   NewMsg => # commit message, but with any [dgit import ...] edited
 277 #             # to say "[was: ...]"
 278 #
 279 # Types:
 280 #   Packaging
 281 #   Changelog
 282 #   Upstream
 283 #   AddPatches
 284 #   Mixed
 285 #
 286 #   Pseudomerge
 287 #     has additional entres in classification result
 288 #       Overwritten = [ subset of Parents ]
 289 #       Contributor = $the_remaining_Parent
 290 #
 291 #   DgitImportUnpatched
 292 #     has additional entry in classification result
 293 #       OrigParents = [ subset of Parents ]
 294 #
 295 #   Anchor
 296 #     has additional entry in classification result
 297 #       OrigParents = [ subset of Parents ]  # singleton list
 298 #
 299 #   TreatAsAnchor
 300 #
 301 #   BreakwaterStart
 302 #
 303 #   Unknown
 304 #     has additional entry in classification result
 305 #       Why => "prose"
 306
 307 sub parsecommit ($;$) {
 308     my ($objid, $p_ref) = @_;
 309     # => hash with                   CommitId Hdr Msg Tree Parents
 310     #    Parents entries have only   Ix CommitId
 311     #    $p_ref, if provided, must be [] and is used as a base for Parents
 312
 313     $p_ref //= [];
 314     die if @$p_ref;
 315
 316     my ($h,$m) = get_commit $objid;
 317
 318     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 319     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 320
 321     my $r = {
 322         CommitId => $objid,
 323         Hdr => $h,
 324         Msg => $m,
 325         Tree => $t,
 326         Parents => $p_ref,
 327     };
 328
 329     foreach my $ph (@ph) {
 330         push @$p_ref, {
 331             Ix => scalar @$p_ref,
 332             CommitId => $ph,
 333         };
 334     }
 335
 336     return $r;
 337 }
 338
 339 sub classify ($) {
 340     my ($objid) = @_;
 341
 342     my @p;
 343     my $r = parsecommit($objid, \@p);
 344     my $t = $r->{Tree};
 345
 346     foreach my $p (@p) {
 347         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 348     }
 349
 350     printdebug "classify $objid \$t=$t \@p",
 351         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 352         "\n";
 353
 354     my $classify = sub {
 355         my ($type, @rest) = @_;
 356         $r = { %$r, Type => $type, @rest };
 357         if ($debuglevel) {
 358             printdebug " = $type ".(dd $r)."\n";
 359         }
 360         return $r;
 361     };
 362     my $unknown = sub {
 363         my ($why) = @_;
 364         $r = { %$r, Type => qw(Unknown), Why => $why };
 365         printdebug " ** Unknown\n";
 366         return $r;
 367     };
 368
 369     if (grep { $_ eq $objid } @opt_anchors) {
 370         return $classify->('TreatAsAnchor');
 371     }
 372
 373     my @identical = grep { !$_->{Differs} } @p;
 374     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 375     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 376
 377     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 378         # multi-orig upstreams are represented with an anchor merge
 379         # from a single upstream commit which combines the orig tarballs
 380
 381         # Every anchor tagged this way must be a merge.
 382         # We are relying on the
 383         #     [git-debrebase anchor: ...]
 384         # commit message annotation in "declare" anchor merges (which
 385         # do not have any upstream changes), to distinguish those
 386         # anchor merges from ordinary pseudomerges (which we might
 387         # just try to strip).
 388         #
 389         # However, the user is going to be doing git-rebase a lot.  We
 390         # really don't want them to rewrite an anchor commit.
 391         # git-rebase trips up on merges, so that is a useful safety
 392         # catch.
 393         #
 394         # BreakwaterStart commits are also anchors in the terminology
 395         # of git-debrebase(5), but they are untagged (and always
 396         # manually generated).
 397
 398         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 399         @p == 2 or return $badanchor->("has other than two parents");
 400         $haspatches and return $badanchor->("contains debian/patches");
 401
 402         # How to decide about l/r ordering of anchors ?  git
 403         # --topo-order prefers to expand 2nd parent first.  There's
 404         # already an easy rune to look for debian/ history anyway (git log
 405         # debian/) so debian breakwater branch should be 1st parent; that
 406         # way also there's also an easy rune to look for the upstream
 407         # patches (--topo-order).
 408
 409         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 410         $p[1]{Differs} & ~DS_DEB and
 411             $badanchor->("upstream files differ from left parent");
 412         $p[0]{Differs} & ~D_UPS and
 413             $badanchor->("debian/ differs from right parent");
 414
 415         return $classify->(qw(Anchor),
 416                            OrigParents => [ $p[1] ]);
 417     }
 418
 419     if (@p == 1) {
 420         my $d = $r->{Parents}[0]{Differs};
 421         if ($d == D_PAT_ADD) {
 422             return $classify->(qw(AddPatches));
 423         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 424             return $unknown->("edits debian/patches");
 425         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 426             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 427             if ($ty eq 'tree') {
 428                 if ($d == D_DEB_CLOG) {
 429                     return $classify->(qw(Changelog));
 430                 } else {
 431                     return $classify->(qw(Packaging));
 432                 }
 433             } elsif ($ty eq 'missing') {
 434                 return $classify->(qw(BreakwaterStart));
 435             } else {
 436                 return $unknown->("parent's debian is not a directory");
 437             }
 438         } elsif ($d == D_UPS) {
 439             return $classify->(qw(Upstream));
 440         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 441             return $classify->(qw(Mixed));
 442         } elsif ($d == 0) {
 443             return $unknown->("no changes");
 444         } else {
 445             confess "internal error $objid ?";
 446         }
 447     }
 448     if (!@p) {
 449         return $unknown->("origin commit");
 450     }
 451
 452     if (@p == 2 && @identical == 1) {
 453         my @overwritten = grep { $_->{Differs} } @p;
 454         confess "internal error $objid ?" unless @overwritten==1;
 455         return $classify->(qw(Pseudomerge),
 456                            Overwritten => [ $overwritten[0] ],
 457                            Contributor => $identical[0]);
 458     }
 459     if (@p == 2 && @identical == 2) {
 460         my $get_t = sub {
 461             my ($ph,$pm) = get_commit $_[0]{CommitId};
 462             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 463             $1;
 464         };
 465         my @bytime = @p;
 466         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 467         if ($order > 0) { # newer first
 468         } elsif ($order < 0) {
 469             @bytime = reverse @bytime;
 470         } else {
 471             # same age, default to order made by -s ours
 472             # that is, commit was made by someone who preferred L
 473         }
 474         return $classify->(qw(Pseudomerge),
 475                            SubType => qw(Ambiguous),
 476                            Contributor => $bytime[0],
 477                            Overwritten => [ $bytime[1] ]);
 478     }
 479     foreach my $p (@p) {
 480         my ($p_h, $p_m) = get_commit $p->{CommitId};
 481         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 482         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 483     }
 484     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 485     my $m2 = $r->{Msg};
 486     if (!(grep { !$_->{IsOrigin} } @p) and
 487         (@orig_ps >= @p - 1) and
 488         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 489         $r->{NewMsg} = $m2;
 490         return $classify->(qw(DgitImportUnpatched),
 491                            OrigParents => \@orig_ps);
 492     }
 493
 494     return $unknown->("complex merge");
 495 }
 496
 497 sub breakwater_of ($;$) {
 498     my ($head, $unclean_fproblem_tag) = @_;
 499     # $head should be laundered; if not, $unclean_fproblem_tag controls:
 500     # if falseish, calls fail; otherwise, calls fproblem and returns undef
 501     my $breakwater;
 502     my $unclean = sub {
 503         my ($why) = @_;
 504         my $m = "branch needs laundering (run git-debrebase): $why";
 505         fail $m unless $unclean_fproblem_tag;
 506         fproblem $unclean_fproblem_tag, $m;
 507         $breakwater = undef;
 508         no warnings qw(exiting);
 509         last;
 510     };
 511     for (;;) {
 512         my $cl = classify $head;
 513         my $ty = $cl->{Type};
 514         if ($ty eq 'Packaging' or
 515             $ty eq 'Changelog') {
 516             $breakwater //= $head;
 517         } elsif ($ty eq 'Anchor' or
 518                  $ty eq 'TreatAsAnchor' or
 519                  $ty eq 'BreakwaterStart') {
 520             $breakwater //= $head;
 521             last;
 522         } elsif ($ty eq 'Upstream') {
 523             $unclean->("packaging change ($breakwater)".
 524                        " follows upstream change (eg $head)")
 525                 if defined $breakwater;
 526         } elsif ($ty eq 'Mixed') {
 527             $unclean->('found mixed upstream/packaging commit ($head)');
 528         } elsif ($ty eq 'Pseudomerge' or
 529                  $ty eq 'AddPatches') {
 530             $unclean->("found interchange conversion commit ($ty, $head)");
 531         } elsif ($ty eq 'DgitImportUnpatched') {
 532             $unclean->("found dgit dsc import ($head)");
 533         } else {
 534             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 535         }
 536         $head = $cl->{Parents}[0]{CommitId};
 537     }
 538     return $breakwater;
 539 }
 540
 541 sub walk ($;$$);
 542 sub walk ($;$$) {
 543     my ($input,
 544         $nogenerate,$report) = @_;
 545     # => ($tip, $breakwater_tip, $last_anchor)
 546     # (or nothing, if $nogenerate)
 547
 548     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 549
 550     # go through commits backwards
 551     # we generate two lists of commits to apply:
 552     # breakwater branch and upstream patches
 553     my (@brw_cl, @upp_cl, @processed);
 554     my %found;
 555     my $upp_limit;
 556     my @pseudomerges;
 557
 558     my $cl;
 559     my $xmsg = sub {
 560         my ($prose, $info) = @_;
 561         my $ms = $cl->{Msg};
 562         chomp $ms;
 563         $info //= '';
 564         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 565         return (Msg => $ms);
 566     };
 567     my $rewrite_from_here = sub {
 568         my ($cl) = @_;
 569         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 570         push @$cl, $sp_cl;
 571         push @processed, $sp_cl;
 572     };
 573     my $cur = $input;
 574
 575     my $prdelim = "";
 576     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 577
 578     my $prline = sub {
 579         return unless $report;
 580         print $report $prdelim, @_;
 581         $prdelim = "\n";
 582     };
 583
 584     my $bomb = sub { # usage: return $bomb->();
 585         print $report " Unprocessable" if $report;
 586         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 587         $prprdelim->();
 588         if ($nogenerate) {
 589             return (undef,undef);
 590         }
 591         die "commit $cur: Cannot cope with this commit (d.".
 592             (join ' ', map { sprintf "%#x", $_->{Differs} }
 593              @{ $cl->{Parents} }).
 594             (defined $cl->{Why} ? "; $cl->{Why}": '').
 595                  ")";
 596     };
 597
 598     my $build;
 599     my $breakwater;
 600
 601     my $build_start = sub {
 602         my ($msg, $parent) = @_;
 603         $prline->(" $msg");
 604         $build = $parent;
 605         no warnings qw(exiting); last;
 606     };
 607
 608     my $last_anchor;
 609
 610     for (;;) {
 611         $cl = classify $cur;
 612         my $ty = $cl->{Type};
 613         my $st = $cl->{SubType};
 614         $prline->("$cl->{CommitId} $cl->{Type}");
 615         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 616         push @processed, $cl;
 617         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 618         if ($ty eq 'AddPatches') {
 619             $cur = $p0;
 620             $rewrite_from_here->(\@upp_cl);
 621             next;
 622         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 623             push @brw_cl, $cl;
 624             $cur = $p0;
 625             next;
 626         } elsif ($ty eq 'BreakwaterStart') {
 627             $last_anchor = $cur;
 628             $build_start->('FirstPackaging', $cur);
 629         } elsif ($ty eq 'Upstream') {
 630             push @upp_cl, $cl;
 631             $cur = $p0;
 632             next;
 633         } elsif ($ty eq 'Mixed') {
 634             my $queue = sub {
 635                 my ($q, $wh) = @_;
 636                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 637                 push @$q, $cls;
 638             };
 639             $queue->(\@brw_cl, "debian");
 640             $queue->(\@upp_cl, "upstream");
 641             $rewrite_from_here->(\@brw_cl);
 642             $cur = $p0;
 643             next;
 644         } elsif ($ty eq 'Pseudomerge') {
 645             my $contrib = $cl->{Contributor}{CommitId};
 646             print $report " Contributor=$contrib" if $report;
 647             push @pseudomerges, $cl;
 648             $rewrite_from_here->(\@upp_cl);
 649             $cur = $contrib;
 650             next;
 651         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 652             $last_anchor = $cur;
 653             $build_start->("Anchor", $cur);
 654         } elsif ($ty eq 'DgitImportUnpatched') {
 655             my $pm = $pseudomerges[-1];
 656             if (defined $pm) {
 657                 # To an extent, this is heuristic.  Imports don't have
 658                 # a useful history of the debian/ branch.  We assume
 659                 # that the first pseudomerge after an import has a
 660                 # useful history of debian/, and ignore the histories
 661                 # from later pseudomerges.  Often the first pseudomerge
 662                 # will be the dgit import of the upload to the actual
 663                 # suite intended by the non-dgit NMUer, and later
 664                 # pseudomerges may represent in-archive copies.
 665                 my $ovwrs = $pm->{Overwritten};
 666                 printf $report " PM=%s \@Overwr:%d",
 667                     $pm->{CommitId}, (scalar @$ovwrs)
 668                     if $report;
 669                 if (@$ovwrs != 1) {
 670                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 671                     return $bomb->();
 672                 }
 673                 my $ovwr = $ovwrs->[0]{CommitId};
 674                 printf $report " Overwr=%s", $ovwr if $report;
 675                 # This import has a tree which is just like a
 676                 # breakwater tree, but it has the wrong history.  It
 677                 # ought to have the previous breakwater (which the
 678                 # pseudomerge overwrote) as an ancestor.  That will
 679                 # make the history of the debian/ files correct.  As
 680                 # for the upstream version: either it's the same as
 681                 # was ovewritten (ie, same as the previous
 682                 # breakwater), in which case that history is precisely
 683                 # right; or, otherwise, it was a non-gitish upload of a
 684                 # new upstream version.  We can tell these apart by
 685                 # looking at the tree of the supposed upstream.
 686                 push @brw_cl, {
 687                     %$cl,
 688                     SpecialMethod => 'DgitImportDebianUpdate',
 689                     $xmsg->("convert dgit import: debian changes")
 690                 }, {
 691                     %$cl,
 692                     SpecialMethod => 'DgitImportUpstreamUpdate',
 693                     $xmsg->("convert dgit import: upstream update",
 694                             " anchor")
 695                 };
 696                 $prline->(" Import");
 697                 $rewrite_from_here->(\@brw_cl);
 698                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 699                 $cur = $ovwr;
 700                 next;
 701             } else {
 702                 # Everything is from this import.  This kind of import
 703                 # is already in valid breakwater format, with the
 704                 # patches as commits.
 705                 printf $report " NoPM" if $report;
 706                 # last thing we processed will have been the first patch,
 707                 # if there is one; which is fine, so no need to rewrite
 708                 # on account of this import
 709                 $build_start->("ImportOrigin", $cur);
 710             }
 711             die "$ty ?";
 712         } else {
 713             printdebug "*** WALK BOMB unrecognised\n";
 714             return $bomb->();
 715         }
 716     }
 717     $prprdelim->();
 718
 719     printdebug "*** WALK prep done cur=$cur".
 720         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 721
 722     return if $nogenerate;
 723
 724     # Now we build it back up again
 725
 726     fresh_workarea();
 727
 728     my $rewriting = 0;
 729
 730     my $read_tree_debian = sub {
 731         my ($treeish) = @_;
 732         read_tree_subdir 'debian', "$treeish:debian";
 733         rm_subdir_cached 'debian/patches';
 734     };
 735     my $read_tree_upstream = sub {
 736         my ($treeish) = @_;
 737         runcmd @git, qw(read-tree), $treeish;
 738         $read_tree_debian->($build);
 739     };
 740
 741     $#upp_cl = $upp_limit if defined $upp_limit;
 742
 743     my $committer_authline = calculate_committer_authline();
 744
 745     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 746
 747     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 748
 749     in_workarea sub {
 750         mkdir $rd or $!==EEXIST or die $!;
 751         my $current_method;
 752         runcmd @git, qw(read-tree), $build;
 753         foreach my $cl (qw(Debian), (reverse @brw_cl),
 754                         { SpecialMethod => 'RecordBreakwaterTip' },
 755                         qw(Upstream), (reverse @upp_cl)) {
 756             if (!ref $cl) {
 757                 $current_method = $cl;
 758                 next;
 759             }
 760             my $method = $cl->{SpecialMethod} // $current_method;
 761             my @parents = ($build);
 762             my $cltree = $cl->{CommitId};
 763             printdebug "WALK BUILD ".($cltree//'undef').
 764                 " $method (rewriting=$rewriting)\n";
 765             if ($method eq 'Debian') {
 766                 $read_tree_debian->($cltree);
 767             } elsif ($method eq 'Upstream') {
 768                 $read_tree_upstream->($cltree);
 769             } elsif ($method eq 'StartRewrite') {
 770                 $rewriting = 1;
 771                 next;
 772             } elsif ($method eq 'RecordBreakwaterTip') {
 773                 $breakwater = $build;
 774                 next;
 775             } elsif ($method eq 'DgitImportDebianUpdate') {
 776                 $read_tree_debian->($cltree);
 777             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 778                 confess unless $rewriting;
 779                 my $differs = (get_differs $build, $cltree);
 780                 next unless $differs & D_UPS;
 781                 $read_tree_upstream->($cltree);
 782                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 783             } else {
 784                 confess "$method ?";
 785             }
 786             if (!$rewriting) {
 787                 my $procd = (pop @processed) // 'UNDEF';
 788                 if ($cl ne $procd) {
 789                     $rewriting = 1;
 790                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 791                 }
 792             }
 793             my $newtree = cmdoutput @git, qw(write-tree);
 794             my $ch = $cl->{Hdr};
 795             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 796             $ch =~ s{^parent .*\n}{}mg;
 797             $ch =~ s{(?=^author)}{
 798                 join '', map { "parent $_\n" } @parents
 799             }me or confess "$ch ?";
 800             if ($rewriting) {
 801                 $ch =~ s{^committer .*$}{$committer_authline}m
 802                     or confess "$ch ?";
 803             }
 804             my $cf = "$rd/m$rewriting";
 805             open CD, ">", $cf or die $!;
 806             print CD $ch, "\n", $cl->{Msg} or die $!;
 807             close CD or die $!;
 808             my @cmd = (@git, qw(hash-object));
 809             push @cmd, qw(-w) if $rewriting;
 810             push @cmd, qw(-t commit), $cf;
 811             my $newcommit = cmdoutput @cmd;
 812             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 813             $build = $newcommit;
 814             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 815                 $last_anchor = $cur;
 816             }
 817         }
 818     };
 819
 820     my $final_check = get_differs $build, $input;
 821     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 822         if $final_check & ~D_PAT_ADD;
 823
 824     my @r = ($build, $breakwater, $last_anchor);
 825     printdebug "*** WALK RETURN @r\n";
 826     return @r
 827 }
 828
 829 sub get_head () {
 830     git_check_unmodified();
 831     return git_rev_parse qw(HEAD);
 832 }
 833
 834 sub update_head ($$$) {
 835     my ($old, $new, $mrest) = @_;
 836     push @deferred_updates, "update HEAD $new $old";
 837     run_deferred_updates $mrest;
 838 }
 839
 840 sub update_head_checkout ($$$) {
 841     my ($old, $new, $mrest) = @_;
 842     update_head $old, $new, $mrest;
 843     runcmd @git, qw(reset --hard);
 844 }
 845
 846 sub update_head_postlaunder ($$$) {
 847     my ($old, $tip, $reflogmsg) = @_;
 848     return if $tip eq $old;
 849     print "git-debrebase: laundered (head was $old)\n";
 850     update_head $old, $tip, $reflogmsg;
 851     # no tree changes except debian/patches
 852     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 853 }
 854
 855 sub cmd_launder_v0 () {
 856     badusage "no arguments to launder-v0 allowed" if @ARGV;
 857     my $old = get_head();
 858     my ($tip,$breakwater,$last_anchor) = walk $old;
 859     update_head_postlaunder $old, $tip, 'launder';
 860     printf "# breakwater tip\n%s\n", $breakwater;
 861     printf "# working tip\n%s\n", $tip;
 862     printf "# last anchor\n%s\n", $last_anchor;
 863 }
 864
 865 sub defaultcmd_rebase () {
 866     my $old = get_head();
 867     record_ffq_auto();
 868     my ($tip,$breakwater) = walk $old;
 869     update_head_postlaunder $old, $tip, 'launder for rebase';
 870     runcmd @git, qw(rebase), @ARGV, $breakwater;
 871 }
 872
 873 sub cmd_analyse () {
 874     die if ($ARGV[0]//'') =~ m/^-/;
 875     badusage "too many arguments to analyse" if @ARGV>1;
 876     my ($old) = @ARGV;
 877     if (defined $old) {
 878         $old = git_rev_parse $old;
 879     } else {
 880         $old = git_rev_parse 'HEAD';
 881     }
 882     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 883     STDOUT->error and die $!;
 884 }
 885
 886 sub ffq_prev_branchinfo () {
 887     # => ('status', "message", [$current, $ffq_prev, $drlast])
 888     # 'status' may be
 889     #    branch         message is undef
 890     #    weird-symref   } no $current,
 891     #    notbranch      }  no $ffq_prev
 892     my $current = git_get_symref();
 893     return ('detached', 'detached HEAD') unless defined $current;
 894     return ('weird-symref', 'HEAD symref is not to refs/')
 895         unless $current =~ m{^refs/};
 896     my $ffq_prev = "refs/$ffq_refprefix/$'";
 897     my $drlast = "refs/$gdrlast_refprefix/$'";
 898     printdebug "ffq_prev_branchinfo branch current $current\n";
 899     return ('branch', undef, $current, $ffq_prev, $drlast);
 900 }
 901
 902 sub record_ffq_prev_deferred () {
 903     # => ('status', "message")
 904     # 'status' may be
 905     #    deferred          message is undef
 906     #    exists
 907     #    detached
 908     #    weird-symref
 909     #    notbranch
 910     # if not ff from some branch we should be ff from, is an fproblem
 911     # if "deferred", will have added something about that to
 912     #   @deferred_update_messages, and also maybe printed (already)
 913     #   some messages about ff checks
 914     my ($status, $message, $current, $ffq_prev, $drlast)
 915         = ffq_prev_branchinfo();
 916     return ($status, $message) unless $status eq 'branch';
 917
 918     my $currentval = get_head();
 919
 920     my $exists = git_get_ref $ffq_prev;
 921     return ('exists',"$ffq_prev already exists") if $exists;
 922
 923     return ('not-branch', 'HEAD symref is not to refs/heads/')
 924         unless $current =~ m{^refs/heads/};
 925     my $branch = $';
 926
 927     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
 928     my %checked;
 929
 930     printdebug "ffq check_specs @check_specs\n";
 931
 932     my $check = sub {
 933         my ($lrref, $desc) = @_;
 934         printdebug "ffq might check $lrref ($desc)\n";
 935         my $invert;
 936         for my $chk (@check_specs) {
 937             my $glob = $chk;
 938             $invert = $glob =~ s{^[!^]}{};
 939             last if fnmatch $glob, $lrref;
 940         }
 941         return if $invert;
 942         my $lrval = git_get_ref $lrref;
 943         return unless defined $lrval;
 944
 945         if (is_fast_fwd $lrval, $currentval) {
 946             print "OK, you are ahead of $lrref\n" or die $!;
 947             $checked{$lrref} = 1;
 948         } elsif (is_fast_fwd $currentval, $lrval) {
 949             $checked{$lrref} = -1;
 950             fproblem 'behind', "you are behind $lrref, divergence risk";
 951         } else {
 952             $checked{$lrref} = -1;
 953             fproblem 'diverged', "you have diverged from $lrref";
 954         }
 955     };
 956
 957     my $merge = cfg "branch.$branch.merge",1;
 958     if (defined $merge and $merge =~ m{^refs/heads/}) {
 959         my $rhs = $';
 960         printdebug "ffq merge $rhs\n";
 961         my $check_remote = sub {
 962             my ($remote, $desc) = @_;
 963             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
 964             return unless defined $remote;
 965             $check->("refs/remotes/$remote/$rhs", $desc);
 966         };
 967         $check_remote->((scalar cfg "branch.$branch.remote",1),
 968                         'remote fetch/merge branch');
 969         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
 970                         (scalar cfg "branch.$branch.pushDefault",1),
 971                         'remote push branch');
 972     }
 973     if ($branch =~ m{^dgit/}) {
 974         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
 975     } elsif ($branch =~ m{^master$}) {
 976         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
 977     }
 978
 979     fproblems_maybe_bail();
 980
 981     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
 982     push @deferred_updates, "delete $drlast";
 983     push @deferred_update_messages, "Recorded current head for preservation";
 984     return ('deferred', undef);
 985 }
 986
 987 sub record_ffq_auto () {
 988     my ($status, $message) = record_ffq_prev_deferred();
 989     if ($status eq 'deferred' || $status eq 'exists') {
 990     } else {
 991         fproblem $status, "could not record ffq-prev: $message";
 992         fproblems_maybe_bail();
 993     }
 994 }
 995
 996 sub cmd_new_upstream_v0 () {
 997     # automatically and unconditionally launders before rebasing
 998     # if rebase --abort is used, laundering has still been done
 999
1000     my %pieces;
1001
1002     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1003
1004     # parse args - low commitment
1005     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1006     my $new_upstream_version = $new_version->version();
1007
1008     my $new_upstream = git_rev_parse (shift @ARGV // 'upstream');
1009
1010     record_ffq_auto();
1011
1012     my $piece = sub {
1013         my ($n, @x) = @_; # may be ''
1014         my $pc = $pieces{$n} //= {
1015             Name => $n,
1016             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1017         };
1018         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1019         $pc;
1020     };
1021
1022     my @newpieces;
1023     my $newpiece = sub {
1024         my ($n, @x) = @_; # may be ''
1025         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1026         push @newpieces, $pc;
1027     };
1028
1029     $newpiece->('',
1030         OldIx => 0,
1031         New => $new_upstream,
1032     );
1033     while (@ARGV && $ARGV[0] !~ m{^-}) {
1034         my $n = shift @ARGV;
1035
1036         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1037             unless @ARGV && $ARGV[0] !~ m{^-};
1038
1039         my $c = git_rev_parse shift @ARGV;
1040         die unless $n =~ m/^$extra_orig_namepart_re$/;
1041         $newpiece->($n, New => $c);
1042     }
1043
1044     # now we need to investigate the branch this generates the
1045     # laundered version but we don't switch to it yet
1046     my $old_head = get_head();
1047     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1048
1049     my $old_bw_cl = classify $old_bw;
1050     my $old_anchor_cl = classify $old_anchor;
1051     my $old_upstream;
1052     if (!$old_anchor_cl->{OrigParents}) {
1053         fproblem 'anchor-treated',
1054             'old anchor is recognised due to --anchor, cannot check upstream';
1055     } else {
1056         $old_upstream = parsecommit
1057             $old_anchor_cl->{OrigParents}[0]{CommitId};
1058         $piece->('', Old => $old_upstream->{CommitId});
1059     }
1060
1061     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1062         if ($old_upstream->{Msg} =~
1063  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
1064            ) {
1065             my @oldpieces = ('', split / /, $1);
1066             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
1067             foreach my $i (0..$#oldpieces) {
1068                 my $n = $oldpieces[$i];
1069                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1070             }
1071         } else {
1072             fproblem 'upstream-confusing',
1073                 "previous upstream $old_upstream->{CommitId} is from".
1074                " git-debrebase but not an \`upstream-combine' commit";
1075         }
1076     }
1077
1078     foreach my $pc (values %pieces) {
1079         if (!$old_upstream) {
1080             # we have complained already
1081         } elsif (!$pc->{Old}) {
1082             fproblem 'upstream-new-piece',
1083                 "introducing upstream piece \`$pc->{Name}'";
1084         } elsif (!$pc->{New}) {
1085             fproblem 'upstream-rm-piece',
1086                 "dropping upstream piece \`$pc->{Name}'";
1087         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1088             fproblem 'upstream-not-ff',
1089                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1090         }
1091     }
1092
1093     printdebug "%pieces = ", (dd \%pieces), "\n";
1094     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1095
1096     fproblems_maybe_bail();
1097
1098     my $new_bw;
1099
1100     fresh_workarea();
1101     in_workarea sub {
1102         my @upstream_merge_parents;
1103
1104         if (!any_fproblems()) {
1105             push @upstream_merge_parents, $old_upstream->{CommitId};
1106         }
1107
1108         foreach my $pc (@newpieces) { # always has '' first
1109             if ($pc->{Name}) {
1110                 read_tree_subdir $pc->{Name}, $pc->{New};
1111             } else {
1112                 runcmd @git, qw(read-tree), $pc->{New};
1113             }
1114             push @upstream_merge_parents, $pc->{New};
1115         }
1116
1117         # index now contains the new upstream
1118
1119         if (@newpieces > 1) {
1120             # need to make the upstream subtree merge commit
1121             $new_upstream = make_commit \@upstream_merge_parents,
1122                 [ "Combine upstreams for $new_upstream_version",
1123  ("[git-debrebase upstream-combine . ".
1124  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1125  ": new upstream]"),
1126                 ];
1127         }
1128
1129         # $new_upstream is either the single upstream commit, or the
1130         # combined commit we just made.  Either way it will be the
1131         # "upstream" parent of the anchor merge.
1132
1133         read_tree_subdir 'debian', "$old_bw:debian";
1134
1135         # index now contains the anchor merge contents
1136         $new_bw = make_commit [ $old_bw, $new_upstream ],
1137             [ "Update to upstream $new_upstream_version",
1138  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1139             ];
1140
1141         # Now we have to add a changelog stanza so the Debian version
1142         # is right.
1143         die if unlink "debian";
1144         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1145         unlink "debian/changelog" or $!==ENOENT or die $!;
1146         mkdir "debian" or die $!;
1147         open CN, ">", "debian/changelog" or die $!;
1148         my $oldclog = git_cat_file ":debian/changelog";
1149         $oldclog =~ m/^($package_re) \(\S+\) / or
1150             fail "cannot parse old changelog to get package name";
1151         my $p = $1;
1152         print CN <<END, $oldclog or die $!;
1153 $p ($new_version) UNRELEASED; urgency=medium
1154
1155   * Update to new upstream version $new_upstream_version.
1156
1157  --
1158
1159 END
1160         close CN or die $!;
1161         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1162
1163         # Now we have the final new breakwater branch in the index
1164         $new_bw = make_commit [ $new_bw ],
1165             [ "Update changelog for new upstream $new_upstream_version",
1166               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1167             ];
1168     };
1169
1170     # we have constructed the new breakwater. we now need to commit to
1171     # the laundering output, because git-rebase can't easily be made
1172     # to make a replay list which is based on some other branch
1173
1174     update_head_postlaunder $old_head, $old_laundered_tip,
1175         'launder for new upstream';
1176
1177     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1178     runcmd @cmd;
1179     # now it's for the user to sort out
1180 }
1181
1182 sub cmd_record_ffq_prev () {
1183     badusage "no arguments allowed" if @ARGV;
1184     my ($status, $msg) = record_ffq_prev_deferred();
1185     if ($status eq 'exists' && $opt_noop_ok) {
1186         print "Previous head already recorded\n" or die $!;
1187     } elsif ($status eq 'deferred') {
1188         run_deferred_updates 'record-ffq-prev';
1189     } else {
1190         fail "Could not preserve: $msg";
1191     }
1192 }
1193
1194 sub cmd_breakwater () {
1195     badusage "no arguments allowed" if @ARGV;
1196     my $bw = breakwater_of git_rev_parse 'HEAD';
1197     print "$bw\n" or die $!;
1198 }
1199
1200 sub cmd_stitch () {
1201     my $prose = '';
1202     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1203     badusage "no arguments allowed" if @ARGV;
1204     my ($status, $message, $current, $ffq_prev, $drlast)
1205         = ffq_prev_branchinfo();
1206     if ($status ne 'branch') {
1207         fproblem $status, "could not check ffq-prev: $message";
1208         fproblems_maybe_bail();
1209     }
1210     my $prev = $ffq_prev && git_get_ref $ffq_prev;
1211     if (!$prev) {
1212         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1213         return;
1214     }
1215     my $old_head = get_head();
1216
1217     breakwater_of $old_head, 'unclean-stitch';
1218
1219     push @deferred_updates, "delete $ffq_prev $prev";
1220
1221     if (is_fast_fwd $old_head, $prev) {
1222         my $differs = get_differs $old_head, $prev;
1223         unless ($differs & ~D_PAT_ADD) {
1224             # ffq-prev is ahead of us, and the only tree changes it has
1225             # are possibly addition of things in debian/patches/.
1226             # Just wind forwards rather than making a pointless pseudomerge.
1227             push @deferred_updates, "update $drlast $prev $git_null_obj";
1228             update_head_checkout $old_head, $prev, "stitch (fast forward)";
1229             return;
1230         }
1231     }
1232     fresh_workarea();
1233     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1234         'Declare fast forward / record previous work',
1235         "[git-debrebase pseudomerge: stitch$prose]",
1236     ];
1237     push @deferred_updates, "update $drlast $new_head $git_null_obj";
1238     update_head $old_head, $new_head, "stitch";
1239 }
1240
1241 sub cmd_convert_from_gbp () {
1242     badusage "needs 1 optional argument, the upstream git rev"
1243         unless @ARGV<=1;
1244     my ($upstream_spec) = @ARGV;
1245     $upstream_spec //= 'refs/heads/upstream';
1246     my $upstream = git_rev_parse $upstream_spec;
1247     my $old_head = get_head();
1248
1249     my $upsdiff = get_differs $upstream, $old_head;
1250     if ($upsdiff & D_UPS) {
1251         runcmd @git, qw(--no-pager diff),
1252             $upstream, $old_head,
1253             qw( -- :!/debian :/);
1254  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1255     }
1256
1257     if (!is_fast_fwd $upstream, $old_head) {
1258         fproblem 'upstream-not-ancestor',
1259             "upstream ($upstream) is not an ancestor of HEAD";
1260     } else {
1261         my $wrong = cmdoutput
1262             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1263              qw(-- :/ :!/debian));
1264         if (length $wrong) {
1265             fproblem 'unexpected-upstream-changes',
1266                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1267             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1268         }
1269     }
1270
1271     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1272         fproblem 'upstream-has-debian',
1273             "upstream ($upstream) contains debian/ directory";
1274     }
1275
1276     fproblems_maybe_bail();
1277
1278     my $work;
1279
1280     fresh_workarea();
1281     in_workarea sub {
1282         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1283         # make a branch out of the patch queue - we'll want this in a mo
1284         runcmd qw(gbp pq import);
1285         # strip the patches out
1286         runcmd @git, qw(checkout -q gdr-internal~0);
1287         rm_subdir_cached 'debian/patches';
1288         $work = make_commit ['HEAD'], [
1289  'git-debrebase convert-from-gbp: drop patches from tree',
1290  'Delete debian/patches, as part of converting to git-debrebase format.',
1291  '[git-debrebase convert-from-gbp: drop patches from tree]'
1292                               ];
1293         # make the anchor merge
1294         # the tree is already exactly right
1295         $work = make_commit [$work, $upstream], [
1296  'git-debrebase import: declare upstream',
1297  'First breakwater merge.',
1298  '[git-debrebase anchor: declare upstream]'
1299                               ];
1300
1301         # rebase the patch queue onto the new breakwater
1302         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1303         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1304         $work = git_rev_parse 'HEAD';
1305     };
1306
1307     update_head_checkout $old_head, $work, 'convert-from-gbp';
1308 }
1309
1310 sub cmd_convert_to_gbp () {
1311     badusage "no arguments allowed" if @ARGV;
1312     my $head = get_head();
1313     my (undef, undef, undef, $ffq, $drlast) = ffq_prev_branchinfo();
1314     my $bw = breakwater_of $head;
1315     fresh_workarea();
1316     my $out;
1317     in_workarea sub {
1318         runcmd @git, qw(checkout -q -b bw), $bw;
1319         runcmd @git, qw(checkout -q -b patch-queue/bw), $head;
1320         runcmd qw(gbp pq export);
1321         runcmd @git, qw(add debian/patches);
1322         $out = make_commit ['HEAD'], [
1323             'Commit patch queue (converted from git-debrebase format)',
1324             '[git-debrebase convert-to-gbp: commit patches]',
1325         ];
1326     };
1327     if (defined $ffq) {
1328         push @deferred_updates, "delete $ffq";
1329         push @deferred_updates, "delete $drlast";
1330     }
1331     update_head_checkout $head, $out, "convert to gbp (v0)";
1332     print <<END or die $!;
1333 git-debrebase: converted to git-buildpackage branch format
1334 git-debrebase: WARNING: do not now run "git-debrebase" any more
1335 git-debrebase: WARNING: doing so would drop all upstream patches!
1336 END
1337 }
1338
1339 sub cmd_downstream_rebase_launder_v0 () {
1340     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1341     my ($base) = @ARGV;
1342     $base = git_rev_parse $base;
1343     my $old_head = get_head();
1344     my $current = $old_head;
1345     my $topmost_keep;
1346     for (;;) {
1347         if ($current eq $base) {
1348             $topmost_keep //= $current;
1349             print " $current BASE stop\n";
1350             last;
1351         }
1352         my $cl = classify $current;
1353         print " $current $cl->{Type}";
1354         my $keep = 0;
1355         my $p0 = $cl->{Parents}[0]{CommitId};
1356         my $next;
1357         if ($cl->{Type} eq 'Pseudomerge') {
1358             print " ^".($cl->{Contributor}{Ix}+1);
1359             $next = $cl->{Contributor}{CommitId};
1360         } elsif ($cl->{Type} eq 'AddPatches' or
1361                  $cl->{Type} eq 'Changelog') {
1362             print " strip";
1363             $next = $p0;
1364         } else {
1365             print " keep";
1366             $next = $p0;
1367             $keep = 1;
1368         }
1369         print "\n";
1370         if ($keep) {
1371             $topmost_keep //= $current;
1372         } else {
1373             die "to-be stripped changes not on top of the branch\n"
1374                 if $topmost_keep;
1375         }
1376         $current = $next;
1377     }
1378     if ($topmost_keep eq $old_head) {
1379         print "unchanged\n";
1380     } else {
1381         print "updating to $topmost_keep\n";
1382         update_head_checkout
1383             $old_head, $topmost_keep,
1384             'downstream-rebase-launder-v0';
1385     }
1386 }
1387
1388 GetOptions("D+" => \$debuglevel,
1389            'noop-ok', => \$opt_noop_ok,
1390            'f=s' => \@fproblem_force_opts,
1391            'anchor=s' => \@opt_anchors,
1392            'force!') or die badusage "bad options\n";
1393 initdebug('git-debrebase ');
1394 enabledebug if $debuglevel;
1395
1396 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1397 chdir $toplevel or die "chdir $toplevel: $!";
1398
1399 $rd = fresh_playground "$playprefix/misc";
1400
1401 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1402
1403 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1404     defaultcmd_rebase();
1405 } else {
1406     my $cmd = shift @ARGV;
1407     my $cmdfn = $cmd;
1408     $cmdfn =~ y/-/_/;
1409     $cmdfn = ${*::}{"cmd_$cmdfn"};
1410
1411     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1412     $cmdfn->();
1413 }