git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea () {
 132     $workarea = fresh_playground "$playprefix/work";
 133     in_workarea sub { playtree_setup };
 134 }
 135
 136 sub run_ref_updates_now ($$) {
 137     my ($mrest, $updates) = @_;
 138     # @$updates is a list of lines for git-update-ref, without \ns
 139
 140     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 141     debugcmd '>|', @upd_cmd;
 142     open U, "|-", @upd_cmd or die $!;
 143     foreach (@$updates) {
 144         printdebug ">= ", $_, "\n";
 145         print U $_, "\n" or die $!;
 146     }
 147     printdebug ">\$\n";
 148     close U or failedcmd @upd_cmd;
 149 }
 150
 151 our $snags_forced = 0;
 152 our $snags_tripped = 0;
 153 our $snags_summarised = 0;
 154 our @deferred_updates;
 155 our @deferred_update_messages;
 156
 157 sub merge_wreckage_cleaning ($) {
 158     my ($updates) = @_;
 159     git_for_each_ref("$wrecknoteprefix/*", sub {
 160         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 161         push @$updates, "delete $fullrefname";
 162     });
 163 }
 164
 165 sub all_snags_summarised () {
 166     $snags_forced + $snags_tripped == $snags_summarised;
 167 }
 168 sub run_deferred_updates ($) {
 169     my ($mrest) = @_;
 170
 171     confess 'dangerous internal error' unless all_snags_summarised();
 172
 173     merge_wreckage_cleaning \@deferred_updates;
 174     run_ref_updates_now $mrest, \@deferred_updates;
 175     print $_, "\n" foreach @deferred_update_messages;
 176
 177     @deferred_updates = ();
 178     @deferred_update_messages = ();
 179 }
 180
 181 sub get_differs ($$) {
 182     my ($x,$y) = @_;
 183     # This resembles quiltify_trees_differ, in dgit, a bit.
 184     # But we don't care about modes, or dpkg-source-unrepresentable
 185     # changes, and we don't need the plethora of different modes.
 186     # Conversely we need to distinguish different kinds of changes to
 187     # debian/ and debian/patches/.
 188
 189     my $differs = 0;
 190
 191     my $rundiff = sub {
 192         my ($opts, $limits, $fn) = @_;
 193         my @cmd = (@git, qw(diff-tree -z --no-renames));
 194         push @cmd, @$opts;
 195         push @cmd, "$_:" foreach $x, $y;
 196         push @cmd, '--', @$limits;
 197         my $diffs = cmdoutput @cmd;
 198         foreach (split /\0/, $diffs) { $fn->(); }
 199     };
 200
 201     $rundiff->([qw(--name-only)], [], sub {
 202         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 203     });
 204
 205     if ($differs & DS_DEB) {
 206         $differs &= ~DS_DEB;
 207         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 208             $differs |=
 209                 m{^debian/patches/}      ? D_PAT_OTH  :
 210                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 211                                            D_DEB_OTH;
 212         });
 213         die "mysterious debian changes $x..$y"
 214             unless $differs & (D_PAT_OTH|DS_DEB);
 215     }
 216
 217     if ($differs & D_PAT_OTH) {
 218         my $mode;
 219         $differs &= ~D_PAT_OTH;
 220         my $pat_oth = sub {
 221             $differs |= D_PAT_OTH;
 222             no warnings qw(exiting);  last;
 223         };
 224         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 225             no warnings qw(exiting);
 226             if (!defined $mode) {
 227                 $mode = $_;  next;
 228             }
 229             die unless s{^debian/patches/}{};
 230             my $ok;
 231             if ($mode eq 'A' && !m/\.series$/s) {
 232                 $ok = 1;
 233             } elsif ($mode eq 'M' && $_ eq 'series') {
 234                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 235                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 236                 chomp $x_s;  $x_s .= "\n";
 237                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 238             } else {
 239                 # nope
 240             }
 241             $mode = undef;
 242             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 243         });
 244         die "mysterious debian/patches changes $x..$y"
 245             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 246     }
 247
 248     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 249
 250     return $differs;
 251 }
 252
 253 sub commit_pr_info ($) {
 254     my ($r) = @_;
 255     return Data::Dumper->dump([$r], [qw(commit)]);
 256 }
 257
 258 sub calculate_committer_authline () {
 259     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 260         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 261     my ($h,$m) = get_commit $c;
 262     $h =~ m/^committer .*$/m or confess "($h) ?";
 263     return $&;
 264 }
 265
 266 sub rm_subdir_cached ($) {
 267     my ($subdir) = @_;
 268     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 269 }
 270
 271 sub read_tree_subdir ($$) {
 272     my ($subdir, $new_tree_object) = @_;
 273     rm_subdir_cached $subdir;
 274     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 275 }
 276
 277 sub read_tree_debian ($) {
 278     my ($treeish) = @_;
 279     read_tree_subdir 'debian', "$treeish:debian";
 280     rm_subdir_cached 'debian/patches';
 281 }
 282
 283 sub read_tree_upstream ($;$$) {
 284     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 285     # if $tree_with_debian is supplied, will use that for debian/
 286     # otherwise will save and restore it.
 287     my $debian =
 288         $tree_with_debian ? "$tree_with_debian:debian"
 289         : cmdoutput @git, qw(write-tree --prefix=debian/);
 290     runcmd @git, qw(read-tree), $treeish;
 291     read_tree_subdir 'debian', $debian;
 292     rm_subdir_cached 'debian/patches' unless $keep_patches;
 293 };
 294
 295 sub make_commit ($$) {
 296     my ($parents, $message_paras) = @_;
 297     my $tree = cmdoutput @git, qw(write-tree);
 298     my @cmd = (@git, qw(commit-tree), $tree);
 299     push @cmd, qw(-p), $_ foreach @$parents;
 300     push @cmd, qw(-m), $_ foreach @$message_paras;
 301     return cmdoutput @cmd;
 302 }
 303
 304 our @snag_force_opts;
 305 sub snag ($$;@) {
 306     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 307     if (grep { $_ eq $tag } @snag_force_opts) {
 308         $snags_forced++;
 309         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 310     } else {
 311         $snags_tripped++;
 312         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 313     }
 314 }
 315
 316 # Important: all mainline code must call snags_maybe_bail after
 317 # any point where snag might be called, but before making changes
 318 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 319 # may be called more than once if necessary (but this is not ideal
 320 # because then the messages about number of snags may be confusing).
 321 sub snags_maybe_bail () {
 322     return if all_snags_summarised();
 323     if ($snags_forced) {
 324         printf STDERR
 325             "%s: snags: %d overriden by individual -f options\n",
 326             $us, $snags_forced;
 327     }
 328     if ($snags_tripped) {
 329         if ($opt_force) {
 330             printf STDERR
 331                 "%s: snags: %d overriden by global --force\n",
 332                 $us, $snags_tripped;
 333         } else {
 334             fail sprintf
 335   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 336                 $us, $snags_tripped;
 337         }
 338     }
 339     $snags_summarised = $snags_forced + $snags_tripped;
 340 }
 341 sub snags_maybe_bail_early () {
 342     # useful to bail out early without doing a lot of work;
 343     # not a substitute for snags_maybe_bail.
 344     snags_maybe_bail() if $snags_tripped && !$opt_force;
 345 }
 346 sub any_snags () {
 347     return $snags_forced || $snags_tripped;
 348 }
 349
 350 sub gbp_pq_export ($$$) {
 351     my ($bname, $base, $tip) = @_;
 352     # must be run in a workarea.  $bname and patch-queue/$bname
 353     # ought not to exist.  Leaves you on patch-queue/$bname with
 354     # the patches staged but not committed.
 355     printdebug "gbp_pq_export $bname $base $tip\n";
 356     runcmd @git, qw(checkout -q -b), $bname, $base;
 357     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 358     my @gbp_cmd = (qw(gbp pq export));
 359     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 360     if ($r) {
 361         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 362         failedcmd @gbp_cmd;
 363     }
 364     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 365 }
 366
 367
 368 # xxx allow merge resolution separately from laundering, before git merge
 369 #
 370 # xxx general gdr docs highlight forbidden things
 371 # xxx general gdr docs list allowable things ?
 372 # xxx general gdr docs explicitly forbid some rebase
 373 #
 374 # xxx provide a way for the user to help
 375 # xxx (eg, provide wreckage provide way to continue)
 376
 377 # later/rework?
 378 #  use git-format-patch?
 379 #  our own patch identification algorithm?
 380 #  this is an alternative strategy
 381
 382 sub merge_failed ($$) {
 383     my ($wrecknotes, $emsg) = @_;
 384     my @m;
 385     push @m, "Merge resolution failed: $emsg";
 386
 387     changedir $maindir;
 388
 389     my @updates;
 390     merge_wreckage_cleaning \@updates;
 391     keys %$wrecknotes;
 392     while (my ($k,$v) = each %$wrecknotes) {
 393         push @updates, "create $wrecknoteprefix/$k $v";
 394     }
 395     run_ref_updates_now "merge failed", \@updates;
 396     push @m, "Wreckage left in $wrecknoteprefix/*.";
 397
 398     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 399     # ^ xxx this section does not yet exist
 400     fail join '', map { "$_\n" } @m;
 401 }
 402
 403 sub mwrecknote ($$$) {
 404     my ($wrecknotes, $reftail, $commitish) = @_;
 405     confess unless defined $commitish;
 406     printdebug "mwrecknote $reftail $commitish\n";
 407     $wrecknotes->{$reftail} = $commitish;
 408 }
 409
 410 sub merge_series ($$$;@) {
 411     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 412     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 413     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 414     # ^ specifies several patch series (currently we only support exactly 2)
 415     # return value is a commit which is the result of
 416     # merging the two versions of the same topic branch
 417     #   $input_q[0] and $input_q[1]
 418     # with respect to the old version
 419     #   $base_q
 420     # all onto $newbase.
 421
 422     # Creates, in *_q, a key MR for its private use
 423
 424     printdebug "merge_series newbase=$newbase\n";
 425
 426     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 427     $base_q->{MR}{S} = 'base';
 428
 429     my %prereq;
 430     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 431     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 432     # $prereq{<patch filename>}               exists or not (even later)
 433
 434     my $result;
 435
 436     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 437
 438     local $workarea = fresh_playground "$playprefix/merge";
 439     my $seriesfile = "debian/patches/series";
 440     in_workarea sub {
 441         playtree_setup();
 442         foreach my $q ($base_q, reverse @input_qs) {
 443             my $s = $q->{MR}{S};
 444             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 445             my @earlier;
 446             if (open S, $seriesfile) {
 447                 while (my $patch = <S>) {
 448                     chomp $patch or die $!;
 449                     $prereq{$patch} //= {};
 450                     foreach my $earlier (@earlier) {
 451                         $prereq{$patch}{$earlier}{$s}++ and die;
 452                     }
 453                     push @earlier, $patch;
 454                     stat "debian/patches/$patch" or die "$patch ?";
 455                 }
 456                 S->error and die "$seriesfile $!";
 457                 close S;
 458             } else {
 459                 die "$seriesfile $!" unless $!==ENOENT;
 460             }
 461             read_tree_upstream $newbase, 1;
 462             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 463                 "Convert $s to patch queue for merging",
 464                 "[git-debrebase merge-innards patch-queue import:".
 465                 " $q->{SeriesTip}]"
 466             ];
 467             printdebug "merge_series  pec $pec ";
 468             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 469             $pec = make_commit [ $pec ], [
 470                 "Drop series file from $s to avoid merge trouble",
 471                 "[git-debrebase merge-innards patch-queue prep:".
 472                 " $q->{SeriesTip}]"
 473             ];
 474
 475             read_tree_debian $newbase;
 476             if (@earlier) {
 477                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 478             } else {
 479                 rm_subdir_cached 'debian/patches';
 480             }
 481             $pec = make_commit [ $pec ], [
 482  "Update debian/ (excluding patches) to final to avoid re-merging",
 483  "debian/ was already merged and we need to just take that.",
 484                 "[git-debrebase merge-innards patch-queue packaging:".
 485                 " $q->{SeriesTip}]"
 486             ];
 487
 488             printdebug "pec' $pec\n";
 489             runcmd @git, qw(reset -q --hard), $pec;
 490             $q->{MR}{PEC} = $pec;
 491             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 492         }
 493         # now, because of reverse, we are on $input_q->{MR}{OQC}
 494         runcmd @git, qw(checkout -q -b merge);
 495         printdebug "merge_series merging...\n";
 496         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 497         debugcmd '+', @mergecmd;
 498         $!=0; $?=-1;
 499         if (system @mergecmd) {
 500             failedcmd @mergecmd;
 501         }
 502
 503         printdebug "merge_series merge ok, series...\n";
 504         # We need to construct a new series file
 505         # Firstly, resolve prereq
 506         foreach my $f (sort keys %prereq) {
 507             printdebug "merge_series  patch\t$f\t";
 508             if (!stat_exists "debian/patches/$f") {
 509                 print DEBUG " drop\n" if $debuglevel;
 510                 # git merge deleted it; that's how we tell it's not wanted
 511                 delete $prereq{$f};
 512                 next;
 513             }
 514             print DEBUG " keep\n" if $debuglevel;
 515             foreach my $g (sort keys %{ $prereq{$f} }) {
 516                 my $gfp = $prereq{$f}{$g};
 517                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 518                 if (!!$gfp->{0} == !!$gfp->{1}
 519                     ? $gfp->{0}
 520                     : !$gfp->{base}) {
 521                     print DEBUG "\tkeep\n" if $debuglevel;
 522                 } else {
 523                     print DEBUG "\tdrop\n" if $debuglevel;
 524                     delete $prereq{$f}{$g};
 525                 }
 526             }
 527         }
 528
 529         my $unsat = sub {
 530             my ($f) = @_;
 531             return scalar keys %{ $prereq{$f} };
 532         };
 533
 534         my $nodate = time + 1;
 535         my %authordate;
 536         # $authordate{<patch filename>};
 537         my $authordate = sub {
 538             my ($f) = @_;
 539             $authordate{$f} //= do {
 540                 open PF, "<", "debian/patches/$f" or die "$f $!";
 541                 while (<PF>) {
 542                     return $nodate if m/^$/;
 543                     last if s{^Date: }{};
 544                 }
 545                 chomp;
 546                 return cmdoutput qw(date +%s -d), $_;
 547             };
 548         };
 549
 550         open NS, '>', $seriesfile or die $!;
 551
 552         while (keys %prereq) {
 553             my $best;
 554             foreach my $try (sort keys %prereq) {
 555                 if ($best) {
 556                     next if (
 557                              $unsat->($try) <=> $unsat->($best) or
 558                              $authordate->($try) <=> $authordate->($best) or
 559                              $try cmp $best
 560                             ) >= 0;
 561                 }
 562                 $best = $try;
 563             }
 564             printdebug "merge_series series next $best\n";
 565             print NS "$best\n" or die $!;
 566             delete $prereq{$best};
 567             foreach my $gp (values %prereq) {
 568                 delete $gp->{$best};
 569             }
 570         }
 571
 572         runcmd @git, qw(add), $seriesfile;
 573         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 574         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
 575
 576         printdebug "merge_series series gbp pq import\n";
 577         runcmd qw(gbp pq import);
 578
 579         # OK now we are on patch-queue/merge, and we need to rebase
 580         # onto the intended parent and drop the patches from each one
 581
 582         printdebug "merge_series series ok, building...\n";
 583         my $build = $newbase;
 584         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 585         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 586             my $commit = git_cat_file $c, 'commit';
 587             printdebug "merge_series series ok, building $c\n";
 588             read_tree_upstream $c, 0, $newbase;
 589             my $tree = cmdoutput @git, qw(write-tree);
 590             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 591             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 592             open C, ">", "../mcommit" or die $!;
 593             print C $commit or die $!;
 594             close C or die $!;
 595             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 596         }
 597         $result = $build;
 598         $mwrecknote->('merged-result', $result);
 599
 600         runcmd @git, qw(update-ref refs/heads/result), $result;
 601
 602         runcmd @git, qw(checkout -q -b debug);
 603         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 604         runcmd @git, qw(add .);
 605         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 606         my $mdebug = git_rev_parse 'HEAD';
 607         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 608         $mwrecknote->('merged-debug', $mdebug);
 609     };
 610     printdebug "merge_series returns $result\n";
 611     return $result;
 612 }
 613
 614 # classify returns an info hash like this
 615 #   CommitId => $objid
 616 #   Hdr => # commit headers, including 1 final newline
 617 #   Msg => # commit message (so one newline is dropped)
 618 #   Tree => $treeobjid
 619 #   Type => (see below)
 620 #   Parents = [ {
 621 #       Ix => $index # ie 0, 1, 2, ...
 622 #       CommitId
 623 #       Differs => return value from get_differs
 624 #       IsOrigin
 625 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 626 #     } ...]
 627 #   NewMsg => # commit message, but with any [dgit import ...] edited
 628 #             # to say "[was: ...]"
 629 #
 630 # Types:
 631 #   Packaging
 632 #   Changelog
 633 #   Upstream
 634 #   AddPatches
 635 #   Mixed
 636 #
 637 #   Pseudomerge
 638 #     has additional entres in classification result
 639 #       Overwritten = [ subset of Parents ]
 640 #       Contributor = $the_remaining_Parent
 641 #
 642 #   DgitImportUnpatched
 643 #     has additional entry in classification result
 644 #       OrigParents = [ subset of Parents ]
 645 #
 646 #   Anchor
 647 #     has additional entry in classification result
 648 #       OrigParents = [ subset of Parents ]  # singleton list
 649 #
 650 #   TreatAsAnchor
 651 #
 652 #   BreakwaterStart
 653 #
 654 #   Unknown
 655 #     has additional entry in classification result
 656 #       Why => "prose"
 657
 658 sub parsecommit ($;$) {
 659     my ($objid, $p_ref) = @_;
 660     # => hash with                   CommitId Hdr Msg Tree Parents
 661     #    Parents entries have only   Ix CommitId
 662     #    $p_ref, if provided, must be [] and is used as a base for Parents
 663
 664     $p_ref //= [];
 665     die if @$p_ref;
 666
 667     my ($h,$m) = get_commit $objid;
 668
 669     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 670     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 671
 672     my $r = {
 673         CommitId => $objid,
 674         Hdr => $h,
 675         Msg => $m,
 676         Tree => $t,
 677         Parents => $p_ref,
 678     };
 679
 680     foreach my $ph (@ph) {
 681         push @$p_ref, {
 682             Ix => scalar @$p_ref,
 683             CommitId => $ph,
 684         };
 685     }
 686
 687     return $r;
 688 }
 689
 690 sub classify ($) {
 691     my ($objid) = @_;
 692
 693     my @p;
 694     my $r = parsecommit($objid, \@p);
 695     my $t = $r->{Tree};
 696
 697     foreach my $p (@p) {
 698         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 699     }
 700
 701     printdebug "classify $objid \$t=$t \@p",
 702         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 703         "\n";
 704
 705     my $classify = sub {
 706         my ($type, @rest) = @_;
 707         $r = { %$r, Type => $type, @rest };
 708         if ($debuglevel) {
 709             printdebug " = $type ".(dd $r)."\n";
 710         }
 711         return $r;
 712     };
 713     my $unknown = sub {
 714         my ($why) = @_;
 715         $r = { %$r, Type => qw(Unknown), Why => $why };
 716         printdebug " ** Unknown\n";
 717         return $r;
 718     };
 719
 720     if (grep { $_ eq $objid } @opt_anchors) {
 721         return $classify->('TreatAsAnchor');
 722     }
 723
 724     my @identical = grep { !$_->{Differs} } @p;
 725     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 726     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 727
 728     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 729         # multi-orig upstreams are represented with an anchor merge
 730         # from a single upstream commit which combines the orig tarballs
 731
 732         # Every anchor tagged this way must be a merge.
 733         # We are relying on the
 734         #     [git-debrebase anchor: ...]
 735         # commit message annotation in "declare" anchor merges (which
 736         # do not have any upstream changes), to distinguish those
 737         # anchor merges from ordinary pseudomerges (which we might
 738         # just try to strip).
 739         #
 740         # However, the user is going to be doing git-rebase a lot.  We
 741         # really don't want them to rewrite an anchor commit.
 742         # git-rebase trips up on merges, so that is a useful safety
 743         # catch.
 744         #
 745         # BreakwaterStart commits are also anchors in the terminology
 746         # of git-debrebase(5), but they are untagged (and always
 747         # manually generated).
 748         #
 749         # We cannot not tolerate any tagged linear commit (ie,
 750         # BreakwaterStart commits tagged `[anchor:') because such a
 751         # thing could result from an erroneous linearising raw git
 752         # rebase of a merge anchor.  That would represent a corruption
 753         # of the branch. and we want to detect and reject the results
 754         # of such corruption before it makes it out anywhere.  If we
 755         # reject it here then we avoid making the pseudomerge which
 756         # would be needed to push it.
 757
 758         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 759         @p == 2 or return $badanchor->("has other than two parents");
 760         $haspatches and return $badanchor->("contains debian/patches");
 761
 762         # How to decide about l/r ordering of anchors ?  git
 763         # --topo-order prefers to expand 2nd parent first.  There's
 764         # already an easy rune to look for debian/ history anyway (git log
 765         # debian/) so debian breakwater branch should be 1st parent; that
 766         # way also there's also an easy rune to look for the upstream
 767         # patches (--topo-order).
 768
 769         # Also this makes --first-parent be slightly more likely to
 770         # be useful - it makes it provide a linearised breakwater history.
 771
 772         # Of course one can say somthing like
 773         #  gitk -- ':/' ':!/debian'
 774         # to get _just_ the commits touching upstream files, and by
 775         # the TREESAME logic in git-rev-list this will leave the
 776         # breakwater into upstream at the first anchor.  But that
 777         # doesn't report debian/ changes at all.
 778
 779         # Other observations about gitk: by default, gitk seems to
 780         # produce output in a different order to git-rev-list.  I
 781         # can't seem to find this documented anywhere.  gitk
 782         # --date-order DTRT.  But, gitk always seems to put the
 783         # parents from left to right, in order, so it's easy to see
 784         # which way round a pseudomerge is.
 785
 786         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 787         $p[1]{Differs} & ~DS_DEB and
 788             $badanchor->("upstream files differ from left parent");
 789         $p[0]{Differs} & ~D_UPS and
 790             $badanchor->("debian/ differs from right parent");
 791
 792         return $classify->(qw(Anchor),
 793                            OrigParents => [ $p[1] ]);
 794     }
 795
 796     if (@p == 1) {
 797         my $d = $r->{Parents}[0]{Differs};
 798         if ($d == D_PAT_ADD) {
 799             return $classify->(qw(AddPatches));
 800         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 801             return $unknown->("edits debian/patches");
 802         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 803             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 804             if ($ty eq 'tree') {
 805                 if ($d == D_DEB_CLOG) {
 806                     return $classify->(qw(Changelog));
 807                 } else {
 808                     return $classify->(qw(Packaging));
 809                 }
 810             } elsif ($ty eq 'missing') {
 811                 return $classify->(qw(BreakwaterStart));
 812             } else {
 813                 return $unknown->("parent's debian is not a directory");
 814             }
 815         } elsif ($d == D_UPS) {
 816             return $classify->(qw(Upstream));
 817         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 818             return $classify->(qw(Mixed));
 819         } elsif ($d == 0) {
 820             return $unknown->("no changes");
 821         } else {
 822             confess "internal error $objid ?";
 823         }
 824     }
 825     if (!@p) {
 826         return $unknown->("origin commit");
 827     }
 828
 829     if (@p == 2 && @identical == 1) {
 830         my @overwritten = grep { $_->{Differs} } @p;
 831         confess "internal error $objid ?" unless @overwritten==1;
 832         return $classify->(qw(Pseudomerge),
 833                            Overwritten => [ $overwritten[0] ],
 834                            Contributor => $identical[0]);
 835     }
 836     if (@p == 2 && @identical == 2) {
 837         my $get_t = sub {
 838             my ($ph,$pm) = get_commit $_[0]{CommitId};
 839             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 840             $1;
 841         };
 842         my @bytime = @p;
 843         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 844         if ($order > 0) { # newer first
 845         } elsif ($order < 0) {
 846             @bytime = reverse @bytime;
 847         } else {
 848             # same age, default to order made by -s ours
 849             # that is, commit was made by someone who preferred L
 850         }
 851         return $classify->(qw(Pseudomerge),
 852                            SubType => qw(Ambiguous),
 853                            Contributor => $bytime[0],
 854                            Overwritten => [ $bytime[1] ]);
 855     }
 856     foreach my $p (@p) {
 857         my ($p_h, $p_m) = get_commit $p->{CommitId};
 858         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 859         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 860     }
 861     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 862     my $m2 = $r->{Msg};
 863     if (!(grep { !$_->{IsOrigin} } @p) and
 864         (@orig_ps >= @p - 1) and
 865         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 866         $r->{NewMsg} = $m2;
 867         return $classify->(qw(DgitImportUnpatched),
 868                            OrigParents => \@orig_ps);
 869     }
 870
 871     if (@p == 2 and
 872         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 873         # xxx ^ metadata tag needs adding to (5)
 874         return $classify->("MergedBreakwaters");
 875     }
 876     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 877         return $unknown->("unknown kind of merge from $1");
 878     }
 879     if (@p > 2) {
 880         return $unknown->("octopus merge");
 881     }
 882
 883     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 884         return $unknown->("general two-parent merge");
 885     }
 886
 887     return $classify->("VanillaMerge");
 888 }
 889
 890 sub keycommits ($;$$$$$);
 891
 892 sub mergedbreakwaters_anchor ($) {
 893     my ($cl) = @_;
 894     my $best_anchor;
 895     foreach my $p (@{ $cl->{Parents} }) {
 896         my ($panchor, $pbw) = keycommits $p->{CommitId},
 897             undef,undef,undef,undef, 1;
 898         $best_anchor = $panchor
 899             if !defined $best_anchor
 900             or is_fast_fwd $best_anchor, $panchor;
 901         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 902             unless is_fast_fwd $panchor, $best_anchor;
 903     }
 904     return $best_anchor;
 905 }
 906
 907 sub keycommits ($;$$$$$) {
 908     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 909     # => ($anchor, $breakwater)
 910
 911     # $unclean->("unclean-$tagsfx", $msg, $cl)
 912     # $furniture->("unclean-$tagsfx", $msg, $cl)
 913     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 914     #   is callled for each situation or commit that
 915     #   wouldn't be found in a laundered branch
 916     # $furniture is for furniture commits such as might be found on an
 917     #   interchange branch (pseudomerge, d/patches, changelog)
 918     # $trouble is for things whnich prevent the return of
 919     #   anchor and breakwater information; if that is ignored,
 920     #   then keycommits returns (undef, undef) instead.
 921     # $fatal is for unprocessable commits, and should normally cause
 922     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 923     #
 924     # If $claimed_bw, this is supposed to be a breakwater commit.
 925     #
 926     # If a callback is undef, fail is called instead.
 927     # If a callback is defined but false, the situation is ignored.
 928     # Callbacks may say:
 929     #   no warnings qw(exiting); last;
 930     # if the answer is no longer wanted.
 931
 932     my ($anchor, $breakwater);
 933     $breakwater = $head if $claimed_bw;
 934     my $clogonly;
 935     my $cl;
 936     my $found_pm;
 937     $fatal //= sub { fail $_[1]; };
 938     my $x = sub {
 939         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 940         my $why = $mainwhy.$xwhy;
 941         my $m = "branch needs laundering (run git-debrebase): $why";
 942         fail $m unless defined $cb;
 943         return unless $cb;
 944         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 945     };
 946     my $found_anchor = sub {
 947         ($anchor) = @_;
 948         $breakwater //= $clogonly;
 949         $breakwater //= $head;
 950         no warnings qw(exiting);
 951         last;
 952     };
 953     for (;;) {
 954         $cl = classify $head;
 955         my $ty = $cl->{Type};
 956         if ($ty eq 'Packaging') {
 957             $breakwater //= $clogonly;
 958             $breakwater //= $head;
 959         } elsif ($ty eq 'Changelog') {
 960             # this is going to count as the tip of the breakwater
 961             # only if it has no upstream stuff before it
 962             $clogonly //= $head;
 963         } elsif ($ty eq 'Anchor' or
 964                  $ty eq 'TreatAsAnchor' or
 965                  $ty eq 'BreakwaterStart') {
 966             $found_anchor->($head);
 967         } elsif ($ty eq 'Upstream') {
 968             $x->($unclean, 'ordering',
 969  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 970                 if defined $breakwater;
 971             $clogonly = undef;
 972             $breakwater = undef;
 973         } elsif ($ty eq 'Mixed') {
 974             $x->($unclean, 'mixed',
 975                  "found mixed upstream/packaging commit"," ($head)");
 976             $clogonly = undef;
 977             $breakwater = undef;
 978         } elsif ($ty eq 'Pseudomerge' or
 979                  $ty eq 'AddPatches') {
 980             my $found_pm = 1;
 981             $x->($furniture, (lc $ty),
 982                  "found interchange bureaucracy commit ($ty)"," ($head)");
 983         } elsif ($ty eq 'DgitImportUnpatched') {
 984             if ($found_pm) {
 985                 $x->($trouble, 'dgitimport',
 986                      "found dgit dsc import"," ($head)");
 987                 return (undef,undef);
 988             } else {
 989                 $x->($fatal, 'unprocessable',
 990                      "found bare dgit dsc import with no prior history",
 991                      " ($head)");
 992                 return (undef,undef);
 993             }
 994         } elsif ($ty eq 'VanillaMerge') {
 995             $x->($trouble, 'vanillamerge',
 996                  "found vanilla merge"," ($head)");
 997             return (undef,undef);
 998         } elsif ($ty eq 'MergedBreakwaters') {
 999             $found_anchor->(mergedbreakwaters_anchor $cl);
1000         } else {
1001             $x->($fatal, 'unprocessable',
1002                  "found unprocessable commit, cannot cope: $cl->{Why}",
1003                  " ($head)");
1004             return (undef,undef);
1005         }
1006         $head = $cl->{Parents}[0]{CommitId};
1007     }
1008     return ($anchor, $breakwater);
1009 }
1010
1011 sub walk ($;$$$);
1012 sub walk ($;$$$) {
1013     my ($input,
1014         $nogenerate,$report, $report_lprefix) = @_;
1015     # => ($tip, $breakwater_tip, $last_anchor)
1016     # (or nothing, if $nogenerate)
1017
1018     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1019     $report_lprefix //= '';
1020
1021     # go through commits backwards
1022     # we generate two lists of commits to apply:
1023     # breakwater branch and upstream patches
1024     my (@brw_cl, @upp_cl, @processed);
1025     my %found;
1026     my $upp_limit;
1027     my @pseudomerges;
1028
1029     my $cl;
1030     my $xmsg = sub {
1031         my ($prose, $info) = @_;
1032         my $ms = $cl->{Msg};
1033         chomp $ms;
1034         $info //= '';
1035         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1036         return (Msg => $ms);
1037     };
1038     my $rewrite_from_here = sub {
1039         my ($cl) = @_;
1040         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1041         push @$cl, $sp_cl;
1042         push @processed, $sp_cl;
1043     };
1044     my $cur = $input;
1045
1046     my $prdelim = "";
1047     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1048
1049     my $prline = sub {
1050         return unless $report;
1051         print $report $prdelim, $report_lprefix, @_;
1052         $prdelim = "\n";
1053     };
1054
1055     my $bomb = sub { # usage: return $bomb->();
1056         print $report " Unprocessable" if $report;
1057         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1058         $prprdelim->();
1059         if ($nogenerate) {
1060             return (undef,undef);
1061         }
1062         fail "found unprocessable commit, cannot cope".
1063             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1064             " (commit $cur) (d.".
1065             (join ' ', map { sprintf "%#x", $_->{Differs} }
1066              @{ $cl->{Parents} }).
1067                  ")";
1068     };
1069
1070     my $build;
1071     my $breakwater;
1072
1073     my $build_start = sub {
1074         my ($msg, $parent) = @_;
1075         $prline->(" $msg");
1076         $build = $parent;
1077         no warnings qw(exiting); last;
1078     };
1079
1080     my $nomerge = sub {
1081         my ($emsg) = @_;
1082         merge_failed $cl->{MergeWreckNotes}, $emsg;
1083     };
1084
1085     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1086
1087     my $last_anchor;
1088
1089     for (;;) {
1090         $cl = classify $cur;
1091         $cl->{MergeWreckNotes} //= {};
1092         my $ty = $cl->{Type};
1093         my $st = $cl->{SubType};
1094         $prline->("$cl->{CommitId} $cl->{Type}");
1095         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1096         push @processed, $cl;
1097         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1098         if ($ty eq 'AddPatches') {
1099             $cur = $p0;
1100             $rewrite_from_here->(\@upp_cl);
1101             next;
1102         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1103             push @brw_cl, $cl;
1104             $cur = $p0;
1105             next;
1106         } elsif ($ty eq 'BreakwaterStart') {
1107             $last_anchor = $cur;
1108             $build_start->('FirstPackaging', $cur);
1109         } elsif ($ty eq 'Upstream') {
1110             push @upp_cl, $cl;
1111             $cur = $p0;
1112             next;
1113         } elsif ($ty eq 'Mixed') {
1114             my $queue = sub {
1115                 my ($q, $wh) = @_;
1116                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1117                 push @$q, $cls;
1118             };
1119             $queue->(\@brw_cl, "debian");
1120             $queue->(\@upp_cl, "upstream");
1121             $rewrite_from_here->(\@brw_cl);
1122             $cur = $p0;
1123             next;
1124         } elsif ($ty eq 'Pseudomerge') {
1125             my $contrib = $cl->{Contributor}{CommitId};
1126             print $report " Contributor=$contrib" if $report;
1127             push @pseudomerges, $cl;
1128             $rewrite_from_here->(\@upp_cl);
1129             $cur = $contrib;
1130             next;
1131         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1132             $last_anchor = $cur;
1133             $build_start->("Anchor", $cur);
1134         } elsif ($ty eq 'DgitImportUnpatched') {
1135             my $pm = $pseudomerges[-1];
1136             if (defined $pm) {
1137                 # To an extent, this is heuristic.  Imports don't have
1138                 # a useful history of the debian/ branch.  We assume
1139                 # that the first pseudomerge after an import has a
1140                 # useful history of debian/, and ignore the histories
1141                 # from later pseudomerges.  Often the first pseudomerge
1142                 # will be the dgit import of the upload to the actual
1143                 # suite intended by the non-dgit NMUer, and later
1144                 # pseudomerges may represent in-archive copies.
1145                 my $ovwrs = $pm->{Overwritten};
1146                 printf $report " PM=%s \@Overwr:%d",
1147                     $pm->{CommitId}, (scalar @$ovwrs)
1148                     if $report;
1149                 if (@$ovwrs != 1) {
1150                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1151                     return $bomb->();
1152                 }
1153                 my $ovwr = $ovwrs->[0]{CommitId};
1154                 printf $report " Overwr=%s", $ovwr if $report;
1155                 # This import has a tree which is just like a
1156                 # breakwater tree, but it has the wrong history.  It
1157                 # ought to have the previous breakwater (which the
1158                 # pseudomerge overwrote) as an ancestor.  That will
1159                 # make the history of the debian/ files correct.  As
1160                 # for the upstream version: either it's the same as
1161                 # was ovewritten (ie, same as the previous
1162                 # breakwater), in which case that history is precisely
1163                 # right; or, otherwise, it was a non-gitish upload of a
1164                 # new upstream version.  We can tell these apart by
1165                 # looking at the tree of the supposed upstream.
1166                 push @brw_cl, {
1167                     %$cl,
1168                     SpecialMethod => 'DgitImportDebianUpdate',
1169                     $xmsg->("convert dgit import: debian changes")
1170                 }, {
1171                     %$cl,
1172                     SpecialMethod => 'DgitImportUpstreamUpdate',
1173                     $xmsg->("convert dgit import: upstream update",
1174                             " anchor")
1175                 };
1176                 $prline->(" Import");
1177                 $rewrite_from_here->(\@brw_cl);
1178                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1179                 $cur = $ovwr;
1180                 next;
1181             } else {
1182                 # Everything is from this import.  This kind of import
1183                 # is already nearly in valid breakwater format, with the
1184                 # patches as commits.  Unfortunately it contains
1185                 # debian/patches/.
1186                 printdebug "*** WALK BOMB bare dgit import\n";
1187                 $cl->{Why} = "bare dgit dsc import";
1188                 return $bomb->();
1189             }
1190             die "$ty ?";
1191         } elsif ($ty eq 'MergedBreakwaters') {
1192             $last_anchor = mergedbreakwaters_anchor $cl;
1193             $build_start->(' MergedBreakwaters', $cur);
1194             last;
1195         } elsif ($ty eq 'VanillaMerge') {
1196             # User may have merged unstitched branch(es).  We will
1197             # have now lost what ffq-prev was then (since the later
1198             # pseudomerge may introduce further changes).  The effect
1199             # of resolving such a merge is that we may have to go back
1200             # further in history to find a merge base, since the one
1201             # which was reachable via ffq-prev is no longer findable.
1202             # This is suboptimal, but if it all works we'll have done
1203             # the right thing.
1204             # xxx we should warn the user in the docs about this
1205
1206             my $ok=1;
1207             my $best_anchor;
1208             # We expect to find a dominating anchor amongst the
1209             # inputs' anchors.  That will be the new anchor.
1210             #
1211             # More complicated is finding a merge base for the
1212             # breakwaters.  We need a merge base that is a breakwater
1213             # commit.  The ancestors of breakwater commits are more
1214             # breakwater commits and possibly upstream commits and the
1215             # ancestors of those upstream.  Upstreams might have
1216             # arbitrary ancestors.  But any upstream commit U is
1217             # either included in both anchors, in which case the
1218             # earlier anchor is a better merge base than any of U's
1219             # ancestors; or U is not included in the older anchor, in
1220             # which case U is not an ancestor of the vanilla merge at
1221             # all.  So no upstream commit, nor any ancestor thereof,
1222             # is a best merge base.  As for non-breakwater Debian
1223             # commits: these are never ancestors of any breakwater.
1224             #
1225             # So any best merge base as found by git-merge-base
1226             # is a suitable breakwater anchor.  Usually there will
1227             # be only one.
1228
1229             printdebug "*** MERGE\n";
1230
1231             my @bwbcmd = (@git, qw(merge-base));
1232             my @ibcmd = (@git, qw(merge-base --all));
1233             my $might_be_in_bw = 1;
1234
1235             my $ps = $cl->{Parents};
1236
1237             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1238
1239             foreach my $p (@$ps) {
1240                 $prline->(" VanillaMerge ".$p->{Ix});
1241                 $prprdelim->();
1242                 my ($ptip, $pbw, $panchor) =
1243                     walk $p->{CommitId}, 0, $report,
1244                          $report_lprefix.'  ';
1245                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1246                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1247                 $p->{Anchor} = $panchor;
1248
1249                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1250                 $mwrecknote->("$lr-input", $p->{CommitId});
1251
1252                 my $mwrecknote_parent = sub {
1253                     my ($which) = @_;
1254                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1255                 };
1256                 $mwrecknote_parent->('Laundered');
1257                 $mwrecknote_parent->('Breakwater');
1258                 $mwrecknote_parent->('Anchor');
1259
1260                 $best_anchor = $panchor if
1261                     !defined $best_anchor or
1262                     is_fast_fwd $best_anchor, $panchor;
1263
1264                 printdebug " MERGE BA best=".($best_anchor//'-').
1265                     " p=$panchor\n";
1266             }
1267
1268             $mwrecknote->('result-anchor', $best_anchor);
1269
1270             foreach my $p (@$ps) {
1271                 $prline->(" VanillaMerge ".$p->{Ix});
1272                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1273                     $nomerge->('divergent anchors');
1274                 } elsif ($p->{Anchor} eq $best_anchor) {
1275                     print $report " SameAnchor" if $report;
1276                 } else {
1277                     print $report " SupersededAnchor" if $report;
1278                 }
1279                 if ($p->{Breakwater} eq $p->{CommitId}) {
1280                     # this parent commit was its own breakwater,
1281                     # ie it is part of the breakwater
1282                     print $report " Breakwater" if $report;
1283                 } else {
1284                     $might_be_in_bw = 0;
1285                 }
1286                 push @bwbcmd, $p->{Breakwater};
1287                 push @ibcmd, $p->{CommitId};
1288             }
1289
1290             if ($ok && $might_be_in_bw) {
1291                 # We could rewrite this to contaion the metadata
1292                 # declaring it to be MergedBreakwaters, but
1293                 # unnecessarily rewriting a merge seems unhelpful.
1294                 $prline->(" VanillaMerge MergedBreakwaters");
1295                 $last_anchor = $best_anchor;
1296                 $build_start->('MergedBreakwaters', $cur);
1297             }
1298
1299             my $bwb = cmdoutput @bwbcmd;
1300
1301             # OK, now we have a breakwater base, but we need the merge
1302             # base for the interchange branch because we need the delta
1303             # queue.
1304             #
1305             # This a the best merge base of our inputs which has the
1306             # breakwater merge base as an ancestor.
1307
1308             my @ibs =
1309                 grep /./,
1310                 split /\n/,
1311                 cmdoutput @ibcmd;
1312
1313             @ibs or confess 'internal error, expected anchor at least ?';
1314
1315             my $ib;
1316             my $ibleaf;
1317             foreach my $tibix (0..$#ibs) {
1318                 my $tib = $ibs[$tibix];
1319                 my $ff = is_fast_fwd $bwb, $tib;
1320                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1321                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1322                 $mwrecknote->($tibleaf, $tib);
1323                 next unless $ff;
1324                 next if $ib;
1325                 $ib = $tib;
1326                 $ibleaf = $tibleaf;
1327             }
1328
1329             $ib or $nomerge->("no suitable interchange merge base");
1330
1331             $prline->("  VanillaMerge Base");
1332             $prprdelim->();
1333             my ($btip, $bbw, $banchor) = eval {
1334                 walk $ib, 0, $report, $report_lprefix.'  ';
1335             };
1336             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1337                        $@) if length $@;
1338
1339             $mwrecknote->("mergebase-laundered", $btip);
1340             $mwrecknote->("mergebase-breakwater", $bbw);
1341             $mwrecknote->("mergebase-anchor", $banchor);
1342
1343             my $ibinfo = { SeriesTip => $btip,
1344                            SeriesBase => $bbw,
1345                            Anchor => $banchor,
1346                            LeftRight => 'mergebase' };
1347
1348             $bbw eq $bwb
1349                 or $nomerge->("interchange merge-base ($ib)'s".
1350                               " breakwater ($bbw)".
1351                               " != breakwaters' merge-base ($bwb)");
1352
1353             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1354                  or $nomerge->("interchange merge-base ($ib)'s".
1355                                " anchor ($ibinfo->{SeriesBase})".
1356                                " != any merge input's anchor (".
1357                                (join ' ', map { $_->{Anchor} } @$ps).
1358                                ")");
1359
1360             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1361             $cl->{MergeBestAnchor} = $best_anchor;
1362             push @brw_cl, {
1363                 %$cl,
1364                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1365                 $xmsg->('constructed from vanilla merge',
1366                         ' merged-breakwater'),
1367             };
1368             push @upp_cl, {
1369                 %$cl,
1370                 SpecialMethod => 'MergeMergeSeries',
1371             };
1372             $build_start->('MergeBreakwaters', $cur);
1373         } else {
1374             printdebug "*** WALK BOMB unrecognised\n";
1375             return $bomb->();
1376         }
1377     }
1378     $prprdelim->();
1379
1380     printdebug "*** WALK prep done cur=$cur".
1381         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1382
1383     return if $nogenerate;
1384
1385     # Now we build it back up again
1386
1387     fresh_workarea();
1388
1389     my $rewriting = 0;
1390
1391     my $read_tree_upstream = sub {
1392         my ($treeish) = @_;
1393         read_tree_upstream $treeish, 0, $build;
1394     };
1395
1396     $#upp_cl = $upp_limit if defined $upp_limit;
1397
1398     my $committer_authline = calculate_committer_authline();
1399
1400     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1401
1402     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1403
1404     in_workarea sub {
1405         mkdir $rd or $!==EEXIST or die $!;
1406         my $current_method;
1407         runcmd @git, qw(read-tree), $build;
1408         foreach my $cl (qw(Debian), (reverse @brw_cl),
1409                         { SpecialMethod => 'RecordBreakwaterTip' },
1410                         qw(Upstream), (reverse @upp_cl)) {
1411             if (!ref $cl) {
1412                 $current_method = $cl;
1413                 next;
1414             }
1415             my $method = $cl->{SpecialMethod} // $current_method;
1416             my @parents = ($build);
1417             my $cltree = $cl->{CommitId};
1418             printdebug "WALK BUILD ".($cltree//'undef').
1419                 " $method (rewriting=$rewriting)\n";
1420             if ($method eq 'Debian') {
1421                 read_tree_debian($cltree);
1422             } elsif ($method eq 'Upstream') {
1423                 $read_tree_upstream->($cltree);
1424             } elsif ($method eq 'StartRewrite') {
1425                 $rewriting = 1;
1426                 next;
1427             } elsif ($method eq 'RecordBreakwaterTip') {
1428                 $breakwater = $build;
1429                 next;
1430             } elsif ($method eq 'DgitImportDebianUpdate') {
1431                 read_tree_debian($cltree);
1432             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1433                 confess unless $rewriting;
1434                 my $differs = (get_differs $build, $cltree);
1435                 next unless $differs & D_UPS;
1436                 $read_tree_upstream->($cltree);
1437                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1438             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1439                 print "Found a general merge, will try to tidy it up.\n";
1440                 $rewriting = 1;
1441                 $read_tree_upstream->($cl->{MergeBestAnchor});
1442                 $read_tree_upstream->($cl->{MergeBestAnchor});
1443                 read_tree_debian($cltree);
1444                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1445             } elsif ($method eq 'MergeMergeSeries') {
1446                 print "Running merge resolution for $cl->{CommitId}...\n";
1447                 $build = merge_series
1448                     $build, $cl->{MergeWreckNotes},
1449                     $cl->{MergeInterchangeBaseInfo},
1450                     @{ $cl->{Parents} };
1451                 $last_anchor = $cl->{MergeBestAnchor};
1452
1453                 # Check for mismerges:
1454                 my $check = sub {
1455                     my ($against, $allow, $what) = @_;
1456                     my $differs = get_differs $build, $against;
1457                     $nomerge->(sprintf
1458        "merge misresolved: %s are not the same (%s %s d.%#x)",
1459                                $what, $against, $build, $differs)
1460                         if $differs & ~($allow | D_PAT_ADD);
1461                 };
1462
1463                 # Breakwater changes which were in each side of the
1464                 # merge will have been incorporated into the
1465                 # MergeCreateMergedBreakwaters output.  Because the
1466                 # upstream series was rebased onto the new breakwater,
1467                 # so should all of the packaging changes which were in
1468                 # the input.
1469                 $check->($input, D_UPS, 'debian files');
1470
1471                 # Upstream files are merge_series, which ought to
1472                 # have been identical to the original merge.
1473                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1474
1475                 print "Merge resolution successful.\n";
1476                 next;
1477             } else {
1478                 confess "$method ?";
1479             }
1480             if (!$rewriting) {
1481                 my $procd = (pop @processed) // 'UNDEF';
1482                 if ($cl ne $procd) {
1483                     $rewriting = 1;
1484                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1485                 }
1486             }
1487             my $newtree = cmdoutput @git, qw(write-tree);
1488             my $ch = $cl->{Hdr};
1489             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1490             $ch =~ s{^parent .*\n}{}mg;
1491             $ch =~ s{(?=^author)}{
1492                 join '', map { "parent $_\n" } @parents
1493             }me or confess "$ch ?";
1494             if ($rewriting) {
1495                 $ch =~ s{^committer .*$}{$committer_authline}m
1496                     or confess "$ch ?";
1497             }
1498             my $cf = "$rd/m$rewriting";
1499             open CD, ">", $cf or die $!;
1500             print CD $ch, "\n", $cl->{Msg} or die $!;
1501             close CD or die $!;
1502             my @cmd = (@git, qw(hash-object));
1503             push @cmd, qw(-w) if $rewriting;
1504             push @cmd, qw(-t commit), $cf;
1505             my $newcommit = cmdoutput @cmd;
1506             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1507             $build = $newcommit;
1508             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1509                 $last_anchor = $cur;
1510             }
1511         }
1512     };
1513
1514     my $final_check = get_differs $build, $input;
1515     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1516         if $final_check & ~D_PAT_ADD;
1517
1518     my @r = ($build, $breakwater, $last_anchor);
1519     printdebug "*** WALK RETURN @r\n";
1520     return @r
1521 }
1522
1523 sub get_head () {
1524     git_check_unmodified();
1525     return git_rev_parse qw(HEAD);
1526 }
1527
1528 sub update_head ($$$) {
1529     my ($old, $new, $mrest) = @_;
1530     push @deferred_updates, "update HEAD $new $old";
1531     run_deferred_updates $mrest;
1532 }
1533
1534 sub update_head_checkout ($$$) {
1535     my ($old, $new, $mrest) = @_;
1536     update_head $old, $new, $mrest;
1537     runcmd @git, qw(reset --hard);
1538 }
1539
1540 sub update_head_postlaunder ($$$) {
1541     my ($old, $tip, $reflogmsg) = @_;
1542     return if $tip eq $old;
1543     print "git-debrebase: laundered (head was $old)\n";
1544     update_head $old, $tip, $reflogmsg;
1545     # no tree changes except debian/patches
1546     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1547 }
1548
1549 sub currently_rebasing() {
1550     foreach (qw(rebase-merge rebase-apply)) {
1551         return 1 if stat_exists "$maindir_gitdir/$_";
1552     }
1553     return 0;
1554 }
1555
1556 sub bail_if_rebasing() {
1557     fail "you are in the middle of a git-rebase already"
1558         if currently_rebasing();
1559 }
1560
1561 sub do_launder_head ($) {
1562     my ($reflogmsg) = @_;
1563     my $old = get_head();
1564     record_ffq_auto();
1565     my ($tip,$breakwater) = walk $old;
1566     snags_maybe_bail();
1567     update_head_postlaunder $old, $tip, $reflogmsg;
1568     return ($tip,$breakwater);
1569 }
1570
1571 sub cmd_launder_v0 () {
1572     badusage "no arguments to launder-v0 allowed" if @ARGV;
1573     my $old = get_head();
1574     my ($tip,$breakwater,$last_anchor) = walk $old;
1575     update_head_postlaunder $old, $tip, 'launder';
1576     printf "# breakwater tip\n%s\n", $breakwater;
1577     printf "# working tip\n%s\n", $tip;
1578     printf "# last anchor\n%s\n", $last_anchor;
1579 }
1580
1581 sub defaultcmd_rebase () {
1582     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1583     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1584     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1585 }
1586
1587 sub cmd_analyse () {
1588     badusage "analyse does not support any options"
1589         if @ARGV and $ARGV[0] =~ m/^-/;
1590     badusage "too many arguments to analyse" if @ARGV>1;
1591     my ($old) = @ARGV;
1592     if (defined $old) {
1593         $old = git_rev_parse $old;
1594     } else {
1595         $old = git_rev_parse 'HEAD';
1596     }
1597     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1598     STDOUT->error and die $!;
1599 }
1600
1601 sub ffq_prev_branchinfo () {
1602     my $current = git_get_symref();
1603     return gdr_ffq_prev_branchinfo($current);
1604 }
1605
1606 sub ffq_check ($;$$) {
1607     # calls $ff and/or $notff zero or more times
1608     # then returns either (status,message) where status is
1609     #    exists
1610     #    detached
1611     #    weird-symref
1612     #    notbranch
1613     # or (undef,undef, $ffq_prev,$gdrlast)
1614     # $ff and $notff are called like this:
1615     #   $ff->("message for stdout\n");
1616     #   $notff->('snag-name', $message);
1617     # normally $currentval should be HEAD
1618     my ($currentval, $ff, $notff) =@_;
1619
1620     $ff //= sub { print $_[0] or die $!; };
1621     $notff //= \&snag;
1622
1623     my ($status, $message, $current, $ffq_prev, $gdrlast)
1624         = ffq_prev_branchinfo();
1625     return ($status, $message) unless $status eq 'branch';
1626
1627     my $exists = git_get_ref $ffq_prev;
1628     return ('exists',"$ffq_prev already exists") if $exists;
1629
1630     return ('not-branch', 'HEAD symref is not to refs/heads/')
1631         unless $current =~ m{^refs/heads/};
1632     my $branch = $';
1633
1634     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1635     my %checked;
1636
1637     printdebug "ffq check_specs @check_specs\n";
1638
1639     my $check = sub {
1640         my ($lrref, $desc) = @_;
1641         printdebug "ffq might check $lrref ($desc)\n";
1642         my $invert;
1643         for my $chk (@check_specs) {
1644             my $glob = $chk;
1645             $invert = $glob =~ s{^[!^]}{};
1646             last if fnmatch $glob, $lrref;
1647         }
1648         return if $invert;
1649         my $lrval = git_get_ref $lrref;
1650         return unless length $lrval;
1651
1652         if (is_fast_fwd $lrval, $currentval) {
1653             $ff->("OK, you are ahead of $lrref\n");
1654             $checked{$lrref} = 1;
1655         } elsif (is_fast_fwd $currentval, $lrval) {
1656             $checked{$lrref} = -1;
1657             $notff->('behind', "you are behind $lrref, divergence risk");
1658         } else {
1659             $checked{$lrref} = -1;
1660             $notff->('diverged', "you have diverged from $lrref");
1661         }
1662     };
1663
1664     my $merge = cfg "branch.$branch.merge",1;
1665     if (defined $merge and $merge =~ m{^refs/heads/}) {
1666         my $rhs = $';
1667         printdebug "ffq merge $rhs\n";
1668         my $check_remote = sub {
1669             my ($remote, $desc) = @_;
1670             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1671             return unless defined $remote;
1672             $check->("refs/remotes/$remote/$rhs", $desc);
1673         };
1674         $check_remote->((scalar cfg "branch.$branch.remote",1),
1675                         'remote fetch/merge branch');
1676         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1677                         (scalar cfg "branch.$branch.pushDefault",1),
1678                         'remote push branch');
1679     }
1680     if ($branch =~ m{^dgit/}) {
1681         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1682     } elsif ($branch =~ m{^master$}) {
1683         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1684     }
1685     return (undef, undef, $ffq_prev, $gdrlast);
1686 }
1687
1688 sub record_ffq_prev_deferred () {
1689     # => ('status', "message")
1690     # 'status' may be
1691     #    deferred          message is undef
1692     #    exists
1693     #    detached
1694     #    weird-symref
1695     #    notbranch
1696     # if not ff from some branch we should be ff from, is an snag
1697     # if "deferred", will have added something about that to
1698     #   @deferred_update_messages, and also maybe printed (already)
1699     #   some messages about ff checks
1700     bail_if_rebasing();
1701     my $currentval = get_head();
1702
1703     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1704     return ($status,$message) if defined $status;
1705
1706     snags_maybe_bail();
1707
1708     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1709     push @deferred_updates, "delete $gdrlast";
1710     push @deferred_update_messages, "Recorded previous head for preservation";
1711     return ('deferred', undef);
1712 }
1713
1714 sub record_ffq_auto () {
1715     my ($status, $message) = record_ffq_prev_deferred();
1716     if ($status eq 'deferred' || $status eq 'exists') {
1717     } else {
1718         snag $status, "could not record ffq-prev: $message";
1719         snags_maybe_bail();
1720     }
1721 }
1722
1723 sub ffq_prev_info () {
1724     bail_if_rebasing();
1725     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1726     my ($status, $message, $current, $ffq_prev, $gdrlast)
1727         = ffq_prev_branchinfo();
1728     if ($status ne 'branch') {
1729         snag $status, "could not check ffq-prev: $message";
1730         snags_maybe_bail();
1731     }
1732     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1733     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1734 }
1735
1736 sub stitch ($$$$$) {
1737     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1738
1739     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1740
1741     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1742         my $differs = get_differs $old_head, $ffq_prev_commitish;
1743         unless ($differs & ~D_PAT_ADD) {
1744             # ffq-prev is ahead of us, and the only tree changes it has
1745             # are possibly addition of things in debian/patches/.
1746             # Just wind forwards rather than making a pointless pseudomerge.
1747             push @deferred_updates,
1748                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1749             update_head_checkout $old_head, $ffq_prev_commitish,
1750                 "stitch (fast forward)";
1751             return;
1752         }
1753     }
1754     fresh_workarea();
1755     # We make pseudomerges with L as the contributing parent.
1756     # This makes git rev-list --first-parent work properly.
1757     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1758         'Declare fast forward / record previous work',
1759         "[git-debrebase pseudomerge: $prose]",
1760     ];
1761     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1762     update_head $old_head, $new_head, "stitch: $prose";
1763 }
1764
1765 sub do_stitch ($;$) {
1766     my ($prose, $unclean) = @_;
1767
1768     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1769     if (!$ffq_prev_commitish) {
1770         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1771         return;
1772     }
1773     my $dangling_head = get_head();
1774
1775     keycommits $dangling_head, $unclean,$unclean,$unclean;
1776     snags_maybe_bail();
1777
1778     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1779 }
1780
1781 sub upstream_commitish_search ($$) {
1782     my ($upstream_version, $tried) = @_;
1783     # todo: at some point maybe use git-deborig to do this
1784     foreach my $tagpfx ('', 'v', 'upstream/') {
1785         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1786         my $new_upstream = git_get_ref "refs/tags/$tag";
1787         push @$tried, $tag;
1788         return $new_upstream if length $new_upstream;
1789     }
1790 }
1791
1792 sub resolve_upstream_version ($$) {
1793     my ($new_upstream, $upstream_version) = @_;
1794
1795     if (!defined $new_upstream) {
1796         my @tried;
1797         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1798         if (!length $new_upstream) {
1799             fail "Could not determine appropriate upstream commitish.\n".
1800                 " (Tried these tags: @tried)\n".
1801                 " Check version, and specify upstream commitish explicitly.";
1802         }
1803     }
1804     $new_upstream = git_rev_parse $new_upstream;
1805
1806     return $new_upstream;
1807 }
1808
1809 sub cmd_new_upstream () {
1810     # automatically and unconditionally launders before rebasing
1811     # if rebase --abort is used, laundering has still been done
1812
1813     my %pieces;
1814
1815     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1816
1817     # parse args - low commitment
1818     my $spec_version = shift @ARGV;
1819     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1820     fail "bad version number \`$spec_version'" unless defined $new_version;
1821     if ($new_version->is_native()) {
1822         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1823     }
1824
1825     my $new_upstream = shift @ARGV;
1826     my $new_upstream_version = upstreamversion  $new_version;
1827     $new_upstream =
1828         resolve_upstream_version $new_upstream, $new_upstream_version;
1829
1830     record_ffq_auto();
1831
1832     my $piece = sub {
1833         my ($n, @x) = @_; # may be ''
1834         my $pc = $pieces{$n} //= {
1835             Name => $n,
1836             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1837         };
1838         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1839         $pc;
1840     };
1841
1842     my @newpieces;
1843     my $newpiece = sub {
1844         my ($n, @x) = @_; # may be ''
1845         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1846         push @newpieces, $pc;
1847     };
1848
1849     $newpiece->('',
1850         OldIx => 0,
1851         New => $new_upstream,
1852     );
1853     while (@ARGV && $ARGV[0] !~ m{^-}) {
1854         my $n = shift @ARGV;
1855
1856         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1857             unless @ARGV && $ARGV[0] !~ m{^-};
1858
1859         my $c = git_rev_parse shift @ARGV;
1860         die unless $n =~ m/^$extra_orig_namepart_re$/;
1861         $newpiece->($n, New => $c);
1862     }
1863
1864     # now we need to investigate the branch this generates the
1865     # laundered version but we don't switch to it yet
1866     my $old_head = get_head();
1867     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1868
1869     my $old_bw_cl = classify $old_bw;
1870     my $old_anchor_cl = classify $old_anchor;
1871     my $old_upstream;
1872     if (!$old_anchor_cl->{OrigParents}) {
1873         snag 'anchor-treated',
1874             'old anchor is recognised due to --anchor, cannot check upstream';
1875     } else {
1876         $old_upstream = parsecommit
1877             $old_anchor_cl->{OrigParents}[0]{CommitId};
1878         $piece->('', Old => $old_upstream->{CommitId});
1879     }
1880
1881     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1882         if ($old_upstream->{Msg} =~
1883  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1884            ) {
1885             my @oldpieces = (split / /, $1);
1886             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1887             if ($old_n_parents != @oldpieces &&
1888                 $old_n_parents != @oldpieces + 1) {
1889                 snag 'upstream-confusing', sprintf
1890                     "previous upstream combine %s".
1891                     " mentions %d pieces (each implying one parent)".
1892                     " but has %d parents".
1893                     " (one per piece plus maybe a previous combine)",
1894                     $old_upstream->{CommitId},
1895                     (scalar @oldpieces),
1896                     $old_n_parents;
1897             } elsif ($oldpieces[0] ne '.') {
1898                 snag 'upstream-confusing', sprintf
1899                     "previous upstream combine %s".
1900                     " first piece is not \`.'",
1901                     $oldpieces[0];
1902             } else {
1903                 $oldpieces[0] = '';
1904                 foreach my $i (0..$#oldpieces) {
1905                     my $n = $oldpieces[$i];
1906                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1907                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1908                 }
1909             }
1910         } else {
1911             snag 'upstream-confusing',
1912                 "previous upstream $old_upstream->{CommitId} is from".
1913                " git-debrebase but not an \`upstream-combine' commit";
1914         }
1915     }
1916
1917     foreach my $pc (values %pieces) {
1918         if (!$old_upstream) {
1919             # we have complained already
1920         } elsif (!$pc->{Old}) {
1921             snag 'upstream-new-piece',
1922                 "introducing upstream piece \`$pc->{Name}'";
1923         } elsif (!$pc->{New}) {
1924             snag 'upstream-rm-piece',
1925                 "dropping upstream piece \`$pc->{Name}'";
1926         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1927             snag 'upstream-not-ff',
1928                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1929         }
1930     }
1931
1932     printdebug "%pieces = ", (dd \%pieces), "\n";
1933     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1934
1935     snags_maybe_bail();
1936
1937     my $new_bw;
1938
1939     fresh_workarea();
1940     in_workarea sub {
1941         my @upstream_merge_parents;
1942
1943         if (!any_snags()) {
1944             push @upstream_merge_parents, $old_upstream->{CommitId};
1945         }
1946
1947         foreach my $pc (@newpieces) { # always has '' first
1948             if ($pc->{Name}) {
1949                 read_tree_subdir $pc->{Name}, $pc->{New};
1950             } else {
1951                 runcmd @git, qw(read-tree), $pc->{New};
1952             }
1953             push @upstream_merge_parents, $pc->{New};
1954         }
1955
1956         # index now contains the new upstream
1957
1958         if (@newpieces > 1) {
1959             # need to make the upstream subtree merge commit
1960             $new_upstream = make_commit \@upstream_merge_parents,
1961                 [ "Combine upstreams for $new_upstream_version",
1962  ("[git-debrebase upstream-combine . ".
1963  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1964  ": new upstream]"),
1965                 ];
1966         }
1967
1968         # $new_upstream is either the single upstream commit, or the
1969         # combined commit we just made.  Either way it will be the
1970         # "upstream" parent of the anchor merge.
1971
1972         read_tree_subdir 'debian', "$old_bw:debian";
1973
1974         # index now contains the anchor merge contents
1975         $new_bw = make_commit [ $old_bw, $new_upstream ],
1976             [ "Update to upstream $new_upstream_version",
1977  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1978             ];
1979
1980         my $clogsignoff = cmdoutput qw(git show),
1981             '--pretty=format:%an <%ae>  %aD',
1982             $new_bw;
1983
1984         # Now we have to add a changelog stanza so the Debian version
1985         # is right.
1986         die if unlink "debian";
1987         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1988         unlink "debian/changelog" or $!==ENOENT or die $!;
1989         mkdir "debian" or die $!;
1990         open CN, ">", "debian/changelog" or die $!;
1991         my $oldclog = git_cat_file ":debian/changelog";
1992         $oldclog =~ m/^($package_re) \(\S+\) / or
1993             fail "cannot parse old changelog to get package name";
1994         my $p = $1;
1995         print CN <<END, $oldclog or die $!;
1996 $p ($new_version) UNRELEASED; urgency=medium
1997
1998   * Update to new upstream version $new_upstream_version.
1999
2000  -- $clogsignoff
2001
2002 END
2003         close CN or die $!;
2004         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2005
2006         # Now we have the final new breakwater branch in the index
2007         $new_bw = make_commit [ $new_bw ],
2008             [ "Update changelog for new upstream $new_upstream_version",
2009               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2010             ];
2011     };
2012
2013     # we have constructed the new breakwater. we now need to commit to
2014     # the laundering output, because git-rebase can't easily be made
2015     # to make a replay list which is based on some other branch
2016
2017     update_head_postlaunder $old_head, $old_laundered_tip,
2018         'launder for new upstream';
2019
2020     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2021     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2022         "debrebase new-upstream $new_version: rebase";
2023     runcmd @cmd;
2024     # now it's for the user to sort out
2025 }
2026
2027 sub cmd_record_ffq_prev () {
2028     badusage "no arguments allowed" if @ARGV;
2029     my ($status, $msg) = record_ffq_prev_deferred();
2030     if ($status eq 'exists' && $opt_noop_ok) {
2031         print "Previous head already recorded\n" or die $!;
2032     } elsif ($status eq 'deferred') {
2033         run_deferred_updates 'record-ffq-prev';
2034     } else {
2035         fail "Could not preserve: $msg";
2036     }
2037 }
2038
2039 sub cmd_anchor () {
2040     badusage "no arguments allowed" if @ARGV;
2041     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2042     print "$bw\n" or die $!;
2043 }
2044
2045 sub cmd_breakwater () {
2046     badusage "no arguments allowed" if @ARGV;
2047     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2048     print "$bw\n" or die $!;
2049 }
2050
2051 sub cmd_status () {
2052     badusage "no arguments allowed" if @ARGV;
2053
2054     # todo: gdr status should print divergence info
2055     # todo: gdr status should print upstream component(s) info
2056     # todo: gdr should leave/maintain some refs with this kind of info ?
2057
2058     my $oldest = { Badness => 0 };
2059     my $newest;
2060     my $note = sub {
2061         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2062         if ($oldest->{Badness} < $badness) {
2063             $oldest = $newest = undef;
2064         }
2065         $oldest = {
2066                    Badness => $badness,
2067                    CommitId => $cl->{CommitId},
2068                    OurMsg => $ourmsg,
2069                    KcMsg => $kcmsg,
2070                   };
2071         $newest //= $oldest;
2072     };
2073     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2074         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2075         sub { $note->(2, 'branch is unlaundered', @_); },
2076         sub { $note->(3, 'branch needs laundering', @_); },
2077         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2078
2079     my $prcommitinfo = sub {
2080         my ($cid) = @_;
2081         flush STDOUT or die $!;
2082         runcmd @git, qw(--no-pager log -n1),
2083             '--pretty=format:    %h %s%n',
2084             $cid;
2085     };
2086
2087     print "current branch contents, in git-debrebase terms:\n";
2088     if (!$oldest->{Badness}) {
2089         print "  branch is laundered\n";
2090     } else {
2091         print "  $oldest->{OurMsg}\n";
2092         my $printed = '';
2093         foreach my $info ($oldest, $newest) {
2094             my $cid = $info->{CommitId};
2095             next if $cid eq $printed;
2096             $printed = $cid;
2097             print "  $info->{KcMsg}\n";
2098             $prcommitinfo->($cid);
2099         }
2100     }
2101
2102     my $prab = sub {
2103         my ($cid, $what) = @_;
2104         if (!defined $cid) {
2105             print "  $what is not well-defined\n";
2106         } else {
2107             print "  $what\n";
2108             $prcommitinfo->($cid);
2109         }
2110     };
2111     print "key git-debrebase commits:\n";
2112     $prab->($anchor, 'anchor');
2113     $prab->($bw, 'breakwater');
2114
2115     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2116         ffq_prev_branchinfo();
2117
2118     print "branch and ref status, in git-debrebase terms:\n";
2119     if ($ffq_msg) {
2120         print "  $ffq_msg\n";
2121     } else {
2122         $ffq_prev = git_get_ref $ffq_prev;
2123         $gdrlast = git_get_ref $gdrlast;
2124         if ($ffq_prev) {
2125             print "  unstitched; previous tip was:\n";
2126             $prcommitinfo->($ffq_prev);
2127         } elsif (!$gdrlast) {
2128             print "  stitched? (no record of git-debrebase work)\n";
2129         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2130             print "  stitched\n";
2131         } else {
2132             print "  not git-debrebase (diverged since last stitch)\n"
2133         }
2134     }
2135     print "you are currently rebasing\n" if currently_rebasing();
2136 }
2137
2138 sub cmd_stitch () {
2139     my $prose = 'stitch';
2140     getoptions("stitch",
2141                'prose=s', \$prose);
2142     badusage "no arguments allowed" if @ARGV;
2143     do_stitch $prose, 0;
2144 }
2145 sub cmd_prepush () { cmd_stitch(); }
2146
2147 sub cmd_quick () {
2148     badusage "no arguments allowed" if @ARGV;
2149     do_launder_head 'launder for git-debrebase quick';
2150     do_stitch 'quick';
2151 }
2152
2153 sub cmd_conclude () {
2154     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2155     if (!$ffq_prev_commitish) {
2156         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2157         return;
2158     }
2159     my $dangling_head = get_head();
2160
2161     badusage "no arguments allowed" if @ARGV;
2162     do_launder_head 'launder for git-debrebase quick';
2163     do_stitch 'quick';
2164 }
2165
2166 sub cmd_scrap () {
2167     if (currently_rebasing()) {
2168         runcmd @git, qw(rebase --abort);
2169     }
2170     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2171     if (!$ffq_prev_commitish) {
2172         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2173         finish 0;
2174     }
2175     my $scrapping_head = get_head();
2176     badusage "no arguments allowed" if @ARGV;
2177     push @deferred_updates,
2178         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2179         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2180     snags_maybe_bail();
2181     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2182 }
2183
2184 sub make_patches_staged ($) {
2185     my ($head) = @_;
2186     # Produces the patches that would result from $head if it were
2187     # laundered.
2188     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2189     fresh_workarea();
2190     in_workarea sub {
2191         gbp_pq_export 'bw', $secret_bw, $secret_head;
2192     };
2193 }
2194
2195 sub make_patches ($) {
2196     my ($head) = @_;
2197     keycommits $head, 0, \&snag;
2198     make_patches_staged $head;
2199     my $out;
2200     in_workarea sub {
2201         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2202         runcmd @git, qw(read-tree), $head;
2203         read_tree_subdir 'debian/patches', $ptree;
2204         $out = make_commit [$head], [
2205             'Commit patch queue (exported by git-debrebase)',
2206             '[git-debrebase: export and commit patches]',
2207         ];
2208     };
2209     return $out;
2210 }
2211
2212 sub cmd_make_patches () {
2213     my $opt_quiet_would_amend;
2214     getoptions("make-patches",
2215                'quiet-would-amend!', \$opt_quiet_would_amend);
2216     badusage "no arguments allowed" if @ARGV;
2217     bail_if_rebasing();
2218     my $old_head = get_head();
2219     my $new = make_patches $old_head;
2220     my $d = get_differs $old_head, $new;
2221     if ($d == 0) {
2222         fail "No (more) patches to export." unless $opt_noop_ok;
2223         return;
2224     } elsif ($d == D_PAT_ADD) {
2225         snags_maybe_bail();
2226         update_head_checkout $old_head, $new, 'make-patches';
2227     } else {
2228         print STDERR failmsg
2229             "Patch export produced patch amendments".
2230             " (abandoned output commit $new).".
2231             "  Try laundering first."
2232             unless $opt_quiet_would_amend;
2233         finish 7;
2234     }
2235 }
2236
2237 sub cmd_convert_from_gbp () {
2238     badusage "want only 1 optional argument, the upstream git commitish"
2239         unless @ARGV<=1;
2240
2241     my $clogp = parsechangelog();
2242     my $version = $clogp->{'Version'}
2243         // die "missing Version from changelog";
2244
2245     my ($upstream_spec) = @ARGV;
2246
2247     my $upstream_version = upstreamversion $version;
2248     my $upstream =
2249         resolve_upstream_version($upstream_spec, $upstream_version);
2250
2251     my $old_head = get_head();
2252
2253     my $upsdiff = get_differs $upstream, $old_head;
2254     if ($upsdiff & D_UPS) {
2255         runcmd @git, qw(--no-pager diff --stat),
2256             $upstream, $old_head,
2257             qw( -- :!/debian :/);
2258         fail <<END;
2259 upstream ($upstream_spec) and HEAD are not
2260 identical in upstream files.  See diffstat above, or run
2261   git diff $upstream_spec HEAD -- :!/debian :/
2262 END
2263     }
2264
2265     if (!is_fast_fwd $upstream, $old_head) {
2266         snag 'upstream-not-ancestor',
2267             "upstream ($upstream) is not an ancestor of HEAD";
2268     } else {
2269         my $wrong = cmdoutput
2270             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2271              qw(-- :/ :!/debian));
2272         if (length $wrong) {
2273             snag 'unexpected-upstream-changes',
2274                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2275             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2276         }
2277     }
2278
2279     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2280         snag 'upstream-has-debian',
2281             "upstream ($upstream) contains debian/ directory";
2282     }
2283
2284     my $previous_dgit_view = eval {
2285         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2286         my ($lvsn, $suite);
2287         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2288             my ($stz, $desc) = @_;
2289             no warnings qw(exiting);
2290             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2291             next unless $stz->{Date};
2292             next unless $stz->{Distribution} ne 'UNRELEASED';
2293             $lvsn = $stz->{Version};
2294             $suite = $stz->{Distribution};
2295             last;
2296         };
2297         die "neither of the first two changelog entries are released\n"
2298             unless defined $lvsn;
2299         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2300         my $mtag_pat = debiantag_maintview $lvsn, '*';
2301         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2302             $mtag_pat;
2303         die "could not find suitable maintainer view tag $mtag_pat\n"
2304             unless $mtag_pat =~ m{/};
2305         is_fast_fwd $mtag, 'HEAD' or
2306             die "HEAD is not FF from maintainer tag $mtag!";
2307         my $dtag = "archive/$mtag";
2308         is_fast_fwd $mtag, $dtag or
2309             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2310         print "will stitch in dgit view, $dtag\n";
2311         git_rev_parse $dtag;
2312     };
2313     if (!$previous_dgit_view) {
2314         $@ =~ s/^\n+//;
2315         chomp $@;
2316         print STDERR "cannot stitch in dgit view: $@\n";
2317     }
2318
2319     snags_maybe_bail_early();
2320
2321     my $work;
2322
2323     fresh_workarea();
2324     in_workarea sub {
2325         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2326         # make a branch out of the patch queue - we'll want this in a mo
2327         runcmd qw(gbp pq import);
2328         # strip the patches out
2329         runcmd @git, qw(checkout -q gdr-internal~0);
2330         rm_subdir_cached 'debian/patches';
2331         $work = make_commit ['HEAD'], [
2332  'git-debrebase convert-from-gbp: drop patches from tree',
2333  'Delete debian/patches, as part of converting to git-debrebase format.',
2334  '[git-debrebase convert-from-gbp: drop patches from tree]'
2335                               ];
2336         # make the anchor merge
2337         # the tree is already exactly right
2338         $work = make_commit [$work, $upstream], [
2339  'git-debrebase import: declare upstream',
2340  'First breakwater merge.',
2341  '[git-debrebase anchor: declare upstream]'
2342                               ];
2343
2344         # rebase the patch queue onto the new breakwater
2345         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2346         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2347         $work = git_rev_parse 'HEAD';
2348
2349         if ($previous_dgit_view) {
2350             $work = make_commit [$work, $previous_dgit_view], [
2351  'git-debrebase import: declare ff from dgit archive view',
2352  '[git-debrebase pseudomerge: import-from-gbp]',
2353             ];
2354         }
2355     };
2356
2357     ffq_check $work;
2358     snags_maybe_bail();
2359     update_head_checkout $old_head, $work, 'convert-from-gbp';
2360 }
2361
2362 sub cmd_convert_to_gbp () {
2363     badusage "no arguments allowed" if @ARGV;
2364     my $head = get_head();
2365     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2366     keycommits $head, 0;
2367     my $out;
2368     make_patches_staged $head;
2369     in_workarea sub {
2370         $out = make_commit ['HEAD'], [
2371             'Commit patch queue (converted from git-debrebase format)',
2372             '[git-debrebase convert-to-gbp: commit patches]',
2373         ];
2374     };
2375     if (defined $ffq) {
2376         push @deferred_updates, "delete $ffq";
2377         push @deferred_updates, "delete $gdrlast";
2378     }
2379     snags_maybe_bail();
2380     update_head_checkout $head, $out, "convert to gbp (v0)";
2381     print <<END or die $!;
2382 git-debrebase: converted to git-buildpackage branch format
2383 git-debrebase: WARNING: do not now run "git-debrebase" any more
2384 git-debrebase: WARNING: doing so would drop all upstream patches!
2385 END
2386 }
2387
2388 sub cmd_convert_from_dgit_view () {
2389     my $clogp = parsechangelog();
2390
2391     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2392     my $do_origs = 1;
2393     my $do_tags = 1;
2394     my $always = 0;
2395     my $diagnose = 0;
2396
2397     getoptions("convert-from-dgit-view",
2398                'diagnose!', \$diagnose,
2399                'build-products-dir:s', \$bpd,
2400                'origs!', \$do_origs,
2401                'tags!', \$do_tags,
2402                'always-convert-anyway!', \$always);
2403     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2404
2405     my @upstreams;
2406
2407     if (@ARGV) {
2408         my $spec = shift @ARGV;
2409         my $commit = git_rev_parse "$spec^{commit}";
2410         push @upstreams, { Commit => $commit,
2411                            Source => "$ARGV[0], from command line",
2412                            Only => 1,
2413                          };
2414     }
2415
2416     my $head = get_head();
2417
2418     if (!$always) {
2419         my $troubles = 0;
2420         my $trouble = sub { $troubles++; };
2421         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2422         printdebug "troubles=$troubles\n";
2423         if (!$troubles) {
2424             print STDERR <<END;
2425 $us: Branch already seems to be in git-debrebase format!
2426 $us: --always-convert-anyway would do the conversion operation anyway
2427 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2428 END
2429             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2430             finish 0;
2431         }
2432     }
2433
2434     snags_maybe_bail_early();
2435
2436     my $version = upstreamversion $clogp->{Version};
2437     print STDERR "Considering possible commits corresponding to upstream:\n";
2438
2439     if (!@upstreams) {
2440         if ($do_tags) {
2441             my @tried;
2442             my $ups_tag = upstream_commitish_search $version, \@tried;
2443             if ($ups_tag) {
2444                 my $this = "git tag $tried[-1]";
2445                 push @upstreams, { Commit => $ups_tag,
2446                                    Source => $this,
2447                                  };
2448             } else {
2449                 printf STDERR
2450                     " git tag: no suitable tag found (tried %s)\n",
2451                     "@tried";
2452             }
2453         }
2454         if ($do_origs) {
2455             my $p = $clogp->{'Source'};
2456             # we do a quick check to see if there are plausible origs
2457             my $something=0;
2458             if (!opendir BPD, $bpd) {
2459                 die "$bpd: opendir: $!" unless $!==ENOENT;
2460             } else {
2461                 while ($!=0, my $f = readdir BPD) {
2462                     next unless is_orig_file_of_p_v $f, $p, $version;
2463                     printf STDERR
2464                         " orig: found what looks like a .orig, %s\n",
2465                         "$bpd/$f";
2466                     $something=1;
2467                     last;
2468                 }
2469                 die "read $bpd: $!" if $!;
2470                 closedir BPD;
2471             }
2472             if ($something) {
2473                 my $tree = cmdoutput
2474                     @dgit, qw(--build-products-dir), $bpd,
2475                     qw(print-unapplied-treeish);
2476                 fresh_workarea();
2477                 in_workarea sub {
2478                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2479                     rm_subdir_cached 'debian';
2480                     $tree = cmdoutput @git, qw(write-tree);
2481                     my $ups_synth = make_commit [], [ <<END, <<END,
2482 Import effective orig tree for upstream version $version
2483 END
2484 This includes the contents of the .orig(s), minus any debian/ directory.
2485
2486 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2487 END
2488                                                     ];
2489                     push @upstreams, { Commit => $ups_synth,
2490                                        Source => "orig(s) imported via dgit",
2491                                      };
2492                 }
2493             } else {
2494                 printf STDERR
2495                     " orig: no suitable origs found (looked for %s in %s)\n",
2496                     "${p}_".(stripeoch $version)."...", $bpd;
2497             }
2498         }
2499     }
2500
2501     my $some_patches = stat_exists 'debian/patches/series';
2502
2503     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2504
2505     my $result;
2506     foreach my $u (@upstreams) {
2507         my $work = $head;
2508         fresh_workarea();
2509         in_workarea sub {
2510             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2511             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2512             runcmd @git, qw(clean -xdff);
2513             runcmd @git, qw(checkout), $head, qw(-- debian);
2514             if ($some_patches) {
2515                 rm_subdir_cached 'debian/patches';
2516                 $work = make_commit [ $work ], [
2517  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2518  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2519  "to git-debrebase format.  Upstream changes will appear as commits.",
2520  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2521                                            ];
2522             }
2523             $work = make_commit [ $work, $u->{Commit} ], [
2524  'git-debrebase convert-from-dgit-view: declare upstream',
2525  '(Re)constructed breakwater merge.',
2526  '[git-debrebase anchor: declare upstream]'
2527                                                          ];
2528             runcmd @git, qw(checkout --quiet -b mk), $work;
2529             if ($some_patches) {
2530                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2531                 runcmd @git, qw(reset --quiet);
2532                 my @gbp_cmd = (qw(gbp pq import));
2533                 if (!$diagnose) {
2534                     my $gbp_err = "../gbp-pq-err";
2535                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2536                 }
2537                 my $r = system @gbp_cmd;
2538                 if ($r) {
2539                     printf STDERR
2540                         " %s: couldn't apply patches: gbp pq %s",
2541                         $u->{Source}, waitstatusmsg();
2542                     return;
2543                 }
2544             }
2545             my $work = git_rev_parse qw(HEAD);
2546             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2547             if (length $diffout) {
2548                 print STDERR
2549                     " $u->{Source}: applying patches gives different tree\n";
2550                 print STDERR $diffout if $diagnose;
2551                 return;
2552             }
2553             # OMG!
2554             $u->{Result} = $work;
2555             $result = $u;
2556         };
2557         last if $result;
2558     }
2559
2560     if (!$result) {
2561         fail <<END;
2562 Could not find or construct a suitable upstream commit.
2563 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2564 upstream commmit explicitly or provide suitable origs.
2565 END
2566     }
2567
2568     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2569
2570     ffq_check $result->{Result};
2571     snags_maybe_bail();
2572     update_head_checkout $head, $result->{Result},
2573         'convert-from-dgit-view';
2574 }
2575
2576 sub cmd_downstream_rebase_launder_v0 () {
2577     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2578     my ($base) = @ARGV;
2579     $base = git_rev_parse $base;
2580     my $old_head = get_head();
2581     my $current = $old_head;
2582     my $topmost_keep;
2583     for (;;) {
2584         if ($current eq $base) {
2585             $topmost_keep //= $current;
2586             print " $current BASE stop\n";
2587             last;
2588         }
2589         my $cl = classify $current;
2590         print " $current $cl->{Type}";
2591         my $keep = 0;
2592         my $p0 = $cl->{Parents}[0]{CommitId};
2593         my $next;
2594         if ($cl->{Type} eq 'Pseudomerge') {
2595             print " ^".($cl->{Contributor}{Ix}+1);
2596             $next = $cl->{Contributor}{CommitId};
2597         } elsif ($cl->{Type} eq 'AddPatches' or
2598                  $cl->{Type} eq 'Changelog') {
2599             print " strip";
2600             $next = $p0;
2601         } else {
2602             print " keep";
2603             $next = $p0;
2604             $keep = 1;
2605         }
2606         print "\n";
2607         if ($keep) {
2608             $topmost_keep //= $current;
2609         } else {
2610             die "to-be stripped changes not on top of the branch\n"
2611                 if $topmost_keep;
2612         }
2613         $current = $next;
2614     }
2615     if ($topmost_keep eq $old_head) {
2616         print "unchanged\n";
2617     } else {
2618         print "updating to $topmost_keep\n";
2619         update_head_checkout
2620             $old_head, $topmost_keep,
2621             'downstream-rebase-launder-v0';
2622     }
2623 }
2624
2625 getoptions_main
2626           ("bad options\n",
2627            "D+" => \$debuglevel,
2628            'noop-ok', => \$opt_noop_ok,
2629            'f=s' => \@snag_force_opts,
2630            'anchor=s' => \@opt_anchors,
2631            '--dgit=s' => \($dgit[0]),
2632            'force!',
2633            '-i:s' => sub {
2634                my ($opt,$val) = @_;
2635                badusage "git-debrebase: no cuddling to -i for git-rebase"
2636                    if length $val;
2637                die if $opt_defaultcmd_interactive; # should not happen
2638                $opt_defaultcmd_interactive = [ qw(-i) ];
2639                # This access to @ARGV is excessive familiarity with
2640                # Getopt::Long, but there isn't another sensible
2641                # approach.  '-i=s{0,}' does not work with bundling.
2642                push @$opt_defaultcmd_interactive, @ARGV;
2643                @ARGV=();
2644            },
2645            'help' => sub { print $usage_message or die $!; finish 0; },
2646            );
2647
2648 initdebug('git-debrebase ');
2649 enabledebug if $debuglevel;
2650
2651 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2652 chdir $toplevel or die "chdir $toplevel: $!";
2653
2654 $rd = fresh_playground "$playprefix/misc";
2655
2656 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2657
2658 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2659     defaultcmd_rebase();
2660 } else {
2661     my $cmd = shift @ARGV;
2662     my $cmdfn = $cmd;
2663     $cmdfn =~ y/-/_/;
2664     $cmdfn = ${*::}{"cmd_$cmdfn"};
2665
2666     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2667     $cmdfn->();
2668 }
2669
2670 finish 0;