git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23
  24 use strict;
  25
  26 use Debian::Dgit qw(:DEFAULT :playground);
  27 setup_sigwarn();
  28
  29 use Memoize;
  30 use Carp;
  31 use POSIX;
  32 use Data::Dumper;
  33 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  34 use Dpkg::Version;
  35 use File::FnMatch qw(:fnmatch);
  36
  37 our ($opt_force, $opt_noop_ok, @opt_anchors);
  38 our ($opt_defaultcmd_interactive);
  39
  40 our $us = qw(git-debrebase);
  41
  42 sub badusage ($) {
  43     my ($m) = @_;
  44     print STDERR "bad usage: $m\n";
  45     finish 8;
  46 }
  47
  48 sub cfg ($;$) {
  49     my ($k, $optional) = @_;
  50     local $/ = "\0";
  51     my @cmd = qw(git config -z);
  52     push @cmd, qw(--get-all) if wantarray;
  53     push @cmd, $k;
  54     my $out = cmdoutput_errok @cmd;
  55     if (!defined $out) {
  56         fail "missing required git config $k" unless $optional;
  57         return ();
  58     }
  59     my @l = split /\0/, $out;
  60     return wantarray ? @l : $l[0];
  61 }
  62
  63 memoize('cfg');
  64
  65 sub dd ($) {
  66     my ($v) = @_;
  67     my $dd = new Data::Dumper [ $v ];
  68     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  69     return Dump $dd;
  70 }
  71
  72 sub get_commit ($) {
  73     my ($objid) = @_;
  74     my $data = (git_cat_file $objid, 'commit');
  75     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
  76     return ($`,$');
  77 }
  78
  79 sub D_UPS ()      { 0x02; } # upstream files
  80 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
  81 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
  82 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
  83 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
  84 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
  85
  86 our $playprefix = 'debrebase';
  87 our $rd;
  88 our $workarea;
  89
  90 our @git = qw(git);
  91
  92 sub in_workarea ($) {
  93     my ($sub) = @_;
  94     changedir $workarea;
  95     my $r = eval { $sub->(); };
  96     { local $@; changedir $maindir; }
  97     die $@ if $@;
  98 }
  99
 100 sub fresh_workarea () {
 101     $workarea = fresh_playground "$playprefix/work";
 102     in_workarea sub { playtree_setup };
 103 }
 104
 105 our $snags_forced = 0;
 106 our $snags_tripped = 0;
 107 our $snags_summarised = 0;
 108 our @deferred_updates;
 109 our @deferred_update_messages;
 110
 111 sub all_snags_summarised () {
 112     $snags_forced + $snags_tripped == $snags_summarised;
 113 }
 114 sub run_deferred_updates ($) {
 115     my ($mrest) = @_;
 116
 117     confess 'dangerous internal error' unless all_snags_summarised();
 118
 119     my @upd_cmd = (@git, qw(update-ref --stdin -m), "debrebase: $mrest");
 120     debugcmd '>|', @upd_cmd;
 121     open U, "|-", @upd_cmd or die $!;
 122     foreach (@deferred_updates) {
 123         printdebug ">= ", $_, "\n";
 124         print U $_, "\n" or die $!;
 125     }
 126     printdebug ">\$\n";
 127     close U or failedcmd @upd_cmd;
 128
 129     print $_, "\n" foreach @deferred_update_messages;
 130
 131     @deferred_updates = ();
 132     @deferred_update_messages = ();
 133 }
 134
 135 sub get_differs ($$) {
 136     my ($x,$y) = @_;
 137     # This resembles quiltify_trees_differ, in dgit, a bit.
 138     # But we don't care about modes, or dpkg-source-unrepresentable
 139     # changes, and we don't need the plethora of different modes.
 140     # Conversely we need to distinguish different kinds of changes to
 141     # debian/ and debian/patches/.
 142
 143     my $differs = 0;
 144
 145     my $rundiff = sub {
 146         my ($opts, $limits, $fn) = @_;
 147         my @cmd = (@git, qw(diff-tree -z --no-renames));
 148         push @cmd, @$opts;
 149         push @cmd, "$_:" foreach $x, $y;
 150         push @cmd, '--', @$limits;
 151         my $diffs = cmdoutput @cmd;
 152         foreach (split /\0/, $diffs) { $fn->(); }
 153     };
 154
 155     $rundiff->([qw(--name-only)], [], sub {
 156         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 157     });
 158
 159     if ($differs & DS_DEB) {
 160         $differs &= ~DS_DEB;
 161         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 162             $differs |=
 163                 m{^debian/patches/}      ? D_PAT_OTH  :
 164                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 165                                            D_DEB_OTH;
 166         });
 167         die "mysterious debian changes $x..$y"
 168             unless $differs & (D_PAT_OTH|DS_DEB);
 169     }
 170
 171     if ($differs & D_PAT_OTH) {
 172         my $mode;
 173         $differs &= ~D_PAT_OTH;
 174         my $pat_oth = sub {
 175             $differs |= D_PAT_OTH;
 176             no warnings qw(exiting);  last;
 177         };
 178         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 179             no warnings qw(exiting);
 180             if (!defined $mode) {
 181                 $mode = $_;  next;
 182             }
 183             die unless s{^debian/patches/}{};
 184             my $ok;
 185             if ($mode eq 'A' && !m/\.series$/s) {
 186                 $ok = 1;
 187             } elsif ($mode eq 'M' && $_ eq 'series') {
 188                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 189                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 190                 chomp $x_s;  $x_s .= "\n";
 191                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 192             } else {
 193                 # nope
 194             }
 195             $mode = undef;
 196             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 197         });
 198         die "mysterious debian/patches changes $x..$y"
 199             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 200     }
 201
 202     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 203
 204     return $differs;
 205 }
 206
 207 sub commit_pr_info ($) {
 208     my ($r) = @_;
 209     return Data::Dumper->dump([$r], [qw(commit)]);
 210 }
 211
 212 sub calculate_committer_authline () {
 213     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 214         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 215     my ($h,$m) = get_commit $c;
 216     $h =~ m/^committer .*$/m or confess "($h) ?";
 217     return $&;
 218 }
 219
 220 sub rm_subdir_cached ($) {
 221     my ($subdir) = @_;
 222     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 223 }
 224
 225 sub read_tree_subdir ($$) {
 226     my ($subdir, $new_tree_object) = @_;
 227     rm_subdir_cached $subdir;
 228     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 229 }
 230
 231 sub make_commit ($$) {
 232     my ($parents, $message_paras) = @_;
 233     my $tree = cmdoutput @git, qw(write-tree);
 234     my @cmd = (@git, qw(commit-tree), $tree);
 235     push @cmd, qw(-p), $_ foreach @$parents;
 236     push @cmd, qw(-m), $_ foreach @$message_paras;
 237     return cmdoutput @cmd;
 238 }
 239
 240 our @snag_force_opts;
 241 sub snag ($$) {
 242     my ($tag,$msg) = @_;
 243     if (grep { $_ eq $tag } @snag_force_opts) {
 244         $snags_forced++;
 245         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 246     } else {
 247         $snags_tripped++;
 248         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 249     }
 250 }
 251
 252 # Important: all mainline code must call snags_maybe_bail after
 253 # any point where snag might be called, but before making changes
 254 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 255 # may be called more than once if necessary (but this is not ideal
 256 # because then the messages about number of snags may be confusing).
 257 sub snags_maybe_bail () {
 258     return if all_snags_summarised();
 259     if ($snags_forced) {
 260         printf STDERR
 261             "%s: snags: %d overriden by individual -f options\n",
 262             $us, $snags_forced;
 263     }
 264     if ($snags_tripped) {
 265         if ($opt_force) {
 266             printf STDERR
 267                 "%s: snags: %d overriden by global --force\n",
 268                 $us, $snags_tripped;
 269         } else {
 270             fail sprintf
 271   "%s: snags: %d blockers (you could -f<tag>, or --force)",
 272                 $us, $snags_tripped;
 273         }
 274     }
 275     $snags_summarised = $snags_forced + $snags_tripped;
 276 }
 277 sub any_snags () {
 278     return $snags_forced || $snags_tripped;
 279 }
 280
 281 # classify returns an info hash like this
 282 #   CommitId => $objid
 283 #   Hdr => # commit headers, including 1 final newline
 284 #   Msg => # commit message (so one newline is dropped)
 285 #   Tree => $treeobjid
 286 #   Type => (see below)
 287 #   Parents = [ {
 288 #       Ix => $index # ie 0, 1, 2, ...
 289 #       CommitId
 290 #       Differs => return value from get_differs
 291 #       IsOrigin
 292 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 293 #     } ...]
 294 #   NewMsg => # commit message, but with any [dgit import ...] edited
 295 #             # to say "[was: ...]"
 296 #
 297 # Types:
 298 #   Packaging
 299 #   Changelog
 300 #   Upstream
 301 #   AddPatches
 302 #   Mixed
 303 #
 304 #   Pseudomerge
 305 #     has additional entres in classification result
 306 #       Overwritten = [ subset of Parents ]
 307 #       Contributor = $the_remaining_Parent
 308 #
 309 #   DgitImportUnpatched
 310 #     has additional entry in classification result
 311 #       OrigParents = [ subset of Parents ]
 312 #
 313 #   Anchor
 314 #     has additional entry in classification result
 315 #       OrigParents = [ subset of Parents ]  # singleton list
 316 #
 317 #   TreatAsAnchor
 318 #
 319 #   BreakwaterStart
 320 #
 321 #   Unknown
 322 #     has additional entry in classification result
 323 #       Why => "prose"
 324
 325 sub parsecommit ($;$) {
 326     my ($objid, $p_ref) = @_;
 327     # => hash with                   CommitId Hdr Msg Tree Parents
 328     #    Parents entries have only   Ix CommitId
 329     #    $p_ref, if provided, must be [] and is used as a base for Parents
 330
 331     $p_ref //= [];
 332     die if @$p_ref;
 333
 334     my ($h,$m) = get_commit $objid;
 335
 336     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 337     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 338
 339     my $r = {
 340         CommitId => $objid,
 341         Hdr => $h,
 342         Msg => $m,
 343         Tree => $t,
 344         Parents => $p_ref,
 345     };
 346
 347     foreach my $ph (@ph) {
 348         push @$p_ref, {
 349             Ix => scalar @$p_ref,
 350             CommitId => $ph,
 351         };
 352     }
 353
 354     return $r;
 355 }
 356
 357 sub classify ($) {
 358     my ($objid) = @_;
 359
 360     my @p;
 361     my $r = parsecommit($objid, \@p);
 362     my $t = $r->{Tree};
 363
 364     foreach my $p (@p) {
 365         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 366     }
 367
 368     printdebug "classify $objid \$t=$t \@p",
 369         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 370         "\n";
 371
 372     my $classify = sub {
 373         my ($type, @rest) = @_;
 374         $r = { %$r, Type => $type, @rest };
 375         if ($debuglevel) {
 376             printdebug " = $type ".(dd $r)."\n";
 377         }
 378         return $r;
 379     };
 380     my $unknown = sub {
 381         my ($why) = @_;
 382         $r = { %$r, Type => qw(Unknown), Why => $why };
 383         printdebug " ** Unknown\n";
 384         return $r;
 385     };
 386
 387     if (grep { $_ eq $objid } @opt_anchors) {
 388         return $classify->('TreatAsAnchor');
 389     }
 390
 391     my @identical = grep { !$_->{Differs} } @p;
 392     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 393     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 394
 395     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 396         # multi-orig upstreams are represented with an anchor merge
 397         # from a single upstream commit which combines the orig tarballs
 398
 399         # Every anchor tagged this way must be a merge.
 400         # We are relying on the
 401         #     [git-debrebase anchor: ...]
 402         # commit message annotation in "declare" anchor merges (which
 403         # do not have any upstream changes), to distinguish those
 404         # anchor merges from ordinary pseudomerges (which we might
 405         # just try to strip).
 406         #
 407         # However, the user is going to be doing git-rebase a lot.  We
 408         # really don't want them to rewrite an anchor commit.
 409         # git-rebase trips up on merges, so that is a useful safety
 410         # catch.
 411         #
 412         # BreakwaterStart commits are also anchors in the terminology
 413         # of git-debrebase(5), but they are untagged (and always
 414         # manually generated).
 415         #
 416         # We cannot not tolerate any tagged linear commit (ie,
 417         # BreakwaterStart commits tagged `[anchor:') because such a
 418         # thing could result from an erroneous linearising raw git
 419         # rebase of a merge anchor.  That would represent a corruption
 420         # of the branch. and we want to detect and reject the results
 421         # of such corruption before it makes it out anywhere.  If we
 422         # reject it here then we avoid making the pseudomerge which
 423         # would be needed to push it.
 424
 425         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 426         @p == 2 or return $badanchor->("has other than two parents");
 427         $haspatches and return $badanchor->("contains debian/patches");
 428
 429         # How to decide about l/r ordering of anchors ?  git
 430         # --topo-order prefers to expand 2nd parent first.  There's
 431         # already an easy rune to look for debian/ history anyway (git log
 432         # debian/) so debian breakwater branch should be 1st parent; that
 433         # way also there's also an easy rune to look for the upstream
 434         # patches (--topo-order).
 435
 436         # Also this makes --first-parent be slightly more likely to
 437         # be useful - it makes it provide a linearised breakwater history.
 438
 439         # Of course one can say somthing like
 440         #  gitk -- ':/' ':!/debian'
 441         # to get _just_ the commits touching upstream files, and by
 442         # the TREESAME logic in git-rev-list this will leave the
 443         # breakwater into upstream at the first anchor.  But that
 444         # doesn't report debian/ changes at all.
 445
 446         # Other observations about gitk: by default, gitk seems to
 447         # produce output in a different order to git-rev-list.  I
 448         # can't seem to find this documented anywhere.  gitk
 449         # --date-order DTRT.  But, gitk always seems to put the
 450         # parents from left to right, in order, so it's easy to see
 451         # which way round a pseudomerge is.
 452
 453         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 454         $p[1]{Differs} & ~DS_DEB and
 455             $badanchor->("upstream files differ from left parent");
 456         $p[0]{Differs} & ~D_UPS and
 457             $badanchor->("debian/ differs from right parent");
 458
 459         return $classify->(qw(Anchor),
 460                            OrigParents => [ $p[1] ]);
 461     }
 462
 463     if (@p == 1) {
 464         my $d = $r->{Parents}[0]{Differs};
 465         if ($d == D_PAT_ADD) {
 466             return $classify->(qw(AddPatches));
 467         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 468             return $unknown->("edits debian/patches");
 469         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 470             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 471             if ($ty eq 'tree') {
 472                 if ($d == D_DEB_CLOG) {
 473                     return $classify->(qw(Changelog));
 474                 } else {
 475                     return $classify->(qw(Packaging));
 476                 }
 477             } elsif ($ty eq 'missing') {
 478                 return $classify->(qw(BreakwaterStart));
 479             } else {
 480                 return $unknown->("parent's debian is not a directory");
 481             }
 482         } elsif ($d == D_UPS) {
 483             return $classify->(qw(Upstream));
 484         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 485             return $classify->(qw(Mixed));
 486         } elsif ($d == 0) {
 487             return $unknown->("no changes");
 488         } else {
 489             confess "internal error $objid ?";
 490         }
 491     }
 492     if (!@p) {
 493         return $unknown->("origin commit");
 494     }
 495
 496     if (@p == 2 && @identical == 1) {
 497         my @overwritten = grep { $_->{Differs} } @p;
 498         confess "internal error $objid ?" unless @overwritten==1;
 499         return $classify->(qw(Pseudomerge),
 500                            Overwritten => [ $overwritten[0] ],
 501                            Contributor => $identical[0]);
 502     }
 503     if (@p == 2 && @identical == 2) {
 504         my $get_t = sub {
 505             my ($ph,$pm) = get_commit $_[0]{CommitId};
 506             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 507             $1;
 508         };
 509         my @bytime = @p;
 510         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 511         if ($order > 0) { # newer first
 512         } elsif ($order < 0) {
 513             @bytime = reverse @bytime;
 514         } else {
 515             # same age, default to order made by -s ours
 516             # that is, commit was made by someone who preferred L
 517         }
 518         return $classify->(qw(Pseudomerge),
 519                            SubType => qw(Ambiguous),
 520                            Contributor => $bytime[0],
 521                            Overwritten => [ $bytime[1] ]);
 522     }
 523     foreach my $p (@p) {
 524         my ($p_h, $p_m) = get_commit $p->{CommitId};
 525         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 526         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 527     }
 528     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 529     my $m2 = $r->{Msg};
 530     if (!(grep { !$_->{IsOrigin} } @p) and
 531         (@orig_ps >= @p - 1) and
 532         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 533         $r->{NewMsg} = $m2;
 534         return $classify->(qw(DgitImportUnpatched),
 535                            OrigParents => \@orig_ps);
 536     }
 537
 538     return $unknown->("complex merge");
 539 }
 540
 541 sub keycommits ($;$$$) {
 542     my ($head, $furniture, $unclean, $trouble) = @_;
 543     # => ($anchor, $breakwater)
 544
 545     # $unclean->("unclean-$tagsfx", $msg)
 546     # $furniture->("unclean-$tagsfx", $msg)
 547     # $dgitimport->("unclean-$tagsfx", $msg)
 548     #   is callled for each situation or commit that
 549     #   wouldn't be found in a laundered branch
 550     # $furniture is for furniture commits such as might be found on an
 551     #   interchange branch (pseudomerge, d/patches, changelog)
 552     # $trouble is for things whnich prevent the return of
 553     #   anchor and breakwater information; if that is ignored,
 554     #   then keycommits returns (undef, undef) instead.
 555     #
 556     # If a callback is undef, fail is called instead.
 557     # If a callback is defined but false, the situation is ignored.
 558     # Callbacks may say:
 559     #   no warnings qw(exiting); last;
 560     # if the answer is no longer wanted.
 561
 562     my ($anchor, $breakwater);
 563     my $clogonly;
 564     my $cl;
 565     my $x = sub {
 566         my ($cb, $tagsfx, $why) = @_;
 567         my $m = "branch needs laundering (run git-debrebase): $why";
 568         fail $m unless defined $cb;
 569         return unless $cb;
 570         $cb->("unclean-$tagsfx", $why);
 571     };
 572     for (;;) {
 573         $cl = classify $head;
 574         my $ty = $cl->{Type};
 575         if ($ty eq 'Packaging') {
 576             $breakwater //= $clogonly;
 577             $breakwater //= $head;
 578         } elsif ($ty eq 'Changelog') {
 579             # this is going to count as the tip of the breakwater
 580             # only if it has no upstream stuff before it
 581             $clogonly //= $head;
 582         } elsif ($ty eq 'Anchor' or
 583                  $ty eq 'TreatAsAnchor' or
 584                  $ty eq 'BreakwaterStart') {
 585             $anchor = $head;
 586             $breakwater //= $clogonly;
 587             $breakwater //= $head;
 588             last;
 589         } elsif ($ty eq 'Upstream') {
 590             $x->($unclean, 'ordering',
 591  "packaging change ($breakwater) follows upstream change (eg $head)")
 592                 if defined $breakwater;
 593             $clogonly = undef;
 594             $breakwater = undef;
 595         } elsif ($ty eq 'Mixed') {
 596             $x->($unclean, 'mixed',
 597                  "found mixed upstream/packaging commit ($head)");
 598             $clogonly = undef;
 599             $breakwater = undef;
 600         } elsif ($ty eq 'Pseudomerge' or
 601                  $ty eq 'AddPatches') {
 602             $x->($furniture, (lc $ty),
 603                  "found interchange bureaucracy commit ($ty, $head)");
 604         } elsif ($ty eq 'DgitImportUnpatched') {
 605             $x->($trouble, 'dgitimport',
 606                  "found dgit dsc import ($head)");
 607             $breakwater = undef;
 608             $anchor = undef;
 609             no warnings qw(exiting);
 610             last;
 611         } else {
 612             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 613         }
 614         $head = $cl->{Parents}[0]{CommitId};
 615     }
 616     return ($anchor, $breakwater);
 617 }
 618
 619 sub walk ($;$$);
 620 sub walk ($;$$) {
 621     my ($input,
 622         $nogenerate,$report) = @_;
 623     # => ($tip, $breakwater_tip, $last_anchor)
 624     # (or nothing, if $nogenerate)
 625
 626     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 627
 628     # go through commits backwards
 629     # we generate two lists of commits to apply:
 630     # breakwater branch and upstream patches
 631     my (@brw_cl, @upp_cl, @processed);
 632     my %found;
 633     my $upp_limit;
 634     my @pseudomerges;
 635
 636     my $cl;
 637     my $xmsg = sub {
 638         my ($prose, $info) = @_;
 639         my $ms = $cl->{Msg};
 640         chomp $ms;
 641         $info //= '';
 642         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 643         return (Msg => $ms);
 644     };
 645     my $rewrite_from_here = sub {
 646         my ($cl) = @_;
 647         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 648         push @$cl, $sp_cl;
 649         push @processed, $sp_cl;
 650     };
 651     my $cur = $input;
 652
 653     my $prdelim = "";
 654     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 655
 656     my $prline = sub {
 657         return unless $report;
 658         print $report $prdelim, @_;
 659         $prdelim = "\n";
 660     };
 661
 662     my $bomb = sub { # usage: return $bomb->();
 663         print $report " Unprocessable" if $report;
 664         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 665         $prprdelim->();
 666         if ($nogenerate) {
 667             return (undef,undef);
 668         }
 669         die "commit $cur: Cannot cope with this commit (d.".
 670             (join ' ', map { sprintf "%#x", $_->{Differs} }
 671              @{ $cl->{Parents} }).
 672             (defined $cl->{Why} ? "; $cl->{Why}": '').
 673                  ")";
 674     };
 675
 676     my $build;
 677     my $breakwater;
 678
 679     my $build_start = sub {
 680         my ($msg, $parent) = @_;
 681         $prline->(" $msg");
 682         $build = $parent;
 683         no warnings qw(exiting); last;
 684     };
 685
 686     my $last_anchor;
 687
 688     for (;;) {
 689         $cl = classify $cur;
 690         my $ty = $cl->{Type};
 691         my $st = $cl->{SubType};
 692         $prline->("$cl->{CommitId} $cl->{Type}");
 693         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 694         push @processed, $cl;
 695         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 696         if ($ty eq 'AddPatches') {
 697             $cur = $p0;
 698             $rewrite_from_here->(\@upp_cl);
 699             next;
 700         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 701             push @brw_cl, $cl;
 702             $cur = $p0;
 703             next;
 704         } elsif ($ty eq 'BreakwaterStart') {
 705             $last_anchor = $cur;
 706             $build_start->('FirstPackaging', $cur);
 707         } elsif ($ty eq 'Upstream') {
 708             push @upp_cl, $cl;
 709             $cur = $p0;
 710             next;
 711         } elsif ($ty eq 'Mixed') {
 712             my $queue = sub {
 713                 my ($q, $wh) = @_;
 714                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 715                 push @$q, $cls;
 716             };
 717             $queue->(\@brw_cl, "debian");
 718             $queue->(\@upp_cl, "upstream");
 719             $rewrite_from_here->(\@brw_cl);
 720             $cur = $p0;
 721             next;
 722         } elsif ($ty eq 'Pseudomerge') {
 723             my $contrib = $cl->{Contributor}{CommitId};
 724             print $report " Contributor=$contrib" if $report;
 725             push @pseudomerges, $cl;
 726             $rewrite_from_here->(\@upp_cl);
 727             $cur = $contrib;
 728             next;
 729         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 730             $last_anchor = $cur;
 731             $build_start->("Anchor", $cur);
 732         } elsif ($ty eq 'DgitImportUnpatched') {
 733             my $pm = $pseudomerges[-1];
 734             if (defined $pm) {
 735                 # To an extent, this is heuristic.  Imports don't have
 736                 # a useful history of the debian/ branch.  We assume
 737                 # that the first pseudomerge after an import has a
 738                 # useful history of debian/, and ignore the histories
 739                 # from later pseudomerges.  Often the first pseudomerge
 740                 # will be the dgit import of the upload to the actual
 741                 # suite intended by the non-dgit NMUer, and later
 742                 # pseudomerges may represent in-archive copies.
 743                 my $ovwrs = $pm->{Overwritten};
 744                 printf $report " PM=%s \@Overwr:%d",
 745                     $pm->{CommitId}, (scalar @$ovwrs)
 746                     if $report;
 747                 if (@$ovwrs != 1) {
 748                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 749                     return $bomb->();
 750                 }
 751                 my $ovwr = $ovwrs->[0]{CommitId};
 752                 printf $report " Overwr=%s", $ovwr if $report;
 753                 # This import has a tree which is just like a
 754                 # breakwater tree, but it has the wrong history.  It
 755                 # ought to have the previous breakwater (which the
 756                 # pseudomerge overwrote) as an ancestor.  That will
 757                 # make the history of the debian/ files correct.  As
 758                 # for the upstream version: either it's the same as
 759                 # was ovewritten (ie, same as the previous
 760                 # breakwater), in which case that history is precisely
 761                 # right; or, otherwise, it was a non-gitish upload of a
 762                 # new upstream version.  We can tell these apart by
 763                 # looking at the tree of the supposed upstream.
 764                 push @brw_cl, {
 765                     %$cl,
 766                     SpecialMethod => 'DgitImportDebianUpdate',
 767                     $xmsg->("convert dgit import: debian changes")
 768                 }, {
 769                     %$cl,
 770                     SpecialMethod => 'DgitImportUpstreamUpdate',
 771                     $xmsg->("convert dgit import: upstream update",
 772                             " anchor")
 773                 };
 774                 $prline->(" Import");
 775                 $rewrite_from_here->(\@brw_cl);
 776                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 777                 $cur = $ovwr;
 778                 next;
 779             } else {
 780                 # Everything is from this import.  This kind of import
 781                 # is already in valid breakwater format, with the
 782                 # patches as commits.
 783                 printf $report " NoPM" if $report;
 784                 # last thing we processed will have been the first patch,
 785                 # if there is one; which is fine, so no need to rewrite
 786                 # on account of this import
 787                 $build_start->("ImportOrigin", $cur);
 788             }
 789             die "$ty ?";
 790         } else {
 791             printdebug "*** WALK BOMB unrecognised\n";
 792             return $bomb->();
 793         }
 794     }
 795     $prprdelim->();
 796
 797     printdebug "*** WALK prep done cur=$cur".
 798         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 799
 800     return if $nogenerate;
 801
 802     # Now we build it back up again
 803
 804     fresh_workarea();
 805
 806     my $rewriting = 0;
 807
 808     my $read_tree_debian = sub {
 809         my ($treeish) = @_;
 810         read_tree_subdir 'debian', "$treeish:debian";
 811         rm_subdir_cached 'debian/patches';
 812     };
 813     my $read_tree_upstream = sub {
 814         my ($treeish) = @_;
 815         runcmd @git, qw(read-tree), $treeish;
 816         $read_tree_debian->($build);
 817     };
 818
 819     $#upp_cl = $upp_limit if defined $upp_limit;
 820
 821     my $committer_authline = calculate_committer_authline();
 822
 823     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 824
 825     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 826
 827     in_workarea sub {
 828         mkdir $rd or $!==EEXIST or die $!;
 829         my $current_method;
 830         runcmd @git, qw(read-tree), $build;
 831         foreach my $cl (qw(Debian), (reverse @brw_cl),
 832                         { SpecialMethod => 'RecordBreakwaterTip' },
 833                         qw(Upstream), (reverse @upp_cl)) {
 834             if (!ref $cl) {
 835                 $current_method = $cl;
 836                 next;
 837             }
 838             my $method = $cl->{SpecialMethod} // $current_method;
 839             my @parents = ($build);
 840             my $cltree = $cl->{CommitId};
 841             printdebug "WALK BUILD ".($cltree//'undef').
 842                 " $method (rewriting=$rewriting)\n";
 843             if ($method eq 'Debian') {
 844                 $read_tree_debian->($cltree);
 845             } elsif ($method eq 'Upstream') {
 846                 $read_tree_upstream->($cltree);
 847             } elsif ($method eq 'StartRewrite') {
 848                 $rewriting = 1;
 849                 next;
 850             } elsif ($method eq 'RecordBreakwaterTip') {
 851                 $breakwater = $build;
 852                 next;
 853             } elsif ($method eq 'DgitImportDebianUpdate') {
 854                 $read_tree_debian->($cltree);
 855             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 856                 confess unless $rewriting;
 857                 my $differs = (get_differs $build, $cltree);
 858                 next unless $differs & D_UPS;
 859                 $read_tree_upstream->($cltree);
 860                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 861             } else {
 862                 confess "$method ?";
 863             }
 864             if (!$rewriting) {
 865                 my $procd = (pop @processed) // 'UNDEF';
 866                 if ($cl ne $procd) {
 867                     $rewriting = 1;
 868                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 869                 }
 870             }
 871             my $newtree = cmdoutput @git, qw(write-tree);
 872             my $ch = $cl->{Hdr};
 873             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 874             $ch =~ s{^parent .*\n}{}mg;
 875             $ch =~ s{(?=^author)}{
 876                 join '', map { "parent $_\n" } @parents
 877             }me or confess "$ch ?";
 878             if ($rewriting) {
 879                 $ch =~ s{^committer .*$}{$committer_authline}m
 880                     or confess "$ch ?";
 881             }
 882             my $cf = "$rd/m$rewriting";
 883             open CD, ">", $cf or die $!;
 884             print CD $ch, "\n", $cl->{Msg} or die $!;
 885             close CD or die $!;
 886             my @cmd = (@git, qw(hash-object));
 887             push @cmd, qw(-w) if $rewriting;
 888             push @cmd, qw(-t commit), $cf;
 889             my $newcommit = cmdoutput @cmd;
 890             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 891             $build = $newcommit;
 892             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 893                 $last_anchor = $cur;
 894             }
 895         }
 896     };
 897
 898     my $final_check = get_differs $build, $input;
 899     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 900         if $final_check & ~D_PAT_ADD;
 901
 902     my @r = ($build, $breakwater, $last_anchor);
 903     printdebug "*** WALK RETURN @r\n";
 904     return @r
 905 }
 906
 907 sub get_head () {
 908     git_check_unmodified();
 909     return git_rev_parse qw(HEAD);
 910 }
 911
 912 sub update_head ($$$) {
 913     my ($old, $new, $mrest) = @_;
 914     push @deferred_updates, "update HEAD $new $old";
 915     run_deferred_updates $mrest;
 916 }
 917
 918 sub update_head_checkout ($$$) {
 919     my ($old, $new, $mrest) = @_;
 920     update_head $old, $new, $mrest;
 921     runcmd @git, qw(reset --hard);
 922 }
 923
 924 sub update_head_postlaunder ($$$) {
 925     my ($old, $tip, $reflogmsg) = @_;
 926     return if $tip eq $old;
 927     print "git-debrebase: laundered (head was $old)\n";
 928     update_head $old, $tip, $reflogmsg;
 929     # no tree changes except debian/patches
 930     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 931 }
 932
 933 sub do_launder_head ($) {
 934     my ($reflogmsg) = @_;
 935     my $old = get_head();
 936     record_ffq_auto();
 937     my ($tip,$breakwater) = walk $old;
 938     snags_maybe_bail();
 939     update_head_postlaunder $old, $tip, $reflogmsg;
 940     return ($tip,$breakwater);
 941 }
 942
 943 sub cmd_launder_v0 () {
 944     badusage "no arguments to launder-v0 allowed" if @ARGV;
 945     my $old = get_head();
 946     my ($tip,$breakwater,$last_anchor) = walk $old;
 947     update_head_postlaunder $old, $tip, 'launder';
 948     printf "# breakwater tip\n%s\n", $breakwater;
 949     printf "# working tip\n%s\n", $tip;
 950     printf "# last anchor\n%s\n", $last_anchor;
 951 }
 952
 953 sub defaultcmd_rebase () {
 954     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
 955     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
 956     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
 957 }
 958
 959 sub cmd_analyse () {
 960     die if ($ARGV[0]//'') =~ m/^-/;
 961     badusage "too many arguments to analyse" if @ARGV>1;
 962     my ($old) = @ARGV;
 963     if (defined $old) {
 964         $old = git_rev_parse $old;
 965     } else {
 966         $old = git_rev_parse 'HEAD';
 967     }
 968     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 969     STDOUT->error and die $!;
 970 }
 971
 972 sub ffq_prev_branchinfo () {
 973     # => ('status', "message", [$current, $ffq_prev, $gdrlast])
 974     # 'status' may be
 975     #    branch         message is undef
 976     #    weird-symref   } no $current,
 977     #    notbranch      }  no $ffq_prev
 978     my $current = git_get_symref();
 979     return ('detached', 'detached HEAD') unless defined $current;
 980     return ('weird-symref', 'HEAD symref is not to refs/')
 981         unless $current =~ m{^refs/};
 982     my $ffq_prev = "refs/$ffq_refprefix/$'";
 983     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 984     printdebug "ffq_prev_branchinfo branch current $current\n";
 985     return ('branch', undef, $current, $ffq_prev, $gdrlast);
 986 }
 987
 988 sub record_ffq_prev_deferred () {
 989     # => ('status', "message")
 990     # 'status' may be
 991     #    deferred          message is undef
 992     #    exists
 993     #    detached
 994     #    weird-symref
 995     #    notbranch
 996     # if not ff from some branch we should be ff from, is an snag
 997     # if "deferred", will have added something about that to
 998     #   @deferred_update_messages, and also maybe printed (already)
 999     #   some messages about ff checks
1000     my ($status, $message, $current, $ffq_prev, $gdrlast)
1001         = ffq_prev_branchinfo();
1002     return ($status, $message) unless $status eq 'branch';
1003
1004     my $currentval = get_head();
1005
1006     my $exists = git_get_ref $ffq_prev;
1007     return ('exists',"$ffq_prev already exists") if $exists;
1008
1009     return ('not-branch', 'HEAD symref is not to refs/heads/')
1010         unless $current =~ m{^refs/heads/};
1011     my $branch = $';
1012
1013     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1014     my %checked;
1015
1016     printdebug "ffq check_specs @check_specs\n";
1017
1018     my $check = sub {
1019         my ($lrref, $desc) = @_;
1020         printdebug "ffq might check $lrref ($desc)\n";
1021         my $invert;
1022         for my $chk (@check_specs) {
1023             my $glob = $chk;
1024             $invert = $glob =~ s{^[!^]}{};
1025             last if fnmatch $glob, $lrref;
1026         }
1027         return if $invert;
1028         my $lrval = git_get_ref $lrref;
1029         return unless defined $lrval;
1030
1031         if (is_fast_fwd $lrval, $currentval) {
1032             print "OK, you are ahead of $lrref\n" or die $!;
1033             $checked{$lrref} = 1;
1034         } elsif (is_fast_fwd $currentval, $lrval) {
1035             $checked{$lrref} = -1;
1036             snag 'behind', "you are behind $lrref, divergence risk";
1037         } else {
1038             $checked{$lrref} = -1;
1039             snag 'diverged', "you have diverged from $lrref";
1040         }
1041     };
1042
1043     my $merge = cfg "branch.$branch.merge",1;
1044     if (defined $merge and $merge =~ m{^refs/heads/}) {
1045         my $rhs = $';
1046         printdebug "ffq merge $rhs\n";
1047         my $check_remote = sub {
1048             my ($remote, $desc) = @_;
1049             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1050             return unless defined $remote;
1051             $check->("refs/remotes/$remote/$rhs", $desc);
1052         };
1053         $check_remote->((scalar cfg "branch.$branch.remote",1),
1054                         'remote fetch/merge branch');
1055         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1056                         (scalar cfg "branch.$branch.pushDefault",1),
1057                         'remote push branch');
1058     }
1059     if ($branch =~ m{^dgit/}) {
1060         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1061     } elsif ($branch =~ m{^master$}) {
1062         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1063     }
1064
1065     snags_maybe_bail();
1066
1067     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1068     push @deferred_updates, "delete $gdrlast";
1069     push @deferred_update_messages, "Recorded current head for preservation";
1070     return ('deferred', undef);
1071 }
1072
1073 sub record_ffq_auto () {
1074     my ($status, $message) = record_ffq_prev_deferred();
1075     if ($status eq 'deferred' || $status eq 'exists') {
1076     } else {
1077         snag $status, "could not record ffq-prev: $message";
1078         snags_maybe_bail();
1079     }
1080 }
1081
1082 sub ffq_prev_info () {
1083     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1084     my ($status, $message, $current, $ffq_prev, $gdrlast)
1085         = ffq_prev_branchinfo();
1086     if ($status ne 'branch') {
1087         snag $status, "could not check ffq-prev: $message";
1088         snags_maybe_bail();
1089     }
1090     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1091     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1092 }
1093
1094 sub stitch ($$$$$) {
1095     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1096
1097     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1098
1099     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1100         my $differs = get_differs $old_head, $ffq_prev_commitish;
1101         unless ($differs & ~D_PAT_ADD) {
1102             # ffq-prev is ahead of us, and the only tree changes it has
1103             # are possibly addition of things in debian/patches/.
1104             # Just wind forwards rather than making a pointless pseudomerge.
1105             push @deferred_updates,
1106                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1107             update_head_checkout $old_head, $ffq_prev_commitish,
1108                 "stitch (fast forward)";
1109             return;
1110         }
1111     }
1112     fresh_workarea();
1113     # We make pseudomerges with L as the contributing parent.
1114     # This makes git rev-list --first-parent work properly.
1115     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1116         'Declare fast forward / record previous work',
1117         "[git-debrebase pseudomerge: $prose]",
1118     ];
1119     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1120     update_head $old_head, $new_head, "stitch: $prose";
1121 }
1122
1123 sub do_stitch ($;$) {
1124     my ($prose, $unclean) = @_;
1125
1126     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1127     if (!$ffq_prev_commitish) {
1128         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1129         return;
1130     }
1131     my $dangling_head = get_head();
1132
1133     keycommits $dangling_head, $unclean,$unclean,$unclean;
1134     snags_maybe_bail();
1135
1136     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1137 }
1138
1139 sub cmd_new_upstream_v0 () {
1140     # automatically and unconditionally launders before rebasing
1141     # if rebase --abort is used, laundering has still been done
1142
1143     my %pieces;
1144
1145     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1146
1147     # parse args - low commitment
1148     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1149     my $new_upstream_version = $new_version->version();
1150
1151     my $new_upstream = git_rev_parse (shift @ARGV // 'upstream');
1152
1153     record_ffq_auto();
1154
1155     my $piece = sub {
1156         my ($n, @x) = @_; # may be ''
1157         my $pc = $pieces{$n} //= {
1158             Name => $n,
1159             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1160         };
1161         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1162         $pc;
1163     };
1164
1165     my @newpieces;
1166     my $newpiece = sub {
1167         my ($n, @x) = @_; # may be ''
1168         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1169         push @newpieces, $pc;
1170     };
1171
1172     $newpiece->('',
1173         OldIx => 0,
1174         New => $new_upstream,
1175     );
1176     while (@ARGV && $ARGV[0] !~ m{^-}) {
1177         my $n = shift @ARGV;
1178
1179         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1180             unless @ARGV && $ARGV[0] !~ m{^-};
1181
1182         my $c = git_rev_parse shift @ARGV;
1183         die unless $n =~ m/^$extra_orig_namepart_re$/;
1184         $newpiece->($n, New => $c);
1185     }
1186
1187     # now we need to investigate the branch this generates the
1188     # laundered version but we don't switch to it yet
1189     my $old_head = get_head();
1190     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1191
1192     my $old_bw_cl = classify $old_bw;
1193     my $old_anchor_cl = classify $old_anchor;
1194     my $old_upstream;
1195     if (!$old_anchor_cl->{OrigParents}) {
1196         snag 'anchor-treated',
1197             'old anchor is recognised due to --anchor, cannot check upstream';
1198     } else {
1199         $old_upstream = parsecommit
1200             $old_anchor_cl->{OrigParents}[0]{CommitId};
1201         $piece->('', Old => $old_upstream->{CommitId});
1202     }
1203
1204     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1205         if ($old_upstream->{Msg} =~
1206  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1207            ) {
1208             my @oldpieces = (split / /, $1);
1209             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1210             if (@oldpieces != $old_n_parents) {
1211                 snag 'upstream-confusing', sprintf
1212                     "previous upstream combine %s".
1213                     " mentions %d pieces (each implying one orig commit)".
1214                     " but has %d parents",
1215                     $old_upstream->{CommitId},
1216                     (scalar @oldpieces),
1217                     $old_n_parents;
1218             } elsif ($oldpieces[0] ne '.') {
1219                 snag 'upstream-confusing', sprintf
1220                     "previous upstream combine %s".
1221                     " first piece is not \`.'",
1222                     $oldpieces[0];
1223             } else {
1224                 $oldpieces[0] = '';
1225                 foreach my $i (0..$#oldpieces) {
1226                     my $n = $oldpieces[$i];
1227                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.($i+1));
1228                 }
1229             }
1230         } else {
1231             snag 'upstream-confusing',
1232                 "previous upstream $old_upstream->{CommitId} is from".
1233                " git-debrebase but not an \`upstream-combine' commit";
1234         }
1235     }
1236
1237     foreach my $pc (values %pieces) {
1238         if (!$old_upstream) {
1239             # we have complained already
1240         } elsif (!$pc->{Old}) {
1241             snag 'upstream-new-piece',
1242                 "introducing upstream piece \`$pc->{Name}'";
1243         } elsif (!$pc->{New}) {
1244             snag 'upstream-rm-piece',
1245                 "dropping upstream piece \`$pc->{Name}'";
1246         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1247             snag 'upstream-not-ff',
1248                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1249         }
1250     }
1251
1252     printdebug "%pieces = ", (dd \%pieces), "\n";
1253     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1254
1255     snags_maybe_bail();
1256
1257     my $new_bw;
1258
1259     fresh_workarea();
1260     in_workarea sub {
1261         my @upstream_merge_parents;
1262
1263         if (!any_snags()) {
1264             push @upstream_merge_parents, $old_upstream->{CommitId};
1265         }
1266
1267         foreach my $pc (@newpieces) { # always has '' first
1268             if ($pc->{Name}) {
1269                 read_tree_subdir $pc->{Name}, $pc->{New};
1270             } else {
1271                 runcmd @git, qw(read-tree), $pc->{New};
1272             }
1273             push @upstream_merge_parents, $pc->{New};
1274         }
1275
1276         # index now contains the new upstream
1277
1278         if (@newpieces > 1) {
1279             # need to make the upstream subtree merge commit
1280             $new_upstream = make_commit \@upstream_merge_parents,
1281                 [ "Combine upstreams for $new_upstream_version",
1282  ("[git-debrebase upstream-combine . ".
1283  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1284  ": new upstream]"),
1285                 ];
1286         }
1287
1288         # $new_upstream is either the single upstream commit, or the
1289         # combined commit we just made.  Either way it will be the
1290         # "upstream" parent of the anchor merge.
1291
1292         read_tree_subdir 'debian', "$old_bw:debian";
1293
1294         # index now contains the anchor merge contents
1295         $new_bw = make_commit [ $old_bw, $new_upstream ],
1296             [ "Update to upstream $new_upstream_version",
1297  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1298             ];
1299
1300         my $clogsignoff = cmdoutput qw(git show),
1301             '--pretty=format:%an <%ae>  %aD',
1302             $new_bw;
1303
1304         # Now we have to add a changelog stanza so the Debian version
1305         # is right.
1306         die if unlink "debian";
1307         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1308         unlink "debian/changelog" or $!==ENOENT or die $!;
1309         mkdir "debian" or die $!;
1310         open CN, ">", "debian/changelog" or die $!;
1311         my $oldclog = git_cat_file ":debian/changelog";
1312         $oldclog =~ m/^($package_re) \(\S+\) / or
1313             fail "cannot parse old changelog to get package name";
1314         my $p = $1;
1315         print CN <<END, $oldclog or die $!;
1316 $p ($new_version) UNRELEASED; urgency=medium
1317
1318   * Update to new upstream version $new_upstream_version.
1319
1320  -- $clogsignoff
1321
1322 END
1323         close CN or die $!;
1324         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1325
1326         # Now we have the final new breakwater branch in the index
1327         $new_bw = make_commit [ $new_bw ],
1328             [ "Update changelog for new upstream $new_upstream_version",
1329               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1330             ];
1331     };
1332
1333     # we have constructed the new breakwater. we now need to commit to
1334     # the laundering output, because git-rebase can't easily be made
1335     # to make a replay list which is based on some other branch
1336
1337     update_head_postlaunder $old_head, $old_laundered_tip,
1338         'launder for new upstream';
1339
1340     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1341     runcmd @cmd;
1342     # now it's for the user to sort out
1343 }
1344
1345 sub cmd_record_ffq_prev () {
1346     badusage "no arguments allowed" if @ARGV;
1347     my ($status, $msg) = record_ffq_prev_deferred();
1348     if ($status eq 'exists' && $opt_noop_ok) {
1349         print "Previous head already recorded\n" or die $!;
1350     } elsif ($status eq 'deferred') {
1351         run_deferred_updates 'record-ffq-prev';
1352     } else {
1353         fail "Could not preserve: $msg";
1354     }
1355 }
1356
1357 sub cmd_anchor () {
1358     badusage "no arguments allowed" if @ARGV;
1359     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1360     print "$bw\n" or die $!;
1361 }
1362
1363 sub cmd_breakwater () {
1364     badusage "no arguments allowed" if @ARGV;
1365     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1366     print "$bw\n" or die $!;
1367 }
1368
1369 sub cmd_stitch () {
1370     my $prose = 'stitch';
1371     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1372     badusage "no arguments allowed" if @ARGV;
1373     do_stitch $prose, 0;
1374 }
1375 sub cmd_prepush () { cmd_stitch(); }
1376
1377 sub cmd_quick () {
1378     badusage "no arguments allowed" if @ARGV;
1379     do_launder_head 'launder for git-debrebase quick';
1380     do_stitch 'quick';
1381 }
1382
1383 sub cmd_conclude () {
1384     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1385     if (!$ffq_prev_commitish) {
1386         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1387         return;
1388     }
1389     my $dangling_head = get_head();
1390
1391     badusage "no arguments allowed" if @ARGV;
1392     do_launder_head 'launder for git-debrebase quick';
1393     do_stitch 'quick';
1394 }
1395
1396 sub make_patches_staged ($) {
1397     my ($head) = @_;
1398     # Produces the patches that would result from $head if it were
1399     # laundered.
1400     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
1401     fresh_workarea();
1402     in_workarea sub {
1403         runcmd @git, qw(checkout -q -b bw), $secret_bw;
1404         runcmd @git, qw(checkout -q -b patch-queue/bw), $secret_head;
1405         runcmd qw(gbp pq export);
1406         runcmd @git, qw(add debian/patches);
1407     };
1408 }
1409
1410 sub make_patches ($) {
1411     my ($head) = @_;
1412     keycommits $head, 0, \&snag;
1413     make_patches_staged $head;
1414     my $out;
1415     in_workarea sub {
1416         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
1417         runcmd @git, qw(read-tree), $head;
1418         read_tree_subdir 'debian/patches', $ptree;
1419         $out = make_commit [$head], [
1420             'Commit patch queue (exported by git-debrebase)',
1421             '[git-debrebase: export and commit patches]',
1422         ];
1423     };
1424     my $d = get_differs $head, $out;
1425     if ($d == 0) {
1426         return undef; # nothing to do
1427     } elsif ($d == D_PAT_ADD) {
1428         return $out; # OK
1429     } else {
1430         fail "Patch export produced patch amendments".
1431             " (abandoned output commit $out).".
1432             "  Try laundering first.";
1433     }
1434 }
1435
1436 sub cmd_make_patches () {
1437     badusage "no arguments allowed" if @ARGV;
1438     my $old_head = get_head();
1439     my $new = make_patches $old_head;
1440     snags_maybe_bail();
1441     if (!$new) {
1442         fail "No (more) patches to export." unless $opt_noop_ok;
1443         return;
1444     }
1445     update_head_checkout $old_head, $new, 'make-patches';
1446 }
1447
1448 sub cmd_convert_from_gbp () {
1449     badusage "needs 1 optional argument, the upstream git rev"
1450         unless @ARGV<=1;
1451     my ($upstream_spec) = @ARGV;
1452     $upstream_spec //= 'refs/heads/upstream';
1453     my $upstream = git_rev_parse $upstream_spec;
1454     my $old_head = get_head();
1455
1456     my $upsdiff = get_differs $upstream, $old_head;
1457     if ($upsdiff & D_UPS) {
1458         runcmd @git, qw(--no-pager diff),
1459             $upstream, $old_head,
1460             qw( -- :!/debian :/);
1461  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1462     }
1463
1464     if (!is_fast_fwd $upstream, $old_head) {
1465         snag 'upstream-not-ancestor',
1466             "upstream ($upstream) is not an ancestor of HEAD";
1467     } else {
1468         my $wrong = cmdoutput
1469             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1470              qw(-- :/ :!/debian));
1471         if (length $wrong) {
1472             snag 'unexpected-upstream-changes',
1473                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1474             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1475         }
1476     }
1477
1478     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1479         snag 'upstream-has-debian',
1480             "upstream ($upstream) contains debian/ directory";
1481     }
1482
1483     snags_maybe_bail();
1484
1485     my $work;
1486
1487     fresh_workarea();
1488     in_workarea sub {
1489         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1490         # make a branch out of the patch queue - we'll want this in a mo
1491         runcmd qw(gbp pq import);
1492         # strip the patches out
1493         runcmd @git, qw(checkout -q gdr-internal~0);
1494         rm_subdir_cached 'debian/patches';
1495         $work = make_commit ['HEAD'], [
1496  'git-debrebase convert-from-gbp: drop patches from tree',
1497  'Delete debian/patches, as part of converting to git-debrebase format.',
1498  '[git-debrebase convert-from-gbp: drop patches from tree]'
1499                               ];
1500         # make the anchor merge
1501         # the tree is already exactly right
1502         $work = make_commit [$work, $upstream], [
1503  'git-debrebase import: declare upstream',
1504  'First breakwater merge.',
1505  '[git-debrebase anchor: declare upstream]'
1506                               ];
1507
1508         # rebase the patch queue onto the new breakwater
1509         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1510         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1511         $work = git_rev_parse 'HEAD';
1512     };
1513
1514     update_head_checkout $old_head, $work, 'convert-from-gbp';
1515 }
1516
1517 sub cmd_convert_to_gbp () {
1518     badusage "no arguments allowed" if @ARGV;
1519     my $head = get_head();
1520     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
1521     keycommits $head, 0;
1522     my $out;
1523     make_patches_staged $head;
1524     in_workarea sub {
1525         $out = make_commit ['HEAD'], [
1526             'Commit patch queue (converted from git-debrebase format)',
1527             '[git-debrebase convert-to-gbp: commit patches]',
1528         ];
1529     };
1530     if (defined $ffq) {
1531         push @deferred_updates, "delete $ffq";
1532         push @deferred_updates, "delete $gdrlast";
1533     }
1534     snags_maybe_bail();
1535     update_head_checkout $head, $out, "convert to gbp (v0)";
1536     print <<END or die $!;
1537 git-debrebase: converted to git-buildpackage branch format
1538 git-debrebase: WARNING: do not now run "git-debrebase" any more
1539 git-debrebase: WARNING: doing so would drop all upstream patches!
1540 END
1541 }
1542
1543 sub cmd_downstream_rebase_launder_v0 () {
1544     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1545     my ($base) = @ARGV;
1546     $base = git_rev_parse $base;
1547     my $old_head = get_head();
1548     my $current = $old_head;
1549     my $topmost_keep;
1550     for (;;) {
1551         if ($current eq $base) {
1552             $topmost_keep //= $current;
1553             print " $current BASE stop\n";
1554             last;
1555         }
1556         my $cl = classify $current;
1557         print " $current $cl->{Type}";
1558         my $keep = 0;
1559         my $p0 = $cl->{Parents}[0]{CommitId};
1560         my $next;
1561         if ($cl->{Type} eq 'Pseudomerge') {
1562             print " ^".($cl->{Contributor}{Ix}+1);
1563             $next = $cl->{Contributor}{CommitId};
1564         } elsif ($cl->{Type} eq 'AddPatches' or
1565                  $cl->{Type} eq 'Changelog') {
1566             print " strip";
1567             $next = $p0;
1568         } else {
1569             print " keep";
1570             $next = $p0;
1571             $keep = 1;
1572         }
1573         print "\n";
1574         if ($keep) {
1575             $topmost_keep //= $current;
1576         } else {
1577             die "to-be stripped changes not on top of the branch\n"
1578                 if $topmost_keep;
1579         }
1580         $current = $next;
1581     }
1582     if ($topmost_keep eq $old_head) {
1583         print "unchanged\n";
1584     } else {
1585         print "updating to $topmost_keep\n";
1586         update_head_checkout
1587             $old_head, $topmost_keep,
1588             'downstream-rebase-launder-v0';
1589     }
1590 }
1591
1592 GetOptions("D+" => \$debuglevel,
1593            'noop-ok', => \$opt_noop_ok,
1594            'f=s' => \@snag_force_opts,
1595            'anchor=s' => \@opt_anchors,
1596            'force!',
1597            '-i:s' => sub {
1598                my ($opt,$val) = @_;
1599                badusage "git-debrebase: no cuddling to -i for git-rebase"
1600                    if length $val;
1601                die if $opt_defaultcmd_interactive; # should not happen
1602                $opt_defaultcmd_interactive = [ qw(-i) ];
1603                # This access to @ARGV is excessive familiarity with
1604                # Getopt::Long, but there isn't another sensible
1605                # approach.  '-i=s{0,}' does not work with bundling.
1606                push @$opt_defaultcmd_interactive, @ARGV;
1607                @ARGV=();
1608            }) or die badusage "bad options\n";
1609 initdebug('git-debrebase ');
1610 enabledebug if $debuglevel;
1611
1612 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1613 chdir $toplevel or die "chdir $toplevel: $!";
1614
1615 $rd = fresh_playground "$playprefix/misc";
1616
1617 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1618
1619 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
1620     defaultcmd_rebase();
1621 } else {
1622     my $cmd = shift @ARGV;
1623     my $cmdfn = $cmd;
1624     $cmdfn =~ y/-/_/;
1625     $cmdfn = ${*::}{"cmd_$cmdfn"};
1626
1627     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1628     $cmdfn->();
1629 }
1630
1631 finish 0;