dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $isuite;
  51 our $idistro;
  52 our $package;
  53 our @ropts;
  54
  55 our $sign = 1;
  56 our $dryrun_level = 0;
  57 our $changesfile;
  58 our $buildproductsdir = '..';
  59 our $new_package = 0;
  60 our $ignoredirty = 0;
  61 our $rmonerror = 1;
  62 our @deliberatelies;
  63 our %previously;
  64 our $existing_package = 'dpkg';
  65 our $cleanmode;
  66 our $changes_since_version;
  67 our $rmchanges;
  68 our $overwrite_version; # undef: not specified; '': check changelog
  69 our $quilt_mode;
  70 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  71 our $dodep14tag;
  72 our $split_brain_save;
  73 our $we_are_responder;
  74 our $we_are_initiator;
  75 our $initiator_tempdir;
  76 our $patches_applied_dirtily = 00;
  77 our $tagformat_want;
  78 our $tagformat;
  79 our $tagformatfn;
  80 our $chase_dsc_distro=1;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = qw(curl);
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146 sub setup_gitattrs(;$);
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     return unless forkcheck_mainprocess();
 159     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 160 }
 161
 162 our $remotename = 'dgit';
 163 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 164 our $csuite;
 165 our $instead_distro;
 166
 167 if (!defined $absurdity) {
 168     $absurdity = $0;
 169     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 170 }
 171
 172 sub debiantag ($$) {
 173     my ($v,$distro) = @_;
 174     return $tagformatfn->($v, $distro);
 175 }
 176
 177 sub debiantag_maintview ($$) {
 178     my ($v,$distro) = @_;
 179     return "$distro/".dep14_version_mangle $v;
 180 }
 181
 182 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 183
 184 sub lbranch () { return "$branchprefix/$csuite"; }
 185 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 186 sub lref () { return "refs/heads/".lbranch(); }
 187 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 188 sub rrref () { return server_ref($csuite); }
 189
 190 sub stripepoch ($) {
 191     my ($vsn) = @_;
 192     $vsn =~ s/^\d+\://;
 193     return $vsn;
 194 }
 195
 196 sub srcfn ($$) {
 197     my ($vsn,$sfx) = @_;
 198     return "${package}_".(stripepoch $vsn).$sfx
 199 }
 200
 201 sub dscfn ($) {
 202     my ($vsn) = @_;
 203     return srcfn($vsn,".dsc");
 204 }
 205
 206 sub changespat ($;$) {
 207     my ($vsn, $arch) = @_;
 208     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 209 }
 210
 211 sub upstreamversion ($) {
 212     my ($vsn) = @_;
 213     $vsn =~ s/-[^-]+$//;
 214     return $vsn;
 215 }
 216
 217 our $us = 'dgit';
 218 initdebug('');
 219
 220 our @end;
 221 END {
 222     local ($?);
 223     return unless forkcheck_mainprocess();
 224     foreach my $f (@end) {
 225         eval { $f->(); };
 226         print STDERR "$us: cleanup: $@" if length $@;
 227     }
 228 };
 229
 230 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 231
 232 sub forceable_fail ($$) {
 233     my ($forceoptsl, $msg) = @_;
 234     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 235     print STDERR "warning: overriding problem due to --force:\n". $msg;
 236 }
 237
 238 sub forceing ($) {
 239     my ($forceoptsl) = @_;
 240     my @got = grep { $forceopts{$_} } @$forceoptsl;
 241     return 0 unless @got;
 242     print STDERR
 243  "warning: skipping checks or functionality due to --force-$got[0]\n";
 244 }
 245
 246 sub no_such_package () {
 247     print STDERR "$us: package $package does not exist in suite $isuite\n";
 248     exit 4;
 249 }
 250
 251 sub changedir ($) {
 252     my ($newdir) = @_;
 253     printdebug "CD $newdir\n";
 254     chdir $newdir or confess "chdir: $newdir: $!";
 255 }
 256
 257 sub deliberately ($) {
 258     my ($enquiry) = @_;
 259     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 260 }
 261
 262 sub deliberately_not_fast_forward () {
 263     foreach (qw(not-fast-forward fresh-repo)) {
 264         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 265     }
 266 }
 267
 268 sub quiltmode_splitbrain () {
 269     $quilt_mode =~ m/gbp|dpm|unapplied/;
 270 }
 271
 272 sub opts_opt_multi_cmd {
 273     my @cmd;
 274     push @cmd, split /\s+/, shift @_;
 275     push @cmd, @_;
 276     @cmd;
 277 }
 278
 279 sub gbp_pq {
 280     return opts_opt_multi_cmd @gbp_pq;
 281 }
 282
 283 #---------- remote protocol support, common ----------
 284
 285 # remote push initiator/responder protocol:
 286 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 287 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 288 #  < dgit-remote-push-ready <actual-proto-vsn>
 289 #
 290 # occasionally:
 291 #
 292 #  > progress NBYTES
 293 #  [NBYTES message]
 294 #
 295 #  > supplementary-message NBYTES          # $protovsn >= 3
 296 #  [NBYTES message]
 297 #
 298 # main sequence:
 299 #
 300 #  > file parsed-changelog
 301 #  [indicates that output of dpkg-parsechangelog follows]
 302 #  > data-block NBYTES
 303 #  > [NBYTES bytes of data (no newline)]
 304 #  [maybe some more blocks]
 305 #  > data-end
 306 #
 307 #  > file dsc
 308 #  [etc]
 309 #
 310 #  > file changes
 311 #  [etc]
 312 #
 313 #  > param head DGIT-VIEW-HEAD
 314 #  > param csuite SUITE
 315 #  > param tagformat old|new
 316 #  > param maint-view MAINT-VIEW-HEAD
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < files-end
 335 #
 336 #  > complete
 337
 338 our $i_child_pid;
 339
 340 sub i_child_report () {
 341     # Sees if our child has died, and reap it if so.  Returns a string
 342     # describing how it died if it failed, or undef otherwise.
 343     return undef unless $i_child_pid;
 344     my $got = waitpid $i_child_pid, WNOHANG;
 345     return undef if $got <= 0;
 346     die unless $got == $i_child_pid;
 347     $i_child_pid = undef;
 348     return undef unless $?;
 349     return "build host child ".waitstatusmsg();
 350 }
 351
 352 sub badproto ($$) {
 353     my ($fh, $m) = @_;
 354     fail "connection lost: $!" if $fh->error;
 355     fail "protocol violation; $m not expected";
 356 }
 357
 358 sub badproto_badread ($$) {
 359     my ($fh, $wh) = @_;
 360     fail "connection lost: $!" if $!;
 361     my $report = i_child_report();
 362     fail $report if defined $report;
 363     badproto $fh, "eof (reading $wh)";
 364 }
 365
 366 sub protocol_expect (&$) {
 367     my ($match, $fh) = @_;
 368     local $_;
 369     $_ = <$fh>;
 370     defined && chomp or badproto_badread $fh, "protocol message";
 371     if (wantarray) {
 372         my @r = &$match;
 373         return @r if @r;
 374     } else {
 375         my $r = &$match;
 376         return $r if $r;
 377     }
 378     badproto $fh, "\`$_'";
 379 }
 380
 381 sub protocol_send_file ($$) {
 382     my ($fh, $ourfn) = @_;
 383     open PF, "<", $ourfn or die "$ourfn: $!";
 384     for (;;) {
 385         my $d;
 386         my $got = read PF, $d, 65536;
 387         die "$ourfn: $!" unless defined $got;
 388         last if !$got;
 389         print $fh "data-block ".length($d)."\n" or die $!;
 390         print $fh $d or die $!;
 391     }
 392     PF->error and die "$ourfn $!";
 393     print $fh "data-end\n" or die $!;
 394     close PF;
 395 }
 396
 397 sub protocol_read_bytes ($$) {
 398     my ($fh, $nbytes) = @_;
 399     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 400     my $d;
 401     my $got = read $fh, $d, $nbytes;
 402     $got==$nbytes or badproto_badread $fh, "data block";
 403     return $d;
 404 }
 405
 406 sub protocol_receive_file ($$) {
 407     my ($fh, $ourfn) = @_;
 408     printdebug "() $ourfn\n";
 409     open PF, ">", $ourfn or die "$ourfn: $!";
 410     for (;;) {
 411         my ($y,$l) = protocol_expect {
 412             m/^data-block (.*)$/ ? (1,$1) :
 413             m/^data-end$/ ? (0,) :
 414             ();
 415         } $fh;
 416         last unless $y;
 417         my $d = protocol_read_bytes $fh, $l;
 418         print PF $d or die $!;
 419     }
 420     close PF or die $!;
 421 }
 422
 423 #---------- remote protocol support, responder ----------
 424
 425 sub responder_send_command ($) {
 426     my ($command) = @_;
 427     return unless $we_are_responder;
 428     # called even without $we_are_responder
 429     printdebug ">> $command\n";
 430     print PO $command, "\n" or die $!;
 431 }
 432
 433 sub responder_send_file ($$) {
 434     my ($keyword, $ourfn) = @_;
 435     return unless $we_are_responder;
 436     printdebug "]] $keyword $ourfn\n";
 437     responder_send_command "file $keyword";
 438     protocol_send_file \*PO, $ourfn;
 439 }
 440
 441 sub responder_receive_files ($@) {
 442     my ($keyword, @ourfns) = @_;
 443     die unless $we_are_responder;
 444     printdebug "[[ $keyword @ourfns\n";
 445     responder_send_command "want $keyword";
 446     foreach my $fn (@ourfns) {
 447         protocol_receive_file \*PI, $fn;
 448     }
 449     printdebug "[[\$\n";
 450     protocol_expect { m/^files-end$/ } \*PI;
 451 }
 452
 453 #---------- remote protocol support, initiator ----------
 454
 455 sub initiator_expect (&) {
 456     my ($match) = @_;
 457     protocol_expect { &$match } \*RO;
 458 }
 459
 460 #---------- end remote code ----------
 461
 462 sub progress {
 463     if ($we_are_responder) {
 464         my $m = join '', @_;
 465         responder_send_command "progress ".length($m) or die $!;
 466         print PO $m or die $!;
 467     } else {
 468         print @_, "\n";
 469     }
 470 }
 471
 472 our $ua;
 473
 474 sub url_get {
 475     if (!$ua) {
 476         $ua = LWP::UserAgent->new();
 477         $ua->env_proxy;
 478     }
 479     my $what = $_[$#_];
 480     progress "downloading $what...";
 481     my $r = $ua->get(@_) or die $!;
 482     return undef if $r->code == 404;
 483     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 484     return $r->decoded_content(charset => 'none');
 485 }
 486
 487 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 488
 489 sub runcmd {
 490     debugcmd "+",@_;
 491     $!=0; $?=-1;
 492     failedcmd @_ if system @_;
 493 }
 494
 495 sub act_local () { return $dryrun_level <= 1; }
 496 sub act_scary () { return !$dryrun_level; }
 497
 498 sub printdone {
 499     if (!$dryrun_level) {
 500         progress "$us ok: @_";
 501     } else {
 502         progress "would be ok: @_ (but dry run only)";
 503     }
 504 }
 505
 506 sub dryrun_report {
 507     printcmd(\*STDERR,$debugprefix."#",@_);
 508 }
 509
 510 sub runcmd_ordryrun {
 511     if (act_scary()) {
 512         runcmd @_;
 513     } else {
 514         dryrun_report @_;
 515     }
 516 }
 517
 518 sub runcmd_ordryrun_local {
 519     if (act_local()) {
 520         runcmd @_;
 521     } else {
 522         dryrun_report @_;
 523     }
 524 }
 525
 526 sub shell_cmd {
 527     my ($first_shell, @cmd) = @_;
 528     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 529 }
 530
 531 our $helpmsg = <<END;
 532 main usages:
 533   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 534   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 535   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 536   dgit [dgit-opts] sbuild [sbuild-opts]
 537   dgit [dgit-opts] push [dgit-opts] [suite]
 538   dgit [dgit-opts] rpush build-host:build-dir ...
 539 important dgit options:
 540   -k<keyid>           sign tag and package with <keyid> instead of default
 541   --dry-run -n        do not change anything, but go through the motions
 542   --damp-run -L       like --dry-run but make local changes, without signing
 543   --new -N            allow introducing a new package
 544   --debug -D          increase debug level
 545   -c<name>=<value>    set git config option (used directly by dgit too)
 546 END
 547
 548 our $later_warning_msg = <<END;
 549 Perhaps the upload is stuck in incoming.  Using the version from git.
 550 END
 551
 552 sub badusage {
 553     print STDERR "$us: @_\n", $helpmsg or die $!;
 554     exit 8;
 555 }
 556
 557 sub nextarg {
 558     @ARGV or badusage "too few arguments";
 559     return scalar shift @ARGV;
 560 }
 561
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638
 639 sub git_slurp_config () {
 640     local ($debuglevel) = $debuglevel-2;
 641     local $/="\0";
 642
 643     # This algoritm is a bit subtle, but this is needed so that for
 644     # options which we want to be single-valued, we allow the
 645     # different config sources to override properly.  See #835858.
 646     foreach my $src (@gitcfgsources) {
 647         next if $src eq 'cmdline';
 648         # we do this ourselves since git doesn't handle it
 649
 650         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 651         debugcmd "|",@cmd;
 652
 653         open GITS, "-|", @cmd or die $!;
 654         while (<GITS>) {
 655             chomp or die;
 656             printdebug "=> ", (messagequote $_), "\n";
 657             m/\n/ or die "$_ ?";
 658             push @{ $gitcfgs{$src}{$`} }, $'; #';
 659         }
 660         $!=0; $?=0;
 661         close GITS
 662             or ($!==0 && $?==256)
 663             or failedcmd @cmd;
 664     }
 665 }
 666
 667 sub git_get_config ($) {
 668     my ($c) = @_;
 669     foreach my $src (@gitcfgsources) {
 670         my $l = $gitcfgs{$src}{$c};
 671         croak "$l $c" if $l && !ref $l;
 672         printdebug"C $c ".(defined $l ?
 673                            join " ", map { messagequote "'$_'" } @$l :
 674                            "undef")."\n"
 675             if $debuglevel >= 4;
 676         $l or next;
 677         @$l==1 or badcfg "multiple values for $c".
 678             " (in $src git config)" if @$l > 1;
 679         return $l->[0];
 680     }
 681     return undef;
 682 }
 683
 684 sub cfg {
 685     foreach my $c (@_) {
 686         return undef if $c =~ /RETURN-UNDEF/;
 687         printdebug "C? $c\n" if $debuglevel >= 5;
 688         my $v = git_get_config($c);
 689         return $v if defined $v;
 690         my $dv = $defcfg{$c};
 691         if (defined $dv) {
 692             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 693             return $dv;
 694         }
 695     }
 696     badcfg "need value for one of: @_\n".
 697         "$us: distro or suite appears not to be (properly) supported";
 698 }
 699
 700 sub access_basedistro__noalias () {
 701     if (defined $idistro) {
 702         return $idistro;
 703     } else {
 704         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 705         return $def if defined $def;
 706         foreach my $src (@gitcfgsources, 'internal') {
 707             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 708             next unless $kl;
 709             foreach my $k (keys %$kl) {
 710                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 711                 my $dpat = $1;
 712                 next unless match_glob $dpat, $isuite;
 713                 return $kl->{$k};
 714             }
 715         }
 716         return cfg("dgit.default.distro");
 717     }
 718 }
 719
 720 sub access_basedistro () {
 721     my $noalias = access_basedistro__noalias();
 722     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 723     return $canon // $noalias;
 724 }
 725
 726 sub access_nomdistro () {
 727     my $base = access_basedistro();
 728     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 729     $r =~ m/^$distro_re$/ or badcfg
 730  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 731     return $r;
 732 }
 733
 734 sub access_quirk () {
 735     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 736     my $basedistro = access_basedistro();
 737     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 738                               'RETURN-UNDEF');
 739     if (defined $backports_quirk) {
 740         my $re = $backports_quirk;
 741         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 742         $re =~ s/\*/.*/g;
 743         $re =~ s/\%/([-0-9a-z_]+)/
 744             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 745         if ($isuite =~ m/^$re$/) {
 746             return ('backports',"$basedistro-backports",$1);
 747         }
 748     }
 749     return ('none',undef);
 750 }
 751
 752 our $access_forpush;
 753
 754 sub parse_cfg_bool ($$$) {
 755     my ($what,$def,$v) = @_;
 756     $v //= $def;
 757     return
 758         $v =~ m/^[ty1]/ ? 1 :
 759         $v =~ m/^[fn0]/ ? 0 :
 760         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 761 }
 762
 763 sub access_forpush_config () {
 764     my $d = access_basedistro();
 765
 766     return 1 if
 767         $new_package &&
 768         parse_cfg_bool('new-private-pushers', 0,
 769                        cfg("dgit-distro.$d.new-private-pushers",
 770                            'RETURN-UNDEF'));
 771
 772     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 773     $v //= 'a';
 774     return
 775         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 776         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 777         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 778         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 779 }
 780
 781 sub access_forpush () {
 782     $access_forpush //= access_forpush_config();
 783     return $access_forpush;
 784 }
 785
 786 sub pushing () {
 787     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 788     badcfg "pushing but distro is configured readonly"
 789         if access_forpush_config() eq '0';
 790     $access_forpush = 1;
 791     $supplementary_message = <<'END' unless $we_are_responder;
 792 Push failed, before we got started.
 793 You can retry the push, after fixing the problem, if you like.
 794 END
 795     parseopts_late_defaults();
 796 }
 797
 798 sub notpushing () {
 799     parseopts_late_defaults();
 800 }
 801
 802 sub supplementary_message ($) {
 803     my ($msg) = @_;
 804     if (!$we_are_responder) {
 805         $supplementary_message = $msg;
 806         return;
 807     } elsif ($protovsn >= 3) {
 808         responder_send_command "supplementary-message ".length($msg)
 809             or die $!;
 810         print PO $msg or die $!;
 811     }
 812 }
 813
 814 sub access_distros () {
 815     # Returns list of distros to try, in order
 816     #
 817     # We want to try:
 818     #    0. `instead of' distro name(s) we have been pointed to
 819     #    1. the access_quirk distro, if any
 820     #    2a. the user's specified distro, or failing that  } basedistro
 821     #    2b. the distro calculated from the suite          }
 822     my @l = access_basedistro();
 823
 824     my (undef,$quirkdistro) = access_quirk();
 825     unshift @l, $quirkdistro;
 826     unshift @l, $instead_distro;
 827     @l = grep { defined } @l;
 828
 829     push @l, access_nomdistro();
 830
 831     if (access_forpush()) {
 832         @l = map { ("$_/push", $_) } @l;
 833     }
 834     @l;
 835 }
 836
 837 sub access_cfg_cfgs (@) {
 838     my (@keys) = @_;
 839     my @cfgs;
 840     # The nesting of these loops determines the search order.  We put
 841     # the key loop on the outside so that we search all the distros
 842     # for each key, before going on to the next key.  That means that
 843     # if access_cfg is called with a more specific, and then a less
 844     # specific, key, an earlier distro can override the less specific
 845     # without necessarily overriding any more specific keys.  (If the
 846     # distro wants to override the more specific keys it can simply do
 847     # so; whereas if we did the loop the other way around, it would be
 848     # impossible to for an earlier distro to override a less specific
 849     # key but not the more specific ones without restating the unknown
 850     # values of the more specific keys.
 851     my @realkeys;
 852     my @rundef;
 853     # We have to deal with RETURN-UNDEF specially, so that we don't
 854     # terminate the search prematurely.
 855     foreach (@keys) {
 856         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 857         push @realkeys, $_
 858     }
 859     foreach my $d (access_distros()) {
 860         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 861     }
 862     push @cfgs, map { "dgit.default.$_" } @realkeys;
 863     push @cfgs, @rundef;
 864     return @cfgs;
 865 }
 866
 867 sub access_cfg (@) {
 868     my (@keys) = @_;
 869     my (@cfgs) = access_cfg_cfgs(@keys);
 870     my $value = cfg(@cfgs);
 871     return $value;
 872 }
 873
 874 sub access_cfg_bool ($$) {
 875     my ($def, @keys) = @_;
 876     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 877 }
 878
 879 sub string_to_ssh ($) {
 880     my ($spec) = @_;
 881     if ($spec =~ m/\s/) {
 882         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 883     } else {
 884         return ($spec);
 885     }
 886 }
 887
 888 sub access_cfg_ssh () {
 889     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 890     if (!defined $gitssh) {
 891         return @ssh;
 892     } else {
 893         return string_to_ssh $gitssh;
 894     }
 895 }
 896
 897 sub access_runeinfo ($) {
 898     my ($info) = @_;
 899     return ": dgit ".access_basedistro()." $info ;";
 900 }
 901
 902 sub access_someuserhost ($) {
 903     my ($some) = @_;
 904     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 905     defined($user) && length($user) or
 906         $user = access_cfg("$some-user",'username');
 907     my $host = access_cfg("$some-host");
 908     return length($user) ? "$user\@$host" : $host;
 909 }
 910
 911 sub access_gituserhost () {
 912     return access_someuserhost('git');
 913 }
 914
 915 sub access_giturl (;$) {
 916     my ($optional) = @_;
 917     my $url = access_cfg('git-url','RETURN-UNDEF');
 918     my $suffix;
 919     if (!length $url) {
 920         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 921         return undef unless defined $proto;
 922         $url =
 923             $proto.
 924             access_gituserhost().
 925             access_cfg('git-path');
 926     } else {
 927         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 928     }
 929     $suffix //= '.git';
 930     return "$url/$package$suffix";
 931 }
 932
 933 sub parsecontrolfh ($$;$) {
 934     my ($fh, $desc, $allowsigned) = @_;
 935     our $dpkgcontrolhash_noissigned;
 936     my $c;
 937     for (;;) {
 938         my %opts = ('name' => $desc);
 939         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 940         $c = Dpkg::Control::Hash->new(%opts);
 941         $c->parse($fh,$desc) or die "parsing of $desc failed";
 942         last if $allowsigned;
 943         last if $dpkgcontrolhash_noissigned;
 944         my $issigned= $c->get_option('is_pgp_signed');
 945         if (!defined $issigned) {
 946             $dpkgcontrolhash_noissigned= 1;
 947             seek $fh, 0,0 or die "seek $desc: $!";
 948         } elsif ($issigned) {
 949             fail "control file $desc is (already) PGP-signed. ".
 950                 " Note that dgit push needs to modify the .dsc and then".
 951                 " do the signature itself";
 952         } else {
 953             last;
 954         }
 955     }
 956     return $c;
 957 }
 958
 959 sub parsecontrol {
 960     my ($file, $desc, $allowsigned) = @_;
 961     my $fh = new IO::Handle;
 962     open $fh, '<', $file or die "$file: $!";
 963     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 964     $fh->error and die $!;
 965     close $fh;
 966     return $c;
 967 }
 968
 969 sub getfield ($$) {
 970     my ($dctrl,$field) = @_;
 971     my $v = $dctrl->{$field};
 972     return $v if defined $v;
 973     fail "missing field $field in ".$dctrl->get_option('name');
 974 }
 975
 976 sub parsechangelog {
 977     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 978     my $p = new IO::Handle;
 979     my @cmd = (qw(dpkg-parsechangelog), @_);
 980     open $p, '-|', @cmd or die $!;
 981     $c->parse($p);
 982     $?=0; $!=0; close $p or failedcmd @cmd;
 983     return $c;
 984 }
 985
 986 sub commit_getclogp ($) {
 987     # Returns the parsed changelog hashref for a particular commit
 988     my ($objid) = @_;
 989     our %commit_getclogp_memo;
 990     my $memo = $commit_getclogp_memo{$objid};
 991     return $memo if $memo;
 992     mkpath '.git/dgit';
 993     my $mclog = ".git/dgit/clog-$objid";
 994     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 995         "$objid:debian/changelog";
 996     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 997 }
 998
 999 sub must_getcwd () {
1000     my $d = getcwd();
1001     defined $d or fail "getcwd failed: $!";
1002     return $d;
1003 }
1004
1005 sub parse_dscdata () {
1006     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1007     printdebug Dumper($dscdata) if $debuglevel>1;
1008     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1009     printdebug Dumper($dsc) if $debuglevel>1;
1010 }
1011
1012 our %rmad;
1013
1014 sub archive_query ($;@) {
1015     my ($method) = shift @_;
1016     fail "this operation does not support multiple comma-separated suites"
1017         if $isuite =~ m/,/;
1018     my $query = access_cfg('archive-query','RETURN-UNDEF');
1019     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1020     my $proto = $1;
1021     my $data = $'; #';
1022     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1023 }
1024
1025 sub archive_query_prepend_mirror {
1026     my $m = access_cfg('mirror');
1027     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1028 }
1029
1030 sub pool_dsc_subpath ($$) {
1031     my ($vsn,$component) = @_; # $package is implict arg
1032     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1033     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1034 }
1035
1036 sub cfg_apply_map ($$$) {
1037     my ($varref, $what, $mapspec) = @_;
1038     return unless $mapspec;
1039
1040     printdebug "config $what EVAL{ $mapspec; }\n";
1041     $_ = $$varref;
1042     eval "package Dgit::Config; $mapspec;";
1043     die $@ if $@;
1044     $$varref = $_;
1045 }
1046
1047 #---------- `ftpmasterapi' archive query method (nascent) ----------
1048
1049 sub archive_api_query_cmd ($) {
1050     my ($subpath) = @_;
1051     my @cmd = (@curl, qw(-sS));
1052     my $url = access_cfg('archive-query-url');
1053     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1054         my $host = $1;
1055         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1056         foreach my $key (split /\:/, $keys) {
1057             $key =~ s/\%HOST\%/$host/g;
1058             if (!stat $key) {
1059                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1060                 next;
1061             }
1062             fail "config requested specific TLS key but do not know".
1063                 " how to get curl to use exactly that EE key ($key)";
1064 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1065 #           # Sadly the above line does not work because of changes
1066 #           # to gnutls.   The real fix for #790093 may involve
1067 #           # new curl options.
1068             last;
1069         }
1070         # Fixing #790093 properly will involve providing a value
1071         # for this on clients.
1072         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1073         push @cmd, split / /, $kargs if defined $kargs;
1074     }
1075     push @cmd, $url.$subpath;
1076     return @cmd;
1077 }
1078
1079 sub api_query ($$;$) {
1080     use JSON;
1081     my ($data, $subpath, $ok404) = @_;
1082     badcfg "ftpmasterapi archive query method takes no data part"
1083         if length $data;
1084     my @cmd = archive_api_query_cmd($subpath);
1085     my $url = $cmd[$#cmd];
1086     push @cmd, qw(-w %{http_code});
1087     my $json = cmdoutput @cmd;
1088     unless ($json =~ s/\d+\d+\d$//) {
1089         failedcmd_report_cmd undef, @cmd;
1090         fail "curl failed to print 3-digit HTTP code";
1091     }
1092     my $code = $&;
1093     return undef if $code eq '404' && $ok404;
1094     fail "fetch of $url gave HTTP code $code"
1095         unless $url =~ m#^file://# or $code =~ m/^2/;
1096     return decode_json($json);
1097 }
1098
1099 sub canonicalise_suite_ftpmasterapi {
1100     my ($proto,$data) = @_;
1101     my $suites = api_query($data, 'suites');
1102     my @matched;
1103     foreach my $entry (@$suites) {
1104         next unless grep {
1105             my $v = $entry->{$_};
1106             defined $v && $v eq $isuite;
1107         } qw(codename name);
1108         push @matched, $entry;
1109     }
1110     fail "unknown suite $isuite" unless @matched;
1111     my $cn;
1112     eval {
1113         @matched==1 or die "multiple matches for suite $isuite\n";
1114         $cn = "$matched[0]{codename}";
1115         defined $cn or die "suite $isuite info has no codename\n";
1116         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1117     };
1118     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1119         if length $@;
1120     return $cn;
1121 }
1122
1123 sub archive_query_ftpmasterapi {
1124     my ($proto,$data) = @_;
1125     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1126     my @rows;
1127     my $digester = Digest::SHA->new(256);
1128     foreach my $entry (@$info) {
1129         eval {
1130             my $vsn = "$entry->{version}";
1131             my ($ok,$msg) = version_check $vsn;
1132             die "bad version: $msg\n" unless $ok;
1133             my $component = "$entry->{component}";
1134             $component =~ m/^$component_re$/ or die "bad component";
1135             my $filename = "$entry->{filename}";
1136             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1137                 or die "bad filename";
1138             my $sha256sum = "$entry->{sha256sum}";
1139             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1140             push @rows, [ $vsn, "/pool/$component/$filename",
1141                           $digester, $sha256sum ];
1142         };
1143         die "bad ftpmaster api response: $@\n".Dumper($entry)
1144             if length $@;
1145     }
1146     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1147     return archive_query_prepend_mirror @rows;
1148 }
1149
1150 sub file_in_archive_ftpmasterapi {
1151     my ($proto,$data,$filename) = @_;
1152     my $pat = $filename;
1153     $pat =~ s/_/\\_/g;
1154     $pat = "%/$pat";
1155     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1156     my $info = api_query($data, "file_in_archive/$pat", 1);
1157 }
1158
1159 #---------- `aptget' archive query method ----------
1160
1161 our $aptget_base;
1162 our $aptget_releasefile;
1163 our $aptget_configpath;
1164
1165 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1166 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1167
1168 sub aptget_cache_clean {
1169     runcmd_ordryrun_local qw(sh -ec),
1170         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1171         'x', $aptget_base;
1172 }
1173
1174 sub aptget_lock_acquire () {
1175     my $lockfile = "$aptget_base/lock";
1176     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1177     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1178 }
1179
1180 sub aptget_prep ($) {
1181     my ($data) = @_;
1182     return if defined $aptget_base;
1183
1184     badcfg "aptget archive query method takes no data part"
1185         if length $data;
1186
1187     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1188
1189     ensuredir $cache;
1190     ensuredir "$cache/dgit";
1191     my $cachekey =
1192         access_cfg('aptget-cachekey','RETURN-UNDEF')
1193         // access_nomdistro();
1194
1195     $aptget_base = "$cache/dgit/aptget";
1196     ensuredir $aptget_base;
1197
1198     my $quoted_base = $aptget_base;
1199     die "$quoted_base contains bad chars, cannot continue"
1200         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1201
1202     ensuredir $aptget_base;
1203
1204     aptget_lock_acquire();
1205
1206     aptget_cache_clean();
1207
1208     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1209     my $sourceslist = "source.list#$cachekey";
1210
1211     my $aptsuites = $isuite;
1212     cfg_apply_map(\$aptsuites, 'suite map',
1213                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1214
1215     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1216     printf SRCS "deb-src %s %s %s\n",
1217         access_cfg('mirror'),
1218         $aptsuites,
1219         access_cfg('aptget-components')
1220         or die $!;
1221
1222     ensuredir "$aptget_base/cache";
1223     ensuredir "$aptget_base/lists";
1224
1225     open CONF, ">", $aptget_configpath or die $!;
1226     print CONF <<END;
1227 Debug::NoLocking "true";
1228 APT::Get::List-Cleanup "false";
1229 #clear APT::Update::Post-Invoke-Success;
1230 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1231 Dir::State::Lists "$quoted_base/lists";
1232 Dir::Etc::preferences "$quoted_base/preferences";
1233 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1234 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1235 END
1236
1237     foreach my $key (qw(
1238                         Dir::Cache
1239                         Dir::State
1240                         Dir::Cache::Archives
1241                         Dir::Etc::SourceParts
1242                         Dir::Etc::preferencesparts
1243                       )) {
1244         ensuredir "$aptget_base/$key";
1245         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1246     };
1247
1248     my $oldatime = (time // die $!) - 1;
1249     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1250         next unless stat_exists $oldlist;
1251         my ($mtime) = (stat _)[9];
1252         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1253     }
1254
1255     runcmd_ordryrun_local aptget_aptget(), qw(update);
1256
1257     my @releasefiles;
1258     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1259         next unless stat_exists $oldlist;
1260         my ($atime) = (stat _)[8];
1261         next if $atime == $oldatime;
1262         push @releasefiles, $oldlist;
1263     }
1264     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1265     @releasefiles = @inreleasefiles if @inreleasefiles;
1266     die "apt updated wrong number of Release files (@releasefiles), erk"
1267         unless @releasefiles == 1;
1268
1269     ($aptget_releasefile) = @releasefiles;
1270 }
1271
1272 sub canonicalise_suite_aptget {
1273     my ($proto,$data) = @_;
1274     aptget_prep($data);
1275
1276     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1277
1278     foreach my $name (qw(Codename Suite)) {
1279         my $val = $release->{$name};
1280         if (defined $val) {
1281             printdebug "release file $name: $val\n";
1282             $val =~ m/^$suite_re$/o or fail
1283  "Release file ($aptget_releasefile) specifies intolerable $name";
1284             cfg_apply_map(\$val, 'suite rmap',
1285                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1286             return $val
1287         }
1288     }
1289     return $isuite;
1290 }
1291
1292 sub archive_query_aptget {
1293     my ($proto,$data) = @_;
1294     aptget_prep($data);
1295
1296     ensuredir "$aptget_base/source";
1297     foreach my $old (<$aptget_base/source/*.dsc>) {
1298         unlink $old or die "$old: $!";
1299     }
1300
1301     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1302     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1303     # avoids apt-get source failing with ambiguous error code
1304
1305     runcmd_ordryrun_local
1306         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1307         aptget_aptget(), qw(--download-only --only-source source), $package;
1308
1309     my @dscs = <$aptget_base/source/*.dsc>;
1310     fail "apt-get source did not produce a .dsc" unless @dscs;
1311     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1312
1313     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1314
1315     use URI::Escape;
1316     my $uri = "file://". uri_escape $dscs[0];
1317     $uri =~ s{\%2f}{/}gi;
1318     return [ (getfield $pre_dsc, 'Version'), $uri ];
1319 }
1320
1321 #---------- `dummyapicat' archive query method ----------
1322
1323 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1324 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1325
1326 sub file_in_archive_dummycatapi ($$$) {
1327     my ($proto,$data,$filename) = @_;
1328     my $mirror = access_cfg('mirror');
1329     $mirror =~ s#^file://#/# or die "$mirror ?";
1330     my @out;
1331     my @cmd = (qw(sh -ec), '
1332             cd "$1"
1333             find -name "$2" -print0 |
1334             xargs -0r sha256sum
1335         ', qw(x), $mirror, $filename);
1336     debugcmd "-|", @cmd;
1337     open FIA, "-|", @cmd or die $!;
1338     while (<FIA>) {
1339         chomp or die;
1340         printdebug "| $_\n";
1341         m/^(\w+)  (\S+)$/ or die "$_ ?";
1342         push @out, { sha256sum => $1, filename => $2 };
1343     }
1344     close FIA or die failedcmd @cmd;
1345     return \@out;
1346 }
1347
1348 #---------- `madison' archive query method ----------
1349
1350 sub archive_query_madison {
1351     return archive_query_prepend_mirror
1352         map { [ @$_[0..1] ] } madison_get_parse(@_);
1353 }
1354
1355 sub madison_get_parse {
1356     my ($proto,$data) = @_;
1357     die unless $proto eq 'madison';
1358     if (!length $data) {
1359         $data= access_cfg('madison-distro','RETURN-UNDEF');
1360         $data //= access_basedistro();
1361     }
1362     $rmad{$proto,$data,$package} ||= cmdoutput
1363         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1364     my $rmad = $rmad{$proto,$data,$package};
1365
1366     my @out;
1367     foreach my $l (split /\n/, $rmad) {
1368         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1369                   \s*( [^ \t|]+ )\s* \|
1370                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1371                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1372         $1 eq $package or die "$rmad $package ?";
1373         my $vsn = $2;
1374         my $newsuite = $3;
1375         my $component;
1376         if (defined $4) {
1377             $component = $4;
1378         } else {
1379             $component = access_cfg('archive-query-default-component');
1380         }
1381         $5 eq 'source' or die "$rmad ?";
1382         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1383     }
1384     return sort { -version_compare($a->[0],$b->[0]); } @out;
1385 }
1386
1387 sub canonicalise_suite_madison {
1388     # madison canonicalises for us
1389     my @r = madison_get_parse(@_);
1390     @r or fail
1391         "unable to canonicalise suite using package $package".
1392         " which does not appear to exist in suite $isuite;".
1393         " --existing-package may help";
1394     return $r[0][2];
1395 }
1396
1397 sub file_in_archive_madison { return undef; }
1398
1399 #---------- `sshpsql' archive query method ----------
1400
1401 sub sshpsql ($$$) {
1402     my ($data,$runeinfo,$sql) = @_;
1403     if (!length $data) {
1404         $data= access_someuserhost('sshpsql').':'.
1405             access_cfg('sshpsql-dbname');
1406     }
1407     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1408     my ($userhost,$dbname) = ($`,$'); #';
1409     my @rows;
1410     my @cmd = (access_cfg_ssh, $userhost,
1411                access_runeinfo("ssh-psql $runeinfo").
1412                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1413                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1414     debugcmd "|",@cmd;
1415     open P, "-|", @cmd or die $!;
1416     while (<P>) {
1417         chomp or die;
1418         printdebug(">|$_|\n");
1419         push @rows, $_;
1420     }
1421     $!=0; $?=0; close P or failedcmd @cmd;
1422     @rows or die;
1423     my $nrows = pop @rows;
1424     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1425     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1426     @rows = map { [ split /\|/, $_ ] } @rows;
1427     my $ncols = scalar @{ shift @rows };
1428     die if grep { scalar @$_ != $ncols } @rows;
1429     return @rows;
1430 }
1431
1432 sub sql_injection_check {
1433     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1434 }
1435
1436 sub archive_query_sshpsql ($$) {
1437     my ($proto,$data) = @_;
1438     sql_injection_check $isuite, $package;
1439     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1440         SELECT source.version, component.name, files.filename, files.sha256sum
1441           FROM source
1442           JOIN src_associations ON source.id = src_associations.source
1443           JOIN suite ON suite.id = src_associations.suite
1444           JOIN dsc_files ON dsc_files.source = source.id
1445           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1446           JOIN component ON component.id = files_archive_map.component_id
1447           JOIN files ON files.id = dsc_files.file
1448          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1449            AND source.source='$package'
1450            AND files.filename LIKE '%.dsc';
1451 END
1452     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1453     my $digester = Digest::SHA->new(256);
1454     @rows = map {
1455         my ($vsn,$component,$filename,$sha256sum) = @$_;
1456         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1457     } @rows;
1458     return archive_query_prepend_mirror @rows;
1459 }
1460
1461 sub canonicalise_suite_sshpsql ($$) {
1462     my ($proto,$data) = @_;
1463     sql_injection_check $isuite;
1464     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1465         SELECT suite.codename
1466           FROM suite where suite_name='$isuite' or codename='$isuite';
1467 END
1468     @rows = map { $_->[0] } @rows;
1469     fail "unknown suite $isuite" unless @rows;
1470     die "ambiguous $isuite: @rows ?" if @rows>1;
1471     return $rows[0];
1472 }
1473
1474 sub file_in_archive_sshpsql ($$$) { return undef; }
1475
1476 #---------- `dummycat' archive query method ----------
1477
1478 sub canonicalise_suite_dummycat ($$) {
1479     my ($proto,$data) = @_;
1480     my $dpath = "$data/suite.$isuite";
1481     if (!open C, "<", $dpath) {
1482         $!==ENOENT or die "$dpath: $!";
1483         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1484         return $isuite;
1485     }
1486     $!=0; $_ = <C>;
1487     chomp or die "$dpath: $!";
1488     close C;
1489     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1490     return $_;
1491 }
1492
1493 sub archive_query_dummycat ($$) {
1494     my ($proto,$data) = @_;
1495     canonicalise_suite();
1496     my $dpath = "$data/package.$csuite.$package";
1497     if (!open C, "<", $dpath) {
1498         $!==ENOENT or die "$dpath: $!";
1499         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1500         return ();
1501     }
1502     my @rows;
1503     while (<C>) {
1504         next if m/^\#/;
1505         next unless m/\S/;
1506         die unless chomp;
1507         printdebug "dummycat query $csuite $package $dpath | $_\n";
1508         my @row = split /\s+/, $_;
1509         @row==2 or die "$dpath: $_ ?";
1510         push @rows, \@row;
1511     }
1512     C->error and die "$dpath: $!";
1513     close C;
1514     return archive_query_prepend_mirror
1515         sort { -version_compare($a->[0],$b->[0]); } @rows;
1516 }
1517
1518 sub file_in_archive_dummycat () { return undef; }
1519
1520 #---------- tag format handling ----------
1521
1522 sub access_cfg_tagformats () {
1523     split /\,/, access_cfg('dgit-tag-format');
1524 }
1525
1526 sub access_cfg_tagformats_can_splitbrain () {
1527     my %y = map { $_ => 1 } access_cfg_tagformats;
1528     foreach my $needtf (qw(new maint)) {
1529         next if $y{$needtf};
1530         return 0;
1531     }
1532     return 1;
1533 }
1534
1535 sub need_tagformat ($$) {
1536     my ($fmt, $why) = @_;
1537     fail "need to use tag format $fmt ($why) but also need".
1538         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1539         " - no way to proceed"
1540         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1541     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1542 }
1543
1544 sub select_tagformat () {
1545     # sets $tagformatfn
1546     return if $tagformatfn && !$tagformat_want;
1547     die 'bug' if $tagformatfn && $tagformat_want;
1548     # ... $tagformat_want assigned after previous select_tagformat
1549
1550     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1551     printdebug "select_tagformat supported @supported\n";
1552
1553     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1554     printdebug "select_tagformat specified @$tagformat_want\n";
1555
1556     my ($fmt,$why,$override) = @$tagformat_want;
1557
1558     fail "target distro supports tag formats @supported".
1559         " but have to use $fmt ($why)"
1560         unless $override
1561             or grep { $_ eq $fmt } @supported;
1562
1563     $tagformat_want = undef;
1564     $tagformat = $fmt;
1565     $tagformatfn = ${*::}{"debiantag_$fmt"};
1566
1567     fail "trying to use unknown tag format \`$fmt' ($why) !"
1568         unless $tagformatfn;
1569 }
1570
1571 #---------- archive query entrypoints and rest of program ----------
1572
1573 sub canonicalise_suite () {
1574     return if defined $csuite;
1575     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1576     $csuite = archive_query('canonicalise_suite');
1577     if ($isuite ne $csuite) {
1578         progress "canonical suite name for $isuite is $csuite";
1579     } else {
1580         progress "canonical suite name is $csuite";
1581     }
1582 }
1583
1584 sub get_archive_dsc () {
1585     canonicalise_suite();
1586     my @vsns = archive_query('archive_query');
1587     foreach my $vinfo (@vsns) {
1588         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1589         $dscurl = $vsn_dscurl;
1590         $dscdata = url_get($dscurl);
1591         if (!$dscdata) {
1592             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1593             next;
1594         }
1595         if ($digester) {
1596             $digester->reset();
1597             $digester->add($dscdata);
1598             my $got = $digester->hexdigest();
1599             $got eq $digest or
1600                 fail "$dscurl has hash $got but".
1601                     " archive told us to expect $digest";
1602         }
1603         parse_dscdata();
1604         my $fmt = getfield $dsc, 'Format';
1605         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1606             "unsupported source format $fmt, sorry";
1607
1608         $dsc_checked = !!$digester;
1609         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1610         return;
1611     }
1612     $dsc = undef;
1613     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1614 }
1615
1616 sub check_for_git ();
1617 sub check_for_git () {
1618     # returns 0 or 1
1619     my $how = access_cfg('git-check');
1620     if ($how eq 'ssh-cmd') {
1621         my @cmd =
1622             (access_cfg_ssh, access_gituserhost(),
1623              access_runeinfo("git-check $package").
1624              " set -e; cd ".access_cfg('git-path').";".
1625              " if test -d $package.git; then echo 1; else echo 0; fi");
1626         my $r= cmdoutput @cmd;
1627         if (defined $r and $r =~ m/^divert (\w+)$/) {
1628             my $divert=$1;
1629             my ($usedistro,) = access_distros();
1630             # NB that if we are pushing, $usedistro will be $distro/push
1631             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1632             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1633             progress "diverting to $divert (using config for $instead_distro)";
1634             return check_for_git();
1635         }
1636         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1637         return $r+0;
1638     } elsif ($how eq 'url') {
1639         my $prefix = access_cfg('git-check-url','git-url');
1640         my $suffix = access_cfg('git-check-suffix','git-suffix',
1641                                 'RETURN-UNDEF') // '.git';
1642         my $url = "$prefix/$package$suffix";
1643         my @cmd = (@curl, qw(-sS -I), $url);
1644         my $result = cmdoutput @cmd;
1645         $result =~ s/^\S+ 200 .*\n\r?\n//;
1646         # curl -sS -I with https_proxy prints
1647         # HTTP/1.0 200 Connection established
1648         $result =~ m/^\S+ (404|200) /s or
1649             fail "unexpected results from git check query - ".
1650                 Dumper($prefix, $result);
1651         my $code = $1;
1652         if ($code eq '404') {
1653             return 0;
1654         } elsif ($code eq '200') {
1655             return 1;
1656         } else {
1657             die;
1658         }
1659     } elsif ($how eq 'true') {
1660         return 1;
1661     } elsif ($how eq 'false') {
1662         return 0;
1663     } else {
1664         badcfg "unknown git-check \`$how'";
1665     }
1666 }
1667
1668 sub create_remote_git_repo () {
1669     my $how = access_cfg('git-create');
1670     if ($how eq 'ssh-cmd') {
1671         runcmd_ordryrun
1672             (access_cfg_ssh, access_gituserhost(),
1673              access_runeinfo("git-create $package").
1674              "set -e; cd ".access_cfg('git-path').";".
1675              " cp -a _template $package.git");
1676     } elsif ($how eq 'true') {
1677         # nothing to do
1678     } else {
1679         badcfg "unknown git-create \`$how'";
1680     }
1681 }
1682
1683 our ($dsc_hash,$lastpush_mergeinput);
1684 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1685
1686 our $ud = '.git/dgit/unpack';
1687
1688 sub prep_ud (;$) {
1689     my ($d) = @_;
1690     $d //= $ud;
1691     rmtree($d);
1692     mkpath '.git/dgit';
1693     mkdir $d or die $!;
1694 }
1695
1696 sub mktree_in_ud_here () {
1697     runcmd qw(git init -q);
1698     runcmd qw(git config gc.auto 0);
1699     rmtree('.git/objects');
1700     symlink '../../../../objects','.git/objects' or die $!;
1701 }
1702
1703 sub git_write_tree () {
1704     my $tree = cmdoutput @git, qw(write-tree);
1705     $tree =~ m/^\w+$/ or die "$tree ?";
1706     return $tree;
1707 }
1708
1709 sub git_add_write_tree () {
1710     runcmd @git, qw(add -Af .);
1711     return git_write_tree();
1712 }
1713
1714 sub remove_stray_gits ($) {
1715     my ($what) = @_;
1716     my @gitscmd = qw(find -name .git -prune -print0);
1717     debugcmd "|",@gitscmd;
1718     open GITS, "-|", @gitscmd or die $!;
1719     {
1720         local $/="\0";
1721         while (<GITS>) {
1722             chomp or die;
1723             print STDERR "$us: warning: removing from $what: ",
1724                 (messagequote $_), "\n";
1725             rmtree $_;
1726         }
1727     }
1728     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1729 }
1730
1731 sub mktree_in_ud_from_only_subdir ($;$) {
1732     my ($what,$raw) = @_;
1733
1734     # changes into the subdir
1735     my (@dirs) = <*/.>;
1736     die "expected one subdir but found @dirs ?" unless @dirs==1;
1737     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1738     my $dir = $1;
1739     changedir $dir;
1740
1741     remove_stray_gits($what);
1742     mktree_in_ud_here();
1743     if (!$raw) {
1744         my ($format, $fopts) = get_source_format();
1745         if (madformat($format)) {
1746             rmtree '.pc';
1747         }
1748     }
1749
1750     my $tree=git_add_write_tree();
1751     return ($tree,$dir);
1752 }
1753
1754 our @files_csum_info_fields =
1755     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1756      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1757      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1758
1759 sub dsc_files_info () {
1760     foreach my $csumi (@files_csum_info_fields) {
1761         my ($fname, $module, $method) = @$csumi;
1762         my $field = $dsc->{$fname};
1763         next unless defined $field;
1764         eval "use $module; 1;" or die $@;
1765         my @out;
1766         foreach (split /\n/, $field) {
1767             next unless m/\S/;
1768             m/^(\w+) (\d+) (\S+)$/ or
1769                 fail "could not parse .dsc $fname line \`$_'";
1770             my $digester = eval "$module"."->$method;" or die $@;
1771             push @out, {
1772                 Hash => $1,
1773                 Bytes => $2,
1774                 Filename => $3,
1775                 Digester => $digester,
1776             };
1777         }
1778         return @out;
1779     }
1780     fail "missing any supported Checksums-* or Files field in ".
1781         $dsc->get_option('name');
1782 }
1783
1784 sub dsc_files () {
1785     map { $_->{Filename} } dsc_files_info();
1786 }
1787
1788 sub files_compare_inputs (@) {
1789     my $inputs = \@_;
1790     my %record;
1791     my %fchecked;
1792
1793     my $showinputs = sub {
1794         return join "; ", map { $_->get_option('name') } @$inputs;
1795     };
1796
1797     foreach my $in (@$inputs) {
1798         my $expected_files;
1799         my $in_name = $in->get_option('name');
1800
1801         printdebug "files_compare_inputs $in_name\n";
1802
1803         foreach my $csumi (@files_csum_info_fields) {
1804             my ($fname) = @$csumi;
1805             printdebug "files_compare_inputs $in_name $fname\n";
1806
1807             my $field = $in->{$fname};
1808             next unless defined $field;
1809
1810             my @files;
1811             foreach (split /\n/, $field) {
1812                 next unless m/\S/;
1813
1814                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1815                     fail "could not parse $in_name $fname line \`$_'";
1816
1817                 printdebug "files_compare_inputs $in_name $fname $f\n";
1818
1819                 push @files, $f;
1820
1821                 my $re = \ $record{$f}{$fname};
1822                 if (defined $$re) {
1823                     $fchecked{$f}{$in_name} = 1;
1824                     $$re eq $info or
1825                         fail "hash or size of $f varies in $fname fields".
1826                         " (between: ".$showinputs->().")";
1827                 } else {
1828                     $$re = $info;
1829                 }
1830             }
1831             @files = sort @files;
1832             $expected_files //= \@files;
1833             "@$expected_files" eq "@files" or
1834                 fail "file list in $in_name varies between hash fields!";
1835         }
1836         $expected_files or
1837             fail "$in_name has no files list field(s)";
1838     }
1839     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1840         if $debuglevel>=2;
1841
1842     grep { keys %$_ == @$inputs-1 } values %fchecked
1843         or fail "no file appears in all file lists".
1844         " (looked in: ".$showinputs->().")";
1845 }
1846
1847 sub is_orig_file_in_dsc ($$) {
1848     my ($f, $dsc_files_info) = @_;
1849     return 0 if @$dsc_files_info <= 1;
1850     # One file means no origs, and the filename doesn't have a "what
1851     # part of dsc" component.  (Consider versions ending `.orig'.)
1852     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1853     return 1;
1854 }
1855
1856 sub is_orig_file_of_vsn ($$) {
1857     my ($f, $upstreamvsn) = @_;
1858     my $base = srcfn $upstreamvsn, '';
1859     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1860     return 1;
1861 }
1862
1863 sub changes_update_origs_from_dsc ($$$$) {
1864     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1865     my %changes_f;
1866     printdebug "checking origs needed ($upstreamvsn)...\n";
1867     $_ = getfield $changes, 'Files';
1868     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1869         fail "cannot find section/priority from .changes Files field";
1870     my $placementinfo = $1;
1871     my %changed;
1872     printdebug "checking origs needed placement '$placementinfo'...\n";
1873     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1874         $l =~ m/\S+$/ or next;
1875         my $file = $&;
1876         printdebug "origs $file | $l\n";
1877         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1878         printdebug "origs $file is_orig\n";
1879         my $have = archive_query('file_in_archive', $file);
1880         if (!defined $have) {
1881             print STDERR <<END;
1882 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1883 END
1884             return;
1885         }
1886         my $found_same = 0;
1887         my @found_differ;
1888         printdebug "origs $file \$#\$have=$#$have\n";
1889         foreach my $h (@$have) {
1890             my $same = 0;
1891             my @differ;
1892             foreach my $csumi (@files_csum_info_fields) {
1893                 my ($fname, $module, $method, $archivefield) = @$csumi;
1894                 next unless defined $h->{$archivefield};
1895                 $_ = $dsc->{$fname};
1896                 next unless defined;
1897                 m/^(\w+) .* \Q$file\E$/m or
1898                     fail ".dsc $fname missing entry for $file";
1899                 if ($h->{$archivefield} eq $1) {
1900                     $same++;
1901                 } else {
1902                     push @differ,
1903  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1904                 }
1905             }
1906             die "$file ".Dumper($h)." ?!" if $same && @differ;
1907             $found_same++
1908                 if $same;
1909             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1910                 if @differ;
1911         }
1912         printdebug "origs $file f.same=$found_same".
1913             " #f._differ=$#found_differ\n";
1914         if (@found_differ && !$found_same) {
1915             fail join "\n",
1916                 "archive contains $file with different checksum",
1917                 @found_differ;
1918         }
1919         # Now we edit the changes file to add or remove it
1920         foreach my $csumi (@files_csum_info_fields) {
1921             my ($fname, $module, $method, $archivefield) = @$csumi;
1922             next unless defined $changes->{$fname};
1923             if ($found_same) {
1924                 # in archive, delete from .changes if it's there
1925                 $changed{$file} = "removed" if
1926                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1927             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1928                 # not in archive, but it's here in the .changes
1929             } else {
1930                 my $dsc_data = getfield $dsc, $fname;
1931                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1932                 my $extra = $1;
1933                 $extra =~ s/ \d+ /$&$placementinfo /
1934                     or die "$fname $extra >$dsc_data< ?"
1935                     if $fname eq 'Files';
1936                 $changes->{$fname} .= "\n". $extra;
1937                 $changed{$file} = "added";
1938             }
1939         }
1940     }
1941     if (%changed) {
1942         foreach my $file (keys %changed) {
1943             progress sprintf
1944                 "edited .changes for archive .orig contents: %s %s",
1945                 $changed{$file}, $file;
1946         }
1947         my $chtmp = "$changesfile.tmp";
1948         $changes->save($chtmp);
1949         if (act_local()) {
1950             rename $chtmp,$changesfile or die "$changesfile $!";
1951         } else {
1952             progress "[new .changes left in $changesfile]";
1953         }
1954     } else {
1955         progress "$changesfile already has appropriate .orig(s) (if any)";
1956     }
1957 }
1958
1959 sub make_commit ($) {
1960     my ($file) = @_;
1961     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1962 }
1963
1964 sub make_commit_text ($) {
1965     my ($text) = @_;
1966     my ($out, $in);
1967     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1968     debugcmd "|",@cmd;
1969     print Dumper($text) if $debuglevel > 1;
1970     my $child = open2($out, $in, @cmd) or die $!;
1971     my $h;
1972     eval {
1973         print $in $text or die $!;
1974         close $in or die $!;
1975         $h = <$out>;
1976         $h =~ m/^\w+$/ or die;
1977         $h = $&;
1978         printdebug "=> $h\n";
1979     };
1980     close $out;
1981     waitpid $child, 0 == $child or die "$child $!";
1982     $? and failedcmd @cmd;
1983     return $h;
1984 }
1985
1986 sub clogp_authline ($) {
1987     my ($clogp) = @_;
1988     my $author = getfield $clogp, 'Maintainer';
1989     $author =~ s#,.*##ms;
1990     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1991     my $authline = "$author $date";
1992     $authline =~ m/$git_authline_re/o or
1993         fail "unexpected commit author line format \`$authline'".
1994         " (was generated from changelog Maintainer field)";
1995     return ($1,$2,$3) if wantarray;
1996     return $authline;
1997 }
1998
1999 sub vendor_patches_distro ($$) {
2000     my ($checkdistro, $what) = @_;
2001     return unless defined $checkdistro;
2002
2003     my $series = "debian/patches/\L$checkdistro\E.series";
2004     printdebug "checking for vendor-specific $series ($what)\n";
2005
2006     if (!open SERIES, "<", $series) {
2007         die "$series $!" unless $!==ENOENT;
2008         return;
2009     }
2010     while (<SERIES>) {
2011         next unless m/\S/;
2012         next if m/^\s+\#/;
2013
2014         print STDERR <<END;
2015
2016 Unfortunately, this source package uses a feature of dpkg-source where
2017 the same source package unpacks to different source code on different
2018 distros.  dgit cannot safely operate on such packages on affected
2019 distros, because the meaning of source packages is not stable.
2020
2021 Please ask the distro/maintainer to remove the distro-specific series
2022 files and use a different technique (if necessary, uploading actually
2023 different packages, if different distros are supposed to have
2024 different code).
2025
2026 END
2027         fail "Found active distro-specific series file for".
2028             " $checkdistro ($what): $series, cannot continue";
2029     }
2030     die "$series $!" if SERIES->error;
2031     close SERIES;
2032 }
2033
2034 sub check_for_vendor_patches () {
2035     # This dpkg-source feature doesn't seem to be documented anywhere!
2036     # But it can be found in the changelog (reformatted):
2037
2038     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2039     #   Author: Raphael Hertzog <hertzog@debian.org>
2040     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2041
2042     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2043     #   series files
2044     #
2045     #   If you have debian/patches/ubuntu.series and you were
2046     #   unpacking the source package on ubuntu, quilt was still
2047     #   directed to debian/patches/series instead of
2048     #   debian/patches/ubuntu.series.
2049     #
2050     #   debian/changelog                        |    3 +++
2051     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2052     #   2 files changed, 6 insertions(+), 1 deletion(-)
2053
2054     use Dpkg::Vendor;
2055     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2056     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2057                          "Dpkg::Vendor \`current vendor'");
2058     vendor_patches_distro(access_basedistro(),
2059                           "(base) distro being accessed");
2060     vendor_patches_distro(access_nomdistro(),
2061                           "(nominal) distro being accessed");
2062 }
2063
2064 sub generate_commits_from_dsc () {
2065     # See big comment in fetch_from_archive, below.
2066     # See also README.dsc-import.
2067     prep_ud();
2068     changedir $ud;
2069
2070     my @dfi = dsc_files_info();
2071     foreach my $fi (@dfi) {
2072         my $f = $fi->{Filename};
2073         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2074         my $upper_f = "../../../../$f";
2075
2076         printdebug "considering reusing $f: ";
2077
2078         if (link_ltarget "$upper_f,fetch", $f) {
2079             printdebug "linked (using ...,fetch).\n";
2080         } elsif ((printdebug "($!) "),
2081                  $! != ENOENT) {
2082             fail "accessing ../$f,fetch: $!";
2083         } elsif (link_ltarget $upper_f, $f) {
2084             printdebug "linked.\n";
2085         } elsif ((printdebug "($!) "),
2086                  $! != ENOENT) {
2087             fail "accessing ../$f: $!";
2088         } else {
2089             printdebug "absent.\n";
2090         }
2091
2092         my $refetched;
2093         complete_file_from_dsc('.', $fi, \$refetched)
2094             or next;
2095
2096         printdebug "considering saving $f: ";
2097
2098         if (link $f, $upper_f) {
2099             printdebug "linked.\n";
2100         } elsif ((printdebug "($!) "),
2101                  $! != EEXIST) {
2102             fail "saving ../$f: $!";
2103         } elsif (!$refetched) {
2104             printdebug "no need.\n";
2105         } elsif (link $f, "$upper_f,fetch") {
2106             printdebug "linked (using ...,fetch).\n";
2107         } elsif ((printdebug "($!) "),
2108                  $! != EEXIST) {
2109             fail "saving ../$f,fetch: $!";
2110         } else {
2111             printdebug "cannot.\n";
2112         }
2113     }
2114
2115     # We unpack and record the orig tarballs first, so that we only
2116     # need disk space for one private copy of the unpacked source.
2117     # But we can't make them into commits until we have the metadata
2118     # from the debian/changelog, so we record the tree objects now and
2119     # make them into commits later.
2120     my @tartrees;
2121     my $upstreamv = upstreamversion $dsc->{version};
2122     my $orig_f_base = srcfn $upstreamv, '';
2123
2124     foreach my $fi (@dfi) {
2125         # We actually import, and record as a commit, every tarball
2126         # (unless there is only one file, in which case there seems
2127         # little point.
2128
2129         my $f = $fi->{Filename};
2130         printdebug "import considering $f ";
2131         (printdebug "only one dfi\n"), next if @dfi == 1;
2132         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2133         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2134         my $compr_ext = $1;
2135
2136         my ($orig_f_part) =
2137             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2138
2139         printdebug "Y ", (join ' ', map { $_//"(none)" }
2140                           $compr_ext, $orig_f_part
2141                          ), "\n";
2142
2143         my $input = new IO::File $f, '<' or die "$f $!";
2144         my $compr_pid;
2145         my @compr_cmd;
2146
2147         if (defined $compr_ext) {
2148             my $cname =
2149                 Dpkg::Compression::compression_guess_from_filename $f;
2150             fail "Dpkg::Compression cannot handle file $f in source package"
2151                 if defined $compr_ext && !defined $cname;
2152             my $compr_proc =
2153                 new Dpkg::Compression::Process compression => $cname;
2154             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2155             my $compr_fh = new IO::Handle;
2156             my $compr_pid = open $compr_fh, "-|" // die $!;
2157             if (!$compr_pid) {
2158                 open STDIN, "<&", $input or die $!;
2159                 exec @compr_cmd;
2160                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2161             }
2162             $input = $compr_fh;
2163         }
2164
2165         rmtree "_unpack-tar";
2166         mkdir "_unpack-tar" or die $!;
2167         my @tarcmd = qw(tar -x -f -
2168                         --no-same-owner --no-same-permissions
2169                         --no-acls --no-xattrs --no-selinux);
2170         my $tar_pid = fork // die $!;
2171         if (!$tar_pid) {
2172             chdir "_unpack-tar" or die $!;
2173             open STDIN, "<&", $input or die $!;
2174             exec @tarcmd;
2175             die "dgit (child): exec $tarcmd[0]: $!";
2176         }
2177         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2178         !$? or failedcmd @tarcmd;
2179
2180         close $input or
2181             (@compr_cmd ? failedcmd @compr_cmd
2182              : die $!);
2183         # finally, we have the results in "tarball", but maybe
2184         # with the wrong permissions
2185
2186         runcmd qw(chmod -R +rwX _unpack-tar);
2187         changedir "_unpack-tar";
2188         remove_stray_gits($f);
2189         mktree_in_ud_here();
2190
2191         my ($tree) = git_add_write_tree();
2192         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2193         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2194             $tree = $1;
2195             printdebug "one subtree $1\n";
2196         } else {
2197             printdebug "multiple subtrees\n";
2198         }
2199         changedir "..";
2200         rmtree "_unpack-tar";
2201
2202         my $ent = [ $f, $tree ];
2203         push @tartrees, {
2204             Orig => !!$orig_f_part,
2205             Sort => (!$orig_f_part         ? 2 :
2206                      $orig_f_part =~ m/-/g ? 1 :
2207                                              0),
2208             F => $f,
2209             Tree => $tree,
2210         };
2211     }
2212
2213     @tartrees = sort {
2214         # put any without "_" first (spec is not clear whether files
2215         # are always in the usual order).  Tarballs without "_" are
2216         # the main orig or the debian tarball.
2217         $a->{Sort} <=> $b->{Sort} or
2218         $a->{F}    cmp $b->{F}
2219     } @tartrees;
2220
2221     my $any_orig = grep { $_->{Orig} } @tartrees;
2222
2223     my $dscfn = "$package.dsc";
2224
2225     my $treeimporthow = 'package';
2226
2227     open D, ">", $dscfn or die "$dscfn: $!";
2228     print D $dscdata or die "$dscfn: $!";
2229     close D or die "$dscfn: $!";
2230     my @cmd = qw(dpkg-source);
2231     push @cmd, '--no-check' if $dsc_checked;
2232     if (madformat $dsc->{format}) {
2233         push @cmd, '--skip-patches';
2234         $treeimporthow = 'unpatched';
2235     }
2236     push @cmd, qw(-x --), $dscfn;
2237     runcmd @cmd;
2238
2239     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2240     if (madformat $dsc->{format}) {
2241         check_for_vendor_patches();
2242     }
2243
2244     my $dappliedtree;
2245     if (madformat $dsc->{format}) {
2246         my @pcmd = qw(dpkg-source --before-build .);
2247         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2248         rmtree '.pc';
2249         $dappliedtree = git_add_write_tree();
2250     }
2251
2252     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2253     debugcmd "|",@clogcmd;
2254     open CLOGS, "-|", @clogcmd or die $!;
2255
2256     my $clogp;
2257     my $r1clogp;
2258
2259     printdebug "import clog search...\n";
2260
2261     for (;;) {
2262         my $stanzatext = do { local $/=""; <CLOGS>; };
2263         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2264         last if !defined $stanzatext;
2265
2266         my $desc = "package changelog, entry no.$.";
2267         open my $stanzafh, "<", \$stanzatext or die;
2268         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2269         $clogp //= $thisstanza;
2270
2271         printdebug "import clog $thisstanza->{version} $desc...\n";
2272
2273         last if !$any_orig; # we don't need $r1clogp
2274
2275         # We look for the first (most recent) changelog entry whose
2276         # version number is lower than the upstream version of this
2277         # package.  Then the last (least recent) previous changelog
2278         # entry is treated as the one which introduced this upstream
2279         # version and used for the synthetic commits for the upstream
2280         # tarballs.
2281
2282         # One might think that a more sophisticated algorithm would be
2283         # necessary.  But: we do not want to scan the whole changelog
2284         # file.  Stopping when we see an earlier version, which
2285         # necessarily then is an earlier upstream version, is the only
2286         # realistic way to do that.  Then, either the earliest
2287         # changelog entry we have seen so far is indeed the earliest
2288         # upload of this upstream version; or there are only changelog
2289         # entries relating to later upstream versions (which is not
2290         # possible unless the changelog and .dsc disagree about the
2291         # version).  Then it remains to choose between the physically
2292         # last entry in the file, and the one with the lowest version
2293         # number.  If these are not the same, we guess that the
2294         # versions were created in a non-monotic order rather than
2295         # that the changelog entries have been misordered.
2296
2297         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2298
2299         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2300         $r1clogp = $thisstanza;
2301
2302         printdebug "import clog $r1clogp->{version} becomes r1\n";
2303     }
2304     die $! if CLOGS->error;
2305     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2306
2307     $clogp or fail "package changelog has no entries!";
2308
2309     my $authline = clogp_authline $clogp;
2310     my $changes = getfield $clogp, 'Changes';
2311     my $cversion = getfield $clogp, 'Version';
2312
2313     if (@tartrees) {
2314         $r1clogp //= $clogp; # maybe there's only one entry;
2315         my $r1authline = clogp_authline $r1clogp;
2316         # Strictly, r1authline might now be wrong if it's going to be
2317         # unused because !$any_orig.  Whatever.
2318
2319         printdebug "import tartrees authline   $authline\n";
2320         printdebug "import tartrees r1authline $r1authline\n";
2321
2322         foreach my $tt (@tartrees) {
2323             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2324
2325             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2326 tree $tt->{Tree}
2327 author $r1authline
2328 committer $r1authline
2329
2330 Import $tt->{F}
2331
2332 [dgit import orig $tt->{F}]
2333 END_O
2334 tree $tt->{Tree}
2335 author $authline
2336 committer $authline
2337
2338 Import $tt->{F}
2339
2340 [dgit import tarball $package $cversion $tt->{F}]
2341 END_T
2342         }
2343     }
2344
2345     printdebug "import main commit\n";
2346
2347     open C, ">../commit.tmp" or die $!;
2348     print C <<END or die $!;
2349 tree $tree
2350 END
2351     print C <<END or die $! foreach @tartrees;
2352 parent $_->{Commit}
2353 END
2354     print C <<END or die $!;
2355 author $authline
2356 committer $authline
2357
2358 $changes
2359
2360 [dgit import $treeimporthow $package $cversion]
2361 END
2362
2363     close C or die $!;
2364     my $rawimport_hash = make_commit qw(../commit.tmp);
2365
2366     if (madformat $dsc->{format}) {
2367         printdebug "import apply patches...\n";
2368
2369         # regularise the state of the working tree so that
2370         # the checkout of $rawimport_hash works nicely.
2371         my $dappliedcommit = make_commit_text(<<END);
2372 tree $dappliedtree
2373 author $authline
2374 committer $authline
2375
2376 [dgit dummy commit]
2377 END
2378         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2379
2380         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2381
2382         # We need the answers to be reproducible
2383         my @authline = clogp_authline($clogp);
2384         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2385         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2386         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2387         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2388         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2389         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2390
2391         my $path = $ENV{PATH} or die;
2392
2393         foreach my $use_absurd (qw(0 1)) {
2394             runcmd @git, qw(checkout -q unpa);
2395             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2396             local $ENV{PATH} = $path;
2397             if ($use_absurd) {
2398                 chomp $@;
2399                 progress "warning: $@";
2400                 $path = "$absurdity:$path";
2401                 progress "$us: trying slow absurd-git-apply...";
2402                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2403                     or $!==ENOENT
2404                     or die $!;
2405             }
2406             eval {
2407                 die "forbid absurd git-apply\n" if $use_absurd
2408                     && forceing [qw(import-gitapply-no-absurd)];
2409                 die "only absurd git-apply!\n" if !$use_absurd
2410                     && forceing [qw(import-gitapply-absurd)];
2411
2412                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2413                 local $ENV{PATH} = $path                    if $use_absurd;
2414
2415                 my @showcmd = (gbp_pq, qw(import));
2416                 my @realcmd = shell_cmd
2417                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2418                 debugcmd "+",@realcmd;
2419                 if (system @realcmd) {
2420                     die +(shellquote @showcmd).
2421                         " failed: ".
2422                         failedcmd_waitstatus()."\n";
2423                 }
2424
2425                 my $gapplied = git_rev_parse('HEAD');
2426                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2427                 $gappliedtree eq $dappliedtree or
2428                     fail <<END;
2429 gbp-pq import and dpkg-source disagree!
2430  gbp-pq import gave commit $gapplied
2431  gbp-pq import gave tree $gappliedtree
2432  dpkg-source --before-build gave tree $dappliedtree
2433 END
2434                 $rawimport_hash = $gapplied;
2435             };
2436             last unless $@;
2437         }
2438         if ($@) {
2439             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2440             die $@;
2441         }
2442     }
2443
2444     progress "synthesised git commit from .dsc $cversion";
2445
2446     my $rawimport_mergeinput = {
2447         Commit => $rawimport_hash,
2448         Info => "Import of source package",
2449     };
2450     my @output = ($rawimport_mergeinput);
2451
2452     if ($lastpush_mergeinput) {
2453         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2454         my $oversion = getfield $oldclogp, 'Version';
2455         my $vcmp =
2456             version_compare($oversion, $cversion);
2457         if ($vcmp < 0) {
2458             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2459                 { Message => <<END, ReverseParents => 1 });
2460 Record $package ($cversion) in archive suite $csuite
2461 END
2462         } elsif ($vcmp > 0) {
2463             print STDERR <<END or die $!;
2464
2465 Version actually in archive:   $cversion (older)
2466 Last version pushed with dgit: $oversion (newer or same)
2467 $later_warning_msg
2468 END
2469             @output = $lastpush_mergeinput;
2470         } else {
2471             # Same version.  Use what's in the server git branch,
2472             # discarding our own import.  (This could happen if the
2473             # server automatically imports all packages into git.)
2474             @output = $lastpush_mergeinput;
2475         }
2476     }
2477     changedir '../../../..';
2478     rmtree($ud);
2479     return @output;
2480 }
2481
2482 sub complete_file_from_dsc ($$;$) {
2483     our ($dstdir, $fi, $refetched) = @_;
2484     # Ensures that we have, in $dstdir, the file $fi, with the correct
2485     # contents.  (Downloading it from alongside $dscurl if necessary.)
2486     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2487     # and will set $$refetched=1 if it did so (or tried to).
2488
2489     my $f = $fi->{Filename};
2490     my $tf = "$dstdir/$f";
2491     my $downloaded = 0;
2492
2493     my $got;
2494     my $checkhash = sub {
2495         open F, "<", "$tf" or die "$tf: $!";
2496         $fi->{Digester}->reset();
2497         $fi->{Digester}->addfile(*F);
2498         F->error and die $!;
2499         my $got = $fi->{Digester}->hexdigest();
2500         return $got eq $fi->{Hash};
2501     };
2502
2503     if (stat_exists $tf) {
2504         if ($checkhash->()) {
2505             progress "using existing $f";
2506             return 1;
2507         }
2508         if (!$refetched) {
2509             fail "file $f has hash $got but .dsc".
2510                 " demands hash $fi->{Hash} ".
2511                 "(perhaps you should delete this file?)";
2512         }
2513         progress "need to fetch correct version of $f";
2514         unlink $tf or die "$tf $!";
2515         $$refetched = 1;
2516     } else {
2517         printdebug "$tf does not exist, need to fetch\n";
2518     }
2519
2520     my $furl = $dscurl;
2521     $furl =~ s{/[^/]+$}{};
2522     $furl .= "/$f";
2523     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2524     die "$f ?" if $f =~ m#/#;
2525     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2526     return 0 if !act_local();
2527
2528     $checkhash->() or
2529         fail "file $f has hash $got but .dsc".
2530             " demands hash $fi->{Hash} ".
2531             "(got wrong file from archive!)";
2532
2533     return 1;
2534 }
2535
2536 sub ensure_we_have_orig () {
2537     my @dfi = dsc_files_info();
2538     foreach my $fi (@dfi) {
2539         my $f = $fi->{Filename};
2540         next unless is_orig_file_in_dsc($f, \@dfi);
2541         complete_file_from_dsc('..', $fi)
2542             or next;
2543     }
2544 }
2545
2546 #---------- git fetch ----------
2547
2548 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2549 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2550
2551 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2552 # locally fetched refs because they have unhelpful names and clutter
2553 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2554 # whether we have made another local ref which refers to this object).
2555 #
2556 # (If we deleted them unconditionally, then we might end up
2557 # re-fetching the same git objects each time dgit fetch was run.)
2558 #
2559 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2560 # in git_fetch_us to fetch the refs in question, and possibly a call
2561 # to lrfetchref_used.
2562
2563 our (%lrfetchrefs_f, %lrfetchrefs_d);
2564 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2565
2566 sub lrfetchref_used ($) {
2567     my ($fullrefname) = @_;
2568     my $objid = $lrfetchrefs_f{$fullrefname};
2569     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2570 }
2571
2572 sub git_lrfetch_sane {
2573     my ($supplementary, @specs) = @_;
2574     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2575     # at least as regards @specs.  Also leave the results in
2576     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2577     # able to clean these up.
2578     #
2579     # With $supplementary==1, @specs must not contain wildcards
2580     # and we add to our previous fetches (non-atomically).
2581
2582     # This is rather miserable:
2583     # When git fetch --prune is passed a fetchspec ending with a *,
2584     # it does a plausible thing.  If there is no * then:
2585     # - it matches subpaths too, even if the supplied refspec
2586     #   starts refs, and behaves completely madly if the source
2587     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2588     # - if there is no matching remote ref, it bombs out the whole
2589     #   fetch.
2590     # We want to fetch a fixed ref, and we don't know in advance
2591     # if it exists, so this is not suitable.
2592     #
2593     # Our workaround is to use git ls-remote.  git ls-remote has its
2594     # own qairks.  Notably, it has the absurd multi-tail-matching
2595     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2596     # refs/refs/foo etc.
2597     #
2598     # Also, we want an idempotent snapshot, but we have to make two
2599     # calls to the remote: one to git ls-remote and to git fetch.  The
2600     # solution is use git ls-remote to obtain a target state, and
2601     # git fetch to try to generate it.  If we don't manage to generate
2602     # the target state, we try again.
2603
2604     my $url = access_giturl();
2605
2606     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2607
2608     my $specre = join '|', map {
2609         my $x = $_;
2610         $x =~ s/\W/\\$&/g;
2611         my $wildcard = $x =~ s/\\\*$/.*/;
2612         die if $wildcard && $supplementary;
2613         "(?:refs/$x)";
2614     } @specs;
2615     printdebug "git_lrfetch_sane specre=$specre\n";
2616     my $wanted_rref = sub {
2617         local ($_) = @_;
2618         return m/^(?:$specre)$/;
2619     };
2620
2621     my $fetch_iteration = 0;
2622     FETCH_ITERATION:
2623     for (;;) {
2624         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2625         if (++$fetch_iteration > 10) {
2626             fail "too many iterations trying to get sane fetch!";
2627         }
2628
2629         my @look = map { "refs/$_" } @specs;
2630         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2631         debugcmd "|",@lcmd;
2632
2633         my %wantr;
2634         open GITLS, "-|", @lcmd or die $!;
2635         while (<GITLS>) {
2636             printdebug "=> ", $_;
2637             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2638             my ($objid,$rrefname) = ($1,$2);
2639             if (!$wanted_rref->($rrefname)) {
2640                 print STDERR <<END;
2641 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2642 END
2643                 next;
2644             }
2645             $wantr{$rrefname} = $objid;
2646         }
2647         $!=0; $?=0;
2648         close GITLS or failedcmd @lcmd;
2649
2650         # OK, now %want is exactly what we want for refs in @specs
2651         my @fspecs = map {
2652             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2653             "+refs/$_:".lrfetchrefs."/$_";
2654         } @specs;
2655
2656         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2657
2658         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2659         runcmd_ordryrun_local @fcmd if @fspecs;
2660
2661         if (!$supplementary) {
2662             %lrfetchrefs_f = ();
2663         }
2664         my %objgot;
2665
2666         git_for_each_ref(lrfetchrefs, sub {
2667             my ($objid,$objtype,$lrefname,$reftail) = @_;
2668             $lrfetchrefs_f{$lrefname} = $objid;
2669             $objgot{$objid} = 1;
2670         });
2671
2672         if ($supplementary) {
2673             last;
2674         }
2675
2676         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2677             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2678             if (!exists $wantr{$rrefname}) {
2679                 if ($wanted_rref->($rrefname)) {
2680                     printdebug <<END;
2681 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2682 END
2683                 } else {
2684                     print STDERR <<END
2685 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2686 END
2687                 }
2688                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2689                 delete $lrfetchrefs_f{$lrefname};
2690                 next;
2691             }
2692         }
2693         foreach my $rrefname (sort keys %wantr) {
2694             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2695             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2696             my $want = $wantr{$rrefname};
2697             next if $got eq $want;
2698             if (!defined $objgot{$want}) {
2699                 print STDERR <<END;
2700 warning: git ls-remote suggests we want $lrefname
2701 warning:  and it should refer to $want
2702 warning:  but git fetch didn't fetch that object to any relevant ref.
2703 warning:  This may be due to a race with someone updating the server.
2704 warning:  Will try again...
2705 END
2706                 next FETCH_ITERATION;
2707             }
2708             printdebug <<END;
2709 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2710 END
2711             runcmd_ordryrun_local @git, qw(update-ref -m),
2712                 "dgit fetch git fetch fixup", $lrefname, $want;
2713             $lrfetchrefs_f{$lrefname} = $want;
2714         }
2715         last;
2716     }
2717
2718     if (defined $csuite) {
2719         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2720         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2721             my ($objid,$objtype,$lrefname,$reftail) = @_;
2722             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2723             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2724         });
2725     }
2726
2727     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2728         Dumper(\%lrfetchrefs_f);
2729 }
2730
2731 sub git_fetch_us () {
2732     # Want to fetch only what we are going to use, unless
2733     # deliberately-not-ff, in which case we must fetch everything.
2734
2735     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2736         map { "tags/$_" }
2737         (quiltmode_splitbrain
2738          ? (map { $_->('*',access_nomdistro) }
2739             \&debiantag_new, \&debiantag_maintview)
2740          : debiantags('*',access_nomdistro));
2741     push @specs, server_branch($csuite);
2742     push @specs, $rewritemap;
2743     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2744
2745     git_lrfetch_sane 0, @specs;
2746
2747     my %here;
2748     my @tagpats = debiantags('*',access_nomdistro);
2749
2750     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2751         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2752         printdebug "currently $fullrefname=$objid\n";
2753         $here{$fullrefname} = $objid;
2754     });
2755     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2756         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2757         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2758         printdebug "offered $lref=$objid\n";
2759         if (!defined $here{$lref}) {
2760             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2761             runcmd_ordryrun_local @upd;
2762             lrfetchref_used $fullrefname;
2763         } elsif ($here{$lref} eq $objid) {
2764             lrfetchref_used $fullrefname;
2765         } else {
2766             print STDERR
2767                 "Not updating $lref from $here{$lref} to $objid.\n";
2768         }
2769     });
2770 }
2771
2772 #---------- dsc and archive handling ----------
2773
2774 sub mergeinfo_getclogp ($) {
2775     # Ensures thit $mi->{Clogp} exists and returns it
2776     my ($mi) = @_;
2777     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2778 }
2779
2780 sub mergeinfo_version ($) {
2781     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2782 }
2783
2784 sub fetch_from_archive_record_1 ($) {
2785     my ($hash) = @_;
2786     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2787             'DGIT_ARCHIVE', $hash;
2788     cmdoutput @git, qw(log -n2), $hash;
2789     # ... gives git a chance to complain if our commit is malformed
2790 }
2791
2792 sub fetch_from_archive_record_2 ($) {
2793     my ($hash) = @_;
2794     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2795     if (act_local()) {
2796         cmdoutput @upd_cmd;
2797     } else {
2798         dryrun_report @upd_cmd;
2799     }
2800 }
2801
2802 sub parse_dsc_field_def_dsc_distro () {
2803     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2804                            dgit.default.distro);
2805 }
2806
2807 sub parse_dsc_field ($$) {
2808     my ($dsc, $what) = @_;
2809     my $f;
2810     foreach my $field (@ourdscfield) {
2811         $f = $dsc->{$field};
2812         last if defined $f;
2813     }
2814
2815     if (!defined $f) {
2816         progress "$what: NO git hash";
2817         parse_dsc_field_def_dsc_distro();
2818     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2819              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2820         progress "$what: specified git info ($dsc_distro)";
2821         $dsc_hint_tag = [ $dsc_hint_tag ];
2822     } elsif ($f =~ m/^\w+\s*$/) {
2823         $dsc_hash = $&;
2824         parse_dsc_field_def_dsc_distro();
2825         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2826                           $dsc_distro ];
2827         progress "$what: specified git hash";
2828     } else {
2829         fail "$what: invalid Dgit info";
2830     }
2831 }
2832
2833 sub resolve_dsc_field_commit ($$) {
2834     my ($already_distro, $already_mapref) = @_;
2835
2836     return unless defined $dsc_hash;
2837
2838     my $mapref =
2839         defined $already_mapref &&
2840         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2841         ? $already_mapref : undef;
2842
2843     my $do_fetch;
2844     $do_fetch = sub {
2845         my ($what, @fetch) = @_;
2846
2847         local $idistro = $dsc_distro;
2848         my $lrf = lrfetchrefs;
2849
2850         if (!$chase_dsc_distro) {
2851             progress
2852                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2853             return 0;
2854         }
2855
2856         progress
2857             ".dsc names distro $dsc_distro: fetching $what";
2858
2859         my $url = access_giturl();
2860         if (!defined $url) {
2861             defined $dsc_hint_url or fail <<END;
2862 .dsc Dgit metadata is in context of distro $dsc_distro
2863 for which we have no configured url and .dsc provides no hint
2864 END
2865             my $proto =
2866                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2867                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2868             parse_cfg_bool "dsc-url-proto-ok", 'false',
2869                 cfg("dgit.dsc-url-proto-ok.$proto",
2870                     "dgit.default.dsc-url-proto-ok")
2871                 or fail <<END;
2872 .dsc Dgit metadata is in context of distro $dsc_distro
2873 for which we have no configured url;
2874 .dsc provices hinted url with protocol $proto which is unsafe.
2875 (can be overridden by config - consult documentation)
2876 END
2877             $url = $dsc_hint_url;
2878         }
2879
2880         git_lrfetch_sane 1, @fetch;
2881
2882         return $lrf;
2883     };
2884
2885     my $rewrite_enable = do {
2886         local $idistro = $dsc_distro;
2887         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2888     };
2889
2890     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2891         if (!defined $mapref) {
2892             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2893             $mapref = $lrf.'/'.$rewritemap;
2894         }
2895         my $rewritemapdata = git_cat_file $mapref.':map';
2896         if (defined $rewritemapdata
2897             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2898             progress
2899                 "server's git history rewrite map contains a relevant entry!";
2900
2901             $dsc_hash = $1;
2902             if (defined $dsc_hash) {
2903                 progress "using rewritten git hash in place of .dsc value";
2904             } else {
2905                 progress "server data says .dsc hash is to be disregarded";
2906             }
2907         }
2908     }
2909
2910     if (!defined git_cat_file $dsc_hash) {
2911         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2912         my $lrf = $do_fetch->("additional commits", @tags) &&
2913             defined git_cat_file $dsc_hash
2914             or fail <<END;
2915 .dsc Dgit metadata requires commit $dsc_hash
2916 but we could not obtain that object anywhere.
2917 END
2918         foreach my $t (@tags) {
2919             my $fullrefname = $lrf.'/'.$t;
2920 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2921             next unless $lrfetchrefs_f{$fullrefname};
2922             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2923             lrfetchref_used $fullrefname;
2924         }
2925     }
2926 }
2927
2928 sub fetch_from_archive () {
2929     ensure_setup_existing_tree();
2930
2931     # Ensures that lrref() is what is actually in the archive, one way
2932     # or another, according to us - ie this client's
2933     # appropritaely-updated archive view.  Also returns the commit id.
2934     # If there is nothing in the archive, leaves lrref alone and
2935     # returns undef.  git_fetch_us must have already been called.
2936     get_archive_dsc();
2937
2938     if ($dsc) {
2939         parse_dsc_field($dsc, 'last upload to archive');
2940         resolve_dsc_field_commit access_basedistro,
2941             lrfetchrefs."/".$rewritemap
2942     } else {
2943         progress "no version available from the archive";
2944     }
2945
2946     # If the archive's .dsc has a Dgit field, there are three
2947     # relevant git commitids we need to choose between and/or merge
2948     # together:
2949     #   1. $dsc_hash: the Dgit field from the archive
2950     #   2. $lastpush_hash: the suite branch on the dgit git server
2951     #   3. $lastfetch_hash: our local tracking brach for the suite
2952     #
2953     # These may all be distinct and need not be in any fast forward
2954     # relationship:
2955     #
2956     # If the dsc was pushed to this suite, then the server suite
2957     # branch will have been updated; but it might have been pushed to
2958     # a different suite and copied by the archive.  Conversely a more
2959     # recent version may have been pushed with dgit but not appeared
2960     # in the archive (yet).
2961     #
2962     # $lastfetch_hash may be awkward because archive imports
2963     # (particularly, imports of Dgit-less .dscs) are performed only as
2964     # needed on individual clients, so different clients may perform a
2965     # different subset of them - and these imports are only made
2966     # public during push.  So $lastfetch_hash may represent a set of
2967     # imports different to a subsequent upload by a different dgit
2968     # client.
2969     #
2970     # Our approach is as follows:
2971     #
2972     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2973     # descendant of $dsc_hash, then it was pushed by a dgit user who
2974     # had based their work on $dsc_hash, so we should prefer it.
2975     # Otherwise, $dsc_hash was installed into this suite in the
2976     # archive other than by a dgit push, and (necessarily) after the
2977     # last dgit push into that suite (since a dgit push would have
2978     # been descended from the dgit server git branch); thus, in that
2979     # case, we prefer the archive's version (and produce a
2980     # pseudo-merge to overwrite the dgit server git branch).
2981     #
2982     # (If there is no Dgit field in the archive's .dsc then
2983     # generate_commit_from_dsc uses the version numbers to decide
2984     # whether the suite branch or the archive is newer.  If the suite
2985     # branch is newer it ignores the archive's .dsc; otherwise it
2986     # generates an import of the .dsc, and produces a pseudo-merge to
2987     # overwrite the suite branch with the archive contents.)
2988     #
2989     # The outcome of that part of the algorithm is the `public view',
2990     # and is same for all dgit clients: it does not depend on any
2991     # unpublished history in the local tracking branch.
2992     #
2993     # As between the public view and the local tracking branch: The
2994     # local tracking branch is only updated by dgit fetch, and
2995     # whenever dgit fetch runs it includes the public view in the
2996     # local tracking branch.  Therefore if the public view is not
2997     # descended from the local tracking branch, the local tracking
2998     # branch must contain history which was imported from the archive
2999     # but never pushed; and, its tip is now out of date.  So, we make
3000     # a pseudo-merge to overwrite the old imports and stitch the old
3001     # history in.
3002     #
3003     # Finally: we do not necessarily reify the public view (as
3004     # described above).  This is so that we do not end up stacking two
3005     # pseudo-merges.  So what we actually do is figure out the inputs
3006     # to any public view pseudo-merge and put them in @mergeinputs.
3007
3008     my @mergeinputs;
3009     # $mergeinputs[]{Commit}
3010     # $mergeinputs[]{Info}
3011     # $mergeinputs[0] is the one whose tree we use
3012     # @mergeinputs is in the order we use in the actual commit)
3013     #
3014     # Also:
3015     # $mergeinputs[]{Message} is a commit message to use
3016     # $mergeinputs[]{ReverseParents} if def specifies that parent
3017     #                                list should be in opposite order
3018     # Such an entry has no Commit or Info.  It applies only when found
3019     # in the last entry.  (This ugliness is to support making
3020     # identical imports to previous dgit versions.)
3021
3022     my $lastpush_hash = git_get_ref(lrfetchref());
3023     printdebug "previous reference hash=$lastpush_hash\n";
3024     $lastpush_mergeinput = $lastpush_hash && {
3025         Commit => $lastpush_hash,
3026         Info => "dgit suite branch on dgit git server",
3027     };
3028
3029     my $lastfetch_hash = git_get_ref(lrref());
3030     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3031     my $lastfetch_mergeinput = $lastfetch_hash && {
3032         Commit => $lastfetch_hash,
3033         Info => "dgit client's archive history view",
3034     };
3035
3036     my $dsc_mergeinput = $dsc_hash && {
3037         Commit => $dsc_hash,
3038         Info => "Dgit field in .dsc from archive",
3039     };
3040
3041     my $cwd = getcwd();
3042     my $del_lrfetchrefs = sub {
3043         changedir $cwd;
3044         my $gur;
3045         printdebug "del_lrfetchrefs...\n";
3046         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3047             my $objid = $lrfetchrefs_d{$fullrefname};
3048             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3049             if (!$gur) {
3050                 $gur ||= new IO::Handle;
3051                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3052             }
3053             printf $gur "delete %s %s\n", $fullrefname, $objid;
3054         }
3055         if ($gur) {
3056             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3057         }
3058     };
3059
3060     if (defined $dsc_hash) {
3061         ensure_we_have_orig();
3062         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3063             @mergeinputs = $dsc_mergeinput
3064         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3065             print STDERR <<END or die $!;
3066
3067 Git commit in archive is behind the last version allegedly pushed/uploaded.
3068 Commit referred to by archive: $dsc_hash
3069 Last version pushed with dgit: $lastpush_hash
3070 $later_warning_msg
3071 END
3072             @mergeinputs = ($lastpush_mergeinput);
3073         } else {
3074             # Archive has .dsc which is not a descendant of the last dgit
3075             # push.  This can happen if the archive moves .dscs about.
3076             # Just follow its lead.
3077             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3078                 progress "archive .dsc names newer git commit";
3079                 @mergeinputs = ($dsc_mergeinput);
3080             } else {
3081                 progress "archive .dsc names other git commit, fixing up";
3082                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3083             }
3084         }
3085     } elsif ($dsc) {
3086         @mergeinputs = generate_commits_from_dsc();
3087         # We have just done an import.  Now, our import algorithm might
3088         # have been improved.  But even so we do not want to generate
3089         # a new different import of the same package.  So if the
3090         # version numbers are the same, just use our existing version.
3091         # If the version numbers are different, the archive has changed
3092         # (perhaps, rewound).
3093         if ($lastfetch_mergeinput &&
3094             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3095                               (mergeinfo_version $mergeinputs[0]) )) {
3096             @mergeinputs = ($lastfetch_mergeinput);
3097         }
3098     } elsif ($lastpush_hash) {
3099         # only in git, not in the archive yet
3100         @mergeinputs = ($lastpush_mergeinput);
3101         print STDERR <<END or die $!;
3102
3103 Package not found in the archive, but has allegedly been pushed using dgit.
3104 $later_warning_msg
3105 END
3106     } else {
3107         printdebug "nothing found!\n";
3108         if (defined $skew_warning_vsn) {
3109             print STDERR <<END or die $!;
3110
3111 Warning: relevant archive skew detected.
3112 Archive allegedly contains $skew_warning_vsn
3113 But we were not able to obtain any version from the archive or git.
3114
3115 END
3116         }
3117         unshift @end, $del_lrfetchrefs;
3118         return undef;
3119     }
3120
3121     if ($lastfetch_hash &&
3122         !grep {
3123             my $h = $_->{Commit};
3124             $h and is_fast_fwd($lastfetch_hash, $h);
3125             # If true, one of the existing parents of this commit
3126             # is a descendant of the $lastfetch_hash, so we'll
3127             # be ff from that automatically.
3128         } @mergeinputs
3129         ) {
3130         # Otherwise:
3131         push @mergeinputs, $lastfetch_mergeinput;
3132     }
3133
3134     printdebug "fetch mergeinfos:\n";
3135     foreach my $mi (@mergeinputs) {
3136         if ($mi->{Info}) {
3137             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3138         } else {
3139             printdebug sprintf " ReverseParents=%d Message=%s",
3140                 $mi->{ReverseParents}, $mi->{Message};
3141         }
3142     }
3143
3144     my $compat_info= pop @mergeinputs
3145         if $mergeinputs[$#mergeinputs]{Message};
3146
3147     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3148
3149     my $hash;
3150     if (@mergeinputs > 1) {
3151         # here we go, then:
3152         my $tree_commit = $mergeinputs[0]{Commit};
3153
3154         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3155         $tree =~ m/\n\n/;  $tree = $`;
3156         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3157         $tree = $1;
3158
3159         # We use the changelog author of the package in question the
3160         # author of this pseudo-merge.  This is (roughly) correct if
3161         # this commit is simply representing aa non-dgit upload.
3162         # (Roughly because it does not record sponsorship - but we
3163         # don't have sponsorship info because that's in the .changes,
3164         # which isn't in the archivw.)
3165         #
3166         # But, it might be that we are representing archive history
3167         # updates (including in-archive copies).  These are not really
3168         # the responsibility of the person who created the .dsc, but
3169         # there is no-one whose name we should better use.  (The
3170         # author of the .dsc-named commit is clearly worse.)
3171
3172         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3173         my $author = clogp_authline $useclogp;
3174         my $cversion = getfield $useclogp, 'Version';
3175
3176         my $mcf = ".git/dgit/mergecommit";
3177         open MC, ">", $mcf or die "$mcf $!";
3178         print MC <<END or die $!;
3179 tree $tree
3180 END
3181
3182         my @parents = grep { $_->{Commit} } @mergeinputs;
3183         @parents = reverse @parents if $compat_info->{ReverseParents};
3184         print MC <<END or die $! foreach @parents;
3185 parent $_->{Commit}
3186 END
3187
3188         print MC <<END or die $!;
3189 author $author
3190 committer $author
3191
3192 END
3193
3194         if (defined $compat_info->{Message}) {
3195             print MC $compat_info->{Message} or die $!;
3196         } else {
3197             print MC <<END or die $!;
3198 Record $package ($cversion) in archive suite $csuite
3199
3200 Record that
3201 END
3202             my $message_add_info = sub {
3203                 my ($mi) = (@_);
3204                 my $mversion = mergeinfo_version $mi;
3205                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3206                     or die $!;
3207             };
3208
3209             $message_add_info->($mergeinputs[0]);
3210             print MC <<END or die $!;
3211 should be treated as descended from
3212 END
3213             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3214         }
3215
3216         close MC or die $!;
3217         $hash = make_commit $mcf;
3218     } else {
3219         $hash = $mergeinputs[0]{Commit};
3220     }
3221     printdebug "fetch hash=$hash\n";
3222
3223     my $chkff = sub {
3224         my ($lasth, $what) = @_;
3225         return unless $lasth;
3226         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3227     };
3228
3229     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3230         if $lastpush_hash;
3231     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3232
3233     fetch_from_archive_record_1($hash);
3234
3235     if (defined $skew_warning_vsn) {
3236         mkpath '.git/dgit';
3237         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3238         my $gotclogp = commit_getclogp($hash);
3239         my $got_vsn = getfield $gotclogp, 'Version';
3240         printdebug "SKEW CHECK GOT $got_vsn\n";
3241         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3242             print STDERR <<END or die $!;
3243
3244 Warning: archive skew detected.  Using the available version:
3245 Archive allegedly contains    $skew_warning_vsn
3246 We were able to obtain only   $got_vsn
3247
3248 END
3249         }
3250     }
3251
3252     if ($lastfetch_hash ne $hash) {
3253         fetch_from_archive_record_2($hash);
3254     }
3255
3256     lrfetchref_used lrfetchref();
3257
3258     unshift @end, $del_lrfetchrefs;
3259     return $hash;
3260 }
3261
3262 sub set_local_git_config ($$) {
3263     my ($k, $v) = @_;
3264     runcmd @git, qw(config), $k, $v;
3265 }
3266
3267 sub setup_mergechangelogs (;$) {
3268     my ($always) = @_;
3269     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3270
3271     my $driver = 'dpkg-mergechangelogs';
3272     my $cb = "merge.$driver";
3273     my $attrs = '.git/info/attributes';
3274     ensuredir '.git/info';
3275
3276     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3277     if (!open ATTRS, "<", $attrs) {
3278         $!==ENOENT or die "$attrs: $!";
3279     } else {
3280         while (<ATTRS>) {
3281             chomp;
3282             next if m{^debian/changelog\s};
3283             print NATTRS $_, "\n" or die $!;
3284         }
3285         ATTRS->error and die $!;
3286         close ATTRS;
3287     }
3288     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3289     close NATTRS;
3290
3291     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3292     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3293
3294     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3295 }
3296
3297 sub setup_useremail (;$) {
3298     my ($always) = @_;
3299     return unless $always || access_cfg_bool(1, 'setup-useremail');
3300
3301     my $setup = sub {
3302         my ($k, $envvar) = @_;
3303         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3304         return unless defined $v;
3305         set_local_git_config "user.$k", $v;
3306     };
3307
3308     $setup->('email', 'DEBEMAIL');
3309     $setup->('name', 'DEBFULLNAME');
3310 }
3311
3312 sub ensure_setup_existing_tree () {
3313     my $k = "remote.$remotename.skipdefaultupdate";
3314     my $c = git_get_config $k;
3315     return if defined $c;
3316     set_local_git_config $k, 'true';
3317 }
3318
3319 sub open_gitattrs () {
3320     my $gai = new IO::File ".git/info/attributes"
3321         or $!==ENOENT
3322         or die "open .git/info/attributes: $!";
3323     return $gai;
3324 }
3325
3326 sub is_gitattrs_setup () {
3327     my $gai = open_gitattrs();
3328     return 0 unless $gai;
3329     while (<$gai>) {
3330         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3331     }
3332     $gai->error and die $!;
3333     return 0;
3334 }
3335
3336 sub setup_gitattrs (;$) {
3337     my ($always) = @_;
3338     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3339
3340     if (is_gitattrs_setup()) {
3341         progress <<END;
3342 [attr]dgit-defuse-attrs already found in .git/info/attributes
3343  not doing further gitattributes setup
3344 END
3345         return;
3346     }
3347     my $af = ".git/info/attributes";
3348     open GAO, "> $af.new" or die $!;
3349     print GAO <<END or die $!;
3350 *       dgit-defuse-attrs
3351 [attr]dgit-defuse-attrs -text -eol -crlf -ident -filter
3352 # ^ see dgit(7).  To undo, leave a definition of [attr]dgit-defuse-attrs
3353 END
3354     my $gai = open_gitattrs();
3355     if ($gai) {
3356         while (<$gai>) {
3357             chomp;
3358             print GAO $_, "\n" or die $!;
3359         }
3360         $gai->error and die $!;
3361     }
3362     close GAO or die $!;
3363     rename "$af.new", "$af" or die "install $af: $!";
3364 }
3365
3366 sub setup_new_tree () {
3367     setup_mergechangelogs();
3368     setup_useremail();
3369 }
3370
3371 sub multisuite_suite_child ($$$) {
3372     my ($tsuite, $merginputs, $fn) = @_;
3373     # in child, sets things up, calls $fn->(), and returns undef
3374     # in parent, returns canonical suite name for $tsuite
3375     my $canonsuitefh = IO::File::new_tmpfile;
3376     my $pid = fork // die $!;
3377     if (!$pid) {
3378         forkcheck_setup();
3379         $isuite = $tsuite;
3380         $us .= " [$isuite]";
3381         $debugprefix .= " ";
3382         progress "fetching $tsuite...";
3383         canonicalise_suite();
3384         print $canonsuitefh $csuite, "\n" or die $!;
3385         close $canonsuitefh or die $!;
3386         $fn->();
3387         return undef;
3388     }
3389     waitpid $pid,0 == $pid or die $!;
3390     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3391     seek $canonsuitefh,0,0 or die $!;
3392     local $csuite = <$canonsuitefh>;
3393     die $! unless defined $csuite && chomp $csuite;
3394     if ($? == 256*4) {
3395         printdebug "multisuite $tsuite missing\n";
3396         return $csuite;
3397     }
3398     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3399     push @$merginputs, {
3400         Ref => lrref,
3401         Info => $csuite,
3402     };
3403     return $csuite;
3404 }
3405
3406 sub fork_for_multisuite ($) {
3407     my ($before_fetch_merge) = @_;
3408     # if nothing unusual, just returns ''
3409     #
3410     # if multisuite:
3411     # returns 0 to caller in child, to do first of the specified suites
3412     # in child, $csuite is not yet set
3413     #
3414     # returns 1 to caller in parent, to finish up anything needed after
3415     # in parent, $csuite is set to canonicalised portmanteau
3416
3417     my $org_isuite = $isuite;
3418     my @suites = split /\,/, $isuite;
3419     return '' unless @suites > 1;
3420     printdebug "fork_for_multisuite: @suites\n";
3421
3422     my @mergeinputs;
3423
3424     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3425                                             sub { });
3426     return 0 unless defined $cbasesuite;
3427
3428     fail "package $package missing in (base suite) $cbasesuite"
3429         unless @mergeinputs;
3430
3431     my @csuites = ($cbasesuite);
3432
3433     $before_fetch_merge->();
3434
3435     foreach my $tsuite (@suites[1..$#suites]) {
3436         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3437                                                sub {
3438             @end = ();
3439             fetch();
3440             exit 0;
3441         });
3442         # xxx collecte the ref here
3443
3444         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3445         push @csuites, $csubsuite;
3446     }
3447
3448     foreach my $mi (@mergeinputs) {
3449         my $ref = git_get_ref $mi->{Ref};
3450         die "$mi->{Ref} ?" unless length $ref;
3451         $mi->{Commit} = $ref;
3452     }
3453
3454     $csuite = join ",", @csuites;
3455
3456     my $previous = git_get_ref lrref;
3457     if ($previous) {
3458         unshift @mergeinputs, {
3459             Commit => $previous,
3460             Info => "local combined tracking branch",
3461             Warning =>
3462  "archive seems to have rewound: local tracking branch is ahead!",
3463         };
3464     }
3465
3466     foreach my $ix (0..$#mergeinputs) {
3467         $mergeinputs[$ix]{Index} = $ix;
3468     }
3469
3470     @mergeinputs = sort {
3471         -version_compare(mergeinfo_version $a,
3472                          mergeinfo_version $b) # highest version first
3473             or
3474         $a->{Index} <=> $b->{Index}; # earliest in spec first
3475     } @mergeinputs;
3476
3477     my @needed;
3478
3479   NEEDED:
3480     foreach my $mi (@mergeinputs) {
3481         printdebug "multisuite merge check $mi->{Info}\n";
3482         foreach my $previous (@needed) {
3483             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3484             printdebug "multisuite merge un-needed $previous->{Info}\n";
3485             next NEEDED;
3486         }
3487         push @needed, $mi;
3488         printdebug "multisuite merge this-needed\n";
3489         $mi->{Character} = '+';
3490     }
3491
3492     $needed[0]{Character} = '*';
3493
3494     my $output = $needed[0]{Commit};
3495
3496     if (@needed > 1) {
3497         printdebug "multisuite merge nontrivial\n";
3498         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3499
3500         my $commit = "tree $tree\n";
3501         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3502             "Input branches:\n";
3503
3504         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3505             printdebug "multisuite merge include $mi->{Info}\n";
3506             $mi->{Character} //= ' ';
3507             $commit .= "parent $mi->{Commit}\n";
3508             $msg .= sprintf " %s  %-25s %s\n",
3509                 $mi->{Character},
3510                 (mergeinfo_version $mi),
3511                 $mi->{Info};
3512         }
3513         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3514         $msg .= "\nKey\n".
3515             " * marks the highest version branch, which choose to use\n".
3516             " + marks each branch which was not already an ancestor\n\n".
3517             "[dgit multi-suite $csuite]\n";
3518         $commit .=
3519             "author $authline\n".
3520             "committer $authline\n\n";
3521         $output = make_commit_text $commit.$msg;
3522         printdebug "multisuite merge generated $output\n";
3523     }
3524
3525     fetch_from_archive_record_1($output);
3526     fetch_from_archive_record_2($output);
3527
3528     progress "calculated combined tracking suite $csuite";
3529
3530     return 1;
3531 }
3532
3533 sub clone_set_head () {
3534     open H, "> .git/HEAD" or die $!;
3535     print H "ref: ".lref()."\n" or die $!;
3536     close H or die $!;
3537 }
3538 sub clone_finish ($) {
3539     my ($dstdir) = @_;
3540     runcmd @git, qw(reset --hard), lrref();
3541     runcmd qw(bash -ec), <<'END';
3542         set -o pipefail
3543         git ls-tree -r --name-only -z HEAD | \
3544         xargs -0r touch -h -r . --
3545 END
3546     printdone "ready for work in $dstdir";
3547 }
3548
3549 sub clone ($) {
3550     my ($dstdir) = @_;
3551     badusage "dry run makes no sense with clone" unless act_local();
3552
3553     my $multi_fetched = fork_for_multisuite(sub {
3554         printdebug "multi clone before fetch merge\n";
3555         changedir $dstdir;
3556     });
3557     if ($multi_fetched) {
3558         printdebug "multi clone after fetch merge\n";
3559         clone_set_head();
3560         clone_finish($dstdir);
3561         exit 0;
3562     }
3563     printdebug "clone main body\n";
3564
3565     canonicalise_suite();
3566     my $hasgit = check_for_git();
3567     mkdir $dstdir or fail "create \`$dstdir': $!";
3568     changedir $dstdir;
3569     runcmd @git, qw(init -q);
3570     clone_set_head();
3571     my $giturl = access_giturl(1);
3572     if (defined $giturl) {
3573         runcmd @git, qw(remote add), 'origin', $giturl;
3574     }
3575     if ($hasgit) {
3576         progress "fetching existing git history";
3577         git_fetch_us();
3578         runcmd_ordryrun_local @git, qw(fetch origin);
3579     } else {
3580         progress "starting new git history";
3581     }
3582     fetch_from_archive() or no_such_package;
3583     my $vcsgiturl = $dsc->{'Vcs-Git'};
3584     if (length $vcsgiturl) {
3585         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3586         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3587     }
3588     setup_new_tree();
3589     clone_finish($dstdir);
3590 }
3591
3592 sub fetch () {
3593     canonicalise_suite();
3594     if (check_for_git()) {
3595         git_fetch_us();
3596     }
3597     fetch_from_archive() or no_such_package();
3598     printdone "fetched into ".lrref();
3599 }
3600
3601 sub pull () {
3602     my $multi_fetched = fork_for_multisuite(sub { });
3603     fetch() unless $multi_fetched; # parent
3604     return if $multi_fetched eq '0'; # child
3605     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3606         lrref();
3607     printdone "fetched to ".lrref()." and merged into HEAD";
3608 }
3609
3610 sub check_not_dirty () {
3611     foreach my $f (qw(local-options local-patch-header)) {
3612         if (stat_exists "debian/source/$f") {
3613             fail "git tree contains debian/source/$f";
3614         }
3615     }
3616
3617     return if $ignoredirty;
3618
3619     my @cmd = (@git, qw(diff --quiet HEAD));
3620     debugcmd "+",@cmd;
3621     $!=0; $?=-1; system @cmd;
3622     return if !$?;
3623     if ($?==256) {
3624         fail "working tree is dirty (does not match HEAD)";
3625     } else {
3626         failedcmd @cmd;
3627     }
3628 }
3629
3630 sub commit_admin ($) {
3631     my ($m) = @_;
3632     progress "$m";
3633     runcmd_ordryrun_local @git, qw(commit -m), $m;
3634 }
3635
3636 sub commit_quilty_patch () {
3637     my $output = cmdoutput @git, qw(status --porcelain);
3638     my %adds;
3639     foreach my $l (split /\n/, $output) {
3640         next unless $l =~ m/\S/;
3641         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3642             $adds{$1}++;
3643         }
3644     }
3645     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3646     if (!%adds) {
3647         progress "nothing quilty to commit, ok.";
3648         return;
3649     }
3650     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3651     runcmd_ordryrun_local @git, qw(add -f), @adds;
3652     commit_admin <<END
3653 Commit Debian 3.0 (quilt) metadata
3654
3655 [dgit ($our_version) quilt-fixup]
3656 END
3657 }
3658
3659 sub get_source_format () {
3660     my %options;
3661     if (open F, "debian/source/options") {
3662         while (<F>) {
3663             next if m/^\s*\#/;
3664             next unless m/\S/;
3665             s/\s+$//; # ignore missing final newline
3666             if (m/\s*\#\s*/) {
3667                 my ($k, $v) = ($`, $'); #');
3668                 $v =~ s/^"(.*)"$/$1/;
3669                 $options{$k} = $v;
3670             } else {
3671                 $options{$_} = 1;
3672             }
3673         }
3674         F->error and die $!;
3675         close F;
3676     } else {
3677         die $! unless $!==&ENOENT;
3678     }
3679
3680     if (!open F, "debian/source/format") {
3681         die $! unless $!==&ENOENT;
3682         return '';
3683     }
3684     $_ = <F>;
3685     F->error and die $!;
3686     chomp;
3687     return ($_, \%options);
3688 }
3689
3690 sub madformat_wantfixup ($) {
3691     my ($format) = @_;
3692     return 0 unless $format eq '3.0 (quilt)';
3693     our $quilt_mode_warned;
3694     if ($quilt_mode eq 'nocheck') {
3695         progress "Not doing any fixup of \`$format' due to".
3696             " ----no-quilt-fixup or --quilt=nocheck"
3697             unless $quilt_mode_warned++;
3698         return 0;
3699     }
3700     progress "Format \`$format', need to check/update patch stack"
3701         unless $quilt_mode_warned++;
3702     return 1;
3703 }
3704
3705 sub maybe_split_brain_save ($$$) {
3706     my ($headref, $dgitview, $msg) = @_;
3707     # => message fragment "$saved" describing disposition of $dgitview
3708     return "commit id $dgitview" unless defined $split_brain_save;
3709     my @cmd = (shell_cmd "cd ../../../..",
3710                @git, qw(update-ref -m),
3711                "dgit --dgit-view-save $msg HEAD=$headref",
3712                $split_brain_save, $dgitview);
3713     runcmd @cmd;
3714     return "and left in $split_brain_save";
3715 }
3716
3717 # An "infopair" is a tuple [ $thing, $what ]
3718 # (often $thing is a commit hash; $what is a description)
3719
3720 sub infopair_cond_equal ($$) {
3721     my ($x,$y) = @_;
3722     $x->[0] eq $y->[0] or fail <<END;
3723 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3724 END
3725 };
3726
3727 sub infopair_lrf_tag_lookup ($$) {
3728     my ($tagnames, $what) = @_;
3729     # $tagname may be an array ref
3730     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3731     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3732     foreach my $tagname (@tagnames) {
3733         my $lrefname = lrfetchrefs."/tags/$tagname";
3734         my $tagobj = $lrfetchrefs_f{$lrefname};
3735         next unless defined $tagobj;
3736         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3737         return [ git_rev_parse($tagobj), $what ];
3738     }
3739     fail @tagnames==1 ? <<END : <<END;
3740 Wanted tag $what (@tagnames) on dgit server, but not found
3741 END
3742 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3743 END
3744 }
3745
3746 sub infopair_cond_ff ($$) {
3747     my ($anc,$desc) = @_;
3748     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3749 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3750 END
3751 };
3752
3753 sub pseudomerge_version_check ($$) {
3754     my ($clogp, $archive_hash) = @_;
3755
3756     my $arch_clogp = commit_getclogp $archive_hash;
3757     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3758                      'version currently in archive' ];
3759     if (defined $overwrite_version) {
3760         if (length $overwrite_version) {
3761             infopair_cond_equal([ $overwrite_version,
3762                                   '--overwrite= version' ],
3763                                 $i_arch_v);
3764         } else {
3765             my $v = $i_arch_v->[0];
3766             progress "Checking package changelog for archive version $v ...";
3767             eval {
3768                 my @xa = ("-f$v", "-t$v");
3769                 my $vclogp = parsechangelog @xa;
3770                 my $cv = [ (getfield $vclogp, 'Version'),
3771                            "Version field from dpkg-parsechangelog @xa" ];
3772                 infopair_cond_equal($i_arch_v, $cv);
3773             };
3774             if ($@) {
3775                 $@ =~ s/^dgit: //gm;
3776                 fail "$@".
3777                     "Perhaps debian/changelog does not mention $v ?";
3778             }
3779         }
3780     }
3781
3782     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3783     return $i_arch_v;
3784 }
3785
3786 sub pseudomerge_make_commit ($$$$ $$) {
3787     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3788         $msg_cmd, $msg_msg) = @_;
3789     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3790
3791     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3792     my $authline = clogp_authline $clogp;
3793
3794     chomp $msg_msg;
3795     $msg_cmd .=
3796         !defined $overwrite_version ? ""
3797         : !length  $overwrite_version ? " --overwrite"
3798         : " --overwrite=".$overwrite_version;
3799
3800     mkpath '.git/dgit';
3801     my $pmf = ".git/dgit/pseudomerge";
3802     open MC, ">", $pmf or die "$pmf $!";
3803     print MC <<END or die $!;
3804 tree $tree
3805 parent $dgitview
3806 parent $archive_hash
3807 author $authline
3808 committer $authline
3809
3810 $msg_msg
3811
3812 [$msg_cmd]
3813 END
3814     close MC or die $!;
3815
3816     return make_commit($pmf);
3817 }
3818
3819 sub splitbrain_pseudomerge ($$$$) {
3820     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3821     # => $merged_dgitview
3822     printdebug "splitbrain_pseudomerge...\n";
3823     #
3824     #     We:      debian/PREVIOUS    HEAD($maintview)
3825     # expect:          o ----------------- o
3826     #                    \                   \
3827     #                     o                   o
3828     #                 a/d/PREVIOUS        $dgitview
3829     #                $archive_hash              \
3830     #  If so,                \                   \
3831     #  we do:                 `------------------ o
3832     #   this:                                   $dgitview'
3833     #
3834
3835     return $dgitview unless defined $archive_hash;
3836
3837     printdebug "splitbrain_pseudomerge...\n";
3838
3839     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3840
3841     if (!defined $overwrite_version) {
3842         progress "Checking that HEAD inciudes all changes in archive...";
3843     }
3844
3845     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3846
3847     if (defined $overwrite_version) {
3848     } elsif (!eval {
3849         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3850         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3851         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3852         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3853         my $i_archive = [ $archive_hash, "current archive contents" ];
3854
3855         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3856
3857         infopair_cond_equal($i_dgit, $i_archive);
3858         infopair_cond_ff($i_dep14, $i_dgit);
3859         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3860         1;
3861     }) {
3862         print STDERR <<END;
3863 $us: check failed (maybe --overwrite is needed, consult documentation)
3864 END
3865         die "$@";
3866     }
3867
3868     my $r = pseudomerge_make_commit
3869         $clogp, $dgitview, $archive_hash, $i_arch_v,
3870         "dgit --quilt=$quilt_mode",
3871         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3872 Declare fast forward from $i_arch_v->[0]
3873 END_OVERWR
3874 Make fast forward from $i_arch_v->[0]
3875 END_MAKEFF
3876
3877     maybe_split_brain_save $maintview, $r, "pseudomerge";
3878
3879     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3880     return $r;
3881 }
3882
3883 sub plain_overwrite_pseudomerge ($$$) {
3884     my ($clogp, $head, $archive_hash) = @_;
3885
3886     printdebug "plain_overwrite_pseudomerge...";
3887
3888     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3889
3890     return $head if is_fast_fwd $archive_hash, $head;
3891
3892     my $m = "Declare fast forward from $i_arch_v->[0]";
3893
3894     my $r = pseudomerge_make_commit
3895         $clogp, $head, $archive_hash, $i_arch_v,
3896         "dgit", $m;
3897
3898     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3899
3900     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3901     return $r;
3902 }
3903
3904 sub push_parse_changelog ($) {
3905     my ($clogpfn) = @_;
3906
3907     my $clogp = Dpkg::Control::Hash->new();
3908     $clogp->load($clogpfn) or die;
3909
3910     my $clogpackage = getfield $clogp, 'Source';
3911     $package //= $clogpackage;
3912     fail "-p specified $package but changelog specified $clogpackage"
3913         unless $package eq $clogpackage;
3914     my $cversion = getfield $clogp, 'Version';
3915
3916     if (!$we_are_initiator) {
3917         # rpush initiator can't do this because it doesn't have $isuite yet
3918         my $tag = debiantag($cversion, access_nomdistro);
3919         runcmd @git, qw(check-ref-format), $tag;
3920     }
3921
3922     my $dscfn = dscfn($cversion);
3923
3924     return ($clogp, $cversion, $dscfn);
3925 }
3926
3927 sub push_parse_dsc ($$$) {
3928     my ($dscfn,$dscfnwhat, $cversion) = @_;
3929     $dsc = parsecontrol($dscfn,$dscfnwhat);
3930     my $dversion = getfield $dsc, 'Version';
3931     my $dscpackage = getfield $dsc, 'Source';
3932     ($dscpackage eq $package && $dversion eq $cversion) or
3933         fail "$dscfn is for $dscpackage $dversion".
3934             " but debian/changelog is for $package $cversion";
3935 }
3936
3937 sub push_tagwants ($$$$) {
3938     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3939     my @tagwants;
3940     push @tagwants, {
3941         TagFn => \&debiantag,
3942         Objid => $dgithead,
3943         TfSuffix => '',
3944         View => 'dgit',
3945     };
3946     if (defined $maintviewhead) {
3947         push @tagwants, {
3948             TagFn => \&debiantag_maintview,
3949             Objid => $maintviewhead,
3950             TfSuffix => '-maintview',
3951             View => 'maint',
3952         };
3953     } elsif ($dodep14tag eq 'no' ? 0
3954              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3955              : $dodep14tag eq 'always'
3956              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3957 --dep14tag-always (or equivalent in config) means server must support
3958  both "new" and "maint" tag formats, but config says it doesn't.
3959 END
3960             : die "$dodep14tag ?") {
3961         push @tagwants, {
3962             TagFn => \&debiantag_maintview,
3963             Objid => $dgithead,
3964             TfSuffix => '-dgit',
3965             View => 'dgit',
3966         };
3967     };
3968     foreach my $tw (@tagwants) {
3969         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3970         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3971     }
3972     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3973     return @tagwants;
3974 }
3975
3976 sub push_mktags ($$ $$ $) {
3977     my ($clogp,$dscfn,
3978         $changesfile,$changesfilewhat,
3979         $tagwants) = @_;
3980
3981     die unless $tagwants->[0]{View} eq 'dgit';
3982
3983     my $declaredistro = access_nomdistro();
3984     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3985     $dsc->{$ourdscfield[0]} = join " ",
3986         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3987         $reader_giturl;
3988     $dsc->save("$dscfn.tmp") or die $!;
3989
3990     my $changes = parsecontrol($changesfile,$changesfilewhat);
3991     foreach my $field (qw(Source Distribution Version)) {
3992         $changes->{$field} eq $clogp->{$field} or
3993             fail "changes field $field \`$changes->{$field}'".
3994                 " does not match changelog \`$clogp->{$field}'";
3995     }
3996
3997     my $cversion = getfield $clogp, 'Version';
3998     my $clogsuite = getfield $clogp, 'Distribution';
3999
4000     # We make the git tag by hand because (a) that makes it easier
4001     # to control the "tagger" (b) we can do remote signing
4002     my $authline = clogp_authline $clogp;
4003     my $delibs = join(" ", "",@deliberatelies);
4004
4005     my $mktag = sub {
4006         my ($tw) = @_;
4007         my $tfn = $tw->{Tfn};
4008         my $head = $tw->{Objid};
4009         my $tag = $tw->{Tag};
4010
4011         open TO, '>', $tfn->('.tmp') or die $!;
4012         print TO <<END or die $!;
4013 object $head
4014 type commit
4015 tag $tag
4016 tagger $authline
4017
4018 END
4019         if ($tw->{View} eq 'dgit') {
4020             print TO <<END or die $!;
4021 $package release $cversion for $clogsuite ($csuite) [dgit]
4022 [dgit distro=$declaredistro$delibs]
4023 END
4024             foreach my $ref (sort keys %previously) {
4025                 print TO <<END or die $!;
4026 [dgit previously:$ref=$previously{$ref}]
4027 END
4028             }
4029         } elsif ($tw->{View} eq 'maint') {
4030             print TO <<END or die $!;
4031 $package release $cversion for $clogsuite ($csuite)
4032 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4033 END
4034         } else {
4035             die Dumper($tw)."?";
4036         }
4037
4038         close TO or die $!;
4039
4040         my $tagobjfn = $tfn->('.tmp');
4041         if ($sign) {
4042             if (!defined $keyid) {
4043                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4044             }
4045             if (!defined $keyid) {
4046                 $keyid = getfield $clogp, 'Maintainer';
4047             }
4048             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4049             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4050             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4051             push @sign_cmd, $tfn->('.tmp');
4052             runcmd_ordryrun @sign_cmd;
4053             if (act_scary()) {
4054                 $tagobjfn = $tfn->('.signed.tmp');
4055                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4056                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4057             }
4058         }
4059         return $tagobjfn;
4060     };
4061
4062     my @r = map { $mktag->($_); } @$tagwants;
4063     return @r;
4064 }
4065
4066 sub sign_changes ($) {
4067     my ($changesfile) = @_;
4068     if ($sign) {
4069         my @debsign_cmd = @debsign;
4070         push @debsign_cmd, "-k$keyid" if defined $keyid;
4071         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4072         push @debsign_cmd, $changesfile;
4073         runcmd_ordryrun @debsign_cmd;
4074     }
4075 }
4076
4077 sub dopush () {
4078     printdebug "actually entering push\n";
4079
4080     supplementary_message(<<'END');
4081 Push failed, while checking state of the archive.
4082 You can retry the push, after fixing the problem, if you like.
4083 END
4084     if (check_for_git()) {
4085         git_fetch_us();
4086     }
4087     my $archive_hash = fetch_from_archive();
4088     if (!$archive_hash) {
4089         $new_package or
4090             fail "package appears to be new in this suite;".
4091                 " if this is intentional, use --new";
4092     }
4093
4094     supplementary_message(<<'END');
4095 Push failed, while preparing your push.
4096 You can retry the push, after fixing the problem, if you like.
4097 END
4098
4099     need_tagformat 'new', "quilt mode $quilt_mode"
4100         if quiltmode_splitbrain;
4101
4102     prep_ud();
4103
4104     access_giturl(); # check that success is vaguely likely
4105     rpush_handle_protovsn_bothends() if $we_are_initiator;
4106     select_tagformat();
4107
4108     my $clogpfn = ".git/dgit/changelog.822.tmp";
4109     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4110
4111     responder_send_file('parsed-changelog', $clogpfn);
4112
4113     my ($clogp, $cversion, $dscfn) =
4114         push_parse_changelog("$clogpfn");
4115
4116     my $dscpath = "$buildproductsdir/$dscfn";
4117     stat_exists $dscpath or
4118         fail "looked for .dsc $dscpath, but $!;".
4119             " maybe you forgot to build";
4120
4121     responder_send_file('dsc', $dscpath);
4122
4123     push_parse_dsc($dscpath, $dscfn, $cversion);
4124
4125     my $format = getfield $dsc, 'Format';
4126     printdebug "format $format\n";
4127
4128     my $actualhead = git_rev_parse('HEAD');
4129     my $dgithead = $actualhead;
4130     my $maintviewhead = undef;
4131
4132     my $upstreamversion = upstreamversion $clogp->{Version};
4133
4134     if (madformat_wantfixup($format)) {
4135         # user might have not used dgit build, so maybe do this now:
4136         if (quiltmode_splitbrain()) {
4137             changedir $ud;
4138             quilt_make_fake_dsc($upstreamversion);
4139             my $cachekey;
4140             ($dgithead, $cachekey) =
4141                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4142             $dgithead or fail
4143  "--quilt=$quilt_mode but no cached dgit view:
4144  perhaps tree changed since dgit build[-source] ?";
4145             $split_brain = 1;
4146             $dgithead = splitbrain_pseudomerge($clogp,
4147                                                $actualhead, $dgithead,
4148                                                $archive_hash);
4149             $maintviewhead = $actualhead;
4150             changedir '../../../..';
4151             prep_ud(); # so _only_subdir() works, below
4152         } else {
4153             commit_quilty_patch();
4154         }
4155     }
4156
4157     if (defined $overwrite_version && !defined $maintviewhead) {
4158         $dgithead = plain_overwrite_pseudomerge($clogp,
4159                                                 $dgithead,
4160                                                 $archive_hash);
4161     }
4162
4163     check_not_dirty();
4164
4165     my $forceflag = '';
4166     if ($archive_hash) {
4167         if (is_fast_fwd($archive_hash, $dgithead)) {
4168             # ok
4169         } elsif (deliberately_not_fast_forward) {
4170             $forceflag = '+';
4171         } else {
4172             fail "dgit push: HEAD is not a descendant".
4173                 " of the archive's version.\n".
4174                 "To overwrite the archive's contents,".
4175                 " pass --overwrite[=VERSION].\n".
4176                 "To rewind history, if permitted by the archive,".
4177                 " use --deliberately-not-fast-forward.";
4178         }
4179     }
4180
4181     changedir $ud;
4182     progress "checking that $dscfn corresponds to HEAD";
4183     runcmd qw(dpkg-source -x --),
4184         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4185     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4186     check_for_vendor_patches() if madformat($dsc->{format});
4187     changedir '../../../..';
4188     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4189     debugcmd "+",@diffcmd;
4190     $!=0; $?=-1;
4191     my $r = system @diffcmd;
4192     if ($r) {
4193         if ($r==256) {
4194             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4195             fail <<END
4196 HEAD specifies a different tree to $dscfn:
4197 $diffs
4198 Perhaps you forgot to build.  Or perhaps there is a problem with your
4199  source tree (see dgit(7) for some hints).  To see a full diff, run
4200    git diff $tree HEAD
4201 END
4202         } else {
4203             failedcmd @diffcmd;
4204         }
4205     }
4206     if (!$changesfile) {
4207         my $pat = changespat $cversion;
4208         my @cs = glob "$buildproductsdir/$pat";
4209         fail "failed to find unique changes file".
4210             " (looked for $pat in $buildproductsdir);".
4211             " perhaps you need to use dgit -C"
4212             unless @cs==1;
4213         ($changesfile) = @cs;
4214     } else {
4215         $changesfile = "$buildproductsdir/$changesfile";
4216     }
4217
4218     # Check that changes and .dsc agree enough
4219     $changesfile =~ m{[^/]*$};
4220     my $changes = parsecontrol($changesfile,$&);
4221     files_compare_inputs($dsc, $changes)
4222         unless forceing [qw(dsc-changes-mismatch)];
4223
4224     # Perhaps adjust .dsc to contain right set of origs
4225     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4226                                   $changesfile)
4227         unless forceing [qw(changes-origs-exactly)];
4228
4229     # Checks complete, we're going to try and go ahead:
4230
4231     responder_send_file('changes',$changesfile);
4232     responder_send_command("param head $dgithead");
4233     responder_send_command("param csuite $csuite");
4234     responder_send_command("param isuite $isuite");
4235     responder_send_command("param tagformat $tagformat");
4236     if (defined $maintviewhead) {
4237         die unless ($protovsn//4) >= 4;
4238         responder_send_command("param maint-view $maintviewhead");
4239     }
4240
4241     if (deliberately_not_fast_forward) {
4242         git_for_each_ref(lrfetchrefs, sub {
4243             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4244             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4245             responder_send_command("previously $rrefname=$objid");
4246             $previously{$rrefname} = $objid;
4247         });
4248     }
4249
4250     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4251                                  ".git/dgit/tag");
4252     my @tagobjfns;
4253
4254     supplementary_message(<<'END');
4255 Push failed, while signing the tag.
4256 You can retry the push, after fixing the problem, if you like.
4257 END
4258     # If we manage to sign but fail to record it anywhere, it's fine.
4259     if ($we_are_responder) {
4260         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4261         responder_receive_files('signed-tag', @tagobjfns);
4262     } else {
4263         @tagobjfns = push_mktags($clogp,$dscpath,
4264                               $changesfile,$changesfile,
4265                               \@tagwants);
4266     }
4267     supplementary_message(<<'END');
4268 Push failed, *after* signing the tag.
4269 If you want to try again, you should use a new version number.
4270 END
4271
4272     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4273
4274     foreach my $tw (@tagwants) {
4275         my $tag = $tw->{Tag};
4276         my $tagobjfn = $tw->{TagObjFn};
4277         my $tag_obj_hash =
4278             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4279         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4280         runcmd_ordryrun_local
4281             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4282     }
4283
4284     supplementary_message(<<'END');
4285 Push failed, while updating the remote git repository - see messages above.
4286 If you want to try again, you should use a new version number.
4287 END
4288     if (!check_for_git()) {
4289         create_remote_git_repo();
4290     }
4291
4292     my @pushrefs = $forceflag.$dgithead.":".rrref();
4293     foreach my $tw (@tagwants) {
4294         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4295     }
4296
4297     runcmd_ordryrun @git,
4298         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4299     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4300
4301     supplementary_message(<<'END');
4302 Push failed, while obtaining signatures on the .changes and .dsc.
4303 If it was just that the signature failed, you may try again by using
4304 debsign by hand to sign the changes
4305    $changesfile
4306 and then dput to complete the upload.
4307 If you need to change the package, you must use a new version number.
4308 END
4309     if ($we_are_responder) {
4310         my $dryrunsuffix = act_local() ? "" : ".tmp";
4311         responder_receive_files('signed-dsc-changes',
4312                                 "$dscpath$dryrunsuffix",
4313                                 "$changesfile$dryrunsuffix");
4314     } else {
4315         if (act_local()) {
4316             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4317         } else {
4318             progress "[new .dsc left in $dscpath.tmp]";
4319         }
4320         sign_changes $changesfile;
4321     }
4322
4323     supplementary_message(<<END);
4324 Push failed, while uploading package(s) to the archive server.
4325 You can retry the upload of exactly these same files with dput of:
4326   $changesfile
4327 If that .changes file is broken, you will need to use a new version
4328 number for your next attempt at the upload.
4329 END
4330     my $host = access_cfg('upload-host','RETURN-UNDEF');
4331     my @hostarg = defined($host) ? ($host,) : ();
4332     runcmd_ordryrun @dput, @hostarg, $changesfile;
4333     printdone "pushed and uploaded $cversion";
4334
4335     supplementary_message('');
4336     responder_send_command("complete");
4337 }
4338
4339 sub cmd_clone {
4340     parseopts();
4341     my $dstdir;
4342     badusage "-p is not allowed with clone; specify as argument instead"
4343         if defined $package;
4344     if (@ARGV==1) {
4345         ($package) = @ARGV;
4346     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4347         ($package,$isuite) = @ARGV;
4348     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4349         ($package,$dstdir) = @ARGV;
4350     } elsif (@ARGV==3) {
4351         ($package,$isuite,$dstdir) = @ARGV;
4352     } else {
4353         badusage "incorrect arguments to dgit clone";
4354     }
4355     notpushing();
4356
4357     $dstdir ||= "$package";
4358     if (stat_exists $dstdir) {
4359         fail "$dstdir already exists";
4360     }
4361
4362     my $cwd_remove;
4363     if ($rmonerror && !$dryrun_level) {
4364         $cwd_remove= getcwd();
4365         unshift @end, sub {
4366             return unless defined $cwd_remove;
4367             if (!chdir "$cwd_remove") {
4368                 return if $!==&ENOENT;
4369                 die "chdir $cwd_remove: $!";
4370             }
4371             printdebug "clone rmonerror removing $dstdir\n";
4372             if (stat $dstdir) {
4373                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4374             } elsif (grep { $! == $_ }
4375                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4376             } else {
4377                 print STDERR "check whether to remove $dstdir: $!\n";
4378             }
4379         };
4380     }
4381
4382     clone($dstdir);
4383     $cwd_remove = undef;
4384 }
4385
4386 sub branchsuite () {
4387     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4388     if ($branch =~ m#$lbranch_re#o) {
4389         return $1;
4390     } else {
4391         return undef;
4392     }
4393 }
4394
4395 sub fetchpullargs () {
4396     if (!defined $package) {
4397         my $sourcep = parsecontrol('debian/control','debian/control');
4398         $package = getfield $sourcep, 'Source';
4399     }
4400     if (@ARGV==0) {
4401         $isuite = branchsuite();
4402         if (!$isuite) {
4403             my $clogp = parsechangelog();
4404             my $clogsuite = getfield $clogp, 'Distribution';
4405             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4406         }
4407     } elsif (@ARGV==1) {
4408         ($isuite) = @ARGV;
4409     } else {
4410         badusage "incorrect arguments to dgit fetch or dgit pull";
4411     }
4412     notpushing();
4413 }
4414
4415 sub cmd_fetch {
4416     parseopts();
4417     fetchpullargs();
4418     my $multi_fetched = fork_for_multisuite(sub { });
4419     exit 0 if $multi_fetched;
4420     fetch();
4421 }
4422
4423 sub cmd_pull {
4424     parseopts();
4425     fetchpullargs();
4426     if (quiltmode_splitbrain()) {
4427         my ($format, $fopts) = get_source_format();
4428         madformat($format) and fail <<END
4429 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4430 END
4431     }
4432     pull();
4433 }
4434
4435 sub cmd_push {
4436     parseopts();
4437     badusage "-p is not allowed with dgit push" if defined $package;
4438     check_not_dirty();
4439     my $clogp = parsechangelog();
4440     $package = getfield $clogp, 'Source';
4441     my $specsuite;
4442     if (@ARGV==0) {
4443     } elsif (@ARGV==1) {
4444         ($specsuite) = (@ARGV);
4445     } else {
4446         badusage "incorrect arguments to dgit push";
4447     }
4448     $isuite = getfield $clogp, 'Distribution';
4449     pushing();
4450     if ($new_package) {
4451         local ($package) = $existing_package; # this is a hack
4452         canonicalise_suite();
4453     } else {
4454         canonicalise_suite();
4455     }
4456     if (defined $specsuite &&
4457         $specsuite ne $isuite &&
4458         $specsuite ne $csuite) {
4459             fail "dgit push: changelog specifies $isuite ($csuite)".
4460                 " but command line specifies $specsuite";
4461     }
4462     dopush();
4463 }
4464
4465 #---------- remote commands' implementation ----------
4466
4467 sub cmd_remote_push_build_host {
4468     my ($nrargs) = shift @ARGV;
4469     my (@rargs) = @ARGV[0..$nrargs-1];
4470     @ARGV = @ARGV[$nrargs..$#ARGV];
4471     die unless @rargs;
4472     my ($dir,$vsnwant) = @rargs;
4473     # vsnwant is a comma-separated list; we report which we have
4474     # chosen in our ready response (so other end can tell if they
4475     # offered several)
4476     $debugprefix = ' ';
4477     $we_are_responder = 1;
4478     $us .= " (build host)";
4479
4480     open PI, "<&STDIN" or die $!;
4481     open STDIN, "/dev/null" or die $!;
4482     open PO, ">&STDOUT" or die $!;
4483     autoflush PO 1;
4484     open STDOUT, ">&STDERR" or die $!;
4485     autoflush STDOUT 1;
4486
4487     $vsnwant //= 1;
4488     ($protovsn) = grep {
4489         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4490     } @rpushprotovsn_support;
4491
4492     fail "build host has dgit rpush protocol versions ".
4493         (join ",", @rpushprotovsn_support).
4494         " but invocation host has $vsnwant"
4495         unless defined $protovsn;
4496
4497     responder_send_command("dgit-remote-push-ready $protovsn");
4498     changedir $dir;
4499     &cmd_push;
4500 }
4501
4502 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4503 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4504 #     a good error message)
4505
4506 sub rpush_handle_protovsn_bothends () {
4507     if ($protovsn < 4) {
4508         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4509     }
4510     select_tagformat();
4511 }
4512
4513 our $i_tmp;
4514
4515 sub i_cleanup {
4516     local ($@, $?);
4517     my $report = i_child_report();
4518     if (defined $report) {
4519         printdebug "($report)\n";
4520     } elsif ($i_child_pid) {
4521         printdebug "(killing build host child $i_child_pid)\n";
4522         kill 15, $i_child_pid;
4523     }
4524     if (defined $i_tmp && !defined $initiator_tempdir) {
4525         changedir "/";
4526         eval { rmtree $i_tmp; };
4527     }
4528 }
4529
4530 END {
4531     return unless forkcheck_mainprocess();
4532     i_cleanup();
4533 }
4534
4535 sub i_method {
4536     my ($base,$selector,@args) = @_;
4537     $selector =~ s/\-/_/g;
4538     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4539 }
4540
4541 sub cmd_rpush {
4542     my $host = nextarg;
4543     my $dir;
4544     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4545         $host = $1;
4546         $dir = $'; #';
4547     } else {
4548         $dir = nextarg;
4549     }
4550     $dir =~ s{^-}{./-};
4551     my @rargs = ($dir);
4552     push @rargs, join ",", @rpushprotovsn_support;
4553     my @rdgit;
4554     push @rdgit, @dgit;
4555     push @rdgit, @ropts;
4556     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4557     push @rdgit, @ARGV;
4558     my @cmd = (@ssh, $host, shellquote @rdgit);
4559     debugcmd "+",@cmd;
4560
4561     $we_are_initiator=1;
4562
4563     if (defined $initiator_tempdir) {
4564         rmtree $initiator_tempdir;
4565         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4566         $i_tmp = $initiator_tempdir;
4567     } else {
4568         $i_tmp = tempdir();
4569     }
4570     $i_child_pid = open2(\*RO, \*RI, @cmd);
4571     changedir $i_tmp;
4572     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4573     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4574     $supplementary_message = '' unless $protovsn >= 3;
4575
4576     for (;;) {
4577         my ($icmd,$iargs) = initiator_expect {
4578             m/^(\S+)(?: (.*))?$/;
4579             ($1,$2);
4580         };
4581         i_method "i_resp", $icmd, $iargs;
4582     }
4583 }
4584
4585 sub i_resp_progress ($) {
4586     my ($rhs) = @_;
4587     my $msg = protocol_read_bytes \*RO, $rhs;
4588     progress $msg;
4589 }
4590
4591 sub i_resp_supplementary_message ($) {
4592     my ($rhs) = @_;
4593     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4594 }
4595
4596 sub i_resp_complete {
4597     my $pid = $i_child_pid;
4598     $i_child_pid = undef; # prevents killing some other process with same pid
4599     printdebug "waiting for build host child $pid...\n";
4600     my $got = waitpid $pid, 0;
4601     die $! unless $got == $pid;
4602     die "build host child failed $?" if $?;
4603
4604     i_cleanup();
4605     printdebug "all done\n";
4606     exit 0;
4607 }
4608
4609 sub i_resp_file ($) {
4610     my ($keyword) = @_;
4611     my $localname = i_method "i_localname", $keyword;
4612     my $localpath = "$i_tmp/$localname";
4613     stat_exists $localpath and
4614         badproto \*RO, "file $keyword ($localpath) twice";
4615     protocol_receive_file \*RO, $localpath;
4616     i_method "i_file", $keyword;
4617 }
4618
4619 our %i_param;
4620
4621 sub i_resp_param ($) {
4622     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4623     $i_param{$1} = $2;
4624 }
4625
4626 sub i_resp_previously ($) {
4627     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4628         or badproto \*RO, "bad previously spec";
4629     my $r = system qw(git check-ref-format), $1;
4630     die "bad previously ref spec ($r)" if $r;
4631     $previously{$1} = $2;
4632 }
4633
4634 our %i_wanted;
4635
4636 sub i_resp_want ($) {
4637     my ($keyword) = @_;
4638     die "$keyword ?" if $i_wanted{$keyword}++;
4639
4640     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4641     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4642     die unless $isuite =~ m/^$suite_re$/;
4643
4644     pushing();
4645     rpush_handle_protovsn_bothends();
4646
4647     fail "rpush negotiated protocol version $protovsn".
4648         " which does not support quilt mode $quilt_mode"
4649         if quiltmode_splitbrain;
4650
4651     my @localpaths = i_method "i_want", $keyword;
4652     printdebug "[[  $keyword @localpaths\n";
4653     foreach my $localpath (@localpaths) {
4654         protocol_send_file \*RI, $localpath;
4655     }
4656     print RI "files-end\n" or die $!;
4657 }
4658
4659 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4660
4661 sub i_localname_parsed_changelog {
4662     return "remote-changelog.822";
4663 }
4664 sub i_file_parsed_changelog {
4665     ($i_clogp, $i_version, $i_dscfn) =
4666         push_parse_changelog "$i_tmp/remote-changelog.822";
4667     die if $i_dscfn =~ m#/|^\W#;
4668 }
4669
4670 sub i_localname_dsc {
4671     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4672     return $i_dscfn;
4673 }
4674 sub i_file_dsc { }
4675
4676 sub i_localname_changes {
4677     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4678     $i_changesfn = $i_dscfn;
4679     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4680     return $i_changesfn;
4681 }
4682 sub i_file_changes { }
4683
4684 sub i_want_signed_tag {
4685     printdebug Dumper(\%i_param, $i_dscfn);
4686     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4687         && defined $i_param{'csuite'}
4688         or badproto \*RO, "premature desire for signed-tag";
4689     my $head = $i_param{'head'};
4690     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4691
4692     my $maintview = $i_param{'maint-view'};
4693     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4694
4695     select_tagformat();
4696     if ($protovsn >= 4) {
4697         my $p = $i_param{'tagformat'} // '<undef>';
4698         $p eq $tagformat
4699             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4700     }
4701
4702     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4703     $csuite = $&;
4704     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4705
4706     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4707
4708     return
4709         push_mktags $i_clogp, $i_dscfn,
4710             $i_changesfn, 'remote changes',
4711             \@tagwants;
4712 }
4713
4714 sub i_want_signed_dsc_changes {
4715     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4716     sign_changes $i_changesfn;
4717     return ($i_dscfn, $i_changesfn);
4718 }
4719
4720 #---------- building etc. ----------
4721
4722 our $version;
4723 our $sourcechanges;
4724 our $dscfn;
4725
4726 #----- `3.0 (quilt)' handling -----
4727
4728 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4729
4730 sub quiltify_dpkg_commit ($$$;$) {
4731     my ($patchname,$author,$msg, $xinfo) = @_;
4732     $xinfo //= '';
4733
4734     mkpath '.git/dgit';
4735     my $descfn = ".git/dgit/quilt-description.tmp";
4736     open O, '>', $descfn or die "$descfn: $!";
4737     $msg =~ s/\n+/\n\n/;
4738     print O <<END or die $!;
4739 From: $author
4740 ${xinfo}Subject: $msg
4741 ---
4742
4743 END
4744     close O or die $!;
4745
4746     {
4747         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4748         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4749         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4750         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4751     }
4752 }
4753
4754 sub quiltify_trees_differ ($$;$$$) {
4755     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4756     # returns true iff the two tree objects differ other than in debian/
4757     # with $finegrained,
4758     # returns bitmask 01 - differ in upstream files except .gitignore
4759     #                 02 - differ in .gitignore
4760     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4761     #  is set for each modified .gitignore filename $fn
4762     # if $unrepres is defined, array ref to which is appeneded
4763     #  a list of unrepresentable changes (removals of upstream files
4764     #  (as messages)
4765     local $/=undef;
4766     my @cmd = (@git, qw(diff-tree -z));
4767     push @cmd, qw(--name-only) unless $unrepres;
4768     push @cmd, qw(-r) if $finegrained || $unrepres;
4769     push @cmd, $x, $y;
4770     my $diffs= cmdoutput @cmd;
4771     my $r = 0;
4772     my @lmodes;
4773     foreach my $f (split /\0/, $diffs) {
4774         if ($unrepres && !@lmodes) {
4775             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4776             next;
4777         }
4778         my ($oldmode,$newmode) = @lmodes;
4779         @lmodes = ();
4780
4781         next if $f =~ m#^debian(?:/.*)?$#s;
4782
4783         if ($unrepres) {
4784             eval {
4785                 die "not a plain file\n"
4786                     unless $newmode =~ m/^10\d{4}$/ ||
4787                            $oldmode =~ m/^10\d{4}$/;
4788                 if ($oldmode =~ m/[^0]/ &&
4789                     $newmode =~ m/[^0]/) {
4790                     die "mode changed\n" if $oldmode ne $newmode;
4791                 } else {
4792                     die "non-default mode\n"
4793                         unless $newmode =~ m/^100644$/ ||
4794                                $oldmode =~ m/^100644$/;
4795                 }
4796             };
4797             if ($@) {
4798                 local $/="\n"; chomp $@;
4799                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4800             }
4801         }
4802
4803         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4804         $r |= $isignore ? 02 : 01;
4805         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4806     }
4807     printdebug "quiltify_trees_differ $x $y => $r\n";
4808     return $r;
4809 }
4810
4811 sub quiltify_tree_sentinelfiles ($) {
4812     # lists the `sentinel' files present in the tree
4813     my ($x) = @_;
4814     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4815         qw(-- debian/rules debian/control);
4816     $r =~ s/\n/,/g;
4817     return $r;
4818 }
4819
4820 sub quiltify_splitbrain_needed () {
4821     if (!$split_brain) {
4822         progress "dgit view: changes are required...";
4823         runcmd @git, qw(checkout -q -b dgit-view);
4824         $split_brain = 1;
4825     }
4826 }
4827
4828 sub quiltify_splitbrain ($$$$$$) {
4829     my ($clogp, $unapplied, $headref, $diffbits,
4830         $editedignores, $cachekey) = @_;
4831     if ($quilt_mode !~ m/gbp|dpm/) {
4832         # treat .gitignore just like any other upstream file
4833         $diffbits = { %$diffbits };
4834         $_ = !!$_ foreach values %$diffbits;
4835     }
4836     # We would like any commits we generate to be reproducible
4837     my @authline = clogp_authline($clogp);
4838     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4839     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4840     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4841     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4842     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4843     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4844
4845     if ($quilt_mode =~ m/gbp|unapplied/ &&
4846         ($diffbits->{O2H} & 01)) {
4847         my $msg =
4848  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4849  " but git tree differs from orig in upstream files.";
4850         if (!stat_exists "debian/patches") {
4851             $msg .=
4852  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4853         }
4854         fail $msg;
4855     }
4856     if ($quilt_mode =~ m/dpm/ &&
4857         ($diffbits->{H2A} & 01)) {
4858         fail <<END;
4859 --quilt=$quilt_mode specified, implying patches-applied git tree
4860  but git tree differs from result of applying debian/patches to upstream
4861 END
4862     }
4863     if ($quilt_mode =~ m/gbp|unapplied/ &&
4864         ($diffbits->{O2A} & 01)) { # some patches
4865         quiltify_splitbrain_needed();
4866         progress "dgit view: creating patches-applied version using gbp pq";
4867         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4868         # gbp pq import creates a fresh branch; push back to dgit-view
4869         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4870         runcmd @git, qw(checkout -q dgit-view);
4871     }
4872     if ($quilt_mode =~ m/gbp|dpm/ &&
4873         ($diffbits->{O2A} & 02)) {
4874         fail <<END
4875 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4876  tool which does not create patches for changes to upstream
4877  .gitignores: but, such patches exist in debian/patches.
4878 END
4879     }
4880     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4881         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4882         quiltify_splitbrain_needed();
4883         progress "dgit view: creating patch to represent .gitignore changes";
4884         ensuredir "debian/patches";
4885         my $gipatch = "debian/patches/auto-gitignore";
4886         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4887         stat GIPATCH or die "$gipatch: $!";
4888         fail "$gipatch already exists; but want to create it".
4889             " to record .gitignore changes" if (stat _)[7];
4890         print GIPATCH <<END or die "$gipatch: $!";
4891 Subject: Update .gitignore from Debian packaging branch
4892
4893 The Debian packaging git branch contains these updates to the upstream
4894 .gitignore file(s).  This patch is autogenerated, to provide these
4895 updates to users of the official Debian archive view of the package.
4896
4897 [dgit ($our_version) update-gitignore]
4898 ---
4899 END
4900         close GIPATCH or die "$gipatch: $!";
4901         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4902             $unapplied, $headref, "--", sort keys %$editedignores;
4903         open SERIES, "+>>", "debian/patches/series" or die $!;
4904         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4905         my $newline;
4906         defined read SERIES, $newline, 1 or die $!;
4907         print SERIES "\n" or die $! unless $newline eq "\n";
4908         print SERIES "auto-gitignore\n" or die $!;
4909         close SERIES or die  $!;
4910         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4911         commit_admin <<END
4912 Commit patch to update .gitignore
4913
4914 [dgit ($our_version) update-gitignore-quilt-fixup]
4915 END
4916     }
4917
4918     my $dgitview = git_rev_parse 'HEAD';
4919
4920     changedir '../../../..';
4921     # When we no longer need to support squeeze, use --create-reflog
4922     # instead of this:
4923     ensuredir ".git/logs/refs/dgit-intern";
4924     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4925       or die $!;
4926
4927     my $oldcache = git_get_ref "refs/$splitbraincache";
4928     if ($oldcache eq $dgitview) {
4929         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4930         # git update-ref doesn't always update, in this case.  *sigh*
4931         my $dummy = make_commit_text <<END;
4932 tree $tree
4933 parent $dgitview
4934 author Dgit <dgit\@example.com> 1000000000 +0000
4935 committer Dgit <dgit\@example.com> 1000000000 +0000
4936
4937 Dummy commit - do not use
4938 END
4939         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4940             "refs/$splitbraincache", $dummy;
4941     }
4942     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4943         $dgitview;
4944
4945     changedir '.git/dgit/unpack/work';
4946
4947     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4948     progress "dgit view: created ($saved)";
4949 }
4950
4951 sub quiltify ($$$$) {
4952     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4953
4954     # Quilt patchification algorithm
4955     #
4956     # We search backwards through the history of the main tree's HEAD
4957     # (T) looking for a start commit S whose tree object is identical
4958     # to to the patch tip tree (ie the tree corresponding to the
4959     # current dpkg-committed patch series).  For these purposes
4960     # `identical' disregards anything in debian/ - this wrinkle is
4961     # necessary because dpkg-source treates debian/ specially.
4962     #
4963     # We can only traverse edges where at most one of the ancestors'
4964     # trees differs (in changes outside in debian/).  And we cannot
4965     # handle edges which change .pc/ or debian/patches.  To avoid
4966     # going down a rathole we avoid traversing edges which introduce
4967     # debian/rules or debian/control.  And we set a limit on the
4968     # number of edges we are willing to look at.
4969     #
4970     # If we succeed, we walk forwards again.  For each traversed edge
4971     # PC (with P parent, C child) (starting with P=S and ending with
4972     # C=T) to we do this:
4973     #  - git checkout C
4974     #  - dpkg-source --commit with a patch name and message derived from C
4975     # After traversing PT, we git commit the changes which
4976     # should be contained within debian/patches.
4977
4978     # The search for the path S..T is breadth-first.  We maintain a
4979     # todo list containing search nodes.  A search node identifies a
4980     # commit, and looks something like this:
4981     #  $p = {
4982     #      Commit => $git_commit_id,
4983     #      Child => $c,                          # or undef if P=T
4984     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4985     #      Nontrivial => true iff $p..$c has relevant changes
4986     #  };
4987
4988     my @todo;
4989     my @nots;
4990     my $sref_S;
4991     my $max_work=100;
4992     my %considered; # saves being exponential on some weird graphs
4993
4994     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4995
4996     my $not = sub {
4997         my ($search,$whynot) = @_;
4998         printdebug " search NOT $search->{Commit} $whynot\n";
4999         $search->{Whynot} = $whynot;
5000         push @nots, $search;
5001         no warnings qw(exiting);
5002         next;
5003     };
5004
5005     push @todo, {
5006         Commit => $target,
5007     };
5008
5009     while (@todo) {
5010         my $c = shift @todo;
5011         next if $considered{$c->{Commit}}++;
5012
5013         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5014
5015         printdebug "quiltify investigate $c->{Commit}\n";
5016
5017         # are we done?
5018         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5019             printdebug " search finished hooray!\n";
5020             $sref_S = $c;
5021             last;
5022         }
5023
5024         if ($quilt_mode eq 'nofix') {
5025             fail "quilt fixup required but quilt mode is \`nofix'\n".
5026                 "HEAD commit $c->{Commit} differs from tree implied by ".
5027                 " debian/patches (tree object $oldtiptree)";
5028         }
5029         if ($quilt_mode eq 'smash') {
5030             printdebug " search quitting smash\n";
5031             last;
5032         }
5033
5034         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5035         $not->($c, "has $c_sentinels not $t_sentinels")
5036             if $c_sentinels ne $t_sentinels;
5037
5038         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5039         $commitdata =~ m/\n\n/;
5040         $commitdata =~ $`;
5041         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5042         @parents = map { { Commit => $_, Child => $c } } @parents;
5043
5044         $not->($c, "root commit") if !@parents;
5045
5046         foreach my $p (@parents) {
5047             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5048         }
5049         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5050         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5051
5052         foreach my $p (@parents) {
5053             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5054
5055             my @cmd= (@git, qw(diff-tree -r --name-only),
5056                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5057             my $patchstackchange = cmdoutput @cmd;
5058             if (length $patchstackchange) {
5059                 $patchstackchange =~ s/\n/,/g;
5060                 $not->($p, "changed $patchstackchange");
5061             }
5062
5063             printdebug " search queue P=$p->{Commit} ",
5064                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5065             push @todo, $p;
5066         }
5067     }
5068
5069     if (!$sref_S) {
5070         printdebug "quiltify want to smash\n";
5071
5072         my $abbrev = sub {
5073             my $x = $_[0]{Commit};
5074             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5075             return $x;
5076         };
5077         my $reportnot = sub {
5078             my ($notp) = @_;
5079             my $s = $abbrev->($notp);
5080             my $c = $notp->{Child};
5081             $s .= "..".$abbrev->($c) if $c;
5082             $s .= ": ".$notp->{Whynot};
5083             return $s;
5084         };
5085         if ($quilt_mode eq 'linear') {
5086             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5087             foreach my $notp (@nots) {
5088                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5089             }
5090             print STDERR "$us: $_\n" foreach @$failsuggestion;
5091             fail "quilt fixup naive history linearisation failed.\n".
5092  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5093         } elsif ($quilt_mode eq 'smash') {
5094         } elsif ($quilt_mode eq 'auto') {
5095             progress "quilt fixup cannot be linear, smashing...";
5096         } else {
5097             die "$quilt_mode ?";
5098         }
5099
5100         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5101         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5102         my $ncommits = 3;
5103         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5104
5105         quiltify_dpkg_commit "auto-$version-$target-$time",
5106             (getfield $clogp, 'Maintainer'),
5107             "Automatically generated patch ($clogp->{Version})\n".
5108             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5109         return;
5110     }
5111
5112     progress "quiltify linearisation planning successful, executing...";
5113
5114     for (my $p = $sref_S;
5115          my $c = $p->{Child};
5116          $p = $p->{Child}) {
5117         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5118         next unless $p->{Nontrivial};
5119
5120         my $cc = $c->{Commit};
5121
5122         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5123         $commitdata =~ m/\n\n/ or die "$c ?";
5124         $commitdata = $`;
5125         my $msg = $'; #';
5126         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5127         my $author = $1;
5128
5129         my $commitdate = cmdoutput
5130             @git, qw(log -n1 --pretty=format:%aD), $cc;
5131
5132         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5133
5134         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5135         $strip_nls->();
5136
5137         my $title = $1;
5138         my $patchname;
5139         my $patchdir;
5140
5141         my $gbp_check_suitable = sub {
5142             $_ = shift;
5143             my ($what) = @_;
5144
5145             eval {
5146                 die "contains unexpected slashes\n" if m{//} || m{/$};
5147                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5148                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5149                 die "too long" if length > 200;
5150             };
5151             return $_ unless $@;
5152             print STDERR "quiltifying commit $cc:".
5153                 " ignoring/dropping Gbp-Pq $what: $@";
5154             return undef;
5155         };
5156
5157         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5158                            gbp-pq-name: \s* )
5159                        (\S+) \s* \n //ixm) {
5160             $patchname = $gbp_check_suitable->($1, 'Name');
5161         }
5162         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5163                            gbp-pq-topic: \s* )
5164                        (\S+) \s* \n //ixm) {
5165             $patchdir = $gbp_check_suitable->($1, 'Topic');
5166         }
5167
5168         $strip_nls->();
5169
5170         if (!defined $patchname) {
5171             $patchname = $title;
5172             $patchname =~ s/[.:]$//;
5173             use Text::Iconv;
5174             eval {
5175                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5176                 my $translitname = $converter->convert($patchname);
5177                 die unless defined $translitname;
5178                 $patchname = $translitname;
5179             };
5180             print STDERR
5181                 "dgit: patch title transliteration error: $@"
5182                 if $@;
5183             $patchname =~ y/ A-Z/-a-z/;
5184             $patchname =~ y/-a-z0-9_.+=~//cd;
5185             $patchname =~ s/^\W/x-$&/;
5186             $patchname = substr($patchname,0,40);
5187         }
5188         if (!defined $patchdir) {
5189             $patchdir = '';
5190         }
5191         if (length $patchdir) {
5192             $patchname = "$patchdir/$patchname";
5193         }
5194         if ($patchname =~ m{^(.*)/}) {
5195             mkpath "debian/patches/$1";
5196         }
5197
5198         my $index;
5199         for ($index='';
5200              stat "debian/patches/$patchname$index";
5201              $index++) { }
5202         $!==ENOENT or die "$patchname$index $!";
5203
5204         runcmd @git, qw(checkout -q), $cc;
5205
5206         # We use the tip's changelog so that dpkg-source doesn't
5207         # produce complaining messages from dpkg-parsechangelog.  None
5208         # of the information dpkg-source gets from the changelog is
5209         # actually relevant - it gets put into the original message
5210         # which dpkg-source provides our stunt editor, and then
5211         # overwritten.
5212         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5213
5214         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5215             "Date: $commitdate\n".
5216             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5217
5218         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5219     }
5220
5221     runcmd @git, qw(checkout -q master);
5222 }
5223
5224 sub build_maybe_quilt_fixup () {
5225     my ($format,$fopts) = get_source_format;
5226     return unless madformat_wantfixup $format;
5227     # sigh
5228
5229     check_for_vendor_patches();
5230
5231     if (quiltmode_splitbrain) {
5232         fail <<END unless access_cfg_tagformats_can_splitbrain;
5233 quilt mode $quilt_mode requires split view so server needs to support
5234  both "new" and "maint" tag formats, but config says it doesn't.
5235 END
5236     }
5237
5238     my $clogp = parsechangelog();
5239     my $headref = git_rev_parse('HEAD');
5240
5241     prep_ud();
5242     changedir $ud;
5243
5244     my $upstreamversion = upstreamversion $version;
5245
5246     if ($fopts->{'single-debian-patch'}) {
5247         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5248     } else {
5249         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5250     }
5251
5252     die 'bug' if $split_brain && !$need_split_build_invocation;
5253
5254     changedir '../../../..';
5255     runcmd_ordryrun_local
5256         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5257 }
5258
5259 sub quilt_fixup_mkwork ($) {
5260     my ($headref) = @_;
5261
5262     mkdir "work" or die $!;
5263     changedir "work";
5264     mktree_in_ud_here();
5265     runcmd @git, qw(reset -q --hard), $headref;
5266 }
5267
5268 sub quilt_fixup_linkorigs ($$) {
5269     my ($upstreamversion, $fn) = @_;
5270     # calls $fn->($leafname);
5271
5272     foreach my $f (<../../../../*>) { #/){
5273         my $b=$f; $b =~ s{.*/}{};
5274         {
5275             local ($debuglevel) = $debuglevel-1;
5276             printdebug "QF linkorigs $b, $f ?\n";
5277         }
5278         next unless is_orig_file_of_vsn $b, $upstreamversion;
5279         printdebug "QF linkorigs $b, $f Y\n";
5280         link_ltarget $f, $b or die "$b $!";
5281         $fn->($b);
5282     }
5283 }
5284
5285 sub quilt_fixup_delete_pc () {
5286     runcmd @git, qw(rm -rqf .pc);
5287     commit_admin <<END
5288 Commit removal of .pc (quilt series tracking data)
5289
5290 [dgit ($our_version) upgrade quilt-remove-pc]
5291 END
5292 }
5293
5294 sub quilt_fixup_singlepatch ($$$) {
5295     my ($clogp, $headref, $upstreamversion) = @_;
5296
5297     progress "starting quiltify (single-debian-patch)";
5298
5299     # dpkg-source --commit generates new patches even if
5300     # single-debian-patch is in debian/source/options.  In order to
5301     # get it to generate debian/patches/debian-changes, it is
5302     # necessary to build the source package.
5303
5304     quilt_fixup_linkorigs($upstreamversion, sub { });
5305     quilt_fixup_mkwork($headref);
5306
5307     rmtree("debian/patches");
5308
5309     runcmd @dpkgsource, qw(-b .);
5310     changedir "..";
5311     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5312     rename srcfn("$upstreamversion", "/debian/patches"),
5313            "work/debian/patches";
5314
5315     changedir "work";
5316     commit_quilty_patch();
5317 }
5318
5319 sub quilt_make_fake_dsc ($) {
5320     my ($upstreamversion) = @_;
5321
5322     my $fakeversion="$upstreamversion-~~DGITFAKE";
5323
5324     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5325     print $fakedsc <<END or die $!;
5326 Format: 3.0 (quilt)
5327 Source: $package
5328 Version: $fakeversion
5329 Files:
5330 END
5331
5332     my $dscaddfile=sub {
5333         my ($b) = @_;
5334
5335         my $md = new Digest::MD5;
5336
5337         my $fh = new IO::File $b, '<' or die "$b $!";
5338         stat $fh or die $!;
5339         my $size = -s _;
5340
5341         $md->addfile($fh);
5342         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5343     };
5344
5345     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5346
5347     my @files=qw(debian/source/format debian/rules
5348                  debian/control debian/changelog);
5349     foreach my $maybe (qw(debian/patches debian/source/options
5350                           debian/tests/control)) {
5351         next unless stat_exists "../../../$maybe";
5352         push @files, $maybe;
5353     }
5354
5355     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5356     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5357
5358     $dscaddfile->($debtar);
5359     close $fakedsc or die $!;
5360 }
5361
5362 sub quilt_check_splitbrain_cache ($$) {
5363     my ($headref, $upstreamversion) = @_;
5364     # Called only if we are in (potentially) split brain mode.
5365     # Called in $ud.
5366     # Computes the cache key and looks in the cache.
5367     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5368
5369     my $splitbrain_cachekey;
5370
5371     progress
5372  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5373     # we look in the reflog of dgit-intern/quilt-cache
5374     # we look for an entry whose message is the key for the cache lookup
5375     my @cachekey = (qw(dgit), $our_version);
5376     push @cachekey, $upstreamversion;
5377     push @cachekey, $quilt_mode;
5378     push @cachekey, $headref;
5379
5380     push @cachekey, hashfile('fake.dsc');
5381
5382     my $srcshash = Digest::SHA->new(256);
5383     my %sfs = ( %INC, '$0(dgit)' => $0 );
5384     foreach my $sfk (sort keys %sfs) {
5385         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5386         $srcshash->add($sfk,"  ");
5387         $srcshash->add(hashfile($sfs{$sfk}));
5388         $srcshash->add("\n");
5389     }
5390     push @cachekey, $srcshash->hexdigest();
5391     $splitbrain_cachekey = "@cachekey";
5392
5393     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5394                $splitbraincache);
5395     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5396     debugcmd "|(probably)",@cmd;
5397     my $child = open GC, "-|";  defined $child or die $!;
5398     if (!$child) {
5399         chdir '../../..' or die $!;
5400         if (!stat ".git/logs/refs/$splitbraincache") {
5401             $! == ENOENT or die $!;
5402             printdebug ">(no reflog)\n";
5403             exit 0;
5404         }
5405         exec @cmd; die $!;
5406     }
5407     while (<GC>) {
5408         chomp;
5409         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5410         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5411
5412         my $cachehit = $1;
5413         quilt_fixup_mkwork($headref);
5414         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5415         if ($cachehit ne $headref) {
5416             progress "dgit view: found cached ($saved)";
5417             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5418             $split_brain = 1;
5419             return ($cachehit, $splitbrain_cachekey);
5420         }
5421         progress "dgit view: found cached, no changes required";
5422         return ($headref, $splitbrain_cachekey);
5423     }
5424     die $! if GC->error;
5425     failedcmd unless close GC;
5426
5427     printdebug "splitbrain cache miss\n";
5428     return (undef, $splitbrain_cachekey);
5429 }
5430
5431 sub quilt_fixup_multipatch ($$$) {
5432     my ($clogp, $headref, $upstreamversion) = @_;
5433
5434     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5435
5436     # Our objective is:
5437     #  - honour any existing .pc in case it has any strangeness
5438     #  - determine the git commit corresponding to the tip of
5439     #    the patch stack (if there is one)
5440     #  - if there is such a git commit, convert each subsequent
5441     #    git commit into a quilt patch with dpkg-source --commit
5442     #  - otherwise convert all the differences in the tree into
5443     #    a single git commit
5444     #
5445     # To do this we:
5446
5447     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5448     # dgit would include the .pc in the git tree.)  If there isn't
5449     # one, we need to generate one by unpacking the patches that we
5450     # have.
5451     #
5452     # We first look for a .pc in the git tree.  If there is one, we
5453     # will use it.  (This is not the normal case.)
5454     #
5455     # Otherwise need to regenerate .pc so that dpkg-source --commit
5456     # can work.  We do this as follows:
5457     #     1. Collect all relevant .orig from parent directory
5458     #     2. Generate a debian.tar.gz out of
5459     #         debian/{patches,rules,source/format,source/options}
5460     #     3. Generate a fake .dsc containing just these fields:
5461     #          Format Source Version Files
5462     #     4. Extract the fake .dsc
5463     #        Now the fake .dsc has a .pc directory.
5464     # (In fact we do this in every case, because in future we will
5465     # want to search for a good base commit for generating patches.)
5466     #
5467     # Then we can actually do the dpkg-source --commit
5468     #     1. Make a new working tree with the same object
5469     #        store as our main tree and check out the main
5470     #        tree's HEAD.
5471     #     2. Copy .pc from the fake's extraction, if necessary
5472     #     3. Run dpkg-source --commit
5473     #     4. If the result has changes to debian/, then
5474     #          - git add them them
5475     #          - git add .pc if we had a .pc in-tree
5476     #          - git commit
5477     #     5. If we had a .pc in-tree, delete it, and git commit
5478     #     6. Back in the main tree, fast forward to the new HEAD
5479
5480     # Another situation we may have to cope with is gbp-style
5481     # patches-unapplied trees.
5482     #
5483     # We would want to detect these, so we know to escape into
5484     # quilt_fixup_gbp.  However, this is in general not possible.
5485     # Consider a package with a one patch which the dgit user reverts
5486     # (with git revert or the moral equivalent).
5487     #
5488     # That is indistinguishable in contents from a patches-unapplied
5489     # tree.  And looking at the history to distinguish them is not
5490     # useful because the user might have made a confusing-looking git
5491     # history structure (which ought to produce an error if dgit can't
5492     # cope, not a silent reintroduction of an unwanted patch).
5493     #
5494     # So gbp users will have to pass an option.  But we can usually
5495     # detect their failure to do so: if the tree is not a clean
5496     # patches-applied tree, quilt linearisation fails, but the tree
5497     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5498     # they want --quilt=unapplied.
5499     #
5500     # To help detect this, when we are extracting the fake dsc, we
5501     # first extract it with --skip-patches, and then apply the patches
5502     # afterwards with dpkg-source --before-build.  That lets us save a
5503     # tree object corresponding to .origs.
5504
5505     my $splitbrain_cachekey;
5506
5507     quilt_make_fake_dsc($upstreamversion);
5508
5509     if (quiltmode_splitbrain()) {
5510         my $cachehit;
5511         ($cachehit, $splitbrain_cachekey) =
5512             quilt_check_splitbrain_cache($headref, $upstreamversion);
5513         return if $cachehit;
5514     }
5515
5516     runcmd qw(sh -ec),
5517         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5518
5519     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5520     rename $fakexdir, "fake" or die "$fakexdir $!";
5521
5522     changedir 'fake';
5523
5524     remove_stray_gits("source package");
5525     mktree_in_ud_here();
5526
5527     rmtree '.pc';
5528
5529     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5530     my $unapplied=git_add_write_tree();
5531     printdebug "fake orig tree object $unapplied\n";
5532
5533     ensuredir '.pc';
5534
5535     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5536     $!=0; $?=-1;
5537     if (system @bbcmd) {
5538         failedcmd @bbcmd if $? < 0;
5539         fail <<END;
5540 failed to apply your git tree's patch stack (from debian/patches/) to
5541  the corresponding upstream tarball(s).  Your source tree and .orig
5542  are probably too inconsistent.  dgit can only fix up certain kinds of
5543  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5544 END
5545     }
5546
5547     changedir '..';
5548
5549     quilt_fixup_mkwork($headref);
5550
5551     my $mustdeletepc=0;
5552     if (stat_exists ".pc") {
5553         -d _ or die;
5554         progress "Tree already contains .pc - will use it then delete it.";
5555         $mustdeletepc=1;
5556     } else {
5557         rename '../fake/.pc','.pc' or die $!;
5558     }
5559
5560     changedir '../fake';
5561     rmtree '.pc';
5562     my $oldtiptree=git_add_write_tree();
5563     printdebug "fake o+d/p tree object $unapplied\n";
5564     changedir '../work';
5565
5566
5567     # We calculate some guesswork now about what kind of tree this might
5568     # be.  This is mostly for error reporting.
5569
5570     my %editedignores;
5571     my @unrepres;
5572     my $diffbits = {
5573         # H = user's HEAD
5574         # O = orig, without patches applied
5575         # A = "applied", ie orig with H's debian/patches applied
5576         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5577                                      \%editedignores, \@unrepres),
5578         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5579         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5580     };
5581
5582     my @dl;
5583     foreach my $b (qw(01 02)) {
5584         foreach my $v (qw(O2H O2A H2A)) {
5585             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5586         }
5587     }
5588     printdebug "differences \@dl @dl.\n";
5589
5590     progress sprintf
5591 "$us: base trees orig=%.20s o+d/p=%.20s",
5592               $unapplied, $oldtiptree;
5593     progress sprintf
5594 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5595 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5596                              $dl[0], $dl[1],              $dl[3], $dl[4],
5597                                  $dl[2],                     $dl[5];
5598
5599     if (@unrepres) {
5600         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5601             foreach @unrepres;
5602         forceable_fail [qw(unrepresentable)], <<END;
5603 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5604 END
5605     }
5606
5607     my @failsuggestion;
5608     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5609         push @failsuggestion, "This might be a patches-unapplied branch.";
5610     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5611         push @failsuggestion, "This might be a patches-applied branch.";
5612     }
5613     push @failsuggestion, "Maybe you need to specify one of".
5614         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5615
5616     if (quiltmode_splitbrain()) {
5617         quiltify_splitbrain($clogp, $unapplied, $headref,
5618                             $diffbits, \%editedignores,
5619                             $splitbrain_cachekey);
5620         return;
5621     }
5622
5623     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5624     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5625
5626     if (!open P, '>>', ".pc/applied-patches") {
5627         $!==&ENOENT or die $!;
5628     } else {
5629         close P;
5630     }
5631
5632     commit_quilty_patch();
5633
5634     if ($mustdeletepc) {
5635         quilt_fixup_delete_pc();
5636     }
5637 }
5638
5639 sub quilt_fixup_editor () {
5640     my $descfn = $ENV{$fakeeditorenv};
5641     my $editing = $ARGV[$#ARGV];
5642     open I1, '<', $descfn or die "$descfn: $!";
5643     open I2, '<', $editing or die "$editing: $!";
5644     unlink $editing or die "$editing: $!";
5645     open O, '>', $editing or die "$editing: $!";
5646     while (<I1>) { print O or die $!; } I1->error and die $!;
5647     my $copying = 0;
5648     while (<I2>) {
5649         $copying ||= m/^\-\-\- /;
5650         next unless $copying;
5651         print O or die $!;
5652     }
5653     I2->error and die $!;
5654     close O or die $1;
5655     exit 0;
5656 }
5657
5658 sub maybe_apply_patches_dirtily () {
5659     return unless $quilt_mode =~ m/gbp|unapplied/;
5660     print STDERR <<END or die $!;
5661
5662 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5663 dgit: Have to apply the patches - making the tree dirty.
5664 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5665
5666 END
5667     $patches_applied_dirtily = 01;
5668     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5669     runcmd qw(dpkg-source --before-build .);
5670 }
5671
5672 sub maybe_unapply_patches_again () {
5673     progress "dgit: Unapplying patches again to tidy up the tree."
5674         if $patches_applied_dirtily;
5675     runcmd qw(dpkg-source --after-build .)
5676         if $patches_applied_dirtily & 01;
5677     rmtree '.pc'
5678         if $patches_applied_dirtily & 02;
5679     $patches_applied_dirtily = 0;
5680 }
5681
5682 #----- other building -----
5683
5684 our $clean_using_builder;
5685 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5686 #   clean the tree before building (perhaps invoked indirectly by
5687 #   whatever we are using to run the build), rather than separately
5688 #   and explicitly by us.
5689
5690 sub clean_tree () {
5691     return if $clean_using_builder;
5692     if ($cleanmode eq 'dpkg-source') {
5693         maybe_apply_patches_dirtily();
5694         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5695     } elsif ($cleanmode eq 'dpkg-source-d') {
5696         maybe_apply_patches_dirtily();
5697         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5698     } elsif ($cleanmode eq 'git') {
5699         runcmd_ordryrun_local @git, qw(clean -xdf);
5700     } elsif ($cleanmode eq 'git-ff') {
5701         runcmd_ordryrun_local @git, qw(clean -xdff);
5702     } elsif ($cleanmode eq 'check') {
5703         my $leftovers = cmdoutput @git, qw(clean -xdn);
5704         if (length $leftovers) {
5705             print STDERR $leftovers, "\n" or die $!;
5706             fail "tree contains uncommitted files and --clean=check specified";
5707         }
5708     } elsif ($cleanmode eq 'none') {
5709     } else {
5710         die "$cleanmode ?";
5711     }
5712 }
5713
5714 sub cmd_clean () {
5715     badusage "clean takes no additional arguments" if @ARGV;
5716     notpushing();
5717     clean_tree();
5718     maybe_unapply_patches_again();
5719 }
5720
5721 sub build_prep_early () {
5722     our $build_prep_early_done //= 0;
5723     return if $build_prep_early_done++;
5724     badusage "-p is not allowed when building" if defined $package;
5725     my $clogp = parsechangelog();
5726     $isuite = getfield $clogp, 'Distribution';
5727     $package = getfield $clogp, 'Source';
5728     $version = getfield $clogp, 'Version';
5729     notpushing();
5730     check_not_dirty();
5731 }
5732
5733 sub build_prep () {
5734     build_prep_early();
5735     clean_tree();
5736     build_maybe_quilt_fixup();
5737     if ($rmchanges) {
5738         my $pat = changespat $version;
5739         foreach my $f (glob "$buildproductsdir/$pat") {
5740             if (act_local()) {
5741                 unlink $f or fail "remove old changes file $f: $!";
5742             } else {
5743                 progress "would remove $f";
5744             }
5745         }
5746     }
5747 }
5748
5749 sub changesopts_initial () {
5750     my @opts =@changesopts[1..$#changesopts];
5751 }
5752
5753 sub changesopts_version () {
5754     if (!defined $changes_since_version) {
5755         my @vsns = archive_query('archive_query');
5756         my @quirk = access_quirk();
5757         if ($quirk[0] eq 'backports') {
5758             local $isuite = $quirk[2];
5759             local $csuite;
5760             canonicalise_suite();
5761             push @vsns, archive_query('archive_query');
5762         }
5763         if (@vsns) {
5764             @vsns = map { $_->[0] } @vsns;
5765             @vsns = sort { -version_compare($a, $b) } @vsns;
5766             $changes_since_version = $vsns[0];
5767             progress "changelog will contain changes since $vsns[0]";
5768         } else {
5769             $changes_since_version = '_';
5770             progress "package seems new, not specifying -v<version>";
5771         }
5772     }
5773     if ($changes_since_version ne '_') {
5774         return ("-v$changes_since_version");
5775     } else {
5776         return ();
5777     }
5778 }
5779
5780 sub changesopts () {
5781     return (changesopts_initial(), changesopts_version());
5782 }
5783
5784 sub massage_dbp_args ($;$) {
5785     my ($cmd,$xargs) = @_;
5786     # We need to:
5787     #
5788     #  - if we're going to split the source build out so we can
5789     #    do strange things to it, massage the arguments to dpkg-buildpackage
5790     #    so that the main build doessn't build source (or add an argument
5791     #    to stop it building source by default).
5792     #
5793     #  - add -nc to stop dpkg-source cleaning the source tree,
5794     #    unless we're not doing a split build and want dpkg-source
5795     #    as cleanmode, in which case we can do nothing
5796     #
5797     # return values:
5798     #    0 - source will NOT need to be built separately by caller
5799     #   +1 - source will need to be built separately by caller
5800     #   +2 - source will need to be built separately by caller AND
5801     #        dpkg-buildpackage should not in fact be run at all!
5802     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5803 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5804     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5805         $clean_using_builder = 1;
5806         return 0;
5807     }
5808     # -nc has the side effect of specifying -b if nothing else specified
5809     # and some combinations of -S, -b, et al, are errors, rather than
5810     # later simply overriding earlie.  So we need to:
5811     #  - search the command line for these options
5812     #  - pick the last one
5813     #  - perhaps add our own as a default
5814     #  - perhaps adjust it to the corresponding non-source-building version
5815     my $dmode = '-F';
5816     foreach my $l ($cmd, $xargs) {
5817         next unless $l;
5818         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5819     }
5820     push @$cmd, '-nc';
5821 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5822     my $r = 0;
5823     if ($need_split_build_invocation) {
5824         printdebug "massage split $dmode.\n";
5825         $r = $dmode =~ m/[S]/     ? +2 :
5826              $dmode =~ y/gGF/ABb/ ? +1 :
5827              $dmode =~ m/[ABb]/   ?  0 :
5828              die "$dmode ?";
5829     }
5830     printdebug "massage done $r $dmode.\n";
5831     push @$cmd, $dmode;
5832 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5833     return $r;
5834 }
5835
5836 sub in_parent (&) {
5837     my ($fn) = @_;
5838     my $wasdir = must_getcwd();
5839     changedir "..";
5840     $fn->();
5841     changedir $wasdir;
5842 }
5843
5844 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5845     my ($msg_if_onlyone) = @_;
5846     # If there is only one .changes file, fail with $msg_if_onlyone,
5847     # or if that is undef, be a no-op.
5848     # Returns the changes file to report to the user.
5849     my $pat = changespat $version;
5850     my @changesfiles = glob $pat;
5851     @changesfiles = sort {
5852         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5853             or $a cmp $b
5854     } @changesfiles;
5855     my $result;
5856     if (@changesfiles==1) {
5857         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5858 only one changes file from build (@changesfiles)
5859 END
5860         $result = $changesfiles[0];
5861     } elsif (@changesfiles==2) {
5862         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5863         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5864             fail "$l found in binaries changes file $binchanges"
5865                 if $l =~ m/\.dsc$/;
5866         }
5867         runcmd_ordryrun_local @mergechanges, @changesfiles;
5868         my $multichanges = changespat $version,'multi';
5869         if (act_local()) {
5870             stat_exists $multichanges or fail "$multichanges: $!";
5871             foreach my $cf (glob $pat) {
5872                 next if $cf eq $multichanges;
5873                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5874             }
5875         }
5876         $result = $multichanges;
5877     } else {
5878         fail "wrong number of different changes files (@changesfiles)";
5879     }
5880     printdone "build successful, results in $result\n" or die $!;
5881 }
5882
5883 sub midbuild_checkchanges () {
5884     my $pat = changespat $version;
5885     return if $rmchanges;
5886     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5887     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5888     fail <<END
5889 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5890 Suggest you delete @unwanted.
5891 END
5892         if @unwanted;
5893 }
5894
5895 sub midbuild_checkchanges_vanilla ($) {
5896     my ($wantsrc) = @_;
5897     midbuild_checkchanges() if $wantsrc == 1;
5898 }
5899
5900 sub postbuild_mergechanges_vanilla ($) {
5901     my ($wantsrc) = @_;
5902     if ($wantsrc == 1) {
5903         in_parent {
5904             postbuild_mergechanges(undef);
5905         };
5906     } else {
5907         printdone "build successful\n";
5908     }
5909 }
5910
5911 sub cmd_build {
5912     build_prep_early();
5913     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5914     my $wantsrc = massage_dbp_args \@dbp;
5915     if ($wantsrc > 0) {
5916         build_source();
5917         midbuild_checkchanges_vanilla $wantsrc;
5918     } else {
5919         build_prep();
5920     }
5921     if ($wantsrc < 2) {
5922         push @dbp, changesopts_version();
5923         maybe_apply_patches_dirtily();
5924         runcmd_ordryrun_local @dbp;
5925     }
5926     maybe_unapply_patches_again();
5927     postbuild_mergechanges_vanilla $wantsrc;
5928 }
5929
5930 sub pre_gbp_build {
5931     $quilt_mode //= 'gbp';
5932 }
5933
5934 sub cmd_gbp_build {
5935     build_prep_early();
5936
5937     # gbp can make .origs out of thin air.  In my tests it does this
5938     # even for a 1.0 format package, with no origs present.  So I
5939     # guess it keys off just the version number.  We don't know
5940     # exactly what .origs ought to exist, but let's assume that we
5941     # should run gbp if: the version has an upstream part and the main
5942     # orig is absent.
5943     my $upstreamversion = upstreamversion $version;
5944     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5945     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5946
5947     if ($gbp_make_orig) {
5948         clean_tree();
5949         $cleanmode = 'none'; # don't do it again
5950         $need_split_build_invocation = 1;
5951     }
5952
5953     my @dbp = @dpkgbuildpackage;
5954
5955     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5956
5957     if (!length $gbp_build[0]) {
5958         if (length executable_on_path('git-buildpackage')) {
5959             $gbp_build[0] = qw(git-buildpackage);
5960         } else {
5961             $gbp_build[0] = 'gbp buildpackage';
5962         }
5963     }
5964     my @cmd = opts_opt_multi_cmd @gbp_build;
5965
5966     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5967
5968     if ($gbp_make_orig) {
5969         ensuredir '.git/dgit';
5970         my $ok = '.git/dgit/origs-gen-ok';
5971         unlink $ok or $!==&ENOENT or die $!;
5972         my @origs_cmd = @cmd;
5973         push @origs_cmd, qw(--git-cleaner=true);
5974         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5975         push @origs_cmd, @ARGV;
5976         if (act_local()) {
5977             debugcmd @origs_cmd;
5978             system @origs_cmd;
5979             do { local $!; stat_exists $ok; }
5980                 or failedcmd @origs_cmd;
5981         } else {
5982             dryrun_report @origs_cmd;
5983         }
5984     }
5985
5986     if ($wantsrc > 0) {
5987         build_source();
5988         midbuild_checkchanges_vanilla $wantsrc;
5989     } else {
5990         if (!$clean_using_builder) {
5991             push @cmd, '--git-cleaner=true';
5992         }
5993         build_prep();
5994     }
5995     maybe_unapply_patches_again();
5996     if ($wantsrc < 2) {
5997         push @cmd, changesopts();
5998         runcmd_ordryrun_local @cmd, @ARGV;
5999     }
6000     postbuild_mergechanges_vanilla $wantsrc;
6001 }
6002 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6003
6004 sub build_source {
6005     build_prep_early();
6006     my $our_cleanmode = $cleanmode;
6007     if ($need_split_build_invocation) {
6008         # Pretend that clean is being done some other way.  This
6009         # forces us not to try to use dpkg-buildpackage to clean and
6010         # build source all in one go; and instead we run dpkg-source
6011         # (and build_prep() will do the clean since $clean_using_builder
6012         # is false).
6013         $our_cleanmode = 'ELSEWHERE';
6014     }
6015     if ($our_cleanmode =~ m/^dpkg-source/) {
6016         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6017         $clean_using_builder = 1;
6018     }
6019     build_prep();
6020     $sourcechanges = changespat $version,'source';
6021     if (act_local()) {
6022         unlink "../$sourcechanges" or $!==ENOENT
6023             or fail "remove $sourcechanges: $!";
6024     }
6025     $dscfn = dscfn($version);
6026     if ($our_cleanmode eq 'dpkg-source') {
6027         maybe_apply_patches_dirtily();
6028         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6029             changesopts();
6030     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6031         maybe_apply_patches_dirtily();
6032         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6033             changesopts();
6034     } else {
6035         my @cmd = (@dpkgsource, qw(-b --));
6036         if ($split_brain) {
6037             changedir $ud;
6038             runcmd_ordryrun_local @cmd, "work";
6039             my @udfiles = <${package}_*>;
6040             changedir "../../..";
6041             foreach my $f (@udfiles) {
6042                 printdebug "source copy, found $f\n";
6043                 next unless
6044                     $f eq $dscfn or
6045                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6046                      $f eq srcfn($version, $&));
6047                 printdebug "source copy, found $f - renaming\n";
6048                 rename "$ud/$f", "../$f" or $!==ENOENT
6049                     or fail "put in place new source file ($f): $!";
6050             }
6051         } else {
6052             my $pwd = must_getcwd();
6053             my $leafdir = basename $pwd;
6054             changedir "..";
6055             runcmd_ordryrun_local @cmd, $leafdir;
6056             changedir $pwd;
6057         }
6058         runcmd_ordryrun_local qw(sh -ec),
6059             'exec >$1; shift; exec "$@"','x',
6060             "../$sourcechanges",
6061             @dpkggenchanges, qw(-S), changesopts();
6062     }
6063 }
6064
6065 sub cmd_build_source {
6066     build_prep_early();
6067     badusage "build-source takes no additional arguments" if @ARGV;
6068     build_source();
6069     maybe_unapply_patches_again();
6070     printdone "source built, results in $dscfn and $sourcechanges";
6071 }
6072
6073 sub cmd_sbuild {
6074     build_source();
6075     midbuild_checkchanges();
6076     in_parent {
6077         if (act_local()) {
6078             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6079             stat_exists $sourcechanges
6080                 or fail "$sourcechanges (in parent directory): $!";
6081         }
6082         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6083     };
6084     maybe_unapply_patches_again();
6085     in_parent {
6086         postbuild_mergechanges(<<END);
6087 perhaps you need to pass -A ?  (sbuild's default is to build only
6088 arch-specific binaries; dgit 1.4 used to override that.)
6089 END
6090     };
6091 }
6092
6093 sub cmd_quilt_fixup {
6094     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6095     build_prep_early();
6096     clean_tree();
6097     build_maybe_quilt_fixup();
6098 }
6099
6100 sub import_dsc_result {
6101     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6102     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6103     runcmd @cmd;
6104     progress "dgit: import-dsc: $what_msg";
6105 }
6106
6107 sub cmd_import_dsc {
6108     my $needsig = 0;
6109
6110     while (@ARGV) {
6111         last unless $ARGV[0] =~ m/^-/;
6112         $_ = shift @ARGV;
6113         last if m/^--?$/;
6114         if (m/^--require-valid-signature$/) {
6115             $needsig = 1;
6116         } else {
6117             badusage "unknown dgit import-dsc sub-option \`$_'";
6118         }
6119     }
6120
6121     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6122     my ($dscfn, $dstbranch) = @ARGV;
6123
6124     badusage "dry run makes no sense with import-dsc" unless act_local();
6125
6126     my $force = $dstbranch =~ s/^\+//   ? +1 :
6127                 $dstbranch =~ s/^\.\.// ? -1 :
6128                                            0;
6129     my $info = $force ? " $&" : '';
6130     $info = "$dscfn$info";
6131
6132     my $specbranch = $dstbranch;
6133     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6134     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6135
6136     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6137     my $chead = cmdoutput_errok @symcmd;
6138     defined $chead or $?==256 or failedcmd @symcmd;
6139
6140     fail "$dstbranch is checked out - will not update it"
6141         if defined $chead and $chead eq $dstbranch;
6142
6143     my $oldhash = git_get_ref $dstbranch;
6144
6145     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6146     $dscdata = do { local $/ = undef; <D>; };
6147     D->error and fail "read $dscfn: $!";
6148     close C;
6149
6150     # we don't normally need this so import it here
6151     use Dpkg::Source::Package;
6152     my $dp = new Dpkg::Source::Package filename => $dscfn,
6153         require_valid_signature => $needsig;
6154     {
6155         local $SIG{__WARN__} = sub {
6156             print STDERR $_[0];
6157             return unless $needsig;
6158             fail "import-dsc signature check failed";
6159         };
6160         if (!$dp->is_signed()) {
6161             warn "$us: warning: importing unsigned .dsc\n";
6162         } else {
6163             my $r = $dp->check_signature();
6164             die "->check_signature => $r" if $needsig && $r;
6165         }
6166     }
6167
6168     parse_dscdata();
6169
6170     $package = getfield $dsc, 'Source';
6171
6172     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6173         unless forceing [qw(import-dsc-with-dgit-field)];
6174     parse_dsc_field_def_dsc_distro();
6175
6176     $isuite = 'DGIT-IMPORT-DSC';
6177     $idistro //= $dsc_distro;
6178
6179     notpushing();
6180
6181     if (defined $dsc_hash) {
6182         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6183         resolve_dsc_field_commit undef, undef;
6184     }
6185     if (defined $dsc_hash) {
6186         my @cmd = (qw(sh -ec),
6187                    "echo $dsc_hash | git cat-file --batch-check");
6188         my $objgot = cmdoutput @cmd;
6189         if ($objgot =~ m#^\w+ missing\b#) {
6190             fail <<END
6191 .dsc contains Dgit field referring to object $dsc_hash
6192 Your git tree does not have that object.  Try `git fetch' from a
6193 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6194 END
6195         }
6196         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6197             if ($force > 0) {
6198                 progress "Not fast forward, forced update.";
6199             } else {
6200                 fail "Not fast forward to $dsc_hash";
6201             }
6202         }
6203         import_dsc_result $dstbranch, $dsc_hash,
6204             "dgit import-dsc (Dgit): $info",
6205             "updated git ref $dstbranch";
6206         return 0;
6207     }
6208
6209     fail <<END
6210 Branch $dstbranch already exists
6211 Specify ..$specbranch for a pseudo-merge, binding in existing history
6212 Specify  +$specbranch to overwrite, discarding existing history
6213 END
6214         if $oldhash && !$force;
6215
6216     my @dfi = dsc_files_info();
6217     foreach my $fi (@dfi) {
6218         my $f = $fi->{Filename};
6219         my $here = "../$f";
6220         next if lstat $here;
6221         fail "stat $here: $!" unless $! == ENOENT;
6222         my $there = $dscfn;
6223         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6224             $there = $';
6225         } elsif ($dscfn =~ m#^/#) {
6226             $there = $dscfn;
6227         } else {
6228             fail "cannot import $dscfn which seems to be inside working tree!";
6229         }
6230         $there =~ s#/+[^/]+$## or
6231             fail "cannot import $dscfn which seems to not have a basename";
6232         $there .= "/$f";
6233         symlink $there, $here or fail "symlink $there to $here: $!";
6234         progress "made symlink $here -> $there";
6235 #       print STDERR Dumper($fi);
6236     }
6237     my @mergeinputs = generate_commits_from_dsc();
6238     die unless @mergeinputs == 1;
6239
6240     my $newhash = $mergeinputs[0]{Commit};
6241
6242     if ($oldhash) {
6243         if ($force > 0) {
6244             progress "Import, forced update - synthetic orphan git history.";
6245         } elsif ($force < 0) {
6246             progress "Import, merging.";
6247             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6248             my $version = getfield $dsc, 'Version';
6249             my $clogp = commit_getclogp $newhash;
6250             my $authline = clogp_authline $clogp;
6251             $newhash = make_commit_text <<END;
6252 tree $tree
6253 parent $newhash
6254 parent $oldhash
6255 author $authline
6256 committer $authline
6257
6258 Merge $package ($version) import into $dstbranch
6259 END
6260         } else {
6261             die; # caught earlier
6262         }
6263     }
6264
6265     import_dsc_result $dstbranch, $newhash,
6266         "dgit import-dsc: $info",
6267         "results are in in git ref $dstbranch";
6268 }
6269
6270 sub cmd_archive_api_query {
6271     badusage "need only 1 subpath argument" unless @ARGV==1;
6272     my ($subpath) = @ARGV;
6273     my @cmd = archive_api_query_cmd($subpath);
6274     push @cmd, qw(-f);
6275     debugcmd ">",@cmd;
6276     exec @cmd or fail "exec curl: $!\n";
6277 }
6278
6279 sub cmd_clone_dgit_repos_server {
6280     badusage "need destination argument" unless @ARGV==1;
6281     my ($destdir) = @ARGV;
6282     $package = '_dgit-repos-server';
6283     local $access_forpush = 0;
6284     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6285     debugcmd ">",@cmd;
6286     exec @cmd or fail "exec git clone: $!\n";
6287 }
6288
6289 sub cmd_print_dgit_repos_server_source_url {
6290     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6291         if @ARGV;
6292     $package = '_dgit-repos-server';
6293     local $access_forpush = 0;
6294     my $url = access_giturl();
6295     print $url, "\n" or die $!;
6296 }
6297
6298 sub cmd_setup_mergechangelogs {
6299     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6300     setup_mergechangelogs(1);
6301 }
6302
6303 sub cmd_setup_useremail {
6304     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6305     setup_useremail(1);
6306 }
6307
6308 sub cmd_setup_new_tree {
6309     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6310     setup_new_tree();
6311 }
6312
6313 #---------- argument parsing and main program ----------
6314
6315 sub cmd_version {
6316     print "dgit version $our_version\n" or die $!;
6317     exit 0;
6318 }
6319
6320 our (%valopts_long, %valopts_short);
6321 our (%funcopts_long);
6322 our @rvalopts;
6323 our (@modeopt_cfgs);
6324
6325 sub defvalopt ($$$$) {
6326     my ($long,$short,$val_re,$how) = @_;
6327     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6328     $valopts_long{$long} = $oi;
6329     $valopts_short{$short} = $oi;
6330     # $how subref should:
6331     #   do whatever assignemnt or thing it likes with $_[0]
6332     #   if the option should not be passed on to remote, @rvalopts=()
6333     # or $how can be a scalar ref, meaning simply assign the value
6334 }
6335
6336 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6337 defvalopt '--distro',        '-d', '.+',      \$idistro;
6338 defvalopt '',                '-k', '.+',      \$keyid;
6339 defvalopt '--existing-package','', '.*',      \$existing_package;
6340 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6341 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6342 defvalopt '--package',   '-p',   $package_re, \$package;
6343 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6344
6345 defvalopt '', '-C', '.+', sub {
6346     ($changesfile) = (@_);
6347     if ($changesfile =~ s#^(.*)/##) {
6348         $buildproductsdir = $1;
6349     }
6350 };
6351
6352 defvalopt '--initiator-tempdir','','.*', sub {
6353     ($initiator_tempdir) = (@_);
6354     $initiator_tempdir =~ m#^/# or
6355         badusage "--initiator-tempdir must be used specify an".
6356         " absolute, not relative, directory."
6357 };
6358
6359 sub defoptmodes ($@) {
6360     my ($varref, $cfgkey, $default, %optmap) = @_;
6361     my %permit;
6362     while (my ($opt,$val) = each %optmap) {
6363         $funcopts_long{$opt} = sub { $$varref = $val; };
6364         $permit{$val} = $val;
6365     }
6366     push @modeopt_cfgs, {
6367         Var => $varref,
6368         Key => $cfgkey,
6369         Default => $default,
6370         Vals => \%permit
6371     };
6372 }
6373
6374 defoptmodes \$dodep14tag, qw( dep14tag          want
6375                               --dep14tag        want
6376                               --no-dep14tag     no
6377                               --always-dep14tag always );
6378
6379 sub parseopts () {
6380     my $om;
6381
6382     if (defined $ENV{'DGIT_SSH'}) {
6383         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6384     } elsif (defined $ENV{'GIT_SSH'}) {
6385         @ssh = ($ENV{'GIT_SSH'});
6386     }
6387
6388     my $oi;
6389     my $val;
6390     my $valopt = sub {
6391         my ($what) = @_;
6392         @rvalopts = ($_);
6393         if (!defined $val) {
6394             badusage "$what needs a value" unless @ARGV;
6395             $val = shift @ARGV;
6396             push @rvalopts, $val;
6397         }
6398         badusage "bad value \`$val' for $what" unless
6399             $val =~ m/^$oi->{Re}$(?!\n)/s;
6400         my $how = $oi->{How};
6401         if (ref($how) eq 'SCALAR') {
6402             $$how = $val;
6403         } else {
6404             $how->($val);
6405         }
6406         push @ropts, @rvalopts;
6407     };
6408
6409     while (@ARGV) {
6410         last unless $ARGV[0] =~ m/^-/;
6411         $_ = shift @ARGV;
6412         last if m/^--?$/;
6413         if (m/^--/) {
6414             if (m/^--dry-run$/) {
6415                 push @ropts, $_;
6416                 $dryrun_level=2;
6417             } elsif (m/^--damp-run$/) {
6418                 push @ropts, $_;
6419                 $dryrun_level=1;
6420             } elsif (m/^--no-sign$/) {
6421                 push @ropts, $_;
6422                 $sign=0;
6423             } elsif (m/^--help$/) {
6424                 cmd_help();
6425             } elsif (m/^--version$/) {
6426                 cmd_version();
6427             } elsif (m/^--new$/) {
6428                 push @ropts, $_;
6429                 $new_package=1;
6430             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6431                      ($om = $opts_opt_map{$1}) &&
6432                      length $om->[0]) {
6433                 push @ropts, $_;
6434                 $om->[0] = $2;
6435             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6436                      !$opts_opt_cmdonly{$1} &&
6437                      ($om = $opts_opt_map{$1})) {
6438                 push @ropts, $_;
6439                 push @$om, $2;
6440             } elsif (m/^--(gbp|dpm)$/s) {
6441                 push @ropts, "--quilt=$1";
6442                 $quilt_mode = $1;
6443             } elsif (m/^--ignore-dirty$/s) {
6444                 push @ropts, $_;
6445                 $ignoredirty = 1;
6446             } elsif (m/^--no-quilt-fixup$/s) {
6447                 push @ropts, $_;
6448                 $quilt_mode = 'nocheck';
6449             } elsif (m/^--no-rm-on-error$/s) {
6450                 push @ropts, $_;
6451                 $rmonerror = 0;
6452             } elsif (m/^--no-chase-dsc-distro$/s) {
6453                 push @ropts, $_;
6454                 $chase_dsc_distro = 0;
6455             } elsif (m/^--overwrite$/s) {
6456                 push @ropts, $_;
6457                 $overwrite_version = '';
6458             } elsif (m/^--overwrite=(.+)$/s) {
6459                 push @ropts, $_;
6460                 $overwrite_version = $1;
6461             } elsif (m/^--delayed=(\d+)$/s) {
6462                 push @ropts, $_;
6463                 push @dput, $_;
6464             } elsif (m/^--dgit-view-save=(.+)$/s) {
6465                 push @ropts, $_;
6466                 $split_brain_save = $1;
6467                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6468             } elsif (m/^--(no-)?rm-old-changes$/s) {
6469                 push @ropts, $_;
6470                 $rmchanges = !$1;
6471             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6472                 push @ropts, $_;
6473                 push @deliberatelies, $&;
6474             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6475                 push @ropts, $&;
6476                 $forceopts{$1} = 1;
6477                 $_='';
6478             } elsif (m/^--force-/) {
6479                 print STDERR
6480                     "$us: warning: ignoring unknown force option $_\n";
6481                 $_='';
6482             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6483                 # undocumented, for testing
6484                 push @ropts, $_;
6485                 $tagformat_want = [ $1, 'command line', 1 ];
6486                 # 1 menas overrides distro configuration
6487             } elsif (m/^--always-split-source-build$/s) {
6488                 # undocumented, for testing
6489                 push @ropts, $_;
6490                 $need_split_build_invocation = 1;
6491             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6492                 # undocumented, for testing
6493                 push @ropts, $_;
6494                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6495                 # ^ it's supposed to be an array ref
6496             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6497                 $val = $2 ? $' : undef; #';
6498                 $valopt->($oi->{Long});
6499             } elsif ($funcopts_long{$_}) {
6500                 push @ropts, $_;
6501                 $funcopts_long{$_}();
6502             } else {
6503                 badusage "unknown long option \`$_'";
6504             }
6505         } else {
6506             while (m/^-./s) {
6507                 if (s/^-n/-/) {
6508                     push @ropts, $&;
6509                     $dryrun_level=2;
6510                 } elsif (s/^-L/-/) {
6511                     push @ropts, $&;
6512                     $dryrun_level=1;
6513                 } elsif (s/^-h/-/) {
6514                     cmd_help();
6515                 } elsif (s/^-D/-/) {
6516                     push @ropts, $&;
6517                     $debuglevel++;
6518                     enabledebug();
6519                 } elsif (s/^-N/-/) {
6520                     push @ropts, $&;
6521                     $new_package=1;
6522                 } elsif (m/^-m/) {
6523                     push @ropts, $&;
6524                     push @changesopts, $_;
6525                     $_ = '';
6526                 } elsif (s/^-wn$//s) {
6527                     push @ropts, $&;
6528                     $cleanmode = 'none';
6529                 } elsif (s/^-wg$//s) {
6530                     push @ropts, $&;
6531                     $cleanmode = 'git';
6532                 } elsif (s/^-wgf$//s) {
6533                     push @ropts, $&;
6534                     $cleanmode = 'git-ff';
6535                 } elsif (s/^-wd$//s) {
6536                     push @ropts, $&;
6537                     $cleanmode = 'dpkg-source';
6538                 } elsif (s/^-wdd$//s) {
6539                     push @ropts, $&;
6540                     $cleanmode = 'dpkg-source-d';
6541                 } elsif (s/^-wc$//s) {
6542                     push @ropts, $&;
6543                     $cleanmode = 'check';
6544                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6545                     push @git, '-c', $&;
6546                     $gitcfgs{cmdline}{$1} = [ $2 ];
6547                 } elsif (s/^-c([^=]+)$//s) {
6548                     push @git, '-c', $&;
6549                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6550                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6551                     $val = $'; #';
6552                     $val = undef unless length $val;
6553                     $valopt->($oi->{Short});
6554                     $_ = '';
6555                 } else {
6556                     badusage "unknown short option \`$_'";
6557                 }
6558             }
6559         }
6560     }
6561 }
6562
6563 sub check_env_sanity () {
6564     my $blocked = new POSIX::SigSet;
6565     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6566
6567     eval {
6568         foreach my $name (qw(PIPE CHLD)) {
6569             my $signame = "SIG$name";
6570             my $signum = eval "POSIX::$signame" // die;
6571             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6572                 die "$signame is set to something other than SIG_DFL\n";
6573             $blocked->ismember($signum) and
6574                 die "$signame is blocked\n";
6575         }
6576     };
6577     return unless $@;
6578     chomp $@;
6579     fail <<END;
6580 On entry to dgit, $@
6581 This is a bug produced by something in in your execution environment.
6582 Giving up.
6583 END
6584 }
6585
6586
6587 sub parseopts_late_defaults () {
6588     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6589         if defined $idistro;
6590     $isuite //= cfg('dgit.default.default-suite');
6591
6592     foreach my $k (keys %opts_opt_map) {
6593         my $om = $opts_opt_map{$k};
6594
6595         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6596         if (defined $v) {
6597             badcfg "cannot set command for $k"
6598                 unless length $om->[0];
6599             $om->[0] = $v;
6600         }
6601
6602         foreach my $c (access_cfg_cfgs("opts-$k")) {
6603             my @vl =
6604                 map { $_ ? @$_ : () }
6605                 map { $gitcfgs{$_}{$c} }
6606                 reverse @gitcfgsources;
6607             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6608                 "\n" if $debuglevel >= 4;
6609             next unless @vl;
6610             badcfg "cannot configure options for $k"
6611                 if $opts_opt_cmdonly{$k};
6612             my $insertpos = $opts_cfg_insertpos{$k};
6613             @$om = ( @$om[0..$insertpos-1],
6614                      @vl,
6615                      @$om[$insertpos..$#$om] );
6616         }
6617     }
6618
6619     if (!defined $rmchanges) {
6620         local $access_forpush;
6621         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6622     }
6623
6624     if (!defined $quilt_mode) {
6625         local $access_forpush;
6626         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6627             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6628             // 'linear';
6629         $quilt_mode =~ m/^($quilt_modes_re)$/
6630             or badcfg "unknown quilt-mode \`$quilt_mode'";
6631         $quilt_mode = $1;
6632     }
6633
6634     foreach my $moc (@modeopt_cfgs) {
6635         local $access_forpush;
6636         my $vr = $moc->{Var};
6637         next if defined $$vr;
6638         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6639         my $v = $moc->{Vals}{$$vr};
6640         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6641         $$vr = $v;
6642     }
6643
6644     $need_split_build_invocation ||= quiltmode_splitbrain();
6645
6646     if (!defined $cleanmode) {
6647         local $access_forpush;
6648         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6649         $cleanmode //= 'dpkg-source';
6650
6651         badcfg "unknown clean-mode \`$cleanmode'" unless
6652             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6653     }
6654 }
6655
6656 if ($ENV{$fakeeditorenv}) {
6657     git_slurp_config();
6658     quilt_fixup_editor();
6659 }
6660
6661 parseopts();
6662 check_env_sanity();
6663 git_slurp_config();
6664
6665 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6666 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6667     if $dryrun_level == 1;
6668 if (!@ARGV) {
6669     print STDERR $helpmsg or die $!;
6670     exit 8;
6671 }
6672 my $cmd = shift @ARGV;
6673 $cmd =~ y/-/_/;
6674
6675 my $pre_fn = ${*::}{"pre_$cmd"};
6676 $pre_fn->() if $pre_fn;
6677
6678 my $fn = ${*::}{"cmd_$cmd"};
6679 $fn or badusage "unknown operation $cmd";
6680 $fn->();