dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23 use Debian::Dgit::I18n;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use IO::Handle;
  31 use Data::Dumper;
  32 use LWP::UserAgent;
  33 use Dpkg::Control::Hash;
  34 use File::Path;
  35 use File::Spec;
  36 use File::Temp qw(tempdir);
  37 use File::Basename;
  38 use Dpkg::Version;
  39 use Dpkg::Compression;
  40 use Dpkg::Compression::Process;
  41 use POSIX;
  42 use Locale::gettext;
  43 use IPC::Open2;
  44 use Digest::SHA;
  45 use Digest::MD5;
  46 use List::MoreUtils qw(pairwise);
  47 use Text::Glob qw(match_glob);
  48 use Fcntl qw(:DEFAULT :flock);
  49 use Carp;
  50
  51 use Debian::Dgit;
  52
  53 our $our_version = 'UNRELEASED'; ###substituted###
  54 our $absurdity = undef; ###substituted###
  55
  56 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  57 our $protovsn;
  58
  59 our $cmd;
  60 our $subcommand;
  61 our $isuite;
  62 our $idistro;
  63 our $package;
  64 our @ropts;
  65
  66 our $sign = 1;
  67 our $dryrun_level = 0;
  68 our $changesfile;
  69 our $buildproductsdir;
  70 our $bpd_glob;
  71 our $new_package = 0;
  72 our $includedirty = 0;
  73 our $rmonerror = 1;
  74 our @deliberatelies;
  75 our %previously;
  76 our $existing_package = 'dpkg';
  77 our $cleanmode;
  78 our $changes_since_version;
  79 our $rmchanges;
  80 our $overwrite_version; # undef: not specified; '': check changelog
  81 our $quilt_mode;
  82 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  83 our $dodep14tag;
  84 our %internal_object_save;
  85 our $we_are_responder;
  86 our $we_are_initiator;
  87 our $initiator_tempdir;
  88 our $patches_applied_dirtily = 00;
  89 our $chase_dsc_distro=1;
  90
  91 our %forceopts = map { $_=>0 }
  92     qw(unrepresentable unsupported-source-format
  93        dsc-changes-mismatch changes-origs-exactly
  94        uploading-binaries uploading-source-only
  95        import-gitapply-absurd
  96        import-gitapply-no-absurd
  97        import-dsc-with-dgit-field);
  98
  99 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 100
 101 our $suite_re = '[-+.0-9a-z]+';
 102 our $cleanmode_re = qr{(?: dpkg-source (?: -d )? (?: ,no-check | ,all-check )?
 103                      | (?: git | git-ff ) (?: ,always )?
 104                          | check (?: ,ignores )?
 105                          | none
 106                          )}x;
 107
 108 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 109 our $splitbraincache = 'dgit-intern/quilt-cache';
 110 our $rewritemap = 'dgit-rewrite/map';
 111
 112 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 113
 114 our (@git) = qw(git);
 115 our (@dget) = qw(dget);
 116 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 117 our (@dput) = qw(dput);
 118 our (@debsign) = qw(debsign);
 119 our (@gpg) = qw(gpg);
 120 our (@sbuild) = (qw(sbuild --no-source));
 121 our (@ssh) = 'ssh';
 122 our (@dgit) = qw(dgit);
 123 our (@git_debrebase) = qw(git-debrebase);
 124 our (@aptget) = qw(apt-get);
 125 our (@aptcache) = qw(apt-cache);
 126 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 127 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 128 our (@dpkggenchanges) = qw(dpkg-genchanges);
 129 our (@mergechanges) = qw(mergechanges -f);
 130 our (@gbp_build) = ('');
 131 our (@gbp_pq) = ('gbp pq');
 132 our (@changesopts) = ('');
 133 our (@pbuilder) = ("sudo -E pbuilder","--no-source-only-changes");
 134 our (@cowbuilder) = ("sudo -E cowbuilder","--no-source-only-changes");
 135
 136 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 137                      'curl' => \@curl,
 138                      'dput' => \@dput,
 139                      'debsign' => \@debsign,
 140                      'gpg' => \@gpg,
 141                      'sbuild' => \@sbuild,
 142                      'ssh' => \@ssh,
 143                      'dgit' => \@dgit,
 144                      'git' => \@git,
 145                      'git-debrebase' => \@git_debrebase,
 146                      'apt-get' => \@aptget,
 147                      'apt-cache' => \@aptcache,
 148                      'dpkg-source' => \@dpkgsource,
 149                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 150                      'dpkg-genchanges' => \@dpkggenchanges,
 151                      'gbp-build' => \@gbp_build,
 152                      'gbp-pq' => \@gbp_pq,
 153                      'ch' => \@changesopts,
 154                      'mergechanges' => \@mergechanges,
 155                      'pbuilder' => \@pbuilder,
 156                      'cowbuilder' => \@cowbuilder);
 157
 158 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 159 our %opts_cfg_insertpos = map {
 160     $_,
 161     scalar @{ $opts_opt_map{$_} }
 162 } keys %opts_opt_map;
 163
 164 sub parseopts_late_defaults();
 165 sub quiltify_trees_differ ($$;$$$);
 166 sub setup_gitattrs(;$);
 167 sub check_gitattrs($$);
 168
 169 our $playground;
 170 our $keyid;
 171
 172 autoflush STDOUT 1;
 173
 174 our $supplementary_message = '';
 175 our $made_split_brain = 0;
 176 our $do_split_brain = 0;
 177
 178 # Interactions between quilt mode and split brain
 179 # (currently, split brain only implemented iff
 180 #  madformat_wantfixup && quiltmode_splitbrain)
 181 #
 182 #   source format        sane           `3.0 (quilt)'
 183 #                                       madformat_wantfixup()
 184 #
 185 #   quilt mode                          normal              quiltmode
 186 #                                       (eg linear)         _splitbrain
 187 #
 188 #   ------------      ------------------------------------------------
 189 #
 190 #   no split          no q cache        no q cache          forbidden,
 191 #     brain           PM on master      q fixup on master   prevented
 192 #   !$do_split_brain                    PM on master
 193 #
 194 #   split brain       no q cache        q fixup cached, to dgit view
 195 #                     PM in dgit view   PM in dgit view
 196 #
 197 # PM = pseudomerge to make ff, due to overwrite (or split view)
 198 # "no q cache" = do not record in cache on build, do not check cache
 199 # `3.0 (quilt)' with --quilt=nocheck is treated as sane format
 200
 201 END {
 202     local ($@, $?);
 203     return unless forkcheck_mainprocess();
 204     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 205 }
 206
 207 our $remotename = 'dgit';
 208 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 209 our $csuite;
 210 our $instead_distro;
 211
 212 if (!defined $absurdity) {
 213     $absurdity = $0;
 214     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 215 }
 216
 217 sub debiantag ($$) {
 218     my ($v,$distro) = @_;
 219     return debiantag_new($v, $distro);
 220 }
 221
 222 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 223
 224 sub lbranch () { return "$branchprefix/$csuite"; }
 225 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 226 sub lref () { return "refs/heads/".lbranch(); }
 227 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 228 sub rrref () { return server_ref($csuite); }
 229
 230 sub srcfn ($$) {
 231     my ($vsn, $sfx) = @_;
 232     return &source_file_leafname($package, $vsn, $sfx);
 233 }
 234 sub is_orig_file_of_vsn ($$) {
 235     my ($f, $upstreamvsn) = @_;
 236     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 237 }
 238
 239 sub dscfn ($) {
 240     my ($vsn) = @_;
 241     return srcfn($vsn,".dsc");
 242 }
 243
 244 sub changespat ($;$) {
 245     my ($vsn, $arch) = @_;
 246     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 247 }
 248
 249 our $us = 'dgit';
 250 initdebug('');
 251
 252 our @end;
 253 END {
 254     local ($?);
 255     return unless forkcheck_mainprocess();
 256     foreach my $f (@end) {
 257         eval { $f->(); };
 258         print STDERR "$us: cleanup: $@" if length $@;
 259     }
 260 };
 261
 262 sub badcfg {
 263     print STDERR f_ "%s: invalid configuration: %s\n", $us, "@_";
 264     finish 12;
 265 }
 266
 267 sub forceable_fail ($$) {
 268     my ($forceoptsl, $msg) = @_;
 269     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 270     print STDERR +(__ "warning: overriding problem due to --force:\n"). $msg;
 271 }
 272
 273 sub forceing ($) {
 274     my ($forceoptsl) = @_;
 275     my @got = grep { $forceopts{$_} } @$forceoptsl;
 276     return 0 unless @got;
 277     print STDERR f_
 278         "warning: skipping checks or functionality due to --force-%s\n",
 279         $got[0];
 280 }
 281
 282 sub no_such_package () {
 283     print STDERR f_ "%s: source package %s does not exist in suite %s\n",
 284         $us, $package, $isuite;
 285     finish 4;
 286 }
 287
 288 sub deliberately ($) {
 289     my ($enquiry) = @_;
 290     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 291 }
 292
 293 sub deliberately_not_fast_forward () {
 294     foreach (qw(not-fast-forward fresh-repo)) {
 295         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 296     }
 297 }
 298
 299 sub quiltmode_splitbrain () {
 300     $quilt_mode =~ m/gbp|dpm|unapplied/;
 301 }
 302
 303 sub opts_opt_multi_cmd {
 304     my $extra = shift;
 305     my @cmd;
 306     push @cmd, split /\s+/, shift @_;
 307     push @cmd, @$extra;
 308     push @cmd, @_;
 309     @cmd;
 310 }
 311
 312 sub gbp_pq {
 313     return opts_opt_multi_cmd [], @gbp_pq;
 314 }
 315
 316 sub dgit_privdir () {
 317     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 318 }
 319
 320 sub bpd_abs () {
 321     my $r = $buildproductsdir;
 322     $r = "$maindir/$r" unless $r =~ m{^/};
 323     return $r;
 324 }
 325
 326 sub get_tree_of_commit ($) {
 327     my ($commitish) = @_;
 328     my $cdata = cmdoutput @git, qw(cat-file commit), $commitish;
 329     $cdata =~ m/\n\n/;  $cdata = $`;
 330     $cdata =~ m/^tree (\w+)$/m or confess "cdata $cdata ?";
 331     return $1;
 332 }
 333
 334 sub branch_gdr_info ($$) {
 335     my ($symref, $head) = @_;
 336     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 337         gdr_ffq_prev_branchinfo($symref);
 338     return () unless $status eq 'branch';
 339     $ffq_prev = git_get_ref $ffq_prev;
 340     $gdrlast  = git_get_ref $gdrlast;
 341     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 342     return ($ffq_prev, $gdrlast);
 343 }
 344
 345 sub branch_is_gdr_unstitched_ff ($$$) {
 346     my ($symref, $head, $ancestor) = @_;
 347     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 348     return 0 unless $ffq_prev;
 349     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
 350     return 1;
 351 }
 352
 353 sub branch_is_gdr ($) {
 354     my ($head) = @_;
 355     # This is quite like git-debrebase's keycommits.
 356     # We have our own implementation because:
 357     #  - our algorighm can do fewer tests so is faster
 358     #  - it saves testing to see if gdr is installed
 359
 360     # NB we use this jsut for deciding whether to run gdr make-patches
 361     # Before reusing this algorithm for somthing else, its
 362     # suitability should be reconsidered.
 363
 364     my $walk = $head;
 365     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 366     printdebug "branch_is_gdr $head...\n";
 367     my $get_patches = sub {
 368         my $t = git_cat_file "$_[0]:debian/patches", [qw(missing tree)];
 369         return $t // '';
 370     };
 371     my $tip_patches = $get_patches->($head);
 372   WALK:
 373     for (;;) {
 374         my $cdata = git_cat_file $walk, 'commit';
 375         my ($hdrs,$msg) = $cdata =~ m{\n\n} ? ($`,$') : ($cdata,'');
 376         if ($msg =~ m{^\[git-debrebase\ (
 377                           anchor | changelog | make-patches |
 378                           merged-breakwater | pseudomerge
 379                       ) [: ] }mx) {
 380             # no need to analyse this - it's sufficient
 381             # (gdr classifications: Anchor, MergedBreakwaters)
 382             # (made by gdr: Pseudomerge, Changelog)
 383             printdebug "branch_is_gdr  $walk gdr $1 YES\n";
 384             return 1;
 385         }
 386         my @parents = ($hdrs =~ m/^parent (\w+)$/gm);
 387         if (@parents==2) {
 388             my $walk_tree = get_tree_of_commit $walk;
 389             foreach my $p (@parents) {
 390                 my $p_tree = get_tree_of_commit $p;
 391                 if ($p_tree eq $walk_tree) { # pseudomerge contriburor
 392                     # (gdr classification: Pseudomerge; not made by gdr)
 393                     printdebug "branch_is_gdr  $walk unmarked pseudomerge\n"
 394                         if $debuglevel >= 2;
 395                     $walk = $p;
 396                     next WALK;
 397                 }
 398             }
 399             # some other non-gdr merge
 400             # (gdr classification: VanillaMerge, DgitImportUnpatched, ?)
 401             printdebug "branch_is_gdr  $walk ?-2-merge NO\n";
 402             return 0;
 403         }
 404         if (@parents>2) {
 405             # (gdr classification: ?)
 406             printdebug "branch_is_gdr  $walk ?-octopus NO\n";
 407             return 0;
 408         }
 409         if (!@parents) {
 410             printdebug "branch_is_gdr  $walk origin\n";
 411             return 0;
 412         }
 413         if ($get_patches->($walk) ne $tip_patches) {
 414             # Our parent added, removed, or edited patches, and wasn't
 415             # a gdr make-patches commit.  gdr make-patches probably
 416             # won't do that well, then.
 417             # (gdr classification of parent: AddPatches or ?)
 418             printdebug "branch_is_gdr  $walk ?-patches NO\n";
 419             return 0;
 420         }
 421         if ($tip_patches eq '' and
 422             !defined git_cat_file "$walk~:debian" and
 423             !quiltify_trees_differ "$walk~", $walk
 424            ) {
 425             # (gdr classification of parent: BreakwaterStart
 426             printdebug "branch_is_gdr  $walk unmarked BreakwaterStart YES\n";
 427             return 1;
 428         }
 429         # (gdr classification: Upstream Packaging Mixed Changelog)
 430         printdebug "branch_is_gdr  $walk plain\n"
 431             if $debuglevel >= 2;
 432         $walk = $parents[0];
 433     }
 434 }
 435
 436 #---------- remote protocol support, common ----------
 437
 438 # remote push initiator/responder protocol:
 439 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 440 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 441 #  < dgit-remote-push-ready <actual-proto-vsn>
 442 #
 443 # occasionally:
 444 #
 445 #  > progress NBYTES
 446 #  [NBYTES message]
 447 #
 448 #  > supplementary-message NBYTES          # $protovsn >= 3
 449 #  [NBYTES message]
 450 #
 451 # main sequence:
 452 #
 453 #  > file parsed-changelog
 454 #  [indicates that output of dpkg-parsechangelog follows]
 455 #  > data-block NBYTES
 456 #  > [NBYTES bytes of data (no newline)]
 457 #  [maybe some more blocks]
 458 #  > data-end
 459 #
 460 #  > file dsc
 461 #  [etc]
 462 #
 463 #  > file changes
 464 #  [etc]
 465 #
 466 #  > param head DGIT-VIEW-HEAD
 467 #  > param csuite SUITE
 468 #  > param tagformat new              # $protovsn >= 4
 469 #  > param maint-view MAINT-VIEW-HEAD
 470 #
 471 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 472 #  > file buildinfo                             # for buildinfos to sign
 473 #
 474 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 475 #                                     # goes into tag, for replay prevention
 476 #
 477 #  > want signed-tag
 478 #  [indicates that signed tag is wanted]
 479 #  < data-block NBYTES
 480 #  < [NBYTES bytes of data (no newline)]
 481 #  [maybe some more blocks]
 482 #  < data-end
 483 #  < files-end
 484 #
 485 #  > want signed-dsc-changes
 486 #  < data-block NBYTES    [transfer of signed dsc]
 487 #  [etc]
 488 #  < data-block NBYTES    [transfer of signed changes]
 489 #  [etc]
 490 #  < data-block NBYTES    [transfer of each signed buildinfo
 491 #  [etc]                   same number and order as "file buildinfo"]
 492 #  ...
 493 #  < files-end
 494 #
 495 #  > complete
 496
 497 our $i_child_pid;
 498
 499 sub i_child_report () {
 500     # Sees if our child has died, and reap it if so.  Returns a string
 501     # describing how it died if it failed, or undef otherwise.
 502     return undef unless $i_child_pid;
 503     my $got = waitpid $i_child_pid, WNOHANG;
 504     return undef if $got <= 0;
 505     die unless $got == $i_child_pid;
 506     $i_child_pid = undef;
 507     return undef unless $?;
 508     return f_ "build host child %s", waitstatusmsg();
 509 }
 510
 511 sub badproto ($$) {
 512     my ($fh, $m) = @_;
 513     fail f_ "connection lost: %s", $! if $fh->error;
 514     fail f_ "protocol violation; %s not expected", $m;
 515 }
 516
 517 sub badproto_badread ($$) {
 518     my ($fh, $wh) = @_;
 519     fail f_ "connection lost: %s", $! if $!;
 520     my $report = i_child_report();
 521     fail $report if defined $report;
 522     badproto $fh, f_ "eof (reading %s)", $wh;
 523 }
 524
 525 sub protocol_expect (&$) {
 526     my ($match, $fh) = @_;
 527     local $_;
 528     $_ = <$fh>;
 529     defined && chomp or badproto_badread $fh, __ "protocol message";
 530     if (wantarray) {
 531         my @r = &$match;
 532         return @r if @r;
 533     } else {
 534         my $r = &$match;
 535         return $r if $r;
 536     }
 537     badproto $fh, f_ "\`%s'", $_;
 538 }
 539
 540 sub protocol_send_file ($$) {
 541     my ($fh, $ourfn) = @_;
 542     open PF, "<", $ourfn or die "$ourfn: $!";
 543     for (;;) {
 544         my $d;
 545         my $got = read PF, $d, 65536;
 546         die "$ourfn: $!" unless defined $got;
 547         last if !$got;
 548         print $fh "data-block ".length($d)."\n" or confess "$!";
 549         print $fh $d or confess "$!";
 550     }
 551     PF->error and die "$ourfn $!";
 552     print $fh "data-end\n" or confess "$!";
 553     close PF;
 554 }
 555
 556 sub protocol_read_bytes ($$) {
 557     my ($fh, $nbytes) = @_;
 558     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, __ "bad byte count";
 559     my $d;
 560     my $got = read $fh, $d, $nbytes;
 561     $got==$nbytes or badproto_badread $fh, __ "data block";
 562     return $d;
 563 }
 564
 565 sub protocol_receive_file ($$) {
 566     my ($fh, $ourfn) = @_;
 567     printdebug "() $ourfn\n";
 568     open PF, ">", $ourfn or die "$ourfn: $!";
 569     for (;;) {
 570         my ($y,$l) = protocol_expect {
 571             m/^data-block (.*)$/ ? (1,$1) :
 572             m/^data-end$/ ? (0,) :
 573             ();
 574         } $fh;
 575         last unless $y;
 576         my $d = protocol_read_bytes $fh, $l;
 577         print PF $d or confess "$!";
 578     }
 579     close PF or confess "$!";
 580 }
 581
 582 #---------- remote protocol support, responder ----------
 583
 584 sub responder_send_command ($) {
 585     my ($command) = @_;
 586     return unless $we_are_responder;
 587     # called even without $we_are_responder
 588     printdebug ">> $command\n";
 589     print PO $command, "\n" or confess "$!";
 590 }
 591
 592 sub responder_send_file ($$) {
 593     my ($keyword, $ourfn) = @_;
 594     return unless $we_are_responder;
 595     printdebug "]] $keyword $ourfn\n";
 596     responder_send_command "file $keyword";
 597     protocol_send_file \*PO, $ourfn;
 598 }
 599
 600 sub responder_receive_files ($@) {
 601     my ($keyword, @ourfns) = @_;
 602     die unless $we_are_responder;
 603     printdebug "[[ $keyword @ourfns\n";
 604     responder_send_command "want $keyword";
 605     foreach my $fn (@ourfns) {
 606         protocol_receive_file \*PI, $fn;
 607     }
 608     printdebug "[[\$\n";
 609     protocol_expect { m/^files-end$/ } \*PI;
 610 }
 611
 612 #---------- remote protocol support, initiator ----------
 613
 614 sub initiator_expect (&) {
 615     my ($match) = @_;
 616     protocol_expect { &$match } \*RO;
 617 }
 618
 619 #---------- end remote code ----------
 620
 621 sub progress {
 622     if ($we_are_responder) {
 623         my $m = join '', @_;
 624         responder_send_command "progress ".length($m) or confess "$!";
 625         print PO $m or confess "$!";
 626     } else {
 627         print @_, "\n";
 628     }
 629 }
 630
 631 our $ua;
 632
 633 sub url_get {
 634     if (!$ua) {
 635         $ua = LWP::UserAgent->new();
 636         $ua->env_proxy;
 637     }
 638     my $what = $_[$#_];
 639     progress "downloading $what...";
 640     my $r = $ua->get(@_) or confess "$!";
 641     return undef if $r->code == 404;
 642     $r->is_success or fail f_ "failed to fetch %s: %s",
 643         $what, $r->status_line;
 644     return $r->decoded_content(charset => 'none');
 645 }
 646
 647 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 648
 649 sub act_local () { return $dryrun_level <= 1; }
 650 sub act_scary () { return !$dryrun_level; }
 651
 652 sub printdone {
 653     if (!$dryrun_level) {
 654         progress f_ "%s ok: %s", $us, "@_";
 655     } else {
 656         progress f_ "would be ok: %s (but dry run only)", "@_";
 657     }
 658 }
 659
 660 sub dryrun_report {
 661     printcmd(\*STDERR,$debugprefix."#",@_);
 662 }
 663
 664 sub runcmd_ordryrun {
 665     if (act_scary()) {
 666         runcmd @_;
 667     } else {
 668         dryrun_report @_;
 669     }
 670 }
 671
 672 sub runcmd_ordryrun_local {
 673     if (act_local()) {
 674         runcmd @_;
 675     } else {
 676         dryrun_report @_;
 677     }
 678 }
 679
 680 our $helpmsg = i_ <<END;
 681 main usages:
 682   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 683   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 684   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 685   dgit [dgit-opts] sbuild [sbuild-opts]
 686   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 687   dgit [dgit-opts] push [dgit-opts] [suite]
 688   dgit [dgit-opts] push-source [dgit-opts] [suite]
 689   dgit [dgit-opts] rpush build-host:build-dir ...
 690 important dgit options:
 691   -k<keyid>           sign tag and package with <keyid> instead of default
 692   --dry-run -n        do not change anything, but go through the motions
 693   --damp-run -L       like --dry-run but make local changes, without signing
 694   --new -N            allow introducing a new package
 695   --debug -D          increase debug level
 696   -c<name>=<value>    set git config option (used directly by dgit too)
 697 END
 698
 699 our $later_warning_msg = i_ <<END;
 700 Perhaps the upload is stuck in incoming.  Using the version from git.
 701 END
 702
 703 sub badusage {
 704     print STDERR f_ "%s: %s\n%s", $us, "@_", __ $helpmsg or confess "$!";
 705     finish 8;
 706 }
 707
 708 sub nextarg {
 709     @ARGV or badusage __ "too few arguments";
 710     return scalar shift @ARGV;
 711 }
 712
 713 sub pre_help () {
 714     not_necessarily_a_tree();
 715 }
 716 sub cmd_help () {
 717     print __ $helpmsg or confess "$!";
 718     finish 0;
 719 }
 720
 721 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 722
 723 our %defcfg = ('dgit.default.distro' => 'debian',
 724                'dgit.default.default-suite' => 'unstable',
 725                'dgit.default.old-dsc-distro' => 'debian',
 726                'dgit-suite.*-security.distro' => 'debian-security',
 727                'dgit.default.username' => '',
 728                'dgit.default.archive-query-default-component' => 'main',
 729                'dgit.default.ssh' => 'ssh',
 730                'dgit.default.archive-query' => 'madison:',
 731                'dgit.default.sshpsql-dbname' => 'service=projectb',
 732                'dgit.default.aptget-components' => 'main',
 733                'dgit.default.source-only-uploads' => 'ok',
 734                'dgit.dsc-url-proto-ok.http'    => 'true',
 735                'dgit.dsc-url-proto-ok.https'   => 'true',
 736                'dgit.dsc-url-proto-ok.git'     => 'true',
 737                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 738                'dgit.default.dsc-url-proto-ok' => 'false',
 739                # old means "repo server accepts pushes with old dgit tags"
 740                # new means "repo server accepts pushes with new dgit tags"
 741                # maint means "repo server accepts split brain pushes"
 742                # hist means "repo server may have old pushes without new tag"
 743                #   ("hist" is implied by "old")
 744                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 745                'dgit-distro.debian.git-check' => 'url',
 746                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 747                'dgit-distro.debian.new-private-pushers' => 't',
 748                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 749                'dgit-distro.debian/push.git-url' => '',
 750                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 751                'dgit-distro.debian/push.git-user-force' => 'dgit',
 752                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 753                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 754                'dgit-distro.debian/push.git-create' => 'true',
 755                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 756  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 757 # 'dgit-distro.debian.archive-query-tls-key',
 758 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 759 # ^ this does not work because curl is broken nowadays
 760 # Fixing #790093 properly will involve providing providing the key
 761 # in some pacagke and maybe updating these paths.
 762 #
 763 # 'dgit-distro.debian.archive-query-tls-curl-args',
 764 #   '--ca-path=/etc/ssl/ca-debian',
 765 # ^ this is a workaround but works (only) on DSA-administered machines
 766                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 767                'dgit-distro.debian.git-url-suffix' => '',
 768                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 769                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 770  'dgit-distro.debian-security.archive-query' => 'aptget:',
 771  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 772  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 773  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 774  'dgit-distro.debian-security.nominal-distro' => 'debian',
 775  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 776  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 777                'dgit-distro.ubuntu.git-check' => 'false',
 778  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 779                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 780                'dgit-distro.test-dummy.username' => "alice",
 781                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 782                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 783                'dgit-distro.test-dummy.git-url' => "$td/git",
 784                'dgit-distro.test-dummy.git-host' => "git",
 785                'dgit-distro.test-dummy.git-path' => "$td/git",
 786                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 787                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 788                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 789                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 790                );
 791
 792 our %gitcfgs;
 793 our @gitcfgsources = qw(cmdline local global system);
 794 our $invoked_in_git_tree = 1;
 795
 796 sub git_slurp_config () {
 797     # This algoritm is a bit subtle, but this is needed so that for
 798     # options which we want to be single-valued, we allow the
 799     # different config sources to override properly.  See #835858.
 800     foreach my $src (@gitcfgsources) {
 801         next if $src eq 'cmdline';
 802         # we do this ourselves since git doesn't handle it
 803
 804         $gitcfgs{$src} = git_slurp_config_src $src;
 805     }
 806 }
 807
 808 sub git_get_config ($) {
 809     my ($c) = @_;
 810     foreach my $src (@gitcfgsources) {
 811         my $l = $gitcfgs{$src}{$c};
 812         confess "internal error ($l $c)" if $l && !ref $l;
 813         printdebug"C $c ".(defined $l ?
 814                            join " ", map { messagequote "'$_'" } @$l :
 815                            "undef")."\n"
 816             if $debuglevel >= 4;
 817         $l or next;
 818         @$l==1 or badcfg
 819             f_ "multiple values for %s (in %s git config)", $c, $src
 820             if @$l > 1;
 821         $l->[0] =~ m/\n/ and badcfg f_
 822  "value for config option %s (in %s git config) contains newline(s)!",
 823             $c, $src;
 824         return $l->[0];
 825     }
 826     return undef;
 827 }
 828
 829 sub cfg {
 830     foreach my $c (@_) {
 831         return undef if $c =~ /RETURN-UNDEF/;
 832         printdebug "C? $c\n" if $debuglevel >= 5;
 833         my $v = git_get_config($c);
 834         return $v if defined $v;
 835         my $dv = $defcfg{$c};
 836         if (defined $dv) {
 837             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 838             return $dv;
 839         }
 840     }
 841     badcfg f_
 842         "need value for one of: %s\n".
 843         "%s: distro or suite appears not to be (properly) supported",
 844         "@_", $us;
 845 }
 846
 847 sub not_necessarily_a_tree () {
 848     # needs to be called from pre_*
 849     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 850     $invoked_in_git_tree = 0;
 851 }
 852
 853 sub access_basedistro__noalias () {
 854     if (defined $idistro) {
 855         return $idistro;
 856     } else {
 857         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 858         return $def if defined $def;
 859         foreach my $src (@gitcfgsources, 'internal') {
 860             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 861             next unless $kl;
 862             foreach my $k (keys %$kl) {
 863                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 864                 my $dpat = $1;
 865                 next unless match_glob $dpat, $isuite;
 866                 return $kl->{$k};
 867             }
 868         }
 869         return cfg("dgit.default.distro");
 870     }
 871 }
 872
 873 sub access_basedistro () {
 874     my $noalias = access_basedistro__noalias();
 875     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 876     return $canon // $noalias;
 877 }
 878
 879 sub access_nomdistro () {
 880     my $base = access_basedistro();
 881     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 882     $r =~ m/^$distro_re$/ or badcfg
 883         f_ "bad syntax for (nominal) distro \`%s' (does not match %s)",
 884         $r, "/^$distro_re$/";
 885     return $r;
 886 }
 887
 888 sub access_quirk () {
 889     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 890     my $basedistro = access_basedistro();
 891     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 892                               'RETURN-UNDEF');
 893     if (defined $backports_quirk) {
 894         my $re = $backports_quirk;
 895         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 896         $re =~ s/\*/.*/g;
 897         $re =~ s/\%/([-0-9a-z_]+)/
 898             or $re =~ m/[()]/ or badcfg __ "backports-quirk needs \% or ( )";
 899         if ($isuite =~ m/^$re$/) {
 900             return ('backports',"$basedistro-backports",$1);
 901         }
 902     }
 903     return ('none',undef);
 904 }
 905
 906 our $access_forpush;
 907
 908 sub parse_cfg_bool ($$$) {
 909     my ($what,$def,$v) = @_;
 910     $v //= $def;
 911     return
 912         $v =~ m/^[ty1]/ ? 1 :
 913         $v =~ m/^[fn0]/ ? 0 :
 914         badcfg f_ "%s needs t (true, y, 1) or f (false, n, 0) not \`%s'",
 915             $what, $v;
 916 }
 917
 918 sub access_forpush_config () {
 919     my $d = access_basedistro();
 920
 921     return 1 if
 922         $new_package &&
 923         parse_cfg_bool('new-private-pushers', 0,
 924                        cfg("dgit-distro.$d.new-private-pushers",
 925                            'RETURN-UNDEF'));
 926
 927     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 928     $v //= 'a';
 929     return
 930         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 931         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 932         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 933         badcfg __
 934             "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 935 }
 936
 937 sub access_forpush () {
 938     $access_forpush //= access_forpush_config();
 939     return $access_forpush;
 940 }
 941
 942 sub default_from_access_cfg ($$$;$) {
 943     my ($var, $keybase, $defval, $permit_re) = @_;
 944     return if defined $$var;
 945
 946     $$var = access_cfg("$keybase-newer", 'RETURN-UNDEF');
 947     $$var = undef if $$var && $$var !~ m/^$permit_re$/;
 948
 949     $$var //= access_cfg($keybase, 'RETURN-UNDEF');
 950     $$var //= $defval;
 951
 952     badcfg f_ "unknown %s \`%s'", $keybase, $$var
 953         if defined $permit_re and $$var !~ m/$permit_re/;
 954 }
 955
 956 sub pushing () {
 957     confess +(__ 'internal error').' '.Dumper($access_forpush)," ?" if
 958         defined $access_forpush and !$access_forpush;
 959     badcfg __ "pushing but distro is configured readonly"
 960         if access_forpush_config() eq '0';
 961     $access_forpush = 1;
 962     $supplementary_message = __ <<'END' unless $we_are_responder;
 963 Push failed, before we got started.
 964 You can retry the push, after fixing the problem, if you like.
 965 END
 966     parseopts_late_defaults();
 967 }
 968
 969 sub notpushing () {
 970     parseopts_late_defaults();
 971 }
 972
 973 sub supplementary_message ($) {
 974     my ($msg) = @_;
 975     if (!$we_are_responder) {
 976         $supplementary_message = $msg;
 977         return;
 978     } elsif ($protovsn >= 3) {
 979         responder_send_command "supplementary-message ".length($msg)
 980             or confess "$!";
 981         print PO $msg or confess "$!";
 982     }
 983 }
 984
 985 sub access_distros () {
 986     # Returns list of distros to try, in order
 987     #
 988     # We want to try:
 989     #    0. `instead of' distro name(s) we have been pointed to
 990     #    1. the access_quirk distro, if any
 991     #    2a. the user's specified distro, or failing that  } basedistro
 992     #    2b. the distro calculated from the suite          }
 993     my @l = access_basedistro();
 994
 995     my (undef,$quirkdistro) = access_quirk();
 996     unshift @l, $quirkdistro;
 997     unshift @l, $instead_distro;
 998     @l = grep { defined } @l;
 999
1000     push @l, access_nomdistro();
1001
1002     if (access_forpush()) {
1003         @l = map { ("$_/push", $_) } @l;
1004     }
1005     @l;
1006 }
1007
1008 sub access_cfg_cfgs (@) {
1009     my (@keys) = @_;
1010     my @cfgs;
1011     # The nesting of these loops determines the search order.  We put
1012     # the key loop on the outside so that we search all the distros
1013     # for each key, before going on to the next key.  That means that
1014     # if access_cfg is called with a more specific, and then a less
1015     # specific, key, an earlier distro can override the less specific
1016     # without necessarily overriding any more specific keys.  (If the
1017     # distro wants to override the more specific keys it can simply do
1018     # so; whereas if we did the loop the other way around, it would be
1019     # impossible to for an earlier distro to override a less specific
1020     # key but not the more specific ones without restating the unknown
1021     # values of the more specific keys.
1022     my @realkeys;
1023     my @rundef;
1024     # We have to deal with RETURN-UNDEF specially, so that we don't
1025     # terminate the search prematurely.
1026     foreach (@keys) {
1027         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
1028         push @realkeys, $_
1029     }
1030     foreach my $d (access_distros()) {
1031         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
1032     }
1033     push @cfgs, map { "dgit.default.$_" } @realkeys;
1034     push @cfgs, @rundef;
1035     return @cfgs;
1036 }
1037
1038 sub access_cfg (@) {
1039     my (@keys) = @_;
1040     my (@cfgs) = access_cfg_cfgs(@keys);
1041     my $value = cfg(@cfgs);
1042     return $value;
1043 }
1044
1045 sub access_cfg_bool ($$) {
1046     my ($def, @keys) = @_;
1047     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
1048 }
1049
1050 sub string_to_ssh ($) {
1051     my ($spec) = @_;
1052     if ($spec =~ m/\s/) {
1053         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
1054     } else {
1055         return ($spec);
1056     }
1057 }
1058
1059 sub access_cfg_ssh () {
1060     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
1061     if (!defined $gitssh) {
1062         return @ssh;
1063     } else {
1064         return string_to_ssh $gitssh;
1065     }
1066 }
1067
1068 sub access_runeinfo ($) {
1069     my ($info) = @_;
1070     return ": dgit ".access_basedistro()." $info ;";
1071 }
1072
1073 sub access_someuserhost ($) {
1074     my ($some) = @_;
1075     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
1076     defined($user) && length($user) or
1077         $user = access_cfg("$some-user",'username');
1078     my $host = access_cfg("$some-host");
1079     return length($user) ? "$user\@$host" : $host;
1080 }
1081
1082 sub access_gituserhost () {
1083     return access_someuserhost('git');
1084 }
1085
1086 sub access_giturl (;$) {
1087     my ($optional) = @_;
1088     my $url = access_cfg('git-url','RETURN-UNDEF');
1089     my $suffix;
1090     if (!length $url) {
1091         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
1092         return undef unless defined $proto;
1093         $url =
1094             $proto.
1095             access_gituserhost().
1096             access_cfg('git-path');
1097     } else {
1098         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
1099     }
1100     $suffix //= '.git';
1101     return "$url/$package$suffix";
1102 }
1103
1104 sub commit_getclogp ($) {
1105     # Returns the parsed changelog hashref for a particular commit
1106     my ($objid) = @_;
1107     our %commit_getclogp_memo;
1108     my $memo = $commit_getclogp_memo{$objid};
1109     return $memo if $memo;
1110
1111     my $mclog = dgit_privdir()."clog";
1112     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1113         "$objid:debian/changelog";
1114     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1115 }
1116
1117 sub parse_dscdata () {
1118     my $dscfh = new IO::File \$dscdata, '<' or confess "$!";
1119     printdebug Dumper($dscdata) if $debuglevel>1;
1120     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1121     printdebug Dumper($dsc) if $debuglevel>1;
1122 }
1123
1124 our %rmad;
1125
1126 sub archive_query ($;@) {
1127     my ($method) = shift @_;
1128     fail __ "this operation does not support multiple comma-separated suites"
1129         if $isuite =~ m/,/;
1130     my $query = access_cfg('archive-query','RETURN-UNDEF');
1131     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1132     my $proto = $1;
1133     my $data = $'; #';
1134     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1135 }
1136
1137 sub archive_query_prepend_mirror {
1138     my $m = access_cfg('mirror');
1139     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1140 }
1141
1142 sub pool_dsc_subpath ($$) {
1143     my ($vsn,$component) = @_; # $package is implict arg
1144     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1145     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1146 }
1147
1148 sub cfg_apply_map ($$$) {
1149     my ($varref, $what, $mapspec) = @_;
1150     return unless $mapspec;
1151
1152     printdebug "config $what EVAL{ $mapspec; }\n";
1153     $_ = $$varref;
1154     eval "package Dgit::Config; $mapspec;";
1155     die $@ if $@;
1156     $$varref = $_;
1157 }
1158
1159 #---------- `ftpmasterapi' archive query method (nascent) ----------
1160
1161 sub archive_api_query_cmd ($) {
1162     my ($subpath) = @_;
1163     my @cmd = (@curl, qw(-sS));
1164     my $url = access_cfg('archive-query-url');
1165     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1166         my $host = $1;
1167         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1168         foreach my $key (split /\:/, $keys) {
1169             $key =~ s/\%HOST\%/$host/g;
1170             if (!stat $key) {
1171                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1172                 next;
1173             }
1174             fail f_ "config requested specific TLS key but do not know".
1175                     " how to get curl to use exactly that EE key (%s)",
1176                     $key;
1177 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1178 #           # Sadly the above line does not work because of changes
1179 #           # to gnutls.   The real fix for #790093 may involve
1180 #           # new curl options.
1181             last;
1182         }
1183         # Fixing #790093 properly will involve providing a value
1184         # for this on clients.
1185         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1186         push @cmd, split / /, $kargs if defined $kargs;
1187     }
1188     push @cmd, $url.$subpath;
1189     return @cmd;
1190 }
1191
1192 sub api_query ($$;$) {
1193     use JSON;
1194     my ($data, $subpath, $ok404) = @_;
1195     badcfg __ "ftpmasterapi archive query method takes no data part"
1196         if length $data;
1197     my @cmd = archive_api_query_cmd($subpath);
1198     my $url = $cmd[$#cmd];
1199     push @cmd, qw(-w %{http_code});
1200     my $json = cmdoutput @cmd;
1201     unless ($json =~ s/\d+\d+\d$//) {
1202         failedcmd_report_cmd undef, @cmd;
1203         fail __ "curl failed to print 3-digit HTTP code";
1204     }
1205     my $code = $&;
1206     return undef if $code eq '404' && $ok404;
1207     fail f_ "fetch of %s gave HTTP code %s", $url, $code
1208         unless $url =~ m#^file://# or $code =~ m/^2/;
1209     return decode_json($json);
1210 }
1211
1212 sub canonicalise_suite_ftpmasterapi {
1213     my ($proto,$data) = @_;
1214     my $suites = api_query($data, 'suites');
1215     my @matched;
1216     foreach my $entry (@$suites) {
1217         next unless grep {
1218             my $v = $entry->{$_};
1219             defined $v && $v eq $isuite;
1220         } qw(codename name);
1221         push @matched, $entry;
1222     }
1223     fail f_ "unknown suite %s, maybe -d would help", $isuite
1224         unless @matched;
1225     my $cn;
1226     eval {
1227         @matched==1 or die f_ "multiple matches for suite %s\n", $isuite;
1228         $cn = "$matched[0]{codename}";
1229         defined $cn or die f_ "suite %s info has no codename\n", $isuite;
1230         $cn =~ m/^$suite_re$/
1231             or die f_ "suite %s maps to bad codename\n", $isuite;
1232     };
1233     die +(__ "bad ftpmaster api response: ")."$@\n".Dumper(\@matched)
1234         if length $@;
1235     return $cn;
1236 }
1237
1238 sub archive_query_ftpmasterapi {
1239     my ($proto,$data) = @_;
1240     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1241     my @rows;
1242     my $digester = Digest::SHA->new(256);
1243     foreach my $entry (@$info) {
1244         eval {
1245             my $vsn = "$entry->{version}";
1246             my ($ok,$msg) = version_check $vsn;
1247             die f_ "bad version: %s\n", $msg unless $ok;
1248             my $component = "$entry->{component}";
1249             $component =~ m/^$component_re$/ or die __ "bad component";
1250             my $filename = "$entry->{filename}";
1251             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1252                 or die __ "bad filename";
1253             my $sha256sum = "$entry->{sha256sum}";
1254             $sha256sum =~ m/^[0-9a-f]+$/ or die __ "bad sha256sum";
1255             push @rows, [ $vsn, "/pool/$component/$filename",
1256                           $digester, $sha256sum ];
1257         };
1258         die +(__ "bad ftpmaster api response: ")."$@\n".Dumper($entry)
1259             if length $@;
1260     }
1261     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1262     return archive_query_prepend_mirror @rows;
1263 }
1264
1265 sub file_in_archive_ftpmasterapi {
1266     my ($proto,$data,$filename) = @_;
1267     my $pat = $filename;
1268     $pat =~ s/_/\\_/g;
1269     $pat = "%/$pat";
1270     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1271     my $info = api_query($data, "file_in_archive/$pat", 1);
1272 }
1273
1274 sub package_not_wholly_new_ftpmasterapi {
1275     my ($proto,$data,$pkg) = @_;
1276     my $info = api_query($data,"madison?package=${pkg}&f=json");
1277     return !!@$info;
1278 }
1279
1280 #---------- `aptget' archive query method ----------
1281
1282 our $aptget_base;
1283 our $aptget_releasefile;
1284 our $aptget_configpath;
1285
1286 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1287 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1288
1289 sub aptget_cache_clean {
1290     runcmd_ordryrun_local qw(sh -ec),
1291         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1292         'x', $aptget_base;
1293 }
1294
1295 sub aptget_lock_acquire () {
1296     my $lockfile = "$aptget_base/lock";
1297     open APTGET_LOCK, '>', $lockfile or confess "open $lockfile: $!";
1298     flock APTGET_LOCK, LOCK_EX or confess "lock $lockfile: $!";
1299 }
1300
1301 sub aptget_prep ($) {
1302     my ($data) = @_;
1303     return if defined $aptget_base;
1304
1305     badcfg __ "aptget archive query method takes no data part"
1306         if length $data;
1307
1308     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1309
1310     ensuredir $cache;
1311     ensuredir "$cache/dgit";
1312     my $cachekey =
1313         access_cfg('aptget-cachekey','RETURN-UNDEF')
1314         // access_nomdistro();
1315
1316     $aptget_base = "$cache/dgit/aptget";
1317     ensuredir $aptget_base;
1318
1319     my $quoted_base = $aptget_base;
1320     confess "$quoted_base contains bad chars, cannot continue"
1321         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1322
1323     ensuredir $aptget_base;
1324
1325     aptget_lock_acquire();
1326
1327     aptget_cache_clean();
1328
1329     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1330     my $sourceslist = "source.list#$cachekey";
1331
1332     my $aptsuites = $isuite;
1333     cfg_apply_map(\$aptsuites, 'suite map',
1334                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1335
1336     open SRCS, ">", "$aptget_base/$sourceslist" or confess "$!";
1337     printf SRCS "deb-src %s %s %s\n",
1338         access_cfg('mirror'),
1339         $aptsuites,
1340         access_cfg('aptget-components')
1341         or confess "$!";
1342
1343     ensuredir "$aptget_base/cache";
1344     ensuredir "$aptget_base/lists";
1345
1346     open CONF, ">", $aptget_configpath or confess "$!";
1347     print CONF <<END;
1348 Debug::NoLocking "true";
1349 APT::Get::List-Cleanup "false";
1350 #clear APT::Update::Post-Invoke-Success;
1351 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1352 Dir::State::Lists "$quoted_base/lists";
1353 Dir::Etc::preferences "$quoted_base/preferences";
1354 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1355 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1356 END
1357
1358     foreach my $key (qw(
1359                         Dir::Cache
1360                         Dir::State
1361                         Dir::Cache::Archives
1362                         Dir::Etc::SourceParts
1363                         Dir::Etc::preferencesparts
1364                       )) {
1365         ensuredir "$aptget_base/$key";
1366         print CONF "$key \"$quoted_base/$key\";\n" or confess "$!";
1367     };
1368
1369     my $oldatime = (time // confess "$!") - 1;
1370     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1371         next unless stat_exists $oldlist;
1372         my ($mtime) = (stat _)[9];
1373         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1374     }
1375
1376     runcmd_ordryrun_local aptget_aptget(), qw(update);
1377
1378     my @releasefiles;
1379     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1380         next unless stat_exists $oldlist;
1381         my ($atime) = (stat _)[8];
1382         next if $atime == $oldatime;
1383         push @releasefiles, $oldlist;
1384     }
1385     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1386     @releasefiles = @inreleasefiles if @inreleasefiles;
1387     if (!@releasefiles) {
1388         fail f_ <<END, $isuite, $cache;
1389 apt seemed to not to update dgit's cached Release files for %s.
1390 (Perhaps %s
1391  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1392 END
1393     }
1394     confess "apt updated too many Release files (@releasefiles), erk"
1395         unless @releasefiles == 1;
1396
1397     ($aptget_releasefile) = @releasefiles;
1398 }
1399
1400 sub canonicalise_suite_aptget {
1401     my ($proto,$data) = @_;
1402     aptget_prep($data);
1403
1404     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1405
1406     foreach my $name (qw(Codename Suite)) {
1407         my $val = $release->{$name};
1408         if (defined $val) {
1409             printdebug "release file $name: $val\n";
1410             $val =~ m/^$suite_re$/o or fail f_
1411                 "Release file (%s) specifies intolerable %s",
1412                 $aptget_releasefile, $name;
1413             cfg_apply_map(\$val, 'suite rmap',
1414                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1415             return $val
1416         }
1417     }
1418     return $isuite;
1419 }
1420
1421 sub archive_query_aptget {
1422     my ($proto,$data) = @_;
1423     aptget_prep($data);
1424
1425     ensuredir "$aptget_base/source";
1426     foreach my $old (<$aptget_base/source/*.dsc>) {
1427         unlink $old or die "$old: $!";
1428     }
1429
1430     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1431     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1432     # avoids apt-get source failing with ambiguous error code
1433
1434     runcmd_ordryrun_local
1435         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1436         aptget_aptget(), qw(--download-only --only-source source), $package;
1437
1438     my @dscs = <$aptget_base/source/*.dsc>;
1439     fail __ "apt-get source did not produce a .dsc" unless @dscs;
1440     fail f_ "apt-get source produced several .dscs (%s)", "@dscs"
1441         unless @dscs==1;
1442
1443     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1444
1445     use URI::Escape;
1446     my $uri = "file://". uri_escape $dscs[0];
1447     $uri =~ s{\%2f}{/}gi;
1448     return [ (getfield $pre_dsc, 'Version'), $uri ];
1449 }
1450
1451 sub file_in_archive_aptget () { return undef; }
1452 sub package_not_wholly_new_aptget () { return undef; }
1453
1454 #---------- `dummyapicat' archive query method ----------
1455 # (untranslated, because this is for testing purposes etc.)
1456
1457 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1458 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1459
1460 sub dummycatapi_run_in_mirror ($@) {
1461     # runs $fn with FIA open onto rune
1462     my ($rune, $argl, $fn) = @_;
1463
1464     my $mirror = access_cfg('mirror');
1465     $mirror =~ s#^file://#/# or die "$mirror ?";
1466     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1467                qw(x), $mirror, @$argl);
1468     debugcmd "-|", @cmd;
1469     open FIA, "-|", @cmd or confess "$!";
1470     my $r = $fn->();
1471     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1472     return $r;
1473 }
1474
1475 sub file_in_archive_dummycatapi ($$$) {
1476     my ($proto,$data,$filename) = @_;
1477     my @out;
1478     dummycatapi_run_in_mirror '
1479             find -name "$1" -print0 |
1480             xargs -0r sha256sum
1481     ', [$filename], sub {
1482         while (<FIA>) {
1483             chomp or die;
1484             printdebug "| $_\n";
1485             m/^(\w+)  (\S+)$/ or die "$_ ?";
1486             push @out, { sha256sum => $1, filename => $2 };
1487         }
1488     };
1489     return \@out;
1490 }
1491
1492 sub package_not_wholly_new_dummycatapi {
1493     my ($proto,$data,$pkg) = @_;
1494     dummycatapi_run_in_mirror "
1495             find -name ${pkg}_*.dsc
1496     ", [], sub {
1497         local $/ = undef;
1498         !!<FIA>;
1499     };
1500 }
1501
1502 #---------- `madison' archive query method ----------
1503
1504 sub archive_query_madison {
1505     return archive_query_prepend_mirror
1506         map { [ @$_[0..1] ] } madison_get_parse(@_);
1507 }
1508
1509 sub madison_get_parse {
1510     my ($proto,$data) = @_;
1511     die unless $proto eq 'madison';
1512     if (!length $data) {
1513         $data= access_cfg('madison-distro','RETURN-UNDEF');
1514         $data //= access_basedistro();
1515     }
1516     $rmad{$proto,$data,$package} ||= cmdoutput
1517         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1518     my $rmad = $rmad{$proto,$data,$package};
1519
1520     my @out;
1521     foreach my $l (split /\n/, $rmad) {
1522         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1523                   \s*( [^ \t|]+ )\s* \|
1524                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1525                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1526         $1 eq $package or die "$rmad $package ?";
1527         my $vsn = $2;
1528         my $newsuite = $3;
1529         my $component;
1530         if (defined $4) {
1531             $component = $4;
1532         } else {
1533             $component = access_cfg('archive-query-default-component');
1534         }
1535         $5 eq 'source' or die "$rmad ?";
1536         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1537     }
1538     return sort { -version_compare($a->[0],$b->[0]); } @out;
1539 }
1540
1541 sub canonicalise_suite_madison {
1542     # madison canonicalises for us
1543     my @r = madison_get_parse(@_);
1544     @r or fail f_
1545         "unable to canonicalise suite using package %s".
1546         " which does not appear to exist in suite %s;".
1547         " --existing-package may help",
1548         $package, $isuite;
1549     return $r[0][2];
1550 }
1551
1552 sub file_in_archive_madison { return undef; }
1553 sub package_not_wholly_new_madison { return undef; }
1554
1555 #---------- `sshpsql' archive query method ----------
1556 # (untranslated, because this is obsolete)
1557
1558 sub sshpsql ($$$) {
1559     my ($data,$runeinfo,$sql) = @_;
1560     if (!length $data) {
1561         $data= access_someuserhost('sshpsql').':'.
1562             access_cfg('sshpsql-dbname');
1563     }
1564     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1565     my ($userhost,$dbname) = ($`,$'); #';
1566     my @rows;
1567     my @cmd = (access_cfg_ssh, $userhost,
1568                access_runeinfo("ssh-psql $runeinfo").
1569                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1570                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1571     debugcmd "|",@cmd;
1572     open P, "-|", @cmd or confess "$!";
1573     while (<P>) {
1574         chomp or die;
1575         printdebug(">|$_|\n");
1576         push @rows, $_;
1577     }
1578     $!=0; $?=0; close P or failedcmd @cmd;
1579     @rows or die;
1580     my $nrows = pop @rows;
1581     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1582     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1583     @rows = map { [ split /\|/, $_ ] } @rows;
1584     my $ncols = scalar @{ shift @rows };
1585     die if grep { scalar @$_ != $ncols } @rows;
1586     return @rows;
1587 }
1588
1589 sub sql_injection_check {
1590     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1591 }
1592
1593 sub archive_query_sshpsql ($$) {
1594     my ($proto,$data) = @_;
1595     sql_injection_check $isuite, $package;
1596     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1597         SELECT source.version, component.name, files.filename, files.sha256sum
1598           FROM source
1599           JOIN src_associations ON source.id = src_associations.source
1600           JOIN suite ON suite.id = src_associations.suite
1601           JOIN dsc_files ON dsc_files.source = source.id
1602           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1603           JOIN component ON component.id = files_archive_map.component_id
1604           JOIN files ON files.id = dsc_files.file
1605          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1606            AND source.source='$package'
1607            AND files.filename LIKE '%.dsc';
1608 END
1609     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1610     my $digester = Digest::SHA->new(256);
1611     @rows = map {
1612         my ($vsn,$component,$filename,$sha256sum) = @$_;
1613         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1614     } @rows;
1615     return archive_query_prepend_mirror @rows;
1616 }
1617
1618 sub canonicalise_suite_sshpsql ($$) {
1619     my ($proto,$data) = @_;
1620     sql_injection_check $isuite;
1621     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1622         SELECT suite.codename
1623           FROM suite where suite_name='$isuite' or codename='$isuite';
1624 END
1625     @rows = map { $_->[0] } @rows;
1626     fail "unknown suite $isuite" unless @rows;
1627     die "ambiguous $isuite: @rows ?" if @rows>1;
1628     return $rows[0];
1629 }
1630
1631 sub file_in_archive_sshpsql ($$$) { return undef; }
1632 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1633
1634 #---------- `dummycat' archive query method ----------
1635 # (untranslated, because this is for testing purposes etc.)
1636
1637 sub canonicalise_suite_dummycat ($$) {
1638     my ($proto,$data) = @_;
1639     my $dpath = "$data/suite.$isuite";
1640     if (!open C, "<", $dpath) {
1641         $!==ENOENT or die "$dpath: $!";
1642         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1643         return $isuite;
1644     }
1645     $!=0; $_ = <C>;
1646     chomp or die "$dpath: $!";
1647     close C;
1648     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1649     return $_;
1650 }
1651
1652 sub archive_query_dummycat ($$) {
1653     my ($proto,$data) = @_;
1654     canonicalise_suite();
1655     my $dpath = "$data/package.$csuite.$package";
1656     if (!open C, "<", $dpath) {
1657         $!==ENOENT or die "$dpath: $!";
1658         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1659         return ();
1660     }
1661     my @rows;
1662     while (<C>) {
1663         next if m/^\#/;
1664         next unless m/\S/;
1665         die unless chomp;
1666         printdebug "dummycat query $csuite $package $dpath | $_\n";
1667         my @row = split /\s+/, $_;
1668         @row==2 or die "$dpath: $_ ?";
1669         push @rows, \@row;
1670     }
1671     C->error and die "$dpath: $!";
1672     close C;
1673     return archive_query_prepend_mirror
1674         sort { -version_compare($a->[0],$b->[0]); } @rows;
1675 }
1676
1677 sub file_in_archive_dummycat () { return undef; }
1678 sub package_not_wholly_new_dummycat () { return undef; }
1679
1680 #---------- archive query entrypoints and rest of program ----------
1681
1682 sub canonicalise_suite () {
1683     return if defined $csuite;
1684     fail f_ "cannot operate on %s suite", $isuite if $isuite eq 'UNRELEASED';
1685     $csuite = archive_query('canonicalise_suite');
1686     if ($isuite ne $csuite) {
1687         progress f_ "canonical suite name for %s is %s", $isuite, $csuite;
1688     } else {
1689         progress f_ "canonical suite name is %s", $csuite;
1690     }
1691 }
1692
1693 sub get_archive_dsc () {
1694     canonicalise_suite();
1695     my @vsns = archive_query('archive_query');
1696     foreach my $vinfo (@vsns) {
1697         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1698         $dscurl = $vsn_dscurl;
1699         $dscdata = url_get($dscurl);
1700         if (!$dscdata) {
1701             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1702             next;
1703         }
1704         if ($digester) {
1705             $digester->reset();
1706             $digester->add($dscdata);
1707             my $got = $digester->hexdigest();
1708             $got eq $digest or
1709                 fail f_ "%s has hash %s but archive told us to expect %s",
1710                         $dscurl, $got, $digest;
1711         }
1712         parse_dscdata();
1713         my $fmt = getfield $dsc, 'Format';
1714         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1715             f_ "unsupported source format %s, sorry", $fmt;
1716
1717         $dsc_checked = !!$digester;
1718         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1719         return;
1720     }
1721     $dsc = undef;
1722     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1723 }
1724
1725 sub check_for_git ();
1726 sub check_for_git () {
1727     # returns 0 or 1
1728     my $how = access_cfg('git-check');
1729     if ($how eq 'ssh-cmd') {
1730         my @cmd =
1731             (access_cfg_ssh, access_gituserhost(),
1732              access_runeinfo("git-check $package").
1733              " set -e; cd ".access_cfg('git-path').";".
1734              " if test -d $package.git; then echo 1; else echo 0; fi");
1735         my $r= cmdoutput @cmd;
1736         if (defined $r and $r =~ m/^divert (\w+)$/) {
1737             my $divert=$1;
1738             my ($usedistro,) = access_distros();
1739             # NB that if we are pushing, $usedistro will be $distro/push
1740             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1741             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1742             progress f_ "diverting to %s (using config for %s)",
1743                         $divert, $instead_distro;
1744             return check_for_git();
1745         }
1746         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1747         return $r+0;
1748     } elsif ($how eq 'url') {
1749         my $prefix = access_cfg('git-check-url','git-url');
1750         my $suffix = access_cfg('git-check-suffix','git-suffix',
1751                                 'RETURN-UNDEF') // '.git';
1752         my $url = "$prefix/$package$suffix";
1753         my @cmd = (@curl, qw(-sS -I), $url);
1754         my $result = cmdoutput @cmd;
1755         $result =~ s/^\S+ 200 .*\n\r?\n//;
1756         # curl -sS -I with https_proxy prints
1757         # HTTP/1.0 200 Connection established
1758         $result =~ m/^\S+ (404|200) /s or
1759             fail +(__ "unexpected results from git check query - ").
1760                 Dumper($prefix, $result);
1761         my $code = $1;
1762         if ($code eq '404') {
1763             return 0;
1764         } elsif ($code eq '200') {
1765             return 1;
1766         } else {
1767             die;
1768         }
1769     } elsif ($how eq 'true') {
1770         return 1;
1771     } elsif ($how eq 'false') {
1772         return 0;
1773     } else {
1774         badcfg f_ "unknown git-check \`%s'", $how;
1775     }
1776 }
1777
1778 sub create_remote_git_repo () {
1779     my $how = access_cfg('git-create');
1780     if ($how eq 'ssh-cmd') {
1781         runcmd_ordryrun
1782             (access_cfg_ssh, access_gituserhost(),
1783              access_runeinfo("git-create $package").
1784              "set -e; cd ".access_cfg('git-path').";".
1785              " cp -a _template $package.git");
1786     } elsif ($how eq 'true') {
1787         # nothing to do
1788     } else {
1789         badcfg f_ "unknown git-create \`%s'", $how;
1790     }
1791 }
1792
1793 our ($dsc_hash,$lastpush_mergeinput);
1794 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1795
1796
1797 sub prep_ud () {
1798     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1799     $playground = fresh_playground 'dgit/unpack';
1800 }
1801
1802 sub mktree_in_ud_here () {
1803     playtree_setup $gitcfgs{local};
1804 }
1805
1806 sub git_write_tree () {
1807     my $tree = cmdoutput @git, qw(write-tree);
1808     $tree =~ m/^\w+$/ or die "$tree ?";
1809     return $tree;
1810 }
1811
1812 sub git_add_write_tree () {
1813     runcmd @git, qw(add -Af .);
1814     return git_write_tree();
1815 }
1816
1817 sub remove_stray_gits ($) {
1818     my ($what) = @_;
1819     my @gitscmd = qw(find -name .git -prune -print0);
1820     debugcmd "|",@gitscmd;
1821     open GITS, "-|", @gitscmd or confess "$!";
1822     {
1823         local $/="\0";
1824         while (<GITS>) {
1825             chomp or die;
1826             print STDERR f_ "%s: warning: removing from %s: %s\n",
1827                 $us, $what, (messagequote $_);
1828             rmtree $_;
1829         }
1830     }
1831     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1832 }
1833
1834 sub mktree_in_ud_from_only_subdir ($;$) {
1835     my ($what,$raw) = @_;
1836     # changes into the subdir
1837
1838     my (@dirs) = <*/.>;
1839     confess "expected one subdir but found @dirs ?" unless @dirs==1;
1840     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1841     my $dir = $1;
1842     changedir $dir;
1843
1844     remove_stray_gits($what);
1845     mktree_in_ud_here();
1846     if (!$raw) {
1847         my ($format, $fopts) = get_source_format();
1848         if (madformat($format)) {
1849             rmtree '.pc';
1850         }
1851     }
1852
1853     my $tree=git_add_write_tree();
1854     return ($tree,$dir);
1855 }
1856
1857 our @files_csum_info_fields =
1858     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1859      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1860      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1861
1862 sub dsc_files_info () {
1863     foreach my $csumi (@files_csum_info_fields) {
1864         my ($fname, $module, $method) = @$csumi;
1865         my $field = $dsc->{$fname};
1866         next unless defined $field;
1867         eval "use $module; 1;" or die $@;
1868         my @out;
1869         foreach (split /\n/, $field) {
1870             next unless m/\S/;
1871             m/^(\w+) (\d+) (\S+)$/ or
1872                 fail f_ "could not parse .dsc %s line \`%s'", $fname, $_;
1873             my $digester = eval "$module"."->$method;" or die $@;
1874             push @out, {
1875                 Hash => $1,
1876                 Bytes => $2,
1877                 Filename => $3,
1878                 Digester => $digester,
1879             };
1880         }
1881         return @out;
1882     }
1883     fail f_ "missing any supported Checksums-* or Files field in %s",
1884             $dsc->get_option('name');
1885 }
1886
1887 sub dsc_files () {
1888     map { $_->{Filename} } dsc_files_info();
1889 }
1890
1891 sub files_compare_inputs (@) {
1892     my $inputs = \@_;
1893     my %record;
1894     my %fchecked;
1895
1896     my $showinputs = sub {
1897         return join "; ", map { $_->get_option('name') } @$inputs;
1898     };
1899
1900     foreach my $in (@$inputs) {
1901         my $expected_files;
1902         my $in_name = $in->get_option('name');
1903
1904         printdebug "files_compare_inputs $in_name\n";
1905
1906         foreach my $csumi (@files_csum_info_fields) {
1907             my ($fname) = @$csumi;
1908             printdebug "files_compare_inputs $in_name $fname\n";
1909
1910             my $field = $in->{$fname};
1911             next unless defined $field;
1912
1913             my @files;
1914             foreach (split /\n/, $field) {
1915                 next unless m/\S/;
1916
1917                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1918                     fail "could not parse $in_name $fname line \`$_'";
1919
1920                 printdebug "files_compare_inputs $in_name $fname $f\n";
1921
1922                 push @files, $f;
1923
1924                 my $re = \ $record{$f}{$fname};
1925                 if (defined $$re) {
1926                     $fchecked{$f}{$in_name} = 1;
1927                     $$re eq $info or
1928                         fail f_
1929               "hash or size of %s varies in %s fields (between: %s)",
1930                                  $f, $fname, $showinputs->();
1931                 } else {
1932                     $$re = $info;
1933                 }
1934             }
1935             @files = sort @files;
1936             $expected_files //= \@files;
1937             "@$expected_files" eq "@files" or
1938                 fail f_ "file list in %s varies between hash fields!",
1939                         $in_name;
1940         }
1941         $expected_files or
1942             fail f_ "%s has no files list field(s)", $in_name;
1943     }
1944     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1945         if $debuglevel>=2;
1946
1947     grep { keys %$_ == @$inputs-1 } values %fchecked
1948         or fail f_ "no file appears in all file lists (looked in: %s)",
1949                    $showinputs->();
1950 }
1951
1952 sub is_orig_file_in_dsc ($$) {
1953     my ($f, $dsc_files_info) = @_;
1954     return 0 if @$dsc_files_info <= 1;
1955     # One file means no origs, and the filename doesn't have a "what
1956     # part of dsc" component.  (Consider versions ending `.orig'.)
1957     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1958     return 1;
1959 }
1960
1961 # This function determines whether a .changes file is source-only from
1962 # the point of view of dak.  Thus, it permits *_source.buildinfo
1963 # files.
1964 #
1965 # It does not, however, permit any other buildinfo files.  After a
1966 # source-only upload, the buildds will try to upload files like
1967 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1968 # named like this in their (otherwise) source-only upload, the uploads
1969 # of the buildd can be rejected by dak.  Fixing the resultant
1970 # situation can require manual intervention.  So we block such
1971 # .buildinfo files when the user tells us to perform a source-only
1972 # upload (such as when using the push-source subcommand with the -C
1973 # option, which calls this function).
1974 #
1975 # Note, though, that when dgit is told to prepare a source-only
1976 # upload, such as when subcommands like build-source and push-source
1977 # without -C are used, dgit has a more restrictive notion of
1978 # source-only .changes than dak: such uploads will never include
1979 # *_source.buildinfo files.  This is because there is no use for such
1980 # files when using a tool like dgit to produce the source package, as
1981 # dgit ensures the source is identical to git HEAD.
1982 sub test_source_only_changes ($) {
1983     my ($changes) = @_;
1984     foreach my $l (split /\n/, getfield $changes, 'Files') {
1985         $l =~ m/\S+$/ or next;
1986         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
1987         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
1988             print f_ "purportedly source-only changes polluted by %s\n", $&;
1989             return 0;
1990         }
1991     }
1992     return 1;
1993 }
1994
1995 sub changes_update_origs_from_dsc ($$$$) {
1996     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1997     my %changes_f;
1998     printdebug "checking origs needed ($upstreamvsn)...\n";
1999     $_ = getfield $changes, 'Files';
2000     m/^\w+ \d+ (\S+ \S+) \S+$/m or
2001         fail __ "cannot find section/priority from .changes Files field";
2002     my $placementinfo = $1;
2003     my %changed;
2004     printdebug "checking origs needed placement '$placementinfo'...\n";
2005     foreach my $l (split /\n/, getfield $dsc, 'Files') {
2006         $l =~ m/\S+$/ or next;
2007         my $file = $&;
2008         printdebug "origs $file | $l\n";
2009         next unless is_orig_file_of_vsn $file, $upstreamvsn;
2010         printdebug "origs $file is_orig\n";
2011         my $have = archive_query('file_in_archive', $file);
2012         if (!defined $have) {
2013             print STDERR __ <<END;
2014 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
2015 END
2016             return;
2017         }
2018         my $found_same = 0;
2019         my @found_differ;
2020         printdebug "origs $file \$#\$have=$#$have\n";
2021         foreach my $h (@$have) {
2022             my $same = 0;
2023             my @differ;
2024             foreach my $csumi (@files_csum_info_fields) {
2025                 my ($fname, $module, $method, $archivefield) = @$csumi;
2026                 next unless defined $h->{$archivefield};
2027                 $_ = $dsc->{$fname};
2028                 next unless defined;
2029                 m/^(\w+) .* \Q$file\E$/m or
2030                     fail f_ ".dsc %s missing entry for %s", $fname, $file;
2031                 if ($h->{$archivefield} eq $1) {
2032                     $same++;
2033                 } else {
2034                     push @differ, f_
2035                         "%s: %s (archive) != %s (local .dsc)",
2036                         $archivefield, $h->{$archivefield}, $1;
2037                 }
2038             }
2039             confess "$file ".Dumper($h)." ?!" if $same && @differ;
2040             $found_same++
2041                 if $same;
2042             push @found_differ,
2043                 f_ "archive %s: %s", $h->{filename}, join "; ", @differ
2044                 if @differ;
2045         }
2046         printdebug "origs $file f.same=$found_same".
2047             " #f._differ=$#found_differ\n";
2048         if (@found_differ && !$found_same) {
2049             fail join "\n",
2050                 (f_ "archive contains %s with different checksum", $file),
2051                 @found_differ;
2052         }
2053         # Now we edit the changes file to add or remove it
2054         foreach my $csumi (@files_csum_info_fields) {
2055             my ($fname, $module, $method, $archivefield) = @$csumi;
2056             next unless defined $changes->{$fname};
2057             if ($found_same) {
2058                 # in archive, delete from .changes if it's there
2059                 $changed{$file} = "removed" if
2060                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
2061             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
2062                 # not in archive, but it's here in the .changes
2063             } else {
2064                 my $dsc_data = getfield $dsc, $fname;
2065                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
2066                 my $extra = $1;
2067                 $extra =~ s/ \d+ /$&$placementinfo /
2068                     or confess "$fname $extra >$dsc_data< ?"
2069                     if $fname eq 'Files';
2070                 $changes->{$fname} .= "\n". $extra;
2071                 $changed{$file} = "added";
2072             }
2073         }
2074     }
2075     if (%changed) {
2076         foreach my $file (keys %changed) {
2077             progress f_
2078                 "edited .changes for archive .orig contents: %s %s",
2079                 $changed{$file}, $file;
2080         }
2081         my $chtmp = "$changesfile.tmp";
2082         $changes->save($chtmp);
2083         if (act_local()) {
2084             rename $chtmp,$changesfile or die "$changesfile $!";
2085         } else {
2086             progress f_ "[new .changes left in %s]", $changesfile;
2087         }
2088     } else {
2089         progress f_ "%s already has appropriate .orig(s) (if any)",
2090                     $changesfile;
2091     }
2092 }
2093
2094 sub make_commit ($) {
2095     my ($file) = @_;
2096     return cmdoutput @git, qw(hash-object -w -t commit), $file;
2097 }
2098
2099 sub clogp_authline ($) {
2100     my ($clogp) = @_;
2101     my $author = getfield $clogp, 'Maintainer';
2102     if ($author =~ m/^[^"\@]+\,/) {
2103         # single entry Maintainer field with unquoted comma
2104         $author = ($& =~ y/,//rd).$'; # strip the comma
2105     }
2106     # git wants a single author; any remaining commas in $author
2107     # are by now preceded by @ (or ").  It seems safer to punt on
2108     # "..." for now rather than attempting to dequote or something.
2109     $author =~ s#,.*##ms unless $author =~ m/"/;
2110     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2111     my $authline = "$author $date";
2112     $authline =~ m/$git_authline_re/o or
2113         fail f_ "unexpected commit author line format \`%s'".
2114                 " (was generated from changelog Maintainer field)",
2115                 $authline;
2116     return ($1,$2,$3) if wantarray;
2117     return $authline;
2118 }
2119
2120 sub vendor_patches_distro ($$) {
2121     my ($checkdistro, $what) = @_;
2122     return unless defined $checkdistro;
2123
2124     my $series = "debian/patches/\L$checkdistro\E.series";
2125     printdebug "checking for vendor-specific $series ($what)\n";
2126
2127     if (!open SERIES, "<", $series) {
2128         confess "$series $!" unless $!==ENOENT;
2129         return;
2130     }
2131     while (<SERIES>) {
2132         next unless m/\S/;
2133         next if m/^\s+\#/;
2134
2135         print STDERR __ <<END;
2136
2137 Unfortunately, this source package uses a feature of dpkg-source where
2138 the same source package unpacks to different source code on different
2139 distros.  dgit cannot safely operate on such packages on affected
2140 distros, because the meaning of source packages is not stable.
2141
2142 Please ask the distro/maintainer to remove the distro-specific series
2143 files and use a different technique (if necessary, uploading actually
2144 different packages, if different distros are supposed to have
2145 different code).
2146
2147 END
2148         fail f_ "Found active distro-specific series file for".
2149                 " %s (%s): %s, cannot continue",
2150                 $checkdistro, $what, $series;
2151     }
2152     die "$series $!" if SERIES->error;
2153     close SERIES;
2154 }
2155
2156 sub check_for_vendor_patches () {
2157     # This dpkg-source feature doesn't seem to be documented anywhere!
2158     # But it can be found in the changelog (reformatted):
2159
2160     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2161     #   Author: Raphael Hertzog <hertzog@debian.org>
2162     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2163
2164     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2165     #   series files
2166     #
2167     #   If you have debian/patches/ubuntu.series and you were
2168     #   unpacking the source package on ubuntu, quilt was still
2169     #   directed to debian/patches/series instead of
2170     #   debian/patches/ubuntu.series.
2171     #
2172     #   debian/changelog                        |    3 +++
2173     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2174     #   2 files changed, 6 insertions(+), 1 deletion(-)
2175
2176     use Dpkg::Vendor;
2177     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2178     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2179                           __ "Dpkg::Vendor \`current vendor'");
2180     vendor_patches_distro(access_basedistro(),
2181                           __ "(base) distro being accessed");
2182     vendor_patches_distro(access_nomdistro(),
2183                           __ "(nominal) distro being accessed");
2184 }
2185
2186 sub check_bpd_exists () {
2187     stat $buildproductsdir
2188         or fail f_ "build-products-dir %s is not accessible: %s\n",
2189         $buildproductsdir, $!;
2190 }
2191
2192 sub dotdot_bpd_transfer_origs ($$$) {
2193     my ($bpd_abs, $upstreamversion, $wanted) = @_;
2194     # checks is_orig_file_of_vsn and if
2195     # calls $wanted->{$leaf} and expects boolish
2196
2197     return if $buildproductsdir eq '..';
2198
2199     my $warned;
2200     my $dotdot = $maindir;
2201     $dotdot =~ s{/[^/]+$}{};
2202     opendir DD, $dotdot or fail "opendir .. ($dotdot): $!";
2203     while ($!=0, defined(my $leaf = readdir DD)) {
2204         {
2205             local ($debuglevel) = $debuglevel-1;
2206             printdebug "DD_BPD $leaf ?\n";
2207         }
2208         next unless is_orig_file_of_vsn $leaf, $upstreamversion;
2209         next unless $wanted->($leaf);
2210         next if lstat "$bpd_abs/$leaf";
2211
2212         print STDERR f_
2213  "%s: found orig(s) in .. missing from build-products-dir, transferring:\n",
2214             $us
2215             unless $warned++;
2216         $! == &ENOENT or fail f_
2217             "check orig file %s in bpd %s: %s", $leaf, $bpd_abs, $!;
2218         lstat "$dotdot/$leaf" or fail f_
2219             "check orig file %s in ..: %s", $leaf, $!;
2220         if (-l _) {
2221             stat "$dotdot/$leaf" or fail f_
2222                 "check target of orig symlink %s in ..: %s", $leaf, $!;
2223             my $ltarget = readlink "$dotdot/$leaf" or
2224                 die "readlink $dotdot/$leaf: $!";
2225             if ($ltarget !~ m{^/}) {
2226                 $ltarget = "$dotdot/$ltarget";
2227             }
2228             symlink $ltarget, "$bpd_abs/$leaf"
2229                 or die "$ltarget $bpd_abs $leaf: $!";
2230             print STDERR f_
2231  "%s: cloned orig symlink from ..: %s\n",
2232                 $us, $leaf;
2233         } elsif (link "$dotdot/$leaf", "$bpd_abs/$leaf") {
2234             print STDERR f_
2235  "%s: hardlinked orig from ..: %s\n",
2236                 $us, $leaf;
2237         } elsif ($! != EXDEV) {
2238             fail f_ "failed to make %s a hardlink to %s: %s",
2239                 "$bpd_abs/$leaf", "$dotdot/$leaf", $!;
2240         } else {
2241             symlink "$bpd_abs/$leaf", "$dotdot/$leaf"
2242                 or die "$bpd_abs $dotdot $leaf $!";
2243             print STDERR f_
2244  "%s: symmlinked orig from .. on other filesystem: %s\n",
2245                 $us, $leaf;
2246         }
2247     }
2248     die "$dotdot; $!" if $!;
2249     closedir DD;
2250 }
2251
2252 sub generate_commits_from_dsc () {
2253     # See big comment in fetch_from_archive, below.
2254     # See also README.dsc-import.
2255     prep_ud();
2256     changedir $playground;
2257
2258     my $bpd_abs = bpd_abs();
2259     my $upstreamv = upstreamversion $dsc->{version};
2260     my @dfi = dsc_files_info();
2261
2262     dotdot_bpd_transfer_origs $bpd_abs, $upstreamv,
2263         sub { grep { $_->{Filename} eq $_[0] } @dfi };
2264
2265     foreach my $fi (@dfi) {
2266         my $f = $fi->{Filename};
2267         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2268         my $upper_f = "$bpd_abs/$f";
2269
2270         printdebug "considering reusing $f: ";
2271
2272         if (link_ltarget "$upper_f,fetch", $f) {
2273             printdebug "linked (using ...,fetch).\n";
2274         } elsif ((printdebug "($!) "),
2275                  $! != ENOENT) {
2276             fail f_ "accessing %s: %s", "$buildproductsdir/$f,fetch", $!;
2277         } elsif (link_ltarget $upper_f, $f) {
2278             printdebug "linked.\n";
2279         } elsif ((printdebug "($!) "),
2280                  $! != ENOENT) {
2281             fail f_ "accessing %s: %s", "$buildproductsdir/$f", $!;
2282         } else {
2283             printdebug "absent.\n";
2284         }
2285
2286         my $refetched;
2287         complete_file_from_dsc('.', $fi, \$refetched)
2288             or next;
2289
2290         printdebug "considering saving $f: ";
2291
2292         if (rename_link_xf 1, $f, $upper_f) {
2293             printdebug "linked.\n";
2294         } elsif ((printdebug "($@) "),
2295                  $! != EEXIST) {
2296             fail f_ "saving %s: %s", "$buildproductsdir/$f", $@;
2297         } elsif (!$refetched) {
2298             printdebug "no need.\n";
2299         } elsif (rename_link_xf 1, $f, "$upper_f,fetch") {
2300             printdebug "linked (using ...,fetch).\n";
2301         } elsif ((printdebug "($@) "),
2302                  $! != EEXIST) {
2303             fail f_ "saving %s: %s", "$buildproductsdir/$f,fetch", $@;
2304         } else {
2305             printdebug "cannot.\n";
2306         }
2307     }
2308
2309     # We unpack and record the orig tarballs first, so that we only
2310     # need disk space for one private copy of the unpacked source.
2311     # But we can't make them into commits until we have the metadata
2312     # from the debian/changelog, so we record the tree objects now and
2313     # make them into commits later.
2314     my @tartrees;
2315     my $orig_f_base = srcfn $upstreamv, '';
2316
2317     foreach my $fi (@dfi) {
2318         # We actually import, and record as a commit, every tarball
2319         # (unless there is only one file, in which case there seems
2320         # little point.
2321
2322         my $f = $fi->{Filename};
2323         printdebug "import considering $f ";
2324         (printdebug "only one dfi\n"), next if @dfi == 1;
2325         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2326         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2327         my $compr_ext = $1;
2328
2329         my ($orig_f_part) =
2330             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2331
2332         printdebug "Y ", (join ' ', map { $_//"(none)" }
2333                           $compr_ext, $orig_f_part
2334                          ), "\n";
2335
2336         my $input = new IO::File $f, '<' or die "$f $!";
2337         my $compr_pid;
2338         my @compr_cmd;
2339
2340         if (defined $compr_ext) {
2341             my $cname =
2342                 Dpkg::Compression::compression_guess_from_filename $f;
2343             fail "Dpkg::Compression cannot handle file $f in source package"
2344                 if defined $compr_ext && !defined $cname;
2345             my $compr_proc =
2346                 new Dpkg::Compression::Process compression => $cname;
2347             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2348             my $compr_fh = new IO::Handle;
2349             my $compr_pid = open $compr_fh, "-|" // confess "$!";
2350             if (!$compr_pid) {
2351                 open STDIN, "<&", $input or confess "$!";
2352                 exec @compr_cmd;
2353                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2354             }
2355             $input = $compr_fh;
2356         }
2357
2358         rmtree "_unpack-tar";
2359         mkdir "_unpack-tar" or confess "$!";
2360         my @tarcmd = qw(tar -x -f -
2361                         --no-same-owner --no-same-permissions
2362                         --no-acls --no-xattrs --no-selinux);
2363         my $tar_pid = fork // confess "$!";
2364         if (!$tar_pid) {
2365             chdir "_unpack-tar" or confess "$!";
2366             open STDIN, "<&", $input or confess "$!";
2367             exec @tarcmd;
2368             die f_ "dgit (child): exec %s: %s", $tarcmd[0], $!;
2369         }
2370         $!=0; (waitpid $tar_pid, 0) == $tar_pid or confess "$!";
2371         !$? or failedcmd @tarcmd;
2372
2373         close $input or
2374             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2375              : confess "$!");
2376         # finally, we have the results in "tarball", but maybe
2377         # with the wrong permissions
2378
2379         runcmd qw(chmod -R +rwX _unpack-tar);
2380         changedir "_unpack-tar";
2381         remove_stray_gits($f);
2382         mktree_in_ud_here();
2383
2384         my ($tree) = git_add_write_tree();
2385         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2386         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2387             $tree = $1;
2388             printdebug "one subtree $1\n";
2389         } else {
2390             printdebug "multiple subtrees\n";
2391         }
2392         changedir "..";
2393         rmtree "_unpack-tar";
2394
2395         my $ent = [ $f, $tree ];
2396         push @tartrees, {
2397             Orig => !!$orig_f_part,
2398             Sort => (!$orig_f_part         ? 2 :
2399                      $orig_f_part =~ m/-/g ? 1 :
2400                                              0),
2401             F => $f,
2402             Tree => $tree,
2403         };
2404     }
2405
2406     @tartrees = sort {
2407         # put any without "_" first (spec is not clear whether files
2408         # are always in the usual order).  Tarballs without "_" are
2409         # the main orig or the debian tarball.
2410         $a->{Sort} <=> $b->{Sort} or
2411         $a->{F}    cmp $b->{F}
2412     } @tartrees;
2413
2414     my $any_orig = grep { $_->{Orig} } @tartrees;
2415
2416     my $dscfn = "$package.dsc";
2417
2418     my $treeimporthow = 'package';
2419
2420     open D, ">", $dscfn or die "$dscfn: $!";
2421     print D $dscdata or die "$dscfn: $!";
2422     close D or die "$dscfn: $!";
2423     my @cmd = qw(dpkg-source);
2424     push @cmd, '--no-check' if $dsc_checked;
2425     if (madformat $dsc->{format}) {
2426         push @cmd, '--skip-patches';
2427         $treeimporthow = 'unpatched';
2428     }
2429     push @cmd, qw(-x --), $dscfn;
2430     runcmd @cmd;
2431
2432     my ($tree,$dir) = mktree_in_ud_from_only_subdir(__ "source package");
2433     if (madformat $dsc->{format}) {
2434         check_for_vendor_patches();
2435     }
2436
2437     my $dappliedtree;
2438     if (madformat $dsc->{format}) {
2439         my @pcmd = qw(dpkg-source --before-build .);
2440         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2441         rmtree '.pc';
2442         $dappliedtree = git_add_write_tree();
2443     }
2444
2445     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2446     my $clogp;
2447     my $r1clogp;
2448
2449     printdebug "import clog search...\n";
2450     parsechangelog_loop \@clogcmd, (__ "package changelog"), sub {
2451         my ($thisstanza, $desc) = @_;
2452         no warnings qw(exiting);
2453
2454         $clogp //= $thisstanza;
2455
2456         printdebug "import clog $thisstanza->{version} $desc...\n";
2457
2458         last if !$any_orig; # we don't need $r1clogp
2459
2460         # We look for the first (most recent) changelog entry whose
2461         # version number is lower than the upstream version of this
2462         # package.  Then the last (least recent) previous changelog
2463         # entry is treated as the one which introduced this upstream
2464         # version and used for the synthetic commits for the upstream
2465         # tarballs.
2466
2467         # One might think that a more sophisticated algorithm would be
2468         # necessary.  But: we do not want to scan the whole changelog
2469         # file.  Stopping when we see an earlier version, which
2470         # necessarily then is an earlier upstream version, is the only
2471         # realistic way to do that.  Then, either the earliest
2472         # changelog entry we have seen so far is indeed the earliest
2473         # upload of this upstream version; or there are only changelog
2474         # entries relating to later upstream versions (which is not
2475         # possible unless the changelog and .dsc disagree about the
2476         # version).  Then it remains to choose between the physically
2477         # last entry in the file, and the one with the lowest version
2478         # number.  If these are not the same, we guess that the
2479         # versions were created in a non-monotonic order rather than
2480         # that the changelog entries have been misordered.
2481
2482         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2483
2484         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2485         $r1clogp = $thisstanza;
2486
2487         printdebug "import clog $r1clogp->{version} becomes r1\n";
2488     };
2489
2490     $clogp or fail __ "package changelog has no entries!";
2491
2492     my $authline = clogp_authline $clogp;
2493     my $changes = getfield $clogp, 'Changes';
2494     $changes =~ s/^\n//; # Changes: \n
2495     my $cversion = getfield $clogp, 'Version';
2496
2497     if (@tartrees) {
2498         $r1clogp //= $clogp; # maybe there's only one entry;
2499         my $r1authline = clogp_authline $r1clogp;
2500         # Strictly, r1authline might now be wrong if it's going to be
2501         # unused because !$any_orig.  Whatever.
2502
2503         printdebug "import tartrees authline   $authline\n";
2504         printdebug "import tartrees r1authline $r1authline\n";
2505
2506         foreach my $tt (@tartrees) {
2507             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2508
2509             my $mbody = f_ "Import %s", $tt->{F};
2510             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2511 tree $tt->{Tree}
2512 author $r1authline
2513 committer $r1authline
2514
2515 $mbody
2516
2517 [dgit import orig $tt->{F}]
2518 END_O
2519 tree $tt->{Tree}
2520 author $authline
2521 committer $authline
2522
2523 $mbody
2524
2525 [dgit import tarball $package $cversion $tt->{F}]
2526 END_T
2527         }
2528     }
2529
2530     printdebug "import main commit\n";
2531
2532     open C, ">../commit.tmp" or confess "$!";
2533     print C <<END or confess "$!";
2534 tree $tree
2535 END
2536     print C <<END or confess "$!" foreach @tartrees;
2537 parent $_->{Commit}
2538 END
2539     print C <<END or confess "$!";
2540 author $authline
2541 committer $authline
2542
2543 $changes
2544
2545 [dgit import $treeimporthow $package $cversion]
2546 END
2547
2548     close C or confess "$!";
2549     my $rawimport_hash = make_commit qw(../commit.tmp);
2550
2551     if (madformat $dsc->{format}) {
2552         printdebug "import apply patches...\n";
2553
2554         # regularise the state of the working tree so that
2555         # the checkout of $rawimport_hash works nicely.
2556         my $dappliedcommit = make_commit_text(<<END);
2557 tree $dappliedtree
2558 author $authline
2559 committer $authline
2560
2561 [dgit dummy commit]
2562 END
2563         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2564
2565         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2566
2567         # We need the answers to be reproducible
2568         my @authline = clogp_authline($clogp);
2569         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2570         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2571         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2572         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2573         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2574         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2575
2576         my $path = $ENV{PATH} or die;
2577
2578         # we use ../../gbp-pq-output, which (given that we are in
2579         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2580         # is .git/dgit.
2581
2582         foreach my $use_absurd (qw(0 1)) {
2583             runcmd @git, qw(checkout -q unpa);
2584             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2585             local $ENV{PATH} = $path;
2586             if ($use_absurd) {
2587                 chomp $@;
2588                 progress "warning: $@";
2589                 $path = "$absurdity:$path";
2590                 progress f_ "%s: trying slow absurd-git-apply...", $us;
2591                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2592                     or $!==ENOENT
2593                     or confess "$!";
2594             }
2595             eval {
2596                 die "forbid absurd git-apply\n" if $use_absurd
2597                     && forceing [qw(import-gitapply-no-absurd)];
2598                 die "only absurd git-apply!\n" if !$use_absurd
2599                     && forceing [qw(import-gitapply-absurd)];
2600
2601                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2602                 local $ENV{PATH} = $path                    if $use_absurd;
2603
2604                 my @showcmd = (gbp_pq, qw(import));
2605                 my @realcmd = shell_cmd
2606                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2607                 debugcmd "+",@realcmd;
2608                 if (system @realcmd) {
2609                     die f_ "%s failed: %s\n",
2610                         +(shellquote @showcmd),
2611                         failedcmd_waitstatus();
2612                 }
2613
2614                 my $gapplied = git_rev_parse('HEAD');
2615                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2616                 $gappliedtree eq $dappliedtree or
2617                     fail f_ <<END, $gapplied, $gappliedtree, $dappliedtree;
2618 gbp-pq import and dpkg-source disagree!
2619  gbp-pq import gave commit %s
2620  gbp-pq import gave tree %s
2621  dpkg-source --before-build gave tree %s
2622 END
2623                 $rawimport_hash = $gapplied;
2624             };
2625             last unless $@;
2626         }
2627         if ($@) {
2628             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2629             die $@;
2630         }
2631     }
2632
2633     progress f_ "synthesised git commit from .dsc %s", $cversion;
2634
2635     my $rawimport_mergeinput = {
2636         Commit => $rawimport_hash,
2637         Info => __ "Import of source package",
2638     };
2639     my @output = ($rawimport_mergeinput);
2640
2641     if ($lastpush_mergeinput) {
2642         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2643         my $oversion = getfield $oldclogp, 'Version';
2644         my $vcmp =
2645             version_compare($oversion, $cversion);
2646         if ($vcmp < 0) {
2647             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2648                 { ReverseParents => 1,
2649                   Message => (f_ <<END, $package, $cversion, $csuite) });
2650 Record %s (%s) in archive suite %s
2651 END
2652         } elsif ($vcmp > 0) {
2653             print STDERR f_ <<END, $cversion, $oversion,
2654
2655 Version actually in archive:   %s (older)
2656 Last version pushed with dgit: %s (newer or same)
2657 %s
2658 END
2659                 __ $later_warning_msg or confess "$!";
2660             @output = $lastpush_mergeinput;
2661         } else {
2662             # Same version.  Use what's in the server git branch,
2663             # discarding our own import.  (This could happen if the
2664             # server automatically imports all packages into git.)
2665             @output = $lastpush_mergeinput;
2666         }
2667     }
2668     changedir $maindir;
2669     rmtree $playground;
2670     return @output;
2671 }
2672
2673 sub complete_file_from_dsc ($$;$) {
2674     our ($dstdir, $fi, $refetched) = @_;
2675     # Ensures that we have, in $dstdir, the file $fi, with the correct
2676     # contents.  (Downloading it from alongside $dscurl if necessary.)
2677     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2678     # and will set $$refetched=1 if it did so (or tried to).
2679
2680     my $f = $fi->{Filename};
2681     my $tf = "$dstdir/$f";
2682     my $downloaded = 0;
2683
2684     my $got;
2685     my $checkhash = sub {
2686         open F, "<", "$tf" or die "$tf: $!";
2687         $fi->{Digester}->reset();
2688         $fi->{Digester}->addfile(*F);
2689         F->error and confess "$!";
2690         $got = $fi->{Digester}->hexdigest();
2691         return $got eq $fi->{Hash};
2692     };
2693
2694     if (stat_exists $tf) {
2695         if ($checkhash->()) {
2696             progress f_ "using existing %s", $f;
2697             return 1;
2698         }
2699         if (!$refetched) {
2700             fail f_ "file %s has hash %s but .dsc demands hash %s".
2701                     " (perhaps you should delete this file?)",
2702                     $f, $got, $fi->{Hash};
2703         }
2704         progress f_ "need to fetch correct version of %s", $f;
2705         unlink $tf or die "$tf $!";
2706         $$refetched = 1;
2707     } else {
2708         printdebug "$tf does not exist, need to fetch\n";
2709     }
2710
2711     my $furl = $dscurl;
2712     $furl =~ s{/[^/]+$}{};
2713     $furl .= "/$f";
2714     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2715     die "$f ?" if $f =~ m#/#;
2716     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2717     return 0 if !act_local();
2718
2719     $checkhash->() or
2720         fail f_ "file %s has hash %s but .dsc demands hash %s".
2721                 " (got wrong file from archive!)",
2722                 $f, $got, $fi->{Hash};
2723
2724     return 1;
2725 }
2726
2727 sub ensure_we_have_orig () {
2728     my @dfi = dsc_files_info();
2729     foreach my $fi (@dfi) {
2730         my $f = $fi->{Filename};
2731         next unless is_orig_file_in_dsc($f, \@dfi);
2732         complete_file_from_dsc($buildproductsdir, $fi)
2733             or next;
2734     }
2735 }
2736
2737 #---------- git fetch ----------
2738
2739 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2740 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2741
2742 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2743 # locally fetched refs because they have unhelpful names and clutter
2744 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2745 # whether we have made another local ref which refers to this object).
2746 #
2747 # (If we deleted them unconditionally, then we might end up
2748 # re-fetching the same git objects each time dgit fetch was run.)
2749 #
2750 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2751 # in git_fetch_us to fetch the refs in question, and possibly a call
2752 # to lrfetchref_used.
2753
2754 our (%lrfetchrefs_f, %lrfetchrefs_d);
2755 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2756
2757 sub lrfetchref_used ($) {
2758     my ($fullrefname) = @_;
2759     my $objid = $lrfetchrefs_f{$fullrefname};
2760     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2761 }
2762
2763 sub git_lrfetch_sane {
2764     my ($url, $supplementary, @specs) = @_;
2765     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2766     # at least as regards @specs.  Also leave the results in
2767     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2768     # able to clean these up.
2769     #
2770     # With $supplementary==1, @specs must not contain wildcards
2771     # and we add to our previous fetches (non-atomically).
2772
2773     # This is rather miserable:
2774     # When git fetch --prune is passed a fetchspec ending with a *,
2775     # it does a plausible thing.  If there is no * then:
2776     # - it matches subpaths too, even if the supplied refspec
2777     #   starts refs, and behaves completely madly if the source
2778     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2779     # - if there is no matching remote ref, it bombs out the whole
2780     #   fetch.
2781     # We want to fetch a fixed ref, and we don't know in advance
2782     # if it exists, so this is not suitable.
2783     #
2784     # Our workaround is to use git ls-remote.  git ls-remote has its
2785     # own qairks.  Notably, it has the absurd multi-tail-matching
2786     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2787     # refs/refs/foo etc.
2788     #
2789     # Also, we want an idempotent snapshot, but we have to make two
2790     # calls to the remote: one to git ls-remote and to git fetch.  The
2791     # solution is use git ls-remote to obtain a target state, and
2792     # git fetch to try to generate it.  If we don't manage to generate
2793     # the target state, we try again.
2794
2795     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2796
2797     my $specre = join '|', map {
2798         my $x = $_;
2799         $x =~ s/\W/\\$&/g;
2800         my $wildcard = $x =~ s/\\\*$/.*/;
2801         die if $wildcard && $supplementary;
2802         "(?:refs/$x)";
2803     } @specs;
2804     printdebug "git_lrfetch_sane specre=$specre\n";
2805     my $wanted_rref = sub {
2806         local ($_) = @_;
2807         return m/^(?:$specre)$/;
2808     };
2809
2810     my $fetch_iteration = 0;
2811     FETCH_ITERATION:
2812     for (;;) {
2813         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2814         if (++$fetch_iteration > 10) {
2815             fail __ "too many iterations trying to get sane fetch!";
2816         }
2817
2818         my @look = map { "refs/$_" } @specs;
2819         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2820         debugcmd "|",@lcmd;
2821
2822         my %wantr;
2823         open GITLS, "-|", @lcmd or confess "$!";
2824         while (<GITLS>) {
2825             printdebug "=> ", $_;
2826             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2827             my ($objid,$rrefname) = ($1,$2);
2828             if (!$wanted_rref->($rrefname)) {
2829                 print STDERR f_ <<END, "@look", $rrefname;
2830 warning: git ls-remote %s reported %s; this is silly, ignoring it.
2831 END
2832                 next;
2833             }
2834             $wantr{$rrefname} = $objid;
2835         }
2836         $!=0; $?=0;
2837         close GITLS or failedcmd @lcmd;
2838
2839         # OK, now %want is exactly what we want for refs in @specs
2840         my @fspecs = map {
2841             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2842             "+refs/$_:".lrfetchrefs."/$_";
2843         } @specs;
2844
2845         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2846
2847         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2848         runcmd_ordryrun_local @fcmd if @fspecs;
2849
2850         if (!$supplementary) {
2851             %lrfetchrefs_f = ();
2852         }
2853         my %objgot;
2854
2855         git_for_each_ref(lrfetchrefs, sub {
2856             my ($objid,$objtype,$lrefname,$reftail) = @_;
2857             $lrfetchrefs_f{$lrefname} = $objid;
2858             $objgot{$objid} = 1;
2859         });
2860
2861         if ($supplementary) {
2862             last;
2863         }
2864
2865         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2866             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2867             if (!exists $wantr{$rrefname}) {
2868                 if ($wanted_rref->($rrefname)) {
2869                     printdebug <<END;
2870 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2871 END
2872                 } else {
2873                     print STDERR f_ <<END, "@fspecs", $lrefname
2874 warning: git fetch %s created %s; this is silly, deleting it.
2875 END
2876                 }
2877                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2878                 delete $lrfetchrefs_f{$lrefname};
2879                 next;
2880             }
2881         }
2882         foreach my $rrefname (sort keys %wantr) {
2883             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2884             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2885             my $want = $wantr{$rrefname};
2886             next if $got eq $want;
2887             if (!defined $objgot{$want}) {
2888                 fail __ <<END unless act_local();
2889 --dry-run specified but we actually wanted the results of git fetch,
2890 so this is not going to work.  Try running dgit fetch first,
2891 or using --damp-run instead of --dry-run.
2892 END
2893                 print STDERR f_ <<END, $lrefname, $want;
2894 warning: git ls-remote suggests we want %s
2895 warning:  and it should refer to %s
2896 warning:  but git fetch didn't fetch that object to any relevant ref.
2897 warning:  This may be due to a race with someone updating the server.
2898 warning:  Will try again...
2899 END
2900                 next FETCH_ITERATION;
2901             }
2902             printdebug <<END;
2903 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2904 END
2905             runcmd_ordryrun_local @git, qw(update-ref -m),
2906                 "dgit fetch git fetch fixup", $lrefname, $want;
2907             $lrfetchrefs_f{$lrefname} = $want;
2908         }
2909         last;
2910     }
2911
2912     if (defined $csuite) {
2913         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2914         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2915             my ($objid,$objtype,$lrefname,$reftail) = @_;
2916             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2917             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2918         });
2919     }
2920
2921     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2922         Dumper(\%lrfetchrefs_f);
2923 }
2924
2925 sub git_fetch_us () {
2926     # Want to fetch only what we are going to use, unless
2927     # deliberately-not-ff, in which case we must fetch everything.
2928
2929     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2930         map { "tags/$_" }
2931         (quiltmode_splitbrain
2932          ? (map { $_->('*',access_nomdistro) }
2933             \&debiantag_new, \&debiantag_maintview)
2934          : debiantags('*',access_nomdistro));
2935     push @specs, server_branch($csuite);
2936     push @specs, $rewritemap;
2937     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2938
2939     my $url = access_giturl();
2940     git_lrfetch_sane $url, 0, @specs;
2941
2942     my %here;
2943     my @tagpats = debiantags('*',access_nomdistro);
2944
2945     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2946         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2947         printdebug "currently $fullrefname=$objid\n";
2948         $here{$fullrefname} = $objid;
2949     });
2950     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2951         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2952         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2953         printdebug "offered $lref=$objid\n";
2954         if (!defined $here{$lref}) {
2955             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2956             runcmd_ordryrun_local @upd;
2957             lrfetchref_used $fullrefname;
2958         } elsif ($here{$lref} eq $objid) {
2959             lrfetchref_used $fullrefname;
2960         } else {
2961             print STDERR f_ "Not updating %s from %s to %s.\n",
2962                             $lref, $here{$lref}, $objid;
2963         }
2964     });
2965 }
2966
2967 #---------- dsc and archive handling ----------
2968
2969 sub mergeinfo_getclogp ($) {
2970     # Ensures thit $mi->{Clogp} exists and returns it
2971     my ($mi) = @_;
2972     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2973 }
2974
2975 sub mergeinfo_version ($) {
2976     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2977 }
2978
2979 sub fetch_from_archive_record_1 ($) {
2980     my ($hash) = @_;
2981     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
2982     cmdoutput @git, qw(log -n2), $hash;
2983     # ... gives git a chance to complain if our commit is malformed
2984 }
2985
2986 sub fetch_from_archive_record_2 ($) {
2987     my ($hash) = @_;
2988     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
2989     if (act_local()) {
2990         cmdoutput @upd_cmd;
2991     } else {
2992         dryrun_report @upd_cmd;
2993     }
2994 }
2995
2996 sub parse_dsc_field_def_dsc_distro () {
2997     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2998                            dgit.default.distro);
2999 }
3000
3001 sub parse_dsc_field ($$) {
3002     my ($dsc, $what) = @_;
3003     my $f;
3004     foreach my $field (@ourdscfield) {
3005         $f = $dsc->{$field};
3006         last if defined $f;
3007     }
3008
3009     if (!defined $f) {
3010         progress f_ "%s: NO git hash", $what;
3011         parse_dsc_field_def_dsc_distro();
3012     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
3013              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
3014         progress f_ "%s: specified git info (%s)", $what, $dsc_distro;
3015         $dsc_hint_tag = [ $dsc_hint_tag ];
3016     } elsif ($f =~ m/^\w+\s*$/) {
3017         $dsc_hash = $&;
3018         parse_dsc_field_def_dsc_distro();
3019         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
3020                           $dsc_distro ];
3021         progress f_ "%s: specified git hash", $what;
3022     } else {
3023         fail f_ "%s: invalid Dgit info", $what;
3024     }
3025 }
3026
3027 sub resolve_dsc_field_commit ($$) {
3028     my ($already_distro, $already_mapref) = @_;
3029
3030     return unless defined $dsc_hash;
3031
3032     my $mapref =
3033         defined $already_mapref &&
3034         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
3035         ? $already_mapref : undef;
3036
3037     my $do_fetch;
3038     $do_fetch = sub {
3039         my ($what, @fetch) = @_;
3040
3041         local $idistro = $dsc_distro;
3042         my $lrf = lrfetchrefs;
3043
3044         if (!$chase_dsc_distro) {
3045             progress f_ "not chasing .dsc distro %s: not fetching %s",
3046                         $dsc_distro, $what;
3047             return 0;
3048         }
3049
3050         progress f_ ".dsc names distro %s: fetching %s", $dsc_distro, $what;
3051
3052         my $url = access_giturl();
3053         if (!defined $url) {
3054             defined $dsc_hint_url or fail f_ <<END, $dsc_distro;
3055 .dsc Dgit metadata is in context of distro %s
3056 for which we have no configured url and .dsc provides no hint
3057 END
3058             my $proto =
3059                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
3060                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
3061             parse_cfg_bool "dsc-url-proto-ok", 'false',
3062                 cfg("dgit.dsc-url-proto-ok.$proto",
3063                     "dgit.default.dsc-url-proto-ok")
3064                 or fail f_ <<END, $dsc_distro, $proto;
3065 .dsc Dgit metadata is in context of distro %s
3066 for which we have no configured url;
3067 .dsc provides hinted url with protocol %s which is unsafe.
3068 (can be overridden by config - consult documentation)
3069 END
3070             $url = $dsc_hint_url;
3071         }
3072
3073         git_lrfetch_sane $url, 1, @fetch;
3074
3075         return $lrf;
3076     };
3077
3078     my $rewrite_enable = do {
3079         local $idistro = $dsc_distro;
3080         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
3081     };
3082
3083     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
3084         if (!defined $mapref) {
3085             my $lrf = $do_fetch->((__ "rewrite map"), $rewritemap) or return;
3086             $mapref = $lrf.'/'.$rewritemap;
3087         }
3088         my $rewritemapdata = git_cat_file $mapref.':map';
3089         if (defined $rewritemapdata
3090             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
3091             progress __
3092                 "server's git history rewrite map contains a relevant entry!";
3093
3094             $dsc_hash = $1;
3095             if (defined $dsc_hash) {
3096                 progress __ "using rewritten git hash in place of .dsc value";
3097             } else {
3098                 progress __ "server data says .dsc hash is to be disregarded";
3099             }
3100         }
3101     }
3102
3103     if (!defined git_cat_file $dsc_hash) {
3104         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
3105         my $lrf = $do_fetch->((__ "additional commits"), @tags) &&
3106             defined git_cat_file $dsc_hash
3107             or fail f_ <<END, $dsc_hash;
3108 .dsc Dgit metadata requires commit %s
3109 but we could not obtain that object anywhere.
3110 END
3111         foreach my $t (@tags) {
3112             my $fullrefname = $lrf.'/'.$t;
3113 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
3114             next unless $lrfetchrefs_f{$fullrefname};
3115             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
3116             lrfetchref_used $fullrefname;
3117         }
3118     }
3119 }
3120
3121 sub fetch_from_archive () {
3122     check_bpd_exists();
3123     ensure_setup_existing_tree();
3124
3125     # Ensures that lrref() is what is actually in the archive, one way
3126     # or another, according to us - ie this client's
3127     # appropritaely-updated archive view.  Also returns the commit id.
3128     # If there is nothing in the archive, leaves lrref alone and
3129     # returns undef.  git_fetch_us must have already been called.
3130     get_archive_dsc();
3131
3132     if ($dsc) {
3133         parse_dsc_field($dsc, __ 'last upload to archive');
3134         resolve_dsc_field_commit access_basedistro,
3135             lrfetchrefs."/".$rewritemap
3136     } else {
3137         progress __ "no version available from the archive";
3138     }
3139
3140     # If the archive's .dsc has a Dgit field, there are three
3141     # relevant git commitids we need to choose between and/or merge
3142     # together:
3143     #   1. $dsc_hash: the Dgit field from the archive
3144     #   2. $lastpush_hash: the suite branch on the dgit git server
3145     #   3. $lastfetch_hash: our local tracking brach for the suite
3146     #
3147     # These may all be distinct and need not be in any fast forward
3148     # relationship:
3149     #
3150     # If the dsc was pushed to this suite, then the server suite
3151     # branch will have been updated; but it might have been pushed to
3152     # a different suite and copied by the archive.  Conversely a more
3153     # recent version may have been pushed with dgit but not appeared
3154     # in the archive (yet).
3155     #
3156     # $lastfetch_hash may be awkward because archive imports
3157     # (particularly, imports of Dgit-less .dscs) are performed only as
3158     # needed on individual clients, so different clients may perform a
3159     # different subset of them - and these imports are only made
3160     # public during push.  So $lastfetch_hash may represent a set of
3161     # imports different to a subsequent upload by a different dgit
3162     # client.
3163     #
3164     # Our approach is as follows:
3165     #
3166     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3167     # descendant of $dsc_hash, then it was pushed by a dgit user who
3168     # had based their work on $dsc_hash, so we should prefer it.
3169     # Otherwise, $dsc_hash was installed into this suite in the
3170     # archive other than by a dgit push, and (necessarily) after the
3171     # last dgit push into that suite (since a dgit push would have
3172     # been descended from the dgit server git branch); thus, in that
3173     # case, we prefer the archive's version (and produce a
3174     # pseudo-merge to overwrite the dgit server git branch).
3175     #
3176     # (If there is no Dgit field in the archive's .dsc then
3177     # generate_commit_from_dsc uses the version numbers to decide
3178     # whether the suite branch or the archive is newer.  If the suite
3179     # branch is newer it ignores the archive's .dsc; otherwise it
3180     # generates an import of the .dsc, and produces a pseudo-merge to
3181     # overwrite the suite branch with the archive contents.)
3182     #
3183     # The outcome of that part of the algorithm is the `public view',
3184     # and is same for all dgit clients: it does not depend on any
3185     # unpublished history in the local tracking branch.
3186     #
3187     # As between the public view and the local tracking branch: The
3188     # local tracking branch is only updated by dgit fetch, and
3189     # whenever dgit fetch runs it includes the public view in the
3190     # local tracking branch.  Therefore if the public view is not
3191     # descended from the local tracking branch, the local tracking
3192     # branch must contain history which was imported from the archive
3193     # but never pushed; and, its tip is now out of date.  So, we make
3194     # a pseudo-merge to overwrite the old imports and stitch the old
3195     # history in.
3196     #
3197     # Finally: we do not necessarily reify the public view (as
3198     # described above).  This is so that we do not end up stacking two
3199     # pseudo-merges.  So what we actually do is figure out the inputs
3200     # to any public view pseudo-merge and put them in @mergeinputs.
3201
3202     my @mergeinputs;
3203     # $mergeinputs[]{Commit}
3204     # $mergeinputs[]{Info}
3205     # $mergeinputs[0] is the one whose tree we use
3206     # @mergeinputs is in the order we use in the actual commit)
3207     #
3208     # Also:
3209     # $mergeinputs[]{Message} is a commit message to use
3210     # $mergeinputs[]{ReverseParents} if def specifies that parent
3211     #                                list should be in opposite order
3212     # Such an entry has no Commit or Info.  It applies only when found
3213     # in the last entry.  (This ugliness is to support making
3214     # identical imports to previous dgit versions.)
3215
3216     my $lastpush_hash = git_get_ref(lrfetchref());
3217     printdebug "previous reference hash=$lastpush_hash\n";
3218     $lastpush_mergeinput = $lastpush_hash && {
3219         Commit => $lastpush_hash,
3220         Info => (__ "dgit suite branch on dgit git server"),
3221     };
3222
3223     my $lastfetch_hash = git_get_ref(lrref());
3224     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3225     my $lastfetch_mergeinput = $lastfetch_hash && {
3226         Commit => $lastfetch_hash,
3227         Info => (__ "dgit client's archive history view"),
3228     };
3229
3230     my $dsc_mergeinput = $dsc_hash && {
3231         Commit => $dsc_hash,
3232         Info => (__ "Dgit field in .dsc from archive"),
3233     };
3234
3235     my $cwd = getcwd();
3236     my $del_lrfetchrefs = sub {
3237         changedir $cwd;
3238         my $gur;
3239         printdebug "del_lrfetchrefs...\n";
3240         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3241             my $objid = $lrfetchrefs_d{$fullrefname};
3242             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3243             if (!$gur) {
3244                 $gur ||= new IO::Handle;
3245                 open $gur, "|-", qw(git update-ref --stdin) or confess "$!";
3246             }
3247             printf $gur "delete %s %s\n", $fullrefname, $objid;
3248         }
3249         if ($gur) {
3250             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3251         }
3252     };
3253
3254     if (defined $dsc_hash) {
3255         ensure_we_have_orig();
3256         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3257             @mergeinputs = $dsc_mergeinput
3258         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3259             print STDERR f_ <<END, $dsc_hash, $lastpush_hash,
3260
3261 Git commit in archive is behind the last version allegedly pushed/uploaded.
3262 Commit referred to by archive: %s
3263 Last version pushed with dgit: %s
3264 %s
3265 END
3266                 __ $later_warning_msg or confess "$!";
3267             @mergeinputs = ($lastpush_mergeinput);
3268         } else {
3269             # Archive has .dsc which is not a descendant of the last dgit
3270             # push.  This can happen if the archive moves .dscs about.
3271             # Just follow its lead.
3272             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3273                 progress __ "archive .dsc names newer git commit";
3274                 @mergeinputs = ($dsc_mergeinput);
3275             } else {
3276                 progress __ "archive .dsc names other git commit, fixing up";
3277                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3278             }
3279         }
3280     } elsif ($dsc) {
3281         @mergeinputs = generate_commits_from_dsc();
3282         # We have just done an import.  Now, our import algorithm might
3283         # have been improved.  But even so we do not want to generate
3284         # a new different import of the same package.  So if the
3285         # version numbers are the same, just use our existing version.
3286         # If the version numbers are different, the archive has changed
3287         # (perhaps, rewound).
3288         if ($lastfetch_mergeinput &&
3289             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3290                               (mergeinfo_version $mergeinputs[0]) )) {
3291             @mergeinputs = ($lastfetch_mergeinput);
3292         }
3293     } elsif ($lastpush_hash) {
3294         # only in git, not in the archive yet
3295         @mergeinputs = ($lastpush_mergeinput);
3296         print STDERR f_ <<END,
3297
3298 Package not found in the archive, but has allegedly been pushed using dgit.
3299 %s
3300 END
3301             __ $later_warning_msg or confess "$!";
3302     } else {
3303         printdebug "nothing found!\n";
3304         if (defined $skew_warning_vsn) {
3305             print STDERR f_ <<END, $skew_warning_vsn or confess "$!";
3306
3307 Warning: relevant archive skew detected.
3308 Archive allegedly contains %s
3309 But we were not able to obtain any version from the archive or git.
3310
3311 END
3312         }
3313         unshift @end, $del_lrfetchrefs;
3314         return undef;
3315     }
3316
3317     if ($lastfetch_hash &&
3318         !grep {
3319             my $h = $_->{Commit};
3320             $h and is_fast_fwd($lastfetch_hash, $h);
3321             # If true, one of the existing parents of this commit
3322             # is a descendant of the $lastfetch_hash, so we'll
3323             # be ff from that automatically.
3324         } @mergeinputs
3325         ) {
3326         # Otherwise:
3327         push @mergeinputs, $lastfetch_mergeinput;
3328     }
3329
3330     printdebug "fetch mergeinfos:\n";
3331     foreach my $mi (@mergeinputs) {
3332         if ($mi->{Info}) {
3333             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3334         } else {
3335             printdebug sprintf " ReverseParents=%d Message=%s",
3336                 $mi->{ReverseParents}, $mi->{Message};
3337         }
3338     }
3339
3340     my $compat_info= pop @mergeinputs
3341         if $mergeinputs[$#mergeinputs]{Message};
3342
3343     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3344
3345     my $hash;
3346     if (@mergeinputs > 1) {
3347         # here we go, then:
3348         my $tree_commit = $mergeinputs[0]{Commit};
3349
3350         my $tree = get_tree_of_commit $tree_commit;;
3351
3352         # We use the changelog author of the package in question the
3353         # author of this pseudo-merge.  This is (roughly) correct if
3354         # this commit is simply representing aa non-dgit upload.
3355         # (Roughly because it does not record sponsorship - but we
3356         # don't have sponsorship info because that's in the .changes,
3357         # which isn't in the archivw.)
3358         #
3359         # But, it might be that we are representing archive history
3360         # updates (including in-archive copies).  These are not really
3361         # the responsibility of the person who created the .dsc, but
3362         # there is no-one whose name we should better use.  (The
3363         # author of the .dsc-named commit is clearly worse.)
3364
3365         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3366         my $author = clogp_authline $useclogp;
3367         my $cversion = getfield $useclogp, 'Version';
3368
3369         my $mcf = dgit_privdir()."/mergecommit";
3370         open MC, ">", $mcf or die "$mcf $!";
3371         print MC <<END or confess "$!";
3372 tree $tree
3373 END
3374
3375         my @parents = grep { $_->{Commit} } @mergeinputs;
3376         @parents = reverse @parents if $compat_info->{ReverseParents};
3377         print MC <<END or confess "$!" foreach @parents;
3378 parent $_->{Commit}
3379 END
3380
3381         print MC <<END or confess "$!";
3382 author $author
3383 committer $author
3384
3385 END
3386
3387         if (defined $compat_info->{Message}) {
3388             print MC $compat_info->{Message} or confess "$!";
3389         } else {
3390             print MC f_ <<END, $package, $cversion, $csuite or confess "$!";
3391 Record %s (%s) in archive suite %s
3392
3393 Record that
3394 END
3395             my $message_add_info = sub {
3396                 my ($mi) = (@_);
3397                 my $mversion = mergeinfo_version $mi;
3398                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3399                     or confess "$!";
3400             };
3401
3402             $message_add_info->($mergeinputs[0]);
3403             print MC __ <<END or confess "$!";
3404 should be treated as descended from
3405 END
3406             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3407         }
3408
3409         close MC or confess "$!";
3410         $hash = make_commit $mcf;
3411     } else {
3412         $hash = $mergeinputs[0]{Commit};
3413     }
3414     printdebug "fetch hash=$hash\n";
3415
3416     my $chkff = sub {
3417         my ($lasth, $what) = @_;
3418         return unless $lasth;
3419         confess "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3420     };
3421
3422     $chkff->($lastpush_hash, __ 'dgit repo server tip (last push)')
3423         if $lastpush_hash;
3424     $chkff->($lastfetch_hash, __ 'local tracking tip (last fetch)');
3425
3426     fetch_from_archive_record_1($hash);
3427
3428     if (defined $skew_warning_vsn) {
3429         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3430         my $gotclogp = commit_getclogp($hash);
3431         my $got_vsn = getfield $gotclogp, 'Version';
3432         printdebug "SKEW CHECK GOT $got_vsn\n";
3433         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3434             print STDERR f_ <<END, $skew_warning_vsn, $got_vsn or confess "$!";
3435
3436 Warning: archive skew detected.  Using the available version:
3437 Archive allegedly contains    %s
3438 We were able to obtain only   %s
3439
3440 END
3441         }
3442     }
3443
3444     if ($lastfetch_hash ne $hash) {
3445         fetch_from_archive_record_2($hash);
3446     }
3447
3448     lrfetchref_used lrfetchref();
3449
3450     check_gitattrs($hash, __ "fetched source tree");
3451
3452     unshift @end, $del_lrfetchrefs;
3453     return $hash;
3454 }
3455
3456 sub set_local_git_config ($$) {
3457     my ($k, $v) = @_;
3458     runcmd @git, qw(config), $k, $v;
3459 }
3460
3461 sub setup_mergechangelogs (;$) {
3462     my ($always) = @_;
3463     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3464
3465     my $driver = 'dpkg-mergechangelogs';
3466     my $cb = "merge.$driver";
3467     confess unless defined $maindir;
3468     my $attrs = "$maindir_gitcommon/info/attributes";
3469     ensuredir "$maindir_gitcommon/info";
3470
3471     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3472     if (!open ATTRS, "<", $attrs) {
3473         $!==ENOENT or die "$attrs: $!";
3474     } else {
3475         while (<ATTRS>) {
3476             chomp;
3477             next if m{^debian/changelog\s};
3478             print NATTRS $_, "\n" or confess "$!";
3479         }
3480         ATTRS->error and confess "$!";
3481         close ATTRS;
3482     }
3483     print NATTRS "debian/changelog merge=$driver\n" or confess "$!";
3484     close NATTRS;
3485
3486     set_local_git_config "$cb.name", __ 'debian/changelog merge driver';
3487     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3488
3489     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3490 }
3491
3492 sub setup_useremail (;$) {
3493     my ($always) = @_;
3494     return unless $always || access_cfg_bool(1, 'setup-useremail');
3495
3496     my $setup = sub {
3497         my ($k, $envvar) = @_;
3498         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3499         return unless defined $v;
3500         set_local_git_config "user.$k", $v;
3501     };
3502
3503     $setup->('email', 'DEBEMAIL');
3504     $setup->('name', 'DEBFULLNAME');
3505 }
3506
3507 sub ensure_setup_existing_tree () {
3508     my $k = "remote.$remotename.skipdefaultupdate";
3509     my $c = git_get_config $k;
3510     return if defined $c;
3511     set_local_git_config $k, 'true';
3512 }
3513
3514 sub open_main_gitattrs () {
3515     confess 'internal error no maindir' unless defined $maindir;
3516     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3517         or $!==ENOENT
3518         or die "open $maindir_gitcommon/info/attributes: $!";
3519     return $gai;
3520 }
3521
3522 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3523
3524 sub is_gitattrs_setup () {
3525     # return values:
3526     #  trueish
3527     #     1: gitattributes set up and should be left alone
3528     #  falseish
3529     #     0: there is a dgit-defuse-attrs but it needs fixing
3530     #     undef: there is none
3531     my $gai = open_main_gitattrs();
3532     return 0 unless $gai;
3533     while (<$gai>) {
3534         next unless m{$gitattrs_ourmacro_re};
3535         return 1 if m{\s-working-tree-encoding\s};
3536         printdebug "is_gitattrs_setup: found old macro\n";
3537         return 0;
3538     }
3539     $gai->error and confess "$!";
3540     printdebug "is_gitattrs_setup: found nothing\n";
3541     return undef;
3542 }
3543
3544 sub setup_gitattrs (;$) {
3545     my ($always) = @_;
3546     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3547
3548     my $already = is_gitattrs_setup();
3549     if ($already) {
3550         progress __ <<END;
3551 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3552  not doing further gitattributes setup
3553 END
3554         return;
3555     }
3556     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3557     my $af = "$maindir_gitcommon/info/attributes";
3558     ensuredir "$maindir_gitcommon/info";
3559
3560     open GAO, "> $af.new" or confess "$!";
3561     print GAO <<END, __ <<ENDT or confess "$!" unless defined $already;
3562 *       dgit-defuse-attrs
3563 $new
3564 END
3565 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3566 ENDT
3567     my $gai = open_main_gitattrs();
3568     if ($gai) {
3569         while (<$gai>) {
3570             if (m{$gitattrs_ourmacro_re}) {
3571                 die unless defined $already;
3572                 $_ = $new;
3573             }
3574             chomp;
3575             print GAO $_, "\n" or confess "$!";
3576         }
3577         $gai->error and confess "$!";
3578     }
3579     close GAO or confess "$!";
3580     rename "$af.new", "$af" or fail f_ "install %s: %s", $af, $!;
3581 }
3582
3583 sub setup_new_tree () {
3584     setup_mergechangelogs();
3585     setup_useremail();
3586     setup_gitattrs();
3587 }
3588
3589 sub check_gitattrs ($$) {
3590     my ($treeish, $what) = @_;
3591
3592     return if is_gitattrs_setup;
3593
3594     local $/="\0";
3595     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3596     debugcmd "|",@cmd;
3597     my $gafl = new IO::File;
3598     open $gafl, "-|", @cmd or confess "$!";
3599     while (<$gafl>) {
3600         chomp or die;
3601         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3602         next if $1 == 0;
3603         next unless m{(?:^|/)\.gitattributes$};
3604
3605         # oh dear, found one
3606         print STDERR f_ <<END, $what;
3607 dgit: warning: %s contains .gitattributes
3608 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3609 END
3610         close $gafl;
3611         return;
3612     }
3613     # tree contains no .gitattributes files
3614     $?=0; $!=0; close $gafl or failedcmd @cmd;
3615 }
3616
3617
3618 sub multisuite_suite_child ($$$) {
3619     my ($tsuite, $mergeinputs, $fn) = @_;
3620     # in child, sets things up, calls $fn->(), and returns undef
3621     # in parent, returns canonical suite name for $tsuite
3622     my $canonsuitefh = IO::File::new_tmpfile;
3623     my $pid = fork // confess "$!";
3624     if (!$pid) {
3625         forkcheck_setup();
3626         $isuite = $tsuite;
3627         $us .= " [$isuite]";
3628         $debugprefix .= " ";
3629         progress f_ "fetching %s...", $tsuite;
3630         canonicalise_suite();
3631         print $canonsuitefh $csuite, "\n" or confess "$!";
3632         close $canonsuitefh or confess "$!";
3633         $fn->();
3634         return undef;
3635     }
3636     waitpid $pid,0 == $pid or confess "$!";
3637     fail f_ "failed to obtain %s: %s", $tsuite, waitstatusmsg()
3638         if $? && $?!=256*4;
3639     seek $canonsuitefh,0,0 or confess "$!";
3640     local $csuite = <$canonsuitefh>;
3641     confess "$!" unless defined $csuite && chomp $csuite;
3642     if ($? == 256*4) {
3643         printdebug "multisuite $tsuite missing\n";
3644         return $csuite;
3645     }
3646     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3647     push @$mergeinputs, {
3648         Ref => lrref,
3649         Info => $csuite,
3650     };
3651     return $csuite;
3652 }
3653
3654 sub fork_for_multisuite ($) {
3655     my ($before_fetch_merge) = @_;
3656     # if nothing unusual, just returns ''
3657     #
3658     # if multisuite:
3659     # returns 0 to caller in child, to do first of the specified suites
3660     # in child, $csuite is not yet set
3661     #
3662     # returns 1 to caller in parent, to finish up anything needed after
3663     # in parent, $csuite is set to canonicalised portmanteau
3664
3665     my $org_isuite = $isuite;
3666     my @suites = split /\,/, $isuite;
3667     return '' unless @suites > 1;
3668     printdebug "fork_for_multisuite: @suites\n";
3669
3670     my @mergeinputs;
3671
3672     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3673                                             sub { });
3674     return 0 unless defined $cbasesuite;
3675
3676     fail f_ "package %s missing in (base suite) %s", $package, $cbasesuite
3677         unless @mergeinputs;
3678
3679     my @csuites = ($cbasesuite);
3680
3681     $before_fetch_merge->();
3682
3683     foreach my $tsuite (@suites[1..$#suites]) {
3684         $tsuite =~ s/^-/$cbasesuite-/;
3685         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3686                                                sub {
3687             @end = ();
3688             fetch_one();
3689             finish 0;
3690         });
3691
3692         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3693         push @csuites, $csubsuite;
3694     }
3695
3696     foreach my $mi (@mergeinputs) {
3697         my $ref = git_get_ref $mi->{Ref};
3698         die "$mi->{Ref} ?" unless length $ref;
3699         $mi->{Commit} = $ref;
3700     }
3701
3702     $csuite = join ",", @csuites;
3703
3704     my $previous = git_get_ref lrref;
3705     if ($previous) {
3706         unshift @mergeinputs, {
3707             Commit => $previous,
3708             Info => (__ "local combined tracking branch"),
3709             Warning => (__
3710  "archive seems to have rewound: local tracking branch is ahead!"),
3711         };
3712     }
3713
3714     foreach my $ix (0..$#mergeinputs) {
3715         $mergeinputs[$ix]{Index} = $ix;
3716     }
3717
3718     @mergeinputs = sort {
3719         -version_compare(mergeinfo_version $a,
3720                          mergeinfo_version $b) # highest version first
3721             or
3722         $a->{Index} <=> $b->{Index}; # earliest in spec first
3723     } @mergeinputs;
3724
3725     my @needed;
3726
3727   NEEDED:
3728     foreach my $mi (@mergeinputs) {
3729         printdebug "multisuite merge check $mi->{Info}\n";
3730         foreach my $previous (@needed) {
3731             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3732             printdebug "multisuite merge un-needed $previous->{Info}\n";
3733             next NEEDED;
3734         }
3735         push @needed, $mi;
3736         printdebug "multisuite merge this-needed\n";
3737         $mi->{Character} = '+';
3738     }
3739
3740     $needed[0]{Character} = '*';
3741
3742     my $output = $needed[0]{Commit};
3743
3744     if (@needed > 1) {
3745         printdebug "multisuite merge nontrivial\n";
3746         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3747
3748         my $commit = "tree $tree\n";
3749         my $msg = f_ "Combine archive branches %s [dgit]\n\n".
3750                      "Input branches:\n",
3751                      $csuite;
3752
3753         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3754             printdebug "multisuite merge include $mi->{Info}\n";
3755             $mi->{Character} //= ' ';
3756             $commit .= "parent $mi->{Commit}\n";
3757             $msg .= sprintf " %s  %-25s %s\n",
3758                 $mi->{Character},
3759                 (mergeinfo_version $mi),
3760                 $mi->{Info};
3761         }
3762         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3763         $msg .= __ "\nKey\n".
3764             " * marks the highest version branch, which choose to use\n".
3765             " + marks each branch which was not already an ancestor\n\n";
3766         $msg .=
3767             "[dgit multi-suite $csuite]\n";
3768         $commit .=
3769             "author $authline\n".
3770             "committer $authline\n\n";
3771         $output = make_commit_text $commit.$msg;
3772         printdebug "multisuite merge generated $output\n";
3773     }
3774
3775     fetch_from_archive_record_1($output);
3776     fetch_from_archive_record_2($output);
3777
3778     progress f_ "calculated combined tracking suite %s", $csuite;
3779
3780     return 1;
3781 }
3782
3783 sub clone_set_head () {
3784     open H, "> .git/HEAD" or confess "$!";
3785     print H "ref: ".lref()."\n" or confess "$!";
3786     close H or confess "$!";
3787 }
3788 sub clone_finish ($) {
3789     my ($dstdir) = @_;
3790     runcmd @git, qw(reset --hard), lrref();
3791     runcmd qw(bash -ec), <<'END';
3792         set -o pipefail
3793         git ls-tree -r --name-only -z HEAD | \
3794         xargs -0r touch -h -r . --
3795 END
3796     printdone f_ "ready for work in %s", $dstdir;
3797 }
3798
3799 sub clone ($) {
3800     # in multisuite, returns twice!
3801     # once in parent after first suite fetched,
3802     # and then again in child after everything is finished
3803     my ($dstdir) = @_;
3804     badusage __ "dry run makes no sense with clone" unless act_local();
3805
3806     my $multi_fetched = fork_for_multisuite(sub {
3807         printdebug "multi clone before fetch merge\n";
3808         changedir $dstdir;
3809         record_maindir();
3810     });
3811     if ($multi_fetched) {
3812         printdebug "multi clone after fetch merge\n";
3813         clone_set_head();
3814         clone_finish($dstdir);
3815         return;
3816     }
3817     printdebug "clone main body\n";
3818
3819     mkdir $dstdir or fail f_ "create \`%s': %s", $dstdir, $!;
3820     changedir $dstdir;
3821     check_bpd_exists();
3822
3823     canonicalise_suite();
3824     my $hasgit = check_for_git();
3825
3826     runcmd @git, qw(init -q);
3827     record_maindir();
3828     setup_new_tree();
3829     clone_set_head();
3830     my $giturl = access_giturl(1);
3831     if (defined $giturl) {
3832         runcmd @git, qw(remote add), 'origin', $giturl;
3833     }
3834     if ($hasgit) {
3835         progress __ "fetching existing git history";
3836         git_fetch_us();
3837         runcmd_ordryrun_local @git, qw(fetch origin);
3838     } else {
3839         progress __ "starting new git history";
3840     }
3841     fetch_from_archive() or no_such_package;
3842     my $vcsgiturl = $dsc->{'Vcs-Git'};
3843     if (length $vcsgiturl) {
3844         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3845         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3846     }
3847     clone_finish($dstdir);
3848 }
3849
3850 sub fetch_one () {
3851     canonicalise_suite();
3852     if (check_for_git()) {
3853         git_fetch_us();
3854     }
3855     fetch_from_archive() or no_such_package();
3856
3857     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3858     if (length $vcsgiturl and
3859         (grep { $csuite eq $_ }
3860          split /\;/,
3861          cfg 'dgit.vcs-git.suites')) {
3862         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3863         if (defined $current && $current ne $vcsgiturl) {
3864             print STDERR f_ <<END, $csuite;
3865 FYI: Vcs-Git in %s has different url to your vcs-git remote.
3866  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3867 END
3868         }
3869     }
3870     printdone f_ "fetched into %s", lrref();
3871 }
3872
3873 sub dofetch () {
3874     my $multi_fetched = fork_for_multisuite(sub { });
3875     fetch_one() unless $multi_fetched; # parent
3876     finish 0 if $multi_fetched eq '0'; # child
3877 }
3878
3879 sub pull () {
3880     dofetch();
3881     runcmd_ordryrun_local @git, qw(merge -m),
3882         (f_ "Merge from %s [dgit]", $csuite),
3883         lrref();
3884     printdone f_ "fetched to %s and merged into HEAD", lrref();
3885 }
3886
3887 sub check_not_dirty () {
3888     my @forbid = qw(local-options local-patch-header);
3889     @forbid = map { "debian/source/$_" } @forbid;
3890     foreach my $f (@forbid) {
3891         if (stat_exists $f) {
3892             fail f_ "git tree contains %s", $f;
3893         }
3894     }
3895
3896     my @cmd = (@git, qw(status -uall --ignored --porcelain));
3897     push @cmd, qw(debian/source/format debian/source/options);
3898     push @cmd, @forbid;
3899
3900     my $bad = cmdoutput @cmd;
3901     if (length $bad) {
3902         fail +(__
3903  "you have uncommitted changes to critical files, cannot continue:\n").
3904               $bad;
3905     }
3906
3907     return if $includedirty;
3908
3909     git_check_unmodified();
3910 }
3911
3912 sub commit_admin ($) {
3913     my ($m) = @_;
3914     progress "$m";
3915     runcmd_ordryrun_local @git, qw(commit -m), $m;
3916 }
3917
3918 sub quiltify_nofix_bail ($$) {
3919     my ($headinfo, $xinfo) = @_;
3920     if ($quilt_mode eq 'nofix') {
3921         fail f_
3922             "quilt fixup required but quilt mode is \`nofix'\n".
3923             "HEAD commit%s differs from tree implied by debian/patches%s",
3924             $headinfo, $xinfo;
3925     }
3926 }
3927
3928 sub commit_quilty_patch () {
3929     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3930     my %adds;
3931     foreach my $l (split /\n/, $output) {
3932         next unless $l =~ m/\S/;
3933         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3934             $adds{$1}++;
3935         }
3936     }
3937     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3938     if (!%adds) {
3939         progress __ "nothing quilty to commit, ok.";
3940         return;
3941     }
3942     quiltify_nofix_bail "", __ " (wanted to commit patch update)";
3943     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3944     runcmd_ordryrun_local @git, qw(add -f), @adds;
3945     commit_admin +(__ <<ENDT).<<END
3946 Commit Debian 3.0 (quilt) metadata
3947
3948 ENDT
3949 [dgit ($our_version) quilt-fixup]
3950 END
3951 }
3952
3953 sub get_source_format () {
3954     my %options;
3955     if (open F, "debian/source/options") {
3956         while (<F>) {
3957             next if m/^\s*\#/;
3958             next unless m/\S/;
3959             s/\s+$//; # ignore missing final newline
3960             if (m/\s*\#\s*/) {
3961                 my ($k, $v) = ($`, $'); #');
3962                 $v =~ s/^"(.*)"$/$1/;
3963                 $options{$k} = $v;
3964             } else {
3965                 $options{$_} = 1;
3966             }
3967         }
3968         F->error and confess "$!";
3969         close F;
3970     } else {
3971         confess "$!" unless $!==&ENOENT;
3972     }
3973
3974     if (!open F, "debian/source/format") {
3975         confess "$!" unless $!==&ENOENT;
3976         return '';
3977     }
3978     $_ = <F>;
3979     F->error and confess "$!";
3980     chomp;
3981     return ($_, \%options);
3982 }
3983
3984 sub madformat_wantfixup ($) {
3985     my ($format) = @_;
3986     return 0 unless $format eq '3.0 (quilt)';
3987     our $quilt_mode_warned;
3988     if ($quilt_mode eq 'nocheck') {
3989         progress f_ "Not doing any fixup of \`%s'".
3990             " due to ----no-quilt-fixup or --quilt=nocheck", $format
3991             unless $quilt_mode_warned++;
3992         return 0;
3993     }
3994     progress f_ "Format \`%s', need to check/update patch stack", $format
3995         unless $quilt_mode_warned++;
3996     return 1;
3997 }
3998
3999 sub maybe_split_brain_save ($$$) {
4000     my ($headref, $dgitview, $msg) = @_;
4001     # => message fragment "$saved" describing disposition of $dgitview
4002     #    (used inside parens, in the English texts)
4003     my $save = $internal_object_save{'dgit-view'};
4004     return f_ "commit id %s", $dgitview unless defined $save;
4005     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
4006                git_update_ref_cmd
4007                "dgit --dgit-view-save $msg HEAD=$headref",
4008                $save, $dgitview);
4009     runcmd @cmd;
4010     return f_ "and left in %s", $save;
4011 }
4012
4013 # An "infopair" is a tuple [ $thing, $what ]
4014 # (often $thing is a commit hash; $what is a description)
4015
4016 sub infopair_cond_equal ($$) {
4017     my ($x,$y) = @_;
4018     $x->[0] eq $y->[0] or fail <<END;
4019 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
4020 END
4021 };
4022
4023 sub infopair_lrf_tag_lookup ($$) {
4024     my ($tagnames, $what) = @_;
4025     # $tagname may be an array ref
4026     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
4027     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
4028     foreach my $tagname (@tagnames) {
4029         my $lrefname = lrfetchrefs."/tags/$tagname";
4030         my $tagobj = $lrfetchrefs_f{$lrefname};
4031         next unless defined $tagobj;
4032         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
4033         return [ git_rev_parse($tagobj), $what ];
4034     }
4035     fail @tagnames==1 ? (f_ <<END, $what, "@tagnames")
4036 Wanted tag %s (%s) on dgit server, but not found
4037 END
4038                       : (f_ <<END, $what, "@tagnames");
4039 Wanted tag %s (one of: %s) on dgit server, but not found
4040 END
4041 }
4042
4043 sub infopair_cond_ff ($$) {
4044     my ($anc,$desc) = @_;
4045     is_fast_fwd($anc->[0], $desc->[0]) or
4046         fail f_ <<END, $anc->[1], $anc->[0], $desc->[1], $desc->[0];
4047 %s (%s) .. %s (%s) is not fast forward
4048 END
4049 };
4050
4051 sub pseudomerge_version_check ($$) {
4052     my ($clogp, $archive_hash) = @_;
4053
4054     my $arch_clogp = commit_getclogp $archive_hash;
4055     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
4056                      __ 'version currently in archive' ];
4057     if (defined $overwrite_version) {
4058         if (length $overwrite_version) {
4059             infopair_cond_equal([ $overwrite_version,
4060                                   '--overwrite= version' ],
4061                                 $i_arch_v);
4062         } else {
4063             my $v = $i_arch_v->[0];
4064             progress f_
4065                 "Checking package changelog for archive version %s ...", $v;
4066             my $cd;
4067             eval {
4068                 my @xa = ("-f$v", "-t$v");
4069                 my $vclogp = parsechangelog @xa;
4070                 my $gf = sub {
4071                     my ($fn) = @_;
4072                     [ (getfield $vclogp, $fn),
4073                       (f_ "%s field from dpkg-parsechangelog %s",
4074                           $fn, "@xa") ];
4075                 };
4076                 my $cv = $gf->('Version');
4077                 infopair_cond_equal($i_arch_v, $cv);
4078                 $cd = $gf->('Distribution');
4079             };
4080             if ($@) {
4081                 $@ =~ s/^\n//s;
4082                 $@ =~ s/^dgit: //gm;
4083                 fail "$@".
4084                     f_ "Perhaps debian/changelog does not mention %s ?", $v;
4085             }
4086             fail f_ <<END, $cd->[1], $cd->[0], $v
4087 %s is %s
4088 Your tree seems to based on earlier (not uploaded) %s.
4089 END
4090                 if $cd->[0] =~ m/UNRELEASED/;
4091         }
4092     }
4093
4094     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
4095     return $i_arch_v;
4096 }
4097
4098 sub pseudomerge_make_commit ($$$$ $$) {
4099     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
4100         $msg_cmd, $msg_msg) = @_;
4101     progress f_ "Declaring that HEAD includes all changes in %s...",
4102                  $i_arch_v->[0];
4103
4104     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
4105     my $authline = clogp_authline $clogp;
4106
4107     chomp $msg_msg;
4108     $msg_cmd .=
4109         !defined $overwrite_version ? ""
4110         : !length  $overwrite_version ? " --overwrite"
4111         : " --overwrite=".$overwrite_version;
4112
4113     # Contributing parent is the first parent - that makes
4114     # git rev-list --first-parent DTRT.
4115     my $pmf = dgit_privdir()."/pseudomerge";
4116     open MC, ">", $pmf or die "$pmf $!";
4117     print MC <<END or confess "$!";
4118 tree $tree
4119 parent $dgitview
4120 parent $archive_hash
4121 author $authline
4122 committer $authline
4123
4124 $msg_msg
4125
4126 [$msg_cmd]
4127 END
4128     close MC or confess "$!";
4129
4130     return make_commit($pmf);
4131 }
4132
4133 sub splitbrain_pseudomerge ($$$$) {
4134     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
4135     # => $merged_dgitview
4136     printdebug "splitbrain_pseudomerge...\n";
4137     #
4138     #     We:      debian/PREVIOUS    HEAD($maintview)
4139     # expect:          o ----------------- o
4140     #                    \                   \
4141     #                     o                   o
4142     #                 a/d/PREVIOUS        $dgitview
4143     #                $archive_hash              \
4144     #  If so,                \                   \
4145     #  we do:                 `------------------ o
4146     #   this:                                   $dgitview'
4147     #
4148
4149     return $dgitview unless defined $archive_hash;
4150     return $dgitview if deliberately_not_fast_forward();
4151
4152     printdebug "splitbrain_pseudomerge...\n";
4153
4154     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4155
4156     if (!defined $overwrite_version) {
4157         progress __ "Checking that HEAD includes all changes in archive...";
4158     }
4159
4160     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
4161
4162     if (defined $overwrite_version) {
4163     } elsif (!eval {
4164         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
4165         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14,
4166                                               __ "maintainer view tag");
4167         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
4168         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, __ "dgit view tag");
4169         my $i_archive = [ $archive_hash, __ "current archive contents" ];
4170
4171         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
4172
4173         infopair_cond_equal($i_dgit, $i_archive);
4174         infopair_cond_ff($i_dep14, $i_dgit);
4175         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
4176         1;
4177     }) {
4178         $@ =~ s/^\n//; chomp $@;
4179         print STDERR <<END.(__ <<ENDT);
4180 $@
4181 END
4182 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
4183 ENDT
4184         finish -1;
4185     }
4186
4187     my $arch_v = $i_arch_v->[0];
4188     my $r = pseudomerge_make_commit
4189         $clogp, $dgitview, $archive_hash, $i_arch_v,
4190         "dgit --quilt=$quilt_mode",
4191         (defined $overwrite_version
4192          ? f_ "Declare fast forward from %s\n", $arch_v
4193          : f_ "Make fast forward from %s\n",    $arch_v);
4194
4195     maybe_split_brain_save $maintview, $r, "pseudomerge";
4196
4197     progress f_ "Made pseudo-merge of %s into dgit view.", $arch_v;
4198     return $r;
4199 }
4200
4201 sub plain_overwrite_pseudomerge ($$$) {
4202     my ($clogp, $head, $archive_hash) = @_;
4203
4204     printdebug "plain_overwrite_pseudomerge...";
4205
4206     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4207
4208     return $head if is_fast_fwd $archive_hash, $head;
4209
4210     my $m = f_ "Declare fast forward from %s", $i_arch_v->[0];
4211
4212     my $r = pseudomerge_make_commit
4213         $clogp, $head, $archive_hash, $i_arch_v,
4214         "dgit", $m;
4215
4216     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4217
4218     progress f_ "Make pseudo-merge of %s into your HEAD.", $i_arch_v->[0];
4219     return $r;
4220 }
4221
4222 sub push_parse_changelog ($) {
4223     my ($clogpfn) = @_;
4224
4225     my $clogp = Dpkg::Control::Hash->new();
4226     $clogp->load($clogpfn) or die;
4227
4228     my $clogpackage = getfield $clogp, 'Source';
4229     $package //= $clogpackage;
4230     fail f_ "-p specified %s but changelog specified %s",
4231             $package, $clogpackage
4232         unless $package eq $clogpackage;
4233     my $cversion = getfield $clogp, 'Version';
4234
4235     if (!$we_are_initiator) {
4236         # rpush initiator can't do this because it doesn't have $isuite yet
4237         my $tag = debiantag($cversion, access_nomdistro);
4238         runcmd @git, qw(check-ref-format), $tag;
4239     }
4240
4241     my $dscfn = dscfn($cversion);
4242
4243     return ($clogp, $cversion, $dscfn);
4244 }
4245
4246 sub push_parse_dsc ($$$) {
4247     my ($dscfn,$dscfnwhat, $cversion) = @_;
4248     $dsc = parsecontrol($dscfn,$dscfnwhat);
4249     my $dversion = getfield $dsc, 'Version';
4250     my $dscpackage = getfield $dsc, 'Source';
4251     ($dscpackage eq $package && $dversion eq $cversion) or
4252         fail f_ "%s is for %s %s but debian/changelog is for %s %s",
4253                 $dscfn, $dscpackage, $dversion,
4254                         $package,    $cversion;
4255 }
4256
4257 sub push_tagwants ($$$$) {
4258     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4259     my @tagwants;
4260     push @tagwants, {
4261         TagFn => \&debiantag,
4262         Objid => $dgithead,
4263         TfSuffix => '',
4264         View => 'dgit',
4265     };
4266     if (defined $maintviewhead) {
4267         push @tagwants, {
4268             TagFn => \&debiantag_maintview,
4269             Objid => $maintviewhead,
4270             TfSuffix => '-maintview',
4271             View => 'maint',
4272         };
4273     } elsif ($dodep14tag eq 'no' ? 0
4274              : $dodep14tag eq 'want' ? 1
4275              : $dodep14tag eq 'always' ? 1
4276              : die "$dodep14tag ?") {
4277         push @tagwants, {
4278             TagFn => \&debiantag_maintview,
4279             Objid => $dgithead,
4280             TfSuffix => '-dgit',
4281             View => 'dgit',
4282         };
4283     };
4284     foreach my $tw (@tagwants) {
4285         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4286         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4287     }
4288     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4289     return @tagwants;
4290 }
4291
4292 sub push_mktags ($$ $$ $) {
4293     my ($clogp,$dscfn,
4294         $changesfile,$changesfilewhat,
4295         $tagwants) = @_;
4296
4297     die unless $tagwants->[0]{View} eq 'dgit';
4298
4299     my $declaredistro = access_nomdistro();
4300     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4301     $dsc->{$ourdscfield[0]} = join " ",
4302         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4303         $reader_giturl;
4304     $dsc->save("$dscfn.tmp") or confess "$!";
4305
4306     my $changes = parsecontrol($changesfile,$changesfilewhat);
4307     foreach my $field (qw(Source Distribution Version)) {
4308         $changes->{$field} eq $clogp->{$field} or
4309             fail f_ "changes field %s \`%s' does not match changelog \`%s'",
4310                     $field, $changes->{$field}, $clogp->{$field};
4311     }
4312
4313     my $cversion = getfield $clogp, 'Version';
4314     my $clogsuite = getfield $clogp, 'Distribution';
4315
4316     # We make the git tag by hand because (a) that makes it easier
4317     # to control the "tagger" (b) we can do remote signing
4318     my $authline = clogp_authline $clogp;
4319     my $delibs = join(" ", "",@deliberatelies);
4320
4321     my $mktag = sub {
4322         my ($tw) = @_;
4323         my $tfn = $tw->{Tfn};
4324         my $head = $tw->{Objid};
4325         my $tag = $tw->{Tag};
4326
4327         open TO, '>', $tfn->('.tmp') or confess "$!";
4328         print TO <<END or confess "$!";
4329 object $head
4330 type commit
4331 tag $tag
4332 tagger $authline
4333
4334 END
4335         if ($tw->{View} eq 'dgit') {
4336             print TO f_ <<ENDT, $package, $cversion, $clogsuite, $csuite
4337 %s release %s for %s (%s) [dgit]
4338 ENDT
4339                 or confess "$!";
4340             print TO <<END or confess "$!";
4341 [dgit distro=$declaredistro$delibs]
4342 END
4343             foreach my $ref (sort keys %previously) {
4344                 print TO <<END or confess "$!";
4345 [dgit previously:$ref=$previously{$ref}]
4346 END
4347             }
4348         } elsif ($tw->{View} eq 'maint') {
4349             print TO f_ <<END, $package, $cversion, $clogsuite, $csuite,
4350 %s release %s for %s (%s)
4351 (maintainer view tag generated by dgit --quilt=%s)
4352 END
4353                 $quilt_mode
4354                 or confess "$!";
4355         } else {
4356             confess Dumper($tw)."?";
4357         }
4358
4359         close TO or confess "$!";
4360
4361         my $tagobjfn = $tfn->('.tmp');
4362         if ($sign) {
4363             if (!defined $keyid) {
4364                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4365             }
4366             if (!defined $keyid) {
4367                 $keyid = getfield $clogp, 'Maintainer';
4368             }
4369             unlink $tfn->('.tmp.asc') or $!==&ENOENT or confess "$!";
4370             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4371             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4372             push @sign_cmd, $tfn->('.tmp');
4373             runcmd_ordryrun @sign_cmd;
4374             if (act_scary()) {
4375                 $tagobjfn = $tfn->('.signed.tmp');
4376                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4377                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4378             }
4379         }
4380         return $tagobjfn;
4381     };
4382
4383     my @r = map { $mktag->($_); } @$tagwants;
4384     return @r;
4385 }
4386
4387 sub sign_changes ($) {
4388     my ($changesfile) = @_;
4389     if ($sign) {
4390         my @debsign_cmd = @debsign;
4391         push @debsign_cmd, "-k$keyid" if defined $keyid;
4392         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4393         push @debsign_cmd, $changesfile;
4394         runcmd_ordryrun @debsign_cmd;
4395     }
4396 }
4397
4398 sub dopush () {
4399     printdebug "actually entering push\n";
4400
4401     supplementary_message(__ <<'END');
4402 Push failed, while checking state of the archive.
4403 You can retry the push, after fixing the problem, if you like.
4404 END
4405     if (check_for_git()) {
4406         git_fetch_us();
4407     }
4408     my $archive_hash = fetch_from_archive();
4409     if (!$archive_hash) {
4410         $new_package or
4411             fail __ "package appears to be new in this suite;".
4412                     " if this is intentional, use --new";
4413     }
4414
4415     supplementary_message(__ <<'END');
4416 Push failed, while preparing your push.
4417 You can retry the push, after fixing the problem, if you like.
4418 END
4419
4420     prep_ud();
4421
4422     access_giturl(); # check that success is vaguely likely
4423     rpush_handle_protovsn_bothends() if $we_are_initiator;
4424
4425     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4426     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4427
4428     responder_send_file('parsed-changelog', $clogpfn);
4429
4430     my ($clogp, $cversion, $dscfn) =
4431         push_parse_changelog("$clogpfn");
4432
4433     my $dscpath = "$buildproductsdir/$dscfn";
4434     stat_exists $dscpath or
4435         fail f_ "looked for .dsc %s, but %s; maybe you forgot to build",
4436                 $dscpath, $!;
4437
4438     responder_send_file('dsc', $dscpath);
4439
4440     push_parse_dsc($dscpath, $dscfn, $cversion);
4441
4442     my $format = getfield $dsc, 'Format';
4443
4444     my $symref = git_get_symref();
4445     my $actualhead = git_rev_parse('HEAD');
4446
4447     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4448         if (quiltmode_splitbrain()) {
4449             my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $actualhead);
4450             fail f_ <<END, $ffq_prev, $quilt_mode;
4451 Branch is managed by git-debrebase (%s
4452 exists), but quilt mode (%s) implies a split view.
4453 Pass the right --quilt option or adjust your git config.
4454 Or, maybe, run git-debrebase forget-was-ever-debrebase.
4455 END
4456         }
4457         runcmd_ordryrun_local @git_debrebase, 'stitch';
4458         $actualhead = git_rev_parse('HEAD');
4459     }
4460
4461     my $dgithead = $actualhead;
4462     my $maintviewhead = undef;
4463
4464     my $upstreamversion = upstreamversion $clogp->{Version};
4465
4466     if (madformat_wantfixup($format)) {
4467         # user might have not used dgit build, so maybe do this now:
4468         if ($do_split_brain) {
4469             changedir $playground;
4470             my $cachekey;
4471             ($dgithead, $cachekey) =
4472                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4473             $dgithead or fail f_
4474  "--quilt=%s but no cached dgit view:
4475  perhaps HEAD changed since dgit build[-source] ?",
4476                               $quilt_mode;
4477         }
4478         if (!$do_split_brain) {
4479             # In split brain mode, do not attempt to incorporate dirty
4480             # stuff from the user's working tree.  That would be mad.
4481             commit_quilty_patch();
4482         }
4483     }
4484     if ($do_split_brain) {
4485         $made_split_brain = 1;
4486         $dgithead = splitbrain_pseudomerge($clogp,
4487                                            $actualhead, $dgithead,
4488                                            $archive_hash);
4489         $maintviewhead = $actualhead;
4490         changedir $maindir;
4491         prep_ud(); # so _only_subdir() works, below
4492     }
4493
4494     if (defined $overwrite_version && !defined $maintviewhead
4495         && $archive_hash) {
4496         $dgithead = plain_overwrite_pseudomerge($clogp,
4497                                                 $dgithead,
4498                                                 $archive_hash);
4499     }
4500
4501     check_not_dirty();
4502
4503     my $forceflag = '';
4504     if ($archive_hash) {
4505         if (is_fast_fwd($archive_hash, $dgithead)) {
4506             # ok
4507         } elsif (deliberately_not_fast_forward) {
4508             $forceflag = '+';
4509         } else {
4510             fail __ "dgit push: HEAD is not a descendant".
4511                 " of the archive's version.\n".
4512                 "To overwrite the archive's contents,".
4513                 " pass --overwrite[=VERSION].\n".
4514                 "To rewind history, if permitted by the archive,".
4515                 " use --deliberately-not-fast-forward.";
4516         }
4517     }
4518
4519     confess unless !!$made_split_brain == !!$do_split_brain;
4520
4521     changedir $playground;
4522     progress f_ "checking that %s corresponds to HEAD", $dscfn;
4523     runcmd qw(dpkg-source -x --),
4524         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4525     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4526     check_for_vendor_patches() if madformat($dsc->{format});
4527     changedir $maindir;
4528     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4529     debugcmd "+",@diffcmd;
4530     $!=0; $?=-1;
4531     my $r = system @diffcmd;
4532     if ($r) {
4533         if ($r==256) {
4534             my $referent = $made_split_brain ? $dgithead : 'HEAD';
4535             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4536
4537             my @mode_changes;
4538             my $raw = cmdoutput @git,
4539                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4540             my $changed;
4541             foreach (split /\0/, $raw) {
4542                 if (defined $changed) {
4543                     push @mode_changes, "$changed: $_\n" if $changed;
4544                     $changed = undef;
4545                     next;
4546                 } elsif (m/^:0+ 0+ /) {
4547                     $changed = '';
4548                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4549                     $changed = "Mode change from $1 to $2"
4550                 } else {
4551                     die "$_ ?";
4552                 }
4553             }
4554             if (@mode_changes) {
4555                 fail +(f_ <<ENDT, $dscfn).<<END
4556 HEAD specifies a different tree to %s:
4557 ENDT
4558 $diffs
4559 END
4560                     .(join '', @mode_changes)
4561                     .(f_ <<ENDT, $tree, $referent);
4562 There is a problem with your source tree (see dgit(7) for some hints).
4563 To see a full diff, run git diff %s %s
4564 ENDT
4565             }
4566
4567             fail +(f_ <<ENDT, $dscfn).<<END.(f_ <<ENDT, $tree, $referent);
4568 HEAD specifies a different tree to %s:
4569 ENDT
4570 $diffs
4571 END
4572 Perhaps you forgot to build.  Or perhaps there is a problem with your
4573  source tree (see dgit(7) for some hints).  To see a full diff, run
4574    git diff %s %s
4575 ENDT
4576         } else {
4577             failedcmd @diffcmd;
4578         }
4579     }
4580     if (!$changesfile) {
4581         my $pat = changespat $cversion;
4582         my @cs = glob "$buildproductsdir/$pat";
4583         fail f_ "failed to find unique changes file".
4584                 " (looked for %s in %s);".
4585                 " perhaps you need to use dgit -C",
4586                 $pat, $buildproductsdir
4587             unless @cs==1;
4588         ($changesfile) = @cs;
4589     } else {
4590         $changesfile = "$buildproductsdir/$changesfile";
4591     }
4592
4593     # Check that changes and .dsc agree enough
4594     $changesfile =~ m{[^/]*$};
4595     my $changes = parsecontrol($changesfile,$&);
4596     files_compare_inputs($dsc, $changes)
4597         unless forceing [qw(dsc-changes-mismatch)];
4598
4599     # Check whether this is a source only upload
4600     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4601     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4602     if ($sourceonlypolicy eq 'ok') {
4603     } elsif ($sourceonlypolicy eq 'always') {
4604         forceable_fail [qw(uploading-binaries)],
4605             __ "uploading binaries, although distro policy is source only"
4606             if $hasdebs;
4607     } elsif ($sourceonlypolicy eq 'never') {
4608         forceable_fail [qw(uploading-source-only)],
4609             __ "source-only upload, although distro policy requires .debs"
4610             if !$hasdebs;
4611     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4612         forceable_fail [qw(uploading-source-only)],
4613             f_ "source-only upload, even though package is entirely NEW\n".
4614                "(this is contrary to policy in %s)",
4615                access_nomdistro()
4616             if !$hasdebs
4617             && $new_package
4618             && !(archive_query('package_not_wholly_new', $package) // 1);
4619     } else {
4620         badcfg f_ "unknown source-only-uploads policy \`%s'",
4621                   $sourceonlypolicy;
4622     }
4623
4624     # Perhaps adjust .dsc to contain right set of origs
4625     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4626                                   $changesfile)
4627         unless forceing [qw(changes-origs-exactly)];
4628
4629     # Checks complete, we're going to try and go ahead:
4630
4631     responder_send_file('changes',$changesfile);
4632     responder_send_command("param head $dgithead");
4633     responder_send_command("param csuite $csuite");
4634     responder_send_command("param isuite $isuite");
4635     responder_send_command("param tagformat new");
4636     if (defined $maintviewhead) {
4637         confess "internal error (protovsn=$protovsn)"
4638             if defined $protovsn and $protovsn < 4;
4639         responder_send_command("param maint-view $maintviewhead");
4640     }
4641
4642     # Perhaps send buildinfo(s) for signing
4643     my $changes_files = getfield $changes, 'Files';
4644     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4645     foreach my $bi (@buildinfos) {
4646         responder_send_command("param buildinfo-filename $bi");
4647         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4648     }
4649
4650     if (deliberately_not_fast_forward) {
4651         git_for_each_ref(lrfetchrefs, sub {
4652             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4653             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4654             responder_send_command("previously $rrefname=$objid");
4655             $previously{$rrefname} = $objid;
4656         });
4657     }
4658
4659     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4660                                  dgit_privdir()."/tag");
4661     my @tagobjfns;
4662
4663     supplementary_message(__ <<'END');
4664 Push failed, while signing the tag.
4665 You can retry the push, after fixing the problem, if you like.
4666 END
4667     # If we manage to sign but fail to record it anywhere, it's fine.
4668     if ($we_are_responder) {
4669         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4670         responder_receive_files('signed-tag', @tagobjfns);
4671     } else {
4672         @tagobjfns = push_mktags($clogp,$dscpath,
4673                               $changesfile,$changesfile,
4674                               \@tagwants);
4675     }
4676     supplementary_message(__ <<'END');
4677 Push failed, *after* signing the tag.
4678 If you want to try again, you should use a new version number.
4679 END
4680
4681     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4682
4683     foreach my $tw (@tagwants) {
4684         my $tag = $tw->{Tag};
4685         my $tagobjfn = $tw->{TagObjFn};
4686         my $tag_obj_hash =
4687             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4688         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4689         runcmd_ordryrun_local
4690             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4691     }
4692
4693     supplementary_message(__ <<'END');
4694 Push failed, while updating the remote git repository - see messages above.
4695 If you want to try again, you should use a new version number.
4696 END
4697     if (!check_for_git()) {
4698         create_remote_git_repo();
4699     }
4700
4701     my @pushrefs = $forceflag.$dgithead.":".rrref();
4702     foreach my $tw (@tagwants) {
4703         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4704     }
4705
4706     runcmd_ordryrun @git,
4707         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4708     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4709
4710     supplementary_message(__ <<'END');
4711 Push failed, while obtaining signatures on the .changes and .dsc.
4712 If it was just that the signature failed, you may try again by using
4713 debsign by hand to sign the changes file (see the command dgit tried,
4714 above), and then dput that changes file to complete the upload.
4715 If you need to change the package, you must use a new version number.
4716 END
4717     if ($we_are_responder) {
4718         my $dryrunsuffix = act_local() ? "" : ".tmp";
4719         my @rfiles = ($dscpath, $changesfile);
4720         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4721         responder_receive_files('signed-dsc-changes',
4722                                 map { "$_$dryrunsuffix" } @rfiles);
4723     } else {
4724         if (act_local()) {
4725             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4726         } else {
4727             progress f_ "[new .dsc left in %s.tmp]", $dscpath;
4728         }
4729         sign_changes $changesfile;
4730     }
4731
4732     supplementary_message(f_ <<END, $changesfile);
4733 Push failed, while uploading package(s) to the archive server.
4734 You can retry the upload of exactly these same files with dput of:
4735   %s
4736 If that .changes file is broken, you will need to use a new version
4737 number for your next attempt at the upload.
4738 END
4739     my $host = access_cfg('upload-host','RETURN-UNDEF');
4740     my @hostarg = defined($host) ? ($host,) : ();
4741     runcmd_ordryrun @dput, @hostarg, $changesfile;
4742     printdone f_ "pushed and uploaded %s", $cversion;
4743
4744     supplementary_message('');
4745     responder_send_command("complete");
4746 }
4747
4748 sub pre_clone () {
4749     not_necessarily_a_tree();
4750 }
4751 sub cmd_clone {
4752     parseopts();
4753     my $dstdir;
4754     badusage __ "-p is not allowed with clone; specify as argument instead"
4755         if defined $package;
4756     if (@ARGV==1) {
4757         ($package) = @ARGV;
4758     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4759         ($package,$isuite) = @ARGV;
4760     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4761         ($package,$dstdir) = @ARGV;
4762     } elsif (@ARGV==3) {
4763         ($package,$isuite,$dstdir) = @ARGV;
4764     } else {
4765         badusage __ "incorrect arguments to dgit clone";
4766     }
4767     notpushing();
4768
4769     $dstdir ||= "$package";
4770     if (stat_exists $dstdir) {
4771         fail f_ "%s already exists", $dstdir;
4772     }
4773
4774     my $cwd_remove;
4775     if ($rmonerror && !$dryrun_level) {
4776         $cwd_remove= getcwd();
4777         unshift @end, sub {
4778             return unless defined $cwd_remove;
4779             if (!chdir "$cwd_remove") {
4780                 return if $!==&ENOENT;
4781                 confess "chdir $cwd_remove: $!";
4782             }
4783             printdebug "clone rmonerror removing $dstdir\n";
4784             if (stat $dstdir) {
4785                 rmtree($dstdir) or fail f_ "remove %s: %s\n", $dstdir, $!;
4786             } elsif (grep { $! == $_ }
4787                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4788             } else {
4789                 print STDERR f_ "check whether to remove %s: %s\n",
4790                                 $dstdir, $!;
4791             }
4792         };
4793     }
4794
4795     clone($dstdir);
4796     $cwd_remove = undef;
4797 }
4798
4799 sub branchsuite () {
4800     my $branch = git_get_symref();
4801     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4802         return $1;
4803     } else {
4804         return undef;
4805     }
4806 }
4807
4808 sub package_from_d_control () {
4809     if (!defined $package) {
4810         my $sourcep = parsecontrol('debian/control','debian/control');
4811         $package = getfield $sourcep, 'Source';
4812     }
4813 }
4814
4815 sub fetchpullargs () {
4816     package_from_d_control();
4817     if (@ARGV==0) {
4818         $isuite = branchsuite();
4819         if (!$isuite) {
4820             my $clogp = parsechangelog();
4821             my $clogsuite = getfield $clogp, 'Distribution';
4822             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4823         }
4824     } elsif (@ARGV==1) {
4825         ($isuite) = @ARGV;
4826     } else {
4827         badusage __ "incorrect arguments to dgit fetch or dgit pull";
4828     }
4829     notpushing();
4830 }
4831
4832 sub cmd_fetch {
4833     parseopts();
4834     fetchpullargs();
4835     dofetch();
4836 }
4837
4838 sub cmd_pull {
4839     parseopts();
4840     fetchpullargs();
4841     if (quiltmode_splitbrain()) {
4842         my ($format, $fopts) = get_source_format();
4843         madformat($format) and fail f_ <<END, $quilt_mode
4844 dgit pull not yet supported in split view mode (--quilt=%s)
4845 END
4846     }
4847     pull();
4848 }
4849
4850 sub cmd_checkout {
4851     parseopts();
4852     package_from_d_control();
4853     @ARGV==1 or badusage __ "dgit checkout needs a suite argument";
4854     ($isuite) = @ARGV;
4855     notpushing();
4856
4857     foreach my $canon (qw(0 1)) {
4858         if (!$canon) {
4859             $csuite= $isuite;
4860         } else {
4861             undef $csuite;
4862             canonicalise_suite();
4863         }
4864         if (length git_get_ref lref()) {
4865             # local branch already exists, yay
4866             last;
4867         }
4868         if (!length git_get_ref lrref()) {
4869             if (!$canon) {
4870                 # nope
4871                 next;
4872             }
4873             dofetch();
4874         }
4875         # now lrref exists
4876         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4877         last;
4878     }
4879     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4880         "dgit checkout $isuite";
4881     runcmd (@git, qw(checkout), lbranch());
4882 }
4883
4884 sub cmd_update_vcs_git () {
4885     my $specsuite;
4886     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4887         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4888     } else {
4889         ($specsuite) = (@ARGV);
4890         shift @ARGV;
4891     }
4892     my $dofetch=1;
4893     if (@ARGV) {
4894         if ($ARGV[0] eq '-') {
4895             $dofetch = 0;
4896         } elsif ($ARGV[0] eq '-') {
4897             shift;
4898         }
4899     }
4900
4901     package_from_d_control();
4902     my $ctrl;
4903     if ($specsuite eq '.') {
4904         $ctrl = parsecontrol 'debian/control', 'debian/control';
4905     } else {
4906         $isuite = $specsuite;
4907         get_archive_dsc();
4908         $ctrl = $dsc;
4909     }
4910     my $url = getfield $ctrl, 'Vcs-Git';
4911
4912     my @cmd;
4913     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4914     if (!defined $orgurl) {
4915         print STDERR f_ "setting up vcs-git: %s\n", $url;
4916         @cmd = (@git, qw(remote add vcs-git), $url);
4917     } elsif ($orgurl eq $url) {
4918         print STDERR f_ "vcs git already configured: %s\n", $url;
4919     } else {
4920         print STDERR f_ "changing vcs-git url to: %s\n", $url;
4921         @cmd = (@git, qw(remote set-url vcs-git), $url);
4922     }
4923     runcmd_ordryrun_local @cmd;
4924     if ($dofetch) {
4925         print f_ "fetching (%s)\n", "@ARGV";
4926         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4927     }
4928 }
4929
4930 sub prep_push () {
4931     parseopts();
4932     build_or_push_prep_early();
4933     pushing();
4934     build_or_push_prep_modes();
4935     check_not_dirty();
4936     my $specsuite;
4937     if (@ARGV==0) {
4938     } elsif (@ARGV==1) {
4939         ($specsuite) = (@ARGV);
4940     } else {
4941         badusage f_ "incorrect arguments to dgit %s", $subcommand;
4942     }
4943     if ($new_package) {
4944         local ($package) = $existing_package; # this is a hack
4945         canonicalise_suite();
4946     } else {
4947         canonicalise_suite();
4948     }
4949     if (defined $specsuite &&
4950         $specsuite ne $isuite &&
4951         $specsuite ne $csuite) {
4952             fail f_ "dgit %s: changelog specifies %s (%s)".
4953                     " but command line specifies %s",
4954                     $subcommand, $isuite, $csuite, $specsuite;
4955     }
4956 }
4957
4958 sub cmd_push {
4959     prep_push();
4960     dopush();
4961 }
4962
4963 #---------- remote commands' implementation ----------
4964
4965 sub pre_remote_push_build_host {
4966     my ($nrargs) = shift @ARGV;
4967     my (@rargs) = @ARGV[0..$nrargs-1];
4968     @ARGV = @ARGV[$nrargs..$#ARGV];
4969     die unless @rargs;
4970     my ($dir,$vsnwant) = @rargs;
4971     # vsnwant is a comma-separated list; we report which we have
4972     # chosen in our ready response (so other end can tell if they
4973     # offered several)
4974     $debugprefix = ' ';
4975     $we_are_responder = 1;
4976     $us .= " (build host)";
4977
4978     open PI, "<&STDIN" or confess "$!";
4979     open STDIN, "/dev/null" or confess "$!";
4980     open PO, ">&STDOUT" or confess "$!";
4981     autoflush PO 1;
4982     open STDOUT, ">&STDERR" or confess "$!";
4983     autoflush STDOUT 1;
4984
4985     $vsnwant //= 1;
4986     ($protovsn) = grep {
4987         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4988     } @rpushprotovsn_support;
4989
4990     fail f_ "build host has dgit rpush protocol versions %s".
4991             " but invocation host has %s",
4992             (join ",", @rpushprotovsn_support), $vsnwant
4993         unless defined $protovsn;
4994
4995     changedir $dir;
4996 }
4997 sub cmd_remote_push_build_host {
4998     responder_send_command("dgit-remote-push-ready $protovsn");
4999     &cmd_push;
5000 }
5001
5002 sub pre_remote_push_responder { pre_remote_push_build_host(); }
5003 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
5004 # ... for compatibility with proto vsn.1 dgit (just so that user gets
5005 #     a good error message)
5006
5007 sub rpush_handle_protovsn_bothends () {
5008     if ($protovsn < 4) {
5009         fail "negotiated protocol version $protovsn but need at least 4";
5010     }
5011 }
5012
5013 our $i_tmp;
5014
5015 sub i_cleanup {
5016     local ($@, $?);
5017     my $report = i_child_report();
5018     if (defined $report) {
5019         printdebug "($report)\n";
5020     } elsif ($i_child_pid) {
5021         printdebug "(killing build host child $i_child_pid)\n";
5022         kill 15, $i_child_pid;
5023     }
5024     if (defined $i_tmp && !defined $initiator_tempdir) {
5025         changedir "/";
5026         eval { rmtree $i_tmp; };
5027     }
5028 }
5029
5030 END {
5031     return unless forkcheck_mainprocess();
5032     i_cleanup();
5033 }
5034
5035 sub i_method {
5036     my ($base,$selector,@args) = @_;
5037     $selector =~ s/\-/_/g;
5038     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
5039 }
5040
5041 sub pre_rpush () {
5042     not_necessarily_a_tree();
5043 }
5044 sub cmd_rpush {
5045     my $host = nextarg;
5046     my $dir;
5047     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
5048         $host = $1;
5049         $dir = $'; #';
5050     } else {
5051         $dir = nextarg;
5052     }
5053     $dir =~ s{^-}{./-};
5054     my @rargs = ($dir);
5055     push @rargs, join ",", @rpushprotovsn_support;
5056     my @rdgit;
5057     push @rdgit, @dgit;
5058     push @rdgit, @ropts;
5059     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
5060     push @rdgit, @ARGV;
5061     my @cmd = (@ssh, $host, shellquote @rdgit);
5062     debugcmd "+",@cmd;
5063
5064     $we_are_initiator=1;
5065
5066     if (defined $initiator_tempdir) {
5067         rmtree $initiator_tempdir;
5068         mkdir $initiator_tempdir, 0700
5069             or fail f_ "create %s: %s", $initiator_tempdir, $!;
5070         $i_tmp = $initiator_tempdir;
5071     } else {
5072         $i_tmp = tempdir();
5073     }
5074     $i_child_pid = open2(\*RO, \*RI, @cmd);
5075     changedir $i_tmp;
5076     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
5077     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
5078     $supplementary_message = '' unless $protovsn >= 3;
5079
5080     for (;;) {
5081         my ($icmd,$iargs) = initiator_expect {
5082             m/^(\S+)(?: (.*))?$/;
5083             ($1,$2);
5084         };
5085         i_method "i_resp", $icmd, $iargs;
5086     }
5087 }
5088
5089 sub i_resp_progress ($) {
5090     my ($rhs) = @_;
5091     my $msg = protocol_read_bytes \*RO, $rhs;
5092     progress $msg;
5093 }
5094
5095 sub i_resp_supplementary_message ($) {
5096     my ($rhs) = @_;
5097     $supplementary_message = protocol_read_bytes \*RO, $rhs;
5098 }
5099
5100 sub i_resp_complete {
5101     my $pid = $i_child_pid;
5102     $i_child_pid = undef; # prevents killing some other process with same pid
5103     printdebug "waiting for build host child $pid...\n";
5104     my $got = waitpid $pid, 0;
5105     confess "$!" unless $got == $pid;
5106     fail f_ "build host child failed: %s", waitstatusmsg() if $?;
5107
5108     i_cleanup();
5109     printdebug __ "all done\n";
5110     finish 0;
5111 }
5112
5113 sub i_resp_file ($) {
5114     my ($keyword) = @_;
5115     my $localname = i_method "i_localname", $keyword;
5116     my $localpath = "$i_tmp/$localname";
5117     stat_exists $localpath and
5118         badproto \*RO, f_ "file %s (%s) twice", $keyword, $localpath;
5119     protocol_receive_file \*RO, $localpath;
5120     i_method "i_file", $keyword;
5121 }
5122
5123 our %i_param;
5124
5125 sub i_resp_param ($) {
5126     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, __ "bad param spec";
5127     $i_param{$1} = $2;
5128 }
5129
5130 sub i_resp_previously ($) {
5131     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
5132         or badproto \*RO, __ "bad previously spec";
5133     my $r = system qw(git check-ref-format), $1;
5134     confess "bad previously ref spec ($r)" if $r;
5135     $previously{$1} = $2;
5136 }
5137
5138 our %i_wanted;
5139
5140 sub i_resp_want ($) {
5141     my ($keyword) = @_;
5142     die "$keyword ?" if $i_wanted{$keyword}++;
5143
5144     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
5145     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
5146     die unless $isuite =~ m/^$suite_re$/;
5147
5148     pushing();
5149     rpush_handle_protovsn_bothends();
5150
5151     fail f_ "rpush negotiated protocol version %s".
5152         " which does not support quilt mode %s",
5153         $protovsn, $quilt_mode
5154         if quiltmode_splitbrain && $protovsn < 4;
5155
5156     my @localpaths = i_method "i_want", $keyword;
5157     printdebug "[[  $keyword @localpaths\n";
5158     foreach my $localpath (@localpaths) {
5159         protocol_send_file \*RI, $localpath;
5160     }
5161     print RI "files-end\n" or confess "$!";
5162 }
5163
5164 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
5165
5166 sub i_localname_parsed_changelog {
5167     return "remote-changelog.822";
5168 }
5169 sub i_file_parsed_changelog {
5170     ($i_clogp, $i_version, $i_dscfn) =
5171         push_parse_changelog "$i_tmp/remote-changelog.822";
5172     die if $i_dscfn =~ m#/|^\W#;
5173 }
5174
5175 sub i_localname_dsc {
5176     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5177     return $i_dscfn;
5178 }
5179 sub i_file_dsc { }
5180
5181 sub i_localname_buildinfo ($) {
5182     my $bi = $i_param{'buildinfo-filename'};
5183     defined $bi or badproto \*RO, "buildinfo before filename";
5184     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
5185     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
5186         or badproto \*RO, "improper buildinfo filename";
5187     return $&;
5188 }
5189 sub i_file_buildinfo {
5190     my $bi = $i_param{'buildinfo-filename'};
5191     my $bd = parsecontrol "$i_tmp/$bi", $bi;
5192     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
5193     if (!forceing [qw(buildinfo-changes-mismatch)]) {
5194         files_compare_inputs($bd, $ch);
5195         (getfield $bd, $_) eq (getfield $ch, $_) or
5196             fail f_ "buildinfo mismatch in field %s", $_
5197             foreach qw(Source Version);
5198         !defined $bd->{$_} or
5199             fail f_ "buildinfo contains forbidden field %s", $_
5200             foreach qw(Changes Changed-by Distribution);
5201     }
5202     push @i_buildinfos, $bi;
5203     delete $i_param{'buildinfo-filename'};
5204 }
5205
5206 sub i_localname_changes {
5207     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5208     $i_changesfn = $i_dscfn;
5209     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
5210     return $i_changesfn;
5211 }
5212 sub i_file_changes { }
5213
5214 sub i_want_signed_tag {
5215     printdebug Dumper(\%i_param, $i_dscfn);
5216     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
5217         && defined $i_param{'csuite'}
5218         or badproto \*RO, "premature desire for signed-tag";
5219     my $head = $i_param{'head'};
5220     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
5221
5222     my $maintview = $i_param{'maint-view'};
5223     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
5224
5225     if ($protovsn >= 4) {
5226         my $p = $i_param{'tagformat'} // '<undef>';
5227         $p eq 'new'
5228             or badproto \*RO, "tag format mismatch: $p vs. new";
5229     }
5230
5231     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
5232     $csuite = $&;
5233     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
5234
5235     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
5236
5237     return
5238         push_mktags $i_clogp, $i_dscfn,
5239             $i_changesfn, (__ 'remote changes file'),
5240             \@tagwants;
5241 }
5242
5243 sub i_want_signed_dsc_changes {
5244     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5245     sign_changes $i_changesfn;
5246     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5247 }
5248
5249 #---------- building etc. ----------
5250
5251 our $version;
5252 our $sourcechanges;
5253 our $dscfn;
5254
5255 #----- `3.0 (quilt)' handling -----
5256
5257 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5258
5259 sub quiltify_dpkg_commit ($$$;$) {
5260     my ($patchname,$author,$msg, $xinfo) = @_;
5261     $xinfo //= '';
5262
5263     mkpath '.git/dgit'; # we are in playtree
5264     my $descfn = ".git/dgit/quilt-description.tmp";
5265     open O, '>', $descfn or confess "$descfn: $!";
5266     $msg =~ s/\n+/\n\n/;
5267     print O <<END or confess "$!";
5268 From: $author
5269 ${xinfo}Subject: $msg
5270 ---
5271
5272 END
5273     close O or confess "$!";
5274
5275     {
5276         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5277         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5278         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5279         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5280     }
5281 }
5282
5283 sub quiltify_trees_differ ($$;$$$) {
5284     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5285     # returns true iff the two tree objects differ other than in debian/
5286     # with $finegrained,
5287     # returns bitmask 01 - differ in upstream files except .gitignore
5288     #                 02 - differ in .gitignore
5289     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5290     #  is set for each modified .gitignore filename $fn
5291     # if $unrepres is defined, array ref to which is appeneded
5292     #  a list of unrepresentable changes (removals of upstream files
5293     #  (as messages)
5294     local $/=undef;
5295     my @cmd = (@git, qw(diff-tree -z --no-renames));
5296     push @cmd, qw(--name-only) unless $unrepres;
5297     push @cmd, qw(-r) if $finegrained || $unrepres;
5298     push @cmd, $x, $y;
5299     my $diffs= cmdoutput @cmd;
5300     my $r = 0;
5301     my @lmodes;
5302     foreach my $f (split /\0/, $diffs) {
5303         if ($unrepres && !@lmodes) {
5304             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5305             next;
5306         }
5307         my ($oldmode,$newmode) = @lmodes;
5308         @lmodes = ();
5309
5310         next if $f =~ m#^debian(?:/.*)?$#s;
5311
5312         if ($unrepres) {
5313             eval {
5314                 die __ "not a plain file or symlink\n"
5315                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5316                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5317                 if ($oldmode =~ m/[^0]/ &&
5318                     $newmode =~ m/[^0]/) {
5319                     # both old and new files exist
5320                     die __ "mode or type changed\n" if $oldmode ne $newmode;
5321                     die __ "modified symlink\n" unless $newmode =~ m/^10/;
5322                 } elsif ($oldmode =~ m/[^0]/) {
5323                     # deletion
5324                     die __ "deletion of symlink\n"
5325                         unless $oldmode =~ m/^10/;
5326                 } else {
5327                     # creation
5328                     die __ "creation with non-default mode\n"
5329                         unless $newmode =~ m/^100644$/ or
5330                                $newmode =~ m/^120000$/;
5331                 }
5332             };
5333             if ($@) {
5334                 local $/="\n"; chomp $@;
5335                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5336             }
5337         }
5338
5339         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5340         $r |= $isignore ? 02 : 01;
5341         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5342     }
5343     printdebug "quiltify_trees_differ $x $y => $r\n";
5344     return $r;
5345 }
5346
5347 sub quiltify_tree_sentinelfiles ($) {
5348     # lists the `sentinel' files present in the tree
5349     my ($x) = @_;
5350     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5351         qw(-- debian/rules debian/control);
5352     $r =~ s/\n/,/g;
5353     return $r;
5354 }
5355
5356 sub quiltify_splitbrain ($$$$$$$) {
5357     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5358         $editedignores, $cachekey) = @_;
5359     my $gitignore_special = 1;
5360     if ($quilt_mode !~ m/gbp|dpm/) {
5361         # treat .gitignore just like any other upstream file
5362         $diffbits = { %$diffbits };
5363         $_ = !!$_ foreach values %$diffbits;
5364         $gitignore_special = 0;
5365     }
5366     # We would like any commits we generate to be reproducible
5367     my @authline = clogp_authline($clogp);
5368     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5369     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5370     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5371     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5372     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5373     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5374
5375     confess unless $do_split_brain;
5376
5377     my $fulldiffhint = sub {
5378         my ($x,$y) = @_;
5379         my $cmd = "git diff $x $y -- :/ ':!debian'";
5380         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5381         return f_ "\nFor full diff showing the problem(s), type:\n %s\n",
5382                   $cmd;
5383     };
5384
5385     if ($quilt_mode =~ m/gbp|unapplied/ &&
5386         ($diffbits->{O2H} & 01)) {
5387         my $msg = f_
5388  "--quilt=%s specified, implying patches-unapplied git tree\n".
5389  " but git tree differs from orig in upstream files.",
5390                      $quilt_mode;
5391         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5392         if (!stat_exists "debian/patches") {
5393             $msg .= __
5394  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5395         }
5396         fail $msg;
5397     }
5398     if ($quilt_mode =~ m/dpm/ &&
5399         ($diffbits->{H2A} & 01)) {
5400         fail +(f_ <<END, $quilt_mode). $fulldiffhint->($oldtiptree,'HEAD');
5401 --quilt=%s specified, implying patches-applied git tree
5402  but git tree differs from result of applying debian/patches to upstream
5403 END
5404     }
5405     if ($quilt_mode =~ m/gbp|unapplied/ &&
5406         ($diffbits->{O2A} & 01)) { # some patches
5407         progress __ "dgit view: creating patches-applied version using gbp pq";
5408         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5409         # gbp pq import creates a fresh branch; push back to dgit-view
5410         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5411         runcmd @git, qw(checkout -q dgit-view);
5412     }
5413     if ($quilt_mode =~ m/gbp|dpm/ &&
5414         ($diffbits->{O2A} & 02)) {
5415         fail f_ <<END, $quilt_mode;
5416 --quilt=%s specified, implying that HEAD is for use with a
5417  tool which does not create patches for changes to upstream
5418  .gitignores: but, such patches exist in debian/patches.
5419 END
5420     }
5421     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5422         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5423         progress __
5424             "dgit view: creating patch to represent .gitignore changes";
5425         ensuredir "debian/patches";
5426         my $gipatch = "debian/patches/auto-gitignore";
5427         open GIPATCH, ">>", "$gipatch" or confess "$gipatch: $!";
5428         stat GIPATCH or confess "$gipatch: $!";
5429         fail f_ "%s already exists; but want to create it".
5430                 " to record .gitignore changes",
5431                 $gipatch
5432             if (stat _)[7];
5433         print GIPATCH +(__ <<END).<<ENDU or die "$gipatch: $!";
5434 Subject: Update .gitignore from Debian packaging branch
5435
5436 The Debian packaging git branch contains these updates to the upstream
5437 .gitignore file(s).  This patch is autogenerated, to provide these
5438 updates to users of the official Debian archive view of the package.
5439 END
5440
5441 [dgit ($our_version) update-gitignore]
5442 ---
5443 ENDU
5444         close GIPATCH or die "$gipatch: $!";
5445         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5446             $unapplied, $headref, "--", sort keys %$editedignores;
5447         open SERIES, "+>>", "debian/patches/series" or confess "$!";
5448         defined seek SERIES, -1, 2 or $!==EINVAL or confess "$!";
5449         my $newline;
5450         defined read SERIES, $newline, 1 or confess "$!";
5451         print SERIES "\n" or confess "$!" unless $newline eq "\n";
5452         print SERIES "auto-gitignore\n" or confess "$!";
5453         close SERIES or die  $!;
5454         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5455         commit_admin +(__ <<END).<<ENDU
5456 Commit patch to update .gitignore
5457 END
5458
5459 [dgit ($our_version) update-gitignore-quilt-fixup]
5460 ENDU
5461     }
5462 }
5463
5464 sub quiltify ($$$$) {
5465     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5466
5467     # Quilt patchification algorithm
5468     #
5469     # We search backwards through the history of the main tree's HEAD
5470     # (T) looking for a start commit S whose tree object is identical
5471     # to to the patch tip tree (ie the tree corresponding to the
5472     # current dpkg-committed patch series).  For these purposes
5473     # `identical' disregards anything in debian/ - this wrinkle is
5474     # necessary because dpkg-source treates debian/ specially.
5475     #
5476     # We can only traverse edges where at most one of the ancestors'
5477     # trees differs (in changes outside in debian/).  And we cannot
5478     # handle edges which change .pc/ or debian/patches.  To avoid
5479     # going down a rathole we avoid traversing edges which introduce
5480     # debian/rules or debian/control.  And we set a limit on the
5481     # number of edges we are willing to look at.
5482     #
5483     # If we succeed, we walk forwards again.  For each traversed edge
5484     # PC (with P parent, C child) (starting with P=S and ending with
5485     # C=T) to we do this:
5486     #  - git checkout C
5487     #  - dpkg-source --commit with a patch name and message derived from C
5488     # After traversing PT, we git commit the changes which
5489     # should be contained within debian/patches.
5490
5491     # The search for the path S..T is breadth-first.  We maintain a
5492     # todo list containing search nodes.  A search node identifies a
5493     # commit, and looks something like this:
5494     #  $p = {
5495     #      Commit => $git_commit_id,
5496     #      Child => $c,                          # or undef if P=T
5497     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5498     #      Nontrivial => true iff $p..$c has relevant changes
5499     #  };
5500
5501     my @todo;
5502     my @nots;
5503     my $sref_S;
5504     my $max_work=100;
5505     my %considered; # saves being exponential on some weird graphs
5506
5507     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5508
5509     my $not = sub {
5510         my ($search,$whynot) = @_;
5511         printdebug " search NOT $search->{Commit} $whynot\n";
5512         $search->{Whynot} = $whynot;
5513         push @nots, $search;
5514         no warnings qw(exiting);
5515         next;
5516     };
5517
5518     push @todo, {
5519         Commit => $target,
5520     };
5521
5522     while (@todo) {
5523         my $c = shift @todo;
5524         next if $considered{$c->{Commit}}++;
5525
5526         $not->($c, __ "maximum search space exceeded") if --$max_work <= 0;
5527
5528         printdebug "quiltify investigate $c->{Commit}\n";
5529
5530         # are we done?
5531         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5532             printdebug " search finished hooray!\n";
5533             $sref_S = $c;
5534             last;
5535         }
5536
5537         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5538         if ($quilt_mode eq 'smash') {
5539             printdebug " search quitting smash\n";
5540             last;
5541         }
5542
5543         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5544         $not->($c, f_ "has %s not %s", $c_sentinels, $t_sentinels)
5545             if $c_sentinels ne $t_sentinels;
5546
5547         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5548         $commitdata =~ m/\n\n/;
5549         $commitdata =~ $`;
5550         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5551         @parents = map { { Commit => $_, Child => $c } } @parents;
5552
5553         $not->($c, __ "root commit") if !@parents;
5554
5555         foreach my $p (@parents) {
5556             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5557         }
5558         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5559         $not->($c, f_ "merge (%s nontrivial parents)", $ndiffers)
5560             if $ndiffers > 1;
5561
5562         foreach my $p (@parents) {
5563             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5564
5565             my @cmd= (@git, qw(diff-tree -r --name-only),
5566                       $p->{Commit},$c->{Commit},
5567                       qw(-- debian/patches .pc debian/source/format));
5568             my $patchstackchange = cmdoutput @cmd;
5569             if (length $patchstackchange) {
5570                 $patchstackchange =~ s/\n/,/g;
5571                 $not->($p, f_ "changed %s", $patchstackchange);
5572             }
5573
5574             printdebug " search queue P=$p->{Commit} ",
5575                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5576             push @todo, $p;
5577         }
5578     }
5579
5580     if (!$sref_S) {
5581         printdebug "quiltify want to smash\n";
5582
5583         my $abbrev = sub {
5584             my $x = $_[0]{Commit};
5585             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5586             return $x;
5587         };
5588         if ($quilt_mode eq 'linear') {
5589             print STDERR f_
5590                 "\n%s: error: quilt fixup cannot be linear.  Stopped at:\n",
5591                 $us;
5592             my $all_gdr = !!@nots;
5593             foreach my $notp (@nots) {
5594                 my $c = $notp->{Child};
5595                 my $cprange = $abbrev->($notp);
5596                 $cprange .= "..".$abbrev->($c) if $c;
5597                 print STDERR f_ "%s:  %s: %s\n",
5598                     $us, $cprange, $notp->{Whynot};
5599                 $all_gdr &&= $notp->{Child} &&
5600                     (git_cat_file $notp->{Child}{Commit}, 'commit')
5601                     =~ m{^\[git-debrebase(?! split[: ]).*\]$}m;
5602             }
5603             print STDERR "\n";
5604             $failsuggestion =
5605                 [ grep { $_->[0] ne 'quilt-mode' } @$failsuggestion ]
5606                 if $all_gdr;
5607             print STDERR "$us: $_->[1]\n" foreach @$failsuggestion;
5608             fail __
5609  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n";
5610         } elsif ($quilt_mode eq 'smash') {
5611         } elsif ($quilt_mode eq 'auto') {
5612             progress __ "quilt fixup cannot be linear, smashing...";
5613         } else {
5614             confess "$quilt_mode ?";
5615         }
5616
5617         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5618         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5619         my $ncommits = 3;
5620         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5621
5622         quiltify_dpkg_commit "auto-$version-$target-$time",
5623             (getfield $clogp, 'Maintainer'),
5624             (f_ "Automatically generated patch (%s)\n".
5625              "Last (up to) %s git changes, FYI:\n\n",
5626              $clogp->{Version}, $ncommits).
5627              $msg;
5628         return;
5629     }
5630
5631     progress __ "quiltify linearisation planning successful, executing...";
5632
5633     for (my $p = $sref_S;
5634          my $c = $p->{Child};
5635          $p = $p->{Child}) {
5636         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5637         next unless $p->{Nontrivial};
5638
5639         my $cc = $c->{Commit};
5640
5641         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5642         $commitdata =~ m/\n\n/ or die "$c ?";
5643         $commitdata = $`;
5644         my $msg = $'; #';
5645         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5646         my $author = $1;
5647
5648         my $commitdate = cmdoutput
5649             @git, qw(log -n1 --pretty=format:%aD), $cc;
5650
5651         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5652
5653         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5654         $strip_nls->();
5655
5656         my $title = $1;
5657         my $patchname;
5658         my $patchdir;
5659
5660         my $gbp_check_suitable = sub {
5661             $_ = shift;
5662             my ($what) = @_;
5663
5664             eval {
5665                 die __ "contains unexpected slashes\n" if m{//} || m{/$};
5666                 die __ "contains leading punctuation\n" if m{^\W} || m{/\W};
5667                 die __ "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5668                 die __ "is series file\n" if m{$series_filename_re}o;
5669                 die __ "too long\n" if length > 200;
5670             };
5671             return $_ unless $@;
5672             print STDERR f_
5673                 "quiltifying commit %s: ignoring/dropping Gbp-Pq %s: %s",
5674                 $cc, $what, $@;
5675             return undef;
5676         };
5677
5678         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5679                            gbp-pq-name: \s* )
5680                        (\S+) \s* \n //ixm) {
5681             $patchname = $gbp_check_suitable->($1, 'Name');
5682         }
5683         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5684                            gbp-pq-topic: \s* )
5685                        (\S+) \s* \n //ixm) {
5686             $patchdir = $gbp_check_suitable->($1, 'Topic');
5687         }
5688
5689         $strip_nls->();
5690
5691         if (!defined $patchname) {
5692             $patchname = $title;
5693             $patchname =~ s/[.:]$//;
5694             use Text::Iconv;
5695             eval {
5696                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5697                 my $translitname = $converter->convert($patchname);
5698                 die unless defined $translitname;
5699                 $patchname = $translitname;
5700             };
5701             print STDERR
5702                 +(f_ "dgit: patch title transliteration error: %s", $@)
5703                 if $@;
5704             $patchname =~ y/ A-Z/-a-z/;
5705             $patchname =~ y/-a-z0-9_.+=~//cd;
5706             $patchname =~ s/^\W/x-$&/;
5707             $patchname = substr($patchname,0,40);
5708             $patchname .= ".patch";
5709         }
5710         if (!defined $patchdir) {
5711             $patchdir = '';
5712         }
5713         if (length $patchdir) {
5714             $patchname = "$patchdir/$patchname";
5715         }
5716         if ($patchname =~ m{^(.*)/}) {
5717             mkpath "debian/patches/$1";
5718         }
5719
5720         my $index;
5721         for ($index='';
5722              stat "debian/patches/$patchname$index";
5723              $index++) { }
5724         $!==ENOENT or confess "$patchname$index $!";
5725
5726         runcmd @git, qw(checkout -q), $cc;
5727
5728         # We use the tip's changelog so that dpkg-source doesn't
5729         # produce complaining messages from dpkg-parsechangelog.  None
5730         # of the information dpkg-source gets from the changelog is
5731         # actually relevant - it gets put into the original message
5732         # which dpkg-source provides our stunt editor, and then
5733         # overwritten.
5734         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5735
5736         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5737             "Date: $commitdate\n".
5738             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5739
5740         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5741     }
5742 }
5743
5744 sub build_maybe_quilt_fixup () {
5745     my ($format,$fopts) = get_source_format;
5746     return unless madformat_wantfixup $format;
5747     # sigh
5748
5749     check_for_vendor_patches();
5750
5751     my $clogp = parsechangelog();
5752     my $headref = git_rev_parse('HEAD');
5753     my $symref = git_get_symref();
5754     my $upstreamversion = upstreamversion $version;
5755
5756     prep_ud();
5757     changedir $playground;
5758
5759     my $splitbrain_cachekey;
5760
5761     if ($do_split_brain) {
5762         my $cachehit;
5763         ($cachehit, $splitbrain_cachekey) =
5764             quilt_check_splitbrain_cache($headref, $upstreamversion);
5765         if ($cachehit) {
5766             changedir $maindir;
5767             return;
5768         }
5769     }
5770
5771     unpack_playtree_need_cd_work($headref);
5772     if ($do_split_brain) {
5773         runcmd @git, qw(checkout -q -b dgit-view);
5774         # so long as work is not deleted, its current branch will
5775         # remain dgit-view, rather than master, so subsequent calls to
5776         #  unpack_playtree_need_cd_work
5777         # will DTRT, resetting dgit-view.
5778         confess if $made_split_brain;
5779         $made_split_brain = 1;
5780     }
5781     chdir '..';
5782
5783     if ($fopts->{'single-debian-patch'}) {
5784         fail f_
5785  "quilt mode %s does not make sense (or is not supported) with single-debian-patch",
5786             $quilt_mode
5787             if quiltmode_splitbrain();
5788         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5789     } else {
5790         quilt_fixup_multipatch($clogp, $headref, $upstreamversion,
5791                               $splitbrain_cachekey);
5792     }
5793
5794     if ($do_split_brain) {
5795         my $dgitview = git_rev_parse 'HEAD';
5796
5797         changedir $maindir;
5798         reflog_cache_insert "refs/$splitbraincache",
5799             $splitbrain_cachekey, $dgitview;
5800
5801         changedir "$playground/work";
5802
5803         my $saved = maybe_split_brain_save $headref, $dgitview, __ "converted";
5804         progress f_ "dgit view: created (%s)", $saved;
5805     }
5806
5807     changedir $maindir;
5808     runcmd_ordryrun_local
5809         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5810 }
5811
5812 sub build_check_quilt_splitbrain () {
5813     build_maybe_quilt_fixup();
5814 }
5815
5816 sub unpack_playtree_need_cd_work ($) {
5817     my ($headref) = @_;
5818
5819     # prep_ud() must have been called already.
5820     if (!chdir "work") {
5821         # Check in the filesystem because sometimes we run prep_ud
5822         # in between multiple calls to unpack_playtree_need_cd_work.
5823         confess "$!" unless $!==ENOENT;
5824         mkdir "work" or confess "$!";
5825         changedir "work";
5826         mktree_in_ud_here();
5827     }
5828     runcmd @git, qw(reset -q --hard), $headref;
5829 }
5830
5831 sub unpack_playtree_linkorigs ($$) {
5832     my ($upstreamversion, $fn) = @_;
5833     # calls $fn->($leafname);
5834
5835     my $bpd_abs = bpd_abs();
5836
5837     dotdot_bpd_transfer_origs $bpd_abs, $upstreamversion, sub { 1 };
5838
5839     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5840     while ($!=0, defined(my $leaf = readdir QFD)) {
5841         my $f = bpd_abs()."/".$leaf;
5842         {
5843             local ($debuglevel) = $debuglevel-1;
5844             printdebug "QF linkorigs bpd $leaf, $f ?\n";
5845         }
5846         next unless is_orig_file_of_vsn $leaf, $upstreamversion;
5847         printdebug "QF linkorigs $leaf, $f Y\n";
5848         link_ltarget $f, $leaf or die "$leaf $!";
5849         $fn->($leaf);
5850     }
5851     die "$buildproductsdir: $!" if $!;
5852     closedir QFD;
5853 }
5854
5855 sub quilt_fixup_delete_pc () {
5856     runcmd @git, qw(rm -rqf .pc);
5857     commit_admin +(__ <<END).<<ENDU
5858 Commit removal of .pc (quilt series tracking data)
5859 END
5860
5861 [dgit ($our_version) upgrade quilt-remove-pc]
5862 ENDU
5863 }
5864
5865 sub quilt_fixup_singlepatch ($$$) {
5866     my ($clogp, $headref, $upstreamversion) = @_;
5867
5868     progress __ "starting quiltify (single-debian-patch)";
5869
5870     # dpkg-source --commit generates new patches even if
5871     # single-debian-patch is in debian/source/options.  In order to
5872     # get it to generate debian/patches/debian-changes, it is
5873     # necessary to build the source package.
5874
5875     unpack_playtree_linkorigs($upstreamversion, sub { });
5876     unpack_playtree_need_cd_work($headref);
5877
5878     rmtree("debian/patches");
5879
5880     runcmd @dpkgsource, qw(-b .);
5881     changedir "..";
5882     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5883     rename srcfn("$upstreamversion", "/debian/patches"),
5884         "work/debian/patches"
5885         or $!==ENOENT
5886         or confess "install d/patches: $!";
5887
5888     changedir "work";
5889     commit_quilty_patch();
5890 }
5891
5892 sub quilt_need_fake_dsc ($) {
5893     # cwd should be playground
5894     my ($upstreamversion) = @_;
5895
5896     return if stat_exists "fake.dsc";
5897     # ^ OK to test this as a sentinel because if we created it
5898     # we must either have done the rest too, or crashed.
5899
5900     my $fakeversion="$upstreamversion-~~DGITFAKE";
5901
5902     my $fakedsc=new IO::File 'fake.dsc', '>' or confess "$!";
5903     print $fakedsc <<END or confess "$!";
5904 Format: 3.0 (quilt)
5905 Source: $package
5906 Version: $fakeversion
5907 Files:
5908 END
5909
5910     my $dscaddfile=sub {
5911         my ($leaf) = @_;
5912
5913         my $md = new Digest::MD5;
5914
5915         my $fh = new IO::File $leaf, '<' or die "$leaf $!";
5916         stat $fh or confess "$!";
5917         my $size = -s _;
5918
5919         $md->addfile($fh);
5920         print $fakedsc " ".$md->hexdigest." $size $leaf\n" or confess "$!";
5921     };
5922
5923     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5924
5925     my @files=qw(debian/source/format debian/rules
5926                  debian/control debian/changelog);
5927     foreach my $maybe (qw(debian/patches debian/source/options
5928                           debian/tests/control)) {
5929         next unless stat_exists "$maindir/$maybe";
5930         push @files, $maybe;
5931     }
5932
5933     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5934     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
5935
5936     $dscaddfile->($debtar);
5937     close $fakedsc or confess "$!";
5938 }
5939
5940 sub quilt_fakedsc2unapplied ($$) {
5941     my ($headref, $upstreamversion) = @_;
5942     # must be run in the playground
5943     # quilt_need_fake_dsc must have been called
5944
5945     quilt_need_fake_dsc($upstreamversion);
5946     runcmd qw(sh -ec),
5947         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5948
5949     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5950     rename $fakexdir, "fake" or die "$fakexdir $!";
5951
5952     changedir 'fake';
5953
5954     remove_stray_gits(__ "source package");
5955     mktree_in_ud_here();
5956
5957     rmtree '.pc';
5958
5959     rmtree 'debian'; # git checkout commitish paths does not delete!
5960     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5961     my $unapplied=git_add_write_tree();
5962     printdebug "fake orig tree object $unapplied\n";
5963     return $unapplied;
5964 }
5965
5966 sub quilt_check_splitbrain_cache ($$) {
5967     my ($headref, $upstreamversion) = @_;
5968     # Called only if we are in (potentially) split brain mode.
5969     # Called in playground.
5970     # Computes the cache key and looks in the cache.
5971     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5972
5973     quilt_need_fake_dsc($upstreamversion);
5974
5975     my $splitbrain_cachekey;
5976
5977     progress f_
5978  "dgit: split brain (separate dgit view) may be needed (--quilt=%s).",
5979                 $quilt_mode;
5980     # we look in the reflog of dgit-intern/quilt-cache
5981     # we look for an entry whose message is the key for the cache lookup
5982     my @cachekey = (qw(dgit), $our_version);
5983     push @cachekey, $upstreamversion;
5984     push @cachekey, $quilt_mode;
5985     push @cachekey, $headref;
5986
5987     push @cachekey, hashfile('fake.dsc');
5988
5989     my $srcshash = Digest::SHA->new(256);
5990     my %sfs = ( %INC, '$0(dgit)' => $0 );
5991     foreach my $sfk (sort keys %sfs) {
5992         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5993         $srcshash->add($sfk,"  ");
5994         $srcshash->add(hashfile($sfs{$sfk}));
5995         $srcshash->add("\n");
5996     }
5997     push @cachekey, $srcshash->hexdigest();
5998     $splitbrain_cachekey = "@cachekey";
5999
6000     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
6001
6002     my $cachehit = reflog_cache_lookup
6003         "refs/$splitbraincache", $splitbrain_cachekey;
6004
6005     if ($cachehit) {
6006         unpack_playtree_need_cd_work($headref);
6007         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
6008         if ($cachehit ne $headref) {
6009             progress f_ "dgit view: found cached (%s)", $saved;
6010             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
6011             $made_split_brain = 1;
6012             return ($cachehit, $splitbrain_cachekey);
6013         }
6014         progress __ "dgit view: found cached, no changes required";
6015         return ($headref, $splitbrain_cachekey);
6016     }
6017
6018     printdebug "splitbrain cache miss\n";
6019     return (undef, $splitbrain_cachekey);
6020 }
6021
6022 sub quilt_fixup_multipatch ($$$) {
6023     my ($clogp, $headref, $upstreamversion, $splitbrain_cachekey) = @_;
6024
6025     progress f_ "examining quilt state (multiple patches, %s mode)",
6026                 $quilt_mode;
6027
6028     # Our objective is:
6029     #  - honour any existing .pc in case it has any strangeness
6030     #  - determine the git commit corresponding to the tip of
6031     #    the patch stack (if there is one)
6032     #  - if there is such a git commit, convert each subsequent
6033     #    git commit into a quilt patch with dpkg-source --commit
6034     #  - otherwise convert all the differences in the tree into
6035     #    a single git commit
6036     #
6037     # To do this we:
6038
6039     # Our git tree doesn't necessarily contain .pc.  (Some versions of
6040     # dgit would include the .pc in the git tree.)  If there isn't
6041     # one, we need to generate one by unpacking the patches that we
6042     # have.
6043     #
6044     # We first look for a .pc in the git tree.  If there is one, we
6045     # will use it.  (This is not the normal case.)
6046     #
6047     # Otherwise need to regenerate .pc so that dpkg-source --commit
6048     # can work.  We do this as follows:
6049     #     1. Collect all relevant .orig from parent directory
6050     #     2. Generate a debian.tar.gz out of
6051     #         debian/{patches,rules,source/format,source/options}
6052     #     3. Generate a fake .dsc containing just these fields:
6053     #          Format Source Version Files
6054     #     4. Extract the fake .dsc
6055     #        Now the fake .dsc has a .pc directory.
6056     # (In fact we do this in every case, because in future we will
6057     # want to search for a good base commit for generating patches.)
6058     #
6059     # Then we can actually do the dpkg-source --commit
6060     #     1. Make a new working tree with the same object
6061     #        store as our main tree and check out the main
6062     #        tree's HEAD.
6063     #     2. Copy .pc from the fake's extraction, if necessary
6064     #     3. Run dpkg-source --commit
6065     #     4. If the result has changes to debian/, then
6066     #          - git add them them
6067     #          - git add .pc if we had a .pc in-tree
6068     #          - git commit
6069     #     5. If we had a .pc in-tree, delete it, and git commit
6070     #     6. Back in the main tree, fast forward to the new HEAD
6071
6072     # Another situation we may have to cope with is gbp-style
6073     # patches-unapplied trees.
6074     #
6075     # We would want to detect these, so we know to escape into
6076     # quilt_fixup_gbp.  However, this is in general not possible.
6077     # Consider a package with a one patch which the dgit user reverts
6078     # (with git revert or the moral equivalent).
6079     #
6080     # That is indistinguishable in contents from a patches-unapplied
6081     # tree.  And looking at the history to distinguish them is not
6082     # useful because the user might have made a confusing-looking git
6083     # history structure (which ought to produce an error if dgit can't
6084     # cope, not a silent reintroduction of an unwanted patch).
6085     #
6086     # So gbp users will have to pass an option.  But we can usually
6087     # detect their failure to do so: if the tree is not a clean
6088     # patches-applied tree, quilt linearisation fails, but the tree
6089     # _is_ a clean patches-unapplied tree, we can suggest that maybe
6090     # they want --quilt=unapplied.
6091     #
6092     # To help detect this, when we are extracting the fake dsc, we
6093     # first extract it with --skip-patches, and then apply the patches
6094     # afterwards with dpkg-source --before-build.  That lets us save a
6095     # tree object corresponding to .origs.
6096
6097     if ($quilt_mode eq 'linear'
6098         && branch_is_gdr($headref)) {
6099         # This is much faster.  It also makes patches that gdr
6100         # likes better for future updates without laundering.
6101         #
6102         # However, it can fail in some casses where we would
6103         # succeed: if there are existing patches, which correspond
6104         # to a prefix of the branch, but are not in gbp/gdr
6105         # format, gdr will fail (exiting status 7), but we might
6106         # be able to figure out where to start linearising.  That
6107         # will be slower so hopefully there's not much to do.
6108
6109         unpack_playtree_need_cd_work $headref;
6110
6111         my @cmd = (@git_debrebase,
6112                    qw(--noop-ok -funclean-mixed -funclean-ordering
6113                       make-patches --quiet-would-amend));
6114         # We tolerate soe snags that gdr wouldn't, by default.
6115         if (act_local()) {
6116             debugcmd "+",@cmd;
6117             $!=0; $?=-1;
6118             failedcmd @cmd
6119                 if system @cmd
6120                 and not ($? == 7*256 or
6121                          $? == -1 && $!==ENOENT);
6122         } else {
6123             dryrun_report @cmd;
6124         }
6125         $headref = git_rev_parse('HEAD');
6126
6127         chdir '..';
6128     }
6129
6130     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
6131
6132     ensuredir '.pc';
6133
6134     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
6135     $!=0; $?=-1;
6136     if (system @bbcmd) {
6137         failedcmd @bbcmd if $? < 0;
6138         fail __ <<END;
6139 failed to apply your git tree's patch stack (from debian/patches/) to
6140  the corresponding upstream tarball(s).  Your source tree and .orig
6141  are probably too inconsistent.  dgit can only fix up certain kinds of
6142  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
6143 END
6144     }
6145
6146     changedir '..';
6147
6148     unpack_playtree_need_cd_work($headref);
6149
6150     my $mustdeletepc=0;
6151     if (stat_exists ".pc") {
6152         -d _ or die;
6153         progress __ "Tree already contains .pc - will use it then delete it.";
6154         $mustdeletepc=1;
6155     } else {
6156         rename '../fake/.pc','.pc' or confess "$!";
6157     }
6158
6159     changedir '../fake';
6160     rmtree '.pc';
6161     my $oldtiptree=git_add_write_tree();
6162     printdebug "fake o+d/p tree object $unapplied\n";
6163     changedir '../work';
6164
6165
6166     # We calculate some guesswork now about what kind of tree this might
6167     # be.  This is mostly for error reporting.
6168
6169     my %editedignores;
6170     my @unrepres;
6171     my $diffbits = {
6172         # H = user's HEAD
6173         # O = orig, without patches applied
6174         # A = "applied", ie orig with H's debian/patches applied
6175         O2H => quiltify_trees_differ($unapplied,$headref,   1,
6176                                      \%editedignores, \@unrepres),
6177         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
6178         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
6179     };
6180
6181     my @dl;
6182     foreach my $bits (qw(01 02)) {
6183         foreach my $v (qw(O2H O2A H2A)) {
6184             push @dl, ($diffbits->{$v} & $bits) ? '##' : '==';
6185         }
6186     }
6187     printdebug "differences \@dl @dl.\n";
6188
6189     progress f_
6190 "%s: base trees orig=%.20s o+d/p=%.20s",
6191               $us, $unapplied, $oldtiptree;
6192     progress f_
6193 "%s: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
6194 "%s: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
6195   $us,                      $dl[0], $dl[1],              $dl[3], $dl[4],
6196   $us,                          $dl[2],                     $dl[5];
6197
6198     if (@unrepres) {
6199         print STDERR f_ "dgit:  cannot represent change: %s: %s\n",
6200                         $_->[1], $_->[0]
6201             foreach @unrepres;
6202         forceable_fail [qw(unrepresentable)], __ <<END;
6203 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
6204 END
6205     }
6206
6207     my @failsuggestion;
6208     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
6209         push @failsuggestion, [ 'unapplied', __
6210  "This might be a patches-unapplied branch." ];
6211     } elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
6212         push @failsuggestion, [ 'applied', __
6213  "This might be a patches-applied branch." ];
6214     }
6215     push @failsuggestion, [ 'quilt-mode', __
6216  "Maybe you need one of --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?" ];
6217
6218     push @failsuggestion, [ 'gitattrs', __
6219  "Warning: Tree has .gitattributes.  See GITATTRIBUTES in dgit(7)." ]
6220         if stat_exists '.gitattributes';
6221
6222     push @failsuggestion, [ 'origs', __
6223  "Maybe orig tarball(s) are not identical to git representation?" ];
6224
6225     if (quiltmode_splitbrain()) {
6226         quiltify_splitbrain($clogp, $unapplied, $headref, $oldtiptree,
6227                             $diffbits, \%editedignores,
6228                             $splitbrain_cachekey);
6229         return;
6230     }
6231
6232     progress f_ "starting quiltify (multiple patches, %s mode)", $quilt_mode;
6233     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
6234     runcmd @git, qw(checkout -q), (qw(master dgit-view)[!!$do_split_brain]);
6235
6236     if (!open P, '>>', ".pc/applied-patches") {
6237         $!==&ENOENT or confess "$!";
6238     } else {
6239         close P;
6240     }
6241
6242     commit_quilty_patch();
6243
6244     if ($mustdeletepc) {
6245         quilt_fixup_delete_pc();
6246     }
6247 }
6248
6249 sub quilt_fixup_editor () {
6250     my $descfn = $ENV{$fakeeditorenv};
6251     my $editing = $ARGV[$#ARGV];
6252     open I1, '<', $descfn or confess "$descfn: $!";
6253     open I2, '<', $editing or confess "$editing: $!";
6254     unlink $editing or confess "$editing: $!";
6255     open O, '>', $editing or confess "$editing: $!";
6256     while (<I1>) { print O or confess "$!"; } I1->error and confess "$!";
6257     my $copying = 0;
6258     while (<I2>) {
6259         $copying ||= m/^\-\-\- /;
6260         next unless $copying;
6261         print O or confess "$!";
6262     }
6263     I2->error and confess "$!";
6264     close O or die $1;
6265     finish 0;
6266 }
6267
6268 sub maybe_apply_patches_dirtily () {
6269     return unless $quilt_mode =~ m/gbp|unapplied/;
6270     print STDERR __ <<END or confess "$!";
6271
6272 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
6273 dgit: Have to apply the patches - making the tree dirty.
6274 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
6275
6276 END
6277     $patches_applied_dirtily = 01;
6278     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
6279     runcmd qw(dpkg-source --before-build .);
6280 }
6281
6282 sub maybe_unapply_patches_again () {
6283     progress __ "dgit: Unapplying patches again to tidy up the tree."
6284         if $patches_applied_dirtily;
6285     runcmd qw(dpkg-source --after-build .)
6286         if $patches_applied_dirtily & 01;
6287     rmtree '.pc'
6288         if $patches_applied_dirtily & 02;
6289     $patches_applied_dirtily = 0;
6290 }
6291
6292 #----- other building -----
6293
6294 sub clean_tree_check_git ($$$) {
6295     my ($honour_ignores, $message, $ignmessage) = @_;
6296     my @cmd = (@git, qw(clean -dn));
6297     push @cmd, qw(-x) unless $honour_ignores;
6298     my $leftovers = cmdoutput @cmd;
6299     if (length $leftovers) {
6300         print STDERR $leftovers, "\n" or confess "$!";
6301         $message .= $ignmessage if $honour_ignores;
6302         fail $message;
6303     }
6304 }
6305
6306 sub clean_tree_check_git_wd ($) {
6307     my ($message) = @_;
6308     return if $cleanmode =~ m{no-check};
6309     return if $patches_applied_dirtily; # yuk
6310     clean_tree_check_git +($cleanmode !~ m{all-check}),
6311         $message, "\n".__ <<END;
6312 If this is just missing .gitignore entries, use a different clean
6313 mode, eg --clean=dpkg-source,no-check (-wdn/-wddn) to ignore them
6314 or --clean=git (-wg/-wgf) to use \`git clean' instead.
6315 END
6316 }
6317
6318 sub clean_tree_check () {
6319     # This function needs to not care about modified but tracked files.
6320     # That was done by check_not_dirty, and by now we may have run
6321     # the rules clean target which might modify tracked files (!)
6322     if ($cleanmode =~ m{^check}) {
6323         clean_tree_check_git +($cleanmode =~ m{ignores}), __
6324  "tree contains uncommitted files and --clean=check specified", '';
6325     } elsif ($cleanmode =~ m{^dpkg-source}) {
6326         clean_tree_check_git_wd __
6327  "tree contains uncommitted files (NB dgit didn't run rules clean)";
6328     } elsif ($cleanmode =~ m{^git}) {
6329         clean_tree_check_git 1, __
6330  "tree contains uncommited, untracked, unignored files\n".
6331  "You can use --clean=git[-ff],always (-wga/-wgfa) to delete them.", '';
6332     } elsif ($cleanmode eq 'none') {
6333     } else {
6334         confess "$cleanmode ?";
6335     }
6336 }
6337
6338 sub clean_tree () {
6339     # We always clean the tree ourselves, rather than leave it to the
6340     # builder (dpkg-source, or soemthing which calls dpkg-source).
6341     if ($cleanmode =~ m{^dpkg-source}) {
6342         my @cmd = @dpkgbuildpackage;
6343         push @cmd, qw(-d) if $cleanmode =~ m{^dpkg-source-d};
6344         push @cmd, qw(-T clean);
6345         maybe_apply_patches_dirtily();
6346         runcmd_ordryrun_local @cmd;
6347         clean_tree_check_git_wd __
6348  "tree contains uncommitted files (after running rules clean)";
6349     } elsif ($cleanmode =~ m{^git(?!-)}) {
6350         runcmd_ordryrun_local @git, qw(clean -xdf);
6351     } elsif ($cleanmode =~ m{^git-ff}) {
6352         runcmd_ordryrun_local @git, qw(clean -xdff);
6353     } elsif ($cleanmode =~ m{^check}) {
6354         clean_tree_check();
6355     } elsif ($cleanmode eq 'none') {
6356     } else {
6357         confess "$cleanmode ?";
6358     }
6359 }
6360
6361 sub cmd_clean () {
6362     badusage __ "clean takes no additional arguments" if @ARGV;
6363     notpushing();
6364     clean_tree();
6365     maybe_unapply_patches_again();
6366 }
6367
6368 # return values from massage_dbp_args are one or both of these flags
6369 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6370 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6371
6372 sub build_or_push_prep_early () {
6373     our $build_or_push_prep_early_done //= 0;
6374     return if $build_or_push_prep_early_done++;
6375     badusage f_ "-p is not allowed with dgit %s", $subcommand
6376         if defined $package;
6377     my $clogp = parsechangelog();
6378     $isuite = getfield $clogp, 'Distribution';
6379     $package = getfield $clogp, 'Source';
6380     $version = getfield $clogp, 'Version';
6381     $dscfn = dscfn($version);
6382 }
6383
6384 sub build_or_push_prep_modes () {
6385     my ($format,) = get_source_format();
6386     printdebug "format $format, quilt mode $quilt_mode\n";
6387     if (madformat_wantfixup($format) && quiltmode_splitbrain()) {
6388         $do_split_brain = 1;
6389     }
6390     fail __ "dgit: --include-dirty is not supported in split view quilt mode"
6391         if $do_split_brain && $includedirty;
6392 }
6393
6394 sub build_prep_early () {
6395     build_or_push_prep_early();
6396     notpushing();
6397     build_or_push_prep_modes();
6398     check_not_dirty();
6399 }
6400
6401 sub build_prep ($) {
6402     my ($wantsrc) = @_;
6403     build_prep_early();
6404     check_bpd_exists();
6405     if (!building_source_in_playtree() || ($wantsrc & WANTSRC_BUILDER)
6406         # Clean the tree because we're going to use the contents of
6407         # $maindir.  (We trying to include dirty changes in the source
6408         # package, or we are running the builder in $maindir.)
6409         || $cleanmode =~ m{always}) {
6410         # Or because the user asked us to.
6411         clean_tree();
6412     } else {
6413         # We don't actually need to do anything in $maindir, but we
6414         # should do some kind of cleanliness check because (i) the
6415         # user may have forgotten a `git add', and (ii) if the user
6416         # said -wc we should still do the check.
6417         clean_tree_check();
6418     }
6419     build_check_quilt_splitbrain();
6420     if ($rmchanges) {
6421         my $pat = changespat $version;
6422         foreach my $f (glob "$buildproductsdir/$pat") {
6423             if (act_local()) {
6424                 unlink $f or
6425                     fail f_ "remove old changes file %s: %s", $f, $!;
6426             } else {
6427                 progress f_ "would remove %s", $f;
6428             }
6429         }
6430     }
6431 }
6432
6433 sub changesopts_initial () {
6434     my @opts =@changesopts[1..$#changesopts];
6435 }
6436
6437 sub changesopts_version () {
6438     if (!defined $changes_since_version) {
6439         my @vsns;
6440         unless (eval {
6441             @vsns = archive_query('archive_query');
6442             my @quirk = access_quirk();
6443             if ($quirk[0] eq 'backports') {
6444                 local $isuite = $quirk[2];
6445                 local $csuite;
6446                 canonicalise_suite();
6447                 push @vsns, archive_query('archive_query');
6448             }
6449             1;
6450         }) {
6451             print STDERR $@;
6452             fail __
6453  "archive query failed (queried because --since-version not specified)";
6454         }
6455         if (@vsns) {
6456             @vsns = map { $_->[0] } @vsns;
6457             @vsns = sort { -version_compare($a, $b) } @vsns;
6458             $changes_since_version = $vsns[0];
6459             progress f_ "changelog will contain changes since %s", $vsns[0];
6460         } else {
6461             $changes_since_version = '_';
6462             progress __ "package seems new, not specifying -v<version>";
6463         }
6464     }
6465     if ($changes_since_version ne '_') {
6466         return ("-v$changes_since_version");
6467     } else {
6468         return ();
6469     }
6470 }
6471
6472 sub changesopts () {
6473     return (changesopts_initial(), changesopts_version());
6474 }
6475
6476 sub massage_dbp_args ($;$) {
6477     my ($cmd,$xargs) = @_;
6478     # Since we split the source build out so we can do strange things
6479     # to it, massage the arguments to dpkg-buildpackage so that the
6480     # main build doessn't build source (or add an argument to stop it
6481     # building source by default).
6482     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6483     # -nc has the side effect of specifying -b if nothing else specified
6484     # and some combinations of -S, -b, et al, are errors, rather than
6485     # later simply overriding earlie.  So we need to:
6486     #  - search the command line for these options
6487     #  - pick the last one
6488     #  - perhaps add our own as a default
6489     #  - perhaps adjust it to the corresponding non-source-building version
6490     my $dmode = '-F';
6491     foreach my $l ($cmd, $xargs) {
6492         next unless $l;
6493         @$l = grep { !(m/^-[SgGFABb]$|^--build=/s and $dmode=$_) } @$l;
6494     }
6495     push @$cmd, '-nc';
6496 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6497     my $r = WANTSRC_BUILDER;
6498     printdebug "massage split $dmode.\n";
6499     if ($dmode =~ s/^--build=//) {
6500         $r = 0;
6501         my @d = split /,/, $dmode;
6502         $r |= WANTSRC_SOURCE  if grep { s/^full$/binary/ } @d;
6503         $r |= WANTSRC_SOURCE  if grep { s/^source$// } @d;
6504         $r |= WANTSRC_BUILDER if grep { m/./ } @d;
6505         fail __ "Wanted to build nothing!" unless $r;
6506         $dmode = '--build='. join ',', grep m/./, @d;
6507     } else {
6508         $r =
6509           $dmode =~ m/[S]/     ?  WANTSRC_SOURCE :
6510           $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6511           $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6512           confess "$dmode ?";
6513     }
6514     printdebug "massage done $r $dmode.\n";
6515     push @$cmd, $dmode;
6516 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6517     return $r;
6518 }
6519
6520 sub in_bpd (&) {
6521     my ($fn) = @_;
6522     my $wasdir = must_getcwd();
6523     changedir $buildproductsdir;
6524     $fn->();
6525     changedir $wasdir;
6526 }
6527
6528 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6529 sub postbuild_mergechanges ($) {
6530     my ($msg_if_onlyone) = @_;
6531     # If there is only one .changes file, fail with $msg_if_onlyone,
6532     # or if that is undef, be a no-op.
6533     # Returns the changes file to report to the user.
6534     my $pat = changespat $version;
6535     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6536     @changesfiles = sort {
6537         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6538             or $a cmp $b
6539     } @changesfiles;
6540     my $result;
6541     if (@changesfiles==1) {
6542         fail +(f_ <<END, "@changesfiles").$msg_if_onlyone
6543 only one changes file from build (%s)
6544 END
6545             if defined $msg_if_onlyone;
6546         $result = $changesfiles[0];
6547     } elsif (@changesfiles==2) {
6548         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6549         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6550             fail f_ "%s found in binaries changes file %s", $l, $binchanges
6551                 if $l =~ m/\.dsc$/;
6552         }
6553         runcmd_ordryrun_local @mergechanges, @changesfiles;
6554         my $multichanges = changespat $version,'multi';
6555         if (act_local()) {
6556             stat_exists $multichanges or fail f_
6557                 "%s unexpectedly not created by build", $multichanges;
6558             foreach my $cf (glob $pat) {
6559                 next if $cf eq $multichanges;
6560                 rename "$cf", "$cf.inmulti" or fail f_
6561                     "install new changes %s\{,.inmulti}: %s", $cf, $!;
6562             }
6563         }
6564         $result = $multichanges;
6565     } else {
6566         fail f_ "wrong number of different changes files (%s)",
6567                 "@changesfiles";
6568     }
6569     printdone f_ "build successful, results in %s\n", $result
6570         or confess "$!";
6571 }
6572
6573 sub midbuild_checkchanges () {
6574     my $pat = changespat $version;
6575     return if $rmchanges;
6576     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6577     @unwanted = grep {
6578         $_ ne changespat $version,'source' and
6579         $_ ne changespat $version,'multi'
6580     } @unwanted;
6581     fail +(f_ <<END, $pat, "@unwanted")
6582 changes files other than source matching %s already present; building would result in ambiguity about the intended results.
6583 Suggest you delete %s.
6584 END
6585         if @unwanted;
6586 }
6587
6588 sub midbuild_checkchanges_vanilla ($) {
6589     my ($wantsrc) = @_;
6590     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6591 }
6592
6593 sub postbuild_mergechanges_vanilla ($) {
6594     my ($wantsrc) = @_;
6595     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6596         in_bpd {
6597             postbuild_mergechanges(undef);
6598         };
6599     } else {
6600         printdone __ "build successful\n";
6601     }
6602 }
6603
6604 sub cmd_build {
6605     build_prep_early();
6606     $buildproductsdir eq '..' or print STDERR +(f_ <<END, $us, $us);
6607 %s: warning: build-products-dir set, but not supported by dpkg-buildpackage
6608 %s: warning: build-products-dir will be ignored; files will go to ..
6609 END
6610     $buildproductsdir = '..';
6611     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6612     my $wantsrc = massage_dbp_args \@dbp;
6613     build_prep($wantsrc);
6614     if ($wantsrc & WANTSRC_SOURCE) {
6615         build_source();
6616         midbuild_checkchanges_vanilla $wantsrc;
6617     }
6618     if ($wantsrc & WANTSRC_BUILDER) {
6619         push @dbp, changesopts_version();
6620         maybe_apply_patches_dirtily();
6621         runcmd_ordryrun_local @dbp;
6622     }
6623     maybe_unapply_patches_again();
6624     postbuild_mergechanges_vanilla $wantsrc;
6625 }
6626
6627 sub pre_gbp_build {
6628     $quilt_mode //= 'gbp';
6629 }
6630
6631 sub cmd_gbp_build {
6632     build_prep_early();
6633
6634     # gbp can make .origs out of thin air.  In my tests it does this
6635     # even for a 1.0 format package, with no origs present.  So I
6636     # guess it keys off just the version number.  We don't know
6637     # exactly what .origs ought to exist, but let's assume that we
6638     # should run gbp if: the version has an upstream part and the main
6639     # orig is absent.
6640     my $upstreamversion = upstreamversion $version;
6641     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6642     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6643
6644     if ($gbp_make_orig) {
6645         clean_tree();
6646         $cleanmode = 'none'; # don't do it again
6647     }
6648
6649     my @dbp = @dpkgbuildpackage;
6650
6651     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6652
6653     if (!length $gbp_build[0]) {
6654         if (length executable_on_path('git-buildpackage')) {
6655             $gbp_build[0] = qw(git-buildpackage);
6656         } else {
6657             $gbp_build[0] = 'gbp buildpackage';
6658         }
6659     }
6660     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6661
6662     push @cmd, (qw(-us -uc --git-no-sign-tags),
6663                 "--git-builder=".(shellquote @dbp));
6664
6665     if ($gbp_make_orig) {
6666         my $priv = dgit_privdir();
6667         my $ok = "$priv/origs-gen-ok";
6668         unlink $ok or $!==&ENOENT or confess "$!";
6669         my @origs_cmd = @cmd;
6670         push @origs_cmd, qw(--git-cleaner=true);
6671         push @origs_cmd, "--git-prebuild=".
6672             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6673         push @origs_cmd, @ARGV;
6674         if (act_local()) {
6675             debugcmd @origs_cmd;
6676             system @origs_cmd;
6677             do { local $!; stat_exists $ok; }
6678                 or failedcmd @origs_cmd;
6679         } else {
6680             dryrun_report @origs_cmd;
6681         }
6682     }
6683
6684     build_prep($wantsrc);
6685     if ($wantsrc & WANTSRC_SOURCE) {
6686         build_source();
6687         midbuild_checkchanges_vanilla $wantsrc;
6688     } else {
6689         push @cmd, '--git-cleaner=true';
6690     }
6691     maybe_unapply_patches_again();
6692     if ($wantsrc & WANTSRC_BUILDER) {
6693         push @cmd, changesopts();
6694         runcmd_ordryrun_local @cmd, @ARGV;
6695     }
6696     postbuild_mergechanges_vanilla $wantsrc;
6697 }
6698 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6699
6700 sub building_source_in_playtree {
6701     # If $includedirty, we have to build the source package from the
6702     # working tree, not a playtree, so that uncommitted changes are
6703     # included (copying or hardlinking them into the playtree could
6704     # cause trouble).
6705     #
6706     # Note that if we are building a source package in split brain
6707     # mode we do not support including uncommitted changes, because
6708     # that makes quilt fixup too hard.  I.e. ($made_split_brain && (dgit is
6709     # building a source package)) => !$includedirty
6710     return !$includedirty;
6711 }
6712
6713 sub build_source {
6714     $sourcechanges = changespat $version,'source';
6715     if (act_local()) {
6716         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6717             or fail f_ "remove %s: %s", $sourcechanges, $!;
6718     }
6719 #    confess unless !!$made_split_brain == !!$do_split_brain;
6720
6721     my @cmd = (@dpkgsource, qw(-b --));
6722     my $leafdir;
6723     if (building_source_in_playtree()) {
6724         $leafdir = 'work';
6725         my $headref = git_rev_parse('HEAD');
6726         # If we are in split brain, there is already a playtree with
6727         # the thing we should package into a .dsc (thanks to quilt
6728         # fixup).  If not, make a playtree
6729         prep_ud() unless $made_split_brain;
6730         changedir $playground;
6731         unless ($made_split_brain) {
6732             my $upstreamversion = upstreamversion $version;
6733             unpack_playtree_linkorigs($upstreamversion, sub { });
6734             unpack_playtree_need_cd_work($headref);
6735             changedir '..';
6736         }
6737     } else {
6738         $leafdir = basename $maindir;
6739
6740         if ($buildproductsdir ne '..') {
6741             # Well, we are going to run dpkg-source -b which consumes
6742             # origs from .. and generates output there.  To make this
6743             # work when the bpd is not .. , we would have to (i) link
6744             # origs from bpd to .. , (ii) check for files that
6745             # dpkg-source -b would/might overwrite, and afterwards
6746             # (iii) move all the outputs back to the bpd (iv) except
6747             # for the origs which should be deleted from .. if they
6748             # weren't there beforehand.  And if there is an error and
6749             # we don't run to completion we would necessarily leave a
6750             # mess.  This is too much.  The real way to fix this
6751             # is for dpkg-source to have bpd support.
6752             confess unless $includedirty;
6753             fail __
6754  "--include-dirty not supported with --build-products-dir, sorry";
6755         }
6756
6757         changedir '..';
6758     }
6759     runcmd_ordryrun_local @cmd, $leafdir;
6760
6761     changedir $leafdir;
6762     runcmd_ordryrun_local qw(sh -ec),
6763       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6764       @dpkggenchanges, qw(-S), changesopts();
6765     changedir '..';
6766
6767     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6768     $dsc = parsecontrol($dscfn, "source package");
6769
6770     my $mv = sub {
6771         my ($why, $l) = @_;
6772         printdebug " renaming ($why) $l\n";
6773         rename_link_xf 0, "$l", bpd_abs()."/$l"
6774             or fail f_ "put in place new built file (%s): %s", $l, $@;
6775     };
6776     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6777         $l =~ m/\S+$/ or next;
6778         $mv->('Files', $&);
6779     }
6780     $mv->('dsc', $dscfn);
6781     $mv->('changes', $sourcechanges);
6782
6783     changedir $maindir;
6784 }
6785
6786 sub cmd_build_source {
6787     badusage __ "build-source takes no additional arguments" if @ARGV;
6788     build_prep(WANTSRC_SOURCE);
6789     build_source();
6790     maybe_unapply_patches_again();
6791     printdone f_ "source built, results in %s and %s",
6792                  $dscfn, $sourcechanges;
6793 }
6794
6795 sub cmd_push_source {
6796     prep_push();
6797     fail __
6798         "dgit push-source: --include-dirty/--ignore-dirty does not make".
6799         "sense with push-source!"
6800         if $includedirty;
6801     build_check_quilt_splitbrain();
6802     if ($changesfile) {
6803         my $changes = parsecontrol("$buildproductsdir/$changesfile",
6804                                    __ "source changes file");
6805         unless (test_source_only_changes($changes)) {
6806             fail __ "user-specified changes file is not source-only";
6807         }
6808     } else {
6809         # Building a source package is very fast, so just do it
6810         build_source();
6811         confess "er, patches are applied dirtily but shouldn't be.."
6812             if $patches_applied_dirtily;
6813         $changesfile = $sourcechanges;
6814     }
6815     dopush();
6816 }
6817
6818 sub binary_builder {
6819     my ($bbuilder, $pbmc_msg, @args) = @_;
6820     build_prep(WANTSRC_SOURCE);
6821     build_source();
6822     midbuild_checkchanges();
6823     in_bpd {
6824         if (act_local()) {
6825             stat_exists $dscfn or fail f_
6826                 "%s (in build products dir): %s", $dscfn, $!;
6827             stat_exists $sourcechanges or fail f_
6828                 "%s (in build products dir): %s", $sourcechanges, $!;
6829         }
6830         runcmd_ordryrun_local @$bbuilder, @args;
6831     };
6832     maybe_unapply_patches_again();
6833     in_bpd {
6834         postbuild_mergechanges($pbmc_msg);
6835     };
6836 }
6837
6838 sub cmd_sbuild {
6839     build_prep_early();
6840     binary_builder(\@sbuild, (__ <<END), qw(-d), $isuite, @ARGV, $dscfn);
6841 perhaps you need to pass -A ?  (sbuild's default is to build only
6842 arch-specific binaries; dgit 1.4 used to override that.)
6843 END
6844 }
6845
6846 sub pbuilder ($) {
6847     my ($pbuilder) = @_;
6848     build_prep_early();
6849     # @ARGV is allowed to contain only things that should be passed to
6850     # pbuilder under debbuildopts; just massage those
6851     my $wantsrc = massage_dbp_args \@ARGV;
6852     fail __
6853         "you asked for a builder but your debbuildopts didn't ask for".
6854         " any binaries -- is this really what you meant?"
6855         unless $wantsrc & WANTSRC_BUILDER;
6856     fail __
6857         "we must build a .dsc to pass to the builder but your debbuiltopts".
6858         " forbids the building of a source package; cannot continue"
6859       unless $wantsrc & WANTSRC_SOURCE;
6860     # We do not want to include the verb "build" in @pbuilder because
6861     # the user can customise @pbuilder and they shouldn't be required
6862     # to include "build" in their customised value.  However, if the
6863     # user passes any additional args to pbuilder using the dgit
6864     # option --pbuilder:foo, such args need to come after the "build"
6865     # verb.  opts_opt_multi_cmd does all of that.
6866     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
6867                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
6868                    $dscfn);
6869 }
6870
6871 sub cmd_pbuilder {
6872     pbuilder(\@pbuilder);
6873 }
6874
6875 sub cmd_cowbuilder {
6876     pbuilder(\@cowbuilder);
6877 }
6878
6879 sub cmd_quilt_fixup {
6880     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6881     build_prep_early();
6882     clean_tree();
6883     build_maybe_quilt_fixup();
6884 }
6885
6886 sub cmd_print_unapplied_treeish {
6887     badusage __ "incorrect arguments to dgit print-unapplied-treeish"
6888         if @ARGV;
6889     my $headref = git_rev_parse('HEAD');
6890     my $clogp = commit_getclogp $headref;
6891     $package = getfield $clogp, 'Source';
6892     $version = getfield $clogp, 'Version';
6893     $isuite = getfield $clogp, 'Distribution';
6894     $csuite = $isuite; # we want this to be offline!
6895     notpushing();
6896
6897     prep_ud();
6898     changedir $playground;
6899     my $uv = upstreamversion $version;
6900     my $u = quilt_fakedsc2unapplied($headref, $uv);
6901     print $u, "\n" or confess "$!";
6902 }
6903
6904 sub import_dsc_result {
6905     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6906     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
6907     runcmd @cmd;
6908     check_gitattrs($newhash, __ "source tree");
6909
6910     progress f_ "dgit: import-dsc: %s", $what_msg;
6911 }
6912
6913 sub cmd_import_dsc {
6914     my $needsig = 0;
6915
6916     while (@ARGV) {
6917         last unless $ARGV[0] =~ m/^-/;
6918         $_ = shift @ARGV;
6919         last if m/^--?$/;
6920         if (m/^--require-valid-signature$/) {
6921             $needsig = 1;
6922         } else {
6923             badusage f_ "unknown dgit import-dsc sub-option \`%s'", $_;
6924         }
6925     }
6926
6927     badusage __ "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH"
6928         unless @ARGV==2;
6929     my ($dscfn, $dstbranch) = @ARGV;
6930
6931     badusage __ "dry run makes no sense with import-dsc"
6932         unless act_local();
6933
6934     my $force = $dstbranch =~ s/^\+//   ? +1 :
6935                 $dstbranch =~ s/^\.\.// ? -1 :
6936                                            0;
6937     my $info = $force ? " $&" : '';
6938     $info = "$dscfn$info";
6939
6940     my $specbranch = $dstbranch;
6941     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6942     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6943
6944     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6945     my $chead = cmdoutput_errok @symcmd;
6946     defined $chead or $?==256 or failedcmd @symcmd;
6947
6948     fail f_ "%s is checked out - will not update it", $dstbranch
6949         if defined $chead and $chead eq $dstbranch;
6950
6951     my $oldhash = git_get_ref $dstbranch;
6952
6953     open D, "<", $dscfn or fail f_ "open import .dsc (%s): %s", $dscfn, $!;
6954     $dscdata = do { local $/ = undef; <D>; };
6955     D->error and fail f_ "read %s: %s", $dscfn, $!;
6956     close C;
6957
6958     # we don't normally need this so import it here
6959     use Dpkg::Source::Package;
6960     my $dp = new Dpkg::Source::Package filename => $dscfn,
6961         require_valid_signature => $needsig;
6962     {
6963         local $SIG{__WARN__} = sub {
6964             print STDERR $_[0];
6965             return unless $needsig;
6966             fail __ "import-dsc signature check failed";
6967         };
6968         if (!$dp->is_signed()) {
6969             warn f_ "%s: warning: importing unsigned .dsc\n", $us;
6970         } else {
6971             my $r = $dp->check_signature();
6972             confess "->check_signature => $r" if $needsig && $r;
6973         }
6974     }
6975
6976     parse_dscdata();
6977
6978     $package = getfield $dsc, 'Source';
6979
6980     parse_dsc_field($dsc, __ "Dgit metadata in .dsc")
6981         unless forceing [qw(import-dsc-with-dgit-field)];
6982     parse_dsc_field_def_dsc_distro();
6983
6984     $isuite = 'DGIT-IMPORT-DSC';
6985     $idistro //= $dsc_distro;
6986
6987     notpushing();
6988
6989     if (defined $dsc_hash) {
6990         progress __
6991             "dgit: import-dsc of .dsc with Dgit field, using git hash";
6992         resolve_dsc_field_commit undef, undef;
6993     }
6994     if (defined $dsc_hash) {
6995         my @cmd = (qw(sh -ec),
6996                    "echo $dsc_hash | git cat-file --batch-check");
6997         my $objgot = cmdoutput @cmd;
6998         if ($objgot =~ m#^\w+ missing\b#) {
6999             fail f_ <<END, $dsc_hash
7000 .dsc contains Dgit field referring to object %s
7001 Your git tree does not have that object.  Try `git fetch' from a
7002 plausible server (browse.dgit.d.o? salsa?), and try the import-dsc again.
7003 END
7004         }
7005         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
7006             if ($force > 0) {
7007                 progress __ "Not fast forward, forced update.";
7008             } else {
7009                 fail f_ "Not fast forward to %s", $dsc_hash;
7010             }
7011         }
7012         import_dsc_result $dstbranch, $dsc_hash,
7013             "dgit import-dsc (Dgit): $info",
7014             f_ "updated git ref %s", $dstbranch;
7015         return 0;
7016     }
7017
7018     fail f_ <<END, $dstbranch, $specbranch, $specbranch
7019 Branch %s already exists
7020 Specify ..%s for a pseudo-merge, binding in existing history
7021 Specify  +%s to overwrite, discarding existing history
7022 END
7023         if $oldhash && !$force;
7024
7025     my @dfi = dsc_files_info();
7026     foreach my $fi (@dfi) {
7027         my $f = $fi->{Filename};
7028         # We transfer all the pieces of the dsc to the bpd, not just
7029         # origs.  This is by analogy with dgit fetch, which wants to
7030         # keep them somewhere to avoid downloading them again.
7031         # We make symlinks, though.  If the user wants copies, then
7032         # they can copy the parts of the dsc to the bpd using dcmd,
7033         # or something.
7034         my $here = "$buildproductsdir/$f";
7035         if (lstat $here) {
7036             if (stat $here) {
7037                 next;
7038             }
7039             fail f_ "lstat %s works but stat gives %s !", $here, $!;
7040         }
7041         fail f_ "stat %s: %s", $here, $! unless $! == ENOENT;
7042         printdebug "not in bpd, $f ...\n";
7043         # $f does not exist in bpd, we need to transfer it
7044         my $there = $dscfn;
7045         $there =~ s{[^/]+$}{$f} or confess "$there ?";
7046         # $there is file we want, relative to user's cwd, or abs
7047         printdebug "not in bpd, $f, test $there ...\n";
7048         stat $there or fail f_
7049             "import %s requires %s, but: %s", $dscfn, $there, $!;
7050         if ($there =~ m#^(?:\./+)?\.\./+#) {
7051             # $there is relative to user's cwd
7052             my $there_from_parent = $';
7053             if ($buildproductsdir !~ m{^/}) {
7054                 # abs2rel, despite its name, can take two relative paths
7055                 $there = File::Spec->abs2rel($there,$buildproductsdir);
7056                 # now $there is relative to bpd, great
7057                 printdebug "not in bpd, $f, abs2rel, $there ...\n";
7058             } else {
7059                 $there = (dirname $maindir)."/$there_from_parent";
7060                 # now $there is absoute
7061                 printdebug "not in bpd, $f, rel2rel, $there ...\n";
7062             }
7063         } elsif ($there =~ m#^/#) {
7064             # $there is absolute already
7065             printdebug "not in bpd, $f, abs, $there ...\n";
7066         } else {
7067             fail f_
7068                 "cannot import %s which seems to be inside working tree!",
7069                 $dscfn;
7070         }
7071         symlink $there, $here or fail f_
7072             "symlink %s to %s: %s", $there, $here, $!;
7073         progress f_ "made symlink %s -> %s", $here, $there;
7074 #       print STDERR Dumper($fi);
7075     }
7076     my @mergeinputs = generate_commits_from_dsc();
7077     die unless @mergeinputs == 1;
7078
7079     my $newhash = $mergeinputs[0]{Commit};
7080
7081     if ($oldhash) {
7082         if ($force > 0) {
7083             progress __
7084                 "Import, forced update - synthetic orphan git history.";
7085         } elsif ($force < 0) {
7086             progress __ "Import, merging.";
7087             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
7088             my $version = getfield $dsc, 'Version';
7089             my $clogp = commit_getclogp $newhash;
7090             my $authline = clogp_authline $clogp;
7091             $newhash = make_commit_text <<ENDU
7092 tree $tree
7093 parent $newhash
7094 parent $oldhash
7095 author $authline
7096 committer $authline
7097
7098 ENDU
7099                 .(f_ <<END, $package, $version, $dstbranch);
7100 Merge %s (%s) import into %s
7101 END
7102         } else {
7103             die; # caught earlier
7104         }
7105     }
7106
7107     import_dsc_result $dstbranch, $newhash,
7108         "dgit import-dsc: $info",
7109         f_ "results are in git ref %s", $dstbranch;
7110 }
7111
7112 sub pre_archive_api_query () {
7113     not_necessarily_a_tree();
7114 }
7115 sub cmd_archive_api_query {
7116     badusage __ "need only 1 subpath argument" unless @ARGV==1;
7117     my ($subpath) = @ARGV;
7118     local $isuite = 'DGIT-API-QUERY-CMD';
7119     my @cmd = archive_api_query_cmd($subpath);
7120     push @cmd, qw(-f);
7121     debugcmd ">",@cmd;
7122     exec @cmd or fail f_ "exec curl: %s\n", $!;
7123 }
7124
7125 sub repos_server_url () {
7126     $package = '_dgit-repos-server';
7127     local $access_forpush = 1;
7128     local $isuite = 'DGIT-REPOS-SERVER';
7129     my $url = access_giturl();
7130 }
7131
7132 sub pre_clone_dgit_repos_server () {
7133     not_necessarily_a_tree();
7134 }
7135 sub cmd_clone_dgit_repos_server {
7136     badusage __ "need destination argument" unless @ARGV==1;
7137     my ($destdir) = @ARGV;
7138     my $url = repos_server_url();
7139     my @cmd = (@git, qw(clone), $url, $destdir);
7140     debugcmd ">",@cmd;
7141     exec @cmd or fail f_ "exec git clone: %s\n", $!;
7142 }
7143
7144 sub pre_print_dgit_repos_server_source_url () {
7145     not_necessarily_a_tree();
7146 }
7147 sub cmd_print_dgit_repos_server_source_url {
7148     badusage __
7149         "no arguments allowed to dgit print-dgit-repos-server-source-url"
7150         if @ARGV;
7151     my $url = repos_server_url();
7152     print $url, "\n" or confess "$!";
7153 }
7154
7155 sub pre_print_dpkg_source_ignores {
7156     not_necessarily_a_tree();
7157 }
7158 sub cmd_print_dpkg_source_ignores {
7159     badusage __
7160         "no arguments allowed to dgit print-dpkg-source-ignores"
7161         if @ARGV;
7162     print "@dpkg_source_ignores\n" or confess "$!";
7163 }
7164
7165 sub cmd_setup_mergechangelogs {
7166     badusage __ "no arguments allowed to dgit setup-mergechangelogs"
7167         if @ARGV;
7168     local $isuite = 'DGIT-SETUP-TREE';
7169     setup_mergechangelogs(1);
7170 }
7171
7172 sub cmd_setup_useremail {
7173     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7174     local $isuite = 'DGIT-SETUP-TREE';
7175     setup_useremail(1);
7176 }
7177
7178 sub cmd_setup_gitattributes {
7179     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7180     local $isuite = 'DGIT-SETUP-TREE';
7181     setup_gitattrs(1);
7182 }
7183
7184 sub cmd_setup_new_tree {
7185     badusage __ "no arguments allowed to dgit setup-tree" if @ARGV;
7186     local $isuite = 'DGIT-SETUP-TREE';
7187     setup_new_tree();
7188 }
7189
7190 #---------- argument parsing and main program ----------
7191
7192 sub cmd_version {
7193     print "dgit version $our_version\n" or confess "$!";
7194     finish 0;
7195 }
7196
7197 our (%valopts_long, %valopts_short);
7198 our (%funcopts_long);
7199 our @rvalopts;
7200 our (@modeopt_cfgs);
7201
7202 sub defvalopt ($$$$) {
7203     my ($long,$short,$val_re,$how) = @_;
7204     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
7205     $valopts_long{$long} = $oi;
7206     $valopts_short{$short} = $oi;
7207     # $how subref should:
7208     #   do whatever assignemnt or thing it likes with $_[0]
7209     #   if the option should not be passed on to remote, @rvalopts=()
7210     # or $how can be a scalar ref, meaning simply assign the value
7211 }
7212
7213 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
7214 defvalopt '--distro',        '-d', '.+',      \$idistro;
7215 defvalopt '',                '-k', '.+',      \$keyid;
7216 defvalopt '--existing-package','', '.*',      \$existing_package;
7217 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
7218 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
7219 defvalopt '--package',   '-p',   $package_re, \$package;
7220 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
7221
7222 defvalopt '', '-C', '.+', sub {
7223     ($changesfile) = (@_);
7224     if ($changesfile =~ s#^(.*)/##) {
7225         $buildproductsdir = $1;
7226     }
7227 };
7228
7229 defvalopt '--initiator-tempdir','','.*', sub {
7230     ($initiator_tempdir) = (@_);
7231     $initiator_tempdir =~ m#^/# or
7232         badusage __ "--initiator-tempdir must be used specify an".
7233                     " absolute, not relative, directory."
7234 };
7235
7236 sub defoptmodes ($@) {
7237     my ($varref, $cfgkey, $default, %optmap) = @_;
7238     my %permit;
7239     while (my ($opt,$val) = each %optmap) {
7240         $funcopts_long{$opt} = sub { $$varref = $val; };
7241         $permit{$val} = $val;
7242     }
7243     push @modeopt_cfgs, {
7244         Var => $varref,
7245         Key => $cfgkey,
7246         Default => $default,
7247         Vals => \%permit
7248     };
7249 }
7250
7251 defoptmodes \$dodep14tag, qw( dep14tag          want
7252                               --dep14tag        want
7253                               --no-dep14tag     no
7254                               --always-dep14tag always );
7255
7256 sub parseopts () {
7257     my $om;
7258
7259     if (defined $ENV{'DGIT_SSH'}) {
7260         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
7261     } elsif (defined $ENV{'GIT_SSH'}) {
7262         @ssh = ($ENV{'GIT_SSH'});
7263     }
7264
7265     my $oi;
7266     my $val;
7267     my $valopt = sub {
7268         my ($what) = @_;
7269         @rvalopts = ($_);
7270         if (!defined $val) {
7271             badusage f_ "%s needs a value", $what unless @ARGV;
7272             $val = shift @ARGV;
7273             push @rvalopts, $val;
7274         }
7275         badusage f_ "bad value \`%s' for %s", $val, $what unless
7276             $val =~ m/^$oi->{Re}$(?!\n)/s;
7277         my $how = $oi->{How};
7278         if (ref($how) eq 'SCALAR') {
7279             $$how = $val;
7280         } else {
7281             $how->($val);
7282         }
7283         push @ropts, @rvalopts;
7284     };
7285
7286     while (@ARGV) {
7287         last unless $ARGV[0] =~ m/^-/;
7288         $_ = shift @ARGV;
7289         last if m/^--?$/;
7290         if (m/^--/) {
7291             if (m/^--dry-run$/) {
7292                 push @ropts, $_;
7293                 $dryrun_level=2;
7294             } elsif (m/^--damp-run$/) {
7295                 push @ropts, $_;
7296                 $dryrun_level=1;
7297             } elsif (m/^--no-sign$/) {
7298                 push @ropts, $_;
7299                 $sign=0;
7300             } elsif (m/^--help$/) {
7301                 cmd_help();
7302             } elsif (m/^--version$/) {
7303                 cmd_version();
7304             } elsif (m/^--new$/) {
7305                 push @ropts, $_;
7306                 $new_package=1;
7307             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
7308                      ($om = $opts_opt_map{$1}) &&
7309                      length $om->[0]) {
7310                 push @ropts, $_;
7311                 $om->[0] = $2;
7312             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
7313                      !$opts_opt_cmdonly{$1} &&
7314                      ($om = $opts_opt_map{$1})) {
7315                 push @ropts, $_;
7316                 push @$om, $2;
7317             } elsif (m/^--([-0-9a-z]+)\!:(.*)/s &&
7318                      !$opts_opt_cmdonly{$1} &&
7319                      ($om = $opts_opt_map{$1})) {
7320                 push @ropts, $_;
7321                 my $cmd = shift @$om;
7322                 @$om = ($cmd, grep { $_ ne $2 } @$om);
7323             } elsif (m/^--(gbp|dpm)$/s) {
7324                 push @ropts, "--quilt=$1";
7325                 $quilt_mode = $1;
7326             } elsif (m/^--(?:ignore|include)-dirty$/s) {
7327                 push @ropts, $_;
7328                 $includedirty = 1;
7329             } elsif (m/^--no-quilt-fixup$/s) {
7330                 push @ropts, $_;
7331                 $quilt_mode = 'nocheck';
7332             } elsif (m/^--no-rm-on-error$/s) {
7333                 push @ropts, $_;
7334                 $rmonerror = 0;
7335             } elsif (m/^--no-chase-dsc-distro$/s) {
7336                 push @ropts, $_;
7337                 $chase_dsc_distro = 0;
7338             } elsif (m/^--overwrite$/s) {
7339                 push @ropts, $_;
7340                 $overwrite_version = '';
7341             } elsif (m/^--overwrite=(.+)$/s) {
7342                 push @ropts, $_;
7343                 $overwrite_version = $1;
7344             } elsif (m/^--delayed=(\d+)$/s) {
7345                 push @ropts, $_;
7346                 push @dput, $_;
7347             } elsif (m/^--save-(dgit-view)=(.+)$/s ||
7348                      m/^--(dgit-view)-save=(.+)$/s
7349                      ) {
7350                 my ($k,$v) = ($1,$2);
7351                 push @ropts, $_;
7352                 $v =~ s#^(?!refs/)#refs/heads/#;
7353                 $internal_object_save{$k} = $v;
7354             } elsif (m/^--(no-)?rm-old-changes$/s) {
7355                 push @ropts, $_;
7356                 $rmchanges = !$1;
7357             } elsif (m/^--deliberately-($deliberately_re)$/s) {
7358                 push @ropts, $_;
7359                 push @deliberatelies, $&;
7360             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
7361                 push @ropts, $&;
7362                 $forceopts{$1} = 1;
7363                 $_='';
7364             } elsif (m/^--force-/) {
7365                 print STDERR
7366                     f_ "%s: warning: ignoring unknown force option %s\n",
7367                        $us, $_;
7368                 $_='';
7369             } elsif (m/^--config-lookup-explode=(.+)$/s) {
7370                 # undocumented, for testing
7371                 push @ropts, $_;
7372                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
7373                 # ^ it's supposed to be an array ref
7374             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
7375                 $val = $2 ? $' : undef; #';
7376                 $valopt->($oi->{Long});
7377             } elsif ($funcopts_long{$_}) {
7378                 push @ropts, $_;
7379                 $funcopts_long{$_}();
7380             } else {
7381                 badusage f_ "unknown long option \`%s'", $_;
7382             }
7383         } else {
7384             while (m/^-./s) {
7385                 if (s/^-n/-/) {
7386                     push @ropts, $&;
7387                     $dryrun_level=2;
7388                 } elsif (s/^-L/-/) {
7389                     push @ropts, $&;
7390                     $dryrun_level=1;
7391                 } elsif (s/^-h/-/) {
7392                     cmd_help();
7393                 } elsif (s/^-D/-/) {
7394                     push @ropts, $&;
7395                     $debuglevel++;
7396                     enabledebug();
7397                 } elsif (s/^-N/-/) {
7398                     push @ropts, $&;
7399                     $new_package=1;
7400                 } elsif (m/^-m/) {
7401                     push @ropts, $&;
7402                     push @changesopts, $_;
7403                     $_ = '';
7404                 } elsif (s/^-wn$//s) {
7405                     push @ropts, $&;
7406                     $cleanmode = 'none';
7407                 } elsif (s/^-wg(f?)(a?)$//s) {
7408                     push @ropts, $&;
7409                     $cleanmode = 'git';
7410                     $cleanmode .= '-ff' if $1;
7411                     $cleanmode .= ',always' if $2;
7412                 } elsif (s/^-wd(d?)([na]?)$//s) {
7413                     push @ropts, $&;
7414                     $cleanmode = 'dpkg-source';
7415                     $cleanmode .= '-d' if $1;
7416                     $cleanmode .= ',no-check' if $2 eq 'n';
7417                     $cleanmode .= ',all-check' if $2 eq 'a';
7418                 } elsif (s/^-wc$//s) {
7419                     push @ropts, $&;
7420                     $cleanmode = 'check';
7421                 } elsif (s/^-wci$//s) {
7422                     push @ropts, $&;
7423                     $cleanmode = 'check,ignores';
7424                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
7425                     push @git, '-c', $&;
7426                     $gitcfgs{cmdline}{$1} = [ $2 ];
7427                 } elsif (s/^-c([^=]+)$//s) {
7428                     push @git, '-c', $&;
7429                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7430                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7431                     $val = $'; #';
7432                     $val = undef unless length $val;
7433                     $valopt->($oi->{Short});
7434                     $_ = '';
7435                 } else {
7436                     badusage f_ "unknown short option \`%s'", $_;
7437                 }
7438             }
7439         }
7440     }
7441 }
7442
7443 sub check_env_sanity () {
7444     my $blocked = new POSIX::SigSet;
7445     sigprocmask SIG_UNBLOCK, $blocked, $blocked or confess "$!";
7446
7447     eval {
7448         foreach my $name (qw(PIPE CHLD)) {
7449             my $signame = "SIG$name";
7450             my $signum = eval "POSIX::$signame" // die;
7451             die f_ "%s is set to something other than SIG_DFL\n",
7452                 $signame
7453                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7454             $blocked->ismember($signum) and
7455                 die f_ "%s is blocked\n", $signame;
7456         }
7457     };
7458     return unless $@;
7459     chomp $@;
7460     fail f_ <<END, $@;
7461 On entry to dgit, %s
7462 This is a bug produced by something in your execution environment.
7463 Giving up.
7464 END
7465 }
7466
7467
7468 sub parseopts_late_defaults () {
7469     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7470         if defined $idistro;
7471     $isuite //= cfg('dgit.default.default-suite');
7472
7473     foreach my $k (keys %opts_opt_map) {
7474         my $om = $opts_opt_map{$k};
7475
7476         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7477         if (defined $v) {
7478             badcfg f_ "cannot set command for %s", $k
7479                 unless length $om->[0];
7480             $om->[0] = $v;
7481         }
7482
7483         foreach my $c (access_cfg_cfgs("opts-$k")) {
7484             my @vl =
7485                 map { $_ ? @$_ : () }
7486                 map { $gitcfgs{$_}{$c} }
7487                 reverse @gitcfgsources;
7488             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7489                 "\n" if $debuglevel >= 4;
7490             next unless @vl;
7491             badcfg f_ "cannot configure options for %s", $k
7492                 if $opts_opt_cmdonly{$k};
7493             my $insertpos = $opts_cfg_insertpos{$k};
7494             @$om = ( @$om[0..$insertpos-1],
7495                      @vl,
7496                      @$om[$insertpos..$#$om] );
7497         }
7498     }
7499
7500     if (!defined $rmchanges) {
7501         local $access_forpush;
7502         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7503     }
7504
7505     if (!defined $quilt_mode) {
7506         local $access_forpush;
7507         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7508             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7509             // 'linear';
7510         $quilt_mode =~ m/^($quilt_modes_re)$/
7511             or badcfg f_ "unknown quilt-mode \`%s'", $quilt_mode;
7512         $quilt_mode = $1;
7513     }
7514
7515     foreach my $moc (@modeopt_cfgs) {
7516         local $access_forpush;
7517         my $vr = $moc->{Var};
7518         next if defined $$vr;
7519         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7520         my $v = $moc->{Vals}{$$vr};
7521         badcfg f_ "unknown %s setting \`%s'", $moc->{Key}, $$vr
7522             unless defined $v;
7523         $$vr = $v;
7524     }
7525
7526     {
7527         local $access_forpush;
7528         default_from_access_cfg(\$cleanmode, 'clean-mode', 'dpkg-source',
7529                                 $cleanmode_re);
7530     }
7531
7532     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7533     $buildproductsdir //= '..';
7534     $bpd_glob = $buildproductsdir;
7535     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7536 }
7537
7538 setlocale(LC_MESSAGES, "");
7539 textdomain("dgit");
7540
7541 if ($ENV{$fakeeditorenv}) {
7542     git_slurp_config();
7543     quilt_fixup_editor();
7544 }
7545
7546 parseopts();
7547 check_env_sanity();
7548
7549 print STDERR __ "DRY RUN ONLY\n" if $dryrun_level > 1;
7550 print STDERR __ "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7551     if $dryrun_level == 1;
7552 if (!@ARGV) {
7553     print STDERR __ $helpmsg or confess "$!";
7554     finish 8;
7555 }
7556 $cmd = $subcommand = shift @ARGV;
7557 $cmd =~ y/-/_/;
7558
7559 my $pre_fn = ${*::}{"pre_$cmd"};
7560 $pre_fn->() if $pre_fn;
7561
7562 if ($invoked_in_git_tree) {
7563     changedir_git_toplevel();
7564     record_maindir();
7565 }
7566 git_slurp_config();
7567
7568 my $fn = ${*::}{"cmd_$cmd"};
7569 $fn or badusage f_ "unknown operation %s", $cmd;
7570 $fn->();
7571
7572 finish 0;