chiark - git - mdw - sod/blob - src/module-parse.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Top-level parser for module syntax
   4 ;;;
   5 ;;; (c) 2010 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Toplevel syntax.
  30
  31 ;;; Type names.
  32
  33 (define-pluggable-parser module typename (scanner pset)
  34   ;; `typename' list[id] `;'
  35   (declare (ignore pset))
  36   (with-parser-context (token-scanner-context :scanner scanner)
  37     (parse (and "typename"
  38                 (skip-many ()
  39                   (error ()
  40                       (seq ((id :id))
  41                         (if (or (gethash id *module-type-map*)
  42                                 (find-simple-c-type id))
  43                             (cerror* "Type `~A' already defined" id)
  44                             (add-to-module *module*
  45                                            (make-instance 'type-item
  46                                                           :name id))))
  47                     (skip-until () #\, #\;))
  48                   #\,)
  49                 (must #\;)))))
  50
  51 ;;; Fragments.
  52
  53 (define-pluggable-parser module code (scanner pset)
  54   ;; `code' id `:' item-name [constraints] `{' c-fragment `}'
  55   ;;
  56   ;; constraints ::= `[' list[constraint] `]'
  57   ;; constraint ::= item-name+
  58   ;; item-name ::= id | `(' id+ `)'
  59   (declare (ignore pset))
  60   (with-parser-context (token-scanner-context :scanner scanner)
  61     (labels ((kw ()
  62                (parse (seq ((kw :id))
  63                         (intern (frob-identifier kw) 'keyword))))
  64              (item ()
  65                (parse (or (kw)
  66                           (seq (#\( (names (list (:min 1) (kw))) #\))
  67                             names)))))
  68       (parse (seq ("code"
  69                    (reason (must (kw)))
  70                    (nil (must #\:))
  71                    (name (must (item)))
  72                    (constraints (? (seq (#\[
  73                                          (constraints
  74                                           (list ()
  75                                             (list (:min 1)
  76                                               (error (:ignore-unconsumed t)
  77                                                   (item)
  78                                                 (skip-until ()
  79                                                   :id #\( #\, #\])))
  80                                             #\,))
  81                                          #\])
  82                                      constraints)))
  83                    (fragment (parse-delimited-fragment scanner #\{ #\})))
  84                (when name
  85                  (add-to-module *module*
  86                                 (make-instance 'code-fragment-item
  87                                                :fragment fragment
  88                                                :constraints constraints
  89                                                :reason reason
  90                                                :name name))))))))
  91
  92 ;;; External files.
  93
  94 (export 'read-module)
  95 (defun read-module (pathname &key (truename nil truep) location)
  96   "Parse the file at PATHNAME as a module, returning it.
  97
  98    This is the main entry point for parsing module files.  You may well know
  99    the file's TRUENAME already (e.g., because `probe-file' dropped it into
 100    your lap) so you can avoid repeating the search by providing it.
 101
 102    The LOCATION is the thing which wanted the module imported -- usually a
 103    `file-location' object, though it might be anything other than `t' which
 104    can be printed in the event of circular imports."
 105
 106   (setf pathname (merge-pathnames pathname
 107                                   (make-pathname :type "SOD" :case :common)))
 108   (unless truep (setf truename (truename pathname)))
 109   (define-module (pathname :location location :truename truename)
 110     (with-open-file (f-stream pathname :direction :input)
 111       (let* ((*readtable* (copy-readtable))
 112              (*package* (find-package '#:sod-user))
 113              (char-scanner (make-instance 'charbuf-scanner
 114                                           :stream f-stream
 115                                           :filename (namestring pathname)))
 116              (scanner (make-instance 'sod-token-scanner
 117                                      :char-scanner char-scanner)))
 118         (with-default-error-location (scanner)
 119           (with-parser-context (token-scanner-context :scanner scanner)
 120             (multiple-value-bind (result winp consumedp)
 121                 (parse (skip-many ()
 122                           (seq ((pset (parse-property-set scanner))
 123                                 (nil (error ()
 124                                          (plug module scanner pset)
 125                                        (skip-until (:keep-end nil)
 126                                          #\; #\}))))
 127                             (check-unused-properties pset))))
 128               (declare (ignore consumedp))
 129               (unless winp (syntax-error scanner result)))))))))
 130
 131 (define-pluggable-parser module test (scanner pset)
 132   ;; `demo' string `;'
 133   (declare (ignore pset))
 134   (with-parser-context (token-scanner-context :scanner scanner)
 135     (parse (seq ("demo" (string (must :string)) (nil (must #\;)))
 136              (format t ";; DEMO ~S~%" string)))))
 137
 138 (define-pluggable-parser module file (scanner pset)
 139   ;; `import' string `;'
 140   ;; `load' string `;'
 141   (declare (ignore pset))
 142   (flet ((common (name type what thunk)
 143            (find-file scanner
 144                       (merge-pathnames name
 145                                        (make-pathname :type type
 146                                                       :case :common))
 147                       what
 148                       thunk)))
 149     (with-parser-context (token-scanner-context :scanner scanner)
 150       (parse (or (seq ("import" (name :string) #\;)
 151                    (common name "SOD" "module"
 152                            (lambda (path true)
 153                              (handler-case
 154                                  (let ((module (read-module path
 155                                                             :truename true)))
 156                                    (when module
 157                                      (module-import module)
 158                                      (pushnew module
 159                                               (module-dependencies
 160                                                *module*))))
 161                                (file-error (error)
 162                                  (cerror* "Error reading module ~S: ~A"
 163                                           path error))))))
 164                  (seq ("load" (name :string) #\;)
 165                    (common name "LISP" "Lisp file"
 166                            (lambda (path true)
 167                              (handler-case
 168                                  (load true :verbose nil :print nil)
 169                                (error (error)
 170                                  (cerror* "Error loading Lisp file ~S: ~A"
 171                                           path error)))))))))))
 172
 173 ;;; Setting properties.
 174
 175 (define-pluggable-parser module set (scanner pset)
 176   ;; `set' list[property] `;'
 177   (with-parser-context (token-scanner-context :scanner scanner)
 178     (parse (and "set"
 179                 (lisp (let ((module-pset (module-pset *module*)))
 180                         (when pset
 181                           (pset-map (lambda (prop)
 182                                       (add-property
 183                                        module-pset
 184                                        (p-name prop) (p-value prop)
 185                                        :type (p-type prop)
 186                                        :location (p-location prop))
 187                                       (setf (p-seenp prop) t))
 188                                     pset))
 189                         (parse (skip-many (:min (if pset 0 1))
 190                                  (error (:ignore-unconsumed t)
 191                                      (parse-property scanner module-pset)
 192                                    (skip-until () #\, #\;))
 193                                  #\,))))
 194                 #\;))))
 195
 196 ;;; Lisp escape.
 197
 198 (define-pluggable-parser module lisp (scanner pset)
 199   ;; `lisp' s-expression `;'
 200   (declare (ignore pset))
 201   (with-parser-context (token-scanner-context :scanner scanner)
 202     (parse (seq ((sexp (if (and (eql (token-type scanner) :id)
 203                                 (string= (token-value scanner) "lisp"))
 204                            (let* ((stream (make-scanner-stream scanner))
 205                                   (sexp (read stream t)))
 206                              (scanner-step scanner)
 207                              (values sexp t t))
 208                            (values '((:id "lisp")) nil nil)))
 209                  #\;)
 210              (eval sexp)))))
 211
 212 ;;;--------------------------------------------------------------------------
 213 ;;; Class declarations.
 214
 215 (export 'class-item)
 216
 217 (define-pluggable-parser class-item initfrags (scanner class pset)
 218   ;; raw-class-item ::= frag-keyword `{' c-fragment `}'
 219   ;; frag-keyword ::= `init' | `teardown'
 220   (with-parser-context (token-scanner-context :scanner scanner)
 221     (parse (seq ((make (or (seq ("init") #'make-sod-class-initfrag)
 222                            (seq ("teardown") #'make-sod-class-tearfrag)))
 223                  (frag (parse-delimited-fragment scanner #\{ #\})))
 224              (funcall make class frag pset scanner)))))
 225
 226 (define-pluggable-parser class-item initargs (scanner class pset)
 227   ;; initarg-item ::= `initarg' declspec+ list[init-declarator]
 228   ;; init-declarator ::= declarator [`=' initializer]
 229   (with-parser-context (token-scanner-context :scanner scanner)
 230     (parse (seq ("initarg"
 231                  (base-type (parse-c-type scanner))
 232                  (nil (skip-many (:min 1)
 233                         (seq ((declarator (parse-declarator scanner
 234                                                             base-type))
 235                               (init (? (parse-delimited-fragment
 236                                         scanner #\= (list #\; #\,)
 237                                         :keep-end t))))
 238                           (make-sod-user-initarg class
 239                                                  (cdr declarator)
 240                                                  (car declarator)
 241                                                  pset init scanner))
 242                         #\,))
 243                    #\;)))))
 244
 245 (defun parse-class-body (scanner pset name supers)
 246   ;; class-body ::= `{' class-item* `}'
 247   ;;
 248   ;; class-item ::= property-set raw-class-item
 249   (with-parser-context (token-scanner-context :scanner scanner)
 250     (make-class-type name)
 251     (let* ((duff nil)
 252            (class (make-sod-class name
 253                                   (restart-case
 254                                       (mapcar #'find-sod-class supers)
 255                                     (continue ()
 256                                       (setf duff t)
 257                                       (list (find-sod-class "SodObject"))))
 258                                   pset scanner))
 259            (nick (sod-class-nickname class)))
 260
 261       (labels ((parse-maybe-dotted-declarator (base-type)
 262                  ;; Parse a declarator or dotted-declarator, i.e., one whose
 263                  ;; centre is
 264                  ;;
 265                  ;; maybe-dotted-identifier ::= [id `.'] id
 266                  ;;
 267                  ;; A plain identifier is returned as a string, as usual; a
 268                  ;; dotted identifier is returned as a cons cell of the two
 269                  ;; names.
 270                  (parse-declarator
 271                   scanner base-type
 272                   :keywordp t
 273                   :kernel (parser ()
 274                             (seq ((name-a :id)
 275                                   (name-b (? (seq (#\. (id :id)) id))))
 276                               (if name-b (cons name-a name-b)
 277                                   name-a)))))
 278
 279                (parse-message-item (sub-pset type name)
 280                  ;; message-item ::=
 281                  ;;     declspec+ declarator -!- (method-body | `;')
 282                  ;;
 283                  ;; Don't allow a method-body here if the message takes a
 284                  ;; varargs list, because we don't have a name for the
 285                  ;; `va_list' parameter.
 286                  (let ((message (make-sod-message class name type
 287                                                   sub-pset scanner)))
 288                    (if (varargs-message-p message)
 289                        (parse #\;)
 290                        (parse (or #\; (parse-method-item sub-pset
 291                                                          type nick name))))))
 292
 293                (parse-method-item (sub-pset type sub-nick name)
 294                  ;; method-item ::=
 295                  ;;     declspec+ dotted-declarator -!- method-body
 296                  ;;
 297                  ;; method-body ::= `{' c-fragment `}' | `extern' `;'
 298                  (parse (seq ((body (or (seq ("extern" #\;) nil)
 299                                         (parse-delimited-fragment
 300                                          scanner #\{ #\}))))
 301                           (make-sod-method class sub-nick name type
 302                                            body sub-pset scanner))))
 303
 304                (parse-initializer ()
 305                  ;; initializer ::= `=' c-fragment
 306                  ;;
 307                  ;; Return a VALUE, ready for passing to a `sod-initializer'
 308                  ;; constructor.
 309                  (parse-delimited-fragment scanner #\= (list #\, #\;)
 310                                            :keep-end t))
 311
 312                (parse-slot-item (sub-pset base-type type name)
 313                  ;; slot-item ::=
 314                  ;;     declspec+ declarator -!- [initializer]
 315                  ;;             [`,' list[init-declarator]] `;'
 316                  ;;
 317                  ;; init-declarator ::= declarator [initializer]
 318                  (parse (and (seq ((init (? (parse-initializer))))
 319                                (make-sod-slot class name type
 320                                               sub-pset scanner)
 321                                (when init
 322                                  (make-sod-instance-initializer
 323                                   class nick name init sub-pset scanner)))
 324                              (skip-many ()
 325                                (seq (#\,
 326                                      (ds (parse-declarator scanner
 327                                                            base-type))
 328                                      (init (? (parse-initializer))))
 329                                  (make-sod-slot class (cdr ds) (car ds)
 330                                                 sub-pset scanner)
 331                                  (when init
 332                                    (make-sod-instance-initializer
 333                                     class nick (cdr ds) init
 334                                     sub-pset scanner))))
 335                              #\;)))
 336
 337                (parse-initializer-item (sub-pset must-init-p constructor)
 338                  ;; initializer-item ::=
 339                  ;;     [`class'] -!- list[slot-initializer] `;'
 340                  ;;
 341                  ;; slot-initializer ::= id `.' id [initializer]
 342                  (let ((parse-init (if must-init-p #'parse-initializer
 343                                        (parser () (? (parse-initializer))))))
 344                    (parse (and (skip-many ()
 345                                  (seq ((name-a :id) #\. (name-b :id)
 346                                        (init (funcall parse-init)))
 347                                    (funcall constructor class
 348                                             name-a name-b init
 349                                             sub-pset scanner))
 350                                  #\,)
 351                                #\;))))
 352
 353                (class-item-dispatch (sub-pset base-type type name)
 354                  ;; Logically part of `parse-raw-class-item', but the
 355                  ;; indentation was getting crazy.  We're currently at
 356                  ;;
 357                  ;; raw-class-item ::=
 358                  ;;     declspec+ (declarator | dotted-declarator) -!- ...
 359                  ;;   | other-items
 360                  ;;
 361                  ;; If the declarator is dotted then this must be a method
 362                  ;; definition; otherwise it might be a message or slot.
 363                  (cond ((not (typep type 'c-function-type))
 364                         (when (consp name)
 365                           (cerror*
 366                            "Method declarations must have function type")
 367                           (setf name (cdr name)))
 368                         (parse-slot-item sub-pset base-type type name))
 369                        ((consp name)
 370                         (parse-method-item sub-pset type
 371                                            (car name) (cdr name)))
 372                        (t
 373                         (parse-message-item sub-pset type name))))
 374
 375                (parse-raw-class-item (sub-pset)
 376                  ;; raw-class-item ::=
 377                  ;;     message-item
 378                  ;;   | method-item
 379                  ;;   | slot-item
 380                  ;;   | initializer-item
 381                  ;;   | initfrag-item
 382                  ;;
 383                  ;; Most of the above begin with declspecs and a declarator
 384                  ;; (which might be dotted).  So we parse that here and
 385                  ;; dispatch based on what we find.
 386                  (parse (or (plug class-item scanner class sub-pset)
 387                             (peek
 388                              (seq ((ds (parse-c-type scanner))
 389                                    (dc (parse-maybe-dotted-declarator ds))
 390                                    (nil (commit))
 391                                    (nil (class-item-dispatch sub-pset
 392                                                              ds
 393                                                              (car dc)
 394                                                              (cdr dc))))))
 395                             (and "class"
 396                                  (parse-initializer-item sub-pset t
 397                                   #'make-sod-class-initializer))
 398                             (parse-initializer-item sub-pset nil
 399                              #'make-sod-instance-initializer)))))
 400
 401         (parse (seq (#\{
 402                      (nil (skip-many ()
 403                             (seq ((sub-pset (parse-property-set scanner))
 404                                   (nil (parse-raw-class-item sub-pset)))
 405                               (check-unused-properties sub-pset))))
 406                      (nil (error () #\})))
 407                  (unless (finalize-sod-class class)
 408                    (setf duff t))
 409                  (unless duff
 410                    (add-to-module *module* class))))))))
 411
 412 (define-pluggable-parser module class (scanner pset)
 413   ;; `class' id `:' list[id] class-body
 414   ;; `class' id `;'
 415   (with-parser-context (token-scanner-context :scanner scanner)
 416     (parse (seq ("class"
 417                  (name :id)
 418                  (nil (or (seq (#\;)
 419                             (make-class-type name))
 420                           (seq ((supers (seq (#\: (ids (list () :id #\,)))
 421                                           ids))
 422                                 (nil (parse-class-body
 423                                       scanner
 424                                       pset name supers)))))))))))
 425
 426 ;;;----- That's all, folks --------------------------------------------------