dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use Dpkg::Version;
  28 use POSIX;
  29
  30 our $isuite = 'unstable';
  31 our $idistro;
  32 our $package;
  33
  34 our $sign = 1;
  35 our $dryrun = 0;
  36 our $changesfile;
  37 our $new_package = 0;
  38 our $existing_package = 'dpkg';
  39
  40 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  41
  42 our (@git) = qw(git);
  43 our (@dget) = qw(dget);
  44 our (@dput) = qw(dput);
  45 our (@debsign) = qw(debsign);
  46 our (@sbuild) = qw(sbuild -A);
  47 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  48 our (@mergechanges) = qw(mergechanges -f);
  49
  50
  51 our %opts_opt_map = ('dget' => \@dget,
  52                      'dput' => \@dput,
  53                      'debsign' => \@debsign,
  54                      'sbuild' => \@sbuild,
  55                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  56                      'mergechanges' => \@mergechanges);
  57
  58 our $keyid;
  59
  60 our $debug = 0;
  61 open DEBUG, ">/dev/null" or die $!;
  62
  63 our $remotename = 'dgit';
  64 our $ourdscfield = 'Vcs-Dgit-Master';
  65 our $branchprefix = 'dgit';
  66 our $csuite;
  67
  68 sub lbranch () { return "$branchprefix/$csuite"; }
  69 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
  70 sub lref () { return "refs/heads/".lbranch(); }
  71 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
  72 sub rrref () { return "refs/$branchprefix/$csuite"; }
  73 sub debiantag ($) {
  74     my ($v) = @_;
  75     $v =~ y/~:/_%/;
  76     return "debian/$v";
  77 }
  78
  79 sub dscfn ($) { return "${package}_$_[0].dsc"; }
  80
  81 our $us = 'dgit';
  82
  83 sub fail { die "$us: @_\n"; }
  84
  85 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
  86
  87 sub no_such_package () {
  88     print STDERR "$us: package $package does not exist in suite $isuite\n";
  89     exit 4;
  90 }
  91
  92 sub fetchspec () {
  93     local $csuite = '*';
  94     return  "+".rrref().":".lrref();
  95 }
  96
  97 our $ua;
  98
  99 sub url_get {
 100     if (!$ua) {
 101         $ua = LWP::UserAgent->new();
 102         $ua->env_proxy;
 103     }
 104     my $what = $_[$#_];
 105     print "downloading $what...\n";
 106     my $r = $ua->get(@_) or die $!;
 107     return undef if $r->code == 404;
 108     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 109     return $r->decoded_content();
 110 }
 111
 112 our ($dscdata,$dscurl,$dsc);
 113
 114 sub printcmd {
 115     my $fh = shift @_;
 116     my $intro = shift @_;
 117     print $fh $intro or die $!;
 118     local $_;
 119     foreach my $a (@_) {
 120         $_ = $a;
 121         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
 122             print $fh " '$_'" or die $!;
 123         } else {
 124             print $fh " $_" or die $!;
 125         }
 126     }
 127     print $fh "\n" or die $!;
 128 }
 129
 130 sub failedcmd {
 131     { local ($!); printcmd \*STDERR, "$_[0]: failed command:", @_ or die $!; };
 132     if ($!) {
 133         fail "failed to fork/exec: $!";
 134     } elsif (!($? & 0xff)) {
 135         fail "subprocess failed with error exit status ".($?>>8);
 136     } elsif ($?) {
 137         fail "subprocess crashed (wait status $?)";
 138     } else {
 139         fail "subprocess produced invalid output";
 140     }
 141 }
 142
 143 sub runcmd {
 144     printcmd(\*DEBUG,"+",@_) if $debug>0;
 145     $!=0; $?=0;
 146     failedcmd @_ if system @_;
 147 }
 148
 149 sub printdone {
 150     if (!$dryrun) {
 151         print "dgit ok: @_\n";
 152     } else {
 153         print "would be ok: @_ (but dry run only)\n";
 154     }
 155 }
 156
 157 sub cmdoutput_errok {
 158     die Dumper(\@_)." ?" if grep { !defined } @_;
 159     printcmd(\*DEBUG,"|",@_) if $debug>0;
 160     open P, "-|", @_ or die $!;
 161     my $d;
 162     $!=0; $?=0;
 163     { local $/ = undef; $d = <P>; }
 164     die $! if P->error;
 165     if (!close P) { print DEBUG "=>!$?\n" if $debug>0; return undef; }
 166     chomp $d;
 167     $d =~ m/^.*/;
 168     print DEBUG "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 169     return $d;
 170 }
 171
 172 sub cmdoutput {
 173     my $d = cmdoutput_errok @_;
 174     defined $d or failedcmd @_;
 175     return $d;
 176 }
 177
 178 sub dryrun_report {
 179     printcmd(\*STDOUT,"#",@_);
 180 }
 181
 182 sub runcmd_ordryrun {
 183     if (!$dryrun) {
 184         runcmd @_;
 185     } else {
 186         dryrun_report @_;
 187     }
 188 }
 189
 190 our $helpmsg = <<END;
 191 main usages:
 192   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 193   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 194   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 195   dgit [dgit-opts] push [dgit-opts] [suite]
 196 important dgit options:
 197   -k<keyid>           sign tag and package with <keyid> instead of default
 198   --dry-run -n        do not change anything, but go through the motions
 199   --new -N            allow introducing a new package
 200   --debug -D          increase debug level
 201   -c<name>=<value>    set git config option (used directly by dgit too)
 202 END
 203
 204 our $later_warning_msg = <<END;
 205 Perhaps the upload is stuck in incoming.  Using the version from git.
 206 END
 207
 208 sub badusage {
 209     print STDERR "$us: @_\n", $helpmsg or die $!;
 210     exit 8;
 211 }
 212
 213 sub helponly () {
 214     print $helpmsg or die $!;
 215     exit 0;
 216 }
 217
 218 our %defcfg = ('dgit.default.distro' => 'debian',
 219                'dgit.default.username' => '',
 220                'dgit.default.archive-query-default-component' => 'main',
 221                'dgit.default.ssh' => 'ssh',
 222                'dgit-distro.debian.git-host' => 'git.debian.org',
 223                'dgit-distro.debian.git-proto' => 'git+ssh://',
 224                'dgit-distro.debian.git-path' => '/git/dgit-repos',
 225                'dgit-distro.debian.git-check' => 'ssh-cmd',
 226                'dgit-distro.debian.git-create' => 'ssh-cmd',
 227                'dgit-distro.debian.sshdakls-host' => 'coccia.debian.org',
 228                'dgit-distro.debian.sshdakls-dir' =>
 229                    '/srv/ftp-master.debian.org/ftp/dists',
 230                'dgit-distro.debian.mirror' => 'http://http.debian.net/debian/');
 231
 232 sub cfg {
 233     foreach my $c (@_) {
 234         return undef if $c =~ /RETURN-UNDEF/;
 235         my @cmd = (@git, qw(config --), $c);
 236         my $v;
 237         {
 238             local ($debug) = $debug-1;
 239             $v = cmdoutput_errok @cmd;
 240         };
 241         if ($?==0) {
 242             return $v;
 243         } elsif ($?!=256) {
 244             failedcmd @cmd;
 245         }
 246         my $dv = $defcfg{$c};
 247         return $dv if defined $dv;
 248     }
 249     badcfg "need value for one of: @_";
 250 }
 251
 252 sub access_distro () {
 253     return cfg("dgit-suite.$isuite.distro",
 254                "dgit.default.distro");
 255 }
 256
 257 sub access_cfg (@) {
 258     my (@keys) = @_;
 259     my $distro = $idistro || access_distro();
 260     my $value = cfg(map { ("dgit-distro.$distro.$_",
 261                            "dgit.default.$_") } @keys);
 262     return $value;
 263 }
 264
 265 sub access_someuserhost ($) {
 266     my ($some) = @_;
 267     my $user = access_cfg("$some-user",'username');
 268     my $host = access_cfg("$some-host");
 269     return length($user) ? "$user\@$host" : $host;
 270 }
 271
 272 sub access_gituserhost () {
 273     return access_someuserhost('git');
 274 }
 275
 276 sub access_giturl () {
 277     my $url = access_cfg('git-url','RETURN-UNDEF');
 278     if (!defined $url) {
 279         $url =
 280             access_cfg('git-proto').
 281             access_gituserhost().
 282             access_cfg('git-path');
 283     }
 284     return "$url/$package.git";
 285 }
 286
 287 sub parsecontrolfh ($$@) {
 288     my ($fh, $desc, @opts) = @_;
 289     my %opts = ('name' => $desc, @opts);
 290     my $c = Dpkg::Control::Hash->new(%opts);
 291     $c->parse($fh) or die "parsing of $desc failed";
 292     return $c;
 293 }
 294
 295 sub parsecontrol {
 296     my ($file, $desc) = @_;
 297     my $fh = new IO::Handle;
 298     open $fh, '<', $file or die "$file: $!";
 299     my $c = parsecontrolfh($fh,$desc);
 300     $fh->error and die $!;
 301     close $fh;
 302     return $c;
 303 }
 304
 305 sub getfield ($$) {
 306     my ($dctrl,$field) = @_;
 307     my $v = $dctrl->{$field};
 308     return $v if defined $v;
 309     fail "missing field $field in ".$v->get_option('name');
 310 }
 311
 312 sub parsechangelog {
 313     my $c = Dpkg::Control::Hash->new();
 314     my $p = new IO::Handle;
 315     my @cmd = (qw(dpkg-parsechangelog));
 316     open $p, '-|', @cmd or die $!;
 317     $c->parse($p);
 318     $?=0; $!=0; close $p or failedcmd @cmd;
 319     return $c;
 320 }
 321
 322 our %rmad;
 323
 324 sub archive_query ($) {
 325     my ($method) = @_;
 326     my $query = access_cfg('archive-query','RETURN-UNDEF');
 327     if (!defined $query) {
 328         my $distro = access_distro();
 329         if ($distro eq 'debian') {
 330             $query = "sshdakls:".
 331                 access_someuserhost('sshdakls').':'.
 332                 access_cfg('sshdakls-dir');
 333         } else {
 334             $query = "madison:$distro";
 335         }
 336     }
 337     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 338     my $proto = $1;
 339     my $data = $'; #';
 340     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 341 }
 342
 343 sub archive_query_madison ($$) {
 344     my ($proto,$data) = @_;
 345     die unless $proto eq 'madison';
 346     $rmad{$package} ||= cmdoutput
 347         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 348     my $rmad = $rmad{$package};
 349     return madison_parse($rmad);
 350 }
 351
 352 sub archive_query_sshdakls ($$) {
 353     my ($proto,$data) = @_;
 354     $data =~ s/:.*// or badcfg "invalid sshdakls method string \`$data'";
 355     my $dakls = cmdoutput
 356         access_cfg('ssh'), $data, qw(dak ls -asource),"-s$isuite",$package;
 357     return madison_parse($dakls);
 358 }
 359
 360 sub canonicalise_suite_sshdakls ($$) {
 361     my ($proto,$data) = @_;
 362     $data =~ m/:/ or badcfg "invalid sshdakls method string \`$data'";
 363     my @cmd =
 364         (access_cfg('ssh'), $`,
 365          "set -e; cd $';".
 366          " if test -h $isuite; then readlink $isuite; exit 0; fi;".
 367          " if test -d $isuite; then echo $isuite; exit 0; fi;".
 368          " exit 1");
 369     my $dakls = cmdoutput @cmd;
 370     failedcmd @cmd unless $dakls =~ m/^\w/;
 371     return $dakls;
 372 }
 373
 374 sub madison_parse ($) {
 375     my ($rmad) = @_;
 376     my @out;
 377     foreach my $l (split /\n/, $rmad) {
 378         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 379                   \s*( [^ \t|]+ )\s* \|
 380                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 381                   \s*( [^ \t|]+ )\s* }x or die "$rmad $?";
 382         $1 eq $package or die "$rmad $package ?";
 383         my $vsn = $2;
 384         my $newsuite = $3;
 385         my $component;
 386         if (defined $4) {
 387             $component = $4;
 388         } else {
 389             $component = access_cfg('archive-query-default-component');
 390         }
 391         $5 eq 'source' or die "$rmad ?";
 392         my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 393         my $subpath = "/pool/$component/$prefix/$package/${package}_$vsn.dsc";
 394         push @out, [$vsn,$subpath,$newsuite];
 395     }
 396     return sort { -version_compare_string($a->[0],$b->[0]); } @out;
 397 }
 398
 399 sub canonicalise_suite_madison ($$) {
 400     my @r = archive_query_madison($_[0],$_[1]);
 401     @r or fail
 402         "unable to canonicalise suite using package $package".
 403         " which does not appear to exist in suite $isuite;".
 404         " --existing-package may help";
 405     return $r[0][2];
 406 }
 407
 408 sub canonicalise_suite () {
 409     $csuite = archive_query('canonicalise_suite');
 410     if ($isuite ne $csuite) {
 411         # madison canonicalises for us
 412         print "canonical suite name for $isuite is $csuite\n";
 413     }
 414 }
 415
 416 sub get_archive_dsc () {
 417     canonicalise_suite();
 418     my @vsns = archive_query('archive_query');
 419     foreach my $vinfo (@vsns) {
 420         my ($vsn,$subpath) = @$vinfo;
 421         $dscurl = access_cfg('mirror').$subpath;
 422         $dscdata = url_get($dscurl);
 423         next unless defined $dscdata;
 424         $dscurl = access_cfg('mirror').$subpath;
 425         $dscdata = url_get($dscurl);
 426         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 427         print DEBUG Dumper($dscdata) if $debug>1;
 428         $dsc = parsecontrolfh($dscfh,$dscurl, allow_pgp=>1);
 429         print DEBUG Dumper($dsc) if $debug>1;
 430         my $fmt = getfield $dsc, 'Format';
 431         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 432         return $dsc;
 433     }
 434     return undef;
 435 }
 436
 437 sub check_for_git () {
 438     # returns 0 or 1
 439     my $how = access_cfg('git-check');
 440     if ($how eq 'ssh-cmd') {
 441         my @cmd =
 442             (access_cfg('ssh'),access_gituserhost(),
 443              " set -e; cd ".access_cfg('git-path').";".
 444              " if test -d $package.git; then echo 1; else echo 0; fi");
 445         my $r= cmdoutput @cmd;
 446         failedcmd @cmd unless $r =~ m/^[01]$/;
 447         return $r+0;
 448     } else {
 449         badcfg "unknown git-check \`$how'";
 450     }
 451 }
 452
 453 sub create_remote_git_repo () {
 454     my $how = access_cfg('git-create');
 455     if ($how eq 'ssh-cmd') {
 456         runcmd_ordryrun
 457             (access_cfg('ssh'),access_gituserhost(),
 458              "set -e; cd ".access_cfg('git-path').";".
 459              " cp -a _template $package.git");
 460     } else {
 461         badcfg "unknown git-create \`$how'";
 462     }
 463 }
 464
 465 our ($dsc_hash,$upload_hash);
 466
 467 our $ud = '.git/dgit/unpack';
 468
 469 sub prep_ud () {
 470     rmtree($ud);
 471     mkpath '.git/dgit';
 472     mkdir $ud or die $!;
 473 }
 474
 475 sub mktree_in_ud_from_only_subdir () {
 476     # changes into the subdir
 477     my (@dirs) = <*/.>;
 478     die unless @dirs==1;
 479     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 480     my $dir = $1;
 481     chdir $dir or die "$dir $!";
 482     die if stat '.git';
 483     die $! unless $!==&ENOENT;
 484     runcmd qw(git init -q);
 485     rmtree('.git/objects');
 486     symlink '../../../../objects','.git/objects' or die $!;
 487     runcmd @git, qw(add -Af);
 488     my $tree = cmdoutput @git, qw(write-tree);
 489     $tree =~ m/^\w+$/ or die "$tree ?";
 490     return ($tree,$dir);
 491 }
 492
 493 sub dsc_files () {
 494     my $field = $dsc->{'Checksums-Sha256'} || $dsc->{Files};
 495     defined $field or
 496         fail "missing both Checksums-Sha256 and Files in ".
 497         $dsc->get_option('name');
 498     map {
 499         m/^\w+ \d+ (\S+)$/ or
 500             fail "could not parse .dsc Files/Checksums line \`$_'";
 501         $1;
 502     } grep m/\S/, split /\n/, $field;
 503 }
 504
 505 sub is_orig_file ($) {
 506     local ($_) = @_;
 507     m/\.orig(?:-\w+)?\.tar\.\w+$/;
 508 }
 509
 510 sub make_commit ($) {
 511     my ($file) = @_;
 512     return cmdoutput @git, qw(hash-object -w -t commit), $file;
 513 }
 514
 515 sub generate_commit_from_dsc () {
 516     prep_ud();
 517     chdir $ud or die $!;
 518     my @files;
 519     foreach my $f (dsc_files()) {
 520         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 521         push @files, $f;
 522         link "../../../$f", $f
 523             or $!==&ENOENT
 524             or die "$f $!";
 525     }
 526     runcmd @dget, qw(--), $dscurl;
 527     foreach my $f (grep { is_orig_file($_) } @files) {
 528         link $f, "../../../../$f"
 529             or $!==&EEXIST
 530             or die "$f $!";
 531     }
 532     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 533     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 534     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
 535     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
 536     my $author = getfield $clogp, 'Maintainer';
 537     $author =~ s#,.*##ms;
 538     my $authline = "$author $date";
 539     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
 540         fail "unexpected commit author line format \`$authline'".
 541             " (was generated from changelog Maintainer field)";
 542     my $changes = getfield $clogp, 'Changes';
 543     open C, ">../commit.tmp" or die $!;
 544     print C <<END or die $!;
 545 tree $tree
 546 author $authline
 547 committer $authline
 548
 549 $changes
 550
 551 # imported from the archive
 552 END
 553     close C or die $!;
 554     my $outputhash = make_commit qw(../commit.tmp);
 555     my $cversion = getfield $clogp, 'Version';
 556     print "synthesised git commit from .dsc $cversion\n";
 557     if ($upload_hash) {
 558         runcmd @git, qw(reset --hard), $upload_hash;
 559         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 560         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
 561         my $oversion = getfield $oldclogp, 'Version';
 562         my $vcmp =
 563             version_compare_string($oversion, $cversion);
 564         if ($vcmp < 0) {
 565             # git upload/ is earlier vsn than archive, use archive
 566             open C, ">../commit2.tmp" or die $!;
 567             print C <<END or die $!;
 568 tree $tree
 569 parent $upload_hash
 570 parent $outputhash
 571 author $authline
 572 committer $authline
 573
 574 Record $package ($cversion) in archive suite $csuite
 575 END
 576             $outputhash = make_commit qw(../commit2.tmp);
 577         } elsif ($vcmp > 0) {
 578             print STDERR <<END or die $!;
 579
 580 Version actually in archive:    $cversion (older)
 581 Last allegedly pushed/uploaded: $oversion (newer or same)
 582 $later_warning_msg
 583 END
 584             $outputhash = $upload_hash;
 585         } elsif ($outputhash ne $upload_hash) {
 586             fail "version in archive ($cversion)".
 587                 " is same as version in git".
 588                 " to-be-uploaded (upload/) branch ($oversion)".
 589                 " but archive version hash no commit hash?!";
 590         }
 591     }
 592     chdir '../../../..' or die $!;
 593     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
 594             'DGIT_ARCHIVE', $outputhash;
 595     cmdoutput @git, qw(log -n2), $outputhash;
 596     # ... gives git a chance to complain if our commit is malformed
 597     rmtree($ud);
 598     return $outputhash;
 599 }
 600
 601 sub ensure_we_have_orig () {
 602     foreach my $f (dsc_files()) {
 603         next unless is_orig_file($f);
 604         if (stat "../$f") {
 605             die "$f ?" unless -f _;
 606         } else {
 607             die "$f $!" unless $!==&ENOENT;
 608         }
 609         my $origurl = $dscurl;
 610         $origurl =~ s{/[^/]+$}{};
 611         $origurl .= "/$f";
 612         die "$f ?" unless $f =~ m/^${package}_/;
 613         die "$f ?" if $f =~ m#/#;
 614         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 615             @dget,'--',$origurl;
 616     }
 617 }
 618
 619 sub rev_parse ($) {
 620     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 621 }
 622
 623 sub is_fast_fwd ($$) {
 624     my ($ancestor,$child) = @_;
 625     my $mb = cmdoutput @git, qw(merge-base), $ancestor, $child;
 626     return rev_parse($mb) eq rev_parse($ancestor);
 627 }
 628
 629 sub git_fetch_us () {
 630     badusage "cannot dry run with fetch" if $dryrun;
 631     runcmd @git, qw(fetch),access_giturl(),fetchspec();
 632 }
 633
 634 sub fetch_from_archive () {
 635     # ensures that lrref() is what is actually in the archive,
 636     #  one way or another
 637     get_archive_dsc() or return 0;
 638     $dsc_hash = $dsc->{$ourdscfield};
 639     if (defined $dsc_hash) {
 640         $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
 641         $dsc_hash = $&;
 642         print "last upload to archive specified git hash\n";
 643     } else {
 644         print "last upload to archive has NO git hash\n";
 645     }
 646
 647     my $lrref_fn = ".git/".lrref();
 648     if (open H, $lrref_fn) {
 649         $upload_hash = <H>;
 650         chomp $upload_hash;
 651         die "$lrref_fn $upload_hash ?" unless $upload_hash =~ m/^\w+$/;
 652     } elsif ($! == &ENOENT) {
 653         $upload_hash = '';
 654     } else {
 655         die "$lrref_fn $!";
 656     }
 657     print DEBUG "previous reference hash=$upload_hash\n";
 658     my $hash;
 659     if (defined $dsc_hash) {
 660         fail "missing git history even though dsc has hash -".
 661             " could not find commit $dsc_hash".
 662             " (should be in ".access_giturl()."#".rref().")"
 663             unless $upload_hash;
 664         $hash = $dsc_hash;
 665         ensure_we_have_orig();
 666         if (is_fast_fwd($dsc_hash,$upload_hash)) {
 667             print STDERR <<END or die $!;
 668
 669 Git commit in archive is behind the last version allegedly pushed/uploaded.
 670 Commit referred to by archive:  $dsc_hash
 671 Last allegedly pushed/uploaded: $upload_hash
 672 $later_warning_msg
 673 END
 674             $hash = $upload_hash;
 675         }
 676     } else {
 677         $hash = generate_commit_from_dsc();
 678     }
 679     print DEBUG "current hash=$hash\n";
 680     if ($upload_hash) {
 681         fail "not fast forward on last upload branch!".
 682             " (archive's version left in DGIT_ARCHIVE)"
 683             unless is_fast_fwd($upload_hash, $hash);
 684     }
 685     if ($upload_hash ne $hash) {
 686         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
 687         if (!$dryrun) {
 688             cmdoutput @upd_cmd;
 689         } else {
 690             dryrun_report @upd_cmd;
 691         }
 692     }
 693     return 1;
 694 }
 695
 696 sub clone ($) {
 697     my ($dstdir) = @_;
 698     canonicalise_suite();
 699     badusage "dry run makes no sense with clone" if $dryrun;
 700     mkdir $dstdir or die "$dstdir $!";
 701     chdir "$dstdir" or die "$dstdir $!";
 702     runcmd @git, qw(init -q);
 703     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
 704     open H, "> .git/HEAD" or die $!;
 705     print H "ref: ".lref()."\n" or die $!;
 706     close H or die $!;
 707     runcmd @git, qw(remote add), 'origin', access_giturl();
 708     if (check_for_git()) {
 709         print "fetching existing git history\n";
 710         git_fetch_us();
 711         runcmd @git, qw(fetch origin);
 712     } else {
 713         print "starting new git history\n";
 714     }
 715     fetch_from_archive() or no_such_package;
 716     runcmd @git, qw(reset --hard), lrref();
 717     printdone "ready for work in $dstdir";
 718 }
 719
 720 sub fetch () {
 721     if (check_for_git()) {
 722         git_fetch_us();
 723     }
 724     fetch_from_archive() or no_such_package();
 725     printdone "fetched into ".lrref();
 726 }
 727
 728 sub pull () {
 729     fetch();
 730     runcmd_ordryrun @git, qw(merge -m),"Merge from $csuite [dgit]",
 731         lrref();
 732     printdone "fetched to ".lrref()." and merged into HEAD";
 733 }
 734
 735 sub check_not_dirty () {
 736     my @cmd = (@git, qw(diff --quiet HEAD));
 737     printcmd(\*DEBUG,"+",@cmd) if $debug>0;
 738     $!=0; $?=0; system @cmd;
 739     return if !$! && !$?;
 740     if (!$! && $?==256) {
 741         fail "working tree is dirty (does not match HEAD)";
 742     } else {
 743         failedcmd @cmd;
 744     }
 745 }
 746
 747 sub commit_quilty_patch ($) {
 748     my ($vsn) = @_;
 749     my $output = cmdoutput @git, qw(status --porcelain);
 750     my %fixups = map {$_=>1}
 751         (".pc/debian-changes-$vsn/","debian/patches/debian-changes-$vsn");
 752     my @files;
 753     foreach my $l (split /\n/, $output) {
 754         next unless $l =~ s/^\?\? //;
 755         next unless $fixups{$l};
 756         push @files, $l;
 757     }
 758     print DEBUG "checking for quilty\n", Dumper(\@files);
 759     if (@files == 2) {
 760         my $m = "Commit Debian 3.0 (quilt) metadata";
 761         print "$m\n";
 762         runcmd_ordryrun @git, qw(add), @files;
 763         runcmd_ordryrun @git, qw(commit -m), $m;
 764     }
 765 }
 766
 767 sub dopush () {
 768     print DEBUG "actually entering push\n";
 769     my $clogp = parsechangelog();
 770     $package = getfield $clogp, 'Source';
 771     my $cversion = getfield $clogp, 'Version';
 772     my $dscfn = dscfn($cversion);
 773     stat "../$dscfn" or
 774         fail "looked for .dsc $dscfn, but $!;".
 775             " maybe you forgot to build";
 776     $dsc = parsecontrol("../$dscfn","$dscfn");
 777     my $dscpackage = getfield $dsc, 'Source';
 778     my $format = getfield $dsc, 'Format';
 779     my $dversion = getfield $dsc, 'Version';
 780     ($dscpackage eq $package && $dversion eq $cversion) or
 781         fail "$dsc is for $dscpackage $dversion".
 782             " but debian/changelog is for $package $cversion";
 783     print DEBUG "format $format\n";
 784     if ($format eq '3.0 (quilt)') {
 785         print "Format \`$format', urgh\n";
 786         commit_quilty_patch($dversion);
 787     }
 788     check_not_dirty();
 789     prep_ud();
 790     chdir $ud or die $!;
 791     print "checking that $dscfn corresponds to HEAD\n";
 792     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 793     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 794     chdir '../../../..' or die $!;
 795     printcmd \*DEBUG,"+",@_;
 796     my @diffcmd = (@git, qw(diff --exit-code), $tree);
 797     $!=0; $?=0;
 798     if (system @diffcmd) {
 799         if ($! && $?==256) {
 800             fail "$dscfn specifies a different tree to your HEAD commit;".
 801                 " perhaps you forgot to build";
 802         } else {
 803             failedcmd @diffcmd;
 804         }
 805     }
 806 #fetch from alioth
 807 #do fast forward check and maybe fake merge
 808 #    if (!is_fast_fwd(mainbranch
 809 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 810 #        map { lref($_).":".rref($_) }
 811 #        (uploadbranch());
 812     $dsc->{$ourdscfield} = rev_parse('HEAD');
 813     $dsc->save("../$dscfn.tmp") or die $!;
 814     if (!$changesfile) {
 815         my $multi = "../${package}_${cversion}_multi.changes";
 816         if (stat "$multi") {
 817             $changesfile = $multi;
 818         } else {
 819             $!==&ENOENT or die "$multi: $!";
 820             my $pat = "${package}_${cversion}_*.changes";
 821             my @cs = glob "../$pat";
 822             fail "failed to find unique changes file".
 823                 " (looked for $pat in .., or $multi);".
 824                 " perhaps you need to use dgit -C"
 825                 unless @cs==1;
 826             ($changesfile) = @cs;
 827         }
 828     }
 829     my $tag = debiantag($dversion);
 830     if (!check_for_git()) {
 831         create_remote_git_repo();
 832     }
 833     runcmd_ordryrun @git, qw(push),access_giturl(),"HEAD:".rrref();
 834     if (!$dryrun) {
 835         rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 836     } else {
 837         print "[new .dsc left in $dscfn.tmp]\n";
 838     }
 839     if ($sign) {
 840         if (!defined $keyid) {
 841             $keyid = access_cfg('keyid','RETURN-UNDEF');
 842         }
 843         my @tag_cmd = (@git, qw(tag -s -m),
 844                        "Release $dversion for $csuite [dgit]");
 845         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 846         push @tag_cmd, $tag;
 847         runcmd_ordryrun @tag_cmd;
 848         my @debsign_cmd = @debsign;
 849         push @debsign_cmd, "-k$keyid" if defined $keyid;
 850         push @debsign_cmd, $changesfile;
 851         runcmd_ordryrun @debsign_cmd;
 852     }
 853     runcmd_ordryrun @git, qw(push),access_giturl(),"refs/tags/$tag";
 854     my $host = access_cfg('upload-host','RETURN-UNDEF');
 855     my @hostarg = defined($host) ? ($host,) : ();
 856     runcmd_ordryrun @dput, @hostarg, $changesfile;
 857     printdone "pushed and uploaded $dversion";
 858 }
 859
 860 sub cmd_clone {
 861     parseopts();
 862     my $dstdir;
 863     badusage "-p is not allowed with clone; specify as argument instead"
 864         if defined $package;
 865     if (@ARGV==1) {
 866         ($package) = @ARGV;
 867     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
 868         ($package,$isuite) = @ARGV;
 869     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
 870         ($package,$dstdir) = @ARGV;
 871     } elsif (@ARGV==3) {
 872         ($package,$isuite,$dstdir) = @ARGV;
 873     } else {
 874         badusage "incorrect arguments to dgit clone";
 875     }
 876     $dstdir ||= "$package";
 877     clone($dstdir);
 878 }
 879
 880 sub branchsuite () {
 881     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 882     if ($branch =~ m#$lbranch_re#o) {
 883         return $1;
 884     } else {
 885         return undef;
 886     }
 887 }
 888
 889 sub fetchpullargs () {
 890     if (!defined $package) {
 891         my $sourcep = parsecontrol('debian/control','debian/control');
 892         $package = getfield $sourcep, 'Source';
 893     }
 894     if (@ARGV==0) {
 895 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
 896         if (!$isuite) {
 897             my $clogp = parsechangelog();
 898             $isuite = getfield $clogp, 'Distribution';
 899         }
 900         canonicalise_suite();
 901         print "fetching from suite $csuite\n";
 902     } elsif (@ARGV==1) {
 903         ($isuite) = @ARGV;
 904         canonicalise_suite();
 905     } else {
 906         badusage "incorrect arguments to dgit fetch or dgit pull";
 907     }
 908 }
 909
 910 sub cmd_fetch {
 911     parseopts();
 912     fetchpullargs();
 913     fetch();
 914 }
 915
 916 sub cmd_pull {
 917     parseopts();
 918     fetchpullargs();
 919     pull();
 920 }
 921
 922 sub cmd_push {
 923     parseopts();
 924     badusage "-p is not allowed with dgit push" if defined $package;
 925     runcmd @git, qw(diff --quiet HEAD);
 926     my $clogp = parsechangelog();
 927     $package = getfield $clogp, 'Source';
 928     if (@ARGV==0) {
 929         $isuite = getfield $clogp, 'Distribution';
 930         if ($new_package) {
 931             local ($package) = $existing_package; # this is a hack
 932             canonicalise_suite();
 933         }
 934     } else {
 935         badusage "incorrect arguments to dgit push";
 936     }
 937     if (fetch_from_archive()) {
 938         is_fast_fwd(lrref(), 'HEAD') or die;
 939     } else {
 940         $new_package or
 941             fail "package appears to be new in this suite;".
 942                 " if this is intentional, use --new";
 943     }
 944     dopush();
 945 }
 946
 947 sub cmd_build {
 948     # we pass further options and args to git-buildpackage
 949     badusage "-p is not allowed with dgit build" if defined $package;
 950     my $clogp = parsechangelog();
 951     $isuite = getfield $clogp, 'Distribution';
 952     $package = getfield $clogp, 'Source';
 953     my @cmd =
 954         (qw(git-buildpackage -us -uc --git-no-sign-tags),
 955          "--git-builder=@dpkgbuildpackage");
 956     unless (grep { m/^--git-debian-branch/ } @ARGV) {
 957         canonicalise_suite();
 958         push @cmd, "--git-debian-branch=".lbranch();
 959     }
 960     runcmd_ordryrun @cmd, @ARGV;
 961     printdone "build successful\n";
 962 }
 963
 964 sub cmd_sbuild {
 965     check_not_dirty();
 966     badusage "-p is not allowed with dgit sbuild" if defined $package;
 967     my $clogp = parsechangelog();
 968     $package = getfield $clogp, 'Source';
 969     my $isuite = getfield $clogp, 'Distribution';
 970     my $version = getfield $clogp, 'Version';
 971     runcmd_ordryrun (@dpkgbuildpackage, qw(-us -uc -S));
 972     chdir ".." or die $!;
 973     my $sourcechanges = "${package}_${version}_source.changes";
 974     my $dscfn = dscfn($version);
 975     my $pat = "${package}_${version}_*.changes";
 976     if (!$dryrun) {
 977         stat $dscfn or fail "$dscfn (in parent directory): $!";
 978         stat $sourcechanges or fail "$sourcechanges (in parent directory): $!";
 979         foreach my $cf (glob $pat) {
 980             next if $cf eq $sourcechanges;
 981             unlink $cf or fail "remove $cf: $!";
 982         }
 983     }
 984     runcmd_ordryrun @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
 985     runcmd_ordryrun @mergechanges, glob $pat;
 986     my $multichanges = "${package}_${version}_multi.changes";
 987     if (!$dryrun) {
 988         stat $multichanges or fail "$multichanges: $!";
 989     }
 990     printdone "build successful, results in $multichanges\n" or die $!;
 991 }
 992
 993 sub cmd_quilt_fixup {
 994     badusage "incorrect arguments to dgit quilt-fixup";
 995     my $clogp = parsechangelog();
 996     commit_quilty_patch((getfield $clogp, 'Version'));
 997 }
 998
 999 sub parseopts () {
1000     my $om;
1001     while (@ARGV) {
1002         last unless $ARGV[0] =~ m/^-/;
1003         $_ = shift @ARGV;
1004         last if m/^--?$/;
1005         if (m/^--/) {
1006             if (m/^--dry-run$/) {
1007                 $dryrun=1;
1008             } elsif (m/^--no-sign$/) {
1009                 $sign=0;
1010             } elsif (m/^--help$/) {
1011                 helponly();
1012             } elsif (m/^--new$/) {
1013                 $new_package=1;
1014             } elsif (m/^--(\w+)=(.*)/s && ($om = $opts_opt_map{$1})) {
1015                 $om->[0] = $2;
1016             } elsif (m/^--(\w+):(.*)/s && ($om = $opts_opt_map{$1})) {
1017                 push @$om, $2;
1018             } elsif (m/^--existing-package=(.*)/s) {
1019                 $existing_package = $1;
1020             } elsif (m/^--distro=(.*)/s) {
1021                 $idistro = $1;
1022             } else {
1023                 badusage "unknown long option \`$_'";
1024             }
1025         } else {
1026             while (m/^-./s) {
1027                 if (s/^-n/-/) {
1028                     $dryrun=1;
1029                 } elsif (s/^-h/-/) {
1030                     helponly();
1031                 } elsif (s/^-D/-/) {
1032                     open DEBUG, ">&STDERR" or die $!;
1033                     $debug++;
1034                 } elsif (s/^-N/-/) {
1035                     $new_package=1;
1036                 } elsif (s/^-c(.*=.*)//s) {
1037                     push @git, '-c', $1;
1038                 } elsif (s/^-d(.*)//s) {
1039                     $idistro = $1;
1040                 } elsif (s/^-C(.*)//s) {
1041                     $changesfile = $1;
1042                 } elsif (s/^-k(.*)//s) {
1043                     $keyid=$1;
1044                 } else {
1045                     badusage "unknown short option \`$_'";
1046                 }
1047             }
1048         }
1049     }
1050 }
1051
1052 parseopts();
1053 print STDERR "DRY RUN ONLY\n" if $dryrun;
1054 if (!@ARGV) {
1055     print STDERR $helpmsg or die $!;
1056     exit 8;
1057 }
1058 my $cmd = shift @ARGV;
1059 $cmd =~ y/-/_/;
1060 { no strict qw(refs); &{"cmd_$cmd"}(); }