git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # usages:
  22 #    git-debrebase status
  23 #    git-debrebase start       # like ffqrebase start + debrebase launder
  24 #    git-debrebase new-upstream [stuff]  # see below
  25 #    git-debrebase <git-rebase options>  # does debrebase start if necessary
  26 #
  27 #    git-debrebase analyse
  28 #    git-debrebase launder     # prints breakwater tip
  29 #    git-debrebase create-new-upstream-breakwater [-f] <upstreaminfo>...
  30 #
  31 # <upstreaminfo> is
  32 #    [,][<subdir>:][+]<commitid>[,...]
  33 #
  34 # if initial comma is supplied, entries are not positional.  Unspecified
  35 # <subdir> means root (and there may be only one).
  36 # xxx want auto branch names
  37 # xxx too complicated
  38 # how about for now
  39 #    [+]<commit> [<subdir/> [+]<commit>...]
  40 # ?  plus options
  41 #     --new-upstream-different-subtrees
  42 #
  43 #  automatic case
  44 #       git-debrebase new-upstream
  45 #             - previous breakwater merge must be gdr-generated
  46 #             - orig set is the same as before
  47 #             - implicitly uses upstream branches according to orig set
  48 #             - not all upstream branches need be updated
  49 #             - insists on fast-forward of each branch, unless
  50 #                  --force (or --force=<subdir>[/])
  51 #  branch set adjustments
  52 #       git-debrebase new-upstream --add <subdir>/
  53 #       git-debrebase new-upstream --rm <subdir>/
  54 #       git-debrebase new-upstream / [<subdir>/ ...]
  55 #             - orig set is adjusted
  56 #             - otherwise like auto (--add is not checked for ffness, obv)
  57 #             - multiple --add and --rm may be specified
  58 #             - --add makes new upstream the last contributor
  59 #  explicit
  60 #       git-debrebase / [<rootcommitid>] [<subdir>/ [<commitid>] ...]
  61 #             - orig set is precisely as specified now
  62 #             - previous breakwater merge is irrelevant
  63 #             - no fast forward checks
  64 #  for now only explicit with commitids
  65
  66 #         implicitly uses `upstream'
  67 #                                     # (or multiple other branches)
  68 #       git-debrebase new-upstream \
  69 #             [<subdir>/]=<commitid>
  70
  71 #    UPSTREAM[,[[SUBDIR:]SUBUPSTREAM]
  72 #    default for SUBDIR: is from previous upstream merge[xxx terminology]
  73 #
  74 #
  75 #xxx
  76 # when starting must record original start (for ff)
  77 # and new rebase basis
  78 #
  79 #    git-ffqrebase start [BASE]
  80 #                # records previous HEAD so it can be overwritten
  81 #                # records base for future git-ffqrebase
  82 #    git-ffqrebase set-base BASE
  83 #    git-ffqrebase <git-rebase options>
  84 #    git-ffqrebase finish
  85 #    git-ffqrebase status [BRANCH]
  86 #
  87 #  refs/ffqrebase-prev/BRANCH    BRANCH may be refs/...; if not it means
  88 #  refs/ffqrebase-base/BRANCH      refs/heads/BRANCH
  89 #                               zero, one, or both of these may exist
  90 #
  91 # git-debrebase without start, if already started, is willing
  92 # to strip pseudomerges provided that they overwrite exactly
  93 # the previous HEAD
  94 #  xxxx is this right ?  what matters is have we pushed
  95 #    I think in fact the right answer is:
  96 #       git-debrebase always strips out pseudomerges from its branch
  97 #       a pseudomerge is put in at the time we want to push
  98 #       at that time, we make a pseudomerge of the remote tracking
  99 #           branch (if raw git) or the dgit view (if dgit)
 100 #       for raw git git-ffqrebase, do want preciseley to record
 101 #           value of remote tracking branch or our branch, on start, so we
 102 #           overwrite only things we intend to
 103 #  the previous pseudomerge    check for tags and remote branches ?
 104
 105 use strict;
 106
 107 use Memoize;
 108 use Carp;
 109 use POSIX;
 110 use Data::Dumper;
 111 use Getopt::Long qw(:config posix_default gnu_compat bundling);
 112
 113 use Debian::Dgit qw(:DEFAULT :playground);
 114
 115 sub badusage ($) {
 116     my ($m) = @_;
 117     die "bad usage: $m\n";
 118 }
 119
 120 sub cfg ($) {
 121     my ($k) = @_;
 122     $/ = "\0";
 123     my @cmd = qw(git config -z);
 124     push @cmd, qw(--get-all) if wantarray;
 125     push @cmd, $k;
 126     my $out = cmdoutput @cmd;
 127     return split /\0/, $out;
 128 }
 129
 130 memoize('cfg');
 131
 132 sub get_commit ($) {
 133     my ($objid) = @_;
 134     my $data = git_cat_file $objid, 'commit';
 135     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 136     return ($`,$');
 137 }
 138
 139 sub D_DEB ()     { return 0x1; } # debian/ (not including debian/patches/)
 140 sub D_UPS ()     { return 0x2; } # upstream files
 141 sub D_PAT_ADD () { return 0x4; } # debian/patches/ extra patches at end
 142 sub D_PAT_OTH () { return 0x8; } # debian/patches other changes
 143
 144
 145 our $playprefix = 'debrebase';
 146 our $rd;
 147 our $workarea;
 148
 149 our @git = qw(git);
 150
 151 sub in_workarea ($) {
 152     my ($sub) = @_;
 153     changedir $workarea;
 154     my $r = eval { $sub->(); };
 155     changedir $maindir;
 156 }
 157
 158 sub fresh_workarea () {
 159     $workarea = fresh_playground "$playprefix/work";
 160     in_workarea sub { playtree_setup };
 161 }
 162
 163 sub get_differs ($$) {
 164     my ($x,$y) = @_;
 165     # This resembles quiltify_trees_differ, in dgit, a bit.
 166     # But we don't care about modes, or dpkg-source-unrepresentable
 167     # changes, and we don't need the plethora of different modes.
 168     # Conversely we need to distinguish different kinds of changes to
 169     # debian/ and debian/patches/.
 170
 171     my $differs = 0;
 172
 173     my $rundiff = sub {
 174         my ($opts, $limits, $fn) = @_;
 175         my @cmd = (@git, qw(diff-tree -z --no-renames));
 176         push @cmd, @$opts;
 177         push @cmd, "$_:" foreach $x, $y;
 178         push @cmd, @$limits;
 179         my $diffs = cmdoutput @cmd;
 180         foreach (split /\0/, $diffs) { $fn->(); }
 181     };
 182
 183     $rundiff->([qw(--name-only)], [], sub {
 184         $differs |= $_ eq 'debian' ? D_DEB : D_UPS;
 185     });
 186
 187     if ($differs & D_DEB) {
 188         $differs &= ~D_DEB;
 189         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 190             $differs |= $_ eq m{^debian/patches/} ? D_PAT_OTH : D_DEB;
 191         });
 192         die "mysterious debian changes $x..$y"
 193             unless $differs & (D_PAT_OTH|D_DEB);
 194     }
 195
 196     if ($differs & D_PAT_OTH) {
 197         my $mode;
 198         $differs &= ~D_PAT_OTH;
 199         my $pat_oth = sub {
 200             $differs |= D_PAT_OTH;
 201             no warnings qw(exiting);  last;
 202         };
 203         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 204             no warnings qw(exiting);
 205             if (!defined $mode) {
 206                 $mode = $_;  next;
 207             }
 208             die unless s{^debian/patches/}{};
 209             my $ok;
 210             if ($mode eq 'A' && !m/(?:^|\.)series$/s) {
 211                 $ok = 1;
 212             } elsif ($mode eq 'M' && $_ eq 'series') {
 213                 my $x_s = git_cat_file "$x:debian/patches/series", 'blob';
 214                 my $y_s = git_cat_file "$y:debian/patches/series", 'blob';
 215                 chomp $x_s;  $x_s .= "\n";
 216                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 217             } else {
 218                 # nope
 219             }
 220             $mode = undef;
 221             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 222         });
 223         die "mysterious debian/patches changes $x..$y"
 224             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 225     }
 226
 227     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 228
 229     return $differs;
 230 }
 231
 232 sub commit_pr_info ($) {
 233     my ($r) = @_;
 234     return Data::Dumper->dump([$r], [qw(commit)]);
 235 }
 236
 237 sub calculate_committer_authline () {
 238     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 239         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 240     my ($h,$m) = get_commit $c;
 241     $h =~ m/^committer .*$/m or confess "($h) ?";
 242     return $&;
 243 }
 244
 245 # classify returns an info hash like this
 246 #   CommitId => $objid
 247 #   Hdr => # commit headers, including 1 final newline
 248 #   Msg => # commit message (so one newline is dropped)
 249 #   Tree => $treeobjid
 250 #   Type => (see below)
 251 #   Parents = [ {
 252 #       Ix => $index # ie 0, 1, 2, ...
 253 #       CommitId
 254 #       Differs => return value from get_differs
 255 #       IsOrigin
 256 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 257 #     } ...]
 258 #   NewMsg => # commit message, but with any [dgit import ...] edited
 259 #             # to say "[was: ...]"
 260 #
 261 # Types:
 262 #   Packaging
 263 #   Upstream
 264 #   AddPatches
 265 #   Mixed
 266 #   Unknown
 267 #
 268 #   Pseudomerge
 269 #     has additional entres in classification result
 270 #       Overwritten = [ subset of Parents ]
 271 #       Contributor = $the_remaining_Parent
 272 #
 273 #   DgitImportUnpatched
 274 #     has additional entry in classification result
 275 #       OrigParents = [ subset of Parents ]
 276 #
 277 #   BreakwaterUpstreamMerge
 278 #     has additional entry in classification result
 279 #       OrigParents = [ subset of Parents ]
 280
 281 sub classify ($) {
 282     my ($objid) = @_;
 283
 284     my ($h,$m) = get_commit $objid;
 285
 286     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 287     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 288     my @p;
 289
 290     my $r = {
 291         CommitId => $objid,
 292         Hdr => $h,
 293         Msg => $m,
 294         Tree => $t,
 295         Parents => \@p,
 296     };
 297
 298     foreach my $ph (@ph) {
 299         push @p, {
 300             Ix => $#p,
 301             CommitId => $ph,
 302             Differs => (get_differs $t, $ph),
 303         };
 304     }
 305
 306     printdebug "classify $objid \$t=$t \@p",
 307         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 308         "\n";
 309
 310     my $classify = sub {
 311         my ($type, @rest) = @_;
 312         $r = { %$r, Type => $type, @rest };
 313         if ($debuglevel) {
 314             my $dd = new Data::Dumper [ $r ];
 315             Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 316             printdebug " = $type ".(Dump $dd)."\n";
 317         }
 318         return $r;
 319     };
 320     my $unknown = sub {
 321         my ($why) = @_;
 322         $r = { %$r, Type => qw(Unknown) };
 323         printdebug " ** Unknown\n";
 324         return $r;
 325     };
 326
 327     if (@p == 1) {
 328         my $d = $r->{Parents}[0]{Differs};
 329         if ($d == D_PAT_ADD) {
 330             return $classify->(qw(AddPatches));
 331         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 332             return $unknown->("edits debian/patches");
 333         } elsif ($d == D_DEB) {
 334             my ($ty,$dummy) = git_cat_file "$ph[0]:debian";
 335             if ($ty eq 'tree') {
 336                 return $classify->(qw(Packaging));
 337             } elsif ($ty eq 'missing') {
 338                 return $classify->(qw(BreakwaterStart));
 339             } else {
 340                 return $unknown->("parent's debian is not a directory");
 341             }
 342         } elsif ($d == D_UPS) {
 343             return $classify->(qw(Upstream));
 344         } elsif ($d == (D_DEB|D_UPS)) {
 345             return $classify->(qw(Mixed));
 346         } elsif ($d == 0) {
 347             return $unknown->("no changes");
 348         } else {
 349             confess "internal error $objid ?";
 350         }
 351     }
 352     if (!@p) {
 353         return $unknown->("origin commit");
 354     }
 355
 356     my @identical = grep { !$_->{Differs} } @p;
 357     if (@p == 2 && @identical == 1) {
 358         my @overwritten = grep { $_->{Differs} } @p;
 359         confess "internal error $objid ?" unless @overwritten==1;
 360         return $classify->(qw(Pseudomerge),
 361                            Overwritten => $overwritten[0],
 362                            Contributor => $identical[0]);
 363     }
 364     if (@p == 2 && @identical == 2) {
 365         my @bytime = nsort_by {
 366             my ($ph,$pm) = get_commit $_->{CommitId};
 367             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 368             $1;
 369         } @p;
 370         return $classify->(qw(Pseudomerge),
 371                            SubType => qw(Ambiguous),
 372                            Overwritten => $bytime[0],
 373                            Contributor => $bytime[1]);
 374     }
 375     foreach my $p (@p) {
 376         my ($p_h, $p_m) = get_commit $p->{CommitId};
 377         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 378         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 379     }
 380     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 381     my $m2 = $m;
 382     if (!(grep { !$_->{IsOrigin} } @p) and
 383         (@orig_ps >= @p - 1) and
 384         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 385         $r->{NewMsg} = $m2;
 386         return $classify->(qw(DgitImportUnpatched),
 387                            OrigParents => \@orig_ps);
 388     }
 389
 390     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 391     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 392
 393     # How to decide about l/r ordering of breakwater merges ?  git
 394     # --topo-order prefers to expand 2nd parent first.  There's
 395     # already an easy rune to look for debian/ history anyway (git log
 396     # debian/) so debian breakwater branch should be 1st parent; that
 397     # way also there's also an easy rune to look for the upstream
 398     # patches (--topo-order).
 399
 400     # The above tells us which way *we* will generate them.  But we
 401     # might encounter ad-hoc breakwater merges generated manually,
 402     # which might be the other way around.  In principle, in some odd
 403     # situations, a breakwater merge might have two identical parents.
 404     # In that case we guess which way round it is (ie, which parent
 405     # has the upstream history).  The order of the 2-iteration loop
 406     # controls which guess we make.
 407
 408     foreach my $prevbrw (qw(0 1)) {
 409         if (@p == 2 &&
 410             !$haspatches &&
 411             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 412             !($p[$prevbrw]{Differs} & ~D_DEB) &&
 413             !($p[!$prevbrw]{Differs} & ~D_UPS)) {
 414             return $classify->(qw(BreakwaterUpstreamMerge),
 415                                OrigParents => [ $p[!$prevbrw] ]);
 416         }
 417         # xxx multi-.orig upstreams
 418     }
 419
 420     return $unknown->("complex merge");
 421 }
 422
 423 sub walk ($;$$);
 424 sub walk ($;$$) {
 425     my ($input,
 426         $nogenerate,$report) = @_;
 427     # => ($tip, $breakwater_tip)
 428     # (or nothing, if $nogenerate)
 429
 430     # go through commits backwards
 431     # we generate two lists of commits to apply:
 432     # breakwater branch and upstream patches
 433     my (@brw_cl, @upp_cl, @processed);
 434     my %found;
 435     my $upp_limit;
 436     my @pseudomerges;
 437
 438     my $cl;
 439     my $xmsg = sub {
 440         my ($appendinfo) = @_;
 441         my $ms = $cl->{Msg};
 442         chomp $ms;
 443         $ms .= "\n\n[git-debrebase $appendinfo]\n";
 444         return (Msg => $ms);
 445     };
 446     my $rewrite_from_here = sub {
 447         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 448         push @brw_cl, $sp_cl;
 449         push @processed, $sp_cl;
 450     };
 451     my $cur = $input;
 452
 453     my $prdelim = "";
 454     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 455
 456     my $prline = sub {
 457         return unless $report;
 458         print $report $prdelim, @_;
 459         $prdelim = "\n";
 460     };
 461
 462     my $bomb = sub { # usage: return $bomb->();
 463         print $report " Unprocessable" if $report;
 464         $prprdelim->();
 465         if ($nogenerate) {
 466             return (undef,undef);
 467         }
 468         die "commit $cur: Cannot cope with this commit";
 469     };
 470
 471     my $build;
 472     my $breakwater;
 473
 474     my $build_start = sub {
 475         my ($msg, $parent) = @_;
 476         $prline->(" $msg");
 477         $build = $parent;
 478         no warnings qw(exiting); last;
 479     };
 480
 481     for (;;) {
 482         $cl = classify $cur;
 483         my $ty = $cl->{Type};
 484         my $st = $cl->{SubType};
 485         $prline->("$cl->{CommitId} $cl->{Type}");
 486         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 487         push @processed, $cl;
 488         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 489         if ($ty eq 'AddPatches') {
 490             $cur = $p0;
 491             $rewrite_from_here->();
 492             next;
 493         } elsif ($ty eq 'Packaging') {
 494             push @brw_cl, $cl;
 495             $cur = $p0;
 496             next;
 497         } elsif ($ty eq 'BreakwaterStart') {
 498             $build_start->('FirstPackaging', $cur);
 499         } elsif ($ty eq 'Upstream') {
 500             push @upp_cl, $cl;
 501             $cur = $p0;
 502             next;
 503         } elsif ($ty eq 'Mixed') {
 504             my $queue = sub {
 505                 my ($q, $wh) = @_;
 506                 my $cls = { $cl, $xmsg->("split mixed commit: $wh part") };
 507                 push @$q, $cls;
 508             };
 509             $queue->(\@brw_cl, "debian");
 510             $queue->(\@upp_cl, "upstream");
 511             $rewrite_from_here->();
 512             $cur = $p0;
 513             next;
 514         } elsif ($ty eq 'Pseudomerge') {
 515             my $contrib = $cl->{Contributor}{CommitId};
 516             print $report " Contributor=$contrib" if $report;
 517             push @pseudomerges, $cl;
 518             $rewrite_from_here->();
 519             $cur = $contrib;
 520             next;
 521         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 522             $build_start->("PreviousBreakwater", $cur);
 523         } elsif ($ty eq 'DgitImportUnpatched') {
 524             my $pm = $pseudomerges[-1];
 525             if (defined $pm) {
 526                 # To an extent, this is heuristic.  Imports don't have
 527                 # a useful history of the debian/ branch.  We assume
 528                 # that the first pseudomerge after an import has a
 529                 # useful history of debian/, and ignore the histories
 530                 # from later pseudomerges.  Often the first pseudomerge
 531                 # will be the dgit import of the upload to the actual
 532                 # suite intended by the non-dgit NMUer, and later
 533                 # pseudomerges may represent in-archive copies.
 534                 my $ovwrs = $pm->{Overwritten};
 535                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 536                     if $report;
 537                 if (@$ovwrs != 1) {
 538                     return $bomb->();
 539                 }
 540                 my $ovwr = $ovwrs->[0]{CommitId};
 541                 printf $report " Overwr=%s", $ovwr if $report;
 542                 # This import has a tree which is just like a
 543                 # breakwater tree, but it has the wrong history.  It
 544                 # ought to have the previous breakwater (which the
 545                 # pseudomerge overwrote) as an ancestor.  That will
 546                 # make the history of the debian/ files correct.  As
 547                 # for the upstream version: either it's the same as
 548                 # was ovewritten (ie, same as the previous
 549                 # breakwater), in which case that history is precisely
 550                 # right; or, otherwise, it was a non-gitish upload of a
 551                 # new upstream version.  We can tell these apart by
 552                 # looking at the tree of the supposed upstream.
 553                 push @brw_cl, {
 554                     %$cl,
 555                     SpecialMethod => 'DgitImportDebianUpdate',
 556                     $xmsg->("convert dgit import: debian changes")
 557                 };
 558                 my $differs = (get_differs $ovwr, $cl->{Tree});
 559                 printf $report " Differs=%#x", $differs if $report;
 560                 if ($differs & D_UPS) {
 561                     printf $report " D_UPS" if $report;
 562                     # This will also trigger if a non-dgit git-based NMU
 563                     # deleted .gitignore (which is a thing that some of
 564                     # the existing git tools do if the user doesn't
 565                     # somehow tell them not to).  Ah well.
 566                     push @brw_cl, {
 567                         %$cl,
 568                         SpecialMethod => 'DgitImportUpstreamUpdate',
 569                         $xmsg->("convert dgit import: upstream changes")
 570                     };
 571                 }
 572                 $prline->(" Import");
 573                 $rewrite_from_here->();
 574                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 575                 $cur = $ovwr;
 576                 next;
 577             } else {
 578                 # Everything is from this import.  This kind of import
 579                 # is already in valid breakwater format, with the
 580                 # patches as commits.
 581                 printf $report " NoPM" if $report;
 582                 # last thing we processed will have been the first patch,
 583                 # if there is one; which is fine, so no need to rewrite
 584                 # on account of this import
 585                 $build_start->("ImportOrigin", $cur);
 586             }
 587             die "$ty ?";
 588         } else {
 589             return $bomb->();
 590         }
 591     }
 592     $prprdelim->();
 593     return if $nogenerate;
 594
 595     # Now we build it back up again
 596
 597     fresh_workarea();
 598
 599     my $rewriting = 0;
 600
 601     my $rm_tree_cached = sub {
 602         my ($subdir) = @_;
 603         runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 604     };
 605     my $read_tree_debian = sub {
 606         my ($treeish) = @_;
 607         $rm_tree_cached->(qw(debian));
 608         runcmd @git, qw(read-tree --prefix=debian/), "$treeish:debian";
 609     };
 610     my $read_tree_upstream = sub {
 611         my ($treeish) = @_;
 612         runcmd @git, qw(read-tree), $treeish;
 613         $read_tree_debian->($build);
 614     };
 615
 616     my $committer_authline = calculate_committer_authline();
 617
 618     in_workarea sub {
 619         mkdir $rd or $!==EEXIST or die $!;
 620         my $current_method;
 621         foreach my $cl (qw(Debian), (reverse @brw_cl),
 622                         { SpecialMethod => 'RecordBreakwaterTip' },
 623                         qw(Upstream), (reverse @upp_cl)) {
 624             if (!ref $cl) {
 625                 $current_method = $cl;
 626                 next;
 627             }
 628             my $method = $cl->{SpecialMethod} // $current_method;
 629             my @parents = ($build);
 630             my $cltree = $cl->{CommitId};
 631             if ($method eq 'Debian') {
 632                 $read_tree_debian->($cltree);
 633             } elsif ($method eq 'Upstream') {
 634                 $read_tree_upstream->($cltree);
 635             } elsif ($method eq 'StartRewrite') {
 636                 $rewriting = 1;
 637                 next;
 638             } elsif ($method eq 'RecordBreakwaterTip') {
 639                 $breakwater = $build;
 640                 next;
 641             } elsif ($method eq 'DgitImportDebianUpdate') {
 642                 $read_tree_debian->($cltree);
 643                 $rm_tree_cached->(qw(debian/patches));
 644             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 645                 $read_tree_upstream->($cltree);
 646                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 647             } else {
 648                 confess "$method ?";
 649             }
 650             $rewriting ||= $cl ne pop @processed;
 651             my $newtree = cmdoutput @git, qw(write-tree);
 652             my $ch = $cl->{Hdr};
 653             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 654             $ch =~ s{^parent .*\n}{}m;
 655             $ch =~ s{(?=^author)}{
 656                 map { "parent $_\n" } @parents
 657             }me or confess "$ch ?";
 658             if ($rewriting) {
 659                 $ch =~ s{^committer .*$}{$committer_authline}m
 660                     or confess "$ch ?";
 661             }
 662             my $cf = "$rd/m$rewriting";
 663             open CD, ">", $cf or die $!;
 664             print CD $ch, "\n", $cl->{Msg} or die $!;
 665             close CD or die $!;
 666             my @cmd = (@git, qw(hash-object));
 667             push @cmd, qw(-w) if $rewriting;
 668             push @cmd, qw(-t commit), $cf;
 669             my $newcommit = cmdoutput @cmd;
 670             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 671             $build = $newcommit;
 672         }
 673     };
 674
 675     runcmd @git, qw(diff-tree --quiet), $input, $build;
 676
 677     return ($build, $breakwater);
 678 }
 679
 680 sub get_head () { return git_rev_parse qw(HEAD); }
 681
 682 sub update_head ($$$) {
 683     my ($old, $new, $mrest) = @_;
 684     runcmd @git, qw(update-ref -m), "git-debrebase $mrest", $new, $old;
 685 }
 686
 687 sub cmd_launder () {
 688     badusage "no arguments to launder allowed" if @ARGV;
 689     my $old = get_head();
 690     my ($tip,$breakwater) = walk $old;
 691     update_head $old, $tip, 'launder';
 692     # no tree changes except debian/patches
 693     runcmd @git, qw(rm --quiet -rf debian/patches);
 694     printf "# breakwater tip\n%s\n", $breakwater;
 695 }
 696
 697 sub cmd_analyse () {
 698     die if ($ARGV[0]//'') =~ m/^-/;
 699     badusage "too many arguments to analyse" if @ARGV>1;
 700     my ($old) = @ARGV;
 701     if (defined $old) {
 702         $old = git_rev_parse $old;
 703     } else {
 704         $old = get_head();
 705     }
 706     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 707     STDOUT->error and die $!;
 708 }
 709
 710 GetOptions("D+" => \$debuglevel) or die badusage "bad options\n";
 711 initdebug('git-debrebase ');
 712 enabledebug if $debuglevel;
 713
 714 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
 715 chdir $toplevel or die "chdir $toplevel: $!";
 716
 717 $rd = fresh_playground "$playprefix/misc";
 718
 719 my $cmd = shift @ARGV;
 720 my $cmdfn = $cmd;
 721 $cmdfn =~ y/-/_/;
 722 $cmdfn = ${*::}{"cmd_$cmdfn"};
 723
 724 $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
 725 $cmdfn->();