Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10
  11 BEGIN {
  12     use Exporter   ();
  13     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  14
  15     $VERSION     = 1.00;
  16     @ISA         = qw(Exporter);
  17     @EXPORT      = qw(debiantag server_branch server_ref
  18                       stat_exists git_for_each_ref
  19                       git_for_each_tag_referring
  20                       $package_re $component_re $branchprefix
  21                       initdebug enabledebug enabledebuglevel
  22                       printdebug debugcmd
  23                       $debugprefix *debuglevel *DEBUG
  24                       shellquote printcmd);
  25     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  26     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  27 }
  28
  29 our @EXPORT_OK;
  30
  31 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  32 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  33 our $branchprefix = 'dgit';
  34
  35 # policy hook exit status bits
  36 # see dgit-repos-server head comment for documentation
  37 # 1 is reserved in case something fails with `exit 1'
  38 sub NOFFCHECK () { return 0x2; }
  39 sub FRESHREPO () { return 0x4; }
  40 # 0x80 is reserved
  41
  42 sub debiantag ($) {
  43     my ($v) = @_;
  44     $v =~ y/~:/_%/;
  45     return "debian/$v";
  46 }
  47
  48 sub server_branch ($) { return "$branchprefix/$_[0]"; }
  49 sub server_ref ($) { return "refs/".server_branch($_[0]); }
  50
  51 sub stat_exists ($) {
  52     my ($f) = @_;
  53     return 1 if stat $f;
  54     return 0 if $!==&ENOENT;
  55     die "stat $f: $!";
  56 }
  57
  58 sub git_for_each_ref ($$) {
  59     my ($pattern,$func) = @_;
  60     # calls $func->($objid,$objtype,$fullrefname,$reftail);
  61     # $reftail is RHS of ref after refs/\w+/
  62     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
  63     open GFER, "-|", qw(git for-each-ref), $pattern or die $!;
  64     while (<GFER>) {
  65         m#^(\w+)\s+(\w+)\s+(refs/\w+/(\S+))\s# or die "$_ ?";
  66         $func->($1,$2,$3,$4);
  67     }
  68     $!=0; $?=0; close GFER or die "$pattern $? $!";
  69 }
  70
  71 sub git_for_each_tag_referring ($$) {
  72     my ($objreferring, $func) = @_;
  73     # calls $func->($objid,$fullrefname,$tagname);
  74     git_for_each_ref('refs/tags', sub {
  75         my ($objid,$objtype,$fullrefname,$tagname) = @_;
  76         next unless $objtype eq 'tag';
  77         next if defined $objreferring and $objid ne $objreferring;
  78         $func->($objid,$fullrefname,$tagname);
  79     });
  80 }
  81
  82 our $debugprefix;
  83 our $debuglevel = 0;
  84
  85 sub initdebug ($) {
  86     ($debugprefix) = @_;
  87     open DEBUG, ">/dev/null" or die $!;
  88 }
  89
  90 sub enabledebug () {
  91     open DEBUG, ">&STDERR" or die $!;
  92     DEBUG->autoflush(1);
  93     $debuglevel ||= 1;
  94 }
  95
  96 sub enabledebuglevel ($) {
  97     my ($newlevel) = @_; # may be undef (eg from env var)
  98     die if $debuglevel;
  99     $newlevel //= 0;
 100     $newlevel += 0;
 101     return unless $newlevel;
 102     $debuglevel = $newlevel;
 103     enabledebug();
 104 }
 105
 106 sub printdebug {
 107     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 108 }
 109
 110 sub shellquote {
 111     my @out;
 112     local $_;
 113     foreach my $a (@_) {
 114         $_ = $a;
 115         if (!length || m{[^-=_./0-9a-z]}i) {
 116             s{['\\]}{'\\$&'}g;
 117             push @out, "'$_'";
 118         } else {
 119             push @out, $_;
 120         }
 121     }
 122     return join ' ', @out;
 123 }
 124
 125 sub printcmd {
 126     my $fh = shift @_;
 127     my $intro = shift @_;
 128     print $fh $intro," " or die $!;
 129     print $fh shellquote @_ or die $!;
 130     print $fh "\n" or die $!;
 131 }
 132
 133 sub debugcmd {
 134     my $extraprefix = shift @_;
 135     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 136 }
 137
 138 1;