chiark / gitweb /
dd22146339b130fc6ffbb7efdd9ab3ce0ccc8515
[subdirmk.git] / generate
1 #!/usr/bin/perl -w
2 #
3 # subdirmk - &-filter (makefile generation program)
4 #  Copyright 2019 Ian Jackson
5 # SPDX-License-Identifier: LGPL-2.0-or-later
6 #
7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
8 #
9 # generates in each subdirectory        from in each subdirectory
10 #     Subdir.mk.tmp                         Subdir.sd.mk
11 #     Makefile                          and included files
12 # and in toplevel                       and in toplevel
13 #     main.mk.tmp                           Perdir.sd.mk
14
15 use strict;
16 use POSIX;
17
18 print "$0 @ARGV\n" or die $!;
19
20 our $srcdir='.';
21
22 while (@ARGV && $ARGV[0] =~ m/^-/) {
23     $_ = shift @ARGV;
24     last if $_ eq '--';
25     if (s/^--srcdir=//) {
26         $srcdir=$';
27     } else {
28         die "$0: unknown option \`$_'\n";
29     }
30 }
31 our @subdirs = @ARGV;
32
33 s{/+$}{} foreach @subdirs;
34
35 our $root = [ '.', [ ] ];
36 # each node is [ 'relative subdir name', \@children ]
37
38 sub build_tree () {
39     foreach my $subdir (@subdirs) {
40         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
41         my $node = $root;
42         foreach my $d (@path) {
43             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
44             if (!$c) {
45                 $c = [ $d, [ ] ];
46                 push @{ $node->[1] }, $c;
47             }
48             $node = $c;
49         }
50     }
51 }
52
53 sub target_varname ($$) {
54     my ($var_prefix, $target) = @_;
55     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
56 }
57
58 our $writing_output;
59 our $buffering_output;
60 our %output_files;
61 our %input_files;
62
63 sub close_any_output_file() {
64     return unless defined $writing_output;
65     O->error and die "error writing $writing_output.tmp: $! (?)\n";
66     close O or die "error closing $writing_output.tmp: $!\n";
67     $writing_output = undef;
68 }
69
70 sub o {
71     if (defined $buffering_output) {
72         $buffering_output .= $_ foreach @_;
73         return;
74     }
75     die unless defined $writing_output;
76     print O @_ or die "error writing $writing_output.tmp: $!\n";
77 }
78
79 sub start_output_file ($) {
80     close_any_output_file();
81     ($writing_output) = @_;
82     die "$writing_output ?" if $output_files{$writing_output}++;
83     my $tmp = "$writing_output.tmp";
84     open O, ">", $tmp or die "create $tmp: $!\n";
85     o "# autogenerated - do not edit\n";
86 }
87
88 sub install_output_files () {
89     close_any_output_file();
90     foreach my $f (sort keys %output_files) {
91         rename "$f.tmp", $f or die "install new $f: $!\n";
92     }
93 }
94
95 sub write_makefile ($$) {
96     my ($dir_prefix,$depth) = @_;
97     #print STDERR "write_makefile @_\n";
98     start_output_file("${dir_prefix}Makefile");
99     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
100     o <<END;
101 default: all
102 \$(MAKECMDGOALS) all: run-main.mk
103         \@:
104 Makefile run-main.mk:
105         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(or \$(MAKECMDGOALS),all))
106 .SUFFIXES:
107 .PHONY: run-main.mk
108 END
109 }
110
111 sub process_input_mk ($$$$$$$$);
112 sub process_input_mk ($$$$$$$$) {
113     my ($dir_prefix, $dir_suffix, $dir_name,
114         $var_prefix, $targets,
115         $f, $esclitr, $enoent_ok) = @_;
116
117     my $caps_re = qr{[A-Z]};
118     my $lc_re = qr{[a-z]};
119
120     my $esc;
121     my $set_esc = sub {
122         $esc = $$esclitr;
123         $esc =~ s/\W/\\$&/g;
124     };
125     $set_esc->();
126
127     my $input = new IO::File $f, '<';
128     if (!$input) {
129         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
130         return;
131     }
132     $input_files{$f}++;
133
134     my %pfxmap = (
135                   ''  => $dir_prefix,
136                   '^' => "\$(top_srcdir)${dir_suffix}/",
137                   '~' => "\$(top_srcdir)/",
138                  );
139
140     while (<$input>) {
141         if (s#^\s*$esc\:##) {
142             $buffering_output='';
143         }
144         for (;;) {
145             unless (s{^(.*?)(\\)?(?=$esc)}{}) { o $_; last; }
146             o $1;
147             if ($2) { s#^$esc##; o $$esclitr; next; }
148             s{^$esc}{} or die "$_ ?";
149             if (s{^$esc}{}) { o "$$esclitr$$esclitr" }
150             elsif (s{^TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
151                 my $t = $1 // 'all';
152                 o target_varname($var_prefix, $t);
153                 $targets->{$t} //= [ ];
154             }
155             elsif (m{^(?=$caps_re)}) { o $var_prefix }
156             elsif (s{^([~^]?)(?=$lc_re)}{}) { o $pfxmap{$1} }
157             elsif (s{^_}{}) { o $var_prefix }
158             elsif (s{^=_}{}) { o $var_prefix }
159             elsif (s{^([~^]?)/}{}) { o $pfxmap{$1} }
160             elsif (s{^=/}{}) { o $dir_name }
161             elsif (s{^([~^]?)(?=[ \t])}{}) {
162                 my $prefix = $pfxmap{$1} // die;
163                 my $after='';
164                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
165                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
166                 o $_;
167                 $_ = $after;
168             } elsif (s{^\#}{}) {
169                 $_ = '';
170             } elsif (s{^![ \t]+}{}) {
171                 o $_;
172                 $_ = '';
173             } elsif (s{^!(\S+)(?:[ \t]+|$)}{}) {
174                 $$esclitr = $1;
175                 $set_esc->();
176             } else {
177                 die "bad escape $$esclitr$_ ";
178             }
179         }
180         if (defined $buffering_output) {
181             $_=$buffering_output;
182             $buffering_output=undef;
183             if (m#^(-?)include\s+(\S+)\s+$#) {
184                 my $subf = "$srcdir/$2";
185                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
186                                  $var_prefix, $targets,
187                                  $subf, $esclitr, $1);
188                 o "\n";
189             } else {
190                 die "unknown directive $_ ";
191             }
192         }
193     }
194     $input->error and die "read $f: $!\n";
195     close $input or die "close $f: $!\n";
196 }
197
198 sub filter_subdir_mk ($$$$$) {
199     my ($dir_prefix, $dir_suffix, $dir_name,
200         $var_prefix, $targets) = @_;
201
202     #use Data::Dumper;
203     #print STDERR "filter @_\n";
204
205     my $esclit = '&';
206
207     my $pi = sub {
208         my ($f, $enoentok) = @_;
209         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
210                          $var_prefix, $targets,
211                          "${srcdir}/$f", \$esclit, $enoentok);
212     };
213     $pi->("${dir_prefix}Subdir.sd.mk", 0);
214     $pi->("Perdir.sd.mk",              1);
215 }
216
217 sub process_subtree ($$);
218 sub process_subtree ($$) {
219     # => list of descendants (in form SUBDIR/)
220     # recursive, children first
221     my ($node, $path) = @_;
222
223     #use Data::Dumper;
224     #print STDERR Dumper(\@_);
225
226     my $dir_prefix = join '', map { "$_/" } @$path;
227     my $dir_suffix = join '', map { "/$_" } @$path;
228     my $dir_name = join '/', @$path ? @$path : '.';
229     my $var_prefix = join '', map { "${_}_" } @$path ? @$path : qw(TOP);
230
231     write_makefile($dir_prefix, scalar @$path);
232
233     my %targets = (all => []);
234     foreach my $child (@{ $node->[1] }) {
235         my @childpath = (@$path, $child->[0]);
236         my $child_subdir = join '/', @childpath;
237         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
238         push @{ $targets{$_} }, $child_subdir foreach
239             process_subtree($child, \@childpath);
240     }
241     start_output_file("${dir_prefix}Subdir.mk.tmp");
242
243     filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
244                      $var_prefix, \%targets);
245
246     o "\n";
247
248     my @targets = sort keys %targets;
249     foreach my $target (@targets) {
250         my $target_varname = target_varname($var_prefix, $target);
251         print O "${dir_prefix}${target}:: \$($target_varname)";
252         foreach my $child_subdir (@{ $targets{$target} }) {
253             print O " $child_subdir/$target";
254         }
255         print O "\n";
256     }
257
258     return @targets;
259 }
260
261 sub process_tree() {
262     process_subtree($root, [ ]);
263     start_output_file("main.mk.tmp");
264     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
265         o "$v=\@$v@\n";
266     }
267     o "SUBDIRMK_MAKEFILES :=\n";
268     o "MAKEFILE_TEMPLATES :=\n";
269     o "SUBDIRMK_MAKEFILES += Subdir.mk\n";
270     foreach my $subdir (@subdirs) {
271         o "SUBDIRMK_MAKEFILES += $subdir/Subdir.mk\n";
272     }
273     foreach my $input (sort keys %input_files) {
274         o "MAKEFILE_TEMPLATES += $input\n";
275     }
276     o "include \$(SUBDIRMK_MAKEFILES)";
277 }
278
279 build_tree();
280 process_tree();
281 install_output_files();