Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32
  33 BEGIN {
  34     use Exporter   ();
  35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  36
  37     $VERSION     = 1.00;
  38     @ISA         = qw(Exporter);
  39     @EXPORT      = qw(setup_sigwarn
  40                       dep14_version_mangle
  41                       debiantags debiantag_old debiantag_new
  42                       server_branch server_ref
  43                       stat_exists link_ltarget
  44                       hashfile
  45                       fail ensuredir executable_on_path
  46                       waitstatusmsg failedcmd_waitstatus
  47                       failedcmd_report_cmd failedcmd
  48                       cmdoutput cmdoutput_errok
  49                       git_rev_parse git_cat_file
  50                       git_get_ref git_for_each_ref
  51                       git_for_each_tag_referring is_fast_fwd
  52                       $package_re $component_re $deliberately_re
  53                       $distro_re $versiontag_re
  54                       $branchprefix
  55                       initdebug enabledebug enabledebuglevel
  56                       printdebug debugcmd
  57                       $debugprefix *debuglevel *DEBUG
  58                       shellquote printcmd messagequote);
  59     # implicitly uses $main::us
  60     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)] );
  61     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  62 }
  63
  64 our @EXPORT_OK;
  65
  66 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  67 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  68 our $deliberately_re = "(?:TEST-)?$package_re";
  69 our $distro_re = $component_re;
  70 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  71 our $branchprefix = 'dgit';
  72
  73 # policy hook exit status bits
  74 # see dgit-repos-server head comment for documentation
  75 # 1 is reserved in case something fails with `exit 1' and to spot
  76 # dynamic loader, runtime, etc., failures, which report 127 or 255
  77 sub NOFFCHECK () { return 0x2; }
  78 sub FRESHREPO () { return 0x4; }
  79 sub NOCOMMITCHECK () { return 0x8; }
  80
  81 our $debugprefix;
  82 our $debuglevel = 0;
  83
  84 sub setup_sigwarn () {
  85     our $sigwarn_mainprocess = $$;
  86     $SIG{__WARN__} = sub {
  87         die $_[0] unless getppid == $sigwarn_mainprocess;
  88     };
  89 }
  90
  91 sub initdebug ($) {
  92     ($debugprefix) = @_;
  93     open DEBUG, ">/dev/null" or die $!;
  94 }
  95
  96 sub enabledebug () {
  97     open DEBUG, ">&STDERR" or die $!;
  98     DEBUG->autoflush(1);
  99     $debuglevel ||= 1;
 100 }
 101
 102 sub enabledebuglevel ($) {
 103     my ($newlevel) = @_; # may be undef (eg from env var)
 104     die if $debuglevel;
 105     $newlevel //= 0;
 106     $newlevel += 0;
 107     return unless $newlevel;
 108     $debuglevel = $newlevel;
 109     enabledebug();
 110 }
 111
 112 sub printdebug {
 113     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 114 }
 115
 116 sub messagequote ($) {
 117     local ($_) = @_;
 118     s{\\}{\\\\}g;
 119     s{\n}{\\n}g;
 120     s{\x08}{\\b}g;
 121     s{\t}{\\t}g;
 122     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 123     $_;
 124 }
 125
 126 sub shellquote {
 127     my @out;
 128     local $_;
 129     foreach my $a (@_) {
 130         $_ = $a;
 131         if (!length || m{[^-=_./:0-9a-z]}i) {
 132             s{['\\]}{'\\$&'}g;
 133             push @out, "'$_'";
 134         } else {
 135             push @out, $_;
 136         }
 137     }
 138     return join ' ', @out;
 139 }
 140
 141 sub printcmd {
 142     my $fh = shift @_;
 143     my $intro = shift @_;
 144     print $fh $intro," " or die $!;
 145     print $fh shellquote @_ or die $!;
 146     print $fh "\n" or die $!;
 147 }
 148
 149 sub debugcmd {
 150     my $extraprefix = shift @_;
 151     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 152 }
 153
 154 sub dep14_version_mangle ($) {
 155     my ($v) = @_;
 156     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 157     $v =~ y/~:/_%/;
 158     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 159     return $v;
 160 }
 161
 162 sub debiantag_old ($$) {
 163     my ($v,$distro) = @_;
 164     return "$distro/". dep14_version_mangle $v;
 165 }
 166
 167 sub debiantag_new ($$) {
 168     my ($v,$distro) = @_;
 169     return "archive/$distro/".dep14_version_mangle $v;
 170 }
 171
 172 sub debiantags ($$) {
 173     my ($version,$distro) = @_;
 174     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 175 }
 176
 177 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 178 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 179
 180 sub stat_exists ($) {
 181     my ($f) = @_;
 182     return 1 if stat $f;
 183     return 0 if $!==&ENOENT;
 184     die "stat $f: $!";
 185 }
 186
 187 sub _us () {
 188     $::us // ($0 =~ m#[^/]*$#, $&);
 189 }
 190
 191 sub fail {
 192     my $s = "@_\n";
 193     $s =~ s/\n\n$/\n/;
 194     my $prefix = _us().": ";
 195     $s =~ s/^/$prefix/gm;
 196     die $s;
 197 }
 198
 199 sub ensuredir ($) {
 200     my ($dir) = @_; # does not create parents
 201     return if mkdir $dir;
 202     return if $! == EEXIST;
 203     die "mkdir $dir: $!";
 204 }
 205
 206 sub executable_on_path ($) {
 207     my ($program) = @_;
 208     return 1 if $program =~ m{/};
 209     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 210     foreach my $pe (@path) {
 211         my $here = "$pe/$program";
 212         return $here if stat_exists $here && -x _;
 213     }
 214     return undef;
 215 }
 216
 217 our @signames = split / /, $Config{sig_name};
 218
 219 sub waitstatusmsg () {
 220     if (!$?) {
 221         return "terminated, reporting successful completion";
 222     } elsif (!($? & 255)) {
 223         return "failed with error exit status ".WEXITSTATUS($?);
 224     } elsif (WIFSIGNALED($?)) {
 225         my $signum=WTERMSIG($?);
 226         return "died due to fatal signal ".
 227             ($signames[$signum] // "number $signum").
 228             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 229     } else {
 230         return "failed with unknown wait status ".$?;
 231     }
 232 }
 233
 234 sub failedcmd_report_cmd {
 235     my $intro = shift @_;
 236     $intro //= "failed command";
 237     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 238 }
 239
 240 sub failedcmd_waitstatus {
 241     if ($? < 0) {
 242         return "failed to fork/exec: $!";
 243     } elsif ($?) {
 244         return "subprocess ".waitstatusmsg();
 245     } else {
 246         return "subprocess produced invalid output";
 247     }
 248 }
 249
 250 sub failedcmd {
 251     # Expects $!,$? as set by close - see below.
 252     # To use with system(), set $?=-1 first.
 253     #
 254     # Actual behaviour of perl operations:
 255     #   success              $!==0       $?==0       close of piped open
 256     #   program failed       $!==0       $? >0       close of piped open
 257     #   syscall failure      $! >0       $?=-1       close of piped open
 258     #   failure              $! >0       unchanged   close of something else
 259     #   success              trashed     $?==0       system
 260     #   program failed       trashed     $? >0       system
 261     #   syscall failure      $! >0       unchanged   system
 262     failedcmd_report_cmd undef, @_;
 263     fail failedcmd_waitstatus();
 264 }
 265
 266 sub cmdoutput_errok {
 267     confess Dumper(\@_)." ?" if grep { !defined } @_;
 268     debugcmd "|",@_;
 269     open P, "-|", @_ or die "$_[0] $!";
 270     my $d;
 271     $!=0; $?=0;
 272     { local $/ = undef; $d = <P>; }
 273     die $! if P->error;
 274     if (!close P) { printdebug "=>!$?\n"; return undef; }
 275     chomp $d;
 276     if ($debuglevel > 0) {
 277         $d =~ m/^.*/;
 278         my $dd = $&;
 279         my $more = (length $' ? '...' : ''); #');
 280         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 281         printdebug "=> \`$dd'",$more,"\n";
 282     }
 283     return $d;
 284 }
 285
 286 sub cmdoutput {
 287     my $d = cmdoutput_errok @_;
 288     defined $d or failedcmd @_;
 289     return $d;
 290 }
 291
 292 sub link_ltarget ($$) {
 293     my ($old,$new) = @_;
 294     lstat $old or return undef;
 295     if (-l _) {
 296         $old = cmdoutput qw(realpath  --), $old;
 297     }
 298     my $r = link $old, $new;
 299     $r = symlink $old, $new if !$r && $!==EXDEV;
 300     $r or die "(sym)link $old $new: $!";
 301 }
 302
 303 sub hashfile ($) {
 304     my ($fn) = @_;
 305     my $h = Digest::SHA->new(256);
 306     $h->addfile($fn);
 307     return $h->hexdigest();
 308 }
 309
 310 sub git_rev_parse ($) {
 311     return cmdoutput qw(git rev-parse), "$_[0]~0";
 312 }
 313
 314 sub git_cat_file ($) {
 315     my ($objname) = @_;
 316     # => ($type, $data) or ('missing', undef)
 317     # in scalar context, just the data
 318     our ($gcf_pid, $gcf_i, $gcf_o);
 319     if (!$gcf_pid) {
 320         my @cmd = qw(git cat-file --batch);
 321         debugcmd "GCF|", @cmd;
 322         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 323     }
 324     printdebug "GCF>| ", $objname, "\n";
 325     print $gcf_i $objname, "\n" or die $!;
 326     my $x = <$gcf_o>;
 327     printdebug "GCF<| ", $x;
 328     if ($x =~ m/ (missing)$/) { return ($1, undef); }
 329     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 330     my $data;
 331     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 332     $x = <$gcf_o>;
 333     $x eq "\n" or die "$objname ($_) $!";
 334     return ($type, $data);
 335 }
 336
 337 sub git_for_each_ref ($$;$) {
 338     my ($pattern,$func,$gitdir) = @_;
 339     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 340     # $reftail is RHS of ref after refs/[^/]+/
 341     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 342     # $pattern may be an array ref to mean multiple patterns
 343     $pattern = [ $pattern ] unless ref $pattern;
 344     my @cmd = (qw(git for-each-ref), @$pattern);
 345     if (defined $gitdir) {
 346         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 347     }
 348     open GFER, "-|", @cmd or die $!;
 349     debugcmd "|", @cmd;
 350     while (<GFER>) {
 351         chomp or die "$_ ?";
 352         printdebug "|> ", $_, "\n";
 353         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 354         $func->($1,$2,$3,$4);
 355     }
 356     $!=0; $?=0; close GFER or die "$pattern $? $!";
 357 }
 358
 359 sub git_get_ref ($) {
 360     # => '' if no such ref
 361     my ($refname) = @_;
 362     local $_ = $refname;
 363     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 364     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 365 }
 366
 367 sub git_for_each_tag_referring ($$) {
 368     my ($objreferring, $func) = @_;
 369     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 370     printdebug "git_for_each_tag_referring ",
 371         ($objreferring // 'UNDEF'),"\n";
 372     git_for_each_ref('refs/tags', sub {
 373         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 374         return unless $objtype eq 'tag';
 375         my $refobjid = git_rev_parse $tagobjid;
 376         return unless
 377             !defined $objreferring # caller wants them all
 378             or $tagobjid eq $objreferring
 379             or $refobjid eq $objreferring;
 380         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 381     });
 382 }
 383
 384 sub is_fast_fwd ($$) {
 385     my ($ancestor,$child) = @_;
 386     my @cmd = (qw(git merge-base), $ancestor, $child);
 387     my $mb = cmdoutput_errok @cmd;
 388     if (defined $mb) {
 389         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 390     } else {
 391         $?==256 or failedcmd @cmd;
 392         return 0;
 393     }
 394 }
 395
 396 1;