dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2018 Ian Jackson
   6 # Copyright (C)2017-2018 Sean Whitton
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::ExitStatus;
  23 use Debian::Dgit::I18n;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use IO::Handle;
  31 use Data::Dumper;
  32 use LWP::UserAgent;
  33 use Dpkg::Control::Hash;
  34 use File::Path;
  35 use File::Spec;
  36 use File::Temp qw(tempdir);
  37 use File::Basename;
  38 use Dpkg::Version;
  39 use Dpkg::Compression;
  40 use Dpkg::Compression::Process;
  41 use POSIX;
  42 use Locale::gettext;
  43 use IPC::Open2;
  44 use Digest::SHA;
  45 use Digest::MD5;
  46 use List::MoreUtils qw(pairwise);
  47 use Text::Glob qw(match_glob);
  48 use Fcntl qw(:DEFAULT :flock);
  49 use Carp;
  50
  51 use Debian::Dgit;
  52
  53 our $our_version = 'UNRELEASED'; ###substituted###
  54 our $absurdity = undef; ###substituted###
  55
  56 our @rpushprotovsn_support = qw(6 5 4); # Reverse order!
  57 our $protovsn;
  58
  59 our $cmd;
  60 our $subcommand;
  61 our $isuite;
  62 our $idistro;
  63 our $package;
  64 our @ropts;
  65
  66 our $sign = 1;
  67 our $dryrun_level = 0;
  68 our $changesfile;
  69 our $buildproductsdir;
  70 our $bpd_glob;
  71 our $new_package = 0;
  72 our $includedirty = 0;
  73 our $rmonerror = 1;
  74 our @deliberatelies;
  75 our %previously;
  76 our $existing_package = 'dpkg';
  77 our $cleanmode;
  78 our $changes_since_version;
  79 our $rmchanges;
  80 our $overwrite_version; # undef: not specified; '': check changelog
  81 our $quilt_mode;
  82 our $quilt_upstream_commitish;
  83 our $quilt_upstream_commitish_used;
  84 our $quilt_upstream_commitish_message;
  85 our $quilt_options_re = 'gbp|dpm|baredebian(?:\+tarball|\+git)?';
  86 our $quilt_modes_re = "linear|smash|auto|nofix|nocheck|unapplied|$quilt_options_re";
  87 our $splitview_mode;
  88 our $splitview_modes_re = qr{auto|always|never};
  89 our $dodep14tag;
  90 our %internal_object_save;
  91 our $we_are_responder;
  92 our $we_are_initiator;
  93 our $initiator_tempdir;
  94 our $patches_applied_dirtily = 00;
  95 our $chase_dsc_distro=1;
  96
  97 our %forceopts = map { $_=>0 }
  98     qw(unrepresentable unsupported-source-format
  99        dsc-changes-mismatch changes-origs-exactly
 100        uploading-binaries uploading-source-only
 101        import-gitapply-absurd
 102        import-gitapply-no-absurd
 103        import-dsc-with-dgit-field);
 104
 105 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
 106
 107 our $cleanmode_re = qr{(?: dpkg-source (?: -d )? (?: ,no-check | ,all-check )?
 108                      | (?: git | git-ff ) (?: ,always )?
 109                          | check (?: ,ignores )?
 110                          | none
 111                          )}x;
 112
 113 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
 114 our $splitbraincache = 'dgit-intern/quilt-cache';
 115 our $rewritemap = 'dgit-rewrite/map';
 116
 117 our @dpkg_source_ignores = qw(-i(?:^|/)\.git(?:/|$) -I.git);
 118
 119 our (@git) = qw(git);
 120 our (@dget) = qw(dget);
 121 our (@curl) = (qw(curl --proto-redir), '-all,http,https', qw(-L));
 122 our (@dput) = qw(dput);
 123 our (@debsign) = qw(debsign);
 124 our (@gpg) = qw(gpg);
 125 our (@sbuild) = (qw(sbuild --no-source));
 126 our (@ssh) = 'ssh';
 127 our (@dgit) = qw(dgit);
 128 our (@git_debrebase) = qw(git-debrebase);
 129 our (@aptget) = qw(apt-get);
 130 our (@aptcache) = qw(apt-cache);
 131 our (@dpkgbuildpackage) = (qw(dpkg-buildpackage), @dpkg_source_ignores);
 132 our (@dpkgsource) = (qw(dpkg-source), @dpkg_source_ignores);
 133 our (@dpkggenchanges) = qw(dpkg-genchanges);
 134 our (@mergechanges) = qw(mergechanges -f);
 135 our (@gbp_build) = ('');
 136 our (@gbp_pq) = ('gbp pq');
 137 our (@changesopts) = ('');
 138 our (@pbuilder) = ("sudo -E pbuilder","--no-source-only-changes");
 139 our (@cowbuilder) = ("sudo -E cowbuilder","--no-source-only-changes");
 140
 141 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 142                      'curl' => \@curl,
 143                      'dput' => \@dput,
 144                      'debsign' => \@debsign,
 145                      'gpg' => \@gpg,
 146                      'sbuild' => \@sbuild,
 147                      'ssh' => \@ssh,
 148                      'dgit' => \@dgit,
 149                      'git' => \@git,
 150                      'git-debrebase' => \@git_debrebase,
 151                      'apt-get' => \@aptget,
 152                      'apt-cache' => \@aptcache,
 153                      'dpkg-source' => \@dpkgsource,
 154                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 155                      'dpkg-genchanges' => \@dpkggenchanges,
 156                      'gbp-build' => \@gbp_build,
 157                      'gbp-pq' => \@gbp_pq,
 158                      'ch' => \@changesopts,
 159                      'mergechanges' => \@mergechanges,
 160                      'pbuilder' => \@pbuilder,
 161                      'cowbuilder' => \@cowbuilder);
 162
 163 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 164 our %opts_cfg_insertpos = map {
 165     $_,
 166     scalar @{ $opts_opt_map{$_} }
 167 } keys %opts_opt_map;
 168
 169 sub parseopts_late_defaults();
 170 sub quiltify_trees_differ ($$;$$$);
 171 sub setup_gitattrs(;$);
 172 sub check_gitattrs($$);
 173
 174 our $playground;
 175 our $keyid;
 176
 177 autoflush STDOUT 1;
 178
 179 our $supplementary_message = '';
 180 our $made_split_brain = 0;
 181 our $do_split_brain;
 182
 183 # Interactions between quilt mode and split brain
 184 # (currently, split brain only implemented iff
 185 #  madformat_wantfixup && quiltmode_splitting)
 186 #
 187 #   source format        sane           `3.0 (quilt)'
 188 #                                       madformat_wantfixup()
 189 #
 190 #   quilt mode                          normal              quiltmode
 191 #                                       (eg linear)         _splitbrain
 192 #
 193 #   ------------      ------------------------------------------------
 194 #
 195 #   no split          no q cache        no q cache          forbidden,
 196 #     brain           PM on master      q fixup on master   prevented
 197 #   !do_split_brain()                    PM on master
 198 #
 199 #   split brain       no q cache        q fixup cached, to dgit view
 200 #                     PM in dgit view   PM in dgit view
 201 #
 202 # PM = pseudomerge to make ff, due to overwrite (or split view)
 203 # "no q cache" = do not record in cache on build, do not check cache
 204 # `3.0 (quilt)' with --quilt=nocheck is treated as sane format
 205
 206 END {
 207     local ($@, $?);
 208     return unless forkcheck_mainprocess();
 209     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 210 }
 211
 212 our $remotename = 'dgit';
 213 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 214 our $csuite;
 215 our $instead_distro;
 216
 217 if (!defined $absurdity) {
 218     $absurdity = $0;
 219     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 220 }
 221
 222 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 223
 224 sub lbranch () { return "$branchprefix/$csuite"; }
 225 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 226 sub lref () { return "refs/heads/".lbranch(); }
 227 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 228 sub rrref () { return server_ref($csuite); }
 229
 230 sub srcfn ($$) {
 231     my ($vsn, $sfx) = @_;
 232     return &source_file_leafname($package, $vsn, $sfx);
 233 }
 234 sub is_orig_file_of_vsn ($$) {
 235     my ($f, $upstreamvsn) = @_;
 236     return is_orig_file_of_p_v($f, $package, $upstreamvsn);
 237 }
 238
 239 sub dscfn ($) {
 240     my ($vsn) = @_;
 241     return srcfn($vsn,".dsc");
 242 }
 243
 244 sub changespat ($;$) {
 245     my ($vsn, $arch) = @_;
 246     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 247 }
 248
 249 our $us = 'dgit';
 250 initdebug('');
 251
 252 our @end;
 253 END {
 254     local ($?);
 255     return unless forkcheck_mainprocess();
 256     foreach my $f (@end) {
 257         eval { $f->(); };
 258         print STDERR "$us: cleanup: $@" if length $@;
 259     }
 260 };
 261
 262 sub badcfg {
 263     print STDERR f_ "%s: invalid configuration: %s\n", $us, "@_";
 264     finish 12;
 265 }
 266
 267 sub forceable_fail ($$) {
 268     my ($forceoptsl, $msg) = @_;
 269     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 270     print STDERR +(__ "warning: overriding problem due to --force:\n"). $msg;
 271 }
 272
 273 sub forceing ($) {
 274     my ($forceoptsl) = @_;
 275     my @got = grep { $forceopts{$_} } @$forceoptsl;
 276     return 0 unless @got;
 277     print STDERR f_
 278         "warning: skipping checks or functionality due to --force-%s\n",
 279         $got[0];
 280 }
 281
 282 sub no_such_package () {
 283     print STDERR f_ "%s: source package %s does not exist in suite %s\n",
 284         $us, $package, $isuite;
 285     finish 4;
 286 }
 287
 288 sub deliberately ($) {
 289     my ($enquiry) = @_;
 290     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 291 }
 292
 293 sub deliberately_not_fast_forward () {
 294     foreach (qw(not-fast-forward fresh-repo)) {
 295         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 296     }
 297 }
 298
 299 sub quiltmode_splitting () {
 300     $quilt_mode =~ m/gbp|dpm|unapplied|baredebian/;
 301 }
 302 sub format_quiltmode_splitting ($) {
 303     my ($format) = @_;
 304     return madformat_wantfixup($format) && quiltmode_splitting();
 305 }
 306
 307 sub do_split_brain () { !!($do_split_brain // confess) }
 308
 309 sub opts_opt_multi_cmd {
 310     my $extra = shift;
 311     my @cmd;
 312     push @cmd, split /\s+/, shift @_;
 313     push @cmd, @$extra;
 314     push @cmd, @_;
 315     @cmd;
 316 }
 317
 318 sub gbp_pq {
 319     return opts_opt_multi_cmd [], @gbp_pq;
 320 }
 321
 322 sub dgit_privdir () {
 323     our $dgit_privdir_made //= ensure_a_playground 'dgit';
 324 }
 325
 326 sub bpd_abs () {
 327     my $r = $buildproductsdir;
 328     $r = "$maindir/$r" unless $r =~ m{^/};
 329     return $r;
 330 }
 331
 332 sub get_tree_of_commit ($) {
 333     my ($commitish) = @_;
 334     my $cdata = cmdoutput @git, qw(cat-file commit), $commitish;
 335     $cdata =~ m/\n\n/;  $cdata = $`;
 336     $cdata =~ m/^tree (\w+)$/m or confess "cdata $cdata ?";
 337     return $1;
 338 }
 339
 340 sub branch_gdr_info ($$) {
 341     my ($symref, $head) = @_;
 342     my ($status, $msg, $current, $ffq_prev, $gdrlast) =
 343         gdr_ffq_prev_branchinfo($symref);
 344     return () unless $status eq 'branch';
 345     $ffq_prev = git_get_ref $ffq_prev;
 346     $gdrlast  = git_get_ref $gdrlast;
 347     $gdrlast &&= is_fast_fwd $gdrlast, $head;
 348     return ($ffq_prev, $gdrlast);
 349 }
 350
 351 sub branch_is_gdr_unstitched_ff ($$$) {
 352     my ($symref, $head, $ancestor) = @_;
 353     my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $head);
 354     return 0 unless $ffq_prev;
 355     return 0 unless !defined $ancestor or is_fast_fwd $ancestor, $ffq_prev;
 356     return 1;
 357 }
 358
 359 sub branch_is_gdr ($) {
 360     my ($head) = @_;
 361     # This is quite like git-debrebase's keycommits.
 362     # We have our own implementation because:
 363     #  - our algorighm can do fewer tests so is faster
 364     #  - it saves testing to see if gdr is installed
 365
 366     # NB we use this jsut for deciding whether to run gdr make-patches
 367     # Before reusing this algorithm for somthing else, its
 368     # suitability should be reconsidered.
 369
 370     my $walk = $head;
 371     local $Debian::Dgit::debugcmd_when_debuglevel = 3;
 372     printdebug "branch_is_gdr $head...\n";
 373     my $get_patches = sub {
 374         my $t = git_cat_file "$_[0]:debian/patches", [qw(missing tree)];
 375         return $t // '';
 376     };
 377     my $tip_patches = $get_patches->($head);
 378   WALK:
 379     for (;;) {
 380         my $cdata = git_cat_file $walk, 'commit';
 381         my ($hdrs,$msg) = $cdata =~ m{\n\n} ? ($`,$') : ($cdata,'');
 382         if ($msg =~ m{^\[git-debrebase\ (
 383                           anchor | changelog | make-patches |
 384                           merged-breakwater | pseudomerge
 385                       ) [: ] }mx) {
 386             # no need to analyse this - it's sufficient
 387             # (gdr classifications: Anchor, MergedBreakwaters)
 388             # (made by gdr: Pseudomerge, Changelog)
 389             printdebug "branch_is_gdr  $walk gdr $1 YES\n";
 390             return 1;
 391         }
 392         my @parents = ($hdrs =~ m/^parent (\w+)$/gm);
 393         if (@parents==2) {
 394             my $walk_tree = get_tree_of_commit $walk;
 395             foreach my $p (@parents) {
 396                 my $p_tree = get_tree_of_commit $p;
 397                 if ($p_tree eq $walk_tree) { # pseudomerge contriburor
 398                     # (gdr classification: Pseudomerge; not made by gdr)
 399                     printdebug "branch_is_gdr  $walk unmarked pseudomerge\n"
 400                         if $debuglevel >= 2;
 401                     $walk = $p;
 402                     next WALK;
 403                 }
 404             }
 405             # some other non-gdr merge
 406             # (gdr classification: VanillaMerge, DgitImportUnpatched, ?)
 407             printdebug "branch_is_gdr  $walk ?-2-merge NO\n";
 408             return 0;
 409         }
 410         if (@parents>2) {
 411             # (gdr classification: ?)
 412             printdebug "branch_is_gdr  $walk ?-octopus NO\n";
 413             return 0;
 414         }
 415         if (!@parents) {
 416             printdebug "branch_is_gdr  $walk origin\n";
 417             return 0;
 418         }
 419         if ($get_patches->($walk) ne $tip_patches) {
 420             # Our parent added, removed, or edited patches, and wasn't
 421             # a gdr make-patches commit.  gdr make-patches probably
 422             # won't do that well, then.
 423             # (gdr classification of parent: AddPatches or ?)
 424             printdebug "branch_is_gdr  $walk ?-patches NO\n";
 425             return 0;
 426         }
 427         if ($tip_patches eq '' and
 428             !defined git_cat_file "$walk~:debian" and
 429             !quiltify_trees_differ "$walk~", $walk
 430            ) {
 431             # (gdr classification of parent: BreakwaterStart
 432             printdebug "branch_is_gdr  $walk unmarked BreakwaterStart YES\n";
 433             return 1;
 434         }
 435         # (gdr classification: Upstream Packaging Mixed Changelog)
 436         printdebug "branch_is_gdr  $walk plain\n"
 437             if $debuglevel >= 2;
 438         $walk = $parents[0];
 439     }
 440 }
 441
 442 #---------- remote protocol support, common ----------
 443
 444 # remote push initiator/responder protocol:
 445 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 446 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 447 #  < dgit-remote-push-ready <actual-proto-vsn>
 448 #
 449 # occasionally:
 450 #
 451 #  > progress NBYTES
 452 #  [NBYTES message]
 453 #
 454 #  > supplementary-message NBYTES
 455 #  [NBYTES message]
 456 #
 457 # main sequence:
 458 #
 459 #  > file parsed-changelog
 460 #  [indicates that output of dpkg-parsechangelog follows]
 461 #  > data-block NBYTES
 462 #  > [NBYTES bytes of data (no newline)]
 463 #  [maybe some more blocks]
 464 #  > data-end
 465 #
 466 #  > file dsc
 467 #  [etc]
 468 #
 469 #  > file changes
 470 #  [etc]
 471 #
 472 #  > param head DGIT-VIEW-HEAD
 473 #  > param csuite SUITE
 474 #  > param tagformat new              # $protovsn == 4
 475 #  > param splitbrain 0|1             # $protovsn >= 6
 476 #  > param maint-view MAINT-VIEW-HEAD
 477 #
 478 #  > param buildinfo-filename P_V_X.buildinfo   # zero or more times
 479 #  > file buildinfo                             # for buildinfos to sign
 480 #
 481 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 482 #                                     # goes into tag, for replay prevention
 483 #
 484 #  > want signed-tag
 485 #  [indicates that signed tag is wanted]
 486 #  < data-block NBYTES
 487 #  < [NBYTES bytes of data (no newline)]
 488 #  [maybe some more blocks]
 489 #  < data-end
 490 #  < files-end
 491 #
 492 #  > want signed-dsc-changes
 493 #  < data-block NBYTES    [transfer of signed dsc]
 494 #  [etc]
 495 #  < data-block NBYTES    [transfer of signed changes]
 496 #  [etc]
 497 #  < data-block NBYTES    [transfer of each signed buildinfo
 498 #  [etc]                   same number and order as "file buildinfo"]
 499 #  ...
 500 #  < files-end
 501 #
 502 #  > complete
 503
 504 our $i_child_pid;
 505
 506 sub i_child_report () {
 507     # Sees if our child has died, and reap it if so.  Returns a string
 508     # describing how it died if it failed, or undef otherwise.
 509     return undef unless $i_child_pid;
 510     my $got = waitpid $i_child_pid, WNOHANG;
 511     return undef if $got <= 0;
 512     die unless $got == $i_child_pid;
 513     $i_child_pid = undef;
 514     return undef unless $?;
 515     return f_ "build host child %s", waitstatusmsg();
 516 }
 517
 518 sub badproto ($$) {
 519     my ($fh, $m) = @_;
 520     fail f_ "connection lost: %s", $! if $fh->error;
 521     fail f_ "protocol violation; %s not expected", $m;
 522 }
 523
 524 sub badproto_badread ($$) {
 525     my ($fh, $wh) = @_;
 526     fail f_ "connection lost: %s", $! if $!;
 527     my $report = i_child_report();
 528     fail $report if defined $report;
 529     badproto $fh, f_ "eof (reading %s)", $wh;
 530 }
 531
 532 sub protocol_expect (&$) {
 533     my ($match, $fh) = @_;
 534     local $_;
 535     $_ = <$fh>;
 536     defined && chomp or badproto_badread $fh, __ "protocol message";
 537     if (wantarray) {
 538         my @r = &$match;
 539         return @r if @r;
 540     } else {
 541         my $r = &$match;
 542         return $r if $r;
 543     }
 544     badproto $fh, f_ "\`%s'", $_;
 545 }
 546
 547 sub protocol_send_file ($$) {
 548     my ($fh, $ourfn) = @_;
 549     open PF, "<", $ourfn or die "$ourfn: $!";
 550     for (;;) {
 551         my $d;
 552         my $got = read PF, $d, 65536;
 553         die "$ourfn: $!" unless defined $got;
 554         last if !$got;
 555         print $fh "data-block ".length($d)."\n" or confess "$!";
 556         print $fh $d or confess "$!";
 557     }
 558     PF->error and die "$ourfn $!";
 559     print $fh "data-end\n" or confess "$!";
 560     close PF;
 561 }
 562
 563 sub protocol_read_bytes ($$) {
 564     my ($fh, $nbytes) = @_;
 565     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, __ "bad byte count";
 566     my $d;
 567     my $got = read $fh, $d, $nbytes;
 568     $got==$nbytes or badproto_badread $fh, __ "data block";
 569     return $d;
 570 }
 571
 572 sub protocol_receive_file ($$) {
 573     my ($fh, $ourfn) = @_;
 574     printdebug "() $ourfn\n";
 575     open PF, ">", $ourfn or die "$ourfn: $!";
 576     for (;;) {
 577         my ($y,$l) = protocol_expect {
 578             m/^data-block (.*)$/ ? (1,$1) :
 579             m/^data-end$/ ? (0,) :
 580             ();
 581         } $fh;
 582         last unless $y;
 583         my $d = protocol_read_bytes $fh, $l;
 584         print PF $d or confess "$!";
 585     }
 586     close PF or confess "$!";
 587 }
 588
 589 #---------- remote protocol support, responder ----------
 590
 591 sub responder_send_command ($) {
 592     my ($command) = @_;
 593     return unless $we_are_responder;
 594     # called even without $we_are_responder
 595     printdebug ">> $command\n";
 596     print PO $command, "\n" or confess "$!";
 597 }
 598
 599 sub responder_send_file ($$) {
 600     my ($keyword, $ourfn) = @_;
 601     return unless $we_are_responder;
 602     printdebug "]] $keyword $ourfn\n";
 603     responder_send_command "file $keyword";
 604     protocol_send_file \*PO, $ourfn;
 605 }
 606
 607 sub responder_receive_files ($@) {
 608     my ($keyword, @ourfns) = @_;
 609     die unless $we_are_responder;
 610     printdebug "[[ $keyword @ourfns\n";
 611     responder_send_command "want $keyword";
 612     foreach my $fn (@ourfns) {
 613         protocol_receive_file \*PI, $fn;
 614     }
 615     printdebug "[[\$\n";
 616     protocol_expect { m/^files-end$/ } \*PI;
 617 }
 618
 619 #---------- remote protocol support, initiator ----------
 620
 621 sub initiator_expect (&) {
 622     my ($match) = @_;
 623     protocol_expect { &$match } \*RO;
 624 }
 625
 626 #---------- end remote code ----------
 627
 628 sub progress {
 629     if ($we_are_responder) {
 630         my $m = join '', @_;
 631         responder_send_command "progress ".length($m) or confess "$!";
 632         print PO $m or confess "$!";
 633     } else {
 634         print @_, "\n";
 635     }
 636 }
 637
 638 our $ua;
 639
 640 sub url_get {
 641     if (!$ua) {
 642         $ua = LWP::UserAgent->new();
 643         $ua->env_proxy;
 644     }
 645     my $what = $_[$#_];
 646     progress "downloading $what...";
 647     my $r = $ua->get(@_) or confess "$!";
 648     return undef if $r->code == 404;
 649     $r->is_success or fail f_ "failed to fetch %s: %s",
 650         $what, $r->status_line;
 651     return $r->decoded_content(charset => 'none');
 652 }
 653
 654 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 655
 656 sub act_local () { return $dryrun_level <= 1; }
 657 sub act_scary () { return !$dryrun_level; }
 658
 659 sub printdone {
 660     if (!$dryrun_level) {
 661         progress f_ "%s ok: %s", $us, "@_";
 662     } else {
 663         progress f_ "would be ok: %s (but dry run only)", "@_";
 664     }
 665 }
 666
 667 sub dryrun_report {
 668     printcmd(\*STDERR,$debugprefix."#",@_);
 669 }
 670
 671 sub runcmd_ordryrun {
 672     if (act_scary()) {
 673         runcmd @_;
 674     } else {
 675         dryrun_report @_;
 676     }
 677 }
 678
 679 sub runcmd_ordryrun_local {
 680     if (act_local()) {
 681         runcmd @_;
 682     } else {
 683         dryrun_report @_;
 684     }
 685 }
 686
 687 our $helpmsg = i_ <<END;
 688 main usages:
 689   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 690   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 691   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 692   dgit [dgit-opts] sbuild [sbuild-opts]
 693   dgit [dgit-opts] pbuilder|cowbuilder [debbuildopts]
 694   dgit [dgit-opts] push [dgit-opts] [suite]
 695   dgit [dgit-opts] push-source [dgit-opts] [suite]
 696   dgit [dgit-opts] rpush build-host:build-dir ...
 697 important dgit options:
 698   -k<keyid>           sign tag and package with <keyid> instead of default
 699   --dry-run -n        do not change anything, but go through the motions
 700   --damp-run -L       like --dry-run but make local changes, without signing
 701   --new -N            allow introducing a new package
 702   --debug -D          increase debug level
 703   -c<name>=<value>    set git config option (used directly by dgit too)
 704 END
 705
 706 our $later_warning_msg = i_ <<END;
 707 Perhaps the upload is stuck in incoming.  Using the version from git.
 708 END
 709
 710 sub badusage {
 711     print STDERR f_ "%s: %s\n%s", $us, "@_", __ $helpmsg or confess "$!";
 712     finish 8;
 713 }
 714
 715 sub nextarg {
 716     @ARGV or badusage __ "too few arguments";
 717     return scalar shift @ARGV;
 718 }
 719
 720 sub pre_help () {
 721     not_necessarily_a_tree();
 722 }
 723 sub cmd_help () {
 724     print __ $helpmsg or confess "$!";
 725     finish 0;
 726 }
 727
 728 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 729
 730 our %defcfg = ('dgit.default.distro' => 'debian',
 731                'dgit.default.default-suite' => 'unstable',
 732                'dgit.default.old-dsc-distro' => 'debian',
 733                'dgit-suite.*-security.distro' => 'debian-security',
 734                'dgit.default.username' => '',
 735                'dgit.default.archive-query-default-component' => 'main',
 736                'dgit.default.ssh' => 'ssh',
 737                'dgit.default.archive-query' => 'madison:',
 738                'dgit.default.sshpsql-dbname' => 'service=projectb',
 739                'dgit.default.aptget-components' => 'main',
 740                'dgit.default.source-only-uploads' => 'ok',
 741                'dgit.dsc-url-proto-ok.http'    => 'true',
 742                'dgit.dsc-url-proto-ok.https'   => 'true',
 743                'dgit.dsc-url-proto-ok.git'     => 'true',
 744                'dgit.vcs-git.suites',          => 'sid', # ;-separated
 745                'dgit.default.dsc-url-proto-ok' => 'false',
 746                # old means "repo server accepts pushes with old dgit tags"
 747                # new means "repo server accepts pushes with new dgit tags"
 748                # maint means "repo server accepts split brain pushes"
 749                # hist means "repo server may have old pushes without new tag"
 750                #   ("hist" is implied by "old")
 751                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 752                'dgit-distro.debian.git-check' => 'url',
 753                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 754                'dgit-distro.debian.new-private-pushers' => 't',
 755                'dgit-distro.debian.source-only-uploads' => 'not-wholly-new',
 756                'dgit-distro.debian/push.git-url' => '',
 757                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 758                'dgit-distro.debian/push.git-user-force' => 'dgit',
 759                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 760                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 761                'dgit-distro.debian/push.git-create' => 'true',
 762                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 763  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 764 # 'dgit-distro.debian.archive-query-tls-key',
 765 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 766 # ^ this does not work because curl is broken nowadays
 767 # Fixing #790093 properly will involve providing providing the key
 768 # in some pacagke and maybe updating these paths.
 769 #
 770 # 'dgit-distro.debian.archive-query-tls-curl-args',
 771 #   '--ca-path=/etc/ssl/ca-debian',
 772 # ^ this is a workaround but works (only) on DSA-administered machines
 773                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 774                'dgit-distro.debian.git-url-suffix' => '',
 775                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 776                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 777  'dgit-distro.debian-security.archive-query' => 'aptget:',
 778  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 779  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 780  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 781  'dgit-distro.debian-security.nominal-distro' => 'debian',
 782  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 783  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 784                'dgit-distro.ubuntu.git-check' => 'false',
 785  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 786                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 787                'dgit-distro.test-dummy.username' => "alice",
 788                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 789                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 790                'dgit-distro.test-dummy.git-url' => "$td/git",
 791                'dgit-distro.test-dummy.git-host' => "git",
 792                'dgit-distro.test-dummy.git-path' => "$td/git",
 793                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 794                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 795                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 796                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 797                );
 798
 799 our %gitcfgs;
 800 our @gitcfgsources = qw(cmdline local global system);
 801 our $invoked_in_git_tree = 1;
 802
 803 sub git_slurp_config () {
 804     # This algoritm is a bit subtle, but this is needed so that for
 805     # options which we want to be single-valued, we allow the
 806     # different config sources to override properly.  See #835858.
 807     foreach my $src (@gitcfgsources) {
 808         next if $src eq 'cmdline';
 809         # we do this ourselves since git doesn't handle it
 810
 811         $gitcfgs{$src} = git_slurp_config_src $src;
 812     }
 813 }
 814
 815 sub git_get_config ($) {
 816     my ($c) = @_;
 817     foreach my $src (@gitcfgsources) {
 818         my $l = $gitcfgs{$src}{$c};
 819         confess "internal error ($l $c)" if $l && !ref $l;
 820         printdebug"C $c ".(defined $l ?
 821                            join " ", map { messagequote "'$_'" } @$l :
 822                            "undef")."\n"
 823             if $debuglevel >= 4;
 824         $l or next;
 825         @$l==1 or badcfg
 826             f_ "multiple values for %s (in %s git config)", $c, $src
 827             if @$l > 1;
 828         $l->[0] =~ m/\n/ and badcfg f_
 829  "value for config option %s (in %s git config) contains newline(s)!",
 830             $c, $src;
 831         return $l->[0];
 832     }
 833     return undef;
 834 }
 835
 836 sub cfg {
 837     foreach my $c (@_) {
 838         return undef if $c =~ /RETURN-UNDEF/;
 839         printdebug "C? $c\n" if $debuglevel >= 5;
 840         my $v = git_get_config($c);
 841         return $v if defined $v;
 842         my $dv = $defcfg{$c};
 843         if (defined $dv) {
 844             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 845             return $dv;
 846         }
 847     }
 848     badcfg f_
 849         "need value for one of: %s\n".
 850         "%s: distro or suite appears not to be (properly) supported",
 851         "@_", $us;
 852 }
 853
 854 sub not_necessarily_a_tree () {
 855     # needs to be called from pre_*
 856     @gitcfgsources = grep { $_ ne 'local' } @gitcfgsources;
 857     $invoked_in_git_tree = 0;
 858 }
 859
 860 sub access_basedistro__noalias () {
 861     if (defined $idistro) {
 862         return $idistro;
 863     } else {
 864         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 865         return $def if defined $def;
 866         foreach my $src (@gitcfgsources, 'internal') {
 867             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 868             next unless $kl;
 869             foreach my $k (keys %$kl) {
 870                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 871                 my $dpat = $1;
 872                 next unless match_glob $dpat, $isuite;
 873                 return $kl->{$k};
 874             }
 875         }
 876         return cfg("dgit.default.distro");
 877     }
 878 }
 879
 880 sub access_basedistro () {
 881     my $noalias = access_basedistro__noalias();
 882     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 883     return $canon // $noalias;
 884 }
 885
 886 sub access_nomdistro () {
 887     my $base = access_basedistro();
 888     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 889     $r =~ m/^$distro_re$/ or badcfg
 890         f_ "bad syntax for (nominal) distro \`%s' (does not match %s)",
 891         $r, "/^$distro_re$/";
 892     return $r;
 893 }
 894
 895 sub access_quirk () {
 896     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 897     my $basedistro = access_basedistro();
 898     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 899                               'RETURN-UNDEF');
 900     if (defined $backports_quirk) {
 901         my $re = $backports_quirk;
 902         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 903         $re =~ s/\*/.*/g;
 904         $re =~ s/\%/([-0-9a-z_]+)/
 905             or $re =~ m/[()]/ or badcfg __ "backports-quirk needs \% or ( )";
 906         if ($isuite =~ m/^$re$/) {
 907             return ('backports',"$basedistro-backports",$1);
 908         }
 909     }
 910     return ('none',undef);
 911 }
 912
 913 our $access_forpush;
 914
 915 sub parse_cfg_bool ($$$) {
 916     my ($what,$def,$v) = @_;
 917     $v //= $def;
 918     return
 919         $v =~ m/^[ty1]/ ? 1 :
 920         $v =~ m/^[fn0]/ ? 0 :
 921         badcfg f_ "%s needs t (true, y, 1) or f (false, n, 0) not \`%s'",
 922             $what, $v;
 923 }
 924
 925 sub access_forpush_config () {
 926     my $d = access_basedistro();
 927
 928     return 1 if
 929         $new_package &&
 930         parse_cfg_bool('new-private-pushers', 0,
 931                        cfg("dgit-distro.$d.new-private-pushers",
 932                            'RETURN-UNDEF'));
 933
 934     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 935     $v //= 'a';
 936     return
 937         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 938         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 939         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 940         badcfg __
 941             "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 942 }
 943
 944 sub access_forpush () {
 945     $access_forpush //= access_forpush_config();
 946     return $access_forpush;
 947 }
 948
 949 sub default_from_access_cfg ($$$;$) {
 950     my ($var, $keybase, $defval, $permit_re) = @_;
 951     return if defined $$var;
 952
 953     $$var = access_cfg("$keybase-newer", 'RETURN-UNDEF');
 954     $$var = undef if $$var && $$var !~ m/^$permit_re$/;
 955
 956     $$var //= access_cfg($keybase, 'RETURN-UNDEF');
 957     $$var //= $defval;
 958
 959     badcfg f_ "unknown %s \`%s'", $keybase, $$var
 960         if defined $permit_re and $$var !~ m/$permit_re/;
 961 }
 962
 963 sub pushing () {
 964     confess +(__ 'internal error').' '.Dumper($access_forpush)," ?" if
 965         defined $access_forpush and !$access_forpush;
 966     badcfg __ "pushing but distro is configured readonly"
 967         if access_forpush_config() eq '0';
 968     $access_forpush = 1;
 969     $supplementary_message = __ <<'END' unless $we_are_responder;
 970 Push failed, before we got started.
 971 You can retry the push, after fixing the problem, if you like.
 972 END
 973     parseopts_late_defaults();
 974 }
 975
 976 sub notpushing () {
 977     parseopts_late_defaults();
 978 }
 979
 980 sub determine_whether_split_brain ($) {
 981     my ($format) = @_;
 982     {
 983         local $access_forpush;
 984         default_from_access_cfg(\$splitview_mode, 'split-view', 'auto',
 985                                 $splitview_modes_re);
 986         $do_split_brain = 1 if $splitview_mode eq 'always';
 987     }
 988
 989     printdebug "format $format, quilt mode $quilt_mode\n";
 990
 991     if (format_quiltmode_splitting $format) {
 992         $splitview_mode ne 'never' or
 993             fail f_ "dgit: quilt mode \`%s' (for format \`%s')".
 994                     " implies split view, but split-view set to \`%s'",
 995                     $quilt_mode, $format, $splitview_mode;
 996         $do_split_brain = 1;
 997     }
 998     $do_split_brain //= 0;
 999 }
1000
1001 sub supplementary_message ($) {
1002     my ($msg) = @_;
1003     if (!$we_are_responder) {
1004         $supplementary_message = $msg;
1005         return;
1006     } else {
1007         responder_send_command "supplementary-message ".length($msg)
1008             or confess "$!";
1009         print PO $msg or confess "$!";
1010     }
1011 }
1012
1013 sub access_distros () {
1014     # Returns list of distros to try, in order
1015     #
1016     # We want to try:
1017     #    0. `instead of' distro name(s) we have been pointed to
1018     #    1. the access_quirk distro, if any
1019     #    2a. the user's specified distro, or failing that  } basedistro
1020     #    2b. the distro calculated from the suite          }
1021     my @l = access_basedistro();
1022
1023     my (undef,$quirkdistro) = access_quirk();
1024     unshift @l, $quirkdistro;
1025     unshift @l, $instead_distro;
1026     @l = grep { defined } @l;
1027
1028     push @l, access_nomdistro();
1029
1030     if (access_forpush()) {
1031         @l = map { ("$_/push", $_) } @l;
1032     }
1033     @l;
1034 }
1035
1036 sub access_cfg_cfgs (@) {
1037     my (@keys) = @_;
1038     my @cfgs;
1039     # The nesting of these loops determines the search order.  We put
1040     # the key loop on the outside so that we search all the distros
1041     # for each key, before going on to the next key.  That means that
1042     # if access_cfg is called with a more specific, and then a less
1043     # specific, key, an earlier distro can override the less specific
1044     # without necessarily overriding any more specific keys.  (If the
1045     # distro wants to override the more specific keys it can simply do
1046     # so; whereas if we did the loop the other way around, it would be
1047     # impossible to for an earlier distro to override a less specific
1048     # key but not the more specific ones without restating the unknown
1049     # values of the more specific keys.
1050     my @realkeys;
1051     my @rundef;
1052     # We have to deal with RETURN-UNDEF specially, so that we don't
1053     # terminate the search prematurely.
1054     foreach (@keys) {
1055         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
1056         push @realkeys, $_
1057     }
1058     foreach my $d (access_distros()) {
1059         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
1060     }
1061     push @cfgs, map { "dgit.default.$_" } @realkeys;
1062     push @cfgs, @rundef;
1063     return @cfgs;
1064 }
1065
1066 sub access_cfg (@) {
1067     my (@keys) = @_;
1068     my (@cfgs) = access_cfg_cfgs(@keys);
1069     my $value = cfg(@cfgs);
1070     return $value;
1071 }
1072
1073 sub access_cfg_bool ($$) {
1074     my ($def, @keys) = @_;
1075     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
1076 }
1077
1078 sub string_to_ssh ($) {
1079     my ($spec) = @_;
1080     if ($spec =~ m/\s/) {
1081         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
1082     } else {
1083         return ($spec);
1084     }
1085 }
1086
1087 sub access_cfg_ssh () {
1088     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
1089     if (!defined $gitssh) {
1090         return @ssh;
1091     } else {
1092         return string_to_ssh $gitssh;
1093     }
1094 }
1095
1096 sub access_runeinfo ($) {
1097     my ($info) = @_;
1098     return ": dgit ".access_basedistro()." $info ;";
1099 }
1100
1101 sub access_someuserhost ($) {
1102     my ($some) = @_;
1103     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
1104     defined($user) && length($user) or
1105         $user = access_cfg("$some-user",'username');
1106     my $host = access_cfg("$some-host");
1107     return length($user) ? "$user\@$host" : $host;
1108 }
1109
1110 sub access_gituserhost () {
1111     return access_someuserhost('git');
1112 }
1113
1114 sub access_giturl (;$) {
1115     my ($optional) = @_;
1116     my $url = access_cfg('git-url','RETURN-UNDEF');
1117     my $suffix;
1118     if (!length $url) {
1119         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
1120         return undef unless defined $proto;
1121         $url =
1122             $proto.
1123             access_gituserhost().
1124             access_cfg('git-path');
1125     } else {
1126         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
1127     }
1128     $suffix //= '.git';
1129     return "$url/$package$suffix";
1130 }
1131
1132 sub commit_getclogp ($) {
1133     # Returns the parsed changelog hashref for a particular commit
1134     my ($objid) = @_;
1135     our %commit_getclogp_memo;
1136     my $memo = $commit_getclogp_memo{$objid};
1137     return $memo if $memo;
1138
1139     my $mclog = dgit_privdir()."clog";
1140     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
1141         "$objid:debian/changelog";
1142     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
1143 }
1144
1145 sub parse_dscdata () {
1146     my $dscfh = new IO::File \$dscdata, '<' or confess "$!";
1147     printdebug Dumper($dscdata) if $debuglevel>1;
1148     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1149     printdebug Dumper($dsc) if $debuglevel>1;
1150 }
1151
1152 our %rmad;
1153
1154 sub archive_query ($;@) {
1155     my ($method) = shift @_;
1156     fail __ "this operation does not support multiple comma-separated suites"
1157         if $isuite =~ m/,/;
1158     my $query = access_cfg('archive-query','RETURN-UNDEF');
1159     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1160     my $proto = $1;
1161     my $data = $'; #';
1162     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1163 }
1164
1165 sub archive_query_prepend_mirror {
1166     my $m = access_cfg('mirror');
1167     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1168 }
1169
1170 sub pool_dsc_subpath ($$) {
1171     my ($vsn,$component) = @_; # $package is implict arg
1172     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1173     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1174 }
1175
1176 sub cfg_apply_map ($$$) {
1177     my ($varref, $what, $mapspec) = @_;
1178     return unless $mapspec;
1179
1180     printdebug "config $what EVAL{ $mapspec; }\n";
1181     $_ = $$varref;
1182     eval "package Dgit::Config; $mapspec;";
1183     die $@ if $@;
1184     $$varref = $_;
1185 }
1186
1187 #---------- `ftpmasterapi' archive query method (nascent) ----------
1188
1189 sub archive_api_query_cmd ($) {
1190     my ($subpath) = @_;
1191     my @cmd = (@curl, qw(-sS));
1192     my $url = access_cfg('archive-query-url');
1193     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1194         my $host = $1;
1195         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1196         foreach my $key (split /\:/, $keys) {
1197             $key =~ s/\%HOST\%/$host/g;
1198             if (!stat $key) {
1199                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1200                 next;
1201             }
1202             fail f_ "config requested specific TLS key but do not know".
1203                     " how to get curl to use exactly that EE key (%s)",
1204                     $key;
1205 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1206 #           # Sadly the above line does not work because of changes
1207 #           # to gnutls.   The real fix for #790093 may involve
1208 #           # new curl options.
1209             last;
1210         }
1211         # Fixing #790093 properly will involve providing a value
1212         # for this on clients.
1213         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1214         push @cmd, split / /, $kargs if defined $kargs;
1215     }
1216     push @cmd, $url.$subpath;
1217     return @cmd;
1218 }
1219
1220 sub api_query ($$;$) {
1221     use JSON;
1222     my ($data, $subpath, $ok404) = @_;
1223     badcfg __ "ftpmasterapi archive query method takes no data part"
1224         if length $data;
1225     my @cmd = archive_api_query_cmd($subpath);
1226     my $url = $cmd[$#cmd];
1227     push @cmd, qw(-w %{http_code});
1228     my $json = cmdoutput @cmd;
1229     unless ($json =~ s/\d+\d+\d$//) {
1230         failedcmd_report_cmd undef, @cmd;
1231         fail __ "curl failed to print 3-digit HTTP code";
1232     }
1233     my $code = $&;
1234     return undef if $code eq '404' && $ok404;
1235     fail f_ "fetch of %s gave HTTP code %s", $url, $code
1236         unless $url =~ m#^file://# or $code =~ m/^2/;
1237     return decode_json($json);
1238 }
1239
1240 sub canonicalise_suite_ftpmasterapi {
1241     my ($proto,$data) = @_;
1242     my $suites = api_query($data, 'suites');
1243     my @matched;
1244     foreach my $entry (@$suites) {
1245         next unless grep {
1246             my $v = $entry->{$_};
1247             defined $v && $v eq $isuite;
1248         } qw(codename name);
1249         push @matched, $entry;
1250     }
1251     fail f_ "unknown suite %s, maybe -d would help", $isuite
1252         unless @matched;
1253     my $cn;
1254     eval {
1255         @matched==1 or die f_ "multiple matches for suite %s\n", $isuite;
1256         $cn = "$matched[0]{codename}";
1257         defined $cn or die f_ "suite %s info has no codename\n", $isuite;
1258         $cn =~ m/^$suite_re$/
1259             or die f_ "suite %s maps to bad codename\n", $isuite;
1260     };
1261     die +(__ "bad ftpmaster api response: ")."$@\n".Dumper(\@matched)
1262         if length $@;
1263     return $cn;
1264 }
1265
1266 sub archive_query_ftpmasterapi {
1267     my ($proto,$data) = @_;
1268     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1269     my @rows;
1270     my $digester = Digest::SHA->new(256);
1271     foreach my $entry (@$info) {
1272         eval {
1273             my $vsn = "$entry->{version}";
1274             my ($ok,$msg) = version_check $vsn;
1275             die f_ "bad version: %s\n", $msg unless $ok;
1276             my $component = "$entry->{component}";
1277             $component =~ m/^$component_re$/ or die __ "bad component";
1278             my $filename = "$entry->{filename}";
1279             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1280                 or die __ "bad filename";
1281             my $sha256sum = "$entry->{sha256sum}";
1282             $sha256sum =~ m/^[0-9a-f]+$/ or die __ "bad sha256sum";
1283             push @rows, [ $vsn, "/pool/$component/$filename",
1284                           $digester, $sha256sum ];
1285         };
1286         die +(__ "bad ftpmaster api response: ")."$@\n".Dumper($entry)
1287             if length $@;
1288     }
1289     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1290     return archive_query_prepend_mirror @rows;
1291 }
1292
1293 sub file_in_archive_ftpmasterapi {
1294     my ($proto,$data,$filename) = @_;
1295     my $pat = $filename;
1296     $pat =~ s/_/\\_/g;
1297     $pat = "%/$pat";
1298     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1299     my $info = api_query($data, "file_in_archive/$pat", 1);
1300 }
1301
1302 sub package_not_wholly_new_ftpmasterapi {
1303     my ($proto,$data,$pkg) = @_;
1304     my $info = api_query($data,"madison?package=${pkg}&f=json");
1305     return !!@$info;
1306 }
1307
1308 #---------- `aptget' archive query method ----------
1309
1310 our $aptget_base;
1311 our $aptget_releasefile;
1312 our $aptget_configpath;
1313
1314 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1315 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1316
1317 sub aptget_cache_clean {
1318     runcmd_ordryrun_local qw(sh -ec),
1319         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1320         'x', $aptget_base;
1321 }
1322
1323 sub aptget_lock_acquire () {
1324     my $lockfile = "$aptget_base/lock";
1325     open APTGET_LOCK, '>', $lockfile or confess "open $lockfile: $!";
1326     flock APTGET_LOCK, LOCK_EX or confess "lock $lockfile: $!";
1327 }
1328
1329 sub aptget_prep ($) {
1330     my ($data) = @_;
1331     return if defined $aptget_base;
1332
1333     badcfg __ "aptget archive query method takes no data part"
1334         if length $data;
1335
1336     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1337
1338     ensuredir $cache;
1339     ensuredir "$cache/dgit";
1340     my $cachekey =
1341         access_cfg('aptget-cachekey','RETURN-UNDEF')
1342         // access_nomdistro();
1343
1344     $aptget_base = "$cache/dgit/aptget";
1345     ensuredir $aptget_base;
1346
1347     my $quoted_base = $aptget_base;
1348     confess "$quoted_base contains bad chars, cannot continue"
1349         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1350
1351     ensuredir $aptget_base;
1352
1353     aptget_lock_acquire();
1354
1355     aptget_cache_clean();
1356
1357     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1358     my $sourceslist = "source.list#$cachekey";
1359
1360     my $aptsuites = $isuite;
1361     cfg_apply_map(\$aptsuites, 'suite map',
1362                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1363
1364     open SRCS, ">", "$aptget_base/$sourceslist" or confess "$!";
1365     printf SRCS "deb-src %s %s %s\n",
1366         access_cfg('mirror'),
1367         $aptsuites,
1368         access_cfg('aptget-components')
1369         or confess "$!";
1370
1371     ensuredir "$aptget_base/cache";
1372     ensuredir "$aptget_base/lists";
1373
1374     open CONF, ">", $aptget_configpath or confess "$!";
1375     print CONF <<END;
1376 Debug::NoLocking "true";
1377 APT::Get::List-Cleanup "false";
1378 #clear APT::Update::Post-Invoke-Success;
1379 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1380 Dir::State::Lists "$quoted_base/lists";
1381 Dir::Etc::preferences "$quoted_base/preferences";
1382 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1383 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1384 END
1385
1386     foreach my $key (qw(
1387                         Dir::Cache
1388                         Dir::State
1389                         Dir::Cache::Archives
1390                         Dir::Etc::SourceParts
1391                         Dir::Etc::preferencesparts
1392                       )) {
1393         ensuredir "$aptget_base/$key";
1394         print CONF "$key \"$quoted_base/$key\";\n" or confess "$!";
1395     };
1396
1397     my $oldatime = (time // confess "$!") - 1;
1398     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1399         next unless stat_exists $oldlist;
1400         my ($mtime) = (stat _)[9];
1401         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1402     }
1403
1404     runcmd_ordryrun_local aptget_aptget(), qw(update);
1405
1406     my @releasefiles;
1407     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1408         next unless stat_exists $oldlist;
1409         my ($atime) = (stat _)[8];
1410         next if $atime == $oldatime;
1411         push @releasefiles, $oldlist;
1412     }
1413     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1414     @releasefiles = @inreleasefiles if @inreleasefiles;
1415     if (!@releasefiles) {
1416         fail f_ <<END, $isuite, $cache;
1417 apt seemed to not to update dgit's cached Release files for %s.
1418 (Perhaps %s
1419  is on a filesystem mounted `noatime'; if so, please use `relatime'.)
1420 END
1421     }
1422     confess "apt updated too many Release files (@releasefiles), erk"
1423         unless @releasefiles == 1;
1424
1425     ($aptget_releasefile) = @releasefiles;
1426 }
1427
1428 sub canonicalise_suite_aptget {
1429     my ($proto,$data) = @_;
1430     aptget_prep($data);
1431
1432     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1433
1434     foreach my $name (qw(Codename Suite)) {
1435         my $val = $release->{$name};
1436         if (defined $val) {
1437             printdebug "release file $name: $val\n";
1438             $val =~ m/^$suite_re$/o or fail f_
1439                 "Release file (%s) specifies intolerable %s",
1440                 $aptget_releasefile, $name;
1441             cfg_apply_map(\$val, 'suite rmap',
1442                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1443             return $val
1444         }
1445     }
1446     return $isuite;
1447 }
1448
1449 sub archive_query_aptget {
1450     my ($proto,$data) = @_;
1451     aptget_prep($data);
1452
1453     ensuredir "$aptget_base/source";
1454     foreach my $old (<$aptget_base/source/*.dsc>) {
1455         unlink $old or die "$old: $!";
1456     }
1457
1458     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1459     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1460     # avoids apt-get source failing with ambiguous error code
1461
1462     runcmd_ordryrun_local
1463         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1464         aptget_aptget(), qw(--download-only --only-source source), $package;
1465
1466     my @dscs = <$aptget_base/source/*.dsc>;
1467     fail __ "apt-get source did not produce a .dsc" unless @dscs;
1468     fail f_ "apt-get source produced several .dscs (%s)", "@dscs"
1469         unless @dscs==1;
1470
1471     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1472
1473     use URI::Escape;
1474     my $uri = "file://". uri_escape $dscs[0];
1475     $uri =~ s{\%2f}{/}gi;
1476     return [ (getfield $pre_dsc, 'Version'), $uri ];
1477 }
1478
1479 sub file_in_archive_aptget () { return undef; }
1480 sub package_not_wholly_new_aptget () { return undef; }
1481
1482 #---------- `dummyapicat' archive query method ----------
1483 # (untranslated, because this is for testing purposes etc.)
1484
1485 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1486 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1487
1488 sub dummycatapi_run_in_mirror ($@) {
1489     # runs $fn with FIA open onto rune
1490     my ($rune, $argl, $fn) = @_;
1491
1492     my $mirror = access_cfg('mirror');
1493     $mirror =~ s#^file://#/# or die "$mirror ?";
1494     my @cmd = (qw(sh -ec), 'cd "$1"; shift'."\n".$rune,
1495                qw(x), $mirror, @$argl);
1496     debugcmd "-|", @cmd;
1497     open FIA, "-|", @cmd or confess "$!";
1498     my $r = $fn->();
1499     close FIA or ($!==0 && $?==141) or die failedcmd @cmd;
1500     return $r;
1501 }
1502
1503 sub file_in_archive_dummycatapi ($$$) {
1504     my ($proto,$data,$filename) = @_;
1505     my @out;
1506     dummycatapi_run_in_mirror '
1507             find -name "$1" -print0 |
1508             xargs -0r sha256sum
1509     ', [$filename], sub {
1510         while (<FIA>) {
1511             chomp or die;
1512             printdebug "| $_\n";
1513             m/^(\w+)  (\S+)$/ or die "$_ ?";
1514             push @out, { sha256sum => $1, filename => $2 };
1515         }
1516     };
1517     return \@out;
1518 }
1519
1520 sub package_not_wholly_new_dummycatapi {
1521     my ($proto,$data,$pkg) = @_;
1522     dummycatapi_run_in_mirror "
1523             find -name ${pkg}_*.dsc
1524     ", [], sub {
1525         local $/ = undef;
1526         !!<FIA>;
1527     };
1528 }
1529
1530 #---------- `madison' archive query method ----------
1531
1532 sub archive_query_madison {
1533     return archive_query_prepend_mirror
1534         map { [ @$_[0..1] ] } madison_get_parse(@_);
1535 }
1536
1537 sub madison_get_parse {
1538     my ($proto,$data) = @_;
1539     die unless $proto eq 'madison';
1540     if (!length $data) {
1541         $data= access_cfg('madison-distro','RETURN-UNDEF');
1542         $data //= access_basedistro();
1543     }
1544     $rmad{$proto,$data,$package} ||= cmdoutput
1545         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1546     my $rmad = $rmad{$proto,$data,$package};
1547
1548     my @out;
1549     foreach my $l (split /\n/, $rmad) {
1550         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1551                   \s*( [^ \t|]+ )\s* \|
1552                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1553                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1554         $1 eq $package or die "$rmad $package ?";
1555         my $vsn = $2;
1556         my $newsuite = $3;
1557         my $component;
1558         if (defined $4) {
1559             $component = $4;
1560         } else {
1561             $component = access_cfg('archive-query-default-component');
1562         }
1563         $5 eq 'source' or die "$rmad ?";
1564         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1565     }
1566     return sort { -version_compare($a->[0],$b->[0]); } @out;
1567 }
1568
1569 sub canonicalise_suite_madison {
1570     # madison canonicalises for us
1571     my @r = madison_get_parse(@_);
1572     @r or fail f_
1573         "unable to canonicalise suite using package %s".
1574         " which does not appear to exist in suite %s;".
1575         " --existing-package may help",
1576         $package, $isuite;
1577     return $r[0][2];
1578 }
1579
1580 sub file_in_archive_madison { return undef; }
1581 sub package_not_wholly_new_madison { return undef; }
1582
1583 #---------- `sshpsql' archive query method ----------
1584 # (untranslated, because this is obsolete)
1585
1586 sub sshpsql ($$$) {
1587     my ($data,$runeinfo,$sql) = @_;
1588     if (!length $data) {
1589         $data= access_someuserhost('sshpsql').':'.
1590             access_cfg('sshpsql-dbname');
1591     }
1592     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1593     my ($userhost,$dbname) = ($`,$'); #';
1594     my @rows;
1595     my @cmd = (access_cfg_ssh, $userhost,
1596                access_runeinfo("ssh-psql $runeinfo").
1597                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1598                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1599     debugcmd "|",@cmd;
1600     open P, "-|", @cmd or confess "$!";
1601     while (<P>) {
1602         chomp or die;
1603         printdebug(">|$_|\n");
1604         push @rows, $_;
1605     }
1606     $!=0; $?=0; close P or failedcmd @cmd;
1607     @rows or die;
1608     my $nrows = pop @rows;
1609     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1610     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1611     @rows = map { [ split /\|/, $_ ] } @rows;
1612     my $ncols = scalar @{ shift @rows };
1613     die if grep { scalar @$_ != $ncols } @rows;
1614     return @rows;
1615 }
1616
1617 sub sql_injection_check {
1618     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1619 }
1620
1621 sub archive_query_sshpsql ($$) {
1622     my ($proto,$data) = @_;
1623     sql_injection_check $isuite, $package;
1624     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1625         SELECT source.version, component.name, files.filename, files.sha256sum
1626           FROM source
1627           JOIN src_associations ON source.id = src_associations.source
1628           JOIN suite ON suite.id = src_associations.suite
1629           JOIN dsc_files ON dsc_files.source = source.id
1630           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1631           JOIN component ON component.id = files_archive_map.component_id
1632           JOIN files ON files.id = dsc_files.file
1633          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1634            AND source.source='$package'
1635            AND files.filename LIKE '%.dsc';
1636 END
1637     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1638     my $digester = Digest::SHA->new(256);
1639     @rows = map {
1640         my ($vsn,$component,$filename,$sha256sum) = @$_;
1641         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1642     } @rows;
1643     return archive_query_prepend_mirror @rows;
1644 }
1645
1646 sub canonicalise_suite_sshpsql ($$) {
1647     my ($proto,$data) = @_;
1648     sql_injection_check $isuite;
1649     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1650         SELECT suite.codename
1651           FROM suite where suite_name='$isuite' or codename='$isuite';
1652 END
1653     @rows = map { $_->[0] } @rows;
1654     fail "unknown suite $isuite" unless @rows;
1655     die "ambiguous $isuite: @rows ?" if @rows>1;
1656     return $rows[0];
1657 }
1658
1659 sub file_in_archive_sshpsql ($$$) { return undef; }
1660 sub package_not_wholly_new_sshpsql ($$$) { return undef; }
1661
1662 #---------- `dummycat' archive query method ----------
1663 # (untranslated, because this is for testing purposes etc.)
1664
1665 sub canonicalise_suite_dummycat ($$) {
1666     my ($proto,$data) = @_;
1667     my $dpath = "$data/suite.$isuite";
1668     if (!open C, "<", $dpath) {
1669         $!==ENOENT or die "$dpath: $!";
1670         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1671         return $isuite;
1672     }
1673     $!=0; $_ = <C>;
1674     chomp or die "$dpath: $!";
1675     close C;
1676     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1677     return $_;
1678 }
1679
1680 sub archive_query_dummycat ($$) {
1681     my ($proto,$data) = @_;
1682     canonicalise_suite();
1683     my $dpath = "$data/package.$csuite.$package";
1684     if (!open C, "<", $dpath) {
1685         $!==ENOENT or die "$dpath: $!";
1686         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1687         return ();
1688     }
1689     my @rows;
1690     while (<C>) {
1691         next if m/^\#/;
1692         next unless m/\S/;
1693         die unless chomp;
1694         printdebug "dummycat query $csuite $package $dpath | $_\n";
1695         my @row = split /\s+/, $_;
1696         @row==2 or die "$dpath: $_ ?";
1697         push @rows, \@row;
1698     }
1699     C->error and die "$dpath: $!";
1700     close C;
1701     return archive_query_prepend_mirror
1702         sort { -version_compare($a->[0],$b->[0]); } @rows;
1703 }
1704
1705 sub file_in_archive_dummycat () { return undef; }
1706 sub package_not_wholly_new_dummycat () { return undef; }
1707
1708 #---------- archive query entrypoints and rest of program ----------
1709
1710 sub canonicalise_suite () {
1711     return if defined $csuite;
1712     fail f_ "cannot operate on %s suite", $isuite if $isuite eq 'UNRELEASED';
1713     $csuite = archive_query('canonicalise_suite');
1714     if ($isuite ne $csuite) {
1715         progress f_ "canonical suite name for %s is %s", $isuite, $csuite;
1716     } else {
1717         progress f_ "canonical suite name is %s", $csuite;
1718     }
1719 }
1720
1721 sub get_archive_dsc () {
1722     canonicalise_suite();
1723     my @vsns = archive_query('archive_query');
1724     foreach my $vinfo (@vsns) {
1725         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1726         $dscurl = $vsn_dscurl;
1727         $dscdata = url_get($dscurl);
1728         if (!$dscdata) {
1729             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1730             next;
1731         }
1732         if ($digester) {
1733             $digester->reset();
1734             $digester->add($dscdata);
1735             my $got = $digester->hexdigest();
1736             $got eq $digest or
1737                 fail f_ "%s has hash %s but archive told us to expect %s",
1738                         $dscurl, $got, $digest;
1739         }
1740         parse_dscdata();
1741         my $fmt = getfield $dsc, 'Format';
1742         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1743             f_ "unsupported source format %s, sorry", $fmt;
1744
1745         $dsc_checked = !!$digester;
1746         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1747         return;
1748     }
1749     $dsc = undef;
1750     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1751 }
1752
1753 sub check_for_git ();
1754 sub check_for_git () {
1755     # returns 0 or 1
1756     my $how = access_cfg('git-check');
1757     if ($how eq 'ssh-cmd') {
1758         my @cmd =
1759             (access_cfg_ssh, access_gituserhost(),
1760              access_runeinfo("git-check $package").
1761              " set -e; cd ".access_cfg('git-path').";".
1762              " if test -d $package.git; then echo 1; else echo 0; fi");
1763         my $r= cmdoutput @cmd;
1764         if (defined $r and $r =~ m/^divert (\w+)$/) {
1765             my $divert=$1;
1766             my ($usedistro,) = access_distros();
1767             # NB that if we are pushing, $usedistro will be $distro/push
1768             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1769             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1770             progress f_ "diverting to %s (using config for %s)",
1771                         $divert, $instead_distro;
1772             return check_for_git();
1773         }
1774         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1775         return $r+0;
1776     } elsif ($how eq 'url') {
1777         my $prefix = access_cfg('git-check-url','git-url');
1778         my $suffix = access_cfg('git-check-suffix','git-suffix',
1779                                 'RETURN-UNDEF') // '.git';
1780         my $url = "$prefix/$package$suffix";
1781         my @cmd = (@curl, qw(-sS -I), $url);
1782         my $result = cmdoutput @cmd;
1783         $result =~ s/^\S+ 200 .*\n\r?\n//;
1784         # curl -sS -I with https_proxy prints
1785         # HTTP/1.0 200 Connection established
1786         $result =~ m/^\S+ (404|200) /s or
1787             fail +(__ "unexpected results from git check query - ").
1788                 Dumper($prefix, $result);
1789         my $code = $1;
1790         if ($code eq '404') {
1791             return 0;
1792         } elsif ($code eq '200') {
1793             return 1;
1794         } else {
1795             die;
1796         }
1797     } elsif ($how eq 'true') {
1798         return 1;
1799     } elsif ($how eq 'false') {
1800         return 0;
1801     } else {
1802         badcfg f_ "unknown git-check \`%s'", $how;
1803     }
1804 }
1805
1806 sub create_remote_git_repo () {
1807     my $how = access_cfg('git-create');
1808     if ($how eq 'ssh-cmd') {
1809         runcmd_ordryrun
1810             (access_cfg_ssh, access_gituserhost(),
1811              access_runeinfo("git-create $package").
1812              "set -e; cd ".access_cfg('git-path').";".
1813              " cp -a _template $package.git");
1814     } elsif ($how eq 'true') {
1815         # nothing to do
1816     } else {
1817         badcfg f_ "unknown git-create \`%s'", $how;
1818     }
1819 }
1820
1821 our ($dsc_hash,$lastpush_mergeinput);
1822 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1823
1824
1825 sub prep_ud () {
1826     dgit_privdir(); # ensures that $dgit_privdir_made is based on $maindir
1827     $playground = fresh_playground 'dgit/unpack';
1828 }
1829
1830 sub mktree_in_ud_here () {
1831     playtree_setup $gitcfgs{local};
1832 }
1833
1834 sub git_write_tree () {
1835     my $tree = cmdoutput @git, qw(write-tree);
1836     $tree =~ m/^\w+$/ or die "$tree ?";
1837     return $tree;
1838 }
1839
1840 sub git_add_write_tree () {
1841     runcmd @git, qw(add -Af .);
1842     return git_write_tree();
1843 }
1844
1845 sub remove_stray_gits ($) {
1846     my ($what) = @_;
1847     my @gitscmd = qw(find -name .git -prune -print0);
1848     debugcmd "|",@gitscmd;
1849     open GITS, "-|", @gitscmd or confess "$!";
1850     {
1851         local $/="\0";
1852         while (<GITS>) {
1853             chomp or die;
1854             print STDERR f_ "%s: warning: removing from %s: %s\n",
1855                 $us, $what, (messagequote $_);
1856             rmtree $_;
1857         }
1858     }
1859     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1860 }
1861
1862 sub mktree_in_ud_from_only_subdir ($;$) {
1863     my ($what,$raw) = @_;
1864     # changes into the subdir
1865
1866     my (@dirs) = <*/.>;
1867     confess "expected one subdir but found @dirs ?" unless @dirs==1;
1868     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1869     my $dir = $1;
1870     changedir $dir;
1871
1872     remove_stray_gits($what);
1873     mktree_in_ud_here();
1874     if (!$raw) {
1875         my ($format, $fopts) = get_source_format();
1876         if (madformat($format)) {
1877             rmtree '.pc';
1878         }
1879     }
1880
1881     my $tree=git_add_write_tree();
1882     return ($tree,$dir);
1883 }
1884
1885 our @files_csum_info_fields =
1886     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1887      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1888      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1889
1890 sub dsc_files_info () {
1891     foreach my $csumi (@files_csum_info_fields) {
1892         my ($fname, $module, $method) = @$csumi;
1893         my $field = $dsc->{$fname};
1894         next unless defined $field;
1895         eval "use $module; 1;" or die $@;
1896         my @out;
1897         foreach (split /\n/, $field) {
1898             next unless m/\S/;
1899             m/^(\w+) (\d+) (\S+)$/ or
1900                 fail f_ "could not parse .dsc %s line \`%s'", $fname, $_;
1901             my $digester = eval "$module"."->$method;" or die $@;
1902             push @out, {
1903                 Hash => $1,
1904                 Bytes => $2,
1905                 Filename => $3,
1906                 Digester => $digester,
1907             };
1908         }
1909         return @out;
1910     }
1911     fail f_ "missing any supported Checksums-* or Files field in %s",
1912             $dsc->get_option('name');
1913 }
1914
1915 sub dsc_files () {
1916     map { $_->{Filename} } dsc_files_info();
1917 }
1918
1919 sub files_compare_inputs (@) {
1920     my $inputs = \@_;
1921     my %record;
1922     my %fchecked;
1923
1924     my $showinputs = sub {
1925         return join "; ", map { $_->get_option('name') } @$inputs;
1926     };
1927
1928     foreach my $in (@$inputs) {
1929         my $expected_files;
1930         my $in_name = $in->get_option('name');
1931
1932         printdebug "files_compare_inputs $in_name\n";
1933
1934         foreach my $csumi (@files_csum_info_fields) {
1935             my ($fname) = @$csumi;
1936             printdebug "files_compare_inputs $in_name $fname\n";
1937
1938             my $field = $in->{$fname};
1939             next unless defined $field;
1940
1941             my @files;
1942             foreach (split /\n/, $field) {
1943                 next unless m/\S/;
1944
1945                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1946                     fail "could not parse $in_name $fname line \`$_'";
1947
1948                 printdebug "files_compare_inputs $in_name $fname $f\n";
1949
1950                 push @files, $f;
1951
1952                 my $re = \ $record{$f}{$fname};
1953                 if (defined $$re) {
1954                     $fchecked{$f}{$in_name} = 1;
1955                     $$re eq $info or
1956                         fail f_
1957               "hash or size of %s varies in %s fields (between: %s)",
1958                                  $f, $fname, $showinputs->();
1959                 } else {
1960                     $$re = $info;
1961                 }
1962             }
1963             @files = sort @files;
1964             $expected_files //= \@files;
1965             "@$expected_files" eq "@files" or
1966                 fail f_ "file list in %s varies between hash fields!",
1967                         $in_name;
1968         }
1969         $expected_files or
1970             fail f_ "%s has no files list field(s)", $in_name;
1971     }
1972     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1973         if $debuglevel>=2;
1974
1975     grep { keys %$_ == @$inputs-1 } values %fchecked
1976         or fail f_ "no file appears in all file lists (looked in: %s)",
1977                    $showinputs->();
1978 }
1979
1980 sub is_orig_file_in_dsc ($$) {
1981     my ($f, $dsc_files_info) = @_;
1982     return 0 if @$dsc_files_info <= 1;
1983     # One file means no origs, and the filename doesn't have a "what
1984     # part of dsc" component.  (Consider versions ending `.orig'.)
1985     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1986     return 1;
1987 }
1988
1989 # This function determines whether a .changes file is source-only from
1990 # the point of view of dak.  Thus, it permits *_source.buildinfo
1991 # files.
1992 #
1993 # It does not, however, permit any other buildinfo files.  After a
1994 # source-only upload, the buildds will try to upload files like
1995 # foo_1.2.3_amd64.buildinfo.  If the package maintainer included files
1996 # named like this in their (otherwise) source-only upload, the uploads
1997 # of the buildd can be rejected by dak.  Fixing the resultant
1998 # situation can require manual intervention.  So we block such
1999 # .buildinfo files when the user tells us to perform a source-only
2000 # upload (such as when using the push-source subcommand with the -C
2001 # option, which calls this function).
2002 #
2003 # Note, though, that when dgit is told to prepare a source-only
2004 # upload, such as when subcommands like build-source and push-source
2005 # without -C are used, dgit has a more restrictive notion of
2006 # source-only .changes than dak: such uploads will never include
2007 # *_source.buildinfo files.  This is because there is no use for such
2008 # files when using a tool like dgit to produce the source package, as
2009 # dgit ensures the source is identical to git HEAD.
2010 sub test_source_only_changes ($) {
2011     my ($changes) = @_;
2012     foreach my $l (split /\n/, getfield $changes, 'Files') {
2013         $l =~ m/\S+$/ or next;
2014         # \.tar\.[a-z0-9]+ covers orig.tar and the tarballs in native packages
2015         unless ($& =~ m/(?:\.dsc|\.diff\.gz|\.tar\.[a-z0-9]+|_source\.buildinfo)$/) {
2016             print f_ "purportedly source-only changes polluted by %s\n", $&;
2017             return 0;
2018         }
2019     }
2020     return 1;
2021 }
2022
2023 sub changes_update_origs_from_dsc ($$$$) {
2024     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
2025     my %changes_f;
2026     printdebug "checking origs needed ($upstreamvsn)...\n";
2027     $_ = getfield $changes, 'Files';
2028     m/^\w+ \d+ (\S+ \S+) \S+$/m or
2029         fail __ "cannot find section/priority from .changes Files field";
2030     my $placementinfo = $1;
2031     my %changed;
2032     printdebug "checking origs needed placement '$placementinfo'...\n";
2033     foreach my $l (split /\n/, getfield $dsc, 'Files') {
2034         $l =~ m/\S+$/ or next;
2035         my $file = $&;
2036         printdebug "origs $file | $l\n";
2037         next unless is_orig_file_of_vsn $file, $upstreamvsn;
2038         printdebug "origs $file is_orig\n";
2039         my $have = archive_query('file_in_archive', $file);
2040         if (!defined $have) {
2041             print STDERR __ <<END;
2042 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
2043 END
2044             return;
2045         }
2046         my $found_same = 0;
2047         my @found_differ;
2048         printdebug "origs $file \$#\$have=$#$have\n";
2049         foreach my $h (@$have) {
2050             my $same = 0;
2051             my @differ;
2052             foreach my $csumi (@files_csum_info_fields) {
2053                 my ($fname, $module, $method, $archivefield) = @$csumi;
2054                 next unless defined $h->{$archivefield};
2055                 $_ = $dsc->{$fname};
2056                 next unless defined;
2057                 m/^(\w+) .* \Q$file\E$/m or
2058                     fail f_ ".dsc %s missing entry for %s", $fname, $file;
2059                 if ($h->{$archivefield} eq $1) {
2060                     $same++;
2061                 } else {
2062                     push @differ, f_
2063                         "%s: %s (archive) != %s (local .dsc)",
2064                         $archivefield, $h->{$archivefield}, $1;
2065                 }
2066             }
2067             confess "$file ".Dumper($h)." ?!" if $same && @differ;
2068             $found_same++
2069                 if $same;
2070             push @found_differ,
2071                 f_ "archive %s: %s", $h->{filename}, join "; ", @differ
2072                 if @differ;
2073         }
2074         printdebug "origs $file f.same=$found_same".
2075             " #f._differ=$#found_differ\n";
2076         if (@found_differ && !$found_same) {
2077             fail join "\n",
2078                 (f_ "archive contains %s with different checksum", $file),
2079                 @found_differ;
2080         }
2081         # Now we edit the changes file to add or remove it
2082         foreach my $csumi (@files_csum_info_fields) {
2083             my ($fname, $module, $method, $archivefield) = @$csumi;
2084             next unless defined $changes->{$fname};
2085             if ($found_same) {
2086                 # in archive, delete from .changes if it's there
2087                 $changed{$file} = "removed" if
2088                     $changes->{$fname} =~ s/\n.* \Q$file\E$(?:)$//m;
2089             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)$/m) {
2090                 # not in archive, but it's here in the .changes
2091             } else {
2092                 my $dsc_data = getfield $dsc, $fname;
2093                 $dsc_data =~ m/^(.* \Q$file\E$)$/m or die "$dsc_data $file ?";
2094                 my $extra = $1;
2095                 $extra =~ s/ \d+ /$&$placementinfo /
2096                     or confess "$fname $extra >$dsc_data< ?"
2097                     if $fname eq 'Files';
2098                 $changes->{$fname} .= "\n". $extra;
2099                 $changed{$file} = "added";
2100             }
2101         }
2102     }
2103     if (%changed) {
2104         foreach my $file (keys %changed) {
2105             progress f_
2106                 "edited .changes for archive .orig contents: %s %s",
2107                 $changed{$file}, $file;
2108         }
2109         my $chtmp = "$changesfile.tmp";
2110         $changes->save($chtmp);
2111         if (act_local()) {
2112             rename $chtmp,$changesfile or die "$changesfile $!";
2113         } else {
2114             progress f_ "[new .changes left in %s]", $changesfile;
2115         }
2116     } else {
2117         progress f_ "%s already has appropriate .orig(s) (if any)",
2118                     $changesfile;
2119     }
2120 }
2121
2122 sub clogp_authline ($) {
2123     my ($clogp) = @_;
2124     my $author = getfield $clogp, 'Maintainer';
2125     if ($author =~ m/^[^"\@]+\,/) {
2126         # single entry Maintainer field with unquoted comma
2127         $author = ($& =~ y/,//rd).$'; # strip the comma
2128     }
2129     # git wants a single author; any remaining commas in $author
2130     # are by now preceded by @ (or ").  It seems safer to punt on
2131     # "..." for now rather than attempting to dequote or something.
2132     $author =~ s#,.*##ms unless $author =~ m/"/;
2133     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
2134     my $authline = "$author $date";
2135     $authline =~ m/$git_authline_re/o or
2136         fail f_ "unexpected commit author line format \`%s'".
2137                 " (was generated from changelog Maintainer field)",
2138                 $authline;
2139     return ($1,$2,$3) if wantarray;
2140     return $authline;
2141 }
2142
2143 sub vendor_patches_distro ($$) {
2144     my ($checkdistro, $what) = @_;
2145     return unless defined $checkdistro;
2146
2147     my $series = "debian/patches/\L$checkdistro\E.series";
2148     printdebug "checking for vendor-specific $series ($what)\n";
2149
2150     if (!open SERIES, "<", $series) {
2151         confess "$series $!" unless $!==ENOENT;
2152         return;
2153     }
2154     while (<SERIES>) {
2155         next unless m/\S/;
2156         next if m/^\s+\#/;
2157
2158         print STDERR __ <<END;
2159
2160 Unfortunately, this source package uses a feature of dpkg-source where
2161 the same source package unpacks to different source code on different
2162 distros.  dgit cannot safely operate on such packages on affected
2163 distros, because the meaning of source packages is not stable.
2164
2165 Please ask the distro/maintainer to remove the distro-specific series
2166 files and use a different technique (if necessary, uploading actually
2167 different packages, if different distros are supposed to have
2168 different code).
2169
2170 END
2171         fail f_ "Found active distro-specific series file for".
2172                 " %s (%s): %s, cannot continue",
2173                 $checkdistro, $what, $series;
2174     }
2175     die "$series $!" if SERIES->error;
2176     close SERIES;
2177 }
2178
2179 sub check_for_vendor_patches () {
2180     # This dpkg-source feature doesn't seem to be documented anywhere!
2181     # But it can be found in the changelog (reformatted):
2182
2183     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2184     #   Author: Raphael Hertzog <hertzog@debian.org>
2185     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2186
2187     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2188     #   series files
2189     #
2190     #   If you have debian/patches/ubuntu.series and you were
2191     #   unpacking the source package on ubuntu, quilt was still
2192     #   directed to debian/patches/series instead of
2193     #   debian/patches/ubuntu.series.
2194     #
2195     #   debian/changelog                        |    3 +++
2196     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2197     #   2 files changed, 6 insertions(+), 1 deletion(-)
2198
2199     use Dpkg::Vendor;
2200     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2201     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2202                           __ "Dpkg::Vendor \`current vendor'");
2203     vendor_patches_distro(access_basedistro(),
2204                           __ "(base) distro being accessed");
2205     vendor_patches_distro(access_nomdistro(),
2206                           __ "(nominal) distro being accessed");
2207 }
2208
2209 sub check_bpd_exists () {
2210     stat $buildproductsdir
2211         or fail f_ "build-products-dir %s is not accessible: %s\n",
2212         $buildproductsdir, $!;
2213 }
2214
2215 sub dotdot_bpd_transfer_origs ($$$) {
2216     my ($bpd_abs, $upstreamversion, $wanted) = @_;
2217     # checks is_orig_file_of_vsn and if
2218     # calls $wanted->{$leaf} and expects boolish
2219
2220     return if $buildproductsdir eq '..';
2221
2222     my $warned;
2223     my $dotdot = $maindir;
2224     $dotdot =~ s{/[^/]+$}{};
2225     opendir DD, $dotdot or fail "opendir .. ($dotdot): $!";
2226     while ($!=0, defined(my $leaf = readdir DD)) {
2227         {
2228             local ($debuglevel) = $debuglevel-1;
2229             printdebug "DD_BPD $leaf ?\n";
2230         }
2231         next unless is_orig_file_of_vsn $leaf, $upstreamversion;
2232         next unless $wanted->($leaf);
2233         next if lstat "$bpd_abs/$leaf";
2234
2235         print STDERR f_
2236  "%s: found orig(s) in .. missing from build-products-dir, transferring:\n",
2237             $us
2238             unless $warned++;
2239         $! == &ENOENT or fail f_
2240             "check orig file %s in bpd %s: %s", $leaf, $bpd_abs, $!;
2241         lstat "$dotdot/$leaf" or fail f_
2242             "check orig file %s in ..: %s", $leaf, $!;
2243         if (-l _) {
2244             stat "$dotdot/$leaf" or fail f_
2245                 "check target of orig symlink %s in ..: %s", $leaf, $!;
2246             my $ltarget = readlink "$dotdot/$leaf" or
2247                 die "readlink $dotdot/$leaf: $!";
2248             if ($ltarget !~ m{^/}) {
2249                 $ltarget = "$dotdot/$ltarget";
2250             }
2251             symlink $ltarget, "$bpd_abs/$leaf"
2252                 or die "$ltarget $bpd_abs $leaf: $!";
2253             print STDERR f_
2254  "%s: cloned orig symlink from ..: %s\n",
2255                 $us, $leaf;
2256         } elsif (link "$dotdot/$leaf", "$bpd_abs/$leaf") {
2257             print STDERR f_
2258  "%s: hardlinked orig from ..: %s\n",
2259                 $us, $leaf;
2260         } elsif ($! != EXDEV) {
2261             fail f_ "failed to make %s a hardlink to %s: %s",
2262                 "$bpd_abs/$leaf", "$dotdot/$leaf", $!;
2263         } else {
2264             symlink "$bpd_abs/$leaf", "$dotdot/$leaf"
2265                 or die "$bpd_abs $dotdot $leaf $!";
2266             print STDERR f_
2267  "%s: symmlinked orig from .. on other filesystem: %s\n",
2268                 $us, $leaf;
2269         }
2270     }
2271     die "$dotdot; $!" if $!;
2272     closedir DD;
2273 }
2274
2275 sub import_tarball_tartrees ($$) {
2276     my ($upstreamv, $dfi) = @_;
2277     # cwd should be the playground
2278
2279     # We unpack and record the orig tarballs first, so that we only
2280     # need disk space for one private copy of the unpacked source.
2281     # But we can't make them into commits until we have the metadata
2282     # from the debian/changelog, so we record the tree objects now and
2283     # make them into commits later.
2284     my @tartrees;
2285     my $orig_f_base = srcfn $upstreamv, '';
2286
2287     foreach my $fi (@$dfi) {
2288         # We actually import, and record as a commit, every tarball
2289         # (unless there is only one file, in which case there seems
2290         # little point.
2291
2292         my $f = $fi->{Filename};
2293         printdebug "import considering $f ";
2294         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2295         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2296         my $compr_ext = $1;
2297
2298         my ($orig_f_part) =
2299             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2300
2301         printdebug "Y ", (join ' ', map { $_//"(none)" }
2302                           $compr_ext, $orig_f_part
2303                          ), "\n";
2304
2305         my $path = $fi->{Path} // $f;
2306         my $input = new IO::File $f, '<' or die "$f $!";
2307         my $compr_pid;
2308         my @compr_cmd;
2309
2310         if (defined $compr_ext) {
2311             my $cname =
2312                 Dpkg::Compression::compression_guess_from_filename $f;
2313             fail "Dpkg::Compression cannot handle file $f in source package"
2314                 if defined $compr_ext && !defined $cname;
2315             my $compr_proc =
2316                 new Dpkg::Compression::Process compression => $cname;
2317             @compr_cmd = $compr_proc->get_uncompress_cmdline();
2318             my $compr_fh = new IO::Handle;
2319             my $compr_pid = open $compr_fh, "-|" // confess "$!";
2320             if (!$compr_pid) {
2321                 open STDIN, "<&", $input or confess "$!";
2322                 exec @compr_cmd;
2323                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2324             }
2325             $input = $compr_fh;
2326         }
2327
2328         rmtree "_unpack-tar";
2329         mkdir "_unpack-tar" or confess "$!";
2330         my @tarcmd = qw(tar -x -f -
2331                         --no-same-owner --no-same-permissions
2332                         --no-acls --no-xattrs --no-selinux);
2333         my $tar_pid = fork // confess "$!";
2334         if (!$tar_pid) {
2335             chdir "_unpack-tar" or confess "$!";
2336             open STDIN, "<&", $input or confess "$!";
2337             exec @tarcmd;
2338             die f_ "dgit (child): exec %s: %s", $tarcmd[0], $!;
2339         }
2340         $!=0; (waitpid $tar_pid, 0) == $tar_pid or confess "$!";
2341         !$? or failedcmd @tarcmd;
2342
2343         close $input or
2344             (@compr_cmd ? ($?==SIGPIPE || failedcmd @compr_cmd)
2345              : confess "$!");
2346         # finally, we have the results in "tarball", but maybe
2347         # with the wrong permissions
2348
2349         runcmd qw(chmod -R +rwX _unpack-tar);
2350         changedir "_unpack-tar";
2351         remove_stray_gits($f);
2352         mktree_in_ud_here();
2353
2354         my ($tree) = git_add_write_tree();
2355         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2356         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2357             $tree = $1;
2358             printdebug "one subtree $1\n";
2359         } else {
2360             printdebug "multiple subtrees\n";
2361         }
2362         changedir "..";
2363         rmtree "_unpack-tar";
2364
2365         my $ent = [ $f, $tree ];
2366         push @tartrees, {
2367             Orig => !!$orig_f_part,
2368             Sort => (!$orig_f_part         ? 2 :
2369                      $orig_f_part =~ m/-/g ? 1 :
2370                                              0),
2371             OrigPart => $orig_f_part, # 'orig', 'orig-XXX', or undef
2372             F => $f,
2373             Tree => $tree,
2374         };
2375     }
2376
2377     @tartrees = sort {
2378         # put any without "_" first (spec is not clear whether files
2379         # are always in the usual order).  Tarballs without "_" are
2380         # the main orig or the debian tarball.
2381         $a->{Sort} <=> $b->{Sort} or
2382         $a->{F}    cmp $b->{F}
2383     } @tartrees;
2384
2385     @tartrees;
2386 }
2387
2388 sub import_tarball_commits ($$) {
2389     my ($tartrees, $upstreamv) = @_;
2390     # cwd should be a playtree which has a relevant debian/changelog
2391     # fills in $tt->{Commit} for each one
2392
2393     my $any_orig = grep { $_->{Orig} } @$tartrees;
2394
2395     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2396     my $clogp;
2397     my $r1clogp;
2398
2399     printdebug "import clog search...\n";
2400     parsechangelog_loop \@clogcmd, (__ "package changelog"), sub {
2401         my ($thisstanza, $desc) = @_;
2402         no warnings qw(exiting);
2403
2404         $clogp //= $thisstanza;
2405
2406         printdebug "import clog $thisstanza->{version} $desc...\n";
2407
2408         last if !$any_orig; # we don't need $r1clogp
2409
2410         # We look for the first (most recent) changelog entry whose
2411         # version number is lower than the upstream version of this
2412         # package.  Then the last (least recent) previous changelog
2413         # entry is treated as the one which introduced this upstream
2414         # version and used for the synthetic commits for the upstream
2415         # tarballs.
2416
2417         # One might think that a more sophisticated algorithm would be
2418         # necessary.  But: we do not want to scan the whole changelog
2419         # file.  Stopping when we see an earlier version, which
2420         # necessarily then is an earlier upstream version, is the only
2421         # realistic way to do that.  Then, either the earliest
2422         # changelog entry we have seen so far is indeed the earliest
2423         # upload of this upstream version; or there are only changelog
2424         # entries relating to later upstream versions (which is not
2425         # possible unless the changelog and .dsc disagree about the
2426         # version).  Then it remains to choose between the physically
2427         # last entry in the file, and the one with the lowest version
2428         # number.  If these are not the same, we guess that the
2429         # versions were created in a non-monotonic order rather than
2430         # that the changelog entries have been misordered.
2431
2432         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2433
2434         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2435         $r1clogp = $thisstanza;
2436
2437         printdebug "import clog $r1clogp->{version} becomes r1\n";
2438     };
2439
2440     $clogp or fail __ "package changelog has no entries!";
2441
2442     my $authline = clogp_authline $clogp;
2443     my $changes = getfield $clogp, 'Changes';
2444     $changes =~ s/^\n//; # Changes: \n
2445     my $cversion = getfield $clogp, 'Version';
2446
2447     my $r1authline;
2448     if (@$tartrees) {
2449         $r1clogp //= $clogp; # maybe there's only one entry;
2450         $r1authline = clogp_authline $r1clogp;
2451         # Strictly, r1authline might now be wrong if it's going to be
2452         # unused because !$any_orig.  Whatever.
2453
2454         printdebug "import tartrees authline   $authline\n";
2455         printdebug "import tartrees r1authline $r1authline\n";
2456
2457         foreach my $tt (@$tartrees) {
2458             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2459
2460             # untranslated so that different people's imports are identical
2461             my $mbody = sprintf "Import %s", $tt->{F};
2462             $tt->{Commit} = hash_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2463 tree $tt->{Tree}
2464 author $r1authline
2465 committer $r1authline
2466
2467 $mbody
2468
2469 [dgit import orig $tt->{F}]
2470 END_O
2471 tree $tt->{Tree}
2472 author $authline
2473 committer $authline
2474
2475 $mbody
2476
2477 [dgit import tarball $package $cversion $tt->{F}]
2478 END_T
2479         }
2480     }
2481
2482     return ($authline, $r1authline, $clogp, $changes);
2483 }
2484
2485 sub generate_commits_from_dsc () {
2486     # See big comment in fetch_from_archive, below.
2487     # See also README.dsc-import.
2488     prep_ud();
2489     changedir $playground;
2490
2491     my $bpd_abs = bpd_abs();
2492     my $upstreamv = upstreamversion $dsc->{version};
2493     my @dfi = dsc_files_info();
2494
2495     dotdot_bpd_transfer_origs $bpd_abs, $upstreamv,
2496         sub { grep { $_->{Filename} eq $_[0] } @dfi };
2497
2498     foreach my $fi (@dfi) {
2499         my $f = $fi->{Filename};
2500         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2501         my $upper_f = "$bpd_abs/$f";
2502
2503         printdebug "considering reusing $f: ";
2504
2505         if (link_ltarget "$upper_f,fetch", $f) {
2506             printdebug "linked (using ...,fetch).\n";
2507         } elsif ((printdebug "($!) "),
2508                  $! != ENOENT) {
2509             fail f_ "accessing %s: %s", "$buildproductsdir/$f,fetch", $!;
2510         } elsif (link_ltarget $upper_f, $f) {
2511             printdebug "linked.\n";
2512         } elsif ((printdebug "($!) "),
2513                  $! != ENOENT) {
2514             fail f_ "accessing %s: %s", "$buildproductsdir/$f", $!;
2515         } else {
2516             printdebug "absent.\n";
2517         }
2518
2519         my $refetched;
2520         complete_file_from_dsc('.', $fi, \$refetched)
2521             or next;
2522
2523         printdebug "considering saving $f: ";
2524
2525         if (rename_link_xf 1, $f, $upper_f) {
2526             printdebug "linked.\n";
2527         } elsif ((printdebug "($@) "),
2528                  $! != EEXIST) {
2529             fail f_ "saving %s: %s", "$buildproductsdir/$f", $@;
2530         } elsif (!$refetched) {
2531             printdebug "no need.\n";
2532         } elsif (rename_link_xf 1, $f, "$upper_f,fetch") {
2533             printdebug "linked (using ...,fetch).\n";
2534         } elsif ((printdebug "($@) "),
2535                  $! != EEXIST) {
2536             fail f_ "saving %s: %s", "$buildproductsdir/$f,fetch", $@;
2537         } else {
2538             printdebug "cannot.\n";
2539         }
2540     }
2541
2542     my @tartrees;
2543     @tartrees = import_tarball_tartrees($upstreamv, \@dfi)
2544         unless @dfi == 1; # only one file in .dsc
2545
2546     my $dscfn = "$package.dsc";
2547
2548     my $treeimporthow = 'package';
2549
2550     open D, ">", $dscfn or die "$dscfn: $!";
2551     print D $dscdata or die "$dscfn: $!";
2552     close D or die "$dscfn: $!";
2553     my @cmd = qw(dpkg-source);
2554     push @cmd, '--no-check' if $dsc_checked;
2555     if (madformat $dsc->{format}) {
2556         push @cmd, '--skip-patches';
2557         $treeimporthow = 'unpatched';
2558     }
2559     push @cmd, qw(-x --), $dscfn;
2560     runcmd @cmd;
2561
2562     my ($tree,$dir) = mktree_in_ud_from_only_subdir(__ "source package");
2563     if (madformat $dsc->{format}) {
2564         check_for_vendor_patches();
2565     }
2566
2567     my $dappliedtree;
2568     if (madformat $dsc->{format}) {
2569         my @pcmd = qw(dpkg-source --before-build .);
2570         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2571         rmtree '.pc';
2572         $dappliedtree = git_add_write_tree();
2573     }
2574
2575     my ($authline, $r1authline, $clogp, $changes) =
2576         import_tarball_commits(\@tartrees, $upstreamv);
2577
2578     my $cversion = getfield $clogp, 'Version';
2579
2580     printdebug "import main commit\n";
2581
2582     open C, ">../commit.tmp" or confess "$!";
2583     print C <<END or confess "$!";
2584 tree $tree
2585 END
2586     print C <<END or confess "$!" foreach @tartrees;
2587 parent $_->{Commit}
2588 END
2589     print C <<END or confess "$!";
2590 author $authline
2591 committer $authline
2592
2593 $changes
2594
2595 [dgit import $treeimporthow $package $cversion]
2596 END
2597
2598     close C or confess "$!";
2599     my $rawimport_hash = hash_commit qw(../commit.tmp);
2600
2601     if (madformat $dsc->{format}) {
2602         printdebug "import apply patches...\n";
2603
2604         # regularise the state of the working tree so that
2605         # the checkout of $rawimport_hash works nicely.
2606         my $dappliedcommit = hash_commit_text(<<END);
2607 tree $dappliedtree
2608 author $authline
2609 committer $authline
2610
2611 [dgit dummy commit]
2612 END
2613         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2614
2615         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2616
2617         # We need the answers to be reproducible
2618         my @authline = clogp_authline($clogp);
2619         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2620         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2621         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2622         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2623         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2624         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2625
2626         my $path = $ENV{PATH} or die;
2627
2628         # we use ../../gbp-pq-output, which (given that we are in
2629         # $playground/PLAYTREE, and $playground is .git/dgit/unpack,
2630         # is .git/dgit.
2631
2632         foreach my $use_absurd (qw(0 1)) {
2633             runcmd @git, qw(checkout -q unpa);
2634             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2635             local $ENV{PATH} = $path;
2636             if ($use_absurd) {
2637                 chomp $@;
2638                 progress "warning: $@";
2639                 $path = "$absurdity:$path";
2640                 progress f_ "%s: trying slow absurd-git-apply...", $us;
2641                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2642                     or $!==ENOENT
2643                     or confess "$!";
2644             }
2645             eval {
2646                 die "forbid absurd git-apply\n" if $use_absurd
2647                     && forceing [qw(import-gitapply-no-absurd)];
2648                 die "only absurd git-apply!\n" if !$use_absurd
2649                     && forceing [qw(import-gitapply-absurd)];
2650
2651                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2652                 local $ENV{PATH} = $path                    if $use_absurd;
2653
2654                 my @showcmd = (gbp_pq, qw(import));
2655                 my @realcmd = shell_cmd
2656                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2657                 debugcmd "+",@realcmd;
2658                 if (system @realcmd) {
2659                     die f_ "%s failed: %s\n",
2660                         +(shellquote @showcmd),
2661                         failedcmd_waitstatus();
2662                 }
2663
2664                 my $gapplied = git_rev_parse('HEAD');
2665                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2666                 $gappliedtree eq $dappliedtree or
2667                     fail f_ <<END, $gapplied, $gappliedtree, $dappliedtree;
2668 gbp-pq import and dpkg-source disagree!
2669  gbp-pq import gave commit %s
2670  gbp-pq import gave tree %s
2671  dpkg-source --before-build gave tree %s
2672 END
2673                 $rawimport_hash = $gapplied;
2674             };
2675             last unless $@;
2676         }
2677         if ($@) {
2678             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2679             die $@;
2680         }
2681     }
2682
2683     progress f_ "synthesised git commit from .dsc %s", $cversion;
2684
2685     my $rawimport_mergeinput = {
2686         Commit => $rawimport_hash,
2687         Info => __ "Import of source package",
2688     };
2689     my @output = ($rawimport_mergeinput);
2690
2691     if ($lastpush_mergeinput) {
2692         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2693         my $oversion = getfield $oldclogp, 'Version';
2694         my $vcmp =
2695             version_compare($oversion, $cversion);
2696         if ($vcmp < 0) {
2697             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2698                 { ReverseParents => 1,
2699                   # untranslated so that different people's pseudomerges
2700                   # are not needlessly different (although they will
2701                   # still differ if the series of pulls is different)
2702                   Message => (sprintf <<END, $package, $cversion, $csuite) });
2703 Record %s (%s) in archive suite %s
2704 END
2705         } elsif ($vcmp > 0) {
2706             print STDERR f_ <<END, $cversion, $oversion,
2707
2708 Version actually in archive:   %s (older)
2709 Last version pushed with dgit: %s (newer or same)
2710 %s
2711 END
2712                 __ $later_warning_msg or confess "$!";
2713             @output = $lastpush_mergeinput;
2714         } else {
2715             # Same version.  Use what's in the server git branch,
2716             # discarding our own import.  (This could happen if the
2717             # server automatically imports all packages into git.)
2718             @output = $lastpush_mergeinput;
2719         }
2720     }
2721     changedir $maindir;
2722     rmtree $playground;
2723     return @output;
2724 }
2725
2726 sub complete_file_from_dsc ($$;$) {
2727     our ($dstdir, $fi, $refetched) = @_;
2728     # Ensures that we have, in $dstdir, the file $fi, with the correct
2729     # contents.  (Downloading it from alongside $dscurl if necessary.)
2730     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2731     # and will set $$refetched=1 if it did so (or tried to).
2732
2733     my $f = $fi->{Filename};
2734     my $tf = "$dstdir/$f";
2735     my $downloaded = 0;
2736
2737     my $got;
2738     my $checkhash = sub {
2739         open F, "<", "$tf" or die "$tf: $!";
2740         $fi->{Digester}->reset();
2741         $fi->{Digester}->addfile(*F);
2742         F->error and confess "$!";
2743         $got = $fi->{Digester}->hexdigest();
2744         return $got eq $fi->{Hash};
2745     };
2746
2747     if (stat_exists $tf) {
2748         if ($checkhash->()) {
2749             progress f_ "using existing %s", $f;
2750             return 1;
2751         }
2752         if (!$refetched) {
2753             fail f_ "file %s has hash %s but .dsc demands hash %s".
2754                     " (perhaps you should delete this file?)",
2755                     $f, $got, $fi->{Hash};
2756         }
2757         progress f_ "need to fetch correct version of %s", $f;
2758         unlink $tf or die "$tf $!";
2759         $$refetched = 1;
2760     } else {
2761         printdebug "$tf does not exist, need to fetch\n";
2762     }
2763
2764     my $furl = $dscurl;
2765     $furl =~ s{/[^/]+$}{};
2766     $furl .= "/$f";
2767     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2768     die "$f ?" if $f =~ m#/#;
2769     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2770     return 0 if !act_local();
2771
2772     $checkhash->() or
2773         fail f_ "file %s has hash %s but .dsc demands hash %s".
2774                 " (got wrong file from archive!)",
2775                 $f, $got, $fi->{Hash};
2776
2777     return 1;
2778 }
2779
2780 sub ensure_we_have_orig () {
2781     my @dfi = dsc_files_info();
2782     foreach my $fi (@dfi) {
2783         my $f = $fi->{Filename};
2784         next unless is_orig_file_in_dsc($f, \@dfi);
2785         complete_file_from_dsc($buildproductsdir, $fi)
2786             or next;
2787     }
2788 }
2789
2790 #---------- git fetch ----------
2791
2792 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2793 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2794
2795 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2796 # locally fetched refs because they have unhelpful names and clutter
2797 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2798 # whether we have made another local ref which refers to this object).
2799 #
2800 # (If we deleted them unconditionally, then we might end up
2801 # re-fetching the same git objects each time dgit fetch was run.)
2802 #
2803 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2804 # in git_fetch_us to fetch the refs in question, and possibly a call
2805 # to lrfetchref_used.
2806
2807 our (%lrfetchrefs_f, %lrfetchrefs_d);
2808 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2809
2810 sub lrfetchref_used ($) {
2811     my ($fullrefname) = @_;
2812     my $objid = $lrfetchrefs_f{$fullrefname};
2813     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2814 }
2815
2816 sub git_lrfetch_sane {
2817     my ($url, $supplementary, @specs) = @_;
2818     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2819     # at least as regards @specs.  Also leave the results in
2820     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2821     # able to clean these up.
2822     #
2823     # With $supplementary==1, @specs must not contain wildcards
2824     # and we add to our previous fetches (non-atomically).
2825
2826     # This is rather miserable:
2827     # When git fetch --prune is passed a fetchspec ending with a *,
2828     # it does a plausible thing.  If there is no * then:
2829     # - it matches subpaths too, even if the supplied refspec
2830     #   starts refs, and behaves completely madly if the source
2831     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2832     # - if there is no matching remote ref, it bombs out the whole
2833     #   fetch.
2834     # We want to fetch a fixed ref, and we don't know in advance
2835     # if it exists, so this is not suitable.
2836     #
2837     # Our workaround is to use git ls-remote.  git ls-remote has its
2838     # own qairks.  Notably, it has the absurd multi-tail-matching
2839     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2840     # refs/refs/foo etc.
2841     #
2842     # Also, we want an idempotent snapshot, but we have to make two
2843     # calls to the remote: one to git ls-remote and to git fetch.  The
2844     # solution is use git ls-remote to obtain a target state, and
2845     # git fetch to try to generate it.  If we don't manage to generate
2846     # the target state, we try again.
2847
2848     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2849
2850     my $specre = join '|', map {
2851         my $x = $_;
2852         $x =~ s/\W/\\$&/g;
2853         my $wildcard = $x =~ s/\\\*$/.*/;
2854         die if $wildcard && $supplementary;
2855         "(?:refs/$x)";
2856     } @specs;
2857     printdebug "git_lrfetch_sane specre=$specre\n";
2858     my $wanted_rref = sub {
2859         local ($_) = @_;
2860         return m/^(?:$specre)$/;
2861     };
2862
2863     my $fetch_iteration = 0;
2864     FETCH_ITERATION:
2865     for (;;) {
2866         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2867         if (++$fetch_iteration > 10) {
2868             fail __ "too many iterations trying to get sane fetch!";
2869         }
2870
2871         my @look = map { "refs/$_" } @specs;
2872         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2873         debugcmd "|",@lcmd;
2874
2875         my %wantr;
2876         open GITLS, "-|", @lcmd or confess "$!";
2877         while (<GITLS>) {
2878             printdebug "=> ", $_;
2879             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2880             my ($objid,$rrefname) = ($1,$2);
2881             if (!$wanted_rref->($rrefname)) {
2882                 print STDERR f_ <<END, "@look", $rrefname;
2883 warning: git ls-remote %s reported %s; this is silly, ignoring it.
2884 END
2885                 next;
2886             }
2887             $wantr{$rrefname} = $objid;
2888         }
2889         $!=0; $?=0;
2890         close GITLS or failedcmd @lcmd;
2891
2892         # OK, now %want is exactly what we want for refs in @specs
2893         my @fspecs = map {
2894             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2895             "+refs/$_:".lrfetchrefs."/$_";
2896         } @specs;
2897
2898         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2899
2900         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2901         runcmd_ordryrun_local @fcmd if @fspecs;
2902
2903         if (!$supplementary) {
2904             %lrfetchrefs_f = ();
2905         }
2906         my %objgot;
2907
2908         git_for_each_ref(lrfetchrefs, sub {
2909             my ($objid,$objtype,$lrefname,$reftail) = @_;
2910             $lrfetchrefs_f{$lrefname} = $objid;
2911             $objgot{$objid} = 1;
2912         });
2913
2914         if ($supplementary) {
2915             last;
2916         }
2917
2918         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2919             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2920             if (!exists $wantr{$rrefname}) {
2921                 if ($wanted_rref->($rrefname)) {
2922                     printdebug <<END;
2923 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2924 END
2925                 } else {
2926                     print STDERR f_ <<END, "@fspecs", $lrefname
2927 warning: git fetch %s created %s; this is silly, deleting it.
2928 END
2929                 }
2930                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2931                 delete $lrfetchrefs_f{$lrefname};
2932                 next;
2933             }
2934         }
2935         foreach my $rrefname (sort keys %wantr) {
2936             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2937             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2938             my $want = $wantr{$rrefname};
2939             next if $got eq $want;
2940             if (!defined $objgot{$want}) {
2941                 fail __ <<END unless act_local();
2942 --dry-run specified but we actually wanted the results of git fetch,
2943 so this is not going to work.  Try running dgit fetch first,
2944 or using --damp-run instead of --dry-run.
2945 END
2946                 print STDERR f_ <<END, $lrefname, $want;
2947 warning: git ls-remote suggests we want %s
2948 warning:  and it should refer to %s
2949 warning:  but git fetch didn't fetch that object to any relevant ref.
2950 warning:  This may be due to a race with someone updating the server.
2951 warning:  Will try again...
2952 END
2953                 next FETCH_ITERATION;
2954             }
2955             printdebug <<END;
2956 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2957 END
2958             runcmd_ordryrun_local @git, qw(update-ref -m),
2959                 "dgit fetch git fetch fixup", $lrefname, $want;
2960             $lrfetchrefs_f{$lrefname} = $want;
2961         }
2962         last;
2963     }
2964
2965     if (defined $csuite) {
2966         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2967         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2968             my ($objid,$objtype,$lrefname,$reftail) = @_;
2969             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2970             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2971         });
2972     }
2973
2974     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2975         Dumper(\%lrfetchrefs_f);
2976 }
2977
2978 sub git_fetch_us () {
2979     # Want to fetch only what we are going to use, unless
2980     # deliberately-not-ff, in which case we must fetch everything.
2981
2982     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2983         map { "tags/$_" } debiantags('*',access_nomdistro);
2984     push @specs, server_branch($csuite);
2985     push @specs, $rewritemap;
2986     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2987
2988     my $url = access_giturl();
2989     git_lrfetch_sane $url, 0, @specs;
2990
2991     my %here;
2992     my @tagpats = debiantags('*',access_nomdistro);
2993
2994     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2995         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2996         printdebug "currently $fullrefname=$objid\n";
2997         $here{$fullrefname} = $objid;
2998     });
2999     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
3000         my ($objid,$objtype,$fullrefname,$reftail) = @_;
3001         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
3002         printdebug "offered $lref=$objid\n";
3003         if (!defined $here{$lref}) {
3004             my @upd = (@git, qw(update-ref), $lref, $objid, '');
3005             runcmd_ordryrun_local @upd;
3006             lrfetchref_used $fullrefname;
3007         } elsif ($here{$lref} eq $objid) {
3008             lrfetchref_used $fullrefname;
3009         } else {
3010             print STDERR f_ "Not updating %s from %s to %s.\n",
3011                             $lref, $here{$lref}, $objid;
3012         }
3013     });
3014 }
3015
3016 #---------- dsc and archive handling ----------
3017
3018 sub mergeinfo_getclogp ($) {
3019     # Ensures thit $mi->{Clogp} exists and returns it
3020     my ($mi) = @_;
3021     $mi->{Clogp} = commit_getclogp($mi->{Commit});
3022 }
3023
3024 sub mergeinfo_version ($) {
3025     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
3026 }
3027
3028 sub fetch_from_archive_record_1 ($) {
3029     my ($hash) = @_;
3030     runcmd git_update_ref_cmd "dgit fetch $csuite", 'DGIT_ARCHIVE', $hash;
3031     cmdoutput @git, qw(log -n2), $hash;
3032     # ... gives git a chance to complain if our commit is malformed
3033 }
3034
3035 sub fetch_from_archive_record_2 ($) {
3036     my ($hash) = @_;
3037     my @upd_cmd = (git_update_ref_cmd 'dgit fetch', lrref(), $hash);
3038     if (act_local()) {
3039         cmdoutput @upd_cmd;
3040     } else {
3041         dryrun_report @upd_cmd;
3042     }
3043 }
3044
3045 sub parse_dsc_field_def_dsc_distro () {
3046     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
3047                            dgit.default.distro);
3048 }
3049
3050 sub parse_dsc_field ($$) {
3051     my ($dsc, $what) = @_;
3052     my $f;
3053     foreach my $field (@ourdscfield) {
3054         $f = $dsc->{$field};
3055         last if defined $f;
3056     }
3057
3058     if (!defined $f) {
3059         progress f_ "%s: NO git hash", $what;
3060         parse_dsc_field_def_dsc_distro();
3061     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
3062              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
3063         progress f_ "%s: specified git info (%s)", $what, $dsc_distro;
3064         $dsc_hint_tag = [ $dsc_hint_tag ];
3065     } elsif ($f =~ m/^\w+\s*$/) {
3066         $dsc_hash = $&;
3067         parse_dsc_field_def_dsc_distro();
3068         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
3069                           $dsc_distro ];
3070         progress f_ "%s: specified git hash", $what;
3071     } else {
3072         fail f_ "%s: invalid Dgit info", $what;
3073     }
3074 }
3075
3076 sub resolve_dsc_field_commit ($$) {
3077     my ($already_distro, $already_mapref) = @_;
3078
3079     return unless defined $dsc_hash;
3080
3081     my $mapref =
3082         defined $already_mapref &&
3083         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
3084         ? $already_mapref : undef;
3085
3086     my $do_fetch;
3087     $do_fetch = sub {
3088         my ($what, @fetch) = @_;
3089
3090         local $idistro = $dsc_distro;
3091         my $lrf = lrfetchrefs;
3092
3093         if (!$chase_dsc_distro) {
3094             progress f_ "not chasing .dsc distro %s: not fetching %s",
3095                         $dsc_distro, $what;
3096             return 0;
3097         }
3098
3099         progress f_ ".dsc names distro %s: fetching %s", $dsc_distro, $what;
3100
3101         my $url = access_giturl();
3102         if (!defined $url) {
3103             defined $dsc_hint_url or fail f_ <<END, $dsc_distro;
3104 .dsc Dgit metadata is in context of distro %s
3105 for which we have no configured url and .dsc provides no hint
3106 END
3107             my $proto =
3108                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
3109                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
3110             parse_cfg_bool "dsc-url-proto-ok", 'false',
3111                 cfg("dgit.dsc-url-proto-ok.$proto",
3112                     "dgit.default.dsc-url-proto-ok")
3113                 or fail f_ <<END, $dsc_distro, $proto;
3114 .dsc Dgit metadata is in context of distro %s
3115 for which we have no configured url;
3116 .dsc provides hinted url with protocol %s which is unsafe.
3117 (can be overridden by config - consult documentation)
3118 END
3119             $url = $dsc_hint_url;
3120         }
3121
3122         git_lrfetch_sane $url, 1, @fetch;
3123
3124         return $lrf;
3125     };
3126
3127     my $rewrite_enable = do {
3128         local $idistro = $dsc_distro;
3129         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
3130     };
3131
3132     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
3133         if (!defined $mapref) {
3134             my $lrf = $do_fetch->((__ "rewrite map"), $rewritemap) or return;
3135             $mapref = $lrf.'/'.$rewritemap;
3136         }
3137         my $rewritemapdata = git_cat_file $mapref.':map';
3138         if (defined $rewritemapdata
3139             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
3140             progress __
3141                 "server's git history rewrite map contains a relevant entry!";
3142
3143             $dsc_hash = $1;
3144             if (defined $dsc_hash) {
3145                 progress __ "using rewritten git hash in place of .dsc value";
3146             } else {
3147                 progress __ "server data says .dsc hash is to be disregarded";
3148             }
3149         }
3150     }
3151
3152     if (!defined git_cat_file $dsc_hash) {
3153         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
3154         my $lrf = $do_fetch->((__ "additional commits"), @tags) &&
3155             defined git_cat_file $dsc_hash
3156             or fail f_ <<END, $dsc_hash;
3157 .dsc Dgit metadata requires commit %s
3158 but we could not obtain that object anywhere.
3159 END
3160         foreach my $t (@tags) {
3161             my $fullrefname = $lrf.'/'.$t;
3162 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
3163             next unless $lrfetchrefs_f{$fullrefname};
3164             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
3165             lrfetchref_used $fullrefname;
3166         }
3167     }
3168 }
3169
3170 sub fetch_from_archive () {
3171     check_bpd_exists();
3172     ensure_setup_existing_tree();
3173
3174     # Ensures that lrref() is what is actually in the archive, one way
3175     # or another, according to us - ie this client's
3176     # appropritaely-updated archive view.  Also returns the commit id.
3177     # If there is nothing in the archive, leaves lrref alone and
3178     # returns undef.  git_fetch_us must have already been called.
3179     get_archive_dsc();
3180
3181     if ($dsc) {
3182         parse_dsc_field($dsc, __ 'last upload to archive');
3183         resolve_dsc_field_commit access_basedistro,
3184             lrfetchrefs."/".$rewritemap
3185     } else {
3186         progress __ "no version available from the archive";
3187     }
3188
3189     # If the archive's .dsc has a Dgit field, there are three
3190     # relevant git commitids we need to choose between and/or merge
3191     # together:
3192     #   1. $dsc_hash: the Dgit field from the archive
3193     #   2. $lastpush_hash: the suite branch on the dgit git server
3194     #   3. $lastfetch_hash: our local tracking brach for the suite
3195     #
3196     # These may all be distinct and need not be in any fast forward
3197     # relationship:
3198     #
3199     # If the dsc was pushed to this suite, then the server suite
3200     # branch will have been updated; but it might have been pushed to
3201     # a different suite and copied by the archive.  Conversely a more
3202     # recent version may have been pushed with dgit but not appeared
3203     # in the archive (yet).
3204     #
3205     # $lastfetch_hash may be awkward because archive imports
3206     # (particularly, imports of Dgit-less .dscs) are performed only as
3207     # needed on individual clients, so different clients may perform a
3208     # different subset of them - and these imports are only made
3209     # public during push.  So $lastfetch_hash may represent a set of
3210     # imports different to a subsequent upload by a different dgit
3211     # client.
3212     #
3213     # Our approach is as follows:
3214     #
3215     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
3216     # descendant of $dsc_hash, then it was pushed by a dgit user who
3217     # had based their work on $dsc_hash, so we should prefer it.
3218     # Otherwise, $dsc_hash was installed into this suite in the
3219     # archive other than by a dgit push, and (necessarily) after the
3220     # last dgit push into that suite (since a dgit push would have
3221     # been descended from the dgit server git branch); thus, in that
3222     # case, we prefer the archive's version (and produce a
3223     # pseudo-merge to overwrite the dgit server git branch).
3224     #
3225     # (If there is no Dgit field in the archive's .dsc then
3226     # generate_commit_from_dsc uses the version numbers to decide
3227     # whether the suite branch or the archive is newer.  If the suite
3228     # branch is newer it ignores the archive's .dsc; otherwise it
3229     # generates an import of the .dsc, and produces a pseudo-merge to
3230     # overwrite the suite branch with the archive contents.)
3231     #
3232     # The outcome of that part of the algorithm is the `public view',
3233     # and is same for all dgit clients: it does not depend on any
3234     # unpublished history in the local tracking branch.
3235     #
3236     # As between the public view and the local tracking branch: The
3237     # local tracking branch is only updated by dgit fetch, and
3238     # whenever dgit fetch runs it includes the public view in the
3239     # local tracking branch.  Therefore if the public view is not
3240     # descended from the local tracking branch, the local tracking
3241     # branch must contain history which was imported from the archive
3242     # but never pushed; and, its tip is now out of date.  So, we make
3243     # a pseudo-merge to overwrite the old imports and stitch the old
3244     # history in.
3245     #
3246     # Finally: we do not necessarily reify the public view (as
3247     # described above).  This is so that we do not end up stacking two
3248     # pseudo-merges.  So what we actually do is figure out the inputs
3249     # to any public view pseudo-merge and put them in @mergeinputs.
3250
3251     my @mergeinputs;
3252     # $mergeinputs[]{Commit}
3253     # $mergeinputs[]{Info}
3254     # $mergeinputs[0] is the one whose tree we use
3255     # @mergeinputs is in the order we use in the actual commit)
3256     #
3257     # Also:
3258     # $mergeinputs[]{Message} is a commit message to use
3259     # $mergeinputs[]{ReverseParents} if def specifies that parent
3260     #                                list should be in opposite order
3261     # Such an entry has no Commit or Info.  It applies only when found
3262     # in the last entry.  (This ugliness is to support making
3263     # identical imports to previous dgit versions.)
3264
3265     my $lastpush_hash = git_get_ref(lrfetchref());
3266     printdebug "previous reference hash=$lastpush_hash\n";
3267     $lastpush_mergeinput = $lastpush_hash && {
3268         Commit => $lastpush_hash,
3269         Info => (__ "dgit suite branch on dgit git server"),
3270     };
3271
3272     my $lastfetch_hash = git_get_ref(lrref());
3273     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3274     my $lastfetch_mergeinput = $lastfetch_hash && {
3275         Commit => $lastfetch_hash,
3276         Info => (__ "dgit client's archive history view"),
3277     };
3278
3279     my $dsc_mergeinput = $dsc_hash && {
3280         Commit => $dsc_hash,
3281         Info => (__ "Dgit field in .dsc from archive"),
3282     };
3283
3284     my $cwd = getcwd();
3285     my $del_lrfetchrefs = sub {
3286         changedir $cwd;
3287         my $gur;
3288         printdebug "del_lrfetchrefs...\n";
3289         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3290             my $objid = $lrfetchrefs_d{$fullrefname};
3291             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3292             if (!$gur) {
3293                 $gur ||= new IO::Handle;
3294                 open $gur, "|-", qw(git update-ref --stdin) or confess "$!";
3295             }
3296             printf $gur "delete %s %s\n", $fullrefname, $objid;
3297         }
3298         if ($gur) {
3299             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3300         }
3301     };
3302
3303     if (defined $dsc_hash) {
3304         ensure_we_have_orig();
3305         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3306             @mergeinputs = $dsc_mergeinput
3307         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3308             print STDERR f_ <<END, $dsc_hash, $lastpush_hash,
3309
3310 Git commit in archive is behind the last version allegedly pushed/uploaded.
3311 Commit referred to by archive: %s
3312 Last version pushed with dgit: %s
3313 %s
3314 END
3315                 __ $later_warning_msg or confess "$!";
3316             @mergeinputs = ($lastpush_mergeinput);
3317         } else {
3318             # Archive has .dsc which is not a descendant of the last dgit
3319             # push.  This can happen if the archive moves .dscs about.
3320             # Just follow its lead.
3321             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3322                 progress __ "archive .dsc names newer git commit";
3323                 @mergeinputs = ($dsc_mergeinput);
3324             } else {
3325                 progress __ "archive .dsc names other git commit, fixing up";
3326                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3327             }
3328         }
3329     } elsif ($dsc) {
3330         @mergeinputs = generate_commits_from_dsc();
3331         # We have just done an import.  Now, our import algorithm might
3332         # have been improved.  But even so we do not want to generate
3333         # a new different import of the same package.  So if the
3334         # version numbers are the same, just use our existing version.
3335         # If the version numbers are different, the archive has changed
3336         # (perhaps, rewound).
3337         if ($lastfetch_mergeinput &&
3338             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3339                               (mergeinfo_version $mergeinputs[0]) )) {
3340             @mergeinputs = ($lastfetch_mergeinput);
3341         }
3342     } elsif ($lastpush_hash) {
3343         # only in git, not in the archive yet
3344         @mergeinputs = ($lastpush_mergeinput);
3345         print STDERR f_ <<END,
3346
3347 Package not found in the archive, but has allegedly been pushed using dgit.
3348 %s
3349 END
3350             __ $later_warning_msg or confess "$!";
3351     } else {
3352         printdebug "nothing found!\n";
3353         if (defined $skew_warning_vsn) {
3354             print STDERR f_ <<END, $skew_warning_vsn or confess "$!";
3355
3356 Warning: relevant archive skew detected.
3357 Archive allegedly contains %s
3358 But we were not able to obtain any version from the archive or git.
3359
3360 END
3361         }
3362         unshift @end, $del_lrfetchrefs;
3363         return undef;
3364     }
3365
3366     if ($lastfetch_hash &&
3367         !grep {
3368             my $h = $_->{Commit};
3369             $h and is_fast_fwd($lastfetch_hash, $h);
3370             # If true, one of the existing parents of this commit
3371             # is a descendant of the $lastfetch_hash, so we'll
3372             # be ff from that automatically.
3373         } @mergeinputs
3374         ) {
3375         # Otherwise:
3376         push @mergeinputs, $lastfetch_mergeinput;
3377     }
3378
3379     printdebug "fetch mergeinfos:\n";
3380     foreach my $mi (@mergeinputs) {
3381         if ($mi->{Info}) {
3382             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3383         } else {
3384             printdebug sprintf " ReverseParents=%d Message=%s",
3385                 $mi->{ReverseParents}, $mi->{Message};
3386         }
3387     }
3388
3389     my $compat_info= pop @mergeinputs
3390         if $mergeinputs[$#mergeinputs]{Message};
3391
3392     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3393
3394     my $hash;
3395     if (@mergeinputs > 1) {
3396         # here we go, then:
3397         my $tree_commit = $mergeinputs[0]{Commit};
3398
3399         my $tree = get_tree_of_commit $tree_commit;;
3400
3401         # We use the changelog author of the package in question the
3402         # author of this pseudo-merge.  This is (roughly) correct if
3403         # this commit is simply representing aa non-dgit upload.
3404         # (Roughly because it does not record sponsorship - but we
3405         # don't have sponsorship info because that's in the .changes,
3406         # which isn't in the archivw.)
3407         #
3408         # But, it might be that we are representing archive history
3409         # updates (including in-archive copies).  These are not really
3410         # the responsibility of the person who created the .dsc, but
3411         # there is no-one whose name we should better use.  (The
3412         # author of the .dsc-named commit is clearly worse.)
3413
3414         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3415         my $author = clogp_authline $useclogp;
3416         my $cversion = getfield $useclogp, 'Version';
3417
3418         my $mcf = dgit_privdir()."/mergecommit";
3419         open MC, ">", $mcf or die "$mcf $!";
3420         print MC <<END or confess "$!";
3421 tree $tree
3422 END
3423
3424         my @parents = grep { $_->{Commit} } @mergeinputs;
3425         @parents = reverse @parents if $compat_info->{ReverseParents};
3426         print MC <<END or confess "$!" foreach @parents;
3427 parent $_->{Commit}
3428 END
3429
3430         print MC <<END or confess "$!";
3431 author $author
3432 committer $author
3433
3434 END
3435
3436         if (defined $compat_info->{Message}) {
3437             print MC $compat_info->{Message} or confess "$!";
3438         } else {
3439             print MC f_ <<END, $package, $cversion, $csuite or confess "$!";
3440 Record %s (%s) in archive suite %s
3441
3442 Record that
3443 END
3444             my $message_add_info = sub {
3445                 my ($mi) = (@_);
3446                 my $mversion = mergeinfo_version $mi;
3447                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3448                     or confess "$!";
3449             };
3450
3451             $message_add_info->($mergeinputs[0]);
3452             print MC __ <<END or confess "$!";
3453 should be treated as descended from
3454 END
3455             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3456         }
3457
3458         close MC or confess "$!";
3459         $hash = hash_commit $mcf;
3460     } else {
3461         $hash = $mergeinputs[0]{Commit};
3462     }
3463     printdebug "fetch hash=$hash\n";
3464
3465     my $chkff = sub {
3466         my ($lasth, $what) = @_;
3467         return unless $lasth;
3468         confess "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3469     };
3470
3471     $chkff->($lastpush_hash, __ 'dgit repo server tip (last push)')
3472         if $lastpush_hash;
3473     $chkff->($lastfetch_hash, __ 'local tracking tip (last fetch)');
3474
3475     fetch_from_archive_record_1($hash);
3476
3477     if (defined $skew_warning_vsn) {
3478         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3479         my $gotclogp = commit_getclogp($hash);
3480         my $got_vsn = getfield $gotclogp, 'Version';
3481         printdebug "SKEW CHECK GOT $got_vsn\n";
3482         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3483             print STDERR f_ <<END, $skew_warning_vsn, $got_vsn or confess "$!";
3484
3485 Warning: archive skew detected.  Using the available version:
3486 Archive allegedly contains    %s
3487 We were able to obtain only   %s
3488
3489 END
3490         }
3491     }
3492
3493     if ($lastfetch_hash ne $hash) {
3494         fetch_from_archive_record_2($hash);
3495     }
3496
3497     lrfetchref_used lrfetchref();
3498
3499     check_gitattrs($hash, __ "fetched source tree");
3500
3501     unshift @end, $del_lrfetchrefs;
3502     return $hash;
3503 }
3504
3505 sub set_local_git_config ($$) {
3506     my ($k, $v) = @_;
3507     runcmd @git, qw(config), $k, $v;
3508 }
3509
3510 sub setup_mergechangelogs (;$) {
3511     my ($always) = @_;
3512     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3513
3514     my $driver = 'dpkg-mergechangelogs';
3515     my $cb = "merge.$driver";
3516     confess unless defined $maindir;
3517     my $attrs = "$maindir_gitcommon/info/attributes";
3518     ensuredir "$maindir_gitcommon/info";
3519
3520     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3521     if (!open ATTRS, "<", $attrs) {
3522         $!==ENOENT or die "$attrs: $!";
3523     } else {
3524         while (<ATTRS>) {
3525             chomp;
3526             next if m{^debian/changelog\s};
3527             print NATTRS $_, "\n" or confess "$!";
3528         }
3529         ATTRS->error and confess "$!";
3530         close ATTRS;
3531     }
3532     print NATTRS "debian/changelog merge=$driver\n" or confess "$!";
3533     close NATTRS;
3534
3535     set_local_git_config "$cb.name", __ 'debian/changelog merge driver';
3536     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3537
3538     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3539 }
3540
3541 sub setup_useremail (;$) {
3542     my ($always) = @_;
3543     return unless $always || access_cfg_bool(1, 'setup-useremail');
3544
3545     my $setup = sub {
3546         my ($k, $envvar) = @_;
3547         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3548         return unless defined $v;
3549         set_local_git_config "user.$k", $v;
3550     };
3551
3552     $setup->('email', 'DEBEMAIL');
3553     $setup->('name', 'DEBFULLNAME');
3554 }
3555
3556 sub ensure_setup_existing_tree () {
3557     my $k = "remote.$remotename.skipdefaultupdate";
3558     my $c = git_get_config $k;
3559     return if defined $c;
3560     set_local_git_config $k, 'true';
3561 }
3562
3563 sub open_main_gitattrs () {
3564     confess 'internal error no maindir' unless defined $maindir;
3565     my $gai = new IO::File "$maindir_gitcommon/info/attributes"
3566         or $!==ENOENT
3567         or die "open $maindir_gitcommon/info/attributes: $!";
3568     return $gai;
3569 }
3570
3571 our $gitattrs_ourmacro_re = qr{^\[attr\]dgit-defuse-attrs\s};
3572
3573 sub is_gitattrs_setup () {
3574     # return values:
3575     #  trueish
3576     #     1: gitattributes set up and should be left alone
3577     #  falseish
3578     #     0: there is a dgit-defuse-attrs but it needs fixing
3579     #     undef: there is none
3580     my $gai = open_main_gitattrs();
3581     return 0 unless $gai;
3582     while (<$gai>) {
3583         next unless m{$gitattrs_ourmacro_re};
3584         return 1 if m{\s-working-tree-encoding\s};
3585         printdebug "is_gitattrs_setup: found old macro\n";
3586         return 0;
3587     }
3588     $gai->error and confess "$!";
3589     printdebug "is_gitattrs_setup: found nothing\n";
3590     return undef;
3591 }
3592
3593 sub setup_gitattrs (;$) {
3594     my ($always) = @_;
3595     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3596
3597     my $already = is_gitattrs_setup();
3598     if ($already) {
3599         progress __ <<END;
3600 [attr]dgit-defuse-attrs already found, and proper, in .git/info/attributes
3601  not doing further gitattributes setup
3602 END
3603         return;
3604     }
3605     my $new = "[attr]dgit-defuse-attrs  $negate_harmful_gitattrs";
3606     my $af = "$maindir_gitcommon/info/attributes";
3607     ensuredir "$maindir_gitcommon/info";
3608
3609     open GAO, "> $af.new" or confess "$!";
3610     print GAO <<END, __ <<ENDT or confess "$!" unless defined $already;
3611 *       dgit-defuse-attrs
3612 $new
3613 END
3614 # ^ see GITATTRIBUTES in dgit(7) and dgit setup-new-tree in dgit(1)
3615 ENDT
3616     my $gai = open_main_gitattrs();
3617     if ($gai) {
3618         while (<$gai>) {
3619             if (m{$gitattrs_ourmacro_re}) {
3620                 die unless defined $already;
3621                 $_ = $new;
3622             }
3623             chomp;
3624             print GAO $_, "\n" or confess "$!";
3625         }
3626         $gai->error and confess "$!";
3627     }
3628     close GAO or confess "$!";
3629     rename "$af.new", "$af" or fail f_ "install %s: %s", $af, $!;
3630 }
3631
3632 sub setup_new_tree () {
3633     setup_mergechangelogs();
3634     setup_useremail();
3635     setup_gitattrs();
3636 }
3637
3638 sub check_gitattrs ($$) {
3639     my ($treeish, $what) = @_;
3640
3641     return if is_gitattrs_setup;
3642
3643     local $/="\0";
3644     my @cmd = (@git, qw(ls-tree -lrz --), "${treeish}:");
3645     debugcmd "|",@cmd;
3646     my $gafl = new IO::File;
3647     open $gafl, "-|", @cmd or confess "$!";
3648     while (<$gafl>) {
3649         chomp or die;
3650         s/^\d+\s+\w+\s+\w+\s+(\d+)\t// or die;
3651         next if $1 == 0;
3652         next unless m{(?:^|/)\.gitattributes$};
3653
3654         # oh dear, found one
3655         print STDERR f_ <<END, $what;
3656 dgit: warning: %s contains .gitattributes
3657 dgit: .gitattributes not (fully) defused.  Recommended: dgit setup-new-tree.
3658 END
3659         close $gafl;
3660         return;
3661     }
3662     # tree contains no .gitattributes files
3663     $?=0; $!=0; close $gafl or failedcmd @cmd;
3664 }
3665
3666
3667 sub multisuite_suite_child ($$$) {
3668     my ($tsuite, $mergeinputs, $fn) = @_;
3669     # in child, sets things up, calls $fn->(), and returns undef
3670     # in parent, returns canonical suite name for $tsuite
3671     my $canonsuitefh = IO::File::new_tmpfile;
3672     my $pid = fork // confess "$!";
3673     if (!$pid) {
3674         forkcheck_setup();
3675         $isuite = $tsuite;
3676         $us .= " [$isuite]";
3677         $debugprefix .= " ";
3678         progress f_ "fetching %s...", $tsuite;
3679         canonicalise_suite();
3680         print $canonsuitefh $csuite, "\n" or confess "$!";
3681         close $canonsuitefh or confess "$!";
3682         $fn->();
3683         return undef;
3684     }
3685     waitpid $pid,0 == $pid or confess "$!";
3686     fail f_ "failed to obtain %s: %s", $tsuite, waitstatusmsg()
3687         if $? && $?!=256*4;
3688     seek $canonsuitefh,0,0 or confess "$!";
3689     local $csuite = <$canonsuitefh>;
3690     confess "$!" unless defined $csuite && chomp $csuite;
3691     if ($? == 256*4) {
3692         printdebug "multisuite $tsuite missing\n";
3693         return $csuite;
3694     }
3695     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3696     push @$mergeinputs, {
3697         Ref => lrref,
3698         Info => $csuite,
3699     };
3700     return $csuite;
3701 }
3702
3703 sub fork_for_multisuite ($) {
3704     my ($before_fetch_merge) = @_;
3705     # if nothing unusual, just returns ''
3706     #
3707     # if multisuite:
3708     # returns 0 to caller in child, to do first of the specified suites
3709     # in child, $csuite is not yet set
3710     #
3711     # returns 1 to caller in parent, to finish up anything needed after
3712     # in parent, $csuite is set to canonicalised portmanteau
3713
3714     my $org_isuite = $isuite;
3715     my @suites = split /\,/, $isuite;
3716     return '' unless @suites > 1;
3717     printdebug "fork_for_multisuite: @suites\n";
3718
3719     my @mergeinputs;
3720
3721     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3722                                             sub { });
3723     return 0 unless defined $cbasesuite;
3724
3725     fail f_ "package %s missing in (base suite) %s", $package, $cbasesuite
3726         unless @mergeinputs;
3727
3728     my @csuites = ($cbasesuite);
3729
3730     $before_fetch_merge->();
3731
3732     foreach my $tsuite (@suites[1..$#suites]) {
3733         $tsuite =~ s/^-/$cbasesuite-/;
3734         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3735                                                sub {
3736             @end = ();
3737             fetch_one();
3738             finish 0;
3739         });
3740
3741         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3742         push @csuites, $csubsuite;
3743     }
3744
3745     foreach my $mi (@mergeinputs) {
3746         my $ref = git_get_ref $mi->{Ref};
3747         die "$mi->{Ref} ?" unless length $ref;
3748         $mi->{Commit} = $ref;
3749     }
3750
3751     $csuite = join ",", @csuites;
3752
3753     my $previous = git_get_ref lrref;
3754     if ($previous) {
3755         unshift @mergeinputs, {
3756             Commit => $previous,
3757             Info => (__ "local combined tracking branch"),
3758             Warning => (__
3759  "archive seems to have rewound: local tracking branch is ahead!"),
3760         };
3761     }
3762
3763     foreach my $ix (0..$#mergeinputs) {
3764         $mergeinputs[$ix]{Index} = $ix;
3765     }
3766
3767     @mergeinputs = sort {
3768         -version_compare(mergeinfo_version $a,
3769                          mergeinfo_version $b) # highest version first
3770             or
3771         $a->{Index} <=> $b->{Index}; # earliest in spec first
3772     } @mergeinputs;
3773
3774     my @needed;
3775
3776   NEEDED:
3777     foreach my $mi (@mergeinputs) {
3778         printdebug "multisuite merge check $mi->{Info}\n";
3779         foreach my $previous (@needed) {
3780             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3781             printdebug "multisuite merge un-needed $previous->{Info}\n";
3782             next NEEDED;
3783         }
3784         push @needed, $mi;
3785         printdebug "multisuite merge this-needed\n";
3786         $mi->{Character} = '+';
3787     }
3788
3789     $needed[0]{Character} = '*';
3790
3791     my $output = $needed[0]{Commit};
3792
3793     if (@needed > 1) {
3794         printdebug "multisuite merge nontrivial\n";
3795         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3796
3797         my $commit = "tree $tree\n";
3798         my $msg = f_ "Combine archive branches %s [dgit]\n\n".
3799                      "Input branches:\n",
3800                      $csuite;
3801
3802         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3803             printdebug "multisuite merge include $mi->{Info}\n";
3804             $mi->{Character} //= ' ';
3805             $commit .= "parent $mi->{Commit}\n";
3806             $msg .= sprintf " %s  %-25s %s\n",
3807                 $mi->{Character},
3808                 (mergeinfo_version $mi),
3809                 $mi->{Info};
3810         }
3811         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3812         $msg .= __ "\nKey\n".
3813             " * marks the highest version branch, which choose to use\n".
3814             " + marks each branch which was not already an ancestor\n\n";
3815         $msg .=
3816             "[dgit multi-suite $csuite]\n";
3817         $commit .=
3818             "author $authline\n".
3819             "committer $authline\n\n";
3820         $output = hash_commit_text $commit.$msg;
3821         printdebug "multisuite merge generated $output\n";
3822     }
3823
3824     fetch_from_archive_record_1($output);
3825     fetch_from_archive_record_2($output);
3826
3827     progress f_ "calculated combined tracking suite %s", $csuite;
3828
3829     return 1;
3830 }
3831
3832 sub clone_set_head () {
3833     open H, "> .git/HEAD" or confess "$!";
3834     print H "ref: ".lref()."\n" or confess "$!";
3835     close H or confess "$!";
3836 }
3837 sub clone_finish ($) {
3838     my ($dstdir) = @_;
3839     runcmd @git, qw(reset --hard), lrref();
3840     runcmd qw(bash -ec), <<'END';
3841         set -o pipefail
3842         git ls-tree -r --name-only -z HEAD | \
3843         xargs -0r touch -h -r . --
3844 END
3845     printdone f_ "ready for work in %s", $dstdir;
3846 }
3847
3848 sub clone ($) {
3849     # in multisuite, returns twice!
3850     # once in parent after first suite fetched,
3851     # and then again in child after everything is finished
3852     my ($dstdir) = @_;
3853     badusage __ "dry run makes no sense with clone" unless act_local();
3854
3855     my $multi_fetched = fork_for_multisuite(sub {
3856         printdebug "multi clone before fetch merge\n";
3857         changedir $dstdir;
3858         record_maindir();
3859     });
3860     if ($multi_fetched) {
3861         printdebug "multi clone after fetch merge\n";
3862         clone_set_head();
3863         clone_finish($dstdir);
3864         return;
3865     }
3866     printdebug "clone main body\n";
3867
3868     mkdir $dstdir or fail f_ "create \`%s': %s", $dstdir, $!;
3869     changedir $dstdir;
3870     check_bpd_exists();
3871
3872     canonicalise_suite();
3873     my $hasgit = check_for_git();
3874
3875     runcmd @git, qw(init -q);
3876     record_maindir();
3877     setup_new_tree();
3878     clone_set_head();
3879     my $giturl = access_giturl(1);
3880     if (defined $giturl) {
3881         runcmd @git, qw(remote add), 'origin', $giturl;
3882     }
3883     if ($hasgit) {
3884         progress __ "fetching existing git history";
3885         git_fetch_us();
3886         runcmd_ordryrun_local @git, qw(fetch origin);
3887     } else {
3888         progress __ "starting new git history";
3889     }
3890     fetch_from_archive() or no_such_package;
3891     my $vcsgiturl = $dsc->{'Vcs-Git'};
3892     if (length $vcsgiturl) {
3893         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3894         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3895     }
3896     clone_finish($dstdir);
3897 }
3898
3899 sub fetch_one () {
3900     canonicalise_suite();
3901     if (check_for_git()) {
3902         git_fetch_us();
3903     }
3904     fetch_from_archive() or no_such_package();
3905
3906     my $vcsgiturl = $dsc && $dsc->{'Vcs-Git'};
3907     if (length $vcsgiturl and
3908         (grep { $csuite eq $_ }
3909          split /\;/,
3910          cfg 'dgit.vcs-git.suites')) {
3911         my $current = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
3912         if (defined $current && $current ne $vcsgiturl) {
3913             print STDERR f_ <<END, $csuite;
3914 FYI: Vcs-Git in %s has different url to your vcs-git remote.
3915  Your vcs-git remote url may be out of date.  Use dgit update-vcs-git ?
3916 END
3917         }
3918     }
3919     printdone f_ "fetched into %s", lrref();
3920 }
3921
3922 sub dofetch () {
3923     my $multi_fetched = fork_for_multisuite(sub { });
3924     fetch_one() unless $multi_fetched; # parent
3925     finish 0 if $multi_fetched eq '0'; # child
3926 }
3927
3928 sub pull () {
3929     dofetch();
3930     runcmd_ordryrun_local @git, qw(merge -m),
3931         (f_ "Merge from %s [dgit]", $csuite),
3932         lrref();
3933     printdone f_ "fetched to %s and merged into HEAD", lrref();
3934 }
3935
3936 sub check_not_dirty () {
3937     my @forbid = qw(local-options local-patch-header);
3938     @forbid = map { "debian/source/$_" } @forbid;
3939     foreach my $f (@forbid) {
3940         if (stat_exists $f) {
3941             fail f_ "git tree contains %s", $f;
3942         }
3943     }
3944
3945     my @cmd = (@git, qw(status -uall --ignored --porcelain));
3946     push @cmd, qw(debian/source/format debian/source/options);
3947     push @cmd, @forbid;
3948
3949     my $bad = cmdoutput @cmd;
3950     if (length $bad) {
3951         fail +(__
3952  "you have uncommitted changes to critical files, cannot continue:\n").
3953               $bad;
3954     }
3955
3956     return if $includedirty;
3957
3958     git_check_unmodified();
3959 }
3960
3961 sub commit_admin ($) {
3962     my ($m) = @_;
3963     progress "$m";
3964     runcmd_ordryrun_local @git, qw(commit -m), $m;
3965 }
3966
3967 sub quiltify_nofix_bail ($$) {
3968     my ($headinfo, $xinfo) = @_;
3969     if ($quilt_mode eq 'nofix') {
3970         fail f_
3971             "quilt fixup required but quilt mode is \`nofix'\n".
3972             "HEAD commit%s differs from tree implied by debian/patches%s",
3973             $headinfo, $xinfo;
3974     }
3975 }
3976
3977 sub commit_quilty_patch () {
3978     my $output = cmdoutput @git, qw(status --ignored --porcelain);
3979     my %adds;
3980     foreach my $l (split /\n/, $output) {
3981         next unless $l =~ m/\S/;
3982         if ($l =~ m{^(?:[?!][?!]| [MADRC]) (.pc|debian/patches)}) {
3983             $adds{$1}++;
3984         }
3985     }
3986     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3987     if (!%adds) {
3988         progress __ "nothing quilty to commit, ok.";
3989         return;
3990     }
3991     quiltify_nofix_bail "", __ " (wanted to commit patch update)";
3992     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3993     runcmd_ordryrun_local @git, qw(add -f), @adds;
3994     commit_admin +(__ <<ENDT).<<END
3995 Commit Debian 3.0 (quilt) metadata
3996
3997 ENDT
3998 [dgit ($our_version) quilt-fixup]
3999 END
4000 }
4001
4002 sub get_source_format () {
4003     my %options;
4004     if (open F, "debian/source/options") {
4005         while (<F>) {
4006             next if m/^\s*\#/;
4007             next unless m/\S/;
4008             s/\s+$//; # ignore missing final newline
4009             if (m/\s*\#\s*/) {
4010                 my ($k, $v) = ($`, $'); #');
4011                 $v =~ s/^"(.*)"$/$1/;
4012                 $options{$k} = $v;
4013             } else {
4014                 $options{$_} = 1;
4015             }
4016         }
4017         F->error and confess "$!";
4018         close F;
4019     } else {
4020         confess "$!" unless $!==&ENOENT;
4021     }
4022
4023     if (!open F, "debian/source/format") {
4024         confess "$!" unless $!==&ENOENT;
4025         return '';
4026     }
4027     $_ = <F>;
4028     F->error and confess "$!";
4029     chomp;
4030     return ($_, \%options);
4031 }
4032
4033 sub madformat_wantfixup ($) {
4034     my ($format) = @_;
4035     return 0 unless $format eq '3.0 (quilt)';
4036     our $quilt_mode_warned;
4037     if ($quilt_mode eq 'nocheck') {
4038         progress f_ "Not doing any fixup of \`%s'".
4039             " due to ----no-quilt-fixup or --quilt=nocheck", $format
4040             unless $quilt_mode_warned++;
4041         return 0;
4042     }
4043     progress f_ "Format \`%s', need to check/update patch stack", $format
4044         unless $quilt_mode_warned++;
4045     return 1;
4046 }
4047
4048 sub maybe_split_brain_save ($$$) {
4049     my ($headref, $dgitview, $msg) = @_;
4050     # => message fragment "$saved" describing disposition of $dgitview
4051     #    (used inside parens, in the English texts)
4052     my $save = $internal_object_save{'dgit-view'};
4053     return f_ "commit id %s", $dgitview unless defined $save;
4054     my @cmd = (shell_cmd 'cd "$1"; shift', $maindir,
4055                git_update_ref_cmd
4056                "dgit --dgit-view-save $msg HEAD=$headref",
4057                $save, $dgitview);
4058     runcmd @cmd;
4059     return f_ "and left in %s", $save;
4060 }
4061
4062 # An "infopair" is a tuple [ $thing, $what ]
4063 # (often $thing is a commit hash; $what is a description)
4064
4065 sub infopair_cond_equal ($$) {
4066     my ($x,$y) = @_;
4067     $x->[0] eq $y->[0] or fail <<END;
4068 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
4069 END
4070 };
4071
4072 sub infopair_lrf_tag_lookup ($$) {
4073     my ($tagnames, $what) = @_;
4074     # $tagname may be an array ref
4075     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
4076     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
4077     foreach my $tagname (@tagnames) {
4078         my $lrefname = lrfetchrefs."/tags/$tagname";
4079         my $tagobj = $lrfetchrefs_f{$lrefname};
4080         next unless defined $tagobj;
4081         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
4082         return [ git_rev_parse($tagobj), $what ];
4083     }
4084     fail @tagnames==1 ? (f_ <<END, $what, "@tagnames")
4085 Wanted tag %s (%s) on dgit server, but not found
4086 END
4087                       : (f_ <<END, $what, "@tagnames");
4088 Wanted tag %s (one of: %s) on dgit server, but not found
4089 END
4090 }
4091
4092 sub infopair_cond_ff ($$) {
4093     my ($anc,$desc) = @_;
4094     is_fast_fwd($anc->[0], $desc->[0]) or
4095         fail f_ <<END, $anc->[1], $anc->[0], $desc->[1], $desc->[0];
4096 %s (%s) .. %s (%s) is not fast forward
4097 END
4098 };
4099
4100 sub pseudomerge_version_check ($$) {
4101     my ($clogp, $archive_hash) = @_;
4102
4103     my $arch_clogp = commit_getclogp $archive_hash;
4104     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
4105                      __ 'version currently in archive' ];
4106     if (defined $overwrite_version) {
4107         if (length $overwrite_version) {
4108             infopair_cond_equal([ $overwrite_version,
4109                                   '--overwrite= version' ],
4110                                 $i_arch_v);
4111         } else {
4112             my $v = $i_arch_v->[0];
4113             progress f_
4114                 "Checking package changelog for archive version %s ...", $v;
4115             my $cd;
4116             eval {
4117                 my @xa = ("-f$v", "-t$v");
4118                 my $vclogp = parsechangelog @xa;
4119                 my $gf = sub {
4120                     my ($fn) = @_;
4121                     [ (getfield $vclogp, $fn),
4122                       (f_ "%s field from dpkg-parsechangelog %s",
4123                           $fn, "@xa") ];
4124                 };
4125                 my $cv = $gf->('Version');
4126                 infopair_cond_equal($i_arch_v, $cv);
4127                 $cd = $gf->('Distribution');
4128             };
4129             if ($@) {
4130                 $@ =~ s/^\n//s;
4131                 $@ =~ s/^dgit: //gm;
4132                 fail "$@".
4133                     f_ "Perhaps debian/changelog does not mention %s ?", $v;
4134             }
4135             fail f_ <<END, $cd->[1], $cd->[0], $v
4136 %s is %s
4137 Your tree seems to based on earlier (not uploaded) %s.
4138 END
4139                 if $cd->[0] =~ m/UNRELEASED/;
4140         }
4141     }
4142
4143     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
4144     return $i_arch_v;
4145 }
4146
4147 sub pseudomerge_hash_commit ($$$$ $$) {
4148     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
4149         $msg_cmd, $msg_msg) = @_;
4150     progress f_ "Declaring that HEAD includes all changes in %s...",
4151                  $i_arch_v->[0];
4152
4153     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
4154     my $authline = clogp_authline $clogp;
4155
4156     chomp $msg_msg;
4157     $msg_cmd .=
4158         !defined $overwrite_version ? ""
4159         : !length  $overwrite_version ? " --overwrite"
4160         : " --overwrite=".$overwrite_version;
4161
4162     # Contributing parent is the first parent - that makes
4163     # git rev-list --first-parent DTRT.
4164     my $pmf = dgit_privdir()."/pseudomerge";
4165     open MC, ">", $pmf or die "$pmf $!";
4166     print MC <<END or confess "$!";
4167 tree $tree
4168 parent $dgitview
4169 parent $archive_hash
4170 author $authline
4171 committer $authline
4172
4173 $msg_msg
4174
4175 [$msg_cmd]
4176 END
4177     close MC or confess "$!";
4178
4179     return hash_commit($pmf);
4180 }
4181
4182 sub splitbrain_pseudomerge ($$$$) {
4183     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
4184     # => $merged_dgitview
4185     printdebug "splitbrain_pseudomerge...\n";
4186     #
4187     #     We:      debian/PREVIOUS    HEAD($maintview)
4188     # expect:          o ----------------- o
4189     #                    \                   \
4190     #                     o                   o
4191     #                 a/d/PREVIOUS        $dgitview
4192     #                $archive_hash              \
4193     #  If so,                \                   \
4194     #  we do:                 `------------------ o
4195     #   this:                                   $dgitview'
4196     #
4197
4198     return $dgitview unless defined $archive_hash;
4199     return $dgitview if deliberately_not_fast_forward();
4200
4201     printdebug "splitbrain_pseudomerge...\n";
4202
4203     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4204
4205     if (!defined $overwrite_version) {
4206         progress __ "Checking that HEAD includes all changes in archive...";
4207     }
4208
4209     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
4210
4211     if (defined $overwrite_version) {
4212     } elsif (!eval {
4213         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
4214         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14,
4215                                               __ "maintainer view tag");
4216         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
4217         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, __ "dgit view tag");
4218         my $i_archive = [ $archive_hash, __ "current archive contents" ];
4219
4220         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
4221
4222         infopair_cond_equal($i_dgit, $i_archive);
4223         infopair_cond_ff($i_dep14, $i_dgit);
4224         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
4225         1;
4226     }) {
4227         $@ =~ s/^\n//; chomp $@;
4228         print STDERR <<END.(__ <<ENDT);
4229 $@
4230 END
4231 | Not fast forward; maybe --overwrite is needed ?  Please see dgit(1).
4232 ENDT
4233         finish -1;
4234     }
4235
4236     my $arch_v = $i_arch_v->[0];
4237     my $r = pseudomerge_hash_commit
4238         $clogp, $dgitview, $archive_hash, $i_arch_v,
4239         "dgit --quilt=$quilt_mode",
4240         (defined $overwrite_version
4241          ? f_ "Declare fast forward from %s\n", $arch_v
4242          : f_ "Make fast forward from %s\n",    $arch_v);
4243
4244     maybe_split_brain_save $maintview, $r, "pseudomerge";
4245
4246     progress f_ "Made pseudo-merge of %s into dgit view.", $arch_v;
4247     return $r;
4248 }
4249
4250 sub plain_overwrite_pseudomerge ($$$) {
4251     my ($clogp, $head, $archive_hash) = @_;
4252
4253     printdebug "plain_overwrite_pseudomerge...";
4254
4255     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
4256
4257     return $head if is_fast_fwd $archive_hash, $head;
4258
4259     my $m = f_ "Declare fast forward from %s", $i_arch_v->[0];
4260
4261     my $r = pseudomerge_hash_commit
4262         $clogp, $head, $archive_hash, $i_arch_v,
4263         "dgit", $m;
4264
4265     runcmd git_update_ref_cmd $m, 'HEAD', $r, $head;
4266
4267     progress f_ "Make pseudo-merge of %s into your HEAD.", $i_arch_v->[0];
4268     return $r;
4269 }
4270
4271 sub push_parse_changelog ($) {
4272     my ($clogpfn) = @_;
4273
4274     my $clogp = Dpkg::Control::Hash->new();
4275     $clogp->load($clogpfn) or die;
4276
4277     my $clogpackage = getfield $clogp, 'Source';
4278     $package //= $clogpackage;
4279     fail f_ "-p specified %s but changelog specified %s",
4280             $package, $clogpackage
4281         unless $package eq $clogpackage;
4282     my $cversion = getfield $clogp, 'Version';
4283
4284     if (!$we_are_initiator) {
4285         # rpush initiator can't do this because it doesn't have $isuite yet
4286         my $tag = debiantag_new($cversion, access_nomdistro);
4287         runcmd @git, qw(check-ref-format), $tag;
4288     }
4289
4290     my $dscfn = dscfn($cversion);
4291
4292     return ($clogp, $cversion, $dscfn);
4293 }
4294
4295 sub push_parse_dsc ($$$) {
4296     my ($dscfn,$dscfnwhat, $cversion) = @_;
4297     $dsc = parsecontrol($dscfn,$dscfnwhat);
4298     my $dversion = getfield $dsc, 'Version';
4299     my $dscpackage = getfield $dsc, 'Source';
4300     ($dscpackage eq $package && $dversion eq $cversion) or
4301         fail f_ "%s is for %s %s but debian/changelog is for %s %s",
4302                 $dscfn, $dscpackage, $dversion,
4303                         $package,    $cversion;
4304 }
4305
4306 sub push_tagwants ($$$$) {
4307     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
4308     my @tagwants;
4309     push @tagwants, {
4310         TagFn => \&debiantag_new,
4311         Objid => $dgithead,
4312         TfSuffix => '',
4313         View => 'dgit',
4314     };
4315     if (defined $maintviewhead) {
4316         push @tagwants, {
4317             TagFn => \&debiantag_maintview,
4318             Objid => $maintviewhead,
4319             TfSuffix => '-maintview',
4320             View => 'maint',
4321         };
4322     } elsif ($dodep14tag ne 'no') {
4323         push @tagwants, {
4324             TagFn => \&debiantag_maintview,
4325             Objid => $dgithead,
4326             TfSuffix => '-dgit',
4327             View => 'dgit',
4328         };
4329     };
4330     foreach my $tw (@tagwants) {
4331         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
4332         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
4333     }
4334     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
4335     return @tagwants;
4336 }
4337
4338 sub push_mktags ($$ $$ $) {
4339     my ($clogp,$dscfn,
4340         $changesfile,$changesfilewhat,
4341         $tagwants) = @_;
4342
4343     die unless $tagwants->[0]{View} eq 'dgit';
4344
4345     my $declaredistro = access_nomdistro();
4346     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
4347     $dsc->{$ourdscfield[0]} = join " ",
4348         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
4349         $reader_giturl;
4350     $dsc->save("$dscfn.tmp") or confess "$!";
4351
4352     my $changes = parsecontrol($changesfile,$changesfilewhat);
4353     foreach my $field (qw(Source Distribution Version)) {
4354         $changes->{$field} eq $clogp->{$field} or
4355             fail f_ "changes field %s \`%s' does not match changelog \`%s'",
4356                     $field, $changes->{$field}, $clogp->{$field};
4357     }
4358
4359     my $cversion = getfield $clogp, 'Version';
4360     my $clogsuite = getfield $clogp, 'Distribution';
4361     my $format = getfield $dsc, 'Format';
4362
4363     # We make the git tag by hand because (a) that makes it easier
4364     # to control the "tagger" (b) we can do remote signing
4365     my $authline = clogp_authline $clogp;
4366
4367     my $mktag = sub {
4368         my ($tw) = @_;
4369         my $tfn = $tw->{Tfn};
4370         my $head = $tw->{Objid};
4371         my $tag = $tw->{Tag};
4372
4373         open TO, '>', $tfn->('.tmp') or confess "$!";
4374         print TO <<END or confess "$!";
4375 object $head
4376 type commit
4377 tag $tag
4378 tagger $authline
4379
4380 END
4381
4382         my @dtxinfo = @deliberatelies;
4383         unshift @dtxinfo, "--quilt=$quilt_mode" if madformat($format);
4384         unshift @dtxinfo, do_split_brain() ? "split" : "no-split"
4385             # rpush protocol 5 and earlier don't tell us
4386             unless $we_are_initiator && $protovsn < 6;
4387         my $dtxinfo = join(" ", "",@dtxinfo);
4388         my $tag_metadata = <<END;
4389 [dgit distro=$declaredistro$dtxinfo]
4390 END
4391         foreach my $ref (sort keys %previously) {
4392             $tag_metadata .= <<END or confess "$!";
4393 [dgit previously:$ref=$previously{$ref}]
4394 END
4395         }
4396
4397         if ($tw->{View} eq 'dgit') {
4398             print TO f_ <<ENDT, $package, $cversion, $clogsuite, $csuite
4399 %s release %s for %s (%s) [dgit]
4400 ENDT
4401                 or confess "$!";
4402         } elsif ($tw->{View} eq 'maint') {
4403             print TO f_ <<END, $package, $cversion, $clogsuite, $csuite,
4404 %s release %s for %s (%s)
4405
4406 (maintainer view tag generated by dgit --quilt=%s)
4407 END
4408                 $quilt_mode
4409                 or confess "$!";
4410         } else {
4411             confess Dumper($tw)."?";
4412         }
4413         print TO "\n", $tag_metadata;
4414
4415         close TO or confess "$!";
4416
4417         my $tagobjfn = $tfn->('.tmp');
4418         if ($sign) {
4419             if (!defined $keyid) {
4420                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4421             }
4422             if (!defined $keyid) {
4423                 $keyid = getfield $clogp, 'Maintainer';
4424             }
4425             unlink $tfn->('.tmp.asc') or $!==&ENOENT or confess "$!";
4426             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4427             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4428             push @sign_cmd, $tfn->('.tmp');
4429             runcmd_ordryrun @sign_cmd;
4430             if (act_scary()) {
4431                 $tagobjfn = $tfn->('.signed.tmp');
4432                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4433                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4434             }
4435         }
4436         return $tagobjfn;
4437     };
4438
4439     my @r = map { $mktag->($_); } @$tagwants;
4440     return @r;
4441 }
4442
4443 sub sign_changes ($) {
4444     my ($changesfile) = @_;
4445     if ($sign) {
4446         my @debsign_cmd = @debsign;
4447         push @debsign_cmd, "-k$keyid" if defined $keyid;
4448         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4449         push @debsign_cmd, $changesfile;
4450         runcmd_ordryrun @debsign_cmd;
4451     }
4452 }
4453
4454 sub dopush () {
4455     printdebug "actually entering push\n";
4456
4457     supplementary_message(__ <<'END');
4458 Push failed, while checking state of the archive.
4459 You can retry the push, after fixing the problem, if you like.
4460 END
4461     if (check_for_git()) {
4462         git_fetch_us();
4463     }
4464     my $archive_hash = fetch_from_archive();
4465     if (!$archive_hash) {
4466         $new_package or
4467             fail __ "package appears to be new in this suite;".
4468                     " if this is intentional, use --new";
4469     }
4470
4471     supplementary_message(__ <<'END');
4472 Push failed, while preparing your push.
4473 You can retry the push, after fixing the problem, if you like.
4474 END
4475
4476     prep_ud();
4477
4478     access_giturl(); # check that success is vaguely likely
4479     rpush_handle_protovsn_bothends() if $we_are_initiator;
4480
4481     my $clogpfn = dgit_privdir()."/changelog.822.tmp";
4482     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4483
4484     responder_send_file('parsed-changelog', $clogpfn);
4485
4486     my ($clogp, $cversion, $dscfn) =
4487         push_parse_changelog("$clogpfn");
4488
4489     my $dscpath = "$buildproductsdir/$dscfn";
4490     stat_exists $dscpath or
4491         fail f_ "looked for .dsc %s, but %s; maybe you forgot to build",
4492                 $dscpath, $!;
4493
4494     responder_send_file('dsc', $dscpath);
4495
4496     push_parse_dsc($dscpath, $dscfn, $cversion);
4497
4498     my $format = getfield $dsc, 'Format';
4499
4500     my $symref = git_get_symref();
4501     my $actualhead = git_rev_parse('HEAD');
4502
4503     if (branch_is_gdr_unstitched_ff($symref, $actualhead, $archive_hash)) {
4504         if (quiltmode_splitting()) {
4505             my ($ffq_prev, $gdrlast) = branch_gdr_info($symref, $actualhead);
4506             fail f_ <<END, $ffq_prev, $quilt_mode;
4507 Branch is managed by git-debrebase (%s
4508 exists), but quilt mode (%s) implies a split view.
4509 Pass the right --quilt option or adjust your git config.
4510 Or, maybe, run git-debrebase forget-was-ever-debrebase.
4511 END
4512         }
4513         runcmd_ordryrun_local @git_debrebase, 'stitch';
4514         $actualhead = git_rev_parse('HEAD');
4515     }
4516
4517     my $dgithead = $actualhead;
4518     my $maintviewhead = undef;
4519
4520     my $upstreamversion = upstreamversion $clogp->{Version};
4521
4522     if (madformat_wantfixup($format)) {
4523         # user might have not used dgit build, so maybe do this now:
4524         if (do_split_brain()) {
4525             changedir $playground;
4526             my $cachekey;
4527             ($dgithead, $cachekey) =
4528                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4529             $dgithead or fail f_
4530  "--quilt=%s but no cached dgit view:
4531  perhaps HEAD changed since dgit build[-source] ?",
4532                               $quilt_mode;
4533         }
4534         if (!do_split_brain()) {
4535             # In split brain mode, do not attempt to incorporate dirty
4536             # stuff from the user's working tree.  That would be mad.
4537             commit_quilty_patch();
4538         }
4539     }
4540     if (do_split_brain()) {
4541         $made_split_brain = 1;
4542         $dgithead = splitbrain_pseudomerge($clogp,
4543                                            $actualhead, $dgithead,
4544                                            $archive_hash);
4545         $maintviewhead = $actualhead;
4546         changedir $maindir;
4547         prep_ud(); # so _only_subdir() works, below
4548     }
4549
4550     if (defined $overwrite_version && !defined $maintviewhead
4551         && $archive_hash) {
4552         $dgithead = plain_overwrite_pseudomerge($clogp,
4553                                                 $dgithead,
4554                                                 $archive_hash);
4555     }
4556
4557     check_not_dirty();
4558
4559     my $forceflag = '';
4560     if ($archive_hash) {
4561         if (is_fast_fwd($archive_hash, $dgithead)) {
4562             # ok
4563         } elsif (deliberately_not_fast_forward) {
4564             $forceflag = '+';
4565         } else {
4566             fail __ "dgit push: HEAD is not a descendant".
4567                 " of the archive's version.\n".
4568                 "To overwrite the archive's contents,".
4569                 " pass --overwrite[=VERSION].\n".
4570                 "To rewind history, if permitted by the archive,".
4571                 " use --deliberately-not-fast-forward.";
4572         }
4573     }
4574
4575     confess unless !!$made_split_brain == do_split_brain();
4576
4577     changedir $playground;
4578     progress f_ "checking that %s corresponds to HEAD", $dscfn;
4579     runcmd qw(dpkg-source -x --),
4580         $dscpath =~ m#^/# ? $dscpath : "$maindir/$dscpath";
4581     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4582     check_for_vendor_patches() if madformat($dsc->{format});
4583     changedir $maindir;
4584     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4585     debugcmd "+",@diffcmd;
4586     $!=0; $?=-1;
4587     my $r = system @diffcmd;
4588     if ($r) {
4589         if ($r==256) {
4590             my $referent = $made_split_brain ? $dgithead : 'HEAD';
4591             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4592
4593             my @mode_changes;
4594             my $raw = cmdoutput @git,
4595                 qw(diff --no-renames -z -r --raw), $tree, $dgithead;
4596             my $changed;
4597             foreach (split /\0/, $raw) {
4598                 if (defined $changed) {
4599                     push @mode_changes, "$changed: $_\n" if $changed;
4600                     $changed = undef;
4601                     next;
4602                 } elsif (m/^:0+ 0+ /) {
4603                     $changed = '';
4604                 } elsif (m/^:(?:10*)?(\d+) (?:10*)?(\d+) /) {
4605                     $changed = "Mode change from $1 to $2"
4606                 } else {
4607                     die "$_ ?";
4608                 }
4609             }
4610             if (@mode_changes) {
4611                 fail +(f_ <<ENDT, $dscfn).<<END
4612 HEAD specifies a different tree to %s:
4613 ENDT
4614 $diffs
4615 END
4616                     .(join '', @mode_changes)
4617                     .(f_ <<ENDT, $tree, $referent);
4618 There is a problem with your source tree (see dgit(7) for some hints).
4619 To see a full diff, run git diff %s %s
4620 ENDT
4621             }
4622
4623             fail +(f_ <<ENDT, $dscfn).<<END.(f_ <<ENDT, $tree, $referent);
4624 HEAD specifies a different tree to %s:
4625 ENDT
4626 $diffs
4627 END
4628 Perhaps you forgot to build.  Or perhaps there is a problem with your
4629  source tree (see dgit(7) for some hints).  To see a full diff, run
4630    git diff %s %s
4631 ENDT
4632         } else {
4633             failedcmd @diffcmd;
4634         }
4635     }
4636     if (!$changesfile) {
4637         my $pat = changespat $cversion;
4638         my @cs = glob "$buildproductsdir/$pat";
4639         fail f_ "failed to find unique changes file".
4640                 " (looked for %s in %s);".
4641                 " perhaps you need to use dgit -C",
4642                 $pat, $buildproductsdir
4643             unless @cs==1;
4644         ($changesfile) = @cs;
4645     } else {
4646         $changesfile = "$buildproductsdir/$changesfile";
4647     }
4648
4649     # Check that changes and .dsc agree enough
4650     $changesfile =~ m{[^/]*$};
4651     my $changes = parsecontrol($changesfile,$&);
4652     files_compare_inputs($dsc, $changes)
4653         unless forceing [qw(dsc-changes-mismatch)];
4654
4655     # Check whether this is a source only upload
4656     my $hasdebs = $changes->{Files} =~ m{\.deb$}m;
4657     my $sourceonlypolicy = access_cfg 'source-only-uploads';
4658     if ($sourceonlypolicy eq 'ok') {
4659     } elsif ($sourceonlypolicy eq 'always') {
4660         forceable_fail [qw(uploading-binaries)],
4661             __ "uploading binaries, although distro policy is source only"
4662             if $hasdebs;
4663     } elsif ($sourceonlypolicy eq 'never') {
4664         forceable_fail [qw(uploading-source-only)],
4665             __ "source-only upload, although distro policy requires .debs"
4666             if !$hasdebs;
4667     } elsif ($sourceonlypolicy eq 'not-wholly-new') {
4668         forceable_fail [qw(uploading-source-only)],
4669             f_ "source-only upload, even though package is entirely NEW\n".
4670                "(this is contrary to policy in %s)",
4671                access_nomdistro()
4672             if !$hasdebs
4673             && $new_package
4674             && !(archive_query('package_not_wholly_new', $package) // 1);
4675     } else {
4676         badcfg f_ "unknown source-only-uploads policy \`%s'",
4677                   $sourceonlypolicy;
4678     }
4679
4680     # Perhaps adjust .dsc to contain right set of origs
4681     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4682                                   $changesfile)
4683         unless forceing [qw(changes-origs-exactly)];
4684
4685     # Checks complete, we're going to try and go ahead:
4686
4687     responder_send_file('changes',$changesfile);
4688     responder_send_command("param head $dgithead");
4689     responder_send_command("param csuite $csuite");
4690     responder_send_command("param isuite $isuite");
4691     responder_send_command("param tagformat new"); # needed in $protovsn==4
4692     responder_send_command("param splitbrain $do_split_brain");
4693     if (defined $maintviewhead) {
4694         responder_send_command("param maint-view $maintviewhead");
4695     }
4696
4697     # Perhaps send buildinfo(s) for signing
4698     my $changes_files = getfield $changes, 'Files';
4699     my @buildinfos = ($changes_files =~ m/ .* (\S+\.buildinfo)$/mg);
4700     foreach my $bi (@buildinfos) {
4701         responder_send_command("param buildinfo-filename $bi");
4702         responder_send_file('buildinfo', "$buildproductsdir/$bi");
4703     }
4704
4705     if (deliberately_not_fast_forward) {
4706         git_for_each_ref(lrfetchrefs, sub {
4707             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4708             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4709             responder_send_command("previously $rrefname=$objid");
4710             $previously{$rrefname} = $objid;
4711         });
4712     }
4713
4714     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4715                                  dgit_privdir()."/tag");
4716     my @tagobjfns;
4717
4718     supplementary_message(__ <<'END');
4719 Push failed, while signing the tag.
4720 You can retry the push, after fixing the problem, if you like.
4721 END
4722     # If we manage to sign but fail to record it anywhere, it's fine.
4723     if ($we_are_responder) {
4724         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4725         responder_receive_files('signed-tag', @tagobjfns);
4726     } else {
4727         @tagobjfns = push_mktags($clogp,$dscpath,
4728                               $changesfile,$changesfile,
4729                               \@tagwants);
4730     }
4731     supplementary_message(__ <<'END');
4732 Push failed, *after* signing the tag.
4733 If you want to try again, you should use a new version number.
4734 END
4735
4736     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4737
4738     foreach my $tw (@tagwants) {
4739         my $tag = $tw->{Tag};
4740         my $tagobjfn = $tw->{TagObjFn};
4741         my $tag_obj_hash =
4742             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4743         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4744         runcmd_ordryrun_local
4745             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4746     }
4747
4748     supplementary_message(__ <<'END');
4749 Push failed, while updating the remote git repository - see messages above.
4750 If you want to try again, you should use a new version number.
4751 END
4752     if (!check_for_git()) {
4753         create_remote_git_repo();
4754     }
4755
4756     my @pushrefs = $forceflag.$dgithead.":".rrref();
4757     foreach my $tw (@tagwants) {
4758         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4759     }
4760
4761     runcmd_ordryrun @git,
4762         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4763     runcmd_ordryrun git_update_ref_cmd 'dgit push', lrref(), $dgithead;
4764
4765     supplementary_message(__ <<'END');
4766 Push failed, while obtaining signatures on the .changes and .dsc.
4767 If it was just that the signature failed, you may try again by using
4768 debsign by hand to sign the changes file (see the command dgit tried,
4769 above), and then dput that changes file to complete the upload.
4770 If you need to change the package, you must use a new version number.
4771 END
4772     if ($we_are_responder) {
4773         my $dryrunsuffix = act_local() ? "" : ".tmp";
4774         my @rfiles = ($dscpath, $changesfile);
4775         push @rfiles, map { "$buildproductsdir/$_" } @buildinfos;
4776         responder_receive_files('signed-dsc-changes',
4777                                 map { "$_$dryrunsuffix" } @rfiles);
4778     } else {
4779         if (act_local()) {
4780             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4781         } else {
4782             progress f_ "[new .dsc left in %s.tmp]", $dscpath;
4783         }
4784         sign_changes $changesfile;
4785     }
4786
4787     supplementary_message(f_ <<END, $changesfile);
4788 Push failed, while uploading package(s) to the archive server.
4789 You can retry the upload of exactly these same files with dput of:
4790   %s
4791 If that .changes file is broken, you will need to use a new version
4792 number for your next attempt at the upload.
4793 END
4794     my $host = access_cfg('upload-host','RETURN-UNDEF');
4795     my @hostarg = defined($host) ? ($host,) : ();
4796     runcmd_ordryrun @dput, @hostarg, $changesfile;
4797     printdone f_ "pushed and uploaded %s", $cversion;
4798
4799     supplementary_message('');
4800     responder_send_command("complete");
4801 }
4802
4803 sub pre_clone () {
4804     not_necessarily_a_tree();
4805 }
4806 sub cmd_clone {
4807     parseopts();
4808     my $dstdir;
4809     badusage __ "-p is not allowed with clone; specify as argument instead"
4810         if defined $package;
4811     if (@ARGV==1) {
4812         ($package) = @ARGV;
4813     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4814         ($package,$isuite) = @ARGV;
4815     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4816         ($package,$dstdir) = @ARGV;
4817     } elsif (@ARGV==3) {
4818         ($package,$isuite,$dstdir) = @ARGV;
4819     } else {
4820         badusage __ "incorrect arguments to dgit clone";
4821     }
4822     notpushing();
4823
4824     $dstdir ||= "$package";
4825     if (stat_exists $dstdir) {
4826         fail f_ "%s already exists", $dstdir;
4827     }
4828
4829     my $cwd_remove;
4830     if ($rmonerror && !$dryrun_level) {
4831         $cwd_remove= getcwd();
4832         unshift @end, sub {
4833             return unless defined $cwd_remove;
4834             if (!chdir "$cwd_remove") {
4835                 return if $!==&ENOENT;
4836                 confess "chdir $cwd_remove: $!";
4837             }
4838             printdebug "clone rmonerror removing $dstdir\n";
4839             if (stat $dstdir) {
4840                 rmtree($dstdir) or fail f_ "remove %s: %s\n", $dstdir, $!;
4841             } elsif (grep { $! == $_ }
4842                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4843             } else {
4844                 print STDERR f_ "check whether to remove %s: %s\n",
4845                                 $dstdir, $!;
4846             }
4847         };
4848     }
4849
4850     clone($dstdir);
4851     $cwd_remove = undef;
4852 }
4853
4854 sub branchsuite () {
4855     my $branch = git_get_symref();
4856     if (defined $branch && $branch =~ m#$lbranch_re#o) {
4857         return $1;
4858     } else {
4859         return undef;
4860     }
4861 }
4862
4863 sub package_from_d_control () {
4864     if (!defined $package) {
4865         my $sourcep = parsecontrol('debian/control','debian/control');
4866         $package = getfield $sourcep, 'Source';
4867     }
4868 }
4869
4870 sub fetchpullargs () {
4871     package_from_d_control();
4872     if (@ARGV==0) {
4873         $isuite = branchsuite();
4874         if (!$isuite) {
4875             my $clogp = parsechangelog();
4876             my $clogsuite = getfield $clogp, 'Distribution';
4877             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4878         }
4879     } elsif (@ARGV==1) {
4880         ($isuite) = @ARGV;
4881     } else {
4882         badusage __ "incorrect arguments to dgit fetch or dgit pull";
4883     }
4884     notpushing();
4885 }
4886
4887 sub cmd_fetch {
4888     parseopts();
4889     fetchpullargs();
4890     dofetch();
4891 }
4892
4893 sub cmd_pull {
4894     parseopts();
4895     fetchpullargs();
4896     determine_whether_split_brain get_source_format();
4897     if (do_split_brain()) {
4898         my ($format, $fopts) = get_source_format();
4899         madformat($format) and fail f_ <<END, $quilt_mode
4900 dgit pull not yet supported in split view mode (including with view-splitting quilt modes)
4901 END
4902     }
4903     pull();
4904 }
4905
4906 sub cmd_checkout {
4907     parseopts();
4908     package_from_d_control();
4909     @ARGV==1 or badusage __ "dgit checkout needs a suite argument";
4910     ($isuite) = @ARGV;
4911     notpushing();
4912
4913     foreach my $canon (qw(0 1)) {
4914         if (!$canon) {
4915             $csuite= $isuite;
4916         } else {
4917             undef $csuite;
4918             canonicalise_suite();
4919         }
4920         if (length git_get_ref lref()) {
4921             # local branch already exists, yay
4922             last;
4923         }
4924         if (!length git_get_ref lrref()) {
4925             if (!$canon) {
4926                 # nope
4927                 next;
4928             }
4929             dofetch();
4930         }
4931         # now lrref exists
4932         runcmd (@git, qw(update-ref), lref(), lrref(), '');
4933         last;
4934     }
4935     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
4936         "dgit checkout $isuite";
4937     runcmd (@git, qw(checkout), lbranch());
4938 }
4939
4940 sub cmd_update_vcs_git () {
4941     my $specsuite;
4942     if (@ARGV==0 || $ARGV[0] =~ m/^-/) {
4943         ($specsuite,) = split /\;/, cfg 'dgit.vcs-git.suites';
4944     } else {
4945         ($specsuite) = (@ARGV);
4946         shift @ARGV;
4947     }
4948     my $dofetch=1;
4949     if (@ARGV) {
4950         if ($ARGV[0] eq '-') {
4951             $dofetch = 0;
4952         } elsif ($ARGV[0] eq '-') {
4953             shift;
4954         }
4955     }
4956
4957     package_from_d_control();
4958     my $ctrl;
4959     if ($specsuite eq '.') {
4960         $ctrl = parsecontrol 'debian/control', 'debian/control';
4961     } else {
4962         $isuite = $specsuite;
4963         get_archive_dsc();
4964         $ctrl = $dsc;
4965     }
4966     my $url = getfield $ctrl, 'Vcs-Git';
4967
4968     my @cmd;
4969     my $orgurl = cfg 'remote.vcs-git.url', 'RETURN-UNDEF';
4970     if (!defined $orgurl) {
4971         print STDERR f_ "setting up vcs-git: %s\n", $url;
4972         @cmd = (@git, qw(remote add vcs-git), $url);
4973     } elsif ($orgurl eq $url) {
4974         print STDERR f_ "vcs git already configured: %s\n", $url;
4975     } else {
4976         print STDERR f_ "changing vcs-git url to: %s\n", $url;
4977         @cmd = (@git, qw(remote set-url vcs-git), $url);
4978     }
4979     runcmd_ordryrun_local @cmd;
4980     if ($dofetch) {
4981         print f_ "fetching (%s)\n", "@ARGV";
4982         runcmd_ordryrun_local @git, qw(fetch vcs-git), @ARGV;
4983     }
4984 }
4985
4986 sub prep_push () {
4987     parseopts();
4988     build_or_push_prep_early();
4989     pushing();
4990     build_or_push_prep_modes();
4991     check_not_dirty();
4992     my $specsuite;
4993     if (@ARGV==0) {
4994     } elsif (@ARGV==1) {
4995         ($specsuite) = (@ARGV);
4996     } else {
4997         badusage f_ "incorrect arguments to dgit %s", $subcommand;
4998     }
4999     if ($new_package) {
5000         local ($package) = $existing_package; # this is a hack
5001         canonicalise_suite();
5002     } else {
5003         canonicalise_suite();
5004     }
5005     if (defined $specsuite &&
5006         $specsuite ne $isuite &&
5007         $specsuite ne $csuite) {
5008             fail f_ "dgit %s: changelog specifies %s (%s)".
5009                     " but command line specifies %s",
5010                     $subcommand, $isuite, $csuite, $specsuite;
5011     }
5012 }
5013
5014 sub cmd_push {
5015     prep_push();
5016     dopush();
5017 }
5018
5019 #---------- remote commands' implementation ----------
5020
5021 sub pre_remote_push_build_host {
5022     my ($nrargs) = shift @ARGV;
5023     my (@rargs) = @ARGV[0..$nrargs-1];
5024     @ARGV = @ARGV[$nrargs..$#ARGV];
5025     die unless @rargs;
5026     my ($dir,$vsnwant) = @rargs;
5027     # vsnwant is a comma-separated list; we report which we have
5028     # chosen in our ready response (so other end can tell if they
5029     # offered several)
5030     $debugprefix = ' ';
5031     $we_are_responder = 1;
5032     $us .= " (build host)";
5033
5034     open PI, "<&STDIN" or confess "$!";
5035     open STDIN, "/dev/null" or confess "$!";
5036     open PO, ">&STDOUT" or confess "$!";
5037     autoflush PO 1;
5038     open STDOUT, ">&STDERR" or confess "$!";
5039     autoflush STDOUT 1;
5040
5041     $vsnwant //= 1;
5042     ($protovsn) = grep {
5043         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
5044     } @rpushprotovsn_support;
5045
5046     fail f_ "build host has dgit rpush protocol versions %s".
5047             " but invocation host has %s",
5048             (join ",", @rpushprotovsn_support), $vsnwant
5049         unless defined $protovsn;
5050
5051     changedir $dir;
5052 }
5053 sub cmd_remote_push_build_host {
5054     responder_send_command("dgit-remote-push-ready $protovsn");
5055     &cmd_push;
5056 }
5057
5058 sub pre_remote_push_responder { pre_remote_push_build_host(); }
5059 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
5060 # ... for compatibility with proto vsn.1 dgit (just so that user gets
5061 #     a good error message)
5062
5063 sub rpush_handle_protovsn_bothends () {
5064 }
5065
5066 our $i_tmp;
5067
5068 sub i_cleanup {
5069     local ($@, $?);
5070     my $report = i_child_report();
5071     if (defined $report) {
5072         printdebug "($report)\n";
5073     } elsif ($i_child_pid) {
5074         printdebug "(killing build host child $i_child_pid)\n";
5075         kill 15, $i_child_pid;
5076     }
5077     if (defined $i_tmp && !defined $initiator_tempdir) {
5078         changedir "/";
5079         eval { rmtree $i_tmp; };
5080     }
5081 }
5082
5083 END {
5084     return unless forkcheck_mainprocess();
5085     i_cleanup();
5086 }
5087
5088 sub i_method {
5089     my ($base,$selector,@args) = @_;
5090     $selector =~ s/\-/_/g;
5091     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
5092 }
5093
5094 sub pre_rpush () {
5095     not_necessarily_a_tree();
5096 }
5097 sub cmd_rpush {
5098     my $host = nextarg;
5099     my $dir;
5100     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
5101         $host = $1;
5102         $dir = $'; #';
5103     } else {
5104         $dir = nextarg;
5105     }
5106     $dir =~ s{^-}{./-};
5107     my @rargs = ($dir);
5108     push @rargs, join ",", @rpushprotovsn_support;
5109     my @rdgit;
5110     push @rdgit, @dgit;
5111     push @rdgit, @ropts;
5112     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
5113     push @rdgit, @ARGV;
5114     my @cmd = (@ssh, $host, shellquote @rdgit);
5115     debugcmd "+",@cmd;
5116
5117     $we_are_initiator=1;
5118
5119     if (defined $initiator_tempdir) {
5120         rmtree $initiator_tempdir;
5121         mkdir $initiator_tempdir, 0700
5122             or fail f_ "create %s: %s", $initiator_tempdir, $!;
5123         $i_tmp = $initiator_tempdir;
5124     } else {
5125         $i_tmp = tempdir();
5126     }
5127     $i_child_pid = open2(\*RO, \*RI, @cmd);
5128     changedir $i_tmp;
5129     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
5130     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
5131
5132     for (;;) {
5133         my ($icmd,$iargs) = initiator_expect {
5134             m/^(\S+)(?: (.*))?$/;
5135             ($1,$2);
5136         };
5137         i_method "i_resp", $icmd, $iargs;
5138     }
5139 }
5140
5141 sub i_resp_progress ($) {
5142     my ($rhs) = @_;
5143     my $msg = protocol_read_bytes \*RO, $rhs;
5144     progress $msg;
5145 }
5146
5147 sub i_resp_supplementary_message ($) {
5148     my ($rhs) = @_;
5149     $supplementary_message = protocol_read_bytes \*RO, $rhs;
5150 }
5151
5152 sub i_resp_complete {
5153     my $pid = $i_child_pid;
5154     $i_child_pid = undef; # prevents killing some other process with same pid
5155     printdebug "waiting for build host child $pid...\n";
5156     my $got = waitpid $pid, 0;
5157     confess "$!" unless $got == $pid;
5158     fail f_ "build host child failed: %s", waitstatusmsg() if $?;
5159
5160     i_cleanup();
5161     printdebug __ "all done\n";
5162     finish 0;
5163 }
5164
5165 sub i_resp_file ($) {
5166     my ($keyword) = @_;
5167     my $localname = i_method "i_localname", $keyword;
5168     my $localpath = "$i_tmp/$localname";
5169     stat_exists $localpath and
5170         badproto \*RO, f_ "file %s (%s) twice", $keyword, $localpath;
5171     protocol_receive_file \*RO, $localpath;
5172     i_method "i_file", $keyword;
5173 }
5174
5175 our %i_param;
5176
5177 sub i_resp_param ($) {
5178     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, __ "bad param spec";
5179     $i_param{$1} = $2;
5180 }
5181
5182 sub i_resp_previously ($) {
5183     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
5184         or badproto \*RO, __ "bad previously spec";
5185     my $r = system qw(git check-ref-format), $1;
5186     confess "bad previously ref spec ($r)" if $r;
5187     $previously{$1} = $2;
5188 }
5189
5190 our %i_wanted;
5191 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn, @i_buildinfos);
5192
5193 sub i_resp_want ($) {
5194     my ($keyword) = @_;
5195     die "$keyword ?" if $i_wanted{$keyword}++;
5196
5197     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
5198     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
5199     die unless $isuite =~ m/^$suite_re$/;
5200
5201     if (!defined $dsc) {
5202         pushing();
5203         rpush_handle_protovsn_bothends();
5204         push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
5205         if ($protovsn >= 6) {
5206             determine_whether_split_brain getfield $dsc, 'Format';
5207             $do_split_brain eq ($i_param{'splitbrain'} // '<unsent>')
5208                 or badproto \*RO,
5209  "split brain mismatch, $do_split_brain != $i_param{'split_brain'}";
5210             printdebug "rpush split brain $do_split_brain\n";
5211         }
5212     }
5213
5214     my @localpaths = i_method "i_want", $keyword;
5215     printdebug "[[  $keyword @localpaths\n";
5216     foreach my $localpath (@localpaths) {
5217         protocol_send_file \*RI, $localpath;
5218     }
5219     print RI "files-end\n" or confess "$!";
5220 }
5221
5222 sub i_localname_parsed_changelog {
5223     return "remote-changelog.822";
5224 }
5225 sub i_file_parsed_changelog {
5226     ($i_clogp, $i_version, $i_dscfn) =
5227         push_parse_changelog "$i_tmp/remote-changelog.822";
5228     die if $i_dscfn =~ m#/|^\W#;
5229 }
5230
5231 sub i_localname_dsc {
5232     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5233     return $i_dscfn;
5234 }
5235 sub i_file_dsc { }
5236
5237 sub i_localname_buildinfo ($) {
5238     my $bi = $i_param{'buildinfo-filename'};
5239     defined $bi or badproto \*RO, "buildinfo before filename";
5240     defined $i_changesfn or badproto \*RO, "buildinfo before changes";
5241     $bi =~ m{^\Q$package\E_[!-.0-~]*\.buildinfo$}s
5242         or badproto \*RO, "improper buildinfo filename";
5243     return $&;
5244 }
5245 sub i_file_buildinfo {
5246     my $bi = $i_param{'buildinfo-filename'};
5247     my $bd = parsecontrol "$i_tmp/$bi", $bi;
5248     my $ch = parsecontrol "$i_tmp/$i_changesfn", 'changes';
5249     if (!forceing [qw(buildinfo-changes-mismatch)]) {
5250         files_compare_inputs($bd, $ch);
5251         (getfield $bd, $_) eq (getfield $ch, $_) or
5252             fail f_ "buildinfo mismatch in field %s", $_
5253             foreach qw(Source Version);
5254         !defined $bd->{$_} or
5255             fail f_ "buildinfo contains forbidden field %s", $_
5256             foreach qw(Changes Changed-by Distribution);
5257     }
5258     push @i_buildinfos, $bi;
5259     delete $i_param{'buildinfo-filename'};
5260 }
5261
5262 sub i_localname_changes {
5263     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
5264     $i_changesfn = $i_dscfn;
5265     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
5266     return $i_changesfn;
5267 }
5268 sub i_file_changes { }
5269
5270 sub i_want_signed_tag {
5271     printdebug Dumper(\%i_param, $i_dscfn);
5272     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
5273         && defined $i_param{'csuite'}
5274         or badproto \*RO, "premature desire for signed-tag";
5275     my $head = $i_param{'head'};
5276     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
5277
5278     my $maintview = $i_param{'maint-view'};
5279     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
5280
5281     if ($protovsn == 4) {
5282         my $p = $i_param{'tagformat'} // '<undef>';
5283         $p eq 'new'
5284             or badproto \*RO, "tag format mismatch: $p vs. new";
5285     }
5286
5287     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
5288     $csuite = $&;
5289     defined $dsc or badproto \*RO, "dsc (before parsed-changelog)";
5290
5291     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
5292
5293     return
5294         push_mktags $i_clogp, $i_dscfn,
5295             $i_changesfn, (__ 'remote changes file'),
5296             \@tagwants;
5297 }
5298
5299 sub i_want_signed_dsc_changes {
5300     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
5301     sign_changes $i_changesfn;
5302     return ($i_dscfn, $i_changesfn, @i_buildinfos);
5303 }
5304
5305 #---------- building etc. ----------
5306
5307 our $version;
5308 our $sourcechanges;
5309 our $dscfn;
5310
5311 #----- `3.0 (quilt)' handling -----
5312
5313 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
5314
5315 sub quiltify_dpkg_commit ($$$;$) {
5316     my ($patchname,$author,$msg, $xinfo) = @_;
5317     $xinfo //= '';
5318
5319     mkpath '.git/dgit'; # we are in playtree
5320     my $descfn = ".git/dgit/quilt-description.tmp";
5321     open O, '>', $descfn or confess "$descfn: $!";
5322     $msg =~ s/\n+/\n\n/;
5323     print O <<END or confess "$!";
5324 From: $author
5325 ${xinfo}Subject: $msg
5326 ---
5327
5328 END
5329     close O or confess "$!";
5330
5331     {
5332         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
5333         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
5334         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
5335         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
5336     }
5337 }
5338
5339 sub quiltify_trees_differ ($$;$$$) {
5340     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
5341     # returns true iff the two tree objects differ other than in debian/
5342     # with $finegrained,
5343     # returns bitmask 01 - differ in upstream files except .gitignore
5344     #                 02 - differ in .gitignore
5345     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
5346     #  is set for each modified .gitignore filename $fn
5347     # if $unrepres is defined, array ref to which is appeneded
5348     #  a list of unrepresentable changes (removals of upstream files
5349     #  (as messages)
5350     local $/=undef;
5351     my @cmd = (@git, qw(diff-tree -z --no-renames));
5352     push @cmd, qw(--name-only) unless $unrepres;
5353     push @cmd, qw(-r) if $finegrained || $unrepres;
5354     push @cmd, $x, $y;
5355     my $diffs= cmdoutput @cmd;
5356     my $r = 0;
5357     my @lmodes;
5358     foreach my $f (split /\0/, $diffs) {
5359         if ($unrepres && !@lmodes) {
5360             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
5361             next;
5362         }
5363         my ($oldmode,$newmode) = @lmodes;
5364         @lmodes = ();
5365
5366         next if $f =~ m#^debian(?:/.*)?$#s;
5367
5368         if ($unrepres) {
5369             eval {
5370                 die __ "not a plain file or symlink\n"
5371                     unless $newmode =~ m/^(?:10|12)\d{4}$/ ||
5372                            $oldmode =~ m/^(?:10|12)\d{4}$/;
5373                 if ($oldmode =~ m/[^0]/ &&
5374                     $newmode =~ m/[^0]/) {
5375                     # both old and new files exist
5376                     die __ "mode or type changed\n" if $oldmode ne $newmode;
5377                     die __ "modified symlink\n" unless $newmode =~ m/^10/;
5378                 } elsif ($oldmode =~ m/[^0]/) {
5379                     # deletion
5380                     die __ "deletion of symlink\n"
5381                         unless $oldmode =~ m/^10/;
5382                 } else {
5383                     # creation
5384                     die __ "creation with non-default mode\n"
5385                         unless $newmode =~ m/^100644$/ or
5386                                $newmode =~ m/^120000$/;
5387                 }
5388             };
5389             if ($@) {
5390                 local $/="\n"; chomp $@;
5391                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
5392             }
5393         }
5394
5395         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
5396         $r |= $isignore ? 02 : 01;
5397         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
5398     }
5399     printdebug "quiltify_trees_differ $x $y => $r\n";
5400     return $r;
5401 }
5402
5403 sub quiltify_tree_sentinelfiles ($) {
5404     # lists the `sentinel' files present in the tree
5405     my ($x) = @_;
5406     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
5407         qw(-- debian/rules debian/control);
5408     $r =~ s/\n/,/g;
5409     return $r;
5410 }
5411
5412 sub quiltify_splitting ($$$$$$$) {
5413     my ($clogp, $unapplied, $headref, $oldtiptree, $diffbits,
5414         $editedignores, $cachekey) = @_;
5415     my $gitignore_special = 1;
5416     if ($quilt_mode !~ m/gbp|dpm|baredebian/) {
5417         # treat .gitignore just like any other upstream file
5418         $diffbits = { %$diffbits };
5419         $_ = !!$_ foreach values %$diffbits;
5420         $gitignore_special = 0;
5421     }
5422     # We would like any commits we generate to be reproducible
5423     my @authline = clogp_authline($clogp);
5424     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
5425     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
5426     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
5427     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
5428     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
5429     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
5430
5431     confess unless do_split_brain();
5432
5433     my $fulldiffhint = sub {
5434         my ($x,$y) = @_;
5435         my $cmd = "git diff $x $y -- :/ ':!debian'";
5436         $cmd .= " ':!/.gitignore' ':!*/.gitignore'" if $gitignore_special;
5437         return f_ "\nFor full diff showing the problem(s), type:\n %s\n",
5438                   $cmd;
5439     };
5440
5441     if ($quilt_mode =~ m/gbp|unapplied|baredebian/ &&
5442         ($diffbits->{O2H} & 01)) {
5443         my $msg = f_
5444  "--quilt=%s specified, implying patches-unapplied git tree\n".
5445  " but git tree differs from orig in upstream files.",
5446                      $quilt_mode;
5447         $msg .= $fulldiffhint->($unapplied, 'HEAD');
5448         if (!stat_exists "debian/patches" and $quilt_mode !~ m/baredebian/) {
5449             $msg .= __
5450  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
5451         }
5452         fail $msg;
5453     }
5454     if ($quilt_mode =~ m/dpm/ &&
5455         ($diffbits->{H2A} & 01)) {
5456         fail +(f_ <<END, $quilt_mode). $fulldiffhint->($oldtiptree,'HEAD');
5457 --quilt=%s specified, implying patches-applied git tree
5458  but git tree differs from result of applying debian/patches to upstream
5459 END
5460     }
5461     if ($quilt_mode =~ m/baredebian/) {
5462         # We need to construct a merge which has upstream files from
5463         # upstream and debian/ files from HEAD.
5464
5465         read_tree_upstream $quilt_upstream_commitish, 1, $headref;
5466         my $version = getfield $clogp, 'Version';
5467         my $upsversion = upstreamversion $version;
5468         my $merge = make_commit
5469             [ $headref, $quilt_upstream_commitish ],
5470  [ +(f_ <<ENDT, $upsversion), $quilt_upstream_commitish_message, <<ENDU ];
5471 Combine debian/ with upstream source for %s
5472 ENDT
5473 [dgit ($our_version) baredebian-merge $version $quilt_upstream_commitish_used]
5474 ENDU
5475         runcmd @git, qw(reset -q --hard), $merge;
5476     }
5477     if ($quilt_mode =~ m/gbp|unapplied|baredebian/ &&
5478         ($diffbits->{O2A} & 01)) { # some patches
5479         progress __ "dgit view: creating patches-applied version using gbp pq";
5480         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
5481         # gbp pq import creates a fresh branch; push back to dgit-view
5482         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
5483         runcmd @git, qw(checkout -q dgit-view);
5484     }
5485     if ($quilt_mode =~ m/gbp|dpm/ &&
5486         ($diffbits->{O2A} & 02)) {
5487         fail f_ <<END, $quilt_mode;
5488 --quilt=%s specified, implying that HEAD is for use with a
5489  tool which does not create patches for changes to upstream
5490  .gitignores: but, such patches exist in debian/patches.
5491 END
5492     }
5493     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
5494         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
5495         progress __
5496             "dgit view: creating patch to represent .gitignore changes";
5497         ensuredir "debian/patches";
5498         my $gipatch = "debian/patches/auto-gitignore";
5499         open GIPATCH, ">>", "$gipatch" or confess "$gipatch: $!";
5500         stat GIPATCH or confess "$gipatch: $!";
5501         fail f_ "%s already exists; but want to create it".
5502                 " to record .gitignore changes",
5503                 $gipatch
5504             if (stat _)[7];
5505         print GIPATCH +(__ <<END).<<ENDU or die "$gipatch: $!";
5506 Subject: Update .gitignore from Debian packaging branch
5507
5508 The Debian packaging git branch contains these updates to the upstream
5509 .gitignore file(s).  This patch is autogenerated, to provide these
5510 updates to users of the official Debian archive view of the package.
5511 END
5512
5513 [dgit ($our_version) update-gitignore]
5514 ---
5515 ENDU
5516         close GIPATCH or die "$gipatch: $!";
5517         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
5518             $unapplied, $headref, "--", sort keys %$editedignores;
5519         open SERIES, "+>>", "debian/patches/series" or confess "$!";
5520         defined seek SERIES, -1, 2 or $!==EINVAL or confess "$!";
5521         my $newline;
5522         defined read SERIES, $newline, 1 or confess "$!";
5523         print SERIES "\n" or confess "$!" unless $newline eq "\n";
5524         print SERIES "auto-gitignore\n" or confess "$!";
5525         close SERIES or die  $!;
5526         runcmd @git, qw(add -f -- debian/patches/series), $gipatch;
5527         commit_admin +(__ <<END).<<ENDU
5528 Commit patch to update .gitignore
5529 END
5530
5531 [dgit ($our_version) update-gitignore-quilt-fixup]
5532 ENDU
5533     }
5534 }
5535
5536 sub quiltify ($$$$) {
5537     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
5538
5539     # Quilt patchification algorithm
5540     #
5541     # We search backwards through the history of the main tree's HEAD
5542     # (T) looking for a start commit S whose tree object is identical
5543     # to to the patch tip tree (ie the tree corresponding to the
5544     # current dpkg-committed patch series).  For these purposes
5545     # `identical' disregards anything in debian/ - this wrinkle is
5546     # necessary because dpkg-source treates debian/ specially.
5547     #
5548     # We can only traverse edges where at most one of the ancestors'
5549     # trees differs (in changes outside in debian/).  And we cannot
5550     # handle edges which change .pc/ or debian/patches.  To avoid
5551     # going down a rathole we avoid traversing edges which introduce
5552     # debian/rules or debian/control.  And we set a limit on the
5553     # number of edges we are willing to look at.
5554     #
5555     # If we succeed, we walk forwards again.  For each traversed edge
5556     # PC (with P parent, C child) (starting with P=S and ending with
5557     # C=T) to we do this:
5558     #  - git checkout C
5559     #  - dpkg-source --commit with a patch name and message derived from C
5560     # After traversing PT, we git commit the changes which
5561     # should be contained within debian/patches.
5562
5563     # The search for the path S..T is breadth-first.  We maintain a
5564     # todo list containing search nodes.  A search node identifies a
5565     # commit, and looks something like this:
5566     #  $p = {
5567     #      Commit => $git_commit_id,
5568     #      Child => $c,                          # or undef if P=T
5569     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
5570     #      Nontrivial => true iff $p..$c has relevant changes
5571     #  };
5572
5573     my @todo;
5574     my @nots;
5575     my $sref_S;
5576     my $max_work=100;
5577     my %considered; # saves being exponential on some weird graphs
5578
5579     my $t_sentinels = quiltify_tree_sentinelfiles $target;
5580
5581     my $not = sub {
5582         my ($search,$whynot) = @_;
5583         printdebug " search NOT $search->{Commit} $whynot\n";
5584         $search->{Whynot} = $whynot;
5585         push @nots, $search;
5586         no warnings qw(exiting);
5587         next;
5588     };
5589
5590     push @todo, {
5591         Commit => $target,
5592     };
5593
5594     while (@todo) {
5595         my $c = shift @todo;
5596         next if $considered{$c->{Commit}}++;
5597
5598         $not->($c, __ "maximum search space exceeded") if --$max_work <= 0;
5599
5600         printdebug "quiltify investigate $c->{Commit}\n";
5601
5602         # are we done?
5603         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5604             printdebug " search finished hooray!\n";
5605             $sref_S = $c;
5606             last;
5607         }
5608
5609         quiltify_nofix_bail " $c->{Commit}", " (tree object $oldtiptree)";
5610         if ($quilt_mode eq 'smash') {
5611             printdebug " search quitting smash\n";
5612             last;
5613         }
5614
5615         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5616         $not->($c, f_ "has %s not %s", $c_sentinels, $t_sentinels)
5617             if $c_sentinels ne $t_sentinels;
5618
5619         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5620         $commitdata =~ m/\n\n/;
5621         $commitdata =~ $`;
5622         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5623         @parents = map { { Commit => $_, Child => $c } } @parents;
5624
5625         $not->($c, __ "root commit") if !@parents;
5626
5627         foreach my $p (@parents) {
5628             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5629         }
5630         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5631         $not->($c, f_ "merge (%s nontrivial parents)", $ndiffers)
5632             if $ndiffers > 1;
5633
5634         foreach my $p (@parents) {
5635             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5636
5637             my @cmd= (@git, qw(diff-tree -r --name-only),
5638                       $p->{Commit},$c->{Commit},
5639                       qw(-- debian/patches .pc debian/source/format));
5640             my $patchstackchange = cmdoutput @cmd;
5641             if (length $patchstackchange) {
5642                 $patchstackchange =~ s/\n/,/g;
5643                 $not->($p, f_ "changed %s", $patchstackchange);
5644             }
5645
5646             printdebug " search queue P=$p->{Commit} ",
5647                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5648             push @todo, $p;
5649         }
5650     }
5651
5652     if (!$sref_S) {
5653         printdebug "quiltify want to smash\n";
5654
5655         my $abbrev = sub {
5656             my $x = $_[0]{Commit};
5657             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5658             return $x;
5659         };
5660         if ($quilt_mode eq 'linear') {
5661             print STDERR f_
5662                 "\n%s: error: quilt fixup cannot be linear.  Stopped at:\n",
5663                 $us;
5664             my $all_gdr = !!@nots;
5665             foreach my $notp (@nots) {
5666                 my $c = $notp->{Child};
5667                 my $cprange = $abbrev->($notp);
5668                 $cprange .= "..".$abbrev->($c) if $c;
5669                 print STDERR f_ "%s:  %s: %s\n",
5670                     $us, $cprange, $notp->{Whynot};
5671                 $all_gdr &&= $notp->{Child} &&
5672                     (git_cat_file $notp->{Child}{Commit}, 'commit')
5673                     =~ m{^\[git-debrebase(?! split[: ]).*\]$}m;
5674             }
5675             print STDERR "\n";
5676             $failsuggestion =
5677                 [ grep { $_->[0] ne 'quilt-mode' } @$failsuggestion ]
5678                 if $all_gdr;
5679             print STDERR "$us: $_->[1]\n" foreach @$failsuggestion;
5680             fail __
5681  "quilt history linearisation failed.  Search \`quilt fixup' in dgit(7).\n";
5682         } elsif ($quilt_mode eq 'smash') {
5683         } elsif ($quilt_mode eq 'auto') {
5684             progress __ "quilt fixup cannot be linear, smashing...";
5685         } else {
5686             confess "$quilt_mode ?";
5687         }
5688
5689         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5690         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5691         my $ncommits = 3;
5692         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5693
5694         quiltify_dpkg_commit "auto-$version-$target-$time",
5695             (getfield $clogp, 'Maintainer'),
5696             (f_ "Automatically generated patch (%s)\n".
5697              "Last (up to) %s git changes, FYI:\n\n",
5698              $clogp->{Version}, $ncommits).
5699              $msg;
5700         return;
5701     }
5702
5703     progress __ "quiltify linearisation planning successful, executing...";
5704
5705     for (my $p = $sref_S;
5706          my $c = $p->{Child};
5707          $p = $p->{Child}) {
5708         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5709         next unless $p->{Nontrivial};
5710
5711         my $cc = $c->{Commit};
5712
5713         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5714         $commitdata =~ m/\n\n/ or die "$c ?";
5715         $commitdata = $`;
5716         my $msg = $'; #';
5717         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5718         my $author = $1;
5719
5720         my $commitdate = cmdoutput
5721             @git, qw(log -n1 --pretty=format:%aD), $cc;
5722
5723         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5724
5725         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5726         $strip_nls->();
5727
5728         my $title = $1;
5729         my $patchname;
5730         my $patchdir;
5731
5732         my $gbp_check_suitable = sub {
5733             $_ = shift;
5734             my ($what) = @_;
5735
5736             eval {
5737                 die __ "contains unexpected slashes\n" if m{//} || m{/$};
5738                 die __ "contains leading punctuation\n" if m{^\W} || m{/\W};
5739                 die __ "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5740                 die __ "is series file\n" if m{$series_filename_re}o;
5741                 die __ "too long\n" if length > 200;
5742             };
5743             return $_ unless $@;
5744             print STDERR f_
5745                 "quiltifying commit %s: ignoring/dropping Gbp-Pq %s: %s",
5746                 $cc, $what, $@;
5747             return undef;
5748         };
5749
5750         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5751                            gbp-pq-name: \s* )
5752                        (\S+) \s* \n //ixm) {
5753             $patchname = $gbp_check_suitable->($1, 'Name');
5754         }
5755         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5756                            gbp-pq-topic: \s* )
5757                        (\S+) \s* \n //ixm) {
5758             $patchdir = $gbp_check_suitable->($1, 'Topic');
5759         }
5760
5761         $strip_nls->();
5762
5763         if (!defined $patchname) {
5764             $patchname = $title;
5765             $patchname =~ s/[.:]$//;
5766             use Text::Iconv;
5767             eval {
5768                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5769                 my $translitname = $converter->convert($patchname);
5770                 die unless defined $translitname;
5771                 $patchname = $translitname;
5772             };
5773             print STDERR
5774                 +(f_ "dgit: patch title transliteration error: %s", $@)
5775                 if $@;
5776             $patchname =~ y/ A-Z/-a-z/;
5777             $patchname =~ y/-a-z0-9_.+=~//cd;
5778             $patchname =~ s/^\W/x-$&/;
5779             $patchname = substr($patchname,0,40);
5780             $patchname .= ".patch";
5781         }
5782         if (!defined $patchdir) {
5783             $patchdir = '';
5784         }
5785         if (length $patchdir) {
5786             $patchname = "$patchdir/$patchname";
5787         }
5788         if ($patchname =~ m{^(.*)/}) {
5789             mkpath "debian/patches/$1";
5790         }
5791
5792         my $index;
5793         for ($index='';
5794              stat "debian/patches/$patchname$index";
5795              $index++) { }
5796         $!==ENOENT or confess "$patchname$index $!";
5797
5798         runcmd @git, qw(checkout -q), $cc;
5799
5800         # We use the tip's changelog so that dpkg-source doesn't
5801         # produce complaining messages from dpkg-parsechangelog.  None
5802         # of the information dpkg-source gets from the changelog is
5803         # actually relevant - it gets put into the original message
5804         # which dpkg-source provides our stunt editor, and then
5805         # overwritten.
5806         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5807
5808         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5809             "Date: $commitdate\n".
5810             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5811
5812         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5813     }
5814 }
5815
5816 sub build_maybe_quilt_fixup () {
5817     my ($format,$fopts) = get_source_format;
5818     return unless madformat_wantfixup $format;
5819     # sigh
5820
5821     check_for_vendor_patches();
5822
5823     my $clogp = parsechangelog();
5824     my $headref = git_rev_parse('HEAD');
5825     my $symref = git_get_symref();
5826     my $upstreamversion = upstreamversion $version;
5827
5828     prep_ud();
5829     changedir $playground;
5830
5831     my $splitbrain_cachekey;
5832
5833     if (do_split_brain()) {
5834         my $cachehit;
5835         ($cachehit, $splitbrain_cachekey) =
5836             quilt_check_splitbrain_cache($headref, $upstreamversion);
5837         if ($cachehit) {
5838             changedir $maindir;
5839             return;
5840         }
5841     }
5842
5843     unpack_playtree_need_cd_work($headref);
5844     if (do_split_brain()) {
5845         runcmd @git, qw(checkout -q -b dgit-view);
5846         # so long as work is not deleted, its current branch will
5847         # remain dgit-view, rather than master, so subsequent calls to
5848         #  unpack_playtree_need_cd_work
5849         # will DTRT, resetting dgit-view.
5850         confess if $made_split_brain;
5851         $made_split_brain = 1;
5852     }
5853     chdir '..';
5854
5855     if ($fopts->{'single-debian-patch'}) {
5856         fail f_
5857  "quilt mode %s does not make sense (or is not supported) with single-debian-patch",
5858             $quilt_mode
5859             if quiltmode_splitting();
5860         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5861     } else {
5862         quilt_fixup_multipatch($clogp, $headref, $upstreamversion,
5863                               $splitbrain_cachekey);
5864     }
5865
5866     if (do_split_brain()) {
5867         my $dgitview = git_rev_parse 'HEAD';
5868
5869         changedir $maindir;
5870         reflog_cache_insert "refs/$splitbraincache",
5871             $splitbrain_cachekey, $dgitview;
5872
5873         changedir "$playground/work";
5874
5875         my $saved = maybe_split_brain_save $headref, $dgitview, __ "converted";
5876         progress f_ "dgit view: created (%s)", $saved;
5877     }
5878
5879     changedir $maindir;
5880     runcmd_ordryrun_local
5881         @git, qw(pull --ff-only -q), "$playground/work", qw(master);
5882 }
5883
5884 sub build_check_quilt_splitbrain () {
5885     build_maybe_quilt_fixup();
5886 }
5887
5888 sub unpack_playtree_need_cd_work ($) {
5889     my ($headref) = @_;
5890
5891     # prep_ud() must have been called already.
5892     if (!chdir "work") {
5893         # Check in the filesystem because sometimes we run prep_ud
5894         # in between multiple calls to unpack_playtree_need_cd_work.
5895         confess "$!" unless $!==ENOENT;
5896         mkdir "work" or confess "$!";
5897         changedir "work";
5898         mktree_in_ud_here();
5899     }
5900     runcmd @git, qw(reset -q --hard), $headref;
5901 }
5902
5903 sub unpack_playtree_linkorigs ($$) {
5904     my ($upstreamversion, $fn) = @_;
5905     # calls $fn->($leafname);
5906
5907     my $bpd_abs = bpd_abs();
5908
5909     dotdot_bpd_transfer_origs $bpd_abs, $upstreamversion, sub { 1 };
5910
5911     opendir QFD, $bpd_abs or fail "buildproductsdir: $bpd_abs: $!";
5912     while ($!=0, defined(my $leaf = readdir QFD)) {
5913         my $f = bpd_abs()."/".$leaf;
5914         {
5915             local ($debuglevel) = $debuglevel-1;
5916             printdebug "QF linkorigs bpd $leaf, $f ?\n";
5917         }
5918         next unless is_orig_file_of_vsn $leaf, $upstreamversion;
5919         printdebug "QF linkorigs $leaf, $f Y\n";
5920         link_ltarget $f, $leaf or die "$leaf $!";
5921         $fn->($leaf);
5922     }
5923     die "$buildproductsdir: $!" if $!;
5924     closedir QFD;
5925 }
5926
5927 sub quilt_fixup_delete_pc () {
5928     runcmd @git, qw(rm -rqf .pc);
5929     commit_admin +(__ <<END).<<ENDU
5930 Commit removal of .pc (quilt series tracking data)
5931 END
5932
5933 [dgit ($our_version) upgrade quilt-remove-pc]
5934 ENDU
5935 }
5936
5937 sub quilt_fixup_singlepatch ($$$) {
5938     my ($clogp, $headref, $upstreamversion) = @_;
5939
5940     progress __ "starting quiltify (single-debian-patch)";
5941
5942     # dpkg-source --commit generates new patches even if
5943     # single-debian-patch is in debian/source/options.  In order to
5944     # get it to generate debian/patches/debian-changes, it is
5945     # necessary to build the source package.
5946
5947     unpack_playtree_linkorigs($upstreamversion, sub { });
5948     unpack_playtree_need_cd_work($headref);
5949
5950     rmtree("debian/patches");
5951
5952     runcmd @dpkgsource, qw(-b .);
5953     changedir "..";
5954     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5955     rename srcfn("$upstreamversion", "/debian/patches"),
5956         "work/debian/patches"
5957         or $!==ENOENT
5958         or confess "install d/patches: $!";
5959
5960     changedir "work";
5961     commit_quilty_patch();
5962 }
5963
5964 sub quilt_need_fake_dsc ($) {
5965     # cwd should be playground
5966     my ($upstreamversion) = @_;
5967
5968     return if stat_exists "fake.dsc";
5969     # ^ OK to test this as a sentinel because if we created it
5970     # we must either have done the rest too, or crashed.
5971
5972     my $fakeversion="$upstreamversion-~~DGITFAKE";
5973
5974     my $fakedsc=new IO::File 'fake.dsc', '>' or confess "$!";
5975     print $fakedsc <<END or confess "$!";
5976 Format: 3.0 (quilt)
5977 Source: $package
5978 Version: $fakeversion
5979 Files:
5980 END
5981
5982     my $dscaddfile=sub {
5983         my ($leaf) = @_;
5984
5985         my $md = new Digest::MD5;
5986
5987         my $fh = new IO::File $leaf, '<' or die "$leaf $!";
5988         stat $fh or confess "$!";
5989         my $size = -s _;
5990
5991         $md->addfile($fh);
5992         print $fakedsc " ".$md->hexdigest." $size $leaf\n" or confess "$!";
5993     };
5994
5995     unpack_playtree_linkorigs($upstreamversion, $dscaddfile);
5996
5997     my @files=qw(debian/source/format debian/rules
5998                  debian/control debian/changelog);
5999     foreach my $maybe (qw(debian/patches debian/source/options
6000                           debian/tests/control)) {
6001         next unless stat_exists "$maindir/$maybe";
6002         push @files, $maybe;
6003     }
6004
6005     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
6006     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C), $maindir, @files;
6007
6008     $dscaddfile->($debtar);
6009     close $fakedsc or confess "$!";
6010 }
6011
6012 sub quilt_fakedsc2unapplied ($$) {
6013     my ($headref, $upstreamversion) = @_;
6014     # must be run in the playground
6015     # quilt_need_fake_dsc must have been called
6016
6017     quilt_need_fake_dsc($upstreamversion);
6018     runcmd qw(sh -ec),
6019         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
6020
6021     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
6022     rename $fakexdir, "fake" or die "$fakexdir $!";
6023
6024     changedir 'fake';
6025
6026     remove_stray_gits(__ "source package");
6027     mktree_in_ud_here();
6028
6029     rmtree '.pc';
6030
6031     rmtree 'debian'; # git checkout commitish paths does not delete!
6032     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
6033     my $unapplied=git_add_write_tree();
6034     printdebug "fake orig tree object $unapplied\n";
6035     return $unapplied;
6036 }
6037
6038 sub quilt_check_splitbrain_cache ($$) {
6039     my ($headref, $upstreamversion) = @_;
6040     # Called only if we are in (potentially) split brain mode.
6041     # Called in playground.
6042     # Computes the cache key and looks in the cache.
6043     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
6044
6045     quilt_need_fake_dsc($upstreamversion);
6046
6047     my $splitbrain_cachekey;
6048
6049     progress f_
6050  "dgit: split brain (separate dgit view) may be needed (--quilt=%s).",
6051                 $quilt_mode;
6052     # we look in the reflog of dgit-intern/quilt-cache
6053     # we look for an entry whose message is the key for the cache lookup
6054     my @cachekey = (qw(dgit), $our_version);
6055     push @cachekey, $upstreamversion;
6056     push @cachekey, $quilt_mode;
6057     push @cachekey, $headref;
6058     push @cachekey, $quilt_upstream_commitish // '-';
6059
6060     push @cachekey, hashfile('fake.dsc');
6061
6062     my $srcshash = Digest::SHA->new(256);
6063     my %sfs = ( %INC, '$0(dgit)' => $0 );
6064     foreach my $sfk (sort keys %sfs) {
6065         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
6066         $srcshash->add($sfk,"  ");
6067         $srcshash->add(hashfile($sfs{$sfk}));
6068         $srcshash->add("\n");
6069     }
6070     push @cachekey, $srcshash->hexdigest();
6071     $splitbrain_cachekey = "@cachekey";
6072
6073     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
6074
6075     my $cachehit = reflog_cache_lookup
6076         "refs/$splitbraincache", $splitbrain_cachekey;
6077
6078     if ($cachehit) {
6079         unpack_playtree_need_cd_work($headref);
6080         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
6081         if ($cachehit ne $headref) {
6082             progress f_ "dgit view: found cached (%s)", $saved;
6083             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
6084             $made_split_brain = 1;
6085             return ($cachehit, $splitbrain_cachekey);
6086         }
6087         progress __ "dgit view: found cached, no changes required";
6088         return ($headref, $splitbrain_cachekey);
6089     }
6090
6091     printdebug "splitbrain cache miss\n";
6092     return (undef, $splitbrain_cachekey);
6093 }
6094
6095 sub baredebian_origtarballs_scan ($$$) {
6096     my ($fakedfi, $upstreamversion, $dir) = @_;
6097     if (!opendir OD, $dir) {
6098         return if $! == ENOENT;
6099         fail "opendir $dir (origs): $!";
6100     }
6101
6102     while ($!=0, defined(my $leaf = readdir OD)) {
6103         {
6104             local ($debuglevel) = $debuglevel-1;
6105             printdebug "BDOS $dir $leaf ?\n";
6106         }
6107         next unless is_orig_file_of_vsn $leaf, $upstreamversion;
6108         next if grep { $_->{Filename} eq $leaf } @$fakedfi;
6109         push @$fakedfi, {
6110             Filename => $leaf,
6111             Path => "$dir/$leaf",
6112                         };
6113     }
6114
6115     die "$dir; $!" if $!;
6116     closedir OD;
6117 }
6118
6119 sub quilt_fixup_multipatch ($$$) {
6120     my ($clogp, $headref, $upstreamversion, $splitbrain_cachekey) = @_;
6121
6122     progress f_ "examining quilt state (multiple patches, %s mode)",
6123                 $quilt_mode;
6124
6125     # Our objective is:
6126     #  - honour any existing .pc in case it has any strangeness
6127     #  - determine the git commit corresponding to the tip of
6128     #    the patch stack (if there is one)
6129     #  - if there is such a git commit, convert each subsequent
6130     #    git commit into a quilt patch with dpkg-source --commit
6131     #  - otherwise convert all the differences in the tree into
6132     #    a single git commit
6133     #
6134     # To do this we:
6135
6136     # Our git tree doesn't necessarily contain .pc.  (Some versions of
6137     # dgit would include the .pc in the git tree.)  If there isn't
6138     # one, we need to generate one by unpacking the patches that we
6139     # have.
6140     #
6141     # We first look for a .pc in the git tree.  If there is one, we
6142     # will use it.  (This is not the normal case.)
6143     #
6144     # Otherwise need to regenerate .pc so that dpkg-source --commit
6145     # can work.  We do this as follows:
6146     #     1. Collect all relevant .orig from parent directory
6147     #     2. Generate a debian.tar.gz out of
6148     #         debian/{patches,rules,source/format,source/options}
6149     #     3. Generate a fake .dsc containing just these fields:
6150     #          Format Source Version Files
6151     #     4. Extract the fake .dsc
6152     #        Now the fake .dsc has a .pc directory.
6153     # (In fact we do this in every case, because in future we will
6154     # want to search for a good base commit for generating patches.)
6155     #
6156     # Then we can actually do the dpkg-source --commit
6157     #     1. Make a new working tree with the same object
6158     #        store as our main tree and check out the main
6159     #        tree's HEAD.
6160     #     2. Copy .pc from the fake's extraction, if necessary
6161     #     3. Run dpkg-source --commit
6162     #     4. If the result has changes to debian/, then
6163     #          - git add them them
6164     #          - git add .pc if we had a .pc in-tree
6165     #          - git commit
6166     #     5. If we had a .pc in-tree, delete it, and git commit
6167     #     6. Back in the main tree, fast forward to the new HEAD
6168
6169     # Another situation we may have to cope with is gbp-style
6170     # patches-unapplied trees.
6171     #
6172     # We would want to detect these, so we know to escape into
6173     # quilt_fixup_gbp.  However, this is in general not possible.
6174     # Consider a package with a one patch which the dgit user reverts
6175     # (with git revert or the moral equivalent).
6176     #
6177     # That is indistinguishable in contents from a patches-unapplied
6178     # tree.  And looking at the history to distinguish them is not
6179     # useful because the user might have made a confusing-looking git
6180     # history structure (which ought to produce an error if dgit can't
6181     # cope, not a silent reintroduction of an unwanted patch).
6182     #
6183     # So gbp users will have to pass an option.  But we can usually
6184     # detect their failure to do so: if the tree is not a clean
6185     # patches-applied tree, quilt linearisation fails, but the tree
6186     # _is_ a clean patches-unapplied tree, we can suggest that maybe
6187     # they want --quilt=unapplied.
6188     #
6189     # To help detect this, when we are extracting the fake dsc, we
6190     # first extract it with --skip-patches, and then apply the patches
6191     # afterwards with dpkg-source --before-build.  That lets us save a
6192     # tree object corresponding to .origs.
6193
6194     if ($quilt_mode eq 'linear'
6195         && branch_is_gdr($headref)) {
6196         # This is much faster.  It also makes patches that gdr
6197         # likes better for future updates without laundering.
6198         #
6199         # However, it can fail in some casses where we would
6200         # succeed: if there are existing patches, which correspond
6201         # to a prefix of the branch, but are not in gbp/gdr
6202         # format, gdr will fail (exiting status 7), but we might
6203         # be able to figure out where to start linearising.  That
6204         # will be slower so hopefully there's not much to do.
6205
6206         unpack_playtree_need_cd_work $headref;
6207
6208         my @cmd = (@git_debrebase,
6209                    qw(--noop-ok -funclean-mixed -funclean-ordering
6210                       make-patches --quiet-would-amend));
6211         # We tolerate soe snags that gdr wouldn't, by default.
6212         if (act_local()) {
6213             debugcmd "+",@cmd;
6214             $!=0; $?=-1;
6215             failedcmd @cmd
6216                 if system @cmd
6217                 and not ($? == 7*256 or
6218                          $? == -1 && $!==ENOENT);
6219         } else {
6220             dryrun_report @cmd;
6221         }
6222         $headref = git_rev_parse('HEAD');
6223
6224         chdir '..';
6225     }
6226
6227     my $unapplied=quilt_fakedsc2unapplied($headref, $upstreamversion);
6228
6229     ensuredir '.pc';
6230
6231     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
6232     $!=0; $?=-1;
6233     if (system @bbcmd) {
6234         failedcmd @bbcmd if $? < 0;
6235         fail __ <<END;
6236 failed to apply your git tree's patch stack (from debian/patches/) to
6237  the corresponding upstream tarball(s).  Your source tree and .orig
6238  are probably too inconsistent.  dgit can only fix up certain kinds of
6239  anomaly (depending on the quilt mode).  Please see --quilt= in dgit(1).
6240 END
6241     }
6242
6243     changedir '..';
6244
6245     unpack_playtree_need_cd_work($headref);
6246
6247     my $mustdeletepc=0;
6248     if (stat_exists ".pc") {
6249         -d _ or die;
6250         progress __ "Tree already contains .pc - will use it then delete it.";
6251         $mustdeletepc=1;
6252     } else {
6253         rename '../fake/.pc','.pc' or confess "$!";
6254     }
6255
6256     changedir '../fake';
6257     rmtree '.pc';
6258     my $oldtiptree=git_add_write_tree();
6259     printdebug "fake o+d/p tree object $unapplied\n";
6260     changedir '../work';
6261
6262
6263     # We calculate some guesswork now about what kind of tree this might
6264     # be.  This is mostly for error reporting.
6265
6266     my $tentries = cmdoutput @git, qw(ls-tree --name-only -z), $headref;
6267     my $onlydebian = $tentries eq "debian\0";
6268
6269     my $uheadref = $headref;
6270     my $uhead_whatshort = 'HEAD';
6271
6272     if ($quilt_mode =~ m/baredebian\+tarball/) {
6273         # We need to make a tarball import.  Yuk.
6274         # We want to do this here so that we have a $uheadref value
6275
6276         my @fakedfi;
6277         baredebian_origtarballs_scan \@fakedfi, $upstreamversion, bpd_abs();
6278         baredebian_origtarballs_scan \@fakedfi, $upstreamversion,
6279             "$maindir/.." unless $buildproductsdir eq '..';
6280         changedir '..';
6281
6282         my @tartrees = import_tarball_tartrees $upstreamversion, \@fakedfi;
6283
6284         fail __ "baredebian quilt fixup: could not find any origs"
6285             unless @tartrees;
6286
6287         changedir 'work';
6288         my ($authline, $r1authline, $clogp,) =
6289             import_tarball_commits \@tartrees, $upstreamversion;
6290
6291         if (@tartrees == 1) {
6292             $uheadref = $tartrees[0]{Commit};
6293             # TRANSLATORS: this translation must fit in the ASCII art
6294             # quilt differences display.  The untranslated display
6295             # says %9.9s, so with that display it must be at most 9
6296             # characters.
6297             $uhead_whatshort = __ 'tarball';
6298         } else {
6299             # on .dsc import we do not make a separate commit, but
6300             # here we need to do so
6301             rm_subdir_cached '.';
6302             my $parents;
6303             foreach my $ti (@tartrees) {
6304                 my $c = $ti->{Commit};
6305                 if ($ti->{OrigPart} eq 'orig') {
6306                     runcmd qw(git read-tree), $c;
6307                 } elsif ($ti->{OrigPart} =~ m/orig-/) {
6308                     read_tree_subdir $', $c;
6309                 } else {
6310                     confess "$ti->OrigPart} ?"
6311                 }
6312                 $parents .= "parent $c\n";
6313             }
6314             my $tree = git_write_tree();
6315             my $mbody = f_ 'Combine orig tarballs for %s %s',
6316                 $package, $upstreamversion;
6317             $uheadref = hash_commit_text <<END;
6318 tree $tree
6319 ${parents}author $r1authline
6320 committer $r1authline
6321
6322 $mbody
6323
6324 [dgit import tarballs combine $package $upstreamversion]
6325 END
6326             # TRANSLATORS: this translation must fit in the ASCII art
6327             # quilt differences display.  The untranslated display
6328             # says %9.9s, so with that display it must be at most 9
6329             # characters.  This fragmentt is referring to multiple
6330             # orig tarballs in a source package.
6331             $uhead_whatshort = __ 'tarballs';
6332
6333             runcmd @git, qw(reset -q);
6334         }
6335         $quilt_upstream_commitish = $uheadref;
6336         $quilt_upstream_commitish_used = '*orig*';
6337         $quilt_upstream_commitish_message = '';
6338     }
6339     if ($quilt_mode =~ m/baredebian$/) {
6340         $uheadref = $quilt_upstream_commitish;
6341         # TRANSLATORS: this translation must fit in the ASCII art
6342         # quilt differences display.  The untranslated display
6343         # says %9.9s, so with that display it must be at most 9
6344         # characters.
6345         $uhead_whatshort = __ 'upstream';
6346     }
6347
6348     my %editedignores;
6349     my @unrepres;
6350     my $diffbits = {
6351         # H = user's HEAD
6352         # O = orig, without patches applied
6353         # A = "applied", ie orig with H's debian/patches applied
6354         O2H => quiltify_trees_differ($unapplied,$uheadref,   1,
6355                                      \%editedignores, \@unrepres),
6356         H2A => quiltify_trees_differ($uheadref, $oldtiptree,1),
6357         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
6358     };
6359
6360     my @dl;
6361     foreach my $bits (qw(01 02)) {
6362         foreach my $v (qw(O2H O2A H2A)) {
6363             push @dl, ($diffbits->{$v} & $bits) ? '##' : '==';
6364         }
6365     }
6366     printdebug "differences \@dl @dl.\n";
6367
6368     progress f_
6369 "%s: base trees orig=%.20s o+d/p=%.20s",
6370               $us, $unapplied, $oldtiptree;
6371     # TRANSLATORS: Try to keep this ascii-art layout right.  The 0s in
6372     # %9.00009s will be ignored and are there to make the format the
6373     # same length (9 characters) as the output it generates.  If you
6374     # change the value 9, your translations of "upstream" and
6375     # 'tarball' must fit into the new length, and you should change
6376     # the number of 0s.  Do not reduce it below 4 as HEAD has to fit
6377     # too.
6378     progress f_
6379 "%s: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
6380 "%s: quilt differences: %9.00009s %s o+d/p          %9.00009s %s o+d/p",
6381   $us,                      $dl[0], $dl[1],              $dl[3], $dl[4],
6382   $us,        $uhead_whatshort, $dl[2],   $uhead_whatshort, $dl[5];
6383
6384     if (@unrepres && $quilt_mode !~ m/baredebian/) {
6385         # With baredebian, even if the upstream commitish has this
6386         # problem, we don't want to print this message, as nothing
6387         # is going to try to make a patch out of it anyway.
6388         print STDERR f_ "dgit:  cannot represent change: %s: %s\n",
6389                         $_->[1], $_->[0]
6390             foreach @unrepres;
6391         forceable_fail [qw(unrepresentable)], __ <<END;
6392 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
6393 END
6394     }
6395
6396     my @failsuggestion;
6397     if ($onlydebian) {
6398         push @failsuggestion, [ 'onlydebian', __
6399  "This has only a debian/ directory; you probably want --quilt=bare debian." ]
6400             unless $quilt_mode =~ m/baredebian/;
6401     } elsif (!($diffbits->{O2H} & $diffbits->{O2A})) {
6402         push @failsuggestion, [ 'unapplied', __
6403  "This might be a patches-unapplied branch." ];
6404     } elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
6405         push @failsuggestion, [ 'applied', __
6406  "This might be a patches-applied branch." ];
6407     }
6408     push @failsuggestion, [ 'quilt-mode', __
6409  "Maybe you need one of --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?" ];
6410
6411     push @failsuggestion, [ 'gitattrs', __
6412  "Warning: Tree has .gitattributes.  See GITATTRIBUTES in dgit(7)." ]
6413         if stat_exists '.gitattributes';
6414
6415     push @failsuggestion, [ 'origs', __
6416  "Maybe orig tarball(s) are not identical to git representation?" ]
6417         unless $onlydebian && $quilt_mode !~ m/baredebian/;
6418                # ^ in that case, we didn't really look properly
6419
6420     if (quiltmode_splitting()) {
6421         quiltify_splitting($clogp, $unapplied, $headref, $oldtiptree,
6422                            $diffbits, \%editedignores,
6423                            $splitbrain_cachekey);
6424         return;
6425     }
6426
6427     progress f_ "starting quiltify (multiple patches, %s mode)", $quilt_mode;
6428     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
6429     runcmd @git, qw(checkout -q), (qw(master dgit-view)[do_split_brain()]);
6430
6431     if (!open P, '>>', ".pc/applied-patches") {
6432         $!==&ENOENT or confess "$!";
6433     } else {
6434         close P;
6435     }
6436
6437     commit_quilty_patch();
6438
6439     if ($mustdeletepc) {
6440         quilt_fixup_delete_pc();
6441     }
6442 }
6443
6444 sub quilt_fixup_editor () {
6445     my $descfn = $ENV{$fakeeditorenv};
6446     my $editing = $ARGV[$#ARGV];
6447     open I1, '<', $descfn or confess "$descfn: $!";
6448     open I2, '<', $editing or confess "$editing: $!";
6449     unlink $editing or confess "$editing: $!";
6450     open O, '>', $editing or confess "$editing: $!";
6451     while (<I1>) { print O or confess "$!"; } I1->error and confess "$!";
6452     my $copying = 0;
6453     while (<I2>) {
6454         $copying ||= m/^\-\-\- /;
6455         next unless $copying;
6456         print O or confess "$!";
6457     }
6458     I2->error and confess "$!";
6459     close O or die $1;
6460     finish 0;
6461 }
6462
6463 sub maybe_apply_patches_dirtily () {
6464     return unless $quilt_mode =~ m/gbp|unapplied|baredebian/;
6465     print STDERR __ <<END or confess "$!";
6466
6467 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
6468 dgit: Have to apply the patches - making the tree dirty.
6469 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
6470
6471 END
6472     $patches_applied_dirtily = 01;
6473     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
6474     runcmd qw(dpkg-source --before-build .);
6475 }
6476
6477 sub maybe_unapply_patches_again () {
6478     progress __ "dgit: Unapplying patches again to tidy up the tree."
6479         if $patches_applied_dirtily;
6480     runcmd qw(dpkg-source --after-build .)
6481         if $patches_applied_dirtily & 01;
6482     rmtree '.pc'
6483         if $patches_applied_dirtily & 02;
6484     $patches_applied_dirtily = 0;
6485 }
6486
6487 #----- other building -----
6488
6489 sub clean_tree_check_git ($$$) {
6490     my ($honour_ignores, $message, $ignmessage) = @_;
6491     my @cmd = (@git, qw(clean -dn));
6492     push @cmd, qw(-x) unless $honour_ignores;
6493     my $leftovers = cmdoutput @cmd;
6494     if (length $leftovers) {
6495         print STDERR $leftovers, "\n" or confess "$!";
6496         $message .= $ignmessage if $honour_ignores;
6497         fail $message;
6498     }
6499 }
6500
6501 sub clean_tree_check_git_wd ($) {
6502     my ($message) = @_;
6503     return if $cleanmode =~ m{no-check};
6504     return if $patches_applied_dirtily; # yuk
6505     clean_tree_check_git +($cleanmode !~ m{all-check}),
6506         $message, "\n".__ <<END;
6507 If this is just missing .gitignore entries, use a different clean
6508 mode, eg --clean=dpkg-source,no-check (-wdn/-wddn) to ignore them
6509 or --clean=git (-wg/-wgf) to use \`git clean' instead.
6510 END
6511 }
6512
6513 sub clean_tree_check () {
6514     # This function needs to not care about modified but tracked files.
6515     # That was done by check_not_dirty, and by now we may have run
6516     # the rules clean target which might modify tracked files (!)
6517     if ($cleanmode =~ m{^check}) {
6518         clean_tree_check_git +($cleanmode =~ m{ignores}), __
6519  "tree contains uncommitted files and --clean=check specified", '';
6520     } elsif ($cleanmode =~ m{^dpkg-source}) {
6521         clean_tree_check_git_wd __
6522  "tree contains uncommitted files (NB dgit didn't run rules clean)";
6523     } elsif ($cleanmode =~ m{^git}) {
6524         clean_tree_check_git 1, __
6525  "tree contains uncommited, untracked, unignored files\n".
6526  "You can use --clean=git[-ff],always (-wga/-wgfa) to delete them.", '';
6527     } elsif ($cleanmode eq 'none') {
6528     } else {
6529         confess "$cleanmode ?";
6530     }
6531 }
6532
6533 sub clean_tree () {
6534     # We always clean the tree ourselves, rather than leave it to the
6535     # builder (dpkg-source, or soemthing which calls dpkg-source).
6536     if ($quilt_mode =~ m/baredebian/ and $cleanmode =~ m/git/) {
6537         fail f_ <<END, $quilt_mode, $cleanmode;
6538 quilt mode %s (generally needs untracked upstream files)
6539 contradicts clean mode %s (which would delete them)
6540 END
6541         # This is not 100% true: dgit build-source and push-source
6542         # (for example) could operate just fine with no upstream
6543         # source in the working tree.  But it doesn't seem likely that
6544         # the user wants dgit to proactively delete such things.
6545         # -wn, for example, would produce identical output without
6546         # deleting anything from the working tree.
6547     }
6548     if ($cleanmode =~ m{^dpkg-source}) {
6549         my @cmd = @dpkgbuildpackage;
6550         push @cmd, qw(-d) if $cleanmode =~ m{^dpkg-source-d};
6551         push @cmd, qw(-T clean);
6552         maybe_apply_patches_dirtily();
6553         runcmd_ordryrun_local @cmd;
6554         clean_tree_check_git_wd __
6555  "tree contains uncommitted files (after running rules clean)";
6556     } elsif ($cleanmode =~ m{^git(?!-)}) {
6557         runcmd_ordryrun_local @git, qw(clean -xdf);
6558     } elsif ($cleanmode =~ m{^git-ff}) {
6559         runcmd_ordryrun_local @git, qw(clean -xdff);
6560     } elsif ($cleanmode =~ m{^check}) {
6561         clean_tree_check();
6562     } elsif ($cleanmode eq 'none') {
6563     } else {
6564         confess "$cleanmode ?";
6565     }
6566 }
6567
6568 sub cmd_clean () {
6569     badusage __ "clean takes no additional arguments" if @ARGV;
6570     notpushing();
6571     clean_tree();
6572     maybe_unapply_patches_again();
6573 }
6574
6575 # return values from massage_dbp_args are one or both of these flags
6576 sub WANTSRC_SOURCE  () { 01; } # caller should build source (separately)
6577 sub WANTSRC_BUILDER () { 02; } # caller should run dpkg-buildpackage
6578
6579 sub build_or_push_prep_early () {
6580     our $build_or_push_prep_early_done //= 0;
6581     return if $build_or_push_prep_early_done++;
6582     my $clogp = parsechangelog();
6583     $isuite = getfield $clogp, 'Distribution';
6584     my $gotpackage = getfield $clogp, 'Source';
6585     $version = getfield $clogp, 'Version';
6586     $package //= $gotpackage;
6587     if ($package ne $gotpackage) {
6588         fail f_ "-p specified package %s, but changelog says %s",
6589             $package, $gotpackage;
6590     }
6591     $dscfn = dscfn($version);
6592 }
6593
6594 sub build_or_push_prep_modes () {
6595     my ($format) = get_source_format();
6596     determine_whether_split_brain($format);
6597
6598     fail __ "dgit: --include-dirty is not supported with split view".
6599             " (including with view-splitting quilt modes)"
6600         if do_split_brain() && $includedirty;
6601
6602     if (madformat_wantfixup $format and $quilt_mode =~ m/baredebian$/) {
6603         ($quilt_upstream_commitish, $quilt_upstream_commitish_used,
6604          $quilt_upstream_commitish_message)
6605             = resolve_upstream_version
6606             $quilt_upstream_commitish, upstreamversion $version;
6607         progress f_ "dgit: --quilt=%s, %s", $quilt_mode,
6608             $quilt_upstream_commitish_message;
6609     } elsif (defined $quilt_upstream_commitish) {
6610         fail __
6611  "dgit: --upstream-commitish only makes sense with --quilt=baredebian"
6612     }
6613 }
6614
6615 sub build_prep_early () {
6616     build_or_push_prep_early();
6617     notpushing();
6618     build_or_push_prep_modes();
6619     check_not_dirty();
6620 }
6621
6622 sub build_prep ($) {
6623     my ($wantsrc) = @_;
6624     build_prep_early();
6625     check_bpd_exists();
6626     if (!building_source_in_playtree() || ($wantsrc & WANTSRC_BUILDER)
6627         # Clean the tree because we're going to use the contents of
6628         # $maindir.  (We trying to include dirty changes in the source
6629         # package, or we are running the builder in $maindir.)
6630         || $cleanmode =~ m{always}) {
6631         # Or because the user asked us to.
6632         clean_tree();
6633     } else {
6634         # We don't actually need to do anything in $maindir, but we
6635         # should do some kind of cleanliness check because (i) the
6636         # user may have forgotten a `git add', and (ii) if the user
6637         # said -wc we should still do the check.
6638         clean_tree_check();
6639     }
6640     build_check_quilt_splitbrain();
6641     if ($rmchanges) {
6642         my $pat = changespat $version;
6643         foreach my $f (glob "$buildproductsdir/$pat") {
6644             if (act_local()) {
6645                 unlink $f or
6646                     fail f_ "remove old changes file %s: %s", $f, $!;
6647             } else {
6648                 progress f_ "would remove %s", $f;
6649             }
6650         }
6651     }
6652 }
6653
6654 sub changesopts_initial () {
6655     my @opts =@changesopts[1..$#changesopts];
6656 }
6657
6658 sub changesopts_version () {
6659     if (!defined $changes_since_version) {
6660         my @vsns;
6661         unless (eval {
6662             @vsns = archive_query('archive_query');
6663             my @quirk = access_quirk();
6664             if ($quirk[0] eq 'backports') {
6665                 local $isuite = $quirk[2];
6666                 local $csuite;
6667                 canonicalise_suite();
6668                 push @vsns, archive_query('archive_query');
6669             }
6670             1;
6671         }) {
6672             print STDERR $@;
6673             fail __
6674  "archive query failed (queried because --since-version not specified)";
6675         }
6676         if (@vsns) {
6677             @vsns = map { $_->[0] } @vsns;
6678             @vsns = sort { -version_compare($a, $b) } @vsns;
6679             $changes_since_version = $vsns[0];
6680             progress f_ "changelog will contain changes since %s", $vsns[0];
6681         } else {
6682             $changes_since_version = '_';
6683             progress __ "package seems new, not specifying -v<version>";
6684         }
6685     }
6686     if ($changes_since_version ne '_') {
6687         return ("-v$changes_since_version");
6688     } else {
6689         return ();
6690     }
6691 }
6692
6693 sub changesopts () {
6694     return (changesopts_initial(), changesopts_version());
6695 }
6696
6697 sub massage_dbp_args ($;$) {
6698     my ($cmd,$xargs) = @_;
6699     # Since we split the source build out so we can do strange things
6700     # to it, massage the arguments to dpkg-buildpackage so that the
6701     # main build doessn't build source (or add an argument to stop it
6702     # building source by default).
6703     debugcmd '#massaging#', @$cmd if $debuglevel>1;
6704     # -nc has the side effect of specifying -b if nothing else specified
6705     # and some combinations of -S, -b, et al, are errors, rather than
6706     # later simply overriding earlie.  So we need to:
6707     #  - search the command line for these options
6708     #  - pick the last one
6709     #  - perhaps add our own as a default
6710     #  - perhaps adjust it to the corresponding non-source-building version
6711     my $dmode = '-F';
6712     foreach my $l ($cmd, $xargs) {
6713         next unless $l;
6714         @$l = grep { !(m/^-[SgGFABb]$|^--build=/s and $dmode=$_) } @$l;
6715     }
6716     push @$cmd, '-nc';
6717 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
6718     my $r = WANTSRC_BUILDER;
6719     printdebug "massage split $dmode.\n";
6720     if ($dmode =~ s/^--build=//) {
6721         $r = 0;
6722         my @d = split /,/, $dmode;
6723         $r |= WANTSRC_SOURCE  if grep { s/^full$/binary/ } @d;
6724         $r |= WANTSRC_SOURCE  if grep { s/^source$// } @d;
6725         $r |= WANTSRC_BUILDER if grep { m/./ } @d;
6726         fail __ "Wanted to build nothing!" unless $r;
6727         $dmode = '--build='. join ',', grep m/./, @d;
6728     } else {
6729         $r =
6730           $dmode =~ m/[S]/     ?  WANTSRC_SOURCE :
6731           $dmode =~ y/gGF/ABb/ ?  WANTSRC_SOURCE | WANTSRC_BUILDER :
6732           $dmode =~ m/[ABb]/   ?                   WANTSRC_BUILDER :
6733           confess "$dmode ?";
6734     }
6735     printdebug "massage done $r $dmode.\n";
6736     push @$cmd, $dmode;
6737 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
6738     return $r;
6739 }
6740
6741 sub in_bpd (&) {
6742     my ($fn) = @_;
6743     my $wasdir = must_getcwd();
6744     changedir $buildproductsdir;
6745     $fn->();
6746     changedir $wasdir;
6747 }
6748
6749 # this sub must run with CWD=$buildproductsdir (eg in in_bpd)
6750 sub postbuild_mergechanges ($) {
6751     my ($msg_if_onlyone) = @_;
6752     # If there is only one .changes file, fail with $msg_if_onlyone,
6753     # or if that is undef, be a no-op.
6754     # Returns the changes file to report to the user.
6755     my $pat = changespat $version;
6756     my @changesfiles = grep { !m/_multi\.changes/ } glob $pat;
6757     @changesfiles = sort {
6758         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
6759             or $a cmp $b
6760     } @changesfiles;
6761     my $result;
6762     if (@changesfiles==1) {
6763         fail +(f_ <<END, "@changesfiles").$msg_if_onlyone
6764 only one changes file from build (%s)
6765 END
6766             if defined $msg_if_onlyone;
6767         $result = $changesfiles[0];
6768     } elsif (@changesfiles==2) {
6769         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
6770         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
6771             fail f_ "%s found in binaries changes file %s", $l, $binchanges
6772                 if $l =~ m/\.dsc$/;
6773         }
6774         runcmd_ordryrun_local @mergechanges, @changesfiles;
6775         my $multichanges = changespat $version,'multi';
6776         if (act_local()) {
6777             stat_exists $multichanges or fail f_
6778                 "%s unexpectedly not created by build", $multichanges;
6779             foreach my $cf (glob $pat) {
6780                 next if $cf eq $multichanges;
6781                 rename "$cf", "$cf.inmulti" or fail f_
6782                     "install new changes %s\{,.inmulti}: %s", $cf, $!;
6783             }
6784         }
6785         $result = $multichanges;
6786     } else {
6787         fail f_ "wrong number of different changes files (%s)",
6788                 "@changesfiles";
6789     }
6790     printdone f_ "build successful, results in %s\n", $result
6791         or confess "$!";
6792 }
6793
6794 sub midbuild_checkchanges () {
6795     my $pat = changespat $version;
6796     return if $rmchanges;
6797     my @unwanted = map { s#.*/##; $_; } glob "$bpd_glob/$pat";
6798     @unwanted = grep {
6799         $_ ne changespat $version,'source' and
6800         $_ ne changespat $version,'multi'
6801     } @unwanted;
6802     fail +(f_ <<END, $pat, "@unwanted")
6803 changes files other than source matching %s already present; building would result in ambiguity about the intended results.
6804 Suggest you delete %s.
6805 END
6806         if @unwanted;
6807 }
6808
6809 sub midbuild_checkchanges_vanilla ($) {
6810     my ($wantsrc) = @_;
6811     midbuild_checkchanges() if $wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER);
6812 }
6813
6814 sub postbuild_mergechanges_vanilla ($) {
6815     my ($wantsrc) = @_;
6816     if ($wantsrc == (WANTSRC_SOURCE|WANTSRC_BUILDER)) {
6817         in_bpd {
6818             postbuild_mergechanges(undef);
6819         };
6820     } else {
6821         printdone __ "build successful\n";
6822     }
6823 }
6824
6825 sub cmd_build {
6826     build_prep_early();
6827     $buildproductsdir eq '..' or print STDERR +(f_ <<END, $us, $us);
6828 %s: warning: build-products-dir set, but not supported by dpkg-buildpackage
6829 %s: warning: build-products-dir will be ignored; files will go to ..
6830 END
6831     $buildproductsdir = '..';
6832     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
6833     my $wantsrc = massage_dbp_args \@dbp;
6834     build_prep($wantsrc);
6835     if ($wantsrc & WANTSRC_SOURCE) {
6836         build_source();
6837         midbuild_checkchanges_vanilla $wantsrc;
6838     }
6839     if ($wantsrc & WANTSRC_BUILDER) {
6840         push @dbp, changesopts_version();
6841         maybe_apply_patches_dirtily();
6842         runcmd_ordryrun_local @dbp;
6843     }
6844     maybe_unapply_patches_again();
6845     postbuild_mergechanges_vanilla $wantsrc;
6846 }
6847
6848 sub pre_gbp_build {
6849     $quilt_mode //= 'gbp';
6850 }
6851
6852 sub cmd_gbp_build {
6853     build_prep_early();
6854
6855     # gbp can make .origs out of thin air.  In my tests it does this
6856     # even for a 1.0 format package, with no origs present.  So I
6857     # guess it keys off just the version number.  We don't know
6858     # exactly what .origs ought to exist, but let's assume that we
6859     # should run gbp if: the version has an upstream part and the main
6860     # orig is absent.
6861     my $upstreamversion = upstreamversion $version;
6862     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
6863     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "$bpd_glob/$origfnpat");
6864
6865     if ($gbp_make_orig) {
6866         clean_tree();
6867         $cleanmode = 'none'; # don't do it again
6868     }
6869
6870     my @dbp = @dpkgbuildpackage;
6871
6872     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
6873
6874     if (!length $gbp_build[0]) {
6875         if (length executable_on_path('git-buildpackage')) {
6876             $gbp_build[0] = qw(git-buildpackage);
6877         } else {
6878             $gbp_build[0] = 'gbp buildpackage';
6879         }
6880     }
6881     my @cmd = opts_opt_multi_cmd [], @gbp_build;
6882
6883     push @cmd, (qw(-us -uc --git-no-sign-tags),
6884                 "--git-builder=".(shellquote @dbp));
6885
6886     if ($gbp_make_orig) {
6887         my $priv = dgit_privdir();
6888         my $ok = "$priv/origs-gen-ok";
6889         unlink $ok or $!==&ENOENT or confess "$!";
6890         my @origs_cmd = @cmd;
6891         push @origs_cmd, qw(--git-cleaner=true);
6892         push @origs_cmd, "--git-prebuild=".
6893             "touch ".(shellquote $ok)." ".(shellquote "$priv/no-such-dir/ok");
6894         push @origs_cmd, @ARGV;
6895         if (act_local()) {
6896             debugcmd @origs_cmd;
6897             system @origs_cmd;
6898             do { local $!; stat_exists $ok; }
6899                 or failedcmd @origs_cmd;
6900         } else {
6901             dryrun_report @origs_cmd;
6902         }
6903     }
6904
6905     build_prep($wantsrc);
6906     if ($wantsrc & WANTSRC_SOURCE) {
6907         build_source();
6908         midbuild_checkchanges_vanilla $wantsrc;
6909     } else {
6910         push @cmd, '--git-cleaner=true';
6911     }
6912     maybe_unapply_patches_again();
6913     if ($wantsrc & WANTSRC_BUILDER) {
6914         push @cmd, changesopts();
6915         runcmd_ordryrun_local @cmd, @ARGV;
6916     }
6917     postbuild_mergechanges_vanilla $wantsrc;
6918 }
6919 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6920
6921 sub building_source_in_playtree {
6922     # If $includedirty, we have to build the source package from the
6923     # working tree, not a playtree, so that uncommitted changes are
6924     # included (copying or hardlinking them into the playtree could
6925     # cause trouble).
6926     #
6927     # Note that if we are building a source package in split brain
6928     # mode we do not support including uncommitted changes, because
6929     # that makes quilt fixup too hard.  I.e. ($made_split_brain && (dgit is
6930     # building a source package)) => !$includedirty
6931     return !$includedirty;
6932 }
6933
6934 sub build_source {
6935     $sourcechanges = changespat $version,'source';
6936     if (act_local()) {
6937         unlink "$buildproductsdir/$sourcechanges" or $!==ENOENT
6938             or fail f_ "remove %s: %s", $sourcechanges, $!;
6939     }
6940 #    confess unless !!$made_split_brain == do_split_brain();
6941
6942     my @cmd = (@dpkgsource, qw(-b --));
6943     my $leafdir;
6944     if (building_source_in_playtree()) {
6945         $leafdir = 'work';
6946         my $headref = git_rev_parse('HEAD');
6947         # If we are in split brain, there is already a playtree with
6948         # the thing we should package into a .dsc (thanks to quilt
6949         # fixup).  If not, make a playtree
6950         prep_ud() unless $made_split_brain;
6951         changedir $playground;
6952         unless ($made_split_brain) {
6953             my $upstreamversion = upstreamversion $version;
6954             unpack_playtree_linkorigs($upstreamversion, sub { });
6955             unpack_playtree_need_cd_work($headref);
6956             changedir '..';
6957         }
6958     } else {
6959         $leafdir = basename $maindir;
6960
6961         if ($buildproductsdir ne '..') {
6962             # Well, we are going to run dpkg-source -b which consumes
6963             # origs from .. and generates output there.  To make this
6964             # work when the bpd is not .. , we would have to (i) link
6965             # origs from bpd to .. , (ii) check for files that
6966             # dpkg-source -b would/might overwrite, and afterwards
6967             # (iii) move all the outputs back to the bpd (iv) except
6968             # for the origs which should be deleted from .. if they
6969             # weren't there beforehand.  And if there is an error and
6970             # we don't run to completion we would necessarily leave a
6971             # mess.  This is too much.  The real way to fix this
6972             # is for dpkg-source to have bpd support.
6973             confess unless $includedirty;
6974             fail __
6975  "--include-dirty not supported with --build-products-dir, sorry";
6976         }
6977
6978         changedir '..';
6979     }
6980     runcmd_ordryrun_local @cmd, $leafdir;
6981
6982     changedir $leafdir;
6983     runcmd_ordryrun_local qw(sh -ec),
6984       'exec >../$1; shift; exec "$@"','x', $sourcechanges,
6985       @dpkggenchanges, qw(-S), changesopts();
6986     changedir '..';
6987
6988     printdebug "moving $dscfn, $sourcechanges, etc. to ".bpd_abs()."\n";
6989     $dsc = parsecontrol($dscfn, "source package");
6990
6991     my $mv = sub {
6992         my ($why, $l) = @_;
6993         printdebug " renaming ($why) $l\n";
6994         rename_link_xf 0, "$l", bpd_abs()."/$l"
6995             or fail f_ "put in place new built file (%s): %s", $l, $@;
6996     };
6997     foreach my $l (split /\n/, getfield $dsc, 'Files') {
6998         $l =~ m/\S+$/ or next;
6999         $mv->('Files', $&);
7000     }
7001     $mv->('dsc', $dscfn);
7002     $mv->('changes', $sourcechanges);
7003
7004     changedir $maindir;
7005 }
7006
7007 sub cmd_build_source {
7008     badusage __ "build-source takes no additional arguments" if @ARGV;
7009     build_prep(WANTSRC_SOURCE);
7010     build_source();
7011     maybe_unapply_patches_again();
7012     printdone f_ "source built, results in %s and %s",
7013                  $dscfn, $sourcechanges;
7014 }
7015
7016 sub cmd_push_source {
7017     prep_push();
7018     fail __
7019         "dgit push-source: --include-dirty/--ignore-dirty does not make".
7020         "sense with push-source!"
7021         if $includedirty;
7022     build_check_quilt_splitbrain();
7023     if ($changesfile) {
7024         my $changes = parsecontrol("$buildproductsdir/$changesfile",
7025                                    __ "source changes file");
7026         unless (test_source_only_changes($changes)) {
7027             fail __ "user-specified changes file is not source-only";
7028         }
7029     } else {
7030         # Building a source package is very fast, so just do it
7031         build_source();
7032         confess "er, patches are applied dirtily but shouldn't be.."
7033             if $patches_applied_dirtily;
7034         $changesfile = $sourcechanges;
7035     }
7036     dopush();
7037 }
7038
7039 sub binary_builder {
7040     my ($bbuilder, $pbmc_msg, @args) = @_;
7041     build_prep(WANTSRC_SOURCE);
7042     build_source();
7043     midbuild_checkchanges();
7044     in_bpd {
7045         if (act_local()) {
7046             stat_exists $dscfn or fail f_
7047                 "%s (in build products dir): %s", $dscfn, $!;
7048             stat_exists $sourcechanges or fail f_
7049                 "%s (in build products dir): %s", $sourcechanges, $!;
7050         }
7051         runcmd_ordryrun_local @$bbuilder, @args;
7052     };
7053     maybe_unapply_patches_again();
7054     in_bpd {
7055         postbuild_mergechanges($pbmc_msg);
7056     };
7057 }
7058
7059 sub cmd_sbuild {
7060     build_prep_early();
7061     binary_builder(\@sbuild, (__ <<END), qw(-d), $isuite, @ARGV, $dscfn);
7062 perhaps you need to pass -A ?  (sbuild's default is to build only
7063 arch-specific binaries; dgit 1.4 used to override that.)
7064 END
7065 }
7066
7067 sub pbuilder ($) {
7068     my ($pbuilder) = @_;
7069     build_prep_early();
7070     # @ARGV is allowed to contain only things that should be passed to
7071     # pbuilder under debbuildopts; just massage those
7072     my $wantsrc = massage_dbp_args \@ARGV;
7073     fail __
7074         "you asked for a builder but your debbuildopts didn't ask for".
7075         " any binaries -- is this really what you meant?"
7076         unless $wantsrc & WANTSRC_BUILDER;
7077     fail __
7078         "we must build a .dsc to pass to the builder but your debbuiltopts".
7079         " forbids the building of a source package; cannot continue"
7080       unless $wantsrc & WANTSRC_SOURCE;
7081     # We do not want to include the verb "build" in @pbuilder because
7082     # the user can customise @pbuilder and they shouldn't be required
7083     # to include "build" in their customised value.  However, if the
7084     # user passes any additional args to pbuilder using the dgit
7085     # option --pbuilder:foo, such args need to come after the "build"
7086     # verb.  opts_opt_multi_cmd does all of that.
7087     binary_builder([opts_opt_multi_cmd ["build"], @$pbuilder], undef,
7088                    qw(--debbuildopts), "@ARGV", qw(--distribution), $isuite,
7089                    $dscfn);
7090 }
7091
7092 sub cmd_pbuilder {
7093     pbuilder(\@pbuilder);
7094 }
7095
7096 sub cmd_cowbuilder {
7097     pbuilder(\@cowbuilder);
7098 }
7099
7100 sub cmd_quilt_fixup {
7101     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
7102     build_prep_early();
7103     clean_tree();
7104     build_maybe_quilt_fixup();
7105 }
7106
7107 sub cmd_print_unapplied_treeish {
7108     badusage __ "incorrect arguments to dgit print-unapplied-treeish"
7109         if @ARGV;
7110     my $headref = git_rev_parse('HEAD');
7111     my $clogp = commit_getclogp $headref;
7112     $package = getfield $clogp, 'Source';
7113     $version = getfield $clogp, 'Version';
7114     $isuite = getfield $clogp, 'Distribution';
7115     $csuite = $isuite; # we want this to be offline!
7116     notpushing();
7117
7118     prep_ud();
7119     changedir $playground;
7120     my $uv = upstreamversion $version;
7121     my $u = quilt_fakedsc2unapplied($headref, $uv);
7122     print $u, "\n" or confess "$!";
7123 }
7124
7125 sub import_dsc_result {
7126     my ($dstref, $newhash, $what_log, $what_msg) = @_;
7127     my @cmd = (git_update_ref_cmd $what_log, $dstref, $newhash);
7128     runcmd @cmd;
7129     check_gitattrs($newhash, __ "source tree");
7130
7131     progress f_ "dgit: import-dsc: %s", $what_msg;
7132 }
7133
7134 sub cmd_import_dsc {
7135     my $needsig = 0;
7136
7137     while (@ARGV) {
7138         last unless $ARGV[0] =~ m/^-/;
7139         $_ = shift @ARGV;
7140         last if m/^--?$/;
7141         if (m/^--require-valid-signature$/) {
7142             $needsig = 1;
7143         } else {
7144             badusage f_ "unknown dgit import-dsc sub-option \`%s'", $_;
7145         }
7146     }
7147
7148     badusage __ "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH"
7149         unless @ARGV==2;
7150     my ($dscfn, $dstbranch) = @ARGV;
7151
7152     badusage __ "dry run makes no sense with import-dsc"
7153         unless act_local();
7154
7155     my $force = $dstbranch =~ s/^\+//   ? +1 :
7156                 $dstbranch =~ s/^\.\.// ? -1 :
7157                                            0;
7158     my $info = $force ? " $&" : '';
7159     $info = "$dscfn$info";
7160
7161     my $specbranch = $dstbranch;
7162     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
7163     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
7164
7165     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
7166     my $chead = cmdoutput_errok @symcmd;
7167     defined $chead or $?==256 or failedcmd @symcmd;
7168
7169     fail f_ "%s is checked out - will not update it", $dstbranch
7170         if defined $chead and $chead eq $dstbranch;
7171
7172     my $oldhash = git_get_ref $dstbranch;
7173
7174     open D, "<", $dscfn or fail f_ "open import .dsc (%s): %s", $dscfn, $!;
7175     $dscdata = do { local $/ = undef; <D>; };
7176     D->error and fail f_ "read %s: %s", $dscfn, $!;
7177     close C;
7178
7179     # we don't normally need this so import it here
7180     use Dpkg::Source::Package;
7181     my $dp = new Dpkg::Source::Package filename => $dscfn,
7182         require_valid_signature => $needsig;
7183     {
7184         local $SIG{__WARN__} = sub {
7185             print STDERR $_[0];
7186             return unless $needsig;
7187             fail __ "import-dsc signature check failed";
7188         };
7189         if (!$dp->is_signed()) {
7190             warn f_ "%s: warning: importing unsigned .dsc\n", $us;
7191         } else {
7192             my $r = $dp->check_signature();
7193             confess "->check_signature => $r" if $needsig && $r;
7194         }
7195     }
7196
7197     parse_dscdata();
7198
7199     $package = getfield $dsc, 'Source';
7200
7201     parse_dsc_field($dsc, __ "Dgit metadata in .dsc")
7202         unless forceing [qw(import-dsc-with-dgit-field)];
7203     parse_dsc_field_def_dsc_distro();
7204
7205     $isuite = 'DGIT-IMPORT-DSC';
7206     $idistro //= $dsc_distro;
7207
7208     notpushing();
7209
7210     if (defined $dsc_hash) {
7211         progress __
7212             "dgit: import-dsc of .dsc with Dgit field, using git hash";
7213         resolve_dsc_field_commit undef, undef;
7214     }
7215     if (defined $dsc_hash) {
7216         my @cmd = (qw(sh -ec),
7217                    "echo $dsc_hash | git cat-file --batch-check");
7218         my $objgot = cmdoutput @cmd;
7219         if ($objgot =~ m#^\w+ missing\b#) {
7220             fail f_ <<END, $dsc_hash
7221 .dsc contains Dgit field referring to object %s
7222 Your git tree does not have that object.  Try `git fetch' from a
7223 plausible server (browse.dgit.d.o? salsa?), and try the import-dsc again.
7224 END
7225         }
7226         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
7227             if ($force > 0) {
7228                 progress __ "Not fast forward, forced update.";
7229             } else {
7230                 fail f_ "Not fast forward to %s", $dsc_hash;
7231             }
7232         }
7233         import_dsc_result $dstbranch, $dsc_hash,
7234             "dgit import-dsc (Dgit): $info",
7235             f_ "updated git ref %s", $dstbranch;
7236         return 0;
7237     }
7238
7239     fail f_ <<END, $dstbranch, $specbranch, $specbranch
7240 Branch %s already exists
7241 Specify ..%s for a pseudo-merge, binding in existing history
7242 Specify  +%s to overwrite, discarding existing history
7243 END
7244         if $oldhash && !$force;
7245
7246     my @dfi = dsc_files_info();
7247     foreach my $fi (@dfi) {
7248         my $f = $fi->{Filename};
7249         # We transfer all the pieces of the dsc to the bpd, not just
7250         # origs.  This is by analogy with dgit fetch, which wants to
7251         # keep them somewhere to avoid downloading them again.
7252         # We make symlinks, though.  If the user wants copies, then
7253         # they can copy the parts of the dsc to the bpd using dcmd,
7254         # or something.
7255         my $here = "$buildproductsdir/$f";
7256         if (lstat $here) {
7257             if (stat $here) {
7258                 next;
7259             }
7260             fail f_ "lstat %s works but stat gives %s !", $here, $!;
7261         }
7262         fail f_ "stat %s: %s", $here, $! unless $! == ENOENT;
7263         printdebug "not in bpd, $f ...\n";
7264         # $f does not exist in bpd, we need to transfer it
7265         my $there = $dscfn;
7266         $there =~ s{[^/]+$}{$f} or confess "$there ?";
7267         # $there is file we want, relative to user's cwd, or abs
7268         printdebug "not in bpd, $f, test $there ...\n";
7269         stat $there or fail f_
7270             "import %s requires %s, but: %s", $dscfn, $there, $!;
7271         if ($there =~ m#^(?:\./+)?\.\./+#) {
7272             # $there is relative to user's cwd
7273             my $there_from_parent = $';
7274             if ($buildproductsdir !~ m{^/}) {
7275                 # abs2rel, despite its name, can take two relative paths
7276                 $there = File::Spec->abs2rel($there,$buildproductsdir);
7277                 # now $there is relative to bpd, great
7278                 printdebug "not in bpd, $f, abs2rel, $there ...\n";
7279             } else {
7280                 $there = (dirname $maindir)."/$there_from_parent";
7281                 # now $there is absoute
7282                 printdebug "not in bpd, $f, rel2rel, $there ...\n";
7283             }
7284         } elsif ($there =~ m#^/#) {
7285             # $there is absolute already
7286             printdebug "not in bpd, $f, abs, $there ...\n";
7287         } else {
7288             fail f_
7289                 "cannot import %s which seems to be inside working tree!",
7290                 $dscfn;
7291         }
7292         symlink $there, $here or fail f_
7293             "symlink %s to %s: %s", $there, $here, $!;
7294         progress f_ "made symlink %s -> %s", $here, $there;
7295 #       print STDERR Dumper($fi);
7296     }
7297     my @mergeinputs = generate_commits_from_dsc();
7298     die unless @mergeinputs == 1;
7299
7300     my $newhash = $mergeinputs[0]{Commit};
7301
7302     if ($oldhash) {
7303         if ($force > 0) {
7304             progress __
7305                 "Import, forced update - synthetic orphan git history.";
7306         } elsif ($force < 0) {
7307             progress __ "Import, merging.";
7308             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
7309             my $version = getfield $dsc, 'Version';
7310             my $clogp = commit_getclogp $newhash;
7311             my $authline = clogp_authline $clogp;
7312             $newhash = hash_commit_text <<ENDU
7313 tree $tree
7314 parent $newhash
7315 parent $oldhash
7316 author $authline
7317 committer $authline
7318
7319 ENDU
7320                 .(f_ <<END, $package, $version, $dstbranch);
7321 Merge %s (%s) import into %s
7322 END
7323         } else {
7324             die; # caught earlier
7325         }
7326     }
7327
7328     import_dsc_result $dstbranch, $newhash,
7329         "dgit import-dsc: $info",
7330         f_ "results are in git ref %s", $dstbranch;
7331 }
7332
7333 sub pre_archive_api_query () {
7334     not_necessarily_a_tree();
7335 }
7336 sub cmd_archive_api_query {
7337     badusage __ "need only 1 subpath argument" unless @ARGV==1;
7338     my ($subpath) = @ARGV;
7339     local $isuite = 'DGIT-API-QUERY-CMD';
7340     my @cmd = archive_api_query_cmd($subpath);
7341     push @cmd, qw(-f);
7342     debugcmd ">",@cmd;
7343     exec @cmd or fail f_ "exec curl: %s\n", $!;
7344 }
7345
7346 sub repos_server_url () {
7347     $package = '_dgit-repos-server';
7348     local $access_forpush = 1;
7349     local $isuite = 'DGIT-REPOS-SERVER';
7350     my $url = access_giturl();
7351 }
7352
7353 sub pre_clone_dgit_repos_server () {
7354     not_necessarily_a_tree();
7355 }
7356 sub cmd_clone_dgit_repos_server {
7357     badusage __ "need destination argument" unless @ARGV==1;
7358     my ($destdir) = @ARGV;
7359     my $url = repos_server_url();
7360     my @cmd = (@git, qw(clone), $url, $destdir);
7361     debugcmd ">",@cmd;
7362     exec @cmd or fail f_ "exec git clone: %s\n", $!;
7363 }
7364
7365 sub pre_print_dgit_repos_server_source_url () {
7366     not_necessarily_a_tree();
7367 }
7368 sub cmd_print_dgit_repos_server_source_url {
7369     badusage __
7370         "no arguments allowed to dgit print-dgit-repos-server-source-url"
7371         if @ARGV;
7372     my $url = repos_server_url();
7373     print $url, "\n" or confess "$!";
7374 }
7375
7376 sub pre_print_dpkg_source_ignores {
7377     not_necessarily_a_tree();
7378 }
7379 sub cmd_print_dpkg_source_ignores {
7380     badusage __
7381         "no arguments allowed to dgit print-dpkg-source-ignores"
7382         if @ARGV;
7383     print "@dpkg_source_ignores\n" or confess "$!";
7384 }
7385
7386 sub cmd_setup_mergechangelogs {
7387     badusage __ "no arguments allowed to dgit setup-mergechangelogs"
7388         if @ARGV;
7389     local $isuite = 'DGIT-SETUP-TREE';
7390     setup_mergechangelogs(1);
7391 }
7392
7393 sub cmd_setup_useremail {
7394     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7395     local $isuite = 'DGIT-SETUP-TREE';
7396     setup_useremail(1);
7397 }
7398
7399 sub cmd_setup_gitattributes {
7400     badusage __ "no arguments allowed to dgit setup-useremail" if @ARGV;
7401     local $isuite = 'DGIT-SETUP-TREE';
7402     setup_gitattrs(1);
7403 }
7404
7405 sub cmd_setup_new_tree {
7406     badusage __ "no arguments allowed to dgit setup-tree" if @ARGV;
7407     local $isuite = 'DGIT-SETUP-TREE';
7408     setup_new_tree();
7409 }
7410
7411 #---------- argument parsing and main program ----------
7412
7413 sub cmd_version {
7414     print "dgit version $our_version\n" or confess "$!";
7415     finish 0;
7416 }
7417
7418 our (%valopts_long, %valopts_short);
7419 our (%funcopts_long);
7420 our @rvalopts;
7421 our (@modeopt_cfgs);
7422
7423 sub defvalopt ($$$$) {
7424     my ($long,$short,$val_re,$how) = @_;
7425     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
7426     $valopts_long{$long} = $oi;
7427     $valopts_short{$short} = $oi;
7428     # $how subref should:
7429     #   do whatever assignemnt or thing it likes with $_[0]
7430     #   if the option should not be passed on to remote, @rvalopts=()
7431     # or $how can be a scalar ref, meaning simply assign the value
7432 }
7433
7434 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
7435 defvalopt '--distro',        '-d', '.+',      \$idistro;
7436 defvalopt '',                '-k', '.+',      \$keyid;
7437 defvalopt '--existing-package','', '.*',      \$existing_package;
7438 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
7439 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
7440 defvalopt '--package',   '-p',   $package_re, \$package;
7441 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
7442
7443 defvalopt '', '-C', '.+', sub {
7444     ($changesfile) = (@_);
7445     if ($changesfile =~ s#^(.*)/##) {
7446         $buildproductsdir = $1;
7447     }
7448 };
7449
7450 defvalopt '--initiator-tempdir','','.*', sub {
7451     ($initiator_tempdir) = (@_);
7452     $initiator_tempdir =~ m#^/# or
7453         badusage __ "--initiator-tempdir must be used specify an".
7454                     " absolute, not relative, directory."
7455 };
7456
7457 sub defoptmodes ($@) {
7458     my ($varref, $cfgkey, $default, %optmap) = @_;
7459     my %permit;
7460     while (my ($opt,$val) = each %optmap) {
7461         $funcopts_long{$opt} = sub { $$varref = $val; };
7462         $permit{$val} = $val;
7463     }
7464     push @modeopt_cfgs, {
7465         Var => $varref,
7466         Key => $cfgkey,
7467         Default => $default,
7468         Vals => \%permit
7469     };
7470 }
7471
7472 defoptmodes \$dodep14tag, qw( dep14tag          want
7473                               --dep14tag        want
7474                               --no-dep14tag     no
7475                               --always-dep14tag always );
7476
7477 sub parseopts () {
7478     my $om;
7479
7480     if (defined $ENV{'DGIT_SSH'}) {
7481         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
7482     } elsif (defined $ENV{'GIT_SSH'}) {
7483         @ssh = ($ENV{'GIT_SSH'});
7484     }
7485
7486     my $oi;
7487     my $val;
7488     my $valopt = sub {
7489         my ($what) = @_;
7490         @rvalopts = ($_);
7491         if (!defined $val) {
7492             badusage f_ "%s needs a value", $what unless @ARGV;
7493             $val = shift @ARGV;
7494             push @rvalopts, $val;
7495         }
7496         badusage f_ "bad value \`%s' for %s", $val, $what unless
7497             $val =~ m/^$oi->{Re}$(?!\n)/s;
7498         my $how = $oi->{How};
7499         if (ref($how) eq 'SCALAR') {
7500             $$how = $val;
7501         } else {
7502             $how->($val);
7503         }
7504         push @ropts, @rvalopts;
7505     };
7506
7507     while (@ARGV) {
7508         last unless $ARGV[0] =~ m/^-/;
7509         $_ = shift @ARGV;
7510         last if m/^--?$/;
7511         if (m/^--/) {
7512             if (m/^--dry-run$/) {
7513                 push @ropts, $_;
7514                 $dryrun_level=2;
7515             } elsif (m/^--damp-run$/) {
7516                 push @ropts, $_;
7517                 $dryrun_level=1;
7518             } elsif (m/^--no-sign$/) {
7519                 push @ropts, $_;
7520                 $sign=0;
7521             } elsif (m/^--help$/) {
7522                 cmd_help();
7523             } elsif (m/^--version$/) {
7524                 cmd_version();
7525             } elsif (m/^--new$/) {
7526                 push @ropts, $_;
7527                 $new_package=1;
7528             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
7529                      ($om = $opts_opt_map{$1}) &&
7530                      length $om->[0]) {
7531                 push @ropts, $_;
7532                 $om->[0] = $2;
7533             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
7534                      !$opts_opt_cmdonly{$1} &&
7535                      ($om = $opts_opt_map{$1})) {
7536                 push @ropts, $_;
7537                 push @$om, $2;
7538             } elsif (m/^--([-0-9a-z]+)\!:(.*)/s &&
7539                      !$opts_opt_cmdonly{$1} &&
7540                      ($om = $opts_opt_map{$1})) {
7541                 push @ropts, $_;
7542                 my $cmd = shift @$om;
7543                 @$om = ($cmd, grep { $_ ne $2 } @$om);
7544             } elsif (m/^--($quilt_options_re)$/s) {
7545                 push @ropts, "--quilt=$1";
7546                 $quilt_mode = $1;
7547             } elsif (m/^--(?:ignore|include)-dirty$/s) {
7548                 push @ropts, $_;
7549                 $includedirty = 1;
7550             } elsif (m/^--no-quilt-fixup$/s) {
7551                 push @ropts, $_;
7552                 $quilt_mode = 'nocheck';
7553             } elsif (m/^--no-rm-on-error$/s) {
7554                 push @ropts, $_;
7555                 $rmonerror = 0;
7556             } elsif (m/^--no-chase-dsc-distro$/s) {
7557                 push @ropts, $_;
7558                 $chase_dsc_distro = 0;
7559             } elsif (m/^--overwrite$/s) {
7560                 push @ropts, $_;
7561                 $overwrite_version = '';
7562             } elsif (m/^--split-(?:view|brain)$/s) {
7563                 push @ropts, $_;
7564                 $splitview_mode = 'always';
7565             } elsif (m/^--split-(?:view|brain)=($splitview_modes_re)$/s) {
7566                 push @ropts, $_;
7567                 $splitview_mode = $1;
7568             } elsif (m/^--overwrite=(.+)$/s) {
7569                 push @ropts, $_;
7570                 $overwrite_version = $1;
7571             } elsif (m/^--delayed=(\d+)$/s) {
7572                 push @ropts, $_;
7573                 push @dput, $_;
7574             } elsif (m/^--upstream-commitish=(.+)$/s) {
7575                 push @ropts, $_;
7576                 $quilt_upstream_commitish = $1;
7577             } elsif (m/^--save-(dgit-view)=(.+)$/s ||
7578                      m/^--(dgit-view)-save=(.+)$/s
7579                      ) {
7580                 my ($k,$v) = ($1,$2);
7581                 push @ropts, $_;
7582                 $v =~ s#^(?!refs/)#refs/heads/#;
7583                 $internal_object_save{$k} = $v;
7584             } elsif (m/^--(no-)?rm-old-changes$/s) {
7585                 push @ropts, $_;
7586                 $rmchanges = !$1;
7587             } elsif (m/^--deliberately-($deliberately_re)$/s) {
7588                 push @ropts, $_;
7589                 push @deliberatelies, $&;
7590             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
7591                 push @ropts, $&;
7592                 $forceopts{$1} = 1;
7593                 $_='';
7594             } elsif (m/^--force-/) {
7595                 print STDERR
7596                     f_ "%s: warning: ignoring unknown force option %s\n",
7597                        $us, $_;
7598                 $_='';
7599             } elsif (m/^--config-lookup-explode=(.+)$/s) {
7600                 # undocumented, for testing
7601                 push @ropts, $_;
7602                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
7603                 # ^ it's supposed to be an array ref
7604             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
7605                 $val = $2 ? $' : undef; #';
7606                 $valopt->($oi->{Long});
7607             } elsif ($funcopts_long{$_}) {
7608                 push @ropts, $_;
7609                 $funcopts_long{$_}();
7610             } else {
7611                 badusage f_ "unknown long option \`%s'", $_;
7612             }
7613         } else {
7614             while (m/^-./s) {
7615                 if (s/^-n/-/) {
7616                     push @ropts, $&;
7617                     $dryrun_level=2;
7618                 } elsif (s/^-L/-/) {
7619                     push @ropts, $&;
7620                     $dryrun_level=1;
7621                 } elsif (s/^-h/-/) {
7622                     cmd_help();
7623                 } elsif (s/^-D/-/) {
7624                     push @ropts, $&;
7625                     $debuglevel++;
7626                     enabledebug();
7627                 } elsif (s/^-N/-/) {
7628                     push @ropts, $&;
7629                     $new_package=1;
7630                 } elsif (m/^-m/) {
7631                     push @ropts, $&;
7632                     push @changesopts, $_;
7633                     $_ = '';
7634                 } elsif (s/^-wn$//s) {
7635                     push @ropts, $&;
7636                     $cleanmode = 'none';
7637                 } elsif (s/^-wg(f?)(a?)$//s) {
7638                     push @ropts, $&;
7639                     $cleanmode = 'git';
7640                     $cleanmode .= '-ff' if $1;
7641                     $cleanmode .= ',always' if $2;
7642                 } elsif (s/^-wd(d?)([na]?)$//s) {
7643                     push @ropts, $&;
7644                     $cleanmode = 'dpkg-source';
7645                     $cleanmode .= '-d' if $1;
7646                     $cleanmode .= ',no-check' if $2 eq 'n';
7647                     $cleanmode .= ',all-check' if $2 eq 'a';
7648                 } elsif (s/^-wc$//s) {
7649                     push @ropts, $&;
7650                     $cleanmode = 'check';
7651                 } elsif (s/^-wci$//s) {
7652                     push @ropts, $&;
7653                     $cleanmode = 'check,ignores';
7654                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
7655                     push @git, '-c', $&;
7656                     $gitcfgs{cmdline}{$1} = [ $2 ];
7657                 } elsif (s/^-c([^=]+)$//s) {
7658                     push @git, '-c', $&;
7659                     $gitcfgs{cmdline}{$1} = [ 'true' ];
7660                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
7661                     $val = $'; #';
7662                     $val = undef unless length $val;
7663                     $valopt->($oi->{Short});
7664                     $_ = '';
7665                 } else {
7666                     badusage f_ "unknown short option \`%s'", $_;
7667                 }
7668             }
7669         }
7670     }
7671 }
7672
7673 sub check_env_sanity () {
7674     my $blocked = new POSIX::SigSet;
7675     sigprocmask SIG_UNBLOCK, $blocked, $blocked or confess "$!";
7676
7677     eval {
7678         foreach my $name (qw(PIPE CHLD)) {
7679             my $signame = "SIG$name";
7680             my $signum = eval "POSIX::$signame" // die;
7681             die f_ "%s is set to something other than SIG_DFL\n",
7682                 $signame
7683                 if defined $SIG{$name} and $SIG{$name} ne 'DEFAULT';
7684             $blocked->ismember($signum) and
7685                 die f_ "%s is blocked\n", $signame;
7686         }
7687     };
7688     return unless $@;
7689     chomp $@;
7690     fail f_ <<END, $@;
7691 On entry to dgit, %s
7692 This is a bug produced by something in your execution environment.
7693 Giving up.
7694 END
7695 }
7696
7697
7698 sub parseopts_late_defaults () {
7699     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
7700         if defined $idistro;
7701     $isuite //= cfg('dgit.default.default-suite');
7702
7703     foreach my $k (keys %opts_opt_map) {
7704         my $om = $opts_opt_map{$k};
7705
7706         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
7707         if (defined $v) {
7708             badcfg f_ "cannot set command for %s", $k
7709                 unless length $om->[0];
7710             $om->[0] = $v;
7711         }
7712
7713         foreach my $c (access_cfg_cfgs("opts-$k")) {
7714             my @vl =
7715                 map { $_ ? @$_ : () }
7716                 map { $gitcfgs{$_}{$c} }
7717                 reverse @gitcfgsources;
7718             printdebug "CL $c ", (join " ", map { shellquote } @vl),
7719                 "\n" if $debuglevel >= 4;
7720             next unless @vl;
7721             badcfg f_ "cannot configure options for %s", $k
7722                 if $opts_opt_cmdonly{$k};
7723             my $insertpos = $opts_cfg_insertpos{$k};
7724             @$om = ( @$om[0..$insertpos-1],
7725                      @vl,
7726                      @$om[$insertpos..$#$om] );
7727         }
7728     }
7729
7730     if (!defined $rmchanges) {
7731         local $access_forpush;
7732         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
7733     }
7734
7735     if (!defined $quilt_mode) {
7736         local $access_forpush;
7737         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
7738             // access_cfg('quilt-mode', 'RETURN-UNDEF')
7739             // 'linear';
7740         $quilt_mode =~ m/^($quilt_modes_re)$/
7741             or badcfg f_ "unknown quilt-mode \`%s'", $quilt_mode;
7742         $quilt_mode = $1;
7743     }
7744     $quilt_mode =~ s/^(baredebian)\+git$/$1/;
7745
7746     foreach my $moc (@modeopt_cfgs) {
7747         local $access_forpush;
7748         my $vr = $moc->{Var};
7749         next if defined $$vr;
7750         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
7751         my $v = $moc->{Vals}{$$vr};
7752         badcfg f_ "unknown %s setting \`%s'", $moc->{Key}, $$vr
7753             unless defined $v;
7754         $$vr = $v;
7755     }
7756
7757     {
7758         local $access_forpush;
7759         default_from_access_cfg(\$cleanmode, 'clean-mode', 'dpkg-source',
7760                                 $cleanmode_re);
7761     }
7762
7763     $buildproductsdir //= access_cfg('build-products-dir', 'RETURN-UNDEF');
7764     $buildproductsdir //= '..';
7765     $bpd_glob = $buildproductsdir;
7766     $bpd_glob =~ s#[][\\{}*?~]#\\$&#g;
7767 }
7768
7769 setlocale(LC_MESSAGES, "");
7770 textdomain("dgit");
7771
7772 if ($ENV{$fakeeditorenv}) {
7773     git_slurp_config();
7774     quilt_fixup_editor();
7775 }
7776
7777 parseopts();
7778 check_env_sanity();
7779
7780 print STDERR __ "DRY RUN ONLY\n" if $dryrun_level > 1;
7781 print STDERR __ "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
7782     if $dryrun_level == 1;
7783 if (!@ARGV) {
7784     print STDERR __ $helpmsg or confess "$!";
7785     finish 8;
7786 }
7787 $cmd = $subcommand = shift @ARGV;
7788 $cmd =~ y/-/_/;
7789
7790 my $pre_fn = ${*::}{"pre_$cmd"};
7791 $pre_fn->() if $pre_fn;
7792
7793 if ($invoked_in_git_tree) {
7794     changedir_git_toplevel();
7795     record_maindir();
7796 }
7797 git_slurp_config();
7798
7799 my $fn = ${*::}{"cmd_$cmd"};
7800 $fn or badusage f_ "unknown operation %s", $cmd;
7801 $fn->();
7802
7803 finish 0;