git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23
  24 use strict;
  25
  26 use Debian::Dgit qw(:DEFAULT :playground);
  27 setup_sigwarn();
  28
  29 use Memoize;
  30 use Carp;
  31 use POSIX;
  32 use Data::Dumper;
  33 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  34 use Dpkg::Version;
  35 use File::FnMatch qw(:fnmatch);
  36
  37 our ($opt_force, $opt_noop_ok, @opt_anchors);
  38 our ($opt_defaultcmd_interactive);
  39
  40 our $us = qw(git-debrebase);
  41
  42 sub badusage ($) {
  43     my ($m) = @_;
  44     print STDERR "bad usage: $m\n";
  45     finish 8;
  46 }
  47
  48 sub cfg ($;$) {
  49     my ($k, $optional) = @_;
  50     local $/ = "\0";
  51     my @cmd = qw(git config -z);
  52     push @cmd, qw(--get-all) if wantarray;
  53     push @cmd, $k;
  54     my $out = cmdoutput_errok @cmd;
  55     if (!defined $out) {
  56         fail "missing required git config $k" unless $optional;
  57         return ();
  58     }
  59     my @l = split /\0/, $out;
  60     return wantarray ? @l : $l[0];
  61 }
  62
  63 memoize('cfg');
  64
  65 sub dd ($) {
  66     my ($v) = @_;
  67     my $dd = new Data::Dumper [ $v ];
  68     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  69     return Dump $dd;
  70 }
  71
  72 sub get_commit ($) {
  73     my ($objid) = @_;
  74     my $data = (git_cat_file $objid, 'commit');
  75     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
  76     return ($`,$');
  77 }
  78
  79 sub D_UPS ()      { 0x02; } # upstream files
  80 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
  81 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
  82 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
  83 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
  84 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
  85
  86 our $playprefix = 'debrebase';
  87 our $rd;
  88 our $workarea;
  89
  90 our @git = qw(git);
  91
  92 sub in_workarea ($) {
  93     my ($sub) = @_;
  94     changedir $workarea;
  95     my $r = eval { $sub->(); };
  96     { local $@; changedir $maindir; }
  97     die $@ if $@;
  98 }
  99
 100 sub fresh_workarea () {
 101     $workarea = fresh_playground "$playprefix/work";
 102     in_workarea sub { playtree_setup };
 103 }
 104
 105 our $snags_forced = 0;
 106 our $snags_tripped = 0;
 107 our $snags_summarised = 0;
 108 our @deferred_updates;
 109 our @deferred_update_messages;
 110
 111 sub all_snags_summarised () {
 112     $snags_forced + $snags_tripped == $snags_summarised;
 113 }
 114 sub run_deferred_updates ($) {
 115     my ($mrest) = @_;
 116
 117     confess 'dangerous internal error' unless all_snags_summarised();
 118
 119     my @upd_cmd = (@git, qw(update-ref --stdin -m), "debrebase: $mrest");
 120     debugcmd '>|', @upd_cmd;
 121     open U, "|-", @upd_cmd or die $!;
 122     foreach (@deferred_updates) {
 123         printdebug ">= ", $_, "\n";
 124         print U $_, "\n" or die $!;
 125     }
 126     printdebug ">\$\n";
 127     close U or failedcmd @upd_cmd;
 128
 129     print $_, "\n" foreach @deferred_update_messages;
 130
 131     @deferred_updates = ();
 132     @deferred_update_messages = ();
 133 }
 134
 135 sub get_differs ($$) {
 136     my ($x,$y) = @_;
 137     # This resembles quiltify_trees_differ, in dgit, a bit.
 138     # But we don't care about modes, or dpkg-source-unrepresentable
 139     # changes, and we don't need the plethora of different modes.
 140     # Conversely we need to distinguish different kinds of changes to
 141     # debian/ and debian/patches/.
 142
 143     my $differs = 0;
 144
 145     my $rundiff = sub {
 146         my ($opts, $limits, $fn) = @_;
 147         my @cmd = (@git, qw(diff-tree -z --no-renames));
 148         push @cmd, @$opts;
 149         push @cmd, "$_:" foreach $x, $y;
 150         push @cmd, '--', @$limits;
 151         my $diffs = cmdoutput @cmd;
 152         foreach (split /\0/, $diffs) { $fn->(); }
 153     };
 154
 155     $rundiff->([qw(--name-only)], [], sub {
 156         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 157     });
 158
 159     if ($differs & DS_DEB) {
 160         $differs &= ~DS_DEB;
 161         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 162             $differs |=
 163                 m{^debian/patches/}      ? D_PAT_OTH  :
 164                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 165                                            D_DEB_OTH;
 166         });
 167         die "mysterious debian changes $x..$y"
 168             unless $differs & (D_PAT_OTH|DS_DEB);
 169     }
 170
 171     if ($differs & D_PAT_OTH) {
 172         my $mode;
 173         $differs &= ~D_PAT_OTH;
 174         my $pat_oth = sub {
 175             $differs |= D_PAT_OTH;
 176             no warnings qw(exiting);  last;
 177         };
 178         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 179             no warnings qw(exiting);
 180             if (!defined $mode) {
 181                 $mode = $_;  next;
 182             }
 183             die unless s{^debian/patches/}{};
 184             my $ok;
 185             if ($mode eq 'A' && !m/\.series$/s) {
 186                 $ok = 1;
 187             } elsif ($mode eq 'M' && $_ eq 'series') {
 188                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 189                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 190                 chomp $x_s;  $x_s .= "\n";
 191                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 192             } else {
 193                 # nope
 194             }
 195             $mode = undef;
 196             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 197         });
 198         die "mysterious debian/patches changes $x..$y"
 199             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 200     }
 201
 202     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 203
 204     return $differs;
 205 }
 206
 207 sub commit_pr_info ($) {
 208     my ($r) = @_;
 209     return Data::Dumper->dump([$r], [qw(commit)]);
 210 }
 211
 212 sub calculate_committer_authline () {
 213     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 214         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 215     my ($h,$m) = get_commit $c;
 216     $h =~ m/^committer .*$/m or confess "($h) ?";
 217     return $&;
 218 }
 219
 220 sub rm_subdir_cached ($) {
 221     my ($subdir) = @_;
 222     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 223 }
 224
 225 sub read_tree_subdir ($$) {
 226     my ($subdir, $new_tree_object) = @_;
 227     rm_subdir_cached $subdir;
 228     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 229 }
 230
 231 sub make_commit ($$) {
 232     my ($parents, $message_paras) = @_;
 233     my $tree = cmdoutput @git, qw(write-tree);
 234     my @cmd = (@git, qw(commit-tree), $tree);
 235     push @cmd, qw(-p), $_ foreach @$parents;
 236     push @cmd, qw(-m), $_ foreach @$message_paras;
 237     return cmdoutput @cmd;
 238 }
 239
 240 our @snag_force_opts;
 241 sub snag ($$;@) {
 242     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 243     if (grep { $_ eq $tag } @snag_force_opts) {
 244         $snags_forced++;
 245         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 246     } else {
 247         $snags_tripped++;
 248         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 249     }
 250 }
 251
 252 # Important: all mainline code must call snags_maybe_bail after
 253 # any point where snag might be called, but before making changes
 254 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 255 # may be called more than once if necessary (but this is not ideal
 256 # because then the messages about number of snags may be confusing).
 257 sub snags_maybe_bail () {
 258     return if all_snags_summarised();
 259     if ($snags_forced) {
 260         printf STDERR
 261             "%s: snags: %d overriden by individual -f options\n",
 262             $us, $snags_forced;
 263     }
 264     if ($snags_tripped) {
 265         if ($opt_force) {
 266             printf STDERR
 267                 "%s: snags: %d overriden by global --force\n",
 268                 $us, $snags_tripped;
 269         } else {
 270             fail sprintf
 271   "%s: snags: %d blockers (you could -f<tag>, or --force)",
 272                 $us, $snags_tripped;
 273         }
 274     }
 275     $snags_summarised = $snags_forced + $snags_tripped;
 276 }
 277 sub any_snags () {
 278     return $snags_forced || $snags_tripped;
 279 }
 280
 281 # classify returns an info hash like this
 282 #   CommitId => $objid
 283 #   Hdr => # commit headers, including 1 final newline
 284 #   Msg => # commit message (so one newline is dropped)
 285 #   Tree => $treeobjid
 286 #   Type => (see below)
 287 #   Parents = [ {
 288 #       Ix => $index # ie 0, 1, 2, ...
 289 #       CommitId
 290 #       Differs => return value from get_differs
 291 #       IsOrigin
 292 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 293 #     } ...]
 294 #   NewMsg => # commit message, but with any [dgit import ...] edited
 295 #             # to say "[was: ...]"
 296 #
 297 # Types:
 298 #   Packaging
 299 #   Changelog
 300 #   Upstream
 301 #   AddPatches
 302 #   Mixed
 303 #
 304 #   Pseudomerge
 305 #     has additional entres in classification result
 306 #       Overwritten = [ subset of Parents ]
 307 #       Contributor = $the_remaining_Parent
 308 #
 309 #   DgitImportUnpatched
 310 #     has additional entry in classification result
 311 #       OrigParents = [ subset of Parents ]
 312 #
 313 #   Anchor
 314 #     has additional entry in classification result
 315 #       OrigParents = [ subset of Parents ]  # singleton list
 316 #
 317 #   TreatAsAnchor
 318 #
 319 #   BreakwaterStart
 320 #
 321 #   Unknown
 322 #     has additional entry in classification result
 323 #       Why => "prose"
 324
 325 sub parsecommit ($;$) {
 326     my ($objid, $p_ref) = @_;
 327     # => hash with                   CommitId Hdr Msg Tree Parents
 328     #    Parents entries have only   Ix CommitId
 329     #    $p_ref, if provided, must be [] and is used as a base for Parents
 330
 331     $p_ref //= [];
 332     die if @$p_ref;
 333
 334     my ($h,$m) = get_commit $objid;
 335
 336     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 337     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 338
 339     my $r = {
 340         CommitId => $objid,
 341         Hdr => $h,
 342         Msg => $m,
 343         Tree => $t,
 344         Parents => $p_ref,
 345     };
 346
 347     foreach my $ph (@ph) {
 348         push @$p_ref, {
 349             Ix => scalar @$p_ref,
 350             CommitId => $ph,
 351         };
 352     }
 353
 354     return $r;
 355 }
 356
 357 sub classify ($) {
 358     my ($objid) = @_;
 359
 360     my @p;
 361     my $r = parsecommit($objid, \@p);
 362     my $t = $r->{Tree};
 363
 364     foreach my $p (@p) {
 365         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 366     }
 367
 368     printdebug "classify $objid \$t=$t \@p",
 369         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 370         "\n";
 371
 372     my $classify = sub {
 373         my ($type, @rest) = @_;
 374         $r = { %$r, Type => $type, @rest };
 375         if ($debuglevel) {
 376             printdebug " = $type ".(dd $r)."\n";
 377         }
 378         return $r;
 379     };
 380     my $unknown = sub {
 381         my ($why) = @_;
 382         $r = { %$r, Type => qw(Unknown), Why => $why };
 383         printdebug " ** Unknown\n";
 384         return $r;
 385     };
 386
 387     if (grep { $_ eq $objid } @opt_anchors) {
 388         return $classify->('TreatAsAnchor');
 389     }
 390
 391     my @identical = grep { !$_->{Differs} } @p;
 392     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 393     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 394
 395     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 396         # multi-orig upstreams are represented with an anchor merge
 397         # from a single upstream commit which combines the orig tarballs
 398
 399         # Every anchor tagged this way must be a merge.
 400         # We are relying on the
 401         #     [git-debrebase anchor: ...]
 402         # commit message annotation in "declare" anchor merges (which
 403         # do not have any upstream changes), to distinguish those
 404         # anchor merges from ordinary pseudomerges (which we might
 405         # just try to strip).
 406         #
 407         # However, the user is going to be doing git-rebase a lot.  We
 408         # really don't want them to rewrite an anchor commit.
 409         # git-rebase trips up on merges, so that is a useful safety
 410         # catch.
 411         #
 412         # BreakwaterStart commits are also anchors in the terminology
 413         # of git-debrebase(5), but they are untagged (and always
 414         # manually generated).
 415         #
 416         # We cannot not tolerate any tagged linear commit (ie,
 417         # BreakwaterStart commits tagged `[anchor:') because such a
 418         # thing could result from an erroneous linearising raw git
 419         # rebase of a merge anchor.  That would represent a corruption
 420         # of the branch. and we want to detect and reject the results
 421         # of such corruption before it makes it out anywhere.  If we
 422         # reject it here then we avoid making the pseudomerge which
 423         # would be needed to push it.
 424
 425         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 426         @p == 2 or return $badanchor->("has other than two parents");
 427         $haspatches and return $badanchor->("contains debian/patches");
 428
 429         # How to decide about l/r ordering of anchors ?  git
 430         # --topo-order prefers to expand 2nd parent first.  There's
 431         # already an easy rune to look for debian/ history anyway (git log
 432         # debian/) so debian breakwater branch should be 1st parent; that
 433         # way also there's also an easy rune to look for the upstream
 434         # patches (--topo-order).
 435
 436         # Also this makes --first-parent be slightly more likely to
 437         # be useful - it makes it provide a linearised breakwater history.
 438
 439         # Of course one can say somthing like
 440         #  gitk -- ':/' ':!/debian'
 441         # to get _just_ the commits touching upstream files, and by
 442         # the TREESAME logic in git-rev-list this will leave the
 443         # breakwater into upstream at the first anchor.  But that
 444         # doesn't report debian/ changes at all.
 445
 446         # Other observations about gitk: by default, gitk seems to
 447         # produce output in a different order to git-rev-list.  I
 448         # can't seem to find this documented anywhere.  gitk
 449         # --date-order DTRT.  But, gitk always seems to put the
 450         # parents from left to right, in order, so it's easy to see
 451         # which way round a pseudomerge is.
 452
 453         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 454         $p[1]{Differs} & ~DS_DEB and
 455             $badanchor->("upstream files differ from left parent");
 456         $p[0]{Differs} & ~D_UPS and
 457             $badanchor->("debian/ differs from right parent");
 458
 459         return $classify->(qw(Anchor),
 460                            OrigParents => [ $p[1] ]);
 461     }
 462
 463     if (@p == 1) {
 464         my $d = $r->{Parents}[0]{Differs};
 465         if ($d == D_PAT_ADD) {
 466             return $classify->(qw(AddPatches));
 467         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 468             return $unknown->("edits debian/patches");
 469         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 470             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 471             if ($ty eq 'tree') {
 472                 if ($d == D_DEB_CLOG) {
 473                     return $classify->(qw(Changelog));
 474                 } else {
 475                     return $classify->(qw(Packaging));
 476                 }
 477             } elsif ($ty eq 'missing') {
 478                 return $classify->(qw(BreakwaterStart));
 479             } else {
 480                 return $unknown->("parent's debian is not a directory");
 481             }
 482         } elsif ($d == D_UPS) {
 483             return $classify->(qw(Upstream));
 484         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 485             return $classify->(qw(Mixed));
 486         } elsif ($d == 0) {
 487             return $unknown->("no changes");
 488         } else {
 489             confess "internal error $objid ?";
 490         }
 491     }
 492     if (!@p) {
 493         return $unknown->("origin commit");
 494     }
 495
 496     if (@p == 2 && @identical == 1) {
 497         my @overwritten = grep { $_->{Differs} } @p;
 498         confess "internal error $objid ?" unless @overwritten==1;
 499         return $classify->(qw(Pseudomerge),
 500                            Overwritten => [ $overwritten[0] ],
 501                            Contributor => $identical[0]);
 502     }
 503     if (@p == 2 && @identical == 2) {
 504         my $get_t = sub {
 505             my ($ph,$pm) = get_commit $_[0]{CommitId};
 506             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 507             $1;
 508         };
 509         my @bytime = @p;
 510         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 511         if ($order > 0) { # newer first
 512         } elsif ($order < 0) {
 513             @bytime = reverse @bytime;
 514         } else {
 515             # same age, default to order made by -s ours
 516             # that is, commit was made by someone who preferred L
 517         }
 518         return $classify->(qw(Pseudomerge),
 519                            SubType => qw(Ambiguous),
 520                            Contributor => $bytime[0],
 521                            Overwritten => [ $bytime[1] ]);
 522     }
 523     foreach my $p (@p) {
 524         my ($p_h, $p_m) = get_commit $p->{CommitId};
 525         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 526         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 527     }
 528     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 529     my $m2 = $r->{Msg};
 530     if (!(grep { !$_->{IsOrigin} } @p) and
 531         (@orig_ps >= @p - 1) and
 532         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 533         $r->{NewMsg} = $m2;
 534         return $classify->(qw(DgitImportUnpatched),
 535                            OrigParents => \@orig_ps);
 536     }
 537
 538     return $unknown->("complex merge");
 539 }
 540
 541 sub keycommits ($;$$$) {
 542     my ($head, $furniture, $unclean, $trouble) = @_;
 543     # => ($anchor, $breakwater)
 544
 545     # $unclean->("unclean-$tagsfx", $msg, $cl)
 546     # $furniture->("unclean-$tagsfx", $msg, $cl)
 547     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 548     #   is callled for each situation or commit that
 549     #   wouldn't be found in a laundered branch
 550     # $furniture is for furniture commits such as might be found on an
 551     #   interchange branch (pseudomerge, d/patches, changelog)
 552     # $trouble is for things whnich prevent the return of
 553     #   anchor and breakwater information; if that is ignored,
 554     #   then keycommits returns (undef, undef) instead.
 555     #
 556     # If a callback is undef, fail is called instead.
 557     # If a callback is defined but false, the situation is ignored.
 558     # Callbacks may say:
 559     #   no warnings qw(exiting); last;
 560     # if the answer is no longer wanted.
 561
 562     my ($anchor, $breakwater);
 563     my $clogonly;
 564     my $cl;
 565     my $x = sub {
 566         my ($cb, $tagsfx, $why) = @_;
 567         my $m = "branch needs laundering (run git-debrebase): $why";
 568         fail $m unless defined $cb;
 569         return unless $cb;
 570         $cb->("unclean-$tagsfx", $why, $cl);
 571     };
 572     for (;;) {
 573         $cl = classify $head;
 574         my $ty = $cl->{Type};
 575         if ($ty eq 'Packaging') {
 576             $breakwater //= $clogonly;
 577             $breakwater //= $head;
 578         } elsif ($ty eq 'Changelog') {
 579             # this is going to count as the tip of the breakwater
 580             # only if it has no upstream stuff before it
 581             $clogonly //= $head;
 582         } elsif ($ty eq 'Anchor' or
 583                  $ty eq 'TreatAsAnchor' or
 584                  $ty eq 'BreakwaterStart') {
 585             $anchor = $head;
 586             $breakwater //= $clogonly;
 587             $breakwater //= $head;
 588             last;
 589         } elsif ($ty eq 'Upstream') {
 590             $x->($unclean, 'ordering',
 591  "packaging change ($breakwater) follows upstream change (eg $head)")
 592                 if defined $breakwater;
 593             $clogonly = undef;
 594             $breakwater = undef;
 595         } elsif ($ty eq 'Mixed') {
 596             $x->($unclean, 'mixed',
 597                  "found mixed upstream/packaging commit ($head)");
 598             $clogonly = undef;
 599             $breakwater = undef;
 600         } elsif ($ty eq 'Pseudomerge' or
 601                  $ty eq 'AddPatches') {
 602             $x->($furniture, (lc $ty),
 603                  "found interchange bureaucracy commit ($ty, $head)");
 604         } elsif ($ty eq 'DgitImportUnpatched') {
 605             $x->($trouble, 'dgitimport',
 606                  "found dgit dsc import ($head)");
 607             return (undef,undef);
 608         } else {
 609             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 610         }
 611         $head = $cl->{Parents}[0]{CommitId};
 612     }
 613     return ($anchor, $breakwater);
 614 }
 615
 616 sub walk ($;$$);
 617 sub walk ($;$$) {
 618     my ($input,
 619         $nogenerate,$report) = @_;
 620     # => ($tip, $breakwater_tip, $last_anchor)
 621     # (or nothing, if $nogenerate)
 622
 623     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 624
 625     # go through commits backwards
 626     # we generate two lists of commits to apply:
 627     # breakwater branch and upstream patches
 628     my (@brw_cl, @upp_cl, @processed);
 629     my %found;
 630     my $upp_limit;
 631     my @pseudomerges;
 632
 633     my $cl;
 634     my $xmsg = sub {
 635         my ($prose, $info) = @_;
 636         my $ms = $cl->{Msg};
 637         chomp $ms;
 638         $info //= '';
 639         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 640         return (Msg => $ms);
 641     };
 642     my $rewrite_from_here = sub {
 643         my ($cl) = @_;
 644         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 645         push @$cl, $sp_cl;
 646         push @processed, $sp_cl;
 647     };
 648     my $cur = $input;
 649
 650     my $prdelim = "";
 651     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 652
 653     my $prline = sub {
 654         return unless $report;
 655         print $report $prdelim, @_;
 656         $prdelim = "\n";
 657     };
 658
 659     my $bomb = sub { # usage: return $bomb->();
 660         print $report " Unprocessable" if $report;
 661         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 662         $prprdelim->();
 663         if ($nogenerate) {
 664             return (undef,undef);
 665         }
 666         die "commit $cur: Cannot cope with this commit (d.".
 667             (join ' ', map { sprintf "%#x", $_->{Differs} }
 668              @{ $cl->{Parents} }).
 669             (defined $cl->{Why} ? "; $cl->{Why}": '').
 670                  ")";
 671     };
 672
 673     my $build;
 674     my $breakwater;
 675
 676     my $build_start = sub {
 677         my ($msg, $parent) = @_;
 678         $prline->(" $msg");
 679         $build = $parent;
 680         no warnings qw(exiting); last;
 681     };
 682
 683     my $last_anchor;
 684
 685     for (;;) {
 686         $cl = classify $cur;
 687         my $ty = $cl->{Type};
 688         my $st = $cl->{SubType};
 689         $prline->("$cl->{CommitId} $cl->{Type}");
 690         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 691         push @processed, $cl;
 692         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 693         if ($ty eq 'AddPatches') {
 694             $cur = $p0;
 695             $rewrite_from_here->(\@upp_cl);
 696             next;
 697         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 698             push @brw_cl, $cl;
 699             $cur = $p0;
 700             next;
 701         } elsif ($ty eq 'BreakwaterStart') {
 702             $last_anchor = $cur;
 703             $build_start->('FirstPackaging', $cur);
 704         } elsif ($ty eq 'Upstream') {
 705             push @upp_cl, $cl;
 706             $cur = $p0;
 707             next;
 708         } elsif ($ty eq 'Mixed') {
 709             my $queue = sub {
 710                 my ($q, $wh) = @_;
 711                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 712                 push @$q, $cls;
 713             };
 714             $queue->(\@brw_cl, "debian");
 715             $queue->(\@upp_cl, "upstream");
 716             $rewrite_from_here->(\@brw_cl);
 717             $cur = $p0;
 718             next;
 719         } elsif ($ty eq 'Pseudomerge') {
 720             my $contrib = $cl->{Contributor}{CommitId};
 721             print $report " Contributor=$contrib" if $report;
 722             push @pseudomerges, $cl;
 723             $rewrite_from_here->(\@upp_cl);
 724             $cur = $contrib;
 725             next;
 726         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 727             $last_anchor = $cur;
 728             $build_start->("Anchor", $cur);
 729         } elsif ($ty eq 'DgitImportUnpatched') {
 730             my $pm = $pseudomerges[-1];
 731             if (defined $pm) {
 732                 # To an extent, this is heuristic.  Imports don't have
 733                 # a useful history of the debian/ branch.  We assume
 734                 # that the first pseudomerge after an import has a
 735                 # useful history of debian/, and ignore the histories
 736                 # from later pseudomerges.  Often the first pseudomerge
 737                 # will be the dgit import of the upload to the actual
 738                 # suite intended by the non-dgit NMUer, and later
 739                 # pseudomerges may represent in-archive copies.
 740                 my $ovwrs = $pm->{Overwritten};
 741                 printf $report " PM=%s \@Overwr:%d",
 742                     $pm->{CommitId}, (scalar @$ovwrs)
 743                     if $report;
 744                 if (@$ovwrs != 1) {
 745                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 746                     return $bomb->();
 747                 }
 748                 my $ovwr = $ovwrs->[0]{CommitId};
 749                 printf $report " Overwr=%s", $ovwr if $report;
 750                 # This import has a tree which is just like a
 751                 # breakwater tree, but it has the wrong history.  It
 752                 # ought to have the previous breakwater (which the
 753                 # pseudomerge overwrote) as an ancestor.  That will
 754                 # make the history of the debian/ files correct.  As
 755                 # for the upstream version: either it's the same as
 756                 # was ovewritten (ie, same as the previous
 757                 # breakwater), in which case that history is precisely
 758                 # right; or, otherwise, it was a non-gitish upload of a
 759                 # new upstream version.  We can tell these apart by
 760                 # looking at the tree of the supposed upstream.
 761                 push @brw_cl, {
 762                     %$cl,
 763                     SpecialMethod => 'DgitImportDebianUpdate',
 764                     $xmsg->("convert dgit import: debian changes")
 765                 }, {
 766                     %$cl,
 767                     SpecialMethod => 'DgitImportUpstreamUpdate',
 768                     $xmsg->("convert dgit import: upstream update",
 769                             " anchor")
 770                 };
 771                 $prline->(" Import");
 772                 $rewrite_from_here->(\@brw_cl);
 773                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 774                 $cur = $ovwr;
 775                 next;
 776             } else {
 777                 # Everything is from this import.  This kind of import
 778                 # is already in valid breakwater format, with the
 779                 # patches as commits.
 780                 printf $report " NoPM" if $report;
 781                 # last thing we processed will have been the first patch,
 782                 # if there is one; which is fine, so no need to rewrite
 783                 # on account of this import
 784                 $build_start->("ImportOrigin", $cur);
 785             }
 786             die "$ty ?";
 787         } else {
 788             printdebug "*** WALK BOMB unrecognised\n";
 789             return $bomb->();
 790         }
 791     }
 792     $prprdelim->();
 793
 794     printdebug "*** WALK prep done cur=$cur".
 795         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 796
 797     return if $nogenerate;
 798
 799     # Now we build it back up again
 800
 801     fresh_workarea();
 802
 803     my $rewriting = 0;
 804
 805     my $read_tree_debian = sub {
 806         my ($treeish) = @_;
 807         read_tree_subdir 'debian', "$treeish:debian";
 808         rm_subdir_cached 'debian/patches';
 809     };
 810     my $read_tree_upstream = sub {
 811         my ($treeish) = @_;
 812         runcmd @git, qw(read-tree), $treeish;
 813         $read_tree_debian->($build);
 814     };
 815
 816     $#upp_cl = $upp_limit if defined $upp_limit;
 817
 818     my $committer_authline = calculate_committer_authline();
 819
 820     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 821
 822     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 823
 824     in_workarea sub {
 825         mkdir $rd or $!==EEXIST or die $!;
 826         my $current_method;
 827         runcmd @git, qw(read-tree), $build;
 828         foreach my $cl (qw(Debian), (reverse @brw_cl),
 829                         { SpecialMethod => 'RecordBreakwaterTip' },
 830                         qw(Upstream), (reverse @upp_cl)) {
 831             if (!ref $cl) {
 832                 $current_method = $cl;
 833                 next;
 834             }
 835             my $method = $cl->{SpecialMethod} // $current_method;
 836             my @parents = ($build);
 837             my $cltree = $cl->{CommitId};
 838             printdebug "WALK BUILD ".($cltree//'undef').
 839                 " $method (rewriting=$rewriting)\n";
 840             if ($method eq 'Debian') {
 841                 $read_tree_debian->($cltree);
 842             } elsif ($method eq 'Upstream') {
 843                 $read_tree_upstream->($cltree);
 844             } elsif ($method eq 'StartRewrite') {
 845                 $rewriting = 1;
 846                 next;
 847             } elsif ($method eq 'RecordBreakwaterTip') {
 848                 $breakwater = $build;
 849                 next;
 850             } elsif ($method eq 'DgitImportDebianUpdate') {
 851                 $read_tree_debian->($cltree);
 852             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 853                 confess unless $rewriting;
 854                 my $differs = (get_differs $build, $cltree);
 855                 next unless $differs & D_UPS;
 856                 $read_tree_upstream->($cltree);
 857                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 858             } else {
 859                 confess "$method ?";
 860             }
 861             if (!$rewriting) {
 862                 my $procd = (pop @processed) // 'UNDEF';
 863                 if ($cl ne $procd) {
 864                     $rewriting = 1;
 865                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 866                 }
 867             }
 868             my $newtree = cmdoutput @git, qw(write-tree);
 869             my $ch = $cl->{Hdr};
 870             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 871             $ch =~ s{^parent .*\n}{}mg;
 872             $ch =~ s{(?=^author)}{
 873                 join '', map { "parent $_\n" } @parents
 874             }me or confess "$ch ?";
 875             if ($rewriting) {
 876                 $ch =~ s{^committer .*$}{$committer_authline}m
 877                     or confess "$ch ?";
 878             }
 879             my $cf = "$rd/m$rewriting";
 880             open CD, ">", $cf or die $!;
 881             print CD $ch, "\n", $cl->{Msg} or die $!;
 882             close CD or die $!;
 883             my @cmd = (@git, qw(hash-object));
 884             push @cmd, qw(-w) if $rewriting;
 885             push @cmd, qw(-t commit), $cf;
 886             my $newcommit = cmdoutput @cmd;
 887             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 888             $build = $newcommit;
 889             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 890                 $last_anchor = $cur;
 891             }
 892         }
 893     };
 894
 895     my $final_check = get_differs $build, $input;
 896     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 897         if $final_check & ~D_PAT_ADD;
 898
 899     my @r = ($build, $breakwater, $last_anchor);
 900     printdebug "*** WALK RETURN @r\n";
 901     return @r
 902 }
 903
 904 sub get_head () {
 905     git_check_unmodified();
 906     return git_rev_parse qw(HEAD);
 907 }
 908
 909 sub update_head ($$$) {
 910     my ($old, $new, $mrest) = @_;
 911     push @deferred_updates, "update HEAD $new $old";
 912     run_deferred_updates $mrest;
 913 }
 914
 915 sub update_head_checkout ($$$) {
 916     my ($old, $new, $mrest) = @_;
 917     update_head $old, $new, $mrest;
 918     runcmd @git, qw(reset --hard);
 919 }
 920
 921 sub update_head_postlaunder ($$$) {
 922     my ($old, $tip, $reflogmsg) = @_;
 923     return if $tip eq $old;
 924     print "git-debrebase: laundered (head was $old)\n";
 925     update_head $old, $tip, $reflogmsg;
 926     # no tree changes except debian/patches
 927     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 928 }
 929
 930 sub do_launder_head ($) {
 931     my ($reflogmsg) = @_;
 932     my $old = get_head();
 933     record_ffq_auto();
 934     my ($tip,$breakwater) = walk $old;
 935     snags_maybe_bail();
 936     update_head_postlaunder $old, $tip, $reflogmsg;
 937     return ($tip,$breakwater);
 938 }
 939
 940 sub cmd_launder_v0 () {
 941     badusage "no arguments to launder-v0 allowed" if @ARGV;
 942     my $old = get_head();
 943     my ($tip,$breakwater,$last_anchor) = walk $old;
 944     update_head_postlaunder $old, $tip, 'launder';
 945     printf "# breakwater tip\n%s\n", $breakwater;
 946     printf "# working tip\n%s\n", $tip;
 947     printf "# last anchor\n%s\n", $last_anchor;
 948 }
 949
 950 sub defaultcmd_rebase () {
 951     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
 952     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
 953     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
 954 }
 955
 956 sub cmd_analyse () {
 957     die if ($ARGV[0]//'') =~ m/^-/;
 958     badusage "too many arguments to analyse" if @ARGV>1;
 959     my ($old) = @ARGV;
 960     if (defined $old) {
 961         $old = git_rev_parse $old;
 962     } else {
 963         $old = git_rev_parse 'HEAD';
 964     }
 965     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 966     STDOUT->error and die $!;
 967 }
 968
 969 sub ffq_prev_branchinfo () {
 970     # => ('status', "message", [$current, $ffq_prev, $gdrlast])
 971     # 'status' may be
 972     #    branch         message is undef
 973     #    weird-symref   } no $current,
 974     #    notbranch      }  no $ffq_prev
 975     my $current = git_get_symref();
 976     return ('detached', 'detached HEAD') unless defined $current;
 977     return ('weird-symref', 'HEAD symref is not to refs/')
 978         unless $current =~ m{^refs/};
 979     my $ffq_prev = "refs/$ffq_refprefix/$'";
 980     my $gdrlast = "refs/$gdrlast_refprefix/$'";
 981     printdebug "ffq_prev_branchinfo branch current $current\n";
 982     return ('branch', undef, $current, $ffq_prev, $gdrlast);
 983 }
 984
 985 sub record_ffq_prev_deferred () {
 986     # => ('status', "message")
 987     # 'status' may be
 988     #    deferred          message is undef
 989     #    exists
 990     #    detached
 991     #    weird-symref
 992     #    notbranch
 993     # if not ff from some branch we should be ff from, is an snag
 994     # if "deferred", will have added something about that to
 995     #   @deferred_update_messages, and also maybe printed (already)
 996     #   some messages about ff checks
 997     my ($status, $message, $current, $ffq_prev, $gdrlast)
 998         = ffq_prev_branchinfo();
 999     return ($status, $message) unless $status eq 'branch';
1000
1001     my $currentval = get_head();
1002
1003     my $exists = git_get_ref $ffq_prev;
1004     return ('exists',"$ffq_prev already exists") if $exists;
1005
1006     return ('not-branch', 'HEAD symref is not to refs/heads/')
1007         unless $current =~ m{^refs/heads/};
1008     my $branch = $';
1009
1010     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1011     my %checked;
1012
1013     printdebug "ffq check_specs @check_specs\n";
1014
1015     my $check = sub {
1016         my ($lrref, $desc) = @_;
1017         printdebug "ffq might check $lrref ($desc)\n";
1018         my $invert;
1019         for my $chk (@check_specs) {
1020             my $glob = $chk;
1021             $invert = $glob =~ s{^[!^]}{};
1022             last if fnmatch $glob, $lrref;
1023         }
1024         return if $invert;
1025         my $lrval = git_get_ref $lrref;
1026         return unless defined $lrval;
1027
1028         if (is_fast_fwd $lrval, $currentval) {
1029             print "OK, you are ahead of $lrref\n" or die $!;
1030             $checked{$lrref} = 1;
1031         } elsif (is_fast_fwd $currentval, $lrval) {
1032             $checked{$lrref} = -1;
1033             snag 'behind', "you are behind $lrref, divergence risk";
1034         } else {
1035             $checked{$lrref} = -1;
1036             snag 'diverged', "you have diverged from $lrref";
1037         }
1038     };
1039
1040     my $merge = cfg "branch.$branch.merge",1;
1041     if (defined $merge and $merge =~ m{^refs/heads/}) {
1042         my $rhs = $';
1043         printdebug "ffq merge $rhs\n";
1044         my $check_remote = sub {
1045             my ($remote, $desc) = @_;
1046             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1047             return unless defined $remote;
1048             $check->("refs/remotes/$remote/$rhs", $desc);
1049         };
1050         $check_remote->((scalar cfg "branch.$branch.remote",1),
1051                         'remote fetch/merge branch');
1052         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1053                         (scalar cfg "branch.$branch.pushDefault",1),
1054                         'remote push branch');
1055     }
1056     if ($branch =~ m{^dgit/}) {
1057         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1058     } elsif ($branch =~ m{^master$}) {
1059         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1060     }
1061
1062     snags_maybe_bail();
1063
1064     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1065     push @deferred_updates, "delete $gdrlast";
1066     push @deferred_update_messages, "Recorded current head for preservation";
1067     return ('deferred', undef);
1068 }
1069
1070 sub record_ffq_auto () {
1071     my ($status, $message) = record_ffq_prev_deferred();
1072     if ($status eq 'deferred' || $status eq 'exists') {
1073     } else {
1074         snag $status, "could not record ffq-prev: $message";
1075         snags_maybe_bail();
1076     }
1077 }
1078
1079 sub ffq_prev_info () {
1080     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1081     my ($status, $message, $current, $ffq_prev, $gdrlast)
1082         = ffq_prev_branchinfo();
1083     if ($status ne 'branch') {
1084         snag $status, "could not check ffq-prev: $message";
1085         snags_maybe_bail();
1086     }
1087     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1088     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1089 }
1090
1091 sub stitch ($$$$$) {
1092     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1093
1094     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1095
1096     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1097         my $differs = get_differs $old_head, $ffq_prev_commitish;
1098         unless ($differs & ~D_PAT_ADD) {
1099             # ffq-prev is ahead of us, and the only tree changes it has
1100             # are possibly addition of things in debian/patches/.
1101             # Just wind forwards rather than making a pointless pseudomerge.
1102             push @deferred_updates,
1103                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1104             update_head_checkout $old_head, $ffq_prev_commitish,
1105                 "stitch (fast forward)";
1106             return;
1107         }
1108     }
1109     fresh_workarea();
1110     # We make pseudomerges with L as the contributing parent.
1111     # This makes git rev-list --first-parent work properly.
1112     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1113         'Declare fast forward / record previous work',
1114         "[git-debrebase pseudomerge: $prose]",
1115     ];
1116     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1117     update_head $old_head, $new_head, "stitch: $prose";
1118 }
1119
1120 sub do_stitch ($;$) {
1121     my ($prose, $unclean) = @_;
1122
1123     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1124     if (!$ffq_prev_commitish) {
1125         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1126         return;
1127     }
1128     my $dangling_head = get_head();
1129
1130     keycommits $dangling_head, $unclean,$unclean,$unclean;
1131     snags_maybe_bail();
1132
1133     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1134 }
1135
1136 sub cmd_new_upstream_v0 () {
1137     # automatically and unconditionally launders before rebasing
1138     # if rebase --abort is used, laundering has still been done
1139
1140     my %pieces;
1141
1142     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1143
1144     # parse args - low commitment
1145     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1146     my $new_upstream_version = $new_version->version();
1147
1148     my $new_upstream = git_rev_parse (shift @ARGV // 'upstream');
1149
1150     record_ffq_auto();
1151
1152     my $piece = sub {
1153         my ($n, @x) = @_; # may be ''
1154         my $pc = $pieces{$n} //= {
1155             Name => $n,
1156             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1157         };
1158         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1159         $pc;
1160     };
1161
1162     my @newpieces;
1163     my $newpiece = sub {
1164         my ($n, @x) = @_; # may be ''
1165         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1166         push @newpieces, $pc;
1167     };
1168
1169     $newpiece->('',
1170         OldIx => 0,
1171         New => $new_upstream,
1172     );
1173     while (@ARGV && $ARGV[0] !~ m{^-}) {
1174         my $n = shift @ARGV;
1175
1176         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1177             unless @ARGV && $ARGV[0] !~ m{^-};
1178
1179         my $c = git_rev_parse shift @ARGV;
1180         die unless $n =~ m/^$extra_orig_namepart_re$/;
1181         $newpiece->($n, New => $c);
1182     }
1183
1184     # now we need to investigate the branch this generates the
1185     # laundered version but we don't switch to it yet
1186     my $old_head = get_head();
1187     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1188
1189     my $old_bw_cl = classify $old_bw;
1190     my $old_anchor_cl = classify $old_anchor;
1191     my $old_upstream;
1192     if (!$old_anchor_cl->{OrigParents}) {
1193         snag 'anchor-treated',
1194             'old anchor is recognised due to --anchor, cannot check upstream';
1195     } else {
1196         $old_upstream = parsecommit
1197             $old_anchor_cl->{OrigParents}[0]{CommitId};
1198         $piece->('', Old => $old_upstream->{CommitId});
1199     }
1200
1201     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1202         if ($old_upstream->{Msg} =~
1203  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1204            ) {
1205             my @oldpieces = (split / /, $1);
1206             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1207             if (@oldpieces != $old_n_parents) {
1208                 snag 'upstream-confusing', sprintf
1209                     "previous upstream combine %s".
1210                     " mentions %d pieces (each implying one orig commit)".
1211                     " but has %d parents",
1212                     $old_upstream->{CommitId},
1213                     (scalar @oldpieces),
1214                     $old_n_parents;
1215             } elsif ($oldpieces[0] ne '.') {
1216                 snag 'upstream-confusing', sprintf
1217                     "previous upstream combine %s".
1218                     " first piece is not \`.'",
1219                     $oldpieces[0];
1220             } else {
1221                 $oldpieces[0] = '';
1222                 foreach my $i (0..$#oldpieces) {
1223                     my $n = $oldpieces[$i];
1224                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.($i+1));
1225                 }
1226             }
1227         } else {
1228             snag 'upstream-confusing',
1229                 "previous upstream $old_upstream->{CommitId} is from".
1230                " git-debrebase but not an \`upstream-combine' commit";
1231         }
1232     }
1233
1234     foreach my $pc (values %pieces) {
1235         if (!$old_upstream) {
1236             # we have complained already
1237         } elsif (!$pc->{Old}) {
1238             snag 'upstream-new-piece',
1239                 "introducing upstream piece \`$pc->{Name}'";
1240         } elsif (!$pc->{New}) {
1241             snag 'upstream-rm-piece',
1242                 "dropping upstream piece \`$pc->{Name}'";
1243         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1244             snag 'upstream-not-ff',
1245                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1246         }
1247     }
1248
1249     printdebug "%pieces = ", (dd \%pieces), "\n";
1250     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1251
1252     snags_maybe_bail();
1253
1254     my $new_bw;
1255
1256     fresh_workarea();
1257     in_workarea sub {
1258         my @upstream_merge_parents;
1259
1260         if (!any_snags()) {
1261             push @upstream_merge_parents, $old_upstream->{CommitId};
1262         }
1263
1264         foreach my $pc (@newpieces) { # always has '' first
1265             if ($pc->{Name}) {
1266                 read_tree_subdir $pc->{Name}, $pc->{New};
1267             } else {
1268                 runcmd @git, qw(read-tree), $pc->{New};
1269             }
1270             push @upstream_merge_parents, $pc->{New};
1271         }
1272
1273         # index now contains the new upstream
1274
1275         if (@newpieces > 1) {
1276             # need to make the upstream subtree merge commit
1277             $new_upstream = make_commit \@upstream_merge_parents,
1278                 [ "Combine upstreams for $new_upstream_version",
1279  ("[git-debrebase upstream-combine . ".
1280  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1281  ": new upstream]"),
1282                 ];
1283         }
1284
1285         # $new_upstream is either the single upstream commit, or the
1286         # combined commit we just made.  Either way it will be the
1287         # "upstream" parent of the anchor merge.
1288
1289         read_tree_subdir 'debian', "$old_bw:debian";
1290
1291         # index now contains the anchor merge contents
1292         $new_bw = make_commit [ $old_bw, $new_upstream ],
1293             [ "Update to upstream $new_upstream_version",
1294  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1295             ];
1296
1297         my $clogsignoff = cmdoutput qw(git show),
1298             '--pretty=format:%an <%ae>  %aD',
1299             $new_bw;
1300
1301         # Now we have to add a changelog stanza so the Debian version
1302         # is right.
1303         die if unlink "debian";
1304         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1305         unlink "debian/changelog" or $!==ENOENT or die $!;
1306         mkdir "debian" or die $!;
1307         open CN, ">", "debian/changelog" or die $!;
1308         my $oldclog = git_cat_file ":debian/changelog";
1309         $oldclog =~ m/^($package_re) \(\S+\) / or
1310             fail "cannot parse old changelog to get package name";
1311         my $p = $1;
1312         print CN <<END, $oldclog or die $!;
1313 $p ($new_version) UNRELEASED; urgency=medium
1314
1315   * Update to new upstream version $new_upstream_version.
1316
1317  -- $clogsignoff
1318
1319 END
1320         close CN or die $!;
1321         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1322
1323         # Now we have the final new breakwater branch in the index
1324         $new_bw = make_commit [ $new_bw ],
1325             [ "Update changelog for new upstream $new_upstream_version",
1326               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1327             ];
1328     };
1329
1330     # we have constructed the new breakwater. we now need to commit to
1331     # the laundering output, because git-rebase can't easily be made
1332     # to make a replay list which is based on some other branch
1333
1334     update_head_postlaunder $old_head, $old_laundered_tip,
1335         'launder for new upstream';
1336
1337     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1338     runcmd @cmd;
1339     # now it's for the user to sort out
1340 }
1341
1342 sub cmd_record_ffq_prev () {
1343     badusage "no arguments allowed" if @ARGV;
1344     my ($status, $msg) = record_ffq_prev_deferred();
1345     if ($status eq 'exists' && $opt_noop_ok) {
1346         print "Previous head already recorded\n" or die $!;
1347     } elsif ($status eq 'deferred') {
1348         run_deferred_updates 'record-ffq-prev';
1349     } else {
1350         fail "Could not preserve: $msg";
1351     }
1352 }
1353
1354 sub cmd_anchor () {
1355     badusage "no arguments allowed" if @ARGV;
1356     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1357     print "$bw\n" or die $!;
1358 }
1359
1360 sub cmd_breakwater () {
1361     badusage "no arguments allowed" if @ARGV;
1362     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1363     print "$bw\n" or die $!;
1364 }
1365
1366 sub cmd_stitch () {
1367     my $prose = 'stitch';
1368     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1369     badusage "no arguments allowed" if @ARGV;
1370     do_stitch $prose, 0;
1371 }
1372 sub cmd_prepush () { cmd_stitch(); }
1373
1374 sub cmd_quick () {
1375     badusage "no arguments allowed" if @ARGV;
1376     do_launder_head 'launder for git-debrebase quick';
1377     do_stitch 'quick';
1378 }
1379
1380 sub cmd_conclude () {
1381     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1382     if (!$ffq_prev_commitish) {
1383         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1384         return;
1385     }
1386     my $dangling_head = get_head();
1387
1388     badusage "no arguments allowed" if @ARGV;
1389     do_launder_head 'launder for git-debrebase quick';
1390     do_stitch 'quick';
1391 }
1392
1393 sub make_patches_staged ($) {
1394     my ($head) = @_;
1395     # Produces the patches that would result from $head if it were
1396     # laundered.
1397     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
1398     fresh_workarea();
1399     in_workarea sub {
1400         runcmd @git, qw(checkout -q -b bw), $secret_bw;
1401         runcmd @git, qw(checkout -q -b patch-queue/bw), $secret_head;
1402         runcmd qw(gbp pq export);
1403         runcmd @git, qw(add debian/patches);
1404     };
1405 }
1406
1407 sub make_patches ($) {
1408     my ($head) = @_;
1409     keycommits $head, 0, \&snag;
1410     make_patches_staged $head;
1411     my $out;
1412     in_workarea sub {
1413         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
1414         runcmd @git, qw(read-tree), $head;
1415         read_tree_subdir 'debian/patches', $ptree;
1416         $out = make_commit [$head], [
1417             'Commit patch queue (exported by git-debrebase)',
1418             '[git-debrebase: export and commit patches]',
1419         ];
1420     };
1421     my $d = get_differs $head, $out;
1422     if ($d == 0) {
1423         return undef; # nothing to do
1424     } elsif ($d == D_PAT_ADD) {
1425         return $out; # OK
1426     } else {
1427         fail "Patch export produced patch amendments".
1428             " (abandoned output commit $out).".
1429             "  Try laundering first.";
1430     }
1431 }
1432
1433 sub cmd_make_patches () {
1434     badusage "no arguments allowed" if @ARGV;
1435     my $old_head = get_head();
1436     my $new = make_patches $old_head;
1437     snags_maybe_bail();
1438     if (!$new) {
1439         fail "No (more) patches to export." unless $opt_noop_ok;
1440         return;
1441     }
1442     update_head_checkout $old_head, $new, 'make-patches';
1443 }
1444
1445 sub cmd_convert_from_gbp () {
1446     badusage "needs 1 optional argument, the upstream git rev"
1447         unless @ARGV<=1;
1448     my ($upstream_spec) = @ARGV;
1449     $upstream_spec //= 'refs/heads/upstream';
1450     my $upstream = git_rev_parse $upstream_spec;
1451     my $old_head = get_head();
1452
1453     my $upsdiff = get_differs $upstream, $old_head;
1454     if ($upsdiff & D_UPS) {
1455         runcmd @git, qw(--no-pager diff),
1456             $upstream, $old_head,
1457             qw( -- :!/debian :/);
1458  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1459     }
1460
1461     if (!is_fast_fwd $upstream, $old_head) {
1462         snag 'upstream-not-ancestor',
1463             "upstream ($upstream) is not an ancestor of HEAD";
1464     } else {
1465         my $wrong = cmdoutput
1466             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1467              qw(-- :/ :!/debian));
1468         if (length $wrong) {
1469             snag 'unexpected-upstream-changes',
1470                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1471             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1472         }
1473     }
1474
1475     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1476         snag 'upstream-has-debian',
1477             "upstream ($upstream) contains debian/ directory";
1478     }
1479
1480     snags_maybe_bail();
1481
1482     my $work;
1483
1484     fresh_workarea();
1485     in_workarea sub {
1486         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1487         # make a branch out of the patch queue - we'll want this in a mo
1488         runcmd qw(gbp pq import);
1489         # strip the patches out
1490         runcmd @git, qw(checkout -q gdr-internal~0);
1491         rm_subdir_cached 'debian/patches';
1492         $work = make_commit ['HEAD'], [
1493  'git-debrebase convert-from-gbp: drop patches from tree',
1494  'Delete debian/patches, as part of converting to git-debrebase format.',
1495  '[git-debrebase convert-from-gbp: drop patches from tree]'
1496                               ];
1497         # make the anchor merge
1498         # the tree is already exactly right
1499         $work = make_commit [$work, $upstream], [
1500  'git-debrebase import: declare upstream',
1501  'First breakwater merge.',
1502  '[git-debrebase anchor: declare upstream]'
1503                               ];
1504
1505         # rebase the patch queue onto the new breakwater
1506         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1507         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1508         $work = git_rev_parse 'HEAD';
1509     };
1510
1511     update_head_checkout $old_head, $work, 'convert-from-gbp';
1512 }
1513
1514 sub cmd_convert_to_gbp () {
1515     badusage "no arguments allowed" if @ARGV;
1516     my $head = get_head();
1517     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
1518     keycommits $head, 0;
1519     my $out;
1520     make_patches_staged $head;
1521     in_workarea sub {
1522         $out = make_commit ['HEAD'], [
1523             'Commit patch queue (converted from git-debrebase format)',
1524             '[git-debrebase convert-to-gbp: commit patches]',
1525         ];
1526     };
1527     if (defined $ffq) {
1528         push @deferred_updates, "delete $ffq";
1529         push @deferred_updates, "delete $gdrlast";
1530     }
1531     snags_maybe_bail();
1532     update_head_checkout $head, $out, "convert to gbp (v0)";
1533     print <<END or die $!;
1534 git-debrebase: converted to git-buildpackage branch format
1535 git-debrebase: WARNING: do not now run "git-debrebase" any more
1536 git-debrebase: WARNING: doing so would drop all upstream patches!
1537 END
1538 }
1539
1540 sub cmd_downstream_rebase_launder_v0 () {
1541     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1542     my ($base) = @ARGV;
1543     $base = git_rev_parse $base;
1544     my $old_head = get_head();
1545     my $current = $old_head;
1546     my $topmost_keep;
1547     for (;;) {
1548         if ($current eq $base) {
1549             $topmost_keep //= $current;
1550             print " $current BASE stop\n";
1551             last;
1552         }
1553         my $cl = classify $current;
1554         print " $current $cl->{Type}";
1555         my $keep = 0;
1556         my $p0 = $cl->{Parents}[0]{CommitId};
1557         my $next;
1558         if ($cl->{Type} eq 'Pseudomerge') {
1559             print " ^".($cl->{Contributor}{Ix}+1);
1560             $next = $cl->{Contributor}{CommitId};
1561         } elsif ($cl->{Type} eq 'AddPatches' or
1562                  $cl->{Type} eq 'Changelog') {
1563             print " strip";
1564             $next = $p0;
1565         } else {
1566             print " keep";
1567             $next = $p0;
1568             $keep = 1;
1569         }
1570         print "\n";
1571         if ($keep) {
1572             $topmost_keep //= $current;
1573         } else {
1574             die "to-be stripped changes not on top of the branch\n"
1575                 if $topmost_keep;
1576         }
1577         $current = $next;
1578     }
1579     if ($topmost_keep eq $old_head) {
1580         print "unchanged\n";
1581     } else {
1582         print "updating to $topmost_keep\n";
1583         update_head_checkout
1584             $old_head, $topmost_keep,
1585             'downstream-rebase-launder-v0';
1586     }
1587 }
1588
1589 GetOptions("D+" => \$debuglevel,
1590            'noop-ok', => \$opt_noop_ok,
1591            'f=s' => \@snag_force_opts,
1592            'anchor=s' => \@opt_anchors,
1593            'force!',
1594            '-i:s' => sub {
1595                my ($opt,$val) = @_;
1596                badusage "git-debrebase: no cuddling to -i for git-rebase"
1597                    if length $val;
1598                die if $opt_defaultcmd_interactive; # should not happen
1599                $opt_defaultcmd_interactive = [ qw(-i) ];
1600                # This access to @ARGV is excessive familiarity with
1601                # Getopt::Long, but there isn't another sensible
1602                # approach.  '-i=s{0,}' does not work with bundling.
1603                push @$opt_defaultcmd_interactive, @ARGV;
1604                @ARGV=();
1605            }) or die badusage "bad options\n";
1606 initdebug('git-debrebase ');
1607 enabledebug if $debuglevel;
1608
1609 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1610 chdir $toplevel or die "chdir $toplevel: $!";
1611
1612 $rd = fresh_playground "$playprefix/misc";
1613
1614 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1615
1616 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
1617     defaultcmd_rebase();
1618 } else {
1619     my $cmd = shift @ARGV;
1620     my $cmdfn = $cmd;
1621     $cmdfn =~ y/-/_/;
1622     $cmdfn = ${*::}{"cmd_$cmdfn"};
1623
1624     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1625     $cmdfn->();
1626 }
1627
1628 finish 0;