chiark - git - mdw - sod/blob - src/lexer-impl.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Implementation of lexical analysis protocol.
   4 ;;;
   5 ;;; (c) 2009 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Class implementation.
  30
  31 (defmethod shared-initialize :after
  32     ((scanner sod-token-scanner) slot-names &key)
  33   (default-slot (scanner 'sod-parser::filename slot-names)
  34     (scanner-filename (token-scanner-char-scanner scanner))))
  35
  36 (defmethod make-scanner-stream ((scanner sod-token-scanner))
  37   (make-scanner-stream (token-scanner-char-scanner scanner)))
  38
  39 ;;;--------------------------------------------------------------------------
  40 ;;; Indicators and error messages.
  41
  42 (defun show-char (char)
  43   "Format CHAR as a string in a readable way."
  44   (cond ((null char) "<end-of-file>")
  45         ((and (graphic-char-p char) (char/= char #\space))
  46          (format nil "`~C'" char))
  47         (t (format nil "<~(~:C~)>" char))))
  48
  49 (defun %skip-until (scanner token-types
  50                     &key (keep-end (not (null (cdr token-types)))))
  51   "This is the implementation of the `skip-until' parser."
  52   (do ((consumedp nil t))
  53       ((member (token-type scanner) token-types)
  54        (unless keep-end (scanner-step scanner))
  55        (values nil t (or keep-end consumedp)))
  56     (when (scanner-at-eof-p scanner)
  57       (return (values token-types nil consumedp)))
  58     (scanner-step scanner)))
  59
  60 (defun parse-error-recover (scanner parser recover
  61                             &key ignore-unconsumed force-progress)
  62   "This is the implementation of the `error' parser."
  63   (multiple-value-bind (result win consumedp) (funcall parser)
  64     (cond ((or win
  65                (and (not consumedp)
  66                     (or ignore-unconsumed
  67                         (scanner-at-eof-p scanner))))
  68            ;; If we succeeded, or if we didn't consume any tokens and the
  69            ;; caller's OK with that, then there's nothing for us to do here.
  70            ;; On the other hand, if we failed, didn't consume any tokens, and
  71            ;; we're at end-of-file, then there's not much hope of making
  72            ;; onward progress, so in this case we propagate the failure
  73            ;; rather than trying to recover.  And we assume that the
  74            ;; continuation will somehow arrange to report the problem, and
  75            ;; avoid inundating the user with error reports.
  76            (values result win consumedp))
  77           (t
  78            ;; Now we have to do some kind of sensible error recovery.  The
  79            ;; important thing to do here is to make sure that we make some
  80            ;; progress.  If we consumed any tokens then we're fine, and we'll
  81            ;; just try the provided recovery strategy.  Otherwise, if we're
  82            ;; not at EOF, then we can ensure progress by discarding the
  83            ;; current token.  Finally, if we are at EOF then our best bet is
  84            ;; simply to propagate the current failure back to the caller, but
  85            ;; we handled that case above.
  86            (syntax-error scanner result)
  87            (when (and force-progress (not consumedp)) (scanner-step scanner))
  88            (funcall recover)))))
  89
  90 ;;;--------------------------------------------------------------------------
  91 ;;; Token scanning.
  92
  93 (defmethod scanner-token ((scanner sod-token-scanner))
  94   (with-slots (char-scanner line column) scanner
  95     (with-parser-context (character-scanner-context :scanner char-scanner)
  96
  97       (flet ((scan-digits (&key (radix 10) (min 1) (init 0))
  98                ;; Scan and return a sequence of digits.
  99                (parse (many (acc init (+ (* acc radix) it) :min min)
 100                         (label (list :digit radix)
 101                                (filter (lambda (ch)
 102                                          (digit-char-p ch radix)))))))
 103              (start-floc ()
 104                ;; This is a little nasty.  We scan the first token during
 105                ;; instance initialization, as a result of `shared-initialize'
 106                ;; on `token-scanner'.  Unfortunately, this happens before
 107                ;; we've had a chance to initialize our own `filename' slot.
 108                ;; This means that we can't use the SCANNER as a file
 109                ;; location, however tempting it might be.  So we have this
 110                ;; hack.
 111                (make-file-location (scanner-filename char-scanner)
 112                                    (scanner-line scanner)
 113                                    (scanner-column scanner))))
 114
 115         ;; Skip initial junk, and remember the place.
 116         (loop
 117           (setf (scanner-line scanner) (scanner-line char-scanner)
 118                 (scanner-column scanner) (scanner-column char-scanner))
 119           (cond-parse (:consumedp cp :expected exp)
 120             ((satisfies whitespace-char-p) (parse :whitespace))
 121             ((scan-comment char-scanner))
 122             (t (if cp (lexer-error char-scanner exp) (return)))))
 123
 124         ;; Now parse something.
 125         (cond-parse (:consumedp cp :expected exp)
 126
 127           ;; Alphanumerics mean we read an identifier.
 128           ((or #\_ (satisfies alpha-char-p))
 129            (values :id (with-output-to-string (out)
 130                          (write-char it out)
 131                          (parse (many (nil nil (write-char it out))
 132                                   (or #\_ (satisfies alphanumericp)))))))
 133
 134           ;; Quotes introduce a literal.
 135           ((seq ((quote (or #\" #\'))
 136                  (contents (many (out (make-string-output-stream)
 137                                       (progn (write-char it out) out)
 138                                       :final (get-output-stream-string out))
 139                              (or (and #\\ :any) (not quote))))
 140                  (nil (or (char quote)
 141                           (seq (:eof)
 142                             (lexer-error char-scanner (list quote))
 143                             (info-with-location
 144                              (start-floc) "Literal started here")))))
 145              (ecase quote
 146                (#\" contents)
 147                (#\' (case (length contents)
 148                       (1 (char contents 0))
 149                       (0 (cerror*-with-location (start-floc)
 150                                                 'simple-lexer-error
 151                                                 :format-control
 152                                                 "Empty character literal")
 153                          #\?)
 154                       (t (cerror*-with-location (start-floc)
 155                                                 'simple-lexer-error
 156                                                 :format-control
 157                                                 "Too many characters ~
 158                                                  in character literal")
 159                          (char contents 0))))))
 160            (values (etypecase it
 161                      (character :char)
 162                      (string :string))
 163                    it))
 164
 165           ;; Zero introduces a chosen-radix integer.
 166           ((and #\0
 167                 (or (and (or #\b #\B) (scan-digits :radix 2))
 168                     (and (or #\o #\O) (scan-digits :radix 8))
 169                     (and (or #\x #\X) (scan-digits :radix 16))
 170                     (scan-digits :radix 8 :min 0)))
 171            (values :int it))
 172
 173           ;; Any other digit forces radix-10.
 174           ((seq ((d (filter digit-char-p))
 175                  (i (scan-digits :radix 10 :min 0 :init d)))
 176              i)
 177            (values :int it))
 178
 179           ;; Some special punctuation sequences are single tokens.
 180           ("..." (values :ellipsis nil))
 181
 182           ;; Any other character is punctuation.
 183           (:any (values it nil))
 184
 185           ;; End of file means precisely that.
 186           (:eof (values :eof nil))
 187
 188           ;; Report errors and try again.  Because we must have consumed some
 189           ;; input in order to get here (we've matched both :any and :eof) we
 190           ;; must make progress on every call.
 191           (t
 192            (assert cp)
 193            (lexer-error char-scanner exp)
 194            (scanner-token scanner)))))))
 195
 196 ;;;----- That's all, folks --------------------------------------------------