dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Config;
  34
  35 our $our_version = 'UNRELEASED'; ###substituted###
  36
  37 our $rpushprotovsn = 2;
  38
  39 our $isuite = 'unstable';
  40 our $idistro;
  41 our $package;
  42 our @ropts;
  43
  44 our $sign = 1;
  45 our $dryrun_level = 0;
  46 our $changesfile;
  47 our $buildproductsdir = '..';
  48 our $new_package = 0;
  49 our $ignoredirty = 0;
  50 our $noquilt = 0;
  51 our $rmonerror = 1;
  52 our $existing_package = 'dpkg';
  53 our $cleanmode = 'dpkg-source';
  54 our $changes_since_version;
  55 our $we_are_responder;
  56 our $initiator_tempdir;
  57
  58 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  59
  60 our $suite_re = '[-+.0-9a-z]+';
  61
  62 our (@git) = qw(git);
  63 our (@dget) = qw(dget);
  64 our (@curl) = qw(curl -f);
  65 our (@dput) = qw(dput);
  66 our (@debsign) = qw(debsign);
  67 our (@gpg) = qw(gpg);
  68 our (@sbuild) = qw(sbuild -A);
  69 our (@ssh) = 'ssh';
  70 our (@dgit) = qw(dgit);
  71 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  72 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  73 our (@dpkggenchanges) = qw(dpkg-genchanges);
  74 our (@mergechanges) = qw(mergechanges -f);
  75 our (@changesopts) = ('');
  76
  77 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  78                      'curl' => \@curl,
  79                      'dput' => \@dput,
  80                      'debsign' => \@debsign,
  81                      'gpg' => \@gpg,
  82                      'sbuild' => \@sbuild,
  83                      'ssh' => \@ssh,
  84                      'dgit' => \@dgit,
  85                      'dpkg-source' => \@dpkgsource,
  86                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  87                      'dpkg-genchanges' => \@dpkggenchanges,
  88                      'ch' => \@changesopts,
  89                      'mergechanges' => \@mergechanges);
  90
  91 our %opts_opt_cmdonly = ('gpg' => 1);
  92
  93 our $keyid;
  94
  95 our $debug = 0;
  96 open DEBUG, ">/dev/null" or die $!;
  97
  98 autoflush STDOUT 1;
  99
 100 our $remotename = 'dgit';
 101 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 102 our $branchprefix = 'dgit';
 103 our $csuite;
 104
 105 sub lbranch () { return "$branchprefix/$csuite"; }
 106 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 107 sub lref () { return "refs/heads/".lbranch(); }
 108 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 109 sub rrref () { return "refs/$branchprefix/$csuite"; }
 110 sub debiantag ($) {
 111     my ($v) = @_;
 112     $v =~ y/~:/_%/;
 113     return "debian/$v";
 114 }
 115
 116 sub stripepoch ($) {
 117     my ($vsn) = @_;
 118     $vsn =~ s/^\d+\://;
 119     return $vsn;
 120 }
 121
 122 sub dscfn ($) {
 123     my ($vsn) = @_;
 124     return "${package}_".(stripepoch $vsn).".dsc";
 125 }
 126
 127 our $us = 'dgit';
 128 our $debugprefix = '';
 129
 130 our @end;
 131 END {
 132     local ($?);
 133     foreach my $f (@end) {
 134         eval { $f->(); };
 135         warn "$us: cleanup: $@" if length $@;
 136     }
 137 };
 138
 139 our @signames = split / /, $Config{sig_name};
 140
 141 sub waitstatusmsg () {
 142     if (!$?) {
 143         return "terminated, reporting successful completion";
 144     } elsif (!($? & 255)) {
 145         return "failed with error exit status ".WEXITSTATUS($?);
 146     } elsif (WIFSIGNALED($?)) {
 147         my $signum=WTERMSIG($?);
 148         return "died due to fatal signal ".
 149             ($signames[$signum] // "number $signum").
 150             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 151     } else {
 152         return "failed with unknown wait status ".$?;
 153     }
 154 }
 155
 156 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 157
 158 sub fail {
 159     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 160 }
 161
 162 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 163
 164 sub no_such_package () {
 165     print STDERR "$us: package $package does not exist in suite $isuite\n";
 166     exit 4;
 167 }
 168
 169 sub fetchspec () {
 170     local $csuite = '*';
 171     return  "+".rrref().":".lrref();
 172 }
 173
 174 sub changedir ($) {
 175     my ($newdir) = @_;
 176     printdebug "CD $newdir\n";
 177     chdir $newdir or die "chdir: $newdir: $!";
 178 }
 179
 180 sub stat_exists ($) {
 181     my ($f) = @_;
 182     return 1 if stat $f;
 183     return 0 if $!==&ENOENT;
 184     die "stat $f: $!";
 185 }
 186
 187 #---------- remote protocol support, common ----------
 188
 189 # remote push initiator/responder protocol:
 190 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 191 #
 192 #  > file parsed-changelog
 193 #  [indicates that output of dpkg-parsechangelog follows]
 194 #  > data-block NBYTES
 195 #  > [NBYTES bytes of data (no newline)]
 196 #  [maybe some more blocks]
 197 #  > data-end
 198 #
 199 #  > file dsc
 200 #  [etc]
 201 #
 202 #  > file changes
 203 #  [etc]
 204 #
 205 #  > param head HEAD
 206 #
 207 #  > want signed-tag
 208 #  [indicates that signed tag is wanted]
 209 #  < data-block NBYTES
 210 #  < [NBYTES bytes of data (no newline)]
 211 #  [maybe some more blocks]
 212 #  < data-end
 213 #  < files-end
 214 #
 215 #  > want signed-dsc-changes
 216 #  < data-block NBYTES    [transfer of signed dsc]
 217 #  [etc]
 218 #  < data-block NBYTES    [transfer of signed changes]
 219 #  [etc]
 220 #  < files-end
 221 #
 222 #  > complete
 223
 224 our $i_child_pid;
 225
 226 sub i_child_report () {
 227     # Sees if our child has died, and reap it if so.  Returns a string
 228     # describing how it died if it failed, or undef otherwise.
 229     return undef unless $i_child_pid;
 230     my $got = waitpid $i_child_pid, WNOHANG;
 231     return undef if $got <= 0;
 232     die unless $got == $i_child_pid;
 233     $i_child_pid = undef;
 234     return undef unless $?;
 235     return "build host child ".waitstatusmsg();
 236 }
 237
 238 sub badproto ($$) {
 239     my ($fh, $m) = @_;
 240     fail "connection lost: $!" if $fh->error;
 241     fail "protocol violation; $m not expected";
 242 }
 243
 244 sub badproto_badread ($$) {
 245     my ($fh, $wh) = @_;
 246     fail "connection lost: $!" if $!;
 247     my $report = i_child_report();
 248     fail $report if defined $report;
 249     badproto $fh, "eof (reading $wh)";
 250 }
 251
 252 sub protocol_expect (&$) {
 253     my ($match, $fh) = @_;
 254     local $_;
 255     $_ = <$fh>;
 256     defined && chomp or badproto_badread $fh, "protocol message";
 257     if (wantarray) {
 258         my @r = &$match;
 259         return @r if @r;
 260     } else {
 261         my $r = &$match;
 262         return $r if $r;
 263     }
 264     badproto $fh, "\`$_'";
 265 }
 266
 267 sub protocol_send_file ($$) {
 268     my ($fh, $ourfn) = @_;
 269     open PF, "<", $ourfn or die "$ourfn: $!";
 270     for (;;) {
 271         my $d;
 272         my $got = read PF, $d, 65536;
 273         die "$ourfn: $!" unless defined $got;
 274         last if !$got;
 275         print $fh "data-block ".length($d)."\n" or die $!;
 276         print $fh $d or die $!;
 277     }
 278     PF->error and die "$ourfn $!";
 279     print $fh "data-end\n" or die $!;
 280     close PF;
 281 }
 282
 283 sub protocol_read_bytes ($$) {
 284     my ($fh, $nbytes) = @_;
 285     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 286     my $d;
 287     my $got = read $fh, $d, $nbytes;
 288     $got==$nbytes or badproto_badread $fh, "data block";
 289     return $d;
 290 }
 291
 292 sub protocol_receive_file ($$) {
 293     my ($fh, $ourfn) = @_;
 294     printdebug "() $ourfn\n";
 295     open PF, ">", $ourfn or die "$ourfn: $!";
 296     for (;;) {
 297         my ($y,$l) = protocol_expect {
 298             m/^data-block (.*)$/ ? (1,$1) :
 299             m/^data-end$/ ? (0,) :
 300             ();
 301         } $fh;
 302         last unless $y;
 303         my $d = protocol_read_bytes $fh, $l;
 304         print PF $d or die $!;
 305     }
 306     close PF or die $!;
 307 }
 308
 309 #---------- remote protocol support, responder ----------
 310
 311 sub responder_send_command ($) {
 312     my ($command) = @_;
 313     return unless $we_are_responder;
 314     # called even without $we_are_responder
 315     printdebug ">> $command\n";
 316     print PO $command, "\n" or die $!;
 317 }
 318
 319 sub responder_send_file ($$) {
 320     my ($keyword, $ourfn) = @_;
 321     return unless $we_are_responder;
 322     printdebug "]] $keyword $ourfn\n";
 323     responder_send_command "file $keyword";
 324     protocol_send_file \*PO, $ourfn;
 325 }
 326
 327 sub responder_receive_files ($@) {
 328     my ($keyword, @ourfns) = @_;
 329     die unless $we_are_responder;
 330     printdebug "[[ $keyword @ourfns\n";
 331     responder_send_command "want $keyword";
 332     foreach my $fn (@ourfns) {
 333         protocol_receive_file \*PI, $fn;
 334     }
 335     printdebug "[[\$\n";
 336     protocol_expect { m/^files-end$/ } \*PI;
 337 }
 338
 339 #---------- remote protocol support, initiator ----------
 340
 341 sub initiator_expect (&) {
 342     my ($match) = @_;
 343     protocol_expect { &$match } \*RO;
 344 }
 345
 346 #---------- end remote code ----------
 347
 348 sub progress {
 349     if ($we_are_responder) {
 350         my $m = join '', @_;
 351         responder_send_command "progress ".length($m) or die $!;
 352         print PO $m or die $!;
 353     } else {
 354         print @_, "\n";
 355     }
 356 }
 357
 358 our $ua;
 359
 360 sub url_get {
 361     if (!$ua) {
 362         $ua = LWP::UserAgent->new();
 363         $ua->env_proxy;
 364     }
 365     my $what = $_[$#_];
 366     progress "downloading $what...";
 367     my $r = $ua->get(@_) or die $!;
 368     return undef if $r->code == 404;
 369     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 370     return $r->decoded_content(charset => 'none');
 371 }
 372
 373 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 374
 375 sub shellquote {
 376     my @out;
 377     local $_;
 378     foreach my $a (@_) {
 379         $_ = $a;
 380         if (m{[^-=_./0-9a-z]}i) {
 381             s{['\\]}{'\\$&'}g;
 382             push @out, "'$_'";
 383         } else {
 384             push @out, $_;
 385         }
 386     }
 387     return join ' ', @out;
 388 }
 389
 390 sub printcmd {
 391     my $fh = shift @_;
 392     my $intro = shift @_;
 393     print $fh $intro," " or die $!;
 394     print $fh shellquote @_ or die $!;
 395     print $fh "\n" or die $!;
 396 }
 397
 398 sub failedcmd {
 399     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 400     if ($!) {
 401         fail "failed to fork/exec: $!";
 402     } elsif ($?) {
 403         fail "subprocess ".waitstatusmsg();
 404     } else {
 405         fail "subprocess produced invalid output";
 406     }
 407 }
 408
 409 sub runcmd {
 410     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 411     $!=0; $?=0;
 412     failedcmd @_ if system @_;
 413 }
 414
 415 sub act_local () { return $dryrun_level <= 1; }
 416 sub act_scary () { return !$dryrun_level; }
 417
 418 sub printdone {
 419     if (!$dryrun_level) {
 420         progress "dgit ok: @_";
 421     } else {
 422         progress "would be ok: @_ (but dry run only)";
 423     }
 424 }
 425
 426 sub cmdoutput_errok {
 427     die Dumper(\@_)." ?" if grep { !defined } @_;
 428     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 429     open P, "-|", @_ or die $!;
 430     my $d;
 431     $!=0; $?=0;
 432     { local $/ = undef; $d = <P>; }
 433     die $! if P->error;
 434     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 435     chomp $d;
 436     $d =~ m/^.*/;
 437     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 438     return $d;
 439 }
 440
 441 sub cmdoutput {
 442     my $d = cmdoutput_errok @_;
 443     defined $d or failedcmd @_;
 444     return $d;
 445 }
 446
 447 sub dryrun_report {
 448     printcmd(\*STDERR,$debugprefix."#",@_);
 449 }
 450
 451 sub runcmd_ordryrun {
 452     if (act_scary()) {
 453         runcmd @_;
 454     } else {
 455         dryrun_report @_;
 456     }
 457 }
 458
 459 sub runcmd_ordryrun_local {
 460     if (act_local()) {
 461         runcmd @_;
 462     } else {
 463         dryrun_report @_;
 464     }
 465 }
 466
 467 sub shell_cmd {
 468     my ($first_shell, @cmd) = @_;
 469     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 470 }
 471
 472 our $helpmsg = <<END;
 473 main usages:
 474   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 475   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 476   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 477   dgit [dgit-opts] push [dgit-opts] [suite]
 478   dgit [dgit-opts] rpush build-host:build-dir ...
 479 important dgit options:
 480   -k<keyid>           sign tag and package with <keyid> instead of default
 481   --dry-run -n        do not change anything, but go through the motions
 482   --damp-run -L       like --dry-run but make local changes, without signing
 483   --new -N            allow introducing a new package
 484   --debug -D          increase debug level
 485   -c<name>=<value>    set git config option (used directly by dgit too)
 486 END
 487
 488 our $later_warning_msg = <<END;
 489 Perhaps the upload is stuck in incoming.  Using the version from git.
 490 END
 491
 492 sub badusage {
 493     print STDERR "$us: @_\n", $helpmsg or die $!;
 494     exit 8;
 495 }
 496
 497 sub nextarg {
 498     @ARGV or badusage "too few arguments";
 499     return scalar shift @ARGV;
 500 }
 501
 502 sub cmd_help () {
 503     print $helpmsg or die $!;
 504     exit 0;
 505 }
 506
 507 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 508
 509 our %defcfg = ('dgit.default.distro' => 'debian',
 510                'dgit.default.username' => '',
 511                'dgit.default.archive-query-default-component' => 'main',
 512                'dgit.default.ssh' => 'ssh',
 513                'dgit-distro.debian.git-host' => 'git.debian.org',
 514                'dgit-distro.debian.git-proto' => 'git+ssh://',
 515                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 516                'dgit-distro.debian.git-check' => 'ssh-cmd',
 517                'dgit-distro.debian.git-create' => 'ssh-cmd',
 518                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 519                'dgit-distro.debian.sshpsql-dbname' => 'service=projectb',
 520                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 521                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 522  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 523  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 524                'dgit-distro.ubuntu.git-check' => 'false',
 525  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 526                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 527                'dgit-distro.test-dummy.username' => "alice",
 528                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 529                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 530                'dgit-distro.test-dummy.git-url' => "$td/git",
 531                'dgit-distro.test-dummy.git-host' => "git",
 532                'dgit-distro.test-dummy.git-path' => "$td/git",
 533                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 534                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 535                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 536                );
 537
 538 sub cfg {
 539     foreach my $c (@_) {
 540         return undef if $c =~ /RETURN-UNDEF/;
 541         my @cmd = (@git, qw(config --), $c);
 542         my $v;
 543         {
 544             local ($debug) = $debug-1;
 545             $v = cmdoutput_errok @cmd;
 546         };
 547         if ($?==0) {
 548             return $v;
 549         } elsif ($?!=256) {
 550             failedcmd @cmd;
 551         }
 552         my $dv = $defcfg{$c};
 553         return $dv if defined $dv;
 554     }
 555     badcfg "need value for one of: @_\n".
 556         "$us: distro or suite appears not to be (properly) supported";
 557 }
 558
 559 sub access_basedistro () {
 560     if (defined $idistro) {
 561         return cfg("dgit-distro.basedistro.distro",
 562                    "dgit-suite.$isuite.distro",
 563                    'RETURN-UNDEF') // $idistro;
 564     } else {
 565         return cfg("dgit-suite.$isuite.distro",
 566                    "dgit.default.distro");
 567     }
 568 }
 569
 570 sub access_quirk () {
 571     # returns (quirk name, distro to use instead, quirk-specific info)
 572     my $basedistro = access_basedistro();
 573     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 574                               'RETURN-UNDEF');
 575     if (defined $backports_quirk) {
 576         my $re = $backports_quirk;
 577         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 578         $re =~ s/\*/.*/g;
 579         $re =~ s/\%/([-0-9a-z_]+)/
 580             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 581         if ($isuite =~ m/^$re$/) {
 582             return ('backports',"$basedistro-backports",$1);
 583         }
 584     }
 585     return ('none',$basedistro);
 586 }
 587
 588 sub access_distro () {
 589     return (access_quirk())[1];
 590 }
 591
 592 sub access_cfg (@) {
 593     my (@keys) = @_;
 594     my $basedistro = access_basedistro();
 595     my $distro = $idistro || access_distro();
 596     my $value = cfg(map {
 597         ("dgit-distro.$distro.$_",
 598          "dgit-distro.$basedistro.$_",
 599          "dgit.default.$_")
 600                     } @keys);
 601     return $value;
 602 }
 603
 604 sub string_to_ssh ($) {
 605     my ($spec) = @_;
 606     if ($spec =~ m/\s/) {
 607         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 608     } else {
 609         return ($spec);
 610     }
 611 }
 612
 613 sub access_cfg_ssh () {
 614     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 615     if (!defined $gitssh) {
 616         return @ssh;
 617     } else {
 618         return string_to_ssh $gitssh;
 619     }
 620 }
 621
 622 sub access_someuserhost ($) {
 623     my ($some) = @_;
 624     my $user = access_cfg("$some-user",'username');
 625     my $host = access_cfg("$some-host");
 626     return length($user) ? "$user\@$host" : $host;
 627 }
 628
 629 sub access_gituserhost () {
 630     return access_someuserhost('git');
 631 }
 632
 633 sub access_giturl () {
 634     my $url = access_cfg('git-url','RETURN-UNDEF');
 635     if (!defined $url) {
 636         $url =
 637             access_cfg('git-proto').
 638             access_gituserhost().
 639             access_cfg('git-path');
 640     }
 641     return "$url/$package.git";
 642 }
 643
 644 sub parsecontrolfh ($$;$) {
 645     my ($fh, $desc, $allowsigned) = @_;
 646     our $dpkgcontrolhash_noissigned;
 647     my $c;
 648     for (;;) {
 649         my %opts = ('name' => $desc);
 650         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 651         $c = Dpkg::Control::Hash->new(%opts);
 652         $c->parse($fh,$desc) or die "parsing of $desc failed";
 653         last if $allowsigned;
 654         last if $dpkgcontrolhash_noissigned;
 655         my $issigned= $c->get_option('is_pgp_signed');
 656         if (!defined $issigned) {
 657             $dpkgcontrolhash_noissigned= 1;
 658             seek $fh, 0,0 or die "seek $desc: $!";
 659         } elsif ($issigned) {
 660             fail "control file $desc is (already) PGP-signed. ".
 661                 " Note that dgit push needs to modify the .dsc and then".
 662                 " do the signature itself";
 663         } else {
 664             last;
 665         }
 666     }
 667     return $c;
 668 }
 669
 670 sub parsecontrol {
 671     my ($file, $desc) = @_;
 672     my $fh = new IO::Handle;
 673     open $fh, '<', $file or die "$file: $!";
 674     my $c = parsecontrolfh($fh,$desc);
 675     $fh->error and die $!;
 676     close $fh;
 677     return $c;
 678 }
 679
 680 sub getfield ($$) {
 681     my ($dctrl,$field) = @_;
 682     my $v = $dctrl->{$field};
 683     return $v if defined $v;
 684     fail "missing field $field in ".$v->get_option('name');
 685 }
 686
 687 sub parsechangelog {
 688     my $c = Dpkg::Control::Hash->new();
 689     my $p = new IO::Handle;
 690     my @cmd = (qw(dpkg-parsechangelog), @_);
 691     open $p, '-|', @cmd or die $!;
 692     $c->parse($p);
 693     $?=0; $!=0; close $p or failedcmd @cmd;
 694     return $c;
 695 }
 696
 697 sub git_get_ref ($) {
 698     my ($refname) = @_;
 699     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 700     if (!defined $got) {
 701         $?==256 or fail "git show-ref failed (status $?)";
 702         printdebug "ref $refname= [show-ref exited 1]\n";
 703         return '';
 704     }
 705     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 706         printdebug "ref $refname=$1\n";
 707         return $1;
 708     } else {
 709         printdebug "ref $refname= [no match]\n";
 710         return '';
 711     }
 712 }
 713
 714 sub must_getcwd () {
 715     my $d = getcwd();
 716     defined $d or fail "getcwd failed: $!";
 717     return $d;
 718 }
 719
 720 our %rmad;
 721
 722 sub archive_query ($) {
 723     my ($method) = @_;
 724     my $query = access_cfg('archive-query','RETURN-UNDEF');
 725     if (!defined $query) {
 726         my $distro = access_basedistro();
 727         if ($distro eq 'debian') {
 728             $query = "sshpsql:".
 729                 access_someuserhost('sshpsql').':'.
 730                 access_cfg('sshpsql-dbname');
 731         } else {
 732             $query = "madison:$distro";
 733         }
 734     }
 735     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 736     my $proto = $1;
 737     my $data = $'; #';
 738     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 739 }
 740
 741 sub pool_dsc_subpath ($$) {
 742     my ($vsn,$component) = @_; # $package is implict arg
 743     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 744     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 745 }
 746
 747 sub archive_query_madison ($$) {
 748     my ($proto,$data) = @_;
 749     die unless $proto eq 'madison';
 750     $rmad{$package} ||= cmdoutput
 751         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 752     my $rmad = $rmad{$package};
 753     return madison_parse($rmad);
 754 }
 755
 756 sub madison_parse ($) {
 757     my ($rmad) = @_;
 758     my @out;
 759     foreach my $l (split /\n/, $rmad) {
 760         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 761                   \s*( [^ \t|]+ )\s* \|
 762                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 763                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 764         $1 eq $package or die "$rmad $package ?";
 765         my $vsn = $2;
 766         my $newsuite = $3;
 767         my $component;
 768         if (defined $4) {
 769             $component = $4;
 770         } else {
 771             $component = access_cfg('archive-query-default-component');
 772         }
 773         $5 eq 'source' or die "$rmad ?";
 774         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 775     }
 776     return sort { -version_compare($a->[0],$b->[0]); } @out;
 777 }
 778
 779 sub canonicalise_suite_madison ($$) {
 780     # madison canonicalises for us
 781     my @r = archive_query_madison($_[0],$_[1]);
 782     @r or fail
 783         "unable to canonicalise suite using package $package".
 784         " which does not appear to exist in suite $isuite;".
 785         " --existing-package may help";
 786     return $r[0][2];
 787 }
 788
 789 sub sshpsql ($$) {
 790     my ($data,$sql) = @_;
 791     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 792     my ($userhost,$dbname) = ($`,$'); #';
 793     my @rows;
 794     my @cmd = (access_cfg_ssh, $userhost,
 795                "export LANG=C; ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 796     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 797     open P, "-|", @cmd or die $!;
 798     while (<P>) {
 799         chomp or die;
 800         printdebug("$debugprefix>|$_|\n");
 801         push @rows, $_;
 802     }
 803     $!=0; $?=0; close P or failedcmd @cmd;
 804     @rows or die;
 805     my $nrows = pop @rows;
 806     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 807     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 808     @rows = map { [ split /\|/, $_ ] } @rows;
 809     my $ncols = scalar @{ shift @rows };
 810     die if grep { scalar @$_ != $ncols } @rows;
 811     return @rows;
 812 }
 813
 814 sub sql_injection_check {
 815     foreach (@_) { die "$_ $& ?" if m/[']/; }
 816 }
 817
 818 sub archive_query_sshpsql ($$) {
 819     my ($proto,$data) = @_;
 820     sql_injection_check $isuite, $package;
 821     my @rows = sshpsql($data, <<END);
 822         SELECT source.version, component.name, files.filename, files.sha256sum
 823           FROM source
 824           JOIN src_associations ON source.id = src_associations.source
 825           JOIN suite ON suite.id = src_associations.suite
 826           JOIN dsc_files ON dsc_files.source = source.id
 827           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 828           JOIN component ON component.id = files_archive_map.component_id
 829           JOIN files ON files.id = dsc_files.file
 830          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 831            AND source.source='$package'
 832            AND files.filename LIKE '%.dsc';
 833 END
 834     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 835     my $digester = Digest::SHA->new(256);
 836     @rows = map {
 837         my ($vsn,$component,$filename,$sha256sum) = @$_;
 838         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 839     } @rows;
 840     return @rows;
 841 }
 842
 843 sub canonicalise_suite_sshpsql ($$) {
 844     my ($proto,$data) = @_;
 845     sql_injection_check $isuite;
 846     my @rows = sshpsql($data, <<END);
 847         SELECT suite.codename
 848           FROM suite where suite_name='$isuite' or codename='$isuite';
 849 END
 850     @rows = map { $_->[0] } @rows;
 851     fail "unknown suite $isuite" unless @rows;
 852     die "ambiguous $isuite: @rows ?" if @rows>1;
 853     return $rows[0];
 854 }
 855
 856 sub canonicalise_suite_dummycat ($$) {
 857     my ($proto,$data) = @_;
 858     my $dpath = "$data/suite.$isuite";
 859     if (!open C, "<", $dpath) {
 860         $!==ENOENT or die "$dpath: $!";
 861         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 862         return $isuite;
 863     }
 864     $!=0; $_ = <C>;
 865     chomp or die "$dpath: $!";
 866     close C;
 867     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 868     return $_;
 869 }
 870
 871 sub archive_query_dummycat ($$) {
 872     my ($proto,$data) = @_;
 873     canonicalise_suite();
 874     my $dpath = "$data/package.$csuite.$package";
 875     if (!open C, "<", $dpath) {
 876         $!==ENOENT or die "$dpath: $!";
 877         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 878         return ();
 879     }
 880     my @rows;
 881     while (<C>) {
 882         next if m/^\#/;
 883         next unless m/\S/;
 884         die unless chomp;
 885         printdebug "dummycat query $csuite $package $dpath | $_\n";
 886         my @row = split /\s+/, $_;
 887         @row==2 or die "$dpath: $_ ?";
 888         push @rows, \@row;
 889     }
 890     C->error and die "$dpath: $!";
 891     close C;
 892     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 893 }
 894
 895 sub canonicalise_suite () {
 896     return if defined $csuite;
 897     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 898     $csuite = archive_query('canonicalise_suite');
 899     if ($isuite ne $csuite) {
 900         progress "canonical suite name for $isuite is $csuite";
 901     }
 902 }
 903
 904 sub get_archive_dsc () {
 905     canonicalise_suite();
 906     my @vsns = archive_query('archive_query');
 907     foreach my $vinfo (@vsns) {
 908         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 909         $dscurl = access_cfg('mirror').$subpath;
 910         $dscdata = url_get($dscurl);
 911         if (!$dscdata) {
 912             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 913             next;
 914         }
 915         if ($digester) {
 916             $digester->reset();
 917             $digester->add($dscdata);
 918             my $got = $digester->hexdigest();
 919             $got eq $digest or
 920                 fail "$dscurl has hash $got but".
 921                     " archive told us to expect $digest";
 922         }
 923         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 924         printdebug Dumper($dscdata) if $debug>1;
 925         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 926         printdebug Dumper($dsc) if $debug>1;
 927         my $fmt = getfield $dsc, 'Format';
 928         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 929         $dsc_checked = !!$digester;
 930         return;
 931     }
 932     $dsc = undef;
 933 }
 934
 935 sub check_for_git () {
 936     # returns 0 or 1
 937     my $how = access_cfg('git-check');
 938     if ($how eq 'ssh-cmd') {
 939         my @cmd =
 940             (access_cfg_ssh, access_gituserhost(),
 941              " set -e; cd ".access_cfg('git-path').";".
 942              " if test -d $package.git; then echo 1; else echo 0; fi");
 943         my $r= cmdoutput @cmd;
 944         failedcmd @cmd unless $r =~ m/^[01]$/;
 945         return $r+0;
 946     } elsif ($how eq 'true') {
 947         return 1;
 948     } elsif ($how eq 'false') {
 949         return 0;
 950     } else {
 951         badcfg "unknown git-check \`$how'";
 952     }
 953 }
 954
 955 sub create_remote_git_repo () {
 956     my $how = access_cfg('git-create');
 957     if ($how eq 'ssh-cmd') {
 958         runcmd_ordryrun
 959             (access_cfg_ssh, access_gituserhost(),
 960              "set -e; cd ".access_cfg('git-path').";".
 961              " cp -a _template $package.git");
 962     } elsif ($how eq 'true') {
 963         # nothing to do
 964     } else {
 965         badcfg "unknown git-create \`$how'";
 966     }
 967 }
 968
 969 our ($dsc_hash,$lastpush_hash);
 970
 971 our $ud = '.git/dgit/unpack';
 972
 973 sub prep_ud () {
 974     rmtree($ud);
 975     mkpath '.git/dgit';
 976     mkdir $ud or die $!;
 977 }
 978
 979 sub mktree_in_ud_here () {
 980     runcmd qw(git init -q);
 981     rmtree('.git/objects');
 982     symlink '../../../../objects','.git/objects' or die $!;
 983 }
 984
 985 sub mktree_in_ud_from_only_subdir () {
 986     # changes into the subdir
 987     my (@dirs) = <*/.>;
 988     die unless @dirs==1;
 989     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 990     my $dir = $1;
 991     changedir $dir;
 992     fail "source package contains .git directory" if stat_exists '.git';
 993     mktree_in_ud_here();
 994     runcmd @git, qw(add -Af);
 995     my $tree = cmdoutput @git, qw(write-tree);
 996     $tree =~ m/^\w+$/ or die "$tree ?";
 997     return ($tree,$dir);
 998 }
 999
1000 sub dsc_files_info () {
1001     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1002                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1003                        ['Files',           'Digest::MD5', 'new()']) {
1004         my ($fname, $module, $method) = @$csumi;
1005         my $field = $dsc->{$fname};
1006         next unless defined $field;
1007         eval "use $module; 1;" or die $@;
1008         my @out;
1009         foreach (split /\n/, $field) {
1010             next unless m/\S/;
1011             m/^(\w+) (\d+) (\S+)$/ or
1012                 fail "could not parse .dsc $fname line \`$_'";
1013             my $digester = eval "$module"."->$method;" or die $@;
1014             push @out, {
1015                 Hash => $1,
1016                 Bytes => $2,
1017                 Filename => $3,
1018                 Digester => $digester,
1019             };
1020         }
1021         return @out;
1022     }
1023     fail "missing any supported Checksums-* or Files field in ".
1024         $dsc->get_option('name');
1025 }
1026
1027 sub dsc_files () {
1028     map { $_->{Filename} } dsc_files_info();
1029 }
1030
1031 sub is_orig_file ($;$) {
1032     local ($_) = $_[0];
1033     my $base = $_[1];
1034     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1035     defined $base or return 1;
1036     return $` eq $base;
1037 }
1038
1039 sub make_commit ($) {
1040     my ($file) = @_;
1041     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1042 }
1043
1044 sub clogp_authline ($) {
1045     my ($clogp) = @_;
1046     my $author = getfield $clogp, 'Maintainer';
1047     $author =~ s#,.*##ms;
1048     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1049     my $authline = "$author $date";
1050     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1051         fail "unexpected commit author line format \`$authline'".
1052         " (was generated from changelog Maintainer field)";
1053     return $authline;
1054 }
1055
1056 sub generate_commit_from_dsc () {
1057     prep_ud();
1058     changedir $ud;
1059
1060     foreach my $fi (dsc_files_info()) {
1061         my $f = $fi->{Filename};
1062         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1063
1064         link "../../../$f", $f
1065             or $!==&ENOENT
1066             or die "$f $!";
1067
1068         complete_file_from_dsc('.', $fi);
1069
1070         if (is_orig_file($f)) {
1071             link $f, "../../../../$f"
1072                 or $!==&EEXIST
1073                 or die "$f $!";
1074         }
1075     }
1076
1077     my $dscfn = "$package.dsc";
1078
1079     open D, ">", $dscfn or die "$dscfn: $!";
1080     print D $dscdata or die "$dscfn: $!";
1081     close D or die "$dscfn: $!";
1082     my @cmd = qw(dpkg-source);
1083     push @cmd, '--no-check' if $dsc_checked;
1084     push @cmd, qw(-x --), $dscfn;
1085     runcmd @cmd;
1086
1087     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1088     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1089     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1090     my $authline = clogp_authline $clogp;
1091     my $changes = getfield $clogp, 'Changes';
1092     open C, ">../commit.tmp" or die $!;
1093     print C <<END or die $!;
1094 tree $tree
1095 author $authline
1096 committer $authline
1097
1098 $changes
1099
1100 # imported from the archive
1101 END
1102     close C or die $!;
1103     my $outputhash = make_commit qw(../commit.tmp);
1104     my $cversion = getfield $clogp, 'Version';
1105     progress "synthesised git commit from .dsc $cversion";
1106     if ($lastpush_hash) {
1107         runcmd @git, qw(reset --hard), $lastpush_hash;
1108         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1109         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1110         my $oversion = getfield $oldclogp, 'Version';
1111         my $vcmp =
1112             version_compare($oversion, $cversion);
1113         if ($vcmp < 0) {
1114             # git upload/ is earlier vsn than archive, use archive
1115             open C, ">../commit2.tmp" or die $!;
1116             print C <<END or die $!;
1117 tree $tree
1118 parent $lastpush_hash
1119 parent $outputhash
1120 author $authline
1121 committer $authline
1122
1123 Record $package ($cversion) in archive suite $csuite
1124 END
1125             $outputhash = make_commit qw(../commit2.tmp);
1126         } elsif ($vcmp > 0) {
1127             print STDERR <<END or die $!;
1128
1129 Version actually in archive:    $cversion (older)
1130 Last allegedly pushed/uploaded: $oversion (newer or same)
1131 $later_warning_msg
1132 END
1133             $outputhash = $lastpush_hash;
1134         } else {
1135             $outputhash = $lastpush_hash;
1136         }
1137     }
1138     changedir '../../../..';
1139     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1140             'DGIT_ARCHIVE', $outputhash;
1141     cmdoutput @git, qw(log -n2), $outputhash;
1142     # ... gives git a chance to complain if our commit is malformed
1143     rmtree($ud);
1144     return $outputhash;
1145 }
1146
1147 sub complete_file_from_dsc ($$) {
1148     our ($dstdir, $fi) = @_;
1149     # Ensures that we have, in $dir, the file $fi, with the correct
1150     # contents.  (Downloading it from alongside $dscurl if necessary.)
1151
1152     my $f = $fi->{Filename};
1153     my $tf = "$dstdir/$f";
1154     my $downloaded = 0;
1155
1156     if (stat_exists $tf) {
1157         progress "using existing $f";
1158     } else {
1159         my $furl = $dscurl;
1160         $furl =~ s{/[^/]+$}{};
1161         $furl .= "/$f";
1162         die "$f ?" unless $f =~ m/^${package}_/;
1163         die "$f ?" if $f =~ m#/#;
1164         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1165         next if !act_local();
1166         $downloaded = 1;
1167     }
1168
1169     open F, "<", "$tf" or die "$tf: $!";
1170     $fi->{Digester}->reset();
1171     $fi->{Digester}->addfile(*F);
1172     F->error and die $!;
1173     my $got = $fi->{Digester}->hexdigest();
1174     $got eq $fi->{Hash} or
1175         fail "file $f has hash $got but .dsc".
1176             " demands hash $fi->{Hash} ".
1177             ($downloaded ? "(got wrong file from archive!)"
1178              : "(perhaps you should delete this file?)");
1179 }
1180
1181 sub ensure_we_have_orig () {
1182     foreach my $fi (dsc_files_info()) {
1183         my $f = $fi->{Filename};
1184         next unless is_orig_file($f);
1185         complete_file_from_dsc('..', $fi);
1186     }
1187 }
1188
1189 sub rev_parse ($) {
1190     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1191 }
1192
1193 sub is_fast_fwd ($$) {
1194     my ($ancestor,$child) = @_;
1195     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1196     my $mb = cmdoutput_errok @cmd;
1197     if (defined $mb) {
1198         return rev_parse($mb) eq rev_parse($ancestor);
1199     } else {
1200         $?==256 or failedcmd @cmd;
1201         return 0;
1202     }
1203 }
1204
1205 sub git_fetch_us () {
1206     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1207 }
1208
1209 sub fetch_from_archive () {
1210     # ensures that lrref() is what is actually in the archive,
1211     #  one way or another
1212     get_archive_dsc();
1213
1214     if ($dsc) {
1215         foreach my $field (@ourdscfield) {
1216             $dsc_hash = $dsc->{$field};
1217             last if defined $dsc_hash;
1218         }
1219         if (defined $dsc_hash) {
1220             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1221             $dsc_hash = $&;
1222             progress "last upload to archive specified git hash";
1223         } else {
1224             progress "last upload to archive has NO git hash";
1225         }
1226     } else {
1227         progress "no version available from the archive";
1228     }
1229
1230     $lastpush_hash = git_get_ref(lrref());
1231     printdebug "previous reference hash=$lastpush_hash\n";
1232     my $hash;
1233     if (defined $dsc_hash) {
1234         fail "missing remote git history even though dsc has hash -".
1235             " could not find ref ".lrref().
1236             " (should have been fetched from ".access_giturl()."#".rrref().")"
1237             unless $lastpush_hash;
1238         $hash = $dsc_hash;
1239         ensure_we_have_orig();
1240         if ($dsc_hash eq $lastpush_hash) {
1241         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1242             print STDERR <<END or die $!;
1243
1244 Git commit in archive is behind the last version allegedly pushed/uploaded.
1245 Commit referred to by archive:  $dsc_hash
1246 Last allegedly pushed/uploaded: $lastpush_hash
1247 $later_warning_msg
1248 END
1249             $hash = $lastpush_hash;
1250         } else {
1251             fail "archive's .dsc refers to ".$dsc_hash.
1252                 " but this is an ancestor of ".$lastpush_hash;
1253         }
1254     } elsif ($dsc) {
1255         $hash = generate_commit_from_dsc();
1256     } elsif ($lastpush_hash) {
1257         # only in git, not in the archive yet
1258         $hash = $lastpush_hash;
1259         print STDERR <<END or die $!;
1260
1261 Package not found in the archive, but has allegedly been pushed using dgit.
1262 $later_warning_msg
1263 END
1264     } else {
1265         printdebug "nothing found!\n";
1266         if (defined $skew_warning_vsn) {
1267             print STDERR <<END or die $!;
1268
1269 Warning: relevant archive skew detected.
1270 Archive allegedly contains $skew_warning_vsn
1271 But we were not able to obtain any version from the archive or git.
1272
1273 END
1274         }
1275         return 0;
1276     }
1277     printdebug "current hash=$hash\n";
1278     if ($lastpush_hash) {
1279         fail "not fast forward on last upload branch!".
1280             " (archive's version left in DGIT_ARCHIVE)"
1281             unless is_fast_fwd($lastpush_hash, $hash);
1282     }
1283     if (defined $skew_warning_vsn) {
1284         mkpath '.git/dgit';
1285         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1286         my $clogf = ".git/dgit/changelog.tmp";
1287         runcmd shell_cmd "exec >$clogf",
1288             @git, qw(cat-file blob), "$hash:debian/changelog";
1289         my $gotclogp = parsechangelog("-l$clogf");
1290         my $got_vsn = getfield $gotclogp, 'Version';
1291         printdebug "SKEW CHECK GOT $got_vsn\n";
1292         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1293             print STDERR <<END or die $!;
1294
1295 Warning: archive skew detected.  Using the available version:
1296 Archive allegedly contains    $skew_warning_vsn
1297 We were able to obtain only   $got_vsn
1298
1299 END
1300         }
1301     }
1302     if ($lastpush_hash ne $hash) {
1303         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1304         if (act_local()) {
1305             cmdoutput @upd_cmd;
1306         } else {
1307             dryrun_report @upd_cmd;
1308         }
1309     }
1310     return 1;
1311 }
1312
1313 sub clone ($) {
1314     my ($dstdir) = @_;
1315     canonicalise_suite();
1316     badusage "dry run makes no sense with clone" unless act_local();
1317     mkdir $dstdir or die "$dstdir $!";
1318     changedir $dstdir;
1319     runcmd @git, qw(init -q);
1320     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1321     open H, "> .git/HEAD" or die $!;
1322     print H "ref: ".lref()."\n" or die $!;
1323     close H or die $!;
1324     runcmd @git, qw(remote add), 'origin', access_giturl();
1325     if (check_for_git()) {
1326         progress "fetching existing git history";
1327         git_fetch_us();
1328         runcmd_ordryrun_local @git, qw(fetch origin);
1329     } else {
1330         progress "starting new git history";
1331     }
1332     fetch_from_archive() or no_such_package;
1333     my $vcsgiturl = $dsc->{'Vcs-Git'};
1334     if (length $vcsgiturl) {
1335         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1336     }
1337     runcmd @git, qw(reset --hard), lrref();
1338     printdone "ready for work in $dstdir";
1339 }
1340
1341 sub fetch () {
1342     if (check_for_git()) {
1343         git_fetch_us();
1344     }
1345     fetch_from_archive() or no_such_package();
1346     printdone "fetched into ".lrref();
1347 }
1348
1349 sub pull () {
1350     fetch();
1351     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1352         lrref();
1353     printdone "fetched to ".lrref()." and merged into HEAD";
1354 }
1355
1356 sub check_not_dirty () {
1357     return if $ignoredirty;
1358     my @cmd = (@git, qw(diff --quiet HEAD));
1359     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1360     $!=0; $?=0; system @cmd;
1361     return if !$! && !$?;
1362     if (!$! && $?==256) {
1363         fail "working tree is dirty (does not match HEAD)";
1364     } else {
1365         failedcmd @cmd;
1366     }
1367 }
1368
1369 sub commit_admin ($) {
1370     my ($m) = @_;
1371     progress "$m";
1372     runcmd_ordryrun_local @git, qw(commit -m), $m;
1373 }
1374
1375 sub commit_quilty_patch () {
1376     my $output = cmdoutput @git, qw(status --porcelain);
1377     my %adds;
1378     foreach my $l (split /\n/, $output) {
1379         next unless $l =~ m/\S/;
1380         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1381             $adds{$1}++;
1382         }
1383     }
1384     if (!%adds) {
1385         progress "nothing quilty to commit, ok.";
1386         return;
1387     }
1388     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1389     commit_admin "Commit Debian 3.0 (quilt) metadata";
1390 }
1391
1392 sub madformat ($) {
1393     my ($format) = @_;
1394     return 0 unless $format eq '3.0 (quilt)';
1395     progress "Format \`$format', urgh";
1396     if ($noquilt) {
1397         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1398         return 0;
1399     }
1400     return 1;
1401 }
1402
1403 sub push_parse_changelog ($) {
1404     my ($clogpfn) = @_;
1405
1406     my $clogp = Dpkg::Control::Hash->new();
1407     $clogp->load($clogpfn) or die;
1408
1409     $package = getfield $clogp, 'Source';
1410     my $cversion = getfield $clogp, 'Version';
1411     my $tag = debiantag($cversion);
1412     runcmd @git, qw(check-ref-format), $tag;
1413
1414     my $dscfn = dscfn($cversion);
1415
1416     return ($clogp, $cversion, $tag, $dscfn);
1417 }
1418
1419 sub push_parse_dsc ($$$) {
1420     my ($dscfn,$dscfnwhat, $cversion) = @_;
1421     $dsc = parsecontrol($dscfn,$dscfnwhat);
1422     my $dversion = getfield $dsc, 'Version';
1423     my $dscpackage = getfield $dsc, 'Source';
1424     ($dscpackage eq $package && $dversion eq $cversion) or
1425         fail "$dscfn is for $dscpackage $dversion".
1426             " but debian/changelog is for $package $cversion";
1427 }
1428
1429 sub push_mktag ($$$$$$$) {
1430     my ($head,$clogp,$tag,
1431         $dscfn,
1432         $changesfile,$changesfilewhat,
1433         $tfn) = @_;
1434
1435     $dsc->{$ourdscfield[0]} = $head;
1436     $dsc->save("$dscfn.tmp") or die $!;
1437
1438     my $changes = parsecontrol($changesfile,$changesfilewhat);
1439     foreach my $field (qw(Source Distribution Version)) {
1440         $changes->{$field} eq $clogp->{$field} or
1441             fail "changes field $field \`$changes->{$field}'".
1442                 " does not match changelog \`$clogp->{$field}'";
1443     }
1444
1445     my $cversion = getfield $clogp, 'Version';
1446     my $clogsuite = getfield $clogp, 'Distribution';
1447
1448     # We make the git tag by hand because (a) that makes it easier
1449     # to control the "tagger" (b) we can do remote signing
1450     my $authline = clogp_authline $clogp;
1451     open TO, '>', $tfn->('.tmp') or die $!;
1452     print TO <<END or die $!;
1453 object $head
1454 type commit
1455 tag $tag
1456 tagger $authline
1457
1458 $package release $cversion for $clogsuite ($csuite) [dgit]
1459 END
1460     close TO or die $!;
1461
1462     my $tagobjfn = $tfn->('.tmp');
1463     if ($sign) {
1464         if (!defined $keyid) {
1465             $keyid = access_cfg('keyid','RETURN-UNDEF');
1466         }
1467         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1468         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1469         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1470         push @sign_cmd, $tfn->('.tmp');
1471         runcmd_ordryrun @sign_cmd;
1472         if (act_scary()) {
1473             $tagobjfn = $tfn->('.signed.tmp');
1474             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1475                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1476         }
1477     }
1478
1479     return ($tagobjfn);
1480 }
1481
1482 sub sign_changes ($) {
1483     my ($changesfile) = @_;
1484     if ($sign) {
1485         my @debsign_cmd = @debsign;
1486         push @debsign_cmd, "-k$keyid" if defined $keyid;
1487         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1488         push @debsign_cmd, $changesfile;
1489         runcmd_ordryrun @debsign_cmd;
1490     }
1491 }
1492
1493 sub dopush () {
1494     printdebug "actually entering push\n";
1495     prep_ud();
1496
1497     access_giturl(); # check that success is vaguely likely
1498
1499     my $clogpfn = ".git/dgit/changelog.822.tmp";
1500     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1501
1502     responder_send_file('parsed-changelog', $clogpfn);
1503
1504     my ($clogp, $cversion, $tag, $dscfn) =
1505         push_parse_changelog("$clogpfn");
1506
1507     my $dscpath = "$buildproductsdir/$dscfn";
1508     stat_exists $dscpath or
1509         fail "looked for .dsc $dscfn, but $!;".
1510             " maybe you forgot to build";
1511
1512     responder_send_file('dsc', $dscpath);
1513
1514     push_parse_dsc($dscpath, $dscfn, $cversion);
1515
1516     my $format = getfield $dsc, 'Format';
1517     printdebug "format $format\n";
1518     if (madformat($format)) {
1519         commit_quilty_patch();
1520     }
1521     check_not_dirty();
1522     changedir $ud;
1523     progress "checking that $dscfn corresponds to HEAD";
1524     runcmd qw(dpkg-source -x --),
1525         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1526     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1527     changedir '../../../..';
1528     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1529     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1530     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1531     $!=0; $?=0;
1532     my $r = system @diffcmd;
1533     if ($r) {
1534         if ($r==256) {
1535             fail "$dscfn specifies a different tree to your HEAD commit;".
1536                 " perhaps you forgot to build".
1537                 ($diffopt eq '--exit-code' ? "" :
1538                  " (run with -D to see full diff output)");
1539         } else {
1540             failedcmd @diffcmd;
1541         }
1542     }
1543 #fetch from alioth
1544 #do fast forward check and maybe fake merge
1545 #    if (!is_fast_fwd(mainbranch
1546 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1547 #        map { lref($_).":".rref($_) }
1548 #        (uploadbranch());
1549     my $head = rev_parse('HEAD');
1550     if (!$changesfile) {
1551         my $multi = "$buildproductsdir/".
1552             "${package}_".(stripepoch $cversion)."_multi.changes";
1553         if (stat_exists "$multi") {
1554             $changesfile = $multi;
1555         } else {
1556             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1557             my @cs = glob "$buildproductsdir/$pat";
1558             fail "failed to find unique changes file".
1559                 " (looked for $pat in $buildproductsdir, or $multi);".
1560                 " perhaps you need to use dgit -C"
1561                 unless @cs==1;
1562             ($changesfile) = @cs;
1563         }
1564     } else {
1565         $changesfile = "$buildproductsdir/$changesfile";
1566     }
1567
1568     responder_send_file('changes',$changesfile);
1569     responder_send_command("param head $head");
1570     responder_send_command("param csuite $csuite");
1571
1572     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1573     my $tagobjfn;
1574
1575     if ($we_are_responder) {
1576         $tagobjfn = $tfn->('.signed.tmp');
1577         responder_receive_files('signed-tag', $tagobjfn);
1578     } else {
1579         $tagobjfn =
1580             push_mktag($head,$clogp,$tag,
1581                        $dscpath,
1582                        $changesfile,$changesfile,
1583                        $tfn);
1584     }
1585
1586     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1587     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1588     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1589     runcmd_ordryrun @git, qw(tag -v --), $tag;
1590
1591     if (!check_for_git()) {
1592         create_remote_git_repo();
1593     }
1594     runcmd_ordryrun @git, qw(push),access_giturl(),
1595         "HEAD:".rrref(), "refs/tags/$tag";
1596     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1597
1598     if ($we_are_responder) {
1599         my $dryrunsuffix = act_local() ? "" : ".tmp";
1600         responder_receive_files('signed-dsc-changes',
1601                                 "$dscpath$dryrunsuffix",
1602                                 "$changesfile$dryrunsuffix");
1603     } else {
1604         if (act_local()) {
1605             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1606         } else {
1607             progress "[new .dsc left in $dscpath.tmp]";
1608         }
1609         sign_changes $changesfile;
1610     }
1611
1612     my $host = access_cfg('upload-host','RETURN-UNDEF');
1613     my @hostarg = defined($host) ? ($host,) : ();
1614     runcmd_ordryrun @dput, @hostarg, $changesfile;
1615     printdone "pushed and uploaded $cversion";
1616
1617     responder_send_command("complete");
1618 }
1619
1620 sub cmd_clone {
1621     parseopts();
1622     my $dstdir;
1623     badusage "-p is not allowed with clone; specify as argument instead"
1624         if defined $package;
1625     if (@ARGV==1) {
1626         ($package) = @ARGV;
1627     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1628         ($package,$isuite) = @ARGV;
1629     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1630         ($package,$dstdir) = @ARGV;
1631     } elsif (@ARGV==3) {
1632         ($package,$isuite,$dstdir) = @ARGV;
1633     } else {
1634         badusage "incorrect arguments to dgit clone";
1635     }
1636     $dstdir ||= "$package";
1637
1638     if (stat_exists $dstdir) {
1639         fail "$dstdir already exists";
1640     }
1641
1642     my $cwd_remove;
1643     if ($rmonerror && !$dryrun_level) {
1644         $cwd_remove= getcwd();
1645         unshift @end, sub {
1646             return unless defined $cwd_remove;
1647             if (!chdir "$cwd_remove") {
1648                 return if $!==&ENOENT;
1649                 die "chdir $cwd_remove: $!";
1650             }
1651             rmtree($dstdir) or die "remove $dstdir: $!\n";
1652         };
1653     }
1654
1655     clone($dstdir);
1656     $cwd_remove = undef;
1657 }
1658
1659 sub branchsuite () {
1660     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1661     if ($branch =~ m#$lbranch_re#o) {
1662         return $1;
1663     } else {
1664         return undef;
1665     }
1666 }
1667
1668 sub fetchpullargs () {
1669     if (!defined $package) {
1670         my $sourcep = parsecontrol('debian/control','debian/control');
1671         $package = getfield $sourcep, 'Source';
1672     }
1673     if (@ARGV==0) {
1674 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1675         if (!$isuite) {
1676             my $clogp = parsechangelog();
1677             $isuite = getfield $clogp, 'Distribution';
1678         }
1679         canonicalise_suite();
1680         progress "fetching from suite $csuite";
1681     } elsif (@ARGV==1) {
1682         ($isuite) = @ARGV;
1683         canonicalise_suite();
1684     } else {
1685         badusage "incorrect arguments to dgit fetch or dgit pull";
1686     }
1687 }
1688
1689 sub cmd_fetch {
1690     parseopts();
1691     fetchpullargs();
1692     fetch();
1693 }
1694
1695 sub cmd_pull {
1696     parseopts();
1697     fetchpullargs();
1698     pull();
1699 }
1700
1701 sub cmd_push {
1702     parseopts();
1703     badusage "-p is not allowed with dgit push" if defined $package;
1704     check_not_dirty();
1705     my $clogp = parsechangelog();
1706     $package = getfield $clogp, 'Source';
1707     my $specsuite;
1708     if (@ARGV==0) {
1709     } elsif (@ARGV==1) {
1710         ($specsuite) = (@ARGV);
1711     } else {
1712         badusage "incorrect arguments to dgit push";
1713     }
1714     $isuite = getfield $clogp, 'Distribution';
1715     if ($new_package) {
1716         local ($package) = $existing_package; # this is a hack
1717         canonicalise_suite();
1718     }
1719     if (defined $specsuite && $specsuite ne $isuite) {
1720         canonicalise_suite();
1721         $csuite eq $specsuite or
1722             fail "dgit push: changelog specifies $isuite ($csuite)".
1723                 " but command line specifies $specsuite";
1724     }
1725     if (check_for_git()) {
1726         git_fetch_us();
1727     }
1728     if (fetch_from_archive()) {
1729         is_fast_fwd(lrref(), 'HEAD') or
1730             fail "dgit push: HEAD is not a descendant".
1731                 " of the archive's version.\n".
1732                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1733     } else {
1734         $new_package or
1735             fail "package appears to be new in this suite;".
1736                 " if this is intentional, use --new";
1737     }
1738     dopush();
1739 }
1740
1741 #---------- remote commands' implementation ----------
1742
1743 sub cmd_remote_push_build_host {
1744     my ($nrargs) = shift @ARGV;
1745     my (@rargs) = @ARGV[0..$nrargs-1];
1746     @ARGV = @ARGV[$nrargs..$#ARGV];
1747     die unless @rargs;
1748     my ($dir,$vsnwant) = @rargs;
1749     # vsnwant is a comma-separated list; we report which we have
1750     # chosen in our ready response (so other end can tell if they
1751     # offered several)
1752     $debugprefix = ' ';
1753     $we_are_responder = 1;
1754
1755     open PI, "<&STDIN" or die $!;
1756     open STDIN, "/dev/null" or die $!;
1757     open PO, ">&STDOUT" or die $!;
1758     autoflush PO 1;
1759     open STDOUT, ">&STDERR" or die $!;
1760     autoflush STDOUT 1;
1761
1762     $vsnwant //= 1;
1763     fail "build host has dgit rpush protocol version".
1764         " $rpushprotovsn but invocation host has $vsnwant"
1765         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1766
1767     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1768
1769     changedir $dir;
1770     &cmd_push;
1771 }
1772
1773 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1774 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1775 #     a good error message)
1776
1777 our $i_tmp;
1778
1779 sub i_cleanup {
1780     local ($@, $?);
1781     my $report = i_child_report();
1782     if (defined $report) {
1783         printdebug "($report)\n";
1784     } elsif ($i_child_pid) {
1785         printdebug "(killing build host child $i_child_pid)\n";
1786         kill 15, $i_child_pid;
1787     }
1788     if (defined $i_tmp && !defined $initiator_tempdir) {
1789         changedir "/";
1790         eval { rmtree $i_tmp; };
1791     }
1792 }
1793
1794 END { i_cleanup(); }
1795
1796 sub i_method {
1797     my ($base,$selector,@args) = @_;
1798     $selector =~ s/\-/_/g;
1799     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1800 }
1801
1802 sub cmd_rpush {
1803     my $host = nextarg;
1804     my $dir;
1805     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1806         $host = $1;
1807         $dir = $'; #';
1808     } else {
1809         $dir = nextarg;
1810     }
1811     $dir =~ s{^-}{./-};
1812     my @rargs = ($dir,$rpushprotovsn);
1813     my @rdgit;
1814     push @rdgit, @dgit;
1815     push @rdgit, @ropts;
1816     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1817     push @rdgit, @ARGV;
1818     my @cmd = (@ssh, $host, shellquote @rdgit);
1819     printcmd \*DEBUG,$debugprefix."+",@cmd;
1820
1821     if (defined $initiator_tempdir) {
1822         rmtree $initiator_tempdir;
1823         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1824         $i_tmp = $initiator_tempdir;
1825     } else {
1826         $i_tmp = tempdir();
1827     }
1828     $i_child_pid = open2(\*RO, \*RI, @cmd);
1829     changedir $i_tmp;
1830     initiator_expect { m/^dgit-remote-push-ready/ };
1831     for (;;) {
1832         my ($icmd,$iargs) = initiator_expect {
1833             m/^(\S+)(?: (.*))?$/;
1834             ($1,$2);
1835         };
1836         i_method "i_resp", $icmd, $iargs;
1837     }
1838 }
1839
1840 sub i_resp_progress ($) {
1841     my ($rhs) = @_;
1842     my $msg = protocol_read_bytes \*RO, $rhs;
1843     progress $msg;
1844 }
1845
1846 sub i_resp_complete {
1847     my $pid = $i_child_pid;
1848     $i_child_pid = undef; # prevents killing some other process with same pid
1849     printdebug "waiting for build host child $pid...\n";
1850     my $got = waitpid $pid, 0;
1851     die $! unless $got == $pid;
1852     die "build host child failed $?" if $?;
1853
1854     i_cleanup();
1855     printdebug "all done\n";
1856     exit 0;
1857 }
1858
1859 sub i_resp_file ($) {
1860     my ($keyword) = @_;
1861     my $localname = i_method "i_localname", $keyword;
1862     my $localpath = "$i_tmp/$localname";
1863     stat_exists $localpath and
1864         badproto \*RO, "file $keyword ($localpath) twice";
1865     protocol_receive_file \*RO, $localpath;
1866     i_method "i_file", $keyword;
1867 }
1868
1869 our %i_param;
1870
1871 sub i_resp_param ($) {
1872     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1873     $i_param{$1} = $2;
1874 }
1875
1876 our %i_wanted;
1877
1878 sub i_resp_want ($) {
1879     my ($keyword) = @_;
1880     die "$keyword ?" if $i_wanted{$keyword}++;
1881     my @localpaths = i_method "i_want", $keyword;
1882     printdebug "[[  $keyword @localpaths\n";
1883     foreach my $localpath (@localpaths) {
1884         protocol_send_file \*RI, $localpath;
1885     }
1886     print RI "files-end\n" or die $!;
1887 }
1888
1889 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1890
1891 sub i_localname_parsed_changelog {
1892     return "remote-changelog.822";
1893 }
1894 sub i_file_parsed_changelog {
1895     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1896         push_parse_changelog "$i_tmp/remote-changelog.822";
1897     die if $i_dscfn =~ m#/|^\W#;
1898 }
1899
1900 sub i_localname_dsc {
1901     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1902     return $i_dscfn;
1903 }
1904 sub i_file_dsc { }
1905
1906 sub i_localname_changes {
1907     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1908     $i_changesfn = $i_dscfn;
1909     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1910     return $i_changesfn;
1911 }
1912 sub i_file_changes { }
1913
1914 sub i_want_signed_tag {
1915     printdebug Dumper(\%i_param, $i_dscfn);
1916     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1917         && defined $i_param{'csuite'}
1918         or badproto \*RO, "premature desire for signed-tag";
1919     my $head = $i_param{'head'};
1920     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1921
1922     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1923     $csuite = $&;
1924     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1925
1926     my $tagobjfn =
1927         push_mktag $head, $i_clogp, $i_tag,
1928             $i_dscfn,
1929             $i_changesfn, 'remote changes',
1930             sub { "tag$_[0]"; };
1931
1932     return $tagobjfn;
1933 }
1934
1935 sub i_want_signed_dsc_changes {
1936     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
1937     sign_changes $i_changesfn;
1938     return ($i_dscfn, $i_changesfn);
1939 }
1940
1941 #---------- building etc. ----------
1942
1943 our $version;
1944 our $sourcechanges;
1945 our $dscfn;
1946
1947 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
1948
1949 sub build_maybe_quilt_fixup () {
1950     if (!open F, "debian/source/format") {
1951         die $! unless $!==&ENOENT;
1952         return;
1953     }
1954     $_ = <F>;
1955     F->error and die $!;
1956     chomp;
1957     return unless madformat($_);
1958     # sigh
1959
1960     my @cmd = (@git, qw(ls-files --exclude-standard -iodm));
1961     my $problems = cmdoutput @cmd;
1962     if (length $problems) {
1963         print STDERR "problematic files:\n";
1964         print STDERR "  $_\n" foreach split /\n/, $problems;
1965         fail "Cannot do quilt fixup in tree containing ignored files.  ".
1966             "Perhaps your package's clean target is broken, in which".
1967             " case -wg (which says to use git-clean -xdf) may help.";
1968     }
1969
1970     my $clogp = parsechangelog();
1971     my $version = getfield $clogp, 'Version';
1972     my $author = getfield $clogp, 'Maintainer';
1973     my $headref = rev_parse('HEAD');
1974     my $time = time;
1975     my $ncommits = 3;
1976     my $patchname = "auto-$version-$headref-$time";
1977     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
1978     mkpath '.git/dgit';
1979     my $descfn = ".git/dgit/quilt-description.tmp";
1980     open O, '>', $descfn or die "$descfn: $!";
1981     $msg =~ s/\n/\n /g;
1982     $msg =~ s/^\s+$/ ./mg;
1983     print O <<END or die $!;
1984 Description: Automatically generated patch ($clogp->{Version})
1985  Last (up to) $ncommits git changes, FYI:
1986  .
1987  $msg
1988 Author: $author
1989
1990 ---
1991
1992 END
1993     close O or die $!;
1994     {
1995         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
1996         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
1997         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
1998         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
1999     }
2000
2001     if (!open P, '>>', ".pc/applied-patches") {
2002         $!==&ENOENT or die $!;
2003     } else {
2004         close P;
2005     }
2006
2007     commit_quilty_patch();
2008 }
2009
2010 sub quilt_fixup_editor () {
2011     my $descfn = $ENV{$fakeeditorenv};
2012     my $editing = $ARGV[$#ARGV];
2013     open I1, '<', $descfn or die "$descfn: $!";
2014     open I2, '<', $editing or die "$editing: $!";
2015     unlink $editing or die "$editing: $!";
2016     open O, '>', $editing or die "$editing: $!";
2017     while (<I1>) { print O or die $!; } I1->error and die $!;
2018     my $copying = 0;
2019     while (<I2>) {
2020         $copying ||= m/^\-\-\- /;
2021         next unless $copying;
2022         print O or die $!;
2023     }
2024     I2->error and die $!;
2025     close O or die $1;
2026     exit 0;
2027 }
2028
2029 sub clean_tree () {
2030     if ($cleanmode eq 'dpkg-source') {
2031         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2032     } elsif ($cleanmode eq 'git') {
2033         runcmd_ordryrun_local @git, qw(clean -xdf);
2034     } elsif ($cleanmode eq 'none') {
2035     } else {
2036         die "$cleanmode ?";
2037     }
2038 }
2039
2040 sub cmd_clean () {
2041     badusage "clean takes no additional arguments" if @ARGV;
2042     clean_tree();
2043 }
2044
2045 sub build_prep () {
2046     badusage "-p is not allowed when building" if defined $package;
2047     check_not_dirty();
2048     clean_tree();
2049     my $clogp = parsechangelog();
2050     $isuite = getfield $clogp, 'Distribution';
2051     $package = getfield $clogp, 'Source';
2052     $version = getfield $clogp, 'Version';
2053     build_maybe_quilt_fixup();
2054 }
2055
2056 sub changesopts () {
2057     my @opts =@changesopts[1..$#changesopts];
2058     if (!defined $changes_since_version) {
2059         my @vsns = archive_query('archive_query');
2060         my @quirk = access_quirk();
2061         if ($quirk[0] eq 'backports') {
2062             local $isuite = $quirk[2];
2063             local $csuite;
2064             canonicalise_suite();
2065             push @vsns, archive_query('archive_query');
2066         }
2067         if (@vsns) {
2068             @vsns = map { $_->[0] } @vsns;
2069             @vsns = sort { -version_compare($a, $b) } @vsns;
2070             $changes_since_version = $vsns[0];
2071             progress "changelog will contain changes since $vsns[0]";
2072         } else {
2073             $changes_since_version = '_';
2074             progress "package seems new, not specifying -v<version>";
2075         }
2076     }
2077     if ($changes_since_version ne '_') {
2078         unshift @opts, "-v$changes_since_version";
2079     }
2080     return @opts;
2081 }
2082
2083 sub cmd_build {
2084     build_prep();
2085     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2086     printdone "build successful\n";
2087 }
2088
2089 sub cmd_git_build {
2090     build_prep();
2091     my @cmd =
2092         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2093          "--git-builder=@dpkgbuildpackage");
2094     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2095         canonicalise_suite();
2096         push @cmd, "--git-debian-branch=".lbranch();
2097     }
2098     push @cmd, changesopts();
2099     runcmd_ordryrun_local @cmd, @ARGV;
2100     printdone "build successful\n";
2101 }
2102
2103 sub build_source {
2104     build_prep();
2105     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2106     $dscfn = dscfn($version);
2107     if ($cleanmode eq 'dpkg-source') {
2108         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2109             changesopts();
2110     } else {
2111         my $pwd = must_getcwd();
2112         my $leafdir = basename $pwd;
2113         changedir "..";
2114         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2115         changedir $pwd;
2116         runcmd_ordryrun_local qw(sh -ec),
2117             'exec >$1; shift; exec "$@"','x',
2118             "../$sourcechanges",
2119             @dpkggenchanges, qw(-S), changesopts();
2120     }
2121 }
2122
2123 sub cmd_build_source {
2124     badusage "build-source takes no additional arguments" if @ARGV;
2125     build_source();
2126     printdone "source built, results in $dscfn and $sourcechanges";
2127 }
2128
2129 sub cmd_sbuild {
2130     build_source();
2131     changedir "..";
2132     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2133     if (act_local()) {
2134         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2135         stat_exists $sourcechanges
2136             or fail "$sourcechanges (in parent directory): $!";
2137         foreach my $cf (glob $pat) {
2138             next if $cf eq $sourcechanges;
2139             unlink $cf or fail "remove $cf: $!";
2140         }
2141     }
2142     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2143     my @changesfiles = glob $pat;
2144     @changesfiles = sort {
2145         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2146             or $a cmp $b
2147     } @changesfiles;
2148     fail "wrong number of different changes files (@changesfiles)"
2149         unless @changesfiles;
2150     runcmd_ordryrun_local @mergechanges, @changesfiles;
2151     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2152     if (act_local()) {
2153         stat_exists $multichanges or fail "$multichanges: $!";
2154     }
2155     printdone "build successful, results in $multichanges\n" or die $!;
2156 }
2157
2158 sub cmd_quilt_fixup {
2159     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2160     my $clogp = parsechangelog();
2161     $version = getfield $clogp, 'Version';
2162     build_maybe_quilt_fixup();
2163 }
2164
2165 #---------- argument parsing and main program ----------
2166
2167 sub cmd_version {
2168     print "dgit version $our_version\n" or die $!;
2169     exit 0;
2170 }
2171
2172 sub parseopts () {
2173     my $om;
2174
2175     if (defined $ENV{'DGIT_SSH'}) {
2176         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2177     } elsif (defined $ENV{'GIT_SSH'}) {
2178         @ssh = ($ENV{'GIT_SSH'});
2179     }
2180
2181     while (@ARGV) {
2182         last unless $ARGV[0] =~ m/^-/;
2183         $_ = shift @ARGV;
2184         last if m/^--?$/;
2185         if (m/^--/) {
2186             if (m/^--dry-run$/) {
2187                 push @ropts, $_;
2188                 $dryrun_level=2;
2189             } elsif (m/^--damp-run$/) {
2190                 push @ropts, $_;
2191                 $dryrun_level=1;
2192             } elsif (m/^--no-sign$/) {
2193                 push @ropts, $_;
2194                 $sign=0;
2195             } elsif (m/^--help$/) {
2196                 cmd_help();
2197             } elsif (m/^--version$/) {
2198                 cmd_version();
2199             } elsif (m/^--new$/) {
2200                 push @ropts, $_;
2201                 $new_package=1;
2202             } elsif (m/^--since-version=([^_]+|_)$/) {
2203                 push @ropts, $_;
2204                 $changes_since_version = $1;
2205             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2206                      ($om = $opts_opt_map{$1}) &&
2207                      length $om->[0]) {
2208                 push @ropts, $_;
2209                 $om->[0] = $2;
2210             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2211                      !$opts_opt_cmdonly{$1} &&
2212                      ($om = $opts_opt_map{$1})) {
2213                 push @ropts, $_;
2214                 push @$om, $2;
2215             } elsif (m/^--existing-package=(.*)/s) {
2216                 push @ropts, $_;
2217                 $existing_package = $1;
2218             } elsif (m/^--initiator-tempdir=(.*)/s) {
2219                 $initiator_tempdir = $1;
2220                 $initiator_tempdir =~ m#^/# or
2221                     badusage "--initiator-tempdir must be used specify an".
2222                         " absolute, not relative, directory."
2223             } elsif (m/^--distro=(.*)/s) {
2224                 push @ropts, $_;
2225                 $idistro = $1;
2226             } elsif (m/^--build-products-dir=(.*)/s) {
2227                 push @ropts, $_;
2228                 $buildproductsdir = $1;
2229             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2230                 push @ropts, $_;
2231                 $cleanmode = $1;
2232             } elsif (m/^--clean=(.*)$/s) {
2233                 badusage "unknown cleaning mode \`$1'";
2234             } elsif (m/^--ignore-dirty$/s) {
2235                 push @ropts, $_;
2236                 $ignoredirty = 1;
2237             } elsif (m/^--no-quilt-fixup$/s) {
2238                 push @ropts, $_;
2239                 $noquilt = 1;
2240             } elsif (m/^--no-rm-on-error$/s) {
2241                 push @ropts, $_;
2242                 $rmonerror = 0;
2243             } else {
2244                 badusage "unknown long option \`$_'";
2245             }
2246         } else {
2247             while (m/^-./s) {
2248                 if (s/^-n/-/) {
2249                     push @ropts, $&;
2250                     $dryrun_level=2;
2251                 } elsif (s/^-L/-/) {
2252                     push @ropts, $&;
2253                     $dryrun_level=1;
2254                 } elsif (s/^-h/-/) {
2255                     cmd_help();
2256                 } elsif (s/^-D/-/) {
2257                     push @ropts, $&;
2258                     open DEBUG, ">&STDERR" or die $!;
2259                     autoflush DEBUG 1;
2260                     $debug++;
2261                 } elsif (s/^-N/-/) {
2262                     push @ropts, $&;
2263                     $new_package=1;
2264                 } elsif (s/^-v([^_]+|_)$//s) {
2265                     push @ropts, $&;
2266                     $changes_since_version = $1;
2267                 } elsif (m/^-m/) {
2268                     push @ropts, $&;
2269                     push @changesopts, $_;
2270                     $_ = '';
2271                 } elsif (s/^-c(.*=.*)//s) {
2272                     push @ropts, $&;
2273                     push @git, '-c', $1;
2274                 } elsif (s/^-d(.*)//s) {
2275                     push @ropts, $&;
2276                     $idistro = $1;
2277                 } elsif (s/^-C(.*)//s) {
2278                     push @ropts, $&;
2279                     $changesfile = $1;
2280                     if ($changesfile =~ s#^(.*)/##) {
2281                         $buildproductsdir = $1;
2282                     }
2283                 } elsif (s/^-k(.*)//s) {
2284                     $keyid=$1;
2285                 } elsif (s/^-wn//s) {
2286                     push @ropts, $&;
2287                     $cleanmode = 'none';
2288                 } elsif (s/^-wg//s) {
2289                     push @ropts, $&;
2290                     $cleanmode = 'git';
2291                 } elsif (s/^-wd//s) {
2292                     push @ropts, $&;
2293                     $cleanmode = 'dpkg-source';
2294                 } else {
2295                     badusage "unknown short option \`$_'";
2296                 }
2297             }
2298         }
2299     }
2300 }
2301
2302 if ($ENV{$fakeeditorenv}) {
2303     quilt_fixup_editor();
2304 }
2305
2306 parseopts();
2307 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2308 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2309     if $dryrun_level == 1;
2310 if (!@ARGV) {
2311     print STDERR $helpmsg or die $!;
2312     exit 8;
2313 }
2314 my $cmd = shift @ARGV;
2315 $cmd =~ y/-/_/;
2316
2317 my $fn = ${*::}{"cmd_$cmd"};
2318 $fn or badusage "unknown operation $cmd";
2319 $fn->();