dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $cmd;
  51 our $subcommand;
  52 our $isuite;
  53 our $idistro;
  54 our $package;
  55 our @ropts;
  56
  57 our $sign = 1;
  58 our $dryrun_level = 0;
  59 our $changesfile;
  60 our $buildproductsdir = '..';
  61 our $new_package = 0;
  62 our $ignoredirty = 0;
  63 our $rmonerror = 1;
  64 our @deliberatelies;
  65 our %previously;
  66 our $existing_package = 'dpkg';
  67 our $cleanmode;
  68 our $changes_since_version;
  69 our $rmchanges;
  70 our $overwrite_version; # undef: not specified; '': check changelog
  71 our $quilt_mode;
  72 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  73 our $dodep14tag;
  74 our $split_brain_save;
  75 our $we_are_responder;
  76 our $we_are_initiator;
  77 our $initiator_tempdir;
  78 our $patches_applied_dirtily = 00;
  79 our $tagformat_want;
  80 our $tagformat;
  81 our $tagformatfn;
  82 our $chase_dsc_distro=1;
  83
  84 our %forceopts = map { $_=>0 }
  85     qw(unrepresentable unsupported-source-format
  86        dsc-changes-mismatch changes-origs-exactly
  87        import-gitapply-absurd
  88        import-gitapply-no-absurd
  89        import-dsc-with-dgit-field);
  90
  91 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  92
  93 our $suite_re = '[-+.0-9a-z]+';
  94 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  95 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  96 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  97 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  98
  99 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 100 our $splitbraincache = 'dgit-intern/quilt-cache';
 101 our $rewritemap = 'dgit-rewrite/map';
 102
 103 our (@git) = qw(git);
 104 our (@dget) = qw(dget);
 105 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 106 our (@dput) = qw(dput);
 107 our (@debsign) = qw(debsign);
 108 our (@gpg) = qw(gpg);
 109 our (@sbuild) = qw(sbuild);
 110 our (@ssh) = 'ssh';
 111 our (@dgit) = qw(dgit);
 112 our (@aptget) = qw(apt-get);
 113 our (@aptcache) = qw(apt-cache);
 114 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 115 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 116 our (@dpkggenchanges) = qw(dpkg-genchanges);
 117 our (@mergechanges) = qw(mergechanges -f);
 118 our (@gbp_build) = ('');
 119 our (@gbp_pq) = ('gbp pq');
 120 our (@changesopts) = ('');
 121
 122 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 123                      'curl' => \@curl,
 124                      'dput' => \@dput,
 125                      'debsign' => \@debsign,
 126                      'gpg' => \@gpg,
 127                      'sbuild' => \@sbuild,
 128                      'ssh' => \@ssh,
 129                      'dgit' => \@dgit,
 130                      'git' => \@git,
 131                      'apt-get' => \@aptget,
 132                      'apt-cache' => \@aptcache,
 133                      'dpkg-source' => \@dpkgsource,
 134                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 135                      'dpkg-genchanges' => \@dpkggenchanges,
 136                      'gbp-build' => \@gbp_build,
 137                      'gbp-pq' => \@gbp_pq,
 138                      'ch' => \@changesopts,
 139                      'mergechanges' => \@mergechanges);
 140
 141 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 142 our %opts_cfg_insertpos = map {
 143     $_,
 144     scalar @{ $opts_opt_map{$_} }
 145 } keys %opts_opt_map;
 146
 147 sub parseopts_late_defaults();
 148 sub setup_gitattrs(;$);
 149 sub check_gitattrs($$);
 150
 151 our $keyid;
 152
 153 autoflush STDOUT 1;
 154
 155 our $supplementary_message = '';
 156 our $need_split_build_invocation = 0;
 157 our $split_brain = 0;
 158
 159 END {
 160     local ($@, $?);
 161     return unless forkcheck_mainprocess();
 162     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 163 }
 164
 165 our $remotename = 'dgit';
 166 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 167 our $csuite;
 168 our $instead_distro;
 169
 170 if (!defined $absurdity) {
 171     $absurdity = $0;
 172     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 173 }
 174
 175 sub debiantag ($$) {
 176     my ($v,$distro) = @_;
 177     return $tagformatfn->($v, $distro);
 178 }
 179
 180 sub debiantag_maintview ($$) {
 181     my ($v,$distro) = @_;
 182     return "$distro/".dep14_version_mangle $v;
 183 }
 184
 185 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 186
 187 sub lbranch () { return "$branchprefix/$csuite"; }
 188 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 189 sub lref () { return "refs/heads/".lbranch(); }
 190 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 191 sub rrref () { return server_ref($csuite); }
 192
 193 sub stripepoch ($) {
 194     my ($vsn) = @_;
 195     $vsn =~ s/^\d+\://;
 196     return $vsn;
 197 }
 198
 199 sub srcfn ($$) {
 200     my ($vsn,$sfx) = @_;
 201     return "${package}_".(stripepoch $vsn).$sfx
 202 }
 203
 204 sub dscfn ($) {
 205     my ($vsn) = @_;
 206     return srcfn($vsn,".dsc");
 207 }
 208
 209 sub changespat ($;$) {
 210     my ($vsn, $arch) = @_;
 211     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 212 }
 213
 214 sub upstreamversion ($) {
 215     my ($vsn) = @_;
 216     $vsn =~ s/-[^-]+$//;
 217     return $vsn;
 218 }
 219
 220 our $us = 'dgit';
 221 initdebug('');
 222
 223 our @end;
 224 END {
 225     local ($?);
 226     return unless forkcheck_mainprocess();
 227     foreach my $f (@end) {
 228         eval { $f->(); };
 229         print STDERR "$us: cleanup: $@" if length $@;
 230     }
 231 };
 232
 233 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 234
 235 sub forceable_fail ($$) {
 236     my ($forceoptsl, $msg) = @_;
 237     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 238     print STDERR "warning: overriding problem due to --force:\n". $msg;
 239 }
 240
 241 sub forceing ($) {
 242     my ($forceoptsl) = @_;
 243     my @got = grep { $forceopts{$_} } @$forceoptsl;
 244     return 0 unless @got;
 245     print STDERR
 246  "warning: skipping checks or functionality due to --force-$got[0]\n";
 247 }
 248
 249 sub no_such_package () {
 250     print STDERR "$us: package $package does not exist in suite $isuite\n";
 251     exit 4;
 252 }
 253
 254 sub deliberately ($) {
 255     my ($enquiry) = @_;
 256     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 257 }
 258
 259 sub deliberately_not_fast_forward () {
 260     foreach (qw(not-fast-forward fresh-repo)) {
 261         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 262     }
 263 }
 264
 265 sub quiltmode_splitbrain () {
 266     $quilt_mode =~ m/gbp|dpm|unapplied/;
 267 }
 268
 269 sub opts_opt_multi_cmd {
 270     my @cmd;
 271     push @cmd, split /\s+/, shift @_;
 272     push @cmd, @_;
 273     @cmd;
 274 }
 275
 276 sub gbp_pq {
 277     return opts_opt_multi_cmd @gbp_pq;
 278 }
 279
 280 #---------- remote protocol support, common ----------
 281
 282 # remote push initiator/responder protocol:
 283 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 284 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 285 #  < dgit-remote-push-ready <actual-proto-vsn>
 286 #
 287 # occasionally:
 288 #
 289 #  > progress NBYTES
 290 #  [NBYTES message]
 291 #
 292 #  > supplementary-message NBYTES          # $protovsn >= 3
 293 #  [NBYTES message]
 294 #
 295 # main sequence:
 296 #
 297 #  > file parsed-changelog
 298 #  [indicates that output of dpkg-parsechangelog follows]
 299 #  > data-block NBYTES
 300 #  > [NBYTES bytes of data (no newline)]
 301 #  [maybe some more blocks]
 302 #  > data-end
 303 #
 304 #  > file dsc
 305 #  [etc]
 306 #
 307 #  > file changes
 308 #  [etc]
 309 #
 310 #  > param head DGIT-VIEW-HEAD
 311 #  > param csuite SUITE
 312 #  > param tagformat old|new
 313 #  > param maint-view MAINT-VIEW-HEAD
 314 #
 315 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 316 #  > file buildinfo                             # for buildinfos to sign
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < data-block NBYTES    [transfer of each signed buildinfo
 335 #  [etc]                   same number and order as "file buildinfo"]
 336 #  ...
 337 #  < files-end
 338 #
 339 #  > complete
 340
 341 our $i_child_pid;
 342
 343 sub i_child_report () {
 344     # Sees if our child has died, and reap it if so.  Returns a string
 345     # describing how it died if it failed, or undef otherwise.
 346     return undef unless $i_child_pid;
 347     my $got = waitpid $i_child_pid, WNOHANG;
 348     return undef if $got <= 0;
 349     die unless $got == $i_child_pid;
 350     $i_child_pid = undef;
 351     return undef unless $?;
 352     return "build host child ".waitstatusmsg();
 353 }
 354
 355 sub badproto ($$) {
 356     my ($fh, $m) = @_;
 357     fail "connection lost: $!" if $fh->error;
 358     fail "protocol violation; $m not expected";
 359 }
 360
 361 sub badproto_badread ($$) {
 362     my ($fh, $wh) = @_;
 363     fail "connection lost: $!" if $!;
 364     my $report = i_child_report();
 365     fail $report if defined $report;
 366     badproto $fh, "eof (reading $wh)";
 367 }
 368
 369 sub protocol_expect (&$) {
 370     my ($match, $fh) = @_;
 371     local $_;
 372     $_ = <$fh>;
 373     defined && chomp or badproto_badread $fh, "protocol message";
 374     if (wantarray) {
 375         my @r = &$match;
 376         return @r if @r;
 377     } else {
 378         my $r = &$match;
 379         return $r if $r;
 380     }
 381     badproto $fh, "\`$_'";
 382 }
 383
 384 sub protocol_send_file ($$) {
 385     my ($fh, $ourfn) = @_;
 386     open PF, "<", $ourfn or die "$ourfn: $!";
 387     for (;;) {
 388         my $d;
 389         my $got = read PF, $d, 65536;
 390         die "$ourfn: $!" unless defined $got;
 391         last if !$got;
 392         print $fh "data-block ".length($d)."\n" or die $!;
 393         print $fh $d or die $!;
 394     }
 395     PF->error and die "$ourfn $!";
 396     print $fh "data-end\n" or die $!;
 397     close PF;
 398 }
 399
 400 sub protocol_read_bytes ($$) {
 401     my ($fh, $nbytes) = @_;
 402     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 403     my $d;
 404     my $got = read $fh, $d, $nbytes;
 405     $got==$nbytes or badproto_badread $fh, "data block";
 406     return $d;
 407 }
 408
 409 sub protocol_receive_file ($$) {
 410     my ($fh, $ourfn) = @_;
 411     printdebug "() $ourfn\n";
 412     open PF, ">", $ourfn or die "$ourfn: $!";
 413     for (;;) {
 414         my ($y,$l) = protocol_expect {
 415             m/^data-block (.*)$/ ? (1,$1) :
 416             m/^data-end$/ ? (0,) :
 417             ();
 418         } $fh;
 419         last unless $y;
 420         my $d = protocol_read_bytes $fh, $l;
 421         print PF $d or die $!;
 422     }
 423     close PF or die $!;
 424 }
 425
 426 #---------- remote protocol support, responder ----------
 427
 428 sub responder_send_command ($) {
 429     my ($command) = @_;
 430     return unless $we_are_responder;
 431     # called even without $we_are_responder
 432     printdebug ">> $command\n";
 433     print PO $command, "\n" or die $!;
 434 }
 435
 436 sub responder_send_file ($$) {
 437     my ($keyword, $ourfn) = @_;
 438     return unless $we_are_responder;
 439     printdebug "]] $keyword $ourfn\n";
 440     responder_send_command "file $keyword";
 441     protocol_send_file \*PO, $ourfn;
 442 }
 443
 444 sub responder_receive_files ($@) {
 445     my ($keyword, @ourfns) = @_;
 446     die unless $we_are_responder;
 447     printdebug "[[ $keyword @ourfns\n";
 448     responder_send_command "want $keyword";
 449     foreach my $fn (@ourfns) {
 450         protocol_receive_file \*PI, $fn;
 451     }
 452     printdebug "[[\$\n";
 453     protocol_expect { m/^files-end$/ } \*PI;
 454 }
 455
 456 #---------- remote protocol support, initiator ----------
 457
 458 sub initiator_expect (&) {
 459     my ($match) = @_;
 460     protocol_expect { &$match } \*RO;
 461 }
 462
 463 #---------- end remote code ----------
 464
 465 sub progress {
 466     if ($we_are_responder) {
 467         my $m = join '', @_;
 468         responder_send_command "progress ".length($m) or die $!;
 469         print PO $m or die $!;
 470     } else {
 471         print @_, "\n";
 472     }
 473 }
 474
 475 our $ua;
 476
 477 sub url_get {
 478     if (!$ua) {
 479         $ua = LWP::UserAgent->new();
 480         $ua->env_proxy;
 481     }
 482     my $what = $_[$#_];
 483     progress "downloading $what...";
 484     my $r = $ua->get(@_) or die $!;
 485     return undef if $r->code == 404;
 486     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 487     return $r->decoded_content(charset => 'none');
 488 }
 489
 490 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 491
 492 sub act_local () { return $dryrun_level <= 1; }
 493 sub act_scary () { return !$dryrun_level; }
 494
 495 sub printdone {
 496     if (!$dryrun_level) {
 497         progress "$us ok: @_";
 498     } else {
 499         progress "would be ok: @_ (but dry run only)";
 500     }
 501 }
 502
 503 sub dryrun_report {
 504     printcmd(\*STDERR,$debugprefix."#",@_);
 505 }
 506
 507 sub runcmd_ordryrun {
 508     if (act_scary()) {
 509         runcmd @_;
 510     } else {
 511         dryrun_report @_;
 512     }
 513 }
 514
 515 sub runcmd_ordryrun_local {
 516     if (act_local()) {
 517         runcmd @_;
 518     } else {
 519         dryrun_report @_;
 520     }
 521 }
 522
 523 sub shell_cmd {
 524     my ($first_shell, @cmd) = @_;
 525     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 526 }
 527
 528 our $helpmsg = <<END;
 529 main usages:
 530   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 531   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 532   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 533   dgit [dgit-opts] sbuild [sbuild-opts]
 534   dgit [dgit-opts] push [dgit-opts] [suite]
 535   dgit [dgit-opts] rpush build-host:build-dir ...
 536 important dgit options:
 537   -k<keyid>           sign tag and package with <keyid> instead of default
 538   --dry-run -n        do not change anything, but go through the motions
 539   --damp-run -L       like --dry-run but make local changes, without signing
 540   --new -N            allow introducing a new package
 541   --debug -D          increase debug level
 542   -c<name>=<value>    set git config option (used directly by dgit too)
 543 END
 544
 545 our $later_warning_msg = <<END;
 546 Perhaps the upload is stuck in incoming.  Using the version from git.
 547 END
 548
 549 sub badusage {
 550     print STDERR "$us: @_\n", $helpmsg or die $!;
 551     exit 8;
 552 }
 553
 554 sub nextarg {
 555     @ARGV or badusage "too few arguments";
 556     return scalar shift @ARGV;
 557 }
 558
 559 sub pre_help () {
 560     no_local_git_cfg();
 561 }
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638
 639 sub git_slurp_config () {
 640     # This algoritm is a bit subtle, but this is needed so that for
 641     # options which we want to be single-valued, we allow the
 642     # different config sources to override properly.  See #835858.
 643     foreach my $src (@gitcfgsources) {
 644         next if $src eq 'cmdline';
 645         # we do this ourselves since git doesn't handle it
 646
 647         $gitcfgs{$src} = git_slurp_config_src $src;
 648     }
 649 }
 650
 651 sub git_get_config ($) {
 652     my ($c) = @_;
 653     foreach my $src (@gitcfgsources) {
 654         my $l = $gitcfgs{$src}{$c};
 655         confess "internal error ($l $c)" if $l && !ref $l;
 656         printdebug"C $c ".(defined $l ?
 657                            join " ", map { messagequote "'$_'" } @$l :
 658                            "undef")."\n"
 659             if $debuglevel >= 4;
 660         $l or next;
 661         @$l==1 or badcfg "multiple values for $c".
 662             " (in $src git config)" if @$l > 1;
 663         return $l->[0];
 664     }
 665     return undef;
 666 }
 667
 668 sub cfg {
 669     foreach my $c (@_) {
 670         return undef if $c =~ /RETURN-UNDEF/;
 671         printdebug "C? $c\n" if $debuglevel >= 5;
 672         my $v = git_get_config($c);
 673         return $v if defined $v;
 674         my $dv = $defcfg{$c};
 675         if (defined $dv) {
 676             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 677             return $dv;
 678         }
 679     }
 680     badcfg "need value for one of: @_\n".
 681         "$us: distro or suite appears not to be (properly) supported";
 682 }
 683
 684 sub no_local_git_cfg () {
 685     # needs to be called from pre_*
 686     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 687 }
 688
 689 sub access_basedistro__noalias () {
 690     if (defined $idistro) {
 691         return $idistro;
 692     } else {
 693         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 694         return $def if defined $def;
 695         foreach my $src (@gitcfgsources, 'internal') {
 696             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 697             next unless $kl;
 698             foreach my $k (keys %$kl) {
 699                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 700                 my $dpat = $1;
 701                 next unless match_glob $dpat, $isuite;
 702                 return $kl->{$k};
 703             }
 704         }
 705         return cfg("dgit.default.distro");
 706     }
 707 }
 708
 709 sub access_basedistro () {
 710     my $noalias = access_basedistro__noalias();
 711     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 712     return $canon // $noalias;
 713 }
 714
 715 sub access_nomdistro () {
 716     my $base = access_basedistro();
 717     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 718     $r =~ m/^$distro_re$/ or badcfg
 719  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 720     return $r;
 721 }
 722
 723 sub access_quirk () {
 724     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 725     my $basedistro = access_basedistro();
 726     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 727                               'RETURN-UNDEF');
 728     if (defined $backports_quirk) {
 729         my $re = $backports_quirk;
 730         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 731         $re =~ s/\*/.*/g;
 732         $re =~ s/\%/([-0-9a-z_]+)/
 733             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 734         if ($isuite =~ m/^$re$/) {
 735             return ('backports',"$basedistro-backports",$1);
 736         }
 737     }
 738     return ('none',undef);
 739 }
 740
 741 our $access_forpush;
 742
 743 sub parse_cfg_bool ($$$) {
 744     my ($what,$def,$v) = @_;
 745     $v //= $def;
 746     return
 747         $v =~ m/^[ty1]/ ? 1 :
 748         $v =~ m/^[fn0]/ ? 0 :
 749         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 750 }
 751
 752 sub access_forpush_config () {
 753     my $d = access_basedistro();
 754
 755     return 1 if
 756         $new_package &&
 757         parse_cfg_bool('new-private-pushers', 0,
 758                        cfg("dgit-distro.$d.new-private-pushers",
 759                            'RETURN-UNDEF'));
 760
 761     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 762     $v //= 'a';
 763     return
 764         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 765         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 766         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 767         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 768 }
 769
 770 sub access_forpush () {
 771     $access_forpush //= access_forpush_config();
 772     return $access_forpush;
 773 }
 774
 775 sub pushing () {
 776     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 777     badcfg "pushing but distro is configured readonly"
 778         if access_forpush_config() eq '0';
 779     $access_forpush = 1;
 780     $supplementary_message = <<'END' unless $we_are_responder;
 781 Push failed, before we got started.
 782 You can retry the push, after fixing the problem, if you like.
 783 END
 784     parseopts_late_defaults();
 785 }
 786
 787 sub notpushing () {
 788     parseopts_late_defaults();
 789 }
 790
 791 sub supplementary_message ($) {
 792     my ($msg) = @_;
 793     if (!$we_are_responder) {
 794         $supplementary_message = $msg;
 795         return;
 796     } elsif ($protovsn >= 3) {
 797         responder_send_command "supplementary-message ".length($msg)
 798             or die $!;
 799         print PO $msg or die $!;
 800     }
 801 }
 802
 803 sub access_distros () {
 804     # Returns list of distros to try, in order
 805     #
 806     # We want to try:
 807     #    0. `instead of' distro name(s) we have been pointed to
 808     #    1. the access_quirk distro, if any
 809     #    2a. the user's specified distro, or failing that  } basedistro
 810     #    2b. the distro calculated from the suite          }
 811     my @l = access_basedistro();
 812
 813     my (undef,$quirkdistro) = access_quirk();
 814     unshift @l, $quirkdistro;
 815     unshift @l, $instead_distro;
 816     @l = grep { defined } @l;
 817
 818     push @l, access_nomdistro();
 819
 820     if (access_forpush()) {
 821         @l = map { ("$_/push", $_) } @l;
 822     }
 823     @l;
 824 }
 825
 826 sub access_cfg_cfgs (@) {
 827     my (@keys) = @_;
 828     my @cfgs;
 829     # The nesting of these loops determines the search order.  We put
 830     # the key loop on the outside so that we search all the distros
 831     # for each key, before going on to the next key.  That means that
 832     # if access_cfg is called with a more specific, and then a less
 833     # specific, key, an earlier distro can override the less specific
 834     # without necessarily overriding any more specific keys.  (If the
 835     # distro wants to override the more specific keys it can simply do
 836     # so; whereas if we did the loop the other way around, it would be
 837     # impossible to for an earlier distro to override a less specific
 838     # key but not the more specific ones without restating the unknown
 839     # values of the more specific keys.
 840     my @realkeys;
 841     my @rundef;
 842     # We have to deal with RETURN-UNDEF specially, so that we don't
 843     # terminate the search prematurely.
 844     foreach (@keys) {
 845         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 846         push @realkeys, $_
 847     }
 848     foreach my $d (access_distros()) {
 849         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 850     }
 851     push @cfgs, map { "dgit.default.$_" } @realkeys;
 852     push @cfgs, @rundef;
 853     return @cfgs;
 854 }
 855
 856 sub access_cfg (@) {
 857     my (@keys) = @_;
 858     my (@cfgs) = access_cfg_cfgs(@keys);
 859     my $value = cfg(@cfgs);
 860     return $value;
 861 }
 862
 863 sub access_cfg_bool ($$) {
 864     my ($def, @keys) = @_;
 865     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 866 }
 867
 868 sub string_to_ssh ($) {
 869     my ($spec) = @_;
 870     if ($spec =~ m/\s/) {
 871         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 872     } else {
 873         return ($spec);
 874     }
 875 }
 876
 877 sub access_cfg_ssh () {
 878     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 879     if (!defined $gitssh) {
 880         return @ssh;
 881     } else {
 882         return string_to_ssh $gitssh;
 883     }
 884 }
 885
 886 sub access_runeinfo ($) {
 887     my ($info) = @_;
 888     return ": dgit ".access_basedistro()." $info ;";
 889 }
 890
 891 sub access_someuserhost ($) {
 892     my ($some) = @_;
 893     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 894     defined($user) && length($user) or
 895         $user = access_cfg("$some-user",'username');
 896     my $host = access_cfg("$some-host");
 897     return length($user) ? "$user\@$host" : $host;
 898 }
 899
 900 sub access_gituserhost () {
 901     return access_someuserhost('git');
 902 }
 903
 904 sub access_giturl (;$) {
 905     my ($optional) = @_;
 906     my $url = access_cfg('git-url','RETURN-UNDEF');
 907     my $suffix;
 908     if (!length $url) {
 909         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 910         return undef unless defined $proto;
 911         $url =
 912             $proto.
 913             access_gituserhost().
 914             access_cfg('git-path');
 915     } else {
 916         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 917     }
 918     $suffix //= '.git';
 919     return "$url/$package$suffix";
 920 }
 921
 922 sub parsecontrolfh ($$;$) {
 923     my ($fh, $desc, $allowsigned) = @_;
 924     our $dpkgcontrolhash_noissigned;
 925     my $c;
 926     for (;;) {
 927         my %opts = ('name' => $desc);
 928         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 929         $c = Dpkg::Control::Hash->new(%opts);
 930         $c->parse($fh,$desc) or die "parsing of $desc failed";
 931         last if $allowsigned;
 932         last if $dpkgcontrolhash_noissigned;
 933         my $issigned= $c->get_option('is_pgp_signed');
 934         if (!defined $issigned) {
 935             $dpkgcontrolhash_noissigned= 1;
 936             seek $fh, 0,0 or die "seek $desc: $!";
 937         } elsif ($issigned) {
 938             fail "control file $desc is (already) PGP-signed. ".
 939                 " Note that dgit push needs to modify the .dsc and then".
 940                 " do the signature itself";
 941         } else {
 942             last;
 943         }
 944     }
 945     return $c;
 946 }
 947
 948 sub parsecontrol {
 949     my ($file, $desc, $allowsigned) = @_;
 950     my $fh = new IO::Handle;
 951     open $fh, '<', $file or die "$file: $!";
 952     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 953     $fh->error and die $!;
 954     close $fh;
 955     return $c;
 956 }
 957
 958 sub getfield ($$) {
 959     my ($dctrl,$field) = @_;
 960     my $v = $dctrl->{$field};
 961     return $v if defined $v;
 962     fail "missing field $field in ".$dctrl->get_option('name');
 963 }
 964
 965 sub parsechangelog {
 966     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 967     my $p = new IO::Handle;
 968     my @cmd = (qw(dpkg-parsechangelog), @_);
 969     open $p, '-|', @cmd or die $!;
 970     $c->parse($p);
 971     $?=0; $!=0; close $p or failedcmd @cmd;
 972     return $c;
 973 }
 974
 975 sub commit_getclogp ($) {
 976     # Returns the parsed changelog hashref for a particular commit
 977     my ($objid) = @_;
 978     our %commit_getclogp_memo;
 979     my $memo = $commit_getclogp_memo{$objid};
 980     return $memo if $memo;
 981     mkpath '.git/dgit';
 982     my $mclog = ".git/dgit/clog-$objid";
 983     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 984         "$objid:debian/changelog";
 985     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 986 }
 987
 988 sub parse_dscdata () {
 989     my $dscfh = new IO::File \$dscdata, '<' or die $!;
 990     printdebug Dumper($dscdata) if $debuglevel>1;
 991     $dsc = parsecontrolfh($dscfh,$dscurl,1);
 992     printdebug Dumper($dsc) if $debuglevel>1;
 993 }
 994
 995 our %rmad;
 996
 997 sub archive_query ($;@) {
 998     my ($method) = shift @_;
 999     fail "this operation does not support multiple comma-separated suites"
1000         if $isuite =~ m/,/;
1001     my $query = access_cfg('archive-query','RETURN-UNDEF');
1002     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1003     my $proto = $1;
1004     my $data = $'; #';
1005     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1006 }
1007
1008 sub archive_query_prepend_mirror {
1009     my $m = access_cfg('mirror');
1010     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1011 }
1012
1013 sub pool_dsc_subpath ($$) {
1014     my ($vsn,$component) = @_; # $package is implict arg
1015     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1016     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1017 }
1018
1019 sub cfg_apply_map ($$$) {
1020     my ($varref, $what, $mapspec) = @_;
1021     return unless $mapspec;
1022
1023     printdebug "config $what EVAL{ $mapspec; }\n";
1024     $_ = $$varref;
1025     eval "package Dgit::Config; $mapspec;";
1026     die $@ if $@;
1027     $$varref = $_;
1028 }
1029
1030 #---------- `ftpmasterapi' archive query method (nascent) ----------
1031
1032 sub archive_api_query_cmd ($) {
1033     my ($subpath) = @_;
1034     my @cmd = (@curl, qw(-sS));
1035     my $url = access_cfg('archive-query-url');
1036     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1037         my $host = $1;
1038         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1039         foreach my $key (split /\:/, $keys) {
1040             $key =~ s/\%HOST\%/$host/g;
1041             if (!stat $key) {
1042                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1043                 next;
1044             }
1045             fail "config requested specific TLS key but do not know".
1046                 " how to get curl to use exactly that EE key ($key)";
1047 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1048 #           # Sadly the above line does not work because of changes
1049 #           # to gnutls.   The real fix for #790093 may involve
1050 #           # new curl options.
1051             last;
1052         }
1053         # Fixing #790093 properly will involve providing a value
1054         # for this on clients.
1055         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1056         push @cmd, split / /, $kargs if defined $kargs;
1057     }
1058     push @cmd, $url.$subpath;
1059     return @cmd;
1060 }
1061
1062 sub api_query ($$;$) {
1063     use JSON;
1064     my ($data, $subpath, $ok404) = @_;
1065     badcfg "ftpmasterapi archive query method takes no data part"
1066         if length $data;
1067     my @cmd = archive_api_query_cmd($subpath);
1068     my $url = $cmd[$#cmd];
1069     push @cmd, qw(-w %{http_code});
1070     my $json = cmdoutput @cmd;
1071     unless ($json =~ s/\d+\d+\d$//) {
1072         failedcmd_report_cmd undef, @cmd;
1073         fail "curl failed to print 3-digit HTTP code";
1074     }
1075     my $code = $&;
1076     return undef if $code eq '404' && $ok404;
1077     fail "fetch of $url gave HTTP code $code"
1078         unless $url =~ m#^file://# or $code =~ m/^2/;
1079     return decode_json($json);
1080 }
1081
1082 sub canonicalise_suite_ftpmasterapi {
1083     my ($proto,$data) = @_;
1084     my $suites = api_query($data, 'suites');
1085     my @matched;
1086     foreach my $entry (@$suites) {
1087         next unless grep {
1088             my $v = $entry->{$_};
1089             defined $v && $v eq $isuite;
1090         } qw(codename name);
1091         push @matched, $entry;
1092     }
1093     fail "unknown suite $isuite" unless @matched;
1094     my $cn;
1095     eval {
1096         @matched==1 or die "multiple matches for suite $isuite\n";
1097         $cn = "$matched[0]{codename}";
1098         defined $cn or die "suite $isuite info has no codename\n";
1099         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1100     };
1101     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1102         if length $@;
1103     return $cn;
1104 }
1105
1106 sub archive_query_ftpmasterapi {
1107     my ($proto,$data) = @_;
1108     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1109     my @rows;
1110     my $digester = Digest::SHA->new(256);
1111     foreach my $entry (@$info) {
1112         eval {
1113             my $vsn = "$entry->{version}";
1114             my ($ok,$msg) = version_check $vsn;
1115             die "bad version: $msg\n" unless $ok;
1116             my $component = "$entry->{component}";
1117             $component =~ m/^$component_re$/ or die "bad component";
1118             my $filename = "$entry->{filename}";
1119             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1120                 or die "bad filename";
1121             my $sha256sum = "$entry->{sha256sum}";
1122             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1123             push @rows, [ $vsn, "/pool/$component/$filename",
1124                           $digester, $sha256sum ];
1125         };
1126         die "bad ftpmaster api response: $@\n".Dumper($entry)
1127             if length $@;
1128     }
1129     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1130     return archive_query_prepend_mirror @rows;
1131 }
1132
1133 sub file_in_archive_ftpmasterapi {
1134     my ($proto,$data,$filename) = @_;
1135     my $pat = $filename;
1136     $pat =~ s/_/\\_/g;
1137     $pat = "%/$pat";
1138     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1139     my $info = api_query($data, "file_in_archive/$pat", 1);
1140 }
1141
1142 #---------- `aptget' archive query method ----------
1143
1144 our $aptget_base;
1145 our $aptget_releasefile;
1146 our $aptget_configpath;
1147
1148 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1149 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1150
1151 sub aptget_cache_clean {
1152     runcmd_ordryrun_local qw(sh -ec),
1153         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1154         'x', $aptget_base;
1155 }
1156
1157 sub aptget_lock_acquire () {
1158     my $lockfile = "$aptget_base/lock";
1159     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1160     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1161 }
1162
1163 sub aptget_prep ($) {
1164     my ($data) = @_;
1165     return if defined $aptget_base;
1166
1167     badcfg "aptget archive query method takes no data part"
1168         if length $data;
1169
1170     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1171
1172     ensuredir $cache;
1173     ensuredir "$cache/dgit";
1174     my $cachekey =
1175         access_cfg('aptget-cachekey','RETURN-UNDEF')
1176         // access_nomdistro();
1177
1178     $aptget_base = "$cache/dgit/aptget";
1179     ensuredir $aptget_base;
1180
1181     my $quoted_base = $aptget_base;
1182     die "$quoted_base contains bad chars, cannot continue"
1183         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1184
1185     ensuredir $aptget_base;
1186
1187     aptget_lock_acquire();
1188
1189     aptget_cache_clean();
1190
1191     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1192     my $sourceslist = "source.list#$cachekey";
1193
1194     my $aptsuites = $isuite;
1195     cfg_apply_map(\$aptsuites, 'suite map',
1196                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1197
1198     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1199     printf SRCS "deb-src %s %s %s\n",
1200         access_cfg('mirror'),
1201         $aptsuites,
1202         access_cfg('aptget-components')
1203         or die $!;
1204
1205     ensuredir "$aptget_base/cache";
1206     ensuredir "$aptget_base/lists";
1207
1208     open CONF, ">", $aptget_configpath or die $!;
1209     print CONF <<END;
1210 Debug::NoLocking "true";
1211 APT::Get::List-Cleanup "false";
1212 #clear APT::Update::Post-Invoke-Success;
1213 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1214 Dir::State::Lists "$quoted_base/lists";
1215 Dir::Etc::preferences "$quoted_base/preferences";
1216 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1217 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1218 END
1219
1220     foreach my $key (qw(
1221                         Dir::Cache
1222                         Dir::State
1223                         Dir::Cache::Archives
1224                         Dir::Etc::SourceParts
1225                         Dir::Etc::preferencesparts
1226                       )) {
1227         ensuredir "$aptget_base/$key";
1228         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1229     };
1230
1231     my $oldatime = (time // die $!) - 1;
1232     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1233         next unless stat_exists $oldlist;
1234         my ($mtime) = (stat _)[9];
1235         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1236     }
1237
1238     runcmd_ordryrun_local aptget_aptget(), qw(update);
1239
1240     my @releasefiles;
1241     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1242         next unless stat_exists $oldlist;
1243         my ($atime) = (stat _)[8];
1244         next if $atime == $oldatime;
1245         push @releasefiles, $oldlist;
1246     }
1247     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1248     @releasefiles = @inreleasefiles if @inreleasefiles;
1249     die "apt updated wrong number of Release files (@releasefiles), erk"
1250         unless @releasefiles == 1;
1251
1252     ($aptget_releasefile) = @releasefiles;
1253 }
1254
1255 sub canonicalise_suite_aptget {
1256     my ($proto,$data) = @_;
1257     aptget_prep($data);
1258
1259     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1260
1261     foreach my $name (qw(Codename Suite)) {
1262         my $val = $release->{$name};
1263         if (defined $val) {
1264             printdebug "release file $name: $val\n";
1265             $val =~ m/^$suite_re$/o or fail
1266  "Release file ($aptget_releasefile) specifies intolerable $name";
1267             cfg_apply_map(\$val, 'suite rmap',
1268                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1269             return $val
1270         }
1271     }
1272     return $isuite;
1273 }
1274
1275 sub archive_query_aptget {
1276     my ($proto,$data) = @_;
1277     aptget_prep($data);
1278
1279     ensuredir "$aptget_base/source";
1280     foreach my $old (<$aptget_base/source/*.dsc>) {
1281         unlink $old or die "$old: $!";
1282     }
1283
1284     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1285     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1286     # avoids apt-get source failing with ambiguous error code
1287
1288     runcmd_ordryrun_local
1289         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1290         aptget_aptget(), qw(--download-only --only-source source), $package;
1291
1292     my @dscs = <$aptget_base/source/*.dsc>;
1293     fail "apt-get source did not produce a .dsc" unless @dscs;
1294     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1295
1296     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1297
1298     use URI::Escape;
1299     my $uri = "file://". uri_escape $dscs[0];
1300     $uri =~ s{\%2f}{/}gi;
1301     return [ (getfield $pre_dsc, 'Version'), $uri ];
1302 }
1303
1304 sub file_in_archive_aptget () { return undef; }
1305
1306 #---------- `dummyapicat' archive query method ----------
1307
1308 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1309 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1310
1311 sub file_in_archive_dummycatapi ($$$) {
1312     my ($proto,$data,$filename) = @_;
1313     my $mirror = access_cfg('mirror');
1314     $mirror =~ s#^file://#/# or die "$mirror ?";
1315     my @out;
1316     my @cmd = (qw(sh -ec), '
1317             cd "$1"
1318             find -name "$2" -print0 |
1319             xargs -0r sha256sum
1320         ', qw(x), $mirror, $filename);
1321     debugcmd "-|", @cmd;
1322     open FIA, "-|", @cmd or die $!;
1323     while (<FIA>) {
1324         chomp or die;
1325         printdebug "| $_\n";
1326         m/^(\w+)  (\S+)$/ or die "$_ ?";
1327         push @out, { sha256sum => $1, filename => $2 };
1328     }
1329     close FIA or die failedcmd @cmd;
1330     return \@out;
1331 }
1332
1333 #---------- `madison' archive query method ----------
1334
1335 sub archive_query_madison {
1336     return archive_query_prepend_mirror
1337         map { [ @$_[0..1] ] } madison_get_parse(@_);
1338 }
1339
1340 sub madison_get_parse {
1341     my ($proto,$data) = @_;
1342     die unless $proto eq 'madison';
1343     if (!length $data) {
1344         $data= access_cfg('madison-distro','RETURN-UNDEF');
1345         $data //= access_basedistro();
1346     }
1347     $rmad{$proto,$data,$package} ||= cmdoutput
1348         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1349     my $rmad = $rmad{$proto,$data,$package};
1350
1351     my @out;
1352     foreach my $l (split /\n/, $rmad) {
1353         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1354                   \s*( [^ \t|]+ )\s* \|
1355                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1356                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1357         $1 eq $package or die "$rmad $package ?";
1358         my $vsn = $2;
1359         my $newsuite = $3;
1360         my $component;
1361         if (defined $4) {
1362             $component = $4;
1363         } else {
1364             $component = access_cfg('archive-query-default-component');
1365         }
1366         $5 eq 'source' or die "$rmad ?";
1367         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1368     }
1369     return sort { -version_compare($a->[0],$b->[0]); } @out;
1370 }
1371
1372 sub canonicalise_suite_madison {
1373     # madison canonicalises for us
1374     my @r = madison_get_parse(@_);
1375     @r or fail
1376         "unable to canonicalise suite using package $package".
1377         " which does not appear to exist in suite $isuite;".
1378         " --existing-package may help";
1379     return $r[0][2];
1380 }
1381
1382 sub file_in_archive_madison { return undef; }
1383
1384 #---------- `sshpsql' archive query method ----------
1385
1386 sub sshpsql ($$$) {
1387     my ($data,$runeinfo,$sql) = @_;
1388     if (!length $data) {
1389         $data= access_someuserhost('sshpsql').':'.
1390             access_cfg('sshpsql-dbname');
1391     }
1392     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1393     my ($userhost,$dbname) = ($`,$'); #';
1394     my @rows;
1395     my @cmd = (access_cfg_ssh, $userhost,
1396                access_runeinfo("ssh-psql $runeinfo").
1397                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1398                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1399     debugcmd "|",@cmd;
1400     open P, "-|", @cmd or die $!;
1401     while (<P>) {
1402         chomp or die;
1403         printdebug(">|$_|\n");
1404         push @rows, $_;
1405     }
1406     $!=0; $?=0; close P or failedcmd @cmd;
1407     @rows or die;
1408     my $nrows = pop @rows;
1409     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1410     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1411     @rows = map { [ split /\|/, $_ ] } @rows;
1412     my $ncols = scalar @{ shift @rows };
1413     die if grep { scalar @$_ != $ncols } @rows;
1414     return @rows;
1415 }
1416
1417 sub sql_injection_check {
1418     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1419 }
1420
1421 sub archive_query_sshpsql ($$) {
1422     my ($proto,$data) = @_;
1423     sql_injection_check $isuite, $package;
1424     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1425         SELECT source.version, component.name, files.filename, files.sha256sum
1426           FROM source
1427           JOIN src_associations ON source.id = src_associations.source
1428           JOIN suite ON suite.id = src_associations.suite
1429           JOIN dsc_files ON dsc_files.source = source.id
1430           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1431           JOIN component ON component.id = files_archive_map.component_id
1432           JOIN files ON files.id = dsc_files.file
1433          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1434            AND source.source='$package'
1435            AND files.filename LIKE '%.dsc';
1436 END
1437     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1438     my $digester = Digest::SHA->new(256);
1439     @rows = map {
1440         my ($vsn,$component,$filename,$sha256sum) = @$_;
1441         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1442     } @rows;
1443     return archive_query_prepend_mirror @rows;
1444 }
1445
1446 sub canonicalise_suite_sshpsql ($$) {
1447     my ($proto,$data) = @_;
1448     sql_injection_check $isuite;
1449     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1450         SELECT suite.codename
1451           FROM suite where suite_name='$isuite' or codename='$isuite';
1452 END
1453     @rows = map { $_->[0] } @rows;
1454     fail "unknown suite $isuite" unless @rows;
1455     die "ambiguous $isuite: @rows ?" if @rows>1;
1456     return $rows[0];
1457 }
1458
1459 sub file_in_archive_sshpsql ($$$) { return undef; }
1460
1461 #---------- `dummycat' archive query method ----------
1462
1463 sub canonicalise_suite_dummycat ($$) {
1464     my ($proto,$data) = @_;
1465     my $dpath = "$data/suite.$isuite";
1466     if (!open C, "<", $dpath) {
1467         $!==ENOENT or die "$dpath: $!";
1468         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1469         return $isuite;
1470     }
1471     $!=0; $_ = <C>;
1472     chomp or die "$dpath: $!";
1473     close C;
1474     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1475     return $_;
1476 }
1477
1478 sub archive_query_dummycat ($$) {
1479     my ($proto,$data) = @_;
1480     canonicalise_suite();
1481     my $dpath = "$data/package.$csuite.$package";
1482     if (!open C, "<", $dpath) {
1483         $!==ENOENT or die "$dpath: $!";
1484         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1485         return ();
1486     }
1487     my @rows;
1488     while (<C>) {
1489         next if m/^\#/;
1490         next unless m/\S/;
1491         die unless chomp;
1492         printdebug "dummycat query $csuite $package $dpath | $_\n";
1493         my @row = split /\s+/, $_;
1494         @row==2 or die "$dpath: $_ ?";
1495         push @rows, \@row;
1496     }
1497     C->error and die "$dpath: $!";
1498     close C;
1499     return archive_query_prepend_mirror
1500         sort { -version_compare($a->[0],$b->[0]); } @rows;
1501 }
1502
1503 sub file_in_archive_dummycat () { return undef; }
1504
1505 #---------- tag format handling ----------
1506
1507 sub access_cfg_tagformats () {
1508     split /\,/, access_cfg('dgit-tag-format');
1509 }
1510
1511 sub access_cfg_tagformats_can_splitbrain () {
1512     my %y = map { $_ => 1 } access_cfg_tagformats;
1513     foreach my $needtf (qw(new maint)) {
1514         next if $y{$needtf};
1515         return 0;
1516     }
1517     return 1;
1518 }
1519
1520 sub need_tagformat ($$) {
1521     my ($fmt, $why) = @_;
1522     fail "need to use tag format $fmt ($why) but also need".
1523         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1524         " - no way to proceed"
1525         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1526     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1527 }
1528
1529 sub select_tagformat () {
1530     # sets $tagformatfn
1531     return if $tagformatfn && !$tagformat_want;
1532     die 'bug' if $tagformatfn && $tagformat_want;
1533     # ... $tagformat_want assigned after previous select_tagformat
1534
1535     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1536     printdebug "select_tagformat supported @supported\n";
1537
1538     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1539     printdebug "select_tagformat specified @$tagformat_want\n";
1540
1541     my ($fmt,$why,$override) = @$tagformat_want;
1542
1543     fail "target distro supports tag formats @supported".
1544         " but have to use $fmt ($why)"
1545         unless $override
1546             or grep { $_ eq $fmt } @supported;
1547
1548     $tagformat_want = undef;
1549     $tagformat = $fmt;
1550     $tagformatfn = ${*::}{"debiantag_$fmt"};
1551
1552     fail "trying to use unknown tag format \`$fmt' ($why) !"
1553         unless $tagformatfn;
1554 }
1555
1556 #---------- archive query entrypoints and rest of program ----------
1557
1558 sub canonicalise_suite () {
1559     return if defined $csuite;
1560     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1561     $csuite = archive_query('canonicalise_suite');
1562     if ($isuite ne $csuite) {
1563         progress "canonical suite name for $isuite is $csuite";
1564     } else {
1565         progress "canonical suite name is $csuite";
1566     }
1567 }
1568
1569 sub get_archive_dsc () {
1570     canonicalise_suite();
1571     my @vsns = archive_query('archive_query');
1572     foreach my $vinfo (@vsns) {
1573         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1574         $dscurl = $vsn_dscurl;
1575         $dscdata = url_get($dscurl);
1576         if (!$dscdata) {
1577             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1578             next;
1579         }
1580         if ($digester) {
1581             $digester->reset();
1582             $digester->add($dscdata);
1583             my $got = $digester->hexdigest();
1584             $got eq $digest or
1585                 fail "$dscurl has hash $got but".
1586                     " archive told us to expect $digest";
1587         }
1588         parse_dscdata();
1589         my $fmt = getfield $dsc, 'Format';
1590         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1591             "unsupported source format $fmt, sorry";
1592
1593         $dsc_checked = !!$digester;
1594         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1595         return;
1596     }
1597     $dsc = undef;
1598     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1599 }
1600
1601 sub check_for_git ();
1602 sub check_for_git () {
1603     # returns 0 or 1
1604     my $how = access_cfg('git-check');
1605     if ($how eq 'ssh-cmd') {
1606         my @cmd =
1607             (access_cfg_ssh, access_gituserhost(),
1608              access_runeinfo("git-check $package").
1609              " set -e; cd ".access_cfg('git-path').";".
1610              " if test -d $package.git; then echo 1; else echo 0; fi");
1611         my $r= cmdoutput @cmd;
1612         if (defined $r and $r =~ m/^divert (\w+)$/) {
1613             my $divert=$1;
1614             my ($usedistro,) = access_distros();
1615             # NB that if we are pushing, $usedistro will be $distro/push
1616             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1617             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1618             progress "diverting to $divert (using config for $instead_distro)";
1619             return check_for_git();
1620         }
1621         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1622         return $r+0;
1623     } elsif ($how eq 'url') {
1624         my $prefix = access_cfg('git-check-url','git-url');
1625         my $suffix = access_cfg('git-check-suffix','git-suffix',
1626                                 'RETURN-UNDEF') // '.git';
1627         my $url = "$prefix/$package$suffix";
1628         my @cmd = (@curl, qw(-sS -I), $url);
1629         my $result = cmdoutput @cmd;
1630         $result =~ s/^\S+ 200 .*\n\r?\n//;
1631         # curl -sS -I with https_proxy prints
1632         # HTTP/1.0 200 Connection established
1633         $result =~ m/^\S+ (404|200) /s or
1634             fail "unexpected results from git check query - ".
1635                 Dumper($prefix, $result);
1636         my $code = $1;
1637         if ($code eq '404') {
1638             return 0;
1639         } elsif ($code eq '200') {
1640             return 1;
1641         } else {
1642             die;
1643         }
1644     } elsif ($how eq 'true') {
1645         return 1;
1646     } elsif ($how eq 'false') {
1647         return 0;
1648     } else {
1649         badcfg "unknown git-check \`$how'";
1650     }
1651 }
1652
1653 sub create_remote_git_repo () {
1654     my $how = access_cfg('git-create');
1655     if ($how eq 'ssh-cmd') {
1656         runcmd_ordryrun
1657             (access_cfg_ssh, access_gituserhost(),
1658              access_runeinfo("git-create $package").
1659              "set -e; cd ".access_cfg('git-path').";".
1660              " cp -a _template $package.git");
1661     } elsif ($how eq 'true') {
1662         # nothing to do
1663     } else {
1664         badcfg "unknown git-create \`$how'";
1665     }
1666 }
1667
1668 our ($dsc_hash,$lastpush_mergeinput);
1669 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1670
1671 our $ud = '.git/dgit/unpack';
1672
1673 sub prep_ud (;$) {
1674     my ($d) = @_;
1675     $d //= $ud;
1676     rmtree($d);
1677     mkpath '.git/dgit';
1678     mkdir $d or die $!;
1679 }
1680
1681 sub mktree_in_ud_here () {
1682     playtree_setup $gitcfgs{local};
1683 }
1684
1685 sub git_write_tree () {
1686     my $tree = cmdoutput @git, qw(write-tree);
1687     $tree =~ m/^\w+$/ or die "$tree ?";
1688     return $tree;
1689 }
1690
1691 sub git_add_write_tree () {
1692     runcmd @git, qw(add -Af .);
1693     return git_write_tree();
1694 }
1695
1696 sub remove_stray_gits ($) {
1697     my ($what) = @_;
1698     my @gitscmd = qw(find -name .git -prune -print0);
1699     debugcmd "|",@gitscmd;
1700     open GITS, "-|", @gitscmd or die $!;
1701     {
1702         local $/="\0";
1703         while (<GITS>) {
1704             chomp or die;
1705             print STDERR "$us: warning: removing from $what: ",
1706                 (messagequote $_), "\n";
1707             rmtree $_;
1708         }
1709     }
1710     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1711 }
1712
1713 sub mktree_in_ud_from_only_subdir ($;$) {
1714     my ($what,$raw) = @_;
1715
1716     # changes into the subdir
1717     my (@dirs) = <*/.>;
1718     die "expected one subdir but found @dirs ?" unless @dirs==1;
1719     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1720     my $dir = $1;
1721     changedir $dir;
1722
1723     remove_stray_gits($what);
1724     mktree_in_ud_here();
1725     if (!$raw) {
1726         my ($format, $fopts) = get_source_format();
1727         if (madformat($format)) {
1728             rmtree '.pc';
1729         }
1730     }
1731
1732     my $tree=git_add_write_tree();
1733     return ($tree,$dir);
1734 }
1735
1736 our @files_csum_info_fields =
1737     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1738      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1739      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1740
1741 sub dsc_files_info () {
1742     foreach my $csumi (@files_csum_info_fields) {
1743         my ($fname, $module, $method) = @$csumi;
1744         my $field = $dsc->{$fname};
1745         next unless defined $field;
1746         eval "use $module; 1;" or die $@;
1747         my @out;
1748         foreach (split /\n/, $field) {
1749             next unless m/\S/;
1750             m/^(\w+) (\d+) (\S+)$/ or
1751                 fail "could not parse .dsc $fname line \`$_'";
1752             my $digester = eval "$module"."->$method;" or die $@;
1753             push @out, {
1754                 Hash => $1,
1755                 Bytes => $2,
1756                 Filename => $3,
1757                 Digester => $digester,
1758             };
1759         }
1760         return @out;
1761     }
1762     fail "missing any supported Checksums-* or Files field in ".
1763         $dsc->get_option('name');
1764 }
1765
1766 sub dsc_files () {
1767     map { $_->{Filename} } dsc_files_info();
1768 }
1769
1770 sub files_compare_inputs (@) {
1771     my $inputs = \@_;
1772     my %record;
1773     my %fchecked;
1774
1775     my $showinputs = sub {
1776         return join "; ", map { $_->get_option('name') } @$inputs;
1777     };
1778
1779     foreach my $in (@$inputs) {
1780         my $expected_files;
1781         my $in_name = $in->get_option('name');
1782
1783         printdebug "files_compare_inputs $in_name\n";
1784
1785         foreach my $csumi (@files_csum_info_fields) {
1786             my ($fname) = @$csumi;
1787             printdebug "files_compare_inputs $in_name $fname\n";
1788
1789             my $field = $in->{$fname};
1790             next unless defined $field;
1791
1792             my @files;
1793             foreach (split /\n/, $field) {
1794                 next unless m/\S/;
1795
1796                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1797                     fail "could not parse $in_name $fname line \`$_'";
1798
1799                 printdebug "files_compare_inputs $in_name $fname $f\n";
1800
1801                 push @files, $f;
1802
1803                 my $re = \ $record{$f}{$fname};
1804                 if (defined $$re) {
1805                     $fchecked{$f}{$in_name} = 1;
1806                     $$re eq $info or
1807                         fail "hash or size of $f varies in $fname fields".
1808                         " (between: ".$showinputs->().")";
1809                 } else {
1810                     $$re = $info;
1811                 }
1812             }
1813             @files = sort @files;
1814             $expected_files //= \@files;
1815             "@$expected_files" eq "@files" or
1816                 fail "file list in $in_name varies between hash fields!";
1817         }
1818         $expected_files or
1819             fail "$in_name has no files list field(s)";
1820     }
1821     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1822         if $debuglevel>=2;
1823
1824     grep { keys %$_ == @$inputs-1 } values %fchecked
1825         or fail "no file appears in all file lists".
1826         " (looked in: ".$showinputs->().")";
1827 }
1828
1829 sub is_orig_file_in_dsc ($$) {
1830     my ($f, $dsc_files_info) = @_;
1831     return 0 if @$dsc_files_info <= 1;
1832     # One file means no origs, and the filename doesn't have a "what
1833     # part of dsc" component.  (Consider versions ending `.orig'.)
1834     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1835     return 1;
1836 }
1837
1838 sub is_orig_file_of_vsn ($$) {
1839     my ($f, $upstreamvsn) = @_;
1840     my $base = srcfn $upstreamvsn, '';
1841     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1842     return 1;
1843 }
1844
1845 sub changes_update_origs_from_dsc ($$$$) {
1846     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1847     my %changes_f;
1848     printdebug "checking origs needed ($upstreamvsn)...\n";
1849     $_ = getfield $changes, 'Files';
1850     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1851         fail "cannot find section/priority from .changes Files field";
1852     my $placementinfo = $1;
1853     my %changed;
1854     printdebug "checking origs needed placement '$placementinfo'...\n";
1855     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1856         $l =~ m/\S+$/ or next;
1857         my $file = $&;
1858         printdebug "origs $file | $l\n";
1859         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1860         printdebug "origs $file is_orig\n";
1861         my $have = archive_query('file_in_archive', $file);
1862         if (!defined $have) {
1863             print STDERR <<END;
1864 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1865 END
1866             return;
1867         }
1868         my $found_same = 0;
1869         my @found_differ;
1870         printdebug "origs $file \$#\$have=$#$have\n";
1871         foreach my $h (@$have) {
1872             my $same = 0;
1873             my @differ;
1874             foreach my $csumi (@files_csum_info_fields) {
1875                 my ($fname, $module, $method, $archivefield) = @$csumi;
1876                 next unless defined $h->{$archivefield};
1877                 $_ = $dsc->{$fname};
1878                 next unless defined;
1879                 m/^(\w+) .* \Q$file\E$/m or
1880                     fail ".dsc $fname missing entry for $file";
1881                 if ($h->{$archivefield} eq $1) {
1882                     $same++;
1883                 } else {
1884                     push @differ,
1885  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1886                 }
1887             }
1888             die "$file ".Dumper($h)." ?!" if $same && @differ;
1889             $found_same++
1890                 if $same;
1891             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1892                 if @differ;
1893         }
1894         printdebug "origs $file f.same=$found_same".
1895             " #f._differ=$#found_differ\n";
1896         if (@found_differ && !$found_same) {
1897             fail join "\n",
1898                 "archive contains $file with different checksum",
1899                 @found_differ;
1900         }
1901         # Now we edit the changes file to add or remove it
1902         foreach my $csumi (@files_csum_info_fields) {
1903             my ($fname, $module, $method, $archivefield) = @$csumi;
1904             next unless defined $changes->{$fname};
1905             if ($found_same) {
1906                 # in archive, delete from .changes if it's there
1907                 $changed{$file} = "removed" if
1908                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1909             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1910                 # not in archive, but it's here in the .changes
1911             } else {
1912                 my $dsc_data = getfield $dsc, $fname;
1913                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1914                 my $extra = $1;
1915                 $extra =~ s/ \d+ /$&$placementinfo /
1916                     or die "$fname $extra >$dsc_data< ?"
1917                     if $fname eq 'Files';
1918                 $changes->{$fname} .= "\n". $extra;
1919                 $changed{$file} = "added";
1920             }
1921         }
1922     }
1923     if (%changed) {
1924         foreach my $file (keys %changed) {
1925             progress sprintf
1926                 "edited .changes for archive .orig contents: %s %s",
1927                 $changed{$file}, $file;
1928         }
1929         my $chtmp = "$changesfile.tmp";
1930         $changes->save($chtmp);
1931         if (act_local()) {
1932             rename $chtmp,$changesfile or die "$changesfile $!";
1933         } else {
1934             progress "[new .changes left in $changesfile]";
1935         }
1936     } else {
1937         progress "$changesfile already has appropriate .orig(s) (if any)";
1938     }
1939 }
1940
1941 sub make_commit ($) {
1942     my ($file) = @_;
1943     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1944 }
1945
1946 sub make_commit_text ($) {
1947     my ($text) = @_;
1948     my ($out, $in);
1949     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1950     debugcmd "|",@cmd;
1951     print Dumper($text) if $debuglevel > 1;
1952     my $child = open2($out, $in, @cmd) or die $!;
1953     my $h;
1954     eval {
1955         print $in $text or die $!;
1956         close $in or die $!;
1957         $h = <$out>;
1958         $h =~ m/^\w+$/ or die;
1959         $h = $&;
1960         printdebug "=> $h\n";
1961     };
1962     close $out;
1963     waitpid $child, 0 == $child or die "$child $!";
1964     $? and failedcmd @cmd;
1965     return $h;
1966 }
1967
1968 sub clogp_authline ($) {
1969     my ($clogp) = @_;
1970     my $author = getfield $clogp, 'Maintainer';
1971     if ($author =~ m/^[^"\@]+\,/) {
1972         # single entry Maintainer field with unquoted comma
1973         $author = ($& =~ y/,//rd).$'; # strip the comma
1974     }
1975     # git wants a single author; any remaining commas in $author
1976     # are by now preceded by @ (or ").  It seems safer to punt on
1977     # "..." for now rather than attempting to dequote or something.
1978     $author =~ s#,.*##ms unless $author =~ m/"/;
1979     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1980     my $authline = "$author $date";
1981     $authline =~ m/$git_authline_re/o or
1982         fail "unexpected commit author line format \`$authline'".
1983         " (was generated from changelog Maintainer field)";
1984     return ($1,$2,$3) if wantarray;
1985     return $authline;
1986 }
1987
1988 sub vendor_patches_distro ($$) {
1989     my ($checkdistro, $what) = @_;
1990     return unless defined $checkdistro;
1991
1992     my $series = "debian/patches/\L$checkdistro\E.series";
1993     printdebug "checking for vendor-specific $series ($what)\n";
1994
1995     if (!open SERIES, "<", $series) {
1996         die "$series $!" unless $!==ENOENT;
1997         return;
1998     }
1999     while (<SERIES>) {
2000         next unless m/\S/;
2001         next if m/^\s+\#/;
2002
2003         print STDERR <<END;
2004
2005 Unfortunately, this source package uses a feature of dpkg-source where
2006 the same source package unpacks to different source code on different
2007 distros.  dgit cannot safely operate on such packages on affected
2008 distros, because the meaning of source packages is not stable.
2009
2010 Please ask the distro/maintainer to remove the distro-specific series
2011 files and use a different technique (if necessary, uploading actually
2012 different packages, if different distros are supposed to have
2013 different code).
2014
2015 END
2016         fail "Found active distro-specific series file for".
2017             " $checkdistro ($what): $series, cannot continue";
2018     }
2019     die "$series $!" if SERIES->error;
2020     close SERIES;
2021 }
2022
2023 sub check_for_vendor_patches () {
2024     # This dpkg-source feature doesn't seem to be documented anywhere!
2025     # But it can be found in the changelog (reformatted):
2026
2027     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2028     #   Author: Raphael Hertzog <hertzog@debian.org>
2029     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2030
2031     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2032     #   series files
2033     #
2034     #   If you have debian/patches/ubuntu.series and you were
2035     #   unpacking the source package on ubuntu, quilt was still
2036     #   directed to debian/patches/series instead of
2037     #   debian/patches/ubuntu.series.
2038     #
2039     #   debian/changelog                        |    3 +++
2040     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2041     #   2 files changed, 6 insertions(+), 1 deletion(-)
2042
2043     use Dpkg::Vendor;
2044     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2045     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2046                          "Dpkg::Vendor \`current vendor'");
2047     vendor_patches_distro(access_basedistro(),
2048                           "(base) distro being accessed");
2049     vendor_patches_distro(access_nomdistro(),
2050                           "(nominal) distro being accessed");
2051 }
2052
2053 sub generate_commits_from_dsc () {
2054     # See big comment in fetch_from_archive, below.
2055     # See also README.dsc-import.
2056     prep_ud();
2057     changedir $ud;
2058
2059     my @dfi = dsc_files_info();
2060     foreach my $fi (@dfi) {
2061         my $f = $fi->{Filename};
2062         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2063         my $upper_f = "../../../../$f";
2064
2065         printdebug "considering reusing $f: ";
2066
2067         if (link_ltarget "$upper_f,fetch", $f) {
2068             printdebug "linked (using ...,fetch).\n";
2069         } elsif ((printdebug "($!) "),
2070                  $! != ENOENT) {
2071             fail "accessing ../$f,fetch: $!";
2072         } elsif (link_ltarget $upper_f, $f) {
2073             printdebug "linked.\n";
2074         } elsif ((printdebug "($!) "),
2075                  $! != ENOENT) {
2076             fail "accessing ../$f: $!";
2077         } else {
2078             printdebug "absent.\n";
2079         }
2080
2081         my $refetched;
2082         complete_file_from_dsc('.', $fi, \$refetched)
2083             or next;
2084
2085         printdebug "considering saving $f: ";
2086
2087         if (link $f, $upper_f) {
2088             printdebug "linked.\n";
2089         } elsif ((printdebug "($!) "),
2090                  $! != EEXIST) {
2091             fail "saving ../$f: $!";
2092         } elsif (!$refetched) {
2093             printdebug "no need.\n";
2094         } elsif (link $f, "$upper_f,fetch") {
2095             printdebug "linked (using ...,fetch).\n";
2096         } elsif ((printdebug "($!) "),
2097                  $! != EEXIST) {
2098             fail "saving ../$f,fetch: $!";
2099         } else {
2100             printdebug "cannot.\n";
2101         }
2102     }
2103
2104     # We unpack and record the orig tarballs first, so that we only
2105     # need disk space for one private copy of the unpacked source.
2106     # But we can't make them into commits until we have the metadata
2107     # from the debian/changelog, so we record the tree objects now and
2108     # make them into commits later.
2109     my @tartrees;
2110     my $upstreamv = upstreamversion $dsc->{version};
2111     my $orig_f_base = srcfn $upstreamv, '';
2112
2113     foreach my $fi (@dfi) {
2114         # We actually import, and record as a commit, every tarball
2115         # (unless there is only one file, in which case there seems
2116         # little point.
2117
2118         my $f = $fi->{Filename};
2119         printdebug "import considering $f ";
2120         (printdebug "only one dfi\n"), next if @dfi == 1;
2121         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2122         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2123         my $compr_ext = $1;
2124
2125         my ($orig_f_part) =
2126             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2127
2128         printdebug "Y ", (join ' ', map { $_//"(none)" }
2129                           $compr_ext, $orig_f_part
2130                          ), "\n";
2131
2132         my $input = new IO::File $f, '<' or die "$f $!";
2133         my $compr_pid;
2134         my @compr_cmd;
2135
2136         if (defined $compr_ext) {
2137             my $cname =
2138                 Dpkg::Compression::compression_guess_from_filename $f;
2139             fail "Dpkg::Compression cannot handle file $f in source package"
2140                 if defined $compr_ext && !defined $cname;
2141             my $compr_proc =
2142                 new Dpkg::Compression::Process compression => $cname;
2143             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2144             my $compr_fh = new IO::Handle;
2145             my $compr_pid = open $compr_fh, "-|" // die $!;
2146             if (!$compr_pid) {
2147                 open STDIN, "<&", $input or die $!;
2148                 exec @compr_cmd;
2149                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2150             }
2151             $input = $compr_fh;
2152         }
2153
2154         rmtree "_unpack-tar";
2155         mkdir "_unpack-tar" or die $!;
2156         my @tarcmd = qw(tar -x -f -
2157                         --no-same-owner --no-same-permissions
2158                         --no-acls --no-xattrs --no-selinux);
2159         my $tar_pid = fork // die $!;
2160         if (!$tar_pid) {
2161             chdir "_unpack-tar" or die $!;
2162             open STDIN, "<&", $input or die $!;
2163             exec @tarcmd;
2164             die "dgit (child): exec $tarcmd[0]: $!";
2165         }
2166         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2167         !$? or failedcmd @tarcmd;
2168
2169         close $input or
2170             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2171              : die $!);
2172         # finally, we have the results in "tarball", but maybe
2173         # with the wrong permissions
2174
2175         runcmd qw(chmod -R +rwX _unpack-tar);
2176         changedir "_unpack-tar";
2177         remove_stray_gits($f);
2178         mktree_in_ud_here();
2179
2180         my ($tree) = git_add_write_tree();
2181         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2182         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2183             $tree = $1;
2184             printdebug "one subtree $1\n";
2185         } else {
2186             printdebug "multiple subtrees\n";
2187         }
2188         changedir "..";
2189         rmtree "_unpack-tar";
2190
2191         my $ent = [ $f, $tree ];
2192         push @tartrees, {
2193             Orig => !!$orig_f_part,
2194             Sort => (!$orig_f_part         ? 2 :
2195                      $orig_f_part =~ m/-/g ? 1 :
2196                                              0),
2197             F => $f,
2198             Tree => $tree,
2199         };
2200     }
2201
2202     @tartrees = sort {
2203         # put any without "_" first (spec is not clear whether files
2204         # are always in the usual order).  Tarballs without "_" are
2205         # the main orig or the debian tarball.
2206         $a->{Sort} <=> $b->{Sort} or
2207         $a->{F}    cmp $b->{F}
2208     } @tartrees;
2209
2210     my $any_orig = grep { $_->{Orig} } @tartrees;
2211
2212     my $dscfn = "$package.dsc";
2213
2214     my $treeimporthow = 'package';
2215
2216     open D, ">", $dscfn or die "$dscfn: $!";
2217     print D $dscdata or die "$dscfn: $!";
2218     close D or die "$dscfn: $!";
2219     my @cmd = qw(dpkg-source);
2220     push @cmd, '--no-check' if $dsc_checked;
2221     if (madformat $dsc->{format}) {
2222         push @cmd, '--skip-patches';
2223         $treeimporthow = 'unpatched';
2224     }
2225     push @cmd, qw(-x --), $dscfn;
2226     runcmd @cmd;
2227
2228     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2229     if (madformat $dsc->{format}) {
2230         check_for_vendor_patches();
2231     }
2232
2233     my $dappliedtree;
2234     if (madformat $dsc->{format}) {
2235         my @pcmd = qw(dpkg-source --before-build .);
2236         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2237         rmtree '.pc';
2238         $dappliedtree = git_add_write_tree();
2239     }
2240
2241     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2242     debugcmd "|",@clogcmd;
2243     open CLOGS, "-|", @clogcmd or die $!;
2244
2245     my $clogp;
2246     my $r1clogp;
2247
2248     printdebug "import clog search...\n";
2249
2250     for (;;) {
2251         my $stanzatext = do { local $/=""; <CLOGS>; };
2252         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2253         last if !defined $stanzatext;
2254
2255         my $desc = "package changelog, entry no.$.";
2256         open my $stanzafh, "<", \$stanzatext or die;
2257         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2258         $clogp //= $thisstanza;
2259
2260         printdebug "import clog $thisstanza->{version} $desc...\n";
2261
2262         last if !$any_orig; # we don't need $r1clogp
2263
2264         # We look for the first (most recent) changelog entry whose
2265         # version number is lower than the upstream version of this
2266         # package.  Then the last (least recent) previous changelog
2267         # entry is treated as the one which introduced this upstream
2268         # version and used for the synthetic commits for the upstream
2269         # tarballs.
2270
2271         # One might think that a more sophisticated algorithm would be
2272         # necessary.  But: we do not want to scan the whole changelog
2273         # file.  Stopping when we see an earlier version, which
2274         # necessarily then is an earlier upstream version, is the only
2275         # realistic way to do that.  Then, either the earliest
2276         # changelog entry we have seen so far is indeed the earliest
2277         # upload of this upstream version; or there are only changelog
2278         # entries relating to later upstream versions (which is not
2279         # possible unless the changelog and .dsc disagree about the
2280         # version).  Then it remains to choose between the physically
2281         # last entry in the file, and the one with the lowest version
2282         # number.  If these are not the same, we guess that the
2283         # versions were created in a non-monotic order rather than
2284         # that the changelog entries have been misordered.
2285
2286         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2287
2288         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2289         $r1clogp = $thisstanza;
2290
2291         printdebug "import clog $r1clogp->{version} becomes r1\n";
2292     }
2293     die $! if CLOGS->error;
2294     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2295
2296     $clogp or fail "package changelog has no entries!";
2297
2298     my $authline = clogp_authline $clogp;
2299     my $changes = getfield $clogp, 'Changes';
2300     $changes =~ s/^\n//; # Changes: \n
2301     my $cversion = getfield $clogp, 'Version';
2302
2303     if (@tartrees) {
2304         $r1clogp //= $clogp; # maybe there's only one entry;
2305         my $r1authline = clogp_authline $r1clogp;
2306         # Strictly, r1authline might now be wrong if it's going to be
2307         # unused because !$any_orig.  Whatever.
2308
2309         printdebug "import tartrees authline   $authline\n";
2310         printdebug "import tartrees r1authline $r1authline\n";
2311
2312         foreach my $tt (@tartrees) {
2313             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2314
2315             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2316 tree $tt->{Tree}
2317 author $r1authline
2318 committer $r1authline
2319
2320 Import $tt->{F}
2321
2322 [dgit import orig $tt->{F}]
2323 END_O
2324 tree $tt->{Tree}
2325 author $authline
2326 committer $authline
2327
2328 Import $tt->{F}
2329
2330 [dgit import tarball $package $cversion $tt->{F}]
2331 END_T
2332         }
2333     }
2334
2335     printdebug "import main commit\n";
2336
2337     open C, ">../commit.tmp" or die $!;
2338     print C <<END or die $!;
2339 tree $tree
2340 END
2341     print C <<END or die $! foreach @tartrees;
2342 parent $_->{Commit}
2343 END
2344     print C <<END or die $!;
2345 author $authline
2346 committer $authline
2347
2348 $changes
2349
2350 [dgit import $treeimporthow $package $cversion]
2351 END
2352
2353     close C or die $!;
2354     my $rawimport_hash = make_commit qw(../commit.tmp);
2355
2356     if (madformat $dsc->{format}) {
2357         printdebug "import apply patches...\n";
2358
2359         # regularise the state of the working tree so that
2360         # the checkout of $rawimport_hash works nicely.
2361         my $dappliedcommit = make_commit_text(<<END);
2362 tree $dappliedtree
2363 author $authline
2364 committer $authline
2365
2366 [dgit dummy commit]
2367 END
2368         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2369
2370         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2371
2372         # We need the answers to be reproducible
2373         my @authline = clogp_authline($clogp);
2374         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2375         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2376         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2377         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2378         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2379         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2380
2381         my $path = $ENV{PATH} or die;
2382
2383         foreach my $use_absurd (qw(0 1)) {
2384             runcmd @git, qw(checkout -q unpa);
2385             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2386             local $ENV{PATH} = $path;
2387             if ($use_absurd) {
2388                 chomp $@;
2389                 progress "warning: $@";
2390                 $path = "$absurdity:$path";
2391                 progress "$us: trying slow absurd-git-apply...";
2392                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2393                     or $!==ENOENT
2394                     or die $!;
2395             }
2396             eval {
2397                 die "forbid absurd git-apply\n" if $use_absurd
2398                     && forceing [qw(import-gitapply-no-absurd)];
2399                 die "only absurd git-apply!\n" if !$use_absurd
2400                     && forceing [qw(import-gitapply-absurd)];
2401
2402                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2403                 local $ENV{PATH} = $path                    if $use_absurd;
2404
2405                 my @showcmd = (gbp_pq, qw(import));
2406                 my @realcmd = shell_cmd
2407                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2408                 debugcmd "+",@realcmd;
2409                 if (system @realcmd) {
2410                     die +(shellquote @showcmd).
2411                         " failed: ".
2412                         failedcmd_waitstatus()."\n";
2413                 }
2414
2415                 my $gapplied = git_rev_parse('HEAD');
2416                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2417                 $gappliedtree eq $dappliedtree or
2418                     fail <<END;
2419 gbp-pq import and dpkg-source disagree!
2420  gbp-pq import gave commit $gapplied
2421  gbp-pq import gave tree $gappliedtree
2422  dpkg-source --before-build gave tree $dappliedtree
2423 END
2424                 $rawimport_hash = $gapplied;
2425             };
2426             last unless $@;
2427         }
2428         if ($@) {
2429             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2430             die $@;
2431         }
2432     }
2433
2434     progress "synthesised git commit from .dsc $cversion";
2435
2436     my $rawimport_mergeinput = {
2437         Commit => $rawimport_hash,
2438         Info => "Import of source package",
2439     };
2440     my @output = ($rawimport_mergeinput);
2441
2442     if ($lastpush_mergeinput) {
2443         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2444         my $oversion = getfield $oldclogp, 'Version';
2445         my $vcmp =
2446             version_compare($oversion, $cversion);
2447         if ($vcmp < 0) {
2448             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2449                 { Message => <<END, ReverseParents => 1 });
2450 Record $package ($cversion) in archive suite $csuite
2451 END
2452         } elsif ($vcmp > 0) {
2453             print STDERR <<END or die $!;
2454
2455 Version actually in archive:   $cversion (older)
2456 Last version pushed with dgit: $oversion (newer or same)
2457 $later_warning_msg
2458 END
2459             @output = $lastpush_mergeinput;
2460         } else {
2461             # Same version.  Use what's in the server git branch,
2462             # discarding our own import.  (This could happen if the
2463             # server automatically imports all packages into git.)
2464             @output = $lastpush_mergeinput;
2465         }
2466     }
2467     changedir '../../../..';
2468     rmtree($ud);
2469     return @output;
2470 }
2471
2472 sub complete_file_from_dsc ($$;$) {
2473     our ($dstdir, $fi, $refetched) = @_;
2474     # Ensures that we have, in $dstdir, the file $fi, with the correct
2475     # contents.  (Downloading it from alongside $dscurl if necessary.)
2476     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2477     # and will set $$refetched=1 if it did so (or tried to).
2478
2479     my $f = $fi->{Filename};
2480     my $tf = "$dstdir/$f";
2481     my $downloaded = 0;
2482
2483     my $got;
2484     my $checkhash = sub {
2485         open F, "<", "$tf" or die "$tf: $!";
2486         $fi->{Digester}->reset();
2487         $fi->{Digester}->addfile(*F);
2488         F->error and die $!;
2489         $got = $fi->{Digester}->hexdigest();
2490         return $got eq $fi->{Hash};
2491     };
2492
2493     if (stat_exists $tf) {
2494         if ($checkhash->()) {
2495             progress "using existing $f";
2496             return 1;
2497         }
2498         if (!$refetched) {
2499             fail "file $f has hash $got but .dsc".
2500                 " demands hash $fi->{Hash} ".
2501                 "(perhaps you should delete this file?)";
2502         }
2503         progress "need to fetch correct version of $f";
2504         unlink $tf or die "$tf $!";
2505         $$refetched = 1;
2506     } else {
2507         printdebug "$tf does not exist, need to fetch\n";
2508     }
2509
2510     my $furl = $dscurl;
2511     $furl =~ s{/[^/]+$}{};
2512     $furl .= "/$f";
2513     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2514     die "$f ?" if $f =~ m#/#;
2515     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2516     return 0 if !act_local();
2517
2518     $checkhash->() or
2519         fail "file $f has hash $got but .dsc".
2520             " demands hash $fi->{Hash} ".
2521             "(got wrong file from archive!)";
2522
2523     return 1;
2524 }
2525
2526 sub ensure_we_have_orig () {
2527     my @dfi = dsc_files_info();
2528     foreach my $fi (@dfi) {
2529         my $f = $fi->{Filename};
2530         next unless is_orig_file_in_dsc($f, \@dfi);
2531         complete_file_from_dsc('..', $fi)
2532             or next;
2533     }
2534 }
2535
2536 #---------- git fetch ----------
2537
2538 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2539 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2540
2541 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2542 # locally fetched refs because they have unhelpful names and clutter
2543 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2544 # whether we have made another local ref which refers to this object).
2545 #
2546 # (If we deleted them unconditionally, then we might end up
2547 # re-fetching the same git objects each time dgit fetch was run.)
2548 #
2549 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2550 # in git_fetch_us to fetch the refs in question, and possibly a call
2551 # to lrfetchref_used.
2552
2553 our (%lrfetchrefs_f, %lrfetchrefs_d);
2554 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2555
2556 sub lrfetchref_used ($) {
2557     my ($fullrefname) = @_;
2558     my $objid = $lrfetchrefs_f{$fullrefname};
2559     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2560 }
2561
2562 sub git_lrfetch_sane {
2563     my ($url, $supplementary, @specs) = @_;
2564     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2565     # at least as regards @specs.  Also leave the results in
2566     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2567     # able to clean these up.
2568     #
2569     # With $supplementary==1, @specs must not contain wildcards
2570     # and we add to our previous fetches (non-atomically).
2571
2572     # This is rather miserable:
2573     # When git fetch --prune is passed a fetchspec ending with a *,
2574     # it does a plausible thing.  If there is no * then:
2575     # - it matches subpaths too, even if the supplied refspec
2576     #   starts refs, and behaves completely madly if the source
2577     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2578     # - if there is no matching remote ref, it bombs out the whole
2579     #   fetch.
2580     # We want to fetch a fixed ref, and we don't know in advance
2581     # if it exists, so this is not suitable.
2582     #
2583     # Our workaround is to use git ls-remote.  git ls-remote has its
2584     # own qairks.  Notably, it has the absurd multi-tail-matching
2585     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2586     # refs/refs/foo etc.
2587     #
2588     # Also, we want an idempotent snapshot, but we have to make two
2589     # calls to the remote: one to git ls-remote and to git fetch.  The
2590     # solution is use git ls-remote to obtain a target state, and
2591     # git fetch to try to generate it.  If we don't manage to generate
2592     # the target state, we try again.
2593
2594     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2595
2596     my $specre = join '|', map {
2597         my $x = $_;
2598         $x =~ s/\W/\\$&/g;
2599         my $wildcard = $x =~ s/\\\*$/.*/;
2600         die if $wildcard && $supplementary;
2601         "(?:refs/$x)";
2602     } @specs;
2603     printdebug "git_lrfetch_sane specre=$specre\n";
2604     my $wanted_rref = sub {
2605         local ($_) = @_;
2606         return m/^(?:$specre)$/;
2607     };
2608
2609     my $fetch_iteration = 0;
2610     FETCH_ITERATION:
2611     for (;;) {
2612         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2613         if (++$fetch_iteration > 10) {
2614             fail "too many iterations trying to get sane fetch!";
2615         }
2616
2617         my @look = map { "refs/$_" } @specs;
2618         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2619         debugcmd "|",@lcmd;
2620
2621         my %wantr;
2622         open GITLS, "-|", @lcmd or die $!;
2623         while (<GITLS>) {
2624             printdebug "=> ", $_;
2625             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2626             my ($objid,$rrefname) = ($1,$2);
2627             if (!$wanted_rref->($rrefname)) {
2628                 print STDERR <<END;
2629 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2630 END
2631                 next;
2632             }
2633             $wantr{$rrefname} = $objid;
2634         }
2635         $!=0; $?=0;
2636         close GITLS or failedcmd @lcmd;
2637
2638         # OK, now %want is exactly what we want for refs in @specs
2639         my @fspecs = map {
2640             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2641             "+refs/$_:".lrfetchrefs."/$_";
2642         } @specs;
2643
2644         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2645
2646         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2647         runcmd_ordryrun_local @fcmd if @fspecs;
2648
2649         if (!$supplementary) {
2650             %lrfetchrefs_f = ();
2651         }
2652         my %objgot;
2653
2654         git_for_each_ref(lrfetchrefs, sub {
2655             my ($objid,$objtype,$lrefname,$reftail) = @_;
2656             $lrfetchrefs_f{$lrefname} = $objid;
2657             $objgot{$objid} = 1;
2658         });
2659
2660         if ($supplementary) {
2661             last;
2662         }
2663
2664         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2665             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2666             if (!exists $wantr{$rrefname}) {
2667                 if ($wanted_rref->($rrefname)) {
2668                     printdebug <<END;
2669 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2670 END
2671                 } else {
2672                     print STDERR <<END
2673 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2674 END
2675                 }
2676                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2677                 delete $lrfetchrefs_f{$lrefname};
2678                 next;
2679             }
2680         }
2681         foreach my $rrefname (sort keys %wantr) {
2682             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2683             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2684             my $want = $wantr{$rrefname};
2685             next if $got eq $want;
2686             if (!defined $objgot{$want}) {
2687                 print STDERR <<END;
2688 warning: git ls-remote suggests we want $lrefname
2689 warning:  and it should refer to $want
2690 warning:  but git fetch didn't fetch that object to any relevant ref.
2691 warning:  This may be due to a race with someone updating the server.
2692 warning:  Will try again...
2693 END
2694                 next FETCH_ITERATION;
2695             }
2696             printdebug <<END;
2697 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2698 END
2699             runcmd_ordryrun_local @git, qw(update-ref -m),
2700                 "dgit fetch git fetch fixup", $lrefname, $want;
2701             $lrfetchrefs_f{$lrefname} = $want;
2702         }
2703         last;
2704     }
2705
2706     if (defined $csuite) {
2707         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2708         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2709             my ($objid,$objtype,$lrefname,$reftail) = @_;
2710             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2711             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2712         });
2713     }
2714
2715     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2716         Dumper(\%lrfetchrefs_f);
2717 }
2718
2719 sub git_fetch_us () {
2720     # Want to fetch only what we are going to use, unless
2721     # deliberately-not-ff, in which case we must fetch everything.
2722
2723     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2724         map { "tags/$_" }
2725         (quiltmode_splitbrain
2726          ? (map { $_->('*',access_nomdistro) }
2727             \&debiantag_new, \&debiantag_maintview)
2728          : debiantags('*',access_nomdistro));
2729     push @specs, server_branch($csuite);
2730     push @specs, $rewritemap;
2731     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2732
2733     my $url = access_giturl();
2734     git_lrfetch_sane $url, 0, @specs;
2735
2736     my %here;
2737     my @tagpats = debiantags('*',access_nomdistro);
2738
2739     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2740         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2741         printdebug "currently $fullrefname=$objid\n";
2742         $here{$fullrefname} = $objid;
2743     });
2744     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2745         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2746         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2747         printdebug "offered $lref=$objid\n";
2748         if (!defined $here{$lref}) {
2749             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2750             runcmd_ordryrun_local @upd;
2751             lrfetchref_used $fullrefname;
2752         } elsif ($here{$lref} eq $objid) {
2753             lrfetchref_used $fullrefname;
2754         } else {
2755             print STDERR
2756                 "Not updating $lref from $here{$lref} to $objid.\n";
2757         }
2758     });
2759 }
2760
2761 #---------- dsc and archive handling ----------
2762
2763 sub mergeinfo_getclogp ($) {
2764     # Ensures thit $mi->{Clogp} exists and returns it
2765     my ($mi) = @_;
2766     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2767 }
2768
2769 sub mergeinfo_version ($) {
2770     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2771 }
2772
2773 sub fetch_from_archive_record_1 ($) {
2774     my ($hash) = @_;
2775     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2776             'DGIT_ARCHIVE', $hash;
2777     cmdoutput @git, qw(log -n2), $hash;
2778     # ... gives git a chance to complain if our commit is malformed
2779 }
2780
2781 sub fetch_from_archive_record_2 ($) {
2782     my ($hash) = @_;
2783     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2784     if (act_local()) {
2785         cmdoutput @upd_cmd;
2786     } else {
2787         dryrun_report @upd_cmd;
2788     }
2789 }
2790
2791 sub parse_dsc_field_def_dsc_distro () {
2792     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2793                            dgit.default.distro);
2794 }
2795
2796 sub parse_dsc_field ($$) {
2797     my ($dsc, $what) = @_;
2798     my $f;
2799     foreach my $field (@ourdscfield) {
2800         $f = $dsc->{$field};
2801         last if defined $f;
2802     }
2803
2804     if (!defined $f) {
2805         progress "$what: NO git hash";
2806         parse_dsc_field_def_dsc_distro();
2807     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2808              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2809         progress "$what: specified git info ($dsc_distro)";
2810         $dsc_hint_tag = [ $dsc_hint_tag ];
2811     } elsif ($f =~ m/^\w+\s*$/) {
2812         $dsc_hash = $&;
2813         parse_dsc_field_def_dsc_distro();
2814         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2815                           $dsc_distro ];
2816         progress "$what: specified git hash";
2817     } else {
2818         fail "$what: invalid Dgit info";
2819     }
2820 }
2821
2822 sub resolve_dsc_field_commit ($$) {
2823     my ($already_distro, $already_mapref) = @_;
2824
2825     return unless defined $dsc_hash;
2826
2827     my $mapref =
2828         defined $already_mapref &&
2829         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2830         ? $already_mapref : undef;
2831
2832     my $do_fetch;
2833     $do_fetch = sub {
2834         my ($what, @fetch) = @_;
2835
2836         local $idistro = $dsc_distro;
2837         my $lrf = lrfetchrefs;
2838
2839         if (!$chase_dsc_distro) {
2840             progress
2841                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2842             return 0;
2843         }
2844
2845         progress
2846             ".dsc names distro $dsc_distro: fetching $what";
2847
2848         my $url = access_giturl();
2849         if (!defined $url) {
2850             defined $dsc_hint_url or fail <<END;
2851 .dsc Dgit metadata is in context of distro $dsc_distro
2852 for which we have no configured url and .dsc provides no hint
2853 END
2854             my $proto =
2855                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2856                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2857             parse_cfg_bool "dsc-url-proto-ok", 'false',
2858                 cfg("dgit.dsc-url-proto-ok.$proto",
2859                     "dgit.default.dsc-url-proto-ok")
2860                 or fail <<END;
2861 .dsc Dgit metadata is in context of distro $dsc_distro
2862 for which we have no configured url;
2863 .dsc provides hinted url with protocol $proto which is unsafe.
2864 (can be overridden by config - consult documentation)
2865 END
2866             $url = $dsc_hint_url;
2867         }
2868
2869         git_lrfetch_sane $url, 1, @fetch;
2870
2871         return $lrf;
2872     };
2873
2874     my $rewrite_enable = do {
2875         local $idistro = $dsc_distro;
2876         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2877     };
2878
2879     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2880         if (!defined $mapref) {
2881             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2882             $mapref = $lrf.'/'.$rewritemap;
2883         }
2884         my $rewritemapdata = git_cat_file $mapref.':map';
2885         if (defined $rewritemapdata
2886             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2887             progress
2888                 "server's git history rewrite map contains a relevant entry!";
2889
2890             $dsc_hash = $1;
2891             if (defined $dsc_hash) {
2892                 progress "using rewritten git hash in place of .dsc value";
2893             } else {
2894                 progress "server data says .dsc hash is to be disregarded";
2895             }
2896         }
2897     }
2898
2899     if (!defined git_cat_file $dsc_hash) {
2900         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2901         my $lrf = $do_fetch->("additional commits", @tags) &&
2902             defined git_cat_file $dsc_hash
2903             or fail <<END;
2904 .dsc Dgit metadata requires commit $dsc_hash
2905 but we could not obtain that object anywhere.
2906 END
2907         foreach my $t (@tags) {
2908             my $fullrefname = $lrf.'/'.$t;
2909 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2910             next unless $lrfetchrefs_f{$fullrefname};
2911             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2912             lrfetchref_used $fullrefname;
2913         }
2914     }
2915 }
2916
2917 sub fetch_from_archive () {
2918     ensure_setup_existing_tree();
2919
2920     # Ensures that lrref() is what is actually in the archive, one way
2921     # or another, according to us - ie this client's
2922     # appropritaely-updated archive view.  Also returns the commit id.
2923     # If there is nothing in the archive, leaves lrref alone and
2924     # returns undef.  git_fetch_us must have already been called.
2925     get_archive_dsc();
2926
2927     if ($dsc) {
2928         parse_dsc_field($dsc, 'last upload to archive');
2929         resolve_dsc_field_commit access_basedistro,
2930             lrfetchrefs."/".$rewritemap
2931     } else {
2932         progress "no version available from the archive";
2933     }
2934
2935     # If the archive's .dsc has a Dgit field, there are three
2936     # relevant git commitids we need to choose between and/or merge
2937     # together:
2938     #   1. $dsc_hash: the Dgit field from the archive
2939     #   2. $lastpush_hash: the suite branch on the dgit git server
2940     #   3. $lastfetch_hash: our local tracking brach for the suite
2941     #
2942     # These may all be distinct and need not be in any fast forward
2943     # relationship:
2944     #
2945     # If the dsc was pushed to this suite, then the server suite
2946     # branch will have been updated; but it might have been pushed to
2947     # a different suite and copied by the archive.  Conversely a more
2948     # recent version may have been pushed with dgit but not appeared
2949     # in the archive (yet).
2950     #
2951     # $lastfetch_hash may be awkward because archive imports
2952     # (particularly, imports of Dgit-less .dscs) are performed only as
2953     # needed on individual clients, so different clients may perform a
2954     # different subset of them - and these imports are only made
2955     # public during push.  So $lastfetch_hash may represent a set of
2956     # imports different to a subsequent upload by a different dgit
2957     # client.
2958     #
2959     # Our approach is as follows:
2960     #
2961     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2962     # descendant of $dsc_hash, then it was pushed by a dgit user who
2963     # had based their work on $dsc_hash, so we should prefer it.
2964     # Otherwise, $dsc_hash was installed into this suite in the
2965     # archive other than by a dgit push, and (necessarily) after the
2966     # last dgit push into that suite (since a dgit push would have
2967     # been descended from the dgit server git branch); thus, in that
2968     # case, we prefer the archive's version (and produce a
2969     # pseudo-merge to overwrite the dgit server git branch).
2970     #
2971     # (If there is no Dgit field in the archive's .dsc then
2972     # generate_commit_from_dsc uses the version numbers to decide
2973     # whether the suite branch or the archive is newer.  If the suite
2974     # branch is newer it ignores the archive's .dsc; otherwise it
2975     # generates an import of the .dsc, and produces a pseudo-merge to
2976     # overwrite the suite branch with the archive contents.)
2977     #
2978     # The outcome of that part of the algorithm is the `public view',
2979     # and is same for all dgit clients: it does not depend on any
2980     # unpublished history in the local tracking branch.
2981     #
2982     # As between the public view and the local tracking branch: The
2983     # local tracking branch is only updated by dgit fetch, and
2984     # whenever dgit fetch runs it includes the public view in the
2985     # local tracking branch.  Therefore if the public view is not
2986     # descended from the local tracking branch, the local tracking
2987     # branch must contain history which was imported from the archive
2988     # but never pushed; and, its tip is now out of date.  So, we make
2989     # a pseudo-merge to overwrite the old imports and stitch the old
2990     # history in.
2991     #
2992     # Finally: we do not necessarily reify the public view (as
2993     # described above).  This is so that we do not end up stacking two
2994     # pseudo-merges.  So what we actually do is figure out the inputs
2995     # to any public view pseudo-merge and put them in @mergeinputs.
2996
2997     my @mergeinputs;
2998     # $mergeinputs[]{Commit}
2999     # $mergeinputs[]{Info}
3000     # $mergeinputs[0] is the one whose tree we use
3001     # @mergeinputs is in the order we use in the actual commit)
3002     #
3003     # Also:
3004     # $mergeinputs[]{Message} is a commit message to use
3005     # $mergeinputs[]{ReverseParents} if def specifies that parent
3006     #                                list should be in opposite order
3007     # Such an entry has no Commit or Info.  It applies only when found
3008     # in the last entry.  (This ugliness is to support making
3009     # identical imports to previous dgit versions.)
3010
3011     my $lastpush_hash = git_get_ref(lrfetchref());
3012     printdebug "previous reference hash=$lastpush_hash\n";
3013     $lastpush_mergeinput = $lastpush_hash && {
3014         Commit => $lastpush_hash,
3015         Info => "dgit suite branch on dgit git server",
3016     };
3017
3018     my $lastfetch_hash = git_get_ref(lrref());
3019     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3020     my $lastfetch_mergeinput = $lastfetch_hash && {
3021         Commit => $lastfetch_hash,
3022         Info => "dgit client's archive history view",
3023     };
3024
3025     my $dsc_mergeinput = $dsc_hash && {
3026         Commit => $dsc_hash,
3027         Info => "Dgit field in .dsc from archive",
3028     };
3029
3030     my $cwd = getcwd();
3031     my $del_lrfetchrefs = sub {
3032         changedir $cwd;
3033         my $gur;
3034         printdebug "del_lrfetchrefs...\n";
3035         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3036             my $objid = $lrfetchrefs_d{$fullrefname};
3037             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3038             if (!$gur) {
3039                 $gur ||= new IO::Handle;
3040                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3041             }
3042             printf $gur "delete %s %s\n", $fullrefname, $objid;
3043         }
3044         if ($gur) {
3045             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3046         }
3047     };
3048
3049     if (defined $dsc_hash) {
3050         ensure_we_have_orig();
3051         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3052             @mergeinputs = $dsc_mergeinput
3053         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3054             print STDERR <<END or die $!;
3055
3056 Git commit in archive is behind the last version allegedly pushed/uploaded.
3057 Commit referred to by archive: $dsc_hash
3058 Last version pushed with dgit: $lastpush_hash
3059 $later_warning_msg
3060 END
3061             @mergeinputs = ($lastpush_mergeinput);
3062         } else {
3063             # Archive has .dsc which is not a descendant of the last dgit
3064             # push.  This can happen if the archive moves .dscs about.
3065             # Just follow its lead.
3066             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3067                 progress "archive .dsc names newer git commit";
3068                 @mergeinputs = ($dsc_mergeinput);
3069             } else {
3070                 progress "archive .dsc names other git commit, fixing up";
3071                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3072             }
3073         }
3074     } elsif ($dsc) {
3075         @mergeinputs = generate_commits_from_dsc();
3076         # We have just done an import.  Now, our import algorithm might
3077         # have been improved.  But even so we do not want to generate
3078         # a new different import of the same package.  So if the
3079         # version numbers are the same, just use our existing version.
3080         # If the version numbers are different, the archive has changed
3081         # (perhaps, rewound).
3082         if ($lastfetch_mergeinput &&
3083             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3084                               (mergeinfo_version $mergeinputs[0]) )) {
3085             @mergeinputs = ($lastfetch_mergeinput);
3086         }
3087     } elsif ($lastpush_hash) {
3088         # only in git, not in the archive yet
3089         @mergeinputs = ($lastpush_mergeinput);
3090         print STDERR <<END or die $!;
3091
3092 Package not found in the archive, but has allegedly been pushed using dgit.
3093 $later_warning_msg
3094 END
3095     } else {
3096         printdebug "nothing found!\n";
3097         if (defined $skew_warning_vsn) {
3098             print STDERR <<END or die $!;
3099
3100 Warning: relevant archive skew detected.
3101 Archive allegedly contains $skew_warning_vsn
3102 But we were not able to obtain any version from the archive or git.
3103
3104 END
3105         }
3106         unshift @end, $del_lrfetchrefs;
3107         return undef;
3108     }
3109
3110     if ($lastfetch_hash &&
3111         !grep {
3112             my $h = $_->{Commit};
3113             $h and is_fast_fwd($lastfetch_hash, $h);
3114             # If true, one of the existing parents of this commit
3115             # is a descendant of the $lastfetch_hash, so we'll
3116             # be ff from that automatically.
3117         } @mergeinputs
3118         ) {
3119         # Otherwise:
3120         push @mergeinputs, $lastfetch_mergeinput;
3121     }
3122
3123     printdebug "fetch mergeinfos:\n";
3124     foreach my $mi (@mergeinputs) {
3125         if ($mi->{Info}) {
3126             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3127         } else {
3128             printdebug sprintf " ReverseParents=%d Message=%s",
3129                 $mi->{ReverseParents}, $mi->{Message};
3130         }
3131     }
3132
3133     my $compat_info= pop @mergeinputs
3134         if $mergeinputs[$#mergeinputs]{Message};
3135
3136     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3137
3138     my $hash;
3139     if (@mergeinputs > 1) {
3140         # here we go, then:
3141         my $tree_commit = $mergeinputs[0]{Commit};
3142
3143         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3144         $tree =~ m/\n\n/;  $tree = $`;
3145         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3146         $tree = $1;
3147
3148         # We use the changelog author of the package in question the
3149         # author of this pseudo-merge.  This is (roughly) correct if
3150         # this commit is simply representing aa non-dgit upload.
3151         # (Roughly because it does not record sponsorship - but we
3152         # don't have sponsorship info because that's in the .changes,
3153         # which isn't in the archivw.)
3154         #
3155         # But, it might be that we are representing archive history
3156         # updates (including in-archive copies).  These are not really
3157         # the responsibility of the person who created the .dsc, but
3158         # there is no-one whose name we should better use.  (The
3159         # author of the .dsc-named commit is clearly worse.)
3160
3161         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3162         my $author = clogp_authline $useclogp;
3163         my $cversion = getfield $useclogp, 'Version';
3164
3165         my $mcf = ".git/dgit/mergecommit";
3166         open MC, ">", $mcf or die "$mcf $!";
3167         print MC <<END or die $!;
3168 tree $tree
3169 END
3170
3171         my @parents = grep { $_->{Commit} } @mergeinputs;
3172         @parents = reverse @parents if $compat_info->{ReverseParents};
3173         print MC <<END or die $! foreach @parents;
3174 parent $_->{Commit}
3175 END
3176
3177         print MC <<END or die $!;
3178 author $author
3179 committer $author
3180
3181 END
3182
3183         if (defined $compat_info->{Message}) {
3184             print MC $compat_info->{Message} or die $!;
3185         } else {
3186             print MC <<END or die $!;
3187 Record $package ($cversion) in archive suite $csuite
3188
3189 Record that
3190 END
3191             my $message_add_info = sub {
3192                 my ($mi) = (@_);
3193                 my $mversion = mergeinfo_version $mi;
3194                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3195                     or die $!;
3196             };
3197
3198             $message_add_info->($mergeinputs[0]);
3199             print MC <<END or die $!;
3200 should be treated as descended from
3201 END
3202             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3203         }
3204
3205         close MC or die $!;
3206         $hash = make_commit $mcf;
3207     } else {
3208         $hash = $mergeinputs[0]{Commit};
3209     }
3210     printdebug "fetch hash=$hash\n";
3211
3212     my $chkff = sub {
3213         my ($lasth, $what) = @_;
3214         return unless $lasth;
3215         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3216     };
3217
3218     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3219         if $lastpush_hash;
3220     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3221
3222     fetch_from_archive_record_1($hash);
3223
3224     if (defined $skew_warning_vsn) {
3225         mkpath '.git/dgit';
3226         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3227         my $gotclogp = commit_getclogp($hash);
3228         my $got_vsn = getfield $gotclogp, 'Version';
3229         printdebug "SKEW CHECK GOT $got_vsn\n";
3230         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3231             print STDERR <<END or die $!;
3232
3233 Warning: archive skew detected.  Using the available version:
3234 Archive allegedly contains    $skew_warning_vsn
3235 We were able to obtain only   $got_vsn
3236
3237 END
3238         }
3239     }
3240
3241     if ($lastfetch_hash ne $hash) {
3242         fetch_from_archive_record_2($hash);
3243     }
3244
3245     lrfetchref_used lrfetchref();
3246
3247     check_gitattrs($hash, "fetched source tree");
3248
3249     unshift @end, $del_lrfetchrefs;
3250     return $hash;
3251 }
3252
3253 sub set_local_git_config ($$) {
3254     my ($k, $v) = @_;
3255     runcmd @git, qw(config), $k, $v;
3256 }
3257
3258 sub setup_mergechangelogs (;$) {
3259     my ($always) = @_;
3260     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3261
3262     my $driver = 'dpkg-mergechangelogs';
3263     my $cb = "merge.$driver";
3264     my $attrs = '.git/info/attributes';
3265     ensuredir '.git/info';
3266
3267     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3268     if (!open ATTRS, "<", $attrs) {
3269         $!==ENOENT or die "$attrs: $!";
3270     } else {
3271         while (<ATTRS>) {
3272             chomp;
3273             next if m{^debian/changelog\s};
3274             print NATTRS $_, "\n" or die $!;
3275         }
3276         ATTRS->error and die $!;
3277         close ATTRS;
3278     }
3279     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3280     close NATTRS;
3281
3282     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3283     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3284
3285     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3286 }
3287
3288 sub setup_useremail (;$) {
3289     my ($always) = @_;
3290     return unless $always || access_cfg_bool(1, 'setup-useremail');
3291
3292     my $setup = sub {
3293         my ($k, $envvar) = @_;
3294         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3295         return unless defined $v;
3296         set_local_git_config "user.$k", $v;
3297     };
3298
3299     $setup->('email', 'DEBEMAIL');
3300     $setup->('name', 'DEBFULLNAME');
3301 }
3302
3303 sub ensure_setup_existing_tree () {
3304     my $k = "remote.$remotename.skipdefaultupdate";
3305     my $c = git_get_config $k;
3306     return if defined $c;
3307     set_local_git_config $k, 'true';
3308 }
3309
3310 sub open_gitattrs () {
3311     my $gai = new IO::File ".git/info/attributes"
3312         or $!==ENOENT
3313         or die "open .git/info/attributes: $!";
3314     return $gai;
3315 }
3316
3317 sub is_gitattrs_setup () {
3318     my $gai = open_gitattrs();
3319     return 0 unless $gai;
3320     while (<$gai>) {
3321         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3322     }
3323     $gai->error and die $!;
3324     return 0;
3325 }
3326
3327 sub setup_gitattrs (;$) {
3328     my ($always) = @_;
3329     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3330
3331     if (is_gitattrs_setup()) {
3332         progress <<END;
3333 [attr]dgit-defuse-attrs already found in .git/info/attributes
3334  not doing further gitattributes setup
3335 END
3336         return;
3337     }
3338     my $af = ".git/info/attributes";
3339     ensuredir '.git/info';
3340     open GAO, "> $af.new" or die $!;
3341     print GAO <<END or die $!;
3342 *       dgit-defuse-attrs
3343 [attr]dgit-defuse-attrs $negate_harmful_gitattrs
3344 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3345 END
3346     my $gai = open_gitattrs();
3347     if ($gai) {
3348         while (<$gai>) {
3349             chomp;
3350             print GAO $_, "\n" or die $!;
3351         }
3352         $gai->error and die $!;
3353     }
3354     close GAO or die $!;
3355     rename "$af.new", "$af" or die "install $af: $!";
3356 }
3357
3358 sub setup_new_tree () {
3359     setup_mergechangelogs();
3360     setup_useremail();
3361     setup_gitattrs();
3362 }
3363
3364 sub check_gitattrs ($$) {
3365     my ($treeish, $what) = @_;
3366
3367     return if is_gitattrs_setup;
3368
3369     local $/="\0";
3370     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3371     debugcmd "|",@cmd;
3372     my $gafl = new IO::File;
3373     open $gafl, "-|", @cmd or die $!;
3374     while (<$gafl>) {
3375         chomp or die;
3376         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3377         next if $1 == 0;
3378         next unless m{(?:^|/)\.gitattributes$};
3379
3380         # oh dear, found one
3381         print STDERR <<END;
3382 dgit: warning: $what contains .gitattributes
3383 dgit: .gitattributes have not been defused.  Recommended: dgit setup-new-tree.
3384 END
3385         close $gafl;
3386         return;
3387     }
3388     # tree contains no .gitattributes files
3389     $?=0; $!=0; close $gafl or failedcmd @cmd;
3390 }
3391
3392
3393 sub multisuite_suite_child ($$$) {
3394     my ($tsuite, $merginputs, $fn) = @_;
3395     # in child, sets things up, calls $fn->(), and returns undef
3396     # in parent, returns canonical suite name for $tsuite
3397     my $canonsuitefh = IO::File::new_tmpfile;
3398     my $pid = fork // die $!;
3399     if (!$pid) {
3400         forkcheck_setup();
3401         $isuite = $tsuite;
3402         $us .= " [$isuite]";
3403         $debugprefix .= " ";
3404         progress "fetching $tsuite...";
3405         canonicalise_suite();
3406         print $canonsuitefh $csuite, "\n" or die $!;
3407         close $canonsuitefh or die $!;
3408         $fn->();
3409         return undef;
3410     }
3411     waitpid $pid,0 == $pid or die $!;
3412     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3413     seek $canonsuitefh,0,0 or die $!;
3414     local $csuite = <$canonsuitefh>;
3415     die $! unless defined $csuite && chomp $csuite;
3416     if ($? == 256*4) {
3417         printdebug "multisuite $tsuite missing\n";
3418         return $csuite;
3419     }
3420     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3421     push @$merginputs, {
3422         Ref => lrref,
3423         Info => $csuite,
3424     };
3425     return $csuite;
3426 }
3427
3428 sub fork_for_multisuite ($) {
3429     my ($before_fetch_merge) = @_;
3430     # if nothing unusual, just returns ''
3431     #
3432     # if multisuite:
3433     # returns 0 to caller in child, to do first of the specified suites
3434     # in child, $csuite is not yet set
3435     #
3436     # returns 1 to caller in parent, to finish up anything needed after
3437     # in parent, $csuite is set to canonicalised portmanteau
3438
3439     my $org_isuite = $isuite;
3440     my @suites = split /\,/, $isuite;
3441     return '' unless @suites > 1;
3442     printdebug "fork_for_multisuite: @suites\n";
3443
3444     my @mergeinputs;
3445
3446     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3447                                             sub { });
3448     return 0 unless defined $cbasesuite;
3449
3450     fail "package $package missing in (base suite) $cbasesuite"
3451         unless @mergeinputs;
3452
3453     my @csuites = ($cbasesuite);
3454
3455     $before_fetch_merge->();
3456
3457     foreach my $tsuite (@suites[1..$#suites]) {
3458         $tsuite =~ s/^-/$cbasesuite-/;
3459         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3460                                                sub {
3461             @end = ();
3462             fetch();
3463             exit 0;
3464         });
3465         # xxx collecte the ref here
3466
3467         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3468         push @csuites, $csubsuite;
3469     }
3470
3471     foreach my $mi (@mergeinputs) {
3472         my $ref = git_get_ref $mi->{Ref};
3473         die "$mi->{Ref} ?" unless length $ref;
3474         $mi->{Commit} = $ref;
3475     }
3476
3477     $csuite = join ",", @csuites;
3478
3479     my $previous = git_get_ref lrref;
3480     if ($previous) {
3481         unshift @mergeinputs, {
3482             Commit => $previous,
3483             Info => "local combined tracking branch",
3484             Warning =>
3485  "archive seems to have rewound: local tracking branch is ahead!",
3486         };
3487     }
3488
3489     foreach my $ix (0..$#mergeinputs) {
3490         $mergeinputs[$ix]{Index} = $ix;
3491     }
3492
3493     @mergeinputs = sort {
3494         -version_compare(mergeinfo_version $a,
3495                          mergeinfo_version $b) # highest version first
3496             or
3497         $a->{Index} <=> $b->{Index}; # earliest in spec first
3498     } @mergeinputs;
3499
3500     my @needed;
3501
3502   NEEDED:
3503     foreach my $mi (@mergeinputs) {
3504         printdebug "multisuite merge check $mi->{Info}\n";
3505         foreach my $previous (@needed) {
3506             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3507             printdebug "multisuite merge un-needed $previous->{Info}\n";
3508             next NEEDED;
3509         }
3510         push @needed, $mi;
3511         printdebug "multisuite merge this-needed\n";
3512         $mi->{Character} = '+';
3513     }
3514
3515     $needed[0]{Character} = '*';
3516
3517     my $output = $needed[0]{Commit};
3518
3519     if (@needed > 1) {
3520         printdebug "multisuite merge nontrivial\n";
3521         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3522
3523         my $commit = "tree $tree\n";
3524         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3525             "Input branches:\n";
3526
3527         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3528             printdebug "multisuite merge include $mi->{Info}\n";
3529             $mi->{Character} //= ' ';
3530             $commit .= "parent $mi->{Commit}\n";
3531             $msg .= sprintf " %s  %-25s %s\n",
3532                 $mi->{Character},
3533                 (mergeinfo_version $mi),
3534                 $mi->{Info};
3535         }
3536         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3537         $msg .= "\nKey\n".
3538             " * marks the highest version branch, which choose to use\n".
3539             " + marks each branch which was not already an ancestor\n\n".
3540             "[dgit multi-suite $csuite]\n";
3541         $commit .=
3542             "author $authline\n".
3543             "committer $authline\n\n";
3544         $output = make_commit_text $commit.$msg;
3545         printdebug "multisuite merge generated $output\n";
3546     }
3547
3548     fetch_from_archive_record_1($output);
3549     fetch_from_archive_record_2($output);
3550
3551     progress "calculated combined tracking suite $csuite";
3552
3553     return 1;
3554 }
3555
3556 sub clone_set_head () {
3557     open H, "> .git/HEAD" or die $!;
3558     print H "ref: ".lref()."\n" or die $!;
3559     close H or die $!;
3560 }
3561 sub clone_finish ($) {
3562     my ($dstdir) = @_;
3563     runcmd @git, qw(reset --hard), lrref();
3564     runcmd qw(bash -ec), <<'END';
3565         set -o pipefail
3566         git ls-tree -r --name-only -z HEAD | \
3567         xargs -0r touch -h -r . --
3568 END
3569     printdone "ready for work in $dstdir";
3570 }
3571
3572 sub clone ($) {
3573     # in multisuite, returns twice!
3574     # once in parent after first suite fetched,
3575     # and then again in child after everything is finished
3576     my ($dstdir) = @_;
3577     badusage "dry run makes no sense with clone" unless act_local();
3578
3579     my $multi_fetched = fork_for_multisuite(sub {
3580         printdebug "multi clone before fetch merge\n";
3581         changedir $dstdir;
3582     });
3583     if ($multi_fetched) {
3584         printdebug "multi clone after fetch merge\n";
3585         clone_set_head();
3586         clone_finish($dstdir);
3587         return;
3588     }
3589     printdebug "clone main body\n";
3590
3591     canonicalise_suite();
3592     my $hasgit = check_for_git();
3593     mkdir $dstdir or fail "create \`$dstdir': $!";
3594     changedir $dstdir;
3595     runcmd @git, qw(init -q);
3596     setup_new_tree();
3597     clone_set_head();
3598     my $giturl = access_giturl(1);
3599     if (defined $giturl) {
3600         runcmd @git, qw(remote add), 'origin', $giturl;
3601     }
3602     if ($hasgit) {
3603         progress "fetching existing git history";
3604         git_fetch_us();
3605         runcmd_ordryrun_local @git, qw(fetch origin);
3606     } else {
3607         progress "starting new git history";
3608     }
3609     fetch_from_archive() or no_such_package;
3610     my $vcsgiturl = $dsc->{'Vcs-Git'};
3611     if (length $vcsgiturl) {
3612         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3613         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3614     }
3615     clone_finish($dstdir);
3616 }
3617
3618 sub fetch () {
3619     canonicalise_suite();
3620     if (check_for_git()) {
3621         git_fetch_us();
3622     }
3623     fetch_from_archive() or no_such_package();
3624     printdone "fetched into ".lrref();
3625 }
3626
3627 sub pull () {
3628     my $multi_fetched = fork_for_multisuite(sub { });
3629     fetch() unless $multi_fetched; # parent
3630     return if $multi_fetched eq '0'; # child
3631     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3632         lrref();
3633     printdone "fetched to ".lrref()." and merged into HEAD";
3634 }
3635
3636 sub check_not_dirty () {
3637     foreach my $f (qw(local-options local-patch-header)) {
3638         if (stat_exists "debian/source/$f") {
3639             fail "git tree contains debian/source/$f";
3640         }
3641     }
3642
3643     return if $ignoredirty;
3644
3645     my @cmd = (@git, qw(diff --quiet HEAD));
3646     debugcmd "+",@cmd;
3647     $!=0; $?=-1; system @cmd;
3648     return if !$?;
3649     if ($?==256) {
3650         fail "working tree is dirty (does not match HEAD)";
3651     } else {
3652         failedcmd @cmd;
3653     }
3654 }
3655
3656 sub commit_admin ($) {
3657     my ($m) = @_;
3658     progress "$m";
3659     runcmd_ordryrun_local @git, qw(commit -m), $m;
3660 }
3661
3662 sub commit_quilty_patch () {
3663     my $output = cmdoutput @git, qw(status --porcelain);
3664     my %adds;
3665     foreach my $l (split /\n/, $output) {
3666         next unless $l =~ m/\S/;
3667         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3668             $adds{$1}++;
3669         }
3670     }
3671     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3672     if (!%adds) {
3673         progress "nothing quilty to commit, ok.";
3674         return;
3675     }
3676     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3677     runcmd_ordryrun_local @git, qw(add -f), @adds;
3678     commit_admin <<END
3679 Commit Debian 3.0 (quilt) metadata
3680
3681 [dgit ($our_version) quilt-fixup]
3682 END
3683 }
3684
3685 sub get_source_format () {
3686     my %options;
3687     if (open F, "debian/source/options") {
3688         while (<F>) {
3689             next if m/^\s*\#/;
3690             next unless m/\S/;
3691             s/\s+$//; # ignore missing final newline
3692             if (m/\s*\#\s*/) {
3693                 my ($k, $v) = ($`, $'); #');
3694                 $v =~ s/^"(.*)"$/$1/;
3695                 $options{$k} = $v;
3696             } else {
3697                 $options{$_} = 1;
3698             }
3699         }
3700         F->error and die $!;
3701         close F;
3702     } else {
3703         die $! unless $!==&ENOENT;
3704     }
3705
3706     if (!open F, "debian/source/format") {
3707         die $! unless $!==&ENOENT;
3708         return '';
3709     }
3710     $_ = <F>;
3711     F->error and die $!;
3712     chomp;
3713     return ($_, \%options);
3714 }
3715
3716 sub madformat_wantfixup ($) {
3717     my ($format) = @_;
3718     return 0 unless $format eq '3.0 (quilt)';
3719     our $quilt_mode_warned;
3720     if ($quilt_mode eq 'nocheck') {
3721         progress "Not doing any fixup of \`$format' due to".
3722             " ----no-quilt-fixup or --quilt=nocheck"
3723             unless $quilt_mode_warned++;
3724         return 0;
3725     }
3726     progress "Format \`$format', need to check/update patch stack"
3727         unless $quilt_mode_warned++;
3728     return 1;
3729 }
3730
3731 sub maybe_split_brain_save ($$$) {
3732     my ($headref, $dgitview, $msg) = @_;
3733     # => message fragment "$saved" describing disposition of $dgitview
3734     return "commit id $dgitview" unless defined $split_brain_save;
3735     my @cmd = (shell_cmd "cd ../../../..",
3736                @git, qw(update-ref -m),
3737                "dgit --dgit-view-save $msg HEAD=$headref",
3738                $split_brain_save, $dgitview);
3739     runcmd @cmd;
3740     return "and left in $split_brain_save";
3741 }
3742
3743 # An "infopair" is a tuple [ $thing, $what ]
3744 # (often $thing is a commit hash; $what is a description)
3745
3746 sub infopair_cond_equal ($$) {
3747     my ($x,$y) = @_;
3748     $x->[0] eq $y->[0] or fail <<END;
3749 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3750 END
3751 };
3752
3753 sub infopair_lrf_tag_lookup ($$) {
3754     my ($tagnames, $what) = @_;
3755     # $tagname may be an array ref
3756     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3757     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3758     foreach my $tagname (@tagnames) {
3759         my $lrefname = lrfetchrefs."/tags/$tagname";
3760         my $tagobj = $lrfetchrefs_f{$lrefname};
3761         next unless defined $tagobj;
3762         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3763         return [ git_rev_parse($tagobj), $what ];
3764     }
3765     fail @tagnames==1 ? <<END : <<END;
3766 Wanted tag $what (@tagnames) on dgit server, but not found
3767 END
3768 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3769 END
3770 }
3771
3772 sub infopair_cond_ff ($$) {
3773     my ($anc,$desc) = @_;
3774     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3775 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3776 END
3777 };
3778
3779 sub pseudomerge_version_check ($$) {
3780     my ($clogp, $archive_hash) = @_;
3781
3782     my $arch_clogp = commit_getclogp $archive_hash;
3783     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3784                      'version currently in archive' ];
3785     if (defined $overwrite_version) {
3786         if (length $overwrite_version) {
3787             infopair_cond_equal([ $overwrite_version,
3788                                   '--overwrite= version' ],
3789                                 $i_arch_v);
3790         } else {
3791             my $v = $i_arch_v->[0];
3792             progress "Checking package changelog for archive version $v ...";
3793             my $cd;
3794             eval {
3795                 my @xa = ("-f$v", "-t$v");
3796                 my $vclogp = parsechangelog @xa;
3797                 my $gf = sub {
3798                     my ($fn) = @_;
3799                     [ (getfield $vclogp, $fn),
3800                       "$fn field from dpkg-parsechangelog @xa" ];
3801                 };
3802                 my $cv = $gf->('Version');
3803                 infopair_cond_equal($i_arch_v, $cv);
3804                 $cd = $gf->('Distribution');
3805             };
3806             if ($@) {
3807                 $@ =~ s/^dgit: //gm;
3808                 fail "$@".
3809                     "Perhaps debian/changelog does not mention $v ?";
3810             }
3811             fail <<END if $cd->[0] =~ m/UNRELEASED/;
3812 $cd->[1] is $cd->[0]
3813 Your tree seems to based on earlier (not uploaded) $v.
3814 END
3815         }
3816     }
3817
3818     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3819     return $i_arch_v;
3820 }
3821
3822 sub pseudomerge_make_commit ($$$$ $$) {
3823     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3824         $msg_cmd, $msg_msg) = @_;
3825     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3826
3827     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3828     my $authline = clogp_authline $clogp;
3829
3830     chomp $msg_msg;
3831     $msg_cmd .=
3832         !defined $overwrite_version ? ""
3833         : !length  $overwrite_version ? " --overwrite"
3834         : " --overwrite=".$overwrite_version;
3835
3836     mkpath '.git/dgit';
3837     my $pmf = ".git/dgit/pseudomerge";
3838     open MC, ">", $pmf or die "$pmf $!";
3839     print MC <<END or die $!;
3840 tree $tree
3841 parent $dgitview
3842 parent $archive_hash
3843 author $authline
3844 committer $authline
3845
3846 $msg_msg
3847
3848 [$msg_cmd]
3849 END
3850     close MC or die $!;
3851
3852     return make_commit($pmf);
3853 }
3854
3855 sub splitbrain_pseudomerge ($$$$) {
3856     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3857     # => $merged_dgitview
3858     printdebug "splitbrain_pseudomerge...\n";
3859     #
3860     #     We:      debian/PREVIOUS    HEAD($maintview)
3861     # expect:          o ----------------- o
3862     #                    \                   \
3863     #                     o                   o
3864     #                 a/d/PREVIOUS        $dgitview
3865     #                $archive_hash              \
3866     #  If so,                \                   \
3867     #  we do:                 `------------------ o
3868     #   this:                                   $dgitview'
3869     #
3870
3871     return $dgitview unless defined $archive_hash;
3872     return $dgitview if deliberately_not_fast_forward();
3873
3874     printdebug "splitbrain_pseudomerge...\n";
3875
3876     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3877
3878     if (!defined $overwrite_version) {
3879         progress "Checking that HEAD inciudes all changes in archive...";
3880     }
3881
3882     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3883
3884     if (defined $overwrite_version) {
3885     } elsif (!eval {
3886         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3887         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3888         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3889         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3890         my $i_archive = [ $archive_hash, "current archive contents" ];
3891
3892         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3893
3894         infopair_cond_equal($i_dgit, $i_archive);
3895         infopair_cond_ff($i_dep14, $i_dgit);
3896         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3897         1;
3898     }) {
3899         print STDERR <<END;
3900 $us: check failed (maybe --overwrite is needed, consult documentation)
3901 END
3902         die "$@";
3903     }
3904
3905     my $r = pseudomerge_make_commit
3906         $clogp, $dgitview, $archive_hash, $i_arch_v,
3907         "dgit --quilt=$quilt_mode",
3908         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3909 Declare fast forward from $i_arch_v->[0]
3910 END_OVERWR
3911 Make fast forward from $i_arch_v->[0]
3912 END_MAKEFF
3913
3914     maybe_split_brain_save $maintview, $r, "pseudomerge";
3915
3916     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3917     return $r;
3918 }
3919
3920 sub plain_overwrite_pseudomerge ($$$) {
3921     my ($clogp, $head, $archive_hash) = @_;
3922
3923     printdebug "plain_overwrite_pseudomerge...";
3924
3925     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3926
3927     return $head if is_fast_fwd $archive_hash, $head;
3928
3929     my $m = "Declare fast forward from $i_arch_v->[0]";
3930
3931     my $r = pseudomerge_make_commit
3932         $clogp, $head, $archive_hash, $i_arch_v,
3933         "dgit", $m;
3934
3935     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3936
3937     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3938     return $r;
3939 }
3940
3941 sub push_parse_changelog ($) {
3942     my ($clogpfn) = @_;
3943
3944     my $clogp = Dpkg::Control::Hash->new();
3945     $clogp->load($clogpfn) or die;
3946
3947     my $clogpackage = getfield $clogp, 'Source';
3948     $package //= $clogpackage;
3949     fail "-p specified $package but changelog specified $clogpackage"
3950         unless $package eq $clogpackage;
3951     my $cversion = getfield $clogp, 'Version';
3952
3953     if (!$we_are_initiator) {
3954         # rpush initiator can't do this because it doesn't have $isuite yet
3955         my $tag = debiantag($cversion, access_nomdistro);
3956         runcmd @git, qw(check-ref-format), $tag;
3957     }
3958
3959     my $dscfn = dscfn($cversion);
3960
3961     return ($clogp, $cversion, $dscfn);
3962 }
3963
3964 sub push_parse_dsc ($$$) {
3965     my ($dscfn,$dscfnwhat, $cversion) = @_;
3966     $dsc = parsecontrol($dscfn,$dscfnwhat);
3967     my $dversion = getfield $dsc, 'Version';
3968     my $dscpackage = getfield $dsc, 'Source';
3969     ($dscpackage eq $package && $dversion eq $cversion) or
3970         fail "$dscfn is for $dscpackage $dversion".
3971             " but debian/changelog is for $package $cversion";
3972 }
3973
3974 sub push_tagwants ($$$$) {
3975     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3976     my @tagwants;
3977     push @tagwants, {
3978         TagFn => \&debiantag,
3979         Objid => $dgithead,
3980         TfSuffix => '',
3981         View => 'dgit',
3982     };
3983     if (defined $maintviewhead) {
3984         push @tagwants, {
3985             TagFn => \&debiantag_maintview,
3986             Objid => $maintviewhead,
3987             TfSuffix => '-maintview',
3988             View => 'maint',
3989         };
3990     } elsif ($dodep14tag eq 'no' ? 0
3991              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3992              : $dodep14tag eq 'always'
3993              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3994 --dep14tag-always (or equivalent in config) means server must support
3995  both "new" and "maint" tag formats, but config says it doesn't.
3996 END
3997             : die "$dodep14tag ?") {
3998         push @tagwants, {
3999             TagFn => \&debiantag_maintview,
4000             Objid => $dgithead,
4001             TfSuffix => '-dgit',
4002             View => 'dgit',
4003         };
4004     };
4005     foreach my $tw (@tagwants) {
4006         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4007         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4008     }
4009     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4010     return @tagwants;
4011 }
4012
4013 sub push_mktags ($$ $$ $) {
4014     my ($clogp,$dscfn,
4015         $changesfile,$changesfilewhat,
4016         $tagwants) = @_;
4017
4018     die unless $tagwants->[0]{View} eq 'dgit';
4019
4020     my $declaredistro = access_nomdistro();
4021     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4022     $dsc->{$ourdscfield[0]} = join " ",
4023         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4024         $reader_giturl;
4025     $dsc->save("$dscfn.tmp") or die $!;
4026
4027     my $changes = parsecontrol($changesfile,$changesfilewhat);
4028     foreach my $field (qw(Source Distribution Version)) {
4029         $changes->{$field} eq $clogp->{$field} or
4030             fail "changes field $field \`$changes->{$field}'".
4031                 " does not match changelog \`$clogp->{$field}'";
4032     }
4033
4034     my $cversion = getfield $clogp, 'Version';
4035     my $clogsuite = getfield $clogp, 'Distribution';
4036
4037     # We make the git tag by hand because (a) that makes it easier
4038     # to control the "tagger" (b) we can do remote signing
4039     my $authline = clogp_authline $clogp;
4040     my $delibs = join(" ", "",@deliberatelies);
4041
4042     my $mktag = sub {
4043         my ($tw) = @_;
4044         my $tfn = $tw->{Tfn};
4045         my $head = $tw->{Objid};
4046         my $tag = $tw->{Tag};
4047
4048         open TO, '>', $tfn->('.tmp') or die $!;
4049         print TO <<END or die $!;
4050 object $head
4051 type commit
4052 tag $tag
4053 tagger $authline
4054
4055 END
4056         if ($tw->{View} eq 'dgit') {
4057             print TO <<END or die $!;
4058 $package release $cversion for $clogsuite ($csuite) [dgit]
4059 [dgit distro=$declaredistro$delibs]
4060 END
4061             foreach my $ref (sort keys %previously) {
4062                 print TO <<END or die $!;
4063 [dgit previously:$ref=$previously{$ref}]
4064 END
4065             }
4066         } elsif ($tw->{View} eq 'maint') {
4067             print TO <<END or die $!;
4068 $package release $cversion for $clogsuite ($csuite)
4069 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4070 END
4071         } else {
4072             die Dumper($tw)."?";
4073         }
4074
4075         close TO or die $!;
4076
4077         my $tagobjfn = $tfn->('.tmp');
4078         if ($sign) {
4079             if (!defined $keyid) {
4080                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4081             }
4082             if (!defined $keyid) {
4083                 $keyid = getfield $clogp, 'Maintainer';
4084             }
4085             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4086             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4087             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4088             push @sign_cmd, $tfn->('.tmp');
4089             runcmd_ordryrun @sign_cmd;
4090             if (act_scary()) {
4091                 $tagobjfn = $tfn->('.signed.tmp');
4092                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4093                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4094             }
4095         }
4096         return $tagobjfn;
4097     };
4098
4099     my @r = map { $mktag->($_); } @$tagwants;
4100     return @r;
4101 }
4102
4103 sub sign_changes ($) {
4104     my ($changesfile) = @_;
4105     if ($sign) {
4106         my @debsign_cmd = @debsign;
4107         push @debsign_cmd, "-k$keyid" if defined $keyid;
4108         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4109         push @debsign_cmd, $changesfile;
4110         runcmd_ordryrun @debsign_cmd;
4111     }
4112 }
4113
4114 sub dopush () {
4115     printdebug "actually entering push\n";
4116
4117     supplementary_message(<<'END');
4118 Push failed, while checking state of the archive.
4119 You can retry the push, after fixing the problem, if you like.
4120 END
4121     if (check_for_git()) {
4122         git_fetch_us();
4123     }
4124     my $archive_hash = fetch_from_archive();
4125     if (!$archive_hash) {
4126         $new_package or
4127             fail "package appears to be new in this suite;".
4128                 " if this is intentional, use --new";
4129     }
4130
4131     supplementary_message(<<'END');
4132 Push failed, while preparing your push.
4133 You can retry the push, after fixing the problem, if you like.
4134 END
4135
4136     need_tagformat 'new', "quilt mode $quilt_mode"
4137         if quiltmode_splitbrain;
4138
4139     prep_ud();
4140
4141     access_giturl(); # check that success is vaguely likely
4142     rpush_handle_protovsn_bothends() if $we_are_initiator;
4143     select_tagformat();
4144
4145     my $clogpfn = ".git/dgit/changelog.822.tmp";
4146     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4147
4148     responder_send_file('parsed-changelog', $clogpfn);
4149
4150     my ($clogp, $cversion, $dscfn) =
4151         push_parse_changelog("$clogpfn");
4152
4153     my $dscpath = "$buildproductsdir/$dscfn";
4154     stat_exists $dscpath or
4155         fail "looked for .dsc $dscpath, but $!;".
4156             " maybe you forgot to build";
4157
4158     responder_send_file('dsc', $dscpath);
4159
4160     push_parse_dsc($dscpath, $dscfn, $cversion);
4161
4162     my $format = getfield $dsc, 'Format';
4163     printdebug "format $format\n";
4164
4165     my $actualhead = git_rev_parse('HEAD');
4166     my $dgithead = $actualhead;
4167     my $maintviewhead = undef;
4168
4169     my $upstreamversion = upstreamversion $clogp->{Version};
4170
4171     if (madformat_wantfixup($format)) {
4172         # user might have not used dgit build, so maybe do this now:
4173         if (quiltmode_splitbrain()) {
4174             changedir $ud;
4175             quilt_make_fake_dsc($upstreamversion);
4176             my $cachekey;
4177             ($dgithead, $cachekey) =
4178                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4179             $dgithead or fail
4180  "--quilt=$quilt_mode but no cached dgit view:
4181  perhaps tree changed since dgit build[-source] ?";
4182             $split_brain = 1;
4183             $dgithead = splitbrain_pseudomerge($clogp,
4184                                                $actualhead, $dgithead,
4185                                                $archive_hash);
4186             $maintviewhead = $actualhead;
4187             changedir '../../../..';
4188             prep_ud(); # so _only_subdir() works, below
4189         } else {
4190             commit_quilty_patch();
4191         }
4192     }
4193
4194     if (defined $overwrite_version && !defined $maintviewhead) {
4195         $dgithead = plain_overwrite_pseudomerge($clogp,
4196                                                 $dgithead,
4197                                                 $archive_hash);
4198     }
4199
4200     check_not_dirty();
4201
4202     my $forceflag = '';
4203     if ($archive_hash) {
4204         if (is_fast_fwd($archive_hash, $dgithead)) {
4205             # ok
4206         } elsif (deliberately_not_fast_forward) {
4207             $forceflag = '+';
4208         } else {
4209             fail "dgit push: HEAD is not a descendant".
4210                 " of the archive's version.\n".
4211                 "To overwrite the archive's contents,".
4212                 " pass --overwrite[=VERSION].\n".
4213                 "To rewind history, if permitted by the archive,".
4214                 " use --deliberately-not-fast-forward.";
4215         }
4216     }
4217
4218     changedir $ud;
4219     progress "checking that $dscfn corresponds to HEAD";
4220     runcmd qw(dpkg-source -x --),
4221         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4222     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4223     check_for_vendor_patches() if madformat($dsc->{format});
4224     changedir '../../../..';
4225     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4226     debugcmd "+",@diffcmd;
4227     $!=0; $?=-1;
4228     my $r = system @diffcmd;
4229     if ($r) {
4230         if ($r==256) {
4231             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4232             fail <<END
4233 HEAD specifies a different tree to $dscfn:
4234 $diffs
4235 Perhaps you forgot to build.  Or perhaps there is a problem with your
4236  source tree (see dgit(7) for some hints).  To see a full diff, run
4237    git diff $tree HEAD
4238 END
4239         } else {
4240             failedcmd @diffcmd;
4241         }
4242     }
4243     if (!$changesfile) {
4244         my $pat = changespat $cversion;
4245         my @cs = glob "$buildproductsdir/$pat";
4246         fail "failed to find unique changes file".
4247             " (looked for $pat in $buildproductsdir);".
4248             " perhaps you need to use dgit -C"
4249             unless @cs==1;
4250         ($changesfile) = @cs;
4251     } else {
4252         $changesfile = "$buildproductsdir/$changesfile";
4253     }
4254
4255     # Check that changes and .dsc agree enough
4256     $changesfile =~ m{[^/]*$};
4257     my $changes = parsecontrol($changesfile,$&);
4258     files_compare_inputs($dsc, $changes)
4259         unless forceing [qw(dsc-changes-mismatch)];
4260
4261     # Perhaps adjust .dsc to contain right set of origs
4262     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4263                                   $changesfile)
4264         unless forceing [qw(changes-origs-exactly)];
4265
4266     # Checks complete, we're going to try and go ahead:
4267
4268     responder_send_file('changes',$changesfile);
4269     responder_send_command("param head $dgithead");
4270     responder_send_command("param csuite $csuite");
4271     responder_send_command("param isuite $isuite");
4272     responder_send_command("param tagformat $tagformat");
4273     if (defined $maintviewhead) {
4274         die unless ($protovsn//4) >= 4;
4275         responder_send_command("param maint-view $maintviewhead");
4276     }
4277
4278     # Perhaps send buildinfo(s) for signing
4279     my $changes_files = getfield $changes, 'Files';
4280     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4281     foreach my $bi (@buildinfos) {
4282         responder_send_command("param buildinfo-filename $bi");
4283         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4284     }
4285
4286     if (deliberately_not_fast_forward) {
4287         git_for_each_ref(lrfetchrefs, sub {
4288             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4289             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4290             responder_send_command("previously $rrefname=$objid");
4291             $previously{$rrefname} = $objid;
4292         });
4293     }
4294
4295     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4296                                  ".git/dgit/tag");
4297     my @tagobjfns;
4298
4299     supplementary_message(<<'END');
4300 Push failed, while signing the tag.
4301 You can retry the push, after fixing the problem, if you like.
4302 END
4303     # If we manage to sign but fail to record it anywhere, it's fine.
4304     if ($we_are_responder) {
4305         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4306         responder_receive_files('signed-tag', @tagobjfns);
4307     } else {
4308         @tagobjfns = push_mktags($clogp,$dscpath,
4309                               $changesfile,$changesfile,
4310                               \@tagwants);
4311     }
4312     supplementary_message(<<'END');
4313 Push failed, *after* signing the tag.
4314 If you want to try again, you should use a new version number.
4315 END
4316
4317     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4318
4319     foreach my $tw (@tagwants) {
4320         my $tag = $tw->{Tag};
4321         my $tagobjfn = $tw->{TagObjFn};
4322         my $tag_obj_hash =
4323             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4324         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4325         runcmd_ordryrun_local
4326             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4327     }
4328
4329     supplementary_message(<<'END');
4330 Push failed, while updating the remote git repository - see messages above.
4331 If you want to try again, you should use a new version number.
4332 END
4333     if (!check_for_git()) {
4334         create_remote_git_repo();
4335     }
4336
4337     my @pushrefs = $forceflag.$dgithead.":".rrref();
4338     foreach my $tw (@tagwants) {
4339         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4340     }
4341
4342     runcmd_ordryrun @git,
4343         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4344     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4345
4346     supplementary_message(<<'END');
4347 Push failed, while obtaining signatures on the .changes and .dsc.
4348 If it was just that the signature failed, you may try again by using
4349 debsign by hand to sign the changes
4350    $changesfile
4351 and then dput to complete the upload.
4352 If you need to change the package, you must use a new version number.
4353 END
4354     if ($we_are_responder) {
4355         my $dryrunsuffix = act_local() ? "" : ".tmp";
4356         my @rfiles = ($dscpath, $changesfile);
4357         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4358         responder_receive_files('signed-dsc-changes',
4359                                 map { "$_$dryrunsuffix" } @rfiles);
4360     } else {
4361         if (act_local()) {
4362             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4363         } else {
4364             progress "[new .dsc left in $dscpath.tmp]";
4365         }
4366         sign_changes $changesfile;
4367     }
4368
4369     supplementary_message(<<END);
4370 Push failed, while uploading package(s) to the archive server.
4371 You can retry the upload of exactly these same files with dput of:
4372   $changesfile
4373 If that .changes file is broken, you will need to use a new version
4374 number for your next attempt at the upload.
4375 END
4376     my $host = access_cfg('upload-host','RETURN-UNDEF');
4377     my @hostarg = defined($host) ? ($host,) : ();
4378     runcmd_ordryrun @dput, @hostarg, $changesfile;
4379     printdone "pushed and uploaded $cversion";
4380
4381     supplementary_message('');
4382     responder_send_command("complete");
4383 }
4384
4385 sub pre_clone () {
4386     no_local_git_cfg();
4387 }
4388 sub cmd_clone {
4389     parseopts();
4390     my $dstdir;
4391     badusage "-p is not allowed with clone; specify as argument instead"
4392         if defined $package;
4393     if (@ARGV==1) {
4394         ($package) = @ARGV;
4395     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4396         ($package,$isuite) = @ARGV;
4397     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4398         ($package,$dstdir) = @ARGV;
4399     } elsif (@ARGV==3) {
4400         ($package,$isuite,$dstdir) = @ARGV;
4401     } else {
4402         badusage "incorrect arguments to dgit clone";
4403     }
4404     notpushing();
4405
4406     $dstdir ||= "$package";
4407     if (stat_exists $dstdir) {
4408         fail "$dstdir already exists";
4409     }
4410
4411     my $cwd_remove;
4412     if ($rmonerror && !$dryrun_level) {
4413         $cwd_remove= getcwd();
4414         unshift @end, sub {
4415             return unless defined $cwd_remove;
4416             if (!chdir "$cwd_remove") {
4417                 return if $!==&ENOENT;
4418                 die "chdir $cwd_remove: $!";
4419             }
4420             printdebug "clone rmonerror removing $dstdir\n";
4421             if (stat $dstdir) {
4422                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4423             } elsif (grep { $! == $_ }
4424                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4425             } else {
4426                 print STDERR "check whether to remove $dstdir: $!\n";
4427             }
4428         };
4429     }
4430
4431     clone($dstdir);
4432     $cwd_remove = undef;
4433 }
4434
4435 sub branchsuite () {
4436     my @cmd = (@git, qw(symbolic-ref -q HEAD));
4437     my $branch = cmdoutput_errok @cmd;
4438     if (!defined $branch) {
4439         $?==256 or failedcmd @cmd;
4440         return undef;
4441     }
4442     if ($branch =~ m#$lbranch_re#o) {
4443         return $1;
4444     } else {
4445         return undef;
4446     }
4447 }
4448
4449 sub fetchpullargs () {
4450     if (!defined $package) {
4451         my $sourcep = parsecontrol('debian/control','debian/control');
4452         $package = getfield $sourcep, 'Source';
4453     }
4454     if (@ARGV==0) {
4455         $isuite = branchsuite();
4456         if (!$isuite) {
4457             my $clogp = parsechangelog();
4458             my $clogsuite = getfield $clogp, 'Distribution';
4459             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4460         }
4461     } elsif (@ARGV==1) {
4462         ($isuite) = @ARGV;
4463     } else {
4464         badusage "incorrect arguments to dgit fetch or dgit pull";
4465     }
4466     notpushing();
4467 }
4468
4469 sub cmd_fetch {
4470     parseopts();
4471     fetchpullargs();
4472     my $multi_fetched = fork_for_multisuite(sub { });
4473     exit 0 if $multi_fetched;
4474     fetch();
4475 }
4476
4477 sub cmd_pull {
4478     parseopts();
4479     fetchpullargs();
4480     if (quiltmode_splitbrain()) {
4481         my ($format, $fopts) = get_source_format();
4482         madformat($format) and fail <<END
4483 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4484 END
4485     }
4486     pull();
4487 }
4488
4489 sub prep_push () {
4490     parseopts();
4491     build_or_push_prep_early();
4492     pushing();
4493     check_not_dirty();
4494     my $specsuite;
4495     if (@ARGV==0) {
4496     } elsif (@ARGV==1) {
4497         ($specsuite) = (@ARGV);
4498     } else {
4499         badusage "incorrect arguments to dgit $subcommand";
4500     }
4501     if ($new_package) {
4502         local ($package) = $existing_package; # this is a hack
4503         canonicalise_suite();
4504     } else {
4505         canonicalise_suite();
4506     }
4507     if (defined $specsuite &&
4508         $specsuite ne $isuite &&
4509         $specsuite ne $csuite) {
4510             fail "dgit $subcommand: changelog specifies $isuite ($csuite)".
4511                 " but command line specifies $specsuite";
4512     }
4513 }
4514
4515 sub cmd_push {
4516     prep_push();
4517     dopush();
4518 }
4519
4520 #---------- remote commands' implementation ----------
4521
4522 sub pre_remote_push_build_host {
4523     my ($nrargs) = shift @ARGV;
4524     my (@rargs) = @ARGV[0..$nrargs-1];
4525     @ARGV = @ARGV[$nrargs..$#ARGV];
4526     die unless @rargs;
4527     my ($dir,$vsnwant) = @rargs;
4528     # vsnwant is a comma-separated list; we report which we have
4529     # chosen in our ready response (so other end can tell if they
4530     # offered several)
4531     $debugprefix = ' ';
4532     $we_are_responder = 1;
4533     $us .= " (build host)";
4534
4535     open PI, "<&STDIN" or die $!;
4536     open STDIN, "/dev/null" or die $!;
4537     open PO, ">&STDOUT" or die $!;
4538     autoflush PO 1;
4539     open STDOUT, ">&STDERR" or die $!;
4540     autoflush STDOUT 1;
4541
4542     $vsnwant //= 1;
4543     ($protovsn) = grep {
4544         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4545     } @rpushprotovsn_support;
4546
4547     fail "build host has dgit rpush protocol versions ".
4548         (join ",", @rpushprotovsn_support).
4549         " but invocation host has $vsnwant"
4550         unless defined $protovsn;
4551
4552     changedir $dir;
4553 }
4554 sub cmd_remote_push_build_host {
4555     responder_send_command("dgit-remote-push-ready $protovsn");
4556     &cmd_push;
4557 }
4558
4559 sub pre_remote_push_responder { pre_remote_push_build_host(); }
4560 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4561 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4562 #     a good error message)
4563
4564 sub rpush_handle_protovsn_bothends () {
4565     if ($protovsn < 4) {
4566         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4567     }
4568     select_tagformat();
4569 }
4570
4571 our $i_tmp;
4572
4573 sub i_cleanup {
4574     local ($@, $?);
4575     my $report = i_child_report();
4576     if (defined $report) {
4577         printdebug "($report)\n";
4578     } elsif ($i_child_pid) {
4579         printdebug "(killing build host child $i_child_pid)\n";
4580         kill 15, $i_child_pid;
4581     }
4582     if (defined $i_tmp && !defined $initiator_tempdir) {
4583         changedir "/";
4584         eval { rmtree $i_tmp; };
4585     }
4586 }
4587
4588 END {
4589     return unless forkcheck_mainprocess();
4590     i_cleanup();
4591 }
4592
4593 sub i_method {
4594     my ($base,$selector,@args) = @_;
4595     $selector =~ s/\-/_/g;
4596     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4597 }
4598
4599 sub pre_rpush () {
4600     no_local_git_cfg();
4601 }
4602 sub cmd_rpush {
4603     my $host = nextarg;
4604     my $dir;
4605     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4606         $host = $1;
4607         $dir = $'; #';
4608     } else {
4609         $dir = nextarg;
4610     }
4611     $dir =~ s{^-}{./-};
4612     my @rargs = ($dir);
4613     push @rargs, join ",", @rpushprotovsn_support;
4614     my @rdgit;
4615     push @rdgit, @dgit;
4616     push @rdgit, @ropts;
4617     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4618     push @rdgit, @ARGV;
4619     my @cmd = (@ssh, $host, shellquote @rdgit);
4620     debugcmd "+",@cmd;
4621
4622     $we_are_initiator=1;
4623
4624     if (defined $initiator_tempdir) {
4625         rmtree $initiator_tempdir;
4626         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4627         $i_tmp = $initiator_tempdir;
4628     } else {
4629         $i_tmp = tempdir();
4630     }
4631     $i_child_pid = open2(\*RO, \*RI, @cmd);
4632     changedir $i_tmp;
4633     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4634     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4635     $supplementary_message = '' unless $protovsn >= 3;
4636
4637     for (;;) {
4638         my ($icmd,$iargs) = initiator_expect {
4639             m/^(\S+)(?: (.*))?$/;
4640             ($1,$2);
4641         };
4642         i_method "i_resp", $icmd, $iargs;
4643     }
4644 }
4645
4646 sub i_resp_progress ($) {
4647     my ($rhs) = @_;
4648     my $msg = protocol_read_bytes \*RO, $rhs;
4649     progress $msg;
4650 }
4651
4652 sub i_resp_supplementary_message ($) {
4653     my ($rhs) = @_;
4654     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4655 }
4656
4657 sub i_resp_complete {
4658     my $pid = $i_child_pid;
4659     $i_child_pid = undef; # prevents killing some other process with same pid
4660     printdebug "waiting for build host child $pid...\n";
4661     my $got = waitpid $pid, 0;
4662     die $! unless $got == $pid;
4663     die "build host child failed $?" if $?;
4664
4665     i_cleanup();
4666     printdebug "all done\n";
4667     exit 0;
4668 }
4669
4670 sub i_resp_file ($) {
4671     my ($keyword) = @_;
4672     my $localname = i_method "i_localname", $keyword;
4673     my $localpath = "$i_tmp/$localname";
4674     stat_exists $localpath and
4675         badproto \*RO, "file $keyword ($localpath) twice";
4676     protocol_receive_file \*RO, $localpath;
4677     i_method "i_file", $keyword;
4678 }
4679
4680 our %i_param;
4681
4682 sub i_resp_param ($) {
4683     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4684     $i_param{$1} = $2;
4685 }
4686
4687 sub i_resp_previously ($) {
4688     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4689         or badproto \*RO, "bad previously spec";
4690     my $r = system qw(git check-ref-format), $1;
4691     die "bad previously ref spec ($r)" if $r;
4692     $previously{$1} = $2;
4693 }
4694
4695 our %i_wanted;
4696
4697 sub i_resp_want ($) {
4698     my ($keyword) = @_;
4699     die "$keyword ?" if $i_wanted{$keyword}++;
4700
4701     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4702     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4703     die unless $isuite =~ m/^$suite_re$/;
4704
4705     pushing();
4706     rpush_handle_protovsn_bothends();
4707
4708     fail "rpush negotiated protocol version $protovsn".
4709         " which does not support quilt mode $quilt_mode"
4710         if quiltmode_splitbrain;
4711
4712     my @localpaths = i_method "i_want", $keyword;
4713     printdebug "[[  $keyword @localpaths\n";
4714     foreach my $localpath (@localpaths) {
4715         protocol_send_file \*RI, $localpath;
4716     }
4717     print RI "files-end\n" or die $!;
4718 }
4719
4720 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
4721
4722 sub i_localname_parsed_changelog {
4723     return "remote-changelog.822";
4724 }
4725 sub i_file_parsed_changelog {
4726     ($i_clogp, $i_version, $i_dscfn) =
4727         push_parse_changelog "$i_tmp/remote-changelog.822";
4728     die if $i_dscfn =~ m#/|^\W#;
4729 }
4730
4731 sub i_localname_dsc {
4732     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4733     return $i_dscfn;
4734 }
4735 sub i_file_dsc { }
4736
4737 sub i_localname_buildinfo ($) {
4738     my $bi = $i_param{'buildinfo-filename'};
4739     defined $bi or badproto \*RO, "buildinfo before filename";
4740     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
4741     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
4742         or badproto \*RO, "improper buildinfo filename";
4743     return $&;
4744 }
4745 sub i_file_buildinfo {
4746     my $bi = $i_param{'buildinfo-filename'};
4747     my $bd = parsecontrol "$i_tmp/$bi", $bi;
4748     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
4749     if (!forceing [qw(buildinfo-changes-mismatch)]) {
4750         files_compare_inputs($bd, $ch);
4751         (getfield $bd, $_) eq (getfield $ch, $_) or
4752             fail "buildinfo mismatch $_"
4753             foreach qw(Source Version);
4754         !defined $bd->{$_} or
4755             fail "buildinfo contains $_"
4756             foreach qw(Changes Changed-by Distribution);
4757     }
4758     push @i_buildinfos, $bi;
4759     delete $i_param{'buildinfo-filename'};
4760 }
4761
4762 sub i_localname_changes {
4763     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4764     $i_changesfn = $i_dscfn;
4765     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4766     return $i_changesfn;
4767 }
4768 sub i_file_changes { }
4769
4770 sub i_want_signed_tag {
4771     printdebug Dumper(\%i_param, $i_dscfn);
4772     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4773         && defined $i_param{'csuite'}
4774         or badproto \*RO, "premature desire for signed-tag";
4775     my $head = $i_param{'head'};
4776     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4777
4778     my $maintview = $i_param{'maint-view'};
4779     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4780
4781     select_tagformat();
4782     if ($protovsn >= 4) {
4783         my $p = $i_param{'tagformat'} // '<undef>';
4784         $p eq $tagformat
4785             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4786     }
4787
4788     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4789     $csuite = $&;
4790     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4791
4792     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4793
4794     return
4795         push_mktags $i_clogp, $i_dscfn,
4796             $i_changesfn, 'remote changes',
4797             \@tagwants;
4798 }
4799
4800 sub i_want_signed_dsc_changes {
4801     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4802     sign_changes $i_changesfn;
4803     return ($i_dscfn, $i_changesfn, @i_buildinfos);
4804 }
4805
4806 #---------- building etc. ----------
4807
4808 our $version;
4809 our $sourcechanges;
4810 our $dscfn;
4811
4812 #----- `3.0 (quilt)' handling -----
4813
4814 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4815
4816 sub quiltify_dpkg_commit ($$$;$) {
4817     my ($patchname,$author,$msg, $xinfo) = @_;
4818     $xinfo //= '';
4819
4820     mkpath '.git/dgit';
4821     my $descfn = ".git/dgit/quilt-description.tmp";
4822     open O, '>', $descfn or die "$descfn: $!";
4823     $msg =~ s/\n+/\n\n/;
4824     print O <<END or die $!;
4825 From: $author
4826 ${xinfo}Subject: $msg
4827 ---
4828
4829 END
4830     close O or die $!;
4831
4832     {
4833         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4834         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4835         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4836         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4837     }
4838 }
4839
4840 sub quiltify_trees_differ ($$;$$$) {
4841     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4842     # returns true iff the two tree objects differ other than in debian/
4843     # with $finegrained,
4844     # returns bitmask 01 - differ in upstream files except .gitignore
4845     #                 02 - differ in .gitignore
4846     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4847     #  is set for each modified .gitignore filename $fn
4848     # if $unrepres is defined, array ref to which is appeneded
4849     #  a list of unrepresentable changes (removals of upstream files
4850     #  (as messages)
4851     local $/=undef;
4852     my @cmd = (@git, qw(diff-tree -z --no-renames));
4853     push @cmd, qw(--name-only) unless $unrepres;
4854     push @cmd, qw(-r) if $finegrained || $unrepres;
4855     push @cmd, $x, $y;
4856     my $diffs= cmdoutput @cmd;
4857     my $r = 0;
4858     my @lmodes;
4859     foreach my $f (split /\0/, $diffs) {
4860         if ($unrepres && !@lmodes) {
4861             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4862             next;
4863         }
4864         my ($oldmode,$newmode) = @lmodes;
4865         @lmodes = ();
4866
4867         next if $f =~ m#^debian(?:/.*)?$#s;
4868
4869         if ($unrepres) {
4870             eval {
4871                 die "not a plain file or symlink\n"
4872                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
4873                            $oldmode =~ m/^(?:10|12)\d{4}$/;
4874                 if ($oldmode =~ m/[^0]/ &&
4875                     $newmode =~ m/[^0]/) {
4876                     # both old and new files exist
4877                     die "mode or type changed\n" if $oldmode ne $newmode;
4878                     die "modified symlink\n" unless $newmode =~ m/^10/;
4879                 } elsif ($oldmode =~ m/[^0]/) {
4880                     # deletion
4881                     die "deletion of symlink\n"
4882                         unless $oldmode =~ m/^10/;
4883                 } else {
4884                     # creation
4885                     die "creation with non-default mode\n"
4886                         unless $newmode =~ m/^100644$/ or
4887                                $newmode =~ m/^120000$/;
4888                 }
4889             };
4890             if ($@) {
4891                 local $/="\n"; chomp $@;
4892                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4893             }
4894         }
4895
4896         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4897         $r |= $isignore ? 02 : 01;
4898         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4899     }
4900     printdebug "quiltify_trees_differ $x $y => $r\n";
4901     return $r;
4902 }
4903
4904 sub quiltify_tree_sentinelfiles ($) {
4905     # lists the `sentinel' files present in the tree
4906     my ($x) = @_;
4907     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4908         qw(-- debian/rules debian/control);
4909     $r =~ s/\n/,/g;
4910     return $r;
4911 }
4912
4913 sub quiltify_splitbrain_needed () {
4914     if (!$split_brain) {
4915         progress "dgit view: changes are required...";
4916         runcmd @git, qw(checkout -q -b dgit-view);
4917         $split_brain = 1;
4918     }
4919 }
4920
4921 sub quiltify_splitbrain ($$$$$$) {
4922     my ($clogp, $unapplied, $headref, $diffbits,
4923         $editedignores, $cachekey) = @_;
4924     if ($quilt_mode !~ m/gbp|dpm/) {
4925         # treat .gitignore just like any other upstream file
4926         $diffbits = { %$diffbits };
4927         $_ = !!$_ foreach values %$diffbits;
4928     }
4929     # We would like any commits we generate to be reproducible
4930     my @authline = clogp_authline($clogp);
4931     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4932     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4933     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4934     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4935     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4936     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4937
4938     if ($quilt_mode =~ m/gbp|unapplied/ &&
4939         ($diffbits->{O2H} & 01)) {
4940         my $msg =
4941  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4942  " but git tree differs from orig in upstream files.";
4943         if (!stat_exists "debian/patches") {
4944             $msg .=
4945  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4946         }
4947         fail $msg;
4948     }
4949     if ($quilt_mode =~ m/dpm/ &&
4950         ($diffbits->{H2A} & 01)) {
4951         fail <<END;
4952 --quilt=$quilt_mode specified, implying patches-applied git tree
4953  but git tree differs from result of applying debian/patches to upstream
4954 END
4955     }
4956     if ($quilt_mode =~ m/gbp|unapplied/ &&
4957         ($diffbits->{O2A} & 01)) { # some patches
4958         quiltify_splitbrain_needed();
4959         progress "dgit view: creating patches-applied version using gbp pq";
4960         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4961         # gbp pq import creates a fresh branch; push back to dgit-view
4962         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4963         runcmd @git, qw(checkout -q dgit-view);
4964     }
4965     if ($quilt_mode =~ m/gbp|dpm/ &&
4966         ($diffbits->{O2A} & 02)) {
4967         fail <<END
4968 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4969  tool which does not create patches for changes to upstream
4970  .gitignores: but, such patches exist in debian/patches.
4971 END
4972     }
4973     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4974         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4975         quiltify_splitbrain_needed();
4976         progress "dgit view: creating patch to represent .gitignore changes";
4977         ensuredir "debian/patches";
4978         my $gipatch = "debian/patches/auto-gitignore";
4979         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4980         stat GIPATCH or die "$gipatch: $!";
4981         fail "$gipatch already exists; but want to create it".
4982             " to record .gitignore changes" if (stat _)[7];
4983         print GIPATCH <<END or die "$gipatch: $!";
4984 Subject: Update .gitignore from Debian packaging branch
4985
4986 The Debian packaging git branch contains these updates to the upstream
4987 .gitignore file(s).  This patch is autogenerated, to provide these
4988 updates to users of the official Debian archive view of the package.
4989
4990 [dgit ($our_version) update-gitignore]
4991 ---
4992 END
4993         close GIPATCH or die "$gipatch: $!";
4994         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4995             $unapplied, $headref, "--", sort keys %$editedignores;
4996         open SERIES, "+>>", "debian/patches/series" or die $!;
4997         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4998         my $newline;
4999         defined read SERIES, $newline, 1 or die $!;
5000         print SERIES "\n" or die $! unless $newline eq "\n";
5001         print SERIES "auto-gitignore\n" or die $!;
5002         close SERIES or die  $!;
5003         runcmd @git, qw(add -- debian/patches/series), $gipatch;
5004         commit_admin <<END
5005 Commit patch to update .gitignore
5006
5007 [dgit ($our_version) update-gitignore-quilt-fixup]
5008 END
5009     }
5010
5011     my $dgitview = git_rev_parse 'HEAD';
5012
5013     changedir '../../../..';
5014     # When we no longer need to support squeeze, use --create-reflog
5015     # instead of this:
5016     ensuredir ".git/logs/refs/dgit-intern";
5017     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
5018       or die $!;
5019
5020     my $oldcache = git_get_ref "refs/$splitbraincache";
5021     if ($oldcache eq $dgitview) {
5022         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
5023         # git update-ref doesn't always update, in this case.  *sigh*
5024         my $dummy = make_commit_text <<END;
5025 tree $tree
5026 parent $dgitview
5027 author Dgit <dgit\@example.com> 1000000000 +0000
5028 committer Dgit <dgit\@example.com> 1000000000 +0000
5029
5030 Dummy commit - do not use
5031 END
5032         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
5033             "refs/$splitbraincache", $dummy;
5034     }
5035     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
5036         $dgitview;
5037
5038     changedir '.git/dgit/unpack/work';
5039
5040     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
5041     progress "dgit view: created ($saved)";
5042 }
5043
5044 sub quiltify ($$$$) {
5045     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5046
5047     # Quilt patchification algorithm
5048     #
5049     # We search backwards through the history of the main tree's HEAD
5050     # (T) looking for a start commit S whose tree object is identical
5051     # to to the patch tip tree (ie the tree corresponding to the
5052     # current dpkg-committed patch series).  For these purposes
5053     # `identical' disregards anything in debian/ - this wrinkle is
5054     # necessary because dpkg-source treates debian/ specially.
5055     #
5056     # We can only traverse edges where at most one of the ancestors'
5057     # trees differs (in changes outside in debian/).  And we cannot
5058     # handle edges which change .pc/ or debian/patches.  To avoid
5059     # going down a rathole we avoid traversing edges which introduce
5060     # debian/rules or debian/control.  And we set a limit on the
5061     # number of edges we are willing to look at.
5062     #
5063     # If we succeed, we walk forwards again.  For each traversed edge
5064     # PC (with P parent, C child) (starting with P=S and ending with
5065     # C=T) to we do this:
5066     #  - git checkout C
5067     #  - dpkg-source --commit with a patch name and message derived from C
5068     # After traversing PT, we git commit the changes which
5069     # should be contained within debian/patches.
5070
5071     # The search for the path S..T is breadth-first.  We maintain a
5072     # todo list containing search nodes.  A search node identifies a
5073     # commit, and looks something like this:
5074     #  $p = {
5075     #      Commit => $git_commit_id,
5076     #      Child => $c,                          # or undef if P=T
5077     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5078     #      Nontrivial => true iff $p..$c has relevant changes
5079     #  };
5080
5081     my @todo;
5082     my @nots;
5083     my $sref_S;
5084     my $max_work=100;
5085     my %considered; # saves being exponential on some weird graphs
5086
5087     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5088
5089     my $not = sub {
5090         my ($search,$whynot) = @_;
5091         printdebug " search NOT $search->{Commit} $whynot\n";
5092         $search->{Whynot} = $whynot;
5093         push @nots, $search;
5094         no warnings qw(exiting);
5095         next;
5096     };
5097
5098     push @todo, {
5099         Commit => $target,
5100     };
5101
5102     while (@todo) {
5103         my $c = shift @todo;
5104         next if $considered{$c->{Commit}}++;
5105
5106         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5107
5108         printdebug "quiltify investigate $c->{Commit}\n";
5109
5110         # are we done?
5111         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5112             printdebug " search finished hooray!\n";
5113             $sref_S = $c;
5114             last;
5115         }
5116
5117         if ($quilt_mode eq 'nofix') {
5118             fail "quilt fixup required but quilt mode is \`nofix'\n".
5119                 "HEAD commit $c->{Commit} differs from tree implied by ".
5120                 " debian/patches (tree object $oldtiptree)";
5121         }
5122         if ($quilt_mode eq 'smash') {
5123             printdebug " search quitting smash\n";
5124             last;
5125         }
5126
5127         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5128         $not->($c, "has $c_sentinels not $t_sentinels")
5129             if $c_sentinels ne $t_sentinels;
5130
5131         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5132         $commitdata =~ m/\n\n/;
5133         $commitdata =~ $`;
5134         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5135         @parents = map { { Commit => $_, Child => $c } } @parents;
5136
5137         $not->($c, "root commit") if !@parents;
5138
5139         foreach my $p (@parents) {
5140             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5141         }
5142         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5143         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5144
5145         foreach my $p (@parents) {
5146             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5147
5148             my @cmd= (@git, qw(diff-tree -r --name-only),
5149                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5150             my $patchstackchange = cmdoutput @cmd;
5151             if (length $patchstackchange) {
5152                 $patchstackchange =~ s/\n/,/g;
5153                 $not->($p, "changed $patchstackchange");
5154             }
5155
5156             printdebug " search queue P=$p->{Commit} ",
5157                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5158             push @todo, $p;
5159         }
5160     }
5161
5162     if (!$sref_S) {
5163         printdebug "quiltify want to smash\n";
5164
5165         my $abbrev = sub {
5166             my $x = $_[0]{Commit};
5167             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5168             return $x;
5169         };
5170         my $reportnot = sub {
5171             my ($notp) = @_;
5172             my $s = $abbrev->($notp);
5173             my $c = $notp->{Child};
5174             $s .= "..".$abbrev->($c) if $c;
5175             $s .= ": ".$notp->{Whynot};
5176             return $s;
5177         };
5178         if ($quilt_mode eq 'linear') {
5179             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5180             foreach my $notp (@nots) {
5181                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5182             }
5183             print STDERR "$us: $_\n" foreach @$failsuggestion;
5184             fail "quilt fixup naive history linearisation failed.\n".
5185  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5186         } elsif ($quilt_mode eq 'smash') {
5187         } elsif ($quilt_mode eq 'auto') {
5188             progress "quilt fixup cannot be linear, smashing...";
5189         } else {
5190             die "$quilt_mode ?";
5191         }
5192
5193         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5194         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5195         my $ncommits = 3;
5196         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5197
5198         quiltify_dpkg_commit "auto-$version-$target-$time",
5199             (getfield $clogp, 'Maintainer'),
5200             "Automatically generated patch ($clogp->{Version})\n".
5201             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5202         return;
5203     }
5204
5205     progress "quiltify linearisation planning successful, executing...";
5206
5207     for (my $p = $sref_S;
5208          my $c = $p->{Child};
5209          $p = $p->{Child}) {
5210         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5211         next unless $p->{Nontrivial};
5212
5213         my $cc = $c->{Commit};
5214
5215         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5216         $commitdata =~ m/\n\n/ or die "$c ?";
5217         $commitdata = $`;
5218         my $msg = $'; #';
5219         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5220         my $author = $1;
5221
5222         my $commitdate = cmdoutput
5223             @git, qw(log -n1 --pretty=format:%aD), $cc;
5224
5225         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5226
5227         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5228         $strip_nls->();
5229
5230         my $title = $1;
5231         my $patchname;
5232         my $patchdir;
5233
5234         my $gbp_check_suitable = sub {
5235             $_ = shift;
5236             my ($what) = @_;
5237
5238             eval {
5239                 die "contains unexpected slashes\n" if m{//} || m{/$};
5240                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5241                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5242                 die "is series file\n" if m{$series_filename_re}o;
5243                 die "too long" if length > 200;
5244             };
5245             return $_ unless $@;
5246             print STDERR "quiltifying commit $cc:".
5247                 " ignoring/dropping Gbp-Pq $what: $@";
5248             return undef;
5249         };
5250
5251         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5252                            gbp-pq-name: \s* )
5253                        (\S+) \s* \n //ixm) {
5254             $patchname = $gbp_check_suitable->($1, 'Name');
5255         }
5256         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5257                            gbp-pq-topic: \s* )
5258                        (\S+) \s* \n //ixm) {
5259             $patchdir = $gbp_check_suitable->($1, 'Topic');
5260         }
5261
5262         $strip_nls->();
5263
5264         if (!defined $patchname) {
5265             $patchname = $title;
5266             $patchname =~ s/[.:]$//;
5267             use Text::Iconv;
5268             eval {
5269                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5270                 my $translitname = $converter->convert($patchname);
5271                 die unless defined $translitname;
5272                 $patchname = $translitname;
5273             };
5274             print STDERR
5275                 "dgit: patch title transliteration error: $@"
5276                 if $@;
5277             $patchname =~ y/ A-Z/-a-z/;
5278             $patchname =~ y/-a-z0-9_.+=~//cd;
5279             $patchname =~ s/^\W/x-$&/;
5280             $patchname = substr($patchname,0,40);
5281             $patchname .= ".patch";
5282         }
5283         if (!defined $patchdir) {
5284             $patchdir = '';
5285         }
5286         if (length $patchdir) {
5287             $patchname = "$patchdir/$patchname";
5288         }
5289         if ($patchname =~ m{^(.*)/}) {
5290             mkpath "debian/patches/$1";
5291         }
5292
5293         my $index;
5294         for ($index='';
5295              stat "debian/patches/$patchname$index";
5296              $index++) { }
5297         $!==ENOENT or die "$patchname$index $!";
5298
5299         runcmd @git, qw(checkout -q), $cc;
5300
5301         # We use the tip's changelog so that dpkg-source doesn't
5302         # produce complaining messages from dpkg-parsechangelog.  None
5303         # of the information dpkg-source gets from the changelog is
5304         # actually relevant - it gets put into the original message
5305         # which dpkg-source provides our stunt editor, and then
5306         # overwritten.
5307         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5308
5309         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5310             "Date: $commitdate\n".
5311             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5312
5313         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5314     }
5315
5316     runcmd @git, qw(checkout -q master);
5317 }
5318
5319 sub build_maybe_quilt_fixup () {
5320     my ($format,$fopts) = get_source_format;
5321     return unless madformat_wantfixup $format;
5322     # sigh
5323
5324     check_for_vendor_patches();
5325
5326     if (quiltmode_splitbrain) {
5327         fail <<END unless access_cfg_tagformats_can_splitbrain;
5328 quilt mode $quilt_mode requires split view so server needs to support
5329  both "new" and "maint" tag formats, but config says it doesn't.
5330 END
5331     }
5332
5333     my $clogp = parsechangelog();
5334     my $headref = git_rev_parse('HEAD');
5335
5336     prep_ud();
5337     changedir $ud;
5338
5339     my $upstreamversion = upstreamversion $version;
5340
5341     if ($fopts->{'single-debian-patch'}) {
5342         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5343     } else {
5344         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5345     }
5346
5347     die 'bug' if $split_brain && !$need_split_build_invocation;
5348
5349     changedir '../../../..';
5350     runcmd_ordryrun_local
5351         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5352 }
5353
5354 sub quilt_fixup_mkwork ($) {
5355     my ($headref) = @_;
5356
5357     mkdir "work" or die $!;
5358     changedir "work";
5359     mktree_in_ud_here();
5360     runcmd @git, qw(reset -q --hard), $headref;
5361 }
5362
5363 sub quilt_fixup_linkorigs ($$) {
5364     my ($upstreamversion, $fn) = @_;
5365     # calls $fn->($leafname);
5366
5367     foreach my $f (<../../../../*>) { #/){
5368         my $b=$f; $b =~ s{.*/}{};
5369         {
5370             local ($debuglevel) = $debuglevel-1;
5371             printdebug "QF linkorigs $b, $f ?\n";
5372         }
5373         next unless is_orig_file_of_vsn $b, $upstreamversion;
5374         printdebug "QF linkorigs $b, $f Y\n";
5375         link_ltarget $f, $b or die "$b $!";
5376         $fn->($b);
5377     }
5378 }
5379
5380 sub quilt_fixup_delete_pc () {
5381     runcmd @git, qw(rm -rqf .pc);
5382     commit_admin <<END
5383 Commit removal of .pc (quilt series tracking data)
5384
5385 [dgit ($our_version) upgrade quilt-remove-pc]
5386 END
5387 }
5388
5389 sub quilt_fixup_singlepatch ($$$) {
5390     my ($clogp, $headref, $upstreamversion) = @_;
5391
5392     progress "starting quiltify (single-debian-patch)";
5393
5394     # dpkg-source --commit generates new patches even if
5395     # single-debian-patch is in debian/source/options.  In order to
5396     # get it to generate debian/patches/debian-changes, it is
5397     # necessary to build the source package.
5398
5399     quilt_fixup_linkorigs($upstreamversion, sub { });
5400     quilt_fixup_mkwork($headref);
5401
5402     rmtree("debian/patches");
5403
5404     runcmd @dpkgsource, qw(-b .);
5405     changedir "..";
5406     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5407     rename srcfn("$upstreamversion", "/debian/patches"),
5408            "work/debian/patches";
5409
5410     changedir "work";
5411     commit_quilty_patch();
5412 }
5413
5414 sub quilt_make_fake_dsc ($) {
5415     my ($upstreamversion) = @_;
5416
5417     my $fakeversion="$upstreamversion-~~DGITFAKE";
5418
5419     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5420     print $fakedsc <<END or die $!;
5421 Format: 3.0 (quilt)
5422 Source: $package
5423 Version: $fakeversion
5424 Files:
5425 END
5426
5427     my $dscaddfile=sub {
5428         my ($b) = @_;
5429
5430         my $md = new Digest::MD5;
5431
5432         my $fh = new IO::File $b, '<' or die "$b $!";
5433         stat $fh or die $!;
5434         my $size = -s _;
5435
5436         $md->addfile($fh);
5437         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5438     };
5439
5440     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5441
5442     my @files=qw(debian/source/format debian/rules
5443                  debian/control debian/changelog);
5444     foreach my $maybe (qw(debian/patches debian/source/options
5445                           debian/tests/control)) {
5446         next unless stat_exists "../../../$maybe";
5447         push @files, $maybe;
5448     }
5449
5450     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5451     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5452
5453     $dscaddfile->($debtar);
5454     close $fakedsc or die $!;
5455 }
5456
5457 sub quilt_check_splitbrain_cache ($$) {
5458     my ($headref, $upstreamversion) = @_;
5459     # Called only if we are in (potentially) split brain mode.
5460     # Called in $ud.
5461     # Computes the cache key and looks in the cache.
5462     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5463
5464     my $splitbrain_cachekey;
5465
5466     progress
5467  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5468     # we look in the reflog of dgit-intern/quilt-cache
5469     # we look for an entry whose message is the key for the cache lookup
5470     my @cachekey = (qw(dgit), $our_version);
5471     push @cachekey, $upstreamversion;
5472     push @cachekey, $quilt_mode;
5473     push @cachekey, $headref;
5474
5475     push @cachekey, hashfile('fake.dsc');
5476
5477     my $srcshash = Digest::SHA->new(256);
5478     my %sfs = ( %INC, '$0(dgit)' => $0 );
5479     foreach my $sfk (sort keys %sfs) {
5480         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5481         $srcshash->add($sfk,"  ");
5482         $srcshash->add(hashfile($sfs{$sfk}));
5483         $srcshash->add("\n");
5484     }
5485     push @cachekey, $srcshash->hexdigest();
5486     $splitbrain_cachekey = "@cachekey";
5487
5488     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5489                $splitbraincache);
5490     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5491     debugcmd "|(probably)",@cmd;
5492     my $child = open GC, "-|";  defined $child or die $!;
5493     if (!$child) {
5494         chdir '../../..' or die $!;
5495         if (!stat ".git/logs/refs/$splitbraincache") {
5496             $! == ENOENT or die $!;
5497             printdebug ">(no reflog)\n";
5498             exit 0;
5499         }
5500         exec @cmd; die $!;
5501     }
5502     while (<GC>) {
5503         chomp;
5504         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5505         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5506
5507         my $cachehit = $1;
5508         quilt_fixup_mkwork($headref);
5509         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5510         if ($cachehit ne $headref) {
5511             progress "dgit view: found cached ($saved)";
5512             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5513             $split_brain = 1;
5514             return ($cachehit, $splitbrain_cachekey);
5515         }
5516         progress "dgit view: found cached, no changes required";
5517         return ($headref, $splitbrain_cachekey);
5518     }
5519     die $! if GC->error;
5520     failedcmd unless close GC;
5521
5522     printdebug "splitbrain cache miss\n";
5523     return (undef, $splitbrain_cachekey);
5524 }
5525
5526 sub quilt_fixup_multipatch ($$$) {
5527     my ($clogp, $headref, $upstreamversion) = @_;
5528
5529     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5530
5531     # Our objective is:
5532     #  - honour any existing .pc in case it has any strangeness
5533     #  - determine the git commit corresponding to the tip of
5534     #    the patch stack (if there is one)
5535     #  - if there is such a git commit, convert each subsequent
5536     #    git commit into a quilt patch with dpkg-source --commit
5537     #  - otherwise convert all the differences in the tree into
5538     #    a single git commit
5539     #
5540     # To do this we:
5541
5542     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5543     # dgit would include the .pc in the git tree.)  If there isn't
5544     # one, we need to generate one by unpacking the patches that we
5545     # have.
5546     #
5547     # We first look for a .pc in the git tree.  If there is one, we
5548     # will use it.  (This is not the normal case.)
5549     #
5550     # Otherwise need to regenerate .pc so that dpkg-source --commit
5551     # can work.  We do this as follows:
5552     #     1. Collect all relevant .orig from parent directory
5553     #     2. Generate a debian.tar.gz out of
5554     #         debian/{patches,rules,source/format,source/options}
5555     #     3. Generate a fake .dsc containing just these fields:
5556     #          Format Source Version Files
5557     #     4. Extract the fake .dsc
5558     #        Now the fake .dsc has a .pc directory.
5559     # (In fact we do this in every case, because in future we will
5560     # want to search for a good base commit for generating patches.)
5561     #
5562     # Then we can actually do the dpkg-source --commit
5563     #     1. Make a new working tree with the same object
5564     #        store as our main tree and check out the main
5565     #        tree's HEAD.
5566     #     2. Copy .pc from the fake's extraction, if necessary
5567     #     3. Run dpkg-source --commit
5568     #     4. If the result has changes to debian/, then
5569     #          - git add them them
5570     #          - git add .pc if we had a .pc in-tree
5571     #          - git commit
5572     #     5. If we had a .pc in-tree, delete it, and git commit
5573     #     6. Back in the main tree, fast forward to the new HEAD
5574
5575     # Another situation we may have to cope with is gbp-style
5576     # patches-unapplied trees.
5577     #
5578     # We would want to detect these, so we know to escape into
5579     # quilt_fixup_gbp.  However, this is in general not possible.
5580     # Consider a package with a one patch which the dgit user reverts
5581     # (with git revert or the moral equivalent).
5582     #
5583     # That is indistinguishable in contents from a patches-unapplied
5584     # tree.  And looking at the history to distinguish them is not
5585     # useful because the user might have made a confusing-looking git
5586     # history structure (which ought to produce an error if dgit can't
5587     # cope, not a silent reintroduction of an unwanted patch).
5588     #
5589     # So gbp users will have to pass an option.  But we can usually
5590     # detect their failure to do so: if the tree is not a clean
5591     # patches-applied tree, quilt linearisation fails, but the tree
5592     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5593     # they want --quilt=unapplied.
5594     #
5595     # To help detect this, when we are extracting the fake dsc, we
5596     # first extract it with --skip-patches, and then apply the patches
5597     # afterwards with dpkg-source --before-build.  That lets us save a
5598     # tree object corresponding to .origs.
5599
5600     my $splitbrain_cachekey;
5601
5602     quilt_make_fake_dsc($upstreamversion);
5603
5604     if (quiltmode_splitbrain()) {
5605         my $cachehit;
5606         ($cachehit, $splitbrain_cachekey) =
5607             quilt_check_splitbrain_cache($headref, $upstreamversion);
5608         return if $cachehit;
5609     }
5610
5611     runcmd qw(sh -ec),
5612         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5613
5614     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5615     rename $fakexdir, "fake" or die "$fakexdir $!";
5616
5617     changedir 'fake';
5618
5619     remove_stray_gits("source package");
5620     mktree_in_ud_here();
5621
5622     rmtree '.pc';
5623
5624     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5625     my $unapplied=git_add_write_tree();
5626     printdebug "fake orig tree object $unapplied\n";
5627
5628     ensuredir '.pc';
5629
5630     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5631     $!=0; $?=-1;
5632     if (system @bbcmd) {
5633         failedcmd @bbcmd if $? < 0;
5634         fail <<END;
5635 failed to apply your git tree's patch stack (from debian/patches/) to
5636  the corresponding upstream tarball(s).  Your source tree and .orig
5637  are probably too inconsistent.  dgit can only fix up certain kinds of
5638  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5639 END
5640     }
5641
5642     changedir '..';
5643
5644     quilt_fixup_mkwork($headref);
5645
5646     my $mustdeletepc=0;
5647     if (stat_exists ".pc") {
5648         -d _ or die;
5649         progress "Tree already contains .pc - will use it then delete it.";
5650         $mustdeletepc=1;
5651     } else {
5652         rename '../fake/.pc','.pc' or die $!;
5653     }
5654
5655     changedir '../fake';
5656     rmtree '.pc';
5657     my $oldtiptree=git_add_write_tree();
5658     printdebug "fake o+d/p tree object $unapplied\n";
5659     changedir '../work';
5660
5661
5662     # We calculate some guesswork now about what kind of tree this might
5663     # be.  This is mostly for error reporting.
5664
5665     my %editedignores;
5666     my @unrepres;
5667     my $diffbits = {
5668         # H = user's HEAD
5669         # O = orig, without patches applied
5670         # A = "applied", ie orig with H's debian/patches applied
5671         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5672                                      \%editedignores, \@unrepres),
5673         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5674         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5675     };
5676
5677     my @dl;
5678     foreach my $b (qw(01 02)) {
5679         foreach my $v (qw(O2H O2A H2A)) {
5680             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5681         }
5682     }
5683     printdebug "differences \@dl @dl.\n";
5684
5685     progress sprintf
5686 "$us: base trees orig=%.20s o+d/p=%.20s",
5687               $unapplied, $oldtiptree;
5688     progress sprintf
5689 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5690 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5691                              $dl[0], $dl[1],              $dl[3], $dl[4],
5692                                  $dl[2],                     $dl[5];
5693
5694     if (@unrepres) {
5695         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5696             foreach @unrepres;
5697         forceable_fail [qw(unrepresentable)], <<END;
5698 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5699 END
5700     }
5701
5702     my @failsuggestion;
5703     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5704         push @failsuggestion, "This might be a patches-unapplied branch.";
5705     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5706         push @failsuggestion, "This might be a patches-applied branch.";
5707     }
5708     push @failsuggestion, "Maybe you need to specify one of".
5709         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5710
5711     if (quiltmode_splitbrain()) {
5712         quiltify_splitbrain($clogp, $unapplied, $headref,
5713                             $diffbits, \%editedignores,
5714                             $splitbrain_cachekey);
5715         return;
5716     }
5717
5718     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5719     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5720
5721     if (!open P, '>>', ".pc/applied-patches") {
5722         $!==&ENOENT or die $!;
5723     } else {
5724         close P;
5725     }
5726
5727     commit_quilty_patch();
5728
5729     if ($mustdeletepc) {
5730         quilt_fixup_delete_pc();
5731     }
5732 }
5733
5734 sub quilt_fixup_editor () {
5735     my $descfn = $ENV{$fakeeditorenv};
5736     my $editing = $ARGV[$#ARGV];
5737     open I1, '<', $descfn or die "$descfn: $!";
5738     open I2, '<', $editing or die "$editing: $!";
5739     unlink $editing or die "$editing: $!";
5740     open O, '>', $editing or die "$editing: $!";
5741     while (<I1>) { print O or die $!; } I1->error and die $!;
5742     my $copying = 0;
5743     while (<I2>) {
5744         $copying ||= m/^\-\-\- /;
5745         next unless $copying;
5746         print O or die $!;
5747     }
5748     I2->error and die $!;
5749     close O or die $1;
5750     exit 0;
5751 }
5752
5753 sub maybe_apply_patches_dirtily () {
5754     return unless $quilt_mode =~ m/gbp|unapplied/;
5755     print STDERR <<END or die $!;
5756
5757 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5758 dgit: Have to apply the patches - making the tree dirty.
5759 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5760
5761 END
5762     $patches_applied_dirtily = 01;
5763     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5764     runcmd qw(dpkg-source --before-build .);
5765 }
5766
5767 sub maybe_unapply_patches_again () {
5768     progress "dgit: Unapplying patches again to tidy up the tree."
5769         if $patches_applied_dirtily;
5770     runcmd qw(dpkg-source --after-build .)
5771         if $patches_applied_dirtily & 01;
5772     rmtree '.pc'
5773         if $patches_applied_dirtily & 02;
5774     $patches_applied_dirtily = 0;
5775 }
5776
5777 #----- other building -----
5778
5779 our $clean_using_builder;
5780 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5781 #   clean the tree before building (perhaps invoked indirectly by
5782 #   whatever we are using to run the build), rather than separately
5783 #   and explicitly by us.
5784
5785 sub clean_tree () {
5786     return if $clean_using_builder;
5787     if ($cleanmode eq 'dpkg-source') {
5788         maybe_apply_patches_dirtily();
5789         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5790     } elsif ($cleanmode eq 'dpkg-source-d') {
5791         maybe_apply_patches_dirtily();
5792         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5793     } elsif ($cleanmode eq 'git') {
5794         runcmd_ordryrun_local @git, qw(clean -xdf);
5795     } elsif ($cleanmode eq 'git-ff') {
5796         runcmd_ordryrun_local @git, qw(clean -xdff);
5797     } elsif ($cleanmode eq 'check') {
5798         my $leftovers = cmdoutput @git, qw(clean -xdn);
5799         if (length $leftovers) {
5800             print STDERR $leftovers, "\n" or die $!;
5801             fail "tree contains uncommitted files and --clean=check specified";
5802         }
5803     } elsif ($cleanmode eq 'none') {
5804     } else {
5805         die "$cleanmode ?";
5806     }
5807 }
5808
5809 sub cmd_clean () {
5810     badusage "clean takes no additional arguments" if @ARGV;
5811     notpushing();
5812     clean_tree();
5813     maybe_unapply_patches_again();
5814 }
5815
5816 sub build_or_push_prep_early () {
5817     our $build_or_push_prep_early_done //= 0;
5818     return if $build_or_push_prep_early_done++;
5819     badusage "-p is not allowed with dgit $subcommand" if defined $package;
5820     my $clogp = parsechangelog();
5821     $isuite = getfield $clogp, 'Distribution';
5822     $package = getfield $clogp, 'Source';
5823     $version = getfield $clogp, 'Version';
5824 }
5825
5826 sub build_prep_early () {
5827     build_or_push_prep_early();
5828     notpushing();
5829     check_not_dirty();
5830 }
5831
5832 sub build_prep () {
5833     build_prep_early();
5834     clean_tree();
5835     build_maybe_quilt_fixup();
5836     if ($rmchanges) {
5837         my $pat = changespat $version;
5838         foreach my $f (glob "$buildproductsdir/$pat") {
5839             if (act_local()) {
5840                 unlink $f or fail "remove old changes file $f: $!";
5841             } else {
5842                 progress "would remove $f";
5843             }
5844         }
5845     }
5846 }
5847
5848 sub changesopts_initial () {
5849     my @opts =@changesopts[1..$#changesopts];
5850 }
5851
5852 sub changesopts_version () {
5853     if (!defined $changes_since_version) {
5854         my @vsns = archive_query('archive_query');
5855         my @quirk = access_quirk();
5856         if ($quirk[0] eq 'backports') {
5857             local $isuite = $quirk[2];
5858             local $csuite;
5859             canonicalise_suite();
5860             push @vsns, archive_query('archive_query');
5861         }
5862         if (@vsns) {
5863             @vsns = map { $_->[0] } @vsns;
5864             @vsns = sort { -version_compare($a, $b) } @vsns;
5865             $changes_since_version = $vsns[0];
5866             progress "changelog will contain changes since $vsns[0]";
5867         } else {
5868             $changes_since_version = '_';
5869             progress "package seems new, not specifying -v<version>";
5870         }
5871     }
5872     if ($changes_since_version ne '_') {
5873         return ("-v$changes_since_version");
5874     } else {
5875         return ();
5876     }
5877 }
5878
5879 sub changesopts () {
5880     return (changesopts_initial(), changesopts_version());
5881 }
5882
5883 sub massage_dbp_args ($;$) {
5884     my ($cmd,$xargs) = @_;
5885     # We need to:
5886     #
5887     #  - if we're going to split the source build out so we can
5888     #    do strange things to it, massage the arguments to dpkg-buildpackage
5889     #    so that the main build doessn't build source (or add an argument
5890     #    to stop it building source by default).
5891     #
5892     #  - add -nc to stop dpkg-source cleaning the source tree,
5893     #    unless we're not doing a split build and want dpkg-source
5894     #    as cleanmode, in which case we can do nothing
5895     #
5896     # return values:
5897     #    0 - source will NOT need to be built separately by caller
5898     #   +1 - source will need to be built separately by caller
5899     #   +2 - source will need to be built separately by caller AND
5900     #        dpkg-buildpackage should not in fact be run at all!
5901     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5902 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5903     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5904         $clean_using_builder = 1;
5905         return 0;
5906     }
5907     # -nc has the side effect of specifying -b if nothing else specified
5908     # and some combinations of -S, -b, et al, are errors, rather than
5909     # later simply overriding earlie.  So we need to:
5910     #  - search the command line for these options
5911     #  - pick the last one
5912     #  - perhaps add our own as a default
5913     #  - perhaps adjust it to the corresponding non-source-building version
5914     my $dmode = '-F';
5915     foreach my $l ($cmd, $xargs) {
5916         next unless $l;
5917         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5918     }
5919     push @$cmd, '-nc';
5920 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5921     my $r = 0;
5922     if ($need_split_build_invocation) {
5923         printdebug "massage split $dmode.\n";
5924         $r = $dmode =~ m/[S]/     ? +2 :
5925              $dmode =~ y/gGF/ABb/ ? +1 :
5926              $dmode =~ m/[ABb]/   ?  0 :
5927              die "$dmode ?";
5928     }
5929     printdebug "massage done $r $dmode.\n";
5930     push @$cmd, $dmode;
5931 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5932     return $r;
5933 }
5934
5935 sub in_parent (&) {
5936     my ($fn) = @_;
5937     my $wasdir = must_getcwd();
5938     changedir "..";
5939     $fn->();
5940     changedir $wasdir;
5941 }
5942
5943 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5944     my ($msg_if_onlyone) = @_;
5945     # If there is only one .changes file, fail with $msg_if_onlyone,
5946     # or if that is undef, be a no-op.
5947     # Returns the changes file to report to the user.
5948     my $pat = changespat $version;
5949     my @changesfiles = glob $pat;
5950     @changesfiles = sort {
5951         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5952             or $a cmp $b
5953     } @changesfiles;
5954     my $result;
5955     if (@changesfiles==1) {
5956         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5957 only one changes file from build (@changesfiles)
5958 END
5959         $result = $changesfiles[0];
5960     } elsif (@changesfiles==2) {
5961         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5962         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5963             fail "$l found in binaries changes file $binchanges"
5964                 if $l =~ m/\.dsc$/;
5965         }
5966         runcmd_ordryrun_local @mergechanges, @changesfiles;
5967         my $multichanges = changespat $version,'multi';
5968         if (act_local()) {
5969             stat_exists $multichanges or fail "$multichanges: $!";
5970             foreach my $cf (glob $pat) {
5971                 next if $cf eq $multichanges;
5972                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5973             }
5974         }
5975         $result = $multichanges;
5976     } else {
5977         fail "wrong number of different changes files (@changesfiles)";
5978     }
5979     printdone "build successful, results in $result\n" or die $!;
5980 }
5981
5982 sub midbuild_checkchanges () {
5983     my $pat = changespat $version;
5984     return if $rmchanges;
5985     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5986     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5987     fail <<END
5988 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5989 Suggest you delete @unwanted.
5990 END
5991         if @unwanted;
5992 }
5993
5994 sub midbuild_checkchanges_vanilla ($) {
5995     my ($wantsrc) = @_;
5996     midbuild_checkchanges() if $wantsrc == 1;
5997 }
5998
5999 sub postbuild_mergechanges_vanilla ($) {
6000     my ($wantsrc) = @_;
6001     if ($wantsrc == 1) {
6002         in_parent {
6003             postbuild_mergechanges(undef);
6004         };
6005     } else {
6006         printdone "build successful\n";
6007     }
6008 }
6009
6010 sub cmd_build {
6011     build_prep_early();
6012     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6013     my $wantsrc = massage_dbp_args \@dbp;
6014     if ($wantsrc > 0) {
6015         build_source();
6016         midbuild_checkchanges_vanilla $wantsrc;
6017     } else {
6018         build_prep();
6019     }
6020     if ($wantsrc < 2) {
6021         push @dbp, changesopts_version();
6022         maybe_apply_patches_dirtily();
6023         runcmd_ordryrun_local @dbp;
6024     }
6025     maybe_unapply_patches_again();
6026     postbuild_mergechanges_vanilla $wantsrc;
6027 }
6028
6029 sub pre_gbp_build {
6030     $quilt_mode //= 'gbp';
6031 }
6032
6033 sub cmd_gbp_build {
6034     build_prep_early();
6035
6036     # gbp can make .origs out of thin air.  In my tests it does this
6037     # even for a 1.0 format package, with no origs present.  So I
6038     # guess it keys off just the version number.  We don't know
6039     # exactly what .origs ought to exist, but let's assume that we
6040     # should run gbp if: the version has an upstream part and the main
6041     # orig is absent.
6042     my $upstreamversion = upstreamversion $version;
6043     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6044     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
6045
6046     if ($gbp_make_orig) {
6047         clean_tree();
6048         $cleanmode = 'none'; # don't do it again
6049         $need_split_build_invocation = 1;
6050     }
6051
6052     my @dbp = @dpkgbuildpackage;
6053
6054     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6055
6056     if (!length $gbp_build[0]) {
6057         if (length executable_on_path('git-buildpackage')) {
6058             $gbp_build[0] = qw(git-buildpackage);
6059         } else {
6060             $gbp_build[0] = 'gbp buildpackage';
6061         }
6062     }
6063     my @cmd = opts_opt_multi_cmd @gbp_build;
6064
6065     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
6066
6067     if ($gbp_make_orig) {
6068         ensuredir '.git/dgit';
6069         my $ok = '.git/dgit/origs-gen-ok';
6070         unlink $ok or $!==&ENOENT or die $!;
6071         my @origs_cmd = @cmd;
6072         push @origs_cmd, qw(--git-cleaner=true);
6073         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
6074         push @origs_cmd, @ARGV;
6075         if (act_local()) {
6076             debugcmd @origs_cmd;
6077             system @origs_cmd;
6078             do { local $!; stat_exists $ok; }
6079                 or failedcmd @origs_cmd;
6080         } else {
6081             dryrun_report @origs_cmd;
6082         }
6083     }
6084
6085     if ($wantsrc > 0) {
6086         build_source();
6087         midbuild_checkchanges_vanilla $wantsrc;
6088     } else {
6089         if (!$clean_using_builder) {
6090             push @cmd, '--git-cleaner=true';
6091         }
6092         build_prep();
6093     }
6094     maybe_unapply_patches_again();
6095     if ($wantsrc < 2) {
6096         push @cmd, changesopts();
6097         runcmd_ordryrun_local @cmd, @ARGV;
6098     }
6099     postbuild_mergechanges_vanilla $wantsrc;
6100 }
6101 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6102
6103 sub build_source {
6104     build_prep_early();
6105     my $our_cleanmode = $cleanmode;
6106     if ($need_split_build_invocation) {
6107         # Pretend that clean is being done some other way.  This
6108         # forces us not to try to use dpkg-buildpackage to clean and
6109         # build source all in one go; and instead we run dpkg-source
6110         # (and build_prep() will do the clean since $clean_using_builder
6111         # is false).
6112         $our_cleanmode = 'ELSEWHERE';
6113     }
6114     if ($our_cleanmode =~ m/^dpkg-source/) {
6115         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6116         $clean_using_builder = 1;
6117     }
6118     build_prep();
6119     $sourcechanges = changespat $version,'source';
6120     if (act_local()) {
6121         unlink "../$sourcechanges" or $!==ENOENT
6122             or fail "remove $sourcechanges: $!";
6123     }
6124     $dscfn = dscfn($version);
6125     if ($our_cleanmode eq 'dpkg-source') {
6126         maybe_apply_patches_dirtily();
6127         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6128             changesopts();
6129     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6130         maybe_apply_patches_dirtily();
6131         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6132             changesopts();
6133     } else {
6134         my @cmd = (@dpkgsource, qw(-b --));
6135         if ($split_brain) {
6136             changedir $ud;
6137             runcmd_ordryrun_local @cmd, "work";
6138             my @udfiles = <${package}_*>;
6139             changedir "../../..";
6140             foreach my $f (@udfiles) {
6141                 printdebug "source copy, found $f\n";
6142                 next unless
6143                     $f eq $dscfn or
6144                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6145                      $f eq srcfn($version, $&));
6146                 printdebug "source copy, found $f - renaming\n";
6147                 rename "$ud/$f", "../$f" or $!==ENOENT
6148                     or fail "put in place new source file ($f): $!";
6149             }
6150         } else {
6151             my $pwd = must_getcwd();
6152             my $leafdir = basename $pwd;
6153             changedir "..";
6154             runcmd_ordryrun_local @cmd, $leafdir;
6155             changedir $pwd;
6156         }
6157         runcmd_ordryrun_local qw(sh -ec),
6158             'exec >$1; shift; exec "$@"','x',
6159             "../$sourcechanges",
6160             @dpkggenchanges, qw(-S), changesopts();
6161     }
6162 }
6163
6164 sub cmd_build_source {
6165     build_prep_early();
6166     badusage "build-source takes no additional arguments" if @ARGV;
6167     build_source();
6168     maybe_unapply_patches_again();
6169     printdone "source built, results in $dscfn and $sourcechanges";
6170 }
6171
6172 sub cmd_sbuild {
6173     build_source();
6174     midbuild_checkchanges();
6175     in_parent {
6176         if (act_local()) {
6177             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6178             stat_exists $sourcechanges
6179                 or fail "$sourcechanges (in parent directory): $!";
6180         }
6181         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6182     };
6183     maybe_unapply_patches_again();
6184     in_parent {
6185         postbuild_mergechanges(<<END);
6186 perhaps you need to pass -A ?  (sbuild's default is to build only
6187 arch-specific binaries; dgit 1.4 used to override that.)
6188 END
6189     };
6190 }
6191
6192 sub cmd_quilt_fixup {
6193     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6194     build_prep_early();
6195     clean_tree();
6196     build_maybe_quilt_fixup();
6197 }
6198
6199 sub import_dsc_result {
6200     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6201     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6202     runcmd @cmd;
6203     check_gitattrs($newhash, "source tree");
6204
6205     progress "dgit: import-dsc: $what_msg";
6206 }
6207
6208 sub cmd_import_dsc {
6209     my $needsig = 0;
6210
6211     while (@ARGV) {
6212         last unless $ARGV[0] =~ m/^-/;
6213         $_ = shift @ARGV;
6214         last if m/^--?$/;
6215         if (m/^--require-valid-signature$/) {
6216             $needsig = 1;
6217         } else {
6218             badusage "unknown dgit import-dsc sub-option \`$_'";
6219         }
6220     }
6221
6222     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6223     my ($dscfn, $dstbranch) = @ARGV;
6224
6225     badusage "dry run makes no sense with import-dsc" unless act_local();
6226
6227     my $force = $dstbranch =~ s/^\+//   ? +1 :
6228                 $dstbranch =~ s/^\.\.// ? -1 :
6229                                            0;
6230     my $info = $force ? " $&" : '';
6231     $info = "$dscfn$info";
6232
6233     my $specbranch = $dstbranch;
6234     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6235     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6236
6237     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6238     my $chead = cmdoutput_errok @symcmd;
6239     defined $chead or $?==256 or failedcmd @symcmd;
6240
6241     fail "$dstbranch is checked out - will not update it"
6242         if defined $chead and $chead eq $dstbranch;
6243
6244     my $oldhash = git_get_ref $dstbranch;
6245
6246     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6247     $dscdata = do { local $/ = undef; <D>; };
6248     D->error and fail "read $dscfn: $!";
6249     close C;
6250
6251     # we don't normally need this so import it here
6252     use Dpkg::Source::Package;
6253     my $dp = new Dpkg::Source::Package filename => $dscfn,
6254         require_valid_signature => $needsig;
6255     {
6256         local $SIG{__WARN__} = sub {
6257             print STDERR $_[0];
6258             return unless $needsig;
6259             fail "import-dsc signature check failed";
6260         };
6261         if (!$dp->is_signed()) {
6262             warn "$us: warning: importing unsigned .dsc\n";
6263         } else {
6264             my $r = $dp->check_signature();
6265             die "->check_signature => $r" if $needsig && $r;
6266         }
6267     }
6268
6269     parse_dscdata();
6270
6271     $package = getfield $dsc, 'Source';
6272
6273     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6274         unless forceing [qw(import-dsc-with-dgit-field)];
6275     parse_dsc_field_def_dsc_distro();
6276
6277     $isuite = 'DGIT-IMPORT-DSC';
6278     $idistro //= $dsc_distro;
6279
6280     notpushing();
6281
6282     if (defined $dsc_hash) {
6283         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6284         resolve_dsc_field_commit undef, undef;
6285     }
6286     if (defined $dsc_hash) {
6287         my @cmd = (qw(sh -ec),
6288                    "echo $dsc_hash | git cat-file --batch-check");
6289         my $objgot = cmdoutput @cmd;
6290         if ($objgot =~ m#^\w+ missing\b#) {
6291             fail <<END
6292 .dsc contains Dgit field referring to object $dsc_hash
6293 Your git tree does not have that object.  Try `git fetch' from a
6294 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6295 END
6296         }
6297         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6298             if ($force > 0) {
6299                 progress "Not fast forward, forced update.";
6300             } else {
6301                 fail "Not fast forward to $dsc_hash";
6302             }
6303         }
6304         import_dsc_result $dstbranch, $dsc_hash,
6305             "dgit import-dsc (Dgit): $info",
6306             "updated git ref $dstbranch";
6307         return 0;
6308     }
6309
6310     fail <<END
6311 Branch $dstbranch already exists
6312 Specify ..$specbranch for a pseudo-merge, binding in existing history
6313 Specify  +$specbranch to overwrite, discarding existing history
6314 END
6315         if $oldhash && !$force;
6316
6317     my @dfi = dsc_files_info();
6318     foreach my $fi (@dfi) {
6319         my $f = $fi->{Filename};
6320         my $here = "../$f";
6321         if (lstat $here) {
6322             next if stat $here;
6323             fail "lstat $here works but stat gives $! !";
6324         }
6325         fail "stat $here: $!" unless $! == ENOENT;
6326         my $there = $dscfn;
6327         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6328             $there = $';
6329         } elsif ($dscfn =~ m#^/#) {
6330             $there = $dscfn;
6331         } else {
6332             fail "cannot import $dscfn which seems to be inside working tree!";
6333         }
6334         $there =~ s#/+[^/]+$## or
6335             fail "import $dscfn requires ../$f, but it does not exist";
6336         $there .= "/$f";
6337         my $test = $there =~ m{^/} ? $there : "../$there";
6338         stat $test or fail "import $dscfn requires $test, but: $!";
6339         symlink $there, $here or fail "symlink $there to $here: $!";
6340         progress "made symlink $here -> $there";
6341 #       print STDERR Dumper($fi);
6342     }
6343     my @mergeinputs = generate_commits_from_dsc();
6344     die unless @mergeinputs == 1;
6345
6346     my $newhash = $mergeinputs[0]{Commit};
6347
6348     if ($oldhash) {
6349         if ($force > 0) {
6350             progress "Import, forced update - synthetic orphan git history.";
6351         } elsif ($force < 0) {
6352             progress "Import, merging.";
6353             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6354             my $version = getfield $dsc, 'Version';
6355             my $clogp = commit_getclogp $newhash;
6356             my $authline = clogp_authline $clogp;
6357             $newhash = make_commit_text <<END;
6358 tree $tree
6359 parent $newhash
6360 parent $oldhash
6361 author $authline
6362 committer $authline
6363
6364 Merge $package ($version) import into $dstbranch
6365 END
6366         } else {
6367             die; # caught earlier
6368         }
6369     }
6370
6371     import_dsc_result $dstbranch, $newhash,
6372         "dgit import-dsc: $info",
6373         "results are in in git ref $dstbranch";
6374 }
6375
6376 sub pre_archive_api_query () {
6377     no_local_git_cfg();
6378 }
6379 sub cmd_archive_api_query {
6380     badusage "need only 1 subpath argument" unless @ARGV==1;
6381     my ($subpath) = @ARGV;
6382     my @cmd = archive_api_query_cmd($subpath);
6383     push @cmd, qw(-f);
6384     debugcmd ">",@cmd;
6385     exec @cmd or fail "exec curl: $!\n";
6386 }
6387
6388 sub repos_server_url () {
6389     $package = '_dgit-repos-server';
6390     local $access_forpush = 1;
6391     local $isuite = 'DGIT-REPOS-SERVER';
6392     my $url = access_giturl();
6393 }
6394
6395 sub pre_clone_dgit_repos_server () {
6396     no_local_git_cfg();
6397 }
6398 sub cmd_clone_dgit_repos_server {
6399     badusage "need destination argument" unless @ARGV==1;
6400     my ($destdir) = @ARGV;
6401     my $url = repos_server_url();
6402     my @cmd = (@git, qw(clone), $url, $destdir);
6403     debugcmd ">",@cmd;
6404     exec @cmd or fail "exec git clone: $!\n";
6405 }
6406
6407 sub pre_print_dgit_repos_server_source_url () {
6408     no_local_git_cfg();
6409 }
6410 sub cmd_print_dgit_repos_server_source_url {
6411     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6412         if @ARGV;
6413     my $url = repos_server_url();
6414     print $url, "\n" or die $!;
6415 }
6416
6417 sub cmd_setup_mergechangelogs {
6418     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6419     local $isuite = 'DGIT-SETUP-TREE';
6420     setup_mergechangelogs(1);
6421 }
6422
6423 sub cmd_setup_useremail {
6424     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6425     local $isuite = 'DGIT-SETUP-TREE';
6426     setup_useremail(1);
6427 }
6428
6429 sub cmd_setup_gitattributes {
6430     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6431     local $isuite = 'DGIT-SETUP-TREE';
6432     setup_gitattrs(1);
6433 }
6434
6435 sub cmd_setup_new_tree {
6436     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6437     local $isuite = 'DGIT-SETUP-TREE';
6438     setup_new_tree();
6439 }
6440
6441 #---------- argument parsing and main program ----------
6442
6443 sub cmd_version {
6444     print "dgit version $our_version\n" or die $!;
6445     exit 0;
6446 }
6447
6448 our (%valopts_long, %valopts_short);
6449 our (%funcopts_long);
6450 our @rvalopts;
6451 our (@modeopt_cfgs);
6452
6453 sub defvalopt ($$$$) {
6454     my ($long,$short,$val_re,$how) = @_;
6455     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6456     $valopts_long{$long} = $oi;
6457     $valopts_short{$short} = $oi;
6458     # $how subref should:
6459     #   do whatever assignemnt or thing it likes with $_[0]
6460     #   if the option should not be passed on to remote, @rvalopts=()
6461     # or $how can be a scalar ref, meaning simply assign the value
6462 }
6463
6464 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6465 defvalopt '--distro',        '-d', '.+',      \$idistro;
6466 defvalopt '',                '-k', '.+',      \$keyid;
6467 defvalopt '--existing-package','', '.*',      \$existing_package;
6468 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6469 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6470 defvalopt '--package',   '-p',   $package_re, \$package;
6471 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6472
6473 defvalopt '', '-C', '.+', sub {
6474     ($changesfile) = (@_);
6475     if ($changesfile =~ s#^(.*)/##) {
6476         $buildproductsdir = $1;
6477     }
6478 };
6479
6480 defvalopt '--initiator-tempdir','','.*', sub {
6481     ($initiator_tempdir) = (@_);
6482     $initiator_tempdir =~ m#^/# or
6483         badusage "--initiator-tempdir must be used specify an".
6484         " absolute, not relative, directory."
6485 };
6486
6487 sub defoptmodes ($@) {
6488     my ($varref, $cfgkey, $default, %optmap) = @_;
6489     my %permit;
6490     while (my ($opt,$val) = each %optmap) {
6491         $funcopts_long{$opt} = sub { $$varref = $val; };
6492         $permit{$val} = $val;
6493     }
6494     push @modeopt_cfgs, {
6495         Var => $varref,
6496         Key => $cfgkey,
6497         Default => $default,
6498         Vals => \%permit
6499     };
6500 }
6501
6502 defoptmodes \$dodep14tag, qw( dep14tag          want
6503                               --dep14tag        want
6504                               --no-dep14tag     no
6505                               --always-dep14tag always );
6506
6507 sub parseopts () {
6508     my $om;
6509
6510     if (defined $ENV{'DGIT_SSH'}) {
6511         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6512     } elsif (defined $ENV{'GIT_SSH'}) {
6513         @ssh = ($ENV{'GIT_SSH'});
6514     }
6515
6516     my $oi;
6517     my $val;
6518     my $valopt = sub {
6519         my ($what) = @_;
6520         @rvalopts = ($_);
6521         if (!defined $val) {
6522             badusage "$what needs a value" unless @ARGV;
6523             $val = shift @ARGV;
6524             push @rvalopts, $val;
6525         }
6526         badusage "bad value \`$val' for $what" unless
6527             $val =~ m/^$oi->{Re}$(?!\n)/s;
6528         my $how = $oi->{How};
6529         if (ref($how) eq 'SCALAR') {
6530             $$how = $val;
6531         } else {
6532             $how->($val);
6533         }
6534         push @ropts, @rvalopts;
6535     };
6536
6537     while (@ARGV) {
6538         last unless $ARGV[0] =~ m/^-/;
6539         $_ = shift @ARGV;
6540         last if m/^--?$/;
6541         if (m/^--/) {
6542             if (m/^--dry-run$/) {
6543                 push @ropts, $_;
6544                 $dryrun_level=2;
6545             } elsif (m/^--damp-run$/) {
6546                 push @ropts, $_;
6547                 $dryrun_level=1;
6548             } elsif (m/^--no-sign$/) {
6549                 push @ropts, $_;
6550                 $sign=0;
6551             } elsif (m/^--help$/) {
6552                 cmd_help();
6553             } elsif (m/^--version$/) {
6554                 cmd_version();
6555             } elsif (m/^--new$/) {
6556                 push @ropts, $_;
6557                 $new_package=1;
6558             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6559                      ($om = $opts_opt_map{$1}) &&
6560                      length $om->[0]) {
6561                 push @ropts, $_;
6562                 $om->[0] = $2;
6563             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6564                      !$opts_opt_cmdonly{$1} &&
6565                      ($om = $opts_opt_map{$1})) {
6566                 push @ropts, $_;
6567                 push @$om, $2;
6568             } elsif (m/^--(gbp|dpm)$/s) {
6569                 push @ropts, "--quilt=$1";
6570                 $quilt_mode = $1;
6571             } elsif (m/^--ignore-dirty$/s) {
6572                 push @ropts, $_;
6573                 $ignoredirty = 1;
6574             } elsif (m/^--no-quilt-fixup$/s) {
6575                 push @ropts, $_;
6576                 $quilt_mode = 'nocheck';
6577             } elsif (m/^--no-rm-on-error$/s) {
6578                 push @ropts, $_;
6579                 $rmonerror = 0;
6580             } elsif (m/^--no-chase-dsc-distro$/s) {
6581                 push @ropts, $_;
6582                 $chase_dsc_distro = 0;
6583             } elsif (m/^--overwrite$/s) {
6584                 push @ropts, $_;
6585                 $overwrite_version = '';
6586             } elsif (m/^--overwrite=(.+)$/s) {
6587                 push @ropts, $_;
6588                 $overwrite_version = $1;
6589             } elsif (m/^--delayed=(\d+)$/s) {
6590                 push @ropts, $_;
6591                 push @dput, $_;
6592             } elsif (m/^--dgit-view-save=(.+)$/s) {
6593                 push @ropts, $_;
6594                 $split_brain_save = $1;
6595                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6596             } elsif (m/^--(no-)?rm-old-changes$/s) {
6597                 push @ropts, $_;
6598                 $rmchanges = !$1;
6599             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6600                 push @ropts, $_;
6601                 push @deliberatelies, $&;
6602             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6603                 push @ropts, $&;
6604                 $forceopts{$1} = 1;
6605                 $_='';
6606             } elsif (m/^--force-/) {
6607                 print STDERR
6608                     "$us: warning: ignoring unknown force option $_\n";
6609                 $_='';
6610             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6611                 # undocumented, for testing
6612                 push @ropts, $_;
6613                 $tagformat_want = [ $1, 'command line', 1 ];
6614                 # 1 menas overrides distro configuration
6615             } elsif (m/^--always-split-source-build$/s) {
6616                 # undocumented, for testing
6617                 push @ropts, $_;
6618                 $need_split_build_invocation = 1;
6619             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6620                 # undocumented, for testing
6621                 push @ropts, $_;
6622                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6623                 # ^ it's supposed to be an array ref
6624             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6625                 $val = $2 ? $' : undef; #';
6626                 $valopt->($oi->{Long});
6627             } elsif ($funcopts_long{$_}) {
6628                 push @ropts, $_;
6629                 $funcopts_long{$_}();
6630             } else {
6631                 badusage "unknown long option \`$_'";
6632             }
6633         } else {
6634             while (m/^-./s) {
6635                 if (s/^-n/-/) {
6636                     push @ropts, $&;
6637                     $dryrun_level=2;
6638                 } elsif (s/^-L/-/) {
6639                     push @ropts, $&;
6640                     $dryrun_level=1;
6641                 } elsif (s/^-h/-/) {
6642                     cmd_help();
6643                 } elsif (s/^-D/-/) {
6644                     push @ropts, $&;
6645                     $debuglevel++;
6646                     enabledebug();
6647                 } elsif (s/^-N/-/) {
6648                     push @ropts, $&;
6649                     $new_package=1;
6650                 } elsif (m/^-m/) {
6651                     push @ropts, $&;
6652                     push @changesopts, $_;
6653                     $_ = '';
6654                 } elsif (s/^-wn$//s) {
6655                     push @ropts, $&;
6656                     $cleanmode = 'none';
6657                 } elsif (s/^-wg$//s) {
6658                     push @ropts, $&;
6659                     $cleanmode = 'git';
6660                 } elsif (s/^-wgf$//s) {
6661                     push @ropts, $&;
6662                     $cleanmode = 'git-ff';
6663                 } elsif (s/^-wd$//s) {
6664                     push @ropts, $&;
6665                     $cleanmode = 'dpkg-source';
6666                 } elsif (s/^-wdd$//s) {
6667                     push @ropts, $&;
6668                     $cleanmode = 'dpkg-source-d';
6669                 } elsif (s/^-wc$//s) {
6670                     push @ropts, $&;
6671                     $cleanmode = 'check';
6672                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6673                     push @git, '-c', $&;
6674                     $gitcfgs{cmdline}{$1} = [ $2 ];
6675                 } elsif (s/^-c([^=]+)$//s) {
6676                     push @git, '-c', $&;
6677                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6678                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6679                     $val = $'; #';
6680                     $val = undef unless length $val;
6681                     $valopt->($oi->{Short});
6682                     $_ = '';
6683                 } else {
6684                     badusage "unknown short option \`$_'";
6685                 }
6686             }
6687         }
6688     }
6689 }
6690
6691 sub check_env_sanity () {
6692     my $blocked = new POSIX::SigSet;
6693     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6694
6695     eval {
6696         foreach my $name (qw(PIPE CHLD)) {
6697             my $signame = "SIG$name";
6698             my $signum = eval "POSIX::$signame" // die;
6699             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6700                 die "$signame is set to something other than SIG_DFL\n";
6701             $blocked->ismember($signum) and
6702                 die "$signame is blocked\n";
6703         }
6704     };
6705     return unless $@;
6706     chomp $@;
6707     fail <<END;
6708 On entry to dgit, $@
6709 This is a bug produced by something in in your execution environment.
6710 Giving up.
6711 END
6712 }
6713
6714
6715 sub parseopts_late_defaults () {
6716     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6717         if defined $idistro;
6718     $isuite //= cfg('dgit.default.default-suite');
6719
6720     foreach my $k (keys %opts_opt_map) {
6721         my $om = $opts_opt_map{$k};
6722
6723         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6724         if (defined $v) {
6725             badcfg "cannot set command for $k"
6726                 unless length $om->[0];
6727             $om->[0] = $v;
6728         }
6729
6730         foreach my $c (access_cfg_cfgs("opts-$k")) {
6731             my @vl =
6732                 map { $_ ? @$_ : () }
6733                 map { $gitcfgs{$_}{$c} }
6734                 reverse @gitcfgsources;
6735             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6736                 "\n" if $debuglevel >= 4;
6737             next unless @vl;
6738             badcfg "cannot configure options for $k"
6739                 if $opts_opt_cmdonly{$k};
6740             my $insertpos = $opts_cfg_insertpos{$k};
6741             @$om = ( @$om[0..$insertpos-1],
6742                      @vl,
6743                      @$om[$insertpos..$#$om] );
6744         }
6745     }
6746
6747     if (!defined $rmchanges) {
6748         local $access_forpush;
6749         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6750     }
6751
6752     if (!defined $quilt_mode) {
6753         local $access_forpush;
6754         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6755             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6756             // 'linear';
6757         $quilt_mode =~ m/^($quilt_modes_re)$/
6758             or badcfg "unknown quilt-mode \`$quilt_mode'";
6759         $quilt_mode = $1;
6760     }
6761
6762     foreach my $moc (@modeopt_cfgs) {
6763         local $access_forpush;
6764         my $vr = $moc->{Var};
6765         next if defined $$vr;
6766         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6767         my $v = $moc->{Vals}{$$vr};
6768         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6769         $$vr = $v;
6770     }
6771
6772     $need_split_build_invocation ||= quiltmode_splitbrain();
6773
6774     if (!defined $cleanmode) {
6775         local $access_forpush;
6776         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6777         $cleanmode //= 'dpkg-source';
6778
6779         badcfg "unknown clean-mode \`$cleanmode'" unless
6780             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6781     }
6782 }
6783
6784 if ($ENV{$fakeeditorenv}) {
6785     git_slurp_config();
6786     quilt_fixup_editor();
6787 }
6788
6789 parseopts();
6790 check_env_sanity();
6791
6792 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6793 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6794     if $dryrun_level == 1;
6795 if (!@ARGV) {
6796     print STDERR $helpmsg or die $!;
6797     exit 8;
6798 }
6799 $cmd = $subcommand = shift @ARGV;
6800 $cmd =~ y/-/_/;
6801
6802 my $pre_fn = ${*::}{"pre_$cmd"};
6803 $pre_fn->() if $pre_fn;
6804
6805 git_slurp_config();
6806
6807 my $fn = ${*::}{"cmd_$cmd"};
6808 $fn or badusage "unknown operation $cmd";
6809 $fn->();