dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Config;
  34
  35 our $our_version = 'UNRELEASED'; ###substituted###
  36
  37 our $rpushprotovsn = 2;
  38
  39 our $isuite = 'unstable';
  40 our $idistro;
  41 our $package;
  42 our @ropts;
  43
  44 our $sign = 1;
  45 our $dryrun_level = 0;
  46 our $changesfile;
  47 our $buildproductsdir = '..';
  48 our $new_package = 0;
  49 our $ignoredirty = 0;
  50 our $noquilt = 0;
  51 our $rmonerror = 1;
  52 our $existing_package = 'dpkg';
  53 our $cleanmode = 'dpkg-source';
  54 our $changes_since_version;
  55 our $we_are_responder;
  56 our $initiator_tempdir;
  57
  58 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  59
  60 our $suite_re = '[-+.0-9a-z]+';
  61
  62 our (@git) = qw(git);
  63 our (@dget) = qw(dget);
  64 our (@curl) = qw(curl -f);
  65 our (@dput) = qw(dput);
  66 our (@debsign) = qw(debsign);
  67 our (@gpg) = qw(gpg);
  68 our (@sbuild) = qw(sbuild -A);
  69 our (@ssh) = 'ssh';
  70 our (@dgit) = qw(dgit);
  71 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  72 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  73 our (@dpkggenchanges) = qw(dpkg-genchanges);
  74 our (@mergechanges) = qw(mergechanges -f);
  75 our (@changesopts) = ('');
  76
  77 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  78                      'curl' => \@curl,
  79                      'dput' => \@dput,
  80                      'debsign' => \@debsign,
  81                      'gpg' => \@gpg,
  82                      'sbuild' => \@sbuild,
  83                      'ssh' => \@ssh,
  84                      'dgit' => \@dgit,
  85                      'dpkg-source' => \@dpkgsource,
  86                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  87                      'dpkg-genchanges' => \@dpkggenchanges,
  88                      'ch' => \@changesopts,
  89                      'mergechanges' => \@mergechanges);
  90
  91 our %opts_opt_cmdonly = ('gpg' => 1);
  92
  93 our $keyid;
  94
  95 our $debug = 0;
  96 open DEBUG, ">/dev/null" or die $!;
  97
  98 autoflush STDOUT 1;
  99
 100 our $remotename = 'dgit';
 101 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 102 our $branchprefix = 'dgit';
 103 our $csuite;
 104
 105 sub lbranch () { return "$branchprefix/$csuite"; }
 106 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 107 sub lref () { return "refs/heads/".lbranch(); }
 108 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 109 sub rrref () { return "refs/$branchprefix/$csuite"; }
 110 sub debiantag ($) {
 111     my ($v) = @_;
 112     $v =~ y/~:/_%/;
 113     return "debian/$v";
 114 }
 115
 116 sub stripepoch ($) {
 117     my ($vsn) = @_;
 118     $vsn =~ s/^\d+\://;
 119     return $vsn;
 120 }
 121
 122 sub dscfn ($) {
 123     my ($vsn) = @_;
 124     return "${package}_".(stripepoch $vsn).".dsc";
 125 }
 126
 127 our $us = 'dgit';
 128 our $debugprefix = '';
 129
 130 our @end;
 131 END {
 132     local ($?);
 133     foreach my $f (@end) {
 134         eval { $f->(); };
 135         warn "$us: cleanup: $@" if length $@;
 136     }
 137 };
 138
 139 our @signames = split / /, $Config{sig_name};
 140
 141 sub waitstatusmsg () {
 142     if (!$?) {
 143         return "terminated, reporting successful completion";
 144     } elsif (!($? & 255)) {
 145         return "failed with error exit status ".WEXITSTATUS($?);
 146     } elsif (WIFSIGNALED($?)) {
 147         my $signum=WTERMSIG($?);
 148         return "died due to fatal signal ".
 149             ($signames[$signum] // "number $signum").
 150             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 151     } else {
 152         return "failed with unknown wait status ".$?;
 153     }
 154 }
 155
 156 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 157
 158 sub fail {
 159     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 160 }
 161
 162 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 163
 164 sub no_such_package () {
 165     print STDERR "$us: package $package does not exist in suite $isuite\n";
 166     exit 4;
 167 }
 168
 169 sub fetchspec () {
 170     local $csuite = '*';
 171     return  "+".rrref().":".lrref();
 172 }
 173
 174 sub changedir ($) {
 175     my ($newdir) = @_;
 176     printdebug "CD $newdir\n";
 177     chdir $newdir or die "chdir: $newdir: $!";
 178 }
 179
 180 sub stat_exists ($) {
 181     my ($f) = @_;
 182     return 1 if stat $f;
 183     return 0 if $!==&ENOENT;
 184     die "stat $f: $!";
 185 }
 186
 187 #---------- remote protocol support, common ----------
 188
 189 # remote push initiator/responder protocol:
 190 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 191 #
 192 #  > file parsed-changelog
 193 #  [indicates that output of dpkg-parsechangelog follows]
 194 #  > data-block NBYTES
 195 #  > [NBYTES bytes of data (no newline)]
 196 #  [maybe some more blocks]
 197 #  > data-end
 198 #
 199 #  > file dsc
 200 #  [etc]
 201 #
 202 #  > file changes
 203 #  [etc]
 204 #
 205 #  > param head HEAD
 206 #
 207 #  > want signed-tag
 208 #  [indicates that signed tag is wanted]
 209 #  < data-block NBYTES
 210 #  < [NBYTES bytes of data (no newline)]
 211 #  [maybe some more blocks]
 212 #  < data-end
 213 #  < files-end
 214 #
 215 #  > want signed-dsc-changes
 216 #  < data-block NBYTES    [transfer of signed dsc]
 217 #  [etc]
 218 #  < data-block NBYTES    [transfer of signed changes]
 219 #  [etc]
 220 #  < files-end
 221 #
 222 #  > complete
 223
 224 our $i_child_pid;
 225
 226 sub i_child_report () {
 227     # Sees if our child has died, and reap it if so.  Returns a string
 228     # describing how it died if it failed, or undef otherwise.
 229     return undef unless $i_child_pid;
 230     my $got = waitpid $i_child_pid, WNOHANG;
 231     return undef if $got <= 0;
 232     die unless $got == $i_child_pid;
 233     $i_child_pid = undef;
 234     return undef unless $?;
 235     return "build host child ".waitstatusmsg();
 236 }
 237
 238 sub badproto ($$) {
 239     my ($fh, $m) = @_;
 240     fail "connection lost: $!" if $fh->error;
 241     fail "protocol violation; $m not expected";
 242 }
 243
 244 sub badproto_badread ($$) {
 245     my ($fh, $wh) = @_;
 246     fail "connection lost: $!" if $!;
 247     my $report = i_child_report();
 248     fail $report if defined $report;
 249     badproto $fh, "eof (reading $wh)";
 250 }
 251
 252 sub protocol_expect (&$) {
 253     my ($match, $fh) = @_;
 254     local $_;
 255     $_ = <$fh>;
 256     defined && chomp or badproto_badread $fh, "protocol message";
 257     if (wantarray) {
 258         my @r = &$match;
 259         return @r if @r;
 260     } else {
 261         my $r = &$match;
 262         return $r if $r;
 263     }
 264     badproto $fh, "\`$_'";
 265 }
 266
 267 sub protocol_send_file ($$) {
 268     my ($fh, $ourfn) = @_;
 269     open PF, "<", $ourfn or die "$ourfn: $!";
 270     for (;;) {
 271         my $d;
 272         my $got = read PF, $d, 65536;
 273         die "$ourfn: $!" unless defined $got;
 274         last if !$got;
 275         print $fh "data-block ".length($d)."\n" or die $!;
 276         print $fh $d or die $!;
 277     }
 278     PF->error and die "$ourfn $!";
 279     print $fh "data-end\n" or die $!;
 280     close PF;
 281 }
 282
 283 sub protocol_read_bytes ($$) {
 284     my ($fh, $nbytes) = @_;
 285     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 286     my $d;
 287     my $got = read $fh, $d, $nbytes;
 288     $got==$nbytes or badproto_badread $fh, "data block";
 289     return $d;
 290 }
 291
 292 sub protocol_receive_file ($$) {
 293     my ($fh, $ourfn) = @_;
 294     printdebug "() $ourfn\n";
 295     open PF, ">", $ourfn or die "$ourfn: $!";
 296     for (;;) {
 297         my ($y,$l) = protocol_expect {
 298             m/^data-block (.*)$/ ? (1,$1) :
 299             m/^data-end$/ ? (0,) :
 300             ();
 301         } $fh;
 302         last unless $y;
 303         my $d = protocol_read_bytes $fh, $l;
 304         print PF $d or die $!;
 305     }
 306     close PF or die $!;
 307 }
 308
 309 #---------- remote protocol support, responder ----------
 310
 311 sub responder_send_command ($) {
 312     my ($command) = @_;
 313     return unless $we_are_responder;
 314     # called even without $we_are_responder
 315     printdebug ">> $command\n";
 316     print PO $command, "\n" or die $!;
 317 }
 318
 319 sub responder_send_file ($$) {
 320     my ($keyword, $ourfn) = @_;
 321     return unless $we_are_responder;
 322     printdebug "]] $keyword $ourfn\n";
 323     responder_send_command "file $keyword";
 324     protocol_send_file \*PO, $ourfn;
 325 }
 326
 327 sub responder_receive_files ($@) {
 328     my ($keyword, @ourfns) = @_;
 329     die unless $we_are_responder;
 330     printdebug "[[ $keyword @ourfns\n";
 331     responder_send_command "want $keyword";
 332     foreach my $fn (@ourfns) {
 333         protocol_receive_file \*PI, $fn;
 334     }
 335     printdebug "[[\$\n";
 336     protocol_expect { m/^files-end$/ } \*PI;
 337 }
 338
 339 #---------- remote protocol support, initiator ----------
 340
 341 sub initiator_expect (&) {
 342     my ($match) = @_;
 343     protocol_expect { &$match } \*RO;
 344 }
 345
 346 #---------- end remote code ----------
 347
 348 sub progress {
 349     if ($we_are_responder) {
 350         my $m = join '', @_;
 351         responder_send_command "progress ".length($m) or die $!;
 352         print PO $m or die $!;
 353     } else {
 354         print @_, "\n";
 355     }
 356 }
 357
 358 our $ua;
 359
 360 sub url_get {
 361     if (!$ua) {
 362         $ua = LWP::UserAgent->new();
 363         $ua->env_proxy;
 364     }
 365     my $what = $_[$#_];
 366     progress "downloading $what...";
 367     my $r = $ua->get(@_) or die $!;
 368     return undef if $r->code == 404;
 369     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 370     return $r->decoded_content(charset => 'none');
 371 }
 372
 373 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 374
 375 sub shellquote {
 376     my @out;
 377     local $_;
 378     foreach my $a (@_) {
 379         $_ = $a;
 380         if (m{[^-=_./0-9a-z]}i) {
 381             s{['\\]}{'\\$&'}g;
 382             push @out, "'$_'";
 383         } else {
 384             push @out, $_;
 385         }
 386     }
 387     return join ' ', @out;
 388 }
 389
 390 sub printcmd {
 391     my $fh = shift @_;
 392     my $intro = shift @_;
 393     print $fh $intro," " or die $!;
 394     print $fh shellquote @_ or die $!;
 395     print $fh "\n" or die $!;
 396 }
 397
 398 sub failedcmd {
 399     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 400     if ($!) {
 401         fail "failed to fork/exec: $!";
 402     } elsif ($?) {
 403         fail "subprocess ".waitstatusmsg();
 404     } else {
 405         fail "subprocess produced invalid output";
 406     }
 407 }
 408
 409 sub runcmd {
 410     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 411     $!=0; $?=0;
 412     failedcmd @_ if system @_;
 413 }
 414
 415 sub act_local () { return $dryrun_level <= 1; }
 416 sub act_scary () { return !$dryrun_level; }
 417
 418 sub printdone {
 419     if (!$dryrun_level) {
 420         progress "dgit ok: @_";
 421     } else {
 422         progress "would be ok: @_ (but dry run only)";
 423     }
 424 }
 425
 426 sub cmdoutput_errok {
 427     die Dumper(\@_)." ?" if grep { !defined } @_;
 428     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 429     open P, "-|", @_ or die $!;
 430     my $d;
 431     $!=0; $?=0;
 432     { local $/ = undef; $d = <P>; }
 433     die $! if P->error;
 434     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 435     chomp $d;
 436     $d =~ m/^.*/;
 437     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 438     return $d;
 439 }
 440
 441 sub cmdoutput {
 442     my $d = cmdoutput_errok @_;
 443     defined $d or failedcmd @_;
 444     return $d;
 445 }
 446
 447 sub dryrun_report {
 448     printcmd(\*STDERR,$debugprefix."#",@_);
 449 }
 450
 451 sub runcmd_ordryrun {
 452     if (act_scary()) {
 453         runcmd @_;
 454     } else {
 455         dryrun_report @_;
 456     }
 457 }
 458
 459 sub runcmd_ordryrun_local {
 460     if (act_local()) {
 461         runcmd @_;
 462     } else {
 463         dryrun_report @_;
 464     }
 465 }
 466
 467 sub shell_cmd {
 468     my ($first_shell, @cmd) = @_;
 469     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 470 }
 471
 472 our $helpmsg = <<END;
 473 main usages:
 474   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 475   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 476   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 477   dgit [dgit-opts] push [dgit-opts] [suite]
 478   dgit [dgit-opts] rpush build-host:build-dir ...
 479 important dgit options:
 480   -k<keyid>           sign tag and package with <keyid> instead of default
 481   --dry-run -n        do not change anything, but go through the motions
 482   --damp-run -L       like --dry-run but make local changes, without signing
 483   --new -N            allow introducing a new package
 484   --debug -D          increase debug level
 485   -c<name>=<value>    set git config option (used directly by dgit too)
 486 END
 487
 488 our $later_warning_msg = <<END;
 489 Perhaps the upload is stuck in incoming.  Using the version from git.
 490 END
 491
 492 sub badusage {
 493     print STDERR "$us: @_\n", $helpmsg or die $!;
 494     exit 8;
 495 }
 496
 497 sub nextarg {
 498     @ARGV or badusage "too few arguments";
 499     return scalar shift @ARGV;
 500 }
 501
 502 sub cmd_help () {
 503     print $helpmsg or die $!;
 504     exit 0;
 505 }
 506
 507 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 508
 509 our %defcfg = ('dgit.default.distro' => 'debian',
 510                'dgit.default.username' => '',
 511                'dgit.default.archive-query-default-component' => 'main',
 512                'dgit.default.ssh' => 'ssh',
 513                'dgit-distro.debian.git-host' => 'git.debian.org',
 514                'dgit-distro.debian.git-proto' => 'git+ssh://',
 515                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 516                'dgit-distro.debian.git-check' => 'ssh-cmd',
 517                'dgit-distro.debian.git-create' => 'ssh-cmd',
 518                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 519                'dgit-distro.debian.sshpsql-dbname' => 'service=projectb',
 520                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 521                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 522  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 523  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 524                'dgit-distro.ubuntu.git-check' => 'false',
 525  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 526                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 527                'dgit-distro.test-dummy.username' => "alice",
 528                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 529                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 530                'dgit-distro.test-dummy.git-url' => "$td/git",
 531                'dgit-distro.test-dummy.git-host' => "git",
 532                'dgit-distro.test-dummy.git-path' => "$td/git",
 533                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 534                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 535                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 536                );
 537
 538 sub cfg {
 539     foreach my $c (@_) {
 540         return undef if $c =~ /RETURN-UNDEF/;
 541         my @cmd = (@git, qw(config --), $c);
 542         my $v;
 543         {
 544             local ($debug) = $debug-1;
 545             $v = cmdoutput_errok @cmd;
 546         };
 547         if ($?==0) {
 548             return $v;
 549         } elsif ($?!=256) {
 550             failedcmd @cmd;
 551         }
 552         my $dv = $defcfg{$c};
 553         return $dv if defined $dv;
 554     }
 555     badcfg "need value for one of: @_\n".
 556         "$us: distro or suite appears not to be (properly) supported";
 557 }
 558
 559 sub access_basedistro () {
 560     if (defined $idistro) {
 561         return cfg("dgit-distro.basedistro.distro",
 562                    "dgit-suite.$isuite.distro",
 563                    'RETURN-UNDEF') // $idistro;
 564     } else {
 565         return cfg("dgit-suite.$isuite.distro",
 566                    "dgit.default.distro");
 567     }
 568 }
 569
 570 sub access_quirk () {
 571     # returns (quirk name, distro to use instead, quirk-specific info)
 572     my $basedistro = access_basedistro();
 573     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 574                               'RETURN-UNDEF');
 575     if (defined $backports_quirk) {
 576         my $re = $backports_quirk;
 577         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 578         $re =~ s/\*/.*/g;
 579         $re =~ s/\%/([-0-9a-z_]+)/
 580             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 581         if ($isuite =~ m/^$re$/) {
 582             return ('backports',"$basedistro-backports",$1);
 583         }
 584     }
 585     return ('none',$basedistro);
 586 }
 587
 588 sub access_distro () {
 589     return (access_quirk())[1];
 590 }
 591
 592 sub access_cfg (@) {
 593     my (@keys) = @_;
 594     my $basedistro = access_basedistro();
 595     my $distro = $idistro || access_distro();
 596     my $value = cfg(map {
 597         ("dgit-distro.$distro.$_",
 598          "dgit-distro.$basedistro.$_",
 599          "dgit.default.$_")
 600                     } @keys);
 601     return $value;
 602 }
 603
 604 sub string_to_ssh ($) {
 605     my ($spec) = @_;
 606     if ($spec =~ m/\s/) {
 607         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 608     } else {
 609         return ($spec);
 610     }
 611 }
 612
 613 sub access_cfg_ssh () {
 614     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 615     if (!defined $gitssh) {
 616         return @ssh;
 617     } else {
 618         return string_to_ssh $gitssh;
 619     }
 620 }
 621
 622 sub access_someuserhost ($) {
 623     my ($some) = @_;
 624     my $user = access_cfg("$some-user",'username');
 625     my $host = access_cfg("$some-host");
 626     return length($user) ? "$user\@$host" : $host;
 627 }
 628
 629 sub access_gituserhost () {
 630     return access_someuserhost('git');
 631 }
 632
 633 sub access_giturl () {
 634     my $url = access_cfg('git-url','RETURN-UNDEF');
 635     if (!defined $url) {
 636         $url =
 637             access_cfg('git-proto').
 638             access_gituserhost().
 639             access_cfg('git-path');
 640     }
 641     return "$url/$package.git";
 642 }
 643
 644 sub parsecontrolfh ($$;$) {
 645     my ($fh, $desc, $allowsigned) = @_;
 646     our $dpkgcontrolhash_noissigned;
 647     my $c;
 648     for (;;) {
 649         my %opts = ('name' => $desc);
 650         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 651         $c = Dpkg::Control::Hash->new(%opts);
 652         $c->parse($fh,$desc) or die "parsing of $desc failed";
 653         last if $allowsigned;
 654         last if $dpkgcontrolhash_noissigned;
 655         my $issigned= $c->get_option('is_pgp_signed');
 656         if (!defined $issigned) {
 657             $dpkgcontrolhash_noissigned= 1;
 658             seek $fh, 0,0 or die "seek $desc: $!";
 659         } elsif ($issigned) {
 660             fail "control file $desc is (already) PGP-signed. ".
 661                 " Note that dgit push needs to modify the .dsc and then".
 662                 " do the signature itself";
 663         } else {
 664             last;
 665         }
 666     }
 667     return $c;
 668 }
 669
 670 sub parsecontrol {
 671     my ($file, $desc) = @_;
 672     my $fh = new IO::Handle;
 673     open $fh, '<', $file or die "$file: $!";
 674     my $c = parsecontrolfh($fh,$desc);
 675     $fh->error and die $!;
 676     close $fh;
 677     return $c;
 678 }
 679
 680 sub getfield ($$) {
 681     my ($dctrl,$field) = @_;
 682     my $v = $dctrl->{$field};
 683     return $v if defined $v;
 684     fail "missing field $field in ".$v->get_option('name');
 685 }
 686
 687 sub parsechangelog {
 688     my $c = Dpkg::Control::Hash->new();
 689     my $p = new IO::Handle;
 690     my @cmd = (qw(dpkg-parsechangelog), @_);
 691     open $p, '-|', @cmd or die $!;
 692     $c->parse($p);
 693     $?=0; $!=0; close $p or failedcmd @cmd;
 694     return $c;
 695 }
 696
 697 sub git_get_ref ($) {
 698     my ($refname) = @_;
 699     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 700     if (!defined $got) {
 701         $?==256 or fail "git show-ref failed (status $?)";
 702         printdebug "ref $refname= [show-ref exited 1]\n";
 703         return '';
 704     }
 705     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 706         printdebug "ref $refname=$1\n";
 707         return $1;
 708     } else {
 709         printdebug "ref $refname= [no match]\n";
 710         return '';
 711     }
 712 }
 713
 714 sub must_getcwd () {
 715     my $d = getcwd();
 716     defined $d or fail "getcwd failed: $!";
 717     return $d;
 718 }
 719
 720 our %rmad;
 721
 722 sub archive_query ($) {
 723     my ($method) = @_;
 724     my $query = access_cfg('archive-query','RETURN-UNDEF');
 725     if (!defined $query) {
 726         my $distro = access_basedistro();
 727         if ($distro eq 'debian') {
 728             $query = "sshpsql:".
 729                 access_someuserhost('sshpsql').':'.
 730                 access_cfg('sshpsql-dbname');
 731         } else {
 732             $query = "madison:$distro";
 733         }
 734     }
 735     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 736     my $proto = $1;
 737     my $data = $'; #';
 738     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 739 }
 740
 741 sub pool_dsc_subpath ($$) {
 742     my ($vsn,$component) = @_; # $package is implict arg
 743     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 744     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 745 }
 746
 747 sub archive_query_madison ($$) {
 748     my ($proto,$data) = @_;
 749     die unless $proto eq 'madison';
 750     $rmad{$package} ||= cmdoutput
 751         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 752     my $rmad = $rmad{$package};
 753     return madison_parse($rmad);
 754 }
 755
 756 sub madison_parse ($) {
 757     my ($rmad) = @_;
 758     my @out;
 759     foreach my $l (split /\n/, $rmad) {
 760         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 761                   \s*( [^ \t|]+ )\s* \|
 762                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 763                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 764         $1 eq $package or die "$rmad $package ?";
 765         my $vsn = $2;
 766         my $newsuite = $3;
 767         my $component;
 768         if (defined $4) {
 769             $component = $4;
 770         } else {
 771             $component = access_cfg('archive-query-default-component');
 772         }
 773         $5 eq 'source' or die "$rmad ?";
 774         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 775     }
 776     return sort { -version_compare($a->[0],$b->[0]); } @out;
 777 }
 778
 779 sub canonicalise_suite_madison ($$) {
 780     # madison canonicalises for us
 781     my @r = archive_query_madison($_[0],$_[1]);
 782     @r or fail
 783         "unable to canonicalise suite using package $package".
 784         " which does not appear to exist in suite $isuite;".
 785         " --existing-package may help";
 786     return $r[0][2];
 787 }
 788
 789 sub sshpsql ($$) {
 790     my ($data,$sql) = @_;
 791     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 792     my ($userhost,$dbname) = ($`,$'); #';
 793     my @rows;
 794     my @cmd = (access_cfg_ssh, $userhost,
 795                "export LANG=C; ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 796     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 797     open P, "-|", @cmd or die $!;
 798     while (<P>) {
 799         chomp or die;
 800         printdebug("$debugprefix>|$_|\n");
 801         push @rows, $_;
 802     }
 803     $!=0; $?=0; close P or failedcmd @cmd;
 804     @rows or die;
 805     my $nrows = pop @rows;
 806     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 807     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 808     @rows = map { [ split /\|/, $_ ] } @rows;
 809     my $ncols = scalar @{ shift @rows };
 810     die if grep { scalar @$_ != $ncols } @rows;
 811     return @rows;
 812 }
 813
 814 sub sql_injection_check {
 815     foreach (@_) { die "$_ $& ?" if m/[']/; }
 816 }
 817
 818 sub archive_query_sshpsql ($$) {
 819     my ($proto,$data) = @_;
 820     sql_injection_check $isuite, $package;
 821     my @rows = sshpsql($data, <<END);
 822         SELECT source.version, component.name, files.filename, files.sha256sum
 823           FROM source
 824           JOIN src_associations ON source.id = src_associations.source
 825           JOIN suite ON suite.id = src_associations.suite
 826           JOIN dsc_files ON dsc_files.source = source.id
 827           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 828           JOIN component ON component.id = files_archive_map.component_id
 829           JOIN files ON files.id = dsc_files.file
 830          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 831            AND source.source='$package'
 832            AND files.filename LIKE '%.dsc';
 833 END
 834     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 835     my $digester = Digest::SHA->new(256);
 836     @rows = map {
 837         my ($vsn,$component,$filename,$sha256sum) = @$_;
 838         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 839     } @rows;
 840     return @rows;
 841 }
 842
 843 sub canonicalise_suite_sshpsql ($$) {
 844     my ($proto,$data) = @_;
 845     sql_injection_check $isuite;
 846     my @rows = sshpsql($data, <<END);
 847         SELECT suite.codename
 848           FROM suite where suite_name='$isuite' or codename='$isuite';
 849 END
 850     @rows = map { $_->[0] } @rows;
 851     fail "unknown suite $isuite" unless @rows;
 852     die "ambiguous $isuite: @rows ?" if @rows>1;
 853     return $rows[0];
 854 }
 855
 856 sub canonicalise_suite_dummycat ($$) {
 857     my ($proto,$data) = @_;
 858     my $dpath = "$data/suite.$isuite";
 859     if (!open C, "<", $dpath) {
 860         $!==ENOENT or die "$dpath: $!";
 861         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 862         return $isuite;
 863     }
 864     $!=0; $_ = <C>;
 865     chomp or die "$dpath: $!";
 866     close C;
 867     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 868     return $_;
 869 }
 870
 871 sub archive_query_dummycat ($$) {
 872     my ($proto,$data) = @_;
 873     canonicalise_suite();
 874     my $dpath = "$data/package.$csuite.$package";
 875     if (!open C, "<", $dpath) {
 876         $!==ENOENT or die "$dpath: $!";
 877         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 878         return ();
 879     }
 880     my @rows;
 881     while (<C>) {
 882         next if m/^\#/;
 883         next unless m/\S/;
 884         die unless chomp;
 885         printdebug "dummycat query $csuite $package $dpath | $_\n";
 886         my @row = split /\s+/, $_;
 887         @row==2 or die "$dpath: $_ ?";
 888         push @rows, \@row;
 889     }
 890     C->error and die "$dpath: $!";
 891     close C;
 892     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 893 }
 894
 895 sub canonicalise_suite () {
 896     return if defined $csuite;
 897     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 898     $csuite = archive_query('canonicalise_suite');
 899     if ($isuite ne $csuite) {
 900         progress "canonical suite name for $isuite is $csuite";
 901     }
 902 }
 903
 904 sub get_archive_dsc () {
 905     canonicalise_suite();
 906     my @vsns = archive_query('archive_query');
 907     foreach my $vinfo (@vsns) {
 908         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 909         $dscurl = access_cfg('mirror').$subpath;
 910         $dscdata = url_get($dscurl);
 911         if (!$dscdata) {
 912             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 913             next;
 914         }
 915         if ($digester) {
 916             $digester->reset();
 917             $digester->add($dscdata);
 918             my $got = $digester->hexdigest();
 919             $got eq $digest or
 920                 fail "$dscurl has hash $got but".
 921                     " archive told us to expect $digest";
 922         }
 923         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 924         printdebug Dumper($dscdata) if $debug>1;
 925         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 926         printdebug Dumper($dsc) if $debug>1;
 927         my $fmt = getfield $dsc, 'Format';
 928         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 929         $dsc_checked = !!$digester;
 930         return;
 931     }
 932     $dsc = undef;
 933 }
 934
 935 sub check_for_git () {
 936     # returns 0 or 1
 937     my $how = access_cfg('git-check');
 938     if ($how eq 'ssh-cmd') {
 939         my @cmd =
 940             (access_cfg_ssh, access_gituserhost(),
 941              " set -e; cd ".access_cfg('git-path').";".
 942              " if test -d $package.git; then echo 1; else echo 0; fi");
 943         my $r= cmdoutput @cmd;
 944         failedcmd @cmd unless $r =~ m/^[01]$/;
 945         return $r+0;
 946     } elsif ($how eq 'true') {
 947         return 1;
 948     } elsif ($how eq 'false') {
 949         return 0;
 950     } else {
 951         badcfg "unknown git-check \`$how'";
 952     }
 953 }
 954
 955 sub create_remote_git_repo () {
 956     my $how = access_cfg('git-create');
 957     if ($how eq 'ssh-cmd') {
 958         runcmd_ordryrun
 959             (access_cfg_ssh, access_gituserhost(),
 960              "set -e; cd ".access_cfg('git-path').";".
 961              " cp -a _template $package.git");
 962     } elsif ($how eq 'true') {
 963         # nothing to do
 964     } else {
 965         badcfg "unknown git-create \`$how'";
 966     }
 967 }
 968
 969 our ($dsc_hash,$lastpush_hash);
 970
 971 our $ud = '.git/dgit/unpack';
 972
 973 sub prep_ud () {
 974     rmtree($ud);
 975     mkpath '.git/dgit';
 976     mkdir $ud or die $!;
 977 }
 978
 979 sub mktree_in_ud_here () {
 980     runcmd qw(git init -q);
 981     rmtree('.git/objects');
 982     symlink '../../../../objects','.git/objects' or die $!;
 983 }
 984
 985 sub mktree_in_ud_from_only_subdir () {
 986     # changes into the subdir
 987     my (@dirs) = <*/.>;
 988     die unless @dirs==1;
 989     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 990     my $dir = $1;
 991     changedir $dir;
 992     fail "source package contains .git directory" if stat_exists '.git';
 993     mktree_in_ud_here();
 994     runcmd @git, qw(add -Af);
 995     my $tree = cmdoutput @git, qw(write-tree);
 996     $tree =~ m/^\w+$/ or die "$tree ?";
 997     return ($tree,$dir);
 998 }
 999
1000 sub dsc_files_info () {
1001     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1002                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1003                        ['Files',           'Digest::MD5', 'new()']) {
1004         my ($fname, $module, $method) = @$csumi;
1005         my $field = $dsc->{$fname};
1006         next unless defined $field;
1007         eval "use $module; 1;" or die $@;
1008         my @out;
1009         foreach (split /\n/, $field) {
1010             next unless m/\S/;
1011             m/^(\w+) (\d+) (\S+)$/ or
1012                 fail "could not parse .dsc $fname line \`$_'";
1013             my $digester = eval "$module"."->$method;" or die $@;
1014             push @out, {
1015                 Hash => $1,
1016                 Bytes => $2,
1017                 Filename => $3,
1018                 Digester => $digester,
1019             };
1020         }
1021         return @out;
1022     }
1023     fail "missing any supported Checksums-* or Files field in ".
1024         $dsc->get_option('name');
1025 }
1026
1027 sub dsc_files () {
1028     map { $_->{Filename} } dsc_files_info();
1029 }
1030
1031 sub is_orig_file ($) {
1032     local ($_) = @_;
1033     m/\.orig(?:-\w+)?\.tar\.\w+$/;
1034 }
1035
1036 sub make_commit ($) {
1037     my ($file) = @_;
1038     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1039 }
1040
1041 sub clogp_authline ($) {
1042     my ($clogp) = @_;
1043     my $author = getfield $clogp, 'Maintainer';
1044     $author =~ s#,.*##ms;
1045     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1046     my $authline = "$author $date";
1047     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1048         fail "unexpected commit author line format \`$authline'".
1049         " (was generated from changelog Maintainer field)";
1050     return $authline;
1051 }
1052
1053 sub generate_commit_from_dsc () {
1054     prep_ud();
1055     changedir $ud;
1056
1057     foreach my $fi (dsc_files_info()) {
1058         my $f = $fi->{Filename};
1059         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1060
1061         link "../../../$f", $f
1062             or $!==&ENOENT
1063             or die "$f $!";
1064
1065         complete_file_from_dsc('.', $fi);
1066
1067         if (is_orig_file($f)) {
1068             link $f, "../../../../$f"
1069                 or $!==&EEXIST
1070                 or die "$f $!";
1071         }
1072     }
1073
1074     my $dscfn = "$package.dsc";
1075
1076     open D, ">", $dscfn or die "$dscfn: $!";
1077     print D $dscdata or die "$dscfn: $!";
1078     close D or die "$dscfn: $!";
1079     my @cmd = qw(dpkg-source);
1080     push @cmd, '--no-check' if $dsc_checked;
1081     push @cmd, qw(-x --), $dscfn;
1082     runcmd @cmd;
1083
1084     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1085     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1086     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1087     my $authline = clogp_authline $clogp;
1088     my $changes = getfield $clogp, 'Changes';
1089     open C, ">../commit.tmp" or die $!;
1090     print C <<END or die $!;
1091 tree $tree
1092 author $authline
1093 committer $authline
1094
1095 $changes
1096
1097 # imported from the archive
1098 END
1099     close C or die $!;
1100     my $outputhash = make_commit qw(../commit.tmp);
1101     my $cversion = getfield $clogp, 'Version';
1102     progress "synthesised git commit from .dsc $cversion";
1103     if ($lastpush_hash) {
1104         runcmd @git, qw(reset --hard), $lastpush_hash;
1105         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1106         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1107         my $oversion = getfield $oldclogp, 'Version';
1108         my $vcmp =
1109             version_compare($oversion, $cversion);
1110         if ($vcmp < 0) {
1111             # git upload/ is earlier vsn than archive, use archive
1112             open C, ">../commit2.tmp" or die $!;
1113             print C <<END or die $!;
1114 tree $tree
1115 parent $lastpush_hash
1116 parent $outputhash
1117 author $authline
1118 committer $authline
1119
1120 Record $package ($cversion) in archive suite $csuite
1121 END
1122             $outputhash = make_commit qw(../commit2.tmp);
1123         } elsif ($vcmp > 0) {
1124             print STDERR <<END or die $!;
1125
1126 Version actually in archive:    $cversion (older)
1127 Last allegedly pushed/uploaded: $oversion (newer or same)
1128 $later_warning_msg
1129 END
1130             $outputhash = $lastpush_hash;
1131         } else {
1132             $outputhash = $lastpush_hash;
1133         }
1134     }
1135     changedir '../../../..';
1136     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1137             'DGIT_ARCHIVE', $outputhash;
1138     cmdoutput @git, qw(log -n2), $outputhash;
1139     # ... gives git a chance to complain if our commit is malformed
1140     rmtree($ud);
1141     return $outputhash;
1142 }
1143
1144 sub complete_file_from_dsc ($$) {
1145     our ($dstdir, $fi) = @_;
1146     # Ensures that we have, in $dir, the file $fi, with the correct
1147     # contents.  (Downloading it from alongside $dscurl if necessary.)
1148
1149     my $f = $fi->{Filename};
1150     my $tf = "$dstdir/$f";
1151     my $downloaded = 0;
1152
1153     if (stat_exists $tf) {
1154         progress "using existing $f";
1155     } else {
1156         my $furl = $dscurl;
1157         $furl =~ s{/[^/]+$}{};
1158         $furl .= "/$f";
1159         die "$f ?" unless $f =~ m/^${package}_/;
1160         die "$f ?" if $f =~ m#/#;
1161         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1162         next if !act_local();
1163         $downloaded = 1;
1164     }
1165
1166     open F, "<", "$tf" or die "$tf: $!";
1167     $fi->{Digester}->reset();
1168     $fi->{Digester}->addfile(*F);
1169     F->error and die $!;
1170     my $got = $fi->{Digester}->hexdigest();
1171     $got eq $fi->{Hash} or
1172         fail "file $f has hash $got but .dsc".
1173             " demands hash $fi->{Hash} ".
1174             ($downloaded ? "(got wrong file from archive!)"
1175              : "(perhaps you should delete this file?)");
1176 }
1177
1178 sub ensure_we_have_orig () {
1179     foreach my $fi (dsc_files_info()) {
1180         my $f = $fi->{Filename};
1181         next unless is_orig_file($f);
1182         complete_file_from_dsc('..', $fi);
1183     }
1184 }
1185
1186 sub rev_parse ($) {
1187     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1188 }
1189
1190 sub is_fast_fwd ($$) {
1191     my ($ancestor,$child) = @_;
1192     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1193     my $mb = cmdoutput_errok @cmd;
1194     if (defined $mb) {
1195         return rev_parse($mb) eq rev_parse($ancestor);
1196     } else {
1197         $?==256 or failedcmd @cmd;
1198         return 0;
1199     }
1200 }
1201
1202 sub git_fetch_us () {
1203     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1204 }
1205
1206 sub fetch_from_archive () {
1207     # ensures that lrref() is what is actually in the archive,
1208     #  one way or another
1209     get_archive_dsc();
1210
1211     if ($dsc) {
1212         foreach my $field (@ourdscfield) {
1213             $dsc_hash = $dsc->{$field};
1214             last if defined $dsc_hash;
1215         }
1216         if (defined $dsc_hash) {
1217             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1218             $dsc_hash = $&;
1219             progress "last upload to archive specified git hash";
1220         } else {
1221             progress "last upload to archive has NO git hash";
1222         }
1223     } else {
1224         progress "no version available from the archive";
1225     }
1226
1227     $lastpush_hash = git_get_ref(lrref());
1228     printdebug "previous reference hash=$lastpush_hash\n";
1229     my $hash;
1230     if (defined $dsc_hash) {
1231         fail "missing remote git history even though dsc has hash -".
1232             " could not find ref ".lrref().
1233             " (should have been fetched from ".access_giturl()."#".rrref().")"
1234             unless $lastpush_hash;
1235         $hash = $dsc_hash;
1236         ensure_we_have_orig();
1237         if ($dsc_hash eq $lastpush_hash) {
1238         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1239             print STDERR <<END or die $!;
1240
1241 Git commit in archive is behind the last version allegedly pushed/uploaded.
1242 Commit referred to by archive:  $dsc_hash
1243 Last allegedly pushed/uploaded: $lastpush_hash
1244 $later_warning_msg
1245 END
1246             $hash = $lastpush_hash;
1247         } else {
1248             fail "archive's .dsc refers to ".$dsc_hash.
1249                 " but this is an ancestor of ".$lastpush_hash;
1250         }
1251     } elsif ($dsc) {
1252         $hash = generate_commit_from_dsc();
1253     } elsif ($lastpush_hash) {
1254         # only in git, not in the archive yet
1255         $hash = $lastpush_hash;
1256         print STDERR <<END or die $!;
1257
1258 Package not found in the archive, but has allegedly been pushed using dgit.
1259 $later_warning_msg
1260 END
1261     } else {
1262         printdebug "nothing found!\n";
1263         if (defined $skew_warning_vsn) {
1264             print STDERR <<END or die $!;
1265
1266 Warning: relevant archive skew detected.
1267 Archive allegedly contains $skew_warning_vsn
1268 But we were not able to obtain any version from the archive or git.
1269
1270 END
1271         }
1272         return 0;
1273     }
1274     printdebug "current hash=$hash\n";
1275     if ($lastpush_hash) {
1276         fail "not fast forward on last upload branch!".
1277             " (archive's version left in DGIT_ARCHIVE)"
1278             unless is_fast_fwd($lastpush_hash, $hash);
1279     }
1280     if (defined $skew_warning_vsn) {
1281         mkpath '.git/dgit';
1282         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1283         my $clogf = ".git/dgit/changelog.tmp";
1284         runcmd shell_cmd "exec >$clogf",
1285             @git, qw(cat-file blob), "$hash:debian/changelog";
1286         my $gotclogp = parsechangelog("-l$clogf");
1287         my $got_vsn = getfield $gotclogp, 'Version';
1288         printdebug "SKEW CHECK GOT $got_vsn\n";
1289         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1290             print STDERR <<END or die $!;
1291
1292 Warning: archive skew detected.  Using the available version:
1293 Archive allegedly contains    $skew_warning_vsn
1294 We were able to obtain only   $got_vsn
1295
1296 END
1297         }
1298     }
1299     if ($lastpush_hash ne $hash) {
1300         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1301         if (act_local()) {
1302             cmdoutput @upd_cmd;
1303         } else {
1304             dryrun_report @upd_cmd;
1305         }
1306     }
1307     return 1;
1308 }
1309
1310 sub clone ($) {
1311     my ($dstdir) = @_;
1312     canonicalise_suite();
1313     badusage "dry run makes no sense with clone" unless act_local();
1314     mkdir $dstdir or die "$dstdir $!";
1315     changedir $dstdir;
1316     runcmd @git, qw(init -q);
1317     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1318     open H, "> .git/HEAD" or die $!;
1319     print H "ref: ".lref()."\n" or die $!;
1320     close H or die $!;
1321     runcmd @git, qw(remote add), 'origin', access_giturl();
1322     if (check_for_git()) {
1323         progress "fetching existing git history";
1324         git_fetch_us();
1325         runcmd_ordryrun_local @git, qw(fetch origin);
1326     } else {
1327         progress "starting new git history";
1328     }
1329     fetch_from_archive() or no_such_package;
1330     my $vcsgiturl = $dsc->{'Vcs-Git'};
1331     if (length $vcsgiturl) {
1332         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1333     }
1334     runcmd @git, qw(reset --hard), lrref();
1335     printdone "ready for work in $dstdir";
1336 }
1337
1338 sub fetch () {
1339     if (check_for_git()) {
1340         git_fetch_us();
1341     }
1342     fetch_from_archive() or no_such_package();
1343     printdone "fetched into ".lrref();
1344 }
1345
1346 sub pull () {
1347     fetch();
1348     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1349         lrref();
1350     printdone "fetched to ".lrref()." and merged into HEAD";
1351 }
1352
1353 sub check_not_dirty () {
1354     return if $ignoredirty;
1355     my @cmd = (@git, qw(diff --quiet HEAD));
1356     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1357     $!=0; $?=0; system @cmd;
1358     return if !$! && !$?;
1359     if (!$! && $?==256) {
1360         fail "working tree is dirty (does not match HEAD)";
1361     } else {
1362         failedcmd @cmd;
1363     }
1364 }
1365
1366 sub commit_quilty_patch () {
1367     my $output = cmdoutput @git, qw(status --porcelain);
1368     my %adds;
1369     foreach my $l (split /\n/, $output) {
1370         next unless $l =~ m/\S/;
1371         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1372             $adds{$1}++;
1373         }
1374     }
1375     if (!%adds) {
1376         progress "nothing quilty to commit, ok.";
1377         return;
1378     }
1379     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1380     my $m = "Commit Debian 3.0 (quilt) metadata";
1381     progress "$m";
1382     runcmd_ordryrun_local @git, qw(commit -m), $m;
1383 }
1384
1385 sub madformat ($) {
1386     my ($format) = @_;
1387     return 0 unless $format eq '3.0 (quilt)';
1388     progress "Format \`$format', urgh";
1389     if ($noquilt) {
1390         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1391         return 0;
1392     }
1393     return 1;
1394 }
1395
1396 sub push_parse_changelog ($) {
1397     my ($clogpfn) = @_;
1398
1399     my $clogp = Dpkg::Control::Hash->new();
1400     $clogp->load($clogpfn) or die;
1401
1402     $package = getfield $clogp, 'Source';
1403     my $cversion = getfield $clogp, 'Version';
1404     my $tag = debiantag($cversion);
1405     runcmd @git, qw(check-ref-format), $tag;
1406
1407     my $dscfn = dscfn($cversion);
1408
1409     return ($clogp, $cversion, $tag, $dscfn);
1410 }
1411
1412 sub push_parse_dsc ($$$) {
1413     my ($dscfn,$dscfnwhat, $cversion) = @_;
1414     $dsc = parsecontrol($dscfn,$dscfnwhat);
1415     my $dversion = getfield $dsc, 'Version';
1416     my $dscpackage = getfield $dsc, 'Source';
1417     ($dscpackage eq $package && $dversion eq $cversion) or
1418         fail "$dscfn is for $dscpackage $dversion".
1419             " but debian/changelog is for $package $cversion";
1420 }
1421
1422 sub push_mktag ($$$$$$$) {
1423     my ($head,$clogp,$tag,
1424         $dscfn,
1425         $changesfile,$changesfilewhat,
1426         $tfn) = @_;
1427
1428     $dsc->{$ourdscfield[0]} = $head;
1429     $dsc->save("$dscfn.tmp") or die $!;
1430
1431     my $changes = parsecontrol($changesfile,$changesfilewhat);
1432     foreach my $field (qw(Source Distribution Version)) {
1433         $changes->{$field} eq $clogp->{$field} or
1434             fail "changes field $field \`$changes->{$field}'".
1435                 " does not match changelog \`$clogp->{$field}'";
1436     }
1437
1438     my $cversion = getfield $clogp, 'Version';
1439     my $clogsuite = getfield $clogp, 'Distribution';
1440
1441     # We make the git tag by hand because (a) that makes it easier
1442     # to control the "tagger" (b) we can do remote signing
1443     my $authline = clogp_authline $clogp;
1444     open TO, '>', $tfn->('.tmp') or die $!;
1445     print TO <<END or die $!;
1446 object $head
1447 type commit
1448 tag $tag
1449 tagger $authline
1450
1451 $package release $cversion for $clogsuite ($csuite) [dgit]
1452 END
1453     close TO or die $!;
1454
1455     my $tagobjfn = $tfn->('.tmp');
1456     if ($sign) {
1457         if (!defined $keyid) {
1458             $keyid = access_cfg('keyid','RETURN-UNDEF');
1459         }
1460         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1461         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1462         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1463         push @sign_cmd, $tfn->('.tmp');
1464         runcmd_ordryrun @sign_cmd;
1465         if (act_scary()) {
1466             $tagobjfn = $tfn->('.signed.tmp');
1467             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1468                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1469         }
1470     }
1471
1472     return ($tagobjfn);
1473 }
1474
1475 sub sign_changes ($) {
1476     my ($changesfile) = @_;
1477     if ($sign) {
1478         my @debsign_cmd = @debsign;
1479         push @debsign_cmd, "-k$keyid" if defined $keyid;
1480         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1481         push @debsign_cmd, $changesfile;
1482         runcmd_ordryrun @debsign_cmd;
1483     }
1484 }
1485
1486 sub dopush () {
1487     printdebug "actually entering push\n";
1488     prep_ud();
1489
1490     access_giturl(); # check that success is vaguely likely
1491
1492     my $clogpfn = ".git/dgit/changelog.822.tmp";
1493     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1494
1495     responder_send_file('parsed-changelog', $clogpfn);
1496
1497     my ($clogp, $cversion, $tag, $dscfn) =
1498         push_parse_changelog("$clogpfn");
1499
1500     my $dscpath = "$buildproductsdir/$dscfn";
1501     stat_exists $dscpath or
1502         fail "looked for .dsc $dscfn, but $!;".
1503             " maybe you forgot to build";
1504
1505     responder_send_file('dsc', $dscpath);
1506
1507     push_parse_dsc($dscpath, $dscfn, $cversion);
1508
1509     my $format = getfield $dsc, 'Format';
1510     printdebug "format $format\n";
1511     if (madformat($format)) {
1512         commit_quilty_patch();
1513     }
1514     check_not_dirty();
1515     changedir $ud;
1516     progress "checking that $dscfn corresponds to HEAD";
1517     runcmd qw(dpkg-source -x --),
1518         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1519     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1520     changedir '../../../..';
1521     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1522     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1523     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1524     $!=0; $?=0;
1525     my $r = system @diffcmd;
1526     if ($r) {
1527         if ($r==256) {
1528             fail "$dscfn specifies a different tree to your HEAD commit;".
1529                 " perhaps you forgot to build".
1530                 ($diffopt eq '--exit-code' ? "" :
1531                  " (run with -D to see full diff output)");
1532         } else {
1533             failedcmd @diffcmd;
1534         }
1535     }
1536 #fetch from alioth
1537 #do fast forward check and maybe fake merge
1538 #    if (!is_fast_fwd(mainbranch
1539 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1540 #        map { lref($_).":".rref($_) }
1541 #        (uploadbranch());
1542     my $head = rev_parse('HEAD');
1543     if (!$changesfile) {
1544         my $multi = "$buildproductsdir/".
1545             "${package}_".(stripepoch $cversion)."_multi.changes";
1546         if (stat_exists "$multi") {
1547             $changesfile = $multi;
1548         } else {
1549             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1550             my @cs = glob "$buildproductsdir/$pat";
1551             fail "failed to find unique changes file".
1552                 " (looked for $pat in $buildproductsdir, or $multi);".
1553                 " perhaps you need to use dgit -C"
1554                 unless @cs==1;
1555             ($changesfile) = @cs;
1556         }
1557     } else {
1558         $changesfile = "$buildproductsdir/$changesfile";
1559     }
1560
1561     responder_send_file('changes',$changesfile);
1562     responder_send_command("param head $head");
1563     responder_send_command("param csuite $csuite");
1564
1565     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1566     my $tagobjfn;
1567
1568     if ($we_are_responder) {
1569         $tagobjfn = $tfn->('.signed.tmp');
1570         responder_receive_files('signed-tag', $tagobjfn);
1571     } else {
1572         $tagobjfn =
1573             push_mktag($head,$clogp,$tag,
1574                        $dscpath,
1575                        $changesfile,$changesfile,
1576                        $tfn);
1577     }
1578
1579     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1580     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1581     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1582     runcmd_ordryrun @git, qw(tag -v --), $tag;
1583
1584     if (!check_for_git()) {
1585         create_remote_git_repo();
1586     }
1587     runcmd_ordryrun @git, qw(push),access_giturl(),
1588         "HEAD:".rrref(), "refs/tags/$tag";
1589     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1590
1591     if ($we_are_responder) {
1592         my $dryrunsuffix = act_local() ? "" : ".tmp";
1593         responder_receive_files('signed-dsc-changes',
1594                                 "$dscpath$dryrunsuffix",
1595                                 "$changesfile$dryrunsuffix");
1596     } else {
1597         if (act_local()) {
1598             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1599         } else {
1600             progress "[new .dsc left in $dscpath.tmp]";
1601         }
1602         sign_changes $changesfile;
1603     }
1604
1605     my $host = access_cfg('upload-host','RETURN-UNDEF');
1606     my @hostarg = defined($host) ? ($host,) : ();
1607     runcmd_ordryrun @dput, @hostarg, $changesfile;
1608     printdone "pushed and uploaded $cversion";
1609
1610     responder_send_command("complete");
1611 }
1612
1613 sub cmd_clone {
1614     parseopts();
1615     my $dstdir;
1616     badusage "-p is not allowed with clone; specify as argument instead"
1617         if defined $package;
1618     if (@ARGV==1) {
1619         ($package) = @ARGV;
1620     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1621         ($package,$isuite) = @ARGV;
1622     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1623         ($package,$dstdir) = @ARGV;
1624     } elsif (@ARGV==3) {
1625         ($package,$isuite,$dstdir) = @ARGV;
1626     } else {
1627         badusage "incorrect arguments to dgit clone";
1628     }
1629     $dstdir ||= "$package";
1630
1631     if (stat_exists $dstdir) {
1632         fail "$dstdir already exists";
1633     }
1634
1635     my $cwd_remove;
1636     if ($rmonerror && !$dryrun_level) {
1637         $cwd_remove= getcwd();
1638         unshift @end, sub {
1639             return unless defined $cwd_remove;
1640             if (!chdir "$cwd_remove") {
1641                 return if $!==&ENOENT;
1642                 die "chdir $cwd_remove: $!";
1643             }
1644             rmtree($dstdir) or die "remove $dstdir: $!\n";
1645         };
1646     }
1647
1648     clone($dstdir);
1649     $cwd_remove = undef;
1650 }
1651
1652 sub branchsuite () {
1653     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1654     if ($branch =~ m#$lbranch_re#o) {
1655         return $1;
1656     } else {
1657         return undef;
1658     }
1659 }
1660
1661 sub fetchpullargs () {
1662     if (!defined $package) {
1663         my $sourcep = parsecontrol('debian/control','debian/control');
1664         $package = getfield $sourcep, 'Source';
1665     }
1666     if (@ARGV==0) {
1667 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1668         if (!$isuite) {
1669             my $clogp = parsechangelog();
1670             $isuite = getfield $clogp, 'Distribution';
1671         }
1672         canonicalise_suite();
1673         progress "fetching from suite $csuite";
1674     } elsif (@ARGV==1) {
1675         ($isuite) = @ARGV;
1676         canonicalise_suite();
1677     } else {
1678         badusage "incorrect arguments to dgit fetch or dgit pull";
1679     }
1680 }
1681
1682 sub cmd_fetch {
1683     parseopts();
1684     fetchpullargs();
1685     fetch();
1686 }
1687
1688 sub cmd_pull {
1689     parseopts();
1690     fetchpullargs();
1691     pull();
1692 }
1693
1694 sub cmd_push {
1695     parseopts();
1696     badusage "-p is not allowed with dgit push" if defined $package;
1697     check_not_dirty();
1698     my $clogp = parsechangelog();
1699     $package = getfield $clogp, 'Source';
1700     my $specsuite;
1701     if (@ARGV==0) {
1702     } elsif (@ARGV==1) {
1703         ($specsuite) = (@ARGV);
1704     } else {
1705         badusage "incorrect arguments to dgit push";
1706     }
1707     $isuite = getfield $clogp, 'Distribution';
1708     if ($new_package) {
1709         local ($package) = $existing_package; # this is a hack
1710         canonicalise_suite();
1711     }
1712     if (defined $specsuite && $specsuite ne $isuite) {
1713         canonicalise_suite();
1714         $csuite eq $specsuite or
1715             fail "dgit push: changelog specifies $isuite ($csuite)".
1716                 " but command line specifies $specsuite";
1717     }
1718     if (check_for_git()) {
1719         git_fetch_us();
1720     }
1721     if (fetch_from_archive()) {
1722         is_fast_fwd(lrref(), 'HEAD') or
1723             fail "dgit push: HEAD is not a descendant".
1724                 " of the archive's version.\n".
1725                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1726     } else {
1727         $new_package or
1728             fail "package appears to be new in this suite;".
1729                 " if this is intentional, use --new";
1730     }
1731     dopush();
1732 }
1733
1734 #---------- remote commands' implementation ----------
1735
1736 sub cmd_remote_push_build_host {
1737     my ($nrargs) = shift @ARGV;
1738     my (@rargs) = @ARGV[0..$nrargs-1];
1739     @ARGV = @ARGV[$nrargs..$#ARGV];
1740     die unless @rargs;
1741     my ($dir,$vsnwant) = @rargs;
1742     # vsnwant is a comma-separated list; we report which we have
1743     # chosen in our ready response (so other end can tell if they
1744     # offered several)
1745     $debugprefix = ' ';
1746     $we_are_responder = 1;
1747
1748     open PI, "<&STDIN" or die $!;
1749     open STDIN, "/dev/null" or die $!;
1750     open PO, ">&STDOUT" or die $!;
1751     autoflush PO 1;
1752     open STDOUT, ">&STDERR" or die $!;
1753     autoflush STDOUT 1;
1754
1755     $vsnwant //= 1;
1756     fail "build host has dgit rpush protocol version".
1757         " $rpushprotovsn but invocation host has $vsnwant"
1758         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1759
1760     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1761
1762     changedir $dir;
1763     &cmd_push;
1764 }
1765
1766 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1767 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1768 #     a good error message)
1769
1770 our $i_tmp;
1771
1772 sub i_cleanup {
1773     local ($@, $?);
1774     my $report = i_child_report();
1775     if (defined $report) {
1776         printdebug "($report)\n";
1777     } elsif ($i_child_pid) {
1778         printdebug "(killing build host child $i_child_pid)\n";
1779         kill 15, $i_child_pid;
1780     }
1781     if (defined $i_tmp && !defined $initiator_tempdir) {
1782         changedir "/";
1783         eval { rmtree $i_tmp; };
1784     }
1785 }
1786
1787 END { i_cleanup(); }
1788
1789 sub i_method {
1790     my ($base,$selector,@args) = @_;
1791     $selector =~ s/\-/_/g;
1792     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1793 }
1794
1795 sub cmd_rpush {
1796     my $host = nextarg;
1797     my $dir;
1798     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1799         $host = $1;
1800         $dir = $'; #';
1801     } else {
1802         $dir = nextarg;
1803     }
1804     $dir =~ s{^-}{./-};
1805     my @rargs = ($dir,$rpushprotovsn);
1806     my @rdgit;
1807     push @rdgit, @dgit;
1808     push @rdgit, @ropts;
1809     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1810     push @rdgit, @ARGV;
1811     my @cmd = (@ssh, $host, shellquote @rdgit);
1812     printcmd \*DEBUG,$debugprefix."+",@cmd;
1813
1814     if (defined $initiator_tempdir) {
1815         rmtree $initiator_tempdir;
1816         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1817         $i_tmp = $initiator_tempdir;
1818     } else {
1819         $i_tmp = tempdir();
1820     }
1821     $i_child_pid = open2(\*RO, \*RI, @cmd);
1822     changedir $i_tmp;
1823     initiator_expect { m/^dgit-remote-push-ready/ };
1824     for (;;) {
1825         my ($icmd,$iargs) = initiator_expect {
1826             m/^(\S+)(?: (.*))?$/;
1827             ($1,$2);
1828         };
1829         i_method "i_resp", $icmd, $iargs;
1830     }
1831 }
1832
1833 sub i_resp_progress ($) {
1834     my ($rhs) = @_;
1835     my $msg = protocol_read_bytes \*RO, $rhs;
1836     progress $msg;
1837 }
1838
1839 sub i_resp_complete {
1840     my $pid = $i_child_pid;
1841     $i_child_pid = undef; # prevents killing some other process with same pid
1842     printdebug "waiting for build host child $pid...\n";
1843     my $got = waitpid $pid, 0;
1844     die $! unless $got == $pid;
1845     die "build host child failed $?" if $?;
1846
1847     i_cleanup();
1848     printdebug "all done\n";
1849     exit 0;
1850 }
1851
1852 sub i_resp_file ($) {
1853     my ($keyword) = @_;
1854     my $localname = i_method "i_localname", $keyword;
1855     my $localpath = "$i_tmp/$localname";
1856     stat_exists $localpath and
1857         badproto \*RO, "file $keyword ($localpath) twice";
1858     protocol_receive_file \*RO, $localpath;
1859     i_method "i_file", $keyword;
1860 }
1861
1862 our %i_param;
1863
1864 sub i_resp_param ($) {
1865     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1866     $i_param{$1} = $2;
1867 }
1868
1869 our %i_wanted;
1870
1871 sub i_resp_want ($) {
1872     my ($keyword) = @_;
1873     die "$keyword ?" if $i_wanted{$keyword}++;
1874     my @localpaths = i_method "i_want", $keyword;
1875     printdebug "[[  $keyword @localpaths\n";
1876     foreach my $localpath (@localpaths) {
1877         protocol_send_file \*RI, $localpath;
1878     }
1879     print RI "files-end\n" or die $!;
1880 }
1881
1882 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1883
1884 sub i_localname_parsed_changelog {
1885     return "remote-changelog.822";
1886 }
1887 sub i_file_parsed_changelog {
1888     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1889         push_parse_changelog "$i_tmp/remote-changelog.822";
1890     die if $i_dscfn =~ m#/|^\W#;
1891 }
1892
1893 sub i_localname_dsc {
1894     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1895     return $i_dscfn;
1896 }
1897 sub i_file_dsc { }
1898
1899 sub i_localname_changes {
1900     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1901     $i_changesfn = $i_dscfn;
1902     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1903     return $i_changesfn;
1904 }
1905 sub i_file_changes { }
1906
1907 sub i_want_signed_tag {
1908     printdebug Dumper(\%i_param, $i_dscfn);
1909     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1910         && defined $i_param{'csuite'}
1911         or badproto \*RO, "premature desire for signed-tag";
1912     my $head = $i_param{'head'};
1913     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1914
1915     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1916     $csuite = $&;
1917     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1918
1919     my $tagobjfn =
1920         push_mktag $head, $i_clogp, $i_tag,
1921             $i_dscfn,
1922             $i_changesfn, 'remote changes',
1923             sub { "tag$_[0]"; };
1924
1925     return $tagobjfn;
1926 }
1927
1928 sub i_want_signed_dsc_changes {
1929     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
1930     sign_changes $i_changesfn;
1931     return ($i_dscfn, $i_changesfn);
1932 }
1933
1934 #---------- building etc. ----------
1935
1936 our $version;
1937 our $sourcechanges;
1938 our $dscfn;
1939
1940 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
1941
1942 sub build_maybe_quilt_fixup () {
1943     if (!open F, "debian/source/format") {
1944         die $! unless $!==&ENOENT;
1945         return;
1946     }
1947     $_ = <F>;
1948     F->error and die $!;
1949     chomp;
1950     return unless madformat($_);
1951     # sigh
1952
1953     my @cmd = (@git, qw(ls-files --exclude-standard -iodm));
1954     my $problems = cmdoutput @cmd;
1955     if (length $problems) {
1956         print STDERR "problematic files:\n";
1957         print STDERR "  $_\n" foreach split /\n/, $problems;
1958         fail "Cannot do quilt fixup in tree containing ignored files.  ".
1959             "Perhaps your package's clean target is broken, in which".
1960             " case -wg (which says to use git-clean -xdf) may help.";
1961     }
1962
1963     my $clogp = parsechangelog();
1964     my $version = getfield $clogp, 'Version';
1965     my $author = getfield $clogp, 'Maintainer';
1966     my $headref = rev_parse('HEAD');
1967     my $time = time;
1968     my $ncommits = 3;
1969     my $patchname = "auto-$version-$headref-$time";
1970     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
1971     mkpath '.git/dgit';
1972     my $descfn = ".git/dgit/quilt-description.tmp";
1973     open O, '>', $descfn or die "$descfn: $!";
1974     $msg =~ s/\n/\n /g;
1975     $msg =~ s/^\s+$/ ./mg;
1976     print O <<END or die $!;
1977 Description: Automatically generated patch ($clogp->{Version})
1978  Last (up to) $ncommits git changes, FYI:
1979  .
1980  $msg
1981 Author: $author
1982
1983 ---
1984
1985 END
1986     close O or die $!;
1987     {
1988         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
1989         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
1990         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
1991         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
1992     }
1993
1994     if (!open P, '>>', ".pc/applied-patches") {
1995         $!==&ENOENT or die $!;
1996     } else {
1997         close P;
1998     }
1999
2000     commit_quilty_patch();
2001 }
2002
2003 sub quilt_fixup_editor () {
2004     my $descfn = $ENV{$fakeeditorenv};
2005     my $editing = $ARGV[$#ARGV];
2006     open I1, '<', $descfn or die "$descfn: $!";
2007     open I2, '<', $editing or die "$editing: $!";
2008     unlink $editing or die "$editing: $!";
2009     open O, '>', $editing or die "$editing: $!";
2010     while (<I1>) { print O or die $!; } I1->error and die $!;
2011     my $copying = 0;
2012     while (<I2>) {
2013         $copying ||= m/^\-\-\- /;
2014         next unless $copying;
2015         print O or die $!;
2016     }
2017     I2->error and die $!;
2018     close O or die $1;
2019     exit 0;
2020 }
2021
2022 sub clean_tree () {
2023     if ($cleanmode eq 'dpkg-source') {
2024         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2025     } elsif ($cleanmode eq 'git') {
2026         runcmd_ordryrun_local @git, qw(clean -xdf);
2027     } elsif ($cleanmode eq 'none') {
2028     } else {
2029         die "$cleanmode ?";
2030     }
2031 }
2032
2033 sub cmd_clean () {
2034     badusage "clean takes no additional arguments" if @ARGV;
2035     clean_tree();
2036 }
2037
2038 sub build_prep () {
2039     badusage "-p is not allowed when building" if defined $package;
2040     check_not_dirty();
2041     clean_tree();
2042     my $clogp = parsechangelog();
2043     $isuite = getfield $clogp, 'Distribution';
2044     $package = getfield $clogp, 'Source';
2045     $version = getfield $clogp, 'Version';
2046     build_maybe_quilt_fixup();
2047 }
2048
2049 sub changesopts () {
2050     my @opts =@changesopts[1..$#changesopts];
2051     if (!defined $changes_since_version) {
2052         my @vsns = archive_query('archive_query');
2053         my @quirk = access_quirk();
2054         if ($quirk[0] eq 'backports') {
2055             local $isuite = $quirk[2];
2056             local $csuite;
2057             canonicalise_suite();
2058             push @vsns, archive_query('archive_query');
2059         }
2060         if (@vsns) {
2061             @vsns = map { $_->[0] } @vsns;
2062             @vsns = sort { -version_compare($a, $b) } @vsns;
2063             $changes_since_version = $vsns[0];
2064             progress "changelog will contain changes since $vsns[0]";
2065         } else {
2066             $changes_since_version = '_';
2067             progress "package seems new, not specifying -v<version>";
2068         }
2069     }
2070     if ($changes_since_version ne '_') {
2071         unshift @opts, "-v$changes_since_version";
2072     }
2073     return @opts;
2074 }
2075
2076 sub cmd_build {
2077     build_prep();
2078     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2079     printdone "build successful\n";
2080 }
2081
2082 sub cmd_git_build {
2083     build_prep();
2084     my @cmd =
2085         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2086          "--git-builder=@dpkgbuildpackage");
2087     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2088         canonicalise_suite();
2089         push @cmd, "--git-debian-branch=".lbranch();
2090     }
2091     push @cmd, changesopts();
2092     runcmd_ordryrun_local @cmd, @ARGV;
2093     printdone "build successful\n";
2094 }
2095
2096 sub build_source {
2097     build_prep();
2098     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2099     $dscfn = dscfn($version);
2100     if ($cleanmode eq 'dpkg-source') {
2101         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2102             changesopts();
2103     } else {
2104         my $pwd = must_getcwd();
2105         my $leafdir = basename $pwd;
2106         changedir "..";
2107         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2108         changedir $pwd;
2109         runcmd_ordryrun_local qw(sh -ec),
2110             'exec >$1; shift; exec "$@"','x',
2111             "../$sourcechanges",
2112             @dpkggenchanges, qw(-S), changesopts();
2113     }
2114 }
2115
2116 sub cmd_build_source {
2117     badusage "build-source takes no additional arguments" if @ARGV;
2118     build_source();
2119     printdone "source built, results in $dscfn and $sourcechanges";
2120 }
2121
2122 sub cmd_sbuild {
2123     build_source();
2124     changedir "..";
2125     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2126     if (act_local()) {
2127         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2128         stat_exists $sourcechanges
2129             or fail "$sourcechanges (in parent directory): $!";
2130         foreach my $cf (glob $pat) {
2131             next if $cf eq $sourcechanges;
2132             unlink $cf or fail "remove $cf: $!";
2133         }
2134     }
2135     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2136     my @changesfiles = glob $pat;
2137     @changesfiles = sort {
2138         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2139             or $a cmp $b
2140     } @changesfiles;
2141     fail "wrong number of different changes files (@changesfiles)"
2142         unless @changesfiles;
2143     runcmd_ordryrun_local @mergechanges, @changesfiles;
2144     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2145     if (act_local()) {
2146         stat_exists $multichanges or fail "$multichanges: $!";
2147     }
2148     printdone "build successful, results in $multichanges\n" or die $!;
2149 }
2150
2151 sub cmd_quilt_fixup {
2152     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2153     my $clogp = parsechangelog();
2154     $version = getfield $clogp, 'Version';
2155     build_maybe_quilt_fixup();
2156 }
2157
2158 #---------- argument parsing and main program ----------
2159
2160 sub cmd_version {
2161     print "dgit version $our_version\n" or die $!;
2162     exit 0;
2163 }
2164
2165 sub parseopts () {
2166     my $om;
2167
2168     if (defined $ENV{'DGIT_SSH'}) {
2169         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2170     } elsif (defined $ENV{'GIT_SSH'}) {
2171         @ssh = ($ENV{'GIT_SSH'});
2172     }
2173
2174     while (@ARGV) {
2175         last unless $ARGV[0] =~ m/^-/;
2176         $_ = shift @ARGV;
2177         last if m/^--?$/;
2178         if (m/^--/) {
2179             if (m/^--dry-run$/) {
2180                 push @ropts, $_;
2181                 $dryrun_level=2;
2182             } elsif (m/^--damp-run$/) {
2183                 push @ropts, $_;
2184                 $dryrun_level=1;
2185             } elsif (m/^--no-sign$/) {
2186                 push @ropts, $_;
2187                 $sign=0;
2188             } elsif (m/^--help$/) {
2189                 cmd_help();
2190             } elsif (m/^--version$/) {
2191                 cmd_version();
2192             } elsif (m/^--new$/) {
2193                 push @ropts, $_;
2194                 $new_package=1;
2195             } elsif (m/^--since-version=([^_]+|_)$/) {
2196                 push @ropts, $_;
2197                 $changes_since_version = $1;
2198             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2199                      ($om = $opts_opt_map{$1}) &&
2200                      length $om->[0]) {
2201                 push @ropts, $_;
2202                 $om->[0] = $2;
2203             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2204                      !$opts_opt_cmdonly{$1} &&
2205                      ($om = $opts_opt_map{$1})) {
2206                 push @ropts, $_;
2207                 push @$om, $2;
2208             } elsif (m/^--existing-package=(.*)/s) {
2209                 push @ropts, $_;
2210                 $existing_package = $1;
2211             } elsif (m/^--initiator-tempdir=(.*)/s) {
2212                 $initiator_tempdir = $1;
2213                 $initiator_tempdir =~ m#^/# or
2214                     badusage "--initiator-tempdir must be used specify an".
2215                         " absolute, not relative, directory."
2216             } elsif (m/^--distro=(.*)/s) {
2217                 push @ropts, $_;
2218                 $idistro = $1;
2219             } elsif (m/^--build-products-dir=(.*)/s) {
2220                 push @ropts, $_;
2221                 $buildproductsdir = $1;
2222             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2223                 push @ropts, $_;
2224                 $cleanmode = $1;
2225             } elsif (m/^--clean=(.*)$/s) {
2226                 badusage "unknown cleaning mode \`$1'";
2227             } elsif (m/^--ignore-dirty$/s) {
2228                 push @ropts, $_;
2229                 $ignoredirty = 1;
2230             } elsif (m/^--no-quilt-fixup$/s) {
2231                 push @ropts, $_;
2232                 $noquilt = 1;
2233             } elsif (m/^--no-rm-on-error$/s) {
2234                 push @ropts, $_;
2235                 $rmonerror = 0;
2236             } else {
2237                 badusage "unknown long option \`$_'";
2238             }
2239         } else {
2240             while (m/^-./s) {
2241                 if (s/^-n/-/) {
2242                     push @ropts, $&;
2243                     $dryrun_level=2;
2244                 } elsif (s/^-L/-/) {
2245                     push @ropts, $&;
2246                     $dryrun_level=1;
2247                 } elsif (s/^-h/-/) {
2248                     cmd_help();
2249                 } elsif (s/^-D/-/) {
2250                     push @ropts, $&;
2251                     open DEBUG, ">&STDERR" or die $!;
2252                     autoflush DEBUG 1;
2253                     $debug++;
2254                 } elsif (s/^-N/-/) {
2255                     push @ropts, $&;
2256                     $new_package=1;
2257                 } elsif (s/^-v([^_]+|_)$//s) {
2258                     push @ropts, $&;
2259                     $changes_since_version = $1;
2260                 } elsif (m/^-m/) {
2261                     push @ropts, $&;
2262                     push @changesopts, $_;
2263                     $_ = '';
2264                 } elsif (s/^-c(.*=.*)//s) {
2265                     push @ropts, $&;
2266                     push @git, '-c', $1;
2267                 } elsif (s/^-d(.*)//s) {
2268                     push @ropts, $&;
2269                     $idistro = $1;
2270                 } elsif (s/^-C(.*)//s) {
2271                     push @ropts, $&;
2272                     $changesfile = $1;
2273                     if ($changesfile =~ s#^(.*)/##) {
2274                         $buildproductsdir = $1;
2275                     }
2276                 } elsif (s/^-k(.*)//s) {
2277                     $keyid=$1;
2278                 } elsif (s/^-wn//s) {
2279                     push @ropts, $&;
2280                     $cleanmode = 'none';
2281                 } elsif (s/^-wg//s) {
2282                     push @ropts, $&;
2283                     $cleanmode = 'git';
2284                 } elsif (s/^-wd//s) {
2285                     push @ropts, $&;
2286                     $cleanmode = 'dpkg-source';
2287                 } else {
2288                     badusage "unknown short option \`$_'";
2289                 }
2290             }
2291         }
2292     }
2293 }
2294
2295 if ($ENV{$fakeeditorenv}) {
2296     quilt_fixup_editor();
2297 }
2298
2299 parseopts();
2300 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2301 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2302     if $dryrun_level == 1;
2303 if (!@ARGV) {
2304     print STDERR $helpmsg or die $!;
2305     exit 8;
2306 }
2307 my $cmd = shift @ARGV;
2308 $cmd =~ y/-/_/;
2309
2310 my $fn = ${*::}{"cmd_$cmd"};
2311 $fn or badusage "unknown operation $cmd";
2312 $fn->();