dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::Util qw(any);
  38 use List::MoreUtils qw(pairwise);
  39 use Text::Glob qw(match_glob);
  40 use Fcntl qw(:DEFAULT :flock);
  41 use Carp;
  42
  43 use Debian::Dgit;
  44
  45 our $our_version = 'UNRELEASED'; ###substituted###
  46 our $absurdity = undef; ###substituted###
  47
  48 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  49 our $protovsn;
  50
  51 our $isuite = 'unstable';
  52 our $idistro;
  53 our $package;
  54 our @ropts;
  55
  56 our $sign = 1;
  57 our $dryrun_level = 0;
  58 our $changesfile;
  59 our $buildproductsdir = '..';
  60 our $new_package = 0;
  61 our $ignoredirty = 0;
  62 our $rmonerror = 1;
  63 our @deliberatelies;
  64 our %previously;
  65 our $existing_package = 'dpkg';
  66 our $cleanmode;
  67 our $changes_since_version;
  68 our $rmchanges;
  69 our $overwrite_version; # undef: not specified; '': check changelog
  70 our $quilt_mode;
  71 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  72 our $dodep14tag;
  73 our $dodep14tag_re = 'want|no|always';
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $initiator_tempdir;
  77 our $patches_applied_dirtily = 00;
  78 our $tagformat_want;
  79 our $tagformat;
  80 our $tagformatfn;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = qw(curl);
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146
 147 our $keyid;
 148
 149 autoflush STDOUT 1;
 150
 151 our $supplementary_message = '';
 152 our $need_split_build_invocation = 0;
 153 our $split_brain = 0;
 154
 155 END {
 156     local ($@, $?);
 157     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 158 }
 159
 160 our $remotename = 'dgit';
 161 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 162 our $csuite;
 163 our $instead_distro;
 164
 165 if (!defined $absurdity) {
 166     $absurdity = $0;
 167     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 168 }
 169
 170 sub debiantag ($$) {
 171     my ($v,$distro) = @_;
 172     return $tagformatfn->($v, $distro);
 173 }
 174
 175 sub debiantag_maintview ($$) {
 176     my ($v,$distro) = @_;
 177     return "$distro/".dep14_version_mangle $v;
 178 }
 179
 180 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 181
 182 sub lbranch () { return "$branchprefix/$csuite"; }
 183 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 184 sub lref () { return "refs/heads/".lbranch(); }
 185 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 186 sub rrref () { return server_ref($csuite); }
 187
 188 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 189 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
 190
 191 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
 192 # locally fetched refs because they have unhelpful names and clutter
 193 # up gitk etc.  So we track whether we have "used up" head ref (ie,
 194 # whether we have made another local ref which refers to this object).
 195 #
 196 # (If we deleted them unconditionally, then we might end up
 197 # re-fetching the same git objects each time dgit fetch was run.)
 198 #
 199 # So, leach use of lrfetchrefs needs to be accompanied by arrangements
 200 # in git_fetch_us to fetch the refs in question, and possibly a call
 201 # to lrfetchref_used.
 202
 203 our (%lrfetchrefs_f, %lrfetchrefs_d);
 204 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
 205
 206 sub lrfetchref_used ($) {
 207     my ($fullrefname) = @_;
 208     my $objid = $lrfetchrefs_f{$fullrefname};
 209     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
 210 }
 211
 212 sub stripepoch ($) {
 213     my ($vsn) = @_;
 214     $vsn =~ s/^\d+\://;
 215     return $vsn;
 216 }
 217
 218 sub srcfn ($$) {
 219     my ($vsn,$sfx) = @_;
 220     return "${package}_".(stripepoch $vsn).$sfx
 221 }
 222
 223 sub dscfn ($) {
 224     my ($vsn) = @_;
 225     return srcfn($vsn,".dsc");
 226 }
 227
 228 sub changespat ($;$) {
 229     my ($vsn, $arch) = @_;
 230     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 231 }
 232
 233 sub upstreamversion ($) {
 234     my ($vsn) = @_;
 235     $vsn =~ s/-[^-]+$//;
 236     return $vsn;
 237 }
 238
 239 our $us = 'dgit';
 240 initdebug('');
 241
 242 our @end;
 243 END {
 244     local ($?);
 245     foreach my $f (@end) {
 246         eval { $f->(); };
 247         print STDERR "$us: cleanup: $@" if length $@;
 248     }
 249 };
 250
 251 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 252
 253 sub forceable_fail ($$) {
 254     my ($forceoptsl, $msg) = @_;
 255     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 256     print STDERR "warning: overriding problem due to --force:\n". $msg;
 257 }
 258
 259 sub forceing ($) {
 260     my ($forceoptsl) = @_;
 261     my @got = grep { $forceopts{$_} } @$forceoptsl;
 262     return 0 unless @got;
 263     print STDERR
 264  "warning: skipping checks or functionality due to --force-$got[0]\n";
 265 }
 266
 267 sub no_such_package () {
 268     print STDERR "$us: package $package does not exist in suite $isuite\n";
 269     exit 4;
 270 }
 271
 272 sub changedir ($) {
 273     my ($newdir) = @_;
 274     printdebug "CD $newdir\n";
 275     chdir $newdir or confess "chdir: $newdir: $!";
 276 }
 277
 278 sub deliberately ($) {
 279     my ($enquiry) = @_;
 280     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 281 }
 282
 283 sub deliberately_not_fast_forward () {
 284     foreach (qw(not-fast-forward fresh-repo)) {
 285         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 286     }
 287 }
 288
 289 sub quiltmode_splitbrain () {
 290     $quilt_mode =~ m/gbp|dpm|unapplied/;
 291 }
 292
 293 sub opts_opt_multi_cmd {
 294     my @cmd;
 295     push @cmd, split /\s+/, shift @_;
 296     push @cmd, @_;
 297     @cmd;
 298 }
 299
 300 sub gbp_pq {
 301     return opts_opt_multi_cmd @gbp_pq;
 302 }
 303
 304 #---------- remote protocol support, common ----------
 305
 306 # remote push initiator/responder protocol:
 307 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 308 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 309 #  < dgit-remote-push-ready <actual-proto-vsn>
 310 #
 311 # occasionally:
 312 #
 313 #  > progress NBYTES
 314 #  [NBYTES message]
 315 #
 316 #  > supplementary-message NBYTES          # $protovsn >= 3
 317 #  [NBYTES message]
 318 #
 319 # main sequence:
 320 #
 321 #  > file parsed-changelog
 322 #  [indicates that output of dpkg-parsechangelog follows]
 323 #  > data-block NBYTES
 324 #  > [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  > data-end
 327 #
 328 #  > file dsc
 329 #  [etc]
 330 #
 331 #  > file changes
 332 #  [etc]
 333 #
 334 #  > param head DGIT-VIEW-HEAD
 335 #  > param csuite SUITE
 336 #  > param tagformat old|new
 337 #  > param maint-view MAINT-VIEW-HEAD
 338 #
 339 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 340 #                                     # goes into tag, for replay prevention
 341 #
 342 #  > want signed-tag
 343 #  [indicates that signed tag is wanted]
 344 #  < data-block NBYTES
 345 #  < [NBYTES bytes of data (no newline)]
 346 #  [maybe some more blocks]
 347 #  < data-end
 348 #  < files-end
 349 #
 350 #  > want signed-dsc-changes
 351 #  < data-block NBYTES    [transfer of signed dsc]
 352 #  [etc]
 353 #  < data-block NBYTES    [transfer of signed changes]
 354 #  [etc]
 355 #  < files-end
 356 #
 357 #  > complete
 358
 359 our $i_child_pid;
 360
 361 sub i_child_report () {
 362     # Sees if our child has died, and reap it if so.  Returns a string
 363     # describing how it died if it failed, or undef otherwise.
 364     return undef unless $i_child_pid;
 365     my $got = waitpid $i_child_pid, WNOHANG;
 366     return undef if $got <= 0;
 367     die unless $got == $i_child_pid;
 368     $i_child_pid = undef;
 369     return undef unless $?;
 370     return "build host child ".waitstatusmsg();
 371 }
 372
 373 sub badproto ($$) {
 374     my ($fh, $m) = @_;
 375     fail "connection lost: $!" if $fh->error;
 376     fail "protocol violation; $m not expected";
 377 }
 378
 379 sub badproto_badread ($$) {
 380     my ($fh, $wh) = @_;
 381     fail "connection lost: $!" if $!;
 382     my $report = i_child_report();
 383     fail $report if defined $report;
 384     badproto $fh, "eof (reading $wh)";
 385 }
 386
 387 sub protocol_expect (&$) {
 388     my ($match, $fh) = @_;
 389     local $_;
 390     $_ = <$fh>;
 391     defined && chomp or badproto_badread $fh, "protocol message";
 392     if (wantarray) {
 393         my @r = &$match;
 394         return @r if @r;
 395     } else {
 396         my $r = &$match;
 397         return $r if $r;
 398     }
 399     badproto $fh, "\`$_'";
 400 }
 401
 402 sub protocol_send_file ($$) {
 403     my ($fh, $ourfn) = @_;
 404     open PF, "<", $ourfn or die "$ourfn: $!";
 405     for (;;) {
 406         my $d;
 407         my $got = read PF, $d, 65536;
 408         die "$ourfn: $!" unless defined $got;
 409         last if !$got;
 410         print $fh "data-block ".length($d)."\n" or die $!;
 411         print $fh $d or die $!;
 412     }
 413     PF->error and die "$ourfn $!";
 414     print $fh "data-end\n" or die $!;
 415     close PF;
 416 }
 417
 418 sub protocol_read_bytes ($$) {
 419     my ($fh, $nbytes) = @_;
 420     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 421     my $d;
 422     my $got = read $fh, $d, $nbytes;
 423     $got==$nbytes or badproto_badread $fh, "data block";
 424     return $d;
 425 }
 426
 427 sub protocol_receive_file ($$) {
 428     my ($fh, $ourfn) = @_;
 429     printdebug "() $ourfn\n";
 430     open PF, ">", $ourfn or die "$ourfn: $!";
 431     for (;;) {
 432         my ($y,$l) = protocol_expect {
 433             m/^data-block (.*)$/ ? (1,$1) :
 434             m/^data-end$/ ? (0,) :
 435             ();
 436         } $fh;
 437         last unless $y;
 438         my $d = protocol_read_bytes $fh, $l;
 439         print PF $d or die $!;
 440     }
 441     close PF or die $!;
 442 }
 443
 444 #---------- remote protocol support, responder ----------
 445
 446 sub responder_send_command ($) {
 447     my ($command) = @_;
 448     return unless $we_are_responder;
 449     # called even without $we_are_responder
 450     printdebug ">> $command\n";
 451     print PO $command, "\n" or die $!;
 452 }
 453
 454 sub responder_send_file ($$) {
 455     my ($keyword, $ourfn) = @_;
 456     return unless $we_are_responder;
 457     printdebug "]] $keyword $ourfn\n";
 458     responder_send_command "file $keyword";
 459     protocol_send_file \*PO, $ourfn;
 460 }
 461
 462 sub responder_receive_files ($@) {
 463     my ($keyword, @ourfns) = @_;
 464     die unless $we_are_responder;
 465     printdebug "[[ $keyword @ourfns\n";
 466     responder_send_command "want $keyword";
 467     foreach my $fn (@ourfns) {
 468         protocol_receive_file \*PI, $fn;
 469     }
 470     printdebug "[[\$\n";
 471     protocol_expect { m/^files-end$/ } \*PI;
 472 }
 473
 474 #---------- remote protocol support, initiator ----------
 475
 476 sub initiator_expect (&) {
 477     my ($match) = @_;
 478     protocol_expect { &$match } \*RO;
 479 }
 480
 481 #---------- end remote code ----------
 482
 483 sub progress {
 484     if ($we_are_responder) {
 485         my $m = join '', @_;
 486         responder_send_command "progress ".length($m) or die $!;
 487         print PO $m or die $!;
 488     } else {
 489         print @_, "\n";
 490     }
 491 }
 492
 493 our $ua;
 494
 495 sub url_get {
 496     if (!$ua) {
 497         $ua = LWP::UserAgent->new();
 498         $ua->env_proxy;
 499     }
 500     my $what = $_[$#_];
 501     progress "downloading $what...";
 502     my $r = $ua->get(@_) or die $!;
 503     return undef if $r->code == 404;
 504     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 505     return $r->decoded_content(charset => 'none');
 506 }
 507
 508 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 509
 510 sub runcmd {
 511     debugcmd "+",@_;
 512     $!=0; $?=-1;
 513     failedcmd @_ if system @_;
 514 }
 515
 516 sub act_local () { return $dryrun_level <= 1; }
 517 sub act_scary () { return !$dryrun_level; }
 518
 519 sub printdone {
 520     if (!$dryrun_level) {
 521         progress "$us ok: @_";
 522     } else {
 523         progress "would be ok: @_ (but dry run only)";
 524     }
 525 }
 526
 527 sub dryrun_report {
 528     printcmd(\*STDERR,$debugprefix."#",@_);
 529 }
 530
 531 sub runcmd_ordryrun {
 532     if (act_scary()) {
 533         runcmd @_;
 534     } else {
 535         dryrun_report @_;
 536     }
 537 }
 538
 539 sub runcmd_ordryrun_local {
 540     if (act_local()) {
 541         runcmd @_;
 542     } else {
 543         dryrun_report @_;
 544     }
 545 }
 546
 547 sub shell_cmd {
 548     my ($first_shell, @cmd) = @_;
 549     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 550 }
 551
 552 our $helpmsg = <<END;
 553 main usages:
 554   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 555   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 556   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 557   dgit [dgit-opts] sbuild [sbuild-opts]
 558   dgit [dgit-opts] push [dgit-opts] [suite]
 559   dgit [dgit-opts] rpush build-host:build-dir ...
 560 important dgit options:
 561   -k<keyid>           sign tag and package with <keyid> instead of default
 562   --dry-run -n        do not change anything, but go through the motions
 563   --damp-run -L       like --dry-run but make local changes, without signing
 564   --new -N            allow introducing a new package
 565   --debug -D          increase debug level
 566   -c<name>=<value>    set git config option (used directly by dgit too)
 567 END
 568
 569 our $later_warning_msg = <<END;
 570 Perhaps the upload is stuck in incoming.  Using the version from git.
 571 END
 572
 573 sub badusage {
 574     print STDERR "$us: @_\n", $helpmsg or die $!;
 575     exit 8;
 576 }
 577
 578 sub nextarg {
 579     @ARGV or badusage "too few arguments";
 580     return scalar shift @ARGV;
 581 }
 582
 583 sub cmd_help () {
 584     print $helpmsg or die $!;
 585     exit 0;
 586 }
 587
 588 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 589
 590 our %defcfg = ('dgit.default.distro' => 'debian',
 591                'dgit-suite.*-security.distro' => 'debian-security',
 592                'dgit.default.username' => '',
 593                'dgit.default.archive-query-default-component' => 'main',
 594                'dgit.default.ssh' => 'ssh',
 595                'dgit.default.archive-query' => 'madison:',
 596                'dgit.default.sshpsql-dbname' => 'service=projectb',
 597                'dgit.default.aptget-components' => 'main',
 598                'dgit.default.dgit-tag-format' => 'new,old,maint',
 599                # old means "repo server accepts pushes with old dgit tags"
 600                # new means "repo server accepts pushes with new dgit tags"
 601                # maint means "repo server accepts split brain pushes"
 602                # hist means "repo server may have old pushes without new tag"
 603                #   ("hist" is implied by "old")
 604                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 605                'dgit-distro.debian.git-check' => 'url',
 606                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 607                'dgit-distro.debian.new-private-pushers' => 't',
 608                'dgit-distro.debian/push.git-url' => '',
 609                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 610                'dgit-distro.debian/push.git-user-force' => 'dgit',
 611                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 612                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 613                'dgit-distro.debian/push.git-create' => 'true',
 614                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 615  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 616 # 'dgit-distro.debian.archive-query-tls-key',
 617 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 618 # ^ this does not work because curl is broken nowadays
 619 # Fixing #790093 properly will involve providing providing the key
 620 # in some pacagke and maybe updating these paths.
 621 #
 622 # 'dgit-distro.debian.archive-query-tls-curl-args',
 623 #   '--ca-path=/etc/ssl/ca-debian',
 624 # ^ this is a workaround but works (only) on DSA-administered machines
 625                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 626                'dgit-distro.debian.git-url-suffix' => '',
 627                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 628                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 629  'dgit-distro.debian-security.archive-query' => 'aptget:',
 630  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 631  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 632  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 633  'dgit-distro.debian-security.nominal-distro' => 'debian',
 634  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 635  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 636                'dgit-distro.ubuntu.git-check' => 'false',
 637  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 638                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 639                'dgit-distro.test-dummy.username' => "alice",
 640                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 641                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 642                'dgit-distro.test-dummy.git-url' => "$td/git",
 643                'dgit-distro.test-dummy.git-host' => "git",
 644                'dgit-distro.test-dummy.git-path' => "$td/git",
 645                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 646                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 647                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 648                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 649                );
 650
 651 our %gitcfgs;
 652 our @gitcfgsources = qw(cmdline local global system);
 653
 654 sub git_slurp_config () {
 655     local ($debuglevel) = $debuglevel-2;
 656     local $/="\0";
 657
 658     # This algoritm is a bit subtle, but this is needed so that for
 659     # options which we want to be single-valued, we allow the
 660     # different config sources to override properly.  See #835858.
 661     foreach my $src (@gitcfgsources) {
 662         next if $src eq 'cmdline';
 663         # we do this ourselves since git doesn't handle it
 664
 665         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 666         debugcmd "|",@cmd;
 667
 668         open GITS, "-|", @cmd or die $!;
 669         while (<GITS>) {
 670             chomp or die;
 671             printdebug "=> ", (messagequote $_), "\n";
 672             m/\n/ or die "$_ ?";
 673             push @{ $gitcfgs{$src}{$`} }, $'; #';
 674         }
 675         $!=0; $?=0;
 676         close GITS
 677             or ($!==0 && $?==256)
 678             or failedcmd @cmd;
 679     }
 680 }
 681
 682 sub git_get_config ($) {
 683     my ($c) = @_;
 684     foreach my $src (@gitcfgsources) {
 685         my $l = $gitcfgs{$src}{$c};
 686         printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 687             if $debuglevel >= 4;
 688         $l or next;
 689         @$l==1 or badcfg "multiple values for $c".
 690             " (in $src git config)" if @$l > 1;
 691         return $l->[0];
 692     }
 693     return undef;
 694 }
 695
 696 sub cfg {
 697     foreach my $c (@_) {
 698         return undef if $c =~ /RETURN-UNDEF/;
 699         my $v = git_get_config($c);
 700         return $v if defined $v;
 701         my $dv = $defcfg{$c};
 702         return $dv if defined $dv;
 703     }
 704     badcfg "need value for one of: @_\n".
 705         "$us: distro or suite appears not to be (properly) supported";
 706 }
 707
 708 sub access_basedistro () {
 709     if (defined $idistro) {
 710         return $idistro;
 711     } else {
 712         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 713         return $def if defined $def;
 714         foreach my $src (@gitcfgsources, 'internal') {
 715             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 716             next unless $kl;
 717             foreach my $k (keys %$kl) {
 718                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 719                 my $dpat = $1;
 720                 next unless match_glob $dpat, $isuite;
 721                 return $kl->{$k};
 722             }
 723         }
 724         return cfg("dgit.default.distro");
 725     }
 726 }
 727
 728 sub access_nomdistro () {
 729     my $base = access_basedistro();
 730     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 731     $r =~ m/^$distro_re$/ or badcfg
 732  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 733     return $r;
 734 }
 735
 736 sub access_quirk () {
 737     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 738     my $basedistro = access_basedistro();
 739     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 740                               'RETURN-UNDEF');
 741     if (defined $backports_quirk) {
 742         my $re = $backports_quirk;
 743         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 744         $re =~ s/\*/.*/g;
 745         $re =~ s/\%/([-0-9a-z_]+)/
 746             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 747         if ($isuite =~ m/^$re$/) {
 748             return ('backports',"$basedistro-backports",$1);
 749         }
 750     }
 751     return ('none',undef);
 752 }
 753
 754 our $access_forpush;
 755
 756 sub parse_cfg_bool ($$$) {
 757     my ($what,$def,$v) = @_;
 758     $v //= $def;
 759     return
 760         $v =~ m/^[ty1]/ ? 1 :
 761         $v =~ m/^[fn0]/ ? 0 :
 762         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 763 }
 764
 765 sub access_forpush_config () {
 766     my $d = access_basedistro();
 767
 768     return 1 if
 769         $new_package &&
 770         parse_cfg_bool('new-private-pushers', 0,
 771                        cfg("dgit-distro.$d.new-private-pushers",
 772                            'RETURN-UNDEF'));
 773
 774     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 775     $v //= 'a';
 776     return
 777         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 778         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 779         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 780         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 781 }
 782
 783 sub access_forpush () {
 784     $access_forpush //= access_forpush_config();
 785     return $access_forpush;
 786 }
 787
 788 sub pushing () {
 789     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 790     badcfg "pushing but distro is configured readonly"
 791         if access_forpush_config() eq '0';
 792     $access_forpush = 1;
 793     $supplementary_message = <<'END' unless $we_are_responder;
 794 Push failed, before we got started.
 795 You can retry the push, after fixing the problem, if you like.
 796 END
 797     parseopts_late_defaults();
 798 }
 799
 800 sub notpushing () {
 801     parseopts_late_defaults();
 802 }
 803
 804 sub supplementary_message ($) {
 805     my ($msg) = @_;
 806     if (!$we_are_responder) {
 807         $supplementary_message = $msg;
 808         return;
 809     } elsif ($protovsn >= 3) {
 810         responder_send_command "supplementary-message ".length($msg)
 811             or die $!;
 812         print PO $msg or die $!;
 813     }
 814 }
 815
 816 sub access_distros () {
 817     # Returns list of distros to try, in order
 818     #
 819     # We want to try:
 820     #    0. `instead of' distro name(s) we have been pointed to
 821     #    1. the access_quirk distro, if any
 822     #    2a. the user's specified distro, or failing that  } basedistro
 823     #    2b. the distro calculated from the suite          }
 824     my @l = access_basedistro();
 825
 826     my (undef,$quirkdistro) = access_quirk();
 827     unshift @l, $quirkdistro;
 828     unshift @l, $instead_distro;
 829     @l = grep { defined } @l;
 830
 831     push @l, access_nomdistro();
 832
 833     if (access_forpush()) {
 834         @l = map { ("$_/push", $_) } @l;
 835     }
 836     @l;
 837 }
 838
 839 sub access_cfg_cfgs (@) {
 840     my (@keys) = @_;
 841     my @cfgs;
 842     # The nesting of these loops determines the search order.  We put
 843     # the key loop on the outside so that we search all the distros
 844     # for each key, before going on to the next key.  That means that
 845     # if access_cfg is called with a more specific, and then a less
 846     # specific, key, an earlier distro can override the less specific
 847     # without necessarily overriding any more specific keys.  (If the
 848     # distro wants to override the more specific keys it can simply do
 849     # so; whereas if we did the loop the other way around, it would be
 850     # impossible to for an earlier distro to override a less specific
 851     # key but not the more specific ones without restating the unknown
 852     # values of the more specific keys.
 853     my @realkeys;
 854     my @rundef;
 855     # We have to deal with RETURN-UNDEF specially, so that we don't
 856     # terminate the search prematurely.
 857     foreach (@keys) {
 858         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 859         push @realkeys, $_
 860     }
 861     foreach my $d (access_distros()) {
 862         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 863     }
 864     push @cfgs, map { "dgit.default.$_" } @realkeys;
 865     push @cfgs, @rundef;
 866     return @cfgs;
 867 }
 868
 869 sub access_cfg (@) {
 870     my (@keys) = @_;
 871     my (@cfgs) = access_cfg_cfgs(@keys);
 872     my $value = cfg(@cfgs);
 873     return $value;
 874 }
 875
 876 sub access_cfg_bool ($$) {
 877     my ($def, @keys) = @_;
 878     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 879 }
 880
 881 sub string_to_ssh ($) {
 882     my ($spec) = @_;
 883     if ($spec =~ m/\s/) {
 884         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 885     } else {
 886         return ($spec);
 887     }
 888 }
 889
 890 sub access_cfg_ssh () {
 891     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 892     if (!defined $gitssh) {
 893         return @ssh;
 894     } else {
 895         return string_to_ssh $gitssh;
 896     }
 897 }
 898
 899 sub access_runeinfo ($) {
 900     my ($info) = @_;
 901     return ": dgit ".access_basedistro()." $info ;";
 902 }
 903
 904 sub access_someuserhost ($) {
 905     my ($some) = @_;
 906     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 907     defined($user) && length($user) or
 908         $user = access_cfg("$some-user",'username');
 909     my $host = access_cfg("$some-host");
 910     return length($user) ? "$user\@$host" : $host;
 911 }
 912
 913 sub access_gituserhost () {
 914     return access_someuserhost('git');
 915 }
 916
 917 sub access_giturl (;$) {
 918     my ($optional) = @_;
 919     my $url = access_cfg('git-url','RETURN-UNDEF');
 920     my $suffix;
 921     if (!length $url) {
 922         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 923         return undef unless defined $proto;
 924         $url =
 925             $proto.
 926             access_gituserhost().
 927             access_cfg('git-path');
 928     } else {
 929         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 930     }
 931     $suffix //= '.git';
 932     return "$url/$package$suffix";
 933 }
 934
 935 sub parsecontrolfh ($$;$) {
 936     my ($fh, $desc, $allowsigned) = @_;
 937     our $dpkgcontrolhash_noissigned;
 938     my $c;
 939     for (;;) {
 940         my %opts = ('name' => $desc);
 941         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 942         $c = Dpkg::Control::Hash->new(%opts);
 943         $c->parse($fh,$desc) or die "parsing of $desc failed";
 944         last if $allowsigned;
 945         last if $dpkgcontrolhash_noissigned;
 946         my $issigned= $c->get_option('is_pgp_signed');
 947         if (!defined $issigned) {
 948             $dpkgcontrolhash_noissigned= 1;
 949             seek $fh, 0,0 or die "seek $desc: $!";
 950         } elsif ($issigned) {
 951             fail "control file $desc is (already) PGP-signed. ".
 952                 " Note that dgit push needs to modify the .dsc and then".
 953                 " do the signature itself";
 954         } else {
 955             last;
 956         }
 957     }
 958     return $c;
 959 }
 960
 961 sub parsecontrol {
 962     my ($file, $desc, $allowsigned) = @_;
 963     my $fh = new IO::Handle;
 964     open $fh, '<', $file or die "$file: $!";
 965     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 966     $fh->error and die $!;
 967     close $fh;
 968     return $c;
 969 }
 970
 971 sub getfield ($$) {
 972     my ($dctrl,$field) = @_;
 973     my $v = $dctrl->{$field};
 974     return $v if defined $v;
 975     fail "missing field $field in ".$dctrl->get_option('name');
 976 }
 977
 978 sub parsechangelog {
 979     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 980     my $p = new IO::Handle;
 981     my @cmd = (qw(dpkg-parsechangelog), @_);
 982     open $p, '-|', @cmd or die $!;
 983     $c->parse($p);
 984     $?=0; $!=0; close $p or failedcmd @cmd;
 985     return $c;
 986 }
 987
 988 sub commit_getclogp ($) {
 989     # Returns the parsed changelog hashref for a particular commit
 990     my ($objid) = @_;
 991     our %commit_getclogp_memo;
 992     my $memo = $commit_getclogp_memo{$objid};
 993     return $memo if $memo;
 994     mkpath '.git/dgit';
 995     my $mclog = ".git/dgit/clog-$objid";
 996     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 997         "$objid:debian/changelog";
 998     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 999 }
1000
1001 sub must_getcwd () {
1002     my $d = getcwd();
1003     defined $d or fail "getcwd failed: $!";
1004     return $d;
1005 }
1006
1007 sub parse_dscdata () {
1008     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1009     printdebug Dumper($dscdata) if $debuglevel>1;
1010     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1011     printdebug Dumper($dsc) if $debuglevel>1;
1012 }
1013
1014 our %rmad;
1015
1016 sub archive_query ($;@) {
1017     my ($method) = shift @_;
1018     fail "this operation does not support multiple comma-separated suites"
1019         if $isuite =~ m/,/;
1020     my $query = access_cfg('archive-query','RETURN-UNDEF');
1021     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1022     my $proto = $1;
1023     my $data = $'; #';
1024     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1025 }
1026
1027 sub archive_query_prepend_mirror {
1028     my $m = access_cfg('mirror');
1029     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1030 }
1031
1032 sub pool_dsc_subpath ($$) {
1033     my ($vsn,$component) = @_; # $package is implict arg
1034     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1035     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1036 }
1037
1038 sub cfg_apply_map ($$$) {
1039     my ($varref, $what, $mapspec) = @_;
1040     return unless $mapspec;
1041
1042     printdebug "config $what EVAL{ $mapspec; }\n";
1043     $_ = $$varref;
1044     eval "package Dgit::Config; $mapspec;";
1045     die $@ if $@;
1046     $$varref = $_;
1047 }
1048
1049 #---------- `ftpmasterapi' archive query method (nascent) ----------
1050
1051 sub archive_api_query_cmd ($) {
1052     my ($subpath) = @_;
1053     my @cmd = (@curl, qw(-sS));
1054     my $url = access_cfg('archive-query-url');
1055     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1056         my $host = $1;
1057         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1058         foreach my $key (split /\:/, $keys) {
1059             $key =~ s/\%HOST\%/$host/g;
1060             if (!stat $key) {
1061                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1062                 next;
1063             }
1064             fail "config requested specific TLS key but do not know".
1065                 " how to get curl to use exactly that EE key ($key)";
1066 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1067 #           # Sadly the above line does not work because of changes
1068 #           # to gnutls.   The real fix for #790093 may involve
1069 #           # new curl options.
1070             last;
1071         }
1072         # Fixing #790093 properly will involve providing a value
1073         # for this on clients.
1074         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1075         push @cmd, split / /, $kargs if defined $kargs;
1076     }
1077     push @cmd, $url.$subpath;
1078     return @cmd;
1079 }
1080
1081 sub api_query ($$;$) {
1082     use JSON;
1083     my ($data, $subpath, $ok404) = @_;
1084     badcfg "ftpmasterapi archive query method takes no data part"
1085         if length $data;
1086     my @cmd = archive_api_query_cmd($subpath);
1087     my $url = $cmd[$#cmd];
1088     push @cmd, qw(-w %{http_code});
1089     my $json = cmdoutput @cmd;
1090     unless ($json =~ s/\d+\d+\d$//) {
1091         failedcmd_report_cmd undef, @cmd;
1092         fail "curl failed to print 3-digit HTTP code";
1093     }
1094     my $code = $&;
1095     return undef if $code eq '404' && $ok404;
1096     fail "fetch of $url gave HTTP code $code"
1097         unless $url =~ m#^file://# or $code =~ m/^2/;
1098     return decode_json($json);
1099 }
1100
1101 sub canonicalise_suite_ftpmasterapi {
1102     my ($proto,$data) = @_;
1103     my $suites = api_query($data, 'suites');
1104     my @matched;
1105     foreach my $entry (@$suites) {
1106         next unless grep {
1107             my $v = $entry->{$_};
1108             defined $v && $v eq $isuite;
1109         } qw(codename name);
1110         push @matched, $entry;
1111     }
1112     fail "unknown suite $isuite" unless @matched;
1113     my $cn;
1114     eval {
1115         @matched==1 or die "multiple matches for suite $isuite\n";
1116         $cn = "$matched[0]{codename}";
1117         defined $cn or die "suite $isuite info has no codename\n";
1118         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1119     };
1120     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1121         if length $@;
1122     return $cn;
1123 }
1124
1125 sub archive_query_ftpmasterapi {
1126     my ($proto,$data) = @_;
1127     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1128     my @rows;
1129     my $digester = Digest::SHA->new(256);
1130     foreach my $entry (@$info) {
1131         eval {
1132             my $vsn = "$entry->{version}";
1133             my ($ok,$msg) = version_check $vsn;
1134             die "bad version: $msg\n" unless $ok;
1135             my $component = "$entry->{component}";
1136             $component =~ m/^$component_re$/ or die "bad component";
1137             my $filename = "$entry->{filename}";
1138             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1139                 or die "bad filename";
1140             my $sha256sum = "$entry->{sha256sum}";
1141             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1142             push @rows, [ $vsn, "/pool/$component/$filename",
1143                           $digester, $sha256sum ];
1144         };
1145         die "bad ftpmaster api response: $@\n".Dumper($entry)
1146             if length $@;
1147     }
1148     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1149     return archive_query_prepend_mirror @rows;
1150 }
1151
1152 sub file_in_archive_ftpmasterapi {
1153     my ($proto,$data,$filename) = @_;
1154     my $pat = $filename;
1155     $pat =~ s/_/\\_/g;
1156     $pat = "%/$pat";
1157     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1158     my $info = api_query($data, "file_in_archive/$pat", 1);
1159 }
1160
1161 #---------- `aptget' archive query method ----------
1162
1163 our $aptget_base;
1164 our $aptget_releasefile;
1165 our $aptget_configpath;
1166
1167 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1168 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1169
1170 sub aptget_cache_clean {
1171     runcmd_ordryrun_local qw(sh -ec),
1172         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1173         'x', $aptget_base;
1174 }
1175
1176 sub aptget_lock_acquire () {
1177     my $lockfile = "$aptget_base/lock";
1178     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1179     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1180 }
1181
1182 sub aptget_prep ($) {
1183     my ($data) = @_;
1184     return if defined $aptget_base;
1185
1186     badcfg "aptget archive query method takes no data part"
1187         if length $data;
1188
1189     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1190
1191     ensuredir $cache;
1192     ensuredir "$cache/dgit";
1193     my $cachekey =
1194         access_cfg('aptget-cachekey','RETURN-UNDEF')
1195         // access_nomdistro();
1196
1197     $aptget_base = "$cache/dgit/aptget";
1198     ensuredir $aptget_base;
1199
1200     my $quoted_base = $aptget_base;
1201     die "$quoted_base contains bad chars, cannot continue"
1202         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1203
1204     ensuredir $aptget_base;
1205
1206     aptget_lock_acquire();
1207
1208     aptget_cache_clean();
1209
1210     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1211     my $sourceslist = "source.list#$cachekey";
1212
1213     my $aptsuites = $isuite;
1214     cfg_apply_map(\$aptsuites, 'suite map',
1215                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1216
1217     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1218     printf SRCS "deb-src %s %s %s\n",
1219         access_cfg('mirror'),
1220         $aptsuites,
1221         access_cfg('aptget-components')
1222         or die $!;
1223
1224     ensuredir "$aptget_base/cache";
1225     ensuredir "$aptget_base/lists";
1226
1227     open CONF, ">", $aptget_configpath or die $!;
1228     print CONF <<END;
1229 Debug::NoLocking "true";
1230 APT::Get::List-Cleanup "false";
1231 #clear APT::Update::Post-Invoke-Success;
1232 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1233 Dir::State::Lists "$quoted_base/lists";
1234 Dir::Etc::preferences "$quoted_base/preferences";
1235 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1236 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1237 END
1238
1239     foreach my $key (qw(
1240                         Dir::Cache
1241                         Dir::State
1242                         Dir::Cache::Archives
1243                         Dir::Etc::SourceParts
1244                         Dir::Etc::preferencesparts
1245                       )) {
1246         ensuredir "$aptget_base/$key";
1247         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1248     };
1249
1250     my $oldatime = (time // die $!) - 1;
1251     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1252         next unless stat_exists $oldlist;
1253         my ($mtime) = (stat _)[9];
1254         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1255     }
1256
1257     runcmd_ordryrun_local aptget_aptget(), qw(update);
1258
1259     my @releasefiles;
1260     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1261         next unless stat_exists $oldlist;
1262         my ($atime) = (stat _)[8];
1263         next if $atime == $oldatime;
1264         push @releasefiles, $oldlist;
1265     }
1266     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1267     @releasefiles = @inreleasefiles if @inreleasefiles;
1268     die "apt updated wrong number of Release files (@releasefiles), erk"
1269         unless @releasefiles == 1;
1270
1271     ($aptget_releasefile) = @releasefiles;
1272 }
1273
1274 sub canonicalise_suite_aptget {
1275     my ($proto,$data) = @_;
1276     aptget_prep($data);
1277
1278     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1279
1280     foreach my $name (qw(Codename Suite)) {
1281         my $val = $release->{$name};
1282         if (defined $val) {
1283             printdebug "release file $name: $val\n";
1284             $val =~ m/^$suite_re$/o or fail
1285  "Release file ($aptget_releasefile) specifies intolerable $name";
1286             cfg_apply_map(\$val, 'suite rmap',
1287                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1288             return $val
1289         }
1290     }
1291     return $isuite;
1292 }
1293
1294 sub archive_query_aptget {
1295     my ($proto,$data) = @_;
1296     aptget_prep($data);
1297
1298     ensuredir "$aptget_base/source";
1299     foreach my $old (<$aptget_base/source/*.dsc>) {
1300         unlink $old or die "$old: $!";
1301     }
1302
1303     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1304     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1305     # avoids apt-get source failing with ambiguous error code
1306
1307     runcmd_ordryrun_local
1308         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1309         aptget_aptget(), qw(--download-only --only-source source), $package;
1310
1311     my @dscs = <$aptget_base/source/*.dsc>;
1312     fail "apt-get source did not produce a .dsc" unless @dscs;
1313     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1314
1315     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1316
1317     use URI::Escape;
1318     my $uri = "file://". uri_escape $dscs[0];
1319     $uri =~ s{\%2f}{/}gi;
1320     return [ (getfield $pre_dsc, 'Version'), $uri ];
1321 }
1322
1323 #---------- `dummyapicat' archive query method ----------
1324
1325 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1326 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1327
1328 sub file_in_archive_dummycatapi ($$$) {
1329     my ($proto,$data,$filename) = @_;
1330     my $mirror = access_cfg('mirror');
1331     $mirror =~ s#^file://#/# or die "$mirror ?";
1332     my @out;
1333     my @cmd = (qw(sh -ec), '
1334             cd "$1"
1335             find -name "$2" -print0 |
1336             xargs -0r sha256sum
1337         ', qw(x), $mirror, $filename);
1338     debugcmd "-|", @cmd;
1339     open FIA, "-|", @cmd or die $!;
1340     while (<FIA>) {
1341         chomp or die;
1342         printdebug "| $_\n";
1343         m/^(\w+)  (\S+)$/ or die "$_ ?";
1344         push @out, { sha256sum => $1, filename => $2 };
1345     }
1346     close FIA or die failedcmd @cmd;
1347     return \@out;
1348 }
1349
1350 #---------- `madison' archive query method ----------
1351
1352 sub archive_query_madison {
1353     return archive_query_prepend_mirror
1354         map { [ @$_[0..1] ] } madison_get_parse(@_);
1355 }
1356
1357 sub madison_get_parse {
1358     my ($proto,$data) = @_;
1359     die unless $proto eq 'madison';
1360     if (!length $data) {
1361         $data= access_cfg('madison-distro','RETURN-UNDEF');
1362         $data //= access_basedistro();
1363     }
1364     $rmad{$proto,$data,$package} ||= cmdoutput
1365         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1366     my $rmad = $rmad{$proto,$data,$package};
1367
1368     my @out;
1369     foreach my $l (split /\n/, $rmad) {
1370         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1371                   \s*( [^ \t|]+ )\s* \|
1372                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1373                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1374         $1 eq $package or die "$rmad $package ?";
1375         my $vsn = $2;
1376         my $newsuite = $3;
1377         my $component;
1378         if (defined $4) {
1379             $component = $4;
1380         } else {
1381             $component = access_cfg('archive-query-default-component');
1382         }
1383         $5 eq 'source' or die "$rmad ?";
1384         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1385     }
1386     return sort { -version_compare($a->[0],$b->[0]); } @out;
1387 }
1388
1389 sub canonicalise_suite_madison {
1390     # madison canonicalises for us
1391     my @r = madison_get_parse(@_);
1392     @r or fail
1393         "unable to canonicalise suite using package $package".
1394         " which does not appear to exist in suite $isuite;".
1395         " --existing-package may help";
1396     return $r[0][2];
1397 }
1398
1399 sub file_in_archive_madison { return undef; }
1400
1401 #---------- `sshpsql' archive query method ----------
1402
1403 sub sshpsql ($$$) {
1404     my ($data,$runeinfo,$sql) = @_;
1405     if (!length $data) {
1406         $data= access_someuserhost('sshpsql').':'.
1407             access_cfg('sshpsql-dbname');
1408     }
1409     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1410     my ($userhost,$dbname) = ($`,$'); #';
1411     my @rows;
1412     my @cmd = (access_cfg_ssh, $userhost,
1413                access_runeinfo("ssh-psql $runeinfo").
1414                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1415                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1416     debugcmd "|",@cmd;
1417     open P, "-|", @cmd or die $!;
1418     while (<P>) {
1419         chomp or die;
1420         printdebug(">|$_|\n");
1421         push @rows, $_;
1422     }
1423     $!=0; $?=0; close P or failedcmd @cmd;
1424     @rows or die;
1425     my $nrows = pop @rows;
1426     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1427     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1428     @rows = map { [ split /\|/, $_ ] } @rows;
1429     my $ncols = scalar @{ shift @rows };
1430     die if grep { scalar @$_ != $ncols } @rows;
1431     return @rows;
1432 }
1433
1434 sub sql_injection_check {
1435     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1436 }
1437
1438 sub archive_query_sshpsql ($$) {
1439     my ($proto,$data) = @_;
1440     sql_injection_check $isuite, $package;
1441     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1442         SELECT source.version, component.name, files.filename, files.sha256sum
1443           FROM source
1444           JOIN src_associations ON source.id = src_associations.source
1445           JOIN suite ON suite.id = src_associations.suite
1446           JOIN dsc_files ON dsc_files.source = source.id
1447           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1448           JOIN component ON component.id = files_archive_map.component_id
1449           JOIN files ON files.id = dsc_files.file
1450          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1451            AND source.source='$package'
1452            AND files.filename LIKE '%.dsc';
1453 END
1454     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1455     my $digester = Digest::SHA->new(256);
1456     @rows = map {
1457         my ($vsn,$component,$filename,$sha256sum) = @$_;
1458         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1459     } @rows;
1460     return archive_query_prepend_mirror @rows;
1461 }
1462
1463 sub canonicalise_suite_sshpsql ($$) {
1464     my ($proto,$data) = @_;
1465     sql_injection_check $isuite;
1466     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1467         SELECT suite.codename
1468           FROM suite where suite_name='$isuite' or codename='$isuite';
1469 END
1470     @rows = map { $_->[0] } @rows;
1471     fail "unknown suite $isuite" unless @rows;
1472     die "ambiguous $isuite: @rows ?" if @rows>1;
1473     return $rows[0];
1474 }
1475
1476 sub file_in_archive_sshpsql ($$$) { return undef; }
1477
1478 #---------- `dummycat' archive query method ----------
1479
1480 sub canonicalise_suite_dummycat ($$) {
1481     my ($proto,$data) = @_;
1482     my $dpath = "$data/suite.$isuite";
1483     if (!open C, "<", $dpath) {
1484         $!==ENOENT or die "$dpath: $!";
1485         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1486         return $isuite;
1487     }
1488     $!=0; $_ = <C>;
1489     chomp or die "$dpath: $!";
1490     close C;
1491     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1492     return $_;
1493 }
1494
1495 sub archive_query_dummycat ($$) {
1496     my ($proto,$data) = @_;
1497     canonicalise_suite();
1498     my $dpath = "$data/package.$csuite.$package";
1499     if (!open C, "<", $dpath) {
1500         $!==ENOENT or die "$dpath: $!";
1501         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1502         return ();
1503     }
1504     my @rows;
1505     while (<C>) {
1506         next if m/^\#/;
1507         next unless m/\S/;
1508         die unless chomp;
1509         printdebug "dummycat query $csuite $package $dpath | $_\n";
1510         my @row = split /\s+/, $_;
1511         @row==2 or die "$dpath: $_ ?";
1512         push @rows, \@row;
1513     }
1514     C->error and die "$dpath: $!";
1515     close C;
1516     return archive_query_prepend_mirror
1517         sort { -version_compare($a->[0],$b->[0]); } @rows;
1518 }
1519
1520 sub file_in_archive_dummycat () { return undef; }
1521
1522 #---------- tag format handling ----------
1523
1524 sub access_cfg_tagformats () {
1525     split /\,/, access_cfg('dgit-tag-format');
1526 }
1527
1528 sub access_cfg_tagformats_can_splitbrain () {
1529     my %y = map { $_ => 1 } access_cfg_tagformats;
1530     foreach my $needtf (qw(new maint)) {
1531         next if $y{$needtf};
1532         return 0;
1533     }
1534     return 1;
1535 }
1536
1537 sub need_tagformat ($$) {
1538     my ($fmt, $why) = @_;
1539     fail "need to use tag format $fmt ($why) but also need".
1540         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1541         " - no way to proceed"
1542         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1543     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1544 }
1545
1546 sub select_tagformat () {
1547     # sets $tagformatfn
1548     return if $tagformatfn && !$tagformat_want;
1549     die 'bug' if $tagformatfn && $tagformat_want;
1550     # ... $tagformat_want assigned after previous select_tagformat
1551
1552     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1553     printdebug "select_tagformat supported @supported\n";
1554
1555     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1556     printdebug "select_tagformat specified @$tagformat_want\n";
1557
1558     my ($fmt,$why,$override) = @$tagformat_want;
1559
1560     fail "target distro supports tag formats @supported".
1561         " but have to use $fmt ($why)"
1562         unless $override
1563             or grep { $_ eq $fmt } @supported;
1564
1565     $tagformat_want = undef;
1566     $tagformat = $fmt;
1567     $tagformatfn = ${*::}{"debiantag_$fmt"};
1568
1569     fail "trying to use unknown tag format \`$fmt' ($why) !"
1570         unless $tagformatfn;
1571 }
1572
1573 #---------- archive query entrypoints and rest of program ----------
1574
1575 sub canonicalise_suite () {
1576     return if defined $csuite;
1577     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1578     $csuite = archive_query('canonicalise_suite');
1579     if ($isuite ne $csuite) {
1580         progress "canonical suite name for $isuite is $csuite";
1581     } else {
1582         progress "canonical suite name is $csuite";
1583     }
1584 }
1585
1586 sub get_archive_dsc () {
1587     canonicalise_suite();
1588     my @vsns = archive_query('archive_query');
1589     foreach my $vinfo (@vsns) {
1590         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1591         $dscurl = $vsn_dscurl;
1592         $dscdata = url_get($dscurl);
1593         if (!$dscdata) {
1594             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1595             next;
1596         }
1597         if ($digester) {
1598             $digester->reset();
1599             $digester->add($dscdata);
1600             my $got = $digester->hexdigest();
1601             $got eq $digest or
1602                 fail "$dscurl has hash $got but".
1603                     " archive told us to expect $digest";
1604         }
1605         parse_dscdata();
1606         my $fmt = getfield $dsc, 'Format';
1607         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1608             "unsupported source format $fmt, sorry";
1609
1610         $dsc_checked = !!$digester;
1611         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1612         return;
1613     }
1614     $dsc = undef;
1615     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1616 }
1617
1618 sub check_for_git ();
1619 sub check_for_git () {
1620     # returns 0 or 1
1621     my $how = access_cfg('git-check');
1622     if ($how eq 'ssh-cmd') {
1623         my @cmd =
1624             (access_cfg_ssh, access_gituserhost(),
1625              access_runeinfo("git-check $package").
1626              " set -e; cd ".access_cfg('git-path').";".
1627              " if test -d $package.git; then echo 1; else echo 0; fi");
1628         my $r= cmdoutput @cmd;
1629         if (defined $r and $r =~ m/^divert (\w+)$/) {
1630             my $divert=$1;
1631             my ($usedistro,) = access_distros();
1632             # NB that if we are pushing, $usedistro will be $distro/push
1633             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1634             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1635             progress "diverting to $divert (using config for $instead_distro)";
1636             return check_for_git();
1637         }
1638         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1639         return $r+0;
1640     } elsif ($how eq 'url') {
1641         my $prefix = access_cfg('git-check-url','git-url');
1642         my $suffix = access_cfg('git-check-suffix','git-suffix',
1643                                 'RETURN-UNDEF') // '.git';
1644         my $url = "$prefix/$package$suffix";
1645         my @cmd = (@curl, qw(-sS -I), $url);
1646         my $result = cmdoutput @cmd;
1647         $result =~ s/^\S+ 200 .*\n\r?\n//;
1648         # curl -sS -I with https_proxy prints
1649         # HTTP/1.0 200 Connection established
1650         $result =~ m/^\S+ (404|200) /s or
1651             fail "unexpected results from git check query - ".
1652                 Dumper($prefix, $result);
1653         my $code = $1;
1654         if ($code eq '404') {
1655             return 0;
1656         } elsif ($code eq '200') {
1657             return 1;
1658         } else {
1659             die;
1660         }
1661     } elsif ($how eq 'true') {
1662         return 1;
1663     } elsif ($how eq 'false') {
1664         return 0;
1665     } else {
1666         badcfg "unknown git-check \`$how'";
1667     }
1668 }
1669
1670 sub create_remote_git_repo () {
1671     my $how = access_cfg('git-create');
1672     if ($how eq 'ssh-cmd') {
1673         runcmd_ordryrun
1674             (access_cfg_ssh, access_gituserhost(),
1675              access_runeinfo("git-create $package").
1676              "set -e; cd ".access_cfg('git-path').";".
1677              " cp -a _template $package.git");
1678     } elsif ($how eq 'true') {
1679         # nothing to do
1680     } else {
1681         badcfg "unknown git-create \`$how'";
1682     }
1683 }
1684
1685 our ($dsc_hash,$lastpush_mergeinput);
1686 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1687
1688 our $ud = '.git/dgit/unpack';
1689
1690 sub prep_ud (;$) {
1691     my ($d) = @_;
1692     $d //= $ud;
1693     rmtree($d);
1694     mkpath '.git/dgit';
1695     mkdir $d or die $!;
1696 }
1697
1698 sub mktree_in_ud_here () {
1699     runcmd qw(git init -q);
1700     runcmd qw(git config gc.auto 0);
1701     rmtree('.git/objects');
1702     symlink '../../../../objects','.git/objects' or die $!;
1703 }
1704
1705 sub git_write_tree () {
1706     my $tree = cmdoutput @git, qw(write-tree);
1707     $tree =~ m/^\w+$/ or die "$tree ?";
1708     return $tree;
1709 }
1710
1711 sub git_add_write_tree () {
1712     runcmd @git, qw(add -Af .);
1713     return git_write_tree();
1714 }
1715
1716 sub remove_stray_gits ($) {
1717     my ($what) = @_;
1718     my @gitscmd = qw(find -name .git -prune -print0);
1719     debugcmd "|",@gitscmd;
1720     open GITS, "-|", @gitscmd or die $!;
1721     {
1722         local $/="\0";
1723         while (<GITS>) {
1724             chomp or die;
1725             print STDERR "$us: warning: removing from $what: ",
1726                 (messagequote $_), "\n";
1727             rmtree $_;
1728         }
1729     }
1730     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1731 }
1732
1733 sub mktree_in_ud_from_only_subdir ($;$) {
1734     my ($what,$raw) = @_;
1735
1736     # changes into the subdir
1737     my (@dirs) = <*/.>;
1738     die "expected one subdir but found @dirs ?" unless @dirs==1;
1739     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1740     my $dir = $1;
1741     changedir $dir;
1742
1743     remove_stray_gits($what);
1744     mktree_in_ud_here();
1745     if (!$raw) {
1746         my ($format, $fopts) = get_source_format();
1747         if (madformat($format)) {
1748             rmtree '.pc';
1749         }
1750     }
1751
1752     my $tree=git_add_write_tree();
1753     return ($tree,$dir);
1754 }
1755
1756 our @files_csum_info_fields =
1757     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1758      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1759      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1760
1761 sub dsc_files_info () {
1762     foreach my $csumi (@files_csum_info_fields) {
1763         my ($fname, $module, $method) = @$csumi;
1764         my $field = $dsc->{$fname};
1765         next unless defined $field;
1766         eval "use $module; 1;" or die $@;
1767         my @out;
1768         foreach (split /\n/, $field) {
1769             next unless m/\S/;
1770             m/^(\w+) (\d+) (\S+)$/ or
1771                 fail "could not parse .dsc $fname line \`$_'";
1772             my $digester = eval "$module"."->$method;" or die $@;
1773             push @out, {
1774                 Hash => $1,
1775                 Bytes => $2,
1776                 Filename => $3,
1777                 Digester => $digester,
1778             };
1779         }
1780         return @out;
1781     }
1782     fail "missing any supported Checksums-* or Files field in ".
1783         $dsc->get_option('name');
1784 }
1785
1786 sub dsc_files () {
1787     map { $_->{Filename} } dsc_files_info();
1788 }
1789
1790 sub files_compare_inputs (@) {
1791     my $inputs = \@_;
1792     my %record;
1793     my %fchecked;
1794
1795     my $showinputs = sub {
1796         return join "; ", map { $_->get_option('name') } @$inputs;
1797     };
1798
1799     foreach my $in (@$inputs) {
1800         my $expected_files;
1801         my $in_name = $in->get_option('name');
1802
1803         printdebug "files_compare_inputs $in_name\n";
1804
1805         foreach my $csumi (@files_csum_info_fields) {
1806             my ($fname) = @$csumi;
1807             printdebug "files_compare_inputs $in_name $fname\n";
1808
1809             my $field = $in->{$fname};
1810             next unless defined $field;
1811
1812             my @files;
1813             foreach (split /\n/, $field) {
1814                 next unless m/\S/;
1815
1816                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1817                     fail "could not parse $in_name $fname line \`$_'";
1818
1819                 printdebug "files_compare_inputs $in_name $fname $f\n";
1820
1821                 push @files, $f;
1822
1823                 my $re = \ $record{$f}{$fname};
1824                 if (defined $$re) {
1825                     $fchecked{$f}{$in_name} = 1;
1826                     $$re eq $info or
1827                         fail "hash or size of $f varies in $fname fields".
1828                         " (between: ".$showinputs->().")";
1829                 } else {
1830                     $$re = $info;
1831                 }
1832             }
1833             @files = sort @files;
1834             $expected_files //= \@files;
1835             "@$expected_files" eq "@files" or
1836                 fail "file list in $in_name varies between hash fields!";
1837         }
1838         $expected_files or
1839             fail "$in_name has no files list field(s)";
1840     }
1841     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1842         if $debuglevel>=2;
1843
1844     grep { keys %$_ == @$inputs-1 } values %fchecked
1845         or fail "no file appears in all file lists".
1846         " (looked in: ".$showinputs->().")";
1847 }
1848
1849 sub is_orig_file_in_dsc ($$) {
1850     my ($f, $dsc_files_info) = @_;
1851     return 0 if @$dsc_files_info <= 1;
1852     # One file means no origs, and the filename doesn't have a "what
1853     # part of dsc" component.  (Consider versions ending `.orig'.)
1854     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1855     return 1;
1856 }
1857
1858 sub is_orig_file_of_vsn ($$) {
1859     my ($f, $upstreamvsn) = @_;
1860     my $base = srcfn $upstreamvsn, '';
1861     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1862     return 1;
1863 }
1864
1865 sub changes_update_origs_from_dsc ($$$$) {
1866     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1867     my %changes_f;
1868     printdebug "checking origs needed ($upstreamvsn)...\n";
1869     $_ = getfield $changes, 'Files';
1870     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1871         fail "cannot find section/priority from .changes Files field";
1872     my $placementinfo = $1;
1873     my %changed;
1874     printdebug "checking origs needed placement '$placementinfo'...\n";
1875     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1876         $l =~ m/\S+$/ or next;
1877         my $file = $&;
1878         printdebug "origs $file | $l\n";
1879         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1880         printdebug "origs $file is_orig\n";
1881         my $have = archive_query('file_in_archive', $file);
1882         if (!defined $have) {
1883             print STDERR <<END;
1884 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1885 END
1886             return;
1887         }
1888         my $found_same = 0;
1889         my @found_differ;
1890         printdebug "origs $file \$#\$have=$#$have\n";
1891         foreach my $h (@$have) {
1892             my $same = 0;
1893             my @differ;
1894             foreach my $csumi (@files_csum_info_fields) {
1895                 my ($fname, $module, $method, $archivefield) = @$csumi;
1896                 next unless defined $h->{$archivefield};
1897                 $_ = $dsc->{$fname};
1898                 next unless defined;
1899                 m/^(\w+) .* \Q$file\E$/m or
1900                     fail ".dsc $fname missing entry for $file";
1901                 if ($h->{$archivefield} eq $1) {
1902                     $same++;
1903                 } else {
1904                     push @differ,
1905  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1906                 }
1907             }
1908             die "$file ".Dumper($h)." ?!" if $same && @differ;
1909             $found_same++
1910                 if $same;
1911             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1912                 if @differ;
1913         }
1914         printdebug "origs $file f.same=$found_same".
1915             " #f._differ=$#found_differ\n";
1916         if (@found_differ && !$found_same) {
1917             fail join "\n",
1918                 "archive contains $file with different checksum",
1919                 @found_differ;
1920         }
1921         # Now we edit the changes file to add or remove it
1922         foreach my $csumi (@files_csum_info_fields) {
1923             my ($fname, $module, $method, $archivefield) = @$csumi;
1924             next unless defined $changes->{$fname};
1925             if ($found_same) {
1926                 # in archive, delete from .changes if it's there
1927                 $changed{$file} = "removed" if
1928                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1929             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1930                 # not in archive, but it's here in the .changes
1931             } else {
1932                 my $dsc_data = getfield $dsc, $fname;
1933                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1934                 my $extra = $1;
1935                 $extra =~ s/ \d+ /$&$placementinfo /
1936                     or die "$fname $extra >$dsc_data< ?"
1937                     if $fname eq 'Files';
1938                 $changes->{$fname} .= "\n". $extra;
1939                 $changed{$file} = "added";
1940             }
1941         }
1942     }
1943     if (%changed) {
1944         foreach my $file (keys %changed) {
1945             progress sprintf
1946                 "edited .changes for archive .orig contents: %s %s",
1947                 $changed{$file}, $file;
1948         }
1949         my $chtmp = "$changesfile.tmp";
1950         $changes->save($chtmp);
1951         if (act_local()) {
1952             rename $chtmp,$changesfile or die "$changesfile $!";
1953         } else {
1954             progress "[new .changes left in $changesfile]";
1955         }
1956     } else {
1957         progress "$changesfile already has appropriate .orig(s) (if any)";
1958     }
1959 }
1960
1961 sub make_commit ($) {
1962     my ($file) = @_;
1963     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1964 }
1965
1966 sub make_commit_text ($) {
1967     my ($text) = @_;
1968     my ($out, $in);
1969     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1970     debugcmd "|",@cmd;
1971     print Dumper($text) if $debuglevel > 1;
1972     my $child = open2($out, $in, @cmd) or die $!;
1973     my $h;
1974     eval {
1975         print $in $text or die $!;
1976         close $in or die $!;
1977         $h = <$out>;
1978         $h =~ m/^\w+$/ or die;
1979         $h = $&;
1980         printdebug "=> $h\n";
1981     };
1982     close $out;
1983     waitpid $child, 0 == $child or die "$child $!";
1984     $? and failedcmd @cmd;
1985     return $h;
1986 }
1987
1988 sub clogp_authline ($) {
1989     my ($clogp) = @_;
1990     my $author = getfield $clogp, 'Maintainer';
1991     $author =~ s#,.*##ms;
1992     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1993     my $authline = "$author $date";
1994     $authline =~ m/$git_authline_re/o or
1995         fail "unexpected commit author line format \`$authline'".
1996         " (was generated from changelog Maintainer field)";
1997     return ($1,$2,$3) if wantarray;
1998     return $authline;
1999 }
2000
2001 sub vendor_patches_distro ($$) {
2002     my ($checkdistro, $what) = @_;
2003     return unless defined $checkdistro;
2004
2005     my $series = "debian/patches/\L$checkdistro\E.series";
2006     printdebug "checking for vendor-specific $series ($what)\n";
2007
2008     if (!open SERIES, "<", $series) {
2009         die "$series $!" unless $!==ENOENT;
2010         return;
2011     }
2012     while (<SERIES>) {
2013         next unless m/\S/;
2014         next if m/^\s+\#/;
2015
2016         print STDERR <<END;
2017
2018 Unfortunately, this source package uses a feature of dpkg-source where
2019 the same source package unpacks to different source code on different
2020 distros.  dgit cannot safely operate on such packages on affected
2021 distros, because the meaning of source packages is not stable.
2022
2023 Please ask the distro/maintainer to remove the distro-specific series
2024 files and use a different technique (if necessary, uploading actually
2025 different packages, if different distros are supposed to have
2026 different code).
2027
2028 END
2029         fail "Found active distro-specific series file for".
2030             " $checkdistro ($what): $series, cannot continue";
2031     }
2032     die "$series $!" if SERIES->error;
2033     close SERIES;
2034 }
2035
2036 sub check_for_vendor_patches () {
2037     # This dpkg-source feature doesn't seem to be documented anywhere!
2038     # But it can be found in the changelog (reformatted):
2039
2040     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2041     #   Author: Raphael Hertzog <hertzog@debian.org>
2042     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2043
2044     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2045     #   series files
2046     #
2047     #   If you have debian/patches/ubuntu.series and you were
2048     #   unpacking the source package on ubuntu, quilt was still
2049     #   directed to debian/patches/series instead of
2050     #   debian/patches/ubuntu.series.
2051     #
2052     #   debian/changelog                        |    3 +++
2053     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2054     #   2 files changed, 6 insertions(+), 1 deletion(-)
2055
2056     use Dpkg::Vendor;
2057     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2058     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2059                          "Dpkg::Vendor \`current vendor'");
2060     vendor_patches_distro(access_basedistro(),
2061                           "(base) distro being accessed");
2062     vendor_patches_distro(access_nomdistro(),
2063                           "(nominal) distro being accessed");
2064 }
2065
2066 sub generate_commits_from_dsc () {
2067     # See big comment in fetch_from_archive, below.
2068     # See also README.dsc-import.
2069     prep_ud();
2070     changedir $ud;
2071
2072     my @dfi = dsc_files_info();
2073     foreach my $fi (@dfi) {
2074         my $f = $fi->{Filename};
2075         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2076
2077         printdebug "considering linking $f: ";
2078
2079         link_ltarget "../../../../$f", $f
2080             or ((printdebug "($!) "), 0)
2081             or $!==&ENOENT
2082             or die "$f $!";
2083
2084         printdebug "linked.\n";
2085
2086         complete_file_from_dsc('.', $fi)
2087             or next;
2088
2089         if (is_orig_file_in_dsc($f, \@dfi)) {
2090             link $f, "../../../../$f"
2091                 or $!==&EEXIST
2092                 or die "$f $!";
2093         }
2094     }
2095
2096     # We unpack and record the orig tarballs first, so that we only
2097     # need disk space for one private copy of the unpacked source.
2098     # But we can't make them into commits until we have the metadata
2099     # from the debian/changelog, so we record the tree objects now and
2100     # make them into commits later.
2101     my @tartrees;
2102     my $upstreamv = upstreamversion $dsc->{version};
2103     my $orig_f_base = srcfn $upstreamv, '';
2104
2105     foreach my $fi (@dfi) {
2106         # We actually import, and record as a commit, every tarball
2107         # (unless there is only one file, in which case there seems
2108         # little point.
2109
2110         my $f = $fi->{Filename};
2111         printdebug "import considering $f ";
2112         (printdebug "only one dfi\n"), next if @dfi == 1;
2113         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2114         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2115         my $compr_ext = $1;
2116
2117         my ($orig_f_part) =
2118             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2119
2120         printdebug "Y ", (join ' ', map { $_//"(none)" }
2121                           $compr_ext, $orig_f_part
2122                          ), "\n";
2123
2124         my $input = new IO::File $f, '<' or die "$f $!";
2125         my $compr_pid;
2126         my @compr_cmd;
2127
2128         if (defined $compr_ext) {
2129             my $cname =
2130                 Dpkg::Compression::compression_guess_from_filename $f;
2131             fail "Dpkg::Compression cannot handle file $f in source package"
2132                 if defined $compr_ext && !defined $cname;
2133             my $compr_proc =
2134                 new Dpkg::Compression::Process compression => $cname;
2135             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2136             my $compr_fh = new IO::Handle;
2137             my $compr_pid = open $compr_fh, "-|" // die $!;
2138             if (!$compr_pid) {
2139                 open STDIN, "<&", $input or die $!;
2140                 exec @compr_cmd;
2141                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2142             }
2143             $input = $compr_fh;
2144         }
2145
2146         rmtree "_unpack-tar";
2147         mkdir "_unpack-tar" or die $!;
2148         my @tarcmd = qw(tar -x -f -
2149                         --no-same-owner --no-same-permissions
2150                         --no-acls --no-xattrs --no-selinux);
2151         my $tar_pid = fork // die $!;
2152         if (!$tar_pid) {
2153             chdir "_unpack-tar" or die $!;
2154             open STDIN, "<&", $input or die $!;
2155             exec @tarcmd;
2156             die "dgit (child): exec $tarcmd[0]: $!";
2157         }
2158         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2159         !$? or failedcmd @tarcmd;
2160
2161         close $input or
2162             (@compr_cmd ? failedcmd @compr_cmd
2163              : die $!);
2164         # finally, we have the results in "tarball", but maybe
2165         # with the wrong permissions
2166
2167         runcmd qw(chmod -R +rwX _unpack-tar);
2168         changedir "_unpack-tar";
2169         remove_stray_gits($f);
2170         mktree_in_ud_here();
2171
2172         my ($tree) = git_add_write_tree();
2173         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2174         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2175             $tree = $1;
2176             printdebug "one subtree $1\n";
2177         } else {
2178             printdebug "multiple subtrees\n";
2179         }
2180         changedir "..";
2181         rmtree "_unpack-tar";
2182
2183         my $ent = [ $f, $tree ];
2184         push @tartrees, {
2185             Orig => !!$orig_f_part,
2186             Sort => (!$orig_f_part         ? 2 :
2187                      $orig_f_part =~ m/-/g ? 1 :
2188                                              0),
2189             F => $f,
2190             Tree => $tree,
2191         };
2192     }
2193
2194     @tartrees = sort {
2195         # put any without "_" first (spec is not clear whether files
2196         # are always in the usual order).  Tarballs without "_" are
2197         # the main orig or the debian tarball.
2198         $a->{Sort} <=> $b->{Sort} or
2199         $a->{F}    cmp $b->{F}
2200     } @tartrees;
2201
2202     my $any_orig = grep { $_->{Orig} } @tartrees;
2203
2204     my $dscfn = "$package.dsc";
2205
2206     my $treeimporthow = 'package';
2207
2208     open D, ">", $dscfn or die "$dscfn: $!";
2209     print D $dscdata or die "$dscfn: $!";
2210     close D or die "$dscfn: $!";
2211     my @cmd = qw(dpkg-source);
2212     push @cmd, '--no-check' if $dsc_checked;
2213     if (madformat $dsc->{format}) {
2214         push @cmd, '--skip-patches';
2215         $treeimporthow = 'unpatched';
2216     }
2217     push @cmd, qw(-x --), $dscfn;
2218     runcmd @cmd;
2219
2220     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2221     if (madformat $dsc->{format}) {
2222         check_for_vendor_patches();
2223     }
2224
2225     my $dappliedtree;
2226     if (madformat $dsc->{format}) {
2227         my @pcmd = qw(dpkg-source --before-build .);
2228         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2229         rmtree '.pc';
2230         $dappliedtree = git_add_write_tree();
2231     }
2232
2233     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2234     debugcmd "|",@clogcmd;
2235     open CLOGS, "-|", @clogcmd or die $!;
2236
2237     my $clogp;
2238     my $r1clogp;
2239
2240     printdebug "import clog search...\n";
2241
2242     for (;;) {
2243         my $stanzatext = do { local $/=""; <CLOGS>; };
2244         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2245         last if !defined $stanzatext;
2246
2247         my $desc = "package changelog, entry no.$.";
2248         open my $stanzafh, "<", \$stanzatext or die;
2249         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2250         $clogp //= $thisstanza;
2251
2252         printdebug "import clog $thisstanza->{version} $desc...\n";
2253
2254         last if !$any_orig; # we don't need $r1clogp
2255
2256         # We look for the first (most recent) changelog entry whose
2257         # version number is lower than the upstream version of this
2258         # package.  Then the last (least recent) previous changelog
2259         # entry is treated as the one which introduced this upstream
2260         # version and used for the synthetic commits for the upstream
2261         # tarballs.
2262
2263         # One might think that a more sophisticated algorithm would be
2264         # necessary.  But: we do not want to scan the whole changelog
2265         # file.  Stopping when we see an earlier version, which
2266         # necessarily then is an earlier upstream version, is the only
2267         # realistic way to do that.  Then, either the earliest
2268         # changelog entry we have seen so far is indeed the earliest
2269         # upload of this upstream version; or there are only changelog
2270         # entries relating to later upstream versions (which is not
2271         # possible unless the changelog and .dsc disagree about the
2272         # version).  Then it remains to choose between the physically
2273         # last entry in the file, and the one with the lowest version
2274         # number.  If these are not the same, we guess that the
2275         # versions were created in a non-monotic order rather than
2276         # that the changelog entries have been misordered.
2277
2278         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2279
2280         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2281         $r1clogp = $thisstanza;
2282
2283         printdebug "import clog $r1clogp->{version} becomes r1\n";
2284     }
2285     die $! if CLOGS->error;
2286     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2287
2288     $clogp or fail "package changelog has no entries!";
2289
2290     my $authline = clogp_authline $clogp;
2291     my $changes = getfield $clogp, 'Changes';
2292     my $cversion = getfield $clogp, 'Version';
2293
2294     if (@tartrees) {
2295         $r1clogp //= $clogp; # maybe there's only one entry;
2296         my $r1authline = clogp_authline $r1clogp;
2297         # Strictly, r1authline might now be wrong if it's going to be
2298         # unused because !$any_orig.  Whatever.
2299
2300         printdebug "import tartrees authline   $authline\n";
2301         printdebug "import tartrees r1authline $r1authline\n";
2302
2303         foreach my $tt (@tartrees) {
2304             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2305
2306             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2307 tree $tt->{Tree}
2308 author $r1authline
2309 committer $r1authline
2310
2311 Import $tt->{F}
2312
2313 [dgit import orig $tt->{F}]
2314 END_O
2315 tree $tt->{Tree}
2316 author $authline
2317 committer $authline
2318
2319 Import $tt->{F}
2320
2321 [dgit import tarball $package $cversion $tt->{F}]
2322 END_T
2323         }
2324     }
2325
2326     printdebug "import main commit\n";
2327
2328     open C, ">../commit.tmp" or die $!;
2329     print C <<END or die $!;
2330 tree $tree
2331 END
2332     print C <<END or die $! foreach @tartrees;
2333 parent $_->{Commit}
2334 END
2335     print C <<END or die $!;
2336 author $authline
2337 committer $authline
2338
2339 $changes
2340
2341 [dgit import $treeimporthow $package $cversion]
2342 END
2343
2344     close C or die $!;
2345     my $rawimport_hash = make_commit qw(../commit.tmp);
2346
2347     if (madformat $dsc->{format}) {
2348         printdebug "import apply patches...\n";
2349
2350         # regularise the state of the working tree so that
2351         # the checkout of $rawimport_hash works nicely.
2352         my $dappliedcommit = make_commit_text(<<END);
2353 tree $dappliedtree
2354 author $authline
2355 committer $authline
2356
2357 [dgit dummy commit]
2358 END
2359         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2360
2361         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2362
2363         # We need the answers to be reproducible
2364         my @authline = clogp_authline($clogp);
2365         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2366         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2367         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2368         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2369         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2370         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2371
2372         my $path = $ENV{PATH} or die;
2373
2374         foreach my $use_absurd (qw(0 1)) {
2375             runcmd @git, qw(checkout -q unpa);
2376             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2377             local $ENV{PATH} = $path;
2378             if ($use_absurd) {
2379                 chomp $@;
2380                 progress "warning: $@";
2381                 $path = "$absurdity:$path";
2382                 progress "$us: trying slow absurd-git-apply...";
2383                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2384                     or $!==ENOENT
2385                     or die $!;
2386             }
2387             eval {
2388                 die "forbid absurd git-apply\n" if $use_absurd
2389                     && forceing [qw(import-gitapply-no-absurd)];
2390                 die "only absurd git-apply!\n" if !$use_absurd
2391                     && forceing [qw(import-gitapply-absurd)];
2392
2393                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2394                 local $ENV{PATH} = $path                    if $use_absurd;
2395
2396                 my @showcmd = (gbp_pq, qw(import));
2397                 my @realcmd = shell_cmd
2398                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2399                 debugcmd "+",@realcmd;
2400                 if (system @realcmd) {
2401                     die +(shellquote @showcmd).
2402                         " failed: ".
2403                         failedcmd_waitstatus()."\n";
2404                 }
2405
2406                 my $gapplied = git_rev_parse('HEAD');
2407                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2408                 $gappliedtree eq $dappliedtree or
2409                     fail <<END;
2410 gbp-pq import and dpkg-source disagree!
2411  gbp-pq import gave commit $gapplied
2412  gbp-pq import gave tree $gappliedtree
2413  dpkg-source --before-build gave tree $dappliedtree
2414 END
2415                 $rawimport_hash = $gapplied;
2416             };
2417             last unless $@;
2418         }
2419         if ($@) {
2420             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2421             die $@;
2422         }
2423     }
2424
2425     progress "synthesised git commit from .dsc $cversion";
2426
2427     my $rawimport_mergeinput = {
2428         Commit => $rawimport_hash,
2429         Info => "Import of source package",
2430     };
2431     my @output = ($rawimport_mergeinput);
2432
2433     if ($lastpush_mergeinput) {
2434         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2435         my $oversion = getfield $oldclogp, 'Version';
2436         my $vcmp =
2437             version_compare($oversion, $cversion);
2438         if ($vcmp < 0) {
2439             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2440                 { Message => <<END, ReverseParents => 1 });
2441 Record $package ($cversion) in archive suite $csuite
2442 END
2443         } elsif ($vcmp > 0) {
2444             print STDERR <<END or die $!;
2445
2446 Version actually in archive:   $cversion (older)
2447 Last version pushed with dgit: $oversion (newer or same)
2448 $later_warning_msg
2449 END
2450             @output = $lastpush_mergeinput;
2451         } else {
2452             # Same version.  Use what's in the server git branch,
2453             # discarding our own import.  (This could happen if the
2454             # server automatically imports all packages into git.)
2455             @output = $lastpush_mergeinput;
2456         }
2457     }
2458     changedir '../../../..';
2459     rmtree($ud);
2460     return @output;
2461 }
2462
2463 sub complete_file_from_dsc ($$) {
2464     our ($dstdir, $fi) = @_;
2465     # Ensures that we have, in $dir, the file $fi, with the correct
2466     # contents.  (Downloading it from alongside $dscurl if necessary.)
2467
2468     my $f = $fi->{Filename};
2469     my $tf = "$dstdir/$f";
2470     my $downloaded = 0;
2471
2472     if (stat_exists $tf) {
2473         progress "using existing $f";
2474     } else {
2475         printdebug "$tf does not exist, need to fetch\n";
2476         my $furl = $dscurl;
2477         $furl =~ s{/[^/]+$}{};
2478         $furl .= "/$f";
2479         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2480         die "$f ?" if $f =~ m#/#;
2481         runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2482         return 0 if !act_local();
2483         $downloaded = 1;
2484     }
2485
2486     open F, "<", "$tf" or die "$tf: $!";
2487     $fi->{Digester}->reset();
2488     $fi->{Digester}->addfile(*F);
2489     F->error and die $!;
2490     my $got = $fi->{Digester}->hexdigest();
2491     $got eq $fi->{Hash} or
2492         fail "file $f has hash $got but .dsc".
2493             " demands hash $fi->{Hash} ".
2494             ($downloaded ? "(got wrong file from archive!)"
2495              : "(perhaps you should delete this file?)");
2496
2497     return 1;
2498 }
2499
2500 sub ensure_we_have_orig () {
2501     my @dfi = dsc_files_info();
2502     foreach my $fi (@dfi) {
2503         my $f = $fi->{Filename};
2504         next unless is_orig_file_in_dsc($f, \@dfi);
2505         complete_file_from_dsc('..', $fi)
2506             or next;
2507     }
2508 }
2509
2510 sub git_lrfetch_sane {
2511     my (@specs) = @_;
2512
2513     # This is rather miserable:
2514     # When git fetch --prune is passed a fetchspec ending with a *,
2515     # it does a plausible thing.  If there is no * then:
2516     # - it matches subpaths too, even if the supplied refspec
2517     #   starts refs, and behaves completely madly if the source
2518     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2519     # - if there is no matching remote ref, it bombs out the whole
2520     #   fetch.
2521     # We want to fetch a fixed ref, and we don't know in advance
2522     # if it exists, so this is not suitable.
2523     #
2524     # Our workaround is to use git ls-remote.  git ls-remote has its
2525     # own qairks.  Notably, it has the absurd multi-tail-matching
2526     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2527     # refs/refs/foo etc.
2528     #
2529     # Also, we want an idempotent snapshot, but we have to make two
2530     # calls to the remote: one to git ls-remote and to git fetch.  The
2531     # solution is use git ls-remote to obtain a target state, and
2532     # git fetch to try to generate it.  If we don't manage to generate
2533     # the target state, we try again.
2534
2535     printdebug "git_fetch_us specs @specs\n";
2536
2537     my $specre = join '|', map {
2538         my $x = $_;
2539         $x =~ s/\W/\\$&/g;
2540         $x =~ s/\\\*$/.*/;
2541         "(?:refs/$x)";
2542     } @specs;
2543     printdebug "git_fetch_us specre=$specre\n";
2544     my $wanted_rref = sub {
2545         local ($_) = @_;
2546         return m/^(?:$specre)$/o;
2547     };
2548
2549     my $fetch_iteration = 0;
2550     FETCH_ITERATION:
2551     for (;;) {
2552         printdebug "git_fetch_us iteration $fetch_iteration\n";
2553         if (++$fetch_iteration > 10) {
2554             fail "too many iterations trying to get sane fetch!";
2555         }
2556
2557         my @look = map { "refs/$_" } @specs;
2558         my @lcmd = (@git, qw(ls-remote -q --refs), access_giturl(), @look);
2559         debugcmd "|",@lcmd;
2560
2561         my %wantr;
2562         open GITLS, "-|", @lcmd or die $!;
2563         while (<GITLS>) {
2564             printdebug "=> ", $_;
2565             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2566             my ($objid,$rrefname) = ($1,$2);
2567             if (!$wanted_rref->($rrefname)) {
2568                 print STDERR <<END;
2569 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2570 END
2571                 next;
2572             }
2573             $wantr{$rrefname} = $objid;
2574         }
2575         $!=0; $?=0;
2576         close GITLS or failedcmd @lcmd;
2577
2578         # OK, now %want is exactly what we want for refs in @specs
2579         my @fspecs = map {
2580             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2581             "+refs/$_:".lrfetchrefs."/$_";
2582         } @specs;
2583
2584         printdebug "git_fetch_us fspecs @fspecs\n";
2585
2586         my @fcmd = (@git, qw(fetch -p -n -q), access_giturl(), @fspecs);
2587         runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(),
2588             @fspecs;
2589
2590         %lrfetchrefs_f = ();
2591         my %objgot;
2592
2593         git_for_each_ref(lrfetchrefs, sub {
2594             my ($objid,$objtype,$lrefname,$reftail) = @_;
2595             $lrfetchrefs_f{$lrefname} = $objid;
2596             $objgot{$objid} = 1;
2597         });
2598
2599         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2600             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2601             if (!exists $wantr{$rrefname}) {
2602                 if ($wanted_rref->($rrefname)) {
2603                     printdebug <<END;
2604 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2605 END
2606                 } else {
2607                     print STDERR <<END
2608 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2609 END
2610                 }
2611                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2612                 delete $lrfetchrefs_f{$lrefname};
2613                 next;
2614             }
2615         }
2616         foreach my $rrefname (sort keys %wantr) {
2617             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2618             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2619             my $want = $wantr{$rrefname};
2620             next if $got eq $want;
2621             if (!defined $objgot{$want}) {
2622                 print STDERR <<END;
2623 warning: git ls-remote suggests we want $lrefname
2624 warning:  and it should refer to $want
2625 warning:  but git fetch didn't fetch that object to any relevant ref.
2626 warning:  This may be due to a race with someone updating the server.
2627 warning:  Will try again...
2628 END
2629                 next FETCH_ITERATION;
2630             }
2631             printdebug <<END;
2632 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2633 END
2634             runcmd_ordryrun_local @git, qw(update-ref -m),
2635                 "dgit fetch git fetch fixup", $lrefname, $want;
2636             $lrfetchrefs_f{$lrefname} = $want;
2637         }
2638         last;
2639     }
2640     printdebug "git_fetch_us: git fetch --no-insane emulation complete\n",
2641         Dumper(\%lrfetchrefs_f);
2642 }
2643
2644 sub git_fetch_us () {
2645     # Want to fetch only what we are going to use, unless
2646     # deliberately-not-ff, in which case we must fetch everything.
2647
2648     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2649         map { "tags/$_" }
2650         (quiltmode_splitbrain
2651          ? (map { $_->('*',access_nomdistro) }
2652             \&debiantag_new, \&debiantag_maintview)
2653          : debiantags('*',access_nomdistro));
2654     push @specs, server_branch($csuite);
2655     push @specs, $rewritemap;
2656     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2657
2658     git_lrfetch_sane @specs;
2659
2660     my %here;
2661     my @tagpats = debiantags('*',access_nomdistro);
2662
2663     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2664         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2665         printdebug "currently $fullrefname=$objid\n";
2666         $here{$fullrefname} = $objid;
2667     });
2668     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2669         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2670         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2671         printdebug "offered $lref=$objid\n";
2672         if (!defined $here{$lref}) {
2673             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2674             runcmd_ordryrun_local @upd;
2675             lrfetchref_used $fullrefname;
2676         } elsif ($here{$lref} eq $objid) {
2677             lrfetchref_used $fullrefname;
2678         } else {
2679             print STDERR \
2680                 "Not updateting $lref from $here{$lref} to $objid.\n";
2681         }
2682     });
2683 }
2684
2685 sub mergeinfo_getclogp ($) {
2686     # Ensures thit $mi->{Clogp} exists and returns it
2687     my ($mi) = @_;
2688     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2689 }
2690
2691 sub mergeinfo_version ($) {
2692     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2693 }
2694
2695 sub fetch_from_archive_record_1 ($) {
2696     my ($hash) = @_;
2697     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2698             'DGIT_ARCHIVE', $hash;
2699     cmdoutput @git, qw(log -n2), $hash;
2700     # ... gives git a chance to complain if our commit is malformed
2701 }
2702
2703 sub fetch_from_archive_record_2 ($) {
2704     my ($hash) = @_;
2705     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2706     if (act_local()) {
2707         cmdoutput @upd_cmd;
2708     } else {
2709         dryrun_report @upd_cmd;
2710     }
2711 }
2712
2713 sub parse_dsc_field ($$) {
2714     my ($dsc, $what) = @_;
2715     my $f;
2716     foreach my $field (@ourdscfield) {
2717         $f = $dsc->{$field};
2718         last if defined $f;
2719     }
2720     if (!defined $f) {
2721         progress "$what: NO git hash";
2722     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2723              = $f =~ m/^(\w+) ($distro_re) ($versiontag_re) (\S+)(?:\s|$)/) {
2724         progress "$what: specified git info ($dsc_distro)";
2725         $dsc_hint_tag = [ $dsc_hint_tag ];
2726     } elsif ($f =~ m/^\w+\s*$/) {
2727         $dsc_hash = $&;
2728         $dsc_distro //= 'debian';
2729         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2730                           $dsc_distro ];
2731         progress "$what: specified git hash";
2732     } else {
2733         fail "$what: invalid Dgit info";
2734     }
2735 }
2736
2737 sub resolve_dsc_field_commit ($$) {
2738     my ($already_distro, $already_mapref) = @_;
2739
2740     return unless defined $dsc_hash;
2741
2742     my $rewritemapdata = git_cat_file $already_mapref.':map';
2743     if (defined $rewritemapdata
2744         && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2745         progress "server's git history rewrite map contains a relevant entry!";
2746
2747         $dsc_hash = $1;
2748         if (defined $dsc_hash) {
2749             progress "using rewritten git hash in place of .dsc value";
2750         } else {
2751             progress "server data says .dsc hash is to be disregarded";
2752         }
2753     }
2754 }
2755
2756 sub fetch_from_archive () {
2757     ensure_setup_existing_tree();
2758
2759     # Ensures that lrref() is what is actually in the archive, one way
2760     # or another, according to us - ie this client's
2761     # appropritaely-updated archive view.  Also returns the commit id.
2762     # If there is nothing in the archive, leaves lrref alone and
2763     # returns undef.  git_fetch_us must have already been called.
2764     get_archive_dsc();
2765
2766     if ($dsc) {
2767         parse_dsc_field($dsc, 'last upload to archive');
2768         resolve_dsc_field_commit access_basedistro,
2769             lrfetchrefs."/".$rewritemap
2770     } else {
2771         progress "no version available from the archive";
2772     }
2773
2774     # If the archive's .dsc has a Dgit field, there are three
2775     # relevant git commitids we need to choose between and/or merge
2776     # together:
2777     #   1. $dsc_hash: the Dgit field from the archive
2778     #   2. $lastpush_hash: the suite branch on the dgit git server
2779     #   3. $lastfetch_hash: our local tracking brach for the suite
2780     #
2781     # These may all be distinct and need not be in any fast forward
2782     # relationship:
2783     #
2784     # If the dsc was pushed to this suite, then the server suite
2785     # branch will have been updated; but it might have been pushed to
2786     # a different suite and copied by the archive.  Conversely a more
2787     # recent version may have been pushed with dgit but not appeared
2788     # in the archive (yet).
2789     #
2790     # $lastfetch_hash may be awkward because archive imports
2791     # (particularly, imports of Dgit-less .dscs) are performed only as
2792     # needed on individual clients, so different clients may perform a
2793     # different subset of them - and these imports are only made
2794     # public during push.  So $lastfetch_hash may represent a set of
2795     # imports different to a subsequent upload by a different dgit
2796     # client.
2797     #
2798     # Our approach is as follows:
2799     #
2800     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2801     # descendant of $dsc_hash, then it was pushed by a dgit user who
2802     # had based their work on $dsc_hash, so we should prefer it.
2803     # Otherwise, $dsc_hash was installed into this suite in the
2804     # archive other than by a dgit push, and (necessarily) after the
2805     # last dgit push into that suite (since a dgit push would have
2806     # been descended from the dgit server git branch); thus, in that
2807     # case, we prefer the archive's version (and produce a
2808     # pseudo-merge to overwrite the dgit server git branch).
2809     #
2810     # (If there is no Dgit field in the archive's .dsc then
2811     # generate_commit_from_dsc uses the version numbers to decide
2812     # whether the suite branch or the archive is newer.  If the suite
2813     # branch is newer it ignores the archive's .dsc; otherwise it
2814     # generates an import of the .dsc, and produces a pseudo-merge to
2815     # overwrite the suite branch with the archive contents.)
2816     #
2817     # The outcome of that part of the algorithm is the `public view',
2818     # and is same for all dgit clients: it does not depend on any
2819     # unpublished history in the local tracking branch.
2820     #
2821     # As between the public view and the local tracking branch: The
2822     # local tracking branch is only updated by dgit fetch, and
2823     # whenever dgit fetch runs it includes the public view in the
2824     # local tracking branch.  Therefore if the public view is not
2825     # descended from the local tracking branch, the local tracking
2826     # branch must contain history which was imported from the archive
2827     # but never pushed; and, its tip is now out of date.  So, we make
2828     # a pseudo-merge to overwrite the old imports and stitch the old
2829     # history in.
2830     #
2831     # Finally: we do not necessarily reify the public view (as
2832     # described above).  This is so that we do not end up stacking two
2833     # pseudo-merges.  So what we actually do is figure out the inputs
2834     # to any public view pseudo-merge and put them in @mergeinputs.
2835
2836     my @mergeinputs;
2837     # $mergeinputs[]{Commit}
2838     # $mergeinputs[]{Info}
2839     # $mergeinputs[0] is the one whose tree we use
2840     # @mergeinputs is in the order we use in the actual commit)
2841     #
2842     # Also:
2843     # $mergeinputs[]{Message} is a commit message to use
2844     # $mergeinputs[]{ReverseParents} if def specifies that parent
2845     #                                list should be in opposite order
2846     # Such an entry has no Commit or Info.  It applies only when found
2847     # in the last entry.  (This ugliness is to support making
2848     # identical imports to previous dgit versions.)
2849
2850     my $lastpush_hash = git_get_ref(lrfetchref());
2851     printdebug "previous reference hash=$lastpush_hash\n";
2852     $lastpush_mergeinput = $lastpush_hash && {
2853         Commit => $lastpush_hash,
2854         Info => "dgit suite branch on dgit git server",
2855     };
2856
2857     my $lastfetch_hash = git_get_ref(lrref());
2858     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
2859     my $lastfetch_mergeinput = $lastfetch_hash && {
2860         Commit => $lastfetch_hash,
2861         Info => "dgit client's archive history view",
2862     };
2863
2864     my $dsc_mergeinput = $dsc_hash && {
2865         Commit => $dsc_hash,
2866         Info => "Dgit field in .dsc from archive",
2867     };
2868
2869     my $cwd = getcwd();
2870     my $del_lrfetchrefs = sub {
2871         changedir $cwd;
2872         my $gur;
2873         printdebug "del_lrfetchrefs...\n";
2874         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
2875             my $objid = $lrfetchrefs_d{$fullrefname};
2876             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
2877             if (!$gur) {
2878                 $gur ||= new IO::Handle;
2879                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
2880             }
2881             printf $gur "delete %s %s\n", $fullrefname, $objid;
2882         }
2883         if ($gur) {
2884             close $gur or failedcmd "git update-ref delete lrfetchrefs";
2885         }
2886     };
2887
2888     if (defined $dsc_hash) {
2889         ensure_we_have_orig();
2890         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
2891             @mergeinputs = $dsc_mergeinput
2892         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
2893             print STDERR <<END or die $!;
2894
2895 Git commit in archive is behind the last version allegedly pushed/uploaded.
2896 Commit referred to by archive: $dsc_hash
2897 Last version pushed with dgit: $lastpush_hash
2898 $later_warning_msg
2899 END
2900             @mergeinputs = ($lastpush_mergeinput);
2901         } else {
2902             # Archive has .dsc which is not a descendant of the last dgit
2903             # push.  This can happen if the archive moves .dscs about.
2904             # Just follow its lead.
2905             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
2906                 progress "archive .dsc names newer git commit";
2907                 @mergeinputs = ($dsc_mergeinput);
2908             } else {
2909                 progress "archive .dsc names other git commit, fixing up";
2910                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
2911             }
2912         }
2913     } elsif ($dsc) {
2914         @mergeinputs = generate_commits_from_dsc();
2915         # We have just done an import.  Now, our import algorithm might
2916         # have been improved.  But even so we do not want to generate
2917         # a new different import of the same package.  So if the
2918         # version numbers are the same, just use our existing version.
2919         # If the version numbers are different, the archive has changed
2920         # (perhaps, rewound).
2921         if ($lastfetch_mergeinput &&
2922             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
2923                               (mergeinfo_version $mergeinputs[0]) )) {
2924             @mergeinputs = ($lastfetch_mergeinput);
2925         }
2926     } elsif ($lastpush_hash) {
2927         # only in git, not in the archive yet
2928         @mergeinputs = ($lastpush_mergeinput);
2929         print STDERR <<END or die $!;
2930
2931 Package not found in the archive, but has allegedly been pushed using dgit.
2932 $later_warning_msg
2933 END
2934     } else {
2935         printdebug "nothing found!\n";
2936         if (defined $skew_warning_vsn) {
2937             print STDERR <<END or die $!;
2938
2939 Warning: relevant archive skew detected.
2940 Archive allegedly contains $skew_warning_vsn
2941 But we were not able to obtain any version from the archive or git.
2942
2943 END
2944         }
2945         unshift @end, $del_lrfetchrefs;
2946         return undef;
2947     }
2948
2949     if ($lastfetch_hash &&
2950         !grep {
2951             my $h = $_->{Commit};
2952             $h and is_fast_fwd($lastfetch_hash, $h);
2953             # If true, one of the existing parents of this commit
2954             # is a descendant of the $lastfetch_hash, so we'll
2955             # be ff from that automatically.
2956         } @mergeinputs
2957         ) {
2958         # Otherwise:
2959         push @mergeinputs, $lastfetch_mergeinput;
2960     }
2961
2962     printdebug "fetch mergeinfos:\n";
2963     foreach my $mi (@mergeinputs) {
2964         if ($mi->{Info}) {
2965             printdebug " commit $mi->{Commit} $mi->{Info}\n";
2966         } else {
2967             printdebug sprintf " ReverseParents=%d Message=%s",
2968                 $mi->{ReverseParents}, $mi->{Message};
2969         }
2970     }
2971
2972     my $compat_info= pop @mergeinputs
2973         if $mergeinputs[$#mergeinputs]{Message};
2974
2975     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
2976
2977     my $hash;
2978     if (@mergeinputs > 1) {
2979         # here we go, then:
2980         my $tree_commit = $mergeinputs[0]{Commit};
2981
2982         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
2983         $tree =~ m/\n\n/;  $tree = $`;
2984         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
2985         $tree = $1;
2986
2987         # We use the changelog author of the package in question the
2988         # author of this pseudo-merge.  This is (roughly) correct if
2989         # this commit is simply representing aa non-dgit upload.
2990         # (Roughly because it does not record sponsorship - but we
2991         # don't have sponsorship info because that's in the .changes,
2992         # which isn't in the archivw.)
2993         #
2994         # But, it might be that we are representing archive history
2995         # updates (including in-archive copies).  These are not really
2996         # the responsibility of the person who created the .dsc, but
2997         # there is no-one whose name we should better use.  (The
2998         # author of the .dsc-named commit is clearly worse.)
2999
3000         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3001         my $author = clogp_authline $useclogp;
3002         my $cversion = getfield $useclogp, 'Version';
3003
3004         my $mcf = ".git/dgit/mergecommit";
3005         open MC, ">", $mcf or die "$mcf $!";
3006         print MC <<END or die $!;
3007 tree $tree
3008 END
3009
3010         my @parents = grep { $_->{Commit} } @mergeinputs;
3011         @parents = reverse @parents if $compat_info->{ReverseParents};
3012         print MC <<END or die $! foreach @parents;
3013 parent $_->{Commit}
3014 END
3015
3016         print MC <<END or die $!;
3017 author $author
3018 committer $author
3019
3020 END
3021
3022         if (defined $compat_info->{Message}) {
3023             print MC $compat_info->{Message} or die $!;
3024         } else {
3025             print MC <<END or die $!;
3026 Record $package ($cversion) in archive suite $csuite
3027
3028 Record that
3029 END
3030             my $message_add_info = sub {
3031                 my ($mi) = (@_);
3032                 my $mversion = mergeinfo_version $mi;
3033                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3034                     or die $!;
3035             };
3036
3037             $message_add_info->($mergeinputs[0]);
3038             print MC <<END or die $!;
3039 should be treated as descended from
3040 END
3041             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3042         }
3043
3044         close MC or die $!;
3045         $hash = make_commit $mcf;
3046     } else {
3047         $hash = $mergeinputs[0]{Commit};
3048     }
3049     printdebug "fetch hash=$hash\n";
3050
3051     my $chkff = sub {
3052         my ($lasth, $what) = @_;
3053         return unless $lasth;
3054         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3055     };
3056
3057     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3058         if $lastpush_hash;
3059     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3060
3061     fetch_from_archive_record_1($hash);
3062
3063     if (defined $skew_warning_vsn) {
3064         mkpath '.git/dgit';
3065         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3066         my $gotclogp = commit_getclogp($hash);
3067         my $got_vsn = getfield $gotclogp, 'Version';
3068         printdebug "SKEW CHECK GOT $got_vsn\n";
3069         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3070             print STDERR <<END or die $!;
3071
3072 Warning: archive skew detected.  Using the available version:
3073 Archive allegedly contains    $skew_warning_vsn
3074 We were able to obtain only   $got_vsn
3075
3076 END
3077         }
3078     }
3079
3080     if ($lastfetch_hash ne $hash) {
3081         fetch_from_archive_record_2($hash);
3082     }
3083
3084     lrfetchref_used lrfetchref();
3085
3086     unshift @end, $del_lrfetchrefs;
3087     return $hash;
3088 }
3089
3090 sub set_local_git_config ($$) {
3091     my ($k, $v) = @_;
3092     runcmd @git, qw(config), $k, $v;
3093 }
3094
3095 sub setup_mergechangelogs (;$) {
3096     my ($always) = @_;
3097     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3098
3099     my $driver = 'dpkg-mergechangelogs';
3100     my $cb = "merge.$driver";
3101     my $attrs = '.git/info/attributes';
3102     ensuredir '.git/info';
3103
3104     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3105     if (!open ATTRS, "<", $attrs) {
3106         $!==ENOENT or die "$attrs: $!";
3107     } else {
3108         while (<ATTRS>) {
3109             chomp;
3110             next if m{^debian/changelog\s};
3111             print NATTRS $_, "\n" or die $!;
3112         }
3113         ATTRS->error and die $!;
3114         close ATTRS;
3115     }
3116     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3117     close NATTRS;
3118
3119     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3120     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3121
3122     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3123 }
3124
3125 sub setup_useremail (;$) {
3126     my ($always) = @_;
3127     return unless $always || access_cfg_bool(1, 'setup-useremail');
3128
3129     my $setup = sub {
3130         my ($k, $envvar) = @_;
3131         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3132         return unless defined $v;
3133         set_local_git_config "user.$k", $v;
3134     };
3135
3136     $setup->('email', 'DEBEMAIL');
3137     $setup->('name', 'DEBFULLNAME');
3138 }
3139
3140 sub ensure_setup_existing_tree () {
3141     my $k = "remote.$remotename.skipdefaultupdate";
3142     my $c = git_get_config $k;
3143     return if defined $c;
3144     set_local_git_config $k, 'true';
3145 }
3146
3147 sub setup_new_tree () {
3148     setup_mergechangelogs();
3149     setup_useremail();
3150 }
3151
3152 sub multisuite_suite_child ($$$) {
3153     my ($tsuite, $merginputs, $fn) = @_;
3154     # in child, sets things up, calls $fn->(), and returns undef
3155     # in parent, returns canonical suite name for $tsuite
3156     my $canonsuitefh = IO::File::new_tmpfile;
3157     my $pid = fork // die $!;
3158     if (!$pid) {
3159         $isuite = $tsuite;
3160         $us .= " [$isuite]";
3161         $debugprefix .= " ";
3162         progress "fetching $tsuite...";
3163         canonicalise_suite();
3164         print $canonsuitefh $csuite, "\n" or die $!;
3165         close $canonsuitefh or die $!;
3166         $fn->();
3167         return undef;
3168     }
3169     waitpid $pid,0 == $pid or die $!;
3170     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3171     seek $canonsuitefh,0,0 or die $!;
3172     local $csuite = <$canonsuitefh>;
3173     die $! unless defined $csuite && chomp $csuite;
3174     if ($? == 256*4) {
3175         printdebug "multisuite $tsuite missing\n";
3176         return $csuite;
3177     }
3178     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3179     push @$merginputs, {
3180         Ref => lrref,
3181         Info => $csuite,
3182     };
3183     return $csuite;
3184 }
3185
3186 sub fork_for_multisuite ($) {
3187     my ($before_fetch_merge) = @_;
3188     # if nothing unusual, just returns ''
3189     #
3190     # if multisuite:
3191     # returns 0 to caller in child, to do first of the specified suites
3192     # in child, $csuite is not yet set
3193     #
3194     # returns 1 to caller in parent, to finish up anything needed after
3195     # in parent, $csuite is set to canonicalised portmanteau
3196
3197     my $org_isuite = $isuite;
3198     my @suites = split /\,/, $isuite;
3199     return '' unless @suites > 1;
3200     printdebug "fork_for_multisuite: @suites\n";
3201
3202     my @mergeinputs;
3203
3204     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3205                                             sub { });
3206     return 0 unless defined $cbasesuite;
3207
3208     fail "package $package missing in (base suite) $cbasesuite"
3209         unless @mergeinputs;
3210
3211     my @csuites = ($cbasesuite);
3212
3213     $before_fetch_merge->();
3214
3215     foreach my $tsuite (@suites[1..$#suites]) {
3216         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3217                                                sub {
3218             @end = ();
3219             fetch();
3220             exit 0;
3221         });
3222         # xxx collecte the ref here
3223
3224         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3225         push @csuites, $csubsuite;
3226     }
3227
3228     foreach my $mi (@mergeinputs) {
3229         my $ref = git_get_ref $mi->{Ref};
3230         die "$mi->{Ref} ?" unless length $ref;
3231         $mi->{Commit} = $ref;
3232     }
3233
3234     $csuite = join ",", @csuites;
3235
3236     my $previous = git_get_ref lrref;
3237     if ($previous) {
3238         unshift @mergeinputs, {
3239             Commit => $previous,
3240             Info => "local combined tracking branch",
3241             Warning =>
3242  "archive seems to have rewound: local tracking branch is ahead!",
3243         };
3244     }
3245
3246     foreach my $ix (0..$#mergeinputs) {
3247         $mergeinputs[$ix]{Index} = $ix;
3248     }
3249
3250     @mergeinputs = sort {
3251         -version_compare(mergeinfo_version $a,
3252                          mergeinfo_version $b) # highest version first
3253             or
3254         $a->{Index} <=> $b->{Index}; # earliest in spec first
3255     } @mergeinputs;
3256
3257     my @needed;
3258
3259   NEEDED:
3260     foreach my $mi (@mergeinputs) {
3261         printdebug "multisuite merge check $mi->{Info}\n";
3262         foreach my $previous (@needed) {
3263             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3264             printdebug "multisuite merge un-needed $previous->{Info}\n";
3265             next NEEDED;
3266         }
3267         push @needed, $mi;
3268         printdebug "multisuite merge this-needed\n";
3269         $mi->{Character} = '+';
3270     }
3271
3272     $needed[0]{Character} = '*';
3273
3274     my $output = $needed[0]{Commit};
3275
3276     if (@needed > 1) {
3277         printdebug "multisuite merge nontrivial\n";
3278         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3279
3280         my $commit = "tree $tree\n";
3281         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3282             "Input branches:\n";
3283
3284         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3285             printdebug "multisuite merge include $mi->{Info}\n";
3286             $mi->{Character} //= ' ';
3287             $commit .= "parent $mi->{Commit}\n";
3288             $msg .= sprintf " %s  %-25s %s\n",
3289                 $mi->{Character},
3290                 (mergeinfo_version $mi),
3291                 $mi->{Info};
3292         }
3293         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3294         $msg .= "\nKey\n".
3295             " * marks the highest version branch, which choose to use\n".
3296             " + marks each branch which was not already an ancestor\n\n".
3297             "[dgit multi-suite $csuite]\n";
3298         $commit .=
3299             "author $authline\n".
3300             "committer $authline\n\n";
3301         $output = make_commit_text $commit.$msg;
3302         printdebug "multisuite merge generated $output\n";
3303     }
3304
3305     fetch_from_archive_record_1($output);
3306     fetch_from_archive_record_2($output);
3307
3308     progress "calculated combined tracking suite $csuite";
3309
3310     return 1;
3311 }
3312
3313 sub clone_set_head () {
3314     open H, "> .git/HEAD" or die $!;
3315     print H "ref: ".lref()."\n" or die $!;
3316     close H or die $!;
3317 }
3318 sub clone_finish ($) {
3319     my ($dstdir) = @_;
3320     runcmd @git, qw(reset --hard), lrref();
3321     runcmd qw(bash -ec), <<'END';
3322         set -o pipefail
3323         git ls-tree -r --name-only -z HEAD | \
3324         xargs -0r touch -h -r . --
3325 END
3326     printdone "ready for work in $dstdir";
3327 }
3328
3329 sub clone ($) {
3330     my ($dstdir) = @_;
3331     badusage "dry run makes no sense with clone" unless act_local();
3332
3333     my $multi_fetched = fork_for_multisuite(sub {
3334         printdebug "multi clone before fetch merge\n";
3335         changedir $dstdir;
3336     });
3337     if ($multi_fetched) {
3338         printdebug "multi clone after fetch merge\n";
3339         clone_set_head();
3340         clone_finish($dstdir);
3341         exit 0;
3342     }
3343     printdebug "clone main body\n";
3344
3345     canonicalise_suite();
3346     my $hasgit = check_for_git();
3347     mkdir $dstdir or fail "create \`$dstdir': $!";
3348     changedir $dstdir;
3349     runcmd @git, qw(init -q);
3350     clone_set_head();
3351     my $giturl = access_giturl(1);
3352     if (defined $giturl) {
3353         runcmd @git, qw(remote add), 'origin', $giturl;
3354     }
3355     if ($hasgit) {
3356         progress "fetching existing git history";
3357         git_fetch_us();
3358         runcmd_ordryrun_local @git, qw(fetch origin);
3359     } else {
3360         progress "starting new git history";
3361     }
3362     fetch_from_archive() or no_such_package;
3363     my $vcsgiturl = $dsc->{'Vcs-Git'};
3364     if (length $vcsgiturl) {
3365         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3366         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3367     }
3368     setup_new_tree();
3369     clone_finish($dstdir);
3370 }
3371
3372 sub fetch () {
3373     canonicalise_suite();
3374     if (check_for_git()) {
3375         git_fetch_us();
3376     }
3377     fetch_from_archive() or no_such_package();
3378     printdone "fetched into ".lrref();
3379 }
3380
3381 sub pull () {
3382     my $multi_fetched = fork_for_multisuite(sub { });
3383     fetch() unless $multi_fetched; # parent
3384     return if $multi_fetched eq '0'; # child
3385     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3386         lrref();
3387     printdone "fetched to ".lrref()." and merged into HEAD";
3388 }
3389
3390 sub check_not_dirty () {
3391     foreach my $f (qw(local-options local-patch-header)) {
3392         if (stat_exists "debian/source/$f") {
3393             fail "git tree contains debian/source/$f";
3394         }
3395     }
3396
3397     return if $ignoredirty;
3398
3399     my @cmd = (@git, qw(diff --quiet HEAD));
3400     debugcmd "+",@cmd;
3401     $!=0; $?=-1; system @cmd;
3402     return if !$?;
3403     if ($?==256) {
3404         fail "working tree is dirty (does not match HEAD)";
3405     } else {
3406         failedcmd @cmd;
3407     }
3408 }
3409
3410 sub commit_admin ($) {
3411     my ($m) = @_;
3412     progress "$m";
3413     runcmd_ordryrun_local @git, qw(commit -m), $m;
3414 }
3415
3416 sub commit_quilty_patch () {
3417     my $output = cmdoutput @git, qw(status --porcelain);
3418     my %adds;
3419     foreach my $l (split /\n/, $output) {
3420         next unless $l =~ m/\S/;
3421         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3422             $adds{$1}++;
3423         }
3424     }
3425     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3426     if (!%adds) {
3427         progress "nothing quilty to commit, ok.";
3428         return;
3429     }
3430     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3431     runcmd_ordryrun_local @git, qw(add -f), @adds;
3432     commit_admin <<END
3433 Commit Debian 3.0 (quilt) metadata
3434
3435 [dgit ($our_version) quilt-fixup]
3436 END
3437 }
3438
3439 sub get_source_format () {
3440     my %options;
3441     if (open F, "debian/source/options") {
3442         while (<F>) {
3443             next if m/^\s*\#/;
3444             next unless m/\S/;
3445             s/\s+$//; # ignore missing final newline
3446             if (m/\s*\#\s*/) {
3447                 my ($k, $v) = ($`, $'); #');
3448                 $v =~ s/^"(.*)"$/$1/;
3449                 $options{$k} = $v;
3450             } else {
3451                 $options{$_} = 1;
3452             }
3453         }
3454         F->error and die $!;
3455         close F;
3456     } else {
3457         die $! unless $!==&ENOENT;
3458     }
3459
3460     if (!open F, "debian/source/format") {
3461         die $! unless $!==&ENOENT;
3462         return '';
3463     }
3464     $_ = <F>;
3465     F->error and die $!;
3466     chomp;
3467     return ($_, \%options);
3468 }
3469
3470 sub madformat_wantfixup ($) {
3471     my ($format) = @_;
3472     return 0 unless $format eq '3.0 (quilt)';
3473     our $quilt_mode_warned;
3474     if ($quilt_mode eq 'nocheck') {
3475         progress "Not doing any fixup of \`$format' due to".
3476             " ----no-quilt-fixup or --quilt=nocheck"
3477             unless $quilt_mode_warned++;
3478         return 0;
3479     }
3480     progress "Format \`$format', need to check/update patch stack"
3481         unless $quilt_mode_warned++;
3482     return 1;
3483 }
3484
3485 sub maybe_split_brain_save ($$$) {
3486     my ($headref, $dgitview, $msg) = @_;
3487     # => message fragment "$saved" describing disposition of $dgitview
3488     return "commit id $dgitview" unless defined $split_brain_save;
3489     my @cmd = (shell_cmd "cd ../../../..",
3490                @git, qw(update-ref -m),
3491                "dgit --dgit-view-save $msg HEAD=$headref",
3492                $split_brain_save, $dgitview);
3493     runcmd @cmd;
3494     return "and left in $split_brain_save";
3495 }
3496
3497 # An "infopair" is a tuple [ $thing, $what ]
3498 # (often $thing is a commit hash; $what is a description)
3499
3500 sub infopair_cond_equal ($$) {
3501     my ($x,$y) = @_;
3502     $x->[0] eq $y->[0] or fail <<END;
3503 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3504 END
3505 };
3506
3507 sub infopair_lrf_tag_lookup ($$) {
3508     my ($tagnames, $what) = @_;
3509     # $tagname may be an array ref
3510     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3511     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3512     foreach my $tagname (@tagnames) {
3513         my $lrefname = lrfetchrefs."/tags/$tagname";
3514         my $tagobj = $lrfetchrefs_f{$lrefname};
3515         next unless defined $tagobj;
3516         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3517         return [ git_rev_parse($tagobj), $what ];
3518     }
3519     fail @tagnames==1 ? <<END : <<END;
3520 Wanted tag $what (@tagnames) on dgit server, but not found
3521 END
3522 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3523 END
3524 }
3525
3526 sub infopair_cond_ff ($$) {
3527     my ($anc,$desc) = @_;
3528     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3529 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3530 END
3531 };
3532
3533 sub pseudomerge_version_check ($$) {
3534     my ($clogp, $archive_hash) = @_;
3535
3536     my $arch_clogp = commit_getclogp $archive_hash;
3537     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3538                      'version currently in archive' ];
3539     if (defined $overwrite_version) {
3540         if (length $overwrite_version) {
3541             infopair_cond_equal([ $overwrite_version,
3542                                   '--overwrite= version' ],
3543                                 $i_arch_v);
3544         } else {
3545             my $v = $i_arch_v->[0];
3546             progress "Checking package changelog for archive version $v ...";
3547             eval {
3548                 my @xa = ("-f$v", "-t$v");
3549                 my $vclogp = parsechangelog @xa;
3550                 my $cv = [ (getfield $vclogp, 'Version'),
3551                            "Version field from dpkg-parsechangelog @xa" ];
3552                 infopair_cond_equal($i_arch_v, $cv);
3553             };
3554             if ($@) {
3555                 $@ =~ s/^dgit: //gm;
3556                 fail "$@".
3557                     "Perhaps debian/changelog does not mention $v ?";
3558             }
3559         }
3560     }
3561
3562     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3563     return $i_arch_v;
3564 }
3565
3566 sub pseudomerge_make_commit ($$$$ $$) {
3567     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3568         $msg_cmd, $msg_msg) = @_;
3569     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3570
3571     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3572     my $authline = clogp_authline $clogp;
3573
3574     chomp $msg_msg;
3575     $msg_cmd .=
3576         !defined $overwrite_version ? ""
3577         : !length  $overwrite_version ? " --overwrite"
3578         : " --overwrite=".$overwrite_version;
3579
3580     mkpath '.git/dgit';
3581     my $pmf = ".git/dgit/pseudomerge";
3582     open MC, ">", $pmf or die "$pmf $!";
3583     print MC <<END or die $!;
3584 tree $tree
3585 parent $dgitview
3586 parent $archive_hash
3587 author $authline
3588 committer $authline
3589
3590 $msg_msg
3591
3592 [$msg_cmd]
3593 END
3594     close MC or die $!;
3595
3596     return make_commit($pmf);
3597 }
3598
3599 sub splitbrain_pseudomerge ($$$$) {
3600     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3601     # => $merged_dgitview
3602     printdebug "splitbrain_pseudomerge...\n";
3603     #
3604     #     We:      debian/PREVIOUS    HEAD($maintview)
3605     # expect:          o ----------------- o
3606     #                    \                   \
3607     #                     o                   o
3608     #                 a/d/PREVIOUS        $dgitview
3609     #                $archive_hash              \
3610     #  If so,                \                   \
3611     #  we do:                 `------------------ o
3612     #   this:                                   $dgitview'
3613     #
3614
3615     return $dgitview unless defined $archive_hash;
3616
3617     printdebug "splitbrain_pseudomerge...\n";
3618
3619     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3620
3621     if (!defined $overwrite_version) {
3622         progress "Checking that HEAD inciudes all changes in archive...";
3623     }
3624
3625     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3626
3627     if (defined $overwrite_version) {
3628     } elsif (!eval {
3629         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3630         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3631         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3632         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3633         my $i_archive = [ $archive_hash, "current archive contents" ];
3634
3635         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3636
3637         infopair_cond_equal($i_dgit, $i_archive);
3638         infopair_cond_ff($i_dep14, $i_dgit);
3639         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3640         1;
3641     }) {
3642         print STDERR <<END;
3643 $us: check failed (maybe --overwrite is needed, consult documentation)
3644 END
3645         die "$@";
3646     }
3647
3648     my $r = pseudomerge_make_commit
3649         $clogp, $dgitview, $archive_hash, $i_arch_v,
3650         "dgit --quilt=$quilt_mode",
3651         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3652 Declare fast forward from $i_arch_v->[0]
3653 END_OVERWR
3654 Make fast forward from $i_arch_v->[0]
3655 END_MAKEFF
3656
3657     maybe_split_brain_save $maintview, $r, "pseudomerge";
3658
3659     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3660     return $r;
3661 }
3662
3663 sub plain_overwrite_pseudomerge ($$$) {
3664     my ($clogp, $head, $archive_hash) = @_;
3665
3666     printdebug "plain_overwrite_pseudomerge...";
3667
3668     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3669
3670     return $head if is_fast_fwd $archive_hash, $head;
3671
3672     my $m = "Declare fast forward from $i_arch_v->[0]";
3673
3674     my $r = pseudomerge_make_commit
3675         $clogp, $head, $archive_hash, $i_arch_v,
3676         "dgit", $m;
3677
3678     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3679
3680     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3681     return $r;
3682 }
3683
3684 sub push_parse_changelog ($) {
3685     my ($clogpfn) = @_;
3686
3687     my $clogp = Dpkg::Control::Hash->new();
3688     $clogp->load($clogpfn) or die;
3689
3690     my $clogpackage = getfield $clogp, 'Source';
3691     $package //= $clogpackage;
3692     fail "-p specified $package but changelog specified $clogpackage"
3693         unless $package eq $clogpackage;
3694     my $cversion = getfield $clogp, 'Version';
3695     my $tag = debiantag($cversion, access_nomdistro);
3696     runcmd @git, qw(check-ref-format), $tag;
3697
3698     my $dscfn = dscfn($cversion);
3699
3700     return ($clogp, $cversion, $dscfn);
3701 }
3702
3703 sub push_parse_dsc ($$$) {
3704     my ($dscfn,$dscfnwhat, $cversion) = @_;
3705     $dsc = parsecontrol($dscfn,$dscfnwhat);
3706     my $dversion = getfield $dsc, 'Version';
3707     my $dscpackage = getfield $dsc, 'Source';
3708     ($dscpackage eq $package && $dversion eq $cversion) or
3709         fail "$dscfn is for $dscpackage $dversion".
3710             " but debian/changelog is for $package $cversion";
3711 }
3712
3713 sub push_tagwants ($$$$) {
3714     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3715     my @tagwants;
3716     push @tagwants, {
3717         TagFn => \&debiantag,
3718         Objid => $dgithead,
3719         TfSuffix => '',
3720         View => 'dgit',
3721     };
3722     if (defined $maintviewhead) {
3723         push @tagwants, {
3724             TagFn => \&debiantag_maintview,
3725             Objid => $maintviewhead,
3726             TfSuffix => '-maintview',
3727             View => 'maint',
3728         };
3729     } elsif ($dodep14tag eq 'no' ? 0
3730              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3731              : $dodep14tag eq 'always'
3732              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3733 --dep14tag-always (or equivalent in config) means server must support
3734  both "new" and "maint" tag formats, but config says it doesn't.
3735 END
3736             : die "$dodep14tag ?") {
3737         push @tagwants, {
3738             TagFn => \&debiantag_maintview,
3739             Objid => $dgithead,
3740             TfSuffix => '-dgit',
3741             View => 'dgit',
3742         };
3743     };
3744     foreach my $tw (@tagwants) {
3745         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3746         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3747     }
3748     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3749     return @tagwants;
3750 }
3751
3752 sub push_mktags ($$ $$ $) {
3753     my ($clogp,$dscfn,
3754         $changesfile,$changesfilewhat,
3755         $tagwants) = @_;
3756
3757     die unless $tagwants->[0]{View} eq 'dgit';
3758
3759     my $declaredistro = access_nomdistro();
3760     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3761     $dsc->{$ourdscfield[0]} = join " ",
3762         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3763         $reader_giturl;
3764     $dsc->save("$dscfn.tmp") or die $!;
3765
3766     my $changes = parsecontrol($changesfile,$changesfilewhat);
3767     foreach my $field (qw(Source Distribution Version)) {
3768         $changes->{$field} eq $clogp->{$field} or
3769             fail "changes field $field \`$changes->{$field}'".
3770                 " does not match changelog \`$clogp->{$field}'";
3771     }
3772
3773     my $cversion = getfield $clogp, 'Version';
3774     my $clogsuite = getfield $clogp, 'Distribution';
3775
3776     # We make the git tag by hand because (a) that makes it easier
3777     # to control the "tagger" (b) we can do remote signing
3778     my $authline = clogp_authline $clogp;
3779     my $delibs = join(" ", "",@deliberatelies);
3780
3781     my $mktag = sub {
3782         my ($tw) = @_;
3783         my $tfn = $tw->{Tfn};
3784         my $head = $tw->{Objid};
3785         my $tag = $tw->{Tag};
3786
3787         open TO, '>', $tfn->('.tmp') or die $!;
3788         print TO <<END or die $!;
3789 object $head
3790 type commit
3791 tag $tag
3792 tagger $authline
3793
3794 END
3795         if ($tw->{View} eq 'dgit') {
3796             print TO <<END or die $!;
3797 $package release $cversion for $clogsuite ($csuite) [dgit]
3798 [dgit distro=$declaredistro$delibs]
3799 END
3800             foreach my $ref (sort keys %previously) {
3801                 print TO <<END or die $!;
3802 [dgit previously:$ref=$previously{$ref}]
3803 END
3804             }
3805         } elsif ($tw->{View} eq 'maint') {
3806             print TO <<END or die $!;
3807 $package release $cversion for $clogsuite ($csuite)
3808 (maintainer view tag generated by dgit --quilt=$quilt_mode)
3809 END
3810         } else {
3811             die Dumper($tw)."?";
3812         }
3813
3814         close TO or die $!;
3815
3816         my $tagobjfn = $tfn->('.tmp');
3817         if ($sign) {
3818             if (!defined $keyid) {
3819                 $keyid = access_cfg('keyid','RETURN-UNDEF');
3820             }
3821             if (!defined $keyid) {
3822                 $keyid = getfield $clogp, 'Maintainer';
3823             }
3824             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
3825             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
3826             push @sign_cmd, qw(-u),$keyid if defined $keyid;
3827             push @sign_cmd, $tfn->('.tmp');
3828             runcmd_ordryrun @sign_cmd;
3829             if (act_scary()) {
3830                 $tagobjfn = $tfn->('.signed.tmp');
3831                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
3832                     $tfn->('.tmp'), $tfn->('.tmp.asc');
3833             }
3834         }
3835         return $tagobjfn;
3836     };
3837
3838     my @r = map { $mktag->($_); } @$tagwants;
3839     return @r;
3840 }
3841
3842 sub sign_changes ($) {
3843     my ($changesfile) = @_;
3844     if ($sign) {
3845         my @debsign_cmd = @debsign;
3846         push @debsign_cmd, "-k$keyid" if defined $keyid;
3847         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
3848         push @debsign_cmd, $changesfile;
3849         runcmd_ordryrun @debsign_cmd;
3850     }
3851 }
3852
3853 sub dopush () {
3854     printdebug "actually entering push\n";
3855
3856     supplementary_message(<<'END');
3857 Push failed, while checking state of the archive.
3858 You can retry the push, after fixing the problem, if you like.
3859 END
3860     if (check_for_git()) {
3861         git_fetch_us();
3862     }
3863     my $archive_hash = fetch_from_archive();
3864     if (!$archive_hash) {
3865         $new_package or
3866             fail "package appears to be new in this suite;".
3867                 " if this is intentional, use --new";
3868     }
3869
3870     supplementary_message(<<'END');
3871 Push failed, while preparing your push.
3872 You can retry the push, after fixing the problem, if you like.
3873 END
3874
3875     need_tagformat 'new', "quilt mode $quilt_mode"
3876         if quiltmode_splitbrain;
3877
3878     prep_ud();
3879
3880     access_giturl(); # check that success is vaguely likely
3881     select_tagformat();
3882
3883     my $clogpfn = ".git/dgit/changelog.822.tmp";
3884     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
3885
3886     responder_send_file('parsed-changelog', $clogpfn);
3887
3888     my ($clogp, $cversion, $dscfn) =
3889         push_parse_changelog("$clogpfn");
3890
3891     my $dscpath = "$buildproductsdir/$dscfn";
3892     stat_exists $dscpath or
3893         fail "looked for .dsc $dscpath, but $!;".
3894             " maybe you forgot to build";
3895
3896     responder_send_file('dsc', $dscpath);
3897
3898     push_parse_dsc($dscpath, $dscfn, $cversion);
3899
3900     my $format = getfield $dsc, 'Format';
3901     printdebug "format $format\n";
3902
3903     my $actualhead = git_rev_parse('HEAD');
3904     my $dgithead = $actualhead;
3905     my $maintviewhead = undef;
3906
3907     my $upstreamversion = upstreamversion $clogp->{Version};
3908
3909     if (madformat_wantfixup($format)) {
3910         # user might have not used dgit build, so maybe do this now:
3911         if (quiltmode_splitbrain()) {
3912             changedir $ud;
3913             quilt_make_fake_dsc($upstreamversion);
3914             my $cachekey;
3915             ($dgithead, $cachekey) =
3916                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
3917             $dgithead or fail
3918  "--quilt=$quilt_mode but no cached dgit view:
3919  perhaps tree changed since dgit build[-source] ?";
3920             $split_brain = 1;
3921             $dgithead = splitbrain_pseudomerge($clogp,
3922                                                $actualhead, $dgithead,
3923                                                $archive_hash);
3924             $maintviewhead = $actualhead;
3925             changedir '../../../..';
3926             prep_ud(); # so _only_subdir() works, below
3927         } else {
3928             commit_quilty_patch();
3929         }
3930     }
3931
3932     if (defined $overwrite_version && !defined $maintviewhead) {
3933         $dgithead = plain_overwrite_pseudomerge($clogp,
3934                                                 $dgithead,
3935                                                 $archive_hash);
3936     }
3937
3938     check_not_dirty();
3939
3940     my $forceflag = '';
3941     if ($archive_hash) {
3942         if (is_fast_fwd($archive_hash, $dgithead)) {
3943             # ok
3944         } elsif (deliberately_not_fast_forward) {
3945             $forceflag = '+';
3946         } else {
3947             fail "dgit push: HEAD is not a descendant".
3948                 " of the archive's version.\n".
3949                 "To overwrite the archive's contents,".
3950                 " pass --overwrite[=VERSION].\n".
3951                 "To rewind history, if permitted by the archive,".
3952                 " use --deliberately-not-fast-forward.";
3953         }
3954     }
3955
3956     changedir $ud;
3957     progress "checking that $dscfn corresponds to HEAD";
3958     runcmd qw(dpkg-source -x --),
3959         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
3960     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
3961     check_for_vendor_patches() if madformat($dsc->{format});
3962     changedir '../../../..';
3963     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
3964     debugcmd "+",@diffcmd;
3965     $!=0; $?=-1;
3966     my $r = system @diffcmd;
3967     if ($r) {
3968         if ($r==256) {
3969             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
3970             fail <<END
3971 HEAD specifies a different tree to $dscfn:
3972 $diffs
3973 Perhaps you forgot to build.  Or perhaps there is a problem with your
3974  source tree (see dgit(7) for some hints).  To see a full diff, run
3975    git diff $tree HEAD
3976 END
3977         } else {
3978             failedcmd @diffcmd;
3979         }
3980     }
3981     if (!$changesfile) {
3982         my $pat = changespat $cversion;
3983         my @cs = glob "$buildproductsdir/$pat";
3984         fail "failed to find unique changes file".
3985             " (looked for $pat in $buildproductsdir);".
3986             " perhaps you need to use dgit -C"
3987             unless @cs==1;
3988         ($changesfile) = @cs;
3989     } else {
3990         $changesfile = "$buildproductsdir/$changesfile";
3991     }
3992
3993     # Check that changes and .dsc agree enough
3994     $changesfile =~ m{[^/]*$};
3995     my $changes = parsecontrol($changesfile,$&);
3996     files_compare_inputs($dsc, $changes)
3997         unless forceing [qw(dsc-changes-mismatch)];
3998
3999     # Perhaps adjust .dsc to contain right set of origs
4000     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4001                                   $changesfile)
4002         unless forceing [qw(changes-origs-exactly)];
4003
4004     # Checks complete, we're going to try and go ahead:
4005
4006     responder_send_file('changes',$changesfile);
4007     responder_send_command("param head $dgithead");
4008     responder_send_command("param csuite $csuite");
4009     responder_send_command("param tagformat $tagformat");
4010     if (defined $maintviewhead) {
4011         die unless ($protovsn//4) >= 4;
4012         responder_send_command("param maint-view $maintviewhead");
4013     }
4014
4015     if (deliberately_not_fast_forward) {
4016         git_for_each_ref(lrfetchrefs, sub {
4017             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4018             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4019             responder_send_command("previously $rrefname=$objid");
4020             $previously{$rrefname} = $objid;
4021         });
4022     }
4023
4024     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4025                                  ".git/dgit/tag");
4026     my @tagobjfns;
4027
4028     supplementary_message(<<'END');
4029 Push failed, while signing the tag.
4030 You can retry the push, after fixing the problem, if you like.
4031 END
4032     # If we manage to sign but fail to record it anywhere, it's fine.
4033     if ($we_are_responder) {
4034         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4035         responder_receive_files('signed-tag', @tagobjfns);
4036     } else {
4037         @tagobjfns = push_mktags($clogp,$dscpath,
4038                               $changesfile,$changesfile,
4039                               \@tagwants);
4040     }
4041     supplementary_message(<<'END');
4042 Push failed, *after* signing the tag.
4043 If you want to try again, you should use a new version number.
4044 END
4045
4046     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4047
4048     foreach my $tw (@tagwants) {
4049         my $tag = $tw->{Tag};
4050         my $tagobjfn = $tw->{TagObjFn};
4051         my $tag_obj_hash =
4052             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4053         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4054         runcmd_ordryrun_local
4055             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4056     }
4057
4058     supplementary_message(<<'END');
4059 Push failed, while updating the remote git repository - see messages above.
4060 If you want to try again, you should use a new version number.
4061 END
4062     if (!check_for_git()) {
4063         create_remote_git_repo();
4064     }
4065
4066     my @pushrefs = $forceflag.$dgithead.":".rrref();
4067     foreach my $tw (@tagwants) {
4068         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4069     }
4070
4071     runcmd_ordryrun @git,
4072         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4073     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4074
4075     supplementary_message(<<'END');
4076 Push failed, while obtaining signatures on the .changes and .dsc.
4077 If it was just that the signature failed, you may try again by using
4078 debsign by hand to sign the changes
4079    $changesfile
4080 and then dput to complete the upload.
4081 If you need to change the package, you must use a new version number.
4082 END
4083     if ($we_are_responder) {
4084         my $dryrunsuffix = act_local() ? "" : ".tmp";
4085         responder_receive_files('signed-dsc-changes',
4086                                 "$dscpath$dryrunsuffix",
4087                                 "$changesfile$dryrunsuffix");
4088     } else {
4089         if (act_local()) {
4090             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4091         } else {
4092             progress "[new .dsc left in $dscpath.tmp]";
4093         }
4094         sign_changes $changesfile;
4095     }
4096
4097     supplementary_message(<<END);
4098 Push failed, while uploading package(s) to the archive server.
4099 You can retry the upload of exactly these same files with dput of:
4100   $changesfile
4101 If that .changes file is broken, you will need to use a new version
4102 number for your next attempt at the upload.
4103 END
4104     my $host = access_cfg('upload-host','RETURN-UNDEF');
4105     my @hostarg = defined($host) ? ($host,) : ();
4106     runcmd_ordryrun @dput, @hostarg, $changesfile;
4107     printdone "pushed and uploaded $cversion";
4108
4109     supplementary_message('');
4110     responder_send_command("complete");
4111 }
4112
4113 sub cmd_clone {
4114     parseopts();
4115     my $dstdir;
4116     badusage "-p is not allowed with clone; specify as argument instead"
4117         if defined $package;
4118     if (@ARGV==1) {
4119         ($package) = @ARGV;
4120     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4121         ($package,$isuite) = @ARGV;
4122     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4123         ($package,$dstdir) = @ARGV;
4124     } elsif (@ARGV==3) {
4125         ($package,$isuite,$dstdir) = @ARGV;
4126     } else {
4127         badusage "incorrect arguments to dgit clone";
4128     }
4129     notpushing();
4130
4131     $dstdir ||= "$package";
4132     if (stat_exists $dstdir) {
4133         fail "$dstdir already exists";
4134     }
4135
4136     my $cwd_remove;
4137     if ($rmonerror && !$dryrun_level) {
4138         $cwd_remove= getcwd();
4139         unshift @end, sub {
4140             return unless defined $cwd_remove;
4141             if (!chdir "$cwd_remove") {
4142                 return if $!==&ENOENT;
4143                 die "chdir $cwd_remove: $!";
4144             }
4145             printdebug "clone rmonerror removing $dstdir\n";
4146             if (stat $dstdir) {
4147                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4148             } elsif (grep { $! == $_ }
4149                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4150             } else {
4151                 print STDERR "check whether to remove $dstdir: $!\n";
4152             }
4153         };
4154     }
4155
4156     clone($dstdir);
4157     $cwd_remove = undef;
4158 }
4159
4160 sub branchsuite () {
4161     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4162     if ($branch =~ m#$lbranch_re#o) {
4163         return $1;
4164     } else {
4165         return undef;
4166     }
4167 }
4168
4169 sub fetchpullargs () {
4170     if (!defined $package) {
4171         my $sourcep = parsecontrol('debian/control','debian/control');
4172         $package = getfield $sourcep, 'Source';
4173     }
4174     if (@ARGV==0) {
4175         $isuite = branchsuite();
4176         if (!$isuite) {
4177             my $clogp = parsechangelog();
4178             $isuite = getfield $clogp, 'Distribution';
4179         }
4180     } elsif (@ARGV==1) {
4181         ($isuite) = @ARGV;
4182     } else {
4183         badusage "incorrect arguments to dgit fetch or dgit pull";
4184     }
4185     notpushing();
4186 }
4187
4188 sub cmd_fetch {
4189     parseopts();
4190     fetchpullargs();
4191     my $multi_fetched = fork_for_multisuite(sub { });
4192     exit 0 if $multi_fetched;
4193     fetch();
4194 }
4195
4196 sub cmd_pull {
4197     parseopts();
4198     fetchpullargs();
4199     if (quiltmode_splitbrain()) {
4200         my ($format, $fopts) = get_source_format();
4201         madformat($format) and fail <<END
4202 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4203 END
4204     }
4205     pull();
4206 }
4207
4208 sub cmd_push {
4209     parseopts();
4210     pushing();
4211     badusage "-p is not allowed with dgit push" if defined $package;
4212     check_not_dirty();
4213     my $clogp = parsechangelog();
4214     $package = getfield $clogp, 'Source';
4215     my $specsuite;
4216     if (@ARGV==0) {
4217     } elsif (@ARGV==1) {
4218         ($specsuite) = (@ARGV);
4219     } else {
4220         badusage "incorrect arguments to dgit push";
4221     }
4222     $isuite = getfield $clogp, 'Distribution';
4223     if ($new_package) {
4224         local ($package) = $existing_package; # this is a hack
4225         canonicalise_suite();
4226     } else {
4227         canonicalise_suite();
4228     }
4229     if (defined $specsuite &&
4230         $specsuite ne $isuite &&
4231         $specsuite ne $csuite) {
4232             fail "dgit push: changelog specifies $isuite ($csuite)".
4233                 " but command line specifies $specsuite";
4234     }
4235     dopush();
4236 }
4237
4238 #---------- remote commands' implementation ----------
4239
4240 sub cmd_remote_push_build_host {
4241     my ($nrargs) = shift @ARGV;
4242     my (@rargs) = @ARGV[0..$nrargs-1];
4243     @ARGV = @ARGV[$nrargs..$#ARGV];
4244     die unless @rargs;
4245     my ($dir,$vsnwant) = @rargs;
4246     # vsnwant is a comma-separated list; we report which we have
4247     # chosen in our ready response (so other end can tell if they
4248     # offered several)
4249     $debugprefix = ' ';
4250     $we_are_responder = 1;
4251     $us .= " (build host)";
4252
4253     pushing();
4254
4255     open PI, "<&STDIN" or die $!;
4256     open STDIN, "/dev/null" or die $!;
4257     open PO, ">&STDOUT" or die $!;
4258     autoflush PO 1;
4259     open STDOUT, ">&STDERR" or die $!;
4260     autoflush STDOUT 1;
4261
4262     $vsnwant //= 1;
4263     ($protovsn) = grep {
4264         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4265     } @rpushprotovsn_support;
4266
4267     fail "build host has dgit rpush protocol versions ".
4268         (join ",", @rpushprotovsn_support).
4269         " but invocation host has $vsnwant"
4270         unless defined $protovsn;
4271
4272     responder_send_command("dgit-remote-push-ready $protovsn");
4273     rpush_handle_protovsn_bothends();
4274     changedir $dir;
4275     &cmd_push;
4276 }
4277
4278 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4279 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4280 #     a good error message)
4281
4282 sub rpush_handle_protovsn_bothends () {
4283     if ($protovsn < 4) {
4284         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4285     }
4286     select_tagformat();
4287 }
4288
4289 our $i_tmp;
4290
4291 sub i_cleanup {
4292     local ($@, $?);
4293     my $report = i_child_report();
4294     if (defined $report) {
4295         printdebug "($report)\n";
4296     } elsif ($i_child_pid) {
4297         printdebug "(killing build host child $i_child_pid)\n";
4298         kill 15, $i_child_pid;
4299     }
4300     if (defined $i_tmp && !defined $initiator_tempdir) {
4301         changedir "/";
4302         eval { rmtree $i_tmp; };
4303     }
4304 }
4305
4306 END { i_cleanup(); }
4307
4308 sub i_method {
4309     my ($base,$selector,@args) = @_;
4310     $selector =~ s/\-/_/g;
4311     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4312 }
4313
4314 sub cmd_rpush {
4315     pushing();
4316     my $host = nextarg;
4317     my $dir;
4318     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4319         $host = $1;
4320         $dir = $'; #';
4321     } else {
4322         $dir = nextarg;
4323     }
4324     $dir =~ s{^-}{./-};
4325     my @rargs = ($dir);
4326     push @rargs, join ",", @rpushprotovsn_support;
4327     my @rdgit;
4328     push @rdgit, @dgit;
4329     push @rdgit, @ropts;
4330     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4331     push @rdgit, @ARGV;
4332     my @cmd = (@ssh, $host, shellquote @rdgit);
4333     debugcmd "+",@cmd;
4334
4335     if (defined $initiator_tempdir) {
4336         rmtree $initiator_tempdir;
4337         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4338         $i_tmp = $initiator_tempdir;
4339     } else {
4340         $i_tmp = tempdir();
4341     }
4342     $i_child_pid = open2(\*RO, \*RI, @cmd);
4343     changedir $i_tmp;
4344     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4345     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4346     $supplementary_message = '' unless $protovsn >= 3;
4347
4348     fail "rpush negotiated protocol version $protovsn".
4349         " which does not support quilt mode $quilt_mode"
4350         if quiltmode_splitbrain;
4351
4352     rpush_handle_protovsn_bothends();
4353     for (;;) {
4354         my ($icmd,$iargs) = initiator_expect {
4355             m/^(\S+)(?: (.*))?$/;
4356             ($1,$2);
4357         };
4358         i_method "i_resp", $icmd, $iargs;
4359     }
4360 }
4361
4362 sub i_resp_progress ($) {
4363     my ($rhs) = @_;
4364     my $msg = protocol_read_bytes \*RO, $rhs;
4365     progress $msg;
4366 }
4367
4368 sub i_resp_supplementary_message ($) {
4369     my ($rhs) = @_;
4370     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4371 }
4372
4373 sub i_resp_complete {
4374     my $pid = $i_child_pid;
4375     $i_child_pid = undef; # prevents killing some other process with same pid
4376     printdebug "waiting for build host child $pid...\n";
4377     my $got = waitpid $pid, 0;
4378     die $! unless $got == $pid;
4379     die "build host child failed $?" if $?;
4380
4381     i_cleanup();
4382     printdebug "all done\n";
4383     exit 0;
4384 }
4385
4386 sub i_resp_file ($) {
4387     my ($keyword) = @_;
4388     my $localname = i_method "i_localname", $keyword;
4389     my $localpath = "$i_tmp/$localname";
4390     stat_exists $localpath and
4391         badproto \*RO, "file $keyword ($localpath) twice";
4392     protocol_receive_file \*RO, $localpath;
4393     i_method "i_file", $keyword;
4394 }
4395
4396 our %i_param;
4397
4398 sub i_resp_param ($) {
4399     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4400     $i_param{$1} = $2;
4401 }
4402
4403 sub i_resp_previously ($) {
4404     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4405         or badproto \*RO, "bad previously spec";
4406     my $r = system qw(git check-ref-format), $1;
4407     die "bad previously ref spec ($r)" if $r;
4408     $previously{$1} = $2;
4409 }
4410
4411 our %i_wanted;
4412
4413 sub i_resp_want ($) {
4414     my ($keyword) = @_;
4415     die "$keyword ?" if $i_wanted{$keyword}++;
4416     my @localpaths = i_method "i_want", $keyword;
4417     printdebug "[[  $keyword @localpaths\n";
4418     foreach my $localpath (@localpaths) {
4419         protocol_send_file \*RI, $localpath;
4420     }
4421     print RI "files-end\n" or die $!;
4422 }
4423
4424 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4425
4426 sub i_localname_parsed_changelog {
4427     return "remote-changelog.822";
4428 }
4429 sub i_file_parsed_changelog {
4430     ($i_clogp, $i_version, $i_dscfn) =
4431         push_parse_changelog "$i_tmp/remote-changelog.822";
4432     die if $i_dscfn =~ m#/|^\W#;
4433 }
4434
4435 sub i_localname_dsc {
4436     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4437     return $i_dscfn;
4438 }
4439 sub i_file_dsc { }
4440
4441 sub i_localname_changes {
4442     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4443     $i_changesfn = $i_dscfn;
4444     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4445     return $i_changesfn;
4446 }
4447 sub i_file_changes { }
4448
4449 sub i_want_signed_tag {
4450     printdebug Dumper(\%i_param, $i_dscfn);
4451     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4452         && defined $i_param{'csuite'}
4453         or badproto \*RO, "premature desire for signed-tag";
4454     my $head = $i_param{'head'};
4455     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4456
4457     my $maintview = $i_param{'maint-view'};
4458     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4459
4460     select_tagformat();
4461     if ($protovsn >= 4) {
4462         my $p = $i_param{'tagformat'} // '<undef>';
4463         $p eq $tagformat
4464             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4465     }
4466
4467     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4468     $csuite = $&;
4469     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4470
4471     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4472
4473     return
4474         push_mktags $i_clogp, $i_dscfn,
4475             $i_changesfn, 'remote changes',
4476             \@tagwants;
4477 }
4478
4479 sub i_want_signed_dsc_changes {
4480     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4481     sign_changes $i_changesfn;
4482     return ($i_dscfn, $i_changesfn);
4483 }
4484
4485 #---------- building etc. ----------
4486
4487 our $version;
4488 our $sourcechanges;
4489 our $dscfn;
4490
4491 #----- `3.0 (quilt)' handling -----
4492
4493 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4494
4495 sub quiltify_dpkg_commit ($$$;$) {
4496     my ($patchname,$author,$msg, $xinfo) = @_;
4497     $xinfo //= '';
4498
4499     mkpath '.git/dgit';
4500     my $descfn = ".git/dgit/quilt-description.tmp";
4501     open O, '>', $descfn or die "$descfn: $!";
4502     $msg =~ s/\n+/\n\n/;
4503     print O <<END or die $!;
4504 From: $author
4505 ${xinfo}Subject: $msg
4506 ---
4507
4508 END
4509     close O or die $!;
4510
4511     {
4512         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4513         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4514         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4515         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4516     }
4517 }
4518
4519 sub quiltify_trees_differ ($$;$$$) {
4520     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4521     # returns true iff the two tree objects differ other than in debian/
4522     # with $finegrained,
4523     # returns bitmask 01 - differ in upstream files except .gitignore
4524     #                 02 - differ in .gitignore
4525     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4526     #  is set for each modified .gitignore filename $fn
4527     # if $unrepres is defined, array ref to which is appeneded
4528     #  a list of unrepresentable changes (removals of upstream files
4529     #  (as messages)
4530     local $/=undef;
4531     my @cmd = (@git, qw(diff-tree -z));
4532     push @cmd, qw(--name-only) unless $unrepres;
4533     push @cmd, qw(-r) if $finegrained || $unrepres;
4534     push @cmd, $x, $y;
4535     my $diffs= cmdoutput @cmd;
4536     my $r = 0;
4537     my @lmodes;
4538     foreach my $f (split /\0/, $diffs) {
4539         if ($unrepres && !@lmodes) {
4540             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4541             next;
4542         }
4543         my ($oldmode,$newmode) = @lmodes;
4544         @lmodes = ();
4545
4546         next if $f =~ m#^debian(?:/.*)?$#s;
4547
4548         if ($unrepres) {
4549             eval {
4550                 die "not a plain file\n"
4551                     unless $newmode =~ m/^10\d{4}$/ ||
4552                            $oldmode =~ m/^10\d{4}$/;
4553                 if ($oldmode =~ m/[^0]/ &&
4554                     $newmode =~ m/[^0]/) {
4555                     die "mode changed\n" if $oldmode ne $newmode;
4556                 } else {
4557                     die "non-default mode\n"
4558                         unless $newmode =~ m/^100644$/ ||
4559                                $oldmode =~ m/^100644$/;
4560                 }
4561             };
4562             if ($@) {
4563                 local $/="\n"; chomp $@;
4564                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4565             }
4566         }
4567
4568         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4569         $r |= $isignore ? 02 : 01;
4570         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4571     }
4572     printdebug "quiltify_trees_differ $x $y => $r\n";
4573     return $r;
4574 }
4575
4576 sub quiltify_tree_sentinelfiles ($) {
4577     # lists the `sentinel' files present in the tree
4578     my ($x) = @_;
4579     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4580         qw(-- debian/rules debian/control);
4581     $r =~ s/\n/,/g;
4582     return $r;
4583 }
4584
4585 sub quiltify_splitbrain_needed () {
4586     if (!$split_brain) {
4587         progress "dgit view: changes are required...";
4588         runcmd @git, qw(checkout -q -b dgit-view);
4589         $split_brain = 1;
4590     }
4591 }
4592
4593 sub quiltify_splitbrain ($$$$$$) {
4594     my ($clogp, $unapplied, $headref, $diffbits,
4595         $editedignores, $cachekey) = @_;
4596     if ($quilt_mode !~ m/gbp|dpm/) {
4597         # treat .gitignore just like any other upstream file
4598         $diffbits = { %$diffbits };
4599         $_ = !!$_ foreach values %$diffbits;
4600     }
4601     # We would like any commits we generate to be reproducible
4602     my @authline = clogp_authline($clogp);
4603     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4604     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4605     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4606     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4607     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4608     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4609
4610     if ($quilt_mode =~ m/gbp|unapplied/ &&
4611         ($diffbits->{O2H} & 01)) {
4612         my $msg =
4613  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4614  " but git tree differs from orig in upstream files.";
4615         if (!stat_exists "debian/patches") {
4616             $msg .=
4617  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4618         }
4619         fail $msg;
4620     }
4621     if ($quilt_mode =~ m/dpm/ &&
4622         ($diffbits->{H2A} & 01)) {
4623         fail <<END;
4624 --quilt=$quilt_mode specified, implying patches-applied git tree
4625  but git tree differs from result of applying debian/patches to upstream
4626 END
4627     }
4628     if ($quilt_mode =~ m/gbp|unapplied/ &&
4629         ($diffbits->{O2A} & 01)) { # some patches
4630         quiltify_splitbrain_needed();
4631         progress "dgit view: creating patches-applied version using gbp pq";
4632         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4633         # gbp pq import creates a fresh branch; push back to dgit-view
4634         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4635         runcmd @git, qw(checkout -q dgit-view);
4636     }
4637     if ($quilt_mode =~ m/gbp|dpm/ &&
4638         ($diffbits->{O2A} & 02)) {
4639         fail <<END
4640 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4641  tool which does not create patches for changes to upstream
4642  .gitignores: but, such patches exist in debian/patches.
4643 END
4644     }
4645     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4646         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4647         quiltify_splitbrain_needed();
4648         progress "dgit view: creating patch to represent .gitignore changes";
4649         ensuredir "debian/patches";
4650         my $gipatch = "debian/patches/auto-gitignore";
4651         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4652         stat GIPATCH or die "$gipatch: $!";
4653         fail "$gipatch already exists; but want to create it".
4654             " to record .gitignore changes" if (stat _)[7];
4655         print GIPATCH <<END or die "$gipatch: $!";
4656 Subject: Update .gitignore from Debian packaging branch
4657
4658 The Debian packaging git branch contains these updates to the upstream
4659 .gitignore file(s).  This patch is autogenerated, to provide these
4660 updates to users of the official Debian archive view of the package.
4661
4662 [dgit ($our_version) update-gitignore]
4663 ---
4664 END
4665         close GIPATCH or die "$gipatch: $!";
4666         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4667             $unapplied, $headref, "--", sort keys %$editedignores;
4668         open SERIES, "+>>", "debian/patches/series" or die $!;
4669         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4670         my $newline;
4671         defined read SERIES, $newline, 1 or die $!;
4672         print SERIES "\n" or die $! unless $newline eq "\n";
4673         print SERIES "auto-gitignore\n" or die $!;
4674         close SERIES or die  $!;
4675         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4676         commit_admin <<END
4677 Commit patch to update .gitignore
4678
4679 [dgit ($our_version) update-gitignore-quilt-fixup]
4680 END
4681     }
4682
4683     my $dgitview = git_rev_parse 'HEAD';
4684
4685     changedir '../../../..';
4686     # When we no longer need to support squeeze, use --create-reflog
4687     # instead of this:
4688     ensuredir ".git/logs/refs/dgit-intern";
4689     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4690       or die $!;
4691
4692     my $oldcache = git_get_ref "refs/$splitbraincache";
4693     if ($oldcache eq $dgitview) {
4694         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4695         # git update-ref doesn't always update, in this case.  *sigh*
4696         my $dummy = make_commit_text <<END;
4697 tree $tree
4698 parent $dgitview
4699 author Dgit <dgit\@example.com> 1000000000 +0000
4700 committer Dgit <dgit\@example.com> 1000000000 +0000
4701
4702 Dummy commit - do not use
4703 END
4704         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4705             "refs/$splitbraincache", $dummy;
4706     }
4707     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4708         $dgitview;
4709
4710     changedir '.git/dgit/unpack/work';
4711
4712     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4713     progress "dgit view: created ($saved)";
4714 }
4715
4716 sub quiltify ($$$$) {
4717     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4718
4719     # Quilt patchification algorithm
4720     #
4721     # We search backwards through the history of the main tree's HEAD
4722     # (T) looking for a start commit S whose tree object is identical
4723     # to to the patch tip tree (ie the tree corresponding to the
4724     # current dpkg-committed patch series).  For these purposes
4725     # `identical' disregards anything in debian/ - this wrinkle is
4726     # necessary because dpkg-source treates debian/ specially.
4727     #
4728     # We can only traverse edges where at most one of the ancestors'
4729     # trees differs (in changes outside in debian/).  And we cannot
4730     # handle edges which change .pc/ or debian/patches.  To avoid
4731     # going down a rathole we avoid traversing edges which introduce
4732     # debian/rules or debian/control.  And we set a limit on the
4733     # number of edges we are willing to look at.
4734     #
4735     # If we succeed, we walk forwards again.  For each traversed edge
4736     # PC (with P parent, C child) (starting with P=S and ending with
4737     # C=T) to we do this:
4738     #  - git checkout C
4739     #  - dpkg-source --commit with a patch name and message derived from C
4740     # After traversing PT, we git commit the changes which
4741     # should be contained within debian/patches.
4742
4743     # The search for the path S..T is breadth-first.  We maintain a
4744     # todo list containing search nodes.  A search node identifies a
4745     # commit, and looks something like this:
4746     #  $p = {
4747     #      Commit => $git_commit_id,
4748     #      Child => $c,                          # or undef if P=T
4749     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4750     #      Nontrivial => true iff $p..$c has relevant changes
4751     #  };
4752
4753     my @todo;
4754     my @nots;
4755     my $sref_S;
4756     my $max_work=100;
4757     my %considered; # saves being exponential on some weird graphs
4758
4759     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4760
4761     my $not = sub {
4762         my ($search,$whynot) = @_;
4763         printdebug " search NOT $search->{Commit} $whynot\n";
4764         $search->{Whynot} = $whynot;
4765         push @nots, $search;
4766         no warnings qw(exiting);
4767         next;
4768     };
4769
4770     push @todo, {
4771         Commit => $target,
4772     };
4773
4774     while (@todo) {
4775         my $c = shift @todo;
4776         next if $considered{$c->{Commit}}++;
4777
4778         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
4779
4780         printdebug "quiltify investigate $c->{Commit}\n";
4781
4782         # are we done?
4783         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
4784             printdebug " search finished hooray!\n";
4785             $sref_S = $c;
4786             last;
4787         }
4788
4789         if ($quilt_mode eq 'nofix') {
4790             fail "quilt fixup required but quilt mode is \`nofix'\n".
4791                 "HEAD commit $c->{Commit} differs from tree implied by ".
4792                 " debian/patches (tree object $oldtiptree)";
4793         }
4794         if ($quilt_mode eq 'smash') {
4795             printdebug " search quitting smash\n";
4796             last;
4797         }
4798
4799         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
4800         $not->($c, "has $c_sentinels not $t_sentinels")
4801             if $c_sentinels ne $t_sentinels;
4802
4803         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
4804         $commitdata =~ m/\n\n/;
4805         $commitdata =~ $`;
4806         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
4807         @parents = map { { Commit => $_, Child => $c } } @parents;
4808
4809         $not->($c, "root commit") if !@parents;
4810
4811         foreach my $p (@parents) {
4812             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
4813         }
4814         my $ndiffers = grep { $_->{Nontrivial} } @parents;
4815         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
4816
4817         foreach my $p (@parents) {
4818             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
4819
4820             my @cmd= (@git, qw(diff-tree -r --name-only),
4821                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
4822             my $patchstackchange = cmdoutput @cmd;
4823             if (length $patchstackchange) {
4824                 $patchstackchange =~ s/\n/,/g;
4825                 $not->($p, "changed $patchstackchange");
4826             }
4827
4828             printdebug " search queue P=$p->{Commit} ",
4829                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
4830             push @todo, $p;
4831         }
4832     }
4833
4834     if (!$sref_S) {
4835         printdebug "quiltify want to smash\n";
4836
4837         my $abbrev = sub {
4838             my $x = $_[0]{Commit};
4839             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
4840             return $x;
4841         };
4842         my $reportnot = sub {
4843             my ($notp) = @_;
4844             my $s = $abbrev->($notp);
4845             my $c = $notp->{Child};
4846             $s .= "..".$abbrev->($c) if $c;
4847             $s .= ": ".$notp->{Whynot};
4848             return $s;
4849         };
4850         if ($quilt_mode eq 'linear') {
4851             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
4852             foreach my $notp (@nots) {
4853                 print STDERR "$us:  ", $reportnot->($notp), "\n";
4854             }
4855             print STDERR "$us: $_\n" foreach @$failsuggestion;
4856             fail "quilt fixup naive history linearisation failed.\n".
4857  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
4858         } elsif ($quilt_mode eq 'smash') {
4859         } elsif ($quilt_mode eq 'auto') {
4860             progress "quilt fixup cannot be linear, smashing...";
4861         } else {
4862             die "$quilt_mode ?";
4863         }
4864
4865         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
4866         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
4867         my $ncommits = 3;
4868         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
4869
4870         quiltify_dpkg_commit "auto-$version-$target-$time",
4871             (getfield $clogp, 'Maintainer'),
4872             "Automatically generated patch ($clogp->{Version})\n".
4873             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
4874         return;
4875     }
4876
4877     progress "quiltify linearisation planning successful, executing...";
4878
4879     for (my $p = $sref_S;
4880          my $c = $p->{Child};
4881          $p = $p->{Child}) {
4882         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
4883         next unless $p->{Nontrivial};
4884
4885         my $cc = $c->{Commit};
4886
4887         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
4888         $commitdata =~ m/\n\n/ or die "$c ?";
4889         $commitdata = $`;
4890         my $msg = $'; #';
4891         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
4892         my $author = $1;
4893
4894         my $commitdate = cmdoutput
4895             @git, qw(log -n1 --pretty=format:%aD), $cc;
4896
4897         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
4898
4899         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
4900         $strip_nls->();
4901
4902         my $title = $1;
4903         my $patchname;
4904         my $patchdir;
4905
4906         my $gbp_check_suitable = sub {
4907             $_ = shift;
4908             my ($what) = @_;
4909
4910             eval {
4911                 die "contains unexpected slashes\n" if m{//} || m{/$};
4912                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
4913                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
4914                 die "too long" if length > 200;
4915             };
4916             return $_ unless $@;
4917             print STDERR "quiltifying commit $cc:".
4918                 " ignoring/dropping Gbp-Pq $what: $@";
4919             return undef;
4920         };
4921
4922         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
4923                            gbp-pq-name: \s* )
4924                        (\S+) \s* \n //ixm) {
4925             $patchname = $gbp_check_suitable->($1, 'Name');
4926         }
4927         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
4928                            gbp-pq-topic: \s* )
4929                        (\S+) \s* \n //ixm) {
4930             $patchdir = $gbp_check_suitable->($1, 'Topic');
4931         }
4932
4933         $strip_nls->();
4934
4935         if (!defined $patchname) {
4936             $patchname = $title;
4937             $patchname =~ s/[.:]$//;
4938             use Text::Iconv;
4939             eval {
4940                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
4941                 my $translitname = $converter->convert($patchname);
4942                 die unless defined $translitname;
4943                 $patchname = $translitname;
4944             };
4945             print STDERR
4946                 "dgit: patch title transliteration error: $@"
4947                 if $@;
4948             $patchname =~ y/ A-Z/-a-z/;
4949             $patchname =~ y/-a-z0-9_.+=~//cd;
4950             $patchname =~ s/^\W/x-$&/;
4951             $patchname = substr($patchname,0,40);
4952         }
4953         if (!defined $patchdir) {
4954             $patchdir = '';
4955         }
4956         if (length $patchdir) {
4957             $patchname = "$patchdir/$patchname";
4958         }
4959         if ($patchname =~ m{^(.*)/}) {
4960             mkpath "debian/patches/$1";
4961         }
4962
4963         my $index;
4964         for ($index='';
4965              stat "debian/patches/$patchname$index";
4966              $index++) { }
4967         $!==ENOENT or die "$patchname$index $!";
4968
4969         runcmd @git, qw(checkout -q), $cc;
4970
4971         # We use the tip's changelog so that dpkg-source doesn't
4972         # produce complaining messages from dpkg-parsechangelog.  None
4973         # of the information dpkg-source gets from the changelog is
4974         # actually relevant - it gets put into the original message
4975         # which dpkg-source provides our stunt editor, and then
4976         # overwritten.
4977         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
4978
4979         quiltify_dpkg_commit "$patchname$index", $author, $msg,
4980             "Date: $commitdate\n".
4981             "X-Dgit-Generated: $clogp->{Version} $cc\n";
4982
4983         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
4984     }
4985
4986     runcmd @git, qw(checkout -q master);
4987 }
4988
4989 sub build_maybe_quilt_fixup () {
4990     my ($format,$fopts) = get_source_format;
4991     return unless madformat_wantfixup $format;
4992     # sigh
4993
4994     check_for_vendor_patches();
4995
4996     if (quiltmode_splitbrain) {
4997         fail <<END unless access_cfg_tagformats_can_splitbrain;
4998 quilt mode $quilt_mode requires split view so server needs to support
4999  both "new" and "maint" tag formats, but config says it doesn't.
5000 END
5001     }
5002
5003     my $clogp = parsechangelog();
5004     my $headref = git_rev_parse('HEAD');
5005
5006     prep_ud();
5007     changedir $ud;
5008
5009     my $upstreamversion = upstreamversion $version;
5010
5011     if ($fopts->{'single-debian-patch'}) {
5012         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5013     } else {
5014         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5015     }
5016
5017     die 'bug' if $split_brain && !$need_split_build_invocation;
5018
5019     changedir '../../../..';
5020     runcmd_ordryrun_local
5021         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5022 }
5023
5024 sub quilt_fixup_mkwork ($) {
5025     my ($headref) = @_;
5026
5027     mkdir "work" or die $!;
5028     changedir "work";
5029     mktree_in_ud_here();
5030     runcmd @git, qw(reset -q --hard), $headref;
5031 }
5032
5033 sub quilt_fixup_linkorigs ($$) {
5034     my ($upstreamversion, $fn) = @_;
5035     # calls $fn->($leafname);
5036
5037     foreach my $f (<../../../../*>) { #/){
5038         my $b=$f; $b =~ s{.*/}{};
5039         {
5040             local ($debuglevel) = $debuglevel-1;
5041             printdebug "QF linkorigs $b, $f ?\n";
5042         }
5043         next unless is_orig_file_of_vsn $b, $upstreamversion;
5044         printdebug "QF linkorigs $b, $f Y\n";
5045         link_ltarget $f, $b or die "$b $!";
5046         $fn->($b);
5047     }
5048 }
5049
5050 sub quilt_fixup_delete_pc () {
5051     runcmd @git, qw(rm -rqf .pc);
5052     commit_admin <<END
5053 Commit removal of .pc (quilt series tracking data)
5054
5055 [dgit ($our_version) upgrade quilt-remove-pc]
5056 END
5057 }
5058
5059 sub quilt_fixup_singlepatch ($$$) {
5060     my ($clogp, $headref, $upstreamversion) = @_;
5061
5062     progress "starting quiltify (single-debian-patch)";
5063
5064     # dpkg-source --commit generates new patches even if
5065     # single-debian-patch is in debian/source/options.  In order to
5066     # get it to generate debian/patches/debian-changes, it is
5067     # necessary to build the source package.
5068
5069     quilt_fixup_linkorigs($upstreamversion, sub { });
5070     quilt_fixup_mkwork($headref);
5071
5072     rmtree("debian/patches");
5073
5074     runcmd @dpkgsource, qw(-b .);
5075     changedir "..";
5076     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5077     rename srcfn("$upstreamversion", "/debian/patches"),
5078            "work/debian/patches";
5079
5080     changedir "work";
5081     commit_quilty_patch();
5082 }
5083
5084 sub quilt_make_fake_dsc ($) {
5085     my ($upstreamversion) = @_;
5086
5087     my $fakeversion="$upstreamversion-~~DGITFAKE";
5088
5089     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5090     print $fakedsc <<END or die $!;
5091 Format: 3.0 (quilt)
5092 Source: $package
5093 Version: $fakeversion
5094 Files:
5095 END
5096
5097     my $dscaddfile=sub {
5098         my ($b) = @_;
5099
5100         my $md = new Digest::MD5;
5101
5102         my $fh = new IO::File $b, '<' or die "$b $!";
5103         stat $fh or die $!;
5104         my $size = -s _;
5105
5106         $md->addfile($fh);
5107         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5108     };
5109
5110     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5111
5112     my @files=qw(debian/source/format debian/rules
5113                  debian/control debian/changelog);
5114     foreach my $maybe (qw(debian/patches debian/source/options
5115                           debian/tests/control)) {
5116         next unless stat_exists "../../../$maybe";
5117         push @files, $maybe;
5118     }
5119
5120     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5121     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5122
5123     $dscaddfile->($debtar);
5124     close $fakedsc or die $!;
5125 }
5126
5127 sub quilt_check_splitbrain_cache ($$) {
5128     my ($headref, $upstreamversion) = @_;
5129     # Called only if we are in (potentially) split brain mode.
5130     # Called in $ud.
5131     # Computes the cache key and looks in the cache.
5132     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5133
5134     my $splitbrain_cachekey;
5135
5136     progress
5137  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5138     # we look in the reflog of dgit-intern/quilt-cache
5139     # we look for an entry whose message is the key for the cache lookup
5140     my @cachekey = (qw(dgit), $our_version);
5141     push @cachekey, $upstreamversion;
5142     push @cachekey, $quilt_mode;
5143     push @cachekey, $headref;
5144
5145     push @cachekey, hashfile('fake.dsc');
5146
5147     my $srcshash = Digest::SHA->new(256);
5148     my %sfs = ( %INC, '$0(dgit)' => $0 );
5149     foreach my $sfk (sort keys %sfs) {
5150         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5151         $srcshash->add($sfk,"  ");
5152         $srcshash->add(hashfile($sfs{$sfk}));
5153         $srcshash->add("\n");
5154     }
5155     push @cachekey, $srcshash->hexdigest();
5156     $splitbrain_cachekey = "@cachekey";
5157
5158     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5159                $splitbraincache);
5160     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5161     debugcmd "|(probably)",@cmd;
5162     my $child = open GC, "-|";  defined $child or die $!;
5163     if (!$child) {
5164         chdir '../../..' or die $!;
5165         if (!stat ".git/logs/refs/$splitbraincache") {
5166             $! == ENOENT or die $!;
5167             printdebug ">(no reflog)\n";
5168             exit 0;
5169         }
5170         exec @cmd; die $!;
5171     }
5172     while (<GC>) {
5173         chomp;
5174         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5175         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5176
5177         my $cachehit = $1;
5178         quilt_fixup_mkwork($headref);
5179         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5180         if ($cachehit ne $headref) {
5181             progress "dgit view: found cached ($saved)";
5182             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5183             $split_brain = 1;
5184             return ($cachehit, $splitbrain_cachekey);
5185         }
5186         progress "dgit view: found cached, no changes required";
5187         return ($headref, $splitbrain_cachekey);
5188     }
5189     die $! if GC->error;
5190     failedcmd unless close GC;
5191
5192     printdebug "splitbrain cache miss\n";
5193     return (undef, $splitbrain_cachekey);
5194 }
5195
5196 sub quilt_fixup_multipatch ($$$) {
5197     my ($clogp, $headref, $upstreamversion) = @_;
5198
5199     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5200
5201     # Our objective is:
5202     #  - honour any existing .pc in case it has any strangeness
5203     #  - determine the git commit corresponding to the tip of
5204     #    the patch stack (if there is one)
5205     #  - if there is such a git commit, convert each subsequent
5206     #    git commit into a quilt patch with dpkg-source --commit
5207     #  - otherwise convert all the differences in the tree into
5208     #    a single git commit
5209     #
5210     # To do this we:
5211
5212     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5213     # dgit would include the .pc in the git tree.)  If there isn't
5214     # one, we need to generate one by unpacking the patches that we
5215     # have.
5216     #
5217     # We first look for a .pc in the git tree.  If there is one, we
5218     # will use it.  (This is not the normal case.)
5219     #
5220     # Otherwise need to regenerate .pc so that dpkg-source --commit
5221     # can work.  We do this as follows:
5222     #     1. Collect all relevant .orig from parent directory
5223     #     2. Generate a debian.tar.gz out of
5224     #         debian/{patches,rules,source/format,source/options}
5225     #     3. Generate a fake .dsc containing just these fields:
5226     #          Format Source Version Files
5227     #     4. Extract the fake .dsc
5228     #        Now the fake .dsc has a .pc directory.
5229     # (In fact we do this in every case, because in future we will
5230     # want to search for a good base commit for generating patches.)
5231     #
5232     # Then we can actually do the dpkg-source --commit
5233     #     1. Make a new working tree with the same object
5234     #        store as our main tree and check out the main
5235     #        tree's HEAD.
5236     #     2. Copy .pc from the fake's extraction, if necessary
5237     #     3. Run dpkg-source --commit
5238     #     4. If the result has changes to debian/, then
5239     #          - git add them them
5240     #          - git add .pc if we had a .pc in-tree
5241     #          - git commit
5242     #     5. If we had a .pc in-tree, delete it, and git commit
5243     #     6. Back in the main tree, fast forward to the new HEAD
5244
5245     # Another situation we may have to cope with is gbp-style
5246     # patches-unapplied trees.
5247     #
5248     # We would want to detect these, so we know to escape into
5249     # quilt_fixup_gbp.  However, this is in general not possible.
5250     # Consider a package with a one patch which the dgit user reverts
5251     # (with git revert or the moral equivalent).
5252     #
5253     # That is indistinguishable in contents from a patches-unapplied
5254     # tree.  And looking at the history to distinguish them is not
5255     # useful because the user might have made a confusing-looking git
5256     # history structure (which ought to produce an error if dgit can't
5257     # cope, not a silent reintroduction of an unwanted patch).
5258     #
5259     # So gbp users will have to pass an option.  But we can usually
5260     # detect their failure to do so: if the tree is not a clean
5261     # patches-applied tree, quilt linearisation fails, but the tree
5262     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5263     # they want --quilt=unapplied.
5264     #
5265     # To help detect this, when we are extracting the fake dsc, we
5266     # first extract it with --skip-patches, and then apply the patches
5267     # afterwards with dpkg-source --before-build.  That lets us save a
5268     # tree object corresponding to .origs.
5269
5270     my $splitbrain_cachekey;
5271
5272     quilt_make_fake_dsc($upstreamversion);
5273
5274     if (quiltmode_splitbrain()) {
5275         my $cachehit;
5276         ($cachehit, $splitbrain_cachekey) =
5277             quilt_check_splitbrain_cache($headref, $upstreamversion);
5278         return if $cachehit;
5279     }
5280
5281     runcmd qw(sh -ec),
5282         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5283
5284     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5285     rename $fakexdir, "fake" or die "$fakexdir $!";
5286
5287     changedir 'fake';
5288
5289     remove_stray_gits("source package");
5290     mktree_in_ud_here();
5291
5292     rmtree '.pc';
5293
5294     my $unapplied=git_add_write_tree();
5295     printdebug "fake orig tree object $unapplied\n";
5296
5297     ensuredir '.pc';
5298
5299     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5300     $!=0; $?=-1;
5301     if (system @bbcmd) {
5302         failedcmd @bbcmd if $? < 0;
5303         fail <<END;
5304 failed to apply your git tree's patch stack (from debian/patches/) to
5305  the corresponding upstream tarball(s).  Your source tree and .orig
5306  are probably too inconsistent.  dgit can only fix up certain kinds of
5307  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5308 END
5309     }
5310
5311     changedir '..';
5312
5313     quilt_fixup_mkwork($headref);
5314
5315     my $mustdeletepc=0;
5316     if (stat_exists ".pc") {
5317         -d _ or die;
5318         progress "Tree already contains .pc - will use it then delete it.";
5319         $mustdeletepc=1;
5320     } else {
5321         rename '../fake/.pc','.pc' or die $!;
5322     }
5323
5324     changedir '../fake';
5325     rmtree '.pc';
5326     my $oldtiptree=git_add_write_tree();
5327     printdebug "fake o+d/p tree object $unapplied\n";
5328     changedir '../work';
5329
5330
5331     # We calculate some guesswork now about what kind of tree this might
5332     # be.  This is mostly for error reporting.
5333
5334     my %editedignores;
5335     my @unrepres;
5336     my $diffbits = {
5337         # H = user's HEAD
5338         # O = orig, without patches applied
5339         # A = "applied", ie orig with H's debian/patches applied
5340         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5341                                      \%editedignores, \@unrepres),
5342         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5343         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5344     };
5345
5346     my @dl;
5347     foreach my $b (qw(01 02)) {
5348         foreach my $v (qw(O2H O2A H2A)) {
5349             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5350         }
5351     }
5352     printdebug "differences \@dl @dl.\n";
5353
5354     progress sprintf
5355 "$us: base trees orig=%.20s o+d/p=%.20s",
5356               $unapplied, $oldtiptree;
5357     progress sprintf
5358 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5359 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5360                              $dl[0], $dl[1],              $dl[3], $dl[4],
5361                                  $dl[2],                     $dl[5];
5362
5363     if (@unrepres) {
5364         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5365             foreach @unrepres;
5366         forceable_fail [qw(unrepresentable)], <<END;
5367 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5368 END
5369     }
5370
5371     my @failsuggestion;
5372     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5373         push @failsuggestion, "This might be a patches-unapplied branch.";
5374     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5375         push @failsuggestion, "This might be a patches-applied branch.";
5376     }
5377     push @failsuggestion, "Maybe you need to specify one of".
5378         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5379
5380     if (quiltmode_splitbrain()) {
5381         quiltify_splitbrain($clogp, $unapplied, $headref,
5382                             $diffbits, \%editedignores,
5383                             $splitbrain_cachekey);
5384         return;
5385     }
5386
5387     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5388     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5389
5390     if (!open P, '>>', ".pc/applied-patches") {
5391         $!==&ENOENT or die $!;
5392     } else {
5393         close P;
5394     }
5395
5396     commit_quilty_patch();
5397
5398     if ($mustdeletepc) {
5399         quilt_fixup_delete_pc();
5400     }
5401 }
5402
5403 sub quilt_fixup_editor () {
5404     my $descfn = $ENV{$fakeeditorenv};
5405     my $editing = $ARGV[$#ARGV];
5406     open I1, '<', $descfn or die "$descfn: $!";
5407     open I2, '<', $editing or die "$editing: $!";
5408     unlink $editing or die "$editing: $!";
5409     open O, '>', $editing or die "$editing: $!";
5410     while (<I1>) { print O or die $!; } I1->error and die $!;
5411     my $copying = 0;
5412     while (<I2>) {
5413         $copying ||= m/^\-\-\- /;
5414         next unless $copying;
5415         print O or die $!;
5416     }
5417     I2->error and die $!;
5418     close O or die $1;
5419     exit 0;
5420 }
5421
5422 sub maybe_apply_patches_dirtily () {
5423     return unless $quilt_mode =~ m/gbp|unapplied/;
5424     print STDERR <<END or die $!;
5425
5426 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5427 dgit: Have to apply the patches - making the tree dirty.
5428 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5429
5430 END
5431     $patches_applied_dirtily = 01;
5432     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5433     runcmd qw(dpkg-source --before-build .);
5434 }
5435
5436 sub maybe_unapply_patches_again () {
5437     progress "dgit: Unapplying patches again to tidy up the tree."
5438         if $patches_applied_dirtily;
5439     runcmd qw(dpkg-source --after-build .)
5440         if $patches_applied_dirtily & 01;
5441     rmtree '.pc'
5442         if $patches_applied_dirtily & 02;
5443     $patches_applied_dirtily = 0;
5444 }
5445
5446 #----- other building -----
5447
5448 our $clean_using_builder;
5449 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5450 #   clean the tree before building (perhaps invoked indirectly by
5451 #   whatever we are using to run the build), rather than separately
5452 #   and explicitly by us.
5453
5454 sub clean_tree () {
5455     return if $clean_using_builder;
5456     if ($cleanmode eq 'dpkg-source') {
5457         maybe_apply_patches_dirtily();
5458         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5459     } elsif ($cleanmode eq 'dpkg-source-d') {
5460         maybe_apply_patches_dirtily();
5461         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5462     } elsif ($cleanmode eq 'git') {
5463         runcmd_ordryrun_local @git, qw(clean -xdf);
5464     } elsif ($cleanmode eq 'git-ff') {
5465         runcmd_ordryrun_local @git, qw(clean -xdff);
5466     } elsif ($cleanmode eq 'check') {
5467         my $leftovers = cmdoutput @git, qw(clean -xdn);
5468         if (length $leftovers) {
5469             print STDERR $leftovers, "\n" or die $!;
5470             fail "tree contains uncommitted files and --clean=check specified";
5471         }
5472     } elsif ($cleanmode eq 'none') {
5473     } else {
5474         die "$cleanmode ?";
5475     }
5476 }
5477
5478 sub cmd_clean () {
5479     badusage "clean takes no additional arguments" if @ARGV;
5480     notpushing();
5481     clean_tree();
5482     maybe_unapply_patches_again();
5483 }
5484
5485 sub build_prep_early () {
5486     our $build_prep_early_done //= 0;
5487     return if $build_prep_early_done++;
5488     notpushing();
5489     badusage "-p is not allowed when building" if defined $package;
5490     my $clogp = parsechangelog();
5491     $isuite = getfield $clogp, 'Distribution';
5492     $package = getfield $clogp, 'Source';
5493     $version = getfield $clogp, 'Version';
5494     check_not_dirty();
5495 }
5496
5497 sub build_prep () {
5498     build_prep_early();
5499     clean_tree();
5500     build_maybe_quilt_fixup();
5501     if ($rmchanges) {
5502         my $pat = changespat $version;
5503         foreach my $f (glob "$buildproductsdir/$pat") {
5504             if (act_local()) {
5505                 unlink $f or fail "remove old changes file $f: $!";
5506             } else {
5507                 progress "would remove $f";
5508             }
5509         }
5510     }
5511 }
5512
5513 sub changesopts_initial () {
5514     my @opts =@changesopts[1..$#changesopts];
5515 }
5516
5517 sub changesopts_version () {
5518     if (!defined $changes_since_version) {
5519         my @vsns = archive_query('archive_query');
5520         my @quirk = access_quirk();
5521         if ($quirk[0] eq 'backports') {
5522             local $isuite = $quirk[2];
5523             local $csuite;
5524             canonicalise_suite();
5525             push @vsns, archive_query('archive_query');
5526         }
5527         if (@vsns) {
5528             @vsns = map { $_->[0] } @vsns;
5529             @vsns = sort { -version_compare($a, $b) } @vsns;
5530             $changes_since_version = $vsns[0];
5531             progress "changelog will contain changes since $vsns[0]";
5532         } else {
5533             $changes_since_version = '_';
5534             progress "package seems new, not specifying -v<version>";
5535         }
5536     }
5537     if ($changes_since_version ne '_') {
5538         return ("-v$changes_since_version");
5539     } else {
5540         return ();
5541     }
5542 }
5543
5544 sub changesopts () {
5545     return (changesopts_initial(), changesopts_version());
5546 }
5547
5548 sub massage_dbp_args ($;$) {
5549     my ($cmd,$xargs) = @_;
5550     # We need to:
5551     #
5552     #  - if we're going to split the source build out so we can
5553     #    do strange things to it, massage the arguments to dpkg-buildpackage
5554     #    so that the main build doessn't build source (or add an argument
5555     #    to stop it building source by default).
5556     #
5557     #  - add -nc to stop dpkg-source cleaning the source tree,
5558     #    unless we're not doing a split build and want dpkg-source
5559     #    as cleanmode, in which case we can do nothing
5560     #
5561     # return values:
5562     #    0 - source will NOT need to be built separately by caller
5563     #   +1 - source will need to be built separately by caller
5564     #   +2 - source will need to be built separately by caller AND
5565     #        dpkg-buildpackage should not in fact be run at all!
5566     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5567 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5568     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5569         $clean_using_builder = 1;
5570         return 0;
5571     }
5572     # -nc has the side effect of specifying -b if nothing else specified
5573     # and some combinations of -S, -b, et al, are errors, rather than
5574     # later simply overriding earlie.  So we need to:
5575     #  - search the command line for these options
5576     #  - pick the last one
5577     #  - perhaps add our own as a default
5578     #  - perhaps adjust it to the corresponding non-source-building version
5579     my $dmode = '-F';
5580     foreach my $l ($cmd, $xargs) {
5581         next unless $l;
5582         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5583     }
5584     push @$cmd, '-nc';
5585 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5586     my $r = 0;
5587     if ($need_split_build_invocation) {
5588         printdebug "massage split $dmode.\n";
5589         $r = $dmode =~ m/[S]/     ? +2 :
5590              $dmode =~ y/gGF/ABb/ ? +1 :
5591              $dmode =~ m/[ABb]/   ?  0 :
5592              die "$dmode ?";
5593     }
5594     printdebug "massage done $r $dmode.\n";
5595     push @$cmd, $dmode;
5596 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5597     return $r;
5598 }
5599
5600 sub in_parent (&) {
5601     my ($fn) = @_;
5602     my $wasdir = must_getcwd();
5603     changedir "..";
5604     $fn->();
5605     changedir $wasdir;
5606 }
5607
5608 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5609     my ($msg_if_onlyone) = @_;
5610     # If there is only one .changes file, fail with $msg_if_onlyone,
5611     # or if that is undef, be a no-op.
5612     # Returns the changes file to report to the user.
5613     my $pat = changespat $version;
5614     my @changesfiles = glob $pat;
5615     @changesfiles = sort {
5616         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5617             or $a cmp $b
5618     } @changesfiles;
5619     my $result;
5620     if (@changesfiles==1) {
5621         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5622 only one changes file from build (@changesfiles)
5623 END
5624         $result = $changesfiles[0];
5625     } elsif (@changesfiles==2) {
5626         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5627         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5628             fail "$l found in binaries changes file $binchanges"
5629                 if $l =~ m/\.dsc$/;
5630         }
5631         runcmd_ordryrun_local @mergechanges, @changesfiles;
5632         my $multichanges = changespat $version,'multi';
5633         if (act_local()) {
5634             stat_exists $multichanges or fail "$multichanges: $!";
5635             foreach my $cf (glob $pat) {
5636                 next if $cf eq $multichanges;
5637                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5638             }
5639         }
5640         $result = $multichanges;
5641     } else {
5642         fail "wrong number of different changes files (@changesfiles)";
5643     }
5644     printdone "build successful, results in $result\n" or die $!;
5645 }
5646
5647 sub midbuild_checkchanges () {
5648     my $pat = changespat $version;
5649     return if $rmchanges;
5650     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5651     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5652     fail <<END
5653 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5654 Suggest you delete @unwanted.
5655 END
5656         if @unwanted;
5657 }
5658
5659 sub midbuild_checkchanges_vanilla ($) {
5660     my ($wantsrc) = @_;
5661     midbuild_checkchanges() if $wantsrc == 1;
5662 }
5663
5664 sub postbuild_mergechanges_vanilla ($) {
5665     my ($wantsrc) = @_;
5666     if ($wantsrc == 1) {
5667         in_parent {
5668             postbuild_mergechanges(undef);
5669         };
5670     } else {
5671         printdone "build successful\n";
5672     }
5673 }
5674
5675 sub cmd_build {
5676     build_prep_early();
5677     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5678     my $wantsrc = massage_dbp_args \@dbp;
5679     if ($wantsrc > 0) {
5680         build_source();
5681         midbuild_checkchanges_vanilla $wantsrc;
5682     } else {
5683         build_prep();
5684     }
5685     if ($wantsrc < 2) {
5686         push @dbp, changesopts_version();
5687         maybe_apply_patches_dirtily();
5688         runcmd_ordryrun_local @dbp;
5689     }
5690     maybe_unapply_patches_again();
5691     postbuild_mergechanges_vanilla $wantsrc;
5692 }
5693
5694 sub pre_gbp_build {
5695     $quilt_mode //= 'gbp';
5696 }
5697
5698 sub cmd_gbp_build {
5699     build_prep_early();
5700
5701     # gbp can make .origs out of thin air.  In my tests it does this
5702     # even for a 1.0 format package, with no origs present.  So I
5703     # guess it keys off just the version number.  We don't know
5704     # exactly what .origs ought to exist, but let's assume that we
5705     # should run gbp if: the version has an upstream part and the main
5706     # orig is absent.
5707     my $upstreamversion = upstreamversion $version;
5708     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5709     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5710
5711     if ($gbp_make_orig) {
5712         clean_tree();
5713         $cleanmode = 'none'; # don't do it again
5714         $need_split_build_invocation = 1;
5715     }
5716
5717     my @dbp = @dpkgbuildpackage;
5718
5719     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5720
5721     if (!length $gbp_build[0]) {
5722         if (length executable_on_path('git-buildpackage')) {
5723             $gbp_build[0] = qw(git-buildpackage);
5724         } else {
5725             $gbp_build[0] = 'gbp buildpackage';
5726         }
5727     }
5728     my @cmd = opts_opt_multi_cmd @gbp_build;
5729
5730     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5731
5732     if ($gbp_make_orig) {
5733         ensuredir '.git/dgit';
5734         my $ok = '.git/dgit/origs-gen-ok';
5735         unlink $ok or $!==&ENOENT or die $!;
5736         my @origs_cmd = @cmd;
5737         push @origs_cmd, qw(--git-cleaner=true);
5738         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5739         push @origs_cmd, @ARGV;
5740         if (act_local()) {
5741             debugcmd @origs_cmd;
5742             system @origs_cmd;
5743             do { local $!; stat_exists $ok; }
5744                 or failedcmd @origs_cmd;
5745         } else {
5746             dryrun_report @origs_cmd;
5747         }
5748     }
5749
5750     if ($wantsrc > 0) {
5751         build_source();
5752         midbuild_checkchanges_vanilla $wantsrc;
5753     } else {
5754         if (!$clean_using_builder) {
5755             push @cmd, '--git-cleaner=true';
5756         }
5757         build_prep();
5758     }
5759     maybe_unapply_patches_again();
5760     if ($wantsrc < 2) {
5761         push @cmd, changesopts();
5762         runcmd_ordryrun_local @cmd, @ARGV;
5763     }
5764     postbuild_mergechanges_vanilla $wantsrc;
5765 }
5766 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
5767
5768 sub build_source {
5769     build_prep_early();
5770     my $our_cleanmode = $cleanmode;
5771     if ($need_split_build_invocation) {
5772         # Pretend that clean is being done some other way.  This
5773         # forces us not to try to use dpkg-buildpackage to clean and
5774         # build source all in one go; and instead we run dpkg-source
5775         # (and build_prep() will do the clean since $clean_using_builder
5776         # is false).
5777         $our_cleanmode = 'ELSEWHERE';
5778     }
5779     if ($our_cleanmode =~ m/^dpkg-source/) {
5780         # dpkg-source invocation (below) will clean, so build_prep shouldn't
5781         $clean_using_builder = 1;
5782     }
5783     build_prep();
5784     $sourcechanges = changespat $version,'source';
5785     if (act_local()) {
5786         unlink "../$sourcechanges" or $!==ENOENT
5787             or fail "remove $sourcechanges: $!";
5788     }
5789     $dscfn = dscfn($version);
5790     if ($our_cleanmode eq 'dpkg-source') {
5791         maybe_apply_patches_dirtily();
5792         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
5793             changesopts();
5794     } elsif ($our_cleanmode eq 'dpkg-source-d') {
5795         maybe_apply_patches_dirtily();
5796         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
5797             changesopts();
5798     } else {
5799         my @cmd = (@dpkgsource, qw(-b --));
5800         if ($split_brain) {
5801             changedir $ud;
5802             runcmd_ordryrun_local @cmd, "work";
5803             my @udfiles = <${package}_*>;
5804             changedir "../../..";
5805             foreach my $f (@udfiles) {
5806                 printdebug "source copy, found $f\n";
5807                 next unless
5808                     $f eq $dscfn or
5809                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
5810                      $f eq srcfn($version, $&));
5811                 printdebug "source copy, found $f - renaming\n";
5812                 rename "$ud/$f", "../$f" or $!==ENOENT
5813                     or fail "put in place new source file ($f): $!";
5814             }
5815         } else {
5816             my $pwd = must_getcwd();
5817             my $leafdir = basename $pwd;
5818             changedir "..";
5819             runcmd_ordryrun_local @cmd, $leafdir;
5820             changedir $pwd;
5821         }
5822         runcmd_ordryrun_local qw(sh -ec),
5823             'exec >$1; shift; exec "$@"','x',
5824             "../$sourcechanges",
5825             @dpkggenchanges, qw(-S), changesopts();
5826     }
5827 }
5828
5829 sub cmd_build_source {
5830     build_prep_early();
5831     badusage "build-source takes no additional arguments" if @ARGV;
5832     build_source();
5833     maybe_unapply_patches_again();
5834     printdone "source built, results in $dscfn and $sourcechanges";
5835 }
5836
5837 sub cmd_sbuild {
5838     build_source();
5839     midbuild_checkchanges();
5840     in_parent {
5841         if (act_local()) {
5842             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
5843             stat_exists $sourcechanges
5844                 or fail "$sourcechanges (in parent directory): $!";
5845         }
5846         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
5847     };
5848     maybe_unapply_patches_again();
5849     in_parent {
5850         postbuild_mergechanges(<<END);
5851 perhaps you need to pass -A ?  (sbuild's default is to build only
5852 arch-specific binaries; dgit 1.4 used to override that.)
5853 END
5854     };
5855 }
5856
5857 sub cmd_quilt_fixup {
5858     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
5859     build_prep_early();
5860     clean_tree();
5861     build_maybe_quilt_fixup();
5862 }
5863
5864 sub cmd_import_dsc {
5865     my $needsig = 0;
5866
5867     while (@ARGV) {
5868         last unless $ARGV[0] =~ m/^-/;
5869         $_ = shift @ARGV;
5870         last if m/^--?$/;
5871         if (m/^--require-valid-signature$/) {
5872             $needsig = 1;
5873         } else {
5874             badusage "unknown dgit import-dsc sub-option \`$_'";
5875         }
5876     }
5877
5878     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
5879     my ($dscfn, $dstbranch) = @ARGV;
5880
5881     badusage "dry run makes no sense with import-dsc" unless act_local();
5882
5883     my $force = $dstbranch =~ s/^\+//   ? +1 :
5884                 $dstbranch =~ s/^\.\.// ? -1 :
5885                                            0;
5886     my $info = $force ? " $&" : '';
5887     $info = "$dscfn$info";
5888
5889     my $specbranch = $dstbranch;
5890     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
5891     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
5892
5893     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
5894     my $chead = cmdoutput_errok @symcmd;
5895     defined $chead or $?==256 or failedcmd @symcmd;
5896
5897     fail "$dstbranch is checked out - will not update it"
5898         if defined $chead and $chead eq $dstbranch;
5899
5900     my $oldhash = git_get_ref $dstbranch;
5901
5902     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
5903     $dscdata = do { local $/ = undef; <D>; };
5904     D->error and fail "read $dscfn: $!";
5905     close C;
5906
5907     # we don't normally need this so import it here
5908     use Dpkg::Source::Package;
5909     my $dp = new Dpkg::Source::Package filename => $dscfn,
5910         require_valid_signature => $needsig;
5911     {
5912         local $SIG{__WARN__} = sub {
5913             print STDERR $_[0];
5914             return unless $needsig;
5915             fail "import-dsc signature check failed";
5916         };
5917         if (!$dp->is_signed()) {
5918             warn "$us: warning: importing unsigned .dsc\n";
5919         } else {
5920             my $r = $dp->check_signature();
5921             die "->check_signature => $r" if $needsig && $r;
5922         }
5923     }
5924
5925     parse_dscdata();
5926
5927     parse_dsc_field($dsc, "Dgit metadata in .dsc");
5928
5929     if (defined $dsc_hash
5930         && !forceing [qw(import-dsc-with-dgit-field)]) {
5931         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
5932         my @cmd = (qw(sh -ec),
5933                    "echo $dsc_hash | git cat-file --batch-check");
5934         my $objgot = cmdoutput @cmd;
5935         if ($objgot =~ m#^\w+ missing\b#) {
5936             fail <<END
5937 .dsc contains Dgit field referring to object $dsc_hash
5938 Your git tree does not have that object.  Try `git fetch' from a
5939 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
5940 END
5941         }
5942         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
5943             if ($force > 0) {
5944                 progress "Not fast forward, forced update.";
5945             } else {
5946                 fail "Not fast forward to $dsc_hash";
5947             }
5948         }
5949         @cmd = (@git, qw(update-ref -m), "dgit import-dsc (Dgit): $info",
5950                 $dstbranch, $dsc_hash);
5951         runcmd @cmd;
5952         progress "dgit: import-dsc updated git ref $dstbranch";
5953         return 0;
5954     }
5955
5956     fail <<END
5957 Branch $dstbranch already exists
5958 Specify ..$specbranch for a pseudo-merge, binding in existing history
5959 Specify  +$specbranch to overwrite, discarding existing history
5960 END
5961         if $oldhash && !$force;
5962
5963     $package = getfield $dsc, 'Source';
5964     my @dfi = dsc_files_info();
5965     foreach my $fi (@dfi) {
5966         my $f = $fi->{Filename};
5967         my $here = "../$f";
5968         next if lstat $here;
5969         fail "stat $here: $!" unless $! == ENOENT;
5970         my $there = $dscfn;
5971         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
5972             $there = $';
5973         } elsif ($dscfn =~ m#^/#) {
5974             $there = $dscfn;
5975         } else {
5976             fail "cannot import $dscfn which seems to be inside working tree!";
5977         }
5978         $there =~ s#/+[^/]+$## or
5979             fail "cannot import $dscfn which seems to not have a basename";
5980         $there .= "/$f";
5981         symlink $there, $here or fail "symlink $there to $here: $!";
5982         progress "made symlink $here -> $there";
5983 #       print STDERR Dumper($fi);
5984     }
5985     my @mergeinputs = generate_commits_from_dsc();
5986     die unless @mergeinputs == 1;
5987
5988     my $newhash = $mergeinputs[0]{Commit};
5989
5990     if ($oldhash) {
5991         if ($force > 0) {
5992             progress "Import, forced update - synthetic orphan git history.";
5993         } elsif ($force < 0) {
5994             progress "Import, merging.";
5995             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
5996             my $version = getfield $dsc, 'Version';
5997             my $clogp = commit_getclogp $newhash;
5998             my $authline = clogp_authline $clogp;
5999             $newhash = make_commit_text <<END;
6000 tree $tree
6001 parent $newhash
6002 parent $oldhash
6003 author $authline
6004 committer $authline
6005
6006 Merge $package ($version) import into $dstbranch
6007 END
6008         } else {
6009             die; # caught earlier
6010         }
6011     }
6012
6013     my @cmd = (@git, qw(update-ref -m), "dgit import-dsc: $info",
6014                $dstbranch, $newhash);
6015     runcmd @cmd;
6016     progress "dgit: import-dsc results are in in git ref $dstbranch";
6017 }
6018
6019 sub cmd_archive_api_query {
6020     badusage "need only 1 subpath argument" unless @ARGV==1;
6021     my ($subpath) = @ARGV;
6022     my @cmd = archive_api_query_cmd($subpath);
6023     push @cmd, qw(-f);
6024     debugcmd ">",@cmd;
6025     exec @cmd or fail "exec curl: $!\n";
6026 }
6027
6028 sub cmd_clone_dgit_repos_server {
6029     badusage "need destination argument" unless @ARGV==1;
6030     my ($destdir) = @ARGV;
6031     $package = '_dgit-repos-server';
6032     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6033     debugcmd ">",@cmd;
6034     exec @cmd or fail "exec git clone: $!\n";
6035 }
6036
6037 sub cmd_setup_mergechangelogs {
6038     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6039     setup_mergechangelogs(1);
6040 }
6041
6042 sub cmd_setup_useremail {
6043     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6044     setup_useremail(1);
6045 }
6046
6047 sub cmd_setup_new_tree {
6048     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6049     setup_new_tree();
6050 }
6051
6052 #---------- argument parsing and main program ----------
6053
6054 sub cmd_version {
6055     print "dgit version $our_version\n" or die $!;
6056     exit 0;
6057 }
6058
6059 our (%valopts_long, %valopts_short);
6060 our @rvalopts;
6061
6062 sub defvalopt ($$$$) {
6063     my ($long,$short,$val_re,$how) = @_;
6064     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6065     $valopts_long{$long} = $oi;
6066     $valopts_short{$short} = $oi;
6067     # $how subref should:
6068     #   do whatever assignemnt or thing it likes with $_[0]
6069     #   if the option should not be passed on to remote, @rvalopts=()
6070     # or $how can be a scalar ref, meaning simply assign the value
6071 }
6072
6073 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6074 defvalopt '--distro',        '-d', '.+',      \$idistro;
6075 defvalopt '',                '-k', '.+',      \$keyid;
6076 defvalopt '--existing-package','', '.*',      \$existing_package;
6077 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6078 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6079 defvalopt '--package',   '-p',   $package_re, \$package;
6080 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6081
6082 defvalopt '', '-C', '.+', sub {
6083     ($changesfile) = (@_);
6084     if ($changesfile =~ s#^(.*)/##) {
6085         $buildproductsdir = $1;
6086     }
6087 };
6088
6089 defvalopt '--initiator-tempdir','','.*', sub {
6090     ($initiator_tempdir) = (@_);
6091     $initiator_tempdir =~ m#^/# or
6092         badusage "--initiator-tempdir must be used specify an".
6093         " absolute, not relative, directory."
6094 };
6095
6096 sub parseopts () {
6097     my $om;
6098
6099     if (defined $ENV{'DGIT_SSH'}) {
6100         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6101     } elsif (defined $ENV{'GIT_SSH'}) {
6102         @ssh = ($ENV{'GIT_SSH'});
6103     }
6104
6105     my $oi;
6106     my $val;
6107     my $valopt = sub {
6108         my ($what) = @_;
6109         @rvalopts = ($_);
6110         if (!defined $val) {
6111             badusage "$what needs a value" unless @ARGV;
6112             $val = shift @ARGV;
6113             push @rvalopts, $val;
6114         }
6115         badusage "bad value \`$val' for $what" unless
6116             $val =~ m/^$oi->{Re}$(?!\n)/s;
6117         my $how = $oi->{How};
6118         if (ref($how) eq 'SCALAR') {
6119             $$how = $val;
6120         } else {
6121             $how->($val);
6122         }
6123         push @ropts, @rvalopts;
6124     };
6125
6126     while (@ARGV) {
6127         last unless $ARGV[0] =~ m/^-/;
6128         $_ = shift @ARGV;
6129         last if m/^--?$/;
6130         if (m/^--/) {
6131             if (m/^--dry-run$/) {
6132                 push @ropts, $_;
6133                 $dryrun_level=2;
6134             } elsif (m/^--damp-run$/) {
6135                 push @ropts, $_;
6136                 $dryrun_level=1;
6137             } elsif (m/^--no-sign$/) {
6138                 push @ropts, $_;
6139                 $sign=0;
6140             } elsif (m/^--help$/) {
6141                 cmd_help();
6142             } elsif (m/^--version$/) {
6143                 cmd_version();
6144             } elsif (m/^--new$/) {
6145                 push @ropts, $_;
6146                 $new_package=1;
6147             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6148                      ($om = $opts_opt_map{$1}) &&
6149                      length $om->[0]) {
6150                 push @ropts, $_;
6151                 $om->[0] = $2;
6152             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6153                      !$opts_opt_cmdonly{$1} &&
6154                      ($om = $opts_opt_map{$1})) {
6155                 push @ropts, $_;
6156                 push @$om, $2;
6157             } elsif (m/^--(gbp|dpm)$/s) {
6158                 push @ropts, "--quilt=$1";
6159                 $quilt_mode = $1;
6160             } elsif (m/^--ignore-dirty$/s) {
6161                 push @ropts, $_;
6162                 $ignoredirty = 1;
6163             } elsif (m/^--no-quilt-fixup$/s) {
6164                 push @ropts, $_;
6165                 $quilt_mode = 'nocheck';
6166             } elsif (m/^--no-rm-on-error$/s) {
6167                 push @ropts, $_;
6168                 $rmonerror = 0;
6169             } elsif (m/^--overwrite$/s) {
6170                 push @ropts, $_;
6171                 $overwrite_version = '';
6172             } elsif (m/^--overwrite=(.+)$/s) {
6173                 push @ropts, $_;
6174                 $overwrite_version = $1;
6175             } elsif (m/^--dep14tag$/s) {
6176                 push @ropts, $_;
6177                 $dodep14tag= 'want';
6178             } elsif (m/^--no-dep14tag$/s) {
6179                 push @ropts, $_;
6180                 $dodep14tag= 'no';
6181             } elsif (m/^--always-dep14tag$/s) {
6182                 push @ropts, $_;
6183                 $dodep14tag= 'always';
6184             } elsif (m/^--delayed=(\d+)$/s) {
6185                 push @ropts, $_;
6186                 push @dput, $_;
6187             } elsif (m/^--dgit-view-save=(.+)$/s) {
6188                 push @ropts, $_;
6189                 $split_brain_save = $1;
6190                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6191             } elsif (m/^--(no-)?rm-old-changes$/s) {
6192                 push @ropts, $_;
6193                 $rmchanges = !$1;
6194             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6195                 push @ropts, $_;
6196                 push @deliberatelies, $&;
6197             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6198                 push @ropts, $&;
6199                 $forceopts{$1} = 1;
6200                 $_='';
6201             } elsif (m/^--force-/) {
6202                 print STDERR
6203                     "$us: warning: ignoring unknown force option $_\n";
6204                 $_='';
6205             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6206                 # undocumented, for testing
6207                 push @ropts, $_;
6208                 $tagformat_want = [ $1, 'command line', 1 ];
6209                 # 1 menas overrides distro configuration
6210             } elsif (m/^--always-split-source-build$/s) {
6211                 # undocumented, for testing
6212                 push @ropts, $_;
6213                 $need_split_build_invocation = 1;
6214             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6215                 $val = $2 ? $' : undef; #';
6216                 $valopt->($oi->{Long});
6217             } else {
6218                 badusage "unknown long option \`$_'";
6219             }
6220         } else {
6221             while (m/^-./s) {
6222                 if (s/^-n/-/) {
6223                     push @ropts, $&;
6224                     $dryrun_level=2;
6225                 } elsif (s/^-L/-/) {
6226                     push @ropts, $&;
6227                     $dryrun_level=1;
6228                 } elsif (s/^-h/-/) {
6229                     cmd_help();
6230                 } elsif (s/^-D/-/) {
6231                     push @ropts, $&;
6232                     $debuglevel++;
6233                     enabledebug();
6234                 } elsif (s/^-N/-/) {
6235                     push @ropts, $&;
6236                     $new_package=1;
6237                 } elsif (m/^-m/) {
6238                     push @ropts, $&;
6239                     push @changesopts, $_;
6240                     $_ = '';
6241                 } elsif (s/^-wn$//s) {
6242                     push @ropts, $&;
6243                     $cleanmode = 'none';
6244                 } elsif (s/^-wg$//s) {
6245                     push @ropts, $&;
6246                     $cleanmode = 'git';
6247                 } elsif (s/^-wgf$//s) {
6248                     push @ropts, $&;
6249                     $cleanmode = 'git-ff';
6250                 } elsif (s/^-wd$//s) {
6251                     push @ropts, $&;
6252                     $cleanmode = 'dpkg-source';
6253                 } elsif (s/^-wdd$//s) {
6254                     push @ropts, $&;
6255                     $cleanmode = 'dpkg-source-d';
6256                 } elsif (s/^-wc$//s) {
6257                     push @ropts, $&;
6258                     $cleanmode = 'check';
6259                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6260                     push @git, '-c', $&;
6261                     $gitcfgs{cmdline}{$1} = [ $2 ];
6262                 } elsif (s/^-c([^=]+)$//s) {
6263                     push @git, '-c', $&;
6264                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6265                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6266                     $val = $'; #';
6267                     $val = undef unless length $val;
6268                     $valopt->($oi->{Short});
6269                     $_ = '';
6270                 } else {
6271                     badusage "unknown short option \`$_'";
6272                 }
6273             }
6274         }
6275     }
6276 }
6277
6278 sub check_env_sanity () {
6279     my $blocked = new POSIX::SigSet;
6280     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6281
6282     eval {
6283         foreach my $name (qw(PIPE CHLD)) {
6284             my $signame = "SIG$name";
6285             my $signum = eval "POSIX::$signame" // die;
6286             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6287                 die "$signame is set to something other than SIG_DFL\n";
6288             $blocked->ismember($signum) and
6289                 die "$signame is blocked\n";
6290         }
6291     };
6292     return unless $@;
6293     chomp $@;
6294     fail <<END;
6295 On entry to dgit, $@
6296 This is a bug produced by something in in your execution environment.
6297 Giving up.
6298 END
6299 }
6300
6301
6302 sub parseopts_late_defaults () {
6303     foreach my $k (keys %opts_opt_map) {
6304         my $om = $opts_opt_map{$k};
6305
6306         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6307         if (defined $v) {
6308             badcfg "cannot set command for $k"
6309                 unless length $om->[0];
6310             $om->[0] = $v;
6311         }
6312
6313         foreach my $c (access_cfg_cfgs("opts-$k")) {
6314             my @vl =
6315                 map { $_ ? @$_ : () }
6316                 map { $gitcfgs{$_}{$c} }
6317                 reverse @gitcfgsources;
6318             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6319                 "\n" if $debuglevel >= 4;
6320             next unless @vl;
6321             badcfg "cannot configure options for $k"
6322                 if $opts_opt_cmdonly{$k};
6323             my $insertpos = $opts_cfg_insertpos{$k};
6324             @$om = ( @$om[0..$insertpos-1],
6325                      @vl,
6326                      @$om[$insertpos..$#$om] );
6327         }
6328     }
6329
6330     if (!defined $rmchanges) {
6331         local $access_forpush;
6332         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6333     }
6334
6335     if (!defined $quilt_mode) {
6336         local $access_forpush;
6337         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6338             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6339             // 'linear';
6340         $quilt_mode =~ m/^($quilt_modes_re)$/
6341             or badcfg "unknown quilt-mode \`$quilt_mode'";
6342         $quilt_mode = $1;
6343     }
6344
6345     if (!defined $dodep14tag) {
6346         local $access_forpush;
6347         $dodep14tag = access_cfg('dep14tag', 'RETURN-UNDEF') // 'want';
6348         $dodep14tag =~ m/^($dodep14tag_re)$/
6349             or badcfg "unknown dep14tag setting \`$dodep14tag'";
6350         $dodep14tag = $1;
6351     }
6352
6353     $need_split_build_invocation ||= quiltmode_splitbrain();
6354
6355     if (!defined $cleanmode) {
6356         local $access_forpush;
6357         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6358         $cleanmode //= 'dpkg-source';
6359
6360         badcfg "unknown clean-mode \`$cleanmode'" unless
6361             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6362     }
6363 }
6364
6365 if ($ENV{$fakeeditorenv}) {
6366     git_slurp_config();
6367     quilt_fixup_editor();
6368 }
6369
6370 parseopts();
6371 check_env_sanity();
6372 git_slurp_config();
6373
6374 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6375 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6376     if $dryrun_level == 1;
6377 if (!@ARGV) {
6378     print STDERR $helpmsg or die $!;
6379     exit 8;
6380 }
6381 my $cmd = shift @ARGV;
6382 $cmd =~ y/-/_/;
6383
6384 my $pre_fn = ${*::}{"pre_$cmd"};
6385 $pre_fn->() if $pre_fn;
6386
6387 my $fn = ${*::}{"cmd_$cmd"};
6388 $fn or badusage "unknown operation $cmd";
6389 $fn->();