Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11
  12 BEGIN {
  13     use Exporter   ();
  14     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  15
  16     $VERSION     = 1.00;
  17     @ISA         = qw(Exporter);
  18     @EXPORT      = qw(setup_sigwarn
  19                       debiantag server_branch server_ref
  20                       stat_exists fail ensuredir executable_on_path
  21                       waitstatusmsg failedcmd
  22                       cmdoutput cmdoutput_errok
  23                       git_rev_parse git_get_ref git_for_each_ref
  24                       git_for_each_tag_referring is_fast_fwd
  25                       $package_re $component_re $deliberately_re
  26                       $branchprefix
  27                       initdebug enabledebug enabledebuglevel
  28                       printdebug debugcmd
  29                       $debugprefix *debuglevel *DEBUG
  30                       shellquote printcmd messagequote);
  31     # implicitly uses $main::us
  32     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  33     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  34 }
  35
  36 our @EXPORT_OK;
  37
  38 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  39 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  40 our $deliberately_re = "(?:TEST-)?$package_re";
  41 our $branchprefix = 'dgit';
  42
  43 # policy hook exit status bits
  44 # see dgit-repos-server head comment for documentation
  45 # 1 is reserved in case something fails with `exit 1' and to spot
  46 # dynamic loader, runtime, etc., failures, which report 127 or 255
  47 sub NOFFCHECK () { return 0x2; }
  48 sub FRESHREPO () { return 0x4; }
  49
  50 our $debugprefix;
  51 our $debuglevel = 0;
  52
  53 sub setup_sigwarn () {
  54     our $sigwarn_mainprocess = $$;
  55     $SIG{__WARN__} = sub {
  56         die $_[0] unless getppid == $sigwarn_mainprocess;
  57     };
  58 }
  59
  60 sub initdebug ($) {
  61     ($debugprefix) = @_;
  62     open DEBUG, ">/dev/null" or die $!;
  63 }
  64
  65 sub enabledebug () {
  66     open DEBUG, ">&STDERR" or die $!;
  67     DEBUG->autoflush(1);
  68     $debuglevel ||= 1;
  69 }
  70
  71 sub enabledebuglevel ($) {
  72     my ($newlevel) = @_; # may be undef (eg from env var)
  73     die if $debuglevel;
  74     $newlevel //= 0;
  75     $newlevel += 0;
  76     return unless $newlevel;
  77     $debuglevel = $newlevel;
  78     enabledebug();
  79 }
  80
  81 sub printdebug {
  82     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  83 }
  84
  85 sub messagequote ($) {
  86     local ($_) = @_;
  87     s{\\}{\\\\}g;
  88     s{\n}{\\n}g;
  89     s{\x08}{\\b}g;
  90     s{\t}{\\t}g;
  91     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  92     $_;
  93 }
  94
  95 sub shellquote {
  96     my @out;
  97     local $_;
  98     foreach my $a (@_) {
  99         $_ = $a;
 100         if (!length || m{[^-=_./:0-9a-z]}i) {
 101             s{['\\]}{'\\$&'}g;
 102             push @out, "'$_'";
 103         } else {
 104             push @out, $_;
 105         }
 106     }
 107     return join ' ', @out;
 108 }
 109
 110 sub printcmd {
 111     my $fh = shift @_;
 112     my $intro = shift @_;
 113     print $fh $intro," " or die $!;
 114     print $fh shellquote @_ or die $!;
 115     print $fh "\n" or die $!;
 116 }
 117
 118 sub debugcmd {
 119     my $extraprefix = shift @_;
 120     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 121 }
 122
 123 sub debiantag ($$) {
 124     my ($v,$distro) = @_;
 125     $v =~ y/~:/_%/;
 126     return "$distro/$v";
 127 }
 128
 129 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 130 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 131
 132 sub stat_exists ($) {
 133     my ($f) = @_;
 134     return 1 if stat $f;
 135     return 0 if $!==&ENOENT;
 136     die "stat $f: $!";
 137 }
 138
 139 sub _us () {
 140     $::us // ($0 =~ m#[^/]*$#, $&);
 141 }
 142
 143 sub fail {
 144     my $s = "@_\n";
 145     my $prefix = _us().": ";
 146     $s =~ s/^/$prefix/gm;
 147     die $s;
 148 }
 149
 150 sub ensuredir ($) {
 151     my ($dir) = @_; # does not create parents
 152     return if mkdir $dir;
 153     return if $! == EEXIST;
 154     die "mkdir $dir: $!";
 155 }
 156
 157 sub executable_on_path ($) {
 158     my ($program) = @_;
 159     return 1 if $program =~ m{/};
 160     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 161     foreach my $pe (@path) {
 162         my $here = "$pe/$program";
 163         return $here if stat_exists $here && -x _;
 164     }
 165     return undef;
 166 }
 167
 168 our @signames = split / /, $Config{sig_name};
 169
 170 sub waitstatusmsg () {
 171     if (!$?) {
 172         return "terminated, reporting successful completion";
 173     } elsif (!($? & 255)) {
 174         return "failed with error exit status ".WEXITSTATUS($?);
 175     } elsif (WIFSIGNALED($?)) {
 176         my $signum=WTERMSIG($?);
 177         return "died due to fatal signal ".
 178             ($signames[$signum] // "number $signum").
 179             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 180     } else {
 181         return "failed with unknown wait status ".$?;
 182     }
 183 }
 184
 185 sub failedcmd {
 186     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 187     if ($!) {
 188         fail "failed to fork/exec: $!";
 189     } elsif ($?) {
 190         fail "subprocess ".waitstatusmsg();
 191     } else {
 192         fail "subprocess produced invalid output";
 193     }
 194 }
 195
 196 sub cmdoutput_errok {
 197     die Dumper(\@_)." ?" if grep { !defined } @_;
 198     debugcmd "|",@_;
 199     open P, "-|", @_ or die "$_[0] $!";
 200     my $d;
 201     $!=0; $?=0;
 202     { local $/ = undef; $d = <P>; }
 203     die $! if P->error;
 204     if (!close P) { printdebug "=>!$?\n"; return undef; }
 205     chomp $d;
 206     if ($debuglevel > 0) {
 207         $d =~ m/^.*/;
 208         my $dd = $&;
 209         my $more = (length $' ? '...' : ''); #');
 210         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 211         printdebug "=> \`$dd'",$more,"\n";
 212     }
 213     return $d;
 214 }
 215
 216 sub cmdoutput {
 217     my $d = cmdoutput_errok @_;
 218     defined $d or failedcmd @_;
 219     return $d;
 220 }
 221
 222 sub git_rev_parse ($) {
 223     return cmdoutput qw(git rev-parse), "$_[0]~0";
 224 }
 225
 226 sub git_for_each_ref ($$;$) {
 227     my ($pattern,$func,$gitdir) = @_;
 228     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 229     # $reftail is RHS of ref after refs/[^/]+/
 230     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 231     my @cmd = (qw(git for-each-ref), $pattern);
 232     if (defined $gitdir) {
 233         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 234     }
 235     open GFER, "-|", @cmd or die $!;
 236     debugcmd "|", @cmd;
 237     while (<GFER>) {
 238         chomp or die "$_ ?";
 239         printdebug "|> ", $_, "\n";
 240         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 241         $func->($1,$2,$3,$4);
 242     }
 243     $!=0; $?=0; close GFER or die "$pattern $? $!";
 244 }
 245
 246 sub git_get_ref ($) {
 247     # => '' if no such ref
 248     my ($refname) = @_;
 249     local $_ = $refname;
 250     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 251     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 252 }
 253
 254 sub git_for_each_tag_referring ($$) {
 255     my ($objreferring, $func) = @_;
 256     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 257     printdebug "git_for_each_tag_referring ",
 258         ($objreferring // 'UNDEF'),"\n";
 259     git_for_each_ref('refs/tags', sub {
 260         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 261         return unless $objtype eq 'tag';
 262         my $refobjid = git_rev_parse $tagobjid;
 263         return unless
 264             !defined $objreferring # caller wants them all
 265             or $tagobjid eq $objreferring
 266             or $refobjid eq $objreferring;
 267         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 268     });
 269 }
 270
 271 sub is_fast_fwd ($$) {
 272     my ($ancestor,$child) = @_;
 273     my @cmd = (qw(git merge-base), $ancestor, $child);
 274     my $mb = cmdoutput_errok @cmd;
 275     if (defined $mb) {
 276         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 277     } else {
 278         $?==256 or failedcmd @cmd;
 279         return 0;
 280     }
 281 }
 282
 283 1;