dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite = 'unstable';
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = qw(curl);
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146
 147 our $keyid;
 148
 149 autoflush STDOUT 1;
 150
 151 our $supplementary_message = '';
 152 our $need_split_build_invocation = 0;
 153 our $split_brain = 0;
 154
 155 END {
 156     local ($@, $?);
 157     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 158 }
 159
 160 our $remotename = 'dgit';
 161 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 162 our $csuite;
 163 our $instead_distro;
 164
 165 if (!defined $absurdity) {
 166     $absurdity = $0;
 167     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 168 }
 169
 170 sub debiantag ($$) {
 171     my ($v,$distro) = @_;
 172     return $tagformatfn->($v, $distro);
 173 }
 174
 175 sub debiantag_maintview ($$) {
 176     my ($v,$distro) = @_;
 177     return "$distro/".dep14_version_mangle $v;
 178 }
 179
 180 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 181
 182 sub lbranch () { return "$branchprefix/$csuite"; }
 183 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 184 sub lref () { return "refs/heads/".lbranch(); }
 185 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 186 sub rrref () { return server_ref($csuite); }
 187
 188 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 189 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
 190
 191 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
 192 # locally fetched refs because they have unhelpful names and clutter
 193 # up gitk etc.  So we track whether we have "used up" head ref (ie,
 194 # whether we have made another local ref which refers to this object).
 195 #
 196 # (If we deleted them unconditionally, then we might end up
 197 # re-fetching the same git objects each time dgit fetch was run.)
 198 #
 199 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
 200 # in git_fetch_us to fetch the refs in question, and possibly a call
 201 # to lrfetchref_used.
 202
 203 our (%lrfetchrefs_f, %lrfetchrefs_d);
 204 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
 205
 206 sub lrfetchref_used ($) {
 207     my ($fullrefname) = @_;
 208     my $objid = $lrfetchrefs_f{$fullrefname};
 209     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
 210 }
 211
 212 sub stripepoch ($) {
 213     my ($vsn) = @_;
 214     $vsn =~ s/^\d+\://;
 215     return $vsn;
 216 }
 217
 218 sub srcfn ($$) {
 219     my ($vsn,$sfx) = @_;
 220     return "${package}_".(stripepoch $vsn).$sfx
 221 }
 222
 223 sub dscfn ($) {
 224     my ($vsn) = @_;
 225     return srcfn($vsn,".dsc");
 226 }
 227
 228 sub changespat ($;$) {
 229     my ($vsn, $arch) = @_;
 230     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 231 }
 232
 233 sub upstreamversion ($) {
 234     my ($vsn) = @_;
 235     $vsn =~ s/-[^-]+$//;
 236     return $vsn;
 237 }
 238
 239 our $us = 'dgit';
 240 initdebug('');
 241
 242 our @end;
 243 END {
 244     local ($?);
 245     foreach my $f (@end) {
 246         eval { $f->(); };
 247         print STDERR "$us: cleanup: $@" if length $@;
 248     }
 249 };
 250
 251 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 252
 253 sub forceable_fail ($$) {
 254     my ($forceoptsl, $msg) = @_;
 255     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 256     print STDERR "warning: overriding problem due to --force:\n". $msg;
 257 }
 258
 259 sub forceing ($) {
 260     my ($forceoptsl) = @_;
 261     my @got = grep { $forceopts{$_} } @$forceoptsl;
 262     return 0 unless @got;
 263     print STDERR
 264  "warning: skipping checks or functionality due to --force-$got[0]\n";
 265 }
 266
 267 sub no_such_package () {
 268     print STDERR "$us: package $package does not exist in suite $isuite\n";
 269     exit 4;
 270 }
 271
 272 sub changedir ($) {
 273     my ($newdir) = @_;
 274     printdebug "CD $newdir\n";
 275     chdir $newdir or confess "chdir: $newdir: $!";
 276 }
 277
 278 sub deliberately ($) {
 279     my ($enquiry) = @_;
 280     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 281 }
 282
 283 sub deliberately_not_fast_forward () {
 284     foreach (qw(not-fast-forward fresh-repo)) {
 285         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 286     }
 287 }
 288
 289 sub quiltmode_splitbrain () {
 290     $quilt_mode =~ m/gbp|dpm|unapplied/;
 291 }
 292
 293 sub opts_opt_multi_cmd {
 294     my @cmd;
 295     push @cmd, split /\s+/, shift @_;
 296     push @cmd, @_;
 297     @cmd;
 298 }
 299
 300 sub gbp_pq {
 301     return opts_opt_multi_cmd @gbp_pq;
 302 }
 303
 304 #---------- remote protocol support, common ----------
 305
 306 # remote push initiator/responder protocol:
 307 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 308 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 309 #  < dgit-remote-push-ready <actual-proto-vsn>
 310 #
 311 # occasionally:
 312 #
 313 #  > progress NBYTES
 314 #  [NBYTES message]
 315 #
 316 #  > supplementary-message NBYTES          # $protovsn >= 3
 317 #  [NBYTES message]
 318 #
 319 # main sequence:
 320 #
 321 #  > file parsed-changelog
 322 #  [indicates that output of dpkg-parsechangelog follows]
 323 #  > data-block NBYTES
 324 #  > [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  > data-end
 327 #
 328 #  > file dsc
 329 #  [etc]
 330 #
 331 #  > file changes
 332 #  [etc]
 333 #
 334 #  > param head DGIT-VIEW-HEAD
 335 #  > param csuite SUITE
 336 #  > param tagformat old|new
 337 #  > param maint-view MAINT-VIEW-HEAD
 338 #
 339 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 340 #                                     # goes into tag, for replay prevention
 341 #
 342 #  > want signed-tag
 343 #  [indicates that signed tag is wanted]
 344 #  < data-block NBYTES
 345 #  < [NBYTES bytes of data (no newline)]
 346 #  [maybe some more blocks]
 347 #  < data-end
 348 #  < files-end
 349 #
 350 #  > want signed-dsc-changes
 351 #  < data-block NBYTES    [transfer of signed dsc]
 352 #  [etc]
 353 #  < data-block NBYTES    [transfer of signed changes]
 354 #  [etc]
 355 #  < files-end
 356 #
 357 #  > complete
 358
 359 our $i_child_pid;
 360
 361 sub i_child_report () {
 362     # Sees if our child has died, and reap it if so.  Returns a string
 363     # describing how it died if it failed, or undef otherwise.
 364     return undef unless $i_child_pid;
 365     my $got = waitpid $i_child_pid, WNOHANG;
 366     return undef if $got <= 0;
 367     die unless $got == $i_child_pid;
 368     $i_child_pid = undef;
 369     return undef unless $?;
 370     return "build host child ".waitstatusmsg();
 371 }
 372
 373 sub badproto ($$) {
 374     my ($fh, $m) = @_;
 375     fail "connection lost: $!" if $fh->error;
 376     fail "protocol violation; $m not expected";
 377 }
 378
 379 sub badproto_badread ($$) {
 380     my ($fh, $wh) = @_;
 381     fail "connection lost: $!" if $!;
 382     my $report = i_child_report();
 383     fail $report if defined $report;
 384     badproto $fh, "eof (reading $wh)";
 385 }
 386
 387 sub protocol_expect (&$) {
 388     my ($match, $fh) = @_;
 389     local $_;
 390     $_ = <$fh>;
 391     defined && chomp or badproto_badread $fh, "protocol message";
 392     if (wantarray) {
 393         my @r = &$match;
 394         return @r if @r;
 395     } else {
 396         my $r = &$match;
 397         return $r if $r;
 398     }
 399     badproto $fh, "\`$_'";
 400 }
 401
 402 sub protocol_send_file ($$) {
 403     my ($fh, $ourfn) = @_;
 404     open PF, "<", $ourfn or die "$ourfn: $!";
 405     for (;;) {
 406         my $d;
 407         my $got = read PF, $d, 65536;
 408         die "$ourfn: $!" unless defined $got;
 409         last if !$got;
 410         print $fh "data-block ".length($d)."\n" or die $!;
 411         print $fh $d or die $!;
 412     }
 413     PF->error and die "$ourfn $!";
 414     print $fh "data-end\n" or die $!;
 415     close PF;
 416 }
 417
 418 sub protocol_read_bytes ($$) {
 419     my ($fh, $nbytes) = @_;
 420     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 421     my $d;
 422     my $got = read $fh, $d, $nbytes;
 423     $got==$nbytes or badproto_badread $fh, "data block";
 424     return $d;
 425 }
 426
 427 sub protocol_receive_file ($$) {
 428     my ($fh, $ourfn) = @_;
 429     printdebug "() $ourfn\n";
 430     open PF, ">", $ourfn or die "$ourfn: $!";
 431     for (;;) {
 432         my ($y,$l) = protocol_expect {
 433             m/^data-block (.*)$/ ? (1,$1) :
 434             m/^data-end$/ ? (0,) :
 435             ();
 436         } $fh;
 437         last unless $y;
 438         my $d = protocol_read_bytes $fh, $l;
 439         print PF $d or die $!;
 440     }
 441     close PF or die $!;
 442 }
 443
 444 #---------- remote protocol support, responder ----------
 445
 446 sub responder_send_command ($) {
 447     my ($command) = @_;
 448     return unless $we_are_responder;
 449     # called even without $we_are_responder
 450     printdebug ">> $command\n";
 451     print PO $command, "\n" or die $!;
 452 }
 453
 454 sub responder_send_file ($$) {
 455     my ($keyword, $ourfn) = @_;
 456     return unless $we_are_responder;
 457     printdebug "]] $keyword $ourfn\n";
 458     responder_send_command "file $keyword";
 459     protocol_send_file \*PO, $ourfn;
 460 }
 461
 462 sub responder_receive_files ($@) {
 463     my ($keyword, @ourfns) = @_;
 464     die unless $we_are_responder;
 465     printdebug "[[ $keyword @ourfns\n";
 466     responder_send_command "want $keyword";
 467     foreach my $fn (@ourfns) {
 468         protocol_receive_file \*PI, $fn;
 469     }
 470     printdebug "[[\$\n";
 471     protocol_expect { m/^files-end$/ } \*PI;
 472 }
 473
 474 #---------- remote protocol support, initiator ----------
 475
 476 sub initiator_expect (&) {
 477     my ($match) = @_;
 478     protocol_expect { &$match } \*RO;
 479 }
 480
 481 #---------- end remote code ----------
 482
 483 sub progress {
 484     if ($we_are_responder) {
 485         my $m = join '', @_;
 486         responder_send_command "progress ".length($m) or die $!;
 487         print PO $m or die $!;
 488     } else {
 489         print @_, "\n";
 490     }
 491 }
 492
 493 our $ua;
 494
 495 sub url_get {
 496     if (!$ua) {
 497         $ua = LWP::UserAgent->new();
 498         $ua->env_proxy;
 499     }
 500     my $what = $_[$#_];
 501     progress "downloading $what...";
 502     my $r = $ua->get(@_) or die $!;
 503     return undef if $r->code == 404;
 504     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 505     return $r->decoded_content(charset => 'none');
 506 }
 507
 508 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 509
 510 sub runcmd {
 511     debugcmd "+",@_;
 512     $!=0; $?=-1;
 513     failedcmd @_ if system @_;
 514 }
 515
 516 sub act_local () { return $dryrun_level <= 1; }
 517 sub act_scary () { return !$dryrun_level; }
 518
 519 sub printdone {
 520     if (!$dryrun_level) {
 521         progress "$us ok: @_";
 522     } else {
 523         progress "would be ok: @_ (but dry run only)";
 524     }
 525 }
 526
 527 sub dryrun_report {
 528     printcmd(\*STDERR,$debugprefix."#",@_);
 529 }
 530
 531 sub runcmd_ordryrun {
 532     if (act_scary()) {
 533         runcmd @_;
 534     } else {
 535         dryrun_report @_;
 536     }
 537 }
 538
 539 sub runcmd_ordryrun_local {
 540     if (act_local()) {
 541         runcmd @_;
 542     } else {
 543         dryrun_report @_;
 544     }
 545 }
 546
 547 sub shell_cmd {
 548     my ($first_shell, @cmd) = @_;
 549     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 550 }
 551
 552 our $helpmsg = <<END;
 553 main usages:
 554   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 555   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 556   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 557   dgit [dgit-opts] sbuild [sbuild-opts]
 558   dgit [dgit-opts] push [dgit-opts] [suite]
 559   dgit [dgit-opts] rpush build-host:build-dir ...
 560 important dgit options:
 561   -k<keyid>           sign tag and package with <keyid> instead of default
 562   --dry-run -n        do not change anything, but go through the motions
 563   --damp-run -L       like --dry-run but make local changes, without signing
 564   --new -N            allow introducing a new package
 565   --debug -D          increase debug level
 566   -c<name>=<value>    set git config option (used directly by dgit too)
 567 END
 568
 569 our $later_warning_msg = <<END;
 570 Perhaps the upload is stuck in incoming.  Using the version from git.
 571 END
 572
 573 sub badusage {
 574     print STDERR "$us: @_\n", $helpmsg or die $!;
 575     exit 8;
 576 }
 577
 578 sub nextarg {
 579     @ARGV or badusage "too few arguments";
 580     return scalar shift @ARGV;
 581 }
 582
 583 sub cmd_help () {
 584     print $helpmsg or die $!;
 585     exit 0;
 586 }
 587
 588 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 589
 590 our %defcfg = ('dgit.default.distro' => 'debian',
 591                'dgit-suite.*-security.distro' => 'debian-security',
 592                'dgit.default.username' => '',
 593                'dgit.default.archive-query-default-component' => 'main',
 594                'dgit.default.ssh' => 'ssh',
 595                'dgit.default.archive-query' => 'madison:',
 596                'dgit.default.sshpsql-dbname' => 'service=projectb',
 597                'dgit.default.aptget-components' => 'main',
 598                'dgit.default.dgit-tag-format' => 'new,old,maint',
 599                # old means "repo server accepts pushes with old dgit tags"
 600                # new means "repo server accepts pushes with new dgit tags"
 601                # maint means "repo server accepts split brain pushes"
 602                # hist means "repo server may have old pushes without new tag"
 603                #   ("hist" is implied by "old")
 604                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 605                'dgit-distro.debian.git-check' => 'url',
 606                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 607                'dgit-distro.debian.new-private-pushers' => 't',
 608                'dgit-distro.debian/push.git-url' => '',
 609                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 610                'dgit-distro.debian/push.git-user-force' => 'dgit',
 611                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 612                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 613                'dgit-distro.debian/push.git-create' => 'true',
 614                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 615  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 616 # 'dgit-distro.debian.archive-query-tls-key',
 617 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 618 # ^ this does not work because curl is broken nowadays
 619 # Fixing #790093 properly will involve providing providing the key
 620 # in some pacagke and maybe updating these paths.
 621 #
 622 # 'dgit-distro.debian.archive-query-tls-curl-args',
 623 #   '--ca-path=/etc/ssl/ca-debian',
 624 # ^ this is a workaround but works (only) on DSA-administered machines
 625                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 626                'dgit-distro.debian.git-url-suffix' => '',
 627                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 628                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 629  'dgit-distro.debian-security.archive-query' => 'aptget:',
 630  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 631  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 632  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 633  'dgit-distro.debian-security.nominal-distro' => 'debian',
 634  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 635  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 636                'dgit-distro.ubuntu.git-check' => 'false',
 637  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 638                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 639                'dgit-distro.test-dummy.username' => "alice",
 640                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 641                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 642                'dgit-distro.test-dummy.git-url' => "$td/git",
 643                'dgit-distro.test-dummy.git-host' => "git",
 644                'dgit-distro.test-dummy.git-path' => "$td/git",
 645                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 646                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 647                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 648                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 649                );
 650
 651 our %gitcfgs;
 652 our @gitcfgsources = qw(cmdline local global system);
 653
 654 sub git_slurp_config () {
 655     local ($debuglevel) = $debuglevel-2;
 656     local $/="\0";
 657
 658     # This algoritm is a bit subtle, but this is needed so that for
 659     # options which we want to be single-valued, we allow the
 660     # different config sources to override properly.  See #835858.
 661     foreach my $src (@gitcfgsources) {
 662         next if $src eq 'cmdline';
 663         # we do this ourselves since git doesn't handle it
 664
 665         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 666         debugcmd "|",@cmd;
 667
 668         open GITS, "-|", @cmd or die $!;
 669         while (<GITS>) {
 670             chomp or die;
 671             printdebug "=> ", (messagequote $_), "\n";
 672             m/\n/ or die "$_ ?";
 673             push @{ $gitcfgs{$src}{$`} }, $'; #';
 674         }
 675         $!=0; $?=0;
 676         close GITS
 677             or ($!==0 && $?==256)
 678             or failedcmd @cmd;
 679     }
 680 }
 681
 682 sub git_get_config ($) {
 683     my ($c) = @_;
 684     foreach my $src (@gitcfgsources) {
 685         my $l = $gitcfgs{$src}{$c};
 686         printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 687             if $debuglevel >= 4;
 688         $l or next;
 689         @$l==1 or badcfg "multiple values for $c".
 690             " (in $src git config)" if @$l > 1;
 691         return $l->[0];
 692     }
 693     return undef;
 694 }
 695
 696 sub cfg {
 697     foreach my $c (@_) {
 698         return undef if $c =~ /RETURN-UNDEF/;
 699         my $v = git_get_config($c);
 700         return $v if defined $v;
 701         my $dv = $defcfg{$c};
 702         return $dv if defined $dv;
 703     }
 704     badcfg "need value for one of: @_\n".
 705         "$us: distro or suite appears not to be (properly) supported";
 706 }
 707
 708 sub access_basedistro () {
 709     if (defined $idistro) {
 710         return $idistro;
 711     } else {
 712         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 713         return $def if defined $def;
 714         foreach my $src (@gitcfgsources, 'internal') {
 715             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 716             next unless $kl;
 717             foreach my $k (keys %$kl) {
 718                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 719                 my $dpat = $1;
 720                 next unless match_glob $dpat, $isuite;
 721                 return $kl->{$k};
 722             }
 723         }
 724         return cfg("dgit.default.distro");
 725     }
 726 }
 727
 728 sub access_nomdistro () {
 729     my $base = access_basedistro();
 730     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 731     $r =~ m/^$distro_re$/ or badcfg
 732  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 733     return $r;
 734 }
 735
 736 sub access_quirk () {
 737     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 738     my $basedistro = access_basedistro();
 739     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 740                               'RETURN-UNDEF');
 741     if (defined $backports_quirk) {
 742         my $re = $backports_quirk;
 743         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 744         $re =~ s/\*/.*/g;
 745         $re =~ s/\%/([-0-9a-z_]+)/
 746             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 747         if ($isuite =~ m/^$re$/) {
 748             return ('backports',"$basedistro-backports",$1);
 749         }
 750     }
 751     return ('none',undef);
 752 }
 753
 754 our $access_forpush;
 755
 756 sub parse_cfg_bool ($$$) {
 757     my ($what,$def,$v) = @_;
 758     $v //= $def;
 759     return
 760         $v =~ m/^[ty1]/ ? 1 :
 761         $v =~ m/^[fn0]/ ? 0 :
 762         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 763 }
 764
 765 sub access_forpush_config () {
 766     my $d = access_basedistro();
 767
 768     return 1 if
 769         $new_package &&
 770         parse_cfg_bool('new-private-pushers', 0,
 771                        cfg("dgit-distro.$d.new-private-pushers",
 772                            'RETURN-UNDEF'));
 773
 774     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 775     $v //= 'a';
 776     return
 777         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 778         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 779         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 780         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 781 }
 782
 783 sub access_forpush () {
 784     $access_forpush //= access_forpush_config();
 785     return $access_forpush;
 786 }
 787
 788 sub pushing () {
 789     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 790     badcfg "pushing but distro is configured readonly"
 791         if access_forpush_config() eq '0';
 792     $access_forpush = 1;
 793     $supplementary_message = <<'END' unless $we_are_responder;
 794 Push failed, before we got started.
 795 You can retry the push, after fixing the problem, if you like.
 796 END
 797     parseopts_late_defaults();
 798 }
 799
 800 sub notpushing () {
 801     parseopts_late_defaults();
 802 }
 803
 804 sub supplementary_message ($) {
 805     my ($msg) = @_;
 806     if (!$we_are_responder) {
 807         $supplementary_message = $msg;
 808         return;
 809     } elsif ($protovsn >= 3) {
 810         responder_send_command "supplementary-message ".length($msg)
 811             or die $!;
 812         print PO $msg or die $!;
 813     }
 814 }
 815
 816 sub access_distros () {
 817     # Returns list of distros to try, in order
 818     #
 819     # We want to try:
 820     #    0. `instead of' distro name(s) we have been pointed to
 821     #    1. the access_quirk distro, if any
 822     #    2a. the user's specified distro, or failing that  } basedistro
 823     #    2b. the distro calculated from the suite          }
 824     my @l = access_basedistro();
 825
 826     my (undef,$quirkdistro) = access_quirk();
 827     unshift @l, $quirkdistro;
 828     unshift @l, $instead_distro;
 829     @l = grep { defined } @l;
 830
 831     push @l, access_nomdistro();
 832
 833     if (access_forpush()) {
 834         @l = map { ("$_/push", $_) } @l;
 835     }
 836     @l;
 837 }
 838
 839 sub access_cfg_cfgs (@) {
 840     my (@keys) = @_;
 841     my @cfgs;
 842     # The nesting of these loops determines the search order.  We put
 843     # the key loop on the outside so that we search all the distros
 844     # for each key, before going on to the next key.  That means that
 845     # if access_cfg is called with a more specific, and then a less
 846     # specific, key, an earlier distro can override the less specific
 847     # without necessarily overriding any more specific keys.  (If the
 848     # distro wants to override the more specific keys it can simply do
 849     # so; whereas if we did the loop the other way around, it would be
 850     # impossible to for an earlier distro to override a less specific
 851     # key but not the more specific ones without restating the unknown
 852     # values of the more specific keys.
 853     my @realkeys;
 854     my @rundef;
 855     # We have to deal with RETURN-UNDEF specially, so that we don't
 856     # terminate the search prematurely.
 857     foreach (@keys) {
 858         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 859         push @realkeys, $_
 860     }
 861     foreach my $d (access_distros()) {
 862         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 863     }
 864     push @cfgs, map { "dgit.default.$_" } @realkeys;
 865     push @cfgs, @rundef;
 866     return @cfgs;
 867 }
 868
 869 sub access_cfg (@) {
 870     my (@keys) = @_;
 871     my (@cfgs) = access_cfg_cfgs(@keys);
 872     my $value = cfg(@cfgs);
 873     return $value;
 874 }
 875
 876 sub access_cfg_bool ($$) {
 877     my ($def, @keys) = @_;
 878     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 879 }
 880
 881 sub string_to_ssh ($) {
 882     my ($spec) = @_;
 883     if ($spec =~ m/\s/) {
 884         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 885     } else {
 886         return ($spec);
 887     }
 888 }
 889
 890 sub access_cfg_ssh () {
 891     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 892     if (!defined $gitssh) {
 893         return @ssh;
 894     } else {
 895         return string_to_ssh $gitssh;
 896     }
 897 }
 898
 899 sub access_runeinfo ($) {
 900     my ($info) = @_;
 901     return ": dgit ".access_basedistro()." $info ;";
 902 }
 903
 904 sub access_someuserhost ($) {
 905     my ($some) = @_;
 906     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 907     defined($user) && length($user) or
 908         $user = access_cfg("$some-user",'username');
 909     my $host = access_cfg("$some-host");
 910     return length($user) ? "$user\@$host" : $host;
 911 }
 912
 913 sub access_gituserhost () {
 914     return access_someuserhost('git');
 915 }
 916
 917 sub access_giturl (;$) {
 918     my ($optional) = @_;
 919     my $url = access_cfg('git-url','RETURN-UNDEF');
 920     my $suffix;
 921     if (!length $url) {
 922         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 923         return undef unless defined $proto;
 924         $url =
 925             $proto.
 926             access_gituserhost().
 927             access_cfg('git-path');
 928     } else {
 929         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 930     }
 931     $suffix //= '.git';
 932     return "$url/$package$suffix";
 933 }
 934
 935 sub parsecontrolfh ($$;$) {
 936     my ($fh, $desc, $allowsigned) = @_;
 937     our $dpkgcontrolhash_noissigned;
 938     my $c;
 939     for (;;) {
 940         my %opts = ('name' => $desc);
 941         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 942         $c = Dpkg::Control::Hash->new(%opts);
 943         $c->parse($fh,$desc) or die "parsing of $desc failed";
 944         last if $allowsigned;
 945         last if $dpkgcontrolhash_noissigned;
 946         my $issigned= $c->get_option('is_pgp_signed');
 947         if (!defined $issigned) {
 948             $dpkgcontrolhash_noissigned= 1;
 949             seek $fh, 0,0 or die "seek $desc: $!";
 950         } elsif ($issigned) {
 951             fail "control file $desc is (already) PGP-signed. ".
 952                 " Note that dgit push needs to modify the .dsc and then".
 953                 " do the signature itself";
 954         } else {
 955             last;
 956         }
 957     }
 958     return $c;
 959 }
 960
 961 sub parsecontrol {
 962     my ($file, $desc, $allowsigned) = @_;
 963     my $fh = new IO::Handle;
 964     open $fh, '<', $file or die "$file: $!";
 965     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 966     $fh->error and die $!;
 967     close $fh;
 968     return $c;
 969 }
 970
 971 sub getfield ($$) {
 972     my ($dctrl,$field) = @_;
 973     my $v = $dctrl->{$field};
 974     return $v if defined $v;
 975     fail "missing field $field in ".$dctrl->get_option('name');
 976 }
 977
 978 sub parsechangelog {
 979     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 980     my $p = new IO::Handle;
 981     my @cmd = (qw(dpkg-parsechangelog), @_);
 982     open $p, '-|', @cmd or die $!;
 983     $c->parse($p);
 984     $?=0; $!=0; close $p or failedcmd @cmd;
 985     return $c;
 986 }
 987
 988 sub commit_getclogp ($) {
 989     # Returns the parsed changelog hashref for a particular commit
 990     my ($objid) = @_;
 991     our %commit_getclogp_memo;
 992     my $memo = $commit_getclogp_memo{$objid};
 993     return $memo if $memo;
 994     mkpath '.git/dgit';
 995     my $mclog = ".git/dgit/clog-$objid";
 996     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 997         "$objid:debian/changelog";
 998     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 999 }
1000
1001 sub must_getcwd () {
1002     my $d = getcwd();
1003     defined $d or fail "getcwd failed: $!";
1004     return $d;
1005 }
1006
1007 sub parse_dscdata () {
1008     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1009     printdebug Dumper($dscdata) if $debuglevel>1;
1010     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1011     printdebug Dumper($dsc) if $debuglevel>1;
1012 }
1013
1014 our %rmad;
1015
1016 sub archive_query ($;@) {
1017     my ($method) = shift @_;
1018     fail "this operation does not support multiple comma-separated suites"
1019         if $isuite =~ m/,/;
1020     my $query = access_cfg('archive-query','RETURN-UNDEF');
1021     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1022     my $proto = $1;
1023     my $data = $'; #';
1024     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1025 }
1026
1027 sub archive_query_prepend_mirror {
1028     my $m = access_cfg('mirror');
1029     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1030 }
1031
1032 sub pool_dsc_subpath ($$) {
1033     my ($vsn,$component) = @_; # $package is implict arg
1034     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1035     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1036 }
1037
1038 sub cfg_apply_map ($$$) {
1039     my ($varref, $what, $mapspec) = @_;
1040     return unless $mapspec;
1041
1042     printdebug "config $what EVAL{ $mapspec; }\n";
1043     $_ = $$varref;
1044     eval "package Dgit::Config; $mapspec;";
1045     die $@ if $@;
1046     $$varref = $_;
1047 }
1048
1049 #---------- `ftpmasterapi' archive query method (nascent) ----------
1050
1051 sub archive_api_query_cmd ($) {
1052     my ($subpath) = @_;
1053     my @cmd = (@curl, qw(-sS));
1054     my $url = access_cfg('archive-query-url');
1055     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1056         my $host = $1;
1057         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1058         foreach my $key (split /\:/, $keys) {
1059             $key =~ s/\%HOST\%/$host/g;
1060             if (!stat $key) {
1061                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1062                 next;
1063             }
1064             fail "config requested specific TLS key but do not know".
1065                 " how to get curl to use exactly that EE key ($key)";
1066 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1067 #           # Sadly the above line does not work because of changes
1068 #           # to gnutls.   The real fix for #790093 may involve
1069 #           # new curl options.
1070             last;
1071         }
1072         # Fixing #790093 properly will involve providing a value
1073         # for this on clients.
1074         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1075         push @cmd, split / /, $kargs if defined $kargs;
1076     }
1077     push @cmd, $url.$subpath;
1078     return @cmd;
1079 }
1080
1081 sub api_query ($$;$) {
1082     use JSON;
1083     my ($data, $subpath, $ok404) = @_;
1084     badcfg "ftpmasterapi archive query method takes no data part"
1085         if length $data;
1086     my @cmd = archive_api_query_cmd($subpath);
1087     my $url = $cmd[$#cmd];
1088     push @cmd, qw(-w %{http_code});
1089     my $json = cmdoutput @cmd;
1090     unless ($json =~ s/\d+\d+\d$//) {
1091         failedcmd_report_cmd undef, @cmd;
1092         fail "curl failed to print 3-digit HTTP code";
1093     }
1094     my $code = $&;
1095     return undef if $code eq '404' && $ok404;
1096     fail "fetch of $url gave HTTP code $code"
1097         unless $url =~ m#^file://# or $code =~ m/^2/;
1098     return decode_json($json);
1099 }
1100
1101 sub canonicalise_suite_ftpmasterapi {
1102     my ($proto,$data) = @_;
1103     my $suites = api_query($data, 'suites');
1104     my @matched;
1105     foreach my $entry (@$suites) {
1106         next unless grep {
1107             my $v = $entry->{$_};
1108             defined $v && $v eq $isuite;
1109         } qw(codename name);
1110         push @matched, $entry;
1111     }
1112     fail "unknown suite $isuite" unless @matched;
1113     my $cn;
1114     eval {
1115         @matched==1 or die "multiple matches for suite $isuite\n";
1116         $cn = "$matched[0]{codename}";
1117         defined $cn or die "suite $isuite info has no codename\n";
1118         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1119     };
1120     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1121         if length $@;
1122     return $cn;
1123 }
1124
1125 sub archive_query_ftpmasterapi {
1126     my ($proto,$data) = @_;
1127     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1128     my @rows;
1129     my $digester = Digest::SHA->new(256);
1130     foreach my $entry (@$info) {
1131         eval {
1132             my $vsn = "$entry->{version}";
1133             my ($ok,$msg) = version_check $vsn;
1134             die "bad version: $msg\n" unless $ok;
1135             my $component = "$entry->{component}";
1136             $component =~ m/^$component_re$/ or die "bad component";
1137             my $filename = "$entry->{filename}";
1138             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1139                 or die "bad filename";
1140             my $sha256sum = "$entry->{sha256sum}";
1141             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1142             push @rows, [ $vsn, "/pool/$component/$filename",
1143                           $digester, $sha256sum ];
1144         };
1145         die "bad ftpmaster api response: $@\n".Dumper($entry)
1146             if length $@;
1147     }
1148     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1149     return archive_query_prepend_mirror @rows;
1150 }
1151
1152 sub file_in_archive_ftpmasterapi {
1153     my ($proto,$data,$filename) = @_;
1154     my $pat = $filename;
1155     $pat =~ s/_/\\_/g;
1156     $pat = "%/$pat";
1157     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1158     my $info = api_query($data, "file_in_archive/$pat", 1);
1159 }
1160
1161 #---------- `aptget' archive query method ----------
1162
1163 our $aptget_base;
1164 our $aptget_releasefile;
1165 our $aptget_configpath;
1166
1167 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1168 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1169
1170 sub aptget_cache_clean {
1171     runcmd_ordryrun_local qw(sh -ec),
1172         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1173         'x', $aptget_base;
1174 }
1175
1176 sub aptget_lock_acquire () {
1177     my $lockfile = "$aptget_base/lock";
1178     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1179     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1180 }
1181
1182 sub aptget_prep ($) {
1183     my ($data) = @_;
1184     return if defined $aptget_base;
1185
1186     badcfg "aptget archive query method takes no data part"
1187         if length $data;
1188
1189     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1190
1191     ensuredir $cache;
1192     ensuredir "$cache/dgit";
1193     my $cachekey =
1194         access_cfg('aptget-cachekey','RETURN-UNDEF')
1195         // access_nomdistro();
1196
1197     $aptget_base = "$cache/dgit/aptget";
1198     ensuredir $aptget_base;
1199
1200     my $quoted_base = $aptget_base;
1201     die "$quoted_base contains bad chars, cannot continue"
1202         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1203
1204     ensuredir $aptget_base;
1205
1206     aptget_lock_acquire();
1207
1208     aptget_cache_clean();
1209
1210     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1211     my $sourceslist = "source.list#$cachekey";
1212
1213     my $aptsuites = $isuite;
1214     cfg_apply_map(\$aptsuites, 'suite map',
1215                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1216
1217     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1218     printf SRCS "deb-src %s %s %s\n",
1219         access_cfg('mirror'),
1220         $aptsuites,
1221         access_cfg('aptget-components')
1222         or die $!;
1223
1224     ensuredir "$aptget_base/cache";
1225     ensuredir "$aptget_base/lists";
1226
1227     open CONF, ">", $aptget_configpath or die $!;
1228     print CONF <<END;
1229 Debug::NoLocking "true";
1230 APT::Get::List-Cleanup "false";
1231 #clear APT::Update::Post-Invoke-Success;
1232 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1233 Dir::State::Lists "$quoted_base/lists";
1234 Dir::Etc::preferences "$quoted_base/preferences";
1235 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1236 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1237 END
1238
1239     foreach my $key (qw(
1240                         Dir::Cache
1241                         Dir::State
1242                         Dir::Cache::Archives
1243                         Dir::Etc::SourceParts
1244                         Dir::Etc::preferencesparts
1245                       )) {
1246         ensuredir "$aptget_base/$key";
1247         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1248     };
1249
1250     my $oldatime = (time // die $!) - 1;
1251     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1252         next unless stat_exists $oldlist;
1253         my ($mtime) = (stat _)[9];
1254         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1255     }
1256
1257     runcmd_ordryrun_local aptget_aptget(), qw(update);
1258
1259     my @releasefiles;
1260     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1261         next unless stat_exists $oldlist;
1262         my ($atime) = (stat _)[8];
1263         next if $atime == $oldatime;
1264         push @releasefiles, $oldlist;
1265     }
1266     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1267     @releasefiles = @inreleasefiles if @inreleasefiles;
1268     die "apt updated wrong number of Release files (@releasefiles), erk"
1269         unless @releasefiles == 1;
1270
1271     ($aptget_releasefile) = @releasefiles;
1272 }
1273
1274 sub canonicalise_suite_aptget {
1275     my ($proto,$data) = @_;
1276     aptget_prep($data);
1277
1278     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1279
1280     foreach my $name (qw(Codename Suite)) {
1281         my $val = $release->{$name};
1282         if (defined $val) {
1283             printdebug "release file $name: $val\n";
1284             $val =~ m/^$suite_re$/o or fail
1285  "Release file ($aptget_releasefile) specifies intolerable $name";
1286             cfg_apply_map(\$val, 'suite rmap',
1287                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1288             return $val
1289         }
1290     }
1291     return $isuite;
1292 }
1293
1294 sub archive_query_aptget {
1295     my ($proto,$data) = @_;
1296     aptget_prep($data);
1297
1298     ensuredir "$aptget_base/source";
1299     foreach my $old (<$aptget_base/source/*.dsc>) {
1300         unlink $old or die "$old: $!";
1301     }
1302
1303     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1304     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1305     # avoids apt-get source failing with ambiguous error code
1306
1307     runcmd_ordryrun_local
1308         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1309         aptget_aptget(), qw(--download-only --only-source source), $package;
1310
1311     my @dscs = <$aptget_base/source/*.dsc>;
1312     fail "apt-get source did not produce a .dsc" unless @dscs;
1313     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1314
1315     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1316
1317     use URI::Escape;
1318     my $uri = "file://". uri_escape $dscs[0];
1319     $uri =~ s{\%2f}{/}gi;
1320     return [ (getfield $pre_dsc, 'Version'), $uri ];
1321 }
1322
1323 #---------- `dummyapicat' archive query method ----------
1324
1325 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1326 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1327
1328 sub file_in_archive_dummycatapi ($$$) {
1329     my ($proto,$data,$filename) = @_;
1330     my $mirror = access_cfg('mirror');
1331     $mirror =~ s#^file://#/# or die "$mirror ?";
1332     my @out;
1333     my @cmd = (qw(sh -ec), '
1334             cd "$1"
1335             find -name "$2" -print0 |
1336             xargs -0r sha256sum
1337         ', qw(x), $mirror, $filename);
1338     debugcmd "-|", @cmd;
1339     open FIA, "-|", @cmd or die $!;
1340     while (<FIA>) {
1341         chomp or die;
1342         printdebug "| $_\n";
1343         m/^(\w+)  (\S+)$/ or die "$_ ?";
1344         push @out, { sha256sum => $1, filename => $2 };
1345     }
1346     close FIA or die failedcmd @cmd;
1347     return \@out;
1348 }
1349
1350 #---------- `madison' archive query method ----------
1351
1352 sub archive_query_madison {
1353     return archive_query_prepend_mirror
1354         map { [ @$_[0..1] ] } madison_get_parse(@_);
1355 }
1356
1357 sub madison_get_parse {
1358     my ($proto,$data) = @_;
1359     die unless $proto eq 'madison';
1360     if (!length $data) {
1361         $data= access_cfg('madison-distro','RETURN-UNDEF');
1362         $data //= access_basedistro();
1363     }
1364     $rmad{$proto,$data,$package} ||= cmdoutput
1365         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1366     my $rmad = $rmad{$proto,$data,$package};
1367
1368     my @out;
1369     foreach my $l (split /\n/, $rmad) {
1370         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1371                   \s*( [^ \t|]+ )\s* \|
1372                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1373                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1374         $1 eq $package or die "$rmad $package ?";
1375         my $vsn = $2;
1376         my $newsuite = $3;
1377         my $component;
1378         if (defined $4) {
1379             $component = $4;
1380         } else {
1381             $component = access_cfg('archive-query-default-component');
1382         }
1383         $5 eq 'source' or die "$rmad ?";
1384         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1385     }
1386     return sort { -version_compare($a->[0],$b->[0]); } @out;
1387 }
1388
1389 sub canonicalise_suite_madison {
1390     # madison canonicalises for us
1391     my @r = madison_get_parse(@_);
1392     @r or fail
1393         "unable to canonicalise suite using package $package".
1394         " which does not appear to exist in suite $isuite;".
1395         " --existing-package may help";
1396     return $r[0][2];
1397 }
1398
1399 sub file_in_archive_madison { return undef; }
1400
1401 #---------- `sshpsql' archive query method ----------
1402
1403 sub sshpsql ($$$) {
1404     my ($data,$runeinfo,$sql) = @_;
1405     if (!length $data) {
1406         $data= access_someuserhost('sshpsql').':'.
1407             access_cfg('sshpsql-dbname');
1408     }
1409     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1410     my ($userhost,$dbname) = ($`,$'); #';
1411     my @rows;
1412     my @cmd = (access_cfg_ssh, $userhost,
1413                access_runeinfo("ssh-psql $runeinfo").
1414                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1415                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1416     debugcmd "|",@cmd;
1417     open P, "-|", @cmd or die $!;
1418     while (<P>) {
1419         chomp or die;
1420         printdebug(">|$_|\n");
1421         push @rows, $_;
1422     }
1423     $!=0; $?=0; close P or failedcmd @cmd;
1424     @rows or die;
1425     my $nrows = pop @rows;
1426     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1427     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1428     @rows = map { [ split /\|/, $_ ] } @rows;
1429     my $ncols = scalar @{ shift @rows };
1430     die if grep { scalar @$_ != $ncols } @rows;
1431     return @rows;
1432 }
1433
1434 sub sql_injection_check {
1435     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1436 }
1437
1438 sub archive_query_sshpsql ($$) {
1439     my ($proto,$data) = @_;
1440     sql_injection_check $isuite, $package;
1441     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1442         SELECT source.version, component.name, files.filename, files.sha256sum
1443           FROM source
1444           JOIN src_associations ON source.id = src_associations.source
1445           JOIN suite ON suite.id = src_associations.suite
1446           JOIN dsc_files ON dsc_files.source = source.id
1447           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1448           JOIN component ON component.id = files_archive_map.component_id
1449           JOIN files ON files.id = dsc_files.file
1450          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1451            AND source.source='$package'
1452            AND files.filename LIKE '%.dsc';
1453 END
1454     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1455     my $digester = Digest::SHA->new(256);
1456     @rows = map {
1457         my ($vsn,$component,$filename,$sha256sum) = @$_;
1458         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1459     } @rows;
1460     return archive_query_prepend_mirror @rows;
1461 }
1462
1463 sub canonicalise_suite_sshpsql ($$) {
1464     my ($proto,$data) = @_;
1465     sql_injection_check $isuite;
1466     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1467         SELECT suite.codename
1468           FROM suite where suite_name='$isuite' or codename='$isuite';
1469 END
1470     @rows = map { $_->[0] } @rows;
1471     fail "unknown suite $isuite" unless @rows;
1472     die "ambiguous $isuite: @rows ?" if @rows>1;
1473     return $rows[0];
1474 }
1475
1476 sub file_in_archive_sshpsql ($$$) { return undef; }
1477
1478 #---------- `dummycat' archive query method ----------
1479
1480 sub canonicalise_suite_dummycat ($$) {
1481     my ($proto,$data) = @_;
1482     my $dpath = "$data/suite.$isuite";
1483     if (!open C, "<", $dpath) {
1484         $!==ENOENT or die "$dpath: $!";
1485         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1486         return $isuite;
1487     }
1488     $!=0; $_ = <C>;
1489     chomp or die "$dpath: $!";
1490     close C;
1491     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1492     return $_;
1493 }
1494
1495 sub archive_query_dummycat ($$) {
1496     my ($proto,$data) = @_;
1497     canonicalise_suite();
1498     my $dpath = "$data/package.$csuite.$package";
1499     if (!open C, "<", $dpath) {
1500         $!==ENOENT or die "$dpath: $!";
1501         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1502         return ();
1503     }
1504     my @rows;
1505     while (<C>) {
1506         next if m/^\#/;
1507         next unless m/\S/;
1508         die unless chomp;
1509         printdebug "dummycat query $csuite $package $dpath | $_\n";
1510         my @row = split /\s+/, $_;
1511         @row==2 or die "$dpath: $_ ?";
1512         push @rows, \@row;
1513     }
1514     C->error and die "$dpath: $!";
1515     close C;
1516     return archive_query_prepend_mirror
1517         sort { -version_compare($a->[0],$b->[0]); } @rows;
1518 }
1519
1520 sub file_in_archive_dummycat () { return undef; }
1521
1522 #---------- tag format handling ----------
1523
1524 sub access_cfg_tagformats () {
1525     split /\,/, access_cfg('dgit-tag-format');
1526 }
1527
1528 sub access_cfg_tagformats_can_splitbrain () {
1529     my %y = map { $_ => 1 } access_cfg_tagformats;
1530     foreach my $needtf (qw(new maint)) {
1531         next if $y{$needtf};
1532         return 0;
1533     }
1534     return 1;
1535 }
1536
1537 sub need_tagformat ($$) {
1538     my ($fmt, $why) = @_;
1539     fail "need to use tag format $fmt ($why) but also need".
1540         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1541         " - no way to proceed"
1542         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1543     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1544 }
1545
1546 sub select_tagformat () {
1547     # sets $tagformatfn
1548     return if $tagformatfn && !$tagformat_want;
1549     die 'bug' if $tagformatfn && $tagformat_want;
1550     # ... $tagformat_want assigned after previous select_tagformat
1551
1552     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1553     printdebug "select_tagformat supported @supported\n";
1554
1555     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1556     printdebug "select_tagformat specified @$tagformat_want\n";
1557
1558     my ($fmt,$why,$override) = @$tagformat_want;
1559
1560     fail "target distro supports tag formats @supported".
1561         " but have to use $fmt ($why)"
1562         unless $override
1563             or grep { $_ eq $fmt } @supported;
1564
1565     $tagformat_want = undef;
1566     $tagformat = $fmt;
1567     $tagformatfn = ${*::}{"debiantag_$fmt"};
1568
1569     fail "trying to use unknown tag format \`$fmt' ($why) !"
1570         unless $tagformatfn;
1571 }
1572
1573 #---------- archive query entrypoints and rest of program ----------
1574
1575 sub canonicalise_suite () {
1576     return if defined $csuite;
1577     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1578     $csuite = archive_query('canonicalise_suite');
1579     if ($isuite ne $csuite) {
1580         progress "canonical suite name for $isuite is $csuite";
1581     } else {
1582         progress "canonical suite name is $csuite";
1583     }
1584 }
1585
1586 sub get_archive_dsc () {
1587     canonicalise_suite();
1588     my @vsns = archive_query('archive_query');
1589     foreach my $vinfo (@vsns) {
1590         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1591         $dscurl = $vsn_dscurl;
1592         $dscdata = url_get($dscurl);
1593         if (!$dscdata) {
1594             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1595             next;
1596         }
1597         if ($digester) {
1598             $digester->reset();
1599             $digester->add($dscdata);
1600             my $got = $digester->hexdigest();
1601             $got eq $digest or
1602                 fail "$dscurl has hash $got but".
1603                     " archive told us to expect $digest";
1604         }
1605         parse_dscdata();
1606         my $fmt = getfield $dsc, 'Format';
1607         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1608             "unsupported source format $fmt, sorry";
1609
1610         $dsc_checked = !!$digester;
1611         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1612         return;
1613     }
1614     $dsc = undef;
1615     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1616 }
1617
1618 sub check_for_git ();
1619 sub check_for_git () {
1620     # returns 0 or 1
1621     my $how = access_cfg('git-check');
1622     if ($how eq 'ssh-cmd') {
1623         my @cmd =
1624             (access_cfg_ssh, access_gituserhost(),
1625              access_runeinfo("git-check $package").
1626              " set -e; cd ".access_cfg('git-path').";".
1627              " if test -d $package.git; then echo 1; else echo 0; fi");
1628         my $r= cmdoutput @cmd;
1629         if (defined $r and $r =~ m/^divert (\w+)$/) {
1630             my $divert=$1;
1631             my ($usedistro,) = access_distros();
1632             # NB that if we are pushing, $usedistro will be $distro/push
1633             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1634             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1635             progress "diverting to $divert (using config for $instead_distro)";
1636             return check_for_git();
1637         }
1638         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1639         return $r+0;
1640     } elsif ($how eq 'url') {
1641         my $prefix = access_cfg('git-check-url','git-url');
1642         my $suffix = access_cfg('git-check-suffix','git-suffix',
1643                                 'RETURN-UNDEF') // '.git';
1644         my $url = "$prefix/$package$suffix";
1645         my @cmd = (@curl, qw(-sS -I), $url);
1646         my $result = cmdoutput @cmd;
1647         $result =~ s/^\S+ 200 .*\n\r?\n//;
1648         # curl -sS -I with https_proxy prints
1649         # HTTP/1.0 200 Connection established
1650         $result =~ m/^\S+ (404|200) /s or
1651             fail "unexpected results from git check query - ".
1652                 Dumper($prefix, $result);
1653         my $code = $1;
1654         if ($code eq '404') {
1655             return 0;
1656         } elsif ($code eq '200') {
1657             return 1;
1658         } else {
1659             die;
1660         }
1661     } elsif ($how eq 'true') {
1662         return 1;
1663     } elsif ($how eq 'false') {
1664         return 0;
1665     } else {
1666         badcfg "unknown git-check \`$how'";
1667     }
1668 }
1669
1670 sub create_remote_git_repo () {
1671     my $how = access_cfg('git-create');
1672     if ($how eq 'ssh-cmd') {
1673         runcmd_ordryrun
1674             (access_cfg_ssh, access_gituserhost(),
1675              access_runeinfo("git-create $package").
1676              "set -e; cd ".access_cfg('git-path').";".
1677              " cp -a _template $package.git");
1678     } elsif ($how eq 'true') {
1679         # nothing to do
1680     } else {
1681         badcfg "unknown git-create \`$how'";
1682     }
1683 }
1684
1685 our ($dsc_hash,$lastpush_mergeinput);
1686
1687 our $ud = '.git/dgit/unpack';
1688
1689 sub prep_ud (;$) {
1690     my ($d) = @_;
1691     $d //= $ud;
1692     rmtree($d);
1693     mkpath '.git/dgit';
1694     mkdir $d or die $!;
1695 }
1696
1697 sub mktree_in_ud_here () {
1698     runcmd qw(git init -q);
1699     runcmd qw(git config gc.auto 0);
1700     rmtree('.git/objects');
1701     symlink '../../../../objects','.git/objects' or die $!;
1702 }
1703
1704 sub git_write_tree () {
1705     my $tree = cmdoutput @git, qw(write-tree);
1706     $tree =~ m/^\w+$/ or die "$tree ?";
1707     return $tree;
1708 }
1709
1710 sub git_add_write_tree () {
1711     runcmd @git, qw(add -Af .);
1712     return git_write_tree();
1713 }
1714
1715 sub remove_stray_gits ($) {
1716     my ($what) = @_;
1717     my @gitscmd = qw(find -name .git -prune -print0);
1718     debugcmd "|",@gitscmd;
1719     open GITS, "-|", @gitscmd or die $!;
1720     {
1721         local $/="\0";
1722         while (<GITS>) {
1723             chomp or die;
1724             print STDERR "$us: warning: removing from $what: ",
1725                 (messagequote $_), "\n";
1726             rmtree $_;
1727         }
1728     }
1729     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1730 }
1731
1732 sub mktree_in_ud_from_only_subdir ($;$) {
1733     my ($what,$raw) = @_;
1734
1735     # changes into the subdir
1736     my (@dirs) = <*/.>;
1737     die "expected one subdir but found @dirs ?" unless @dirs==1;
1738     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1739     my $dir = $1;
1740     changedir $dir;
1741
1742     remove_stray_gits($what);
1743     mktree_in_ud_here();
1744     if (!$raw) {
1745         my ($format, $fopts) = get_source_format();
1746         if (madformat($format)) {
1747             rmtree '.pc';
1748         }
1749     }
1750
1751     my $tree=git_add_write_tree();
1752     return ($tree,$dir);
1753 }
1754
1755 our @files_csum_info_fields =
1756     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1757      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1758      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1759
1760 sub dsc_files_info () {
1761     foreach my $csumi (@files_csum_info_fields) {
1762         my ($fname, $module, $method) = @$csumi;
1763         my $field = $dsc->{$fname};
1764         next unless defined $field;
1765         eval "use $module; 1;" or die $@;
1766         my @out;
1767         foreach (split /\n/, $field) {
1768             next unless m/\S/;
1769             m/^(\w+) (\d+) (\S+)$/ or
1770                 fail "could not parse .dsc $fname line \`$_'";
1771             my $digester = eval "$module"."->$method;" or die $@;
1772             push @out, {
1773                 Hash => $1,
1774                 Bytes => $2,
1775                 Filename => $3,
1776                 Digester => $digester,
1777             };
1778         }
1779         return @out;
1780     }
1781     fail "missing any supported Checksums-* or Files field in ".
1782         $dsc->get_option('name');
1783 }
1784
1785 sub dsc_files () {
1786     map { $_->{Filename} } dsc_files_info();
1787 }
1788
1789 sub files_compare_inputs (@) {
1790     my $inputs = \@_;
1791     my %record;
1792     my %fchecked;
1793
1794     my $showinputs = sub {
1795         return join "; ", map { $_->get_option('name') } @$inputs;
1796     };
1797
1798     foreach my $in (@$inputs) {
1799         my $expected_files;
1800         my $in_name = $in->get_option('name');
1801
1802         printdebug "files_compare_inputs $in_name\n";
1803
1804         foreach my $csumi (@files_csum_info_fields) {
1805             my ($fname) = @$csumi;
1806             printdebug "files_compare_inputs $in_name $fname\n";
1807
1808             my $field = $in->{$fname};
1809             next unless defined $field;
1810
1811             my @files;
1812             foreach (split /\n/, $field) {
1813                 next unless m/\S/;
1814
1815                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1816                     fail "could not parse $in_name $fname line \`$_'";
1817
1818                 printdebug "files_compare_inputs $in_name $fname $f\n";
1819
1820                 push @files, $f;
1821
1822                 my $re = \ $record{$f}{$fname};
1823                 if (defined $$re) {
1824                     $fchecked{$f}{$in_name} = 1;
1825                     $$re eq $info or
1826                         fail "hash or size of $f varies in $fname fields".
1827                         " (between: ".$showinputs->().")";
1828                 } else {
1829                     $$re = $info;
1830                 }
1831             }
1832             @files = sort @files;
1833             $expected_files //= \@files;
1834             "@$expected_files" eq "@files" or
1835                 fail "file list in $in_name varies between hash fields!";
1836         }
1837         $expected_files or
1838             fail "$in_name has no files list field(s)";
1839     }
1840     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1841         if $debuglevel>=2;
1842
1843     grep { keys %$_ == @$inputs-1 } values %fchecked
1844         or fail "no file appears in all file lists".
1845         " (looked in: ".$showinputs->().")";
1846 }
1847
1848 sub is_orig_file_in_dsc ($$) {
1849     my ($f, $dsc_files_info) = @_;
1850     return 0 if @$dsc_files_info <= 1;
1851     # One file means no origs, and the filename doesn't have a "what
1852     # part of dsc" component.  (Consider versions ending `.orig'.)
1853     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1854     return 1;
1855 }
1856
1857 sub is_orig_file_of_vsn ($$) {
1858     my ($f, $upstreamvsn) = @_;
1859     my $base = srcfn $upstreamvsn, '';
1860     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1861     return 1;
1862 }
1863
1864 sub changes_update_origs_from_dsc ($$$$) {
1865     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1866     my %changes_f;
1867     printdebug "checking origs needed ($upstreamvsn)...\n";
1868     $_ = getfield $changes, 'Files';
1869     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1870         fail "cannot find section/priority from .changes Files field";
1871     my $placementinfo = $1;
1872     my %changed;
1873     printdebug "checking origs needed placement '$placementinfo'...\n";
1874     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1875         $l =~ m/\S+$/ or next;
1876         my $file = $&;
1877         printdebug "origs $file | $l\n";
1878         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1879         printdebug "origs $file is_orig\n";
1880         my $have = archive_query('file_in_archive', $file);
1881         if (!defined $have) {
1882             print STDERR <<END;
1883 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1884 END
1885             return;
1886         }
1887         my $found_same = 0;
1888         my @found_differ;
1889         printdebug "origs $file \$#\$have=$#$have\n";
1890         foreach my $h (@$have) {
1891             my $same = 0;
1892             my @differ;
1893             foreach my $csumi (@files_csum_info_fields) {
1894                 my ($fname, $module, $method, $archivefield) = @$csumi;
1895                 next unless defined $h->{$archivefield};
1896                 $_ = $dsc->{$fname};
1897                 next unless defined;
1898                 m/^(\w+) .* \Q$file\E$/m or
1899                     fail ".dsc $fname missing entry for $file";
1900                 if ($h->{$archivefield} eq $1) {
1901                     $same++;
1902                 } else {
1903                     push @differ,
1904  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1905                 }
1906             }
1907             die "$file ".Dumper($h)." ?!" if $same && @differ;
1908             $found_same++
1909                 if $same;
1910             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1911                 if @differ;
1912         }
1913         printdebug "origs $file f.same=$found_same".
1914             " #f._differ=$#found_differ\n";
1915         if (@found_differ && !$found_same) {
1916             fail join "\n",
1917                 "archive contains $file with different checksum",
1918                 @found_differ;
1919         }
1920         # Now we edit the changes file to add or remove it
1921         foreach my $csumi (@files_csum_info_fields) {
1922             my ($fname, $module, $method, $archivefield) = @$csumi;
1923             next unless defined $changes->{$fname};
1924             if ($found_same) {
1925                 # in archive, delete from .changes if it's there
1926                 $changed{$file} = "removed" if
1927                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1928             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1929                 # not in archive, but it's here in the .changes
1930             } else {
1931                 my $dsc_data = getfield $dsc, $fname;
1932                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1933                 my $extra = $1;
1934                 $extra =~ s/ \d+ /$&$placementinfo /
1935                     or die "$fname $extra >$dsc_data< ?"
1936                     if $fname eq 'Files';
1937                 $changes->{$fname} .= "\n". $extra;
1938                 $changed{$file} = "added";
1939             }
1940         }
1941     }
1942     if (%changed) {
1943         foreach my $file (keys %changed) {
1944             progress sprintf
1945                 "edited .changes for archive .orig contents: %s %s",
1946                 $changed{$file}, $file;
1947         }
1948         my $chtmp = "$changesfile.tmp";
1949         $changes->save($chtmp);
1950         if (act_local()) {
1951             rename $chtmp,$changesfile or die "$changesfile $!";
1952         } else {
1953             progress "[new .changes left in $changesfile]";
1954         }
1955     } else {
1956         progress "$changesfile already has appropriate .orig(s) (if any)";
1957     }
1958 }
1959
1960 sub make_commit ($) {
1961     my ($file) = @_;
1962     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1963 }
1964
1965 sub make_commit_text ($) {
1966     my ($text) = @_;
1967     my ($out, $in);
1968     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1969     debugcmd "|",@cmd;
1970     print Dumper($text) if $debuglevel > 1;
1971     my $child = open2($out, $in, @cmd) or die $!;
1972     my $h;
1973     eval {
1974         print $in $text or die $!;
1975         close $in or die $!;
1976         $h = <$out>;
1977         $h =~ m/^\w+$/ or die;
1978         $h = $&;
1979         printdebug "=> $h\n";
1980     };
1981     close $out;
1982     waitpid $child, 0 == $child or die "$child $!";
1983     $? and failedcmd @cmd;
1984     return $h;
1985 }
1986
1987 sub clogp_authline ($) {
1988     my ($clogp) = @_;
1989     my $author = getfield $clogp, 'Maintainer';
1990     $author =~ s#,.*##ms;
1991     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1992     my $authline = "$author $date";
1993     $authline =~ m/$git_authline_re/o or
1994         fail "unexpected commit author line format \`$authline'".
1995         " (was generated from changelog Maintainer field)";
1996     return ($1,$2,$3) if wantarray;
1997     return $authline;
1998 }
1999
2000 sub vendor_patches_distro ($$) {
2001     my ($checkdistro, $what) = @_;
2002     return unless defined $checkdistro;
2003
2004     my $series = "debian/patches/\L$checkdistro\E.series";
2005     printdebug "checking for vendor-specific $series ($what)\n";
2006
2007     if (!open SERIES, "<", $series) {
2008         die "$series $!" unless $!==ENOENT;
2009         return;
2010     }
2011     while (<SERIES>) {
2012         next unless m/\S/;
2013         next if m/^\s+\#/;
2014
2015         print STDERR <<END;
2016
2017 Unfortunately, this source package uses a feature of dpkg-source where
2018 the same source package unpacks to different source code on different
2019 distros.  dgit cannot safely operate on such packages on affected
2020 distros, because the meaning of source packages is not stable.
2021
2022 Please ask the distro/maintainer to remove the distro-specific series
2023 files and use a different technique (if necessary, uploading actually
2024 different packages, if different distros are supposed to have
2025 different code).
2026
2027 END
2028         fail "Found active distro-specific series file for".
2029             " $checkdistro ($what): $series, cannot continue";
2030     }
2031     die "$series $!" if SERIES->error;
2032     close SERIES;
2033 }
2034
2035 sub check_for_vendor_patches () {
2036     # This dpkg-source feature doesn't seem to be documented anywhere!
2037     # But it can be found in the changelog (reformatted):
2038
2039     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2040     #   Author: Raphael Hertzog <hertzog@debian.org>
2041     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2042
2043     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2044     #   series files
2045     #
2046     #   If you have debian/patches/ubuntu.series and you were
2047     #   unpacking the source package on ubuntu, quilt was still
2048     #   directed to debian/patches/series instead of
2049     #   debian/patches/ubuntu.series.
2050     #
2051     #   debian/changelog                        |    3 +++
2052     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2053     #   2 files changed, 6 insertions(+), 1 deletion(-)
2054
2055     use Dpkg::Vendor;
2056     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2057     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2058                          "Dpkg::Vendor \`current vendor'");
2059     vendor_patches_distro(access_basedistro(),
2060                           "(base) distro being accessed");
2061     vendor_patches_distro(access_nomdistro(),
2062                           "(nominal) distro being accessed");
2063 }
2064
2065 sub generate_commits_from_dsc () {
2066     # See big comment in fetch_from_archive, below.
2067     # See also README.dsc-import.
2068     prep_ud();
2069     changedir $ud;
2070
2071     my @dfi = dsc_files_info();
2072     foreach my $fi (@dfi) {
2073         my $f = $fi->{Filename};
2074         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2075
2076         printdebug "considering linking $f: ";
2077
2078         link_ltarget "../../../../$f", $f
2079             or ((printdebug "($!) "), 0)
2080             or $!==&ENOENT
2081             or die "$f $!";
2082
2083         printdebug "linked.\n";
2084
2085         complete_file_from_dsc('.', $fi)
2086             or next;
2087
2088         if (is_orig_file_in_dsc($f, \@dfi)) {
2089             link $f, "../../../../$f"
2090                 or $!==&EEXIST
2091                 or die "$f $!";
2092         }
2093     }
2094
2095     # We unpack and record the orig tarballs first, so that we only
2096     # need disk space for one private copy of the unpacked source.
2097     # But we can't make them into commits until we have the metadata
2098     # from the debian/changelog, so we record the tree objects now and
2099     # make them into commits later.
2100     my @tartrees;
2101     my $upstreamv = upstreamversion $dsc->{version};
2102     my $orig_f_base = srcfn $upstreamv, '';
2103
2104     foreach my $fi (@dfi) {
2105         # We actually import, and record as a commit, every tarball
2106         # (unless there is only one file, in which case there seems
2107         # little point.
2108
2109         my $f = $fi->{Filename};
2110         printdebug "import considering $f ";
2111         (printdebug "only one dfi\n"), next if @dfi == 1;
2112         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2113         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2114         my $compr_ext = $1;
2115
2116         my ($orig_f_part) =
2117             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2118
2119         printdebug "Y ", (join ' ', map { $_//"(none)" }
2120                           $compr_ext, $orig_f_part
2121                          ), "\n";
2122
2123         my $input = new IO::File $f, '<' or die "$f $!";
2124         my $compr_pid;
2125         my @compr_cmd;
2126
2127         if (defined $compr_ext) {
2128             my $cname =
2129                 Dpkg::Compression::compression_guess_from_filename $f;
2130             fail "Dpkg::Compression cannot handle file $f in source package"
2131                 if defined $compr_ext && !defined $cname;
2132             my $compr_proc =
2133                 new Dpkg::Compression::Process compression => $cname;
2134             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2135             my $compr_fh = new IO::Handle;
2136             my $compr_pid = open $compr_fh, "-|" // die $!;
2137             if (!$compr_pid) {
2138                 open STDIN, "<&", $input or die $!;
2139                 exec @compr_cmd;
2140                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2141             }
2142             $input = $compr_fh;
2143         }
2144
2145         rmtree "_unpack-tar";
2146         mkdir "_unpack-tar" or die $!;
2147         my @tarcmd = qw(tar -x -f -
2148                         --no-same-owner --no-same-permissions
2149                         --no-acls --no-xattrs --no-selinux);
2150         my $tar_pid = fork // die $!;
2151         if (!$tar_pid) {
2152             chdir "_unpack-tar" or die $!;
2153             open STDIN, "<&", $input or die $!;
2154             exec @tarcmd;
2155             die "dgit (child): exec $tarcmd[0]: $!";
2156         }
2157         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2158         !$? or failedcmd @tarcmd;
2159
2160         close $input or
2161             (@compr_cmd ? failedcmd @compr_cmd
2162              : die $!);
2163         # finally, we have the results in "tarball", but maybe
2164         # with the wrong permissions
2165
2166         runcmd qw(chmod -R +rwX _unpack-tar);
2167         changedir "_unpack-tar";
2168         remove_stray_gits($f);
2169         mktree_in_ud_here();
2170
2171         my ($tree) = git_add_write_tree();
2172         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2173         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2174             $tree = $1;
2175             printdebug "one subtree $1\n";
2176         } else {
2177             printdebug "multiple subtrees\n";
2178         }
2179         changedir "..";
2180         rmtree "_unpack-tar";
2181
2182         my $ent = [ $f, $tree ];
2183         push @tartrees, {
2184             Orig => !!$orig_f_part,
2185             Sort => (!$orig_f_part         ? 2 :
2186                      $orig_f_part =~ m/-/g ? 1 :
2187                                              0),
2188             F => $f,
2189             Tree => $tree,
2190         };
2191     }
2192
2193     @tartrees = sort {
2194         # put any without "_" first (spec is not clear whether files
2195         # are always in the usual order).  Tarballs without "_" are
2196         # the main orig or the debian tarball.
2197         $a->{Sort} <=> $b->{Sort} or
2198         $a->{F}    cmp $b->{F}
2199     } @tartrees;
2200
2201     my $any_orig = grep { $_->{Orig} } @tartrees;
2202
2203     my $dscfn = "$package.dsc";
2204
2205     my $treeimporthow = 'package';
2206
2207     open D, ">", $dscfn or die "$dscfn: $!";
2208     print D $dscdata or die "$dscfn: $!";
2209     close D or die "$dscfn: $!";
2210     my @cmd = qw(dpkg-source);
2211     push @cmd, '--no-check' if $dsc_checked;
2212     if (madformat $dsc->{format}) {
2213         push @cmd, '--skip-patches';
2214         $treeimporthow = 'unpatched';
2215     }
2216     push @cmd, qw(-x --), $dscfn;
2217     runcmd @cmd;
2218
2219     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2220     if (madformat $dsc->{format}) {
2221         check_for_vendor_patches();
2222     }
2223
2224     my $dappliedtree;
2225     if (madformat $dsc->{format}) {
2226         my @pcmd = qw(dpkg-source --before-build .);
2227         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2228         rmtree '.pc';
2229         $dappliedtree = git_add_write_tree();
2230     }
2231
2232     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2233     debugcmd "|",@clogcmd;
2234     open CLOGS, "-|", @clogcmd or die $!;
2235
2236     my $clogp;
2237     my $r1clogp;
2238
2239     printdebug "import clog search...\n";
2240
2241     for (;;) {
2242         my $stanzatext = do { local $/=""; <CLOGS>; };
2243         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2244         last if !defined $stanzatext;
2245
2246         my $desc = "package changelog, entry no.$.";
2247         open my $stanzafh, "<", \$stanzatext or die;
2248         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2249         $clogp //= $thisstanza;
2250
2251         printdebug "import clog $thisstanza->{version} $desc...\n";
2252
2253         last if !$any_orig; # we don't need $r1clogp
2254
2255         # We look for the first (most recent) changelog entry whose
2256         # version number is lower than the upstream version of this
2257         # package.  Then the last (least recent) previous changelog
2258         # entry is treated as the one which introduced this upstream
2259         # version and used for the synthetic commits for the upstream
2260         # tarballs.
2261
2262         # One might think that a more sophisticated algorithm would be
2263         # necessary.  But: we do not want to scan the whole changelog
2264         # file.  Stopping when we see an earlier version, which
2265         # necessarily then is an earlier upstream version, is the only
2266         # realistic way to do that.  Then, either the earliest
2267         # changelog entry we have seen so far is indeed the earliest
2268         # upload of this upstream version; or there are only changelog
2269         # entries relating to later upstream versions (which is not
2270         # possible unless the changelog and .dsc disagree about the
2271         # version).  Then it remains to choose between the physically
2272         # last entry in the file, and the one with the lowest version
2273         # number.  If these are not the same, we guess that the
2274         # versions were created in a non-monotic order rather than
2275         # that the changelog entries have been misordered.
2276
2277         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2278
2279         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2280         $r1clogp = $thisstanza;
2281
2282         printdebug "import clog $r1clogp->{version} becomes r1\n";
2283     }
2284     die $! if CLOGS->error;
2285     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2286
2287     $clogp or fail "package changelog has no entries!";
2288
2289     my $authline = clogp_authline $clogp;
2290     my $changes = getfield $clogp, 'Changes';
2291     my $cversion = getfield $clogp, 'Version';
2292
2293     if (@tartrees) {
2294         $r1clogp //= $clogp; # maybe there's only one entry;
2295         my $r1authline = clogp_authline $r1clogp;
2296         # Strictly, r1authline might now be wrong if it's going to be
2297         # unused because !$any_orig.  Whatever.
2298
2299         printdebug "import tartrees authline   $authline\n";
2300         printdebug "import tartrees r1authline $r1authline\n";
2301
2302         foreach my $tt (@tartrees) {
2303             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2304
2305             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2306 tree $tt->{Tree}
2307 author $r1authline
2308 committer $r1authline
2309
2310 Import $tt->{F}
2311
2312 [dgit import orig $tt->{F}]
2313 END_O
2314 tree $tt->{Tree}
2315 author $authline
2316 committer $authline
2317
2318 Import $tt->{F}
2319
2320 [dgit import tarball $package $cversion $tt->{F}]
2321 END_T
2322         }
2323     }
2324
2325     printdebug "import main commit\n";
2326
2327     open C, ">../commit.tmp" or die $!;
2328     print C <<END or die $!;
2329 tree $tree
2330 END
2331     print C <<END or die $! foreach @tartrees;
2332 parent $_->{Commit}
2333 END
2334     print C <<END or die $!;
2335 author $authline
2336 committer $authline
2337
2338 $changes
2339
2340 [dgit import $treeimporthow $package $cversion]
2341 END
2342
2343     close C or die $!;
2344     my $rawimport_hash = make_commit qw(../commit.tmp);
2345
2346     if (madformat $dsc->{format}) {
2347         printdebug "import apply patches...\n";
2348
2349         # regularise the state of the working tree so that
2350         # the checkout of $rawimport_hash works nicely.
2351         my $dappliedcommit = make_commit_text(<<END);
2352 tree $dappliedtree
2353 author $authline
2354 committer $authline
2355
2356 [dgit dummy commit]
2357 END
2358         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2359
2360         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2361
2362         # We need the answers to be reproducible
2363         my @authline = clogp_authline($clogp);
2364         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2365         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2366         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2367         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2368         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2369         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2370
2371         my $path = $ENV{PATH} or die;
2372
2373         foreach my $use_absurd (qw(0 1)) {
2374             runcmd @git, qw(checkout -q unpa);
2375             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2376             local $ENV{PATH} = $path;
2377             if ($use_absurd) {
2378                 chomp $@;
2379                 progress "warning: $@";
2380                 $path = "$absurdity:$path";
2381                 progress "$us: trying slow absurd-git-apply...";
2382                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2383                     or $!==ENOENT
2384                     or die $!;
2385             }
2386             eval {
2387                 die "forbid absurd git-apply\n" if $use_absurd
2388                     && forceing [qw(import-gitapply-no-absurd)];
2389                 die "only absurd git-apply!\n" if !$use_absurd
2390                     && forceing [qw(import-gitapply-absurd)];
2391
2392                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2393                 local $ENV{PATH} = $path                    if $use_absurd;
2394
2395                 my @showcmd = (gbp_pq, qw(import));
2396                 my @realcmd = shell_cmd
2397                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2398                 debugcmd "+",@realcmd;
2399                 if (system @realcmd) {
2400                     die +(shellquote @showcmd).
2401                         " failed: ".
2402                         failedcmd_waitstatus()."\n";
2403                 }
2404
2405                 my $gapplied = git_rev_parse('HEAD');
2406                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2407                 $gappliedtree eq $dappliedtree or
2408                     fail <<END;
2409 gbp-pq import and dpkg-source disagree!
2410  gbp-pq import gave commit $gapplied
2411  gbp-pq import gave tree $gappliedtree
2412  dpkg-source --before-build gave tree $dappliedtree
2413 END
2414                 $rawimport_hash = $gapplied;
2415             };
2416             last unless $@;
2417         }
2418         if ($@) {
2419             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2420             die $@;
2421         }
2422     }
2423
2424     progress "synthesised git commit from .dsc $cversion";
2425
2426     my $rawimport_mergeinput = {
2427         Commit => $rawimport_hash,
2428         Info => "Import of source package",
2429     };
2430     my @output = ($rawimport_mergeinput);
2431
2432     if ($lastpush_mergeinput) {
2433         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2434         my $oversion = getfield $oldclogp, 'Version';
2435         my $vcmp =
2436             version_compare($oversion, $cversion);
2437         if ($vcmp < 0) {
2438             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2439                 { Message => <<END, ReverseParents => 1 });
2440 Record $package ($cversion) in archive suite $csuite
2441 END
2442         } elsif ($vcmp > 0) {
2443             print STDERR <<END or die $!;
2444
2445 Version actually in archive:   $cversion (older)
2446 Last version pushed with dgit: $oversion (newer or same)
2447 $later_warning_msg
2448 END
2449             @output = $lastpush_mergeinput;
2450         } else {
2451             # Same version.  Use what's in the server git branch,
2452             # discarding our own import.  (This could happen if the
2453             # server automatically imports all packages into git.)
2454             @output = $lastpush_mergeinput;
2455         }
2456     }
2457     changedir '../../../..';
2458     rmtree($ud);
2459     return @output;
2460 }
2461
2462 sub complete_file_from_dsc ($$) {
2463     our ($dstdir, $fi) = @_;
2464     # Ensures that we have, in $dir, the file $fi, with the correct
2465     # contents.  (Downloading it from alongside $dscurl if necessary.)
2466
2467     my $f = $fi->{Filename};
2468     my $tf = "$dstdir/$f";
2469     my $downloaded = 0;
2470
2471     if (stat_exists $tf) {
2472         progress "using existing $f";
2473     } else {
2474         printdebug "$tf does not exist, need to fetch\n";
2475         my $furl = $dscurl;
2476         $furl =~ s{/[^/]+$}{};
2477         $furl .= "/$f";
2478         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2479         die "$f ?" if $f =~ m#/#;
2480         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2481         return 0 if !act_local();
2482         $downloaded = 1;
2483     }
2484
2485     open F, "<", "$tf" or die "$tf: $!";
2486     $fi->{Digester}->reset();
2487     $fi->{Digester}->addfile(*F);
2488     F->error and die $!;
2489     my $got = $fi->{Digester}->hexdigest();
2490     $got eq $fi->{Hash} or
2491         fail "file $f has hash $got but .dsc".
2492             " demands hash $fi->{Hash} ".
2493             ($downloaded ? "(got wrong file from archive!)"
2494              : "(perhaps you should delete this file?)");
2495
2496     return 1;
2497 }
2498
2499 sub ensure_we_have_orig () {
2500     my @dfi = dsc_files_info();
2501     foreach my $fi (@dfi) {
2502         my $f = $fi->{Filename};
2503         next unless is_orig_file_in_dsc($f, \@dfi);
2504         complete_file_from_dsc('..', $fi)
2505             or next;
2506     }
2507 }
2508
2509 sub git_fetch_us () {
2510     # Want to fetch only what we are going to use, unless
2511     # deliberately-not-ff, in which case we must fetch everything.
2512
2513     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2514         map { "tags/$_" }
2515         (quiltmode_splitbrain
2516          ? (map { $_->('*',access_nomdistro) }
2517             \&debiantag_new, \&debiantag_maintview)
2518          : debiantags('*',access_nomdistro));
2519     push @specs, server_branch($csuite);
2520     push @specs, $rewritemap;
2521     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2522
2523     # This is rather miserable:
2524     # When git fetch --prune is passed a fetchspec ending with a *,
2525     # it does a plausible thing.  If there is no * then:
2526     # - it matches subpaths too, even if the supplied refspec
2527     #   starts refs, and behaves completely madly if the source
2528     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2529     # - if there is no matching remote ref, it bombs out the whole
2530     #   fetch.
2531     # We want to fetch a fixed ref, and we don't know in advance
2532     # if it exists, so this is not suitable.
2533     #
2534     # Our workaround is to use git ls-remote.  git ls-remote has its
2535     # own qairks.  Notably, it has the absurd multi-tail-matching
2536     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2537     # refs/refs/foo etc.
2538     #
2539     # Also, we want an idempotent snapshot, but we have to make two
2540     # calls to the remote: one to git ls-remote and to git fetch.  The
2541     # solution is use git ls-remote to obtain a target state, and
2542     # git fetch to try to generate it.  If we don't manage to generate
2543     # the target state, we try again.
2544
2545     printdebug "git_fetch_us specs @specs\n";
2546
2547     my $specre = join '|', map {
2548         my $x = $_;
2549         $x =~ s/\W/\\$&/g;
2550         $x =~ s/\\\*$/.*/;
2551         "(?:refs/$x)";
2552     } @specs;
2553     printdebug "git_fetch_us specre=$specre\n";
2554     my $wanted_rref = sub {
2555         local ($_) = @_;
2556         return m/^(?:$specre)$/o;
2557     };
2558
2559     my $fetch_iteration = 0;
2560     FETCH_ITERATION:
2561     for (;;) {
2562         printdebug "git_fetch_us iteration $fetch_iteration\n";
2563         if (++$fetch_iteration > 10) {
2564             fail "too many iterations trying to get sane fetch!";
2565         }
2566
2567         my @look = map { "refs/$_" } @specs;
2568         my @lcmd = (@git, qw(ls-remote -q --refs), access_giturl(), @look);
2569         debugcmd "|",@lcmd;
2570
2571         my %wantr;
2572         open GITLS, "-|", @lcmd or die $!;
2573         while (<GITLS>) {
2574             printdebug "=> ", $_;
2575             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2576             my ($objid,$rrefname) = ($1,$2);
2577             if (!$wanted_rref->($rrefname)) {
2578                 print STDERR <<END;
2579 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2580 END
2581                 next;
2582             }
2583             $wantr{$rrefname} = $objid;
2584         }
2585         $!=0; $?=0;
2586         close GITLS or failedcmd @lcmd;
2587
2588         # OK, now %want is exactly what we want for refs in @specs
2589         my @fspecs = map {
2590             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2591             "+refs/$_:".lrfetchrefs."/$_";
2592         } @specs;
2593
2594         printdebug "git_fetch_us fspecs @fspecs\n";
2595
2596         my @fcmd = (@git, qw(fetch -p -n -q), access_giturl(), @fspecs);
2597         runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(),
2598             @fspecs;
2599
2600         %lrfetchrefs_f = ();
2601         my %objgot;
2602
2603         git_for_each_ref(lrfetchrefs, sub {
2604             my ($objid,$objtype,$lrefname,$reftail) = @_;
2605             $lrfetchrefs_f{$lrefname} = $objid;
2606             $objgot{$objid} = 1;
2607         });
2608
2609         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2610             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2611             if (!exists $wantr{$rrefname}) {
2612                 if ($wanted_rref->($rrefname)) {
2613                     printdebug <<END;
2614 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2615 END
2616                 } else {
2617                     print STDERR <<END
2618 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2619 END
2620                 }
2621                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2622                 delete $lrfetchrefs_f{$lrefname};
2623                 next;
2624             }
2625         }
2626         foreach my $rrefname (sort keys %wantr) {
2627             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2628             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2629             my $want = $wantr{$rrefname};
2630             next if $got eq $want;
2631             if (!defined $objgot{$want}) {
2632                 print STDERR <<END;
2633 warning: git ls-remote suggests we want $lrefname
2634 warning:  and it should refer to $want
2635 warning:  but git fetch didn't fetch that object to any relevant ref.
2636 warning:  This may be due to a race with someone updating the server.
2637 warning:  Will try again...
2638 END
2639                 next FETCH_ITERATION;
2640             }
2641             printdebug <<END;
2642 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2643 END
2644             runcmd_ordryrun_local @git, qw(update-ref -m),
2645                 "dgit fetch git fetch fixup", $lrefname, $want;
2646             $lrfetchrefs_f{$lrefname} = $want;
2647         }
2648         last;
2649     }
2650     printdebug "git_fetch_us: git fetch --no-insane emulation complete\n",
2651         Dumper(\%lrfetchrefs_f);
2652
2653     my %here;
2654     my @tagpats = debiantags('*',access_nomdistro);
2655
2656     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2657         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2658         printdebug "currently $fullrefname=$objid\n";
2659         $here{$fullrefname} = $objid;
2660     });
2661     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2662         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2663         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2664         printdebug "offered $lref=$objid\n";
2665         if (!defined $here{$lref}) {
2666             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2667             runcmd_ordryrun_local @upd;
2668             lrfetchref_used $fullrefname;
2669         } elsif ($here{$lref} eq $objid) {
2670             lrfetchref_used $fullrefname;
2671         } else {
2672             print STDERR \
2673                 "Not updateting $lref from $here{$lref} to $objid.\n";
2674         }
2675     });
2676 }
2677
2678 sub mergeinfo_getclogp ($) {
2679     # Ensures thit $mi->{Clogp} exists and returns it
2680     my ($mi) = @_;
2681     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2682 }
2683
2684 sub mergeinfo_version ($) {
2685     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2686 }
2687
2688 sub fetch_from_archive_record_1 ($) {
2689     my ($hash) = @_;
2690     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2691             'DGIT_ARCHIVE', $hash;
2692     cmdoutput @git, qw(log -n2), $hash;
2693     # ... gives git a chance to complain if our commit is malformed
2694 }
2695
2696 sub fetch_from_archive_record_2 ($) {
2697     my ($hash) = @_;
2698     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2699     if (act_local()) {
2700         cmdoutput @upd_cmd;
2701     } else {
2702         dryrun_report @upd_cmd;
2703     }
2704 }
2705
2706 sub parse_dsc_field ($$) {
2707     my ($f, $what) = @_;
2708     if (!defined $f) {
2709         progress "$what: NO git hash";
2710     } elsif ($f =~ m/^\w+/) {
2711         $dsc_hash = $&;
2712         progress "$what: specified git hash";
2713     } else {
2714         fail "$what: invalid Dgit info";
2715     }
2716 }
2717
2718 sub fetch_from_archive () {
2719     ensure_setup_existing_tree();
2720
2721     # Ensures that lrref() is what is actually in the archive, one way
2722     # or another, according to us - ie this client's
2723     # appropritaely-updated archive view.  Also returns the commit id.
2724     # If there is nothing in the archive, leaves lrref alone and
2725     # returns undef.  git_fetch_us must have already been called.
2726     get_archive_dsc();
2727
2728     if ($dsc) {
2729         my $f;
2730         foreach my $field (@ourdscfield) {
2731             $f = $dsc->{$field};
2732             last if defined $f;
2733         }
2734         parse_dsc_field($f, 'last upload to archive');
2735     } else {
2736         progress "no version available from the archive";
2737     }
2738
2739     my $rewritemapdata = git_cat_file lrfetchrefs."/".$rewritemap.':map';
2740     if (defined $rewritemapdata
2741         && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2742         progress "server's git history rewrite map contains a relevant entry!";
2743         $dsc_hash = $1;
2744         if (defined $dsc_hash) {
2745             progress "using rewritten git hash in place of .dsc value";
2746         } else {
2747             progress "server data says .dsc hash is to be disregarded";
2748         }
2749     }
2750
2751     # If the archive's .dsc has a Dgit field, there are three
2752     # relevant git commitids we need to choose between and/or merge
2753     # together:
2754     #   1. $dsc_hash: the Dgit field from the archive
2755     #   2. $lastpush_hash: the suite branch on the dgit git server
2756     #   3. $lastfetch_hash: our local tracking brach for the suite
2757     #
2758     # These may all be distinct and need not be in any fast forward
2759     # relationship:
2760     #
2761     # If the dsc was pushed to this suite, then the server suite
2762     # branch will have been updated; but it might have been pushed to
2763     # a different suite and copied by the archive.  Conversely a more
2764     # recent version may have been pushed with dgit but not appeared
2765     # in the archive (yet).
2766     #
2767     # $lastfetch_hash may be awkward because archive imports
2768     # (particularly, imports of Dgit-less .dscs) are performed only as
2769     # needed on individual clients, so different clients may perform a
2770     # different subset of them - and these imports are only made
2771     # public during push.  So $lastfetch_hash may represent a set of
2772     # imports different to a subsequent upload by a different dgit
2773     # client.
2774     #
2775     # Our approach is as follows:
2776     #
2777     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2778     # descendant of $dsc_hash, then it was pushed by a dgit user who
2779     # had based their work on $dsc_hash, so we should prefer it.
2780     # Otherwise, $dsc_hash was installed into this suite in the
2781     # archive other than by a dgit push, and (necessarily) after the
2782     # last dgit push into that suite (since a dgit push would have
2783     # been descended from the dgit server git branch); thus, in that
2784     # case, we prefer the archive's version (and produce a
2785     # pseudo-merge to overwrite the dgit server git branch).
2786     #
2787     # (If there is no Dgit field in the archive's .dsc then
2788     # generate_commit_from_dsc uses the version numbers to decide
2789     # whether the suite branch or the archive is newer.  If the suite
2790     # branch is newer it ignores the archive's .dsc; otherwise it
2791     # generates an import of the .dsc, and produces a pseudo-merge to
2792     # overwrite the suite branch with the archive contents.)
2793     #
2794     # The outcome of that part of the algorithm is the `public view',
2795     # and is same for all dgit clients: it does not depend on any
2796     # unpublished history in the local tracking branch.
2797     #
2798     # As between the public view and the local tracking branch: The
2799     # local tracking branch is only updated by dgit fetch, and
2800     # whenever dgit fetch runs it includes the public view in the
2801     # local tracking branch.  Therefore if the public view is not
2802     # descended from the local tracking branch, the local tracking
2803     # branch must contain history which was imported from the archive
2804     # but never pushed; and, its tip is now out of date.  So, we make
2805     # a pseudo-merge to overwrite the old imports and stitch the old
2806     # history in.
2807     #
2808     # Finally: we do not necessarily reify the public view (as
2809     # described above).  This is so that we do not end up stacking two
2810     # pseudo-merges.  So what we actually do is figure out the inputs
2811     # to any public view pseudo-merge and put them in @mergeinputs.
2812
2813     my @mergeinputs;
2814     # $mergeinputs[]{Commit}
2815     # $mergeinputs[]{Info}
2816     # $mergeinputs[0] is the one whose tree we use
2817     # @mergeinputs is in the order we use in the actual commit)
2818     #
2819     # Also:
2820     # $mergeinputs[]{Message} is a commit message to use
2821     # $mergeinputs[]{ReverseParents} if def specifies that parent
2822     #                                list should be in opposite order
2823     # Such an entry has no Commit or Info.  It applies only when found
2824     # in the last entry.  (This ugliness is to support making
2825     # identical imports to previous dgit versions.)
2826
2827     my $lastpush_hash = git_get_ref(lrfetchref());
2828     printdebug "previous reference hash=$lastpush_hash\n";
2829     $lastpush_mergeinput = $lastpush_hash && {
2830         Commit => $lastpush_hash,
2831         Info => "dgit suite branch on dgit git server",
2832     };
2833
2834     my $lastfetch_hash = git_get_ref(lrref());
2835     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2836     my $lastfetch_mergeinput = $lastfetch_hash && {
2837         Commit => $lastfetch_hash,
2838         Info => "dgit client's archive history view",
2839     };
2840
2841     my $dsc_mergeinput = $dsc_hash && {
2842         Commit => $dsc_hash,
2843         Info => "Dgit field in .dsc from archive",
2844     };
2845
2846     my $cwd = getcwd();
2847     my $del_lrfetchrefs = sub {
2848         changedir $cwd;
2849         my $gur;
2850         printdebug "del_lrfetchrefs...\n";
2851         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2852             my $objid = $lrfetchrefs_d{$fullrefname};
2853             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2854             if (!$gur) {
2855                 $gur ||= new IO::Handle;
2856                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2857             }
2858             printf $gur "delete %s %s\n", $fullrefname, $objid;
2859         }
2860         if ($gur) {
2861             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2862         }
2863     };
2864
2865     if (defined $dsc_hash) {
2866         ensure_we_have_orig();
2867         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
2868             @mergeinputs = $dsc_mergeinput
2869         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
2870             print STDERR <<END or die $!;
2871
2872 Git commit in archive is behind the last version allegedly pushed/uploaded.
2873 Commit referred to by archive: $dsc_hash
2874 Last version pushed with dgit: $lastpush_hash
2875 $later_warning_msg
2876 END
2877             @mergeinputs = ($lastpush_mergeinput);
2878         } else {
2879             # Archive has .dsc which is not a descendant of the last dgit
2880             # push.  This can happen if the archive moves .dscs about.
2881             # Just follow its lead.
2882             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
2883                 progress "archive .dsc names newer git commit";
2884                 @mergeinputs = ($dsc_mergeinput);
2885             } else {
2886                 progress "archive .dsc names other git commit, fixing up";
2887                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
2888             }
2889         }
2890     } elsif ($dsc) {
2891         @mergeinputs = generate_commits_from_dsc();
2892         # We have just done an import.  Now, our import algorithm might
2893         # have been improved.  But even so we do not want to generate
2894         # a new different import of the same package.  So if the
2895         # version numbers are the same, just use our existing version.
2896         # If the version numbers are different, the archive has changed
2897         # (perhaps, rewound).
2898         if ($lastfetch_mergeinput &&
2899             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
2900                               (mergeinfo_version $mergeinputs[0]) )) {
2901             @mergeinputs = ($lastfetch_mergeinput);
2902         }
2903     } elsif ($lastpush_hash) {
2904         # only in git, not in the archive yet
2905         @mergeinputs = ($lastpush_mergeinput);
2906         print STDERR <<END or die $!;
2907
2908 Package not found in the archive, but has allegedly been pushed using dgit.
2909 $later_warning_msg
2910 END
2911     } else {
2912         printdebug "nothing found!\n";
2913         if (defined $skew_warning_vsn) {
2914             print STDERR <<END or die $!;
2915
2916 Warning: relevant archive skew detected.
2917 Archive allegedly contains $skew_warning_vsn
2918 But we were not able to obtain any version from the archive or git.
2919
2920 END
2921         }
2922         unshift @end, $del_lrfetchrefs;
2923         return undef;
2924     }
2925
2926     if ($lastfetch_hash &&
2927         !grep {
2928             my $h = $_->{Commit};
2929             $h and is_fast_fwd($lastfetch_hash, $h);
2930             # If true, one of the existing parents of this commit
2931             # is a descendant of the $lastfetch_hash, so we'll
2932             # be ff from that automatically.
2933         } @mergeinputs
2934         ) {
2935         # Otherwise:
2936         push @mergeinputs, $lastfetch_mergeinput;
2937     }
2938
2939     printdebug "fetch mergeinfos:\n";
2940     foreach my $mi (@mergeinputs) {
2941         if ($mi->{Info}) {
2942             printdebug " commit $mi->{Commit} $mi->{Info}\n";
2943         } else {
2944             printdebug sprintf " ReverseParents=%d Message=%s",
2945                 $mi->{ReverseParents}, $mi->{Message};
2946         }
2947     }
2948
2949     my $compat_info= pop @mergeinputs
2950         if $mergeinputs[$#mergeinputs]{Message};
2951
2952     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
2953
2954     my $hash;
2955     if (@mergeinputs > 1) {
2956         # here we go, then:
2957         my $tree_commit = $mergeinputs[0]{Commit};
2958
2959         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
2960         $tree =~ m/\n\n/;  $tree = $`;
2961         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
2962         $tree = $1;
2963
2964         # We use the changelog author of the package in question the
2965         # author of this pseudo-merge.  This is (roughly) correct if
2966         # this commit is simply representing aa non-dgit upload.
2967         # (Roughly because it does not record sponsorship - but we
2968         # don't have sponsorship info because that's in the .changes,
2969         # which isn't in the archivw.)
2970         #
2971         # But, it might be that we are representing archive history
2972         # updates (including in-archive copies).  These are not really
2973         # the responsibility of the person who created the .dsc, but
2974         # there is no-one whose name we should better use.  (The
2975         # author of the .dsc-named commit is clearly worse.)
2976
2977         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
2978         my $author = clogp_authline $useclogp;
2979         my $cversion = getfield $useclogp, 'Version';
2980
2981         my $mcf = ".git/dgit/mergecommit";
2982         open MC, ">", $mcf or die "$mcf $!";
2983         print MC <<END or die $!;
2984 tree $tree
2985 END
2986
2987         my @parents = grep { $_->{Commit} } @mergeinputs;
2988         @parents = reverse @parents if $compat_info->{ReverseParents};
2989         print MC <<END or die $! foreach @parents;
2990 parent $_->{Commit}
2991 END
2992
2993         print MC <<END or die $!;
2994 author $author
2995 committer $author
2996
2997 END
2998
2999         if (defined $compat_info->{Message}) {
3000             print MC $compat_info->{Message} or die $!;
3001         } else {
3002             print MC <<END or die $!;
3003 Record $package ($cversion) in archive suite $csuite
3004
3005 Record that
3006 END
3007             my $message_add_info = sub {
3008                 my ($mi) = (@_);
3009                 my $mversion = mergeinfo_version $mi;
3010                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3011                     or die $!;
3012             };
3013
3014             $message_add_info->($mergeinputs[0]);
3015             print MC <<END or die $!;
3016 should be treated as descended from
3017 END
3018             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3019         }
3020
3021         close MC or die $!;
3022         $hash = make_commit $mcf;
3023     } else {
3024         $hash = $mergeinputs[0]{Commit};
3025     }
3026     printdebug "fetch hash=$hash\n";
3027
3028     my $chkff = sub {
3029         my ($lasth, $what) = @_;
3030         return unless $lasth;
3031         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3032     };
3033
3034     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3035         if $lastpush_hash;
3036     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3037
3038     fetch_from_archive_record_1($hash);
3039
3040     if (defined $skew_warning_vsn) {
3041         mkpath '.git/dgit';
3042         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3043         my $gotclogp = commit_getclogp($hash);
3044         my $got_vsn = getfield $gotclogp, 'Version';
3045         printdebug "SKEW CHECK GOT $got_vsn\n";
3046         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3047             print STDERR <<END or die $!;
3048
3049 Warning: archive skew detected.  Using the available version:
3050 Archive allegedly contains    $skew_warning_vsn
3051 We were able to obtain only   $got_vsn
3052
3053 END
3054         }
3055     }
3056
3057     if ($lastfetch_hash ne $hash) {
3058         fetch_from_archive_record_2($hash);
3059     }
3060
3061     lrfetchref_used lrfetchref();
3062
3063     unshift @end, $del_lrfetchrefs;
3064     return $hash;
3065 }
3066
3067 sub set_local_git_config ($$) {
3068     my ($k, $v) = @_;
3069     runcmd @git, qw(config), $k, $v;
3070 }
3071
3072 sub setup_mergechangelogs (;$) {
3073     my ($always) = @_;
3074     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3075
3076     my $driver = 'dpkg-mergechangelogs';
3077     my $cb = "merge.$driver";
3078     my $attrs = '.git/info/attributes';
3079     ensuredir '.git/info';
3080
3081     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3082     if (!open ATTRS, "<", $attrs) {
3083         $!==ENOENT or die "$attrs: $!";
3084     } else {
3085         while (<ATTRS>) {
3086             chomp;
3087             next if m{^debian/changelog\s};
3088             print NATTRS $_, "\n" or die $!;
3089         }
3090         ATTRS->error and die $!;
3091         close ATTRS;
3092     }
3093     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3094     close NATTRS;
3095
3096     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3097     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3098
3099     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3100 }
3101
3102 sub setup_useremail (;$) {
3103     my ($always) = @_;
3104     return unless $always || access_cfg_bool(1, 'setup-useremail');
3105
3106     my $setup = sub {
3107         my ($k, $envvar) = @_;
3108         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3109         return unless defined $v;
3110         set_local_git_config "user.$k", $v;
3111     };
3112
3113     $setup->('email', 'DEBEMAIL');
3114     $setup->('name', 'DEBFULLNAME');
3115 }
3116
3117 sub ensure_setup_existing_tree () {
3118     my $k = "remote.$remotename.skipdefaultupdate";
3119     my $c = git_get_config $k;
3120     return if defined $c;
3121     set_local_git_config $k, 'true';
3122 }
3123
3124 sub setup_new_tree () {
3125     setup_mergechangelogs();
3126     setup_useremail();
3127 }
3128
3129 sub multisuite_suite_child ($$$) {
3130     my ($tsuite, $merginputs, $fn) = @_;
3131     # in child, sets things up, calls $fn->(), and returns undef
3132     # in parent, returns canonical suite name for $tsuite
3133     my $canonsuitefh = IO::File::new_tmpfile;
3134     my $pid = fork // die $!;
3135     if (!$pid) {
3136         $isuite = $tsuite;
3137         $us .= " [$isuite]";
3138         $debugprefix .= " ";
3139         progress "fetching $tsuite...";
3140         canonicalise_suite();
3141         print $canonsuitefh $csuite, "\n" or die $!;
3142         close $canonsuitefh or die $!;
3143         $fn->();
3144         return undef;
3145     }
3146     waitpid $pid,0 == $pid or die $!;
3147     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3148     seek $canonsuitefh,0,0 or die $!;
3149     local $csuite = <$canonsuitefh>;
3150     die $! unless defined $csuite && chomp $csuite;
3151     if ($? == 256*4) {
3152         printdebug "multisuite $tsuite missing\n";
3153         return $csuite;
3154     }
3155     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3156     push @$merginputs, {
3157         Ref => lrref,
3158         Info => $csuite,
3159     };
3160     return $csuite;
3161 }
3162
3163 sub fork_for_multisuite ($) {
3164     my ($before_fetch_merge) = @_;
3165     # if nothing unusual, just returns ''
3166     #
3167     # if multisuite:
3168     # returns 0 to caller in child, to do first of the specified suites
3169     # in child, $csuite is not yet set
3170     #
3171     # returns 1 to caller in parent, to finish up anything needed after
3172     # in parent, $csuite is set to canonicalised portmanteau
3173
3174     my $org_isuite = $isuite;
3175     my @suites = split /\,/, $isuite;
3176     return '' unless @suites > 1;
3177     printdebug "fork_for_multisuite: @suites\n";
3178
3179     my @mergeinputs;
3180
3181     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3182                                             sub { });
3183     return 0 unless defined $cbasesuite;
3184
3185     fail "package $package missing in (base suite) $cbasesuite"
3186         unless @mergeinputs;
3187
3188     my @csuites = ($cbasesuite);
3189
3190     $before_fetch_merge->();
3191
3192     foreach my $tsuite (@suites[1..$#suites]) {
3193         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3194                                                sub {
3195             @end = ();
3196             fetch();
3197             exit 0;
3198         });
3199         # xxx collecte the ref here
3200
3201         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3202         push @csuites, $csubsuite;
3203     }
3204
3205     foreach my $mi (@mergeinputs) {
3206         my $ref = git_get_ref $mi->{Ref};
3207         die "$mi->{Ref} ?" unless length $ref;
3208         $mi->{Commit} = $ref;
3209     }
3210
3211     $csuite = join ",", @csuites;
3212
3213     my $previous = git_get_ref lrref;
3214     if ($previous) {
3215         unshift @mergeinputs, {
3216             Commit => $previous,
3217             Info => "local combined tracking branch",
3218             Warning =>
3219  "archive seems to have rewound: local tracking branch is ahead!",
3220         };
3221     }
3222
3223     foreach my $ix (0..$#mergeinputs) {
3224         $mergeinputs[$ix]{Index} = $ix;
3225     }
3226
3227     @mergeinputs = sort {
3228         -version_compare(mergeinfo_version $a,
3229                          mergeinfo_version $b) # highest version first
3230             or
3231         $a->{Index} <=> $b->{Index}; # earliest in spec first
3232     } @mergeinputs;
3233
3234     my @needed;
3235
3236   NEEDED:
3237     foreach my $mi (@mergeinputs) {
3238         printdebug "multisuite merge check $mi->{Info}\n";
3239         foreach my $previous (@needed) {
3240             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3241             printdebug "multisuite merge un-needed $previous->{Info}\n";
3242             next NEEDED;
3243         }
3244         push @needed, $mi;
3245         printdebug "multisuite merge this-needed\n";
3246         $mi->{Character} = '+';
3247     }
3248
3249     $needed[0]{Character} = '*';
3250
3251     my $output = $needed[0]{Commit};
3252
3253     if (@needed > 1) {
3254         printdebug "multisuite merge nontrivial\n";
3255         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3256
3257         my $commit = "tree $tree\n";
3258         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3259             "Input branches:\n";
3260
3261         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3262             printdebug "multisuite merge include $mi->{Info}\n";
3263             $mi->{Character} //= ' ';
3264             $commit .= "parent $mi->{Commit}\n";
3265             $msg .= sprintf " %s  %-25s %s\n",
3266                 $mi->{Character},
3267                 (mergeinfo_version $mi),
3268                 $mi->{Info};
3269         }
3270         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3271         $msg .= "\nKey\n".
3272             " * marks the highest version branch, which choose to use\n".
3273             " + marks each branch which was not already an ancestor\n\n".
3274             "[dgit multi-suite $csuite]\n";
3275         $commit .=
3276             "author $authline\n".
3277             "committer $authline\n\n";
3278         $output = make_commit_text $commit.$msg;
3279         printdebug "multisuite merge generated $output\n";
3280     }
3281
3282     fetch_from_archive_record_1($output);
3283     fetch_from_archive_record_2($output);
3284
3285     progress "calculated combined tracking suite $csuite";
3286
3287     return 1;
3288 }
3289
3290 sub clone_set_head () {
3291     open H, "> .git/HEAD" or die $!;
3292     print H "ref: ".lref()."\n" or die $!;
3293     close H or die $!;
3294 }
3295 sub clone_finish ($) {
3296     my ($dstdir) = @_;
3297     runcmd @git, qw(reset --hard), lrref();
3298     runcmd qw(bash -ec), <<'END';
3299         set -o pipefail
3300         git ls-tree -r --name-only -z HEAD | \
3301         xargs -0r touch -h -r . --
3302 END
3303     printdone "ready for work in $dstdir";
3304 }
3305
3306 sub clone ($) {
3307     my ($dstdir) = @_;
3308     badusage "dry run makes no sense with clone" unless act_local();
3309
3310     my $multi_fetched = fork_for_multisuite(sub {
3311         printdebug "multi clone before fetch merge\n";
3312         changedir $dstdir;
3313     });
3314     if ($multi_fetched) {
3315         printdebug "multi clone after fetch merge\n";
3316         clone_set_head();
3317         clone_finish($dstdir);
3318         exit 0;
3319     }
3320     printdebug "clone main body\n";
3321
3322     canonicalise_suite();
3323     my $hasgit = check_for_git();
3324     mkdir $dstdir or fail "create \`$dstdir': $!";
3325     changedir $dstdir;
3326     runcmd @git, qw(init -q);
3327     clone_set_head();
3328     my $giturl = access_giturl(1);
3329     if (defined $giturl) {
3330         runcmd @git, qw(remote add), 'origin', $giturl;
3331     }
3332     if ($hasgit) {
3333         progress "fetching existing git history";
3334         git_fetch_us();
3335         runcmd_ordryrun_local @git, qw(fetch origin);
3336     } else {
3337         progress "starting new git history";
3338     }
3339     fetch_from_archive() or no_such_package;
3340     my $vcsgiturl = $dsc->{'Vcs-Git'};
3341     if (length $vcsgiturl) {
3342         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3343         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3344     }
3345     setup_new_tree();
3346     clone_finish($dstdir);
3347 }
3348
3349 sub fetch () {
3350     canonicalise_suite();
3351     if (check_for_git()) {
3352         git_fetch_us();
3353     }
3354     fetch_from_archive() or no_such_package();
3355     printdone "fetched into ".lrref();
3356 }
3357
3358 sub pull () {
3359     my $multi_fetched = fork_for_multisuite(sub { });
3360     fetch() unless $multi_fetched; # parent
3361     return if $multi_fetched eq '0'; # child
3362     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3363         lrref();
3364     printdone "fetched to ".lrref()." and merged into HEAD";
3365 }
3366
3367 sub check_not_dirty () {
3368     foreach my $f (qw(local-options local-patch-header)) {
3369         if (stat_exists "debian/source/$f") {
3370             fail "git tree contains debian/source/$f";
3371         }
3372     }
3373
3374     return if $ignoredirty;
3375
3376     my @cmd = (@git, qw(diff --quiet HEAD));
3377     debugcmd "+",@cmd;
3378     $!=0; $?=-1; system @cmd;
3379     return if !$?;
3380     if ($?==256) {
3381         fail "working tree is dirty (does not match HEAD)";
3382     } else {
3383         failedcmd @cmd;
3384     }
3385 }
3386
3387 sub commit_admin ($) {
3388     my ($m) = @_;
3389     progress "$m";
3390     runcmd_ordryrun_local @git, qw(commit -m), $m;
3391 }
3392
3393 sub commit_quilty_patch () {
3394     my $output = cmdoutput @git, qw(status --porcelain);
3395     my %adds;
3396     foreach my $l (split /\n/, $output) {
3397         next unless $l =~ m/\S/;
3398         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3399             $adds{$1}++;
3400         }
3401     }
3402     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3403     if (!%adds) {
3404         progress "nothing quilty to commit, ok.";
3405         return;
3406     }
3407     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3408     runcmd_ordryrun_local @git, qw(add -f), @adds;
3409     commit_admin <<END
3410 Commit Debian 3.0 (quilt) metadata
3411
3412 [dgit ($our_version) quilt-fixup]
3413 END
3414 }
3415
3416 sub get_source_format () {
3417     my %options;
3418     if (open F, "debian/source/options") {
3419         while (<F>) {
3420             next if m/^\s*\#/;
3421             next unless m/\S/;
3422             s/\s+$//; # ignore missing final newline
3423             if (m/\s*\#\s*/) {
3424                 my ($k, $v) = ($`, $'); #');
3425                 $v =~ s/^"(.*)"$/$1/;
3426                 $options{$k} = $v;
3427             } else {
3428                 $options{$_} = 1;
3429             }
3430         }
3431         F->error and die $!;
3432         close F;
3433     } else {
3434         die $! unless $!==&ENOENT;
3435     }
3436
3437     if (!open F, "debian/source/format") {
3438         die $! unless $!==&ENOENT;
3439         return '';
3440     }
3441     $_ = <F>;
3442     F->error and die $!;
3443     chomp;
3444     return ($_, \%options);
3445 }
3446
3447 sub madformat_wantfixup ($) {
3448     my ($format) = @_;
3449     return 0 unless $format eq '3.0 (quilt)';
3450     our $quilt_mode_warned;
3451     if ($quilt_mode eq 'nocheck') {
3452         progress "Not doing any fixup of \`$format' due to".
3453             " ----no-quilt-fixup or --quilt=nocheck"
3454             unless $quilt_mode_warned++;
3455         return 0;
3456     }
3457     progress "Format \`$format', need to check/update patch stack"
3458         unless $quilt_mode_warned++;
3459     return 1;
3460 }
3461
3462 sub maybe_split_brain_save ($$$) {
3463     my ($headref, $dgitview, $msg) = @_;
3464     # => message fragment "$saved" describing disposition of $dgitview
3465     return "commit id $dgitview" unless defined $split_brain_save;
3466     my @cmd = (shell_cmd "cd ../../../..",
3467                @git, qw(update-ref -m),
3468                "dgit --dgit-view-save $msg HEAD=$headref",
3469                $split_brain_save, $dgitview);
3470     runcmd @cmd;
3471     return "and left in $split_brain_save";
3472 }
3473
3474 # An "infopair" is a tuple [ $thing, $what ]
3475 # (often $thing is a commit hash; $what is a description)
3476
3477 sub infopair_cond_equal ($$) {
3478     my ($x,$y) = @_;
3479     $x->[0] eq $y->[0] or fail <<END;
3480 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3481 END
3482 };
3483
3484 sub infopair_lrf_tag_lookup ($$) {
3485     my ($tagnames, $what) = @_;
3486     # $tagname may be an array ref
3487     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3488     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3489     foreach my $tagname (@tagnames) {
3490         my $lrefname = lrfetchrefs."/tags/$tagname";
3491         my $tagobj = $lrfetchrefs_f{$lrefname};
3492         next unless defined $tagobj;
3493         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3494         return [ git_rev_parse($tagobj), $what ];
3495     }
3496     fail @tagnames==1 ? <<END : <<END;
3497 Wanted tag $what (@tagnames) on dgit server, but not found
3498 END
3499 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3500 END
3501 }
3502
3503 sub infopair_cond_ff ($$) {
3504     my ($anc,$desc) = @_;
3505     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3506 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3507 END
3508 };
3509
3510 sub pseudomerge_version_check ($$) {
3511     my ($clogp, $archive_hash) = @_;
3512
3513     my $arch_clogp = commit_getclogp $archive_hash;
3514     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3515                      'version currently in archive' ];
3516     if (defined $overwrite_version) {
3517         if (length $overwrite_version) {
3518             infopair_cond_equal([ $overwrite_version,
3519                                   '--overwrite= version' ],
3520                                 $i_arch_v);
3521         } else {
3522             my $v = $i_arch_v->[0];
3523             progress "Checking package changelog for archive version $v ...";
3524             eval {
3525                 my @xa = ("-f$v", "-t$v");
3526                 my $vclogp = parsechangelog @xa;
3527                 my $cv = [ (getfield $vclogp, 'Version'),
3528                            "Version field from dpkg-parsechangelog @xa" ];
3529                 infopair_cond_equal($i_arch_v, $cv);
3530             };
3531             if ($@) {
3532                 $@ =~ s/^dgit: //gm;
3533                 fail "$@".
3534                     "Perhaps debian/changelog does not mention $v ?";
3535             }
3536         }
3537     }
3538
3539     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3540     return $i_arch_v;
3541 }
3542
3543 sub pseudomerge_make_commit ($$$$ $$) {
3544     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3545         $msg_cmd, $msg_msg) = @_;
3546     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3547
3548     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3549     my $authline = clogp_authline $clogp;
3550
3551     chomp $msg_msg;
3552     $msg_cmd .=
3553         !defined $overwrite_version ? ""
3554         : !length  $overwrite_version ? " --overwrite"
3555         : " --overwrite=".$overwrite_version;
3556
3557     mkpath '.git/dgit';
3558     my $pmf = ".git/dgit/pseudomerge";
3559     open MC, ">", $pmf or die "$pmf $!";
3560     print MC <<END or die $!;
3561 tree $tree
3562 parent $dgitview
3563 parent $archive_hash
3564 author $authline
3565 committer $authline
3566
3567 $msg_msg
3568
3569 [$msg_cmd]
3570 END
3571     close MC or die $!;
3572
3573     return make_commit($pmf);
3574 }
3575
3576 sub splitbrain_pseudomerge ($$$$) {
3577     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3578     # => $merged_dgitview
3579     printdebug "splitbrain_pseudomerge...\n";
3580     #
3581     #     We:      debian/PREVIOUS    HEAD($maintview)
3582     # expect:          o ----------------- o
3583     #                    \                   \
3584     #                     o                   o
3585     #                 a/d/PREVIOUS        $dgitview
3586     #                $archive_hash              \
3587     #  If so,                \                   \
3588     #  we do:                 `------------------ o
3589     #   this:                                   $dgitview'
3590     #
3591
3592     return $dgitview unless defined $archive_hash;
3593
3594     printdebug "splitbrain_pseudomerge...\n";
3595
3596     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3597
3598     if (!defined $overwrite_version) {
3599         progress "Checking that HEAD inciudes all changes in archive...";
3600     }
3601
3602     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3603
3604     if (defined $overwrite_version) {
3605     } elsif (!eval {
3606         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3607         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3608         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3609         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3610         my $i_archive = [ $archive_hash, "current archive contents" ];
3611
3612         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3613
3614         infopair_cond_equal($i_dgit, $i_archive);
3615         infopair_cond_ff($i_dep14, $i_dgit);
3616         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3617         1;
3618     }) {
3619         print STDERR <<END;
3620 $us: check failed (maybe --overwrite is needed, consult documentation)
3621 END
3622         die "$@";
3623     }
3624
3625     my $r = pseudomerge_make_commit
3626         $clogp, $dgitview, $archive_hash, $i_arch_v,
3627         "dgit --quilt=$quilt_mode",
3628         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3629 Declare fast forward from $i_arch_v->[0]
3630 END_OVERWR
3631 Make fast forward from $i_arch_v->[0]
3632 END_MAKEFF
3633
3634     maybe_split_brain_save $maintview, $r, "pseudomerge";
3635
3636     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3637     return $r;
3638 }
3639
3640 sub plain_overwrite_pseudomerge ($$$) {
3641     my ($clogp, $head, $archive_hash) = @_;
3642
3643     printdebug "plain_overwrite_pseudomerge...";
3644
3645     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3646
3647     return $head if is_fast_fwd $archive_hash, $head;
3648
3649     my $m = "Declare fast forward from $i_arch_v->[0]";
3650
3651     my $r = pseudomerge_make_commit
3652         $clogp, $head, $archive_hash, $i_arch_v,
3653         "dgit", $m;
3654
3655     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3656
3657     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3658     return $r;
3659 }
3660
3661 sub push_parse_changelog ($) {
3662     my ($clogpfn) = @_;
3663
3664     my $clogp = Dpkg::Control::Hash->new();
3665     $clogp->load($clogpfn) or die;
3666
3667     my $clogpackage = getfield $clogp, 'Source';
3668     $package //= $clogpackage;
3669     fail "-p specified $package but changelog specified $clogpackage"
3670         unless $package eq $clogpackage;
3671     my $cversion = getfield $clogp, 'Version';
3672     my $tag = debiantag($cversion, access_nomdistro);
3673     runcmd @git, qw(check-ref-format), $tag;
3674
3675     my $dscfn = dscfn($cversion);
3676
3677     return ($clogp, $cversion, $dscfn);
3678 }
3679
3680 sub push_parse_dsc ($$$) {
3681     my ($dscfn,$dscfnwhat, $cversion) = @_;
3682     $dsc = parsecontrol($dscfn,$dscfnwhat);
3683     my $dversion = getfield $dsc, 'Version';
3684     my $dscpackage = getfield $dsc, 'Source';
3685     ($dscpackage eq $package && $dversion eq $cversion) or
3686         fail "$dscfn is for $dscpackage $dversion".
3687             " but debian/changelog is for $package $cversion";
3688 }
3689
3690 sub push_tagwants ($$$$) {
3691     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3692     my @tagwants;
3693     push @tagwants, {
3694         TagFn => \&debiantag,
3695         Objid => $dgithead,
3696         TfSuffix => '',
3697         View => 'dgit',
3698     };
3699     if (defined $maintviewhead) {
3700         push @tagwants, {
3701             TagFn => \&debiantag_maintview,
3702             Objid => $maintviewhead,
3703             TfSuffix => '-maintview',
3704             View => 'maint',
3705         };
3706     } elsif ($dodep14tag eq 'no' ? 0
3707              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3708              : $dodep14tag eq 'always'
3709              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3710 --dep14tag-always (or equivalent in config) means server must support
3711  both "new" and "maint" tag formats, but config says it doesn't.
3712 END
3713             : die "$dodep14tag ?") {
3714         push @tagwants, {
3715             TagFn => \&debiantag_maintview,
3716             Objid => $dgithead,
3717             TfSuffix => '-dgit',
3718             View => 'dgit',
3719         };
3720     };
3721     foreach my $tw (@tagwants) {
3722         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3723         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3724     }
3725     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3726     return @tagwants;
3727 }
3728
3729 sub push_mktags ($$ $$ $) {
3730     my ($clogp,$dscfn,
3731         $changesfile,$changesfilewhat,
3732         $tagwants) = @_;
3733
3734     die unless $tagwants->[0]{View} eq 'dgit';
3735
3736     my $declaredistro = access_nomdistro();
3737     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3738     $dsc->{$ourdscfield[0]} = join " ",
3739         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3740         $reader_giturl;
3741     $dsc->save("$dscfn.tmp") or die $!;
3742
3743     my $changes = parsecontrol($changesfile,$changesfilewhat);
3744     foreach my $field (qw(Source Distribution Version)) {
3745         $changes->{$field} eq $clogp->{$field} or
3746             fail "changes field $field \`$changes->{$field}'".
3747                 " does not match changelog \`$clogp->{$field}'";
3748     }
3749
3750     my $cversion = getfield $clogp, 'Version';
3751     my $clogsuite = getfield $clogp, 'Distribution';
3752
3753     # We make the git tag by hand because (a) that makes it easier
3754     # to control the "tagger" (b) we can do remote signing
3755     my $authline = clogp_authline $clogp;
3756     my $delibs = join(" ", "",@deliberatelies);
3757
3758     my $mktag = sub {
3759         my ($tw) = @_;
3760         my $tfn = $tw->{Tfn};
3761         my $head = $tw->{Objid};
3762         my $tag = $tw->{Tag};
3763
3764         open TO, '>', $tfn->('.tmp') or die $!;
3765         print TO <<END or die $!;
3766 object $head
3767 type commit
3768 tag $tag
3769 tagger $authline
3770
3771 END
3772         if ($tw->{View} eq 'dgit') {
3773             print TO <<END or die $!;
3774 $package release $cversion for $clogsuite ($csuite) [dgit]
3775 [dgit distro=$declaredistro$delibs]
3776 END
3777             foreach my $ref (sort keys %previously) {
3778                 print TO <<END or die $!;
3779 [dgit previously:$ref=$previously{$ref}]
3780 END
3781             }
3782         } elsif ($tw->{View} eq 'maint') {
3783             print TO <<END or die $!;
3784 $package release $cversion for $clogsuite ($csuite)
3785 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3786 END
3787         } else {
3788             die Dumper($tw)."?";
3789         }
3790
3791         close TO or die $!;
3792
3793         my $tagobjfn = $tfn->('.tmp');
3794         if ($sign) {
3795             if (!defined $keyid) {
3796                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3797             }
3798             if (!defined $keyid) {
3799                 $keyid = getfield $clogp, 'Maintainer';
3800             }
3801             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3802             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3803             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3804             push @sign_cmd, $tfn->('.tmp');
3805             runcmd_ordryrun @sign_cmd;
3806             if (act_scary()) {
3807                 $tagobjfn = $tfn->('.signed.tmp');
3808                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3809                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3810             }
3811         }
3812         return $tagobjfn;
3813     };
3814
3815     my @r = map { $mktag->($_); } @$tagwants;
3816     return @r;
3817 }
3818
3819 sub sign_changes ($) {
3820     my ($changesfile) = @_;
3821     if ($sign) {
3822         my @debsign_cmd = @debsign;
3823         push @debsign_cmd, "-k$keyid" if defined $keyid;
3824         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3825         push @debsign_cmd, $changesfile;
3826         runcmd_ordryrun @debsign_cmd;
3827     }
3828 }
3829
3830 sub dopush () {
3831     printdebug "actually entering push\n";
3832
3833     supplementary_message(<<'END');
3834 Push failed, while checking state of the archive.
3835 You can retry the push, after fixing the problem, if you like.
3836 END
3837     if (check_for_git()) {
3838         git_fetch_us();
3839     }
3840     my $archive_hash = fetch_from_archive();
3841     if (!$archive_hash) {
3842         $new_package or
3843             fail "package appears to be new in this suite;".
3844                 " if this is intentional, use --new";
3845     }
3846
3847     supplementary_message(<<'END');
3848 Push failed, while preparing your push.
3849 You can retry the push, after fixing the problem, if you like.
3850 END
3851
3852     need_tagformat 'new', "quilt mode $quilt_mode"
3853         if quiltmode_splitbrain;
3854
3855     prep_ud();
3856
3857     access_giturl(); # check that success is vaguely likely
3858     select_tagformat();
3859
3860     my $clogpfn = ".git/dgit/changelog.822.tmp";
3861     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3862
3863     responder_send_file('parsed-changelog', $clogpfn);
3864
3865     my ($clogp, $cversion, $dscfn) =
3866         push_parse_changelog("$clogpfn");
3867
3868     my $dscpath = "$buildproductsdir/$dscfn";
3869     stat_exists $dscpath or
3870         fail "looked for .dsc $dscpath, but $!;".
3871             " maybe you forgot to build";
3872
3873     responder_send_file('dsc', $dscpath);
3874
3875     push_parse_dsc($dscpath, $dscfn, $cversion);
3876
3877     my $format = getfield $dsc, 'Format';
3878     printdebug "format $format\n";
3879
3880     my $actualhead = git_rev_parse('HEAD');
3881     my $dgithead = $actualhead;
3882     my $maintviewhead = undef;
3883
3884     my $upstreamversion = upstreamversion $clogp->{Version};
3885
3886     if (madformat_wantfixup($format)) {
3887         # user might have not used dgit build, so maybe do this now:
3888         if (quiltmode_splitbrain()) {
3889             changedir $ud;
3890             quilt_make_fake_dsc($upstreamversion);
3891             my $cachekey;
3892             ($dgithead, $cachekey) =
3893                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
3894             $dgithead or fail
3895  "--quilt=$quilt_mode but no cached dgit view:
3896  perhaps tree changed since dgit build[-source] ?";
3897             $split_brain = 1;
3898             $dgithead = splitbrain_pseudomerge($clogp,
3899                                                $actualhead, $dgithead,
3900                                                $archive_hash);
3901             $maintviewhead = $actualhead;
3902             changedir '../../../..';
3903             prep_ud(); # so _only_subdir() works, below
3904         } else {
3905             commit_quilty_patch();
3906         }
3907     }
3908
3909     if (defined $overwrite_version && !defined $maintviewhead) {
3910         $dgithead = plain_overwrite_pseudomerge($clogp,
3911                                                 $dgithead,
3912                                                 $archive_hash);
3913     }
3914
3915     check_not_dirty();
3916
3917     my $forceflag = '';
3918     if ($archive_hash) {
3919         if (is_fast_fwd($archive_hash, $dgithead)) {
3920             # ok
3921         } elsif (deliberately_not_fast_forward) {
3922             $forceflag = '+';
3923         } else {
3924             fail "dgit push: HEAD is not a descendant".
3925                 " of the archive's version.\n".
3926                 "To overwrite the archive's contents,".
3927                 " pass --overwrite[=VERSION].\n".
3928                 "To rewind history, if permitted by the archive,".
3929                 " use --deliberately-not-fast-forward.";
3930         }
3931     }
3932
3933     changedir $ud;
3934     progress "checking that $dscfn corresponds to HEAD";
3935     runcmd qw(dpkg-source -x --),
3936         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
3937     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
3938     check_for_vendor_patches() if madformat($dsc->{format});
3939     changedir '../../../..';
3940     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
3941     debugcmd "+",@diffcmd;
3942     $!=0; $?=-1;
3943     my $r = system @diffcmd;
3944     if ($r) {
3945         if ($r==256) {
3946             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
3947             fail <<END
3948 HEAD specifies a different tree to $dscfn:
3949 $diffs
3950 Perhaps you forgot to build.  Or perhaps there is a problem with your
3951  source tree (see dgit(7) for some hints).  To see a full diff, run
3952    git diff $tree HEAD
3953 END
3954         } else {
3955             failedcmd @diffcmd;
3956         }
3957     }
3958     if (!$changesfile) {
3959         my $pat = changespat $cversion;
3960         my @cs = glob "$buildproductsdir/$pat";
3961         fail "failed to find unique changes file".
3962             " (looked for $pat in $buildproductsdir);".
3963             " perhaps you need to use dgit -C"
3964             unless @cs==1;
3965         ($changesfile) = @cs;
3966     } else {
3967         $changesfile = "$buildproductsdir/$changesfile";
3968     }
3969
3970     # Check that changes and .dsc agree enough
3971     $changesfile =~ m{[^/]*$};
3972     my $changes = parsecontrol($changesfile,$&);
3973     files_compare_inputs($dsc, $changes)
3974         unless forceing [qw(dsc-changes-mismatch)];
3975
3976     # Perhaps adjust .dsc to contain right set of origs
3977     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
3978                                   $changesfile)
3979         unless forceing [qw(changes-origs-exactly)];
3980
3981     # Checks complete, we're going to try and go ahead:
3982
3983     responder_send_file('changes',$changesfile);
3984     responder_send_command("param head $dgithead");
3985     responder_send_command("param csuite $csuite");
3986     responder_send_command("param tagformat $tagformat");
3987     if (defined $maintviewhead) {
3988         die unless ($protovsn//4) >= 4;
3989         responder_send_command("param maint-view $maintviewhead");
3990     }
3991
3992     if (deliberately_not_fast_forward) {
3993         git_for_each_ref(lrfetchrefs, sub {
3994             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
3995             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
3996             responder_send_command("previously $rrefname=$objid");
3997             $previously{$rrefname} = $objid;
3998         });
3999     }
4000
4001     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4002                                  ".git/dgit/tag");
4003     my @tagobjfns;
4004
4005     supplementary_message(<<'END');
4006 Push failed, while signing the tag.
4007 You can retry the push, after fixing the problem, if you like.
4008 END
4009     # If we manage to sign but fail to record it anywhere, it's fine.
4010     if ($we_are_responder) {
4011         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4012         responder_receive_files('signed-tag', @tagobjfns);
4013     } else {
4014         @tagobjfns = push_mktags($clogp,$dscpath,
4015                               $changesfile,$changesfile,
4016                               \@tagwants);
4017     }
4018     supplementary_message(<<'END');
4019 Push failed, *after* signing the tag.
4020 If you want to try again, you should use a new version number.
4021 END
4022
4023     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4024
4025     foreach my $tw (@tagwants) {
4026         my $tag = $tw->{Tag};
4027         my $tagobjfn = $tw->{TagObjFn};
4028         my $tag_obj_hash =
4029             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4030         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4031         runcmd_ordryrun_local
4032             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4033     }
4034
4035     supplementary_message(<<'END');
4036 Push failed, while updating the remote git repository - see messages above.
4037 If you want to try again, you should use a new version number.
4038 END
4039     if (!check_for_git()) {
4040         create_remote_git_repo();
4041     }
4042
4043     my @pushrefs = $forceflag.$dgithead.":".rrref();
4044     foreach my $tw (@tagwants) {
4045         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4046     }
4047
4048     runcmd_ordryrun @git,
4049         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4050     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4051
4052     supplementary_message(<<'END');
4053 Push failed, while obtaining signatures on the .changes and .dsc.
4054 If it was just that the signature failed, you may try again by using
4055 debsign by hand to sign the changes
4056    $changesfile
4057 and then dput to complete the upload.
4058 If you need to change the package, you must use a new version number.
4059 END
4060     if ($we_are_responder) {
4061         my $dryrunsuffix = act_local() ? "" : ".tmp";
4062         responder_receive_files('signed-dsc-changes',
4063                                 "$dscpath$dryrunsuffix",
4064                                 "$changesfile$dryrunsuffix");
4065     } else {
4066         if (act_local()) {
4067             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4068         } else {
4069             progress "[new .dsc left in $dscpath.tmp]";
4070         }
4071         sign_changes $changesfile;
4072     }
4073
4074     supplementary_message(<<END);
4075 Push failed, while uploading package(s) to the archive server.
4076 You can retry the upload of exactly these same files with dput of:
4077   $changesfile
4078 If that .changes file is broken, you will need to use a new version
4079 number for your next attempt at the upload.
4080 END
4081     my $host = access_cfg('upload-host','RETURN-UNDEF');
4082     my @hostarg = defined($host) ? ($host,) : ();
4083     runcmd_ordryrun @dput, @hostarg, $changesfile;
4084     printdone "pushed and uploaded $cversion";
4085
4086     supplementary_message('');
4087     responder_send_command("complete");
4088 }
4089
4090 sub cmd_clone {
4091     parseopts();
4092     my $dstdir;
4093     badusage "-p is not allowed with clone; specify as argument instead"
4094         if defined $package;
4095     if (@ARGV==1) {
4096         ($package) = @ARGV;
4097     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4098         ($package,$isuite) = @ARGV;
4099     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4100         ($package,$dstdir) = @ARGV;
4101     } elsif (@ARGV==3) {
4102         ($package,$isuite,$dstdir) = @ARGV;
4103     } else {
4104         badusage "incorrect arguments to dgit clone";
4105     }
4106     notpushing();
4107
4108     $dstdir ||= "$package";
4109     if (stat_exists $dstdir) {
4110         fail "$dstdir already exists";
4111     }
4112
4113     my $cwd_remove;
4114     if ($rmonerror && !$dryrun_level) {
4115         $cwd_remove= getcwd();
4116         unshift @end, sub {
4117             return unless defined $cwd_remove;
4118             if (!chdir "$cwd_remove") {
4119                 return if $!==&ENOENT;
4120                 die "chdir $cwd_remove: $!";
4121             }
4122             printdebug "clone rmonerror removing $dstdir\n";
4123             if (stat $dstdir) {
4124                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4125             } elsif (grep { $! == $_ }
4126                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4127             } else {
4128                 print STDERR "check whether to remove $dstdir: $!\n";
4129             }
4130         };
4131     }
4132
4133     clone($dstdir);
4134     $cwd_remove = undef;
4135 }
4136
4137 sub branchsuite () {
4138     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4139     if ($branch =~ m#$lbranch_re#o) {
4140         return $1;
4141     } else {
4142         return undef;
4143     }
4144 }
4145
4146 sub fetchpullargs () {
4147     if (!defined $package) {
4148         my $sourcep = parsecontrol('debian/control','debian/control');
4149         $package = getfield $sourcep, 'Source';
4150     }
4151     if (@ARGV==0) {
4152         $isuite = branchsuite();
4153         if (!$isuite) {
4154             my $clogp = parsechangelog();
4155             $isuite = getfield $clogp, 'Distribution';
4156         }
4157     } elsif (@ARGV==1) {
4158         ($isuite) = @ARGV;
4159     } else {
4160         badusage "incorrect arguments to dgit fetch or dgit pull";
4161     }
4162     notpushing();
4163 }
4164
4165 sub cmd_fetch {
4166     parseopts();
4167     fetchpullargs();
4168     my $multi_fetched = fork_for_multisuite(sub { });
4169     exit 0 if $multi_fetched;
4170     fetch();
4171 }
4172
4173 sub cmd_pull {
4174     parseopts();
4175     fetchpullargs();
4176     if (quiltmode_splitbrain()) {
4177         my ($format, $fopts) = get_source_format();
4178         madformat($format) and fail <<END
4179 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4180 END
4181     }
4182     pull();
4183 }
4184
4185 sub cmd_push {
4186     parseopts();
4187     pushing();
4188     badusage "-p is not allowed with dgit push" if defined $package;
4189     check_not_dirty();
4190     my $clogp = parsechangelog();
4191     $package = getfield $clogp, 'Source';
4192     my $specsuite;
4193     if (@ARGV==0) {
4194     } elsif (@ARGV==1) {
4195         ($specsuite) = (@ARGV);
4196     } else {
4197         badusage "incorrect arguments to dgit push";
4198     }
4199     $isuite = getfield $clogp, 'Distribution';
4200     if ($new_package) {
4201         local ($package) = $existing_package; # this is a hack
4202         canonicalise_suite();
4203     } else {
4204         canonicalise_suite();
4205     }
4206     if (defined $specsuite &&
4207         $specsuite ne $isuite &&
4208         $specsuite ne $csuite) {
4209             fail "dgit push: changelog specifies $isuite ($csuite)".
4210                 " but command line specifies $specsuite";
4211     }
4212     dopush();
4213 }
4214
4215 #---------- remote commands' implementation ----------
4216
4217 sub cmd_remote_push_build_host {
4218     my ($nrargs) = shift @ARGV;
4219     my (@rargs) = @ARGV[0..$nrargs-1];
4220     @ARGV = @ARGV[$nrargs..$#ARGV];
4221     die unless @rargs;
4222     my ($dir,$vsnwant) = @rargs;
4223     # vsnwant is a comma-separated list; we report which we have
4224     # chosen in our ready response (so other end can tell if they
4225     # offered several)
4226     $debugprefix = ' ';
4227     $we_are_responder = 1;
4228     $us .= " (build host)";
4229
4230     pushing();
4231
4232     open PI, "<&STDIN" or die $!;
4233     open STDIN, "/dev/null" or die $!;
4234     open PO, ">&STDOUT" or die $!;
4235     autoflush PO 1;
4236     open STDOUT, ">&STDERR" or die $!;
4237     autoflush STDOUT 1;
4238
4239     $vsnwant //= 1;
4240     ($protovsn) = grep {
4241         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4242     } @rpushprotovsn_support;
4243
4244     fail "build host has dgit rpush protocol versions ".
4245         (join ",", @rpushprotovsn_support).
4246         " but invocation host has $vsnwant"
4247         unless defined $protovsn;
4248
4249     responder_send_command("dgit-remote-push-ready $protovsn");
4250     rpush_handle_protovsn_bothends();
4251     changedir $dir;
4252     &cmd_push;
4253 }
4254
4255 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4256 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4257 #     a good error message)
4258
4259 sub rpush_handle_protovsn_bothends () {
4260     if ($protovsn < 4) {
4261         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4262     }
4263     select_tagformat();
4264 }
4265
4266 our $i_tmp;
4267
4268 sub i_cleanup {
4269     local ($@, $?);
4270     my $report = i_child_report();
4271     if (defined $report) {
4272         printdebug "($report)\n";
4273     } elsif ($i_child_pid) {
4274         printdebug "(killing build host child $i_child_pid)\n";
4275         kill 15, $i_child_pid;
4276     }
4277     if (defined $i_tmp && !defined $initiator_tempdir) {
4278         changedir "/";
4279         eval { rmtree $i_tmp; };
4280     }
4281 }
4282
4283 END { i_cleanup(); }
4284
4285 sub i_method {
4286     my ($base,$selector,@args) = @_;
4287     $selector =~ s/\-/_/g;
4288     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4289 }
4290
4291 sub cmd_rpush {
4292     pushing();
4293     my $host = nextarg;
4294     my $dir;
4295     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4296         $host = $1;
4297         $dir = $'; #';
4298     } else {
4299         $dir = nextarg;
4300     }
4301     $dir =~ s{^-}{./-};
4302     my @rargs = ($dir);
4303     push @rargs, join ",", @rpushprotovsn_support;
4304     my @rdgit;
4305     push @rdgit, @dgit;
4306     push @rdgit, @ropts;
4307     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4308     push @rdgit, @ARGV;
4309     my @cmd = (@ssh, $host, shellquote @rdgit);
4310     debugcmd "+",@cmd;
4311
4312     if (defined $initiator_tempdir) {
4313         rmtree $initiator_tempdir;
4314         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4315         $i_tmp = $initiator_tempdir;
4316     } else {
4317         $i_tmp = tempdir();
4318     }
4319     $i_child_pid = open2(\*RO, \*RI, @cmd);
4320     changedir $i_tmp;
4321     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4322     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4323     $supplementary_message = '' unless $protovsn >= 3;
4324
4325     fail "rpush negotiated protocol version $protovsn".
4326         " which does not support quilt mode $quilt_mode"
4327         if quiltmode_splitbrain;
4328
4329     rpush_handle_protovsn_bothends();
4330     for (;;) {
4331         my ($icmd,$iargs) = initiator_expect {
4332             m/^(\S+)(?: (.*))?$/;
4333             ($1,$2);
4334         };
4335         i_method "i_resp", $icmd, $iargs;
4336     }
4337 }
4338
4339 sub i_resp_progress ($) {
4340     my ($rhs) = @_;
4341     my $msg = protocol_read_bytes \*RO, $rhs;
4342     progress $msg;
4343 }
4344
4345 sub i_resp_supplementary_message ($) {
4346     my ($rhs) = @_;
4347     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4348 }
4349
4350 sub i_resp_complete {
4351     my $pid = $i_child_pid;
4352     $i_child_pid = undef; # prevents killing some other process with same pid
4353     printdebug "waiting for build host child $pid...\n";
4354     my $got = waitpid $pid, 0;
4355     die $! unless $got == $pid;
4356     die "build host child failed $?" if $?;
4357
4358     i_cleanup();
4359     printdebug "all done\n";
4360     exit 0;
4361 }
4362
4363 sub i_resp_file ($) {
4364     my ($keyword) = @_;
4365     my $localname = i_method "i_localname", $keyword;
4366     my $localpath = "$i_tmp/$localname";
4367     stat_exists $localpath and
4368         badproto \*RO, "file $keyword ($localpath) twice";
4369     protocol_receive_file \*RO, $localpath;
4370     i_method "i_file", $keyword;
4371 }
4372
4373 our %i_param;
4374
4375 sub i_resp_param ($) {
4376     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4377     $i_param{$1} = $2;
4378 }
4379
4380 sub i_resp_previously ($) {
4381     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4382         or badproto \*RO, "bad previously spec";
4383     my $r = system qw(git check-ref-format), $1;
4384     die "bad previously ref spec ($r)" if $r;
4385     $previously{$1} = $2;
4386 }
4387
4388 our %i_wanted;
4389
4390 sub i_resp_want ($) {
4391     my ($keyword) = @_;
4392     die "$keyword ?" if $i_wanted{$keyword}++;
4393     my @localpaths = i_method "i_want", $keyword;
4394     printdebug "[[  $keyword @localpaths\n";
4395     foreach my $localpath (@localpaths) {
4396         protocol_send_file \*RI, $localpath;
4397     }
4398     print RI "files-end\n" or die $!;
4399 }
4400
4401 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4402
4403 sub i_localname_parsed_changelog {
4404     return "remote-changelog.822";
4405 }
4406 sub i_file_parsed_changelog {
4407     ($i_clogp, $i_version, $i_dscfn) =
4408         push_parse_changelog "$i_tmp/remote-changelog.822";
4409     die if $i_dscfn =~ m#/|^\W#;
4410 }
4411
4412 sub i_localname_dsc {
4413     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4414     return $i_dscfn;
4415 }
4416 sub i_file_dsc { }
4417
4418 sub i_localname_changes {
4419     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4420     $i_changesfn = $i_dscfn;
4421     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4422     return $i_changesfn;
4423 }
4424 sub i_file_changes { }
4425
4426 sub i_want_signed_tag {
4427     printdebug Dumper(\%i_param, $i_dscfn);
4428     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4429         && defined $i_param{'csuite'}
4430         or badproto \*RO, "premature desire for signed-tag";
4431     my $head = $i_param{'head'};
4432     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4433
4434     my $maintview = $i_param{'maint-view'};
4435     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4436
4437     select_tagformat();
4438     if ($protovsn >= 4) {
4439         my $p = $i_param{'tagformat'} // '<undef>';
4440         $p eq $tagformat
4441             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4442     }
4443
4444     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4445     $csuite = $&;
4446     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4447
4448     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4449
4450     return
4451         push_mktags $i_clogp, $i_dscfn,
4452             $i_changesfn, 'remote changes',
4453             \@tagwants;
4454 }
4455
4456 sub i_want_signed_dsc_changes {
4457     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4458     sign_changes $i_changesfn;
4459     return ($i_dscfn, $i_changesfn);
4460 }
4461
4462 #---------- building etc. ----------
4463
4464 our $version;
4465 our $sourcechanges;
4466 our $dscfn;
4467
4468 #----- `3.0 (quilt)' handling -----
4469
4470 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4471
4472 sub quiltify_dpkg_commit ($$$;$) {
4473     my ($patchname,$author,$msg, $xinfo) = @_;
4474     $xinfo //= '';
4475
4476     mkpath '.git/dgit';
4477     my $descfn = ".git/dgit/quilt-description.tmp";
4478     open O, '>', $descfn or die "$descfn: $!";
4479     $msg =~ s/\n+/\n\n/;
4480     print O <<END or die $!;
4481 From: $author
4482 ${xinfo}Subject: $msg
4483 ---
4484
4485 END
4486     close O or die $!;
4487
4488     {
4489         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4490         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4491         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4492         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4493     }
4494 }
4495
4496 sub quiltify_trees_differ ($$;$$$) {
4497     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4498     # returns true iff the two tree objects differ other than in debian/
4499     # with $finegrained,
4500     # returns bitmask 01 - differ in upstream files except .gitignore
4501     #                 02 - differ in .gitignore
4502     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4503     #  is set for each modified .gitignore filename $fn
4504     # if $unrepres is defined, array ref to which is appeneded
4505     #  a list of unrepresentable changes (removals of upstream files
4506     #  (as messages)
4507     local $/=undef;
4508     my @cmd = (@git, qw(diff-tree -z));
4509     push @cmd, qw(--name-only) unless $unrepres;
4510     push @cmd, qw(-r) if $finegrained || $unrepres;
4511     push @cmd, $x, $y;
4512     my $diffs= cmdoutput @cmd;
4513     my $r = 0;
4514     my @lmodes;
4515     foreach my $f (split /\0/, $diffs) {
4516         if ($unrepres && !@lmodes) {
4517             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4518             next;
4519         }
4520         my ($oldmode,$newmode) = @lmodes;
4521         @lmodes = ();
4522
4523         next if $f =~ m#^debian(?:/.*)?$#s;
4524
4525         if ($unrepres) {
4526             eval {
4527                 die "not a plain file\n"
4528                     unless $newmode =~ m/^10\d{4}$/ ||
4529                            $oldmode =~ m/^10\d{4}$/;
4530                 if ($oldmode =~ m/[^0]/ &&
4531                     $newmode =~ m/[^0]/) {
4532                     die "mode changed\n" if $oldmode ne $newmode;
4533                 } else {
4534                     die "non-default mode\n"
4535                         unless $newmode =~ m/^100644$/ ||
4536                                $oldmode =~ m/^100644$/;
4537                 }
4538             };
4539             if ($@) {
4540                 local $/="\n"; chomp $@;
4541                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4542             }
4543         }
4544
4545         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4546         $r |= $isignore ? 02 : 01;
4547         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4548     }
4549     printdebug "quiltify_trees_differ $x $y => $r\n";
4550     return $r;
4551 }
4552
4553 sub quiltify_tree_sentinelfiles ($) {
4554     # lists the `sentinel' files present in the tree
4555     my ($x) = @_;
4556     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4557         qw(-- debian/rules debian/control);
4558     $r =~ s/\n/,/g;
4559     return $r;
4560 }
4561
4562 sub quiltify_splitbrain_needed () {
4563     if (!$split_brain) {
4564         progress "dgit view: changes are required...";
4565         runcmd @git, qw(checkout -q -b dgit-view);
4566         $split_brain = 1;
4567     }
4568 }
4569
4570 sub quiltify_splitbrain ($$$$$$) {
4571     my ($clogp, $unapplied, $headref, $diffbits,
4572         $editedignores, $cachekey) = @_;
4573     if ($quilt_mode !~ m/gbp|dpm/) {
4574         # treat .gitignore just like any other upstream file
4575         $diffbits = { %$diffbits };
4576         $_ = !!$_ foreach values %$diffbits;
4577     }
4578     # We would like any commits we generate to be reproducible
4579     my @authline = clogp_authline($clogp);
4580     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4581     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4582     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4583     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4584     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4585     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4586
4587     if ($quilt_mode =~ m/gbp|unapplied/ &&
4588         ($diffbits->{O2H} & 01)) {
4589         my $msg =
4590  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4591  " but git tree differs from orig in upstream files.";
4592         if (!stat_exists "debian/patches") {
4593             $msg .=
4594  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4595         }
4596         fail $msg;
4597     }
4598     if ($quilt_mode =~ m/dpm/ &&
4599         ($diffbits->{H2A} & 01)) {
4600         fail <<END;
4601 --quilt=$quilt_mode specified, implying patches-applied git tree
4602  but git tree differs from result of applying debian/patches to upstream
4603 END
4604     }
4605     if ($quilt_mode =~ m/gbp|unapplied/ &&
4606         ($diffbits->{O2A} & 01)) { # some patches
4607         quiltify_splitbrain_needed();
4608         progress "dgit view: creating patches-applied version using gbp pq";
4609         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4610         # gbp pq import creates a fresh branch; push back to dgit-view
4611         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4612         runcmd @git, qw(checkout -q dgit-view);
4613     }
4614     if ($quilt_mode =~ m/gbp|dpm/ &&
4615         ($diffbits->{O2A} & 02)) {
4616         fail <<END
4617 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4618  tool which does not create patches for changes to upstream
4619  .gitignores: but, such patches exist in debian/patches.
4620 END
4621     }
4622     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4623         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4624         quiltify_splitbrain_needed();
4625         progress "dgit view: creating patch to represent .gitignore changes";
4626         ensuredir "debian/patches";
4627         my $gipatch = "debian/patches/auto-gitignore";
4628         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4629         stat GIPATCH or die "$gipatch: $!";
4630         fail "$gipatch already exists; but want to create it".
4631             " to record .gitignore changes" if (stat _)[7];
4632         print GIPATCH <<END or die "$gipatch: $!";
4633 Subject: Update .gitignore from Debian packaging branch
4634
4635 The Debian packaging git branch contains these updates to the upstream
4636 .gitignore file(s).  This patch is autogenerated, to provide these
4637 updates to users of the official Debian archive view of the package.
4638
4639 [dgit ($our_version) update-gitignore]
4640 ---
4641 END
4642         close GIPATCH or die "$gipatch: $!";
4643         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4644             $unapplied, $headref, "--", sort keys %$editedignores;
4645         open SERIES, "+>>", "debian/patches/series" or die $!;
4646         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4647         my $newline;
4648         defined read SERIES, $newline, 1 or die $!;
4649         print SERIES "\n" or die $! unless $newline eq "\n";
4650         print SERIES "auto-gitignore\n" or die $!;
4651         close SERIES or die  $!;
4652         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4653         commit_admin <<END
4654 Commit patch to update .gitignore
4655
4656 [dgit ($our_version) update-gitignore-quilt-fixup]
4657 END
4658     }
4659
4660     my $dgitview = git_rev_parse 'HEAD';
4661
4662     changedir '../../../..';
4663     # When we no longer need to support squeeze, use --create-reflog
4664     # instead of this:
4665     ensuredir ".git/logs/refs/dgit-intern";
4666     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4667       or die $!;
4668
4669     my $oldcache = git_get_ref "refs/$splitbraincache";
4670     if ($oldcache eq $dgitview) {
4671         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4672         # git update-ref doesn't always update, in this case.  *sigh*
4673         my $dummy = make_commit_text <<END;
4674 tree $tree
4675 parent $dgitview
4676 author Dgit <dgit\@example.com> 1000000000 +0000
4677 committer Dgit <dgit\@example.com> 1000000000 +0000
4678
4679 Dummy commit - do not use
4680 END
4681         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4682             "refs/$splitbraincache", $dummy;
4683     }
4684     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4685         $dgitview;
4686
4687     changedir '.git/dgit/unpack/work';
4688
4689     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4690     progress "dgit view: created ($saved)";
4691 }
4692
4693 sub quiltify ($$$$) {
4694     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4695
4696     # Quilt patchification algorithm
4697     #
4698     # We search backwards through the history of the main tree's HEAD
4699     # (T) looking for a start commit S whose tree object is identical
4700     # to to the patch tip tree (ie the tree corresponding to the
4701     # current dpkg-committed patch series).  For these purposes
4702     # `identical' disregards anything in debian/ - this wrinkle is
4703     # necessary because dpkg-source treates debian/ specially.
4704     #
4705     # We can only traverse edges where at most one of the ancestors'
4706     # trees differs (in changes outside in debian/).  And we cannot
4707     # handle edges which change .pc/ or debian/patches.  To avoid
4708     # going down a rathole we avoid traversing edges which introduce
4709     # debian/rules or debian/control.  And we set a limit on the
4710     # number of edges we are willing to look at.
4711     #
4712     # If we succeed, we walk forwards again.  For each traversed edge
4713     # PC (with P parent, C child) (starting with P=S and ending with
4714     # C=T) to we do this:
4715     #  - git checkout C
4716     #  - dpkg-source --commit with a patch name and message derived from C
4717     # After traversing PT, we git commit the changes which
4718     # should be contained within debian/patches.
4719
4720     # The search for the path S..T is breadth-first.  We maintain a
4721     # todo list containing search nodes.  A search node identifies a
4722     # commit, and looks something like this:
4723     #  $p = {
4724     #      Commit => $git_commit_id,
4725     #      Child => $c,                          # or undef if P=T
4726     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4727     #      Nontrivial => true iff $p..$c has relevant changes
4728     #  };
4729
4730     my @todo;
4731     my @nots;
4732     my $sref_S;
4733     my $max_work=100;
4734     my %considered; # saves being exponential on some weird graphs
4735
4736     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4737
4738     my $not = sub {
4739         my ($search,$whynot) = @_;
4740         printdebug " search NOT $search->{Commit} $whynot\n";
4741         $search->{Whynot} = $whynot;
4742         push @nots, $search;
4743         no warnings qw(exiting);
4744         next;
4745     };
4746
4747     push @todo, {
4748         Commit => $target,
4749     };
4750
4751     while (@todo) {
4752         my $c = shift @todo;
4753         next if $considered{$c->{Commit}}++;
4754
4755         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4756
4757         printdebug "quiltify investigate $c->{Commit}\n";
4758
4759         # are we done?
4760         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4761             printdebug " search finished hooray!\n";
4762             $sref_S = $c;
4763             last;
4764         }
4765
4766         if ($quilt_mode eq 'nofix') {
4767             fail "quilt fixup required but quilt mode is \`nofix'\n".
4768                 "HEAD commit $c->{Commit} differs from tree implied by ".
4769                 " debian/patches (tree object $oldtiptree)";
4770         }
4771         if ($quilt_mode eq 'smash') {
4772             printdebug " search quitting smash\n";
4773             last;
4774         }
4775
4776         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4777         $not->($c, "has $c_sentinels not $t_sentinels")
4778             if $c_sentinels ne $t_sentinels;
4779
4780         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4781         $commitdata =~ m/\n\n/;
4782         $commitdata =~ $`;
4783         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4784         @parents = map { { Commit => $_, Child => $c } } @parents;
4785
4786         $not->($c, "root commit") if !@parents;
4787
4788         foreach my $p (@parents) {
4789             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4790         }
4791         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4792         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4793
4794         foreach my $p (@parents) {
4795             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4796
4797             my @cmd= (@git, qw(diff-tree -r --name-only),
4798                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4799             my $patchstackchange = cmdoutput @cmd;
4800             if (length $patchstackchange) {
4801                 $patchstackchange =~ s/\n/,/g;
4802                 $not->($p, "changed $patchstackchange");
4803             }
4804
4805             printdebug " search queue P=$p->{Commit} ",
4806                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4807             push @todo, $p;
4808         }
4809     }
4810
4811     if (!$sref_S) {
4812         printdebug "quiltify want to smash\n";
4813
4814         my $abbrev = sub {
4815             my $x = $_[0]{Commit};
4816             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4817             return $x;
4818         };
4819         my $reportnot = sub {
4820             my ($notp) = @_;
4821             my $s = $abbrev->($notp);
4822             my $c = $notp->{Child};
4823             $s .= "..".$abbrev->($c) if $c;
4824             $s .= ": ".$notp->{Whynot};
4825             return $s;
4826         };
4827         if ($quilt_mode eq 'linear') {
4828             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4829             foreach my $notp (@nots) {
4830                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4831             }
4832             print STDERR "$us: $_\n" foreach @$failsuggestion;
4833             fail "quilt fixup naive history linearisation failed.\n".
4834  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4835         } elsif ($quilt_mode eq 'smash') {
4836         } elsif ($quilt_mode eq 'auto') {
4837             progress "quilt fixup cannot be linear, smashing...";
4838         } else {
4839             die "$quilt_mode ?";
4840         }
4841
4842         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4843         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4844         my $ncommits = 3;
4845         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4846
4847         quiltify_dpkg_commit "auto-$version-$target-$time",
4848             (getfield $clogp, 'Maintainer'),
4849             "Automatically generated patch ($clogp->{Version})\n".
4850             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4851         return;
4852     }
4853
4854     progress "quiltify linearisation planning successful, executing...";
4855
4856     for (my $p = $sref_S;
4857          my $c = $p->{Child};
4858          $p = $p->{Child}) {
4859         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
4860         next unless $p->{Nontrivial};
4861
4862         my $cc = $c->{Commit};
4863
4864         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
4865         $commitdata =~ m/\n\n/ or die "$c ?";
4866         $commitdata = $`;
4867         my $msg = $'; #';
4868         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
4869         my $author = $1;
4870
4871         my $commitdate = cmdoutput
4872             @git, qw(log -n1 --pretty=format:%aD), $cc;
4873
4874         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
4875
4876         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
4877         $strip_nls->();
4878
4879         my $title = $1;
4880         my $patchname;
4881         my $patchdir;
4882
4883         my $gbp_check_suitable = sub {
4884             $_ = shift;
4885             my ($what) = @_;
4886
4887             eval {
4888                 die "contains unexpected slashes\n" if m{//} || m{/$};
4889                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
4890                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
4891                 die "too long" if length > 200;
4892             };
4893             return $_ unless $@;
4894             print STDERR "quiltifying commit $cc:".
4895                 " ignoring/dropping Gbp-Pq $what: $@";
4896             return undef;
4897         };
4898
4899         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
4900                            gbp-pq-name: \s* )
4901                        (\S+) \s* \n //ixm) {
4902             $patchname = $gbp_check_suitable->($1, 'Name');
4903         }
4904         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
4905                            gbp-pq-topic: \s* )
4906                        (\S+) \s* \n //ixm) {
4907             $patchdir = $gbp_check_suitable->($1, 'Topic');
4908         }
4909
4910         $strip_nls->();
4911
4912         if (!defined $patchname) {
4913             $patchname = $title;
4914             $patchname =~ s/[.:]$//;
4915             use Text::Iconv;
4916             eval {
4917                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
4918                 my $translitname = $converter->convert($patchname);
4919                 die unless defined $translitname;
4920                 $patchname = $translitname;
4921             };
4922             print STDERR
4923                 "dgit: patch title transliteration error: $@"
4924                 if $@;
4925             $patchname =~ y/ A-Z/-a-z/;
4926             $patchname =~ y/-a-z0-9_.+=~//cd;
4927             $patchname =~ s/^\W/x-$&/;
4928             $patchname = substr($patchname,0,40);
4929         }
4930         if (!defined $patchdir) {
4931             $patchdir = '';
4932         }
4933         if (length $patchdir) {
4934             $patchname = "$patchdir/$patchname";
4935         }
4936         if ($patchname =~ m{^(.*)/}) {
4937             mkpath "debian/patches/$1";
4938         }
4939
4940         my $index;
4941         for ($index='';
4942              stat "debian/patches/$patchname$index";
4943              $index++) { }
4944         $!==ENOENT or die "$patchname$index $!";
4945
4946         runcmd @git, qw(checkout -q), $cc;
4947
4948         # We use the tip's changelog so that dpkg-source doesn't
4949         # produce complaining messages from dpkg-parsechangelog.  None
4950         # of the information dpkg-source gets from the changelog is
4951         # actually relevant - it gets put into the original message
4952         # which dpkg-source provides our stunt editor, and then
4953         # overwritten.
4954         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
4955
4956         quiltify_dpkg_commit "$patchname$index", $author, $msg,
4957             "Date: $commitdate\n".
4958             "X-Dgit-Generated: $clogp->{Version} $cc\n";
4959
4960         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
4961     }
4962
4963     runcmd @git, qw(checkout -q master);
4964 }
4965
4966 sub build_maybe_quilt_fixup () {
4967     my ($format,$fopts) = get_source_format;
4968     return unless madformat_wantfixup $format;
4969     # sigh
4970
4971     check_for_vendor_patches();
4972
4973     if (quiltmode_splitbrain) {
4974         fail <<END unless access_cfg_tagformats_can_splitbrain;
4975 quilt mode $quilt_mode requires split view so server needs to support
4976  both "new" and "maint" tag formats, but config says it doesn't.
4977 END
4978     }
4979
4980     my $clogp = parsechangelog();
4981     my $headref = git_rev_parse('HEAD');
4982
4983     prep_ud();
4984     changedir $ud;
4985
4986     my $upstreamversion = upstreamversion $version;
4987
4988     if ($fopts->{'single-debian-patch'}) {
4989         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
4990     } else {
4991         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
4992     }
4993
4994     die 'bug' if $split_brain && !$need_split_build_invocation;
4995
4996     changedir '../../../..';
4997     runcmd_ordryrun_local
4998         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
4999 }
5000
5001 sub quilt_fixup_mkwork ($) {
5002     my ($headref) = @_;
5003
5004     mkdir "work" or die $!;
5005     changedir "work";
5006     mktree_in_ud_here();
5007     runcmd @git, qw(reset -q --hard), $headref;
5008 }
5009
5010 sub quilt_fixup_linkorigs ($$) {
5011     my ($upstreamversion, $fn) = @_;
5012     # calls $fn->($leafname);
5013
5014     foreach my $f (<../../../../*>) { #/){
5015         my $b=$f; $b =~ s{.*/}{};
5016         {
5017             local ($debuglevel) = $debuglevel-1;
5018             printdebug "QF linkorigs $b, $f ?\n";
5019         }
5020         next unless is_orig_file_of_vsn $b, $upstreamversion;
5021         printdebug "QF linkorigs $b, $f Y\n";
5022         link_ltarget $f, $b or die "$b $!";
5023         $fn->($b);
5024     }
5025 }
5026
5027 sub quilt_fixup_delete_pc () {
5028     runcmd @git, qw(rm -rqf .pc);
5029     commit_admin <<END
5030 Commit removal of .pc (quilt series tracking data)
5031
5032 [dgit ($our_version) upgrade quilt-remove-pc]
5033 END
5034 }
5035
5036 sub quilt_fixup_singlepatch ($$$) {
5037     my ($clogp, $headref, $upstreamversion) = @_;
5038
5039     progress "starting quiltify (single-debian-patch)";
5040
5041     # dpkg-source --commit generates new patches even if
5042     # single-debian-patch is in debian/source/options.  In order to
5043     # get it to generate debian/patches/debian-changes, it is
5044     # necessary to build the source package.
5045
5046     quilt_fixup_linkorigs($upstreamversion, sub { });
5047     quilt_fixup_mkwork($headref);
5048
5049     rmtree("debian/patches");
5050
5051     runcmd @dpkgsource, qw(-b .);
5052     changedir "..";
5053     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5054     rename srcfn("$upstreamversion", "/debian/patches"),
5055            "work/debian/patches";
5056
5057     changedir "work";
5058     commit_quilty_patch();
5059 }
5060
5061 sub quilt_make_fake_dsc ($) {
5062     my ($upstreamversion) = @_;
5063
5064     my $fakeversion="$upstreamversion-~~DGITFAKE";
5065
5066     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5067     print $fakedsc <<END or die $!;
5068 Format: 3.0 (quilt)
5069 Source: $package
5070 Version: $fakeversion
5071 Files:
5072 END
5073
5074     my $dscaddfile=sub {
5075         my ($b) = @_;
5076
5077         my $md = new Digest::MD5;
5078
5079         my $fh = new IO::File $b, '<' or die "$b $!";
5080         stat $fh or die $!;
5081         my $size = -s _;
5082
5083         $md->addfile($fh);
5084         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5085     };
5086
5087     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5088
5089     my @files=qw(debian/source/format debian/rules
5090                  debian/control debian/changelog);
5091     foreach my $maybe (qw(debian/patches debian/source/options
5092                           debian/tests/control)) {
5093         next unless stat_exists "../../../$maybe";
5094         push @files, $maybe;
5095     }
5096
5097     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5098     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5099
5100     $dscaddfile->($debtar);
5101     close $fakedsc or die $!;
5102 }
5103
5104 sub quilt_check_splitbrain_cache ($$) {
5105     my ($headref, $upstreamversion) = @_;
5106     # Called only if we are in (potentially) split brain mode.
5107     # Called in $ud.
5108     # Computes the cache key and looks in the cache.
5109     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5110
5111     my $splitbrain_cachekey;
5112
5113     progress
5114  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5115     # we look in the reflog of dgit-intern/quilt-cache
5116     # we look for an entry whose message is the key for the cache lookup
5117     my @cachekey = (qw(dgit), $our_version);
5118     push @cachekey, $upstreamversion;
5119     push @cachekey, $quilt_mode;
5120     push @cachekey, $headref;
5121
5122     push @cachekey, hashfile('fake.dsc');
5123
5124     my $srcshash = Digest::SHA->new(256);
5125     my %sfs = ( %INC, '$0(dgit)' => $0 );
5126     foreach my $sfk (sort keys %sfs) {
5127         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5128         $srcshash->add($sfk,"  ");
5129         $srcshash->add(hashfile($sfs{$sfk}));
5130         $srcshash->add("\n");
5131     }
5132     push @cachekey, $srcshash->hexdigest();
5133     $splitbrain_cachekey = "@cachekey";
5134
5135     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5136                $splitbraincache);
5137     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5138     debugcmd "|(probably)",@cmd;
5139     my $child = open GC, "-|";  defined $child or die $!;
5140     if (!$child) {
5141         chdir '../../..' or die $!;
5142         if (!stat ".git/logs/refs/$splitbraincache") {
5143             $! == ENOENT or die $!;
5144             printdebug ">(no reflog)\n";
5145             exit 0;
5146         }
5147         exec @cmd; die $!;
5148     }
5149     while (<GC>) {
5150         chomp;
5151         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5152         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5153
5154         my $cachehit = $1;
5155         quilt_fixup_mkwork($headref);
5156         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5157         if ($cachehit ne $headref) {
5158             progress "dgit view: found cached ($saved)";
5159             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5160             $split_brain = 1;
5161             return ($cachehit, $splitbrain_cachekey);
5162         }
5163         progress "dgit view: found cached, no changes required";
5164         return ($headref, $splitbrain_cachekey);
5165     }
5166     die $! if GC->error;
5167     failedcmd unless close GC;
5168
5169     printdebug "splitbrain cache miss\n";
5170     return (undef, $splitbrain_cachekey);
5171 }
5172
5173 sub quilt_fixup_multipatch ($$$) {
5174     my ($clogp, $headref, $upstreamversion) = @_;
5175
5176     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5177
5178     # Our objective is:
5179     #  - honour any existing .pc in case it has any strangeness
5180     #  - determine the git commit corresponding to the tip of
5181     #    the patch stack (if there is one)
5182     #  - if there is such a git commit, convert each subsequent
5183     #    git commit into a quilt patch with dpkg-source --commit
5184     #  - otherwise convert all the differences in the tree into
5185     #    a single git commit
5186     #
5187     # To do this we:
5188
5189     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5190     # dgit would include the .pc in the git tree.)  If there isn't
5191     # one, we need to generate one by unpacking the patches that we
5192     # have.
5193     #
5194     # We first look for a .pc in the git tree.  If there is one, we
5195     # will use it.  (This is not the normal case.)
5196     #
5197     # Otherwise need to regenerate .pc so that dpkg-source --commit
5198     # can work.  We do this as follows:
5199     #     1. Collect all relevant .orig from parent directory
5200     #     2. Generate a debian.tar.gz out of
5201     #         debian/{patches,rules,source/format,source/options}
5202     #     3. Generate a fake .dsc containing just these fields:
5203     #          Format Source Version Files
5204     #     4. Extract the fake .dsc
5205     #        Now the fake .dsc has a .pc directory.
5206     # (In fact we do this in every case, because in future we will
5207     # want to search for a good base commit for generating patches.)
5208     #
5209     # Then we can actually do the dpkg-source --commit
5210     #     1. Make a new working tree with the same object
5211     #        store as our main tree and check out the main
5212     #        tree's HEAD.
5213     #     2. Copy .pc from the fake's extraction, if necessary
5214     #     3. Run dpkg-source --commit
5215     #     4. If the result has changes to debian/, then
5216     #          - git add them them
5217     #          - git add .pc if we had a .pc in-tree
5218     #          - git commit
5219     #     5. If we had a .pc in-tree, delete it, and git commit
5220     #     6. Back in the main tree, fast forward to the new HEAD
5221
5222     # Another situation we may have to cope with is gbp-style
5223     # patches-unapplied trees.
5224     #
5225     # We would want to detect these, so we know to escape into
5226     # quilt_fixup_gbp.  However, this is in general not possible.
5227     # Consider a package with a one patch which the dgit user reverts
5228     # (with git revert or the moral equivalent).
5229     #
5230     # That is indistinguishable in contents from a patches-unapplied
5231     # tree.  And looking at the history to distinguish them is not
5232     # useful because the user might have made a confusing-looking git
5233     # history structure (which ought to produce an error if dgit can't
5234     # cope, not a silent reintroduction of an unwanted patch).
5235     #
5236     # So gbp users will have to pass an option.  But we can usually
5237     # detect their failure to do so: if the tree is not a clean
5238     # patches-applied tree, quilt linearisation fails, but the tree
5239     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5240     # they want --quilt=unapplied.
5241     #
5242     # To help detect this, when we are extracting the fake dsc, we
5243     # first extract it with --skip-patches, and then apply the patches
5244     # afterwards with dpkg-source --before-build.  That lets us save a
5245     # tree object corresponding to .origs.
5246
5247     my $splitbrain_cachekey;
5248
5249     quilt_make_fake_dsc($upstreamversion);
5250
5251     if (quiltmode_splitbrain()) {
5252         my $cachehit;
5253         ($cachehit, $splitbrain_cachekey) =
5254             quilt_check_splitbrain_cache($headref, $upstreamversion);
5255         return if $cachehit;
5256     }
5257
5258     runcmd qw(sh -ec),
5259         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5260
5261     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5262     rename $fakexdir, "fake" or die "$fakexdir $!";
5263
5264     changedir 'fake';
5265
5266     remove_stray_gits("source package");
5267     mktree_in_ud_here();
5268
5269     rmtree '.pc';
5270
5271     my $unapplied=git_add_write_tree();
5272     printdebug "fake orig tree object $unapplied\n";
5273
5274     ensuredir '.pc';
5275
5276     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5277     $!=0; $?=-1;
5278     if (system @bbcmd) {
5279         failedcmd @bbcmd if $? < 0;
5280         fail <<END;
5281 failed to apply your git tree's patch stack (from debian/patches/) to
5282  the corresponding upstream tarball(s).  Your source tree and .orig
5283  are probably too inconsistent.  dgit can only fix up certain kinds of
5284  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5285 END
5286     }
5287
5288     changedir '..';
5289
5290     quilt_fixup_mkwork($headref);
5291
5292     my $mustdeletepc=0;
5293     if (stat_exists ".pc") {
5294         -d _ or die;
5295         progress "Tree already contains .pc - will use it then delete it.";
5296         $mustdeletepc=1;
5297     } else {
5298         rename '../fake/.pc','.pc' or die $!;
5299     }
5300
5301     changedir '../fake';
5302     rmtree '.pc';
5303     my $oldtiptree=git_add_write_tree();
5304     printdebug "fake o+d/p tree object $unapplied\n";
5305     changedir '../work';
5306
5307
5308     # We calculate some guesswork now about what kind of tree this might
5309     # be.  This is mostly for error reporting.
5310
5311     my %editedignores;
5312     my @unrepres;
5313     my $diffbits = {
5314         # H = user's HEAD
5315         # O = orig, without patches applied
5316         # A = "applied", ie orig with H's debian/patches applied
5317         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5318                                      \%editedignores, \@unrepres),
5319         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5320         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5321     };
5322
5323     my @dl;
5324     foreach my $b (qw(01 02)) {
5325         foreach my $v (qw(O2H O2A H2A)) {
5326             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5327         }
5328     }
5329     printdebug "differences \@dl @dl.\n";
5330
5331     progress sprintf
5332 "$us: base trees orig=%.20s o+d/p=%.20s",
5333               $unapplied, $oldtiptree;
5334     progress sprintf
5335 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5336 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5337                              $dl[0], $dl[1],              $dl[3], $dl[4],
5338                                  $dl[2],                     $dl[5];
5339
5340     if (@unrepres) {
5341         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5342             foreach @unrepres;
5343         forceable_fail [qw(unrepresentable)], <<END;
5344 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5345 END
5346     }
5347
5348     my @failsuggestion;
5349     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5350         push @failsuggestion, "This might be a patches-unapplied branch.";
5351     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5352         push @failsuggestion, "This might be a patches-applied branch.";
5353     }
5354     push @failsuggestion, "Maybe you need to specify one of".
5355         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5356
5357     if (quiltmode_splitbrain()) {
5358         quiltify_splitbrain($clogp, $unapplied, $headref,
5359                             $diffbits, \%editedignores,
5360                             $splitbrain_cachekey);
5361         return;
5362     }
5363
5364     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5365     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5366
5367     if (!open P, '>>', ".pc/applied-patches") {
5368         $!==&ENOENT or die $!;
5369     } else {
5370         close P;
5371     }
5372
5373     commit_quilty_patch();
5374
5375     if ($mustdeletepc) {
5376         quilt_fixup_delete_pc();
5377     }
5378 }
5379
5380 sub quilt_fixup_editor () {
5381     my $descfn = $ENV{$fakeeditorenv};
5382     my $editing = $ARGV[$#ARGV];
5383     open I1, '<', $descfn or die "$descfn: $!";
5384     open I2, '<', $editing or die "$editing: $!";
5385     unlink $editing or die "$editing: $!";
5386     open O, '>', $editing or die "$editing: $!";
5387     while (<I1>) { print O or die $!; } I1->error and die $!;
5388     my $copying = 0;
5389     while (<I2>) {
5390         $copying ||= m/^\-\-\- /;
5391         next unless $copying;
5392         print O or die $!;
5393     }
5394     I2->error and die $!;
5395     close O or die $1;
5396     exit 0;
5397 }
5398
5399 sub maybe_apply_patches_dirtily () {
5400     return unless $quilt_mode =~ m/gbp|unapplied/;
5401     print STDERR <<END or die $!;
5402
5403 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5404 dgit: Have to apply the patches - making the tree dirty.
5405 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5406
5407 END
5408     $patches_applied_dirtily = 01;
5409     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5410     runcmd qw(dpkg-source --before-build .);
5411 }
5412
5413 sub maybe_unapply_patches_again () {
5414     progress "dgit: Unapplying patches again to tidy up the tree."
5415         if $patches_applied_dirtily;
5416     runcmd qw(dpkg-source --after-build .)
5417         if $patches_applied_dirtily & 01;
5418     rmtree '.pc'
5419         if $patches_applied_dirtily & 02;
5420     $patches_applied_dirtily = 0;
5421 }
5422
5423 #----- other building -----
5424
5425 our $clean_using_builder;
5426 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5427 #   clean the tree before building (perhaps invoked indirectly by
5428 #   whatever we are using to run the build), rather than separately
5429 #   and explicitly by us.
5430
5431 sub clean_tree () {
5432     return if $clean_using_builder;
5433     if ($cleanmode eq 'dpkg-source') {
5434         maybe_apply_patches_dirtily();
5435         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5436     } elsif ($cleanmode eq 'dpkg-source-d') {
5437         maybe_apply_patches_dirtily();
5438         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5439     } elsif ($cleanmode eq 'git') {
5440         runcmd_ordryrun_local @git, qw(clean -xdf);
5441     } elsif ($cleanmode eq 'git-ff') {
5442         runcmd_ordryrun_local @git, qw(clean -xdff);
5443     } elsif ($cleanmode eq 'check') {
5444         my $leftovers = cmdoutput @git, qw(clean -xdn);
5445         if (length $leftovers) {
5446             print STDERR $leftovers, "\n" or die $!;
5447             fail "tree contains uncommitted files and --clean=check specified";
5448         }
5449     } elsif ($cleanmode eq 'none') {
5450     } else {
5451         die "$cleanmode ?";
5452     }
5453 }
5454
5455 sub cmd_clean () {
5456     badusage "clean takes no additional arguments" if @ARGV;
5457     notpushing();
5458     clean_tree();
5459     maybe_unapply_patches_again();
5460 }
5461
5462 sub build_prep_early () {
5463     our $build_prep_early_done //= 0;
5464     return if $build_prep_early_done++;
5465     notpushing();
5466     badusage "-p is not allowed when building" if defined $package;
5467     my $clogp = parsechangelog();
5468     $isuite = getfield $clogp, 'Distribution';
5469     $package = getfield $clogp, 'Source';
5470     $version = getfield $clogp, 'Version';
5471     check_not_dirty();
5472 }
5473
5474 sub build_prep () {
5475     build_prep_early();
5476     clean_tree();
5477     build_maybe_quilt_fixup();
5478     if ($rmchanges) {
5479         my $pat = changespat $version;
5480         foreach my $f (glob "$buildproductsdir/$pat") {
5481             if (act_local()) {
5482                 unlink $f or fail "remove old changes file $f: $!";
5483             } else {
5484                 progress "would remove $f";
5485             }
5486         }
5487     }
5488 }
5489
5490 sub changesopts_initial () {
5491     my @opts =@changesopts[1..$#changesopts];
5492 }
5493
5494 sub changesopts_version () {
5495     if (!defined $changes_since_version) {
5496         my @vsns = archive_query('archive_query');
5497         my @quirk = access_quirk();
5498         if ($quirk[0] eq 'backports') {
5499             local $isuite = $quirk[2];
5500             local $csuite;
5501             canonicalise_suite();
5502             push @vsns, archive_query('archive_query');
5503         }
5504         if (@vsns) {
5505             @vsns = map { $_->[0] } @vsns;
5506             @vsns = sort { -version_compare($a, $b) } @vsns;
5507             $changes_since_version = $vsns[0];
5508             progress "changelog will contain changes since $vsns[0]";
5509         } else {
5510             $changes_since_version = '_';
5511             progress "package seems new, not specifying -v<version>";
5512         }
5513     }
5514     if ($changes_since_version ne '_') {
5515         return ("-v$changes_since_version");
5516     } else {
5517         return ();
5518     }
5519 }
5520
5521 sub changesopts () {
5522     return (changesopts_initial(), changesopts_version());
5523 }
5524
5525 sub massage_dbp_args ($;$) {
5526     my ($cmd,$xargs) = @_;
5527     # We need to:
5528     #
5529     #  - if we're going to split the source build out so we can
5530     #    do strange things to it, massage the arguments to dpkg-buildpackage
5531     #    so that the main build doessn't build source (or add an argument
5532     #    to stop it building source by default).
5533     #
5534     #  - add -nc to stop dpkg-source cleaning the source tree,
5535     #    unless we're not doing a split build and want dpkg-source
5536     #    as cleanmode, in which case we can do nothing
5537     #
5538     # return values:
5539     #    0 - source will NOT need to be built separately by caller
5540     #   +1 - source will need to be built separately by caller
5541     #   +2 - source will need to be built separately by caller AND
5542     #        dpkg-buildpackage should not in fact be run at all!
5543     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5544 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5545     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5546         $clean_using_builder = 1;
5547         return 0;
5548     }
5549     # -nc has the side effect of specifying -b if nothing else specified
5550     # and some combinations of -S, -b, et al, are errors, rather than
5551     # later simply overriding earlie.  So we need to:
5552     #  - search the command line for these options
5553     #  - pick the last one
5554     #  - perhaps add our own as a default
5555     #  - perhaps adjust it to the corresponding non-source-building version
5556     my $dmode = '-F';
5557     foreach my $l ($cmd, $xargs) {
5558         next unless $l;
5559         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5560     }
5561     push @$cmd, '-nc';
5562 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5563     my $r = 0;
5564     if ($need_split_build_invocation) {
5565         printdebug "massage split $dmode.\n";
5566         $r = $dmode =~ m/[S]/     ? +2 :
5567              $dmode =~ y/gGF/ABb/ ? +1 :
5568              $dmode =~ m/[ABb]/   ?  0 :
5569              die "$dmode ?";
5570     }
5571     printdebug "massage done $r $dmode.\n";
5572     push @$cmd, $dmode;
5573 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5574     return $r;
5575 }
5576
5577 sub in_parent (&) {
5578     my ($fn) = @_;
5579     my $wasdir = must_getcwd();
5580     changedir "..";
5581     $fn->();
5582     changedir $wasdir;
5583 }
5584
5585 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5586     my ($msg_if_onlyone) = @_;
5587     # If there is only one .changes file, fail with $msg_if_onlyone,
5588     # or if that is undef, be a no-op.
5589     # Returns the changes file to report to the user.
5590     my $pat = changespat $version;
5591     my @changesfiles = glob $pat;
5592     @changesfiles = sort {
5593         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5594             or $a cmp $b
5595     } @changesfiles;
5596     my $result;
5597     if (@changesfiles==1) {
5598         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5599 only one changes file from build (@changesfiles)
5600 END
5601         $result = $changesfiles[0];
5602     } elsif (@changesfiles==2) {
5603         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5604         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5605             fail "$l found in binaries changes file $binchanges"
5606                 if $l =~ m/\.dsc$/;
5607         }
5608         runcmd_ordryrun_local @mergechanges, @changesfiles;
5609         my $multichanges = changespat $version,'multi';
5610         if (act_local()) {
5611             stat_exists $multichanges or fail "$multichanges: $!";
5612             foreach my $cf (glob $pat) {
5613                 next if $cf eq $multichanges;
5614                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5615             }
5616         }
5617         $result = $multichanges;
5618     } else {
5619         fail "wrong number of different changes files (@changesfiles)";
5620     }
5621     printdone "build successful, results in $result\n" or die $!;
5622 }
5623
5624 sub midbuild_checkchanges () {
5625     my $pat = changespat $version;
5626     return if $rmchanges;
5627     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5628     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5629     fail <<END
5630 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5631 Suggest you delete @unwanted.
5632 END
5633         if @unwanted;
5634 }
5635
5636 sub midbuild_checkchanges_vanilla ($) {
5637     my ($wantsrc) = @_;
5638     midbuild_checkchanges() if $wantsrc == 1;
5639 }
5640
5641 sub postbuild_mergechanges_vanilla ($) {
5642     my ($wantsrc) = @_;
5643     if ($wantsrc == 1) {
5644         in_parent {
5645             postbuild_mergechanges(undef);
5646         };
5647     } else {
5648         printdone "build successful\n";
5649     }
5650 }
5651
5652 sub cmd_build {
5653     build_prep_early();
5654     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5655     my $wantsrc = massage_dbp_args \@dbp;
5656     if ($wantsrc > 0) {
5657         build_source();
5658         midbuild_checkchanges_vanilla $wantsrc;
5659     } else {
5660         build_prep();
5661     }
5662     if ($wantsrc < 2) {
5663         push @dbp, changesopts_version();
5664         maybe_apply_patches_dirtily();
5665         runcmd_ordryrun_local @dbp;
5666     }
5667     maybe_unapply_patches_again();
5668     postbuild_mergechanges_vanilla $wantsrc;
5669 }
5670
5671 sub pre_gbp_build {
5672     $quilt_mode //= 'gbp';
5673 }
5674
5675 sub cmd_gbp_build {
5676     build_prep_early();
5677
5678     # gbp can make .origs out of thin air.  In my tests it does this
5679     # even for a 1.0 format package, with no origs present.  So I
5680     # guess it keys off just the version number.  We don't know
5681     # exactly what .origs ought to exist, but let's assume that we
5682     # should run gbp if: the version has an upstream part and the main
5683     # orig is absent.
5684     my $upstreamversion = upstreamversion $version;
5685     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5686     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5687
5688     if ($gbp_make_orig) {
5689         clean_tree();
5690         $cleanmode = 'none'; # don't do it again
5691         $need_split_build_invocation = 1;
5692     }
5693
5694     my @dbp = @dpkgbuildpackage;
5695
5696     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5697
5698     if (!length $gbp_build[0]) {
5699         if (length executable_on_path('git-buildpackage')) {
5700             $gbp_build[0] = qw(git-buildpackage);
5701         } else {
5702             $gbp_build[0] = 'gbp buildpackage';
5703         }
5704     }
5705     my @cmd = opts_opt_multi_cmd @gbp_build;
5706
5707     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5708
5709     if ($gbp_make_orig) {
5710         ensuredir '.git/dgit';
5711         my $ok = '.git/dgit/origs-gen-ok';
5712         unlink $ok or $!==&ENOENT or die $!;
5713         my @origs_cmd = @cmd;
5714         push @origs_cmd, qw(--git-cleaner=true);
5715         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5716         push @origs_cmd, @ARGV;
5717         if (act_local()) {
5718             debugcmd @origs_cmd;
5719             system @origs_cmd;
5720             do { local $!; stat_exists $ok; }
5721                 or failedcmd @origs_cmd;
5722         } else {
5723             dryrun_report @origs_cmd;
5724         }
5725     }
5726
5727     if ($wantsrc > 0) {
5728         build_source();
5729         midbuild_checkchanges_vanilla $wantsrc;
5730     } else {
5731         if (!$clean_using_builder) {
5732             push @cmd, '--git-cleaner=true';
5733         }
5734         build_prep();
5735     }
5736     maybe_unapply_patches_again();
5737     if ($wantsrc < 2) {
5738         push @cmd, changesopts();
5739         runcmd_ordryrun_local @cmd, @ARGV;
5740     }
5741     postbuild_mergechanges_vanilla $wantsrc;
5742 }
5743 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5744
5745 sub build_source {
5746     build_prep_early();
5747     my $our_cleanmode = $cleanmode;
5748     if ($need_split_build_invocation) {
5749         # Pretend that clean is being done some other way.  This
5750         # forces us not to try to use dpkg-buildpackage to clean and
5751         # build source all in one go; and instead we run dpkg-source
5752         # (and build_prep() will do the clean since $clean_using_builder
5753         # is false).
5754         $our_cleanmode = 'ELSEWHERE';
5755     }
5756     if ($our_cleanmode =~ m/^dpkg-source/) {
5757         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5758         $clean_using_builder = 1;
5759     }
5760     build_prep();
5761     $sourcechanges = changespat $version,'source';
5762     if (act_local()) {
5763         unlink "../$sourcechanges" or $!==ENOENT
5764             or fail "remove $sourcechanges: $!";
5765     }
5766     $dscfn = dscfn($version);
5767     if ($our_cleanmode eq 'dpkg-source') {
5768         maybe_apply_patches_dirtily();
5769         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5770             changesopts();
5771     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5772         maybe_apply_patches_dirtily();
5773         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5774             changesopts();
5775     } else {
5776         my @cmd = (@dpkgsource, qw(-b --));
5777         if ($split_brain) {
5778             changedir $ud;
5779             runcmd_ordryrun_local @cmd, "work";
5780             my @udfiles = <${package}_*>;
5781             changedir "../../..";
5782             foreach my $f (@udfiles) {
5783                 printdebug "source copy, found $f\n";
5784                 next unless
5785                     $f eq $dscfn or
5786                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5787                      $f eq srcfn($version, $&));
5788                 printdebug "source copy, found $f - renaming\n";
5789                 rename "$ud/$f", "../$f" or $!==ENOENT
5790                     or fail "put in place new source file ($f): $!";
5791             }
5792         } else {
5793             my $pwd = must_getcwd();
5794             my $leafdir = basename $pwd;
5795             changedir "..";
5796             runcmd_ordryrun_local @cmd, $leafdir;
5797             changedir $pwd;
5798         }
5799         runcmd_ordryrun_local qw(sh -ec),
5800             'exec >$1; shift; exec "$@"','x',
5801             "../$sourcechanges",
5802             @dpkggenchanges, qw(-S), changesopts();
5803     }
5804 }
5805
5806 sub cmd_build_source {
5807     build_prep_early();
5808     badusage "build-source takes no additional arguments" if @ARGV;
5809     build_source();
5810     maybe_unapply_patches_again();
5811     printdone "source built, results in $dscfn and $sourcechanges";
5812 }
5813
5814 sub cmd_sbuild {
5815     build_source();
5816     midbuild_checkchanges();
5817     in_parent {
5818         if (act_local()) {
5819             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5820             stat_exists $sourcechanges
5821                 or fail "$sourcechanges (in parent directory): $!";
5822         }
5823         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5824     };
5825     maybe_unapply_patches_again();
5826     in_parent {
5827         postbuild_mergechanges(<<END);
5828 perhaps you need to pass -A ?  (sbuild's default is to build only
5829 arch-specific binaries; dgit 1.4 used to override that.)
5830 END
5831     };
5832 }
5833
5834 sub cmd_quilt_fixup {
5835     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5836     build_prep_early();
5837     clean_tree();
5838     build_maybe_quilt_fixup();
5839 }
5840
5841 sub cmd_import_dsc {
5842     my $needsig = 0;
5843
5844     while (@ARGV) {
5845         last unless $ARGV[0] =~ m/^-/;
5846         $_ = shift @ARGV;
5847         last if m/^--?$/;
5848         if (m/^--require-valid-signature$/) {
5849             $needsig = 1;
5850         } else {
5851             badusage "unknown dgit import-dsc sub-option \`$_'";
5852         }
5853     }
5854
5855     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
5856     my ($dscfn, $dstbranch) = @ARGV;
5857
5858     badusage "dry run makes no sense with import-dsc" unless act_local();
5859
5860     my $force = $dstbranch =~ s/^\+//   ? +1 :
5861                 $dstbranch =~ s/^\.\.// ? -1 :
5862                                            0;
5863     my $info = $force ? " $&" : '';
5864     $info = "$dscfn$info";
5865
5866     my $specbranch = $dstbranch;
5867     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
5868     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
5869
5870     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
5871     my $chead = cmdoutput_errok @symcmd;
5872     defined $chead or $?==256 or failedcmd @symcmd;
5873
5874     fail "$dstbranch is checked out - will not update it"
5875         if defined $chead and $chead eq $dstbranch;
5876
5877     my $oldhash = git_get_ref $dstbranch;
5878
5879     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
5880     $dscdata = do { local $/ = undef; <D>; };
5881     D->error and fail "read $dscfn: $!";
5882     close C;
5883
5884     # we don't normally need this so import it here
5885     use Dpkg::Source::Package;
5886     my $dp = new Dpkg::Source::Package filename => $dscfn,
5887         require_valid_signature => $needsig;
5888     {
5889         local $SIG{__WARN__} = sub {
5890             print STDERR $_[0];
5891             return unless $needsig;
5892             fail "import-dsc signature check failed";
5893         };
5894         if (!$dp->is_signed()) {
5895             warn "$us: warning: importing unsigned .dsc\n";
5896         } else {
5897             my $r = $dp->check_signature();
5898             die "->check_signature => $r" if $needsig && $r;
5899         }
5900     }
5901
5902     parse_dscdata();
5903
5904     my $dgit_field = $dsc->{$ourdscfield[0]};
5905     parse_dsc_field($dgit_field, "$ourdscfield[0] field in .dsc");
5906
5907     if (defined $dsc_hash
5908         && !forceing [qw(import-dsc-with-dgit-field)]) {
5909         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
5910         my @cmd = (qw(sh -ec),
5911                    "echo $dsc_hash | git cat-file --batch-check");
5912         my $objgot = cmdoutput @cmd;
5913         if ($objgot =~ m#^\w+ missing\b#) {
5914             fail <<END
5915 .dsc contains Dgit field referring to object $dsc_hash
5916 Your git tree does not have that object.  Try `git fetch' from a
5917 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
5918 END
5919         }
5920         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
5921             if ($force > 0) {
5922                 progress "Not fast forward, forced update.";
5923             } else {
5924                 fail "Not fast forward to $dsc_hash";
5925             }
5926         }
5927         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
5928                 $dstbranch, $dsc_hash);
5929         runcmd @cmd;
5930         progress "dgit: import-dsc updated git ref $dstbranch";
5931         return 0;
5932     }
5933
5934     fail <<END
5935 Branch $dstbranch already exists
5936 Specify ..$specbranch for a pseudo-merge, binding in existing history
5937 Specify  +$specbranch to overwrite, discarding existing history
5938 END
5939         if $oldhash && !$force;
5940
5941     $package = getfield $dsc, 'Source';
5942     my @dfi = dsc_files_info();
5943     foreach my $fi (@dfi) {
5944         my $f = $fi->{Filename};
5945         my $here = "../$f";
5946         next if lstat $here;
5947         fail "stat $here: $!" unless $! == ENOENT;
5948         my $there = $dscfn;
5949         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
5950             $there = $';
5951         } elsif ($dscfn =~ m#^/#) {
5952             $there = $dscfn;
5953         } else {
5954             fail "cannot import $dscfn which seems to be inside working tree!";
5955         }
5956         $there =~ s#/+[^/]+$## or
5957             fail "cannot import $dscfn which seems to not have a basename";
5958         $there .= "/$f";
5959         symlink $there, $here or fail "symlink $there to $here: $!";
5960         progress "made symlink $here -> $there";
5961 #       print STDERR Dumper($fi);
5962     }
5963     my @mergeinputs = generate_commits_from_dsc();
5964     die unless @mergeinputs == 1;
5965
5966     my $newhash = $mergeinputs[0]{Commit};
5967
5968     if ($oldhash) {
5969         if ($force > 0) {
5970             progress "Import, forced update - synthetic orphan git history.";
5971         } elsif ($force < 0) {
5972             progress "Import, merging.";
5973             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
5974             my $version = getfield $dsc, 'Version';
5975             my $clogp = commit_getclogp $newhash;
5976             my $authline = clogp_authline $clogp;
5977             $newhash = make_commit_text <<END;
5978 tree $tree
5979 parent $newhash
5980 parent $oldhash
5981 author $authline
5982 committer $authline
5983
5984 Merge $package ($version) import into $dstbranch
5985 END
5986         } else {
5987             die; # caught earlier
5988         }
5989     }
5990
5991     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
5992                $dstbranch, $newhash);
5993     runcmd @cmd;
5994     progress "dgit: import-dsc results are in in git ref $dstbranch";
5995 }
5996
5997 sub cmd_archive_api_query {
5998     badusage "need only 1 subpath argument" unless @ARGV==1;
5999     my ($subpath) = @ARGV;
6000     my @cmd = archive_api_query_cmd($subpath);
6001     push @cmd, qw(-f);
6002     debugcmd ">",@cmd;
6003     exec @cmd or fail "exec curl: $!\n";
6004 }
6005
6006 sub cmd_clone_dgit_repos_server {
6007     badusage "need destination argument" unless @ARGV==1;
6008     my ($destdir) = @ARGV;
6009     $package = '_dgit-repos-server';
6010     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6011     debugcmd ">",@cmd;
6012     exec @cmd or fail "exec git clone: $!\n";
6013 }
6014
6015 sub cmd_setup_mergechangelogs {
6016     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6017     setup_mergechangelogs(1);
6018 }
6019
6020 sub cmd_setup_useremail {
6021     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6022     setup_useremail(1);
6023 }
6024
6025 sub cmd_setup_new_tree {
6026     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6027     setup_new_tree();
6028 }
6029
6030 #---------- argument parsing and main program ----------
6031
6032 sub cmd_version {
6033     print "dgit version $our_version\n" or die $!;
6034     exit 0;
6035 }
6036
6037 our (%valopts_long, %valopts_short);
6038 our @rvalopts;
6039
6040 sub defvalopt ($$$$) {
6041     my ($long,$short,$val_re,$how) = @_;
6042     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6043     $valopts_long{$long} = $oi;
6044     $valopts_short{$short} = $oi;
6045     # $how subref should:
6046     #   do whatever assignemnt or thing it likes with $_[0]
6047     #   if the option should not be passed on to remote, @rvalopts=()
6048     # or $how can be a scalar ref, meaning simply assign the value
6049 }
6050
6051 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6052 defvalopt '--distro',        '-d', '.+',      \$idistro;
6053 defvalopt '',                '-k', '.+',      \$keyid;
6054 defvalopt '--existing-package','', '.*',      \$existing_package;
6055 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6056 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6057 defvalopt '--package',   '-p',   $package_re, \$package;
6058 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6059
6060 defvalopt '', '-C', '.+', sub {
6061     ($changesfile) = (@_);
6062     if ($changesfile =~ s#^(.*)/##) {
6063         $buildproductsdir = $1;
6064     }
6065 };
6066
6067 defvalopt '--initiator-tempdir','','.*', sub {
6068     ($initiator_tempdir) = (@_);
6069     $initiator_tempdir =~ m#^/# or
6070         badusage "--initiator-tempdir must be used specify an".
6071         " absolute, not relative, directory."
6072 };
6073
6074 sub parseopts () {
6075     my $om;
6076
6077     if (defined $ENV{'DGIT_SSH'}) {
6078         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6079     } elsif (defined $ENV{'GIT_SSH'}) {
6080         @ssh = ($ENV{'GIT_SSH'});
6081     }
6082
6083     my $oi;
6084     my $val;
6085     my $valopt = sub {
6086         my ($what) = @_;
6087         @rvalopts = ($_);
6088         if (!defined $val) {
6089             badusage "$what needs a value" unless @ARGV;
6090             $val = shift @ARGV;
6091             push @rvalopts, $val;
6092         }
6093         badusage "bad value \`$val' for $what" unless
6094             $val =~ m/^$oi->{Re}$(?!\n)/s;
6095         my $how = $oi->{How};
6096         if (ref($how) eq 'SCALAR') {
6097             $$how = $val;
6098         } else {
6099             $how->($val);
6100         }
6101         push @ropts, @rvalopts;
6102     };
6103
6104     while (@ARGV) {
6105         last unless $ARGV[0] =~ m/^-/;
6106         $_ = shift @ARGV;
6107         last if m/^--?$/;
6108         if (m/^--/) {
6109             if (m/^--dry-run$/) {
6110                 push @ropts, $_;
6111                 $dryrun_level=2;
6112             } elsif (m/^--damp-run$/) {
6113                 push @ropts, $_;
6114                 $dryrun_level=1;
6115             } elsif (m/^--no-sign$/) {
6116                 push @ropts, $_;
6117                 $sign=0;
6118             } elsif (m/^--help$/) {
6119                 cmd_help();
6120             } elsif (m/^--version$/) {
6121                 cmd_version();
6122             } elsif (m/^--new$/) {
6123                 push @ropts, $_;
6124                 $new_package=1;
6125             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6126                      ($om = $opts_opt_map{$1}) &&
6127                      length $om->[0]) {
6128                 push @ropts, $_;
6129                 $om->[0] = $2;
6130             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6131                      !$opts_opt_cmdonly{$1} &&
6132                      ($om = $opts_opt_map{$1})) {
6133                 push @ropts, $_;
6134                 push @$om, $2;
6135             } elsif (m/^--(gbp|dpm)$/s) {
6136                 push @ropts, "--quilt=$1";
6137                 $quilt_mode = $1;
6138             } elsif (m/^--ignore-dirty$/s) {
6139                 push @ropts, $_;
6140                 $ignoredirty = 1;
6141             } elsif (m/^--no-quilt-fixup$/s) {
6142                 push @ropts, $_;
6143                 $quilt_mode = 'nocheck';
6144             } elsif (m/^--no-rm-on-error$/s) {
6145                 push @ropts, $_;
6146                 $rmonerror = 0;
6147             } elsif (m/^--overwrite$/s) {
6148                 push @ropts, $_;
6149                 $overwrite_version = '';
6150             } elsif (m/^--overwrite=(.+)$/s) {
6151                 push @ropts, $_;
6152                 $overwrite_version = $1;
6153             } elsif (m/^--dep14tag$/s) {
6154                 push @ropts, $_;
6155                 $dodep14tag= 'want';
6156             } elsif (m/^--no-dep14tag$/s) {
6157                 push @ropts, $_;
6158                 $dodep14tag= 'no';
6159             } elsif (m/^--always-dep14tag$/s) {
6160                 push @ropts, $_;
6161                 $dodep14tag= 'always';
6162             } elsif (m/^--delayed=(\d+)$/s) {
6163                 push @ropts, $_;
6164                 push @dput, $_;
6165             } elsif (m/^--dgit-view-save=(.+)$/s) {
6166                 push @ropts, $_;
6167                 $split_brain_save = $1;
6168                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6169             } elsif (m/^--(no-)?rm-old-changes$/s) {
6170                 push @ropts, $_;
6171                 $rmchanges = !$1;
6172             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6173                 push @ropts, $_;
6174                 push @deliberatelies, $&;
6175             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6176                 push @ropts, $&;
6177                 $forceopts{$1} = 1;
6178                 $_='';
6179             } elsif (m/^--force-/) {
6180                 print STDERR
6181                     "$us: warning: ignoring unknown force option $_\n";
6182                 $_='';
6183             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6184                 # undocumented, for testing
6185                 push @ropts, $_;
6186                 $tagformat_want = [ $1, 'command line', 1 ];
6187                 # 1 menas overrides distro configuration
6188             } elsif (m/^--always-split-source-build$/s) {
6189                 # undocumented, for testing
6190                 push @ropts, $_;
6191                 $need_split_build_invocation = 1;
6192             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6193                 $val = $2 ? $' : undef; #';
6194                 $valopt->($oi->{Long});
6195             } else {
6196                 badusage "unknown long option \`$_'";
6197             }
6198         } else {
6199             while (m/^-./s) {
6200                 if (s/^-n/-/) {
6201                     push @ropts, $&;
6202                     $dryrun_level=2;
6203                 } elsif (s/^-L/-/) {
6204                     push @ropts, $&;
6205                     $dryrun_level=1;
6206                 } elsif (s/^-h/-/) {
6207                     cmd_help();
6208                 } elsif (s/^-D/-/) {
6209                     push @ropts, $&;
6210                     $debuglevel++;
6211                     enabledebug();
6212                 } elsif (s/^-N/-/) {
6213                     push @ropts, $&;
6214                     $new_package=1;
6215                 } elsif (m/^-m/) {
6216                     push @ropts, $&;
6217                     push @changesopts, $_;
6218                     $_ = '';
6219                 } elsif (s/^-wn$//s) {
6220                     push @ropts, $&;
6221                     $cleanmode = 'none';
6222                 } elsif (s/^-wg$//s) {
6223                     push @ropts, $&;
6224                     $cleanmode = 'git';
6225                 } elsif (s/^-wgf$//s) {
6226                     push @ropts, $&;
6227                     $cleanmode = 'git-ff';
6228                 } elsif (s/^-wd$//s) {
6229                     push @ropts, $&;
6230                     $cleanmode = 'dpkg-source';
6231                 } elsif (s/^-wdd$//s) {
6232                     push @ropts, $&;
6233                     $cleanmode = 'dpkg-source-d';
6234                 } elsif (s/^-wc$//s) {
6235                     push @ropts, $&;
6236                     $cleanmode = 'check';
6237                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6238                     push @git, '-c', $&;
6239                     $gitcfgs{cmdline}{$1} = [ $2 ];
6240                 } elsif (s/^-c([^=]+)$//s) {
6241                     push @git, '-c', $&;
6242                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6243                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6244                     $val = $'; #';
6245                     $val = undef unless length $val;
6246                     $valopt->($oi->{Short});
6247                     $_ = '';
6248                 } else {
6249                     badusage "unknown short option \`$_'";
6250                 }
6251             }
6252         }
6253     }
6254 }
6255
6256 sub check_env_sanity () {
6257     my $blocked = new POSIX::SigSet;
6258     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6259
6260     eval {
6261         foreach my $name (qw(PIPE CHLD)) {
6262             my $signame = "SIG$name";
6263             my $signum = eval "POSIX::$signame" // die;
6264             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6265                 die "$signame is set to something other than SIG_DFL\n";
6266             $blocked->ismember($signum) and
6267                 die "$signame is blocked\n";
6268         }
6269     };
6270     return unless $@;
6271     chomp $@;
6272     fail <<END;
6273 On entry to dgit, $@
6274 This is a bug produced by something in in your execution environment.
6275 Giving up.
6276 END
6277 }
6278
6279
6280 sub parseopts_late_defaults () {
6281     foreach my $k (keys %opts_opt_map) {
6282         my $om = $opts_opt_map{$k};
6283
6284         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6285         if (defined $v) {
6286             badcfg "cannot set command for $k"
6287                 unless length $om->[0];
6288             $om->[0] = $v;
6289         }
6290
6291         foreach my $c (access_cfg_cfgs("opts-$k")) {
6292             my @vl =
6293                 map { $_ ? @$_ : () }
6294                 map { $gitcfgs{$_}{$c} }
6295                 reverse @gitcfgsources;
6296             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6297                 "\n" if $debuglevel >= 4;
6298             next unless @vl;
6299             badcfg "cannot configure options for $k"
6300                 if $opts_opt_cmdonly{$k};
6301             my $insertpos = $opts_cfg_insertpos{$k};
6302             @$om = ( @$om[0..$insertpos-1],
6303                      @vl,
6304                      @$om[$insertpos..$#$om] );
6305         }
6306     }
6307
6308     if (!defined $rmchanges) {
6309         local $access_forpush;
6310         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6311     }
6312
6313     if (!defined $quilt_mode) {
6314         local $access_forpush;
6315         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6316             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6317             // 'linear';
6318         $quilt_mode =~ m/^($quilt_modes_re)$/
6319             or badcfg "unknown quilt-mode \`$quilt_mode'";
6320         $quilt_mode = $1;
6321     }
6322
6323     if (!defined $dodep14tag) {
6324         local $access_forpush;
6325         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6326         $dodep14tag =~ m/^($dodep14tag_re)$/
6327             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6328         $dodep14tag = $1;
6329     }
6330
6331     $need_split_build_invocation ||= quiltmode_splitbrain();
6332
6333     if (!defined $cleanmode) {
6334         local $access_forpush;
6335         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6336         $cleanmode //= 'dpkg-source';
6337
6338         badcfg "unknown clean-mode \`$cleanmode'" unless
6339             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6340     }
6341 }
6342
6343 if ($ENV{$fakeeditorenv}) {
6344     git_slurp_config();
6345     quilt_fixup_editor();
6346 }
6347
6348 parseopts();
6349 check_env_sanity();
6350 git_slurp_config();
6351
6352 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6353 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6354     if $dryrun_level == 1;
6355 if (!@ARGV) {
6356     print STDERR $helpmsg or die $!;
6357     exit 8;
6358 }
6359 my $cmd = shift @ARGV;
6360 $cmd =~ y/-/_/;
6361
6362 my $pre_fn = ${*::}{"pre_$cmd"};
6363 $pre_fn->() if $pre_fn;
6364
6365 my $fn = ${*::}{"cmd_$cmd"};
6366 $fn or badusage "unknown operation $cmd";
6367 $fn->();