git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 our ($opt_force, $opt_noop_ok, @opt_anchors);
  40 our ($opt_defaultcmd_interactive);
  41
  42 our $us = qw(git-debrebase);
  43
  44 sub badusage ($) {
  45     my ($m) = @_;
  46     print STDERR "bad usage: $m\n";
  47     finish 8;
  48 }
  49
  50 sub cfg ($;$) {
  51     my ($k, $optional) = @_;
  52     local $/ = "\0";
  53     my @cmd = qw(git config -z);
  54     push @cmd, qw(--get-all) if wantarray;
  55     push @cmd, $k;
  56     my $out = cmdoutput_errok @cmd;
  57     if (!defined $out) {
  58         fail "missing required git config $k" unless $optional;
  59         return ();
  60     }
  61     my @l = split /\0/, $out;
  62     return wantarray ? @l : $l[0];
  63 }
  64
  65 memoize('cfg');
  66
  67 sub dd ($) {
  68     my ($v) = @_;
  69     my $dd = new Data::Dumper [ $v ];
  70     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  71     return Dump $dd;
  72 }
  73
  74 sub get_commit ($) {
  75     my ($objid) = @_;
  76     my $data = (git_cat_file $objid, 'commit');
  77     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
  78     return ($`,$');
  79 }
  80
  81 sub D_UPS ()      { 0x02; } # upstream files
  82 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
  83 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
  84 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
  85 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
  86 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
  87
  88 our $playprefix = 'debrebase';
  89 our $rd;
  90 our $workarea;
  91
  92 our @git = qw(git);
  93
  94 sub in_workarea ($) {
  95     my ($sub) = @_;
  96     changedir $workarea;
  97     my $r = eval { $sub->(); };
  98     { local $@; changedir $maindir; }
  99     die $@ if $@;
 100 }
 101
 102 sub fresh_workarea () {
 103     $workarea = fresh_playground "$playprefix/work";
 104     in_workarea sub { playtree_setup };
 105 }
 106
 107 our $snags_forced = 0;
 108 our $snags_tripped = 0;
 109 our $snags_summarised = 0;
 110 our @deferred_updates;
 111 our @deferred_update_messages;
 112
 113 sub all_snags_summarised () {
 114     $snags_forced + $snags_tripped == $snags_summarised;
 115 }
 116 sub run_deferred_updates ($) {
 117     my ($mrest) = @_;
 118
 119     confess 'dangerous internal error' unless all_snags_summarised();
 120
 121     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 122     debugcmd '>|', @upd_cmd;
 123     open U, "|-", @upd_cmd or die $!;
 124     foreach (@deferred_updates) {
 125         printdebug ">= ", $_, "\n";
 126         print U $_, "\n" or die $!;
 127     }
 128     printdebug ">\$\n";
 129     close U or failedcmd @upd_cmd;
 130
 131     print $_, "\n" foreach @deferred_update_messages;
 132
 133     @deferred_updates = ();
 134     @deferred_update_messages = ();
 135 }
 136
 137 sub get_differs ($$) {
 138     my ($x,$y) = @_;
 139     # This resembles quiltify_trees_differ, in dgit, a bit.
 140     # But we don't care about modes, or dpkg-source-unrepresentable
 141     # changes, and we don't need the plethora of different modes.
 142     # Conversely we need to distinguish different kinds of changes to
 143     # debian/ and debian/patches/.
 144
 145     my $differs = 0;
 146
 147     my $rundiff = sub {
 148         my ($opts, $limits, $fn) = @_;
 149         my @cmd = (@git, qw(diff-tree -z --no-renames));
 150         push @cmd, @$opts;
 151         push @cmd, "$_:" foreach $x, $y;
 152         push @cmd, '--', @$limits;
 153         my $diffs = cmdoutput @cmd;
 154         foreach (split /\0/, $diffs) { $fn->(); }
 155     };
 156
 157     $rundiff->([qw(--name-only)], [], sub {
 158         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 159     });
 160
 161     if ($differs & DS_DEB) {
 162         $differs &= ~DS_DEB;
 163         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 164             $differs |=
 165                 m{^debian/patches/}      ? D_PAT_OTH  :
 166                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 167                                            D_DEB_OTH;
 168         });
 169         die "mysterious debian changes $x..$y"
 170             unless $differs & (D_PAT_OTH|DS_DEB);
 171     }
 172
 173     if ($differs & D_PAT_OTH) {
 174         my $mode;
 175         $differs &= ~D_PAT_OTH;
 176         my $pat_oth = sub {
 177             $differs |= D_PAT_OTH;
 178             no warnings qw(exiting);  last;
 179         };
 180         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 181             no warnings qw(exiting);
 182             if (!defined $mode) {
 183                 $mode = $_;  next;
 184             }
 185             die unless s{^debian/patches/}{};
 186             my $ok;
 187             if ($mode eq 'A' && !m/\.series$/s) {
 188                 $ok = 1;
 189             } elsif ($mode eq 'M' && $_ eq 'series') {
 190                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 191                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 192                 chomp $x_s;  $x_s .= "\n";
 193                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 194             } else {
 195                 # nope
 196             }
 197             $mode = undef;
 198             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 199         });
 200         die "mysterious debian/patches changes $x..$y"
 201             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 202     }
 203
 204     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 205
 206     return $differs;
 207 }
 208
 209 sub commit_pr_info ($) {
 210     my ($r) = @_;
 211     return Data::Dumper->dump([$r], [qw(commit)]);
 212 }
 213
 214 sub calculate_committer_authline () {
 215     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 216         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 217     my ($h,$m) = get_commit $c;
 218     $h =~ m/^committer .*$/m or confess "($h) ?";
 219     return $&;
 220 }
 221
 222 sub rm_subdir_cached ($) {
 223     my ($subdir) = @_;
 224     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 225 }
 226
 227 sub read_tree_subdir ($$) {
 228     my ($subdir, $new_tree_object) = @_;
 229     rm_subdir_cached $subdir;
 230     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 231 }
 232
 233 sub make_commit ($$) {
 234     my ($parents, $message_paras) = @_;
 235     my $tree = cmdoutput @git, qw(write-tree);
 236     my @cmd = (@git, qw(commit-tree), $tree);
 237     push @cmd, qw(-p), $_ foreach @$parents;
 238     push @cmd, qw(-m), $_ foreach @$message_paras;
 239     return cmdoutput @cmd;
 240 }
 241
 242 our @snag_force_opts;
 243 sub snag ($$;@) {
 244     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 245     if (grep { $_ eq $tag } @snag_force_opts) {
 246         $snags_forced++;
 247         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 248     } else {
 249         $snags_tripped++;
 250         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 251     }
 252 }
 253
 254 # Important: all mainline code must call snags_maybe_bail after
 255 # any point where snag might be called, but before making changes
 256 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 257 # may be called more than once if necessary (but this is not ideal
 258 # because then the messages about number of snags may be confusing).
 259 sub snags_maybe_bail () {
 260     return if all_snags_summarised();
 261     if ($snags_forced) {
 262         printf STDERR
 263             "%s: snags: %d overriden by individual -f options\n",
 264             $us, $snags_forced;
 265     }
 266     if ($snags_tripped) {
 267         if ($opt_force) {
 268             printf STDERR
 269                 "%s: snags: %d overriden by global --force\n",
 270                 $us, $snags_tripped;
 271         } else {
 272             fail sprintf
 273   "%s: snags: %d blockers (you could -f<tag>, or --force)",
 274                 $us, $snags_tripped;
 275         }
 276     }
 277     $snags_summarised = $snags_forced + $snags_tripped;
 278 }
 279 sub any_snags () {
 280     return $snags_forced || $snags_tripped;
 281 }
 282
 283 # classify returns an info hash like this
 284 #   CommitId => $objid
 285 #   Hdr => # commit headers, including 1 final newline
 286 #   Msg => # commit message (so one newline is dropped)
 287 #   Tree => $treeobjid
 288 #   Type => (see below)
 289 #   Parents = [ {
 290 #       Ix => $index # ie 0, 1, 2, ...
 291 #       CommitId
 292 #       Differs => return value from get_differs
 293 #       IsOrigin
 294 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 295 #     } ...]
 296 #   NewMsg => # commit message, but with any [dgit import ...] edited
 297 #             # to say "[was: ...]"
 298 #
 299 # Types:
 300 #   Packaging
 301 #   Changelog
 302 #   Upstream
 303 #   AddPatches
 304 #   Mixed
 305 #
 306 #   Pseudomerge
 307 #     has additional entres in classification result
 308 #       Overwritten = [ subset of Parents ]
 309 #       Contributor = $the_remaining_Parent
 310 #
 311 #   DgitImportUnpatched
 312 #     has additional entry in classification result
 313 #       OrigParents = [ subset of Parents ]
 314 #
 315 #   Anchor
 316 #     has additional entry in classification result
 317 #       OrigParents = [ subset of Parents ]  # singleton list
 318 #
 319 #   TreatAsAnchor
 320 #
 321 #   BreakwaterStart
 322 #
 323 #   Unknown
 324 #     has additional entry in classification result
 325 #       Why => "prose"
 326
 327 sub parsecommit ($;$) {
 328     my ($objid, $p_ref) = @_;
 329     # => hash with                   CommitId Hdr Msg Tree Parents
 330     #    Parents entries have only   Ix CommitId
 331     #    $p_ref, if provided, must be [] and is used as a base for Parents
 332
 333     $p_ref //= [];
 334     die if @$p_ref;
 335
 336     my ($h,$m) = get_commit $objid;
 337
 338     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 339     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 340
 341     my $r = {
 342         CommitId => $objid,
 343         Hdr => $h,
 344         Msg => $m,
 345         Tree => $t,
 346         Parents => $p_ref,
 347     };
 348
 349     foreach my $ph (@ph) {
 350         push @$p_ref, {
 351             Ix => scalar @$p_ref,
 352             CommitId => $ph,
 353         };
 354     }
 355
 356     return $r;
 357 }
 358
 359 sub classify ($) {
 360     my ($objid) = @_;
 361
 362     my @p;
 363     my $r = parsecommit($objid, \@p);
 364     my $t = $r->{Tree};
 365
 366     foreach my $p (@p) {
 367         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 368     }
 369
 370     printdebug "classify $objid \$t=$t \@p",
 371         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 372         "\n";
 373
 374     my $classify = sub {
 375         my ($type, @rest) = @_;
 376         $r = { %$r, Type => $type, @rest };
 377         if ($debuglevel) {
 378             printdebug " = $type ".(dd $r)."\n";
 379         }
 380         return $r;
 381     };
 382     my $unknown = sub {
 383         my ($why) = @_;
 384         $r = { %$r, Type => qw(Unknown), Why => $why };
 385         printdebug " ** Unknown\n";
 386         return $r;
 387     };
 388
 389     if (grep { $_ eq $objid } @opt_anchors) {
 390         return $classify->('TreatAsAnchor');
 391     }
 392
 393     my @identical = grep { !$_->{Differs} } @p;
 394     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 395     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 396
 397     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 398         # multi-orig upstreams are represented with an anchor merge
 399         # from a single upstream commit which combines the orig tarballs
 400
 401         # Every anchor tagged this way must be a merge.
 402         # We are relying on the
 403         #     [git-debrebase anchor: ...]
 404         # commit message annotation in "declare" anchor merges (which
 405         # do not have any upstream changes), to distinguish those
 406         # anchor merges from ordinary pseudomerges (which we might
 407         # just try to strip).
 408         #
 409         # However, the user is going to be doing git-rebase a lot.  We
 410         # really don't want them to rewrite an anchor commit.
 411         # git-rebase trips up on merges, so that is a useful safety
 412         # catch.
 413         #
 414         # BreakwaterStart commits are also anchors in the terminology
 415         # of git-debrebase(5), but they are untagged (and always
 416         # manually generated).
 417         #
 418         # We cannot not tolerate any tagged linear commit (ie,
 419         # BreakwaterStart commits tagged `[anchor:') because such a
 420         # thing could result from an erroneous linearising raw git
 421         # rebase of a merge anchor.  That would represent a corruption
 422         # of the branch. and we want to detect and reject the results
 423         # of such corruption before it makes it out anywhere.  If we
 424         # reject it here then we avoid making the pseudomerge which
 425         # would be needed to push it.
 426
 427         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 428         @p == 2 or return $badanchor->("has other than two parents");
 429         $haspatches and return $badanchor->("contains debian/patches");
 430
 431         # How to decide about l/r ordering of anchors ?  git
 432         # --topo-order prefers to expand 2nd parent first.  There's
 433         # already an easy rune to look for debian/ history anyway (git log
 434         # debian/) so debian breakwater branch should be 1st parent; that
 435         # way also there's also an easy rune to look for the upstream
 436         # patches (--topo-order).
 437
 438         # Also this makes --first-parent be slightly more likely to
 439         # be useful - it makes it provide a linearised breakwater history.
 440
 441         # Of course one can say somthing like
 442         #  gitk -- ':/' ':!/debian'
 443         # to get _just_ the commits touching upstream files, and by
 444         # the TREESAME logic in git-rev-list this will leave the
 445         # breakwater into upstream at the first anchor.  But that
 446         # doesn't report debian/ changes at all.
 447
 448         # Other observations about gitk: by default, gitk seems to
 449         # produce output in a different order to git-rev-list.  I
 450         # can't seem to find this documented anywhere.  gitk
 451         # --date-order DTRT.  But, gitk always seems to put the
 452         # parents from left to right, in order, so it's easy to see
 453         # which way round a pseudomerge is.
 454
 455         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 456         $p[1]{Differs} & ~DS_DEB and
 457             $badanchor->("upstream files differ from left parent");
 458         $p[0]{Differs} & ~D_UPS and
 459             $badanchor->("debian/ differs from right parent");
 460
 461         return $classify->(qw(Anchor),
 462                            OrigParents => [ $p[1] ]);
 463     }
 464
 465     if (@p == 1) {
 466         my $d = $r->{Parents}[0]{Differs};
 467         if ($d == D_PAT_ADD) {
 468             return $classify->(qw(AddPatches));
 469         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 470             return $unknown->("edits debian/patches");
 471         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 472             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 473             if ($ty eq 'tree') {
 474                 if ($d == D_DEB_CLOG) {
 475                     return $classify->(qw(Changelog));
 476                 } else {
 477                     return $classify->(qw(Packaging));
 478                 }
 479             } elsif ($ty eq 'missing') {
 480                 return $classify->(qw(BreakwaterStart));
 481             } else {
 482                 return $unknown->("parent's debian is not a directory");
 483             }
 484         } elsif ($d == D_UPS) {
 485             return $classify->(qw(Upstream));
 486         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 487             return $classify->(qw(Mixed));
 488         } elsif ($d == 0) {
 489             return $unknown->("no changes");
 490         } else {
 491             confess "internal error $objid ?";
 492         }
 493     }
 494     if (!@p) {
 495         return $unknown->("origin commit");
 496     }
 497
 498     if (@p == 2 && @identical == 1) {
 499         my @overwritten = grep { $_->{Differs} } @p;
 500         confess "internal error $objid ?" unless @overwritten==1;
 501         return $classify->(qw(Pseudomerge),
 502                            Overwritten => [ $overwritten[0] ],
 503                            Contributor => $identical[0]);
 504     }
 505     if (@p == 2 && @identical == 2) {
 506         my $get_t = sub {
 507             my ($ph,$pm) = get_commit $_[0]{CommitId};
 508             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 509             $1;
 510         };
 511         my @bytime = @p;
 512         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 513         if ($order > 0) { # newer first
 514         } elsif ($order < 0) {
 515             @bytime = reverse @bytime;
 516         } else {
 517             # same age, default to order made by -s ours
 518             # that is, commit was made by someone who preferred L
 519         }
 520         return $classify->(qw(Pseudomerge),
 521                            SubType => qw(Ambiguous),
 522                            Contributor => $bytime[0],
 523                            Overwritten => [ $bytime[1] ]);
 524     }
 525     foreach my $p (@p) {
 526         my ($p_h, $p_m) = get_commit $p->{CommitId};
 527         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 528         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 529     }
 530     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 531     my $m2 = $r->{Msg};
 532     if (!(grep { !$_->{IsOrigin} } @p) and
 533         (@orig_ps >= @p - 1) and
 534         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 535         $r->{NewMsg} = $m2;
 536         return $classify->(qw(DgitImportUnpatched),
 537                            OrigParents => \@orig_ps);
 538     }
 539
 540     return $unknown->("complex merge");
 541 }
 542
 543 sub keycommits ($;$$$$) {
 544     my ($head, $furniture, $unclean, $trouble, $fatal) = @_;
 545     # => ($anchor, $breakwater)
 546
 547     # $unclean->("unclean-$tagsfx", $msg, $cl)
 548     # $furniture->("unclean-$tagsfx", $msg, $cl)
 549     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 550     #   is callled for each situation or commit that
 551     #   wouldn't be found in a laundered branch
 552     # $furniture is for furniture commits such as might be found on an
 553     #   interchange branch (pseudomerge, d/patches, changelog)
 554     # $trouble is for things whnich prevent the return of
 555     #   anchor and breakwater information; if that is ignored,
 556     #   then keycommits returns (undef, undef) instead.
 557     # $fatal is for unprocessable commits, and should normally cause
 558     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 559     #
 560     # If a callback is undef, fail is called instead.
 561     # If a callback is defined but false, the situation is ignored.
 562     # Callbacks may say:
 563     #   no warnings qw(exiting); last;
 564     # if the answer is no longer wanted.
 565
 566     my ($anchor, $breakwater);
 567     my $clogonly;
 568     my $cl;
 569     $fatal //= sub { fail $_[2]; };
 570     my $x = sub {
 571         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 572         my $why = $mainwhy.$xwhy;
 573         my $m = "branch needs laundering (run git-debrebase): $why";
 574         fail $m unless defined $cb;
 575         return unless $cb;
 576         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 577     };
 578     for (;;) {
 579         $cl = classify $head;
 580         my $ty = $cl->{Type};
 581         if ($ty eq 'Packaging') {
 582             $breakwater //= $clogonly;
 583             $breakwater //= $head;
 584         } elsif ($ty eq 'Changelog') {
 585             # this is going to count as the tip of the breakwater
 586             # only if it has no upstream stuff before it
 587             $clogonly //= $head;
 588         } elsif ($ty eq 'Anchor' or
 589                  $ty eq 'TreatAsAnchor' or
 590                  $ty eq 'BreakwaterStart') {
 591             $anchor = $head;
 592             $breakwater //= $clogonly;
 593             $breakwater //= $head;
 594             last;
 595         } elsif ($ty eq 'Upstream') {
 596             $x->($unclean, 'ordering',
 597  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 598                 if defined $breakwater;
 599             $clogonly = undef;
 600             $breakwater = undef;
 601         } elsif ($ty eq 'Mixed') {
 602             $x->($unclean, 'mixed',
 603                  "found mixed upstream/packaging commit"," ($head)");
 604             $clogonly = undef;
 605             $breakwater = undef;
 606         } elsif ($ty eq 'Pseudomerge' or
 607                  $ty eq 'AddPatches') {
 608             $x->($furniture, (lc $ty),
 609                  "found interchange bureaucracy commit ($ty)"," ($head)");
 610         } elsif ($ty eq 'DgitImportUnpatched') {
 611             $x->($trouble, 'dgitimport',
 612                  "found dgit dsc import ($head)");
 613             return (undef,undef);
 614         } else {
 615             $x->($fatal, 'unprocessable',
 616                  "found unprocessable commit, cannot cope: $cl->{Why}",
 617                  " ($head)");
 618             return (undef,undef);
 619         }
 620         $head = $cl->{Parents}[0]{CommitId};
 621     }
 622     return ($anchor, $breakwater);
 623 }
 624
 625 sub walk ($;$$);
 626 sub walk ($;$$) {
 627     my ($input,
 628         $nogenerate,$report) = @_;
 629     # => ($tip, $breakwater_tip, $last_anchor)
 630     # (or nothing, if $nogenerate)
 631
 632     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 633
 634     # go through commits backwards
 635     # we generate two lists of commits to apply:
 636     # breakwater branch and upstream patches
 637     my (@brw_cl, @upp_cl, @processed);
 638     my %found;
 639     my $upp_limit;
 640     my @pseudomerges;
 641
 642     my $cl;
 643     my $xmsg = sub {
 644         my ($prose, $info) = @_;
 645         my $ms = $cl->{Msg};
 646         chomp $ms;
 647         $info //= '';
 648         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 649         return (Msg => $ms);
 650     };
 651     my $rewrite_from_here = sub {
 652         my ($cl) = @_;
 653         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 654         push @$cl, $sp_cl;
 655         push @processed, $sp_cl;
 656     };
 657     my $cur = $input;
 658
 659     my $prdelim = "";
 660     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 661
 662     my $prline = sub {
 663         return unless $report;
 664         print $report $prdelim, @_;
 665         $prdelim = "\n";
 666     };
 667
 668     my $bomb = sub { # usage: return $bomb->();
 669         print $report " Unprocessable" if $report;
 670         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 671         $prprdelim->();
 672         if ($nogenerate) {
 673             return (undef,undef);
 674         }
 675         die "commit $cur: Cannot cope with this commit (d.".
 676             (join ' ', map { sprintf "%#x", $_->{Differs} }
 677              @{ $cl->{Parents} }).
 678             (defined $cl->{Why} ? "; $cl->{Why}": '').
 679                  ")";
 680     };
 681
 682     my $build;
 683     my $breakwater;
 684
 685     my $build_start = sub {
 686         my ($msg, $parent) = @_;
 687         $prline->(" $msg");
 688         $build = $parent;
 689         no warnings qw(exiting); last;
 690     };
 691
 692     my $last_anchor;
 693
 694     for (;;) {
 695         $cl = classify $cur;
 696         my $ty = $cl->{Type};
 697         my $st = $cl->{SubType};
 698         $prline->("$cl->{CommitId} $cl->{Type}");
 699         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 700         push @processed, $cl;
 701         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 702         if ($ty eq 'AddPatches') {
 703             $cur = $p0;
 704             $rewrite_from_here->(\@upp_cl);
 705             next;
 706         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 707             push @brw_cl, $cl;
 708             $cur = $p0;
 709             next;
 710         } elsif ($ty eq 'BreakwaterStart') {
 711             $last_anchor = $cur;
 712             $build_start->('FirstPackaging', $cur);
 713         } elsif ($ty eq 'Upstream') {
 714             push @upp_cl, $cl;
 715             $cur = $p0;
 716             next;
 717         } elsif ($ty eq 'Mixed') {
 718             my $queue = sub {
 719                 my ($q, $wh) = @_;
 720                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 721                 push @$q, $cls;
 722             };
 723             $queue->(\@brw_cl, "debian");
 724             $queue->(\@upp_cl, "upstream");
 725             $rewrite_from_here->(\@brw_cl);
 726             $cur = $p0;
 727             next;
 728         } elsif ($ty eq 'Pseudomerge') {
 729             my $contrib = $cl->{Contributor}{CommitId};
 730             print $report " Contributor=$contrib" if $report;
 731             push @pseudomerges, $cl;
 732             $rewrite_from_here->(\@upp_cl);
 733             $cur = $contrib;
 734             next;
 735         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
 736             $last_anchor = $cur;
 737             $build_start->("Anchor", $cur);
 738         } elsif ($ty eq 'DgitImportUnpatched') {
 739             my $pm = $pseudomerges[-1];
 740             if (defined $pm) {
 741                 # To an extent, this is heuristic.  Imports don't have
 742                 # a useful history of the debian/ branch.  We assume
 743                 # that the first pseudomerge after an import has a
 744                 # useful history of debian/, and ignore the histories
 745                 # from later pseudomerges.  Often the first pseudomerge
 746                 # will be the dgit import of the upload to the actual
 747                 # suite intended by the non-dgit NMUer, and later
 748                 # pseudomerges may represent in-archive copies.
 749                 my $ovwrs = $pm->{Overwritten};
 750                 printf $report " PM=%s \@Overwr:%d",
 751                     $pm->{CommitId}, (scalar @$ovwrs)
 752                     if $report;
 753                 if (@$ovwrs != 1) {
 754                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 755                     return $bomb->();
 756                 }
 757                 my $ovwr = $ovwrs->[0]{CommitId};
 758                 printf $report " Overwr=%s", $ovwr if $report;
 759                 # This import has a tree which is just like a
 760                 # breakwater tree, but it has the wrong history.  It
 761                 # ought to have the previous breakwater (which the
 762                 # pseudomerge overwrote) as an ancestor.  That will
 763                 # make the history of the debian/ files correct.  As
 764                 # for the upstream version: either it's the same as
 765                 # was ovewritten (ie, same as the previous
 766                 # breakwater), in which case that history is precisely
 767                 # right; or, otherwise, it was a non-gitish upload of a
 768                 # new upstream version.  We can tell these apart by
 769                 # looking at the tree of the supposed upstream.
 770                 push @brw_cl, {
 771                     %$cl,
 772                     SpecialMethod => 'DgitImportDebianUpdate',
 773                     $xmsg->("convert dgit import: debian changes")
 774                 }, {
 775                     %$cl,
 776                     SpecialMethod => 'DgitImportUpstreamUpdate',
 777                     $xmsg->("convert dgit import: upstream update",
 778                             " anchor")
 779                 };
 780                 $prline->(" Import");
 781                 $rewrite_from_here->(\@brw_cl);
 782                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 783                 $cur = $ovwr;
 784                 next;
 785             } else {
 786                 # Everything is from this import.  This kind of import
 787                 # is already in valid breakwater format, with the
 788                 # patches as commits.
 789                 printf $report " NoPM" if $report;
 790                 # last thing we processed will have been the first patch,
 791                 # if there is one; which is fine, so no need to rewrite
 792                 # on account of this import
 793                 $build_start->("ImportOrigin", $cur);
 794             }
 795             die "$ty ?";
 796         } else {
 797             printdebug "*** WALK BOMB unrecognised\n";
 798             return $bomb->();
 799         }
 800     }
 801     $prprdelim->();
 802
 803     printdebug "*** WALK prep done cur=$cur".
 804         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 805
 806     return if $nogenerate;
 807
 808     # Now we build it back up again
 809
 810     fresh_workarea();
 811
 812     my $rewriting = 0;
 813
 814     my $read_tree_debian = sub {
 815         my ($treeish) = @_;
 816         read_tree_subdir 'debian', "$treeish:debian";
 817         rm_subdir_cached 'debian/patches';
 818     };
 819     my $read_tree_upstream = sub {
 820         my ($treeish) = @_;
 821         runcmd @git, qw(read-tree), $treeish;
 822         $read_tree_debian->($build);
 823     };
 824
 825     $#upp_cl = $upp_limit if defined $upp_limit;
 826
 827     my $committer_authline = calculate_committer_authline();
 828
 829     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 830
 831     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 832
 833     in_workarea sub {
 834         mkdir $rd or $!==EEXIST or die $!;
 835         my $current_method;
 836         runcmd @git, qw(read-tree), $build;
 837         foreach my $cl (qw(Debian), (reverse @brw_cl),
 838                         { SpecialMethod => 'RecordBreakwaterTip' },
 839                         qw(Upstream), (reverse @upp_cl)) {
 840             if (!ref $cl) {
 841                 $current_method = $cl;
 842                 next;
 843             }
 844             my $method = $cl->{SpecialMethod} // $current_method;
 845             my @parents = ($build);
 846             my $cltree = $cl->{CommitId};
 847             printdebug "WALK BUILD ".($cltree//'undef').
 848                 " $method (rewriting=$rewriting)\n";
 849             if ($method eq 'Debian') {
 850                 $read_tree_debian->($cltree);
 851             } elsif ($method eq 'Upstream') {
 852                 $read_tree_upstream->($cltree);
 853             } elsif ($method eq 'StartRewrite') {
 854                 $rewriting = 1;
 855                 next;
 856             } elsif ($method eq 'RecordBreakwaterTip') {
 857                 $breakwater = $build;
 858                 next;
 859             } elsif ($method eq 'DgitImportDebianUpdate') {
 860                 $read_tree_debian->($cltree);
 861             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 862                 confess unless $rewriting;
 863                 my $differs = (get_differs $build, $cltree);
 864                 next unless $differs & D_UPS;
 865                 $read_tree_upstream->($cltree);
 866                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 867             } else {
 868                 confess "$method ?";
 869             }
 870             if (!$rewriting) {
 871                 my $procd = (pop @processed) // 'UNDEF';
 872                 if ($cl ne $procd) {
 873                     $rewriting = 1;
 874                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 875                 }
 876             }
 877             my $newtree = cmdoutput @git, qw(write-tree);
 878             my $ch = $cl->{Hdr};
 879             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 880             $ch =~ s{^parent .*\n}{}mg;
 881             $ch =~ s{(?=^author)}{
 882                 join '', map { "parent $_\n" } @parents
 883             }me or confess "$ch ?";
 884             if ($rewriting) {
 885                 $ch =~ s{^committer .*$}{$committer_authline}m
 886                     or confess "$ch ?";
 887             }
 888             my $cf = "$rd/m$rewriting";
 889             open CD, ">", $cf or die $!;
 890             print CD $ch, "\n", $cl->{Msg} or die $!;
 891             close CD or die $!;
 892             my @cmd = (@git, qw(hash-object));
 893             push @cmd, qw(-w) if $rewriting;
 894             push @cmd, qw(-t commit), $cf;
 895             my $newcommit = cmdoutput @cmd;
 896             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 897             $build = $newcommit;
 898             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 899                 $last_anchor = $cur;
 900             }
 901         }
 902     };
 903
 904     my $final_check = get_differs $build, $input;
 905     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 906         if $final_check & ~D_PAT_ADD;
 907
 908     my @r = ($build, $breakwater, $last_anchor);
 909     printdebug "*** WALK RETURN @r\n";
 910     return @r
 911 }
 912
 913 sub get_head () {
 914     git_check_unmodified();
 915     return git_rev_parse qw(HEAD);
 916 }
 917
 918 sub update_head ($$$) {
 919     my ($old, $new, $mrest) = @_;
 920     push @deferred_updates, "update HEAD $new $old";
 921     run_deferred_updates $mrest;
 922 }
 923
 924 sub update_head_checkout ($$$) {
 925     my ($old, $new, $mrest) = @_;
 926     update_head $old, $new, $mrest;
 927     runcmd @git, qw(reset --hard);
 928 }
 929
 930 sub update_head_postlaunder ($$$) {
 931     my ($old, $tip, $reflogmsg) = @_;
 932     return if $tip eq $old;
 933     print "git-debrebase: laundered (head was $old)\n";
 934     update_head $old, $tip, $reflogmsg;
 935     # no tree changes except debian/patches
 936     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 937 }
 938
 939 sub do_launder_head ($) {
 940     my ($reflogmsg) = @_;
 941     my $old = get_head();
 942     record_ffq_auto();
 943     my ($tip,$breakwater) = walk $old;
 944     snags_maybe_bail();
 945     update_head_postlaunder $old, $tip, $reflogmsg;
 946     return ($tip,$breakwater);
 947 }
 948
 949 sub cmd_launder_v0 () {
 950     badusage "no arguments to launder-v0 allowed" if @ARGV;
 951     my $old = get_head();
 952     my ($tip,$breakwater,$last_anchor) = walk $old;
 953     update_head_postlaunder $old, $tip, 'launder';
 954     printf "# breakwater tip\n%s\n", $breakwater;
 955     printf "# working tip\n%s\n", $tip;
 956     printf "# last anchor\n%s\n", $last_anchor;
 957 }
 958
 959 sub defaultcmd_rebase () {
 960     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
 961     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
 962     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
 963 }
 964
 965 sub cmd_analyse () {
 966     die if ($ARGV[0]//'') =~ m/^-/;
 967     badusage "too many arguments to analyse" if @ARGV>1;
 968     my ($old) = @ARGV;
 969     if (defined $old) {
 970         $old = git_rev_parse $old;
 971     } else {
 972         $old = git_rev_parse 'HEAD';
 973     }
 974     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 975     STDOUT->error and die $!;
 976 }
 977
 978 sub ffq_prev_branchinfo () {
 979     my $current = git_get_symref();
 980     return gdr_ffq_prev_branchinfo($current);
 981 }
 982
 983 sub record_ffq_prev_deferred () {
 984     # => ('status', "message")
 985     # 'status' may be
 986     #    deferred          message is undef
 987     #    exists
 988     #    detached
 989     #    weird-symref
 990     #    notbranch
 991     # if not ff from some branch we should be ff from, is an snag
 992     # if "deferred", will have added something about that to
 993     #   @deferred_update_messages, and also maybe printed (already)
 994     #   some messages about ff checks
 995     my ($status, $message, $current, $ffq_prev, $gdrlast)
 996         = ffq_prev_branchinfo();
 997     return ($status, $message) unless $status eq 'branch';
 998
 999     my $currentval = get_head();
1000
1001     my $exists = git_get_ref $ffq_prev;
1002     return ('exists',"$ffq_prev already exists") if $exists;
1003
1004     return ('not-branch', 'HEAD symref is not to refs/heads/')
1005         unless $current =~ m{^refs/heads/};
1006     my $branch = $';
1007
1008     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1009     my %checked;
1010
1011     printdebug "ffq check_specs @check_specs\n";
1012
1013     my $check = sub {
1014         my ($lrref, $desc) = @_;
1015         printdebug "ffq might check $lrref ($desc)\n";
1016         my $invert;
1017         for my $chk (@check_specs) {
1018             my $glob = $chk;
1019             $invert = $glob =~ s{^[!^]}{};
1020             last if fnmatch $glob, $lrref;
1021         }
1022         return if $invert;
1023         my $lrval = git_get_ref $lrref;
1024         return unless length $lrval;
1025
1026         if (is_fast_fwd $lrval, $currentval) {
1027             print "OK, you are ahead of $lrref\n" or die $!;
1028             $checked{$lrref} = 1;
1029         } elsif (is_fast_fwd $currentval, $lrval) {
1030             $checked{$lrref} = -1;
1031             snag 'behind', "you are behind $lrref, divergence risk";
1032         } else {
1033             $checked{$lrref} = -1;
1034             snag 'diverged', "you have diverged from $lrref";
1035         }
1036     };
1037
1038     my $merge = cfg "branch.$branch.merge",1;
1039     if (defined $merge and $merge =~ m{^refs/heads/}) {
1040         my $rhs = $';
1041         printdebug "ffq merge $rhs\n";
1042         my $check_remote = sub {
1043             my ($remote, $desc) = @_;
1044             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1045             return unless defined $remote;
1046             $check->("refs/remotes/$remote/$rhs", $desc);
1047         };
1048         $check_remote->((scalar cfg "branch.$branch.remote",1),
1049                         'remote fetch/merge branch');
1050         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1051                         (scalar cfg "branch.$branch.pushDefault",1),
1052                         'remote push branch');
1053     }
1054     if ($branch =~ m{^dgit/}) {
1055         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1056     } elsif ($branch =~ m{^master$}) {
1057         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1058     }
1059
1060     snags_maybe_bail();
1061
1062     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1063     push @deferred_updates, "delete $gdrlast";
1064     push @deferred_update_messages, "Recorded current head for preservation";
1065     return ('deferred', undef);
1066 }
1067
1068 sub record_ffq_auto () {
1069     my ($status, $message) = record_ffq_prev_deferred();
1070     if ($status eq 'deferred' || $status eq 'exists') {
1071     } else {
1072         snag $status, "could not record ffq-prev: $message";
1073         snags_maybe_bail();
1074     }
1075 }
1076
1077 sub ffq_prev_info () {
1078     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1079     my ($status, $message, $current, $ffq_prev, $gdrlast)
1080         = ffq_prev_branchinfo();
1081     if ($status ne 'branch') {
1082         snag $status, "could not check ffq-prev: $message";
1083         snags_maybe_bail();
1084     }
1085     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1086     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1087 }
1088
1089 sub stitch ($$$$$) {
1090     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1091
1092     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1093
1094     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1095         my $differs = get_differs $old_head, $ffq_prev_commitish;
1096         unless ($differs & ~D_PAT_ADD) {
1097             # ffq-prev is ahead of us, and the only tree changes it has
1098             # are possibly addition of things in debian/patches/.
1099             # Just wind forwards rather than making a pointless pseudomerge.
1100             push @deferred_updates,
1101                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1102             update_head_checkout $old_head, $ffq_prev_commitish,
1103                 "stitch (fast forward)";
1104             return;
1105         }
1106     }
1107     fresh_workarea();
1108     # We make pseudomerges with L as the contributing parent.
1109     # This makes git rev-list --first-parent work properly.
1110     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1111         'Declare fast forward / record previous work',
1112         "[git-debrebase pseudomerge: $prose]",
1113     ];
1114     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1115     update_head $old_head, $new_head, "stitch: $prose";
1116 }
1117
1118 sub do_stitch ($;$) {
1119     my ($prose, $unclean) = @_;
1120
1121     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1122     if (!$ffq_prev_commitish) {
1123         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1124         return;
1125     }
1126     my $dangling_head = get_head();
1127
1128     keycommits $dangling_head, $unclean,$unclean,$unclean;
1129     snags_maybe_bail();
1130
1131     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1132 }
1133
1134 sub cmd_new_upstream () {
1135     # automatically and unconditionally launders before rebasing
1136     # if rebase --abort is used, laundering has still been done
1137
1138     my %pieces;
1139
1140     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1141
1142     # parse args - low commitment
1143     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1144     my $new_upstream_version = $new_version->version();
1145
1146     my $new_upstream = shift @ARGV;
1147     if (!defined $new_upstream) {
1148         my @tried;
1149         # todo: at some point maybe use git-deborig to do this
1150         foreach my $tagpfx ('', 'v', 'upstream/') {
1151             my $tag = $tagpfx.(dep14_version_mangle $new_upstream_version);
1152             $new_upstream = git_get_ref "refs/tags/$tag";
1153             last if length $new_upstream;
1154             push @tried, $tag;
1155         }
1156         if (!length $new_upstream) {
1157             fail "Could not determine appropriate upstream commitish.\n".
1158                 " (Tried these tags: @tried)\n".
1159                 " Check version, and specify upstream commitish explicitly.";
1160         }
1161     }
1162     $new_upstream = git_rev_parse $new_upstream;
1163
1164     record_ffq_auto();
1165
1166     my $piece = sub {
1167         my ($n, @x) = @_; # may be ''
1168         my $pc = $pieces{$n} //= {
1169             Name => $n,
1170             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1171         };
1172         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1173         $pc;
1174     };
1175
1176     my @newpieces;
1177     my $newpiece = sub {
1178         my ($n, @x) = @_; # may be ''
1179         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1180         push @newpieces, $pc;
1181     };
1182
1183     $newpiece->('',
1184         OldIx => 0,
1185         New => $new_upstream,
1186     );
1187     while (@ARGV && $ARGV[0] !~ m{^-}) {
1188         my $n = shift @ARGV;
1189
1190         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1191             unless @ARGV && $ARGV[0] !~ m{^-};
1192
1193         my $c = git_rev_parse shift @ARGV;
1194         die unless $n =~ m/^$extra_orig_namepart_re$/;
1195         $newpiece->($n, New => $c);
1196     }
1197
1198     # now we need to investigate the branch this generates the
1199     # laundered version but we don't switch to it yet
1200     my $old_head = get_head();
1201     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1202
1203     my $old_bw_cl = classify $old_bw;
1204     my $old_anchor_cl = classify $old_anchor;
1205     my $old_upstream;
1206     if (!$old_anchor_cl->{OrigParents}) {
1207         snag 'anchor-treated',
1208             'old anchor is recognised due to --anchor, cannot check upstream';
1209     } else {
1210         $old_upstream = parsecommit
1211             $old_anchor_cl->{OrigParents}[0]{CommitId};
1212         $piece->('', Old => $old_upstream->{CommitId});
1213     }
1214
1215     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1216         if ($old_upstream->{Msg} =~
1217  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1218            ) {
1219             my @oldpieces = (split / /, $1);
1220             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1221             if ($old_n_parents != @oldpieces &&
1222                 $old_n_parents != @oldpieces + 1) {
1223                 snag 'upstream-confusing', sprintf
1224                     "previous upstream combine %s".
1225                     " mentions %d pieces (each implying one parent)".
1226                     " but has %d parents".
1227                     " (one per piece plus maybe a previous combine)",
1228                     $old_upstream->{CommitId},
1229                     (scalar @oldpieces),
1230                     $old_n_parents;
1231             } elsif ($oldpieces[0] ne '.') {
1232                 snag 'upstream-confusing', sprintf
1233                     "previous upstream combine %s".
1234                     " first piece is not \`.'",
1235                     $oldpieces[0];
1236             } else {
1237                 $oldpieces[0] = '';
1238                 foreach my $i (0..$#oldpieces) {
1239                     my $n = $oldpieces[$i];
1240                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1241                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1242                 }
1243             }
1244         } else {
1245             snag 'upstream-confusing',
1246                 "previous upstream $old_upstream->{CommitId} is from".
1247                " git-debrebase but not an \`upstream-combine' commit";
1248         }
1249     }
1250
1251     foreach my $pc (values %pieces) {
1252         if (!$old_upstream) {
1253             # we have complained already
1254         } elsif (!$pc->{Old}) {
1255             snag 'upstream-new-piece',
1256                 "introducing upstream piece \`$pc->{Name}'";
1257         } elsif (!$pc->{New}) {
1258             snag 'upstream-rm-piece',
1259                 "dropping upstream piece \`$pc->{Name}'";
1260         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1261             snag 'upstream-not-ff',
1262                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1263         }
1264     }
1265
1266     printdebug "%pieces = ", (dd \%pieces), "\n";
1267     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1268
1269     snags_maybe_bail();
1270
1271     my $new_bw;
1272
1273     fresh_workarea();
1274     in_workarea sub {
1275         my @upstream_merge_parents;
1276
1277         if (!any_snags()) {
1278             push @upstream_merge_parents, $old_upstream->{CommitId};
1279         }
1280
1281         foreach my $pc (@newpieces) { # always has '' first
1282             if ($pc->{Name}) {
1283                 read_tree_subdir $pc->{Name}, $pc->{New};
1284             } else {
1285                 runcmd @git, qw(read-tree), $pc->{New};
1286             }
1287             push @upstream_merge_parents, $pc->{New};
1288         }
1289
1290         # index now contains the new upstream
1291
1292         if (@newpieces > 1) {
1293             # need to make the upstream subtree merge commit
1294             $new_upstream = make_commit \@upstream_merge_parents,
1295                 [ "Combine upstreams for $new_upstream_version",
1296  ("[git-debrebase upstream-combine . ".
1297  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1298  ": new upstream]"),
1299                 ];
1300         }
1301
1302         # $new_upstream is either the single upstream commit, or the
1303         # combined commit we just made.  Either way it will be the
1304         # "upstream" parent of the anchor merge.
1305
1306         read_tree_subdir 'debian', "$old_bw:debian";
1307
1308         # index now contains the anchor merge contents
1309         $new_bw = make_commit [ $old_bw, $new_upstream ],
1310             [ "Update to upstream $new_upstream_version",
1311  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1312             ];
1313
1314         my $clogsignoff = cmdoutput qw(git show),
1315             '--pretty=format:%an <%ae>  %aD',
1316             $new_bw;
1317
1318         # Now we have to add a changelog stanza so the Debian version
1319         # is right.
1320         die if unlink "debian";
1321         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1322         unlink "debian/changelog" or $!==ENOENT or die $!;
1323         mkdir "debian" or die $!;
1324         open CN, ">", "debian/changelog" or die $!;
1325         my $oldclog = git_cat_file ":debian/changelog";
1326         $oldclog =~ m/^($package_re) \(\S+\) / or
1327             fail "cannot parse old changelog to get package name";
1328         my $p = $1;
1329         print CN <<END, $oldclog or die $!;
1330 $p ($new_version) UNRELEASED; urgency=medium
1331
1332   * Update to new upstream version $new_upstream_version.
1333
1334  -- $clogsignoff
1335
1336 END
1337         close CN or die $!;
1338         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1339
1340         # Now we have the final new breakwater branch in the index
1341         $new_bw = make_commit [ $new_bw ],
1342             [ "Update changelog for new upstream $new_upstream_version",
1343               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1344             ];
1345     };
1346
1347     # we have constructed the new breakwater. we now need to commit to
1348     # the laundering output, because git-rebase can't easily be made
1349     # to make a replay list which is based on some other branch
1350
1351     update_head_postlaunder $old_head, $old_laundered_tip,
1352         'launder for new upstream';
1353
1354     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1355     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1356         "debrebase new-upstream $new_version: rebase";
1357     runcmd @cmd;
1358     # now it's for the user to sort out
1359 }
1360
1361 sub cmd_record_ffq_prev () {
1362     badusage "no arguments allowed" if @ARGV;
1363     my ($status, $msg) = record_ffq_prev_deferred();
1364     if ($status eq 'exists' && $opt_noop_ok) {
1365         print "Previous head already recorded\n" or die $!;
1366     } elsif ($status eq 'deferred') {
1367         run_deferred_updates 'record-ffq-prev';
1368     } else {
1369         fail "Could not preserve: $msg";
1370     }
1371 }
1372
1373 sub cmd_anchor () {
1374     badusage "no arguments allowed" if @ARGV;
1375     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1376     print "$bw\n" or die $!;
1377 }
1378
1379 sub cmd_breakwater () {
1380     badusage "no arguments allowed" if @ARGV;
1381     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1382     print "$bw\n" or die $!;
1383 }
1384
1385 sub cmd_status () {
1386     badusage "no arguments allowed" if @ARGV;
1387
1388     # todo: gdr status should print divergence info
1389     # todo: gdr status should print upstream component(s) info
1390     # todo: gdr should leave/maintain some refs with this kind of info ?
1391
1392     my $oldest = [ 0 ];
1393     my $newest;
1394     my $note = sub {
1395         my ($badness, $ourmsg, $snagname, $kcmsg, $cl) = @_;
1396         if ($oldest->[0] < $badness) {
1397             $oldest = $newest = undef;
1398         }
1399         $oldest = \@_; # we're walking backwards
1400         $newest //= \@_;
1401     };
1402     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1403         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1404         sub { $note->(2, 'branch is unlaundered', @_); },
1405         sub { $note->(3, 'branch needs laundering', @_); },
1406         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1407
1408     my $prcommitinfo = sub {
1409         my ($cid) = @_;
1410         flush STDOUT or die $!;
1411         runcmd @git, qw(--no-pager log -n1),
1412             '--pretty=format:    %h %s%n',
1413             $cid;
1414     };
1415
1416     print "current branch contents, in git-debrebase terms:\n";
1417     if (!$oldest->[0]) {
1418         print "  branch is laundered\n";
1419     } else {
1420         print "  $oldest->[1]\n";
1421         my $printed = '';
1422         foreach my $info ($oldest, $newest) {
1423             my $cid = $info->[4]{CommitId};
1424             next if $cid eq $printed;
1425             $printed = $cid;
1426             print "  $info->[3]\n";
1427             $prcommitinfo->($cid);
1428         }
1429     }
1430
1431     my $prab = sub {
1432         my ($cid, $what) = @_;
1433         if (!defined $cid) {
1434             print "  $what is not well-defined\n";
1435         } else {
1436             print "  $what\n";
1437             $prcommitinfo->($cid);
1438         }
1439     };
1440     print "key git-debrebase commits:\n";
1441     $prab->($anchor, 'anchor');
1442     $prab->($bw, 'breakwater');
1443
1444     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1445         ffq_prev_branchinfo();
1446
1447     print "branch and ref status, in git-debrebase terms:\n";
1448     if ($ffq_msg) {
1449         print "  $ffq_msg\n";
1450     } else {
1451         $ffq_prev = git_get_ref $ffq_prev;
1452         $gdrlast = git_get_ref $gdrlast;
1453         if ($ffq_prev) {
1454             print "  unstitched; previous tip was:\n";
1455             $prcommitinfo->($ffq_prev);
1456         } elsif (!$gdrlast) {
1457             print "  stitched? (no record of git-debrebase work)\n";
1458         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1459             print "  stitched\n";
1460         } else {
1461             print "  not git-debrebase (diverged since last stitch)\n"
1462         }
1463     }
1464 }
1465
1466 sub cmd_stitch () {
1467     my $prose = 'stitch';
1468     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1469     badusage "no arguments allowed" if @ARGV;
1470     do_stitch $prose, 0;
1471 }
1472 sub cmd_prepush () { cmd_stitch(); }
1473
1474 sub cmd_quick () {
1475     badusage "no arguments allowed" if @ARGV;
1476     do_launder_head 'launder for git-debrebase quick';
1477     do_stitch 'quick';
1478 }
1479
1480 sub cmd_conclude () {
1481     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1482     if (!$ffq_prev_commitish) {
1483         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1484         return;
1485     }
1486     my $dangling_head = get_head();
1487
1488     badusage "no arguments allowed" if @ARGV;
1489     do_launder_head 'launder for git-debrebase quick';
1490     do_stitch 'quick';
1491 }
1492
1493 sub make_patches_staged ($) {
1494     my ($head) = @_;
1495     # Produces the patches that would result from $head if it were
1496     # laundered.
1497     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
1498     fresh_workarea();
1499     in_workarea sub {
1500         runcmd @git, qw(checkout -q -b bw), $secret_bw;
1501         runcmd @git, qw(checkout -q -b patch-queue/bw), $secret_head;
1502         my @gbp_cmd = (qw(gbp pq export));
1503         my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
1504         if ($r) {
1505             { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
1506             failedcmd @gbp_cmd;
1507         }
1508         runcmd @git, qw(add -f debian/patches);
1509     };
1510 }
1511
1512 sub make_patches ($) {
1513     my ($head) = @_;
1514     keycommits $head, 0, \&snag;
1515     make_patches_staged $head;
1516     my $out;
1517     in_workarea sub {
1518         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
1519         runcmd @git, qw(read-tree), $head;
1520         read_tree_subdir 'debian/patches', $ptree;
1521         $out = make_commit [$head], [
1522             'Commit patch queue (exported by git-debrebase)',
1523             '[git-debrebase: export and commit patches]',
1524         ];
1525     };
1526     return $out;
1527 }
1528
1529 sub cmd_make_patches () {
1530     my $opt_quiet_would_amend;
1531     GetOptions('quiet-would-amend!', \$opt_quiet_would_amend)
1532         or die badusage("bad options to make-patches");
1533     badusage "no arguments allowed" if @ARGV;
1534     my $old_head = get_head();
1535     my $new = make_patches $old_head;
1536     my $d = get_differs $old_head, $new;
1537     if ($d == 0) {
1538         fail "No (more) patches to export." unless $opt_noop_ok;
1539         return;
1540     } elsif ($d == D_PAT_ADD) {
1541         snags_maybe_bail();
1542         update_head_checkout $old_head, $new, 'make-patches';
1543     } else {
1544         print STDERR failmsg
1545             "Patch export produced patch amendments".
1546             " (abandoned output commit $new).".
1547             "  Try laundering first."
1548             unless $opt_quiet_would_amend;
1549         finish 7;
1550     }
1551 }
1552
1553 sub cmd_convert_from_gbp () {
1554     badusage "needs 1 optional argument, the upstream git rev"
1555         unless @ARGV<=1;
1556     my ($upstream_spec) = @ARGV;
1557     $upstream_spec //= 'refs/heads/upstream';
1558     my $upstream = git_rev_parse $upstream_spec;
1559     my $old_head = get_head();
1560
1561     my $upsdiff = get_differs $upstream, $old_head;
1562     if ($upsdiff & D_UPS) {
1563         runcmd @git, qw(--no-pager diff),
1564             $upstream, $old_head,
1565             qw( -- :!/debian :/);
1566  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1567     }
1568
1569     if (!is_fast_fwd $upstream, $old_head) {
1570         snag 'upstream-not-ancestor',
1571             "upstream ($upstream) is not an ancestor of HEAD";
1572     } else {
1573         my $wrong = cmdoutput
1574             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1575              qw(-- :/ :!/debian));
1576         if (length $wrong) {
1577             snag 'unexpected-upstream-changes',
1578                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1579             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1580         }
1581     }
1582
1583     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1584         snag 'upstream-has-debian',
1585             "upstream ($upstream) contains debian/ directory";
1586     }
1587
1588     snags_maybe_bail();
1589
1590     my $work;
1591
1592     fresh_workarea();
1593     in_workarea sub {
1594         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1595         # make a branch out of the patch queue - we'll want this in a mo
1596         runcmd qw(gbp pq import);
1597         # strip the patches out
1598         runcmd @git, qw(checkout -q gdr-internal~0);
1599         rm_subdir_cached 'debian/patches';
1600         $work = make_commit ['HEAD'], [
1601  'git-debrebase convert-from-gbp: drop patches from tree',
1602  'Delete debian/patches, as part of converting to git-debrebase format.',
1603  '[git-debrebase convert-from-gbp: drop patches from tree]'
1604                               ];
1605         # make the anchor merge
1606         # the tree is already exactly right
1607         $work = make_commit [$work, $upstream], [
1608  'git-debrebase import: declare upstream',
1609  'First breakwater merge.',
1610  '[git-debrebase anchor: declare upstream]'
1611                               ];
1612
1613         # rebase the patch queue onto the new breakwater
1614         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1615         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1616         $work = git_rev_parse 'HEAD';
1617     };
1618
1619     update_head_checkout $old_head, $work, 'convert-from-gbp';
1620 }
1621
1622 sub cmd_convert_to_gbp () {
1623     badusage "no arguments allowed" if @ARGV;
1624     my $head = get_head();
1625     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
1626     keycommits $head, 0;
1627     my $out;
1628     make_patches_staged $head;
1629     in_workarea sub {
1630         $out = make_commit ['HEAD'], [
1631             'Commit patch queue (converted from git-debrebase format)',
1632             '[git-debrebase convert-to-gbp: commit patches]',
1633         ];
1634     };
1635     if (defined $ffq) {
1636         push @deferred_updates, "delete $ffq";
1637         push @deferred_updates, "delete $gdrlast";
1638     }
1639     snags_maybe_bail();
1640     update_head_checkout $head, $out, "convert to gbp (v0)";
1641     print <<END or die $!;
1642 git-debrebase: converted to git-buildpackage branch format
1643 git-debrebase: WARNING: do not now run "git-debrebase" any more
1644 git-debrebase: WARNING: doing so would drop all upstream patches!
1645 END
1646 }
1647
1648 sub cmd_downstream_rebase_launder_v0 () {
1649     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1650     my ($base) = @ARGV;
1651     $base = git_rev_parse $base;
1652     my $old_head = get_head();
1653     my $current = $old_head;
1654     my $topmost_keep;
1655     for (;;) {
1656         if ($current eq $base) {
1657             $topmost_keep //= $current;
1658             print " $current BASE stop\n";
1659             last;
1660         }
1661         my $cl = classify $current;
1662         print " $current $cl->{Type}";
1663         my $keep = 0;
1664         my $p0 = $cl->{Parents}[0]{CommitId};
1665         my $next;
1666         if ($cl->{Type} eq 'Pseudomerge') {
1667             print " ^".($cl->{Contributor}{Ix}+1);
1668             $next = $cl->{Contributor}{CommitId};
1669         } elsif ($cl->{Type} eq 'AddPatches' or
1670                  $cl->{Type} eq 'Changelog') {
1671             print " strip";
1672             $next = $p0;
1673         } else {
1674             print " keep";
1675             $next = $p0;
1676             $keep = 1;
1677         }
1678         print "\n";
1679         if ($keep) {
1680             $topmost_keep //= $current;
1681         } else {
1682             die "to-be stripped changes not on top of the branch\n"
1683                 if $topmost_keep;
1684         }
1685         $current = $next;
1686     }
1687     if ($topmost_keep eq $old_head) {
1688         print "unchanged\n";
1689     } else {
1690         print "updating to $topmost_keep\n";
1691         update_head_checkout
1692             $old_head, $topmost_keep,
1693             'downstream-rebase-launder-v0';
1694     }
1695 }
1696
1697 GetOptions("D+" => \$debuglevel,
1698            'noop-ok', => \$opt_noop_ok,
1699            'f=s' => \@snag_force_opts,
1700            'anchor=s' => \@opt_anchors,
1701            'force!',
1702            '-i:s' => sub {
1703                my ($opt,$val) = @_;
1704                badusage "git-debrebase: no cuddling to -i for git-rebase"
1705                    if length $val;
1706                die if $opt_defaultcmd_interactive; # should not happen
1707                $opt_defaultcmd_interactive = [ qw(-i) ];
1708                # This access to @ARGV is excessive familiarity with
1709                # Getopt::Long, but there isn't another sensible
1710                # approach.  '-i=s{0,}' does not work with bundling.
1711                push @$opt_defaultcmd_interactive, @ARGV;
1712                @ARGV=();
1713            }) or die badusage "bad options\n";
1714 initdebug('git-debrebase ');
1715 enabledebug if $debuglevel;
1716
1717 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1718 chdir $toplevel or die "chdir $toplevel: $!";
1719
1720 $rd = fresh_playground "$playprefix/misc";
1721
1722 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
1723
1724 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
1725     defaultcmd_rebase();
1726 } else {
1727     my $cmd = shift @ARGV;
1728     my $cmdfn = $cmd;
1729     $cmdfn =~ y/-/_/;
1730     $cmdfn = ${*::}{"cmd_$cmdfn"};
1731
1732     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1733     $cmdfn->();
1734 }
1735
1736 finish 0;