dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Digest::MD5;
  34 use Config;
  35
  36 our $our_version = 'UNRELEASED'; ###substituted###
  37
  38 our $rpushprotovsn = 2;
  39
  40 our $isuite = 'unstable';
  41 our $idistro;
  42 our $package;
  43 our @ropts;
  44
  45 our $sign = 1;
  46 our $dryrun_level = 0;
  47 our $changesfile;
  48 our $buildproductsdir = '..';
  49 our $new_package = 0;
  50 our $ignoredirty = 0;
  51 our $noquilt = 0;
  52 our $rmonerror = 1;
  53 our $existing_package = 'dpkg';
  54 our $cleanmode = 'dpkg-source';
  55 our $changes_since_version;
  56 our $we_are_responder;
  57 our $initiator_tempdir;
  58
  59 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  60
  61 our $suite_re = '[-+.0-9a-z]+';
  62
  63 our (@git) = qw(git);
  64 our (@dget) = qw(dget);
  65 our (@curl) = qw(curl -f);
  66 our (@dput) = qw(dput);
  67 our (@debsign) = qw(debsign);
  68 our (@gpg) = qw(gpg);
  69 our (@sbuild) = qw(sbuild -A);
  70 our (@ssh) = 'ssh';
  71 our (@dgit) = qw(dgit);
  72 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  73 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  74 our (@dpkggenchanges) = qw(dpkg-genchanges);
  75 our (@mergechanges) = qw(mergechanges -f);
  76 our (@changesopts) = ('');
  77
  78 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  79                      'curl' => \@curl,
  80                      'dput' => \@dput,
  81                      'debsign' => \@debsign,
  82                      'gpg' => \@gpg,
  83                      'sbuild' => \@sbuild,
  84                      'ssh' => \@ssh,
  85                      'dgit' => \@dgit,
  86                      'dpkg-source' => \@dpkgsource,
  87                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  88                      'dpkg-genchanges' => \@dpkggenchanges,
  89                      'ch' => \@changesopts,
  90                      'mergechanges' => \@mergechanges);
  91
  92 our %opts_opt_cmdonly = ('gpg' => 1);
  93
  94 our $keyid;
  95
  96 our $debug = 0;
  97 open DEBUG, ">/dev/null" or die $!;
  98
  99 autoflush STDOUT 1;
 100
 101 our $remotename = 'dgit';
 102 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 103 our $branchprefix = 'dgit';
 104 our $csuite;
 105
 106 sub lbranch () { return "$branchprefix/$csuite"; }
 107 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 108 sub lref () { return "refs/heads/".lbranch(); }
 109 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 110 sub rrref () { return "refs/$branchprefix/$csuite"; }
 111 sub debiantag ($) {
 112     my ($v) = @_;
 113     $v =~ y/~:/_%/;
 114     return "debian/$v";
 115 }
 116
 117 sub stripepoch ($) {
 118     my ($vsn) = @_;
 119     $vsn =~ s/^\d+\://;
 120     return $vsn;
 121 }
 122
 123 sub srcfn ($$) {
 124     my ($vsn,$sfx) = @_;
 125     return "${package}_".(stripepoch $vsn).$sfx
 126 }
 127
 128 sub dscfn ($) {
 129     my ($vsn) = @_;
 130     return srcfn($vsn,".dsc");
 131 }
 132
 133 our $us = 'dgit';
 134 our $debugprefix = '';
 135
 136 our @end;
 137 END {
 138     local ($?);
 139     foreach my $f (@end) {
 140         eval { $f->(); };
 141         warn "$us: cleanup: $@" if length $@;
 142     }
 143 };
 144
 145 our @signames = split / /, $Config{sig_name};
 146
 147 sub waitstatusmsg () {
 148     if (!$?) {
 149         return "terminated, reporting successful completion";
 150     } elsif (!($? & 255)) {
 151         return "failed with error exit status ".WEXITSTATUS($?);
 152     } elsif (WIFSIGNALED($?)) {
 153         my $signum=WTERMSIG($?);
 154         return "died due to fatal signal ".
 155             ($signames[$signum] // "number $signum").
 156             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 157     } else {
 158         return "failed with unknown wait status ".$?;
 159     }
 160 }
 161
 162 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 163
 164 sub fail {
 165     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 166 }
 167
 168 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 169
 170 sub no_such_package () {
 171     print STDERR "$us: package $package does not exist in suite $isuite\n";
 172     exit 4;
 173 }
 174
 175 sub fetchspec () {
 176     local $csuite = '*';
 177     return  "+".rrref().":".lrref();
 178 }
 179
 180 sub changedir ($) {
 181     my ($newdir) = @_;
 182     printdebug "CD $newdir\n";
 183     chdir $newdir or die "chdir: $newdir: $!";
 184 }
 185
 186 sub stat_exists ($) {
 187     my ($f) = @_;
 188     return 1 if stat $f;
 189     return 0 if $!==&ENOENT;
 190     die "stat $f: $!";
 191 }
 192
 193 #---------- remote protocol support, common ----------
 194
 195 # remote push initiator/responder protocol:
 196 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 197 #
 198 #  > file parsed-changelog
 199 #  [indicates that output of dpkg-parsechangelog follows]
 200 #  > data-block NBYTES
 201 #  > [NBYTES bytes of data (no newline)]
 202 #  [maybe some more blocks]
 203 #  > data-end
 204 #
 205 #  > file dsc
 206 #  [etc]
 207 #
 208 #  > file changes
 209 #  [etc]
 210 #
 211 #  > param head HEAD
 212 #
 213 #  > want signed-tag
 214 #  [indicates that signed tag is wanted]
 215 #  < data-block NBYTES
 216 #  < [NBYTES bytes of data (no newline)]
 217 #  [maybe some more blocks]
 218 #  < data-end
 219 #  < files-end
 220 #
 221 #  > want signed-dsc-changes
 222 #  < data-block NBYTES    [transfer of signed dsc]
 223 #  [etc]
 224 #  < data-block NBYTES    [transfer of signed changes]
 225 #  [etc]
 226 #  < files-end
 227 #
 228 #  > complete
 229
 230 our $i_child_pid;
 231
 232 sub i_child_report () {
 233     # Sees if our child has died, and reap it if so.  Returns a string
 234     # describing how it died if it failed, or undef otherwise.
 235     return undef unless $i_child_pid;
 236     my $got = waitpid $i_child_pid, WNOHANG;
 237     return undef if $got <= 0;
 238     die unless $got == $i_child_pid;
 239     $i_child_pid = undef;
 240     return undef unless $?;
 241     return "build host child ".waitstatusmsg();
 242 }
 243
 244 sub badproto ($$) {
 245     my ($fh, $m) = @_;
 246     fail "connection lost: $!" if $fh->error;
 247     fail "protocol violation; $m not expected";
 248 }
 249
 250 sub badproto_badread ($$) {
 251     my ($fh, $wh) = @_;
 252     fail "connection lost: $!" if $!;
 253     my $report = i_child_report();
 254     fail $report if defined $report;
 255     badproto $fh, "eof (reading $wh)";
 256 }
 257
 258 sub protocol_expect (&$) {
 259     my ($match, $fh) = @_;
 260     local $_;
 261     $_ = <$fh>;
 262     defined && chomp or badproto_badread $fh, "protocol message";
 263     if (wantarray) {
 264         my @r = &$match;
 265         return @r if @r;
 266     } else {
 267         my $r = &$match;
 268         return $r if $r;
 269     }
 270     badproto $fh, "\`$_'";
 271 }
 272
 273 sub protocol_send_file ($$) {
 274     my ($fh, $ourfn) = @_;
 275     open PF, "<", $ourfn or die "$ourfn: $!";
 276     for (;;) {
 277         my $d;
 278         my $got = read PF, $d, 65536;
 279         die "$ourfn: $!" unless defined $got;
 280         last if !$got;
 281         print $fh "data-block ".length($d)."\n" or die $!;
 282         print $fh $d or die $!;
 283     }
 284     PF->error and die "$ourfn $!";
 285     print $fh "data-end\n" or die $!;
 286     close PF;
 287 }
 288
 289 sub protocol_read_bytes ($$) {
 290     my ($fh, $nbytes) = @_;
 291     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 292     my $d;
 293     my $got = read $fh, $d, $nbytes;
 294     $got==$nbytes or badproto_badread $fh, "data block";
 295     return $d;
 296 }
 297
 298 sub protocol_receive_file ($$) {
 299     my ($fh, $ourfn) = @_;
 300     printdebug "() $ourfn\n";
 301     open PF, ">", $ourfn or die "$ourfn: $!";
 302     for (;;) {
 303         my ($y,$l) = protocol_expect {
 304             m/^data-block (.*)$/ ? (1,$1) :
 305             m/^data-end$/ ? (0,) :
 306             ();
 307         } $fh;
 308         last unless $y;
 309         my $d = protocol_read_bytes $fh, $l;
 310         print PF $d or die $!;
 311     }
 312     close PF or die $!;
 313 }
 314
 315 #---------- remote protocol support, responder ----------
 316
 317 sub responder_send_command ($) {
 318     my ($command) = @_;
 319     return unless $we_are_responder;
 320     # called even without $we_are_responder
 321     printdebug ">> $command\n";
 322     print PO $command, "\n" or die $!;
 323 }
 324
 325 sub responder_send_file ($$) {
 326     my ($keyword, $ourfn) = @_;
 327     return unless $we_are_responder;
 328     printdebug "]] $keyword $ourfn\n";
 329     responder_send_command "file $keyword";
 330     protocol_send_file \*PO, $ourfn;
 331 }
 332
 333 sub responder_receive_files ($@) {
 334     my ($keyword, @ourfns) = @_;
 335     die unless $we_are_responder;
 336     printdebug "[[ $keyword @ourfns\n";
 337     responder_send_command "want $keyword";
 338     foreach my $fn (@ourfns) {
 339         protocol_receive_file \*PI, $fn;
 340     }
 341     printdebug "[[\$\n";
 342     protocol_expect { m/^files-end$/ } \*PI;
 343 }
 344
 345 #---------- remote protocol support, initiator ----------
 346
 347 sub initiator_expect (&) {
 348     my ($match) = @_;
 349     protocol_expect { &$match } \*RO;
 350 }
 351
 352 #---------- end remote code ----------
 353
 354 sub progress {
 355     if ($we_are_responder) {
 356         my $m = join '', @_;
 357         responder_send_command "progress ".length($m) or die $!;
 358         print PO $m or die $!;
 359     } else {
 360         print @_, "\n";
 361     }
 362 }
 363
 364 our $ua;
 365
 366 sub url_get {
 367     if (!$ua) {
 368         $ua = LWP::UserAgent->new();
 369         $ua->env_proxy;
 370     }
 371     my $what = $_[$#_];
 372     progress "downloading $what...";
 373     my $r = $ua->get(@_) or die $!;
 374     return undef if $r->code == 404;
 375     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 376     return $r->decoded_content(charset => 'none');
 377 }
 378
 379 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 380
 381 sub shellquote {
 382     my @out;
 383     local $_;
 384     foreach my $a (@_) {
 385         $_ = $a;
 386         if (m{[^-=_./0-9a-z]}i) {
 387             s{['\\]}{'\\$&'}g;
 388             push @out, "'$_'";
 389         } else {
 390             push @out, $_;
 391         }
 392     }
 393     return join ' ', @out;
 394 }
 395
 396 sub printcmd {
 397     my $fh = shift @_;
 398     my $intro = shift @_;
 399     print $fh $intro," " or die $!;
 400     print $fh shellquote @_ or die $!;
 401     print $fh "\n" or die $!;
 402 }
 403
 404 sub failedcmd {
 405     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 406     if ($!) {
 407         fail "failed to fork/exec: $!";
 408     } elsif ($?) {
 409         fail "subprocess ".waitstatusmsg();
 410     } else {
 411         fail "subprocess produced invalid output";
 412     }
 413 }
 414
 415 sub runcmd {
 416     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 417     $!=0; $?=0;
 418     failedcmd @_ if system @_;
 419 }
 420
 421 sub act_local () { return $dryrun_level <= 1; }
 422 sub act_scary () { return !$dryrun_level; }
 423
 424 sub printdone {
 425     if (!$dryrun_level) {
 426         progress "dgit ok: @_";
 427     } else {
 428         progress "would be ok: @_ (but dry run only)";
 429     }
 430 }
 431
 432 sub cmdoutput_errok {
 433     die Dumper(\@_)." ?" if grep { !defined } @_;
 434     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 435     open P, "-|", @_ or die $!;
 436     my $d;
 437     $!=0; $?=0;
 438     { local $/ = undef; $d = <P>; }
 439     die $! if P->error;
 440     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 441     chomp $d;
 442     $d =~ m/^.*/;
 443     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 444     return $d;
 445 }
 446
 447 sub cmdoutput {
 448     my $d = cmdoutput_errok @_;
 449     defined $d or failedcmd @_;
 450     return $d;
 451 }
 452
 453 sub dryrun_report {
 454     printcmd(\*STDERR,$debugprefix."#",@_);
 455 }
 456
 457 sub runcmd_ordryrun {
 458     if (act_scary()) {
 459         runcmd @_;
 460     } else {
 461         dryrun_report @_;
 462     }
 463 }
 464
 465 sub runcmd_ordryrun_local {
 466     if (act_local()) {
 467         runcmd @_;
 468     } else {
 469         dryrun_report @_;
 470     }
 471 }
 472
 473 sub shell_cmd {
 474     my ($first_shell, @cmd) = @_;
 475     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 476 }
 477
 478 our $helpmsg = <<END;
 479 main usages:
 480   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 481   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 482   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 483   dgit [dgit-opts] push [dgit-opts] [suite]
 484   dgit [dgit-opts] rpush build-host:build-dir ...
 485 important dgit options:
 486   -k<keyid>           sign tag and package with <keyid> instead of default
 487   --dry-run -n        do not change anything, but go through the motions
 488   --damp-run -L       like --dry-run but make local changes, without signing
 489   --new -N            allow introducing a new package
 490   --debug -D          increase debug level
 491   -c<name>=<value>    set git config option (used directly by dgit too)
 492 END
 493
 494 our $later_warning_msg = <<END;
 495 Perhaps the upload is stuck in incoming.  Using the version from git.
 496 END
 497
 498 sub badusage {
 499     print STDERR "$us: @_\n", $helpmsg or die $!;
 500     exit 8;
 501 }
 502
 503 sub nextarg {
 504     @ARGV or badusage "too few arguments";
 505     return scalar shift @ARGV;
 506 }
 507
 508 sub cmd_help () {
 509     print $helpmsg or die $!;
 510     exit 0;
 511 }
 512
 513 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 514
 515 our %defcfg = ('dgit.default.distro' => 'debian',
 516                'dgit.default.username' => '',
 517                'dgit.default.archive-query-default-component' => 'main',
 518                'dgit.default.ssh' => 'ssh',
 519                'dgit.default.archive-query' => 'madison:',
 520                'dgit.default.sshpsql-dbname' => 'service=projectb',
 521                'dgit-distro.debian.archive-query' => 'sshpsql:',
 522                'dgit-distro.debian.git-host' => 'git.debian.org',
 523                'dgit-distro.debian.git-proto' => 'git+ssh://',
 524                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 525                'dgit-distro.debian.git-check' => 'ssh-cmd',
 526                'dgit-distro.debian.git-create' => 'ssh-cmd',
 527                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 528                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 529                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 530  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 531  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 532                'dgit-distro.ubuntu.git-check' => 'false',
 533  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 534                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 535                'dgit-distro.test-dummy.username' => "alice",
 536                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 537                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 538                'dgit-distro.test-dummy.git-url' => "$td/git",
 539                'dgit-distro.test-dummy.git-host' => "git",
 540                'dgit-distro.test-dummy.git-path' => "$td/git",
 541                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 542                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 543                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 544                );
 545
 546 sub cfg {
 547     foreach my $c (@_) {
 548         return undef if $c =~ /RETURN-UNDEF/;
 549         my @cmd = (@git, qw(config --), $c);
 550         my $v;
 551         {
 552             local ($debug) = $debug-1;
 553             $v = cmdoutput_errok @cmd;
 554         };
 555         if ($?==0) {
 556             return $v;
 557         } elsif ($?!=256) {
 558             failedcmd @cmd;
 559         }
 560         my $dv = $defcfg{$c};
 561         return $dv if defined $dv;
 562     }
 563     badcfg "need value for one of: @_\n".
 564         "$us: distro or suite appears not to be (properly) supported";
 565 }
 566
 567 sub access_basedistro () {
 568     if (defined $idistro) {
 569         return $idistro;
 570     } else {
 571         return cfg("dgit-suite.$isuite.distro",
 572                    "dgit.default.distro");
 573     }
 574 }
 575
 576 sub access_quirk () {
 577     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 578     my $basedistro = access_basedistro();
 579     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 580                               'RETURN-UNDEF');
 581     if (defined $backports_quirk) {
 582         my $re = $backports_quirk;
 583         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 584         $re =~ s/\*/.*/g;
 585         $re =~ s/\%/([-0-9a-z_]+)/
 586             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 587         if ($isuite =~ m/^$re$/) {
 588             return ('backports',"$basedistro-backports",$1);
 589         }
 590     }
 591     return ('none',undef);
 592 }
 593
 594 sub access_distros () {
 595     # Returns list of distros to try, in order
 596     #
 597     # We want to try:
 598     #    1. the access_quirk distro, if any
 599     #    2a. the user's specified distro, or failing that  } basedistro
 600     #    2b. the distro calculated from the suite          }
 601     my @l = access_basedistro();
 602
 603     my (undef,$quirkdistro) = access_quirk();
 604     unshift @l, $quirkdistro;
 605     return grep { defined } @l;
 606 }
 607
 608 sub access_cfg (@) {
 609     my (@keys) = @_;
 610     my @cfgs;
 611     # The nesting of these loops determines the search order.  We put
 612     # the key loop on the outside so that we search all the distros
 613     # for each key, before going on to the next key.  That means that
 614     # if access_cfg is called with a more specific, and then a less
 615     # specific, key, an earlier distro can override the less specific
 616     # without necessarily overriding any more specific keys.  (If the
 617     # distro wants to override the more specific keys it can simply do
 618     # so; whereas if we did the loop the other way around, it would be
 619     # impossible to for an earlier distro to override a less specific
 620     # key but not the more specific ones without restating the unknown
 621     # values of the more specific keys.
 622     my @realkeys;
 623     my @rundef;
 624     # We have to deal with RETURN-UNDEF specially, so that we don't
 625     # terminate the search prematurely.
 626     foreach (@keys) {
 627         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 628         push @realkeys, $_
 629     }
 630     foreach my $d (access_distros()) {
 631         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 632     }
 633     push @cfgs, map { "dgit.default.$_" } @realkeys;
 634     push @cfgs, @rundef;
 635     my $value = cfg(@cfgs);
 636     return $value;
 637 }
 638
 639 sub string_to_ssh ($) {
 640     my ($spec) = @_;
 641     if ($spec =~ m/\s/) {
 642         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 643     } else {
 644         return ($spec);
 645     }
 646 }
 647
 648 sub access_cfg_ssh () {
 649     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 650     if (!defined $gitssh) {
 651         return @ssh;
 652     } else {
 653         return string_to_ssh $gitssh;
 654     }
 655 }
 656
 657 sub access_runeinfo ($) {
 658     my ($info) = @_;
 659     return ": dgit ".access_basedistro()." $info ;";
 660 }
 661
 662 sub access_someuserhost ($) {
 663     my ($some) = @_;
 664     my $user = access_cfg("$some-user",'username');
 665     my $host = access_cfg("$some-host");
 666     return length($user) ? "$user\@$host" : $host;
 667 }
 668
 669 sub access_gituserhost () {
 670     return access_someuserhost('git');
 671 }
 672
 673 sub access_giturl (;$) {
 674     my ($optional) = @_;
 675     my $url = access_cfg('git-url','RETURN-UNDEF');
 676     if (!defined $url) {
 677         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 678         return undef unless defined $proto;
 679         $url =
 680             $proto.
 681             access_gituserhost().
 682             access_cfg('git-path');
 683     }
 684     return "$url/$package.git";
 685 }
 686
 687 sub parsecontrolfh ($$;$) {
 688     my ($fh, $desc, $allowsigned) = @_;
 689     our $dpkgcontrolhash_noissigned;
 690     my $c;
 691     for (;;) {
 692         my %opts = ('name' => $desc);
 693         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 694         $c = Dpkg::Control::Hash->new(%opts);
 695         $c->parse($fh,$desc) or die "parsing of $desc failed";
 696         last if $allowsigned;
 697         last if $dpkgcontrolhash_noissigned;
 698         my $issigned= $c->get_option('is_pgp_signed');
 699         if (!defined $issigned) {
 700             $dpkgcontrolhash_noissigned= 1;
 701             seek $fh, 0,0 or die "seek $desc: $!";
 702         } elsif ($issigned) {
 703             fail "control file $desc is (already) PGP-signed. ".
 704                 " Note that dgit push needs to modify the .dsc and then".
 705                 " do the signature itself";
 706         } else {
 707             last;
 708         }
 709     }
 710     return $c;
 711 }
 712
 713 sub parsecontrol {
 714     my ($file, $desc) = @_;
 715     my $fh = new IO::Handle;
 716     open $fh, '<', $file or die "$file: $!";
 717     my $c = parsecontrolfh($fh,$desc);
 718     $fh->error and die $!;
 719     close $fh;
 720     return $c;
 721 }
 722
 723 sub getfield ($$) {
 724     my ($dctrl,$field) = @_;
 725     my $v = $dctrl->{$field};
 726     return $v if defined $v;
 727     fail "missing field $field in ".$v->get_option('name');
 728 }
 729
 730 sub parsechangelog {
 731     my $c = Dpkg::Control::Hash->new();
 732     my $p = new IO::Handle;
 733     my @cmd = (qw(dpkg-parsechangelog), @_);
 734     open $p, '-|', @cmd or die $!;
 735     $c->parse($p);
 736     $?=0; $!=0; close $p or failedcmd @cmd;
 737     return $c;
 738 }
 739
 740 sub git_get_ref ($) {
 741     my ($refname) = @_;
 742     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 743     if (!defined $got) {
 744         $?==256 or fail "git show-ref failed (status $?)";
 745         printdebug "ref $refname= [show-ref exited 1]\n";
 746         return '';
 747     }
 748     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 749         printdebug "ref $refname=$1\n";
 750         return $1;
 751     } else {
 752         printdebug "ref $refname= [no match]\n";
 753         return '';
 754     }
 755 }
 756
 757 sub must_getcwd () {
 758     my $d = getcwd();
 759     defined $d or fail "getcwd failed: $!";
 760     return $d;
 761 }
 762
 763 our %rmad;
 764
 765 sub archive_query ($) {
 766     my ($method) = @_;
 767     my $query = access_cfg('archive-query','RETURN-UNDEF');
 768     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 769     my $proto = $1;
 770     my $data = $'; #';
 771     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 772 }
 773
 774 sub pool_dsc_subpath ($$) {
 775     my ($vsn,$component) = @_; # $package is implict arg
 776     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 777     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 778 }
 779
 780 sub archive_query_madison {
 781     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 782 }
 783
 784 sub madison_get_parse {
 785     my ($proto,$data) = @_;
 786     die unless $proto eq 'madison';
 787     if (!length $data) {
 788         $data= access_cfg('madison-distro','RETURN-UNDEF');
 789         $data //= access_basedistro();
 790     }
 791     $rmad{$proto,$data,$package} ||= cmdoutput
 792         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 793     my $rmad = $rmad{$proto,$data,$package};
 794
 795     my @out;
 796     foreach my $l (split /\n/, $rmad) {
 797         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 798                   \s*( [^ \t|]+ )\s* \|
 799                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 800                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 801         $1 eq $package or die "$rmad $package ?";
 802         my $vsn = $2;
 803         my $newsuite = $3;
 804         my $component;
 805         if (defined $4) {
 806             $component = $4;
 807         } else {
 808             $component = access_cfg('archive-query-default-component');
 809         }
 810         $5 eq 'source' or die "$rmad ?";
 811         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 812     }
 813     return sort { -version_compare($a->[0],$b->[0]); } @out;
 814 }
 815
 816 sub canonicalise_suite_madison {
 817     # madison canonicalises for us
 818     my @r = madison_get_parse(@_);
 819     @r or fail
 820         "unable to canonicalise suite using package $package".
 821         " which does not appear to exist in suite $isuite;".
 822         " --existing-package may help";
 823     return $r[0][2];
 824 }
 825
 826 sub sshpsql ($$$) {
 827     my ($data,$runeinfo,$sql) = @_;
 828     if (!length $data) {
 829         $data= access_someuserhost('sshpsql').':'.
 830             access_cfg('sshpsql-dbname');
 831     }
 832     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 833     my ($userhost,$dbname) = ($`,$'); #';
 834     my @rows;
 835     my @cmd = (access_cfg_ssh, $userhost,
 836                access_runeinfo("ssh-psql $runeinfo").
 837                " export LANG=C;".
 838                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 839     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 840     open P, "-|", @cmd or die $!;
 841     while (<P>) {
 842         chomp or die;
 843         printdebug("$debugprefix>|$_|\n");
 844         push @rows, $_;
 845     }
 846     $!=0; $?=0; close P or failedcmd @cmd;
 847     @rows or die;
 848     my $nrows = pop @rows;
 849     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 850     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 851     @rows = map { [ split /\|/, $_ ] } @rows;
 852     my $ncols = scalar @{ shift @rows };
 853     die if grep { scalar @$_ != $ncols } @rows;
 854     return @rows;
 855 }
 856
 857 sub sql_injection_check {
 858     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 859 }
 860
 861 sub archive_query_sshpsql ($$) {
 862     my ($proto,$data) = @_;
 863     sql_injection_check $isuite, $package;
 864     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 865         SELECT source.version, component.name, files.filename, files.sha256sum
 866           FROM source
 867           JOIN src_associations ON source.id = src_associations.source
 868           JOIN suite ON suite.id = src_associations.suite
 869           JOIN dsc_files ON dsc_files.source = source.id
 870           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 871           JOIN component ON component.id = files_archive_map.component_id
 872           JOIN files ON files.id = dsc_files.file
 873          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 874            AND source.source='$package'
 875            AND files.filename LIKE '%.dsc';
 876 END
 877     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 878     my $digester = Digest::SHA->new(256);
 879     @rows = map {
 880         my ($vsn,$component,$filename,$sha256sum) = @$_;
 881         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 882     } @rows;
 883     return @rows;
 884 }
 885
 886 sub canonicalise_suite_sshpsql ($$) {
 887     my ($proto,$data) = @_;
 888     sql_injection_check $isuite;
 889     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 890         SELECT suite.codename
 891           FROM suite where suite_name='$isuite' or codename='$isuite';
 892 END
 893     @rows = map { $_->[0] } @rows;
 894     fail "unknown suite $isuite" unless @rows;
 895     die "ambiguous $isuite: @rows ?" if @rows>1;
 896     return $rows[0];
 897 }
 898
 899 sub canonicalise_suite_dummycat ($$) {
 900     my ($proto,$data) = @_;
 901     my $dpath = "$data/suite.$isuite";
 902     if (!open C, "<", $dpath) {
 903         $!==ENOENT or die "$dpath: $!";
 904         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 905         return $isuite;
 906     }
 907     $!=0; $_ = <C>;
 908     chomp or die "$dpath: $!";
 909     close C;
 910     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 911     return $_;
 912 }
 913
 914 sub archive_query_dummycat ($$) {
 915     my ($proto,$data) = @_;
 916     canonicalise_suite();
 917     my $dpath = "$data/package.$csuite.$package";
 918     if (!open C, "<", $dpath) {
 919         $!==ENOENT or die "$dpath: $!";
 920         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 921         return ();
 922     }
 923     my @rows;
 924     while (<C>) {
 925         next if m/^\#/;
 926         next unless m/\S/;
 927         die unless chomp;
 928         printdebug "dummycat query $csuite $package $dpath | $_\n";
 929         my @row = split /\s+/, $_;
 930         @row==2 or die "$dpath: $_ ?";
 931         push @rows, \@row;
 932     }
 933     C->error and die "$dpath: $!";
 934     close C;
 935     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 936 }
 937
 938 sub canonicalise_suite () {
 939     return if defined $csuite;
 940     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 941     $csuite = archive_query('canonicalise_suite');
 942     if ($isuite ne $csuite) {
 943         progress "canonical suite name for $isuite is $csuite";
 944     }
 945 }
 946
 947 sub get_archive_dsc () {
 948     canonicalise_suite();
 949     my @vsns = archive_query('archive_query');
 950     foreach my $vinfo (@vsns) {
 951         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 952         $dscurl = access_cfg('mirror').$subpath;
 953         $dscdata = url_get($dscurl);
 954         if (!$dscdata) {
 955             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 956             next;
 957         }
 958         if ($digester) {
 959             $digester->reset();
 960             $digester->add($dscdata);
 961             my $got = $digester->hexdigest();
 962             $got eq $digest or
 963                 fail "$dscurl has hash $got but".
 964                     " archive told us to expect $digest";
 965         }
 966         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 967         printdebug Dumper($dscdata) if $debug>1;
 968         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 969         printdebug Dumper($dsc) if $debug>1;
 970         my $fmt = getfield $dsc, 'Format';
 971         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 972         $dsc_checked = !!$digester;
 973         return;
 974     }
 975     $dsc = undef;
 976 }
 977
 978 sub check_for_git () {
 979     # returns 0 or 1
 980     my $how = access_cfg('git-check');
 981     if ($how eq 'ssh-cmd') {
 982         my @cmd =
 983             (access_cfg_ssh, access_gituserhost(),
 984              access_runeinfo("git-check $package").
 985              " set -e; cd ".access_cfg('git-path').";".
 986              " if test -d $package.git; then echo 1; else echo 0; fi");
 987         my $r= cmdoutput @cmd;
 988         failedcmd @cmd unless $r =~ m/^[01]$/;
 989         return $r+0;
 990     } elsif ($how eq 'true') {
 991         return 1;
 992     } elsif ($how eq 'false') {
 993         return 0;
 994     } else {
 995         badcfg "unknown git-check \`$how'";
 996     }
 997 }
 998
 999 sub create_remote_git_repo () {
1000     my $how = access_cfg('git-create');
1001     if ($how eq 'ssh-cmd') {
1002         runcmd_ordryrun
1003             (access_cfg_ssh, access_gituserhost(),
1004              access_runeinfo("git-create $package").
1005              "set -e; cd ".access_cfg('git-path').";".
1006              " cp -a _template $package.git");
1007     } elsif ($how eq 'true') {
1008         # nothing to do
1009     } else {
1010         badcfg "unknown git-create \`$how'";
1011     }
1012 }
1013
1014 our ($dsc_hash,$lastpush_hash);
1015
1016 our $ud = '.git/dgit/unpack';
1017
1018 sub prep_ud () {
1019     rmtree($ud);
1020     mkpath '.git/dgit';
1021     mkdir $ud or die $!;
1022 }
1023
1024 sub mktree_in_ud_here () {
1025     runcmd qw(git init -q);
1026     rmtree('.git/objects');
1027     symlink '../../../../objects','.git/objects' or die $!;
1028 }
1029
1030 sub mktree_in_ud_from_only_subdir () {
1031     # changes into the subdir
1032     my (@dirs) = <*/.>;
1033     die unless @dirs==1;
1034     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1035     my $dir = $1;
1036     changedir $dir;
1037     fail "source package contains .git directory" if stat_exists '.git';
1038     mktree_in_ud_here();
1039     my $format=get_source_format();
1040     if (madformat($format)) {
1041         rmtree '.pc';
1042     }
1043     runcmd @git, qw(add -Af);
1044     my $tree = cmdoutput @git, qw(write-tree);
1045     $tree =~ m/^\w+$/ or die "$tree ?";
1046     return ($tree,$dir);
1047 }
1048
1049 sub dsc_files_info () {
1050     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1051                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1052                        ['Files',           'Digest::MD5', 'new()']) {
1053         my ($fname, $module, $method) = @$csumi;
1054         my $field = $dsc->{$fname};
1055         next unless defined $field;
1056         eval "use $module; 1;" or die $@;
1057         my @out;
1058         foreach (split /\n/, $field) {
1059             next unless m/\S/;
1060             m/^(\w+) (\d+) (\S+)$/ or
1061                 fail "could not parse .dsc $fname line \`$_'";
1062             my $digester = eval "$module"."->$method;" or die $@;
1063             push @out, {
1064                 Hash => $1,
1065                 Bytes => $2,
1066                 Filename => $3,
1067                 Digester => $digester,
1068             };
1069         }
1070         return @out;
1071     }
1072     fail "missing any supported Checksums-* or Files field in ".
1073         $dsc->get_option('name');
1074 }
1075
1076 sub dsc_files () {
1077     map { $_->{Filename} } dsc_files_info();
1078 }
1079
1080 sub is_orig_file ($;$) {
1081     local ($_) = $_[0];
1082     my $base = $_[1];
1083     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1084     defined $base or return 1;
1085     return $` eq $base;
1086 }
1087
1088 sub make_commit ($) {
1089     my ($file) = @_;
1090     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1091 }
1092
1093 sub clogp_authline ($) {
1094     my ($clogp) = @_;
1095     my $author = getfield $clogp, 'Maintainer';
1096     $author =~ s#,.*##ms;
1097     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1098     my $authline = "$author $date";
1099     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1100         fail "unexpected commit author line format \`$authline'".
1101         " (was generated from changelog Maintainer field)";
1102     return $authline;
1103 }
1104
1105 sub generate_commit_from_dsc () {
1106     prep_ud();
1107     changedir $ud;
1108
1109     foreach my $fi (dsc_files_info()) {
1110         my $f = $fi->{Filename};
1111         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1112
1113         link "../../../$f", $f
1114             or $!==&ENOENT
1115             or die "$f $!";
1116
1117         complete_file_from_dsc('.', $fi);
1118
1119         if (is_orig_file($f)) {
1120             link $f, "../../../../$f"
1121                 or $!==&EEXIST
1122                 or die "$f $!";
1123         }
1124     }
1125
1126     my $dscfn = "$package.dsc";
1127
1128     open D, ">", $dscfn or die "$dscfn: $!";
1129     print D $dscdata or die "$dscfn: $!";
1130     close D or die "$dscfn: $!";
1131     my @cmd = qw(dpkg-source);
1132     push @cmd, '--no-check' if $dsc_checked;
1133     push @cmd, qw(-x --), $dscfn;
1134     runcmd @cmd;
1135
1136     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1137     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1138     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1139     my $authline = clogp_authline $clogp;
1140     my $changes = getfield $clogp, 'Changes';
1141     open C, ">../commit.tmp" or die $!;
1142     print C <<END or die $!;
1143 tree $tree
1144 author $authline
1145 committer $authline
1146
1147 $changes
1148
1149 # imported from the archive
1150 END
1151     close C or die $!;
1152     my $outputhash = make_commit qw(../commit.tmp);
1153     my $cversion = getfield $clogp, 'Version';
1154     progress "synthesised git commit from .dsc $cversion";
1155     if ($lastpush_hash) {
1156         runcmd @git, qw(reset --hard), $lastpush_hash;
1157         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1158         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1159         my $oversion = getfield $oldclogp, 'Version';
1160         my $vcmp =
1161             version_compare($oversion, $cversion);
1162         if ($vcmp < 0) {
1163             # git upload/ is earlier vsn than archive, use archive
1164             open C, ">../commit2.tmp" or die $!;
1165             print C <<END or die $!;
1166 tree $tree
1167 parent $lastpush_hash
1168 parent $outputhash
1169 author $authline
1170 committer $authline
1171
1172 Record $package ($cversion) in archive suite $csuite
1173 END
1174             $outputhash = make_commit qw(../commit2.tmp);
1175         } elsif ($vcmp > 0) {
1176             print STDERR <<END or die $!;
1177
1178 Version actually in archive:    $cversion (older)
1179 Last allegedly pushed/uploaded: $oversion (newer or same)
1180 $later_warning_msg
1181 END
1182             $outputhash = $lastpush_hash;
1183         } else {
1184             $outputhash = $lastpush_hash;
1185         }
1186     }
1187     changedir '../../../..';
1188     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1189             'DGIT_ARCHIVE', $outputhash;
1190     cmdoutput @git, qw(log -n2), $outputhash;
1191     # ... gives git a chance to complain if our commit is malformed
1192     rmtree($ud);
1193     return $outputhash;
1194 }
1195
1196 sub complete_file_from_dsc ($$) {
1197     our ($dstdir, $fi) = @_;
1198     # Ensures that we have, in $dir, the file $fi, with the correct
1199     # contents.  (Downloading it from alongside $dscurl if necessary.)
1200
1201     my $f = $fi->{Filename};
1202     my $tf = "$dstdir/$f";
1203     my $downloaded = 0;
1204
1205     if (stat_exists $tf) {
1206         progress "using existing $f";
1207     } else {
1208         my $furl = $dscurl;
1209         $furl =~ s{/[^/]+$}{};
1210         $furl .= "/$f";
1211         die "$f ?" unless $f =~ m/^${package}_/;
1212         die "$f ?" if $f =~ m#/#;
1213         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1214         next if !act_local();
1215         $downloaded = 1;
1216     }
1217
1218     open F, "<", "$tf" or die "$tf: $!";
1219     $fi->{Digester}->reset();
1220     $fi->{Digester}->addfile(*F);
1221     F->error and die $!;
1222     my $got = $fi->{Digester}->hexdigest();
1223     $got eq $fi->{Hash} or
1224         fail "file $f has hash $got but .dsc".
1225             " demands hash $fi->{Hash} ".
1226             ($downloaded ? "(got wrong file from archive!)"
1227              : "(perhaps you should delete this file?)");
1228 }
1229
1230 sub ensure_we_have_orig () {
1231     foreach my $fi (dsc_files_info()) {
1232         my $f = $fi->{Filename};
1233         next unless is_orig_file($f);
1234         complete_file_from_dsc('..', $fi);
1235     }
1236 }
1237
1238 sub rev_parse ($) {
1239     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1240 }
1241
1242 sub is_fast_fwd ($$) {
1243     my ($ancestor,$child) = @_;
1244     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1245     my $mb = cmdoutput_errok @cmd;
1246     if (defined $mb) {
1247         return rev_parse($mb) eq rev_parse($ancestor);
1248     } else {
1249         $?==256 or failedcmd @cmd;
1250         return 0;
1251     }
1252 }
1253
1254 sub git_fetch_us () {
1255     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1256 }
1257
1258 sub fetch_from_archive () {
1259     # ensures that lrref() is what is actually in the archive,
1260     #  one way or another
1261     get_archive_dsc();
1262
1263     if ($dsc) {
1264         foreach my $field (@ourdscfield) {
1265             $dsc_hash = $dsc->{$field};
1266             last if defined $dsc_hash;
1267         }
1268         if (defined $dsc_hash) {
1269             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1270             $dsc_hash = $&;
1271             progress "last upload to archive specified git hash";
1272         } else {
1273             progress "last upload to archive has NO git hash";
1274         }
1275     } else {
1276         progress "no version available from the archive";
1277     }
1278
1279     $lastpush_hash = git_get_ref(lrref());
1280     printdebug "previous reference hash=$lastpush_hash\n";
1281     my $hash;
1282     if (defined $dsc_hash) {
1283         fail "missing remote git history even though dsc has hash -".
1284             " could not find ref ".lrref().
1285             " (should have been fetched from ".access_giturl()."#".rrref().")"
1286             unless $lastpush_hash;
1287         $hash = $dsc_hash;
1288         ensure_we_have_orig();
1289         if ($dsc_hash eq $lastpush_hash) {
1290         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1291             print STDERR <<END or die $!;
1292
1293 Git commit in archive is behind the last version allegedly pushed/uploaded.
1294 Commit referred to by archive:  $dsc_hash
1295 Last allegedly pushed/uploaded: $lastpush_hash
1296 $later_warning_msg
1297 END
1298             $hash = $lastpush_hash;
1299         } else {
1300             fail "archive's .dsc refers to ".$dsc_hash.
1301                 " but this is an ancestor of ".$lastpush_hash;
1302         }
1303     } elsif ($dsc) {
1304         $hash = generate_commit_from_dsc();
1305     } elsif ($lastpush_hash) {
1306         # only in git, not in the archive yet
1307         $hash = $lastpush_hash;
1308         print STDERR <<END or die $!;
1309
1310 Package not found in the archive, but has allegedly been pushed using dgit.
1311 $later_warning_msg
1312 END
1313     } else {
1314         printdebug "nothing found!\n";
1315         if (defined $skew_warning_vsn) {
1316             print STDERR <<END or die $!;
1317
1318 Warning: relevant archive skew detected.
1319 Archive allegedly contains $skew_warning_vsn
1320 But we were not able to obtain any version from the archive or git.
1321
1322 END
1323         }
1324         return 0;
1325     }
1326     printdebug "current hash=$hash\n";
1327     if ($lastpush_hash) {
1328         fail "not fast forward on last upload branch!".
1329             " (archive's version left in DGIT_ARCHIVE)"
1330             unless is_fast_fwd($lastpush_hash, $hash);
1331     }
1332     if (defined $skew_warning_vsn) {
1333         mkpath '.git/dgit';
1334         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1335         my $clogf = ".git/dgit/changelog.tmp";
1336         runcmd shell_cmd "exec >$clogf",
1337             @git, qw(cat-file blob), "$hash:debian/changelog";
1338         my $gotclogp = parsechangelog("-l$clogf");
1339         my $got_vsn = getfield $gotclogp, 'Version';
1340         printdebug "SKEW CHECK GOT $got_vsn\n";
1341         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1342             print STDERR <<END or die $!;
1343
1344 Warning: archive skew detected.  Using the available version:
1345 Archive allegedly contains    $skew_warning_vsn
1346 We were able to obtain only   $got_vsn
1347
1348 END
1349         }
1350     }
1351     if ($lastpush_hash ne $hash) {
1352         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1353         if (act_local()) {
1354             cmdoutput @upd_cmd;
1355         } else {
1356             dryrun_report @upd_cmd;
1357         }
1358     }
1359     return 1;
1360 }
1361
1362 sub clone ($) {
1363     my ($dstdir) = @_;
1364     canonicalise_suite();
1365     badusage "dry run makes no sense with clone" unless act_local();
1366     mkdir $dstdir or die "$dstdir $!";
1367     changedir $dstdir;
1368     runcmd @git, qw(init -q);
1369     my $giturl = access_giturl(1);
1370     if (defined $giturl) {
1371         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1372         open H, "> .git/HEAD" or die $!;
1373         print H "ref: ".lref()."\n" or die $!;
1374         close H or die $!;
1375         runcmd @git, qw(remote add), 'origin', $giturl;
1376     }
1377     if (check_for_git()) {
1378         progress "fetching existing git history";
1379         git_fetch_us();
1380         runcmd_ordryrun_local @git, qw(fetch origin);
1381     } else {
1382         progress "starting new git history";
1383     }
1384     fetch_from_archive() or no_such_package;
1385     my $vcsgiturl = $dsc->{'Vcs-Git'};
1386     if (length $vcsgiturl) {
1387         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1388     }
1389     runcmd @git, qw(reset --hard), lrref();
1390     printdone "ready for work in $dstdir";
1391 }
1392
1393 sub fetch () {
1394     if (check_for_git()) {
1395         git_fetch_us();
1396     }
1397     fetch_from_archive() or no_such_package();
1398     printdone "fetched into ".lrref();
1399 }
1400
1401 sub pull () {
1402     fetch();
1403     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1404         lrref();
1405     printdone "fetched to ".lrref()." and merged into HEAD";
1406 }
1407
1408 sub check_not_dirty () {
1409     return if $ignoredirty;
1410     my @cmd = (@git, qw(diff --quiet HEAD));
1411     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1412     $!=0; $?=0; system @cmd;
1413     return if !$! && !$?;
1414     if (!$! && $?==256) {
1415         fail "working tree is dirty (does not match HEAD)";
1416     } else {
1417         failedcmd @cmd;
1418     }
1419 }
1420
1421 sub commit_admin ($) {
1422     my ($m) = @_;
1423     progress "$m";
1424     runcmd_ordryrun_local @git, qw(commit -m), $m;
1425 }
1426
1427 sub commit_quilty_patch () {
1428     my $output = cmdoutput @git, qw(status --porcelain);
1429     my %adds;
1430     foreach my $l (split /\n/, $output) {
1431         next unless $l =~ m/\S/;
1432         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1433             $adds{$1}++;
1434         }
1435     }
1436     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1437     if (!%adds) {
1438         progress "nothing quilty to commit, ok.";
1439         return;
1440     }
1441     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1442     commit_admin "Commit Debian 3.0 (quilt) metadata";
1443 }
1444
1445 sub get_source_format () {
1446     if (!open F, "debian/source/format") {
1447         die $! unless $!==&ENOENT;
1448         return '';
1449     }
1450     $_ = <F>;
1451     F->error and die $!;
1452     chomp;
1453     return $_;
1454 }
1455
1456 sub madformat ($) {
1457     my ($format) = @_;
1458     return 0 unless $format eq '3.0 (quilt)';
1459     if ($noquilt) {
1460         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1461         return 0;
1462     }
1463     progress "Format \`$format', checking/updating patch stack";
1464     return 1;
1465 }
1466
1467 sub push_parse_changelog ($) {
1468     my ($clogpfn) = @_;
1469
1470     my $clogp = Dpkg::Control::Hash->new();
1471     $clogp->load($clogpfn) or die;
1472
1473     $package = getfield $clogp, 'Source';
1474     my $cversion = getfield $clogp, 'Version';
1475     my $tag = debiantag($cversion);
1476     runcmd @git, qw(check-ref-format), $tag;
1477
1478     my $dscfn = dscfn($cversion);
1479
1480     return ($clogp, $cversion, $tag, $dscfn);
1481 }
1482
1483 sub push_parse_dsc ($$$) {
1484     my ($dscfn,$dscfnwhat, $cversion) = @_;
1485     $dsc = parsecontrol($dscfn,$dscfnwhat);
1486     my $dversion = getfield $dsc, 'Version';
1487     my $dscpackage = getfield $dsc, 'Source';
1488     ($dscpackage eq $package && $dversion eq $cversion) or
1489         fail "$dscfn is for $dscpackage $dversion".
1490             " but debian/changelog is for $package $cversion";
1491 }
1492
1493 sub push_mktag ($$$$$$$) {
1494     my ($head,$clogp,$tag,
1495         $dscfn,
1496         $changesfile,$changesfilewhat,
1497         $tfn) = @_;
1498
1499     $dsc->{$ourdscfield[0]} = $head;
1500     $dsc->save("$dscfn.tmp") or die $!;
1501
1502     my $changes = parsecontrol($changesfile,$changesfilewhat);
1503     foreach my $field (qw(Source Distribution Version)) {
1504         $changes->{$field} eq $clogp->{$field} or
1505             fail "changes field $field \`$changes->{$field}'".
1506                 " does not match changelog \`$clogp->{$field}'";
1507     }
1508
1509     my $cversion = getfield $clogp, 'Version';
1510     my $clogsuite = getfield $clogp, 'Distribution';
1511
1512     # We make the git tag by hand because (a) that makes it easier
1513     # to control the "tagger" (b) we can do remote signing
1514     my $authline = clogp_authline $clogp;
1515     open TO, '>', $tfn->('.tmp') or die $!;
1516     print TO <<END or die $!;
1517 object $head
1518 type commit
1519 tag $tag
1520 tagger $authline
1521
1522 $package release $cversion for $clogsuite ($csuite) [dgit]
1523 END
1524     close TO or die $!;
1525
1526     my $tagobjfn = $tfn->('.tmp');
1527     if ($sign) {
1528         if (!defined $keyid) {
1529             $keyid = access_cfg('keyid','RETURN-UNDEF');
1530         }
1531         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1532         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1533         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1534         push @sign_cmd, $tfn->('.tmp');
1535         runcmd_ordryrun @sign_cmd;
1536         if (act_scary()) {
1537             $tagobjfn = $tfn->('.signed.tmp');
1538             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1539                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1540         }
1541     }
1542
1543     return ($tagobjfn);
1544 }
1545
1546 sub sign_changes ($) {
1547     my ($changesfile) = @_;
1548     if ($sign) {
1549         my @debsign_cmd = @debsign;
1550         push @debsign_cmd, "-k$keyid" if defined $keyid;
1551         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1552         push @debsign_cmd, $changesfile;
1553         runcmd_ordryrun @debsign_cmd;
1554     }
1555 }
1556
1557 sub dopush () {
1558     printdebug "actually entering push\n";
1559     prep_ud();
1560
1561     access_giturl(); # check that success is vaguely likely
1562
1563     my $clogpfn = ".git/dgit/changelog.822.tmp";
1564     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1565
1566     responder_send_file('parsed-changelog', $clogpfn);
1567
1568     my ($clogp, $cversion, $tag, $dscfn) =
1569         push_parse_changelog("$clogpfn");
1570
1571     my $dscpath = "$buildproductsdir/$dscfn";
1572     stat_exists $dscpath or
1573         fail "looked for .dsc $dscfn, but $!;".
1574             " maybe you forgot to build";
1575
1576     responder_send_file('dsc', $dscpath);
1577
1578     push_parse_dsc($dscpath, $dscfn, $cversion);
1579
1580     my $format = getfield $dsc, 'Format';
1581     printdebug "format $format\n";
1582     if (madformat($format)) {
1583         commit_quilty_patch();
1584     }
1585     check_not_dirty();
1586     changedir $ud;
1587     progress "checking that $dscfn corresponds to HEAD";
1588     runcmd qw(dpkg-source -x --),
1589         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1590     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1591     changedir '../../../..';
1592     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1593     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1594     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1595     $!=0; $?=0;
1596     my $r = system @diffcmd;
1597     if ($r) {
1598         if ($r==256) {
1599             fail "$dscfn specifies a different tree to your HEAD commit;".
1600                 " perhaps you forgot to build".
1601                 ($diffopt eq '--exit-code' ? "" :
1602                  " (run with -D to see full diff output)");
1603         } else {
1604             failedcmd @diffcmd;
1605         }
1606     }
1607 #fetch from alioth
1608 #do fast forward check and maybe fake merge
1609 #    if (!is_fast_fwd(mainbranch
1610 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1611 #        map { lref($_).":".rref($_) }
1612 #        (uploadbranch());
1613     my $head = rev_parse('HEAD');
1614     if (!$changesfile) {
1615         my $multi = "$buildproductsdir/".
1616             "${package}_".(stripepoch $cversion)."_multi.changes";
1617         if (stat_exists "$multi") {
1618             $changesfile = $multi;
1619         } else {
1620             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1621             my @cs = glob "$buildproductsdir/$pat";
1622             fail "failed to find unique changes file".
1623                 " (looked for $pat in $buildproductsdir, or $multi);".
1624                 " perhaps you need to use dgit -C"
1625                 unless @cs==1;
1626             ($changesfile) = @cs;
1627         }
1628     } else {
1629         $changesfile = "$buildproductsdir/$changesfile";
1630     }
1631
1632     responder_send_file('changes',$changesfile);
1633     responder_send_command("param head $head");
1634     responder_send_command("param csuite $csuite");
1635
1636     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1637     my $tagobjfn;
1638
1639     if ($we_are_responder) {
1640         $tagobjfn = $tfn->('.signed.tmp');
1641         responder_receive_files('signed-tag', $tagobjfn);
1642     } else {
1643         $tagobjfn =
1644             push_mktag($head,$clogp,$tag,
1645                        $dscpath,
1646                        $changesfile,$changesfile,
1647                        $tfn);
1648     }
1649
1650     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1651     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1652     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1653     runcmd_ordryrun @git, qw(tag -v --), $tag;
1654
1655     if (!check_for_git()) {
1656         create_remote_git_repo();
1657     }
1658     runcmd_ordryrun @git, qw(push),access_giturl(),
1659         "HEAD:".rrref(), "refs/tags/$tag";
1660     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1661
1662     if ($we_are_responder) {
1663         my $dryrunsuffix = act_local() ? "" : ".tmp";
1664         responder_receive_files('signed-dsc-changes',
1665                                 "$dscpath$dryrunsuffix",
1666                                 "$changesfile$dryrunsuffix");
1667     } else {
1668         if (act_local()) {
1669             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1670         } else {
1671             progress "[new .dsc left in $dscpath.tmp]";
1672         }
1673         sign_changes $changesfile;
1674     }
1675
1676     my $host = access_cfg('upload-host','RETURN-UNDEF');
1677     my @hostarg = defined($host) ? ($host,) : ();
1678     runcmd_ordryrun @dput, @hostarg, $changesfile;
1679     printdone "pushed and uploaded $cversion";
1680
1681     responder_send_command("complete");
1682 }
1683
1684 sub cmd_clone {
1685     parseopts();
1686     my $dstdir;
1687     badusage "-p is not allowed with clone; specify as argument instead"
1688         if defined $package;
1689     if (@ARGV==1) {
1690         ($package) = @ARGV;
1691     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1692         ($package,$isuite) = @ARGV;
1693     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1694         ($package,$dstdir) = @ARGV;
1695     } elsif (@ARGV==3) {
1696         ($package,$isuite,$dstdir) = @ARGV;
1697     } else {
1698         badusage "incorrect arguments to dgit clone";
1699     }
1700     $dstdir ||= "$package";
1701
1702     if (stat_exists $dstdir) {
1703         fail "$dstdir already exists";
1704     }
1705
1706     my $cwd_remove;
1707     if ($rmonerror && !$dryrun_level) {
1708         $cwd_remove= getcwd();
1709         unshift @end, sub {
1710             return unless defined $cwd_remove;
1711             if (!chdir "$cwd_remove") {
1712                 return if $!==&ENOENT;
1713                 die "chdir $cwd_remove: $!";
1714             }
1715             rmtree($dstdir) or die "remove $dstdir: $!\n";
1716         };
1717     }
1718
1719     clone($dstdir);
1720     $cwd_remove = undef;
1721 }
1722
1723 sub branchsuite () {
1724     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1725     if ($branch =~ m#$lbranch_re#o) {
1726         return $1;
1727     } else {
1728         return undef;
1729     }
1730 }
1731
1732 sub fetchpullargs () {
1733     if (!defined $package) {
1734         my $sourcep = parsecontrol('debian/control','debian/control');
1735         $package = getfield $sourcep, 'Source';
1736     }
1737     if (@ARGV==0) {
1738 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1739         if (!$isuite) {
1740             my $clogp = parsechangelog();
1741             $isuite = getfield $clogp, 'Distribution';
1742         }
1743         canonicalise_suite();
1744         progress "fetching from suite $csuite";
1745     } elsif (@ARGV==1) {
1746         ($isuite) = @ARGV;
1747         canonicalise_suite();
1748     } else {
1749         badusage "incorrect arguments to dgit fetch or dgit pull";
1750     }
1751 }
1752
1753 sub cmd_fetch {
1754     parseopts();
1755     fetchpullargs();
1756     fetch();
1757 }
1758
1759 sub cmd_pull {
1760     parseopts();
1761     fetchpullargs();
1762     pull();
1763 }
1764
1765 sub cmd_push {
1766     parseopts();
1767     badusage "-p is not allowed with dgit push" if defined $package;
1768     check_not_dirty();
1769     my $clogp = parsechangelog();
1770     $package = getfield $clogp, 'Source';
1771     my $specsuite;
1772     if (@ARGV==0) {
1773     } elsif (@ARGV==1) {
1774         ($specsuite) = (@ARGV);
1775     } else {
1776         badusage "incorrect arguments to dgit push";
1777     }
1778     $isuite = getfield $clogp, 'Distribution';
1779     if ($new_package) {
1780         local ($package) = $existing_package; # this is a hack
1781         canonicalise_suite();
1782     }
1783     if (defined $specsuite && $specsuite ne $isuite) {
1784         canonicalise_suite();
1785         $csuite eq $specsuite or
1786             fail "dgit push: changelog specifies $isuite ($csuite)".
1787                 " but command line specifies $specsuite";
1788     }
1789     if (check_for_git()) {
1790         git_fetch_us();
1791     }
1792     if (fetch_from_archive()) {
1793         is_fast_fwd(lrref(), 'HEAD') or
1794             fail "dgit push: HEAD is not a descendant".
1795                 " of the archive's version.\n".
1796                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1797     } else {
1798         $new_package or
1799             fail "package appears to be new in this suite;".
1800                 " if this is intentional, use --new";
1801     }
1802     dopush();
1803 }
1804
1805 #---------- remote commands' implementation ----------
1806
1807 sub cmd_remote_push_build_host {
1808     my ($nrargs) = shift @ARGV;
1809     my (@rargs) = @ARGV[0..$nrargs-1];
1810     @ARGV = @ARGV[$nrargs..$#ARGV];
1811     die unless @rargs;
1812     my ($dir,$vsnwant) = @rargs;
1813     # vsnwant is a comma-separated list; we report which we have
1814     # chosen in our ready response (so other end can tell if they
1815     # offered several)
1816     $debugprefix = ' ';
1817     $we_are_responder = 1;
1818
1819     open PI, "<&STDIN" or die $!;
1820     open STDIN, "/dev/null" or die $!;
1821     open PO, ">&STDOUT" or die $!;
1822     autoflush PO 1;
1823     open STDOUT, ">&STDERR" or die $!;
1824     autoflush STDOUT 1;
1825
1826     $vsnwant //= 1;
1827     fail "build host has dgit rpush protocol version".
1828         " $rpushprotovsn but invocation host has $vsnwant"
1829         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1830
1831     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1832
1833     changedir $dir;
1834     &cmd_push;
1835 }
1836
1837 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1838 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1839 #     a good error message)
1840
1841 our $i_tmp;
1842
1843 sub i_cleanup {
1844     local ($@, $?);
1845     my $report = i_child_report();
1846     if (defined $report) {
1847         printdebug "($report)\n";
1848     } elsif ($i_child_pid) {
1849         printdebug "(killing build host child $i_child_pid)\n";
1850         kill 15, $i_child_pid;
1851     }
1852     if (defined $i_tmp && !defined $initiator_tempdir) {
1853         changedir "/";
1854         eval { rmtree $i_tmp; };
1855     }
1856 }
1857
1858 END { i_cleanup(); }
1859
1860 sub i_method {
1861     my ($base,$selector,@args) = @_;
1862     $selector =~ s/\-/_/g;
1863     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1864 }
1865
1866 sub cmd_rpush {
1867     my $host = nextarg;
1868     my $dir;
1869     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1870         $host = $1;
1871         $dir = $'; #';
1872     } else {
1873         $dir = nextarg;
1874     }
1875     $dir =~ s{^-}{./-};
1876     my @rargs = ($dir,$rpushprotovsn);
1877     my @rdgit;
1878     push @rdgit, @dgit;
1879     push @rdgit, @ropts;
1880     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1881     push @rdgit, @ARGV;
1882     my @cmd = (@ssh, $host, shellquote @rdgit);
1883     printcmd \*DEBUG,$debugprefix."+",@cmd;
1884
1885     if (defined $initiator_tempdir) {
1886         rmtree $initiator_tempdir;
1887         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1888         $i_tmp = $initiator_tempdir;
1889     } else {
1890         $i_tmp = tempdir();
1891     }
1892     $i_child_pid = open2(\*RO, \*RI, @cmd);
1893     changedir $i_tmp;
1894     initiator_expect { m/^dgit-remote-push-ready/ };
1895     for (;;) {
1896         my ($icmd,$iargs) = initiator_expect {
1897             m/^(\S+)(?: (.*))?$/;
1898             ($1,$2);
1899         };
1900         i_method "i_resp", $icmd, $iargs;
1901     }
1902 }
1903
1904 sub i_resp_progress ($) {
1905     my ($rhs) = @_;
1906     my $msg = protocol_read_bytes \*RO, $rhs;
1907     progress $msg;
1908 }
1909
1910 sub i_resp_complete {
1911     my $pid = $i_child_pid;
1912     $i_child_pid = undef; # prevents killing some other process with same pid
1913     printdebug "waiting for build host child $pid...\n";
1914     my $got = waitpid $pid, 0;
1915     die $! unless $got == $pid;
1916     die "build host child failed $?" if $?;
1917
1918     i_cleanup();
1919     printdebug "all done\n";
1920     exit 0;
1921 }
1922
1923 sub i_resp_file ($) {
1924     my ($keyword) = @_;
1925     my $localname = i_method "i_localname", $keyword;
1926     my $localpath = "$i_tmp/$localname";
1927     stat_exists $localpath and
1928         badproto \*RO, "file $keyword ($localpath) twice";
1929     protocol_receive_file \*RO, $localpath;
1930     i_method "i_file", $keyword;
1931 }
1932
1933 our %i_param;
1934
1935 sub i_resp_param ($) {
1936     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1937     $i_param{$1} = $2;
1938 }
1939
1940 our %i_wanted;
1941
1942 sub i_resp_want ($) {
1943     my ($keyword) = @_;
1944     die "$keyword ?" if $i_wanted{$keyword}++;
1945     my @localpaths = i_method "i_want", $keyword;
1946     printdebug "[[  $keyword @localpaths\n";
1947     foreach my $localpath (@localpaths) {
1948         protocol_send_file \*RI, $localpath;
1949     }
1950     print RI "files-end\n" or die $!;
1951 }
1952
1953 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1954
1955 sub i_localname_parsed_changelog {
1956     return "remote-changelog.822";
1957 }
1958 sub i_file_parsed_changelog {
1959     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1960         push_parse_changelog "$i_tmp/remote-changelog.822";
1961     die if $i_dscfn =~ m#/|^\W#;
1962 }
1963
1964 sub i_localname_dsc {
1965     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1966     return $i_dscfn;
1967 }
1968 sub i_file_dsc { }
1969
1970 sub i_localname_changes {
1971     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1972     $i_changesfn = $i_dscfn;
1973     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1974     return $i_changesfn;
1975 }
1976 sub i_file_changes { }
1977
1978 sub i_want_signed_tag {
1979     printdebug Dumper(\%i_param, $i_dscfn);
1980     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1981         && defined $i_param{'csuite'}
1982         or badproto \*RO, "premature desire for signed-tag";
1983     my $head = $i_param{'head'};
1984     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
1985
1986     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
1987     $csuite = $&;
1988     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
1989
1990     my $tagobjfn =
1991         push_mktag $head, $i_clogp, $i_tag,
1992             $i_dscfn,
1993             $i_changesfn, 'remote changes',
1994             sub { "tag$_[0]"; };
1995
1996     return $tagobjfn;
1997 }
1998
1999 sub i_want_signed_dsc_changes {
2000     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2001     sign_changes $i_changesfn;
2002     return ($i_dscfn, $i_changesfn);
2003 }
2004
2005 #---------- building etc. ----------
2006
2007 our $version;
2008 our $sourcechanges;
2009 our $dscfn;
2010
2011 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2012
2013 sub build_maybe_quilt_fixup () {
2014     my $format=get_source_format;
2015     return unless madformat $format;
2016     # sigh
2017
2018     # Our objective is:
2019     #  - honour any existing .pc in case it has any strangeness
2020     #  - determine the git commit corresponding to the tip of
2021     #    the patch stack (if there is one)
2022     #  - if there is such a git commit, convert each subsequent
2023     #    git commit into a quilt patch with dpkg-source --commit
2024     #  - otherwise convert all the differences in the tree into
2025     #    a single git commit
2026     #
2027     # To do this we:
2028
2029     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2030     # dgit would include the .pc in the git tree.)  If there isn't
2031     # one, we need to generate one by unpacking the patches that we
2032     # have.
2033     #
2034     # We first look for a .pc in the git tree.  If there is one, we
2035     # will use it.  (This is not the normal case.)
2036     #
2037     # Otherwise need to regenerate .pc so that dpkg-source --commit
2038     # can work.  We do this as follows:
2039     #     1. Collect all relevant .orig from parent directory
2040     #     2. Generate a debian.tar.gz out of
2041     #         debian/{patches,rules,source/format}
2042     #     3. Generate a fake .dsc containing just these fields:
2043     #          Format Source Version Files
2044     #     4. Extract the fake .dsc
2045     #        Now the fake .dsc has a .pc directory.
2046     # (In fact we do this in every case, because in future we will
2047     # want to search for a good base commit for generating patches.)
2048     #
2049     # Then we can actually do the dpkg-source --commit
2050     #     1. Make a new working tree with the same object
2051     #        store as our main tree and check out the main
2052     #        tree's HEAD.
2053     #     2. Copy .pc from the fake's extraction, if necessary
2054     #     3. Run dpkg-source --commit
2055     #     4. If the result has changes to debian/, then
2056     #          - git-add them them
2057     #          - git-add .pc if we had a .pc in-tree
2058     #          - git-commit
2059     #     5. If we had a .pc in-tree, delete it, and git-commit
2060     #     6. Back in the main tree, fast forward to the new HEAD
2061
2062     my $clogp = parsechangelog();
2063     my $headref = rev_parse('HEAD');
2064
2065     prep_ud();
2066     changedir $ud;
2067
2068     my $upstreamversion=$version;
2069     $upstreamversion =~ s/-[^-]*$//;
2070
2071     my $fakeversion="$upstreamversion-~~DGITFAKE";
2072
2073     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2074     print $fakedsc <<END or die $!;
2075 Format: 3.0 (quilt)
2076 Source: $package
2077 Version: $fakeversion
2078 Files:
2079 END
2080
2081     my $dscaddfile=sub {
2082         my ($b) = @_;
2083
2084         my $md = new Digest::MD5;
2085
2086         my $fh = new IO::File $b, '<' or die "$b $!";
2087         stat $fh or die $!;
2088         my $size = -s _;
2089
2090         $md->addfile($fh);
2091         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2092     };
2093
2094     foreach my $f (<../../../../*>) { #/){
2095         my $b=$f; $b =~ s{.*/}{};
2096         next unless is_orig_file $b, srcfn $upstreamversion,'';
2097         link $f, $b or die "$b $!";
2098         $dscaddfile->($b);
2099     }
2100
2101     my @files=qw(debian/source/format debian/rules);
2102     if (stat_exists '../../../debian/patches') {
2103         push @files, 'debian/patches';
2104     }
2105
2106     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2107     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2108
2109     $dscaddfile->($debtar);
2110     close $fakedsc or die $!;
2111
2112     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2113
2114     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2115     rename $fakexdir, "fake" or die "$fakexdir $!";
2116
2117     mkdir "work" or die $!;
2118     changedir "work";
2119     mktree_in_ud_here();
2120     runcmd @git, qw(reset --hard), $headref;
2121
2122     my $mustdeletepc=0;
2123     if (stat_exists ".pc") {
2124         -d _ or die;
2125         progress "Tree already contains .pc - will use it then delete it.";
2126         $mustdeletepc=1;
2127     } else {
2128         rename '../fake/.pc','.pc' or die $!;
2129     }
2130
2131     my $author = getfield $clogp, 'Maintainer';
2132     my $time = time;
2133     my $ncommits = 3;
2134     my $patchname = "auto-$version-$headref-$time";
2135     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2136     mkpath '.git/dgit';
2137     my $descfn = ".git/dgit/quilt-description.tmp";
2138     open O, '>', $descfn or die "$descfn: $!";
2139     $msg =~ s/\n/\n /g;
2140     $msg =~ s/^\s+$/ ./mg;
2141     print O <<END or die $!;
2142 Description: Automatically generated patch ($clogp->{Version})
2143  Last (up to) $ncommits git changes, FYI:
2144  .
2145  $msg
2146 Author: $author
2147
2148 ---
2149
2150 END
2151     close O or die $!;
2152     {
2153         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2154         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2155         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2156         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2157     }
2158
2159     if (!open P, '>>', ".pc/applied-patches") {
2160         $!==&ENOENT or die $!;
2161     } else {
2162         close P;
2163     }
2164
2165     commit_quilty_patch();
2166
2167     if ($mustdeletepc) {
2168         runcmd @git, qw(rm -rq .pc);
2169         commit_admin "Commit removal of .pc (quilt series tracking data)";
2170     }
2171
2172     changedir '../../../..';
2173     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2174 }
2175
2176 sub quilt_fixup_editor () {
2177     my $descfn = $ENV{$fakeeditorenv};
2178     my $editing = $ARGV[$#ARGV];
2179     open I1, '<', $descfn or die "$descfn: $!";
2180     open I2, '<', $editing or die "$editing: $!";
2181     unlink $editing or die "$editing: $!";
2182     open O, '>', $editing or die "$editing: $!";
2183     while (<I1>) { print O or die $!; } I1->error and die $!;
2184     my $copying = 0;
2185     while (<I2>) {
2186         $copying ||= m/^\-\-\- /;
2187         next unless $copying;
2188         print O or die $!;
2189     }
2190     I2->error and die $!;
2191     close O or die $1;
2192     exit 0;
2193 }
2194
2195 sub clean_tree () {
2196     if ($cleanmode eq 'dpkg-source') {
2197         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2198     } elsif ($cleanmode eq 'git') {
2199         runcmd_ordryrun_local @git, qw(clean -xdf);
2200     } elsif ($cleanmode eq 'none') {
2201     } else {
2202         die "$cleanmode ?";
2203     }
2204 }
2205
2206 sub cmd_clean () {
2207     badusage "clean takes no additional arguments" if @ARGV;
2208     clean_tree();
2209 }
2210
2211 sub build_prep () {
2212     badusage "-p is not allowed when building" if defined $package;
2213     check_not_dirty();
2214     clean_tree();
2215     my $clogp = parsechangelog();
2216     $isuite = getfield $clogp, 'Distribution';
2217     $package = getfield $clogp, 'Source';
2218     $version = getfield $clogp, 'Version';
2219     build_maybe_quilt_fixup();
2220 }
2221
2222 sub changesopts () {
2223     my @opts =@changesopts[1..$#changesopts];
2224     if (!defined $changes_since_version) {
2225         my @vsns = archive_query('archive_query');
2226         my @quirk = access_quirk();
2227         if ($quirk[0] eq 'backports') {
2228             local $isuite = $quirk[2];
2229             local $csuite;
2230             canonicalise_suite();
2231             push @vsns, archive_query('archive_query');
2232         }
2233         if (@vsns) {
2234             @vsns = map { $_->[0] } @vsns;
2235             @vsns = sort { -version_compare($a, $b) } @vsns;
2236             $changes_since_version = $vsns[0];
2237             progress "changelog will contain changes since $vsns[0]";
2238         } else {
2239             $changes_since_version = '_';
2240             progress "package seems new, not specifying -v<version>";
2241         }
2242     }
2243     if ($changes_since_version ne '_') {
2244         unshift @opts, "-v$changes_since_version";
2245     }
2246     return @opts;
2247 }
2248
2249 sub cmd_build {
2250     build_prep();
2251     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2252     printdone "build successful\n";
2253 }
2254
2255 sub cmd_git_build {
2256     build_prep();
2257     my @cmd =
2258         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2259          "--git-builder=@dpkgbuildpackage");
2260     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2261         canonicalise_suite();
2262         push @cmd, "--git-debian-branch=".lbranch();
2263     }
2264     push @cmd, changesopts();
2265     runcmd_ordryrun_local @cmd, @ARGV;
2266     printdone "build successful\n";
2267 }
2268
2269 sub build_source {
2270     build_prep();
2271     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2272     $dscfn = dscfn($version);
2273     if ($cleanmode eq 'dpkg-source') {
2274         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2275             changesopts();
2276     } else {
2277         my $pwd = must_getcwd();
2278         my $leafdir = basename $pwd;
2279         changedir "..";
2280         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2281         changedir $pwd;
2282         runcmd_ordryrun_local qw(sh -ec),
2283             'exec >$1; shift; exec "$@"','x',
2284             "../$sourcechanges",
2285             @dpkggenchanges, qw(-S), changesopts();
2286     }
2287 }
2288
2289 sub cmd_build_source {
2290     badusage "build-source takes no additional arguments" if @ARGV;
2291     build_source();
2292     printdone "source built, results in $dscfn and $sourcechanges";
2293 }
2294
2295 sub cmd_sbuild {
2296     build_source();
2297     changedir "..";
2298     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2299     if (act_local()) {
2300         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2301         stat_exists $sourcechanges
2302             or fail "$sourcechanges (in parent directory): $!";
2303         foreach my $cf (glob $pat) {
2304             next if $cf eq $sourcechanges;
2305             unlink $cf or fail "remove $cf: $!";
2306         }
2307     }
2308     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2309     my @changesfiles = glob $pat;
2310     @changesfiles = sort {
2311         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2312             or $a cmp $b
2313     } @changesfiles;
2314     fail "wrong number of different changes files (@changesfiles)"
2315         unless @changesfiles;
2316     runcmd_ordryrun_local @mergechanges, @changesfiles;
2317     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2318     if (act_local()) {
2319         stat_exists $multichanges or fail "$multichanges: $!";
2320     }
2321     printdone "build successful, results in $multichanges\n" or die $!;
2322 }
2323
2324 sub cmd_quilt_fixup {
2325     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2326     my $clogp = parsechangelog();
2327     $version = getfield $clogp, 'Version';
2328     $package = getfield $clogp, 'Source';
2329     build_maybe_quilt_fixup();
2330 }
2331
2332 #---------- argument parsing and main program ----------
2333
2334 sub cmd_version {
2335     print "dgit version $our_version\n" or die $!;
2336     exit 0;
2337 }
2338
2339 sub parseopts () {
2340     my $om;
2341
2342     if (defined $ENV{'DGIT_SSH'}) {
2343         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2344     } elsif (defined $ENV{'GIT_SSH'}) {
2345         @ssh = ($ENV{'GIT_SSH'});
2346     }
2347
2348     while (@ARGV) {
2349         last unless $ARGV[0] =~ m/^-/;
2350         $_ = shift @ARGV;
2351         last if m/^--?$/;
2352         if (m/^--/) {
2353             if (m/^--dry-run$/) {
2354                 push @ropts, $_;
2355                 $dryrun_level=2;
2356             } elsif (m/^--damp-run$/) {
2357                 push @ropts, $_;
2358                 $dryrun_level=1;
2359             } elsif (m/^--no-sign$/) {
2360                 push @ropts, $_;
2361                 $sign=0;
2362             } elsif (m/^--help$/) {
2363                 cmd_help();
2364             } elsif (m/^--version$/) {
2365                 cmd_version();
2366             } elsif (m/^--new$/) {
2367                 push @ropts, $_;
2368                 $new_package=1;
2369             } elsif (m/^--since-version=([^_]+|_)$/) {
2370                 push @ropts, $_;
2371                 $changes_since_version = $1;
2372             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2373                      ($om = $opts_opt_map{$1}) &&
2374                      length $om->[0]) {
2375                 push @ropts, $_;
2376                 $om->[0] = $2;
2377             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2378                      !$opts_opt_cmdonly{$1} &&
2379                      ($om = $opts_opt_map{$1})) {
2380                 push @ropts, $_;
2381                 push @$om, $2;
2382             } elsif (m/^--existing-package=(.*)/s) {
2383                 push @ropts, $_;
2384                 $existing_package = $1;
2385             } elsif (m/^--initiator-tempdir=(.*)/s) {
2386                 $initiator_tempdir = $1;
2387                 $initiator_tempdir =~ m#^/# or
2388                     badusage "--initiator-tempdir must be used specify an".
2389                         " absolute, not relative, directory."
2390             } elsif (m/^--distro=(.*)/s) {
2391                 push @ropts, $_;
2392                 $idistro = $1;
2393             } elsif (m/^--build-products-dir=(.*)/s) {
2394                 push @ropts, $_;
2395                 $buildproductsdir = $1;
2396             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2397                 push @ropts, $_;
2398                 $cleanmode = $1;
2399             } elsif (m/^--clean=(.*)$/s) {
2400                 badusage "unknown cleaning mode \`$1'";
2401             } elsif (m/^--ignore-dirty$/s) {
2402                 push @ropts, $_;
2403                 $ignoredirty = 1;
2404             } elsif (m/^--no-quilt-fixup$/s) {
2405                 push @ropts, $_;
2406                 $noquilt = 1;
2407             } elsif (m/^--no-rm-on-error$/s) {
2408                 push @ropts, $_;
2409                 $rmonerror = 0;
2410             } else {
2411                 badusage "unknown long option \`$_'";
2412             }
2413         } else {
2414             while (m/^-./s) {
2415                 if (s/^-n/-/) {
2416                     push @ropts, $&;
2417                     $dryrun_level=2;
2418                 } elsif (s/^-L/-/) {
2419                     push @ropts, $&;
2420                     $dryrun_level=1;
2421                 } elsif (s/^-h/-/) {
2422                     cmd_help();
2423                 } elsif (s/^-D/-/) {
2424                     push @ropts, $&;
2425                     open DEBUG, ">&STDERR" or die $!;
2426                     autoflush DEBUG 1;
2427                     $debug++;
2428                 } elsif (s/^-N/-/) {
2429                     push @ropts, $&;
2430                     $new_package=1;
2431                 } elsif (s/^-v([^_]+|_)$//s) {
2432                     push @ropts, $&;
2433                     $changes_since_version = $1;
2434                 } elsif (m/^-m/) {
2435                     push @ropts, $&;
2436                     push @changesopts, $_;
2437                     $_ = '';
2438                 } elsif (s/^-c(.*=.*)//s) {
2439                     push @ropts, $&;
2440                     push @git, '-c', $1;
2441                 } elsif (s/^-d(.*)//s) {
2442                     push @ropts, $&;
2443                     $idistro = $1;
2444                 } elsif (s/^-C(.*)//s) {
2445                     push @ropts, $&;
2446                     $changesfile = $1;
2447                     if ($changesfile =~ s#^(.*)/##) {
2448                         $buildproductsdir = $1;
2449                     }
2450                 } elsif (s/^-k(.*)//s) {
2451                     $keyid=$1;
2452                 } elsif (s/^-wn//s) {
2453                     push @ropts, $&;
2454                     $cleanmode = 'none';
2455                 } elsif (s/^-wg//s) {
2456                     push @ropts, $&;
2457                     $cleanmode = 'git';
2458                 } elsif (s/^-wd//s) {
2459                     push @ropts, $&;
2460                     $cleanmode = 'dpkg-source';
2461                 } else {
2462                     badusage "unknown short option \`$_'";
2463                 }
2464             }
2465         }
2466     }
2467 }
2468
2469 if ($ENV{$fakeeditorenv}) {
2470     quilt_fixup_editor();
2471 }
2472
2473 parseopts();
2474 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2475 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2476     if $dryrun_level == 1;
2477 if (!@ARGV) {
2478     print STDERR $helpmsg or die $!;
2479     exit 8;
2480 }
2481 my $cmd = shift @ARGV;
2482 $cmd =~ y/-/_/;
2483
2484 my $fn = ${*::}{"cmd_$cmd"};
2485 $fn or badusage "unknown operation $cmd";
2486 $fn->();