chiark / gitweb /
Test suite: build-modes tests: Do extra clean mode tests with build-source
[dgit.git] / Debian / Dgit.pm
1 # -*- perl -*-
2
3 package Debian::Dgit;
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::Handle;
10 use Config;
11
12 BEGIN {
13     use Exporter   ();
14     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
15
16     $VERSION     = 1.00;
17     @ISA         = qw(Exporter);
18     @EXPORT      = qw(setup_sigwarn
19                       debiantag server_branch server_ref
20                       stat_exists fail ensuredir waitstatusmsg failedcmd
21                       cmdoutput cmdoutput_errok
22                       git_rev_parse git_get_ref git_for_each_ref
23                       git_for_each_tag_referring is_fast_fwd
24                       $package_re $component_re $deliberately_re
25                       $branchprefix
26                       initdebug enabledebug enabledebuglevel
27                       printdebug debugcmd
28                       $debugprefix *debuglevel *DEBUG
29                       shellquote printcmd messagequote);
30     # implicitly uses $main::us
31     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
32     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
33 }
34
35 our @EXPORT_OK;
36
37 our $package_re = '[0-9a-z][-+.0-9a-z]*';
38 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
39 our $deliberately_re = "(?:TEST-)?$package_re";
40 our $branchprefix = 'dgit';
41
42 # policy hook exit status bits
43 # see dgit-repos-server head comment for documentation
44 # 1 is reserved in case something fails with `exit 1' and to spot
45 # dynamic loader, runtime, etc., failures, which report 127 or 255
46 sub NOFFCHECK () { return 0x2; }
47 sub FRESHREPO () { return 0x4; }
48
49 our $debugprefix;
50 our $debuglevel = 0;
51
52 sub setup_sigwarn () {
53     our $sigwarn_mainprocess = $$;
54     $SIG{__WARN__} = sub { 
55         die $_[0] unless getppid == $sigwarn_mainprocess;
56     };
57 }
58
59 sub initdebug ($) { 
60     ($debugprefix) = @_;
61     open DEBUG, ">/dev/null" or die $!;
62 }
63
64 sub enabledebug () {
65     open DEBUG, ">&STDERR" or die $!;
66     DEBUG->autoflush(1);
67     $debuglevel ||= 1;
68 }
69     
70 sub enabledebuglevel ($) {
71     my ($newlevel) = @_; # may be undef (eg from env var)
72     die if $debuglevel;
73     $newlevel //= 0;
74     $newlevel += 0;
75     return unless $newlevel;
76     $debuglevel = $newlevel;
77     enabledebug();
78 }
79     
80 sub printdebug {
81     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
82 }
83
84 sub messagequote ($) {
85     local ($_) = @_;
86     s{\\}{\\\\}g;
87     s{\n}{\\n}g;
88     s{\x08}{\\b}g;
89     s{\t}{\\t}g;
90     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
91     $_;
92 }
93
94 sub shellquote {
95     my @out;
96     local $_;
97     foreach my $a (@_) {
98         $_ = $a;
99         if (!length || m{[^-=_./:0-9a-z]}i) {
100             s{['\\]}{'\\$&'}g;
101             push @out, "'$_'";
102         } else {
103             push @out, $_;
104         }
105     }
106     return join ' ', @out;
107 }
108
109 sub printcmd {
110     my $fh = shift @_;
111     my $intro = shift @_;
112     print $fh $intro," " or die $!;
113     print $fh shellquote @_ or die $!;
114     print $fh "\n" or die $!;
115 }
116
117 sub debugcmd {
118     my $extraprefix = shift @_;
119     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
120 }
121
122 sub debiantag ($$) { 
123     my ($v,$distro) = @_;
124     $v =~ y/~:/_%/;
125     return "$distro/$v";
126 }
127
128 sub server_branch ($) { return "$branchprefix/$_[0]"; }
129 sub server_ref ($) { return "refs/".server_branch($_[0]); }
130
131 sub stat_exists ($) {
132     my ($f) = @_;
133     return 1 if stat $f;
134     return 0 if $!==&ENOENT;
135     die "stat $f: $!";
136 }
137
138 sub _us () {
139     $::us // ($0 =~ m#[^/]*$#, $&);
140 }
141
142 sub fail { 
143     my $s = "@_\n";
144     my $prefix = _us().": ";
145     $s =~ s/^/$prefix/gm;
146     die $s;
147 }
148
149 sub ensuredir ($) {
150     my ($dir) = @_; # does not create parents
151     return if mkdir $dir;
152     return if $! == EEXIST;
153     die "mkdir $dir: $!";
154 }
155
156 our @signames = split / /, $Config{sig_name};
157
158 sub waitstatusmsg () {
159     if (!$?) {
160         return "terminated, reporting successful completion";
161     } elsif (!($? & 255)) {
162         return "failed with error exit status ".WEXITSTATUS($?);
163     } elsif (WIFSIGNALED($?)) {
164         my $signum=WTERMSIG($?);
165         return "died due to fatal signal ".
166             ($signames[$signum] // "number $signum").
167             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
168     } else {
169         return "failed with unknown wait status ".$?;
170     }
171 }
172
173 sub failedcmd {
174     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
175     if ($!) {
176         fail "failed to fork/exec: $!";
177     } elsif ($?) {
178         fail "subprocess ".waitstatusmsg();
179     } else {
180         fail "subprocess produced invalid output";
181     }
182 }
183
184 sub cmdoutput_errok {
185     die Dumper(\@_)." ?" if grep { !defined } @_;
186     debugcmd "|",@_;
187     open P, "-|", @_ or die $!;
188     my $d;
189     $!=0; $?=0;
190     { local $/ = undef; $d = <P>; }
191     die $! if P->error;
192     if (!close P) { printdebug "=>!$?\n"; return undef; }
193     chomp $d;
194     if ($debuglevel > 0) {
195         $d =~ m/^.*/;
196         my $dd = $&;
197         my $more = (length $' ? '...' : ''); #');
198         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
199         printdebug "=> \`$dd'",$more,"\n";
200     }
201     return $d;
202 }
203
204 sub cmdoutput {
205     my $d = cmdoutput_errok @_;
206     defined $d or failedcmd @_;
207     return $d;
208 }
209
210 sub git_rev_parse ($) {
211     return cmdoutput qw(git rev-parse), "$_[0]~0";
212 }
213
214 sub git_for_each_ref ($$;$) {
215     my ($pattern,$func,$gitdir) = @_;
216     # calls $func->($objid,$objtype,$fullrefname,$reftail);
217     # $reftail is RHS of ref after refs/[^/]+/
218     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
219     my @cmd = (qw(git for-each-ref), $pattern);
220     if (defined $gitdir) {
221         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
222     }
223     open GFER, "-|", @cmd or die $!;
224     debugcmd "|", @cmd;
225     while (<GFER>) {
226         chomp or die "$_ ?";
227         printdebug "|> ", $_, "\n";
228         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
229         $func->($1,$2,$3,$4);
230     }
231     $!=0; $?=0; close GFER or die "$pattern $? $!";
232 }
233
234 sub git_get_ref ($) {
235     # => '' if no such ref
236     my ($refname) = @_;
237     local $_ = $refname;
238     s{^refs/}{[r]efs/} or die "$refname $_ ?";
239     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
240 }
241
242 sub git_for_each_tag_referring ($$) {
243     my ($objreferring, $func) = @_;
244     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
245     printdebug "git_for_each_tag_referring ",
246         ($objreferring // 'UNDEF'),"\n";
247     git_for_each_ref('refs/tags', sub {
248         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
249         return unless $objtype eq 'tag';
250         my $refobjid = git_rev_parse $tagobjid;
251         return unless
252             !defined $objreferring # caller wants them all
253             or $tagobjid eq $objreferring
254             or $refobjid eq $objreferring;
255         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
256     });
257 }
258
259 sub is_fast_fwd ($$) {
260     my ($ancestor,$child) = @_;
261     my @cmd = (qw(git merge-base), $ancestor, $child);
262     my $mb = cmdoutput_errok @cmd;
263     if (defined $mb) {
264         return git_rev_parse($mb) eq git_rev_parse($ancestor);
265     } else {
266         $?==256 or failedcmd @cmd;
267         return 0;
268     }
269 }
270
271 1;