git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_careful, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 $opt_careful = 0;
  57
  58 our $us = qw(git-debrebase);
  59
  60 our $wrecknoteprefix = 'refs/debrebase/wreckage';
  61 our $merge_cache_ref = 'refs/debrebase/merge-resolutions';
  62
  63 $|=1;
  64
  65 sub badusage ($) {
  66     my ($m) = @_;
  67     print STDERR "$us: bad usage: $m\n";
  68     finish 8;
  69 }
  70
  71 sub getoptions_main {
  72     my $m = shift;
  73     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  74     GetOptions @_ or badusage $m;
  75 }
  76 sub getoptions {
  77     my $sc = shift;
  78     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  79 }
  80
  81 sub cfg ($;$) {
  82     my ($k, $optional) = @_;
  83     local $/ = "\0";
  84     my @cmd = qw(git config -z);
  85     push @cmd, qw(--get-all) if wantarray;
  86     push @cmd, $k;
  87     my $out = cmdoutput_errok @cmd;
  88     if (!defined $out) {
  89         fail "missing required git config $k" unless $optional;
  90         return ();
  91     }
  92     my @l = split /\0/, $out;
  93     return wantarray ? @l : $l[0];
  94 }
  95
  96 memoize('cfg');
  97
  98 sub dd ($) {
  99     my ($v) = @_;
 100     my $dd = new Data::Dumper [ $v ];
 101     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 102     return Dump $dd;
 103 }
 104
 105 sub get_commit ($) {
 106     my ($objid) = @_;
 107     my $data = (git_cat_file $objid, 'commit');
 108     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 109     return ($`,$');
 110 }
 111
 112 sub D_UPS ()      { 0x02; } # upstream files
 113 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 114 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 115 sub D_DEB_CLOG () { 0x10; } # debian/changelog
 116 sub D_DEB_OTH ()  { 0x20; } # debian/ (not patches/ or changelog)
 117 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 118
 119 our $playprefix = 'debrebase';
 120 our $rd;
 121 our $workarea;
 122
 123 our @git = qw(git);
 124 our @dgit = qw(dgit);
 125
 126 sub in_workarea ($) {
 127     my ($sub) = @_;
 128     changedir $workarea;
 129     my $r = eval { $sub->(); };
 130     { local $@; changedir $maindir; }
 131     die $@ if $@;
 132 }
 133
 134 sub fresh_workarea (;$) {
 135     my ($subdir) = @_;
 136     $subdir //= 'work';
 137     $workarea = fresh_playground "$playprefix/$subdir";
 138     in_workarea sub { playtree_setup };
 139 }
 140
 141 sub run_ref_updates_now ($$) {
 142     my ($mrest, $updates) = @_;
 143     # @$updates is a list of lines for git-update-ref, without \ns
 144
 145     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 146     debugcmd '>|', @upd_cmd;
 147     open U, "|-", @upd_cmd or die $!;
 148     foreach (@$updates) {
 149         printdebug ">= ", $_, "\n";
 150         print U $_, "\n" or die $!;
 151     }
 152     printdebug ">\$\n";
 153     close U or failedcmd @upd_cmd;
 154 }
 155
 156 our $snags_forced = 0;
 157 our $snags_tripped = 0;
 158 our $snags_summarised = 0;
 159 our @deferred_updates;
 160 our @deferred_update_messages;
 161
 162 sub merge_wreckage_cleaning ($) {
 163     my ($updates) = @_;
 164     git_for_each_ref("$wrecknoteprefix/*", sub {
 165         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 166         push @$updates, "delete $fullrefname";
 167     });
 168 }
 169
 170 sub all_snags_summarised () {
 171     $snags_forced + $snags_tripped == $snags_summarised;
 172 }
 173 sub run_deferred_updates ($) {
 174     my ($mrest) = @_;
 175
 176     confess 'dangerous internal error' unless all_snags_summarised();
 177
 178     merge_wreckage_cleaning \@deferred_updates;
 179     run_ref_updates_now $mrest, \@deferred_updates;
 180     print $_, "\n" foreach @deferred_update_messages;
 181
 182     @deferred_updates = ();
 183     @deferred_update_messages = ();
 184 }
 185
 186 sub get_tree ($;$$) {
 187     # tree object name => ([ $name, $info ], ...)
 188     # where $name is the sort key, ie has / at end for subtrees
 189     # $info is the LHS from git-ls-tree (<mode> <type> <hash>)
 190     # without $precheck, will crash if $x does not exist, so don't do that;
 191     # instead pass '' to get ().
 192     my ($x, $precheck, $recurse) = @_;
 193
 194     return () if !length $x;
 195
 196     if ($precheck) {
 197         my ($type, $dummy) = git_cat_file $x, [qw(tree missing)];
 198         return () if $type eq 'missing';
 199     }
 200
 201     our (@get_tree_memo, %get_tree_memo);
 202     my $memo = $get_tree_memo{$x};
 203     return @$memo if $memo;
 204
 205     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 206     my @l;
 207     my @cmd = (qw(git ls-tree -z --full-tree));
 208     push @cmd, qw(-r) if $recurse;
 209     push @cmd, qw(--), $x;
 210     my $o = cmdoutput @cmd;
 211     $o =~ s/\0$//s;
 212     my $last = '';
 213     foreach my $l (split /\0/, $o) {
 214         my ($i, $n) = split /\t/, $l, 2;
 215         $n .= '/' if $i =~ m/^\d+ tree /;
 216         push @l, [ $n, $i ];
 217         confess "$x need $last < $n ?" unless $last lt $n;
 218     }
 219     $get_tree_memo{$x} = \@l;
 220     push @get_tree_memo, $x;
 221     if (@get_tree_memo > 10) {
 222         delete $get_tree_memo{ shift @get_tree_memo };
 223     }
 224     return @l;
 225 }
 226
 227 sub trees_diff_walk ($$$;$) {
 228     # trees_diff_walk [$all,] $x, $y, sub {... }
 229     # calls sub->($name, $ix, $iy) for each difference (with $all, each name)
 230     # $x and $y are as for get_tree
 231     # where $name, $ix, $iy are $name and $info from get_tree
 232     my $all = shift @_ if @_>=4;
 233     my ($x,$y,$call) = @_;
 234     return if !$all and $x eq $y;
 235     my @x = get_tree $x;
 236     my @y = get_tree $y;
 237     printdebug "trees_diff_walk(..$x,$y..) ".Dumper(\@x,\@y)
 238         if $debuglevel >= 3;
 239     while (@x || @y) {
 240         my $cmp = !@x       <=> !@y          # eg @y empty? $cmp=-1, use x
 241              ||    $x[0][0] cmp  $y[0][0];   # eg, x lt y ? $cmp=-1, use x
 242         my ($n, $ix, $iy);                   # all same? $cmp=0, use both
 243         $ix=$iy='';
 244         printdebug "trees_diff_walk $cmp : @{ $x[0]//[] } | @{ $y[0]//[] }\n"
 245             if $debuglevel >= 3;
 246         ($n, $ix) = @{ shift @x } if $cmp <= 0;
 247         ($n, $iy) = @{ shift @y } if $cmp >= 0;
 248         next if !$all and $ix eq $iy;
 249         printdebug sprintf
 250             "trees_diff_walk(%d,'%s','%s') call('%s','%s','%s')\n",
 251             !!$all,$x,$y, $n,$ix,$iy
 252             if $debuglevel >= 2;
 253         $call->($n, $ix, $iy);
 254     }
 255 }
 256
 257 sub get_differs ($$) {
 258     my ($x,$y) = @_;
 259     # This does a similar job to quiltify_trees_differ, in dgit, a bit.
 260     # But we don't care about modes, or dpkg-source-unrepresentable
 261     # changes, and we don't need the plethora of different modes.
 262     # Conversely we need to distinguish different kinds of changes to
 263     # debian/ and debian/patches/.
 264     # Also, here we have, and want to use, trees_diff_walk, because
 265     # we may be calling this an awful lot and we want it to be fast.
 266
 267     my $differs = 0;
 268     my @debian_info;
 269
 270     no warnings qw(exiting);
 271
 272     my $plain = sub { $_[0] =~ m{^(100|0*)644 blob }s; };
 273
 274     trees_diff_walk "$x:", "$y:", sub {
 275         my ($n,$ix,$iy) = @_;
 276
 277         # analyse difference at the toplevel
 278
 279         if ($n ne 'debian/') {
 280             $differs |= D_UPS;
 281             next;
 282         }
 283         if ($n eq 'debian') {
 284             # one side has a non-tree for ./debian !
 285             $differs |= D_DEB_OTH;
 286             next;
 287         }
 288
 289         my $xd = $ix && "$x:debian";
 290         my $yd = $iy && "$y:debian";
 291         trees_diff_walk $xd, $yd, sub {
 292             my ($n,$ix,$iy) = @_;
 293
 294             # analyse difference in debian/
 295
 296             if ($n eq 'changelog' && (!$ix || $plain->($ix))
 297                                   &&          $plain->($iy) ) {
 298                 $differs |= D_DEB_CLOG;
 299                 next;
 300             }
 301             if ($n ne 'patches/') {
 302                 $differs |= D_DEB_OTH;
 303                 next;
 304             }
 305
 306             my $xp = $ix && "$xd/patches";
 307             my $yp = $iy && "$yd/patches";
 308             trees_diff_walk $xp, $yp, sub {
 309                 my ($n,$ix,$iy) = @_;
 310
 311                 # analyse difference in debian/patches
 312
 313                 my $ok;
 314                 if ($n !~ m/\.series$/s && !$ix && $plain->($iy)) {
 315                     $ok = 1;
 316                 } elsif ($n eq 'series' && $plain->($ix) && $plain->($iy)) {
 317                     my $x_s = (git_cat_file "$xp/series", 'blob');
 318                     my $y_s = (git_cat_file "$yp/series", 'blob');
 319                     chomp $x_s;  $x_s .= "\n";
 320                     $ok = $x_s eq substr($y_s, 0, length $x_s);
 321                 } else {
 322                     # nope
 323                 }
 324                 $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 325             };
 326         };
 327     };
 328
 329     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 330
 331     return $differs;
 332 }
 333
 334 sub commit_pr_info ($) {
 335     my ($r) = @_;
 336     return Data::Dumper->dump([$r], [qw(commit)]);
 337 }
 338
 339 sub calculate_committer_authline () {
 340     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 341         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 342     my ($h,$m) = get_commit $c;
 343     $h =~ m/^committer .*$/m or confess "($h) ?";
 344     return $&;
 345 }
 346
 347 sub rm_subdir_cached ($) {
 348     my ($subdir) = @_;
 349     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 350 }
 351
 352 sub read_tree_subdir ($$) {
 353     my ($subdir, $new_tree_object) = @_;
 354     rm_subdir_cached $subdir;
 355     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 356 }
 357
 358 sub read_tree_debian ($) {
 359     my ($treeish) = @_;
 360     read_tree_subdir 'debian', "$treeish:debian";
 361     rm_subdir_cached 'debian/patches';
 362 }
 363
 364 sub read_tree_upstream ($;$$) {
 365     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 366     # if $tree_with_debian is supplied, will use that for debian/
 367     # otherwise will save and restore it.
 368     my $debian =
 369         $tree_with_debian ? "$tree_with_debian:debian"
 370         : cmdoutput @git, qw(write-tree --prefix=debian/);
 371     runcmd @git, qw(read-tree), $treeish;
 372     read_tree_subdir 'debian', $debian;
 373     rm_subdir_cached 'debian/patches' unless $keep_patches;
 374 };
 375
 376 sub make_commit ($$) {
 377     my ($parents, $message_paras) = @_;
 378     my $tree = cmdoutput @git, qw(write-tree);
 379     my @cmd = (@git, qw(commit-tree), $tree);
 380     push @cmd, qw(-p), $_ foreach @$parents;
 381     push @cmd, qw(-m), $_ foreach @$message_paras;
 382     return cmdoutput @cmd;
 383 }
 384
 385 our @snag_force_opts;
 386 sub snag ($$;@) {
 387     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 388     if (grep { $_ eq $tag } @snag_force_opts) {
 389         $snags_forced++;
 390         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 391     } else {
 392         $snags_tripped++;
 393         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 394     }
 395 }
 396
 397 # Important: all mainline code must call snags_maybe_bail after
 398 # any point where snag might be called, but before making changes
 399 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 400 # may be called more than once if necessary (but this is not ideal
 401 # because then the messages about number of snags may be confusing).
 402 sub snags_maybe_bail () {
 403     return if all_snags_summarised();
 404     if ($snags_forced) {
 405         printf STDERR
 406             "%s: snags: %d overriden by individual -f options\n",
 407             $us, $snags_forced;
 408     }
 409     if ($snags_tripped) {
 410         if ($opt_force) {
 411             printf STDERR
 412                 "%s: snags: %d overriden by global --force\n",
 413                 $us, $snags_tripped;
 414         } else {
 415             fail sprintf
 416   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 417                 $us, $snags_tripped;
 418         }
 419     }
 420     $snags_summarised = $snags_forced + $snags_tripped;
 421 }
 422 sub snags_maybe_bail_early () {
 423     # useful to bail out early without doing a lot of work;
 424     # not a substitute for snags_maybe_bail.
 425     snags_maybe_bail() if $snags_tripped && !$opt_force;
 426 }
 427 sub any_snags () {
 428     return $snags_forced || $snags_tripped;
 429 }
 430
 431 sub gbp_pq_export ($$$) {
 432     my ($bname, $base, $tip) = @_;
 433     # must be run in a workarea.  $bname and patch-queue/$bname
 434     # ought not to exist.  Leaves you on patch-queue/$bname with
 435     # the patches staged but not committed.
 436     printdebug "gbp_pq_export $bname $base $tip\n";
 437     runcmd @git, qw(checkout -q -b), $bname, $base;
 438     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 439     my @gbp_cmd = (qw(gbp pq export));
 440     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 441     if ($r) {
 442         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 443         failedcmd @gbp_cmd;
 444     }
 445     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 446 }
 447
 448
 449 # xxx allow merge resolution separately from laundering, before git merge
 450
 451 # later/rework?
 452 #  use git-format-patch?
 453 #  our own patch identification algorithm?
 454 #  this is an alternative strategy
 455
 456 sub merge_failed ($$;@) {
 457     my ($wrecknotes, $emsg, @xmsgs) = @_;
 458     my @m;
 459     push @m, "Merge resolution failed: $emsg";
 460     push @m, @xmsgs;
 461
 462     changedir $maindir;
 463
 464     my @updates;
 465     merge_wreckage_cleaning \@updates;
 466     run_ref_updates_now "merge failed", \@updates;
 467
 468     @updates = ();
 469     keys %$wrecknotes;
 470     while (my ($k,$v) = each %$wrecknotes) {
 471         push @updates, "create $wrecknoteprefix/$k $v";
 472     }
 473     run_ref_updates_now "merge failed", \@updates;
 474     push @m, "Wreckage left in $wrecknoteprefix/*.";
 475
 476     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 477
 478     # use finish rather than fail, in case we are within an eval
 479     # (that can happen inside walk!)
 480     print STDERR "\n";
 481     print STDERR "$us: $_\n" foreach @m;
 482     finish 15;
 483 }
 484
 485 sub mwrecknote ($$$) {
 486     my ($wrecknotes, $reftail, $commitish) = @_;
 487     confess unless defined $commitish;
 488     printdebug "mwrecknote $reftail $commitish\n";
 489     $wrecknotes->{$reftail} = $commitish;
 490 }
 491
 492 sub merge_attempt_cmd {
 493     my $wrecknotes = shift @_;
 494     debugcmd '+', @_;
 495     $!=0; $?=-1;
 496     if (system @_) {
 497         merge_failed $wrecknotes,
 498             failedcmd_waitstatus(),
 499             "failed command: @_";
 500     }
 501 }
 502
 503 sub merge_series_patchqueue_convert ($$$);
 504
 505 sub merge_series ($$$;@) {
 506     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 507     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 508     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 509     # ^ specifies several patch series (currently we only support exactly 2)
 510     # return value is a commit which is the result of
 511     # merging the two versions of the same topic branch
 512     #   $input_q[0] and $input_q[1]
 513     # with respect to the old version
 514     #   $base_q
 515     # all onto $newbase.
 516
 517     # Creates, in *_q, a key MR for its private use
 518
 519     printdebug "merge_series newbase=$newbase\n";
 520
 521     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 522     $base_q->{MR}{S} = 'base';
 523
 524     my %prereq;
 525     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 526     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 527     # $prereq{<patch filename>}               exists or not (even later)
 528
 529     my $merged_pq;
 530
 531     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 532
 533     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 534
 535     local $workarea;
 536     fresh_workarea "merge";
 537     my $seriesfile = "debian/patches/series";
 538     in_workarea sub {
 539         playtree_setup();
 540         foreach my $q ($base_q, reverse @input_qs) {
 541             my $s = $q->{MR}{S};
 542             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 543             my @earlier;
 544             if (open S, $seriesfile) {
 545                 while (my $patch = <S>) {
 546                     chomp $patch or die $!;
 547                     $prereq{$patch} //= {};
 548                     foreach my $earlier (@earlier) {
 549                         $prereq{$patch}{$earlier}{$s}++ and die;
 550                     }
 551                     push @earlier, $patch;
 552                     stat "debian/patches/$patch" or die "$patch ?";
 553                 }
 554                 S->error and die "$seriesfile $!";
 555                 close S;
 556             } else {
 557                 die "$seriesfile $!" unless $!==ENOENT;
 558             }
 559             read_tree_upstream $newbase, 1;
 560             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 561                 "Convert $s to patch queue for merging",
 562                 "[git-debrebase merge-innards patch-queue import:".
 563                 " $q->{SeriesTip}]"
 564             ];
 565             printdebug "merge_series  pec $pec ";
 566             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 567             $pec = make_commit [ $pec ], [
 568                 "Drop series file from $s to avoid merge trouble",
 569                 "[git-debrebase merge-innards patch-queue prep:".
 570                 " $q->{SeriesTip}]"
 571             ];
 572
 573             read_tree_debian $newbase;
 574             if (@earlier) {
 575                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 576             } else {
 577                 rm_subdir_cached 'debian/patches';
 578             }
 579             $pec = make_commit [ $pec ], [
 580  "Update debian/ (excluding patches) to final to avoid re-merging",
 581  "debian/ was already merged and we need to just take that.",
 582                 "[git-debrebase merge-innards patch-queue packaging:".
 583                 " $q->{SeriesTip}]"
 584             ];
 585
 586             printdebug "pec' $pec\n";
 587             runcmd @git, qw(reset -q --hard), $pec;
 588             $q->{MR}{PEC} = $pec;
 589             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 590         }
 591         # now, because of reverse, we are on $input_q->{MR}{OQC}
 592         runcmd @git, qw(checkout -q -b merge);
 593         printdebug "merge_series merging...\n";
 594         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 595
 596         $attempt_cmd->(@mergecmd);
 597
 598         printdebug "merge_series merge ok, series...\n";
 599         # We need to construct a new series file
 600         # Firstly, resolve prereq
 601         foreach my $f (sort keys %prereq) {
 602             printdebug "merge_series  patch\t$f\t";
 603             if (!stat_exists "debian/patches/$f") {
 604                 print DEBUG " drop\n" if $debuglevel;
 605                 # git merge deleted it; that's how we tell it's not wanted
 606                 delete $prereq{$f};
 607                 next;
 608             }
 609             print DEBUG " keep\n" if $debuglevel;
 610             foreach my $g (sort keys %{ $prereq{$f} }) {
 611                 my $gfp = $prereq{$f}{$g};
 612                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 613                 if (!!$gfp->{0} == !!$gfp->{1}
 614                     ? $gfp->{0}
 615                     : !$gfp->{base}) {
 616                     print DEBUG "\tkeep\n" if $debuglevel;
 617                 } else {
 618                     print DEBUG "\tdrop\n" if $debuglevel;
 619                     delete $prereq{$f}{$g};
 620                 }
 621             }
 622         }
 623
 624         my $unsat = sub {
 625             my ($f) = @_;
 626             return scalar keys %{ $prereq{$f} };
 627         };
 628
 629         my $nodate = time + 1;
 630         my %authordate;
 631         # $authordate{<patch filename>};
 632         my $authordate = sub {
 633             my ($f) = @_;
 634             $authordate{$f} //= do {
 635                 open PF, "<", "debian/patches/$f" or die "$f $!";
 636                 while (<PF>) {
 637                     return $nodate if m/^$/;
 638                     last if s{^Date: }{};
 639                 }
 640                 chomp;
 641                 return cmdoutput qw(date +%s -d), $_;
 642             };
 643         };
 644
 645         open NS, '>', $seriesfile or die $!;
 646
 647         while (keys %prereq) {
 648             my $best;
 649             foreach my $try (sort keys %prereq) {
 650                 if ($best) {
 651                     next if (
 652                              $unsat->($try) <=> $unsat->($best) or
 653                              $authordate->($try) <=> $authordate->($best) or
 654                              $try cmp $best
 655                             ) >= 0;
 656                 }
 657                 $best = $try;
 658             }
 659             printdebug "merge_series series next $best\n";
 660             print NS "$best\n" or die $!;
 661             delete $prereq{$best};
 662             foreach my $gp (values %prereq) {
 663                 delete $gp->{$best};
 664             }
 665         }
 666
 667         runcmd @git, qw(add), $seriesfile;
 668         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 669         $merged_pq = git_rev_parse 'HEAD';
 670         $mwrecknote->('merged-patchqueue', $merged_pq);
 671     };
 672     return merge_series_patchqueue_convert
 673             $wrecknotes, $newbase, $merged_pq;
 674 }
 675
 676 sub merge_series_patchqueue_convert ($$$) {
 677     my ($wrecknotes, $newbase, $merged_pq) = @_;
 678
 679     my $result;
 680     in_workarea sub {
 681         playtree_setup();
 682         printdebug "merge_series series gbp pq import\n";
 683         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 684
 685         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 686
 687         # OK now we are on patch-queue/merge, and we need to rebase
 688         # onto the intended parent and drop the patches from each one
 689
 690         printdebug "merge_series series ok, building...\n";
 691         my $build = $newbase;
 692         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 693         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 694             my $commit = git_cat_file $c, 'commit';
 695             printdebug "merge_series series ok, building $c\n";
 696             read_tree_upstream $c, 0, $newbase;
 697             my $tree = cmdoutput @git, qw(write-tree);
 698             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 699             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 700             open C, ">", "../mcommit" or die $!;
 701             print C $commit or die $!;
 702             close C or die $!;
 703             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 704         }
 705         $result = $build;
 706         mwrecknote($wrecknotes, 'merged-result', $result);
 707
 708         runcmd @git, qw(update-ref refs/heads/result), $result;
 709
 710         runcmd @git, qw(checkout -q -b debug);
 711         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 712         runcmd @git, qw(add .);
 713         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 714         my $mdebug = git_rev_parse 'HEAD';
 715         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 716         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 717     };
 718     printdebug "merge_series returns $result\n";
 719     return $result;
 720 }
 721
 722 # classify returns an info hash like this
 723 #   CommitId => $objid
 724 #   Hdr => # commit headers, including 1 final newline
 725 #   Msg => # commit message (so one newline is dropped)
 726 #   Tree => $treeobjid
 727 #   Type => (see below)
 728 #   Parents = [ {
 729 #       Ix => $index # ie 0, 1, 2, ...
 730 #       CommitId
 731 #       Differs => return value from get_differs
 732 #       IsOrigin
 733 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 734 #     } ...]
 735 #   NewMsg => # commit message, but with any [dgit import ...] edited
 736 #             # to say "[was: ...]"
 737 #
 738 # Types:
 739 #   Packaging
 740 #   Changelog
 741 #   Upstream
 742 #   AddPatches
 743 #   Mixed
 744 #
 745 #   Pseudomerge
 746 #     has additional entres in classification result
 747 #       Overwritten = [ subset of Parents ]
 748 #       Contributor = $the_remaining_Parent
 749 #
 750 #   DgitImportUnpatched
 751 #     has additional entry in classification result
 752 #       OrigParents = [ subset of Parents ]
 753 #
 754 #   Anchor
 755 #     has additional entry in classification result
 756 #       OrigParents = [ subset of Parents ]  # singleton list
 757 #
 758 #   TreatAsAnchor
 759 #
 760 #   BreakwaterStart
 761 #
 762 #   Unknown
 763 #     has additional entry in classification result
 764 #       Why => "prose"
 765
 766 sub parsecommit ($;$) {
 767     my ($objid, $p_ref) = @_;
 768     # => hash with                   CommitId Hdr Msg Tree Parents
 769     #    Parents entries have only   Ix CommitId
 770     #    $p_ref, if provided, must be [] and is used as a base for Parents
 771
 772     $p_ref //= [];
 773     die if @$p_ref;
 774
 775     my ($h,$m) = get_commit $objid;
 776
 777     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 778     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 779
 780     my $r = {
 781         CommitId => $objid,
 782         Hdr => $h,
 783         Msg => $m,
 784         Tree => $t,
 785         Parents => $p_ref,
 786     };
 787
 788     foreach my $ph (@ph) {
 789         push @$p_ref, {
 790             Ix => scalar @$p_ref,
 791             CommitId => $ph,
 792         };
 793     }
 794
 795     return $r;
 796 }
 797
 798 sub classify ($) {
 799     my ($objid) = @_;
 800
 801     my @p;
 802     my $r = parsecommit($objid, \@p);
 803     my $t = $r->{Tree};
 804
 805     foreach my $p (@p) {
 806         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 807     }
 808
 809     printdebug "classify $objid \$t=$t \@p",
 810         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 811         "\n";
 812
 813     my $classify = sub {
 814         my ($type, @rest) = @_;
 815         $r = { %$r, Type => $type, @rest };
 816         if ($debuglevel) {
 817             printdebug " = $type ".(dd $r)."\n";
 818         }
 819         return $r;
 820     };
 821     my $unknown = sub {
 822         my ($why) = @_;
 823         $r = { %$r, Type => qw(Unknown), Why => $why };
 824         printdebug " ** Unknown\n";
 825         return $r;
 826     };
 827
 828     if (grep { $_ eq $objid } @opt_anchors) {
 829         return $classify->('TreatAsAnchor');
 830     }
 831
 832     my @identical = grep { !$_->{Differs} } @p;
 833     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 834     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 835
 836     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 837         # multi-orig upstreams are represented with an anchor merge
 838         # from a single upstream commit which combines the orig tarballs
 839
 840         # Every anchor tagged this way must be a merge.
 841         # We are relying on the
 842         #     [git-debrebase anchor: ...]
 843         # commit message annotation in "declare" anchor merges (which
 844         # do not have any upstream changes), to distinguish those
 845         # anchor merges from ordinary pseudomerges (which we might
 846         # just try to strip).
 847         #
 848         # However, the user is going to be doing git-rebase a lot.  We
 849         # really don't want them to rewrite an anchor commit.
 850         # git-rebase trips up on merges, so that is a useful safety
 851         # catch.
 852         #
 853         # BreakwaterStart commits are also anchors in the terminology
 854         # of git-debrebase(5), but they are untagged (and always
 855         # manually generated).
 856         #
 857         # We cannot not tolerate any tagged linear commit (ie,
 858         # BreakwaterStart commits tagged `[anchor:') because such a
 859         # thing could result from an erroneous linearising raw git
 860         # rebase of a merge anchor.  That would represent a corruption
 861         # of the branch. and we want to detect and reject the results
 862         # of such corruption before it makes it out anywhere.  If we
 863         # reject it here then we avoid making the pseudomerge which
 864         # would be needed to push it.
 865
 866         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 867         @p == 2 or return $badanchor->("has other than two parents");
 868         $haspatches and return $badanchor->("contains debian/patches");
 869
 870         # How to decide about l/r ordering of anchors ?  git
 871         # --topo-order prefers to expand 2nd parent first.  There's
 872         # already an easy rune to look for debian/ history anyway (git log
 873         # debian/) so debian breakwater branch should be 1st parent; that
 874         # way also there's also an easy rune to look for the upstream
 875         # patches (--topo-order).
 876
 877         # Also this makes --first-parent be slightly more likely to
 878         # be useful - it makes it provide a linearised breakwater history.
 879
 880         # Of course one can say somthing like
 881         #  gitk -- ':/' ':!/debian'
 882         # to get _just_ the commits touching upstream files, and by
 883         # the TREESAME logic in git-rev-list this will leave the
 884         # breakwater into upstream at the first anchor.  But that
 885         # doesn't report debian/ changes at all.
 886
 887         # Other observations about gitk: by default, gitk seems to
 888         # produce output in a different order to git-rev-list.  I
 889         # can't seem to find this documented anywhere.  gitk
 890         # --date-order DTRT.  But, gitk always seems to put the
 891         # parents from left to right, in order, so it's easy to see
 892         # which way round a pseudomerge is.
 893
 894         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 895         $p[1]{Differs} & ~DS_DEB and
 896             $badanchor->("upstream files differ from left parent");
 897         $p[0]{Differs} & ~D_UPS and
 898             $badanchor->("debian/ differs from right parent");
 899
 900         return $classify->(qw(Anchor),
 901                            OrigParents => [ $p[1] ]);
 902     }
 903
 904     if (@p == 1) {
 905         my $d = $r->{Parents}[0]{Differs};
 906         if ($d == D_PAT_ADD) {
 907             return $classify->(qw(AddPatches));
 908         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 909             return $unknown->("edits debian/patches");
 910         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 911             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 912             if ($ty eq 'tree') {
 913                 if ($d == D_DEB_CLOG) {
 914                     return $classify->(qw(Changelog));
 915                 } else {
 916                     return $classify->(qw(Packaging));
 917                 }
 918             } elsif ($ty eq 'missing') {
 919                 return $classify->(qw(BreakwaterStart));
 920             } else {
 921                 return $unknown->("parent's debian is not a directory");
 922             }
 923         } elsif ($d == D_UPS) {
 924             return $classify->(qw(Upstream));
 925         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 926             return $classify->(qw(Mixed));
 927         } elsif ($d == 0) {
 928             return $unknown->("no changes");
 929         } else {
 930             confess "internal error $objid ?";
 931         }
 932     }
 933     if (!@p) {
 934         return $unknown->("origin commit");
 935     }
 936
 937     if (@p == 2 && @identical == 1) {
 938         my @overwritten = grep { $_->{Differs} } @p;
 939         confess "internal error $objid ?" unless @overwritten==1;
 940         return $classify->(qw(Pseudomerge),
 941                            Overwritten => [ $overwritten[0] ],
 942                            Contributor => $identical[0]);
 943     }
 944     if (@p == 2 && @identical == 2) {
 945         my $get_t = sub {
 946             my ($ph,$pm) = get_commit $_[0]{CommitId};
 947             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 948             $1;
 949         };
 950         my @bytime = @p;
 951         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 952         if ($order > 0) { # newer first
 953         } elsif ($order < 0) {
 954             @bytime = reverse @bytime;
 955         } else {
 956             # same age, default to order made by -s ours
 957             # that is, commit was made by someone who preferred L
 958         }
 959         return $classify->(qw(Pseudomerge),
 960                            SubType => qw(Ambiguous),
 961                            Contributor => $bytime[0],
 962                            Overwritten => [ $bytime[1] ]);
 963     }
 964     foreach my $p (@p) {
 965         my ($p_h, $p_m) = get_commit $p->{CommitId};
 966         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 967         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 968     }
 969     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 970     my $m2 = $r->{Msg};
 971     if (!(grep { !$_->{IsOrigin} } @p) and
 972         (@orig_ps >= @p - 1) and
 973         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 974         $r->{NewMsg} = $m2;
 975         return $classify->(qw(DgitImportUnpatched),
 976                            OrigParents => \@orig_ps);
 977     }
 978
 979     if (@p == 2 and
 980         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 981         # xxx ^ metadata tag needs adding to (5)
 982         return $classify->("MergedBreakwaters");
 983     }
 984     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 985         return $unknown->("unknown kind of merge from $1");
 986     }
 987     if (@p > 2) {
 988         return $unknown->("octopus merge");
 989     }
 990
 991     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 992         return $unknown->("general two-parent merge");
 993     }
 994
 995     return $classify->("VanillaMerge");
 996 }
 997
 998 sub keycommits ($;$$$$$);
 999
1000 sub mergedbreakwaters_anchor ($) {
1001     my ($cl) = @_;
1002     my $best_anchor;
1003     foreach my $p (@{ $cl->{Parents} }) {
1004         my ($panchor, $pbw) = keycommits $p->{CommitId},
1005             undef,undef,undef,undef, 1;
1006         $best_anchor = $panchor
1007             if !defined $best_anchor
1008             or is_fast_fwd $best_anchor, $panchor;
1009         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
1010             unless is_fast_fwd $panchor, $best_anchor;
1011     }
1012     return $best_anchor;
1013 }
1014
1015 sub keycommits ($;$$$$$) {
1016     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
1017     # => ($anchor, $breakwater)
1018
1019     # $unclean->("unclean-$tagsfx", $msg, $cl)
1020     # $furniture->("unclean-$tagsfx", $msg, $cl)
1021     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
1022     #   is callled for each situation or commit that
1023     #   wouldn't be found in a laundered branch
1024     # $furniture is for furniture commits such as might be found on an
1025     #   interchange branch (pseudomerge, d/patches, changelog)
1026     # $trouble is for things whnich prevent the return of
1027     #   anchor and breakwater information; if that is ignored,
1028     #   then keycommits returns (undef, undef) instead.
1029     # $fatal is for unprocessable commits, and should normally cause
1030     #    a failure.  If ignored, agaion, (undef, undef) is returned.
1031     #
1032     # If $claimed_bw, this is supposed to be a breakwater commit.
1033     #
1034     # If a callback is undef, fail is called instead.
1035     # If a callback is defined but false, the situation is ignored.
1036     # Callbacks may say:
1037     #   no warnings qw(exiting); last;
1038     # if the answer is no longer wanted.
1039
1040     my ($anchor, $breakwater);
1041     $breakwater = $head if $claimed_bw;
1042     my $clogonly;
1043     my $cl;
1044     my $found_pm;
1045     $fatal //= sub { fail $_[1]; };
1046     my $x = sub {
1047         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
1048         my $why = $mainwhy.$xwhy;
1049         my $m = "branch needs laundering (run git-debrebase): $why";
1050         fail $m unless defined $cb;
1051         return unless $cb;
1052         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
1053     };
1054     my $found_anchor = sub {
1055         ($anchor) = @_;
1056         $breakwater //= $clogonly;
1057         $breakwater //= $head;
1058         no warnings qw(exiting);
1059         last;
1060     };
1061     for (;;) {
1062         $cl = classify $head;
1063         my $ty = $cl->{Type};
1064         if ($ty eq 'Packaging') {
1065             $breakwater //= $clogonly;
1066             $breakwater //= $head;
1067         } elsif ($ty eq 'Changelog') {
1068             # this is going to count as the tip of the breakwater
1069             # only if it has no upstream stuff before it
1070             $clogonly //= $head;
1071         } elsif ($ty eq 'Anchor' or
1072                  $ty eq 'TreatAsAnchor' or
1073                  $ty eq 'BreakwaterStart') {
1074             $found_anchor->($head);
1075         } elsif ($ty eq 'Upstream') {
1076             $x->($unclean, 'ordering',
1077  "packaging change ($breakwater) follows upstream change"," (eg $head)")
1078                 if defined $breakwater;
1079             $clogonly = undef;
1080             $breakwater = undef;
1081         } elsif ($ty eq 'Mixed') {
1082             $x->($unclean, 'mixed',
1083                  "found mixed upstream/packaging commit"," ($head)");
1084             $clogonly = undef;
1085             $breakwater = undef;
1086         } elsif ($ty eq 'Pseudomerge' or
1087                  $ty eq 'AddPatches') {
1088             my $found_pm = 1;
1089             $x->($furniture, (lc $ty),
1090                  "found interchange bureaucracy commit ($ty)"," ($head)");
1091         } elsif ($ty eq 'DgitImportUnpatched') {
1092             if ($found_pm) {
1093                 $x->($trouble, 'dgitimport',
1094                      "found dgit dsc import"," ($head)");
1095                 return (undef,undef);
1096             } else {
1097                 $x->($fatal, 'unprocessable',
1098                      "found bare dgit dsc import with no prior history",
1099                      " ($head)");
1100                 return (undef,undef);
1101             }
1102         } elsif ($ty eq 'VanillaMerge') {
1103             $x->($trouble, 'vanillamerge',
1104                  "found vanilla merge"," ($head)");
1105             return (undef,undef);
1106         } elsif ($ty eq 'MergedBreakwaters') {
1107             $found_anchor->(mergedbreakwaters_anchor $cl);
1108         } else {
1109             $x->($fatal, 'unprocessable',
1110                  "found unprocessable commit, cannot cope: $cl->{Why}",
1111                  " ($head)");
1112             return (undef,undef);
1113         }
1114         $head = $cl->{Parents}[0]{CommitId};
1115     }
1116     return ($anchor, $breakwater);
1117 }
1118
1119 sub walk ($;$$$);
1120 sub walk ($;$$$) {
1121     my ($input,
1122         $nogenerate,$report, $report_lprefix) = @_;
1123     # => ($tip, $breakwater_tip, $last_anchor)
1124     # (or nothing, if $nogenerate)
1125
1126     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1127     $report_lprefix //= '';
1128
1129     # go through commits backwards
1130     # we generate two lists of commits to apply:
1131     # breakwater branch and upstream patches
1132     my (@brw_cl, @upp_cl, @processed);
1133     my %found;
1134     my $upp_limit;
1135     my @pseudomerges;
1136
1137     my $cl;
1138     my $xmsg = sub {
1139         my ($prose, $info) = @_;
1140         my $ms = $cl->{Msg};
1141         chomp $ms;
1142         $info //= '';
1143         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1144         return (Msg => $ms);
1145     };
1146     my $rewrite_from_here = sub {
1147         my ($cl) = @_;
1148         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1149         push @$cl, $sp_cl;
1150         push @processed, $sp_cl;
1151     };
1152     my $cur = $input;
1153
1154     my $prdelim = "";
1155     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1156
1157     my $prline = sub {
1158         return unless $report;
1159         print $report $prdelim, $report_lprefix, @_;
1160         $prdelim = "\n";
1161     };
1162
1163     my $bomb = sub { # usage: return $bomb->();
1164         print $report " Unprocessable" if $report;
1165         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1166         $prprdelim->();
1167         if ($nogenerate) {
1168             return (undef,undef);
1169         }
1170         fail "found unprocessable commit, cannot cope".
1171             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1172             " (commit $cur) (d.".
1173             (join ' ', map { sprintf "%#x", $_->{Differs} }
1174              @{ $cl->{Parents} }).
1175                  ")";
1176     };
1177
1178     my $build;
1179     my $breakwater;
1180
1181     my $build_start = sub {
1182         my ($msg, $parent) = @_;
1183         $prline->(" $msg");
1184         $build = $parent;
1185         no warnings qw(exiting); last;
1186     };
1187
1188     my $nomerge = sub {
1189         my ($emsg) = @_;
1190         merge_failed $cl->{MergeWreckNotes}, $emsg;
1191     };
1192
1193     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1194
1195     my $last_anchor;
1196
1197     for (;;) {
1198         $cl = classify $cur;
1199         $cl->{MergeWreckNotes} //= {};
1200         my $ty = $cl->{Type};
1201         my $st = $cl->{SubType};
1202         $prline->("$cl->{CommitId} $cl->{Type}");
1203         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1204         push @processed, $cl;
1205         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1206         if ($ty eq 'AddPatches') {
1207             $cur = $p0;
1208             $rewrite_from_here->(\@upp_cl);
1209             next;
1210         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1211             push @brw_cl, $cl;
1212             $cur = $p0;
1213             next;
1214         } elsif ($ty eq 'BreakwaterStart') {
1215             $last_anchor = $cur;
1216             $build_start->('FirstPackaging', $cur);
1217         } elsif ($ty eq 'Upstream') {
1218             push @upp_cl, $cl;
1219             $cur = $p0;
1220             next;
1221         } elsif ($ty eq 'Mixed') {
1222             my $queue = sub {
1223                 my ($q, $wh) = @_;
1224                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1225                 push @$q, $cls;
1226             };
1227             $queue->(\@brw_cl, "debian");
1228             $queue->(\@upp_cl, "upstream");
1229             $rewrite_from_here->(\@brw_cl);
1230             $cur = $p0;
1231             next;
1232         } elsif ($ty eq 'Pseudomerge') {
1233             my $contrib = $cl->{Contributor}{CommitId};
1234             print $report " Contributor=$contrib" if $report;
1235             push @pseudomerges, $cl;
1236             $rewrite_from_here->(\@upp_cl);
1237             $cur = $contrib;
1238             next;
1239         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1240             $last_anchor = $cur;
1241             $build_start->("Anchor", $cur);
1242         } elsif ($ty eq 'DgitImportUnpatched') {
1243             my $pm = $pseudomerges[-1];
1244             if (defined $pm) {
1245                 # To an extent, this is heuristic.  Imports don't have
1246                 # a useful history of the debian/ branch.  We assume
1247                 # that the first pseudomerge after an import has a
1248                 # useful history of debian/, and ignore the histories
1249                 # from later pseudomerges.  Often the first pseudomerge
1250                 # will be the dgit import of the upload to the actual
1251                 # suite intended by the non-dgit NMUer, and later
1252                 # pseudomerges may represent in-archive copies.
1253                 my $ovwrs = $pm->{Overwritten};
1254                 printf $report " PM=%s \@Overwr:%d",
1255                     $pm->{CommitId}, (scalar @$ovwrs)
1256                     if $report;
1257                 if (@$ovwrs != 1) {
1258                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1259                     return $bomb->();
1260                 }
1261                 my $ovwr = $ovwrs->[0]{CommitId};
1262                 printf $report " Overwr=%s", $ovwr if $report;
1263                 # This import has a tree which is just like a
1264                 # breakwater tree, but it has the wrong history.  It
1265                 # ought to have the previous breakwater (which the
1266                 # pseudomerge overwrote) as an ancestor.  That will
1267                 # make the history of the debian/ files correct.  As
1268                 # for the upstream version: either it's the same as
1269                 # was ovewritten (ie, same as the previous
1270                 # breakwater), in which case that history is precisely
1271                 # right; or, otherwise, it was a non-gitish upload of a
1272                 # new upstream version.  We can tell these apart by
1273                 # looking at the tree of the supposed upstream.
1274                 push @brw_cl, {
1275                     %$cl,
1276                     SpecialMethod => 'DgitImportDebianUpdate',
1277                     $xmsg->("convert dgit import: debian changes")
1278                 }, {
1279                     %$cl,
1280                     SpecialMethod => 'DgitImportUpstreamUpdate',
1281                     $xmsg->("convert dgit import: upstream update",
1282                             " anchor")
1283                 };
1284                 $prline->(" Import");
1285                 $rewrite_from_here->(\@brw_cl);
1286                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1287                 $cur = $ovwr;
1288                 next;
1289             } else {
1290                 # Everything is from this import.  This kind of import
1291                 # is already nearly in valid breakwater format, with the
1292                 # patches as commits.  Unfortunately it contains
1293                 # debian/patches/.
1294                 printdebug "*** WALK BOMB bare dgit import\n";
1295                 $cl->{Why} = "bare dgit dsc import";
1296                 return $bomb->();
1297             }
1298             die "$ty ?";
1299         } elsif ($ty eq 'MergedBreakwaters') {
1300             $last_anchor = mergedbreakwaters_anchor $cl;
1301             $build_start->(' MergedBreakwaters', $cur);
1302             last;
1303         } elsif ($ty eq 'VanillaMerge') {
1304             # User may have merged unstitched branch(es).  We will
1305             # have now lost what ffq-prev was then (since the later
1306             # pseudomerge may introduce further changes).  The effect
1307             # of resolving such a merge is that we may have to go back
1308             # further in history to find a merge base, since the one
1309             # which was reachable via ffq-prev is no longer findable.
1310             # This is suboptimal, but if it all works we'll have done
1311             # the right thing.
1312             # xxx we should warn the user in the docs about this
1313
1314             my $ok=1;
1315             my $best_anchor;
1316             # We expect to find a dominating anchor amongst the
1317             # inputs' anchors.  That will be the new anchor.
1318             #
1319             # More complicated is finding a merge base for the
1320             # breakwaters.  We need a merge base that is a breakwater
1321             # commit.  The ancestors of breakwater commits are more
1322             # breakwater commits and possibly upstream commits and the
1323             # ancestors of those upstream.  Upstreams might have
1324             # arbitrary ancestors.  But any upstream commit U is
1325             # either included in both anchors, in which case the
1326             # earlier anchor is a better merge base than any of U's
1327             # ancestors; or U is not included in the older anchor, in
1328             # which case U is not an ancestor of the vanilla merge at
1329             # all.  So no upstream commit, nor any ancestor thereof,
1330             # is a best merge base.  As for non-breakwater Debian
1331             # commits: these are never ancestors of any breakwater.
1332             #
1333             # So any best merge base as found by git-merge-base
1334             # is a suitable breakwater anchor.  Usually there will
1335             # be only one.
1336
1337             printdebug "*** MERGE\n";
1338
1339             my @bwbcmd = (@git, qw(merge-base));
1340             my @ibcmd = (@git, qw(merge-base --all));
1341             my $might_be_in_bw = 1;
1342
1343             my $ps = $cl->{Parents};
1344
1345             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1346
1347             foreach my $p (@$ps) {
1348                 $prline->(" VanillaMerge ".$p->{Ix});
1349                 $prprdelim->();
1350                 my ($ptip, $pbw, $panchor) =
1351                     walk $p->{CommitId}, 0, $report,
1352                          $report_lprefix.'  ';
1353                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1354                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1355                 $p->{Anchor} = $panchor;
1356
1357                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1358                 $mwrecknote->("$lr-input", $p->{CommitId});
1359
1360                 my $mwrecknote_parent = sub {
1361                     my ($which) = @_;
1362                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1363                 };
1364                 $mwrecknote_parent->('Laundered');
1365                 $mwrecknote_parent->('Breakwater');
1366                 $mwrecknote_parent->('Anchor');
1367
1368                 $best_anchor = $panchor if
1369                     !defined $best_anchor or
1370                     is_fast_fwd $best_anchor, $panchor;
1371
1372                 printdebug " MERGE BA best=".($best_anchor//'-').
1373                     " p=$panchor\n";
1374             }
1375
1376             $mwrecknote->('result-anchor', $best_anchor);
1377
1378             foreach my $p (@$ps) {
1379                 $prline->(" VanillaMerge ".$p->{Ix});
1380                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1381                     $nomerge->('divergent anchors');
1382                 } elsif ($p->{Anchor} eq $best_anchor) {
1383                     print $report " SameAnchor" if $report;
1384                 } else {
1385                     print $report " SupersededAnchor" if $report;
1386                 }
1387                 if ($p->{Breakwater} eq $p->{CommitId}) {
1388                     # this parent commit was its own breakwater,
1389                     # ie it is part of the breakwater
1390                     print $report " Breakwater" if $report;
1391                 } else {
1392                     $might_be_in_bw = 0;
1393                 }
1394                 push @bwbcmd, $p->{Breakwater};
1395                 push @ibcmd, $p->{CommitId};
1396             }
1397
1398             if ($ok && $might_be_in_bw) {
1399                 # We could rewrite this to contaion the metadata
1400                 # declaring it to be MergedBreakwaters, but
1401                 # unnecessarily rewriting a merge seems unhelpful.
1402                 $prline->(" VanillaMerge MergedBreakwaters");
1403                 $last_anchor = $best_anchor;
1404                 $build_start->('MergedBreakwaters', $cur);
1405             }
1406
1407             my $bwb = cmdoutput @bwbcmd;
1408
1409             # OK, now we have a breakwater base, but we need the merge
1410             # base for the interchange branch because we need the delta
1411             # queue.
1412             #
1413             # This a the best merge base of our inputs which has the
1414             # breakwater merge base as an ancestor.
1415
1416             my @ibs =
1417                 grep /./,
1418                 split /\n/,
1419                 cmdoutput @ibcmd;
1420
1421             @ibs or confess 'internal error, expected anchor at least ?';
1422
1423             my $ib;
1424             my $ibleaf;
1425             foreach my $tibix (0..$#ibs) {
1426                 my $tib = $ibs[$tibix];
1427                 my $ff = is_fast_fwd $bwb, $tib;
1428                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1429                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1430                 $mwrecknote->($tibleaf, $tib);
1431                 next unless $ff;
1432                 next if $ib;
1433                 $ib = $tib;
1434                 $ibleaf = $tibleaf;
1435             }
1436
1437             $ib or $nomerge->("no suitable interchange merge base");
1438
1439             $prline->("  VanillaMerge Base");
1440             $prprdelim->();
1441             my ($btip, $bbw, $banchor) = eval {
1442                 walk $ib, 0, $report, $report_lprefix.'  ';
1443             };
1444             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1445                        $@)
1446                 if length $@;
1447
1448             $mwrecknote->("mergebase-laundered", $btip);
1449             $mwrecknote->("mergebase-breakwater", $bbw);
1450             $mwrecknote->("mergebase-anchor", $banchor);
1451
1452             my $ibinfo = { SeriesTip => $btip,
1453                            SeriesBase => $bbw,
1454                            Anchor => $banchor,
1455                            LeftRight => 'mergebase' };
1456
1457             $bbw eq $bwb
1458                 or $nomerge->("interchange merge-base ($ib)'s".
1459                               " breakwater ($bbw)".
1460                               " != breakwaters' merge-base ($bwb)");
1461
1462             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1463                  or $nomerge->("interchange merge-base ($ib)'s".
1464                                " anchor ($ibinfo->{SeriesBase})".
1465                                " != any merge input's anchor (".
1466                                (join ' ', map { $_->{Anchor} } @$ps).
1467                                ")");
1468
1469             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1470             $cl->{MergeBestAnchor} = $best_anchor;
1471             push @brw_cl, {
1472                 %$cl,
1473                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1474                 $xmsg->('constructed from vanilla merge',
1475                         ' merged-breakwater'),
1476             };
1477             push @upp_cl, {
1478                 %$cl,
1479                 SpecialMethod => 'MergeMergeSeries',
1480             };
1481             $build_start->('MergeBreakwaters', $cur);
1482         } else {
1483             printdebug "*** WALK BOMB unrecognised\n";
1484             return $bomb->();
1485         }
1486     }
1487     $prprdelim->();
1488
1489     printdebug "*** WALK prep done cur=$cur".
1490         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1491
1492     return if $nogenerate;
1493
1494     # Now we build it back up again
1495
1496     fresh_workarea();
1497
1498     my $rewriting = 0;
1499
1500     $#upp_cl = $upp_limit if defined $upp_limit;
1501
1502     my $committer_authline = calculate_committer_authline();
1503
1504     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1505
1506     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1507
1508     in_workarea sub {
1509         mkdir $rd or $!==EEXIST or die $!;
1510         my $current_method;
1511         my $want_debian = $build;
1512         my $want_upstream = $build;
1513
1514         my $read_tree_upstream = sub { ($want_upstream) = @_; };
1515         my $read_tree_debian = sub { ($want_debian) = @_; };
1516
1517         foreach my $cl (qw(Debian), (reverse @brw_cl),
1518                         { SpecialMethod => 'RecordBreakwaterTip' },
1519                         qw(Upstream), (reverse @upp_cl)) {
1520             if (!ref $cl) {
1521                 $current_method = $cl;
1522                 next;
1523             }
1524             my $method = $cl->{SpecialMethod} // $current_method;
1525             my @parents = ($build);
1526             my $cltree = $cl->{CommitId};
1527             printdebug "WALK BUILD ".($cltree//'undef').
1528                 " $method (rewriting=$rewriting)\n";
1529             if ($method eq 'Debian') {
1530                 $read_tree_debian->($cltree);
1531             } elsif ($method eq 'Upstream') {
1532                 $read_tree_upstream->($cltree);
1533             } elsif ($method eq 'StartRewrite') {
1534                 $rewriting = 1;
1535                 next;
1536             } elsif ($method eq 'RecordBreakwaterTip') {
1537                 $breakwater = $build;
1538                 next;
1539             } elsif ($method eq 'DgitImportDebianUpdate') {
1540                 $read_tree_debian->($cltree);
1541             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1542                 confess unless $rewriting;
1543                 my $differs = (get_differs $build, $cltree);
1544                 next unless $differs & D_UPS;
1545                 $read_tree_upstream->($cltree);
1546                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1547             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1548                 print "Found a general merge, will try to tidy it up.\n";
1549                 $rewriting = 1;
1550                 $read_tree_upstream->($cl->{MergeBestAnchor});
1551                 $read_tree_debian->($cltree);
1552                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1553             } elsif ($method eq 'MergeMergeSeries') {
1554                 my $cachehit = reflog_cache_lookup
1555                     $merge_cache_ref, "vanilla-merge $cl->{CommitId}";
1556                 if ($cachehit) {
1557                     print "Using supplied resolution for $cl->{CommitId}...\n";
1558                     $build = $cachehit;
1559                     $mwrecknote->('cached-resolution', $build);
1560                 } else {
1561                     print "Running merge resolution for $cl->{CommitId}...\n";
1562                     $mwrecknote->('new-base', $build);
1563                     $build = merge_series
1564                         $build, $cl->{MergeWreckNotes},
1565                         $cl->{MergeInterchangeBaseInfo},
1566                         @{ $cl->{Parents} };
1567                 }
1568                 $last_anchor = $cl->{MergeBestAnchor};
1569
1570                 # Check for mismerges:
1571                 my $check = sub {
1572                     my ($against, $allow, $what) = @_;
1573                     my $differs = get_differs $build, $against;
1574                     $nomerge->(sprintf
1575        "merge misresolved: %s are not the same (%s %s d.%#x)",
1576                                $what, $against, $build, $differs)
1577                         if $differs & ~($allow | D_PAT_ADD);
1578                 };
1579
1580                 # Breakwater changes which were in each side of the
1581                 # merge will have been incorporated into the
1582                 # MergeCreateMergedBreakwaters output.  Because the
1583                 # upstream series was rebased onto the new breakwater,
1584                 # so should all of the packaging changes which were in
1585                 # the input.
1586                 $check->($input, D_UPS, 'debian files');
1587
1588                 # Upstream files are merge_series, which ought to
1589                 # have been identical to the original merge.
1590                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1591
1592                 print "Merge resolution successful.\n";
1593                 next;
1594             } else {
1595                 confess "$method ?";
1596             }
1597             if (!$rewriting) {
1598                 my $procd = (pop @processed) // 'UNDEF';
1599                 if ($cl ne $procd) {
1600                     $rewriting = 1;
1601                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1602                 }
1603             }
1604             if ($rewriting || $opt_careful) {
1605                 read_tree_upstream $want_upstream, 0, $want_debian;
1606
1607                 my $newtree = cmdoutput @git, qw(write-tree);
1608                 my $ch = $cl->{Hdr};
1609                 $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1610                 $ch =~ s{^parent .*\n}{}mg;
1611                 $ch =~ s{(?=^author)}{
1612                     join '', map { "parent $_\n" } @parents
1613                 }me or confess "$ch ?";
1614                 if ($rewriting) {
1615                     $ch =~ s{^committer .*$}{$committer_authline}m
1616                         or confess "$ch ?";
1617                 }
1618                 my $cf = "$rd/m$rewriting";
1619                 open CD, ">", $cf or die $!;
1620                 print CD $ch, "\n", $cl->{Msg} or die $!;
1621                 close CD or die $!;
1622                 my @cmd = (@git, qw(hash-object));
1623                 push @cmd, qw(-w) if $rewriting;
1624                 push @cmd, qw(-t commit), $cf;
1625                 my $newcommit = cmdoutput @cmd;
1626                 confess "$ch ?" unless $rewriting
1627                     or $newcommit eq $cl->{CommitId};
1628                 $build = $newcommit;
1629             } else {
1630                 $build = $cl->{CommitId};
1631                 trees_diff_walk "$want_upstream:", "$build:", sub {
1632                     my ($n) = @_;
1633                     no warnings qw(exiting);
1634                     next if $n eq 'debian/';
1635                     confess "mismatch @_ ?";
1636                 };
1637                 trees_diff_walk "$want_debian:debian", "$build:debian", sub {
1638                     confess "mismatch @_ ?";
1639                 };
1640                 my @old_parents = map { $_->{CommitId} } @{ $cl->{Parents} };
1641                 confess "mismatch @parents != @old_parents ?"
1642                     unless "@parents" eq "@old_parents";
1643             }
1644             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1645                 $last_anchor = $cur;
1646             }
1647         }
1648     };
1649
1650     my $final_check = get_differs $build, $input;
1651     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1652         if $final_check & ~D_PAT_ADD;
1653
1654     my @r = ($build, $breakwater, $last_anchor);
1655     printdebug "*** WALK RETURN @r\n";
1656     return @r
1657 }
1658
1659 sub get_head () {
1660     git_check_unmodified();
1661     return git_rev_parse qw(HEAD);
1662 }
1663
1664 sub update_head ($$$) {
1665     my ($old, $new, $mrest) = @_;
1666     push @deferred_updates, "update HEAD $new $old";
1667     run_deferred_updates $mrest;
1668 }
1669
1670 sub update_head_checkout ($$$) {
1671     my ($old, $new, $mrest) = @_;
1672     update_head $old, $new, $mrest;
1673     runcmd @git, qw(reset --hard);
1674 }
1675
1676 sub update_head_postlaunder ($$$) {
1677     my ($old, $tip, $reflogmsg) = @_;
1678     return if $tip eq $old && !@deferred_updates;
1679     print "git-debrebase: laundered (head was $old)\n";
1680     update_head $old, $tip, $reflogmsg;
1681     # no tree changes except debian/patches
1682     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1683 }
1684
1685 sub currently_rebasing() {
1686     foreach (qw(rebase-merge rebase-apply)) {
1687         return 1 if stat_exists "$maindir_gitdir/$_";
1688     }
1689     return 0;
1690 }
1691
1692 sub bail_if_rebasing() {
1693     fail "you are in the middle of a git-rebase already"
1694         if currently_rebasing();
1695 }
1696
1697 sub do_launder_head ($) {
1698     my ($reflogmsg) = @_;
1699     my $old = get_head();
1700     record_ffq_auto();
1701     my ($tip,$breakwater) = walk $old;
1702     snags_maybe_bail();
1703     update_head_postlaunder $old, $tip, $reflogmsg;
1704     return ($tip,$breakwater);
1705 }
1706
1707 sub cmd_launder_v0 () {
1708     badusage "no arguments to launder-v0 allowed" if @ARGV;
1709     my $old = get_head();
1710     my ($tip,$breakwater,$last_anchor) = walk $old;
1711     update_head_postlaunder $old, $tip, 'launder';
1712     printf "# breakwater tip\n%s\n", $breakwater;
1713     printf "# working tip\n%s\n", $tip;
1714     printf "# last anchor\n%s\n", $last_anchor;
1715 }
1716
1717 sub defaultcmd_rebase () {
1718     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1719     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1720     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1721 }
1722
1723 sub cmd_analyse () {
1724     badusage "analyse does not support any options"
1725         if @ARGV and $ARGV[0] =~ m/^-/;
1726     badusage "too many arguments to analyse" if @ARGV>1;
1727     my ($old) = @ARGV;
1728     if (defined $old) {
1729         $old = git_rev_parse $old;
1730     } else {
1731         $old = git_rev_parse 'HEAD';
1732     }
1733     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1734     STDOUT->error and die $!;
1735 }
1736
1737 sub ffq_prev_branchinfo () {
1738     my $current = git_get_symref();
1739     return gdr_ffq_prev_branchinfo($current);
1740 }
1741
1742 sub ffq_check ($;$$) {
1743     # calls $ff and/or $notff zero or more times
1744     # then returns either (status,message) where status is
1745     #    exists
1746     #    detached
1747     #    weird-symref
1748     #    notbranch
1749     # or (undef,undef, $ffq_prev,$gdrlast)
1750     # $ff and $notff are called like this:
1751     #   $ff->("message for stdout\n");
1752     #   $notff->('snag-name', $message);
1753     # normally $currentval should be HEAD
1754     my ($currentval, $ff, $notff) =@_;
1755
1756     $ff //= sub { print $_[0] or die $!; };
1757     $notff //= \&snag;
1758
1759     my ($status, $message, $current, $ffq_prev, $gdrlast)
1760         = ffq_prev_branchinfo();
1761     return ($status, $message) unless $status eq 'branch';
1762
1763     my $exists = git_get_ref $ffq_prev;
1764     return ('exists',"$ffq_prev already exists") if $exists;
1765
1766     return ('not-branch', 'HEAD symref is not to refs/heads/')
1767         unless $current =~ m{^refs/heads/};
1768     my $branch = $';
1769
1770     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1771     my %checked;
1772
1773     printdebug "ffq check_specs @check_specs\n";
1774
1775     my $check = sub {
1776         my ($lrref, $desc) = @_;
1777         printdebug "ffq might check $lrref ($desc)\n";
1778         my $invert;
1779         for my $chk (@check_specs) {
1780             my $glob = $chk;
1781             $invert = $glob =~ s{^[!^]}{};
1782             last if fnmatch $glob, $lrref;
1783         }
1784         return if $invert;
1785         my $lrval = git_get_ref $lrref;
1786         return unless length $lrval;
1787
1788         if (is_fast_fwd $lrval, $currentval) {
1789             $ff->("OK, you are ahead of $lrref\n");
1790             $checked{$lrref} = 1;
1791         } elsif (is_fast_fwd $currentval, $lrval) {
1792             $checked{$lrref} = -1;
1793             $notff->('behind', "you are behind $lrref, divergence risk");
1794         } else {
1795             $checked{$lrref} = -1;
1796             $notff->('diverged', "you have diverged from $lrref");
1797         }
1798     };
1799
1800     my $merge = cfg "branch.$branch.merge",1;
1801     if (defined $merge and $merge =~ m{^refs/heads/}) {
1802         my $rhs = $';
1803         printdebug "ffq merge $rhs\n";
1804         my $check_remote = sub {
1805             my ($remote, $desc) = @_;
1806             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1807             return unless defined $remote;
1808             $check->("refs/remotes/$remote/$rhs", $desc);
1809         };
1810         $check_remote->((scalar cfg "branch.$branch.remote",1),
1811                         'remote fetch/merge branch');
1812         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1813                         (scalar cfg "branch.$branch.pushDefault",1),
1814                         'remote push branch');
1815     }
1816     if ($branch =~ m{^dgit/}) {
1817         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1818     } elsif ($branch =~ m{^master$}) {
1819         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1820     }
1821     return (undef, undef, $ffq_prev, $gdrlast);
1822 }
1823
1824 sub record_ffq_prev_deferred () {
1825     # => ('status', "message")
1826     # 'status' may be
1827     #    deferred          message is undef
1828     #    exists
1829     #    detached
1830     #    weird-symref
1831     #    notbranch
1832     # if not ff from some branch we should be ff from, is an snag
1833     # if "deferred", will have added something about that to
1834     #   @deferred_update_messages, and also maybe printed (already)
1835     #   some messages about ff checks
1836     bail_if_rebasing();
1837     my $currentval = get_head();
1838
1839     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1840     return ($status,$message) if defined $status;
1841
1842     snags_maybe_bail();
1843
1844     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1845     push @deferred_updates, "delete $gdrlast";
1846     push @deferred_update_messages, "Recorded previous head for preservation";
1847     return ('deferred', undef);
1848 }
1849
1850 sub record_ffq_auto () {
1851     my ($status, $message) = record_ffq_prev_deferred();
1852     if ($status eq 'deferred' || $status eq 'exists') {
1853     } else {
1854         snag $status, "could not record ffq-prev: $message";
1855         snags_maybe_bail();
1856     }
1857 }
1858
1859 sub ffq_prev_info () {
1860     bail_if_rebasing();
1861     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1862     my ($status, $message, $current, $ffq_prev, $gdrlast)
1863         = ffq_prev_branchinfo();
1864     if ($status ne 'branch') {
1865         snag $status, "could not check ffq-prev: $message";
1866         snags_maybe_bail();
1867     }
1868     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1869     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1870 }
1871
1872 sub stitch ($$$$$) {
1873     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1874
1875     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1876
1877     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1878         my $differs = get_differs $old_head, $ffq_prev_commitish;
1879         unless ($differs & ~D_PAT_ADD) {
1880             # ffq-prev is ahead of us, and the only tree changes it has
1881             # are possibly addition of things in debian/patches/.
1882             # Just wind forwards rather than making a pointless pseudomerge.
1883             push @deferred_updates,
1884                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1885             update_head_checkout $old_head, $ffq_prev_commitish,
1886                 "stitch (fast forward)";
1887             return;
1888         }
1889     }
1890     fresh_workarea();
1891     # We make pseudomerges with L as the contributing parent.
1892     # This makes git rev-list --first-parent work properly.
1893     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1894         'Declare fast forward / record previous work',
1895         "[git-debrebase pseudomerge: $prose]",
1896     ];
1897     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1898     update_head $old_head, $new_head, "stitch: $prose";
1899 }
1900
1901 sub do_stitch ($;$) {
1902     my ($prose, $unclean) = @_;
1903
1904     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1905     if (!$ffq_prev_commitish) {
1906         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1907         return;
1908     }
1909     my $dangling_head = get_head();
1910
1911     keycommits $dangling_head, $unclean,$unclean,$unclean;
1912     snags_maybe_bail();
1913
1914     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1915 }
1916
1917 sub upstream_commitish_search ($$) {
1918     my ($upstream_version, $tried) = @_;
1919     # todo: at some point maybe use git-deborig to do this
1920     foreach my $tagpfx ('', 'v', 'upstream/') {
1921         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1922         my $new_upstream = git_get_ref "refs/tags/$tag";
1923         push @$tried, $tag;
1924         return $new_upstream if length $new_upstream;
1925     }
1926 }
1927
1928 sub resolve_upstream_version ($$) {
1929     my ($new_upstream, $upstream_version) = @_;
1930
1931     if (!defined $new_upstream) {
1932         my @tried;
1933         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1934         if (!length $new_upstream) {
1935             fail "Could not determine appropriate upstream commitish.\n".
1936                 " (Tried these tags: @tried)\n".
1937                 " Check version, and specify upstream commitish explicitly.";
1938         }
1939     }
1940     $new_upstream = git_rev_parse $new_upstream;
1941
1942     return $new_upstream;
1943 }
1944
1945 sub cmd_new_upstream () {
1946     # automatically and unconditionally launders before rebasing
1947     # if rebase --abort is used, laundering has still been done
1948
1949     my %pieces;
1950
1951     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1952
1953     # parse args - low commitment
1954     my $spec_version = shift @ARGV;
1955     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1956     fail "bad version number \`$spec_version'" unless defined $new_version;
1957     if ($new_version->is_native()) {
1958         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1959     }
1960
1961     my $new_upstream = shift @ARGV;
1962     my $new_upstream_version = upstreamversion  $new_version;
1963     $new_upstream =
1964         resolve_upstream_version $new_upstream, $new_upstream_version;
1965
1966     record_ffq_auto();
1967
1968     my $piece = sub {
1969         my ($n, @x) = @_; # may be ''
1970         my $pc = $pieces{$n} //= {
1971             Name => $n,
1972             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1973         };
1974         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1975         $pc;
1976     };
1977
1978     my @newpieces;
1979     my $newpiece = sub {
1980         my ($n, @x) = @_; # may be ''
1981         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1982         push @newpieces, $pc;
1983     };
1984
1985     $newpiece->('',
1986         OldIx => 0,
1987         New => $new_upstream,
1988     );
1989     while (@ARGV && $ARGV[0] !~ m{^-}) {
1990         my $n = shift @ARGV;
1991
1992         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1993             unless @ARGV && $ARGV[0] !~ m{^-};
1994
1995         my $c = git_rev_parse shift @ARGV;
1996         die unless $n =~ m/^$extra_orig_namepart_re$/;
1997         $newpiece->($n, New => $c);
1998     }
1999
2000     # now we need to investigate the branch this generates the
2001     # laundered version but we don't switch to it yet
2002     my $old_head = get_head();
2003     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
2004
2005     my $old_bw_cl = classify $old_bw;
2006     my $old_anchor_cl = classify $old_anchor;
2007     my $old_upstream;
2008     if (!$old_anchor_cl->{OrigParents}) {
2009         snag 'anchor-treated',
2010             'old anchor is recognised due to --anchor, cannot check upstream';
2011     } else {
2012         $old_upstream = parsecommit
2013             $old_anchor_cl->{OrigParents}[0]{CommitId};
2014         $piece->('', Old => $old_upstream->{CommitId});
2015     }
2016
2017     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
2018         if ($old_upstream->{Msg} =~
2019  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
2020            ) {
2021             my @oldpieces = (split / /, $1);
2022             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
2023             if ($old_n_parents != @oldpieces &&
2024                 $old_n_parents != @oldpieces + 1) {
2025                 snag 'upstream-confusing', sprintf
2026                     "previous upstream combine %s".
2027                     " mentions %d pieces (each implying one parent)".
2028                     " but has %d parents".
2029                     " (one per piece plus maybe a previous combine)",
2030                     $old_upstream->{CommitId},
2031                     (scalar @oldpieces),
2032                     $old_n_parents;
2033             } elsif ($oldpieces[0] ne '.') {
2034                 snag 'upstream-confusing', sprintf
2035                     "previous upstream combine %s".
2036                     " first piece is not \`.'",
2037                     $oldpieces[0];
2038             } else {
2039                 $oldpieces[0] = '';
2040                 foreach my $i (0..$#oldpieces) {
2041                     my $n = $oldpieces[$i];
2042                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
2043                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
2044                 }
2045             }
2046         } else {
2047             snag 'upstream-confusing',
2048                 "previous upstream $old_upstream->{CommitId} is from".
2049                " git-debrebase but not an \`upstream-combine' commit";
2050         }
2051     }
2052
2053     foreach my $pc (values %pieces) {
2054         if (!$old_upstream) {
2055             # we have complained already
2056         } elsif (!$pc->{Old}) {
2057             snag 'upstream-new-piece',
2058                 "introducing upstream piece \`$pc->{Name}'";
2059         } elsif (!$pc->{New}) {
2060             snag 'upstream-rm-piece',
2061                 "dropping upstream piece \`$pc->{Name}'";
2062         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
2063             snag 'upstream-not-ff',
2064                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
2065         }
2066     }
2067
2068     printdebug "%pieces = ", (dd \%pieces), "\n";
2069     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
2070
2071     snags_maybe_bail();
2072
2073     my $new_bw;
2074
2075     fresh_workarea();
2076     in_workarea sub {
2077         my @upstream_merge_parents;
2078
2079         if (!any_snags()) {
2080             push @upstream_merge_parents, $old_upstream->{CommitId};
2081         }
2082
2083         foreach my $pc (@newpieces) { # always has '' first
2084             if ($pc->{Name}) {
2085                 read_tree_subdir $pc->{Name}, $pc->{New};
2086             } else {
2087                 runcmd @git, qw(read-tree), $pc->{New};
2088             }
2089             push @upstream_merge_parents, $pc->{New};
2090         }
2091
2092         # index now contains the new upstream
2093
2094         if (@newpieces > 1) {
2095             # need to make the upstream subtree merge commit
2096             $new_upstream = make_commit \@upstream_merge_parents,
2097                 [ "Combine upstreams for $new_upstream_version",
2098  ("[git-debrebase upstream-combine . ".
2099  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
2100  ": new upstream]"),
2101                 ];
2102         }
2103
2104         # $new_upstream is either the single upstream commit, or the
2105         # combined commit we just made.  Either way it will be the
2106         # "upstream" parent of the anchor merge.
2107
2108         read_tree_subdir 'debian', "$old_bw:debian";
2109
2110         # index now contains the anchor merge contents
2111         $new_bw = make_commit [ $old_bw, $new_upstream ],
2112             [ "Update to upstream $new_upstream_version",
2113  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2114             ];
2115
2116         my $clogsignoff = cmdoutput qw(git show),
2117             '--pretty=format:%an <%ae>  %aD',
2118             $new_bw;
2119
2120         # Now we have to add a changelog stanza so the Debian version
2121         # is right.
2122         die if unlink "debian";
2123         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2124         unlink "debian/changelog" or $!==ENOENT or die $!;
2125         mkdir "debian" or die $!;
2126         open CN, ">", "debian/changelog" or die $!;
2127         my $oldclog = git_cat_file ":debian/changelog";
2128         $oldclog =~ m/^($package_re) \(\S+\) / or
2129             fail "cannot parse old changelog to get package name";
2130         my $p = $1;
2131         print CN <<END, $oldclog or die $!;
2132 $p ($new_version) UNRELEASED; urgency=medium
2133
2134   * Update to new upstream version $new_upstream_version.
2135
2136  -- $clogsignoff
2137
2138 END
2139         close CN or die $!;
2140         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2141
2142         # Now we have the final new breakwater branch in the index
2143         $new_bw = make_commit [ $new_bw ],
2144             [ "Update changelog for new upstream $new_upstream_version",
2145               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2146             ];
2147     };
2148
2149     # we have constructed the new breakwater. we now need to commit to
2150     # the laundering output, because git-rebase can't easily be made
2151     # to make a replay list which is based on some other branch
2152
2153     update_head_postlaunder $old_head, $old_laundered_tip,
2154         'launder for new upstream';
2155
2156     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2157     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2158         "debrebase new-upstream $new_version: rebase";
2159     runcmd @cmd;
2160     # now it's for the user to sort out
2161 }
2162
2163 sub cmd_record_ffq_prev () {
2164     badusage "no arguments allowed" if @ARGV;
2165     my ($status, $msg) = record_ffq_prev_deferred();
2166     if ($status eq 'exists' && $opt_noop_ok) {
2167         print "Previous head already recorded\n" or die $!;
2168     } elsif ($status eq 'deferred') {
2169         run_deferred_updates 'record-ffq-prev';
2170     } else {
2171         fail "Could not preserve: $msg";
2172     }
2173 }
2174
2175 sub cmd_anchor () {
2176     badusage "no arguments allowed" if @ARGV;
2177     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2178     print "$bw\n" or die $!;
2179 }
2180
2181 sub cmd_breakwater () {
2182     badusage "no arguments allowed" if @ARGV;
2183     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2184     print "$bw\n" or die $!;
2185 }
2186
2187 sub cmd_status () {
2188     badusage "no arguments allowed" if @ARGV;
2189
2190     # todo: gdr status should print divergence info
2191     # todo: gdr status should print upstream component(s) info
2192     # todo: gdr should leave/maintain some refs with this kind of info ?
2193
2194     my $oldest = { Badness => 0 };
2195     my $newest;
2196     my $note = sub {
2197         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2198         if ($oldest->{Badness} < $badness) {
2199             $oldest = $newest = undef;
2200         }
2201         $oldest = {
2202                    Badness => $badness,
2203                    CommitId => $cl->{CommitId},
2204                    OurMsg => $ourmsg,
2205                    KcMsg => $kcmsg,
2206                   };
2207         $newest //= $oldest;
2208     };
2209     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2210         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2211         sub { $note->(2, 'branch is unlaundered', @_); },
2212         sub { $note->(3, 'branch needs laundering', @_); },
2213         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2214
2215     my $prcommitinfo = sub {
2216         my ($cid) = @_;
2217         flush STDOUT or die $!;
2218         runcmd @git, qw(--no-pager log -n1),
2219             '--pretty=format:    %h %s%n',
2220             $cid;
2221     };
2222
2223     print "current branch contents, in git-debrebase terms:\n";
2224     if (!$oldest->{Badness}) {
2225         print "  branch is laundered\n";
2226     } else {
2227         print "  $oldest->{OurMsg}\n";
2228         my $printed = '';
2229         foreach my $info ($oldest, $newest) {
2230             my $cid = $info->{CommitId};
2231             next if $cid eq $printed;
2232             $printed = $cid;
2233             print "  $info->{KcMsg}\n";
2234             $prcommitinfo->($cid);
2235         }
2236     }
2237
2238     my $prab = sub {
2239         my ($cid, $what) = @_;
2240         if (!defined $cid) {
2241             print "  $what is not well-defined\n";
2242         } else {
2243             print "  $what\n";
2244             $prcommitinfo->($cid);
2245         }
2246     };
2247     print "key git-debrebase commits:\n";
2248     $prab->($anchor, 'anchor');
2249     $prab->($bw, 'breakwater');
2250
2251     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2252         ffq_prev_branchinfo();
2253
2254     print "branch and ref status, in git-debrebase terms:\n";
2255     if ($ffq_msg) {
2256         print "  $ffq_msg\n";
2257     } else {
2258         $ffq_prev = git_get_ref $ffq_prev;
2259         $gdrlast = git_get_ref $gdrlast;
2260         if ($ffq_prev) {
2261             print "  unstitched; previous tip was:\n";
2262             $prcommitinfo->($ffq_prev);
2263         } elsif (!$gdrlast) {
2264             print "  stitched? (no record of git-debrebase work)\n";
2265         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2266             print "  stitched\n";
2267         } else {
2268             print "  not git-debrebase (diverged since last stitch)\n"
2269         }
2270     }
2271     print "you are currently rebasing\n" if currently_rebasing();
2272 }
2273
2274 sub cmd_stitch () {
2275     my $prose = 'stitch';
2276     getoptions("stitch",
2277                'prose=s', \$prose);
2278     badusage "no arguments allowed" if @ARGV;
2279     do_stitch $prose, 0;
2280 }
2281 sub cmd_prepush () {
2282     $opt_noop_ok = 1;
2283     cmd_stitch();
2284 }
2285
2286 sub cmd_quick () {
2287     badusage "no arguments allowed" if @ARGV;
2288     do_launder_head 'launder for git-debrebase quick';
2289     do_stitch 'quick';
2290 }
2291
2292 sub cmd_conclude () {
2293     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2294     if (!$ffq_prev_commitish) {
2295         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2296         return;
2297     }
2298     my $dangling_head = get_head();
2299
2300     badusage "no arguments allowed" if @ARGV;
2301     do_launder_head 'launder for git-debrebase quick';
2302     do_stitch 'quick';
2303 }
2304
2305 sub cmd_scrap () {
2306     if (currently_rebasing()) {
2307         runcmd @git, qw(rebase --abort);
2308         push @deferred_updates, 'verify HEAD HEAD';
2309         # noop, but stops us complaining that scrap was a noop
2310     }
2311     badusage "no arguments allowed" if @ARGV;
2312     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2313     my $scrapping_head;
2314     if ($ffq_prev_commitish) {
2315         $scrapping_head = get_head();
2316         push @deferred_updates,
2317             "update $gdrlast $ffq_prev_commitish $git_null_obj",
2318             "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2319     }
2320     if (git_get_ref $merge_cache_ref) {
2321         push @deferred_updates,
2322             "delete $merge_cache_ref";
2323     }
2324     if (!@deferred_updates) {
2325         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2326         finish 0;
2327     }
2328     snags_maybe_bail();
2329     if ($scrapping_head) {
2330         update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2331     } else {
2332         run_deferred_updates "scrap";
2333     }
2334 }
2335
2336 sub make_patches_staged ($) {
2337     my ($head) = @_;
2338     # Produces the patches that would result from $head if it were
2339     # laundered.
2340     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2341     fresh_workarea();
2342     in_workarea sub {
2343         gbp_pq_export 'bw', $secret_bw, $secret_head;
2344     };
2345 }
2346
2347 sub make_patches ($) {
2348     my ($head) = @_;
2349     keycommits $head, 0, \&snag;
2350     make_patches_staged $head;
2351     my $out;
2352     in_workarea sub {
2353         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2354         runcmd @git, qw(read-tree), $head;
2355         read_tree_subdir 'debian/patches', $ptree;
2356         $out = make_commit [$head], [
2357             'Commit patch queue (exported by git-debrebase)',
2358             '[git-debrebase: export and commit patches]',
2359         ];
2360     };
2361     return $out;
2362 }
2363
2364 sub cmd_make_patches () {
2365     my $opt_quiet_would_amend;
2366     getoptions("make-patches",
2367                'quiet-would-amend!', \$opt_quiet_would_amend);
2368     badusage "no arguments allowed" if @ARGV;
2369     bail_if_rebasing();
2370     my $old_head = get_head();
2371     my $new = make_patches $old_head;
2372     my $d = get_differs $old_head, $new;
2373     if ($d == 0) {
2374         fail "No (more) patches to export." unless $opt_noop_ok;
2375         return;
2376     } elsif ($d == D_PAT_ADD) {
2377         snags_maybe_bail();
2378         update_head_checkout $old_head, $new, 'make-patches';
2379     } else {
2380         print STDERR failmsg
2381             "Patch export produced patch amendments".
2382             " (abandoned output commit $new).".
2383             "  Try laundering first."
2384             unless $opt_quiet_would_amend;
2385         finish 7;
2386     }
2387 }
2388
2389 sub check_series_has_all_patches ($) {
2390     my ($head) = @_;
2391     my $seriesfn = 'debian/patches/series';
2392     my ($dummy, $series) = git_cat_file "$head:$seriesfn",
2393         [qw(blob missing)];
2394     $series //= '';
2395     my %series;
2396     foreach my $f (grep /\S/, grep {!m/^\s\#/} split /\n/, $series) {
2397         fail "patch $f repeated in $seriesfn !" if $series{$f}++;
2398     }
2399     foreach my $patchfile (get_tree "$head:debian/patches", 1,1) {
2400         my ($f,$i) = @$patchfile;
2401         next if $series{$f};
2402         next if $f eq 'series';
2403         snag 'unused-patches', "Unused patch file $f will be discarded";
2404     }
2405 }
2406
2407 sub cmd_convert_from_gbp () {
2408     badusage "want only 1 optional argument, the upstream git commitish"
2409         unless @ARGV<=1;
2410
2411     my $clogp = parsechangelog();
2412     my $version = $clogp->{'Version'}
2413         // die "missing Version from changelog";
2414
2415     my ($upstream_spec) = @ARGV;
2416
2417     my $upstream_version = upstreamversion $version;
2418     my $upstream =
2419         resolve_upstream_version($upstream_spec, $upstream_version);
2420
2421     my $old_head = get_head();
2422
2423     my $upsdiff = get_differs $upstream, $old_head;
2424     if ($upsdiff & D_UPS) {
2425         runcmd @git, qw(--no-pager diff --stat),
2426             $upstream, $old_head,
2427             qw( -- :!/debian :/);
2428         fail <<END;
2429 upstream ($upstream_spec) and HEAD are not
2430 identical in upstream files.  See diffstat above, or run
2431   git diff $upstream_spec HEAD -- :!/debian :/
2432 END
2433     }
2434
2435     if (!is_fast_fwd $upstream, $old_head) {
2436         snag 'upstream-not-ancestor',
2437             "upstream ($upstream) is not an ancestor of HEAD";
2438     } else {
2439         my $wrong = cmdoutput
2440             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2441              qw(-- :/ :!/debian));
2442         if (length $wrong) {
2443             snag 'unexpected-upstream-changes',
2444                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2445             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2446         }
2447     }
2448
2449     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2450         snag 'upstream-has-debian',
2451             "upstream ($upstream) contains debian/ directory";
2452     }
2453
2454     check_series_has_all_patches $old_head;
2455
2456     my $previous_dgit_view = eval {
2457         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2458         my ($lvsn, $suite);
2459         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2460             my ($stz, $desc) = @_;
2461             no warnings qw(exiting);
2462             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2463             next unless $stz->{Date};
2464             next unless $stz->{Distribution} ne 'UNRELEASED';
2465             $lvsn = $stz->{Version};
2466             $suite = $stz->{Distribution};
2467             last;
2468         };
2469         die "neither of the first two changelog entries are released\n"
2470             unless defined $lvsn;
2471         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2472         my $mtag_pat = debiantag_maintview $lvsn, '*';
2473         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2474             $mtag_pat;
2475         die "could not find suitable maintainer view tag $mtag_pat\n"
2476             unless $mtag =~ m{/};
2477         is_fast_fwd $mtag, 'HEAD' or
2478             die "HEAD is not FF from maintainer tag $mtag!";
2479         my $dtag = "archive/$mtag";
2480         git_get_ref "refs/tags/$dtag" or
2481             die "dgit view tag $dtag not found\n";
2482         is_fast_fwd $mtag, $dtag or
2483             die "dgit view tag $dtag is not FF from maintainer tag $mtag\n";
2484         print "will stitch in dgit view, $dtag\n";
2485         git_rev_parse $dtag;
2486     };
2487     if (!$previous_dgit_view) {
2488         $@ =~ s/^\n+//;
2489         chomp $@;
2490         print STDERR <<END;
2491 Cannot confirm dgit view: $@
2492 Failed to stitch in dgit view (see messages above).
2493 dgit --overwrite will be needed on the first dgit push after conversion.
2494 END
2495     }
2496
2497     snags_maybe_bail_early();
2498
2499     my $work;
2500
2501     fresh_workarea();
2502     in_workarea sub {
2503         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2504         # make a branch out of the patch queue - we'll want this in a mo
2505         runcmd qw(gbp pq import);
2506         # strip the patches out
2507         runcmd @git, qw(checkout -q gdr-internal~0);
2508         rm_subdir_cached 'debian/patches';
2509         $work = make_commit ['HEAD'], [
2510  'git-debrebase convert-from-gbp: drop patches from tree',
2511  'Delete debian/patches, as part of converting to git-debrebase format.',
2512  '[git-debrebase convert-from-gbp: drop patches from tree]'
2513                               ];
2514         # make the anchor merge
2515         # the tree is already exactly right
2516         $work = make_commit [$work, $upstream], [
2517  'git-debrebase import: declare upstream',
2518  'First breakwater merge.',
2519  '[git-debrebase anchor: declare upstream]'
2520                               ];
2521
2522         # rebase the patch queue onto the new breakwater
2523         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2524         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2525         $work = git_rev_parse 'HEAD';
2526
2527         if ($previous_dgit_view) {
2528             $work = make_commit [$work, $previous_dgit_view], [
2529  'git-debrebase import: declare ff from dgit archive view',
2530  '[git-debrebase pseudomerge: import-from-gbp]',
2531             ];
2532         }
2533     };
2534
2535     ffq_check $work;
2536     snags_maybe_bail();
2537     update_head_checkout $old_head, $work, 'convert-from-gbp';
2538     print <<END or die $!;
2539 git-debrebase: converted from patched-unapplied (gbp) branch format, OK
2540 END
2541 }
2542
2543 sub cmd_convert_to_gbp () {
2544     badusage "no arguments allowed" if @ARGV;
2545     my $head = get_head();
2546     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2547     keycommits $head, 0;
2548     my $out;
2549     make_patches_staged $head;
2550     in_workarea sub {
2551         $out = make_commit ['HEAD'], [
2552             'Commit patch queue (converted from git-debrebase format)',
2553             '[git-debrebase convert-to-gbp: commit patches]',
2554         ];
2555     };
2556     if (defined $ffq) {
2557         push @deferred_updates, "delete $ffq";
2558         push @deferred_updates, "delete $gdrlast";
2559     }
2560     snags_maybe_bail();
2561     update_head_checkout $head, $out, "convert to gbp (v0)";
2562     print <<END or die $!;
2563 git-debrebase: converted to git-buildpackage branch format
2564 git-debrebase: WARNING: do not now run "git-debrebase" any more
2565 git-debrebase: WARNING: doing so would drop all upstream patches!
2566 END
2567 }
2568
2569 sub cmd_convert_from_dgit_view () {
2570     my $clogp = parsechangelog();
2571
2572     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2573     my $do_origs = 1;
2574     my $do_tags = 1;
2575     my $always = 0;
2576     my $diagnose = 0;
2577
2578     getoptions("convert-from-dgit-view",
2579                'diagnose!', \$diagnose,
2580                'build-products-dir:s', \$bpd,
2581                'origs!', \$do_origs,
2582                'tags!', \$do_tags,
2583                'always-convert-anyway!', \$always);
2584     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2585
2586     my @upstreams;
2587
2588     if (@ARGV) {
2589         my $spec = shift @ARGV;
2590         my $commit = git_rev_parse "$spec^{commit}";
2591         push @upstreams, { Commit => $commit,
2592                            Source => "$ARGV[0], from command line",
2593                            Only => 1,
2594                          };
2595     }
2596
2597     my $head = get_head();
2598
2599     if (!$always) {
2600         my $troubles = 0;
2601         my $trouble = sub { $troubles++; };
2602         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2603         printdebug "troubles=$troubles\n";
2604         if (!$troubles) {
2605             print STDERR <<END;
2606 $us: Branch already seems to be in git-debrebase format!
2607 $us: --always-convert-anyway would do the conversion operation anyway
2608 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2609 END
2610             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2611             finish 0;
2612         }
2613     }
2614
2615     check_series_has_all_patches $head;
2616
2617     snags_maybe_bail_early();
2618
2619     my $version = upstreamversion $clogp->{Version};
2620     print STDERR "Considering possible commits corresponding to upstream:\n";
2621
2622     if (!@upstreams) {
2623         if ($do_tags) {
2624             my @tried;
2625             my $ups_tag = upstream_commitish_search $version, \@tried;
2626             if ($ups_tag) {
2627                 my $this = "git tag $tried[-1]";
2628                 push @upstreams, { Commit => $ups_tag,
2629                                    Source => $this,
2630                                  };
2631             } else {
2632                 printf STDERR
2633                     " git tag: no suitable tag found (tried %s)\n",
2634                     "@tried";
2635             }
2636         }
2637         if ($do_origs) {
2638             my $p = $clogp->{'Source'};
2639             # we do a quick check to see if there are plausible origs
2640             my $something=0;
2641             if (!opendir BPD, $bpd) {
2642                 die "$bpd: opendir: $!" unless $!==ENOENT;
2643             } else {
2644                 while ($!=0, my $f = readdir BPD) {
2645                     next unless is_orig_file_of_p_v $f, $p, $version;
2646                     printf STDERR
2647                         " orig: found what looks like a .orig, %s\n",
2648                         "$bpd/$f";
2649                     $something=1;
2650                     last;
2651                 }
2652                 die "read $bpd: $!" if $!;
2653                 closedir BPD;
2654             }
2655             if ($something) {
2656                 my $tree = cmdoutput
2657                     @dgit, qw(--build-products-dir), $bpd,
2658                     qw(print-unapplied-treeish);
2659                 fresh_workarea();
2660                 in_workarea sub {
2661                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2662                     rm_subdir_cached 'debian';
2663                     $tree = cmdoutput @git, qw(write-tree);
2664                     my $ups_synth = make_commit [], [ <<END, <<END,
2665 Import effective orig tree for upstream version $version
2666 END
2667 This includes the contents of the .orig(s), minus any debian/ directory.
2668
2669 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2670 END
2671                                                     ];
2672                     push @upstreams, { Commit => $ups_synth,
2673                                        Source => "orig(s) imported via dgit",
2674                                      };
2675                 }
2676             } else {
2677                 printf STDERR
2678                     " orig: no suitable origs found (looked for %s in %s)\n",
2679                     "${p}_".(stripeoch $version)."...", $bpd;
2680             }
2681         }
2682     }
2683
2684     my $some_patches = stat_exists 'debian/patches/series';
2685
2686     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2687
2688     my $result;
2689     foreach my $u (@upstreams) {
2690         my $work = $head;
2691         fresh_workarea();
2692         in_workarea sub {
2693             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2694             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2695             runcmd @git, qw(clean -xdff);
2696             runcmd @git, qw(checkout), $head, qw(-- debian);
2697             if ($some_patches) {
2698                 rm_subdir_cached 'debian/patches';
2699                 $work = make_commit [ $work ], [
2700  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2701  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2702  "to git-debrebase format.  Upstream changes will appear as commits.",
2703  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2704                                            ];
2705             }
2706             $work = make_commit [ $work, $u->{Commit} ], [
2707  'git-debrebase convert-from-dgit-view: declare upstream',
2708  '(Re)constructed breakwater merge.',
2709  '[git-debrebase anchor: declare upstream]'
2710                                                          ];
2711             runcmd @git, qw(checkout --quiet -b mk), $work;
2712             if ($some_patches) {
2713                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2714                 runcmd @git, qw(reset --quiet);
2715                 my @gbp_cmd = (qw(gbp pq import));
2716                 if (!$diagnose) {
2717                     my $gbp_err = "../gbp-pq-err";
2718                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2719                 }
2720                 my $r = system @gbp_cmd;
2721                 if ($r) {
2722                     printf STDERR
2723                         " %s: couldn't apply patches: gbp pq %s",
2724                         $u->{Source}, waitstatusmsg();
2725                     return;
2726                 }
2727             }
2728             my $work = git_rev_parse qw(HEAD);
2729             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2730             if (length $diffout) {
2731                 print STDERR
2732                     " $u->{Source}: applying patches gives different tree\n";
2733                 print STDERR $diffout if $diagnose;
2734                 return;
2735             }
2736             # OMG!
2737             $u->{Result} = $work;
2738             $result = $u;
2739         };
2740         last if $result;
2741     }
2742
2743     if (!$result) {
2744         fail <<END;
2745 Could not find or construct a suitable upstream commit.
2746 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2747 upstream commmit explicitly or provide suitable origs.
2748 END
2749     }
2750
2751     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2752
2753     ffq_check $result->{Result};
2754     snags_maybe_bail();
2755     update_head_checkout $head, $result->{Result},
2756         'convert-from-dgit-view';
2757 }
2758
2759 sub cmd_record_resolved_merge () {
2760     badusage "record-resolved-merge takes no further arguments" if @ARGV;
2761     # xxx needs documentation
2762     my $new = get_head();
2763     my $method;
2764
2765     print "Checking how you have resolved the merge problem\n";
2766     my $nope = sub { print "Not $method: @_"; 0; };
2767
2768     my $maybe = sub { print "Seems to be $method.\n"; };
2769     my $yes = sub {
2770         my ($key, $ref) = @_;
2771         reflog_cache_insert $merge_cache_ref, $key, $ref;
2772         print "OK.  You can switch branches and try git-debrebase again.\n";
2773         1;
2774     };
2775
2776     fresh_workarea 'merge';
2777     sub {
2778         $method = 'vanilla-merge patchqueue';
2779         my $vanilla = git_get_ref "$wrecknoteprefix/vanilla-merge";
2780         $vanilla or return $nope->("wreckage was not of vanilla-merge");
2781         foreach my $lr (qw(left right)) {
2782             my $n = "$wrecknoteprefix/$lr-patchqueue";
2783             my $lrpq = git_get_ref $n;
2784             $lrpq or return $nope->("wreckage did not contain patchqueues");
2785             is_fast_fwd $lrpq, $new or return $nope->("HEAD not ff of $n");
2786         }
2787         $maybe->();
2788         my $newbase = git_get_ref "$wrecknoteprefix/new-base"
2789             or die "wreckage element $wrecknoteprefix/new-base missing";
2790         my $result = merge_series_patchqueue_convert
2791             {}, $newbase, $new;
2792         $yes->("vanilla-merge $vanilla", $result);
2793         1;
2794     }->() or sub {
2795         fail "No resolved merge method seems applicable.\n";
2796     }->();
2797 }
2798
2799 sub cmd_downstream_rebase_launder_v0 () {
2800     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2801     my ($base) = @ARGV;
2802     $base = git_rev_parse $base;
2803     my $old_head = get_head();
2804     my $current = $old_head;
2805     my $topmost_keep;
2806     for (;;) {
2807         if ($current eq $base) {
2808             $topmost_keep //= $current;
2809             print " $current BASE stop\n";
2810             last;
2811         }
2812         my $cl = classify $current;
2813         print " $current $cl->{Type}";
2814         my $keep = 0;
2815         my $p0 = $cl->{Parents}[0]{CommitId};
2816         my $next;
2817         if ($cl->{Type} eq 'Pseudomerge') {
2818             print " ^".($cl->{Contributor}{Ix}+1);
2819             $next = $cl->{Contributor}{CommitId};
2820         } elsif ($cl->{Type} eq 'AddPatches' or
2821                  $cl->{Type} eq 'Changelog') {
2822             print " strip";
2823             $next = $p0;
2824         } else {
2825             print " keep";
2826             $next = $p0;
2827             $keep = 1;
2828         }
2829         print "\n";
2830         if ($keep) {
2831             $topmost_keep //= $current;
2832         } else {
2833             die "to-be stripped changes not on top of the branch\n"
2834                 if $topmost_keep;
2835         }
2836         $current = $next;
2837     }
2838     if ($topmost_keep eq $old_head) {
2839         print "unchanged\n";
2840     } else {
2841         print "updating to $topmost_keep\n";
2842         update_head_checkout
2843             $old_head, $topmost_keep,
2844             'downstream-rebase-launder-v0';
2845     }
2846 }
2847
2848 getoptions_main
2849           ("bad options\n",
2850            "D+" => \$debuglevel,
2851            'noop-ok', => \$opt_noop_ok,
2852            'f=s' => \@snag_force_opts,
2853            'anchor=s' => \@opt_anchors,
2854            '--dgit=s' => \($dgit[0]),
2855            'force!',
2856            '-i:s' => sub {
2857                my ($opt,$val) = @_;
2858                badusage "git-debrebase: no cuddling to -i for git-rebase"
2859                    if length $val;
2860                die if $opt_defaultcmd_interactive; # should not happen
2861                $opt_defaultcmd_interactive = [ qw(-i) ];
2862                # This access to @ARGV is excessive familiarity with
2863                # Getopt::Long, but there isn't another sensible
2864                # approach.  '-i=s{0,}' does not work with bundling.
2865                push @$opt_defaultcmd_interactive, @ARGV;
2866                @ARGV=();
2867            },
2868            'help' => sub { print $usage_message or die $!; finish 0; },
2869            );
2870
2871 initdebug('git-debrebase ');
2872 enabledebug if $debuglevel;
2873
2874 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2875 chdir $toplevel or die "chdir $toplevel: $!";
2876
2877 $rd = fresh_playground "$playprefix/misc";
2878
2879 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2880
2881 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2882     defaultcmd_rebase();
2883 } else {
2884     my $cmd = shift @ARGV;
2885     my $cmdfn = $cmd;
2886     $cmdfn =~ y/-/_/;
2887     $cmdfn = ${*::}{"cmd_$cmdfn"};
2888
2889     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2890     $cmdfn->();
2891 }
2892
2893 finish 0;