Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32 use File::Path;
  33
  34 BEGIN {
  35     use Exporter   ();
  36     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  37
  38     $VERSION     = 1.00;
  39     @ISA         = qw(Exporter);
  40     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  41                       dep14_version_mangle
  42                       debiantags debiantag_old debiantag_new
  43                       server_branch server_ref
  44                       stat_exists link_ltarget
  45                       hashfile
  46                       fail ensuredir must_getcwd executable_on_path
  47                       waitstatusmsg failedcmd_waitstatus
  48                       failedcmd_report_cmd failedcmd
  49                       runcmd cmdoutput cmdoutput_errok
  50                       git_rev_parse git_cat_file
  51                       git_get_ref git_for_each_ref
  52                       git_for_each_tag_referring is_fast_fwd
  53                       $package_re $component_re $deliberately_re
  54                       $distro_re $versiontag_re $series_filename_re
  55                       $branchprefix
  56                       initdebug enabledebug enabledebuglevel
  57                       printdebug debugcmd
  58                       $debugprefix *debuglevel *DEBUG
  59                       shellquote printcmd messagequote
  60                       $negate_harmful_gitattrs
  61                       changedir git_slurp_config_src
  62                       playtree_setup);
  63     # implicitly uses $main::us
  64     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)],
  65                      playground => [qw($local_git_cfg)]);
  66     @EXPORT_OK   = ( @{ $EXPORT_TAGS{policyflags} },
  67                      @{ $EXPORT_TAGS{playground} } );
  68 }
  69
  70 our @EXPORT_OK;
  71
  72 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  73 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  74 our $deliberately_re = "(?:TEST-)?$package_re";
  75 our $distro_re = $component_re;
  76 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  77 our $branchprefix = 'dgit';
  78 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  79
  80 # policy hook exit status bits
  81 # see dgit-repos-server head comment for documentation
  82 # 1 is reserved in case something fails with `exit 1' and to spot
  83 # dynamic loader, runtime, etc., failures, which report 127 or 255
  84 sub NOFFCHECK () { return 0x2; }
  85 sub FRESHREPO () { return 0x4; }
  86 sub NOCOMMITCHECK () { return 0x8; }
  87
  88 our $debugprefix;
  89 our $debuglevel = 0;
  90
  91 our $negate_harmful_gitattrs = "-text -eol -crlf -ident -filter";
  92
  93 our $forkcheck_mainprocess;
  94
  95 sub forkcheck_setup () {
  96     $forkcheck_mainprocess = $$;
  97 }
  98
  99 sub forkcheck_mainprocess () {
 100     # You must have called forkcheck_setup or setup_sigwarn already
 101     getppid != $forkcheck_mainprocess;
 102 }
 103
 104 sub setup_sigwarn () {
 105     forkcheck_setup();
 106     $SIG{__WARN__} = sub {
 107         die $_[0] if forkcheck_mainprocess;
 108     };
 109 }
 110
 111 sub initdebug ($) {
 112     ($debugprefix) = @_;
 113     open DEBUG, ">/dev/null" or die $!;
 114 }
 115
 116 sub enabledebug () {
 117     open DEBUG, ">&STDERR" or die $!;
 118     DEBUG->autoflush(1);
 119     $debuglevel ||= 1;
 120 }
 121
 122 sub enabledebuglevel ($) {
 123     my ($newlevel) = @_; # may be undef (eg from env var)
 124     die if $debuglevel;
 125     $newlevel //= 0;
 126     $newlevel += 0;
 127     return unless $newlevel;
 128     $debuglevel = $newlevel;
 129     enabledebug();
 130 }
 131
 132 sub printdebug {
 133     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 134 }
 135
 136 sub messagequote ($) {
 137     local ($_) = @_;
 138     s{\\}{\\\\}g;
 139     s{\n}{\\n}g;
 140     s{\x08}{\\b}g;
 141     s{\t}{\\t}g;
 142     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 143     $_;
 144 }
 145
 146 sub shellquote {
 147     my @out;
 148     local $_;
 149     defined or confess 'internal error' foreach @_;
 150     foreach my $a (@_) {
 151         $_ = $a;
 152         if (!length || m{[^-=_./:0-9a-z]}i) {
 153             s{['\\]}{'\\$&'}g;
 154             push @out, "'$_'";
 155         } else {
 156             push @out, $_;
 157         }
 158     }
 159     return join ' ', @out;
 160 }
 161
 162 sub printcmd {
 163     my $fh = shift @_;
 164     my $intro = shift @_;
 165     print $fh $intro," " or die $!;
 166     print $fh shellquote @_ or die $!;
 167     print $fh "\n" or die $!;
 168 }
 169
 170 sub debugcmd {
 171     my $extraprefix = shift @_;
 172     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 173 }
 174
 175 sub dep14_version_mangle ($) {
 176     my ($v) = @_;
 177     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 178     $v =~ y/~:/_%/;
 179     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 180     return $v;
 181 }
 182
 183 sub debiantag_old ($$) {
 184     my ($v,$distro) = @_;
 185     return "$distro/". dep14_version_mangle $v;
 186 }
 187
 188 sub debiantag_new ($$) {
 189     my ($v,$distro) = @_;
 190     return "archive/$distro/".dep14_version_mangle $v;
 191 }
 192
 193 sub debiantags ($$) {
 194     my ($version,$distro) = @_;
 195     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 196 }
 197
 198 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 199 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 200
 201 sub stat_exists ($) {
 202     my ($f) = @_;
 203     return 1 if stat $f;
 204     return 0 if $!==&ENOENT;
 205     die "stat $f: $!";
 206 }
 207
 208 sub _us () {
 209     $::us // ($0 =~ m#[^/]*$#, $&);
 210 }
 211
 212 sub fail {
 213     my $s = "@_\n";
 214     $s =~ s/\n\n$/\n/;
 215     my $prefix = _us().": ";
 216     $s =~ s/^/$prefix/gm;
 217     die $s;
 218 }
 219
 220 sub ensuredir ($) {
 221     my ($dir) = @_; # does not create parents
 222     return if mkdir $dir;
 223     return if $! == EEXIST;
 224     die "mkdir $dir: $!";
 225 }
 226
 227 sub must_getcwd () {
 228     my $d = getcwd();
 229     defined $d or fail "getcwd failed: $!";
 230     return $d;
 231 }
 232
 233 sub executable_on_path ($) {
 234     my ($program) = @_;
 235     return 1 if $program =~ m{/};
 236     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 237     foreach my $pe (@path) {
 238         my $here = "$pe/$program";
 239         return $here if stat_exists $here && -x _;
 240     }
 241     return undef;
 242 }
 243
 244 our @signames = split / /, $Config{sig_name};
 245
 246 sub waitstatusmsg () {
 247     if (!$?) {
 248         return "terminated, reporting successful completion";
 249     } elsif (!($? & 255)) {
 250         return "failed with error exit status ".WEXITSTATUS($?);
 251     } elsif (WIFSIGNALED($?)) {
 252         my $signum=WTERMSIG($?);
 253         return "died due to fatal signal ".
 254             ($signames[$signum] // "number $signum").
 255             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 256     } else {
 257         return "failed with unknown wait status ".$?;
 258     }
 259 }
 260
 261 sub failedcmd_report_cmd {
 262     my $intro = shift @_;
 263     $intro //= "failed command";
 264     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 265 }
 266
 267 sub failedcmd_waitstatus {
 268     if ($? < 0) {
 269         return "failed to fork/exec: $!";
 270     } elsif ($?) {
 271         return "subprocess ".waitstatusmsg();
 272     } else {
 273         return "subprocess produced invalid output";
 274     }
 275 }
 276
 277 sub failedcmd {
 278     # Expects $!,$? as set by close - see below.
 279     # To use with system(), set $?=-1 first.
 280     #
 281     # Actual behaviour of perl operations:
 282     #   success              $!==0       $?==0       close of piped open
 283     #   program failed       $!==0       $? >0       close of piped open
 284     #   syscall failure      $! >0       $?=-1       close of piped open
 285     #   failure              $! >0       unchanged   close of something else
 286     #   success              trashed     $?==0       system
 287     #   program failed       trashed     $? >0       system
 288     #   syscall failure      $! >0       unchanged   system
 289     failedcmd_report_cmd undef, @_;
 290     fail failedcmd_waitstatus();
 291 }
 292
 293 sub runcmd {
 294     debugcmd "+",@_;
 295     $!=0; $?=-1;
 296     failedcmd @_ if system @_;
 297 }
 298
 299 sub cmdoutput_errok {
 300     confess Dumper(\@_)." ?" if grep { !defined } @_;
 301     debugcmd "|",@_;
 302     open P, "-|", @_ or die "$_[0] $!";
 303     my $d;
 304     $!=0; $?=0;
 305     { local $/ = undef; $d = <P>; }
 306     die $! if P->error;
 307     if (!close P) { printdebug "=>!$?\n"; return undef; }
 308     chomp $d;
 309     if ($debuglevel > 0) {
 310         $d =~ m/^.*/;
 311         my $dd = $&;
 312         my $more = (length $' ? '...' : ''); #');
 313         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 314         printdebug "=> \`$dd'",$more,"\n";
 315     }
 316     return $d;
 317 }
 318
 319 sub cmdoutput {
 320     my $d = cmdoutput_errok @_;
 321     defined $d or failedcmd @_;
 322     return $d;
 323 }
 324
 325 sub link_ltarget ($$) {
 326     my ($old,$new) = @_;
 327     lstat $old or return undef;
 328     if (-l _) {
 329         $old = cmdoutput qw(realpath  --), $old;
 330     }
 331     my $r = link $old, $new;
 332     $r = symlink $old, $new if !$r && $!==EXDEV;
 333     $r or die "(sym)link $old $new: $!";
 334 }
 335
 336 sub hashfile ($) {
 337     my ($fn) = @_;
 338     my $h = Digest::SHA->new(256);
 339     $h->addfile($fn);
 340     return $h->hexdigest();
 341 }
 342
 343 sub git_rev_parse ($) {
 344     return cmdoutput qw(git rev-parse), "$_[0]~0";
 345 }
 346
 347 sub git_cat_file ($) {
 348     my ($objname) = @_;
 349     # => ($type, $data) or ('missing', undef)
 350     # in scalar context, just the data
 351     our ($gcf_pid, $gcf_i, $gcf_o);
 352     if (!$gcf_pid) {
 353         my @cmd = qw(git cat-file --batch);
 354         debugcmd "GCF|", @cmd;
 355         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 356     }
 357     printdebug "GCF>| ", $objname, "\n";
 358     print $gcf_i $objname, "\n" or die $!;
 359     my $x = <$gcf_o>;
 360     printdebug "GCF<| ", $x;
 361     if ($x =~ m/ (missing)$/) { return ($1, undef); }
 362     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 363     my $data;
 364     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 365     $x = <$gcf_o>;
 366     $x eq "\n" or die "$objname ($_) $!";
 367     return ($type, $data);
 368 }
 369
 370 sub git_for_each_ref ($$;$) {
 371     my ($pattern,$func,$gitdir) = @_;
 372     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 373     # $reftail is RHS of ref after refs/[^/]+/
 374     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 375     # $pattern may be an array ref to mean multiple patterns
 376     $pattern = [ $pattern ] unless ref $pattern;
 377     my @cmd = (qw(git for-each-ref), @$pattern);
 378     if (defined $gitdir) {
 379         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 380     }
 381     open GFER, "-|", @cmd or die $!;
 382     debugcmd "|", @cmd;
 383     while (<GFER>) {
 384         chomp or die "$_ ?";
 385         printdebug "|> ", $_, "\n";
 386         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 387         $func->($1,$2,$3,$4);
 388     }
 389     $!=0; $?=0; close GFER or die "$pattern $? $!";
 390 }
 391
 392 sub git_get_ref ($) {
 393     # => '' if no such ref
 394     my ($refname) = @_;
 395     local $_ = $refname;
 396     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 397     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 398 }
 399
 400 sub git_for_each_tag_referring ($$) {
 401     my ($objreferring, $func) = @_;
 402     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 403     printdebug "git_for_each_tag_referring ",
 404         ($objreferring // 'UNDEF'),"\n";
 405     git_for_each_ref('refs/tags', sub {
 406         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 407         return unless $objtype eq 'tag';
 408         my $refobjid = git_rev_parse $tagobjid;
 409         return unless
 410             !defined $objreferring # caller wants them all
 411             or $tagobjid eq $objreferring
 412             or $refobjid eq $objreferring;
 413         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 414     });
 415 }
 416
 417 sub is_fast_fwd ($$) {
 418     my ($ancestor,$child) = @_;
 419     my @cmd = (qw(git merge-base), $ancestor, $child);
 420     my $mb = cmdoutput_errok @cmd;
 421     if (defined $mb) {
 422         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 423     } else {
 424         $?==256 or failedcmd @cmd;
 425         return 0;
 426     }
 427 }
 428
 429 sub changedir ($) {
 430     my ($newdir) = @_;
 431     printdebug "CD $newdir\n";
 432     chdir $newdir or confess "chdir: $newdir: $!";
 433 }
 434
 435 sub git_slurp_config_src ($) {
 436     my ($src) = @_;
 437     # returns $r such that $r->{KEY}[] = VALUE
 438     my @cmd = (qw(git config -z --get-regexp), "--$src", qw(.*));
 439     debugcmd "|",@cmd;
 440
 441     local ($debuglevel) = $debuglevel-2;
 442     local $/="\0";
 443
 444     my $r = { };
 445     open GITS, "-|", @cmd or die $!;
 446     while (<GITS>) {
 447         chomp or die;
 448         printdebug "=> ", (messagequote $_), "\n";
 449         m/\n/ or die "$_ ?";
 450         push @{ $r->{$`} }, $'; #';
 451     }
 452     $!=0; $?=0;
 453     close GITS
 454         or ($!==0 && $?==256)
 455         or failedcmd @cmd;
 456     return $r;
 457 }
 458
 459 # ========== playground handling ==========
 460
 461 #   $local_git_cfg    hash of arrays of values: git config from $maindir
 462
 463 our $local_git_cfg;
 464
 465 # ----- playtrees -----
 466
 467 sub playtree_setup (;$) {
 468     my ($t_local_git_cfg) = @_;
 469     $t_local_git_cfg //= $local_git_cfg;
 470     # should be run in a directory .git/FOO/BAR of a working tree
 471     runcmd qw(git init -q);
 472     runcmd qw(git config gc.auto 0);
 473     foreach my $copy (qw(user.email user.name user.useConfigOnly
 474                          core.sharedRepository
 475                          core.compression core.looseCompression
 476                          core.bigFileThreshold core.fsyncObjectFiles)) {
 477         my $v = $t_local_git_cfg->{$copy};
 478         next unless $v;
 479         runcmd qw(git config), $copy, $_ foreach @$v;
 480     }
 481     rmtree('.git/objects');
 482     symlink '../../../../objects','.git/objects' or die $!;
 483     ensuredir '.git/info';
 484     open GA, "> .git/info/attributes" or die $!;
 485     print GA "* $negate_harmful_gitattrs\n" or die $!;
 486     close GA or die $!;
 487 }
 488
 489 1;