yarrg/Commods.pm

   1 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   2 # players of Yohoho Puzzle Pirates.
   3 #
   4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  20 # are used without permission.  This program is not endorsed or
  21 # sponsored by Three Rings.
  22
  23 package Commods;
  24 use IO::File;
  25 use HTTP::Request::Common ();
  26 use POSIX;
  27
  28 use strict;
  29 use warnings;
  30
  31 BEGIN {
  32     use Exporter ();
  33     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  34     $VERSION     = 1.00;
  35     @ISA         = qw(Exporter);
  36     @EXPORT      = qw(&parse_info_clientside &fetch_with_rsync
  37                       &parse_info_serverside &parse_info_serverside_ocean
  38                       %oceans %commods %clients %routes %route_mysteries
  39                       &parse_pctb_commodmap %pctb_commodmap @pctb_commodmap
  40                       &get_our_version &check_tsv_line
  41                       &pipethrough_prep &pipethrough_run
  42                       &pipethrough_run_along &pipethrough_run_finish
  43                       &pipethrough_run_gzip
  44                       &cgipostform &yarrgpostform &cgi_get_caller
  45                       &set_ctype_utf8);
  46     %EXPORT_TAGS = ( );
  47
  48     @EXPORT_OK   = qw();
  49 }
  50
  51 our %oceans; # eg $oceans{'Midnight'}{'Ruby'}{'Eta Island'}= $sources;
  52 our %clients; # eg $clients{'ypp-sc-tools'}= [ qw(last-page) ];
  53 our %routes; # eg $routes{'Midnight'}{'Orca'}{'Tinga'}= $sources  NB abbrevs!
  54 our %route_mysteries; # eg $route_mysteries{'Midnight'}{'Norse'}= 3
  55 # $sources = 's[l]b';
  56 #       's' = Special Circumstances; 'l' = local ; B = with Bleach
  57
  58 our %commods;
  59 # eg $commods{'Fine black cloth'}{Srcs}= $sources;
  60 # eg $commods{'Fine black cloth'}{Mass}= 700 [g]
  61 # eg $commods{'Fine black cloth'}{Volume}= 1000 [ml]
  62
  63 our (%pctb_commodmap,@pctb_commodmap);
  64
  65 my %colours; # eg $colours{'c'}{'black'}= $sources
  66 my @rawcm; # eg $rawcm[0]='fine rum'; $rawcm[1]='fine %c cloth'
  67
  68 sub parse_info1 ($$) {
  69     my ($mmfn,$src)= @_;
  70     my $mm= new IO::File $mmfn, 'r' or die "$mmfn $!";
  71     my @ctx= ();
  72     while (<$mm>) {
  73         next if m/^\s*\#/;
  74         next unless m/\S/;
  75         s/\s+$//;
  76         if (m/^\%(\w+)$/) {
  77             my $colourkind= $1;
  78             @ctx= (sub { $colours{$colourkind}{lc $_} .= $src; });
  79         } elsif (m/^commods$/) {
  80             @ctx= (sub { push @rawcm, lc $_; });
  81         } elsif (m/^ocean (\w+)$/) {
  82             my $ocean= $1;
  83             @ctx= (sub {
  84                 $ocean or die; # ref to $ocean needed to work
  85                                # around a perl bug
  86                 my $arch= $_;
  87                 $ctx[1]= sub {
  88                     $oceans{$ocean}{$arch}{$_} .= $src;
  89                 };
  90             });
  91         } elsif (m/^routes (\w+)$/) {
  92             my $ocean= $1;
  93             @ctx= (sub {
  94                 m/^(\S[^\t]*\S),\s*(\S[^\t]*\S),\s*([1-9][0-9]{0,2})$/ or die;
  95                 $routes{$ocean}{$1}{$2}= $3;
  96             });
  97         } elsif (m/^client (\S+.*\S)$/) {
  98             my $client= $1;
  99             $clients{$client}= [ ];
 100             @ctx= (sub {
 101                 my $bug= $_;
 102                 push @{ $clients{$client} }, $bug;
 103             });
 104         } elsif (s/^ +//) {
 105             my $indent= length $&;
 106             die "wrong indent $indent" unless defined $ctx[$indent-1];
 107             &{ $ctx[$indent-1] }();
 108         } else {
 109             die "bad syntax";
 110         }
 111     }
 112     $mm->error and die $!;
 113     close $mm or die $!;
 114
 115 #print Dumper(\%oceans);
 116 #print Dumper(\@rawcm);
 117
 118     %commods= ();
 119     my $ca;
 120     $ca= sub {
 121         my ($s,$ss) = @_;
 122 #print "ca($s)\n";
 123         if ($s !~ m/\%(\w+)/) {
 124             my ($name, $props) = $s =~
 125                 /^(\S[^\t]*\S)(?:\t+(\S[^\t]*\S))?$/
 126                 or die "bad commodspec $s";
 127             my $ucname= ucfirst $name;
 128             $commods{$ucname}{Srcs} .= $ss;
 129             my $c= $commods{$ucname};
 130             $c->{Volume}= 1000;
 131             foreach my $prop (defined $props ? split /\s+/, $props : ()) {
 132                 if ($prop =~ m/^([1-9]\d*)(k?)g$/) {
 133                     $c->{Mass}= $1 * ($2 ? 1000 : 1);
 134                 } elsif ($prop =~m/^([1-9]\d*)l$/) {
 135                     $c->{Volume}= $1 * 1000;
 136                 } else {
 137                     die "unknown property $prop for $ucname";
 138                 }
 139             }
 140             return;
 141         }
 142         die "unknown $&" unless defined $colours{$1};
 143         my ($lhs,$pctlet,$rhs)= ($`,$1,$');
 144         foreach my $c (keys %{ $colours{$pctlet} }) {
 145             &$ca($lhs.$c.$rhs, $ss .'%'. $colours{$pctlet}{$c});
 146         }
 147     };
 148     foreach (@rawcm) { &$ca($_,$src); }
 149
 150     foreach my $on (keys %routes) {
 151         my $routes= $routes{$on};
 152         my $ocean= $oceans{$on};
 153         die unless defined $ocean;
 154
 155         my @allislands;
 156         foreach my $an (sort keys %$ocean) {
 157             my $arch= $ocean->{$an};
 158             push @allislands, sort keys %$arch;
 159         }
 160         parse_info_maproutes($on, \@allislands, $routes);
 161         foreach my $route (values %$routes) {
 162             parse_info_maproutes($on, \@allislands, $route);
 163         }
 164     }
 165 }
 166
 167 sub parse_info_clientside () {
 168     my $yarrg= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
 169     return unless $yarrg;
 170     my $master= fetch_with_rsync('info');
 171     parse_info1($master,'s');
 172     my $local= '_local-info.txt';
 173     if (stat $local) {
 174         parse_info1($local,'s');
 175     } else {
 176         die "$local $!" unless $! == &ENOENT;
 177     }
 178 }
 179
 180 sub fetch_with_rsync ($) {
 181     my ($stem) = @_;
 182
 183     my $rsync= $ENV{'YPPSC_YARRG_RSYNC'};
 184     $rsync= 'rsync' if !defined $rsync;
 185
 186     my $local= "_master-$stem.txt";
 187     my $src= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
 188     if ($src) {
 189         my $remote= "$src/master-$stem.txt";
 190         $!=0; system 'rsync','-Lt','--',$remote,$local;
 191         die "$? $!" if $! or $?;
 192     }
 193     return $local;
 194 }
 195
 196 sub parse_info_maproutes ($$$) {
 197     my ($on, $allislands, $routemap) = @_;;
 198     foreach my $k (sort keys %$routemap) {
 199         my @ok= grep { index($_,$k) >= 0 } @$allislands;
 200         die "ambiguous $k" if @ok>1;
 201         if (!@ok) {
 202             $route_mysteries{$on}{$k}++;
 203             delete $routemap->{$k};
 204         } elsif ($ok[0] ne $k) {
 205             $routemap->{$ok[0]}= $routemap->{$k};
 206             delete $routemap->{$k};
 207         }
 208     }
 209 }
 210
 211 sub parse_info_serverside () {
 212     parse_info1('master-info.txt','s');
 213 }
 214 sub parse_info_serverside_ocean ($) {
 215     my ($oceanname) = @_;
 216     die "unknown ocean $oceanname ?" unless exists $oceans{$oceanname};
 217     parse_info1("ocean-".(lc $oceanname).".txt",'s');
 218 }
 219
 220 sub parse_pctb_commodmap () {
 221     undef %pctb_commodmap;
 222     foreach my $commod (keys %commods) { $commods{$commod}{Srcs} =~ s/b//; }
 223
 224     my $c= new IO::File '_commodmap.tsv';
 225     if (!$c) { $!==&ENOENT or die $!; return 0; }
 226
 227     while (<$c>) {
 228         m/^(\S.*\S)\t(\d+)\n$/ or die "$_";
 229         die if defined $pctb_commodmap{$1};  $pctb_commodmap{$1}= $2;
 230         die if defined $pctb_commodmap[$2];  $pctb_commodmap[$2]= $1;
 231         $commods{$1}{Srcs} .= 'b';
 232     }
 233     $c->error and die $!;
 234     close $c or die $!;
 235     return 1;
 236 }
 237
 238 sub get_our_version ($$) {
 239     my ($aref,$prefix) = @_;
 240     $aref->{"${prefix}name"}= 'ypp-sc-tools yarrg';
 241     $aref->{"${prefix}fixes"}= 'lastpage';
 242
 243     my $version= `git-describe --tags HEAD || echo 0unknown`; $? and die $?;
 244     chomp($version);
 245     $aref->{"${prefix}version"}= $version;
 246     return $aref;
 247     # clientname        "ypp-sc-tools"
 248     # clientversion     2.1-g2e06a26  [from git-describe --tags HEAD]
 249     # clientfixes       "lastpage"  [space separated list]
 250 }
 251
 252 sub pipethrough_prep () {
 253     my $tf= IO::File::new_tmpfile() or die $!;
 254     return $tf;
 255 }
 256
 257 sub pipethrough_run_along ($$$@) {
 258     my ($tf, $childprep, $cmd, @a) = @_;
 259     $tf->error and die $!;
 260     $tf->flush or die $!;
 261     $tf->seek(0,0) or die $!;
 262     my $fh= new IO::File;
 263     my $child= $fh->open("-|"); defined $child or die $!;
 264     if (!$child) {
 265         open STDIN, "<&", $tf;
 266         &$childprep() if defined $childprep;
 267         exec $cmd @a; die "@a $!";
 268     }
 269     return $fh;
 270 }
 271 sub pipethrough_run_finish ($$) {
 272     my ($fh, $what)= @_;
 273     $fh->error and die $!;
 274     close $fh or die "$what $! $?";  die $? if $?;
 275 }
 276
 277 sub pipethrough_run ($$$@) {
 278     my ($tf, $childprep, $cmd, @a) = @_;
 279     my $pt= pipethrough_run_along($tf,$childprep,$cmd,@a);
 280     my $r;
 281     { undef $/; $!=0; $r= <$pt>; }
 282     defined $r or die $!;
 283     pipethrough_run_finish($pt, "@a");
 284     return $r;
 285 }
 286 sub pipethrough_run_gzip ($) {
 287     pipethrough_run($_[0],undef,'gzip','gzip');
 288 }
 289
 290 sub yarrgpostform ($$) {
 291     my ($ua, $form) = @_;
 292     my $dest= $ENV{'YPPSC_YARRG_YARRG'};
 293     get_our_version($form, 'client');
 294     die unless $dest =~ m,/$,;
 295     return cgipostform($ua, "${dest}commod-update-receiver", $form);
 296 }
 297
 298 sub cgipostform ($$$) {
 299     my ($ua, $url, $form) = @_;
 300     my $req= HTTP::Request::Common::POST($url,
 301                                          Content => $form,
 302                                          Content_Type => 'form-data');
 303     if ($url =~ m,^\.?/,) {
 304         my $tf= pipethrough_prep();
 305         print $tf $req->content() or die $!;
 306 #print STDERR "[[[",$req->content(),"]]]";
 307         my $out= pipethrough_run($tf, sub {
 308             $ENV{'REQUEST_METHOD'}= 'POST';
 309             $ENV{'QUERY_STRING'}= '';
 310             $ENV{'PATH_TRANSLATED'}= $url;
 311             $ENV{'PATH_INFO'}= '';
 312             $ENV{'HTTP_HOST'}= 'localhost';
 313             $ENV{'REMOTE_ADDR'}= '127.0.0.1';
 314             $ENV{'GATEWAY_INTERFACE'}= 'CGI/1.1';
 315             $ENV{'DOCUMENT_ROOT'}= '.';
 316             $ENV{'SCRIPT_FILENAME'}= $url;
 317             $ENV{'SCRIPT_NAME'}= $url;
 318             $ENV{'HTTP_USER_AGENT'}= 'Commods.pm local test';
 319
 320             foreach my $f (qw(Content_Length Content_Type)) {
 321                 $ENV{uc $f}= $req->header($f);
 322             }
 323 #system 'printenv >&2';
 324         }, "$url", "$url");
 325         $out =~ s/\r\n/\n/g;
 326         $out =~ m,^Content-Type: text/plain.*\n\n, or die "$out ?";
 327         return $';
 328     } else {
 329         my $resp= $ua->request($req);
 330         die $resp->status_line."\n".$resp->content."\n "
 331             unless $resp->is_success;
 332         return $resp->content();
 333     }
 334 }
 335
 336 our %check_tsv_done;
 337
 338 sub check_tsv_line ($$) {
 339     my ($l, $bad_data_callback) = @_;
 340     my $bad_data= sub { &$bad_data_callback("bad data: line $.: $_[0]"); };
 341
 342     chomp($l) or &$bad_data('missing end-of-line');
 343
 344     $l !~ m/\P{IsPrint}/ or &$bad_data('nonprinting char(s)');
 345     my @v= split /\t/, $l, -1;
 346     @v==6 or &$bad_data('wrong number of fields');
 347     my ($commod,$stall) = @v;
 348
 349     !keys %commods or
 350         defined $commods{$commod} or
 351         &$bad_data("unknown commodity \`$commod'");
 352
 353     $stall =~ m/^\p{IsUpper}|^[0-9]/ or &$bad_data("stall not capitalised");
 354     !exists $check_tsv_done{$commod,$stall} or &$bad_data("repeated data");
 355     $check_tsv_done{$commod,$stall}= 1;
 356     foreach my $i (2..5) {
 357         my $f= $v[$i];
 358         $f =~ m/^(|0|[1-9][0-9]{0,5}|\>1000)$/ or &$bad_data("bad field $i");
 359         ($i % 2) or ($f !~ m/\>/) or &$bad_data("> in field $i price");
 360     }
 361
 362     foreach my $i (2,4) {
 363         &$bad_data("price with no qty or vice versa (field $i)")
 364             if length($v[$i]) xor length($v[$i+1]);
 365     }
 366     length($v[2]) or length($v[4]) or
 367         &$bad_data("commodity entry with no buy or sell offer");
 368
 369     return @v;
 370 }
 371
 372 sub cgi_get_caller () {
 373     my $caller= $ENV{'REMOTE_ADDR'};
 374     $caller= 'LOCAL' unless defined $caller;
 375
 376     my $fwdf= $ENV{'HTTP_X_FORWARDED_FOR'};
 377     if (defined $fwdf) {
 378         $fwdf =~ s/\s//g;
 379         $fwdf =~ s/[^0-9.,]/?/g;
 380         $caller= "$fwdf";
 381     }
 382     return $caller;
 383 }
 384
 385 sub set_ctype_utf8 () {
 386     setlocale(LC_CTYPE, "en.UTF-8");
 387 }
 388
 389 1;