dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit qw(:DEFAULT :playground);
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $cmd;
  51 our $subcommand;
  52 our $isuite;
  53 our $idistro;
  54 our $package;
  55 our @ropts;
  56
  57 our $sign = 1;
  58 our $dryrun_level = 0;
  59 our $changesfile;
  60 our $buildproductsdir = '..';
  61 our $new_package = 0;
  62 our $ignoredirty = 0;
  63 our $rmonerror = 1;
  64 our @deliberatelies;
  65 our %previously;
  66 our $existing_package = 'dpkg';
  67 our $cleanmode;
  68 our $changes_since_version;
  69 our $rmchanges;
  70 our $overwrite_version; # undef: not specified; '': check changelog
  71 our $quilt_mode;
  72 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  73 our $dodep14tag;
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $we_are_initiator;
  77 our $initiator_tempdir;
  78 our $patches_applied_dirtily = 00;
  79 our $tagformat_want;
  80 our $tagformat;
  81 our $tagformatfn;
  82 our $chase_dsc_distro=1;
  83
  84 our %forceopts = map { $_=>0 }
  85     qw(unrepresentable unsupported-source-format
  86        dsc-changes-mismatch changes-origs-exactly
  87        import-gitapply-absurd
  88        import-gitapply-no-absurd
  89        import-dsc-with-dgit-field);
  90
  91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  92
  93 our $suite_re = '[-+.0-9a-z]+';
  94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  98
  99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 100 our $splitbraincache = 'dgit-intern/quilt-cache';
 101 our $rewritemap = 'dgit-rewrite/map';
 102
 103 our (@git) = qw(git);
 104 our (@dget) = qw(dget);
 105 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 106 our (@dput) = qw(dput);
 107 our (@debsign) = qw(debsign);
 108 our (@gpg) = qw(gpg);
 109 our (@sbuild) = qw(sbuild);
 110 our (@ssh) = 'ssh';
 111 our (@dgit) = qw(dgit);
 112 our (@aptget) = qw(apt-get);
 113 our (@aptcache) = qw(apt-cache);
 114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 116 our (@dpkggenchanges) = qw(dpkg-genchanges);
 117 our (@mergechanges) = qw(mergechanges -f);
 118 our (@gbp_build) = ('');
 119 our (@gbp_pq) = ('gbp pq');
 120 our (@changesopts) = ('');
 121
 122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 123                      'curl' => \@curl,
 124                      'dput' => \@dput,
 125                      'debsign' => \@debsign,
 126                      'gpg' => \@gpg,
 127                      'sbuild' => \@sbuild,
 128                      'ssh' => \@ssh,
 129                      'dgit' => \@dgit,
 130                      'git' => \@git,
 131                      'apt-get' => \@aptget,
 132                      'apt-cache' => \@aptcache,
 133                      'dpkg-source' => \@dpkgsource,
 134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 135                      'dpkg-genchanges' => \@dpkggenchanges,
 136                      'gbp-build' => \@gbp_build,
 137                      'gbp-pq' => \@gbp_pq,
 138                      'ch' => \@changesopts,
 139                      'mergechanges' => \@mergechanges);
 140
 141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 142 our %opts_cfg_insertpos = map {
 143     $_,
 144     scalar @{ $opts_opt_map{$_} }
 145 } keys %opts_opt_map;
 146
 147 sub parseopts_late_defaults();
 148 sub setup_gitattrs(;$);
 149 sub check_gitattrs($$);
 150
 151 our $keyid;
 152
 153 autoflush STDOUT 1;
 154
 155 our $supplementary_message = '';
 156 our $need_split_build_invocation = 0;
 157 our $split_brain = 0;
 158
 159 END {
 160     local ($@, $?);
 161     return unless forkcheck_mainprocess();
 162     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 163 }
 164
 165 our $remotename = 'dgit';
 166 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 167 our $csuite;
 168 our $instead_distro;
 169
 170 if (!defined $absurdity) {
 171     $absurdity = $0;
 172     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 173 }
 174
 175 sub debiantag ($$) {
 176     my ($v,$distro) = @_;
 177     return $tagformatfn->($v, $distro);
 178 }
 179
 180 sub debiantag_maintview ($$) {
 181     my ($v,$distro) = @_;
 182     return "$distro/".dep14_version_mangle $v;
 183 }
 184
 185 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 186
 187 sub lbranch () { return "$branchprefix/$csuite"; }
 188 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 189 sub lref () { return "refs/heads/".lbranch(); }
 190 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 191 sub rrref () { return server_ref($csuite); }
 192
 193 sub stripepoch ($) {
 194     my ($vsn) = @_;
 195     $vsn =~ s/^\d+\://;
 196     return $vsn;
 197 }
 198
 199 sub srcfn ($$) {
 200     my ($vsn,$sfx) = @_;
 201     return "${package}_".(stripepoch $vsn).$sfx
 202 }
 203
 204 sub dscfn ($) {
 205     my ($vsn) = @_;
 206     return srcfn($vsn,".dsc");
 207 }
 208
 209 sub changespat ($;$) {
 210     my ($vsn, $arch) = @_;
 211     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 212 }
 213
 214 sub upstreamversion ($) {
 215     my ($vsn) = @_;
 216     $vsn =~ s/-[^-]+$//;
 217     return $vsn;
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     exit 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my @cmd;
 271     push @cmd, split /\s+/, shift @_;
 272     push @cmd, @_;
 273     @cmd;
 274 }
 275
 276 sub gbp_pq {
 277     return opts_opt_multi_cmd @gbp_pq;
 278 }
 279
 280 #---------- remote protocol support, common ----------
 281
 282 # remote push initiator/responder protocol:
 283 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 284 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 285 #  < dgit-remote-push-ready <actual-proto-vsn>
 286 #
 287 # occasionally:
 288 #
 289 #  > progress NBYTES
 290 #  [NBYTES message]
 291 #
 292 #  > supplementary-message NBYTES          # $protovsn >= 3
 293 #  [NBYTES message]
 294 #
 295 # main sequence:
 296 #
 297 #  > file parsed-changelog
 298 #  [indicates that output of dpkg-parsechangelog follows]
 299 #  > data-block NBYTES
 300 #  > [NBYTES bytes of data (no newline)]
 301 #  [maybe some more blocks]
 302 #  > data-end
 303 #
 304 #  > file dsc
 305 #  [etc]
 306 #
 307 #  > file changes
 308 #  [etc]
 309 #
 310 #  > param head DGIT-VIEW-HEAD
 311 #  > param csuite SUITE
 312 #  > param tagformat old|new
 313 #  > param maint-view MAINT-VIEW-HEAD
 314 #
 315 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 316 #  > file buildinfo                             # for buildinfos to sign
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < data-block NBYTES    [transfer of each signed buildinfo
 335 #  [etc]                   same number and order as "file buildinfo"]
 336 #  ...
 337 #  < files-end
 338 #
 339 #  > complete
 340
 341 our $i_child_pid;
 342
 343 sub i_child_report () {
 344     # Sees if our child has died, and reap it if so.  Returns a string
 345     # describing how it died if it failed, or undef otherwise.
 346     return undef unless $i_child_pid;
 347     my $got = waitpid $i_child_pid, WNOHANG;
 348     return undef if $got <= 0;
 349     die unless $got == $i_child_pid;
 350     $i_child_pid = undef;
 351     return undef unless $?;
 352     return "build host child ".waitstatusmsg();
 353 }
 354
 355 sub badproto ($$) {
 356     my ($fh, $m) = @_;
 357     fail "connection lost: $!" if $fh->error;
 358     fail "protocol violation; $m not expected";
 359 }
 360
 361 sub badproto_badread ($$) {
 362     my ($fh, $wh) = @_;
 363     fail "connection lost: $!" if $!;
 364     my $report = i_child_report();
 365     fail $report if defined $report;
 366     badproto $fh, "eof (reading $wh)";
 367 }
 368
 369 sub protocol_expect (&$) {
 370     my ($match, $fh) = @_;
 371     local $_;
 372     $_ = <$fh>;
 373     defined && chomp or badproto_badread $fh, "protocol message";
 374     if (wantarray) {
 375         my @r = &$match;
 376         return @r if @r;
 377     } else {
 378         my $r = &$match;
 379         return $r if $r;
 380     }
 381     badproto $fh, "\`$_'";
 382 }
 383
 384 sub protocol_send_file ($$) {
 385     my ($fh, $ourfn) = @_;
 386     open PF, "<", $ourfn or die "$ourfn: $!";
 387     for (;;) {
 388         my $d;
 389         my $got = read PF, $d, 65536;
 390         die "$ourfn: $!" unless defined $got;
 391         last if !$got;
 392         print $fh "data-block ".length($d)."\n" or die $!;
 393         print $fh $d or die $!;
 394     }
 395     PF->error and die "$ourfn $!";
 396     print $fh "data-end\n" or die $!;
 397     close PF;
 398 }
 399
 400 sub protocol_read_bytes ($$) {
 401     my ($fh, $nbytes) = @_;
 402     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 403     my $d;
 404     my $got = read $fh, $d, $nbytes;
 405     $got==$nbytes or badproto_badread $fh, "data block";
 406     return $d;
 407 }
 408
 409 sub protocol_receive_file ($$) {
 410     my ($fh, $ourfn) = @_;
 411     printdebug "() $ourfn\n";
 412     open PF, ">", $ourfn or die "$ourfn: $!";
 413     for (;;) {
 414         my ($y,$l) = protocol_expect {
 415             m/^data-block (.*)$/ ? (1,$1) :
 416             m/^data-end$/ ? (0,) :
 417             ();
 418         } $fh;
 419         last unless $y;
 420         my $d = protocol_read_bytes $fh, $l;
 421         print PF $d or die $!;
 422     }
 423     close PF or die $!;
 424 }
 425
 426 #---------- remote protocol support, responder ----------
 427
 428 sub responder_send_command ($) {
 429     my ($command) = @_;
 430     return unless $we_are_responder;
 431     # called even without $we_are_responder
 432     printdebug ">> $command\n";
 433     print PO $command, "\n" or die $!;
 434 }
 435
 436 sub responder_send_file ($$) {
 437     my ($keyword, $ourfn) = @_;
 438     return unless $we_are_responder;
 439     printdebug "]] $keyword $ourfn\n";
 440     responder_send_command "file $keyword";
 441     protocol_send_file \*PO, $ourfn;
 442 }
 443
 444 sub responder_receive_files ($@) {
 445     my ($keyword, @ourfns) = @_;
 446     die unless $we_are_responder;
 447     printdebug "[[ $keyword @ourfns\n";
 448     responder_send_command "want $keyword";
 449     foreach my $fn (@ourfns) {
 450         protocol_receive_file \*PI, $fn;
 451     }
 452     printdebug "[[\$\n";
 453     protocol_expect { m/^files-end$/ } \*PI;
 454 }
 455
 456 #---------- remote protocol support, initiator ----------
 457
 458 sub initiator_expect (&) {
 459     my ($match) = @_;
 460     protocol_expect { &$match } \*RO;
 461 }
 462
 463 #---------- end remote code ----------
 464
 465 sub progress {
 466     if ($we_are_responder) {
 467         my $m = join '', @_;
 468         responder_send_command "progress ".length($m) or die $!;
 469         print PO $m or die $!;
 470     } else {
 471         print @_, "\n";
 472     }
 473 }
 474
 475 our $ua;
 476
 477 sub url_get {
 478     if (!$ua) {
 479         $ua = LWP::UserAgent->new();
 480         $ua->env_proxy;
 481     }
 482     my $what = $_[$#_];
 483     progress "downloading $what...";
 484     my $r = $ua->get(@_) or die $!;
 485     return undef if $r->code == 404;
 486     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 487     return $r->decoded_content(charset => 'none');
 488 }
 489
 490 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 491
 492 sub act_local () { return $dryrun_level <= 1; }
 493 sub act_scary () { return !$dryrun_level; }
 494
 495 sub printdone {
 496     if (!$dryrun_level) {
 497         progress "$us ok: @_";
 498     } else {
 499         progress "would be ok: @_ (but dry run only)";
 500     }
 501 }
 502
 503 sub dryrun_report {
 504     printcmd(\*STDERR,$debugprefix."#",@_);
 505 }
 506
 507 sub runcmd_ordryrun {
 508     if (act_scary()) {
 509         runcmd @_;
 510     } else {
 511         dryrun_report @_;
 512     }
 513 }
 514
 515 sub runcmd_ordryrun_local {
 516     if (act_local()) {
 517         runcmd @_;
 518     } else {
 519         dryrun_report @_;
 520     }
 521 }
 522
 523 sub shell_cmd {
 524     my ($first_shell, @cmd) = @_;
 525     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 526 }
 527
 528 our $helpmsg = <<END;
 529 main usages:
 530   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 531   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 532   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 533   dgit [dgit-opts] sbuild [sbuild-opts]
 534   dgit [dgit-opts] push [dgit-opts] [suite]
 535   dgit [dgit-opts] rpush build-host:build-dir ...
 536 important dgit options:
 537   -k<keyid>           sign tag and package with <keyid> instead of default
 538   --dry-run -n        do not change anything, but go through the motions
 539   --damp-run -L       like --dry-run but make local changes, without signing
 540   --new -N            allow introducing a new package
 541   --debug -D          increase debug level
 542   -c<name>=<value>    set git config option (used directly by dgit too)
 543 END
 544
 545 our $later_warning_msg = <<END;
 546 Perhaps the upload is stuck in incoming.  Using the version from git.
 547 END
 548
 549 sub badusage {
 550     print STDERR "$us: @_\n", $helpmsg or die $!;
 551     exit 8;
 552 }
 553
 554 sub nextarg {
 555     @ARGV or badusage "too few arguments";
 556     return scalar shift @ARGV;
 557 }
 558
 559 sub pre_help () {
 560     not_necessarily_a_tree();
 561 }
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638 our $invoked_in_git_tree = 1;
 639
 640 sub git_slurp_config () {
 641     # This algoritm is a bit subtle, but this is needed so that for
 642     # options which we want to be single-valued, we allow the
 643     # different config sources to override properly.  See #835858.
 644     foreach my $src (@gitcfgsources) {
 645         next if $src eq 'cmdline';
 646         # we do this ourselves since git doesn't handle it
 647
 648         $gitcfgs{$src} = git_slurp_config_src $src;
 649     }
 650 }
 651
 652 sub git_get_config ($) {
 653     my ($c) = @_;
 654     foreach my $src (@gitcfgsources) {
 655         my $l = $gitcfgs{$src}{$c};
 656         confess "internal error ($l $c)" if $l && !ref $l;
 657         printdebug"C $c ".(defined $l ?
 658                            join " ", map { messagequote "'$_'" } @$l :
 659                            "undef")."\n"
 660             if $debuglevel >= 4;
 661         $l or next;
 662         @$l==1 or badcfg "multiple values for $c".
 663             " (in $src git config)" if @$l > 1;
 664         return $l->[0];
 665     }
 666     return undef;
 667 }
 668
 669 sub cfg {
 670     foreach my $c (@_) {
 671         return undef if $c =~ /RETURN-UNDEF/;
 672         printdebug "C? $c\n" if $debuglevel >= 5;
 673         my $v = git_get_config($c);
 674         return $v if defined $v;
 675         my $dv = $defcfg{$c};
 676         if (defined $dv) {
 677             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 678             return $dv;
 679         }
 680     }
 681     badcfg "need value for one of: @_\n".
 682         "$us: distro or suite appears not to be (properly) supported";
 683 }
 684
 685 sub not_necessarily_a_tree () {
 686     # needs to be called from pre_*
 687     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 688     $invoked_in_git_tree = 0;
 689 }
 690
 691 sub access_basedistro__noalias () {
 692     if (defined $idistro) {
 693         return $idistro;
 694     } else {
 695         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 696         return $def if defined $def;
 697         foreach my $src (@gitcfgsources, 'internal') {
 698             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 699             next unless $kl;
 700             foreach my $k (keys %$kl) {
 701                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 702                 my $dpat = $1;
 703                 next unless match_glob $dpat, $isuite;
 704                 return $kl->{$k};
 705             }
 706         }
 707         return cfg("dgit.default.distro");
 708     }
 709 }
 710
 711 sub access_basedistro () {
 712     my $noalias = access_basedistro__noalias();
 713     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 714     return $canon // $noalias;
 715 }
 716
 717 sub access_nomdistro () {
 718     my $base = access_basedistro();
 719     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 720     $r =~ m/^$distro_re$/ or badcfg
 721  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 722     return $r;
 723 }
 724
 725 sub access_quirk () {
 726     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 727     my $basedistro = access_basedistro();
 728     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 729                               'RETURN-UNDEF');
 730     if (defined $backports_quirk) {
 731         my $re = $backports_quirk;
 732         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 733         $re =~ s/\*/.*/g;
 734         $re =~ s/\%/([-0-9a-z_]+)/
 735             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 736         if ($isuite =~ m/^$re$/) {
 737             return ('backports',"$basedistro-backports",$1);
 738         }
 739     }
 740     return ('none',undef);
 741 }
 742
 743 our $access_forpush;
 744
 745 sub parse_cfg_bool ($$$) {
 746     my ($what,$def,$v) = @_;
 747     $v //= $def;
 748     return
 749         $v =~ m/^[ty1]/ ? 1 :
 750         $v =~ m/^[fn0]/ ? 0 :
 751         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 752 }
 753
 754 sub access_forpush_config () {
 755     my $d = access_basedistro();
 756
 757     return 1 if
 758         $new_package &&
 759         parse_cfg_bool('new-private-pushers', 0,
 760                        cfg("dgit-distro.$d.new-private-pushers",
 761                            'RETURN-UNDEF'));
 762
 763     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 764     $v //= 'a';
 765     return
 766         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 767         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 768         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 769         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 770 }
 771
 772 sub access_forpush () {
 773     $access_forpush //= access_forpush_config();
 774     return $access_forpush;
 775 }
 776
 777 sub pushing () {
 778     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 779     badcfg "pushing but distro is configured readonly"
 780         if access_forpush_config() eq '0';
 781     $access_forpush = 1;
 782     $supplementary_message = <<'END' unless $we_are_responder;
 783 Push failed, before we got started.
 784 You can retry the push, after fixing the problem, if you like.
 785 END
 786     parseopts_late_defaults();
 787 }
 788
 789 sub notpushing () {
 790     parseopts_late_defaults();
 791 }
 792
 793 sub supplementary_message ($) {
 794     my ($msg) = @_;
 795     if (!$we_are_responder) {
 796         $supplementary_message = $msg;
 797         return;
 798     } elsif ($protovsn >= 3) {
 799         responder_send_command "supplementary-message ".length($msg)
 800             or die $!;
 801         print PO $msg or die $!;
 802     }
 803 }
 804
 805 sub access_distros () {
 806     # Returns list of distros to try, in order
 807     #
 808     # We want to try:
 809     #    0. `instead of' distro name(s) we have been pointed to
 810     #    1. the access_quirk distro, if any
 811     #    2a. the user's specified distro, or failing that  } basedistro
 812     #    2b. the distro calculated from the suite          }
 813     my @l = access_basedistro();
 814
 815     my (undef,$quirkdistro) = access_quirk();
 816     unshift @l, $quirkdistro;
 817     unshift @l, $instead_distro;
 818     @l = grep { defined } @l;
 819
 820     push @l, access_nomdistro();
 821
 822     if (access_forpush()) {
 823         @l = map { ("$_/push", $_) } @l;
 824     }
 825     @l;
 826 }
 827
 828 sub access_cfg_cfgs (@) {
 829     my (@keys) = @_;
 830     my @cfgs;
 831     # The nesting of these loops determines the search order.  We put
 832     # the key loop on the outside so that we search all the distros
 833     # for each key, before going on to the next key.  That means that
 834     # if access_cfg is called with a more specific, and then a less
 835     # specific, key, an earlier distro can override the less specific
 836     # without necessarily overriding any more specific keys.  (If the
 837     # distro wants to override the more specific keys it can simply do
 838     # so; whereas if we did the loop the other way around, it would be
 839     # impossible to for an earlier distro to override a less specific
 840     # key but not the more specific ones without restating the unknown
 841     # values of the more specific keys.
 842     my @realkeys;
 843     my @rundef;
 844     # We have to deal with RETURN-UNDEF specially, so that we don't
 845     # terminate the search prematurely.
 846     foreach (@keys) {
 847         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 848         push @realkeys, $_
 849     }
 850     foreach my $d (access_distros()) {
 851         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 852     }
 853     push @cfgs, map { "dgit.default.$_" } @realkeys;
 854     push @cfgs, @rundef;
 855     return @cfgs;
 856 }
 857
 858 sub access_cfg (@) {
 859     my (@keys) = @_;
 860     my (@cfgs) = access_cfg_cfgs(@keys);
 861     my $value = cfg(@cfgs);
 862     return $value;
 863 }
 864
 865 sub access_cfg_bool ($$) {
 866     my ($def, @keys) = @_;
 867     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 868 }
 869
 870 sub string_to_ssh ($) {
 871     my ($spec) = @_;
 872     if ($spec =~ m/\s/) {
 873         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 874     } else {
 875         return ($spec);
 876     }
 877 }
 878
 879 sub access_cfg_ssh () {
 880     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 881     if (!defined $gitssh) {
 882         return @ssh;
 883     } else {
 884         return string_to_ssh $gitssh;
 885     }
 886 }
 887
 888 sub access_runeinfo ($) {
 889     my ($info) = @_;
 890     return ": dgit ".access_basedistro()." $info ;";
 891 }
 892
 893 sub access_someuserhost ($) {
 894     my ($some) = @_;
 895     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 896     defined($user) && length($user) or
 897         $user = access_cfg("$some-user",'username');
 898     my $host = access_cfg("$some-host");
 899     return length($user) ? "$user\@$host" : $host;
 900 }
 901
 902 sub access_gituserhost () {
 903     return access_someuserhost('git');
 904 }
 905
 906 sub access_giturl (;$) {
 907     my ($optional) = @_;
 908     my $url = access_cfg('git-url','RETURN-UNDEF');
 909     my $suffix;
 910     if (!length $url) {
 911         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 912         return undef unless defined $proto;
 913         $url =
 914             $proto.
 915             access_gituserhost().
 916             access_cfg('git-path');
 917     } else {
 918         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 919     }
 920     $suffix //= '.git';
 921     return "$url/$package$suffix";
 922 }
 923
 924 sub parsecontrolfh ($$;$) {
 925     my ($fh, $desc, $allowsigned) = @_;
 926     our $dpkgcontrolhash_noissigned;
 927     my $c;
 928     for (;;) {
 929         my %opts = ('name' => $desc);
 930         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 931         $c = Dpkg::Control::Hash->new(%opts);
 932         $c->parse($fh,$desc) or die "parsing of $desc failed";
 933         last if $allowsigned;
 934         last if $dpkgcontrolhash_noissigned;
 935         my $issigned= $c->get_option('is_pgp_signed');
 936         if (!defined $issigned) {
 937             $dpkgcontrolhash_noissigned= 1;
 938             seek $fh, 0,0 or die "seek $desc: $!";
 939         } elsif ($issigned) {
 940             fail "control file $desc is (already) PGP-signed. ".
 941                 " Note that dgit push needs to modify the .dsc and then".
 942                 " do the signature itself";
 943         } else {
 944             last;
 945         }
 946     }
 947     return $c;
 948 }
 949
 950 sub parsecontrol {
 951     my ($file, $desc, $allowsigned) = @_;
 952     my $fh = new IO::Handle;
 953     open $fh, '<', $file or die "$file: $!";
 954     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 955     $fh->error and die $!;
 956     close $fh;
 957     return $c;
 958 }
 959
 960 sub getfield ($$) {
 961     my ($dctrl,$field) = @_;
 962     my $v = $dctrl->{$field};
 963     return $v if defined $v;
 964     fail "missing field $field in ".$dctrl->get_option('name');
 965 }
 966
 967 sub parsechangelog {
 968     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 969     my $p = new IO::Handle;
 970     my @cmd = (qw(dpkg-parsechangelog), @_);
 971     open $p, '-|', @cmd or die $!;
 972     $c->parse($p);
 973     $?=0; $!=0; close $p or failedcmd @cmd;
 974     return $c;
 975 }
 976
 977 sub commit_getclogp ($) {
 978     # Returns the parsed changelog hashref for a particular commit
 979     my ($objid) = @_;
 980     our %commit_getclogp_memo;
 981     my $memo = $commit_getclogp_memo{$objid};
 982     return $memo if $memo;
 983     mkpath '.git/dgit';
 984     my $mclog = ".git/dgit/clog-$objid";
 985     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 986         "$objid:debian/changelog";
 987     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 988 }
 989
 990 sub parse_dscdata () {
 991     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 992     printdebug Dumper($dscdata) if $debuglevel>1;
 993     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 994     printdebug Dumper($dsc) if $debuglevel>1;
 995 }
 996
 997 our %rmad;
 998
 999 sub archive_query ($;@) {
1000     my ($method) = shift @_;
1001     fail "this operation does not support multiple comma-separated suites"
1002         if $isuite =~ m/,/;
1003     my $query = access_cfg('archive-query','RETURN-UNDEF');
1004     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1005     my $proto = $1;
1006     my $data = $'; #';
1007     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1008 }
1009
1010 sub archive_query_prepend_mirror {
1011     my $m = access_cfg('mirror');
1012     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1013 }
1014
1015 sub pool_dsc_subpath ($$) {
1016     my ($vsn,$component) = @_; # $package is implict arg
1017     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1018     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1019 }
1020
1021 sub cfg_apply_map ($$$) {
1022     my ($varref, $what, $mapspec) = @_;
1023     return unless $mapspec;
1024
1025     printdebug "config $what EVAL{ $mapspec; }\n";
1026     $_ = $$varref;
1027     eval "package Dgit::Config; $mapspec;";
1028     die $@ if $@;
1029     $$varref = $_;
1030 }
1031
1032 #---------- `ftpmasterapi' archive query method (nascent) ----------
1033
1034 sub archive_api_query_cmd ($) {
1035     my ($subpath) = @_;
1036     my @cmd = (@curl, qw(-sS));
1037     my $url = access_cfg('archive-query-url');
1038     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1039         my $host = $1;
1040         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1041         foreach my $key (split /\:/, $keys) {
1042             $key =~ s/\%HOST\%/$host/g;
1043             if (!stat $key) {
1044                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1045                 next;
1046             }
1047             fail "config requested specific TLS key but do not know".
1048                 " how to get curl to use exactly that EE key ($key)";
1049 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1050 #           # Sadly the above line does not work because of changes
1051 #           # to gnutls.   The real fix for #790093 may involve
1052 #           # new curl options.
1053             last;
1054         }
1055         # Fixing #790093 properly will involve providing a value
1056         # for this on clients.
1057         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1058         push @cmd, split / /, $kargs if defined $kargs;
1059     }
1060     push @cmd, $url.$subpath;
1061     return @cmd;
1062 }
1063
1064 sub api_query ($$;$) {
1065     use JSON;
1066     my ($data, $subpath, $ok404) = @_;
1067     badcfg "ftpmasterapi archive query method takes no data part"
1068         if length $data;
1069     my @cmd = archive_api_query_cmd($subpath);
1070     my $url = $cmd[$#cmd];
1071     push @cmd, qw(-w %{http_code});
1072     my $json = cmdoutput @cmd;
1073     unless ($json =~ s/\d+\d+\d$//) {
1074         failedcmd_report_cmd undef, @cmd;
1075         fail "curl failed to print 3-digit HTTP code";
1076     }
1077     my $code = $&;
1078     return undef if $code eq '404' && $ok404;
1079     fail "fetch of $url gave HTTP code $code"
1080         unless $url =~ m#^file://# or $code =~ m/^2/;
1081     return decode_json($json);
1082 }
1083
1084 sub canonicalise_suite_ftpmasterapi {
1085     my ($proto,$data) = @_;
1086     my $suites = api_query($data, 'suites');
1087     my @matched;
1088     foreach my $entry (@$suites) {
1089         next unless grep {
1090             my $v = $entry->{$_};
1091             defined $v && $v eq $isuite;
1092         } qw(codename name);
1093         push @matched, $entry;
1094     }
1095     fail "unknown suite $isuite" unless @matched;
1096     my $cn;
1097     eval {
1098         @matched==1 or die "multiple matches for suite $isuite\n";
1099         $cn = "$matched[0]{codename}";
1100         defined $cn or die "suite $isuite info has no codename\n";
1101         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1102     };
1103     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1104         if length $@;
1105     return $cn;
1106 }
1107
1108 sub archive_query_ftpmasterapi {
1109     my ($proto,$data) = @_;
1110     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1111     my @rows;
1112     my $digester = Digest::SHA->new(256);
1113     foreach my $entry (@$info) {
1114         eval {
1115             my $vsn = "$entry->{version}";
1116             my ($ok,$msg) = version_check $vsn;
1117             die "bad version: $msg\n" unless $ok;
1118             my $component = "$entry->{component}";
1119             $component =~ m/^$component_re$/ or die "bad component";
1120             my $filename = "$entry->{filename}";
1121             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1122                 or die "bad filename";
1123             my $sha256sum = "$entry->{sha256sum}";
1124             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1125             push @rows, [ $vsn, "/pool/$component/$filename",
1126                           $digester, $sha256sum ];
1127         };
1128         die "bad ftpmaster api response: $@\n".Dumper($entry)
1129             if length $@;
1130     }
1131     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1132     return archive_query_prepend_mirror @rows;
1133 }
1134
1135 sub file_in_archive_ftpmasterapi {
1136     my ($proto,$data,$filename) = @_;
1137     my $pat = $filename;
1138     $pat =~ s/_/\\_/g;
1139     $pat = "%/$pat";
1140     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1141     my $info = api_query($data, "file_in_archive/$pat", 1);
1142 }
1143
1144 #---------- `aptget' archive query method ----------
1145
1146 our $aptget_base;
1147 our $aptget_releasefile;
1148 our $aptget_configpath;
1149
1150 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1151 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1152
1153 sub aptget_cache_clean {
1154     runcmd_ordryrun_local qw(sh -ec),
1155         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1156         'x', $aptget_base;
1157 }
1158
1159 sub aptget_lock_acquire () {
1160     my $lockfile = "$aptget_base/lock";
1161     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1162     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1163 }
1164
1165 sub aptget_prep ($) {
1166     my ($data) = @_;
1167     return if defined $aptget_base;
1168
1169     badcfg "aptget archive query method takes no data part"
1170         if length $data;
1171
1172     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1173
1174     ensuredir $cache;
1175     ensuredir "$cache/dgit";
1176     my $cachekey =
1177         access_cfg('aptget-cachekey','RETURN-UNDEF')
1178         // access_nomdistro();
1179
1180     $aptget_base = "$cache/dgit/aptget";
1181     ensuredir $aptget_base;
1182
1183     my $quoted_base = $aptget_base;
1184     die "$quoted_base contains bad chars, cannot continue"
1185         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1186
1187     ensuredir $aptget_base;
1188
1189     aptget_lock_acquire();
1190
1191     aptget_cache_clean();
1192
1193     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1194     my $sourceslist = "source.list#$cachekey";
1195
1196     my $aptsuites = $isuite;
1197     cfg_apply_map(\$aptsuites, 'suite map',
1198                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1199
1200     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1201     printf SRCS "deb-src %s %s %s\n",
1202         access_cfg('mirror'),
1203         $aptsuites,
1204         access_cfg('aptget-components')
1205         or die $!;
1206
1207     ensuredir "$aptget_base/cache";
1208     ensuredir "$aptget_base/lists";
1209
1210     open CONF, ">", $aptget_configpath or die $!;
1211     print CONF <<END;
1212 Debug::NoLocking "true";
1213 APT::Get::List-Cleanup "false";
1214 #clear APT::Update::Post-Invoke-Success;
1215 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1216 Dir::State::Lists "$quoted_base/lists";
1217 Dir::Etc::preferences "$quoted_base/preferences";
1218 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1219 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1220 END
1221
1222     foreach my $key (qw(
1223                         Dir::Cache
1224                         Dir::State
1225                         Dir::Cache::Archives
1226                         Dir::Etc::SourceParts
1227                         Dir::Etc::preferencesparts
1228                       )) {
1229         ensuredir "$aptget_base/$key";
1230         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1231     };
1232
1233     my $oldatime = (time // die $!) - 1;
1234     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1235         next unless stat_exists $oldlist;
1236         my ($mtime) = (stat _)[9];
1237         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1238     }
1239
1240     runcmd_ordryrun_local aptget_aptget(), qw(update);
1241
1242     my @releasefiles;
1243     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1244         next unless stat_exists $oldlist;
1245         my ($atime) = (stat _)[8];
1246         next if $atime == $oldatime;
1247         push @releasefiles, $oldlist;
1248     }
1249     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1250     @releasefiles = @inreleasefiles if @inreleasefiles;
1251     die "apt updated wrong number of Release files (@releasefiles), erk"
1252         unless @releasefiles == 1;
1253
1254     ($aptget_releasefile) = @releasefiles;
1255 }
1256
1257 sub canonicalise_suite_aptget {
1258     my ($proto,$data) = @_;
1259     aptget_prep($data);
1260
1261     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1262
1263     foreach my $name (qw(Codename Suite)) {
1264         my $val = $release->{$name};
1265         if (defined $val) {
1266             printdebug "release file $name: $val\n";
1267             $val =~ m/^$suite_re$/o or fail
1268  "Release file ($aptget_releasefile) specifies intolerable $name";
1269             cfg_apply_map(\$val, 'suite rmap',
1270                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1271             return $val
1272         }
1273     }
1274     return $isuite;
1275 }
1276
1277 sub archive_query_aptget {
1278     my ($proto,$data) = @_;
1279     aptget_prep($data);
1280
1281     ensuredir "$aptget_base/source";
1282     foreach my $old (<$aptget_base/source/*.dsc>) {
1283         unlink $old or die "$old: $!";
1284     }
1285
1286     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1287     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1288     # avoids apt-get source failing with ambiguous error code
1289
1290     runcmd_ordryrun_local
1291         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1292         aptget_aptget(), qw(--download-only --only-source source), $package;
1293
1294     my @dscs = <$aptget_base/source/*.dsc>;
1295     fail "apt-get source did not produce a .dsc" unless @dscs;
1296     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1297
1298     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1299
1300     use URI::Escape;
1301     my $uri = "file://". uri_escape $dscs[0];
1302     $uri =~ s{\%2f}{/}gi;
1303     return [ (getfield $pre_dsc, 'Version'), $uri ];
1304 }
1305
1306 sub file_in_archive_aptget () { return undef; }
1307
1308 #---------- `dummyapicat' archive query method ----------
1309
1310 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1311 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1312
1313 sub file_in_archive_dummycatapi ($$$) {
1314     my ($proto,$data,$filename) = @_;
1315     my $mirror = access_cfg('mirror');
1316     $mirror =~ s#^file://#/# or die "$mirror ?";
1317     my @out;
1318     my @cmd = (qw(sh -ec), '
1319             cd "$1"
1320             find -name "$2" -print0 |
1321             xargs -0r sha256sum
1322         ', qw(x), $mirror, $filename);
1323     debugcmd "-|", @cmd;
1324     open FIA, "-|", @cmd or die $!;
1325     while (<FIA>) {
1326         chomp or die;
1327         printdebug "| $_\n";
1328         m/^(\w+)  (\S+)$/ or die "$_ ?";
1329         push @out, { sha256sum => $1, filename => $2 };
1330     }
1331     close FIA or die failedcmd @cmd;
1332     return \@out;
1333 }
1334
1335 #---------- `madison' archive query method ----------
1336
1337 sub archive_query_madison {
1338     return archive_query_prepend_mirror
1339         map { [ @$_[0..1] ] } madison_get_parse(@_);
1340 }
1341
1342 sub madison_get_parse {
1343     my ($proto,$data) = @_;
1344     die unless $proto eq 'madison';
1345     if (!length $data) {
1346         $data= access_cfg('madison-distro','RETURN-UNDEF');
1347         $data //= access_basedistro();
1348     }
1349     $rmad{$proto,$data,$package} ||= cmdoutput
1350         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1351     my $rmad = $rmad{$proto,$data,$package};
1352
1353     my @out;
1354     foreach my $l (split /\n/, $rmad) {
1355         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1356                   \s*( [^ \t|]+ )\s* \|
1357                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1358                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1359         $1 eq $package or die "$rmad $package ?";
1360         my $vsn = $2;
1361         my $newsuite = $3;
1362         my $component;
1363         if (defined $4) {
1364             $component = $4;
1365         } else {
1366             $component = access_cfg('archive-query-default-component');
1367         }
1368         $5 eq 'source' or die "$rmad ?";
1369         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1370     }
1371     return sort { -version_compare($a->[0],$b->[0]); } @out;
1372 }
1373
1374 sub canonicalise_suite_madison {
1375     # madison canonicalises for us
1376     my @r = madison_get_parse(@_);
1377     @r or fail
1378         "unable to canonicalise suite using package $package".
1379         " which does not appear to exist in suite $isuite;".
1380         " --existing-package may help";
1381     return $r[0][2];
1382 }
1383
1384 sub file_in_archive_madison { return undef; }
1385
1386 #---------- `sshpsql' archive query method ----------
1387
1388 sub sshpsql ($$$) {
1389     my ($data,$runeinfo,$sql) = @_;
1390     if (!length $data) {
1391         $data= access_someuserhost('sshpsql').':'.
1392             access_cfg('sshpsql-dbname');
1393     }
1394     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1395     my ($userhost,$dbname) = ($`,$'); #';
1396     my @rows;
1397     my @cmd = (access_cfg_ssh, $userhost,
1398                access_runeinfo("ssh-psql $runeinfo").
1399                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1400                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1401     debugcmd "|",@cmd;
1402     open P, "-|", @cmd or die $!;
1403     while (<P>) {
1404         chomp or die;
1405         printdebug(">|$_|\n");
1406         push @rows, $_;
1407     }
1408     $!=0; $?=0; close P or failedcmd @cmd;
1409     @rows or die;
1410     my $nrows = pop @rows;
1411     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1412     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1413     @rows = map { [ split /\|/, $_ ] } @rows;
1414     my $ncols = scalar @{ shift @rows };
1415     die if grep { scalar @$_ != $ncols } @rows;
1416     return @rows;
1417 }
1418
1419 sub sql_injection_check {
1420     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1421 }
1422
1423 sub archive_query_sshpsql ($$) {
1424     my ($proto,$data) = @_;
1425     sql_injection_check $isuite, $package;
1426     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1427         SELECT source.version, component.name, files.filename, files.sha256sum
1428           FROM source
1429           JOIN src_associations ON source.id = src_associations.source
1430           JOIN suite ON suite.id = src_associations.suite
1431           JOIN dsc_files ON dsc_files.source = source.id
1432           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1433           JOIN component ON component.id = files_archive_map.component_id
1434           JOIN files ON files.id = dsc_files.file
1435          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1436            AND source.source='$package'
1437            AND files.filename LIKE '%.dsc';
1438 END
1439     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1440     my $digester = Digest::SHA->new(256);
1441     @rows = map {
1442         my ($vsn,$component,$filename,$sha256sum) = @$_;
1443         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1444     } @rows;
1445     return archive_query_prepend_mirror @rows;
1446 }
1447
1448 sub canonicalise_suite_sshpsql ($$) {
1449     my ($proto,$data) = @_;
1450     sql_injection_check $isuite;
1451     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1452         SELECT suite.codename
1453           FROM suite where suite_name='$isuite' or codename='$isuite';
1454 END
1455     @rows = map { $_->[0] } @rows;
1456     fail "unknown suite $isuite" unless @rows;
1457     die "ambiguous $isuite: @rows ?" if @rows>1;
1458     return $rows[0];
1459 }
1460
1461 sub file_in_archive_sshpsql ($$$) { return undef; }
1462
1463 #---------- `dummycat' archive query method ----------
1464
1465 sub canonicalise_suite_dummycat ($$) {
1466     my ($proto,$data) = @_;
1467     my $dpath = "$data/suite.$isuite";
1468     if (!open C, "<", $dpath) {
1469         $!==ENOENT or die "$dpath: $!";
1470         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1471         return $isuite;
1472     }
1473     $!=0; $_ = <C>;
1474     chomp or die "$dpath: $!";
1475     close C;
1476     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1477     return $_;
1478 }
1479
1480 sub archive_query_dummycat ($$) {
1481     my ($proto,$data) = @_;
1482     canonicalise_suite();
1483     my $dpath = "$data/package.$csuite.$package";
1484     if (!open C, "<", $dpath) {
1485         $!==ENOENT or die "$dpath: $!";
1486         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1487         return ();
1488     }
1489     my @rows;
1490     while (<C>) {
1491         next if m/^\#/;
1492         next unless m/\S/;
1493         die unless chomp;
1494         printdebug "dummycat query $csuite $package $dpath | $_\n";
1495         my @row = split /\s+/, $_;
1496         @row==2 or die "$dpath: $_ ?";
1497         push @rows, \@row;
1498     }
1499     C->error and die "$dpath: $!";
1500     close C;
1501     return archive_query_prepend_mirror
1502         sort { -version_compare($a->[0],$b->[0]); } @rows;
1503 }
1504
1505 sub file_in_archive_dummycat () { return undef; }
1506
1507 #---------- tag format handling ----------
1508
1509 sub access_cfg_tagformats () {
1510     split /\,/, access_cfg('dgit-tag-format');
1511 }
1512
1513 sub access_cfg_tagformats_can_splitbrain () {
1514     my %y = map { $_ => 1 } access_cfg_tagformats;
1515     foreach my $needtf (qw(new maint)) {
1516         next if $y{$needtf};
1517         return 0;
1518     }
1519     return 1;
1520 }
1521
1522 sub need_tagformat ($$) {
1523     my ($fmt, $why) = @_;
1524     fail "need to use tag format $fmt ($why) but also need".
1525         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1526         " - no way to proceed"
1527         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1528     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1529 }
1530
1531 sub select_tagformat () {
1532     # sets $tagformatfn
1533     return if $tagformatfn && !$tagformat_want;
1534     die 'bug' if $tagformatfn && $tagformat_want;
1535     # ... $tagformat_want assigned after previous select_tagformat
1536
1537     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1538     printdebug "select_tagformat supported @supported\n";
1539
1540     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1541     printdebug "select_tagformat specified @$tagformat_want\n";
1542
1543     my ($fmt,$why,$override) = @$tagformat_want;
1544
1545     fail "target distro supports tag formats @supported".
1546         " but have to use $fmt ($why)"
1547         unless $override
1548             or grep { $_ eq $fmt } @supported;
1549
1550     $tagformat_want = undef;
1551     $tagformat = $fmt;
1552     $tagformatfn = ${*::}{"debiantag_$fmt"};
1553
1554     fail "trying to use unknown tag format \`$fmt' ($why) !"
1555         unless $tagformatfn;
1556 }
1557
1558 #---------- archive query entrypoints and rest of program ----------
1559
1560 sub canonicalise_suite () {
1561     return if defined $csuite;
1562     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1563     $csuite = archive_query('canonicalise_suite');
1564     if ($isuite ne $csuite) {
1565         progress "canonical suite name for $isuite is $csuite";
1566     } else {
1567         progress "canonical suite name is $csuite";
1568     }
1569 }
1570
1571 sub get_archive_dsc () {
1572     canonicalise_suite();
1573     my @vsns = archive_query('archive_query');
1574     foreach my $vinfo (@vsns) {
1575         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1576         $dscurl = $vsn_dscurl;
1577         $dscdata = url_get($dscurl);
1578         if (!$dscdata) {
1579             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1580             next;
1581         }
1582         if ($digester) {
1583             $digester->reset();
1584             $digester->add($dscdata);
1585             my $got = $digester->hexdigest();
1586             $got eq $digest or
1587                 fail "$dscurl has hash $got but".
1588                     " archive told us to expect $digest";
1589         }
1590         parse_dscdata();
1591         my $fmt = getfield $dsc, 'Format';
1592         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1593             "unsupported source format $fmt, sorry";
1594
1595         $dsc_checked = !!$digester;
1596         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1597         return;
1598     }
1599     $dsc = undef;
1600     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1601 }
1602
1603 sub check_for_git ();
1604 sub check_for_git () {
1605     # returns 0 or 1
1606     my $how = access_cfg('git-check');
1607     if ($how eq 'ssh-cmd') {
1608         my @cmd =
1609             (access_cfg_ssh, access_gituserhost(),
1610              access_runeinfo("git-check $package").
1611              " set -e; cd ".access_cfg('git-path').";".
1612              " if test -d $package.git; then echo 1; else echo 0; fi");
1613         my $r= cmdoutput @cmd;
1614         if (defined $r and $r =~ m/^divert (\w+)$/) {
1615             my $divert=$1;
1616             my ($usedistro,) = access_distros();
1617             # NB that if we are pushing, $usedistro will be $distro/push
1618             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1619             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1620             progress "diverting to $divert (using config for $instead_distro)";
1621             return check_for_git();
1622         }
1623         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1624         return $r+0;
1625     } elsif ($how eq 'url') {
1626         my $prefix = access_cfg('git-check-url','git-url');
1627         my $suffix = access_cfg('git-check-suffix','git-suffix',
1628                                 'RETURN-UNDEF') // '.git';
1629         my $url = "$prefix/$package$suffix";
1630         my @cmd = (@curl, qw(-sS -I), $url);
1631         my $result = cmdoutput @cmd;
1632         $result =~ s/^\S+ 200 .*\n\r?\n//;
1633         # curl -sS -I with https_proxy prints
1634         # HTTP/1.0 200 Connection established
1635         $result =~ m/^\S+ (404|200) /s or
1636             fail "unexpected results from git check query - ".
1637                 Dumper($prefix, $result);
1638         my $code = $1;
1639         if ($code eq '404') {
1640             return 0;
1641         } elsif ($code eq '200') {
1642             return 1;
1643         } else {
1644             die;
1645         }
1646     } elsif ($how eq 'true') {
1647         return 1;
1648     } elsif ($how eq 'false') {
1649         return 0;
1650     } else {
1651         badcfg "unknown git-check \`$how'";
1652     }
1653 }
1654
1655 sub create_remote_git_repo () {
1656     my $how = access_cfg('git-create');
1657     if ($how eq 'ssh-cmd') {
1658         runcmd_ordryrun
1659             (access_cfg_ssh, access_gituserhost(),
1660              access_runeinfo("git-create $package").
1661              "set -e; cd ".access_cfg('git-path').";".
1662              " cp -a _template $package.git");
1663     } elsif ($how eq 'true') {
1664         # nothing to do
1665     } else {
1666         badcfg "unknown git-create \`$how'";
1667     }
1668 }
1669
1670 our ($dsc_hash,$lastpush_mergeinput);
1671 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1672
1673
1674 sub prep_ud () {
1675     fresh_playground 'dgit/unpack';
1676 }
1677
1678 sub mktree_in_ud_here () {
1679     playtree_setup $gitcfgs{local};
1680 }
1681
1682 sub git_write_tree () {
1683     my $tree = cmdoutput @git, qw(write-tree);
1684     $tree =~ m/^\w+$/ or die "$tree ?";
1685     return $tree;
1686 }
1687
1688 sub git_add_write_tree () {
1689     runcmd @git, qw(add -Af .);
1690     return git_write_tree();
1691 }
1692
1693 sub remove_stray_gits ($) {
1694     my ($what) = @_;
1695     my @gitscmd = qw(find -name .git -prune -print0);
1696     debugcmd "|",@gitscmd;
1697     open GITS, "-|", @gitscmd or die $!;
1698     {
1699         local $/="\0";
1700         while (<GITS>) {
1701             chomp or die;
1702             print STDERR "$us: warning: removing from $what: ",
1703                 (messagequote $_), "\n";
1704             rmtree $_;
1705         }
1706     }
1707     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1708 }
1709
1710 sub mktree_in_ud_from_only_subdir ($;$) {
1711     my ($what,$raw) = @_;
1712
1713     # changes into the subdir
1714     my (@dirs) = <*/.>;
1715     die "expected one subdir but found @dirs ?" unless @dirs==1;
1716     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1717     my $dir = $1;
1718     changedir $dir;
1719
1720     remove_stray_gits($what);
1721     mktree_in_ud_here();
1722     if (!$raw) {
1723         my ($format, $fopts) = get_source_format();
1724         if (madformat($format)) {
1725             rmtree '.pc';
1726         }
1727     }
1728
1729     my $tree=git_add_write_tree();
1730     return ($tree,$dir);
1731 }
1732
1733 our @files_csum_info_fields =
1734     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1735      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1736      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1737
1738 sub dsc_files_info () {
1739     foreach my $csumi (@files_csum_info_fields) {
1740         my ($fname, $module, $method) = @$csumi;
1741         my $field = $dsc->{$fname};
1742         next unless defined $field;
1743         eval "use $module; 1;" or die $@;
1744         my @out;
1745         foreach (split /\n/, $field) {
1746             next unless m/\S/;
1747             m/^(\w+) (\d+) (\S+)$/ or
1748                 fail "could not parse .dsc $fname line \`$_'";
1749             my $digester = eval "$module"."->$method;" or die $@;
1750             push @out, {
1751                 Hash => $1,
1752                 Bytes => $2,
1753                 Filename => $3,
1754                 Digester => $digester,
1755             };
1756         }
1757         return @out;
1758     }
1759     fail "missing any supported Checksums-* or Files field in ".
1760         $dsc->get_option('name');
1761 }
1762
1763 sub dsc_files () {
1764     map { $_->{Filename} } dsc_files_info();
1765 }
1766
1767 sub files_compare_inputs (@) {
1768     my $inputs = \@_;
1769     my %record;
1770     my %fchecked;
1771
1772     my $showinputs = sub {
1773         return join "; ", map { $_->get_option('name') } @$inputs;
1774     };
1775
1776     foreach my $in (@$inputs) {
1777         my $expected_files;
1778         my $in_name = $in->get_option('name');
1779
1780         printdebug "files_compare_inputs $in_name\n";
1781
1782         foreach my $csumi (@files_csum_info_fields) {
1783             my ($fname) = @$csumi;
1784             printdebug "files_compare_inputs $in_name $fname\n";
1785
1786             my $field = $in->{$fname};
1787             next unless defined $field;
1788
1789             my @files;
1790             foreach (split /\n/, $field) {
1791                 next unless m/\S/;
1792
1793                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1794                     fail "could not parse $in_name $fname line \`$_'";
1795
1796                 printdebug "files_compare_inputs $in_name $fname $f\n";
1797
1798                 push @files, $f;
1799
1800                 my $re = \ $record{$f}{$fname};
1801                 if (defined $$re) {
1802                     $fchecked{$f}{$in_name} = 1;
1803                     $$re eq $info or
1804                         fail "hash or size of $f varies in $fname fields".
1805                         " (between: ".$showinputs->().")";
1806                 } else {
1807                     $$re = $info;
1808                 }
1809             }
1810             @files = sort @files;
1811             $expected_files //= \@files;
1812             "@$expected_files" eq "@files" or
1813                 fail "file list in $in_name varies between hash fields!";
1814         }
1815         $expected_files or
1816             fail "$in_name has no files list field(s)";
1817     }
1818     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1819         if $debuglevel>=2;
1820
1821     grep { keys %$_ == @$inputs-1 } values %fchecked
1822         or fail "no file appears in all file lists".
1823         " (looked in: ".$showinputs->().")";
1824 }
1825
1826 sub is_orig_file_in_dsc ($$) {
1827     my ($f, $dsc_files_info) = @_;
1828     return 0 if @$dsc_files_info <= 1;
1829     # One file means no origs, and the filename doesn't have a "what
1830     # part of dsc" component.  (Consider versions ending `.orig'.)
1831     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1832     return 1;
1833 }
1834
1835 sub is_orig_file_of_vsn ($$) {
1836     my ($f, $upstreamvsn) = @_;
1837     my $base = srcfn $upstreamvsn, '';
1838     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1839     return 1;
1840 }
1841
1842 sub changes_update_origs_from_dsc ($$$$) {
1843     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1844     my %changes_f;
1845     printdebug "checking origs needed ($upstreamvsn)...\n";
1846     $_ = getfield $changes, 'Files';
1847     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1848         fail "cannot find section/priority from .changes Files field";
1849     my $placementinfo = $1;
1850     my %changed;
1851     printdebug "checking origs needed placement '$placementinfo'...\n";
1852     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1853         $l =~ m/\S+$/ or next;
1854         my $file = $&;
1855         printdebug "origs $file | $l\n";
1856         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1857         printdebug "origs $file is_orig\n";
1858         my $have = archive_query('file_in_archive', $file);
1859         if (!defined $have) {
1860             print STDERR <<END;
1861 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1862 END
1863             return;
1864         }
1865         my $found_same = 0;
1866         my @found_differ;
1867         printdebug "origs $file \$#\$have=$#$have\n";
1868         foreach my $h (@$have) {
1869             my $same = 0;
1870             my @differ;
1871             foreach my $csumi (@files_csum_info_fields) {
1872                 my ($fname, $module, $method, $archivefield) = @$csumi;
1873                 next unless defined $h->{$archivefield};
1874                 $_ = $dsc->{$fname};
1875                 next unless defined;
1876                 m/^(\w+) .* \Q$file\E$/m or
1877                     fail ".dsc $fname missing entry for $file";
1878                 if ($h->{$archivefield} eq $1) {
1879                     $same++;
1880                 } else {
1881                     push @differ,
1882  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1883                 }
1884             }
1885             die "$file ".Dumper($h)." ?!" if $same && @differ;
1886             $found_same++
1887                 if $same;
1888             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1889                 if @differ;
1890         }
1891         printdebug "origs $file f.same=$found_same".
1892             " #f._differ=$#found_differ\n";
1893         if (@found_differ && !$found_same) {
1894             fail join "\n",
1895                 "archive contains $file with different checksum",
1896                 @found_differ;
1897         }
1898         # Now we edit the changes file to add or remove it
1899         foreach my $csumi (@files_csum_info_fields) {
1900             my ($fname, $module, $method, $archivefield) = @$csumi;
1901             next unless defined $changes->{$fname};
1902             if ($found_same) {
1903                 # in archive, delete from .changes if it's there
1904                 $changed{$file} = "removed" if
1905                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1906             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1907                 # not in archive, but it's here in the .changes
1908             } else {
1909                 my $dsc_data = getfield $dsc, $fname;
1910                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1911                 my $extra = $1;
1912                 $extra =~ s/ \d+ /$&$placementinfo /
1913                     or die "$fname $extra >$dsc_data< ?"
1914                     if $fname eq 'Files';
1915                 $changes->{$fname} .= "\n". $extra;
1916                 $changed{$file} = "added";
1917             }
1918         }
1919     }
1920     if (%changed) {
1921         foreach my $file (keys %changed) {
1922             progress sprintf
1923                 "edited .changes for archive .orig contents: %s %s",
1924                 $changed{$file}, $file;
1925         }
1926         my $chtmp = "$changesfile.tmp";
1927         $changes->save($chtmp);
1928         if (act_local()) {
1929             rename $chtmp,$changesfile or die "$changesfile $!";
1930         } else {
1931             progress "[new .changes left in $changesfile]";
1932         }
1933     } else {
1934         progress "$changesfile already has appropriate .orig(s) (if any)";
1935     }
1936 }
1937
1938 sub make_commit ($) {
1939     my ($file) = @_;
1940     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1941 }
1942
1943 sub make_commit_text ($) {
1944     my ($text) = @_;
1945     my ($out, $in);
1946     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1947     debugcmd "|",@cmd;
1948     print Dumper($text) if $debuglevel > 1;
1949     my $child = open2($out, $in, @cmd) or die $!;
1950     my $h;
1951     eval {
1952         print $in $text or die $!;
1953         close $in or die $!;
1954         $h = <$out>;
1955         $h =~ m/^\w+$/ or die;
1956         $h = $&;
1957         printdebug "=> $h\n";
1958     };
1959     close $out;
1960     waitpid $child, 0 == $child or die "$child $!";
1961     $? and failedcmd @cmd;
1962     return $h;
1963 }
1964
1965 sub clogp_authline ($) {
1966     my ($clogp) = @_;
1967     my $author = getfield $clogp, 'Maintainer';
1968     if ($author =~ m/^[^"\@]+\,/) {
1969         # single entry Maintainer field with unquoted comma
1970         $author = ($& =~ y/,//rd).$'; # strip the comma
1971     }
1972     # git wants a single author; any remaining commas in $author
1973     # are by now preceded by @ (or ").  It seems safer to punt on
1974     # "..." for now rather than attempting to dequote or something.
1975     $author =~ s#,.*##ms unless $author =~ m/"/;
1976     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1977     my $authline = "$author $date";
1978     $authline =~ m/$git_authline_re/o or
1979         fail "unexpected commit author line format \`$authline'".
1980         " (was generated from changelog Maintainer field)";
1981     return ($1,$2,$3) if wantarray;
1982     return $authline;
1983 }
1984
1985 sub vendor_patches_distro ($$) {
1986     my ($checkdistro, $what) = @_;
1987     return unless defined $checkdistro;
1988
1989     my $series = "debian/patches/\L$checkdistro\E.series";
1990     printdebug "checking for vendor-specific $series ($what)\n";
1991
1992     if (!open SERIES, "<", $series) {
1993         die "$series $!" unless $!==ENOENT;
1994         return;
1995     }
1996     while (<SERIES>) {
1997         next unless m/\S/;
1998         next if m/^\s+\#/;
1999
2000         print STDERR <<END;
2001
2002 Unfortunately, this source package uses a feature of dpkg-source where
2003 the same source package unpacks to different source code on different
2004 distros.  dgit cannot safely operate on such packages on affected
2005 distros, because the meaning of source packages is not stable.
2006
2007 Please ask the distro/maintainer to remove the distro-specific series
2008 files and use a different technique (if necessary, uploading actually
2009 different packages, if different distros are supposed to have
2010 different code).
2011
2012 END
2013         fail "Found active distro-specific series file for".
2014             " $checkdistro ($what): $series, cannot continue";
2015     }
2016     die "$series $!" if SERIES->error;
2017     close SERIES;
2018 }
2019
2020 sub check_for_vendor_patches () {
2021     # This dpkg-source feature doesn't seem to be documented anywhere!
2022     # But it can be found in the changelog (reformatted):
2023
2024     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2025     #   Author: Raphael Hertzog <hertzog@debian.org>
2026     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2027
2028     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2029     #   series files
2030     #
2031     #   If you have debian/patches/ubuntu.series and you were
2032     #   unpacking the source package on ubuntu, quilt was still
2033     #   directed to debian/patches/series instead of
2034     #   debian/patches/ubuntu.series.
2035     #
2036     #   debian/changelog                        |    3 +++
2037     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2038     #   2 files changed, 6 insertions(+), 1 deletion(-)
2039
2040     use Dpkg::Vendor;
2041     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2042     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2043                          "Dpkg::Vendor \`current vendor'");
2044     vendor_patches_distro(access_basedistro(),
2045                           "(base) distro being accessed");
2046     vendor_patches_distro(access_nomdistro(),
2047                           "(nominal) distro being accessed");
2048 }
2049
2050 sub generate_commits_from_dsc () {
2051     # See big comment in fetch_from_archive, below.
2052     # See also README.dsc-import.
2053     prep_ud();
2054     changedir $playground;
2055
2056     my @dfi = dsc_files_info();
2057     foreach my $fi (@dfi) {
2058         my $f = $fi->{Filename};
2059         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2060         my $upper_f = "../../../../$f";
2061
2062         printdebug "considering reusing $f: ";
2063
2064         if (link_ltarget "$upper_f,fetch", $f) {
2065             printdebug "linked (using ...,fetch).\n";
2066         } elsif ((printdebug "($!) "),
2067                  $! != ENOENT) {
2068             fail "accessing ../$f,fetch: $!";
2069         } elsif (link_ltarget $upper_f, $f) {
2070             printdebug "linked.\n";
2071         } elsif ((printdebug "($!) "),
2072                  $! != ENOENT) {
2073             fail "accessing ../$f: $!";
2074         } else {
2075             printdebug "absent.\n";
2076         }
2077
2078         my $refetched;
2079         complete_file_from_dsc('.', $fi, \$refetched)
2080             or next;
2081
2082         printdebug "considering saving $f: ";
2083
2084         if (link $f, $upper_f) {
2085             printdebug "linked.\n";
2086         } elsif ((printdebug "($!) "),
2087                  $! != EEXIST) {
2088             fail "saving ../$f: $!";
2089         } elsif (!$refetched) {
2090             printdebug "no need.\n";
2091         } elsif (link $f, "$upper_f,fetch") {
2092             printdebug "linked (using ...,fetch).\n";
2093         } elsif ((printdebug "($!) "),
2094                  $! != EEXIST) {
2095             fail "saving ../$f,fetch: $!";
2096         } else {
2097             printdebug "cannot.\n";
2098         }
2099     }
2100
2101     # We unpack and record the orig tarballs first, so that we only
2102     # need disk space for one private copy of the unpacked source.
2103     # But we can't make them into commits until we have the metadata
2104     # from the debian/changelog, so we record the tree objects now and
2105     # make them into commits later.
2106     my @tartrees;
2107     my $upstreamv = upstreamversion $dsc->{version};
2108     my $orig_f_base = srcfn $upstreamv, '';
2109
2110     foreach my $fi (@dfi) {
2111         # We actually import, and record as a commit, every tarball
2112         # (unless there is only one file, in which case there seems
2113         # little point.
2114
2115         my $f = $fi->{Filename};
2116         printdebug "import considering $f ";
2117         (printdebug "only one dfi\n"), next if @dfi == 1;
2118         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2119         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2120         my $compr_ext = $1;
2121
2122         my ($orig_f_part) =
2123             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2124
2125         printdebug "Y ", (join ' ', map { $_//"(none)" }
2126                           $compr_ext, $orig_f_part
2127                          ), "\n";
2128
2129         my $input = new IO::File $f, '<' or die "$f $!";
2130         my $compr_pid;
2131         my @compr_cmd;
2132
2133         if (defined $compr_ext) {
2134             my $cname =
2135                 Dpkg::Compression::compression_guess_from_filename $f;
2136             fail "Dpkg::Compression cannot handle file $f in source package"
2137                 if defined $compr_ext && !defined $cname;
2138             my $compr_proc =
2139                 new Dpkg::Compression::Process compression => $cname;
2140             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2141             my $compr_fh = new IO::Handle;
2142             my $compr_pid = open $compr_fh, "-|" // die $!;
2143             if (!$compr_pid) {
2144                 open STDIN, "<&", $input or die $!;
2145                 exec @compr_cmd;
2146                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2147             }
2148             $input = $compr_fh;
2149         }
2150
2151         rmtree "_unpack-tar";
2152         mkdir "_unpack-tar" or die $!;
2153         my @tarcmd = qw(tar -x -f -
2154                         --no-same-owner --no-same-permissions
2155                         --no-acls --no-xattrs --no-selinux);
2156         my $tar_pid = fork // die $!;
2157         if (!$tar_pid) {
2158             chdir "_unpack-tar" or die $!;
2159             open STDIN, "<&", $input or die $!;
2160             exec @tarcmd;
2161             die "dgit (child): exec $tarcmd[0]: $!";
2162         }
2163         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2164         !$? or failedcmd @tarcmd;
2165
2166         close $input or
2167             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2168              : die $!);
2169         # finally, we have the results in "tarball", but maybe
2170         # with the wrong permissions
2171
2172         runcmd qw(chmod -R +rwX _unpack-tar);
2173         changedir "_unpack-tar";
2174         remove_stray_gits($f);
2175         mktree_in_ud_here();
2176
2177         my ($tree) = git_add_write_tree();
2178         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2179         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2180             $tree = $1;
2181             printdebug "one subtree $1\n";
2182         } else {
2183             printdebug "multiple subtrees\n";
2184         }
2185         changedir "..";
2186         rmtree "_unpack-tar";
2187
2188         my $ent = [ $f, $tree ];
2189         push @tartrees, {
2190             Orig => !!$orig_f_part,
2191             Sort => (!$orig_f_part         ? 2 :
2192                      $orig_f_part =~ m/-/g ? 1 :
2193                                              0),
2194             F => $f,
2195             Tree => $tree,
2196         };
2197     }
2198
2199     @tartrees = sort {
2200         # put any without "_" first (spec is not clear whether files
2201         # are always in the usual order).  Tarballs without "_" are
2202         # the main orig or the debian tarball.
2203         $a->{Sort} <=> $b->{Sort} or
2204         $a->{F}    cmp $b->{F}
2205     } @tartrees;
2206
2207     my $any_orig = grep { $_->{Orig} } @tartrees;
2208
2209     my $dscfn = "$package.dsc";
2210
2211     my $treeimporthow = 'package';
2212
2213     open D, ">", $dscfn or die "$dscfn: $!";
2214     print D $dscdata or die "$dscfn: $!";
2215     close D or die "$dscfn: $!";
2216     my @cmd = qw(dpkg-source);
2217     push @cmd, '--no-check' if $dsc_checked;
2218     if (madformat $dsc->{format}) {
2219         push @cmd, '--skip-patches';
2220         $treeimporthow = 'unpatched';
2221     }
2222     push @cmd, qw(-x --), $dscfn;
2223     runcmd @cmd;
2224
2225     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2226     if (madformat $dsc->{format}) {
2227         check_for_vendor_patches();
2228     }
2229
2230     my $dappliedtree;
2231     if (madformat $dsc->{format}) {
2232         my @pcmd = qw(dpkg-source --before-build .);
2233         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2234         rmtree '.pc';
2235         $dappliedtree = git_add_write_tree();
2236     }
2237
2238     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2239     debugcmd "|",@clogcmd;
2240     open CLOGS, "-|", @clogcmd or die $!;
2241
2242     my $clogp;
2243     my $r1clogp;
2244
2245     printdebug "import clog search...\n";
2246
2247     for (;;) {
2248         my $stanzatext = do { local $/=""; <CLOGS>; };
2249         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2250         last if !defined $stanzatext;
2251
2252         my $desc = "package changelog, entry no.$.";
2253         open my $stanzafh, "<", \$stanzatext or die;
2254         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2255         $clogp //= $thisstanza;
2256
2257         printdebug "import clog $thisstanza->{version} $desc...\n";
2258
2259         last if !$any_orig; # we don't need $r1clogp
2260
2261         # We look for the first (most recent) changelog entry whose
2262         # version number is lower than the upstream version of this
2263         # package.  Then the last (least recent) previous changelog
2264         # entry is treated as the one which introduced this upstream
2265         # version and used for the synthetic commits for the upstream
2266         # tarballs.
2267
2268         # One might think that a more sophisticated algorithm would be
2269         # necessary.  But: we do not want to scan the whole changelog
2270         # file.  Stopping when we see an earlier version, which
2271         # necessarily then is an earlier upstream version, is the only
2272         # realistic way to do that.  Then, either the earliest
2273         # changelog entry we have seen so far is indeed the earliest
2274         # upload of this upstream version; or there are only changelog
2275         # entries relating to later upstream versions (which is not
2276         # possible unless the changelog and .dsc disagree about the
2277         # version).  Then it remains to choose between the physically
2278         # last entry in the file, and the one with the lowest version
2279         # number.  If these are not the same, we guess that the
2280         # versions were created in a non-monotic order rather than
2281         # that the changelog entries have been misordered.
2282
2283         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2284
2285         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2286         $r1clogp = $thisstanza;
2287
2288         printdebug "import clog $r1clogp->{version} becomes r1\n";
2289     }
2290     die $! if CLOGS->error;
2291     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2292
2293     $clogp or fail "package changelog has no entries!";
2294
2295     my $authline = clogp_authline $clogp;
2296     my $changes = getfield $clogp, 'Changes';
2297     $changes =~ s/^\n//; # Changes: \n
2298     my $cversion = getfield $clogp, 'Version';
2299
2300     if (@tartrees) {
2301         $r1clogp //= $clogp; # maybe there's only one entry;
2302         my $r1authline = clogp_authline $r1clogp;
2303         # Strictly, r1authline might now be wrong if it's going to be
2304         # unused because !$any_orig.  Whatever.
2305
2306         printdebug "import tartrees authline   $authline\n";
2307         printdebug "import tartrees r1authline $r1authline\n";
2308
2309         foreach my $tt (@tartrees) {
2310             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2311
2312             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2313 tree $tt->{Tree}
2314 author $r1authline
2315 committer $r1authline
2316
2317 Import $tt->{F}
2318
2319 [dgit import orig $tt->{F}]
2320 END_O
2321 tree $tt->{Tree}
2322 author $authline
2323 committer $authline
2324
2325 Import $tt->{F}
2326
2327 [dgit import tarball $package $cversion $tt->{F}]
2328 END_T
2329         }
2330     }
2331
2332     printdebug "import main commit\n";
2333
2334     open C, ">../commit.tmp" or die $!;
2335     print C <<END or die $!;
2336 tree $tree
2337 END
2338     print C <<END or die $! foreach @tartrees;
2339 parent $_->{Commit}
2340 END
2341     print C <<END or die $!;
2342 author $authline
2343 committer $authline
2344
2345 $changes
2346
2347 [dgit import $treeimporthow $package $cversion]
2348 END
2349
2350     close C or die $!;
2351     my $rawimport_hash = make_commit qw(../commit.tmp);
2352
2353     if (madformat $dsc->{format}) {
2354         printdebug "import apply patches...\n";
2355
2356         # regularise the state of the working tree so that
2357         # the checkout of $rawimport_hash works nicely.
2358         my $dappliedcommit = make_commit_text(<<END);
2359 tree $dappliedtree
2360 author $authline
2361 committer $authline
2362
2363 [dgit dummy commit]
2364 END
2365         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2366
2367         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2368
2369         # We need the answers to be reproducible
2370         my @authline = clogp_authline($clogp);
2371         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2372         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2373         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2374         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2375         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2376         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2377
2378         my $path = $ENV{PATH} or die;
2379
2380         foreach my $use_absurd (qw(0 1)) {
2381             runcmd @git, qw(checkout -q unpa);
2382             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2383             local $ENV{PATH} = $path;
2384             if ($use_absurd) {
2385                 chomp $@;
2386                 progress "warning: $@";
2387                 $path = "$absurdity:$path";
2388                 progress "$us: trying slow absurd-git-apply...";
2389                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2390                     or $!==ENOENT
2391                     or die $!;
2392             }
2393             eval {
2394                 die "forbid absurd git-apply\n" if $use_absurd
2395                     && forceing [qw(import-gitapply-no-absurd)];
2396                 die "only absurd git-apply!\n" if !$use_absurd
2397                     && forceing [qw(import-gitapply-absurd)];
2398
2399                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2400                 local $ENV{PATH} = $path                    if $use_absurd;
2401
2402                 my @showcmd = (gbp_pq, qw(import));
2403                 my @realcmd = shell_cmd
2404                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2405                 debugcmd "+",@realcmd;
2406                 if (system @realcmd) {
2407                     die +(shellquote @showcmd).
2408                         " failed: ".
2409                         failedcmd_waitstatus()."\n";
2410                 }
2411
2412                 my $gapplied = git_rev_parse('HEAD');
2413                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2414                 $gappliedtree eq $dappliedtree or
2415                     fail <<END;
2416 gbp-pq import and dpkg-source disagree!
2417  gbp-pq import gave commit $gapplied
2418  gbp-pq import gave tree $gappliedtree
2419  dpkg-source --before-build gave tree $dappliedtree
2420 END
2421                 $rawimport_hash = $gapplied;
2422             };
2423             last unless $@;
2424         }
2425         if ($@) {
2426             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2427             die $@;
2428         }
2429     }
2430
2431     progress "synthesised git commit from .dsc $cversion";
2432
2433     my $rawimport_mergeinput = {
2434         Commit => $rawimport_hash,
2435         Info => "Import of source package",
2436     };
2437     my @output = ($rawimport_mergeinput);
2438
2439     if ($lastpush_mergeinput) {
2440         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2441         my $oversion = getfield $oldclogp, 'Version';
2442         my $vcmp =
2443             version_compare($oversion, $cversion);
2444         if ($vcmp < 0) {
2445             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2446                 { Message => <<END, ReverseParents => 1 });
2447 Record $package ($cversion) in archive suite $csuite
2448 END
2449         } elsif ($vcmp > 0) {
2450             print STDERR <<END or die $!;
2451
2452 Version actually in archive:   $cversion (older)
2453 Last version pushed with dgit: $oversion (newer or same)
2454 $later_warning_msg
2455 END
2456             @output = $lastpush_mergeinput;
2457         } else {
2458             # Same version.  Use what's in the server git branch,
2459             # discarding our own import.  (This could happen if the
2460             # server automatically imports all packages into git.)
2461             @output = $lastpush_mergeinput;
2462         }
2463     }
2464     changedir $maindir;
2465     rmtree $playground;
2466     return @output;
2467 }
2468
2469 sub complete_file_from_dsc ($$;$) {
2470     our ($dstdir, $fi, $refetched) = @_;
2471     # Ensures that we have, in $dstdir, the file $fi, with the correct
2472     # contents.  (Downloading it from alongside $dscurl if necessary.)
2473     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2474     # and will set $$refetched=1 if it did so (or tried to).
2475
2476     my $f = $fi->{Filename};
2477     my $tf = "$dstdir/$f";
2478     my $downloaded = 0;
2479
2480     my $got;
2481     my $checkhash = sub {
2482         open F, "<", "$tf" or die "$tf: $!";
2483         $fi->{Digester}->reset();
2484         $fi->{Digester}->addfile(*F);
2485         F->error and die $!;
2486         $got = $fi->{Digester}->hexdigest();
2487         return $got eq $fi->{Hash};
2488     };
2489
2490     if (stat_exists $tf) {
2491         if ($checkhash->()) {
2492             progress "using existing $f";
2493             return 1;
2494         }
2495         if (!$refetched) {
2496             fail "file $f has hash $got but .dsc".
2497                 " demands hash $fi->{Hash} ".
2498                 "(perhaps you should delete this file?)";
2499         }
2500         progress "need to fetch correct version of $f";
2501         unlink $tf or die "$tf $!";
2502         $$refetched = 1;
2503     } else {
2504         printdebug "$tf does not exist, need to fetch\n";
2505     }
2506
2507     my $furl = $dscurl;
2508     $furl =~ s{/[^/]+$}{};
2509     $furl .= "/$f";
2510     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2511     die "$f ?" if $f =~ m#/#;
2512     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2513     return 0 if !act_local();
2514
2515     $checkhash->() or
2516         fail "file $f has hash $got but .dsc".
2517             " demands hash $fi->{Hash} ".
2518             "(got wrong file from archive!)";
2519
2520     return 1;
2521 }
2522
2523 sub ensure_we_have_orig () {
2524     my @dfi = dsc_files_info();
2525     foreach my $fi (@dfi) {
2526         my $f = $fi->{Filename};
2527         next unless is_orig_file_in_dsc($f, \@dfi);
2528         complete_file_from_dsc('..', $fi)
2529             or next;
2530     }
2531 }
2532
2533 #---------- git fetch ----------
2534
2535 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2536 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2537
2538 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2539 # locally fetched refs because they have unhelpful names and clutter
2540 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2541 # whether we have made another local ref which refers to this object).
2542 #
2543 # (If we deleted them unconditionally, then we might end up
2544 # re-fetching the same git objects each time dgit fetch was run.)
2545 #
2546 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2547 # in git_fetch_us to fetch the refs in question, and possibly a call
2548 # to lrfetchref_used.
2549
2550 our (%lrfetchrefs_f, %lrfetchrefs_d);
2551 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2552
2553 sub lrfetchref_used ($) {
2554     my ($fullrefname) = @_;
2555     my $objid = $lrfetchrefs_f{$fullrefname};
2556     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2557 }
2558
2559 sub git_lrfetch_sane {
2560     my ($url, $supplementary, @specs) = @_;
2561     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2562     # at least as regards @specs.  Also leave the results in
2563     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2564     # able to clean these up.
2565     #
2566     # With $supplementary==1, @specs must not contain wildcards
2567     # and we add to our previous fetches (non-atomically).
2568
2569     # This is rather miserable:
2570     # When git fetch --prune is passed a fetchspec ending with a *,
2571     # it does a plausible thing.  If there is no * then:
2572     # - it matches subpaths too, even if the supplied refspec
2573     #   starts refs, and behaves completely madly if the source
2574     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2575     # - if there is no matching remote ref, it bombs out the whole
2576     #   fetch.
2577     # We want to fetch a fixed ref, and we don't know in advance
2578     # if it exists, so this is not suitable.
2579     #
2580     # Our workaround is to use git ls-remote.  git ls-remote has its
2581     # own qairks.  Notably, it has the absurd multi-tail-matching
2582     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2583     # refs/refs/foo etc.
2584     #
2585     # Also, we want an idempotent snapshot, but we have to make two
2586     # calls to the remote: one to git ls-remote and to git fetch.  The
2587     # solution is use git ls-remote to obtain a target state, and
2588     # git fetch to try to generate it.  If we don't manage to generate
2589     # the target state, we try again.
2590
2591     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2592
2593     my $specre = join '|', map {
2594         my $x = $_;
2595         $x =~ s/\W/\\$&/g;
2596         my $wildcard = $x =~ s/\\\*$/.*/;
2597         die if $wildcard && $supplementary;
2598         "(?:refs/$x)";
2599     } @specs;
2600     printdebug "git_lrfetch_sane specre=$specre\n";
2601     my $wanted_rref = sub {
2602         local ($_) = @_;
2603         return m/^(?:$specre)$/;
2604     };
2605
2606     my $fetch_iteration = 0;
2607     FETCH_ITERATION:
2608     for (;;) {
2609         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2610         if (++$fetch_iteration > 10) {
2611             fail "too many iterations trying to get sane fetch!";
2612         }
2613
2614         my @look = map { "refs/$_" } @specs;
2615         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2616         debugcmd "|",@lcmd;
2617
2618         my %wantr;
2619         open GITLS, "-|", @lcmd or die $!;
2620         while (<GITLS>) {
2621             printdebug "=> ", $_;
2622             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2623             my ($objid,$rrefname) = ($1,$2);
2624             if (!$wanted_rref->($rrefname)) {
2625                 print STDERR <<END;
2626 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2627 END
2628                 next;
2629             }
2630             $wantr{$rrefname} = $objid;
2631         }
2632         $!=0; $?=0;
2633         close GITLS or failedcmd @lcmd;
2634
2635         # OK, now %want is exactly what we want for refs in @specs
2636         my @fspecs = map {
2637             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2638             "+refs/$_:".lrfetchrefs."/$_";
2639         } @specs;
2640
2641         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2642
2643         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2644         runcmd_ordryrun_local @fcmd if @fspecs;
2645
2646         if (!$supplementary) {
2647             %lrfetchrefs_f = ();
2648         }
2649         my %objgot;
2650
2651         git_for_each_ref(lrfetchrefs, sub {
2652             my ($objid,$objtype,$lrefname,$reftail) = @_;
2653             $lrfetchrefs_f{$lrefname} = $objid;
2654             $objgot{$objid} = 1;
2655         });
2656
2657         if ($supplementary) {
2658             last;
2659         }
2660
2661         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2662             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2663             if (!exists $wantr{$rrefname}) {
2664                 if ($wanted_rref->($rrefname)) {
2665                     printdebug <<END;
2666 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2667 END
2668                 } else {
2669                     print STDERR <<END
2670 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2671 END
2672                 }
2673                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2674                 delete $lrfetchrefs_f{$lrefname};
2675                 next;
2676             }
2677         }
2678         foreach my $rrefname (sort keys %wantr) {
2679             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2680             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2681             my $want = $wantr{$rrefname};
2682             next if $got eq $want;
2683             if (!defined $objgot{$want}) {
2684                 print STDERR <<END;
2685 warning: git ls-remote suggests we want $lrefname
2686 warning:  and it should refer to $want
2687 warning:  but git fetch didn't fetch that object to any relevant ref.
2688 warning:  This may be due to a race with someone updating the server.
2689 warning:  Will try again...
2690 END
2691                 next FETCH_ITERATION;
2692             }
2693             printdebug <<END;
2694 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2695 END
2696             runcmd_ordryrun_local @git, qw(update-ref -m),
2697                 "dgit fetch git fetch fixup", $lrefname, $want;
2698             $lrfetchrefs_f{$lrefname} = $want;
2699         }
2700         last;
2701     }
2702
2703     if (defined $csuite) {
2704         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2705         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2706             my ($objid,$objtype,$lrefname,$reftail) = @_;
2707             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2708             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2709         });
2710     }
2711
2712     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2713         Dumper(\%lrfetchrefs_f);
2714 }
2715
2716 sub git_fetch_us () {
2717     # Want to fetch only what we are going to use, unless
2718     # deliberately-not-ff, in which case we must fetch everything.
2719
2720     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2721         map { "tags/$_" }
2722         (quiltmode_splitbrain
2723          ? (map { $_->('*',access_nomdistro) }
2724             \&debiantag_new, \&debiantag_maintview)
2725          : debiantags('*',access_nomdistro));
2726     push @specs, server_branch($csuite);
2727     push @specs, $rewritemap;
2728     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2729
2730     my $url = access_giturl();
2731     git_lrfetch_sane $url, 0, @specs;
2732
2733     my %here;
2734     my @tagpats = debiantags('*',access_nomdistro);
2735
2736     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2737         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2738         printdebug "currently $fullrefname=$objid\n";
2739         $here{$fullrefname} = $objid;
2740     });
2741     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2742         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2743         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2744         printdebug "offered $lref=$objid\n";
2745         if (!defined $here{$lref}) {
2746             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2747             runcmd_ordryrun_local @upd;
2748             lrfetchref_used $fullrefname;
2749         } elsif ($here{$lref} eq $objid) {
2750             lrfetchref_used $fullrefname;
2751         } else {
2752             print STDERR
2753                 "Not updating $lref from $here{$lref} to $objid.\n";
2754         }
2755     });
2756 }
2757
2758 #---------- dsc and archive handling ----------
2759
2760 sub mergeinfo_getclogp ($) {
2761     # Ensures thit $mi->{Clogp} exists and returns it
2762     my ($mi) = @_;
2763     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2764 }
2765
2766 sub mergeinfo_version ($) {
2767     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2768 }
2769
2770 sub fetch_from_archive_record_1 ($) {
2771     my ($hash) = @_;
2772     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2773             'DGIT_ARCHIVE', $hash;
2774     cmdoutput @git, qw(log -n2), $hash;
2775     # ... gives git a chance to complain if our commit is malformed
2776 }
2777
2778 sub fetch_from_archive_record_2 ($) {
2779     my ($hash) = @_;
2780     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2781     if (act_local()) {
2782         cmdoutput @upd_cmd;
2783     } else {
2784         dryrun_report @upd_cmd;
2785     }
2786 }
2787
2788 sub parse_dsc_field_def_dsc_distro () {
2789     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2790                            dgit.default.distro);
2791 }
2792
2793 sub parse_dsc_field ($$) {
2794     my ($dsc, $what) = @_;
2795     my $f;
2796     foreach my $field (@ourdscfield) {
2797         $f = $dsc->{$field};
2798         last if defined $f;
2799     }
2800
2801     if (!defined $f) {
2802         progress "$what: NO git hash";
2803         parse_dsc_field_def_dsc_distro();
2804     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2805              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2806         progress "$what: specified git info ($dsc_distro)";
2807         $dsc_hint_tag = [ $dsc_hint_tag ];
2808     } elsif ($f =~ m/^\w+\s*$/) {
2809         $dsc_hash = $&;
2810         parse_dsc_field_def_dsc_distro();
2811         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2812                           $dsc_distro ];
2813         progress "$what: specified git hash";
2814     } else {
2815         fail "$what: invalid Dgit info";
2816     }
2817 }
2818
2819 sub resolve_dsc_field_commit ($$) {
2820     my ($already_distro, $already_mapref) = @_;
2821
2822     return unless defined $dsc_hash;
2823
2824     my $mapref =
2825         defined $already_mapref &&
2826         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2827         ? $already_mapref : undef;
2828
2829     my $do_fetch;
2830     $do_fetch = sub {
2831         my ($what, @fetch) = @_;
2832
2833         local $idistro = $dsc_distro;
2834         my $lrf = lrfetchrefs;
2835
2836         if (!$chase_dsc_distro) {
2837             progress
2838                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2839             return 0;
2840         }
2841
2842         progress
2843             ".dsc names distro $dsc_distro: fetching $what";
2844
2845         my $url = access_giturl();
2846         if (!defined $url) {
2847             defined $dsc_hint_url or fail <<END;
2848 .dsc Dgit metadata is in context of distro $dsc_distro
2849 for which we have no configured url and .dsc provides no hint
2850 END
2851             my $proto =
2852                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2853                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2854             parse_cfg_bool "dsc-url-proto-ok", 'false',
2855                 cfg("dgit.dsc-url-proto-ok.$proto",
2856                     "dgit.default.dsc-url-proto-ok")
2857                 or fail <<END;
2858 .dsc Dgit metadata is in context of distro $dsc_distro
2859 for which we have no configured url;
2860 .dsc provides hinted url with protocol $proto which is unsafe.
2861 (can be overridden by config - consult documentation)
2862 END
2863             $url = $dsc_hint_url;
2864         }
2865
2866         git_lrfetch_sane $url, 1, @fetch;
2867
2868         return $lrf;
2869     };
2870
2871     my $rewrite_enable = do {
2872         local $idistro = $dsc_distro;
2873         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2874     };
2875
2876     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2877         if (!defined $mapref) {
2878             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2879             $mapref = $lrf.'/'.$rewritemap;
2880         }
2881         my $rewritemapdata = git_cat_file $mapref.':map';
2882         if (defined $rewritemapdata
2883             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2884             progress
2885                 "server's git history rewrite map contains a relevant entry!";
2886
2887             $dsc_hash = $1;
2888             if (defined $dsc_hash) {
2889                 progress "using rewritten git hash in place of .dsc value";
2890             } else {
2891                 progress "server data says .dsc hash is to be disregarded";
2892             }
2893         }
2894     }
2895
2896     if (!defined git_cat_file $dsc_hash) {
2897         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2898         my $lrf = $do_fetch->("additional commits", @tags) &&
2899             defined git_cat_file $dsc_hash
2900             or fail <<END;
2901 .dsc Dgit metadata requires commit $dsc_hash
2902 but we could not obtain that object anywhere.
2903 END
2904         foreach my $t (@tags) {
2905             my $fullrefname = $lrf.'/'.$t;
2906 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2907             next unless $lrfetchrefs_f{$fullrefname};
2908             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2909             lrfetchref_used $fullrefname;
2910         }
2911     }
2912 }
2913
2914 sub fetch_from_archive () {
2915     ensure_setup_existing_tree();
2916
2917     # Ensures that lrref() is what is actually in the archive, one way
2918     # or another, according to us - ie this client's
2919     # appropritaely-updated archive view.  Also returns the commit id.
2920     # If there is nothing in the archive, leaves lrref alone and
2921     # returns undef.  git_fetch_us must have already been called.
2922     get_archive_dsc();
2923
2924     if ($dsc) {
2925         parse_dsc_field($dsc, 'last upload to archive');
2926         resolve_dsc_field_commit access_basedistro,
2927             lrfetchrefs."/".$rewritemap
2928     } else {
2929         progress "no version available from the archive";
2930     }
2931
2932     # If the archive's .dsc has a Dgit field, there are three
2933     # relevant git commitids we need to choose between and/or merge
2934     # together:
2935     #   1. $dsc_hash: the Dgit field from the archive
2936     #   2. $lastpush_hash: the suite branch on the dgit git server
2937     #   3. $lastfetch_hash: our local tracking brach for the suite
2938     #
2939     # These may all be distinct and need not be in any fast forward
2940     # relationship:
2941     #
2942     # If the dsc was pushed to this suite, then the server suite
2943     # branch will have been updated; but it might have been pushed to
2944     # a different suite and copied by the archive.  Conversely a more
2945     # recent version may have been pushed with dgit but not appeared
2946     # in the archive (yet).
2947     #
2948     # $lastfetch_hash may be awkward because archive imports
2949     # (particularly, imports of Dgit-less .dscs) are performed only as
2950     # needed on individual clients, so different clients may perform a
2951     # different subset of them - and these imports are only made
2952     # public during push.  So $lastfetch_hash may represent a set of
2953     # imports different to a subsequent upload by a different dgit
2954     # client.
2955     #
2956     # Our approach is as follows:
2957     #
2958     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2959     # descendant of $dsc_hash, then it was pushed by a dgit user who
2960     # had based their work on $dsc_hash, so we should prefer it.
2961     # Otherwise, $dsc_hash was installed into this suite in the
2962     # archive other than by a dgit push, and (necessarily) after the
2963     # last dgit push into that suite (since a dgit push would have
2964     # been descended from the dgit server git branch); thus, in that
2965     # case, we prefer the archive's version (and produce a
2966     # pseudo-merge to overwrite the dgit server git branch).
2967     #
2968     # (If there is no Dgit field in the archive's .dsc then
2969     # generate_commit_from_dsc uses the version numbers to decide
2970     # whether the suite branch or the archive is newer.  If the suite
2971     # branch is newer it ignores the archive's .dsc; otherwise it
2972     # generates an import of the .dsc, and produces a pseudo-merge to
2973     # overwrite the suite branch with the archive contents.)
2974     #
2975     # The outcome of that part of the algorithm is the `public view',
2976     # and is same for all dgit clients: it does not depend on any
2977     # unpublished history in the local tracking branch.
2978     #
2979     # As between the public view and the local tracking branch: The
2980     # local tracking branch is only updated by dgit fetch, and
2981     # whenever dgit fetch runs it includes the public view in the
2982     # local tracking branch.  Therefore if the public view is not
2983     # descended from the local tracking branch, the local tracking
2984     # branch must contain history which was imported from the archive
2985     # but never pushed; and, its tip is now out of date.  So, we make
2986     # a pseudo-merge to overwrite the old imports and stitch the old
2987     # history in.
2988     #
2989     # Finally: we do not necessarily reify the public view (as
2990     # described above).  This is so that we do not end up stacking two
2991     # pseudo-merges.  So what we actually do is figure out the inputs
2992     # to any public view pseudo-merge and put them in @mergeinputs.
2993
2994     my @mergeinputs;
2995     # $mergeinputs[]{Commit}
2996     # $mergeinputs[]{Info}
2997     # $mergeinputs[0] is the one whose tree we use
2998     # @mergeinputs is in the order we use in the actual commit)
2999     #
3000     # Also:
3001     # $mergeinputs[]{Message} is a commit message to use
3002     # $mergeinputs[]{ReverseParents} if def specifies that parent
3003     #                                list should be in opposite order
3004     # Such an entry has no Commit or Info.  It applies only when found
3005     # in the last entry.  (This ugliness is to support making
3006     # identical imports to previous dgit versions.)
3007
3008     my $lastpush_hash = git_get_ref(lrfetchref());
3009     printdebug "previous reference hash=$lastpush_hash\n";
3010     $lastpush_mergeinput = $lastpush_hash && {
3011         Commit => $lastpush_hash,
3012         Info => "dgit suite branch on dgit git server",
3013     };
3014
3015     my $lastfetch_hash = git_get_ref(lrref());
3016     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3017     my $lastfetch_mergeinput = $lastfetch_hash && {
3018         Commit => $lastfetch_hash,
3019         Info => "dgit client's archive history view",
3020     };
3021
3022     my $dsc_mergeinput = $dsc_hash && {
3023         Commit => $dsc_hash,
3024         Info => "Dgit field in .dsc from archive",
3025     };
3026
3027     my $cwd = getcwd();
3028     my $del_lrfetchrefs = sub {
3029         changedir $cwd;
3030         my $gur;
3031         printdebug "del_lrfetchrefs...\n";
3032         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3033             my $objid = $lrfetchrefs_d{$fullrefname};
3034             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3035             if (!$gur) {
3036                 $gur ||= new IO::Handle;
3037                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3038             }
3039             printf $gur "delete %s %s\n", $fullrefname, $objid;
3040         }
3041         if ($gur) {
3042             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3043         }
3044     };
3045
3046     if (defined $dsc_hash) {
3047         ensure_we_have_orig();
3048         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3049             @mergeinputs = $dsc_mergeinput
3050         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3051             print STDERR <<END or die $!;
3052
3053 Git commit in archive is behind the last version allegedly pushed/uploaded.
3054 Commit referred to by archive: $dsc_hash
3055 Last version pushed with dgit: $lastpush_hash
3056 $later_warning_msg
3057 END
3058             @mergeinputs = ($lastpush_mergeinput);
3059         } else {
3060             # Archive has .dsc which is not a descendant of the last dgit
3061             # push.  This can happen if the archive moves .dscs about.
3062             # Just follow its lead.
3063             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3064                 progress "archive .dsc names newer git commit";
3065                 @mergeinputs = ($dsc_mergeinput);
3066             } else {
3067                 progress "archive .dsc names other git commit, fixing up";
3068                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3069             }
3070         }
3071     } elsif ($dsc) {
3072         @mergeinputs = generate_commits_from_dsc();
3073         # We have just done an import.  Now, our import algorithm might
3074         # have been improved.  But even so we do not want to generate
3075         # a new different import of the same package.  So if the
3076         # version numbers are the same, just use our existing version.
3077         # If the version numbers are different, the archive has changed
3078         # (perhaps, rewound).
3079         if ($lastfetch_mergeinput &&
3080             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3081                               (mergeinfo_version $mergeinputs[0]) )) {
3082             @mergeinputs = ($lastfetch_mergeinput);
3083         }
3084     } elsif ($lastpush_hash) {
3085         # only in git, not in the archive yet
3086         @mergeinputs = ($lastpush_mergeinput);
3087         print STDERR <<END or die $!;
3088
3089 Package not found in the archive, but has allegedly been pushed using dgit.
3090 $later_warning_msg
3091 END
3092     } else {
3093         printdebug "nothing found!\n";
3094         if (defined $skew_warning_vsn) {
3095             print STDERR <<END or die $!;
3096
3097 Warning: relevant archive skew detected.
3098 Archive allegedly contains $skew_warning_vsn
3099 But we were not able to obtain any version from the archive or git.
3100
3101 END
3102         }
3103         unshift @end, $del_lrfetchrefs;
3104         return undef;
3105     }
3106
3107     if ($lastfetch_hash &&
3108         !grep {
3109             my $h = $_->{Commit};
3110             $h and is_fast_fwd($lastfetch_hash, $h);
3111             # If true, one of the existing parents of this commit
3112             # is a descendant of the $lastfetch_hash, so we'll
3113             # be ff from that automatically.
3114         } @mergeinputs
3115         ) {
3116         # Otherwise:
3117         push @mergeinputs, $lastfetch_mergeinput;
3118     }
3119
3120     printdebug "fetch mergeinfos:\n";
3121     foreach my $mi (@mergeinputs) {
3122         if ($mi->{Info}) {
3123             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3124         } else {
3125             printdebug sprintf " ReverseParents=%d Message=%s",
3126                 $mi->{ReverseParents}, $mi->{Message};
3127         }
3128     }
3129
3130     my $compat_info= pop @mergeinputs
3131         if $mergeinputs[$#mergeinputs]{Message};
3132
3133     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3134
3135     my $hash;
3136     if (@mergeinputs > 1) {
3137         # here we go, then:
3138         my $tree_commit = $mergeinputs[0]{Commit};
3139
3140         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3141         $tree =~ m/\n\n/;  $tree = $`;
3142         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3143         $tree = $1;
3144
3145         # We use the changelog author of the package in question the
3146         # author of this pseudo-merge.  This is (roughly) correct if
3147         # this commit is simply representing aa non-dgit upload.
3148         # (Roughly because it does not record sponsorship - but we
3149         # don't have sponsorship info because that's in the .changes,
3150         # which isn't in the archivw.)
3151         #
3152         # But, it might be that we are representing archive history
3153         # updates (including in-archive copies).  These are not really
3154         # the responsibility of the person who created the .dsc, but
3155         # there is no-one whose name we should better use.  (The
3156         # author of the .dsc-named commit is clearly worse.)
3157
3158         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3159         my $author = clogp_authline $useclogp;
3160         my $cversion = getfield $useclogp, 'Version';
3161
3162         my $mcf = ".git/dgit/mergecommit";
3163         open MC, ">", $mcf or die "$mcf $!";
3164         print MC <<END or die $!;
3165 tree $tree
3166 END
3167
3168         my @parents = grep { $_->{Commit} } @mergeinputs;
3169         @parents = reverse @parents if $compat_info->{ReverseParents};
3170         print MC <<END or die $! foreach @parents;
3171 parent $_->{Commit}
3172 END
3173
3174         print MC <<END or die $!;
3175 author $author
3176 committer $author
3177
3178 END
3179
3180         if (defined $compat_info->{Message}) {
3181             print MC $compat_info->{Message} or die $!;
3182         } else {
3183             print MC <<END or die $!;
3184 Record $package ($cversion) in archive suite $csuite
3185
3186 Record that
3187 END
3188             my $message_add_info = sub {
3189                 my ($mi) = (@_);
3190                 my $mversion = mergeinfo_version $mi;
3191                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3192                     or die $!;
3193             };
3194
3195             $message_add_info->($mergeinputs[0]);
3196             print MC <<END or die $!;
3197 should be treated as descended from
3198 END
3199             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3200         }
3201
3202         close MC or die $!;
3203         $hash = make_commit $mcf;
3204     } else {
3205         $hash = $mergeinputs[0]{Commit};
3206     }
3207     printdebug "fetch hash=$hash\n";
3208
3209     my $chkff = sub {
3210         my ($lasth, $what) = @_;
3211         return unless $lasth;
3212         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3213     };
3214
3215     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3216         if $lastpush_hash;
3217     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3218
3219     fetch_from_archive_record_1($hash);
3220
3221     if (defined $skew_warning_vsn) {
3222         mkpath '.git/dgit';
3223         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3224         my $gotclogp = commit_getclogp($hash);
3225         my $got_vsn = getfield $gotclogp, 'Version';
3226         printdebug "SKEW CHECK GOT $got_vsn\n";
3227         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3228             print STDERR <<END or die $!;
3229
3230 Warning: archive skew detected.  Using the available version:
3231 Archive allegedly contains    $skew_warning_vsn
3232 We were able to obtain only   $got_vsn
3233
3234 END
3235         }
3236     }
3237
3238     if ($lastfetch_hash ne $hash) {
3239         fetch_from_archive_record_2($hash);
3240     }
3241
3242     lrfetchref_used lrfetchref();
3243
3244     check_gitattrs($hash, "fetched source tree");
3245
3246     unshift @end, $del_lrfetchrefs;
3247     return $hash;
3248 }
3249
3250 sub set_local_git_config ($$) {
3251     my ($k, $v) = @_;
3252     runcmd @git, qw(config), $k, $v;
3253 }
3254
3255 sub setup_mergechangelogs (;$) {
3256     my ($always) = @_;
3257     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3258
3259     my $driver = 'dpkg-mergechangelogs';
3260     my $cb = "merge.$driver";
3261     my $attrs = '.git/info/attributes';
3262     ensuredir '.git/info';
3263
3264     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3265     if (!open ATTRS, "<", $attrs) {
3266         $!==ENOENT or die "$attrs: $!";
3267     } else {
3268         while (<ATTRS>) {
3269             chomp;
3270             next if m{^debian/changelog\s};
3271             print NATTRS $_, "\n" or die $!;
3272         }
3273         ATTRS->error and die $!;
3274         close ATTRS;
3275     }
3276     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3277     close NATTRS;
3278
3279     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3280     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3281
3282     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3283 }
3284
3285 sub setup_useremail (;$) {
3286     my ($always) = @_;
3287     return unless $always || access_cfg_bool(1, 'setup-useremail');
3288
3289     my $setup = sub {
3290         my ($k, $envvar) = @_;
3291         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3292         return unless defined $v;
3293         set_local_git_config "user.$k", $v;
3294     };
3295
3296     $setup->('email', 'DEBEMAIL');
3297     $setup->('name', 'DEBFULLNAME');
3298 }
3299
3300 sub ensure_setup_existing_tree () {
3301     my $k = "remote.$remotename.skipdefaultupdate";
3302     my $c = git_get_config $k;
3303     return if defined $c;
3304     set_local_git_config $k, 'true';
3305 }
3306
3307 sub open_gitattrs () {
3308     my $gai = new IO::File ".git/info/attributes"
3309         or $!==ENOENT
3310         or die "open .git/info/attributes: $!";
3311     return $gai;
3312 }
3313
3314 sub is_gitattrs_setup () {
3315     my $gai = open_gitattrs();
3316     return 0 unless $gai;
3317     while (<$gai>) {
3318         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3319     }
3320     $gai->error and die $!;
3321     return 0;
3322 }
3323
3324 sub setup_gitattrs (;$) {
3325     my ($always) = @_;
3326     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3327
3328     if (is_gitattrs_setup()) {
3329         progress <<END;
3330 [attr]dgit-defuse-attrs already found in .git/info/attributes
3331  not doing further gitattributes setup
3332 END
3333         return;
3334     }
3335     my $af = ".git/info/attributes";
3336     ensuredir '.git/info';
3337     open GAO, "> $af.new" or die $!;
3338     print GAO <<END or die $!;
3339 *       dgit-defuse-attrs
3340 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3341 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3342 END
3343     my $gai = open_gitattrs();
3344     if ($gai) {
3345         while (<$gai>) {
3346             chomp;
3347             print GAO $_, "\n" or die $!;
3348         }
3349         $gai->error and die $!;
3350     }
3351     close GAO or die $!;
3352     rename "$af.new", "$af" or die "install $af: $!";
3353 }
3354
3355 sub setup_new_tree () {
3356     setup_mergechangelogs();
3357     setup_useremail();
3358     setup_gitattrs();
3359 }
3360
3361 sub check_gitattrs ($$) {
3362     my ($treeish, $what) = @_;
3363
3364     return if is_gitattrs_setup;
3365
3366     local $/="\0";
3367     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3368     debugcmd "|",@cmd;
3369     my $gafl = new IO::File;
3370     open $gafl, "-|", @cmd or die $!;
3371     while (<$gafl>) {
3372         chomp or die;
3373         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3374         next if $1 == 0;
3375         next unless m{(?:^|/)\.gitattributes$};
3376
3377         # oh dear, found one
3378         print STDERR <<END;
3379 dgit: warning: $what contains .gitattributes
3380 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3381 END
3382         close $gafl;
3383         return;
3384     }
3385     # tree contains no .gitattributes files
3386     $?=0; $!=0; close $gafl or failedcmd @cmd;
3387 }
3388
3389
3390 sub multisuite_suite_child ($$$) {
3391     my ($tsuite, $merginputs, $fn) = @_;
3392     # in child, sets things up, calls $fn->(), and returns undef
3393     # in parent, returns canonical suite name for $tsuite
3394     my $canonsuitefh = IO::File::new_tmpfile;
3395     my $pid = fork // die $!;
3396     if (!$pid) {
3397         forkcheck_setup();
3398         $isuite = $tsuite;
3399         $us .= " [$isuite]";
3400         $debugprefix .= " ";
3401         progress "fetching $tsuite...";
3402         canonicalise_suite();
3403         print $canonsuitefh $csuite, "\n" or die $!;
3404         close $canonsuitefh or die $!;
3405         $fn->();
3406         return undef;
3407     }
3408     waitpid $pid,0 == $pid or die $!;
3409     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3410     seek $canonsuitefh,0,0 or die $!;
3411     local $csuite = <$canonsuitefh>;
3412     die $! unless defined $csuite && chomp $csuite;
3413     if ($? == 256*4) {
3414         printdebug "multisuite $tsuite missing\n";
3415         return $csuite;
3416     }
3417     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3418     push @$merginputs, {
3419         Ref => lrref,
3420         Info => $csuite,
3421     };
3422     return $csuite;
3423 }
3424
3425 sub fork_for_multisuite ($) {
3426     my ($before_fetch_merge) = @_;
3427     # if nothing unusual, just returns ''
3428     #
3429     # if multisuite:
3430     # returns 0 to caller in child, to do first of the specified suites
3431     # in child, $csuite is not yet set
3432     #
3433     # returns 1 to caller in parent, to finish up anything needed after
3434     # in parent, $csuite is set to canonicalised portmanteau
3435
3436     my $org_isuite = $isuite;
3437     my @suites = split /\,/, $isuite;
3438     return '' unless @suites > 1;
3439     printdebug "fork_for_multisuite: @suites\n";
3440
3441     my @mergeinputs;
3442
3443     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3444                                             sub { });
3445     return 0 unless defined $cbasesuite;
3446
3447     fail "package $package missing in (base suite) $cbasesuite"
3448         unless @mergeinputs;
3449
3450     my @csuites = ($cbasesuite);
3451
3452     $before_fetch_merge->();
3453
3454     foreach my $tsuite (@suites[1..$#suites]) {
3455         $tsuite =~ s/^-/$cbasesuite-/;
3456         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3457                                                sub {
3458             @end = ();
3459             fetch();
3460             exit 0;
3461         });
3462         # xxx collecte the ref here
3463
3464         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3465         push @csuites, $csubsuite;
3466     }
3467
3468     foreach my $mi (@mergeinputs) {
3469         my $ref = git_get_ref $mi->{Ref};
3470         die "$mi->{Ref} ?" unless length $ref;
3471         $mi->{Commit} = $ref;
3472     }
3473
3474     $csuite = join ",", @csuites;
3475
3476     my $previous = git_get_ref lrref;
3477     if ($previous) {
3478         unshift @mergeinputs, {
3479             Commit => $previous,
3480             Info => "local combined tracking branch",
3481             Warning =>
3482  "archive seems to have rewound: local tracking branch is ahead!",
3483         };
3484     }
3485
3486     foreach my $ix (0..$#mergeinputs) {
3487         $mergeinputs[$ix]{Index} = $ix;
3488     }
3489
3490     @mergeinputs = sort {
3491         -version_compare(mergeinfo_version $a,
3492                          mergeinfo_version $b) # highest version first
3493             or
3494         $a->{Index} <=> $b->{Index}; # earliest in spec first
3495     } @mergeinputs;
3496
3497     my @needed;
3498
3499   NEEDED:
3500     foreach my $mi (@mergeinputs) {
3501         printdebug "multisuite merge check $mi->{Info}\n";
3502         foreach my $previous (@needed) {
3503             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3504             printdebug "multisuite merge un-needed $previous->{Info}\n";
3505             next NEEDED;
3506         }
3507         push @needed, $mi;
3508         printdebug "multisuite merge this-needed\n";
3509         $mi->{Character} = '+';
3510     }
3511
3512     $needed[0]{Character} = '*';
3513
3514     my $output = $needed[0]{Commit};
3515
3516     if (@needed > 1) {
3517         printdebug "multisuite merge nontrivial\n";
3518         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3519
3520         my $commit = "tree $tree\n";
3521         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3522             "Input branches:\n";
3523
3524         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3525             printdebug "multisuite merge include $mi->{Info}\n";
3526             $mi->{Character} //= ' ';
3527             $commit .= "parent $mi->{Commit}\n";
3528             $msg .= sprintf " %s  %-25s %s\n",
3529                 $mi->{Character},
3530                 (mergeinfo_version $mi),
3531                 $mi->{Info};
3532         }
3533         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3534         $msg .= "\nKey\n".
3535             " * marks the highest version branch, which choose to use\n".
3536             " + marks each branch which was not already an ancestor\n\n".
3537             "[dgit multi-suite $csuite]\n";
3538         $commit .=
3539             "author $authline\n".
3540             "committer $authline\n\n";
3541         $output = make_commit_text $commit.$msg;
3542         printdebug "multisuite merge generated $output\n";
3543     }
3544
3545     fetch_from_archive_record_1($output);
3546     fetch_from_archive_record_2($output);
3547
3548     progress "calculated combined tracking suite $csuite";
3549
3550     return 1;
3551 }
3552
3553 sub clone_set_head () {
3554     open H, "> .git/HEAD" or die $!;
3555     print H "ref: ".lref()."\n" or die $!;
3556     close H or die $!;
3557 }
3558 sub clone_finish ($) {
3559     my ($dstdir) = @_;
3560     runcmd @git, qw(reset --hard), lrref();
3561     runcmd qw(bash -ec), <<'END';
3562         set -o pipefail
3563         git ls-tree -r --name-only -z HEAD | \
3564         xargs -0r touch -h -r . --
3565 END
3566     printdone "ready for work in $dstdir";
3567 }
3568
3569 sub clone ($) {
3570     # in multisuite, returns twice!
3571     # once in parent after first suite fetched,
3572     # and then again in child after everything is finished
3573     my ($dstdir) = @_;
3574     badusage "dry run makes no sense with clone" unless act_local();
3575
3576     my $multi_fetched = fork_for_multisuite(sub {
3577         printdebug "multi clone before fetch merge\n";
3578         changedir $dstdir;
3579     });
3580     if ($multi_fetched) {
3581         printdebug "multi clone after fetch merge\n";
3582         clone_set_head();
3583         clone_finish($dstdir);
3584         return;
3585     }
3586     printdebug "clone main body\n";
3587
3588     canonicalise_suite();
3589     my $hasgit = check_for_git();
3590     mkdir $dstdir or fail "create \`$dstdir': $!";
3591     changedir $dstdir;
3592     runcmd @git, qw(init -q);
3593     setup_new_tree();
3594     clone_set_head();
3595     my $giturl = access_giturl(1);
3596     if (defined $giturl) {
3597         runcmd @git, qw(remote add), 'origin', $giturl;
3598     }
3599     if ($hasgit) {
3600         progress "fetching existing git history";
3601         git_fetch_us();
3602         runcmd_ordryrun_local @git, qw(fetch origin);
3603     } else {
3604         progress "starting new git history";
3605     }
3606     fetch_from_archive() or no_such_package;
3607     my $vcsgiturl = $dsc->{'Vcs-Git'};
3608     if (length $vcsgiturl) {
3609         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3610         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3611     }
3612     clone_finish($dstdir);
3613 }
3614
3615 sub fetch () {
3616     canonicalise_suite();
3617     if (check_for_git()) {
3618         git_fetch_us();
3619     }
3620     fetch_from_archive() or no_such_package();
3621     printdone "fetched into ".lrref();
3622 }
3623
3624 sub pull () {
3625     my $multi_fetched = fork_for_multisuite(sub { });
3626     fetch() unless $multi_fetched; # parent
3627     return if $multi_fetched eq '0'; # child
3628     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3629         lrref();
3630     printdone "fetched to ".lrref()." and merged into HEAD";
3631 }
3632
3633 sub check_not_dirty () {
3634     foreach my $f (qw(local-options local-patch-header)) {
3635         if (stat_exists "debian/source/$f") {
3636             fail "git tree contains debian/source/$f";
3637         }
3638     }
3639
3640     return if $ignoredirty;
3641
3642     my @cmd = (@git, qw(diff --quiet HEAD));
3643     debugcmd "+",@cmd;
3644     $!=0; $?=-1; system @cmd;
3645     return if !$?;
3646     if ($?==256) {
3647         fail "working tree is dirty (does not match HEAD)";
3648     } else {
3649         failedcmd @cmd;
3650     }
3651 }
3652
3653 sub commit_admin ($) {
3654     my ($m) = @_;
3655     progress "$m";
3656     runcmd_ordryrun_local @git, qw(commit -m), $m;
3657 }
3658
3659 sub commit_quilty_patch () {
3660     my $output = cmdoutput @git, qw(status --porcelain);
3661     my %adds;
3662     foreach my $l (split /\n/, $output) {
3663         next unless $l =~ m/\S/;
3664         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3665             $adds{$1}++;
3666         }
3667     }
3668     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3669     if (!%adds) {
3670         progress "nothing quilty to commit, ok.";
3671         return;
3672     }
3673     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3674     runcmd_ordryrun_local @git, qw(add -f), @adds;
3675     commit_admin <<END
3676 Commit Debian 3.0 (quilt) metadata
3677
3678 [dgit ($our_version) quilt-fixup]
3679 END
3680 }
3681
3682 sub get_source_format () {
3683     my %options;
3684     if (open F, "debian/source/options") {
3685         while (<F>) {
3686             next if m/^\s*\#/;
3687             next unless m/\S/;
3688             s/\s+$//; # ignore missing final newline
3689             if (m/\s*\#\s*/) {
3690                 my ($k, $v) = ($`, $'); #');
3691                 $v =~ s/^"(.*)"$/$1/;
3692                 $options{$k} = $v;
3693             } else {
3694                 $options{$_} = 1;
3695             }
3696         }
3697         F->error and die $!;
3698         close F;
3699     } else {
3700         die $! unless $!==&ENOENT;
3701     }
3702
3703     if (!open F, "debian/source/format") {
3704         die $! unless $!==&ENOENT;
3705         return '';
3706     }
3707     $_ = <F>;
3708     F->error and die $!;
3709     chomp;
3710     return ($_, \%options);
3711 }
3712
3713 sub madformat_wantfixup ($) {
3714     my ($format) = @_;
3715     return 0 unless $format eq '3.0 (quilt)';
3716     our $quilt_mode_warned;
3717     if ($quilt_mode eq 'nocheck') {
3718         progress "Not doing any fixup of \`$format' due to".
3719             " ----no-quilt-fixup or --quilt=nocheck"
3720             unless $quilt_mode_warned++;
3721         return 0;
3722     }
3723     progress "Format \`$format', need to check/update patch stack"
3724         unless $quilt_mode_warned++;
3725     return 1;
3726 }
3727
3728 sub maybe_split_brain_save ($$$) {
3729     my ($headref, $dgitview, $msg) = @_;
3730     # => message fragment "$saved" describing disposition of $dgitview
3731     return "commit id $dgitview" unless defined $split_brain_save;
3732     my @cmd = (shell_cmd "cd ../../../..",
3733                @git, qw(update-ref -m),
3734                "dgit --dgit-view-save $msg HEAD=$headref",
3735                $split_brain_save, $dgitview);
3736     runcmd @cmd;
3737     return "and left in $split_brain_save";
3738 }
3739
3740 # An "infopair" is a tuple [ $thing, $what ]
3741 # (often $thing is a commit hash; $what is a description)
3742
3743 sub infopair_cond_equal ($$) {
3744     my ($x,$y) = @_;
3745     $x->[0] eq $y->[0] or fail <<END;
3746 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3747 END
3748 };
3749
3750 sub infopair_lrf_tag_lookup ($$) {
3751     my ($tagnames, $what) = @_;
3752     # $tagname may be an array ref
3753     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3754     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3755     foreach my $tagname (@tagnames) {
3756         my $lrefname = lrfetchrefs."/tags/$tagname";
3757         my $tagobj = $lrfetchrefs_f{$lrefname};
3758         next unless defined $tagobj;
3759         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3760         return [ git_rev_parse($tagobj), $what ];
3761     }
3762     fail @tagnames==1 ? <<END : <<END;
3763 Wanted tag $what (@tagnames) on dgit server, but not found
3764 END
3765 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3766 END
3767 }
3768
3769 sub infopair_cond_ff ($$) {
3770     my ($anc,$desc) = @_;
3771     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3772 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3773 END
3774 };
3775
3776 sub pseudomerge_version_check ($$) {
3777     my ($clogp, $archive_hash) = @_;
3778
3779     my $arch_clogp = commit_getclogp $archive_hash;
3780     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3781                      'version currently in archive' ];
3782     if (defined $overwrite_version) {
3783         if (length $overwrite_version) {
3784             infopair_cond_equal([ $overwrite_version,
3785                                   '--overwrite= version' ],
3786                                 $i_arch_v);
3787         } else {
3788             my $v = $i_arch_v->[0];
3789             progress "Checking package changelog for archive version $v ...";
3790             my $cd;
3791             eval {
3792                 my @xa = ("-f$v", "-t$v");
3793                 my $vclogp = parsechangelog @xa;
3794                 my $gf = sub {
3795                     my ($fn) = @_;
3796                     [ (getfield $vclogp, $fn),
3797                       "$fn field from dpkg-parsechangelog @xa" ];
3798                 };
3799                 my $cv = $gf->('Version');
3800                 infopair_cond_equal($i_arch_v, $cv);
3801                 $cd = $gf->('Distribution');
3802             };
3803             if ($@) {
3804                 $@ =~ s/^dgit: //gm;
3805                 fail "$@".
3806                     "Perhaps debian/changelog does not mention $v ?";
3807             }
3808             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3809 $cd->[1] is $cd->[0]
3810 Your tree seems to based on earlier (not uploaded) $v.
3811 END
3812         }
3813     }
3814
3815     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3816     return $i_arch_v;
3817 }
3818
3819 sub pseudomerge_make_commit ($$$$ $$) {
3820     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3821         $msg_cmd, $msg_msg) = @_;
3822     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3823
3824     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3825     my $authline = clogp_authline $clogp;
3826
3827     chomp $msg_msg;
3828     $msg_cmd .=
3829         !defined $overwrite_version ? ""
3830         : !length  $overwrite_version ? " --overwrite"
3831         : " --overwrite=".$overwrite_version;
3832
3833     mkpath '.git/dgit';
3834     my $pmf = ".git/dgit/pseudomerge";
3835     open MC, ">", $pmf or die "$pmf $!";
3836     print MC <<END or die $!;
3837 tree $tree
3838 parent $dgitview
3839 parent $archive_hash
3840 author $authline
3841 committer $authline
3842
3843 $msg_msg
3844
3845 [$msg_cmd]
3846 END
3847     close MC or die $!;
3848
3849     return make_commit($pmf);
3850 }
3851
3852 sub splitbrain_pseudomerge ($$$$) {
3853     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3854     # => $merged_dgitview
3855     printdebug "splitbrain_pseudomerge...\n";
3856     #
3857     #     We:      debian/PREVIOUS    HEAD($maintview)
3858     # expect:          o ----------------- o
3859     #                    \                   \
3860     #                     o                   o
3861     #                 a/d/PREVIOUS        $dgitview
3862     #                $archive_hash              \
3863     #  If so,                \                   \
3864     #  we do:                 `------------------ o
3865     #   this:                                   $dgitview'
3866     #
3867
3868     return $dgitview unless defined $archive_hash;
3869     return $dgitview if deliberately_not_fast_forward();
3870
3871     printdebug "splitbrain_pseudomerge...\n";
3872
3873     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3874
3875     if (!defined $overwrite_version) {
3876         progress "Checking that HEAD inciudes all changes in archive...";
3877     }
3878
3879     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3880
3881     if (defined $overwrite_version) {
3882     } elsif (!eval {
3883         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3884         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3885         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3886         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3887         my $i_archive = [ $archive_hash, "current archive contents" ];
3888
3889         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3890
3891         infopair_cond_equal($i_dgit, $i_archive);
3892         infopair_cond_ff($i_dep14, $i_dgit);
3893         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3894         1;
3895     }) {
3896         print STDERR <<END;
3897 $us: check failed (maybe --overwrite is needed, consult documentation)
3898 END
3899         die "$@";
3900     }
3901
3902     my $r = pseudomerge_make_commit
3903         $clogp, $dgitview, $archive_hash, $i_arch_v,
3904         "dgit --quilt=$quilt_mode",
3905         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3906 Declare fast forward from $i_arch_v->[0]
3907 END_OVERWR
3908 Make fast forward from $i_arch_v->[0]
3909 END_MAKEFF
3910
3911     maybe_split_brain_save $maintview, $r, "pseudomerge";
3912
3913     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3914     return $r;
3915 }
3916
3917 sub plain_overwrite_pseudomerge ($$$) {
3918     my ($clogp, $head, $archive_hash) = @_;
3919
3920     printdebug "plain_overwrite_pseudomerge...";
3921
3922     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3923
3924     return $head if is_fast_fwd $archive_hash, $head;
3925
3926     my $m = "Declare fast forward from $i_arch_v->[0]";
3927
3928     my $r = pseudomerge_make_commit
3929         $clogp, $head, $archive_hash, $i_arch_v,
3930         "dgit", $m;
3931
3932     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3933
3934     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3935     return $r;
3936 }
3937
3938 sub push_parse_changelog ($) {
3939     my ($clogpfn) = @_;
3940
3941     my $clogp = Dpkg::Control::Hash->new();
3942     $clogp->load($clogpfn) or die;
3943
3944     my $clogpackage = getfield $clogp, 'Source';
3945     $package //= $clogpackage;
3946     fail "-p specified $package but changelog specified $clogpackage"
3947         unless $package eq $clogpackage;
3948     my $cversion = getfield $clogp, 'Version';
3949
3950     if (!$we_are_initiator) {
3951         # rpush initiator can't do this because it doesn't have $isuite yet
3952         my $tag = debiantag($cversion, access_nomdistro);
3953         runcmd @git, qw(check-ref-format), $tag;
3954     }
3955
3956     my $dscfn = dscfn($cversion);
3957
3958     return ($clogp, $cversion, $dscfn);
3959 }
3960
3961 sub push_parse_dsc ($$$) {
3962     my ($dscfn,$dscfnwhat, $cversion) = @_;
3963     $dsc = parsecontrol($dscfn,$dscfnwhat);
3964     my $dversion = getfield $dsc, 'Version';
3965     my $dscpackage = getfield $dsc, 'Source';
3966     ($dscpackage eq $package && $dversion eq $cversion) or
3967         fail "$dscfn is for $dscpackage $dversion".
3968             " but debian/changelog is for $package $cversion";
3969 }
3970
3971 sub push_tagwants ($$$$) {
3972     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3973     my @tagwants;
3974     push @tagwants, {
3975         TagFn => \&debiantag,
3976         Objid => $dgithead,
3977         TfSuffix => '',
3978         View => 'dgit',
3979     };
3980     if (defined $maintviewhead) {
3981         push @tagwants, {
3982             TagFn => \&debiantag_maintview,
3983             Objid => $maintviewhead,
3984             TfSuffix => '-maintview',
3985             View => 'maint',
3986         };
3987     } elsif ($dodep14tag eq 'no' ? 0
3988              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3989              : $dodep14tag eq 'always'
3990              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3991 --dep14tag-always (or equivalent in config) means server must support
3992  both "new" and "maint" tag formats, but config says it doesn't.
3993 END
3994             : die "$dodep14tag ?") {
3995         push @tagwants, {
3996             TagFn => \&debiantag_maintview,
3997             Objid => $dgithead,
3998             TfSuffix => '-dgit',
3999             View => 'dgit',
4000         };
4001     };
4002     foreach my $tw (@tagwants) {
4003         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4004         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4005     }
4006     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4007     return @tagwants;
4008 }
4009
4010 sub push_mktags ($$ $$ $) {
4011     my ($clogp,$dscfn,
4012         $changesfile,$changesfilewhat,
4013         $tagwants) = @_;
4014
4015     die unless $tagwants->[0]{View} eq 'dgit';
4016
4017     my $declaredistro = access_nomdistro();
4018     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4019     $dsc->{$ourdscfield[0]} = join " ",
4020         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4021         $reader_giturl;
4022     $dsc->save("$dscfn.tmp") or die $!;
4023
4024     my $changes = parsecontrol($changesfile,$changesfilewhat);
4025     foreach my $field (qw(Source Distribution Version)) {
4026         $changes->{$field} eq $clogp->{$field} or
4027             fail "changes field $field \`$changes->{$field}'".
4028                 " does not match changelog \`$clogp->{$field}'";
4029     }
4030
4031     my $cversion = getfield $clogp, 'Version';
4032     my $clogsuite = getfield $clogp, 'Distribution';
4033
4034     # We make the git tag by hand because (a) that makes it easier
4035     # to control the "tagger" (b) we can do remote signing
4036     my $authline = clogp_authline $clogp;
4037     my $delibs = join(" ", "",@deliberatelies);
4038
4039     my $mktag = sub {
4040         my ($tw) = @_;
4041         my $tfn = $tw->{Tfn};
4042         my $head = $tw->{Objid};
4043         my $tag = $tw->{Tag};
4044
4045         open TO, '>', $tfn->('.tmp') or die $!;
4046         print TO <<END or die $!;
4047 object $head
4048 type commit
4049 tag $tag
4050 tagger $authline
4051
4052 END
4053         if ($tw->{View} eq 'dgit') {
4054             print TO <<END or die $!;
4055 $package release $cversion for $clogsuite ($csuite) [dgit]
4056 [dgit distro=$declaredistro$delibs]
4057 END
4058             foreach my $ref (sort keys %previously) {
4059                 print TO <<END or die $!;
4060 [dgit previously:$ref=$previously{$ref}]
4061 END
4062             }
4063         } elsif ($tw->{View} eq 'maint') {
4064             print TO <<END or die $!;
4065 $package release $cversion for $clogsuite ($csuite)
4066 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4067 END
4068         } else {
4069             die Dumper($tw)."?";
4070         }
4071
4072         close TO or die $!;
4073
4074         my $tagobjfn = $tfn->('.tmp');
4075         if ($sign) {
4076             if (!defined $keyid) {
4077                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4078             }
4079             if (!defined $keyid) {
4080                 $keyid = getfield $clogp, 'Maintainer';
4081             }
4082             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4083             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4084             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4085             push @sign_cmd, $tfn->('.tmp');
4086             runcmd_ordryrun @sign_cmd;
4087             if (act_scary()) {
4088                 $tagobjfn = $tfn->('.signed.tmp');
4089                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4090                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4091             }
4092         }
4093         return $tagobjfn;
4094     };
4095
4096     my @r = map { $mktag->($_); } @$tagwants;
4097     return @r;
4098 }
4099
4100 sub sign_changes ($) {
4101     my ($changesfile) = @_;
4102     if ($sign) {
4103         my @debsign_cmd = @debsign;
4104         push @debsign_cmd, "-k$keyid" if defined $keyid;
4105         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4106         push @debsign_cmd, $changesfile;
4107         runcmd_ordryrun @debsign_cmd;
4108     }
4109 }
4110
4111 sub dopush () {
4112     printdebug "actually entering push\n";
4113
4114     supplementary_message(<<'END');
4115 Push failed, while checking state of the archive.
4116 You can retry the push, after fixing the problem, if you like.
4117 END
4118     if (check_for_git()) {
4119         git_fetch_us();
4120     }
4121     my $archive_hash = fetch_from_archive();
4122     if (!$archive_hash) {
4123         $new_package or
4124             fail "package appears to be new in this suite;".
4125                 " if this is intentional, use --new";
4126     }
4127
4128     supplementary_message(<<'END');
4129 Push failed, while preparing your push.
4130 You can retry the push, after fixing the problem, if you like.
4131 END
4132
4133     need_tagformat 'new', "quilt mode $quilt_mode"
4134         if quiltmode_splitbrain;
4135
4136     prep_ud();
4137
4138     access_giturl(); # check that success is vaguely likely
4139     rpush_handle_protovsn_bothends() if $we_are_initiator;
4140     select_tagformat();
4141
4142     my $clogpfn = ".git/dgit/changelog.822.tmp";
4143     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4144
4145     responder_send_file('parsed-changelog', $clogpfn);
4146
4147     my ($clogp, $cversion, $dscfn) =
4148         push_parse_changelog("$clogpfn");
4149
4150     my $dscpath = "$buildproductsdir/$dscfn";
4151     stat_exists $dscpath or
4152         fail "looked for .dsc $dscpath, but $!;".
4153             " maybe you forgot to build";
4154
4155     responder_send_file('dsc', $dscpath);
4156
4157     push_parse_dsc($dscpath, $dscfn, $cversion);
4158
4159     my $format = getfield $dsc, 'Format';
4160     printdebug "format $format\n";
4161
4162     my $actualhead = git_rev_parse('HEAD');
4163     my $dgithead = $actualhead;
4164     my $maintviewhead = undef;
4165
4166     my $upstreamversion = upstreamversion $clogp->{Version};
4167
4168     if (madformat_wantfixup($format)) {
4169         # user might have not used dgit build, so maybe do this now:
4170         if (quiltmode_splitbrain()) {
4171             changedir $playground;
4172             quilt_make_fake_dsc($upstreamversion);
4173             my $cachekey;
4174             ($dgithead, $cachekey) =
4175                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4176             $dgithead or fail
4177  "--quilt=$quilt_mode but no cached dgit view:
4178  perhaps tree changed since dgit build[-source] ?";
4179             $split_brain = 1;
4180             $dgithead = splitbrain_pseudomerge($clogp,
4181                                                $actualhead, $dgithead,
4182                                                $archive_hash);
4183             $maintviewhead = $actualhead;
4184             changedir $maindir;
4185             prep_ud(); # so _only_subdir() works, below
4186         } else {
4187             commit_quilty_patch();
4188         }
4189     }
4190
4191     if (defined $overwrite_version && !defined $maintviewhead) {
4192         $dgithead = plain_overwrite_pseudomerge($clogp,
4193                                                 $dgithead,
4194                                                 $archive_hash);
4195     }
4196
4197     check_not_dirty();
4198
4199     my $forceflag = '';
4200     if ($archive_hash) {
4201         if (is_fast_fwd($archive_hash, $dgithead)) {
4202             # ok
4203         } elsif (deliberately_not_fast_forward) {
4204             $forceflag = '+';
4205         } else {
4206             fail "dgit push: HEAD is not a descendant".
4207                 " of the archive's version.\n".
4208                 "To overwrite the archive's contents,".
4209                 " pass --overwrite[=VERSION].\n".
4210                 "To rewind history, if permitted by the archive,".
4211                 " use --deliberately-not-fast-forward.";
4212         }
4213     }
4214
4215     changedir $playground;
4216     progress "checking that $dscfn corresponds to HEAD";
4217     runcmd qw(dpkg-source -x --),
4218         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4219     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4220     check_for_vendor_patches() if madformat($dsc->{format});
4221     changedir $maindir;
4222     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4223     debugcmd "+",@diffcmd;
4224     $!=0; $?=-1;
4225     my $r = system @diffcmd;
4226     if ($r) {
4227         if ($r==256) {
4228             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4229             fail <<END
4230 HEAD specifies a different tree to $dscfn:
4231 $diffs
4232 Perhaps you forgot to build.  Or perhaps there is a problem with your
4233  source tree (see dgit(7) for some hints).  To see a full diff, run
4234    git diff $tree HEAD
4235 END
4236         } else {
4237             failedcmd @diffcmd;
4238         }
4239     }
4240     if (!$changesfile) {
4241         my $pat = changespat $cversion;
4242         my @cs = glob "$buildproductsdir/$pat";
4243         fail "failed to find unique changes file".
4244             " (looked for $pat in $buildproductsdir);".
4245             " perhaps you need to use dgit -C"
4246             unless @cs==1;
4247         ($changesfile) = @cs;
4248     } else {
4249         $changesfile = "$buildproductsdir/$changesfile";
4250     }
4251
4252     # Check that changes and .dsc agree enough
4253     $changesfile =~ m{[^/]*$};
4254     my $changes = parsecontrol($changesfile,$&);
4255     files_compare_inputs($dsc, $changes)
4256         unless forceing [qw(dsc-changes-mismatch)];
4257
4258     # Perhaps adjust .dsc to contain right set of origs
4259     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4260                                   $changesfile)
4261         unless forceing [qw(changes-origs-exactly)];
4262
4263     # Checks complete, we're going to try and go ahead:
4264
4265     responder_send_file('changes',$changesfile);
4266     responder_send_command("param head $dgithead");
4267     responder_send_command("param csuite $csuite");
4268     responder_send_command("param isuite $isuite");
4269     responder_send_command("param tagformat $tagformat");
4270     if (defined $maintviewhead) {
4271         die unless ($protovsn//4) >= 4;
4272         responder_send_command("param maint-view $maintviewhead");
4273     }
4274
4275     # Perhaps send buildinfo(s) for signing
4276     my $changes_files = getfield $changes, 'Files';
4277     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4278     foreach my $bi (@buildinfos) {
4279         responder_send_command("param buildinfo-filename $bi");
4280         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4281     }
4282
4283     if (deliberately_not_fast_forward) {
4284         git_for_each_ref(lrfetchrefs, sub {
4285             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4286             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4287             responder_send_command("previously $rrefname=$objid");
4288             $previously{$rrefname} = $objid;
4289         });
4290     }
4291
4292     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4293                                  ".git/dgit/tag");
4294     my @tagobjfns;
4295
4296     supplementary_message(<<'END');
4297 Push failed, while signing the tag.
4298 You can retry the push, after fixing the problem, if you like.
4299 END
4300     # If we manage to sign but fail to record it anywhere, it's fine.
4301     if ($we_are_responder) {
4302         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4303         responder_receive_files('signed-tag', @tagobjfns);
4304     } else {
4305         @tagobjfns = push_mktags($clogp,$dscpath,
4306                               $changesfile,$changesfile,
4307                               \@tagwants);
4308     }
4309     supplementary_message(<<'END');
4310 Push failed, *after* signing the tag.
4311 If you want to try again, you should use a new version number.
4312 END
4313
4314     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4315
4316     foreach my $tw (@tagwants) {
4317         my $tag = $tw->{Tag};
4318         my $tagobjfn = $tw->{TagObjFn};
4319         my $tag_obj_hash =
4320             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4321         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4322         runcmd_ordryrun_local
4323             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4324     }
4325
4326     supplementary_message(<<'END');
4327 Push failed, while updating the remote git repository - see messages above.
4328 If you want to try again, you should use a new version number.
4329 END
4330     if (!check_for_git()) {
4331         create_remote_git_repo();
4332     }
4333
4334     my @pushrefs = $forceflag.$dgithead.":".rrref();
4335     foreach my $tw (@tagwants) {
4336         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4337     }
4338
4339     runcmd_ordryrun @git,
4340         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4341     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4342
4343     supplementary_message(<<'END');
4344 Push failed, while obtaining signatures on the .changes and .dsc.
4345 If it was just that the signature failed, you may try again by using
4346 debsign by hand to sign the changes
4347    $changesfile
4348 and then dput to complete the upload.
4349 If you need to change the package, you must use a new version number.
4350 END
4351     if ($we_are_responder) {
4352         my $dryrunsuffix = act_local() ? "" : ".tmp";
4353         my @rfiles = ($dscpath, $changesfile);
4354         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4355         responder_receive_files('signed-dsc-changes',
4356                                 map { "$_$dryrunsuffix" } @rfiles);
4357     } else {
4358         if (act_local()) {
4359             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4360         } else {
4361             progress "[new .dsc left in $dscpath.tmp]";
4362         }
4363         sign_changes $changesfile;
4364     }
4365
4366     supplementary_message(<<END);
4367 Push failed, while uploading package(s) to the archive server.
4368 You can retry the upload of exactly these same files with dput of:
4369   $changesfile
4370 If that .changes file is broken, you will need to use a new version
4371 number for your next attempt at the upload.
4372 END
4373     my $host = access_cfg('upload-host','RETURN-UNDEF');
4374     my @hostarg = defined($host) ? ($host,) : ();
4375     runcmd_ordryrun @dput, @hostarg, $changesfile;
4376     printdone "pushed and uploaded $cversion";
4377
4378     supplementary_message('');
4379     responder_send_command("complete");
4380 }
4381
4382 sub pre_clone () {
4383     not_necessarily_a_tree();
4384 }
4385 sub cmd_clone {
4386     parseopts();
4387     my $dstdir;
4388     badusage "-p is not allowed with clone; specify as argument instead"
4389         if defined $package;
4390     if (@ARGV==1) {
4391         ($package) = @ARGV;
4392     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4393         ($package,$isuite) = @ARGV;
4394     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4395         ($package,$dstdir) = @ARGV;
4396     } elsif (@ARGV==3) {
4397         ($package,$isuite,$dstdir) = @ARGV;
4398     } else {
4399         badusage "incorrect arguments to dgit clone";
4400     }
4401     notpushing();
4402
4403     $dstdir ||= "$package";
4404     if (stat_exists $dstdir) {
4405         fail "$dstdir already exists";
4406     }
4407
4408     my $cwd_remove;
4409     if ($rmonerror && !$dryrun_level) {
4410         $cwd_remove= getcwd();
4411         unshift @end, sub {
4412             return unless defined $cwd_remove;
4413             if (!chdir "$cwd_remove") {
4414                 return if $!==&ENOENT;
4415                 die "chdir $cwd_remove: $!";
4416             }
4417             printdebug "clone rmonerror removing $dstdir\n";
4418             if (stat $dstdir) {
4419                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4420             } elsif (grep { $! == $_ }
4421                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4422             } else {
4423                 print STDERR "check whether to remove $dstdir: $!\n";
4424             }
4425         };
4426     }
4427
4428     clone($dstdir);
4429     $cwd_remove = undef;
4430 }
4431
4432 sub branchsuite () {
4433     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4434     my $branch = cmdoutput_errok @cmd;
4435     if (!defined $branch) {
4436         $?==256 or failedcmd @cmd;
4437         return undef;
4438     }
4439     if ($branch =~ m#$lbranch_re#o) {
4440         return $1;
4441     } else {
4442         return undef;
4443     }
4444 }
4445
4446 sub fetchpullargs () {
4447     if (!defined $package) {
4448         my $sourcep = parsecontrol('debian/control','debian/control');
4449         $package = getfield $sourcep, 'Source';
4450     }
4451     if (@ARGV==0) {
4452         $isuite = branchsuite();
4453         if (!$isuite) {
4454             my $clogp = parsechangelog();
4455             my $clogsuite = getfield $clogp, 'Distribution';
4456             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4457         }
4458     } elsif (@ARGV==1) {
4459         ($isuite) = @ARGV;
4460     } else {
4461         badusage "incorrect arguments to dgit fetch or dgit pull";
4462     }
4463     notpushing();
4464 }
4465
4466 sub cmd_fetch {
4467     parseopts();
4468     fetchpullargs();
4469     my $multi_fetched = fork_for_multisuite(sub { });
4470     exit 0 if $multi_fetched;
4471     fetch();
4472 }
4473
4474 sub cmd_pull {
4475     parseopts();
4476     fetchpullargs();
4477     if (quiltmode_splitbrain()) {
4478         my ($format, $fopts) = get_source_format();
4479         madformat($format) and fail <<END
4480 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4481 END
4482     }
4483     pull();
4484 }
4485
4486 sub prep_push () {
4487     parseopts();
4488     build_or_push_prep_early();
4489     pushing();
4490     check_not_dirty();
4491     my $specsuite;
4492     if (@ARGV==0) {
4493     } elsif (@ARGV==1) {
4494         ($specsuite) = (@ARGV);
4495     } else {
4496         badusage "incorrect arguments to dgit $subcommand";
4497     }
4498     if ($new_package) {
4499         local ($package) = $existing_package; # this is a hack
4500         canonicalise_suite();
4501     } else {
4502         canonicalise_suite();
4503     }
4504     if (defined $specsuite &&
4505         $specsuite ne $isuite &&
4506         $specsuite ne $csuite) {
4507             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4508                 " but command line specifies $specsuite";
4509     }
4510 }
4511
4512 sub cmd_push {
4513     prep_push();
4514     dopush();
4515 }
4516
4517 #---------- remote commands' implementation ----------
4518
4519 sub pre_remote_push_build_host {
4520     my ($nrargs) = shift @ARGV;
4521     my (@rargs) = @ARGV[0..$nrargs-1];
4522     @ARGV = @ARGV[$nrargs..$#ARGV];
4523     die unless @rargs;
4524     my ($dir,$vsnwant) = @rargs;
4525     # vsnwant is a comma-separated list; we report which we have
4526     # chosen in our ready response (so other end can tell if they
4527     # offered several)
4528     $debugprefix = ' ';
4529     $we_are_responder = 1;
4530     $us .= " (build host)";
4531
4532     open PI, "<&STDIN" or die $!;
4533     open STDIN, "/dev/null" or die $!;
4534     open PO, ">&STDOUT" or die $!;
4535     autoflush PO 1;
4536     open STDOUT, ">&STDERR" or die $!;
4537     autoflush STDOUT 1;
4538
4539     $vsnwant //= 1;
4540     ($protovsn) = grep {
4541         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4542     } @rpushprotovsn_support;
4543
4544     fail "build host has dgit rpush protocol versions ".
4545         (join ",", @rpushprotovsn_support).
4546         " but invocation host has $vsnwant"
4547         unless defined $protovsn;
4548
4549     changedir $dir;
4550 }
4551 sub cmd_remote_push_build_host {
4552     responder_send_command("dgit-remote-push-ready $protovsn");
4553     &cmd_push;
4554 }
4555
4556 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4557 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4558 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4559 #     a good error message)
4560
4561 sub rpush_handle_protovsn_bothends () {
4562     if ($protovsn < 4) {
4563         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4564     }
4565     select_tagformat();
4566 }
4567
4568 our $i_tmp;
4569
4570 sub i_cleanup {
4571     local ($@, $?);
4572     my $report = i_child_report();
4573     if (defined $report) {
4574         printdebug "($report)\n";
4575     } elsif ($i_child_pid) {
4576         printdebug "(killing build host child $i_child_pid)\n";
4577         kill 15, $i_child_pid;
4578     }
4579     if (defined $i_tmp && !defined $initiator_tempdir) {
4580         changedir "/";
4581         eval { rmtree $i_tmp; };
4582     }
4583 }
4584
4585 END {
4586     return unless forkcheck_mainprocess();
4587     i_cleanup();
4588 }
4589
4590 sub i_method {
4591     my ($base,$selector,@args) = @_;
4592     $selector =~ s/\-/_/g;
4593     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4594 }
4595
4596 sub pre_rpush () {
4597     not_necessarily_a_tree();
4598 }
4599 sub cmd_rpush {
4600     my $host = nextarg;
4601     my $dir;
4602     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4603         $host = $1;
4604         $dir = $'; #';
4605     } else {
4606         $dir = nextarg;
4607     }
4608     $dir =~ s{^-}{./-};
4609     my @rargs = ($dir);
4610     push @rargs, join ",", @rpushprotovsn_support;
4611     my @rdgit;
4612     push @rdgit, @dgit;
4613     push @rdgit, @ropts;
4614     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4615     push @rdgit, @ARGV;
4616     my @cmd = (@ssh, $host, shellquote @rdgit);
4617     debugcmd "+",@cmd;
4618
4619     $we_are_initiator=1;
4620
4621     if (defined $initiator_tempdir) {
4622         rmtree $initiator_tempdir;
4623         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4624         $i_tmp = $initiator_tempdir;
4625     } else {
4626         $i_tmp = tempdir();
4627     }
4628     $i_child_pid = open2(\*RO, \*RI, @cmd);
4629     changedir $i_tmp;
4630     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4631     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4632     $supplementary_message = '' unless $protovsn >= 3;
4633
4634     for (;;) {
4635         my ($icmd,$iargs) = initiator_expect {
4636             m/^(\S+)(?: (.*))?$/;
4637             ($1,$2);
4638         };
4639         i_method "i_resp", $icmd, $iargs;
4640     }
4641 }
4642
4643 sub i_resp_progress ($) {
4644     my ($rhs) = @_;
4645     my $msg = protocol_read_bytes \*RO, $rhs;
4646     progress $msg;
4647 }
4648
4649 sub i_resp_supplementary_message ($) {
4650     my ($rhs) = @_;
4651     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4652 }
4653
4654 sub i_resp_complete {
4655     my $pid = $i_child_pid;
4656     $i_child_pid = undef; # prevents killing some other process with same pid
4657     printdebug "waiting for build host child $pid...\n";
4658     my $got = waitpid $pid, 0;
4659     die $! unless $got == $pid;
4660     die "build host child failed $?" if $?;
4661
4662     i_cleanup();
4663     printdebug "all done\n";
4664     exit 0;
4665 }
4666
4667 sub i_resp_file ($) {
4668     my ($keyword) = @_;
4669     my $localname = i_method "i_localname", $keyword;
4670     my $localpath = "$i_tmp/$localname";
4671     stat_exists $localpath and
4672         badproto \*RO, "file $keyword ($localpath) twice";
4673     protocol_receive_file \*RO, $localpath;
4674     i_method "i_file", $keyword;
4675 }
4676
4677 our %i_param;
4678
4679 sub i_resp_param ($) {
4680     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4681     $i_param{$1} = $2;
4682 }
4683
4684 sub i_resp_previously ($) {
4685     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4686         or badproto \*RO, "bad previously spec";
4687     my $r = system qw(git check-ref-format), $1;
4688     die "bad previously ref spec ($r)" if $r;
4689     $previously{$1} = $2;
4690 }
4691
4692 our %i_wanted;
4693
4694 sub i_resp_want ($) {
4695     my ($keyword) = @_;
4696     die "$keyword ?" if $i_wanted{$keyword}++;
4697
4698     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4699     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4700     die unless $isuite =~ m/^$suite_re$/;
4701
4702     pushing();
4703     rpush_handle_protovsn_bothends();
4704
4705     fail "rpush negotiated protocol version $protovsn".
4706         " which does not support quilt mode $quilt_mode"
4707         if quiltmode_splitbrain;
4708
4709     my @localpaths = i_method "i_want", $keyword;
4710     printdebug "[[  $keyword @localpaths\n";
4711     foreach my $localpath (@localpaths) {
4712         protocol_send_file \*RI, $localpath;
4713     }
4714     print RI "files-end\n" or die $!;
4715 }
4716
4717 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4718
4719 sub i_localname_parsed_changelog {
4720     return "remote-changelog.822";
4721 }
4722 sub i_file_parsed_changelog {
4723     ($i_clogp, $i_version, $i_dscfn) =
4724         push_parse_changelog "$i_tmp/remote-changelog.822";
4725     die if $i_dscfn =~ m#/|^\W#;
4726 }
4727
4728 sub i_localname_dsc {
4729     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4730     return $i_dscfn;
4731 }
4732 sub i_file_dsc { }
4733
4734 sub i_localname_buildinfo ($) {
4735     my $bi = $i_param{'buildinfo-filename'};
4736     defined $bi or badproto \*RO, "buildinfo before filename";
4737     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4738     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4739         or badproto \*RO, "improper buildinfo filename";
4740     return $&;
4741 }
4742 sub i_file_buildinfo {
4743     my $bi = $i_param{'buildinfo-filename'};
4744     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4745     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4746     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4747         files_compare_inputs($bd, $ch);
4748         (getfield $bd, $_) eq (getfield $ch, $_) or
4749             fail "buildinfo mismatch $_"
4750             foreach qw(Source Version);
4751         !defined $bd->{$_} or
4752             fail "buildinfo contains $_"
4753             foreach qw(Changes Changed-by Distribution);
4754     }
4755     push @i_buildinfos, $bi;
4756     delete $i_param{'buildinfo-filename'};
4757 }
4758
4759 sub i_localname_changes {
4760     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4761     $i_changesfn = $i_dscfn;
4762     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4763     return $i_changesfn;
4764 }
4765 sub i_file_changes { }
4766
4767 sub i_want_signed_tag {
4768     printdebug Dumper(\%i_param, $i_dscfn);
4769     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4770         && defined $i_param{'csuite'}
4771         or badproto \*RO, "premature desire for signed-tag";
4772     my $head = $i_param{'head'};
4773     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4774
4775     my $maintview = $i_param{'maint-view'};
4776     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4777
4778     select_tagformat();
4779     if ($protovsn >= 4) {
4780         my $p = $i_param{'tagformat'} // '<undef>';
4781         $p eq $tagformat
4782             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4783     }
4784
4785     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4786     $csuite = $&;
4787     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4788
4789     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4790
4791     return
4792         push_mktags $i_clogp, $i_dscfn,
4793             $i_changesfn, 'remote changes',
4794             \@tagwants;
4795 }
4796
4797 sub i_want_signed_dsc_changes {
4798     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4799     sign_changes $i_changesfn;
4800     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4801 }
4802
4803 #---------- building etc. ----------
4804
4805 our $version;
4806 our $sourcechanges;
4807 our $dscfn;
4808
4809 #----- `3.0 (quilt)' handling -----
4810
4811 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4812
4813 sub quiltify_dpkg_commit ($$$;$) {
4814     my ($patchname,$author,$msg, $xinfo) = @_;
4815     $xinfo //= '';
4816
4817     mkpath '.git/dgit';
4818     my $descfn = ".git/dgit/quilt-description.tmp";
4819     open O, '>', $descfn or die "$descfn: $!";
4820     $msg =~ s/\n+/\n\n/;
4821     print O <<END or die $!;
4822 From: $author
4823 ${xinfo}Subject: $msg
4824 ---
4825
4826 END
4827     close O or die $!;
4828
4829     {
4830         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4831         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4832         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4833         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4834     }
4835 }
4836
4837 sub quiltify_trees_differ ($$;$$$) {
4838     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4839     # returns true iff the two tree objects differ other than in debian/
4840     # with $finegrained,
4841     # returns bitmask 01 - differ in upstream files except .gitignore
4842     #                 02 - differ in .gitignore
4843     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4844     #  is set for each modified .gitignore filename $fn
4845     # if $unrepres is defined, array ref to which is appeneded
4846     #  a list of unrepresentable changes (removals of upstream files
4847     #  (as messages)
4848     local $/=undef;
4849     my @cmd = (@git, qw(diff-tree -z --no-renames));
4850     push @cmd, qw(--name-only) unless $unrepres;
4851     push @cmd, qw(-r) if $finegrained || $unrepres;
4852     push @cmd, $x, $y;
4853     my $diffs= cmdoutput @cmd;
4854     my $r = 0;
4855     my @lmodes;
4856     foreach my $f (split /\0/, $diffs) {
4857         if ($unrepres && !@lmodes) {
4858             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4859             next;
4860         }
4861         my ($oldmode,$newmode) = @lmodes;
4862         @lmodes = ();
4863
4864         next if $f =~ m#^debian(?:/.*)?$#s;
4865
4866         if ($unrepres) {
4867             eval {
4868                 die "not a plain file or symlink\n"
4869                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
4870                            $oldmode =~ m/^(?:10|12)\d{4}$/;
4871                 if ($oldmode =~ m/[^0]/ &&
4872                     $newmode =~ m/[^0]/) {
4873                     # both old and new files exist
4874                     die "mode or type changed\n" if $oldmode ne $newmode;
4875                     die "modified symlink\n" unless $newmode =~ m/^10/;
4876                 } elsif ($oldmode =~ m/[^0]/) {
4877                     # deletion
4878                     die "deletion of symlink\n"
4879                         unless $oldmode =~ m/^10/;
4880                 } else {
4881                     # creation
4882                     die "creation with non-default mode\n"
4883                         unless $newmode =~ m/^100644$/ or
4884                                $newmode =~ m/^120000$/;
4885                 }
4886             };
4887             if ($@) {
4888                 local $/="\n"; chomp $@;
4889                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4890             }
4891         }
4892
4893         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4894         $r |= $isignore ? 02 : 01;
4895         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4896     }
4897     printdebug "quiltify_trees_differ $x $y => $r\n";
4898     return $r;
4899 }
4900
4901 sub quiltify_tree_sentinelfiles ($) {
4902     # lists the `sentinel' files present in the tree
4903     my ($x) = @_;
4904     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4905         qw(-- debian/rules debian/control);
4906     $r =~ s/\n/,/g;
4907     return $r;
4908 }
4909
4910 sub quiltify_splitbrain_needed () {
4911     if (!$split_brain) {
4912         progress "dgit view: changes are required...";
4913         runcmd @git, qw(checkout -q -b dgit-view);
4914         $split_brain = 1;
4915     }
4916 }
4917
4918 sub quiltify_splitbrain ($$$$$$) {
4919     my ($clogp, $unapplied, $headref, $diffbits,
4920         $editedignores, $cachekey) = @_;
4921     if ($quilt_mode !~ m/gbp|dpm/) {
4922         # treat .gitignore just like any other upstream file
4923         $diffbits = { %$diffbits };
4924         $_ = !!$_ foreach values %$diffbits;
4925     }
4926     # We would like any commits we generate to be reproducible
4927     my @authline = clogp_authline($clogp);
4928     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4929     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4930     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4931     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4932     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4933     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4934
4935     if ($quilt_mode =~ m/gbp|unapplied/ &&
4936         ($diffbits->{O2H} & 01)) {
4937         my $msg =
4938  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4939  " but git tree differs from orig in upstream files.";
4940         if (!stat_exists "debian/patches") {
4941             $msg .=
4942  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4943         }
4944         fail $msg;
4945     }
4946     if ($quilt_mode =~ m/dpm/ &&
4947         ($diffbits->{H2A} & 01)) {
4948         fail <<END;
4949 --quilt=$quilt_mode specified, implying patches-applied git tree
4950  but git tree differs from result of applying debian/patches to upstream
4951 END
4952     }
4953     if ($quilt_mode =~ m/gbp|unapplied/ &&
4954         ($diffbits->{O2A} & 01)) { # some patches
4955         quiltify_splitbrain_needed();
4956         progress "dgit view: creating patches-applied version using gbp pq";
4957         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4958         # gbp pq import creates a fresh branch; push back to dgit-view
4959         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4960         runcmd @git, qw(checkout -q dgit-view);
4961     }
4962     if ($quilt_mode =~ m/gbp|dpm/ &&
4963         ($diffbits->{O2A} & 02)) {
4964         fail <<END
4965 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4966  tool which does not create patches for changes to upstream
4967  .gitignores: but, such patches exist in debian/patches.
4968 END
4969     }
4970     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4971         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4972         quiltify_splitbrain_needed();
4973         progress "dgit view: creating patch to represent .gitignore changes";
4974         ensuredir "debian/patches";
4975         my $gipatch = "debian/patches/auto-gitignore";
4976         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4977         stat GIPATCH or die "$gipatch: $!";
4978         fail "$gipatch already exists; but want to create it".
4979             " to record .gitignore changes" if (stat _)[7];
4980         print GIPATCH <<END or die "$gipatch: $!";
4981 Subject: Update .gitignore from Debian packaging branch
4982
4983 The Debian packaging git branch contains these updates to the upstream
4984 .gitignore file(s).  This patch is autogenerated, to provide these
4985 updates to users of the official Debian archive view of the package.
4986
4987 [dgit ($our_version) update-gitignore]
4988 ---
4989 END
4990         close GIPATCH or die "$gipatch: $!";
4991         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4992             $unapplied, $headref, "--", sort keys %$editedignores;
4993         open SERIES, "+>>", "debian/patches/series" or die $!;
4994         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4995         my $newline;
4996         defined read SERIES, $newline, 1 or die $!;
4997         print SERIES "\n" or die $! unless $newline eq "\n";
4998         print SERIES "auto-gitignore\n" or die $!;
4999         close SERIES or die  $!;
5000         runcmd @git, qw(add -- debian/patches/series), $gipatch;
5001         commit_admin <<END
5002 Commit patch to update .gitignore
5003
5004 [dgit ($our_version) update-gitignore-quilt-fixup]
5005 END
5006     }
5007
5008     my $dgitview = git_rev_parse 'HEAD';
5009
5010     changedir $maindir;
5011     # When we no longer need to support squeeze, use --create-reflog
5012     # instead of this:
5013     ensuredir ".git/logs/refs/dgit-intern";
5014     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
5015       or die $!;
5016
5017     my $oldcache = git_get_ref "refs/$splitbraincache";
5018     if ($oldcache eq $dgitview) {
5019         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5020         # git update-ref doesn't always update, in this case.  *sigh*
5021         my $dummy = make_commit_text <<END;
5022 tree $tree
5023 parent $dgitview
5024 author Dgit <dgit\@example.com> 1000000000 +0000
5025 committer Dgit <dgit\@example.com> 1000000000 +0000
5026
5027 Dummy commit - do not use
5028 END
5029         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5030             "refs/$splitbraincache", $dummy;
5031     }
5032     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5033         $dgitview;
5034
5035     changedir "$playground/work";
5036
5037     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5038     progress "dgit view: created ($saved)";
5039 }
5040
5041 sub quiltify ($$$$) {
5042     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5043
5044     # Quilt patchification algorithm
5045     #
5046     # We search backwards through the history of the main tree's HEAD
5047     # (T) looking for a start commit S whose tree object is identical
5048     # to to the patch tip tree (ie the tree corresponding to the
5049     # current dpkg-committed patch series).  For these purposes
5050     # `identical' disregards anything in debian/ - this wrinkle is
5051     # necessary because dpkg-source treates debian/ specially.
5052     #
5053     # We can only traverse edges where at most one of the ancestors'
5054     # trees differs (in changes outside in debian/).  And we cannot
5055     # handle edges which change .pc/ or debian/patches.  To avoid
5056     # going down a rathole we avoid traversing edges which introduce
5057     # debian/rules or debian/control.  And we set a limit on the
5058     # number of edges we are willing to look at.
5059     #
5060     # If we succeed, we walk forwards again.  For each traversed edge
5061     # PC (with P parent, C child) (starting with P=S and ending with
5062     # C=T) to we do this:
5063     #  - git checkout C
5064     #  - dpkg-source --commit with a patch name and message derived from C
5065     # After traversing PT, we git commit the changes which
5066     # should be contained within debian/patches.
5067
5068     # The search for the path S..T is breadth-first.  We maintain a
5069     # todo list containing search nodes.  A search node identifies a
5070     # commit, and looks something like this:
5071     #  $p = {
5072     #      Commit => $git_commit_id,
5073     #      Child => $c,                          # or undef if P=T
5074     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5075     #      Nontrivial => true iff $p..$c has relevant changes
5076     #  };
5077
5078     my @todo;
5079     my @nots;
5080     my $sref_S;
5081     my $max_work=100;
5082     my %considered; # saves being exponential on some weird graphs
5083
5084     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5085
5086     my $not = sub {
5087         my ($search,$whynot) = @_;
5088         printdebug " search NOT $search->{Commit} $whynot\n";
5089         $search->{Whynot} = $whynot;
5090         push @nots, $search;
5091         no warnings qw(exiting);
5092         next;
5093     };
5094
5095     push @todo, {
5096         Commit => $target,
5097     };
5098
5099     while (@todo) {
5100         my $c = shift @todo;
5101         next if $considered{$c->{Commit}}++;
5102
5103         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5104
5105         printdebug "quiltify investigate $c->{Commit}\n";
5106
5107         # are we done?
5108         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5109             printdebug " search finished hooray!\n";
5110             $sref_S = $c;
5111             last;
5112         }
5113
5114         if ($quilt_mode eq 'nofix') {
5115             fail "quilt fixup required but quilt mode is \`nofix'\n".
5116                 "HEAD commit $c->{Commit} differs from tree implied by ".
5117                 " debian/patches (tree object $oldtiptree)";
5118         }
5119         if ($quilt_mode eq 'smash') {
5120             printdebug " search quitting smash\n";
5121             last;
5122         }
5123
5124         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5125         $not->($c, "has $c_sentinels not $t_sentinels")
5126             if $c_sentinels ne $t_sentinels;
5127
5128         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5129         $commitdata =~ m/\n\n/;
5130         $commitdata =~ $`;
5131         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5132         @parents = map { { Commit => $_, Child => $c } } @parents;
5133
5134         $not->($c, "root commit") if !@parents;
5135
5136         foreach my $p (@parents) {
5137             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5138         }
5139         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5140         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5141
5142         foreach my $p (@parents) {
5143             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5144
5145             my @cmd= (@git, qw(diff-tree -r --name-only),
5146                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5147             my $patchstackchange = cmdoutput @cmd;
5148             if (length $patchstackchange) {
5149                 $patchstackchange =~ s/\n/,/g;
5150                 $not->($p, "changed $patchstackchange");
5151             }
5152
5153             printdebug " search queue P=$p->{Commit} ",
5154                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5155             push @todo, $p;
5156         }
5157     }
5158
5159     if (!$sref_S) {
5160         printdebug "quiltify want to smash\n";
5161
5162         my $abbrev = sub {
5163             my $x = $_[0]{Commit};
5164             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5165             return $x;
5166         };
5167         my $reportnot = sub {
5168             my ($notp) = @_;
5169             my $s = $abbrev->($notp);
5170             my $c = $notp->{Child};
5171             $s .= "..".$abbrev->($c) if $c;
5172             $s .= ": ".$notp->{Whynot};
5173             return $s;
5174         };
5175         if ($quilt_mode eq 'linear') {
5176             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5177             foreach my $notp (@nots) {
5178                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5179             }
5180             print STDERR "$us: $_\n" foreach @$failsuggestion;
5181             fail "quilt fixup naive history linearisation failed.\n".
5182  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5183         } elsif ($quilt_mode eq 'smash') {
5184         } elsif ($quilt_mode eq 'auto') {
5185             progress "quilt fixup cannot be linear, smashing...";
5186         } else {
5187             die "$quilt_mode ?";
5188         }
5189
5190         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5191         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5192         my $ncommits = 3;
5193         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5194
5195         quiltify_dpkg_commit "auto-$version-$target-$time",
5196             (getfield $clogp, 'Maintainer'),
5197             "Automatically generated patch ($clogp->{Version})\n".
5198             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5199         return;
5200     }
5201
5202     progress "quiltify linearisation planning successful, executing...";
5203
5204     for (my $p = $sref_S;
5205          my $c = $p->{Child};
5206          $p = $p->{Child}) {
5207         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5208         next unless $p->{Nontrivial};
5209
5210         my $cc = $c->{Commit};
5211
5212         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5213         $commitdata =~ m/\n\n/ or die "$c ?";
5214         $commitdata = $`;
5215         my $msg = $'; #';
5216         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5217         my $author = $1;
5218
5219         my $commitdate = cmdoutput
5220             @git, qw(log -n1 --pretty=format:%aD), $cc;
5221
5222         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5223
5224         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5225         $strip_nls->();
5226
5227         my $title = $1;
5228         my $patchname;
5229         my $patchdir;
5230
5231         my $gbp_check_suitable = sub {
5232             $_ = shift;
5233             my ($what) = @_;
5234
5235             eval {
5236                 die "contains unexpected slashes\n" if m{//} || m{/$};
5237                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5238                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5239                 die "is series file\n" if m{$series_filename_re}o;
5240                 die "too long" if length > 200;
5241             };
5242             return $_ unless $@;
5243             print STDERR "quiltifying commit $cc:".
5244                 " ignoring/dropping Gbp-Pq $what: $@";
5245             return undef;
5246         };
5247
5248         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5249                            gbp-pq-name: \s* )
5250                        (\S+) \s* \n //ixm) {
5251             $patchname = $gbp_check_suitable->($1, 'Name');
5252         }
5253         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5254                            gbp-pq-topic: \s* )
5255                        (\S+) \s* \n //ixm) {
5256             $patchdir = $gbp_check_suitable->($1, 'Topic');
5257         }
5258
5259         $strip_nls->();
5260
5261         if (!defined $patchname) {
5262             $patchname = $title;
5263             $patchname =~ s/[.:]$//;
5264             use Text::Iconv;
5265             eval {
5266                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5267                 my $translitname = $converter->convert($patchname);
5268                 die unless defined $translitname;
5269                 $patchname = $translitname;
5270             };
5271             print STDERR
5272                 "dgit: patch title transliteration error: $@"
5273                 if $@;
5274             $patchname =~ y/ A-Z/-a-z/;
5275             $patchname =~ y/-a-z0-9_.+=~//cd;
5276             $patchname =~ s/^\W/x-$&/;
5277             $patchname = substr($patchname,0,40);
5278             $patchname .= ".patch";
5279         }
5280         if (!defined $patchdir) {
5281             $patchdir = '';
5282         }
5283         if (length $patchdir) {
5284             $patchname = "$patchdir/$patchname";
5285         }
5286         if ($patchname =~ m{^(.*)/}) {
5287             mkpath "debian/patches/$1";
5288         }
5289
5290         my $index;
5291         for ($index='';
5292              stat "debian/patches/$patchname$index";
5293              $index++) { }
5294         $!==ENOENT or die "$patchname$index $!";
5295
5296         runcmd @git, qw(checkout -q), $cc;
5297
5298         # We use the tip's changelog so that dpkg-source doesn't
5299         # produce complaining messages from dpkg-parsechangelog.  None
5300         # of the information dpkg-source gets from the changelog is
5301         # actually relevant - it gets put into the original message
5302         # which dpkg-source provides our stunt editor, and then
5303         # overwritten.
5304         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5305
5306         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5307             "Date: $commitdate\n".
5308             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5309
5310         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5311     }
5312
5313     runcmd @git, qw(checkout -q master);
5314 }
5315
5316 sub build_maybe_quilt_fixup () {
5317     my ($format,$fopts) = get_source_format;
5318     return unless madformat_wantfixup $format;
5319     # sigh
5320
5321     check_for_vendor_patches();
5322
5323     if (quiltmode_splitbrain) {
5324         fail <<END unless access_cfg_tagformats_can_splitbrain;
5325 quilt mode $quilt_mode requires split view so server needs to support
5326  both "new" and "maint" tag formats, but config says it doesn't.
5327 END
5328     }
5329
5330     my $clogp = parsechangelog();
5331     my $headref = git_rev_parse('HEAD');
5332
5333     prep_ud();
5334     changedir $playground;
5335
5336     my $upstreamversion = upstreamversion $version;
5337
5338     if ($fopts->{'single-debian-patch'}) {
5339         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5340     } else {
5341         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5342     }
5343
5344     die 'bug' if $split_brain && !$need_split_build_invocation;
5345
5346     changedir $maindir;
5347     runcmd_ordryrun_local
5348         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5349 }
5350
5351 sub quilt_fixup_mkwork ($) {
5352     my ($headref) = @_;
5353
5354     mkdir "work" or die $!;
5355     changedir "work";
5356     mktree_in_ud_here();
5357     runcmd @git, qw(reset -q --hard), $headref;
5358 }
5359
5360 sub quilt_fixup_linkorigs ($$) {
5361     my ($upstreamversion, $fn) = @_;
5362     # calls $fn->($leafname);
5363
5364     foreach my $f (<../../../../*>) { #/){
5365         my $b=$f; $b =~ s{.*/}{};
5366         {
5367             local ($debuglevel) = $debuglevel-1;
5368             printdebug "QF linkorigs $b, $f ?\n";
5369         }
5370         next unless is_orig_file_of_vsn $b, $upstreamversion;
5371         printdebug "QF linkorigs $b, $f Y\n";
5372         link_ltarget $f, $b or die "$b $!";
5373         $fn->($b);
5374     }
5375 }
5376
5377 sub quilt_fixup_delete_pc () {
5378     runcmd @git, qw(rm -rqf .pc);
5379     commit_admin <<END
5380 Commit removal of .pc (quilt series tracking data)
5381
5382 [dgit ($our_version) upgrade quilt-remove-pc]
5383 END
5384 }
5385
5386 sub quilt_fixup_singlepatch ($$$) {
5387     my ($clogp, $headref, $upstreamversion) = @_;
5388
5389     progress "starting quiltify (single-debian-patch)";
5390
5391     # dpkg-source --commit generates new patches even if
5392     # single-debian-patch is in debian/source/options.  In order to
5393     # get it to generate debian/patches/debian-changes, it is
5394     # necessary to build the source package.
5395
5396     quilt_fixup_linkorigs($upstreamversion, sub { });
5397     quilt_fixup_mkwork($headref);
5398
5399     rmtree("debian/patches");
5400
5401     runcmd @dpkgsource, qw(-b .);
5402     changedir "..";
5403     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5404     rename srcfn("$upstreamversion", "/debian/patches"),
5405            "work/debian/patches";
5406
5407     changedir "work";
5408     commit_quilty_patch();
5409 }
5410
5411 sub quilt_make_fake_dsc ($) {
5412     my ($upstreamversion) = @_;
5413
5414     my $fakeversion="$upstreamversion-~~DGITFAKE";
5415
5416     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5417     print $fakedsc <<END or die $!;
5418 Format: 3.0 (quilt)
5419 Source: $package
5420 Version: $fakeversion
5421 Files:
5422 END
5423
5424     my $dscaddfile=sub {
5425         my ($b) = @_;
5426
5427         my $md = new Digest::MD5;
5428
5429         my $fh = new IO::File $b, '<' or die "$b $!";
5430         stat $fh or die $!;
5431         my $size = -s _;
5432
5433         $md->addfile($fh);
5434         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5435     };
5436
5437     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5438
5439     my @files=qw(debian/source/format debian/rules
5440                  debian/control debian/changelog);
5441     foreach my $maybe (qw(debian/patches debian/source/options
5442                           debian/tests/control)) {
5443         next unless stat_exists "../../../$maybe";
5444         push @files, $maybe;
5445     }
5446
5447     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5448     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5449
5450     $dscaddfile->($debtar);
5451     close $fakedsc or die $!;
5452 }
5453
5454 sub quilt_check_splitbrain_cache ($$) {
5455     my ($headref, $upstreamversion) = @_;
5456     # Called only if we are in (potentially) split brain mode.
5457     # Called in playground.
5458     # Computes the cache key and looks in the cache.
5459     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5460
5461     my $splitbrain_cachekey;
5462
5463     progress
5464  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5465     # we look in the reflog of dgit-intern/quilt-cache
5466     # we look for an entry whose message is the key for the cache lookup
5467     my @cachekey = (qw(dgit), $our_version);
5468     push @cachekey, $upstreamversion;
5469     push @cachekey, $quilt_mode;
5470     push @cachekey, $headref;
5471
5472     push @cachekey, hashfile('fake.dsc');
5473
5474     my $srcshash = Digest::SHA->new(256);
5475     my %sfs = ( %INC, '$0(dgit)' => $0 );
5476     foreach my $sfk (sort keys %sfs) {
5477         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5478         $srcshash->add($sfk,"  ");
5479         $srcshash->add(hashfile($sfs{$sfk}));
5480         $srcshash->add("\n");
5481     }
5482     push @cachekey, $srcshash->hexdigest();
5483     $splitbrain_cachekey = "@cachekey";
5484
5485     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5486                $splitbraincache);
5487     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5488     debugcmd "|(probably)",@cmd;
5489     my $child = open GC, "-|";  defined $child or die $!;
5490     if (!$child) {
5491         chdir '../../..' or die $!;
5492         if (!stat ".git/logs/refs/$splitbraincache") {
5493             $! == ENOENT or die $!;
5494             printdebug ">(no reflog)\n";
5495             exit 0;
5496         }
5497         exec @cmd; die $!;
5498     }
5499     while (<GC>) {
5500         chomp;
5501         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5502         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5503
5504         my $cachehit = $1;
5505         quilt_fixup_mkwork($headref);
5506         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5507         if ($cachehit ne $headref) {
5508             progress "dgit view: found cached ($saved)";
5509             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5510             $split_brain = 1;
5511             return ($cachehit, $splitbrain_cachekey);
5512         }
5513         progress "dgit view: found cached, no changes required";
5514         return ($headref, $splitbrain_cachekey);
5515     }
5516     die $! if GC->error;
5517     failedcmd unless close GC;
5518
5519     printdebug "splitbrain cache miss\n";
5520     return (undef, $splitbrain_cachekey);
5521 }
5522
5523 sub quilt_fixup_multipatch ($$$) {
5524     my ($clogp, $headref, $upstreamversion) = @_;
5525
5526     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5527
5528     # Our objective is:
5529     #  - honour any existing .pc in case it has any strangeness
5530     #  - determine the git commit corresponding to the tip of
5531     #    the patch stack (if there is one)
5532     #  - if there is such a git commit, convert each subsequent
5533     #    git commit into a quilt patch with dpkg-source --commit
5534     #  - otherwise convert all the differences in the tree into
5535     #    a single git commit
5536     #
5537     # To do this we:
5538
5539     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5540     # dgit would include the .pc in the git tree.)  If there isn't
5541     # one, we need to generate one by unpacking the patches that we
5542     # have.
5543     #
5544     # We first look for a .pc in the git tree.  If there is one, we
5545     # will use it.  (This is not the normal case.)
5546     #
5547     # Otherwise need to regenerate .pc so that dpkg-source --commit
5548     # can work.  We do this as follows:
5549     #     1. Collect all relevant .orig from parent directory
5550     #     2. Generate a debian.tar.gz out of
5551     #         debian/{patches,rules,source/format,source/options}
5552     #     3. Generate a fake .dsc containing just these fields:
5553     #          Format Source Version Files
5554     #     4. Extract the fake .dsc
5555     #        Now the fake .dsc has a .pc directory.
5556     # (In fact we do this in every case, because in future we will
5557     # want to search for a good base commit for generating patches.)
5558     #
5559     # Then we can actually do the dpkg-source --commit
5560     #     1. Make a new working tree with the same object
5561     #        store as our main tree and check out the main
5562     #        tree's HEAD.
5563     #     2. Copy .pc from the fake's extraction, if necessary
5564     #     3. Run dpkg-source --commit
5565     #     4. If the result has changes to debian/, then
5566     #          - git add them them
5567     #          - git add .pc if we had a .pc in-tree
5568     #          - git commit
5569     #     5. If we had a .pc in-tree, delete it, and git commit
5570     #     6. Back in the main tree, fast forward to the new HEAD
5571
5572     # Another situation we may have to cope with is gbp-style
5573     # patches-unapplied trees.
5574     #
5575     # We would want to detect these, so we know to escape into
5576     # quilt_fixup_gbp.  However, this is in general not possible.
5577     # Consider a package with a one patch which the dgit user reverts
5578     # (with git revert or the moral equivalent).
5579     #
5580     # That is indistinguishable in contents from a patches-unapplied
5581     # tree.  And looking at the history to distinguish them is not
5582     # useful because the user might have made a confusing-looking git
5583     # history structure (which ought to produce an error if dgit can't
5584     # cope, not a silent reintroduction of an unwanted patch).
5585     #
5586     # So gbp users will have to pass an option.  But we can usually
5587     # detect their failure to do so: if the tree is not a clean
5588     # patches-applied tree, quilt linearisation fails, but the tree
5589     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5590     # they want --quilt=unapplied.
5591     #
5592     # To help detect this, when we are extracting the fake dsc, we
5593     # first extract it with --skip-patches, and then apply the patches
5594     # afterwards with dpkg-source --before-build.  That lets us save a
5595     # tree object corresponding to .origs.
5596
5597     my $splitbrain_cachekey;
5598
5599     quilt_make_fake_dsc($upstreamversion);
5600
5601     if (quiltmode_splitbrain()) {
5602         my $cachehit;
5603         ($cachehit, $splitbrain_cachekey) =
5604             quilt_check_splitbrain_cache($headref, $upstreamversion);
5605         return if $cachehit;
5606     }
5607
5608     runcmd qw(sh -ec),
5609         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5610
5611     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5612     rename $fakexdir, "fake" or die "$fakexdir $!";
5613
5614     changedir 'fake';
5615
5616     remove_stray_gits("source package");
5617     mktree_in_ud_here();
5618
5619     rmtree '.pc';
5620
5621     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5622     my $unapplied=git_add_write_tree();
5623     printdebug "fake orig tree object $unapplied\n";
5624
5625     ensuredir '.pc';
5626
5627     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5628     $!=0; $?=-1;
5629     if (system @bbcmd) {
5630         failedcmd @bbcmd if $? < 0;
5631         fail <<END;
5632 failed to apply your git tree's patch stack (from debian/patches/) to
5633  the corresponding upstream tarball(s).  Your source tree and .orig
5634  are probably too inconsistent.  dgit can only fix up certain kinds of
5635  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5636 END
5637     }
5638
5639     changedir '..';
5640
5641     quilt_fixup_mkwork($headref);
5642
5643     my $mustdeletepc=0;
5644     if (stat_exists ".pc") {
5645         -d _ or die;
5646         progress "Tree already contains .pc - will use it then delete it.";
5647         $mustdeletepc=1;
5648     } else {
5649         rename '../fake/.pc','.pc' or die $!;
5650     }
5651
5652     changedir '../fake';
5653     rmtree '.pc';
5654     my $oldtiptree=git_add_write_tree();
5655     printdebug "fake o+d/p tree object $unapplied\n";
5656     changedir '../work';
5657
5658
5659     # We calculate some guesswork now about what kind of tree this might
5660     # be.  This is mostly for error reporting.
5661
5662     my %editedignores;
5663     my @unrepres;
5664     my $diffbits = {
5665         # H = user's HEAD
5666         # O = orig, without patches applied
5667         # A = "applied", ie orig with H's debian/patches applied
5668         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5669                                      \%editedignores, \@unrepres),
5670         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5671         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5672     };
5673
5674     my @dl;
5675     foreach my $b (qw(01 02)) {
5676         foreach my $v (qw(O2H O2A H2A)) {
5677             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5678         }
5679     }
5680     printdebug "differences \@dl @dl.\n";
5681
5682     progress sprintf
5683 "$us: base trees orig=%.20s o+d/p=%.20s",
5684               $unapplied, $oldtiptree;
5685     progress sprintf
5686 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5687 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5688                              $dl[0], $dl[1],              $dl[3], $dl[4],
5689                                  $dl[2],                     $dl[5];
5690
5691     if (@unrepres) {
5692         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5693             foreach @unrepres;
5694         forceable_fail [qw(unrepresentable)], <<END;
5695 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5696 END
5697     }
5698
5699     my @failsuggestion;
5700     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5701         push @failsuggestion, "This might be a patches-unapplied branch.";
5702     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5703         push @failsuggestion, "This might be a patches-applied branch.";
5704     }
5705     push @failsuggestion, "Maybe you need to specify one of".
5706         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5707
5708     if (quiltmode_splitbrain()) {
5709         quiltify_splitbrain($clogp, $unapplied, $headref,
5710                             $diffbits, \%editedignores,
5711                             $splitbrain_cachekey);
5712         return;
5713     }
5714
5715     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5716     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5717
5718     if (!open P, '>>', ".pc/applied-patches") {
5719         $!==&ENOENT or die $!;
5720     } else {
5721         close P;
5722     }
5723
5724     commit_quilty_patch();
5725
5726     if ($mustdeletepc) {
5727         quilt_fixup_delete_pc();
5728     }
5729 }
5730
5731 sub quilt_fixup_editor () {
5732     my $descfn = $ENV{$fakeeditorenv};
5733     my $editing = $ARGV[$#ARGV];
5734     open I1, '<', $descfn or die "$descfn: $!";
5735     open I2, '<', $editing or die "$editing: $!";
5736     unlink $editing or die "$editing: $!";
5737     open O, '>', $editing or die "$editing: $!";
5738     while (<I1>) { print O or die $!; } I1->error and die $!;
5739     my $copying = 0;
5740     while (<I2>) {
5741         $copying ||= m/^\-\-\- /;
5742         next unless $copying;
5743         print O or die $!;
5744     }
5745     I2->error and die $!;
5746     close O or die $1;
5747     exit 0;
5748 }
5749
5750 sub maybe_apply_patches_dirtily () {
5751     return unless $quilt_mode =~ m/gbp|unapplied/;
5752     print STDERR <<END or die $!;
5753
5754 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5755 dgit: Have to apply the patches - making the tree dirty.
5756 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5757
5758 END
5759     $patches_applied_dirtily = 01;
5760     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5761     runcmd qw(dpkg-source --before-build .);
5762 }
5763
5764 sub maybe_unapply_patches_again () {
5765     progress "dgit: Unapplying patches again to tidy up the tree."
5766         if $patches_applied_dirtily;
5767     runcmd qw(dpkg-source --after-build .)
5768         if $patches_applied_dirtily & 01;
5769     rmtree '.pc'
5770         if $patches_applied_dirtily & 02;
5771     $patches_applied_dirtily = 0;
5772 }
5773
5774 #----- other building -----
5775
5776 our $clean_using_builder;
5777 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5778 #   clean the tree before building (perhaps invoked indirectly by
5779 #   whatever we are using to run the build), rather than separately
5780 #   and explicitly by us.
5781
5782 sub clean_tree () {
5783     return if $clean_using_builder;
5784     if ($cleanmode eq 'dpkg-source') {
5785         maybe_apply_patches_dirtily();
5786         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5787     } elsif ($cleanmode eq 'dpkg-source-d') {
5788         maybe_apply_patches_dirtily();
5789         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5790     } elsif ($cleanmode eq 'git') {
5791         runcmd_ordryrun_local @git, qw(clean -xdf);
5792     } elsif ($cleanmode eq 'git-ff') {
5793         runcmd_ordryrun_local @git, qw(clean -xdff);
5794     } elsif ($cleanmode eq 'check') {
5795         my $leftovers = cmdoutput @git, qw(clean -xdn);
5796         if (length $leftovers) {
5797             print STDERR $leftovers, "\n" or die $!;
5798             fail "tree contains uncommitted files and --clean=check specified";
5799         }
5800     } elsif ($cleanmode eq 'none') {
5801     } else {
5802         die "$cleanmode ?";
5803     }
5804 }
5805
5806 sub cmd_clean () {
5807     badusage "clean takes no additional arguments" if @ARGV;
5808     notpushing();
5809     clean_tree();
5810     maybe_unapply_patches_again();
5811 }
5812
5813 sub build_or_push_prep_early () {
5814     our $build_or_push_prep_early_done //= 0;
5815     return if $build_or_push_prep_early_done++;
5816     badusage "-p is not allowed with dgit $subcommand" if defined $package;
5817     my $clogp = parsechangelog();
5818     $isuite = getfield $clogp, 'Distribution';
5819     $package = getfield $clogp, 'Source';
5820     $version = getfield $clogp, 'Version';
5821 }
5822
5823 sub build_prep_early () {
5824     build_or_push_prep_early();
5825     notpushing();
5826     check_not_dirty();
5827 }
5828
5829 sub build_prep () {
5830     build_prep_early();
5831     clean_tree();
5832     build_maybe_quilt_fixup();
5833     if ($rmchanges) {
5834         my $pat = changespat $version;
5835         foreach my $f (glob "$buildproductsdir/$pat") {
5836             if (act_local()) {
5837                 unlink $f or fail "remove old changes file $f: $!";
5838             } else {
5839                 progress "would remove $f";
5840             }
5841         }
5842     }
5843 }
5844
5845 sub changesopts_initial () {
5846     my @opts =@changesopts[1..$#changesopts];
5847 }
5848
5849 sub changesopts_version () {
5850     if (!defined $changes_since_version) {
5851         my @vsns = archive_query('archive_query');
5852         my @quirk = access_quirk();
5853         if ($quirk[0] eq 'backports') {
5854             local $isuite = $quirk[2];
5855             local $csuite;
5856             canonicalise_suite();
5857             push @vsns, archive_query('archive_query');
5858         }
5859         if (@vsns) {
5860             @vsns = map { $_->[0] } @vsns;
5861             @vsns = sort { -version_compare($a, $b) } @vsns;
5862             $changes_since_version = $vsns[0];
5863             progress "changelog will contain changes since $vsns[0]";
5864         } else {
5865             $changes_since_version = '_';
5866             progress "package seems new, not specifying -v<version>";
5867         }
5868     }
5869     if ($changes_since_version ne '_') {
5870         return ("-v$changes_since_version");
5871     } else {
5872         return ();
5873     }
5874 }
5875
5876 sub changesopts () {
5877     return (changesopts_initial(), changesopts_version());
5878 }
5879
5880 sub massage_dbp_args ($;$) {
5881     my ($cmd,$xargs) = @_;
5882     # We need to:
5883     #
5884     #  - if we're going to split the source build out so we can
5885     #    do strange things to it, massage the arguments to dpkg-buildpackage
5886     #    so that the main build doessn't build source (or add an argument
5887     #    to stop it building source by default).
5888     #
5889     #  - add -nc to stop dpkg-source cleaning the source tree,
5890     #    unless we're not doing a split build and want dpkg-source
5891     #    as cleanmode, in which case we can do nothing
5892     #
5893     # return values:
5894     #    0 - source will NOT need to be built separately by caller
5895     #   +1 - source will need to be built separately by caller
5896     #   +2 - source will need to be built separately by caller AND
5897     #        dpkg-buildpackage should not in fact be run at all!
5898     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5899 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5900     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5901         $clean_using_builder = 1;
5902         return 0;
5903     }
5904     # -nc has the side effect of specifying -b if nothing else specified
5905     # and some combinations of -S, -b, et al, are errors, rather than
5906     # later simply overriding earlie.  So we need to:
5907     #  - search the command line for these options
5908     #  - pick the last one
5909     #  - perhaps add our own as a default
5910     #  - perhaps adjust it to the corresponding non-source-building version
5911     my $dmode = '-F';
5912     foreach my $l ($cmd, $xargs) {
5913         next unless $l;
5914         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5915     }
5916     push @$cmd, '-nc';
5917 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5918     my $r = 0;
5919     if ($need_split_build_invocation) {
5920         printdebug "massage split $dmode.\n";
5921         $r = $dmode =~ m/[S]/     ? +2 :
5922              $dmode =~ y/gGF/ABb/ ? +1 :
5923              $dmode =~ m/[ABb]/   ?  0 :
5924              die "$dmode ?";
5925     }
5926     printdebug "massage done $r $dmode.\n";
5927     push @$cmd, $dmode;
5928 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5929     return $r;
5930 }
5931
5932 sub in_parent (&) {
5933     my ($fn) = @_;
5934     my $wasdir = must_getcwd();
5935     changedir "..";
5936     $fn->();
5937     changedir $wasdir;
5938 }
5939
5940 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5941     my ($msg_if_onlyone) = @_;
5942     # If there is only one .changes file, fail with $msg_if_onlyone,
5943     # or if that is undef, be a no-op.
5944     # Returns the changes file to report to the user.
5945     my $pat = changespat $version;
5946     my @changesfiles = glob $pat;
5947     @changesfiles = sort {
5948         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5949             or $a cmp $b
5950     } @changesfiles;
5951     my $result;
5952     if (@changesfiles==1) {
5953         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5954 only one changes file from build (@changesfiles)
5955 END
5956         $result = $changesfiles[0];
5957     } elsif (@changesfiles==2) {
5958         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5959         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5960             fail "$l found in binaries changes file $binchanges"
5961                 if $l =~ m/\.dsc$/;
5962         }
5963         runcmd_ordryrun_local @mergechanges, @changesfiles;
5964         my $multichanges = changespat $version,'multi';
5965         if (act_local()) {
5966             stat_exists $multichanges or fail "$multichanges: $!";
5967             foreach my $cf (glob $pat) {
5968                 next if $cf eq $multichanges;
5969                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5970             }
5971         }
5972         $result = $multichanges;
5973     } else {
5974         fail "wrong number of different changes files (@changesfiles)";
5975     }
5976     printdone "build successful, results in $result\n" or die $!;
5977 }
5978
5979 sub midbuild_checkchanges () {
5980     my $pat = changespat $version;
5981     return if $rmchanges;
5982     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5983     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5984     fail <<END
5985 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5986 Suggest you delete @unwanted.
5987 END
5988         if @unwanted;
5989 }
5990
5991 sub midbuild_checkchanges_vanilla ($) {
5992     my ($wantsrc) = @_;
5993     midbuild_checkchanges() if $wantsrc == 1;
5994 }
5995
5996 sub postbuild_mergechanges_vanilla ($) {
5997     my ($wantsrc) = @_;
5998     if ($wantsrc == 1) {
5999         in_parent {
6000             postbuild_mergechanges(undef);
6001         };
6002     } else {
6003         printdone "build successful\n";
6004     }
6005 }
6006
6007 sub cmd_build {
6008     build_prep_early();
6009     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6010     my $wantsrc = massage_dbp_args \@dbp;
6011     if ($wantsrc > 0) {
6012         build_source();
6013         midbuild_checkchanges_vanilla $wantsrc;
6014     } else {
6015         build_prep();
6016     }
6017     if ($wantsrc < 2) {
6018         push @dbp, changesopts_version();
6019         maybe_apply_patches_dirtily();
6020         runcmd_ordryrun_local @dbp;
6021     }
6022     maybe_unapply_patches_again();
6023     postbuild_mergechanges_vanilla $wantsrc;
6024 }
6025
6026 sub pre_gbp_build {
6027     $quilt_mode //= 'gbp';
6028 }
6029
6030 sub cmd_gbp_build {
6031     build_prep_early();
6032
6033     # gbp can make .origs out of thin air.  In my tests it does this
6034     # even for a 1.0 format package, with no origs present.  So I
6035     # guess it keys off just the version number.  We don't know
6036     # exactly what .origs ought to exist, but let's assume that we
6037     # should run gbp if: the version has an upstream part and the main
6038     # orig is absent.
6039     my $upstreamversion = upstreamversion $version;
6040     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6041     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6042
6043     if ($gbp_make_orig) {
6044         clean_tree();
6045         $cleanmode = 'none'; # don't do it again
6046         $need_split_build_invocation = 1;
6047     }
6048
6049     my @dbp = @dpkgbuildpackage;
6050
6051     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6052
6053     if (!length $gbp_build[0]) {
6054         if (length executable_on_path('git-buildpackage')) {
6055             $gbp_build[0] = qw(git-buildpackage);
6056         } else {
6057             $gbp_build[0] = 'gbp buildpackage';
6058         }
6059     }
6060     my @cmd = opts_opt_multi_cmd @gbp_build;
6061
6062     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6063
6064     if ($gbp_make_orig) {
6065         ensuredir '.git/dgit';
6066         my $ok = '.git/dgit/origs-gen-ok';
6067         unlink $ok or $!==&ENOENT or die $!;
6068         my @origs_cmd = @cmd;
6069         push @origs_cmd, qw(--git-cleaner=true);
6070         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6071         push @origs_cmd, @ARGV;
6072         if (act_local()) {
6073             debugcmd @origs_cmd;
6074             system @origs_cmd;
6075             do { local $!; stat_exists $ok; }
6076                 or failedcmd @origs_cmd;
6077         } else {
6078             dryrun_report @origs_cmd;
6079         }
6080     }
6081
6082     if ($wantsrc > 0) {
6083         build_source();
6084         midbuild_checkchanges_vanilla $wantsrc;
6085     } else {
6086         if (!$clean_using_builder) {
6087             push @cmd, '--git-cleaner=true';
6088         }
6089         build_prep();
6090     }
6091     maybe_unapply_patches_again();
6092     if ($wantsrc < 2) {
6093         push @cmd, changesopts();
6094         runcmd_ordryrun_local @cmd, @ARGV;
6095     }
6096     postbuild_mergechanges_vanilla $wantsrc;
6097 }
6098 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6099
6100 sub build_source {
6101     build_prep_early();
6102     my $our_cleanmode = $cleanmode;
6103     if ($need_split_build_invocation) {
6104         # Pretend that clean is being done some other way.  This
6105         # forces us not to try to use dpkg-buildpackage to clean and
6106         # build source all in one go; and instead we run dpkg-source
6107         # (and build_prep() will do the clean since $clean_using_builder
6108         # is false).
6109         $our_cleanmode = 'ELSEWHERE';
6110     }
6111     if ($our_cleanmode =~ m/^dpkg-source/) {
6112         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6113         $clean_using_builder = 1;
6114     }
6115     build_prep();
6116     $sourcechanges = changespat $version,'source';
6117     if (act_local()) {
6118         unlink "../$sourcechanges" or $!==ENOENT
6119             or fail "remove $sourcechanges: $!";
6120     }
6121     $dscfn = dscfn($version);
6122     if ($our_cleanmode eq 'dpkg-source') {
6123         maybe_apply_patches_dirtily();
6124         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6125             changesopts();
6126     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6127         maybe_apply_patches_dirtily();
6128         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6129             changesopts();
6130     } else {
6131         my @cmd = (@dpkgsource, qw(-b --));
6132         if ($split_brain) {
6133             changedir $playground;
6134             runcmd_ordryrun_local @cmd, "work";
6135             my @udfiles = <${package}_*>;
6136             changedir $maindir;
6137             foreach my $f (@udfiles) {
6138                 printdebug "source copy, found $f\n";
6139                 next unless
6140                     $f eq $dscfn or
6141                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6142                      $f eq srcfn($version, $&));
6143                 printdebug "source copy, found $f - renaming\n";
6144                 rename "$playground/$f", "../$f" or $!==ENOENT
6145                     or fail "put in place new source file ($f): $!";
6146             }
6147         } else {
6148             my $pwd = must_getcwd();
6149             my $leafdir = basename $pwd;
6150             changedir "..";
6151             runcmd_ordryrun_local @cmd, $leafdir;
6152             changedir $pwd;
6153         }
6154         runcmd_ordryrun_local qw(sh -ec),
6155             'exec >$1; shift; exec "$@"','x',
6156             "../$sourcechanges",
6157             @dpkggenchanges, qw(-S), changesopts();
6158     }
6159 }
6160
6161 sub cmd_build_source {
6162     build_prep_early();
6163     badusage "build-source takes no additional arguments" if @ARGV;
6164     build_source();
6165     maybe_unapply_patches_again();
6166     printdone "source built, results in $dscfn and $sourcechanges";
6167 }
6168
6169 sub cmd_sbuild {
6170     build_source();
6171     midbuild_checkchanges();
6172     in_parent {
6173         if (act_local()) {
6174             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6175             stat_exists $sourcechanges
6176                 or fail "$sourcechanges (in parent directory): $!";
6177         }
6178         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6179     };
6180     maybe_unapply_patches_again();
6181     in_parent {
6182         postbuild_mergechanges(<<END);
6183 perhaps you need to pass -A ?  (sbuild's default is to build only
6184 arch-specific binaries; dgit 1.4 used to override that.)
6185 END
6186     };
6187 }
6188
6189 sub cmd_quilt_fixup {
6190     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6191     build_prep_early();
6192     clean_tree();
6193     build_maybe_quilt_fixup();
6194 }
6195
6196 sub import_dsc_result {
6197     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6198     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6199     runcmd @cmd;
6200     check_gitattrs($newhash, "source tree");
6201
6202     progress "dgit: import-dsc: $what_msg";
6203 }
6204
6205 sub cmd_import_dsc {
6206     my $needsig = 0;
6207
6208     while (@ARGV) {
6209         last unless $ARGV[0] =~ m/^-/;
6210         $_ = shift @ARGV;
6211         last if m/^--?$/;
6212         if (m/^--require-valid-signature$/) {
6213             $needsig = 1;
6214         } else {
6215             badusage "unknown dgit import-dsc sub-option \`$_'";
6216         }
6217     }
6218
6219     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6220     my ($dscfn, $dstbranch) = @ARGV;
6221
6222     badusage "dry run makes no sense with import-dsc" unless act_local();
6223
6224     my $force = $dstbranch =~ s/^\+//   ? +1 :
6225                 $dstbranch =~ s/^\.\.// ? -1 :
6226                                            0;
6227     my $info = $force ? " $&" : '';
6228     $info = "$dscfn$info";
6229
6230     my $specbranch = $dstbranch;
6231     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6232     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6233
6234     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6235     my $chead = cmdoutput_errok @symcmd;
6236     defined $chead or $?==256 or failedcmd @symcmd;
6237
6238     fail "$dstbranch is checked out - will not update it"
6239         if defined $chead and $chead eq $dstbranch;
6240
6241     my $oldhash = git_get_ref $dstbranch;
6242
6243     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6244     $dscdata = do { local $/ = undef; <D>; };
6245     D->error and fail "read $dscfn: $!";
6246     close C;
6247
6248     # we don't normally need this so import it here
6249     use Dpkg::Source::Package;
6250     my $dp = new Dpkg::Source::Package filename => $dscfn,
6251         require_valid_signature => $needsig;
6252     {
6253         local $SIG{__WARN__} = sub {
6254             print STDERR $_[0];
6255             return unless $needsig;
6256             fail "import-dsc signature check failed";
6257         };
6258         if (!$dp->is_signed()) {
6259             warn "$us: warning: importing unsigned .dsc\n";
6260         } else {
6261             my $r = $dp->check_signature();
6262             die "->check_signature => $r" if $needsig && $r;
6263         }
6264     }
6265
6266     parse_dscdata();
6267
6268     $package = getfield $dsc, 'Source';
6269
6270     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6271         unless forceing [qw(import-dsc-with-dgit-field)];
6272     parse_dsc_field_def_dsc_distro();
6273
6274     $isuite = 'DGIT-IMPORT-DSC';
6275     $idistro //= $dsc_distro;
6276
6277     notpushing();
6278
6279     if (defined $dsc_hash) {
6280         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6281         resolve_dsc_field_commit undef, undef;
6282     }
6283     if (defined $dsc_hash) {
6284         my @cmd = (qw(sh -ec),
6285                    "echo $dsc_hash | git cat-file --batch-check");
6286         my $objgot = cmdoutput @cmd;
6287         if ($objgot =~ m#^\w+ missing\b#) {
6288             fail <<END
6289 .dsc contains Dgit field referring to object $dsc_hash
6290 Your git tree does not have that object.  Try `git fetch' from a
6291 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6292 END
6293         }
6294         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6295             if ($force > 0) {
6296                 progress "Not fast forward, forced update.";
6297             } else {
6298                 fail "Not fast forward to $dsc_hash";
6299             }
6300         }
6301         import_dsc_result $dstbranch, $dsc_hash,
6302             "dgit import-dsc (Dgit): $info",
6303             "updated git ref $dstbranch";
6304         return 0;
6305     }
6306
6307     fail <<END
6308 Branch $dstbranch already exists
6309 Specify ..$specbranch for a pseudo-merge, binding in existing history
6310 Specify  +$specbranch to overwrite, discarding existing history
6311 END
6312         if $oldhash && !$force;
6313
6314     my @dfi = dsc_files_info();
6315     foreach my $fi (@dfi) {
6316         my $f = $fi->{Filename};
6317         my $here = "../$f";
6318         if (lstat $here) {
6319             next if stat $here;
6320             fail "lstat $here works but stat gives $! !";
6321         }
6322         fail "stat $here: $!" unless $! == ENOENT;
6323         my $there = $dscfn;
6324         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6325             $there = $';
6326         } elsif ($dscfn =~ m#^/#) {
6327             $there = $dscfn;
6328         } else {
6329             fail "cannot import $dscfn which seems to be inside working tree!";
6330         }
6331         $there =~ s#/+[^/]+$## or
6332             fail "import $dscfn requires ../$f, but it does not exist";
6333         $there .= "/$f";
6334         my $test = $there =~ m{^/} ? $there : "../$there";
6335         stat $test or fail "import $dscfn requires $test, but: $!";
6336         symlink $there, $here or fail "symlink $there to $here: $!";
6337         progress "made symlink $here -> $there";
6338 #       print STDERR Dumper($fi);
6339     }
6340     my @mergeinputs = generate_commits_from_dsc();
6341     die unless @mergeinputs == 1;
6342
6343     my $newhash = $mergeinputs[0]{Commit};
6344
6345     if ($oldhash) {
6346         if ($force > 0) {
6347             progress "Import, forced update - synthetic orphan git history.";
6348         } elsif ($force < 0) {
6349             progress "Import, merging.";
6350             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6351             my $version = getfield $dsc, 'Version';
6352             my $clogp = commit_getclogp $newhash;
6353             my $authline = clogp_authline $clogp;
6354             $newhash = make_commit_text <<END;
6355 tree $tree
6356 parent $newhash
6357 parent $oldhash
6358 author $authline
6359 committer $authline
6360
6361 Merge $package ($version) import into $dstbranch
6362 END
6363         } else {
6364             die; # caught earlier
6365         }
6366     }
6367
6368     import_dsc_result $dstbranch, $newhash,
6369         "dgit import-dsc: $info",
6370         "results are in in git ref $dstbranch";
6371 }
6372
6373 sub pre_archive_api_query () {
6374     not_necessarily_a_tree();
6375 }
6376 sub cmd_archive_api_query {
6377     badusage "need only 1 subpath argument" unless @ARGV==1;
6378     my ($subpath) = @ARGV;
6379     my @cmd = archive_api_query_cmd($subpath);
6380     push @cmd, qw(-f);
6381     debugcmd ">",@cmd;
6382     exec @cmd or fail "exec curl: $!\n";
6383 }
6384
6385 sub repos_server_url () {
6386     $package = '_dgit-repos-server';
6387     local $access_forpush = 1;
6388     local $isuite = 'DGIT-REPOS-SERVER';
6389     my $url = access_giturl();
6390 }
6391
6392 sub pre_clone_dgit_repos_server () {
6393     not_necessarily_a_tree();
6394 }
6395 sub cmd_clone_dgit_repos_server {
6396     badusage "need destination argument" unless @ARGV==1;
6397     my ($destdir) = @ARGV;
6398     my $url = repos_server_url();
6399     my @cmd = (@git, qw(clone), $url, $destdir);
6400     debugcmd ">",@cmd;
6401     exec @cmd or fail "exec git clone: $!\n";
6402 }
6403
6404 sub pre_print_dgit_repos_server_source_url () {
6405     not_necessarily_a_tree();
6406 }
6407 sub cmd_print_dgit_repos_server_source_url {
6408     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6409         if @ARGV;
6410     my $url = repos_server_url();
6411     print $url, "\n" or die $!;
6412 }
6413
6414 sub cmd_setup_mergechangelogs {
6415     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6416     local $isuite = 'DGIT-SETUP-TREE';
6417     setup_mergechangelogs(1);
6418 }
6419
6420 sub cmd_setup_useremail {
6421     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6422     local $isuite = 'DGIT-SETUP-TREE';
6423     setup_useremail(1);
6424 }
6425
6426 sub cmd_setup_gitattributes {
6427     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6428     local $isuite = 'DGIT-SETUP-TREE';
6429     setup_gitattrs(1);
6430 }
6431
6432 sub cmd_setup_new_tree {
6433     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6434     local $isuite = 'DGIT-SETUP-TREE';
6435     setup_new_tree();
6436 }
6437
6438 #---------- argument parsing and main program ----------
6439
6440 sub cmd_version {
6441     print "dgit version $our_version\n" or die $!;
6442     exit 0;
6443 }
6444
6445 our (%valopts_long, %valopts_short);
6446 our (%funcopts_long);
6447 our @rvalopts;
6448 our (@modeopt_cfgs);
6449
6450 sub defvalopt ($$$$) {
6451     my ($long,$short,$val_re,$how) = @_;
6452     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6453     $valopts_long{$long} = $oi;
6454     $valopts_short{$short} = $oi;
6455     # $how subref should:
6456     #   do whatever assignemnt or thing it likes with $_[0]
6457     #   if the option should not be passed on to remote, @rvalopts=()
6458     # or $how can be a scalar ref, meaning simply assign the value
6459 }
6460
6461 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6462 defvalopt '--distro',        '-d', '.+',      \$idistro;
6463 defvalopt '',                '-k', '.+',      \$keyid;
6464 defvalopt '--existing-package','', '.*',      \$existing_package;
6465 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6466 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6467 defvalopt '--package',   '-p',   $package_re, \$package;
6468 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6469
6470 defvalopt '', '-C', '.+', sub {
6471     ($changesfile) = (@_);
6472     if ($changesfile =~ s#^(.*)/##) {
6473         $buildproductsdir = $1;
6474     }
6475 };
6476
6477 defvalopt '--initiator-tempdir','','.*', sub {
6478     ($initiator_tempdir) = (@_);
6479     $initiator_tempdir =~ m#^/# or
6480         badusage "--initiator-tempdir must be used specify an".
6481         " absolute, not relative, directory."
6482 };
6483
6484 sub defoptmodes ($@) {
6485     my ($varref, $cfgkey, $default, %optmap) = @_;
6486     my %permit;
6487     while (my ($opt,$val) = each %optmap) {
6488         $funcopts_long{$opt} = sub { $$varref = $val; };
6489         $permit{$val} = $val;
6490     }
6491     push @modeopt_cfgs, {
6492         Var => $varref,
6493         Key => $cfgkey,
6494         Default => $default,
6495         Vals => \%permit
6496     };
6497 }
6498
6499 defoptmodes \$dodep14tag, qw( dep14tag          want
6500                               --dep14tag        want
6501                               --no-dep14tag     no
6502                               --always-dep14tag always );
6503
6504 sub parseopts () {
6505     my $om;
6506
6507     if (defined $ENV{'DGIT_SSH'}) {
6508         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6509     } elsif (defined $ENV{'GIT_SSH'}) {
6510         @ssh = ($ENV{'GIT_SSH'});
6511     }
6512
6513     my $oi;
6514     my $val;
6515     my $valopt = sub {
6516         my ($what) = @_;
6517         @rvalopts = ($_);
6518         if (!defined $val) {
6519             badusage "$what needs a value" unless @ARGV;
6520             $val = shift @ARGV;
6521             push @rvalopts, $val;
6522         }
6523         badusage "bad value \`$val' for $what" unless
6524             $val =~ m/^$oi->{Re}$(?!\n)/s;
6525         my $how = $oi->{How};
6526         if (ref($how) eq 'SCALAR') {
6527             $$how = $val;
6528         } else {
6529             $how->($val);
6530         }
6531         push @ropts, @rvalopts;
6532     };
6533
6534     while (@ARGV) {
6535         last unless $ARGV[0] =~ m/^-/;
6536         $_ = shift @ARGV;
6537         last if m/^--?$/;
6538         if (m/^--/) {
6539             if (m/^--dry-run$/) {
6540                 push @ropts, $_;
6541                 $dryrun_level=2;
6542             } elsif (m/^--damp-run$/) {
6543                 push @ropts, $_;
6544                 $dryrun_level=1;
6545             } elsif (m/^--no-sign$/) {
6546                 push @ropts, $_;
6547                 $sign=0;
6548             } elsif (m/^--help$/) {
6549                 cmd_help();
6550             } elsif (m/^--version$/) {
6551                 cmd_version();
6552             } elsif (m/^--new$/) {
6553                 push @ropts, $_;
6554                 $new_package=1;
6555             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6556                      ($om = $opts_opt_map{$1}) &&
6557                      length $om->[0]) {
6558                 push @ropts, $_;
6559                 $om->[0] = $2;
6560             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6561                      !$opts_opt_cmdonly{$1} &&
6562                      ($om = $opts_opt_map{$1})) {
6563                 push @ropts, $_;
6564                 push @$om, $2;
6565             } elsif (m/^--(gbp|dpm)$/s) {
6566                 push @ropts, "--quilt=$1";
6567                 $quilt_mode = $1;
6568             } elsif (m/^--ignore-dirty$/s) {
6569                 push @ropts, $_;
6570                 $ignoredirty = 1;
6571             } elsif (m/^--no-quilt-fixup$/s) {
6572                 push @ropts, $_;
6573                 $quilt_mode = 'nocheck';
6574             } elsif (m/^--no-rm-on-error$/s) {
6575                 push @ropts, $_;
6576                 $rmonerror = 0;
6577             } elsif (m/^--no-chase-dsc-distro$/s) {
6578                 push @ropts, $_;
6579                 $chase_dsc_distro = 0;
6580             } elsif (m/^--overwrite$/s) {
6581                 push @ropts, $_;
6582                 $overwrite_version = '';
6583             } elsif (m/^--overwrite=(.+)$/s) {
6584                 push @ropts, $_;
6585                 $overwrite_version = $1;
6586             } elsif (m/^--delayed=(\d+)$/s) {
6587                 push @ropts, $_;
6588                 push @dput, $_;
6589             } elsif (m/^--dgit-view-save=(.+)$/s) {
6590                 push @ropts, $_;
6591                 $split_brain_save = $1;
6592                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6593             } elsif (m/^--(no-)?rm-old-changes$/s) {
6594                 push @ropts, $_;
6595                 $rmchanges = !$1;
6596             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6597                 push @ropts, $_;
6598                 push @deliberatelies, $&;
6599             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6600                 push @ropts, $&;
6601                 $forceopts{$1} = 1;
6602                 $_='';
6603             } elsif (m/^--force-/) {
6604                 print STDERR
6605                     "$us: warning: ignoring unknown force option $_\n";
6606                 $_='';
6607             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6608                 # undocumented, for testing
6609                 push @ropts, $_;
6610                 $tagformat_want = [ $1, 'command line', 1 ];
6611                 # 1 menas overrides distro configuration
6612             } elsif (m/^--always-split-source-build$/s) {
6613                 # undocumented, for testing
6614                 push @ropts, $_;
6615                 $need_split_build_invocation = 1;
6616             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6617                 # undocumented, for testing
6618                 push @ropts, $_;
6619                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6620                 # ^ it's supposed to be an array ref
6621             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6622                 $val = $2 ? $' : undef; #';
6623                 $valopt->($oi->{Long});
6624             } elsif ($funcopts_long{$_}) {
6625                 push @ropts, $_;
6626                 $funcopts_long{$_}();
6627             } else {
6628                 badusage "unknown long option \`$_'";
6629             }
6630         } else {
6631             while (m/^-./s) {
6632                 if (s/^-n/-/) {
6633                     push @ropts, $&;
6634                     $dryrun_level=2;
6635                 } elsif (s/^-L/-/) {
6636                     push @ropts, $&;
6637                     $dryrun_level=1;
6638                 } elsif (s/^-h/-/) {
6639                     cmd_help();
6640                 } elsif (s/^-D/-/) {
6641                     push @ropts, $&;
6642                     $debuglevel++;
6643                     enabledebug();
6644                 } elsif (s/^-N/-/) {
6645                     push @ropts, $&;
6646                     $new_package=1;
6647                 } elsif (m/^-m/) {
6648                     push @ropts, $&;
6649                     push @changesopts, $_;
6650                     $_ = '';
6651                 } elsif (s/^-wn$//s) {
6652                     push @ropts, $&;
6653                     $cleanmode = 'none';
6654                 } elsif (s/^-wg$//s) {
6655                     push @ropts, $&;
6656                     $cleanmode = 'git';
6657                 } elsif (s/^-wgf$//s) {
6658                     push @ropts, $&;
6659                     $cleanmode = 'git-ff';
6660                 } elsif (s/^-wd$//s) {
6661                     push @ropts, $&;
6662                     $cleanmode = 'dpkg-source';
6663                 } elsif (s/^-wdd$//s) {
6664                     push @ropts, $&;
6665                     $cleanmode = 'dpkg-source-d';
6666                 } elsif (s/^-wc$//s) {
6667                     push @ropts, $&;
6668                     $cleanmode = 'check';
6669                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6670                     push @git, '-c', $&;
6671                     $gitcfgs{cmdline}{$1} = [ $2 ];
6672                 } elsif (s/^-c([^=]+)$//s) {
6673                     push @git, '-c', $&;
6674                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6675                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6676                     $val = $'; #';
6677                     $val = undef unless length $val;
6678                     $valopt->($oi->{Short});
6679                     $_ = '';
6680                 } else {
6681                     badusage "unknown short option \`$_'";
6682                 }
6683             }
6684         }
6685     }
6686 }
6687
6688 sub check_env_sanity () {
6689     my $blocked = new POSIX::SigSet;
6690     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6691
6692     eval {
6693         foreach my $name (qw(PIPE CHLD)) {
6694             my $signame = "SIG$name";
6695             my $signum = eval "POSIX::$signame" // die;
6696             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6697                 die "$signame is set to something other than SIG_DFL\n";
6698             $blocked->ismember($signum) and
6699                 die "$signame is blocked\n";
6700         }
6701     };
6702     return unless $@;
6703     chomp $@;
6704     fail <<END;
6705 On entry to dgit, $@
6706 This is a bug produced by something in in your execution environment.
6707 Giving up.
6708 END
6709 }
6710
6711
6712 sub parseopts_late_defaults () {
6713     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6714         if defined $idistro;
6715     $isuite //= cfg('dgit.default.default-suite');
6716
6717     foreach my $k (keys %opts_opt_map) {
6718         my $om = $opts_opt_map{$k};
6719
6720         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6721         if (defined $v) {
6722             badcfg "cannot set command for $k"
6723                 unless length $om->[0];
6724             $om->[0] = $v;
6725         }
6726
6727         foreach my $c (access_cfg_cfgs("opts-$k")) {
6728             my @vl =
6729                 map { $_ ? @$_ : () }
6730                 map { $gitcfgs{$_}{$c} }
6731                 reverse @gitcfgsources;
6732             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6733                 "\n" if $debuglevel >= 4;
6734             next unless @vl;
6735             badcfg "cannot configure options for $k"
6736                 if $opts_opt_cmdonly{$k};
6737             my $insertpos = $opts_cfg_insertpos{$k};
6738             @$om = ( @$om[0..$insertpos-1],
6739                      @vl,
6740                      @$om[$insertpos..$#$om] );
6741         }
6742     }
6743
6744     if (!defined $rmchanges) {
6745         local $access_forpush;
6746         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6747     }
6748
6749     if (!defined $quilt_mode) {
6750         local $access_forpush;
6751         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6752             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6753             // 'linear';
6754         $quilt_mode =~ m/^($quilt_modes_re)$/
6755             or badcfg "unknown quilt-mode \`$quilt_mode'";
6756         $quilt_mode = $1;
6757     }
6758
6759     foreach my $moc (@modeopt_cfgs) {
6760         local $access_forpush;
6761         my $vr = $moc->{Var};
6762         next if defined $$vr;
6763         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6764         my $v = $moc->{Vals}{$$vr};
6765         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6766         $$vr = $v;
6767     }
6768
6769     $need_split_build_invocation ||= quiltmode_splitbrain();
6770
6771     if (!defined $cleanmode) {
6772         local $access_forpush;
6773         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6774         $cleanmode //= 'dpkg-source';
6775
6776         badcfg "unknown clean-mode \`$cleanmode'" unless
6777             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6778     }
6779 }
6780
6781 if ($ENV{$fakeeditorenv}) {
6782     git_slurp_config();
6783     quilt_fixup_editor();
6784 }
6785
6786 parseopts();
6787 check_env_sanity();
6788
6789 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6790 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6791     if $dryrun_level == 1;
6792 if (!@ARGV) {
6793     print STDERR $helpmsg or die $!;
6794     exit 8;
6795 }
6796 $cmd = $subcommand = shift @ARGV;
6797 $cmd =~ y/-/_/;
6798
6799 my $pre_fn = ${*::}{"pre_$cmd"};
6800 $pre_fn->() if $pre_fn;
6801
6802 record_maindir if $invoked_in_git_tree;
6803 git_slurp_config();
6804
6805 my $fn = ${*::}{"cmd_$cmd"};
6806 $fn or badusage "unknown operation $cmd";
6807 $fn->();