chiark / gitweb /
Merge tag dgit/2.14 into `defence in dgit-repos-server' branch
[dgit.git] / dgit
1 #!/usr/bin/perl -w
2 # dgit
3 # Integration between git and Debian-style archives
4 #
5 # Copyright (C)2013-2016 Ian Jackson
6 #
7 # This program is free software: you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation, either version 3 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
19
20 use strict;
21
22 use Debian::Dgit;
23 setup_sigwarn();
24
25 use IO::Handle;
26 use Data::Dumper;
27 use LWP::UserAgent;
28 use Dpkg::Control::Hash;
29 use File::Path;
30 use File::Temp qw(tempdir);
31 use File::Basename;
32 use Dpkg::Version;
33 use POSIX;
34 use IPC::Open2;
35 use Digest::SHA;
36 use Digest::MD5;
37 use List::Util qw(any);
38 use List::MoreUtils qw(pairwise);
39 use Text::Glob qw(match_glob);
40 use Fcntl qw(:DEFAULT :flock);
41 use Carp;
42
43 use Debian::Dgit;
44
45 our $our_version = 'UNRELEASED'; ###substituted###
46 our $absurdity = undef; ###substituted###
47
48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
49 our $protovsn;
50
51 our $isuite = 'unstable';
52 our $idistro;
53 our $package;
54 our @ropts;
55
56 our $sign = 1;
57 our $dryrun_level = 0;
58 our $changesfile;
59 our $buildproductsdir = '..';
60 our $new_package = 0;
61 our $ignoredirty = 0;
62 our $rmonerror = 1;
63 our @deliberatelies;
64 our %previously;
65 our $existing_package = 'dpkg';
66 our $cleanmode;
67 our $changes_since_version;
68 our $rmchanges;
69 our $overwrite_version; # undef: not specified; '': check changelog
70 our $quilt_mode;
71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
72 our $dodep14tag;
73 our $dodep14tag_re = 'want|no|always';
74 our $split_brain_save;
75 our $we_are_responder;
76 our $initiator_tempdir;
77 our $patches_applied_dirtily = 00;
78 our $tagformat_want;
79 our $tagformat;
80 our $tagformatfn;
81
82 our %forceopts = map { $_=>0 }
83     qw(unrepresentable unsupported-source-format
84        dsc-changes-mismatch changes-origs-exactly
85        import-gitapply-absurd
86        import-gitapply-no-absurd
87        import-dsc-with-dgit-field);
88
89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
90
91 our $suite_re = '[-+.0-9a-z]+';
92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
96
97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
98 our $splitbraincache = 'dgit-intern/quilt-cache';
99
100 our (@git) = qw(git);
101 our (@dget) = qw(dget);
102 our (@curl) = qw(curl);
103 our (@dput) = qw(dput);
104 our (@debsign) = qw(debsign);
105 our (@gpg) = qw(gpg);
106 our (@sbuild) = qw(sbuild);
107 our (@ssh) = 'ssh';
108 our (@dgit) = qw(dgit);
109 our (@aptget) = qw(apt-get);
110 our (@aptcache) = qw(apt-cache);
111 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
112 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
113 our (@dpkggenchanges) = qw(dpkg-genchanges);
114 our (@mergechanges) = qw(mergechanges -f);
115 our (@gbp_build) = ('');
116 our (@gbp_pq) = ('gbp pq');
117 our (@changesopts) = ('');
118
119 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
120                      'curl' => \@curl,
121                      'dput' => \@dput,
122                      'debsign' => \@debsign,
123                      'gpg' => \@gpg,
124                      'sbuild' => \@sbuild,
125                      'ssh' => \@ssh,
126                      'dgit' => \@dgit,
127                      'git' => \@git,
128                      'apt-get' => \@aptget,
129                      'apt-cache' => \@aptcache,
130                      'dpkg-source' => \@dpkgsource,
131                      'dpkg-buildpackage' => \@dpkgbuildpackage,
132                      'dpkg-genchanges' => \@dpkggenchanges,
133                      'gbp-build' => \@gbp_build,
134                      'gbp-pq' => \@gbp_pq,
135                      'ch' => \@changesopts,
136                      'mergechanges' => \@mergechanges);
137
138 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
139 our %opts_cfg_insertpos = map {
140     $_,
141     scalar @{ $opts_opt_map{$_} }
142 } keys %opts_opt_map;
143
144 sub finalise_opts_opts();
145
146 our $keyid;
147
148 autoflush STDOUT 1;
149
150 our $supplementary_message = '';
151 our $need_split_build_invocation = 0;
152 our $split_brain = 0;
153
154 END {
155     local ($@, $?);
156     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
157 }
158
159 our $remotename = 'dgit';
160 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
161 our $csuite;
162 our $instead_distro;
163
164 if (!defined $absurdity) {
165     $absurdity = $0;
166     $absurdity =~ s{/[^/]+$}{/absurd} or die;
167 }
168
169 sub debiantag ($$) {
170     my ($v,$distro) = @_;
171     return $tagformatfn->($v, $distro);
172 }
173
174 sub debiantag_maintview ($$) { 
175     my ($v,$distro) = @_;
176     return "$distro/".dep14_version_mangle $v;
177 }
178
179 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
180
181 sub lbranch () { return "$branchprefix/$csuite"; }
182 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
183 sub lref () { return "refs/heads/".lbranch(); }
184 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
185 sub rrref () { return server_ref($csuite); }
186
187 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
188 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
189
190 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
191 # locally fetched refs because they have unhelpful names and clutter
192 # up gitk etc.  So we track whether we have "used up" head ref (ie,
193 # whether we have made another local ref which refers to this object).
194 #
195 # (If we deleted them unconditionally, then we might end up
196 # re-fetching the same git objects each time dgit fetch was run.)
197 #
198 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
199 # in git_fetch_us to fetch the refs in question, and possibly a call
200 # to lrfetchref_used.
201
202 our (%lrfetchrefs_f, %lrfetchrefs_d);
203 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
204
205 sub lrfetchref_used ($) {
206     my ($fullrefname) = @_;
207     my $objid = $lrfetchrefs_f{$fullrefname};
208     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
209 }
210
211 sub stripepoch ($) {
212     my ($vsn) = @_;
213     $vsn =~ s/^\d+\://;
214     return $vsn;
215 }
216
217 sub srcfn ($$) {
218     my ($vsn,$sfx) = @_;
219     return "${package}_".(stripepoch $vsn).$sfx
220 }
221
222 sub dscfn ($) {
223     my ($vsn) = @_;
224     return srcfn($vsn,".dsc");
225 }
226
227 sub changespat ($;$) {
228     my ($vsn, $arch) = @_;
229     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
230 }
231
232 sub upstreamversion ($) {
233     my ($vsn) = @_;
234     $vsn =~ s/-[^-]+$//;
235     return $vsn;
236 }
237
238 our $us = 'dgit';
239 initdebug('');
240
241 our @end;
242 END { 
243     local ($?);
244     foreach my $f (@end) {
245         eval { $f->(); };
246         print STDERR "$us: cleanup: $@" if length $@;
247     }
248 };
249
250 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
251
252 sub forceable_fail ($$) {
253     my ($forceoptsl, $msg) = @_;
254     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
255     print STDERR "warning: overriding problem due to --force:\n". $msg;
256 }
257
258 sub forceing ($) {
259     my ($forceoptsl) = @_;
260     my @got = grep { $forceopts{$_} } @$forceoptsl;
261     return 0 unless @got;
262     print STDERR
263  "warning: skipping checks or functionality due to --force-$got[0]\n";
264 }
265
266 sub no_such_package () {
267     print STDERR "$us: package $package does not exist in suite $isuite\n";
268     exit 4;
269 }
270
271 sub changedir ($) {
272     my ($newdir) = @_;
273     printdebug "CD $newdir\n";
274     chdir $newdir or confess "chdir: $newdir: $!";
275 }
276
277 sub deliberately ($) {
278     my ($enquiry) = @_;
279     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
280 }
281
282 sub deliberately_not_fast_forward () {
283     foreach (qw(not-fast-forward fresh-repo)) {
284         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
285     }
286 }
287
288 sub quiltmode_splitbrain () {
289     $quilt_mode =~ m/gbp|dpm|unapplied/;
290 }
291
292 sub opts_opt_multi_cmd {
293     my @cmd;
294     push @cmd, split /\s+/, shift @_;
295     push @cmd, @_;
296     @cmd;
297 }
298
299 sub gbp_pq {
300     return opts_opt_multi_cmd @gbp_pq;
301 }
302
303 #---------- remote protocol support, common ----------
304
305 # remote push initiator/responder protocol:
306 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
307 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
308 #  < dgit-remote-push-ready <actual-proto-vsn>
309 #
310 # occasionally:
311 #
312 #  > progress NBYTES
313 #  [NBYTES message]
314 #
315 #  > supplementary-message NBYTES          # $protovsn >= 3
316 #  [NBYTES message]
317 #
318 # main sequence:
319 #
320 #  > file parsed-changelog
321 #  [indicates that output of dpkg-parsechangelog follows]
322 #  > data-block NBYTES
323 #  > [NBYTES bytes of data (no newline)]
324 #  [maybe some more blocks]
325 #  > data-end
326 #
327 #  > file dsc
328 #  [etc]
329 #
330 #  > file changes
331 #  [etc]
332 #
333 #  > param head DGIT-VIEW-HEAD
334 #  > param csuite SUITE
335 #  > param tagformat old|new
336 #  > param maint-view MAINT-VIEW-HEAD
337 #
338 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
339 #                                     # goes into tag, for replay prevention
340 #
341 #  > want signed-tag
342 #  [indicates that signed tag is wanted]
343 #  < data-block NBYTES
344 #  < [NBYTES bytes of data (no newline)]
345 #  [maybe some more blocks]
346 #  < data-end
347 #  < files-end
348 #
349 #  > want signed-dsc-changes
350 #  < data-block NBYTES    [transfer of signed dsc]
351 #  [etc]
352 #  < data-block NBYTES    [transfer of signed changes]
353 #  [etc]
354 #  < files-end
355 #
356 #  > complete
357
358 our $i_child_pid;
359
360 sub i_child_report () {
361     # Sees if our child has died, and reap it if so.  Returns a string
362     # describing how it died if it failed, or undef otherwise.
363     return undef unless $i_child_pid;
364     my $got = waitpid $i_child_pid, WNOHANG;
365     return undef if $got <= 0;
366     die unless $got == $i_child_pid;
367     $i_child_pid = undef;
368     return undef unless $?;
369     return "build host child ".waitstatusmsg();
370 }
371
372 sub badproto ($$) {
373     my ($fh, $m) = @_;
374     fail "connection lost: $!" if $fh->error;
375     fail "protocol violation; $m not expected";
376 }
377
378 sub badproto_badread ($$) {
379     my ($fh, $wh) = @_;
380     fail "connection lost: $!" if $!;
381     my $report = i_child_report();
382     fail $report if defined $report;
383     badproto $fh, "eof (reading $wh)";
384 }
385
386 sub protocol_expect (&$) {
387     my ($match, $fh) = @_;
388     local $_;
389     $_ = <$fh>;
390     defined && chomp or badproto_badread $fh, "protocol message";
391     if (wantarray) {
392         my @r = &$match;
393         return @r if @r;
394     } else {
395         my $r = &$match;
396         return $r if $r;
397     }
398     badproto $fh, "\`$_'";
399 }
400
401 sub protocol_send_file ($$) {
402     my ($fh, $ourfn) = @_;
403     open PF, "<", $ourfn or die "$ourfn: $!";
404     for (;;) {
405         my $d;
406         my $got = read PF, $d, 65536;
407         die "$ourfn: $!" unless defined $got;
408         last if !$got;
409         print $fh "data-block ".length($d)."\n" or die $!;
410         print $fh $d or die $!;
411     }
412     PF->error and die "$ourfn $!";
413     print $fh "data-end\n" or die $!;
414     close PF;
415 }
416
417 sub protocol_read_bytes ($$) {
418     my ($fh, $nbytes) = @_;
419     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
420     my $d;
421     my $got = read $fh, $d, $nbytes;
422     $got==$nbytes or badproto_badread $fh, "data block";
423     return $d;
424 }
425
426 sub protocol_receive_file ($$) {
427     my ($fh, $ourfn) = @_;
428     printdebug "() $ourfn\n";
429     open PF, ">", $ourfn or die "$ourfn: $!";
430     for (;;) {
431         my ($y,$l) = protocol_expect {
432             m/^data-block (.*)$/ ? (1,$1) :
433             m/^data-end$/ ? (0,) :
434             ();
435         } $fh;
436         last unless $y;
437         my $d = protocol_read_bytes $fh, $l;
438         print PF $d or die $!;
439     }
440     close PF or die $!;
441 }
442
443 #---------- remote protocol support, responder ----------
444
445 sub responder_send_command ($) {
446     my ($command) = @_;
447     return unless $we_are_responder;
448     # called even without $we_are_responder
449     printdebug ">> $command\n";
450     print PO $command, "\n" or die $!;
451 }    
452
453 sub responder_send_file ($$) {
454     my ($keyword, $ourfn) = @_;
455     return unless $we_are_responder;
456     printdebug "]] $keyword $ourfn\n";
457     responder_send_command "file $keyword";
458     protocol_send_file \*PO, $ourfn;
459 }
460
461 sub responder_receive_files ($@) {
462     my ($keyword, @ourfns) = @_;
463     die unless $we_are_responder;
464     printdebug "[[ $keyword @ourfns\n";
465     responder_send_command "want $keyword";
466     foreach my $fn (@ourfns) {
467         protocol_receive_file \*PI, $fn;
468     }
469     printdebug "[[\$\n";
470     protocol_expect { m/^files-end$/ } \*PI;
471 }
472
473 #---------- remote protocol support, initiator ----------
474
475 sub initiator_expect (&) {
476     my ($match) = @_;
477     protocol_expect { &$match } \*RO;
478 }
479
480 #---------- end remote code ----------
481
482 sub progress {
483     if ($we_are_responder) {
484         my $m = join '', @_;
485         responder_send_command "progress ".length($m) or die $!;
486         print PO $m or die $!;
487     } else {
488         print @_, "\n";
489     }
490 }
491
492 our $ua;
493
494 sub url_get {
495     if (!$ua) {
496         $ua = LWP::UserAgent->new();
497         $ua->env_proxy;
498     }
499     my $what = $_[$#_];
500     progress "downloading $what...";
501     my $r = $ua->get(@_) or die $!;
502     return undef if $r->code == 404;
503     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
504     return $r->decoded_content(charset => 'none');
505 }
506
507 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
508
509 sub runcmd {
510     debugcmd "+",@_;
511     $!=0; $?=-1;
512     failedcmd @_ if system @_;
513 }
514
515 sub act_local () { return $dryrun_level <= 1; }
516 sub act_scary () { return !$dryrun_level; }
517
518 sub printdone {
519     if (!$dryrun_level) {
520         progress "$us ok: @_";
521     } else {
522         progress "would be ok: @_ (but dry run only)";
523     }
524 }
525
526 sub dryrun_report {
527     printcmd(\*STDERR,$debugprefix."#",@_);
528 }
529
530 sub runcmd_ordryrun {
531     if (act_scary()) {
532         runcmd @_;
533     } else {
534         dryrun_report @_;
535     }
536 }
537
538 sub runcmd_ordryrun_local {
539     if (act_local()) {
540         runcmd @_;
541     } else {
542         dryrun_report @_;
543     }
544 }
545
546 sub shell_cmd {
547     my ($first_shell, @cmd) = @_;
548     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
549 }
550
551 our $helpmsg = <<END;
552 main usages:
553   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
554   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
555   dgit [dgit-opts] build [dpkg-buildpackage-opts]
556   dgit [dgit-opts] sbuild [sbuild-opts]
557   dgit [dgit-opts] push [dgit-opts] [suite]
558   dgit [dgit-opts] rpush build-host:build-dir ...
559 important dgit options:
560   -k<keyid>           sign tag and package with <keyid> instead of default
561   --dry-run -n        do not change anything, but go through the motions
562   --damp-run -L       like --dry-run but make local changes, without signing
563   --new -N            allow introducing a new package
564   --debug -D          increase debug level
565   -c<name>=<value>    set git config option (used directly by dgit too)
566 END
567
568 our $later_warning_msg = <<END;
569 Perhaps the upload is stuck in incoming.  Using the version from git.
570 END
571
572 sub badusage {
573     print STDERR "$us: @_\n", $helpmsg or die $!;
574     exit 8;
575 }
576
577 sub nextarg {
578     @ARGV or badusage "too few arguments";
579     return scalar shift @ARGV;
580 }
581
582 sub cmd_help () {
583     print $helpmsg or die $!;
584     exit 0;
585 }
586
587 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
588
589 our %defcfg = ('dgit.default.distro' => 'debian',
590                'dgit-suite.*-security.distro' => 'debian-security',
591                'dgit.default.username' => '',
592                'dgit.default.archive-query-default-component' => 'main',
593                'dgit.default.ssh' => 'ssh',
594                'dgit.default.archive-query' => 'madison:',
595                'dgit.default.sshpsql-dbname' => 'service=projectb',
596                'dgit.default.aptget-components' => 'main',
597                'dgit.default.dgit-tag-format' => 'new,old,maint',
598                # old means "repo server accepts pushes with old dgit tags"
599                # new means "repo server accepts pushes with new dgit tags"
600                # maint means "repo server accepts split brain pushes"
601                # hist means "repo server may have old pushes without new tag"
602                #   ("hist" is implied by "old")
603                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
604                'dgit-distro.debian.git-check' => 'url',
605                'dgit-distro.debian.git-check-suffix' => '/info/refs',
606                'dgit-distro.debian.new-private-pushers' => 't',
607                'dgit-distro.debian/push.git-url' => '',
608                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
609                'dgit-distro.debian/push.git-user-force' => 'dgit',
610                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
611                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
612                'dgit-distro.debian/push.git-create' => 'true',
613                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
614  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
615 # 'dgit-distro.debian.archive-query-tls-key',
616 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
617 # ^ this does not work because curl is broken nowadays
618 # Fixing #790093 properly will involve providing providing the key
619 # in some pacagke and maybe updating these paths.
620 #
621 # 'dgit-distro.debian.archive-query-tls-curl-args',
622 #   '--ca-path=/etc/ssl/ca-debian',
623 # ^ this is a workaround but works (only) on DSA-administered machines
624                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
625                'dgit-distro.debian.git-url-suffix' => '',
626                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
627                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
628  'dgit-distro.debian-security.archive-query' => 'aptget:',
629  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
630  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
631  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
632  'dgit-distro.debian-security.nominal-distro' => 'debian',
633  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
634  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
635                'dgit-distro.ubuntu.git-check' => 'false',
636  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
637                'dgit-distro.test-dummy.ssh' => "$td/ssh",
638                'dgit-distro.test-dummy.username' => "alice",
639                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
640                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
641                'dgit-distro.test-dummy.git-url' => "$td/git",
642                'dgit-distro.test-dummy.git-host' => "git",
643                'dgit-distro.test-dummy.git-path' => "$td/git",
644                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
645                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
646                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
647                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
648                );
649
650 our %gitcfgs;
651 our @gitcfgsources = qw(cmdline local global system);
652
653 sub git_slurp_config () {
654     local ($debuglevel) = $debuglevel-2;
655     local $/="\0";
656
657     # This algoritm is a bit subtle, but this is needed so that for
658     # options which we want to be single-valued, we allow the
659     # different config sources to override properly.  See #835858.
660     foreach my $src (@gitcfgsources) {
661         next if $src eq 'cmdline';
662         # we do this ourselves since git doesn't handle it
663         
664         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
665         debugcmd "|",@cmd;
666
667         open GITS, "-|", @cmd or die $!;
668         while (<GITS>) {
669             chomp or die;
670             printdebug "=> ", (messagequote $_), "\n";
671             m/\n/ or die "$_ ?";
672             push @{ $gitcfgs{$src}{$`} }, $'; #';
673         }
674         $!=0; $?=0;
675         close GITS
676             or ($!==0 && $?==256)
677             or failedcmd @cmd;
678     }
679 }
680
681 sub git_get_config ($) {
682     my ($c) = @_;
683     foreach my $src (@gitcfgsources) {
684         my $l = $gitcfgs{$src}{$c};
685         printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
686             if $debuglevel >= 4;
687         $l or next;
688         @$l==1 or badcfg "multiple values for $c".
689             " (in $src git config)" if @$l > 1;
690         return $l->[0];
691     }
692     return undef;
693 }
694
695 sub cfg {
696     foreach my $c (@_) {
697         return undef if $c =~ /RETURN-UNDEF/;
698         my $v = git_get_config($c);
699         return $v if defined $v;
700         my $dv = $defcfg{$c};
701         return $dv if defined $dv;
702     }
703     badcfg "need value for one of: @_\n".
704         "$us: distro or suite appears not to be (properly) supported";
705 }
706
707 sub access_basedistro () {
708     if (defined $idistro) {
709         return $idistro;
710     } else {    
711         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
712         return $def if defined $def;
713         foreach my $src (@gitcfgsources, 'internal') {
714             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
715             next unless $kl;
716             foreach my $k (keys %$kl) {
717                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
718                 my $dpat = $1;
719                 next unless match_glob $dpat, $isuite;
720                 return $kl->{$k};
721             }
722         }
723         return cfg("dgit.default.distro");
724     }
725 }
726
727 sub access_nomdistro () {
728     my $base = access_basedistro();
729     return cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
730 }
731
732 sub access_quirk () {
733     # returns (quirk name, distro to use instead or undef, quirk-specific info)
734     my $basedistro = access_basedistro();
735     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
736                               'RETURN-UNDEF');
737     if (defined $backports_quirk) {
738         my $re = $backports_quirk;
739         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
740         $re =~ s/\*/.*/g;
741         $re =~ s/\%/([-0-9a-z_]+)/
742             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
743         if ($isuite =~ m/^$re$/) {
744             return ('backports',"$basedistro-backports",$1);
745         }
746     }
747     return ('none',undef);
748 }
749
750 our $access_forpush;
751
752 sub parse_cfg_bool ($$$) {
753     my ($what,$def,$v) = @_;
754     $v //= $def;
755     return
756         $v =~ m/^[ty1]/ ? 1 :
757         $v =~ m/^[fn0]/ ? 0 :
758         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
759 }       
760
761 sub access_forpush_config () {
762     my $d = access_basedistro();
763
764     return 1 if
765         $new_package &&
766         parse_cfg_bool('new-private-pushers', 0,
767                        cfg("dgit-distro.$d.new-private-pushers",
768                            'RETURN-UNDEF'));
769
770     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
771     $v //= 'a';
772     return
773         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
774         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
775         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
776         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
777 }
778
779 sub access_forpush () {
780     $access_forpush //= access_forpush_config();
781     return $access_forpush;
782 }
783
784 sub pushing () {
785     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
786     badcfg "pushing but distro is configured readonly"
787         if access_forpush_config() eq '0';
788     $access_forpush = 1;
789     $supplementary_message = <<'END' unless $we_are_responder;
790 Push failed, before we got started.
791 You can retry the push, after fixing the problem, if you like.
792 END
793     finalise_opts_opts();
794 }
795
796 sub notpushing () {
797     finalise_opts_opts();
798 }
799
800 sub supplementary_message ($) {
801     my ($msg) = @_;
802     if (!$we_are_responder) {
803         $supplementary_message = $msg;
804         return;
805     } elsif ($protovsn >= 3) {
806         responder_send_command "supplementary-message ".length($msg)
807             or die $!;
808         print PO $msg or die $!;
809     }
810 }
811
812 sub access_distros () {
813     # Returns list of distros to try, in order
814     #
815     # We want to try:
816     #    0. `instead of' distro name(s) we have been pointed to
817     #    1. the access_quirk distro, if any
818     #    2a. the user's specified distro, or failing that  } basedistro
819     #    2b. the distro calculated from the suite          }
820     my @l = access_basedistro();
821
822     my (undef,$quirkdistro) = access_quirk();
823     unshift @l, $quirkdistro;
824     unshift @l, $instead_distro;
825     @l = grep { defined } @l;
826
827     push @l, access_nomdistro();
828
829     if (access_forpush()) {
830         @l = map { ("$_/push", $_) } @l;
831     }
832     @l;
833 }
834
835 sub access_cfg_cfgs (@) {
836     my (@keys) = @_;
837     my @cfgs;
838     # The nesting of these loops determines the search order.  We put
839     # the key loop on the outside so that we search all the distros
840     # for each key, before going on to the next key.  That means that
841     # if access_cfg is called with a more specific, and then a less
842     # specific, key, an earlier distro can override the less specific
843     # without necessarily overriding any more specific keys.  (If the
844     # distro wants to override the more specific keys it can simply do
845     # so; whereas if we did the loop the other way around, it would be
846     # impossible to for an earlier distro to override a less specific
847     # key but not the more specific ones without restating the unknown
848     # values of the more specific keys.
849     my @realkeys;
850     my @rundef;
851     # We have to deal with RETURN-UNDEF specially, so that we don't
852     # terminate the search prematurely.
853     foreach (@keys) {
854         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
855         push @realkeys, $_
856     }
857     foreach my $d (access_distros()) {
858         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
859     }
860     push @cfgs, map { "dgit.default.$_" } @realkeys;
861     push @cfgs, @rundef;
862     return @cfgs;
863 }
864
865 sub access_cfg (@) {
866     my (@keys) = @_;
867     my (@cfgs) = access_cfg_cfgs(@keys);
868     my $value = cfg(@cfgs);
869     return $value;
870 }
871
872 sub access_cfg_bool ($$) {
873     my ($def, @keys) = @_;
874     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
875 }
876
877 sub string_to_ssh ($) {
878     my ($spec) = @_;
879     if ($spec =~ m/\s/) {
880         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
881     } else {
882         return ($spec);
883     }
884 }
885
886 sub access_cfg_ssh () {
887     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
888     if (!defined $gitssh) {
889         return @ssh;
890     } else {
891         return string_to_ssh $gitssh;
892     }
893 }
894
895 sub access_runeinfo ($) {
896     my ($info) = @_;
897     return ": dgit ".access_basedistro()." $info ;";
898 }
899
900 sub access_someuserhost ($) {
901     my ($some) = @_;
902     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
903     defined($user) && length($user) or
904         $user = access_cfg("$some-user",'username');
905     my $host = access_cfg("$some-host");
906     return length($user) ? "$user\@$host" : $host;
907 }
908
909 sub access_gituserhost () {
910     return access_someuserhost('git');
911 }
912
913 sub access_giturl (;$) {
914     my ($optional) = @_;
915     my $url = access_cfg('git-url','RETURN-UNDEF');
916     my $suffix;
917     if (!length $url) {
918         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
919         return undef unless defined $proto;
920         $url =
921             $proto.
922             access_gituserhost().
923             access_cfg('git-path');
924     } else {
925         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
926     }
927     $suffix //= '.git';
928     return "$url/$package$suffix";
929 }              
930
931 sub parsecontrolfh ($$;$) {
932     my ($fh, $desc, $allowsigned) = @_;
933     our $dpkgcontrolhash_noissigned;
934     my $c;
935     for (;;) {
936         my %opts = ('name' => $desc);
937         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
938         $c = Dpkg::Control::Hash->new(%opts);
939         $c->parse($fh,$desc) or die "parsing of $desc failed";
940         last if $allowsigned;
941         last if $dpkgcontrolhash_noissigned;
942         my $issigned= $c->get_option('is_pgp_signed');
943         if (!defined $issigned) {
944             $dpkgcontrolhash_noissigned= 1;
945             seek $fh, 0,0 or die "seek $desc: $!";
946         } elsif ($issigned) {
947             fail "control file $desc is (already) PGP-signed. ".
948                 " Note that dgit push needs to modify the .dsc and then".
949                 " do the signature itself";
950         } else {
951             last;
952         }
953     }
954     return $c;
955 }
956
957 sub parsecontrol {
958     my ($file, $desc, $allowsigned) = @_;
959     my $fh = new IO::Handle;
960     open $fh, '<', $file or die "$file: $!";
961     my $c = parsecontrolfh($fh,$desc,$allowsigned);
962     $fh->error and die $!;
963     close $fh;
964     return $c;
965 }
966
967 sub getfield ($$) {
968     my ($dctrl,$field) = @_;
969     my $v = $dctrl->{$field};
970     return $v if defined $v;
971     fail "missing field $field in ".$dctrl->get_option('name');
972 }
973
974 sub parsechangelog {
975     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
976     my $p = new IO::Handle;
977     my @cmd = (qw(dpkg-parsechangelog), @_);
978     open $p, '-|', @cmd or die $!;
979     $c->parse($p);
980     $?=0; $!=0; close $p or failedcmd @cmd;
981     return $c;
982 }
983
984 sub commit_getclogp ($) {
985     # Returns the parsed changelog hashref for a particular commit
986     my ($objid) = @_;
987     our %commit_getclogp_memo;
988     my $memo = $commit_getclogp_memo{$objid};
989     return $memo if $memo;
990     mkpath '.git/dgit';
991     my $mclog = ".git/dgit/clog-$objid";
992     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
993         "$objid:debian/changelog";
994     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
995 }
996
997 sub must_getcwd () {
998     my $d = getcwd();
999     defined $d or fail "getcwd failed: $!";
1000     return $d;
1001 }
1002
1003 sub parse_dscdata () {
1004     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1005     printdebug Dumper($dscdata) if $debuglevel>1;
1006     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1007     printdebug Dumper($dsc) if $debuglevel>1;
1008 }
1009
1010 our %rmad;
1011
1012 sub archive_query ($;@) {
1013     my ($method) = shift @_;
1014     fail "this operation does not support multiple comma-separated suites"
1015         if $isuite =~ m/,/;
1016     my $query = access_cfg('archive-query','RETURN-UNDEF');
1017     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1018     my $proto = $1;
1019     my $data = $'; #';
1020     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1021 }
1022
1023 sub archive_query_prepend_mirror {
1024     my $m = access_cfg('mirror');
1025     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1026 }
1027
1028 sub pool_dsc_subpath ($$) {
1029     my ($vsn,$component) = @_; # $package is implict arg
1030     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1031     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1032 }
1033
1034 sub cfg_apply_map ($$$) {
1035     my ($varref, $what, $mapspec) = @_;
1036     return unless $mapspec;
1037
1038     printdebug "config $what EVAL{ $mapspec; }\n";
1039     $_ = $$varref;
1040     eval "package Dgit::Config; $mapspec;";
1041     die $@ if $@;
1042     $$varref = $_;
1043 }
1044
1045 #---------- `ftpmasterapi' archive query method (nascent) ----------
1046
1047 sub archive_api_query_cmd ($) {
1048     my ($subpath) = @_;
1049     my @cmd = (@curl, qw(-sS));
1050     my $url = access_cfg('archive-query-url');
1051     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1052         my $host = $1;
1053         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1054         foreach my $key (split /\:/, $keys) {
1055             $key =~ s/\%HOST\%/$host/g;
1056             if (!stat $key) {
1057                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1058                 next;
1059             }
1060             fail "config requested specific TLS key but do not know".
1061                 " how to get curl to use exactly that EE key ($key)";
1062 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1063 #           # Sadly the above line does not work because of changes
1064 #           # to gnutls.   The real fix for #790093 may involve
1065 #           # new curl options.
1066             last;
1067         }
1068         # Fixing #790093 properly will involve providing a value
1069         # for this on clients.
1070         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1071         push @cmd, split / /, $kargs if defined $kargs;
1072     }
1073     push @cmd, $url.$subpath;
1074     return @cmd;
1075 }
1076
1077 sub api_query ($$;$) {
1078     use JSON;
1079     my ($data, $subpath, $ok404) = @_;
1080     badcfg "ftpmasterapi archive query method takes no data part"
1081         if length $data;
1082     my @cmd = archive_api_query_cmd($subpath);
1083     my $url = $cmd[$#cmd];
1084     push @cmd, qw(-w %{http_code});
1085     my $json = cmdoutput @cmd;
1086     unless ($json =~ s/\d+\d+\d$//) {
1087         failedcmd_report_cmd undef, @cmd;
1088         fail "curl failed to print 3-digit HTTP code";
1089     }
1090     my $code = $&;
1091     return undef if $code eq '404' && $ok404;
1092     fail "fetch of $url gave HTTP code $code"
1093         unless $url =~ m#^file://# or $code =~ m/^2/;
1094     return decode_json($json);
1095 }
1096
1097 sub canonicalise_suite_ftpmasterapi {
1098     my ($proto,$data) = @_;
1099     my $suites = api_query($data, 'suites');
1100     my @matched;
1101     foreach my $entry (@$suites) {
1102         next unless grep { 
1103             my $v = $entry->{$_};
1104             defined $v && $v eq $isuite;
1105         } qw(codename name);
1106         push @matched, $entry;
1107     }
1108     fail "unknown suite $isuite" unless @matched;
1109     my $cn;
1110     eval {
1111         @matched==1 or die "multiple matches for suite $isuite\n";
1112         $cn = "$matched[0]{codename}";
1113         defined $cn or die "suite $isuite info has no codename\n";
1114         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1115     };
1116     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1117         if length $@;
1118     return $cn;
1119 }
1120
1121 sub archive_query_ftpmasterapi {
1122     my ($proto,$data) = @_;
1123     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1124     my @rows;
1125     my $digester = Digest::SHA->new(256);
1126     foreach my $entry (@$info) {
1127         eval {
1128             my $vsn = "$entry->{version}";
1129             my ($ok,$msg) = version_check $vsn;
1130             die "bad version: $msg\n" unless $ok;
1131             my $component = "$entry->{component}";
1132             $component =~ m/^$component_re$/ or die "bad component";
1133             my $filename = "$entry->{filename}";
1134             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1135                 or die "bad filename";
1136             my $sha256sum = "$entry->{sha256sum}";
1137             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1138             push @rows, [ $vsn, "/pool/$component/$filename",
1139                           $digester, $sha256sum ];
1140         };
1141         die "bad ftpmaster api response: $@\n".Dumper($entry)
1142             if length $@;
1143     }
1144     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1145     return archive_query_prepend_mirror @rows;
1146 }
1147
1148 sub file_in_archive_ftpmasterapi {
1149     my ($proto,$data,$filename) = @_;
1150     my $pat = $filename;
1151     $pat =~ s/_/\\_/g;
1152     $pat = "%/$pat";
1153     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1154     my $info = api_query($data, "file_in_archive/$pat", 1);
1155 }
1156
1157 #---------- `aptget' archive query method ----------
1158
1159 our $aptget_base;
1160 our $aptget_releasefile;
1161 our $aptget_configpath;
1162
1163 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1164 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1165
1166 sub aptget_cache_clean {
1167     runcmd_ordryrun_local qw(sh -ec),
1168         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1169         'x', $aptget_base;
1170 }
1171
1172 sub aptget_lock_acquire () {
1173     my $lockfile = "$aptget_base/lock";
1174     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1175     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1176 }
1177
1178 sub aptget_prep ($) {
1179     my ($data) = @_;
1180     return if defined $aptget_base;
1181
1182     badcfg "aptget archive query method takes no data part"
1183         if length $data;
1184
1185     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1186
1187     ensuredir $cache;
1188     ensuredir "$cache/dgit";
1189     my $cachekey =
1190         access_cfg('aptget-cachekey','RETURN-UNDEF')
1191         // access_nomdistro();
1192
1193     $aptget_base = "$cache/dgit/aptget";
1194     ensuredir $aptget_base;
1195
1196     my $quoted_base = $aptget_base;
1197     die "$quoted_base contains bad chars, cannot continue"
1198         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1199
1200     ensuredir $aptget_base;
1201
1202     aptget_lock_acquire();
1203
1204     aptget_cache_clean();
1205
1206     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1207     my $sourceslist = "source.list#$cachekey";
1208
1209     my $aptsuites = $isuite;
1210     cfg_apply_map(\$aptsuites, 'suite map',
1211                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1212
1213     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1214     printf SRCS "deb-src %s %s %s\n",
1215         access_cfg('mirror'),
1216         $aptsuites,
1217         access_cfg('aptget-components')
1218         or die $!;
1219
1220     ensuredir "$aptget_base/cache";
1221     ensuredir "$aptget_base/lists";
1222
1223     open CONF, ">", $aptget_configpath or die $!;
1224     print CONF <<END;
1225 Debug::NoLocking "true";
1226 APT::Get::List-Cleanup "false";
1227 #clear APT::Update::Post-Invoke-Success;
1228 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1229 Dir::State::Lists "$quoted_base/lists";
1230 Dir::Etc::preferences "$quoted_base/preferences";
1231 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1232 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1233 END
1234
1235     foreach my $key (qw(
1236                         Dir::Cache
1237                         Dir::State
1238                         Dir::Cache::Archives
1239                         Dir::Etc::SourceParts
1240                         Dir::Etc::preferencesparts
1241                       )) {
1242         ensuredir "$aptget_base/$key";
1243         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1244     };
1245
1246     my $oldatime = (time // die $!) - 1;
1247     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1248         next unless stat_exists $oldlist;
1249         my ($mtime) = (stat _)[9];
1250         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1251     }
1252
1253     runcmd_ordryrun_local aptget_aptget(), qw(update);
1254
1255     my @releasefiles;
1256     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1257         next unless stat_exists $oldlist;
1258         my ($atime) = (stat _)[8];
1259         next if $atime == $oldatime;
1260         push @releasefiles, $oldlist;
1261     }
1262     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1263     @releasefiles = @inreleasefiles if @inreleasefiles;
1264     die "apt updated wrong number of Release files (@releasefiles), erk"
1265         unless @releasefiles == 1;
1266
1267     ($aptget_releasefile) = @releasefiles;
1268 }
1269
1270 sub canonicalise_suite_aptget {
1271     my ($proto,$data) = @_;
1272     aptget_prep($data);
1273
1274     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1275
1276     foreach my $name (qw(Codename Suite)) {
1277         my $val = $release->{$name};
1278         if (defined $val) {
1279             printdebug "release file $name: $val\n";
1280             $val =~ m/^$suite_re$/o or fail
1281  "Release file ($aptget_releasefile) specifies intolerable $name";
1282             cfg_apply_map(\$val, 'suite rmap',
1283                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1284             return $val
1285         }
1286     }
1287     return $isuite;
1288 }
1289
1290 sub archive_query_aptget {
1291     my ($proto,$data) = @_;
1292     aptget_prep($data);
1293
1294     ensuredir "$aptget_base/source";
1295     foreach my $old (<$aptget_base/source/*.dsc>) {
1296         unlink $old or die "$old: $!";
1297     }
1298
1299     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1300     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1301     # avoids apt-get source failing with ambiguous error code
1302
1303     runcmd_ordryrun_local
1304         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1305         aptget_aptget(), qw(--download-only --only-source source), $package;
1306
1307     my @dscs = <$aptget_base/source/*.dsc>;
1308     fail "apt-get source did not produce a .dsc" unless @dscs;
1309     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1310
1311     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1312
1313     use URI::Escape;
1314     my $uri = "file://". uri_escape $dscs[0];
1315     $uri =~ s{\%2f}{/}gi;
1316     return [ (getfield $pre_dsc, 'Version'), $uri ];
1317 }
1318
1319 #---------- `dummyapicat' archive query method ----------
1320
1321 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1322 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1323
1324 sub file_in_archive_dummycatapi ($$$) {
1325     my ($proto,$data,$filename) = @_;
1326     my $mirror = access_cfg('mirror');
1327     $mirror =~ s#^file://#/# or die "$mirror ?";
1328     my @out;
1329     my @cmd = (qw(sh -ec), '
1330             cd "$1"
1331             find -name "$2" -print0 |
1332             xargs -0r sha256sum
1333         ', qw(x), $mirror, $filename);
1334     debugcmd "-|", @cmd;
1335     open FIA, "-|", @cmd or die $!;
1336     while (<FIA>) {
1337         chomp or die;
1338         printdebug "| $_\n";
1339         m/^(\w+)  (\S+)$/ or die "$_ ?";
1340         push @out, { sha256sum => $1, filename => $2 };
1341     }
1342     close FIA or die failedcmd @cmd;
1343     return \@out;
1344 }
1345
1346 #---------- `madison' archive query method ----------
1347
1348 sub archive_query_madison {
1349     return archive_query_prepend_mirror
1350         map { [ @$_[0..1] ] } madison_get_parse(@_);
1351 }
1352
1353 sub madison_get_parse {
1354     my ($proto,$data) = @_;
1355     die unless $proto eq 'madison';
1356     if (!length $data) {
1357         $data= access_cfg('madison-distro','RETURN-UNDEF');
1358         $data //= access_basedistro();
1359     }
1360     $rmad{$proto,$data,$package} ||= cmdoutput
1361         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1362     my $rmad = $rmad{$proto,$data,$package};
1363
1364     my @out;
1365     foreach my $l (split /\n/, $rmad) {
1366         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1367                   \s*( [^ \t|]+ )\s* \|
1368                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1369                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1370         $1 eq $package or die "$rmad $package ?";
1371         my $vsn = $2;
1372         my $newsuite = $3;
1373         my $component;
1374         if (defined $4) {
1375             $component = $4;
1376         } else {
1377             $component = access_cfg('archive-query-default-component');
1378         }
1379         $5 eq 'source' or die "$rmad ?";
1380         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1381     }
1382     return sort { -version_compare($a->[0],$b->[0]); } @out;
1383 }
1384
1385 sub canonicalise_suite_madison {
1386     # madison canonicalises for us
1387     my @r = madison_get_parse(@_);
1388     @r or fail
1389         "unable to canonicalise suite using package $package".
1390         " which does not appear to exist in suite $isuite;".
1391         " --existing-package may help";
1392     return $r[0][2];
1393 }
1394
1395 sub file_in_archive_madison { return undef; }
1396
1397 #---------- `sshpsql' archive query method ----------
1398
1399 sub sshpsql ($$$) {
1400     my ($data,$runeinfo,$sql) = @_;
1401     if (!length $data) {
1402         $data= access_someuserhost('sshpsql').':'.
1403             access_cfg('sshpsql-dbname');
1404     }
1405     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1406     my ($userhost,$dbname) = ($`,$'); #';
1407     my @rows;
1408     my @cmd = (access_cfg_ssh, $userhost,
1409                access_runeinfo("ssh-psql $runeinfo").
1410                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1411                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1412     debugcmd "|",@cmd;
1413     open P, "-|", @cmd or die $!;
1414     while (<P>) {
1415         chomp or die;
1416         printdebug(">|$_|\n");
1417         push @rows, $_;
1418     }
1419     $!=0; $?=0; close P or failedcmd @cmd;
1420     @rows or die;
1421     my $nrows = pop @rows;
1422     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1423     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1424     @rows = map { [ split /\|/, $_ ] } @rows;
1425     my $ncols = scalar @{ shift @rows };
1426     die if grep { scalar @$_ != $ncols } @rows;
1427     return @rows;
1428 }
1429
1430 sub sql_injection_check {
1431     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1432 }
1433
1434 sub archive_query_sshpsql ($$) {
1435     my ($proto,$data) = @_;
1436     sql_injection_check $isuite, $package;
1437     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1438         SELECT source.version, component.name, files.filename, files.sha256sum
1439           FROM source
1440           JOIN src_associations ON source.id = src_associations.source
1441           JOIN suite ON suite.id = src_associations.suite
1442           JOIN dsc_files ON dsc_files.source = source.id
1443           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1444           JOIN component ON component.id = files_archive_map.component_id
1445           JOIN files ON files.id = dsc_files.file
1446          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1447            AND source.source='$package'
1448            AND files.filename LIKE '%.dsc';
1449 END
1450     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1451     my $digester = Digest::SHA->new(256);
1452     @rows = map {
1453         my ($vsn,$component,$filename,$sha256sum) = @$_;
1454         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1455     } @rows;
1456     return archive_query_prepend_mirror @rows;
1457 }
1458
1459 sub canonicalise_suite_sshpsql ($$) {
1460     my ($proto,$data) = @_;
1461     sql_injection_check $isuite;
1462     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1463         SELECT suite.codename
1464           FROM suite where suite_name='$isuite' or codename='$isuite';
1465 END
1466     @rows = map { $_->[0] } @rows;
1467     fail "unknown suite $isuite" unless @rows;
1468     die "ambiguous $isuite: @rows ?" if @rows>1;
1469     return $rows[0];
1470 }
1471
1472 sub file_in_archive_sshpsql ($$$) { return undef; }
1473
1474 #---------- `dummycat' archive query method ----------
1475
1476 sub canonicalise_suite_dummycat ($$) {
1477     my ($proto,$data) = @_;
1478     my $dpath = "$data/suite.$isuite";
1479     if (!open C, "<", $dpath) {
1480         $!==ENOENT or die "$dpath: $!";
1481         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1482         return $isuite;
1483     }
1484     $!=0; $_ = <C>;
1485     chomp or die "$dpath: $!";
1486     close C;
1487     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1488     return $_;
1489 }
1490
1491 sub archive_query_dummycat ($$) {
1492     my ($proto,$data) = @_;
1493     canonicalise_suite();
1494     my $dpath = "$data/package.$csuite.$package";
1495     if (!open C, "<", $dpath) {
1496         $!==ENOENT or die "$dpath: $!";
1497         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1498         return ();
1499     }
1500     my @rows;
1501     while (<C>) {
1502         next if m/^\#/;
1503         next unless m/\S/;
1504         die unless chomp;
1505         printdebug "dummycat query $csuite $package $dpath | $_\n";
1506         my @row = split /\s+/, $_;
1507         @row==2 or die "$dpath: $_ ?";
1508         push @rows, \@row;
1509     }
1510     C->error and die "$dpath: $!";
1511     close C;
1512     return archive_query_prepend_mirror
1513         sort { -version_compare($a->[0],$b->[0]); } @rows;
1514 }
1515
1516 sub file_in_archive_dummycat () { return undef; }
1517
1518 #---------- tag format handling ----------
1519
1520 sub access_cfg_tagformats () {
1521     split /\,/, access_cfg('dgit-tag-format');
1522 }
1523
1524 sub access_cfg_tagformats_can_splitbrain () {
1525     my %y = map { $_ => 1 } access_cfg_tagformats;
1526     foreach my $needtf (qw(new maint)) {
1527         next if $y{$needtf};
1528         return 0;
1529     }
1530     return 1;
1531 }
1532
1533 sub need_tagformat ($$) {
1534     my ($fmt, $why) = @_;
1535     fail "need to use tag format $fmt ($why) but also need".
1536         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1537         " - no way to proceed"
1538         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1539     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1540 }
1541
1542 sub select_tagformat () {
1543     # sets $tagformatfn
1544     return if $tagformatfn && !$tagformat_want;
1545     die 'bug' if $tagformatfn && $tagformat_want;
1546     # ... $tagformat_want assigned after previous select_tagformat
1547
1548     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1549     printdebug "select_tagformat supported @supported\n";
1550
1551     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1552     printdebug "select_tagformat specified @$tagformat_want\n";
1553
1554     my ($fmt,$why,$override) = @$tagformat_want;
1555
1556     fail "target distro supports tag formats @supported".
1557         " but have to use $fmt ($why)"
1558         unless $override
1559             or grep { $_ eq $fmt } @supported;
1560
1561     $tagformat_want = undef;
1562     $tagformat = $fmt;
1563     $tagformatfn = ${*::}{"debiantag_$fmt"};
1564
1565     fail "trying to use unknown tag format \`$fmt' ($why) !"
1566         unless $tagformatfn;
1567 }
1568
1569 #---------- archive query entrypoints and rest of program ----------
1570
1571 sub canonicalise_suite () {
1572     return if defined $csuite;
1573     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1574     $csuite = archive_query('canonicalise_suite');
1575     if ($isuite ne $csuite) {
1576         progress "canonical suite name for $isuite is $csuite";
1577     } else {
1578         progress "canonical suite name is $csuite";
1579     }
1580 }
1581
1582 sub get_archive_dsc () {
1583     canonicalise_suite();
1584     my @vsns = archive_query('archive_query');
1585     foreach my $vinfo (@vsns) {
1586         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1587         $dscurl = $vsn_dscurl;
1588         $dscdata = url_get($dscurl);
1589         if (!$dscdata) {
1590             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1591             next;
1592         }
1593         if ($digester) {
1594             $digester->reset();
1595             $digester->add($dscdata);
1596             my $got = $digester->hexdigest();
1597             $got eq $digest or
1598                 fail "$dscurl has hash $got but".
1599                     " archive told us to expect $digest";
1600         }
1601         parse_dscdata();
1602         my $fmt = getfield $dsc, 'Format';
1603         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1604             "unsupported source format $fmt, sorry";
1605             
1606         $dsc_checked = !!$digester;
1607         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1608         return;
1609     }
1610     $dsc = undef;
1611     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1612 }
1613
1614 sub check_for_git ();
1615 sub check_for_git () {
1616     # returns 0 or 1
1617     my $how = access_cfg('git-check');
1618     if ($how eq 'ssh-cmd') {
1619         my @cmd =
1620             (access_cfg_ssh, access_gituserhost(),
1621              access_runeinfo("git-check $package").
1622              " set -e; cd ".access_cfg('git-path').";".
1623              " if test -d $package.git; then echo 1; else echo 0; fi");
1624         my $r= cmdoutput @cmd;
1625         if (defined $r and $r =~ m/^divert (\w+)$/) {
1626             my $divert=$1;
1627             my ($usedistro,) = access_distros();
1628             # NB that if we are pushing, $usedistro will be $distro/push
1629             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1630             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1631             progress "diverting to $divert (using config for $instead_distro)";
1632             return check_for_git();
1633         }
1634         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1635         return $r+0;
1636     } elsif ($how eq 'url') {
1637         my $prefix = access_cfg('git-check-url','git-url');
1638         my $suffix = access_cfg('git-check-suffix','git-suffix',
1639                                 'RETURN-UNDEF') // '.git';
1640         my $url = "$prefix/$package$suffix";
1641         my @cmd = (@curl, qw(-sS -I), $url);
1642         my $result = cmdoutput @cmd;
1643         $result =~ s/^\S+ 200 .*\n\r?\n//;
1644         # curl -sS -I with https_proxy prints
1645         # HTTP/1.0 200 Connection established
1646         $result =~ m/^\S+ (404|200) /s or
1647             fail "unexpected results from git check query - ".
1648                 Dumper($prefix, $result);
1649         my $code = $1;
1650         if ($code eq '404') {
1651             return 0;
1652         } elsif ($code eq '200') {
1653             return 1;
1654         } else {
1655             die;
1656         }
1657     } elsif ($how eq 'true') {
1658         return 1;
1659     } elsif ($how eq 'false') {
1660         return 0;
1661     } else {
1662         badcfg "unknown git-check \`$how'";
1663     }
1664 }
1665
1666 sub create_remote_git_repo () {
1667     my $how = access_cfg('git-create');
1668     if ($how eq 'ssh-cmd') {
1669         runcmd_ordryrun
1670             (access_cfg_ssh, access_gituserhost(),
1671              access_runeinfo("git-create $package").
1672              "set -e; cd ".access_cfg('git-path').";".
1673              " cp -a _template $package.git");
1674     } elsif ($how eq 'true') {
1675         # nothing to do
1676     } else {
1677         badcfg "unknown git-create \`$how'";
1678     }
1679 }
1680
1681 our ($dsc_hash,$lastpush_mergeinput);
1682
1683 our $ud = '.git/dgit/unpack';
1684
1685 sub prep_ud (;$) {
1686     my ($d) = @_;
1687     $d //= $ud;
1688     rmtree($d);
1689     mkpath '.git/dgit';
1690     mkdir $d or die $!;
1691 }
1692
1693 sub mktree_in_ud_here () {
1694     runcmd qw(git init -q);
1695     runcmd qw(git config gc.auto 0);
1696     rmtree('.git/objects');
1697     symlink '../../../../objects','.git/objects' or die $!;
1698 }
1699
1700 sub git_write_tree () {
1701     my $tree = cmdoutput @git, qw(write-tree);
1702     $tree =~ m/^\w+$/ or die "$tree ?";
1703     return $tree;
1704 }
1705
1706 sub git_add_write_tree () {
1707     runcmd @git, qw(add -Af .);
1708     return git_write_tree();
1709 }
1710
1711 sub remove_stray_gits ($) {
1712     my ($what) = @_;
1713     my @gitscmd = qw(find -name .git -prune -print0);
1714     debugcmd "|",@gitscmd;
1715     open GITS, "-|", @gitscmd or die $!;
1716     {
1717         local $/="\0";
1718         while (<GITS>) {
1719             chomp or die;
1720             print STDERR "$us: warning: removing from $what: ",
1721                 (messagequote $_), "\n";
1722             rmtree $_;
1723         }
1724     }
1725     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1726 }
1727
1728 sub mktree_in_ud_from_only_subdir ($;$) {
1729     my ($what,$raw) = @_;
1730
1731     # changes into the subdir
1732     my (@dirs) = <*/.>;
1733     die "expected one subdir but found @dirs ?" unless @dirs==1;
1734     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1735     my $dir = $1;
1736     changedir $dir;
1737
1738     remove_stray_gits($what);
1739     mktree_in_ud_here();
1740     if (!$raw) {
1741         my ($format, $fopts) = get_source_format();
1742         if (madformat($format)) {
1743             rmtree '.pc';
1744         }
1745     }
1746
1747     my $tree=git_add_write_tree();
1748     return ($tree,$dir);
1749 }
1750
1751 our @files_csum_info_fields = 
1752     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1753      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1754      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1755
1756 sub dsc_files_info () {
1757     foreach my $csumi (@files_csum_info_fields) {
1758         my ($fname, $module, $method) = @$csumi;
1759         my $field = $dsc->{$fname};
1760         next unless defined $field;
1761         eval "use $module; 1;" or die $@;
1762         my @out;
1763         foreach (split /\n/, $field) {
1764             next unless m/\S/;
1765             m/^(\w+) (\d+) (\S+)$/ or
1766                 fail "could not parse .dsc $fname line \`$_'";
1767             my $digester = eval "$module"."->$method;" or die $@;
1768             push @out, {
1769                 Hash => $1,
1770                 Bytes => $2,
1771                 Filename => $3,
1772                 Digester => $digester,
1773             };
1774         }
1775         return @out;
1776     }
1777     fail "missing any supported Checksums-* or Files field in ".
1778         $dsc->get_option('name');
1779 }
1780
1781 sub dsc_files () {
1782     map { $_->{Filename} } dsc_files_info();
1783 }
1784
1785 sub files_compare_inputs (@) {
1786     my $inputs = \@_;
1787     my %record;
1788     my %fchecked;
1789
1790     my $showinputs = sub {
1791         return join "; ", map { $_->get_option('name') } @$inputs;
1792     };
1793
1794     foreach my $in (@$inputs) {
1795         my $expected_files;
1796         my $in_name = $in->get_option('name');
1797
1798         printdebug "files_compare_inputs $in_name\n";
1799
1800         foreach my $csumi (@files_csum_info_fields) {
1801             my ($fname) = @$csumi;
1802             printdebug "files_compare_inputs $in_name $fname\n";
1803
1804             my $field = $in->{$fname};
1805             next unless defined $field;
1806
1807             my @files;
1808             foreach (split /\n/, $field) {
1809                 next unless m/\S/;
1810
1811                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1812                     fail "could not parse $in_name $fname line \`$_'";
1813
1814                 printdebug "files_compare_inputs $in_name $fname $f\n";
1815
1816                 push @files, $f;
1817
1818                 my $re = \ $record{$f}{$fname};
1819                 if (defined $$re) {
1820                     $fchecked{$f}{$in_name} = 1;
1821                     $$re eq $info or
1822                         fail "hash or size of $f varies in $fname fields".
1823                         " (between: ".$showinputs->().")";
1824                 } else {
1825                     $$re = $info;
1826                 }
1827             }
1828             @files = sort @files;
1829             $expected_files //= \@files;
1830             "@$expected_files" eq "@files" or
1831                 fail "file list in $in_name varies between hash fields!";
1832         }
1833         $expected_files or
1834             fail "$in_name has no files list field(s)";
1835     }
1836     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1837         if $debuglevel>=2;
1838
1839     grep { keys %$_ == @$inputs-1 } values %fchecked
1840         or fail "no file appears in all file lists".
1841         " (looked in: ".$showinputs->().")";
1842 }
1843
1844 sub is_orig_file_in_dsc ($$) {
1845     my ($f, $dsc_files_info) = @_;
1846     return 0 if @$dsc_files_info <= 1;
1847     # One file means no origs, and the filename doesn't have a "what
1848     # part of dsc" component.  (Consider versions ending `.orig'.)
1849     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1850     return 1;
1851 }
1852
1853 sub is_orig_file_of_vsn ($$) {
1854     my ($f, $upstreamvsn) = @_;
1855     my $base = srcfn $upstreamvsn, '';
1856     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1857     return 1;
1858 }
1859
1860 sub changes_update_origs_from_dsc ($$$$) {
1861     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1862     my %changes_f;
1863     printdebug "checking origs needed ($upstreamvsn)...\n";
1864     $_ = getfield $changes, 'Files';
1865     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1866         fail "cannot find section/priority from .changes Files field";
1867     my $placementinfo = $1;
1868     my %changed;
1869     printdebug "checking origs needed placement '$placementinfo'...\n";
1870     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1871         $l =~ m/\S+$/ or next;
1872         my $file = $&;
1873         printdebug "origs $file | $l\n";
1874         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1875         printdebug "origs $file is_orig\n";
1876         my $have = archive_query('file_in_archive', $file);
1877         if (!defined $have) {
1878             print STDERR <<END;
1879 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1880 END
1881             return;
1882         }
1883         my $found_same = 0;
1884         my @found_differ;
1885         printdebug "origs $file \$#\$have=$#$have\n";
1886         foreach my $h (@$have) {
1887             my $same = 0;
1888             my @differ;
1889             foreach my $csumi (@files_csum_info_fields) {
1890                 my ($fname, $module, $method, $archivefield) = @$csumi;
1891                 next unless defined $h->{$archivefield};
1892                 $_ = $dsc->{$fname};
1893                 next unless defined;
1894                 m/^(\w+) .* \Q$file\E$/m or
1895                     fail ".dsc $fname missing entry for $file";
1896                 if ($h->{$archivefield} eq $1) {
1897                     $same++;
1898                 } else {
1899                     push @differ,
1900  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1901                 }
1902             }
1903             die "$file ".Dumper($h)." ?!" if $same && @differ;
1904             $found_same++
1905                 if $same;
1906             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1907                 if @differ;
1908         }
1909         printdebug "origs $file f.same=$found_same".
1910             " #f._differ=$#found_differ\n";
1911         if (@found_differ && !$found_same) {
1912             fail join "\n",
1913                 "archive contains $file with different checksum",
1914                 @found_differ;
1915         }
1916         # Now we edit the changes file to add or remove it
1917         foreach my $csumi (@files_csum_info_fields) {
1918             my ($fname, $module, $method, $archivefield) = @$csumi;
1919             next unless defined $changes->{$fname};
1920             if ($found_same) {
1921                 # in archive, delete from .changes if it's there
1922                 $changed{$file} = "removed" if
1923                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1924             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1925                 # not in archive, but it's here in the .changes
1926             } else {
1927                 my $dsc_data = getfield $dsc, $fname;
1928                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1929                 my $extra = $1;
1930                 $extra =~ s/ \d+ /$&$placementinfo /
1931                     or die "$fname $extra >$dsc_data< ?"
1932                     if $fname eq 'Files';
1933                 $changes->{$fname} .= "\n". $extra;
1934                 $changed{$file} = "added";
1935             }
1936         }
1937     }
1938     if (%changed) {
1939         foreach my $file (keys %changed) {
1940             progress sprintf
1941                 "edited .changes for archive .orig contents: %s %s",
1942                 $changed{$file}, $file;
1943         }
1944         my $chtmp = "$changesfile.tmp";
1945         $changes->save($chtmp);
1946         if (act_local()) {
1947             rename $chtmp,$changesfile or die "$changesfile $!";
1948         } else {
1949             progress "[new .changes left in $changesfile]";
1950         }
1951     } else {
1952         progress "$changesfile already has appropriate .orig(s) (if any)";
1953     }
1954 }
1955
1956 sub make_commit ($) {
1957     my ($file) = @_;
1958     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1959 }
1960
1961 sub make_commit_text ($) {
1962     my ($text) = @_;
1963     my ($out, $in);
1964     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1965     debugcmd "|",@cmd;
1966     print Dumper($text) if $debuglevel > 1;
1967     my $child = open2($out, $in, @cmd) or die $!;
1968     my $h;
1969     eval {
1970         print $in $text or die $!;
1971         close $in or die $!;
1972         $h = <$out>;
1973         $h =~ m/^\w+$/ or die;
1974         $h = $&;
1975         printdebug "=> $h\n";
1976     };
1977     close $out;
1978     waitpid $child, 0 == $child or die "$child $!";
1979     $? and failedcmd @cmd;
1980     return $h;
1981 }
1982
1983 sub clogp_authline ($) {
1984     my ($clogp) = @_;
1985     my $author = getfield $clogp, 'Maintainer';
1986     $author =~ s#,.*##ms;
1987     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1988     my $authline = "$author $date";
1989     $authline =~ m/$git_authline_re/o or
1990         fail "unexpected commit author line format \`$authline'".
1991         " (was generated from changelog Maintainer field)";
1992     return ($1,$2,$3) if wantarray;
1993     return $authline;
1994 }
1995
1996 sub vendor_patches_distro ($$) {
1997     my ($checkdistro, $what) = @_;
1998     return unless defined $checkdistro;
1999
2000     my $series = "debian/patches/\L$checkdistro\E.series";
2001     printdebug "checking for vendor-specific $series ($what)\n";
2002
2003     if (!open SERIES, "<", $series) {
2004         die "$series $!" unless $!==ENOENT;
2005         return;
2006     }
2007     while (<SERIES>) {
2008         next unless m/\S/;
2009         next if m/^\s+\#/;
2010
2011         print STDERR <<END;
2012
2013 Unfortunately, this source package uses a feature of dpkg-source where
2014 the same source package unpacks to different source code on different
2015 distros.  dgit cannot safely operate on such packages on affected
2016 distros, because the meaning of source packages is not stable.
2017
2018 Please ask the distro/maintainer to remove the distro-specific series
2019 files and use a different technique (if necessary, uploading actually
2020 different packages, if different distros are supposed to have
2021 different code).
2022
2023 END
2024         fail "Found active distro-specific series file for".
2025             " $checkdistro ($what): $series, cannot continue";
2026     }
2027     die "$series $!" if SERIES->error;
2028     close SERIES;
2029 }
2030
2031 sub check_for_vendor_patches () {
2032     # This dpkg-source feature doesn't seem to be documented anywhere!
2033     # But it can be found in the changelog (reformatted):
2034
2035     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2036     #   Author: Raphael Hertzog <hertzog@debian.org>
2037     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2038
2039     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2040     #   series files
2041     #   
2042     #   If you have debian/patches/ubuntu.series and you were
2043     #   unpacking the source package on ubuntu, quilt was still
2044     #   directed to debian/patches/series instead of
2045     #   debian/patches/ubuntu.series.
2046     #   
2047     #   debian/changelog                        |    3 +++
2048     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2049     #   2 files changed, 6 insertions(+), 1 deletion(-)
2050
2051     use Dpkg::Vendor;
2052     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2053     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2054                          "Dpkg::Vendor \`current vendor'");
2055     vendor_patches_distro(access_basedistro(),
2056                           "(base) distro being accessed");
2057     vendor_patches_distro(access_nomdistro(),
2058                           "(nominal) distro being accessed");
2059 }
2060
2061 sub generate_commits_from_dsc () {
2062     # See big comment in fetch_from_archive, below.
2063     # See also README.dsc-import.
2064     prep_ud();
2065     changedir $ud;
2066
2067     my @dfi = dsc_files_info();
2068     foreach my $fi (@dfi) {
2069         my $f = $fi->{Filename};
2070         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2071
2072         printdebug "considering linking $f: ";
2073
2074         link_ltarget "../../../../$f", $f
2075             or ((printdebug "($!) "), 0)
2076             or $!==&ENOENT
2077             or die "$f $!";
2078
2079         printdebug "linked.\n";
2080
2081         complete_file_from_dsc('.', $fi)
2082             or next;
2083
2084         if (is_orig_file_in_dsc($f, \@dfi)) {
2085             link $f, "../../../../$f"
2086                 or $!==&EEXIST
2087                 or die "$f $!";
2088         }
2089     }
2090
2091     # We unpack and record the orig tarballs first, so that we only
2092     # need disk space for one private copy of the unpacked source.
2093     # But we can't make them into commits until we have the metadata
2094     # from the debian/changelog, so we record the tree objects now and
2095     # make them into commits later.
2096     my @tartrees;
2097     my $upstreamv = upstreamversion $dsc->{version};
2098     my $orig_f_base = srcfn $upstreamv, '';
2099
2100     foreach my $fi (@dfi) {
2101         # We actually import, and record as a commit, every tarball
2102         # (unless there is only one file, in which case there seems
2103         # little point.
2104
2105         my $f = $fi->{Filename};
2106         printdebug "import considering $f ";
2107         (printdebug "only one dfi\n"), next if @dfi == 1;
2108         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2109         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2110         my $compr_ext = $1;
2111
2112         my ($orig_f_part) =
2113             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2114
2115         printdebug "Y ", (join ' ', map { $_//"(none)" }
2116                           $compr_ext, $orig_f_part
2117                          ), "\n";
2118
2119         my $input = new IO::File $f, '<' or die "$f $!";
2120         my $compr_pid;
2121         my @compr_cmd;
2122
2123         if (defined $compr_ext) {
2124             my $cname =
2125                 Dpkg::Compression::compression_guess_from_filename $f;
2126             fail "Dpkg::Compression cannot handle file $f in source package"
2127                 if defined $compr_ext && !defined $cname;
2128             my $compr_proc =
2129                 new Dpkg::Compression::Process compression => $cname;
2130             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2131             my $compr_fh = new IO::Handle;
2132             my $compr_pid = open $compr_fh, "-|" // die $!;
2133             if (!$compr_pid) {
2134                 open STDIN, "<&", $input or die $!;
2135                 exec @compr_cmd;
2136                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2137             }
2138             $input = $compr_fh;
2139         }
2140
2141         rmtree "_unpack-tar";
2142         mkdir "_unpack-tar" or die $!;
2143         my @tarcmd = qw(tar -x -f -
2144                         --no-same-owner --no-same-permissions
2145                         --no-acls --no-xattrs --no-selinux);
2146         my $tar_pid = fork // die $!;
2147         if (!$tar_pid) {
2148             chdir "_unpack-tar" or die $!;
2149             open STDIN, "<&", $input or die $!;
2150             exec @tarcmd;
2151             die "dgit (child): exec $tarcmd[0]: $!";
2152         }
2153         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2154         !$? or failedcmd @tarcmd;
2155
2156         close $input or
2157             (@compr_cmd ? failedcmd @compr_cmd
2158              : die $!);
2159         # finally, we have the results in "tarball", but maybe
2160         # with the wrong permissions
2161
2162         runcmd qw(chmod -R +rwX _unpack-tar);
2163         changedir "_unpack-tar";
2164         remove_stray_gits($f);
2165         mktree_in_ud_here();
2166         
2167         my ($tree) = git_add_write_tree();
2168         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2169         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2170             $tree = $1;
2171             printdebug "one subtree $1\n";
2172         } else {
2173             printdebug "multiple subtrees\n";
2174         }
2175         changedir "..";
2176         rmtree "_unpack-tar";
2177
2178         my $ent = [ $f, $tree ];
2179         push @tartrees, {
2180             Orig => !!$orig_f_part,
2181             Sort => (!$orig_f_part         ? 2 :
2182                      $orig_f_part =~ m/-/g ? 1 :
2183                                              0),
2184             F => $f,
2185             Tree => $tree,
2186         };
2187     }
2188
2189     @tartrees = sort {
2190         # put any without "_" first (spec is not clear whether files
2191         # are always in the usual order).  Tarballs without "_" are
2192         # the main orig or the debian tarball.
2193         $a->{Sort} <=> $b->{Sort} or
2194         $a->{F}    cmp $b->{F}
2195     } @tartrees;
2196
2197     my $any_orig = grep { $_->{Orig} } @tartrees;
2198
2199     my $dscfn = "$package.dsc";
2200
2201     my $treeimporthow = 'package';
2202
2203     open D, ">", $dscfn or die "$dscfn: $!";
2204     print D $dscdata or die "$dscfn: $!";
2205     close D or die "$dscfn: $!";
2206     my @cmd = qw(dpkg-source);
2207     push @cmd, '--no-check' if $dsc_checked;
2208     if (madformat $dsc->{format}) {
2209         push @cmd, '--skip-patches';
2210         $treeimporthow = 'unpatched';
2211     }
2212     push @cmd, qw(-x --), $dscfn;
2213     runcmd @cmd;
2214
2215     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2216     if (madformat $dsc->{format}) { 
2217         check_for_vendor_patches();
2218     }
2219
2220     my $dappliedtree;
2221     if (madformat $dsc->{format}) {
2222         my @pcmd = qw(dpkg-source --before-build .);
2223         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2224         rmtree '.pc';
2225         $dappliedtree = git_add_write_tree();
2226     }
2227
2228     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2229     debugcmd "|",@clogcmd;
2230     open CLOGS, "-|", @clogcmd or die $!;
2231
2232     my $clogp;
2233     my $r1clogp;
2234
2235     printdebug "import clog search...\n";
2236
2237     for (;;) {
2238         my $stanzatext = do { local $/=""; <CLOGS>; };
2239         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2240         last if !defined $stanzatext;
2241
2242         my $desc = "package changelog, entry no.$.";
2243         open my $stanzafh, "<", \$stanzatext or die;
2244         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2245         $clogp //= $thisstanza;
2246
2247         printdebug "import clog $thisstanza->{version} $desc...\n";
2248
2249         last if !$any_orig; # we don't need $r1clogp
2250
2251         # We look for the first (most recent) changelog entry whose
2252         # version number is lower than the upstream version of this
2253         # package.  Then the last (least recent) previous changelog
2254         # entry is treated as the one which introduced this upstream
2255         # version and used for the synthetic commits for the upstream
2256         # tarballs.
2257
2258         # One might think that a more sophisticated algorithm would be
2259         # necessary.  But: we do not want to scan the whole changelog
2260         # file.  Stopping when we see an earlier version, which
2261         # necessarily then is an earlier upstream version, is the only
2262         # realistic way to do that.  Then, either the earliest
2263         # changelog entry we have seen so far is indeed the earliest
2264         # upload of this upstream version; or there are only changelog
2265         # entries relating to later upstream versions (which is not
2266         # possible unless the changelog and .dsc disagree about the
2267         # version).  Then it remains to choose between the physically
2268         # last entry in the file, and the one with the lowest version
2269         # number.  If these are not the same, we guess that the
2270         # versions were created in a non-monotic order rather than
2271         # that the changelog entries have been misordered.
2272
2273         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2274
2275         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2276         $r1clogp = $thisstanza;
2277
2278         printdebug "import clog $r1clogp->{version} becomes r1\n";
2279     }
2280     die $! if CLOGS->error;
2281     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2282
2283     $clogp or fail "package changelog has no entries!";
2284
2285     my $authline = clogp_authline $clogp;
2286     my $changes = getfield $clogp, 'Changes';
2287     my $cversion = getfield $clogp, 'Version';
2288
2289     if (@tartrees) {
2290         $r1clogp //= $clogp; # maybe there's only one entry;
2291         my $r1authline = clogp_authline $r1clogp;
2292         # Strictly, r1authline might now be wrong if it's going to be
2293         # unused because !$any_orig.  Whatever.
2294
2295         printdebug "import tartrees authline   $authline\n";
2296         printdebug "import tartrees r1authline $r1authline\n";
2297
2298         foreach my $tt (@tartrees) {
2299             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2300
2301             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2302 tree $tt->{Tree}
2303 author $r1authline
2304 committer $r1authline
2305
2306 Import $tt->{F}
2307
2308 [dgit import orig $tt->{F}]
2309 END_O
2310 tree $tt->{Tree}
2311 author $authline
2312 committer $authline
2313
2314 Import $tt->{F}
2315
2316 [dgit import tarball $package $cversion $tt->{F}]
2317 END_T
2318         }
2319     }
2320
2321     printdebug "import main commit\n";
2322
2323     open C, ">../commit.tmp" or die $!;
2324     print C <<END or die $!;
2325 tree $tree
2326 END
2327     print C <<END or die $! foreach @tartrees;
2328 parent $_->{Commit}
2329 END
2330     print C <<END or die $!;
2331 author $authline
2332 committer $authline
2333
2334 $changes
2335
2336 [dgit import $treeimporthow $package $cversion]
2337 END
2338
2339     close C or die $!;
2340     my $rawimport_hash = make_commit qw(../commit.tmp);
2341
2342     if (madformat $dsc->{format}) {
2343         printdebug "import apply patches...\n";
2344
2345         # regularise the state of the working tree so that
2346         # the checkout of $rawimport_hash works nicely.
2347         my $dappliedcommit = make_commit_text(<<END);
2348 tree $dappliedtree
2349 author $authline
2350 committer $authline
2351
2352 [dgit dummy commit]
2353 END
2354         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2355
2356         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2357
2358         # We need the answers to be reproducible
2359         my @authline = clogp_authline($clogp);
2360         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2361         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2362         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2363         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2364         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2365         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2366
2367         my $path = $ENV{PATH} or die;
2368
2369         foreach my $use_absurd (qw(0 1)) {
2370             runcmd @git, qw(checkout -q unpa);
2371             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2372             local $ENV{PATH} = $path;
2373             if ($use_absurd) {
2374                 chomp $@;
2375                 progress "warning: $@";
2376                 $path = "$absurdity:$path";
2377                 progress "$us: trying slow absurd-git-apply...";
2378                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2379                     or $!==ENOENT
2380                     or die $!;
2381             }
2382             eval {
2383                 die "forbid absurd git-apply\n" if $use_absurd
2384                     && forceing [qw(import-gitapply-no-absurd)];
2385                 die "only absurd git-apply!\n" if !$use_absurd
2386                     && forceing [qw(import-gitapply-absurd)];
2387
2388                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2389                 local $ENV{PATH} = $path                    if $use_absurd;
2390
2391                 my @showcmd = (gbp_pq, qw(import));
2392                 my @realcmd = shell_cmd
2393                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2394                 debugcmd "+",@realcmd;
2395                 if (system @realcmd) {
2396                     die +(shellquote @showcmd).
2397                         " failed: ".
2398                         failedcmd_waitstatus()."\n";
2399                 }
2400
2401                 my $gapplied = git_rev_parse('HEAD');
2402                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2403                 $gappliedtree eq $dappliedtree or
2404                     fail <<END;
2405 gbp-pq import and dpkg-source disagree!
2406  gbp-pq import gave commit $gapplied
2407  gbp-pq import gave tree $gappliedtree
2408  dpkg-source --before-build gave tree $dappliedtree
2409 END
2410                 $rawimport_hash = $gapplied;
2411             };
2412             last unless $@;
2413         }
2414         if ($@) {
2415             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2416             die $@;
2417         }
2418     }
2419
2420     progress "synthesised git commit from .dsc $cversion";
2421
2422     my $rawimport_mergeinput = {
2423         Commit => $rawimport_hash,
2424         Info => "Import of source package",
2425     };
2426     my @output = ($rawimport_mergeinput);
2427
2428     if ($lastpush_mergeinput) {
2429         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2430         my $oversion = getfield $oldclogp, 'Version';
2431         my $vcmp =
2432             version_compare($oversion, $cversion);
2433         if ($vcmp < 0) {
2434             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2435                 { Message => <<END, ReverseParents => 1 });
2436 Record $package ($cversion) in archive suite $csuite
2437 END
2438         } elsif ($vcmp > 0) {
2439             print STDERR <<END or die $!;
2440
2441 Version actually in archive:   $cversion (older)
2442 Last version pushed with dgit: $oversion (newer or same)
2443 $later_warning_msg
2444 END
2445             @output = $lastpush_mergeinput;
2446         } else {
2447             # Same version.  Use what's in the server git branch,
2448             # discarding our own import.  (This could happen if the
2449             # server automatically imports all packages into git.)
2450             @output = $lastpush_mergeinput;
2451         }
2452     }
2453     changedir '../../../..';
2454     rmtree($ud);
2455     return @output;
2456 }
2457
2458 sub complete_file_from_dsc ($$) {
2459     our ($dstdir, $fi) = @_;
2460     # Ensures that we have, in $dir, the file $fi, with the correct
2461     # contents.  (Downloading it from alongside $dscurl if necessary.)
2462
2463     my $f = $fi->{Filename};
2464     my $tf = "$dstdir/$f";
2465     my $downloaded = 0;
2466
2467     if (stat_exists $tf) {
2468         progress "using existing $f";
2469     } else {
2470         printdebug "$tf does not exist, need to fetch\n";
2471         my $furl = $dscurl;
2472         $furl =~ s{/[^/]+$}{};
2473         $furl .= "/$f";
2474         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2475         die "$f ?" if $f =~ m#/#;
2476         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2477         return 0 if !act_local();
2478         $downloaded = 1;
2479     }
2480
2481     open F, "<", "$tf" or die "$tf: $!";
2482     $fi->{Digester}->reset();
2483     $fi->{Digester}->addfile(*F);
2484     F->error and die $!;
2485     my $got = $fi->{Digester}->hexdigest();
2486     $got eq $fi->{Hash} or
2487         fail "file $f has hash $got but .dsc".
2488             " demands hash $fi->{Hash} ".
2489             ($downloaded ? "(got wrong file from archive!)"
2490              : "(perhaps you should delete this file?)");
2491
2492     return 1;
2493 }
2494
2495 sub ensure_we_have_orig () {
2496     my @dfi = dsc_files_info();
2497     foreach my $fi (@dfi) {
2498         my $f = $fi->{Filename};
2499         next unless is_orig_file_in_dsc($f, \@dfi);
2500         complete_file_from_dsc('..', $fi)
2501             or next;
2502     }
2503 }
2504
2505 sub git_fetch_us () {
2506     # Want to fetch only what we are going to use, unless
2507     # deliberately-not-ff, in which case we must fetch everything.
2508
2509     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2510         map { "tags/$_" }
2511         (quiltmode_splitbrain
2512          ? (map { $_->('*',access_nomdistro) }
2513             \&debiantag_new, \&debiantag_maintview)
2514          : debiantags('*',access_nomdistro));
2515     push @specs, server_branch($csuite);
2516     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2517
2518     # This is rather miserable:
2519     # When git fetch --prune is passed a fetchspec ending with a *,
2520     # it does a plausible thing.  If there is no * then:
2521     # - it matches subpaths too, even if the supplied refspec
2522     #   starts refs, and behaves completely madly if the source
2523     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2524     # - if there is no matching remote ref, it bombs out the whole
2525     #   fetch.
2526     # We want to fetch a fixed ref, and we don't know in advance
2527     # if it exists, so this is not suitable.
2528     #
2529     # Our workaround is to use git ls-remote.  git ls-remote has its
2530     # own qairks.  Notably, it has the absurd multi-tail-matching
2531     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2532     # refs/refs/foo etc.
2533     #
2534     # Also, we want an idempotent snapshot, but we have to make two
2535     # calls to the remote: one to git ls-remote and to git fetch.  The
2536     # solution is use git ls-remote to obtain a target state, and
2537     # git fetch to try to generate it.  If we don't manage to generate
2538     # the target state, we try again.
2539
2540     printdebug "git_fetch_us specs @specs\n";
2541
2542     my $specre = join '|', map {
2543         my $x = $_;
2544         $x =~ s/\W/\\$&/g;
2545         $x =~ s/\\\*$/.*/;
2546         "(?:refs/$x)";
2547     } @specs;
2548     printdebug "git_fetch_us specre=$specre\n";
2549     my $wanted_rref = sub {
2550         local ($_) = @_;
2551         return m/^(?:$specre)$/o;
2552     };
2553
2554     my $fetch_iteration = 0;
2555     FETCH_ITERATION:
2556     for (;;) {
2557         printdebug "git_fetch_us iteration $fetch_iteration\n";
2558         if (++$fetch_iteration > 10) {
2559             fail "too many iterations trying to get sane fetch!";
2560         }
2561
2562         my @look = map { "refs/$_" } @specs;
2563         my @lcmd = (@git, qw(ls-remote -q --refs), access_giturl(), @look);
2564         debugcmd "|",@lcmd;
2565
2566         my %wantr;
2567         open GITLS, "-|", @lcmd or die $!;
2568         while (<GITLS>) {
2569             printdebug "=> ", $_;
2570             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2571             my ($objid,$rrefname) = ($1,$2);
2572             if (!$wanted_rref->($rrefname)) {
2573                 print STDERR <<END;
2574 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2575 END
2576                 next;
2577             }
2578             $wantr{$rrefname} = $objid;
2579         }
2580         $!=0; $?=0;
2581         close GITLS or failedcmd @lcmd;
2582
2583         # OK, now %want is exactly what we want for refs in @specs
2584         my @fspecs = map {
2585             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2586             "+refs/$_:".lrfetchrefs."/$_";
2587         } @specs;
2588
2589         printdebug "git_fetch_us fspecs @fspecs\n";
2590
2591         my @fcmd = (@git, qw(fetch -p -n -q), access_giturl(), @fspecs);
2592         runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(),
2593             @fspecs;
2594
2595         %lrfetchrefs_f = ();
2596         my %objgot;
2597
2598         git_for_each_ref(lrfetchrefs, sub {
2599             my ($objid,$objtype,$lrefname,$reftail) = @_;
2600             $lrfetchrefs_f{$lrefname} = $objid;
2601             $objgot{$objid} = 1;
2602         });
2603
2604         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2605             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2606             if (!exists $wantr{$rrefname}) {
2607                 if ($wanted_rref->($rrefname)) {
2608                     printdebug <<END;
2609 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2610 END
2611                 } else {
2612                     print STDERR <<END
2613 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2614 END
2615                 }
2616                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2617                 delete $lrfetchrefs_f{$lrefname};
2618                 next;
2619             }
2620         }
2621         foreach my $rrefname (sort keys %wantr) {
2622             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2623             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2624             my $want = $wantr{$rrefname};
2625             next if $got eq $want;
2626             if (!defined $objgot{$want}) {
2627                 print STDERR <<END;
2628 warning: git ls-remote suggests we want $lrefname
2629 warning:  and it should refer to $want
2630 warning:  but git fetch didn't fetch that object to any relevant ref.
2631 warning:  This may be due to a race with someone updating the server.
2632 warning:  Will try again...
2633 END
2634                 next FETCH_ITERATION;
2635             }
2636             printdebug <<END;
2637 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2638 END
2639             runcmd_ordryrun_local @git, qw(update-ref -m),
2640                 "dgit fetch git fetch fixup", $lrefname, $want;
2641             $lrfetchrefs_f{$lrefname} = $want;
2642         }
2643         last;
2644     }
2645     printdebug "git_fetch_us: git fetch --no-insane emulation complete\n",
2646         Dumper(\%lrfetchrefs_f);
2647
2648     my %here;
2649     my @tagpats = debiantags('*',access_nomdistro);
2650
2651     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2652         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2653         printdebug "currently $fullrefname=$objid\n";
2654         $here{$fullrefname} = $objid;
2655     });
2656     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2657         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2658         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2659         printdebug "offered $lref=$objid\n";
2660         if (!defined $here{$lref}) {
2661             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2662             runcmd_ordryrun_local @upd;
2663             lrfetchref_used $fullrefname;
2664         } elsif ($here{$lref} eq $objid) {
2665             lrfetchref_used $fullrefname;
2666         } else {
2667             print STDERR \
2668                 "Not updateting $lref from $here{$lref} to $objid.\n";
2669         }
2670     });
2671 }
2672
2673 sub mergeinfo_getclogp ($) {
2674     # Ensures thit $mi->{Clogp} exists and returns it
2675     my ($mi) = @_;
2676     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2677 }
2678
2679 sub mergeinfo_version ($) {
2680     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2681 }
2682
2683 sub fetch_from_archive_record_1 ($) {
2684     my ($hash) = @_;
2685     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2686             'DGIT_ARCHIVE', $hash;
2687     cmdoutput @git, qw(log -n2), $hash;
2688     # ... gives git a chance to complain if our commit is malformed
2689 }
2690
2691 sub fetch_from_archive_record_2 ($) {
2692     my ($hash) = @_;
2693     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2694     if (act_local()) {
2695         cmdoutput @upd_cmd;
2696     } else {
2697         dryrun_report @upd_cmd;
2698     }
2699 }
2700
2701 sub fetch_from_archive () {
2702     ensure_setup_existing_tree();
2703
2704     # Ensures that lrref() is what is actually in the archive, one way
2705     # or another, according to us - ie this client's
2706     # appropritaely-updated archive view.  Also returns the commit id.
2707     # If there is nothing in the archive, leaves lrref alone and
2708     # returns undef.  git_fetch_us must have already been called.
2709     get_archive_dsc();
2710
2711     if ($dsc) {
2712         foreach my $field (@ourdscfield) {
2713             $dsc_hash = $dsc->{$field};
2714             last if defined $dsc_hash;
2715         }
2716         if (defined $dsc_hash) {
2717             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
2718             $dsc_hash = $&;
2719             progress "last upload to archive specified git hash";
2720         } else {
2721             progress "last upload to archive has NO git hash";
2722         }
2723     } else {
2724         progress "no version available from the archive";
2725     }
2726
2727     # If the archive's .dsc has a Dgit field, there are three
2728     # relevant git commitids we need to choose between and/or merge
2729     # together:
2730     #   1. $dsc_hash: the Dgit field from the archive
2731     #   2. $lastpush_hash: the suite branch on the dgit git server
2732     #   3. $lastfetch_hash: our local tracking brach for the suite
2733     #
2734     # These may all be distinct and need not be in any fast forward
2735     # relationship:
2736     #
2737     # If the dsc was pushed to this suite, then the server suite
2738     # branch will have been updated; but it might have been pushed to
2739     # a different suite and copied by the archive.  Conversely a more
2740     # recent version may have been pushed with dgit but not appeared
2741     # in the archive (yet).
2742     #
2743     # $lastfetch_hash may be awkward because archive imports
2744     # (particularly, imports of Dgit-less .dscs) are performed only as
2745     # needed on individual clients, so different clients may perform a
2746     # different subset of them - and these imports are only made
2747     # public during push.  So $lastfetch_hash may represent a set of
2748     # imports different to a subsequent upload by a different dgit
2749     # client.
2750     #
2751     # Our approach is as follows:
2752     #
2753     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2754     # descendant of $dsc_hash, then it was pushed by a dgit user who
2755     # had based their work on $dsc_hash, so we should prefer it.
2756     # Otherwise, $dsc_hash was installed into this suite in the
2757     # archive other than by a dgit push, and (necessarily) after the
2758     # last dgit push into that suite (since a dgit push would have
2759     # been descended from the dgit server git branch); thus, in that
2760     # case, we prefer the archive's version (and produce a
2761     # pseudo-merge to overwrite the dgit server git branch).
2762     #
2763     # (If there is no Dgit field in the archive's .dsc then
2764     # generate_commit_from_dsc uses the version numbers to decide
2765     # whether the suite branch or the archive is newer.  If the suite
2766     # branch is newer it ignores the archive's .dsc; otherwise it
2767     # generates an import of the .dsc, and produces a pseudo-merge to
2768     # overwrite the suite branch with the archive contents.)
2769     #
2770     # The outcome of that part of the algorithm is the `public view',
2771     # and is same for all dgit clients: it does not depend on any
2772     # unpublished history in the local tracking branch.
2773     #
2774     # As between the public view and the local tracking branch: The
2775     # local tracking branch is only updated by dgit fetch, and
2776     # whenever dgit fetch runs it includes the public view in the
2777     # local tracking branch.  Therefore if the public view is not
2778     # descended from the local tracking branch, the local tracking
2779     # branch must contain history which was imported from the archive
2780     # but never pushed; and, its tip is now out of date.  So, we make
2781     # a pseudo-merge to overwrite the old imports and stitch the old
2782     # history in.
2783     #
2784     # Finally: we do not necessarily reify the public view (as
2785     # described above).  This is so that we do not end up stacking two
2786     # pseudo-merges.  So what we actually do is figure out the inputs
2787     # to any public view pseudo-merge and put them in @mergeinputs.
2788
2789     my @mergeinputs;
2790     # $mergeinputs[]{Commit}
2791     # $mergeinputs[]{Info}
2792     # $mergeinputs[0] is the one whose tree we use
2793     # @mergeinputs is in the order we use in the actual commit)
2794     #
2795     # Also:
2796     # $mergeinputs[]{Message} is a commit message to use
2797     # $mergeinputs[]{ReverseParents} if def specifies that parent
2798     #                                list should be in opposite order
2799     # Such an entry has no Commit or Info.  It applies only when found
2800     # in the last entry.  (This ugliness is to support making
2801     # identical imports to previous dgit versions.)
2802
2803     my $lastpush_hash = git_get_ref(lrfetchref());
2804     printdebug "previous reference hash=$lastpush_hash\n";
2805     $lastpush_mergeinput = $lastpush_hash && {
2806         Commit => $lastpush_hash,
2807         Info => "dgit suite branch on dgit git server",
2808     };
2809
2810     my $lastfetch_hash = git_get_ref(lrref());
2811     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2812     my $lastfetch_mergeinput = $lastfetch_hash && {
2813         Commit => $lastfetch_hash,
2814         Info => "dgit client's archive history view",
2815     };
2816
2817     my $dsc_mergeinput = $dsc_hash && {
2818         Commit => $dsc_hash,
2819         Info => "Dgit field in .dsc from archive",
2820     };
2821
2822     my $cwd = getcwd();
2823     my $del_lrfetchrefs = sub {
2824         changedir $cwd;
2825         my $gur;
2826         printdebug "del_lrfetchrefs...\n";
2827         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2828             my $objid = $lrfetchrefs_d{$fullrefname};
2829             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2830             if (!$gur) {
2831                 $gur ||= new IO::Handle;
2832                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2833             }
2834             printf $gur "delete %s %s\n", $fullrefname, $objid;
2835         }
2836         if ($gur) {
2837             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2838         }
2839     };
2840
2841     if (defined $dsc_hash) {
2842         ensure_we_have_orig();
2843         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
2844             @mergeinputs = $dsc_mergeinput
2845         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
2846             print STDERR <<END or die $!;
2847
2848 Git commit in archive is behind the last version allegedly pushed/uploaded.
2849 Commit referred to by archive: $dsc_hash
2850 Last version pushed with dgit: $lastpush_hash
2851 $later_warning_msg
2852 END
2853             @mergeinputs = ($lastpush_mergeinput);
2854         } else {
2855             # Archive has .dsc which is not a descendant of the last dgit
2856             # push.  This can happen if the archive moves .dscs about.
2857             # Just follow its lead.
2858             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
2859                 progress "archive .dsc names newer git commit";
2860                 @mergeinputs = ($dsc_mergeinput);
2861             } else {
2862                 progress "archive .dsc names other git commit, fixing up";
2863                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
2864             }
2865         }
2866     } elsif ($dsc) {
2867         @mergeinputs = generate_commits_from_dsc();
2868         # We have just done an import.  Now, our import algorithm might
2869         # have been improved.  But even so we do not want to generate
2870         # a new different import of the same package.  So if the
2871         # version numbers are the same, just use our existing version.
2872         # If the version numbers are different, the archive has changed
2873         # (perhaps, rewound).
2874         if ($lastfetch_mergeinput &&
2875             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
2876                               (mergeinfo_version $mergeinputs[0]) )) {
2877             @mergeinputs = ($lastfetch_mergeinput);
2878         }
2879     } elsif ($lastpush_hash) {
2880         # only in git, not in the archive yet
2881         @mergeinputs = ($lastpush_mergeinput);
2882         print STDERR <<END or die $!;
2883
2884 Package not found in the archive, but has allegedly been pushed using dgit.
2885 $later_warning_msg
2886 END
2887     } else {
2888         printdebug "nothing found!\n";
2889         if (defined $skew_warning_vsn) {
2890             print STDERR <<END or die $!;
2891
2892 Warning: relevant archive skew detected.
2893 Archive allegedly contains $skew_warning_vsn
2894 But we were not able to obtain any version from the archive or git.
2895
2896 END
2897         }
2898         unshift @end, $del_lrfetchrefs;
2899         return undef;
2900     }
2901
2902     if ($lastfetch_hash &&
2903         !grep {
2904             my $h = $_->{Commit};
2905             $h and is_fast_fwd($lastfetch_hash, $h);
2906             # If true, one of the existing parents of this commit
2907             # is a descendant of the $lastfetch_hash, so we'll
2908             # be ff from that automatically.
2909         } @mergeinputs
2910         ) {
2911         # Otherwise:
2912         push @mergeinputs, $lastfetch_mergeinput;
2913     }
2914
2915     printdebug "fetch mergeinfos:\n";
2916     foreach my $mi (@mergeinputs) {
2917         if ($mi->{Info}) {
2918             printdebug " commit $mi->{Commit} $mi->{Info}\n";
2919         } else {
2920             printdebug sprintf " ReverseParents=%d Message=%s",
2921                 $mi->{ReverseParents}, $mi->{Message};
2922         }
2923     }
2924
2925     my $compat_info= pop @mergeinputs
2926         if $mergeinputs[$#mergeinputs]{Message};
2927
2928     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
2929
2930     my $hash;
2931     if (@mergeinputs > 1) {
2932         # here we go, then:
2933         my $tree_commit = $mergeinputs[0]{Commit};
2934
2935         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
2936         $tree =~ m/\n\n/;  $tree = $`;
2937         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
2938         $tree = $1;
2939
2940         # We use the changelog author of the package in question the
2941         # author of this pseudo-merge.  This is (roughly) correct if
2942         # this commit is simply representing aa non-dgit upload.
2943         # (Roughly because it does not record sponsorship - but we
2944         # don't have sponsorship info because that's in the .changes,
2945         # which isn't in the archivw.)
2946         #
2947         # But, it might be that we are representing archive history
2948         # updates (including in-archive copies).  These are not really
2949         # the responsibility of the person who created the .dsc, but
2950         # there is no-one whose name we should better use.  (The
2951         # author of the .dsc-named commit is clearly worse.)
2952
2953         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
2954         my $author = clogp_authline $useclogp;
2955         my $cversion = getfield $useclogp, 'Version';
2956
2957         my $mcf = ".git/dgit/mergecommit";
2958         open MC, ">", $mcf or die "$mcf $!";
2959         print MC <<END or die $!;
2960 tree $tree
2961 END
2962
2963         my @parents = grep { $_->{Commit} } @mergeinputs;
2964         @parents = reverse @parents if $compat_info->{ReverseParents};
2965         print MC <<END or die $! foreach @parents;
2966 parent $_->{Commit}
2967 END
2968
2969         print MC <<END or die $!;
2970 author $author
2971 committer $author
2972
2973 END
2974
2975         if (defined $compat_info->{Message}) {
2976             print MC $compat_info->{Message} or die $!;
2977         } else {
2978             print MC <<END or die $!;
2979 Record $package ($cversion) in archive suite $csuite
2980
2981 Record that
2982 END
2983             my $message_add_info = sub {
2984                 my ($mi) = (@_);
2985                 my $mversion = mergeinfo_version $mi;
2986                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
2987                     or die $!;
2988             };
2989
2990             $message_add_info->($mergeinputs[0]);
2991             print MC <<END or die $!;
2992 should be treated as descended from
2993 END
2994             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
2995         }
2996
2997         close MC or die $!;
2998         $hash = make_commit $mcf;
2999     } else {
3000         $hash = $mergeinputs[0]{Commit};
3001     }
3002     printdebug "fetch hash=$hash\n";
3003
3004     my $chkff = sub {
3005         my ($lasth, $what) = @_;
3006         return unless $lasth;
3007         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3008     };
3009
3010     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3011         if $lastpush_hash;
3012     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3013
3014     fetch_from_archive_record_1($hash);
3015
3016     if (defined $skew_warning_vsn) {
3017         mkpath '.git/dgit';
3018         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3019         my $gotclogp = commit_getclogp($hash);
3020         my $got_vsn = getfield $gotclogp, 'Version';
3021         printdebug "SKEW CHECK GOT $got_vsn\n";
3022         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3023             print STDERR <<END or die $!;
3024
3025 Warning: archive skew detected.  Using the available version:
3026 Archive allegedly contains    $skew_warning_vsn
3027 We were able to obtain only   $got_vsn
3028
3029 END
3030         }
3031     }
3032
3033     if ($lastfetch_hash ne $hash) {
3034         fetch_from_archive_record_2($hash);
3035     }
3036
3037     lrfetchref_used lrfetchref();
3038
3039     unshift @end, $del_lrfetchrefs;
3040     return $hash;
3041 }
3042
3043 sub set_local_git_config ($$) {
3044     my ($k, $v) = @_;
3045     runcmd @git, qw(config), $k, $v;
3046 }
3047
3048 sub setup_mergechangelogs (;$) {
3049     my ($always) = @_;
3050     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3051
3052     my $driver = 'dpkg-mergechangelogs';
3053     my $cb = "merge.$driver";
3054     my $attrs = '.git/info/attributes';
3055     ensuredir '.git/info';
3056
3057     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3058     if (!open ATTRS, "<", $attrs) {
3059         $!==ENOENT or die "$attrs: $!";
3060     } else {
3061         while (<ATTRS>) {
3062             chomp;
3063             next if m{^debian/changelog\s};
3064             print NATTRS $_, "\n" or die $!;
3065         }
3066         ATTRS->error and die $!;
3067         close ATTRS;
3068     }
3069     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3070     close NATTRS;
3071
3072     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3073     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3074
3075     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3076 }
3077
3078 sub setup_useremail (;$) {
3079     my ($always) = @_;
3080     return unless $always || access_cfg_bool(1, 'setup-useremail');
3081
3082     my $setup = sub {
3083         my ($k, $envvar) = @_;
3084         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3085         return unless defined $v;
3086         set_local_git_config "user.$k", $v;
3087     };
3088
3089     $setup->('email', 'DEBEMAIL');
3090     $setup->('name', 'DEBFULLNAME');
3091 }
3092
3093 sub ensure_setup_existing_tree () {
3094     my $k = "remote.$remotename.skipdefaultupdate";
3095     my $c = git_get_config $k;
3096     return if defined $c;
3097     set_local_git_config $k, 'true';
3098 }
3099
3100 sub setup_new_tree () {
3101     setup_mergechangelogs();
3102     setup_useremail();
3103 }
3104
3105 sub multisuite_suite_child ($$$) {
3106     my ($tsuite, $merginputs, $fn) = @_;
3107     # in child, sets things up, calls $fn->(), and returns undef
3108     # in parent, returns canonical suite name for $tsuite
3109     my $canonsuitefh = IO::File::new_tmpfile;
3110     my $pid = fork // die $!;
3111     if (!$pid) {
3112         $isuite = $tsuite;
3113         $us .= " [$isuite]";
3114         $debugprefix .= " ";
3115         progress "fetching $tsuite...";
3116         canonicalise_suite();
3117         print $canonsuitefh $csuite, "\n" or die $!;
3118         close $canonsuitefh or die $!;
3119         $fn->();
3120         return undef;
3121     }
3122     waitpid $pid,0 == $pid or die $!;
3123     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3124     seek $canonsuitefh,0,0 or die $!;
3125     local $csuite = <$canonsuitefh>;
3126     die $! unless defined $csuite && chomp $csuite;
3127     if ($? == 256*4) {
3128         printdebug "multisuite $tsuite missing\n";
3129         return $csuite;
3130     }
3131     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3132     push @$merginputs, {
3133         Ref => lrref,
3134         Info => $csuite,
3135     };
3136     return $csuite;
3137 }
3138
3139 sub fork_for_multisuite ($) {
3140     my ($before_fetch_merge) = @_;
3141     # if nothing unusual, just returns ''
3142     #
3143     # if multisuite:
3144     # returns 0 to caller in child, to do first of the specified suites
3145     # in child, $csuite is not yet set
3146     #
3147     # returns 1 to caller in parent, to finish up anything needed after
3148     # in parent, $csuite is set to canonicalised portmanteau
3149
3150     my $org_isuite = $isuite;
3151     my @suites = split /\,/, $isuite;
3152     return '' unless @suites > 1;
3153     printdebug "fork_for_multisuite: @suites\n";
3154
3155     my @mergeinputs;
3156
3157     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3158                                             sub { });
3159     return 0 unless defined $cbasesuite;
3160
3161     fail "package $package missing in (base suite) $cbasesuite"
3162         unless @mergeinputs;
3163
3164     my @csuites = ($cbasesuite);
3165
3166     $before_fetch_merge->();
3167
3168     foreach my $tsuite (@suites[1..$#suites]) {
3169         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3170                                                sub {
3171             @end = ();
3172             fetch();
3173             exit 0;
3174         });
3175         # xxx collecte the ref here
3176
3177         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3178         push @csuites, $csubsuite;
3179     }
3180
3181     foreach my $mi (@mergeinputs) {
3182         my $ref = git_get_ref $mi->{Ref};
3183         die "$mi->{Ref} ?" unless length $ref;
3184         $mi->{Commit} = $ref;
3185     }
3186
3187     $csuite = join ",", @csuites;
3188
3189     my $previous = git_get_ref lrref;
3190     if ($previous) {
3191         unshift @mergeinputs, {
3192             Commit => $previous,
3193             Info => "local combined tracking branch",
3194             Warning =>
3195  "archive seems to have rewound: local tracking branch is ahead!",
3196         };
3197     }
3198
3199     foreach my $ix (0..$#mergeinputs) {
3200         $mergeinputs[$ix]{Index} = $ix;
3201     }
3202
3203     @mergeinputs = sort {
3204         -version_compare(mergeinfo_version $a,
3205                          mergeinfo_version $b) # highest version first
3206             or
3207         $a->{Index} <=> $b->{Index}; # earliest in spec first
3208     } @mergeinputs;
3209
3210     my @needed;
3211
3212   NEEDED:
3213     foreach my $mi (@mergeinputs) {
3214         printdebug "multisuite merge check $mi->{Info}\n";
3215         foreach my $previous (@needed) {
3216             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3217             printdebug "multisuite merge un-needed $previous->{Info}\n";
3218             next NEEDED;
3219         }
3220         push @needed, $mi;
3221         printdebug "multisuite merge this-needed\n";
3222         $mi->{Character} = '+';
3223     }
3224
3225     $needed[0]{Character} = '*';
3226
3227     my $output = $needed[0]{Commit};
3228
3229     if (@needed > 1) {
3230         printdebug "multisuite merge nontrivial\n";
3231         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3232
3233         my $commit = "tree $tree\n";
3234         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3235             "Input branches:\n";
3236
3237         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3238             printdebug "multisuite merge include $mi->{Info}\n";
3239             $mi->{Character} //= ' ';
3240             $commit .= "parent $mi->{Commit}\n";
3241             $msg .= sprintf " %s  %-25s %s\n",
3242                 $mi->{Character},
3243                 (mergeinfo_version $mi),
3244                 $mi->{Info};
3245         }
3246         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3247         $msg .= "\nKey\n".
3248             " * marks the highest version branch, which choose to use\n".
3249             " + marks each branch which was not already an ancestor\n\n".
3250             "[dgit multi-suite $csuite]\n";
3251         $commit .=
3252             "author $authline\n".
3253             "committer $authline\n\n";
3254         $output = make_commit_text $commit.$msg;
3255         printdebug "multisuite merge generated $output\n";
3256     }
3257
3258     fetch_from_archive_record_1($output);
3259     fetch_from_archive_record_2($output);
3260
3261     progress "calculated combined tracking suite $csuite";
3262
3263     return 1;
3264 }
3265
3266 sub clone_set_head () {
3267     open H, "> .git/HEAD" or die $!;
3268     print H "ref: ".lref()."\n" or die $!;
3269     close H or die $!;
3270 }
3271 sub clone_finish ($) {
3272     my ($dstdir) = @_;
3273     runcmd @git, qw(reset --hard), lrref();
3274     runcmd qw(bash -ec), <<'END';
3275         set -o pipefail
3276         git ls-tree -r --name-only -z HEAD | \
3277         xargs -0r touch -h -r . --
3278 END
3279     printdone "ready for work in $dstdir";
3280 }
3281
3282 sub clone ($) {
3283     my ($dstdir) = @_;
3284     badusage "dry run makes no sense with clone" unless act_local();
3285
3286     my $multi_fetched = fork_for_multisuite(sub {
3287         printdebug "multi clone before fetch merge\n";
3288         changedir $dstdir;
3289     });
3290     if ($multi_fetched) {
3291         printdebug "multi clone after fetch merge\n";
3292         clone_set_head();
3293         clone_finish($dstdir);
3294         exit 0;
3295     }
3296     printdebug "clone main body\n";
3297
3298     canonicalise_suite();
3299     my $hasgit = check_for_git();
3300     mkdir $dstdir or fail "create \`$dstdir': $!";
3301     changedir $dstdir;
3302     runcmd @git, qw(init -q);
3303     clone_set_head();
3304     my $giturl = access_giturl(1);
3305     if (defined $giturl) {
3306         runcmd @git, qw(remote add), 'origin', $giturl;
3307     }
3308     if ($hasgit) {
3309         progress "fetching existing git history";
3310         git_fetch_us();
3311         runcmd_ordryrun_local @git, qw(fetch origin);
3312     } else {
3313         progress "starting new git history";
3314     }
3315     fetch_from_archive() or no_such_package;
3316     my $vcsgiturl = $dsc->{'Vcs-Git'};
3317     if (length $vcsgiturl) {
3318         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3319         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3320     }
3321     setup_new_tree();
3322     clone_finish($dstdir);
3323 }
3324
3325 sub fetch () {
3326     canonicalise_suite();
3327     if (check_for_git()) {
3328         git_fetch_us();
3329     }
3330     fetch_from_archive() or no_such_package();
3331     printdone "fetched into ".lrref();
3332 }
3333
3334 sub pull () {
3335     my $multi_fetched = fork_for_multisuite(sub { });
3336     fetch() unless $multi_fetched; # parent
3337     return if $multi_fetched eq '0'; # child
3338     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3339         lrref();
3340     printdone "fetched to ".lrref()." and merged into HEAD";
3341 }
3342
3343 sub check_not_dirty () {
3344     foreach my $f (qw(local-options local-patch-header)) {
3345         if (stat_exists "debian/source/$f") {
3346             fail "git tree contains debian/source/$f";
3347         }
3348     }
3349
3350     return if $ignoredirty;
3351
3352     my @cmd = (@git, qw(diff --quiet HEAD));
3353     debugcmd "+",@cmd;
3354     $!=0; $?=-1; system @cmd;
3355     return if !$?;
3356     if ($?==256) {
3357         fail "working tree is dirty (does not match HEAD)";
3358     } else {
3359         failedcmd @cmd;
3360     }
3361 }
3362
3363 sub commit_admin ($) {
3364     my ($m) = @_;
3365     progress "$m";
3366     runcmd_ordryrun_local @git, qw(commit -m), $m;
3367 }
3368
3369 sub commit_quilty_patch () {
3370     my $output = cmdoutput @git, qw(status --porcelain);
3371     my %adds;
3372     foreach my $l (split /\n/, $output) {
3373         next unless $l =~ m/\S/;
3374         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3375             $adds{$1}++;
3376         }
3377     }
3378     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3379     if (!%adds) {
3380         progress "nothing quilty to commit, ok.";
3381         return;
3382     }
3383     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3384     runcmd_ordryrun_local @git, qw(add -f), @adds;
3385     commit_admin <<END
3386 Commit Debian 3.0 (quilt) metadata
3387
3388 [dgit ($our_version) quilt-fixup]
3389 END
3390 }
3391
3392 sub get_source_format () {
3393     my %options;
3394     if (open F, "debian/source/options") {
3395         while (<F>) {
3396             next if m/^\s*\#/;
3397             next unless m/\S/;
3398             s/\s+$//; # ignore missing final newline
3399             if (m/\s*\#\s*/) {
3400                 my ($k, $v) = ($`, $'); #');
3401                 $v =~ s/^"(.*)"$/$1/;
3402                 $options{$k} = $v;
3403             } else {
3404                 $options{$_} = 1;
3405             }
3406         }
3407         F->error and die $!;
3408         close F;
3409     } else {
3410         die $! unless $!==&ENOENT;
3411     }
3412
3413     if (!open F, "debian/source/format") {
3414         die $! unless $!==&ENOENT;
3415         return '';
3416     }
3417     $_ = <F>;
3418     F->error and die $!;
3419     chomp;
3420     return ($_, \%options);
3421 }
3422
3423 sub madformat_wantfixup ($) {
3424     my ($format) = @_;
3425     return 0 unless $format eq '3.0 (quilt)';
3426     our $quilt_mode_warned;
3427     if ($quilt_mode eq 'nocheck') {
3428         progress "Not doing any fixup of \`$format' due to".
3429             " ----no-quilt-fixup or --quilt=nocheck"
3430             unless $quilt_mode_warned++;
3431         return 0;
3432     }
3433     progress "Format \`$format', need to check/update patch stack"
3434         unless $quilt_mode_warned++;
3435     return 1;
3436 }
3437
3438 sub maybe_split_brain_save ($$$) {
3439     my ($headref, $dgitview, $msg) = @_;
3440     # => message fragment "$saved" describing disposition of $dgitview
3441     return "commit id $dgitview" unless defined $split_brain_save;
3442     my @cmd = (shell_cmd "cd ../../../..",
3443                @git, qw(update-ref -m),
3444                "dgit --dgit-view-save $msg HEAD=$headref",
3445                $split_brain_save, $dgitview);
3446     runcmd @cmd;
3447     return "and left in $split_brain_save";
3448 }
3449
3450 # An "infopair" is a tuple [ $thing, $what ]
3451 # (often $thing is a commit hash; $what is a description)
3452
3453 sub infopair_cond_equal ($$) {
3454     my ($x,$y) = @_;
3455     $x->[0] eq $y->[0] or fail <<END;
3456 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3457 END
3458 };
3459
3460 sub infopair_lrf_tag_lookup ($$) {
3461     my ($tagnames, $what) = @_;
3462     # $tagname may be an array ref
3463     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3464     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3465     foreach my $tagname (@tagnames) {
3466         my $lrefname = lrfetchrefs."/tags/$tagname";
3467         my $tagobj = $lrfetchrefs_f{$lrefname};
3468         next unless defined $tagobj;
3469         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3470         return [ git_rev_parse($tagobj), $what ];
3471     }
3472     fail @tagnames==1 ? <<END : <<END;
3473 Wanted tag $what (@tagnames) on dgit server, but not found
3474 END
3475 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3476 END
3477 }
3478
3479 sub infopair_cond_ff ($$) {
3480     my ($anc,$desc) = @_;
3481     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3482 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3483 END
3484 };
3485
3486 sub pseudomerge_version_check ($$) {
3487     my ($clogp, $archive_hash) = @_;
3488
3489     my $arch_clogp = commit_getclogp $archive_hash;
3490     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3491                      'version currently in archive' ];
3492     if (defined $overwrite_version) {
3493         if (length $overwrite_version) {
3494             infopair_cond_equal([ $overwrite_version,
3495                                   '--overwrite= version' ],
3496                                 $i_arch_v);
3497         } else {
3498             my $v = $i_arch_v->[0];
3499             progress "Checking package changelog for archive version $v ...";
3500             eval {
3501                 my @xa = ("-f$v", "-t$v");
3502                 my $vclogp = parsechangelog @xa;
3503                 my $cv = [ (getfield $vclogp, 'Version'),
3504                            "Version field from dpkg-parsechangelog @xa" ];
3505                 infopair_cond_equal($i_arch_v, $cv);
3506             };
3507             if ($@) {
3508                 $@ =~ s/^dgit: //gm;
3509                 fail "$@".
3510                     "Perhaps debian/changelog does not mention $v ?";
3511             }
3512         }
3513     }
3514     
3515     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3516     return $i_arch_v;
3517 }
3518
3519 sub pseudomerge_make_commit ($$$$ $$) {
3520     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3521         $msg_cmd, $msg_msg) = @_;
3522     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3523
3524     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3525     my $authline = clogp_authline $clogp;
3526
3527     chomp $msg_msg;
3528     $msg_cmd .=
3529         !defined $overwrite_version ? ""
3530         : !length  $overwrite_version ? " --overwrite"
3531         : " --overwrite=".$overwrite_version;
3532
3533     mkpath '.git/dgit';
3534     my $pmf = ".git/dgit/pseudomerge";
3535     open MC, ">", $pmf or die "$pmf $!";
3536     print MC <<END or die $!;
3537 tree $tree
3538 parent $dgitview
3539 parent $archive_hash
3540 author $authline
3541 committer $authline
3542
3543 $msg_msg
3544
3545 [$msg_cmd]
3546 END
3547     close MC or die $!;
3548
3549     return make_commit($pmf);
3550 }
3551
3552 sub splitbrain_pseudomerge ($$$$) {
3553     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3554     # => $merged_dgitview
3555     printdebug "splitbrain_pseudomerge...\n";
3556     #
3557     #     We:      debian/PREVIOUS    HEAD($maintview)
3558     # expect:          o ----------------- o
3559     #                    \                   \
3560     #                     o                   o
3561     #                 a/d/PREVIOUS        $dgitview
3562     #                $archive_hash              \
3563     #  If so,                \                   \
3564     #  we do:                 `------------------ o
3565     #   this:                                   $dgitview'
3566     #
3567
3568     return $dgitview unless defined $archive_hash;
3569
3570     printdebug "splitbrain_pseudomerge...\n";
3571
3572     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3573
3574     if (!defined $overwrite_version) {
3575         progress "Checking that HEAD inciudes all changes in archive...";
3576     }
3577
3578     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3579
3580     if (defined $overwrite_version) {
3581     } elsif (!eval {
3582         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3583         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3584         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3585         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3586         my $i_archive = [ $archive_hash, "current archive contents" ];
3587
3588         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3589
3590         infopair_cond_equal($i_dgit, $i_archive);
3591         infopair_cond_ff($i_dep14, $i_dgit);
3592         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3593         1;
3594     }) {
3595         print STDERR <<END;
3596 $us: check failed (maybe --overwrite is needed, consult documentation)
3597 END
3598         die "$@";
3599     }
3600
3601     my $r = pseudomerge_make_commit
3602         $clogp, $dgitview, $archive_hash, $i_arch_v,
3603         "dgit --quilt=$quilt_mode",
3604         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3605 Declare fast forward from $i_arch_v->[0]
3606 END_OVERWR
3607 Make fast forward from $i_arch_v->[0]
3608 END_MAKEFF
3609
3610     maybe_split_brain_save $maintview, $r, "pseudomerge";
3611
3612     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3613     return $r;
3614 }       
3615
3616 sub plain_overwrite_pseudomerge ($$$) {
3617     my ($clogp, $head, $archive_hash) = @_;
3618
3619     printdebug "plain_overwrite_pseudomerge...";
3620
3621     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3622
3623     return $head if is_fast_fwd $archive_hash, $head;
3624
3625     my $m = "Declare fast forward from $i_arch_v->[0]";
3626
3627     my $r = pseudomerge_make_commit
3628         $clogp, $head, $archive_hash, $i_arch_v,
3629         "dgit", $m;
3630
3631     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3632
3633     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3634     return $r;
3635 }
3636
3637 sub push_parse_changelog ($) {
3638     my ($clogpfn) = @_;
3639
3640     my $clogp = Dpkg::Control::Hash->new();
3641     $clogp->load($clogpfn) or die;
3642
3643     my $clogpackage = getfield $clogp, 'Source';
3644     $package //= $clogpackage;
3645     fail "-p specified $package but changelog specified $clogpackage"
3646         unless $package eq $clogpackage;
3647     my $cversion = getfield $clogp, 'Version';
3648     my $tag = debiantag($cversion, access_nomdistro);
3649     runcmd @git, qw(check-ref-format), $tag;
3650
3651     my $dscfn = dscfn($cversion);
3652
3653     return ($clogp, $cversion, $dscfn);
3654 }
3655
3656 sub push_parse_dsc ($$$) {
3657     my ($dscfn,$dscfnwhat, $cversion) = @_;
3658     $dsc = parsecontrol($dscfn,$dscfnwhat);
3659     my $dversion = getfield $dsc, 'Version';
3660     my $dscpackage = getfield $dsc, 'Source';
3661     ($dscpackage eq $package && $dversion eq $cversion) or
3662         fail "$dscfn is for $dscpackage $dversion".
3663             " but debian/changelog is for $package $cversion";
3664 }
3665
3666 sub push_tagwants ($$$$) {
3667     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3668     my @tagwants;
3669     push @tagwants, {
3670         TagFn => \&debiantag,
3671         Objid => $dgithead,
3672         TfSuffix => '',
3673         View => 'dgit',
3674     };
3675     if (defined $maintviewhead) {
3676         push @tagwants, {
3677             TagFn => \&debiantag_maintview,
3678             Objid => $maintviewhead,
3679             TfSuffix => '-maintview',
3680             View => 'maint',
3681         };
3682     } elsif ($dodep14tag eq 'no' ? 0
3683              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3684              : $dodep14tag eq 'always'
3685              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3686 --dep14tag-always (or equivalent in config) means server must support
3687  both "new" and "maint" tag formats, but config says it doesn't.
3688 END
3689             : die "$dodep14tag ?") {
3690         push @tagwants, {
3691             TagFn => \&debiantag_maintview,
3692             Objid => $dgithead,
3693             TfSuffix => '-dgit',
3694             View => 'dgit',
3695         };
3696     };
3697     foreach my $tw (@tagwants) {
3698         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3699         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3700     }
3701     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3702     return @tagwants;
3703 }
3704
3705 sub push_mktags ($$ $$ $) {
3706     my ($clogp,$dscfn,
3707         $changesfile,$changesfilewhat,
3708         $tagwants) = @_;
3709
3710     die unless $tagwants->[0]{View} eq 'dgit';
3711
3712     $dsc->{$ourdscfield[0]} = $tagwants->[0]{Objid};
3713     $dsc->save("$dscfn.tmp") or die $!;
3714
3715     my $changes = parsecontrol($changesfile,$changesfilewhat);
3716     foreach my $field (qw(Source Distribution Version)) {
3717         $changes->{$field} eq $clogp->{$field} or
3718             fail "changes field $field \`$changes->{$field}'".
3719                 " does not match changelog \`$clogp->{$field}'";
3720     }
3721
3722     my $cversion = getfield $clogp, 'Version';
3723     my $clogsuite = getfield $clogp, 'Distribution';
3724
3725     # We make the git tag by hand because (a) that makes it easier
3726     # to control the "tagger" (b) we can do remote signing
3727     my $authline = clogp_authline $clogp;
3728     my $delibs = join(" ", "",@deliberatelies);
3729     my $declaredistro = access_nomdistro();
3730
3731     my $mktag = sub {
3732         my ($tw) = @_;
3733         my $tfn = $tw->{Tfn};
3734         my $head = $tw->{Objid};
3735         my $tag = $tw->{Tag};
3736
3737         open TO, '>', $tfn->('.tmp') or die $!;
3738         print TO <<END or die $!;
3739 object $head
3740 type commit
3741 tag $tag
3742 tagger $authline
3743
3744 END
3745         if ($tw->{View} eq 'dgit') {
3746             print TO <<END or die $!;
3747 $package release $cversion for $clogsuite ($csuite) [dgit]
3748 [dgit distro=$declaredistro$delibs]
3749 END
3750             foreach my $ref (sort keys %previously) {
3751                 print TO <<END or die $!;
3752 [dgit previously:$ref=$previously{$ref}]
3753 END
3754             }
3755         } elsif ($tw->{View} eq 'maint') {
3756             print TO <<END or die $!;
3757 $package release $cversion for $clogsuite ($csuite)
3758 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3759 END
3760         } else {
3761             die Dumper($tw)."?";
3762         }
3763
3764         close TO or die $!;
3765
3766         my $tagobjfn = $tfn->('.tmp');
3767         if ($sign) {
3768             if (!defined $keyid) {
3769                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3770             }
3771             if (!defined $keyid) {
3772                 $keyid = getfield $clogp, 'Maintainer';
3773             }
3774             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3775             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3776             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3777             push @sign_cmd, $tfn->('.tmp');
3778             runcmd_ordryrun @sign_cmd;
3779             if (act_scary()) {
3780                 $tagobjfn = $tfn->('.signed.tmp');
3781                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3782                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3783             }
3784         }
3785         return $tagobjfn;
3786     };
3787
3788     my @r = map { $mktag->($_); } @$tagwants;
3789     return @r;
3790 }
3791
3792 sub sign_changes ($) {
3793     my ($changesfile) = @_;
3794     if ($sign) {
3795         my @debsign_cmd = @debsign;
3796         push @debsign_cmd, "-k$keyid" if defined $keyid;
3797         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3798         push @debsign_cmd, $changesfile;
3799         runcmd_ordryrun @debsign_cmd;
3800     }
3801 }
3802
3803 sub dopush () {
3804     printdebug "actually entering push\n";
3805
3806     supplementary_message(<<'END');
3807 Push failed, while checking state of the archive.
3808 You can retry the push, after fixing the problem, if you like.
3809 END
3810     if (check_for_git()) {
3811         git_fetch_us();
3812     }
3813     my $archive_hash = fetch_from_archive();
3814     if (!$archive_hash) {
3815         $new_package or
3816             fail "package appears to be new in this suite;".
3817                 " if this is intentional, use --new";
3818     }
3819
3820     supplementary_message(<<'END');
3821 Push failed, while preparing your push.
3822 You can retry the push, after fixing the problem, if you like.
3823 END
3824
3825     need_tagformat 'new', "quilt mode $quilt_mode"
3826         if quiltmode_splitbrain;
3827
3828     prep_ud();
3829
3830     access_giturl(); # check that success is vaguely likely
3831     select_tagformat();
3832
3833     my $clogpfn = ".git/dgit/changelog.822.tmp";
3834     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3835
3836     responder_send_file('parsed-changelog', $clogpfn);
3837
3838     my ($clogp, $cversion, $dscfn) =
3839         push_parse_changelog("$clogpfn");
3840
3841     my $dscpath = "$buildproductsdir/$dscfn";
3842     stat_exists $dscpath or
3843         fail "looked for .dsc $dscpath, but $!;".
3844             " maybe you forgot to build";
3845
3846     responder_send_file('dsc', $dscpath);
3847
3848     push_parse_dsc($dscpath, $dscfn, $cversion);
3849
3850     my $format = getfield $dsc, 'Format';
3851     printdebug "format $format\n";
3852
3853     my $actualhead = git_rev_parse('HEAD');
3854     my $dgithead = $actualhead;
3855     my $maintviewhead = undef;
3856
3857     my $upstreamversion = upstreamversion $clogp->{Version};
3858
3859     if (madformat_wantfixup($format)) {
3860         # user might have not used dgit build, so maybe do this now:
3861         if (quiltmode_splitbrain()) {
3862             changedir $ud;
3863             quilt_make_fake_dsc($upstreamversion);
3864             my $cachekey;
3865             ($dgithead, $cachekey) =
3866                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
3867             $dgithead or fail
3868  "--quilt=$quilt_mode but no cached dgit view:
3869  perhaps tree changed since dgit build[-source] ?";
3870             $split_brain = 1;
3871             $dgithead = splitbrain_pseudomerge($clogp,
3872                                                $actualhead, $dgithead,
3873                                                $archive_hash);
3874             $maintviewhead = $actualhead;
3875             changedir '../../../..';
3876             prep_ud(); # so _only_subdir() works, below
3877         } else {
3878             commit_quilty_patch();
3879         }
3880     }
3881
3882     if (defined $overwrite_version && !defined $maintviewhead) {
3883         $dgithead = plain_overwrite_pseudomerge($clogp,
3884                                                 $dgithead,
3885                                                 $archive_hash);
3886     }
3887
3888     check_not_dirty();
3889
3890     my $forceflag = '';
3891     if ($archive_hash) {
3892         if (is_fast_fwd($archive_hash, $dgithead)) {
3893             # ok
3894         } elsif (deliberately_not_fast_forward) {
3895             $forceflag = '+';
3896         } else {
3897             fail "dgit push: HEAD is not a descendant".
3898                 " of the archive's version.\n".
3899                 "To overwrite the archive's contents,".
3900                 " pass --overwrite[=VERSION].\n".
3901                 "To rewind history, if permitted by the archive,".
3902                 " use --deliberately-not-fast-forward.";
3903         }
3904     }
3905
3906     changedir $ud;
3907     progress "checking that $dscfn corresponds to HEAD";
3908     runcmd qw(dpkg-source -x --),
3909         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
3910     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
3911     check_for_vendor_patches() if madformat($dsc->{format});
3912     changedir '../../../..';
3913     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
3914     debugcmd "+",@diffcmd;
3915     $!=0; $?=-1;
3916     my $r = system @diffcmd;
3917     if ($r) {
3918         if ($r==256) {
3919             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
3920             fail <<END
3921 HEAD specifies a different tree to $dscfn:
3922 $diffs
3923 Perhaps you forgot to build.  Or perhaps there is a problem with your
3924  source tree (see dgit(7) for some hints).  To see a full diff, run
3925    git diff $tree HEAD
3926 END
3927         } else {
3928             failedcmd @diffcmd;
3929         }
3930     }
3931     if (!$changesfile) {
3932         my $pat = changespat $cversion;
3933         my @cs = glob "$buildproductsdir/$pat";
3934         fail "failed to find unique changes file".
3935             " (looked for $pat in $buildproductsdir);".
3936             " perhaps you need to use dgit -C"
3937             unless @cs==1;
3938         ($changesfile) = @cs;
3939     } else {
3940         $changesfile = "$buildproductsdir/$changesfile";
3941     }
3942
3943     # Check that changes and .dsc agree enough
3944     $changesfile =~ m{[^/]*$};
3945     my $changes = parsecontrol($changesfile,$&);
3946     files_compare_inputs($dsc, $changes)
3947         unless forceing [qw(dsc-changes-mismatch)];
3948
3949     # Perhaps adjust .dsc to contain right set of origs
3950     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
3951                                   $changesfile)
3952         unless forceing [qw(changes-origs-exactly)];
3953
3954     # Checks complete, we're going to try and go ahead:
3955
3956     responder_send_file('changes',$changesfile);
3957     responder_send_command("param head $dgithead");
3958     responder_send_command("param csuite $csuite");
3959     responder_send_command("param tagformat $tagformat");
3960     if (defined $maintviewhead) {
3961         die unless ($protovsn//4) >= 4;
3962         responder_send_command("param maint-view $maintviewhead");
3963     }
3964
3965     if (deliberately_not_fast_forward) {
3966         git_for_each_ref(lrfetchrefs, sub {
3967             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
3968             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
3969             responder_send_command("previously $rrefname=$objid");
3970             $previously{$rrefname} = $objid;
3971         });
3972     }
3973
3974     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
3975                                  ".git/dgit/tag");
3976     my @tagobjfns;
3977
3978     supplementary_message(<<'END');
3979 Push failed, while signing the tag.
3980 You can retry the push, after fixing the problem, if you like.
3981 END
3982     # If we manage to sign but fail to record it anywhere, it's fine.
3983     if ($we_are_responder) {
3984         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
3985         responder_receive_files('signed-tag', @tagobjfns);
3986     } else {
3987         @tagobjfns = push_mktags($clogp,$dscpath,
3988                               $changesfile,$changesfile,
3989                               \@tagwants);
3990     }
3991     supplementary_message(<<'END');
3992 Push failed, *after* signing the tag.
3993 If you want to try again, you should use a new version number.
3994 END
3995
3996     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
3997
3998     foreach my $tw (@tagwants) {
3999         my $tag = $tw->{Tag};
4000         my $tagobjfn = $tw->{TagObjFn};
4001         my $tag_obj_hash =
4002             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4003         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4004         runcmd_ordryrun_local
4005             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4006     }
4007
4008     supplementary_message(<<'END');
4009 Push failed, while updating the remote git repository - see messages above.
4010 If you want to try again, you should use a new version number.
4011 END
4012     if (!check_for_git()) {
4013         create_remote_git_repo();
4014     }
4015
4016     my @pushrefs = $forceflag.$dgithead.":".rrref();
4017     foreach my $tw (@tagwants) {
4018         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4019     }
4020
4021     runcmd_ordryrun @git,
4022         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4023     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4024
4025     supplementary_message(<<'END');
4026 Push failed, while obtaining signatures on the .changes and .dsc.
4027 If it was just that the signature failed, you may try again by using
4028 debsign by hand to sign the changes
4029    $changesfile
4030 and then dput to complete the upload.
4031 If you need to change the package, you must use a new version number.
4032 END
4033     if ($we_are_responder) {
4034         my $dryrunsuffix = act_local() ? "" : ".tmp";
4035         responder_receive_files('signed-dsc-changes',
4036                                 "$dscpath$dryrunsuffix",
4037                                 "$changesfile$dryrunsuffix");
4038     } else {
4039         if (act_local()) {
4040             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4041         } else {
4042             progress "[new .dsc left in $dscpath.tmp]";
4043         }
4044         sign_changes $changesfile;
4045     }
4046
4047     supplementary_message(<<END);
4048 Push failed, while uploading package(s) to the archive server.
4049 You can retry the upload of exactly these same files with dput of:
4050   $changesfile
4051 If that .changes file is broken, you will need to use a new version
4052 number for your next attempt at the upload.
4053 END
4054     my $host = access_cfg('upload-host','RETURN-UNDEF');
4055     my @hostarg = defined($host) ? ($host,) : ();
4056     runcmd_ordryrun @dput, @hostarg, $changesfile;
4057     printdone "pushed and uploaded $cversion";
4058
4059     supplementary_message('');
4060     responder_send_command("complete");
4061 }
4062
4063 sub cmd_clone {
4064     parseopts();
4065     notpushing();
4066     my $dstdir;
4067     badusage "-p is not allowed with clone; specify as argument instead"
4068         if defined $package;
4069     if (@ARGV==1) {
4070         ($package) = @ARGV;
4071     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4072         ($package,$isuite) = @ARGV;
4073     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4074         ($package,$dstdir) = @ARGV;
4075     } elsif (@ARGV==3) {
4076         ($package,$isuite,$dstdir) = @ARGV;
4077     } else {
4078         badusage "incorrect arguments to dgit clone";
4079     }
4080     $dstdir ||= "$package";
4081
4082     if (stat_exists $dstdir) {
4083         fail "$dstdir already exists";
4084     }
4085
4086     my $cwd_remove;
4087     if ($rmonerror && !$dryrun_level) {
4088         $cwd_remove= getcwd();
4089         unshift @end, sub { 
4090             return unless defined $cwd_remove;
4091             if (!chdir "$cwd_remove") {
4092                 return if $!==&ENOENT;
4093                 die "chdir $cwd_remove: $!";
4094             }
4095             printdebug "clone rmonerror removing $dstdir\n";
4096             if (stat $dstdir) {
4097                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4098             } elsif (grep { $! == $_ }
4099                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4100             } else {
4101                 print STDERR "check whether to remove $dstdir: $!\n";
4102             }
4103         };
4104     }
4105
4106     clone($dstdir);
4107     $cwd_remove = undef;
4108 }
4109
4110 sub branchsuite () {
4111     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4112     if ($branch =~ m#$lbranch_re#o) {
4113         return $1;
4114     } else {
4115         return undef;
4116     }
4117 }
4118
4119 sub fetchpullargs () {
4120     notpushing();
4121     if (!defined $package) {
4122         my $sourcep = parsecontrol('debian/control','debian/control');
4123         $package = getfield $sourcep, 'Source';
4124     }
4125     if (@ARGV==0) {
4126         $isuite = branchsuite();
4127         if (!$isuite) {
4128             my $clogp = parsechangelog();
4129             $isuite = getfield $clogp, 'Distribution';
4130         }
4131     } elsif (@ARGV==1) {
4132         ($isuite) = @ARGV;
4133     } else {
4134         badusage "incorrect arguments to dgit fetch or dgit pull";
4135     }
4136 }
4137
4138 sub cmd_fetch {
4139     parseopts();
4140     fetchpullargs();
4141     my $multi_fetched = fork_for_multisuite(sub { });
4142     exit 0 if $multi_fetched;
4143     fetch();
4144 }
4145
4146 sub cmd_pull {
4147     parseopts();
4148     fetchpullargs();
4149     if (quiltmode_splitbrain()) {
4150         my ($format, $fopts) = get_source_format();
4151         madformat($format) and fail <<END
4152 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4153 END
4154     }
4155     pull();
4156 }
4157
4158 sub cmd_push {
4159     parseopts();
4160     pushing();
4161     badusage "-p is not allowed with dgit push" if defined $package;
4162     check_not_dirty();
4163     my $clogp = parsechangelog();
4164     $package = getfield $clogp, 'Source';
4165     my $specsuite;
4166     if (@ARGV==0) {
4167     } elsif (@ARGV==1) {
4168         ($specsuite) = (@ARGV);
4169     } else {
4170         badusage "incorrect arguments to dgit push";
4171     }
4172     $isuite = getfield $clogp, 'Distribution';
4173     if ($new_package) {
4174         local ($package) = $existing_package; # this is a hack
4175         canonicalise_suite();
4176     } else {
4177         canonicalise_suite();
4178     }
4179     if (defined $specsuite &&
4180         $specsuite ne $isuite &&
4181         $specsuite ne $csuite) {
4182             fail "dgit push: changelog specifies $isuite ($csuite)".
4183                 " but command line specifies $specsuite";
4184     }
4185     dopush();
4186 }
4187
4188 #---------- remote commands' implementation ----------
4189
4190 sub cmd_remote_push_build_host {
4191     my ($nrargs) = shift @ARGV;
4192     my (@rargs) = @ARGV[0..$nrargs-1];
4193     @ARGV = @ARGV[$nrargs..$#ARGV];
4194     die unless @rargs;
4195     my ($dir,$vsnwant) = @rargs;
4196     # vsnwant is a comma-separated list; we report which we have
4197     # chosen in our ready response (so other end can tell if they
4198     # offered several)
4199     $debugprefix = ' ';
4200     $we_are_responder = 1;
4201     $us .= " (build host)";
4202
4203     pushing();
4204
4205     open PI, "<&STDIN" or die $!;
4206     open STDIN, "/dev/null" or die $!;
4207     open PO, ">&STDOUT" or die $!;
4208     autoflush PO 1;
4209     open STDOUT, ">&STDERR" or die $!;
4210     autoflush STDOUT 1;
4211
4212     $vsnwant //= 1;
4213     ($protovsn) = grep {
4214         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4215     } @rpushprotovsn_support;
4216
4217     fail "build host has dgit rpush protocol versions ".
4218         (join ",", @rpushprotovsn_support).
4219         " but invocation host has $vsnwant"
4220         unless defined $protovsn;
4221
4222     responder_send_command("dgit-remote-push-ready $protovsn");
4223     rpush_handle_protovsn_bothends();
4224     changedir $dir;
4225     &cmd_push;
4226 }
4227
4228 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4229 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4230 #     a good error message)
4231
4232 sub rpush_handle_protovsn_bothends () {
4233     if ($protovsn < 4) {
4234         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4235     }
4236     select_tagformat();
4237 }
4238
4239 our $i_tmp;
4240
4241 sub i_cleanup {
4242     local ($@, $?);
4243     my $report = i_child_report();
4244     if (defined $report) {
4245         printdebug "($report)\n";
4246     } elsif ($i_child_pid) {
4247         printdebug "(killing build host child $i_child_pid)\n";
4248         kill 15, $i_child_pid;
4249     }
4250     if (defined $i_tmp && !defined $initiator_tempdir) {
4251         changedir "/";
4252         eval { rmtree $i_tmp; };
4253     }
4254 }
4255
4256 END { i_cleanup(); }
4257
4258 sub i_method {
4259     my ($base,$selector,@args) = @_;
4260     $selector =~ s/\-/_/g;
4261     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4262 }
4263
4264 sub cmd_rpush {
4265     pushing();
4266     my $host = nextarg;
4267     my $dir;
4268     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4269         $host = $1;
4270         $dir = $'; #';
4271     } else {
4272         $dir = nextarg;
4273     }
4274     $dir =~ s{^-}{./-};
4275     my @rargs = ($dir);
4276     push @rargs, join ",", @rpushprotovsn_support;
4277     my @rdgit;
4278     push @rdgit, @dgit;
4279     push @rdgit, @ropts;
4280     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4281     push @rdgit, @ARGV;
4282     my @cmd = (@ssh, $host, shellquote @rdgit);
4283     debugcmd "+",@cmd;
4284
4285     if (defined $initiator_tempdir) {
4286         rmtree $initiator_tempdir;
4287         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4288         $i_tmp = $initiator_tempdir;
4289     } else {
4290         $i_tmp = tempdir();
4291     }
4292     $i_child_pid = open2(\*RO, \*RI, @cmd);
4293     changedir $i_tmp;
4294     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4295     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4296     $supplementary_message = '' unless $protovsn >= 3;
4297
4298     fail "rpush negotiated protocol version $protovsn".
4299         " which does not support quilt mode $quilt_mode"
4300         if quiltmode_splitbrain;
4301
4302     rpush_handle_protovsn_bothends();
4303     for (;;) {
4304         my ($icmd,$iargs) = initiator_expect {
4305             m/^(\S+)(?: (.*))?$/;
4306             ($1,$2);
4307         };
4308         i_method "i_resp", $icmd, $iargs;
4309     }
4310 }
4311
4312 sub i_resp_progress ($) {
4313     my ($rhs) = @_;
4314     my $msg = protocol_read_bytes \*RO, $rhs;
4315     progress $msg;
4316 }
4317
4318 sub i_resp_supplementary_message ($) {
4319     my ($rhs) = @_;
4320     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4321 }
4322
4323 sub i_resp_complete {
4324     my $pid = $i_child_pid;
4325     $i_child_pid = undef; # prevents killing some other process with same pid
4326     printdebug "waiting for build host child $pid...\n";
4327     my $got = waitpid $pid, 0;
4328     die $! unless $got == $pid;
4329     die "build host child failed $?" if $?;
4330
4331     i_cleanup();
4332     printdebug "all done\n";
4333     exit 0;
4334 }
4335
4336 sub i_resp_file ($) {
4337     my ($keyword) = @_;
4338     my $localname = i_method "i_localname", $keyword;
4339     my $localpath = "$i_tmp/$localname";
4340     stat_exists $localpath and
4341         badproto \*RO, "file $keyword ($localpath) twice";
4342     protocol_receive_file \*RO, $localpath;
4343     i_method "i_file", $keyword;
4344 }
4345
4346 our %i_param;
4347
4348 sub i_resp_param ($) {
4349     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4350     $i_param{$1} = $2;
4351 }
4352
4353 sub i_resp_previously ($) {
4354     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4355         or badproto \*RO, "bad previously spec";
4356     my $r = system qw(git check-ref-format), $1;
4357     die "bad previously ref spec ($r)" if $r;
4358     $previously{$1} = $2;
4359 }
4360
4361 our %i_wanted;
4362
4363 sub i_resp_want ($) {
4364     my ($keyword) = @_;
4365     die "$keyword ?" if $i_wanted{$keyword}++;
4366     my @localpaths = i_method "i_want", $keyword;
4367     printdebug "[[  $keyword @localpaths\n";
4368     foreach my $localpath (@localpaths) {
4369         protocol_send_file \*RI, $localpath;
4370     }
4371     print RI "files-end\n" or die $!;
4372 }
4373
4374 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4375
4376 sub i_localname_parsed_changelog {
4377     return "remote-changelog.822";
4378 }
4379 sub i_file_parsed_changelog {
4380     ($i_clogp, $i_version, $i_dscfn) =
4381         push_parse_changelog "$i_tmp/remote-changelog.822";
4382     die if $i_dscfn =~ m#/|^\W#;
4383 }
4384
4385 sub i_localname_dsc {
4386     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4387     return $i_dscfn;
4388 }
4389 sub i_file_dsc { }
4390
4391 sub i_localname_changes {
4392     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4393     $i_changesfn = $i_dscfn;
4394     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4395     return $i_changesfn;
4396 }
4397 sub i_file_changes { }
4398
4399 sub i_want_signed_tag {
4400     printdebug Dumper(\%i_param, $i_dscfn);
4401     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4402         && defined $i_param{'csuite'}
4403         or badproto \*RO, "premature desire for signed-tag";
4404     my $head = $i_param{'head'};
4405     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4406
4407     my $maintview = $i_param{'maint-view'};
4408     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4409
4410