dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use POSIX;
  28
  29 our $suite = 'sid';
  30 our $package;
  31
  32 our $sign = 1;
  33 our $dryrun = 0;
  34 our $changesfile;
  35
  36 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  37
  38 our (@git) = qw(git);
  39 our (@dget) = qw(dget);
  40 our (@dput) = qw(dput);
  41 our (@debsign) = qw(debsign);
  42 our $keyid;
  43
  44 our $debug = 0;
  45 open DEBUG, ">/dev/null" or die $!;
  46
  47 our %opts_opt_map = ('dget' => \@dget,
  48                      'dput' => \@dput,
  49                      'debsign' => \@debsign);
  50
  51 our $remotename = 'dgit';
  52 our $ourdscfield = 'Vcs-Git-Master';
  53 our $branchprefix = 'dgit';
  54
  55 sub lbranch () { return "$branchprefix/$suite"; }
  56 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
  57 sub lref () { return "refs/heads/".lbranch(); }
  58 sub lrref () { return "refs/remotes/$remotename/$suite"; }
  59 sub rrref () { return "refs/$branchprefix/$suite"; }
  60 sub debiantag ($) { return "debian/$_[0]"; }
  61
  62 sub fetchspec () {
  63     local $suite = '*';
  64     return  "+".rrref().":".lrref();
  65 }
  66
  67 our $ua;
  68
  69 sub url_get {
  70     if (!$ua) {
  71         $ua = LWP::UserAgent->new();
  72         $ua->env_proxy;
  73     }
  74     print "downloading @_...\n";
  75     my $r = $ua->get(@_) or die $!;
  76     die "$_[0]: ".$r->status_line."; failed.\n" unless $r->is_success;
  77     return $r->decoded_content();
  78 }
  79
  80 our ($dscdata,$dscurl,$dsc);
  81
  82 sub printcmd {
  83     my $fh = shift @_;
  84     my $intro = shift @_;
  85     print $fh $intro or die $!;
  86     local $_;
  87     foreach my $a (@_) {
  88         $_ = $a;
  89         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
  90             print $fh " '$_'" or die $!;
  91         } else {
  92             print $fh " $_" or die $!;
  93         }
  94     }
  95     print $fh "\n" or die $!;
  96 }
  97
  98 sub runcmd {
  99     printcmd(\*DEBUG,"+",@_) if $debug>0;
 100     $!=0; $?=0;
 101     die "@_ $! $?" if system @_;
 102 }
 103
 104 sub cmdoutput_errok {
 105     die Dumper(\@_)." ?" if grep { !defined } @_;
 106     printcmd(\*DEBUG,"|",@_) if $debug>0;
 107     open P, "-|", @_ or die $!;
 108     my $d;
 109     $!=0; $?=0;
 110     { local $/ = undef; $d = <P>; }
 111     die if P->error;
 112     close P or return undef;
 113     chomp $d;
 114     return $d;
 115 }
 116
 117 sub cmdoutput {
 118     my $d = cmdoutput_errok @_;
 119     defined $d or die "@_ $? $!";
 120     return $d;
 121 }
 122
 123 sub dryrun_report {
 124     printcmd(\*STDOUT,"#",@_);
 125 }
 126
 127 sub runcmd_ordryrun {
 128     if (!$dryrun) {
 129         runcmd @_;
 130     } else {
 131         dryrun_report @_;
 132     }
 133 }
 134
 135 our %defcfg = ('dgit.default.distro' => 'debian',
 136                'dgit.default.username' => '',
 137                'dgit.default.ssh' => 'ssh',
 138                'dgit-distro.debian.git-host' => 'git.debian.org',
 139                'dgit-distro.debian.git-proto' => 'git+ssh://',
 140                'dgit-distro.debian.git-path' => '/git/dgit-repos',
 141                'dgit-distro.debian.git-check' => 'ssh-cmd',
 142                'dgit-distro.debian.git-create' => 'ssh-cmd',
 143                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/');
 144
 145 sub cfg {
 146     foreach my $c (@_) {
 147         my $v;
 148         {
 149             my $d2 = $debug-1;
 150             local ($debug) = $d2;
 151             $v = cmdoutput_errok(@git, qw(config --), $c);
 152         };
 153         if ($?==0) {
 154             chomp $v;
 155             return $v;
 156         } elsif ($?!=256) {
 157             die "$c $?";
 158         }
 159         my $dv = $defcfg{$c};
 160         return $dv if defined $dv;
 161     }
 162     return undef;
 163 }
 164
 165 sub access_distro () {
 166     return cfg("dgit-suite.$suite.distro",
 167                "dgit.default.distro");
 168 }
 169
 170 sub access_cfg ($) {
 171     my ($key) = @_;
 172     my $distro = access_distro();
 173     my $value = cfg("dgit-distro.$distro.$key",
 174                     "dgit.default.$key");
 175     return $value;
 176 }
 177
 178 sub access_gituserhost () {
 179     my $user = access_cfg('git-user');
 180     my $host = access_cfg('git-host');
 181     return defined($user) && length($user) ? "$user\@$host" : $host;
 182 }
 183
 184 sub access_giturl () {
 185     my $url = access_cfg('git-url');
 186     if (!defined $url) {
 187         $url =
 188             access_cfg('git-proto').
 189             access_gituserhost().
 190             access_cfg('git-path');
 191     }
 192     return "$url/$package.git";
 193 }
 194
 195 sub parsecontrol {
 196     my $c = Dpkg::Control::Hash->new();
 197     $c->load(@_) or return undef;
 198     return $c;
 199 }
 200
 201 sub parsechangelog {
 202     my $c = Dpkg::Control::Hash->new();
 203     my $p = new IO::Handle;
 204     open $p, '-|', qw(dpkg-parsechangelog) or die $!;
 205     $c->parse($p);
 206     $?=0; $!=0; close $p or die "$! $?";
 207     return $c;
 208 }
 209
 210 our $rmad;
 211
 212 sub archive_query () {
 213     my $query = access_cfg('archive-query');
 214     $query ||= "madison:".access_distro();
 215     $query =~ s/^(\w+):// or die "$query ?";
 216     my $proto = $1;
 217     my $url = $'; #';
 218     die unless $proto eq 'madison';
 219     $rmad ||= cmdoutput qw(rmadison -asource),"-s$suite","-u$url",$package;
 220     $rmad =~ m/^ \s*( [^ \t|]+ )\s* \|
 221                  \s*( [^ \t|]+ )\s* \|
 222                  \s*( [^ \t|]+ )\s* \|
 223                  \s*( [^ \t|]+ )\s* /x or die "$rmad $?";
 224     $1 eq $package or die "$rmad $package ?";
 225     my $vsn = $2;
 226     if ($suite ne $3) {
 227         # madison canonicalises for us
 228         print "canonical suite name for $suite is $3\n";
 229         $suite = $3;
 230     }
 231     $4 eq 'source' or die "$rmad ?";
 232     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 233     my $subpath = "/pool/main/$prefix/$package/${package}_$vsn.dsc";
 234     return ($vsn,$subpath);
 235 }
 236
 237 sub canonicalise_suite () {
 238     archive_query();
 239 }
 240
 241 sub get_archive_dsc () {
 242     my ($vsn,$subpath) = archive_query();
 243     # fixme madison does not show us the component
 244     $dscurl = access_cfg('mirror').$subpath;
 245     $dscdata = url_get($dscurl);
 246     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 247     print DEBUG Dumper($dscdata) if $debug>1;
 248     $dsc = Dpkg::Control::Hash->new(allow_pgp=>1);
 249     $dsc->parse($dscfh, 'dsc') or die "parsing of $dscurl failed\n";
 250     print DEBUG Dumper($dsc) if $debug>1;
 251     my $fmt = $dsc->{Format};
 252     die "unsupported format $fmt, sorry\n" unless $format_ok{$fmt};
 253 }
 254
 255 sub check_for_git () {
 256     # returns 0 or 1
 257     my $how = access_cfg('git-check');
 258     if ($how eq 'ssh-cmd') {
 259         my $r= cmdoutput
 260             (access_cfg('ssh'),access_gituserhost(),
 261              " set -e; cd ".access_cfg('git-path').";".
 262              " if test -d $package.git; then echo 1; else echo 0; fi");
 263         print DEBUG "got \`$r'\n";
 264         die "$r $! $?" unless $r =~ m/^[01]$/;
 265         return $r+0;
 266     } else {
 267         die "unknown git-check $how ?";
 268     }
 269 }
 270
 271 sub create_remote_git_repo () {
 272     my $how = access_cfg('git-create');
 273     if ($how eq 'ssh-cmd') {
 274         runcmd_ordryrun
 275             (access_cfg('ssh'),access_gituserhost(),
 276              "set -e; cd ".access_cfg('git-path').";".
 277              " mkdir -p $package.git;".
 278              " cd $package.git;".
 279              " if ! test -d objects; then git init --bare; fi");
 280     } else {
 281         die "unknown git-create $how ?";
 282     }
 283 }
 284
 285 our ($dsc_hash,$upload_hash);
 286
 287 our $ud = '.git/dgit/unpack';
 288
 289 sub prep_ud () {
 290     rmtree($ud);
 291     mkpath '.git/dgit';
 292     mkdir $ud or die $!;
 293 }
 294
 295 sub mktree_in_ud_from_only_subdir () {
 296     # changes into the subdir
 297     my (@dirs) = <*/.>;
 298     die unless @dirs==1;
 299     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 300     my $dir = $1;
 301     chdir $dir or die "$dir $!";
 302     die if stat '.git';
 303     die $! unless $!==&ENOENT;
 304     runcmd qw(git init -q);
 305     rmtree('.git/objects');
 306     symlink '../../../../objects','.git/objects' or die $!;
 307     runcmd @git, qw(add -Af);
 308     my $tree = cmdoutput @git, qw(write-tree);
 309     chomp $tree; $tree =~ m/^\w+$/ or die "$tree ?";
 310     return ($tree,$dir);
 311 }
 312
 313 sub dsc_files () {
 314     map {
 315         m/^\w+ \d+ (\S+)$/ or die "$_ ?";
 316         $1;
 317     } grep m/\S/, split /\n/, ($dsc->{'Checksums-Sha256'} || $dsc->{Files});
 318 }
 319
 320 sub is_orig_file ($) {
 321     local ($_) = @_;
 322     m/\.orig(?:-\w+)?\.tar\.\w+$/;
 323 }
 324
 325 sub generate_commit_from_dsc () {
 326     prep_ud();
 327     chdir $ud or die $!;
 328     my @files;
 329     foreach my $f (dsc_files()) {
 330         die if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 331         push @files, $f;
 332         link "../../../$f", $f
 333             or $!==&ENOENT
 334             or die "$f $!";
 335     }
 336     runcmd @dget, qw(--), $dscurl;
 337     foreach my $f (grep { is_orig_file($_) } @files) {
 338         link $f, "../../../../$f"
 339             or $!==&EEXIST
 340             or die "$f $!";
 341     }
 342     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 343     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 344     my $clogp = parsecontrol('../changelog.tmp','changelog') or die;
 345     my $date = cmdoutput qw(date), '+%s %z', qw(-d),$clogp->{Date};
 346     my $author = $clogp->{Maintainer};
 347     $author =~ s#,.*##ms;
 348     my $authline = "$author $date";
 349     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or die $authline;
 350     open C, ">../commit.tmp" or die $!;
 351     print C "tree $tree\n" or die $!;
 352     print C "parent $upload_hash\n" or die $! if $upload_hash;
 353     print C <<END or die $!;
 354 author $authline
 355 committer $authline
 356
 357 $clogp->{Changes}
 358
 359 # imported by dgit from the archive
 360 END
 361     close C or die $!;
 362     my $commithash = cmdoutput @git, qw(hash-object -w -t commit ../commit.tmp);
 363     print "synthesised git commit from .dsc $clogp->{Version}\n";
 364     chdir '../../../..' or die $!;
 365     cmdoutput @git, qw(update-ref -m),"dgit synthesise $clogp->{Version}",
 366               'DGIT_ARCHIVE', $commithash;
 367     cmdoutput @git, qw(log -n2), $commithash;
 368     # ... gives git a chance to complain if our commit is malformed
 369     my $outputhash = $commithash;
 370     if ($upload_hash) {
 371         chdir "$ud/$dir" or die $!;
 372         runcmd @git, qw(reset --hard), $upload_hash;
 373         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 374         my $oldclogp = Dpkg::Control::Hash->new();
 375         $oldclogp->parse('../changelogold.tmp','previous changelog') or die;
 376         my $vcmp =
 377             version_compare_string($oldclogp->{Version}, $clogp->{Version});
 378         if ($vcmp < 0) {
 379             # git upload/ is earlier vsn than archive, use archive
 380         } elsif ($vcmp >= 0) {
 381             print STDERR <<END or die $!;
 382 Version actually in archive:    $clogp->{Version} (older)
 383 Last allegedly pushed/uploaded: $oldclogp->{Version} (newer or same)
 384 Perhaps the upload is stuck in incoming.  Using the version from git.
 385 END
 386         } else {
 387             die "version in archive is same as version in git".
 388                 " to-be-uploaded (upload/) branch but archive".
 389                 " version hash no commit hash?!\n";
 390         }
 391         chdir '../../../..' or die $!;
 392     }
 393     rmtree($ud);
 394     return $outputhash;
 395 }
 396
 397 sub ensure_we_have_orig () {
 398     foreach my $f (dsc_files()) {
 399         next unless is_orig_file($f);
 400         if (stat "../$f") {
 401             die "$f ?" unless -f _;
 402         } else {
 403             die "$f $!" unless $!==&ENOENT;
 404         }
 405         my $origurl = $dscurl;
 406         $origurl =~ s{/[^/]+$}{};
 407         $origurl .= "/$f";
 408         die "$f ?" unless $f =~ m/^${package}_/;
 409         die "$f ?" if $f =~ m#/#;
 410         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 411             @dget,'--',$origurl;
 412     }
 413 }
 414
 415 sub rev_parse ($) {
 416     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 417 }
 418
 419 sub is_fast_fwd ($$) {
 420     my ($ancestor,$child) = @_;
 421     my $mb = cmdoutput @git, qw(merge-base), $dsc_hash, $upload_hash;
 422     return rev_parse($mb) eq rev_parse($ancestor);
 423 }
 424
 425 sub git_fetch_us () {
 426     die "cannot dry run with fetch" if $dryrun;
 427     runcmd @git, qw(fetch),access_giturl(),fetchspec();
 428 }
 429
 430 sub fetch_from_archive () {
 431     # ensures that lrref() is what is actually in the archive,
 432     #  one way or another
 433     get_archive_dsc();
 434     $dsc_hash = $dsc->{$ourdscfield};
 435     if (defined $dsc_hash) {
 436         $dsc_hash =~ m/\w+/ or die "$dsc_hash $?";
 437         $dsc_hash = $&;
 438         print "last upload to archive specified git hash\n";
 439     } else {
 440         print "last upload to archive has NO git hash\n";
 441     }
 442
 443     $!=0; $upload_hash =
 444         cmdoutput_errok @git, qw(show-ref --heads), lrref();
 445     if ($?==0) {
 446         die unless chomp $upload_hash;
 447     } elsif ($?==256) {
 448         $upload_hash = '';
 449     } else {
 450         die $?;
 451     }
 452     my $hash;
 453     if (defined $dsc_hash) {
 454         die "missing git history even though dsc has hash"
 455             unless $upload_hash;
 456         $hash = $dsc_hash;
 457         ensure_we_have_orig();
 458     } else {
 459         $hash = generate_commit_from_dsc();
 460     }
 461     if ($upload_hash) {
 462         die "not fast forward on last upload branch!".
 463             " (archive's version left in DGIT_ARCHIVE)"
 464             unless is_fast_fwd($dsc_hash, $upload_hash);
 465     }
 466     if ($upload_hash ne $hash) {
 467         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
 468         if (!$dryrun) {
 469             cmdoutput @upd_cmd;
 470         } else {
 471             dryrun_report @upd_cmd;
 472         }
 473     }
 474 }
 475
 476 sub clone ($) {
 477     my ($dstdir) = @_;
 478     die "dry run makes no sense with clone" if $dryrun;
 479     mkdir $dstdir or die "$dstdir $!";
 480     chdir "$dstdir" or die "$dstdir $!";
 481     runcmd @git, qw(init -q);
 482     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
 483     open H, "> .git/HEAD" or die $!;
 484     print H "ref: ".lref()."\n" or die $!;
 485     close H or die $!;
 486     runcmd @git, qw(remote add), 'origin', access_giturl();
 487     if (check_for_git()) {
 488         print "fetching existing git history\n";
 489         git_fetch_us();
 490         runcmd @git, qw(fetch origin);
 491     } else {
 492         print "starting new git history\n";
 493     }
 494     fetch_from_archive();
 495     runcmd @git, qw(reset --hard), lrref();
 496     print "ready for work in $dstdir\n";
 497 }
 498
 499 sub fetch () {
 500     if (check_for_git()) {
 501         git_fetch_us();
 502     }
 503     fetch_from_archive();
 504 }
 505
 506 sub pull () {
 507     fetch();
 508     runcmd_ordryrun @git, qw(merge -m),"Merge from $suite [dgit]",
 509         lrref();
 510 }
 511
 512 sub dopush () {
 513     runcmd @git, qw(diff --quiet HEAD);
 514     my $clogp = parsechangelog();
 515     $package = $clogp->{Source};
 516     my $dscfn = "${package}_$clogp->{Version}.dsc";
 517     stat "../$dscfn" or die "$dscfn $!";
 518     $dsc = parsecontrol("../$dscfn");
 519     prep_ud();
 520     chdir $ud or die $!;
 521     print "checking that $dscfn corresponds to HEAD\n";
 522     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 523     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 524     chdir '../../../..' or die $!;
 525     runcmd @git, qw(diff --exit-code), $tree;
 526 #fetch from alioth
 527 #do fast forward check and maybe fake merge
 528 #    if (!is_fast_fwd(mainbranch
 529 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 530 #        map { lref($_).":".rref($_) }
 531 #        (uploadbranch());
 532     $dsc->{$ourdscfield} = rev_parse('HEAD');
 533     $dsc->save("../$dscfn.tmp") or die $!;
 534     if (!$dryrun) {
 535         rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 536     } else {
 537         print "[new .dsc left in $dscfn.tmp]\n";
 538     }
 539     if (!$changesfile) {
 540         my $pat = "../${package}_$clogp->{Version}_*.changes";
 541         my @cs = glob $pat;
 542         die "$pat ?" unless @cs==1;
 543         ($changesfile) = @cs;
 544     }
 545     my $tag = debiantag($dsc->{Version});
 546     if (!check_for_git()) {
 547         create_remote_git_repo();
 548     }
 549     runcmd_ordryrun @git, qw(push),access_giturl(),"HEAD:".rrref();
 550     if ($sign) {
 551         my @tag_cmd = (@git, qw(tag -s -m),
 552                        "Release $dsc->{Version} for $suite [dgit]");
 553         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 554         push @tag_cmd, $tag;
 555         runcmd_ordryrun @tag_cmd;
 556         my @debsign_cmd = @debsign;
 557         push @debsign_cmd, "-k$keyid" if defined $keyid;
 558         push @debsign_cmd, $changesfile;
 559         runcmd_ordryrun @debsign_cmd;
 560     }
 561     runcmd_ordryrun @git, qw(push),access_giturl(),"refs/tags/$tag";
 562     my $host = access_cfg('upload-host');
 563     my @hostarg = defined($host) ? ($host,) : ();
 564     runcmd_ordryrun @dput, @hostarg, $changesfile;
 565 }
 566
 567 sub cmd_clone {
 568     my $dstdir;
 569     die if defined $package;
 570     if (@ARGV==1) {
 571         ($package) = @ARGV;
 572     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
 573         ($package,$suite) = @ARGV;
 574     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
 575         ($package,$dstdir) = @ARGV;
 576     } elsif (@ARGV==3) {
 577         ($package,$suite,$dstdir) = @ARGV;
 578     } else {
 579         die;
 580     }
 581     $dstdir ||= "$package";
 582     clone($dstdir);
 583 }
 584
 585 sub branchsuite () {
 586     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 587     chomp $branch;
 588     if ($branch =~ m#$lbranch_re#o) {
 589         return $1;
 590     } else {
 591         return undef;
 592     }
 593 }
 594
 595 sub fetchpullargs () {
 596     if (!defined $package) {
 597         my $sourcep = parsecontrol('debian/control');
 598         $package = $sourcep->{Source};
 599     }
 600     if (@ARGV==0) {
 601         $suite = branchsuite();
 602         if (!$suite) {
 603             my $clogp = parsechangelog();
 604             $suite = $clogp->{Distribution};
 605         }
 606         canonicalise_suite();
 607         print "fetching from suite $suite\n";
 608     } elsif (@ARGV==1) {
 609         ($suite) = @ARGV;
 610         canonicalise_suite();
 611     } else {
 612         die;
 613     }
 614 }
 615
 616 sub cmd_fetch {
 617     fetchpullargs();
 618     fetch();
 619 }
 620
 621 sub cmd_pull {
 622     fetchpullargs();
 623     pull();
 624 }
 625
 626 sub cmd_push {
 627     die if defined $package;
 628     my $clogp = parsechangelog();
 629     $package = $clogp->{Source};
 630     if (@ARGV==0) {
 631         $suite = $clogp->{Distribution};
 632         canonicalise_suite();
 633     } else {
 634         die;
 635     }
 636     dopush();
 637 }
 638
 639 sub cmd_build {
 640     die if defined $package;
 641     my $clogp = parsechangelog();
 642     $suite = $clogp->{Distribution};
 643     $package = $clogp->{Source};
 644     canonicalise_suite();
 645     runcmd_ordryrun
 646         qw(git-buildpackage -us -uc --git-no-sign-tags),
 647             "--git-debian-branch=".lbranch(),
 648             @ARGV;
 649 }
 650
 651 sub parseopts () {
 652     my $om;
 653     while (@ARGV) {
 654         last unless $ARGV[0] =~ m/^-/;
 655         $_ = shift @ARGV;
 656         last if m/^--?$/;
 657         if (m/^--/) {
 658             if (m/^--dry-run$/) {
 659                 $dryrun=1;
 660             } elsif (m/^--no-sign$/) {
 661                 $sign=0;
 662             } elsif (m/^--(\w+)=(.*)/s && ($om = $opts_opt_map{$1})) {
 663                 $om->[0] = $2;
 664             } elsif (m/^--(\w+):(.*)/s && ($om = $opts_opt_map{$1})) {
 665                 push @$om, $2;
 666             } else {
 667                 die "$_ ?";
 668             }
 669         } else {
 670             while (m/^-./s) {
 671                 if (s/^-n/-/) {
 672                     $dryrun=1;
 673                 } elsif (s/^-D/-/) {
 674                     open DEBUG, ">&STDERR" or die $!;
 675                     $debug++;
 676                 } elsif (s/^-c(.*=.*)//s) {
 677                     push @git, '-c', $1;
 678                 } elsif (s/^-C(.*)//s) {
 679                     $changesfile = $1;
 680                 } elsif (s/^-k(.*)//s) {
 681                     $keyid=$1;
 682                 } else {
 683                     die "$_ ?";
 684                 }
 685             }
 686         }
 687     }
 688 }
 689
 690 parseopts();
 691 die unless @ARGV;
 692 my $cmd = shift @ARGV;
 693 parseopts();
 694
 695 { no strict qw(refs); &{"cmd_$cmd"}(); }