chiark - git - mdw - sod/blob - src/method-impl.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Method combination implementation
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Message classes.
  30
  31 (export 'basic-message)
  32 (defclass basic-message (sod-message)
  33   ((argument-tail :type list :reader sod-message-argument-tail))
  34   (:documentation
  35    "Base class for built-in message classes.
  36
  37    Provides the basic functionality for the built-in method combinations.
  38    This is a separate class so that `special effect' messages can avoid
  39    inheriting its default behaviour.
  40
  41    The function type protocol is implemented on `basic-message' using slot
  42    reader methods.  The actual values are computed on demand."))
  43
  44 (define-on-demand-slot basic-message argument-tail (message)
  45   (let ((seq 0))
  46     (mapcar (lambda (arg)
  47               (if (or (eq arg :ellipsis) (argument-name arg)) arg
  48                   (make-argument (make-instance 'temporary-argument
  49                                                 :tag (prog1 seq
  50                                                        (incf seq)))
  51                                  (argument-type arg))))
  52             (c-function-arguments (sod-message-type message)))))
  53
  54 (defmethod sod-message-method-class
  55     ((message basic-message) (class sod-class) pset)
  56   (let ((role (get-property pset :role :keyword nil)))
  57     (case role
  58       ((:before :after) 'daemon-direct-method)
  59       (:around 'delegating-direct-method)
  60       ((nil) (error "How odd: a primary method slipped through the net"))
  61       (t (error "Unknown method role ~A" role)))))
  62
  63 (export 'simple-message)
  64 (defclass simple-message (basic-message)
  65   ()
  66   (:documentation
  67    "Base class for messages with `simple' method combinations.
  68
  69    A simple method combination is one which has only one method role other
  70    than the `before', `after' and `around' methods provided by
  71    `basic-message'.  We call these `primary' methods, and the programmer
  72    designates them by not specifying an explicit role.
  73
  74    If the programmer doesn't define any primary methods then the effective
  75    method is null -- i.e., the method entry pointer shows up as a null
  76    pointer."))
  77
  78 (defmethod sod-message-method-class
  79     ((message simple-message) (class sod-class) pset)
  80   (if (get-property pset :role :keyword nil)
  81       (call-next-method)
  82       (primary-method-class message)))
  83
  84 (defmethod primary-method-class ((message simple-message))
  85   'basic-direct-method)
  86
  87 ;;;--------------------------------------------------------------------------
  88 ;;; Direct method classes.
  89
  90 (export '(basic-direct-method sod-method-role))
  91 (defclass basic-direct-method (sod-method)
  92   ((role :initarg :role :type symbol :reader sod-method-role)
  93    (function-type :type c-function-type :reader sod-method-function-type))
  94   (:documentation
  95    "Base class for built-in direct method classes.
  96
  97    Provides the basic functionality for the built-in direct-method classes.
  98    This is a separate class so that `special effect' methods can avoid
  99    inheriting its default behaviour and slots.
 100
 101    A basic method can be assigned a `role', which may be set either as an
 102    initarg or using the `:role' property.  Roles are used for method
 103    categorization.
 104
 105    The function type protocol is implemented on `basic-direct-method' using
 106    slot reader methods."))
 107
 108 (defmethod shared-initialize :after
 109     ((method basic-direct-method) slot-names &key pset)
 110   (declare (ignore slot-names))
 111   (default-slot (method 'role) (get-property pset :role :keyword nil)))
 112
 113 (defun direct-method-suppliedp-struct-tag (direct-method)
 114   (with-slots ((class %class) role message) direct-method
 115     (format nil "~A__~@[~(~A~)_~]suppliedp_~A__~A"
 116             class role
 117             (sod-class-nickname (sod-message-class message))
 118             (sod-message-name message))))
 119
 120 (defun effective-method-keyword-struct-tag (effective-method)
 121   (with-slots ((class %class) message) effective-method
 122     (format nil "~A__keywords_~A__~A"
 123             class
 124             (sod-class-nickname (sod-message-class message))
 125             (sod-message-name message))))
 126
 127 (defun fix-up-keyword-method-args (method args)
 128   "Adjust the ARGS to include METHOD's `suppliedp' and keyword arguments.
 129
 130    Return the adjusted list.  The `suppliedp' argument, if any, is prepended
 131    to the list; the keyword arguments are added to the end.
 132
 133    (The input ARGS list is not actually modified.)"
 134   (let* ((type (sod-method-type method))
 135          (keys (c-function-keywords type))
 136          (tag (direct-method-suppliedp-struct-tag method)))
 137     (append (and keys
 138                  (list (make-argument "suppliedp" (c-type (struct tag)))))
 139             args
 140             (mapcar (lambda (key)
 141                       (make-argument (argument-name key)
 142                                      (argument-type key)))
 143                     keys))))
 144
 145 (define-on-demand-slot basic-direct-method function-type (method)
 146   (let* ((message (sod-method-message method))
 147          (type (sod-method-type method))
 148          (method-args (c-function-arguments type)))
 149     (when (keyword-message-p message)
 150       (setf method-args (fix-up-keyword-method-args method method-args)))
 151     (c-type (fun (lisp (c-type-subtype type))
 152                  ("me" (* (class (sod-method-class method))))
 153                  . method-args))))
 154
 155 (defmethod sod-method-description ((method basic-direct-method))
 156   (with-slots (role) method
 157     (if role (string-downcase role)
 158         "primary")))
 159
 160 (defmethod sod-method-function-name ((method basic-direct-method))
 161   (with-slots ((class %class) role message) method
 162     (format nil "~A__~@[~(~A~)_~]method_~A__~A" class role
 163             (sod-class-nickname (sod-message-class message))
 164             (sod-message-name message))))
 165
 166 (export 'daemon-direct-method)
 167 (defclass daemon-direct-method (basic-direct-method)
 168   ()
 169   (:documentation
 170    "A daemon direct method is invoked for side effects and cannot override.
 171
 172    This is the direct method class for `before' and `after' methods, which
 173    cannot choose to override the remaining methods and are not involved in
 174    the computation of the final result.
 175
 176    In C terms, a daemon method must return `void', and is not passed a
 177    `next_method' pointer."))
 178
 179 (defmethod check-method-type ((method daemon-direct-method)
 180                               (message sod-message)
 181                               (type c-function-type))
 182   (with-slots ((msgtype %type)) message
 183     (check-method-return-type type c-type-void)
 184     (check-method-argument-lists type msgtype)))
 185
 186 (export 'delegating-direct-method)
 187 (defclass delegating-direct-method (basic-direct-method)
 188   ((next-method-type :type c-function-type
 189                      :reader sod-method-next-method-type))
 190   (:documentation
 191    "A delegating direct method can choose to override other methods.
 192
 193    This is the direct method class for `around' and standard-method-
 194    combination primary methods, which are given the choice of computing the
 195    entire method's result or delegating to (usually) less-specific methods.
 196
 197    In C terms, a delegating method is passed a `next_method' pointer so that
 198    it can delegate part of its behaviour.  (A delegating direct method for a
 199    varargs message is also given an additional `va_list' argument,
 200    conventionally named `sod__ap_master', which it is expected to pass on to
 201    its `next_method' function if necessary.)
 202
 203    The function type protocol is implemented on `delegating-direct-method'
 204    using slot reader methods.."))
 205
 206 (define-on-demand-slot delegating-direct-method next-method-type (method)
 207   (let* ((message (sod-method-message method))
 208          (return-type (c-type-subtype (sod-message-type message)))
 209          (msgargs (sod-message-argument-tail message))
 210          (arguments (cond ((varargs-message-p message)
 211                            (cons (make-argument *sod-master-ap*
 212                                                 c-type-va-list)
 213                                  (butlast msgargs)))
 214                           ((keyword-message-p message)
 215                            (cons (make-argument *sod-keywords*
 216                                                 (c-type (* (void :const))))
 217                                  msgargs))
 218                           (t
 219                            msgargs))))
 220     (c-type (fun (lisp return-type)
 221                  ("me" (* (class (sod-method-class method))))
 222                  . arguments))))
 223
 224 (define-on-demand-slot delegating-direct-method function-type (method)
 225   (let* ((message (sod-method-message method))
 226          (type (sod-method-type method))
 227          (method-args (c-function-arguments type))
 228          (next-method-arg (make-argument
 229                            "next_method"
 230                            (make-pointer-type
 231                             (commentify-function-type
 232                              (sod-method-next-method-type method))))))
 233     (cond ((varargs-message-p message)
 234            (push (make-argument *sod-master-ap* c-type-va-list)
 235                  method-args)
 236            (push next-method-arg method-args))
 237           ((keyword-message-p message)
 238            (push (make-argument *sod-keywords* (c-type (* (void :const))))
 239                  method-args)
 240            (push next-method-arg method-args)
 241            (setf method-args
 242                  (fix-up-keyword-method-args method method-args)))
 243           (t
 244            (push next-method-arg method-args)))
 245     (c-type (fun (lisp (c-type-subtype type))
 246                  ("me" (* (class (sod-method-class method))))
 247                  . method-args))))
 248
 249 ;;;--------------------------------------------------------------------------
 250 ;;; Effective method classes.
 251
 252 (defmethod method-keyword-argument-lists
 253     ((method effective-method) direct-methods state)
 254   (with-slots (message) method
 255     (and (keyword-message-p message)
 256          (cons (cons (lambda (arg)
 257                        (let ((class (sod-message-class message)))
 258                          (info-with-location
 259                           message "Type `~A' declared in message ~
 260                                    definition in `~A' (here)"
 261                           (argument-type arg) class)
 262                          (report-inheritance-path state class)))
 263                      (c-function-keywords (sod-message-type message)))
 264                (mapcar (lambda (m)
 265                          (cons (lambda (arg)
 266                                  (let ((class (sod-method-class m)))
 267                                    (info-with-location
 268                                     m "Type `~A' declared in ~A direct ~
 269                                        method of `~A' (defined here)"
 270                                     (argument-type arg)
 271                                     (sod-method-description m) class)
 272                                    (report-inheritance-path state class)))
 273                                (c-function-keywords (sod-method-type m))))
 274                        direct-methods)))))
 275
 276 (defmethod shared-initialize :after
 277     ((method effective-method) slot-names &key direct-methods)
 278   (declare (ignore slot-names))
 279
 280   ;; Set the keyword argument list.  Blame the class as a whole for mismatch
 281   ;; errors, because they're fundamentally a non-local problem about the
 282   ;; class construction.
 283   (with-slots ((class %class) message keywords) method
 284     (setf keywords
 285           (merge-keyword-lists
 286            (lambda ()
 287              (values class
 288                      (format nil
 289                              "methods for message `~A' ~
 290                               applicable to class `~A'"
 291                              message class)))
 292            (method-keyword-argument-lists method direct-methods
 293             (make-inheritance-path-reporter-state class))))))
 294
 295 (export '(basic-effective-method
 296           effective-method-around-methods effective-method-before-methods
 297           effective-method-after-methods))
 298 (defclass basic-effective-method (effective-method)
 299   ((around-methods :initarg :around-methods :initform nil
 300                    :type list :reader effective-method-around-methods)
 301    (before-methods :initarg :before-methods :initform nil
 302                    :type list :reader effective-method-before-methods)
 303    (after-methods :initarg :after-methods :initform nil
 304                   :type list :reader effective-method-after-methods)
 305    (basic-argument-names :type list
 306                          :reader effective-method-basic-argument-names)
 307    (functions :type list :reader effective-method-functions))
 308   (:documentation
 309    "Base class for built-in effective method classes.
 310
 311    This class maintains lists of the applicable `before', `after' and
 312    `around' methods and provides behaviour for invoking these methods
 313    correctly.
 314
 315    The argument names protocol is implemented on `basic-effective-method'
 316    using a slot reader method."))
 317
 318 (define-on-demand-slot basic-effective-method basic-argument-names (method)
 319   (let* ((message (effective-method-message method))
 320          (raw-tail (sod-message-argument-tail message)))
 321     (mapcar #'argument-name (reify-variable-argument-tail raw-tail))))
 322
 323 (defmethod effective-method-function-name ((method effective-method))
 324   (let* ((class (effective-method-class method))
 325          (message (effective-method-message method))
 326          (message-class (sod-message-class message)))
 327     (format nil "~A__emethod_~A__~A"
 328             class
 329             (sod-class-nickname message-class)
 330             (sod-message-name message))))
 331
 332 (define-on-demand-slot basic-effective-method functions (method)
 333   (compute-method-entry-functions method))
 334
 335 (export 'simple-effective-method)
 336 (defclass simple-effective-method (basic-effective-method)
 337   ((primary-methods :initarg :primary-methods :initform nil
 338                     :type list :reader effective-method-primary-methods))
 339   (:documentation
 340    "Effective method counterpart to `simple-message'."))
 341
 342 (defmethod shared-initialize :after
 343     ((method simple-effective-method) slot-names &key direct-methods)
 344   (declare (ignore slot-names))
 345   (categorize (method direct-methods :bind ((role (sod-method-role method))))
 346       ((primary (null role))
 347        (before (eq role :before))
 348        (after (eq role :after))
 349        (around (eq role :around)))
 350     (with-slots (primary-methods before-methods after-methods around-methods)
 351         method
 352       (setf primary-methods primary
 353             before-methods before
 354             after-methods (reverse after)
 355             around-methods around))))
 356
 357 ;;;--------------------------------------------------------------------------
 358 ;;; Code generation.
 359
 360 (defmethod shared-initialize :after
 361     ((codegen method-codegen) slot-names &key)
 362   (declare (ignore slot-names))
 363   (with-slots (message target) codegen
 364     (setf target
 365           (if (eq (c-type-subtype (sod-message-type message)) c-type-void)
 366               :void
 367               :return))))
 368
 369 ;;;--------------------------------------------------------------------------
 370 ;;; Invoking direct methods.
 371
 372 (export 'basic-effective-method-body)
 373 (defun basic-effective-method-body (codegen target method body)
 374   "Build the common method-invocation structure.
 375
 376    Writes to CODEGEN some basic method-invocation instructions.  It invokes
 377    the `around' methods, from most- to least-specific.  If they all delegate,
 378    then the `before' methods are run, most-specific first; next, the
 379    instructions generated by BODY (invoked with a target argument); then, the
 380    `after' methods are run, least-specific first; and, finally, the value
 381    delivered by the BODY is returned to the `around' methods.  The result
 382    returned by the outermost `around' method -- or, if there are none,
 383    delivered by the BODY -- is finally delivered to the TARGET."
 384
 385   (with-slots (message (class %class)
 386                before-methods after-methods around-methods)
 387       method
 388     (let* ((message-type (sod-message-type message))
 389            (return-type (c-type-subtype message-type))
 390            (basic-tail (effective-method-basic-argument-names method)))
 391       (flet ((method-kernel (target)
 392                (dolist (before before-methods)
 393                  (invoke-method codegen :void basic-tail before))
 394                (if (null after-methods)
 395                    (funcall body target)
 396                    (convert-stmts codegen target return-type
 397                                   (lambda (target)
 398                                     (funcall body target)
 399                                     (dolist (after (reverse after-methods))
 400                                       (invoke-method codegen :void
 401                                                      basic-tail after)))))))
 402         (invoke-delegation-chain codegen target basic-tail
 403                                  around-methods #'method-kernel)))))
 404
 405 ;;;--------------------------------------------------------------------------
 406 ;;; Method entry points.
 407
 408 (defparameter *method-entry-inline-threshold* 200
 409   "Threshold below which effective method bodies are inlined into entries.
 410
 411    After the effective method body has been computed, we calculate its
 412    metric, multiply by the number of entries we need to generate, and compare
 413    it with this threshold.  If the metric is below the threshold then we
 414    fold the method body into the entry functions; otherwise we split the
 415    effective method out into its own function.")
 416
 417 (defmethod method-entry-function-name
 418     ((method effective-method) (chain-head sod-class) role)
 419   (let* ((class (effective-method-class method))
 420          (message (effective-method-message method))
 421          (message-class (sod-message-class message)))
 422     (if (or (not (slot-boundp method 'functions))
 423             (slot-value method 'functions))
 424         (format nil "~A__mentry~@[__~(~A~)~]_~A__~A__chain_~A"
 425                 class role
 426                 (sod-class-nickname message-class)
 427                 (sod-message-name message)
 428                 (sod-class-nickname chain-head))
 429         *null-pointer*)))
 430
 431 (defmethod method-entry-slot-name ((entry method-entry))
 432   (let* ((method (method-entry-effective-method entry))
 433          (message (effective-method-message method))
 434          (name (sod-message-name message))
 435          (role (method-entry-role entry)))
 436     (method-entry-slot-name-by-role entry role name)))
 437
 438 (defmethod method-entry-function-type ((entry method-entry))
 439   (let* ((method (method-entry-effective-method entry))
 440          (message (effective-method-message method))
 441          (type (sod-message-type message))
 442          (keywordsp (keyword-message-p message))
 443          (raw-tail (append (sod-message-argument-tail message)
 444                            (and keywordsp (list :ellipsis))))
 445          (tail (ecase (method-entry-role entry)
 446                  ((nil) raw-tail)
 447                  (:valist (reify-variable-argument-tail raw-tail)))))
 448     (c-type (fun (lisp (c-type-subtype type))
 449                  ("me" (* (class (method-entry-chain-tail entry))))
 450                  . tail))))
 451
 452 (defgeneric effective-method-keyword-parser-function-name (method)
 453   (:documentation
 454    "Return the name of the keyword-parsing function for an effective METHOD.
 455
 456    See `make-keyword-parser-function' for details of what this function
 457    actually does."))
 458
 459 (defmethod effective-method-keyword-parser-function-name
 460     ((method basic-effective-method))
 461   (with-slots ((class %class) message) method
 462     (format nil "~A__kwparse_~A__~A"
 463             class
 464             (sod-class-nickname (sod-message-class message))
 465             (sod-message-name message))))
 466
 467 (defun make-keyword-parser-function (codegen method tag set keywords)
 468   "Construct and return a keyword-argument parsing function.
 469
 470    The function is contributed to the CODEGEN, with the name constructed from
 471    the effective METHOD.  It will populate an argument structure with the
 472    given TAG.  In case of error, it will mention the name SET in its report.
 473    The KEYWORDS are a list of `argument' objects naming the keywords to be
 474    accepted.
 475
 476    The generated function has the signature
 477
 478         void NAME(struct TAG *kw, va_list *ap, struct kwval *v, size_t n)
 479
 480     It assumes that AP includes the first keyword name.  (This makes it
 481     different from the keyword-parsing functions generated by the
 482     `KWSET_PARSEFN' macro, but this interface is slightly more convenient and
 483     we don't need to cope with functions which accept no required
 484     arguments.)"
 485
 486   ;; Let's start, then.
 487   (codegen-push codegen)
 488
 489   ;; Set up the local variables we'll need.
 490   (macrolet ((var (name type)
 491                `(ensure-var codegen ,name (c-type ,type))))
 492     (var "k" const-string)
 493     (var "aap" (* va-list))
 494     (var "t" (* (struct "kwtab" :const)))
 495     (var "vv" (* (struct "kwval" :const)))
 496     (var "nn" size-t))
 497
 498   (flet ((call (target func &rest args)
 499            ;; Call FUNC with ARGS; return result in TARGET.
 500
 501            (apply #'deliver-call codegen target func args))
 502
 503          (convert (target type)
 504            ;; Fetch the object of TYPE pointed to by `v->val', and store it
 505            ;; in TARGET.
 506
 507            (deliver-expr codegen target
 508                          (format nil "*(~A)v->val"
 509                                  (make-pointer-type (qualify-c-type
 510                                                      type (list :const))))))
 511
 512          (namecheck (var name conseq alt)
 513            ;; Return an instruction: if VAR matches the string NAME then do
 514            ;; CONSEQ; otherwise do ALT.
 515
 516            (make-if-inst (make-call-inst "!strcmp"
 517                                          var (prin1-to-string name))
 518                          conseq alt)))
 519
 520     ;; Prepare the main parsing loops.  We're going to construct them both at
 521     ;; the same time.  They're not quite similar enough for it to be
 522     ;; worthwhile abstracting this further, but carving up the keywords is
 523     ;; too tedious to write out more than once.
 524     (let ((va-act (make-expr-inst (make-call-inst "kw_unknown" set "k")))
 525           (tab-act (make-expr-inst (make-call-inst "kw_unknown"
 526                                                    set "v->kw")))
 527           (name (effective-method-keyword-parser-function-name method)))
 528
 529       ;; Work through the keywords.  We're going to be building up the
 530       ;; conditional dispatch from the end, so reverse the (nicely sorted)
 531       ;; list before processing it.
 532       (dolist (key (reverse keywords))
 533         (let* ((key-name (argument-name key))
 534                (key-type (argument-type key)))
 535
 536           ;; Handle the varargs case.
 537           (codegen-push codegen)
 538           (deliver-expr codegen (format nil "kw->~A__suppliedp" key-name) 1)
 539           (call (format nil "kw->~A" key-name) "va_arg" "*ap" key-type)
 540           (setf va-act (namecheck "k" key-name
 541                                   (codegen-pop-block codegen) va-act))
 542
 543           ;; Handle the table case.
 544           (codegen-push codegen)
 545           (deliver-expr codegen (format nil "kw->~A__suppliedp" key-name) 1)
 546           (convert (format nil "kw->~A" key-name) key-type)
 547           (setf tab-act (namecheck "v->kw" key-name
 548                                    (codegen-pop-block codegen) tab-act))))
 549
 550       ;; Deal with the special `kw.' keywords read via varargs.
 551       (codegen-push codegen)
 552       (call "vv" "va_arg" "*ap" (c-type (* (struct "kwval" :const))))
 553       (call "nn" "va_arg" "*ap" c-type-size-t)
 554       (call :void name "kw" *null-pointer* "vv" "nn")
 555       (setf va-act (namecheck "k" "kw.tab"
 556                               (codegen-pop-block codegen) va-act))
 557
 558       (codegen-push codegen)
 559       (call "aap" "va_arg" "*ap" (c-type (* va-list)))
 560       (call :void name "kw" "aap" *null-pointer* 0)
 561       (setf va-act (namecheck "k" "kw.va_list"
 562                               (codegen-pop-block codegen) va-act))
 563
 564       ;; Finish up the varargs loop.
 565       (emit-banner codegen "Parse keywords from the variable-length tail.")
 566       (codegen-push codegen)
 567       (call "k" "va_arg" "*ap" c-type-const-string)
 568       (emit-inst codegen (make-if-inst "!k" (make-break-inst)))
 569       (emit-inst codegen va-act)
 570       (let ((loop (make-for-inst nil nil nil (codegen-pop-block codegen))))
 571         (emit-inst codegen
 572                    (make-if-inst "ap" (make-block-inst nil (list loop)))))
 573
 574       ;; Deal with the special `kw.' keywords read from a table.
 575       (codegen-push codegen)
 576       (deliver-expr codegen "t"
 577                     (format nil "(~A)v->val"
 578                             (c-type (* (struct "kwtab" :const)))))
 579       (call :void name "kw" *null-pointer* "t->v" "t->n")
 580       (setf tab-act (namecheck "v->kw" "kw.tab"
 581                                (codegen-pop-block codegen) tab-act))
 582
 583       (emit-banner codegen "Parse keywords from the argument table.")
 584       (codegen-push codegen)
 585       (convert "aap" (c-type (* va-list)))
 586       (call :void name "kw" "aap" *null-pointer* 0)
 587       (setf tab-act (namecheck "v->kw" "kw.va_list"
 588                                (codegen-pop-block codegen) tab-act))
 589
 590       ;; Finish off the table loop.
 591       (codegen-push codegen)
 592       (emit-inst codegen tab-act)
 593       (emit-inst codegen (make-expr-inst "v++"))
 594       (emit-inst codegen (make-expr-inst "n--"))
 595       (emit-inst codegen (make-while-inst "n" (codegen-pop-block codegen)))
 596
 597       ;; Wrap the whole lot up with a nice bow.
 598       (let ((message (effective-method-message method)))
 599         (codegen-pop-function codegen name
 600                               (c-type (fun void
 601                                            ("kw" (* (struct tag)))
 602                                            ("ap" (* va-list))
 603                                            ("v" (* (struct "kwval" :const)))
 604                                            ("n" size-t)))
 605                               "Keyword parsing for `~A.~A' on class `~A'."
 606                               (sod-class-nickname
 607                                (sod-message-class message))
 608                               (sod-message-name message)
 609                               (effective-method-class method))))))
 610
 611 (defmethod make-method-entries ((method basic-effective-method)
 612                                 (chain-head sod-class)
 613                                 (chain-tail sod-class))
 614   (let ((entries nil)
 615         (message (effective-method-message method)))
 616     (flet ((make (role)
 617              (push (make-instance 'method-entry
 618                                   :method method :role role
 619                                   :chain-head chain-head
 620                                   :chain-tail chain-tail)
 621                    entries)))
 622       (when (or (varargs-message-p message)
 623                 (keyword-message-p message))
 624         (make :valist))
 625       (make nil)
 626       entries)))
 627
 628 (defmethod compute-method-entry-functions ((method basic-effective-method))
 629
 630   ;; OK, there's quite a lot of this, so hold tight.
 631   ;;
 632   ;; The first thing we need to do is find all of the related objects.  This
 633   ;; is a bit verbose but fairly straightforward.
 634   ;;
 635   ;; Next, we generate the effective method body -- using `compute-effective-
 636   ;; method-body' of all things.  This gives us the declarations and body for
 637   ;; an effective method function, but we don't have an actual function yet.
 638   ;;
 639   ;; Now we look at the chains which are actually going to need a method
 640   ;; entry: only those chains whose tail (most specific) class is a
 641   ;; superclass of the class which defined the message need an entry.  We
 642   ;; build a list of these tail classes.
 643   ;;
 644   ;; Having done this, we decide whether it's better to generate a standalone
 645   ;; effective-method function and call it from each of the method entries,
 646   ;; or to inline the effective method body into each of the entries.
 647   ;;
 648   ;; Most of the complexity here comes from (a) dealing with the two
 649   ;; different strategies for constructing method entry functions and (b)
 650   ;; (unsurprisingly) the mess involved with dealing with varargs messages.
 651
 652   (let* ((message (effective-method-message method))
 653          (class (effective-method-class method))
 654          (message-class (sod-message-class message))
 655          (return-type (c-type-subtype (sod-message-type message)))
 656          (codegen (make-instance 'method-codegen
 657                                  :message message
 658                                  :class class
 659                                  :method method))
 660
 661          ;; Method entry details.
 662          (chain-tails (remove-if-not (lambda (super)
 663                                        (sod-subclass-p super message-class))
 664                                      (mapcar #'car
 665                                              (sod-class-chains class))))
 666          (n-entries (length chain-tails))
 667          (raw-entry-args (append (sod-message-argument-tail message)
 668                                  (and (keyword-message-p message)
 669                                       (list :ellipsis))))
 670          (entry-args (reify-variable-argument-tail raw-entry-args))
 671          (parm-n (let ((tail (last (cons (make-argument "me" c-type-void)
 672                                          raw-entry-args) 2)))
 673                    (and tail (eq (cadr tail) :ellipsis)
 674                         (argument-name (car tail)))))
 675          (entry-target (codegen-target codegen))
 676
 677          ;; Effective method function details.
 678          (emf-name (effective-method-function-name method))
 679          (ilayout-type (c-type (* (struct (ilayout-struct-tag class)))))
 680          (emf-type (c-type (fun (lisp return-type)
 681                                 ("sod__obj" (lisp ilayout-type))
 682                                 . entry-args))))
 683
 684     (flet ((setup-entry (tail)
 685              (let ((head (sod-class-chain-head tail)))
 686                (codegen-push codegen)
 687                (ensure-var codegen "sod__obj" ilayout-type
 688                            (make-convert-to-ilayout-inst class
 689                                                          head "me"))))
 690            (finish-entry (tail)
 691              (let* ((head (sod-class-chain-head tail))
 692                     (role (if parm-n :valist nil))
 693                     (name (method-entry-function-name method head role))
 694                     (type (c-type (fun (lisp return-type)
 695                                        ("me" (* (class tail)))
 696                                        . entry-args))))
 697                (codegen-pop-function codegen name type
 698                 "~@(~@[~A ~]entry~) function ~:_~
 699                  for method `~A.~A' ~:_~
 700                  via chain headed by `~A' ~:_~
 701                  defined on `~A'."
 702                 (if parm-n "Indirect argument-tail" nil)
 703                 (sod-class-nickname message-class)
 704                 (sod-message-name message)
 705                 head class)
 706
 707                ;; If this is a varargs or keyword method then we've made the
 708                ;; `:valist' role.  Also make the `nil' role.
 709                (when parm-n
 710                  (let ((call (apply #'make-call-inst name "me"
 711                                     (mapcar #'argument-name entry-args)))
 712                        (main (method-entry-function-name method head nil))
 713                        (main-type (c-type (fun (lisp return-type)
 714                                                ("me" (* (class tail)))
 715                                                . raw-entry-args))))
 716                    (codegen-push codegen)
 717                    (ensure-var codegen *sod-ap* c-type-va-list)
 718                    (convert-stmts codegen entry-target return-type
 719                                   (lambda (target)
 720                                     (deliver-call codegen :void "va_start"
 721                                                   *sod-ap* parm-n)
 722                                     (deliver-expr codegen target call)
 723                                     (deliver-call codegen :void "va_end"
 724                                                   *sod-ap*)))
 725                    (codegen-pop-function codegen main main-type
 726                     "Variable-length argument list ~:_~
 727                      entry function ~:_~
 728                      for method `~A.~A' ~:_~
 729                      via chain headed by `~A' ~:_~
 730                      defined on `~A'."
 731                 (sod-class-nickname message-class)
 732                 (sod-message-name message)
 733                 head class))))))
 734
 735       ;; Generate the method body.  We'll work out what to do with it later.
 736       (codegen-push codegen)
 737       (let* ((result (if (eq return-type c-type-void) nil
 738                          (temporary-var codegen return-type)))
 739              (emf-target (or result :void)))
 740         (compute-effective-method-body method codegen emf-target)
 741         (multiple-value-bind (vars insts) (codegen-pop codegen)
 742           (cond ((or (= n-entries 1)
 743                      (<= (* n-entries (reduce #'+ insts :key #'inst-metric))
 744                          *method-entry-inline-threshold*))
 745
 746                  ;; The effective method body is simple -- or there's only
 747                  ;; one of them.  We'll inline the method body into the entry
 748                  ;; functions.
 749                  (dolist (tail chain-tails)
 750                    (setup-entry tail)
 751                    (dolist (var vars)
 752                      (if (typep var 'var-inst)
 753                          (ensure-var codegen (inst-name var)
 754                                      (inst-type var) (inst-init var))
 755                          (emit-decl codegen var)))
 756                    (emit-insts codegen insts)
 757                    (deliver-expr codegen entry-target result)
 758                    (finish-entry tail)))
 759
 760                 (t
 761
 762                  ;; The effective method body is complicated and we'd need
 763                  ;; more than one copy.  We'll generate an effective method
 764                  ;; function and call it a lot.
 765                  (codegen-build-function codegen emf-name emf-type vars
 766                   (nconc insts (and result
 767                                     (list (make-return-inst result))))
 768                   "Effective method function ~:_for `~A.~A' ~:_~
 769                    defined on `~A'."
 770                   (sod-class-nickname message-class)
 771                   (sod-message-name message)
 772                   (effective-method-class method))
 773
 774                  (let ((call (apply #'make-call-inst emf-name "sod__obj"
 775                                     (mapcar #'argument-name entry-args))))
 776                    (dolist (tail chain-tails)
 777                      (setup-entry tail)
 778                      (deliver-expr codegen entry-target call)
 779                      (finish-entry tail)))))))
 780
 781       (codegen-functions codegen))))
 782
 783 (defmethod compute-effective-method-body :around
 784     ((method basic-effective-method) codegen target)
 785   (let* ((message (effective-method-message method))
 786          (keywordsp (keyword-message-p message))
 787          (keywords (effective-method-keywords method))
 788          (ap-addr (format nil "&~A" *sod-tmp-ap*))
 789          (set (format nil "\"~A:~A.~A\""
 790                       (sod-class-name (effective-method-class method))
 791                       (sod-class-nickname (sod-message-class message))
 792                       (sod-message-name message))))
 793     (labels ((call (target func &rest args)
 794                (apply #'deliver-call codegen target func args))
 795              (parse-keywords (body)
 796                (ensure-var codegen *sod-tmp-ap* c-type-va-list)
 797                (call :void "va_copy" *sod-tmp-ap* *sod-ap*)
 798                (funcall body)
 799                (call :void "va_end" *sod-tmp-ap*)))
 800       (cond ((not keywordsp)
 801              (call-next-method))
 802             ((null keywords)
 803              (let ((*keyword-struct-disposition* :null))
 804                (parse-keywords (lambda ()
 805                                  (with-temporary-var
 806                                      (codegen kw c-type-const-string)
 807                                    (call kw "va_arg"
 808                                          *sod-tmp-ap* c-type-const-string)
 809                                    (call :void "kw_parseempty" set
 810                                          kw ap-addr *null-pointer* 0))))
 811                (call-next-method)))
 812             (t
 813              (let* ((name
 814                      (effective-method-keyword-parser-function-name method))
 815                     (tag (effective-method-keyword-struct-tag method))
 816                     (kw-addr (format nil "&~A" *sod-keywords*))
 817                     (*keyword-struct-disposition* :local))
 818                (ensure-var codegen *sod-keywords* (c-type (struct tag)))
 819                (make-keyword-parser-function codegen method tag set keywords)
 820                (parse-keywords (lambda ()
 821                                  (call :void name kw-addr ap-addr
 822                                        *null-pointer* 0)))
 823                (call-next-method)))))))
 824
 825 (defmethod effective-method-live-p ((method simple-effective-method))
 826   (effective-method-primary-methods method))
 827
 828 (defmethod compute-method-entry-functions :around ((method effective-method))
 829   (if (effective-method-live-p method)
 830       (call-next-method)
 831       nil))
 832
 833 (defmethod compute-effective-method-body
 834     ((method simple-effective-method) codegen target)
 835   (basic-effective-method-body codegen target method
 836                                (lambda (target)
 837                                  (simple-method-body method
 838                                                      codegen
 839                                                      target))))
 840
 841 ;;;--------------------------------------------------------------------------
 842 ;;; Standard method combination.
 843
 844 (export 'standard-message)
 845 (defclass standard-message (simple-message)
 846   ()
 847   (:documentation
 848    "Message class for standard method combinations.
 849
 850    Standard method combination is a simple method combination where the
 851    primary methods are invoked as a delegation chain, from most- to
 852    least-specific."))
 853
 854 (export 'standard-effective-method)
 855 (defclass standard-effective-method (simple-effective-method) ()
 856   (:documentation "Effective method counterpart to `standard-message'."))
 857
 858 (defmethod primary-method-class ((message standard-message))
 859   'delegating-direct-method)
 860
 861 (defmethod sod-message-effective-method-class ((message standard-message))
 862   'standard-effective-method)
 863
 864 (defmethod simple-method-body
 865     ((method standard-effective-method) codegen target)
 866   (invoke-delegation-chain codegen
 867                            target
 868                            (effective-method-basic-argument-names method)
 869                            (effective-method-primary-methods method)
 870                            nil))
 871
 872 ;;;----- That's all, folks --------------------------------------------------