dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use POSIX;
  28
  29 open DEBUG, ">&STDERR" or die $!;
  30
  31 our $mirror = 'http://mirror.relativity.greenend.org.uk/mirror/debian-ftp/';
  32 our $suite = 'sid';
  33 our $package;
  34
  35 our $sign = 1;
  36 our $dryrun = 0;
  37 our $changesfile;
  38
  39 our $aliothname = 'iwj@git.debian.org';
  40 our $aliothpath = '/git/dgit-test';
  41 our $alioth_git = "git+ssh://$aliothname/$aliothpath";
  42 our $alioth_sshtestbodge = [$aliothname,$aliothpath];
  43
  44 our (@git) = qw(git);
  45 our (@dget) = qw(dget);
  46 our (@dput) = qw(dput);
  47 our (@debsign) = qw(debsign);
  48 our $keyid;
  49
  50 our %opts_opt_map = ('dget' => \@dget,
  51                      'dput' => \@dput,
  52                      'debsign' => \@debsign);
  53
  54 our $remotename = 'dgit';
  55 our $ourdscfield = 'Vcs-Git-Master';
  56 our $branchprefix = 'dgit';
  57
  58 sub uploadbranch () { return "$branchprefix/$suite"; }
  59 sub lref ($) { return "refs/heads/$_[0]"; }
  60 sub rref ($) { return "refs/remotes/$remotename/$_[0]"; }
  61 sub debiantag ($) { return "debian/$_[0]"; }
  62
  63 our $ua;
  64
  65 sub url_get {
  66     if (!$ua) {
  67         $ua = LWP::UserAgent->new();
  68         $ua->env_proxy;
  69     }
  70     print DEBUG "fetching @_...\n";
  71     my $r = $ua->get(@_) or die $!;
  72     die "$_[0]: ".$r->status_line."; failed.\n" unless $r->is_success;
  73     return $r->decoded_content();
  74 }
  75
  76 our ($dscdata,$dscurl,$dsc);
  77
  78 sub runcmd {
  79     $!=0; $?=0;
  80     die "@_ $! $?" if system @_;
  81 }
  82
  83 sub cmdoutput_errok {
  84     open P, "-|", @_ or die $!;
  85     my $d;
  86     $!=0; $?=0;
  87     { local $/ = undef; $d = <P>; }
  88     die if P->error;
  89     close P or return undef;
  90     chomp $d;
  91     return $d;
  92 }
  93
  94 sub cmdoutput {
  95     my $d = cmdoutput_errok @_;
  96     defined $d or die "@_ $? $!";
  97     return $d;
  98 }
  99
 100 sub dryrun_report {
 101     print "#" or die $!;
 102     local $_;
 103     foreach my $a (@_) {
 104         $_ = $a;
 105         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
 106             print " '$_'" or die $!;
 107         } else {
 108             print " $_" or die $!;
 109         }
 110     }
 111     print "\n" or die $!;
 112 }
 113
 114 sub runcmd_ordryrun {
 115     if (!$dryrun) {
 116         runcmd @_;
 117     } else {
 118         dryrun_report @_;
 119     }
 120 }
 121
 122 sub parsecontrol {
 123     my $c = Dpkg::Control::Hash->new();
 124     $c->load(@_) or return undef;
 125     return $c;
 126 }
 127
 128 sub parsechangelog {
 129     my $c = Dpkg::Control::Hash->new();
 130     my $p = new IO::Handle;
 131     open $p, '-|', qw(dpkg-parsechangelog) or die $!;
 132     $c->parse($p);
 133     $?=0; $!=0; close $p or die "$! $?";
 134     return $c;
 135 }
 136
 137 sub get_archive_dsc () {
 138     my $rmad = cmdoutput qw(rmadison -asource),"-s$suite",$package;
 139     $rmad =~ m/^ \s*( [^ \t|]+ )\s* \|
 140                  \s*( [^ \t|]+ )\s* \|
 141                  \s*( [^ \t|]+ )\s* \|
 142                  \s*( [^ \t|]+ )\s* /x or die "$rmad $?";
 143     $1 eq $package or die "$rmad $package ?";
 144     my $vsn = $2;
 145     $3 eq $suite or die "$rmad $suite ?";
 146     $4 eq 'source' or die "$rmad ?";
 147     # fixme it does not show us the component ?
 148     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 149     $dscurl = "$mirror/pool/main/$prefix/$package/${package}_$vsn.dsc";
 150 #print DEBUG Dumper($pdodata, $&, $dscurl);
 151     $dscdata = url_get($dscurl);
 152     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 153 #print DEBUG Dumper($dscdata, $dscfh);
 154     $dsc = Dpkg::Control::Hash->new(allow_pgp=>1);
 155     $dsc->parse($dscfh, 'dsc') or die "parsing of $dscurl failed\n";
 156 #print DEBUG Dumper($dsc);
 157     my $fmt = $dsc->{Format};
 158     die "unsupported format $fmt, sorry\n" unless $fmt eq '1.0';
 159 }
 160
 161 sub check_for_git () {
 162     # returns 0 or 1
 163     my $cmd=
 164         "ssh $alioth_sshtestbodge->[0] '".
 165         " set -e; cd $aliothpath;".
 166         " if test -d $package.git; then echo 1; else echo 0; fi".
 167         "'";
 168     #print DEBUG "$cmd\n";
 169     open P, "$cmd |" or die $!;
 170     $!=0; $?=0;
 171     my $r = <P>; close P;
 172 #print STDERR ">$r<\n";
 173     die "$r $! $?" unless $r =~ m/^[01]$/;
 174     return $r+0;
 175 }
 176
 177 our ($dsc_hash,$upload_hash);
 178
 179 our $ud = '.git/dgit/unpack';
 180
 181 sub prep_ud () {
 182     rmtree($ud);
 183     mkpath '.git/dgit';
 184     mkdir $ud or die $!;
 185 }
 186
 187 sub mktree_in_ud_from_only_subdir () {
 188     # changes into the subdir
 189     my (@dirs) = <*/.>;
 190     die unless @dirs==1;
 191     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 192     my $dir = $1;
 193     chdir $dir or die "$dir $!";
 194     die if stat '.git';
 195     die $! unless $!==&ENOENT;
 196     runcmd qw(git init -q);
 197     rmtree('.git/objects');
 198     symlink '../../../../objects','.git/objects' or die $!;
 199     runcmd @git, qw(add -Af);
 200     my $tree = cmdoutput @git, qw(write-tree);
 201     chomp $tree; $tree =~ m/^\w+$/ or die "$tree ?";
 202     return ($tree,$dir);
 203 }
 204
 205 sub dsc_files () {
 206     map {
 207         m/^\w+ \d+ (\S+)$/ or die "$_ ?";
 208         $1;
 209     } grep m/\S/, split /\n/, ($dsc->{'Checksums-Sha256'} || $dsc->{Files});
 210 }
 211
 212 sub is_orig_file ($) {
 213     local ($_) = @_;
 214     m/\.orig\.tar\.\w+$/;
 215 }
 216
 217 sub generate_commit_from_dsc () {
 218     prep_ud();
 219     chdir $ud or die $!;
 220     my @files;
 221     foreach my $f (dsc_files()) {
 222         die if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 223         push @files, $f;
 224         link "../../../$f", $f
 225             or $!==&ENOENT
 226             or die "$f $!";
 227     }
 228     runcmd @dget, qw(--), $dscurl;
 229     foreach my $f (grep { is_orig_file($_) } @files) {
 230         link $f, "../../../../$f"
 231             or $!==&EEXIST
 232             or die "$f $!";
 233     }
 234     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 235     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 236     my $clogp = parsecontrol('../changelog.tmp','changelog') or die;
 237     my $date = cmdoutput qw(date), '+%s %z', qw(-d),$clogp->{Date};
 238     my $author = $clogp->{Maintainer};
 239     $author =~ s#,.*##ms;
 240     my $authline = "$author $date";
 241     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or die $authline;
 242     open C, ">../commit.tmp" or die $!;
 243     print C "tree $tree\n" or die $!;
 244     print C "parent $upload_hash\n" or die $! if $upload_hash;
 245     print C <<END or die $!;
 246 author $authline
 247 committer $authline
 248
 249 $clogp->{Changes}
 250
 251 # imported by dgit from the archive
 252 END
 253     close C or die $!;
 254     print "synthesised git commit from .dsc $clogp->{Version}\n";
 255     my $commithash = cmdoutput @git, qw(hash-object -w -t commit ../commit.tmp);
 256     chdir '../../../..' or die $!;
 257     cmdoutput @git, qw(update-ref -m),"dgit synthesise $clogp->{Version}",
 258               'DGIT_ARCHIVE', $commithash;
 259     cmdoutput @git, qw(log -n2), $commithash;
 260     # ... gives git a chance to complain if our commit is malformed
 261     my $outputhash = $commithash;
 262     if ($upload_hash) {
 263         chdir "$ud/$dir" or die $!;
 264         runcmd @git, qw(reset --hard), $upload_hash;
 265         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 266         my $oldclogp = Dpkg::Control::Hash->new();
 267         $oldclogp->parse('../changelogold.tmp','previous changelog') or die;
 268         my $vcmp =
 269             version_compare_string($oldclogp->{Version}, $clogp->{Version});
 270         if ($vcmp < 0) {
 271             # git upload/ is earlier vsn than archive, use archive
 272         } elsif ($vcmp >= 0) {
 273             print STDERR <<END or die $!;
 274 Version actually in archive:    $clogp->{Version} (older)
 275 Last allegedly pushed/uploaded: $oldclogp->{Version} (newer or same)
 276 Perhaps the upload is stuck in incoming.  Using the version from git.
 277 END
 278         } else {
 279             die "version in archive is same as version in git".
 280                 " to-be-uploaded (upload/) branch but archive".
 281                 " version hash no commit hash?!\n";
 282         }
 283         chdir '../../../..' or die $!;
 284     }
 285     rmtree($ud);
 286     return $outputhash;
 287 }
 288
 289 sub ensure_we_have_orig () {
 290     foreach my $f (dsc_files()) {
 291         next unless is_orig_file($f);
 292         if (stat "../$f") {
 293             die "$f ?" unless -f _;
 294         } else {
 295             die "$f $!" unless $!==&ENOENT;
 296         }
 297         my $origurl = $dscurl;
 298         $origurl =~ s{/[^/]+$}{};
 299         $origurl .= "/$f";
 300         die "$f ?" unless $f =~ m/^${package}_/;
 301         die "$f ?" if $f =~ m#/#;
 302         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 303             @dget,'--',$origurl;
 304     }
 305 }
 306
 307 sub rev_parse ($) {
 308     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 309 }
 310
 311 sub is_fast_fwd ($$) {
 312     my ($ancestor,$child) = @_;
 313     my $mb = cmdoutput @git, qw(merge-base), $dsc_hash, $upload_hash;
 314     return rev_parse($mb) eq rev_parse($ancestor);
 315 }
 316
 317 sub fetch_from_archive () {
 318     # ensures that rref(uploadbranch()) is what is actually in the archive,
 319     #  one way or another
 320     my $upload_ref = rref(uploadbranch());
 321     $!=0; $upload_hash =
 322         cmdoutput_errok @git, qw(show-ref --heads), $upload_ref;
 323     die $! if $!;
 324     die $? unless ($?==0 && chomp $upload_hash)
 325         or ($?==256 && !length $upload_hash);
 326     $upload_hash ||= '';
 327     my $hash;
 328     if (defined $dsc_hash) {
 329         die "missing git history even though dsc has hash"
 330             unless $upload_hash;
 331         $hash = $dsc_hash;
 332         ensure_we_have_orig();
 333     } else {
 334         $hash = generate_commit_from_dsc();
 335     }
 336     if ($upload_hash) {
 337         die "not fast forward on last upload branch!".
 338             " (archive's version left in DGIT_ARCHIVE)"
 339             unless is_fast_fwd($dsc_hash, $upload_hash);
 340     }
 341     if ($upload_hash ne $hash) {
 342         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', $upload_ref, $hash);
 343         if (!$dryrun) {
 344             cmdoutput @upd_cmd;
 345         } else {
 346             dryrun_report @upd_cmd;
 347         }
 348     }
 349 }
 350
 351 sub clone () {
 352     die "dry run makes no sense with clone" if $dryrun;
 353     get_archive_dsc();
 354     $dsc_hash = $dsc->{$ourdscfield};
 355     if (defined $dsc_hash) {
 356         $dsc_hash =~ m/\w+/ or die "$dsc_hash $?";
 357         $dsc_hash = $&;
 358         print "last upload to archive specified git hash\n";
 359     } else {
 360         print "last upload to archive has NO git hash\n";
 361     }
 362     my $dstdir = "$package";
 363     my $branch = uploadbranch();
 364     if (check_for_git()) {
 365         print "cloning existing git history\n";
 366         runcmd @git, qw(clone --origin),$remotename, qw(-b), $branch, '--',
 367             "$alioth_git/$package.git", $dstdir;
 368         chdir "$dstdir" or die "$dstdir $!";
 369         fetch_from_archive();
 370         runcmd @git, qw(reset --hard), rref(uploadbranch());
 371     } else {
 372         print "starting new git history\n";
 373         mkdir $dstdir or die "$dstdir $!";
 374         chdir "$dstdir" or die "$dstdir $!";
 375         runcmd @git, qw(init -q);
 376         open H, "> .git/HEAD" or die $!;
 377         print H "ref: ".lref(uploadbranch())."\n" or die $!;
 378         close H or die $!;
 379         runcmd @git, qw(remote add), $remotename, "$alioth_git/$package.git";
 380         runcmd "git config branch.$branch.remote $remotename";
 381         runcmd "git config branch.$branch.merge ".lref(uploadbranch());
 382         my $newhash = generate_commit_from_dsc();
 383         runcmd @git, qw(reset --hard), $newhash;
 384     }
 385     print "ready for work in $dstdir\n";
 386 }
 387
 388 sub fetch () {
 389     get_archive_dsc();
 390     if (check_for_git()) {
 391         runcmd_ordryrun @git, qw(fetch -p),$remotename,
 392             '+refs/heads/*:refs/remotes/origin/*';
 393     }
 394     fetch_from_archive();
 395 }
 396
 397 sub pull () {
 398     fetch();
 399     runcmd_ordryrun @git, qw(merge -m),"Merge from $suite [dgit]",
 400         lref(uploadbranch());
 401 }
 402
 403 sub dopush () {
 404     runcmd @git, qw(diff --quiet HEAD);
 405     my $clogp = parsechangelog();
 406     $package = $clogp->{Source};
 407     my $dscfn = "${package}_$clogp->{Version}.dsc";
 408     stat "../$dscfn" or die "$dscfn $!";
 409     $dsc = parsecontrol("../$dscfn");
 410     prep_ud();
 411     chdir $ud or die $!;
 412     print "checking that $dscfn corresponds to HEAD\n";
 413     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 414     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 415     chdir '../../../..' or die $!;
 416     runcmd @git, qw(diff --exit-code), $tree;
 417 #fetch from alioth
 418 #do fast forward check and maybe fake merge
 419 #    if (!is_fast_fwd(mainbranch
 420 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 421 #        map { lref($_).":".rref($_) }
 422 #        (uploadbranch());
 423     $dsc->{$ourdscfield} = rev_parse('HEAD');
 424     $dsc->save("../$dscfn.tmp") or die $!;
 425     rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 426     if (!$changesfile) {
 427         my $pat = "../${package}_$clogp->{Version}_*.changes";
 428         my @cs = glob $pat;
 429         die "$pat ?" unless @cs==1;
 430         ($changesfile) = @cs;
 431     }
 432     if ($sign) {
 433         my @tag_cmd = (@git, qw(tag -s -m),
 434                        "Release $dsc->{Version} for $suite [dgit]");
 435         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 436         runcmd_ordryrun @tag_cmd;
 437         my @debsign_cmd = @debsign;
 438         push @debsign_cmd, "-k$keyid" if defined $keyid;
 439         push @debsign_cmd, $changesfile;
 440         runcmd_ordryrun @debsign_cmd;
 441     }
 442     runcmd_ordryrun @git, qw(push),$remotename,"HEAD:".lref(uploadbranch());
 443     runcmd_ordryrun @dput, $changesfile;
 444 }
 445
 446 sub cmd_clone {
 447     if (@ARGV==1) {
 448         ($package) = @ARGV;
 449     } elsif (@ARGV==2) {
 450         ($package,$suite) = @ARGV;
 451     } else {
 452         die;
 453     }
 454     clone();
 455 }
 456
 457 sub branchsuite () {
 458     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 459     chomp $branch;
 460     if ($branch =~ m#^refs/heads/$branchprefix/([^/.]+)$#o) {
 461         return $1;
 462     } else {
 463         return undef;
 464     }
 465 }
 466
 467 sub fetchpullargs () {
 468     my $clogp = parsechangelog();
 469     $package = $clogp->{Source};
 470     if (@ARGV==0) {
 471         $suite = branchsuite();
 472         $suite ||= $clogp->{Distribution};
 473         print "fetching from suite $suite\n";
 474     } elsif (@ARGV==1) {
 475         ($suite) = @ARGV;
 476     } else {
 477         die;
 478     }
 479 }
 480
 481 sub cmd_fetch {
 482     fetchpullargs();
 483     fetch();
 484 }
 485
 486 sub cmd_pull {
 487     fetchpullargs();
 488     pull();
 489 }
 490
 491 sub cmd_push {
 492     my $clogp = parsechangelog();
 493     $package = $clogp->{Source};
 494     if (@ARGV==0) {
 495         $suite = $clogp->{Distribution};
 496     } else {
 497         die;
 498     }
 499     dopush();
 500 }
 501
 502 sub cmd_build {
 503     my $clogp = parsechangelog();
 504     $suite = $clogp->{Distribution};
 505     runcmd_ordryrun
 506         qw(git-buildpackage -us -uc --git-no-sign-tags),
 507             "--git-debian-branch=".uploadbranch(),
 508             @ARGV;
 509 }
 510
 511 sub parseopts () {
 512     my $om;
 513     while (@ARGV) {
 514         last unless $ARGV[0] =~ m/^-/;
 515         $_ = shift @ARGV;
 516         last if m/^--?$/;
 517         if (m/^--/) {
 518             if (m/^--dry-run$/) {
 519                 $dryrun=1;
 520             } elsif (m/^--no-sign$/) {
 521                 $sign=0;
 522             } elsif (m/^--(\w+)=(.*)/s && ($om = $opts_opt_map{$1})) {
 523                 $om->[0] = $2;
 524             } elsif (m/^--(\w+):(.*)/s && ($om = $opts_opt_map{$1})) {
 525                 push @$om, $2;
 526             } else {
 527                 die "$_ ?";
 528             }
 529         } else {
 530             while (m/^-./s) {
 531                 if (s/^-n/-/) {
 532                     $dryrun=1;
 533                 } elsif (s/^-c(.*=.*)//s) {
 534                     push @git, $1;
 535                 } elsif (s/^-C(.*)//s) {
 536                     $changesfile = $1;
 537                 } elsif (s/^-k(.*)//s) {
 538                     $keyid=$1;
 539                 } else {
 540                     die "$_ ?";
 541                 }
 542             }
 543         }
 544     }
 545 }
 546
 547 parseopts();
 548 die unless @ARGV;
 549 my $cmd = shift @ARGV;
 550 parseopts();
 551
 552 { no strict qw(refs); &{"cmd_$cmd"}(); }