git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> <orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] launder         # prints breakwater tip etc.
  32 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  33 #
  34 #    git-debrebase [<options>] gbp2debrebase-v0 \
  35 #             <upstream>
  36
  37 # problems / outstanding questions:
  38 #
  39 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  40 #     fixup.  Usually this involves recommitting the whole patch
  41 #     series, one at a time, with dpkg-source --commit.  This is
  42 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  43 #
  44 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  45 #    git-debrebase stripped out the previous pseudomerge and could
  46 #    have remembeed the HEAD.  But it's not quite clear what history
  47 #    ought to be preserved and what should be discarded.  For now
  48 #    the user will have to tell dgit --overwrite.
  49 #
  50 #    To fix this, do we need a new push hook for dgit ?
  51 #
  52 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  53 #    There's not even a guide.
  54 #
  55 #  * There are no tests.
  56 #
  57 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  58 #    runic command lines.
  59 #
  60 #    One consequence of the lack of richness it can need --force in
  61 #    fairly sensible situations and there is no way to tell it what
  62 #    you are really trying to do, other than just --force.  There
  63 #    should be an interface with some default branch names.
  64 #
  65 #  * There should be a standard convention for the version number,
  66 #    and unfinalised or not changelog, after new-upstream.
  67 #
  68 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  69 #    be broken.  They may be not recognised, improperly converted, or
  70 #    their conversion may be unrecognised.
  71 #
  72 #  * Docs need writing and updating.  Even README.git-debrebase
  73 #    describes a design but may not reflect the implementation.
  74 #
  75 #  * We need to develop a plausible model that works for derivatives,
  76 #    who probably want to maintain their stack on top of Debian's.
  77 #    downstream-rebase-launder-v0 may be a starting point?
  78
  79 use strict;
  80
  81 use Debian::Dgit qw(:DEFAULT :playground);
  82 setup_sigwarn();
  83
  84 use Memoize;
  85 use Carp;
  86 use POSIX;
  87 use Data::Dumper;
  88 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  89 use Dpkg::Version;
  90
  91 our ($opt_force);
  92
  93 sub badusage ($) {
  94     my ($m) = @_;
  95     die "bad usage: $m\n";
  96 }
  97
  98 sub cfg ($) {
  99     my ($k) = @_;
 100     $/ = "\0";
 101     my @cmd = qw(git config -z);
 102     push @cmd, qw(--get-all) if wantarray;
 103     push @cmd, $k;
 104     my $out = cmdoutput @cmd;
 105     return split /\0/, $out;
 106 }
 107
 108 memoize('cfg');
 109
 110 sub dd ($) {
 111     my ($v) = @_;
 112     my $dd = new Data::Dumper [ $v ];
 113     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 114     return Dump $dd;
 115 }
 116
 117 sub get_commit ($) {
 118     my ($objid) = @_;
 119     my $data = (git_cat_file $objid, 'commit');
 120     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 121     return ($`,$');
 122 }
 123
 124 sub D_UPS ()      { 0x02; } # upstream files
 125 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 126 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 127 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 128 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 129 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 130
 131 our $playprefix = 'debrebase';
 132 our $rd;
 133 our $workarea;
 134
 135 our @git = qw(git);
 136
 137 sub in_workarea ($) {
 138     my ($sub) = @_;
 139     changedir $workarea;
 140     my $r = eval { $sub->(); };
 141     { local $@; changedir $maindir; }
 142     die $@ if $@;
 143 }
 144
 145 sub fresh_workarea () {
 146     $workarea = fresh_playground "$playprefix/work";
 147     in_workarea sub { playtree_setup };
 148 }
 149
 150 sub get_differs ($$) {
 151     my ($x,$y) = @_;
 152     # This resembles quiltify_trees_differ, in dgit, a bit.
 153     # But we don't care about modes, or dpkg-source-unrepresentable
 154     # changes, and we don't need the plethora of different modes.
 155     # Conversely we need to distinguish different kinds of changes to
 156     # debian/ and debian/patches/.
 157
 158     my $differs = 0;
 159
 160     my $rundiff = sub {
 161         my ($opts, $limits, $fn) = @_;
 162         my @cmd = (@git, qw(diff-tree -z --no-renames));
 163         push @cmd, @$opts;
 164         push @cmd, "$_:" foreach $x, $y;
 165         push @cmd, '--', @$limits;
 166         my $diffs = cmdoutput @cmd;
 167         foreach (split /\0/, $diffs) { $fn->(); }
 168     };
 169
 170     $rundiff->([qw(--name-only)], [], sub {
 171         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 172     });
 173
 174     if ($differs & DS_DEB) {
 175         $differs &= ~DS_DEB;
 176         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 177             $differs |=
 178                 m{^debian/patches/}      ? D_PAT_OTH  :
 179                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 180                                            D_DEB_OTH;
 181         });
 182         die "mysterious debian changes $x..$y"
 183             unless $differs & (D_PAT_OTH|DS_DEB);
 184     }
 185
 186     if ($differs & D_PAT_OTH) {
 187         my $mode;
 188         $differs &= ~D_PAT_OTH;
 189         my $pat_oth = sub {
 190             $differs |= D_PAT_OTH;
 191             no warnings qw(exiting);  last;
 192         };
 193         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 194             no warnings qw(exiting);
 195             if (!defined $mode) {
 196                 $mode = $_;  next;
 197             }
 198             die unless s{^debian/patches/}{};
 199             my $ok;
 200             if ($mode eq 'A' && !m/\.series$/s) {
 201                 $ok = 1;
 202             } elsif ($mode eq 'M' && $_ eq 'series') {
 203                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 204                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 205                 chomp $x_s;  $x_s .= "\n";
 206                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 207             } else {
 208                 # nope
 209             }
 210             $mode = undef;
 211             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 212         });
 213         die "mysterious debian/patches changes $x..$y"
 214             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 215     }
 216
 217     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 218
 219     return $differs;
 220 }
 221
 222 sub commit_pr_info ($) {
 223     my ($r) = @_;
 224     return Data::Dumper->dump([$r], [qw(commit)]);
 225 }
 226
 227 sub calculate_committer_authline () {
 228     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 229         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 230     my ($h,$m) = get_commit $c;
 231     $h =~ m/^committer .*$/m or confess "($h) ?";
 232     return $&;
 233 }
 234
 235 sub rm_subdir_cached ($) {
 236     my ($subdir) = @_;
 237     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 238 }
 239
 240 sub read_tree_subdir ($$) {
 241     my ($subdir, $new_tree_object) = @_;
 242     rm_subdir_cached $subdir;
 243     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 244 }
 245
 246 sub make_commit ($$) {
 247     my ($parents, $message_paras) = @_;
 248     my $tree = cmdoutput @git, qw(write-tree);
 249     my @cmd = (@git, qw(commit-tree), $tree);
 250     push @cmd, qw(-p), $_ foreach @$parents;
 251     push @cmd, qw(-m), $_ foreach @$message_paras;
 252     return cmdoutput @cmd;
 253 }
 254
 255 our $fproblems;
 256 sub fproblem ($) {
 257     my ($msg) = @_;
 258     $fproblems++;
 259     print STDERR "git-debrebase: safety catch tripped: $msg\n";
 260 }
 261 sub fproblems_maybe_bail () {
 262     if ($fproblems) {
 263         if ($opt_force) {
 264             printf STDERR
 265                 "safety catch trips (%d) overriden by --force\n",
 266                 $fproblems;
 267         } else {
 268             fail sprintf
 269                 "safety catch trips (%d) (you could --force)",
 270                 $fproblems;
 271         }
 272     }
 273 }
 274
 275 # classify returns an info hash like this
 276 #   CommitId => $objid
 277 #   Hdr => # commit headers, including 1 final newline
 278 #   Msg => # commit message (so one newline is dropped)
 279 #   Tree => $treeobjid
 280 #   Type => (see below)
 281 #   Parents = [ {
 282 #       Ix => $index # ie 0, 1, 2, ...
 283 #       CommitId
 284 #       Differs => return value from get_differs
 285 #       IsOrigin
 286 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 287 #     } ...]
 288 #   NewMsg => # commit message, but with any [dgit import ...] edited
 289 #             # to say "[was: ...]"
 290 #
 291 # Types:
 292 #   Packaging
 293 #   Changelog
 294 #   Upstream
 295 #   AddPatches
 296 #   Mixed
 297 #   Unknown
 298 #
 299 #   Pseudomerge
 300 #     has additional entres in classification result
 301 #       Overwritten = [ subset of Parents ]
 302 #       Contributor = $the_remaining_Parent
 303 #
 304 #   DgitImportUnpatched
 305 #     has additional entry in classification result
 306 #       OrigParents = [ subset of Parents ]
 307 #
 308 #   BreakwaterUpstreamMerge
 309 #     has additional entry in classification result
 310 #       OrigParents = [ subset of Parents ]  # singleton list
 311
 312 sub parsecommit ($;$) {
 313     my ($objid, $p_ref) = @_;
 314     # => hash with                   CommitId Hdr Msg Tree Parents
 315     #    Parents entries have only   Ix CommitId
 316     #    $p_ref, if provided, must be [] and is used as a base for Parents
 317
 318     $p_ref //= [];
 319     die if @$p_ref;
 320
 321     my ($h,$m) = get_commit $objid;
 322
 323     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 324     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 325
 326     my $r = {
 327         CommitId => $objid,
 328         Hdr => $h,
 329         Msg => $m,
 330         Tree => $t,
 331         Parents => $p_ref,
 332     };
 333
 334     foreach my $ph (@ph) {
 335         push @$p_ref, {
 336             Ix => scalar @$p_ref,
 337             CommitId => $ph,
 338         };
 339     }
 340
 341     return $r;
 342 }
 343
 344 sub classify ($) {
 345     my ($objid) = @_;
 346
 347     my @p;
 348     my $r = parsecommit($objid, \@p);
 349     my $t = $r->{Tree};
 350
 351     foreach my $p (@p) {
 352         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 353     }
 354
 355     printdebug "classify $objid \$t=$t \@p",
 356         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 357         "\n";
 358
 359     my $classify = sub {
 360         my ($type, @rest) = @_;
 361         $r = { %$r, Type => $type, @rest };
 362         if ($debuglevel) {
 363             printdebug " = $type ".(dd $r)."\n";
 364         }
 365         return $r;
 366     };
 367     my $unknown = sub {
 368         my ($why) = @_;
 369         $r = { %$r, Type => qw(Unknown) };
 370         printdebug " ** Unknown\n";
 371         return $r;
 372     };
 373
 374     if (@p == 1) {
 375         my $d = $r->{Parents}[0]{Differs};
 376         if ($d == D_PAT_ADD) {
 377             return $classify->(qw(AddPatches));
 378         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 379             return $unknown->("edits debian/patches");
 380         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 381             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 382             if ($ty eq 'tree') {
 383                 if ($d == D_DEB_CLOG) {
 384                     return $classify->(qw(Changelog));
 385                 } else {
 386                     return $classify->(qw(Packaging));
 387                 }
 388             } elsif ($ty eq 'missing') {
 389                 return $classify->(qw(BreakwaterStart));
 390             } else {
 391                 return $unknown->("parent's debian is not a directory");
 392             }
 393         } elsif ($d == D_UPS) {
 394             return $classify->(qw(Upstream));
 395         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 396             return $classify->(qw(Mixed));
 397         } elsif ($d == 0) {
 398             return $unknown->("no changes");
 399         } else {
 400             confess "internal error $objid ?";
 401         }
 402     }
 403     if (!@p) {
 404         return $unknown->("origin commit");
 405     }
 406
 407     my @identical = grep { !$_->{Differs} } @p;
 408     if (@p == 2 && @identical == 1 &&
 409         $r->{Msg} !~ m{^\[git-debrebase breakwater.*\]$}m
 410         # breakwater merges can look like pseudomerges, if they are
 411         # "declare" commits (ie, there are no upstream changes)
 412        ) {
 413         my @overwritten = grep { $_->{Differs} } @p;
 414         confess "internal error $objid ?" unless @overwritten==1;
 415         return $classify->(qw(Pseudomerge),
 416                            Overwritten => $overwritten[0],
 417                            Contributor => $identical[0]);
 418     }
 419     if (@p == 2 && @identical == 2) {
 420         my @bytime = nsort_by {
 421             my ($ph,$pm) = get_commit $_->{CommitId};
 422             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 423             $1;
 424         } @p;
 425         return $classify->(qw(Pseudomerge),
 426                            SubType => qw(Ambiguous),
 427                            Overwritten => $bytime[0],
 428                            Contributor => $bytime[1]);
 429     }
 430     foreach my $p (@p) {
 431         my ($p_h, $p_m) = get_commit $p->{CommitId};
 432         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 433         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 434     }
 435     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 436     my $m2 = $r->{Msg};
 437     if (!(grep { !$_->{IsOrigin} } @p) and
 438         (@orig_ps >= @p - 1) and
 439         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 440         $r->{NewMsg} = $m2;
 441         return $classify->(qw(DgitImportUnpatched),
 442                            OrigParents => \@orig_ps);
 443     }
 444
 445     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 446     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 447
 448     # How to decide about l/r ordering of breakwater merges ?  git
 449     # --topo-order prefers to expand 2nd parent first.  There's
 450     # already an easy rune to look for debian/ history anyway (git log
 451     # debian/) so debian breakwater branch should be 1st parent; that
 452     # way also there's also an easy rune to look for the upstream
 453     # patches (--topo-order).
 454
 455     # The above tells us which way *we* will generate them.  But we
 456     # might encounter ad-hoc breakwater merges generated manually,
 457     # which might be the other way around.  In principle, in some odd
 458     # situations, a breakwater merge might have two identical parents.
 459     # In that case we guess which way round it is (ie, which parent
 460     # has the upstream history).  The order of the 2-iteration loop
 461     # controls which guess we make.
 462
 463     foreach my $prevbrw (qw(0 1)) {
 464         if (@p == 2 &&
 465             !$haspatches &&
 466             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 467             !($p[!$prevbrw]{Differs} & ~DS_DEB) && # no non-debian changess
 468             !($p[$prevbrw]{Differs} & ~D_UPS)) { # no non-upstream changes
 469             return $classify->(qw(BreakwaterUpstreamMerge),
 470                                OrigParents => [ $p[!$prevbrw] ]);
 471         }
 472     }
 473
 474     # multi-orig upstreams are represented with a breakwater merge
 475     # from a single upstream commit which combines the orig tarballs
 476
 477     return $unknown->("complex merge");
 478 }
 479
 480 sub walk ($;$$);
 481 sub walk ($;$$) {
 482     my ($input,
 483         $nogenerate,$report) = @_;
 484     # => ($tip, $breakwater_tip, $last_upstream_merge_in_breakwater)
 485     # (or nothing, if $nogenerate)
 486
 487     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 488
 489     # go through commits backwards
 490     # we generate two lists of commits to apply:
 491     # breakwater branch and upstream patches
 492     my (@brw_cl, @upp_cl, @processed);
 493     my %found;
 494     my $upp_limit;
 495     my @pseudomerges;
 496
 497     my $cl;
 498     my $xmsg = sub {
 499         my ($prose, $info) = @_;
 500         my $ms = $cl->{Msg};
 501         chomp $ms;
 502         $info //= '';
 503         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 504         return (Msg => $ms);
 505     };
 506     my $rewrite_from_here = sub {
 507         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 508         push @brw_cl, $sp_cl;
 509         push @processed, $sp_cl;
 510     };
 511     my $cur = $input;
 512
 513     my $prdelim = "";
 514     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 515
 516     my $prline = sub {
 517         return unless $report;
 518         print $report $prdelim, @_;
 519         $prdelim = "\n";
 520     };
 521
 522     my $bomb = sub { # usage: return $bomb->();
 523         print $report " Unprocessable" if $report;
 524         $prprdelim->();
 525         if ($nogenerate) {
 526             return (undef,undef);
 527         }
 528         die "commit $cur: Cannot cope with this commit (d.".
 529             (join ' ', map { sprintf "%#x", $_->{Differs} }
 530              @{ $cl->{Parents} }). ")";
 531     };
 532
 533     my $build;
 534     my $breakwater;
 535
 536     my $build_start = sub {
 537         my ($msg, $parent) = @_;
 538         $prline->(" $msg");
 539         $build = $parent;
 540         no warnings qw(exiting); last;
 541     };
 542
 543     my $last_upstream_update;
 544
 545     for (;;) {
 546         $cl = classify $cur;
 547         my $ty = $cl->{Type};
 548         my $st = $cl->{SubType};
 549         $prline->("$cl->{CommitId} $cl->{Type}");
 550         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 551         push @processed, $cl;
 552         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 553         if ($ty eq 'AddPatches') {
 554             $cur = $p0;
 555             $rewrite_from_here->();
 556             next;
 557         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 558             push @brw_cl, $cl;
 559             $cur = $p0;
 560             next;
 561         } elsif ($ty eq 'BreakwaterStart') {
 562             $last_upstream_update = $cur;
 563             $build_start->('FirstPackaging', $cur);
 564         } elsif ($ty eq 'Upstream') {
 565             push @upp_cl, $cl;
 566             $cur = $p0;
 567             next;
 568         } elsif ($ty eq 'Mixed') {
 569             my $queue = sub {
 570                 my ($q, $wh) = @_;
 571                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 572                 push @$q, $cls;
 573             };
 574             $queue->(\@brw_cl, "debian");
 575             $queue->(\@upp_cl, "upstream");
 576             $rewrite_from_here->();
 577             $cur = $p0;
 578             next;
 579         } elsif ($ty eq 'Pseudomerge') {
 580             my $contrib = $cl->{Contributor}{CommitId};
 581             print $report " Contributor=$contrib" if $report;
 582             push @pseudomerges, $cl;
 583             $rewrite_from_here->();
 584             $cur = $contrib;
 585             next;
 586         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 587             $last_upstream_update = $cur;
 588             $build_start->("PreviousBreakwater", $cur);
 589         } elsif ($ty eq 'DgitImportUnpatched') {
 590             my $pm = $pseudomerges[-1];
 591             if (defined $pm) {
 592                 # To an extent, this is heuristic.  Imports don't have
 593                 # a useful history of the debian/ branch.  We assume
 594                 # that the first pseudomerge after an import has a
 595                 # useful history of debian/, and ignore the histories
 596                 # from later pseudomerges.  Often the first pseudomerge
 597                 # will be the dgit import of the upload to the actual
 598                 # suite intended by the non-dgit NMUer, and later
 599                 # pseudomerges may represent in-archive copies.
 600                 my $ovwrs = $pm->{Overwritten};
 601                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 602                     if $report;
 603                 if (@$ovwrs != 1) {
 604                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 605                     return $bomb->();
 606                 }
 607                 my $ovwr = $ovwrs->[0]{CommitId};
 608                 printf $report " Overwr=%s", $ovwr if $report;
 609                 # This import has a tree which is just like a
 610                 # breakwater tree, but it has the wrong history.  It
 611                 # ought to have the previous breakwater (which the
 612                 # pseudomerge overwrote) as an ancestor.  That will
 613                 # make the history of the debian/ files correct.  As
 614                 # for the upstream version: either it's the same as
 615                 # was ovewritten (ie, same as the previous
 616                 # breakwater), in which case that history is precisely
 617                 # right; or, otherwise, it was a non-gitish upload of a
 618                 # new upstream version.  We can tell these apart by
 619                 # looking at the tree of the supposed upstream.
 620                 push @brw_cl, {
 621                     %$cl,
 622                     SpecialMethod => 'DgitImportDebianUpdate',
 623                     $xmsg->("convert dgit import: debian changes")
 624                 };
 625                 my $differs = (get_differs $ovwr, $cl->{Tree});
 626                 printf $report " Differs=%#x", $differs if $report;
 627                 if ($differs & D_UPS) {
 628                     printf $report " D_UPS" if $report;
 629                     # This will also trigger if a non-dgit git-based NMU
 630                     # deleted .gitignore (which is a thing that some of
 631                     # the existing git tools do if the user doesn't
 632                     # somehow tell them not to).  Ah well.
 633                     push @brw_cl, {
 634                         %$cl,
 635                         SpecialMethod => 'DgitImportUpstreamUpdate',
 636                         $xmsg->("convert dgit import: upstream changes",
 637                                 " breakwater")
 638                     };
 639                 }
 640                 $prline->(" Import");
 641                 $rewrite_from_here->();
 642                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 643                 die 'BUG $upp_limit is not used anywhere?';
 644                 $cur = $ovwr;
 645                 next;
 646             } else {
 647                 # Everything is from this import.  This kind of import
 648                 # is already in valid breakwater format, with the
 649                 # patches as commits.
 650                 printf $report " NoPM" if $report;
 651                 # last thing we processed will have been the first patch,
 652                 # if there is one; which is fine, so no need to rewrite
 653                 # on account of this import
 654                 $build_start->("ImportOrigin", $cur);
 655             }
 656             die "$ty ?";
 657         } else {
 658             printdebug "*** WALK BOMB unrecognised\n";
 659             return $bomb->();
 660         }
 661     }
 662     $prprdelim->();
 663
 664     printdebug "*** WALK prep done cur=$cur".
 665         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 666
 667     return if $nogenerate;
 668
 669     # Now we build it back up again
 670
 671     fresh_workarea();
 672
 673     my $rewriting = 0;
 674
 675     my $read_tree_debian = sub {
 676         my ($treeish) = @_;
 677         read_tree_subdir 'debian', "$treeish:debian";
 678         rm_subdir_cached 'debian/patches';
 679     };
 680     my $read_tree_upstream = sub {
 681         my ($treeish) = @_;
 682         runcmd @git, qw(read-tree), $treeish;
 683         $read_tree_debian->($build);
 684     };
 685
 686     my $committer_authline = calculate_committer_authline();
 687
 688     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 689
 690     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 691
 692     in_workarea sub {
 693         mkdir $rd or $!==EEXIST or die $!;
 694         my $current_method;
 695         runcmd @git, qw(read-tree), $build;
 696         foreach my $cl (qw(Debian), (reverse @brw_cl),
 697                         { SpecialMethod => 'RecordBreakwaterTip' },
 698                         qw(Upstream), (reverse @upp_cl)) {
 699             if (!ref $cl) {
 700                 $current_method = $cl;
 701                 next;
 702             }
 703             my $method = $cl->{SpecialMethod} // $current_method;
 704             my @parents = ($build);
 705             my $cltree = $cl->{CommitId};
 706             printdebug "WALK BUILD ".($cltree//'undef').
 707                 " $method (rewriting=$rewriting)\n";
 708             if ($method eq 'Debian') {
 709                 $read_tree_debian->($cltree);
 710             } elsif ($method eq 'Upstream') {
 711                 $read_tree_upstream->($cltree);
 712             } elsif ($method eq 'StartRewrite') {
 713                 $rewriting = 1;
 714                 next;
 715             } elsif ($method eq 'RecordBreakwaterTip') {
 716                 $breakwater = $build;
 717                 next;
 718             } elsif ($method eq 'DgitImportDebianUpdate') {
 719                 $read_tree_debian->($cltree);
 720                 rm_subdir_cached qw(debian/patches);
 721             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 722                 $read_tree_upstream->($cltree);
 723                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 724             } else {
 725                 confess "$method ?";
 726             }
 727             if (!$rewriting) {
 728                 my $procd = (pop @processed) // 'UNDEF';
 729                 if ($cl ne $procd) {
 730                     $rewriting = 1;
 731                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 732                 }
 733             }
 734             my $newtree = cmdoutput @git, qw(write-tree);
 735             my $ch = $cl->{Hdr};
 736             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 737             $ch =~ s{^parent .*\n}{}m;
 738             $ch =~ s{(?=^author)}{
 739                 join '', map { "parent $_\n" } @parents
 740             }me or confess "$ch ?";
 741             if ($rewriting) {
 742                 $ch =~ s{^committer .*$}{$committer_authline}m
 743                     or confess "$ch ?";
 744             }
 745             my $cf = "$rd/m$rewriting";
 746             open CD, ">", $cf or die $!;
 747             print CD $ch, "\n", $cl->{Msg} or die $!;
 748             close CD or die $!;
 749             my @cmd = (@git, qw(hash-object));
 750             push @cmd, qw(-w) if $rewriting;
 751             push @cmd, qw(-t commit), $cf;
 752             my $newcommit = cmdoutput @cmd;
 753             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 754             $build = $newcommit;
 755             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 756                 $last_upstream_update = $cur;
 757             }
 758         }
 759     };
 760
 761     my $final_check = get_differs $build, $input;
 762     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 763         if $final_check & ~D_PAT_ADD;
 764
 765     my @r = ($build, $breakwater, $last_upstream_update);
 766     printdebug "*** WALK RETURN @r\n";
 767     return @r
 768 }
 769
 770 sub get_head () { return git_rev_parse qw(HEAD); }
 771
 772 sub update_head ($$$) {
 773     my ($old, $new, $mrest) = @_;
 774     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 775 }
 776
 777 sub update_head_checkout ($$$) {
 778     my ($old, $new, $mrest) = @_;
 779     update_head $old, $new, $mrest;
 780     runcmd @git, qw(reset --hard);
 781 }
 782
 783 sub update_head_postlaunder ($$$) {
 784     my ($old, $tip, $reflogmsg) = @_;
 785     return if $tip eq $old;
 786     print "git-debrebase: laundered (head was $old)\n";
 787     update_head $old, $tip, $reflogmsg;
 788     # no tree changes except debian/patches
 789     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 790 }
 791
 792 sub cmd_launder () {
 793     badusage "no arguments to launder allowed" if @ARGV;
 794     my $old = get_head();
 795     my ($tip,$breakwater,$last_upstream_merge) = walk $old;
 796     update_head_postlaunder $old, $tip, 'launder';
 797     printf "# breakwater tip\n%s\n", $breakwater;
 798     printf "# working tip\n%s\n", $tip;
 799     printf "# last upstream merge\n%s\n", $last_upstream_merge;
 800 }
 801
 802 sub defaultcmd_rebase () {
 803     my $old = get_head();
 804     my ($tip,$breakwater) = walk $old;
 805     update_head_postlaunder $old, $tip, 'launder for rebase';
 806     @ARGV = qw(-i) unless @ARGV; # make configurable
 807     runcmd @git, qw(rebase), @ARGV, $breakwater;
 808 }
 809
 810 sub cmd_analyse () {
 811     die if ($ARGV[0]//'') =~ m/^-/;
 812     badusage "too many arguments to analyse" if @ARGV>1;
 813     my ($old) = @ARGV;
 814     if (defined $old) {
 815         $old = git_rev_parse $old;
 816     } else {
 817         $old = get_head();
 818     }
 819     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 820     STDOUT->error and die $!;
 821 }
 822
 823 sub cmd_new_upstream_v0 () {
 824     # tree should be clean and this is not checked
 825     # automatically and unconditionally launders before rebasing
 826     # if rebase --abort is used, laundering has still been done
 827
 828     my %pieces;
 829
 830     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
 831
 832     # parse args - low commitment
 833     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
 834     my $new_upstream_version = $new_version->version();
 835
 836     my $new_upstream = git_rev_parse shift @ARGV;
 837
 838     my $piece = sub {
 839         my ($n, @x) = @_; # may be ''
 840         my $pc = $pieces{$n} //= {
 841             Name => $n,
 842             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
 843         };
 844         while (my $k = shift @x) { $pc->{$k} = shift @x; }
 845         $pc;
 846     };
 847
 848     my @newpieces;
 849     my $newpiece = sub {
 850         my ($n, @x) = @_; # may be ''
 851         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
 852         push @newpieces, $pc;
 853     };
 854
 855     $newpiece->('',
 856         OldIx => 0,
 857         New => $new_upstream,
 858     );
 859     while (@ARGV && $ARGV[0] !~ m{^-}) {
 860         my $n = shift @ARGV;
 861
 862         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
 863             unless @ARGV && $ARGV[0] !~ m{^-};
 864
 865         my $c = git_rev_parse shift @ARGV;
 866         die unless $n =~ m/^$extra_orig_namepart_re$/;
 867         $newpiece->($n, New => $c);
 868     }
 869
 870     # now we need to investigate the branch this generates the
 871     # laundered version but we don't switch to it yet
 872     my $old_head = get_head();
 873     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
 874
 875     my $old_bw_cl = classify $old_bw;
 876     my $old_upstream_update_cl = classify $old_upstream_update;
 877     confess unless $old_upstream_update_cl->{OrigParents};
 878     my $old_upstream = parsecommit
 879         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
 880
 881     $piece->('', Old => $old_upstream->{CommitId});
 882
 883     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
 884         if ($old_upstream->{Msg} =~
 885  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
 886            ) {
 887             my @oldpieces = ('', split / /, $1);
 888             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
 889             foreach my $i (0..$#oldpieces) {
 890                 my $n = $oldpieces[$i];
 891                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
 892             }
 893         } else {
 894             fproblem "previous upstream $old_upstream->{CommitId} is from".
 895                  " git-debrebase but not an \`upstream-combine' commit";
 896         }
 897     }
 898
 899     foreach my $pc (values %pieces) {
 900         if (!$pc->{Old}) {
 901             fproblem "introducing upstream piece \`$pc->{Name}'";
 902         } elsif (!$pc->{New}) {
 903             fproblem "dropping upstream piece \`$pc->{Name}'";
 904         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
 905             fproblem "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
 906         }
 907     }
 908
 909     printdebug "%pieces = ", (dd \%pieces), "\n";
 910     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
 911
 912     fproblems_maybe_bail();
 913
 914     my $new_bw;
 915
 916     fresh_workarea();
 917     in_workarea sub {
 918         my @upstream_merge_parents;
 919
 920         if (!$fproblems) {
 921             push @upstream_merge_parents, $old_upstream->{CommitId};
 922         }
 923
 924         foreach my $pc (@newpieces) { # always has '' first
 925             if ($pc->{Name}) {
 926                 read_tree_subdir $pc->{Name}, $pc->{New};
 927             } else {
 928                 runcmd @git, qw(read-tree), $pc->{New};
 929             }
 930             push @upstream_merge_parents, $pc->{New};
 931         }
 932
 933         # index now contains the new upstream
 934
 935         if (@newpieces > 1) {
 936             # need to make the upstream subtree merge commit
 937             $new_upstream = make_commit \@upstream_merge_parents,
 938                 [ "Combine upstreams for $new_upstream_version",
 939  ("[git-debrebase upstream-combine . ".
 940  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
 941  ": new upstream]"),
 942                 ];
 943         }
 944
 945         # $new_upstream is either the single upstream commit, or the
 946         # combined commit we just made.  Either way it will be the
 947         # "upstream" parent of the breakwater special merge.
 948
 949         read_tree_subdir 'debian', "$old_bw:debian";
 950
 951         # index now contains the breakwater merge contents
 952         $new_bw = make_commit [ $old_bw, $new_upstream ],
 953             [ "Update to upstream $new_upstream_version",
 954  "[git-debrebase breakwater: new upstream $new_upstream_version, merge]",
 955             ];
 956
 957         # Now we have to add a changelog stanza so the Debian version
 958         # is right.
 959         die if unlink "debian";
 960         die $! unless $!==ENOENT or $!==ENOTEMPTY;
 961         unlink "debian/changelog" or $!==ENOENT or die $!;
 962         mkdir "debian" or die $!;
 963         open CN, ">", "debian/changelog" or die $!;
 964         my $oldclog = git_cat_file ":debian/changelog";
 965         $oldclog =~ m/^($package_re) \(\S+\) / or
 966             fail "cannot parse old changelog to get package name";
 967         my $p = $1;
 968         print CN <<END, $oldclog or die $!;
 969 $p ($new_version) UNRELEASED; urgency=medium
 970
 971   * Update to new upstream version $new_upstream_version.
 972
 973  --
 974
 975 END
 976         close CN or die $!;
 977         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
 978
 979         # Now we have the final new breakwater branch in the index
 980         $new_bw = make_commit [ $new_bw ],
 981             [ "Update changelog for new upstream $new_upstream_version",
 982               "[git-debrebase: new upstream $new_upstream_version, changelog]",
 983             ];
 984     };
 985
 986     # we have constructed the new breakwater. we now need to commit to
 987     # the laundering output, because git-rebase can't easily be made
 988     # to make a replay list which is based on some other branch
 989
 990     update_head_postlaunder $old_head, $old_laundered_tip,
 991         'launder for new upstream';
 992
 993     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
 994     runcmd @cmd;
 995     # now it's for the user to sort out
 996 }
 997
 998 sub cmd_gbp2debrebase () {
 999     badusage "needs 1 optional argument, the upstream" unless @ARGV<=1;
1000     my ($upstream_spec) = @ARGV;
1001     $upstream_spec //= 'refs/heads/upstream';
1002     my $upstream = git_rev_parse $upstream_spec;
1003     my $old_head = get_head();
1004
1005     my $upsdiff = get_differs $upstream, $old_head;
1006     if ($upsdiff & D_UPS) {
1007         runcmd @git, qw(--no-pager diff),
1008             $upstream, $old_head,
1009             qw( -- :!/debian :/);
1010  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1011     }
1012
1013     if (!is_fast_fwd $upstream, $old_head) {
1014         fproblem "upstream ($upstream) is not an ancestor of HEAD";
1015     } else {
1016         my $wrong = cmdoutput
1017             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1018              qw(-- :/ :!/debian));
1019         if (length $wrong) {
1020             fproblem "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1021             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1022         }
1023     }
1024
1025     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1026         fproblem "upstream ($upstream) contains debian/ directory";
1027     }
1028
1029     fproblems_maybe_bail();
1030
1031     my $work;
1032
1033     fresh_workarea();
1034     in_workarea sub {
1035         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1036         # make a branch out of the patch queue - we'll want this in a mo
1037         runcmd qw(gbp pq import);
1038         # strip the patches out
1039         runcmd @git, qw(checkout -q gdr-internal~0);
1040         rm_subdir_cached 'debian/patches';
1041         $work = make_commit ['HEAD'], [
1042  'git-debrebase import: drop patch queue',
1043  'Delete debian/patches, as part of converting to git-debrebase format.',
1044  '[git-debrebase: gbp2debrebase, drop patches]'
1045                               ];
1046         # make the breakwater pseudomerge
1047         # the tree is already exactly right
1048         $work = make_commit [$work, $upstream], [
1049  'git-debrebase import: declare upstream',
1050  'First breakwater merge.',
1051  '[git-debrebase breakwater: declare upstream]'
1052                               ];
1053
1054         # rebase the patch queue onto the new breakwater
1055         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1056         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1057         $work = get_head();
1058     };
1059
1060     update_head_checkout $old_head, $work, 'gbp2debrebase';
1061 }
1062
1063 sub cmd_downstream_rebase_launder_v0 () {
1064     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1065     my ($base) = @ARGV;
1066     $base = git_rev_parse $base;
1067     my $old_head = get_head();
1068     my $current = $old_head;
1069     my $topmost_keep;
1070     for (;;) {
1071         if ($current eq $base) {
1072             $topmost_keep //= $current;
1073             print " $current BASE stop\n";
1074             last;
1075         }
1076         my $cl = classify $current;
1077         print " $current $cl->{Type}";
1078         my $keep = 0;
1079         my $p0 = $cl->{Parents}[0]{CommitId};
1080         my $next;
1081         if ($cl->{Type} eq 'Pseudomerge') {
1082             print " ^".($cl->{Contributor}{Ix}+1);
1083             $next = $cl->{Contributor}{CommitId};
1084         } elsif ($cl->{Type} eq 'AddPatches' or
1085                  $cl->{Type} eq 'Changelog') {
1086             print " strip";
1087             $next = $p0;
1088         } else {
1089             print " keep";
1090             $next = $p0;
1091             $keep = 1;
1092         }
1093         print "\n";
1094         if ($keep) {
1095             $topmost_keep //= $current;
1096         } else {
1097             die "to-be stripped changes not on top of the branch\n"
1098                 if $topmost_keep;
1099         }
1100         $current = $next;
1101     }
1102     if ($topmost_keep eq $old_head) {
1103         print "unchanged\n";
1104     } else {
1105         print "updating to $topmost_keep\n";
1106         update_head_checkout
1107             $old_head, $topmost_keep,
1108             'downstream-rebase-launder-v0';
1109     }
1110 }
1111
1112 GetOptions("D+" => \$debuglevel,
1113            'force!') or die badusage "bad options\n";
1114 initdebug('git-debrebase ');
1115 enabledebug if $debuglevel;
1116
1117 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1118 chdir $toplevel or die "chdir $toplevel: $!";
1119
1120 $rd = fresh_playground "$playprefix/misc";
1121
1122 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1123     defaultcmd_rebase();
1124 } else {
1125     my $cmd = shift @ARGV;
1126     my $cmdfn = $cmd;
1127     $cmdfn =~ y/-/_/;
1128     $cmdfn = ${*::}{"cmd_$cmdfn"};
1129
1130     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1131     $cmdfn->();
1132 }