yarrg/commod-results-processor

   1 #!/usr/bin/perl -w
   2
   3 # helper program for processing commodity output
   4
   5 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   6 # players of Yohoho Puzzle Pirates.
   7 #
   8 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   9 #
  10 # This program is free software: you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation, either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22 #
  23 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  24 # are used without permission.  This program is not endorsed or
  25 # sponsored by Three Rings.
  26
  27
  28 use strict (qw(vars));
  29 use HTTP::Request;
  30 use IO::File;
  31 use POSIX;
  32 use XML::Parser;
  33
  34 use Commods;
  35
  36 # $commod{'Hemp'}{Buy|Sell}{'stall'}{Stall}
  37 # $commod{'Hemp'}{Buy|Sell}{'stall'}{Price}
  38 # $commod{'Hemp'}{Buy|Sell}{'stall'}{Qty}
  39 # $commod{'Hemp'}{Hold}
  40
  41 our @v;
  42 our ($commod,$stall,%commod,@commods_inorder);
  43
  44 @ARGV==1 or die "You probably don't want to run this program directly.\n";
  45 our ($mode) = shift @ARGV;
  46
  47 # ./yppsc-commod-processor tsv <t |less -x40,80,90,100,110
  48
  49 sub bs_read ($$) {
  50     my ($bs,$c) = @_;
  51     return if @v <= $c;
  52     my ($price,$qty) = @v[$c..$c+1];
  53     return if !length($price) && !length($qty);
  54     die "$_ ?" unless length($price) && length($qty);
  55     $commod{$commod}{$bs}{$stall}= {
  56         Stall => $stall,
  57         Price => $price,
  58         Qty => $qty,
  59     };
  60 }
  61
  62 while (<>) {
  63     chomp;
  64     @v= split /\t/;
  65 #print STDERR "[".join("|",@v)."]\n";
  66     ($commod,$stall) = @v;
  67     push @commods_inorder, $commod unless exists $commod{$commod};
  68     bs_read(Buy,  2);
  69     bs_read(Sell, 4);
  70     $commod{$commod}{Hold}= $v[6]+0 if @v>6;
  71 }
  72
  73 our $current;
  74
  75 sub bs_p ($$$) {
  76     my ($commod,$bs,$sortmul) = @_;
  77     my $ary= $current->{$bs};
  78     my $r= [ ];
  79 #print Dumper($ary);
  80     foreach my $stall (sort {
  81         $sortmul * ($ary->{$a}{Price} <=> $ary->{$b}{Price});
  82     } keys %$ary) {
  83         push @$r, $ary->{$stall};
  84     }
  85     return $r;
  86 }
  87
  88 sub bs_p_bestprice ($) {
  89     my ($l) = @_;
  90     if (@$l) {
  91         printf("| %-25.25s %4d", $l->[0]{Stall}, $l->[0]{Price}) or die $!;
  92     } else {
  93         printf("| %25s %4s","","") or die $!;
  94     }
  95 }
  96
  97 sub main__arbitrage () {
  98     my @arbs= ();
  99     foreach $commod (sort keys %commod) {
 100         $current= $commod{$commod};
 101         my @buys=  @{ bs_p($commod,Buy, -1) };
 102         my @sells= @{ bs_p($commod,Sell,+1) };
 103         my $profit= 0;
 104         my $cqty= 0;
 105         my $info= '';
 106         my $arbs= [];
 107         for (;;) {
 108 #print Dumper($commod,\@buys,\@sells);
 109             last unless @buys;
 110             last unless @sells;
 111             my $pricediff= $buys[0]{Price} - $sells[0]{Price};
 112             last unless $pricediff > 0;
 113             our $qty= 1000;
 114             sub arb_check_qty (\@) {
 115                 my ($verbs) = @_;
 116                 my $vqty= $verbs->[0]{Qty};
 117                 return if $vqty =~ m/^\>/;
 118                 $qty= $vqty if $qty > $vqty;
 119                 return if $vqty;
 120                 my $verb= shift @$verbs;
 121             }
 122             arb_check_qty(@buys);
 123             arb_check_qty(@sells);
 124             next unless $qty;
 125             my $tprofit= $qty*$pricediff;
 126             $profit += $tprofit;
 127             $cqty += $qty;
 128
 129             $info.=
 130                 sprintf("%-13.13s| %-19.19s %4d| %-19.19s %4d|%3d x%3d =%3d\n",
 131                        $commod,
 132                        $sells[0]{Stall},$sells[0]{Price},
 133                        $buys[0]{Stall},$buys[0]{Price},
 134                        $qty, $pricediff, $tprofit);
 135             sub arb_subtract_qty (\@) {
 136                 my ($verbs) = @_;
 137                 my $verb= shift @$verbs;
 138                 my $vqty= $verb->{Qty};
 139                 $vqty =~ s/^\>//;
 140                 unshift @$verbs, {
 141                     Stall => $verb->{Stall},
 142                     Price => $verb->{Price},
 143                     Qty => $vqty - $qty
 144                 };
 145             }
 146             arb_subtract_qty(@buys);
 147             arb_subtract_qty(@sells);
 148         }
 149         next unless $profit;
 150         $info.=
 151             sprintf("%-13.13s| %19s %4s| %19s %4s|%3d      %4d\n",
 152                     $commod, '','', '','', $cqty, $profit);
 153         push @arbs, { Profit => $profit, Info => $info };
 154     }
 155     my $allprofit;
 156
 157     if (!@arbs) {
 158         print "No arbitrage opportunities.\n" or die $!;
 159         return;
 160     }
 161     my $bigdiv= <<END;
 162 =============+=========================+=========================+=============
 163 END
 164
 165     print <<END or die $!;
 166
 167 commodity    | seller             price| buyer              price| qty  ea prof
 168 END
 169
 170     my $div= $bigdiv;
 171     foreach my $arb (sort {
 172         $b->{Profit} <=> $a->{Profit};
 173     } @arbs) {
 174         print $div,$arb->{Info} or die $1;
 175         $div= <<END;
 176 -------------+-------------------------+-------------------------+-------------
 177 END
 178         $allprofit += $arb->{Profit};
 179     }
 180     print $bigdiv or die $!;
 181     printf("%-13.13s  %19s %4s  %19s %4s %-5s %7d\n",
 182            '', '','', '','', 'TOTAL', $allprofit)
 183         or die $!;
 184 }
 185
 186 sub main__bestprices () {
 187     foreach $commod (sort keys %commod) {
 188         $current= $commod{$commod};
 189         my $buys=  bs_p($commod,Buy, -1);
 190         my $sells= bs_p($commod,Sell,+1);
 191         printf("%-15.15s", $commod) or die $!;
 192         bs_p_bestprice($buys);
 193         bs_p_bestprice($sells);
 194         print("\n") or die $!;
 195     }
 196 }
 197
 198 sub bs_p_tsv ($$) {
 199     my ($f, $bs) = @_;
 200     if (exists $current->{$bs}{$stall}) {
 201         my $si= $current->{$bs}{$stall};
 202         printf($f "\t%d\t%s", $si->{Price}, $si->{Qty}) or die $!;
 203     } else {
 204         printf($f "\t\t") or die $!;
 205     }
 206 }
 207
 208 sub write_tsv ($) {
 209     my ($f) = @_;
 210     foreach $commod (sort keys %commod) {
 211         $current= $commod{$commod};
 212         my %stalls;
 213         map { $stalls{$_}=1; } keys %{ $current->{Buy}  };
 214         map { $stalls{$_}=1; } keys %{ $current->{Sell} };
 215         foreach $stall (sort keys %stalls) {
 216             printf($f "%s\t%s", $commod, $stall) or die $!;
 217             bs_p_tsv($f, Buy);
 218             bs_p_tsv($f, Sell);
 219             print($f "\n") or die $!;
 220         }
 221     }
 222     $f->error and die $!;
 223     $f->flush or die $!;
 224 }
 225
 226 sub main__tsv () {
 227     write_tsv(\*STDOUT);
 228 }
 229
 230 sub undef_printable { my ($ov)= @_; defined $ov ? $ov : '?'; };
 231
 232 sub commodsinorder_print1 ($$) {
 233     my ($keyword,$commod) = @_;
 234     printf("%s\t%-40s %10s %s",
 235            $keyword,
 236            $commod,
 237            undef_printable($commods{$commod}{Ordval}),
 238            undef_printable($commods{$commod}{Class}))
 239         or die $!;
 240 }
 241
 242 sub main__commodsinorder () {
 243     parse_info_serverside();
 244     my $last_ov;
 245     foreach my $commod (@commods_inorder) {
 246         my $ov= $commods{$commod}{Ordval};
 247         commodsinorder_print1('found',$commod);
 248         if (defined $ov) {
 249             if (defined $last_ov && $ov <= $last_ov) {
 250                 print " out-of-order" or die $!;
 251             }
 252             $last_ov= $ov;
 253         }
 254         print "\n" or die $!;
 255     }
 256     foreach my $commod (sort {
 257             undef_printable($commods{$a}{Ordval}) cmp
 258             undef_printable($commods{$b}{Ordval})
 259         } keys %commods) {
 260         next if exists $commod{$commod};
 261         commodsinorder_print1('none',$commod);
 262         print "\n" or die $!;
 263     }
 264 }
 265
 266 our ($pctb) = $ENV{'YPPSC_YARRG_PCTB'};
 267
 268 our ($ua)= http_useragent("commod-results-processor $mode");
 269
 270 sub refresh_commodmap() {
 271     die unless $pctb;
 272     $pctb =~ s,/*$,,;
 273     my $resp= $ua->get("$pctb/commodmap.php?version=2");
 274     die $resp->status_line unless $resp->is_success;
 275
 276     my $cdata='';
 277     my $incommodmap=0;
 278     my $intag='';
 279     my %got;
 280     my $o= new IO::File "_commodmap.tsv.tmp",'w' or die $!;
 281     undef %pctb_commodmap;
 282
 283     my $xp= new XML::Parser
 284         (Handlers =>
 285          {
 286              Start => sub {
 287                  $_=$_[1];
 288 #print STDERR "START [$_] intag=$intag icm=$incommodmap\n";
 289                  if (m/^commodmap$/i) {
 290                      $incommodmap++;
 291                      undef %got;
 292                  } elsif (m/^(?:name|index)$/i) {
 293                      $cdata='';
 294                      $intag=lc($_) if $incommodmap;
 295 #print STDERR "START RECOGNISED $intag icm=$incommodmap\n";
 296 #                } else {
 297 #print STDERR "START UNRECOGNISED\n";
 298                  }
 299              },
 300              End => sub {
 301                  $_=$_[1];
 302 #print STDERR "END [$_] intag=$intag icm=$incommodmap\n";
 303                  if (m/^commodmap$/i) {
 304                      $incommodmap--;
 305                      die unless exists $got{'name'};
 306                      die unless exists $got{'index'};
 307                      die unless $got{'index'} =~ m/^\s*([1-9]\d{0,3})\s*$/;
 308                      my $index= $1;
 309                      $_= $got{'name'};
 310                      s/^\s+//; s/\s+$//; s/\n/ /g; s/\s+/ /;
 311                      die "$_ ?" if exists $pctb_commodmap{$_};
 312                      $pctb_commodmap{$_}= $index;
 313                      print $o "$_\t$index\n" or die $!;
 314                  } elsif (lc $_ eq $intag) {
 315                      $got{$intag}= $cdata;
 316                  }
 317              },
 318              Char => sub {
 319 #print STDERR "CHAR [$_[1]] intag=$intag icm=$incommodmap\n";
 320                  $cdata .= $_[1];
 321              }
 322          }) or die;
 323     my $content= $resp->content;
 324
 325 #    print STDERR "[[[$content]]]\n";
 326     my $commodmapxmltmp= '_commodmap.xml';
 327     if (!eval {
 328         $xp->parse($content); 1;
 329     }) {
 330         open R, ">./$commodmapxmltmp" or die $!;
 331         print R $content or die $!;
 332         close R or die $!;
 333         die "$@ parsing commodmap";
 334     }
 335     unlink $commodmapxmltmp or $!==&ENOENT or die $!;
 336     close $o or die $!;
 337     rename "_commodmap.tsv.tmp","_commodmap.tsv" or die $!;
 338 }
 339
 340 our %newcommods;
 341
 342 sub read_newcommods ($) {
 343     my ($file) = @_;
 344     if (!open NC, "< $file") {
 345         $!==&ENOENT or die $!;
 346         return;
 347     }
 348     while (<NC>) {
 349         chomp; s/^\s*//; s/\s+$//;
 350         next if m/^\#/;
 351         next unless m/\S/;
 352         $newcommods{$_}= 1;
 353     }
 354     NC->error and die $!;
 355     close NC or die $!;
 356 }
 357
 358 sub refresh_newcommods() {
 359     my $master= fetch_with_rsync('newcommods');
 360     read_newcommods($master);
 361     read_newcommods('_local-newcommods.txt');
 362 }
 363
 364 our (%stallmap, @stallmap);
 365
 366 sub bs_gen_md ($$) {
 367     my ($bs,$sortmul) = @_;
 368     my $count= 0;
 369     my $o= '';
 370
 371     foreach $commod (
 372                      sort { $pctb_commodmap{$a} <=> $pctb_commodmap{$b} }
 373                      grep { exists $pctb_commodmap{$_} }
 374                      keys %commod
 375                      ) {
 376 #print STDERR "COMMOD $commod\n";
 377         $current= $commod{$commod};
 378         my $l= bs_p($commod,$bs,$sortmul);
 379         next unless @$l;
 380 #print STDERR "COMMOD $commod  has ".scalar(@$l)."\n";
 381         $o .= writeint($pctb_commodmap{$commod});
 382         $o .= writeint(scalar @$l);
 383         foreach my $cs (@$l) {
 384             $stall= $cs->{Stall};
 385             my $stallix= $stallmap{$stall};
 386             if (!defined $stallix) {
 387                 push @stallmap, $stall;
 388                 $stallmap{$stall}= $stallix= @stallmap;
 389 #print STDERR "STALL DEF $stallix $stall\n";
 390             }
 391             my $qty= $cs->{Qty};
 392             $qty =~ s/^\>\s*//;
 393             $o .= writeint($stallix, $cs->{Price}, $qty+0);
 394             $count++;
 395         }
 396     }
 397 #print STDERR "COMMOD $commod COUNT WAS $count\n";
 398     return
 399         writeint($count).$o;
 400 }
 401
 402 sub writeint { return pack 'v*', @_; }
 403
 404 our (%stalltypetoabbrevmap)= qw(
 405                                 Apothecary    A
 406                                 Distilling    D
 407                                 Furnishing    F
 408                                 Ironworking   I
 409                                 Shipbuilding  S
 410                                 Tailoring     T
 411                                 Weaving       W
 412                                 );
 413
 414 sub genmarketdata () {
 415     our $version= '005b';
 416
 417     parse_pctb_commodmap();
 418     my @missing= grep { !exists $pctb_commodmap{$_} } keys %commod;
 419     if (@missing) {
 420         refresh_commodmap();
 421         refresh_newcommods();
 422         my $missing=0;
 423         foreach $commod (sort keys %commod) {
 424             next if exists $pctb_commodmap{$commod};
 425             if (exists $newcommods{$commod}) {
 426                 printf STDERR "Ignoring new commodity \`%s'!\n", $commod;
 427             } else {
 428                 printf STDERR "Unknown commodity \`%s'!\n", $commod;
 429                 $missing++;
 430             }
 431         }
 432         die "$missing unknown commoditi(es).".
 433             "  See README (search for \`newcommods').\n"
 434             if $missing;
 435     }
 436
 437     my $ob='';
 438     $ob .= bs_gen_md(Buy, -1);
 439     $ob .= bs_gen_md(Sell,+1);
 440
 441     my $ot= sprintf("$version\n".
 442                     "%d\n",
 443                     scalar(@stallmap));
 444     foreach $stall (@stallmap) {
 445         my $st= $stall;
 446         if ($st =~ m/^(\S+)\'s (\S+) Stall$/) {
 447             my $stkind= $stalltypetoabbrevmap{$2};
 448             if (defined $stkind) {
 449                 $st= "$1^$stkind";
 450             } else {
 451                 warn "unknown stall type $2 in $st\n";
 452             }
 453         }
 454         $ot .= "$st\n";
 455     }
 456     return $ot.$ob;
 457 }
 458
 459 sub main__genmarketdata () {
 460     my $o= genmarketdata();
 461     print $o or die $!;
 462 }
 463
 464 sub save_upload_html ($$) {
 465     my ($which, $resptxt) = @_;
 466     open R, ">./_upload-$which.html" or die $!;
 467     print R $resptxt or die $!;
 468     close R or die $!;
 469 }
 470
 471 sub gzip ($) {
 472     my ($raw) = @_;
 473     my $tf= pipethrough_prep();
 474     print $tf $raw or die $!;
 475     return pipethrough_run($tf,undef,'gzip','gzip');
 476 }
 477
 478 sub main__uploadyarrg () {
 479     my %o;
 480
 481     parse_info_clientside();
 482
 483     $o{'ocean'}= $ENV{'YPPSC_OCEAN'} or die;
 484     $o{'island'}= $ENV{'YPPSC_ISLAND'} or die;
 485     $o{'timestamp'}= $ENV{'YPPSC_DATA_TIMESTAMP'} or die;
 486
 487     my $tf= pipethrough_prep();
 488     write_tsv($tf);
 489     my $oz= pipethrough_run_gzip($tf);
 490     $o{'data'}=  [ undef, 'deduped.tsv.gz',
 491                     Content_Type => 'application/octet-stream',
 492                     Content => $oz ];
 493
 494     my $respcontent= yarrgpostform($ua, \%o);
 495     $respcontent =~ m/^OK\b/ or die "$respcontent ?";
 496     $respcontent =~ s/^/ /mg;
 497     print $respcontent,"\n";
 498 }
 499
 500 sub main__uploadpctb () {
 501     my $ocean= $ENV{'YPPSC_OCEAN'};  die unless $ocean;
 502     my $island= $ENV{'YPPSC_ISLAND'};  die unless $island;
 503     die unless $pctb;
 504     my $o= genmarketdata();
 505     $pctb =~ s,/*$,,;
 506     my $url= "$pctb/upload.php";
 507     my $content= {
 508         'marketdata' => [ undef, "marketdata.gz",
 509                           Content_Type => 'application/gzip',
 510                           Content => gzip($o),
 511                           ]
 512                       };
 513
 514     print STDERR "Uploading data to $pctb...\n";
 515
 516     my $resp= $ua->post("$url", Content => $content,
 517                         Content_Type => 'form-data');
 518     die $resp->status_line unless $resp->is_success;
 519
 520     my $resptxt= $resp->content();
 521     save_upload_html('1', $resptxt);
 522
 523     open R, ">./_upload-1.html" or die $!;
 524     print R $resptxt or die $!;
 525     close R or die $!;
 526
 527     my @filenames= $resptxt =~
 528  m/input\s+type="hidden"\s+name="filename"\s+value=\"([_.0-9a-z]+)\"/ig;
 529     @filenames or die;
 530
 531     my @forcerls= $resptxt =~
 532  m/input\s+type="hidden"\s+name="forcereload"\s+value=\"([1-9]\d+)\"/ig;
 533     @forcerls or die;
 534
 535     my $filename= $filenames[0];
 536     my $forcerl= $forcerls[0];
 537
 538     $ocean= ucfirst lc $ocean;
 539     my @oceanids= $resptxt =~
 540  m/\<option value\=\"(\d+)\"\>$ocean\<\/option\>/;
 541     @oceanids==1 or die "@oceanids ?";
 542
 543     my $islandid;
 544     while ($resptxt =~
 545  m/^islands\[\d+\]\[\d+\]\=new\s+option\(\"(.*)\"\,(\d+)\)\s*$/mig
 546            ) {
 547         next unless $1 eq $island;
 548         $islandid= $2;
 549     }
 550     defined $islandid or die;
 551
 552     die "@filenames ?" if grep { $_ ne $filename } @filenames;
 553     die "@forcerls ?" if grep { $_ ne $forcerl } @forcerls;
 554
 555     my $setisland= {
 556     };
 557
 558     print STDERR "Setting ocean and island...\n";
 559
 560     my $siurl= ($url . "?action=setisland".
 561                 "&filename=$filename".
 562                 "&forcereload=$forcerl".
 563                 "&ocean=$oceanids[0]".
 564                 "&island=$islandid");
 565     $resp= $ua->get($siurl);
 566
 567     die $resp->status_line unless $resp->is_success;
 568
 569     $resptxt= $resp->content();
 570     save_upload_html('2', $resptxt);
 571
 572     die unless $resptxt =~ m/your uploaded data has been processed/i;
 573     die unless $resptxt =~ m/your data has been integrated into the database/i;
 574
 575     $resptxt =~ s/\<a href=\"about:\w+\"\>[^<>]+\<\/a\>//g;
 576     save_upload_html('3', $resptxt);
 577
 578     print "\n" or die $!;
 579     system('w3m -T text/html -dump < _upload-3.html');
 580
 581     print "\n" or die $!;
 582 }
 583
 584
 585 $mode =~ s/\-//;
 586 &{"main__$mode"};
 587 close(STDOUT) or die $!;