chiark - git - mdw - sod/blob - src/final.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Finishing touches for Sod
   4 ;;;
   5 ;;; (c) 2015 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Miscellaneous details.
  30
  31 (export '*sod-version*)
  32 (defparameter *sod-version* sod-sysdef:*version*
  33   "The version of the SOD translator system, as a string.")
  34
  35 ;;;--------------------------------------------------------------------------
  36 ;;; Debugging utilities.
  37
  38 (export '*debugout-pathname*)
  39 (defvar *debugout-pathname* #p"debugout.c")
  40
  41 (export 'test-module)
  42 (defun test-module (path &key reason clear backtrace)
  43   "Read a module from PATH, to exercise the machinery.
  44
  45    If CLEAR is non-nil, then reset the translator's state before proceeding.
  46
  47    If REASON is non-nil, then output the module to `*debugout-pathname*' with
  48    that REASON.
  49
  50    Return a two-element list (NERROR NWARNING) of the number of errors and
  51    warnings encountered while processing the module."
  52   (when clear (clear-the-decks))
  53   (multiple-value-bind (module nerror nwarning)
  54       (if backtrace (read-module path)
  55           (count-and-report-errors () (read-module path)))
  56     (when (and module reason)
  57       (with-open-file (out *debugout-pathname*
  58                        :direction :output
  59                        :if-exists :supersede
  60                        :if-does-not-exist :create)
  61         (output-module module reason out)))
  62     (list nerror nwarning)))
  63
  64 (export 'test-parse-c-type)
  65 (defun test-parse-c-type (string)
  66   "Parse STRING as a C type, with optional kernel, and show the results."
  67   (with-input-from-string (in string)
  68     (let* ((*module-type-map* (make-hash-table))
  69            (charscan (make-instance 'charbuf-scanner
  70                                     :stream in
  71                                     :filename "<string>"))
  72            (tokscan (make-instance 'sod-token-scanner
  73                                    :char-scanner charscan
  74                                    :filename "<string>")))
  75       (with-parser-context (token-scanner-context :scanner tokscan)
  76         (multiple-value-bind (value winp consumedp)
  77             (parse (seq ((decls (parse-c-type tokscan))
  78                          (type (parse-declarator tokscan decls :abstractp t))
  79                          :eof)
  80                      type))
  81           (declare (ignore consumedp))
  82           (if winp
  83               (values t (car value) (cdr value)
  84                       (princ-to-string (car value)))
  85               (values nil value)))))))
  86
  87 (export 'test-parser)
  88 (defmacro test-parser ((scanner &key backtrace) parser input)
  89   "Convenient macro for testing parsers at the REPL.
  90
  91    This is a macro so that the parser can use the fancy syntax.  The name
  92    SCANNER is bound to a `sod-token-scanner' reading tokens from the INPUT
  93    string.  Then the PARSER is invoked and three values are returned: the
  94    result of the parse, or `nil' if the main parse failed; a list containing
  95    the number of errors and warnings (respectively) reported during the
  96    parse; and a list consisting of the lookahead token type and value, and a
  97    string containing the untokenized remaining input.
  98
  99    If BACKTRACE is nil (the default) then leave errors to the calling
 100    environment to sort out (e.g., by entering the Lisp debugger); otherwise,
 101    catch and report them as they happen so that you can test error recovery
 102    strategies."
 103   (once-only (input)
 104     (with-gensyms (char-scanner value winp body consumedp where nerror nwarn)
 105       `(let ((,char-scanner nil) (,scanner nil))
 106          (with-parser-context (token-scanner-context :scanner ,scanner)
 107            (multiple-value-bind (,value ,nerror ,nwarn)
 108                (flet ((,body ()
 109                         (setf ,char-scanner (make-string-scanner ,input)
 110                               ,scanner (make-instance
 111                                         'sod-token-scanner
 112                                         :char-scanner ,char-scanner))
 113                         (with-default-error-location (,scanner)
 114                           (multiple-value-bind (,value ,winp ,consumedp)
 115                               (parse ,parser)
 116                             (declare (ignore ,consumedp))
 117                             (cond (,winp ,value)
 118                                   (t (syntax-error ,scanner ,value)
 119                                      nil))))))
 120                  (if ,backtrace (,body)
 121                      (count-and-report-errors ()
 122                        (,body))))
 123              (let ((,where (scanner-capture-place ,char-scanner)))
 124                (values ,value
 125                        (list ,nerror ,nwarn)
 126                        (and ,scanner (list (token-type ,scanner)
 127                                            (token-value ,scanner)
 128                                            (subseq ,input ,where)))))))))))
 129
 130 ;;;--------------------------------------------------------------------------
 131 ;;; Calisthenics.
 132
 133 (export 'exercise)
 134 (defun exercise ()
 135   "Exercise the pieces of the metaobject protocol.
 136
 137    In some Lisps, the compiler is run the first time methods are called, to
 138    do fancy just-in-time optimization things.  This is great, only the
 139    program doesn't actually run for very long and a lot of that work is
 140    wasted because we're going to have to do it again next time the program
 141    starts.  Only, if we exercise the various methods, or at least a large
 142    fraction of them, before we dump an image, then everything will be fast.
 143
 144    That's the theory anyway.  Call this function before you dump an image and
 145    see what happens."
 146
 147   (dolist (reason '(:h :c))
 148     (with-output-to-string (bitbucket)
 149       (output-module *builtin-module* reason bitbucket)))
 150
 151   (clear-the-decks))
 152
 153 ;;;--------------------------------------------------------------------------
 154 ;;; Make sure things work after loading the system.
 155
 156 (clear-the-decks)
 157
 158 ;;;----- That's all, folks --------------------------------------------------