git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT :playground);
 114
 115 sub badusage ($) {
 116     my ($m) = @_;
 117     die "bad usage: $m\n";
 118 }
 119
 120 sub cfg ($) {
 121     my ($k) = @_;
 122     $/ = "\0";
 123     my @cmd = qw(git config -z);
 124     push @cmd, qw(--get-all) if wantarray;
 125     push @cmd, $k;
 126     my $out = cmdoutput @cmd;
 127     return split /\0/, $out;
 128 }
 129
 130 memoize('cfg');
 131
 132 sub get_commit ($) {
 133     my ($objid) = @_;
 134     my $data = git_cat_file $objid, 'commit';
 135     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 136     return ($`,$');
 137 }
 138
 139 sub D_DEB ()     { return 0x1; } # debian/ (not including debian/patches/)
 140 sub D_UPS ()     { return 0x2; } # upstream files
 141 sub D_PAT_ADD () { return 0x4; } # debian/patches/ extra patches at end
 142 sub D_PAT_OTH () { return 0x8; } # debian/patches other changes
 143
 144
 145 our $playprefix = 'debrebase';
 146 our $rd;
 147
 148 our @git = qw(git);
 149
 150 sub in_workarea ($) {
 151     my ($sub) = @_;
 152     changedir "$playground/work";
 153     my $r = eval { $sub->(); };
 154     changedir $maindir;
 155 }
 156
 157 sub fresh_workarea () {
 158     do {
 159         local $playground;
 160         fresh_playground "$playprefix/work";
 161     };
 162     in_workarea sub { playtree_setup };
 163 }
 164
 165 sub get_differs ($$) {
 166     my ($x,$y) = @_;
 167     # This resembles quiltify_trees_differ, in dgit, a bit.
 168     # But we don't care about modes, or dpkg-source-unrepresentable
 169     # changes, and we don't need the plethora of different modes.
 170     # Conversely we need to distinguish different kinds of changes to
 171     # debian/ and debian/patches/.
 172
 173     my $differs = 0;
 174
 175     my $rundiff = sub {
 176         my ($opts, $limits, $fn) = @_;
 177         my @cmd = (@git, qw(diff-tree -z --no-renames));
 178         push @cmd, @$opts;
 179         push @cmd, "$_:" foreach $x, $y;
 180         push @cmd, @$limits;
 181         my $diffs = cmdoutput @cmd;
 182         foreach (split /\0/, $diffs) { $fn->(); }
 183     };
 184
 185     $rundiff->([qw(--name-only)], [], sub {
 186         $differs |= $_ eq 'debian' ? D_DEB : D_UPS;
 187     });
 188
 189     if ($differs & D_DEB) {
 190         $differs &= ~D_DEB;
 191         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 192             $differs |= $_ eq m{^debian/patches/} ? D_PAT_OTH : D_DEB;
 193         });
 194         die "mysterious debian changes $x..$y"
 195             unless $differs & (D_PAT_OTH|D_DEB);
 196     }
 197
 198     if ($differs & D_PAT_OTH) {
 199         my $mode;
 200         $differs &= ~D_PAT_OTH;
 201         my $pat_oth = sub {
 202             $differs |= D_PAT_OTH;
 203             no warnings qw(exiting);  last;
 204         };
 205         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 206             no warnings qw(exiting);
 207             if (!defined $mode) {
 208                 $mode = $_;  next;
 209             }
 210             die unless s{^debian/patches/}{};
 211             my $ok;
 212             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 213                 $ok = 1;
 214             } elsif ($mode eq 'M' && $_ eq 'series') {
 215                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 216                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 217                 chomp $x_s;  $x_s .= "\n";
 218                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 219             } else {
 220                 # nope
 221             }
 222             $mode = undef;
 223             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 224         });
 225         die "mysterious debian/patches changes $x..$y"
 226             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 227     }
 228
 229     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 230
 231     return $differs;
 232 }
 233
 234 sub commit_pr_info ($) {
 235     my ($r) = @_;
 236     return Data::Dumper->dump([$r], [qw(commit)]);
 237 }
 238
 239 sub calculate_committer_authline () {
 240     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 241         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 242     my ($h,$m) = get_commit $c;
 243     $h =~ m/^committer .*$/m or confess "($h) ?";
 244     return $&;
 245 }
 246
 247 # classify returns an info hash like this
 248 #   CommitId => $objid
 249 #   Hdr => # commit headers, including 1 final newline
 250 #   Msg => # commit message (so one newline is dropped)
 251 #   Tree => $treeobjid
 252 #   Type => (see below)
 253 #   Parents = [ {
 254 #       Ix => $index # ie 0, 1, 2, ...
 255 #       CommitId
 256 #       Differs => return value from get_differs
 257 #       IsOrigin
 258 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 259 #     } ...]
 260 #   NewMsg => # commit message, but with any [dgit import ...] edited
 261 #             # to say "[was: ...]"
 262 #
 263 # Types:
 264 #   Packaging
 265 #   Upstream
 266 #   AddPatches
 267 #   Mixed
 268 #   Unknown
 269 #
 270 #   Pseudomerge
 271 #     has additional entres in classification result
 272 #       Overwritten = [ subset of Parents ]
 273 #       Contributor = $the_remaining_Parent
 274 #
 275 #   DgitImportUnpatched
 276 #     has additional entry in classification result
 277 #       OrigParents = [ subset of Parents ]
 278 #
 279 #   BreakwaterUpstreamMerge
 280 #     has additional entry in classification result
 281 #       OrigParents = [ subset of Parents ]
 282
 283 sub classify ($) {
 284     my ($objid) = @_;
 285
 286     my ($h,$m) = get_commit $objid;
 287
 288     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 289     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 290     my @p;
 291
 292     my $r = {
 293         CommitId => $objid,
 294         Hdr => $h,
 295         Msg => $m,
 296         Tree => $t,
 297         Parents => \@p,
 298     };
 299
 300     foreach my $ph (@ph) {
 301         push @p, {
 302             Ix => $#p,
 303             CommitId => $ph,
 304             Differs => (get_differs $t, $ph),
 305         };
 306     }
 307
 308     printdebug "classify $objid \$t=$t \@p",
 309         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 310         "\n";
 311
 312     my $classify = sub {
 313         my ($type, @rest) = @_;
 314         $r = { %$r, Type => $type, @rest };
 315         if ($debuglevel) {
 316             my $dd = new Data::Dumper [ $r ];
 317             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 318             printdebug " = $type ".(Dump $dd)."\n";
 319         }
 320         return $r;
 321     };
 322     my $unknown = sub {
 323         my ($why) = @_;
 324         $r = { %$r, Type => qw(Unknown) };
 325         printdebug " ** Unknown\n";
 326         return $r;
 327     };
 328
 329     if (@p == 1) {
 330         my $d = $r->{Parents}[0]{Differs};
 331         if ($d == D_PAT_ADD) {
 332             return $classify->(qw(AddPatches));
 333         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 334             return $unknown->("edits debian/patches");
 335         } elsif ($d == D_DEB) {
 336             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 337             if ($ty eq 'tree') {
 338                 return $classify->(qw(Packaging));
 339             } elsif ($ty eq 'missing') {
 340                 return $classify->(qw(BreakwaterStart));
 341             } else {
 342                 return $unknown->("parent's debian is not a directory");
 343             }
 344         } elsif ($d == D_UPS) {
 345             return $classify->(qw(Upstream));
 346         } elsif ($d == (D_DEB|D_UPS)) {
 347             return $classify->(qw(Mixed));
 348         } elsif ($d == 0) {
 349             return $unknown->("no changes");
 350         } else {
 351             confess "internal error $objid ?";
 352         }
 353     }
 354     if (!@p) {
 355         return $unknown->("origin commit");
 356     }
 357
 358     my @identical = grep { !$_->{Differs} } @p;
 359     if (@p == 2 && @identical == 1) {
 360         my @overwritten = grep { $_->{Differs} } @p;
 361         confess "internal error $objid ?" unless @overwritten==1;
 362         return $classify->(qw(Pseudomerge),
 363                            Overwritten => $overwritten[0],
 364                            Contributor => $identical[0]);
 365     }
 366     if (@p == 2 && @identical == 2) {
 367         my @bytime = nsort_by {
 368             my ($ph,$pm) = get_commit $_->{CommitId};
 369             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 370             $1;
 371         } @p;
 372         return $classify->(qw(Pseudomerge),
 373                            SubType => qw(Ambiguous),
 374                            Overwritten => $bytime[0],
 375                            Contributor => $bytime[1]);
 376     }
 377     foreach my $p (@p) {
 378         my ($p_h, $p_m) = get_commit $p->{CommitId};
 379         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 380         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 381     }
 382     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 383     my $m2 = $m;
 384     if (!(grep { !$_->{IsOrigin} } @p) and
 385         (@orig_ps >= @p - 1) and
 386         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 387         $r->{NewMsg} = $m2;
 388         return $classify->(qw(DgitImportUnpatched),
 389                            OrigParents => \@orig_ps);
 390     }
 391
 392     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 393     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 394
 395 @p = reverse @p; #xxx
 396
 397     # How to decide about l/r ordering of breakwater merges ?  git
 398     # --topo-order prefers to expand 2nd parent first.  There's
 399     # already an easy rune to look for debian/ history anyway (git log
 400     # debian/) so debian breakwater branch should be 1st parent; that
 401     # way also there's also an easy rune to look for the upstream
 402     # patches (--topo-order).
 403     if (@p == 2 &&
 404         !$haspatches &&
 405         !$p[0]{IsOrigin} && # breakwater merge never starts with an origin
 406         !($p[0]{Differs} & ~D_DEB) &&
 407         !($p[1]{Differs} & ~D_UPS)) {
 408         return $classify->(qw(BreakwaterUpstreamMerge),
 409                            OrigParents => [ $p[1] ]);
 410     }
 411     # xxx multi-.orig upstreams
 412
 413     return $unknown->("complex merge");
 414 }
 415
 416 sub walk ($;$$);
 417 sub walk ($;$$) {
 418     my ($input,
 419         $nogenerate,$report) = @_;
 420     # => ($tip, $breakwater_tip)
 421     # (or nothing, if $nogenerate)
 422
 423     # go through commits backwards
 424     # we generate two lists of commits to apply:
 425     # breakwater branch and upstream patches
 426     my (@brw_cl, @upp_cl, @processed);
 427     my %found;
 428     my $upp_limit;
 429     my @pseudomerges;
 430
 431     my $cl;
 432     my $xmsg = sub {
 433         my ($appendinfo) = @_;
 434         my $ms = $cl->{Msg};
 435         chomp $ms;
 436         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 437         return (Msg => $ms);
 438     };
 439     my $rewrite_from_here = sub {
 440         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 441         push @brw_cl, $sp_cl;
 442         push @processed, $sp_cl;
 443     };
 444     my $cur = $input;
 445
 446     my $prdelim = "";
 447     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 448
 449     my $prline = sub {
 450         return unless $report;
 451         print $report $prdelim, @_;
 452         $prdelim = "\n";
 453     };
 454
 455     my $bomb = sub { # usage: return $bomb->();
 456         print $report " Unprocessable" if $report;
 457         $prprdelim->();
 458         if ($nogenerate) {
 459             return (undef,undef);
 460         }
 461         die "commit $cur: Cannot cope with this commit";
 462     };
 463
 464     my $build;
 465     my $breakwater;
 466
 467     my $build_start = sub {
 468         my ($msg, $parent) = @_;
 469         $prline->(" $msg");
 470         $build = $parent;
 471         no warnings qw(exiting); last;
 472     };
 473
 474     for (;;) {
 475         $cl = classify $cur;
 476         my $ty = $cl->{Type};
 477         my $st = $cl->{SubType};
 478         $prline->("$cl->{CommitId} $cl->{Type}");
 479         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 480         push @processed, $cl;
 481         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 482         if ($ty eq 'AddPatches') {
 483             $cur = $p0;
 484             $rewrite_from_here->();
 485             next;
 486         } elsif ($ty eq 'Packaging') {
 487             push @brw_cl, $cl;
 488             $cur = $p0;
 489             next;
 490         } elsif ($ty eq 'BreakwaterStart') {
 491             $build_start->('FirstPackaging', $cur);
 492         } elsif ($ty eq 'Upstream') {
 493             push @upp_cl, $cl;
 494             $cur = $p0;
 495             next;
 496         } elsif ($ty eq 'Mixed') {
 497             my $queue = sub {
 498                 my ($q, $wh) = @_;
 499                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 500                 push @$q, $cls;
 501             };
 502             $queue->(\@brw_cl, "debian");
 503             $queue->(\@upp_cl, "upstream");
 504             $rewrite_from_here->();
 505             $cur = $p0;
 506             next;
 507         } elsif ($ty eq 'Pseudomerge') {
 508             my $contrib = $cl->{Contributor}{CommitId};
 509             print $report " Contributor=$contrib" if $report;
 510             push @pseudomerges, $cl;
 511             $rewrite_from_here->();
 512             $cur = $contrib;
 513             next;
 514         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 515             $build_start->("PreviousBreakwater", $cur);
 516         } elsif ($ty eq 'DgitImportUnpatched') {
 517             my $pm = $pseudomerges[-1];
 518             if (defined $pm) {
 519                 # To an extent, this is heuristic.  Imports don't have
 520                 # a useful history of the debian/ branch.  We assume
 521                 # that the first pseudomerge after an import has a
 522                 # useful history of debian/, and ignore the histories
 523                 # from later pseudomerges.  Often the first pseudomerge
 524                 # will be the dgit import of the upload to the actual
 525                 # suite intended by the non-dgit NMUer, and later
 526                 # pseudomerges may represent in-archive copies.
 527                 my $ovwrs = $pm->{Overwritten};
 528                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 529                     if $report;
 530                 if (@$ovwrs != 1) {
 531                     return $bomb->();
 532                 }
 533                 my $ovwr = $ovwrs->[0]{CommitId};
 534                 printf $report " Overwr=%s", $ovwr if $report;
 535                 # This import has a tree which is just like a
 536                 # breakwater tree, but it has the wrong history.  It
 537                 # ought to have the previous breakwater (which the
 538                 # pseudomerge overwrote) as an ancestor.  That will
 539                 # make the history of the debian/ files correct.  As
 540                 # for the upstream version: either it's the same as
 541                 # was ovewritten (ie, same as the previous
 542                 # breakwater), in which case that history is precisely
 543                 # right; or, otherwise, it was a non-gitish upload of a
 544                 # new upstream version.  We can tell these apart by
 545                 # looking at the tree of the supposed upstream.
 546                 push @brw_cl, {
 547                     %$cl,
 548                     SpecialMethod => 'DgitImportDebianUpdate',
 549                     $xmsg->("convert dgit import: debian changes")
 550                 };
 551                 my $differs = (get_differs $ovwr, $cl->{Tree});
 552                 printf $report " Differs=%#x", $differs if $report;
 553                 if ($differs & D_UPS) {
 554                     printf $report " D_UPS" if $report;
 555                     # This will also trigger if a non-dgit git-based NMU
 556                     # deleted .gitignore (which is a thing that some of
 557                     # the existing git tools do if the user doesn't
 558                     # somehow tell them not to).  Ah well.
 559                     push @brw_cl, {
 560                         %$cl,
 561                         SpecialMethod => 'DgitImportUpstreamUpdate',
 562                         $xmsg->("convert dgit import: upstream changes")
 563                     };
 564                 }
 565                 $prline->(" Import");
 566                 $rewrite_from_here->();
 567                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 568                 $cur = $ovwr;
 569                 next;
 570             } else {
 571                 # Everything is from this import.  This kind of import
 572                 # is already in valid breakwater format, with the
 573                 # patches as commits.
 574                 printf $report " NoPM" if $report;
 575                 # last thing we processed will have been the first patch,
 576                 # if there is one; which is fine, so no need to rewrite
 577                 # on account of this import
 578                 $build_start->("ImportOrigin", $cur);
 579             }
 580             die "$ty ?";
 581         } else {
 582             return $bomb->();
 583         }
 584     }
 585     $prprdelim->();
 586     return if $nogenerate;
 587
 588     # Now we build it back up again
 589
 590     fresh_workarea();
 591
 592     my $rewriting = 0;
 593
 594     my $rm_tree_cached = sub {
 595         my ($subdir) = @_;
 596         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 597     };
 598     my $read_tree_debian = sub {
 599         my ($treeish) = @_;
 600         $rm_tree_cached->(qw(debian));
 601         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 602     };
 603     my $read_tree_upstream = sub {
 604         my ($treeish) = @_;
 605         runcmd @git, qw(read-tree), $treeish;
 606         $read_tree_debian->($build);
 607     };
 608
 609     my $committer_authline = calculate_committer_authline();
 610
 611     in_workarea sub {
 612         mkdir $rd or $!==EEXIST or die $!;
 613         my $current_method;
 614         foreach my $cl (qw(Debian), (reverse @brw_cl),
 615                         { SpecialMethod => 'RecordBreakwaterTip' },
 616                         qw(Upstream), (reverse @upp_cl)) {
 617             if (!ref $cl) {
 618                 $current_method = $cl;
 619                 next;
 620             }
 621             my $method = $cl->{SpecialMethod} // $current_method;
 622             my @parents = ($build);
 623             my $cltree = $cl->{CommitId};
 624             if ($method eq 'Debian') {
 625                 $read_tree_debian->($cltree);
 626             } elsif ($method eq 'Upstream') {
 627                 $read_tree_upstream->($cltree);
 628             } elsif ($method eq 'StartRewrite') {
 629                 $rewriting = 1;
 630                 next;
 631             } elsif ($method eq 'RecordBreakwaterTip') {
 632                 $breakwater = $build;
 633                 next;
 634             } elsif ($method eq 'DgitImportDebianUpdate') {
 635                 $read_tree_debian->($cltree);
 636                 $rm_tree_cached->(qw(debian/patches));
 637             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 638                 $read_tree_upstream->($cltree);
 639                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 640             } else {
 641                 confess "$method ?";
 642             }
 643             $rewriting ||= $cl ne pop @processed;
 644             my $newtree = cmdoutput @git, qw(write-tree);
 645             my $ch = $cl->{Hdr};
 646             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 647             $ch =~ s{^parent .*\n}{}m;
 648             $ch =~ s{(?=^author)}{
 649                 map { "parent $_\n" } @parents
 650             }me or confess "$ch ?";
 651             if ($rewriting) {
 652                 $ch =~ s{^committer .*$}{$committer_authline}m
 653                     or confess "$ch ?";
 654             }
 655             my $cf = "$rd/m$rewriting";
 656             open CD, ">", $cf or die $!;
 657             print CD $ch, "\n", $cl->{Msg} or die $!;
 658             close CD or die $!;
 659             my @cmd = (@git, qw(hash-object));
 660             push @cmd, qw(-w) if $rewriting;
 661             push @cmd, qw(-t commit), $cf;
 662             my $newcommit = cmdoutput @cmd;
 663             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 664             $build = $newcommit;
 665         }
 666     };
 667
 668     runcmd @git, qw(diff-tree --quiet), $input, $build;
 669
 670     return ($build, $breakwater);
 671 }
 672
 673 sub get_head () { return git_rev_parse qw(HEAD); }
 674
 675 sub update_head ($$$) {
 676     my ($old, $new, $mrest) = @_;
 677     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 678 }
 679
 680 sub cmd_launder () {
 681     badusage "no arguments to launder allowed" if @ARGV;
 682     my $old = get_head();
 683     my ($tip,$breakwater) = walk $old;
 684     update_head $old, $tip, 'launder';
 685     # no tree changes except debian/patches
 686     runcmd @git, qw(rm --quiet -rf debian/patches);
 687     printf "# breakwater tip\n%s\n", $breakwater;
 688 }
 689
 690 sub cmd_analyse () {
 691     die if ($ARGV[0]//'') =~ m/^-/;
 692     badusage "too many arguments to analyse" if @ARGV>1;
 693     my ($old) = @ARGV;
 694     if (defined $old) {
 695         $old = git_rev_parse $old;
 696     } else {
 697         $old = get_head();
 698     }
 699     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 700     STDOUT->error and die $!;
 701 }
 702
 703 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 704 initdebug('git-debrebase ');
 705 enabledebug if $debuglevel;
 706
 707 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 708 chdir $toplevel or die "chdir $toplevel: $!";
 709
 710 fresh_playground $playprefix;
 711 $rd = ensure_a_playground "playprefix/misc";
 712
 713 my $cmd = shift @ARGV;
 714 my $cmdfn = $cmd;
 715 $cmdfn =~ y/-/_/;
 716 $cmdfn = ${*::}{"cmd_$cmdfn"};
 717
 718 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 719 $cmdfn->();