git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea (;$) {
 132     my ($subdir) = @_;
 133     $subdir //= 'work';
 134     $workarea = fresh_playground "$playprefix/$subdir";
 135     in_workarea sub { playtree_setup };
 136 }
 137
 138 sub run_ref_updates_now ($$) {
 139     my ($mrest, $updates) = @_;
 140     # @$updates is a list of lines for git-update-ref, without \ns
 141
 142     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 143     debugcmd '>|', @upd_cmd;
 144     open U, "|-", @upd_cmd or die $!;
 145     foreach (@$updates) {
 146         printdebug ">= ", $_, "\n";
 147         print U $_, "\n" or die $!;
 148     }
 149     printdebug ">\$\n";
 150     close U or failedcmd @upd_cmd;
 151 }
 152
 153 our $snags_forced = 0;
 154 our $snags_tripped = 0;
 155 our $snags_summarised = 0;
 156 our @deferred_updates;
 157 our @deferred_update_messages;
 158
 159 sub merge_wreckage_cleaning ($) {
 160     my ($updates) = @_;
 161     git_for_each_ref("$wrecknoteprefix/*", sub {
 162         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 163         push @$updates, "delete $fullrefname";
 164     });
 165 }
 166
 167 sub all_snags_summarised () {
 168     $snags_forced + $snags_tripped == $snags_summarised;
 169 }
 170 sub run_deferred_updates ($) {
 171     my ($mrest) = @_;
 172
 173     confess 'dangerous internal error' unless all_snags_summarised();
 174
 175     merge_wreckage_cleaning \@deferred_updates;
 176     run_ref_updates_now $mrest, \@deferred_updates;
 177     print $_, "\n" foreach @deferred_update_messages;
 178
 179     @deferred_updates = ();
 180     @deferred_update_messages = ();
 181 }
 182
 183 sub get_differs ($$) {
 184     my ($x,$y) = @_;
 185     # This resembles quiltify_trees_differ, in dgit, a bit.
 186     # But we don't care about modes, or dpkg-source-unrepresentable
 187     # changes, and we don't need the plethora of different modes.
 188     # Conversely we need to distinguish different kinds of changes to
 189     # debian/ and debian/patches/.
 190
 191     my $differs = 0;
 192
 193     my $rundiff = sub {
 194         my ($opts, $limits, $fn) = @_;
 195         my @cmd = (@git, qw(diff-tree -z --no-renames));
 196         push @cmd, @$opts;
 197         push @cmd, "$_:" foreach $x, $y;
 198         push @cmd, '--', @$limits;
 199         my $diffs = cmdoutput @cmd;
 200         foreach (split /\0/, $diffs) { $fn->(); }
 201     };
 202
 203     $rundiff->([qw(--name-only)], [], sub {
 204         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 205     });
 206
 207     if ($differs & DS_DEB) {
 208         $differs &= ~DS_DEB;
 209         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 210             $differs |=
 211                 m{^debian/patches/}      ? D_PAT_OTH  :
 212                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 213                                            D_DEB_OTH;
 214         });
 215         die "mysterious debian changes $x..$y"
 216             unless $differs & (D_PAT_OTH|DS_DEB);
 217     }
 218
 219     if ($differs & D_PAT_OTH) {
 220         my $mode;
 221         $differs &= ~D_PAT_OTH;
 222         my $pat_oth = sub {
 223             $differs |= D_PAT_OTH;
 224             no warnings qw(exiting);  last;
 225         };
 226         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 227             no warnings qw(exiting);
 228             if (!defined $mode) {
 229                 $mode = $_;  next;
 230             }
 231             die unless s{^debian/patches/}{};
 232             my $ok;
 233             if ($mode eq 'A' && !m/\.series$/s) {
 234                 $ok = 1;
 235             } elsif ($mode eq 'M' && $_ eq 'series') {
 236                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 237                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 238                 chomp $x_s;  $x_s .= "\n";
 239                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 240             } else {
 241                 # nope
 242             }
 243             $mode = undef;
 244             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 245         });
 246         die "mysterious debian/patches changes $x..$y"
 247             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 248     }
 249
 250     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 251
 252     return $differs;
 253 }
 254
 255 sub commit_pr_info ($) {
 256     my ($r) = @_;
 257     return Data::Dumper->dump([$r], [qw(commit)]);
 258 }
 259
 260 sub calculate_committer_authline () {
 261     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 262         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 263     my ($h,$m) = get_commit $c;
 264     $h =~ m/^committer .*$/m or confess "($h) ?";
 265     return $&;
 266 }
 267
 268 sub rm_subdir_cached ($) {
 269     my ($subdir) = @_;
 270     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 271 }
 272
 273 sub read_tree_subdir ($$) {
 274     my ($subdir, $new_tree_object) = @_;
 275     rm_subdir_cached $subdir;
 276     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 277 }
 278
 279 sub read_tree_debian ($) {
 280     my ($treeish) = @_;
 281     read_tree_subdir 'debian', "$treeish:debian";
 282     rm_subdir_cached 'debian/patches';
 283 }
 284
 285 sub read_tree_upstream ($;$$) {
 286     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 287     # if $tree_with_debian is supplied, will use that for debian/
 288     # otherwise will save and restore it.
 289     my $debian =
 290         $tree_with_debian ? "$tree_with_debian:debian"
 291         : cmdoutput @git, qw(write-tree --prefix=debian/);
 292     runcmd @git, qw(read-tree), $treeish;
 293     read_tree_subdir 'debian', $debian;
 294     rm_subdir_cached 'debian/patches' unless $keep_patches;
 295 };
 296
 297 sub make_commit ($$) {
 298     my ($parents, $message_paras) = @_;
 299     my $tree = cmdoutput @git, qw(write-tree);
 300     my @cmd = (@git, qw(commit-tree), $tree);
 301     push @cmd, qw(-p), $_ foreach @$parents;
 302     push @cmd, qw(-m), $_ foreach @$message_paras;
 303     return cmdoutput @cmd;
 304 }
 305
 306 our @snag_force_opts;
 307 sub snag ($$;@) {
 308     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 309     if (grep { $_ eq $tag } @snag_force_opts) {
 310         $snags_forced++;
 311         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 312     } else {
 313         $snags_tripped++;
 314         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 315     }
 316 }
 317
 318 # Important: all mainline code must call snags_maybe_bail after
 319 # any point where snag might be called, but before making changes
 320 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 321 # may be called more than once if necessary (but this is not ideal
 322 # because then the messages about number of snags may be confusing).
 323 sub snags_maybe_bail () {
 324     return if all_snags_summarised();
 325     if ($snags_forced) {
 326         printf STDERR
 327             "%s: snags: %d overriden by individual -f options\n",
 328             $us, $snags_forced;
 329     }
 330     if ($snags_tripped) {
 331         if ($opt_force) {
 332             printf STDERR
 333                 "%s: snags: %d overriden by global --force\n",
 334                 $us, $snags_tripped;
 335         } else {
 336             fail sprintf
 337   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 338                 $us, $snags_tripped;
 339         }
 340     }
 341     $snags_summarised = $snags_forced + $snags_tripped;
 342 }
 343 sub snags_maybe_bail_early () {
 344     # useful to bail out early without doing a lot of work;
 345     # not a substitute for snags_maybe_bail.
 346     snags_maybe_bail() if $snags_tripped && !$opt_force;
 347 }
 348 sub any_snags () {
 349     return $snags_forced || $snags_tripped;
 350 }
 351
 352 sub gbp_pq_export ($$$) {
 353     my ($bname, $base, $tip) = @_;
 354     # must be run in a workarea.  $bname and patch-queue/$bname
 355     # ought not to exist.  Leaves you on patch-queue/$bname with
 356     # the patches staged but not committed.
 357     printdebug "gbp_pq_export $bname $base $tip\n";
 358     runcmd @git, qw(checkout -q -b), $bname, $base;
 359     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 360     my @gbp_cmd = (qw(gbp pq export));
 361     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 362     if ($r) {
 363         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 364         failedcmd @gbp_cmd;
 365     }
 366     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 367 }
 368
 369
 370 # xxx allow merge resolution separately from laundering, before git merge
 371 #
 372 # xxx general gdr docs highlight forbidden things
 373 # xxx general gdr docs list allowable things ?
 374 # xxx general gdr docs explicitly forbid some rebase
 375 #
 376 # xxx provide a way for the user to help
 377 # xxx (eg, provide wreckage provide way to continue)
 378
 379 # later/rework?
 380 #  use git-format-patch?
 381 #  our own patch identification algorithm?
 382 #  this is an alternative strategy
 383
 384 sub merge_failed ($$;@) {
 385     my ($wrecknotes, $emsg, @xmsgs) = @_;
 386     my @m;
 387     push @m, "Merge resolution failed: $emsg";
 388     push @m, @xmsgs;
 389
 390     changedir $maindir;
 391
 392     my @updates;
 393     merge_wreckage_cleaning \@updates;
 394     run_ref_updates_now "merge failed", \@updates;
 395
 396     @updates = ();
 397     keys %$wrecknotes;
 398     while (my ($k,$v) = each %$wrecknotes) {
 399         push @updates, "create $wrecknoteprefix/$k $v";
 400     }
 401     run_ref_updates_now "merge failed", \@updates;
 402     push @m, "Wreckage left in $wrecknoteprefix/*.";
 403
 404     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 405
 406     # use finish rather than fail, in case we are within an eval
 407     # (that can happen inside walk!)
 408     print STDERR "\n";
 409     print STDERR "$us: $_\n" foreach @m;
 410     finish 15;
 411 }
 412
 413 sub mwrecknote ($$$) {
 414     my ($wrecknotes, $reftail, $commitish) = @_;
 415     confess unless defined $commitish;
 416     printdebug "mwrecknote $reftail $commitish\n";
 417     $wrecknotes->{$reftail} = $commitish;
 418 }
 419
 420 sub merge_attempt_cmd {
 421     my $wrecknotes = shift @_;
 422     debugcmd '+', @_;
 423     $!=0; $?=-1;
 424     if (system @_) {
 425         merge_failed $wrecknotes,
 426             failedcmd_waitstatus(),
 427             "failed command: @_";
 428     }
 429 }
 430
 431 sub merge_series ($$$;@) {
 432     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 433     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 434     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 435     # ^ specifies several patch series (currently we only support exactly 2)
 436     # return value is a commit which is the result of
 437     # merging the two versions of the same topic branch
 438     #   $input_q[0] and $input_q[1]
 439     # with respect to the old version
 440     #   $base_q
 441     # all onto $newbase.
 442
 443     # Creates, in *_q, a key MR for its private use
 444
 445     printdebug "merge_series newbase=$newbase\n";
 446
 447     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 448     $base_q->{MR}{S} = 'base';
 449
 450     my %prereq;
 451     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 452     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 453     # $prereq{<patch filename>}               exists or not (even later)
 454
 455     my $result;
 456     my $merged_pq;
 457
 458     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 459
 460     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 461
 462     local $workarea;
 463     fresh_workarea "merge";
 464     my $seriesfile = "debian/patches/series";
 465     in_workarea sub {
 466         playtree_setup();
 467         foreach my $q ($base_q, reverse @input_qs) {
 468             my $s = $q->{MR}{S};
 469             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 470             my @earlier;
 471             if (open S, $seriesfile) {
 472                 while (my $patch = <S>) {
 473                     chomp $patch or die $!;
 474                     $prereq{$patch} //= {};
 475                     foreach my $earlier (@earlier) {
 476                         $prereq{$patch}{$earlier}{$s}++ and die;
 477                     }
 478                     push @earlier, $patch;
 479                     stat "debian/patches/$patch" or die "$patch ?";
 480                 }
 481                 S->error and die "$seriesfile $!";
 482                 close S;
 483             } else {
 484                 die "$seriesfile $!" unless $!==ENOENT;
 485             }
 486             read_tree_upstream $newbase, 1;
 487             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 488                 "Convert $s to patch queue for merging",
 489                 "[git-debrebase merge-innards patch-queue import:".
 490                 " $q->{SeriesTip}]"
 491             ];
 492             printdebug "merge_series  pec $pec ";
 493             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 494             $pec = make_commit [ $pec ], [
 495                 "Drop series file from $s to avoid merge trouble",
 496                 "[git-debrebase merge-innards patch-queue prep:".
 497                 " $q->{SeriesTip}]"
 498             ];
 499
 500             read_tree_debian $newbase;
 501             if (@earlier) {
 502                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 503             } else {
 504                 rm_subdir_cached 'debian/patches';
 505             }
 506             $pec = make_commit [ $pec ], [
 507  "Update debian/ (excluding patches) to final to avoid re-merging",
 508  "debian/ was already merged and we need to just take that.",
 509                 "[git-debrebase merge-innards patch-queue packaging:".
 510                 " $q->{SeriesTip}]"
 511             ];
 512
 513             printdebug "pec' $pec\n";
 514             runcmd @git, qw(reset -q --hard), $pec;
 515             $q->{MR}{PEC} = $pec;
 516             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 517         }
 518         # now, because of reverse, we are on $input_q->{MR}{OQC}
 519         runcmd @git, qw(checkout -q -b merge);
 520         printdebug "merge_series merging...\n";
 521         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 522
 523         $attempt_cmd->(@mergecmd);
 524
 525         printdebug "merge_series merge ok, series...\n";
 526         # We need to construct a new series file
 527         # Firstly, resolve prereq
 528         foreach my $f (sort keys %prereq) {
 529             printdebug "merge_series  patch\t$f\t";
 530             if (!stat_exists "debian/patches/$f") {
 531                 print DEBUG " drop\n" if $debuglevel;
 532                 # git merge deleted it; that's how we tell it's not wanted
 533                 delete $prereq{$f};
 534                 next;
 535             }
 536             print DEBUG " keep\n" if $debuglevel;
 537             foreach my $g (sort keys %{ $prereq{$f} }) {
 538                 my $gfp = $prereq{$f}{$g};
 539                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 540                 if (!!$gfp->{0} == !!$gfp->{1}
 541                     ? $gfp->{0}
 542                     : !$gfp->{base}) {
 543                     print DEBUG "\tkeep\n" if $debuglevel;
 544                 } else {
 545                     print DEBUG "\tdrop\n" if $debuglevel;
 546                     delete $prereq{$f}{$g};
 547                 }
 548             }
 549         }
 550
 551         my $unsat = sub {
 552             my ($f) = @_;
 553             return scalar keys %{ $prereq{$f} };
 554         };
 555
 556         my $nodate = time + 1;
 557         my %authordate;
 558         # $authordate{<patch filename>};
 559         my $authordate = sub {
 560             my ($f) = @_;
 561             $authordate{$f} //= do {
 562                 open PF, "<", "debian/patches/$f" or die "$f $!";
 563                 while (<PF>) {
 564                     return $nodate if m/^$/;
 565                     last if s{^Date: }{};
 566                 }
 567                 chomp;
 568                 return cmdoutput qw(date +%s -d), $_;
 569             };
 570         };
 571
 572         open NS, '>', $seriesfile or die $!;
 573
 574         while (keys %prereq) {
 575             my $best;
 576             foreach my $try (sort keys %prereq) {
 577                 if ($best) {
 578                     next if (
 579                              $unsat->($try) <=> $unsat->($best) or
 580                              $authordate->($try) <=> $authordate->($best) or
 581                              $try cmp $best
 582                             ) >= 0;
 583                 }
 584                 $best = $try;
 585             }
 586             printdebug "merge_series series next $best\n";
 587             print NS "$best\n" or die $!;
 588             delete $prereq{$best};
 589             foreach my $gp (values %prereq) {
 590                 delete $gp->{$best};
 591             }
 592         }
 593
 594         runcmd @git, qw(add), $seriesfile;
 595         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 596         $merged_pq = git_rev_parse 'HEAD';
 597         $mwrecknote->('merged-patchqueue', $merged_pq);
 598
 599         printdebug "merge_series series gbp pq import\n";
 600
 601         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 602
 603         # OK now we are on patch-queue/merge, and we need to rebase
 604         # onto the intended parent and drop the patches from each one
 605
 606         printdebug "merge_series series ok, building...\n";
 607         my $build = $newbase;
 608         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 609         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 610             my $commit = git_cat_file $c, 'commit';
 611             printdebug "merge_series series ok, building $c\n";
 612             read_tree_upstream $c, 0, $newbase;
 613             my $tree = cmdoutput @git, qw(write-tree);
 614             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 615             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 616             open C, ">", "../mcommit" or die $!;
 617             print C $commit or die $!;
 618             close C or die $!;
 619             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 620         }
 621         $result = $build;
 622         mwrecknote($wrecknotes, 'merged-result', $result);
 623
 624         runcmd @git, qw(update-ref refs/heads/result), $result;
 625
 626         runcmd @git, qw(checkout -q -b debug);
 627         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 628         runcmd @git, qw(add .);
 629         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 630         my $mdebug = git_rev_parse 'HEAD';
 631         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 632         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 633     };
 634     printdebug "merge_series returns $result\n";
 635     return $result;
 636 }
 637
 638 # classify returns an info hash like this
 639 #   CommitId => $objid
 640 #   Hdr => # commit headers, including 1 final newline
 641 #   Msg => # commit message (so one newline is dropped)
 642 #   Tree => $treeobjid
 643 #   Type => (see below)
 644 #   Parents = [ {
 645 #       Ix => $index # ie 0, 1, 2, ...
 646 #       CommitId
 647 #       Differs => return value from get_differs
 648 #       IsOrigin
 649 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 650 #     } ...]
 651 #   NewMsg => # commit message, but with any [dgit import ...] edited
 652 #             # to say "[was: ...]"
 653 #
 654 # Types:
 655 #   Packaging
 656 #   Changelog
 657 #   Upstream
 658 #   AddPatches
 659 #   Mixed
 660 #
 661 #   Pseudomerge
 662 #     has additional entres in classification result
 663 #       Overwritten = [ subset of Parents ]
 664 #       Contributor = $the_remaining_Parent
 665 #
 666 #   DgitImportUnpatched
 667 #     has additional entry in classification result
 668 #       OrigParents = [ subset of Parents ]
 669 #
 670 #   Anchor
 671 #     has additional entry in classification result
 672 #       OrigParents = [ subset of Parents ]  # singleton list
 673 #
 674 #   TreatAsAnchor
 675 #
 676 #   BreakwaterStart
 677 #
 678 #   Unknown
 679 #     has additional entry in classification result
 680 #       Why => "prose"
 681
 682 sub parsecommit ($;$) {
 683     my ($objid, $p_ref) = @_;
 684     # => hash with                   CommitId Hdr Msg Tree Parents
 685     #    Parents entries have only   Ix CommitId
 686     #    $p_ref, if provided, must be [] and is used as a base for Parents
 687
 688     $p_ref //= [];
 689     die if @$p_ref;
 690
 691     my ($h,$m) = get_commit $objid;
 692
 693     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 694     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 695
 696     my $r = {
 697         CommitId => $objid,
 698         Hdr => $h,
 699         Msg => $m,
 700         Tree => $t,
 701         Parents => $p_ref,
 702     };
 703
 704     foreach my $ph (@ph) {
 705         push @$p_ref, {
 706             Ix => scalar @$p_ref,
 707             CommitId => $ph,
 708         };
 709     }
 710
 711     return $r;
 712 }
 713
 714 sub classify ($) {
 715     my ($objid) = @_;
 716
 717     my @p;
 718     my $r = parsecommit($objid, \@p);
 719     my $t = $r->{Tree};
 720
 721     foreach my $p (@p) {
 722         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 723     }
 724
 725     printdebug "classify $objid \$t=$t \@p",
 726         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 727         "\n";
 728
 729     my $classify = sub {
 730         my ($type, @rest) = @_;
 731         $r = { %$r, Type => $type, @rest };
 732         if ($debuglevel) {
 733             printdebug " = $type ".(dd $r)."\n";
 734         }
 735         return $r;
 736     };
 737     my $unknown = sub {
 738         my ($why) = @_;
 739         $r = { %$r, Type => qw(Unknown), Why => $why };
 740         printdebug " ** Unknown\n";
 741         return $r;
 742     };
 743
 744     if (grep { $_ eq $objid } @opt_anchors) {
 745         return $classify->('TreatAsAnchor');
 746     }
 747
 748     my @identical = grep { !$_->{Differs} } @p;
 749     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 750     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 751
 752     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 753         # multi-orig upstreams are represented with an anchor merge
 754         # from a single upstream commit which combines the orig tarballs
 755
 756         # Every anchor tagged this way must be a merge.
 757         # We are relying on the
 758         #     [git-debrebase anchor: ...]
 759         # commit message annotation in "declare" anchor merges (which
 760         # do not have any upstream changes), to distinguish those
 761         # anchor merges from ordinary pseudomerges (which we might
 762         # just try to strip).
 763         #
 764         # However, the user is going to be doing git-rebase a lot.  We
 765         # really don't want them to rewrite an anchor commit.
 766         # git-rebase trips up on merges, so that is a useful safety
 767         # catch.
 768         #
 769         # BreakwaterStart commits are also anchors in the terminology
 770         # of git-debrebase(5), but they are untagged (and always
 771         # manually generated).
 772         #
 773         # We cannot not tolerate any tagged linear commit (ie,
 774         # BreakwaterStart commits tagged `[anchor:') because such a
 775         # thing could result from an erroneous linearising raw git
 776         # rebase of a merge anchor.  That would represent a corruption
 777         # of the branch. and we want to detect and reject the results
 778         # of such corruption before it makes it out anywhere.  If we
 779         # reject it here then we avoid making the pseudomerge which
 780         # would be needed to push it.
 781
 782         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 783         @p == 2 or return $badanchor->("has other than two parents");
 784         $haspatches and return $badanchor->("contains debian/patches");
 785
 786         # How to decide about l/r ordering of anchors ?  git
 787         # --topo-order prefers to expand 2nd parent first.  There's
 788         # already an easy rune to look for debian/ history anyway (git log
 789         # debian/) so debian breakwater branch should be 1st parent; that
 790         # way also there's also an easy rune to look for the upstream
 791         # patches (--topo-order).
 792
 793         # Also this makes --first-parent be slightly more likely to
 794         # be useful - it makes it provide a linearised breakwater history.
 795
 796         # Of course one can say somthing like
 797         #  gitk -- ':/' ':!/debian'
 798         # to get _just_ the commits touching upstream files, and by
 799         # the TREESAME logic in git-rev-list this will leave the
 800         # breakwater into upstream at the first anchor.  But that
 801         # doesn't report debian/ changes at all.
 802
 803         # Other observations about gitk: by default, gitk seems to
 804         # produce output in a different order to git-rev-list.  I
 805         # can't seem to find this documented anywhere.  gitk
 806         # --date-order DTRT.  But, gitk always seems to put the
 807         # parents from left to right, in order, so it's easy to see
 808         # which way round a pseudomerge is.
 809
 810         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 811         $p[1]{Differs} & ~DS_DEB and
 812             $badanchor->("upstream files differ from left parent");
 813         $p[0]{Differs} & ~D_UPS and
 814             $badanchor->("debian/ differs from right parent");
 815
 816         return $classify->(qw(Anchor),
 817                            OrigParents => [ $p[1] ]);
 818     }
 819
 820     if (@p == 1) {
 821         my $d = $r->{Parents}[0]{Differs};
 822         if ($d == D_PAT_ADD) {
 823             return $classify->(qw(AddPatches));
 824         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 825             return $unknown->("edits debian/patches");
 826         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 827             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 828             if ($ty eq 'tree') {
 829                 if ($d == D_DEB_CLOG) {
 830                     return $classify->(qw(Changelog));
 831                 } else {
 832                     return $classify->(qw(Packaging));
 833                 }
 834             } elsif ($ty eq 'missing') {
 835                 return $classify->(qw(BreakwaterStart));
 836             } else {
 837                 return $unknown->("parent's debian is not a directory");
 838             }
 839         } elsif ($d == D_UPS) {
 840             return $classify->(qw(Upstream));
 841         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 842             return $classify->(qw(Mixed));
 843         } elsif ($d == 0) {
 844             return $unknown->("no changes");
 845         } else {
 846             confess "internal error $objid ?";
 847         }
 848     }
 849     if (!@p) {
 850         return $unknown->("origin commit");
 851     }
 852
 853     if (@p == 2 && @identical == 1) {
 854         my @overwritten = grep { $_->{Differs} } @p;
 855         confess "internal error $objid ?" unless @overwritten==1;
 856         return $classify->(qw(Pseudomerge),
 857                            Overwritten => [ $overwritten[0] ],
 858                            Contributor => $identical[0]);
 859     }
 860     if (@p == 2 && @identical == 2) {
 861         my $get_t = sub {
 862             my ($ph,$pm) = get_commit $_[0]{CommitId};
 863             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 864             $1;
 865         };
 866         my @bytime = @p;
 867         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 868         if ($order > 0) { # newer first
 869         } elsif ($order < 0) {
 870             @bytime = reverse @bytime;
 871         } else {
 872             # same age, default to order made by -s ours
 873             # that is, commit was made by someone who preferred L
 874         }
 875         return $classify->(qw(Pseudomerge),
 876                            SubType => qw(Ambiguous),
 877                            Contributor => $bytime[0],
 878                            Overwritten => [ $bytime[1] ]);
 879     }
 880     foreach my $p (@p) {
 881         my ($p_h, $p_m) = get_commit $p->{CommitId};
 882         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 883         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 884     }
 885     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 886     my $m2 = $r->{Msg};
 887     if (!(grep { !$_->{IsOrigin} } @p) and
 888         (@orig_ps >= @p - 1) and
 889         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 890         $r->{NewMsg} = $m2;
 891         return $classify->(qw(DgitImportUnpatched),
 892                            OrigParents => \@orig_ps);
 893     }
 894
 895     if (@p == 2 and
 896         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 897         # xxx ^ metadata tag needs adding to (5)
 898         return $classify->("MergedBreakwaters");
 899     }
 900     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 901         return $unknown->("unknown kind of merge from $1");
 902     }
 903     if (@p > 2) {
 904         return $unknown->("octopus merge");
 905     }
 906
 907     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 908         return $unknown->("general two-parent merge");
 909     }
 910
 911     return $classify->("VanillaMerge");
 912 }
 913
 914 sub keycommits ($;$$$$$);
 915
 916 sub mergedbreakwaters_anchor ($) {
 917     my ($cl) = @_;
 918     my $best_anchor;
 919     foreach my $p (@{ $cl->{Parents} }) {
 920         my ($panchor, $pbw) = keycommits $p->{CommitId},
 921             undef,undef,undef,undef, 1;
 922         $best_anchor = $panchor
 923             if !defined $best_anchor
 924             or is_fast_fwd $best_anchor, $panchor;
 925         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 926             unless is_fast_fwd $panchor, $best_anchor;
 927     }
 928     return $best_anchor;
 929 }
 930
 931 sub keycommits ($;$$$$$) {
 932     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 933     # => ($anchor, $breakwater)
 934
 935     # $unclean->("unclean-$tagsfx", $msg, $cl)
 936     # $furniture->("unclean-$tagsfx", $msg, $cl)
 937     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 938     #   is callled for each situation or commit that
 939     #   wouldn't be found in a laundered branch
 940     # $furniture is for furniture commits such as might be found on an
 941     #   interchange branch (pseudomerge, d/patches, changelog)
 942     # $trouble is for things whnich prevent the return of
 943     #   anchor and breakwater information; if that is ignored,
 944     #   then keycommits returns (undef, undef) instead.
 945     # $fatal is for unprocessable commits, and should normally cause
 946     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 947     #
 948     # If $claimed_bw, this is supposed to be a breakwater commit.
 949     #
 950     # If a callback is undef, fail is called instead.
 951     # If a callback is defined but false, the situation is ignored.
 952     # Callbacks may say:
 953     #   no warnings qw(exiting); last;
 954     # if the answer is no longer wanted.
 955
 956     my ($anchor, $breakwater);
 957     $breakwater = $head if $claimed_bw;
 958     my $clogonly;
 959     my $cl;
 960     my $found_pm;
 961     $fatal //= sub { fail $_[1]; };
 962     my $x = sub {
 963         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 964         my $why = $mainwhy.$xwhy;
 965         my $m = "branch needs laundering (run git-debrebase): $why";
 966         fail $m unless defined $cb;
 967         return unless $cb;
 968         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 969     };
 970     my $found_anchor = sub {
 971         ($anchor) = @_;
 972         $breakwater //= $clogonly;
 973         $breakwater //= $head;
 974         no warnings qw(exiting);
 975         last;
 976     };
 977     for (;;) {
 978         $cl = classify $head;
 979         my $ty = $cl->{Type};
 980         if ($ty eq 'Packaging') {
 981             $breakwater //= $clogonly;
 982             $breakwater //= $head;
 983         } elsif ($ty eq 'Changelog') {
 984             # this is going to count as the tip of the breakwater
 985             # only if it has no upstream stuff before it
 986             $clogonly //= $head;
 987         } elsif ($ty eq 'Anchor' or
 988                  $ty eq 'TreatAsAnchor' or
 989                  $ty eq 'BreakwaterStart') {
 990             $found_anchor->($head);
 991         } elsif ($ty eq 'Upstream') {
 992             $x->($unclean, 'ordering',
 993  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 994                 if defined $breakwater;
 995             $clogonly = undef;
 996             $breakwater = undef;
 997         } elsif ($ty eq 'Mixed') {
 998             $x->($unclean, 'mixed',
 999                  "found mixed upstream/packaging commit"," ($head)");
1000             $clogonly = undef;
1001             $breakwater = undef;
1002         } elsif ($ty eq 'Pseudomerge' or
1003                  $ty eq 'AddPatches') {
1004             my $found_pm = 1;
1005             $x->($furniture, (lc $ty),
1006                  "found interchange bureaucracy commit ($ty)"," ($head)");
1007         } elsif ($ty eq 'DgitImportUnpatched') {
1008             if ($found_pm) {
1009                 $x->($trouble, 'dgitimport',
1010                      "found dgit dsc import"," ($head)");
1011                 return (undef,undef);
1012             } else {
1013                 $x->($fatal, 'unprocessable',
1014                      "found bare dgit dsc import with no prior history",
1015                      " ($head)");
1016                 return (undef,undef);
1017             }
1018         } elsif ($ty eq 'VanillaMerge') {
1019             $x->($trouble, 'vanillamerge',
1020                  "found vanilla merge"," ($head)");
1021             return (undef,undef);
1022         } elsif ($ty eq 'MergedBreakwaters') {
1023             $found_anchor->(mergedbreakwaters_anchor $cl);
1024         } else {
1025             $x->($fatal, 'unprocessable',
1026                  "found unprocessable commit, cannot cope: $cl->{Why}",
1027                  " ($head)");
1028             return (undef,undef);
1029         }
1030         $head = $cl->{Parents}[0]{CommitId};
1031     }
1032     return ($anchor, $breakwater);
1033 }
1034
1035 sub walk ($;$$$);
1036 sub walk ($;$$$) {
1037     my ($input,
1038         $nogenerate,$report, $report_lprefix) = @_;
1039     # => ($tip, $breakwater_tip, $last_anchor)
1040     # (or nothing, if $nogenerate)
1041
1042     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1043     $report_lprefix //= '';
1044
1045     # go through commits backwards
1046     # we generate two lists of commits to apply:
1047     # breakwater branch and upstream patches
1048     my (@brw_cl, @upp_cl, @processed);
1049     my %found;
1050     my $upp_limit;
1051     my @pseudomerges;
1052
1053     my $cl;
1054     my $xmsg = sub {
1055         my ($prose, $info) = @_;
1056         my $ms = $cl->{Msg};
1057         chomp $ms;
1058         $info //= '';
1059         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1060         return (Msg => $ms);
1061     };
1062     my $rewrite_from_here = sub {
1063         my ($cl) = @_;
1064         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1065         push @$cl, $sp_cl;
1066         push @processed, $sp_cl;
1067     };
1068     my $cur = $input;
1069
1070     my $prdelim = "";
1071     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1072
1073     my $prline = sub {
1074         return unless $report;
1075         print $report $prdelim, $report_lprefix, @_;
1076         $prdelim = "\n";
1077     };
1078
1079     my $bomb = sub { # usage: return $bomb->();
1080         print $report " Unprocessable" if $report;
1081         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1082         $prprdelim->();
1083         if ($nogenerate) {
1084             return (undef,undef);
1085         }
1086         fail "found unprocessable commit, cannot cope".
1087             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1088             " (commit $cur) (d.".
1089             (join ' ', map { sprintf "%#x", $_->{Differs} }
1090              @{ $cl->{Parents} }).
1091                  ")";
1092     };
1093
1094     my $build;
1095     my $breakwater;
1096
1097     my $build_start = sub {
1098         my ($msg, $parent) = @_;
1099         $prline->(" $msg");
1100         $build = $parent;
1101         no warnings qw(exiting); last;
1102     };
1103
1104     my $nomerge = sub {
1105         my ($emsg) = @_;
1106         merge_failed $cl->{MergeWreckNotes}, $emsg;
1107     };
1108
1109     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1110
1111     my $last_anchor;
1112
1113     for (;;) {
1114         $cl = classify $cur;
1115         $cl->{MergeWreckNotes} //= {};
1116         my $ty = $cl->{Type};
1117         my $st = $cl->{SubType};
1118         $prline->("$cl->{CommitId} $cl->{Type}");
1119         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1120         push @processed, $cl;
1121         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1122         if ($ty eq 'AddPatches') {
1123             $cur = $p0;
1124             $rewrite_from_here->(\@upp_cl);
1125             next;
1126         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1127             push @brw_cl, $cl;
1128             $cur = $p0;
1129             next;
1130         } elsif ($ty eq 'BreakwaterStart') {
1131             $last_anchor = $cur;
1132             $build_start->('FirstPackaging', $cur);
1133         } elsif ($ty eq 'Upstream') {
1134             push @upp_cl, $cl;
1135             $cur = $p0;
1136             next;
1137         } elsif ($ty eq 'Mixed') {
1138             my $queue = sub {
1139                 my ($q, $wh) = @_;
1140                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1141                 push @$q, $cls;
1142             };
1143             $queue->(\@brw_cl, "debian");
1144             $queue->(\@upp_cl, "upstream");
1145             $rewrite_from_here->(\@brw_cl);
1146             $cur = $p0;
1147             next;
1148         } elsif ($ty eq 'Pseudomerge') {
1149             my $contrib = $cl->{Contributor}{CommitId};
1150             print $report " Contributor=$contrib" if $report;
1151             push @pseudomerges, $cl;
1152             $rewrite_from_here->(\@upp_cl);
1153             $cur = $contrib;
1154             next;
1155         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1156             $last_anchor = $cur;
1157             $build_start->("Anchor", $cur);
1158         } elsif ($ty eq 'DgitImportUnpatched') {
1159             my $pm = $pseudomerges[-1];
1160             if (defined $pm) {
1161                 # To an extent, this is heuristic.  Imports don't have
1162                 # a useful history of the debian/ branch.  We assume
1163                 # that the first pseudomerge after an import has a
1164                 # useful history of debian/, and ignore the histories
1165                 # from later pseudomerges.  Often the first pseudomerge
1166                 # will be the dgit import of the upload to the actual
1167                 # suite intended by the non-dgit NMUer, and later
1168                 # pseudomerges may represent in-archive copies.
1169                 my $ovwrs = $pm->{Overwritten};
1170                 printf $report " PM=%s \@Overwr:%d",
1171                     $pm->{CommitId}, (scalar @$ovwrs)
1172                     if $report;
1173                 if (@$ovwrs != 1) {
1174                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1175                     return $bomb->();
1176                 }
1177                 my $ovwr = $ovwrs->[0]{CommitId};
1178                 printf $report " Overwr=%s", $ovwr if $report;
1179                 # This import has a tree which is just like a
1180                 # breakwater tree, but it has the wrong history.  It
1181                 # ought to have the previous breakwater (which the
1182                 # pseudomerge overwrote) as an ancestor.  That will
1183                 # make the history of the debian/ files correct.  As
1184                 # for the upstream version: either it's the same as
1185                 # was ovewritten (ie, same as the previous
1186                 # breakwater), in which case that history is precisely
1187                 # right; or, otherwise, it was a non-gitish upload of a
1188                 # new upstream version.  We can tell these apart by
1189                 # looking at the tree of the supposed upstream.
1190                 push @brw_cl, {
1191                     %$cl,
1192                     SpecialMethod => 'DgitImportDebianUpdate',
1193                     $xmsg->("convert dgit import: debian changes")
1194                 }, {
1195                     %$cl,
1196                     SpecialMethod => 'DgitImportUpstreamUpdate',
1197                     $xmsg->("convert dgit import: upstream update",
1198                             " anchor")
1199                 };
1200                 $prline->(" Import");
1201                 $rewrite_from_here->(\@brw_cl);
1202                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1203                 $cur = $ovwr;
1204                 next;
1205             } else {
1206                 # Everything is from this import.  This kind of import
1207                 # is already nearly in valid breakwater format, with the
1208                 # patches as commits.  Unfortunately it contains
1209                 # debian/patches/.
1210                 printdebug "*** WALK BOMB bare dgit import\n";
1211                 $cl->{Why} = "bare dgit dsc import";
1212                 return $bomb->();
1213             }
1214             die "$ty ?";
1215         } elsif ($ty eq 'MergedBreakwaters') {
1216             $last_anchor = mergedbreakwaters_anchor $cl;
1217             $build_start->(' MergedBreakwaters', $cur);
1218             last;
1219         } elsif ($ty eq 'VanillaMerge') {
1220             # User may have merged unstitched branch(es).  We will
1221             # have now lost what ffq-prev was then (since the later
1222             # pseudomerge may introduce further changes).  The effect
1223             # of resolving such a merge is that we may have to go back
1224             # further in history to find a merge base, since the one
1225             # which was reachable via ffq-prev is no longer findable.
1226             # This is suboptimal, but if it all works we'll have done
1227             # the right thing.
1228             # xxx we should warn the user in the docs about this
1229
1230             my $ok=1;
1231             my $best_anchor;
1232             # We expect to find a dominating anchor amongst the
1233             # inputs' anchors.  That will be the new anchor.
1234             #
1235             # More complicated is finding a merge base for the
1236             # breakwaters.  We need a merge base that is a breakwater
1237             # commit.  The ancestors of breakwater commits are more
1238             # breakwater commits and possibly upstream commits and the
1239             # ancestors of those upstream.  Upstreams might have
1240             # arbitrary ancestors.  But any upstream commit U is
1241             # either included in both anchors, in which case the
1242             # earlier anchor is a better merge base than any of U's
1243             # ancestors; or U is not included in the older anchor, in
1244             # which case U is not an ancestor of the vanilla merge at
1245             # all.  So no upstream commit, nor any ancestor thereof,
1246             # is a best merge base.  As for non-breakwater Debian
1247             # commits: these are never ancestors of any breakwater.
1248             #
1249             # So any best merge base as found by git-merge-base
1250             # is a suitable breakwater anchor.  Usually there will
1251             # be only one.
1252
1253             printdebug "*** MERGE\n";
1254
1255             my @bwbcmd = (@git, qw(merge-base));
1256             my @ibcmd = (@git, qw(merge-base --all));
1257             my $might_be_in_bw = 1;
1258
1259             my $ps = $cl->{Parents};
1260
1261             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1262
1263             foreach my $p (@$ps) {
1264                 $prline->(" VanillaMerge ".$p->{Ix});
1265                 $prprdelim->();
1266                 my ($ptip, $pbw, $panchor) =
1267                     walk $p->{CommitId}, 0, $report,
1268                          $report_lprefix.'  ';
1269                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1270                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1271                 $p->{Anchor} = $panchor;
1272
1273                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1274                 $mwrecknote->("$lr-input", $p->{CommitId});
1275
1276                 my $mwrecknote_parent = sub {
1277                     my ($which) = @_;
1278                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1279                 };
1280                 $mwrecknote_parent->('Laundered');
1281                 $mwrecknote_parent->('Breakwater');
1282                 $mwrecknote_parent->('Anchor');
1283
1284                 $best_anchor = $panchor if
1285                     !defined $best_anchor or
1286                     is_fast_fwd $best_anchor, $panchor;
1287
1288                 printdebug " MERGE BA best=".($best_anchor//'-').
1289                     " p=$panchor\n";
1290             }
1291
1292             $mwrecknote->('result-anchor', $best_anchor);
1293
1294             foreach my $p (@$ps) {
1295                 $prline->(" VanillaMerge ".$p->{Ix});
1296                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1297                     $nomerge->('divergent anchors');
1298                 } elsif ($p->{Anchor} eq $best_anchor) {
1299                     print $report " SameAnchor" if $report;
1300                 } else {
1301                     print $report " SupersededAnchor" if $report;
1302                 }
1303                 if ($p->{Breakwater} eq $p->{CommitId}) {
1304                     # this parent commit was its own breakwater,
1305                     # ie it is part of the breakwater
1306                     print $report " Breakwater" if $report;
1307                 } else {
1308                     $might_be_in_bw = 0;
1309                 }
1310                 push @bwbcmd, $p->{Breakwater};
1311                 push @ibcmd, $p->{CommitId};
1312             }
1313
1314             if ($ok && $might_be_in_bw) {
1315                 # We could rewrite this to contaion the metadata
1316                 # declaring it to be MergedBreakwaters, but
1317                 # unnecessarily rewriting a merge seems unhelpful.
1318                 $prline->(" VanillaMerge MergedBreakwaters");
1319                 $last_anchor = $best_anchor;
1320                 $build_start->('MergedBreakwaters', $cur);
1321             }
1322
1323             my $bwb = cmdoutput @bwbcmd;
1324
1325             # OK, now we have a breakwater base, but we need the merge
1326             # base for the interchange branch because we need the delta
1327             # queue.
1328             #
1329             # This a the best merge base of our inputs which has the
1330             # breakwater merge base as an ancestor.
1331
1332             my @ibs =
1333                 grep /./,
1334                 split /\n/,
1335                 cmdoutput @ibcmd;
1336
1337             @ibs or confess 'internal error, expected anchor at least ?';
1338
1339             my $ib;
1340             my $ibleaf;
1341             foreach my $tibix (0..$#ibs) {
1342                 my $tib = $ibs[$tibix];
1343                 my $ff = is_fast_fwd $bwb, $tib;
1344                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1345                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1346                 $mwrecknote->($tibleaf, $tib);
1347                 next unless $ff;
1348                 next if $ib;
1349                 $ib = $tib;
1350                 $ibleaf = $tibleaf;
1351             }
1352
1353             $ib or $nomerge->("no suitable interchange merge base");
1354
1355             $prline->("  VanillaMerge Base");
1356             $prprdelim->();
1357             my ($btip, $bbw, $banchor) = eval {
1358                 walk $ib, 0, $report, $report_lprefix.'  ';
1359             };
1360             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1361                        $@)
1362                 if length $@;
1363
1364             $mwrecknote->("mergebase-laundered", $btip);
1365             $mwrecknote->("mergebase-breakwater", $bbw);
1366             $mwrecknote->("mergebase-anchor", $banchor);
1367
1368             my $ibinfo = { SeriesTip => $btip,
1369                            SeriesBase => $bbw,
1370                            Anchor => $banchor,
1371                            LeftRight => 'mergebase' };
1372
1373             $bbw eq $bwb
1374                 or $nomerge->("interchange merge-base ($ib)'s".
1375                               " breakwater ($bbw)".
1376                               " != breakwaters' merge-base ($bwb)");
1377
1378             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1379                  or $nomerge->("interchange merge-base ($ib)'s".
1380                                " anchor ($ibinfo->{SeriesBase})".
1381                                " != any merge input's anchor (".
1382                                (join ' ', map { $_->{Anchor} } @$ps).
1383                                ")");
1384
1385             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1386             $cl->{MergeBestAnchor} = $best_anchor;
1387             push @brw_cl, {
1388                 %$cl,
1389                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1390                 $xmsg->('constructed from vanilla merge',
1391                         ' merged-breakwater'),
1392             };
1393             push @upp_cl, {
1394                 %$cl,
1395                 SpecialMethod => 'MergeMergeSeries',
1396             };
1397             $build_start->('MergeBreakwaters', $cur);
1398         } else {
1399             printdebug "*** WALK BOMB unrecognised\n";
1400             return $bomb->();
1401         }
1402     }
1403     $prprdelim->();
1404
1405     printdebug "*** WALK prep done cur=$cur".
1406         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1407
1408     return if $nogenerate;
1409
1410     # Now we build it back up again
1411
1412     fresh_workarea();
1413
1414     my $rewriting = 0;
1415
1416     my $read_tree_upstream = sub {
1417         my ($treeish) = @_;
1418         read_tree_upstream $treeish, 0, $build;
1419     };
1420
1421     $#upp_cl = $upp_limit if defined $upp_limit;
1422
1423     my $committer_authline = calculate_committer_authline();
1424
1425     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1426
1427     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1428
1429     in_workarea sub {
1430         mkdir $rd or $!==EEXIST or die $!;
1431         my $current_method;
1432         runcmd @git, qw(read-tree), $build;
1433         foreach my $cl (qw(Debian), (reverse @brw_cl),
1434                         { SpecialMethod => 'RecordBreakwaterTip' },
1435                         qw(Upstream), (reverse @upp_cl)) {
1436             if (!ref $cl) {
1437                 $current_method = $cl;
1438                 next;
1439             }
1440             my $method = $cl->{SpecialMethod} // $current_method;
1441             my @parents = ($build);
1442             my $cltree = $cl->{CommitId};
1443             printdebug "WALK BUILD ".($cltree//'undef').
1444                 " $method (rewriting=$rewriting)\n";
1445             if ($method eq 'Debian') {
1446                 read_tree_debian($cltree);
1447             } elsif ($method eq 'Upstream') {
1448                 $read_tree_upstream->($cltree);
1449             } elsif ($method eq 'StartRewrite') {
1450                 $rewriting = 1;
1451                 next;
1452             } elsif ($method eq 'RecordBreakwaterTip') {
1453                 $breakwater = $build;
1454                 next;
1455             } elsif ($method eq 'DgitImportDebianUpdate') {
1456                 read_tree_debian($cltree);
1457             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1458                 confess unless $rewriting;
1459                 my $differs = (get_differs $build, $cltree);
1460                 next unless $differs & D_UPS;
1461                 $read_tree_upstream->($cltree);
1462                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1463             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1464                 print "Found a general merge, will try to tidy it up.\n";
1465                 $rewriting = 1;
1466                 $read_tree_upstream->($cl->{MergeBestAnchor});
1467                 $read_tree_upstream->($cl->{MergeBestAnchor});
1468                 read_tree_debian($cltree);
1469                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1470             } elsif ($method eq 'MergeMergeSeries') {
1471                 print "Running merge resolution for $cl->{CommitId}...\n";
1472                 $build = merge_series
1473                     $build, $cl->{MergeWreckNotes},
1474                     $cl->{MergeInterchangeBaseInfo},
1475                     @{ $cl->{Parents} };
1476                 $last_anchor = $cl->{MergeBestAnchor};
1477
1478                 # Check for mismerges:
1479                 my $check = sub {
1480                     my ($against, $allow, $what) = @_;
1481                     my $differs = get_differs $build, $against;
1482                     $nomerge->(sprintf
1483        "merge misresolved: %s are not the same (%s %s d.%#x)",
1484                                $what, $against, $build, $differs)
1485                         if $differs & ~($allow | D_PAT_ADD);
1486                 };
1487
1488                 # Breakwater changes which were in each side of the
1489                 # merge will have been incorporated into the
1490                 # MergeCreateMergedBreakwaters output.  Because the
1491                 # upstream series was rebased onto the new breakwater,
1492                 # so should all of the packaging changes which were in
1493                 # the input.
1494                 $check->($input, D_UPS, 'debian files');
1495
1496                 # Upstream files are merge_series, which ought to
1497                 # have been identical to the original merge.
1498                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1499
1500                 print "Merge resolution successful.\n";
1501                 next;
1502             } else {
1503                 confess "$method ?";
1504             }
1505             if (!$rewriting) {
1506                 my $procd = (pop @processed) // 'UNDEF';
1507                 if ($cl ne $procd) {
1508                     $rewriting = 1;
1509                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1510                 }
1511             }
1512             my $newtree = cmdoutput @git, qw(write-tree);
1513             my $ch = $cl->{Hdr};
1514             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1515             $ch =~ s{^parent .*\n}{}mg;
1516             $ch =~ s{(?=^author)}{
1517                 join '', map { "parent $_\n" } @parents
1518             }me or confess "$ch ?";
1519             if ($rewriting) {
1520                 $ch =~ s{^committer .*$}{$committer_authline}m
1521                     or confess "$ch ?";
1522             }
1523             my $cf = "$rd/m$rewriting";
1524             open CD, ">", $cf or die $!;
1525             print CD $ch, "\n", $cl->{Msg} or die $!;
1526             close CD or die $!;
1527             my @cmd = (@git, qw(hash-object));
1528             push @cmd, qw(-w) if $rewriting;
1529             push @cmd, qw(-t commit), $cf;
1530             my $newcommit = cmdoutput @cmd;
1531             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1532             $build = $newcommit;
1533             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1534                 $last_anchor = $cur;
1535             }
1536         }
1537     };
1538
1539     my $final_check = get_differs $build, $input;
1540     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1541         if $final_check & ~D_PAT_ADD;
1542
1543     my @r = ($build, $breakwater, $last_anchor);
1544     printdebug "*** WALK RETURN @r\n";
1545     return @r
1546 }
1547
1548 sub get_head () {
1549     git_check_unmodified();
1550     return git_rev_parse qw(HEAD);
1551 }
1552
1553 sub update_head ($$$) {
1554     my ($old, $new, $mrest) = @_;
1555     push @deferred_updates, "update HEAD $new $old";
1556     run_deferred_updates $mrest;
1557 }
1558
1559 sub update_head_checkout ($$$) {
1560     my ($old, $new, $mrest) = @_;
1561     update_head $old, $new, $mrest;
1562     runcmd @git, qw(reset --hard);
1563 }
1564
1565 sub update_head_postlaunder ($$$) {
1566     my ($old, $tip, $reflogmsg) = @_;
1567     return if $tip eq $old;
1568     print "git-debrebase: laundered (head was $old)\n";
1569     update_head $old, $tip, $reflogmsg;
1570     # no tree changes except debian/patches
1571     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1572 }
1573
1574 sub currently_rebasing() {
1575     foreach (qw(rebase-merge rebase-apply)) {
1576         return 1 if stat_exists "$maindir_gitdir/$_";
1577     }
1578     return 0;
1579 }
1580
1581 sub bail_if_rebasing() {
1582     fail "you are in the middle of a git-rebase already"
1583         if currently_rebasing();
1584 }
1585
1586 sub do_launder_head ($) {
1587     my ($reflogmsg) = @_;
1588     my $old = get_head();
1589     record_ffq_auto();
1590     my ($tip,$breakwater) = walk $old;
1591     snags_maybe_bail();
1592     update_head_postlaunder $old, $tip, $reflogmsg;
1593     return ($tip,$breakwater);
1594 }
1595
1596 sub cmd_launder_v0 () {
1597     badusage "no arguments to launder-v0 allowed" if @ARGV;
1598     my $old = get_head();
1599     my ($tip,$breakwater,$last_anchor) = walk $old;
1600     update_head_postlaunder $old, $tip, 'launder';
1601     printf "# breakwater tip\n%s\n", $breakwater;
1602     printf "# working tip\n%s\n", $tip;
1603     printf "# last anchor\n%s\n", $last_anchor;
1604 }
1605
1606 sub defaultcmd_rebase () {
1607     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1608     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1609     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1610 }
1611
1612 sub cmd_analyse () {
1613     badusage "analyse does not support any options"
1614         if @ARGV and $ARGV[0] =~ m/^-/;
1615     badusage "too many arguments to analyse" if @ARGV>1;
1616     my ($old) = @ARGV;
1617     if (defined $old) {
1618         $old = git_rev_parse $old;
1619     } else {
1620         $old = git_rev_parse 'HEAD';
1621     }
1622     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1623     STDOUT->error and die $!;
1624 }
1625
1626 sub ffq_prev_branchinfo () {
1627     my $current = git_get_symref();
1628     return gdr_ffq_prev_branchinfo($current);
1629 }
1630
1631 sub ffq_check ($;$$) {
1632     # calls $ff and/or $notff zero or more times
1633     # then returns either (status,message) where status is
1634     #    exists
1635     #    detached
1636     #    weird-symref
1637     #    notbranch
1638     # or (undef,undef, $ffq_prev,$gdrlast)
1639     # $ff and $notff are called like this:
1640     #   $ff->("message for stdout\n");
1641     #   $notff->('snag-name', $message);
1642     # normally $currentval should be HEAD
1643     my ($currentval, $ff, $notff) =@_;
1644
1645     $ff //= sub { print $_[0] or die $!; };
1646     $notff //= \&snag;
1647
1648     my ($status, $message, $current, $ffq_prev, $gdrlast)
1649         = ffq_prev_branchinfo();
1650     return ($status, $message) unless $status eq 'branch';
1651
1652     my $exists = git_get_ref $ffq_prev;
1653     return ('exists',"$ffq_prev already exists") if $exists;
1654
1655     return ('not-branch', 'HEAD symref is not to refs/heads/')
1656         unless $current =~ m{^refs/heads/};
1657     my $branch = $';
1658
1659     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1660     my %checked;
1661
1662     printdebug "ffq check_specs @check_specs\n";
1663
1664     my $check = sub {
1665         my ($lrref, $desc) = @_;
1666         printdebug "ffq might check $lrref ($desc)\n";
1667         my $invert;
1668         for my $chk (@check_specs) {
1669             my $glob = $chk;
1670             $invert = $glob =~ s{^[!^]}{};
1671             last if fnmatch $glob, $lrref;
1672         }
1673         return if $invert;
1674         my $lrval = git_get_ref $lrref;
1675         return unless length $lrval;
1676
1677         if (is_fast_fwd $lrval, $currentval) {
1678             $ff->("OK, you are ahead of $lrref\n");
1679             $checked{$lrref} = 1;
1680         } elsif (is_fast_fwd $currentval, $lrval) {
1681             $checked{$lrref} = -1;
1682             $notff->('behind', "you are behind $lrref, divergence risk");
1683         } else {
1684             $checked{$lrref} = -1;
1685             $notff->('diverged', "you have diverged from $lrref");
1686         }
1687     };
1688
1689     my $merge = cfg "branch.$branch.merge",1;
1690     if (defined $merge and $merge =~ m{^refs/heads/}) {
1691         my $rhs = $';
1692         printdebug "ffq merge $rhs\n";
1693         my $check_remote = sub {
1694             my ($remote, $desc) = @_;
1695             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1696             return unless defined $remote;
1697             $check->("refs/remotes/$remote/$rhs", $desc);
1698         };
1699         $check_remote->((scalar cfg "branch.$branch.remote",1),
1700                         'remote fetch/merge branch');
1701         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1702                         (scalar cfg "branch.$branch.pushDefault",1),
1703                         'remote push branch');
1704     }
1705     if ($branch =~ m{^dgit/}) {
1706         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1707     } elsif ($branch =~ m{^master$}) {
1708         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1709     }
1710     return (undef, undef, $ffq_prev, $gdrlast);
1711 }
1712
1713 sub record_ffq_prev_deferred () {
1714     # => ('status', "message")
1715     # 'status' may be
1716     #    deferred          message is undef
1717     #    exists
1718     #    detached
1719     #    weird-symref
1720     #    notbranch
1721     # if not ff from some branch we should be ff from, is an snag
1722     # if "deferred", will have added something about that to
1723     #   @deferred_update_messages, and also maybe printed (already)
1724     #   some messages about ff checks
1725     bail_if_rebasing();
1726     my $currentval = get_head();
1727
1728     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1729     return ($status,$message) if defined $status;
1730
1731     snags_maybe_bail();
1732
1733     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1734     push @deferred_updates, "delete $gdrlast";
1735     push @deferred_update_messages, "Recorded previous head for preservation";
1736     return ('deferred', undef);
1737 }
1738
1739 sub record_ffq_auto () {
1740     my ($status, $message) = record_ffq_prev_deferred();
1741     if ($status eq 'deferred' || $status eq 'exists') {
1742     } else {
1743         snag $status, "could not record ffq-prev: $message";
1744         snags_maybe_bail();
1745     }
1746 }
1747
1748 sub ffq_prev_info () {
1749     bail_if_rebasing();
1750     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1751     my ($status, $message, $current, $ffq_prev, $gdrlast)
1752         = ffq_prev_branchinfo();
1753     if ($status ne 'branch') {
1754         snag $status, "could not check ffq-prev: $message";
1755         snags_maybe_bail();
1756     }
1757     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1758     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1759 }
1760
1761 sub stitch ($$$$$) {
1762     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1763
1764     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1765
1766     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1767         my $differs = get_differs $old_head, $ffq_prev_commitish;
1768         unless ($differs & ~D_PAT_ADD) {
1769             # ffq-prev is ahead of us, and the only tree changes it has
1770             # are possibly addition of things in debian/patches/.
1771             # Just wind forwards rather than making a pointless pseudomerge.
1772             push @deferred_updates,
1773                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1774             update_head_checkout $old_head, $ffq_prev_commitish,
1775                 "stitch (fast forward)";
1776             return;
1777         }
1778     }
1779     fresh_workarea();
1780     # We make pseudomerges with L as the contributing parent.
1781     # This makes git rev-list --first-parent work properly.
1782     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1783         'Declare fast forward / record previous work',
1784         "[git-debrebase pseudomerge: $prose]",
1785     ];
1786     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1787     update_head $old_head, $new_head, "stitch: $prose";
1788 }
1789
1790 sub do_stitch ($;$) {
1791     my ($prose, $unclean) = @_;
1792
1793     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1794     if (!$ffq_prev_commitish) {
1795         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1796         return;
1797     }
1798     my $dangling_head = get_head();
1799
1800     keycommits $dangling_head, $unclean,$unclean,$unclean;
1801     snags_maybe_bail();
1802
1803     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1804 }
1805
1806 sub upstream_commitish_search ($$) {
1807     my ($upstream_version, $tried) = @_;
1808     # todo: at some point maybe use git-deborig to do this
1809     foreach my $tagpfx ('', 'v', 'upstream/') {
1810         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1811         my $new_upstream = git_get_ref "refs/tags/$tag";
1812         push @$tried, $tag;
1813         return $new_upstream if length $new_upstream;
1814     }
1815 }
1816
1817 sub resolve_upstream_version ($$) {
1818     my ($new_upstream, $upstream_version) = @_;
1819
1820     if (!defined $new_upstream) {
1821         my @tried;
1822         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1823         if (!length $new_upstream) {
1824             fail "Could not determine appropriate upstream commitish.\n".
1825                 " (Tried these tags: @tried)\n".
1826                 " Check version, and specify upstream commitish explicitly.";
1827         }
1828     }
1829     $new_upstream = git_rev_parse $new_upstream;
1830
1831     return $new_upstream;
1832 }
1833
1834 sub cmd_new_upstream () {
1835     # automatically and unconditionally launders before rebasing
1836     # if rebase --abort is used, laundering has still been done
1837
1838     my %pieces;
1839
1840     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1841
1842     # parse args - low commitment
1843     my $spec_version = shift @ARGV;
1844     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1845     fail "bad version number \`$spec_version'" unless defined $new_version;
1846     if ($new_version->is_native()) {
1847         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1848     }
1849
1850     my $new_upstream = shift @ARGV;
1851     my $new_upstream_version = upstreamversion  $new_version;
1852     $new_upstream =
1853         resolve_upstream_version $new_upstream, $new_upstream_version;
1854
1855     record_ffq_auto();
1856
1857     my $piece = sub {
1858         my ($n, @x) = @_; # may be ''
1859         my $pc = $pieces{$n} //= {
1860             Name => $n,
1861             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1862         };
1863         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1864         $pc;
1865     };
1866
1867     my @newpieces;
1868     my $newpiece = sub {
1869         my ($n, @x) = @_; # may be ''
1870         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1871         push @newpieces, $pc;
1872     };
1873
1874     $newpiece->('',
1875         OldIx => 0,
1876         New => $new_upstream,
1877     );
1878     while (@ARGV && $ARGV[0] !~ m{^-}) {
1879         my $n = shift @ARGV;
1880
1881         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1882             unless @ARGV && $ARGV[0] !~ m{^-};
1883
1884         my $c = git_rev_parse shift @ARGV;
1885         die unless $n =~ m/^$extra_orig_namepart_re$/;
1886         $newpiece->($n, New => $c);
1887     }
1888
1889     # now we need to investigate the branch this generates the
1890     # laundered version but we don't switch to it yet
1891     my $old_head = get_head();
1892     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1893
1894     my $old_bw_cl = classify $old_bw;
1895     my $old_anchor_cl = classify $old_anchor;
1896     my $old_upstream;
1897     if (!$old_anchor_cl->{OrigParents}) {
1898         snag 'anchor-treated',
1899             'old anchor is recognised due to --anchor, cannot check upstream';
1900     } else {
1901         $old_upstream = parsecommit
1902             $old_anchor_cl->{OrigParents}[0]{CommitId};
1903         $piece->('', Old => $old_upstream->{CommitId});
1904     }
1905
1906     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1907         if ($old_upstream->{Msg} =~
1908  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1909            ) {
1910             my @oldpieces = (split / /, $1);
1911             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1912             if ($old_n_parents != @oldpieces &&
1913                 $old_n_parents != @oldpieces + 1) {
1914                 snag 'upstream-confusing', sprintf
1915                     "previous upstream combine %s".
1916                     " mentions %d pieces (each implying one parent)".
1917                     " but has %d parents".
1918                     " (one per piece plus maybe a previous combine)",
1919                     $old_upstream->{CommitId},
1920                     (scalar @oldpieces),
1921                     $old_n_parents;
1922             } elsif ($oldpieces[0] ne '.') {
1923                 snag 'upstream-confusing', sprintf
1924                     "previous upstream combine %s".
1925                     " first piece is not \`.'",
1926                     $oldpieces[0];
1927             } else {
1928                 $oldpieces[0] = '';
1929                 foreach my $i (0..$#oldpieces) {
1930                     my $n = $oldpieces[$i];
1931                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1932                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1933                 }
1934             }
1935         } else {
1936             snag 'upstream-confusing',
1937                 "previous upstream $old_upstream->{CommitId} is from".
1938                " git-debrebase but not an \`upstream-combine' commit";
1939         }
1940     }
1941
1942     foreach my $pc (values %pieces) {
1943         if (!$old_upstream) {
1944             # we have complained already
1945         } elsif (!$pc->{Old}) {
1946             snag 'upstream-new-piece',
1947                 "introducing upstream piece \`$pc->{Name}'";
1948         } elsif (!$pc->{New}) {
1949             snag 'upstream-rm-piece',
1950                 "dropping upstream piece \`$pc->{Name}'";
1951         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1952             snag 'upstream-not-ff',
1953                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1954         }
1955     }
1956
1957     printdebug "%pieces = ", (dd \%pieces), "\n";
1958     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1959
1960     snags_maybe_bail();
1961
1962     my $new_bw;
1963
1964     fresh_workarea();
1965     in_workarea sub {
1966         my @upstream_merge_parents;
1967
1968         if (!any_snags()) {
1969             push @upstream_merge_parents, $old_upstream->{CommitId};
1970         }
1971
1972         foreach my $pc (@newpieces) { # always has '' first
1973             if ($pc->{Name}) {
1974                 read_tree_subdir $pc->{Name}, $pc->{New};
1975             } else {
1976                 runcmd @git, qw(read-tree), $pc->{New};
1977             }
1978             push @upstream_merge_parents, $pc->{New};
1979         }
1980
1981         # index now contains the new upstream
1982
1983         if (@newpieces > 1) {
1984             # need to make the upstream subtree merge commit
1985             $new_upstream = make_commit \@upstream_merge_parents,
1986                 [ "Combine upstreams for $new_upstream_version",
1987  ("[git-debrebase upstream-combine . ".
1988  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1989  ": new upstream]"),
1990                 ];
1991         }
1992
1993         # $new_upstream is either the single upstream commit, or the
1994         # combined commit we just made.  Either way it will be the
1995         # "upstream" parent of the anchor merge.
1996
1997         read_tree_subdir 'debian', "$old_bw:debian";
1998
1999         # index now contains the anchor merge contents
2000         $new_bw = make_commit [ $old_bw, $new_upstream ],
2001             [ "Update to upstream $new_upstream_version",
2002  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2003             ];
2004
2005         my $clogsignoff = cmdoutput qw(git show),
2006             '--pretty=format:%an <%ae>  %aD',
2007             $new_bw;
2008
2009         # Now we have to add a changelog stanza so the Debian version
2010         # is right.
2011         die if unlink "debian";
2012         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2013         unlink "debian/changelog" or $!==ENOENT or die $!;
2014         mkdir "debian" or die $!;
2015         open CN, ">", "debian/changelog" or die $!;
2016         my $oldclog = git_cat_file ":debian/changelog";
2017         $oldclog =~ m/^($package_re) \(\S+\) / or
2018             fail "cannot parse old changelog to get package name";
2019         my $p = $1;
2020         print CN <<END, $oldclog or die $!;
2021 $p ($new_version) UNRELEASED; urgency=medium
2022
2023   * Update to new upstream version $new_upstream_version.
2024
2025  -- $clogsignoff
2026
2027 END
2028         close CN or die $!;
2029         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2030
2031         # Now we have the final new breakwater branch in the index
2032         $new_bw = make_commit [ $new_bw ],
2033             [ "Update changelog for new upstream $new_upstream_version",
2034               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2035             ];
2036     };
2037
2038     # we have constructed the new breakwater. we now need to commit to
2039     # the laundering output, because git-rebase can't easily be made
2040     # to make a replay list which is based on some other branch
2041
2042     update_head_postlaunder $old_head, $old_laundered_tip,
2043         'launder for new upstream';
2044
2045     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2046     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2047         "debrebase new-upstream $new_version: rebase";
2048     runcmd @cmd;
2049     # now it's for the user to sort out
2050 }
2051
2052 sub cmd_record_ffq_prev () {
2053     badusage "no arguments allowed" if @ARGV;
2054     my ($status, $msg) = record_ffq_prev_deferred();
2055     if ($status eq 'exists' && $opt_noop_ok) {
2056         print "Previous head already recorded\n" or die $!;
2057     } elsif ($status eq 'deferred') {
2058         run_deferred_updates 'record-ffq-prev';
2059     } else {
2060         fail "Could not preserve: $msg";
2061     }
2062 }
2063
2064 sub cmd_anchor () {
2065     badusage "no arguments allowed" if @ARGV;
2066     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2067     print "$bw\n" or die $!;
2068 }
2069
2070 sub cmd_breakwater () {
2071     badusage "no arguments allowed" if @ARGV;
2072     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2073     print "$bw\n" or die $!;
2074 }
2075
2076 sub cmd_status () {
2077     badusage "no arguments allowed" if @ARGV;
2078
2079     # todo: gdr status should print divergence info
2080     # todo: gdr status should print upstream component(s) info
2081     # todo: gdr should leave/maintain some refs with this kind of info ?
2082
2083     my $oldest = { Badness => 0 };
2084     my $newest;
2085     my $note = sub {
2086         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2087         if ($oldest->{Badness} < $badness) {
2088             $oldest = $newest = undef;
2089         }
2090         $oldest = {
2091                    Badness => $badness,
2092                    CommitId => $cl->{CommitId},
2093                    OurMsg => $ourmsg,
2094                    KcMsg => $kcmsg,
2095                   };
2096         $newest //= $oldest;
2097     };
2098     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2099         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2100         sub { $note->(2, 'branch is unlaundered', @_); },
2101         sub { $note->(3, 'branch needs laundering', @_); },
2102         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2103
2104     my $prcommitinfo = sub {
2105         my ($cid) = @_;
2106         flush STDOUT or die $!;
2107         runcmd @git, qw(--no-pager log -n1),
2108             '--pretty=format:    %h %s%n',
2109             $cid;
2110     };
2111
2112     print "current branch contents, in git-debrebase terms:\n";
2113     if (!$oldest->{Badness}) {
2114         print "  branch is laundered\n";
2115     } else {
2116         print "  $oldest->{OurMsg}\n";
2117         my $printed = '';
2118         foreach my $info ($oldest, $newest) {
2119             my $cid = $info->{CommitId};
2120             next if $cid eq $printed;
2121             $printed = $cid;
2122             print "  $info->{KcMsg}\n";
2123             $prcommitinfo->($cid);
2124         }
2125     }
2126
2127     my $prab = sub {
2128         my ($cid, $what) = @_;
2129         if (!defined $cid) {
2130             print "  $what is not well-defined\n";
2131         } else {
2132             print "  $what\n";
2133             $prcommitinfo->($cid);
2134         }
2135     };
2136     print "key git-debrebase commits:\n";
2137     $prab->($anchor, 'anchor');
2138     $prab->($bw, 'breakwater');
2139
2140     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2141         ffq_prev_branchinfo();
2142
2143     print "branch and ref status, in git-debrebase terms:\n";
2144     if ($ffq_msg) {
2145         print "  $ffq_msg\n";
2146     } else {
2147         $ffq_prev = git_get_ref $ffq_prev;
2148         $gdrlast = git_get_ref $gdrlast;
2149         if ($ffq_prev) {
2150             print "  unstitched; previous tip was:\n";
2151             $prcommitinfo->($ffq_prev);
2152         } elsif (!$gdrlast) {
2153             print "  stitched? (no record of git-debrebase work)\n";
2154         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2155             print "  stitched\n";
2156         } else {
2157             print "  not git-debrebase (diverged since last stitch)\n"
2158         }
2159     }
2160     print "you are currently rebasing\n" if currently_rebasing();
2161 }
2162
2163 sub cmd_stitch () {
2164     my $prose = 'stitch';
2165     getoptions("stitch",
2166                'prose=s', \$prose);
2167     badusage "no arguments allowed" if @ARGV;
2168     do_stitch $prose, 0;
2169 }
2170 sub cmd_prepush () { cmd_stitch(); }
2171
2172 sub cmd_quick () {
2173     badusage "no arguments allowed" if @ARGV;
2174     do_launder_head 'launder for git-debrebase quick';
2175     do_stitch 'quick';
2176 }
2177
2178 sub cmd_conclude () {
2179     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2180     if (!$ffq_prev_commitish) {
2181         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2182         return;
2183     }
2184     my $dangling_head = get_head();
2185
2186     badusage "no arguments allowed" if @ARGV;
2187     do_launder_head 'launder for git-debrebase quick';
2188     do_stitch 'quick';
2189 }
2190
2191 sub cmd_scrap () {
2192     if (currently_rebasing()) {
2193         runcmd @git, qw(rebase --abort);
2194     }
2195     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2196     if (!$ffq_prev_commitish) {
2197         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2198         finish 0;
2199     }
2200     my $scrapping_head = get_head();
2201     badusage "no arguments allowed" if @ARGV;
2202     push @deferred_updates,
2203         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2204         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2205     snags_maybe_bail();
2206     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2207 }
2208
2209 sub make_patches_staged ($) {
2210     my ($head) = @_;
2211     # Produces the patches that would result from $head if it were
2212     # laundered.
2213     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2214     fresh_workarea();
2215     in_workarea sub {
2216         gbp_pq_export 'bw', $secret_bw, $secret_head;
2217     };
2218 }
2219
2220 sub make_patches ($) {
2221     my ($head) = @_;
2222     keycommits $head, 0, \&snag;
2223     make_patches_staged $head;
2224     my $out;
2225     in_workarea sub {
2226         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2227         runcmd @git, qw(read-tree), $head;
2228         read_tree_subdir 'debian/patches', $ptree;
2229         $out = make_commit [$head], [
2230             'Commit patch queue (exported by git-debrebase)',
2231             '[git-debrebase: export and commit patches]',
2232         ];
2233     };
2234     return $out;
2235 }
2236
2237 sub cmd_make_patches () {
2238     my $opt_quiet_would_amend;
2239     getoptions("make-patches",
2240                'quiet-would-amend!', \$opt_quiet_would_amend);
2241     badusage "no arguments allowed" if @ARGV;
2242     bail_if_rebasing();
2243     my $old_head = get_head();
2244     my $new = make_patches $old_head;
2245     my $d = get_differs $old_head, $new;
2246     if ($d == 0) {
2247         fail "No (more) patches to export." unless $opt_noop_ok;
2248         return;
2249     } elsif ($d == D_PAT_ADD) {
2250         snags_maybe_bail();
2251         update_head_checkout $old_head, $new, 'make-patches';
2252     } else {
2253         print STDERR failmsg
2254             "Patch export produced patch amendments".
2255             " (abandoned output commit $new).".
2256             "  Try laundering first."
2257             unless $opt_quiet_would_amend;
2258         finish 7;
2259     }
2260 }
2261
2262 sub cmd_convert_from_gbp () {
2263     badusage "want only 1 optional argument, the upstream git commitish"
2264         unless @ARGV<=1;
2265
2266     my $clogp = parsechangelog();
2267     my $version = $clogp->{'Version'}
2268         // die "missing Version from changelog";
2269
2270     my ($upstream_spec) = @ARGV;
2271
2272     my $upstream_version = upstreamversion $version;
2273     my $upstream =
2274         resolve_upstream_version($upstream_spec, $upstream_version);
2275
2276     my $old_head = get_head();
2277
2278     my $upsdiff = get_differs $upstream, $old_head;
2279     if ($upsdiff & D_UPS) {
2280         runcmd @git, qw(--no-pager diff --stat),
2281             $upstream, $old_head,
2282             qw( -- :!/debian :/);
2283         fail <<END;
2284 upstream ($upstream_spec) and HEAD are not
2285 identical in upstream files.  See diffstat above, or run
2286   git diff $upstream_spec HEAD -- :!/debian :/
2287 END
2288     }
2289
2290     if (!is_fast_fwd $upstream, $old_head) {
2291         snag 'upstream-not-ancestor',
2292             "upstream ($upstream) is not an ancestor of HEAD";
2293     } else {
2294         my $wrong = cmdoutput
2295             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2296              qw(-- :/ :!/debian));
2297         if (length $wrong) {
2298             snag 'unexpected-upstream-changes',
2299                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2300             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2301         }
2302     }
2303
2304     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2305         snag 'upstream-has-debian',
2306             "upstream ($upstream) contains debian/ directory";
2307     }
2308
2309     my $previous_dgit_view = eval {
2310         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2311         my ($lvsn, $suite);
2312         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2313             my ($stz, $desc) = @_;
2314             no warnings qw(exiting);
2315             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2316             next unless $stz->{Date};
2317             next unless $stz->{Distribution} ne 'UNRELEASED';
2318             $lvsn = $stz->{Version};
2319             $suite = $stz->{Distribution};
2320             last;
2321         };
2322         die "neither of the first two changelog entries are released\n"
2323             unless defined $lvsn;
2324         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2325         my $mtag_pat = debiantag_maintview $lvsn, '*';
2326         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2327             $mtag_pat;
2328         die "could not find suitable maintainer view tag $mtag_pat\n"
2329             unless $mtag_pat =~ m{/};
2330         is_fast_fwd $mtag, 'HEAD' or
2331             die "HEAD is not FF from maintainer tag $mtag!";
2332         my $dtag = "archive/$mtag";
2333         is_fast_fwd $mtag, $dtag or
2334             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2335         print "will stitch in dgit view, $dtag\n";
2336         git_rev_parse $dtag;
2337     };
2338     if (!$previous_dgit_view) {
2339         $@ =~ s/^\n+//;
2340         chomp $@;
2341         print STDERR "cannot stitch in dgit view: $@\n";
2342     }
2343
2344     snags_maybe_bail_early();
2345
2346     my $work;
2347
2348     fresh_workarea();
2349     in_workarea sub {
2350         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2351         # make a branch out of the patch queue - we'll want this in a mo
2352         runcmd qw(gbp pq import);
2353         # strip the patches out
2354         runcmd @git, qw(checkout -q gdr-internal~0);
2355         rm_subdir_cached 'debian/patches';
2356         $work = make_commit ['HEAD'], [
2357  'git-debrebase convert-from-gbp: drop patches from tree',
2358  'Delete debian/patches, as part of converting to git-debrebase format.',
2359  '[git-debrebase convert-from-gbp: drop patches from tree]'
2360                               ];
2361         # make the anchor merge
2362         # the tree is already exactly right
2363         $work = make_commit [$work, $upstream], [
2364  'git-debrebase import: declare upstream',
2365  'First breakwater merge.',
2366  '[git-debrebase anchor: declare upstream]'
2367                               ];
2368
2369         # rebase the patch queue onto the new breakwater
2370         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2371         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2372         $work = git_rev_parse 'HEAD';
2373
2374         if ($previous_dgit_view) {
2375             $work = make_commit [$work, $previous_dgit_view], [
2376  'git-debrebase import: declare ff from dgit archive view',
2377  '[git-debrebase pseudomerge: import-from-gbp]',
2378             ];
2379         }
2380     };
2381
2382     ffq_check $work;
2383     snags_maybe_bail();
2384     update_head_checkout $old_head, $work, 'convert-from-gbp';
2385 }
2386
2387 sub cmd_convert_to_gbp () {
2388     badusage "no arguments allowed" if @ARGV;
2389     my $head = get_head();
2390     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2391     keycommits $head, 0;
2392     my $out;
2393     make_patches_staged $head;
2394     in_workarea sub {
2395         $out = make_commit ['HEAD'], [
2396             'Commit patch queue (converted from git-debrebase format)',
2397             '[git-debrebase convert-to-gbp: commit patches]',
2398         ];
2399     };
2400     if (defined $ffq) {
2401         push @deferred_updates, "delete $ffq";
2402         push @deferred_updates, "delete $gdrlast";
2403     }
2404     snags_maybe_bail();
2405     update_head_checkout $head, $out, "convert to gbp (v0)";
2406     print <<END or die $!;
2407 git-debrebase: converted to git-buildpackage branch format
2408 git-debrebase: WARNING: do not now run "git-debrebase" any more
2409 git-debrebase: WARNING: doing so would drop all upstream patches!
2410 END
2411 }
2412
2413 sub cmd_convert_from_dgit_view () {
2414     my $clogp = parsechangelog();
2415
2416     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2417     my $do_origs = 1;
2418     my $do_tags = 1;
2419     my $always = 0;
2420     my $diagnose = 0;
2421
2422     getoptions("convert-from-dgit-view",
2423                'diagnose!', \$diagnose,
2424                'build-products-dir:s', \$bpd,
2425                'origs!', \$do_origs,
2426                'tags!', \$do_tags,
2427                'always-convert-anyway!', \$always);
2428     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2429
2430     my @upstreams;
2431
2432     if (@ARGV) {
2433         my $spec = shift @ARGV;
2434         my $commit = git_rev_parse "$spec^{commit}";
2435         push @upstreams, { Commit => $commit,
2436                            Source => "$ARGV[0], from command line",
2437                            Only => 1,
2438                          };
2439     }
2440
2441     my $head = get_head();
2442
2443     if (!$always) {
2444         my $troubles = 0;
2445         my $trouble = sub { $troubles++; };
2446         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2447         printdebug "troubles=$troubles\n";
2448         if (!$troubles) {
2449             print STDERR <<END;
2450 $us: Branch already seems to be in git-debrebase format!
2451 $us: --always-convert-anyway would do the conversion operation anyway
2452 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2453 END
2454             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2455             finish 0;
2456         }
2457     }
2458
2459     snags_maybe_bail_early();
2460
2461     my $version = upstreamversion $clogp->{Version};
2462     print STDERR "Considering possible commits corresponding to upstream:\n";
2463
2464     if (!@upstreams) {
2465         if ($do_tags) {
2466             my @tried;
2467             my $ups_tag = upstream_commitish_search $version, \@tried;
2468             if ($ups_tag) {
2469                 my $this = "git tag $tried[-1]";
2470                 push @upstreams, { Commit => $ups_tag,
2471                                    Source => $this,
2472                                  };
2473             } else {
2474                 printf STDERR
2475                     " git tag: no suitable tag found (tried %s)\n",
2476                     "@tried";
2477             }
2478         }
2479         if ($do_origs) {
2480             my $p = $clogp->{'Source'};
2481             # we do a quick check to see if there are plausible origs
2482             my $something=0;
2483             if (!opendir BPD, $bpd) {
2484                 die "$bpd: opendir: $!" unless $!==ENOENT;
2485             } else {
2486                 while ($!=0, my $f = readdir BPD) {
2487                     next unless is_orig_file_of_p_v $f, $p, $version;
2488                     printf STDERR
2489                         " orig: found what looks like a .orig, %s\n",
2490                         "$bpd/$f";
2491                     $something=1;
2492                     last;
2493                 }
2494                 die "read $bpd: $!" if $!;
2495                 closedir BPD;
2496             }
2497             if ($something) {
2498                 my $tree = cmdoutput
2499                     @dgit, qw(--build-products-dir), $bpd,
2500                     qw(print-unapplied-treeish);
2501                 fresh_workarea();
2502                 in_workarea sub {
2503                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2504                     rm_subdir_cached 'debian';
2505                     $tree = cmdoutput @git, qw(write-tree);
2506                     my $ups_synth = make_commit [], [ <<END, <<END,
2507 Import effective orig tree for upstream version $version
2508 END
2509 This includes the contents of the .orig(s), minus any debian/ directory.
2510
2511 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2512 END
2513                                                     ];
2514                     push @upstreams, { Commit => $ups_synth,
2515                                        Source => "orig(s) imported via dgit",
2516                                      };
2517                 }
2518             } else {
2519                 printf STDERR
2520                     " orig: no suitable origs found (looked for %s in %s)\n",
2521                     "${p}_".(stripeoch $version)."...", $bpd;
2522             }
2523         }
2524     }
2525
2526     my $some_patches = stat_exists 'debian/patches/series';
2527
2528     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2529
2530     my $result;
2531     foreach my $u (@upstreams) {
2532         my $work = $head;
2533         fresh_workarea();
2534         in_workarea sub {
2535             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2536             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2537             runcmd @git, qw(clean -xdff);
2538             runcmd @git, qw(checkout), $head, qw(-- debian);
2539             if ($some_patches) {
2540                 rm_subdir_cached 'debian/patches';
2541                 $work = make_commit [ $work ], [
2542  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2543  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2544  "to git-debrebase format.  Upstream changes will appear as commits.",
2545  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2546                                            ];
2547             }
2548             $work = make_commit [ $work, $u->{Commit} ], [
2549  'git-debrebase convert-from-dgit-view: declare upstream',
2550  '(Re)constructed breakwater merge.',
2551  '[git-debrebase anchor: declare upstream]'
2552                                                          ];
2553             runcmd @git, qw(checkout --quiet -b mk), $work;
2554             if ($some_patches) {
2555                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2556                 runcmd @git, qw(reset --quiet);
2557                 my @gbp_cmd = (qw(gbp pq import));
2558                 if (!$diagnose) {
2559                     my $gbp_err = "../gbp-pq-err";
2560                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2561                 }
2562                 my $r = system @gbp_cmd;
2563                 if ($r) {
2564                     printf STDERR
2565                         " %s: couldn't apply patches: gbp pq %s",
2566                         $u->{Source}, waitstatusmsg();
2567                     return;
2568                 }
2569             }
2570             my $work = git_rev_parse qw(HEAD);
2571             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2572             if (length $diffout) {
2573                 print STDERR
2574                     " $u->{Source}: applying patches gives different tree\n";
2575                 print STDERR $diffout if $diagnose;
2576                 return;
2577             }
2578             # OMG!
2579             $u->{Result} = $work;
2580             $result = $u;
2581         };
2582         last if $result;
2583     }
2584
2585     if (!$result) {
2586         fail <<END;
2587 Could not find or construct a suitable upstream commit.
2588 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2589 upstream commmit explicitly or provide suitable origs.
2590 END
2591     }
2592
2593     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2594
2595     ffq_check $result->{Result};
2596     snags_maybe_bail();
2597     update_head_checkout $head, $result->{Result},
2598         'convert-from-dgit-view';
2599 }
2600
2601 sub cmd_downstream_rebase_launder_v0 () {
2602     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2603     my ($base) = @ARGV;
2604     $base = git_rev_parse $base;
2605     my $old_head = get_head();
2606     my $current = $old_head;
2607     my $topmost_keep;
2608     for (;;) {
2609         if ($current eq $base) {
2610             $topmost_keep //= $current;
2611             print " $current BASE stop\n";
2612             last;
2613         }
2614         my $cl = classify $current;
2615         print " $current $cl->{Type}";
2616         my $keep = 0;
2617         my $p0 = $cl->{Parents}[0]{CommitId};
2618         my $next;
2619         if ($cl->{Type} eq 'Pseudomerge') {
2620             print " ^".($cl->{Contributor}{Ix}+1);
2621             $next = $cl->{Contributor}{CommitId};
2622         } elsif ($cl->{Type} eq 'AddPatches' or
2623                  $cl->{Type} eq 'Changelog') {
2624             print " strip";
2625             $next = $p0;
2626         } else {
2627             print " keep";
2628             $next = $p0;
2629             $keep = 1;
2630         }
2631         print "\n";
2632         if ($keep) {
2633             $topmost_keep //= $current;
2634         } else {
2635             die "to-be stripped changes not on top of the branch\n"
2636                 if $topmost_keep;
2637         }
2638         $current = $next;
2639     }
2640     if ($topmost_keep eq $old_head) {
2641         print "unchanged\n";
2642     } else {
2643         print "updating to $topmost_keep\n";
2644         update_head_checkout
2645             $old_head, $topmost_keep,
2646             'downstream-rebase-launder-v0';
2647     }
2648 }
2649
2650 getoptions_main
2651           ("bad options\n",
2652            "D+" => \$debuglevel,
2653            'noop-ok', => \$opt_noop_ok,
2654            'f=s' => \@snag_force_opts,
2655            'anchor=s' => \@opt_anchors,
2656            '--dgit=s' => \($dgit[0]),
2657            'force!',
2658            '-i:s' => sub {
2659                my ($opt,$val) = @_;
2660                badusage "git-debrebase: no cuddling to -i for git-rebase"
2661                    if length $val;
2662                die if $opt_defaultcmd_interactive; # should not happen
2663                $opt_defaultcmd_interactive = [ qw(-i) ];
2664                # This access to @ARGV is excessive familiarity with
2665                # Getopt::Long, but there isn't another sensible
2666                # approach.  '-i=s{0,}' does not work with bundling.
2667                push @$opt_defaultcmd_interactive, @ARGV;
2668                @ARGV=();
2669            },
2670            'help' => sub { print $usage_message or die $!; finish 0; },
2671            );
2672
2673 initdebug('git-debrebase ');
2674 enabledebug if $debuglevel;
2675
2676 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2677 chdir $toplevel or die "chdir $toplevel: $!";
2678
2679 $rd = fresh_playground "$playprefix/misc";
2680
2681 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2682
2683 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2684     defaultcmd_rebase();
2685 } else {
2686     my $cmd = shift @ARGV;
2687     my $cmdfn = $cmd;
2688     $cmdfn =~ y/-/_/;
2689     $cmdfn = ${*::}{"cmd_$cmdfn"};
2690
2691     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2692     $cmdfn->();
2693 }
2694
2695 finish 0;