git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, $opt_merges, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  59 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  60
  61 $|=1;
  62
  63 sub badusage ($) {
  64     my ($m) = @_;
  65     print STDERR "$us: bad usage: $m\n";
  66     finish 8;
  67 }
  68
  69 sub getoptions_main {
  70     my $m = shift;
  71     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  72     GetOptions @_ or badusage $m;
  73 }
  74 sub getoptions {
  75     my $sc = shift;
  76     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  77 }
  78
  79 sub cfg ($;$) {
  80     my ($k, $optional) = @_;
  81     local $/ = "\0";
  82     my @cmd = qw(git config -z);
  83     push @cmd, qw(--get-all) if wantarray;
  84     push @cmd, $k;
  85     my $out = cmdoutput_errok @cmd;
  86     if (!defined $out) {
  87         fail "missing required git config $k" unless $optional;
  88         return ();
  89     }
  90     my @l = split /\0/, $out;
  91     return wantarray ? @l : $l[0];
  92 }
  93
  94 memoize('cfg');
  95
  96 sub dd ($) {
  97     my ($v) = @_;
  98     my $dd = new Data::Dumper [ $v ];
  99     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 100     return Dump $dd;
 101 }
 102
 103 sub get_commit ($) {
 104     my ($objid) = @_;
 105     my $data = (git_cat_file $objid, 'commit');
 106     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 107     return ($`,$');
 108 }
 109
 110 sub D_UPS ()      { 0x02; } # upstream files
 111 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 112 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 113 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 114 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 115 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 116
 117 our $playprefix = 'debrebase';
 118 our $rd;
 119 our $workarea;
 120
 121 our @git = qw(git);
 122 our @dgit = qw(dgit);
 123
 124 sub in_workarea ($) {
 125     my ($sub) = @_;
 126     changedir $workarea;
 127     my $r = eval { $sub->(); };
 128     { local $@; changedir $maindir; }
 129     die $@ if $@;
 130 }
 131
 132 sub fresh_workarea (;$) {
 133     my ($subdir) = @_;
 134     $subdir //= 'work';
 135     $workarea = fresh_playground "$playprefix/$subdir";
 136     in_workarea sub { playtree_setup };
 137 }
 138
 139 sub run_ref_updates_now ($$) {
 140     my ($mrest, $updates) = @_;
 141     # @$updates is a list of lines for git-update-ref, without \ns
 142
 143     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 144     debugcmd '>|', @upd_cmd;
 145     open U, "|-", @upd_cmd or die $!;
 146     foreach (@$updates) {
 147         printdebug ">= ", $_, "\n";
 148         print U $_, "\n" or die $!;
 149     }
 150     printdebug ">\$\n";
 151     close U or failedcmd @upd_cmd;
 152 }
 153
 154 our $snags_forced = 0;
 155 our $snags_tripped = 0;
 156 our $snags_summarised = 0;
 157 our @deferred_updates;
 158 our @deferred_update_messages;
 159
 160 sub merge_wreckage_cleaning ($) {
 161     my ($updates) = @_;
 162     git_for_each_ref("$wrecknoteprefix/*", sub {
 163         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 164         push @$updates, "delete $fullrefname";
 165     });
 166 }
 167
 168 sub all_snags_summarised () {
 169     $snags_forced + $snags_tripped == $snags_summarised;
 170 }
 171 sub run_deferred_updates ($) {
 172     my ($mrest) = @_;
 173
 174     confess 'dangerous internal error' unless all_snags_summarised();
 175
 176     merge_wreckage_cleaning \@deferred_updates;
 177     run_ref_updates_now $mrest, \@deferred_updates;
 178     print $_, "\n" foreach @deferred_update_messages;
 179
 180     @deferred_updates = ();
 181     @deferred_update_messages = ();
 182 }
 183
 184 sub get_tree ($;$$) {
 185     # tree object name => ([ $name, $info ], ...)
 186     # where $name is the sort key, ie has / at end for subtrees
 187     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 188     # without $precheck, will crash if $x does not exist, so don't do that;
 189     # instead pass '' to get ().
 190     my ($x, $precheck, $recurse) = @_;
 191
 192     return () if !length $x;
 193
 194     if ($precheck) {
 195         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 196         return () if $type eq 'missing';
 197     }
 198
 199     confess "get_tree needs object not $x ?" unless $x =~ m{^[0-9a-f]+\:};
 200
 201     our (@get_tree_memo, %get_tree_memo);
 202     my $memo = $get_tree_memo{$x};
 203     return @$memo if $memo;
 204
 205     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 206     my @l;
 207     my @cmd = (qw(git ls-tree -z --full-tree));
 208     push @cmd, qw(-r) if $recurse;
 209     push @cmd, qw(--), $x;
 210     my $o = cmdoutput @cmd;
 211     $o =~ s/\0$//s;
 212     my $last = '';
 213     foreach my $l (split /\0/, $o) {
 214         my ($i, $n) = split /\t/, $l, 2;
 215         $n .= '/' if $i =~ m/^\d+ tree /;
 216         push @l, [ $n, $i ];
 217         confess "$x need $last < $n ?" unless $last lt $n;
 218     }
 219     $get_tree_memo{$x} = \@l;
 220     push @get_tree_memo, $x;
 221     if (@get_tree_memo > 10) {
 222         delete $get_tree_memo{ shift @get_tree_memo };
 223     }
 224     return @l;
 225 }
 226
 227 sub trees_diff_walk ($$$;$) {
 228     # trees_diff_walk [$all,] $x, $y, sub {... }
 229     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 230     # $x and $y are as for get_tree
 231     # where $name, $ix, $iy are $name and $info from get_tree
 232     my $all = shift @_ if @_>=4;
 233     my ($x,$y,$call) = @_;
 234     return if !$all and $x eq $y;
 235     my @x = get_tree $x;
 236     my @y = get_tree $y;
 237     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 238         if $debuglevel >= 3;
 239     while (@x || @y) {
 240         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 241              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 242         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 243         $ix=$iy='';
 244         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 245             if $debuglevel >= 3;
 246         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 247         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 248         next if !$all and $ix eq $iy;
 249         printdebug sprintf
 250             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 251             !!$all,$x,$y, $n,$ix,$iy
 252             if $debuglevel >= 2;
 253         $call->($n, $ix, $iy);
 254     }
 255 }
 256
 257 sub get_differs ($$) {
 258     my ($x,$y) = @_;
 259     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 260     # But we don't care about modes, or dpkg-source-unrepresentable
 261     # changes, and we don't need the plethora of different modes.
 262     # Conversely we need to distinguish different kinds of changes to
 263     # debian/ and debian/patches/.
 264     # Also, here we have, and want to use, trees_diff_walk, because
 265     # we may be calling this an awful lot and we want it to be fast.
 266
 267     my $differs = 0;
 268     my @debian_info;
 269
 270     no warnings qw(exiting);
 271
 272     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 273
 274     trees_diff_walk "$x:", "$y:", sub {
 275         my ($n,$ix,$iy) = @_;
 276
 277         # analyse difference at the toplevel
 278
 279         if ($n ne 'debian/') {
 280             $differs |= D_UPS;
 281             next;
 282         }
 283         if ($n eq 'debian') {
 284             # one side has a non-tree for ./debian !
 285             $differs |= D_DEB_OTH;
 286             next;
 287         }
 288
 289         my $xd = $ix && "$x:debian";
 290         my $yd = $iy && "$y:debian";
 291         trees_diff_walk $xd, $yd, sub {
 292             my ($n,$ix,$iy) = @_;
 293
 294             # analyse difference in debian/
 295
 296             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 297                                   &&          $plain->($iy) ) {
 298                 $differs |= D_DEB_CLOG;
 299                 next;
 300             }
 301             if ($n ne 'patches/') {
 302                 $differs |= D_DEB_OTH;
 303                 next;
 304             }
 305
 306             my $xp = $ix && "$xd/patches";
 307             my $yp = $iy && "$yd/patches";
 308             trees_diff_walk $xp, $yp, sub {
 309                 my ($n,$ix,$iy) = @_;
 310
 311                 # analyse difference in debian/patches
 312
 313                 my $ok;
 314                 if ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 315                     $ok = 1;
 316                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 317                     my $x_s = (git_cat_file "$xp/series", 'blob');
 318                     my $y_s = (git_cat_file "$yp/series", 'blob');
 319                     chomp $x_s;  $x_s .= "\n";
 320                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 321                 } else {
 322                     # nope
 323                 }
 324                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 325             };
 326         };
 327     };
 328
 329     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 330
 331     return $differs;
 332 }
 333
 334 sub commit_pr_info ($) {
 335     my ($r) = @_;
 336     return Data::Dumper->dump([$r], [qw(commit)]);
 337 }
 338
 339 sub calculate_committer_authline () {
 340     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 341         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 342     my ($h,$m) = get_commit $c;
 343     $h =~ m/^committer .*$/m or confess "($h) ?";
 344     return $&;
 345 }
 346
 347 sub rm_subdir_cached ($) {
 348     my ($subdir) = @_;
 349     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 350 }
 351
 352 sub read_tree_subdir ($$) {
 353     my ($subdir, $new_tree_object) = @_;
 354     rm_subdir_cached $subdir;
 355     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 356 }
 357
 358 sub read_tree_debian ($) {
 359     my ($treeish) = @_;
 360     read_tree_subdir 'debian', "$treeish:debian";
 361     rm_subdir_cached 'debian/patches';
 362 }
 363
 364 sub read_tree_upstream ($;$$) {
 365     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 366     # if $tree_with_debian is supplied, will use that for debian/
 367     # otherwise will save and restore it.
 368     my $debian =
 369         $tree_with_debian ? "$tree_with_debian:debian"
 370         : cmdoutput @git, qw(write-tree --prefix=debian/);
 371     runcmd @git, qw(read-tree), $treeish;
 372     read_tree_subdir 'debian', $debian;
 373     rm_subdir_cached 'debian/patches' unless $keep_patches;
 374 };
 375
 376 sub make_commit ($$) {
 377     my ($parents, $message_paras) = @_;
 378     my $tree = cmdoutput @git, qw(write-tree);
 379     my @cmd = (@git, qw(commit-tree), $tree);
 380     push @cmd, qw(-p), $_ foreach @$parents;
 381     push @cmd, qw(-m), $_ foreach @$message_paras;
 382     return cmdoutput @cmd;
 383 }
 384
 385 our @snag_force_opts;
 386 sub snag ($$;@) {
 387     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 388     if (grep { $_ eq $tag } @snag_force_opts) {
 389         $snags_forced++;
 390         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 391     } else {
 392         $snags_tripped++;
 393         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 394     }
 395 }
 396
 397 # Important: all mainline code must call snags_maybe_bail after
 398 # any point where snag might be called, but before making changes
 399 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 400 # may be called more than once if necessary (but this is not ideal
 401 # because then the messages about number of snags may be confusing).
 402 sub snags_maybe_bail () {
 403     return if all_snags_summarised();
 404     if ($snags_forced) {
 405         printf STDERR
 406             "%s: snags: %d overriden by individual -f options\n",
 407             $us, $snags_forced;
 408     }
 409     if ($snags_tripped) {
 410         if ($opt_force) {
 411             printf STDERR
 412                 "%s: snags: %d overriden by global --force\n",
 413                 $us, $snags_tripped;
 414         } else {
 415             fail sprintf
 416   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 417                 $us, $snags_tripped;
 418         }
 419     }
 420     $snags_summarised = $snags_forced + $snags_tripped;
 421 }
 422 sub snags_maybe_bail_early () {
 423     # useful to bail out early without doing a lot of work;
 424     # not a substitute for snags_maybe_bail.
 425     snags_maybe_bail() if $snags_tripped && !$opt_force;
 426 }
 427 sub any_snags () {
 428     return $snags_forced || $snags_tripped;
 429 }
 430
 431 sub record_gdrlast ($$) {
 432     my ($gdrlast, $newvalue) = @_;
 433     push @deferred_updates, "update $gdrlast $newvalue $git_null_obj";
 434 }
 435
 436 sub gbp_pq_export ($$$) {
 437     my ($bname, $base, $tip) = @_;
 438     # must be run in a workarea.  $bname and patch-queue/$bname
 439     # ought not to exist.  Leaves you on patch-queue/$bname with
 440     # the patches staged but not committed.
 441     printdebug "gbp_pq_export $bname $base $tip\n";
 442     runcmd @git, qw(checkout -q -b), $bname, $base;
 443     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 444     my @gbp_cmd = (qw(gbp pq export));
 445     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 446     if ($r) {
 447         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 448         failedcmd @gbp_cmd;
 449     }
 450     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 451 }
 452
 453
 454 # MERGE-TODO allow merge resolution separately from laundering, before git merge
 455
 456 # later/rework?
 457 #  use git-format-patch?
 458 #  our own patch identification algorithm?
 459 #  this is an alternative strategy
 460
 461 sub merge_failed ($$;@) {
 462     my ($wrecknotes, $emsg, @xmsgs) = @_;
 463     my @m;
 464     push @m, "Merge resolution failed: $emsg";
 465     push @m, @xmsgs;
 466
 467     changedir $maindir;
 468
 469     my @updates;
 470     merge_wreckage_cleaning \@updates;
 471     run_ref_updates_now "merge failed", \@updates;
 472
 473     @updates = ();
 474     keys %$wrecknotes;
 475     while (my ($k,$v) = each %$wrecknotes) {
 476         push @updates, "create $wrecknoteprefix/$k $v";
 477     }
 478     run_ref_updates_now "merge failed", \@updates;
 479     push @m, "Wreckage left in $wrecknoteprefix/*.";
 480
 481     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 482
 483     # use finish rather than fail, in case we are within an eval
 484     # (that can happen inside walk!)
 485     print STDERR "\n";
 486     print STDERR "$us: $_\n" foreach @m;
 487     finish 15;
 488 }
 489
 490 sub mwrecknote ($$$) {
 491     my ($wrecknotes, $reftail, $commitish) = @_;
 492     confess unless defined $commitish;
 493     printdebug "mwrecknote $reftail $commitish\n";
 494     $wrecknotes->{$reftail} = $commitish;
 495 }
 496
 497 sub merge_attempt_cmd {
 498     my $wrecknotes = shift @_;
 499     debugcmd '+', @_;
 500     $!=0; $?=-1;
 501     if (system @_) {
 502         merge_failed $wrecknotes,
 503             failedcmd_waitstatus(),
 504             "failed command: @_";
 505     }
 506 }
 507
 508 sub merge_series_patchqueue_convert ($$$);
 509
 510 sub merge_series ($$$;@) {
 511     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 512     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 513     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 514     # ^ specifies several patch series (currently we only support exactly 2)
 515     # return value is a commit which is the result of
 516     # merging the two versions of the same topic branch
 517     #   $input_q[0] and $input_q[1]
 518     # with respect to the old version
 519     #   $base_q
 520     # all onto $newbase.
 521
 522     # Creates, in *_q, a key MR for its private use
 523
 524     printdebug "merge_series newbase=$newbase\n";
 525
 526     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 527     $base_q->{MR}{S} = 'base';
 528
 529     my %prereq;
 530     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 531     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 532     # $prereq{<patch filename>}               exists or not (even later)
 533
 534     my $merged_pq;
 535
 536     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 537
 538     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 539
 540     local $workarea;
 541     fresh_workarea "merge";
 542     my $seriesfile = "debian/patches/series";
 543     in_workarea sub {
 544         playtree_setup();
 545         foreach my $q ($base_q, reverse @input_qs) {
 546             my $s = $q->{MR}{S};
 547             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 548             my @earlier;
 549             if (open S, $seriesfile) {
 550                 while (my $patch = <S>) {
 551                     chomp $patch or die $!;
 552                     $prereq{$patch} //= {};
 553                     foreach my $earlier (@earlier) {
 554                         $prereq{$patch}{$earlier}{$s}++ and die;
 555                     }
 556                     push @earlier, $patch;
 557                     stat "debian/patches/$patch" or die "$patch ?";
 558                 }
 559                 S->error and die "$seriesfile $!";
 560                 close S;
 561             } else {
 562                 die "$seriesfile $!" unless $!==ENOENT;
 563             }
 564             read_tree_upstream $newbase, 1;
 565             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 566                 "Convert $s to patch queue for merging",
 567                 "[git-debrebase merge-innards patch-queue import:".
 568                 " $q->{SeriesTip}]"
 569             ];
 570             printdebug "merge_series  pec $pec ";
 571             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 572             $pec = make_commit [ $pec ], [
 573                 "Drop series file from $s to avoid merge trouble",
 574                 "[git-debrebase merge-innards patch-queue prep:".
 575                 " $q->{SeriesTip}]"
 576             ];
 577
 578             read_tree_debian $newbase;
 579             if (@earlier) {
 580                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 581             } else {
 582                 rm_subdir_cached 'debian/patches';
 583             }
 584             $pec = make_commit [ $pec ], [
 585  "Update debian/ (excluding patches) to final to avoid re-merging",
 586  "debian/ was already merged and we need to just take that.",
 587                 "[git-debrebase merge-innards patch-queue packaging:".
 588                 " $q->{SeriesTip}]"
 589             ];
 590
 591             printdebug "pec' $pec\n";
 592             runcmd @git, qw(reset -q --hard), $pec;
 593             $q->{MR}{PEC} = $pec;
 594             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 595         }
 596         # now, because of reverse, we are on $input_q->{MR}{OQC}
 597         runcmd @git, qw(checkout -q -b merge);
 598         printdebug "merge_series merging...\n";
 599         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 600
 601         $attempt_cmd->(@mergecmd);
 602
 603         printdebug "merge_series merge ok, series...\n";
 604         # We need to construct a new series file
 605         # Firstly, resolve prereq
 606         foreach my $f (sort keys %prereq) {
 607             printdebug "merge_series  patch\t$f\t";
 608             if (!stat_exists "debian/patches/$f") {
 609                 print DEBUG " drop\n" if $debuglevel;
 610                 # git merge deleted it; that's how we tell it's not wanted
 611                 delete $prereq{$f};
 612                 next;
 613             }
 614             print DEBUG " keep\n" if $debuglevel;
 615             foreach my $g (sort keys %{ $prereq{$f} }) {
 616                 my $gfp = $prereq{$f}{$g};
 617                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 618                 if (!!$gfp->{0} == !!$gfp->{1}
 619                     ? $gfp->{0}
 620                     : !$gfp->{base}) {
 621                     print DEBUG "\tkeep\n" if $debuglevel;
 622                 } else {
 623                     print DEBUG "\tdrop\n" if $debuglevel;
 624                     delete $prereq{$f}{$g};
 625                 }
 626             }
 627         }
 628
 629         my $unsat = sub {
 630             my ($f) = @_;
 631             return scalar keys %{ $prereq{$f} };
 632         };
 633
 634         my $nodate = time + 1;
 635         my %authordate;
 636         # $authordate{<patch filename>};
 637         my $authordate = sub {
 638             my ($f) = @_;
 639             $authordate{$f} //= do {
 640                 open PF, "<", "debian/patches/$f" or die "$f $!";
 641                 while (<PF>) {
 642                     return $nodate if m/^$/;
 643                     last if s{^Date: }{};
 644                 }
 645                 chomp;
 646                 return cmdoutput qw(date +%s -d), $_;
 647             };
 648         };
 649
 650         open NS, '>', $seriesfile or die $!;
 651
 652         while (keys %prereq) {
 653             my $best;
 654             foreach my $try (sort keys %prereq) {
 655                 if ($best) {
 656                     next if (
 657                              $unsat->($try) <=> $unsat->($best) or
 658                              $authordate->($try) <=> $authordate->($best) or
 659                              $try cmp $best
 660                             ) >= 0;
 661                 }
 662                 $best = $try;
 663             }
 664             printdebug "merge_series series next $best\n";
 665             print NS "$best\n" or die $!;
 666             delete $prereq{$best};
 667             foreach my $gp (values %prereq) {
 668                 delete $gp->{$best};
 669             }
 670         }
 671
 672         runcmd @git, qw(add), $seriesfile;
 673         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 674         $merged_pq = git_rev_parse 'HEAD';
 675         $mwrecknote->('merged-patchqueue', $merged_pq);
 676     };
 677     return merge_series_patchqueue_convert
 678             $wrecknotes, $newbase, $merged_pq;
 679 }
 680
 681 sub merge_series_patchqueue_convert ($$$) {
 682     my ($wrecknotes, $newbase, $merged_pq) = @_;
 683
 684     my $result;
 685     in_workarea sub {
 686         playtree_setup();
 687         printdebug "merge_series series gbp pq import\n";
 688         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 689
 690         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 691         # MERGE-TODO consider git-format-patch etc. instead,
 692         # since gbp pq doesn't always round-trip :-/
 693
 694         # OK now we are on patch-queue/merge, and we need to rebase
 695         # onto the intended parent and drop the patches from each one
 696
 697         printdebug "merge_series series ok, building...\n";
 698         my $build = $newbase;
 699         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 700         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 701             my $commit = git_cat_file $c, 'commit';
 702             printdebug "merge_series series ok, building $c\n";
 703             read_tree_upstream $c, 0, $newbase;
 704             my $tree = cmdoutput @git, qw(write-tree);
 705             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 706             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 707             open C, ">", "../mcommit" or die $!;
 708             print C $commit or die $!;
 709             close C or die $!;
 710             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 711         }
 712         $result = $build;
 713         mwrecknote($wrecknotes, 'merged-result', $result);
 714
 715         runcmd @git, qw(update-ref refs/heads/result), $result;
 716
 717         runcmd @git, qw(checkout -q -b debug);
 718         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 719         runcmd @git, qw(add .);
 720         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 721         my $mdebug = git_rev_parse 'HEAD';
 722         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 723         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 724     };
 725     printdebug "merge_series returns $result\n";
 726     return $result;
 727 }
 728
 729 # classify returns an info hash like this
 730 #   CommitId => $objid
 731 #   Hdr => # commit headers, including 1 final newline
 732 #   Msg => # commit message (so one newline is dropped)
 733 #   Tree => $treeobjid
 734 #   Type => (see below)
 735 #   Parents = [ {
 736 #       Ix => $index # ie 0, 1, 2, ...
 737 #       CommitId
 738 #       Differs => return value from get_differs
 739 #       IsOrigin
 740 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 741 #     } ...]
 742 #   NewMsg => # commit message, but with any [dgit import ...] edited
 743 #             # to say "[was: ...]"
 744 #
 745 # Types:
 746 #   Packaging
 747 #   Changelog
 748 #   Upstream
 749 #   AddPatches
 750 #   Mixed
 751 #
 752 #   Pseudomerge
 753 #     has additional entres in classification result
 754 #       Overwritten = [ subset of Parents ]
 755 #       Contributor = $the_remaining_Parent
 756 #
 757 #   DgitImportUnpatched
 758 #     has additional entry in classification result
 759 #       OrigParents = [ subset of Parents ]
 760 #
 761 #   Anchor
 762 #     has additional entry in classification result
 763 #       OrigParents = [ subset of Parents ]  # singleton list
 764 #
 765 #   TreatAsAnchor
 766 #
 767 #   BreakwaterStart
 768 #
 769 #   Unknown
 770 #     has additional entry in classification result
 771 #       Why => "prose"
 772
 773 sub parsecommit ($;$) {
 774     my ($objid, $p_ref) = @_;
 775     # => hash with                   CommitId Hdr Msg Tree Parents
 776     #    Parents entries have only   Ix CommitId
 777     #    $p_ref, if provided, must be [] and is used as a base for Parents
 778
 779     $p_ref //= [];
 780     die if @$p_ref;
 781
 782     my ($h,$m) = get_commit $objid;
 783
 784     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 785     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 786
 787     my $r = {
 788         CommitId => $objid,
 789         Hdr => $h,
 790         Msg => $m,
 791         Tree => $t,
 792         Parents => $p_ref,
 793     };
 794
 795     foreach my $ph (@ph) {
 796         push @$p_ref, {
 797             Ix => scalar @$p_ref,
 798             CommitId => $ph,
 799         };
 800     }
 801
 802     return $r;
 803 }
 804
 805 sub classify ($) {
 806     my ($objid) = @_;
 807
 808     my @p;
 809     my $r = parsecommit($objid, \@p);
 810     my $t = $r->{Tree};
 811
 812     foreach my $p (@p) {
 813         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 814     }
 815
 816     printdebug "classify $objid \$t=$t \@p",
 817         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 818         "\n";
 819
 820     my $classify = sub {
 821         my ($type, @rest) = @_;
 822         $r = { %$r, Type => $type, @rest };
 823         if ($debuglevel) {
 824             printdebug " = $type ".(dd $r)."\n";
 825         }
 826         return $r;
 827     };
 828     my $unknown = sub {
 829         my ($why) = @_;
 830         $r = { %$r, Type => qw(Unknown), Why => $why };
 831         printdebug " ** Unknown\n";
 832         return $r;
 833     };
 834
 835     if (grep { $_ eq $objid } @opt_anchors) {
 836         return $classify->('TreatAsAnchor');
 837     }
 838
 839     my @identical = grep { !$_->{Differs} } @p;
 840     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 841     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 842
 843     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 844         # multi-orig upstreams are represented with an anchor merge
 845         # from a single upstream commit which combines the orig tarballs
 846
 847         # Every anchor tagged this way must be a merge.
 848         # We are relying on the
 849         #     [git-debrebase anchor: ...]
 850         # commit message annotation in "declare" anchor merges (which
 851         # do not have any upstream changes), to distinguish those
 852         # anchor merges from ordinary pseudomerges (which we might
 853         # just try to strip).
 854         #
 855         # However, the user is going to be doing git-rebase a lot.  We
 856         # really don't want them to rewrite an anchor commit.
 857         # git-rebase trips up on merges, so that is a useful safety
 858         # catch.
 859         #
 860         # BreakwaterStart commits are also anchors in the terminology
 861         # of git-debrebase(5), but they are untagged (and always
 862         # manually generated).
 863         #
 864         # We cannot not tolerate any tagged linear commit (ie,
 865         # BreakwaterStart commits tagged `[anchor:') because such a
 866         # thing could result from an erroneous linearising raw git
 867         # rebase of a merge anchor.  That would represent a corruption
 868         # of the branch. and we want to detect and reject the results
 869         # of such corruption before it makes it out anywhere.  If we
 870         # reject it here then we avoid making the pseudomerge which
 871         # would be needed to push it.
 872
 873         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 874         @p == 2 or return $badanchor->("has other than two parents");
 875         $haspatches and return $badanchor->("contains debian/patches");
 876
 877         # How to decide about l/r ordering of anchors ?  git
 878         # --topo-order prefers to expand 2nd parent first.  There's
 879         # already an easy rune to look for debian/ history anyway (git log
 880         # debian/) so debian breakwater branch should be 1st parent; that
 881         # way also there's also an easy rune to look for the upstream
 882         # patches (--topo-order).
 883
 884         # Also this makes --first-parent be slightly more likely to
 885         # be useful - it makes it provide a linearised breakwater history.
 886
 887         # Of course one can say somthing like
 888         #  gitk -- ':/' ':!/debian'
 889         # to get _just_ the commits touching upstream files, and by
 890         # the TREESAME logic in git-rev-list this will leave the
 891         # breakwater into upstream at the first anchor.  But that
 892         # doesn't report debian/ changes at all.
 893
 894         # Other observations about gitk: by default, gitk seems to
 895         # produce output in a different order to git-rev-list.  I
 896         # can't seem to find this documented anywhere.  gitk
 897         # --date-order DTRT.  But, gitk always seems to put the
 898         # parents from left to right, in order, so it's easy to see
 899         # which way round a pseudomerge is.
 900
 901         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 902         $p[1]{Differs} & ~DS_DEB and
 903             $badanchor->("upstream files differ from left parent");
 904         $p[0]{Differs} & ~D_UPS and
 905             $badanchor->("debian/ differs from right parent");
 906
 907         return $classify->(qw(Anchor),
 908                            OrigParents => [ $p[1] ]);
 909     }
 910
 911     if (@p == 1) {
 912         my $d = $r->{Parents}[0]{Differs};
 913         if ($d == D_PAT_ADD) {
 914             return $classify->(qw(AddPatches));
 915         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 916             return $unknown->("edits debian/patches");
 917         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 918             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 919             if ($ty eq 'tree') {
 920                 if ($d == D_DEB_CLOG) {
 921                     return $classify->(qw(Changelog));
 922                 } else {
 923                     return $classify->(qw(Packaging));
 924                 }
 925             } elsif ($ty eq 'missing') {
 926                 return $classify->(qw(BreakwaterStart));
 927             } else {
 928                 return $unknown->("parent's debian is not a directory");
 929             }
 930         } elsif ($d == D_UPS) {
 931             return $classify->(qw(Upstream));
 932         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 933             return $classify->(qw(Mixed));
 934         } elsif ($d == 0) {
 935             return $unknown->("no changes");
 936         } else {
 937             confess "internal error $objid ?";
 938         }
 939     }
 940     if (!@p) {
 941         return $unknown->("origin commit");
 942     }
 943
 944     if (@p == 2 && @identical == 1) {
 945         my @overwritten = grep { $_->{Differs} } @p;
 946         confess "internal error $objid ?" unless @overwritten==1;
 947         return $classify->(qw(Pseudomerge),
 948                            Overwritten => [ $overwritten[0] ],
 949                            Contributor => $identical[0]);
 950     }
 951     if (@p == 2 && @identical == 2) {
 952         my $get_t = sub {
 953             my ($ph,$pm) = get_commit $_[0]{CommitId};
 954             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 955             $1;
 956         };
 957         my @bytime = @p;
 958         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 959         if ($order > 0) { # newer first
 960         } elsif ($order < 0) {
 961             @bytime = reverse @bytime;
 962         } else {
 963             # same age, default to order made by -s ours
 964             # that is, commit was made by someone who preferred L
 965         }
 966         return $classify->(qw(Pseudomerge),
 967                            SubType => qw(Ambiguous),
 968                            Contributor => $bytime[0],
 969                            Overwritten => [ $bytime[1] ]);
 970     }
 971     foreach my $p (@p) {
 972         my ($p_h, $p_m) = get_commit $p->{CommitId};
 973         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 974         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 975     }
 976     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 977     my $m2 = $r->{Msg};
 978     if (!(grep { !$_->{IsOrigin} } @p) and
 979         (@orig_ps >= @p - 1) and
 980         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 981         $r->{NewMsg} = $m2;
 982         return $classify->(qw(DgitImportUnpatched),
 983                            OrigParents => \@orig_ps);
 984     }
 985
 986     if (@p == 2 and
 987         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 988         return $classify->("MergedBreakwaters");
 989     }
 990     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 991         return $unknown->("unknown kind of merge from $1");
 992     }
 993     if (@p > 2) {
 994         return $unknown->("octopus merge");
 995     }
 996
 997     if (!$opt_merges) {
 998         return $unknown->("general two-parent merge");
 999     }
1000
1001     return $classify->("VanillaMerge");
1002 }
1003
1004 sub keycommits ($;$$$$$);
1005
1006 sub mergedbreakwaters_anchor ($) {
1007     my ($cl) = @_;
1008     my $best_anchor;
1009     foreach my $p (@{ $cl->{Parents} }) {
1010         my ($panchor, $pbw) = keycommits $p->{CommitId},
1011             undef,undef,undef,undef, 1;
1012         $best_anchor = $panchor
1013             if !defined $best_anchor
1014             or is_fast_fwd $best_anchor, $panchor;
1015         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
1016             unless is_fast_fwd $panchor, $best_anchor;
1017     }
1018     return $best_anchor;
1019 }
1020
1021 sub keycommits ($;$$$$$) {
1022     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1023     # => ($anchor, $breakwater)
1024
1025     # $unclean->("unclean-$tagsfx", $msg, $cl)
1026     # $furniture->("unclean-$tagsfx", $msg, $cl)
1027     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1028     #   is callled for each situation or commit that
1029     #   wouldn't be found in a laundered branch
1030     # $furniture is for furniture commits such as might be found on an
1031     #   interchange branch (pseudomerge, d/patches, changelog)
1032     # $trouble is for things whnich prevent the return of
1033     #   anchor and breakwater information; if that is ignored,
1034     #   then keycommits returns (undef, undef) instead.
1035     # $fatal is for unprocessable commits, and should normally cause
1036     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1037     #
1038     # If $claimed_bw, this is supposed to be a breakwater commit.
1039     #
1040     # If a callback is undef, fail is called instead.
1041     # If a callback is defined but false, the situation is ignored.
1042     # Callbacks may say:
1043     #   no warnings qw(exiting); last;
1044     # if the answer is no longer wanted.
1045
1046     my ($anchor, $breakwater);
1047     $breakwater = $head if $claimed_bw;
1048     my $clogonly;
1049     my $cl;
1050     my $found_pm;
1051     $fatal //= sub { fail $_[1]; };
1052     my $x = sub {
1053         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1054         my $why = $mainwhy.$xwhy;
1055         my $m = "branch needs laundering (run git-debrebase): $why";
1056         fail $m unless defined $cb;
1057         return unless $cb;
1058         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1059     };
1060     my $found_anchor = sub {
1061         ($anchor) = @_;
1062         $breakwater //= $clogonly;
1063         $breakwater //= $head;
1064         no warnings qw(exiting);
1065         last;
1066     };
1067     for (;;) {
1068         $cl = classify $head;
1069         my $ty = $cl->{Type};
1070         if ($ty eq 'Packaging') {
1071             $breakwater //= $clogonly;
1072             $breakwater //= $head;
1073         } elsif ($ty eq 'Changelog') {
1074             # this is going to count as the tip of the breakwater
1075             # only if it has no upstream stuff before it
1076             $clogonly //= $head;
1077         } elsif ($ty eq 'Anchor' or
1078                  $ty eq 'TreatAsAnchor' or
1079                  $ty eq 'BreakwaterStart') {
1080             $found_anchor->($head);
1081         } elsif ($ty eq 'Upstream') {
1082             $x->($unclean, 'ordering',
1083  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1084                 if defined $breakwater;
1085             $clogonly = undef;
1086             $breakwater = undef;
1087         } elsif ($ty eq 'Mixed') {
1088             $x->($unclean, 'mixed',
1089                  "found mixed upstream/packaging commit"," ($head)");
1090             $clogonly = undef;
1091             $breakwater = undef;
1092         } elsif ($ty eq 'Pseudomerge' or
1093                  $ty eq 'AddPatches') {
1094             my $found_pm = 1;
1095             $x->($furniture, (lc $ty),
1096                  "found interchange bureaucracy commit ($ty)"," ($head)");
1097         } elsif ($ty eq 'DgitImportUnpatched') {
1098             if ($found_pm) {
1099                 $x->($trouble, 'dgitimport',
1100                      "found dgit dsc import"," ($head)");
1101                 return (undef,undef);
1102             } else {
1103                 $x->($fatal, 'unprocessable',
1104                      "found bare dgit dsc import with no prior history",
1105                      " ($head)");
1106                 return (undef,undef);
1107             }
1108         } elsif ($ty eq 'VanillaMerge') {
1109             $x->($trouble, 'vanillamerge',
1110                  "found vanilla merge"," ($head)");
1111             return (undef,undef);
1112         } elsif ($ty eq 'MergedBreakwaters') {
1113             $found_anchor->(mergedbreakwaters_anchor $cl);
1114         } else {
1115             $x->($fatal, 'unprocessable',
1116                  "found unprocessable commit, cannot cope: $cl->{Why}",
1117                  " ($head)");
1118             return (undef,undef);
1119         }
1120         $head = $cl->{Parents}[0]{CommitId};
1121     }
1122     return ($anchor, $breakwater);
1123 }
1124
1125 sub walk ($;$$$);
1126 sub walk ($;$$$) {
1127     my ($input,
1128         $nogenerate,$report, $report_lprefix) = @_;
1129     # => ($tip, $breakwater_tip, $last_anchor)
1130     # (or nothing, if $nogenerate)
1131
1132     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1133     $report_lprefix //= '';
1134
1135     # go through commits backwards
1136     # we generate two lists of commits to apply:
1137     # breakwater branch and upstream patches
1138     my (@brw_cl, @upp_cl, @processed);
1139     my %found;
1140     my $upp_limit;
1141     my @pseudomerges;
1142
1143     my $cl;
1144     my $xmsg = sub {
1145         my ($prose, $info) = @_;
1146         my $ms = $cl->{Msg};
1147         chomp $ms;
1148         $info //= '';
1149         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1150         return (Msg => $ms);
1151     };
1152     my $rewrite_from_here = sub {
1153         my ($cl) = @_;
1154         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1155         push @$cl, $sp_cl;
1156         push @processed, $sp_cl;
1157     };
1158     my $cur = $input;
1159
1160     my $prdelim = "";
1161     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1162
1163     my $prline = sub {
1164         return unless $report;
1165         print $report $prdelim, $report_lprefix, @_;
1166         $prdelim = "\n";
1167     };
1168
1169     my $bomb = sub { # usage: return $bomb->();
1170         print $report " Unprocessable" if $report;
1171         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1172         $prprdelim->();
1173         if ($nogenerate) {
1174             return (undef,undef);
1175         }
1176         fail "found unprocessable commit, cannot cope".
1177             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1178             " (commit $cur) (d.".
1179             (join ' ', map { sprintf "%#x", $_->{Differs} }
1180              @{ $cl->{Parents} }).
1181                  ")";
1182     };
1183
1184     my $build;
1185     my $breakwater;
1186
1187     my $build_start = sub {
1188         my ($msg, $parent) = @_;
1189         $prline->(" $msg");
1190         $build = $parent;
1191         no warnings qw(exiting); last;
1192     };
1193
1194     my $nomerge = sub {
1195         my ($emsg) = @_;
1196         merge_failed $cl->{MergeWreckNotes}, $emsg;
1197     };
1198
1199     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1200
1201     my $last_anchor;
1202
1203     for (;;) {
1204         $cl = classify $cur;
1205         $cl->{MergeWreckNotes} //= {};
1206         my $ty = $cl->{Type};
1207         my $st = $cl->{SubType};
1208         $prline->("$cl->{CommitId} $cl->{Type}");
1209         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1210         push @processed, $cl;
1211         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1212         if ($ty eq 'AddPatches') {
1213             $cur = $p0;
1214             $rewrite_from_here->(\@upp_cl);
1215             next;
1216         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1217             push @brw_cl, $cl;
1218             $cur = $p0;
1219             next;
1220         } elsif ($ty eq 'BreakwaterStart') {
1221             $last_anchor = $cur;
1222             $build_start->('FirstPackaging', $cur);
1223         } elsif ($ty eq 'Upstream') {
1224             push @upp_cl, $cl;
1225             $cur = $p0;
1226             next;
1227         } elsif ($ty eq 'Mixed') {
1228             my $queue = sub {
1229                 my ($q, $wh) = @_;
1230                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1231                 push @$q, $cls;
1232             };
1233             $queue->(\@brw_cl, "debian");
1234             $queue->(\@upp_cl, "upstream");
1235             $rewrite_from_here->(\@brw_cl);
1236             $cur = $p0;
1237             next;
1238         } elsif ($ty eq 'Pseudomerge') {
1239             my $contrib = $cl->{Contributor}{CommitId};
1240             print $report " Contributor=$contrib" if $report;
1241             push @pseudomerges, $cl;
1242             $rewrite_from_here->(\@upp_cl);
1243             $cur = $contrib;
1244             next;
1245         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1246             $last_anchor = $cur;
1247             $build_start->("Anchor", $cur);
1248         } elsif ($ty eq 'DgitImportUnpatched') {
1249             my $pm = $pseudomerges[-1];
1250             if (defined $pm) {
1251                 # To an extent, this is heuristic.  Imports don't have
1252                 # a useful history of the debian/ branch.  We assume
1253                 # that the first pseudomerge after an import has a
1254                 # useful history of debian/, and ignore the histories
1255                 # from later pseudomerges.  Often the first pseudomerge
1256                 # will be the dgit import of the upload to the actual
1257                 # suite intended by the non-dgit NMUer, and later
1258                 # pseudomerges may represent in-archive copies.
1259                 my $ovwrs = $pm->{Overwritten};
1260                 printf $report " PM=%s \@Overwr:%d",
1261                     $pm->{CommitId}, (scalar @$ovwrs)
1262                     if $report;
1263                 if (@$ovwrs != 1) {
1264                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1265                     return $bomb->();
1266                 }
1267                 my $ovwr = $ovwrs->[0]{CommitId};
1268                 printf $report " Overwr=%s", $ovwr if $report;
1269                 # This import has a tree which is just like a
1270                 # breakwater tree, but it has the wrong history.  It
1271                 # ought to have the previous breakwater (which the
1272                 # pseudomerge overwrote) as an ancestor.  That will
1273                 # make the history of the debian/ files correct.  As
1274                 # for the upstream version: either it's the same as
1275                 # was ovewritten (ie, same as the previous
1276                 # breakwater), in which case that history is precisely
1277                 # right; or, otherwise, it was a non-gitish upload of a
1278                 # new upstream version.  We can tell these apart by
1279                 # looking at the tree of the supposed upstream.
1280                 push @brw_cl, {
1281                     %$cl,
1282                     SpecialMethod => 'DgitImportDebianUpdate',
1283                     $xmsg->("convert dgit import: debian changes")
1284                 }, {
1285                     %$cl,
1286                     SpecialMethod => 'DgitImportUpstreamUpdate',
1287                     $xmsg->("convert dgit import: upstream update",
1288                             " anchor")
1289                 };
1290                 $prline->(" Import");
1291                 $rewrite_from_here->(\@brw_cl);
1292                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1293                 $cur = $ovwr;
1294                 next;
1295             } else {
1296                 # Everything is from this import.  This kind of import
1297                 # is already nearly in valid breakwater format, with the
1298                 # patches as commits.  Unfortunately it contains
1299                 # debian/patches/.
1300                 printdebug "*** WALK BOMB bare dgit import\n";
1301                 $cl->{Why} = "bare dgit dsc import";
1302                 return $bomb->();
1303             }
1304             die "$ty ?";
1305         } elsif ($ty eq 'MergedBreakwaters') {
1306             $last_anchor = mergedbreakwaters_anchor $cl;
1307             $build_start->(' MergedBreakwaters', $cur);
1308             last;
1309         } elsif ($ty eq 'VanillaMerge') {
1310             # User may have merged unstitched branch(es).  We will
1311             # have now lost what ffq-prev was then (since the later
1312             # pseudomerge may introduce further changes).  The effect
1313             # of resolving such a merge is that we may have to go back
1314             # further in history to find a merge base, since the one
1315             # which was reachable via ffq-prev is no longer findable.
1316             # This is suboptimal, but if it all works we'll have done
1317             # the right thing.
1318             # MERGE-TODO we should warn the user in the docs about this
1319
1320             my $ok=1;
1321             my $best_anchor;
1322             # We expect to find a dominating anchor amongst the
1323             # inputs' anchors.  That will be the new anchor.
1324             #
1325             # More complicated is finding a merge base for the
1326             # breakwaters.  We need a merge base that is a breakwater
1327             # commit.  The ancestors of breakwater commits are more
1328             # breakwater commits and possibly upstream commits and the
1329             # ancestors of those upstream.  Upstreams might have
1330             # arbitrary ancestors.  But any upstream commit U is
1331             # either included in both anchors, in which case the
1332             # earlier anchor is a better merge base than any of U's
1333             # ancestors; or U is not included in the older anchor, in
1334             # which case U is not an ancestor of the vanilla merge at
1335             # all.  So no upstream commit, nor any ancestor thereof,
1336             # is a best merge base.  As for non-breakwater Debian
1337             # commits: these are never ancestors of any breakwater.
1338             #
1339             # So any best merge base as found by git-merge-base
1340             # is a suitable breakwater anchor.  Usually there will
1341             # be only one.
1342
1343             printdebug "*** MERGE\n";
1344
1345             my @bwbcmd = (@git, qw(merge-base));
1346             my @ibcmd = (@git, qw(merge-base --all));
1347             my $might_be_in_bw = 1;
1348
1349             my $ps = $cl->{Parents};
1350
1351             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1352
1353             foreach my $p (@$ps) {
1354                 $prline->(" VanillaMerge ".$p->{Ix});
1355                 $prprdelim->();
1356                 my ($ptip, $pbw, $panchor) =
1357                     walk $p->{CommitId}, 0, $report,
1358                          $report_lprefix.'  ';
1359                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1360                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1361                 $p->{Anchor} = $panchor;
1362
1363                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1364                 $mwrecknote->("$lr-input", $p->{CommitId});
1365
1366                 my $mwrecknote_parent = sub {
1367                     my ($which) = @_;
1368                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1369                 };
1370                 $mwrecknote_parent->('Laundered');
1371                 $mwrecknote_parent->('Breakwater');
1372                 $mwrecknote_parent->('Anchor');
1373
1374                 $best_anchor = $panchor if
1375                     !defined $best_anchor or
1376                     is_fast_fwd $best_anchor, $panchor;
1377
1378                 printdebug " MERGE BA best=".($best_anchor//'-').
1379                     " p=$panchor\n";
1380             }
1381
1382             $mwrecknote->('result-anchor', $best_anchor);
1383
1384             foreach my $p (@$ps) {
1385                 $prline->(" VanillaMerge ".$p->{Ix});
1386                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1387                     $nomerge->('divergent anchors');
1388                 } elsif ($p->{Anchor} eq $best_anchor) {
1389                     print $report " SameAnchor" if $report;
1390                 } else {
1391                     print $report " SupersededAnchor" if $report;
1392                 }
1393                 if ($p->{Breakwater} eq $p->{CommitId}) {
1394                     # this parent commit was its own breakwater,
1395                     # ie it is part of the breakwater
1396                     print $report " Breakwater" if $report;
1397                 } else {
1398                     $might_be_in_bw = 0;
1399                 }
1400                 push @bwbcmd, $p->{Breakwater};
1401                 push @ibcmd, $p->{CommitId};
1402             }
1403
1404             if ($ok && $might_be_in_bw) {
1405                 # We could rewrite this to contaion the metadata
1406                 # declaring it to be MergedBreakwaters, but
1407                 # unnecessarily rewriting a merge seems unhelpful.
1408                 $prline->(" VanillaMerge MergedBreakwaters");
1409                 $last_anchor = $best_anchor;
1410                 $build_start->('MergedBreakwaters', $cur);
1411             }
1412
1413             my $bwb = cmdoutput @bwbcmd;
1414
1415             # OK, now we have a breakwater base, but we need the merge
1416             # base for the interchange branch because we need the delta
1417             # queue.
1418             #
1419             # This a the best merge base of our inputs which has the
1420             # breakwater merge base as an ancestor.
1421
1422             my @ibs =
1423                 grep /./,
1424                 split /\n/,
1425                 cmdoutput @ibcmd;
1426
1427             @ibs or confess 'internal error, expected anchor at least ?';
1428
1429             my $ib;
1430             my $ibleaf;
1431             foreach my $tibix (0..$#ibs) {
1432                 my $tib = $ibs[$tibix];
1433                 my $ff = is_fast_fwd $bwb, $tib;
1434                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1435                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1436                 $mwrecknote->($tibleaf, $tib);
1437                 next unless $ff;
1438                 next if $ib;
1439                 $ib = $tib;
1440                 $ibleaf = $tibleaf;
1441             }
1442
1443             $ib or $nomerge->("no suitable interchange merge base");
1444
1445             $prline->("  VanillaMerge Base");
1446             $prprdelim->();
1447             my ($btip, $bbw, $banchor) = eval {
1448                 walk $ib, 0, $report, $report_lprefix.'  ';
1449             };
1450             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1451                        $@)
1452                 if length $@;
1453
1454             $mwrecknote->("mergebase-laundered", $btip);
1455             $mwrecknote->("mergebase-breakwater", $bbw);
1456             $mwrecknote->("mergebase-anchor", $banchor);
1457
1458             my $ibinfo = { SeriesTip => $btip,
1459                            SeriesBase => $bbw,
1460                            Anchor => $banchor,
1461                            LeftRight => 'mergebase' };
1462
1463             $bbw eq $bwb
1464                 or $nomerge->("interchange merge-base ($ib)'s".
1465                               " breakwater ($bbw)".
1466                               " != breakwaters' merge-base ($bwb)");
1467
1468             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1469                  or $nomerge->("interchange merge-base ($ib)'s".
1470                                " anchor ($ibinfo->{SeriesBase})".
1471                                " != any merge input's anchor (".
1472                                (join ' ', map { $_->{Anchor} } @$ps).
1473                                ")");
1474
1475             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1476             $cl->{MergeBestAnchor} = $best_anchor;
1477             push @brw_cl, {
1478                 %$cl,
1479                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1480                 $xmsg->('constructed from vanilla merge',
1481                         ' merged-breakwater'),
1482             };
1483             push @upp_cl, {
1484                 %$cl,
1485                 SpecialMethod => 'MergeMergeSeries',
1486             };
1487             $build_start->('MergeBreakwaters', $cur);
1488         } else {
1489             printdebug "*** WALK BOMB unrecognised\n";
1490             return $bomb->();
1491         }
1492     }
1493     $prprdelim->();
1494
1495     printdebug "*** WALK prep done cur=$cur".
1496         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1497
1498     return if $nogenerate;
1499
1500     # Now we build it back up again
1501
1502     fresh_workarea();
1503
1504     my $rewriting = 0;
1505
1506     $#upp_cl = $upp_limit if defined $upp_limit;
1507
1508     my $committer_authline = calculate_committer_authline();
1509
1510     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1511
1512     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1513
1514     in_workarea sub {
1515         mkdir $rd or $!==EEXIST or die $!;
1516         my $current_method;
1517         my $want_debian = $build;
1518         my $want_upstream = $build;
1519
1520         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1521         my $read_tree_debian = sub { ($want_debian) = @_; };
1522
1523         foreach my $cl (qw(Debian), (reverse @brw_cl),
1524                         { SpecialMethod => 'RecordBreakwaterTip' },
1525                         qw(Upstream), (reverse @upp_cl)) {
1526             if (!ref $cl) {
1527                 $current_method = $cl;
1528                 next;
1529             }
1530             my $method = $cl->{SpecialMethod} // $current_method;
1531             my @parents = ($build);
1532             my $cltree = $cl->{CommitId};
1533             printdebug "WALK BUILD ".($cltree//'undef').
1534                 " $method (rewriting=$rewriting)\n";
1535             if ($method eq 'Debian') {
1536                 $read_tree_debian->($cltree);
1537             } elsif ($method eq 'Upstream') {
1538                 $read_tree_upstream->($cltree);
1539             } elsif ($method eq 'StartRewrite') {
1540                 $rewriting = 1;
1541                 next;
1542             } elsif ($method eq 'RecordBreakwaterTip') {
1543                 $breakwater = $build;
1544                 next;
1545             } elsif ($method eq 'DgitImportDebianUpdate') {
1546                 $read_tree_debian->($cltree);
1547             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1548                 confess unless $rewriting;
1549                 my $differs = (get_differs $build, $cltree);
1550                 next unless $differs & D_UPS;
1551                 $read_tree_upstream->($cltree);
1552                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1553             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1554                 print "Found a general merge, will try to tidy it up.\n";
1555                 $rewriting = 1;
1556                 $read_tree_upstream->($cl->{MergeBestAnchor});
1557                 $read_tree_debian->($cltree);
1558                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1559             } elsif ($method eq 'MergeMergeSeries') {
1560                 my $cachehit = reflog_cache_lookup
1561                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1562                 if ($cachehit) {
1563                     print "Using supplied resolution for $cl->{CommitId}...\n";
1564                     $build = $cachehit;
1565                     $mwrecknote->('cached-resolution', $build);
1566                 } else {
1567                     print "Running merge resolution for $cl->{CommitId}...\n";
1568                     $mwrecknote->('new-base', $build);
1569                     $build = merge_series
1570                         $build, $cl->{MergeWreckNotes},
1571                         $cl->{MergeInterchangeBaseInfo},
1572                         @{ $cl->{Parents} };
1573                 }
1574                 $last_anchor = $cl->{MergeBestAnchor};
1575
1576                 # Check for mismerges:
1577                 my $check = sub {
1578                     my ($against, $allow, $what) = @_;
1579                     my $differs = get_differs $build, $against;
1580                     $nomerge->(sprintf
1581        "merge misresolved: %s are not the same (%s %s d.%#x)",
1582                                $what, $against, $build, $differs)
1583                         if $differs & ~($allow | D_PAT_ADD);
1584                 };
1585
1586                 # Breakwater changes which were in each side of the
1587                 # merge will have been incorporated into the
1588                 # MergeCreateMergedBreakwaters output.  Because the
1589                 # upstream series was rebased onto the new breakwater,
1590                 # so should all of the packaging changes which were in
1591                 # the input.
1592                 $check->($input, D_UPS, 'debian files');
1593
1594                 # Upstream files are merge_series, which ought to
1595                 # have been identical to the original merge.
1596                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1597
1598                 print "Merge resolution successful.\n";
1599                 next;
1600             } else {
1601                 confess "$method ?";
1602             }
1603             if (!$rewriting) {
1604                 my $procd = (pop @processed) // 'UNDEF';
1605                 if ($cl ne $procd) {
1606                     $rewriting = 1;
1607                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1608                 }
1609             }
1610             if ($rewriting) {
1611                 read_tree_upstream $want_upstream, 0, $want_debian;
1612
1613                 my $newtree = cmdoutput @git, qw(write-tree);
1614                 my $ch = $cl->{Hdr};
1615                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1616                 $ch =~ s{^parent .*\n}{}mg;
1617                 $ch =~ s{(?=^author)}{
1618                     join '', map { "parent $_\n" } @parents
1619                 }me or confess "$ch ?";
1620                 if ($rewriting) {
1621                     $ch =~ s{^committer .*$}{$committer_authline}m
1622                         or confess "$ch ?";
1623                 }
1624                 my $cf = "$rd/m$rewriting";
1625                 open CD, ">", $cf or die $!;
1626                 print CD $ch, "\n", $cl->{Msg} or die $!;
1627                 close CD or die $!;
1628                 my @cmd = (@git, qw(hash-object));
1629                 push @cmd, qw(-w) if $rewriting;
1630                 push @cmd, qw(-t commit), $cf;
1631                 my $newcommit = cmdoutput @cmd;
1632                 confess "$ch ?" unless $rewriting
1633                     or $newcommit eq $cl->{CommitId};
1634                 $build = $newcommit;
1635             } else {
1636                 $build = $cl->{CommitId};
1637                 trees_diff_walk "$want_upstream:", "$build:", sub {
1638                     my ($n) = @_;
1639                     no warnings qw(exiting);
1640                     next if $n eq 'debian/';
1641                     confess "mismatch @_ ?";
1642                 };
1643                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1644                     confess "mismatch @_ ?";
1645                 };
1646                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1647                 confess "mismatch @parents != @old_parents ?"
1648                     unless "@parents" eq "@old_parents";
1649             }
1650             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1651                 $last_anchor = $cur;
1652             }
1653         }
1654     };
1655
1656     my $final_check = get_differs $build, $input;
1657     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1658         if $final_check & ~D_PAT_ADD;
1659
1660     my @r = ($build, $breakwater, $last_anchor);
1661     printdebug "*** WALK RETURN @r\n";
1662     return @r
1663 }
1664
1665 sub get_head () {
1666     git_check_unmodified();
1667     return git_rev_parse qw(HEAD);
1668 }
1669
1670 sub update_head ($$$) {
1671     my ($old, $new, $mrest) = @_;
1672     push @deferred_updates, "update HEAD $new $old";
1673     run_deferred_updates $mrest;
1674 }
1675
1676 sub update_head_checkout ($$$) {
1677     my ($old, $new, $mrest) = @_;
1678     update_head $old, $new, $mrest;
1679     runcmd @git, qw(reset --hard);
1680 }
1681
1682 sub update_head_postlaunder ($$$) {
1683     my ($old, $tip, $reflogmsg) = @_;
1684     return if $tip eq $old && !@deferred_updates;
1685     print "git-debrebase: laundered (head was $old)\n";
1686     update_head $old, $tip, $reflogmsg;
1687     # no tree changes except debian/patches
1688     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1689 }
1690
1691 sub currently_rebasing() {
1692     foreach (qw(rebase-merge rebase-apply)) {
1693         return 1 if stat_exists "$maindir_gitdir/$_";
1694     }
1695     return 0;
1696 }
1697
1698 sub bail_if_rebasing() {
1699     fail "you are in the middle of a git-rebase already"
1700         if currently_rebasing();
1701 }
1702
1703 sub do_launder_head ($) {
1704     my ($reflogmsg) = @_;
1705     my $old = get_head();
1706     record_ffq_auto();
1707     my ($tip,$breakwater) = walk $old;
1708     snags_maybe_bail();
1709     update_head_postlaunder $old, $tip, $reflogmsg;
1710     return ($tip,$breakwater);
1711 }
1712
1713 sub cmd_launder_v0 () {
1714     badusage "no arguments to launder-v0 allowed" if @ARGV;
1715     my $old = get_head();
1716     my ($tip,$breakwater,$last_anchor) = walk $old;
1717     update_head_postlaunder $old, $tip, 'launder';
1718     printf "# breakwater tip\n%s\n", $breakwater;
1719     printf "# working tip\n%s\n", $tip;
1720     printf "# last anchor\n%s\n", $last_anchor;
1721 }
1722
1723 sub defaultcmd_rebase () {
1724     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1725     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1726     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1727 }
1728
1729 sub cmd_analyse () {
1730     badusage "analyse does not support any options"
1731         if @ARGV and $ARGV[0] =~ m/^-/;
1732     badusage "too many arguments to analyse" if @ARGV>1;
1733     my ($old) = @ARGV;
1734     if (defined $old) {
1735         $old = git_rev_parse $old;
1736     } else {
1737         $old = git_rev_parse 'HEAD';
1738     }
1739     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1740     STDOUT->error and die $!;
1741 }
1742
1743 sub ffq_prev_branchinfo () {
1744     my $current = git_get_symref();
1745     return gdr_ffq_prev_branchinfo($current);
1746 }
1747
1748 sub ffq_check ($;$$) {
1749     # calls $ff and/or $notff zero or more times
1750     # then returns either (status,message) where status is
1751     #    exists
1752     #    detached
1753     #    weird-symref
1754     #    notbranch
1755     # or (undef,undef, $ffq_prev,$gdrlast)
1756     # $ff and $notff are called like this:
1757     #   $ff->("message for stdout\n");
1758     #   $notff->('snag-name', $message);
1759     # normally $currentval should be HEAD
1760     my ($currentval, $ff, $notff) =@_;
1761
1762     $ff //= sub { print $_[0] or die $!; };
1763     $notff //= \&snag;
1764
1765     my ($status, $message, $current, $ffq_prev, $gdrlast)
1766         = ffq_prev_branchinfo();
1767     return ($status, $message) unless $status eq 'branch';
1768
1769     my $exists = git_get_ref $ffq_prev;
1770     return ('exists',"$ffq_prev already exists") if $exists;
1771
1772     return ('not-branch', 'HEAD symref is not to refs/heads/')
1773         unless $current =~ m{^refs/heads/};
1774     my $branch = $';
1775
1776     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1777     my %checked;
1778
1779     printdebug "ffq check_specs @check_specs\n";
1780
1781     my $check = sub {
1782         my ($lrref, $desc) = @_;
1783         printdebug "ffq might check $lrref ($desc)\n";
1784         my $invert;
1785         for my $chk (@check_specs) {
1786             my $glob = $chk;
1787             $invert = $glob =~ s{^[!^]}{};
1788             last if fnmatch $glob, $lrref;
1789         }
1790         return if $invert;
1791         my $lrval = git_get_ref $lrref;
1792         return unless length $lrval;
1793
1794         if (is_fast_fwd $lrval, $currentval) {
1795             $ff->("OK, you are ahead of $lrref\n");
1796             $checked{$lrref} = 1;
1797         } elsif (is_fast_fwd $currentval, $lrval) {
1798             $checked{$lrref} = -1;
1799             $notff->('behind', "you are behind $lrref, divergence risk");
1800         } else {
1801             $checked{$lrref} = -1;
1802             $notff->('diverged', "you have diverged from $lrref");
1803         }
1804     };
1805
1806     my $merge = cfg "branch.$branch.merge",1;
1807     if (defined $merge and $merge =~ m{^refs/heads/}) {
1808         my $rhs = $';
1809         printdebug "ffq merge $rhs\n";
1810         my $check_remote = sub {
1811             my ($remote, $desc) = @_;
1812             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1813             return unless defined $remote;
1814             $check->("refs/remotes/$remote/$rhs", $desc);
1815         };
1816         $check_remote->((scalar cfg "branch.$branch.remote",1),
1817                         'remote fetch/merge branch');
1818         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1819                         (scalar cfg "branch.$branch.pushDefault",1),
1820                         'remote push branch');
1821     }
1822     if ($branch =~ m{^dgit/}) {
1823         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1824     } elsif ($branch =~ m{^master$}) {
1825         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1826     }
1827     return (undef, undef, $ffq_prev, $gdrlast);
1828 }
1829
1830 sub record_ffq_prev_deferred () {
1831     # => ('status', "message")
1832     # 'status' may be
1833     #    deferred          message is undef
1834     #    exists
1835     #    detached
1836     #    weird-symref
1837     #    notbranch
1838     # if not ff from some branch we should be ff from, is an snag
1839     # if "deferred", will have added something about that to
1840     #   @deferred_update_messages, and also maybe printed (already)
1841     #   some messages about ff checks
1842     bail_if_rebasing();
1843     my $currentval = get_head();
1844
1845     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1846     return ($status,$message) if defined $status;
1847
1848     snags_maybe_bail();
1849
1850     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1851     push @deferred_updates, "delete $gdrlast";
1852     push @deferred_update_messages, "Recorded previous head for preservation";
1853     return ('deferred', undef);
1854 }
1855
1856 sub record_ffq_auto () {
1857     my ($status, $message) = record_ffq_prev_deferred();
1858     if ($status eq 'deferred' || $status eq 'exists') {
1859     } else {
1860         snag $status, "could not record ffq-prev: $message";
1861         snags_maybe_bail();
1862     }
1863 }
1864
1865 sub ffq_prev_info () {
1866     bail_if_rebasing();
1867     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1868     my ($status, $message, $current, $ffq_prev, $gdrlast)
1869         = ffq_prev_branchinfo();
1870     if ($status ne 'branch') {
1871         snag $status, "could not check ffq-prev: $message";
1872         snags_maybe_bail();
1873     }
1874     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1875     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1876 }
1877
1878 sub stitch ($$$$$) {
1879     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1880
1881     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1882
1883     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1884         my $differs = get_differs $old_head, $ffq_prev_commitish;
1885         unless ($differs & ~D_PAT_ADD) {
1886             # ffq-prev is ahead of us, and the only tree changes it has
1887             # are possibly addition of things in debian/patches/.
1888             # Just wind forwards rather than making a pointless pseudomerge.
1889             record_gdrlast $gdrlast, $ffq_prev_commitish;
1890             update_head_checkout $old_head, $ffq_prev_commitish,
1891                 "stitch (fast forward)";
1892             return;
1893         }
1894     }
1895     fresh_workarea();
1896     # We make pseudomerges with L as the contributing parent.
1897     # This makes git rev-list --first-parent work properly.
1898     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1899         'Declare fast forward / record previous work',
1900         "[git-debrebase pseudomerge: $prose]",
1901     ];
1902     record_gdrlast $gdrlast, $new_head;
1903     update_head $old_head, $new_head, "stitch: $prose";
1904 }
1905
1906 sub do_stitch ($;$) {
1907     my ($prose, $unclean) = @_;
1908
1909     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1910     if (!$ffq_prev_commitish) {
1911         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1912         return;
1913     }
1914     my $dangling_head = get_head();
1915
1916     keycommits $dangling_head, $unclean,$unclean,$unclean;
1917     snags_maybe_bail();
1918
1919     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1920 }
1921
1922 sub upstream_commitish_search ($$) {
1923     my ($upstream_version, $tried) = @_;
1924     # todo: at some point maybe use git-deborig to do this
1925     foreach my $tagpfx ('', 'v', 'upstream/') {
1926         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1927         my $new_upstream = git_get_ref "refs/tags/$tag";
1928         push @$tried, $tag;
1929         return $new_upstream if length $new_upstream;
1930     }
1931 }
1932
1933 sub resolve_upstream_version ($$) {
1934     my ($new_upstream, $upstream_version) = @_;
1935
1936     if (!defined $new_upstream) {
1937         my @tried;
1938         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1939         if (!length $new_upstream) {
1940             fail "Could not determine appropriate upstream commitish.\n".
1941                 " (Tried these tags: @tried)\n".
1942                 " Check version, and specify upstream commitish explicitly.";
1943         }
1944     }
1945     $new_upstream = git_rev_parse $new_upstream;
1946
1947     return $new_upstream;
1948 }
1949
1950 sub cmd_new_upstream () {
1951     # automatically and unconditionally launders before rebasing
1952     # if rebase --abort is used, laundering has still been done
1953
1954     my %pieces;
1955
1956     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1957
1958     # parse args - low commitment
1959     my $spec_version = shift @ARGV;
1960     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1961     fail "bad version number \`$spec_version'" unless defined $new_version;
1962     if ($new_version->is_native()) {
1963         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1964     }
1965
1966     my $new_upstream = shift @ARGV;
1967     my $new_upstream_version = upstreamversion  $new_version;
1968     $new_upstream =
1969         resolve_upstream_version $new_upstream, $new_upstream_version;
1970
1971     record_ffq_auto();
1972
1973     my $piece = sub {
1974         my ($n, @x) = @_; # may be ''
1975         my $pc = $pieces{$n} //= {
1976             Name => $n,
1977             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1978         };
1979         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1980         $pc;
1981     };
1982
1983     my @newpieces;
1984     my $newpiece = sub {
1985         my ($n, @x) = @_; # may be ''
1986         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1987         push @newpieces, $pc;
1988     };
1989
1990     $newpiece->('',
1991         OldIx => 0,
1992         New => $new_upstream,
1993     );
1994     while (@ARGV && $ARGV[0] !~ m{^-}) {
1995         my $n = shift @ARGV;
1996
1997         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1998             unless @ARGV && $ARGV[0] !~ m{^-};
1999
2000         my $c = git_rev_parse shift @ARGV;
2001         die unless $n =~ m/^$extra_orig_namepart_re$/;
2002         $newpiece->($n, New => $c);
2003     }
2004
2005     # now we need to investigate the branch this generates the
2006     # laundered version but we don't switch to it yet
2007     my $old_head = get_head();
2008     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2009
2010     my $old_bw_cl = classify $old_bw;
2011     my $old_anchor_cl = classify $old_anchor;
2012     my $old_upstream;
2013     if (!$old_anchor_cl->{OrigParents}) {
2014         snag 'anchor-treated',
2015             'old anchor is recognised due to --anchor, cannot check upstream';
2016     } else {
2017         $old_upstream = parsecommit
2018             $old_anchor_cl->{OrigParents}[0]{CommitId};
2019         $piece->('', Old => $old_upstream->{CommitId});
2020     }
2021
2022     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2023         if ($old_upstream->{Msg} =~
2024  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2025            ) {
2026             my @oldpieces = (split / /, $1);
2027             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2028             if ($old_n_parents != @oldpieces &&
2029                 $old_n_parents != @oldpieces + 1) {
2030                 snag 'upstream-confusing', sprintf
2031                     "previous upstream combine %s".
2032                     " mentions %d pieces (each implying one parent)".
2033                     " but has %d parents".
2034                     " (one per piece plus maybe a previous combine)",
2035                     $old_upstream->{CommitId},
2036                     (scalar @oldpieces),
2037                     $old_n_parents;
2038             } elsif ($oldpieces[0] ne '.') {
2039                 snag 'upstream-confusing', sprintf
2040                     "previous upstream combine %s".
2041                     " first piece is not \`.'",
2042                     $oldpieces[0];
2043             } else {
2044                 $oldpieces[0] = '';
2045                 foreach my $i (0..$#oldpieces) {
2046                     my $n = $oldpieces[$i];
2047                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2048                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2049                 }
2050             }
2051         } else {
2052             snag 'upstream-confusing',
2053                 "previous upstream $old_upstream->{CommitId} is from".
2054                " git-debrebase but not an \`upstream-combine' commit";
2055         }
2056     }
2057
2058     foreach my $pc (values %pieces) {
2059         if (!$old_upstream) {
2060             # we have complained already
2061         } elsif (!$pc->{Old}) {
2062             snag 'upstream-new-piece',
2063                 "introducing upstream piece \`$pc->{Name}'";
2064         } elsif (!$pc->{New}) {
2065             snag 'upstream-rm-piece',
2066                 "dropping upstream piece \`$pc->{Name}'";
2067         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2068             snag 'upstream-not-ff',
2069                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2070         }
2071     }
2072
2073     printdebug "%pieces = ", (dd \%pieces), "\n";
2074     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2075
2076     snags_maybe_bail();
2077
2078     my $new_bw;
2079
2080     fresh_workarea();
2081     in_workarea sub {
2082         my @upstream_merge_parents;
2083
2084         if (!any_snags()) {
2085             push @upstream_merge_parents, $old_upstream->{CommitId};
2086         }
2087
2088         foreach my $pc (@newpieces) { # always has '' first
2089             if ($pc->{Name}) {
2090                 read_tree_subdir $pc->{Name}, $pc->{New};
2091             } else {
2092                 runcmd @git, qw(read-tree), $pc->{New};
2093             }
2094             push @upstream_merge_parents, $pc->{New};
2095         }
2096
2097         # index now contains the new upstream
2098
2099         if (@newpieces > 1) {
2100             # need to make the upstream subtree merge commit
2101             $new_upstream = make_commit \@upstream_merge_parents,
2102                 [ "Combine upstreams for $new_upstream_version",
2103  ("[git-debrebase upstream-combine . ".
2104  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2105  ": new upstream]"),
2106                 ];
2107         }
2108
2109         # $new_upstream is either the single upstream commit, or the
2110         # combined commit we just made.  Either way it will be the
2111         # "upstream" parent of the anchor merge.
2112
2113         read_tree_subdir 'debian', "$old_bw:debian";
2114
2115         # index now contains the anchor merge contents
2116         $new_bw = make_commit [ $old_bw, $new_upstream ],
2117             [ "Update to upstream $new_upstream_version",
2118  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2119             ];
2120
2121         my $clogsignoff = cmdoutput qw(git show),
2122             '--pretty=format:%an <%ae>  %aD',
2123             $new_bw;
2124
2125         # Now we have to add a changelog stanza so the Debian version
2126         # is right.
2127         die if unlink "debian";
2128         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2129         unlink "debian/changelog" or $!==ENOENT or die $!;
2130         mkdir "debian" or die $!;
2131         open CN, ">", "debian/changelog" or die $!;
2132         my $oldclog = git_cat_file ":debian/changelog";
2133         $oldclog =~ m/^($package_re) \(\S+\) / or
2134             fail "cannot parse old changelog to get package name";
2135         my $p = $1;
2136         print CN <<END, $oldclog or die $!;
2137 $p ($new_version) UNRELEASED; urgency=medium
2138
2139   * Update to new upstream version $new_upstream_version.
2140
2141  -- $clogsignoff
2142
2143 END
2144         close CN or die $!;
2145         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2146
2147         # Now we have the final new breakwater branch in the index
2148         $new_bw = make_commit [ $new_bw ],
2149             [ "Update changelog for new upstream $new_upstream_version",
2150               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2151             ];
2152     };
2153
2154     # we have constructed the new breakwater. we now need to commit to
2155     # the laundering output, because git-rebase can't easily be made
2156     # to make a replay list which is based on some other branch
2157
2158     update_head_postlaunder $old_head, $old_laundered_tip,
2159         'launder for new upstream';
2160
2161     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2162     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2163         "debrebase new-upstream $new_version: rebase";
2164     runcmd @cmd;
2165     # now it's for the user to sort out
2166 }
2167
2168 sub cmd_record_ffq_prev () {
2169     badusage "no arguments allowed" if @ARGV;
2170     my ($status, $msg) = record_ffq_prev_deferred();
2171     if ($status eq 'exists' && $opt_noop_ok) {
2172         print "Previous head already recorded\n" or die $!;
2173     } elsif ($status eq 'deferred') {
2174         run_deferred_updates 'record-ffq-prev';
2175     } else {
2176         fail "Could not preserve: $msg";
2177     }
2178 }
2179
2180 sub cmd_anchor () {
2181     badusage "no arguments allowed" if @ARGV;
2182     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2183     print "$bw\n" or die $!;
2184 }
2185
2186 sub cmd_breakwater () {
2187     badusage "no arguments allowed" if @ARGV;
2188     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2189     print "$bw\n" or die $!;
2190 }
2191
2192 sub cmd_status () {
2193     badusage "no arguments allowed" if @ARGV;
2194
2195     # todo: gdr status should print divergence info
2196     # todo: gdr status should print upstream component(s) info
2197     # todo: gdr should leave/maintain some refs with this kind of info ?
2198
2199     my $oldest = { Badness => 0 };
2200     my $newest;
2201     my $note = sub {
2202         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2203         if ($oldest->{Badness} < $badness) {
2204             $oldest = $newest = undef;
2205         }
2206         $oldest = {
2207                    Badness => $badness,
2208                    CommitId => $cl->{CommitId},
2209                    OurMsg => $ourmsg,
2210                    KcMsg => $kcmsg,
2211                   };
2212         $newest //= $oldest;
2213     };
2214     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2215         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2216         sub { $note->(2, 'branch is unlaundered', @_); },
2217         sub { $note->(3, 'branch needs laundering', @_); },
2218         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2219
2220     my $prcommitinfo = sub {
2221         my ($cid) = @_;
2222         flush STDOUT or die $!;
2223         runcmd @git, qw(--no-pager log -n1),
2224             '--pretty=format:    %h %s%n',
2225             $cid;
2226     };
2227
2228     print "current branch contents, in git-debrebase terms:\n";
2229     if (!$oldest->{Badness}) {
2230         print "  branch is laundered\n";
2231     } else {
2232         print "  $oldest->{OurMsg}\n";
2233         my $printed = '';
2234         foreach my $info ($oldest, $newest) {
2235             my $cid = $info->{CommitId};
2236             next if $cid eq $printed;
2237             $printed = $cid;
2238             print "  $info->{KcMsg}\n";
2239             $prcommitinfo->($cid);
2240         }
2241     }
2242
2243     my $prab = sub {
2244         my ($cid, $what) = @_;
2245         if (!defined $cid) {
2246             print "  $what is not well-defined\n";
2247         } else {
2248             print "  $what\n";
2249             $prcommitinfo->($cid);
2250         }
2251     };
2252     print "key git-debrebase commits:\n";
2253     $prab->($anchor, 'anchor');
2254     $prab->($bw, 'breakwater');
2255
2256     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2257         ffq_prev_branchinfo();
2258
2259     print "branch and ref status, in git-debrebase terms:\n";
2260     if ($ffq_msg) {
2261         print "  $ffq_msg\n";
2262     } else {
2263         $ffq_prev = git_get_ref $ffq_prev;
2264         $gdrlast = git_get_ref $gdrlast;
2265         if ($ffq_prev) {
2266             print "  unstitched; previous tip was:\n";
2267             $prcommitinfo->($ffq_prev);
2268         } elsif (!$gdrlast) {
2269             print "  stitched? (no record of git-debrebase work)\n";
2270         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2271             print "  stitched\n";
2272         } else {
2273             print "  not git-debrebase (diverged since last stitch)\n"
2274         }
2275     }
2276     print "you are currently rebasing\n" if currently_rebasing();
2277 }
2278
2279 sub cmd_stitch () {
2280     my $prose = 'stitch';
2281     getoptions("stitch",
2282                'prose=s', \$prose);
2283     badusage "no arguments allowed" if @ARGV;
2284     do_stitch $prose, 0;
2285 }
2286 sub cmd_prepush () {
2287     $opt_noop_ok = 1;
2288     cmd_stitch();
2289 }
2290
2291 sub cmd_quick () {
2292     badusage "no arguments allowed" if @ARGV;
2293     do_launder_head 'launder for git-debrebase quick';
2294     do_stitch 'quick';
2295 }
2296
2297 sub cmd_conclude () {
2298     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2299     if (!$ffq_prev_commitish) {
2300         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2301         return;
2302     }
2303     my $dangling_head = get_head();
2304
2305     badusage "no arguments allowed" if @ARGV;
2306     do_launder_head 'launder for git-debrebase quick';
2307     do_stitch 'quick';
2308 }
2309
2310 sub cmd_scrap () {
2311     if (currently_rebasing()) {
2312         runcmd @git, qw(rebase --abort);
2313         push @deferred_updates, 'verify HEAD HEAD';
2314         # noop, but stops us complaining that scrap was a noop
2315     }
2316     badusage "no arguments allowed" if @ARGV;
2317     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2318     my $scrapping_head;
2319     if ($ffq_prev_commitish) {
2320         $scrapping_head = get_head();
2321         push @deferred_updates,
2322             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2323             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2324     }
2325     if (git_get_ref $merge_cache_ref) {
2326         push @deferred_updates,
2327             "delete $merge_cache_ref";
2328     }
2329     if (!@deferred_updates) {
2330         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2331         finish 0;
2332     }
2333     snags_maybe_bail();
2334     if ($scrapping_head) {
2335         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2336     } else {
2337         run_deferred_updates "scrap";
2338     }
2339 }
2340
2341 sub make_patches_staged ($) {
2342     my ($head) = @_;
2343     # Produces the patches that would result from $head if it were
2344     # laundered.
2345     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2346     fresh_workarea();
2347     in_workarea sub {
2348         gbp_pq_export 'bw', $secret_bw, $secret_head;
2349     };
2350 }
2351
2352 sub make_patches ($) {
2353     my ($head) = @_;
2354     keycommits $head, 0, \&snag;
2355     make_patches_staged $head;
2356     my $out;
2357     in_workarea sub {
2358         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2359         runcmd @git, qw(read-tree), $head;
2360         read_tree_subdir 'debian/patches', $ptree;
2361         $out = make_commit [$head], [
2362             'Commit patch queue (exported by git-debrebase)',
2363             '[git-debrebase: export and commit patches]',
2364         ];
2365     };
2366     return $out;
2367 }
2368
2369 sub cmd_make_patches () {
2370     my $opt_quiet_would_amend;
2371     getoptions("make-patches",
2372                'quiet-would-amend!', \$opt_quiet_would_amend);
2373     badusage "no arguments allowed" if @ARGV;
2374     bail_if_rebasing();
2375     my $old_head = get_head();
2376     my $new = make_patches $old_head;
2377     my $d = get_differs $old_head, $new;
2378     if ($d == 0) {
2379         fail "No (more) patches to export." unless $opt_noop_ok;
2380         return;
2381     } elsif ($d == D_PAT_ADD) {
2382         snags_maybe_bail();
2383         update_head_checkout $old_head, $new, 'make-patches';
2384     } else {
2385         print STDERR failmsg
2386             "Patch export produced patch amendments".
2387             " (abandoned output commit $new).".
2388             "  Try laundering first."
2389             unless $opt_quiet_would_amend;
2390         finish 7;
2391     }
2392 }
2393
2394 sub check_series_has_all_patches ($) {
2395     my ($head) = @_;
2396     my $seriesfn = 'debian/patches/series';
2397     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2398         [qw(blob missing)];
2399     $series //= '';
2400     my %series;
2401     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2402         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2403     }
2404     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2405         my ($f,$i) = @$patchfile;
2406         next if $series{$f};
2407         next if $f eq 'series';
2408         snag 'unused-patches', "Unused patch file $f will be discarded";
2409     }
2410 }
2411
2412 sub cmd_convert_from_gbp () {
2413     badusage "want only 1 optional argument, the upstream git commitish"
2414         unless @ARGV<=1;
2415
2416     my $clogp = parsechangelog();
2417     my $version = $clogp->{'Version'}
2418         // die "missing Version from changelog";
2419
2420     my ($upstream_spec) = @ARGV;
2421
2422     my $upstream_version = upstreamversion $version;
2423     my $upstream =
2424         resolve_upstream_version($upstream_spec, $upstream_version);
2425
2426     my $old_head = get_head();
2427
2428     my $upsdiff = get_differs $upstream, $old_head;
2429     if ($upsdiff & D_UPS) {
2430         runcmd @git, qw(--no-pager diff --stat),
2431             $upstream, $old_head,
2432             qw( -- :!/debian :/);
2433         fail <<END;
2434 upstream ($upstream_spec) and HEAD are not
2435 identical in upstream files.  See diffstat above, or run
2436   git diff $upstream_spec HEAD -- :!/debian :/
2437 END
2438     }
2439
2440     if (!is_fast_fwd $upstream, $old_head) {
2441         snag 'upstream-not-ancestor',
2442             "upstream ($upstream) is not an ancestor of HEAD";
2443     } else {
2444         my $wrong = cmdoutput
2445             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2446              qw(-- :/ :!/debian));
2447         if (length $wrong) {
2448             snag 'unexpected-upstream-changes',
2449                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2450             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2451         }
2452     }
2453
2454     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2455         snag 'upstream-has-debian',
2456             "upstream ($upstream) contains debian/ directory";
2457     }
2458
2459     check_series_has_all_patches $old_head;
2460
2461     my $previous_dgit_view = eval {
2462         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2463         my ($lvsn, $suite);
2464         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2465             my ($stz, $desc) = @_;
2466             no warnings qw(exiting);
2467             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2468             next unless $stz->{Date};
2469             next unless $stz->{Distribution} ne 'UNRELEASED';
2470             $lvsn = $stz->{Version};
2471             $suite = $stz->{Distribution};
2472             last;
2473         };
2474         die "neither of the first two changelog entries are released\n"
2475             unless defined $lvsn;
2476         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2477         my $mtag_pat = debiantag_maintview $lvsn, '*';
2478         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2479             $mtag_pat;
2480         die "could not find suitable maintainer view tag $mtag_pat\n"
2481             unless $mtag =~ m{/};
2482         is_fast_fwd $mtag, 'HEAD' or
2483             die "HEAD is not FF from maintainer tag $mtag!";
2484         my $dtag = "archive/$mtag";
2485         git_get_ref "refs/tags/$dtag" or
2486             die "dgit view tag $dtag not found\n";
2487         is_fast_fwd $mtag, $dtag or
2488             die "dgit view tag $dtag is not FF from maintainer tag $mtag\n";
2489         print "will stitch in dgit view, $dtag\n";
2490         git_rev_parse $dtag;
2491     };
2492     if (!$previous_dgit_view) {
2493         $@ =~ s/^\n+//;
2494         chomp $@;
2495         print STDERR <<END;
2496 Cannot confirm dgit view: $@
2497 Failed to stitch in dgit view (see messages above).
2498 dgit --overwrite will be needed on the first dgit push after conversion.
2499 END
2500     }
2501
2502     snags_maybe_bail_early();
2503
2504     my $work;
2505
2506     fresh_workarea();
2507     in_workarea sub {
2508         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2509         # make a branch out of the patch queue - we'll want this in a mo
2510         runcmd qw(gbp pq import);
2511         # strip the patches out
2512         runcmd @git, qw(checkout -q gdr-internal~0);
2513         rm_subdir_cached 'debian/patches';
2514         $work = make_commit ['HEAD'], [
2515  'git-debrebase convert-from-gbp: drop patches from tree',
2516  'Delete debian/patches, as part of converting to git-debrebase format.',
2517  '[git-debrebase convert-from-gbp: drop patches from tree]'
2518                               ];
2519         # make the anchor merge
2520         # the tree is already exactly right
2521         $work = make_commit [$work, $upstream], [
2522  'git-debrebase import: declare upstream',
2523  'First breakwater merge.',
2524  '[git-debrebase anchor: declare upstream]'
2525                               ];
2526
2527         # rebase the patch queue onto the new breakwater
2528         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2529         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2530         $work = git_rev_parse 'HEAD';
2531
2532         if ($previous_dgit_view) {
2533             $work = make_commit [$work, $previous_dgit_view], [
2534  'git-debrebase import: declare ff from dgit archive view',
2535  '[git-debrebase pseudomerge: import-from-gbp]',
2536             ];
2537         }
2538     };
2539
2540     ffq_check $work;
2541     snags_maybe_bail();
2542     update_head_checkout $old_head, $work, 'convert-from-gbp';
2543     print <<END or die $!;
2544 git-debrebase: converted from patched-unapplied (gbp) branch format, OK
2545 END
2546 }
2547
2548 sub cmd_convert_to_gbp () {
2549     badusage "no arguments allowed" if @ARGV;
2550     my $head = get_head();
2551     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2552     keycommits $head, 0;
2553     my $out;
2554     make_patches_staged $head;
2555     in_workarea sub {
2556         $out = make_commit ['HEAD'], [
2557             'Commit patch queue (converted from git-debrebase format)',
2558             '[git-debrebase convert-to-gbp: commit patches]',
2559         ];
2560     };
2561     if (defined $ffq) {
2562         push @deferred_updates, "delete $ffq";
2563         push @deferred_updates, "delete $gdrlast";
2564     }
2565     snags_maybe_bail();
2566     update_head_checkout $head, $out, "convert to gbp (v0)";
2567     print <<END or die $!;
2568 git-debrebase: converted to git-buildpackage branch format
2569 git-debrebase: WARNING: do not now run "git-debrebase" any more
2570 git-debrebase: WARNING: doing so would drop all upstream patches!
2571 END
2572 }
2573
2574 sub cmd_convert_from_dgit_view () {
2575     my $clogp = parsechangelog();
2576
2577     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2578     my $do_origs = 1;
2579     my $do_tags = 1;
2580     my $always = 0;
2581     my $diagnose = 0;
2582
2583     getoptions("convert-from-dgit-view",
2584                'diagnose!', \$diagnose,
2585                'build-products-dir:s', \$bpd,
2586                'origs!', \$do_origs,
2587                'tags!', \$do_tags,
2588                'always-convert-anyway!', \$always);
2589     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2590
2591     my @upstreams;
2592
2593     if (@ARGV) {
2594         my $spec = shift @ARGV;
2595         my $commit = git_rev_parse "$spec^{commit}";
2596         push @upstreams, { Commit => $commit,
2597                            Source => "$ARGV[0], from command line",
2598                            Only => 1,
2599                          };
2600     }
2601
2602     my $head = get_head();
2603
2604     if (!$always) {
2605         my $troubles = 0;
2606         my $trouble = sub { $troubles++; };
2607         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2608         printdebug "troubles=$troubles\n";
2609         if (!$troubles) {
2610             print STDERR <<END;
2611 $us: Branch already seems to be in git-debrebase format!
2612 $us: --always-convert-anyway would do the conversion operation anyway
2613 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2614 END
2615             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2616             finish 0;
2617         }
2618     }
2619
2620     check_series_has_all_patches $head;
2621
2622     snags_maybe_bail_early();
2623
2624     my $version = upstreamversion $clogp->{Version};
2625     print STDERR "Considering possible commits corresponding to upstream:\n";
2626
2627     if (!@upstreams) {
2628         if ($do_tags) {
2629             my @tried;
2630             my $ups_tag = upstream_commitish_search $version, \@tried;
2631             if ($ups_tag) {
2632                 my $this = "git tag $tried[-1]";
2633                 push @upstreams, { Commit => $ups_tag,
2634                                    Source => $this,
2635                                  };
2636             } else {
2637                 printf STDERR
2638                     " git tag: no suitable tag found (tried %s)\n",
2639                     "@tried";
2640             }
2641         }
2642         if ($do_origs) {
2643             my $p = $clogp->{'Source'};
2644             # we do a quick check to see if there are plausible origs
2645             my $something=0;
2646             if (!opendir BPD, $bpd) {
2647                 die "$bpd: opendir: $!" unless $!==ENOENT;
2648             } else {
2649                 while ($!=0, my $f = readdir BPD) {
2650                     next unless is_orig_file_of_p_v $f, $p, $version;
2651                     printf STDERR
2652                         " orig: found what looks like a .orig, %s\n",
2653                         "$bpd/$f";
2654                     $something=1;
2655                     last;
2656                 }
2657                 die "read $bpd: $!" if $!;
2658                 closedir BPD;
2659             }
2660             if ($something) {
2661                 my $tree = cmdoutput
2662                     @dgit, qw(--build-products-dir), $bpd,
2663                     qw(print-unapplied-treeish);
2664                 fresh_workarea();
2665                 in_workarea sub {
2666                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2667                     rm_subdir_cached 'debian';
2668                     $tree = cmdoutput @git, qw(write-tree);
2669                     my $ups_synth = make_commit [], [ <<END, <<END,
2670 Import effective orig tree for upstream version $version
2671 END
2672 This includes the contents of the .orig(s), minus any debian/ directory.
2673
2674 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2675 END
2676                                                     ];
2677                     push @upstreams, { Commit => $ups_synth,
2678                                        Source => "orig(s) imported via dgit",
2679                                      };
2680                 }
2681             } else {
2682                 printf STDERR
2683                     " orig: no suitable origs found (looked for %s in %s)\n",
2684                     "${p}_".(stripeoch $version)."...", $bpd;
2685             }
2686         }
2687     }
2688
2689     my $some_patches = stat_exists 'debian/patches/series';
2690
2691     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2692
2693     my $result;
2694     foreach my $u (@upstreams) {
2695         my $work = $head;
2696         fresh_workarea();
2697         in_workarea sub {
2698             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2699             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2700             runcmd @git, qw(clean -xdff);
2701             runcmd @git, qw(checkout), $head, qw(-- debian);
2702             if ($some_patches) {
2703                 rm_subdir_cached 'debian/patches';
2704                 $work = make_commit [ $work ], [
2705  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2706  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2707  "to git-debrebase format.  Upstream changes will appear as commits.",
2708  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2709                                            ];
2710             }
2711             $work = make_commit [ $work, $u->{Commit} ], [
2712  'git-debrebase convert-from-dgit-view: declare upstream',
2713  '(Re)constructed breakwater merge.',
2714  '[git-debrebase anchor: declare upstream]'
2715                                                          ];
2716             runcmd @git, qw(checkout --quiet -b mk), $work;
2717             if ($some_patches) {
2718                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2719                 runcmd @git, qw(reset --quiet);
2720                 my @gbp_cmd = (qw(gbp pq import));
2721                 if (!$diagnose) {
2722                     my $gbp_err = "../gbp-pq-err";
2723                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2724                 }
2725                 my $r = system @gbp_cmd;
2726                 if ($r) {
2727                     printf STDERR
2728                         " %s: couldn't apply patches: gbp pq %s",
2729                         $u->{Source}, waitstatusmsg();
2730                     return;
2731                 }
2732             }
2733             my $work = git_rev_parse qw(HEAD);
2734             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2735             if (length $diffout) {
2736                 print STDERR
2737                     " $u->{Source}: applying patches gives different tree\n";
2738                 print STDERR $diffout if $diagnose;
2739                 return;
2740             }
2741             # OMG!
2742             $u->{Result} = $work;
2743             $result = $u;
2744         };
2745         last if $result;
2746     }
2747
2748     if (!$result) {
2749         fail <<END;
2750 Could not find or construct a suitable upstream commit.
2751 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2752 upstream commmit explicitly or provide suitable origs.
2753 END
2754     }
2755
2756     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2757
2758     ffq_check $result->{Result};
2759     snags_maybe_bail();
2760     update_head_checkout $head, $result->{Result},
2761         'convert-from-dgit-view';
2762 }
2763
2764 sub cmd_record_resolved_merge () {
2765     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2766     # MERGE-TODO needs documentation
2767     my $new = get_head();
2768     my $method;
2769
2770     print "Checking how you have resolved the merge problem\n";
2771     my $nope = sub { print "Not $method: @_"; 0; };
2772
2773     my $maybe = sub { print "Seems to be $method.\n"; };
2774     my $yes = sub {
2775         my ($key, $ref) = @_;
2776         reflog_cache_insert $merge_cache_ref, $key, $ref;
2777         print "OK.  You can switch branches and try git-debrebase again.\n";
2778         1;
2779     };
2780
2781     fresh_workarea 'merge';
2782     sub {
2783         $method = 'vanilla-merge patchqueue';
2784         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2785         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2786         foreach my $lr (qw(left right)) {
2787             my $n = "$wrecknoteprefix/$lr-patchqueue";
2788             my $lrpq = git_get_ref $n;
2789             $lrpq or return $nope->("wreckage did not contain patchqueues");
2790             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2791         }
2792         $maybe->();
2793         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2794             or die "wreckage element $wrecknoteprefix/new-base missing";
2795         my $result = merge_series_patchqueue_convert
2796             {}, $newbase, $new;
2797         $yes->("vanilla-merge $vanilla", $result);
2798         1;
2799     }->() or sub {
2800         fail "No resolved merge method seems applicable.\n";
2801     }->();
2802 }
2803
2804 sub cmd_downstream_rebase_launder_v0 () {
2805     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2806     my ($base) = @ARGV;
2807     $base = git_rev_parse $base;
2808     my $old_head = get_head();
2809     my $current = $old_head;
2810     my $topmost_keep;
2811     for (;;) {
2812         if ($current eq $base) {
2813             $topmost_keep //= $current;
2814             print " $current BASE stop\n";
2815             last;
2816         }
2817         my $cl = classify $current;
2818         print " $current $cl->{Type}";
2819         my $keep = 0;
2820         my $p0 = $cl->{Parents}[0]{CommitId};
2821         my $next;
2822         if ($cl->{Type} eq 'Pseudomerge') {
2823             print " ^".($cl->{Contributor}{Ix}+1);
2824             $next = $cl->{Contributor}{CommitId};
2825         } elsif ($cl->{Type} eq 'AddPatches' or
2826                  $cl->{Type} eq 'Changelog') {
2827             print " strip";
2828             $next = $p0;
2829         } else {
2830             print " keep";
2831             $next = $p0;
2832             $keep = 1;
2833         }
2834         print "\n";
2835         if ($keep) {
2836             $topmost_keep //= $current;
2837         } else {
2838             die "to-be stripped changes not on top of the branch\n"
2839                 if $topmost_keep;
2840         }
2841         $current = $next;
2842     }
2843     if ($topmost_keep eq $old_head) {
2844         print "unchanged\n";
2845     } else {
2846         print "updating to $topmost_keep\n";
2847         update_head_checkout
2848             $old_head, $topmost_keep,
2849             'downstream-rebase-launder-v0';
2850     }
2851 }
2852
2853 getoptions_main
2854           ("bad options\n",
2855            "D+" => \$debuglevel,
2856            'noop-ok', => \$opt_noop_ok,
2857            'f=s' => \@snag_force_opts,
2858            'anchor=s' => \@opt_anchors,
2859            '--dgit=s' => \($dgit[0]),
2860            'force!',
2861            'experimental-merge-resolution!', \$opt_merges,
2862            '-i:s' => sub {
2863                my ($opt,$val) = @_;
2864                badusage "git-debrebase: no cuddling to -i for git-rebase"
2865                    if length $val;
2866                die if $opt_defaultcmd_interactive; # should not happen
2867                $opt_defaultcmd_interactive = [ qw(-i) ];
2868                # This access to @ARGV is excessive familiarity with
2869                # Getopt::Long, but there isn't another sensible
2870                # approach.  '-i=s{0,}' does not work with bundling.
2871                push @$opt_defaultcmd_interactive, @ARGV;
2872                @ARGV=();
2873            },
2874            'help' => sub { print $usage_message or die $!; finish 0; },
2875            );
2876
2877 initdebug('git-debrebase ');
2878 enabledebug if $debuglevel;
2879
2880 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2881 chdir $toplevel or die "chdir $toplevel: $!";
2882
2883 $rd = fresh_playground "$playprefix/misc";
2884
2885 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2886
2887 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2888     defaultcmd_rebase();
2889 } else {
2890     my $cmd = shift @ARGV;
2891     my $cmdfn = $cmd;
2892     $cmdfn =~ y/-/_/;
2893     $cmdfn = ${*::}{"cmd_$cmdfn"};
2894
2895     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2896     $cmdfn->();
2897 }
2898
2899 finish 0;