chiark - git - mdw - sod/blob - src/method-impl.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Method combination implementation
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Message classes.
  30
  31 (export 'basic-message)
  32 (defclass basic-message (sod-message)
  33   ((argument-tail :type list :reader sod-message-argument-tail))
  34   (:documentation
  35    "Base class for built-in message classes.
  36
  37    Provides the basic functionality for the built-in method combinations.
  38    This is a separate class so that `special effect' messages can avoid
  39    inheriting its default behaviour.
  40
  41    The function type protocol is implemented on `basic-message' using slot
  42    reader methods.  The actual values are computed on demand."))
  43
  44 (define-on-demand-slot basic-message argument-tail (message)
  45   (let ((seq 0))
  46     (mapcar (lambda (arg)
  47               (if (or (eq arg :ellipsis) (argument-name arg)) arg
  48                   (make-argument (make-instance 'temporary-argument
  49                                                 :tag (prog1 seq
  50                                                        (incf seq)))
  51                                  (argument-type arg))))
  52             (c-function-arguments (sod-message-type message)))))
  53
  54 (defmethod sod-message-method-class
  55     ((message basic-message) (class sod-class) pset)
  56   (let ((role (get-property pset :role :keyword nil)))
  57     (case role
  58       ((:before :after) 'daemon-direct-method)
  59       (:around 'delegating-direct-method)
  60       ((nil) (error "How odd: a primary method slipped through the net"))
  61       (t (error "Unknown method role ~A" role)))))
  62
  63 (export 'simple-message)
  64 (defclass simple-message (basic-message)
  65   ()
  66   (:documentation
  67    "Base class for messages with `simple' method combinations.
  68
  69    A simple method combination is one which has only one method role other
  70    than the `before', `after' and `around' methods provided by
  71    `basic-message'.  We call these `primary' methods, and the programmer
  72    designates them by not specifying an explicit role.
  73
  74    If the programmer doesn't define any primary methods then the effective
  75    method is null -- i.e., the method entry pointer shows up as a null
  76    pointer."))
  77
  78 (defmethod sod-message-method-class
  79     ((message simple-message) (class sod-class) pset)
  80   (if (get-property pset :role :keyword nil)
  81       (call-next-method)
  82       (primary-method-class message)))
  83
  84 (defmethod primary-method-class ((message simple-message))
  85   'basic-direct-method)
  86
  87 ;;;--------------------------------------------------------------------------
  88 ;;; Direct method classes.
  89
  90 (export '(basic-direct-method sod-method-role))
  91 (defclass basic-direct-method (sod-method)
  92   ((role :initarg :role :type symbol :reader sod-method-role)
  93    (function-type :type c-function-type :reader sod-method-function-type))
  94   (:documentation
  95    "Base class for built-in direct method classes.
  96
  97    Provides the basic functionality for the built-in direct-method classes.
  98    This is a separate class so that `special effect' methods can avoid
  99    inheriting its default behaviour and slots.
 100
 101    A basic method can be assigned a `role', which may be set either as an
 102    initarg or using the `:role' property.  Roles are used for method
 103    categorization.
 104
 105    The function type protocol is implemented on `basic-direct-method' using
 106    slot reader methods."))
 107
 108 (defmethod shared-initialize :after
 109     ((method basic-direct-method) slot-names &key pset)
 110   (declare (ignore slot-names))
 111   (default-slot (method 'role) (get-property pset :role :keyword nil)))
 112
 113 (defun direct-method-suppliedp-struct-tag (direct-method)
 114   (with-slots ((class %class) role message) direct-method
 115     (format nil "~A__~@[~(~A~)_~]suppliedp_~A__~A"
 116             class role
 117             (sod-class-nickname (sod-message-class message))
 118             (sod-message-name message))))
 119
 120 (defun effective-method-keyword-struct-tag (effective-method)
 121   (with-slots ((class %class) message) effective-method
 122     (format nil "~A__keywords_~A__~A"
 123             class
 124             (sod-class-nickname (sod-message-class message))
 125             (sod-message-name message))))
 126
 127 (defun fix-up-keyword-method-args (method args)
 128   "Adjust the ARGS to include METHOD's `suppliedp' and keyword arguments.
 129
 130    Return the adjusted list.  The `suppliedp' argument, if any, is prepended
 131    to the list; the keyword arguments are added to the end.
 132
 133    (The input ARGS list is not actually modified.)"
 134   (let* ((type (sod-method-type method))
 135          (keys (c-function-keywords type))
 136          (tag (direct-method-suppliedp-struct-tag method)))
 137     (append (and keys
 138                  (list (make-argument "suppliedp" (c-type (struct tag)))))
 139             args
 140             (mapcar (lambda (key)
 141                       (make-argument (argument-name key)
 142                                      (argument-type key)))
 143                     keys))))
 144
 145 (define-on-demand-slot basic-direct-method function-type (method)
 146   (let* ((message (sod-method-message method))
 147          (type (sod-method-type method))
 148          (method-args (c-function-arguments type)))
 149     (when (keyword-message-p message)
 150       (setf method-args (fix-up-keyword-method-args method method-args)))
 151     (c-type (fun (lisp (c-type-subtype type))
 152                  ("me" (* (class (sod-method-class method))))
 153                  . method-args))))
 154
 155 (defmethod sod-method-description ((method basic-direct-method))
 156   (with-slots (role) method
 157     (if role (string-downcase role)
 158         "primary")))
 159
 160 (defmethod sod-method-function-name ((method basic-direct-method))
 161   (with-slots ((class %class) role message) method
 162     (format nil "~A__~@[~(~A~)_~]method_~A__~A" class role
 163             (sod-class-nickname (sod-message-class message))
 164             (sod-message-name message))))
 165
 166 (export 'daemon-direct-method)
 167 (defclass daemon-direct-method (basic-direct-method)
 168   ()
 169   (:documentation
 170    "A daemon direct method is invoked for side effects and cannot override.
 171
 172    This is the direct method class for `before' and `after' methods, which
 173    cannot choose to override the remaining methods and are not involved in
 174    the computation of the final result.
 175
 176    In C terms, a daemon method must return `void', and is not passed a
 177    `next_method' pointer."))
 178
 179 (defmethod check-method-type ((method daemon-direct-method)
 180                               (message sod-message)
 181                               (type c-function-type))
 182   (with-slots ((msgtype %type)) message
 183     (check-method-return-type type c-type-void)
 184     (check-method-argument-lists type msgtype)))
 185
 186 (export 'delegating-direct-method)
 187 (defclass delegating-direct-method (basic-direct-method)
 188   ((next-method-type :type c-function-type
 189                      :reader sod-method-next-method-type))
 190   (:documentation
 191    "A delegating direct method can choose to override other methods.
 192
 193    This is the direct method class for `around' and standard-method-
 194    combination primary methods, which are given the choice of computing the
 195    entire method's result or delegating to (usually) less-specific methods.
 196
 197    In C terms, a delegating method is passed a `next_method' pointer so that
 198    it can delegate part of its behaviour.  (A delegating direct method for a
 199    varargs message is also given an additional `va_list' argument,
 200    conventionally named `sod__ap_master', which it is expected to pass on to
 201    its `next_method' function if necessary.)
 202
 203    The function type protocol is implemented on `delegating-direct-method'
 204    using slot reader methods.."))
 205
 206 (define-on-demand-slot delegating-direct-method next-method-type (method)
 207   (let* ((message (sod-method-message method))
 208          (return-type (c-type-subtype (sod-message-type message)))
 209          (msgargs (sod-message-argument-tail message))
 210          (arguments (cond ((varargs-message-p message)
 211                            (cons (make-argument *sod-master-ap*
 212                                                 c-type-va-list)
 213                                  (butlast msgargs)))
 214                           ((keyword-message-p message)
 215                            (cons (make-argument *sod-keywords*
 216                                                 (c-type (* (void :const))))
 217                                  msgargs))
 218                           (t
 219                            msgargs))))
 220     (c-type (fun (lisp return-type)
 221                  ("me" (* (class (sod-method-class method))))
 222                  . arguments))))
 223
 224 (define-on-demand-slot delegating-direct-method function-type (method)
 225   (let* ((message (sod-method-message method))
 226          (type (sod-method-type method))
 227          (method-args (c-function-arguments type))
 228          (next-method-arg (make-argument
 229                            "next_method"
 230                            (make-pointer-type
 231                             (commentify-function-type
 232                              (sod-method-next-method-type method))))))
 233     (cond ((varargs-message-p message)
 234            (push (make-argument *sod-master-ap* c-type-va-list)
 235                  method-args)
 236            (push next-method-arg method-args))
 237           ((keyword-message-p message)
 238            (push (make-argument *sod-keywords* (c-type (* (void :const))))
 239                  method-args)
 240            (push next-method-arg method-args)
 241            (setf method-args
 242                  (fix-up-keyword-method-args method method-args)))
 243           (t
 244            (push next-method-arg method-args)))
 245     (c-type (fun (lisp (c-type-subtype type))
 246                  ("me" (* (class (sod-method-class method))))
 247                  . method-args))))
 248
 249 ;;;--------------------------------------------------------------------------
 250 ;;; Effective method classes.
 251
 252 (defmethod method-keyword-argument-lists
 253     ((method effective-method) direct-methods)
 254   (with-slots (message) method
 255     (and (keyword-message-p message)
 256          (mapcar (lambda (m)
 257                    (cons (c-function-keywords (sod-method-type m))
 258                          (format nil "method for ~A on ~A (at ~A)"
 259                                  message
 260                                  (sod-method-class m)
 261                                  (file-location m))))
 262                  direct-methods))))
 263
 264 (defmethod shared-initialize :after
 265     ((method effective-method) slot-names &key direct-methods)
 266   (declare (ignore slot-names))
 267
 268   ;; Set the keyword argument list.
 269   (with-slots (message keywords) method
 270     (setf keywords
 271           (merge-keyword-lists (method-keyword-argument-lists
 272                                 method direct-methods)))))
 273
 274 (export '(basic-effective-method
 275           effective-method-around-methods effective-method-before-methods
 276           effective-method-after-methods))
 277 (defclass basic-effective-method (effective-method)
 278   ((around-methods :initarg :around-methods :initform nil
 279                    :type list :reader effective-method-around-methods)
 280    (before-methods :initarg :before-methods :initform nil
 281                    :type list :reader effective-method-before-methods)
 282    (after-methods :initarg :after-methods :initform nil
 283                   :type list :reader effective-method-after-methods)
 284    (basic-argument-names :type list
 285                          :reader effective-method-basic-argument-names)
 286    (functions :type list :reader effective-method-functions))
 287   (:documentation
 288    "Base class for built-in effective method classes.
 289
 290    This class maintains lists of the applicable `before', `after' and
 291    `around' methods and provides behaviour for invoking these methods
 292    correctly.
 293
 294    The argument names protocol is implemented on `basic-effective-method'
 295    using a slot reader method."))
 296
 297 (define-on-demand-slot basic-effective-method basic-argument-names (method)
 298   (let* ((message (effective-method-message method))
 299          (raw-tail (sod-message-argument-tail message)))
 300     (mapcar #'argument-name (reify-variable-argument-tail raw-tail))))
 301
 302 (defmethod effective-method-function-name ((method effective-method))
 303   (let* ((class (effective-method-class method))
 304          (message (effective-method-message method))
 305          (message-class (sod-message-class message)))
 306     (format nil "~A__emethod_~A__~A"
 307             class
 308             (sod-class-nickname message-class)
 309             (sod-message-name message))))
 310
 311 (define-on-demand-slot basic-effective-method functions (method)
 312   (compute-method-entry-functions method))
 313
 314 (export 'simple-effective-method)
 315 (defclass simple-effective-method (basic-effective-method)
 316   ((primary-methods :initarg :primary-methods :initform nil
 317                     :type list :reader effective-method-primary-methods))
 318   (:documentation
 319    "Effective method counterpart to `simple-message'."))
 320
 321 (defmethod shared-initialize :after
 322     ((method simple-effective-method) slot-names &key direct-methods)
 323   (declare (ignore slot-names))
 324   (categorize (method direct-methods :bind ((role (sod-method-role method))))
 325       ((primary (null role))
 326        (before (eq role :before))
 327        (after (eq role :after))
 328        (around (eq role :around)))
 329     (with-slots (primary-methods before-methods after-methods around-methods)
 330         method
 331       (setf primary-methods primary
 332             before-methods before
 333             after-methods (reverse after)
 334             around-methods around))))
 335
 336 ;;;--------------------------------------------------------------------------
 337 ;;; Code generation.
 338
 339 (defmethod shared-initialize :after
 340     ((codegen method-codegen) slot-names &key)
 341   (declare (ignore slot-names))
 342   (with-slots (message target) codegen
 343     (setf target
 344           (if (eq (c-type-subtype (sod-message-type message)) c-type-void)
 345               :void
 346               :return))))
 347
 348 ;;;--------------------------------------------------------------------------
 349 ;;; Invoking direct methods.
 350
 351 (export 'basic-effective-method-body)
 352 (defun basic-effective-method-body (codegen target method body)
 353   "Build the common method-invocation structure.
 354
 355    Writes to CODEGEN some basic method-invocation instructions.  It invokes
 356    the `around' methods, from most- to least-specific.  If they all delegate,
 357    then the `before' methods are run, most-specific first; next, the
 358    instructions generated by BODY (invoked with a target argument); then, the
 359    `after' methods are run, least-specific first; and, finally, the value
 360    delivered by the BODY is returned to the `around' methods.  The result
 361    returned by the outermost `around' method -- or, if there are none,
 362    delivered by the BODY -- is finally delivered to the TARGET."
 363
 364   (with-slots (message (class %class)
 365                before-methods after-methods around-methods)
 366       method
 367     (let* ((message-type (sod-message-type message))
 368            (return-type (c-type-subtype message-type))
 369            (basic-tail (effective-method-basic-argument-names method)))
 370       (flet ((method-kernel (target)
 371                (dolist (before before-methods)
 372                  (invoke-method codegen :void basic-tail before))
 373                (if (null after-methods)
 374                    (funcall body target)
 375                    (convert-stmts codegen target return-type
 376                                   (lambda (target)
 377                                     (funcall body target)
 378                                     (dolist (after (reverse after-methods))
 379                                       (invoke-method codegen :void
 380                                                      basic-tail after)))))))
 381         (invoke-delegation-chain codegen target basic-tail
 382                                  around-methods #'method-kernel)))))
 383
 384 ;;;--------------------------------------------------------------------------
 385 ;;; Method entry points.
 386
 387 (defparameter *method-entry-inline-threshold* 200
 388   "Threshold below which effective method bodies are inlined into entries.
 389
 390    After the effective method body has been computed, we calculate its
 391    metric, multiply by the number of entries we need to generate, and compare
 392    it with this threshold.  If the metric is below the threshold then we
 393    fold the method body into the entry functions; otherwise we split the
 394    effective method out into its own function.")
 395
 396 (defmethod method-entry-function-name
 397     ((method effective-method) (chain-head sod-class) role)
 398   (let* ((class (effective-method-class method))
 399          (message (effective-method-message method))
 400          (message-class (sod-message-class message)))
 401     (if (or (not (slot-boundp method 'functions))
 402             (slot-value method 'functions))
 403         (format nil "~A__mentry~@[__~(~A~)~]_~A__~A__chain_~A"
 404                 class role
 405                 (sod-class-nickname message-class)
 406                 (sod-message-name message)
 407                 (sod-class-nickname chain-head))
 408         *null-pointer*)))
 409
 410 (defmethod method-entry-slot-name ((entry method-entry))
 411   (let* ((method (method-entry-effective-method entry))
 412          (message (effective-method-message method))
 413          (name (sod-message-name message))
 414          (role (method-entry-role entry)))
 415     (method-entry-slot-name-by-role entry role name)))
 416
 417 (defmethod method-entry-function-type ((entry method-entry))
 418   (let* ((method (method-entry-effective-method entry))
 419          (message (effective-method-message method))
 420          (type (sod-message-type message))
 421          (keywordsp (keyword-message-p message))
 422          (raw-tail (append (sod-message-argument-tail message)
 423                            (and keywordsp (list :ellipsis))))
 424          (tail (ecase (method-entry-role entry)
 425                  ((nil) raw-tail)
 426                  (:valist (reify-variable-argument-tail raw-tail)))))
 427     (c-type (fun (lisp (c-type-subtype type))
 428                  ("me" (* (class (method-entry-chain-tail entry))))
 429                  . tail))))
 430
 431 (defgeneric effective-method-keyword-parser-function-name (method)
 432   (:documentation
 433    "Return the name of the keyword-parsing function for an effective METHOD.
 434
 435    See `make-keyword-parser-function' for details of what this function
 436    actually does."))
 437
 438 (defmethod effective-method-keyword-parser-function-name
 439     ((method basic-effective-method))
 440   (with-slots ((class %class) message) method
 441     (format nil "~A__kwparse_~A__~A"
 442             class
 443             (sod-class-nickname (sod-message-class message))
 444             (sod-message-name message))))
 445
 446 (defun make-keyword-parser-function (codegen method tag set keywords)
 447   "Construct and return a keyword-argument parsing function.
 448
 449    The function is contributed to the CODEGEN, with the name constructed from
 450    the effective METHOD.  It will populate an argument structure with the
 451    given TAG.  In case of error, it will mention the name SET in its report.
 452    The KEYWORDS are a list of `argument' objects naming the keywords to be
 453    accepted.
 454
 455    The generated function has the signature
 456
 457         void NAME(struct TAG *kw, va_list *ap, struct kwval *v, size_t n)
 458
 459     It assumes that AP includes the first keyword name.  (This makes it
 460     different from the keyword-parsing functions generated by the
 461     `KWSET_PARSEFN' macro, but this interface is slightly more convenient and
 462     we don't need to cope with functions which accept no required
 463     arguments.)"
 464
 465   ;; Let's start, then.
 466   (codegen-push codegen)
 467
 468   ;; Set up the local variables we'll need.
 469   (macrolet ((var (name type)
 470                `(ensure-var codegen ,name (c-type ,type))))
 471     (var "k" const-string)
 472     (var "aap" (* va-list))
 473     (var "t" (* (struct "kwtab" :const)))
 474     (var "vv" (* (struct "kwval" :const)))
 475     (var "nn" size-t))
 476
 477   (flet ((call (target func &rest args)
 478            ;; Call FUNC with ARGS; return result in TARGET.
 479
 480            (apply #'deliver-call codegen target func args))
 481
 482          (convert (target type)
 483            ;; Fetch the object of TYPE pointed to by `v->val', and store it
 484            ;; in TARGET.
 485
 486            (deliver-expr codegen target
 487                          (format nil "*(~A)v->val"
 488                                  (make-pointer-type (qualify-c-type
 489                                                      type (list :const))))))
 490
 491          (namecheck (var name conseq alt)
 492            ;; Return an instruction: if VAR matches the string NAME then do
 493            ;; CONSEQ; otherwise do ALT.
 494
 495            (make-if-inst (make-call-inst "!strcmp"
 496                                          var (prin1-to-string name))
 497                          conseq alt)))
 498
 499     ;; Prepare the main parsing loops.  We're going to construct them both at
 500     ;; the same time.  They're not quite similar enough for it to be
 501     ;; worthwhile abstracting this further, but carving up the keywords is
 502     ;; too tedious to write out more than once.
 503     (let ((va-act (make-expr-inst (make-call-inst "kw_unknown" set "k")))
 504           (tab-act (make-expr-inst (make-call-inst "kw_unknown"
 505                                                    set "v->kw")))
 506           (name (effective-method-keyword-parser-function-name method)))
 507
 508       ;; Work through the keywords.  We're going to be building up the
 509       ;; conditional dispatch from the end, so reverse the (nicely sorted)
 510       ;; list before processing it.
 511       (dolist (key (reverse keywords))
 512         (let* ((key-name (argument-name key))
 513                (key-type (argument-type key)))
 514
 515           ;; Handle the varargs case.
 516           (codegen-push codegen)
 517           (deliver-expr codegen (format nil "kw->~A__suppliedp" key-name) 1)
 518           (call (format nil "kw->~A" key-name) "va_arg" "*ap" key-type)
 519           (setf va-act (namecheck "k" key-name
 520                                   (codegen-pop-block codegen) va-act))
 521
 522           ;; Handle the table case.
 523           (codegen-push codegen)
 524           (deliver-expr codegen (format nil "kw->~A__suppliedp" key-name) 1)
 525           (convert (format nil "kw->~A" key-name) key-type)
 526           (setf tab-act (namecheck "v->kw" key-name
 527                                    (codegen-pop-block codegen) tab-act))))
 528
 529       ;; Deal with the special `kw.' keywords read via varargs.
 530       (codegen-push codegen)
 531       (call "vv" "va_arg" "*ap" (c-type (* (struct "kwval" :const))))
 532       (call "nn" "va_arg" "*ap" c-type-size-t)
 533       (call :void name "kw" *null-pointer* "vv" "nn")
 534       (setf va-act (namecheck "k" "kw.tab"
 535                               (codegen-pop-block codegen) va-act))
 536
 537       (codegen-push codegen)
 538       (call "aap" "va_arg" "*ap" (c-type (* va-list)))
 539       (call :void name "kw" "aap" *null-pointer* 0)
 540       (setf va-act (namecheck "k" "kw.va_list"
 541                               (codegen-pop-block codegen) va-act))
 542
 543       ;; Finish up the varargs loop.
 544       (emit-banner codegen "Parse keywords from the variable-length tail.")
 545       (codegen-push codegen)
 546       (call "k" "va_arg" "*ap" c-type-const-string)
 547       (emit-inst codegen (make-if-inst "!k" (make-break-inst)))
 548       (emit-inst codegen va-act)
 549       (let ((loop (make-for-inst nil nil nil (codegen-pop-block codegen))))
 550         (emit-inst codegen
 551                    (make-if-inst "ap" (make-block-inst nil (list loop)))))
 552
 553       ;; Deal with the special `kw.' keywords read from a table.
 554       (codegen-push codegen)
 555       (deliver-expr codegen "t"
 556                     (format nil "(~A)v->val"
 557                             (c-type (* (struct "kwtab" :const)))))
 558       (call :void name "kw" *null-pointer* "t->v" "t->n")
 559       (setf tab-act (namecheck "v->kw" "kw.tab"
 560                                (codegen-pop-block codegen) tab-act))
 561
 562       (emit-banner codegen "Parse keywords from the argument table.")
 563       (codegen-push codegen)
 564       (convert "aap" (c-type (* va-list)))
 565       (call :void name "kw" "aap" *null-pointer* 0)
 566       (setf tab-act (namecheck "v->kw" "kw.va_list"
 567                                (codegen-pop-block codegen) tab-act))
 568
 569       ;; Finish off the table loop.
 570       (codegen-push codegen)
 571       (emit-inst codegen tab-act)
 572       (emit-inst codegen (make-expr-inst "v++"))
 573       (emit-inst codegen (make-expr-inst "n--"))
 574       (emit-inst codegen (make-while-inst "n" (codegen-pop-block codegen)))
 575
 576       ;; Wrap the whole lot up with a nice bow.
 577       (let ((message (effective-method-message method)))
 578         (codegen-pop-function codegen name
 579                               (c-type (fun void
 580                                            ("kw" (* (struct tag)))
 581                                            ("ap" (* va-list))
 582                                            ("v" (* (struct "kwval" :const)))
 583                                            ("n" size-t)))
 584                               "Keyword parsing for `~A.~A' on class `~A'."
 585                               (sod-class-nickname
 586                                (sod-message-class message))
 587                               (sod-message-name message)
 588                               (effective-method-class method))))))
 589
 590 (defmethod make-method-entries ((method basic-effective-method)
 591                                 (chain-head sod-class)
 592                                 (chain-tail sod-class))
 593   (let ((entries nil)
 594         (message (effective-method-message method)))
 595     (flet ((make (role)
 596              (push (make-instance 'method-entry
 597                                   :method method :role role
 598                                   :chain-head chain-head
 599                                   :chain-tail chain-tail)
 600                    entries)))
 601       (when (or (varargs-message-p message)
 602                 (keyword-message-p message))
 603         (make :valist))
 604       (make nil)
 605       entries)))
 606
 607 (defmethod compute-method-entry-functions ((method basic-effective-method))
 608
 609   ;; OK, there's quite a lot of this, so hold tight.
 610   ;;
 611   ;; The first thing we need to do is find all of the related objects.  This
 612   ;; is a bit verbose but fairly straightforward.
 613   ;;
 614   ;; Next, we generate the effective method body -- using `compute-effective-
 615   ;; method-body' of all things.  This gives us the declarations and body for
 616   ;; an effective method function, but we don't have an actual function yet.
 617   ;;
 618   ;; Now we look at the chains which are actually going to need a method
 619   ;; entry: only those chains whose tail (most specific) class is a
 620   ;; superclass of the class which defined the message need an entry.  We
 621   ;; build a list of these tail classes.
 622   ;;
 623   ;; Having done this, we decide whether it's better to generate a standalone
 624   ;; effective-method function and call it from each of the method entries,
 625   ;; or to inline the effective method body into each of the entries.
 626   ;;
 627   ;; Most of the complexity here comes from (a) dealing with the two
 628   ;; different strategies for constructing method entry functions and (b)
 629   ;; (unsurprisingly) the mess involved with dealing with varargs messages.
 630
 631   (let* ((message (effective-method-message method))
 632          (class (effective-method-class method))
 633          (message-class (sod-message-class message))
 634          (return-type (c-type-subtype (sod-message-type message)))
 635          (codegen (make-instance 'method-codegen
 636                                  :message message
 637                                  :class class
 638                                  :method method))
 639
 640          ;; Method entry details.
 641          (chain-tails (remove-if-not (lambda (super)
 642                                        (sod-subclass-p super message-class))
 643                                      (mapcar #'car
 644                                              (sod-class-chains class))))
 645          (n-entries (length chain-tails))
 646          (raw-entry-args (append (sod-message-argument-tail message)
 647                                  (and (keyword-message-p message)
 648                                       (list :ellipsis))))
 649          (entry-args (reify-variable-argument-tail raw-entry-args))
 650          (parm-n (let ((tail (last (cons (make-argument "me" c-type-void)
 651                                          raw-entry-args) 2)))
 652                    (and tail (eq (cadr tail) :ellipsis)
 653                         (argument-name (car tail)))))
 654          (entry-target (codegen-target codegen))
 655
 656          ;; Effective method function details.
 657          (emf-name (effective-method-function-name method))
 658          (ilayout-type (c-type (* (struct (ilayout-struct-tag class)))))
 659          (emf-type (c-type (fun (lisp return-type)
 660                                 ("sod__obj" (lisp ilayout-type))
 661                                 . entry-args))))
 662
 663     (flet ((setup-entry (tail)
 664              (let ((head (sod-class-chain-head tail)))
 665                (codegen-push codegen)
 666                (ensure-var codegen "sod__obj" ilayout-type
 667                            (make-convert-to-ilayout-inst class
 668                                                          head "me"))))
 669            (finish-entry (tail)
 670              (let* ((head (sod-class-chain-head tail))
 671                     (role (if parm-n :valist nil))
 672                     (name (method-entry-function-name method head role))
 673                     (type (c-type (fun (lisp return-type)
 674                                        ("me" (* (class tail)))
 675                                        . entry-args))))
 676                (codegen-pop-function codegen name type
 677                 "~@(~@[~A ~]entry~) function ~:_~
 678                  for method `~A.~A' ~:_~
 679                  via chain headed by `~A' ~:_~
 680                  defined on `~A'."
 681                 (if parm-n "Indirect argument-tail" nil)
 682                 (sod-class-nickname message-class)
 683                 (sod-message-name message)
 684                 head class)
 685
 686                ;; If this is a varargs or keyword method then we've made the
 687                ;; `:valist' role.  Also make the `nil' role.
 688                (when parm-n
 689                  (let ((call (apply #'make-call-inst name "me"
 690                                     (mapcar #'argument-name entry-args)))
 691                        (main (method-entry-function-name method head nil))
 692                        (main-type (c-type (fun (lisp return-type)
 693                                                ("me" (* (class tail)))
 694                                                . raw-entry-args))))
 695                    (codegen-push codegen)
 696                    (ensure-var codegen *sod-ap* c-type-va-list)
 697                    (convert-stmts codegen entry-target return-type
 698                                   (lambda (target)
 699                                     (deliver-call codegen :void "va_start"
 700                                                   *sod-ap* parm-n)
 701                                     (deliver-expr codegen target call)
 702                                     (deliver-call codegen :void "va_end"
 703                                                   *sod-ap*)))
 704                    (codegen-pop-function codegen main main-type
 705                     "Variable-length argument list ~:_~
 706                      entry function ~:_~
 707                      for method `~A.~A' ~:_~
 708                      via chain headed by `~A' ~:_~
 709                      defined on `~A'."
 710                 (sod-class-nickname message-class)
 711                 (sod-message-name message)
 712                 head class))))))
 713
 714       ;; Generate the method body.  We'll work out what to do with it later.
 715       (codegen-push codegen)
 716       (let* ((result (if (eq return-type c-type-void) nil
 717                          (temporary-var codegen return-type)))
 718              (emf-target (or result :void)))
 719         (compute-effective-method-body method codegen emf-target)
 720         (multiple-value-bind (vars insts) (codegen-pop codegen)
 721           (cond ((or (= n-entries 1)
 722                      (<= (* n-entries (reduce #'+ insts :key #'inst-metric))
 723                          *method-entry-inline-threshold*))
 724
 725                  ;; The effective method body is simple -- or there's only
 726                  ;; one of them.  We'll inline the method body into the entry
 727                  ;; functions.
 728                  (dolist (tail chain-tails)
 729                    (setup-entry tail)
 730                    (dolist (var vars)
 731                      (if (typep var 'var-inst)
 732                          (ensure-var codegen (inst-name var)
 733                                      (inst-type var) (inst-init var))
 734                          (emit-decl codegen var)))
 735                    (emit-insts codegen insts)
 736                    (deliver-expr codegen entry-target result)
 737                    (finish-entry tail)))
 738
 739                 (t
 740
 741                  ;; The effective method body is complicated and we'd need
 742                  ;; more than one copy.  We'll generate an effective method
 743                  ;; function and call it a lot.
 744                  (codegen-build-function codegen emf-name emf-type vars
 745                   (nconc insts (and result
 746                                     (list (make-return-inst result))))
 747                   "Effective method function ~:_for `~A.~A' ~:_~
 748                    defined on `~A'."
 749                   (sod-class-nickname message-class)
 750                   (sod-message-name message)
 751                   (effective-method-class method))
 752
 753                  (let ((call (apply #'make-call-inst emf-name "sod__obj"
 754                                     (mapcar #'argument-name entry-args))))
 755                    (dolist (tail chain-tails)
 756                      (setup-entry tail)
 757                      (deliver-expr codegen entry-target call)
 758                      (finish-entry tail)))))))
 759
 760       (codegen-functions codegen))))
 761
 762 (defmethod compute-effective-method-body :around
 763     ((method basic-effective-method) codegen target)
 764   (let* ((message (effective-method-message method))
 765          (keywordsp (keyword-message-p message))
 766          (keywords (effective-method-keywords method))
 767          (ap-addr (format nil "&~A" *sod-tmp-ap*))
 768          (set (format nil "\"~A:~A.~A\""
 769                       (sod-class-name (effective-method-class method))
 770                       (sod-class-nickname (sod-message-class message))
 771                       (sod-message-name message))))
 772     (labels ((call (target func &rest args)
 773                (apply #'deliver-call codegen target func args))
 774              (parse-keywords (body)
 775                (ensure-var codegen *sod-tmp-ap* c-type-va-list)
 776                (call :void "va_copy" *sod-tmp-ap* *sod-ap*)
 777                (funcall body)
 778                (call :void "va_end" *sod-tmp-ap*)))
 779       (cond ((not keywordsp)
 780              (call-next-method))
 781             ((null keywords)
 782              (let ((*keyword-struct-disposition* :null))
 783                (parse-keywords (lambda ()
 784                                  (with-temporary-var
 785                                      (codegen kw c-type-const-string)
 786                                    (call kw "va_arg"
 787                                          *sod-tmp-ap* c-type-const-string)
 788                                    (call :void "kw_parseempty" set
 789                                          kw ap-addr *null-pointer* 0))))
 790                (call-next-method)))
 791             (t
 792              (let* ((name
 793                      (effective-method-keyword-parser-function-name method))
 794                     (tag (effective-method-keyword-struct-tag method))
 795                     (kw-addr (format nil "&~A" *sod-keywords*))
 796                     (*keyword-struct-disposition* :local))
 797                (ensure-var codegen *sod-keywords* (c-type (struct tag)))
 798                (make-keyword-parser-function codegen method tag set keywords)
 799                (parse-keywords (lambda ()
 800                                  (call :void name kw-addr ap-addr
 801                                        *null-pointer* 0)))
 802                (call-next-method)))))))
 803
 804 (defmethod effective-method-live-p ((method simple-effective-method))
 805   (effective-method-primary-methods method))
 806
 807 (defmethod compute-method-entry-functions :around ((method effective-method))
 808   (if (effective-method-live-p method)
 809       (call-next-method)
 810       nil))
 811
 812 (defmethod compute-effective-method-body
 813     ((method simple-effective-method) codegen target)
 814   (basic-effective-method-body codegen target method
 815                                (lambda (target)
 816                                  (simple-method-body method
 817                                                      codegen
 818                                                      target))))
 819
 820 ;;;--------------------------------------------------------------------------
 821 ;;; Standard method combination.
 822
 823 (export 'standard-message)
 824 (defclass standard-message (simple-message)
 825   ()
 826   (:documentation
 827    "Message class for standard method combinations.
 828
 829    Standard method combination is a simple method combination where the
 830    primary methods are invoked as a delegation chain, from most- to
 831    least-specific."))
 832
 833 (export 'standard-effective-method)
 834 (defclass standard-effective-method (simple-effective-method) ()
 835   (:documentation "Effective method counterpart to `standard-message'."))
 836
 837 (defmethod primary-method-class ((message standard-message))
 838   'delegating-direct-method)
 839
 840 (defmethod sod-message-effective-method-class ((message standard-message))
 841   'standard-effective-method)
 842
 843 (defmethod simple-method-body
 844     ((method standard-effective-method) codegen target)
 845   (invoke-delegation-chain codegen
 846                            target
 847                            (effective-method-basic-argument-names method)
 848                            (effective-method-primary-methods method)
 849                            nil))
 850
 851 ;;;----- That's all, folks --------------------------------------------------