dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2016 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37 use List::MoreUtils qw(pairwise);
  38 use Text::Glob qw(match_glob);
  39 use Fcntl qw(:DEFAULT :flock);
  40 use Carp;
  41
  42 use Debian::Dgit;
  43
  44 our $our_version = 'UNRELEASED'; ###substituted###
  45 our $absurdity = undef; ###substituted###
  46
  47 our @rpushprotovsn_support = qw(4 3 2); # 4 is new tag format
  48 our $protovsn;
  49
  50 our $isuite;
  51 our $idistro;
  52 our $package;
  53 our @ropts;
  54
  55 our $sign = 1;
  56 our $dryrun_level = 0;
  57 our $changesfile;
  58 our $buildproductsdir = '..';
  59 our $new_package = 0;
  60 our $ignoredirty = 0;
  61 our $rmonerror = 1;
  62 our @deliberatelies;
  63 our %previously;
  64 our $existing_package = 'dpkg';
  65 our $cleanmode;
  66 our $changes_since_version;
  67 our $rmchanges;
  68 our $overwrite_version; # undef: not specified; '': check changelog
  69 our $quilt_mode;
  70 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck|gbp|dpm|unapplied';
  71 our $dodep14tag;
  72 our $split_brain_save;
  73 our $we_are_responder;
  74 our $we_are_initiator;
  75 our $initiator_tempdir;
  76 our $patches_applied_dirtily = 00;
  77 our $tagformat_want;
  78 our $tagformat;
  79 our $tagformatfn;
  80 our $chase_dsc_distro=1;
  81
  82 our %forceopts = map { $_=>0 }
  83     qw(unrepresentable unsupported-source-format
  84        dsc-changes-mismatch changes-origs-exactly
  85        import-gitapply-absurd
  86        import-gitapply-no-absurd
  87        import-dsc-with-dgit-field);
  88
  89 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  90
  91 our $suite_re = '[-+.0-9a-z]+';
  92 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  93 our $orig_f_comp_re = 'orig(?:-[-0-9a-z]+)?';
  94 our $orig_f_sig_re = '\\.(?:asc|gpg|pgp)';
  95 our $orig_f_tail_re = "$orig_f_comp_re\\.tar(?:\\.\\w+)?(?:$orig_f_sig_re)?";
  96
  97 our $git_authline_re = '^([^<>]+) \<(\S+)\> (\d+ [-+]\d+)$';
  98 our $splitbraincache = 'dgit-intern/quilt-cache';
  99 our $rewritemap = 'dgit-rewrite/map';
 100
 101 our (@git) = qw(git);
 102 our (@dget) = qw(dget);
 103 our (@curl) = qw(curl);
 104 our (@dput) = qw(dput);
 105 our (@debsign) = qw(debsign);
 106 our (@gpg) = qw(gpg);
 107 our (@sbuild) = qw(sbuild);
 108 our (@ssh) = 'ssh';
 109 our (@dgit) = qw(dgit);
 110 our (@aptget) = qw(apt-get);
 111 our (@aptcache) = qw(apt-cache);
 112 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
 113 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
 114 our (@dpkggenchanges) = qw(dpkg-genchanges);
 115 our (@mergechanges) = qw(mergechanges -f);
 116 our (@gbp_build) = ('');
 117 our (@gbp_pq) = ('gbp pq');
 118 our (@changesopts) = ('');
 119
 120 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
 121                      'curl' => \@curl,
 122                      'dput' => \@dput,
 123                      'debsign' => \@debsign,
 124                      'gpg' => \@gpg,
 125                      'sbuild' => \@sbuild,
 126                      'ssh' => \@ssh,
 127                      'dgit' => \@dgit,
 128                      'git' => \@git,
 129                      'apt-get' => \@aptget,
 130                      'apt-cache' => \@aptcache,
 131                      'dpkg-source' => \@dpkgsource,
 132                      'dpkg-buildpackage' => \@dpkgbuildpackage,
 133                      'dpkg-genchanges' => \@dpkggenchanges,
 134                      'gbp-build' => \@gbp_build,
 135                      'gbp-pq' => \@gbp_pq,
 136                      'ch' => \@changesopts,
 137                      'mergechanges' => \@mergechanges);
 138
 139 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 140 our %opts_cfg_insertpos = map {
 141     $_,
 142     scalar @{ $opts_opt_map{$_} }
 143 } keys %opts_opt_map;
 144
 145 sub parseopts_late_defaults();
 146 sub setup_gitattrs(;$);
 147
 148 our $keyid;
 149
 150 autoflush STDOUT 1;
 151
 152 our $supplementary_message = '';
 153 our $need_split_build_invocation = 0;
 154 our $split_brain = 0;
 155
 156 END {
 157     local ($@, $?);
 158     return unless forkcheck_mainprocess();
 159     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 160 }
 161
 162 our $remotename = 'dgit';
 163 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 164 our $csuite;
 165 our $instead_distro;
 166
 167 if (!defined $absurdity) {
 168     $absurdity = $0;
 169     $absurdity =~ s{/[^/]+$}{/absurd} or die;
 170 }
 171
 172 sub debiantag ($$) {
 173     my ($v,$distro) = @_;
 174     return $tagformatfn->($v, $distro);
 175 }
 176
 177 sub debiantag_maintview ($$) {
 178     my ($v,$distro) = @_;
 179     return "$distro/".dep14_version_mangle $v;
 180 }
 181
 182 sub madformat ($) { $_[0] eq '3.0 (quilt)' }
 183
 184 sub lbranch () { return "$branchprefix/$csuite"; }
 185 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 186 sub lref () { return "refs/heads/".lbranch(); }
 187 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 188 sub rrref () { return server_ref($csuite); }
 189
 190 sub stripepoch ($) {
 191     my ($vsn) = @_;
 192     $vsn =~ s/^\d+\://;
 193     return $vsn;
 194 }
 195
 196 sub srcfn ($$) {
 197     my ($vsn,$sfx) = @_;
 198     return "${package}_".(stripepoch $vsn).$sfx
 199 }
 200
 201 sub dscfn ($) {
 202     my ($vsn) = @_;
 203     return srcfn($vsn,".dsc");
 204 }
 205
 206 sub changespat ($;$) {
 207     my ($vsn, $arch) = @_;
 208     return "${package}_".(stripepoch $vsn)."_".($arch//'*').".changes";
 209 }
 210
 211 sub upstreamversion ($) {
 212     my ($vsn) = @_;
 213     $vsn =~ s/-[^-]+$//;
 214     return $vsn;
 215 }
 216
 217 our $us = 'dgit';
 218 initdebug('');
 219
 220 our @end;
 221 END {
 222     local ($?);
 223     return unless forkcheck_mainprocess();
 224     foreach my $f (@end) {
 225         eval { $f->(); };
 226         print STDERR "$us: cleanup: $@" if length $@;
 227     }
 228 };
 229
 230 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 231
 232 sub forceable_fail ($$) {
 233     my ($forceoptsl, $msg) = @_;
 234     fail $msg unless grep { $forceopts{$_} } @$forceoptsl;
 235     print STDERR "warning: overriding problem due to --force:\n". $msg;
 236 }
 237
 238 sub forceing ($) {
 239     my ($forceoptsl) = @_;
 240     my @got = grep { $forceopts{$_} } @$forceoptsl;
 241     return 0 unless @got;
 242     print STDERR
 243  "warning: skipping checks or functionality due to --force-$got[0]\n";
 244 }
 245
 246 sub no_such_package () {
 247     print STDERR "$us: package $package does not exist in suite $isuite\n";
 248     exit 4;
 249 }
 250
 251 sub changedir ($) {
 252     my ($newdir) = @_;
 253     printdebug "CD $newdir\n";
 254     chdir $newdir or confess "chdir: $newdir: $!";
 255 }
 256
 257 sub deliberately ($) {
 258     my ($enquiry) = @_;
 259     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 260 }
 261
 262 sub deliberately_not_fast_forward () {
 263     foreach (qw(not-fast-forward fresh-repo)) {
 264         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 265     }
 266 }
 267
 268 sub quiltmode_splitbrain () {
 269     $quilt_mode =~ m/gbp|dpm|unapplied/;
 270 }
 271
 272 sub opts_opt_multi_cmd {
 273     my @cmd;
 274     push @cmd, split /\s+/, shift @_;
 275     push @cmd, @_;
 276     @cmd;
 277 }
 278
 279 sub gbp_pq {
 280     return opts_opt_multi_cmd @gbp_pq;
 281 }
 282
 283 #---------- remote protocol support, common ----------
 284
 285 # remote push initiator/responder protocol:
 286 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 287 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 288 #  < dgit-remote-push-ready <actual-proto-vsn>
 289 #
 290 # occasionally:
 291 #
 292 #  > progress NBYTES
 293 #  [NBYTES message]
 294 #
 295 #  > supplementary-message NBYTES          # $protovsn >= 3
 296 #  [NBYTES message]
 297 #
 298 # main sequence:
 299 #
 300 #  > file parsed-changelog
 301 #  [indicates that output of dpkg-parsechangelog follows]
 302 #  > data-block NBYTES
 303 #  > [NBYTES bytes of data (no newline)]
 304 #  [maybe some more blocks]
 305 #  > data-end
 306 #
 307 #  > file dsc
 308 #  [etc]
 309 #
 310 #  > file changes
 311 #  [etc]
 312 #
 313 #  > param head DGIT-VIEW-HEAD
 314 #  > param csuite SUITE
 315 #  > param tagformat old|new
 316 #  > param maint-view MAINT-VIEW-HEAD
 317 #
 318 #  > previously REFNAME=OBJNAME       # if --deliberately-not-fast-forward
 319 #                                     # goes into tag, for replay prevention
 320 #
 321 #  > want signed-tag
 322 #  [indicates that signed tag is wanted]
 323 #  < data-block NBYTES
 324 #  < [NBYTES bytes of data (no newline)]
 325 #  [maybe some more blocks]
 326 #  < data-end
 327 #  < files-end
 328 #
 329 #  > want signed-dsc-changes
 330 #  < data-block NBYTES    [transfer of signed dsc]
 331 #  [etc]
 332 #  < data-block NBYTES    [transfer of signed changes]
 333 #  [etc]
 334 #  < files-end
 335 #
 336 #  > complete
 337
 338 our $i_child_pid;
 339
 340 sub i_child_report () {
 341     # Sees if our child has died, and reap it if so.  Returns a string
 342     # describing how it died if it failed, or undef otherwise.
 343     return undef unless $i_child_pid;
 344     my $got = waitpid $i_child_pid, WNOHANG;
 345     return undef if $got <= 0;
 346     die unless $got == $i_child_pid;
 347     $i_child_pid = undef;
 348     return undef unless $?;
 349     return "build host child ".waitstatusmsg();
 350 }
 351
 352 sub badproto ($$) {
 353     my ($fh, $m) = @_;
 354     fail "connection lost: $!" if $fh->error;
 355     fail "protocol violation; $m not expected";
 356 }
 357
 358 sub badproto_badread ($$) {
 359     my ($fh, $wh) = @_;
 360     fail "connection lost: $!" if $!;
 361     my $report = i_child_report();
 362     fail $report if defined $report;
 363     badproto $fh, "eof (reading $wh)";
 364 }
 365
 366 sub protocol_expect (&$) {
 367     my ($match, $fh) = @_;
 368     local $_;
 369     $_ = <$fh>;
 370     defined && chomp or badproto_badread $fh, "protocol message";
 371     if (wantarray) {
 372         my @r = &$match;
 373         return @r if @r;
 374     } else {
 375         my $r = &$match;
 376         return $r if $r;
 377     }
 378     badproto $fh, "\`$_'";
 379 }
 380
 381 sub protocol_send_file ($$) {
 382     my ($fh, $ourfn) = @_;
 383     open PF, "<", $ourfn or die "$ourfn: $!";
 384     for (;;) {
 385         my $d;
 386         my $got = read PF, $d, 65536;
 387         die "$ourfn: $!" unless defined $got;
 388         last if !$got;
 389         print $fh "data-block ".length($d)."\n" or die $!;
 390         print $fh $d or die $!;
 391     }
 392     PF->error and die "$ourfn $!";
 393     print $fh "data-end\n" or die $!;
 394     close PF;
 395 }
 396
 397 sub protocol_read_bytes ($$) {
 398     my ($fh, $nbytes) = @_;
 399     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 400     my $d;
 401     my $got = read $fh, $d, $nbytes;
 402     $got==$nbytes or badproto_badread $fh, "data block";
 403     return $d;
 404 }
 405
 406 sub protocol_receive_file ($$) {
 407     my ($fh, $ourfn) = @_;
 408     printdebug "() $ourfn\n";
 409     open PF, ">", $ourfn or die "$ourfn: $!";
 410     for (;;) {
 411         my ($y,$l) = protocol_expect {
 412             m/^data-block (.*)$/ ? (1,$1) :
 413             m/^data-end$/ ? (0,) :
 414             ();
 415         } $fh;
 416         last unless $y;
 417         my $d = protocol_read_bytes $fh, $l;
 418         print PF $d or die $!;
 419     }
 420     close PF or die $!;
 421 }
 422
 423 #---------- remote protocol support, responder ----------
 424
 425 sub responder_send_command ($) {
 426     my ($command) = @_;
 427     return unless $we_are_responder;
 428     # called even without $we_are_responder
 429     printdebug ">> $command\n";
 430     print PO $command, "\n" or die $!;
 431 }
 432
 433 sub responder_send_file ($$) {
 434     my ($keyword, $ourfn) = @_;
 435     return unless $we_are_responder;
 436     printdebug "]] $keyword $ourfn\n";
 437     responder_send_command "file $keyword";
 438     protocol_send_file \*PO, $ourfn;
 439 }
 440
 441 sub responder_receive_files ($@) {
 442     my ($keyword, @ourfns) = @_;
 443     die unless $we_are_responder;
 444     printdebug "[[ $keyword @ourfns\n";
 445     responder_send_command "want $keyword";
 446     foreach my $fn (@ourfns) {
 447         protocol_receive_file \*PI, $fn;
 448     }
 449     printdebug "[[\$\n";
 450     protocol_expect { m/^files-end$/ } \*PI;
 451 }
 452
 453 #---------- remote protocol support, initiator ----------
 454
 455 sub initiator_expect (&) {
 456     my ($match) = @_;
 457     protocol_expect { &$match } \*RO;
 458 }
 459
 460 #---------- end remote code ----------
 461
 462 sub progress {
 463     if ($we_are_responder) {
 464         my $m = join '', @_;
 465         responder_send_command "progress ".length($m) or die $!;
 466         print PO $m or die $!;
 467     } else {
 468         print @_, "\n";
 469     }
 470 }
 471
 472 our $ua;
 473
 474 sub url_get {
 475     if (!$ua) {
 476         $ua = LWP::UserAgent->new();
 477         $ua->env_proxy;
 478     }
 479     my $what = $_[$#_];
 480     progress "downloading $what...";
 481     my $r = $ua->get(@_) or die $!;
 482     return undef if $r->code == 404;
 483     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 484     return $r->decoded_content(charset => 'none');
 485 }
 486
 487 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 488
 489 sub runcmd {
 490     debugcmd "+",@_;
 491     $!=0; $?=-1;
 492     failedcmd @_ if system @_;
 493 }
 494
 495 sub act_local () { return $dryrun_level <= 1; }
 496 sub act_scary () { return !$dryrun_level; }
 497
 498 sub printdone {
 499     if (!$dryrun_level) {
 500         progress "$us ok: @_";
 501     } else {
 502         progress "would be ok: @_ (but dry run only)";
 503     }
 504 }
 505
 506 sub dryrun_report {
 507     printcmd(\*STDERR,$debugprefix."#",@_);
 508 }
 509
 510 sub runcmd_ordryrun {
 511     if (act_scary()) {
 512         runcmd @_;
 513     } else {
 514         dryrun_report @_;
 515     }
 516 }
 517
 518 sub runcmd_ordryrun_local {
 519     if (act_local()) {
 520         runcmd @_;
 521     } else {
 522         dryrun_report @_;
 523     }
 524 }
 525
 526 sub shell_cmd {
 527     my ($first_shell, @cmd) = @_;
 528     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 529 }
 530
 531 our $helpmsg = <<END;
 532 main usages:
 533   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 534   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 535   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 536   dgit [dgit-opts] sbuild [sbuild-opts]
 537   dgit [dgit-opts] push [dgit-opts] [suite]
 538   dgit [dgit-opts] rpush build-host:build-dir ...
 539 important dgit options:
 540   -k<keyid>           sign tag and package with <keyid> instead of default
 541   --dry-run -n        do not change anything, but go through the motions
 542   --damp-run -L       like --dry-run but make local changes, without signing
 543   --new -N            allow introducing a new package
 544   --debug -D          increase debug level
 545   -c<name>=<value>    set git config option (used directly by dgit too)
 546 END
 547
 548 our $later_warning_msg = <<END;
 549 Perhaps the upload is stuck in incoming.  Using the version from git.
 550 END
 551
 552 sub badusage {
 553     print STDERR "$us: @_\n", $helpmsg or die $!;
 554     exit 8;
 555 }
 556
 557 sub nextarg {
 558     @ARGV or badusage "too few arguments";
 559     return scalar shift @ARGV;
 560 }
 561
 562 sub cmd_help () {
 563     print $helpmsg or die $!;
 564     exit 0;
 565 }
 566
 567 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 568
 569 our %defcfg = ('dgit.default.distro' => 'debian',
 570                'dgit.default.default-suite' => 'unstable',
 571                'dgit.default.old-dsc-distro' => 'debian',
 572                'dgit-suite.*-security.distro' => 'debian-security',
 573                'dgit.default.username' => '',
 574                'dgit.default.archive-query-default-component' => 'main',
 575                'dgit.default.ssh' => 'ssh',
 576                'dgit.default.archive-query' => 'madison:',
 577                'dgit.default.sshpsql-dbname' => 'service=projectb',
 578                'dgit.default.aptget-components' => 'main',
 579                'dgit.default.dgit-tag-format' => 'new,old,maint',
 580                'dgit.dsc-url-proto-ok.http'    => 'true',
 581                'dgit.dsc-url-proto-ok.https'   => 'true',
 582                'dgit.dsc-url-proto-ok.git'     => 'true',
 583                'dgit.default.dsc-url-proto-ok' => 'false',
 584                # old means "repo server accepts pushes with old dgit tags"
 585                # new means "repo server accepts pushes with new dgit tags"
 586                # maint means "repo server accepts split brain pushes"
 587                # hist means "repo server may have old pushes without new tag"
 588                #   ("hist" is implied by "old")
 589                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 590                'dgit-distro.debian.git-check' => 'url',
 591                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 592                'dgit-distro.debian.new-private-pushers' => 't',
 593                'dgit-distro.debian/push.git-url' => '',
 594                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 595                'dgit-distro.debian/push.git-user-force' => 'dgit',
 596                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 597                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 598                'dgit-distro.debian/push.git-create' => 'true',
 599                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 600  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 601 # 'dgit-distro.debian.archive-query-tls-key',
 602 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 603 # ^ this does not work because curl is broken nowadays
 604 # Fixing #790093 properly will involve providing providing the key
 605 # in some pacagke and maybe updating these paths.
 606 #
 607 # 'dgit-distro.debian.archive-query-tls-curl-args',
 608 #   '--ca-path=/etc/ssl/ca-debian',
 609 # ^ this is a workaround but works (only) on DSA-administered machines
 610                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 611                'dgit-distro.debian.git-url-suffix' => '',
 612                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 613                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 614  'dgit-distro.debian-security.archive-query' => 'aptget:',
 615  'dgit-distro.debian-security.mirror' => 'http://security.debian.org/debian-security/',
 616  'dgit-distro.debian-security.aptget-suite-map' => 's#-security$#/updates#',
 617  'dgit-distro.debian-security.aptget-suite-rmap' => 's#$#-security#',
 618  'dgit-distro.debian-security.nominal-distro' => 'debian',
 619  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 620  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 621                'dgit-distro.ubuntu.git-check' => 'false',
 622  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 623                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 624                'dgit-distro.test-dummy.username' => "alice",
 625                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 626                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 627                'dgit-distro.test-dummy.git-url' => "$td/git",
 628                'dgit-distro.test-dummy.git-host' => "git",
 629                'dgit-distro.test-dummy.git-path' => "$td/git",
 630                'dgit-distro.test-dummy.archive-query' => "dummycatapi:",
 631                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 632                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 633                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 634                );
 635
 636 our %gitcfgs;
 637 our @gitcfgsources = qw(cmdline local global system);
 638
 639 sub git_slurp_config () {
 640     local ($debuglevel) = $debuglevel-2;
 641     local $/="\0";
 642
 643     # This algoritm is a bit subtle, but this is needed so that for
 644     # options which we want to be single-valued, we allow the
 645     # different config sources to override properly.  See #835858.
 646     foreach my $src (@gitcfgsources) {
 647         next if $src eq 'cmdline';
 648         # we do this ourselves since git doesn't handle it
 649
 650         my @cmd = (@git, qw(config -z --get-regexp), "--$src", qw(.*));
 651         debugcmd "|",@cmd;
 652
 653         open GITS, "-|", @cmd or die $!;
 654         while (<GITS>) {
 655             chomp or die;
 656             printdebug "=> ", (messagequote $_), "\n";
 657             m/\n/ or die "$_ ?";
 658             push @{ $gitcfgs{$src}{$`} }, $'; #';
 659         }
 660         $!=0; $?=0;
 661         close GITS
 662             or ($!==0 && $?==256)
 663             or failedcmd @cmd;
 664     }
 665 }
 666
 667 sub git_get_config ($) {
 668     my ($c) = @_;
 669     foreach my $src (@gitcfgsources) {
 670         my $l = $gitcfgs{$src}{$c};
 671         croak "$l $c" if $l && !ref $l;
 672         printdebug"C $c ".(defined $l ?
 673                            join " ", map { messagequote "'$_'" } @$l :
 674                            "undef")."\n"
 675             if $debuglevel >= 4;
 676         $l or next;
 677         @$l==1 or badcfg "multiple values for $c".
 678             " (in $src git config)" if @$l > 1;
 679         return $l->[0];
 680     }
 681     return undef;
 682 }
 683
 684 sub cfg {
 685     foreach my $c (@_) {
 686         return undef if $c =~ /RETURN-UNDEF/;
 687         printdebug "C? $c\n" if $debuglevel >= 5;
 688         my $v = git_get_config($c);
 689         return $v if defined $v;
 690         my $dv = $defcfg{$c};
 691         if (defined $dv) {
 692             printdebug "CD $c $dv\n" if $debuglevel >= 4;
 693             return $dv;
 694         }
 695     }
 696     badcfg "need value for one of: @_\n".
 697         "$us: distro or suite appears not to be (properly) supported";
 698 }
 699
 700 sub access_basedistro__noalias () {
 701     if (defined $idistro) {
 702         return $idistro;
 703     } else {
 704         my $def = cfg("dgit-suite.$isuite.distro", 'RETURN-UNDEF');
 705         return $def if defined $def;
 706         foreach my $src (@gitcfgsources, 'internal') {
 707             my $kl = $src eq 'internal' ? \%defcfg : $gitcfgs{$src};
 708             next unless $kl;
 709             foreach my $k (keys %$kl) {
 710                 next unless $k =~ m#^dgit-suite\.(.*)\.distro$#;
 711                 my $dpat = $1;
 712                 next unless match_glob $dpat, $isuite;
 713                 return $kl->{$k};
 714             }
 715         }
 716         return cfg("dgit.default.distro");
 717     }
 718 }
 719
 720 sub access_basedistro () {
 721     my $noalias = access_basedistro__noalias();
 722     my $canon = cfg("dgit-distro.$noalias.alias-canon",'RETURN-UNDEF');
 723     return $canon // $noalias;
 724 }
 725
 726 sub access_nomdistro () {
 727     my $base = access_basedistro();
 728     my $r = cfg("dgit-distro.$base.nominal-distro",'RETURN-UNDEF') // $base;
 729     $r =~ m/^$distro_re$/ or badcfg
 730  "bad syntax for (nominal) distro \`$r' (does not match /^$distro_re$/)";
 731     return $r;
 732 }
 733
 734 sub access_quirk () {
 735     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 736     my $basedistro = access_basedistro();
 737     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 738                               'RETURN-UNDEF');
 739     if (defined $backports_quirk) {
 740         my $re = $backports_quirk;
 741         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 742         $re =~ s/\*/.*/g;
 743         $re =~ s/\%/([-0-9a-z_]+)/
 744             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 745         if ($isuite =~ m/^$re$/) {
 746             return ('backports',"$basedistro-backports",$1);
 747         }
 748     }
 749     return ('none',undef);
 750 }
 751
 752 our $access_forpush;
 753
 754 sub parse_cfg_bool ($$$) {
 755     my ($what,$def,$v) = @_;
 756     $v //= $def;
 757     return
 758         $v =~ m/^[ty1]/ ? 1 :
 759         $v =~ m/^[fn0]/ ? 0 :
 760         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 761 }
 762
 763 sub access_forpush_config () {
 764     my $d = access_basedistro();
 765
 766     return 1 if
 767         $new_package &&
 768         parse_cfg_bool('new-private-pushers', 0,
 769                        cfg("dgit-distro.$d.new-private-pushers",
 770                            'RETURN-UNDEF'));
 771
 772     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 773     $v //= 'a';
 774     return
 775         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 776         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 777         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 778         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 779 }
 780
 781 sub access_forpush () {
 782     $access_forpush //= access_forpush_config();
 783     return $access_forpush;
 784 }
 785
 786 sub pushing () {
 787     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 788     badcfg "pushing but distro is configured readonly"
 789         if access_forpush_config() eq '0';
 790     $access_forpush = 1;
 791     $supplementary_message = <<'END' unless $we_are_responder;
 792 Push failed, before we got started.
 793 You can retry the push, after fixing the problem, if you like.
 794 END
 795     parseopts_late_defaults();
 796 }
 797
 798 sub notpushing () {
 799     parseopts_late_defaults();
 800 }
 801
 802 sub supplementary_message ($) {
 803     my ($msg) = @_;
 804     if (!$we_are_responder) {
 805         $supplementary_message = $msg;
 806         return;
 807     } elsif ($protovsn >= 3) {
 808         responder_send_command "supplementary-message ".length($msg)
 809             or die $!;
 810         print PO $msg or die $!;
 811     }
 812 }
 813
 814 sub access_distros () {
 815     # Returns list of distros to try, in order
 816     #
 817     # We want to try:
 818     #    0. `instead of' distro name(s) we have been pointed to
 819     #    1. the access_quirk distro, if any
 820     #    2a. the user's specified distro, or failing that  } basedistro
 821     #    2b. the distro calculated from the suite          }
 822     my @l = access_basedistro();
 823
 824     my (undef,$quirkdistro) = access_quirk();
 825     unshift @l, $quirkdistro;
 826     unshift @l, $instead_distro;
 827     @l = grep { defined } @l;
 828
 829     push @l, access_nomdistro();
 830
 831     if (access_forpush()) {
 832         @l = map { ("$_/push", $_) } @l;
 833     }
 834     @l;
 835 }
 836
 837 sub access_cfg_cfgs (@) {
 838     my (@keys) = @_;
 839     my @cfgs;
 840     # The nesting of these loops determines the search order.  We put
 841     # the key loop on the outside so that we search all the distros
 842     # for each key, before going on to the next key.  That means that
 843     # if access_cfg is called with a more specific, and then a less
 844     # specific, key, an earlier distro can override the less specific
 845     # without necessarily overriding any more specific keys.  (If the
 846     # distro wants to override the more specific keys it can simply do
 847     # so; whereas if we did the loop the other way around, it would be
 848     # impossible to for an earlier distro to override a less specific
 849     # key but not the more specific ones without restating the unknown
 850     # values of the more specific keys.
 851     my @realkeys;
 852     my @rundef;
 853     # We have to deal with RETURN-UNDEF specially, so that we don't
 854     # terminate the search prematurely.
 855     foreach (@keys) {
 856         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 857         push @realkeys, $_
 858     }
 859     foreach my $d (access_distros()) {
 860         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 861     }
 862     push @cfgs, map { "dgit.default.$_" } @realkeys;
 863     push @cfgs, @rundef;
 864     return @cfgs;
 865 }
 866
 867 sub access_cfg (@) {
 868     my (@keys) = @_;
 869     my (@cfgs) = access_cfg_cfgs(@keys);
 870     my $value = cfg(@cfgs);
 871     return $value;
 872 }
 873
 874 sub access_cfg_bool ($$) {
 875     my ($def, @keys) = @_;
 876     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 877 }
 878
 879 sub string_to_ssh ($) {
 880     my ($spec) = @_;
 881     if ($spec =~ m/\s/) {
 882         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 883     } else {
 884         return ($spec);
 885     }
 886 }
 887
 888 sub access_cfg_ssh () {
 889     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 890     if (!defined $gitssh) {
 891         return @ssh;
 892     } else {
 893         return string_to_ssh $gitssh;
 894     }
 895 }
 896
 897 sub access_runeinfo ($) {
 898     my ($info) = @_;
 899     return ": dgit ".access_basedistro()." $info ;";
 900 }
 901
 902 sub access_someuserhost ($) {
 903     my ($some) = @_;
 904     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 905     defined($user) && length($user) or
 906         $user = access_cfg("$some-user",'username');
 907     my $host = access_cfg("$some-host");
 908     return length($user) ? "$user\@$host" : $host;
 909 }
 910
 911 sub access_gituserhost () {
 912     return access_someuserhost('git');
 913 }
 914
 915 sub access_giturl (;$) {
 916     my ($optional) = @_;
 917     my $url = access_cfg('git-url','RETURN-UNDEF');
 918     my $suffix;
 919     if (!length $url) {
 920         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 921         return undef unless defined $proto;
 922         $url =
 923             $proto.
 924             access_gituserhost().
 925             access_cfg('git-path');
 926     } else {
 927         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 928     }
 929     $suffix //= '.git';
 930     return "$url/$package$suffix";
 931 }
 932
 933 sub parsecontrolfh ($$;$) {
 934     my ($fh, $desc, $allowsigned) = @_;
 935     our $dpkgcontrolhash_noissigned;
 936     my $c;
 937     for (;;) {
 938         my %opts = ('name' => $desc);
 939         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 940         $c = Dpkg::Control::Hash->new(%opts);
 941         $c->parse($fh,$desc) or die "parsing of $desc failed";
 942         last if $allowsigned;
 943         last if $dpkgcontrolhash_noissigned;
 944         my $issigned= $c->get_option('is_pgp_signed');
 945         if (!defined $issigned) {
 946             $dpkgcontrolhash_noissigned= 1;
 947             seek $fh, 0,0 or die "seek $desc: $!";
 948         } elsif ($issigned) {
 949             fail "control file $desc is (already) PGP-signed. ".
 950                 " Note that dgit push needs to modify the .dsc and then".
 951                 " do the signature itself";
 952         } else {
 953             last;
 954         }
 955     }
 956     return $c;
 957 }
 958
 959 sub parsecontrol {
 960     my ($file, $desc, $allowsigned) = @_;
 961     my $fh = new IO::Handle;
 962     open $fh, '<', $file or die "$file: $!";
 963     my $c = parsecontrolfh($fh,$desc,$allowsigned);
 964     $fh->error and die $!;
 965     close $fh;
 966     return $c;
 967 }
 968
 969 sub getfield ($$) {
 970     my ($dctrl,$field) = @_;
 971     my $v = $dctrl->{$field};
 972     return $v if defined $v;
 973     fail "missing field $field in ".$dctrl->get_option('name');
 974 }
 975
 976 sub parsechangelog {
 977     my $c = Dpkg::Control::Hash->new(name => 'parsed changelog');
 978     my $p = new IO::Handle;
 979     my @cmd = (qw(dpkg-parsechangelog), @_);
 980     open $p, '-|', @cmd or die $!;
 981     $c->parse($p);
 982     $?=0; $!=0; close $p or failedcmd @cmd;
 983     return $c;
 984 }
 985
 986 sub commit_getclogp ($) {
 987     # Returns the parsed changelog hashref for a particular commit
 988     my ($objid) = @_;
 989     our %commit_getclogp_memo;
 990     my $memo = $commit_getclogp_memo{$objid};
 991     return $memo if $memo;
 992     mkpath '.git/dgit';
 993     my $mclog = ".git/dgit/clog-$objid";
 994     runcmd shell_cmd "exec >$mclog", @git, qw(cat-file blob),
 995         "$objid:debian/changelog";
 996     $commit_getclogp_memo{$objid} = parsechangelog("-l$mclog");
 997 }
 998
 999 sub must_getcwd () {
1000     my $d = getcwd();
1001     defined $d or fail "getcwd failed: $!";
1002     return $d;
1003 }
1004
1005 sub parse_dscdata () {
1006     my $dscfh = new IO::File \$dscdata, '<' or die $!;
1007     printdebug Dumper($dscdata) if $debuglevel>1;
1008     $dsc = parsecontrolfh($dscfh,$dscurl,1);
1009     printdebug Dumper($dsc) if $debuglevel>1;
1010 }
1011
1012 our %rmad;
1013
1014 sub archive_query ($;@) {
1015     my ($method) = shift @_;
1016     fail "this operation does not support multiple comma-separated suites"
1017         if $isuite =~ m/,/;
1018     my $query = access_cfg('archive-query','RETURN-UNDEF');
1019     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
1020     my $proto = $1;
1021     my $data = $'; #';
1022     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data,@_); }
1023 }
1024
1025 sub archive_query_prepend_mirror {
1026     my $m = access_cfg('mirror');
1027     return map { [ $_->[0], $m.$_->[1], @$_[2..$#$_] ] } @_;
1028 }
1029
1030 sub pool_dsc_subpath ($$) {
1031     my ($vsn,$component) = @_; # $package is implict arg
1032     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
1033     return "/pool/$component/$prefix/$package/".dscfn($vsn);
1034 }
1035
1036 sub cfg_apply_map ($$$) {
1037     my ($varref, $what, $mapspec) = @_;
1038     return unless $mapspec;
1039
1040     printdebug "config $what EVAL{ $mapspec; }\n";
1041     $_ = $$varref;
1042     eval "package Dgit::Config; $mapspec;";
1043     die $@ if $@;
1044     $$varref = $_;
1045 }
1046
1047 #---------- `ftpmasterapi' archive query method (nascent) ----------
1048
1049 sub archive_api_query_cmd ($) {
1050     my ($subpath) = @_;
1051     my @cmd = (@curl, qw(-sS));
1052     my $url = access_cfg('archive-query-url');
1053     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
1054         my $host = $1;
1055         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
1056         foreach my $key (split /\:/, $keys) {
1057             $key =~ s/\%HOST\%/$host/g;
1058             if (!stat $key) {
1059                 fail "for $url: stat $key: $!" unless $!==ENOENT;
1060                 next;
1061             }
1062             fail "config requested specific TLS key but do not know".
1063                 " how to get curl to use exactly that EE key ($key)";
1064 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
1065 #           # Sadly the above line does not work because of changes
1066 #           # to gnutls.   The real fix for #790093 may involve
1067 #           # new curl options.
1068             last;
1069         }
1070         # Fixing #790093 properly will involve providing a value
1071         # for this on clients.
1072         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
1073         push @cmd, split / /, $kargs if defined $kargs;
1074     }
1075     push @cmd, $url.$subpath;
1076     return @cmd;
1077 }
1078
1079 sub api_query ($$;$) {
1080     use JSON;
1081     my ($data, $subpath, $ok404) = @_;
1082     badcfg "ftpmasterapi archive query method takes no data part"
1083         if length $data;
1084     my @cmd = archive_api_query_cmd($subpath);
1085     my $url = $cmd[$#cmd];
1086     push @cmd, qw(-w %{http_code});
1087     my $json = cmdoutput @cmd;
1088     unless ($json =~ s/\d+\d+\d$//) {
1089         failedcmd_report_cmd undef, @cmd;
1090         fail "curl failed to print 3-digit HTTP code";
1091     }
1092     my $code = $&;
1093     return undef if $code eq '404' && $ok404;
1094     fail "fetch of $url gave HTTP code $code"
1095         unless $url =~ m#^file://# or $code =~ m/^2/;
1096     return decode_json($json);
1097 }
1098
1099 sub canonicalise_suite_ftpmasterapi {
1100     my ($proto,$data) = @_;
1101     my $suites = api_query($data, 'suites');
1102     my @matched;
1103     foreach my $entry (@$suites) {
1104         next unless grep {
1105             my $v = $entry->{$_};
1106             defined $v && $v eq $isuite;
1107         } qw(codename name);
1108         push @matched, $entry;
1109     }
1110     fail "unknown suite $isuite" unless @matched;
1111     my $cn;
1112     eval {
1113         @matched==1 or die "multiple matches for suite $isuite\n";
1114         $cn = "$matched[0]{codename}";
1115         defined $cn or die "suite $isuite info has no codename\n";
1116         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
1117     };
1118     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
1119         if length $@;
1120     return $cn;
1121 }
1122
1123 sub archive_query_ftpmasterapi {
1124     my ($proto,$data) = @_;
1125     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
1126     my @rows;
1127     my $digester = Digest::SHA->new(256);
1128     foreach my $entry (@$info) {
1129         eval {
1130             my $vsn = "$entry->{version}";
1131             my ($ok,$msg) = version_check $vsn;
1132             die "bad version: $msg\n" unless $ok;
1133             my $component = "$entry->{component}";
1134             $component =~ m/^$component_re$/ or die "bad component";
1135             my $filename = "$entry->{filename}";
1136             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
1137                 or die "bad filename";
1138             my $sha256sum = "$entry->{sha256sum}";
1139             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
1140             push @rows, [ $vsn, "/pool/$component/$filename",
1141                           $digester, $sha256sum ];
1142         };
1143         die "bad ftpmaster api response: $@\n".Dumper($entry)
1144             if length $@;
1145     }
1146     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1147     return archive_query_prepend_mirror @rows;
1148 }
1149
1150 sub file_in_archive_ftpmasterapi {
1151     my ($proto,$data,$filename) = @_;
1152     my $pat = $filename;
1153     $pat =~ s/_/\\_/g;
1154     $pat = "%/$pat";
1155     $pat =~ s#[^-+_.0-9a-z/]# sprintf '%%%02x', ord $& #ge;
1156     my $info = api_query($data, "file_in_archive/$pat", 1);
1157 }
1158
1159 #---------- `aptget' archive query method ----------
1160
1161 our $aptget_base;
1162 our $aptget_releasefile;
1163 our $aptget_configpath;
1164
1165 sub aptget_aptget   () { return @aptget,   qw(-c), $aptget_configpath; }
1166 sub aptget_aptcache () { return @aptcache, qw(-c), $aptget_configpath; }
1167
1168 sub aptget_cache_clean {
1169     runcmd_ordryrun_local qw(sh -ec),
1170         'cd "$1"; find -atime +30 -type f -print0 | xargs -0r rm --',
1171         'x', $aptget_base;
1172 }
1173
1174 sub aptget_lock_acquire () {
1175     my $lockfile = "$aptget_base/lock";
1176     open APTGET_LOCK, '>', $lockfile or die "open $lockfile: $!";
1177     flock APTGET_LOCK, LOCK_EX or die "lock $lockfile: $!";
1178 }
1179
1180 sub aptget_prep ($) {
1181     my ($data) = @_;
1182     return if defined $aptget_base;
1183
1184     badcfg "aptget archive query method takes no data part"
1185         if length $data;
1186
1187     my $cache = $ENV{XDG_CACHE_DIR} // "$ENV{HOME}/.cache";
1188
1189     ensuredir $cache;
1190     ensuredir "$cache/dgit";
1191     my $cachekey =
1192         access_cfg('aptget-cachekey','RETURN-UNDEF')
1193         // access_nomdistro();
1194
1195     $aptget_base = "$cache/dgit/aptget";
1196     ensuredir $aptget_base;
1197
1198     my $quoted_base = $aptget_base;
1199     die "$quoted_base contains bad chars, cannot continue"
1200         if $quoted_base =~ m/["\\]/; # apt.conf(5) says no escaping :-/
1201
1202     ensuredir $aptget_base;
1203
1204     aptget_lock_acquire();
1205
1206     aptget_cache_clean();
1207
1208     $aptget_configpath = "$aptget_base/apt.conf#$cachekey";
1209     my $sourceslist = "source.list#$cachekey";
1210
1211     my $aptsuites = $isuite;
1212     cfg_apply_map(\$aptsuites, 'suite map',
1213                   access_cfg('aptget-suite-map', 'RETURN-UNDEF'));
1214
1215     open SRCS, ">", "$aptget_base/$sourceslist" or die $!;
1216     printf SRCS "deb-src %s %s %s\n",
1217         access_cfg('mirror'),
1218         $aptsuites,
1219         access_cfg('aptget-components')
1220         or die $!;
1221
1222     ensuredir "$aptget_base/cache";
1223     ensuredir "$aptget_base/lists";
1224
1225     open CONF, ">", $aptget_configpath or die $!;
1226     print CONF <<END;
1227 Debug::NoLocking "true";
1228 APT::Get::List-Cleanup "false";
1229 #clear APT::Update::Post-Invoke-Success;
1230 Dir::Etc::SourceList "$quoted_base/$sourceslist";
1231 Dir::State::Lists "$quoted_base/lists";
1232 Dir::Etc::preferences "$quoted_base/preferences";
1233 Dir::Cache::srcpkgcache "$quoted_base/cache/srcs#$cachekey";
1234 Dir::Cache::pkgcache "$quoted_base/cache/pkgs#$cachekey";
1235 END
1236
1237     foreach my $key (qw(
1238                         Dir::Cache
1239                         Dir::State
1240                         Dir::Cache::Archives
1241                         Dir::Etc::SourceParts
1242                         Dir::Etc::preferencesparts
1243                       )) {
1244         ensuredir "$aptget_base/$key";
1245         print CONF "$key \"$quoted_base/$key\";\n" or die $!;
1246     };
1247
1248     my $oldatime = (time // die $!) - 1;
1249     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1250         next unless stat_exists $oldlist;
1251         my ($mtime) = (stat _)[9];
1252         utime $oldatime, $mtime, $oldlist or die "$oldlist $!";
1253     }
1254
1255     runcmd_ordryrun_local aptget_aptget(), qw(update);
1256
1257     my @releasefiles;
1258     foreach my $oldlist (<$aptget_base/lists/*Release>) {
1259         next unless stat_exists $oldlist;
1260         my ($atime) = (stat _)[8];
1261         next if $atime == $oldatime;
1262         push @releasefiles, $oldlist;
1263     }
1264     my @inreleasefiles = grep { m#/InRelease$# } @releasefiles;
1265     @releasefiles = @inreleasefiles if @inreleasefiles;
1266     die "apt updated wrong number of Release files (@releasefiles), erk"
1267         unless @releasefiles == 1;
1268
1269     ($aptget_releasefile) = @releasefiles;
1270 }
1271
1272 sub canonicalise_suite_aptget {
1273     my ($proto,$data) = @_;
1274     aptget_prep($data);
1275
1276     my $release = parsecontrol $aptget_releasefile, "Release file", 1;
1277
1278     foreach my $name (qw(Codename Suite)) {
1279         my $val = $release->{$name};
1280         if (defined $val) {
1281             printdebug "release file $name: $val\n";
1282             $val =~ m/^$suite_re$/o or fail
1283  "Release file ($aptget_releasefile) specifies intolerable $name";
1284             cfg_apply_map(\$val, 'suite rmap',
1285                           access_cfg('aptget-suite-rmap', 'RETURN-UNDEF'));
1286             return $val
1287         }
1288     }
1289     return $isuite;
1290 }
1291
1292 sub archive_query_aptget {
1293     my ($proto,$data) = @_;
1294     aptget_prep($data);
1295
1296     ensuredir "$aptget_base/source";
1297     foreach my $old (<$aptget_base/source/*.dsc>) {
1298         unlink $old or die "$old: $!";
1299     }
1300
1301     my $showsrc = cmdoutput aptget_aptcache(), qw(showsrc), $package;
1302     return () unless $showsrc =~ m/^package:\s*\Q$package\E\s*$/mi;
1303     # avoids apt-get source failing with ambiguous error code
1304
1305     runcmd_ordryrun_local
1306         shell_cmd 'cd "$1"/source; shift', $aptget_base,
1307         aptget_aptget(), qw(--download-only --only-source source), $package;
1308
1309     my @dscs = <$aptget_base/source/*.dsc>;
1310     fail "apt-get source did not produce a .dsc" unless @dscs;
1311     fail "apt-get source produced several .dscs (@dscs)" unless @dscs==1;
1312
1313     my $pre_dsc = parsecontrol $dscs[0], $dscs[0], 1;
1314
1315     use URI::Escape;
1316     my $uri = "file://". uri_escape $dscs[0];
1317     $uri =~ s{\%2f}{/}gi;
1318     return [ (getfield $pre_dsc, 'Version'), $uri ];
1319 }
1320
1321 #---------- `dummyapicat' archive query method ----------
1322
1323 sub archive_query_dummycatapi { archive_query_ftpmasterapi @_; }
1324 sub canonicalise_suite_dummycatapi { canonicalise_suite_ftpmasterapi @_; }
1325
1326 sub file_in_archive_dummycatapi ($$$) {
1327     my ($proto,$data,$filename) = @_;
1328     my $mirror = access_cfg('mirror');
1329     $mirror =~ s#^file://#/# or die "$mirror ?";
1330     my @out;
1331     my @cmd = (qw(sh -ec), '
1332             cd "$1"
1333             find -name "$2" -print0 |
1334             xargs -0r sha256sum
1335         ', qw(x), $mirror, $filename);
1336     debugcmd "-|", @cmd;
1337     open FIA, "-|", @cmd or die $!;
1338     while (<FIA>) {
1339         chomp or die;
1340         printdebug "| $_\n";
1341         m/^(\w+)  (\S+)$/ or die "$_ ?";
1342         push @out, { sha256sum => $1, filename => $2 };
1343     }
1344     close FIA or die failedcmd @cmd;
1345     return \@out;
1346 }
1347
1348 #---------- `madison' archive query method ----------
1349
1350 sub archive_query_madison {
1351     return archive_query_prepend_mirror
1352         map { [ @$_[0..1] ] } madison_get_parse(@_);
1353 }
1354
1355 sub madison_get_parse {
1356     my ($proto,$data) = @_;
1357     die unless $proto eq 'madison';
1358     if (!length $data) {
1359         $data= access_cfg('madison-distro','RETURN-UNDEF');
1360         $data //= access_basedistro();
1361     }
1362     $rmad{$proto,$data,$package} ||= cmdoutput
1363         qw(rmadison -asource),"-s$isuite","-u$data",$package;
1364     my $rmad = $rmad{$proto,$data,$package};
1365
1366     my @out;
1367     foreach my $l (split /\n/, $rmad) {
1368         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
1369                   \s*( [^ \t|]+ )\s* \|
1370                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
1371                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
1372         $1 eq $package or die "$rmad $package ?";
1373         my $vsn = $2;
1374         my $newsuite = $3;
1375         my $component;
1376         if (defined $4) {
1377             $component = $4;
1378         } else {
1379             $component = access_cfg('archive-query-default-component');
1380         }
1381         $5 eq 'source' or die "$rmad ?";
1382         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
1383     }
1384     return sort { -version_compare($a->[0],$b->[0]); } @out;
1385 }
1386
1387 sub canonicalise_suite_madison {
1388     # madison canonicalises for us
1389     my @r = madison_get_parse(@_);
1390     @r or fail
1391         "unable to canonicalise suite using package $package".
1392         " which does not appear to exist in suite $isuite;".
1393         " --existing-package may help";
1394     return $r[0][2];
1395 }
1396
1397 sub file_in_archive_madison { return undef; }
1398
1399 #---------- `sshpsql' archive query method ----------
1400
1401 sub sshpsql ($$$) {
1402     my ($data,$runeinfo,$sql) = @_;
1403     if (!length $data) {
1404         $data= access_someuserhost('sshpsql').':'.
1405             access_cfg('sshpsql-dbname');
1406     }
1407     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
1408     my ($userhost,$dbname) = ($`,$'); #';
1409     my @rows;
1410     my @cmd = (access_cfg_ssh, $userhost,
1411                access_runeinfo("ssh-psql $runeinfo").
1412                " export LC_MESSAGES=C; export LC_CTYPE=C;".
1413                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
1414     debugcmd "|",@cmd;
1415     open P, "-|", @cmd or die $!;
1416     while (<P>) {
1417         chomp or die;
1418         printdebug(">|$_|\n");
1419         push @rows, $_;
1420     }
1421     $!=0; $?=0; close P or failedcmd @cmd;
1422     @rows or die;
1423     my $nrows = pop @rows;
1424     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1425     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1426     @rows = map { [ split /\|/, $_ ] } @rows;
1427     my $ncols = scalar @{ shift @rows };
1428     die if grep { scalar @$_ != $ncols } @rows;
1429     return @rows;
1430 }
1431
1432 sub sql_injection_check {
1433     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1434 }
1435
1436 sub archive_query_sshpsql ($$) {
1437     my ($proto,$data) = @_;
1438     sql_injection_check $isuite, $package;
1439     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1440         SELECT source.version, component.name, files.filename, files.sha256sum
1441           FROM source
1442           JOIN src_associations ON source.id = src_associations.source
1443           JOIN suite ON suite.id = src_associations.suite
1444           JOIN dsc_files ON dsc_files.source = source.id
1445           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1446           JOIN component ON component.id = files_archive_map.component_id
1447           JOIN files ON files.id = dsc_files.file
1448          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1449            AND source.source='$package'
1450            AND files.filename LIKE '%.dsc';
1451 END
1452     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1453     my $digester = Digest::SHA->new(256);
1454     @rows = map {
1455         my ($vsn,$component,$filename,$sha256sum) = @$_;
1456         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1457     } @rows;
1458     return archive_query_prepend_mirror @rows;
1459 }
1460
1461 sub canonicalise_suite_sshpsql ($$) {
1462     my ($proto,$data) = @_;
1463     sql_injection_check $isuite;
1464     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1465         SELECT suite.codename
1466           FROM suite where suite_name='$isuite' or codename='$isuite';
1467 END
1468     @rows = map { $_->[0] } @rows;
1469     fail "unknown suite $isuite" unless @rows;
1470     die "ambiguous $isuite: @rows ?" if @rows>1;
1471     return $rows[0];
1472 }
1473
1474 sub file_in_archive_sshpsql ($$$) { return undef; }
1475
1476 #---------- `dummycat' archive query method ----------
1477
1478 sub canonicalise_suite_dummycat ($$) {
1479     my ($proto,$data) = @_;
1480     my $dpath = "$data/suite.$isuite";
1481     if (!open C, "<", $dpath) {
1482         $!==ENOENT or die "$dpath: $!";
1483         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1484         return $isuite;
1485     }
1486     $!=0; $_ = <C>;
1487     chomp or die "$dpath: $!";
1488     close C;
1489     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1490     return $_;
1491 }
1492
1493 sub archive_query_dummycat ($$) {
1494     my ($proto,$data) = @_;
1495     canonicalise_suite();
1496     my $dpath = "$data/package.$csuite.$package";
1497     if (!open C, "<", $dpath) {
1498         $!==ENOENT or die "$dpath: $!";
1499         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1500         return ();
1501     }
1502     my @rows;
1503     while (<C>) {
1504         next if m/^\#/;
1505         next unless m/\S/;
1506         die unless chomp;
1507         printdebug "dummycat query $csuite $package $dpath | $_\n";
1508         my @row = split /\s+/, $_;
1509         @row==2 or die "$dpath: $_ ?";
1510         push @rows, \@row;
1511     }
1512     C->error and die "$dpath: $!";
1513     close C;
1514     return archive_query_prepend_mirror
1515         sort { -version_compare($a->[0],$b->[0]); } @rows;
1516 }
1517
1518 sub file_in_archive_dummycat () { return undef; }
1519
1520 #---------- tag format handling ----------
1521
1522 sub access_cfg_tagformats () {
1523     split /\,/, access_cfg('dgit-tag-format');
1524 }
1525
1526 sub access_cfg_tagformats_can_splitbrain () {
1527     my %y = map { $_ => 1 } access_cfg_tagformats;
1528     foreach my $needtf (qw(new maint)) {
1529         next if $y{$needtf};
1530         return 0;
1531     }
1532     return 1;
1533 }
1534
1535 sub need_tagformat ($$) {
1536     my ($fmt, $why) = @_;
1537     fail "need to use tag format $fmt ($why) but also need".
1538         " to use tag format $tagformat_want->[0] ($tagformat_want->[1])".
1539         " - no way to proceed"
1540         if $tagformat_want && $tagformat_want->[0] ne $fmt;
1541     $tagformat_want = [$fmt, $why, $tagformat_want->[2] // 0];
1542 }
1543
1544 sub select_tagformat () {
1545     # sets $tagformatfn
1546     return if $tagformatfn && !$tagformat_want;
1547     die 'bug' if $tagformatfn && $tagformat_want;
1548     # ... $tagformat_want assigned after previous select_tagformat
1549
1550     my (@supported) = grep { $_ =~ m/^(?:old|new)$/ } access_cfg_tagformats();
1551     printdebug "select_tagformat supported @supported\n";
1552
1553     $tagformat_want //= [ $supported[0], "distro access configuration", 0 ];
1554     printdebug "select_tagformat specified @$tagformat_want\n";
1555
1556     my ($fmt,$why,$override) = @$tagformat_want;
1557
1558     fail "target distro supports tag formats @supported".
1559         " but have to use $fmt ($why)"
1560         unless $override
1561             or grep { $_ eq $fmt } @supported;
1562
1563     $tagformat_want = undef;
1564     $tagformat = $fmt;
1565     $tagformatfn = ${*::}{"debiantag_$fmt"};
1566
1567     fail "trying to use unknown tag format \`$fmt' ($why) !"
1568         unless $tagformatfn;
1569 }
1570
1571 #---------- archive query entrypoints and rest of program ----------
1572
1573 sub canonicalise_suite () {
1574     return if defined $csuite;
1575     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1576     $csuite = archive_query('canonicalise_suite');
1577     if ($isuite ne $csuite) {
1578         progress "canonical suite name for $isuite is $csuite";
1579     } else {
1580         progress "canonical suite name is $csuite";
1581     }
1582 }
1583
1584 sub get_archive_dsc () {
1585     canonicalise_suite();
1586     my @vsns = archive_query('archive_query');
1587     foreach my $vinfo (@vsns) {
1588         my ($vsn,$vsn_dscurl,$digester,$digest) = @$vinfo;
1589         $dscurl = $vsn_dscurl;
1590         $dscdata = url_get($dscurl);
1591         if (!$dscdata) {
1592             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1593             next;
1594         }
1595         if ($digester) {
1596             $digester->reset();
1597             $digester->add($dscdata);
1598             my $got = $digester->hexdigest();
1599             $got eq $digest or
1600                 fail "$dscurl has hash $got but".
1601                     " archive told us to expect $digest";
1602         }
1603         parse_dscdata();
1604         my $fmt = getfield $dsc, 'Format';
1605         $format_ok{$fmt} or forceable_fail [qw(unsupported-source-format)],
1606             "unsupported source format $fmt, sorry";
1607
1608         $dsc_checked = !!$digester;
1609         printdebug "get_archive_dsc: Version ".(getfield $dsc, 'Version')."\n";
1610         return;
1611     }
1612     $dsc = undef;
1613     printdebug "get_archive_dsc: nothing in archive, returning undef\n";
1614 }
1615
1616 sub check_for_git ();
1617 sub check_for_git () {
1618     # returns 0 or 1
1619     my $how = access_cfg('git-check');
1620     if ($how eq 'ssh-cmd') {
1621         my @cmd =
1622             (access_cfg_ssh, access_gituserhost(),
1623              access_runeinfo("git-check $package").
1624              " set -e; cd ".access_cfg('git-path').";".
1625              " if test -d $package.git; then echo 1; else echo 0; fi");
1626         my $r= cmdoutput @cmd;
1627         if (defined $r and $r =~ m/^divert (\w+)$/) {
1628             my $divert=$1;
1629             my ($usedistro,) = access_distros();
1630             # NB that if we are pushing, $usedistro will be $distro/push
1631             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1632             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1633             progress "diverting to $divert (using config for $instead_distro)";
1634             return check_for_git();
1635         }
1636         failedcmd @cmd unless defined $r and $r =~ m/^[01]$/;
1637         return $r+0;
1638     } elsif ($how eq 'url') {
1639         my $prefix = access_cfg('git-check-url','git-url');
1640         my $suffix = access_cfg('git-check-suffix','git-suffix',
1641                                 'RETURN-UNDEF') // '.git';
1642         my $url = "$prefix/$package$suffix";
1643         my @cmd = (@curl, qw(-sS -I), $url);
1644         my $result = cmdoutput @cmd;
1645         $result =~ s/^\S+ 200 .*\n\r?\n//;
1646         # curl -sS -I with https_proxy prints
1647         # HTTP/1.0 200 Connection established
1648         $result =~ m/^\S+ (404|200) /s or
1649             fail "unexpected results from git check query - ".
1650                 Dumper($prefix, $result);
1651         my $code = $1;
1652         if ($code eq '404') {
1653             return 0;
1654         } elsif ($code eq '200') {
1655             return 1;
1656         } else {
1657             die;
1658         }
1659     } elsif ($how eq 'true') {
1660         return 1;
1661     } elsif ($how eq 'false') {
1662         return 0;
1663     } else {
1664         badcfg "unknown git-check \`$how'";
1665     }
1666 }
1667
1668 sub create_remote_git_repo () {
1669     my $how = access_cfg('git-create');
1670     if ($how eq 'ssh-cmd') {
1671         runcmd_ordryrun
1672             (access_cfg_ssh, access_gituserhost(),
1673              access_runeinfo("git-create $package").
1674              "set -e; cd ".access_cfg('git-path').";".
1675              " cp -a _template $package.git");
1676     } elsif ($how eq 'true') {
1677         # nothing to do
1678     } else {
1679         badcfg "unknown git-create \`$how'";
1680     }
1681 }
1682
1683 our ($dsc_hash,$lastpush_mergeinput);
1684 our ($dsc_distro, $dsc_hint_tag, $dsc_hint_url);
1685
1686 our $ud = '.git/dgit/unpack';
1687
1688 sub prep_ud (;$) {
1689     my ($d) = @_;
1690     $d //= $ud;
1691     rmtree($d);
1692     mkpath '.git/dgit';
1693     mkdir $d or die $!;
1694 }
1695
1696 sub mktree_in_ud_here () {
1697     runcmd qw(git init -q);
1698     runcmd qw(git config gc.auto 0);
1699     rmtree('.git/objects');
1700     symlink '../../../../objects','.git/objects' or die $!;
1701     setup_gitattrs();
1702 }
1703
1704 sub git_write_tree () {
1705     my $tree = cmdoutput @git, qw(write-tree);
1706     $tree =~ m/^\w+$/ or die "$tree ?";
1707     return $tree;
1708 }
1709
1710 sub git_add_write_tree () {
1711     runcmd @git, qw(add -Af .);
1712     return git_write_tree();
1713 }
1714
1715 sub remove_stray_gits ($) {
1716     my ($what) = @_;
1717     my @gitscmd = qw(find -name .git -prune -print0);
1718     debugcmd "|",@gitscmd;
1719     open GITS, "-|", @gitscmd or die $!;
1720     {
1721         local $/="\0";
1722         while (<GITS>) {
1723             chomp or die;
1724             print STDERR "$us: warning: removing from $what: ",
1725                 (messagequote $_), "\n";
1726             rmtree $_;
1727         }
1728     }
1729     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1730 }
1731
1732 sub mktree_in_ud_from_only_subdir ($;$) {
1733     my ($what,$raw) = @_;
1734
1735     # changes into the subdir
1736     my (@dirs) = <*/.>;
1737     die "expected one subdir but found @dirs ?" unless @dirs==1;
1738     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1739     my $dir = $1;
1740     changedir $dir;
1741
1742     remove_stray_gits($what);
1743     mktree_in_ud_here();
1744     if (!$raw) {
1745         my ($format, $fopts) = get_source_format();
1746         if (madformat($format)) {
1747             rmtree '.pc';
1748         }
1749     }
1750
1751     my $tree=git_add_write_tree();
1752     return ($tree,$dir);
1753 }
1754
1755 our @files_csum_info_fields =
1756     (['Checksums-Sha256','Digest::SHA', 'new(256)', 'sha256sum'],
1757      ['Checksums-Sha1',  'Digest::SHA', 'new(1)',   'sha1sum'],
1758      ['Files',           'Digest::MD5', 'new()',    'md5sum']);
1759
1760 sub dsc_files_info () {
1761     foreach my $csumi (@files_csum_info_fields) {
1762         my ($fname, $module, $method) = @$csumi;
1763         my $field = $dsc->{$fname};
1764         next unless defined $field;
1765         eval "use $module; 1;" or die $@;
1766         my @out;
1767         foreach (split /\n/, $field) {
1768             next unless m/\S/;
1769             m/^(\w+) (\d+) (\S+)$/ or
1770                 fail "could not parse .dsc $fname line \`$_'";
1771             my $digester = eval "$module"."->$method;" or die $@;
1772             push @out, {
1773                 Hash => $1,
1774                 Bytes => $2,
1775                 Filename => $3,
1776                 Digester => $digester,
1777             };
1778         }
1779         return @out;
1780     }
1781     fail "missing any supported Checksums-* or Files field in ".
1782         $dsc->get_option('name');
1783 }
1784
1785 sub dsc_files () {
1786     map { $_->{Filename} } dsc_files_info();
1787 }
1788
1789 sub files_compare_inputs (@) {
1790     my $inputs = \@_;
1791     my %record;
1792     my %fchecked;
1793
1794     my $showinputs = sub {
1795         return join "; ", map { $_->get_option('name') } @$inputs;
1796     };
1797
1798     foreach my $in (@$inputs) {
1799         my $expected_files;
1800         my $in_name = $in->get_option('name');
1801
1802         printdebug "files_compare_inputs $in_name\n";
1803
1804         foreach my $csumi (@files_csum_info_fields) {
1805             my ($fname) = @$csumi;
1806             printdebug "files_compare_inputs $in_name $fname\n";
1807
1808             my $field = $in->{$fname};
1809             next unless defined $field;
1810
1811             my @files;
1812             foreach (split /\n/, $field) {
1813                 next unless m/\S/;
1814
1815                 my ($info, $f) = m/^(\w+ \d+) (?:\S+ \S+ )?(\S+)$/ or
1816                     fail "could not parse $in_name $fname line \`$_'";
1817
1818                 printdebug "files_compare_inputs $in_name $fname $f\n";
1819
1820                 push @files, $f;
1821
1822                 my $re = \ $record{$f}{$fname};
1823                 if (defined $$re) {
1824                     $fchecked{$f}{$in_name} = 1;
1825                     $$re eq $info or
1826                         fail "hash or size of $f varies in $fname fields".
1827                         " (between: ".$showinputs->().")";
1828                 } else {
1829                     $$re = $info;
1830                 }
1831             }
1832             @files = sort @files;
1833             $expected_files //= \@files;
1834             "@$expected_files" eq "@files" or
1835                 fail "file list in $in_name varies between hash fields!";
1836         }
1837         $expected_files or
1838             fail "$in_name has no files list field(s)";
1839     }
1840     printdebug "files_compare_inputs ".Dumper(\%fchecked, \%record)
1841         if $debuglevel>=2;
1842
1843     grep { keys %$_ == @$inputs-1 } values %fchecked
1844         or fail "no file appears in all file lists".
1845         " (looked in: ".$showinputs->().")";
1846 }
1847
1848 sub is_orig_file_in_dsc ($$) {
1849     my ($f, $dsc_files_info) = @_;
1850     return 0 if @$dsc_files_info <= 1;
1851     # One file means no origs, and the filename doesn't have a "what
1852     # part of dsc" component.  (Consider versions ending `.orig'.)
1853     return 0 unless $f =~ m/\.$orig_f_tail_re$/o;
1854     return 1;
1855 }
1856
1857 sub is_orig_file_of_vsn ($$) {
1858     my ($f, $upstreamvsn) = @_;
1859     my $base = srcfn $upstreamvsn, '';
1860     return 0 unless $f =~ m/^\Q$base\E\.$orig_f_tail_re$/;
1861     return 1;
1862 }
1863
1864 sub changes_update_origs_from_dsc ($$$$) {
1865     my ($dsc, $changes, $upstreamvsn, $changesfile) = @_;
1866     my %changes_f;
1867     printdebug "checking origs needed ($upstreamvsn)...\n";
1868     $_ = getfield $changes, 'Files';
1869     m/^\w+ \d+ (\S+ \S+) \S+$/m or
1870         fail "cannot find section/priority from .changes Files field";
1871     my $placementinfo = $1;
1872     my %changed;
1873     printdebug "checking origs needed placement '$placementinfo'...\n";
1874     foreach my $l (split /\n/, getfield $dsc, 'Files') {
1875         $l =~ m/\S+$/ or next;
1876         my $file = $&;
1877         printdebug "origs $file | $l\n";
1878         next unless is_orig_file_of_vsn $file, $upstreamvsn;
1879         printdebug "origs $file is_orig\n";
1880         my $have = archive_query('file_in_archive', $file);
1881         if (!defined $have) {
1882             print STDERR <<END;
1883 archive does not support .orig check; hope you used --ch:--sa/-sd if needed
1884 END
1885             return;
1886         }
1887         my $found_same = 0;
1888         my @found_differ;
1889         printdebug "origs $file \$#\$have=$#$have\n";
1890         foreach my $h (@$have) {
1891             my $same = 0;
1892             my @differ;
1893             foreach my $csumi (@files_csum_info_fields) {
1894                 my ($fname, $module, $method, $archivefield) = @$csumi;
1895                 next unless defined $h->{$archivefield};
1896                 $_ = $dsc->{$fname};
1897                 next unless defined;
1898                 m/^(\w+) .* \Q$file\E$/m or
1899                     fail ".dsc $fname missing entry for $file";
1900                 if ($h->{$archivefield} eq $1) {
1901                     $same++;
1902                 } else {
1903                     push @differ,
1904  "$archivefield: $h->{$archivefield} (archive) != $1 (local .dsc)";
1905                 }
1906             }
1907             die "$file ".Dumper($h)." ?!" if $same && @differ;
1908             $found_same++
1909                 if $same;
1910             push @found_differ, "archive $h->{filename}: ".join "; ", @differ
1911                 if @differ;
1912         }
1913         printdebug "origs $file f.same=$found_same".
1914             " #f._differ=$#found_differ\n";
1915         if (@found_differ && !$found_same) {
1916             fail join "\n",
1917                 "archive contains $file with different checksum",
1918                 @found_differ;
1919         }
1920         # Now we edit the changes file to add or remove it
1921         foreach my $csumi (@files_csum_info_fields) {
1922             my ($fname, $module, $method, $archivefield) = @$csumi;
1923             next unless defined $changes->{$fname};
1924             if ($found_same) {
1925                 # in archive, delete from .changes if it's there
1926                 $changed{$file} = "removed" if
1927                     $changes->{$fname} =~ s/^.* \Q$file\E$(?:)\n//m;
1928             } elsif ($changes->{$fname} =~ m/^.* \Q$file\E$(?:)\n/m) {
1929                 # not in archive, but it's here in the .changes
1930             } else {
1931                 my $dsc_data = getfield $dsc, $fname;
1932                 $dsc_data =~ m/^(.* \Q$file\E$)\n/m or die "$dsc_data $file ?";
1933                 my $extra = $1;
1934                 $extra =~ s/ \d+ /$&$placementinfo /
1935                     or die "$fname $extra >$dsc_data< ?"
1936                     if $fname eq 'Files';
1937                 $changes->{$fname} .= "\n". $extra;
1938                 $changed{$file} = "added";
1939             }
1940         }
1941     }
1942     if (%changed) {
1943         foreach my $file (keys %changed) {
1944             progress sprintf
1945                 "edited .changes for archive .orig contents: %s %s",
1946                 $changed{$file}, $file;
1947         }
1948         my $chtmp = "$changesfile.tmp";
1949         $changes->save($chtmp);
1950         if (act_local()) {
1951             rename $chtmp,$changesfile or die "$changesfile $!";
1952         } else {
1953             progress "[new .changes left in $changesfile]";
1954         }
1955     } else {
1956         progress "$changesfile already has appropriate .orig(s) (if any)";
1957     }
1958 }
1959
1960 sub make_commit ($) {
1961     my ($file) = @_;
1962     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1963 }
1964
1965 sub make_commit_text ($) {
1966     my ($text) = @_;
1967     my ($out, $in);
1968     my @cmd = (@git, qw(hash-object -w -t commit --stdin));
1969     debugcmd "|",@cmd;
1970     print Dumper($text) if $debuglevel > 1;
1971     my $child = open2($out, $in, @cmd) or die $!;
1972     my $h;
1973     eval {
1974         print $in $text or die $!;
1975         close $in or die $!;
1976         $h = <$out>;
1977         $h =~ m/^\w+$/ or die;
1978         $h = $&;
1979         printdebug "=> $h\n";
1980     };
1981     close $out;
1982     waitpid $child, 0 == $child or die "$child $!";
1983     $? and failedcmd @cmd;
1984     return $h;
1985 }
1986
1987 sub clogp_authline ($) {
1988     my ($clogp) = @_;
1989     my $author = getfield $clogp, 'Maintainer';
1990     $author =~ s#,.*##ms;
1991     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1992     my $authline = "$author $date";
1993     $authline =~ m/$git_authline_re/o or
1994         fail "unexpected commit author line format \`$authline'".
1995         " (was generated from changelog Maintainer field)";
1996     return ($1,$2,$3) if wantarray;
1997     return $authline;
1998 }
1999
2000 sub vendor_patches_distro ($$) {
2001     my ($checkdistro, $what) = @_;
2002     return unless defined $checkdistro;
2003
2004     my $series = "debian/patches/\L$checkdistro\E.series";
2005     printdebug "checking for vendor-specific $series ($what)\n";
2006
2007     if (!open SERIES, "<", $series) {
2008         die "$series $!" unless $!==ENOENT;
2009         return;
2010     }
2011     while (<SERIES>) {
2012         next unless m/\S/;
2013         next if m/^\s+\#/;
2014
2015         print STDERR <<END;
2016
2017 Unfortunately, this source package uses a feature of dpkg-source where
2018 the same source package unpacks to different source code on different
2019 distros.  dgit cannot safely operate on such packages on affected
2020 distros, because the meaning of source packages is not stable.
2021
2022 Please ask the distro/maintainer to remove the distro-specific series
2023 files and use a different technique (if necessary, uploading actually
2024 different packages, if different distros are supposed to have
2025 different code).
2026
2027 END
2028         fail "Found active distro-specific series file for".
2029             " $checkdistro ($what): $series, cannot continue";
2030     }
2031     die "$series $!" if SERIES->error;
2032     close SERIES;
2033 }
2034
2035 sub check_for_vendor_patches () {
2036     # This dpkg-source feature doesn't seem to be documented anywhere!
2037     # But it can be found in the changelog (reformatted):
2038
2039     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
2040     #   Author: Raphael Hertzog <hertzog@debian.org>
2041     #   Date: Sun  Oct  3  09:36:48  2010 +0200
2042
2043     #   dpkg-source: correctly create .pc/.quilt_series with alternate
2044     #   series files
2045     #
2046     #   If you have debian/patches/ubuntu.series and you were
2047     #   unpacking the source package on ubuntu, quilt was still
2048     #   directed to debian/patches/series instead of
2049     #   debian/patches/ubuntu.series.
2050     #
2051     #   debian/changelog                        |    3 +++
2052     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
2053     #   2 files changed, 6 insertions(+), 1 deletion(-)
2054
2055     use Dpkg::Vendor;
2056     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
2057     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
2058                          "Dpkg::Vendor \`current vendor'");
2059     vendor_patches_distro(access_basedistro(),
2060                           "(base) distro being accessed");
2061     vendor_patches_distro(access_nomdistro(),
2062                           "(nominal) distro being accessed");
2063 }
2064
2065 sub generate_commits_from_dsc () {
2066     # See big comment in fetch_from_archive, below.
2067     # See also README.dsc-import.
2068     prep_ud();
2069     changedir $ud;
2070
2071     my @dfi = dsc_files_info();
2072     foreach my $fi (@dfi) {
2073         my $f = $fi->{Filename};
2074         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
2075         my $upper_f = "../../../../$f";
2076
2077         printdebug "considering reusing $f: ";
2078
2079         if (link_ltarget "$upper_f,fetch", $f) {
2080             printdebug "linked (using ...,fetch).\n";
2081         } elsif ((printdebug "($!) "),
2082                  $! != ENOENT) {
2083             fail "accessing ../$f,fetch: $!";
2084         } elsif (link_ltarget $upper_f, $f) {
2085             printdebug "linked.\n";
2086         } elsif ((printdebug "($!) "),
2087                  $! != ENOENT) {
2088             fail "accessing ../$f: $!";
2089         } else {
2090             printdebug "absent.\n";
2091         }
2092
2093         my $refetched;
2094         complete_file_from_dsc('.', $fi, \$refetched)
2095             or next;
2096
2097         printdebug "considering saving $f: ";
2098
2099         if (link $f, $upper_f) {
2100             printdebug "linked.\n";
2101         } elsif ((printdebug "($!) "),
2102                  $! != EEXIST) {
2103             fail "saving ../$f: $!";
2104         } elsif (!$refetched) {
2105             printdebug "no need.\n";
2106         } elsif (link $f, "$upper_f,fetch") {
2107             printdebug "linked (using ...,fetch).\n";
2108         } elsif ((printdebug "($!) "),
2109                  $! != EEXIST) {
2110             fail "saving ../$f,fetch: $!";
2111         } else {
2112             printdebug "cannot.\n";
2113         }
2114     }
2115
2116     # We unpack and record the orig tarballs first, so that we only
2117     # need disk space for one private copy of the unpacked source.
2118     # But we can't make them into commits until we have the metadata
2119     # from the debian/changelog, so we record the tree objects now and
2120     # make them into commits later.
2121     my @tartrees;
2122     my $upstreamv = upstreamversion $dsc->{version};
2123     my $orig_f_base = srcfn $upstreamv, '';
2124
2125     foreach my $fi (@dfi) {
2126         # We actually import, and record as a commit, every tarball
2127         # (unless there is only one file, in which case there seems
2128         # little point.
2129
2130         my $f = $fi->{Filename};
2131         printdebug "import considering $f ";
2132         (printdebug "only one dfi\n"), next if @dfi == 1;
2133         (printdebug "not tar\n"), next unless $f =~ m/\.tar(\.\w+)?$/;
2134         (printdebug "signature\n"), next if $f =~ m/$orig_f_sig_re$/o;
2135         my $compr_ext = $1;
2136
2137         my ($orig_f_part) =
2138             $f =~ m/^\Q$orig_f_base\E\.([^._]+)?\.tar(?:\.\w+)?$/;
2139
2140         printdebug "Y ", (join ' ', map { $_//"(none)" }
2141                           $compr_ext, $orig_f_part
2142                          ), "\n";
2143
2144         my $input = new IO::File $f, '<' or die "$f $!";
2145         my $compr_pid;
2146         my @compr_cmd;
2147
2148         if (defined $compr_ext) {
2149             my $cname =
2150                 Dpkg::Compression::compression_guess_from_filename $f;
2151             fail "Dpkg::Compression cannot handle file $f in source package"
2152                 if defined $compr_ext && !defined $cname;
2153             my $compr_proc =
2154                 new Dpkg::Compression::Process compression => $cname;
2155             my @compr_cmd = $compr_proc->get_uncompress_cmdline();
2156             my $compr_fh = new IO::Handle;
2157             my $compr_pid = open $compr_fh, "-|" // die $!;
2158             if (!$compr_pid) {
2159                 open STDIN, "<&", $input or die $!;
2160                 exec @compr_cmd;
2161                 die "dgit (child): exec $compr_cmd[0]: $!\n";
2162             }
2163             $input = $compr_fh;
2164         }
2165
2166         rmtree "_unpack-tar";
2167         mkdir "_unpack-tar" or die $!;
2168         my @tarcmd = qw(tar -x -f -
2169                         --no-same-owner --no-same-permissions
2170                         --no-acls --no-xattrs --no-selinux);
2171         my $tar_pid = fork // die $!;
2172         if (!$tar_pid) {
2173             chdir "_unpack-tar" or die $!;
2174             open STDIN, "<&", $input or die $!;
2175             exec @tarcmd;
2176             die "dgit (child): exec $tarcmd[0]: $!";
2177         }
2178         $!=0; (waitpid $tar_pid, 0) == $tar_pid or die $!;
2179         !$? or failedcmd @tarcmd;
2180
2181         close $input or
2182             (@compr_cmd ? failedcmd @compr_cmd
2183              : die $!);
2184         # finally, we have the results in "tarball", but maybe
2185         # with the wrong permissions
2186
2187         runcmd qw(chmod -R +rwX _unpack-tar);
2188         changedir "_unpack-tar";
2189         remove_stray_gits($f);
2190         mktree_in_ud_here();
2191
2192         my ($tree) = git_add_write_tree();
2193         my $tentries = cmdoutput @git, qw(ls-tree -z), $tree;
2194         if ($tentries =~ m/^\d+ tree (\w+)\t[^\000]+\000$/s) {
2195             $tree = $1;
2196             printdebug "one subtree $1\n";
2197         } else {
2198             printdebug "multiple subtrees\n";
2199         }
2200         changedir "..";
2201         rmtree "_unpack-tar";
2202
2203         my $ent = [ $f, $tree ];
2204         push @tartrees, {
2205             Orig => !!$orig_f_part,
2206             Sort => (!$orig_f_part         ? 2 :
2207                      $orig_f_part =~ m/-/g ? 1 :
2208                                              0),
2209             F => $f,
2210             Tree => $tree,
2211         };
2212     }
2213
2214     @tartrees = sort {
2215         # put any without "_" first (spec is not clear whether files
2216         # are always in the usual order).  Tarballs without "_" are
2217         # the main orig or the debian tarball.
2218         $a->{Sort} <=> $b->{Sort} or
2219         $a->{F}    cmp $b->{F}
2220     } @tartrees;
2221
2222     my $any_orig = grep { $_->{Orig} } @tartrees;
2223
2224     my $dscfn = "$package.dsc";
2225
2226     my $treeimporthow = 'package';
2227
2228     open D, ">", $dscfn or die "$dscfn: $!";
2229     print D $dscdata or die "$dscfn: $!";
2230     close D or die "$dscfn: $!";
2231     my @cmd = qw(dpkg-source);
2232     push @cmd, '--no-check' if $dsc_checked;
2233     if (madformat $dsc->{format}) {
2234         push @cmd, '--skip-patches';
2235         $treeimporthow = 'unpatched';
2236     }
2237     push @cmd, qw(-x --), $dscfn;
2238     runcmd @cmd;
2239
2240     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
2241     if (madformat $dsc->{format}) {
2242         check_for_vendor_patches();
2243     }
2244
2245     my $dappliedtree;
2246     if (madformat $dsc->{format}) {
2247         my @pcmd = qw(dpkg-source --before-build .);
2248         runcmd shell_cmd 'exec >/dev/null', @pcmd;
2249         rmtree '.pc';
2250         $dappliedtree = git_add_write_tree();
2251     }
2252
2253     my @clogcmd = qw(dpkg-parsechangelog --format rfc822 --all);
2254     debugcmd "|",@clogcmd;
2255     open CLOGS, "-|", @clogcmd or die $!;
2256
2257     my $clogp;
2258     my $r1clogp;
2259
2260     printdebug "import clog search...\n";
2261
2262     for (;;) {
2263         my $stanzatext = do { local $/=""; <CLOGS>; };
2264         printdebug "import clogp ".Dumper($stanzatext) if $debuglevel>1;
2265         last if !defined $stanzatext;
2266
2267         my $desc = "package changelog, entry no.$.";
2268         open my $stanzafh, "<", \$stanzatext or die;
2269         my $thisstanza = parsecontrolfh $stanzafh, $desc, 1;
2270         $clogp //= $thisstanza;
2271
2272         printdebug "import clog $thisstanza->{version} $desc...\n";
2273
2274         last if !$any_orig; # we don't need $r1clogp
2275
2276         # We look for the first (most recent) changelog entry whose
2277         # version number is lower than the upstream version of this
2278         # package.  Then the last (least recent) previous changelog
2279         # entry is treated as the one which introduced this upstream
2280         # version and used for the synthetic commits for the upstream
2281         # tarballs.
2282
2283         # One might think that a more sophisticated algorithm would be
2284         # necessary.  But: we do not want to scan the whole changelog
2285         # file.  Stopping when we see an earlier version, which
2286         # necessarily then is an earlier upstream version, is the only
2287         # realistic way to do that.  Then, either the earliest
2288         # changelog entry we have seen so far is indeed the earliest
2289         # upload of this upstream version; or there are only changelog
2290         # entries relating to later upstream versions (which is not
2291         # possible unless the changelog and .dsc disagree about the
2292         # version).  Then it remains to choose between the physically
2293         # last entry in the file, and the one with the lowest version
2294         # number.  If these are not the same, we guess that the
2295         # versions were created in a non-monotic order rather than
2296         # that the changelog entries have been misordered.
2297
2298         printdebug "import clog $thisstanza->{version} vs $upstreamv...\n";
2299
2300         last if version_compare($thisstanza->{version}, $upstreamv) < 0;
2301         $r1clogp = $thisstanza;
2302
2303         printdebug "import clog $r1clogp->{version} becomes r1\n";
2304     }
2305     die $! if CLOGS->error;
2306     close CLOGS or $?==SIGPIPE or failedcmd @clogcmd;
2307
2308     $clogp or fail "package changelog has no entries!";
2309
2310     my $authline = clogp_authline $clogp;
2311     my $changes = getfield $clogp, 'Changes';
2312     my $cversion = getfield $clogp, 'Version';
2313
2314     if (@tartrees) {
2315         $r1clogp //= $clogp; # maybe there's only one entry;
2316         my $r1authline = clogp_authline $r1clogp;
2317         # Strictly, r1authline might now be wrong if it's going to be
2318         # unused because !$any_orig.  Whatever.
2319
2320         printdebug "import tartrees authline   $authline\n";
2321         printdebug "import tartrees r1authline $r1authline\n";
2322
2323         foreach my $tt (@tartrees) {
2324             printdebug "import tartree $tt->{F} $tt->{Tree}\n";
2325
2326             $tt->{Commit} = make_commit_text($tt->{Orig} ? <<END_O : <<END_T);
2327 tree $tt->{Tree}
2328 author $r1authline
2329 committer $r1authline
2330
2331 Import $tt->{F}
2332
2333 [dgit import orig $tt->{F}]
2334 END_O
2335 tree $tt->{Tree}
2336 author $authline
2337 committer $authline
2338
2339 Import $tt->{F}
2340
2341 [dgit import tarball $package $cversion $tt->{F}]
2342 END_T
2343         }
2344     }
2345
2346     printdebug "import main commit\n";
2347
2348     open C, ">../commit.tmp" or die $!;
2349     print C <<END or die $!;
2350 tree $tree
2351 END
2352     print C <<END or die $! foreach @tartrees;
2353 parent $_->{Commit}
2354 END
2355     print C <<END or die $!;
2356 author $authline
2357 committer $authline
2358
2359 $changes
2360
2361 [dgit import $treeimporthow $package $cversion]
2362 END
2363
2364     close C or die $!;
2365     my $rawimport_hash = make_commit qw(../commit.tmp);
2366
2367     if (madformat $dsc->{format}) {
2368         printdebug "import apply patches...\n";
2369
2370         # regularise the state of the working tree so that
2371         # the checkout of $rawimport_hash works nicely.
2372         my $dappliedcommit = make_commit_text(<<END);
2373 tree $dappliedtree
2374 author $authline
2375 committer $authline
2376
2377 [dgit dummy commit]
2378 END
2379         runcmd @git, qw(checkout -q -b dapplied), $dappliedcommit;
2380
2381         runcmd @git, qw(checkout -q -b unpa), $rawimport_hash;
2382
2383         # We need the answers to be reproducible
2384         my @authline = clogp_authline($clogp);
2385         local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
2386         local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
2387         local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
2388         local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
2389         local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
2390         local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
2391
2392         my $path = $ENV{PATH} or die;
2393
2394         foreach my $use_absurd (qw(0 1)) {
2395             runcmd @git, qw(checkout -q unpa);
2396             runcmd @git, qw(update-ref -d refs/heads/patch-queue/unpa);
2397             local $ENV{PATH} = $path;
2398             if ($use_absurd) {
2399                 chomp $@;
2400                 progress "warning: $@";
2401                 $path = "$absurdity:$path";
2402                 progress "$us: trying slow absurd-git-apply...";
2403                 rename "../../gbp-pq-output","../../gbp-pq-output.0"
2404                     or $!==ENOENT
2405                     or die $!;
2406             }
2407             eval {
2408                 die "forbid absurd git-apply\n" if $use_absurd
2409                     && forceing [qw(import-gitapply-no-absurd)];
2410                 die "only absurd git-apply!\n" if !$use_absurd
2411                     && forceing [qw(import-gitapply-absurd)];
2412
2413                 local $ENV{DGIT_ABSURD_DEBUG} = $debuglevel if $use_absurd;
2414                 local $ENV{PATH} = $path                    if $use_absurd;
2415
2416                 my @showcmd = (gbp_pq, qw(import));
2417                 my @realcmd = shell_cmd
2418                     'exec >/dev/null 2>>../../gbp-pq-output', @showcmd;
2419                 debugcmd "+",@realcmd;
2420                 if (system @realcmd) {
2421                     die +(shellquote @showcmd).
2422                         " failed: ".
2423                         failedcmd_waitstatus()."\n";
2424                 }
2425
2426                 my $gapplied = git_rev_parse('HEAD');
2427                 my $gappliedtree = cmdoutput @git, qw(rev-parse HEAD:);
2428                 $gappliedtree eq $dappliedtree or
2429                     fail <<END;
2430 gbp-pq import and dpkg-source disagree!
2431  gbp-pq import gave commit $gapplied
2432  gbp-pq import gave tree $gappliedtree
2433  dpkg-source --before-build gave tree $dappliedtree
2434 END
2435                 $rawimport_hash = $gapplied;
2436             };
2437             last unless $@;
2438         }
2439         if ($@) {
2440             { local $@; eval { runcmd qw(cat ../../gbp-pq-output); }; }
2441             die $@;
2442         }
2443     }
2444
2445     progress "synthesised git commit from .dsc $cversion";
2446
2447     my $rawimport_mergeinput = {
2448         Commit => $rawimport_hash,
2449         Info => "Import of source package",
2450     };
2451     my @output = ($rawimport_mergeinput);
2452
2453     if ($lastpush_mergeinput) {
2454         my $oldclogp = mergeinfo_getclogp($lastpush_mergeinput);
2455         my $oversion = getfield $oldclogp, 'Version';
2456         my $vcmp =
2457             version_compare($oversion, $cversion);
2458         if ($vcmp < 0) {
2459             @output = ($rawimport_mergeinput, $lastpush_mergeinput,
2460                 { Message => <<END, ReverseParents => 1 });
2461 Record $package ($cversion) in archive suite $csuite
2462 END
2463         } elsif ($vcmp > 0) {
2464             print STDERR <<END or die $!;
2465
2466 Version actually in archive:   $cversion (older)
2467 Last version pushed with dgit: $oversion (newer or same)
2468 $later_warning_msg
2469 END
2470             @output = $lastpush_mergeinput;
2471         } else {
2472             # Same version.  Use what's in the server git branch,
2473             # discarding our own import.  (This could happen if the
2474             # server automatically imports all packages into git.)
2475             @output = $lastpush_mergeinput;
2476         }
2477     }
2478     changedir '../../../..';
2479     rmtree($ud);
2480     return @output;
2481 }
2482
2483 sub complete_file_from_dsc ($$;$) {
2484     our ($dstdir, $fi, $refetched) = @_;
2485     # Ensures that we have, in $dstdir, the file $fi, with the correct
2486     # contents.  (Downloading it from alongside $dscurl if necessary.)
2487     # If $refetched is defined, can overwrite "$dstdir/$fi->{Filename}"
2488     # and will set $$refetched=1 if it did so (or tried to).
2489
2490     my $f = $fi->{Filename};
2491     my $tf = "$dstdir/$f";
2492     my $downloaded = 0;
2493
2494     my $got;
2495     my $checkhash = sub {
2496         open F, "<", "$tf" or die "$tf: $!";
2497         $fi->{Digester}->reset();
2498         $fi->{Digester}->addfile(*F);
2499         F->error and die $!;
2500         my $got = $fi->{Digester}->hexdigest();
2501         return $got eq $fi->{Hash};
2502     };
2503
2504     if (stat_exists $tf) {
2505         if ($checkhash->()) {
2506             progress "using existing $f";
2507             return 1;
2508         }
2509         if (!$refetched) {
2510             fail "file $f has hash $got but .dsc".
2511                 " demands hash $fi->{Hash} ".
2512                 "(perhaps you should delete this file?)";
2513         }
2514         progress "need to fetch correct version of $f";
2515         unlink $tf or die "$tf $!";
2516         $$refetched = 1;
2517     } else {
2518         printdebug "$tf does not exist, need to fetch\n";
2519     }
2520
2521     my $furl = $dscurl;
2522     $furl =~ s{/[^/]+$}{};
2523     $furl .= "/$f";
2524     die "$f ?" unless $f =~ m/^\Q${package}\E_/;
2525     die "$f ?" if $f =~ m#/#;
2526     runcmd_ordryrun_local @curl,qw(-f -o),$tf,'--',"$furl";
2527     return 0 if !act_local();
2528
2529     $checkhash->() or
2530         fail "file $f has hash $got but .dsc".
2531             " demands hash $fi->{Hash} ".
2532             "(got wrong file from archive!)";
2533
2534     return 1;
2535 }
2536
2537 sub ensure_we_have_orig () {
2538     my @dfi = dsc_files_info();
2539     foreach my $fi (@dfi) {
2540         my $f = $fi->{Filename};
2541         next unless is_orig_file_in_dsc($f, \@dfi);
2542         complete_file_from_dsc('..', $fi)
2543             or next;
2544     }
2545 }
2546
2547 #---------- git fetch ----------
2548
2549 sub lrfetchrefs () { return "refs/dgit-fetch/".access_basedistro(); }
2550 sub lrfetchref () { return lrfetchrefs.'/'.server_branch($csuite); }
2551
2552 # We fetch some parts of lrfetchrefs/*.  Ideally we delete these
2553 # locally fetched refs because they have unhelpful names and clutter
2554 # up gitk etc.  So we track whether we have "used up" head ref (ie,
2555 # whether we have made another local ref which refers to this object).
2556 #
2557 # (If we deleted them unconditionally, then we might end up
2558 # re-fetching the same git objects each time dgit fetch was run.)
2559 #
2560 # So, each use of lrfetchrefs needs to be accompanied by arrangements
2561 # in git_fetch_us to fetch the refs in question, and possibly a call
2562 # to lrfetchref_used.
2563
2564 our (%lrfetchrefs_f, %lrfetchrefs_d);
2565 # $lrfetchrefs_X{lrfetchrefs."/heads/whatever"} = $objid
2566
2567 sub lrfetchref_used ($) {
2568     my ($fullrefname) = @_;
2569     my $objid = $lrfetchrefs_f{$fullrefname};
2570     $lrfetchrefs_d{$fullrefname} = $objid if defined $objid;
2571 }
2572
2573 sub git_lrfetch_sane {
2574     my ($supplementary, @specs) = @_;
2575     # Make a 'refs/'.lrfetchrefs.'/*' be just like on server,
2576     # at least as regards @specs.  Also leave the results in
2577     # %lrfetchrefs_f, and arrange for lrfetchref_used to be
2578     # able to clean these up.
2579     #
2580     # With $supplementary==1, @specs must not contain wildcards
2581     # and we add to our previous fetches (non-atomically).
2582
2583     # This is rather miserable:
2584     # When git fetch --prune is passed a fetchspec ending with a *,
2585     # it does a plausible thing.  If there is no * then:
2586     # - it matches subpaths too, even if the supplied refspec
2587     #   starts refs, and behaves completely madly if the source
2588     #   has refs/refs/something.  (See, for example, Debian #NNNN.)
2589     # - if there is no matching remote ref, it bombs out the whole
2590     #   fetch.
2591     # We want to fetch a fixed ref, and we don't know in advance
2592     # if it exists, so this is not suitable.
2593     #
2594     # Our workaround is to use git ls-remote.  git ls-remote has its
2595     # own qairks.  Notably, it has the absurd multi-tail-matching
2596     # behaviour: git ls-remote R refs/foo can report refs/foo AND
2597     # refs/refs/foo etc.
2598     #
2599     # Also, we want an idempotent snapshot, but we have to make two
2600     # calls to the remote: one to git ls-remote and to git fetch.  The
2601     # solution is use git ls-remote to obtain a target state, and
2602     # git fetch to try to generate it.  If we don't manage to generate
2603     # the target state, we try again.
2604
2605     my $url = access_giturl();
2606
2607     printdebug "git_lrfetch_sane suppl=$supplementary specs @specs\n";
2608
2609     my $specre = join '|', map {
2610         my $x = $_;
2611         $x =~ s/\W/\\$&/g;
2612         my $wildcard = $x =~ s/\\\*$/.*/;
2613         die if $wildcard && $supplementary;
2614         "(?:refs/$x)";
2615     } @specs;
2616     printdebug "git_lrfetch_sane specre=$specre\n";
2617     my $wanted_rref = sub {
2618         local ($_) = @_;
2619         return m/^(?:$specre)$/;
2620     };
2621
2622     my $fetch_iteration = 0;
2623     FETCH_ITERATION:
2624     for (;;) {
2625         printdebug "git_lrfetch_sane iteration $fetch_iteration\n";
2626         if (++$fetch_iteration > 10) {
2627             fail "too many iterations trying to get sane fetch!";
2628         }
2629
2630         my @look = map { "refs/$_" } @specs;
2631         my @lcmd = (@git, qw(ls-remote -q --refs), $url, @look);
2632         debugcmd "|",@lcmd;
2633
2634         my %wantr;
2635         open GITLS, "-|", @lcmd or die $!;
2636         while (<GITLS>) {
2637             printdebug "=> ", $_;
2638             m/^(\w+)\s+(\S+)\n/ or die "ls-remote $_ ?";
2639             my ($objid,$rrefname) = ($1,$2);
2640             if (!$wanted_rref->($rrefname)) {
2641                 print STDERR <<END;
2642 warning: git ls-remote @look reported $rrefname; this is silly, ignoring it.
2643 END
2644                 next;
2645             }
2646             $wantr{$rrefname} = $objid;
2647         }
2648         $!=0; $?=0;
2649         close GITLS or failedcmd @lcmd;
2650
2651         # OK, now %want is exactly what we want for refs in @specs
2652         my @fspecs = map {
2653             !m/\*$/ && !exists $wantr{"refs/$_"} ? () :
2654             "+refs/$_:".lrfetchrefs."/$_";
2655         } @specs;
2656
2657         printdebug "git_lrfetch_sane fspecs @fspecs\n";
2658
2659         my @fcmd = (@git, qw(fetch -p -n -q), $url, @fspecs);
2660         runcmd_ordryrun_local @fcmd if @fspecs;
2661
2662         if (!$supplementary) {
2663             %lrfetchrefs_f = ();
2664         }
2665         my %objgot;
2666
2667         git_for_each_ref(lrfetchrefs, sub {
2668             my ($objid,$objtype,$lrefname,$reftail) = @_;
2669             $lrfetchrefs_f{$lrefname} = $objid;
2670             $objgot{$objid} = 1;
2671         });
2672
2673         if ($supplementary) {
2674             last;
2675         }
2676
2677         foreach my $lrefname (sort keys %lrfetchrefs_f) {
2678             my $rrefname = 'refs'.substr($lrefname, length lrfetchrefs);
2679             if (!exists $wantr{$rrefname}) {
2680                 if ($wanted_rref->($rrefname)) {
2681                     printdebug <<END;
2682 git-fetch @fspecs created $lrefname which git ls-remote @look didn't list.
2683 END
2684                 } else {
2685                     print STDERR <<END
2686 warning: git fetch @fspecs created $lrefname; this is silly, deleting it.
2687 END
2688                 }
2689                 runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2690                 delete $lrfetchrefs_f{$lrefname};
2691                 next;
2692             }
2693         }
2694         foreach my $rrefname (sort keys %wantr) {
2695             my $lrefname = lrfetchrefs.substr($rrefname, 4);
2696             my $got = $lrfetchrefs_f{$lrefname} // '<none>';
2697             my $want = $wantr{$rrefname};
2698             next if $got eq $want;
2699             if (!defined $objgot{$want}) {
2700                 print STDERR <<END;
2701 warning: git ls-remote suggests we want $lrefname
2702 warning:  and it should refer to $want
2703 warning:  but git fetch didn't fetch that object to any relevant ref.
2704 warning:  This may be due to a race with someone updating the server.
2705 warning:  Will try again...
2706 END
2707                 next FETCH_ITERATION;
2708             }
2709             printdebug <<END;
2710 git-fetch @fspecs made $lrefname=$got but want git ls-remote @look says $want
2711 END
2712             runcmd_ordryrun_local @git, qw(update-ref -m),
2713                 "dgit fetch git fetch fixup", $lrefname, $want;
2714             $lrfetchrefs_f{$lrefname} = $want;
2715         }
2716         last;
2717     }
2718
2719     if (defined $csuite) {
2720         printdebug "git_lrfetch_sane: tidying any old suite lrfetchrefs\n";
2721         git_for_each_ref("refs/dgit-fetch/$csuite", sub {
2722             my ($objid,$objtype,$lrefname,$reftail) = @_;
2723             next if $lrfetchrefs_f{$lrefname}; # $csuite eq $distro ?
2724             runcmd_ordryrun_local @git, qw(update-ref -d), $lrefname;
2725         });
2726     }
2727
2728     printdebug "git_lrfetch_sane: git fetch --no-insane emulation complete\n",
2729         Dumper(\%lrfetchrefs_f);
2730 }
2731
2732 sub git_fetch_us () {
2733     # Want to fetch only what we are going to use, unless
2734     # deliberately-not-ff, in which case we must fetch everything.
2735
2736     my @specs = deliberately_not_fast_forward ? qw(tags/*) :
2737         map { "tags/$_" }
2738         (quiltmode_splitbrain
2739          ? (map { $_->('*',access_nomdistro) }
2740             \&debiantag_new, \&debiantag_maintview)
2741          : debiantags('*',access_nomdistro));
2742     push @specs, server_branch($csuite);
2743     push @specs, $rewritemap;
2744     push @specs, qw(heads/*) if deliberately_not_fast_forward;
2745
2746     git_lrfetch_sane 0, @specs;
2747
2748     my %here;
2749     my @tagpats = debiantags('*',access_nomdistro);
2750
2751     git_for_each_ref([map { "refs/tags/$_" } @tagpats], sub {
2752         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2753         printdebug "currently $fullrefname=$objid\n";
2754         $here{$fullrefname} = $objid;
2755     });
2756     git_for_each_ref([map { lrfetchrefs."/tags/".$_ } @tagpats], sub {
2757         my ($objid,$objtype,$fullrefname,$reftail) = @_;
2758         my $lref = "refs".substr($fullrefname, length(lrfetchrefs));
2759         printdebug "offered $lref=$objid\n";
2760         if (!defined $here{$lref}) {
2761             my @upd = (@git, qw(update-ref), $lref, $objid, '');
2762             runcmd_ordryrun_local @upd;
2763             lrfetchref_used $fullrefname;
2764         } elsif ($here{$lref} eq $objid) {
2765             lrfetchref_used $fullrefname;
2766         } else {
2767             print STDERR
2768                 "Not updating $lref from $here{$lref} to $objid.\n";
2769         }
2770     });
2771 }
2772
2773 #---------- dsc and archive handling ----------
2774
2775 sub mergeinfo_getclogp ($) {
2776     # Ensures thit $mi->{Clogp} exists and returns it
2777     my ($mi) = @_;
2778     $mi->{Clogp} = commit_getclogp($mi->{Commit});
2779 }
2780
2781 sub mergeinfo_version ($) {
2782     return getfield( (mergeinfo_getclogp $_[0]), 'Version' );
2783 }
2784
2785 sub fetch_from_archive_record_1 ($) {
2786     my ($hash) = @_;
2787     runcmd @git, qw(update-ref -m), "dgit fetch $csuite",
2788             'DGIT_ARCHIVE', $hash;
2789     cmdoutput @git, qw(log -n2), $hash;
2790     # ... gives git a chance to complain if our commit is malformed
2791 }
2792
2793 sub fetch_from_archive_record_2 ($) {
2794     my ($hash) = @_;
2795     my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
2796     if (act_local()) {
2797         cmdoutput @upd_cmd;
2798     } else {
2799         dryrun_report @upd_cmd;
2800     }
2801 }
2802
2803 sub parse_dsc_field_def_dsc_distro () {
2804     $dsc_distro //= cfg qw(dgit.default.old-dsc-distro
2805                            dgit.default.distro);
2806 }
2807
2808 sub parse_dsc_field ($$) {
2809     my ($dsc, $what) = @_;
2810     my $f;
2811     foreach my $field (@ourdscfield) {
2812         $f = $dsc->{$field};
2813         last if defined $f;
2814     }
2815
2816     if (!defined $f) {
2817         progress "$what: NO git hash";
2818         parse_dsc_field_def_dsc_distro();
2819     } elsif (($dsc_hash, $dsc_distro, $dsc_hint_tag, $dsc_hint_url)
2820              = $f =~ m/^(\w+)\s+($distro_re)\s+($versiontag_re)\s+(\S+)(?:\s|$)/) {
2821         progress "$what: specified git info ($dsc_distro)";
2822         $dsc_hint_tag = [ $dsc_hint_tag ];
2823     } elsif ($f =~ m/^\w+\s*$/) {
2824         $dsc_hash = $&;
2825         parse_dsc_field_def_dsc_distro();
2826         $dsc_hint_tag = [ debiantags +(getfield $dsc, 'Version'),
2827                           $dsc_distro ];
2828         progress "$what: specified git hash";
2829     } else {
2830         fail "$what: invalid Dgit info";
2831     }
2832 }
2833
2834 sub resolve_dsc_field_commit ($$) {
2835     my ($already_distro, $already_mapref) = @_;
2836
2837     return unless defined $dsc_hash;
2838
2839     my $mapref =
2840         defined $already_mapref &&
2841         ($already_distro eq $dsc_distro || !$chase_dsc_distro)
2842         ? $already_mapref : undef;
2843
2844     my $do_fetch;
2845     $do_fetch = sub {
2846         my ($what, @fetch) = @_;
2847
2848         local $idistro = $dsc_distro;
2849         my $lrf = lrfetchrefs;
2850
2851         if (!$chase_dsc_distro) {
2852             progress
2853                 "not chasing .dsc distro $dsc_distro: not fetching $what";
2854             return 0;
2855         }
2856
2857         progress
2858             ".dsc names distro $dsc_distro: fetching $what";
2859
2860         my $url = access_giturl();
2861         if (!defined $url) {
2862             defined $dsc_hint_url or fail <<END;
2863 .dsc Dgit metadata is in context of distro $dsc_distro
2864 for which we have no configured url and .dsc provides no hint
2865 END
2866             my $proto =
2867                 $dsc_hint_url =~ m#^([-+0-9a-zA-Z]+):# ? $1 :
2868                 $dsc_hint_url =~ m#^/# ? 'file' : 'bad-syntax';
2869             parse_cfg_bool "dsc-url-proto-ok", 'false',
2870                 cfg("dgit.dsc-url-proto-ok.$proto",
2871                     "dgit.default.dsc-url-proto-ok")
2872                 or fail <<END;
2873 .dsc Dgit metadata is in context of distro $dsc_distro
2874 for which we have no configured url;
2875 .dsc provices hinted url with protocol $proto which is unsafe.
2876 (can be overridden by config - consult documentation)
2877 END
2878             $url = $dsc_hint_url;
2879         }
2880
2881         git_lrfetch_sane 1, @fetch;
2882
2883         return $lrf;
2884     };
2885
2886     my $rewrite_enable = do {
2887         local $idistro = $dsc_distro;
2888         access_cfg('rewrite-map-enable', 'RETURN-UNDEF');
2889     };
2890
2891     if (parse_cfg_bool 'rewrite-map-enable', 'true', $rewrite_enable) {
2892         if (!defined $mapref) {
2893             my $lrf = $do_fetch->("rewrite map", $rewritemap) or return;
2894             $mapref = $lrf.'/'.$rewritemap;
2895         }
2896         my $rewritemapdata = git_cat_file $mapref.':map';
2897         if (defined $rewritemapdata
2898             && $rewritemapdata =~ m/^$dsc_hash(?:[ \t](\w+))/m) {
2899             progress
2900                 "server's git history rewrite map contains a relevant entry!";
2901
2902             $dsc_hash = $1;
2903             if (defined $dsc_hash) {
2904                 progress "using rewritten git hash in place of .dsc value";
2905             } else {
2906                 progress "server data says .dsc hash is to be disregarded";
2907             }
2908         }
2909     }
2910
2911     if (!defined git_cat_file $dsc_hash) {
2912         my @tags = map { "tags/".$_ } @$dsc_hint_tag;
2913         my $lrf = $do_fetch->("additional commits", @tags) &&
2914             defined git_cat_file $dsc_hash
2915             or fail <<END;
2916 .dsc Dgit metadata requires commit $dsc_hash
2917 but we could not obtain that object anywhere.
2918 END
2919         foreach my $t (@tags) {
2920             my $fullrefname = $lrf.'/'.$t;
2921 #           print STDERR "CHK $t $fullrefname ".Dumper(\%lrfetchrefs_f);
2922             next unless $lrfetchrefs_f{$fullrefname};
2923             next unless is_fast_fwd "$fullrefname~0", $dsc_hash;
2924             lrfetchref_used $fullrefname;
2925         }
2926     }
2927 }
2928
2929 sub fetch_from_archive () {
2930     ensure_setup_existing_tree();
2931
2932     # Ensures that lrref() is what is actually in the archive, one way
2933     # or another, according to us - ie this client's
2934     # appropritaely-updated archive view.  Also returns the commit id.
2935     # If there is nothing in the archive, leaves lrref alone and
2936     # returns undef.  git_fetch_us must have already been called.
2937     get_archive_dsc();
2938
2939     if ($dsc) {
2940         parse_dsc_field($dsc, 'last upload to archive');
2941         resolve_dsc_field_commit access_basedistro,
2942             lrfetchrefs."/".$rewritemap
2943     } else {
2944         progress "no version available from the archive";
2945     }
2946
2947     # If the archive's .dsc has a Dgit field, there are three
2948     # relevant git commitids we need to choose between and/or merge
2949     # together:
2950     #   1. $dsc_hash: the Dgit field from the archive
2951     #   2. $lastpush_hash: the suite branch on the dgit git server
2952     #   3. $lastfetch_hash: our local tracking brach for the suite
2953     #
2954     # These may all be distinct and need not be in any fast forward
2955     # relationship:
2956     #
2957     # If the dsc was pushed to this suite, then the server suite
2958     # branch will have been updated; but it might have been pushed to
2959     # a different suite and copied by the archive.  Conversely a more
2960     # recent version may have been pushed with dgit but not appeared
2961     # in the archive (yet).
2962     #
2963     # $lastfetch_hash may be awkward because archive imports
2964     # (particularly, imports of Dgit-less .dscs) are performed only as
2965     # needed on individual clients, so different clients may perform a
2966     # different subset of them - and these imports are only made
2967     # public during push.  So $lastfetch_hash may represent a set of
2968     # imports different to a subsequent upload by a different dgit
2969     # client.
2970     #
2971     # Our approach is as follows:
2972     #
2973     # As between $dsc_hash and $lastpush_hash: if $lastpush_hash is a
2974     # descendant of $dsc_hash, then it was pushed by a dgit user who
2975     # had based their work on $dsc_hash, so we should prefer it.
2976     # Otherwise, $dsc_hash was installed into this suite in the
2977     # archive other than by a dgit push, and (necessarily) after the
2978     # last dgit push into that suite (since a dgit push would have
2979     # been descended from the dgit server git branch); thus, in that
2980     # case, we prefer the archive's version (and produce a
2981     # pseudo-merge to overwrite the dgit server git branch).
2982     #
2983     # (If there is no Dgit field in the archive's .dsc then
2984     # generate_commit_from_dsc uses the version numbers to decide
2985     # whether the suite branch or the archive is newer.  If the suite
2986     # branch is newer it ignores the archive's .dsc; otherwise it
2987     # generates an import of the .dsc, and produces a pseudo-merge to
2988     # overwrite the suite branch with the archive contents.)
2989     #
2990     # The outcome of that part of the algorithm is the `public view',
2991     # and is same for all dgit clients: it does not depend on any
2992     # unpublished history in the local tracking branch.
2993     #
2994     # As between the public view and the local tracking branch: The
2995     # local tracking branch is only updated by dgit fetch, and
2996     # whenever dgit fetch runs it includes the public view in the
2997     # local tracking branch.  Therefore if the public view is not
2998     # descended from the local tracking branch, the local tracking
2999     # branch must contain history which was imported from the archive
3000     # but never pushed; and, its tip is now out of date.  So, we make
3001     # a pseudo-merge to overwrite the old imports and stitch the old
3002     # history in.
3003     #
3004     # Finally: we do not necessarily reify the public view (as
3005     # described above).  This is so that we do not end up stacking two
3006     # pseudo-merges.  So what we actually do is figure out the inputs
3007     # to any public view pseudo-merge and put them in @mergeinputs.
3008
3009     my @mergeinputs;
3010     # $mergeinputs[]{Commit}
3011     # $mergeinputs[]{Info}
3012     # $mergeinputs[0] is the one whose tree we use
3013     # @mergeinputs is in the order we use in the actual commit)
3014     #
3015     # Also:
3016     # $mergeinputs[]{Message} is a commit message to use
3017     # $mergeinputs[]{ReverseParents} if def specifies that parent
3018     #                                list should be in opposite order
3019     # Such an entry has no Commit or Info.  It applies only when found
3020     # in the last entry.  (This ugliness is to support making
3021     # identical imports to previous dgit versions.)
3022
3023     my $lastpush_hash = git_get_ref(lrfetchref());
3024     printdebug "previous reference hash=$lastpush_hash\n";
3025     $lastpush_mergeinput = $lastpush_hash && {
3026         Commit => $lastpush_hash,
3027         Info => "dgit suite branch on dgit git server",
3028     };
3029
3030     my $lastfetch_hash = git_get_ref(lrref());
3031     printdebug "fetch_from_archive: lastfetch=$lastfetch_hash\n";
3032     my $lastfetch_mergeinput = $lastfetch_hash && {
3033         Commit => $lastfetch_hash,
3034         Info => "dgit client's archive history view",
3035     };
3036
3037     my $dsc_mergeinput = $dsc_hash && {
3038         Commit => $dsc_hash,
3039         Info => "Dgit field in .dsc from archive",
3040     };
3041
3042     my $cwd = getcwd();
3043     my $del_lrfetchrefs = sub {
3044         changedir $cwd;
3045         my $gur;
3046         printdebug "del_lrfetchrefs...\n";
3047         foreach my $fullrefname (sort keys %lrfetchrefs_d) {
3048             my $objid = $lrfetchrefs_d{$fullrefname};
3049             printdebug "del_lrfetchrefs: $objid $fullrefname\n";
3050             if (!$gur) {
3051                 $gur ||= new IO::Handle;
3052                 open $gur, "|-", qw(git update-ref --stdin) or die $!;
3053             }
3054             printf $gur "delete %s %s\n", $fullrefname, $objid;
3055         }
3056         if ($gur) {
3057             close $gur or failedcmd "git update-ref delete lrfetchrefs";
3058         }
3059     };
3060
3061     if (defined $dsc_hash) {
3062         ensure_we_have_orig();
3063         if (!$lastpush_hash || $dsc_hash eq $lastpush_hash) {
3064             @mergeinputs = $dsc_mergeinput
3065         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
3066             print STDERR <<END or die $!;
3067
3068 Git commit in archive is behind the last version allegedly pushed/uploaded.
3069 Commit referred to by archive: $dsc_hash
3070 Last version pushed with dgit: $lastpush_hash
3071 $later_warning_msg
3072 END
3073             @mergeinputs = ($lastpush_mergeinput);
3074         } else {
3075             # Archive has .dsc which is not a descendant of the last dgit
3076             # push.  This can happen if the archive moves .dscs about.
3077             # Just follow its lead.
3078             if (is_fast_fwd($lastpush_hash,$dsc_hash)) {
3079                 progress "archive .dsc names newer git commit";
3080                 @mergeinputs = ($dsc_mergeinput);
3081             } else {
3082                 progress "archive .dsc names other git commit, fixing up";
3083                 @mergeinputs = ($dsc_mergeinput, $lastpush_mergeinput);
3084             }
3085         }
3086     } elsif ($dsc) {
3087         @mergeinputs = generate_commits_from_dsc();
3088         # We have just done an import.  Now, our import algorithm might
3089         # have been improved.  But even so we do not want to generate
3090         # a new different import of the same package.  So if the
3091         # version numbers are the same, just use our existing version.
3092         # If the version numbers are different, the archive has changed
3093         # (perhaps, rewound).
3094         if ($lastfetch_mergeinput &&
3095             !version_compare( (mergeinfo_version $lastfetch_mergeinput),
3096                               (mergeinfo_version $mergeinputs[0]) )) {
3097             @mergeinputs = ($lastfetch_mergeinput);
3098         }
3099     } elsif ($lastpush_hash) {
3100         # only in git, not in the archive yet
3101         @mergeinputs = ($lastpush_mergeinput);
3102         print STDERR <<END or die $!;
3103
3104 Package not found in the archive, but has allegedly been pushed using dgit.
3105 $later_warning_msg
3106 END
3107     } else {
3108         printdebug "nothing found!\n";
3109         if (defined $skew_warning_vsn) {
3110             print STDERR <<END or die $!;
3111
3112 Warning: relevant archive skew detected.
3113 Archive allegedly contains $skew_warning_vsn
3114 But we were not able to obtain any version from the archive or git.
3115
3116 END
3117         }
3118         unshift @end, $del_lrfetchrefs;
3119         return undef;
3120     }
3121
3122     if ($lastfetch_hash &&
3123         !grep {
3124             my $h = $_->{Commit};
3125             $h and is_fast_fwd($lastfetch_hash, $h);
3126             # If true, one of the existing parents of this commit
3127             # is a descendant of the $lastfetch_hash, so we'll
3128             # be ff from that automatically.
3129         } @mergeinputs
3130         ) {
3131         # Otherwise:
3132         push @mergeinputs, $lastfetch_mergeinput;
3133     }
3134
3135     printdebug "fetch mergeinfos:\n";
3136     foreach my $mi (@mergeinputs) {
3137         if ($mi->{Info}) {
3138             printdebug " commit $mi->{Commit} $mi->{Info}\n";
3139         } else {
3140             printdebug sprintf " ReverseParents=%d Message=%s",
3141                 $mi->{ReverseParents}, $mi->{Message};
3142         }
3143     }
3144
3145     my $compat_info= pop @mergeinputs
3146         if $mergeinputs[$#mergeinputs]{Message};
3147
3148     @mergeinputs = grep { defined $_->{Commit} } @mergeinputs;
3149
3150     my $hash;
3151     if (@mergeinputs > 1) {
3152         # here we go, then:
3153         my $tree_commit = $mergeinputs[0]{Commit};
3154
3155         my $tree = cmdoutput @git, qw(cat-file commit), $tree_commit;
3156         $tree =~ m/\n\n/;  $tree = $`;
3157         $tree =~ m/^tree (\w+)$/m or die "$dsc_hash tree ?";
3158         $tree = $1;
3159
3160         # We use the changelog author of the package in question the
3161         # author of this pseudo-merge.  This is (roughly) correct if
3162         # this commit is simply representing aa non-dgit upload.
3163         # (Roughly because it does not record sponsorship - but we
3164         # don't have sponsorship info because that's in the .changes,
3165         # which isn't in the archivw.)
3166         #
3167         # But, it might be that we are representing archive history
3168         # updates (including in-archive copies).  These are not really
3169         # the responsibility of the person who created the .dsc, but
3170         # there is no-one whose name we should better use.  (The
3171         # author of the .dsc-named commit is clearly worse.)
3172
3173         my $useclogp = mergeinfo_getclogp $mergeinputs[0];
3174         my $author = clogp_authline $useclogp;
3175         my $cversion = getfield $useclogp, 'Version';
3176
3177         my $mcf = ".git/dgit/mergecommit";
3178         open MC, ">", $mcf or die "$mcf $!";
3179         print MC <<END or die $!;
3180 tree $tree
3181 END
3182
3183         my @parents = grep { $_->{Commit} } @mergeinputs;
3184         @parents = reverse @parents if $compat_info->{ReverseParents};
3185         print MC <<END or die $! foreach @parents;
3186 parent $_->{Commit}
3187 END
3188
3189         print MC <<END or die $!;
3190 author $author
3191 committer $author
3192
3193 END
3194
3195         if (defined $compat_info->{Message}) {
3196             print MC $compat_info->{Message} or die $!;
3197         } else {
3198             print MC <<END or die $!;
3199 Record $package ($cversion) in archive suite $csuite
3200
3201 Record that
3202 END
3203             my $message_add_info = sub {
3204                 my ($mi) = (@_);
3205                 my $mversion = mergeinfo_version $mi;
3206                 printf MC "  %-20s %s\n", $mversion, $mi->{Info}
3207                     or die $!;
3208             };
3209
3210             $message_add_info->($mergeinputs[0]);
3211             print MC <<END or die $!;
3212 should be treated as descended from
3213 END
3214             $message_add_info->($_) foreach @mergeinputs[1..$#mergeinputs];
3215         }
3216
3217         close MC or die $!;
3218         $hash = make_commit $mcf;
3219     } else {
3220         $hash = $mergeinputs[0]{Commit};
3221     }
3222     printdebug "fetch hash=$hash\n";
3223
3224     my $chkff = sub {
3225         my ($lasth, $what) = @_;
3226         return unless $lasth;
3227         die "$lasth $hash $what ?" unless is_fast_fwd($lasth, $hash);
3228     };
3229
3230     $chkff->($lastpush_hash, 'dgit repo server tip (last push)')
3231         if $lastpush_hash;
3232     $chkff->($lastfetch_hash, 'local tracking tip (last fetch)');
3233
3234     fetch_from_archive_record_1($hash);
3235
3236     if (defined $skew_warning_vsn) {
3237         mkpath '.git/dgit';
3238         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
3239         my $gotclogp = commit_getclogp($hash);
3240         my $got_vsn = getfield $gotclogp, 'Version';
3241         printdebug "SKEW CHECK GOT $got_vsn\n";
3242         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
3243             print STDERR <<END or die $!;
3244
3245 Warning: archive skew detected.  Using the available version:
3246 Archive allegedly contains    $skew_warning_vsn
3247 We were able to obtain only   $got_vsn
3248
3249 END
3250         }
3251     }
3252
3253     if ($lastfetch_hash ne $hash) {
3254         fetch_from_archive_record_2($hash);
3255     }
3256
3257     lrfetchref_used lrfetchref();
3258
3259     unshift @end, $del_lrfetchrefs;
3260     return $hash;
3261 }
3262
3263 sub set_local_git_config ($$) {
3264     my ($k, $v) = @_;
3265     runcmd @git, qw(config), $k, $v;
3266 }
3267
3268 sub setup_mergechangelogs (;$) {
3269     my ($always) = @_;
3270     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
3271
3272     my $driver = 'dpkg-mergechangelogs';
3273     my $cb = "merge.$driver";
3274     my $attrs = '.git/info/attributes';
3275     ensuredir '.git/info';
3276
3277     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
3278     if (!open ATTRS, "<", $attrs) {
3279         $!==ENOENT or die "$attrs: $!";
3280     } else {
3281         while (<ATTRS>) {
3282             chomp;
3283             next if m{^debian/changelog\s};
3284             print NATTRS $_, "\n" or die $!;
3285         }
3286         ATTRS->error and die $!;
3287         close ATTRS;
3288     }
3289     print NATTRS "debian/changelog merge=$driver\n" or die $!;
3290     close NATTRS;
3291
3292     set_local_git_config "$cb.name", 'debian/changelog merge driver';
3293     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
3294
3295     rename "$attrs.new", "$attrs" or die "$attrs: $!";
3296 }
3297
3298 sub setup_useremail (;$) {
3299     my ($always) = @_;
3300     return unless $always || access_cfg_bool(1, 'setup-useremail');
3301
3302     my $setup = sub {
3303         my ($k, $envvar) = @_;
3304         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
3305         return unless defined $v;
3306         set_local_git_config "user.$k", $v;
3307     };
3308
3309     $setup->('email', 'DEBEMAIL');
3310     $setup->('name', 'DEBFULLNAME');
3311 }
3312
3313 sub ensure_setup_existing_tree () {
3314     my $k = "remote.$remotename.skipdefaultupdate";
3315     my $c = git_get_config $k;
3316     return if defined $c;
3317     set_local_git_config $k, 'true';
3318 }
3319
3320 sub open_gitattrs () {
3321     my $gai = new IO::File ".git/info/attributes"
3322         or $!==ENOENT
3323         or die "open .git/info/attributes: $!";
3324     return $gai;
3325 }
3326
3327 sub is_gitattrs_setup () {
3328     my $gai = open_gitattrs();
3329     return 0 unless $gai;
3330     while (<$gai>) {
3331         return 1 if m{^\[attr\]dgit-defuse-attrs\s};
3332     }
3333     $gai->error and die $!;
3334     return 0;
3335 }
3336
3337 sub setup_gitattrs (;$) {
3338     my ($always) = @_;
3339     return unless $always || access_cfg_bool(1, 'setup-gitattributes');
3340
3341     if (is_gitattrs_setup()) {
3342         progress <<END;
3343 [attr]dgit-defuse-attrs already found in .git/info/attributes
3344  not doing further gitattributes setup
3345 END
3346         return;
3347     }
3348     my $af = ".git/info/attributes";
3349     open GAO, "> $af.new" or die $!;
3350     print GAO <<END or die $!;
3351 *       dgit-defuse-attrs
3352 [attr]dgit-defuse-attrs -text -eol -crlf -ident -filter
3353 # ^ see dgit(7).  To undo, leave a definition of [attr]dgit-defuse-attrs
3354 END
3355     my $gai = open_gitattrs();
3356     if ($gai) {
3357         while (<$gai>) {
3358             chomp;
3359             print GAO $_, "\n" or die $!;
3360         }
3361         $gai->error and die $!;
3362     }
3363     close GAO or die $!;
3364     rename "$af.new", "$af" or die "install $af: $!";
3365 }
3366
3367 sub setup_new_tree () {
3368     setup_mergechangelogs();
3369     setup_useremail();
3370 }
3371
3372 sub multisuite_suite_child ($$$) {
3373     my ($tsuite, $merginputs, $fn) = @_;
3374     # in child, sets things up, calls $fn->(), and returns undef
3375     # in parent, returns canonical suite name for $tsuite
3376     my $canonsuitefh = IO::File::new_tmpfile;
3377     my $pid = fork // die $!;
3378     if (!$pid) {
3379         forkcheck_setup();
3380         $isuite = $tsuite;
3381         $us .= " [$isuite]";
3382         $debugprefix .= " ";
3383         progress "fetching $tsuite...";
3384         canonicalise_suite();
3385         print $canonsuitefh $csuite, "\n" or die $!;
3386         close $canonsuitefh or die $!;
3387         $fn->();
3388         return undef;
3389     }
3390     waitpid $pid,0 == $pid or die $!;
3391     fail "failed to obtain $tsuite: ".waitstatusmsg() if $? && $?!=256*4;
3392     seek $canonsuitefh,0,0 or die $!;
3393     local $csuite = <$canonsuitefh>;
3394     die $! unless defined $csuite && chomp $csuite;
3395     if ($? == 256*4) {
3396         printdebug "multisuite $tsuite missing\n";
3397         return $csuite;
3398     }
3399     printdebug "multisuite $tsuite ok (canon=$csuite)\n";
3400     push @$merginputs, {
3401         Ref => lrref,
3402         Info => $csuite,
3403     };
3404     return $csuite;
3405 }
3406
3407 sub fork_for_multisuite ($) {
3408     my ($before_fetch_merge) = @_;
3409     # if nothing unusual, just returns ''
3410     #
3411     # if multisuite:
3412     # returns 0 to caller in child, to do first of the specified suites
3413     # in child, $csuite is not yet set
3414     #
3415     # returns 1 to caller in parent, to finish up anything needed after
3416     # in parent, $csuite is set to canonicalised portmanteau
3417
3418     my $org_isuite = $isuite;
3419     my @suites = split /\,/, $isuite;
3420     return '' unless @suites > 1;
3421     printdebug "fork_for_multisuite: @suites\n";
3422
3423     my @mergeinputs;
3424
3425     my $cbasesuite = multisuite_suite_child($suites[0], \@mergeinputs,
3426                                             sub { });
3427     return 0 unless defined $cbasesuite;
3428
3429     fail "package $package missing in (base suite) $cbasesuite"
3430         unless @mergeinputs;
3431
3432     my @csuites = ($cbasesuite);
3433
3434     $before_fetch_merge->();
3435
3436     foreach my $tsuite (@suites[1..$#suites]) {
3437         my $csubsuite = multisuite_suite_child($tsuite, \@mergeinputs,
3438                                                sub {
3439             @end = ();
3440             fetch();
3441             exit 0;
3442         });
3443         # xxx collecte the ref here
3444
3445         $csubsuite =~ s/^\Q$cbasesuite\E-/-/;
3446         push @csuites, $csubsuite;
3447     }
3448
3449     foreach my $mi (@mergeinputs) {
3450         my $ref = git_get_ref $mi->{Ref};
3451         die "$mi->{Ref} ?" unless length $ref;
3452         $mi->{Commit} = $ref;
3453     }
3454
3455     $csuite = join ",", @csuites;
3456
3457     my $previous = git_get_ref lrref;
3458     if ($previous) {
3459         unshift @mergeinputs, {
3460             Commit => $previous,
3461             Info => "local combined tracking branch",
3462             Warning =>
3463  "archive seems to have rewound: local tracking branch is ahead!",
3464         };
3465     }
3466
3467     foreach my $ix (0..$#mergeinputs) {
3468         $mergeinputs[$ix]{Index} = $ix;
3469     }
3470
3471     @mergeinputs = sort {
3472         -version_compare(mergeinfo_version $a,
3473                          mergeinfo_version $b) # highest version first
3474             or
3475         $a->{Index} <=> $b->{Index}; # earliest in spec first
3476     } @mergeinputs;
3477
3478     my @needed;
3479
3480   NEEDED:
3481     foreach my $mi (@mergeinputs) {
3482         printdebug "multisuite merge check $mi->{Info}\n";
3483         foreach my $previous (@needed) {
3484             next unless is_fast_fwd $mi->{Commit}, $previous->{Commit};
3485             printdebug "multisuite merge un-needed $previous->{Info}\n";
3486             next NEEDED;
3487         }
3488         push @needed, $mi;
3489         printdebug "multisuite merge this-needed\n";
3490         $mi->{Character} = '+';
3491     }
3492
3493     $needed[0]{Character} = '*';
3494
3495     my $output = $needed[0]{Commit};
3496
3497     if (@needed > 1) {
3498         printdebug "multisuite merge nontrivial\n";
3499         my $tree = cmdoutput qw(git rev-parse), $needed[0]{Commit}.':';
3500
3501         my $commit = "tree $tree\n";
3502         my $msg = "Combine archive branches $csuite [dgit]\n\n".
3503             "Input branches:\n";
3504
3505         foreach my $mi (sort { $a->{Index} <=> $b->{Index} } @mergeinputs) {
3506             printdebug "multisuite merge include $mi->{Info}\n";
3507             $mi->{Character} //= ' ';
3508             $commit .= "parent $mi->{Commit}\n";
3509             $msg .= sprintf " %s  %-25s %s\n",
3510                 $mi->{Character},
3511                 (mergeinfo_version $mi),
3512                 $mi->{Info};
3513         }
3514         my $authline = clogp_authline mergeinfo_getclogp $needed[0];
3515         $msg .= "\nKey\n".
3516             " * marks the highest version branch, which choose to use\n".
3517             " + marks each branch which was not already an ancestor\n\n".
3518             "[dgit multi-suite $csuite]\n";
3519         $commit .=
3520             "author $authline\n".
3521             "committer $authline\n\n";
3522         $output = make_commit_text $commit.$msg;
3523         printdebug "multisuite merge generated $output\n";
3524     }
3525
3526     fetch_from_archive_record_1($output);
3527     fetch_from_archive_record_2($output);
3528
3529     progress "calculated combined tracking suite $csuite";
3530
3531     return 1;
3532 }
3533
3534 sub clone_set_head () {
3535     open H, "> .git/HEAD" or die $!;
3536     print H "ref: ".lref()."\n" or die $!;
3537     close H or die $!;
3538 }
3539 sub clone_finish ($) {
3540     my ($dstdir) = @_;
3541     runcmd @git, qw(reset --hard), lrref();
3542     runcmd qw(bash -ec), <<'END';
3543         set -o pipefail
3544         git ls-tree -r --name-only -z HEAD | \
3545         xargs -0r touch -h -r . --
3546 END
3547     printdone "ready for work in $dstdir";
3548 }
3549
3550 sub clone ($) {
3551     my ($dstdir) = @_;
3552     badusage "dry run makes no sense with clone" unless act_local();
3553
3554     my $multi_fetched = fork_for_multisuite(sub {
3555         printdebug "multi clone before fetch merge\n";
3556         changedir $dstdir;
3557     });
3558     if ($multi_fetched) {
3559         printdebug "multi clone after fetch merge\n";
3560         clone_set_head();
3561         clone_finish($dstdir);
3562         exit 0;
3563     }
3564     printdebug "clone main body\n";
3565
3566     canonicalise_suite();
3567     my $hasgit = check_for_git();
3568     mkdir $dstdir or fail "create \`$dstdir': $!";
3569     changedir $dstdir;
3570     runcmd @git, qw(init -q);
3571     clone_set_head();
3572     my $giturl = access_giturl(1);
3573     if (defined $giturl) {
3574         runcmd @git, qw(remote add), 'origin', $giturl;
3575     }
3576     if ($hasgit) {
3577         progress "fetching existing git history";
3578         git_fetch_us();
3579         runcmd_ordryrun_local @git, qw(fetch origin);
3580     } else {
3581         progress "starting new git history";
3582     }
3583     fetch_from_archive() or no_such_package;
3584     my $vcsgiturl = $dsc->{'Vcs-Git'};
3585     if (length $vcsgiturl) {
3586         $vcsgiturl =~ s/\s+-b\s+\S+//g;
3587         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
3588     }
3589     setup_new_tree();
3590     clone_finish($dstdir);
3591 }
3592
3593 sub fetch () {
3594     canonicalise_suite();
3595     if (check_for_git()) {
3596         git_fetch_us();
3597     }
3598     fetch_from_archive() or no_such_package();
3599     printdone "fetched into ".lrref();
3600 }
3601
3602 sub pull () {
3603     my $multi_fetched = fork_for_multisuite(sub { });
3604     fetch() unless $multi_fetched; # parent
3605     return if $multi_fetched eq '0'; # child
3606     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
3607         lrref();
3608     printdone "fetched to ".lrref()." and merged into HEAD";
3609 }
3610
3611 sub check_not_dirty () {
3612     foreach my $f (qw(local-options local-patch-header)) {
3613         if (stat_exists "debian/source/$f") {
3614             fail "git tree contains debian/source/$f";
3615         }
3616     }
3617
3618     return if $ignoredirty;
3619
3620     my @cmd = (@git, qw(diff --quiet HEAD));
3621     debugcmd "+",@cmd;
3622     $!=0; $?=-1; system @cmd;
3623     return if !$?;
3624     if ($?==256) {
3625         fail "working tree is dirty (does not match HEAD)";
3626     } else {
3627         failedcmd @cmd;
3628     }
3629 }
3630
3631 sub commit_admin ($) {
3632     my ($m) = @_;
3633     progress "$m";
3634     runcmd_ordryrun_local @git, qw(commit -m), $m;
3635 }
3636
3637 sub commit_quilty_patch () {
3638     my $output = cmdoutput @git, qw(status --porcelain);
3639     my %adds;
3640     foreach my $l (split /\n/, $output) {
3641         next unless $l =~ m/\S/;
3642         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
3643             $adds{$1}++;
3644         }
3645     }
3646     delete $adds{'.pc'}; # if there wasn't one before, don't add it
3647     if (!%adds) {
3648         progress "nothing quilty to commit, ok.";
3649         return;
3650     }
3651     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
3652     runcmd_ordryrun_local @git, qw(add -f), @adds;
3653     commit_admin <<END
3654 Commit Debian 3.0 (quilt) metadata
3655
3656 [dgit ($our_version) quilt-fixup]
3657 END
3658 }
3659
3660 sub get_source_format () {
3661     my %options;
3662     if (open F, "debian/source/options") {
3663         while (<F>) {
3664             next if m/^\s*\#/;
3665             next unless m/\S/;
3666             s/\s+$//; # ignore missing final newline
3667             if (m/\s*\#\s*/) {
3668                 my ($k, $v) = ($`, $'); #');
3669                 $v =~ s/^"(.*)"$/$1/;
3670                 $options{$k} = $v;
3671             } else {
3672                 $options{$_} = 1;
3673             }
3674         }
3675         F->error and die $!;
3676         close F;
3677     } else {
3678         die $! unless $!==&ENOENT;
3679     }
3680
3681     if (!open F, "debian/source/format") {
3682         die $! unless $!==&ENOENT;
3683         return '';
3684     }
3685     $_ = <F>;
3686     F->error and die $!;
3687     chomp;
3688     return ($_, \%options);
3689 }
3690
3691 sub madformat_wantfixup ($) {
3692     my ($format) = @_;
3693     return 0 unless $format eq '3.0 (quilt)';
3694     our $quilt_mode_warned;
3695     if ($quilt_mode eq 'nocheck') {
3696         progress "Not doing any fixup of \`$format' due to".
3697             " ----no-quilt-fixup or --quilt=nocheck"
3698             unless $quilt_mode_warned++;
3699         return 0;
3700     }
3701     progress "Format \`$format', need to check/update patch stack"
3702         unless $quilt_mode_warned++;
3703     return 1;
3704 }
3705
3706 sub maybe_split_brain_save ($$$) {
3707     my ($headref, $dgitview, $msg) = @_;
3708     # => message fragment "$saved" describing disposition of $dgitview
3709     return "commit id $dgitview" unless defined $split_brain_save;
3710     my @cmd = (shell_cmd "cd ../../../..",
3711                @git, qw(update-ref -m),
3712                "dgit --dgit-view-save $msg HEAD=$headref",
3713                $split_brain_save, $dgitview);
3714     runcmd @cmd;
3715     return "and left in $split_brain_save";
3716 }
3717
3718 # An "infopair" is a tuple [ $thing, $what ]
3719 # (often $thing is a commit hash; $what is a description)
3720
3721 sub infopair_cond_equal ($$) {
3722     my ($x,$y) = @_;
3723     $x->[0] eq $y->[0] or fail <<END;
3724 $x->[1] ($x->[0]) not equal to $y->[1] ($y->[0])
3725 END
3726 };
3727
3728 sub infopair_lrf_tag_lookup ($$) {
3729     my ($tagnames, $what) = @_;
3730     # $tagname may be an array ref
3731     my @tagnames = ref $tagnames ? @$tagnames : ($tagnames);
3732     printdebug "infopair_lrfetchref_tag_lookup $what @tagnames\n";
3733     foreach my $tagname (@tagnames) {
3734         my $lrefname = lrfetchrefs."/tags/$tagname";
3735         my $tagobj = $lrfetchrefs_f{$lrefname};
3736         next unless defined $tagobj;
3737         printdebug "infopair_lrfetchref_tag_lookup $tagobj $tagname $what\n";
3738         return [ git_rev_parse($tagobj), $what ];
3739     }
3740     fail @tagnames==1 ? <<END : <<END;
3741 Wanted tag $what (@tagnames) on dgit server, but not found
3742 END
3743 Wanted tag $what (one of: @tagnames) on dgit server, but not found
3744 END
3745 }
3746
3747 sub infopair_cond_ff ($$) {
3748     my ($anc,$desc) = @_;
3749     is_fast_fwd($anc->[0], $desc->[0]) or fail <<END;
3750 $anc->[1] ($anc->[0]) .. $desc->[1] ($desc->[0]) is not fast forward
3751 END
3752 };
3753
3754 sub pseudomerge_version_check ($$) {
3755     my ($clogp, $archive_hash) = @_;
3756
3757     my $arch_clogp = commit_getclogp $archive_hash;
3758     my $i_arch_v = [ (getfield $arch_clogp, 'Version'),
3759                      'version currently in archive' ];
3760     if (defined $overwrite_version) {
3761         if (length $overwrite_version) {
3762             infopair_cond_equal([ $overwrite_version,
3763                                   '--overwrite= version' ],
3764                                 $i_arch_v);
3765         } else {
3766             my $v = $i_arch_v->[0];
3767             progress "Checking package changelog for archive version $v ...";
3768             eval {
3769                 my @xa = ("-f$v", "-t$v");
3770                 my $vclogp = parsechangelog @xa;
3771                 my $cv = [ (getfield $vclogp, 'Version'),
3772                            "Version field from dpkg-parsechangelog @xa" ];
3773                 infopair_cond_equal($i_arch_v, $cv);
3774             };
3775             if ($@) {
3776                 $@ =~ s/^dgit: //gm;
3777                 fail "$@".
3778                     "Perhaps debian/changelog does not mention $v ?";
3779             }
3780         }
3781     }
3782
3783     printdebug "pseudomerge_version_check i_arch_v @$i_arch_v\n";
3784     return $i_arch_v;
3785 }
3786
3787 sub pseudomerge_make_commit ($$$$ $$) {
3788     my ($clogp, $dgitview, $archive_hash, $i_arch_v,
3789         $msg_cmd, $msg_msg) = @_;
3790     progress "Declaring that HEAD inciudes all changes in $i_arch_v->[0]...";
3791
3792     my $tree = cmdoutput qw(git rev-parse), "${dgitview}:";
3793     my $authline = clogp_authline $clogp;
3794
3795     chomp $msg_msg;
3796     $msg_cmd .=
3797         !defined $overwrite_version ? ""
3798         : !length  $overwrite_version ? " --overwrite"
3799         : " --overwrite=".$overwrite_version;
3800
3801     mkpath '.git/dgit';
3802     my $pmf = ".git/dgit/pseudomerge";
3803     open MC, ">", $pmf or die "$pmf $!";
3804     print MC <<END or die $!;
3805 tree $tree
3806 parent $dgitview
3807 parent $archive_hash
3808 author $authline
3809 committer $authline
3810
3811 $msg_msg
3812
3813 [$msg_cmd]
3814 END
3815     close MC or die $!;
3816
3817     return make_commit($pmf);
3818 }
3819
3820 sub splitbrain_pseudomerge ($$$$) {
3821     my ($clogp, $maintview, $dgitview, $archive_hash) = @_;
3822     # => $merged_dgitview
3823     printdebug "splitbrain_pseudomerge...\n";
3824     #
3825     #     We:      debian/PREVIOUS    HEAD($maintview)
3826     # expect:          o ----------------- o
3827     #                    \                   \
3828     #                     o                   o
3829     #                 a/d/PREVIOUS        $dgitview
3830     #                $archive_hash              \
3831     #  If so,                \                   \
3832     #  we do:                 `------------------ o
3833     #   this:                                   $dgitview'
3834     #
3835
3836     return $dgitview unless defined $archive_hash;
3837
3838     printdebug "splitbrain_pseudomerge...\n";
3839
3840     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3841
3842     if (!defined $overwrite_version) {
3843         progress "Checking that HEAD inciudes all changes in archive...";
3844     }
3845
3846     return $dgitview if is_fast_fwd $archive_hash, $dgitview;
3847
3848     if (defined $overwrite_version) {
3849     } elsif (!eval {
3850         my $t_dep14 = debiantag_maintview $i_arch_v->[0], access_nomdistro;
3851         my $i_dep14 = infopair_lrf_tag_lookup($t_dep14, "maintainer view tag");
3852         my $t_dgit = debiantag_new $i_arch_v->[0], access_nomdistro;
3853         my $i_dgit = infopair_lrf_tag_lookup($t_dgit, "dgit view tag");
3854         my $i_archive = [ $archive_hash, "current archive contents" ];
3855
3856         printdebug "splitbrain_pseudomerge i_archive @$i_archive\n";
3857
3858         infopair_cond_equal($i_dgit, $i_archive);
3859         infopair_cond_ff($i_dep14, $i_dgit);
3860         infopair_cond_ff($i_dep14, [ $maintview, 'HEAD' ]);
3861         1;
3862     }) {
3863         print STDERR <<END;
3864 $us: check failed (maybe --overwrite is needed, consult documentation)
3865 END
3866         die "$@";
3867     }
3868
3869     my $r = pseudomerge_make_commit
3870         $clogp, $dgitview, $archive_hash, $i_arch_v,
3871         "dgit --quilt=$quilt_mode",
3872         (defined $overwrite_version ? <<END_OVERWR : <<END_MAKEFF);
3873 Declare fast forward from $i_arch_v->[0]
3874 END_OVERWR
3875 Make fast forward from $i_arch_v->[0]
3876 END_MAKEFF
3877
3878     maybe_split_brain_save $maintview, $r, "pseudomerge";
3879
3880     progress "Made pseudo-merge of $i_arch_v->[0] into dgit view.";
3881     return $r;
3882 }
3883
3884 sub plain_overwrite_pseudomerge ($$$) {
3885     my ($clogp, $head, $archive_hash) = @_;
3886
3887     printdebug "plain_overwrite_pseudomerge...";
3888
3889     my $i_arch_v = pseudomerge_version_check($clogp, $archive_hash);
3890
3891     return $head if is_fast_fwd $archive_hash, $head;
3892
3893     my $m = "Declare fast forward from $i_arch_v->[0]";
3894
3895     my $r = pseudomerge_make_commit
3896         $clogp, $head, $archive_hash, $i_arch_v,
3897         "dgit", $m;
3898
3899     runcmd @git, qw(update-ref -m), $m, 'HEAD', $r, $head;
3900
3901     progress "Make pseudo-merge of $i_arch_v->[0] into your HEAD.";
3902     return $r;
3903 }
3904
3905 sub push_parse_changelog ($) {
3906     my ($clogpfn) = @_;
3907
3908     my $clogp = Dpkg::Control::Hash->new();
3909     $clogp->load($clogpfn) or die;
3910
3911     my $clogpackage = getfield $clogp, 'Source';
3912     $package //= $clogpackage;
3913     fail "-p specified $package but changelog specified $clogpackage"
3914         unless $package eq $clogpackage;
3915     my $cversion = getfield $clogp, 'Version';
3916
3917     if (!$we_are_initiator) {
3918         # rpush initiator can't do this because it doesn't have $isuite yet
3919         my $tag = debiantag($cversion, access_nomdistro);
3920         runcmd @git, qw(check-ref-format), $tag;
3921     }
3922
3923     my $dscfn = dscfn($cversion);
3924
3925     return ($clogp, $cversion, $dscfn);
3926 }
3927
3928 sub push_parse_dsc ($$$) {
3929     my ($dscfn,$dscfnwhat, $cversion) = @_;
3930     $dsc = parsecontrol($dscfn,$dscfnwhat);
3931     my $dversion = getfield $dsc, 'Version';
3932     my $dscpackage = getfield $dsc, 'Source';
3933     ($dscpackage eq $package && $dversion eq $cversion) or
3934         fail "$dscfn is for $dscpackage $dversion".
3935             " but debian/changelog is for $package $cversion";
3936 }
3937
3938 sub push_tagwants ($$$$) {
3939     my ($cversion, $dgithead, $maintviewhead, $tfbase) = @_;
3940     my @tagwants;
3941     push @tagwants, {
3942         TagFn => \&debiantag,
3943         Objid => $dgithead,
3944         TfSuffix => '',
3945         View => 'dgit',
3946     };
3947     if (defined $maintviewhead) {
3948         push @tagwants, {
3949             TagFn => \&debiantag_maintview,
3950             Objid => $maintviewhead,
3951             TfSuffix => '-maintview',
3952             View => 'maint',
3953         };
3954     } elsif ($dodep14tag eq 'no' ? 0
3955              : $dodep14tag eq 'want' ? access_cfg_tagformats_can_splitbrain
3956              : $dodep14tag eq 'always'
3957              ? (access_cfg_tagformats_can_splitbrain or fail <<END)
3958 --dep14tag-always (or equivalent in config) means server must support
3959  both "new" and "maint" tag formats, but config says it doesn't.
3960 END
3961             : die "$dodep14tag ?") {
3962         push @tagwants, {
3963             TagFn => \&debiantag_maintview,
3964             Objid => $dgithead,
3965             TfSuffix => '-dgit',
3966             View => 'dgit',
3967         };
3968     };
3969     foreach my $tw (@tagwants) {
3970         $tw->{Tag} = $tw->{TagFn}($cversion, access_nomdistro);
3971         $tw->{Tfn} = sub { $tfbase.$tw->{TfSuffix}.$_[0]; };
3972     }
3973     printdebug 'push_tagwants: ', Dumper(\@_, \@tagwants);
3974     return @tagwants;
3975 }
3976
3977 sub push_mktags ($$ $$ $) {
3978     my ($clogp,$dscfn,
3979         $changesfile,$changesfilewhat,
3980         $tagwants) = @_;
3981
3982     die unless $tagwants->[0]{View} eq 'dgit';
3983
3984     my $declaredistro = access_nomdistro();
3985     my $reader_giturl = do { local $access_forpush=0; access_giturl(); };
3986     $dsc->{$ourdscfield[0]} = join " ",
3987         $tagwants->[0]{Objid}, $declaredistro, $tagwants->[0]{Tag},
3988         $reader_giturl;
3989     $dsc->save("$dscfn.tmp") or die $!;
3990
3991     my $changes = parsecontrol($changesfile,$changesfilewhat);
3992     foreach my $field (qw(Source Distribution Version)) {
3993         $changes->{$field} eq $clogp->{$field} or
3994             fail "changes field $field \`$changes->{$field}'".
3995                 " does not match changelog \`$clogp->{$field}'";
3996     }
3997
3998     my $cversion = getfield $clogp, 'Version';
3999     my $clogsuite = getfield $clogp, 'Distribution';
4000
4001     # We make the git tag by hand because (a) that makes it easier
4002     # to control the "tagger" (b) we can do remote signing
4003     my $authline = clogp_authline $clogp;
4004     my $delibs = join(" ", "",@deliberatelies);
4005
4006     my $mktag = sub {
4007         my ($tw) = @_;
4008         my $tfn = $tw->{Tfn};
4009         my $head = $tw->{Objid};
4010         my $tag = $tw->{Tag};
4011
4012         open TO, '>', $tfn->('.tmp') or die $!;
4013         print TO <<END or die $!;
4014 object $head
4015 type commit
4016 tag $tag
4017 tagger $authline
4018
4019 END
4020         if ($tw->{View} eq 'dgit') {
4021             print TO <<END or die $!;
4022 $package release $cversion for $clogsuite ($csuite) [dgit]
4023 [dgit distro=$declaredistro$delibs]
4024 END
4025             foreach my $ref (sort keys %previously) {
4026                 print TO <<END or die $!;
4027 [dgit previously:$ref=$previously{$ref}]
4028 END
4029             }
4030         } elsif ($tw->{View} eq 'maint') {
4031             print TO <<END or die $!;
4032 $package release $cversion for $clogsuite ($csuite)
4033 (maintainer view tag generated by dgit --quilt=$quilt_mode)
4034 END
4035         } else {
4036             die Dumper($tw)."?";
4037         }
4038
4039         close TO or die $!;
4040
4041         my $tagobjfn = $tfn->('.tmp');
4042         if ($sign) {
4043             if (!defined $keyid) {
4044                 $keyid = access_cfg('keyid','RETURN-UNDEF');
4045             }
4046             if (!defined $keyid) {
4047                 $keyid = getfield $clogp, 'Maintainer';
4048             }
4049             unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
4050             my @sign_cmd = (@gpg, qw(--detach-sign --armor));
4051             push @sign_cmd, qw(-u),$keyid if defined $keyid;
4052             push @sign_cmd, $tfn->('.tmp');
4053             runcmd_ordryrun @sign_cmd;
4054             if (act_scary()) {
4055                 $tagobjfn = $tfn->('.signed.tmp');
4056                 runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
4057                     $tfn->('.tmp'), $tfn->('.tmp.asc');
4058             }
4059         }
4060         return $tagobjfn;
4061     };
4062
4063     my @r = map { $mktag->($_); } @$tagwants;
4064     return @r;
4065 }
4066
4067 sub sign_changes ($) {
4068     my ($changesfile) = @_;
4069     if ($sign) {
4070         my @debsign_cmd = @debsign;
4071         push @debsign_cmd, "-k$keyid" if defined $keyid;
4072         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
4073         push @debsign_cmd, $changesfile;
4074         runcmd_ordryrun @debsign_cmd;
4075     }
4076 }
4077
4078 sub dopush () {
4079     printdebug "actually entering push\n";
4080
4081     supplementary_message(<<'END');
4082 Push failed, while checking state of the archive.
4083 You can retry the push, after fixing the problem, if you like.
4084 END
4085     if (check_for_git()) {
4086         git_fetch_us();
4087     }
4088     my $archive_hash = fetch_from_archive();
4089     if (!$archive_hash) {
4090         $new_package or
4091             fail "package appears to be new in this suite;".
4092                 " if this is intentional, use --new";
4093     }
4094
4095     supplementary_message(<<'END');
4096 Push failed, while preparing your push.
4097 You can retry the push, after fixing the problem, if you like.
4098 END
4099
4100     need_tagformat 'new', "quilt mode $quilt_mode"
4101         if quiltmode_splitbrain;
4102
4103     prep_ud();
4104
4105     access_giturl(); # check that success is vaguely likely
4106     rpush_handle_protovsn_bothends() if $we_are_initiator;
4107     select_tagformat();
4108
4109     my $clogpfn = ".git/dgit/changelog.822.tmp";
4110     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
4111
4112     responder_send_file('parsed-changelog', $clogpfn);
4113
4114     my ($clogp, $cversion, $dscfn) =
4115         push_parse_changelog("$clogpfn");
4116
4117     my $dscpath = "$buildproductsdir/$dscfn";
4118     stat_exists $dscpath or
4119         fail "looked for .dsc $dscpath, but $!;".
4120             " maybe you forgot to build";
4121
4122     responder_send_file('dsc', $dscpath);
4123
4124     push_parse_dsc($dscpath, $dscfn, $cversion);
4125
4126     my $format = getfield $dsc, 'Format';
4127     printdebug "format $format\n";
4128
4129     my $actualhead = git_rev_parse('HEAD');
4130     my $dgithead = $actualhead;
4131     my $maintviewhead = undef;
4132
4133     my $upstreamversion = upstreamversion $clogp->{Version};
4134
4135     if (madformat_wantfixup($format)) {
4136         # user might have not used dgit build, so maybe do this now:
4137         if (quiltmode_splitbrain()) {
4138             changedir $ud;
4139             quilt_make_fake_dsc($upstreamversion);
4140             my $cachekey;
4141             ($dgithead, $cachekey) =
4142                 quilt_check_splitbrain_cache($actualhead, $upstreamversion);
4143             $dgithead or fail
4144  "--quilt=$quilt_mode but no cached dgit view:
4145  perhaps tree changed since dgit build[-source] ?";
4146             $split_brain = 1;
4147             $dgithead = splitbrain_pseudomerge($clogp,
4148                                                $actualhead, $dgithead,
4149                                                $archive_hash);
4150             $maintviewhead = $actualhead;
4151             changedir '../../../..';
4152             prep_ud(); # so _only_subdir() works, below
4153         } else {
4154             commit_quilty_patch();
4155         }
4156     }
4157
4158     if (defined $overwrite_version && !defined $maintviewhead) {
4159         $dgithead = plain_overwrite_pseudomerge($clogp,
4160                                                 $dgithead,
4161                                                 $archive_hash);
4162     }
4163
4164     check_not_dirty();
4165
4166     my $forceflag = '';
4167     if ($archive_hash) {
4168         if (is_fast_fwd($archive_hash, $dgithead)) {
4169             # ok
4170         } elsif (deliberately_not_fast_forward) {
4171             $forceflag = '+';
4172         } else {
4173             fail "dgit push: HEAD is not a descendant".
4174                 " of the archive's version.\n".
4175                 "To overwrite the archive's contents,".
4176                 " pass --overwrite[=VERSION].\n".
4177                 "To rewind history, if permitted by the archive,".
4178                 " use --deliberately-not-fast-forward.";
4179         }
4180     }
4181
4182     changedir $ud;
4183     progress "checking that $dscfn corresponds to HEAD";
4184     runcmd qw(dpkg-source -x --),
4185         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
4186     my ($tree,$dir) = mktree_in_ud_from_only_subdir("source package");
4187     check_for_vendor_patches() if madformat($dsc->{format});
4188     changedir '../../../..';
4189     my @diffcmd = (@git, qw(diff --quiet), $tree, $dgithead);
4190     debugcmd "+",@diffcmd;
4191     $!=0; $?=-1;
4192     my $r = system @diffcmd;
4193     if ($r) {
4194         if ($r==256) {
4195             my $diffs = cmdoutput @git, qw(diff --stat), $tree, $dgithead;
4196             fail <<END
4197 HEAD specifies a different tree to $dscfn:
4198 $diffs
4199 Perhaps you forgot to build.  Or perhaps there is a problem with your
4200  source tree (see dgit(7) for some hints).  To see a full diff, run
4201    git diff $tree HEAD
4202 END
4203         } else {
4204             failedcmd @diffcmd;
4205         }
4206     }
4207     if (!$changesfile) {
4208         my $pat = changespat $cversion;
4209         my @cs = glob "$buildproductsdir/$pat";
4210         fail "failed to find unique changes file".
4211             " (looked for $pat in $buildproductsdir);".
4212             " perhaps you need to use dgit -C"
4213             unless @cs==1;
4214         ($changesfile) = @cs;
4215     } else {
4216         $changesfile = "$buildproductsdir/$changesfile";
4217     }
4218
4219     # Check that changes and .dsc agree enough
4220     $changesfile =~ m{[^/]*$};
4221     my $changes = parsecontrol($changesfile,$&);
4222     files_compare_inputs($dsc, $changes)
4223         unless forceing [qw(dsc-changes-mismatch)];
4224
4225     # Perhaps adjust .dsc to contain right set of origs
4226     changes_update_origs_from_dsc($dsc, $changes, $upstreamversion,
4227                                   $changesfile)
4228         unless forceing [qw(changes-origs-exactly)];
4229
4230     # Checks complete, we're going to try and go ahead:
4231
4232     responder_send_file('changes',$changesfile);
4233     responder_send_command("param head $dgithead");
4234     responder_send_command("param csuite $csuite");
4235     responder_send_command("param isuite $isuite");
4236     responder_send_command("param tagformat $tagformat");
4237     if (defined $maintviewhead) {
4238         die unless ($protovsn//4) >= 4;
4239         responder_send_command("param maint-view $maintviewhead");
4240     }
4241
4242     if (deliberately_not_fast_forward) {
4243         git_for_each_ref(lrfetchrefs, sub {
4244             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
4245             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
4246             responder_send_command("previously $rrefname=$objid");
4247             $previously{$rrefname} = $objid;
4248         });
4249     }
4250
4251     my @tagwants = push_tagwants($cversion, $dgithead, $maintviewhead,
4252                                  ".git/dgit/tag");
4253     my @tagobjfns;
4254
4255     supplementary_message(<<'END');
4256 Push failed, while signing the tag.
4257 You can retry the push, after fixing the problem, if you like.
4258 END
4259     # If we manage to sign but fail to record it anywhere, it's fine.
4260     if ($we_are_responder) {
4261         @tagobjfns = map { $_->{Tfn}('.signed-tmp') } @tagwants;
4262         responder_receive_files('signed-tag', @tagobjfns);
4263     } else {
4264         @tagobjfns = push_mktags($clogp,$dscpath,
4265                               $changesfile,$changesfile,
4266                               \@tagwants);
4267     }
4268     supplementary_message(<<'END');
4269 Push failed, *after* signing the tag.
4270 If you want to try again, you should use a new version number.
4271 END
4272
4273     pairwise { $a->{TagObjFn} = $b } @tagwants, @tagobjfns;
4274
4275     foreach my $tw (@tagwants) {
4276         my $tag = $tw->{Tag};
4277         my $tagobjfn = $tw->{TagObjFn};
4278         my $tag_obj_hash =
4279             cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
4280         runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
4281         runcmd_ordryrun_local
4282             @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
4283     }
4284
4285     supplementary_message(<<'END');
4286 Push failed, while updating the remote git repository - see messages above.
4287 If you want to try again, you should use a new version number.
4288 END
4289     if (!check_for_git()) {
4290         create_remote_git_repo();
4291     }
4292
4293     my @pushrefs = $forceflag.$dgithead.":".rrref();
4294     foreach my $tw (@tagwants) {
4295         push @pushrefs, $forceflag."refs/tags/$tw->{Tag}";
4296     }
4297
4298     runcmd_ordryrun @git,
4299         qw(-c push.followTags=false push), access_giturl(), @pushrefs;
4300     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), $dgithead;
4301
4302     supplementary_message(<<'END');
4303 Push failed, while obtaining signatures on the .changes and .dsc.
4304 If it was just that the signature failed, you may try again by using
4305 debsign by hand to sign the changes
4306    $changesfile
4307 and then dput to complete the upload.
4308 If you need to change the package, you must use a new version number.
4309 END
4310     if ($we_are_responder) {
4311         my $dryrunsuffix = act_local() ? "" : ".tmp";
4312         responder_receive_files('signed-dsc-changes',
4313                                 "$dscpath$dryrunsuffix",
4314                                 "$changesfile$dryrunsuffix");
4315     } else {
4316         if (act_local()) {
4317             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
4318         } else {
4319             progress "[new .dsc left in $dscpath.tmp]";
4320         }
4321         sign_changes $changesfile;
4322     }
4323
4324     supplementary_message(<<END);
4325 Push failed, while uploading package(s) to the archive server.
4326 You can retry the upload of exactly these same files with dput of:
4327   $changesfile
4328 If that .changes file is broken, you will need to use a new version
4329 number for your next attempt at the upload.
4330 END
4331     my $host = access_cfg('upload-host','RETURN-UNDEF');
4332     my @hostarg = defined($host) ? ($host,) : ();
4333     runcmd_ordryrun @dput, @hostarg, $changesfile;
4334     printdone "pushed and uploaded $cversion";
4335
4336     supplementary_message('');
4337     responder_send_command("complete");
4338 }
4339
4340 sub cmd_clone {
4341     parseopts();
4342     my $dstdir;
4343     badusage "-p is not allowed with clone; specify as argument instead"
4344         if defined $package;
4345     if (@ARGV==1) {
4346         ($package) = @ARGV;
4347     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
4348         ($package,$isuite) = @ARGV;
4349     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
4350         ($package,$dstdir) = @ARGV;
4351     } elsif (@ARGV==3) {
4352         ($package,$isuite,$dstdir) = @ARGV;
4353     } else {
4354         badusage "incorrect arguments to dgit clone";
4355     }
4356     notpushing();
4357
4358     $dstdir ||= "$package";
4359     if (stat_exists $dstdir) {
4360         fail "$dstdir already exists";
4361     }
4362
4363     my $cwd_remove;
4364     if ($rmonerror && !$dryrun_level) {
4365         $cwd_remove= getcwd();
4366         unshift @end, sub {
4367             return unless defined $cwd_remove;
4368             if (!chdir "$cwd_remove") {
4369                 return if $!==&ENOENT;
4370                 die "chdir $cwd_remove: $!";
4371             }
4372             printdebug "clone rmonerror removing $dstdir\n";
4373             if (stat $dstdir) {
4374                 rmtree($dstdir) or die "remove $dstdir: $!\n";
4375             } elsif (grep { $! == $_ }
4376                      (ENOENT, ENOTDIR, EACCES, EPERM, ELOOP)) {
4377             } else {
4378                 print STDERR "check whether to remove $dstdir: $!\n";
4379             }
4380         };
4381     }
4382
4383     clone($dstdir);
4384     $cwd_remove = undef;
4385 }
4386
4387 sub branchsuite () {
4388     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
4389     if ($branch =~ m#$lbranch_re#o) {
4390         return $1;
4391     } else {
4392         return undef;
4393     }
4394 }
4395
4396 sub fetchpullargs () {
4397     if (!defined $package) {
4398         my $sourcep = parsecontrol('debian/control','debian/control');
4399         $package = getfield $sourcep, 'Source';
4400     }
4401     if (@ARGV==0) {
4402         $isuite = branchsuite();
4403         if (!$isuite) {
4404             my $clogp = parsechangelog();
4405             my $clogsuite = getfield $clogp, 'Distribution';
4406             $isuite= $clogsuite if $clogsuite ne 'UNRELEASED';
4407         }
4408     } elsif (@ARGV==1) {
4409         ($isuite) = @ARGV;
4410     } else {
4411         badusage "incorrect arguments to dgit fetch or dgit pull";
4412     }
4413     notpushing();
4414 }
4415
4416 sub cmd_fetch {
4417     parseopts();
4418     fetchpullargs();
4419     my $multi_fetched = fork_for_multisuite(sub { });
4420     exit 0 if $multi_fetched;
4421     fetch();
4422 }
4423
4424 sub cmd_pull {
4425     parseopts();
4426     fetchpullargs();
4427     if (quiltmode_splitbrain()) {
4428         my ($format, $fopts) = get_source_format();
4429         madformat($format) and fail <<END
4430 dgit pull not yet supported in split view mode (--quilt=$quilt_mode)
4431 END
4432     }
4433     pull();
4434 }
4435
4436 sub cmd_push {
4437     parseopts();
4438     badusage "-p is not allowed with dgit push" if defined $package;
4439     check_not_dirty();
4440     my $clogp = parsechangelog();
4441     $package = getfield $clogp, 'Source';
4442     my $specsuite;
4443     if (@ARGV==0) {
4444     } elsif (@ARGV==1) {
4445         ($specsuite) = (@ARGV);
4446     } else {
4447         badusage "incorrect arguments to dgit push";
4448     }
4449     $isuite = getfield $clogp, 'Distribution';
4450     pushing();
4451     if ($new_package) {
4452         local ($package) = $existing_package; # this is a hack
4453         canonicalise_suite();
4454     } else {
4455         canonicalise_suite();
4456     }
4457     if (defined $specsuite &&
4458         $specsuite ne $isuite &&
4459         $specsuite ne $csuite) {
4460             fail "dgit push: changelog specifies $isuite ($csuite)".
4461                 " but command line specifies $specsuite";
4462     }
4463     dopush();
4464 }
4465
4466 #---------- remote commands' implementation ----------
4467
4468 sub cmd_remote_push_build_host {
4469     my ($nrargs) = shift @ARGV;
4470     my (@rargs) = @ARGV[0..$nrargs-1];
4471     @ARGV = @ARGV[$nrargs..$#ARGV];
4472     die unless @rargs;
4473     my ($dir,$vsnwant) = @rargs;
4474     # vsnwant is a comma-separated list; we report which we have
4475     # chosen in our ready response (so other end can tell if they
4476     # offered several)
4477     $debugprefix = ' ';
4478     $we_are_responder = 1;
4479     $us .= " (build host)";
4480
4481     open PI, "<&STDIN" or die $!;
4482     open STDIN, "/dev/null" or die $!;
4483     open PO, ">&STDOUT" or die $!;
4484     autoflush PO 1;
4485     open STDOUT, ">&STDERR" or die $!;
4486     autoflush STDOUT 1;
4487
4488     $vsnwant //= 1;
4489     ($protovsn) = grep {
4490         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
4491     } @rpushprotovsn_support;
4492
4493     fail "build host has dgit rpush protocol versions ".
4494         (join ",", @rpushprotovsn_support).
4495         " but invocation host has $vsnwant"
4496         unless defined $protovsn;
4497
4498     responder_send_command("dgit-remote-push-ready $protovsn");
4499     changedir $dir;
4500     &cmd_push;
4501 }
4502
4503 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
4504 # ... for compatibility with proto vsn.1 dgit (just so that user gets
4505 #     a good error message)
4506
4507 sub rpush_handle_protovsn_bothends () {
4508     if ($protovsn < 4) {
4509         need_tagformat 'old', "rpush negotiated protocol $protovsn";
4510     }
4511     select_tagformat();
4512 }
4513
4514 our $i_tmp;
4515
4516 sub i_cleanup {
4517     local ($@, $?);
4518     my $report = i_child_report();
4519     if (defined $report) {
4520         printdebug "($report)\n";
4521     } elsif ($i_child_pid) {
4522         printdebug "(killing build host child $i_child_pid)\n";
4523         kill 15, $i_child_pid;
4524     }
4525     if (defined $i_tmp && !defined $initiator_tempdir) {
4526         changedir "/";
4527         eval { rmtree $i_tmp; };
4528     }
4529 }
4530
4531 END {
4532     return unless forkcheck_mainprocess();
4533     i_cleanup();
4534 }
4535
4536 sub i_method {
4537     my ($base,$selector,@args) = @_;
4538     $selector =~ s/\-/_/g;
4539     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
4540 }
4541
4542 sub cmd_rpush {
4543     my $host = nextarg;
4544     my $dir;
4545     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
4546         $host = $1;
4547         $dir = $'; #';
4548     } else {
4549         $dir = nextarg;
4550     }
4551     $dir =~ s{^-}{./-};
4552     my @rargs = ($dir);
4553     push @rargs, join ",", @rpushprotovsn_support;
4554     my @rdgit;
4555     push @rdgit, @dgit;
4556     push @rdgit, @ropts;
4557     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
4558     push @rdgit, @ARGV;
4559     my @cmd = (@ssh, $host, shellquote @rdgit);
4560     debugcmd "+",@cmd;
4561
4562     $we_are_initiator=1;
4563
4564     if (defined $initiator_tempdir) {
4565         rmtree $initiator_tempdir;
4566         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
4567         $i_tmp = $initiator_tempdir;
4568     } else {
4569         $i_tmp = tempdir();
4570     }
4571     $i_child_pid = open2(\*RO, \*RI, @cmd);
4572     changedir $i_tmp;
4573     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
4574     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
4575     $supplementary_message = '' unless $protovsn >= 3;
4576
4577     for (;;) {
4578         my ($icmd,$iargs) = initiator_expect {
4579             m/^(\S+)(?: (.*))?$/;
4580             ($1,$2);
4581         };
4582         i_method "i_resp", $icmd, $iargs;
4583     }
4584 }
4585
4586 sub i_resp_progress ($) {
4587     my ($rhs) = @_;
4588     my $msg = protocol_read_bytes \*RO, $rhs;
4589     progress $msg;
4590 }
4591
4592 sub i_resp_supplementary_message ($) {
4593     my ($rhs) = @_;
4594     $supplementary_message = protocol_read_bytes \*RO, $rhs;
4595 }
4596
4597 sub i_resp_complete {
4598     my $pid = $i_child_pid;
4599     $i_child_pid = undef; # prevents killing some other process with same pid
4600     printdebug "waiting for build host child $pid...\n";
4601     my $got = waitpid $pid, 0;
4602     die $! unless $got == $pid;
4603     die "build host child failed $?" if $?;
4604
4605     i_cleanup();
4606     printdebug "all done\n";
4607     exit 0;
4608 }
4609
4610 sub i_resp_file ($) {
4611     my ($keyword) = @_;
4612     my $localname = i_method "i_localname", $keyword;
4613     my $localpath = "$i_tmp/$localname";
4614     stat_exists $localpath and
4615         badproto \*RO, "file $keyword ($localpath) twice";
4616     protocol_receive_file \*RO, $localpath;
4617     i_method "i_file", $keyword;
4618 }
4619
4620 our %i_param;
4621
4622 sub i_resp_param ($) {
4623     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
4624     $i_param{$1} = $2;
4625 }
4626
4627 sub i_resp_previously ($) {
4628     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
4629         or badproto \*RO, "bad previously spec";
4630     my $r = system qw(git check-ref-format), $1;
4631     die "bad previously ref spec ($r)" if $r;
4632     $previously{$1} = $2;
4633 }
4634
4635 our %i_wanted;
4636
4637 sub i_resp_want ($) {
4638     my ($keyword) = @_;
4639     die "$keyword ?" if $i_wanted{$keyword}++;
4640
4641     defined $i_param{'csuite'} or badproto \*RO, "premature desire, no csuite";
4642     $isuite = $i_param{'isuite'} // $i_param{'csuite'};
4643     die unless $isuite =~ m/^$suite_re$/;
4644
4645     pushing();
4646     rpush_handle_protovsn_bothends();
4647
4648     fail "rpush negotiated protocol version $protovsn".
4649         " which does not support quilt mode $quilt_mode"
4650         if quiltmode_splitbrain;
4651
4652     my @localpaths = i_method "i_want", $keyword;
4653     printdebug "[[  $keyword @localpaths\n";
4654     foreach my $localpath (@localpaths) {
4655         protocol_send_file \*RI, $localpath;
4656     }
4657     print RI "files-end\n" or die $!;
4658 }
4659
4660 our ($i_clogp, $i_version, $i_dscfn, $i_changesfn);
4661
4662 sub i_localname_parsed_changelog {
4663     return "remote-changelog.822";
4664 }
4665 sub i_file_parsed_changelog {
4666     ($i_clogp, $i_version, $i_dscfn) =
4667         push_parse_changelog "$i_tmp/remote-changelog.822";
4668     die if $i_dscfn =~ m#/|^\W#;
4669 }
4670
4671 sub i_localname_dsc {
4672     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4673     return $i_dscfn;
4674 }
4675 sub i_file_dsc { }
4676
4677 sub i_localname_changes {
4678     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
4679     $i_changesfn = $i_dscfn;
4680     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
4681     return $i_changesfn;
4682 }
4683 sub i_file_changes { }
4684
4685 sub i_want_signed_tag {
4686     printdebug Dumper(\%i_param, $i_dscfn);
4687     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
4688         && defined $i_param{'csuite'}
4689         or badproto \*RO, "premature desire for signed-tag";
4690     my $head = $i_param{'head'};
4691     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
4692
4693     my $maintview = $i_param{'maint-view'};
4694     die if defined $maintview && $maintview =~ m/[^0-9a-f]/;
4695
4696     select_tagformat();
4697     if ($protovsn >= 4) {
4698         my $p = $i_param{'tagformat'} // '<undef>';
4699         $p eq $tagformat
4700             or badproto \*RO, "tag format mismatch: $p vs. $tagformat";
4701     }
4702
4703     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
4704     $csuite = $&;
4705     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
4706
4707     my @tagwants = push_tagwants $i_version, $head, $maintview, "tag";
4708
4709     return
4710         push_mktags $i_clogp, $i_dscfn,
4711             $i_changesfn, 'remote changes',
4712             \@tagwants;
4713 }
4714
4715 sub i_want_signed_dsc_changes {
4716     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
4717     sign_changes $i_changesfn;
4718     return ($i_dscfn, $i_changesfn);
4719 }
4720
4721 #---------- building etc. ----------
4722
4723 our $version;
4724 our $sourcechanges;
4725 our $dscfn;
4726
4727 #----- `3.0 (quilt)' handling -----
4728
4729 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
4730
4731 sub quiltify_dpkg_commit ($$$;$) {
4732     my ($patchname,$author,$msg, $xinfo) = @_;
4733     $xinfo //= '';
4734
4735     mkpath '.git/dgit';
4736     my $descfn = ".git/dgit/quilt-description.tmp";
4737     open O, '>', $descfn or die "$descfn: $!";
4738     $msg =~ s/\n+/\n\n/;
4739     print O <<END or die $!;
4740 From: $author
4741 ${xinfo}Subject: $msg
4742 ---
4743
4744 END
4745     close O or die $!;
4746
4747     {
4748         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
4749         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
4750         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
4751         runcmd @dpkgsource, qw(--commit --include-removal .), $patchname;
4752     }
4753 }
4754
4755 sub quiltify_trees_differ ($$;$$$) {
4756     my ($x,$y,$finegrained,$ignorenamesr,$unrepres) = @_;
4757     # returns true iff the two tree objects differ other than in debian/
4758     # with $finegrained,
4759     # returns bitmask 01 - differ in upstream files except .gitignore
4760     #                 02 - differ in .gitignore
4761     # if $ignorenamesr is defined, $ingorenamesr->{$fn}
4762     #  is set for each modified .gitignore filename $fn
4763     # if $unrepres is defined, array ref to which is appeneded
4764     #  a list of unrepresentable changes (removals of upstream files
4765     #  (as messages)
4766     local $/=undef;
4767     my @cmd = (@git, qw(diff-tree -z));
4768     push @cmd, qw(--name-only) unless $unrepres;
4769     push @cmd, qw(-r) if $finegrained || $unrepres;
4770     push @cmd, $x, $y;
4771     my $diffs= cmdoutput @cmd;
4772     my $r = 0;
4773     my @lmodes;
4774     foreach my $f (split /\0/, $diffs) {
4775         if ($unrepres && !@lmodes) {
4776             @lmodes = $f =~ m/^\:(\w+) (\w+) \w+ \w+ / or die "$_ ?";
4777             next;
4778         }
4779         my ($oldmode,$newmode) = @lmodes;
4780         @lmodes = ();
4781
4782         next if $f =~ m#^debian(?:/.*)?$#s;
4783
4784         if ($unrepres) {
4785             eval {
4786                 die "not a plain file\n"
4787                     unless $newmode =~ m/^10\d{4}$/ ||
4788                            $oldmode =~ m/^10\d{4}$/;
4789                 if ($oldmode =~ m/[^0]/ &&
4790                     $newmode =~ m/[^0]/) {
4791                     die "mode changed\n" if $oldmode ne $newmode;
4792                 } else {
4793                     die "non-default mode\n"
4794                         unless $newmode =~ m/^100644$/ ||
4795                                $oldmode =~ m/^100644$/;
4796                 }
4797             };
4798             if ($@) {
4799                 local $/="\n"; chomp $@;
4800                 push @$unrepres, [ $f, "$@ ($oldmode->$newmode)" ];
4801             }
4802         }
4803
4804         my $isignore = $f =~ m#^(?:.*/)?.gitignore$#s;
4805         $r |= $isignore ? 02 : 01;
4806         $ignorenamesr->{$f}=1 if $ignorenamesr && $isignore;
4807     }
4808     printdebug "quiltify_trees_differ $x $y => $r\n";
4809     return $r;
4810 }
4811
4812 sub quiltify_tree_sentinelfiles ($) {
4813     # lists the `sentinel' files present in the tree
4814     my ($x) = @_;
4815     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
4816         qw(-- debian/rules debian/control);
4817     $r =~ s/\n/,/g;
4818     return $r;
4819 }
4820
4821 sub quiltify_splitbrain_needed () {
4822     if (!$split_brain) {
4823         progress "dgit view: changes are required...";
4824         runcmd @git, qw(checkout -q -b dgit-view);
4825         $split_brain = 1;
4826     }
4827 }
4828
4829 sub quiltify_splitbrain ($$$$$$) {
4830     my ($clogp, $unapplied, $headref, $diffbits,
4831         $editedignores, $cachekey) = @_;
4832     if ($quilt_mode !~ m/gbp|dpm/) {
4833         # treat .gitignore just like any other upstream file
4834         $diffbits = { %$diffbits };
4835         $_ = !!$_ foreach values %$diffbits;
4836     }
4837     # We would like any commits we generate to be reproducible
4838     my @authline = clogp_authline($clogp);
4839     local $ENV{GIT_COMMITTER_NAME} =  $authline[0];
4840     local $ENV{GIT_COMMITTER_EMAIL} = $authline[1];
4841     local $ENV{GIT_COMMITTER_DATE} =  $authline[2];
4842     local $ENV{GIT_AUTHOR_NAME} =  $authline[0];
4843     local $ENV{GIT_AUTHOR_EMAIL} = $authline[1];
4844     local $ENV{GIT_AUTHOR_DATE} =  $authline[2];
4845
4846     if ($quilt_mode =~ m/gbp|unapplied/ &&
4847         ($diffbits->{O2H} & 01)) {
4848         my $msg =
4849  "--quilt=$quilt_mode specified, implying patches-unapplied git tree\n".
4850  " but git tree differs from orig in upstream files.";
4851         if (!stat_exists "debian/patches") {
4852             $msg .=
4853  "\n ... debian/patches is missing; perhaps this is a patch queue branch?";
4854         }
4855         fail $msg;
4856     }
4857     if ($quilt_mode =~ m/dpm/ &&
4858         ($diffbits->{H2A} & 01)) {
4859         fail <<END;
4860 --quilt=$quilt_mode specified, implying patches-applied git tree
4861  but git tree differs from result of applying debian/patches to upstream
4862 END
4863     }
4864     if ($quilt_mode =~ m/gbp|unapplied/ &&
4865         ($diffbits->{O2A} & 01)) { # some patches
4866         quiltify_splitbrain_needed();
4867         progress "dgit view: creating patches-applied version using gbp pq";
4868         runcmd shell_cmd 'exec >/dev/null', gbp_pq, qw(import);
4869         # gbp pq import creates a fresh branch; push back to dgit-view
4870         runcmd @git, qw(update-ref refs/heads/dgit-view HEAD);
4871         runcmd @git, qw(checkout -q dgit-view);
4872     }
4873     if ($quilt_mode =~ m/gbp|dpm/ &&
4874         ($diffbits->{O2A} & 02)) {
4875         fail <<END
4876 --quilt=$quilt_mode specified, implying that HEAD is for use with a
4877  tool which does not create patches for changes to upstream
4878  .gitignores: but, such patches exist in debian/patches.
4879 END
4880     }
4881     if (($diffbits->{O2H} & 02) && # user has modified .gitignore
4882         !($diffbits->{O2A} & 02)) { # patches do not change .gitignore
4883         quiltify_splitbrain_needed();
4884         progress "dgit view: creating patch to represent .gitignore changes";
4885         ensuredir "debian/patches";
4886         my $gipatch = "debian/patches/auto-gitignore";
4887         open GIPATCH, ">>", "$gipatch" or die "$gipatch: $!";
4888         stat GIPATCH or die "$gipatch: $!";
4889         fail "$gipatch already exists; but want to create it".
4890             " to record .gitignore changes" if (stat _)[7];
4891         print GIPATCH <<END or die "$gipatch: $!";
4892 Subject: Update .gitignore from Debian packaging branch
4893
4894 The Debian packaging git branch contains these updates to the upstream
4895 .gitignore file(s).  This patch is autogenerated, to provide these
4896 updates to users of the official Debian archive view of the package.
4897
4898 [dgit ($our_version) update-gitignore]
4899 ---
4900 END
4901         close GIPATCH or die "$gipatch: $!";
4902         runcmd shell_cmd "exec >>$gipatch", @git, qw(diff),
4903             $unapplied, $headref, "--", sort keys %$editedignores;
4904         open SERIES, "+>>", "debian/patches/series" or die $!;
4905         defined seek SERIES, -1, 2 or $!==EINVAL or die $!;
4906         my $newline;
4907         defined read SERIES, $newline, 1 or die $!;
4908         print SERIES "\n" or die $! unless $newline eq "\n";
4909         print SERIES "auto-gitignore\n" or die $!;
4910         close SERIES or die  $!;
4911         runcmd @git, qw(add -- debian/patches/series), $gipatch;
4912         commit_admin <<END
4913 Commit patch to update .gitignore
4914
4915 [dgit ($our_version) update-gitignore-quilt-fixup]
4916 END
4917     }
4918
4919     my $dgitview = git_rev_parse 'HEAD';
4920
4921     changedir '../../../..';
4922     # When we no longer need to support squeeze, use --create-reflog
4923     # instead of this:
4924     ensuredir ".git/logs/refs/dgit-intern";
4925     my $makelogfh = new IO::File ".git/logs/refs/$splitbraincache", '>>'
4926       or die $!;
4927
4928     my $oldcache = git_get_ref "refs/$splitbraincache";
4929     if ($oldcache eq $dgitview) {
4930         my $tree = cmdoutput qw(git rev-parse), "$dgitview:";
4931         # git update-ref doesn't always update, in this case.  *sigh*
4932         my $dummy = make_commit_text <<END;
4933 tree $tree
4934 parent $dgitview
4935 author Dgit <dgit\@example.com> 1000000000 +0000
4936 committer Dgit <dgit\@example.com> 1000000000 +0000
4937
4938 Dummy commit - do not use
4939 END
4940         runcmd @git, qw(update-ref -m), "dgit $our_version - dummy",
4941             "refs/$splitbraincache", $dummy;
4942     }
4943     runcmd @git, qw(update-ref -m), $cachekey, "refs/$splitbraincache",
4944         $dgitview;
4945
4946     changedir '.git/dgit/unpack/work';
4947
4948     my $saved = maybe_split_brain_save $headref, $dgitview, "converted";
4949     progress "dgit view: created ($saved)";
4950 }
4951
4952 sub quiltify ($$$$) {
4953     my ($clogp,$target,$oldtiptree,$failsuggestion) = @_;
4954
4955     # Quilt patchification algorithm
4956     #
4957     # We search backwards through the history of the main tree's HEAD
4958     # (T) looking for a start commit S whose tree object is identical
4959     # to to the patch tip tree (ie the tree corresponding to the
4960     # current dpkg-committed patch series).  For these purposes
4961     # `identical' disregards anything in debian/ - this wrinkle is
4962     # necessary because dpkg-source treates debian/ specially.
4963     #
4964     # We can only traverse edges where at most one of the ancestors'
4965     # trees differs (in changes outside in debian/).  And we cannot
4966     # handle edges which change .pc/ or debian/patches.  To avoid
4967     # going down a rathole we avoid traversing edges which introduce
4968     # debian/rules or debian/control.  And we set a limit on the
4969     # number of edges we are willing to look at.
4970     #
4971     # If we succeed, we walk forwards again.  For each traversed edge
4972     # PC (with P parent, C child) (starting with P=S and ending with
4973     # C=T) to we do this:
4974     #  - git checkout C
4975     #  - dpkg-source --commit with a patch name and message derived from C
4976     # After traversing PT, we git commit the changes which
4977     # should be contained within debian/patches.
4978
4979     # The search for the path S..T is breadth-first.  We maintain a
4980     # todo list containing search nodes.  A search node identifies a
4981     # commit, and looks something like this:
4982     #  $p = {
4983     #      Commit => $git_commit_id,
4984     #      Child => $c,                          # or undef if P=T
4985     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
4986     #      Nontrivial => true iff $p..$c has relevant changes
4987     #  };
4988
4989     my @todo;
4990     my @nots;
4991     my $sref_S;
4992     my $max_work=100;
4993     my %considered; # saves being exponential on some weird graphs
4994
4995     my $t_sentinels = quiltify_tree_sentinelfiles $target;
4996
4997     my $not = sub {
4998         my ($search,$whynot) = @_;
4999         printdebug " search NOT $search->{Commit} $whynot\n";
5000         $search->{Whynot} = $whynot;
5001         push @nots, $search;
5002         no warnings qw(exiting);
5003         next;
5004     };
5005
5006     push @todo, {
5007         Commit => $target,
5008     };
5009
5010     while (@todo) {
5011         my $c = shift @todo;
5012         next if $considered{$c->{Commit}}++;
5013
5014         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
5015
5016         printdebug "quiltify investigate $c->{Commit}\n";
5017
5018         # are we done?
5019         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
5020             printdebug " search finished hooray!\n";
5021             $sref_S = $c;
5022             last;
5023         }
5024
5025         if ($quilt_mode eq 'nofix') {
5026             fail "quilt fixup required but quilt mode is \`nofix'\n".
5027                 "HEAD commit $c->{Commit} differs from tree implied by ".
5028                 " debian/patches (tree object $oldtiptree)";
5029         }
5030         if ($quilt_mode eq 'smash') {
5031             printdebug " search quitting smash\n";
5032             last;
5033         }
5034
5035         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
5036         $not->($c, "has $c_sentinels not $t_sentinels")
5037             if $c_sentinels ne $t_sentinels;
5038
5039         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
5040         $commitdata =~ m/\n\n/;
5041         $commitdata =~ $`;
5042         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
5043         @parents = map { { Commit => $_, Child => $c } } @parents;
5044
5045         $not->($c, "root commit") if !@parents;
5046
5047         foreach my $p (@parents) {
5048             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
5049         }
5050         my $ndiffers = grep { $_->{Nontrivial} } @parents;
5051         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
5052
5053         foreach my $p (@parents) {
5054             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
5055
5056             my @cmd= (@git, qw(diff-tree -r --name-only),
5057                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
5058             my $patchstackchange = cmdoutput @cmd;
5059             if (length $patchstackchange) {
5060                 $patchstackchange =~ s/\n/,/g;
5061                 $not->($p, "changed $patchstackchange");
5062             }
5063
5064             printdebug " search queue P=$p->{Commit} ",
5065                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
5066             push @todo, $p;
5067         }
5068     }
5069
5070     if (!$sref_S) {
5071         printdebug "quiltify want to smash\n";
5072
5073         my $abbrev = sub {
5074             my $x = $_[0]{Commit};
5075             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
5076             return $x;
5077         };
5078         my $reportnot = sub {
5079             my ($notp) = @_;
5080             my $s = $abbrev->($notp);
5081             my $c = $notp->{Child};
5082             $s .= "..".$abbrev->($c) if $c;
5083             $s .= ": ".$notp->{Whynot};
5084             return $s;
5085         };
5086         if ($quilt_mode eq 'linear') {
5087             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
5088             foreach my $notp (@nots) {
5089                 print STDERR "$us:  ", $reportnot->($notp), "\n";
5090             }
5091             print STDERR "$us: $_\n" foreach @$failsuggestion;
5092             fail "quilt fixup naive history linearisation failed.\n".
5093  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
5094         } elsif ($quilt_mode eq 'smash') {
5095         } elsif ($quilt_mode eq 'auto') {
5096             progress "quilt fixup cannot be linear, smashing...";
5097         } else {
5098             die "$quilt_mode ?";
5099         }
5100
5101         my $time = $ENV{'GIT_COMMITTER_DATE'} || time;
5102         $time =~ s/\s.*//; # trim timezone from GIT_COMMITTER_DATE
5103         my $ncommits = 3;
5104         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
5105
5106         quiltify_dpkg_commit "auto-$version-$target-$time",
5107             (getfield $clogp, 'Maintainer'),
5108             "Automatically generated patch ($clogp->{Version})\n".
5109             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
5110         return;
5111     }
5112
5113     progress "quiltify linearisation planning successful, executing...";
5114
5115     for (my $p = $sref_S;
5116          my $c = $p->{Child};
5117          $p = $p->{Child}) {
5118         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
5119         next unless $p->{Nontrivial};
5120
5121         my $cc = $c->{Commit};
5122
5123         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
5124         $commitdata =~ m/\n\n/ or die "$c ?";
5125         $commitdata = $`;
5126         my $msg = $'; #';
5127         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
5128         my $author = $1;
5129
5130         my $commitdate = cmdoutput
5131             @git, qw(log -n1 --pretty=format:%aD), $cc;
5132
5133         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
5134
5135         my $strip_nls = sub { $msg =~ s/\n+$//; $msg .= "\n"; };
5136         $strip_nls->();
5137
5138         my $title = $1;
5139         my $patchname;
5140         my $patchdir;
5141
5142         my $gbp_check_suitable = sub {
5143             $_ = shift;
5144             my ($what) = @_;
5145
5146             eval {
5147                 die "contains unexpected slashes\n" if m{//} || m{/$};
5148                 die "contains leading punctuation\n" if m{^\W} || m{/\W};
5149                 die "contains bad character(s)\n" if m{[^-a-z0-9_.+=~/]}i;
5150                 die "too long" if length > 200;
5151             };
5152             return $_ unless $@;
5153             print STDERR "quiltifying commit $cc:".
5154                 " ignoring/dropping Gbp-Pq $what: $@";
5155             return undef;
5156         };
5157
5158         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* name \s+ |
5159                            gbp-pq-name: \s* )
5160                        (\S+) \s* \n //ixm) {
5161             $patchname = $gbp_check_suitable->($1, 'Name');
5162         }
5163         if ($msg =~ s/^ (?: gbp(?:-pq)? : \s* topic \s+ |
5164                            gbp-pq-topic: \s* )
5165                        (\S+) \s* \n //ixm) {
5166             $patchdir = $gbp_check_suitable->($1, 'Topic');
5167         }
5168
5169         $strip_nls->();
5170
5171         if (!defined $patchname) {
5172             $patchname = $title;
5173             $patchname =~ s/[.:]$//;
5174             use Text::Iconv;
5175             eval {
5176                 my $converter = new Text::Iconv qw(UTF-8 ASCII//TRANSLIT);
5177                 my $translitname = $converter->convert($patchname);
5178                 die unless defined $translitname;
5179                 $patchname = $translitname;
5180             };
5181             print STDERR
5182                 "dgit: patch title transliteration error: $@"
5183                 if $@;
5184             $patchname =~ y/ A-Z/-a-z/;
5185             $patchname =~ y/-a-z0-9_.+=~//cd;
5186             $patchname =~ s/^\W/x-$&/;
5187             $patchname = substr($patchname,0,40);
5188         }
5189         if (!defined $patchdir) {
5190             $patchdir = '';
5191         }
5192         if (length $patchdir) {
5193             $patchname = "$patchdir/$patchname";
5194         }
5195         if ($patchname =~ m{^(.*)/}) {
5196             mkpath "debian/patches/$1";
5197         }
5198
5199         my $index;
5200         for ($index='';
5201              stat "debian/patches/$patchname$index";
5202              $index++) { }
5203         $!==ENOENT or die "$patchname$index $!";
5204
5205         runcmd @git, qw(checkout -q), $cc;
5206
5207         # We use the tip's changelog so that dpkg-source doesn't
5208         # produce complaining messages from dpkg-parsechangelog.  None
5209         # of the information dpkg-source gets from the changelog is
5210         # actually relevant - it gets put into the original message
5211         # which dpkg-source provides our stunt editor, and then
5212         # overwritten.
5213         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
5214
5215         quiltify_dpkg_commit "$patchname$index", $author, $msg,
5216             "Date: $commitdate\n".
5217             "X-Dgit-Generated: $clogp->{Version} $cc\n";
5218
5219         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
5220     }
5221
5222     runcmd @git, qw(checkout -q master);
5223 }
5224
5225 sub build_maybe_quilt_fixup () {
5226     my ($format,$fopts) = get_source_format;
5227     return unless madformat_wantfixup $format;
5228     # sigh
5229
5230     check_for_vendor_patches();
5231
5232     if (quiltmode_splitbrain) {
5233         fail <<END unless access_cfg_tagformats_can_splitbrain;
5234 quilt mode $quilt_mode requires split view so server needs to support
5235  both "new" and "maint" tag formats, but config says it doesn't.
5236 END
5237     }
5238
5239     my $clogp = parsechangelog();
5240     my $headref = git_rev_parse('HEAD');
5241
5242     prep_ud();
5243     changedir $ud;
5244
5245     my $upstreamversion = upstreamversion $version;
5246
5247     if ($fopts->{'single-debian-patch'}) {
5248         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
5249     } else {
5250         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
5251     }
5252
5253     die 'bug' if $split_brain && !$need_split_build_invocation;
5254
5255     changedir '../../../..';
5256     runcmd_ordryrun_local
5257         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
5258 }
5259
5260 sub quilt_fixup_mkwork ($) {
5261     my ($headref) = @_;
5262
5263     mkdir "work" or die $!;
5264     changedir "work";
5265     mktree_in_ud_here();
5266     runcmd @git, qw(reset -q --hard), $headref;
5267 }
5268
5269 sub quilt_fixup_linkorigs ($$) {
5270     my ($upstreamversion, $fn) = @_;
5271     # calls $fn->($leafname);
5272
5273     foreach my $f (<../../../../*>) { #/){
5274         my $b=$f; $b =~ s{.*/}{};
5275         {
5276             local ($debuglevel) = $debuglevel-1;
5277             printdebug "QF linkorigs $b, $f ?\n";
5278         }
5279         next unless is_orig_file_of_vsn $b, $upstreamversion;
5280         printdebug "QF linkorigs $b, $f Y\n";
5281         link_ltarget $f, $b or die "$b $!";
5282         $fn->($b);
5283     }
5284 }
5285
5286 sub quilt_fixup_delete_pc () {
5287     runcmd @git, qw(rm -rqf .pc);
5288     commit_admin <<END
5289 Commit removal of .pc (quilt series tracking data)
5290
5291 [dgit ($our_version) upgrade quilt-remove-pc]
5292 END
5293 }
5294
5295 sub quilt_fixup_singlepatch ($$$) {
5296     my ($clogp, $headref, $upstreamversion) = @_;
5297
5298     progress "starting quiltify (single-debian-patch)";
5299
5300     # dpkg-source --commit generates new patches even if
5301     # single-debian-patch is in debian/source/options.  In order to
5302     # get it to generate debian/patches/debian-changes, it is
5303     # necessary to build the source package.
5304
5305     quilt_fixup_linkorigs($upstreamversion, sub { });
5306     quilt_fixup_mkwork($headref);
5307
5308     rmtree("debian/patches");
5309
5310     runcmd @dpkgsource, qw(-b .);
5311     changedir "..";
5312     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
5313     rename srcfn("$upstreamversion", "/debian/patches"),
5314            "work/debian/patches";
5315
5316     changedir "work";
5317     commit_quilty_patch();
5318 }
5319
5320 sub quilt_make_fake_dsc ($) {
5321     my ($upstreamversion) = @_;
5322
5323     my $fakeversion="$upstreamversion-~~DGITFAKE";
5324
5325     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
5326     print $fakedsc <<END or die $!;
5327 Format: 3.0 (quilt)
5328 Source: $package
5329 Version: $fakeversion
5330 Files:
5331 END
5332
5333     my $dscaddfile=sub {
5334         my ($b) = @_;
5335
5336         my $md = new Digest::MD5;
5337
5338         my $fh = new IO::File $b, '<' or die "$b $!";
5339         stat $fh or die $!;
5340         my $size = -s _;
5341
5342         $md->addfile($fh);
5343         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
5344     };
5345
5346     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
5347
5348     my @files=qw(debian/source/format debian/rules
5349                  debian/control debian/changelog);
5350     foreach my $maybe (qw(debian/patches debian/source/options
5351                           debian/tests/control)) {
5352         next unless stat_exists "../../../$maybe";
5353         push @files, $maybe;
5354     }
5355
5356     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
5357     runcmd qw(env GZIP=-1n tar -zcf), "./$debtar", qw(-C ../../..), @files;
5358
5359     $dscaddfile->($debtar);
5360     close $fakedsc or die $!;
5361 }
5362
5363 sub quilt_check_splitbrain_cache ($$) {
5364     my ($headref, $upstreamversion) = @_;
5365     # Called only if we are in (potentially) split brain mode.
5366     # Called in $ud.
5367     # Computes the cache key and looks in the cache.
5368     # Returns ($dgit_view_commitid, $cachekey) or (undef, $cachekey)
5369
5370     my $splitbrain_cachekey;
5371
5372     progress
5373  "dgit: split brain (separate dgit view) may be needed (--quilt=$quilt_mode).";
5374     # we look in the reflog of dgit-intern/quilt-cache
5375     # we look for an entry whose message is the key for the cache lookup
5376     my @cachekey = (qw(dgit), $our_version);
5377     push @cachekey, $upstreamversion;
5378     push @cachekey, $quilt_mode;
5379     push @cachekey, $headref;
5380
5381     push @cachekey, hashfile('fake.dsc');
5382
5383     my $srcshash = Digest::SHA->new(256);
5384     my %sfs = ( %INC, '$0(dgit)' => $0 );
5385     foreach my $sfk (sort keys %sfs) {
5386         next unless $sfk =~ m/^\$0\b/ || $sfk =~ m{^Debian/Dgit\b};
5387         $srcshash->add($sfk,"  ");
5388         $srcshash->add(hashfile($sfs{$sfk}));
5389         $srcshash->add("\n");
5390     }
5391     push @cachekey, $srcshash->hexdigest();
5392     $splitbrain_cachekey = "@cachekey";
5393
5394     my @cmd = (@git, qw(log -g), '--pretty=format:%H %gs',
5395                $splitbraincache);
5396     printdebug "splitbrain cachekey $splitbrain_cachekey\n";
5397     debugcmd "|(probably)",@cmd;
5398     my $child = open GC, "-|";  defined $child or die $!;
5399     if (!$child) {
5400         chdir '../../..' or die $!;
5401         if (!stat ".git/logs/refs/$splitbraincache") {
5402             $! == ENOENT or die $!;
5403             printdebug ">(no reflog)\n";
5404             exit 0;
5405         }
5406         exec @cmd; die $!;
5407     }
5408     while (<GC>) {
5409         chomp;
5410         printdebug ">| ", $_, "\n" if $debuglevel > 1;
5411         next unless m/^(\w+) (\S.*\S)$/ && $2 eq $splitbrain_cachekey;
5412
5413         my $cachehit = $1;
5414         quilt_fixup_mkwork($headref);
5415         my $saved = maybe_split_brain_save $headref, $cachehit, "cache-hit";
5416         if ($cachehit ne $headref) {
5417             progress "dgit view: found cached ($saved)";
5418             runcmd @git, qw(checkout -q -b dgit-view), $cachehit;
5419             $split_brain = 1;
5420             return ($cachehit, $splitbrain_cachekey);
5421         }
5422         progress "dgit view: found cached, no changes required";
5423         return ($headref, $splitbrain_cachekey);
5424     }
5425     die $! if GC->error;
5426     failedcmd unless close GC;
5427
5428     printdebug "splitbrain cache miss\n";
5429     return (undef, $splitbrain_cachekey);
5430 }
5431
5432 sub quilt_fixup_multipatch ($$$) {
5433     my ($clogp, $headref, $upstreamversion) = @_;
5434
5435     progress "examining quilt state (multiple patches, $quilt_mode mode)";
5436
5437     # Our objective is:
5438     #  - honour any existing .pc in case it has any strangeness
5439     #  - determine the git commit corresponding to the tip of
5440     #    the patch stack (if there is one)
5441     #  - if there is such a git commit, convert each subsequent
5442     #    git commit into a quilt patch with dpkg-source --commit
5443     #  - otherwise convert all the differences in the tree into
5444     #    a single git commit
5445     #
5446     # To do this we:
5447
5448     # Our git tree doesn't necessarily contain .pc.  (Some versions of
5449     # dgit would include the .pc in the git tree.)  If there isn't
5450     # one, we need to generate one by unpacking the patches that we
5451     # have.
5452     #
5453     # We first look for a .pc in the git tree.  If there is one, we
5454     # will use it.  (This is not the normal case.)
5455     #
5456     # Otherwise need to regenerate .pc so that dpkg-source --commit
5457     # can work.  We do this as follows:
5458     #     1. Collect all relevant .orig from parent directory
5459     #     2. Generate a debian.tar.gz out of
5460     #         debian/{patches,rules,source/format,source/options}
5461     #     3. Generate a fake .dsc containing just these fields:
5462     #          Format Source Version Files
5463     #     4. Extract the fake .dsc
5464     #        Now the fake .dsc has a .pc directory.
5465     # (In fact we do this in every case, because in future we will
5466     # want to search for a good base commit for generating patches.)
5467     #
5468     # Then we can actually do the dpkg-source --commit
5469     #     1. Make a new working tree with the same object
5470     #        store as our main tree and check out the main
5471     #        tree's HEAD.
5472     #     2. Copy .pc from the fake's extraction, if necessary
5473     #     3. Run dpkg-source --commit
5474     #     4. If the result has changes to debian/, then
5475     #          - git add them them
5476     #          - git add .pc if we had a .pc in-tree
5477     #          - git commit
5478     #     5. If we had a .pc in-tree, delete it, and git commit
5479     #     6. Back in the main tree, fast forward to the new HEAD
5480
5481     # Another situation we may have to cope with is gbp-style
5482     # patches-unapplied trees.
5483     #
5484     # We would want to detect these, so we know to escape into
5485     # quilt_fixup_gbp.  However, this is in general not possible.
5486     # Consider a package with a one patch which the dgit user reverts
5487     # (with git revert or the moral equivalent).
5488     #
5489     # That is indistinguishable in contents from a patches-unapplied
5490     # tree.  And looking at the history to distinguish them is not
5491     # useful because the user might have made a confusing-looking git
5492     # history structure (which ought to produce an error if dgit can't
5493     # cope, not a silent reintroduction of an unwanted patch).
5494     #
5495     # So gbp users will have to pass an option.  But we can usually
5496     # detect their failure to do so: if the tree is not a clean
5497     # patches-applied tree, quilt linearisation fails, but the tree
5498     # _is_ a clean patches-unapplied tree, we can suggest that maybe
5499     # they want --quilt=unapplied.
5500     #
5501     # To help detect this, when we are extracting the fake dsc, we
5502     # first extract it with --skip-patches, and then apply the patches
5503     # afterwards with dpkg-source --before-build.  That lets us save a
5504     # tree object corresponding to .origs.
5505
5506     my $splitbrain_cachekey;
5507
5508     quilt_make_fake_dsc($upstreamversion);
5509
5510     if (quiltmode_splitbrain()) {
5511         my $cachehit;
5512         ($cachehit, $splitbrain_cachekey) =
5513             quilt_check_splitbrain_cache($headref, $upstreamversion);
5514         return if $cachehit;
5515     }
5516
5517     runcmd qw(sh -ec),
5518         'exec dpkg-source --no-check --skip-patches -x fake.dsc >/dev/null';
5519
5520     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
5521     rename $fakexdir, "fake" or die "$fakexdir $!";
5522
5523     changedir 'fake';
5524
5525     remove_stray_gits("source package");
5526     mktree_in_ud_here();
5527
5528     rmtree '.pc';
5529
5530     runcmd @git, qw(checkout -f), $headref, qw(-- debian);
5531     my $unapplied=git_add_write_tree();
5532     printdebug "fake orig tree object $unapplied\n";
5533
5534     ensuredir '.pc';
5535
5536     my @bbcmd = (qw(sh -ec), 'exec dpkg-source --before-build . >/dev/null');
5537     $!=0; $?=-1;
5538     if (system @bbcmd) {
5539         failedcmd @bbcmd if $? < 0;
5540         fail <<END;
5541 failed to apply your git tree's patch stack (from debian/patches/) to
5542  the corresponding upstream tarball(s).  Your source tree and .orig
5543  are probably too inconsistent.  dgit can only fix up certain kinds of
5544  anomaly (depending on the quilt mode).  See --quilt= in dgit(1).
5545 END
5546     }
5547
5548     changedir '..';
5549
5550     quilt_fixup_mkwork($headref);
5551
5552     my $mustdeletepc=0;
5553     if (stat_exists ".pc") {
5554         -d _ or die;
5555         progress "Tree already contains .pc - will use it then delete it.";
5556         $mustdeletepc=1;
5557     } else {
5558         rename '../fake/.pc','.pc' or die $!;
5559     }
5560
5561     changedir '../fake';
5562     rmtree '.pc';
5563     my $oldtiptree=git_add_write_tree();
5564     printdebug "fake o+d/p tree object $unapplied\n";
5565     changedir '../work';
5566
5567
5568     # We calculate some guesswork now about what kind of tree this might
5569     # be.  This is mostly for error reporting.
5570
5571     my %editedignores;
5572     my @unrepres;
5573     my $diffbits = {
5574         # H = user's HEAD
5575         # O = orig, without patches applied
5576         # A = "applied", ie orig with H's debian/patches applied
5577         O2H => quiltify_trees_differ($unapplied,$headref,   1,
5578                                      \%editedignores, \@unrepres),
5579         H2A => quiltify_trees_differ($headref,  $oldtiptree,1),
5580         O2A => quiltify_trees_differ($unapplied,$oldtiptree,1),
5581     };
5582
5583     my @dl;
5584     foreach my $b (qw(01 02)) {
5585         foreach my $v (qw(O2H O2A H2A)) {
5586             push @dl, ($diffbits->{$v} & $b) ? '##' : '==';
5587         }
5588     }
5589     printdebug "differences \@dl @dl.\n";
5590
5591     progress sprintf
5592 "$us: base trees orig=%.20s o+d/p=%.20s",
5593               $unapplied, $oldtiptree;
5594     progress sprintf
5595 "$us: quilt differences: src:  %s orig %s     gitignores:  %s orig %s\n".
5596 "$us: quilt differences:      HEAD %s o+d/p               HEAD %s o+d/p",
5597                              $dl[0], $dl[1],              $dl[3], $dl[4],
5598                                  $dl[2],                     $dl[5];
5599
5600     if (@unrepres) {
5601         print STDERR "dgit:  cannot represent change: $_->[1]: $_->[0]\n"
5602             foreach @unrepres;
5603         forceable_fail [qw(unrepresentable)], <<END;
5604 HEAD has changes to .orig[s] which are not representable by `3.0 (quilt)'
5605 END
5606     }
5607
5608     my @failsuggestion;
5609     if (!($diffbits->{O2H} & $diffbits->{O2A})) {
5610         push @failsuggestion, "This might be a patches-unapplied branch.";
5611     }  elsif (!($diffbits->{H2A} & $diffbits->{O2A})) {
5612         push @failsuggestion, "This might be a patches-applied branch.";
5613     }
5614     push @failsuggestion, "Maybe you need to specify one of".
5615         " --[quilt=]gbp --[quilt=]dpm --quilt=unapplied ?";
5616
5617     if (quiltmode_splitbrain()) {
5618         quiltify_splitbrain($clogp, $unapplied, $headref,
5619                             $diffbits, \%editedignores,
5620                             $splitbrain_cachekey);
5621         return;
5622     }
5623
5624     progress "starting quiltify (multiple patches, $quilt_mode mode)";
5625     quiltify($clogp,$headref,$oldtiptree,\@failsuggestion);
5626
5627     if (!open P, '>>', ".pc/applied-patches") {
5628         $!==&ENOENT or die $!;
5629     } else {
5630         close P;
5631     }
5632
5633     commit_quilty_patch();
5634
5635     if ($mustdeletepc) {
5636         quilt_fixup_delete_pc();
5637     }
5638 }
5639
5640 sub quilt_fixup_editor () {
5641     my $descfn = $ENV{$fakeeditorenv};
5642     my $editing = $ARGV[$#ARGV];
5643     open I1, '<', $descfn or die "$descfn: $!";
5644     open I2, '<', $editing or die "$editing: $!";
5645     unlink $editing or die "$editing: $!";
5646     open O, '>', $editing or die "$editing: $!";
5647     while (<I1>) { print O or die $!; } I1->error and die $!;
5648     my $copying = 0;
5649     while (<I2>) {
5650         $copying ||= m/^\-\-\- /;
5651         next unless $copying;
5652         print O or die $!;
5653     }
5654     I2->error and die $!;
5655     close O or die $1;
5656     exit 0;
5657 }
5658
5659 sub maybe_apply_patches_dirtily () {
5660     return unless $quilt_mode =~ m/gbp|unapplied/;
5661     print STDERR <<END or die $!;
5662
5663 dgit: Building, or cleaning with rules target, in patches-unapplied tree.
5664 dgit: Have to apply the patches - making the tree dirty.
5665 dgit: (Consider specifying --clean=git and (or) using dgit sbuild.)
5666
5667 END
5668     $patches_applied_dirtily = 01;
5669     $patches_applied_dirtily |= 02 unless stat_exists '.pc';
5670     runcmd qw(dpkg-source --before-build .);
5671 }
5672
5673 sub maybe_unapply_patches_again () {
5674     progress "dgit: Unapplying patches again to tidy up the tree."
5675         if $patches_applied_dirtily;
5676     runcmd qw(dpkg-source --after-build .)
5677         if $patches_applied_dirtily & 01;
5678     rmtree '.pc'
5679         if $patches_applied_dirtily & 02;
5680     $patches_applied_dirtily = 0;
5681 }
5682
5683 #----- other building -----
5684
5685 our $clean_using_builder;
5686 # ^ tree is to be cleaned by dpkg-source's builtin idea that it should
5687 #   clean the tree before building (perhaps invoked indirectly by
5688 #   whatever we are using to run the build), rather than separately
5689 #   and explicitly by us.
5690
5691 sub clean_tree () {
5692     return if $clean_using_builder;
5693     if ($cleanmode eq 'dpkg-source') {
5694         maybe_apply_patches_dirtily();
5695         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
5696     } elsif ($cleanmode eq 'dpkg-source-d') {
5697         maybe_apply_patches_dirtily();
5698         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
5699     } elsif ($cleanmode eq 'git') {
5700         runcmd_ordryrun_local @git, qw(clean -xdf);
5701     } elsif ($cleanmode eq 'git-ff') {
5702         runcmd_ordryrun_local @git, qw(clean -xdff);
5703     } elsif ($cleanmode eq 'check') {
5704         my $leftovers = cmdoutput @git, qw(clean -xdn);
5705         if (length $leftovers) {
5706             print STDERR $leftovers, "\n" or die $!;
5707             fail "tree contains uncommitted files and --clean=check specified";
5708         }
5709     } elsif ($cleanmode eq 'none') {
5710     } else {
5711         die "$cleanmode ?";
5712     }
5713 }
5714
5715 sub cmd_clean () {
5716     badusage "clean takes no additional arguments" if @ARGV;
5717     notpushing();
5718     clean_tree();
5719     maybe_unapply_patches_again();
5720 }
5721
5722 sub build_prep_early () {
5723     our $build_prep_early_done //= 0;
5724     return if $build_prep_early_done++;
5725     badusage "-p is not allowed when building" if defined $package;
5726     my $clogp = parsechangelog();
5727     $isuite = getfield $clogp, 'Distribution';
5728     $package = getfield $clogp, 'Source';
5729     $version = getfield $clogp, 'Version';
5730     notpushing();
5731     check_not_dirty();
5732 }
5733
5734 sub build_prep () {
5735     build_prep_early();
5736     clean_tree();
5737     build_maybe_quilt_fixup();
5738     if ($rmchanges) {
5739         my $pat = changespat $version;
5740         foreach my $f (glob "$buildproductsdir/$pat") {
5741             if (act_local()) {
5742                 unlink $f or fail "remove old changes file $f: $!";
5743             } else {
5744                 progress "would remove $f";
5745             }
5746         }
5747     }
5748 }
5749
5750 sub changesopts_initial () {
5751     my @opts =@changesopts[1..$#changesopts];
5752 }
5753
5754 sub changesopts_version () {
5755     if (!defined $changes_since_version) {
5756         my @vsns = archive_query('archive_query');
5757         my @quirk = access_quirk();
5758         if ($quirk[0] eq 'backports') {
5759             local $isuite = $quirk[2];
5760             local $csuite;
5761             canonicalise_suite();
5762             push @vsns, archive_query('archive_query');
5763         }
5764         if (@vsns) {
5765             @vsns = map { $_->[0] } @vsns;
5766             @vsns = sort { -version_compare($a, $b) } @vsns;
5767             $changes_since_version = $vsns[0];
5768             progress "changelog will contain changes since $vsns[0]";
5769         } else {
5770             $changes_since_version = '_';
5771             progress "package seems new, not specifying -v<version>";
5772         }
5773     }
5774     if ($changes_since_version ne '_') {
5775         return ("-v$changes_since_version");
5776     } else {
5777         return ();
5778     }
5779 }
5780
5781 sub changesopts () {
5782     return (changesopts_initial(), changesopts_version());
5783 }
5784
5785 sub massage_dbp_args ($;$) {
5786     my ($cmd,$xargs) = @_;
5787     # We need to:
5788     #
5789     #  - if we're going to split the source build out so we can
5790     #    do strange things to it, massage the arguments to dpkg-buildpackage
5791     #    so that the main build doessn't build source (or add an argument
5792     #    to stop it building source by default).
5793     #
5794     #  - add -nc to stop dpkg-source cleaning the source tree,
5795     #    unless we're not doing a split build and want dpkg-source
5796     #    as cleanmode, in which case we can do nothing
5797     #
5798     # return values:
5799     #    0 - source will NOT need to be built separately by caller
5800     #   +1 - source will need to be built separately by caller
5801     #   +2 - source will need to be built separately by caller AND
5802     #        dpkg-buildpackage should not in fact be run at all!
5803     debugcmd '#massaging#', @$cmd if $debuglevel>1;
5804 #print STDERR "MASS0 ",Dumper($cmd, $xargs, $need_split_build_invocation);
5805     if ($cleanmode eq 'dpkg-source' && !$need_split_build_invocation) {
5806         $clean_using_builder = 1;
5807         return 0;
5808     }
5809     # -nc has the side effect of specifying -b if nothing else specified
5810     # and some combinations of -S, -b, et al, are errors, rather than
5811     # later simply overriding earlie.  So we need to:
5812     #  - search the command line for these options
5813     #  - pick the last one
5814     #  - perhaps add our own as a default
5815     #  - perhaps adjust it to the corresponding non-source-building version
5816     my $dmode = '-F';
5817     foreach my $l ($cmd, $xargs) {
5818         next unless $l;
5819         @$l = grep { !(m/^-[SgGFABb]$/s and $dmode=$_) } @$l;
5820     }
5821     push @$cmd, '-nc';
5822 #print STDERR "MASS1 ",Dumper($cmd, $xargs, $dmode);
5823     my $r = 0;
5824     if ($need_split_build_invocation) {
5825         printdebug "massage split $dmode.\n";
5826         $r = $dmode =~ m/[S]/     ? +2 :
5827              $dmode =~ y/gGF/ABb/ ? +1 :
5828              $dmode =~ m/[ABb]/   ?  0 :
5829              die "$dmode ?";
5830     }
5831     printdebug "massage done $r $dmode.\n";
5832     push @$cmd, $dmode;
5833 #print STDERR "MASS2 ",Dumper($cmd, $xargs, $r);
5834     return $r;
5835 }
5836
5837 sub in_parent (&) {
5838     my ($fn) = @_;
5839     my $wasdir = must_getcwd();
5840     changedir "..";
5841     $fn->();
5842     changedir $wasdir;
5843 }
5844
5845 sub postbuild_mergechanges ($) { # must run with CWD=.. (eg in in_parent)
5846     my ($msg_if_onlyone) = @_;
5847     # If there is only one .changes file, fail with $msg_if_onlyone,
5848     # or if that is undef, be a no-op.
5849     # Returns the changes file to report to the user.
5850     my $pat = changespat $version;
5851     my @changesfiles = glob $pat;
5852     @changesfiles = sort {
5853         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
5854             or $a cmp $b
5855     } @changesfiles;
5856     my $result;
5857     if (@changesfiles==1) {
5858         fail <<END.$msg_if_onlyone if defined $msg_if_onlyone;
5859 only one changes file from build (@changesfiles)
5860 END
5861         $result = $changesfiles[0];
5862     } elsif (@changesfiles==2) {
5863         my $binchanges = parsecontrol($changesfiles[1], "binary changes file");
5864         foreach my $l (split /\n/, getfield $binchanges, 'Files') {
5865             fail "$l found in binaries changes file $binchanges"
5866                 if $l =~ m/\.dsc$/;
5867         }
5868         runcmd_ordryrun_local @mergechanges, @changesfiles;
5869         my $multichanges = changespat $version,'multi';
5870         if (act_local()) {
5871             stat_exists $multichanges or fail "$multichanges: $!";
5872             foreach my $cf (glob $pat) {
5873                 next if $cf eq $multichanges;
5874                 rename "$cf", "$cf.inmulti" or fail "$cf\{,.inmulti}: $!";
5875             }
5876         }
5877         $result = $multichanges;
5878     } else {
5879         fail "wrong number of different changes files (@changesfiles)";
5880     }
5881     printdone "build successful, results in $result\n" or die $!;
5882 }
5883
5884 sub midbuild_checkchanges () {
5885     my $pat = changespat $version;
5886     return if $rmchanges;
5887     my @unwanted = map { s#^\.\./##; $_; } glob "../$pat";
5888     @unwanted = grep { $_ ne changespat $version,'source' } @unwanted;
5889     fail <<END
5890 changes files other than source matching $pat already present; building would result in ambiguity about the intended results.
5891 Suggest you delete @unwanted.
5892 END
5893         if @unwanted;
5894 }
5895
5896 sub midbuild_checkchanges_vanilla ($) {
5897     my ($wantsrc) = @_;
5898     midbuild_checkchanges() if $wantsrc == 1;
5899 }
5900
5901 sub postbuild_mergechanges_vanilla ($) {
5902     my ($wantsrc) = @_;
5903     if ($wantsrc == 1) {
5904         in_parent {
5905             postbuild_mergechanges(undef);
5906         };
5907     } else {
5908         printdone "build successful\n";
5909     }
5910 }
5911
5912 sub cmd_build {
5913     build_prep_early();
5914     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
5915     my $wantsrc = massage_dbp_args \@dbp;
5916     if ($wantsrc > 0) {
5917         build_source();
5918         midbuild_checkchanges_vanilla $wantsrc;
5919     } else {
5920         build_prep();
5921     }
5922     if ($wantsrc < 2) {
5923         push @dbp, changesopts_version();
5924         maybe_apply_patches_dirtily();
5925         runcmd_ordryrun_local @dbp;
5926     }
5927     maybe_unapply_patches_again();
5928     postbuild_mergechanges_vanilla $wantsrc;
5929 }
5930
5931 sub pre_gbp_build {
5932     $quilt_mode //= 'gbp';
5933 }
5934
5935 sub cmd_gbp_build {
5936     build_prep_early();
5937
5938     # gbp can make .origs out of thin air.  In my tests it does this
5939     # even for a 1.0 format package, with no origs present.  So I
5940     # guess it keys off just the version number.  We don't know
5941     # exactly what .origs ought to exist, but let's assume that we
5942     # should run gbp if: the version has an upstream part and the main
5943     # orig is absent.
5944     my $upstreamversion = upstreamversion $version;
5945     my $origfnpat = srcfn $upstreamversion, '.orig.tar.*';
5946     my $gbp_make_orig = $version =~ m/-/ && !(() = glob "../$origfnpat");
5947
5948     if ($gbp_make_orig) {
5949         clean_tree();
5950         $cleanmode = 'none'; # don't do it again
5951         $need_split_build_invocation = 1;
5952     }
5953
5954     my @dbp = @dpkgbuildpackage;
5955
5956     my $wantsrc = massage_dbp_args \@dbp, \@ARGV;
5957
5958     if (!length $gbp_build[0]) {
5959         if (length executable_on_path('git-buildpackage')) {
5960             $gbp_build[0] = qw(git-buildpackage);
5961         } else {
5962             $gbp_build[0] = 'gbp buildpackage';
5963         }
5964     }
5965     my @cmd = opts_opt_multi_cmd @gbp_build;
5966
5967     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
5968
5969     if ($gbp_make_orig) {
5970         ensuredir '.git/dgit';
5971         my $ok = '.git/dgit/origs-gen-ok';
5972         unlink $ok or $!==&ENOENT or die $!;
5973         my @origs_cmd = @cmd;
5974         push @origs_cmd, qw(--git-cleaner=true);
5975         push @origs_cmd, "--git-prebuild=touch $ok .git/dgit/no-such-dir/ok";
5976         push @origs_cmd, @ARGV;
5977         if (act_local()) {
5978             debugcmd @origs_cmd;
5979             system @origs_cmd;
5980             do { local $!; stat_exists $ok; }
5981                 or failedcmd @origs_cmd;
5982         } else {
5983             dryrun_report @origs_cmd;
5984         }
5985     }
5986
5987     if ($wantsrc > 0) {
5988         build_source();
5989         midbuild_checkchanges_vanilla $wantsrc;
5990     } else {
5991         if (!$clean_using_builder) {
5992             push @cmd, '--git-cleaner=true';
5993         }
5994         build_prep();
5995     }
5996     maybe_unapply_patches_again();
5997     if ($wantsrc < 2) {
5998         push @cmd, changesopts();
5999         runcmd_ordryrun_local @cmd, @ARGV;
6000     }
6001     postbuild_mergechanges_vanilla $wantsrc;
6002 }
6003 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
6004
6005 sub build_source {
6006     build_prep_early();
6007     my $our_cleanmode = $cleanmode;
6008     if ($need_split_build_invocation) {
6009         # Pretend that clean is being done some other way.  This
6010         # forces us not to try to use dpkg-buildpackage to clean and
6011         # build source all in one go; and instead we run dpkg-source
6012         # (and build_prep() will do the clean since $clean_using_builder
6013         # is false).
6014         $our_cleanmode = 'ELSEWHERE';
6015     }
6016     if ($our_cleanmode =~ m/^dpkg-source/) {
6017         # dpkg-source invocation (below) will clean, so build_prep shouldn't
6018         $clean_using_builder = 1;
6019     }
6020     build_prep();
6021     $sourcechanges = changespat $version,'source';
6022     if (act_local()) {
6023         unlink "../$sourcechanges" or $!==ENOENT
6024             or fail "remove $sourcechanges: $!";
6025     }
6026     $dscfn = dscfn($version);
6027     if ($our_cleanmode eq 'dpkg-source') {
6028         maybe_apply_patches_dirtily();
6029         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S),
6030             changesopts();
6031     } elsif ($our_cleanmode eq 'dpkg-source-d') {
6032         maybe_apply_patches_dirtily();
6033         runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc -S -d),
6034             changesopts();
6035     } else {
6036         my @cmd = (@dpkgsource, qw(-b --));
6037         if ($split_brain) {
6038             changedir $ud;
6039             runcmd_ordryrun_local @cmd, "work";
6040             my @udfiles = <${package}_*>;
6041             changedir "../../..";
6042             foreach my $f (@udfiles) {
6043                 printdebug "source copy, found $f\n";
6044                 next unless
6045                     $f eq $dscfn or
6046                     ($f =~ m/\.debian\.tar(?:\.\w+)$/ &&
6047                      $f eq srcfn($version, $&));
6048                 printdebug "source copy, found $f - renaming\n";
6049                 rename "$ud/$f", "../$f" or $!==ENOENT
6050                     or fail "put in place new source file ($f): $!";
6051             }
6052         } else {
6053             my $pwd = must_getcwd();
6054             my $leafdir = basename $pwd;
6055             changedir "..";
6056             runcmd_ordryrun_local @cmd, $leafdir;
6057             changedir $pwd;
6058         }
6059         runcmd_ordryrun_local qw(sh -ec),
6060             'exec >$1; shift; exec "$@"','x',
6061             "../$sourcechanges",
6062             @dpkggenchanges, qw(-S), changesopts();
6063     }
6064 }
6065
6066 sub cmd_build_source {
6067     build_prep_early();
6068     badusage "build-source takes no additional arguments" if @ARGV;
6069     build_source();
6070     maybe_unapply_patches_again();
6071     printdone "source built, results in $dscfn and $sourcechanges";
6072 }
6073
6074 sub cmd_sbuild {
6075     build_source();
6076     midbuild_checkchanges();
6077     in_parent {
6078         if (act_local()) {
6079             stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
6080             stat_exists $sourcechanges
6081                 or fail "$sourcechanges (in parent directory): $!";
6082         }
6083         runcmd_ordryrun_local @sbuild, qw(-d), $isuite, @ARGV, $dscfn;
6084     };
6085     maybe_unapply_patches_again();
6086     in_parent {
6087         postbuild_mergechanges(<<END);
6088 perhaps you need to pass -A ?  (sbuild's default is to build only
6089 arch-specific binaries; dgit 1.4 used to override that.)
6090 END
6091     };
6092 }
6093
6094 sub cmd_quilt_fixup {
6095     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
6096     build_prep_early();
6097     clean_tree();
6098     build_maybe_quilt_fixup();
6099 }
6100
6101 sub import_dsc_result {
6102     my ($dstref, $newhash, $what_log, $what_msg) = @_;
6103     my @cmd = (@git, qw(update-ref -m), $what_log, $dstref, $newhash);
6104     runcmd @cmd;
6105     progress "dgit: import-dsc: $what_msg";
6106 }
6107
6108 sub cmd_import_dsc {
6109     my $needsig = 0;
6110
6111     while (@ARGV) {
6112         last unless $ARGV[0] =~ m/^-/;
6113         $_ = shift @ARGV;
6114         last if m/^--?$/;
6115         if (m/^--require-valid-signature$/) {
6116             $needsig = 1;
6117         } else {
6118             badusage "unknown dgit import-dsc sub-option \`$_'";
6119         }
6120     }
6121
6122     badusage "usage: dgit import-dsc .../PATH/TO/.DSC BRANCH" unless @ARGV==2;
6123     my ($dscfn, $dstbranch) = @ARGV;
6124
6125     badusage "dry run makes no sense with import-dsc" unless act_local();
6126
6127     my $force = $dstbranch =~ s/^\+//   ? +1 :
6128                 $dstbranch =~ s/^\.\.// ? -1 :
6129                                            0;
6130     my $info = $force ? " $&" : '';
6131     $info = "$dscfn$info";
6132
6133     my $specbranch = $dstbranch;
6134     $dstbranch = "refs/heads/$dstbranch" unless $dstbranch =~ m#^refs/#;
6135     $dstbranch = cmdoutput @git, qw(check-ref-format --normalize), $dstbranch;
6136
6137     my @symcmd = (@git, qw(symbolic-ref -q HEAD));
6138     my $chead = cmdoutput_errok @symcmd;
6139     defined $chead or $?==256 or failedcmd @symcmd;
6140
6141     fail "$dstbranch is checked out - will not update it"
6142         if defined $chead and $chead eq $dstbranch;
6143
6144     my $oldhash = git_get_ref $dstbranch;
6145
6146     open D, "<", $dscfn or fail "open import .dsc ($dscfn): $!";
6147     $dscdata = do { local $/ = undef; <D>; };
6148     D->error and fail "read $dscfn: $!";
6149     close C;
6150
6151     # we don't normally need this so import it here
6152     use Dpkg::Source::Package;
6153     my $dp = new Dpkg::Source::Package filename => $dscfn,
6154         require_valid_signature => $needsig;
6155     {
6156         local $SIG{__WARN__} = sub {
6157             print STDERR $_[0];
6158             return unless $needsig;
6159             fail "import-dsc signature check failed";
6160         };
6161         if (!$dp->is_signed()) {
6162             warn "$us: warning: importing unsigned .dsc\n";
6163         } else {
6164             my $r = $dp->check_signature();
6165             die "->check_signature => $r" if $needsig && $r;
6166         }
6167     }
6168
6169     parse_dscdata();
6170
6171     $package = getfield $dsc, 'Source';
6172
6173     parse_dsc_field($dsc, "Dgit metadata in .dsc")
6174         unless forceing [qw(import-dsc-with-dgit-field)];
6175     parse_dsc_field_def_dsc_distro();
6176
6177     $isuite = 'DGIT-IMPORT-DSC';
6178     $idistro //= $dsc_distro;
6179
6180     notpushing();
6181
6182     if (defined $dsc_hash) {
6183         progress "dgit: import-dsc of .dsc with Dgit field, using git hash";
6184         resolve_dsc_field_commit undef, undef;
6185     }
6186     if (defined $dsc_hash) {
6187         my @cmd = (qw(sh -ec),
6188                    "echo $dsc_hash | git cat-file --batch-check");
6189         my $objgot = cmdoutput @cmd;
6190         if ($objgot =~ m#^\w+ missing\b#) {
6191             fail <<END
6192 .dsc contains Dgit field referring to object $dsc_hash
6193 Your git tree does not have that object.  Try `git fetch' from a
6194 plausible server (browse.dgit.d.o? alioth?), and try the import-dsc again.
6195 END
6196         }
6197         if ($oldhash && !is_fast_fwd $oldhash, $dsc_hash) {
6198             if ($force > 0) {
6199                 progress "Not fast forward, forced update.";
6200             } else {
6201                 fail "Not fast forward to $dsc_hash";
6202             }
6203         }
6204         import_dsc_result $dstbranch, $dsc_hash,
6205             "dgit import-dsc (Dgit): $info",
6206             "updated git ref $dstbranch";
6207         return 0;
6208     }
6209
6210     fail <<END
6211 Branch $dstbranch already exists
6212 Specify ..$specbranch for a pseudo-merge, binding in existing history
6213 Specify  +$specbranch to overwrite, discarding existing history
6214 END
6215         if $oldhash && !$force;
6216
6217     my @dfi = dsc_files_info();
6218     foreach my $fi (@dfi) {
6219         my $f = $fi->{Filename};
6220         my $here = "../$f";
6221         next if lstat $here;
6222         fail "stat $here: $!" unless $! == ENOENT;
6223         my $there = $dscfn;
6224         if ($dscfn =~ m#^(?:\./+)?\.\./+#) {
6225             $there = $';
6226         } elsif ($dscfn =~ m#^/#) {
6227             $there = $dscfn;
6228         } else {
6229             fail "cannot import $dscfn which seems to be inside working tree!";
6230         }
6231         $there =~ s#/+[^/]+$## or
6232             fail "cannot import $dscfn which seems to not have a basename";
6233         $there .= "/$f";
6234         symlink $there, $here or fail "symlink $there to $here: $!";
6235         progress "made symlink $here -> $there";
6236 #       print STDERR Dumper($fi);
6237     }
6238     my @mergeinputs = generate_commits_from_dsc();
6239     die unless @mergeinputs == 1;
6240
6241     my $newhash = $mergeinputs[0]{Commit};
6242
6243     if ($oldhash) {
6244         if ($force > 0) {
6245             progress "Import, forced update - synthetic orphan git history.";
6246         } elsif ($force < 0) {
6247             progress "Import, merging.";
6248             my $tree = cmdoutput @git, qw(rev-parse), "$newhash:";
6249             my $version = getfield $dsc, 'Version';
6250             my $clogp = commit_getclogp $newhash;
6251             my $authline = clogp_authline $clogp;
6252             $newhash = make_commit_text <<END;
6253 tree $tree
6254 parent $newhash
6255 parent $oldhash
6256 author $authline
6257 committer $authline
6258
6259 Merge $package ($version) import into $dstbranch
6260 END
6261         } else {
6262             die; # caught earlier
6263         }
6264     }
6265
6266     import_dsc_result $dstbranch, $newhash,
6267         "dgit import-dsc: $info",
6268         "results are in in git ref $dstbranch";
6269 }
6270
6271 sub cmd_archive_api_query {
6272     badusage "need only 1 subpath argument" unless @ARGV==1;
6273     my ($subpath) = @ARGV;
6274     my @cmd = archive_api_query_cmd($subpath);
6275     push @cmd, qw(-f);
6276     debugcmd ">",@cmd;
6277     exec @cmd or fail "exec curl: $!\n";
6278 }
6279
6280 sub cmd_clone_dgit_repos_server {
6281     badusage "need destination argument" unless @ARGV==1;
6282     my ($destdir) = @ARGV;
6283     $package = '_dgit-repos-server';
6284     local $access_forpush = 0;
6285     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
6286     debugcmd ">",@cmd;
6287     exec @cmd or fail "exec git clone: $!\n";
6288 }
6289
6290 sub cmd_print_dgit_repos_server_source_url {
6291     badusage "no arguments allowed to dgit print-dgit-repos-server-source-url"
6292         if @ARGV;
6293     $package = '_dgit-repos-server';
6294     local $access_forpush = 0;
6295     my $url = access_giturl();
6296     print $url, "\n" or die $!;
6297 }
6298
6299 sub cmd_setup_mergechangelogs {
6300     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
6301     setup_mergechangelogs(1);
6302 }
6303
6304 sub cmd_setup_useremail {
6305     badusage "no arguments allowed to dgit setup-useremail" if @ARGV;
6306     setup_useremail(1);
6307 }
6308
6309 sub cmd_setup_new_tree {
6310     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
6311     setup_new_tree();
6312 }
6313
6314 #---------- argument parsing and main program ----------
6315
6316 sub cmd_version {
6317     print "dgit version $our_version\n" or die $!;
6318     exit 0;
6319 }
6320
6321 our (%valopts_long, %valopts_short);
6322 our (%funcopts_long);
6323 our @rvalopts;
6324 our (@modeopt_cfgs);
6325
6326 sub defvalopt ($$$$) {
6327     my ($long,$short,$val_re,$how) = @_;
6328     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
6329     $valopts_long{$long} = $oi;
6330     $valopts_short{$short} = $oi;
6331     # $how subref should:
6332     #   do whatever assignemnt or thing it likes with $_[0]
6333     #   if the option should not be passed on to remote, @rvalopts=()
6334     # or $how can be a scalar ref, meaning simply assign the value
6335 }
6336
6337 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
6338 defvalopt '--distro',        '-d', '.+',      \$idistro;
6339 defvalopt '',                '-k', '.+',      \$keyid;
6340 defvalopt '--existing-package','', '.*',      \$existing_package;
6341 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
6342 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
6343 defvalopt '--package',   '-p',   $package_re, \$package;
6344 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
6345
6346 defvalopt '', '-C', '.+', sub {
6347     ($changesfile) = (@_);
6348     if ($changesfile =~ s#^(.*)/##) {
6349         $buildproductsdir = $1;
6350     }
6351 };
6352
6353 defvalopt '--initiator-tempdir','','.*', sub {
6354     ($initiator_tempdir) = (@_);
6355     $initiator_tempdir =~ m#^/# or
6356         badusage "--initiator-tempdir must be used specify an".
6357         " absolute, not relative, directory."
6358 };
6359
6360 sub defoptmodes ($@) {
6361     my ($varref, $cfgkey, $default, %optmap) = @_;
6362     my %permit;
6363     while (my ($opt,$val) = each %optmap) {
6364         $funcopts_long{$opt} = sub { $$varref = $val; };
6365         $permit{$val} = $val;
6366     }
6367     push @modeopt_cfgs, {
6368         Var => $varref,
6369         Key => $cfgkey,
6370         Default => $default,
6371         Vals => \%permit
6372     };
6373 }
6374
6375 defoptmodes \$dodep14tag, qw( dep14tag          want
6376                               --dep14tag        want
6377                               --no-dep14tag     no
6378                               --always-dep14tag always );
6379
6380 sub parseopts () {
6381     my $om;
6382
6383     if (defined $ENV{'DGIT_SSH'}) {
6384         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
6385     } elsif (defined $ENV{'GIT_SSH'}) {
6386         @ssh = ($ENV{'GIT_SSH'});
6387     }
6388
6389     my $oi;
6390     my $val;
6391     my $valopt = sub {
6392         my ($what) = @_;
6393         @rvalopts = ($_);
6394         if (!defined $val) {
6395             badusage "$what needs a value" unless @ARGV;
6396             $val = shift @ARGV;
6397             push @rvalopts, $val;
6398         }
6399         badusage "bad value \`$val' for $what" unless
6400             $val =~ m/^$oi->{Re}$(?!\n)/s;
6401         my $how = $oi->{How};
6402         if (ref($how) eq 'SCALAR') {
6403             $$how = $val;
6404         } else {
6405             $how->($val);
6406         }
6407         push @ropts, @rvalopts;
6408     };
6409
6410     while (@ARGV) {
6411         last unless $ARGV[0] =~ m/^-/;
6412         $_ = shift @ARGV;
6413         last if m/^--?$/;
6414         if (m/^--/) {
6415             if (m/^--dry-run$/) {
6416                 push @ropts, $_;
6417                 $dryrun_level=2;
6418             } elsif (m/^--damp-run$/) {
6419                 push @ropts, $_;
6420                 $dryrun_level=1;
6421             } elsif (m/^--no-sign$/) {
6422                 push @ropts, $_;
6423                 $sign=0;
6424             } elsif (m/^--help$/) {
6425                 cmd_help();
6426             } elsif (m/^--version$/) {
6427                 cmd_version();
6428             } elsif (m/^--new$/) {
6429                 push @ropts, $_;
6430                 $new_package=1;
6431             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
6432                      ($om = $opts_opt_map{$1}) &&
6433                      length $om->[0]) {
6434                 push @ropts, $_;
6435                 $om->[0] = $2;
6436             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
6437                      !$opts_opt_cmdonly{$1} &&
6438                      ($om = $opts_opt_map{$1})) {
6439                 push @ropts, $_;
6440                 push @$om, $2;
6441             } elsif (m/^--(gbp|dpm)$/s) {
6442                 push @ropts, "--quilt=$1";
6443                 $quilt_mode = $1;
6444             } elsif (m/^--ignore-dirty$/s) {
6445                 push @ropts, $_;
6446                 $ignoredirty = 1;
6447             } elsif (m/^--no-quilt-fixup$/s) {
6448                 push @ropts, $_;
6449                 $quilt_mode = 'nocheck';
6450             } elsif (m/^--no-rm-on-error$/s) {
6451                 push @ropts, $_;
6452                 $rmonerror = 0;
6453             } elsif (m/^--no-chase-dsc-distro$/s) {
6454                 push @ropts, $_;
6455                 $chase_dsc_distro = 0;
6456             } elsif (m/^--overwrite$/s) {
6457                 push @ropts, $_;
6458                 $overwrite_version = '';
6459             } elsif (m/^--overwrite=(.+)$/s) {
6460                 push @ropts, $_;
6461                 $overwrite_version = $1;
6462             } elsif (m/^--delayed=(\d+)$/s) {
6463                 push @ropts, $_;
6464                 push @dput, $_;
6465             } elsif (m/^--dgit-view-save=(.+)$/s) {
6466                 push @ropts, $_;
6467                 $split_brain_save = $1;
6468                 $split_brain_save =~ s#^(?!refs/)#refs/heads/#;
6469             } elsif (m/^--(no-)?rm-old-changes$/s) {
6470                 push @ropts, $_;
6471                 $rmchanges = !$1;
6472             } elsif (m/^--deliberately-($deliberately_re)$/s) {
6473                 push @ropts, $_;
6474                 push @deliberatelies, $&;
6475             } elsif (m/^--force-(.*)/ && defined $forceopts{$1}) {
6476                 push @ropts, $&;
6477                 $forceopts{$1} = 1;
6478                 $_='';
6479             } elsif (m/^--force-/) {
6480                 print STDERR
6481                     "$us: warning: ignoring unknown force option $_\n";
6482                 $_='';
6483             } elsif (m/^--dgit-tag-format=(old|new)$/s) {
6484                 # undocumented, for testing
6485                 push @ropts, $_;
6486                 $tagformat_want = [ $1, 'command line', 1 ];
6487                 # 1 menas overrides distro configuration
6488             } elsif (m/^--always-split-source-build$/s) {
6489                 # undocumented, for testing
6490                 push @ropts, $_;
6491                 $need_split_build_invocation = 1;
6492             } elsif (m/^--config-lookup-explode=(.+)$/s) {
6493                 # undocumented, for testing
6494                 push @ropts, $_;
6495                 $gitcfgs{cmdline}{$1} = 'CONFIG-LOOKUP-EXPLODE';
6496                 # ^ it's supposed to be an array ref
6497             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
6498                 $val = $2 ? $' : undef; #';
6499                 $valopt->($oi->{Long});
6500             } elsif ($funcopts_long{$_}) {
6501                 push @ropts, $_;
6502                 $funcopts_long{$_}();
6503             } else {
6504                 badusage "unknown long option \`$_'";
6505             }
6506         } else {
6507             while (m/^-./s) {
6508                 if (s/^-n/-/) {
6509                     push @ropts, $&;
6510                     $dryrun_level=2;
6511                 } elsif (s/^-L/-/) {
6512                     push @ropts, $&;
6513                     $dryrun_level=1;
6514                 } elsif (s/^-h/-/) {
6515                     cmd_help();
6516                 } elsif (s/^-D/-/) {
6517                     push @ropts, $&;
6518                     $debuglevel++;
6519                     enabledebug();
6520                 } elsif (s/^-N/-/) {
6521                     push @ropts, $&;
6522                     $new_package=1;
6523                 } elsif (m/^-m/) {
6524                     push @ropts, $&;
6525                     push @changesopts, $_;
6526                     $_ = '';
6527                 } elsif (s/^-wn$//s) {
6528                     push @ropts, $&;
6529                     $cleanmode = 'none';
6530                 } elsif (s/^-wg$//s) {
6531                     push @ropts, $&;
6532                     $cleanmode = 'git';
6533                 } elsif (s/^-wgf$//s) {
6534                     push @ropts, $&;
6535                     $cleanmode = 'git-ff';
6536                 } elsif (s/^-wd$//s) {
6537                     push @ropts, $&;
6538                     $cleanmode = 'dpkg-source';
6539                 } elsif (s/^-wdd$//s) {
6540                     push @ropts, $&;
6541                     $cleanmode = 'dpkg-source-d';
6542                 } elsif (s/^-wc$//s) {
6543                     push @ropts, $&;
6544                     $cleanmode = 'check';
6545                 } elsif (s/^-c([^=]*)\=(.*)$//s) {
6546                     push @git, '-c', $&;
6547                     $gitcfgs{cmdline}{$1} = [ $2 ];
6548                 } elsif (s/^-c([^=]+)$//s) {
6549                     push @git, '-c', $&;
6550                     $gitcfgs{cmdline}{$1} = [ 'true' ];
6551                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
6552                     $val = $'; #';
6553                     $val = undef unless length $val;
6554                     $valopt->($oi->{Short});
6555                     $_ = '';
6556                 } else {
6557                     badusage "unknown short option \`$_'";
6558                 }
6559             }
6560         }
6561     }
6562 }
6563
6564 sub check_env_sanity () {
6565     my $blocked = new POSIX::SigSet;
6566     sigprocmask SIG_UNBLOCK, $blocked, $blocked or die $!;
6567
6568     eval {
6569         foreach my $name (qw(PIPE CHLD)) {
6570             my $signame = "SIG$name";
6571             my $signum = eval "POSIX::$signame" // die;
6572             ($SIG{$name} // 'DEFAULT') eq 'DEFAULT' or
6573                 die "$signame is set to something other than SIG_DFL\n";
6574             $blocked->ismember($signum) and
6575                 die "$signame is blocked\n";
6576         }
6577     };
6578     return unless $@;
6579     chomp $@;
6580     fail <<END;
6581 On entry to dgit, $@
6582 This is a bug produced by something in in your execution environment.
6583 Giving up.
6584 END
6585 }
6586
6587
6588 sub parseopts_late_defaults () {
6589     $isuite //= cfg("dgit-distro.$idistro.default-suite", 'RETURN-UNDEF')
6590         if defined $idistro;
6591     $isuite //= cfg('dgit.default.default-suite');
6592
6593     foreach my $k (keys %opts_opt_map) {
6594         my $om = $opts_opt_map{$k};
6595
6596         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
6597         if (defined $v) {
6598             badcfg "cannot set command for $k"
6599                 unless length $om->[0];
6600             $om->[0] = $v;
6601         }
6602
6603         foreach my $c (access_cfg_cfgs("opts-$k")) {
6604             my @vl =
6605                 map { $_ ? @$_ : () }
6606                 map { $gitcfgs{$_}{$c} }
6607                 reverse @gitcfgsources;
6608             printdebug "CL $c ", (join " ", map { shellquote } @vl),
6609                 "\n" if $debuglevel >= 4;
6610             next unless @vl;
6611             badcfg "cannot configure options for $k"
6612                 if $opts_opt_cmdonly{$k};
6613             my $insertpos = $opts_cfg_insertpos{$k};
6614             @$om = ( @$om[0..$insertpos-1],
6615                      @vl,
6616                      @$om[$insertpos..$#$om] );
6617         }
6618     }
6619
6620     if (!defined $rmchanges) {
6621         local $access_forpush;
6622         $rmchanges = access_cfg_bool(0, 'rm-old-changes');
6623     }
6624
6625     if (!defined $quilt_mode) {
6626         local $access_forpush;
6627         $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
6628             // access_cfg('quilt-mode', 'RETURN-UNDEF')
6629             // 'linear';
6630         $quilt_mode =~ m/^($quilt_modes_re)$/
6631             or badcfg "unknown quilt-mode \`$quilt_mode'";
6632         $quilt_mode = $1;
6633     }
6634
6635     foreach my $moc (@modeopt_cfgs) {
6636         local $access_forpush;
6637         my $vr = $moc->{Var};
6638         next if defined $$vr;
6639         $$vr = access_cfg($moc->{Key}, 'RETURN-UNDEF') // $moc->{Default};
6640         my $v = $moc->{Vals}{$$vr};
6641         badcfg "unknown $moc->{Key} setting \`$$vr'" unless defined $v;
6642         $$vr = $v;
6643     }
6644
6645     $need_split_build_invocation ||= quiltmode_splitbrain();
6646
6647     if (!defined $cleanmode) {
6648         local $access_forpush;
6649         $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
6650         $cleanmode //= 'dpkg-source';
6651
6652         badcfg "unknown clean-mode \`$cleanmode'" unless
6653             $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
6654     }
6655 }
6656
6657 if ($ENV{$fakeeditorenv}) {
6658     git_slurp_config();
6659     quilt_fixup_editor();
6660 }
6661
6662 parseopts();
6663 check_env_sanity();
6664 git_slurp_config();
6665
6666 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
6667 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
6668     if $dryrun_level == 1;
6669 if (!@ARGV) {
6670     print STDERR $helpmsg or die $!;
6671     exit 8;
6672 }
6673 my $cmd = shift @ARGV;
6674 $cmd =~ y/-/_/;
6675
6676 my $pre_fn = ${*::}{"pre_$cmd"};
6677 $pre_fn->() if $pre_fn;
6678
6679 my $fn = ${*::}{"cmd_$cmd"};
6680 $fn or badusage "unknown operation $cmd";
6681 $fn->();