chiark / gitweb /
test/example/check: Make sections appear in stderr output
[subdirmk.git] / generate
1 #!/usr/bin/perl -w
2 #
3 # subdirmk - &-filter (makefile generation program)
4 #  Copyright 2019 Ian Jackson
5 # SPDX-License-Identifier: LGPL-2.0-or-later
6 #
7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
8 #
9 # generates in each subdirectory        from in each subdirectory
10 #     Subdir.mk.tmp                         Subdir.sd.mk
11 #     Makefile                          and included files
12 # and in toplevel                       and in toplevel
13 #     main.mk.tmp                           Perdir.sd.mk
14
15 use strict;
16 use POSIX;
17
18 print "$0 @ARGV\n" or die $!;
19
20 our $srcdir='.';
21
22 while (@ARGV && $ARGV[0] =~ m/^-/) {
23     $_ = shift @ARGV;
24     last if $_ eq '--';
25     if (s/^--srcdir=//) {
26         $srcdir=$';
27     } else {
28         die "$0: unknown option \`$_'\n";
29     }
30 }
31 our @subdirs = @ARGV;
32
33 s{/+$}{} foreach @subdirs;
34
35 our $root = [ '.', [ ], 1 ];
36 # each node is [ 'relative subdir name', \@children, $mentioned ]
37
38 sub build_tree () {
39     foreach my $subdir (@subdirs) {
40         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
41         my $node = $root;
42         foreach my $d (@path) {
43             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
44             if (!$c) {
45                 $c = [ $d, [ ] ];
46                 push @{ $node->[1] }, $c;
47             }
48             $node = $c;
49         }
50         $node->[2] = 1;
51     }
52 }
53
54 sub target_varname ($$) {
55     my ($var_prefix, $target) = @_;
56     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
57 }
58
59 our $writing_output;
60 our $buffering_output;
61 our %output_files;
62 our %input_files;
63 our @output_makefiles;
64
65 sub close_any_output_file() {
66     return unless defined $writing_output;
67     O->error and die "error writing $writing_output.tmp: $! (?)\n";
68     close O or die "error closing $writing_output.tmp: $!\n";
69     $writing_output = undef;
70 }
71
72 sub o {
73     if (defined $buffering_output) {
74         $buffering_output .= $_ foreach @_;
75         return;
76     }
77     die unless defined $writing_output;
78     print O @_ or die "error writing $writing_output.tmp: $!\n";
79 }
80
81 sub start_output_file ($) {
82     close_any_output_file();
83     ($writing_output) = @_;
84     die "$writing_output ?" if $output_files{$writing_output}++;
85     my $tmp = "$writing_output.tmp";
86     open O, ">", $tmp or die "create $tmp: $!\n";
87     o "# autogenerated - do not edit\n";
88 }
89
90 sub install_output_files () {
91     close_any_output_file();
92     foreach my $f (sort keys %output_files) {
93         rename "$f.tmp", $f or die "install new $f: $!\n";
94     }
95 }
96
97 sub write_makefile ($$) {
98     my ($dir_prefix,$depth) = @_;
99     #print STDERR "write_makefile @_\n";
100     start_output_file("${dir_prefix}Makefile");
101     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
102     my $suppress_templates=
103         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
104         ' MAKEFILE_TEMPLATES=)';
105     o <<END;
106 default: all
107 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
108         \@:
109 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
110 Makefile run-main.mk:
111         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
112 .SUFFIXES:
113 .PHONY: run-main.mk
114 END
115 }
116
117 sub process_input_mk ($$$$$$$$$);
118 sub process_input_mk ($$$$$$$$$) {
119     my ($dir_prefix, $dir_suffix, $dir_name,
120         $var_prefix, $var_prefix_name, $targets,
121         $f, $esclitr, $enoent_ok) = @_;
122
123     my $caps_re = qr{[A-Z]};
124     my $lc_re = qr{[a-z]};
125
126     my $esc;
127     my $set_esc = sub {
128         $esc = $$esclitr;
129         $esc =~ s/\W/\\$&/g;
130     };
131     $set_esc->();
132
133     my $input = new IO::File $f, '<';
134     if (!$input) {
135         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
136         return;
137     }
138     $input_files{$f}++;
139
140     my %srcdirmap = (
141                   '^' => "\$(top_srcdir)${dir_suffix}",
142                   '~' => "\$(top_srcdir)",
143                     );
144     my %pfxmap = (
145                   ''  => $dir_prefix,
146                  );
147     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
148
149     while (<$input>) {
150         if (s#^\s*$esc\:changequote\s+(\S+)\s+$##) {
151             $$esclitr = $1;
152             $set_esc->();
153             next;
154         } elsif (s#^\s*$esc\:(?=(-?)include)##) {
155             $buffering_output='';
156         } elsif (m#^\s*$esc\:([a-z][-0-9a-z_]*)#) {
157             die "unknown directive $1";
158         } elsif (s{^\s*${esc}TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
159             my $t = $1 // 'all';
160             o target_varname($var_prefix, $t);
161             $targets->{$t} //= [ ];
162         }
163         for (;;) {
164             unless (s{^(.*?)$esc}{}) { o $_; last; }
165             o $1;
166             if (s{^\\$esc}{}) { o "$$esclitr" }
167             elsif (s{^\\\$}{}) { o '$' }
168             elsif (s{^\\\s+$}{}) { }
169             elsif (s{^$esc}{}) { o "$$esclitr$$esclitr" }
170             elsif (m{^(?=$caps_re)}) { o $var_prefix }
171             elsif (s{^\$([A-Za-z]\w+)}{}) { o "\$(${var_prefix}$1)" }
172             elsif (s{^([~^]?)(?=$lc_re)}{}) { o $pfxmap{$1} }
173             elsif (s{^_}{}) { o $var_prefix }
174             elsif (s{^=}{}) { o $var_prefix_name }
175             elsif (s{^([~^]?)/}{}) { o $pfxmap{$1} }
176             elsif (s{^\.}{}) { o $dir_name }
177             elsif (s{^([~^])\.}{}) { o $srcdirmap{$1} }
178             elsif (s{^([~^]?)(?=[ \t])}{}) {
179                 my $prefix = $pfxmap{$1} // die;
180                 my $after='';
181                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
182                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
183                 o $_;
184                 $_ = $after;
185             } elsif (s{^\#}{}) {
186                 $_ = '';
187             } elsif (s{^![ \t]+}{}) {
188                 o $_;
189                 $_ = '';
190             } else {
191                 die "bad escape $$esclitr$_ ";
192             }
193         }
194         if (defined $buffering_output) {
195             $_=$buffering_output;
196             $buffering_output=undef;
197             if (m#^(-?)include\s+(\S+)\s+$#) {
198                 my $subf = "$srcdir/$2";
199                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
200                                  $var_prefix, $var_prefix_name, $targets,
201                                  $subf, $esclitr, $1);
202                 o "\n";
203             } else {
204                 die "internal error buffering directive $_ ";
205             }
206         }
207     }
208     $input->error and die "read $f: $!\n";
209     close $input or die "close $f: $!\n";
210 }
211
212 sub filter_subdir_mk ($$$$$$) {
213     my ($dir_prefix, $dir_suffix, $dir_name,
214         $var_prefix, $var_prefix_name, $targets) = @_;
215
216     #use Data::Dumper;
217     #print STDERR "filter @_\n";
218
219     my $esclit = '&';
220
221     my $pi = sub {
222         my ($f, $enoentok) = @_;
223         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
224                          $var_prefix, $var_prefix_name, $targets,
225                          "${srcdir}/$f", \$esclit, $enoentok);
226     };
227     $pi->("${dir_prefix}Subdir.sd.mk", 0);
228     $pi->("Perdir.sd.mk",              1);
229 }
230
231 sub process_subtree ($$);
232 sub process_subtree ($$) {
233     # => list of descendants (in form SUBDIR/)
234     # recursive, children first
235     my ($node, $path) = @_;
236
237     #use Data::Dumper;
238     #print STDERR Dumper(\@_);
239
240     my $dir_prefix = join '', map { "$_/" } @$path;
241     my $dir_suffix = join '', map { "/$_" } @$path;
242     my $dir_name = join '/', @$path ? @$path : '.';
243     my $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
244     my $var_prefix = "${var_prefix_name}_";
245
246     push @output_makefiles, "${dir_prefix}Subdir.mk";
247     write_makefile($dir_prefix, scalar @$path);
248
249     my %targets = (all => []);
250     foreach my $child (@{ $node->[1] }) {
251         my @childpath = (@$path, $child->[0]);
252         my $child_subdir = join '/', @childpath;
253         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
254         push @{ $targets{$_} }, $child_subdir foreach
255             process_subtree($child, \@childpath);
256     }
257     start_output_file("${dir_prefix}Subdir.mk.tmp");
258
259     if ($node->[2]) {
260         filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
261                          $var_prefix, $var_prefix_name, \%targets);
262     } else {
263         my $sdmk = "${dir_prefix}Subdir.sd.mk";
264         if (stat $sdmk) {
265             die "$sdmk unexpectedly exists (${dir_prefix} not mentioned)";
266         } elsif ($!==ENOENT) {
267         } else {
268             die "stat $sdmk: $!";
269         }
270     }
271
272     o "\n";
273
274     my @targets = sort keys %targets;
275     foreach my $target (@targets) {
276         my $target_varname = target_varname($var_prefix, $target);
277         print O "${dir_prefix}${target}:: \$($target_varname)";
278         foreach my $child_subdir (@{ $targets{$target} }) {
279             print O " $child_subdir/$target";
280         }
281         print O "\n";
282     }
283     if (@targets) {
284         print O ".PHONY:";
285         print O " ${dir_prefix}${_}" foreach @targets;
286         print O "\n";
287     }
288
289     return @targets;
290 }
291
292 sub process_tree() {
293     process_subtree($root, [ ]);
294     start_output_file("main.mk.tmp");
295     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
296         o "$v=\@$v@\n";
297     }
298     o "SUBDIRMK_MAKEFILES :=\n";
299     o "MAKEFILE_TEMPLATES :=\n";
300     foreach my $mf (@output_makefiles) {
301         o "SUBDIRMK_MAKEFILES += $mf\n";
302     }
303     foreach my $input (sort keys %input_files) {
304         o "MAKEFILE_TEMPLATES += $input\n";
305     }
306     o "include \$(SUBDIRMK_MAKEFILES)\n";
307 }
308
309 build_tree();
310 process_tree();
311 install_output_files();