dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Config;
  34
  35 our $our_version = 'UNRELEASED'; ###substituted###
  36
  37 our $rpushprotovsn = 2;
  38
  39 our $isuite = 'unstable';
  40 our $idistro;
  41 our $package;
  42 our @ropts;
  43
  44 our $sign = 1;
  45 our $dryrun_level = 0;
  46 our $changesfile;
  47 our $buildproductsdir = '..';
  48 our $new_package = 0;
  49 our $ignoredirty = 0;
  50 our $noquilt = 0;
  51 our $rmonerror = 1;
  52 our $existing_package = 'dpkg';
  53 our $cleanmode = 'dpkg-source';
  54 our $changes_since_version;
  55 our $we_are_responder;
  56 our $initiator_tempdir;
  57
  58 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  59
  60 our $suite_re = '[-+.0-9a-z]+';
  61
  62 our (@git) = qw(git);
  63 our (@dget) = qw(dget);
  64 our (@curl) = qw(curl -f);
  65 our (@dput) = qw(dput);
  66 our (@debsign) = qw(debsign);
  67 our (@gpg) = qw(gpg);
  68 our (@sbuild) = qw(sbuild -A);
  69 our (@ssh) = 'ssh';
  70 our (@dgit) = qw(dgit);
  71 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  72 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  73 our (@dpkggenchanges) = qw(dpkg-genchanges);
  74 our (@mergechanges) = qw(mergechanges -f);
  75 our (@changesopts) = ('');
  76
  77 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  78                      'curl' => \@curl,
  79                      'dput' => \@dput,
  80                      'debsign' => \@debsign,
  81                      'gpg' => \@gpg,
  82                      'sbuild' => \@sbuild,
  83                      'ssh' => \@ssh,
  84                      'dgit' => \@dgit,
  85                      'dpkg-source' => \@dpkgsource,
  86                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  87                      'dpkg-genchanges' => \@dpkggenchanges,
  88                      'ch' => \@changesopts,
  89                      'mergechanges' => \@mergechanges);
  90
  91 our %opts_opt_cmdonly = ('gpg' => 1);
  92
  93 our $keyid;
  94
  95 our $debug = 0;
  96 open DEBUG, ">/dev/null" or die $!;
  97
  98 autoflush STDOUT 1;
  99
 100 our $remotename = 'dgit';
 101 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 102 our $branchprefix = 'dgit';
 103 our $csuite;
 104
 105 sub lbranch () { return "$branchprefix/$csuite"; }
 106 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 107 sub lref () { return "refs/heads/".lbranch(); }
 108 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 109 sub rrref () { return "refs/$branchprefix/$csuite"; }
 110 sub debiantag ($) {
 111     my ($v) = @_;
 112     $v =~ y/~:/_%/;
 113     return "debian/$v";
 114 }
 115
 116 sub stripepoch ($) {
 117     my ($vsn) = @_;
 118     $vsn =~ s/^\d+\://;
 119     return $vsn;
 120 }
 121
 122 sub dscfn ($) {
 123     my ($vsn) = @_;
 124     return "${package}_".(stripepoch $vsn).".dsc";
 125 }
 126
 127 our $us = 'dgit';
 128 our $debugprefix = '';
 129
 130 our @end;
 131 END {
 132     local ($?);
 133     foreach my $f (@end) {
 134         eval { $f->(); };
 135         warn "$us: cleanup: $@" if length $@;
 136     }
 137 };
 138
 139 our @signames = split / /, $Config{sig_name};
 140
 141 sub waitstatusmsg () {
 142     if (!$?) {
 143         return "terminated, reporting successful completion";
 144     } elsif (!($? & 255)) {
 145         return "failed with error exit status ".WEXITSTATUS($?);
 146     } elsif (WIFSIGNALED($?)) {
 147         my $signum=WTERMSIG($?);
 148         return "died due to fatal signal ".
 149             ($signames[$signum] // "number $signum").
 150             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 151     } else {
 152         return "failed with unknown wait status ".$?;
 153     }
 154 }
 155
 156 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 157
 158 sub fail {
 159     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 160 }
 161
 162 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 163
 164 sub no_such_package () {
 165     print STDERR "$us: package $package does not exist in suite $isuite\n";
 166     exit 4;
 167 }
 168
 169 sub fetchspec () {
 170     local $csuite = '*';
 171     return  "+".rrref().":".lrref();
 172 }
 173
 174 sub changedir ($) {
 175     my ($newdir) = @_;
 176     printdebug "CD $newdir\n";
 177     chdir $newdir or die "chdir: $newdir: $!";
 178 }
 179
 180 sub stat_exists ($) {
 181     my ($f) = @_;
 182     return 1 if stat $f;
 183     return 0 if $!==&ENOENT;
 184     die "stat $f: $!";
 185 }
 186
 187 #---------- remote protocol support, common ----------
 188
 189 # remote push initiator/responder protocol:
 190 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 191 #
 192 #  > file parsed-changelog
 193 #  [indicates that output of dpkg-parsechangelog follows]
 194 #  > data-block NBYTES
 195 #  > [NBYTES bytes of data (no newline)]
 196 #  [maybe some more blocks]
 197 #  > data-end
 198 #
 199 #  > file dsc
 200 #  [etc]
 201 #
 202 #  > file changes
 203 #  [etc]
 204 #
 205 #  > param head HEAD
 206 #
 207 #  > want signed-tag
 208 #  [indicates that signed tag is wanted]
 209 #  < data-block NBYTES
 210 #  < [NBYTES bytes of data (no newline)]
 211 #  [maybe some more blocks]
 212 #  < data-end
 213 #  < files-end
 214 #
 215 #  > want signed-dsc-changes
 216 #  < data-block NBYTES    [transfer of signed dsc]
 217 #  [etc]
 218 #  < data-block NBYTES    [transfer of signed changes]
 219 #  [etc]
 220 #  < files-end
 221 #
 222 #  > complete
 223
 224 our $i_child_pid;
 225
 226 sub i_child_report () {
 227     # Sees if our child has died, and reap it if so.  Returns a string
 228     # describing how it died if it failed, or undef otherwise.
 229     return undef unless $i_child_pid;
 230     my $got = waitpid $i_child_pid, WNOHANG;
 231     return undef if $got <= 0;
 232     die unless $got == $i_child_pid;
 233     $i_child_pid = undef;
 234     return undef unless $?;
 235     return "build host child ".waitstatusmsg();
 236 }
 237
 238 sub badproto ($$) {
 239     my ($fh, $m) = @_;
 240     fail "connection lost: $!" if $fh->error;
 241     fail "protocol violation; $m not expected";
 242 }
 243
 244 sub badproto_badread ($$) {
 245     my ($fh, $wh) = @_;
 246     fail "connection lost: $!" if $!;
 247     my $report = i_child_report();
 248     fail $report if defined $report;
 249     badproto $fh, "eof (reading $wh)";
 250 }
 251
 252 sub protocol_expect (&$) {
 253     my ($match, $fh) = @_;
 254     local $_;
 255     $_ = <$fh>;
 256     defined && chomp or badproto_badread $fh, "protocol message";
 257     if (wantarray) {
 258         my @r = &$match;
 259         return @r if @r;
 260     } else {
 261         my $r = &$match;
 262         return $r if $r;
 263     }
 264     badproto $fh, "\`$_'";
 265 }
 266
 267 sub protocol_send_file ($$) {
 268     my ($fh, $ourfn) = @_;
 269     open PF, "<", $ourfn or die "$ourfn: $!";
 270     for (;;) {
 271         my $d;
 272         my $got = read PF, $d, 65536;
 273         die "$ourfn: $!" unless defined $got;
 274         last if !$got;
 275         print $fh "data-block ".length($d)."\n" or die $!;
 276         print $fh $d or die $!;
 277     }
 278     PF->error and die "$ourfn $!";
 279     print $fh "data-end\n" or die $!;
 280     close PF;
 281 }
 282
 283 sub protocol_read_bytes ($$) {
 284     my ($fh, $nbytes) = @_;
 285     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 286     my $d;
 287     my $got = read $fh, $d, $nbytes;
 288     $got==$nbytes or badproto_badread $fh, "data block";
 289     return $d;
 290 }
 291
 292 sub protocol_receive_file ($$) {
 293     my ($fh, $ourfn) = @_;
 294     printdebug "() $ourfn\n";
 295     open PF, ">", $ourfn or die "$ourfn: $!";
 296     for (;;) {
 297         my ($y,$l) = protocol_expect {
 298             m/^data-block (.*)$/ ? (1,$1) :
 299             m/^data-end$/ ? (0,) :
 300             ();
 301         } $fh;
 302         last unless $y;
 303         my $d = protocol_read_bytes $fh, $l;
 304         print PF $d or die $!;
 305     }
 306     close PF or die $!;
 307 }
 308
 309 #---------- remote protocol support, responder ----------
 310
 311 sub responder_send_command ($) {
 312     my ($command) = @_;
 313     return unless $we_are_responder;
 314     # called even without $we_are_responder
 315     printdebug ">> $command\n";
 316     print PO $command, "\n" or die $!;
 317 }
 318
 319 sub responder_send_file ($$) {
 320     my ($keyword, $ourfn) = @_;
 321     return unless $we_are_responder;
 322     printdebug "]] $keyword $ourfn\n";
 323     responder_send_command "file $keyword";
 324     protocol_send_file \*PO, $ourfn;
 325 }
 326
 327 sub responder_receive_files ($@) {
 328     my ($keyword, @ourfns) = @_;
 329     die unless $we_are_responder;
 330     printdebug "[[ $keyword @ourfns\n";
 331     responder_send_command "want $keyword";
 332     foreach my $fn (@ourfns) {
 333         protocol_receive_file \*PI, $fn;
 334     }
 335     printdebug "[[\$\n";
 336     protocol_expect { m/^files-end$/ } \*PI;
 337 }
 338
 339 #---------- remote protocol support, initiator ----------
 340
 341 sub initiator_expect (&) {
 342     my ($match) = @_;
 343     protocol_expect { &$match } \*RO;
 344 }
 345
 346 #---------- end remote code ----------
 347
 348 sub progress {
 349     if ($we_are_responder) {
 350         my $m = join '', @_;
 351         responder_send_command "progress ".length($m) or die $!;
 352         print PO $m or die $!;
 353     } else {
 354         print @_, "\n";
 355     }
 356 }
 357
 358 our $ua;
 359
 360 sub url_get {
 361     if (!$ua) {
 362         $ua = LWP::UserAgent->new();
 363         $ua->env_proxy;
 364     }
 365     my $what = $_[$#_];
 366     progress "downloading $what...";
 367     my $r = $ua->get(@_) or die $!;
 368     return undef if $r->code == 404;
 369     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 370     return $r->decoded_content(charset => 'none');
 371 }
 372
 373 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 374
 375 sub shellquote {
 376     my @out;
 377     local $_;
 378     foreach my $a (@_) {
 379         $_ = $a;
 380         if (m{[^-=_./0-9a-z]}i) {
 381             s{['\\]}{'\\$&'}g;
 382             push @out, "'$_'";
 383         } else {
 384             push @out, $_;
 385         }
 386     }
 387     return join ' ', @out;
 388 }
 389
 390 sub printcmd {
 391     my $fh = shift @_;
 392     my $intro = shift @_;
 393     print $fh $intro," " or die $!;
 394     print $fh shellquote @_ or die $!;
 395     print $fh "\n" or die $!;
 396 }
 397
 398 sub failedcmd {
 399     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 400     if ($!) {
 401         fail "failed to fork/exec: $!";
 402     } elsif ($?) {
 403         fail "subprocess ".waitstatusmsg();
 404     } else {
 405         fail "subprocess produced invalid output";
 406     }
 407 }
 408
 409 sub runcmd {
 410     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 411     $!=0; $?=0;
 412     failedcmd @_ if system @_;
 413 }
 414
 415 sub act_local () { return $dryrun_level <= 1; }
 416 sub act_scary () { return !$dryrun_level; }
 417
 418 sub printdone {
 419     if (!$dryrun_level) {
 420         progress "dgit ok: @_";
 421     } else {
 422         progress "would be ok: @_ (but dry run only)";
 423     }
 424 }
 425
 426 sub cmdoutput_errok {
 427     die Dumper(\@_)." ?" if grep { !defined } @_;
 428     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 429     open P, "-|", @_ or die $!;
 430     my $d;
 431     $!=0; $?=0;
 432     { local $/ = undef; $d = <P>; }
 433     die $! if P->error;
 434     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 435     chomp $d;
 436     $d =~ m/^.*/;
 437     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 438     return $d;
 439 }
 440
 441 sub cmdoutput {
 442     my $d = cmdoutput_errok @_;
 443     defined $d or failedcmd @_;
 444     return $d;
 445 }
 446
 447 sub dryrun_report {
 448     printcmd(\*STDERR,$debugprefix."#",@_);
 449 }
 450
 451 sub runcmd_ordryrun {
 452     if (act_scary()) {
 453         runcmd @_;
 454     } else {
 455         dryrun_report @_;
 456     }
 457 }
 458
 459 sub runcmd_ordryrun_local {
 460     if (act_local()) {
 461         runcmd @_;
 462     } else {
 463         dryrun_report @_;
 464     }
 465 }
 466
 467 sub shell_cmd {
 468     my ($first_shell, @cmd) = @_;
 469     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 470 }
 471
 472 our $helpmsg = <<END;
 473 main usages:
 474   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 475   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 476   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 477   dgit [dgit-opts] push [dgit-opts] [suite]
 478   dgit [dgit-opts] rpush build-host:build-dir ...
 479 important dgit options:
 480   -k<keyid>           sign tag and package with <keyid> instead of default
 481   --dry-run -n        do not change anything, but go through the motions
 482   --damp-run -L       like --dry-run but make local changes, without signing
 483   --new -N            allow introducing a new package
 484   --debug -D          increase debug level
 485   -c<name>=<value>    set git config option (used directly by dgit too)
 486 END
 487
 488 our $later_warning_msg = <<END;
 489 Perhaps the upload is stuck in incoming.  Using the version from git.
 490 END
 491
 492 sub badusage {
 493     print STDERR "$us: @_\n", $helpmsg or die $!;
 494     exit 8;
 495 }
 496
 497 sub nextarg {
 498     @ARGV or badusage "too few arguments";
 499     return scalar shift @ARGV;
 500 }
 501
 502 sub cmd_help () {
 503     print $helpmsg or die $!;
 504     exit 0;
 505 }
 506
 507 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 508
 509 our %defcfg = ('dgit.default.distro' => 'debian',
 510                'dgit.default.username' => '',
 511                'dgit.default.archive-query-default-component' => 'main',
 512                'dgit.default.ssh' => 'ssh',
 513                'dgit-distro.debian.git-host' => 'git.debian.org',
 514                'dgit-distro.debian.git-proto' => 'git+ssh://',
 515                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 516                'dgit-distro.debian.git-check' => 'ssh-cmd',
 517                'dgit-distro.debian.git-create' => 'ssh-cmd',
 518                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 519                'dgit-distro.debian.sshpsql-dbname' => 'service=projectb',
 520                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 521                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 522  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 523  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 524                'dgit-distro.ubuntu.git-check' => 'false',
 525  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 526                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 527                'dgit-distro.test-dummy.username' => "alice",
 528                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 529                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 530                'dgit-distro.test-dummy.git-url' => "$td/git",
 531                'dgit-distro.test-dummy.git-host' => "git",
 532                'dgit-distro.test-dummy.git-path' => "$td/git",
 533                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 534                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 535                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 536                );
 537
 538 sub cfg {
 539     foreach my $c (@_) {
 540         return undef if $c =~ /RETURN-UNDEF/;
 541         my @cmd = (@git, qw(config --), $c);
 542         my $v;
 543         {
 544             local ($debug) = $debug-1;
 545             $v = cmdoutput_errok @cmd;
 546         };
 547         if ($?==0) {
 548             return $v;
 549         } elsif ($?!=256) {
 550             failedcmd @cmd;
 551         }
 552         my $dv = $defcfg{$c};
 553         return $dv if defined $dv;
 554     }
 555     badcfg "need value for one of: @_\n".
 556         "$us: distro or suite appears not to be (properly) supported";
 557 }
 558
 559 sub access_basedistro () {
 560     if (defined $idistro) {
 561         return cfg("dgit-distro.basedistro.distro",
 562                    "dgit-suite.$isuite.distro",
 563                    'RETURN-UNDEF') // $idistro;
 564     } else {
 565         return cfg("dgit-suite.$isuite.distro",
 566                    "dgit.default.distro");
 567     }
 568 }
 569
 570 sub access_quirk () {
 571     # returns (quirk name, distro to use instead, quirk-specific info)
 572     my $basedistro = access_basedistro();
 573     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 574                               'RETURN-UNDEF');
 575     if (defined $backports_quirk) {
 576         my $re = $backports_quirk;
 577         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 578         $re =~ s/\*/.*/g;
 579         $re =~ s/\%/([-0-9a-z_]+)/
 580             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 581         if ($isuite =~ m/^$re$/) {
 582             return ('backports',"$basedistro-backports",$1);
 583         }
 584     }
 585     return ('none',$basedistro);
 586 }
 587
 588 sub access_distro () {
 589     return (access_quirk())[1];
 590 }
 591
 592 sub access_cfg (@) {
 593     my (@keys) = @_;
 594     my $basedistro = access_basedistro();
 595     my $distro = $idistro || access_distro();
 596     my $value = cfg(map {
 597         ("dgit-distro.$distro.$_",
 598          "dgit-distro.$basedistro.$_",
 599          "dgit.default.$_")
 600                     } @keys);
 601     return $value;
 602 }
 603
 604 sub string_to_ssh ($) {
 605     my ($spec) = @_;
 606     if ($spec =~ m/\s/) {
 607         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 608     } else {
 609         return ($spec);
 610     }
 611 }
 612
 613 sub access_cfg_ssh () {
 614     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 615     if (!defined $gitssh) {
 616         return @ssh;
 617     } else {
 618         return string_to_ssh $gitssh;
 619     }
 620 }
 621
 622 sub access_someuserhost ($) {
 623     my ($some) = @_;
 624     my $user = access_cfg("$some-user",'username');
 625     my $host = access_cfg("$some-host");
 626     return length($user) ? "$user\@$host" : $host;
 627 }
 628
 629 sub access_gituserhost () {
 630     return access_someuserhost('git');
 631 }
 632
 633 sub access_giturl () {
 634     my $url = access_cfg('git-url','RETURN-UNDEF');
 635     if (!defined $url) {
 636         $url =
 637             access_cfg('git-proto').
 638             access_gituserhost().
 639             access_cfg('git-path');
 640     }
 641     return "$url/$package.git";
 642 }
 643
 644 sub parsecontrolfh ($$;$) {
 645     my ($fh, $desc, $allowsigned) = @_;
 646     our $dpkgcontrolhash_noissigned;
 647     my $c;
 648     for (;;) {
 649         my %opts = ('name' => $desc);
 650         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 651         $c = Dpkg::Control::Hash->new(%opts);
 652         $c->parse($fh,$desc) or die "parsing of $desc failed";
 653         last if $allowsigned;
 654         last if $dpkgcontrolhash_noissigned;
 655         my $issigned= $c->get_option('is_pgp_signed');
 656         if (!defined $issigned) {
 657             $dpkgcontrolhash_noissigned= 1;
 658             seek $fh, 0,0 or die "seek $desc: $!";
 659         } elsif ($issigned) {
 660             fail "control file $desc is (already) PGP-signed. ".
 661                 " Note that dgit push needs to modify the .dsc and then".
 662                 " do the signature itself";
 663         } else {
 664             last;
 665         }
 666     }
 667     return $c;
 668 }
 669
 670 sub parsecontrol {
 671     my ($file, $desc) = @_;
 672     my $fh = new IO::Handle;
 673     open $fh, '<', $file or die "$file: $!";
 674     my $c = parsecontrolfh($fh,$desc);
 675     $fh->error and die $!;
 676     close $fh;
 677     return $c;
 678 }
 679
 680 sub getfield ($$) {
 681     my ($dctrl,$field) = @_;
 682     my $v = $dctrl->{$field};
 683     return $v if defined $v;
 684     fail "missing field $field in ".$v->get_option('name');
 685 }
 686
 687 sub parsechangelog {
 688     my $c = Dpkg::Control::Hash->new();
 689     my $p = new IO::Handle;
 690     my @cmd = (qw(dpkg-parsechangelog), @_);
 691     open $p, '-|', @cmd or die $!;
 692     $c->parse($p);
 693     $?=0; $!=0; close $p or failedcmd @cmd;
 694     return $c;
 695 }
 696
 697 sub git_get_ref ($) {
 698     my ($refname) = @_;
 699     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 700     if (!defined $got) {
 701         $?==256 or fail "git show-ref failed (status $?)";
 702         printdebug "ref $refname= [show-ref exited 1]\n";
 703         return '';
 704     }
 705     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 706         printdebug "ref $refname=$1\n";
 707         return $1;
 708     } else {
 709         printdebug "ref $refname= [no match]\n";
 710         return '';
 711     }
 712 }
 713
 714 sub must_getcwd () {
 715     my $d = getcwd();
 716     defined $d or fail "getcwd failed: $!";
 717     return $d;
 718 }
 719
 720 our %rmad;
 721
 722 sub archive_query ($) {
 723     my ($method) = @_;
 724     my $query = access_cfg('archive-query','RETURN-UNDEF');
 725     if (!defined $query) {
 726         my $distro = access_basedistro();
 727         if ($distro eq 'debian') {
 728             $query = "sshpsql:".
 729                 access_someuserhost('sshpsql').':'.
 730                 access_cfg('sshpsql-dbname');
 731         } else {
 732             $query = "madison:$distro";
 733         }
 734     }
 735     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 736     my $proto = $1;
 737     my $data = $'; #';
 738     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 739 }
 740
 741 sub pool_dsc_subpath ($$) {
 742     my ($vsn,$component) = @_; # $package is implict arg
 743     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 744     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 745 }
 746
 747 sub archive_query_madison ($$) {
 748     my ($proto,$data) = @_;
 749     die unless $proto eq 'madison';
 750     $rmad{$package} ||= cmdoutput
 751         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 752     my $rmad = $rmad{$package};
 753     return madison_parse($rmad);
 754 }
 755
 756 sub madison_parse ($) {
 757     my ($rmad) = @_;
 758     my @out;
 759     foreach my $l (split /\n/, $rmad) {
 760         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 761                   \s*( [^ \t|]+ )\s* \|
 762                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 763                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 764         $1 eq $package or die "$rmad $package ?";
 765         my $vsn = $2;
 766         my $newsuite = $3;
 767         my $component;
 768         if (defined $4) {
 769             $component = $4;
 770         } else {
 771             $component = access_cfg('archive-query-default-component');
 772         }
 773         $5 eq 'source' or die "$rmad ?";
 774         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 775     }
 776     return sort { -version_compare($a->[0],$b->[0]); } @out;
 777 }
 778
 779 sub canonicalise_suite_madison ($$) {
 780     # madison canonicalises for us
 781     my @r = archive_query_madison($_[0],$_[1]);
 782     @r or fail
 783         "unable to canonicalise suite using package $package".
 784         " which does not appear to exist in suite $isuite;".
 785         " --existing-package may help";
 786     return $r[0][2];
 787 }
 788
 789 sub sshpsql ($$) {
 790     my ($data,$sql) = @_;
 791     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 792     my ($userhost,$dbname) = ($`,$'); #';
 793     my @rows;
 794     my @cmd = (access_cfg_ssh, $userhost,
 795                "export LANG=C; ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 796     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 797     open P, "-|", @cmd or die $!;
 798     while (<P>) {
 799         chomp or die;
 800         printdebug("$debugprefix>|$_|\n");
 801         push @rows, $_;
 802     }
 803     $!=0; $?=0; close P or failedcmd @cmd;
 804     @rows or die;
 805     my $nrows = pop @rows;
 806     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 807     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 808     @rows = map { [ split /\|/, $_ ] } @rows;
 809     my $ncols = scalar @{ shift @rows };
 810     die if grep { scalar @$_ != $ncols } @rows;
 811     return @rows;
 812 }
 813
 814 sub sql_injection_check {
 815     foreach (@_) { die "$_ $& ?" if m/[']/; }
 816 }
 817
 818 sub archive_query_sshpsql ($$) {
 819     my ($proto,$data) = @_;
 820     sql_injection_check $isuite, $package;
 821     my @rows = sshpsql($data, <<END);
 822         SELECT source.version, component.name, files.filename, files.sha256sum
 823           FROM source
 824           JOIN src_associations ON source.id = src_associations.source
 825           JOIN suite ON suite.id = src_associations.suite
 826           JOIN dsc_files ON dsc_files.source = source.id
 827           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 828           JOIN component ON component.id = files_archive_map.component_id
 829           JOIN files ON files.id = dsc_files.file
 830          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 831            AND source.source='$package'
 832            AND files.filename LIKE '%.dsc';
 833 END
 834     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 835     my $digester = Digest::SHA->new(256);
 836     @rows = map {
 837         my ($vsn,$component,$filename,$sha256sum) = @$_;
 838         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 839     } @rows;
 840     return @rows;
 841 }
 842
 843 sub canonicalise_suite_sshpsql ($$) {
 844     my ($proto,$data) = @_;
 845     sql_injection_check $isuite;
 846     my @rows = sshpsql($data, <<END);
 847         SELECT suite.codename
 848           FROM suite where suite_name='$isuite' or codename='$isuite';
 849 END
 850     @rows = map { $_->[0] } @rows;
 851     fail "unknown suite $isuite" unless @rows;
 852     die "ambiguous $isuite: @rows ?" if @rows>1;
 853     return $rows[0];
 854 }
 855
 856 sub canonicalise_suite_dummycat ($$) {
 857     my ($proto,$data) = @_;
 858     my $dpath = "$data/suite.$isuite";
 859     if (!open C, "<", $dpath) {
 860         $!==ENOENT or die "$dpath: $!";
 861         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 862         return $isuite;
 863     }
 864     $!=0; $_ = <C>;
 865     chomp or die "$dpath: $!";
 866     close C;
 867     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 868     return $_;
 869 }
 870
 871 sub archive_query_dummycat ($$) {
 872     my ($proto,$data) = @_;
 873     canonicalise_suite();
 874     my $dpath = "$data/package.$csuite.$package";
 875     if (!open C, "<", $dpath) {
 876         $!==ENOENT or die "$dpath: $!";
 877         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 878         return ();
 879     }
 880     my @rows;
 881     while (<C>) {
 882         next if m/^\#/;
 883         next unless m/\S/;
 884         die unless chomp;
 885         printdebug "dummycat query $csuite $package $dpath | $_\n";
 886         my @row = split /\s+/, $_;
 887         @row==2 or die "$dpath: $_ ?";
 888         push @rows, \@row;
 889     }
 890     C->error and die "$dpath: $!";
 891     close C;
 892     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 893 }
 894
 895 sub canonicalise_suite () {
 896     return if defined $csuite;
 897     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 898     $csuite = archive_query('canonicalise_suite');
 899     if ($isuite ne $csuite) {
 900         progress "canonical suite name for $isuite is $csuite";
 901     }
 902 }
 903
 904 sub get_archive_dsc () {
 905     canonicalise_suite();
 906     my @vsns = archive_query('archive_query');
 907     foreach my $vinfo (@vsns) {
 908         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 909         $dscurl = access_cfg('mirror').$subpath;
 910         $dscdata = url_get($dscurl);
 911         if (!$dscdata) {
 912             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 913             next;
 914         }
 915         if ($digester) {
 916             $digester->reset();
 917             $digester->add($dscdata);
 918             my $got = $digester->hexdigest();
 919             $got eq $digest or
 920                 fail "$dscurl has hash $got but".
 921                     " archive told us to expect $digest";
 922         }
 923         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 924         printdebug Dumper($dscdata) if $debug>1;
 925         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 926         printdebug Dumper($dsc) if $debug>1;
 927         my $fmt = getfield $dsc, 'Format';
 928         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 929         $dsc_checked = !!$digester;
 930         return;
 931     }
 932     $dsc = undef;
 933 }
 934
 935 sub check_for_git () {
 936     # returns 0 or 1
 937     my $how = access_cfg('git-check');
 938     if ($how eq 'ssh-cmd') {
 939         my @cmd =
 940             (access_cfg_ssh, access_gituserhost(),
 941              " set -e; cd ".access_cfg('git-path').";".
 942              " if test -d $package.git; then echo 1; else echo 0; fi");
 943         my $r= cmdoutput @cmd;
 944         failedcmd @cmd unless $r =~ m/^[01]$/;
 945         return $r+0;
 946     } elsif ($how eq 'true') {
 947         return 1;
 948     } elsif ($how eq 'false') {
 949         return 0;
 950     } else {
 951         badcfg "unknown git-check \`$how'";
 952     }
 953 }
 954
 955 sub create_remote_git_repo () {
 956     my $how = access_cfg('git-create');
 957     if ($how eq 'ssh-cmd') {
 958         runcmd_ordryrun
 959             (access_cfg_ssh, access_gituserhost(),
 960              "set -e; cd ".access_cfg('git-path').";".
 961              " cp -a _template $package.git");
 962     } elsif ($how eq 'true') {
 963         # nothing to do
 964     } else {
 965         badcfg "unknown git-create \`$how'";
 966     }
 967 }
 968
 969 our ($dsc_hash,$lastpush_hash);
 970
 971 our $ud = '.git/dgit/unpack';
 972
 973 sub prep_ud () {
 974     rmtree($ud);
 975     mkpath '.git/dgit';
 976     mkdir $ud or die $!;
 977 }
 978
 979 sub mktree_in_ud_here () {
 980     runcmd qw(git init -q);
 981     rmtree('.git/objects');
 982     symlink '../../../../objects','.git/objects' or die $!;
 983 }
 984
 985 sub mktree_in_ud_from_only_subdir () {
 986     # changes into the subdir
 987     my (@dirs) = <*/.>;
 988     die unless @dirs==1;
 989     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 990     my $dir = $1;
 991     changedir $dir;
 992     fail "source package contains .git directory" if stat_exists '.git';
 993     mktree_in_ud_here();
 994     runcmd @git, qw(add -Af);
 995     my $tree = cmdoutput @git, qw(write-tree);
 996     $tree =~ m/^\w+$/ or die "$tree ?";
 997     return ($tree,$dir);
 998 }
 999
1000 sub dsc_files_info () {
1001     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1002                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1003                        ['Files',           'Digest::MD5', 'new()']) {
1004         my ($fname, $module, $method) = @$csumi;
1005         my $field = $dsc->{$fname};
1006         next unless defined $field;
1007         eval "use $module; 1;" or die $@;
1008         my @out;
1009         foreach (split /\n/, $field) {
1010             next unless m/\S/;
1011             m/^(\w+) (\d+) (\S+)$/ or
1012                 fail "could not parse .dsc $fname line \`$_'";
1013             my $digester = eval "$module"."->$method;" or die $@;
1014             push @out, {
1015                 Hash => $1,
1016                 Bytes => $2,
1017                 Filename => $3,
1018                 Digester => $digester,
1019             };
1020         }
1021         return @out;
1022     }
1023     fail "missing any supported Checksums-* or Files field in ".
1024         $dsc->get_option('name');
1025 }
1026
1027 sub dsc_files () {
1028     map { $_->{Filename} } dsc_files_info();
1029 }
1030
1031 sub is_orig_file ($;$) {
1032     local ($_) = $_[0];
1033     my $base = $_[1];
1034     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1035     defined $base or return 1;
1036     return $` eq $base;
1037 }
1038
1039 sub make_commit ($) {
1040     my ($file) = @_;
1041     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1042 }
1043
1044 sub clogp_authline ($) {
1045     my ($clogp) = @_;
1046     my $author = getfield $clogp, 'Maintainer';
1047     $author =~ s#,.*##ms;
1048     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1049     my $authline = "$author $date";
1050     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1051         fail "unexpected commit author line format \`$authline'".
1052         " (was generated from changelog Maintainer field)";
1053     return $authline;
1054 }
1055
1056 sub generate_commit_from_dsc () {
1057     prep_ud();
1058     changedir $ud;
1059
1060     foreach my $fi (dsc_files_info()) {
1061         my $f = $fi->{Filename};
1062         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1063
1064         link "../../../$f", $f
1065             or $!==&ENOENT
1066             or die "$f $!";
1067
1068         complete_file_from_dsc('.', $fi);
1069
1070         if (is_orig_file($f)) {
1071             link $f, "../../../../$f"
1072                 or $!==&EEXIST
1073                 or die "$f $!";
1074         }
1075     }
1076
1077     my $dscfn = "$package.dsc";
1078
1079     open D, ">", $dscfn or die "$dscfn: $!";
1080     print D $dscdata or die "$dscfn: $!";
1081     close D or die "$dscfn: $!";
1082     my @cmd = qw(dpkg-source);
1083     push @cmd, '--no-check' if $dsc_checked;
1084     push @cmd, qw(-x --), $dscfn;
1085     runcmd @cmd;
1086
1087     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1088     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1089     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1090     my $authline = clogp_authline $clogp;
1091     my $changes = getfield $clogp, 'Changes';
1092     open C, ">../commit.tmp" or die $!;
1093     print C <<END or die $!;
1094 tree $tree
1095 author $authline
1096 committer $authline
1097
1098 $changes
1099
1100 # imported from the archive
1101 END
1102     close C or die $!;
1103     my $outputhash = make_commit qw(../commit.tmp);
1104     my $cversion = getfield $clogp, 'Version';
1105     progress "synthesised git commit from .dsc $cversion";
1106     if ($lastpush_hash) {
1107         runcmd @git, qw(reset --hard), $lastpush_hash;
1108         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1109         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1110         my $oversion = getfield $oldclogp, 'Version';
1111         my $vcmp =
1112             version_compare($oversion, $cversion);
1113         if ($vcmp < 0) {
1114             # git upload/ is earlier vsn than archive, use archive
1115             open C, ">../commit2.tmp" or die $!;
1116             print C <<END or die $!;
1117 tree $tree
1118 parent $lastpush_hash
1119 parent $outputhash
1120 author $authline
1121 committer $authline
1122
1123 Record $package ($cversion) in archive suite $csuite
1124 END
1125             $outputhash = make_commit qw(../commit2.tmp);
1126         } elsif ($vcmp > 0) {
1127             print STDERR <<END or die $!;
1128
1129 Version actually in archive:    $cversion (older)
1130 Last allegedly pushed/uploaded: $oversion (newer or same)
1131 $later_warning_msg
1132 END
1133             $outputhash = $lastpush_hash;
1134         } else {
1135             $outputhash = $lastpush_hash;
1136         }
1137     }
1138     changedir '../../../..';
1139     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1140             'DGIT_ARCHIVE', $outputhash;
1141     cmdoutput @git, qw(log -n2), $outputhash;
1142     # ... gives git a chance to complain if our commit is malformed
1143     rmtree($ud);
1144     return $outputhash;
1145 }
1146
1147 sub complete_file_from_dsc ($$) {
1148     our ($dstdir, $fi) = @_;
1149     # Ensures that we have, in $dir, the file $fi, with the correct
1150     # contents.  (Downloading it from alongside $dscurl if necessary.)
1151
1152     my $f = $fi->{Filename};
1153     my $tf = "$dstdir/$f";
1154     my $downloaded = 0;
1155
1156     if (stat_exists $tf) {
1157         progress "using existing $f";
1158     } else {
1159         my $furl = $dscurl;
1160         $furl =~ s{/[^/]+$}{};
1161         $furl .= "/$f";
1162         die "$f ?" unless $f =~ m/^${package}_/;
1163         die "$f ?" if $f =~ m#/#;
1164         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1165         next if !act_local();
1166         $downloaded = 1;
1167     }
1168
1169     open F, "<", "$tf" or die "$tf: $!";
1170     $fi->{Digester}->reset();
1171     $fi->{Digester}->addfile(*F);
1172     F->error and die $!;
1173     my $got = $fi->{Digester}->hexdigest();
1174     $got eq $fi->{Hash} or
1175         fail "file $f has hash $got but .dsc".
1176             " demands hash $fi->{Hash} ".
1177             ($downloaded ? "(got wrong file from archive!)"
1178              : "(perhaps you should delete this file?)");
1179 }
1180
1181 sub ensure_we_have_orig () {
1182     foreach my $fi (dsc_files_info()) {
1183         my $f = $fi->{Filename};
1184         next unless is_orig_file($f);
1185         complete_file_from_dsc('..', $fi);
1186     }
1187 }
1188
1189 sub rev_parse ($) {
1190     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1191 }
1192
1193 sub is_fast_fwd ($$) {
1194     my ($ancestor,$child) = @_;
1195     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1196     my $mb = cmdoutput_errok @cmd;
1197     if (defined $mb) {
1198         return rev_parse($mb) eq rev_parse($ancestor);
1199     } else {
1200         $?==256 or failedcmd @cmd;
1201         return 0;
1202     }
1203 }
1204
1205 sub git_fetch_us () {
1206     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1207 }
1208
1209 sub fetch_from_archive () {
1210     # ensures that lrref() is what is actually in the archive,
1211     #  one way or another
1212     get_archive_dsc();
1213
1214     if ($dsc) {
1215         foreach my $field (@ourdscfield) {
1216             $dsc_hash = $dsc->{$field};
1217             last if defined $dsc_hash;
1218         }
1219         if (defined $dsc_hash) {
1220             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1221             $dsc_hash = $&;
1222             progress "last upload to archive specified git hash";
1223         } else {
1224             progress "last upload to archive has NO git hash";
1225         }
1226     } else {
1227         progress "no version available from the archive";
1228     }
1229
1230     $lastpush_hash = git_get_ref(lrref());
1231     printdebug "previous reference hash=$lastpush_hash\n";
1232     my $hash;
1233     if (defined $dsc_hash) {
1234         fail "missing remote git history even though dsc has hash -".
1235             " could not find ref ".lrref().
1236             " (should have been fetched from ".access_giturl()."#".rrref().")"
1237             unless $lastpush_hash;
1238         $hash = $dsc_hash;
1239         ensure_we_have_orig();
1240         if ($dsc_hash eq $lastpush_hash) {
1241         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1242             print STDERR <<END or die $!;
1243
1244 Git commit in archive is behind the last version allegedly pushed/uploaded.
1245 Commit referred to by archive:  $dsc_hash
1246 Last allegedly pushed/uploaded: $lastpush_hash
1247 $later_warning_msg
1248 END
1249             $hash = $lastpush_hash;
1250         } else {
1251             fail "archive's .dsc refers to ".$dsc_hash.
1252                 " but this is an ancestor of ".$lastpush_hash;
1253         }
1254     } elsif ($dsc) {
1255         $hash = generate_commit_from_dsc();
1256     } elsif ($lastpush_hash) {
1257         # only in git, not in the archive yet
1258         $hash = $lastpush_hash;
1259         print STDERR <<END or die $!;
1260
1261 Package not found in the archive, but has allegedly been pushed using dgit.
1262 $later_warning_msg
1263 END
1264     } else {
1265         printdebug "nothing found!\n";
1266         if (defined $skew_warning_vsn) {
1267             print STDERR <<END or die $!;
1268
1269 Warning: relevant archive skew detected.
1270 Archive allegedly contains $skew_warning_vsn
1271 But we were not able to obtain any version from the archive or git.
1272
1273 END
1274         }
1275         return 0;
1276     }
1277     printdebug "current hash=$hash\n";
1278     if ($lastpush_hash) {
1279         fail "not fast forward on last upload branch!".
1280             " (archive's version left in DGIT_ARCHIVE)"
1281             unless is_fast_fwd($lastpush_hash, $hash);
1282     }
1283     if (defined $skew_warning_vsn) {
1284         mkpath '.git/dgit';
1285         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1286         my $clogf = ".git/dgit/changelog.tmp";
1287         runcmd shell_cmd "exec >$clogf",
1288             @git, qw(cat-file blob), "$hash:debian/changelog";
1289         my $gotclogp = parsechangelog("-l$clogf");
1290         my $got_vsn = getfield $gotclogp, 'Version';
1291         printdebug "SKEW CHECK GOT $got_vsn\n";
1292         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1293             print STDERR <<END or die $!;
1294
1295 Warning: archive skew detected.  Using the available version:
1296 Archive allegedly contains    $skew_warning_vsn
1297 We were able to obtain only   $got_vsn
1298
1299 END
1300         }
1301     }
1302     if ($lastpush_hash ne $hash) {
1303         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1304         if (act_local()) {
1305             cmdoutput @upd_cmd;
1306         } else {
1307             dryrun_report @upd_cmd;
1308         }
1309     }
1310     return 1;
1311 }
1312
1313 sub clone ($) {
1314     my ($dstdir) = @_;
1315     canonicalise_suite();
1316     badusage "dry run makes no sense with clone" unless act_local();
1317     mkdir $dstdir or die "$dstdir $!";
1318     changedir $dstdir;
1319     runcmd @git, qw(init -q);
1320     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1321     open H, "> .git/HEAD" or die $!;
1322     print H "ref: ".lref()."\n" or die $!;
1323     close H or die $!;
1324     runcmd @git, qw(remote add), 'origin', access_giturl();
1325     if (check_for_git()) {
1326         progress "fetching existing git history";
1327         git_fetch_us();
1328         runcmd_ordryrun_local @git, qw(fetch origin);
1329     } else {
1330         progress "starting new git history";
1331     }
1332     fetch_from_archive() or no_such_package;
1333     my $vcsgiturl = $dsc->{'Vcs-Git'};
1334     if (length $vcsgiturl) {
1335         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1336     }
1337     runcmd @git, qw(reset --hard), lrref();
1338     printdone "ready for work in $dstdir";
1339 }
1340
1341 sub fetch () {
1342     if (check_for_git()) {
1343         git_fetch_us();
1344     }
1345     fetch_from_archive() or no_such_package();
1346     printdone "fetched into ".lrref();
1347 }
1348
1349 sub pull () {
1350     fetch();
1351     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1352         lrref();
1353     printdone "fetched to ".lrref()." and merged into HEAD";
1354 }
1355
1356 sub check_not_dirty () {
1357     return if $ignoredirty;
1358     my @cmd = (@git, qw(diff --quiet HEAD));
1359     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1360     $!=0; $?=0; system @cmd;
1361     return if !$! && !$?;
1362     if (!$! && $?==256) {
1363         fail "working tree is dirty (does not match HEAD)";
1364     } else {
1365         failedcmd @cmd;
1366     }
1367 }
1368
1369 sub commit_admin ($) {
1370     my ($m) = @_;
1371     progress "$m";
1372     runcmd_ordryrun_local @git, qw(commit -m), $m;
1373 }
1374
1375 sub commit_quilty_patch () {
1376     my $output = cmdoutput @git, qw(status --porcelain);
1377     my %adds;
1378     foreach my $l (split /\n/, $output) {
1379         next unless $l =~ m/\S/;
1380         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1381             $adds{$1}++;
1382         }
1383     }
1384     if (!%adds) {
1385         progress "nothing quilty to commit, ok.";
1386         return;
1387     }
1388     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1389     commit_admin "Commit Debian 3.0 (quilt) metadata";
1390 }
1391
1392 sub get_source_format () {
1393     if (!open F, "debian/source/format") {
1394         die $! unless $!==&ENOENT;
1395         return '';
1396     }
1397     $_ = <F>;
1398     F->error and die $!;
1399     chomp;
1400     return $_;
1401 }
1402
1403 sub madformat ($) {
1404     my ($format) = @_;
1405     return 0 unless $format eq '3.0 (quilt)';
1406     progress "Format \`$format', urgh";
1407     if ($noquilt) {
1408         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1409         return 0;
1410     }
1411     return 1;
1412 }
1413
1414 sub push_parse_changelog ($) {
1415     my ($clogpfn) = @_;
1416
1417     my $clogp = Dpkg::Control::Hash->new();
1418     $clogp->load($clogpfn) or die;
1419
1420     $package = getfield $clogp, 'Source';
1421     my $cversion = getfield $clogp, 'Version';
1422     my $tag = debiantag($cversion);
1423     runcmd @git, qw(check-ref-format), $tag;
1424
1425     my $dscfn = dscfn($cversion);
1426
1427     return ($clogp, $cversion, $tag, $dscfn);
1428 }
1429
1430 sub push_parse_dsc ($$$) {
1431     my ($dscfn,$dscfnwhat, $cversion) = @_;
1432     $dsc = parsecontrol($dscfn,$dscfnwhat);
1433     my $dversion = getfield $dsc, 'Version';
1434     my $dscpackage = getfield $dsc, 'Source';
1435     ($dscpackage eq $package && $dversion eq $cversion) or
1436         fail "$dscfn is for $dscpackage $dversion".
1437             " but debian/changelog is for $package $cversion";
1438 }
1439
1440 sub push_mktag ($$$$$$$) {
1441     my ($head,$clogp,$tag,
1442         $dscfn,
1443         $changesfile,$changesfilewhat,
1444         $tfn) = @_;
1445
1446     $dsc->{$ourdscfield[0]} = $head;
1447     $dsc->save("$dscfn.tmp") or die $!;
1448
1449     my $changes = parsecontrol($changesfile,$changesfilewhat);
1450     foreach my $field (qw(Source Distribution Version)) {
1451         $changes->{$field} eq $clogp->{$field} or
1452             fail "changes field $field \`$changes->{$field}'".
1453                 " does not match changelog \`$clogp->{$field}'";
1454     }
1455
1456     my $cversion = getfield $clogp, 'Version';
1457     my $clogsuite = getfield $clogp, 'Distribution';
1458
1459     # We make the git tag by hand because (a) that makes it easier
1460     # to control the "tagger" (b) we can do remote signing
1461     my $authline = clogp_authline $clogp;
1462     open TO, '>', $tfn->('.tmp') or die $!;
1463     print TO <<END or die $!;
1464 object $head
1465 type commit
1466 tag $tag
1467 tagger $authline
1468
1469 $package release $cversion for $clogsuite ($csuite) [dgit]
1470 END
1471     close TO or die $!;
1472
1473     my $tagobjfn = $tfn->('.tmp');
1474     if ($sign) {
1475         if (!defined $keyid) {
1476             $keyid = access_cfg('keyid','RETURN-UNDEF');
1477         }
1478         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1479         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1480         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1481         push @sign_cmd, $tfn->('.tmp');
1482         runcmd_ordryrun @sign_cmd;
1483         if (act_scary()) {
1484             $tagobjfn = $tfn->('.signed.tmp');
1485             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1486                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1487         }
1488     }
1489
1490     return ($tagobjfn);
1491 }
1492
1493 sub sign_changes ($) {
1494     my ($changesfile) = @_;
1495     if ($sign) {
1496         my @debsign_cmd = @debsign;
1497         push @debsign_cmd, "-k$keyid" if defined $keyid;
1498         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1499         push @debsign_cmd, $changesfile;
1500         runcmd_ordryrun @debsign_cmd;
1501     }
1502 }
1503
1504 sub dopush () {
1505     printdebug "actually entering push\n";
1506     prep_ud();
1507
1508     access_giturl(); # check that success is vaguely likely
1509
1510     my $clogpfn = ".git/dgit/changelog.822.tmp";
1511     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1512
1513     responder_send_file('parsed-changelog', $clogpfn);
1514
1515     my ($clogp, $cversion, $tag, $dscfn) =
1516         push_parse_changelog("$clogpfn");
1517
1518     my $dscpath = "$buildproductsdir/$dscfn";
1519     stat_exists $dscpath or
1520         fail "looked for .dsc $dscfn, but $!;".
1521             " maybe you forgot to build";
1522
1523     responder_send_file('dsc', $dscpath);
1524
1525     push_parse_dsc($dscpath, $dscfn, $cversion);
1526
1527     my $format = getfield $dsc, 'Format';
1528     printdebug "format $format\n";
1529     if (madformat($format)) {
1530         commit_quilty_patch();
1531     }
1532     check_not_dirty();
1533     changedir $ud;
1534     progress "checking that $dscfn corresponds to HEAD";
1535     runcmd qw(dpkg-source -x --),
1536         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1537     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1538     changedir '../../../..';
1539     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1540     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1541     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1542     $!=0; $?=0;
1543     my $r = system @diffcmd;
1544     if ($r) {
1545         if ($r==256) {
1546             fail "$dscfn specifies a different tree to your HEAD commit;".
1547                 " perhaps you forgot to build".
1548                 ($diffopt eq '--exit-code' ? "" :
1549                  " (run with -D to see full diff output)");
1550         } else {
1551             failedcmd @diffcmd;
1552         }
1553     }
1554 #fetch from alioth
1555 #do fast forward check and maybe fake merge
1556 #    if (!is_fast_fwd(mainbranch
1557 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1558 #        map { lref($_).":".rref($_) }
1559 #        (uploadbranch());
1560     my $head = rev_parse('HEAD');
1561     if (!$changesfile) {
1562         my $multi = "$buildproductsdir/".
1563             "${package}_".(stripepoch $cversion)."_multi.changes";
1564         if (stat_exists "$multi") {
1565             $changesfile = $multi;
1566         } else {
1567             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1568             my @cs = glob "$buildproductsdir/$pat";
1569             fail "failed to find unique changes file".
1570                 " (looked for $pat in $buildproductsdir, or $multi);".
1571                 " perhaps you need to use dgit -C"
1572                 unless @cs==1;
1573             ($changesfile) = @cs;
1574         }
1575     } else {
1576         $changesfile = "$buildproductsdir/$changesfile";
1577     }
1578
1579     responder_send_file('changes',$changesfile);
1580     responder_send_command("param head $head");
1581     responder_send_command("param csuite $csuite");
1582
1583     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1584     my $tagobjfn;
1585
1586     if ($we_are_responder) {
1587         $tagobjfn = $tfn->('.signed.tmp');
1588         responder_receive_files('signed-tag', $tagobjfn);
1589     } else {
1590         $tagobjfn =
1591             push_mktag($head,$clogp,$tag,
1592                        $dscpath,
1593                        $changesfile,$changesfile,
1594                        $tfn);
1595     }
1596
1597     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1598     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1599     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1600     runcmd_ordryrun @git, qw(tag -v --), $tag;
1601
1602     if (!check_for_git()) {
1603         create_remote_git_repo();
1604     }
1605     runcmd_ordryrun @git, qw(push),access_giturl(),
1606         "HEAD:".rrref(), "refs/tags/$tag";
1607     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1608
1609     if ($we_are_responder) {
1610         my $dryrunsuffix = act_local() ? "" : ".tmp";
1611         responder_receive_files('signed-dsc-changes',
1612                                 "$dscpath$dryrunsuffix",
1613                                 "$changesfile$dryrunsuffix");
1614     } else {
1615         if (act_local()) {
1616             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1617         } else {
1618             progress "[new .dsc left in $dscpath.tmp]";
1619         }
1620         sign_changes $changesfile;
1621     }
1622
1623     my $host = access_cfg('upload-host','RETURN-UNDEF');
1624     my @hostarg = defined($host) ? ($host,) : ();
1625     runcmd_ordryrun @dput, @hostarg, $changesfile;
1626     printdone "pushed and uploaded $cversion";
1627
1628     responder_send_command("complete");
1629 }
1630
1631 sub cmd_clone {
1632     parseopts();
1633     my $dstdir;
1634     badusage "-p is not allowed with clone; specify as argument instead"
1635         if defined $package;
1636     if (@ARGV==1) {
1637         ($package) = @ARGV;
1638     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1639         ($package,$isuite) = @ARGV;
1640     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1641         ($package,$dstdir) = @ARGV;
1642     } elsif (@ARGV==3) {
1643         ($package,$isuite,$dstdir) = @ARGV;
1644     } else {
1645         badusage "incorrect arguments to dgit clone";
1646     }
1647     $dstdir ||= "$package";
1648
1649     if (stat_exists $dstdir) {
1650         fail "$dstdir already exists";
1651     }
1652
1653     my $cwd_remove;
1654     if ($rmonerror && !$dryrun_level) {
1655         $cwd_remove= getcwd();
1656         unshift @end, sub {
1657             return unless defined $cwd_remove;
1658             if (!chdir "$cwd_remove") {
1659                 return if $!==&ENOENT;
1660                 die "chdir $cwd_remove: $!";
1661             }
1662             rmtree($dstdir) or die "remove $dstdir: $!\n";
1663         };
1664     }
1665
1666     clone($dstdir);
1667     $cwd_remove = undef;
1668 }
1669
1670 sub branchsuite () {
1671     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1672     if ($branch =~ m#$lbranch_re#o) {
1673         return $1;
1674     } else {
1675         return undef;
1676     }
1677 }
1678
1679 sub fetchpullargs () {
1680     if (!defined $package) {
1681         my $sourcep = parsecontrol('debian/control','debian/control');
1682         $package = getfield $sourcep, 'Source';
1683     }
1684     if (@ARGV==0) {
1685 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1686         if (!$isuite) {
1687             my $clogp = parsechangelog();
1688             $isuite = getfield $clogp, 'Distribution';
1689         }
1690         canonicalise_suite();
1691         progress "fetching from suite $csuite";
1692     } elsif (@ARGV==1) {
1693         ($isuite) = @ARGV;
1694         canonicalise_suite();
1695     } else {
1696         badusage "incorrect arguments to dgit fetch or dgit pull";
1697     }
1698 }
1699
1700 sub cmd_fetch {
1701     parseopts();
1702     fetchpullargs();
1703     fetch();
1704 }
1705
1706 sub cmd_pull {
1707     parseopts();
1708     fetchpullargs();
1709     pull();
1710 }
1711
1712 sub cmd_push {
1713     parseopts();
1714     badusage "-p is not allowed with dgit push" if defined $package;
1715     check_not_dirty();
1716     my $clogp = parsechangelog();
1717     $package = getfield $clogp, 'Source';
1718     my $specsuite;
1719     if (@ARGV==0) {
1720     } elsif (@ARGV==1) {
1721         ($specsuite) = (@ARGV);
1722     } else {
1723         badusage "incorrect arguments to dgit push";
1724     }
1725     $isuite = getfield $clogp, 'Distribution';
1726     if ($new_package) {
1727         local ($package) = $existing_package; # this is a hack
1728         canonicalise_suite();
1729     }
1730     if (defined $specsuite && $specsuite ne $isuite) {
1731         canonicalise_suite();
1732         $csuite eq $specsuite or
1733             fail "dgit push: changelog specifies $isuite ($csuite)".
1734                 " but command line specifies $specsuite";
1735     }
1736     if (check_for_git()) {
1737         git_fetch_us();
1738     }
1739     if (fetch_from_archive()) {
1740         is_fast_fwd(lrref(), 'HEAD') or
1741             fail "dgit push: HEAD is not a descendant".
1742                 " of the archive's version.\n".
1743                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1744     } else {
1745         $new_package or
1746             fail "package appears to be new in this suite;".
1747                 " if this is intentional, use --new";
1748     }
1749     dopush();
1750 }
1751
1752 #---------- remote commands' implementation ----------
1753
1754 sub cmd_remote_push_build_host {
1755     my ($nrargs) = shift @ARGV;
1756     my (@rargs) = @ARGV[0..$nrargs-1];
1757     @ARGV = @ARGV[$nrargs..$#ARGV];
1758     die unless @rargs;
1759     my ($dir,$vsnwant) = @rargs;
1760     # vsnwant is a comma-separated list; we report which we have
1761     # chosen in our ready response (so other end can tell if they
1762     # offered several)
1763     $debugprefix = ' ';
1764     $we_are_responder = 1;
1765
1766     open PI, "<&STDIN" or die $!;
1767     open STDIN, "/dev/null" or die $!;
1768     open PO, ">&STDOUT" or die $!;
1769     autoflush PO 1;
1770     open STDOUT, ">&STDERR" or die $!;
1771     autoflush STDOUT 1;
1772
1773     $vsnwant //= 1;
1774     fail "build host has dgit rpush protocol version".
1775         " $rpushprotovsn but invocation host has $vsnwant"
1776         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1777
1778     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1779
1780     changedir $dir;
1781     &cmd_push;
1782 }
1783
1784 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1785 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1786 #     a good error message)
1787
1788 our $i_tmp;
1789
1790 sub i_cleanup {
1791     local ($@, $?);
1792     my $report = i_child_report();
1793     if (defined $report) {
1794         printdebug "($report)\n";
1795     } elsif ($i_child_pid) {
1796         printdebug "(killing build host child $i_child_pid)\n";
1797         kill 15, $i_child_pid;
1798     }
1799     if (defined $i_tmp && !defined $initiator_tempdir) {
1800         changedir "/";
1801         eval { rmtree $i_tmp; };
1802     }
1803 }
1804
1805 END { i_cleanup(); }
1806
1807 sub i_method {
1808     my ($base,$selector,@args) = @_;
1809     $selector =~ s/\-/_/g;
1810     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1811 }
1812
1813 sub cmd_rpush {
1814     my $host = nextarg;
1815     my $dir;
1816     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1817         $host = $1;
1818         $dir = $'; #';
1819     } else {
1820         $dir = nextarg;
1821     }
1822     $dir =~ s{^-}{./-};
1823     my @rargs = ($dir,$rpushprotovsn);
1824     my @rdgit;
1825     push @rdgit, @dgit;
1826     push @rdgit, @ropts;
1827     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1828     push @rdgit, @ARGV;
1829     my @cmd = (@ssh, $host, shellquote @rdgit);
1830     printcmd \*DEBUG,$debugprefix."+",@cmd;
1831
1832     if (defined $initiator_tempdir) {
1833         rmtree $initiator_tempdir;
1834         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1835         $i_tmp = $initiator_tempdir;
1836     } else {
1837         $i_tmp = tempdir();
1838     }
1839     $i_child_pid = open2(\*RO, \*RI, @cmd);
1840     changedir $i_tmp;
1841     initiator_expect { m/^dgit-remote-push-ready/ };
1842     for (;;) {
1843         my ($icmd,$iargs) = initiator_expect {
1844             m/^(\S+)(?: (.*))?$/;
1845             ($1,$2);
1846         };
1847         i_method "i_resp", $icmd, $iargs;
1848     }
1849 }
1850
1851 sub i_resp_progress ($) {
1852     my ($rhs) = @_;
1853     my $msg = protocol_read_bytes \*RO, $rhs;
1854     progress $msg;
1855 }
1856
1857 sub i_resp_complete {
1858     my $pid = $i_child_pid;
1859     $i_child_pid = undef; # prevents killing some other process with same pid
1860     printdebug "waiting for build host child $pid...\n";
1861     my $got = waitpid $pid, 0;
1862     die $! unless $got == $pid;
1863     die "build host child failed $?" if $?;
1864
1865     i_cleanup();
1866     printdebug "all done\n";
1867     exit 0;
1868 }
1869
1870 sub i_resp_file ($) {
1871     my ($keyword) = @_;
1872     my $localname = i_method "i_localname", $keyword;
1873     my $localpath = "$i_tmp/$localname";
1874     stat_exists $localpath and
1875         badproto \*RO, "file $keyword ($localpath) twice";
1876     protocol_receive_file \*RO, $localpath;
1877     i_method "i_file", $keyword;
1878 }
1879
1880 our %i_param;
1881
1882 sub i_resp_param ($) {
1883     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1884     $i_param{$1} = $2;
1885 }
1886
1887 our %i_wanted;
1888
1889 sub i_resp_want ($) {
1890     my ($keyword) = @_;
1891     die "$keyword ?" if $i_wanted{$keyword}++;
1892     my @localpaths = i_method "i_want", $keyword;
1893     printdebug "[[  $keyword @localpaths\n";
1894     foreach my $localpath (@localpaths) {
1895         protocol_send_file \*RI, $localpath;
1896     }
1897     print RI "files-end\n" or die $!;
1898 }
1899
1900 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1901
1902 sub i_localname_parsed_changelog {
1903     return "remote-changelog.822";
1904 }
1905 sub i_file_parsed_changelog {
1906     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1907         push_parse_changelog "$i_tmp/remote-changelog.822";
1908     die if $i_dscfn =~ m#/|^\W#;
1909 }
1910
1911 sub i_localname_dsc {
1912     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1913     return $i_dscfn;
1914 }
1915 sub i_file_dsc { }
1916
1917 sub i_localname_changes {
1918     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1919     $i_changesfn = $i_dscfn;
1920     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1921     return $i_changesfn;
1922 }
1923 sub i_file_changes { }
1924
1925 sub i_want_signed_tag {
1926     printdebug Dumper(\%i_param, $i_dscfn);
1927     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1928         && defined $i_param{'csuite'}
1929         or badproto \*RO, "premature desire for signed-tag";
1930     my $head = $i_param{'head'};
1931     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1932
1933     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1934     $csuite = $&;
1935     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1936
1937     my $tagobjfn =
1938         push_mktag $head, $i_clogp, $i_tag,
1939             $i_dscfn,
1940             $i_changesfn, 'remote changes',
1941             sub { "tag$_[0]"; };
1942
1943     return $tagobjfn;
1944 }
1945
1946 sub i_want_signed_dsc_changes {
1947     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
1948     sign_changes $i_changesfn;
1949     return ($i_dscfn, $i_changesfn);
1950 }
1951
1952 #---------- building etc. ----------
1953
1954 our $version;
1955 our $sourcechanges;
1956 our $dscfn;
1957
1958 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
1959
1960 sub build_maybe_quilt_fixup () {
1961     my $format=get_source_format;
1962     return unless madformat $format;
1963     # sigh
1964
1965     my @cmd = (@git, qw(ls-files --exclude-standard -iodm));
1966     my $problems = cmdoutput @cmd;
1967     if (length $problems) {
1968         print STDERR "problematic files:\n";
1969         print STDERR "  $_\n" foreach split /\n/, $problems;
1970         fail "Cannot do quilt fixup in tree containing ignored files.  ".
1971             "Perhaps your package's clean target is broken, in which".
1972             " case -wg (which says to use git-clean -xdf) may help.";
1973     }
1974
1975     my $clogp = parsechangelog();
1976     my $version = getfield $clogp, 'Version';
1977     my $author = getfield $clogp, 'Maintainer';
1978     my $headref = rev_parse('HEAD');
1979     my $time = time;
1980     my $ncommits = 3;
1981     my $patchname = "auto-$version-$headref-$time";
1982     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
1983     mkpath '.git/dgit';
1984     my $descfn = ".git/dgit/quilt-description.tmp";
1985     open O, '>', $descfn or die "$descfn: $!";
1986     $msg =~ s/\n/\n /g;
1987     $msg =~ s/^\s+$/ ./mg;
1988     print O <<END or die $!;
1989 Description: Automatically generated patch ($clogp->{Version})
1990  Last (up to) $ncommits git changes, FYI:
1991  .
1992  $msg
1993 Author: $author
1994
1995 ---
1996
1997 END
1998     close O or die $!;
1999     {
2000         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2001         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2002         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2003         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2004     }
2005
2006     if (!open P, '>>', ".pc/applied-patches") {
2007         $!==&ENOENT or die $!;
2008     } else {
2009         close P;
2010     }
2011
2012     commit_quilty_patch();
2013 }
2014
2015 sub quilt_fixup_editor () {
2016     my $descfn = $ENV{$fakeeditorenv};
2017     my $editing = $ARGV[$#ARGV];
2018     open I1, '<', $descfn or die "$descfn: $!";
2019     open I2, '<', $editing or die "$editing: $!";
2020     unlink $editing or die "$editing: $!";
2021     open O, '>', $editing or die "$editing: $!";
2022     while (<I1>) { print O or die $!; } I1->error and die $!;
2023     my $copying = 0;
2024     while (<I2>) {
2025         $copying ||= m/^\-\-\- /;
2026         next unless $copying;
2027         print O or die $!;
2028     }
2029     I2->error and die $!;
2030     close O or die $1;
2031     exit 0;
2032 }
2033
2034 sub clean_tree () {
2035     if ($cleanmode eq 'dpkg-source') {
2036         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2037     } elsif ($cleanmode eq 'git') {
2038         runcmd_ordryrun_local @git, qw(clean -xdf);
2039     } elsif ($cleanmode eq 'none') {
2040     } else {
2041         die "$cleanmode ?";
2042     }
2043 }
2044
2045 sub cmd_clean () {
2046     badusage "clean takes no additional arguments" if @ARGV;
2047     clean_tree();
2048 }
2049
2050 sub build_prep () {
2051     badusage "-p is not allowed when building" if defined $package;
2052     check_not_dirty();
2053     clean_tree();
2054     my $clogp = parsechangelog();
2055     $isuite = getfield $clogp, 'Distribution';
2056     $package = getfield $clogp, 'Source';
2057     $version = getfield $clogp, 'Version';
2058     build_maybe_quilt_fixup();
2059 }
2060
2061 sub changesopts () {
2062     my @opts =@changesopts[1..$#changesopts];
2063     if (!defined $changes_since_version) {
2064         my @vsns = archive_query('archive_query');
2065         my @quirk = access_quirk();
2066         if ($quirk[0] eq 'backports') {
2067             local $isuite = $quirk[2];
2068             local $csuite;
2069             canonicalise_suite();
2070             push @vsns, archive_query('archive_query');
2071         }
2072         if (@vsns) {
2073             @vsns = map { $_->[0] } @vsns;
2074             @vsns = sort { -version_compare($a, $b) } @vsns;
2075             $changes_since_version = $vsns[0];
2076             progress "changelog will contain changes since $vsns[0]";
2077         } else {
2078             $changes_since_version = '_';
2079             progress "package seems new, not specifying -v<version>";
2080         }
2081     }
2082     if ($changes_since_version ne '_') {
2083         unshift @opts, "-v$changes_since_version";
2084     }
2085     return @opts;
2086 }
2087
2088 sub cmd_build {
2089     build_prep();
2090     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2091     printdone "build successful\n";
2092 }
2093
2094 sub cmd_git_build {
2095     build_prep();
2096     my @cmd =
2097         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2098          "--git-builder=@dpkgbuildpackage");
2099     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2100         canonicalise_suite();
2101         push @cmd, "--git-debian-branch=".lbranch();
2102     }
2103     push @cmd, changesopts();
2104     runcmd_ordryrun_local @cmd, @ARGV;
2105     printdone "build successful\n";
2106 }
2107
2108 sub build_source {
2109     build_prep();
2110     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2111     $dscfn = dscfn($version);
2112     if ($cleanmode eq 'dpkg-source') {
2113         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2114             changesopts();
2115     } else {
2116         my $pwd = must_getcwd();
2117         my $leafdir = basename $pwd;
2118         changedir "..";
2119         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2120         changedir $pwd;
2121         runcmd_ordryrun_local qw(sh -ec),
2122             'exec >$1; shift; exec "$@"','x',
2123             "../$sourcechanges",
2124             @dpkggenchanges, qw(-S), changesopts();
2125     }
2126 }
2127
2128 sub cmd_build_source {
2129     badusage "build-source takes no additional arguments" if @ARGV;
2130     build_source();
2131     printdone "source built, results in $dscfn and $sourcechanges";
2132 }
2133
2134 sub cmd_sbuild {
2135     build_source();
2136     changedir "..";
2137     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2138     if (act_local()) {
2139         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2140         stat_exists $sourcechanges
2141             or fail "$sourcechanges (in parent directory): $!";
2142         foreach my $cf (glob $pat) {
2143             next if $cf eq $sourcechanges;
2144             unlink $cf or fail "remove $cf: $!";
2145         }
2146     }
2147     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2148     my @changesfiles = glob $pat;
2149     @changesfiles = sort {
2150         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2151             or $a cmp $b
2152     } @changesfiles;
2153     fail "wrong number of different changes files (@changesfiles)"
2154         unless @changesfiles;
2155     runcmd_ordryrun_local @mergechanges, @changesfiles;
2156     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2157     if (act_local()) {
2158         stat_exists $multichanges or fail "$multichanges: $!";
2159     }
2160     printdone "build successful, results in $multichanges\n" or die $!;
2161 }
2162
2163 sub cmd_quilt_fixup {
2164     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2165     my $clogp = parsechangelog();
2166     $version = getfield $clogp, 'Version';
2167     build_maybe_quilt_fixup();
2168 }
2169
2170 #---------- argument parsing and main program ----------
2171
2172 sub cmd_version {
2173     print "dgit version $our_version\n" or die $!;
2174     exit 0;
2175 }
2176
2177 sub parseopts () {
2178     my $om;
2179
2180     if (defined $ENV{'DGIT_SSH'}) {
2181         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2182     } elsif (defined $ENV{'GIT_SSH'}) {
2183         @ssh = ($ENV{'GIT_SSH'});
2184     }
2185
2186     while (@ARGV) {
2187         last unless $ARGV[0] =~ m/^-/;
2188         $_ = shift @ARGV;
2189         last if m/^--?$/;
2190         if (m/^--/) {
2191             if (m/^--dry-run$/) {
2192                 push @ropts, $_;
2193                 $dryrun_level=2;
2194             } elsif (m/^--damp-run$/) {
2195                 push @ropts, $_;
2196                 $dryrun_level=1;
2197             } elsif (m/^--no-sign$/) {
2198                 push @ropts, $_;
2199                 $sign=0;
2200             } elsif (m/^--help$/) {
2201                 cmd_help();
2202             } elsif (m/^--version$/) {
2203                 cmd_version();
2204             } elsif (m/^--new$/) {
2205                 push @ropts, $_;
2206                 $new_package=1;
2207             } elsif (m/^--since-version=([^_]+|_)$/) {
2208                 push @ropts, $_;
2209                 $changes_since_version = $1;
2210             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2211                      ($om = $opts_opt_map{$1}) &&
2212                      length $om->[0]) {
2213                 push @ropts, $_;
2214                 $om->[0] = $2;
2215             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2216                      !$opts_opt_cmdonly{$1} &&
2217                      ($om = $opts_opt_map{$1})) {
2218                 push @ropts, $_;
2219                 push @$om, $2;
2220             } elsif (m/^--existing-package=(.*)/s) {
2221                 push @ropts, $_;
2222                 $existing_package = $1;
2223             } elsif (m/^--initiator-tempdir=(.*)/s) {
2224                 $initiator_tempdir = $1;
2225                 $initiator_tempdir =~ m#^/# or
2226                     badusage "--initiator-tempdir must be used specify an".
2227                         " absolute, not relative, directory."
2228             } elsif (m/^--distro=(.*)/s) {
2229                 push @ropts, $_;
2230                 $idistro = $1;
2231             } elsif (m/^--build-products-dir=(.*)/s) {
2232                 push @ropts, $_;
2233                 $buildproductsdir = $1;
2234             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2235                 push @ropts, $_;
2236                 $cleanmode = $1;
2237             } elsif (m/^--clean=(.*)$/s) {
2238                 badusage "unknown cleaning mode \`$1'";
2239             } elsif (m/^--ignore-dirty$/s) {
2240                 push @ropts, $_;
2241                 $ignoredirty = 1;
2242             } elsif (m/^--no-quilt-fixup$/s) {
2243                 push @ropts, $_;
2244                 $noquilt = 1;
2245             } elsif (m/^--no-rm-on-error$/s) {
2246                 push @ropts, $_;
2247                 $rmonerror = 0;
2248             } else {
2249                 badusage "unknown long option \`$_'";
2250             }
2251         } else {
2252             while (m/^-./s) {
2253                 if (s/^-n/-/) {
2254                     push @ropts, $&;
2255                     $dryrun_level=2;
2256                 } elsif (s/^-L/-/) {
2257                     push @ropts, $&;
2258                     $dryrun_level=1;
2259                 } elsif (s/^-h/-/) {
2260                     cmd_help();
2261                 } elsif (s/^-D/-/) {
2262                     push @ropts, $&;
2263                     open DEBUG, ">&STDERR" or die $!;
2264                     autoflush DEBUG 1;
2265                     $debug++;
2266                 } elsif (s/^-N/-/) {
2267                     push @ropts, $&;
2268                     $new_package=1;
2269                 } elsif (s/^-v([^_]+|_)$//s) {
2270                     push @ropts, $&;
2271                     $changes_since_version = $1;
2272                 } elsif (m/^-m/) {
2273                     push @ropts, $&;
2274                     push @changesopts, $_;
2275                     $_ = '';
2276                 } elsif (s/^-c(.*=.*)//s) {
2277                     push @ropts, $&;
2278                     push @git, '-c', $1;
2279                 } elsif (s/^-d(.*)//s) {
2280                     push @ropts, $&;
2281                     $idistro = $1;
2282                 } elsif (s/^-C(.*)//s) {
2283                     push @ropts, $&;
2284                     $changesfile = $1;
2285                     if ($changesfile =~ s#^(.*)/##) {
2286                         $buildproductsdir = $1;
2287                     }
2288                 } elsif (s/^-k(.*)//s) {
2289                     $keyid=$1;
2290                 } elsif (s/^-wn//s) {
2291                     push @ropts, $&;
2292                     $cleanmode = 'none';
2293                 } elsif (s/^-wg//s) {
2294                     push @ropts, $&;
2295                     $cleanmode = 'git';
2296                 } elsif (s/^-wd//s) {
2297                     push @ropts, $&;
2298                     $cleanmode = 'dpkg-source';
2299                 } else {
2300                     badusage "unknown short option \`$_'";
2301                 }
2302             }
2303         }
2304     }
2305 }
2306
2307 if ($ENV{$fakeeditorenv}) {
2308     quilt_fixup_editor();
2309 }
2310
2311 parseopts();
2312 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2313 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2314     if $dryrun_level == 1;
2315 if (!@ARGV) {
2316     print STDERR $helpmsg or die $!;
2317     exit 8;
2318 }
2319 my $cmd = shift @ARGV;
2320 $cmd =~ y/-/_/;
2321
2322 my $fn = ${*::}{"cmd_$cmd"};
2323 $fn or badusage "unknown operation $cmd";
2324 $fn->();