git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT :playground);
 114
 115 sub badusage ($) {
 116     my ($m) = @_;
 117     die "bad usage: $m\n";
 118 }
 119
 120 sub cfg ($) {
 121     my ($k) = @_;
 122     $/ = "\0";
 123     my @cmd = qw(git config -z);
 124     push @cmd, qw(--get-all) if wantarray;
 125     push @cmd, $k;
 126     my $out = cmdoutput @cmd;
 127     return split /\0/, $out;
 128 }
 129
 130 memoize('cfg');
 131
 132 sub get_commit ($) {
 133     my ($objid) = @_;
 134     my $data = git_cat_file $objid, 'commit';
 135     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 136     return ($`,$');
 137 }
 138
 139 sub D_UPS ()      { 0x02; } # upstream files
 140 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 141 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 142 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 143 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 144 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 145
 146 our $playprefix = 'debrebase';
 147 our $rd;
 148 our $workarea;
 149
 150 our @git = qw(git);
 151
 152 sub in_workarea ($) {
 153     my ($sub) = @_;
 154     changedir $workarea;
 155     my $r = eval { $sub->(); };
 156     changedir $maindir;
 157 }
 158
 159 sub fresh_workarea () {
 160     $workarea = fresh_playground "$playprefix/work";
 161     in_workarea sub { playtree_setup };
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 218                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 # classify returns an info hash like this
 250 #   CommitId => $objid
 251 #   Hdr => # commit headers, including 1 final newline
 252 #   Msg => # commit message (so one newline is dropped)
 253 #   Tree => $treeobjid
 254 #   Type => (see below)
 255 #   Parents = [ {
 256 #       Ix => $index # ie 0, 1, 2, ...
 257 #       CommitId
 258 #       Differs => return value from get_differs
 259 #       IsOrigin
 260 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 261 #     } ...]
 262 #   NewMsg => # commit message, but with any [dgit import ...] edited
 263 #             # to say "[was: ...]"
 264 #
 265 # Types:
 266 #   Packaging
 267 #   Upstream
 268 #   AddPatches
 269 #   Mixed
 270 #   Unknown
 271 #
 272 #   Pseudomerge
 273 #     has additional entres in classification result
 274 #       Overwritten = [ subset of Parents ]
 275 #       Contributor = $the_remaining_Parent
 276 #
 277 #   DgitImportUnpatched
 278 #     has additional entry in classification result
 279 #       OrigParents = [ subset of Parents ]
 280 #
 281 #   BreakwaterUpstreamMerge
 282 #     has additional entry in classification result
 283 #       OrigParents = [ subset of Parents ]
 284
 285 sub classify ($) {
 286     my ($objid) = @_;
 287
 288     my ($h,$m) = get_commit $objid;
 289
 290     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 291     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 292     my @p;
 293
 294     my $r = {
 295         CommitId => $objid,
 296         Hdr => $h,
 297         Msg => $m,
 298         Tree => $t,
 299         Parents => \@p,
 300     };
 301
 302     foreach my $ph (@ph) {
 303         push @p, {
 304             Ix => $#p,
 305             CommitId => $ph,
 306             Differs => (get_differs $t, $ph),
 307         };
 308     }
 309
 310     printdebug "classify $objid \$t=$t \@p",
 311         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 312         "\n";
 313
 314     my $classify = sub {
 315         my ($type, @rest) = @_;
 316         $r = { %$r, Type => $type, @rest };
 317         if ($debuglevel) {
 318             my $dd = new Data::Dumper [ $r ];
 319             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 320             printdebug " = $type ".(Dump $dd)."\n";
 321         }
 322         return $r;
 323     };
 324     my $unknown = sub {
 325         my ($why) = @_;
 326         $r = { %$r, Type => qw(Unknown) };
 327         printdebug " ** Unknown\n";
 328         return $r;
 329     };
 330
 331     if (@p == 1) {
 332         my $d = $r->{Parents}[0]{Differs};
 333         if ($d == D_PAT_ADD) {
 334             return $classify->(qw(AddPatches));
 335         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 336             return $unknown->("edits debian/patches");
 337         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 338             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 339             if ($ty eq 'tree') {
 340                 return $classify->(qw(Packaging));
 341             } elsif ($ty eq 'missing') {
 342                 return $classify->(qw(BreakwaterStart));
 343             } else {
 344                 return $unknown->("parent's debian is not a directory");
 345             }
 346         } elsif ($d == D_UPS) {
 347             return $classify->(qw(Upstream));
 348         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 349             return $classify->(qw(Mixed));
 350         } elsif ($d == 0) {
 351             return $unknown->("no changes");
 352         } else {
 353             confess "internal error $objid ?";
 354         }
 355     }
 356     if (!@p) {
 357         return $unknown->("origin commit");
 358     }
 359
 360     my @identical = grep { !$_->{Differs} } @p;
 361     if (@p == 2 && @identical == 1) {
 362         my @overwritten = grep { $_->{Differs} } @p;
 363         confess "internal error $objid ?" unless @overwritten==1;
 364         return $classify->(qw(Pseudomerge),
 365                            Overwritten => $overwritten[0],
 366                            Contributor => $identical[0]);
 367     }
 368     if (@p == 2 && @identical == 2) {
 369         my @bytime = nsort_by {
 370             my ($ph,$pm) = get_commit $_->{CommitId};
 371             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 372             $1;
 373         } @p;
 374         return $classify->(qw(Pseudomerge),
 375                            SubType => qw(Ambiguous),
 376                            Overwritten => $bytime[0],
 377                            Contributor => $bytime[1]);
 378     }
 379     foreach my $p (@p) {
 380         my ($p_h, $p_m) = get_commit $p->{CommitId};
 381         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 382         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 383     }
 384     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 385     my $m2 = $m;
 386     if (!(grep { !$_->{IsOrigin} } @p) and
 387         (@orig_ps >= @p - 1) and
 388         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 389         $r->{NewMsg} = $m2;
 390         return $classify->(qw(DgitImportUnpatched),
 391                            OrigParents => \@orig_ps);
 392     }
 393
 394     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 395     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 396
 397     # How to decide about l/r ordering of breakwater merges ?  git
 398     # --topo-order prefers to expand 2nd parent first.  There's
 399     # already an easy rune to look for debian/ history anyway (git log
 400     # debian/) so debian breakwater branch should be 1st parent; that
 401     # way also there's also an easy rune to look for the upstream
 402     # patches (--topo-order).
 403
 404     # The above tells us which way *we* will generate them.  But we
 405     # might encounter ad-hoc breakwater merges generated manually,
 406     # which might be the other way around.  In principle, in some odd
 407     # situations, a breakwater merge might have two identical parents.
 408     # In that case we guess which way round it is (ie, which parent
 409     # has the upstream history).  The order of the 2-iteration loop
 410     # controls which guess we make.
 411
 412     foreach my $prevbrw (qw(0 1)) {
 413         if (@p == 2 &&
 414             !$haspatches &&
 415             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 416             !($p[$prevbrw]{Differs} & ~DS_DEB) &&
 417             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 418             return $classify->(qw(BreakwaterUpstreamMerge),
 419                                OrigParents => [ $p[!$prevbrw] ]);
 420         }
 421         # xxx multi-.orig upstreams
 422     }
 423
 424     return $unknown->("complex merge");
 425 }
 426
 427 sub walk ($;$$);
 428 sub walk ($;$$) {
 429     my ($input,
 430         $nogenerate,$report) = @_;
 431     # => ($tip, $breakwater_tip)
 432     # (or nothing, if $nogenerate)
 433
 434     # go through commits backwards
 435     # we generate two lists of commits to apply:
 436     # breakwater branch and upstream patches
 437     my (@brw_cl, @upp_cl, @processed);
 438     my %found;
 439     my $upp_limit;
 440     my @pseudomerges;
 441
 442     my $cl;
 443     my $xmsg = sub {
 444         my ($appendinfo) = @_;
 445         my $ms = $cl->{Msg};
 446         chomp $ms;
 447         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 448         return (Msg => $ms);
 449     };
 450     my $rewrite_from_here = sub {
 451         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 452         push @brw_cl, $sp_cl;
 453         push @processed, $sp_cl;
 454     };
 455     my $cur = $input;
 456
 457     my $prdelim = "";
 458     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 459
 460     my $prline = sub {
 461         return unless $report;
 462         print $report $prdelim, @_;
 463         $prdelim = "\n";
 464     };
 465
 466     my $bomb = sub { # usage: return $bomb->();
 467         print $report " Unprocessable" if $report;
 468         $prprdelim->();
 469         if ($nogenerate) {
 470             return (undef,undef);
 471         }
 472         die "commit $cur: Cannot cope with this commit";
 473     };
 474
 475     my $build;
 476     my $breakwater;
 477
 478     my $build_start = sub {
 479         my ($msg, $parent) = @_;
 480         $prline->(" $msg");
 481         $build = $parent;
 482         no warnings qw(exiting); last;
 483     };
 484
 485     for (;;) {
 486         $cl = classify $cur;
 487         my $ty = $cl->{Type};
 488         my $st = $cl->{SubType};
 489         $prline->("$cl->{CommitId} $cl->{Type}");
 490         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 491         push @processed, $cl;
 492         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 493         if ($ty eq 'AddPatches') {
 494             $cur = $p0;
 495             $rewrite_from_here->();
 496             next;
 497         } elsif ($ty eq 'Packaging') {
 498             push @brw_cl, $cl;
 499             $cur = $p0;
 500             next;
 501         } elsif ($ty eq 'BreakwaterStart') {
 502             $build_start->('FirstPackaging', $cur);
 503         } elsif ($ty eq 'Upstream') {
 504             push @upp_cl, $cl;
 505             $cur = $p0;
 506             next;
 507         } elsif ($ty eq 'Mixed') {
 508             my $queue = sub {
 509                 my ($q, $wh) = @_;
 510                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 511                 push @$q, $cls;
 512             };
 513             $queue->(\@brw_cl, "debian");
 514             $queue->(\@upp_cl, "upstream");
 515             $rewrite_from_here->();
 516             $cur = $p0;
 517             next;
 518         } elsif ($ty eq 'Pseudomerge') {
 519             my $contrib = $cl->{Contributor}{CommitId};
 520             print $report " Contributor=$contrib" if $report;
 521             push @pseudomerges, $cl;
 522             $rewrite_from_here->();
 523             $cur = $contrib;
 524             next;
 525         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 526             $build_start->("PreviousBreakwater", $cur);
 527         } elsif ($ty eq 'DgitImportUnpatched') {
 528             my $pm = $pseudomerges[-1];
 529             if (defined $pm) {
 530                 # To an extent, this is heuristic.  Imports don't have
 531                 # a useful history of the debian/ branch.  We assume
 532                 # that the first pseudomerge after an import has a
 533                 # useful history of debian/, and ignore the histories
 534                 # from later pseudomerges.  Often the first pseudomerge
 535                 # will be the dgit import of the upload to the actual
 536                 # suite intended by the non-dgit NMUer, and later
 537                 # pseudomerges may represent in-archive copies.
 538                 my $ovwrs = $pm->{Overwritten};
 539                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 540                     if $report;
 541                 if (@$ovwrs != 1) {
 542                     return $bomb->();
 543                 }
 544                 my $ovwr = $ovwrs->[0]{CommitId};
 545                 printf $report " Overwr=%s", $ovwr if $report;
 546                 # This import has a tree which is just like a
 547                 # breakwater tree, but it has the wrong history.  It
 548                 # ought to have the previous breakwater (which the
 549                 # pseudomerge overwrote) as an ancestor.  That will
 550                 # make the history of the debian/ files correct.  As
 551                 # for the upstream version: either it's the same as
 552                 # was ovewritten (ie, same as the previous
 553                 # breakwater), in which case that history is precisely
 554                 # right; or, otherwise, it was a non-gitish upload of a
 555                 # new upstream version.  We can tell these apart by
 556                 # looking at the tree of the supposed upstream.
 557                 push @brw_cl, {
 558                     %$cl,
 559                     SpecialMethod => 'DgitImportDebianUpdate',
 560                     $xmsg->("convert dgit import: debian changes")
 561                 };
 562                 my $differs = (get_differs $ovwr, $cl->{Tree});
 563                 printf $report " Differs=%#x", $differs if $report;
 564                 if ($differs & D_UPS) {
 565                     printf $report " D_UPS" if $report;
 566                     # This will also trigger if a non-dgit git-based NMU
 567                     # deleted .gitignore (which is a thing that some of
 568                     # the existing git tools do if the user doesn't
 569                     # somehow tell them not to).  Ah well.
 570                     push @brw_cl, {
 571                         %$cl,
 572                         SpecialMethod => 'DgitImportUpstreamUpdate',
 573                         $xmsg->("convert dgit import: upstream changes")
 574                     };
 575                 }
 576                 $prline->(" Import");
 577                 $rewrite_from_here->();
 578                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 579                 $cur = $ovwr;
 580                 next;
 581             } else {
 582                 # Everything is from this import.  This kind of import
 583                 # is already in valid breakwater format, with the
 584                 # patches as commits.
 585                 printf $report " NoPM" if $report;
 586                 # last thing we processed will have been the first patch,
 587                 # if there is one; which is fine, so no need to rewrite
 588                 # on account of this import
 589                 $build_start->("ImportOrigin", $cur);
 590             }
 591             die "$ty ?";
 592         } else {
 593             return $bomb->();
 594         }
 595     }
 596     $prprdelim->();
 597     return if $nogenerate;
 598
 599     # Now we build it back up again
 600
 601     fresh_workarea();
 602
 603     my $rewriting = 0;
 604
 605     my $rm_tree_cached = sub {
 606         my ($subdir) = @_;
 607         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 608     };
 609     my $read_tree_debian = sub {
 610         my ($treeish) = @_;
 611         $rm_tree_cached->(qw(debian));
 612         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 613     };
 614     my $read_tree_upstream = sub {
 615         my ($treeish) = @_;
 616         runcmd @git, qw(read-tree), $treeish;
 617         $read_tree_debian->($build);
 618     };
 619
 620     my $committer_authline = calculate_committer_authline();
 621
 622     in_workarea sub {
 623         mkdir $rd or $!==EEXIST or die $!;
 624         my $current_method;
 625         foreach my $cl (qw(Debian), (reverse @brw_cl),
 626                         { SpecialMethod => 'RecordBreakwaterTip' },
 627                         qw(Upstream), (reverse @upp_cl)) {
 628             if (!ref $cl) {
 629                 $current_method = $cl;
 630                 next;
 631             }
 632             my $method = $cl->{SpecialMethod} // $current_method;
 633             my @parents = ($build);
 634             my $cltree = $cl->{CommitId};
 635             if ($method eq 'Debian') {
 636                 $read_tree_debian->($cltree);
 637             } elsif ($method eq 'Upstream') {
 638                 $read_tree_upstream->($cltree);
 639             } elsif ($method eq 'StartRewrite') {
 640                 $rewriting = 1;
 641                 next;
 642             } elsif ($method eq 'RecordBreakwaterTip') {
 643                 $breakwater = $build;
 644                 next;
 645             } elsif ($method eq 'DgitImportDebianUpdate') {
 646                 $read_tree_debian->($cltree);
 647                 $rm_tree_cached->(qw(debian/patches));
 648             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 649                 $read_tree_upstream->($cltree);
 650                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 651             } else {
 652                 confess "$method ?";
 653             }
 654             $rewriting ||= $cl ne pop @processed;
 655             my $newtree = cmdoutput @git, qw(write-tree);
 656             my $ch = $cl->{Hdr};
 657             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 658             $ch =~ s{^parent .*\n}{}m;
 659             $ch =~ s{(?=^author)}{
 660                 map { "parent $_\n" } @parents
 661             }me or confess "$ch ?";
 662             if ($rewriting) {
 663                 $ch =~ s{^committer .*$}{$committer_authline}m
 664                     or confess "$ch ?";
 665             }
 666             my $cf = "$rd/m$rewriting";
 667             open CD, ">", $cf or die $!;
 668             print CD $ch, "\n", $cl->{Msg} or die $!;
 669             close CD or die $!;
 670             my @cmd = (@git, qw(hash-object));
 671             push @cmd, qw(-w) if $rewriting;
 672             push @cmd, qw(-t commit), $cf;
 673             my $newcommit = cmdoutput @cmd;
 674             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 675             $build = $newcommit;
 676         }
 677     };
 678
 679     runcmd @git, qw(diff-tree --quiet), $input, $build;
 680
 681     return ($build, $breakwater);
 682 }
 683
 684 sub get_head () { return git_rev_parse qw(HEAD); }
 685
 686 sub update_head ($$$) {
 687     my ($old, $new, $mrest) = @_;
 688     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 689 }
 690
 691 sub cmd_launder () {
 692     badusage "no arguments to launder allowed" if @ARGV;
 693     my $old = get_head();
 694     my ($tip,$breakwater) = walk $old;
 695     update_head $old, $tip, 'launder';
 696     # no tree changes except debian/patches
 697     runcmd @git, qw(rm --quiet -rf debian/patches);
 698     printf "# breakwater tip\n%s\n", $breakwater;
 699 }
 700
 701 sub cmd_analyse () {
 702     die if ($ARGV[0]//'') =~ m/^-/;
 703     badusage "too many arguments to analyse" if @ARGV>1;
 704     my ($old) = @ARGV;
 705     if (defined $old) {
 706         $old = git_rev_parse $old;
 707     } else {
 708         $old = get_head();
 709     }
 710     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 711     STDOUT->error and die $!;
 712 }
 713
 714 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 715 initdebug('git-debrebase ');
 716 enabledebug if $debuglevel;
 717
 718 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 719 chdir $toplevel or die "chdir $toplevel: $!";
 720
 721 $rd = fresh_playground "$playprefix/misc";
 722
 723 my $cmd = shift @ARGV;
 724 my $cmdfn = $cmd;
 725 $cmdfn =~ y/-/_/;
 726 $cmdfn = ${*::}{"cmd_$cmdfn"};
 727
 728 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 729 $cmdfn->();